lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_05';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     @cmdfhs
 631     $CommandSet
 632     $CreateTTY
 633     $DBGR
 634     @dbline
 635     $dbline
 636     %dbline
 637     $dieLevel
 638     $filename
 639     $hist
 640     $histfile
 641     $histsize
 642     $IN
 643     $inhibit_exit
 644     @ini_INC
 645     $ini_warn
 646     $maxtrace
 647     $od
 648     $onetimedumpDepth
 649     @options
 650     $osingle
 651     $otrace
 652     $pager
 653     $post
 654     %postponed
 655     $prc
 656     $pre
 657     $pretype
 658     $psh
 659     @RememberOnROptions
 660     $remoteport
 661     @res
 662     $rl
 663     @saved
 664     $signalLevel
 665     $sub
 666     $term
 667     $usercontext
 668     $warnLevel
 669 );
 670
 671 our (
 672     $evalarg,
 673     $frame,
 674     $ImmediateStop,
 675     $line,
 676     $onetimeDump,
 677     %option,
 678     $OUT,
 679     $packname,
 680     $signal,
 681     $single,
 682     $start,
 683     %sub,
 684     $subname,
 685     $trace,
 686     $window,
 687 );
 688
 689 # Used to save @ARGV and extract any debugger-related flags.
 690 use vars qw(@ARGS);
 691
 692 # Used to prevent multiple entries to diesignal()
 693 # (if for instance diesignal() itself dies)
 694 use vars qw($panic);
 695
 696 # Used to prevent the debugger from running nonstop
 697 # after a restart
 698 our ($second_time);
 699
 700 sub _calc_usercontext {
 701     my ($package) = @_;
 702
 703     # Cancel strict completely for the evaluated code, so the code
 704     # the user evaluates won't be affected by it. (Shlomi Fish)
 705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 706     . "package $package;";    # this won't let them modify, alas
 707 }
 708
 709 sub eval {
 710
 711     # 'my' would make it visible from user code
 712     #    but so does local! --tchrist
 713     # Remember: this localizes @DB::res, not @main::res.
 714     local @res;
 715     {
 716
 717         # Try to keep the user code from messing  with us. Save these so that
 718         # even if the eval'ed code changes them, we can put them back again.
 719         # Needed because the user could refer directly to the debugger's
 720         # package globals (and any 'my' variables in this containing scope)
 721         # inside the eval(), and we want to try to stay safe.
 722         local $otrace  = $trace;
 723         local $osingle = $single;
 724         local $od      = $^D;
 725
 726         # Untaint the incoming eval() argument.
 727         { ($evalarg) = $evalarg =~ /(.*)/s; }
 728
 729         # $usercontext built in DB::DB near the comment
 730         # "set up the context for DB::eval ..."
 731         # Evaluate and save any results.
 732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 733
 734         # Restore those old values.
 735         $trace  = $otrace;
 736         $single = $osingle;
 737         $^D     = $od;
 738     }
 739
 740     # Save the current value of $@, and preserve it in the debugger's copy
 741     # of the saved precious globals.
 742     my $at = $@;
 743
 744     # Since we're only saving $@, we only have to localize the array element
 745     # that it will be stored in.
 746     local $saved[0];    # Preserve the old value of $@
 747     eval { DB::save() };
 748
 749     # Now see whether we need to report an error back to the user.
 750     if ($at) {
 751         local $\ = '';
 752         print $OUT $at;
 753     }
 754
 755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 756     # are package globals.
 757     elsif ($onetimeDump) {
 758         if ( $onetimeDump eq 'dump' ) {
 759             local $option{dumpDepth} = $onetimedumpDepth
 760               if defined $onetimedumpDepth;
 761             dumpit( $OUT, \@res );
 762         }
 763         elsif ( $onetimeDump eq 'methods' ) {
 764             methods( $res[0] );
 765         }
 766     } ## end elsif ($onetimeDump)
 767     @res;
 768 } ## end sub eval
 769
 770 ############################################## End lexical danger zone
 771
 772 # After this point it is safe to introduce lexicals.
 773 # The code being debugged will be executing in its own context, and
 774 # can't see the inside of the debugger.
 775 #
 776 # However, one should not overdo it: leave as much control from outside as
 777 # possible. If you make something a lexical, it's not going to be addressable
 778 # from outside the debugger even if you know its name.
 779
 780 # This file is automatically included if you do perl -d.
 781 # It's probably not useful to include this yourself.
 782 #
 783 # Before venturing further into these twisty passages, it is
 784 # wise to read the perldebguts man page or risk the ire of dragons.
 785 #
 786 # (It should be noted that perldebguts will tell you a lot about
 787 # the underlying mechanics of how the debugger interfaces into the
 788 # Perl interpreter, but not a lot about the debugger itself. The new
 789 # comments in this code try to address this problem.)
 790
 791 # Note that no subroutine call is possible until &DB::sub is defined
 792 # (for subroutines defined outside of the package DB). In fact the same is
 793 # true if $deep is not defined.
 794
 795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 796
 797 # modified Perl debugger, to be run from Emacs in perldb-mode
 798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 799 # Johan Vromans -- upgrade to 4.0 pl 10
 800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 801 ########################################################################
 802
 803 =head1 DEBUGGER INITIALIZATION
 804
 805 The debugger starts up in phases.
 806
 807 =head2 BASIC SETUP
 808
 809 First, it initializes the environment it wants to run in: turning off
 810 warnings during its own compilation, defining variables which it will need
 811 to avoid warnings later, setting itself up to not exit when the program
 812 terminates, and defaulting to printing return values for the C<r> command.
 813
 814 =cut
 815
 816 # Needed for the statement after exec():
 817 #
 818 # This BEGIN block is simply used to switch off warnings during debugger
 819 # compilation. Probably it would be better practice to fix the warnings,
 820 # but this is how it's done at the moment.
 821
 822 BEGIN {
 823     $ini_warn = $^W;
 824     $^W       = 0;
 825 }    # Switch compilation warnings off until another BEGIN.
 826
 827 local ($^W) = 0;    # Switch run-time warnings off during init.
 828
 829 =head2 THREADS SUPPORT
 830
 831 If we are running under a threaded Perl, we require threads and threads::shared
 832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 833 threaded debugger control.  C<-dt> can also be used to set this.
 834
 835 Each new thread will be announced and the debugger prompt will always inform
 836 you of each new thread created.  It will also indicate the thread id in which
 837 we are currently running within the prompt like this:
 838
 839     [tid] DB<$i>
 840
 841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 842 command prompt.  The prompt will show: C<[0]> when running under threads, but
 843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 844
 845 While running under threads, when you set or delete a breakpoint (etc.), this
 846 will apply to all threads, not just the currently running one.  When you are
 847 in a currently executing thread, you will stay there until it completes.  With
 848 the current implementation it is not currently possible to hop from one thread
 849 to another.
 850
 851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 852
 853 Note that threading support was built into the debugger as of Perl version
 854 C<5.8.6> and debugger version C<1.2.8>.
 855
 856 =cut
 857
 858 BEGIN {
 859     # ensure we can share our non-threaded variables or no-op
 860     if ($ENV{PERL5DB_THREADED}) {
 861         require threads;
 862         require threads::shared;
 863         import threads::shared qw(share);
 864         $DBGR;
 865         share(\$DBGR);
 866         lock($DBGR);
 867         print "Threads support enabled\n";
 868     } else {
 869         *lock  = sub(*) {};
 870         *share = sub(*) {};
 871     }
 872 }
 873
 874 # These variables control the execution of 'dumpvar.pl'.
 875 {
 876     package dumpvar;
 877     use vars qw(
 878     $hashDepth
 879     $arrayDepth
 880     $dumpDBFiles
 881     $dumpPackages
 882     $quoteHighBit
 883     $printUndef
 884     $globPrint
 885     $usageOnly
 886     );
 887 }
 888
 889 # used to control die() reporting in diesignal()
 890 {
 891     package Carp;
 892     use vars qw($CarpLevel);
 893 }
 894
 895 # without threads, $filename is not defined until DB::DB is called
 896 foreach my $k (keys (%INC)) {
 897     share(\$main::{'_<'.$filename}) if defined $filename;
 898 };
 899
 900 # Command-line + PERLLIB:
 901 # Save the contents of @INC before they are modified elsewhere.
 902 @ini_INC = @INC;
 903
 904 # This was an attempt to clear out the previous values of various
 905 # trapped errors. Apparently it didn't help. XXX More info needed!
 906 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 907
 908 # We set these variables to safe values. We don't want to blindly turn
 909 # off warnings, because other packages may still want them.
 910 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 911                                    # (local $^W cannot help - other packages!).
 912
 913 # Default to not exiting when program finishes; print the return
 914 # value when the 'r' command is used to return from a subroutine.
 915 $inhibit_exit = $option{PrintRet} = 1;
 916
 917 use vars qw($trace_to_depth);
 918
 919 # Default to 1E9 so it won't be limited to a certain recursion depth.
 920 $trace_to_depth = 1E9;
 921
 922 =head1 OPTION PROCESSING
 923
 924 The debugger's options are actually spread out over the debugger itself and
 925 C<dumpvar.pl>; some of these are variables to be set, while others are
 926 subs to be called with a value. To try to make this a little easier to
 927 manage, the debugger uses a few data structures to define what options
 928 are legal and how they are to be processed.
 929
 930 First, the C<@options> array defines the I<names> of all the options that
 931 are to be accepted.
 932
 933 =cut
 934
 935 @options = qw(
 936   CommandSet   HistFile      HistSize
 937   hashDepth    arrayDepth    dumpDepth
 938   DumpDBFiles  DumpPackages  DumpReused
 939   compactDump  veryCompact   quote
 940   HighBit      undefPrint    globPrint
 941   PrintRet     UsageOnly     frame
 942   AutoTrace    TTY           noTTY
 943   ReadLine     NonStop       LineInfo
 944   maxTraceLen  recallCommand ShellBang
 945   pager        tkRunning     ornaments
 946   signalLevel  warnLevel     dieLevel
 947   inhibit_exit ImmediateStop bareStringify
 948   CreateTTY    RemotePort    windowSize
 949   DollarCaretP
 950 );
 951
 952 @RememberOnROptions = qw(DollarCaretP);
 953
 954 =pod
 955
 956 Second, C<optionVars> lists the variables that each option uses to save its
 957 state.
 958
 959 =cut
 960
 961 use vars qw(%optionVars);
 962
 963 %optionVars = (
 964     hashDepth     => \$dumpvar::hashDepth,
 965     arrayDepth    => \$dumpvar::arrayDepth,
 966     CommandSet    => \$CommandSet,
 967     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 968     DumpPackages  => \$dumpvar::dumpPackages,
 969     DumpReused    => \$dumpvar::dumpReused,
 970     HighBit       => \$dumpvar::quoteHighBit,
 971     undefPrint    => \$dumpvar::printUndef,
 972     globPrint     => \$dumpvar::globPrint,
 973     UsageOnly     => \$dumpvar::usageOnly,
 974     CreateTTY     => \$CreateTTY,
 975     bareStringify => \$dumpvar::bareStringify,
 976     frame         => \$frame,
 977     AutoTrace     => \$trace,
 978     inhibit_exit  => \$inhibit_exit,
 979     maxTraceLen   => \$maxtrace,
 980     ImmediateStop => \$ImmediateStop,
 981     RemotePort    => \$remoteport,
 982     windowSize    => \$window,
 983     HistFile      => \$histfile,
 984     HistSize      => \$histsize,
 985 );
 986
 987 =pod
 988
 989 Third, C<%optionAction> defines the subroutine to be called to process each
 990 option.
 991
 992 =cut
 993
 994 use vars qw(%optionAction);
 995
 996 %optionAction = (
 997     compactDump   => \&dumpvar::compactDump,
 998     veryCompact   => \&dumpvar::veryCompact,
 999     quote         => \&dumpvar::quote,
1000     TTY           => \&TTY,
1001     noTTY         => \&noTTY,
1002     ReadLine      => \&ReadLine,
1003     NonStop       => \&NonStop,
1004     LineInfo      => \&LineInfo,
1005     recallCommand => \&recallCommand,
1006     ShellBang     => \&shellBang,
1007     pager         => \&pager,
1008     signalLevel   => \&signalLevel,
1009     warnLevel     => \&warnLevel,
1010     dieLevel      => \&dieLevel,
1011     tkRunning     => \&tkRunning,
1012     ornaments     => \&ornaments,
1013     RemotePort    => \&RemotePort,
1014     DollarCaretP  => \&DollarCaretP,
1015 );
1016
1017 =pod
1018
1019 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1020 option is used.
1021
1022 =cut
1023
1024 # Note that this list is not complete: several options not listed here
1025 # actually require that dumpvar.pl be loaded for them to work, but are
1026 # not in the table. A subsequent patch will correct this problem; for
1027 # the moment, we're just recommenting, and we are NOT going to change
1028 # function.
1029 use vars qw(%optionRequire);
1030
1031 %optionRequire = (
1032     compactDump => 'dumpvar.pl',
1033     veryCompact => 'dumpvar.pl',
1034     quote       => 'dumpvar.pl',
1035 );
1036
1037 =pod
1038
1039 There are a number of initialization-related variables which can be set
1040 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1041 variable. These are:
1042
1043 =over 4
1044
1045 =item C<$rl> - readline control XXX needs more explanation
1046
1047 =item C<$warnLevel> - whether or not debugger takes over warning handling
1048
1049 =item C<$dieLevel> - whether or not debugger takes over die handling
1050
1051 =item C<$signalLevel> - whether or not debugger takes over signal handling
1052
1053 =item C<$pre> - preprompt actions (array reference)
1054
1055 =item C<$post> - postprompt actions (array reference)
1056
1057 =item C<$pretype>
1058
1059 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1060
1061 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1062
1063 =back
1064
1065 =cut
1066
1067 # These guys may be defined in $ENV{PERL5DB} :
1068 $rl          = 1     unless defined $rl;
1069 $warnLevel   = 1     unless defined $warnLevel;
1070 $dieLevel    = 1     unless defined $dieLevel;
1071 $signalLevel = 1     unless defined $signalLevel;
1072 $pre         = []    unless defined $pre;
1073 $post        = []    unless defined $post;
1074 $pretype     = []    unless defined $pretype;
1075 $CreateTTY   = 3     unless defined $CreateTTY;
1076 $CommandSet  = '580' unless defined $CommandSet;
1077
1078 share($rl);
1079 share($warnLevel);
1080 share($dieLevel);
1081 share($signalLevel);
1082 share($pre);
1083 share($post);
1084 share($pretype);
1085 share($rl);
1086 share($CreateTTY);
1087 share($CommandSet);
1088
1089 =pod
1090
1091 The default C<die>, C<warn>, and C<signal> handlers are set up.
1092
1093 =cut
1094
1095 warnLevel($warnLevel);
1096 dieLevel($dieLevel);
1097 signalLevel($signalLevel);
1098
1099 =pod
1100
1101 The pager to be used is needed next. We try to get it from the
1102 environment first.  If it's not defined there, we try to find it in
1103 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1104 then call the C<pager()> function to save the pager name.
1105
1106 =cut
1107
1108 # This routine makes sure $pager is set up so that '|' can use it.
1109 pager(
1110
1111     # If PAGER is defined in the environment, use it.
1112     defined $ENV{PAGER}
1113     ? $ENV{PAGER}
1114
1115       # If not, see if Config.pm defines it.
1116     : eval { require Config }
1117       && defined $Config::Config{pager}
1118     ? $Config::Config{pager}
1119
1120       # If not, fall back to 'more'.
1121     : 'more'
1122   )
1123   unless defined $pager;
1124
1125 =pod
1126
1127 We set up the command to be used to access the man pages, the command
1128 recall character (C<!> unless otherwise defined) and the shell escape
1129 character (C<!> unless otherwise defined). Yes, these do conflict, and
1130 neither works in the debugger at the moment.
1131
1132 =cut
1133
1134 setman();
1135
1136 # Set up defaults for command recall and shell escape (note:
1137 # these currently don't work in linemode debugging).
1138 recallCommand("!") unless defined $prc;
1139 shellBang("!")     unless defined $psh;
1140
1141 =pod
1142
1143 We then set up the gigantic string containing the debugger help.
1144 We also set the limit on the number of arguments we'll display during a
1145 trace.
1146
1147 =cut
1148
1149 sethelp();
1150
1151 # If we didn't get a default for the length of eval/stack trace args,
1152 # set it here.
1153 $maxtrace = 400 unless defined $maxtrace;
1154
1155 =head2 SETTING UP THE DEBUGGER GREETING
1156
1157 The debugger I<greeting> helps to inform the user how many debuggers are
1158 running, and whether the current debugger is the primary or a child.
1159
1160 If we are the primary, we just hang onto our pid so we'll have it when
1161 or if we start a child debugger. If we are a child, we'll set things up
1162 so we'll have a unique greeting and so the parent will give us our own
1163 TTY later.
1164
1165 We save the current contents of the C<PERLDB_PIDS> environment variable
1166 because we mess around with it. We'll also need to hang onto it because
1167 we'll need it if we restart.
1168
1169 Child debuggers make a label out of the current PID structure recorded in
1170 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1171 yet so the parent will give them one later via C<resetterm()>.
1172
1173 =cut
1174
1175 # Save the current contents of the environment; we're about to
1176 # much with it. We'll need this if we have to restart.
1177 use vars qw($ini_pids);
1178 $ini_pids = $ENV{PERLDB_PIDS};
1179
1180 use vars qw ($pids $term_pid);
1181
1182 if ( defined $ENV{PERLDB_PIDS} ) {
1183
1184     # We're a child. Make us a label out of the current PID structure
1185     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1186     # a term yet so the parent will give us one later via resetterm().
1187
1188     my $env_pids = $ENV{PERLDB_PIDS};
1189     $pids = "[$env_pids]";
1190
1191     # Unless we are on OpenVMS, all programs under the DCL shell run under
1192     # the same PID.
1193
1194     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1195         $term_pid         = $$;
1196     }
1197     else {
1198         $ENV{PERLDB_PIDS} .= "->$$";
1199         $term_pid = -1;
1200     }
1201
1202 } ## end if (defined $ENV{PERLDB_PIDS...
1203 else {
1204
1205     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1206     # child debugger, and mark us as the parent, so we'll know to set up
1207     # more TTY's is we have to.
1208     $ENV{PERLDB_PIDS} = "$$";
1209     $pids             = "[pid=$$]";
1210     $term_pid         = $$;
1211 }
1212
1213 use vars qw($pidprompt);
1214 $pidprompt = '';
1215
1216 # Sets up $emacs as a synonym for $slave_editor.
1217 our ($slave_editor);
1218 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1219
1220 =head2 READING THE RC FILE
1221
1222 The debugger will read a file of initialization options if supplied. If
1223 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1224
1225 =cut
1226
1227 # As noted, this test really doesn't check accurately that the debugger
1228 # is running at a terminal or not.
1229
1230 use vars qw($rcfile);
1231 {
1232     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1233     # this is the wrong metric!
1234     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1235 }
1236
1237 =pod
1238
1239 The debugger does a safety test of the file to be read. It must be owned
1240 either by the current user or root, and must only be writable by the owner.
1241
1242 =cut
1243
1244 # This wraps a safety test around "do" to read and evaluate the init file.
1245 #
1246 # This isn't really safe, because there's a race
1247 # between checking and opening.  The solution is to
1248 # open and fstat the handle, but then you have to read and
1249 # eval the contents.  But then the silly thing gets
1250 # your lexical scope, which is unfortunate at best.
1251 sub safe_do {
1252     my $file = shift;
1253
1254     # Just exactly what part of the word "CORE::" don't you understand?
1255     local $SIG{__WARN__};
1256     local $SIG{__DIE__};
1257
1258     unless ( is_safe_file($file) ) {
1259         CORE::warn <<EO_GRIPE;
1260 perldb: Must not source insecure rcfile $file.
1261         You or the superuser must be the owner, and it must not
1262         be writable by anyone but its owner.
1263 EO_GRIPE
1264         return;
1265     } ## end unless (is_safe_file($file...
1266
1267     do $file;
1268     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1269 } ## end sub safe_do
1270
1271 # This is the safety test itself.
1272 #
1273 # Verifies that owner is either real user or superuser and that no
1274 # one but owner may write to it.  This function is of limited use
1275 # when called on a path instead of upon a handle, because there are
1276 # no guarantees that filename (by dirent) whose file (by ino) is
1277 # eventually accessed is the same as the one tested.
1278 # Assumes that the file's existence is not in doubt.
1279 sub is_safe_file {
1280     my $path = shift;
1281     stat($path) || return;    # mysteriously vaporized
1282     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1283
1284     return 0 if $uid != 0 && $uid != $<;
1285     return 0 if $mode & 022;
1286     return 1;
1287 } ## end sub is_safe_file
1288
1289 # If the rcfile (whichever one we decided was the right one to read)
1290 # exists, we safely do it.
1291 if ( -f $rcfile ) {
1292     safe_do("./$rcfile");
1293 }
1294
1295 # If there isn't one here, try the user's home directory.
1296 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1297     safe_do("$ENV{HOME}/$rcfile");
1298 }
1299
1300 # Else try the login directory.
1301 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1302     safe_do("$ENV{LOGDIR}/$rcfile");
1303 }
1304
1305 # If the PERLDB_OPTS variable has options in it, parse those out next.
1306 if ( defined $ENV{PERLDB_OPTS} ) {
1307     parse_options( $ENV{PERLDB_OPTS} );
1308 }
1309
1310 =pod
1311
1312 The last thing we do during initialization is determine which subroutine is
1313 to be used to obtain a new terminal when a new debugger is started. Right now,
1314 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1315 (darwin).
1316
1317 =cut
1318
1319 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1320 # Works if you're running an xterm or xterm-like window, or you're on
1321 # OS/2, or on Mac OS X. This may need some expansion.
1322
1323 if (not defined &get_fork_TTY)       # only if no routine exists
1324 {
1325     if ( defined $remoteport ) {
1326                                                  # Expect an inetd-like server
1327         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1328     }
1329     elsif (defined $ENV{TERM}                    # If we know what kind
1330                                                  # of terminal this is,
1331         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1332         and defined $ENV{DISPLAY}                # and what display it's on,
1333       )
1334     {
1335         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1336     }
1337     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1338         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1339     }
1340     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1341             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1342             and $ENV{TERM_PROGRAM}
1343                 eq 'Apple_Terminal'              # Terminal.app
1344             )
1345     {
1346         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1347     }
1348 } ## end if (not defined &get_fork_TTY...
1349
1350 # untaint $^O, which may have been tainted by the last statement.
1351 # see bug [perl #24674]
1352 $^O =~ m/^(.*)\z/;
1353 $^O = $1;
1354
1355 # Here begin the unreadable code.  It needs fixing.
1356
1357 =head2 RESTART PROCESSING
1358
1359 This section handles the restart command. When the C<R> command is invoked, it
1360 tries to capture all of the state it can into environment variables, and
1361 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1362 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1363 the R command stuffed into the environment variables.
1364
1365   PERLDB_RESTART   - flag only, contains no restart data itself.
1366   PERLDB_HIST      - command history, if it's available
1367   PERLDB_ON_LOAD   - breakpoints set by the rc file
1368   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1369   PERLDB_VISITED   - files that had breakpoints
1370   PERLDB_FILE_...  - breakpoints for a file
1371   PERLDB_OPT       - active options
1372   PERLDB_INC       - the original @INC
1373   PERLDB_PRETYPE   - preprompt debugger actions
1374   PERLDB_PRE       - preprompt Perl code
1375   PERLDB_POST      - post-prompt Perl code
1376   PERLDB_TYPEAHEAD - typeahead captured by readline()
1377
1378 We chug through all these variables and plug the values saved in them
1379 back into the appropriate spots in the debugger.
1380
1381 =cut
1382
1383 use vars qw(@hist @truehist %postponed_file @typeahead);
1384
1385 sub _restore_shared_globals_after_restart
1386 {
1387     @hist          = get_list('PERLDB_HIST');
1388     %break_on_load = get_list("PERLDB_ON_LOAD");
1389     %postponed     = get_list("PERLDB_POSTPONE");
1390
1391     share(@hist);
1392     share(@truehist);
1393     share(%break_on_load);
1394     share(%postponed);
1395 }
1396
1397 sub _restore_breakpoints_and_actions {
1398
1399     my @had_breakpoints = get_list("PERLDB_VISITED");
1400
1401     for my $file_idx ( 0 .. $#had_breakpoints ) {
1402         my $filename = $had_breakpoints[$file_idx];
1403         my %pf = get_list("PERLDB_FILE_$file_idx");
1404         $postponed_file{ $filename } = \%pf if %pf;
1405         my @lines = sort {$a <=> $b} keys(%pf);
1406         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1407         for my $line_idx (0 .. $#lines) {
1408             _set_breakpoint_enabled_status(
1409                 $filename,
1410                 $lines[$line_idx],
1411                 ($enabled_statuses[$line_idx] ? 1 : ''),
1412             );
1413         }
1414     }
1415
1416     return;
1417 }
1418
1419 sub _restore_options_after_restart
1420 {
1421     my %options_map = get_list("PERLDB_OPT");
1422
1423     while ( my ( $opt, $val ) = each %options_map ) {
1424         $val =~ s/[\\\']/\\$1/g;
1425         parse_options("$opt'$val'");
1426     }
1427
1428     return;
1429 }
1430
1431 sub _restore_globals_after_restart
1432 {
1433     # restore original @INC
1434     @INC     = get_list("PERLDB_INC");
1435     @ini_INC = @INC;
1436
1437     # return pre/postprompt actions and typeahead buffer
1438     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1439     $pre       = [ get_list("PERLDB_PRE") ];
1440     $post      = [ get_list("PERLDB_POST") ];
1441     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1442
1443     return;
1444 }
1445
1446
1447 if ( exists $ENV{PERLDB_RESTART} ) {
1448
1449     # We're restarting, so we don't need the flag that says to restart anymore.
1450     delete $ENV{PERLDB_RESTART};
1451
1452     # $restart = 1;
1453     _restore_shared_globals_after_restart();
1454
1455     _restore_breakpoints_and_actions();
1456
1457     # restore options
1458     _restore_options_after_restart();
1459
1460     _restore_globals_after_restart();
1461 } ## end if (exists $ENV{PERLDB_RESTART...
1462
1463 =head2 SETTING UP THE TERMINAL
1464
1465 Now, we'll decide how the debugger is going to interact with the user.
1466 If there's no TTY, we set the debugger to run non-stop; there's not going
1467 to be anyone there to enter commands.
1468
1469 =cut
1470
1471 use vars qw($notty $console $tty $LINEINFO);
1472 use vars qw($lineinfo $doccmd);
1473
1474 our ($runnonstop);
1475
1476 if ($notty) {
1477     $runnonstop = 1;
1478     share($runnonstop);
1479 }
1480
1481 =pod
1482
1483 If there is a TTY, we have to determine who it belongs to before we can
1484 proceed. If this is a slave editor or graphical debugger (denoted by
1485 the first command-line switch being '-emacs'), we shift this off and
1486 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1487
1488 =cut
1489
1490 else {
1491
1492     # Is Perl being run from a slave editor or graphical debugger?
1493     # If so, don't use readline, and set $slave_editor = 1.
1494     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1495         $rl = 0;
1496         shift(@main::ARGV);
1497     }
1498
1499     #require Term::ReadLine;
1500
1501 =pod
1502
1503 We then determine what the console should be on various systems:
1504
1505 =over 4
1506
1507 =item * Cygwin - We use C<stdin> instead of a separate device.
1508
1509 =cut
1510
1511     if ( $^O eq 'cygwin' ) {
1512
1513         # /dev/tty is binary. use stdin for textmode
1514         undef $console;
1515     }
1516
1517 =item * Unix - use C</dev/tty>.
1518
1519 =cut
1520
1521     elsif ( -e "/dev/tty" ) {
1522         $console = "/dev/tty";
1523     }
1524
1525 =item * Windows or MSDOS - use C<con>.
1526
1527 =cut
1528
1529     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1530         $console = "con";
1531     }
1532
1533 =item * VMS - use C<sys$command>.
1534
1535 =cut
1536
1537     else {
1538
1539         # everything else is ...
1540         $console = "sys\$command";
1541     }
1542
1543 =pod
1544
1545 =back
1546
1547 Several other systems don't use a specific console. We C<undef $console>
1548 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1549 with a slave editor, Epoc).
1550
1551 =cut
1552
1553     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1554
1555         # /dev/tty is binary. use stdin for textmode
1556         $console = undef;
1557     }
1558
1559     if ( $^O eq 'NetWare' ) {
1560
1561         # /dev/tty is binary. use stdin for textmode
1562         $console = undef;
1563     }
1564
1565     # In OS/2, we need to use STDIN to get textmode too, even though
1566     # it pretty much looks like Unix otherwise.
1567     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1568     {    # In OS/2
1569         $console = undef;
1570     }
1571
1572     # EPOC also falls into the 'got to use STDIN' camp.
1573     if ( $^O eq 'epoc' ) {
1574         $console = undef;
1575     }
1576
1577 =pod
1578
1579 If there is a TTY hanging around from a parent, we use that as the console.
1580
1581 =cut
1582
1583     $console = $tty if defined $tty;
1584
1585 =head2 SOCKET HANDLING
1586
1587 The debugger is capable of opening a socket and carrying out a debugging
1588 session over the socket.
1589
1590 If C<RemotePort> was defined in the options, the debugger assumes that it
1591 should try to start a debugging session on that port. It builds the socket
1592 and then tries to connect the input and output filehandles to it.
1593
1594 =cut
1595
1596     # Handle socket stuff.
1597
1598     if ( defined $remoteport ) {
1599
1600         # If RemotePort was defined in the options, connect input and output
1601         # to the socket.
1602         $IN = $OUT = connect_remoteport();
1603     } ## end if (defined $remoteport)
1604
1605 =pod
1606
1607 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1608 this is probably a situation where multiple debuggers are running (for example,
1609 a backticked command that starts up another debugger). We create a new IN and
1610 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1611 and if we can.
1612
1613 =cut
1614
1615     # Non-socket.
1616     else {
1617
1618         # Two debuggers running (probably a system or a backtick that invokes
1619         # the debugger itself under the running one). create a new IN and OUT
1620         # filehandle, and do the necessary mojo to create a new tty if we
1621         # know how, and we can.
1622         create_IN_OUT(4) if $CreateTTY & 4;
1623         if ($console) {
1624
1625             # If we have a console, check to see if there are separate ins and
1626             # outs to open. (They are assumed identical if not.)
1627
1628             my ( $i, $o ) = split /,/, $console;
1629             $o = $i unless defined $o;
1630
1631             # read/write on in, or just read, or read on STDIN.
1632             open( IN,      "+<$i" )
1633               || open( IN, "<$i" )
1634               || open( IN, "<&STDIN" );
1635
1636             # read/write/create/clobber out, or write/create/clobber out,
1637             # or merge with STDERR, or merge with STDOUT.
1638                  open( OUT, "+>$o" )
1639               || open( OUT, ">$o" )
1640               || open( OUT, ">&STDERR" )
1641               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1642
1643         } ## end if ($console)
1644         elsif ( not defined $console ) {
1645
1646             # No console. Open STDIN.
1647             open( IN, "<&STDIN" );
1648
1649             # merge with STDERR, or with STDOUT.
1650             open( OUT,      ">&STDERR" )
1651               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1652             $console = 'STDIN/OUT';
1653         } ## end elsif (not defined $console)
1654
1655         # Keep copies of the filehandles so that when the pager runs, it
1656         # can close standard input without clobbering ours.
1657         if ($console or (not defined($console))) {
1658             $IN = \*IN;
1659             $OUT = \*OUT;
1660         }
1661     } ## end elsif (from if(defined $remoteport))
1662
1663     # Unbuffer DB::OUT. We need to see responses right away.
1664     $OUT->autoflush(1);
1665
1666     # Line info goes to debugger output unless pointed elsewhere.
1667     # Pointing elsewhere makes it possible for slave editors to
1668     # keep track of file and position. We have both a filehandle
1669     # and a I/O description to keep track of.
1670     $LINEINFO = $OUT     unless defined $LINEINFO;
1671     $lineinfo = $console unless defined $lineinfo;
1672     # share($LINEINFO); # <- unable to share globs
1673     share($lineinfo);   #
1674
1675 =pod
1676
1677 To finish initialization, we show the debugger greeting,
1678 and then call the C<afterinit()> subroutine if there is one.
1679
1680 =cut
1681
1682     # Show the debugger greeting.
1683     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1684     unless ($runnonstop) {
1685         local $\ = '';
1686         local $, = '';
1687         if ( $term_pid eq '-1' ) {
1688             print $OUT "\nDaughter DB session started...\n";
1689         }
1690         else {
1691             print $OUT "\nLoading DB routines from $header\n";
1692             print $OUT (
1693                 "Editor support ",
1694                 $slave_editor ? "enabled" : "available", ".\n"
1695             );
1696             print $OUT
1697 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1698         } ## end else [ if ($term_pid eq '-1')
1699     } ## end unless ($runnonstop)
1700 } ## end else [ if ($notty)
1701
1702 # XXX This looks like a bug to me.
1703 # Why copy to @ARGS and then futz with @args?
1704 @ARGS = @ARGV;
1705 # for (@args) {
1706     # Make sure backslashes before single quotes are stripped out, and
1707     # keep args unless they are numeric (XXX why?)
1708     # s/\'/\\\'/g;                      # removed while not justified understandably
1709     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1710 # }
1711
1712 # If there was an afterinit() sub defined, call it. It will get
1713 # executed in our scope, so it can fiddle with debugger globals.
1714 if ( defined &afterinit ) {    # May be defined in $rcfile
1715     afterinit();
1716 }
1717
1718 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1719 use vars qw($I_m_init);
1720
1721 $I_m_init = 1;
1722
1723 ############################################################ Subroutines
1724
1725 =head1 SUBROUTINES
1726
1727 =head2 DB
1728
1729 This gigantic subroutine is the heart of the debugger. Called before every
1730 statement, its job is to determine if a breakpoint has been reached, and
1731 stop if so; read commands from the user, parse them, and execute
1732 them, and then send execution off to the next statement.
1733
1734 Note that the order in which the commands are processed is very important;
1735 some commands earlier in the loop will actually alter the C<$cmd> variable
1736 to create other commands to be executed later. This is all highly I<optimized>
1737 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1738 see what's happening in any given command.
1739
1740 =cut
1741
1742 use vars qw(
1743     $action
1744     %alias
1745     $cmd
1746     $fall_off_end
1747     $file
1748     $filename_ini
1749     $finished
1750     %had_breakpoints
1751     $laststep
1752     $level
1753     $max
1754     $package
1755     $rc
1756     $sh
1757     $try
1758     $end
1759 );
1760
1761 our (
1762     $doret,
1763     $incr,
1764     $stack_depth,
1765     @stack,
1766     @to_watch,
1767     @old_watch,
1768 );
1769
1770 sub _DB__determine_if_we_should_break
1771 {
1772     # if we have something here, see if we should break.
1773     # $stop is lexical and local to this block - $action on the other hand
1774     # is global.
1775     my $stop;
1776
1777     if ( $dbline{$line}
1778         && _is_breakpoint_enabled($filename, $line)
1779         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1780     {
1781
1782         # Stop if the stop criterion says to just stop.
1783         if ( $stop eq '1' ) {
1784             $signal |= 1;
1785         }
1786
1787         # It's a conditional stop; eval it in the user's context and
1788         # see if we should stop. If so, remove the one-time sigil.
1789         elsif ($stop) {
1790             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1791             &eval;
1792             # If the breakpoint is temporary, then delete its enabled status.
1793             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1794                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1795             }
1796         }
1797     } ## end if ($dbline{$line} && ...
1798 }
1799
1800 sub _DB__is_finished {
1801     if ($finished and $level <= 1) {
1802         end_report();
1803         return 1;
1804     }
1805     else {
1806         return;
1807     }
1808 }
1809
1810 sub _DB__read_next_cmd
1811 {
1812     my ($tid) = @_;
1813
1814     # We have a terminal, or can get one ...
1815     if (!$term) {
1816         setterm();
1817     }
1818
1819     # ... and it belogs to this PID or we get one for this PID ...
1820     if ($term_pid != $$) {
1821         resetterm(1);
1822     }
1823
1824     # ... and we got a line of command input ...
1825     $cmd = DB::readline(
1826         "$pidprompt $tid DB"
1827         . ( '<' x $level )
1828         . ( $#hist + 1 )
1829         . ( '>' x $level ) . " "
1830     );
1831
1832     return defined($cmd);
1833 }
1834
1835 sub _DB__trim_command_and_return_first_component {
1836     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1837     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1838
1839     $cmd =~ m{\A(\S*)};
1840     return $1;
1841 }
1842
1843 sub _DB__handle_f_command {
1844     if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
1845         $file =~ s/\s+$//;
1846
1847         # help for no arguments (old-style was return from sub).
1848         if ( !$file ) {
1849             print $OUT
1850             "The old f command is now the r command.\n";    # hint
1851             print $OUT "The new f command switches filenames.\n";
1852             next CMD;
1853         } ## end if (!$file)
1854
1855         # if not in magic file list, try a close match.
1856         if ( !defined $main::{ '_<' . $file } ) {
1857             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1858                 {
1859                     $try = substr( $try, 2 );
1860                     print $OUT "Choosing $try matching '$file':\n";
1861                     $file = $try;
1862                 }
1863             } ## end if (($try) = grep(m#^_<.*$file#...
1864         } ## end if (!defined $main::{ ...
1865
1866         # If not successfully switched now, we failed.
1867         if ( !defined $main::{ '_<' . $file } ) {
1868             print $OUT "No file matching '$file' is loaded.\n";
1869             next CMD;
1870         }
1871
1872         # We switched, so switch the debugger internals around.
1873         elsif ( $file ne $filename ) {
1874             *dbline   = $main::{ '_<' . $file };
1875             $max      = $#dbline;
1876             $filename = $file;
1877             $start    = 1;
1878             $cmd      = "l";
1879         } ## end elsif ($file ne $filename)
1880
1881         # We didn't switch; say we didn't.
1882         else {
1883             print $OUT "Already in $file.\n";
1884             next CMD;
1885         }
1886     }
1887
1888     return;
1889 }
1890
1891 sub _DB__handle_dot_command {
1892     my ($obj) = @_;
1893
1894     # . command.
1895     if ($cmd eq '.') {
1896         $incr = -1;    # stay at current line
1897
1898         # Reset everything to the old location.
1899         $start    = $line;
1900         $filename = $filename_ini;
1901         *dbline   = $main::{ '_<' . $filename };
1902         $max      = $#dbline;
1903
1904         # Now where are we?
1905         print_lineinfo($obj->position());
1906         next CMD;
1907     }
1908
1909     return;
1910 }
1911
1912 sub _DB__handle_y_command {
1913     my ($obj) = @_;
1914
1915     if (my ($match_level, $match_vars)
1916         = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
1917
1918         # See if we've got the necessary support.
1919         eval { require PadWalker; PadWalker->VERSION(0.08) }
1920             or &warn(
1921             $@ =~ /locate/
1922             ? "PadWalker module not found - please install\n"
1923             : $@
1924         )
1925             and next CMD;
1926
1927         # Load up dumpvar if we don't have it. If we can, that is.
1928         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1929         defined &main::dumpvar
1930             or print $OUT "dumpvar.pl not available.\n"
1931             and next CMD;
1932
1933         # Got all the modules we need. Find them and print them.
1934         my @vars = split( ' ', $match_vars || '' );
1935
1936         # Find the pad.
1937         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1938
1939         # Oops. Can't find it.
1940         $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
1941
1942         # Show the desired vars with dumplex().
1943         my $savout = select($OUT);
1944
1945         # Have dumplex dump the lexicals.
1946         dumpvar::dumplex( $_, $h->{$_},
1947             defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1948             @vars )
1949         for sort keys %$h;
1950         select($savout);
1951         next CMD;
1952     }
1953 }
1954
1955 sub DB {
1956
1957     # lock the debugger and get the thread id for the prompt
1958     lock($DBGR);
1959     my $tid;
1960     my $position;
1961     my ($prefix, $after, $infix);
1962     my $pat;
1963     my $explicit_stop;
1964
1965     if ($ENV{PERL5DB_THREADED}) {
1966         $tid = eval { "[".threads->tid."]" };
1967     }
1968
1969     my $obj = DB::Obj->new(
1970         {
1971             position => \$position,
1972             prefix => \$prefix,
1973             after => \$after,
1974             explicit_stop => \$explicit_stop,
1975             infix => \$infix,
1976         },
1977     );
1978
1979     $obj->_DB_on_init__initialize_globals(@_);
1980
1981     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1982     # The code being debugged may have altered them.
1983     &save;
1984
1985     # Since DB::DB gets called after every line, we can use caller() to
1986     # figure out where we last were executing. Sneaky, eh? This works because
1987     # caller is returning all the extra information when called from the
1988     # debugger.
1989     local ( $package, $filename, $line ) = caller;
1990     $filename_ini = $filename;
1991
1992     # set up the context for DB::eval, so it can properly execute
1993     # code on behalf of the user. We add the package in so that the
1994     # code is eval'ed in the proper package (not in the debugger!).
1995     local $usercontext = _calc_usercontext($package);
1996
1997     # Create an alias to the active file magical array to simplify
1998     # the code here.
1999     local (*dbline) = $main::{ '_<' . $filename };
2000
2001     # Last line in the program.
2002     $max = $#dbline;
2003
2004     _DB__determine_if_we_should_break(@_);
2005
2006     # Preserve the current stop-or-not, and see if any of the W
2007     # (watch expressions) has changed.
2008     my $was_signal = $signal;
2009
2010     # If we have any watch expressions ...
2011     $obj->_DB__handle_watch_expressions(@_);
2012
2013 =head2 C<watchfunction()>
2014
2015 C<watchfunction()> is a function that can be defined by the user; it is a
2016 function which will be run on each entry to C<DB::DB>; it gets the
2017 current package, filename, and line as its parameters.
2018
2019 The watchfunction can do anything it likes; it is executing in the
2020 debugger's context, so it has access to all of the debugger's internal
2021 data structures and functions.
2022
2023 C<watchfunction()> can control the debugger's actions. Any of the following
2024 will cause the debugger to return control to the user's program after
2025 C<watchfunction()> executes:
2026
2027 =over 4
2028
2029 =item *
2030
2031 Returning a false value from the C<watchfunction()> itself.
2032
2033 =item *
2034
2035 Altering C<$single> to a false value.
2036
2037 =item *
2038
2039 Altering C<$signal> to a false value.
2040
2041 =item *
2042
2043 Turning off the C<4> bit in C<$trace> (this also disables the
2044 check for C<watchfunction()>. This can be done with
2045
2046     $trace &= ~4;
2047
2048 =back
2049
2050 =cut
2051
2052     # If there's a user-defined DB::watchfunction, call it with the
2053     # current package, filename, and line. The function executes in
2054     # the DB:: package.
2055     if ( $trace & 4 ) {    # User-installed watch
2056         return
2057           if watchfunction( $package, $filename, $line )
2058           and not $single
2059           and not $was_signal
2060           and not( $trace & ~4 );
2061     } ## end if ($trace & 4)
2062
2063     # Pick up any alteration to $signal in the watchfunction, and
2064     # turn off the signal now.
2065     $was_signal = $signal;
2066     $signal     = 0;
2067
2068 =head2 GETTING READY TO EXECUTE COMMANDS
2069
2070 The debugger decides to take control if single-step mode is on, the
2071 C<t> command was entered, or the user generated a signal. If the program
2072 has fallen off the end, we set things up so that entering further commands
2073 won't cause trouble, and we say that the program is over.
2074
2075 =cut
2076
2077     # Make sure that we always print if asked for explicitly regardless
2078     # of $trace_to_depth .
2079     $explicit_stop = ($single || $was_signal);
2080
2081     # Check to see if we should grab control ($single true,
2082     # trace set appropriately, or we got a signal).
2083     if ( $explicit_stop || ( $trace & 1 ) ) {
2084         $obj->_DB__grab_control(@_);
2085     } ## end if ($single || ($trace...
2086
2087 =pod
2088
2089 If there's an action to be executed for the line we stopped at, execute it.
2090 If there are any preprompt actions, execute those as well.
2091
2092 =cut
2093
2094     # If there's an action, do it now.
2095     if ($action) {
2096         $evalarg = $action;
2097         DB::eval();
2098     }
2099
2100     # Are we nested another level (e.g., did we evaluate a function
2101     # that had a breakpoint in it at the debugger prompt)?
2102     if ( $single || $was_signal ) {
2103
2104         # Yes, go down a level.
2105         local $level = $level + 1;
2106
2107         # Do any pre-prompt actions.
2108         foreach $evalarg (@$pre) {
2109             DB::eval();
2110         }
2111
2112         # Complain about too much recursion if we passed the limit.
2113         if ($single & 4) {
2114             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2115         }
2116
2117         # The line we're currently on. Set $incr to -1 to stay here
2118         # until we get a command that tells us to advance.
2119         $start = $line;
2120         $incr  = -1;      # for backward motion.
2121
2122         # Tack preprompt debugger actions ahead of any actual input.
2123         @typeahead = ( @$pretype, @typeahead );
2124
2125 =head2 WHERE ARE WE?
2126
2127 XXX Relocate this section?
2128
2129 The debugger normally shows the line corresponding to the current line of
2130 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2131 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2132
2133 C<$incr> controls by how many lines the I<current> line should move forward
2134 after a command is executed. If set to -1, this indicates that the I<current>
2135 line shouldn't change.
2136
2137 C<$start> is the I<current> line. It is used for things like knowing where to
2138 move forwards or backwards from when doing an C<L> or C<-> command.
2139
2140 C<$max> tells the debugger where the last line of the current file is. It's
2141 used to terminate loops most often.
2142
2143 =head2 THE COMMAND LOOP
2144
2145 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2146 in two parts:
2147
2148 =over 4
2149
2150 =item *
2151
2152 The outer part of the loop, starting at the C<CMD> label. This loop
2153 reads a command and then executes it.
2154
2155 =item *
2156
2157 The inner part of the loop, starting at the C<PIPE> label. This part
2158 is wholly contained inside the C<CMD> block and only executes a command.
2159 Used to handle commands running inside a pager.
2160
2161 =back
2162
2163 So why have two labels to restart the loop? Because sometimes, it's easier to
2164 have a command I<generate> another command and then re-execute the loop to do
2165 the new command. This is faster, but perhaps a bit more convoluted.
2166
2167 =cut
2168
2169         # The big command dispatch loop. It keeps running until the
2170         # user yields up control again.
2171         #
2172         # If we have a terminal for input, and we get something back
2173         # from readline(), keep on processing.
2174         my $piped;
2175         my $selected;
2176
2177       CMD:
2178         while (_DB__read_next_cmd($tid))
2179         {
2180
2181             share($cmd);
2182             # ... try to execute the input as debugger commands.
2183
2184             # Don't stop running.
2185             $single = 0;
2186
2187             # No signal is active.
2188             $signal = 0;
2189
2190             # Handle continued commands (ending with \):
2191             if ($cmd =~ s/\\\z/\n/) {
2192                 $cmd .= DB::readline("  cont: ");
2193                 redo CMD;
2194             }
2195
2196 =head4 The null command
2197
2198 A newline entered by itself means I<re-execute the last command>. We grab the
2199 command out of C<$laststep> (where it was recorded previously), and copy it
2200 back into C<$cmd> to be executed below. If there wasn't any previous command,
2201 we'll do nothing below (no command will match). If there was, we also save it
2202 in the command history and fall through to allow the command parsing to pick
2203 it up.
2204
2205 =cut
2206
2207             # Empty input means repeat the last command.
2208             if ($cmd eq '') {
2209                 $cmd = $laststep;
2210             }
2211             chomp($cmd);    # get rid of the annoying extra newline
2212             if (length($cmd) >= 2) {
2213                 push( @hist, $cmd );
2214             }
2215             push( @truehist, $cmd );
2216             share(@hist);
2217             share(@truehist);
2218
2219             # This is a restart point for commands that didn't arrive
2220             # via direct user input. It allows us to 'redo PIPE' to
2221             # re-execute command processing without reading a new command.
2222           PIPE: {
2223                 my $i = _DB__trim_command_and_return_first_component();
2224
2225 =head3 COMMAND ALIASES
2226
2227 The debugger can create aliases for commands (these are stored in the
2228 C<%alias> hash). Before a command is executed, the command loop looks it up
2229 in the alias hash and substitutes the contents of the alias for the command,
2230 completely replacing it.
2231
2232 =cut
2233
2234                 # See if there's an alias for the command, and set it up if so.
2235                 if ( $alias{$i} ) {
2236
2237                     # Squelch signal handling; we want to keep control here
2238                     # if something goes loco during the alias eval.
2239                     local $SIG{__DIE__};
2240                     local $SIG{__WARN__};
2241
2242                     # This is a command, so we eval it in the DEBUGGER's
2243                     # scope! Otherwise, we can't see the special debugger
2244                     # variables, or get to the debugger's subs. (Well, we
2245                     # _could_, but why make it even more complicated?)
2246                     eval "\$cmd =~ $alias{$i}";
2247                     if ($@) {
2248                         local $\ = '';
2249                         print $OUT "Couldn't evaluate '$i' alias: $@";
2250                         next CMD;
2251                     }
2252                 } ## end if ($alias{$i})
2253
2254 =head3 MAIN-LINE COMMANDS
2255
2256 All of these commands work up to and after the program being debugged has
2257 terminated.
2258
2259 =head4 C<q> - quit
2260
2261 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2262 try to execute further, cleaning any restart-related stuff out of the
2263 environment, and executing with the last value of C<$?>.
2264
2265 =cut
2266
2267                 if ($cmd eq 'q') {
2268                     $fall_off_end = 1;
2269                     clean_ENV();
2270                     exit $?;
2271                 }
2272
2273 =head4 C<t> - trace [n]
2274
2275 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2276 If level is specified, set C<$trace_to_depth>.
2277
2278 =cut
2279
2280                 $obj->_handle_t_command;
2281
2282 =head4 C<S> - list subroutines matching/not matching a pattern
2283
2284 Walks through C<%sub>, checking to see whether or not to print the name.
2285
2286 =cut
2287
2288                 $obj->_handle_S_command;
2289
2290 =head4 C<X> - list variables in current package
2291
2292 Since the C<V> command actually processes this, just change this to the
2293 appropriate C<V> command and fall through.
2294
2295 =head4 C<V> - list variables
2296
2297 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2298
2299 =cut
2300
2301                 $obj->_handle_V_command_and_X_command;
2302
2303 =head4 C<x> - evaluate and print an expression
2304
2305 Hands the expression off to C<DB::eval>, setting it up to print the value
2306 via C<dumpvar.pl> instead of just printing it directly.
2307
2308 =cut
2309
2310                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2311                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2312
2313                     # handle special  "x 3 blah" syntax XXX propagate
2314                     # doc back to special variables.
2315                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2316                         $onetimedumpDepth = $1;
2317                     }
2318                 }
2319
2320 =head4 C<m> - print methods
2321
2322 Just uses C<DB::methods> to determine what methods are available.
2323
2324 =cut
2325
2326                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2327                     methods($1);
2328                     next CMD;
2329                 }
2330
2331                 # m expr - set up DB::eval to do the work
2332                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2333                     $onetimeDump = 'methods';   #  method output gets used there
2334                 }
2335
2336 =head4 C<f> - switch files
2337
2338 =cut
2339
2340                 _DB__handle_f_command();
2341
2342 =head4 C<.> - return to last-executed line.
2343
2344 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2345 and then we look up the line in the magical C<%dbline> hash.
2346
2347 =cut
2348
2349         _DB__handle_dot_command($obj);
2350
2351 =head4 C<-> - back one window
2352
2353 We change C<$start> to be one window back; if we go back past the first line,
2354 we set it to be the first line. We ser C<$incr> to put us back at the
2355 currently-executing line, and then put a C<l $start +> (list one window from
2356 C<$start>) in C<$cmd> to be executed later.
2357
2358 =cut
2359
2360                 # - - back a window.
2361                 $obj->_handle_dash_command;
2362
2363 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2364
2365 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2366 problems, most notably that the default case of several commands destroying
2367 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2368 retain the old commands for those who were used to using them or who preferred
2369 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2370 deal with them instead of processing them in-line.
2371
2372 =cut
2373
2374                 # All of these commands were remapped in perl 5.8.0;
2375                 # we send them off to the secondary dispatcher (see below).
2376                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2377                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2378                     next CMD;
2379                 }
2380
2381 =head4 C<y> - List lexicals in higher scope
2382
2383 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2384 above the current one and then displays then using C<dumpvar.pl>.
2385
2386 =cut
2387
2388                 _DB__handle_y_command($obj);
2389
2390 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2391
2392 All of the commands below this point don't work after the program being
2393 debugged has ended. All of them check to see if the program has ended; this
2394 allows the commands to be relocated without worrying about a 'line of
2395 demarcation' above which commands can be entered anytime, and below which
2396 they can't.
2397
2398 =head4 C<n> - single step, but don't trace down into subs
2399
2400 Done by setting C<$single> to 2, which forces subs to execute straight through
2401 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2402 so a null command knows what to re-execute.
2403
2404 =cut
2405
2406                 # n - next
2407                 if ($cmd eq 'n') {
2408                     next CMD if _DB__is_finished();
2409
2410                     # Single step, but don't enter subs.
2411                     $single = 2;
2412
2413                     # Save for empty command (repeat last).
2414                     $laststep = $cmd;
2415                     last CMD;
2416                 }
2417
2418 =head4 C<s> - single-step, entering subs
2419
2420 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2421 subs. Also saves C<s> as C<$lastcmd>.
2422
2423 =cut
2424
2425                 # s - single step.
2426                 if ($cmd eq 's') {
2427
2428                     # Get out and restart the command loop if program
2429                     # has finished.
2430                     next CMD if _DB__is_finished();
2431
2432                     # Single step should enter subs.
2433                     $single = 1;
2434
2435                     # Save for empty command (repeat last).
2436                     $laststep = $cmd;
2437                     last CMD;
2438                 }
2439
2440 =head4 C<c> - run continuously, setting an optional breakpoint
2441
2442 Most of the code for this command is taken up with locating the optional
2443 breakpoint, which is either a subroutine name or a line number. We set
2444 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2445 in this and all call levels above this one.
2446
2447 =cut
2448
2449                 # c - start continuous execution.
2450                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2451
2452                     # Hey, show's over. The debugged program finished
2453                     # executing already.
2454                     next CMD if _DB__is_finished();
2455
2456                     # Capture the place to put a one-time break.
2457                     $subname = $i;
2458
2459                     #  Probably not needed, since we finish an interactive
2460                     #  sub-session anyway...
2461                     # local $filename = $filename;
2462                     # local *dbline = *dbline; # XXX Would this work?!
2463                     #
2464                     # The above question wonders if localizing the alias
2465                     # to the magic array works or not. Since it's commented
2466                     # out, we'll just leave that to speculation for now.
2467
2468                     # If the "subname" isn't all digits, we'll assume it
2469                     # is a subroutine name, and try to find it.
2470                     if ( $subname =~ /\D/ ) {    # subroutine name
2471                             # Qualify it to the current package unless it's
2472                             # already qualified.
2473                         $subname = $package . "::" . $subname
2474                           unless $subname =~ /::/;
2475
2476                         # find_sub will return "file:line_number" corresponding
2477                         # to where the subroutine is defined; we call find_sub,
2478                         # break up the return value, and assign it in one
2479                         # operation.
2480                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2481
2482                         # Force the line number to be numeric.
2483                         $i += 0;
2484
2485                         # If we got a line number, we found the sub.
2486                         if ($i) {
2487
2488                             # Switch all the debugger's internals around so
2489                             # we're actually working with that file.
2490                             $filename = $file;
2491                             *dbline   = $main::{ '_<' . $filename };
2492
2493                             # Mark that there's a breakpoint in this file.
2494                             $had_breakpoints{$filename} |= 1;
2495
2496                             # Scan forward to the first executable line
2497                             # after the 'sub whatever' line.
2498                             $max = $#dbline;
2499                             ++$i while $dbline[$i] == 0 && $i < $max;
2500                         } ## end if ($i)
2501
2502                         # We didn't find a sub by that name.
2503                         else {
2504                             print $OUT "Subroutine $subname not found.\n";
2505                             next CMD;
2506                         }
2507                     } ## end if ($subname =~ /\D/)
2508
2509                     # At this point, either the subname was all digits (an
2510                     # absolute line-break request) or we've scanned through
2511                     # the code following the definition of the sub, looking
2512                     # for an executable, which we may or may not have found.
2513                     #
2514                     # If $i (which we set $subname from) is non-zero, we
2515                     # got a request to break at some line somewhere. On
2516                     # one hand, if there wasn't any real subroutine name
2517                     # involved, this will be a request to break in the current
2518                     # file at the specified line, so we have to check to make
2519                     # sure that the line specified really is breakable.
2520                     #
2521                     # On the other hand, if there was a subname supplied, the
2522                     # preceding block has moved us to the proper file and
2523                     # location within that file, and then scanned forward
2524                     # looking for the next executable line. We have to make
2525                     # sure that one was found.
2526                     #
2527                     # On the gripping hand, we can't do anything unless the
2528                     # current value of $i points to a valid breakable line.
2529                     # Check that.
2530                     if ($i) {
2531
2532                         # Breakable?
2533                         if ( $dbline[$i] == 0 ) {
2534                             print $OUT "Line $i not breakable.\n";
2535                             next CMD;
2536                         }
2537
2538                         # Yes. Set up the one-time-break sigil.
2539                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2540                         _enable_breakpoint_temp_enabled_status($filename, $i);
2541                     } ## end if ($i)
2542
2543                     # Turn off stack tracing from here up.
2544                     for my $i (0 .. $stack_depth) {
2545                         $stack[ $i ] &= ~1;
2546                     }
2547                     last CMD;
2548                 }
2549
2550 =head4 C<r> - return from a subroutine
2551
2552 For C<r> to work properly, the debugger has to stop execution again
2553 immediately after the return is executed. This is done by forcing
2554 single-stepping to be on in the call level above the current one. If
2555 we are printing return values when a C<r> is executed, set C<$doret>
2556 appropriately, and force us out of the command loop.
2557
2558 =cut
2559
2560                 # r - return from the current subroutine.
2561                 if ($cmd eq 'r') {
2562
2563                     # Can't do anything if the program's over.
2564                     next CMD if _DB__is_finished();
2565
2566                     # Turn on stack trace.
2567                     $stack[$stack_depth] |= 1;
2568
2569                     # Print return value unless the stack is empty.
2570                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2571                     last CMD;
2572                 }
2573
2574 =head4 C<T> - stack trace
2575
2576 Just calls C<DB::print_trace>.
2577
2578 =cut
2579
2580                 if ($cmd eq 'T') {
2581                     print_trace( $OUT, 1 );    # skip DB
2582                     next CMD;
2583                 }
2584
2585 =head4 C<w> - List window around current line.
2586
2587 Just calls C<DB::cmd_w>.
2588
2589 =cut
2590
2591                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2592                     &cmd_w( 'w', $arg );
2593                     next CMD;
2594                 }
2595
2596 =head4 C<W> - watch-expression processing.
2597
2598 Just calls C<DB::cmd_W>.
2599
2600 =cut
2601
2602                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2603                     &cmd_W( 'W', $arg );
2604                     next CMD;
2605                 }
2606
2607 =head4 C</> - search forward for a string in the source
2608
2609 We take the argument and treat it as a pattern. If it turns out to be a
2610 bad one, we return the error we got from trying to C<eval> it and exit.
2611 If not, we create some code to do the search and C<eval> it so it can't
2612 mess us up.
2613
2614 =cut
2615
2616                 # The pattern as a string.
2617                 use vars qw($inpat);
2618
2619                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2620
2621                     # Remove the final slash.
2622                     $inpat =~ s:([^\\])/$:$1:;
2623
2624                     # If the pattern isn't null ...
2625                     if ( $inpat ne "" ) {
2626
2627                         # Turn of warn and die procesing for a bit.
2628                         local $SIG{__DIE__};
2629                         local $SIG{__WARN__};
2630
2631                         # Create the pattern.
2632                         eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2633                         if ( $@ ne "" ) {
2634
2635                             # Oops. Bad pattern. No biscuit.
2636                             # Print the eval error and go back for more
2637                             # commands.
2638                             print $OUT "$@";
2639                             next CMD;
2640                         }
2641                         $pat = $inpat;
2642                     } ## end if ($inpat ne "")
2643
2644                     # Set up to stop on wrap-around.
2645                     $end = $start;
2646
2647                     # Don't move off the current line.
2648                     $incr = -1;
2649
2650                     # Done in eval so nothing breaks if the pattern
2651                     # does something weird.
2652                     eval '
2653                         no strict q/vars/;
2654                         for (;;) {
2655                             # Move ahead one line.
2656                             ++$start;
2657
2658                             # Wrap if we pass the last line.
2659                             $start = 1 if ($start > $max);
2660
2661                             # Stop if we have gotten back to this line again,
2662                             last if ($start == $end);
2663
2664                             # A hit! (Note, though, that we are doing
2665                             # case-insensitive matching. Maybe a qr//
2666                             # expression would be better, so the user could
2667                             # do case-sensitive matching if desired.
2668                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2669                                 if ($slave_editor) {
2670                                     # Handle proper escaping in the slave.
2671                                     print $OUT "\032\032$filename:$start:0\n";
2672                                 }
2673                                 else {
2674                                     # Just print the line normally.
2675                                     print $OUT "$start:\t",$dbline[$start],"\n";
2676                                 }
2677                                 # And quit since we found something.
2678                                 last;
2679                             }
2680                          } ';
2681
2682                     # If we wrapped, there never was a match.
2683                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2684                     next CMD;
2685                 }
2686
2687 =head4 C<?> - search backward for a string in the source
2688
2689 Same as for C</>, except the loop runs backwards.
2690
2691 =cut
2692
2693                 # ? - backward pattern search.
2694                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2695
2696                     # Get the pattern, remove trailing question mark.
2697                     $inpat =~ s:([^\\])\?$:$1:;
2698
2699                     # If we've got one ...
2700                     if ( $inpat ne "" ) {
2701
2702                         # Turn off die & warn handlers.
2703                         local $SIG{__DIE__};
2704                         local $SIG{__WARN__};
2705                         eval '$inpat =~ m' . "\a$inpat\a";
2706
2707                         if ( $@ ne "" ) {
2708
2709                             # Ouch. Not good. Print the error.
2710                             print $OUT $@;
2711                             next CMD;
2712                         }
2713                         $pat = $inpat;
2714                     } ## end if ($inpat ne "")
2715
2716                     # Where we are now is where to stop after wraparound.
2717                     $end = $start;
2718
2719                     # Don't move away from this line.
2720                     $incr = -1;
2721
2722                     # Search inside the eval to prevent pattern badness
2723                     # from killing us.
2724                     eval '
2725                         no strict q/vars/;
2726                         for (;;) {
2727                             # Back up a line.
2728                             --$start;
2729
2730                             # Wrap if we pass the first line.
2731
2732                             $start = $max if ($start <= 0);
2733
2734                             # Quit if we get back where we started,
2735                             last if ($start == $end);
2736
2737                             # Match?
2738                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2739                                 if ($slave_editor) {
2740                                     # Yep, follow slave editor requirements.
2741                                     print $OUT "\032\032$filename:$start:0\n";
2742                                 }
2743                                 else {
2744                                     # Yep, just print normally.
2745                                     print $OUT "$start:\t",$dbline[$start],"\n";
2746                                 }
2747
2748                                 # Found, so done.
2749                                 last;
2750                             }
2751                         } ';
2752
2753                     # Say we failed if the loop never found anything,
2754                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2755                     next CMD;
2756                 }
2757
2758 =head4 C<$rc> - Recall command
2759
2760 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2761 that the terminal supports history). It find the the command required, puts it
2762 into C<$cmd>, and redoes the loop to execute it.
2763
2764 =cut
2765
2766                 # $rc - recall command.
2767                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2768
2769                     # No arguments, take one thing off history.
2770                     pop(@hist) if length($cmd) > 1;
2771
2772                     # Relative (- found)?
2773                     #  Y - index back from most recent (by 1 if bare minus)
2774                     #  N - go to that particular command slot or the last
2775                     #      thing if nothing following.
2776                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2777
2778                     # Pick out the command desired.
2779                     $cmd = $hist[$i];
2780
2781                     # Print the command to be executed and restart the loop
2782                     # with that command in the buffer.
2783                     print $OUT $cmd, "\n";
2784                     redo CMD;
2785                 }
2786
2787 =head4 C<$sh$sh> - C<system()> command
2788
2789 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2790 C<STDOUT> from getting messed up.
2791
2792 =cut
2793
2794                 # $sh$sh - run a shell command (if it's all ASCII).
2795                 # Can't run shell commands with Unicode in the debugger, hmm.
2796                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2797
2798                     # System it.
2799                     &system($arg);
2800                     next CMD;
2801                 }
2802
2803 =head4 C<$rc I<pattern> $rc> - Search command history
2804
2805 Another command to manipulate C<@hist>: this one searches it with a pattern.
2806 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2807
2808 =cut
2809
2810                 # $rc pattern $rc - find a command in the history.
2811                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2812
2813                     # Create the pattern to use.
2814                     $pat = "^$arg";
2815
2816                     # Toss off last entry if length is >1 (and it always is).
2817                     pop(@hist) if length($cmd) > 1;
2818
2819                     # Look backward through the history.
2820                     for ( $i = $#hist ; $i ; --$i ) {
2821                         # Stop if we find it.
2822                         last if $hist[$i] =~ /$pat/;
2823                     }
2824
2825                     if ( !$i ) {
2826
2827                         # Never found it.
2828                         print $OUT "No such command!\n\n";
2829                         next CMD;
2830                     }
2831
2832                     # Found it. Put it in the buffer, print it, and process it.
2833                     $cmd = $hist[$i];
2834                     print $OUT $cmd, "\n";
2835                     redo CMD;
2836                 }
2837
2838 =head4 C<$sh> - Invoke a shell
2839
2840 Uses C<DB::system> to invoke a shell.
2841
2842 =cut
2843
2844                 # $sh - start a shell.
2845                 if ($cmd =~ /\A$sh\z/) {
2846
2847                     # Run the user's shell. If none defined, run Bourne.
2848                     # We resume execution when the shell terminates.
2849                     &system( $ENV{SHELL} || "/bin/sh" );
2850                     next CMD;
2851                 }
2852
2853 =head4 C<$sh I<command>> - Force execution of a command in a shell
2854
2855 Like the above, but the command is passed to the shell. Again, we use
2856 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2857
2858 =cut
2859
2860                 # $sh command - start a shell and run a command in it.
2861                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2862
2863                     # XXX: using csh or tcsh destroys sigint retvals!
2864                     #&system($1);  # use this instead
2865
2866                     # use the user's shell, or Bourne if none defined.
2867                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2868                     next CMD;
2869                 }
2870
2871 =head4 C<H> - display commands in history
2872
2873 Prints the contents of C<@hist> (if any).
2874
2875 =cut
2876
2877                 if ($cmd =~ /\AH\b\s*\*/) {
2878                     @hist = @truehist = ();
2879                     print $OUT "History cleansed\n";
2880                     next CMD;
2881                 }
2882
2883                 if (my ($num)
2884                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
2885
2886                     # Anything other than negative numbers is ignored by
2887                     # the (incorrect) pattern, so this test does nothing.
2888                     $end = $num ? ( $#hist - $num ) : 0;
2889
2890                     # Set to the minimum if less than zero.
2891                     $hist = 0 if $hist < 0;
2892
2893                     # Start at the end of the array.
2894                     # Stay in while we're still above the ending value.
2895                     # Tick back by one each time around the loop.
2896                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2897
2898                         # Print the command  unless it has no arguments.
2899                         print $OUT "$i: ", $hist[$i], "\n"
2900                           unless $hist[$i] =~ /^.?$/;
2901                     }
2902                     next CMD;
2903                 }
2904
2905 =head4 C<man, doc, perldoc> - look up documentation
2906
2907 Just calls C<runman()> to print the appropriate document.
2908
2909 =cut
2910
2911                 # man, perldoc, doc - show manual pages.
2912                 if (my ($man_page)
2913                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
2914                     runman($man_page);
2915                     next CMD;
2916                 }
2917
2918 =head4 C<p> - print
2919
2920 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2921 the bottom of the loop.
2922
2923 =cut
2924
2925                 my $print_cmd = 'print {$DB::OUT} ';
2926                 # p - print (no args): print $_.
2927                 if ($cmd eq 'p') {
2928                     $cmd = $print_cmd . '$_';
2929                 }
2930
2931                 # p - print the given expression.
2932                 $cmd =~ s/\Ap\b/$print_cmd /;
2933
2934 =head4 C<=> - define command alias
2935
2936 Manipulates C<%alias> to add or list command aliases.
2937
2938 =cut
2939
2940                 # = - set up a command alias.
2941                 if ($cmd =~ s/\A=\s*//) {
2942                     my @keys;
2943                     if ( length $cmd == 0 ) {
2944
2945                         # No args, get current aliases.
2946                         @keys = sort keys %alias;
2947                     }
2948                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
2949
2950                         # Creating a new alias. $k is alias name, $v is
2951                         # alias value.
2952
2953                         # can't use $_ or kill //g state
2954                         for my $x ( $k, $v ) {
2955
2956                             # Escape "alarm" characters.
2957                             $x =~ s/\a/\\a/g;
2958                         }
2959
2960                         # Substitute key for value, using alarm chars
2961                         # as separators (which is why we escaped them in
2962                         # the command).
2963                         $alias{$k} = "s\a$k\a$v\a";
2964
2965                         # Turn off standard warn and die behavior.
2966                         local $SIG{__DIE__};
2967                         local $SIG{__WARN__};
2968
2969                         # Is it valid Perl?
2970                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
2971
2972                             # Nope. Bad alias. Say so and get out.
2973                             print $OUT "Can't alias $k to $v: $@\n";
2974                             delete $alias{$k};
2975                             next CMD;
2976                         }
2977
2978                         # We'll only list the new one.
2979                         @keys = ($k);
2980                     } ## end elsif (my ($k, $v) = ($cmd...
2981
2982                     # The argument is the alias to list.
2983                     else {
2984                         @keys = ($cmd);
2985                     }
2986
2987                     # List aliases.
2988                     for my $k (@keys) {
2989
2990                         # Messy metaquoting: Trim the substitution code off.
2991                         # We use control-G as the delimiter because it's not
2992                         # likely to appear in the alias.
2993                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
2994
2995                             # Print the alias.
2996                             print $OUT "$k\t= $1\n";
2997                         }
2998                         elsif ( defined $alias{$k} ) {
2999
3000                             # Couldn't trim it off; just print the alias code.
3001                             print $OUT "$k\t$alias{$k}\n";
3002                         }
3003                         else {
3004
3005                             # No such, dude.
3006                             print "No alias for $k\n";
3007                         }
3008                     } ## end for my $k (@keys)
3009                     next CMD;
3010                 }
3011
3012 =head4 C<source> - read commands from a file.
3013
3014 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3015 pick it up.
3016
3017 =cut
3018
3019                 # source - read commands from a file (or pipe!) and execute.
3020                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3021                     if ( open my $fh, $sourced_fn ) {
3022
3023                         # Opened OK; stick it in the list of file handles.
3024                         push @cmdfhs, $fh;
3025                     }
3026                     else {
3027
3028                         # Couldn't open it.
3029                         &warn("Can't execute '$sourced_fn': $!\n");
3030                     }
3031                     next CMD;
3032                 }
3033
3034                 if (my ($which_cmd, $position)
3035                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3036
3037                     my ($fn, $line_num);
3038                     if ($position =~ m{\A\d+\z})
3039                     {
3040                         $fn = $filename;
3041                         $line_num = $position;
3042                     }
3043                     elsif (my ($new_fn, $new_line_num)
3044                         = $position =~ m{\A(.*):(\d+)\z}) {
3045                         ($fn, $line_num) = ($new_fn, $new_line_num);
3046                     }
3047                     else
3048                     {
3049                         &warn("Wrong spec for enable/disable argument.\n");
3050                     }
3051
3052                     if (defined($fn)) {
3053                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3054                             _set_breakpoint_enabled_status($fn, $line_num,
3055                                 ($which_cmd eq 'enable' ? 1 : '')
3056                             );
3057                         }
3058                         else {
3059                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3060                         }
3061                     }
3062
3063                     next CMD;
3064                 }
3065
3066 =head4 C<save> - send current history to a file
3067
3068 Takes the complete history, (not the shrunken version you see with C<H>),
3069 and saves it to the given filename, so it can be replayed using C<source>.
3070
3071 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3072
3073 =cut
3074
3075                 # save source - write commands to a file for later use
3076                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3077                     my $filename = $new_fn || '.perl5dbrc';    # default?
3078                     if ( open my $fh, '>', $filename ) {
3079
3080                        # chomp to remove extraneous newlines from source'd files
3081                         chomp( my @truelist =
3082                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3083                               @truehist );
3084                         print $fh join( "\n", @truelist );
3085                         print "commands saved in $file\n";
3086                     }
3087                     else {
3088                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3089                     }
3090                     next CMD;
3091                 }
3092
3093 =head4 C<R> - restart
3094
3095 Restart the debugger session.
3096
3097 =head4 C<rerun> - rerun the current session
3098
3099 Return to any given position in the B<true>-history list
3100
3101 =cut
3102
3103                 # R - restart execution.
3104                 # rerun - controlled restart execution.
3105                 if (my ($cmd_cmd, $cmd_params) =
3106                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3107                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3108
3109                     # Close all non-system fds for a clean restart.  A more
3110                     # correct method would be to close all fds that were not
3111                     # open when the process started, but this seems to be
3112                     # hard.  See "debugger 'R'estart and open database
3113                     # connections" on p5p.
3114
3115                     my $max_fd = 1024; # default if POSIX can't be loaded
3116                     if (eval { require POSIX }) {
3117                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3118                     }
3119
3120                     if (defined $max_fd) {
3121                         foreach ($^F+1 .. $max_fd-1) {
3122                             next unless open FD_TO_CLOSE, "<&=$_";
3123                             close(FD_TO_CLOSE);
3124                         }
3125                     }
3126
3127                     # And run Perl again.  We use exec() to keep the
3128                     # PID stable (and that way $ini_pids is still valid).
3129                     exec(@args) || print $OUT "exec failed: $!\n";
3130
3131                     last CMD;
3132                 }
3133
3134 =head4 C<|, ||> - pipe output through the pager.
3135
3136 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3137 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3138 pipe to the pager (restoring the output filehandles if this fails). If this
3139 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3140 set C<$signal>, sending us back into the debugger.
3141
3142 We then trim off the pipe symbols and C<redo> the command loop at the
3143 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3144 reading another.
3145
3146 =cut
3147
3148                 # || - run command in the pager, with output to DB::OUT.
3149                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3150                     if ( $pager =~ /^\|/ ) {
3151
3152                         # Default pager is into a pipe. Redirect I/O.
3153                         open( SAVEOUT, ">&STDOUT" )
3154                           || &warn("Can't save STDOUT");
3155                         open( STDOUT, ">&OUT" )
3156                           || &warn("Can't redirect STDOUT");
3157                     } ## end if ($pager =~ /^\|/)
3158                     else {
3159
3160                         # Not into a pipe. STDOUT is safe.
3161                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3162                     }
3163
3164                     # Fix up environment to record we have less if so.
3165                     fix_less();
3166
3167                     unless ( $piped = open( OUT, $pager ) ) {
3168
3169                         # Couldn't open pipe to pager.
3170                         &warn("Can't pipe output to '$pager'");
3171                         if ( $pager =~ /^\|/ ) {
3172
3173                             # Redirect I/O back again.
3174                             open( OUT, ">&STDOUT" )    # XXX: lost message
3175                               || &warn("Can't restore DB::OUT");
3176                             open( STDOUT, ">&SAVEOUT" )
3177                               || &warn("Can't restore STDOUT");
3178                             close(SAVEOUT);
3179                         } ## end if ($pager =~ /^\|/)
3180                         else {
3181
3182                             # Redirect I/O. STDOUT already safe.
3183                             open( OUT, ">&STDOUT" )    # XXX: lost message
3184                               || &warn("Can't restore DB::OUT");
3185                         }
3186                         next CMD;
3187                     } ## end unless ($piped = open(OUT,...
3188
3189                     # Set up broken-pipe handler if necessary.
3190                     $SIG{PIPE} = \&DB::catch
3191                       if $pager =~ /^\|/
3192                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3193
3194                     OUT->autoflush(1);
3195                     # Save current filehandle, and put it back.
3196                     $selected = select(OUT);
3197                     # Don't put it back if pager was a pipe.
3198                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3199
3200                     # Trim off the pipe symbols and run the command now.
3201                     $cmd =~ s#\A\|+\s*##;
3202                     redo PIPE;
3203                 }
3204
3205 =head3 END OF COMMAND PARSING
3206
3207 Anything left in C<$cmd> at this point is a Perl expression that we want to
3208 evaluate. We'll always evaluate in the user's context, and fully qualify
3209 any variables we might want to address in the C<DB> package.
3210
3211 =cut
3212
3213                 # t - turn trace on.
3214                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3215                     my $trace_arg = $1;
3216                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3217                 }
3218
3219                 # s - single-step. Remember the last command was 's'.
3220                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3221                     $laststep = 's';
3222                 }
3223
3224                 # n - single-step, but not into subs. Remember last command
3225                 # was 'n'.
3226                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3227                     $laststep = 'n';
3228                 }
3229
3230             }    # PIPE:
3231
3232             # Make sure the flag that says "the debugger's running" is
3233             # still on, to make sure we get control again.
3234             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3235
3236             # Run *our* eval that executes in the caller's context.
3237             DB::eval();
3238
3239             # Turn off the one-time-dump stuff now.
3240             if ($onetimeDump) {
3241                 $onetimeDump      = undef;
3242                 $onetimedumpDepth = undef;
3243             }
3244             elsif ( $term_pid == $$ ) {
3245                 eval { # May run under miniperl, when not available...
3246                     STDOUT->flush();
3247                     STDERR->flush();
3248                 };
3249
3250                 # XXX If this is the master pid, print a newline.
3251                 print {$OUT} "\n";
3252             }
3253         } ## end while (($term || &setterm...
3254
3255 =head3 POST-COMMAND PROCESSING
3256
3257 After each command, we check to see if the command output was piped anywhere.
3258 If so, we go through the necessary code to unhook the pipe and go back to
3259 our standard filehandles for input and output.
3260
3261 =cut
3262
3263         continue {    # CMD:
3264
3265             # At the end of every command:
3266             if ($piped) {
3267
3268                 # Unhook the pipe mechanism now.
3269                 if ( $pager =~ /^\|/ ) {
3270
3271                     # No error from the child.
3272                     $? = 0;
3273
3274                     # we cannot warn here: the handle is missing --tchrist
3275                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3276
3277                     # most of the $? crud was coping with broken cshisms
3278                     # $? is explicitly set to 0, so this never runs.
3279                     if ($?) {
3280                         print SAVEOUT "Pager '$pager' failed: ";
3281                         if ( $? == -1 ) {
3282                             print SAVEOUT "shell returned -1\n";
3283                         }
3284                         elsif ( $? >> 8 ) {
3285                             print SAVEOUT ( $? & 127 )
3286                               ? " (SIG#" . ( $? & 127 ) . ")"
3287                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3288                         }
3289                         else {
3290                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3291                         }
3292                     } ## end if ($?)
3293
3294                     # Reopen filehandle for our output (if we can) and
3295                     # restore STDOUT (if we can).
3296                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3297                     open( STDOUT, ">&SAVEOUT" )
3298                       || &warn("Can't restore STDOUT");
3299
3300                     # Turn off pipe exception handler if necessary.
3301                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3302
3303                     # Will stop ignoring SIGPIPE if done like nohup(1)
3304                     # does SIGINT but Perl doesn't give us a choice.
3305                 } ## end if ($pager =~ /^\|/)
3306                 else {
3307
3308                     # Non-piped "pager". Just restore STDOUT.
3309                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3310                 }
3311
3312                 # Close filehandle pager was using, restore the normal one
3313                 # if necessary,
3314                 close(SAVEOUT);
3315                 select($selected), $selected = "" unless $selected eq "";
3316
3317                 # No pipes now.
3318                 $piped = "";
3319             } ## end if ($piped)
3320         }    # CMD:
3321
3322 =head3 COMMAND LOOP TERMINATION
3323
3324 When commands have finished executing, we come here. If the user closed the
3325 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3326 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3327 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3328 The interpreter will then execute the next line and then return control to us
3329 again.
3330
3331 =cut
3332
3333         # No more commands? Quit.
3334         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3335
3336         # Evaluate post-prompt commands.
3337         foreach $evalarg (@$post) {
3338             DB::eval();
3339         }
3340     }    # if ($single || $signal)
3341
3342     # Put the user's globals back where you found them.
3343     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3344     ();
3345 } ## end sub DB
3346
3347 package DB::Obj;
3348
3349 sub new {
3350     my $class = shift;
3351
3352     my $self = bless {}, $class;
3353
3354     $self->_init(@_);
3355
3356     return $self;
3357 }
3358
3359 sub _init {
3360     my ($self, $args) = @_;
3361
3362     %{$self} = (%$self, %$args);
3363
3364     return;
3365 }
3366
3367 {
3368     no strict 'refs';
3369     foreach my $slot_name (qw(after explicit_stop infix position prefix)) {
3370         my $slot = $slot_name;
3371         *{$slot} = sub {
3372             my $self = shift;
3373
3374             if (@_) {
3375                 ${ $self->{$slot} } = shift;
3376             }
3377
3378             return ${ $self->{$slot} };
3379         };
3380
3381         *{"append_to_$slot"} = sub {
3382             my $self = shift;
3383             my $s = shift;
3384
3385             return $self->$slot($self->$slot . $s);
3386         };
3387     }
3388 }
3389
3390 sub _DB_on_init__initialize_globals
3391 {
3392     my $self = shift;
3393
3394     # Check for whether we should be running continuously or not.
3395     # _After_ the perl program is compiled, $single is set to 1:
3396     if ( $single and not $second_time++ ) {
3397
3398         # Options say run non-stop. Run until we get an interrupt.
3399         if ($runnonstop) {    # Disable until signal
3400                 # If there's any call stack in place, turn off single
3401                 # stepping into subs throughout the stack.
3402             for my $i (0 .. $stack_depth) {
3403                 $stack[ $i ] &= ~1;
3404             }
3405
3406             # And we are now no longer in single-step mode.
3407             $single = 0;
3408
3409             # If we simply returned at this point, we wouldn't get
3410             # the trace info. Fall on through.
3411             # return;
3412         } ## end if ($runnonstop)
3413
3414         elsif ($ImmediateStop) {
3415
3416             # We are supposed to stop here; XXX probably a break.
3417             $ImmediateStop = 0;    # We've processed it; turn it off
3418             $signal        = 1;    # Simulate an interrupt to force
3419                                    # us into the command loop
3420         }
3421     } ## end if ($single and not $second_time...
3422
3423     # If we're in single-step mode, or an interrupt (real or fake)
3424     # has occurred, turn off non-stop mode.
3425     $runnonstop = 0 if $single or $signal;
3426
3427     return;
3428 }
3429
3430 sub _DB__handle_watch_expressions
3431 {
3432     my $self = shift;
3433
3434     if ( $trace & 2 ) {
3435         for my $n (0 .. $#to_watch) {
3436             $evalarg = $to_watch[$n];
3437             local $onetimeDump;    # Tell DB::eval() to not output results
3438
3439             # Fix context DB::eval() wants to return an array, but
3440             # we need a scalar here.
3441             my ($val) = join( "', '", DB::eval() );
3442             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3443
3444             # Did it change?
3445             if ( $val ne $old_watch[$n] ) {
3446
3447                 # Yep! Show the difference, and fake an interrupt.
3448                 $signal = 1;
3449                 print {$OUT} <<EOP;
3450 Watchpoint $n:\t$to_watch[$n] changed:
3451     old value:\t$old_watch[$n]
3452     new value:\t$val
3453 EOP
3454                 $old_watch[$n] = $val;
3455             } ## end if ($val ne $old_watch...
3456         } ## end for my $n (0 ..
3457     } ## end if ($trace & 2)
3458
3459     return;
3460 }
3461
3462 sub _my_print_lineinfo
3463 {
3464     my ($self, $i, $incr_pos) = @_;
3465
3466     if ($frame) {
3467         # Print it indented if tracing is on.
3468         DB::print_lineinfo( ' ' x $stack_depth,
3469             "$i:\t$DB::dbline[$i]" . $self->after );
3470     }
3471     else {
3472         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3473     }
3474 }
3475
3476 sub _curr_line {
3477     return $DB::dbline[$line];
3478 }
3479
3480 sub _DB__grab_control
3481 {
3482     my $self = shift;
3483
3484     # Yes, grab control.
3485     if ($slave_editor) {
3486
3487         # Tell the editor to update its position.
3488         $self->position("\032\032${DB::filename}:$line:0\n");
3489         DB::print_lineinfo($self->position());
3490     }
3491
3492 =pod
3493
3494 Special check: if we're in package C<DB::fake>, we've gone through the
3495 C<END> block at least once. We set up everything so that we can continue
3496 to enter commands and have a valid context to be in.
3497
3498 =cut
3499
3500     elsif ( $DB::package eq 'DB::fake' ) {
3501
3502         # Fallen off the end already.
3503         if (!$DB::term) {
3504             DB::setterm();
3505         }
3506
3507         DB::print_help(<<EOP);
3508 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3509 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3510 B<h q>, B<h R> or B<h o> to get additional info.
3511 EOP
3512
3513         # Set the DB::eval context appropriately.
3514         $DB::package     = 'main';
3515         $DB::usercontext = DB::_calc_usercontext($DB::package);
3516     } ## end elsif ($package eq 'DB::fake')
3517
3518 =pod
3519
3520 If the program hasn't finished executing, we scan forward to the
3521 next executable line, print that out, build the prompt from the file and line
3522 number information, and print that.
3523
3524 =cut
3525
3526     else {
3527
3528
3529         # Still somewhere in the midst of execution. Set up the
3530         #  debugger prompt.
3531         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3532                              # Perl 5 ones (sorry, we don't print Klingon
3533                              #module names)
3534
3535         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3536         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3537         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3538
3539         # Break up the prompt if it's really long.
3540         if ( length($self->prefix()) > 30 ) {
3541             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3542             $self->prefix("");
3543             $self->infix(":\t");
3544         }
3545         else {
3546             $self->infix("):\t");
3547             $self->position(
3548                 $self->prefix . $line. $self->infix
3549                 . $self->_curr_line . $self->after
3550             );
3551         }
3552
3553         # Print current line info, indenting if necessary.
3554         $self->_my_print_lineinfo($line, $self->position);
3555
3556         my $i;
3557         my $line_i = sub { return $DB::dbline[$i]; };
3558
3559         # Scan forward, stopping at either the end or the next
3560         # unbreakable line.
3561         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3562         {    #{ vi
3563
3564             # Drop out on null statements, block closers, and comments.
3565             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3566
3567             # Drop out if the user interrupted us.
3568             last if $signal;
3569
3570             # Append a newline if the line doesn't have one. Can happen
3571             # in eval'ed text, for instance.
3572             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3573
3574             # Next executable line.
3575             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3576                 . $self->after;
3577             $self->append_to_position($incr_pos);
3578             $self->_my_print_lineinfo($i, $incr_pos);
3579         } ## end for ($i = $line + 1 ; $i...
3580     } ## end else [ if ($slave_editor)
3581
3582     return;
3583 }
3584
3585 sub _handle_t_command {
3586     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3587         $trace ^= 1;
3588         local $\ = '';
3589         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3590         print {$OUT} "Trace = "
3591         . ( ( $trace & 1 )
3592             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3593             : "off" ) . "\n";
3594         next CMD;
3595     }
3596
3597     return;
3598 }
3599
3600
3601 sub _handle_S_command {
3602     if (my ($print_all_subs, $should_reverse, $Spatt)
3603         = $DB::cmd =~ /\AS(\s+(!)?(.+))?\z/) {
3604         # $Spatt is the pattern (if any) to use.
3605         # Reverse scan?
3606         my $Srev     = defined $should_reverse;
3607         # No args - print all subs.
3608         my $Snocheck = !defined $print_all_subs;
3609
3610         # Need to make these sane here.
3611         local $\ = '';
3612         local $, = '';
3613
3614         # Search through the debugger's magical hash of subs.
3615         # If $nocheck is true, just print the sub name.
3616         # Otherwise, check it against the pattern. We then use
3617         # the XOR trick to reverse the condition as required.
3618         foreach $subname ( sort( keys %sub ) ) {
3619             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3620                 print $OUT $subname, "\n";
3621             }
3622         }
3623         next CMD;
3624     }
3625
3626     return;
3627 }
3628
3629 sub _handle_V_command_and_X_command {
3630
3631     $DB::cmd =~ s/^X\b/V $DB::package/;
3632
3633     # Bare V commands get the currently-being-debugged package
3634     # added.
3635     if ($DB::cmd eq "V") {
3636         $DB::cmd = "V $DB::package";
3637     }
3638
3639     # V - show variables in package.
3640     if (my ($new_packname, $new_vars_str) =
3641         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3642
3643         # Save the currently selected filehandle and
3644         # force output to debugger's filehandle (dumpvar
3645         # just does "print" for output).
3646         my $savout = select($OUT);
3647
3648         # Grab package name and variables to dump.
3649         $packname = $new_packname;
3650         my @vars     = split( ' ', $new_vars_str );
3651
3652         # If main::dumpvar isn't here, get it.
3653         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3654         if ( defined &main::dumpvar ) {
3655
3656             # We got it. Turn off subroutine entry/exit messages
3657             # for the moment, along with return values.
3658             local $frame = 0;
3659             local $doret = -2;
3660
3661             # must detect sigpipe failures  - not catching
3662             # then will cause the debugger to die.
3663             eval {
3664                 &main::dumpvar(
3665                     $packname,
3666                     defined $option{dumpDepth}
3667                     ? $option{dumpDepth}
3668                     : -1,    # assume -1 unless specified
3669                     @vars
3670                 );
3671             };
3672
3673             # The die doesn't need to include the $@, because
3674             # it will automatically get propagated for us.
3675             if ($@) {
3676                 die unless $@ =~ /dumpvar print failed/;
3677             }
3678         } ## end if (defined &main::dumpvar)
3679         else {
3680
3681             # Couldn't load dumpvar.
3682             print $OUT "dumpvar.pl not available.\n";
3683         }
3684
3685         # Restore the output filehandle, and go round again.
3686         select($savout);
3687         next CMD;
3688     }
3689
3690     return;
3691 }
3692
3693 sub _handle_dash_command {
3694
3695     if ($DB::cmd eq '-') {
3696
3697         # back up by a window; go to 1 if back too far.
3698         $start -= $incr + $window + 1;
3699         $start = 1 if $start <= 0;
3700         $incr  = $window - 1;
3701
3702         # Generate and execute a "l +" command (handled below).
3703         $DB::cmd = 'l ' . ($start) . '+';
3704     }
3705     return;
3706 }
3707
3708 package DB;
3709
3710 # The following code may be executed now:
3711 # BEGIN {warn 4}
3712
3713 =head2 sub
3714
3715 C<sub> is called whenever a subroutine call happens in the program being
3716 debugged. The variable C<$DB::sub> contains the name of the subroutine
3717 being called.
3718
3719 The core function of this subroutine is to actually call the sub in the proper
3720 context, capturing its output. This of course causes C<DB::DB> to get called
3721 again, repeating until the subroutine ends and returns control to C<DB::sub>
3722 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3723 return value, and returns its captured copy of the return value as its own
3724 return value. The value then feeds back into the program being debugged as if
3725 C<DB::sub> hadn't been there at all.
3726
3727 C<sub> does all the work of printing the subroutine entry and exit messages
3728 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3729 and also prints the return value if needed (for the C<r> command and if
3730 the 16 bit is set in C<$frame>).
3731
3732 It also tracks the subroutine call depth by saving the current setting of
3733 C<$single> in the C<@stack> package global; if this exceeds the value in
3734 C<$deep>, C<sub> automatically turns on printing of the current depth by
3735 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3736 of stop/don't stop on entry to subs set as it currently is set.
3737
3738 =head3 C<caller()> support
3739
3740 If C<caller()> is called from the package C<DB>, it provides some
3741 additional data, in the following order:
3742
3743 =over 4
3744
3745 =item * C<$package>
3746
3747 The package name the sub was in
3748
3749 =item * C<$filename>
3750
3751 The filename it was defined in
3752
3753 =item * C<$line>
3754
3755 The line number it was defined on
3756
3757 =item * C<$subroutine>
3758
3759 The subroutine name; C<(eval)> if an C<eval>().
3760
3761 =item * C<$hasargs>
3762
3763 1 if it has arguments, 0 if not
3764
3765 =item * C<$wantarray>
3766
3767 1 if array context, 0 if scalar context
3768
3769 =item * C<$evaltext>
3770
3771 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3772
3773 =item * C<$is_require>
3774
3775 frame was created by a C<use> or C<require> statement
3776
3777 =item * C<$hints>
3778
3779 pragma information; subject to change between versions
3780
3781 =item * C<$bitmask>
3782
3783 pragma information; subject to change between versions
3784
3785 =item * C<@DB::args>
3786
3787 arguments with which the subroutine was invoked
3788
3789 =back
3790
3791 =cut
3792
3793 use vars qw($deep);
3794
3795 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3796 # happy. -- Shlomi Fish
3797 sub DB::sub {
3798     # Do not use a regex in this subroutine -> results in corrupted memory
3799     # See: [perl #66110]
3800
3801     # lock ourselves under threads
3802     lock($DBGR);
3803
3804     # Whether or not the autoloader was running, a scalar to put the
3805     # sub's return value in (if needed), and an array to put the sub's
3806     # return value in (if needed).
3807     my ( $al, $ret, @ret ) = "";
3808     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3809         print "creating new thread\n";
3810     }
3811
3812     # If the last ten characters are '::AUTOLOAD', note we've traced
3813     # into AUTOLOAD for $sub.
3814     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3815         no strict 'refs';
3816         $al = " for $$sub" if defined $$sub;
3817     }
3818
3819     # We stack the stack pointer and then increment it to protect us
3820     # from a situation that might unwind a whole bunch of call frames
3821     # at once. Localizing the stack pointer means that it will automatically
3822     # unwind the same amount when multiple stack frames are unwound.
3823     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3824
3825     # Expand @stack.
3826     $#stack = $stack_depth;
3827
3828     # Save current single-step setting.
3829     $stack[-1] = $single;
3830
3831     # Turn off all flags except single-stepping.
3832     $single &= 1;
3833
3834     # If we've gotten really deeply recursed, turn on the flag that will
3835     # make us stop with the 'deep recursion' message.
3836     $single |= 4 if $stack_depth == $deep;
3837
3838     # If frame messages are on ...
3839     (
3840         $frame & 4    # Extended frame entry message
3841         ? (
3842             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3843
3844             # Why -1? But it works! :-(
3845             # Because print_trace will call add 1 to it and then call
3846             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3847             # in dump_trace.
3848             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3849           )
3850         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3851
3852           # standard frame entry message
3853       )
3854       if $frame;
3855
3856     # Determine the sub's return type, and capture appropriately.
3857     if (wantarray) {
3858
3859         # Called in array context. call sub and capture output.
3860         # DB::DB will recursively get control again if appropriate; we'll come
3861         # back here when the sub is finished.
3862         {
3863             no strict 'refs';
3864             @ret = &$sub;
3865         }
3866
3867         # Pop the single-step value back off the stack.
3868         $single |= $stack[ $stack_depth-- ];
3869
3870         # Check for exit trace messages...
3871         (
3872             $frame & 4    # Extended exit message
3873             ? (
3874                 print_lineinfo( ' ' x $stack_depth, "out " ),
3875                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3876               )
3877             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3878
3879               # Standard exit message
3880           )
3881           if $frame & 2;
3882
3883         # Print the return info if we need to.
3884         if ( $doret eq $stack_depth or $frame & 16 ) {
3885
3886             # Turn off output record separator.
3887             local $\ = '';
3888             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3889
3890             # Indent if we're printing because of $frame tracing.
3891             print $fh ' ' x $stack_depth if $frame & 16;
3892
3893             # Print the return value.
3894             print $fh "list context return from $sub:\n";
3895             dumpit( $fh, \@ret );
3896
3897             # And don't print it again.
3898             $doret = -2;
3899         } ## end if ($doret eq $stack_depth...
3900             # And we have to return the return value now.
3901         @ret;
3902     } ## end if (wantarray)
3903
3904     # Scalar context.
3905     else {
3906         if ( defined wantarray ) {
3907             no strict 'refs';
3908             # Save the value if it's wanted at all.
3909             $ret = &$sub;
3910         }
3911         else {
3912             no strict 'refs';
3913             # Void return, explicitly.
3914             &$sub;
3915             undef $ret;
3916         }
3917
3918         # Pop the single-step value off the stack.
3919         $single |= $stack[ $stack_depth-- ];
3920
3921         # If we're doing exit messages...
3922         (
3923             $frame & 4    # Extended messages
3924             ? (
3925                 print_lineinfo( ' ' x $stack_depth, "out " ),
3926                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3927               )
3928             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3929
3930               # Standard messages
3931           )
3932           if $frame & 2;
3933
3934         # If we are supposed to show the return value... same as before.
3935         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3936             local $\ = '';
3937             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3938             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3939             print $fh (
3940                 defined wantarray
3941                 ? "scalar context return from $sub: "
3942                 : "void context return from $sub\n"
3943             );
3944             dumpit( $fh, $ret ) if defined wantarray;
3945             $doret = -2;
3946         } ## end if ($doret eq $stack_depth...
3947
3948         # Return the appropriate scalar value.
3949         $ret;
3950     } ## end else [ if (wantarray)
3951 } ## end sub _sub
3952
3953 sub lsub : lvalue {
3954
3955     no strict 'refs';
3956
3957     # lock ourselves under threads
3958     lock($DBGR);
3959
3960     # Whether or not the autoloader was running, a scalar to put the
3961     # sub's return value in (if needed), and an array to put the sub's
3962     # return value in (if needed).
3963     my ( $al, $ret, @ret ) = "";
3964     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3965         print "creating new thread\n";
3966     }
3967
3968     # If the last ten characters are C'::AUTOLOAD', note we've traced
3969     # into AUTOLOAD for $sub.
3970     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3971         $al = " for $$sub";
3972     }
3973
3974     # We stack the stack pointer and then increment it to protect us
3975     # from a situation that might unwind a whole bunch of call frames
3976     # at once. Localizing the stack pointer means that it will automatically
3977     # unwind the same amount when multiple stack frames are unwound.
3978     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3979
3980     # Expand @stack.
3981     $#stack = $stack_depth;
3982
3983     # Save current single-step setting.
3984     $stack[-1] = $single;
3985
3986     # Turn off all flags except single-stepping.
3987     $single &= 1;
3988
3989     # If we've gotten really deeply recursed, turn on the flag that will
3990     # make us stop with the 'deep recursion' message.
3991     $single |= 4 if $stack_depth == $deep;
3992
3993     # If frame messages are on ...
3994     (
3995         $frame & 4    # Extended frame entry message
3996         ? (
3997             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3998
3999             # Why -1? But it works! :-(
4000             # Because print_trace will call add 1 to it and then call
4001             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4002             # in dump_trace.
4003             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4004           )
4005         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
4006
4007           # standard frame entry message
4008       )
4009       if $frame;
4010
4011     # Pop the single-step value back off the stack.
4012     $single |= $stack[ $stack_depth-- ];
4013
4014     # call the original lvalue sub.
4015     &$sub;
4016 }
4017
4018 # Abstracting common code from multiple places elsewhere:
4019 sub depth_print_lineinfo {
4020     my $always_print = shift;
4021
4022     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4023 }
4024
4025 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4026
4027 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4028 Most of the changes were to systematize the command structure and to eliminate
4029 commands that threw away user input without checking.
4030
4031 The following sections describe the code added to make it easy to support
4032 multiple command sets with conflicting command names. This section is a start
4033 at unifying all command processing to make it simpler to develop commands.
4034
4035 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4036 number, and C<$dbline> (the current line) as arguments.
4037
4038 Support functions in this section which have multiple modes of failure C<die>
4039 on error; the rest simply return a false value.
4040
4041 The user-interface functions (all of the C<cmd_*> functions) just output
4042 error messages.
4043
4044 =head2 C<%set>
4045
4046 The C<%set> hash defines the mapping from command letter to subroutine
4047 name suffix.
4048
4049 C<%set> is a two-level hash, indexed by set name and then by command name.
4050 Note that trying to set the CommandSet to C<foobar> simply results in the
4051 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4052
4053 =cut
4054
4055 ### The API section
4056
4057 my %set = (    #
4058     'pre580' => {
4059         'a' => 'pre580_a',
4060         'A' => 'pre580_null',
4061         'b' => 'pre580_b',
4062         'B' => 'pre580_null',
4063         'd' => 'pre580_null',
4064         'D' => 'pre580_D',
4065         'h' => 'pre580_h',
4066         'M' => 'pre580_null',
4067         'O' => 'o',
4068         'o' => 'pre580_null',
4069         'v' => 'M',
4070         'w' => 'v',
4071         'W' => 'pre580_W',
4072     },
4073     'pre590' => {
4074         '<'  => 'pre590_prepost',
4075         '<<' => 'pre590_prepost',
4076         '>'  => 'pre590_prepost',
4077         '>>' => 'pre590_prepost',
4078         '{'  => 'pre590_prepost',
4079         '{{' => 'pre590_prepost',
4080     },
4081 );
4082
4083 my %breakpoints_data;
4084
4085 sub _has_breakpoint_data_ref {
4086     my ($filename, $line) = @_;
4087
4088     return (
4089         exists( $breakpoints_data{$filename} )
4090             and
4091         exists( $breakpoints_data{$filename}{$line} )
4092     );
4093 }
4094
4095 sub _get_breakpoint_data_ref {
4096     my ($filename, $line) = @_;
4097
4098     return ($breakpoints_data{$filename}{$line} ||= +{});
4099 }
4100
4101 sub _delete_breakpoint_data_ref {
4102     my ($filename, $line) = @_;
4103
4104     delete($breakpoints_data{$filename}{$line});
4105     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4106         delete($breakpoints_data{$filename});
4107     }
4108
4109     return;
4110 }
4111
4112 sub _set_breakpoint_enabled_status {
4113     my ($filename, $line, $status) = @_;
4114
4115     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4116         ($status ? 1 : '')
4117         ;
4118
4119     return;
4120 }
4121
4122 sub _enable_breakpoint_temp_enabled_status {
4123     my ($filename, $line) = @_;
4124
4125     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4126
4127     return;
4128 }
4129
4130 sub _cancel_breakpoint_temp_enabled_status {
4131     my ($filename, $line) = @_;
4132
4133     my $ref = _get_breakpoint_data_ref($filename, $line);
4134
4135     delete ($ref->{'temp_enabled'});
4136
4137     if (! %$ref) {
4138         _delete_breakpoint_data_ref($filename, $line);
4139     }
4140
4141     return;
4142 }
4143
4144 sub _is_breakpoint_enabled {
4145     my ($filename, $line) = @_;
4146
4147     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4148     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4149 }
4150
4151 =head2 C<cmd_wrapper()> (API)
4152
4153 C<cmd_wrapper()> allows the debugger to switch command sets
4154 depending on the value of the C<CommandSet> option.
4155
4156 It tries to look up the command in the C<%set> package-level I<lexical>
4157 (which means external entities can't fiddle with it) and create the name of
4158 the sub to call based on the value found in the hash (if it's there). I<All>
4159 of the commands to be handled in a set have to be added to C<%set>; if they
4160 aren't found, the 5.8.0 equivalent is called (if there is one).
4161
4162 This code uses symbolic references.
4163
4164 =cut
4165
4166 sub cmd_wrapper {
4167     my $cmd      = shift;
4168     my $line     = shift;
4169     my $dblineno = shift;
4170
4171     # Assemble the command subroutine's name by looking up the
4172     # command set and command name in %set. If we can't find it,
4173     # default to the older version of the command.
4174     my $call = 'cmd_'
4175       . ( $set{$CommandSet}{$cmd}
4176           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4177
4178     # Call the command subroutine, call it by name.
4179     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4180 } ## end sub cmd_wrapper
4181
4182 =head3 C<cmd_a> (command)
4183
4184 The C<a> command handles pre-execution actions. These are associated with a
4185 particular line, so they're stored in C<%dbline>. We default to the current
4186 line if none is specified.
4187
4188 =cut
4189
4190 sub cmd_a {
4191     my $cmd    = shift;
4192     my $line   = shift || '';    # [.|line] expr
4193     my $dbline = shift;
4194
4195     # If it's dot (here), or not all digits,  use the current line.
4196     $line =~ s/\A\./$dbline/;
4197
4198     # Should be a line number followed by an expression.
4199     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4200
4201         if (! length($lineno)) {
4202             $lineno = $dbline;
4203         }
4204
4205         # If we have an expression ...
4206         if ( length $expr ) {
4207
4208             # ... but the line isn't breakable, complain.
4209             if ( $dbline[$lineno] == 0 ) {
4210                 print $OUT
4211                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4212             }
4213             else {
4214
4215                 # It's executable. Record that the line has an action.
4216                 $had_breakpoints{$filename} |= 2;
4217
4218                 # Remove any action, temp breakpoint, etc.
4219                 $dbline{$lineno} =~ s/\0[^\0]*//;
4220
4221                 # Add the action to the line.
4222                 $dbline{$lineno} .= "\0" . action($expr);
4223
4224                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4225             }
4226         } ## end if (length $expr)
4227     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4228     else {
4229
4230         # Syntax wrong.
4231         print $OUT
4232           "Adding an action requires an optional lineno and an expression\n"
4233           ;    # hint
4234     }
4235 } ## end sub cmd_a
4236
4237 =head3 C<cmd_A> (command)
4238
4239 Delete actions. Similar to above, except the delete code is in a separate
4240 subroutine, C<delete_action>.
4241
4242 =cut
4243
4244 sub cmd_A {
4245     my $cmd    = shift;
4246     my $line   = shift || '';
4247     my $dbline = shift;
4248
4249     # Dot is this line.
4250     $line =~ s/^\./$dbline/;
4251
4252     # Call delete_action with a null param to delete them all.
4253     # The '1' forces the eval to be true. It'll be false only
4254     # if delete_action blows up for some reason, in which case
4255     # we print $@ and get out.
4256     if ( $line eq '*' ) {
4257         if (! eval { _delete_all_actions(); 1 }) {
4258             print {$OUT} $@;
4259             return;
4260         }
4261     }
4262
4263     # There's a real line  number. Pass it to delete_action.
4264     # Error trapping is as above.
4265     elsif ( $line =~ /^(\S.*)/ ) {
4266         if (! eval { delete_action($1); 1 }) {
4267             print {$OUT} $@;
4268             return;
4269         }
4270     }
4271
4272     # Swing and a miss. Bad syntax.
4273     else {
4274         print $OUT
4275           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4276     }
4277 } ## end sub cmd_A
4278
4279 =head3 C<delete_action> (API)
4280
4281 C<delete_action> accepts either a line number or C<undef>. If a line number
4282 is specified, we check for the line being executable (if it's not, it
4283 couldn't have had an  action). If it is, we just take the action off (this
4284 will get any kind of an action, including breakpoints).
4285
4286 =cut
4287
4288 sub _remove_action_from_dbline {
4289     my $i = shift;
4290
4291     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4292     delete $dbline{$i} if $dbline{$i} eq '';
4293
4294     return;
4295 }
4296
4297 sub _delete_all_actions {
4298     print {$OUT} "Deleting all actions...\n";
4299
4300     for my $file ( keys %had_breakpoints ) {
4301         local *dbline = $main::{ '_<' . $file };
4302         $max = $#dbline;
4303         my $was;
4304         for my $i (1 .. $max) {
4305             if ( defined $dbline{$i} ) {
4306                 _remove_action_from_dbline($i);
4307             }
4308         }
4309
4310         unless ( $had_breakpoints{$file} &= ~2 ) {
4311             delete $had_breakpoints{$file};
4312         }
4313     }
4314
4315     return;
4316 }
4317
4318 sub delete_action {
4319     my $i = shift;
4320
4321     if ( defined($i) ) {
4322         # Can there be one?
4323         die "Line $i has no action .\n" if $dbline[$i] == 0;
4324
4325         # Nuke whatever's there.
4326         _remove_action_from_dbline($i);
4327     }
4328     else {
4329         _delete_all_actions();
4330     }
4331 }
4332
4333 =head3 C<cmd_b> (command)
4334
4335 Set breakpoints. Since breakpoints can be set in so many places, in so many
4336 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4337 we try to parse the command type, and then shuttle it off to an appropriate
4338 subroutine to actually do the work of setting the breakpoint in the right
4339 place.
4340
4341 =cut
4342
4343 sub cmd_b {
4344     my $cmd    = shift;
4345     my $line   = shift;    # [.|line] [cond]
4346     my $dbline = shift;
4347
4348     my $default_cond = sub {
4349         my $cond = shift;
4350         return length($cond) ? $cond : '1';
4351     };
4352
4353     # Make . the current line number if it's there..
4354     $line =~ s/^\.(\s|\z)/$dbline$1/;
4355
4356     # No line number, no condition. Simple break on current line.
4357     if ( $line =~ /^\s*$/ ) {
4358         cmd_b_line( $dbline, 1 );
4359     }
4360
4361     # Break on load for a file.
4362     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4363         $file =~ s/\s+\z//;
4364         cmd_b_load($file);
4365     }
4366
4367     # b compile|postpone <some sub> [<condition>]
4368     # The interpreter actually traps this one for us; we just put the
4369     # necessary condition in the %postponed hash.
4370     elsif ( my ($action, $subname, $cond)
4371         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4372
4373         # De-Perl4-ify the name - ' separators to ::.
4374         $subname =~ s/'/::/g;
4375
4376         # Qualify it into the current package unless it's already qualified.
4377         $subname = "${package}::" . $subname unless $subname =~ /::/;
4378
4379         # Add main if it starts with ::.
4380         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4381
4382         # Save the break type for this sub.
4383         $postponed{$subname} = (($action eq 'postpone')
4384             ? ( "break +0 if " . $default_cond->($cond) )
4385             : "compile");
4386     } ## end elsif ($line =~ ...
4387     # b <filename>:<line> [<condition>]
4388     elsif (my ($filename, $line_num, $cond)
4389         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4390         cmd_b_filename_line(
4391             $filename,
4392             $line_num,
4393             (length($cond) ? $cond : '1'),
4394         );
4395     }
4396     # b <sub name> [<condition>]
4397     elsif ( my ($new_subname, $new_cond) =
4398         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4399
4400         #
4401         $subname = $new_subname;
4402         cmd_b_sub( $subname, $default_cond->($new_cond) );
4403     }
4404
4405     # b <line> [<condition>].
4406     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4407
4408         # Capture the line. If none, it's the current line.
4409         $line = $line_n || $dbline;
4410
4411         # Break on line.
4412         cmd_b_line( $line, $default_cond->($cond) );
4413     }
4414
4415     # Line didn't make sense.
4416     else {
4417         print "confused by line($line)?\n";
4418     }
4419
4420     return;
4421 } ## end sub cmd_b
4422
4423 =head3 C<break_on_load> (API)
4424
4425 We want to break when this file is loaded. Mark this file in the
4426 C<%break_on_load> hash, and note that it has a breakpoint in
4427 C<%had_breakpoints>.
4428
4429 =cut
4430
4431 sub break_on_load {
4432     my $file = shift;
4433     $break_on_load{$file} = 1;
4434     $had_breakpoints{$file} |= 1;
4435 }
4436
4437 =head3 C<report_break_on_load> (API)
4438
4439 Gives us an array of filenames that are set to break on load. Note that
4440 only files with break-on-load are in here, so simply showing the keys
4441 suffices.
4442
4443 =cut
4444
4445 sub report_break_on_load {
4446     sort keys %break_on_load;
4447 }
4448
4449 =head3 C<cmd_b_load> (command)
4450
4451 We take the file passed in and try to find it in C<%INC> (which maps modules
4452 to files they came from). We mark those files for break-on-load via
4453 C<break_on_load> and then report that it was done.
4454
4455 =cut
4456
4457 sub cmd_b_load {
4458     my $file = shift;
4459     my @files;
4460
4461     # This is a block because that way we can use a redo inside it
4462     # even without there being any looping structure at all outside it.
4463     {
4464
4465         # Save short name and full path if found.
4466         push @files, $file;
4467         push @files, $::INC{$file} if $::INC{$file};
4468
4469         # Tack on .pm and do it again unless there was a '.' in the name
4470         # already.
4471         $file .= '.pm', redo unless $file =~ /\./;
4472     }
4473
4474     # Do the real work here.
4475     break_on_load($_) for @files;
4476
4477     # All the files that have break-on-load breakpoints.
4478     @files = report_break_on_load;
4479
4480     # Normalize for the purposes of our printing this.
4481     local $\ = '';
4482     local $" = ' ';
4483     print $OUT "Will stop on load of '@files'.\n";
4484 } ## end sub cmd_b_load
4485
4486 =head3 C<$filename_error> (API package global)
4487
4488 Several of the functions we need to implement in the API need to work both
4489 on the current file and on other files. We don't want to duplicate code, so
4490 C<$filename_error> is used to contain the name of the file that's being
4491 worked on (if it's not the current one).
4492
4493 We can now build functions in pairs: the basic function works on the current
4494 file, and uses C<$filename_error> as part of its error message. Since this is
4495 initialized to C<"">, no filename will appear when we are working on the
4496 current file.
4497
4498 The second function is a wrapper which does the following:
4499
4500 =over 4
4501
4502 =item *
4503
4504 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4505
4506 =item *
4507
4508 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4509
4510 =item *
4511
4512 Calls the first function.
4513
4514 The first function works on the I<current> file (i.e., the one we changed to),
4515 and prints C<$filename_error> in the error message (the name of the other file)
4516 if it needs to. When the functions return, C<*dbline> is restored to point
4517 to the actual current file (the one we're executing in) and
4518 C<$filename_error> is restored to C<"">. This restores everything to
4519 the way it was before the second function was called at all.
4520
4521 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4522 details.
4523
4524 =back
4525
4526 =cut
4527
4528 use vars qw($filename_error);
4529 $filename_error = '';
4530
4531 =head3 breakable_line(from, to) (API)
4532
4533 The subroutine decides whether or not a line in the current file is breakable.
4534 It walks through C<@dbline> within the range of lines specified, looking for
4535 the first line that is breakable.
4536
4537 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4538 first line I<after> C<$to> that's breakable, if there is one.
4539
4540 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4541 first line I<before> C<$to> that's breakable, if there is one.
4542
4543 =cut
4544
4545 sub breakable_line {
4546
4547     my ( $from, $to ) = @_;
4548
4549     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4550     my $i = $from;
4551
4552     # If there are at least 2 arguments, we're trying to search a range.
4553     if ( @_ >= 2 ) {
4554
4555         # $delta is positive for a forward search, negative for a backward one.
4556         my $delta = $from < $to ? +1 : -1;
4557
4558         # Keep us from running off the ends of the file.
4559         my $limit = $delta > 0 ? $#dbline : 1;
4560
4561         # Clever test. If you're a mathematician, it's obvious why this
4562         # test works. If not:
4563         # If $delta is positive (going forward), $limit will be $#dbline.
4564         #    If $to is less than $limit, ($limit - $to) will be positive, times
4565         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4566         #    as the stopping point.
4567         #
4568         #    If $to is greater than $limit, ($limit - $to) is negative,
4569         #    times $delta of 1 (positive), so the result is < 0 and we should
4570         #    use $limit ($#dbline) as the stopping point.
4571         #
4572         # If $delta is negative (going backward), $limit will be 1.
4573         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4574         #    (negative) so the result is > 0, and we use $to as the stopping
4575         #    point.
4576         #
4577         #    If $to is less than zero, ($limit - $to) will be positive,
4578         #    times $delta of -1 (negative), so the result is not > 0, and
4579         #    we use $limit (1) as the stopping point.
4580         #
4581         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4582         #    (negative), still giving zero; the result is not > 0, and
4583         #    we use $limit (1) as the stopping point.
4584         #
4585         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4586         #    (negative), giving a positive (>0) value, so we'll set $limit to
4587         #    $to.
4588
4589         $limit = $to if ( $limit - $to ) * $delta > 0;
4590
4591         # The real search loop.
4592         # $i starts at $from (the point we want to start searching from).
4593         # We move through @dbline in the appropriate direction (determined
4594         # by $delta: either -1 (back) or +1 (ahead).
4595         # We stay in as long as we haven't hit an executable line
4596         # ($dbline[$i] == 0 means not executable) and we haven't reached
4597         # the limit yet (test similar to the above).
4598         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4599
4600     } ## end if (@_ >= 2)
4601
4602     # If $i points to a line that is executable, return that.
4603     return $i unless $dbline[$i] == 0;
4604
4605     # Format the message and print it: no breakable lines in range.
4606     my ( $pl, $upto ) = ( '', '' );
4607     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4608
4609     # If there's a filename in filename_error, we'll see it.
4610     # If not, not.
4611     die "Line$pl $from$upto$filename_error not breakable\n";
4612 } ## end sub breakable_line
4613
4614 =head3 breakable_line_in_filename(file, from, to) (API)
4615
4616 Like C<breakable_line>, but look in another file.
4617
4618 =cut
4619
4620 sub breakable_line_in_filename {
4621
4622     # Capture the file name.
4623     my ($f) = shift;
4624
4625     # Swap the magic line array over there temporarily.
4626     local *dbline = $main::{ '_<' . $f };
4627
4628     # If there's an error, it's in this other file.
4629     local $filename_error = " of '$f'";
4630
4631     # Find the breakable line.
4632     breakable_line(@_);
4633
4634     # *dbline and $filename_error get restored when this block ends.
4635
4636 } ## end sub breakable_line_in_filename
4637
4638 =head3 break_on_line(lineno, [condition]) (API)
4639
4640 Adds a breakpoint with the specified condition (or 1 if no condition was
4641 specified) to the specified line. Dies if it can't.
4642
4643 =cut
4644
4645 sub break_on_line {
4646     my $i = shift;
4647     my $cond = @_ ? shift(@_) : 1;
4648
4649     my $inii  = $i;
4650     my $after = '';
4651     my $pl    = '';
4652
4653     # Woops, not a breakable line. $filename_error allows us to say
4654     # if it was in a different file.
4655     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4656
4657     # Mark this file as having breakpoints in it.
4658     $had_breakpoints{$filename} |= 1;
4659
4660     # If there is an action or condition here already ...
4661     if ( $dbline{$i} ) {
4662
4663         # ... swap this condition for the existing one.
4664         $dbline{$i} =~ s/^[^\0]*/$cond/;
4665     }
4666     else {
4667
4668         # Nothing here - just add the condition.
4669         $dbline{$i} = $cond;
4670
4671         _set_breakpoint_enabled_status($filename, $i, 1);
4672     }
4673
4674     return;
4675 } ## end sub break_on_line
4676
4677 =head3 cmd_b_line(line, [condition]) (command)
4678
4679 Wrapper for C<break_on_line>. Prints the failure message if it
4680 doesn't work.
4681
4682 =cut
4683
4684 sub cmd_b_line {
4685     if (not eval { break_on_line(@_); 1 }) {
4686         local $\ = '';
4687         print $OUT $@ and return;
4688     }
4689
4690     return;
4691 } ## end sub cmd_b_line
4692
4693 =head3 cmd_b_filename_line(line, [condition]) (command)
4694
4695 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4696 doesn't work.
4697
4698 =cut
4699
4700 sub cmd_b_filename_line {
4701     if (not eval { break_on_filename_line(@_); 1 }) {
4702         local $\ = '';
4703         print $OUT $@ and return;
4704     }
4705
4706     return;
4707 }
4708
4709 =head3 break_on_filename_line(file, line, [condition]) (API)
4710
4711 Switches to the file specified and then calls C<break_on_line> to set
4712 the breakpoint.
4713
4714 =cut
4715
4716 sub break_on_filename_line {
4717     my $f = shift;
4718     my $i = shift;
4719     my $cond = @_ ? shift(@_) : 1;
4720
4721     # Switch the magical hash temporarily.
4722     local *dbline = $main::{ '_<' . $f };
4723
4724     # Localize the variables that break_on_line uses to make its message.
4725     local $filename_error = " of '$f'";
4726     local $filename       = $f;
4727
4728     # Add the breakpoint.
4729     break_on_line( $i, $cond );
4730
4731     return;
4732 } ## end sub break_on_filename_line
4733
4734 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4735
4736 Switch to another file, search the range of lines specified for an
4737 executable one, and put a breakpoint on the first one you find.
4738
4739 =cut
4740
4741 sub break_on_filename_line_range {
4742     my $f = shift;
4743     my $from = shift;
4744     my $to = shift;
4745     my $cond = @_ ? shift(@_) : 1;
4746
4747     # Find a breakable line if there is one.
4748     my $i = breakable_line_in_filename( $f, $from, $to );
4749
4750     # Add the breakpoint.
4751     break_on_filename_line( $f, $i, $cond );
4752
4753     return;
4754 } ## end sub break_on_filename_line_range
4755
4756 =head3 subroutine_filename_lines(subname, [condition]) (API)
4757
4758 Search for a subroutine within a given file. The condition is ignored.
4759 Uses C<find_sub> to locate the desired subroutine.
4760
4761 =cut
4762
4763 sub subroutine_filename_lines {
4764     my ( $subname ) = @_;
4765
4766     # Returned value from find_sub() is fullpathname:startline-endline.
4767     # The match creates the list (fullpathname, start, end).
4768     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
4769 } ## end sub subroutine_filename_lines
4770
4771 =head3 break_subroutine(subname) (API)
4772
4773 Places a break on the first line possible in the specified subroutine. Uses
4774 C<subroutine_filename_lines> to find the subroutine, and
4775 C<break_on_filename_line_range> to place the break.
4776
4777 =cut
4778
4779 sub break_subroutine {
4780     my $subname = shift;
4781
4782     # Get filename, start, and end.
4783     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4784       or die "Subroutine $subname not found.\n";
4785
4786
4787     # Null condition changes to '1' (always true).
4788     my $cond = @_ ? shift(@_) : 1;
4789
4790     # Put a break the first place possible in the range of lines
4791     # that make up this subroutine.
4792     break_on_filename_line_range( $file, $s, $e, $cond );
4793
4794     return;
4795 } ## end sub break_subroutine
4796
4797 =head3 cmd_b_sub(subname, [condition]) (command)
4798
4799 We take the incoming subroutine name and fully-qualify it as best we can.
4800
4801 =over 4
4802
4803 =item 1. If it's already fully-qualified, leave it alone.
4804
4805 =item 2. Try putting it in the current package.
4806
4807 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4808
4809 =item 4. If it starts with '::', put it in 'main::'.
4810
4811 =back
4812
4813 After all this cleanup, we call C<break_subroutine> to try to set the
4814 breakpoint.
4815
4816 =cut
4817
4818 sub cmd_b_sub {
4819     my ( $subname, $cond ) = @_;
4820
4821     # Add always-true condition if we have none.
4822     $cond = 1 unless @_ >= 2;
4823
4824     # If the subname isn't a code reference, qualify it so that
4825     # break_subroutine() will work right.
4826     unless ( ref $subname eq 'CODE' ) {
4827
4828         # Not Perl4.
4829         $subname =~ s/\'/::/g;
4830         my $s = $subname;
4831
4832         # Put it in this package unless it's already qualified.
4833         $subname = "${package}::" . $subname
4834           unless $subname =~ /::/;
4835
4836         # Requalify it into CORE::GLOBAL if qualifying it into this
4837         # package resulted in its not being defined, but only do so
4838         # if it really is in CORE::GLOBAL.
4839         $subname = "CORE::GLOBAL::$s"
4840           if not defined &$subname
4841           and $s !~ /::/
4842           and defined &{"CORE::GLOBAL::$s"};
4843
4844         # Put it in package 'main' if it has a leading ::.
4845         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4846
4847     } ## end unless (ref $subname eq 'CODE')
4848
4849     # Try to set the breakpoint.
4850     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
4851         local $\ = '';
4852         print $OUT $@ and return;
4853     }
4854
4855     return;
4856 } ## end sub cmd_b_sub
4857
4858 =head3 C<cmd_B> - delete breakpoint(s) (command)
4859
4860 The command mostly parses the command line and tries to turn the argument
4861 into a line spec. If it can't, it uses the current line. It then calls
4862 C<delete_breakpoint> to actually do the work.
4863
4864 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4865 thereby deleting all the breakpoints.
4866
4867 =cut
4868
4869 sub cmd_B {
4870     my $cmd = shift;
4871
4872     # No line spec? Use dbline.
4873     # If there is one, use it if it's non-zero, or wipe it out if it is.
4874     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
4875     my $dbline = shift;
4876
4877     # If the line was dot, make the line the current one.
4878     $line =~ s/^\./$dbline/;
4879
4880     # If it's * we're deleting all the breakpoints.
4881     if ( $line eq '*' ) {
4882         if (not eval { delete_breakpoint(); 1 }) {
4883             print {$OUT} $@;
4884         }
4885     }
4886
4887     # If there is a line spec, delete the breakpoint on that line.
4888     elsif ( $line =~ /\A(\S.*)/ ) {
4889         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
4890             local $\ = '';
4891             print {$OUT} $@;
4892         }
4893     } ## end elsif ($line =~ /^(\S.*)/)
4894
4895     # No line spec.
4896     else {
4897         print {$OUT}
4898           "Deleting a breakpoint requires a line number, or '*' for all\n"
4899           ;    # hint
4900     }
4901
4902     return;
4903 } ## end sub cmd_B
4904
4905 =head3 delete_breakpoint([line]) (API)
4906
4907 This actually does the work of deleting either a single breakpoint, or all
4908 of them.
4909
4910 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4911 just drop out with a message saying so. If it is, we remove the condition
4912 part of the 'condition\0action' that says there's a breakpoint here. If,
4913 after we've done that, there's nothing left, we delete the corresponding
4914 line in C<%dbline> to signal that no action needs to be taken for this line.
4915
4916 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4917 which lists all currently-loaded files which have breakpoints. We then look
4918 at each line in each of these files, temporarily switching the C<%dbline>
4919 and C<@dbline> structures to point to the files in question, and do what
4920 we did in the single line case: delete the condition in C<@dbline>, and
4921 delete the key in C<%dbline> if nothing's left.
4922
4923 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4924 C<%break_on_load>, because these structures contain breakpoints for files
4925 and code that haven't been loaded yet. We can just kill these off because there
4926 are no magical debugger structures associated with them.
4927
4928 =cut
4929
4930 sub _remove_breakpoint_entry {
4931     my ($fn, $i) = @_;
4932
4933     delete $dbline{$i};
4934     _delete_breakpoint_data_ref($fn, $i);
4935
4936     return;
4937 }
4938
4939 sub _delete_all_breakpoints {
4940     print {$OUT} "Deleting all breakpoints...\n";
4941
4942     # %had_breakpoints lists every file that had at least one
4943     # breakpoint in it.
4944     for my $fn ( keys %had_breakpoints ) {
4945
4946         # Switch to the desired file temporarily.
4947         local *dbline = $main::{ '_<' . $fn };
4948
4949         $max = $#dbline;
4950
4951         # For all lines in this file ...
4952         for my $i (1 .. $max) {
4953
4954             # If there's a breakpoint or action on this line ...
4955             if ( defined $dbline{$i} ) {
4956
4957                 # ... remove the breakpoint.
4958                 $dbline{$i} =~ s/\A[^\0]+//;
4959                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
4960                     # Remove the entry altogether if no action is there.
4961                     _remove_breakpoint_entry($fn, $i);
4962                 }
4963             } ## end if (defined $dbline{$i...
4964         } ## end for $i (1 .. $max)
4965
4966         # If, after we turn off the "there were breakpoints in this file"
4967         # bit, the entry in %had_breakpoints for this file is zero,
4968         # we should remove this file from the hash.
4969         if ( not $had_breakpoints{$fn} &= (~1) ) {
4970             delete $had_breakpoints{$fn};
4971         }
4972     } ## end for my $fn (keys %had_breakpoints)
4973
4974     # Kill off all the other breakpoints that are waiting for files that
4975     # haven't been loaded yet.
4976     undef %postponed;
4977     undef %postponed_file;
4978     undef %break_on_load;
4979
4980     return;
4981 }
4982
4983 sub _delete_breakpoint_from_line {
4984     my ($i) = @_;
4985
4986     # Woops. This line wasn't breakable at all.
4987     die "Line $i not breakable.\n" if $dbline[$i] == 0;
4988
4989     # Kill the condition, but leave any action.
4990     $dbline{$i} =~ s/\A[^\0]*//;
4991
4992     # Remove the entry entirely if there's no action left.
4993     if ($dbline{$i} eq '') {
4994         _remove_breakpoint_entry($filename, $i);
4995     }
4996
4997     return;
4998 }
4999
5000 sub delete_breakpoint {
5001     my $i = shift;
5002
5003     # If we got a line, delete just that one.
5004     if ( defined($i) ) {
5005         _delete_breakpoint_from_line($i);
5006     }
5007     # No line; delete them all.
5008     else {
5009         _delete_all_breakpoints();
5010     }
5011
5012     return;
5013 }
5014
5015 =head3 cmd_stop (command)
5016
5017 This is meant to be part of the new command API, but it isn't called or used
5018 anywhere else in the debugger. XXX It is probably meant for use in development
5019 of new commands.
5020
5021 =cut
5022
5023 sub cmd_stop {    # As on ^C, but not signal-safy.
5024     $signal = 1;
5025 }
5026
5027 =head3 C<cmd_e> - threads
5028
5029 Display the current thread id:
5030
5031     e
5032
5033 This could be how (when implemented) to send commands to this thread id (e cmd)
5034 or that thread id (e tid cmd).
5035
5036 =cut
5037
5038 sub cmd_e {
5039     my $cmd  = shift;
5040     my $line = shift;
5041     unless (exists($INC{'threads.pm'})) {
5042         print "threads not loaded($ENV{PERL5DB_THREADED})
5043         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5044     } else {
5045         my $tid = threads->tid;
5046         print "thread id: $tid\n";
5047     }
5048 } ## end sub cmd_e
5049
5050 =head3 C<cmd_E> - list of thread ids
5051
5052 Display the list of available thread ids:
5053
5054     E
5055
5056 This could be used (when implemented) to send commands to all threads (E cmd).
5057
5058 =cut
5059
5060 sub cmd_E {
5061     my $cmd  = shift;
5062     my $line = shift;
5063     unless (exists($INC{'threads.pm'})) {
5064         print "threads not loaded($ENV{PERL5DB_THREADED})
5065         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5066     } else {
5067         my $tid = threads->tid;
5068         print "thread ids: ".join(', ',
5069             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5070         )."\n";
5071     }
5072 } ## end sub cmd_E
5073
5074 =head3 C<cmd_h> - help command (command)
5075
5076 Does the work of either
5077
5078 =over 4
5079
5080 =item *
5081
5082 Showing all the debugger help
5083
5084 =item *
5085
5086 Showing help for a specific command
5087
5088 =back
5089
5090 =cut
5091
5092 use vars qw($help);
5093 use vars qw($summary);
5094
5095 sub cmd_h {
5096     my $cmd = shift;
5097
5098     # If we have no operand, assume null.
5099     my $line = shift || '';
5100
5101     # 'h h'. Print the long-format help.
5102     if ( $line =~ /\Ah\s*\z/ ) {
5103         print_help($help);
5104     }
5105
5106     # 'h <something>'. Search for the command and print only its help.
5107     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5108
5109         # support long commands; otherwise bogus errors
5110         # happen when you ask for h on <CR> for example
5111         my $qasked = quotemeta($asked);    # for searching; we don't
5112                                            # want to use it as a pattern.
5113                                            # XXX: finds CR but not <CR>
5114
5115         # Search the help string for the command.
5116         if (
5117             $help =~ /^                    # Start of a line
5118                       <?                   # Optional '<'
5119                       (?:[IB]<)            # Optional markup
5120                       $qasked              # The requested command
5121                      /mx
5122           )
5123         {
5124
5125             # It's there; pull it out and print it.
5126             while (
5127                 $help =~ /^
5128                               (<?            # Optional '<'
5129                                  (?:[IB]<)   # Optional markup
5130                                  $qasked     # The command
5131                                  ([\s\S]*?)  # Description line(s)
5132                               \n)            # End of last description line
5133                               (?!\s)         # Next line not starting with
5134                                              # whitespace
5135                              /mgx
5136               )
5137             {
5138                 print_help($1);
5139             }
5140         }
5141
5142         # Not found; not a debugger command.
5143         else {
5144             print_help("B<$asked> is not a debugger command.\n");
5145         }
5146     } ## end elsif ($line =~ /^(\S.*)$/)
5147
5148     # 'h' - print the summary help.
5149     else {
5150         print_help($summary);
5151     }
5152 } ## end sub cmd_h
5153
5154 =head3 C<cmd_i> - inheritance display
5155
5156 Display the (nested) parentage of the module or object given.
5157
5158 =cut
5159
5160 sub cmd_i {
5161     my $cmd  = shift;
5162     my $line = shift;
5163     foreach my $isa ( split( /\s+/, $line ) ) {
5164         $evalarg = $isa;
5165         ($isa) = DB::eval();
5166         no strict 'refs';
5167         print join(
5168             ', ',
5169             map {
5170                 "$_"
5171                   . (
5172                     defined( ${"$_\::VERSION"} )
5173                     ? ' ' . ${"$_\::VERSION"}
5174                     : undef )
5175               } @{mro::get_linear_isa(ref($isa) || $isa)}
5176         );
5177         print "\n";
5178     }
5179 } ## end sub cmd_i
5180
5181 =head3 C<cmd_l> - list lines (command)
5182
5183 Most of the command is taken up with transforming all the different line
5184 specification syntaxes into 'start-stop'. After that is done, the command
5185 runs a loop over C<@dbline> for the specified range of lines. It handles
5186 the printing of each line and any markers (C<==E<gt>> for current line,
5187 C<b> for break on this line, C<a> for action on this line, C<:> for this
5188 line breakable).
5189
5190 We save the last line listed in the C<$start> global for further listing
5191 later.
5192
5193 =cut
5194
5195 sub cmd_l {
5196     my $current_line = $line;
5197     my $cmd  = shift;
5198     my $line = shift;
5199
5200     # If this is '-something', delete any spaces after the dash.
5201     $line =~ s/^-\s*$/-/;
5202
5203     # If the line is '$something', assume this is a scalar containing a
5204     # line number.
5205     if ( $line =~ /^(\$.*)/s ) {
5206
5207         # Set up for DB::eval() - evaluate in *user* context.
5208         $evalarg = $1;
5209         # $evalarg = $2;
5210         my ($s) = DB::eval();
5211
5212         # Ooops. Bad scalar.
5213         if ($@) {
5214             print {$OUT} "Error: $@\n";
5215             next CMD;
5216         }
5217
5218         # Good scalar. If it's a reference, find what it points to.
5219         $s = CvGV_name($s);
5220         print {$OUT} "Interpreted as: $1 $s\n";
5221         $line = "$1 $s";
5222
5223         # Call self recursively to really do the command.
5224         cmd_l( 'l', $s );
5225     } ## end if ($line =~ /^(\$.*)/s)
5226
5227     # l name. Try to find a sub by that name.
5228     elsif ( ($subname) = $line =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5229         my $s = $subname;
5230
5231         # De-Perl4.
5232         $subname =~ s/\'/::/;
5233
5234         # Put it in this package unless it starts with ::.
5235         $subname = $package . "::" . $subname unless $subname =~ /::/;
5236
5237         # Put it in CORE::GLOBAL if t doesn't start with :: and
5238         # it doesn't live in this package and it lives in CORE::GLOBAL.
5239         $subname = "CORE::GLOBAL::$s"
5240           if not defined &$subname
5241           and $s !~ /::/
5242           and defined &{"CORE::GLOBAL::$s"};
5243
5244         # Put leading '::' names into 'main::'.
5245         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5246
5247         # Get name:start-stop from find_sub, and break this up at
5248         # colons.
5249         my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5250
5251         # Pull off start-stop.
5252         my $subrange = pop @pieces;
5253
5254         # If the name contained colons, the split broke it up.
5255         # Put it back together.
5256         $file = join( ':', @pieces );
5257
5258         # If we're not in that file, switch over to it.
5259         if ( $file ne $filename ) {
5260             print $OUT "Switching to file '$file'.\n"
5261               unless $slave_editor;
5262
5263             # Switch debugger's magic structures.
5264             *dbline   = $main::{ '_<' . $file };
5265             $max      = $#dbline;
5266             $filename = $file;
5267         } ## end if ($file ne $filename)
5268
5269         # Subrange is 'start-stop'. If this is less than a window full,
5270         # swap it to 'start+', which will list a window from the start point.
5271         if ($subrange) {
5272             if ( eval($subrange) < -$window ) {
5273                 $subrange =~ s/-.*/+/;
5274             }
5275
5276             # Call self recursively to list the range.
5277             $line = $subrange;
5278             cmd_l( 'l', $subrange );
5279         } ## end if ($subrange)
5280
5281         # Couldn't find it.
5282         else {
5283             print $OUT "Subroutine $subname not found.\n";
5284         }
5285     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
5286
5287     # Bare 'l' command.
5288     elsif ( $line !~ /\S/ ) {
5289
5290         # Compute new range to list.
5291         $incr = $window - 1;
5292         $line = $start . '-' . ( $start + $incr );
5293
5294         # Recurse to do it.
5295         cmd_l( 'l', $line );
5296     }
5297
5298     # l [start]+number_of_lines
5299     elsif ( my ($new_start, $new_incr) = $line =~ /\A(\d*)\+(\d*)\z/ ) {
5300
5301         # Don't reset start for 'l +nnn'.
5302         $start = $new_start if $new_start;
5303
5304         # Increment for list. Use window size if not specified.
5305         # (Allows 'l +' to work.)
5306         $incr = $new_incr;
5307         $incr = $window - 1 unless $incr;
5308
5309         # Create a line range we'll understand, and recurse to do it.
5310         $line = $start . '-' . ( $start + $incr );
5311         cmd_l( 'l', $line );
5312     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
5313
5314     # l start-stop or l start,stop
5315     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
5316
5317         # Determine end point; use end of file if not specified.
5318         my $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5319
5320         # Go on to the end, and then stop.
5321         $end = $max if $end > $max;
5322
5323         # Determine start line.
5324         my $i    = $2;
5325         $i    = $line if $i eq '.';
5326         $i    = 1 if $i < 1;
5327         $incr = $end - $i;
5328
5329         # If we're running under a slave editor, force it to show the lines.
5330         if ($slave_editor) {
5331             print $OUT "\032\032$filename:$i:0\n";
5332             $i = $end;
5333         }
5334
5335         # We're doing it ourselves. We want to show the line and special
5336         # markers for:
5337         # - the current line in execution
5338         # - whether a line is breakable or not
5339         # - whether a line has a break or not
5340         # - whether a line has an action or not
5341         else {
5342             for ( ; $i <= $end ; $i++ ) {
5343
5344                 # Check for breakpoints and actions.
5345                 my ( $stop, $action );
5346                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5347                   if $dbline{$i};
5348
5349                 # ==> if this is the current line in execution,
5350                 # : if it's breakable.
5351                 my $arrow =
5352                   ( $i == $current_line and $filename eq $filename_ini )
5353                   ? '==>'
5354                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5355
5356                 # Add break and action indicators.
5357                 $arrow .= 'b' if $stop;
5358                 $arrow .= 'a' if $action;
5359
5360                 # Print the line.
5361                 print $OUT "$i$arrow\t", $dbline[$i];
5362
5363                 # Move on to the next line. Drop out on an interrupt.
5364                 $i++, last if $signal;
5365             } ## end for (; $i <= $end ; $i++)
5366
5367             # Line the prompt up; print a newline if the last line listed
5368             # didn't have a newline.
5369             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5370         } ## end else [ if ($slave_editor)
5371
5372         # Save the point we last listed to in case another relative 'l'
5373         # command is desired. Don't let it run off the end.
5374         $start = $i;
5375         $start = $max if $start > $max;
5376     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5377 } ## end sub cmd_l
5378
5379 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5380
5381 To list breakpoints, the command has to look determine where all of them are
5382 first. It starts a C<%had_breakpoints>, which tells us what all files have
5383 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5384 magic source and breakpoint data structures) to the file, and then look
5385 through C<%dbline> for lines with breakpoints and/or actions, listing them
5386 out. We look through C<%postponed> not-yet-compiled subroutines that have
5387 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5388 that have breakpoints.
5389
5390 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5391
5392 =cut
5393
5394 sub cmd_L {
5395     my $cmd = shift;
5396
5397     # If no argument, list everything. Pre-5.8.0 version always lists
5398     # everything
5399     my $arg = shift || 'abw';
5400     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5401
5402     # See what is wanted.
5403     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5404     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5405     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5406
5407     # Breaks and actions are found together, so we look in the same place
5408     # for both.
5409     if ( $break_wanted or $action_wanted ) {
5410
5411         # Look in all the files with breakpoints...
5412         for my $file ( keys %had_breakpoints ) {
5413
5414             # Temporary switch to this file.
5415             local *dbline = $main::{ '_<' . $file };
5416
5417             # Set up to look through the whole file.
5418             $max = $#dbline;
5419             my $was;    # Flag: did we print something
5420                         # in this file?
5421
5422             # For each line in the file ...
5423             for my $i (1 .. $max) {
5424
5425                 # We've got something on this line.
5426                 if ( defined $dbline{$i} ) {
5427
5428                     # Print the header if we haven't.
5429                     print $OUT "$file:\n" unless $was++;
5430
5431                     # Print the line.
5432                     print $OUT " $i:\t", $dbline[$i];
5433
5434                     # Pull out the condition and the action.
5435                     my ( $stop, $action ) = split( /\0/, $dbline{$i} );
5436
5437                     # Print the break if there is one and it's wanted.
5438                     print $OUT "   break if (", $stop, ")\n"
5439                       if $stop
5440                       and $break_wanted;
5441
5442                     # Print the action if there is one and it's wanted.
5443                     print $OUT "   action:  ", $action, "\n"
5444                       if $action
5445                       and $action_wanted;
5446
5447                     # Quit if the user hit interrupt.
5448                     last if $signal;
5449                 } ## end if (defined $dbline{$i...
5450             } ## end for my $i (1 .. $max)
5451         } ## end for my $file (keys %had_breakpoints)
5452     } ## end if ($break_wanted or $action_wanted)
5453
5454     # Look for breaks in not-yet-compiled subs:
5455     if ( %postponed and $break_wanted ) {
5456         print $OUT "Postponed breakpoints in subroutines:\n";
5457         my $subname;
5458         for $subname ( keys %postponed ) {
5459             print $OUT " $subname\t$postponed{$subname}\n";
5460             last if $signal;
5461         }
5462     } ## end if (%postponed and $break_wanted)
5463
5464     # Find files that have not-yet-loaded breaks:
5465     my @have = map {    # Combined keys
5466         keys %{ $postponed_file{$_} }
5467     } keys %postponed_file;
5468
5469     # If there are any, list them.
5470     if ( @have and ( $break_wanted or $action_wanted ) ) {
5471         print $OUT "Postponed breakpoints in files:\n";
5472         for my $file ( keys %postponed_file ) {
5473             my $db = $postponed_file{$file};
5474             print $OUT " $file:\n";
5475             for my $line ( sort { $a <=> $b } keys %$db ) {
5476                 print $OUT "  $line:\n";
5477                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5478                 print $OUT "    break if (", $stop, ")\n"
5479                   if $stop
5480                   and $break_wanted;
5481                 print $OUT "    action:  ", $action, "\n"
5482                   if $action
5483                   and $action_wanted;
5484                 last if $signal;
5485             } ## end for $line (sort { $a <=>...
5486             last if $signal;
5487         } ## end for $file (keys %postponed_file)
5488     } ## end if (@have and ($break_wanted...
5489     if ( %break_on_load and $break_wanted ) {
5490         print {$OUT} "Breakpoints on load:\n";
5491         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5492             print {$OUT} " $filename\n";
5493             last BREAK_ON_LOAD if $signal;
5494         }
5495     } ## end if (%break_on_load and...
5496     if ($watch_wanted and ( $trace & 2 )) {
5497         print {$OUT} "Watch-expressions:\n" if @to_watch;
5498         TO_WATCH: for my $expr (@to_watch) {
5499             print {$OUT} " $expr\n";
5500             last TO_WATCH if $signal;
5501         }
5502     }
5503 } ## end sub cmd_L
5504
5505 =head3 C<cmd_M> - list modules (command)
5506
5507 Just call C<list_modules>.
5508
5509 =cut
5510
5511 sub cmd_M {
5512     list_modules();
5513
5514     return;
5515 }
5516
5517 =head3 C<cmd_o> - options (command)
5518
5519 If this is just C<o> by itself, we list the current settings via
5520 C<dump_option>. If there's a nonblank value following it, we pass that on to
5521 C<parse_options> for processing.
5522
5523 =cut
5524
5525 sub cmd_o {
5526     my $cmd = shift;
5527     my $opt = shift || '';    # opt[=val]
5528
5529     # Nonblank. Try to parse and process.
5530     if ( $opt =~ /^(\S.*)/ ) {
5531         &parse_options($1);
5532     }
5533
5534     # Blank. List the current option settings.
5535     else {
5536         for (@options) {
5537             &dump_option($_);
5538         }
5539     }
5540 } ## end sub cmd_o
5541
5542 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5543
5544 Advises the user that the O command has been renamed.
5545
5546 =cut
5547
5548 sub cmd_O {
5549     print $OUT "The old O command is now the o command.\n";             # hint
5550     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5551     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5552 }
5553
5554 =head3 C<cmd_v> - view window (command)
5555
5556 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5557 move back a few lines to list the selected line in context. Uses C<cmd_l>
5558 to do the actual listing after figuring out the range of line to request.
5559
5560 =cut
5561
5562 use vars qw($preview);
5563
5564 sub cmd_v {
5565     my $cmd  = shift;
5566     my $line = shift;
5567
5568     # Extract the line to list around. (Astute readers will have noted that
5569     # this pattern will match whether or not a numeric line is specified,
5570     # which means that we'll always enter this loop (though a non-numeric
5571     # argument results in no action at all)).
5572     if ( $line =~ /^(\d*)$/ ) {
5573
5574         # Total number of lines to list (a windowful).
5575         $incr = $window - 1;
5576
5577         # Set the start to the argument given (if there was one).
5578         $start = $1 if $1;
5579
5580         # Back up by the context amount.
5581         $start -= $preview;
5582
5583         # Put together a linespec that cmd_l will like.
5584         $line = $start . '-' . ( $start + $incr );
5585
5586         # List the lines.
5587         cmd_l( 'l', $line );
5588     } ## end if ($line =~ /^(\d*)$/)
5589 } ## end sub cmd_v
5590
5591 =head3 C<cmd_w> - add a watch expression (command)
5592
5593 The 5.8 version of this command adds a watch expression if one is specified;
5594 it does nothing if entered with no operands.
5595
5596 We extract the expression, save it, evaluate it in the user's context, and
5597 save the value. We'll re-evaluate it each time the debugger passes a line,
5598 and will stop (see the code at the top of the command loop) if the value
5599 of any of the expressions changes.
5600
5601 =cut
5602
5603 sub _add_watch_expr {
5604     my $expr = shift;
5605
5606     # ... save it.
5607     push @to_watch, $expr;
5608
5609     # Parameterize DB::eval and call it to get the expression's value
5610     # in the user's context. This version can handle expressions which
5611     # return a list value.
5612     $evalarg = $expr;
5613     my ($val) = join( ' ', DB::eval() );
5614     $val = ( defined $val ) ? "'$val'" : 'undef';
5615
5616     # Save the current value of the expression.
5617     push @old_watch, $val;
5618
5619     # We are now watching expressions.
5620     $trace |= 2;
5621
5622     return;
5623 }
5624
5625 sub cmd_w {
5626     my $cmd = shift;
5627
5628     # Null expression if no arguments.
5629     my $expr = shift || '';
5630
5631     # If expression is not null ...
5632     if ( $expr =~ /\A\S/ ) {
5633         _add_watch_expr($expr);
5634     } ## end if ($expr =~ /^(\S.*)/)
5635
5636     # You have to give one to get one.
5637     else {
5638         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5639     }
5640
5641     return;
5642 }
5643
5644 =head3 C<cmd_W> - delete watch expressions (command)
5645
5646 This command accepts either a watch expression to be removed from the list
5647 of watch expressions, or C<*> to delete them all.
5648
5649 If C<*> is specified, we simply empty the watch expression list and the
5650 watch expression value list. We also turn off the bit that says we've got
5651 watch expressions.
5652
5653 If an expression (or partial expression) is specified, we pattern-match
5654 through the expressions and remove the ones that match. We also discard
5655 the corresponding values. If no watch expressions are left, we turn off
5656 the I<watching expressions> bit.
5657
5658 =cut
5659
5660 sub cmd_W {
5661     my $cmd  = shift;
5662     my $expr = shift || '';
5663
5664     # Delete them all.
5665     if ( $expr eq '*' ) {
5666
5667         # Not watching now.
5668         $trace &= ~2;
5669
5670         print $OUT "Deleting all watch expressions ...\n";
5671
5672         # And all gone.
5673         @to_watch = @old_watch = ();
5674     }
5675
5676     # Delete one of them.
5677     elsif ( $expr =~ /^(\S.*)/ ) {
5678
5679         # Where we are in the list.
5680         my $i_cnt = 0;
5681
5682         # For each expression ...
5683         foreach (@to_watch) {
5684             my $val = $to_watch[$i_cnt];
5685
5686             # Does this one match the command argument?
5687             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5688                                       # Yes. Turn it off, and its value too.
5689                 splice( @to_watch,  $i_cnt, 1 );
5690                 splice( @old_watch, $i_cnt, 1 );
5691             }
5692             $i_cnt++;
5693         } ## end foreach (@to_watch)
5694
5695         # We don't bother to turn watching off because
5696         #  a) we don't want to stop calling watchfunction() it it exists
5697         #  b) foreach over a null list doesn't do anything anyway
5698
5699     } ## end elsif ($expr =~ /^(\S.*)/)
5700
5701     # No command arguments entered.
5702     else {
5703         print $OUT
5704           "Deleting a watch-expression requires an expression, or '*' for all\n"
5705           ;    # hint
5706     }
5707 } ## end sub cmd_W
5708
5709 ### END of the API section
5710
5711 =head1 SUPPORT ROUTINES
5712
5713 These are general support routines that are used in a number of places
5714 throughout the debugger.
5715
5716 =head2 save
5717
5718 save() saves the user's versions of globals that would mess us up in C<@saved>,
5719 and installs the versions we like better.
5720
5721 =cut
5722
5723 sub save {
5724
5725     # Save eval failure, command failure, extended OS error, output field
5726     # separator, input record separator, output record separator and
5727     # the warning setting.
5728     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5729
5730     $,  = "";      # output field separator is null string
5731     $/  = "\n";    # input record separator is newline
5732     $\  = "";      # output record separator is null string
5733     $^W = 0;       # warnings are off
5734 } ## end sub save
5735
5736 =head2 C<print_lineinfo> - show where we are now
5737
5738 print_lineinfo prints whatever it is that it is handed; it prints it to the
5739 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5740 us to feed line information to a slave editor without messing up the
5741 debugger output.
5742
5743 =cut
5744
5745 sub print_lineinfo {
5746
5747     # Make the terminal sensible if we're not the primary debugger.
5748     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5749     local $\ = '';
5750     local $, = '';
5751     print $LINEINFO @_;
5752 } ## end sub print_lineinfo
5753
5754 =head2 C<postponed_sub>
5755
5756 Handles setting postponed breakpoints in subroutines once they're compiled.
5757 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5758 range for the subroutine, then mark the file as having a breakpoint,
5759 temporarily switch the C<*dbline> glob over to the source file, and then
5760 search the given range of lines to find a breakable line. If we find one,
5761 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5762
5763 =cut
5764
5765 # The following takes its argument via $evalarg to preserve current @_
5766
5767 sub postponed_sub {
5768
5769     # Get the subroutine name.
5770     my $subname = shift;
5771
5772     # If this is a 'break +<n> if <condition>' ...
5773     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5774
5775         # If there's no offset, use '+0'.
5776         my $offset = $1 || 0;
5777
5778         # find_sub's value is 'fullpath-filename:start-stop'. It's
5779         # possible that the filename might have colons in it too.
5780         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5781         if ($i) {
5782
5783             # We got the start line. Add the offset '+<n>' from
5784             # $postponed{subname}.
5785             $i += $offset;
5786
5787             # Switch to the file this sub is in, temporarily.
5788             local *dbline = $main::{ '_<' . $file };
5789
5790             # No warnings, please.
5791             local $^W = 0;    # != 0 is magical below
5792
5793             # This file's got a breakpoint in it.
5794             $had_breakpoints{$file} |= 1;
5795
5796             # Last line in file.
5797             $max = $#dbline;
5798
5799             # Search forward until we hit a breakable line or get to
5800             # the end of the file.
5801             ++$i until $dbline[$i] != 0 or $i >= $max;
5802
5803             # Copy the breakpoint in and delete it from %postponed.
5804             $dbline{$i} = delete $postponed{$subname};
5805         } ## end if ($i)
5806
5807         # find_sub didn't find the sub.
5808         else {
5809             local $\ = '';
5810             print $OUT "Subroutine $subname not found.\n";
5811         }
5812         return;
5813     } ## end if ($postponed{$subname...
5814     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5815
5816     #print $OUT "In postponed_sub for '$subname'.\n";
5817 } ## end sub postponed_sub
5818
5819 =head2 C<postponed>
5820
5821 Called after each required file is compiled, but before it is executed;
5822 also called if the name of a just-compiled subroutine is a key of
5823 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5824 etc.) into the just-compiled code.
5825
5826 If this is a C<require>'d file, the incoming parameter is the glob
5827 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5828
5829 If it's a subroutine, the incoming parameter is the subroutine name.
5830
5831 =cut
5832
5833 sub postponed {
5834
5835     # If there's a break, process it.
5836     if ($ImmediateStop) {
5837
5838         # Right, we've stopped. Turn it off.
5839         $ImmediateStop = 0;
5840
5841         # Enter the command loop when DB::DB gets called.
5842         $signal = 1;
5843     }
5844
5845     # If this is a subroutine, let postponed_sub() deal with it.
5846     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5847
5848     # Not a subroutine. Deal with the file.
5849     local *dbline = shift;
5850     my $filename = $dbline;
5851     $filename =~ s/^_<//;
5852     local $\ = '';
5853     $signal = 1, print $OUT "'$filename' loaded...\n"
5854       if $break_on_load{$filename};
5855     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5856
5857     # Do we have any breakpoints to put in this file?
5858     return unless $postponed_file{$filename};
5859
5860     # Yes. Mark this file as having breakpoints.
5861     $had_breakpoints{$filename} |= 1;
5862
5863     # "Cannot be done: insufficient magic" - we can't just put the
5864     # breakpoints saved in %postponed_file into %dbline by assigning
5865     # the whole hash; we have to do it one item at a time for the
5866     # breakpoints to be set properly.
5867     #%dbline = %{$postponed_file{$filename}};
5868
5869     # Set the breakpoints, one at a time.
5870     my $key;
5871
5872     for $key ( keys %{ $postponed_file{$filename} } ) {
5873
5874         # Stash the saved breakpoint into the current file's magic line array.
5875         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5876     }
5877
5878     # This file's been compiled; discard the stored breakpoints.
5879     delete $postponed_file{$filename};
5880
5881 } ## end sub postponed
5882
5883 =head2 C<dumpit>
5884
5885 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5886
5887 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5888 a reference to a variable (the thing to be dumped) as its input.
5889
5890 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5891 the currently-selected filehandle, thank you very much). The current
5892 values of the package globals C<$single> and C<$trace> are backed up in
5893 lexicals, and they are turned off (this keeps the debugger from trying
5894 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5895 preserve its current value and it is set to zero to prevent entry/exit
5896 messages from printing, and C<$doret> is localized as well and set to -2 to
5897 prevent return values from being shown.
5898
5899 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5900 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5901 installed version in C<@INC>, yours will be used instead. Possible security
5902 problem?).
5903
5904 It then checks to see if the subroutine C<main::dumpValue> is now defined
5905 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5906 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5907 is called, and picks up the variable to be dumped from the parameter list.
5908
5909 It checks the package global C<%options> to see if there's a C<dumpDepth>
5910 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5911 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5912 structure: -1 means dump everything.
5913
5914 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5915 warning.
5916
5917 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5918 and we then return to the caller.
5919
5920 =cut
5921
5922 sub dumpit {
5923
5924     # Save the current output filehandle and switch to the one
5925     # passed in as the first parameter.
5926     my $savout = select(shift);
5927
5928     # Save current settings of $single and $trace, and then turn them off.
5929     my $osingle = $single;
5930     my $otrace  = $trace;
5931     $single = $trace = 0;
5932
5933     # XXX Okay, what do $frame and $doret do, again?
5934     local $frame = 0;
5935     local $doret = -2;
5936
5937     # Load dumpvar.pl unless we've already got the sub we need from it.
5938     unless ( defined &main::dumpValue ) {
5939         do 'dumpvar.pl' or die $@;
5940     }
5941
5942     # If the load succeeded (or we already had dumpvalue()), go ahead
5943     # and dump things.
5944     if ( defined &main::dumpValue ) {
5945         local $\ = '';
5946         local $, = '';
5947         local $" = ' ';
5948         my $v = shift;
5949         my $maxdepth = shift || $option{dumpDepth};
5950         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5951         &main::dumpValue( $v, $maxdepth );
5952     } ## end if (defined &main::dumpValue)
5953
5954     # Oops, couldn't load dumpvar.pl.
5955     else {
5956         local $\ = '';
5957         print $OUT "dumpvar.pl not available.\n";
5958     }
5959
5960     # Reset $single and $trace to their old values.
5961     $single = $osingle;
5962     $trace  = $otrace;
5963
5964     # Restore the old filehandle.
5965     select($savout);
5966 } ## end sub dumpit
5967
5968 =head2 C<print_trace>
5969
5970 C<print_trace>'s job is to print a stack trace. It does this via the
5971 C<dump_trace> routine, which actually does all the ferreting-out of the
5972 stack trace data. C<print_trace> takes care of formatting it nicely and
5973 printing it to the proper filehandle.
5974
5975 Parameters:
5976
5977 =over 4
5978
5979 =item *
5980
5981 The filehandle to print to.
5982
5983 =item *
5984
5985 How many frames to skip before starting trace.
5986
5987 =item *
5988
5989 How many frames to print.
5990
5991 =item *
5992
5993 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5994
5995 =back
5996
5997 The original comment below seems to be noting that the traceback may not be
5998 correct if this routine is called in a tied method.
5999
6000 =cut
6001
6002 # Tied method do not create a context, so may get wrong message:
6003
6004 sub print_trace {
6005     local $\ = '';
6006     my $fh = shift;
6007
6008     # If this is going to a slave editor, but we're not the primary
6009     # debugger, reset it first.
6010     resetterm(1)
6011       if $fh        eq $LINEINFO    # slave editor
6012       and $LINEINFO eq $OUT         # normal output
6013       and $term_pid != $$;          # not the primary
6014
6015     # Collect the actual trace information to be formatted.
6016     # This is an array of hashes of subroutine call info.
6017     my @sub = dump_trace( $_[0] + 1, $_[1] );
6018
6019     # Grab the "short report" flag from @_.
6020     my $short = $_[2];              # Print short report, next one for sub name
6021
6022     # Run through the traceback info, format it, and print it.
6023     my $s;
6024     for my $i (0 .. $#sub) {
6025
6026         # Drop out if the user has lost interest and hit control-C.
6027         last if $signal;
6028
6029         # Set the separator so arrys print nice.
6030         local $" = ', ';
6031
6032         # Grab and stringify the arguments if they are there.
6033         my $args =
6034           defined $sub[$i]{args}
6035           ? "(@{ $sub[$i]{args} })"
6036           : '';
6037
6038         # Shorten them up if $maxtrace says they're too long.
6039         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6040           if length $args > $maxtrace;
6041
6042         # Get the file name.
6043         my $file = $sub[$i]{file};
6044
6045         # Put in a filename header if short is off.
6046         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6047
6048         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6049         $s = $sub[$i]{sub};
6050         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6051
6052         # Short report uses trimmed file and sub names.
6053         if ($short) {
6054             my $sub = @_ >= 4 ? $_[3] : $s;
6055             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6056         } ## end if ($short)
6057
6058         # Non-short report includes full names.
6059         else {
6060             print $fh "$sub[$i]{context} = $s$args"
6061               . " called from $file"
6062               . " line $sub[$i]{line}\n";
6063         }
6064     } ## end for my $i (0 .. $#sub)
6065 } ## end sub print_trace
6066
6067 =head2 dump_trace(skip[,count])
6068
6069 Actually collect the traceback information available via C<caller()>. It does
6070 some filtering and cleanup of the data, but mostly it just collects it to
6071 make C<print_trace()>'s job easier.
6072
6073 C<skip> defines the number of stack frames to be skipped, working backwards
6074 from the most current. C<count> determines the total number of frames to
6075 be returned; all of them (well, the first 10^9) are returned if C<count>
6076 is omitted.
6077
6078 This routine returns a list of hashes, from most-recent to least-recent
6079 stack frame. Each has the following keys and values:
6080
6081 =over 4
6082
6083 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6084
6085 =item * C<sub> - subroutine name, or C<eval> information
6086
6087 =item * C<args> - undef, or a reference to an array of arguments
6088
6089 =item * C<file> - the file in which this item was defined (if any)
6090
6091 =item * C<line> - the line on which it was defined
6092
6093 =back
6094
6095 =cut
6096
6097 sub dump_trace {
6098
6099     # How many levels to skip.
6100     my $skip = shift;
6101
6102     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6103     # it's unlikely that we'll have more than a billion stack frames. If you
6104     # do, you've got an awfully big machine...)
6105     my $count = shift || 1e9;
6106
6107     # We increment skip because caller(1) is the first level *back* from
6108     # the current one.  Add $skip to the count of frames so we have a
6109     # simple stop criterion, counting from $skip to $count+$skip.
6110     $skip++;
6111     $count += $skip;
6112
6113     # These variables are used to capture output from caller();
6114     my ( $p, $file, $line, $sub, $h, $context );
6115
6116     my ( $e, $r, @a, @sub, $args );
6117
6118     # XXX Okay... why'd we do that?
6119     my $nothard = not $frame & 8;
6120     local $frame = 0;
6121
6122     # Do not want to trace this.
6123     my $otrace = $trace;
6124     $trace = 0;
6125
6126     # Start out at the skip count.
6127     # If we haven't reached the number of frames requested, and caller() is
6128     # still returning something, stay in the loop. (If we pass the requested
6129     # number of stack frames, or we run out - caller() returns nothing - we
6130     # quit.
6131     # Up the stack frame index to go back one more level each time.
6132     for (
6133         my $i = $skip ;
6134         $i < $count
6135         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6136         $i++
6137     )
6138     {
6139
6140         # Go through the arguments and save them for later.
6141         @a = ();
6142         for my $arg (@args) {
6143             my $type;
6144             if ( not defined $arg ) {    # undefined parameter
6145                 push @a, "undef";
6146             }
6147
6148             elsif ( $nothard and tied $arg ) {    # tied parameter
6149                 push @a, "tied";
6150             }
6151             elsif ( $nothard and $type = ref $arg ) {    # reference
6152                 push @a, "ref($type)";
6153             }
6154             else {                                       # can be stringified
6155                 local $_ =
6156                   "$arg";    # Safe to stringify now - should not call f().
6157
6158                 # Backslash any single-quotes or backslashes.
6159                 s/([\'\\])/\\$1/g;
6160
6161                 # Single-quote it unless it's a number or a colon-separated
6162                 # name.
6163                 s/(.*)/'$1'/s
6164                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6165
6166                 # Turn high-bit characters into meta-whatever.
6167                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
6168
6169                 # Turn control characters into ^-whatever.
6170                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
6171
6172                 push( @a, $_ );
6173             } ## end else [ if (not defined $arg)
6174         } ## end for $arg (@args)
6175
6176         # If context is true, this is array (@)context.
6177         # If context is false, this is scalar ($) context.
6178         # If neither, context isn't defined. (This is apparently a 'can't
6179         # happen' trap.)
6180         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6181
6182         # if the sub has args ($h true), make an anonymous array of the
6183         # dumped args.
6184         $args = $h ? [@a] : undef;
6185
6186         # remove trailing newline-whitespace-semicolon-end of line sequence
6187         # from the eval text, if any.
6188         $e =~ s/\n\s*\;\s*\Z// if $e;
6189
6190         # Escape backslashed single-quotes again if necessary.
6191         $e =~ s/([\\\'])/\\$1/g if $e;
6192
6193         # if the require flag is true, the eval text is from a require.
6194         if ($r) {
6195             $sub = "require '$e'";
6196         }
6197
6198         # if it's false, the eval text is really from an eval.
6199         elsif ( defined $r ) {
6200             $sub = "eval '$e'";
6201         }
6202
6203         # If the sub is '(eval)', this is a block eval, meaning we don't
6204         # know what the eval'ed text actually was.
6205         elsif ( $sub eq '(eval)' ) {
6206             $sub = "eval {...}";
6207         }
6208
6209         # Stick the collected information into @sub as an anonymous hash.
6210         push(
6211             @sub,
6212             {
6213                 context => $context,
6214                 sub     => $sub,
6215                 args    => $args,
6216                 file    => $file,
6217                 line    => $line
6218             }
6219         );
6220
6221         # Stop processing frames if the user hit control-C.
6222         last if $signal;
6223     } ## end for ($i = $skip ; $i < ...
6224
6225     # Restore the trace value again.
6226     $trace = $otrace;
6227     @sub;
6228 } ## end sub dump_trace
6229
6230 =head2 C<action()>
6231
6232 C<action()> takes input provided as the argument to an add-action command,
6233 either pre- or post-, and makes sure it's a complete command. It doesn't do
6234 any fancy parsing; it just keeps reading input until it gets a string
6235 without a trailing backslash.
6236
6237 =cut
6238
6239 sub action {
6240     my $action = shift;
6241
6242     while ( $action =~ s/\\$// ) {
6243
6244         # We have a backslash on the end. Read more.
6245         $action .= &gets;
6246     } ## end while ($action =~ s/\\$//)
6247
6248     # Return the assembled action.
6249     $action;
6250 } ## end sub action
6251
6252 =head2 unbalanced
6253
6254 This routine mostly just packages up a regular expression to be used
6255 to check that the thing it's being matched against has properly-matched
6256 curly braces.
6257
6258 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6259 speeds things up by only creating the qr//'ed expression once; if it's
6260 already defined, we don't try to define it again. A speed hack.
6261
6262 =cut
6263
6264 use vars qw($balanced_brace_re);
6265
6266 sub unbalanced {
6267
6268     # I hate using globals!
6269     $balanced_brace_re ||= qr{
6270         ^ \{
6271              (?:
6272                  (?> [^{}] + )              # Non-parens without backtracking
6273                 |
6274                  (??{ $balanced_brace_re }) # Group with matching parens
6275               ) *
6276           \} $
6277    }x;
6278     return $_[0] !~ m/$balanced_brace_re/;
6279 } ## end sub unbalanced
6280
6281 =head2 C<gets()>
6282
6283 C<gets()> is a primitive (very primitive) routine to read continuations.
6284 It was devised for reading continuations for actions.
6285 it just reads more input with C<readline()> and returns it.
6286
6287 =cut
6288
6289 sub gets {
6290     &readline("cont: ");
6291 }
6292
6293 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
6294
6295 The C<system()> function assumes that it can just go ahead and use STDIN and
6296 STDOUT, but under the debugger, we want it to use the debugger's input and
6297 outout filehandles.
6298
6299 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
6300 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6301 and then puts everything back again.
6302
6303 =cut
6304
6305 sub system {
6306
6307     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6308     # some non-Unix systems can do system() but have problems with fork().
6309     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
6310     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
6311     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
6312     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
6313
6314     # XXX: using csh or tcsh destroys sigint retvals!
6315     system(@_);
6316     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
6317     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
6318     close(SAVEIN);
6319     close(SAVEOUT);
6320
6321     # most of the $? crud was coping with broken cshisms
6322     if ( $? >> 8 ) {
6323         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6324     }
6325     elsif ($?) {
6326         &warn(
6327             "(Command died of SIG#",
6328             ( $? & 127 ),
6329             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6330             ")", "\n"
6331         );
6332     } ## end elsif ($?)
6333
6334     return $?;
6335
6336 } ## end sub system
6337
6338 =head1 TTY MANAGEMENT
6339
6340 The subs here do some of the terminal management for multiple debuggers.
6341
6342 =head2 setterm
6343
6344 Top-level function called when we want to set up a new terminal for use
6345 by the debugger.
6346
6347 If the C<noTTY> debugger option was set, we'll either use the terminal
6348 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6349 to find one. If we're a forked debugger, we call C<resetterm> to try to
6350 get a whole new terminal if we can.
6351
6352 In either case, we set up the terminal next. If the C<ReadLine> option was
6353 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6354 the appropriate attributes. We then
6355
6356 =cut
6357
6358 use vars qw($ornaments);
6359 use vars qw($rl_attribs);
6360
6361 sub setterm {
6362
6363     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6364     local $frame = 0;
6365     local $doret = -2;
6366     require Term::ReadLine;
6367
6368     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6369     if ($notty) {
6370         if ($tty) {
6371             my ( $i, $o ) = split $tty, /,/;
6372             $o = $i unless defined $o;
6373             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6374             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6375             $IN  = \*IN;
6376             $OUT = \*OUT;
6377             $OUT->autoflush(1);
6378         } ## end if ($tty)
6379
6380         # We don't have a TTY - try to find one via Term::Rendezvous.
6381         else {
6382             require Term::Rendezvous;
6383
6384             # See if we have anything to pass to Term::Rendezvous.
6385             # Use $HOME/.perldbtty$$ if not.
6386             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6387
6388             # Rendezvous and get the filehandles.
6389             my $term_rv = Term::Rendezvous->new( $rv );
6390             $IN  = $term_rv->IN;
6391             $OUT = $term_rv->OUT;
6392         } ## end else [ if ($tty)
6393     } ## end if ($notty)
6394
6395     # We're a daughter debugger. Try to fork off another TTY.
6396     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6397         resetterm(2);
6398     }
6399
6400     # If we shouldn't use Term::ReadLine, don't.
6401     if ( !$rl ) {
6402         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6403     }
6404
6405     # We're using Term::ReadLine. Get all the attributes for this terminal.
6406     else {
6407         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6408
6409         $rl_attribs = $term->Attribs;
6410         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6411           if defined $rl_attribs->{basic_word_break_characters}
6412           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6413         $rl_attribs->{special_prefixes} = '$@&%';
6414         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6415         $rl_attribs->{completion_function} = \&db_complete;
6416     } ## end else [ if (!$rl)
6417
6418     # Set up the LINEINFO filehandle.
6419     $LINEINFO = $OUT     unless defined $LINEINFO;
6420     $lineinfo = $console unless defined $lineinfo;
6421
6422     $term->MinLine(2);
6423
6424     &load_hist();
6425
6426     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6427         $term->SetHistory(@hist);
6428     }
6429
6430     # XXX Ornaments are turned on unconditionally, which is not
6431     # always a good thing.
6432     ornaments($ornaments) if defined $ornaments;
6433     $term_pid = $$;
6434 } ## end sub setterm
6435
6436 sub load_hist {
6437     $histfile //= option_val("HistFile", undef);
6438     return unless defined $histfile;
6439     open my $fh, "<", $histfile or return;
6440     local $/ = "\n";
6441     @hist = ();
6442     while (<$fh>) {
6443         chomp;
6444         push @hist, $_;
6445     }
6446     close $fh;
6447 }
6448
6449 sub save_hist {
6450     return unless defined $histfile;
6451     eval { require File::Path } or return;
6452     eval { require File::Basename } or return;
6453     File::Path::mkpath(File::Basename::dirname($histfile));
6454     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6455     $histsize //= option_val("HistSize",100);
6456     my @copy = grep { $_ ne '?' } @hist;
6457     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6458     for ($start .. $#copy) {
6459         print $fh "$copy[$_]\n";
6460     }
6461     close $fh or die "Could not write '$histfile': $!";
6462 }
6463
6464 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6465
6466 When the process being debugged forks, or the process invokes a command
6467 via C<system()> which starts a new debugger, we need to be able to get a new
6468 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6469 fight over the terminal, and you can never quite be sure who's going to get the
6470 input you're typing.
6471
6472 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6473 is tasked with doing all the necessary operating system mojo to get a new
6474 TTY (and probably another window) and to direct the new debugger to read and
6475 write there.
6476
6477 The debugger provides C<get_fork_TTY> functions which work for TCP
6478 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6479 supported. You are encouraged to write C<get_fork_TTY> functions which
6480 work for I<your> platform and contribute them.
6481
6482 =head3 C<socket_get_fork_TTY>
6483
6484 =cut
6485
6486 sub connect_remoteport {
6487     require IO::Socket;
6488
6489     my $socket = IO::Socket::INET->new(
6490         Timeout  => '10',
6491         PeerAddr => $remoteport,
6492         Proto    => 'tcp',
6493     );
6494     if ( ! $socket ) {
6495         die "Unable to connect to remote host: $remoteport\n";
6496     }
6497     return $socket;
6498 }
6499
6500 sub socket_get_fork_TTY {
6501     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6502
6503     # Do I need to worry about setting $term?
6504
6505     reset_IN_OUT( $IN, $OUT );
6506     return '';
6507 }
6508
6509 =head3 C<xterm_get_fork_TTY>
6510
6511 This function provides the C<get_fork_TTY> function for X11. If a
6512 program running under the debugger forks, a new <xterm> window is opened and
6513 the subsidiary debugger is directed there.
6514
6515 The C<open()> call is of particular note here. We have the new C<xterm>
6516 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6517 command (which prints the device name of the TTY we'll want to use for input
6518 and output to STDOUT, then C<sleep> for a very long time, routing this output
6519 to file number 3. This way we can simply read from the <XT> filehandle (which
6520 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6521
6522 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6523 properly set up.
6524
6525 =cut
6526
6527 sub xterm_get_fork_TTY {
6528     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6529     open XT,
6530 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6531  sleep 10000000' |];
6532
6533     # Get the output from 'tty' and clean it up a little.
6534     my $tty = <XT>;
6535     chomp $tty;
6536
6537     $pidprompt = '';    # Shown anyway in titlebar
6538
6539     # We need $term defined or we can not switch to the newly created xterm
6540     if ($tty ne '' && !defined $term) {
6541         require Term::ReadLine;
6542         if ( !$rl ) {
6543             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6544         }
6545         else {
6546             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6547         }
6548     }
6549     # There's our new TTY.
6550     return $tty;
6551 } ## end sub xterm_get_fork_TTY
6552
6553 =head3 C<os2_get_fork_TTY>
6554
6555 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6556
6557 =cut
6558
6559 # This example function resets $IN, $OUT itself
6560 my $c_pipe = 0;
6561 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6562     local $\  = '';
6563     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6564     my %opt = ( title => "Daughter Perl debugger $pids $name",
6565         ($rl ? (read_by_key => 1) : ()) );
6566     require OS2::Process;
6567     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6568       or return;
6569     $pidprompt = '';    # Shown anyway in titlebar
6570     reset_IN_OUT($in, $out);
6571     $tty = '*reset*';
6572     return '';          # Indicate that reset_IN_OUT is called
6573 } ## end sub os2_get_fork_TTY
6574
6575 =head3 C<macosx_get_fork_TTY>
6576
6577 The Mac OS X version uses AppleScript to tell Terminal.app to create
6578 a new window.
6579
6580 =cut
6581
6582 # Notes about Terminal.app's AppleScript support,
6583 # (aka things that might break in future OS versions).
6584 #
6585 # The "do script" command doesn't return a reference to the new window
6586 # it creates, but since it appears frontmost and windows are enumerated
6587 # front to back, we can use "first window" === "window 1".
6588 #
6589 # Since "do script" is implemented by supplying the argument (plus a
6590 # return character) as terminal input, there's a potential race condition
6591 # where the debugger could beat the shell to reading the command.
6592 # To prevent this, we wait for the screen to clear before proceeding.
6593 #
6594 # 10.3 and 10.4:
6595 # There's no direct accessor for the tty device name, so we fiddle
6596 # with the window title options until it says what we want.
6597 #
6598 # 10.5:
6599 # There _is_ a direct accessor for the tty device name, _and_ there's
6600 # a new possible component of the window title (the name of the settings
6601 # set).  A separate version is needed.
6602
6603 my @script_versions=
6604
6605     ([237, <<'__LEOPARD__'],
6606 tell application "Terminal"
6607     do script "clear;exec sleep 100000"
6608     tell first tab of first window
6609         copy tty to thetty
6610         set custom title to "forked perl debugger"
6611         set title displays custom title to true
6612         repeat while (length of first paragraph of (get contents)) > 0
6613             delay 0.1
6614         end repeat
6615     end tell
6616 end tell
6617 thetty
6618 __LEOPARD__
6619
6620      [100, <<'__JAGUAR_TIGER__'],
6621 tell application "Terminal"
6622     do script "clear;exec sleep 100000"
6623     tell first window
6624         set title displays shell path to false
6625         set title displays window size to false
6626         set title displays file name to false
6627         set title displays device name to true
6628         set title displays custom title to true
6629         set custom title to ""
6630         copy "/dev/" & name to thetty
6631         set custom title to "forked perl debugger"
6632         repeat while (length of first paragraph of (get contents)) > 0
6633             delay 0.1
6634         end repeat
6635     end tell
6636 end tell
6637 thetty
6638 __JAGUAR_TIGER__
6639
6640 );
6641
6642 sub macosx_get_fork_TTY
6643 {
6644     my($version,$script,$pipe,$tty);
6645
6646     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6647     foreach my $entry (@script_versions) {
6648         if ($version>=$entry->[0]) {
6649             $script=$entry->[1];
6650             last;
6651         }
6652     }
6653     return unless defined($script);
6654     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6655     $tty=readline($pipe);
6656     close($pipe);
6657     return unless defined($tty) && $tty =~ m(^/dev/);
6658     chomp $tty;
6659     return $tty;
6660 }
6661
6662 =head2 C<create_IN_OUT($flags)>
6663
6664 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6665 try to diagnose why.
6666
6667 Flags are:
6668
6669 =over 4
6670
6671 =item * 1 - Don't know how to create a new TTY.
6672
6673 =item * 2 - Debugger has forked, but we can't get a new TTY.
6674
6675 =item * 4 - standard debugger startup is happening.
6676
6677 =back
6678
6679 =cut
6680
6681 use vars qw($fork_TTY);
6682
6683 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6684
6685     # If we know how to get a new TTY, do it! $in will have
6686     # the TTY name if get_fork_TTY works.
6687     my $in = &get_fork_TTY if defined &get_fork_TTY;
6688
6689     # It used to be that
6690     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6691
6692     if ( not defined $in ) {
6693         my $why = shift;
6694
6695         # We don't know how.
6696         print_help(<<EOP) if $why == 1;
6697 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6698 EOP
6699
6700         # Forked debugger.
6701         print_help(<<EOP) if $why == 2;
6702 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6703   This may be an asynchronous session, so the parent debugger may be active.
6704 EOP
6705
6706         # Note that both debuggers are fighting over the same input.
6707         print_help(<<EOP) if $why != 4;
6708   Since two debuggers fight for the same TTY, input is severely entangled.
6709
6710 EOP
6711         print_help(<<EOP);
6712   I know how to switch the output to a different window in xterms, OS/2
6713   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6714   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6715   B<DB::get_fork_TTY()> returning this.
6716
6717   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6718   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6719
6720 EOP
6721     } ## end if (not defined $in)
6722     elsif ( $in ne '' ) {
6723         TTY($in);
6724     }
6725     else {
6726         $console = '';    # Indicate no need to open-from-the-console
6727     }
6728     undef $fork_TTY;
6729 } ## end sub create_IN_OUT
6730
6731 =head2 C<resetterm>
6732
6733 Handles rejiggering the prompt when we've forked off a new debugger.
6734
6735 If the new debugger happened because of a C<system()> that invoked a
6736 program under the debugger, the arrow between the old pid and the new
6737 in the prompt has I<two> dashes instead of one.
6738
6739 We take the current list of pids and add this one to the end. If there
6740 isn't any list yet, we make one up out of the initial pid associated with
6741 the terminal and our new pid, sticking an arrow (either one-dashed or
6742 two dashed) in between them.
6743
6744 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6745 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6746 and try to do that.
6747
6748 =cut
6749
6750 sub resetterm {    # We forked, so we need a different TTY
6751
6752     # Needs to be passed to create_IN_OUT() as well.
6753     my $in = shift;
6754
6755     # resetterm(2): got in here because of a system() starting a debugger.
6756     # resetterm(1): just forked.
6757     my $systemed = $in > 1 ? '-' : '';
6758
6759     # If there's already a list of pids, add this to the end.
6760     if ($pids) {
6761         $pids =~ s/\]/$systemed->$$]/;
6762     }
6763
6764     # No pid list. Time to make one.
6765     else {
6766         $pids = "[$term_pid->$$]";
6767     }
6768
6769     # The prompt we're going to be using for this debugger.
6770     $pidprompt = $pids;
6771
6772     # We now 0wnz this terminal.
6773     $term_pid = $$;
6774
6775     # Just return if we're not supposed to try to create a new TTY.
6776     return unless $CreateTTY & $in;
6777
6778     # Try to create a new IN/OUT pair.
6779     create_IN_OUT($in);
6780 } ## end sub resetterm
6781
6782 =head2 C<readline>
6783
6784 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6785 the next line, print a message saying we got it, add it to the terminal
6786 history (if possible), and return it.
6787
6788 If there's nothing in the typeahead buffer, check the command filehandle stack.
6789 If there are any filehandles there, read from the last one, and return the line
6790 if we got one. If not, we pop the filehandle off and close it, and try the
6791 next one up the stack.
6792
6793 If we've emptied the filehandle stack, we check to see if we've got a socket
6794 open, and we read that and return it if we do. If we don't, we just call the
6795 core C<readline()> and return its value.
6796
6797 =cut
6798
6799 sub readline {
6800
6801     # Localize to prevent it from being smashed in the program being debugged.
6802     local $.;
6803
6804     # If there are stacked filehandles to read from ...
6805     # (Handle it before the typeahead, because we may call source/etc. from
6806     # the typeahead.)
6807     while (@cmdfhs) {
6808
6809         # Read from the last one in the stack.
6810         my $line = CORE::readline( $cmdfhs[-1] );
6811
6812         # If we got a line ...
6813         defined $line
6814           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6815           : close pop @cmdfhs;                            # Pop and close
6816     } ## end while (@cmdfhs)
6817
6818     # Pull a line out of the typeahead if there's stuff there.
6819     if (@typeahead) {
6820
6821         # How many lines left.
6822         my $left = @typeahead;
6823
6824         # Get the next line.
6825         my $got = shift @typeahead;
6826
6827         # Print a message saying we got input from the typeahead.
6828         local $\ = '';
6829         print $OUT "auto(-$left)", shift, $got, "\n";
6830
6831         # Add it to the terminal history (if possible).
6832         $term->AddHistory($got)
6833           if length($got) > 1
6834           and defined $term->Features->{addHistory};
6835         return $got;
6836     } ## end if (@typeahead)
6837
6838     # We really need to read some input. Turn off entry/exit trace and
6839     # return value printing.
6840     local $frame = 0;
6841     local $doret = -2;
6842
6843     # Nothing on the filehandle stack. Socket?
6844     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6845
6846         # Send anything we have to send.
6847         $OUT->write( join( '', @_ ) );
6848
6849         # Receive anything there is to receive.
6850         my $stuff = '';
6851         my $buf;
6852         my $first_time = 1;
6853
6854         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
6855         {
6856             $first_time = 0;
6857             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6858                                             # XXX Don't know. You tell me.
6859         }
6860
6861         # What we got.
6862         return $stuff;
6863     } ## end if (ref $OUT and UNIVERSAL::isa...
6864
6865     # No socket. Just read from the terminal.
6866     else {
6867         return $term->readline(@_);
6868     }
6869 } ## end sub readline
6870
6871 =head1 OPTIONS SUPPORT ROUTINES
6872
6873 These routines handle listing and setting option values.
6874
6875 =head2 C<dump_option> - list the current value of an option setting
6876
6877 This routine uses C<option_val> to look up the value for an option.
6878 It cleans up escaped single-quotes and then displays the option and
6879 its value.
6880
6881 =cut
6882
6883 sub dump_option {
6884     my ( $opt, $val ) = @_;
6885     $val = option_val( $opt, 'N/A' );
6886     $val =~ s/([\\\'])/\\$1/g;
6887     printf $OUT "%20s = '%s'\n", $opt, $val;
6888 } ## end sub dump_option
6889
6890 sub options2remember {
6891     foreach my $k (@RememberOnROptions) {
6892         $option{$k} = option_val( $k, 'N/A' );
6893     }
6894     return %option;
6895 }
6896
6897 =head2 C<option_val> - find the current value of an option
6898
6899 This can't just be a simple hash lookup because of the indirect way that
6900 the option values are stored. Some are retrieved by calling a subroutine,
6901 some are just variables.
6902
6903 You must supply a default value to be used in case the option isn't set.
6904
6905 =cut
6906
6907 sub option_val {
6908     my ( $opt, $default ) = @_;
6909     my $val;
6910
6911     # Does this option exist, and is it a variable?
6912     # If so, retrieve the value via the value in %optionVars.
6913     if (    defined $optionVars{$opt}
6914         and defined ${ $optionVars{$opt} } )
6915     {
6916         $val = ${ $optionVars{$opt} };
6917     }
6918
6919     # Does this option exist, and it's a subroutine?
6920     # If so, call the subroutine via the ref in %optionAction
6921     # and capture the value.
6922     elsif ( defined $optionAction{$opt}
6923         and defined &{ $optionAction{$opt} } )
6924     {
6925         $val = &{ $optionAction{$opt} }();
6926     }
6927
6928     # If there's an action or variable for the supplied option,
6929     # but no value was set, use the default.
6930     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6931         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6932     {
6933         $val = $default;
6934     }
6935
6936     # Otherwise, do the simple hash lookup.
6937     else {
6938         $val = $option{$opt};
6939     }
6940
6941     # If the value isn't defined, use the default.
6942     # Then return whatever the value is.
6943     $val = $default unless defined $val;
6944     $val;
6945 } ## end sub option_val
6946
6947 =head2 C<parse_options>
6948
6949 Handles the parsing and execution of option setting/displaying commands.
6950
6951 An option entered by itself is assumed to be I<set me to 1> (the default value)
6952 if the option is a boolean one. If not, the user is prompted to enter a valid
6953 value or to query the current value (via C<option? >).
6954
6955 If C<option=value> is entered, we try to extract a quoted string from the
6956 value (if it is quoted). If it's not, we just use the whole value as-is.
6957
6958 We load any modules required to service this option, and then we set it: if
6959 it just gets stuck in a variable, we do that; if there's a subroutine to
6960 handle setting the option, we call that.
6961
6962 Finally, if we're running in interactive mode, we display the effect of the
6963 user's command back to the terminal, skipping this if we're setting things
6964 during initialization.
6965
6966 =cut
6967
6968 sub parse_options {
6969     my ($s) = @_;
6970     local $\ = '';
6971
6972     my $option;
6973
6974     # These options need a value. Don't allow them to be clobbered by accident.
6975     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6976       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6977       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6978     };
6979
6980     while (length($s)) {
6981         my $val_defaulted;
6982
6983         # Clean off excess leading whitespace.
6984         $s =~ s/^\s+// && next;
6985
6986         # Options are always all word characters, followed by a non-word
6987         # separator.
6988         if ($s !~ s/^(\w+)(\W?)//) {
6989             print {$OUT} "Invalid option '$s'\n";
6990             last;
6991         }
6992         my ( $opt, $sep ) = ( $1, $2 );
6993
6994         # Make sure that such an option exists.
6995         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
6996           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
6997
6998         unless ($matches) {
6999             print {$OUT} "Unknown option '$opt'\n";
7000             next;
7001         }
7002         if ($matches > 1) {
7003             print {$OUT} "Ambiguous option '$opt'\n";
7004             next;
7005         }
7006         my $val;
7007
7008         # '?' as separator means query, but must have whitespace after it.
7009         if ( "?" eq $sep ) {
7010             if ($s =~ /\A\S/) {
7011                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7012
7013                 last;
7014             }
7015
7016             #&dump_option($opt);
7017         } ## end if ("?" eq $sep)
7018
7019         # Separator is whitespace (or just a carriage return).
7020         # They're going for a default, which we assume is 1.
7021         elsif ( $sep !~ /\S/ ) {
7022             $val_defaulted = 1;
7023             $val           = "1";   #  this is an evil default; make 'em set it!
7024         }
7025
7026         # Separator is =. Trying to set a value.
7027         elsif ( $sep eq "=" ) {
7028
7029             # If quoted, extract a quoted string.
7030             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7031                 my $quote = $1;
7032                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7033             }
7034
7035             # Not quoted. Use the whole thing. Warn about 'option='.
7036             else {
7037                 $s =~ s/^(\S*)//;
7038                 $val = $1;
7039                 print OUT qq(Option better cleared using $opt=""\n)
7040                   unless length $val;
7041             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7042
7043         } ## end elsif ($sep eq "=")
7044
7045         # "Quoted" with [], <>, or {}.
7046         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7047             my ($end) =
7048               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7049             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7050               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7051             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7052         } ## end else [ if ("?" eq $sep)
7053
7054         # Exclude non-booleans from getting set to 1 by default.
7055         if ( $opt_needs_val{$option} && $val_defaulted ) {
7056             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7057             print {$OUT}
7058 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7059             next;
7060         } ## end if ($opt_needs_val{$option...
7061
7062         # Save the option value.
7063         $option{$option} = $val if defined $val;
7064
7065         # Load any module that this option requires.
7066         if ( defined($optionRequire{$option}) && defined($val) ) {
7067             eval qq{
7068             local \$frame = 0;
7069             local \$doret = -2;
7070             require '$optionRequire{$option}';
7071             1;
7072             } || die $@   # XXX: shouldn't happen
7073         }
7074
7075         # Set it.
7076         # Stick it in the proper variable if it goes in a variable.
7077         if (defined($optionVars{$option}) && defined($val)) {
7078             ${ $optionVars{$option} } = $val;
7079         }
7080
7081         # Call the appropriate sub if it gets set via sub.
7082         if (defined($optionAction{$option})
7083           && defined (&{ $optionAction{$option} })
7084           && defined ($val))
7085         {
7086           &{ $optionAction{$option} }($val);
7087         }
7088
7089         # Not initialization - echo the value we set it to.
7090         dump_option($option) if ($OUT ne \*STDERR);
7091     } ## end while (length)
7092 } ## end sub parse_options
7093
7094 =head1 RESTART SUPPORT
7095
7096 These routines are used to store (and restore) lists of items in environment
7097 variables during a restart.
7098
7099 =head2 set_list
7100
7101 Set_list packages up items to be stored in a set of environment variables
7102 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7103 the values). Values outside the standard ASCII charset are stored by encoding
7104 then as hexadecimal values.
7105
7106 =cut
7107
7108 sub set_list {
7109     my ( $stem, @list ) = @_;
7110     my $val;
7111
7112     # VAR_n: how many we have. Scalar assignment gets the number of items.
7113     $ENV{"${stem}_n"} = @list;
7114
7115     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7116     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7117     for my $i ( 0 .. $#list ) {
7118         $val = $list[$i];
7119         $val =~ s/\\/\\\\/g;
7120         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
7121         $ENV{"${stem}_$i"} = $val;
7122     } ## end for $i (0 .. $#list)
7123 } ## end sub set_list
7124
7125 =head2 get_list
7126
7127 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7128 back, and then pull VAR_0, VAR_1. etc. back out.
7129
7130 =cut
7131
7132 sub get_list {
7133     my $stem = shift;
7134     my @list;
7135     my $n = delete $ENV{"${stem}_n"};
7136     my $val;
7137     for my $i ( 0 .. $n - 1 ) {
7138         $val = delete $ENV{"${stem}_$i"};
7139         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7140         push @list, $val;
7141     }
7142     @list;
7143 } ## end sub get_list
7144
7145 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7146
7147 =head2 catch()
7148
7149 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7150 set an already-existing global scalar variable to a constant value. This
7151 avoids allocating any memory possibly in the middle of something that will
7152 get all confused if we do, particularly under I<unsafe signals>.
7153
7154 =cut
7155
7156 sub catch {
7157     $signal = 1;
7158     return;    # Put nothing on the stack - malloc/free land!
7159 }
7160
7161 =head2 C<warn()>
7162
7163 C<warn> emits a warning, by joining together its arguments and printing
7164 them, with couple of fillips.
7165
7166 If the composited message I<doesn't> end with a newline, we automatically
7167 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7168 to be set to the filehandle to be used to output warnings; it makes no
7169 assumptions about what filehandles are available.
7170
7171 =cut
7172
7173 sub warn {
7174     my ($msg) = join( "", @_ );
7175     $msg .= ": $!\n" unless $msg =~ /\n$/;
7176     local $\ = '';
7177     print $OUT $msg;
7178 } ## end sub warn
7179
7180 =head1 INITIALIZATION TTY SUPPORT
7181
7182 =head2 C<reset_IN_OUT>
7183
7184 This routine handles restoring the debugger's input and output filehandles
7185 after we've tried and failed to move them elsewhere.  In addition, it assigns
7186 the debugger's output filehandle to $LINEINFO if it was already open there.
7187
7188 =cut
7189
7190 sub reset_IN_OUT {
7191     my $switch_li = $LINEINFO eq $OUT;
7192
7193     # If there's a term and it's able to get a new tty, try to get one.
7194     if ( $term and $term->Features->{newTTY} ) {
7195         ( $IN, $OUT ) = ( shift, shift );
7196         $term->newTTY( $IN, $OUT );
7197     }
7198
7199     # This term can't get a new tty now. Better luck later.
7200     elsif ($term) {
7201         &warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7202     }
7203
7204     # Set the filehndles up as they were.
7205     else {
7206         ( $IN, $OUT ) = ( shift, shift );
7207     }
7208
7209     # Unbuffer the output filehandle.
7210     $OUT->autoflush(1);
7211
7212     # Point LINEINFO to the same output filehandle if it was there before.
7213     $LINEINFO = $OUT if $switch_li;
7214 } ## end sub reset_IN_OUT
7215
7216 =head1 OPTION SUPPORT ROUTINES
7217
7218 The following routines are used to process some of the more complicated
7219 debugger options.
7220
7221 =head2 C<TTY>
7222
7223 Sets the input and output filehandles to the specified files or pipes.
7224 If the terminal supports switching, we go ahead and do it. If not, and
7225 there's already a terminal in place, we save the information to take effect
7226 on restart.
7227
7228 If there's no terminal yet (for instance, during debugger initialization),
7229 we go ahead and set C<$console> and C<$tty> to the file indicated.
7230
7231 =cut
7232
7233 sub TTY {
7234
7235     if ( @_ and $term and $term->Features->{newTTY} ) {
7236
7237         # This terminal supports switching to a new TTY.
7238         # Can be a list of two files, or on string containing both names,
7239         # comma-separated.
7240         # XXX Should this perhaps be an assignment from @_?
7241         my ( $in, $out ) = shift;
7242         if ( $in =~ /,/ ) {
7243
7244             # Split list apart if supplied.
7245             ( $in, $out ) = split /,/, $in, 2;
7246         }
7247         else {
7248
7249             # Use the same file for both input and output.
7250             $out = $in;
7251         }
7252
7253         # Open file onto the debugger's filehandles, if you can.
7254         open IN,  $in     or die "cannot open '$in' for read: $!";
7255         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7256
7257         # Swap to the new filehandles.
7258         reset_IN_OUT( \*IN, \*OUT );
7259
7260         # Save the setting for later.
7261         return $tty = $in;
7262     } ## end if (@_ and $term and $term...
7263
7264     # Terminal doesn't support new TTY, or doesn't support readline.
7265     # Can't do it now, try restarting.
7266     &warn("Too late to set TTY, enabled on next 'R'!\n") if $term and @_;
7267
7268     # Useful if done through PERLDB_OPTS:
7269     $console = $tty = shift if @_;
7270
7271     # Return whatever the TTY is.
7272     $tty or $console;
7273 } ## end sub TTY
7274
7275 =head2 C<noTTY>
7276
7277 Sets the C<$notty> global, controlling whether or not the debugger tries to
7278 get a terminal to read from. If called after a terminal is already in place,
7279 we save the value to use it if we're restarted.
7280
7281 =cut
7282
7283 sub noTTY {
7284     if ($term) {
7285         &warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7286     }
7287     $notty = shift if @_;
7288     $notty;
7289 } ## end sub noTTY
7290
7291 =head2 C<ReadLine>
7292
7293 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7294 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7295 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7296 the value in case a restart is done so we can change it then.
7297
7298 =cut
7299
7300 sub ReadLine {
7301     if ($term) {
7302         &warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7303     }
7304     $rl = shift if @_;
7305     $rl;
7306 } ## end sub ReadLine
7307
7308 =head2 C<RemotePort>
7309
7310 Sets the port that the debugger will try to connect to when starting up.
7311 If the terminal's already been set up, we can't do it, but we remember the
7312 setting in case the user does a restart.
7313
7314 =cut
7315
7316 sub RemotePort {
7317     if ($term) {
7318         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7319     }
7320     $remoteport = shift if @_;
7321     $remoteport;
7322 } ## end sub RemotePort
7323
7324 =head2 C<tkRunning>
7325
7326 Checks with the terminal to see if C<Tk> is running, and returns true or
7327 false. Returns false if the current terminal doesn't support C<readline>.
7328
7329 =cut
7330
7331 sub tkRunning {
7332     if ( ${ $term->Features }{tkRunning} ) {
7333         return $term->tkRunning(@_);
7334     }
7335     else {
7336         local $\ = '';
7337         print $OUT "tkRunning not supported by current ReadLine package.\n";
7338         0;
7339     }
7340 } ## end sub tkRunning
7341
7342 =head2 C<NonStop>
7343
7344 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7345 debugger remembers the setting in case you restart, though.
7346
7347 =cut
7348
7349 sub NonStop {
7350     if ($term) {
7351         &warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7352           if @_;
7353     }
7354     $runnonstop = shift if @_;
7355     $runnonstop;
7356 } ## end sub NonStop
7357
7358 sub DollarCaretP {
7359     if ($term) {
7360         &warn("Some flag changes could not take effect until next 'R'!\n")
7361           if @_;
7362     }
7363     $^P = parse_DollarCaretP_flags(shift) if @_;
7364     expand_DollarCaretP_flags($^P);
7365 }
7366
7367 =head2 C<pager>
7368
7369 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7370 there already.
7371
7372 =cut
7373
7374 sub pager {
7375     if (@_) {
7376         $pager = shift;
7377         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7378     }
7379     $pager;
7380 } ## end sub pager
7381
7382 =head2 C<shellBang>
7383
7384 Sets the shell escape command, and generates a printable copy to be used
7385 in the help.
7386
7387 =cut
7388
7389 sub shellBang {
7390
7391     # If we got an argument, meta-quote it, and add '\b' if it
7392     # ends in a word character.
7393     if (@_) {
7394         $sh = quotemeta shift;
7395         $sh .= "\\b" if $sh =~ /\w$/;
7396     }
7397
7398     # Generate the printable version for the help:
7399     $psh = $sh;    # copy it
7400     $psh =~ s/\\b$//;        # Take off trailing \b if any
7401     $psh =~ s/\\(.)/$1/g;    # De-escape
7402     $psh;                    # return the printable version
7403 } ## end sub shellBang
7404
7405 =head2 C<ornaments>
7406
7407 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7408 was passed as the argument. (This means you can't override the terminal's
7409 ornaments.)
7410
7411 =cut
7412
7413 sub ornaments {
7414     if ( defined $term ) {
7415
7416         # We don't want to show warning backtraces, but we do want die() ones.
7417         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7418
7419         # No ornaments if the terminal doesn't support them.
7420         return '' unless $term->Features->{ornaments};
7421         eval { $term->ornaments(@_) } || '';
7422     }
7423
7424     # Use what was passed in if we can't determine it ourselves.
7425     else {
7426         $ornaments = shift;
7427     }
7428 } ## end sub ornaments
7429
7430 =head2 C<recallCommand>
7431
7432 Sets the recall command, and builds a printable version which will appear in
7433 the help text.
7434
7435 =cut
7436
7437 sub recallCommand {
7438
7439     # If there is input, metaquote it. Add '\b' if it ends with a word
7440     # character.
7441     if (@_) {
7442         $rc = quotemeta shift;
7443         $rc .= "\\b" if $rc =~ /\w$/;
7444     }
7445
7446     # Build it into a printable version.
7447     $prc = $rc;    # Copy it
7448     $prc =~ s/\\b$//;        # Remove trailing \b
7449     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7450     $prc;                    # Return the printable version
7451 } ## end sub recallCommand
7452
7453 =head2 C<LineInfo> - where the line number information goes
7454
7455 Called with no arguments, returns the file or pipe that line info should go to.
7456
7457 Called with an argument (a file or a pipe), it opens that onto the
7458 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7459 file or pipe again to the caller.
7460
7461 =cut
7462
7463 sub LineInfo {
7464     if (@_) {
7465         $lineinfo = shift;
7466
7467         #  If this is a valid "thing to be opened for output", tack a
7468         # '>' onto the front.
7469         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7470
7471         # If this is a pipe, the stream points to a slave editor.
7472         $slave_editor = ( $stream =~ /^\|/ );
7473
7474         # Open it up and unbuffer it.
7475         open( LINEINFO, $stream ) || &warn("Cannot open '$stream' for write");
7476         $LINEINFO = \*LINEINFO;
7477         $LINEINFO->autoflush(1);
7478     }
7479
7480     return $lineinfo;
7481 } ## end sub LineInfo
7482
7483 =head1 COMMAND SUPPORT ROUTINES
7484
7485 These subroutines provide functionality for various commands.
7486
7487 =head2 C<list_modules>
7488
7489 For the C<M> command: list modules loaded and their versions.
7490 Essentially just runs through the keys in %INC, picks each package's
7491 C<$VERSION> variable, gets the file name, and formats the information
7492 for output.
7493
7494 =cut
7495
7496 sub list_modules {    # versions
7497     my %version;
7498     my $file;
7499
7500     # keys are the "as-loaded" name, values are the fully-qualified path
7501     # to the file itself.
7502     for ( keys %INC ) {
7503         $file = $_;                                # get the module name
7504         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7505         s,/,::,g;                                  # change '/' to '::'
7506         s/^perl5db$/DB/;                           # Special case: debugger
7507                                                    # moves to package DB
7508         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7509
7510         # If the package has a $VERSION package global (as all good packages
7511         # should!) decode it and save as partial message.
7512         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
7513         if ( defined $pkg_version ) {
7514             $version{$file} = "$pkg_version from ";
7515         }
7516
7517         # Finish up the message with the file the package came from.
7518         $version{$file} .= $INC{$file};
7519     } ## end for (keys %INC)
7520
7521     # Hey, dumpit() formats a hash nicely, so why not use it?
7522     dumpit( $OUT, \%version );
7523 } ## end sub list_modules
7524
7525 =head2 C<sethelp()>
7526
7527 Sets up the monster string used to format and print the help.
7528
7529 =head3 HELP MESSAGE FORMAT
7530
7531 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7532 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7533 easy to parse and portable, but which still allows the help to be a little
7534 nicer than just plain text.
7535
7536 Essentially, you define the command name (usually marked up with C<< B<> >>
7537 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7538 newline. The descriptive text can also be marked up in the same way. If you
7539 need to continue the descriptive text to another line, start that line with
7540 just tabs and then enter the marked-up text.
7541
7542 If you are modifying the help text, I<be careful>. The help-string parser is
7543 not very sophisticated, and if you don't follow these rules it will mangle the
7544 help beyond hope until you fix the string.
7545
7546 =cut
7547
7548 use vars qw($pre580_help);
7549 use vars qw($pre580_summary);
7550
7551 sub sethelp {
7552
7553     # XXX: make sure there are tabs between the command and explanation,
7554     #      or print_help will screw up your formatting if you have
7555     #      eeevil ornaments enabled.  This is an insane mess.
7556
7557     $help = "
7558 Help is currently only available for the new 5.8 command set.
7559 No help is available for the old command set.
7560 We assume you know what you're doing if you switch to it.
7561
7562 B<T>        Stack trace.
7563 B<s> [I<expr>]    Single step [in I<expr>].
7564 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7565 <B<CR>>        Repeat last B<n> or B<s> command.
7566 B<r>        Return from current subroutine.
7567 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7568         at the specified position.
7569 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7570 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7571 B<l> I<line>        List single I<line>.
7572 B<l> I<subname>    List first window of lines from subroutine.
7573 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7574 B<l>        List next window of lines.
7575 B<->        List previous window of lines.
7576 B<v> [I<line>]    View window around I<line>.
7577 B<.>        Return to the executed line.
7578 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7579         I<filename> may be either the full name of the file, or a regular
7580         expression matching the full file name:
7581         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7582         Evals (with saved bodies) are considered to be filenames:
7583         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7584         (in the order of execution).
7585 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7586 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7587 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7588 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7589 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7590 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7591 B<b>        Sets breakpoint on current line)
7592 B<b> [I<line>] [I<condition>]
7593         Set breakpoint; I<line> defaults to the current execution line;
7594         I<condition> breaks if it evaluates to true, defaults to '1'.
7595 B<b> I<subname> [I<condition>]
7596         Set breakpoint at first line of subroutine.
7597 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7598 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7599 B<b> B<postpone> I<subname> [I<condition>]
7600         Set breakpoint at first line of subroutine after
7601         it is compiled.
7602 B<b> B<compile> I<subname>
7603         Stop after the subroutine is compiled.
7604 B<B> [I<line>]    Delete the breakpoint for I<line>.
7605 B<B> I<*>             Delete all breakpoints.
7606 B<a> [I<line>] I<command>
7607         Set an action to be done before the I<line> is executed;
7608         I<line> defaults to the current execution line.
7609         Sequence is: check for breakpoint/watchpoint, print line
7610         if necessary, do action, prompt user if necessary,
7611         execute line.
7612 B<a>        Does nothing
7613 B<A> [I<line>]    Delete the action for I<line>.
7614 B<A> I<*>             Delete all actions.
7615 B<w> I<expr>        Add a global watch-expression.
7616 B<w>             Does nothing
7617 B<W> I<expr>        Delete a global watch-expression.
7618 B<W> I<*>             Delete all watch-expressions.
7619 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7620         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7621 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7622 B<x> I<expr>        Evals expression in list context, dumps the result.
7623 B<m> I<expr>        Evals expression in list context, prints methods callable
7624         on the first element of the result.
7625 B<m> I<class>        Prints methods callable via the given class.
7626 B<M>        Show versions of loaded modules.
7627 B<i> I<class>       Prints nested parents of given class.
7628 B<e>         Display current thread id.
7629 B<E>         Display all thread ids the current one will be identified: <n>.
7630 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7631
7632 B<<> ?            List Perl commands to run before each prompt.
7633 B<<> I<expr>        Define Perl command to run before each prompt.
7634 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7635 B<< *>                Delete the list of perl commands to run before each prompt.
7636 B<>> ?            List Perl commands to run after each prompt.
7637 B<>> I<expr>        Define Perl command to run after each prompt.
7638 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7639 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7640 B<{> I<db_command>    Define debugger command to run before each prompt.
7641 B<{> ?            List debugger commands to run before each prompt.
7642 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7643 B<{ *>             Delete the list of debugger commands to run before each prompt.
7644 B<$prc> I<number>    Redo a previous command (default previous command).
7645 B<$prc> I<-number>    Redo number'th-to-last command.
7646 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7647         See 'B<O> I<recallCommand>' too.
7648 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7649       . (
7650         $rc eq $sh
7651         ? ""
7652         : "
7653 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7654       ) . "
7655         See 'B<O> I<shellBang>' too.
7656 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7657 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7658 B<rerun>           Rerun session to current position.
7659 B<rerun> I<n>         Rerun session to numbered command.
7660 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7661 B<H> I<-number>    Display last number commands (default all).
7662 B<H> I<*>          Delete complete history.
7663 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7664 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7665 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7666 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7667 I<command>        Execute as a perl statement in current package.
7668 B<R>        Pure-man-restart of debugger, some of debugger state
7669         and command-line options may be lost.
7670         Currently the following settings are preserved:
7671         history, breakpoints and actions, debugger B<O>ptions
7672         and the following command-line options: I<-w>, I<-I>, I<-e>.
7673
7674 B<o> [I<opt>] ...    Set boolean option to true
7675 B<o> [I<opt>B<?>]    Query options
7676 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7677         Set options.  Use quotes if spaces in value.
7678     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7679     I<pager>            program for output of \"|cmd\";
7680     I<tkRunning>            run Tk while prompting (with ReadLine);
7681     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7682     I<inhibit_exit>        Allows stepping off the end of the script.
7683     I<ImmediateStop>        Debugger should stop as early as possible.
7684     I<RemotePort>            Remote hostname:port for remote debugging
7685   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7686     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7687     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7688     I<globPrint>             whether to print contents of globs;
7689     I<DumpDBFiles>         dump arrays holding debugged files;
7690     I<DumpPackages>         dump symbol tables of packages;
7691     I<DumpReused>             dump contents of \"reused\" addresses;
7692     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7693     I<bareStringify>         Do not print the overload-stringified value;
7694   Other options include:
7695     I<PrintRet>        affects printing of return value after B<r> command,
7696     I<frame>        affects printing messages on subroutine entry/exit.
7697     I<AutoTrace>    affects printing messages on possible breaking points.
7698     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7699     I<ornaments>     affects screen appearance of the command line.
7700     I<CreateTTY>     bits control attempts to create a new TTY on events:
7701             1: on fork()    2: debugger is started inside debugger
7702             4: on startup
7703     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7704     You can put additional initialization options I<TTY>, I<noTTY>,
7705     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7706     B<R> after you set them).
7707
7708 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7709 B<h>        Summary of debugger commands.
7710 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7711 B<h h>        Long help for debugger commands
7712 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7713         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7714         Set B<\$DB::doccmd> to change viewer.
7715
7716 Type '|h h' for a paged display if this was too hard to read.
7717
7718 ";    # Fix balance of vi % matching: }}}}
7719
7720     #  note: tabs in the following section are not-so-helpful
7721     $summary = <<"END_SUM";
7722 I<List/search source lines:>               I<Control script execution:>
7723   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7724   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7725   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7726   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7727   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7728   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7729 I<Debugger controls:>                        B<L>           List break/watch/actions
7730   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7731   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7732   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7733   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7734   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7735   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7736   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7737   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7738   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7739 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7740   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7741   B<p> I<expr>         Print expression (uses script's current package).
7742   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7743   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7744   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7745   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7746   B<e>     Display thread id     B<E> Display all thread ids.
7747 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7748 END_SUM
7749
7750     # ')}}; # Fix balance of vi % matching
7751
7752     # and this is really numb...
7753     $pre580_help = "
7754 B<T>        Stack trace.
7755 B<s> [I<expr>]    Single step [in I<expr>].
7756 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7757 B<CR>>        Repeat last B<n> or B<s> command.
7758 B<r>        Return from current subroutine.
7759 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7760         at the specified position.
7761 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7762 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7763 B<l> I<line>        List single I<line>.
7764 B<l> I<subname>    List first window of lines from subroutine.
7765 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7766 B<l>        List next window of lines.
7767 B<->        List previous window of lines.
7768 B<w> [I<line>]    List window around I<line>.
7769 B<.>        Return to the executed line.
7770 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7771         I<filename> may be either the full name of the file, or a regular
7772         expression matching the full file name:
7773         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7774         Evals (with saved bodies) are considered to be filenames:
7775         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7776         (in the order of execution).
7777 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7778 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7779 B<L>        List all breakpoints and actions.
7780 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7781 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
7782 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7783 B<b> [I<line>] [I<condition>]
7784         Set breakpoint; I<line> defaults to the current execution line;
7785         I<condition> breaks if it evaluates to true, defaults to '1'.
7786 B<b> I<subname> [I<condition>]
7787         Set breakpoint at first line of subroutine.
7788 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7789 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7790 B<b> B<postpone> I<subname> [I<condition>]
7791         Set breakpoint at first line of subroutine after
7792         it is compiled.
7793 B<b> B<compile> I<subname>
7794         Stop after the subroutine is compiled.
7795 B<d> [I<line>]    Delete the breakpoint for I<line>.
7796 B<D>        Delete all breakpoints.
7797 B<a> [I<line>] I<command>
7798         Set an action to be done before the I<line> is executed;
7799         I<line> defaults to the current execution line.
7800         Sequence is: check for breakpoint/watchpoint, print line
7801         if necessary, do action, prompt user if necessary,
7802         execute line.
7803 B<a> [I<line>]    Delete the action for I<line>.
7804 B<A>        Delete all actions.
7805 B<W> I<expr>        Add a global watch-expression.
7806 B<W>        Delete all watch-expressions.
7807 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7808         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7809 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7810 B<x> I<expr>        Evals expression in list context, dumps the result.
7811 B<m> I<expr>        Evals expression in list context, prints methods callable
7812         on the first element of the result.
7813 B<m> I<class>        Prints methods callable via the given class.
7814
7815 B<<> ?            List Perl commands to run before each prompt.
7816 B<<> I<expr>        Define Perl command to run before each prompt.
7817 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7818 B<>> ?            List Perl commands to run after each prompt.
7819 B<>> I<expr>        Define Perl command to run after each prompt.
7820 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7821 B<{> I<db_command>    Define debugger command to run before each prompt.
7822 B<{> ?            List debugger commands to run before each prompt.
7823 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7824 B<$prc> I<number>    Redo a previous command (default previous command).
7825 B<$prc> I<-number>    Redo number'th-to-last command.
7826 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7827         See 'B<O> I<recallCommand>' too.
7828 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7829       . (
7830         $rc eq $sh
7831         ? ""
7832         : "
7833 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7834       ) . "
7835         See 'B<O> I<shellBang>' too.
7836 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7837 B<H> I<-number>    Display last number commands (default all).
7838 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7839 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7840 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7841 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7842 I<command>        Execute as a perl statement in current package.
7843 B<v>        Show versions of loaded modules.
7844 B<R>        Pure-man-restart of debugger, some of debugger state
7845         and command-line options may be lost.
7846         Currently the following settings are preserved:
7847         history, breakpoints and actions, debugger B<O>ptions
7848         and the following command-line options: I<-w>, I<-I>, I<-e>.
7849
7850 B<O> [I<opt>] ...    Set boolean option to true
7851 B<O> [I<opt>B<?>]    Query options
7852 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7853         Set options.  Use quotes if spaces in value.
7854     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7855     I<pager>            program for output of \"|cmd\";
7856     I<tkRunning>            run Tk while prompting (with ReadLine);
7857     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7858     I<inhibit_exit>        Allows stepping off the end of the script.
7859     I<ImmediateStop>        Debugger should stop as early as possible.
7860     I<RemotePort>            Remote hostname:port for remote debugging
7861   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7862     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7863     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7864     I<globPrint>             whether to print contents of globs;
7865     I<DumpDBFiles>         dump arrays holding debugged files;
7866     I<DumpPackages>         dump symbol tables of packages;
7867     I<DumpReused>             dump contents of \"reused\" addresses;
7868     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7869     I<bareStringify>         Do not print the overload-stringified value;
7870   Other options include:
7871     I<PrintRet>        affects printing of return value after B<r> command,
7872     I<frame>        affects printing messages on subroutine entry/exit.
7873     I<AutoTrace>    affects printing messages on possible breaking points.
7874     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7875     I<ornaments>     affects screen appearance of the command line.
7876     I<CreateTTY>     bits control attempts to create a new TTY on events:
7877             1: on fork()    2: debugger is started inside debugger
7878             4: on startup
7879     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7880     You can put additional initialization options I<TTY>, I<noTTY>,
7881     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7882     B<R> after you set them).
7883
7884 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7885 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7886 B<h h>        Summary of debugger commands.
7887 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7888         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7889         Set B<\$DB::doccmd> to change viewer.
7890
7891 Type '|h' for a paged display if this was too hard to read.
7892
7893 ";    # Fix balance of vi % matching: }}}}
7894
7895     #  note: tabs in the following section are not-so-helpful
7896     $pre580_summary = <<"END_SUM";
7897 I<List/search source lines:>               I<Control script execution:>
7898   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7899   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7900   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7901   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7902   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7903   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7904 I<Debugger controls:>                        B<L>           List break/watch/actions
7905   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7906   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7907   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7908   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7909   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7910   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7911   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7912   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7913 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7914   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7915   B<p> I<expr>         Print expression (uses script's current package).
7916   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7917   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7918   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7919   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7920 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7921 END_SUM
7922
7923     # ')}}; # Fix balance of vi % matching
7924
7925 } ## end sub sethelp
7926
7927 =head2 C<print_help()>
7928
7929 Most of what C<print_help> does is just text formatting. It finds the
7930 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7931 terminal control characters to simulate them (courtesy of
7932 C<Term::ReadLine::TermCap>).
7933
7934 =cut
7935
7936 sub print_help {
7937     my $help_str = shift;
7938
7939     # Restore proper alignment destroyed by eeevil I<> and B<>
7940     # ornaments: A pox on both their houses!
7941     #
7942     # A help command will have everything up to and including
7943     # the first tab sequence padded into a field 16 (or if indented 20)
7944     # wide.  If it's wider than that, an extra space will be added.
7945     $help_str =~ s{
7946         ^                       # only matters at start of line
7947           ( \040{4} | \t )*     # some subcommands are indented
7948           ( < ?                 # so <CR> works
7949             [BI] < [^\t\n] + )  # find an eeevil ornament
7950           ( \t+ )               # original separation, discarded
7951           ( .* )                # this will now start (no earlier) than
7952                                 # column 16
7953     } {
7954         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7955         my $clean = $command;
7956         $clean =~ s/[BI]<([^>]*)>/$1/g;
7957
7958         # replace with this whole string:
7959         ($leadwhite ? " " x 4 : "")
7960       . $command
7961       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7962       . $text;
7963
7964     }mgex;
7965
7966     $help_str =~ s{                          # handle bold ornaments
7967        B < ( [^>] + | > ) >
7968     } {
7969           $Term::ReadLine::TermCap::rl_term_set[2]
7970         . $1
7971         . $Term::ReadLine::TermCap::rl_term_set[3]
7972     }gex;
7973
7974     $help_str =~ s{                         # handle italic ornaments
7975        I < ( [^>] + | > ) >
7976     } {
7977           $Term::ReadLine::TermCap::rl_term_set[0]
7978         . $1
7979         . $Term::ReadLine::TermCap::rl_term_set[1]
7980     }gex;
7981
7982     local $\ = '';
7983     print {$OUT} $help_str;
7984
7985     return;
7986 } ## end sub print_help
7987
7988 =head2 C<fix_less>
7989
7990 This routine does a lot of gyrations to be sure that the pager is C<less>.
7991 It checks for C<less> masquerading as C<more> and records the result in
7992 C<$fixed_less> so we don't have to go through doing the stats again.
7993
7994 =cut
7995
7996 use vars qw($fixed_less);
7997
7998 sub _calc_is_less {
7999     if ($pager =~ /\bless\b/)
8000     {
8001         return 1;
8002     }
8003     elsif ($pager =~ /\bmore\b/)
8004     {
8005         # Nope, set to more. See what's out there.
8006         my @st_more = stat('/usr/bin/more');
8007         my @st_less = stat('/usr/bin/less');
8008
8009         # is it really less, pretending to be more?
8010         return (
8011             @st_more
8012             && @st_less
8013             && $st_more[0] == $st_less[0]
8014             && $st_more[1] == $st_less[1]
8015         );
8016     }
8017     else {
8018         return;
8019     }
8020 }
8021
8022 sub fix_less {
8023
8024     # We already know if this is set.
8025     return if $fixed_less;
8026
8027     # changes environment!
8028     # 'r' added so we don't do (slow) stats again.
8029     $fixed_less = 1 if _calc_is_less();
8030
8031     return;
8032 } ## end sub fix_less
8033
8034 =head1 DIE AND WARN MANAGEMENT
8035
8036 =head2 C<diesignal>
8037
8038 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8039 to debug a debugger problem.
8040
8041 It does its best to report the error that occurred, and then forces the
8042 program, debugger, and everything to die.
8043
8044 =cut
8045
8046 sub diesignal {
8047
8048     # No entry/exit messages.
8049     local $frame = 0;
8050
8051     # No return value prints.
8052     local $doret = -2;
8053
8054     # set the abort signal handling to the default (just terminate).
8055     $SIG{'ABRT'} = 'DEFAULT';
8056
8057     # If we enter the signal handler recursively, kill myself with an
8058     # abort signal (so we just terminate).
8059     kill 'ABRT', $$ if $panic++;
8060
8061     # If we can show detailed info, do so.
8062     if ( defined &Carp::longmess ) {
8063
8064         # Don't recursively enter the warn handler, since we're carping.
8065         local $SIG{__WARN__} = '';
8066
8067         # Skip two levels before reporting traceback: we're skipping
8068         # mydie and confess.
8069         local $Carp::CarpLevel = 2;    # mydie + confess
8070
8071         # Tell us all about it.
8072         &warn( Carp::longmess("Signal @_") );
8073     }
8074
8075     # No Carp. Tell us about the signal as best we can.
8076     else {
8077         local $\ = '';
8078         print $DB::OUT "Got signal @_\n";
8079     }
8080
8081     # Drop dead.
8082     kill 'ABRT', $$;
8083 } ## end sub diesignal
8084
8085 =head2 C<dbwarn>
8086
8087 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8088 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8089
8090 =cut
8091
8092 sub dbwarn {
8093
8094     # No entry/exit trace.
8095     local $frame = 0;
8096
8097     # No return value printing.
8098     local $doret = -2;
8099
8100     # Turn off warn and die handling to prevent recursive entries to this
8101     # routine.
8102     local $SIG{__WARN__} = '';
8103     local $SIG{__DIE__}  = '';
8104
8105     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8106     # done yet), we may not be able to do a require.
8107     eval { require Carp }
8108       if defined $^S;    # If error/warning during compilation,
8109                          # require may be broken.
8110
8111     # Use the core warn() unless Carp loaded OK.
8112     CORE::warn( @_,
8113         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8114       return
8115       unless defined &Carp::longmess;
8116
8117     # Save the current values of $single and $trace, and then turn them off.
8118     my ( $mysingle, $mytrace ) = ( $single, $trace );
8119     $single = 0;
8120     $trace  = 0;
8121
8122     # We can call Carp::longmess without its being "debugged" (which we
8123     # don't want - we just want to use it!). Capture this for later.
8124     my $mess = Carp::longmess(@_);
8125
8126     # Restore $single and $trace to their original values.
8127     ( $single, $trace ) = ( $mysingle, $mytrace );
8128
8129     # Use the debugger's own special way of printing warnings to print
8130     # the stack trace message.
8131     &warn($mess);
8132 } ## end sub dbwarn
8133
8134 =head2 C<dbdie>
8135
8136 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8137 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8138 single stepping and tracing during the call to C<Carp::longmess> to avoid
8139 debugging it - we just want to use it.
8140
8141 If C<dieLevel> is zero, we let the program being debugged handle the
8142 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8143 the debugger takes over all exception handling, printing a backtrace and
8144 displaying the exception via its C<dbwarn()> routine.
8145
8146 =cut
8147
8148 sub dbdie {
8149     local $frame         = 0;
8150     local $doret         = -2;
8151     local $SIG{__DIE__}  = '';
8152     local $SIG{__WARN__} = '';
8153     my $i      = 0;
8154     my $ineval = 0;
8155     my $sub;
8156     if ( $dieLevel > 2 ) {
8157         local $SIG{__WARN__} = \&dbwarn;
8158         &warn(@_);    # Yell no matter what
8159         return;
8160     }
8161     if ( $dieLevel < 2 ) {
8162         die @_ if $^S;    # in eval propagate
8163     }
8164
8165     # The code used to check $^S to see if compilation of the current thing
8166     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8167     eval { require Carp };
8168
8169     die( @_,
8170         "\nCannot print stack trace, load with -MCarp option to see stack" )
8171       unless defined &Carp::longmess;
8172
8173     # We do not want to debug this chunk (automatic disabling works
8174     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8175     # get the stack trace from Carp::longmess (if possible), restore $signal
8176     # and $trace, and then die with the stack trace.
8177     my ( $mysingle, $mytrace ) = ( $single, $trace );
8178     $single = 0;
8179     $trace  = 0;
8180     my $mess = "@_";
8181     {
8182
8183         package Carp;    # Do not include us in the list
8184         eval { $mess = Carp::longmess(@_); };
8185     }
8186     ( $single, $trace ) = ( $mysingle, $mytrace );
8187     die $mess;
8188 } ## end sub dbdie
8189
8190 =head2 C<warnlevel()>
8191
8192 Set the C<$DB::warnLevel> variable that stores the value of the
8193 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8194 results in the debugger taking over all warning handlers. Setting
8195 C<warnLevel> to zero leaves any warning handlers set up by the program
8196 being debugged in place.
8197
8198 =cut
8199
8200 sub warnLevel {
8201     if (@_) {
8202         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8203         $warnLevel = shift;
8204         if ($warnLevel) {
8205             $SIG{__WARN__} = \&DB::dbwarn;
8206         }
8207         elsif ($prevwarn) {
8208             $SIG{__WARN__} = $prevwarn;
8209         } else {
8210             undef $SIG{__WARN__};
8211         }
8212     } ## end if (@_)
8213     $warnLevel;
8214 } ## end sub warnLevel
8215
8216 =head2 C<dielevel>
8217
8218 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8219 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8220 zero lets you use your own C<die()> handler.
8221
8222 =cut
8223
8224 sub dieLevel {
8225     local $\ = '';
8226     if (@_) {
8227         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8228         $dieLevel = shift;
8229         if ($dieLevel) {
8230
8231             # Always set it to dbdie() for non-zero values.
8232             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8233
8234             # No longer exists, so don't try  to use it.
8235             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8236
8237             # If we've finished initialization, mention that stack dumps
8238             # are enabled, If dieLevel is 1, we won't stack dump if we die
8239             # in an eval().
8240             print $OUT "Stack dump during die enabled",
8241               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8242               if $I_m_init;
8243
8244             # XXX This is probably obsolete, given that diehard() is gone.
8245             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8246         } ## end if ($dieLevel)
8247
8248         # Put the old one back if there was one.
8249         elsif ($prevdie) {
8250             $SIG{__DIE__} = $prevdie;
8251             print $OUT "Default die handler restored.\n";
8252         } else {
8253             undef $SIG{__DIE__};
8254             print $OUT "Die handler removed.\n";
8255         }
8256     } ## end if (@_)
8257     $dieLevel;
8258 } ## end sub dieLevel
8259
8260 =head2 C<signalLevel>
8261
8262 Number three in a series: set C<signalLevel> to zero to keep your own
8263 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8264 takes over and handles them with C<DB::diesignal()>.
8265
8266 =cut
8267
8268 sub signalLevel {
8269     if (@_) {
8270         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8271         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8272         $signalLevel = shift;
8273         if ($signalLevel) {
8274             $SIG{SEGV} = \&DB::diesignal;
8275             $SIG{BUS}  = \&DB::diesignal;
8276         }
8277         else {
8278             $SIG{SEGV} = $prevsegv;
8279             $SIG{BUS}  = $prevbus;
8280         }
8281     } ## end if (@_)
8282     $signalLevel;
8283 } ## end sub signalLevel
8284
8285 =head1 SUBROUTINE DECODING SUPPORT
8286
8287 These subroutines are used during the C<x> and C<X> commands to try to
8288 produce as much information as possible about a code reference. They use
8289 L<Devel::Peek> to try to find the glob in which this code reference lives
8290 (if it does) - this allows us to actually code references which correspond
8291 to named subroutines (including those aliased via glob assignment).
8292
8293 =head2 C<CvGV_name()>
8294
8295 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8296 via that routine. If this fails, return the reference again (when the
8297 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8298
8299 =cut
8300
8301 sub CvGV_name {
8302     my $in   = shift;
8303     my $name = CvGV_name_or_bust($in);
8304     defined $name ? $name : $in;
8305 }
8306
8307 =head2 C<CvGV_name_or_bust> I<coderef>
8308
8309 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8310 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8311 find a glob for this ref.
8312
8313 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8314
8315 =cut
8316
8317 use vars qw($skipCvGV);
8318
8319 sub CvGV_name_or_bust {
8320     my $in = shift;
8321     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8322     return unless ref $in;
8323     $in = \&$in;            # Hard reference...
8324     eval { require Devel::Peek; 1 } or return;
8325     my $gv = Devel::Peek::CvGV($in) or return;
8326     *$gv{PACKAGE} . '::' . *$gv{NAME};
8327 } ## end sub CvGV_name_or_bust
8328
8329 =head2 C<find_sub>
8330
8331 A utility routine used in various places; finds the file where a subroutine
8332 was defined, and returns that filename and a line-number range.
8333
8334 Tries to use C<@sub> first; if it can't find it there, it tries building a
8335 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8336 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8337 this way, it brute-force searches C<%sub>, checking for identical references.
8338
8339 =cut
8340
8341 sub _find_sub_helper {
8342     my $subr = shift;
8343
8344     return unless defined &$subr;
8345     my $name = CvGV_name_or_bust($subr);
8346     my $data;
8347     $data = $sub{$name} if defined $name;
8348     return $data if defined $data;
8349
8350     # Old stupid way...
8351     $subr = \&$subr;    # Hard reference
8352     my $s;
8353     for ( keys %sub ) {
8354         $s = $_, last if $subr eq \&$_;
8355     }
8356     if ($s)
8357     {
8358         return $sub{$s};
8359     }
8360     else
8361     {
8362         return;
8363     }
8364
8365 }
8366
8367 sub find_sub {
8368     my $subr = shift;
8369     return ( $sub{$subr} || _find_sub_helper($subr) );
8370 } ## end sub find_sub
8371
8372 =head2 C<methods>
8373
8374 A subroutine that uses the utility function C<methods_via> to find all the
8375 methods in the class corresponding to the current reference and in
8376 C<UNIVERSAL>.
8377
8378 =cut
8379
8380 use vars qw(%seen);
8381
8382 sub methods {
8383
8384     # Figure out the class - either this is the class or it's a reference
8385     # to something blessed into that class.
8386     my $class = shift;
8387     $class = ref $class if ref $class;
8388
8389     local %seen;
8390
8391     # Show the methods that this class has.
8392     methods_via( $class, '', 1 );
8393
8394     # Show the methods that UNIVERSAL has.
8395     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8396 } ## end sub methods
8397
8398 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8399
8400 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8401 all the parent class methods. C<$class> is the name of the next class to
8402 try; C<$prefix> is the message prefix, which gets built up as we go up the
8403 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8404 higher in the C<@ISA> tree, 0 if we should stop.
8405
8406 =cut
8407
8408 sub methods_via {
8409
8410     # If we've processed this class already, just quit.
8411     my $class = shift;
8412     return if $seen{$class}++;
8413
8414     # This is a package that is contributing the methods we're about to print.
8415     my $prefix  = shift;
8416     my $prepend = $prefix ? "via $prefix: " : '';
8417     my @to_print;
8418
8419     # Extract from all the symbols in this class.
8420     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8421     while (my ($name, $glob) = each %$class_ref) {
8422         # references directly in the symbol table are Proxy Constant
8423         # Subroutines, and are by their very nature defined
8424         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8425         # to a subroutine reference, which can be tested by defined.
8426         # $glob might also be the value -1  (from sub foo;)
8427         # or (say) '$$' (from sub foo ($$);)
8428         # \$glob will be SCALAR in both cases.
8429         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8430             && !$seen{$name}++) {
8431             push @to_print, "$prepend$name\n";
8432         }
8433     }
8434
8435     {
8436         local $\ = '';
8437         local $, = '';
8438         print $DB::OUT $_ foreach sort @to_print;
8439     }
8440
8441     # If the $crawl_upward argument is false, just quit here.
8442     return unless shift;
8443
8444     # $crawl_upward true: keep going up the tree.
8445     # Find all the classes this one is a subclass of.
8446     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8447     for my $name ( @$class_ISA_ref ) {
8448
8449         # Set up the new prefix.
8450         $prepend = $prefix ? $prefix . " -> $name" : $name;
8451
8452         # Crawl up the tree and keep trying to crawl up.
8453         methods_via( $name, $prepend, 1 );
8454     }
8455 } ## end sub methods_via
8456
8457 =head2 C<setman> - figure out which command to use to show documentation
8458
8459 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8460
8461 =cut
8462
8463 sub setman {
8464     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8465       ? "man"         # O Happy Day!
8466       : "perldoc";    # Alas, poor unfortunates
8467 } ## end sub setman
8468
8469 =head2 C<runman> - run the appropriate command to show documentation
8470
8471 Accepts a man page name; runs the appropriate command to display it (set up
8472 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8473 program's STDIN and STDOUT.
8474
8475 =cut
8476
8477 my %_is_in_pods = (map { $_ => 1 }
8478     qw(
8479     5004delta
8480     5005delta
8481     561delta
8482     56delta
8483     570delta
8484     571delta
8485     572delta
8486     573delta
8487     58delta
8488     581delta
8489     582delta
8490     583delta
8491     584delta
8492     590delta
8493     591delta
8494     592delta
8495     aix
8496     amiga
8497     apio
8498     api
8499     artistic
8500     beos
8501     book
8502     boot
8503     bot
8504     bs2000
8505     call
8506     ce
8507     cheat
8508     clib
8509     cn
8510     compile
8511     cygwin
8512     data
8513     dbmfilter
8514     debguts
8515     debtut
8516     debug
8517     delta
8518     dgux
8519     diag
8520     doc
8521     dos
8522     dsc
8523     ebcdic
8524     embed
8525     epoc
8526     faq1
8527     faq2
8528     faq3
8529     faq4
8530     faq5
8531     faq6
8532     faq7
8533     faq8
8534     faq9
8535     faq
8536     filter
8537     fork
8538     form
8539     freebsd
8540     func
8541     gpl
8542     guts
8543     hack
8544     hist
8545     hpux
8546     hurd
8547     intern
8548     intro
8549     iol
8550     ipc
8551     irix
8552     jp
8553     ko
8554     lexwarn
8555     locale
8556     lol
8557     macos
8558     macosx
8559     modinstall
8560     modlib
8561     mod
8562     modstyle
8563     netware
8564     newmod
8565     number
8566     obj
8567     opentut
8568     op
8569     os2
8570     os390
8571     os400
8572     packtut
8573     plan9
8574     pod
8575     podspec
8576     port
8577     qnx
8578     ref
8579     reftut
8580     re
8581     requick
8582     reref
8583     retut
8584     run
8585     sec
8586     solaris
8587     style
8588     sub
8589     syn
8590     thrtut
8591     tie
8592     toc
8593     todo
8594     tooc
8595     toot
8596     trap
8597     tru64
8598     tw
8599     unicode
8600     uniintro
8601     util
8602     uts
8603     var
8604     vms
8605     vos
8606     win32
8607     xs
8608     xstut
8609     )
8610 );
8611
8612 sub runman {
8613     my $page = shift;
8614     unless ($page) {
8615         &system("$doccmd $doccmd");
8616         return;
8617     }
8618
8619     # this way user can override, like with $doccmd="man -Mwhatever"
8620     # or even just "man " to disable the path check.
8621     unless ( $doccmd eq 'man' ) {
8622         &system("$doccmd $page");
8623         return;
8624     }
8625
8626     $page = 'perl' if lc($page) eq 'help';
8627
8628     require Config;
8629     my $man1dir = $Config::Config{'man1dir'};
8630     my $man3dir = $Config::Config{'man3dir'};
8631     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8632     my $manpath = '';
8633     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8634     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8635     chop $manpath if $manpath;
8636
8637     # harmless if missing, I figure
8638     my $oldpath = $ENV{MANPATH};
8639     $ENV{MANPATH} = $manpath if $manpath;
8640     my $nopathopt = $^O =~ /dunno what goes here/;
8641     if (
8642         CORE::system(
8643             $doccmd,
8644
8645             # I just *know* there are men without -M
8646             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8647             split ' ', $page
8648         )
8649       )
8650     {
8651         unless ( $page =~ /^perl\w/ ) {
8652 # do it this way because its easier to slurp in to keep up to date - clunky though.
8653             if (exists($_is_in_pods{$page})) {
8654                 CORE::system( $doccmd,
8655                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8656                     "perl$page" );
8657             }
8658         }
8659     } ## end if (CORE::system($doccmd...
8660     if ( defined $oldpath ) {
8661         $ENV{MANPATH} = $manpath;
8662     }
8663     else {
8664         delete $ENV{MANPATH};
8665     }
8666 } ## end sub runman
8667
8668 #use Carp;                          # This did break, left for debugging
8669
8670 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8671
8672 Because of the way the debugger interface to the Perl core is designed, any
8673 debugger package globals that C<DB::sub()> requires have to be defined before
8674 any subroutines can be called. These are defined in the second C<BEGIN> block.
8675
8676 This block sets things up so that (basically) the world is sane
8677 before the debugger starts executing. We set up various variables that the
8678 debugger has to have set up before the Perl core starts running:
8679
8680 =over 4
8681
8682 =item *
8683
8684 The debugger's own filehandles (copies of STD and STDOUT for now).
8685
8686 =item *
8687
8688 Characters for shell escapes, the recall command, and the history command.
8689
8690 =item *
8691
8692 The maximum recursion depth.
8693
8694 =item *
8695
8696 The size of a C<w> command's window.
8697
8698 =item *
8699
8700 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8701
8702 =item *
8703
8704 The fact that we're not in a sub at all right now.
8705
8706 =item *
8707
8708 The default SIGINT handler for the debugger.
8709
8710 =item *
8711
8712 The appropriate value of the flag in C<$^D> that says the debugger is running
8713
8714 =item *
8715
8716 The current debugger recursion level
8717
8718 =item *
8719
8720 The list of postponed items and the C<$single> stack (XXX define this)
8721
8722 =item *
8723
8724 That we want no return values and no subroutine entry/exit trace.
8725
8726 =back
8727
8728 =cut
8729
8730 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8731
8732 use vars qw($db_stop);
8733
8734 BEGIN {    # This does not compile, alas. (XXX eh?)
8735     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8736     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8737
8738     # Define characters used by command parsing.
8739     $sh       = '!';      # Shell escape (does not work)
8740     $rc       = ',';      # Recall command (does not work)
8741     @hist     = ('?');    # Show history (does not work)
8742     @truehist = ();       # Can be saved for replay (per session)
8743
8744     # This defines the point at which you get the 'deep recursion'
8745     # warning. It MUST be defined or the debugger will not load.
8746     $deep = 100;
8747
8748     # Number of lines around the current one that are shown in the
8749     # 'w' command.
8750     $window = 10;
8751
8752     # How much before-the-current-line context the 'v' command should
8753     # use in calculating the start of the window it will display.
8754     $preview = 3;
8755
8756     # We're not in any sub yet, but we need this to be a defined value.
8757     $sub = '';
8758
8759     # Set up the debugger's interrupt handler. It simply sets a flag
8760     # ($signal) that DB::DB() will check before each command is executed.
8761     $SIG{INT} = \&DB::catch;
8762
8763     # The following lines supposedly, if uncommented, allow the debugger to
8764     # debug itself. Perhaps we can try that someday.
8765     # This may be enabled to debug debugger:
8766     #$warnLevel = 1 unless defined $warnLevel;
8767     #$dieLevel = 1 unless defined $dieLevel;
8768     #$signalLevel = 1 unless defined $signalLevel;
8769
8770     # This is the flag that says "a debugger is running, please call
8771     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8772     # execute anything in the user's context, because we always want to
8773     # get control back.
8774     $db_stop = 0;          # Compiler warning ...
8775     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8776
8777     # This variable records how many levels we're nested in debugging. Used
8778     # Used in the debugger prompt, and in determining whether it's all over or
8779     # not.
8780     $level = 0;            # Level of recursive debugging
8781
8782     # "Triggers bug (?) in perl if we postpone this until runtime."
8783     # XXX No details on this yet, or whether we should fix the bug instead
8784     # of work around it. Stay tuned.
8785     @stack = (0);
8786
8787     # Used to track the current stack depth using the auto-stacked-variable
8788     # trick.
8789     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8790
8791     # Don't print return values on exiting a subroutine.
8792     $doret = -2;
8793
8794     # No extry/exit tracing.
8795     $frame = 0;
8796
8797 } ## end BEGIN
8798
8799 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8800
8801 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8802
8803 =head2 db_complete
8804
8805 C<readline> support - adds command completion to basic C<readline>.
8806
8807 Returns a list of possible completions to C<readline> when invoked. C<readline>
8808 will print the longest common substring following the text already entered.
8809
8810 If there is only a single possible completion, C<readline> will use it in full.
8811
8812 This code uses C<map> and C<grep> heavily to create lists of possible
8813 completion. Think LISP in this section.
8814
8815 =cut
8816
8817 sub db_complete {
8818
8819     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8820     # $text is the text to be completed.
8821     # $line is the incoming line typed by the user.
8822     # $start is the start of the text to be completed in the incoming line.
8823     my ( $text, $line, $start ) = @_;
8824
8825     # Save the initial text.
8826     # The search pattern is current package, ::, extract the next qualifier
8827     # Prefix and pack are set to undef.
8828     my ( $itext, $search, $prefix, $pack ) =
8829       ( $text, "^\Q${package}::\E([^:]+)\$" );
8830
8831 =head3 C<b postpone|compile>
8832
8833 =over 4
8834
8835 =item *
8836
8837 Find all the subroutines that might match in this package
8838
8839 =item *
8840
8841 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8842
8843 =item *
8844
8845 Include all the rest of the subs that are known
8846
8847 =item *
8848
8849 C<grep> out the ones that match the text we have so far
8850
8851 =item *
8852
8853 Return this as the list of possible completions
8854
8855 =back
8856
8857 =cut
8858
8859     return sort grep /^\Q$text/, ( keys %sub ),
8860       qw(postpone load compile),    # subroutines
8861       ( map { /$search/ ? ($1) : () } keys %sub )
8862       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8863
8864 =head3 C<b load>
8865
8866 Get all the possible files from C<@INC> as it currently stands and
8867 select the ones that match the text so far.
8868
8869 =cut
8870
8871     return sort grep /^\Q$text/, values %INC    # files
8872       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8873
8874 =head3  C<V> (list variable) and C<m> (list modules)
8875
8876 There are two entry points for these commands:
8877
8878 =head4 Unqualified package names
8879
8880 Get the top-level packages and grab everything that matches the text
8881 so far. For each match, recursively complete the partial packages to
8882 get all possible matching packages. Return this sorted list.
8883
8884 =cut
8885
8886     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8887       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8888       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8889
8890 =head4 Qualified package names
8891
8892 Take a partially-qualified package and find all subpackages for it
8893 by getting all the subpackages for the package so far, matching all
8894 the subpackages against the text, and discarding all of them which
8895 start with 'main::'. Return this list.
8896
8897 =cut
8898
8899     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8900       grep !/^main::/, grep /^\Q$text/,
8901       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
8902       do { no strict 'refs'; keys %{ $prefix . '::' } }
8903       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8904       and $text =~ /^(.*[^:])::?(\w*)$/
8905       and $prefix = $1;
8906
8907 =head3 C<f> - switch files
8908
8909 Here, we want to get a fully-qualified filename for the C<f> command.
8910 Possibilities are:
8911
8912 =over 4
8913
8914 =item 1. The original source file itself
8915
8916 =item 2. A file from C<@INC>
8917
8918 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8919
8920 =back
8921
8922 =cut
8923
8924     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8925            # We might possibly want to switch to an eval (which has a "filename"
8926            # like '(eval 9)'), so we may need to clean up the completion text
8927            # before proceeding.
8928         $prefix = length($1) - length($text);
8929         $text   = $1;
8930
8931 =pod
8932
8933 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8934 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8935 out of C<%main::>, add the initial source file, and extract the ones that
8936 match the completion text so far.
8937
8938 =cut
8939
8940         return sort
8941           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8942           $0;
8943     } ## end if ($line =~ /^\|*f\s+(.*)/)
8944
8945 =head3 Subroutine name completion
8946
8947 We look through all of the defined subs (the keys of C<%sub>) and
8948 return both all the possible matches to the subroutine name plus
8949 all the matches qualified to the current package.
8950
8951 =cut
8952
8953     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8954         $text = substr $text, 1;
8955         $prefix = "&";
8956         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8957           (
8958             map { /$search/ ? ($1) : () }
8959               keys %sub
8960           );
8961     } ## end if ((substr $text, 0, ...
8962
8963 =head3  Scalar, array, and hash completion: partially qualified package
8964
8965 Much like the above, except we have to do a little more cleanup:
8966
8967 =cut
8968
8969     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8970
8971 =pod
8972
8973 =over 4
8974
8975 =item *
8976
8977 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8978
8979 =cut
8980
8981         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8982
8983 =pod
8984
8985 =item *
8986
8987 Figure out the prefix vs. what needs completing.
8988
8989 =cut
8990
8991         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8992         $text   = $2;
8993
8994 =pod
8995
8996 =item *
8997
8998 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8999
9000 =cut
9001
9002         my @out = do {
9003             no strict 'refs';
9004             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9005             keys %$pack;
9006         };
9007
9008 =pod
9009
9010 =item *
9011
9012 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9013
9014 =cut
9015
9016         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9017             return db_complete( $out[0], $line, $start );
9018         }
9019
9020         # Return the list of possibles.
9021         return sort @out;
9022
9023     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9024
9025 =pod
9026
9027 =back
9028
9029 =head3 Symbol completion: current package or package C<main>.
9030
9031 =cut
9032
9033     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9034 =pod
9035
9036 =over 4
9037
9038 =item *
9039
9040 If it's C<main>, delete main to just get C<::> leading.
9041
9042 =cut
9043
9044         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9045
9046 =pod
9047
9048 =item *
9049
9050 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9051
9052 =cut
9053
9054         $prefix = substr $text, 0, 1;
9055         $text   = substr $text, 1;
9056
9057         my @out;
9058
9059 =pod
9060
9061 =item *
9062
9063 We look for the lexical scope above DB::DB and auto-complete lexical variables
9064 if PadWalker could be loaded.
9065
9066 =cut
9067
9068         if (not $text =~ /::/ and eval { require PadWalker } ) {
9069             my $level = 1;
9070             while (1) {
9071                 my @info = caller($level);
9072                 $level++;
9073                 $level = -1, last
9074                   if not @info;
9075                 last if $info[3] eq 'DB::DB';
9076             }
9077             if ($level > 0) {
9078                 my $lexicals = PadWalker::peek_my($level);
9079                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9080             }
9081         }
9082
9083 =pod
9084
9085 =item *
9086
9087 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9088
9089 =cut
9090
9091         push @out, map "$prefix$_", grep /^\Q$text/,
9092           ( grep /^_?[a-zA-Z]/, keys %$pack ),
9093           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9094
9095 =item *
9096
9097 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9098
9099 =back
9100
9101 =cut
9102
9103         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9104             return db_complete( $out[0], $line, $start );
9105         }
9106
9107         # Return the list of possibles.
9108         return sort @out;
9109     } ## end if ($text =~ /^[\$@%]/)
9110
9111 =head3 Options
9112
9113 We use C<option_val()> to look up the current value of the option. If there's
9114 only a single value, we complete the command in such a way that it is a
9115 complete command for setting the option in question. If there are multiple
9116 possible values, we generate a command consisting of the option plus a trailing
9117 question mark, which, if executed, will list the current value of the option.
9118
9119 =cut
9120
9121     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9122     {    # Options after space
9123            # We look for the text to be matched in the list of possible options,
9124            # and fetch the current value.
9125         my @out = grep /^\Q$text/, @options;
9126         my $val = option_val( $out[0], undef );
9127
9128         # Set up a 'query option's value' command.
9129         my $out = '? ';
9130         if ( not defined $val or $val =~ /[\n\r]/ ) {
9131
9132             # There's really nothing else we can do.
9133         }
9134
9135         # We have a value. Create a proper option-setting command.
9136         elsif ( $val =~ /\s/ ) {
9137
9138             # XXX This may be an extraneous variable.
9139             my $found;
9140
9141             # We'll want to quote the string (because of the embedded
9142             # whtespace), but we want to make sure we don't end up with
9143             # mismatched quote characters. We try several possibilities.
9144             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9145
9146                 # If we didn't find this quote character in the value,
9147                 # quote it using this quote character.
9148                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9149             }
9150         } ## end elsif ($val =~ /\s/)
9151
9152         # Don't need any quotes.
9153         else {
9154             $out = "=$val ";
9155         }
9156
9157         # If there were multiple possible values, return '? ', which
9158         # makes the command into a query command. If there was just one,
9159         # have readline append that.
9160         $rl_attribs->{completer_terminator_character} =
9161           ( @out == 1 ? $out : '? ' );
9162
9163         # Return list of possibilities.
9164         return sort @out;
9165     } ## end if ((substr $line, 0, ...
9166
9167 =head3 Filename completion
9168
9169 For entering filenames. We simply call C<readline>'s C<filename_list()>
9170 method with the completion text to get the possible completions.
9171
9172 =cut
9173
9174     return $term->filename_list($text);    # filenames
9175
9176 } ## end sub db_complete
9177
9178 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9179
9180 Functions that possibly ought to be somewhere else.
9181
9182 =head2 end_report
9183
9184 Say we're done.
9185
9186 =cut
9187
9188 sub end_report {
9189     local $\ = '';
9190     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9191 }
9192
9193 =head2 clean_ENV
9194
9195 If we have $ini_pids, save it in the environment; else remove it from the
9196 environment. Used by the C<R> (restart) command.
9197
9198 =cut
9199
9200 sub clean_ENV {
9201     if ( defined($ini_pids) ) {
9202         $ENV{PERLDB_PIDS} = $ini_pids;
9203     }
9204     else {
9205         delete( $ENV{PERLDB_PIDS} );
9206     }
9207 } ## end sub clean_ENV
9208
9209 # PERLDBf_... flag names from perl.h
9210 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9211
9212 BEGIN {
9213     %DollarCaretP_flags = (
9214         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9215         PERLDBf_LINE      => 0x02,     # Keep line #
9216         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9217         PERLDBf_INTER     => 0x08,     # Preserve more data
9218         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9219         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9220         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9221         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9222         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9223         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9224         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9225         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9226     );
9227     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9228     # doesn't need to set it. It's provided for the benefit of profilers and
9229     # other code analysers.
9230
9231     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9232 }
9233
9234 sub parse_DollarCaretP_flags {
9235     my $flags = shift;
9236     $flags =~ s/^\s+//;
9237     $flags =~ s/\s+$//;
9238     my $acu = 0;
9239     foreach my $f ( split /\s*\|\s*/, $flags ) {
9240         my $value;
9241         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9242             $value = hex $1;
9243         }
9244         elsif ( $f =~ /^(\d+)$/ ) {
9245             $value = int $1;
9246         }
9247         elsif ( $f =~ /^DEFAULT$/i ) {
9248             $value = $DollarCaretP_flags{PERLDB_ALL};
9249         }
9250         else {
9251             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9252             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9253             unless ( defined $value ) {
9254                 print $OUT (
9255                     "Unrecognized \$^P flag '$f'!\n",
9256                     "Acceptable flags are: "
9257                       . join( ', ', sort keys %DollarCaretP_flags ),
9258                     ", and hexadecimal and decimal numbers.\n"
9259                 );
9260                 return undef;
9261             }
9262         }
9263         $acu |= $value;
9264     }
9265     $acu;
9266 }
9267
9268 sub expand_DollarCaretP_flags {
9269     my $DollarCaretP = shift;
9270     my @bits         = (
9271         map {
9272             my $n = ( 1 << $_ );
9273             ( $DollarCaretP & $n )
9274               ? ( $DollarCaretP_flags_r{$n}
9275                   || sprintf( '0x%x', $n ) )
9276               : ()
9277           } 0 .. 31
9278     );
9279     return @bits ? join( '|', @bits ) : 0;
9280 }
9281
9282 =over 4
9283
9284 =item rerun
9285
9286 Rerun the current session to:
9287
9288     rerun        current position
9289
9290     rerun 4      command number 4
9291
9292     rerun -4     current command minus 4 (go back 4 steps)
9293
9294 Whether this always makes sense, in the current context is unknowable, and is
9295 in part left as a useful exercise for the reader.  This sub returns the
9296 appropriate arguments to rerun the current session.
9297
9298 =cut
9299
9300 sub rerun {
9301     my $i = shift;
9302     my @args;
9303     pop(@truehist);                      # strim
9304     unless (defined $truehist[$i]) {
9305         print "Unable to return to non-existent command: $i\n";
9306     } else {
9307         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9308         my @temp = @truehist;            # store
9309         push(@DB::typeahead, @truehist); # saved
9310         @truehist = @hist = ();          # flush
9311         @args = &restart();              # setup
9312         &get_list("PERLDB_HIST");        # clean
9313         &set_list("PERLDB_HIST", @temp); # reset
9314     }
9315     return @args;
9316 }
9317
9318 =item restart
9319
9320 Restarting the debugger is a complex operation that occurs in several phases.
9321 First, we try to reconstruct the command line that was used to invoke Perl
9322 and the debugger.
9323
9324 =cut
9325
9326 sub restart {
9327     # I may not be able to resurrect you, but here goes ...
9328     print $OUT
9329 "Warning: some settings and command-line options may be lost!\n";
9330     my ( @script, @flags, $cl );
9331
9332     # If warn was on before, turn it on again.
9333     push @flags, '-w' if $ini_warn;
9334
9335     # Rebuild the -I flags that were on the initial
9336     # command line.
9337     for (@ini_INC) {
9338         push @flags, '-I', $_;
9339     }
9340
9341     # Turn on taint if it was on before.
9342     push @flags, '-T' if ${^TAINT};
9343
9344     # Arrange for setting the old INC:
9345     # Save the current @init_INC in the environment.
9346     set_list( "PERLDB_INC", @ini_INC );
9347
9348     # If this was a perl one-liner, go to the "file"
9349     # corresponding to the one-liner read all the lines
9350     # out of it (except for the first one, which is going
9351     # to be added back on again when 'perl -d' runs: that's
9352     # the 'require perl5db.pl;' line), and add them back on
9353     # to the command line to be executed.
9354     if ( $0 eq '-e' ) {
9355         my $lines = *{$main::{'_<-e'}}{ARRAY};
9356         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9357             chomp( $cl = $lines->[$_] );
9358             push @script, '-e', $cl;
9359         }
9360     } ## end if ($0 eq '-e')
9361
9362     # Otherwise we just reuse the original name we had
9363     # before.
9364     else {
9365         @script = $0;
9366     }
9367
9368 =pod
9369
9370 After the command line  has been reconstructed, the next step is to save
9371 the debugger's status in environment variables. The C<DB::set_list> routine
9372 is used to save aggregate variables (both hashes and arrays); scalars are
9373 just popped into environment variables directly.
9374
9375 =cut
9376
9377     # If the terminal supported history, grab it and
9378     # save that in the environment.
9379     set_list( "PERLDB_HIST",
9380           $term->Features->{getHistory}
9381         ? $term->GetHistory
9382         : @hist );
9383
9384     # Find all the files that were visited during this
9385     # session (i.e., the debugger had magic hashes
9386     # corresponding to them) and stick them in the environment.
9387     my @had_breakpoints = keys %had_breakpoints;
9388     set_list( "PERLDB_VISITED", @had_breakpoints );
9389
9390     # Save the debugger options we chose.
9391     set_list( "PERLDB_OPT", %option );
9392     # set_list( "PERLDB_OPT", options2remember() );
9393
9394     # Save the break-on-loads.
9395     set_list( "PERLDB_ON_LOAD", %break_on_load );
9396
9397 =pod
9398
9399 The most complex part of this is the saving of all of the breakpoints. They
9400 can live in an awful lot of places, and we have to go through all of them,
9401 find the breakpoints, and then save them in the appropriate environment
9402 variable via C<DB::set_list>.
9403
9404 =cut
9405
9406     # Go through all the breakpoints and make sure they're
9407     # still valid.
9408     my @hard;
9409     for ( 0 .. $#had_breakpoints ) {
9410
9411         # We were in this file.
9412         my $file = $had_breakpoints[$_];
9413
9414         # Grab that file's magic line hash.
9415         *dbline = $main::{ '_<' . $file };
9416
9417         # Skip out if it doesn't exist, or if the breakpoint
9418         # is in a postponed file (we'll do postponed ones
9419         # later).
9420         next unless %dbline or $postponed_file{$file};
9421
9422         # In an eval. This is a little harder, so we'll
9423         # do more processing on that below.
9424         ( push @hard, $file ), next
9425           if $file =~ /^\(\w*eval/;
9426
9427         # XXX I have no idea what this is doing. Yet.
9428         my @add;
9429         @add = %{ $postponed_file{$file} }
9430           if $postponed_file{$file};
9431
9432         # Save the list of all the breakpoints for this file.
9433         set_list( "PERLDB_FILE_$_", %dbline, @add );
9434
9435         # Serialize the extra data %breakpoints_data hash.
9436         # That's a bug fix.
9437         set_list( "PERLDB_FILE_ENABLED_$_",
9438             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9439             sort { $a <=> $b } keys(%dbline)
9440         )
9441     } ## end for (0 .. $#had_breakpoints)
9442
9443     # The breakpoint was inside an eval. This is a little
9444     # more difficult. XXX and I don't understand it.
9445     for (@hard) {
9446         # Get over to the eval in question.
9447         *dbline = $main::{ '_<' . $_ };
9448         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9449         for $sub ( keys %sub ) {
9450             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9451             $subs{$sub} = [ $1, $2 ];
9452         }
9453         unless (%subs) {
9454             print $OUT
9455               "No subroutines in $_, ignoring breakpoints.\n";
9456             next;
9457         }
9458       LINES: for $line ( keys %dbline ) {
9459
9460             # One breakpoint per sub only:
9461             my ( $offset, $sub, $found );
9462           SUBS: for $sub ( keys %subs ) {
9463                 if (
9464                     $subs{$sub}->[1] >=
9465                     $line    # Not after the subroutine
9466                     and (
9467                         not defined $offset    # Not caught
9468                         or $offset < 0
9469                     )
9470                   )
9471                 {                              # or badly caught
9472                     $found  = $sub;
9473                     $offset = $line - $subs{$sub}->[0];
9474                     $offset = "+$offset", last SUBS
9475                       if $offset >= 0;
9476                 } ## end if ($subs{$sub}->[1] >=...
9477             } ## end for $sub (keys %subs)
9478             if ( defined $offset ) {
9479                 $postponed{$found} =
9480                   "break $offset if $dbline{$line}";
9481             }
9482             else {
9483                 print $OUT
9484 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9485             }
9486         } ## end for $line (keys %dbline)
9487     } ## end for (@hard)
9488
9489     # Save the other things that don't need to be
9490     # processed.
9491     set_list( "PERLDB_POSTPONE",  %postponed );
9492     set_list( "PERLDB_PRETYPE",   @$pretype );
9493     set_list( "PERLDB_PRE",       @$pre );
9494     set_list( "PERLDB_POST",      @$post );
9495     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9496
9497     # We are officially restarting.
9498     $ENV{PERLDB_RESTART} = 1;
9499
9500     # We are junking all child debuggers.
9501     delete $ENV{PERLDB_PIDS};    # Restore ini state
9502
9503     # Set this back to the initial pid.
9504     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9505
9506 =pod
9507
9508 After all the debugger status has been saved, we take the command we built up
9509 and then return it, so we can C<exec()> it. The debugger will spot the
9510 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9511 from the environment.
9512
9513 =cut
9514
9515     # And run Perl again. Add the "-d" flag, all the
9516     # flags we built up, the script (whether a one-liner
9517     # or a file), add on the -emacs flag for a slave editor,
9518     # and then the old arguments.
9519
9520     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9521
9522 };  # end restart
9523
9524 =back
9525
9526 =head1 END PROCESSING - THE C<END> BLOCK
9527
9528 Come here at the very end of processing. We want to go into a
9529 loop where we allow the user to enter commands and interact with the
9530 debugger, but we don't want anything else to execute.
9531
9532 First we set the C<$finished> variable, so that some commands that
9533 shouldn't be run after the end of program quit working.
9534
9535 We then figure out whether we're truly done (as in the user entered a C<q>
9536 command, or we finished execution while running nonstop). If we aren't,
9537 we set C<$single> to 1 (causing the debugger to get control again).
9538
9539 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9540 message and returns control to the debugger. Repeat.
9541
9542 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9543 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9544 break, run to completion.).
9545
9546 =cut
9547
9548 END {
9549     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9550     $fall_off_end = 1 unless $inhibit_exit;
9551
9552     # Do not stop in at_exit() and destructors on exit:
9553     if ($fall_off_end or $runnonstop) {
9554         &save_hist();
9555     } else {
9556         $DB::single = 1;
9557         DB::fake::at_exit();
9558     }
9559 } ## end END
9560
9561 =head1 PRE-5.8 COMMANDS
9562
9563 Some of the commands changed function quite a bit in the 5.8 command
9564 realignment, so much so that the old code had to be replaced completely.
9565 Because we wanted to retain the option of being able to go back to the
9566 former command set, we moved the old code off to this section.
9567
9568 There's an awful lot of duplicated code here. We've duplicated the
9569 comments to keep things clear.
9570
9571 =head2 Null command
9572
9573 Does nothing. Used to I<turn off> commands.
9574
9575 =cut
9576
9577 sub cmd_pre580_null {
9578
9579     # do nothing...
9580 }
9581
9582 =head2 Old C<a> command.
9583
9584 This version added actions if you supplied them, and deleted them
9585 if you didn't.
9586
9587 =cut
9588
9589 sub cmd_pre580_a {
9590     my $xcmd = shift;
9591     my $cmd  = shift;
9592
9593     # Argument supplied. Add the action.
9594     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9595
9596         # If the line isn't there, use the current line.
9597         my $i = $1 || $line;
9598         my $j = $2;
9599
9600         # If there is an action ...
9601         if ( length $j ) {
9602
9603             # ... but the line isn't breakable, skip it.
9604             if ( $dbline[$i] == 0 ) {
9605                 print $OUT "Line $i may not have an action.\n";
9606             }
9607             else {
9608
9609                 # ... and the line is breakable:
9610                 # Mark that there's an action in this file.
9611                 $had_breakpoints{$filename} |= 2;
9612
9613                 # Delete any current action.
9614                 $dbline{$i} =~ s/\0[^\0]*//;
9615
9616                 # Add the new action, continuing the line as needed.
9617                 $dbline{$i} .= "\0" . action($j);
9618             }
9619         } ## end if (length $j)
9620
9621         # No action supplied.
9622         else {
9623
9624             # Delete the action.
9625             $dbline{$i} =~ s/\0[^\0]*//;
9626
9627             # Mark as having no break or action if nothing's left.
9628             delete $dbline{$i} if $dbline{$i} eq '';
9629         }
9630     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9631 } ## end sub cmd_pre580_a
9632
9633 =head2 Old C<b> command
9634
9635 Add breakpoints.
9636
9637 =cut
9638
9639 sub cmd_pre580_b {
9640     my $xcmd   = shift;
9641     my $cmd    = shift;
9642     my $dbline = shift;
9643
9644     # Break on load.
9645     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9646         my $file = $1;
9647         $file =~ s/\s+$//;
9648         &cmd_b_load($file);
9649     }
9650
9651     # b compile|postpone <some sub> [<condition>]
9652     # The interpreter actually traps this one for us; we just put the
9653     # necessary condition in the %postponed hash.
9654     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9655
9656         # Capture the condition if there is one. Make it true if none.
9657         my $cond = length $3 ? $3 : '1';
9658
9659         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9660         # if it was 'compile'.
9661         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9662
9663         # De-Perl4-ify the name - ' separators to ::.
9664         $subname =~ s/\'/::/g;
9665
9666         # Qualify it into the current package unless it's already qualified.
9667         $subname = "${package}::" . $subname
9668           unless $subname =~ /::/;
9669
9670         # Add main if it starts with ::.
9671         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9672
9673         # Save the break type for this sub.
9674         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9675     } ## end elsif ($cmd =~ ...
9676
9677     # b <sub name> [<condition>]
9678     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9679         my $subname = $1;
9680         my $cond = length $2 ? $2 : '1';
9681         &cmd_b_sub( $subname, $cond );
9682     }
9683     # b <line> [<condition>].
9684     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9685         my $i = $1 || $dbline;
9686         my $cond = length $2 ? $2 : '1';
9687         &cmd_b_line( $i, $cond );
9688     }
9689 } ## end sub cmd_pre580_b
9690
9691 =head2 Old C<D> command.
9692
9693 Delete all breakpoints unconditionally.
9694
9695 =cut
9696
9697 sub cmd_pre580_D {
9698     my $xcmd = shift;
9699     my $cmd  = shift;
9700     if ( $cmd =~ /^\s*$/ ) {
9701         print $OUT "Deleting all breakpoints...\n";
9702
9703         # %had_breakpoints lists every file that had at least one
9704         # breakpoint in it.
9705         my $file;
9706         for $file ( keys %had_breakpoints ) {
9707
9708             # Switch to the desired file temporarily.
9709             local *dbline = $main::{ '_<' . $file };
9710
9711             $max = $#dbline;
9712             my $was;
9713
9714             # For all lines in this file ...
9715             for my $i (1 .. $max) {
9716
9717                 # If there's a breakpoint or action on this line ...
9718                 if ( defined $dbline{$i} ) {
9719
9720                     # ... remove the breakpoint.
9721                     $dbline{$i} =~ s/^[^\0]+//;
9722                     if ( $dbline{$i} =~ s/^\0?$// ) {
9723
9724                         # Remove the entry altogether if no action is there.
9725                         delete $dbline{$i};
9726                     }
9727                 } ## end if (defined $dbline{$i...
9728             } ## end for my $i (1 .. $max)
9729
9730             # If, after we turn off the "there were breakpoints in this file"
9731             # bit, the entry in %had_breakpoints for this file is zero,
9732             # we should remove this file from the hash.
9733             if ( not $had_breakpoints{$file} &= ~1 ) {
9734                 delete $had_breakpoints{$file};
9735             }
9736         } ## end for $file (keys %had_breakpoints)
9737
9738         # Kill off all the other breakpoints that are waiting for files that
9739         # haven't been loaded yet.
9740         undef %postponed;
9741         undef %postponed_file;
9742         undef %break_on_load;
9743     } ## end if ($cmd =~ /^\s*$/)
9744 } ## end sub cmd_pre580_D
9745
9746 =head2 Old C<h> command
9747
9748 Print help. Defaults to printing the long-form help; the 5.8 version
9749 prints the summary by default.
9750
9751 =cut
9752
9753 sub cmd_pre580_h {
9754     my $xcmd = shift;
9755     my $cmd  = shift;
9756
9757     # Print the *right* help, long format.
9758     if ( $cmd =~ /^\s*$/ ) {
9759         print_help($pre580_help);
9760     }
9761
9762     # 'h h' - explicitly-requested summary.
9763     elsif ( $cmd =~ /^h\s*/ ) {
9764         print_help($pre580_summary);
9765     }
9766
9767     # Find and print a command's help.
9768     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9769         my $asked  = $1;                   # for proper errmsg
9770         my $qasked = quotemeta($asked);    # for searching
9771                                            # XXX: finds CR but not <CR>
9772         if (
9773             $pre580_help =~ /^
9774                               <?           # Optional '<'
9775                               (?:[IB]<)    # Optional markup
9776                               $qasked      # The command name
9777                             /mx
9778           )
9779         {
9780
9781             while (
9782                 $pre580_help =~ /^
9783                                   (             # The command help:
9784                                    <?           # Optional '<'
9785                                    (?:[IB]<)    # Optional markup
9786                                    $qasked      # The command name
9787                                    ([\s\S]*?)   # Lines starting with tabs
9788                                    \n           # Final newline
9789                                   )
9790                                   (?!\s)/mgx
9791               )    # Line not starting with space
9792                    # (Next command's help)
9793             {
9794                 print_help($1);
9795             }
9796         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9797
9798         # Help not found.
9799         else {
9800             print_help("B<$asked> is not a debugger command.\n");
9801         }
9802     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9803 } ## end sub cmd_pre580_h
9804
9805 =head2 Old C<W> command
9806
9807 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9808
9809 =cut
9810
9811 sub cmd_pre580_W {
9812     my $xcmd = shift;
9813     my $cmd  = shift;
9814
9815     # Delete all watch expressions.
9816     if ( $cmd =~ /^$/ ) {
9817
9818         # No watching is going on.
9819         $trace &= ~2;
9820
9821         # Kill all the watch expressions and values.
9822         @to_watch = @old_watch = ();
9823     }
9824
9825     # Add a watch expression.
9826     elsif ( $cmd =~ /^(.*)/s ) {
9827
9828         # add it to the list to be watched.
9829         push @to_watch, $1;
9830
9831         # Get the current value of the expression.
9832         # Doesn't handle expressions returning list values!
9833         $evalarg = $1;
9834         my ($val) = DB::eval();
9835         $val = ( defined $val ) ? "'$val'" : 'undef';
9836
9837         # Save it.
9838         push @old_watch, $val;
9839
9840         # We're watching stuff.
9841         $trace |= 2;
9842
9843     } ## end elsif ($cmd =~ /^(.*)/s)
9844 } ## end sub cmd_pre580_W
9845
9846 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9847
9848 The debugger used to have a bunch of nearly-identical code to handle
9849 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9850 C<cmd_prepost> unify all this into one set of code to handle the
9851 appropriate actions.
9852
9853 =head2 C<cmd_pre590_prepost>
9854
9855 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9856 do something destructive. In pre 5.8 debuggers, the default action was to
9857 delete all the actions.
9858
9859 =cut
9860
9861 sub cmd_pre590_prepost {
9862     my $cmd    = shift;
9863     my $line   = shift || '*';
9864     my $dbline = shift;
9865
9866     return &cmd_prepost( $cmd, $line, $dbline );
9867 } ## end sub cmd_pre590_prepost
9868
9869 =head2 C<cmd_prepost>
9870
9871 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9872 Since the lists of actions are all held in arrays that are pointed to by
9873 references anyway, all we have to do is pick the right array reference and
9874 then use generic code to all, delete, or list actions.
9875
9876 =cut
9877
9878 sub cmd_prepost {
9879     my $cmd = shift;
9880
9881     # No action supplied defaults to 'list'.
9882     my $line = shift || '?';
9883
9884     # Figure out what to put in the prompt.
9885     my $which = '';
9886
9887     # Make sure we have some array or another to address later.
9888     # This means that if ssome reason the tests fail, we won't be
9889     # trying to stash actions or delete them from the wrong place.
9890     my $aref = [];
9891
9892     # < - Perl code to run before prompt.
9893     if ( $cmd =~ /^\</o ) {
9894         $which = 'pre-perl';
9895         $aref  = $pre;
9896     }
9897
9898     # > - Perl code to run after prompt.
9899     elsif ( $cmd =~ /^\>/o ) {
9900         $which = 'post-perl';
9901         $aref  = $post;
9902     }
9903
9904     # { - first check for properly-balanced braces.
9905     elsif ( $cmd =~ /^\{/o ) {
9906         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9907             print $OUT
9908 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
9909         }
9910
9911         # Properly balanced. Pre-prompt debugger actions.
9912         else {
9913             $which = 'pre-debugger';
9914             $aref  = $pretype;
9915         }
9916     } ## end elsif ( $cmd =~ /^\{/o )
9917
9918     # Did we find something that makes sense?
9919     unless ($which) {
9920         print $OUT "Confused by command: $cmd\n";
9921     }
9922
9923     # Yes.
9924     else {
9925
9926         # List actions.
9927         if ( $line =~ /^\s*\?\s*$/o ) {
9928             unless (@$aref) {
9929
9930                 # Nothing there. Complain.
9931                 print $OUT "No $which actions.\n";
9932             }
9933             else {
9934
9935                 # List the actions in the selected list.
9936                 print $OUT "$which commands:\n";
9937                 foreach my $action (@$aref) {
9938                     print $OUT "\t$cmd -- $action\n";
9939                 }
9940             } ## end else
9941         } ## end if ( $line =~ /^\s*\?\s*$/o)
9942
9943         # Might be a delete.
9944         else {
9945             if ( length($cmd) == 1 ) {
9946                 if ( $line =~ /^\s*\*\s*$/o ) {
9947
9948                     # It's a delete. Get rid of the old actions in the
9949                     # selected list..
9950                     @$aref = ();
9951                     print $OUT "All $cmd actions cleared.\n";
9952                 }
9953                 else {
9954
9955                     # Replace all the actions. (This is a <, >, or {).
9956                     @$aref = action($line);
9957                 }
9958             } ## end if ( length($cmd) == 1)
9959             elsif ( length($cmd) == 2 ) {
9960
9961                 # Add the action to the line. (This is a <<, >>, or {{).
9962                 push @$aref, action($line);
9963             }
9964             else {
9965
9966                 # <<<, >>>>, {{{{{{ ... something not a command.
9967                 print $OUT
9968                   "Confused by strange length of $which command($cmd)...\n";
9969             }
9970         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9971     } ## end else
9972 } ## end sub cmd_prepost
9973
9974 =head1 C<DB::fake>
9975
9976 Contains the C<at_exit> routine that the debugger uses to issue the
9977 C<Debugged program terminated ...> message after the program completes. See
9978 the C<END> block documentation for more details.
9979
9980 =cut
9981
9982 package DB::fake;
9983
9984 sub at_exit {
9985     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
9986 }
9987
9988 package DB;    # Do not trace this 1; below!
9989
9990 1;
9991
9992