This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
regen/unicode_constants.pl: Remove unused constant
[perl5.git] / regen / unicode_constants.pl
1 use v5.16.0;
2 use strict;
3 use warnings;
4 require 'regen/regen_lib.pl';
5 use charnames qw(:loose);
6
7 my $out_fh = open_new('unicode_constants.h', '>',
8                       {style => '*', by => $0,
9                       from => "Unicode data"});
10
11 print $out_fh <<END;
12
13 #ifndef H_UNICODE_CONSTANTS   /* Guard against nested #includes */
14 #define H_UNICODE_CONSTANTS   1
15
16 /* This file contains #defines for various Unicode code points.  The values
17  * the macros expand to are the native Unicode code point, or all or portions
18  * of the UTF-8 encoding for the code point.  In the former case, the macro
19  * name has the suffix "_NATIVE"; otherwise, the suffix "_UTF8".
20  *
21  * The macros that have the suffix "_UTF8" may have further suffixes, as
22  * follows:
23  *  "_FIRST_BYTE" if the value is just the first byte of the UTF-8
24  *                representation; the value will be a numeric constant.
25  *  "_TAIL"       if instead it represents all but the first byte.  This, and
26  *                with no additional suffix are both string constants */
27
28 END
29
30 # The data are at the end of this file.  A blank line is output as-is.
31 # Comments (lines whose first non-blank is a '#') are converted to C-style,
32 # though empty comments are converted to blank lines.  Otherwise, each line
33 # represents one #define, and begins with either a Unicode character name with
34 # the blanks and dashes in it squeezed out or replaced by underscores; or it
35 # may be a hexadecimal Unicode code point.  In the latter
36 # case, the name will be looked-up to use as the name of the macro.  In either
37 # case, the macro name will have suffixes as listed above, and all blanks and
38 # dashes will be replaced by underscores.
39 #
40 # Each line may optionally have one of the following flags on it, separated by
41 # white space from the initial token.
42 #   string  indicates that the output is to be of the string form
43 #           described in the comments above that are placed in the file.
44 #   string_skip_ifundef  is the same as 'string', but instead of dying if the
45 #           code point doesn't exist, the line is just skipped: no output is
46 #           generated for it
47 #   first   indicates that the output is to be of the FIRST_BYTE form.
48 #   tail    indicates that the output is of the _TAIL form.
49 #   native  indicates that the output is the code point, converted to the
50 #           platform's native character set if applicable
51 #
52 # If the code point has no official name, the desired name may be appended
53 # after the flag, which will be ignored if there is an official name.
54 #
55 # This program is used to make it convenient to create compile time constants
56 # of UTF-8, and to generate proper EBCDIC as well as ASCII without manually
57 # having to figure things out.
58
59 while ( <DATA> ) {
60     chomp;
61
62     # Convert any '#' comments to /* ... */; empty lines and comments are
63     # output as blank lines
64     if ($_ =~ m/ ^ \s* (?: \# ( .* ) )? $ /x) {
65         my $comment_body = $1 // "";
66         if ($comment_body ne "") {
67             print $out_fh "/* $comment_body */\n";
68         }
69         else {
70             print $out_fh "\n";
71         }
72         next;
73     }
74
75     unless ($_ =~ m/ ^ ( [^\ ]* )           # Name or code point token
76                        (?: [\ ]+ ( [^ ]* ) )?  # optional flag
77                        (?: [\ ]+ ( .* ) )?  # name if unnamed; flag is required
78                    /x)
79     {
80         die "Unexpected syntax at line $.: $_\n";
81     }
82
83     my $name_or_cp = $1;
84     my $flag = $2;
85     my $desired_name = $3;
86
87     my $name;
88     my $cp;
89     my $undef_ok = $desired_name || $flag =~ /skip_if_undef/;
90
91     if ($name_or_cp =~ /[^[:xdigit:]]/) {
92
93         # Anything that isn't a hex value must be a name.
94         $name = $name_or_cp;
95         $cp = charnames::vianame($name =~ s/_/ /gr);
96         die "Unknown name '$name' at line $.: $_\n" unless defined $name;
97     }
98     else {
99         $cp = $name_or_cp;
100         $name = charnames::viacode("0$cp"); # viacode requires a leading zero
101                                             # to be sure that the argument is
102                                             # hex
103         if (! defined $name) {
104             die "Unknown code point '$cp' at line $.: $_\n" unless $undef_ok;
105             $name = "";
106         }
107     }
108
109     $name = $desired_name if $name eq "" && $desired_name;
110     $name =~ s/[- ]/_/g;   # The macro name can have no blanks nor dashes
111
112     my $str = join "", map { sprintf "\\x%02X", $_ }
113                        unpack("U0C*", pack("U", hex $cp));
114
115     my $suffix = '_UTF8';
116     if (! defined $flag  || $flag =~ /^ string (_skip_if_undef)? $/x) {
117         $str = "\"$str\"";  # Will be a string constant
118     } elsif ($flag eq 'tail') {
119             $str =~ s/\\x..//;  # Remove the first byte
120             $suffix .= '_TAIL';
121             $str = "\"$str\"";  # Will be a string constant
122     }
123     elsif ($flag eq 'first') {
124         $str =~ s/ \\x ( .. ) .* /$1/x; # Get the two nibbles of the 1st byte
125         $suffix .= '_FIRST_BYTE';
126         $str = "0x$str";        # Is a numeric constant
127     }
128     elsif ($flag eq 'native') {
129         die "Are you sure you want to run this on an above-Latin1 code point?" if hex $cp > 0xff;
130         $suffix = '_NATIVE';
131         $str = utf8::unicode_to_native(hex $cp);
132         $str = "0x$cp";        # Is a numeric constant
133     }
134     else {
135         die "Unknown flag at line $.: $_\n";
136     }
137     print $out_fh "#define ${name}$suffix $str    /* U+$cp */\n";
138 }
139
140 print $out_fh "\n#endif /* H_UNICODE_CONSTANTS */\n";
141
142 read_only_bottom_close_and_rename($out_fh);
143
144 __DATA__
145 0300 string
146 0301 string
147 0308 string
148
149 03B9 string
150
151 03C5 string
152
153 2010 string
154 D800 first FIRST_SURROGATE
155
156 007F native
157 00DF native
158 00E5 native
159 00C5 native
160 00FF native
161 00B5 native