This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
forbid -l _ after -T _
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<sockatmark>, C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<sockatmark>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item I<-X> FILEHANDLE
250
251 =item I<-X> EXPR
252
253 =item I<-X>
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Age of file in days when script started.
298     -A  Same for access time.
299     -C  Same for inode change time.
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 =item abs VALUE
370
371 =item abs
372
373 Returns the absolute value of its argument.
374 If VALUE is omitted, uses C<$_>.
375
376 =item accept NEWSOCKET,GENERICSOCKET
377
378 Accepts an incoming socket connect, just as the accept(2) system call
379 does.  Returns the packed address if it succeeded, false otherwise.
380 See the example in L<perlipc/"Sockets: Client/Server Communication">.
381
382 On systems that support a close-on-exec flag on files, the flag will
383 be set for the newly opened file descriptor, as determined by the
384 value of $^F.  See L<perlvar/$^F>.
385
386 =item alarm SECONDS
387
388 =item alarm
389
390 Arranges to have a SIGALRM delivered to this process after the
391 specified number of wallclock seconds have elapsed.  If SECONDS is not
392 specified, the value stored in C<$_> is used. (On some machines,
393 unfortunately, the elapsed time may be up to one second less or more
394 than you specified because of how seconds are counted, and process
395 scheduling may delay the delivery of the signal even further.)
396
397 Only one timer may be counting at once.  Each call disables the
398 previous timer, and an argument of C<0> may be supplied to cancel the
399 previous timer without starting a new one.  The returned value is the
400 amount of time remaining on the previous timer.
401
402 For delays of finer granularity than one second, you may use Perl's
403 four-argument version of select() leaving the first three arguments
404 undefined, or you might be able to use the C<syscall> interface to
405 access setitimer(2) if your system supports it.  The Time::HiRes
406 module (from CPAN, and starting from Perl 5.8 part of the standard
407 distribution) may also prove useful.
408
409 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
410 (C<sleep> may be internally implemented in your system with C<alarm>)
411
412 If you want to use C<alarm> to time out a system call you need to use an
413 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
414 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
415 restart system calls on some systems.  Using C<eval>/C<die> always works,
416 modulo the caveats given in L<perlipc/"Signals">.
417
418     eval {
419         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
420         alarm $timeout;
421         $nread = sysread SOCKET, $buffer, $size;
422         alarm 0;
423     };
424     if ($@) {
425         die unless $@ eq "alarm\n";   # propagate unexpected errors
426         # timed out
427     }
428     else {
429         # didn't
430     }
431
432 =item atan2 Y,X
433
434 Returns the arctangent of Y/X in the range -PI to PI.
435
436 For the tangent operation, you may use the C<Math::Trig::tan>
437 function, or use the familiar relation:
438
439     sub tan { sin($_[0]) / cos($_[0])  }
440
441 =item bind SOCKET,NAME
442
443 Binds a network address to a socket, just as the bind system call
444 does.  Returns true if it succeeded, false otherwise.  NAME should be a
445 packed address of the appropriate type for the socket.  See the examples in
446 L<perlipc/"Sockets: Client/Server Communication">.
447
448 =item binmode FILEHANDLE, DISCIPLINE
449
450 =item binmode FILEHANDLE
451
452 Arranges for FILEHANDLE to be read or written in "binary" or "text" mode
453 on systems where the run-time libraries distinguish between binary and
454 text files.  If FILEHANDLE is an expression, the value is taken as the
455 name of the filehandle.  DISCIPLINE can be either of C<:raw> for
456 binary mode or C<:crlf> for "text" mode.  If the DISCIPLINE is
457 omitted, it defaults to C<:raw>.  Returns true on success, C<undef> on
458 failure.  The C<:raw> are C<:clrf>, and any other directives of the
459 form C<:...>, are called I/O I<disciplines>.
460
461 The C<open> pragma can be used to establish default I/O disciplines.
462 See L<open>.
463
464 In general, binmode() should be called after open() but before any I/O
465 is done on the filehandle.  Calling binmode() will flush any possibly
466 pending buffered input or output data on the handle.  The only
467 exception to this is the C<:encoding> discipline that changes
468 the default character encoding of the handle, see L<open>.
469 The C<:encoding> discipline sometimes needs to be called in
470 mid-stream, and it doesn't flush the stream.
471
472 On some systems binmode() is necessary when you're not working with a
473 text file.  For the sake of portability it is a good idea to always use
474 it when appropriate, and to never use it when it isn't appropriate.
475
476 In other words:  Regardless of platform, use binmode() on binary
477 files, and do not use binmode() on text files.
478
479 The operating system, device drivers, C libraries, and Perl run-time
480 system all work together to let the programmer treat a single
481 character (C<\n>) as the line terminator, irrespective of the external
482 representation.  On many operating systems, the native text file
483 representation matches the internal representation, but on some
484 platforms the external representation of C<\n> is made up of more than
485 one character.
486
487 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
488 character to end each line in the external representation of text (even
489 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
490 on Unix and most VMS files).  Consequently binmode() has no effect on
491 these operating systems.  In other systems like OS/2, DOS and the various
492 flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>, but
493 what's stored in text files are the two characters C<\cM\cJ>.  That means
494 that, if you don't use binmode() on these systems, C<\cM\cJ> sequences on
495 disk will be converted to C<\n> on input, and any C<\n> in your program
496 will be converted back to C<\cM\cJ> on output.  This is what you want for
497 text files, but it can be disastrous for binary files.
498
499 Another consequence of using binmode() (on some systems) is that
500 special end-of-file markers will be seen as part of the data stream.
501 For systems from the Microsoft family this means that if your binary
502 data contains C<\cZ>, the I/O subsystem will regard it as the end of
503 the file, unless you use binmode().
504
505 binmode() is not only important for readline() and print() operations,
506 but also when using read(), seek(), sysread(), syswrite() and tell()
507 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
508 in L<perlvar> for how to manually set your input and output
509 line-termination sequences.
510
511 =item bless REF,CLASSNAME
512
513 =item bless REF
514
515 This function tells the thingy referenced by REF that it is now an object
516 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
517 is used.  Because a C<bless> is often the last thing in a constructor,
518 it returns the reference for convenience.  Always use the two-argument
519 version if the function doing the blessing might be inherited by a
520 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
521 (and blessings) of objects.
522
523 Consider always blessing objects in CLASSNAMEs that are mixed case.
524 Namespaces with all lowercase names are considered reserved for
525 Perl pragmata.  Builtin types have all uppercase names, so to prevent
526 confusion, you may wish to avoid such package names as well.  Make sure
527 that CLASSNAME is a true value.
528
529 See L<perlmod/"Perl Modules">.
530
531 =item caller EXPR
532
533 =item caller
534
535 Returns the context of the current subroutine call.  In scalar context,
536 returns the caller's package name if there is a caller, that is, if
537 we're in a subroutine or C<eval> or C<require>, and the undefined value
538 otherwise.  In list context, returns
539
540     ($package, $filename, $line) = caller;
541
542 With EXPR, it returns some extra information that the debugger uses to
543 print a stack trace.  The value of EXPR indicates how many call frames
544 to go back before the current one.
545
546     ($package, $filename, $line, $subroutine, $hasargs,
547     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
548
549 Here $subroutine may be C<(eval)> if the frame is not a subroutine
550 call, but an C<eval>.  In such a case additional elements $evaltext and
551 C<$is_require> are set: C<$is_require> is true if the frame is created by a
552 C<require> or C<use> statement, $evaltext contains the text of the
553 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
554 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
555 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
556 frame.  C<$hasargs> is true if a new instance of C<@_> was set up for the
557 frame.  C<$hints> and C<$bitmask> contain pragmatic hints that the caller
558 was compiled with.  The C<$hints> and C<$bitmask> values are subject to
559 change between versions of Perl, and are not meant for external use.
560
561 Furthermore, when called from within the DB package, caller returns more
562 detailed information: it sets the list variable C<@DB::args> to be the
563 arguments with which the subroutine was invoked.
564
565 Be aware that the optimizer might have optimized call frames away before
566 C<caller> had a chance to get the information.  That means that C<caller(N)>
567 might not return information about the call frame you expect it do, for
568 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
569 previous time C<caller> was called.
570
571 =item chdir EXPR
572
573 Changes the working directory to EXPR, if possible. If EXPR is omitted,
574 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
575 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
576 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
577 neither is set, C<chdir> does nothing. It returns true upon success,
578 false otherwise. See the example under C<die>.
579
580 =item chmod LIST
581
582 Changes the permissions of a list of files.  The first element of the
583 list must be the numerical mode, which should probably be an octal
584 number, and which definitely should I<not> a string of octal digits:
585 C<0644> is okay, C<'0644'> is not.  Returns the number of files
586 successfully changed.  See also L</oct>, if all you have is a string.
587
588     $cnt = chmod 0755, 'foo', 'bar';
589     chmod 0755, @executables;
590     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
591                                              # --w----r-T
592     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
593     $mode = 0644;   chmod $mode, 'foo';      # this is best
594
595 You can also import the symbolic C<S_I*> constants from the Fcntl
596 module:
597
598     use Fcntl ':mode';
599
600     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
601     # This is identical to the chmod 0755 of the above example.
602
603 =item chomp VARIABLE
604
605 =item chomp( LIST )
606
607 =item chomp
608
609 This safer version of L</chop> removes any trailing string
610 that corresponds to the current value of C<$/> (also known as
611 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
612 number of characters removed from all its arguments.  It's often used to
613 remove the newline from the end of an input record when you're worried
614 that the final record may be missing its newline.  When in paragraph
615 mode (C<$/ = "">), it removes all trailing newlines from the string.
616 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
617 a reference to an integer or the like, see L<perlvar>) chomp() won't
618 remove anything.
619 If VARIABLE is omitted, it chomps C<$_>.  Example:
620
621     while (<>) {
622         chomp;  # avoid \n on last field
623         @array = split(/:/);
624         # ...
625     }
626
627 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
628
629 You can actually chomp anything that's an lvalue, including an assignment:
630
631     chomp($cwd = `pwd`);
632     chomp($answer = <STDIN>);
633
634 If you chomp a list, each element is chomped, and the total number of
635 characters removed is returned.
636
637 =item chop VARIABLE
638
639 =item chop( LIST )
640
641 =item chop
642
643 Chops off the last character of a string and returns the character
644 chopped.  It is much more efficient than C<s/.$//s> because it neither
645 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
646 If VARIABLE is a hash, it chops the hash's values, but not its keys.
647
648 You can actually chop anything that's an lvalue, including an assignment.
649
650 If you chop a list, each element is chopped.  Only the value of the
651 last C<chop> is returned.
652
653 Note that C<chop> returns the last character.  To return all but the last
654 character, use C<substr($string, 0, -1)>.
655
656 =item chown LIST
657
658 Changes the owner (and group) of a list of files.  The first two
659 elements of the list must be the I<numeric> uid and gid, in that
660 order.  A value of -1 in either position is interpreted by most
661 systems to leave that value unchanged.  Returns the number of files
662 successfully changed.
663
664     $cnt = chown $uid, $gid, 'foo', 'bar';
665     chown $uid, $gid, @filenames;
666
667 Here's an example that looks up nonnumeric uids in the passwd file:
668
669     print "User: ";
670     chomp($user = <STDIN>);
671     print "Files: ";
672     chomp($pattern = <STDIN>);
673
674     ($login,$pass,$uid,$gid) = getpwnam($user)
675         or die "$user not in passwd file";
676
677     @ary = glob($pattern);      # expand filenames
678     chown $uid, $gid, @ary;
679
680 On most systems, you are not allowed to change the ownership of the
681 file unless you're the superuser, although you should be able to change
682 the group to any of your secondary groups.  On insecure systems, these
683 restrictions may be relaxed, but this is not a portable assumption.
684 On POSIX systems, you can detect this condition this way:
685
686     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
687     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
688
689 =item chr NUMBER
690
691 =item chr
692
693 Returns the character represented by that NUMBER in the character set.
694 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
695 chr(0x263a) is a Unicode smiley face.  Note that characters from 127
696 to 255 (inclusive) are by default not encoded in Unicode for backward
697 compatibility reasons (but see L<encoding>).
698
699 For the reverse, use L</ord>.
700 See L<perlunicode> and L<encoding> for more about Unicode.
701
702 If NUMBER is omitted, uses C<$_>.
703
704 =item chroot FILENAME
705
706 =item chroot
707
708 This function works like the system call by the same name: it makes the
709 named directory the new root directory for all further pathnames that
710 begin with a C</> by your process and all its children.  (It doesn't
711 change your current working directory, which is unaffected.)  For security
712 reasons, this call is restricted to the superuser.  If FILENAME is
713 omitted, does a C<chroot> to C<$_>.
714
715 =item close FILEHANDLE
716
717 =item close
718
719 Closes the file or pipe associated with the file handle, returning
720 true only if IO buffers are successfully flushed and closes the system
721 file descriptor.  Closes the currently selected filehandle if the
722 argument is omitted.
723
724 You don't have to close FILEHANDLE if you are immediately going to do
725 another C<open> on it, because C<open> will close it for you.  (See
726 C<open>.)  However, an explicit C<close> on an input file resets the line
727 counter (C<$.>), while the implicit close done by C<open> does not.
728
729 If the file handle came from a piped open C<close> will additionally
730 return false if one of the other system calls involved fails or if the
731 program exits with non-zero status.  (If the only problem was that the
732 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
733 also waits for the process executing on the pipe to complete, in case you
734 want to look at the output of the pipe afterwards, and
735 implicitly puts the exit status value of that command into C<$?>.
736
737 Prematurely closing the read end of a pipe (i.e. before the process
738 writing to it at the other end has closed it) will result in a
739 SIGPIPE being delivered to the writer.  If the other end can't
740 handle that, be sure to read all the data before closing the pipe.
741
742 Example:
743
744     open(OUTPUT, '|sort >foo')  # pipe to sort
745         or die "Can't start sort: $!";
746     #...                        # print stuff to output
747     close OUTPUT                # wait for sort to finish
748         or warn $! ? "Error closing sort pipe: $!"
749                    : "Exit status $? from sort";
750     open(INPUT, 'foo')          # get sort's results
751         or die "Can't open 'foo' for input: $!";
752
753 FILEHANDLE may be an expression whose value can be used as an indirect
754 filehandle, usually the real filehandle name.
755
756 =item closedir DIRHANDLE
757
758 Closes a directory opened by C<opendir> and returns the success of that
759 system call.
760
761 DIRHANDLE may be an expression whose value can be used as an indirect
762 dirhandle, usually the real dirhandle name.
763
764 =item connect SOCKET,NAME
765
766 Attempts to connect to a remote socket, just as the connect system call
767 does.  Returns true if it succeeded, false otherwise.  NAME should be a
768 packed address of the appropriate type for the socket.  See the examples in
769 L<perlipc/"Sockets: Client/Server Communication">.
770
771 =item continue BLOCK
772
773 Actually a flow control statement rather than a function.  If there is a
774 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
775 C<foreach>), it is always executed just before the conditional is about to
776 be evaluated again, just like the third part of a C<for> loop in C.  Thus
777 it can be used to increment a loop variable, even when the loop has been
778 continued via the C<next> statement (which is similar to the C C<continue>
779 statement).
780
781 C<last>, C<next>, or C<redo> may appear within a C<continue>
782 block.  C<last> and C<redo> will behave as if they had been executed within
783 the main block.  So will C<next>, but since it will execute a C<continue>
784 block, it may be more entertaining.
785
786     while (EXPR) {
787         ### redo always comes here
788         do_something;
789     } continue {
790         ### next always comes here
791         do_something_else;
792         # then back the top to re-check EXPR
793     }
794     ### last always comes here
795
796 Omitting the C<continue> section is semantically equivalent to using an
797 empty one, logically enough.  In that case, C<next> goes directly back
798 to check the condition at the top of the loop.
799
800 =item cos EXPR
801
802 =item cos
803
804 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
805 takes cosine of C<$_>.
806
807 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
808 function, or use this relation:
809
810     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
811
812 =item crypt PLAINTEXT,SALT
813
814 Encrypts a string exactly like the crypt(3) function in the C library
815 (assuming that you actually have a version there that has not been
816 extirpated as a potential munition).  This can prove useful for checking
817 the password file for lousy passwords, amongst other things.  Only the
818 guys wearing white hats should do this.
819
820 Note that C<crypt> is intended to be a one-way function, much like
821 breaking eggs to make an omelette.  There is no (known) corresponding
822 decrypt function (in other words, the crypt() is a one-way hash
823 function).  As a result, this function isn't all that useful for
824 cryptography.  (For that, see your nearby CPAN mirror.)
825
826 When verifying an existing encrypted string you should use the
827 encrypted text as the salt (like C<crypt($plain, $crypted) eq
828 $crypted>).  This allows your code to work with the standard C<crypt>
829 and with more exotic implementations.  In other words, do not assume
830 anything about the returned string itself, or how many bytes in
831 the encrypted string matter.
832
833 Traditionally the result is a string of 13 bytes: two first bytes of
834 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
835 the first eight bytes of the encrypted string mattered, but
836 alternative hashing schemes (like MD5), higher level security schemes
837 (like C2), and implementations on non-UNIX platforms may produce
838 different strings.
839
840 When choosing a new salt create a random two character string whose
841 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
842 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
843
844 Here's an example that makes sure that whoever runs this program knows
845 their own password:
846
847     $pwd = (getpwuid($<))[1];
848
849     system "stty -echo";
850     print "Password: ";
851     chomp($word = <STDIN>);
852     print "\n";
853     system "stty echo";
854
855     if (crypt($word, $pwd) ne $pwd) {
856         die "Sorry...\n";
857     } else {
858         print "ok\n";
859     }
860
861 Of course, typing in your own password to whoever asks you
862 for it is unwise.
863
864 The L<crypt> function is unsuitable for encrypting large quantities
865 of data, not least of all because you can't get the information
866 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
867 on your favorite CPAN mirror for a slew of potentially useful
868 modules.
869
870 If using crypt() on a Unicode string (which I<potentially> has
871 characters with codepoints above 255), Perl tries to make sense
872 of the situation by trying to downgrade (a copy of the string)
873 the string back to an eight-bit byte string before calling crypt()
874 (on that copy).  If that works, good.  If not, crypt() dies with
875 C<Wide character in crypt>.
876
877 =item dbmclose HASH
878
879 [This function has been largely superseded by the C<untie> function.]
880
881 Breaks the binding between a DBM file and a hash.
882
883 =item dbmopen HASH,DBNAME,MASK
884
885 [This function has been largely superseded by the C<tie> function.]
886
887 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
888 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
889 argument is I<not> a filehandle, even though it looks like one).  DBNAME
890 is the name of the database (without the F<.dir> or F<.pag> extension if
891 any).  If the database does not exist, it is created with protection
892 specified by MASK (as modified by the C<umask>).  If your system supports
893 only the older DBM functions, you may perform only one C<dbmopen> in your
894 program.  In older versions of Perl, if your system had neither DBM nor
895 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
896 sdbm(3).
897
898 If you don't have write access to the DBM file, you can only read hash
899 variables, not set them.  If you want to test whether you can write,
900 either use file tests or try setting a dummy hash entry inside an C<eval>,
901 which will trap the error.
902
903 Note that functions such as C<keys> and C<values> may return huge lists
904 when used on large DBM files.  You may prefer to use the C<each>
905 function to iterate over large DBM files.  Example:
906
907     # print out history file offsets
908     dbmopen(%HIST,'/usr/lib/news/history',0666);
909     while (($key,$val) = each %HIST) {
910         print $key, ' = ', unpack('L',$val), "\n";
911     }
912     dbmclose(%HIST);
913
914 See also L<AnyDBM_File> for a more general description of the pros and
915 cons of the various dbm approaches, as well as L<DB_File> for a particularly
916 rich implementation.
917
918 You can control which DBM library you use by loading that library
919 before you call dbmopen():
920
921     use DB_File;
922     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
923         or die "Can't open netscape history file: $!";
924
925 =item defined EXPR
926
927 =item defined
928
929 Returns a Boolean value telling whether EXPR has a value other than
930 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
931 checked.
932
933 Many operations return C<undef> to indicate failure, end of file,
934 system error, uninitialized variable, and other exceptional
935 conditions.  This function allows you to distinguish C<undef> from
936 other values.  (A simple Boolean test will not distinguish among
937 C<undef>, zero, the empty string, and C<"0">, which are all equally
938 false.)  Note that since C<undef> is a valid scalar, its presence
939 doesn't I<necessarily> indicate an exceptional condition: C<pop>
940 returns C<undef> when its argument is an empty array, I<or> when the
941 element to return happens to be C<undef>.
942
943 You may also use C<defined(&func)> to check whether subroutine C<&func>
944 has ever been defined.  The return value is unaffected by any forward
945 declarations of C<&foo>.  Note that a subroutine which is not defined
946 may still be callable: its package may have an C<AUTOLOAD> method that
947 makes it spring into existence the first time that it is called -- see
948 L<perlsub>.
949
950 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
951 used to report whether memory for that aggregate has ever been
952 allocated.  This behavior may disappear in future versions of Perl.
953 You should instead use a simple test for size:
954
955     if (@an_array) { print "has array elements\n" }
956     if (%a_hash)   { print "has hash members\n"   }
957
958 When used on a hash element, it tells you whether the value is defined,
959 not whether the key exists in the hash.  Use L</exists> for the latter
960 purpose.
961
962 Examples:
963
964     print if defined $switch{'D'};
965     print "$val\n" while defined($val = pop(@ary));
966     die "Can't readlink $sym: $!"
967         unless defined($value = readlink $sym);
968     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
969     $debugging = 0 unless defined $debugging;
970
971 Note:  Many folks tend to overuse C<defined>, and then are surprised to
972 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
973 defined values.  For example, if you say
974
975     "ab" =~ /a(.*)b/;
976
977 The pattern match succeeds, and C<$1> is defined, despite the fact that it
978 matched "nothing".  But it didn't really match nothing--rather, it
979 matched something that happened to be zero characters long.  This is all
980 very above-board and honest.  When a function returns an undefined value,
981 it's an admission that it couldn't give you an honest answer.  So you
982 should use C<defined> only when you're questioning the integrity of what
983 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
984 what you want.
985
986 See also L</undef>, L</exists>, L</ref>.
987
988 =item delete EXPR
989
990 Given an expression that specifies a hash element, array element, hash slice,
991 or array slice, deletes the specified element(s) from the hash or array.
992 In the case of an array, if the array elements happen to be at the end,
993 the size of the array will shrink to the highest element that tests
994 true for exists() (or 0 if no such element exists).
995
996 Returns each element so deleted or the undefined value if there was no such
997 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
998 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
999 from a C<tie>d hash or array may not necessarily return anything.
1000
1001 Deleting an array element effectively returns that position of the array
1002 to its initial, uninitialized state.  Subsequently testing for the same
1003 element with exists() will return false.  Note that deleting array
1004 elements in the middle of an array will not shift the index of the ones
1005 after them down--use splice() for that.  See L</exists>.
1006
1007 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1008
1009     foreach $key (keys %HASH) {
1010         delete $HASH{$key};
1011     }
1012
1013     foreach $index (0 .. $#ARRAY) {
1014         delete $ARRAY[$index];
1015     }
1016
1017 And so do these:
1018
1019     delete @HASH{keys %HASH};
1020
1021     delete @ARRAY[0 .. $#ARRAY];
1022
1023 But both of these are slower than just assigning the empty list
1024 or undefining %HASH or @ARRAY:
1025
1026     %HASH = ();         # completely empty %HASH
1027     undef %HASH;        # forget %HASH ever existed
1028
1029     @ARRAY = ();        # completely empty @ARRAY
1030     undef @ARRAY;       # forget @ARRAY ever existed
1031
1032 Note that the EXPR can be arbitrarily complicated as long as the final
1033 operation is a hash element, array element,  hash slice, or array slice
1034 lookup:
1035
1036     delete $ref->[$x][$y]{$key};
1037     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1038
1039     delete $ref->[$x][$y][$index];
1040     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1041
1042 =item die LIST
1043
1044 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1045 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1046 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1047 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1048 an C<eval(),> the error message is stuffed into C<$@> and the
1049 C<eval> is terminated with the undefined value.  This makes
1050 C<die> the way to raise an exception.
1051
1052 Equivalent examples:
1053
1054     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1055     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1056
1057 If the value of EXPR does not end in a newline, the current script line
1058 number and input line number (if any) are also printed, and a newline
1059 is supplied.  Note that the "input line number" (also known as "chunk")
1060 is subject to whatever notion of "line" happens to be currently in
1061 effect, and is also available as the special variable C<$.>.
1062 See L<perlvar/"$/"> and L<perlvar/"$.">.
1063
1064 Hint: sometimes appending C<", stopped"> to your message
1065 will cause it to make better sense when the string C<"at foo line 123"> is
1066 appended.  Suppose you are running script "canasta".
1067
1068     die "/etc/games is no good";
1069     die "/etc/games is no good, stopped";
1070
1071 produce, respectively
1072
1073     /etc/games is no good at canasta line 123.
1074     /etc/games is no good, stopped at canasta line 123.
1075
1076 See also exit(), warn(), and the Carp module.
1077
1078 If LIST is empty and C<$@> already contains a value (typically from a
1079 previous eval) that value is reused after appending C<"\t...propagated">.
1080 This is useful for propagating exceptions:
1081
1082     eval { ... };
1083     die unless $@ =~ /Expected exception/;
1084
1085 If LIST is empty and C<$@> contains an object reference that has a
1086 C<PROPAGATE> method, that method will be called with additional file
1087 and line number parameters.  The return value replaces the value in
1088 C<$@>.  ie. as if C<<$@ = eval { $@->PROPAGATE(__FILE__, __LINE__) };>> 
1089 were called.
1090
1091 If C<$@> is empty then the string C<"Died"> is used.
1092
1093 die() can also be called with a reference argument.  If this happens to be
1094 trapped within an eval(), $@ contains the reference.  This behavior permits
1095 a more elaborate exception handling implementation using objects that
1096 maintain arbitrary state about the nature of the exception.  Such a scheme
1097 is sometimes preferable to matching particular string values of $@ using
1098 regular expressions.  Here's an example:
1099
1100     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1101     if ($@) {
1102         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1103             # handle Some::Module::Exception
1104         }
1105         else {
1106             # handle all other possible exceptions
1107         }
1108     }
1109
1110 Because perl will stringify uncaught exception messages before displaying
1111 them, you may want to overload stringification operations on such custom
1112 exception objects.  See L<overload> for details about that.
1113
1114 You can arrange for a callback to be run just before the C<die>
1115 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1116 handler will be called with the error text and can change the error
1117 message, if it sees fit, by calling C<die> again.  See
1118 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1119 L<"eval BLOCK"> for some examples.  Although this feature was meant
1120 to be run only right before your program was to exit, this is not
1121 currently the case--the C<$SIG{__DIE__}> hook is currently called
1122 even inside eval()ed blocks/strings!  If one wants the hook to do
1123 nothing in such situations, put
1124
1125         die @_ if $^S;
1126
1127 as the first line of the handler (see L<perlvar/$^S>).  Because
1128 this promotes strange action at a distance, this counterintuitive
1129 behavior may be fixed in a future release.
1130
1131 =item do BLOCK
1132
1133 Not really a function.  Returns the value of the last command in the
1134 sequence of commands indicated by BLOCK.  When modified by a loop
1135 modifier, executes the BLOCK once before testing the loop condition.
1136 (On other statements the loop modifiers test the conditional first.)
1137
1138 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1139 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1140 See L<perlsyn> for alternative strategies.
1141
1142 =item do SUBROUTINE(LIST)
1143
1144 A deprecated form of subroutine call.  See L<perlsub>.
1145
1146 =item do EXPR
1147
1148 Uses the value of EXPR as a filename and executes the contents of the
1149 file as a Perl script.  Its primary use is to include subroutines
1150 from a Perl subroutine library.
1151
1152     do 'stat.pl';
1153
1154 is just like
1155
1156     eval `cat stat.pl`;
1157
1158 except that it's more efficient and concise, keeps track of the current
1159 filename for error messages, searches the @INC libraries, and updates
1160 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1161 variables.  It also differs in that code evaluated with C<do FILENAME>
1162 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1163 same, however, in that it does reparse the file every time you call it,
1164 so you probably don't want to do this inside a loop.
1165
1166 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1167 error.  If C<do> can read the file but cannot compile it, it
1168 returns undef and sets an error message in C<$@>.   If the file is
1169 successfully compiled, C<do> returns the value of the last expression
1170 evaluated.
1171
1172 Note that inclusion of library modules is better done with the
1173 C<use> and C<require> operators, which also do automatic error checking
1174 and raise an exception if there's a problem.
1175
1176 You might like to use C<do> to read in a program configuration
1177 file.  Manual error checking can be done this way:
1178
1179     # read in config files: system first, then user
1180     for $file ("/share/prog/defaults.rc",
1181                "$ENV{HOME}/.someprogrc")
1182    {
1183         unless ($return = do $file) {
1184             warn "couldn't parse $file: $@" if $@;
1185             warn "couldn't do $file: $!"    unless defined $return;
1186             warn "couldn't run $file"       unless $return;
1187         }
1188     }
1189
1190 =item dump LABEL
1191
1192 =item dump
1193
1194 This function causes an immediate core dump.  See also the B<-u>
1195 command-line switch in L<perlrun>, which does the same thing.
1196 Primarily this is so that you can use the B<undump> program (not
1197 supplied) to turn your core dump into an executable binary after
1198 having initialized all your variables at the beginning of the
1199 program.  When the new binary is executed it will begin by executing
1200 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1201 Think of it as a goto with an intervening core dump and reincarnation.
1202 If C<LABEL> is omitted, restarts the program from the top.
1203
1204 B<WARNING>: Any files opened at the time of the dump will I<not>
1205 be open any more when the program is reincarnated, with possible
1206 resulting confusion on the part of Perl.
1207
1208 This function is now largely obsolete, partly because it's very
1209 hard to convert a core file into an executable, and because the
1210 real compiler backends for generating portable bytecode and compilable
1211 C code have superseded it.  That's why you should now invoke it as
1212 C<CORE::dump()>, if you don't want to be warned against a possible
1213 typo.
1214
1215 If you're looking to use L<dump> to speed up your program, consider
1216 generating bytecode or native C code as described in L<perlcc>.  If
1217 you're just trying to accelerate a CGI script, consider using the
1218 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1219 You might also consider autoloading or selfloading, which at least
1220 make your program I<appear> to run faster.
1221
1222 =item each HASH
1223
1224 When called in list context, returns a 2-element list consisting of the
1225 key and value for the next element of a hash, so that you can iterate over
1226 it.  When called in scalar context, returns only the key for the next
1227 element in the hash.
1228
1229 Entries are returned in an apparently random order.  The actual random
1230 order is subject to change in future versions of perl, but it is guaranteed
1231 to be in the same order as either the C<keys> or C<values> function
1232 would produce on the same (unmodified) hash.
1233
1234 When the hash is entirely read, a null array is returned in list context
1235 (which when assigned produces a false (C<0>) value), and C<undef> in
1236 scalar context.  The next call to C<each> after that will start iterating
1237 again.  There is a single iterator for each hash, shared by all C<each>,
1238 C<keys>, and C<values> function calls in the program; it can be reset by
1239 reading all the elements from the hash, or by evaluating C<keys HASH> or
1240 C<values HASH>.  If you add or delete elements of a hash while you're
1241 iterating over it, you may get entries skipped or duplicated, so
1242 don't.  Exception: It is always safe to delete the item most recently
1243 returned by C<each()>, which means that the following code will work:
1244
1245         while (($key, $value) = each %hash) {
1246           print $key, "\n";
1247           delete $hash{$key};   # This is safe
1248         }
1249
1250 The following prints out your environment like the printenv(1) program,
1251 only in a different order:
1252
1253     while (($key,$value) = each %ENV) {
1254         print "$key=$value\n";
1255     }
1256
1257 See also C<keys>, C<values> and C<sort>.
1258
1259 =item eof FILEHANDLE
1260
1261 =item eof ()
1262
1263 =item eof
1264
1265 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1266 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1267 gives the real filehandle.  (Note that this function actually
1268 reads a character and then C<ungetc>s it, so isn't very useful in an
1269 interactive context.)  Do not read from a terminal file (or call
1270 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1271 as terminals may lose the end-of-file condition if you do.
1272
1273 An C<eof> without an argument uses the last file read.  Using C<eof()>
1274 with empty parentheses is very different.  It refers to the pseudo file
1275 formed from the files listed on the command line and accessed via the
1276 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1277 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1278 used will cause C<@ARGV> to be examined to determine if input is
1279 available.
1280
1281 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1282 detect the end of each file, C<eof()> will only detect the end of the
1283 last file.  Examples:
1284
1285     # reset line numbering on each input file
1286     while (<>) {
1287         next if /^\s*#/;        # skip comments
1288         print "$.\t$_";
1289     } continue {
1290         close ARGV  if eof;     # Not eof()!
1291     }
1292
1293     # insert dashes just before last line of last file
1294     while (<>) {
1295         if (eof()) {            # check for end of current file
1296             print "--------------\n";
1297             close(ARGV);        # close or last; is needed if we
1298                                 # are reading from the terminal
1299         }
1300         print;
1301     }
1302
1303 Practical hint: you almost never need to use C<eof> in Perl, because the
1304 input operators typically return C<undef> when they run out of data, or if
1305 there was an error.
1306
1307 =item eval EXPR
1308
1309 =item eval BLOCK
1310
1311 In the first form, the return value of EXPR is parsed and executed as if it
1312 were a little Perl program.  The value of the expression (which is itself
1313 determined within scalar context) is first parsed, and if there weren't any
1314 errors, executed in the lexical context of the current Perl program, so
1315 that any variable settings or subroutine and format definitions remain
1316 afterwards.  Note that the value is parsed every time the eval executes.
1317 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1318 delay parsing and subsequent execution of the text of EXPR until run time.
1319
1320 In the second form, the code within the BLOCK is parsed only once--at the
1321 same time the code surrounding the eval itself was parsed--and executed
1322 within the context of the current Perl program.  This form is typically
1323 used to trap exceptions more efficiently than the first (see below), while
1324 also providing the benefit of checking the code within BLOCK at compile
1325 time.
1326
1327 The final semicolon, if any, may be omitted from the value of EXPR or within
1328 the BLOCK.
1329
1330 In both forms, the value returned is the value of the last expression
1331 evaluated inside the mini-program; a return statement may be also used, just
1332 as with subroutines.  The expression providing the return value is evaluated
1333 in void, scalar, or list context, depending on the context of the eval itself.
1334 See L</wantarray> for more on how the evaluation context can be determined.
1335
1336 If there is a syntax error or runtime error, or a C<die> statement is
1337 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1338 error message.  If there was no error, C<$@> is guaranteed to be a null
1339 string.  Beware that using C<eval> neither silences perl from printing
1340 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1341 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1342 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1343 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1344
1345 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1346 determining whether a particular feature (such as C<socket> or C<symlink>)
1347 is implemented.  It is also Perl's exception trapping mechanism, where
1348 the die operator is used to raise exceptions.
1349
1350 If the code to be executed doesn't vary, you may use the eval-BLOCK
1351 form to trap run-time errors without incurring the penalty of
1352 recompiling each time.  The error, if any, is still returned in C<$@>.
1353 Examples:
1354
1355     # make divide-by-zero nonfatal
1356     eval { $answer = $a / $b; }; warn $@ if $@;
1357
1358     # same thing, but less efficient
1359     eval '$answer = $a / $b'; warn $@ if $@;
1360
1361     # a compile-time error
1362     eval { $answer = };                 # WRONG
1363
1364     # a run-time error
1365     eval '$answer =';   # sets $@
1366
1367 Due to the current arguably broken state of C<__DIE__> hooks, when using
1368 the C<eval{}> form as an exception trap in libraries, you may wish not
1369 to trigger any C<__DIE__> hooks that user code may have installed.
1370 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1371 as shown in this example:
1372
1373     # a very private exception trap for divide-by-zero
1374     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1375     warn $@ if $@;
1376
1377 This is especially significant, given that C<__DIE__> hooks can call
1378 C<die> again, which has the effect of changing their error messages:
1379
1380     # __DIE__ hooks may modify error messages
1381     {
1382        local $SIG{'__DIE__'} =
1383               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1384        eval { die "foo lives here" };
1385        print $@ if $@;                # prints "bar lives here"
1386     }
1387
1388 Because this promotes action at a distance, this counterintuitive behavior
1389 may be fixed in a future release.
1390
1391 With an C<eval>, you should be especially careful to remember what's
1392 being looked at when:
1393
1394     eval $x;            # CASE 1
1395     eval "$x";          # CASE 2
1396
1397     eval '$x';          # CASE 3
1398     eval { $x };        # CASE 4
1399
1400     eval "\$$x++";      # CASE 5
1401     $$x++;              # CASE 6
1402
1403 Cases 1 and 2 above behave identically: they run the code contained in
1404 the variable $x.  (Although case 2 has misleading double quotes making
1405 the reader wonder what else might be happening (nothing is).)  Cases 3
1406 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1407 does nothing but return the value of $x.  (Case 4 is preferred for
1408 purely visual reasons, but it also has the advantage of compiling at
1409 compile-time instead of at run-time.)  Case 5 is a place where
1410 normally you I<would> like to use double quotes, except that in this
1411 particular situation, you can just use symbolic references instead, as
1412 in case 6.
1413
1414 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1415 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1416
1417 =item exec LIST
1418
1419 =item exec PROGRAM LIST
1420
1421 The C<exec> function executes a system command I<and never returns>--
1422 use C<system> instead of C<exec> if you want it to return.  It fails and
1423 returns false only if the command does not exist I<and> it is executed
1424 directly instead of via your system's command shell (see below).
1425
1426 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1427 warns you if there is a following statement which isn't C<die>, C<warn>,
1428 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1429 I<really> want to follow an C<exec> with some other statement, you
1430 can use one of these styles to avoid the warning:
1431
1432     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1433     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1434
1435 If there is more than one argument in LIST, or if LIST is an array
1436 with more than one value, calls execvp(3) with the arguments in LIST.
1437 If there is only one scalar argument or an array with one element in it,
1438 the argument is checked for shell metacharacters, and if there are any,
1439 the entire argument is passed to the system's command shell for parsing
1440 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1441 If there are no shell metacharacters in the argument, it is split into
1442 words and passed directly to C<execvp>, which is more efficient.
1443 Examples:
1444
1445     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1446     exec "sort $outfile | uniq";
1447
1448 If you don't really want to execute the first argument, but want to lie
1449 to the program you are executing about its own name, you can specify
1450 the program you actually want to run as an "indirect object" (without a
1451 comma) in front of the LIST.  (This always forces interpretation of the
1452 LIST as a multivalued list, even if there is only a single scalar in
1453 the list.)  Example:
1454
1455     $shell = '/bin/csh';
1456     exec $shell '-sh';          # pretend it's a login shell
1457
1458 or, more directly,
1459
1460     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1461
1462 When the arguments get executed via the system shell, results will
1463 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1464 for details.
1465
1466 Using an indirect object with C<exec> or C<system> is also more
1467 secure.  This usage (which also works fine with system()) forces
1468 interpretation of the arguments as a multivalued list, even if the
1469 list had just one argument.  That way you're safe from the shell
1470 expanding wildcards or splitting up words with whitespace in them.
1471
1472     @args = ( "echo surprise" );
1473
1474     exec @args;               # subject to shell escapes
1475                                 # if @args == 1
1476     exec { $args[0] } @args;  # safe even with one-arg list
1477
1478 The first version, the one without the indirect object, ran the I<echo>
1479 program, passing it C<"surprise"> an argument.  The second version
1480 didn't--it tried to run a program literally called I<"echo surprise">,
1481 didn't find it, and set C<$?> to a non-zero value indicating failure.
1482
1483 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1484 output before the exec, but this may not be supported on some platforms
1485 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1486 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1487 open handles in order to avoid lost output.
1488
1489 Note that C<exec> will not call your C<END> blocks, nor will it call
1490 any C<DESTROY> methods in your objects.
1491
1492 =item exists EXPR
1493
1494 Given an expression that specifies a hash element or array element,
1495 returns true if the specified element in the hash or array has ever
1496 been initialized, even if the corresponding value is undefined.  The
1497 element is not autovivified if it doesn't exist.
1498
1499     print "Exists\n"    if exists $hash{$key};
1500     print "Defined\n"   if defined $hash{$key};
1501     print "True\n"      if $hash{$key};
1502
1503     print "Exists\n"    if exists $array[$index];
1504     print "Defined\n"   if defined $array[$index];
1505     print "True\n"      if $array[$index];
1506
1507 A hash or array element can be true only if it's defined, and defined if
1508 it exists, but the reverse doesn't necessarily hold true.
1509
1510 Given an expression that specifies the name of a subroutine,
1511 returns true if the specified subroutine has ever been declared, even
1512 if it is undefined.  Mentioning a subroutine name for exists or defined
1513 does not count as declaring it.  Note that a subroutine which does not
1514 exist may still be callable: its package may have an C<AUTOLOAD>
1515 method that makes it spring into existence the first time that it is
1516 called -- see L<perlsub>.
1517
1518     print "Exists\n"    if exists &subroutine;
1519     print "Defined\n"   if defined &subroutine;
1520
1521 Note that the EXPR can be arbitrarily complicated as long as the final
1522 operation is a hash or array key lookup or subroutine name:
1523
1524     if (exists $ref->{A}->{B}->{$key})  { }
1525     if (exists $hash{A}{B}{$key})       { }
1526
1527     if (exists $ref->{A}->{B}->[$ix])   { }
1528     if (exists $hash{A}{B}[$ix])        { }
1529
1530     if (exists &{$ref->{A}{B}{$key}})   { }
1531
1532 Although the deepest nested array or hash will not spring into existence
1533 just because its existence was tested, any intervening ones will.
1534 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1535 into existence due to the existence test for the $key element above.
1536 This happens anywhere the arrow operator is used, including even:
1537
1538     undef $ref;
1539     if (exists $ref->{"Some key"})      { }
1540     print $ref;             # prints HASH(0x80d3d5c)
1541
1542 This surprising autovivification in what does not at first--or even
1543 second--glance appear to be an lvalue context may be fixed in a future
1544 release.
1545
1546 See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
1547 on how exists() acts when used on a pseudo-hash.
1548
1549 Use of a subroutine call, rather than a subroutine name, as an argument
1550 to exists() is an error.
1551
1552     exists &sub;        # OK
1553     exists &sub();      # Error
1554
1555 =item exit EXPR
1556
1557 Evaluates EXPR and exits immediately with that value.    Example:
1558
1559     $ans = <STDIN>;
1560     exit 0 if $ans =~ /^[Xx]/;
1561
1562 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1563 universally recognized values for EXPR are C<0> for success and C<1>
1564 for error; other values are subject to interpretation depending on the
1565 environment in which the Perl program is running.  For example, exiting
1566 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1567 the mailer to return the item undelivered, but that's not true everywhere.
1568
1569 Don't use C<exit> to abort a subroutine if there's any chance that
1570 someone might want to trap whatever error happened.  Use C<die> instead,
1571 which can be trapped by an C<eval>.
1572
1573 The exit() function does not always exit immediately.  It calls any
1574 defined C<END> routines first, but these C<END> routines may not
1575 themselves abort the exit.  Likewise any object destructors that need to
1576 be called are called before the real exit.  If this is a problem, you
1577 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1578 See L<perlmod> for details.
1579
1580 =item exp EXPR
1581
1582 =item exp
1583
1584 Returns I<e> (the natural logarithm base) to the power of EXPR.
1585 If EXPR is omitted, gives C<exp($_)>.
1586
1587 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1588
1589 Implements the fcntl(2) function.  You'll probably have to say
1590
1591     use Fcntl;
1592
1593 first to get the correct constant definitions.  Argument processing and
1594 value return works just like C<ioctl> below.
1595 For example:
1596
1597     use Fcntl;
1598     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1599         or die "can't fcntl F_GETFL: $!";
1600
1601 You don't have to check for C<defined> on the return from C<fnctl>.
1602 Like C<ioctl>, it maps a C<0> return from the system call into
1603 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1604 in numeric context.  It is also exempt from the normal B<-w> warnings
1605 on improper numeric conversions.
1606
1607 Note that C<fcntl> will produce a fatal error if used on a machine that
1608 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1609 manpage to learn what functions are available on your system.
1610
1611 =item fileno FILEHANDLE
1612
1613 Returns the file descriptor for a filehandle, or undefined if the
1614 filehandle is not open.  This is mainly useful for constructing
1615 bitmaps for C<select> and low-level POSIX tty-handling operations.
1616 If FILEHANDLE is an expression, the value is taken as an indirect
1617 filehandle, generally its name.
1618
1619 You can use this to find out whether two handles refer to the
1620 same underlying descriptor:
1621
1622     if (fileno(THIS) == fileno(THAT)) {
1623         print "THIS and THAT are dups\n";
1624     }
1625
1626 (Filehandles connected to memory objects via new features of C<open> may
1627 return undefined even though they are open.)
1628
1629
1630 =item flock FILEHANDLE,OPERATION
1631
1632 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1633 for success, false on failure.  Produces a fatal error if used on a
1634 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1635 C<flock> is Perl's portable file locking interface, although it locks
1636 only entire files, not records.
1637
1638 Two potentially non-obvious but traditional C<flock> semantics are
1639 that it waits indefinitely until the lock is granted, and that its locks
1640 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1641 fewer guarantees.  This means that files locked with C<flock> may be
1642 modified by programs that do not also use C<flock>.  See L<perlport>,
1643 your port's specific documentation, or your system-specific local manpages
1644 for details.  It's best to assume traditional behavior if you're writing
1645 portable programs.  (But if you're not, you should as always feel perfectly
1646 free to write for your own system's idiosyncrasies (sometimes called
1647 "features").  Slavish adherence to portability concerns shouldn't get
1648 in the way of your getting your job done.)
1649
1650 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1651 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1652 you can use the symbolic names if you import them from the Fcntl module,
1653 either individually, or as a group using the ':flock' tag.  LOCK_SH
1654 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1655 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1656 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1657 waiting for the lock (check the return status to see if you got it).
1658
1659 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1660 before locking or unlocking it.
1661
1662 Note that the emulation built with lockf(3) doesn't provide shared
1663 locks, and it requires that FILEHANDLE be open with write intent.  These
1664 are the semantics that lockf(3) implements.  Most if not all systems
1665 implement lockf(3) in terms of fcntl(2) locking, though, so the
1666 differing semantics shouldn't bite too many people.
1667
1668 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1669 be open with read intent to use LOCK_SH and requires that it be open
1670 with write intent to use LOCK_EX.
1671
1672 Note also that some versions of C<flock> cannot lock things over the
1673 network; you would need to use the more system-specific C<fcntl> for
1674 that.  If you like you can force Perl to ignore your system's flock(2)
1675 function, and so provide its own fcntl(2)-based emulation, by passing
1676 the switch C<-Ud_flock> to the F<Configure> program when you configure
1677 perl.
1678
1679 Here's a mailbox appender for BSD systems.
1680
1681     use Fcntl ':flock'; # import LOCK_* constants
1682
1683     sub lock {
1684         flock(MBOX,LOCK_EX);
1685         # and, in case someone appended
1686         # while we were waiting...
1687         seek(MBOX, 0, 2);
1688     }
1689
1690     sub unlock {
1691         flock(MBOX,LOCK_UN);
1692     }
1693
1694     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1695             or die "Can't open mailbox: $!";
1696
1697     lock();
1698     print MBOX $msg,"\n\n";
1699     unlock();
1700
1701 On systems that support a real flock(), locks are inherited across fork()
1702 calls, whereas those that must resort to the more capricious fcntl()
1703 function lose the locks, making it harder to write servers.
1704
1705 See also L<DB_File> for other flock() examples.
1706
1707 =item fork
1708
1709 Does a fork(2) system call to create a new process running the
1710 same program at the same point.  It returns the child pid to the
1711 parent process, C<0> to the child process, or C<undef> if the fork is
1712 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1713 are shared, while everything else is copied.  On most systems supporting
1714 fork(), great care has gone into making it extremely efficient (for
1715 example, using copy-on-write technology on data pages), making it the
1716 dominant paradigm for multitasking over the last few decades.
1717
1718 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1719 output before forking the child process, but this may not be supported
1720 on some platforms (see L<perlport>).  To be safe, you may need to set
1721 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1722 C<IO::Handle> on any open handles in order to avoid duplicate output.
1723
1724 If you C<fork> without ever waiting on your children, you will
1725 accumulate zombies.  On some systems, you can avoid this by setting
1726 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1727 forking and reaping moribund children.
1728
1729 Note that if your forked child inherits system file descriptors like
1730 STDIN and STDOUT that are actually connected by a pipe or socket, even
1731 if you exit, then the remote server (such as, say, a CGI script or a
1732 backgrounded job launched from a remote shell) won't think you're done.
1733 You should reopen those to F</dev/null> if it's any issue.
1734
1735 =item format
1736
1737 Declare a picture format for use by the C<write> function.  For
1738 example:
1739
1740     format Something =
1741         Test: @<<<<<<<< @||||| @>>>>>
1742               $str,     $%,    '$' . int($num)
1743     .
1744
1745     $str = "widget";
1746     $num = $cost/$quantity;
1747     $~ = 'Something';
1748     write;
1749
1750 See L<perlform> for many details and examples.
1751
1752 =item formline PICTURE,LIST
1753
1754 This is an internal function used by C<format>s, though you may call it,
1755 too.  It formats (see L<perlform>) a list of values according to the
1756 contents of PICTURE, placing the output into the format output
1757 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1758 Eventually, when a C<write> is done, the contents of
1759 C<$^A> are written to some filehandle, but you could also read C<$^A>
1760 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1761 does one C<formline> per line of form, but the C<formline> function itself
1762 doesn't care how many newlines are embedded in the PICTURE.  This means
1763 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1764 You may therefore need to use multiple formlines to implement a single
1765 record format, just like the format compiler.
1766
1767 Be careful if you put double quotes around the picture, because an C<@>
1768 character may be taken to mean the beginning of an array name.
1769 C<formline> always returns true.  See L<perlform> for other examples.
1770
1771 =item getc FILEHANDLE
1772
1773 =item getc
1774
1775 Returns the next character from the input file attached to FILEHANDLE,
1776 or the undefined value at end of file, or if there was an error.
1777 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1778 efficient.  However, it cannot be used by itself to fetch single
1779 characters without waiting for the user to hit enter.  For that, try
1780 something more like:
1781
1782     if ($BSD_STYLE) {
1783         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1784     }
1785     else {
1786         system "stty", '-icanon', 'eol', "\001";
1787     }
1788
1789     $key = getc(STDIN);
1790
1791     if ($BSD_STYLE) {
1792         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1793     }
1794     else {
1795         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1796     }
1797     print "\n";
1798
1799 Determination of whether $BSD_STYLE should be set
1800 is left as an exercise to the reader.
1801
1802 The C<POSIX::getattr> function can do this more portably on
1803 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1804 module from your nearest CPAN site; details on CPAN can be found on
1805 L<perlmodlib/CPAN>.
1806
1807 =item getlogin
1808
1809 Implements the C library function of the same name, which on most
1810 systems returns the current login from F</etc/utmp>, if any.  If null,
1811 use C<getpwuid>.
1812
1813     $login = getlogin || getpwuid($<) || "Kilroy";
1814
1815 Do not consider C<getlogin> for authentication: it is not as
1816 secure as C<getpwuid>.
1817
1818 =item getpeername SOCKET
1819
1820 Returns the packed sockaddr address of other end of the SOCKET connection.
1821
1822     use Socket;
1823     $hersockaddr    = getpeername(SOCK);
1824     ($port, $iaddr) = sockaddr_in($hersockaddr);
1825     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1826     $herstraddr     = inet_ntoa($iaddr);
1827
1828 =item getpgrp PID
1829
1830 Returns the current process group for the specified PID.  Use
1831 a PID of C<0> to get the current process group for the
1832 current process.  Will raise an exception if used on a machine that
1833 doesn't implement getpgrp(2).  If PID is omitted, returns process
1834 group of current process.  Note that the POSIX version of C<getpgrp>
1835 does not accept a PID argument, so only C<PID==0> is truly portable.
1836
1837 =item getppid
1838
1839 Returns the process id of the parent process.
1840
1841 =item getpriority WHICH,WHO
1842
1843 Returns the current priority for a process, a process group, or a user.
1844 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1845 machine that doesn't implement getpriority(2).
1846
1847 =item getpwnam NAME
1848
1849 =item getgrnam NAME
1850
1851 =item gethostbyname NAME
1852
1853 =item getnetbyname NAME
1854
1855 =item getprotobyname NAME
1856
1857 =item getpwuid UID
1858
1859 =item getgrgid GID
1860
1861 =item getservbyname NAME,PROTO
1862
1863 =item gethostbyaddr ADDR,ADDRTYPE
1864
1865 =item getnetbyaddr ADDR,ADDRTYPE
1866
1867 =item getprotobynumber NUMBER
1868
1869 =item getservbyport PORT,PROTO
1870
1871 =item getpwent
1872
1873 =item getgrent
1874
1875 =item gethostent
1876
1877 =item getnetent
1878
1879 =item getprotoent
1880
1881 =item getservent
1882
1883 =item setpwent
1884
1885 =item setgrent
1886
1887 =item sethostent STAYOPEN
1888
1889 =item setnetent STAYOPEN
1890
1891 =item setprotoent STAYOPEN
1892
1893 =item setservent STAYOPEN
1894
1895 =item endpwent
1896
1897 =item endgrent
1898
1899 =item endhostent
1900
1901 =item endnetent
1902
1903 =item endprotoent
1904
1905 =item endservent
1906
1907 These routines perform the same functions as their counterparts in the
1908 system library.  In list context, the return values from the
1909 various get routines are as follows:
1910
1911     ($name,$passwd,$uid,$gid,
1912        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1913     ($name,$passwd,$gid,$members) = getgr*
1914     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1915     ($name,$aliases,$addrtype,$net) = getnet*
1916     ($name,$aliases,$proto) = getproto*
1917     ($name,$aliases,$port,$proto) = getserv*
1918
1919 (If the entry doesn't exist you get a null list.)
1920
1921 The exact meaning of the $gcos field varies but it usually contains
1922 the real name of the user (as opposed to the login name) and other
1923 information pertaining to the user.  Beware, however, that in many
1924 system users are able to change this information and therefore it
1925 cannot be trusted and therefore the $gcos is tainted (see
1926 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1927 login shell, are also tainted, because of the same reason.
1928
1929 In scalar context, you get the name, unless the function was a
1930 lookup by name, in which case you get the other thing, whatever it is.
1931 (If the entry doesn't exist you get the undefined value.)  For example:
1932
1933     $uid   = getpwnam($name);
1934     $name  = getpwuid($num);
1935     $name  = getpwent();
1936     $gid   = getgrnam($name);
1937     $name  = getgrgid($num;
1938     $name  = getgrent();
1939     #etc.
1940
1941 In I<getpw*()> the fields $quota, $comment, and $expire are special
1942 cases in the sense that in many systems they are unsupported.  If the
1943 $quota is unsupported, it is an empty scalar.  If it is supported, it
1944 usually encodes the disk quota.  If the $comment field is unsupported,
1945 it is an empty scalar.  If it is supported it usually encodes some
1946 administrative comment about the user.  In some systems the $quota
1947 field may be $change or $age, fields that have to do with password
1948 aging.  In some systems the $comment field may be $class.  The $expire
1949 field, if present, encodes the expiration period of the account or the
1950 password.  For the availability and the exact meaning of these fields
1951 in your system, please consult your getpwnam(3) documentation and your
1952 F<pwd.h> file.  You can also find out from within Perl what your
1953 $quota and $comment fields mean and whether you have the $expire field
1954 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1955 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
1956 files are only supported if your vendor has implemented them in the
1957 intuitive fashion that calling the regular C library routines gets the
1958 shadow versions if you're running under privilege or if there exists
1959 the shadow(3) functions as found in System V ( this includes Solaris
1960 and Linux.)  Those systems which implement a proprietary shadow password
1961 facility are unlikely to be supported.
1962
1963 The $members value returned by I<getgr*()> is a space separated list of
1964 the login names of the members of the group.
1965
1966 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1967 C, it will be returned to you via C<$?> if the function call fails.  The
1968 C<@addrs> value returned by a successful call is a list of the raw
1969 addresses returned by the corresponding system library call.  In the
1970 Internet domain, each address is four bytes long and you can unpack it
1971 by saying something like:
1972
1973     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1974
1975 The Socket library makes this slightly easier:
1976
1977     use Socket;
1978     $iaddr = inet_aton("127.1"); # or whatever address
1979     $name  = gethostbyaddr($iaddr, AF_INET);
1980
1981     # or going the other way
1982     $straddr = inet_ntoa($iaddr);
1983
1984 If you get tired of remembering which element of the return list
1985 contains which return value, by-name interfaces are provided
1986 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1987 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1988 and C<User::grent>.  These override the normal built-ins, supplying
1989 versions that return objects with the appropriate names
1990 for each field.  For example:
1991
1992    use File::stat;
1993    use User::pwent;
1994    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1995
1996 Even though it looks like they're the same method calls (uid),
1997 they aren't, because a C<File::stat> object is different from
1998 a C<User::pwent> object.
1999
2000 =item getsockname SOCKET
2001
2002 Returns the packed sockaddr address of this end of the SOCKET connection,
2003 in case you don't know the address because you have several different
2004 IPs that the connection might have come in on.
2005
2006     use Socket;
2007     $mysockaddr = getsockname(SOCK);
2008     ($port, $myaddr) = sockaddr_in($mysockaddr);
2009     printf "Connect to %s [%s]\n",
2010        scalar gethostbyaddr($myaddr, AF_INET),
2011        inet_ntoa($myaddr);
2012
2013 =item getsockopt SOCKET,LEVEL,OPTNAME
2014
2015 Returns the socket option requested, or undef if there is an error.
2016
2017 =item glob EXPR
2018
2019 =item glob
2020
2021 Returns the value of EXPR with filename expansions such as the
2022 standard Unix shell F</bin/csh> would do.  This is the internal function
2023 implementing the C<< <*.c> >> operator, but you can use it directly.
2024 If EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is
2025 discussed in more detail in L<perlop/"I/O Operators">.
2026
2027 Beginning with v5.6.0, this operator is implemented using the standard
2028 C<File::Glob> extension.  See L<File::Glob> for details.
2029
2030 =item gmtime EXPR
2031
2032 Converts a time as returned by the time function to an 8-element list
2033 with the time localized for the standard Greenwich time zone.
2034 Typically used as follows:
2035
2036     #  0    1    2     3     4    5     6     7
2037     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2038                                             gmtime(time);
2039
2040 All list elements are numeric, and come straight out of the C `struct
2041 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2042 specified time.  $mday is the day of the month, and $mon is the month
2043 itself, in the range C<0..11> with 0 indicating January and 11
2044 indicating December.  $year is the number of years since 1900.  That
2045 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2046 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2047 the year, in the range C<0..364> (or C<0..365> in leap years.)
2048
2049 Note that the $year element is I<not> simply the last two digits of
2050 the year.  If you assume it is, then you create non-Y2K-compliant
2051 programs--and you wouldn't want to do that, would you?
2052
2053 The proper way to get a complete 4-digit year is simply:
2054
2055         $year += 1900;
2056
2057 And to get the last two digits of the year (e.g., '01' in 2001) do:
2058
2059         $year = sprintf("%02d", $year % 100);
2060
2061 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2062
2063 In scalar context, C<gmtime()> returns the ctime(3) value:
2064
2065     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2066
2067 Also see the C<timegm> function provided by the C<Time::Local> module,
2068 and the strftime(3) function available via the POSIX module.
2069
2070 This scalar value is B<not> locale dependent (see L<perllocale>), but
2071 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2072 strftime(3) and mktime(3) functions available via the POSIX module.  To
2073 get somewhat similar but locale dependent date strings, set up your
2074 locale environment variables appropriately (please see L<perllocale>)
2075 and try for example:
2076
2077     use POSIX qw(strftime);
2078     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2079
2080 Note that the C<%a> and C<%b> escapes, which represent the short forms
2081 of the day of the week and the month of the year, may not necessarily
2082 be three characters wide in all locales.
2083
2084 =item goto LABEL
2085
2086 =item goto EXPR
2087
2088 =item goto &NAME
2089
2090 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2091 execution there.  It may not be used to go into any construct that
2092 requires initialization, such as a subroutine or a C<foreach> loop.  It
2093 also can't be used to go into a construct that is optimized away,
2094 or to get out of a block or subroutine given to C<sort>.
2095 It can be used to go almost anywhere else within the dynamic scope,
2096 including out of subroutines, but it's usually better to use some other
2097 construct such as C<last> or C<die>.  The author of Perl has never felt the
2098 need to use this form of C<goto> (in Perl, that is--C is another matter).
2099 (The difference being that C does not offer named loops combined with
2100 loop control.  Perl does, and this replaces most structured uses of C<goto>
2101 in other languages.)
2102
2103 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2104 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2105 necessarily recommended if you're optimizing for maintainability:
2106
2107     goto ("FOO", "BAR", "GLARCH")[$i];
2108
2109 The C<goto-&NAME> form is quite different from the other forms of
2110 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2111 doesn't have the stigma associated with other gotos.  Instead, it
2112 exits the current subroutine (losing any changes set by local()) and
2113 immediately calls in its place the named subroutine using the current
2114 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2115 load another subroutine and then pretend that the other subroutine had
2116 been called in the first place (except that any modifications to C<@_>
2117 in the current subroutine are propagated to the other subroutine.)
2118 After the C<goto>, not even C<caller> will be able to tell that this
2119 routine was called first.
2120
2121 NAME needn't be the name of a subroutine; it can be a scalar variable
2122 containing a code reference, or a block which evaluates to a code
2123 reference.
2124
2125 =item grep BLOCK LIST
2126
2127 =item grep EXPR,LIST
2128
2129 This is similar in spirit to, but not the same as, grep(1) and its
2130 relatives.  In particular, it is not limited to using regular expressions.
2131
2132 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2133 C<$_> to each element) and returns the list value consisting of those
2134 elements for which the expression evaluated to true.  In scalar
2135 context, returns the number of times the expression was true.
2136
2137     @foo = grep(!/^#/, @bar);    # weed out comments
2138
2139 or equivalently,
2140
2141     @foo = grep {!/^#/} @bar;    # weed out comments
2142
2143 Note that C<$_> is an alias to the list value, so it can be used to
2144 modify the elements of the LIST.  While this is useful and supported,
2145 it can cause bizarre results if the elements of LIST are not variables.
2146 Similarly, grep returns aliases into the original list, much as a for
2147 loop's index variable aliases the list elements.  That is, modifying an
2148 element of a list returned by grep (for example, in a C<foreach>, C<map>
2149 or another C<grep>) actually modifies the element in the original list.
2150 This is usually something to be avoided when writing clear code.
2151
2152 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2153
2154 =item hex EXPR
2155
2156 =item hex
2157
2158 Interprets EXPR as a hex string and returns the corresponding value.
2159 (To convert strings that might start with either 0, 0x, or 0b, see
2160 L</oct>.)  If EXPR is omitted, uses C<$_>.
2161
2162     print hex '0xAf'; # prints '175'
2163     print hex 'aF';   # same
2164
2165 Hex strings may only represent integers.  Strings that would cause
2166 integer overflow trigger a warning.  Leading whitespace is not stripped,
2167 unlike oct().
2168
2169 =item import
2170
2171 There is no builtin C<import> function.  It is just an ordinary
2172 method (subroutine) defined (or inherited) by modules that wish to export
2173 names to another module.  The C<use> function calls the C<import> method
2174 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2175
2176 =item index STR,SUBSTR,POSITION
2177
2178 =item index STR,SUBSTR
2179
2180 The index function searches for one string within another, but without
2181 the wildcard-like behavior of a full regular-expression pattern match.
2182 It returns the position of the first occurrence of SUBSTR in STR at
2183 or after POSITION.  If POSITION is omitted, starts searching from the
2184 beginning of the string.  The return value is based at C<0> (or whatever
2185 you've set the C<$[> variable to--but don't do that).  If the substring
2186 is not found, returns one less than the base, ordinarily C<-1>.
2187
2188 =item int EXPR
2189
2190 =item int
2191
2192 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2193 You should not use this function for rounding: one because it truncates
2194 towards C<0>, and two because machine representations of floating point
2195 numbers can sometimes produce counterintuitive results.  For example,
2196 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2197 because it's really more like -268.99999999999994315658 instead.  Usually,
2198 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2199 functions will serve you better than will int().
2200
2201 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2202
2203 Implements the ioctl(2) function.  You'll probably first have to say
2204
2205     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2206
2207 to get the correct function definitions.  If F<ioctl.ph> doesn't
2208 exist or doesn't have the correct definitions you'll have to roll your
2209 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2210 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2211 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2212 written depending on the FUNCTION--a pointer to the string value of SCALAR
2213 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2214 has no string value but does have a numeric value, that value will be
2215 passed rather than a pointer to the string value.  To guarantee this to be
2216 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2217 functions may be needed to manipulate the values of structures used by
2218 C<ioctl>.
2219
2220 The return value of C<ioctl> (and C<fcntl>) is as follows:
2221
2222         if OS returns:          then Perl returns:
2223             -1                    undefined value
2224              0                  string "0 but true"
2225         anything else               that number
2226
2227 Thus Perl returns true on success and false on failure, yet you can
2228 still easily determine the actual value returned by the operating
2229 system:
2230
2231     $retval = ioctl(...) || -1;
2232     printf "System returned %d\n", $retval;
2233
2234 The special string "C<0> but true" is exempt from B<-w> complaints
2235 about improper numeric conversions.
2236
2237 Here's an example of setting a filehandle named C<REMOTE> to be
2238 non-blocking at the system level.  You'll have to negotiate C<$|>
2239 on your own, though.
2240
2241     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2242
2243     $flags = fcntl(REMOTE, F_GETFL, 0)
2244                 or die "Can't get flags for the socket: $!\n";
2245
2246     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2247                 or die "Can't set flags for the socket: $!\n";
2248
2249 =item join EXPR,LIST
2250
2251 Joins the separate strings of LIST into a single string with fields
2252 separated by the value of EXPR, and returns that new string.  Example:
2253
2254     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2255
2256 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2257 first argument.  Compare L</split>.
2258
2259 =item keys HASH
2260
2261 Returns a list consisting of all the keys of the named hash.  (In
2262 scalar context, returns the number of keys.)  The keys are returned in
2263 an apparently random order.  The actual random order is subject to
2264 change in future versions of perl, but it is guaranteed to be the same
2265 order as either the C<values> or C<each> function produces (given
2266 that the hash has not been modified).  As a side effect, it resets
2267 HASH's iterator.
2268
2269 Here is yet another way to print your environment:
2270
2271     @keys = keys %ENV;
2272     @values = values %ENV;
2273     while (@keys) {
2274         print pop(@keys), '=', pop(@values), "\n";
2275     }
2276
2277 or how about sorted by key:
2278
2279     foreach $key (sort(keys %ENV)) {
2280         print $key, '=', $ENV{$key}, "\n";
2281     }
2282
2283 The returned values are copies of the original keys in the hash, so
2284 modifying them will not affect the original hash.  Compare L</values>.
2285
2286 To sort a hash by value, you'll need to use a C<sort> function.
2287 Here's a descending numeric sort of a hash by its values:
2288
2289     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2290         printf "%4d %s\n", $hash{$key}, $key;
2291     }
2292
2293 As an lvalue C<keys> allows you to increase the number of hash buckets
2294 allocated for the given hash.  This can gain you a measure of efficiency if
2295 you know the hash is going to get big.  (This is similar to pre-extending
2296 an array by assigning a larger number to $#array.)  If you say
2297
2298     keys %hash = 200;
2299
2300 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2301 in fact, since it rounds up to the next power of two.  These
2302 buckets will be retained even if you do C<%hash = ()>, use C<undef
2303 %hash> if you want to free the storage while C<%hash> is still in scope.
2304 You can't shrink the number of buckets allocated for the hash using
2305 C<keys> in this way (but you needn't worry about doing this by accident,
2306 as trying has no effect).
2307
2308 See also C<each>, C<values> and C<sort>.
2309
2310 =item kill SIGNAL, LIST
2311
2312 Sends a signal to a list of processes.  Returns the number of
2313 processes successfully signaled (which is not necessarily the
2314 same as the number actually killed).
2315
2316     $cnt = kill 1, $child1, $child2;
2317     kill 9, @goners;
2318
2319 If SIGNAL is zero, no signal is sent to the process.  This is a
2320 useful way to check that the process is alive and hasn't changed
2321 its UID.  See L<perlport> for notes on the portability of this
2322 construct.
2323
2324 Unlike in the shell, if SIGNAL is negative, it kills
2325 process groups instead of processes.  (On System V, a negative I<PROCESS>
2326 number will also kill process groups, but that's not portable.)  That
2327 means you usually want to use positive not negative signals.  You may also
2328 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2329
2330 =item last LABEL
2331
2332 =item last
2333
2334 The C<last> command is like the C<break> statement in C (as used in
2335 loops); it immediately exits the loop in question.  If the LABEL is
2336 omitted, the command refers to the innermost enclosing loop.  The
2337 C<continue> block, if any, is not executed:
2338
2339     LINE: while (<STDIN>) {
2340         last LINE if /^$/;      # exit when done with header
2341         #...
2342     }
2343
2344 C<last> cannot be used to exit a block which returns a value such as
2345 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2346 a grep() or map() operation.
2347
2348 Note that a block by itself is semantically identical to a loop
2349 that executes once.  Thus C<last> can be used to effect an early
2350 exit out of such a block.
2351
2352 See also L</continue> for an illustration of how C<last>, C<next>, and
2353 C<redo> work.
2354
2355 =item lc EXPR
2356
2357 =item lc
2358
2359 Returns a lowercased version of EXPR.  This is the internal function
2360 implementing the C<\L> escape in double-quoted strings.  Respects
2361 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2362 and L<perlunicode> for more details about locale and Unicode support.
2363
2364 If EXPR is omitted, uses C<$_>.
2365
2366 =item lcfirst EXPR
2367
2368 =item lcfirst
2369
2370 Returns the value of EXPR with the first character lowercased.  This
2371 is the internal function implementing the C<\l> escape in
2372 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2373 locale> in force.  See L<perllocale> and L<perlunicode> for more
2374 details about locale and Unicode support.
2375
2376 If EXPR is omitted, uses C<$_>.
2377
2378 =item length EXPR
2379
2380 =item length
2381
2382 Returns the length in characters of the value of EXPR.  If EXPR is
2383 omitted, returns length of C<$_>.  Note that this cannot be used on
2384 an entire array or hash to find out how many elements these have.
2385 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2386
2387 =item link OLDFILE,NEWFILE
2388
2389 Creates a new filename linked to the old filename.  Returns true for
2390 success, false otherwise.
2391
2392 =item listen SOCKET,QUEUESIZE
2393
2394 Does the same thing that the listen system call does.  Returns true if
2395 it succeeded, false otherwise.  See the example in
2396 L<perlipc/"Sockets: Client/Server Communication">.
2397
2398 =item local EXPR
2399
2400 You really probably want to be using C<my> instead, because C<local> isn't
2401 what most people think of as "local".  See
2402 L<perlsub/"Private Variables via my()"> for details.
2403
2404 A local modifies the listed variables to be local to the enclosing
2405 block, file, or eval.  If more than one value is listed, the list must
2406 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2407 for details, including issues with tied arrays and hashes.
2408
2409 =item localtime EXPR
2410
2411 Converts a time as returned by the time function to a 9-element list
2412 with the time analyzed for the local time zone.  Typically used as
2413 follows:
2414
2415     #  0    1    2     3     4    5     6     7     8
2416     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2417                                                 localtime(time);
2418
2419 All list elements are numeric, and come straight out of the C `struct
2420 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2421 specified time.  $mday is the day of the month, and $mon is the month
2422 itself, in the range C<0..11> with 0 indicating January and 11
2423 indicating December.  $year is the number of years since 1900.  That
2424 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2425 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2426 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2427 is true if the specified time occurs during daylight savings time,
2428 false otherwise.
2429
2430 Note that the $year element is I<not> simply the last two digits of
2431 the year.  If you assume it is, then you create non-Y2K-compliant
2432 programs--and you wouldn't want to do that, would you?
2433
2434 The proper way to get a complete 4-digit year is simply:
2435
2436         $year += 1900;
2437
2438 And to get the last two digits of the year (e.g., '01' in 2001) do:
2439
2440         $year = sprintf("%02d", $year % 100);
2441
2442 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2443
2444 In scalar context, C<localtime()> returns the ctime(3) value:
2445
2446     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2447
2448 This scalar value is B<not> locale dependent, see L<perllocale>, but
2449 instead a Perl builtin.  Also see the C<Time::Local> module
2450 (to convert the second, minutes, hours, ... back to seconds since the
2451 stroke of midnight the 1st of January 1970, the value returned by
2452 time()), and the strftime(3) and mktime(3) functions available via the
2453 POSIX module.  To get somewhat similar but locale dependent date
2454 strings, set up your locale environment variables appropriately
2455 (please see L<perllocale>) and try for example:
2456
2457     use POSIX qw(strftime);
2458     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2459
2460 Note that the C<%a> and C<%b>, the short forms of the day of the week
2461 and the month of the year, may not necessarily be three characters wide.
2462
2463 =item lock THING
2464
2465 This function places an advisory lock on a variable, subroutine,
2466 or referenced object contained in I<THING> until the lock goes out
2467 of scope.  This is a built-in function only if your version of Perl
2468 was built with threading enabled, and if you've said C<use Thread>.
2469 Otherwise a user-defined function by this name will be called.
2470 See L<Thread>.
2471
2472 =item log EXPR
2473
2474 =item log
2475
2476 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2477 returns log of C<$_>.  To get the log of another base, use basic algebra:
2478 The base-N log of a number is equal to the natural log of that number
2479 divided by the natural log of N.  For example:
2480
2481     sub log10 {
2482         my $n = shift;
2483         return log($n)/log(10);
2484     }
2485
2486 See also L</exp> for the inverse operation.
2487
2488 =item lstat EXPR
2489
2490 =item lstat
2491
2492 Does the same thing as the C<stat> function (including setting the
2493 special C<_> filehandle) but stats a symbolic link instead of the file
2494 the symbolic link points to.  If symbolic links are unimplemented on
2495 your system, a normal C<stat> is done.
2496
2497 If EXPR is omitted, stats C<$_>.
2498
2499 =item m//
2500
2501 The match operator.  See L<perlop>.
2502
2503 =item map BLOCK LIST
2504
2505 =item map EXPR,LIST
2506
2507 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2508 C<$_> to each element) and returns the list value composed of the
2509 results of each such evaluation.  In scalar context, returns the
2510 total number of elements so generated.  Evaluates BLOCK or EXPR in
2511 list context, so each element of LIST may produce zero, one, or
2512 more elements in the returned value.
2513
2514     @chars = map(chr, @nums);
2515
2516 translates a list of numbers to the corresponding characters.  And
2517
2518     %hash = map { getkey($_) => $_ } @array;
2519
2520 is just a funny way to write
2521
2522     %hash = ();
2523     foreach $_ (@array) {
2524         $hash{getkey($_)} = $_;
2525     }
2526
2527 Note that C<$_> is an alias to the list value, so it can be used to
2528 modify the elements of the LIST.  While this is useful and supported,
2529 it can cause bizarre results if the elements of LIST are not variables.
2530 Using a regular C<foreach> loop for this purpose would be clearer in
2531 most cases.  See also L</grep> for an array composed of those items of
2532 the original list for which the BLOCK or EXPR evaluates to true.
2533
2534 C<{> starts both hash references and blocks, so C<map { ...> could be either
2535 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2536 ahead for the closing C<}> it has to take a guess at which its dealing with
2537 based what it finds just after the C<{>. Usually it gets it right, but if it
2538 doesn't it won't realize something is wrong until it gets to the C<}> and
2539 encounters the missing (or unexpected) comma. The syntax error will be
2540 reported close to the C<}> but you'll need to change something near the C<{>
2541 such as using a unary C<+> to give perl some help:
2542
2543     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2544     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2545     %hash = map { ("\L$_", 1) } @array  # this also works
2546     %hash = map {  lc($_), 1  } @array  # as does this.
2547     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2548
2549     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2550
2551 or to force an anon hash constructor use C<+{>
2552
2553    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2554
2555 and you get list of anonymous hashes each with only 1 entry.
2556
2557 =item mkdir FILENAME,MASK
2558
2559 =item mkdir FILENAME
2560
2561 Creates the directory specified by FILENAME, with permissions
2562 specified by MASK (as modified by C<umask>).  If it succeeds it
2563 returns true, otherwise it returns false and sets C<$!> (errno).
2564 If omitted, MASK defaults to 0777.
2565
2566 In general, it is better to create directories with permissive MASK,
2567 and let the user modify that with their C<umask>, than it is to supply
2568 a restrictive MASK and give the user no way to be more permissive.
2569 The exceptions to this rule are when the file or directory should be
2570 kept private (mail files, for instance).  The perlfunc(1) entry on
2571 C<umask> discusses the choice of MASK in more detail.
2572
2573 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2574 number of trailing slashes.  Some operating and filesystems do not get
2575 this right, so Perl automatically removes all trailing slashes to keep
2576 everyone happy.
2577
2578 =item msgctl ID,CMD,ARG
2579
2580 Calls the System V IPC function msgctl(2).  You'll probably have to say
2581
2582     use IPC::SysV;
2583
2584 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2585 then ARG must be a variable which will hold the returned C<msqid_ds>
2586 structure.  Returns like C<ioctl>: the undefined value for error,
2587 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2588 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2589
2590 =item msgget KEY,FLAGS
2591
2592 Calls the System V IPC function msgget(2).  Returns the message queue
2593 id, or the undefined value if there is an error.  See also
2594 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2595
2596 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2597
2598 Calls the System V IPC function msgrcv to receive a message from
2599 message queue ID into variable VAR with a maximum message size of
2600 SIZE.  Note that when a message is received, the message type as a
2601 native long integer will be the first thing in VAR, followed by the
2602 actual message.  This packing may be opened with C<unpack("l! a*")>.
2603 Taints the variable.  Returns true if successful, or false if there is
2604 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2605 C<IPC::SysV::Msg> documentation.
2606
2607 =item msgsnd ID,MSG,FLAGS
2608
2609 Calls the System V IPC function msgsnd to send the message MSG to the
2610 message queue ID.  MSG must begin with the native long integer message
2611 type, and be followed by the length of the actual message, and finally
2612 the message itself.  This kind of packing can be achieved with
2613 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2614 or false if there is an error.  See also C<IPC::SysV>
2615 and C<IPC::SysV::Msg> documentation.
2616
2617 =item my EXPR
2618
2619 =item my EXPR : ATTRIBUTES
2620
2621 A C<my> declares the listed variables to be local (lexically) to the
2622 enclosing block, file, or C<eval>.  If
2623 more than one value is listed, the list must be placed in parentheses.  See
2624 L<perlsub/"Private Variables via my()"> for details.
2625
2626 =item next LABEL
2627
2628 =item next
2629
2630 The C<next> command is like the C<continue> statement in C; it starts
2631 the next iteration of the loop:
2632
2633     LINE: while (<STDIN>) {
2634         next LINE if /^#/;      # discard comments
2635         #...
2636     }
2637
2638 Note that if there were a C<continue> block on the above, it would get
2639 executed even on discarded lines.  If the LABEL is omitted, the command
2640 refers to the innermost enclosing loop.
2641
2642 C<next> cannot be used to exit a block which returns a value such as
2643 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2644 a grep() or map() operation.
2645
2646 Note that a block by itself is semantically identical to a loop
2647 that executes once.  Thus C<next> will exit such a block early.
2648
2649 See also L</continue> for an illustration of how C<last>, C<next>, and
2650 C<redo> work.
2651
2652 =item no Module LIST
2653
2654 See the L</use> function, which C<no> is the opposite of.
2655
2656 =item oct EXPR
2657
2658 =item oct
2659
2660 Interprets EXPR as an octal string and returns the corresponding
2661 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2662 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2663 binary string.  Leading whitespace is ignored in all three cases.)
2664 The following will handle decimal, binary, octal, and hex in the standard
2665 Perl or C notation:
2666
2667     $val = oct($val) if $val =~ /^0/;
2668
2669 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2670 in octal), use sprintf() or printf():
2671
2672     $perms = (stat("filename"))[2] & 07777;
2673     $oct_perms = sprintf "%lo", $perms;
2674
2675 The oct() function is commonly used when a string such as C<644> needs
2676 to be converted into a file mode, for example. (Although perl will
2677 automatically convert strings into numbers as needed, this automatic
2678 conversion assumes base 10.)
2679
2680 =item open FILEHANDLE,EXPR
2681
2682 =item open FILEHANDLE,MODE,EXPR
2683
2684 =item open FILEHANDLE,MODE,EXPR,LIST
2685
2686 =item open FILEHANDLE,MODE,REFERENCE
2687
2688 =item open FILEHANDLE
2689
2690 Opens the file whose filename is given by EXPR, and associates it with
2691 FILEHANDLE.
2692
2693 (The following is a comprehensive reference to open(): for a gentler
2694 introduction you may consider L<perlopentut>.)
2695
2696 If FILEHANDLE is an undefined lexical (C<my>) variable the variable is
2697 assigned a reference to a new anonymous filehandle, otherwise if
2698 FILEHANDLE is an expression, its value is used as the name of the real
2699 filehandle wanted.  (This is considered a symbolic reference, so C<use
2700 strict 'refs'> should I<not> be in effect.)
2701
2702 If EXPR is omitted, the scalar variable of the same name as the
2703 FILEHANDLE contains the filename.  (Note that lexical variables--those
2704 declared with C<my>--will not work for this purpose; so if you're
2705 using C<my>, specify EXPR in your call to open.) 
2706
2707 If three or more arguments are specified then the mode of opening and
2708 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2709 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2710 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2711 the file is opened for appending, again being created if necessary.
2712
2713 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2714 indicate that you want both read and write access to the file; thus
2715 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2716 '+>' >> mode would clobber the file first.  You can't usually use
2717 either read-write mode for updating textfiles, since they have
2718 variable length records.  See the B<-i> switch in L<perlrun> for a
2719 better approach.  The file is created with permissions of C<0666>
2720 modified by the process' C<umask> value.
2721
2722 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2723 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2724
2725 In the 2-arguments (and 1-argument) form of the call the mode and
2726 filename should be concatenated (in this order), possibly separated by
2727 spaces.  It is possible to omit the mode in these forms if the mode is
2728 C<< '<' >>.
2729
2730 If the filename begins with C<'|'>, the filename is interpreted as a
2731 command to which output is to be piped, and if the filename ends with a
2732 C<'|'>, the filename is interpreted as a command which pipes output to
2733 us.  See L<perlipc/"Using open() for IPC">
2734 for more examples of this.  (You are not allowed to C<open> to a command
2735 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2736 and L<perlipc/"Bidirectional Communication with Another Process">
2737 for alternatives.)
2738
2739 For three or more arguments if MODE is C<'|-'>, the filename is
2740 interpreted as a command to which output is to be piped, and if MODE
2741 is C<'-|'>, the filename is interpreted as a command which pipes
2742 output to us.  In the 2-arguments (and 1-argument) form one should
2743 replace dash (C<'-'>) with the command.
2744 See L<perlipc/"Using open() for IPC"> for more examples of this.
2745 (You are not allowed to C<open> to a command that pipes both in I<and>
2746 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2747 L<perlipc/"Bidirectional Communication"> for alternatives.)
2748
2749 In the three-or-more argument form of pipe opens, if LIST is specified
2750 (extra arguments after the command name) then LIST becomes arguments
2751 to the command invoked if the platform supports it.  The meaning of
2752 C<open> with more than three arguments for non-pipe modes is not yet
2753 specified. Experimental "layers" may give extra LIST arguments
2754 meaning.
2755
2756 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2757 and opening C<< '>-' >> opens STDOUT.
2758
2759 You may use the three-argument form of open to specify
2760 I<I/O disciplines> that affect how the input and output
2761 are processed: see L</binmode> and L<open>.  For example
2762
2763   open(FH, "<:utf8", "file")
2764
2765 will open the UTF-8 encoded file containing Unicode characters,
2766 see L<perluniintro>.
2767
2768 Open returns nonzero upon success, the undefined value otherwise.  If
2769 the C<open> involved a pipe, the return value happens to be the pid of
2770 the subprocess.
2771
2772 If you're running Perl on a system that distinguishes between text
2773 files and binary files, then you should check out L</binmode> for tips
2774 for dealing with this.  The key distinction between systems that need
2775 C<binmode> and those that don't is their text file formats.  Systems
2776 like Unix, MacOS, and Plan9, which delimit lines with a single
2777 character, and which encode that character in C as C<"\n">, do not
2778 need C<binmode>.  The rest need it.
2779
2780 In the three argument form MODE may also contain a list of IO "layers"
2781 (see L<open> and L<PerlIO> for more details) to be applied to the
2782 handle. This can be used to achieve the effect of C<binmode> as well
2783 as more complex behaviours.
2784
2785 When opening a file, it's usually a bad idea to continue normal execution
2786 if the request failed, so C<open> is frequently used in connection with
2787 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2788 where you want to make a nicely formatted error message (but there are
2789 modules that can help with that problem)) you should always check
2790 the return value from opening a file.  The infrequent exception is when
2791 working with an unopened filehandle is actually what you want to do.
2792
2793 As a special case the 3 arg form with a read/write mode and the third
2794 argument being C<undef>:
2795
2796     open(TMP, "+>", undef) or die ...
2797
2798 opens a filehandle to an anonymous temporary file.
2799
2800 File handles can be opened to "in memory" files held in Perl scalars via:
2801
2802     open($fh,'>', \$variable) || ..
2803
2804 Examples:
2805
2806     $ARTICLE = 100;
2807     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2808     while (<ARTICLE>) {...
2809
2810     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2811     # if the open fails, output is discarded
2812
2813     open(DBASE, '+<', 'dbase.mine')             # open for update
2814         or die "Can't open 'dbase.mine' for update: $!";
2815
2816     open(DBASE, '+<dbase.mine')                 # ditto
2817         or die "Can't open 'dbase.mine' for update: $!";
2818
2819     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2820         or die "Can't start caesar: $!";
2821
2822     open(ARTICLE, "caesar <$article |")         # ditto
2823         or die "Can't start caesar: $!";
2824
2825     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2826         or die "Can't start sort: $!";
2827
2828     # in memory files
2829     open(MEMORY,'>', \$var)
2830         or die "Can't open memory file: $!";
2831     print MEMORY "foo!\n";                      # output will end up in $var
2832
2833     # process argument list of files along with any includes
2834
2835     foreach $file (@ARGV) {
2836         process($file, 'fh00');
2837     }
2838
2839     sub process {
2840         my($filename, $input) = @_;
2841         $input++;               # this is a string increment
2842         unless (open($input, $filename)) {
2843             print STDERR "Can't open $filename: $!\n";
2844             return;
2845         }
2846
2847         local $_;
2848         while (<$input>) {              # note use of indirection
2849             if (/^#include "(.*)"/) {
2850                 process($1, $input);
2851                 next;
2852             }
2853             #...                # whatever
2854         }
2855     }
2856
2857 You may also, in the Bourne shell tradition, specify an EXPR beginning
2858 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2859 name of a filehandle (or file descriptor, if numeric) to be
2860 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2861 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2862 mode you specify should match the mode of the original filehandle.
2863 (Duping a filehandle does not take into account any existing contents of
2864 IO buffers.) If you use the 3 arg form then you can pass either a number,
2865 the name of a filehandle or the normal "reference to a glob".
2866
2867 Here is a script that saves, redirects, and restores STDOUT and
2868 STDERR:
2869
2870     #!/usr/bin/perl
2871     open(my $oldout, ">&", \*STDOUT);
2872     open(OLDERR, ">&STDERR");
2873
2874     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2875     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2876
2877     select(STDERR); $| = 1;     # make unbuffered
2878     select(STDOUT); $| = 1;     # make unbuffered
2879
2880     print STDOUT "stdout 1\n";  # this works for
2881     print STDERR "stderr 1\n";  # subprocesses too
2882
2883     close(STDOUT);
2884     close(STDERR);
2885
2886     open(STDOUT, ">&OLDOUT");
2887     open(STDERR, ">&OLDERR");
2888
2889     print STDOUT "stdout 2\n";
2890     print STDERR "stderr 2\n";
2891
2892 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will
2893 do an equivalent of C's C<fdopen> of that file descriptor; this is
2894 more parsimonious of file descriptors.  For example:
2895
2896     open(FILEHANDLE, "<&=$fd")
2897
2898 or
2899
2900     open(FILEHANDLE, "<&=", $fd)
2901
2902 Note that if Perl is using the standard C libraries' fdopen() then on
2903 many UNIX systems, fdopen() is known to fail when file descriptors
2904 exceed a certain value, typically 255. If you need more file
2905 descriptors than that, consider rebuilding Perl to use the C<PerlIO>.
2906
2907 You can see whether Perl has been compiled with PerlIO or not by
2908 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
2909 is C<define>, you have PerlIO, otherwise you don't.
2910
2911 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2912 with 2-arguments (or 1-argument) form of open(), then
2913 there is an implicit fork done, and the return value of open is the pid
2914 of the child within the parent process, and C<0> within the child
2915 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2916 The filehandle behaves normally for the parent, but i/o to that
2917 filehandle is piped from/to the STDOUT/STDIN of the child process.
2918 In the child process the filehandle isn't opened--i/o happens from/to
2919 the new STDOUT or STDIN.  Typically this is used like the normal
2920 piped open when you want to exercise more control over just how the
2921 pipe command gets executed, such as when you are running setuid, and
2922 don't want to have to scan shell commands for metacharacters.
2923 The following triples are more or less equivalent:
2924
2925     open(FOO, "|tr '[a-z]' '[A-Z]'");
2926     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2927     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2928     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
2929
2930     open(FOO, "cat -n '$file'|");
2931     open(FOO, '-|', "cat -n '$file'");
2932     open(FOO, '-|') || exec 'cat', '-n', $file;
2933     open(FOO, '-|', "cat", '-n', $file);
2934
2935 The last example in each block shows the pipe as "list form", which is
2936 not yet supported on all platforms.
2937
2938 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2939
2940 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2941 output before any operation that may do a fork, but this may not be
2942 supported on some platforms (see L<perlport>).  To be safe, you may need
2943 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
2944 of C<IO::Handle> on any open handles.
2945
2946 On systems that support a close-on-exec flag on files, the flag will
2947 be set for the newly opened file descriptor as determined by the value
2948 of $^F.  See L<perlvar/$^F>.
2949
2950 Closing any piped filehandle causes the parent process to wait for the
2951 child to finish, and returns the status value in C<$?>.
2952
2953 The filename passed to 2-argument (or 1-argument) form of open() will
2954 have leading and trailing whitespace deleted, and the normal
2955 redirection characters honored.  This property, known as "magic open",
2956 can often be used to good effect.  A user could specify a filename of
2957 F<"rsh cat file |">, or you could change certain filenames as needed:
2958
2959     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2960     open(FH, $filename) or die "Can't open $filename: $!";
2961
2962 Use 3-argument form to open a file with arbitrary weird characters in it,
2963
2964     open(FOO, '<', $file);
2965
2966 otherwise it's necessary to protect any leading and trailing whitespace:
2967
2968     $file =~ s#^(\s)#./$1#;
2969     open(FOO, "< $file\0");
2970
2971 (this may not work on some bizarre filesystems).  One should
2972 conscientiously choose between the I<magic> and 3-arguments form
2973 of open():
2974
2975     open IN, $ARGV[0];
2976
2977 will allow the user to specify an argument of the form C<"rsh cat file |">,
2978 but will not work on a filename which happens to have a trailing space, while
2979
2980     open IN, '<', $ARGV[0];
2981
2982 will have exactly the opposite restrictions.
2983
2984 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2985 should use the C<sysopen> function, which involves no such magic (but
2986 may use subtly different filemodes than Perl open(), which is mapped
2987 to C fopen()).  This is
2988 another way to protect your filenames from interpretation.  For example:
2989
2990     use IO::Handle;
2991     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2992         or die "sysopen $path: $!";
2993     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2994     print HANDLE "stuff $$\n";
2995     seek(HANDLE, 0, 0);
2996     print "File contains: ", <HANDLE>;
2997
2998 Using the constructor from the C<IO::Handle> package (or one of its
2999 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3000 filehandles that have the scope of whatever variables hold references to
3001 them, and automatically close whenever and however you leave that scope:
3002
3003     use IO::File;
3004     #...
3005     sub read_myfile_munged {
3006         my $ALL = shift;
3007         my $handle = new IO::File;
3008         open($handle, "myfile") or die "myfile: $!";
3009         $first = <$handle>
3010             or return ();     # Automatically closed here.
3011         mung $first or die "mung failed";       # Or here.
3012         return $first, <$handle> if $ALL;       # Or here.
3013         $first;                                 # Or here.
3014     }
3015
3016 See L</seek> for some details about mixing reading and writing.
3017
3018 =item opendir DIRHANDLE,EXPR
3019
3020 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3021 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3022 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3023
3024 =item ord EXPR
3025
3026 =item ord
3027
3028 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3029 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3030 uses C<$_>.
3031
3032 For the reverse, see L</chr>.
3033 See L<perlunicode> and L<encoding> for more about Unicode.
3034
3035 =item our EXPR
3036
3037 =item our EXPR : ATTRIBUTES
3038
3039 An C<our> declares the listed variables to be valid globals within
3040 the enclosing block, file, or C<eval>.  That is, it has the same
3041 scoping rules as a "my" declaration, but does not create a local
3042 variable.  If more than one value is listed, the list must be placed
3043 in parentheses.  The C<our> declaration has no semantic effect unless
3044 "use strict vars" is in effect, in which case it lets you use the
3045 declared global variable without qualifying it with a package name.
3046 (But only within the lexical scope of the C<our> declaration.  In this
3047 it differs from "use vars", which is package scoped.)
3048
3049 An C<our> declaration declares a global variable that will be visible
3050 across its entire lexical scope, even across package boundaries.  The
3051 package in which the variable is entered is determined at the point
3052 of the declaration, not at the point of use.  This means the following
3053 behavior holds:
3054
3055     package Foo;
3056     our $bar;           # declares $Foo::bar for rest of lexical scope
3057     $bar = 20;
3058
3059     package Bar;
3060     print $bar;         # prints 20
3061
3062 Multiple C<our> declarations in the same lexical scope are allowed
3063 if they are in different packages.  If they happened to be in the same
3064 package, Perl will emit warnings if you have asked for them.
3065
3066     use warnings;
3067     package Foo;
3068     our $bar;           # declares $Foo::bar for rest of lexical scope
3069     $bar = 20;
3070
3071     package Bar;
3072     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3073     print $bar;         # prints 30
3074
3075     our $bar;           # emits warning
3076
3077 An C<our> declaration may also have a list of attributes associated
3078 with it.  B<WARNING>: This is an experimental feature that may be
3079 changed or removed in future releases of Perl.  It should not be
3080 relied upon.
3081
3082 The only currently recognized attribute is C<unique> which indicates
3083 that a single copy of the global is to be used by all interpreters
3084 should the program happen to be running in a multi-interpreter
3085 environment. (The default behaviour would be for each interpreter to
3086 have its own copy of the global.)  In such an environment, this
3087 attribute also has the effect of making the global readonly.
3088 Examples:
3089
3090     our @EXPORT : unique = qw(foo);
3091     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3092     our $VERSION : unique = "1.00";
3093
3094 Multi-interpreter environments can come to being either through the
3095 fork() emulation on Windows platforms, or by embedding perl in a
3096 multi-threaded application.  The C<unique> attribute does nothing in
3097 all other environments.
3098
3099 =item pack TEMPLATE,LIST
3100
3101 Takes a LIST of values and converts it into a string using the rules
3102 given by the TEMPLATE.  The resulting string is the concatenation of
3103 the converted values.  Typically, each converted value looks
3104 like its machine-level representation.  For example, on 32-bit machines
3105 a converted integer may be represented by a sequence of 4 bytes.
3106
3107 The TEMPLATE is a
3108 sequence of characters that give the order and type of values, as
3109 follows:
3110
3111     a   A string with arbitrary binary data, will be null padded.
3112     A   A text (ASCII) string, will be space padded.
3113     Z   A null terminated (ASCIZ) string, will be null padded.
3114
3115     b   A bit string (ascending bit order inside each byte, like vec()).
3116     B   A bit string (descending bit order inside each byte).
3117     h   A hex string (low nybble first).
3118     H   A hex string (high nybble first).
3119
3120     c   A signed char value.
3121     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3122
3123     s   A signed short value.
3124     S   An unsigned short value.
3125           (This 'short' is _exactly_ 16 bits, which may differ from
3126            what a local C compiler calls 'short'.  If you want
3127            native-length shorts, use the '!' suffix.)
3128
3129     i   A signed integer value.
3130     I   An unsigned integer value.
3131           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3132            size depends on what a local C compiler calls 'int',
3133            and may even be larger than the 'long' described in
3134            the next item.)
3135
3136     l   A signed long value.
3137     L   An unsigned long value.
3138           (This 'long' is _exactly_ 32 bits, which may differ from
3139            what a local C compiler calls 'long'.  If you want
3140            native-length longs, use the '!' suffix.)
3141
3142     n   An unsigned short in "network" (big-endian) order.
3143     N   An unsigned long in "network" (big-endian) order.
3144     v   An unsigned short in "VAX" (little-endian) order.
3145     V   An unsigned long in "VAX" (little-endian) order.
3146           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3147            _exactly_ 32 bits, respectively.)
3148
3149     q   A signed quad (64-bit) value.
3150     Q   An unsigned quad value.
3151           (Quads are available only if your system supports 64-bit
3152            integer values _and_ if Perl has been compiled to support those.
3153            Causes a fatal error otherwise.)
3154
3155     f   A single-precision float in the native format.
3156     d   A double-precision float in the native format.
3157
3158     p   A pointer to a null-terminated string.
3159     P   A pointer to a structure (fixed-length string).
3160
3161     u   A uuencoded string.
3162     U   A Unicode character number.  Encodes to UTF-8 internally
3163         (or UTF-EBCDIC in EBCDIC platforms).
3164
3165     w   A BER compressed integer.  Its bytes represent an unsigned
3166         integer in base 128, most significant digit first, with as
3167         few digits as possible.  Bit eight (the high bit) is set
3168         on each byte except the last.
3169
3170     x   A null byte.
3171     X   Back up a byte.
3172     @   Null fill to absolute position.
3173
3174 The following rules apply:
3175
3176 =over 8
3177
3178 =item *
3179
3180 Each letter may optionally be followed by a number giving a repeat
3181 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3182 C<H>, and C<P> the pack function will gobble up that many values from
3183 the LIST.  A C<*> for the repeat count means to use however many items are
3184 left, except for C<@>, C<x>, C<X>, where it is equivalent
3185 to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the
3186 same).
3187
3188 When used with C<Z>, C<*> results in the addition of a trailing null
3189 byte (so the packed result will be one longer than the byte C<length>
3190 of the item).
3191
3192 The repeat count for C<u> is interpreted as the maximal number of bytes
3193 to encode per line of output, with 0 and 1 replaced by 45.
3194
3195 =item *
3196
3197 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3198 string of length count, padding with nulls or spaces as necessary.  When
3199 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3200 after the first null, and C<a> returns data verbatim.  When packing,
3201 C<a>, and C<Z> are equivalent.
3202
3203 If the value-to-pack is too long, it is truncated.  If too long and an
3204 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3205 by a null byte.  Thus C<Z> always packs a trailing null byte under
3206 all circumstances.
3207
3208 =item *
3209
3210 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3211 Each byte of the input field of pack() generates 1 bit of the result.
3212 Each result bit is based on the least-significant bit of the corresponding
3213 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3214 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3215
3216 Starting from the beginning of the input string of pack(), each 8-tuple
3217 of bytes is converted to 1 byte of output.  With format C<b>
3218 the first byte of the 8-tuple determines the least-significant bit of a
3219 byte, and with format C<B> it determines the most-significant bit of
3220 a byte.
3221
3222 If the length of the input string is not exactly divisible by 8, the
3223 remainder is packed as if the input string were padded by null bytes
3224 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3225
3226 If the input string of pack() is longer than needed, extra bytes are ignored.
3227 A C<*> for the repeat count of pack() means to use all the bytes of
3228 the input field.  On unpack()ing the bits are converted to a string
3229 of C<"0">s and C<"1">s.
3230
3231 =item *
3232
3233 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3234 representable as hexadecimal digits, 0-9a-f) long.
3235
3236 Each byte of the input field of pack() generates 4 bits of the result.
3237 For non-alphabetical bytes the result is based on the 4 least-significant
3238 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3239 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3240 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3241 is compatible with the usual hexadecimal digits, so that C<"a"> and
3242 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3243 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3244
3245 Starting from the beginning of the input string of pack(), each pair
3246 of bytes is converted to 1 byte of output.  With format C<h> the
3247 first byte of the pair determines the least-significant nybble of the
3248 output byte, and with format C<H> it determines the most-significant
3249 nybble.
3250
3251 If the length of the input string is not even, it behaves as if padded
3252 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3253 nybbles are ignored.
3254
3255 If the input string of pack() is longer than needed, extra bytes are ignored.
3256 A C<*> for the repeat count of pack() means to use all the bytes of
3257 the input field.  On unpack()ing the bits are converted to a string
3258 of hexadecimal digits.
3259
3260 =item *
3261
3262 The C<p> type packs a pointer to a null-terminated string.  You are
3263 responsible for ensuring the string is not a temporary value (which can
3264 potentially get deallocated before you get around to using the packed result).
3265 The C<P> type packs a pointer to a structure of the size indicated by the
3266 length.  A NULL pointer is created if the corresponding value for C<p> or
3267 C<P> is C<undef>, similarly for unpack().
3268
3269 =item *
3270
3271 The C</> template character allows packing and unpacking of strings where
3272 the packed structure contains a byte count followed by the string itself.
3273 You write I<length-item>C</>I<string-item>.
3274
3275 The I<length-item> can be any C<pack> template letter,
3276 and describes how the length value is packed.
3277 The ones likely to be of most use are integer-packing ones like
3278 C<n> (for Java strings), C<w> (for ASN.1 or SNMP)
3279 and C<N> (for Sun XDR).
3280
3281 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3282 For C<unpack> the length of the string is obtained from the I<length-item>,
3283 but if you put in the '*' it will be ignored.
3284
3285     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3286     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3287     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3288
3289 The I<length-item> is not returned explicitly from C<unpack>.
3290
3291 Adding a count to the I<length-item> letter is unlikely to do anything
3292 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3293 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3294 which Perl does not regard as legal in numeric strings.
3295
3296 =item *
3297
3298 The integer types C<s>, C<S>, C<l>, and C<L> may be
3299 immediately followed by a C<!> suffix to signify native shorts or
3300 longs--as you can see from above for example a bare C<l> does mean
3301 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3302 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3303 see whether using C<!> makes any difference by
3304
3305         print length(pack("s")), " ", length(pack("s!")), "\n";
3306         print length(pack("l")), " ", length(pack("l!")), "\n";
3307
3308 C<i!> and C<I!> also work but only because of completeness;
3309 they are identical to C<i> and C<I>.
3310
3311 The actual sizes (in bytes) of native shorts, ints, longs, and long
3312 longs on the platform where Perl was built are also available via
3313 L<Config>:
3314
3315        use Config;
3316        print $Config{shortsize},    "\n";
3317        print $Config{intsize},      "\n";
3318        print $Config{longsize},     "\n";
3319        print $Config{longlongsize}, "\n";
3320
3321 (The C<$Config{longlongsize}> will be undefine if your system does
3322 not support long longs.)
3323
3324 =item *
3325
3326 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L>
3327 are inherently non-portable between processors and operating systems
3328 because they obey the native byteorder and endianness.  For example a
3329 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3330 (arranged in and handled by the CPU registers) into bytes as
3331
3332         0x12 0x34 0x56 0x78     # big-endian
3333         0x78 0x56 0x34 0x12     # little-endian
3334
3335 Basically, the Intel and VAX CPUs are little-endian, while everybody
3336 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3337 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3338 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3339 mode.
3340
3341 The names `big-endian' and `little-endian' are comic references to
3342 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3343 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3344 the egg-eating habits of the Lilliputians.
3345
3346 Some systems may have even weirder byte orders such as
3347
3348         0x56 0x78 0x12 0x34
3349         0x34 0x12 0x78 0x56
3350
3351 You can see your system's preference with
3352
3353         print join(" ", map { sprintf "%#02x", $_ }
3354                             unpack("C*",pack("L",0x12345678))), "\n";
3355
3356 The byteorder on the platform where Perl was built is also available
3357 via L<Config>:
3358
3359         use Config;
3360         print $Config{byteorder}, "\n";
3361
3362 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3363 and C<'87654321'> are big-endian.
3364
3365 If you want portable packed integers use the formats C<n>, C<N>,
3366 C<v>, and C<V>, their byte endianness and size are known.
3367 See also L<perlport>.
3368
3369 =item *
3370
3371 Real numbers (floats and doubles) are in the native machine format only;
3372 due to the multiplicity of floating formats around, and the lack of a
3373 standard "network" representation, no facility for interchange has been
3374 made.  This means that packed floating point data written on one machine
3375 may not be readable on another - even if both use IEEE floating point
3376 arithmetic (as the endian-ness of the memory representation is not part
3377 of the IEEE spec).  See also L<perlport>.
3378
3379 Note that Perl uses doubles internally for all numeric calculation, and
3380 converting from double into float and thence back to double again will
3381 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3382 equal $foo).
3383
3384 =item *
3385
3386 If the pattern begins with a C<U>, the resulting string will be treated
3387 as Unicode-encoded. You can force UTF8 encoding on in a string with an
3388 initial C<U0>, and the bytes that follow will be interpreted as Unicode
3389 characters. If you don't want this to happen, you can begin your pattern
3390 with C<C0> (or anything else) to force Perl not to UTF8 encode your
3391 string, and then follow this with a C<U*> somewhere in your pattern.
3392
3393 =item *
3394
3395 You must yourself do any alignment or padding by inserting for example
3396 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3397 could know where the bytes are going to or coming from.  Therefore
3398 C<pack> (and C<unpack>) handle their output and input as flat
3399 sequences of bytes.
3400
3401 =item *
3402
3403 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3404
3405 =item *
3406
3407 If TEMPLATE requires more arguments to pack() than actually given, pack()
3408 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3409 to pack() than actually given, extra arguments are ignored.
3410
3411 =back
3412
3413 Examples:
3414
3415     $foo = pack("CCCC",65,66,67,68);
3416     # foo eq "ABCD"
3417     $foo = pack("C4",65,66,67,68);
3418     # same thing
3419     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3420     # same thing with Unicode circled letters
3421
3422     $foo = pack("ccxxcc",65,66,67,68);
3423     # foo eq "AB\0\0CD"
3424
3425     # note: the above examples featuring "C" and "c" are true
3426     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3427     # and UTF-8.  In EBCDIC the first example would be
3428     # $foo = pack("CCCC",193,194,195,196);
3429
3430     $foo = pack("s2",1,2);
3431     # "\1\0\2\0" on little-endian
3432     # "\0\1\0\2" on big-endian
3433
3434     $foo = pack("a4","abcd","x","y","z");
3435     # "abcd"
3436
3437     $foo = pack("aaaa","abcd","x","y","z");
3438     # "axyz"
3439
3440     $foo = pack("a14","abcdefg");
3441     # "abcdefg\0\0\0\0\0\0\0"
3442
3443     $foo = pack("i9pl", gmtime);
3444     # a real struct tm (on my system anyway)
3445
3446     $utmp_template = "Z8 Z8 Z16 L";
3447     $utmp = pack($utmp_template, @utmp1);
3448     # a struct utmp (BSDish)
3449
3450     @utmp2 = unpack($utmp_template, $utmp);
3451     # "@utmp1" eq "@utmp2"
3452
3453     sub bintodec {
3454         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3455     }
3456
3457     $foo = pack('sx2l', 12, 34);
3458     # short 12, two zero bytes padding, long 34
3459     $bar = pack('s@4l', 12, 34);
3460     # short 12, zero fill to position 4, long 34
3461     # $foo eq $bar
3462
3463 The same template may generally also be used in unpack().
3464
3465 =item package NAMESPACE
3466
3467 =item package
3468
3469 Declares the compilation unit as being in the given namespace.  The scope
3470 of the package declaration is from the declaration itself through the end
3471 of the enclosing block, file, or eval (the same as the C<my> operator).
3472 All further unqualified dynamic identifiers will be in this namespace.
3473 A package statement affects only dynamic variables--including those
3474 you've used C<local> on--but I<not> lexical variables, which are created
3475 with C<my>.  Typically it would be the first declaration in a file to
3476 be included by the C<require> or C<use> operator.  You can switch into a
3477 package in more than one place; it merely influences which symbol table
3478 is used by the compiler for the rest of that block.  You can refer to
3479 variables and filehandles in other packages by prefixing the identifier
3480 with the package name and a double colon:  C<$Package::Variable>.
3481 If the package name is null, the C<main> package as assumed.  That is,
3482 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3483 still seen in older code).
3484
3485 If NAMESPACE is omitted, then there is no current package, and all
3486 identifiers must be fully qualified or lexicals.  However, you are
3487 strongly advised not to make use of this feature. Its use can cause
3488 unexpected behaviour, even crashing some versions of Perl. It is
3489 deprecated, and will be removed from a future release.
3490
3491 See L<perlmod/"Packages"> for more information about packages, modules,
3492 and classes.  See L<perlsub> for other scoping issues.
3493
3494 =item pipe READHANDLE,WRITEHANDLE
3495
3496 Opens a pair of connected pipes like the corresponding system call.
3497 Note that if you set up a loop of piped processes, deadlock can occur
3498 unless you are very careful.  In addition, note that Perl's pipes use
3499 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3500 after each command, depending on the application.
3501
3502 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3503 for examples of such things.
3504
3505 On systems that support a close-on-exec flag on files, the flag will be set
3506 for the newly opened file descriptors as determined by the value of $^F.
3507 See L<perlvar/$^F>.
3508
3509 =item pop ARRAY
3510
3511 =item pop
3512
3513 Pops and returns the last value of the array, shortening the array by
3514 one element.  Has an effect similar to
3515
3516     $ARRAY[$#ARRAY--]
3517
3518 If there are no elements in the array, returns the undefined value
3519 (although this may happen at other times as well).  If ARRAY is
3520 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3521 array in subroutines, just like C<shift>.
3522
3523 =item pos SCALAR
3524
3525 =item pos
3526
3527 Returns the offset of where the last C<m//g> search left off for the variable
3528 in question (C<$_> is used when the variable is not specified).  May be
3529 modified to change that offset.  Such modification will also influence
3530 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3531 L<perlop>.
3532
3533 =item print FILEHANDLE LIST
3534
3535 =item print LIST
3536
3537 =item print
3538
3539 Prints a string or a list of strings.  Returns true if successful.
3540 FILEHANDLE may be a scalar variable name, in which case the variable
3541 contains the name of or a reference to the filehandle, thus introducing
3542 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3543 the next token is a term, it may be misinterpreted as an operator
3544 unless you interpose a C<+> or put parentheses around the arguments.)
3545 If FILEHANDLE is omitted, prints by default to standard output (or
3546 to the last selected output channel--see L</select>).  If LIST is
3547 also omitted, prints C<$_> to the currently selected output channel.
3548 To set the default output channel to something other than STDOUT
3549 use the select operation.  The current value of C<$,> (if any) is
3550 printed between each LIST item.  The current value of C<$\> (if
3551 any) is printed after the entire LIST has been printed.  Because
3552 print takes a LIST, anything in the LIST is evaluated in list
3553 context, and any subroutine that you call will have one or more of
3554 its expressions evaluated in list context.  Also be careful not to
3555 follow the print keyword with a left parenthesis unless you want
3556 the corresponding right parenthesis to terminate the arguments to
3557 the print--interpose a C<+> or put parentheses around all the
3558 arguments.
3559
3560 Note that if you're storing FILEHANDLES in an array or other expression,
3561 you will have to use a block returning its value instead:
3562
3563     print { $files[$i] } "stuff\n";
3564     print { $OK ? STDOUT : STDERR } "stuff\n";
3565
3566 =item printf FILEHANDLE FORMAT, LIST
3567
3568 =item printf FORMAT, LIST
3569
3570 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3571 (the output record separator) is not appended.  The first argument
3572 of the list will be interpreted as the C<printf> format. See C<sprintf>
3573 for an explanation of the format argument. If C<use locale> is in effect,
3574 the character used for the decimal point in formatted real numbers is
3575 affected by the LC_NUMERIC locale.  See L<perllocale>.
3576
3577 Don't fall into the trap of using a C<printf> when a simple
3578 C<print> would do.  The C<print> is more efficient and less
3579 error prone.
3580
3581 =item prototype FUNCTION
3582
3583 Returns the prototype of a function as a string (or C<undef> if the
3584 function has no prototype).  FUNCTION is a reference to, or the name of,
3585 the function whose prototype you want to retrieve.
3586
3587 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3588 name for Perl builtin.  If the builtin is not I<overridable> (such as
3589 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3590 C<system>) returns C<undef> because the builtin does not really behave
3591 like a Perl function.  Otherwise, the string describing the equivalent
3592 prototype is returned.
3593
3594 =item push ARRAY,LIST
3595
3596 Treats ARRAY as a stack, and pushes the values of LIST
3597 onto the end of ARRAY.  The length of ARRAY increases by the length of
3598 LIST.  Has the same effect as
3599
3600     for $value (LIST) {
3601         $ARRAY[++$#ARRAY] = $value;
3602     }
3603
3604 but is more efficient.  Returns the new number of elements in the array.
3605
3606 =item q/STRING/
3607
3608 =item qq/STRING/
3609
3610 =item qr/STRING/
3611
3612 =item qx/STRING/
3613
3614 =item qw/STRING/
3615
3616 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3617
3618 =item quotemeta EXPR
3619
3620 =item quotemeta
3621
3622 Returns the value of EXPR with all non-"word"
3623 characters backslashed.  (That is, all characters not matching
3624 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3625 returned string, regardless of any locale settings.)
3626 This is the internal function implementing
3627 the C<\Q> escape in double-quoted strings.
3628
3629 If EXPR is omitted, uses C<$_>.
3630
3631 =item rand EXPR
3632
3633 =item rand
3634
3635 Returns a random fractional number greater than or equal to C<0> and less
3636 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3637 omitted, or a C<0>, the value C<1> is used.  Automatically calls C<srand>
3638 unless C<srand> has already been called.  See also C<srand>.
3639
3640 Apply C<int()> to the value returned by C<rand()> if you want random
3641 integers instead of random fractional numbers.  For example,
3642
3643     int(rand(10))
3644
3645 returns a random integer between C<0> and C<9>, inclusive.
3646
3647 (Note: If your rand function consistently returns numbers that are too
3648 large or too small, then your version of Perl was probably compiled
3649 with the wrong number of RANDBITS.)
3650
3651 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3652
3653 =item read FILEHANDLE,SCALAR,LENGTH
3654
3655 Attempts to read LENGTH I<characters> of data into variable SCALAR
3656 from the specified FILEHANDLE.  Returns the number of characters
3657 actually read, C<0> at end of file, or undef if there was an error.
3658 SCALAR will be grown or shrunk to the length actually read.  If SCALAR
3659 needs growing, the new bytes will be zero bytes.  An OFFSET may be
3660 specified to place the read data into some other place in SCALAR than
3661 the beginning.  The call is actually implemented in terms of either
3662 Perl's or system's fread() call.  To get a true read(2) system call,
3663 see C<sysread>.
3664
3665 Note the I<characters>: depending on the status of the filehandle,
3666 either (8-bit) bytes or characters are read.  By default all
3667 filehandles operate on bytes, but for example if the filehandle has
3668 been opened with the C<:utf8> discipline (see L</open>, and the C<open>
3669 pragma, L<open>), the I/O will operate on characters, not bytes.
3670
3671 =item readdir DIRHANDLE
3672
3673 Returns the next directory entry for a directory opened by C<opendir>.
3674 If used in list context, returns all the rest of the entries in the
3675 directory.  If there are no more entries, returns an undefined value in
3676 scalar context or a null list in list context.
3677
3678 If you're planning to filetest the return values out of a C<readdir>, you'd
3679 better prepend the directory in question.  Otherwise, because we didn't
3680 C<chdir> there, it would have been testing the wrong file.
3681
3682     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3683     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3684     closedir DIR;
3685
3686 =item readline EXPR
3687
3688 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3689 context, each call reads and returns the next line, until end-of-file is
3690 reached, whereupon the subsequent call returns undef.  In list context,
3691 reads until end-of-file is reached and returns a list of lines.  Note that
3692 the notion of "line" used here is however you may have defined it
3693 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3694
3695 When C<$/> is set to C<undef>, when readline() is in scalar
3696 context (i.e. file slurp mode), and when an empty file is read, it
3697 returns C<''> the first time, followed by C<undef> subsequently.
3698
3699 This is the internal function implementing the C<< <EXPR> >>
3700 operator, but you can use it directly.  The C<< <EXPR> >>
3701 operator is discussed in more detail in L<perlop/"I/O Operators">.
3702
3703     $line = <STDIN>;
3704     $line = readline(*STDIN);           # same thing
3705
3706 =item readlink EXPR
3707
3708 =item readlink
3709
3710 Returns the value of a symbolic link, if symbolic links are
3711 implemented.  If not, gives a fatal error.  If there is some system
3712 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3713 omitted, uses C<$_>.
3714
3715 =item readpipe EXPR
3716
3717 EXPR is executed as a system command.
3718 The collected standard output of the command is returned.
3719 In scalar context, it comes back as a single (potentially
3720 multi-line) string.  In list context, returns a list of lines
3721 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3722 This is the internal function implementing the C<qx/EXPR/>
3723 operator, but you can use it directly.  The C<qx/EXPR/>
3724 operator is discussed in more detail in L<perlop/"I/O Operators">.
3725
3726 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3727
3728 Receives a message on a socket.  Attempts to receive LENGTH characters
3729 of data into variable SCALAR from the specified SOCKET filehandle.
3730 SCALAR will be grown or shrunk to the length actually read.  Takes the
3731 same flags as the system call of the same name.  Returns the address
3732 of the sender if SOCKET's protocol supports this; returns an empty
3733 string otherwise.  If there's an error, returns the undefined value.
3734 This call is actually implemented in terms of recvfrom(2) system call.
3735 See L<perlipc/"UDP: Message Passing"> for examples.
3736
3737 Note the I<characters>: depending on the status of the socket, either
3738 (8-bit) bytes or characters are received.  By default all sockets
3739 operate on bytes, but for example if the socket has been changed using
3740 binmode() to operate with the C<:utf8> discipline (see the C<open>
3741 pragma, L<open>), the I/O will operate on characters, not bytes.
3742
3743 =item redo LABEL
3744
3745 =item redo
3746
3747 The C<redo> command restarts the loop block without evaluating the
3748 conditional again.  The C<continue> block, if any, is not executed.  If
3749 the LABEL is omitted, the command refers to the innermost enclosing
3750 loop.  This command is normally used by programs that want to lie to
3751 themselves about what was just input:
3752
3753     # a simpleminded Pascal comment stripper
3754     # (warning: assumes no { or } in strings)
3755     LINE: while (<STDIN>) {
3756         while (s|({.*}.*){.*}|$1 |) {}
3757         s|{.*}| |;
3758         if (s|{.*| |) {
3759             $front = $_;
3760             while (<STDIN>) {
3761                 if (/}/) {      # end of comment?
3762                     s|^|$front\{|;
3763                     redo LINE;
3764                 }
3765             }
3766         }
3767         print;
3768     }
3769
3770 C<redo> cannot be used to retry a block which returns a value such as
3771 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3772 a grep() or map() operation.
3773
3774 Note that a block by itself is semantically identical to a loop
3775 that executes once.  Thus C<redo> inside such a block will effectively
3776 turn it into a looping construct.
3777
3778 See also L</continue> for an illustration of how C<last>, C<next>, and
3779 C<redo> work.
3780
3781 =item ref EXPR
3782
3783 =item ref
3784
3785 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3786 is not specified, C<$_> will be used.  The value returned depends on the
3787 type of thing the reference is a reference to.
3788 Builtin types include:
3789
3790     SCALAR
3791     ARRAY
3792     HASH
3793     CODE
3794     REF
3795     GLOB
3796     LVALUE
3797
3798 If the referenced object has been blessed into a package, then that package
3799 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3800
3801     if (ref($r) eq "HASH") {
3802         print "r is a reference to a hash.\n";
3803     }
3804     unless (ref($r)) {
3805         print "r is not a reference at all.\n";
3806     }
3807     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3808         print "r is a reference to something that isa hash.\n";
3809     }
3810
3811 See also L<perlref>.
3812
3813 =item rename OLDNAME,NEWNAME
3814
3815 Changes the name of a file; an existing file NEWNAME will be
3816 clobbered.  Returns true for success, false otherwise.
3817
3818 Behavior of this function varies wildly depending on your system
3819 implementation.  For example, it will usually not work across file system
3820 boundaries, even though the system I<mv> command sometimes compensates
3821 for this.  Other restrictions include whether it works on directories,
3822 open files, or pre-existing files.  Check L<perlport> and either the
3823 rename(2) manpage or equivalent system documentation for details.
3824
3825 =item require VERSION
3826
3827 =item require EXPR
3828
3829 =item require
3830
3831 Demands a version of Perl specified by VERSION, or demands some semantics
3832 specified by EXPR or by C<$_> if EXPR is not supplied.
3833
3834 VERSION may be either a numeric argument such as 5.006, which will be
3835 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
3836 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
3837 VERSION is greater than the version of the current Perl interpreter.
3838 Compare with L</use>, which can do a similar check at compile time.
3839
3840 Specifying VERSION as a literal of the form v5.6.1 should generally be
3841 avoided, because it leads to misleading error messages under earlier
3842 versions of Perl which do not support this syntax.  The equivalent numeric
3843 version should be used instead.
3844
3845     require v5.6.1;     # run time version check
3846     require 5.6.1;      # ditto
3847     require 5.006_001;  # ditto; preferred for backwards compatibility
3848
3849 Otherwise, demands that a library file be included if it hasn't already
3850 been included.  The file is included via the do-FILE mechanism, which is
3851 essentially just a variety of C<eval>.  Has semantics similar to the following
3852 subroutine:
3853
3854     sub require {
3855         my($filename) = @_;
3856         return 1 if $INC{$filename};
3857         my($realfilename,$result);
3858         ITER: {
3859             foreach $prefix (@INC) {
3860                 $realfilename = "$prefix/$filename";
3861                 if (-f $realfilename) {
3862                     $INC{$filename} = $realfilename;
3863                     $result = do $realfilename;
3864                     last ITER;
3865                 }
3866             }
3867             die "Can't find $filename in \@INC";
3868         }
3869         delete $INC{$filename} if $@ || !$result;
3870         die $@ if $@;
3871         die "$filename did not return true value" unless $result;
3872         return $result;
3873     }
3874
3875 Note that the file will not be included twice under the same specified
3876 name.  The file must return true as the last statement to indicate
3877 successful execution of any initialization code, so it's customary to
3878 end such a file with C<1;> unless you're sure it'll return true
3879 otherwise.  But it's better just to put the C<1;>, in case you add more
3880 statements.
3881
3882 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3883 replaces "F<::>" with "F</>" in the filename for you,
3884 to make it easy to load standard modules.  This form of loading of
3885 modules does not risk altering your namespace.
3886
3887 In other words, if you try this:
3888
3889         require Foo::Bar;    # a splendid bareword
3890
3891 The require function will actually look for the "F<Foo/Bar.pm>" file in the
3892 directories specified in the C<@INC> array.
3893
3894 But if you try this:
3895
3896         $class = 'Foo::Bar';
3897         require $class;      # $class is not a bareword
3898     #or
3899         require "Foo::Bar";  # not a bareword because of the ""
3900
3901 The require function will look for the "F<Foo::Bar>" file in the @INC array and
3902 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3903
3904         eval "require $class";
3905
3906 You can also insert hooks into the import facility, by putting directly
3907 Perl code into the @INC array.  There are three forms of hooks: subroutine
3908 references, array references and blessed objects.
3909
3910 Subroutine references are the simplest case.  When the inclusion system
3911 walks through @INC and encounters a subroutine, this subroutine gets
3912 called with two parameters, the first being a reference to itself, and the
3913 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
3914 subroutine should return C<undef> or a filehandle, from which the file to
3915 include will be read.  If C<undef> is returned, C<require> will look at
3916 the remaining elements of @INC.
3917
3918 If the hook is an array reference, its first element must be a subroutine
3919 reference.  This subroutine is called as above, but the first parameter is
3920 the array reference.  This enables to pass indirectly some arguments to
3921 the subroutine.
3922
3923 In other words, you can write:
3924
3925     push @INC, \&my_sub;
3926     sub my_sub {
3927         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
3928         ...
3929     }
3930
3931 or:
3932
3933     push @INC, [ \&my_sub, $x, $y, ... ];
3934     sub my_sub {
3935         my ($arrayref, $filename) = @_;
3936         # Retrieve $x, $y, ...
3937         my @parameters = @$arrayref[1..$#$arrayref];
3938         ...
3939     }
3940
3941 If the hook is an object, it must provide an INC method, that will be
3942 called as above, the first parameter being the object itself.  (Note that
3943 you must fully qualify the sub's name, as it is always forced into package
3944 C<main>.)  Here is a typical code layout:
3945
3946     # In Foo.pm
3947     package Foo;
3948     sub new { ... }
3949     sub Foo::INC {
3950         my ($self, $filename) = @_;
3951         ...
3952     }
3953
3954     # In the main program
3955     push @INC, new Foo(...);
3956
3957 Note that these hooks are also permitted to set the %INC entry
3958 corresponding to the files they have loaded. See L<perlvar/%INC>.
3959
3960 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3961
3962 =item reset EXPR
3963
3964 =item reset
3965
3966 Generally used in a C<continue> block at the end of a loop to clear
3967 variables and reset C<??> searches so that they work again.  The
3968 expression is interpreted as a list of single characters (hyphens
3969 allowed for ranges).  All variables and arrays beginning with one of
3970 those letters are reset to their pristine state.  If the expression is
3971 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3972 only variables or searches in the current package.  Always returns
3973 1.  Examples:
3974
3975     reset 'X';          # reset all X variables
3976     reset 'a-z';        # reset lower case variables
3977     reset;              # just reset ?one-time? searches
3978
3979 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3980 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3981 variables--lexical variables are unaffected, but they clean themselves
3982 up on scope exit anyway, so you'll probably want to use them instead.
3983 See L</my>.
3984
3985 =item return EXPR
3986
3987 =item return
3988
3989 Returns from a subroutine, C<eval>, or C<do FILE> with the value
3990 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3991 context, depending on how the return value will be used, and the context
3992 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3993 is given, returns an empty list in list context, the undefined value in
3994 scalar context, and (of course) nothing at all in a void context.
3995
3996 (Note that in the absence of an explicit C<return>, a subroutine, eval,
3997 or do FILE will automatically return the value of the last expression
3998 evaluated.)
3999
4000 =item reverse LIST
4001
4002 In list context, returns a list value consisting of the elements
4003 of LIST in the opposite order.  In scalar context, concatenates the
4004 elements of LIST and returns a string value with all characters
4005 in the opposite order.
4006
4007     print reverse <>;           # line tac, last line first
4008
4009     undef $/;                   # for efficiency of <>
4010     print scalar reverse <>;    # character tac, last line tsrif
4011
4012 This operator is also handy for inverting a hash, although there are some
4013 caveats.  If a value is duplicated in the original hash, only one of those
4014 can be represented as a key in the inverted hash.  Also, this has to
4015 unwind one hash and build a whole new one, which may take some time
4016 on a large hash, such as from a DBM file.
4017
4018     %by_name = reverse %by_address;     # Invert the hash
4019
4020 =item rewinddir DIRHANDLE
4021
4022 Sets the current position to the beginning of the directory for the
4023 C<readdir> routine on DIRHANDLE.
4024
4025 =item rindex STR,SUBSTR,POSITION
4026
4027 =item rindex STR,SUBSTR
4028
4029 Works just like index() except that it returns the position of the LAST
4030 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4031 last occurrence at or before that position.
4032
4033 =item rmdir FILENAME
4034
4035 =item rmdir
4036
4037 Deletes the directory specified by FILENAME if that directory is empty.  If it
4038 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
4039 FILENAME is omitted, uses C<$_>.
4040
4041 =item s///
4042
4043 The substitution operator.  See L<perlop>.
4044
4045 =item scalar EXPR
4046
4047 Forces EXPR to be interpreted in scalar context and returns the value
4048 of EXPR.
4049
4050     @counts = ( scalar @a, scalar @b, scalar @c );
4051
4052 There is no equivalent operator to force an expression to
4053 be interpolated in list context because in practice, this is never
4054 needed.  If you really wanted to do so, however, you could use
4055 the construction C<@{[ (some expression) ]}>, but usually a simple
4056 C<(some expression)> suffices.
4057
4058 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4059 parenthesized list, this behaves as a scalar comma expression, evaluating
4060 all but the last element in void context and returning the final element
4061 evaluated in scalar context.  This is seldom what you want.
4062
4063 The following single statement:
4064
4065         print uc(scalar(&foo,$bar)),$baz;
4066
4067 is the moral equivalent of these two:
4068
4069         &foo;
4070         print(uc($bar),$baz);
4071
4072 See L<perlop> for more details on unary operators and the comma operator.
4073
4074 =item seek FILEHANDLE,POSITION,WHENCE
4075
4076 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4077 FILEHANDLE may be an expression whose value gives the name of the
4078 filehandle.  The values for WHENCE are C<0> to set the new position
4079 I<in bytes> to POSITION, C<1> to set it to the current position plus
4080 POSITION, and C<2> to set it to EOF plus POSITION (typically
4081 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4082 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4083 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4084 otherwise.
4085
4086 Note the I<in bytes>: even if the filehandle has been set to
4087 operate on characters (for example by using the C<:utf8> open
4088 discipline), tell() will return byte offsets, not character offsets
4089 (because implementing that would render seek() and tell() rather slow).
4090
4091 If you want to position file for C<sysread> or C<syswrite>, don't use
4092 C<seek>--buffering makes its effect on the file's system position
4093 unpredictable and non-portable.  Use C<sysseek> instead.
4094
4095 Due to the rules and rigors of ANSI C, on some systems you have to do a
4096 seek whenever you switch between reading and writing.  Amongst other
4097 things, this may have the effect of calling stdio's clearerr(3).
4098 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4099
4100     seek(TEST,0,1);
4101
4102 This is also useful for applications emulating C<tail -f>.  Once you hit
4103 EOF on your read, and then sleep for a while, you might have to stick in a
4104 seek() to reset things.  The C<seek> doesn't change the current position,
4105 but it I<does> clear the end-of-file condition on the handle, so that the
4106 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4107
4108 If that doesn't work (some IO implementations are particularly
4109 cantankerous), then you may need something more like this:
4110
4111     for (;;) {
4112         for ($curpos = tell(FILE); $_ = <FILE>;
4113              $curpos = tell(FILE)) {
4114             # search for some stuff and put it into files
4115         }
4116         sleep($for_a_while);
4117         seek(FILE, $curpos, 0);
4118     }
4119
4120 =item seekdir DIRHANDLE,POS
4121
4122 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4123 must be a value returned by C<telldir>.  Has the same caveats about
4124 possible directory compaction as the corresponding system library
4125 routine.
4126
4127 =item select FILEHANDLE
4128
4129 =item select
4130
4131 Returns the currently selected filehandle.  Sets the current default
4132 filehandle for output, if FILEHANDLE is supplied.  This has two
4133 effects: first, a C<write> or a C<print> without a filehandle will
4134 default to this FILEHANDLE.  Second, references to variables related to
4135 output will refer to this output channel.  For example, if you have to
4136 set the top of form format for more than one output channel, you might
4137 do the following:
4138
4139     select(REPORT1);
4140     $^ = 'report1_top';
4141     select(REPORT2);
4142     $^ = 'report2_top';
4143
4144 FILEHANDLE may be an expression whose value gives the name of the
4145 actual filehandle.  Thus:
4146
4147     $oldfh = select(STDERR); $| = 1; select($oldfh);
4148
4149 Some programmers may prefer to think of filehandles as objects with
4150 methods, preferring to write the last example as:
4151
4152     use IO::Handle;
4153     STDERR->autoflush(1);
4154
4155 =item select RBITS,WBITS,EBITS,TIMEOUT
4156
4157 This calls the select(2) system call with the bit masks specified, which
4158 can be constructed using C<fileno> and C<vec>, along these lines:
4159
4160     $rin = $win = $ein = '';
4161     vec($rin,fileno(STDIN),1) = 1;
4162     vec($win,fileno(STDOUT),1) = 1;
4163     $ein = $rin | $win;
4164
4165 If you want to select on many filehandles you might wish to write a
4166 subroutine:
4167
4168     sub fhbits {
4169         my(@fhlist) = split(' ',$_[0]);
4170         my($bits);
4171         for (@fhlist) {
4172             vec($bits,fileno($_),1) = 1;
4173         }
4174         $bits;
4175     }
4176     $rin = fhbits('STDIN TTY SOCK');
4177
4178 The usual idiom is:
4179
4180     ($nfound,$timeleft) =
4181       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4182
4183 or to block until something becomes ready just do this
4184
4185     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4186
4187 Most systems do not bother to return anything useful in $timeleft, so
4188 calling select() in scalar context just returns $nfound.
4189
4190 Any of the bit masks can also be undef.  The timeout, if specified, is
4191 in seconds, which may be fractional.  Note: not all implementations are
4192 capable of returning the $timeleft.  If not, they always return
4193 $timeleft equal to the supplied $timeout.
4194
4195 You can effect a sleep of 250 milliseconds this way:
4196
4197     select(undef, undef, undef, 0.25);
4198
4199 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4200 or <FH>) with C<select>, except as permitted by POSIX, and even
4201 then only on POSIX systems.  You have to use C<sysread> instead.
4202
4203 =item semctl ID,SEMNUM,CMD,ARG
4204
4205 Calls the System V IPC function C<semctl>.  You'll probably have to say
4206
4207     use IPC::SysV;
4208
4209 first to get the correct constant definitions.  If CMD is IPC_STAT or
4210 GETALL, then ARG must be a variable which will hold the returned
4211 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4212 the undefined value for error, "C<0 but true>" for zero, or the actual
4213 return value otherwise.  The ARG must consist of a vector of native
4214 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4215 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4216 documentation.
4217
4218 =item semget KEY,NSEMS,FLAGS
4219
4220 Calls the System V IPC function semget.  Returns the semaphore id, or
4221 the undefined value if there is an error.  See also
4222 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4223 documentation.
4224
4225 =item semop KEY,OPSTRING
4226
4227 Calls the System V IPC function semop to perform semaphore operations
4228 such as signalling and waiting.  OPSTRING must be a packed array of
4229 semop structures.  Each semop structure can be generated with
4230 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4231 operations is implied by the length of OPSTRING.  Returns true if
4232 successful, or false if there is an error.  As an example, the
4233 following code waits on semaphore $semnum of semaphore id $semid:
4234
4235     $semop = pack("s!3", $semnum, -1, 0);
4236     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4237
4238 To signal the semaphore, replace C<-1> with C<1>.  See also
4239 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4240 documentation.
4241
4242 =item send SOCKET,MSG,FLAGS,TO
4243
4244 =item send SOCKET,MSG,FLAGS
4245
4246 Sends a message on a socket.  Attempts to send the scalar MSG to the
4247 SOCKET filehandle.  Takes the same flags as the system call of the
4248 same name.  On unconnected sockets you must specify a destination to
4249 send TO, in which case it does a C C<sendto>.  Returns the number of
4250 characters sent, or the undefined value if there is an error.  The C
4251 system call sendmsg(2) is currently unimplemented.  See
4252 L<perlipc/"UDP: Message Passing"> for examples.
4253
4254 Note the I<characters>: depending on the status of the socket, either
4255 (8-bit) bytes or characters are sent.  By default all sockets operate
4256 on bytes, but for example if the socket has been changed using
4257 binmode() to operate with the C<:utf8> discipline (see L</open>, or
4258 the C<open> pragma, L<open>), the I/O will operate on characters, not
4259 bytes.
4260
4261 =item setpgrp PID,PGRP
4262
4263 Sets the current process group for the specified PID, C<0> for the current
4264 process.  Will produce a fatal error if used on a machine that doesn't
4265 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4266 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4267 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4268 C<POSIX::setsid()>.
4269
4270 =item setpriority WHICH,WHO,PRIORITY
4271
4272 Sets the current priority for a process, a process group, or a user.
4273 (See setpriority(2).)  Will produce a fatal error if used on a machine
4274 that doesn't implement setpriority(2).
4275
4276 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4277
4278 Sets the socket option requested.  Returns undefined if there is an
4279 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4280 argument.
4281
4282 =item shift ARRAY
4283
4284 =item shift
4285
4286 Shifts the first value of the array off and returns it, shortening the
4287 array by 1 and moving everything down.  If there are no elements in the
4288 array, returns the undefined value.  If ARRAY is omitted, shifts the
4289 C<@_> array within the lexical scope of subroutines and formats, and the
4290 C<@ARGV> array at file scopes or within the lexical scopes established by
4291 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4292 constructs.
4293
4294 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4295 same thing to the left end of an array that C<pop> and C<push> do to the
4296 right end.
4297
4298 =item shmctl ID,CMD,ARG
4299
4300 Calls the System V IPC function shmctl.  You'll probably have to say
4301
4302     use IPC::SysV;
4303
4304 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4305 then ARG must be a variable which will hold the returned C<shmid_ds>
4306 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4307 true" for zero, or the actual return value otherwise.
4308 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4309
4310 =item shmget KEY,SIZE,FLAGS
4311
4312 Calls the System V IPC function shmget.  Returns the shared memory
4313 segment id, or the undefined value if there is an error.
4314 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4315
4316 =item shmread ID,VAR,POS,SIZE
4317
4318 =item shmwrite ID,STRING,POS,SIZE
4319
4320 Reads or writes the System V shared memory segment ID starting at
4321 position POS for size SIZE by attaching to it, copying in/out, and
4322 detaching from it.  When reading, VAR must be a variable that will
4323 hold the data read.  When writing, if STRING is too long, only SIZE
4324 bytes are used; if STRING is too short, nulls are written to fill out
4325 SIZE bytes.  Return true if successful, or false if there is an error.
4326 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4327 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4328
4329 =item shutdown SOCKET,HOW
4330
4331 Shuts down a socket connection in the manner indicated by HOW, which
4332 has the same interpretation as in the system call of the same name.
4333
4334     shutdown(SOCKET, 0);    # I/we have stopped reading data
4335     shutdown(SOCKET, 1);    # I/we have stopped writing data
4336     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4337
4338 This is useful with sockets when you want to tell the other
4339 side you're done writing but not done reading, or vice versa.
4340 It's also a more insistent form of close because it also
4341 disables the file descriptor in any forked copies in other
4342 processes.
4343
4344 =item sin EXPR
4345
4346 =item sin
4347
4348 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4349 returns sine of C<$_>.
4350
4351 For the inverse sine operation, you may use the C<Math::Trig::asin>
4352 function, or use this relation:
4353
4354     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4355
4356 =item sleep EXPR
4357
4358 =item sleep
4359
4360 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4361 May be interrupted if the process receives a signal such as C<SIGALRM>.
4362 Returns the number of seconds actually slept.  You probably cannot
4363 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4364 using C<alarm>.
4365
4366 On some older systems, it may sleep up to a full second less than what
4367 you requested, depending on how it counts seconds.  Most modern systems
4368 always sleep the full amount.  They may appear to sleep longer than that,
4369 however, because your process might not be scheduled right away in a
4370 busy multitasking system.
4371
4372 For delays of finer granularity than one second, you may use Perl's
4373 C<syscall> interface to access setitimer(2) if your system supports
4374 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4375 and starting from Perl 5.8 part of the standard distribution) may also
4376 help.
4377
4378 See also the POSIX module's C<pause> function.
4379
4380 =item sockatmark SOCKET
4381
4382 Returns true if the socket is positioned at the out-of-band mark
4383 (also known as the urgent data mark), false otherwise.  Use right
4384 after reading from the socket.
4385
4386 Not available directly, one has to import the function from
4387 the IO::Socket extension
4388
4389     use IO::Socket 'sockatmark';
4390
4391 Even this doesn't guarantee that sockatmark() really is available,
4392 though, because sockatmark() is a relatively recent addition to
4393 the family of socket functions.  If it is unavailable, attempt to
4394 use it will fail
4395
4396         IO::Socket::atmark not implemented on this architecture ...
4397
4398 See also L<IO::Socket>.
4399
4400 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4401
4402 Opens a socket of the specified kind and attaches it to filehandle
4403 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4404 the system call of the same name.  You should C<use Socket> first
4405 to get the proper definitions imported.  See the examples in
4406 L<perlipc/"Sockets: Client/Server Communication">.
4407
4408 On systems that support a close-on-exec flag on files, the flag will
4409 be set for the newly opened file descriptor, as determined by the
4410 value of $^F.  See L<perlvar/$^F>.
4411
4412 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4413
4414 Creates an unnamed pair of sockets in the specified domain, of the
4415 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4416 for the system call of the same name.  If unimplemented, yields a fatal
4417 error.  Returns true if successful.
4418
4419 On systems that support a close-on-exec flag on files, the flag will
4420 be set for the newly opened file descriptors, as determined by the value
4421 of $^F.  See L<perlvar/$^F>.
4422
4423 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4424 to C<pipe(Rdr, Wtr)> is essentially:
4425
4426     use Socket;
4427     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4428     shutdown(Rdr, 1);        # no more writing for reader
4429     shutdown(Wtr, 0);        # no more reading for writer
4430
4431 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
4432 emulate socketpair using IP sockets to localhost if your system implements
4433 sockets but not socketpair.
4434
4435 =item sort SUBNAME LIST
4436
4437 =item sort BLOCK LIST
4438
4439 =item sort LIST
4440
4441 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4442 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4443 specified, it gives the name of a subroutine that returns an integer
4444 less than, equal to, or greater than C<0>, depending on how the elements
4445 of the list are to be ordered.  (The C<< <=> >> and C<cmp>
4446 operators are extremely useful in such routines.)  SUBNAME may be a
4447 scalar variable name (unsubscripted), in which case the value provides
4448 the name of (or a reference to) the actual subroutine to use.  In place
4449 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4450 subroutine.
4451
4452 If the subroutine's prototype is C<($$)>, the elements to be compared
4453 are passed by reference in C<@_>, as for a normal subroutine.  This is
4454 slower than unprototyped subroutines, where the elements to be
4455 compared are passed into the subroutine
4456 as the package global variables $a and $b (see example below).  Note that
4457 in the latter case, it is usually counter-productive to declare $a and
4458 $b as lexicals.
4459
4460 In either case, the subroutine may not be recursive.  The values to be
4461 compared are always passed by reference, so don't modify them.
4462
4463 You also cannot exit out of the sort block or subroutine using any of the
4464 loop control operators described in L<perlsyn> or with C<goto>.
4465
4466 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4467 current collation locale.  See L<perllocale>.
4468
4469 Perl 5.6 and earlier used a quicksort algorithm to implement sort.
4470 That algorithm was not stable, and I<could> go quadratic.  (A I<stable> sort
4471 preserves the input order of elements that compare equal.  Although
4472 quicksort's run time is O(NlogN) when averaged over all arrays of
4473 length N, the time can be O(N**2), I<quadratic> behavior, for some
4474 inputs.)  In 5.7, the quicksort implementation was replaced with
4475 a stable mergesort algorithm whose worst case behavior is O(NlogN).
4476 But benchmarks indicated that for some inputs, on some platforms,
4477 the original quicksort was faster.  5.8 has a sort pragma for
4478 limited control of the sort.  Its rather blunt control of the
4479 underlying algorithm may not persist into future perls, but the
4480 ability to characterize the input or output in implementation
4481 independent ways quite probably will.  See L</use>.
4482
4483 Examples:
4484
4485     # sort lexically
4486     @articles = sort @files;
4487
4488     # same thing, but with explicit sort routine
4489     @articles = sort {$a cmp $b} @files;
4490
4491     # now case-insensitively
4492     @articles = sort {uc($a) cmp uc($b)} @files;
4493
4494     # same thing in reversed order
4495     @articles = sort {$b cmp $a} @files;
4496
4497     # sort numerically ascending
4498     @articles = sort {$a <=> $b} @files;
4499
4500     # sort numerically descending
4501     @articles = sort {$b <=> $a} @files;
4502
4503     # this sorts the %age hash by value instead of key
4504     # using an in-line function
4505     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4506
4507     # sort using explicit subroutine name
4508     sub byage {
4509         $age{$a} <=> $age{$b};  # presuming numeric
4510     }
4511     @sortedclass = sort byage @class;
4512
4513     sub backwards { $b cmp $a }
4514     @harry  = qw(dog cat x Cain Abel);
4515     @george = qw(gone chased yz Punished Axed);
4516     print sort @harry;
4517             # prints AbelCaincatdogx
4518     print sort backwards @harry;
4519             # prints xdogcatCainAbel
4520     print sort @george, 'to', @harry;
4521             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4522
4523     # inefficiently sort by descending numeric compare using
4524     # the first integer after the first = sign, or the
4525     # whole record case-insensitively otherwise
4526
4527     @new = sort {
4528         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4529                             ||
4530                     uc($a)  cmp  uc($b)
4531     } @old;
4532
4533     # same thing, but much more efficiently;
4534     # we'll build auxiliary indices instead
4535     # for speed
4536     @nums = @caps = ();
4537     for (@old) {
4538         push @nums, /=(\d+)/;
4539         push @caps, uc($_);
4540     }
4541
4542     @new = @old[ sort {
4543                         $nums[$b] <=> $nums[$a]
4544                                  ||
4545                         $caps[$a] cmp $caps[$b]
4546                        } 0..$#old
4547                ];
4548
4549     # same thing, but without any temps
4550     @new = map { $_->[0] }
4551            sort { $b->[1] <=> $a->[1]
4552                            ||
4553                   $a->[2] cmp $b->[2]
4554            } map { [$_, /=(\d+)/, uc($_)] } @old;
4555
4556     # using a prototype allows you to use any comparison subroutine
4557     # as a sort subroutine (including other package's subroutines)
4558     package other;
4559     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4560
4561     package main;
4562     @new = sort other::backwards @old;
4563
4564     # guarantee stability, regardless of algorithm
4565     use sort 'stable';
4566     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4567
4568     # force use of quicksort (not portable outside Perl 5.8)
4569     use sort '_quicksort';  # note discouraging _
4570     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4571
4572     # similar to the previous example, but demand stability as well
4573     use sort qw( _mergesort stable );
4574     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4575
4576 If you're using strict, you I<must not> declare $a
4577 and $b as lexicals.  They are package globals.  That means
4578 if you're in the C<main> package and type
4579
4580     @articles = sort {$b <=> $a} @files;
4581
4582 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4583 but if you're in the C<FooPack> package, it's the same as typing
4584
4585     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4586
4587 The comparison function is required to behave.  If it returns
4588 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4589 sometimes saying the opposite, for example) the results are not
4590 well-defined.
4591
4592 =item splice ARRAY,OFFSET,LENGTH,LIST
4593
4594 =item splice ARRAY,OFFSET,LENGTH
4595
4596 =item splice ARRAY,OFFSET
4597
4598 =item splice ARRAY
4599
4600 Removes the elements designated by OFFSET and LENGTH from an array, and
4601 replaces them with the elements of LIST, if any.  In list context,
4602 returns the elements removed from the array.  In scalar context,
4603 returns the last element removed, or C<undef> if no elements are
4604 removed.  The array grows or shrinks as necessary.
4605 If OFFSET is negative then it starts that far from the end of the array.
4606 If LENGTH is omitted, removes everything from OFFSET onward.
4607 If LENGTH is negative, leaves that many elements off the end of the array.
4608 If both OFFSET and LENGTH are omitted, removes everything.
4609
4610 The following equivalences hold (assuming C<$[ == 0>):
4611
4612     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4613     pop(@a)             splice(@a,-1)
4614     shift(@a)           splice(@a,0,1)
4615     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4616     $a[$x] = $y         splice(@a,$x,1,$y)
4617
4618 Example, assuming array lengths are passed before arrays:
4619
4620     sub aeq {   # compare two list values
4621         my(@a) = splice(@_,0,shift);
4622         my(@b) = splice(@_,0,shift);
4623         return 0 unless @a == @b;       # same len?
4624         while (@a) {
4625             return 0 if pop(@a) ne pop(@b);
4626         }
4627         return 1;
4628     }
4629     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4630
4631 =item split /PATTERN/,EXPR,LIMIT
4632
4633 =item split /PATTERN/,EXPR
4634
4635 =item split /PATTERN/
4636
4637 =item split
4638
4639 Splits a string into a list of strings and returns that list.  By default,
4640 empty leading fields are preserved, and empty trailing ones are deleted.
4641
4642 In scalar context, returns the number of fields found and splits into
4643 the C<@_> array.  Use of split in scalar context is deprecated, however,
4644 because it clobbers your subroutine arguments.
4645
4646 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4647 splits on whitespace (after skipping any leading whitespace).  Anything
4648 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4649 that the delimiter may be longer&