This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: Set proxy tables
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34
35 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
36 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
37
38 ##########################################################################
39 #
40 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
41 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
42 # a pod file and a .t file
43 #
44 # The structure of this file is:
45 #   First these introductory comments; then
46 #   code needed for everywhere, such as debugging stuff; then
47 #   code to handle input parameters; then
48 #   data structures likely to be of external interest (some of which depend on
49 #       the input parameters, so follows them; then
50 #   more data structures and subroutine and package (class) definitions; then
51 #   the small actual loop to process the input files and finish up; then
52 #   a __DATA__ section, for the .t tests
53 #
54 # This program works on all releases of Unicode through at least 6.0.  The
55 # outputs have been scrutinized most intently for release 5.1.  The others
56 # have been checked for somewhat more than just sanity.  It can handle all
57 # existing Unicode character properties in those releases.
58 #
59 # This program is mostly about Unicode character (or code point) properties.
60 # A property describes some attribute or quality of a code point, like if it
61 # is lowercase or not, its name, what version of Unicode it was first defined
62 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
63 # possibilities by making all properties into mappings from each code point
64 # into some corresponding value.  In the case of it being lowercase or not,
65 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
66 # property maps each Unicode code point to a single value, called a "property
67 # value".  (Hence each Unicode property is a true mathematical function with
68 # exactly one value per code point.)
69 #
70 # When using a property in a regular expression, what is desired isn't the
71 # mapping of the code point to its property's value, but the reverse (or the
72 # mathematical "inverse relation"): starting with the property value, "Does a
73 # code point map to it?"  These are written in a "compound" form:
74 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
75 # files containing the lists of code points that map to each such regular
76 # expression property value, one file per list
77 #
78 # There is also a single form shortcut that Perl adds for many of the commonly
79 # used properties.  This happens for all binary properties, plus script,
80 # general_category, and block properties.
81 #
82 # Thus the outputs of this program are files.  There are map files, mostly in
83 # the 'To' directory; and there are list files for use in regular expression
84 # matching, all in subdirectories of the 'lib' directory, with each
85 # subdirectory being named for the property that the lists in it are for.
86 # Bookkeeping, test, and documentation files are also generated.
87
88 my $matches_directory = 'lib';   # Where match (\p{}) files go.
89 my $map_directory = 'To';        # Where map files go.
90
91 # DATA STRUCTURES
92 #
93 # The major data structures of this program are Property, of course, but also
94 # Table.  There are two kinds of tables, very similar to each other.
95 # "Match_Table" is the data structure giving the list of code points that have
96 # a particular property value, mentioned above.  There is also a "Map_Table"
97 # data structure which gives the property's mapping from code point to value.
98 # There are two structures because the match tables need to be combined in
99 # various ways, such as constructing unions, intersections, complements, etc.,
100 # and the map ones don't.  And there would be problems, perhaps subtle, if
101 # a map table were inadvertently operated on in some of those ways.
102 # The use of separate classes with operations defined on one but not the other
103 # prevents accidentally confusing the two.
104 #
105 # At the heart of each table's data structure is a "Range_List", which is just
106 # an ordered list of "Ranges", plus ancillary information, and methods to
107 # operate on them.  A Range is a compact way to store property information.
108 # Each range has a starting code point, an ending code point, and a value that
109 # is meant to apply to all the code points between the two end points,
110 # inclusive.  For a map table, this value is the property value for those
111 # code points.  Two such ranges could be written like this:
112 #   0x41 .. 0x5A, 'Upper',
113 #   0x61 .. 0x7A, 'Lower'
114 #
115 # Each range also has a type used as a convenience to classify the values.
116 # Most ranges in this program will be Type 0, or normal, but there are some
117 # ranges that have a non-zero type.  These are used only in map tables, and
118 # are for mappings that don't fit into the normal scheme of things.  Mappings
119 # that require a hash entry to communicate with utf8.c are one example;
120 # another example is mappings for charnames.pm to use which indicate a name
121 # that is algorithmically determinable from its code point (and vice-versa).
122 # These are used to significantly compact these tables, instead of listing
123 # each one of the tens of thousands individually.
124 #
125 # In a match table, the value of a range is irrelevant (and hence the type as
126 # well, which will always be 0), and arbitrarily set to the null string.
127 # Using the example above, there would be two match tables for those two
128 # entries, one named Upper would contain the 0x41..0x5A range, and the other
129 # named Lower would contain 0x61..0x7A.
130 #
131 # Actually, there are two types of range lists, "Range_Map" is the one
132 # associated with map tables, and "Range_List" with match tables.
133 # Again, this is so that methods can be defined on one and not the other so as
134 # to prevent operating on them in incorrect ways.
135 #
136 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
137 # in the perl core.  All tables could in theory be written, but some are
138 # suppressed because there is no current practical use for them.  It is easy
139 # to change which get written by changing various lists that are near the top
140 # of the actual code in this file.  The table data structures contain enough
141 # ancillary information to allow them to be treated as separate entities for
142 # writing, such as the path to each one's file.  There is a heading in each
143 # map table that gives the format of its entries, and what the map is for all
144 # the code points missing from it.  (This allows tables to be more compact.)
145 #
146 # The Property data structure contains one or more tables.  All properties
147 # contain a map table (except the $perl property which is a
148 # pseudo-property containing only match tables), and any properties that
149 # are usable in regular expression matches also contain various matching
150 # tables, one for each value the property can have.  A binary property can
151 # have two values, True and False (or Y and N, which are preferred by Unicode
152 # terminology).  Thus each of these properties will have a map table that
153 # takes every code point and maps it to Y or N (but having ranges cuts the
154 # number of entries in that table way down), and two match tables, one
155 # which has a list of all the code points that map to Y, and one for all the
156 # code points that map to N.  (For each of these, a third table is also
157 # generated for the pseudo Perl property.  It contains the identical code
158 # points as the Y table, but can be written, not in the compound form, but in
159 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
160 # properties have several possible values, some have many, and properties like
161 # Name have a different value for every named code point.  Those will not,
162 # unless the controlling lists are changed, have their match tables written
163 # out.  But all the ones which can be used in regular expression \p{} and \P{}
164 # constructs will.  Prior to 5.14, generally a property would have either its
165 # map table or its match tables written but not both.  Again, what gets
166 # written is controlled by lists which can easily be changed.  Starting in
167 # 5.14, advantage was taken of this, and all the map tables needed to
168 # reconstruct the Unicode db are now written out, while suppressing the
169 # Unicode .txt files that contain the data.  Our tables are much more compact
170 # than the .txt files, so a significant space savings was achieved.
171
172 # Properties have a 'Type', like binary, or string, or enum depending on how
173 # many match tables there are and the content of the maps.  This 'Type' is
174 # different than a range 'Type', so don't get confused by the two concepts
175 # having the same name.
176 #
177 # For information about the Unicode properties, see Unicode's UAX44 document:
178
179 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
180
181 # As stated earlier, this program will work on any release of Unicode so far.
182 # Most obvious problems in earlier data have NOT been corrected except when
183 # necessary to make Perl or this program work reasonably.  For example, no
184 # folding information was given in early releases, so this program substitutes
185 # lower case instead, just so that a regular expression with the /i option
186 # will do something that actually gives the right results in many cases.
187 # There are also a couple other corrections for version 1.1.5, commented at
188 # the point they are made.  As an example of corrections that weren't made
189 # (but could be) is this statement from DerivedAge.txt: "The supplementary
190 # private use code points and the non-character code points were assigned in
191 # version 2.0, but not specifically listed in the UCD until versions 3.0 and
192 # 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0) More information
193 # on Unicode version glitches is further down in these introductory comments.
194 #
195 # This program works on all non-provisional properties as of 6.0, though the
196 # files for some are suppressed from apparent lack of demand for them.  You
197 # can change which are output by changing lists in this program.
198 #
199 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
200 # loose matchings rules (from Unicode TR18):
201 #
202 #    The recommended names for UCD properties and property values are in
203 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
204 #    [PropValue]. There are both abbreviated names and longer, more
205 #    descriptive names. It is strongly recommended that both names be
206 #    recognized, and that loose matching of property names be used,
207 #    whereby the case distinctions, whitespace, hyphens, and underbar
208 #    are ignored.
209 # The program still allows Fuzzy to override its determination of if loose
210 # matching should be used, but it isn't currently used, as it is no longer
211 # needed; the calculations it makes are good enough.
212 #
213 # SUMMARY OF HOW IT WORKS:
214 #
215 #   Process arguments
216 #
217 #   A list is constructed containing each input file that is to be processed
218 #
219 #   Each file on the list is processed in a loop, using the associated handler
220 #   code for each:
221 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
222 #            first.  These files name the properties and property values.
223 #            Objects are created of all the property and property value names
224 #            that the rest of the input should expect, including all synonyms.
225 #        The other input files give mappings from properties to property
226 #           values.  That is, they list code points and say what the mapping
227 #           is under the given property.  Some files give the mappings for
228 #           just one property; and some for many.  This program goes through
229 #           each file and populates the properties from them.  Some properties
230 #           are listed in more than one file, and Unicode has set up a
231 #           precedence as to which has priority if there is a conflict.  Thus
232 #           the order of processing matters, and this program handles the
233 #           conflict possibility by processing the overriding input files
234 #           last, so that if necessary they replace earlier values.
235 #        After this is all done, the program creates the property mappings not
236 #            furnished by Unicode, but derivable from what it does give.
237 #        The tables of code points that match each property value in each
238 #            property that is accessible by regular expressions are created.
239 #        The Perl-defined properties are created and populated.  Many of these
240 #            require data determined from the earlier steps
241 #        Any Perl-defined synonyms are created, and name clashes between Perl
242 #            and Unicode are reconciled and warned about.
243 #        All the properties are written to files
244 #        Any other files are written, and final warnings issued.
245 #
246 # For clarity, a number of operators have been overloaded to work on tables:
247 #   ~ means invert (take all characters not in the set).  The more
248 #       conventional '!' is not used because of the possibility of confusing
249 #       it with the actual boolean operation.
250 #   + means union
251 #   - means subtraction
252 #   & means intersection
253 # The precedence of these is the order listed.  Parentheses should be
254 # copiously used.  These are not a general scheme.  The operations aren't
255 # defined for a number of things, deliberately, to avoid getting into trouble.
256 # Operations are done on references and affect the underlying structures, so
257 # that the copy constructors for them have been overloaded to not return a new
258 # clone, but the input object itself.
259 #
260 # The bool operator is deliberately not overloaded to avoid confusion with
261 # "should it mean if the object merely exists, or also is non-empty?".
262 #
263 # WHY CERTAIN DESIGN DECISIONS WERE MADE
264 #
265 # This program needs to be able to run under miniperl.  Therefore, it uses a
266 # minimum of other modules, and hence implements some things itself that could
267 # be gotten from CPAN
268 #
269 # This program uses inputs published by the Unicode Consortium.  These can
270 # change incompatibly between releases without the Perl maintainers realizing
271 # it.  Therefore this program is now designed to try to flag these.  It looks
272 # at the directories where the inputs are, and flags any unrecognized files.
273 # It keeps track of all the properties in the files it handles, and flags any
274 # that it doesn't know how to handle.  It also flags any input lines that
275 # don't match the expected syntax, among other checks.
276 #
277 # It is also designed so if a new input file matches one of the known
278 # templates, one hopefully just needs to add it to a list to have it
279 # processed.
280 #
281 # As mentioned earlier, some properties are given in more than one file.  In
282 # particular, the files in the extracted directory are supposedly just
283 # reformattings of the others.  But they contain information not easily
284 # derivable from the other files, including results for Unihan, which this
285 # program doesn't ordinarily look at, and for unassigned code points.  They
286 # also have historically had errors or been incomplete.  In an attempt to
287 # create the best possible data, this program thus processes them first to
288 # glean information missing from the other files; then processes those other
289 # files to override any errors in the extracted ones.  Much of the design was
290 # driven by this need to store things and then possibly override them.
291 #
292 # It tries to keep fatal errors to a minimum, to generate something usable for
293 # testing purposes.  It always looks for files that could be inputs, and will
294 # warn about any that it doesn't know how to handle (the -q option suppresses
295 # the warning).
296 #
297 # Why is there more than one type of range?
298 #   This simplified things.  There are some very specialized code points that
299 #   have to be handled specially for output, such as Hangul syllable names.
300 #   By creating a range type (done late in the development process), it
301 #   allowed this to be stored with the range, and overridden by other input.
302 #   Originally these were stored in another data structure, and it became a
303 #   mess trying to decide if a second file that was for the same property was
304 #   overriding the earlier one or not.
305 #
306 # Why are there two kinds of tables, match and map?
307 #   (And there is a base class shared by the two as well.)  As stated above,
308 #   they actually are for different things.  Development proceeded much more
309 #   smoothly when I (khw) realized the distinction.  Map tables are used to
310 #   give the property value for every code point (actually every code point
311 #   that doesn't map to a default value).  Match tables are used for regular
312 #   expression matches, and are essentially the inverse mapping.  Separating
313 #   the two allows more specialized methods, and error checks so that one
314 #   can't just take the intersection of two map tables, for example, as that
315 #   is nonsensical.
316 #
317 # DEBUGGING
318 #
319 # This program is written so it will run under miniperl.  Occasionally changes
320 # will cause an error where the backtrace doesn't work well under miniperl.
321 # To diagnose the problem, you can instead run it under regular perl, if you
322 # have one compiled.
323 #
324 # There is a good trace facility.  To enable it, first sub DEBUG must be set
325 # to return true.  Then a line like
326 #
327 # local $to_trace = 1 if main::DEBUG;
328 #
329 # can be added to enable tracing in its lexical scope or until you insert
330 # another line:
331 #
332 # local $to_trace = 0 if main::DEBUG;
333 #
334 # then use a line like "trace $a, @b, %c, ...;
335 #
336 # Some of the more complex subroutines already have trace statements in them.
337 # Permanent trace statements should be like:
338 #
339 # trace ... if main::DEBUG && $to_trace;
340 #
341 # If there is just one or a few files that you're debugging, you can easily
342 # cause most everything else to be skipped.  Change the line
343 #
344 # my $debug_skip = 0;
345 #
346 # to 1, and every file whose object is in @input_file_objects and doesn't have
347 # a, 'non_skip => 1,' in its constructor will be skipped.
348 #
349 # To compare the output tables, it may be useful to specify the -annotate
350 # flag.  This causes the tables to expand so there is one entry for each
351 # non-algorithmically named code point giving, currently its name, and its
352 # graphic representation if printable (and you have a font that knows about
353 # it).  This makes it easier to see what the particular code points are in
354 # each output table.  The tables are usable, but because they don't have
355 # ranges (for the most part), a Perl using them will run slower.  Non-named
356 # code points are annotated with a description of their status, and contiguous
357 # ones with the same description will be output as a range rather than
358 # individually.  Algorithmically named characters are also output as ranges,
359 # except when there are just a few contiguous ones.
360 #
361 # FUTURE ISSUES
362 #
363 # The program would break if Unicode were to change its names so that
364 # interior white space, underscores, or dashes differences were significant
365 # within property and property value names.
366 #
367 # It might be easier to use the xml versions of the UCD if this program ever
368 # would need heavy revision, and the ability to handle old versions was not
369 # required.
370 #
371 # There is the potential for name collisions, in that Perl has chosen names
372 # that Unicode could decide it also likes.  There have been such collisions in
373 # the past, with mostly Perl deciding to adopt the Unicode definition of the
374 # name.  However in the 5.2 Unicode beta testing, there were a number of such
375 # collisions, which were withdrawn before the final release, because of Perl's
376 # and other's protests.  These all involved new properties which began with
377 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
378 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
379 # Unicode document, so they are unlikely to be used by Unicode for another
380 # purpose.  However, they might try something beginning with 'In', or use any
381 # of the other Perl-defined properties.  This program will warn you of name
382 # collisions, and refuse to generate tables with them, but manual intervention
383 # will be required in this event.  One scheme that could be implemented, if
384 # necessary, would be to have this program generate another file, or add a
385 # field to mktables.lst that gives the date of first definition of a property.
386 # Each new release of Unicode would use that file as a basis for the next
387 # iteration.  And the Perl synonym addition code could sort based on the age
388 # of the property, so older properties get priority, and newer ones that clash
389 # would be refused; hence existing code would not be impacted, and some other
390 # synonym would have to be used for the new property.  This is ugly, and
391 # manual intervention would certainly be easier to do in the short run; lets
392 # hope it never comes to this.
393 #
394 # A NOTE ON UNIHAN
395 #
396 # This program can generate tables from the Unihan database.  But it doesn't
397 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
398 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
399 # database was split into 8 different files, all beginning with the letters
400 # 'Unihan'.  This program will read those file(s) if present, but it needs to
401 # know which of the many properties in the file(s) should have tables created
402 # for them.  It will create tables for any properties listed in
403 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
404 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
405 # property you want is not in those files of the release you are building
406 # against, you must add it to those two arrays.  Starting in 4.0, the
407 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
408 # is present in the directory, a table will be generated for that property.
409 # In 5.2, several more properties were added.  For your convenience, the two
410 # arrays are initialized with all the 6.0 listed properties that are also in
411 # earlier releases.  But these are commented out.  You can just uncomment the
412 # ones you want, or use them as a template for adding entries for other
413 # properties.
414 #
415 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
416 # and filter_unihan_line() are the functions where this is done.  This program
417 # already does some adjusting to make the lines look more like the rest of the
418 # Unicode DB;  You can see what that is in filter_unihan_line()
419 #
420 # There is a bug in the 3.2 data file in which some values for the
421 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
422 # could be added for these; or for a particular installation, the Unihan.txt
423 # file could be edited to fix them.
424 #
425 # HOW TO ADD A FILE TO BE PROCESSED
426 #
427 # A new file from Unicode needs to have an object constructed for it in
428 # @input_file_objects, probably at the end or at the end of the extracted
429 # ones.  The program should warn you if its name will clash with others on
430 # restrictive file systems, like DOS.  If so, figure out a better name, and
431 # add lines to the README.perl file giving that.  If the file is a character
432 # property, it should be in the format that Unicode has by default
433 # standardized for such files for the more recently introduced ones.
434 # If so, the Input_file constructor for @input_file_objects can just be the
435 # file name and release it first appeared in.  If not, then it should be
436 # possible to construct an each_line_handler() to massage the line into the
437 # standardized form.
438 #
439 # For non-character properties, more code will be needed.  You can look at
440 # the existing entries for clues.
441 #
442 # UNICODE VERSIONS NOTES
443 #
444 # The Unicode UCD has had a number of errors in it over the versions.  And
445 # these remain, by policy, in the standard for that version.  Therefore it is
446 # risky to correct them, because code may be expecting the error.  So this
447 # program doesn't generally make changes, unless the error breaks the Perl
448 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
449 # for U+1105, which causes real problems for the algorithms for Jamo
450 # calculations, so it is changed here.
451 #
452 # But it isn't so clear cut as to what to do about concepts that are
453 # introduced in a later release; should they extend back to earlier releases
454 # where the concept just didn't exist?  It was easier to do this than to not,
455 # so that's what was done.  For example, the default value for code points not
456 # in the files for various properties was probably undefined until changed by
457 # some version.  No_Block for blocks is such an example.  This program will
458 # assign No_Block even in Unicode versions that didn't have it.  This has the
459 # benefit that code being written doesn't have to special case earlier
460 # versions; and the detriment that it doesn't match the Standard precisely for
461 # the affected versions.
462 #
463 # Here are some observations about some of the issues in early versions:
464 #
465 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
466 # the reason is that the CJK block starting at 4E00 was removed from PropList,
467 # and was not put back in until 3.1.0
468 #
469 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
470 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
471 # reason is that 3.2 introduced U+205F=medium math space, which was not
472 # classed as white space, but Perl figured out that it should have been. 4.0
473 # reclassified it correctly.
474 #
475 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
476 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
477 # was left with no code points, as all the ones that mapped to 202 stayed
478 # mapped to 202.  Thus if your program used the numeric name for the class,
479 # it would not have been affected, but if it used the mnemonic, it would have
480 # been.
481 #
482 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
483 # points which eventually came to have this script property value, instead
484 # mapped to "Unknown".  But in the next release all these code points were
485 # moved to \p{sc=common} instead.
486 #
487 # The default for missing code points for BidiClass is complicated.  Starting
488 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
489 # tries to do the best it can for earlier releases.  It is done in
490 # process_PropertyAliases()
491 #
492 ##############################################################################
493
494 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
495                         # and errors
496 my $MAX_LINE_WIDTH = 78;
497
498 # Debugging aid to skip most files so as to not be distracted by them when
499 # concentrating on the ones being debugged.  Add
500 # non_skip => 1,
501 # to the constructor for those files you want processed when you set this.
502 # Files with a first version number of 0 are special: they are always
503 # processed regardless of the state of this flag.  Generally, Jamo.txt and
504 # UnicodeData.txt must not be skipped if you want this program to not die
505 # before normal completion.
506 my $debug_skip = 0;
507
508 # Set to 1 to enable tracing.
509 our $to_trace = 0;
510
511 { # Closure for trace: debugging aid
512     my $print_caller = 1;        # ? Include calling subroutine name
513     my $main_with_colon = 'main::';
514     my $main_colon_length = length($main_with_colon);
515
516     sub trace {
517         return unless $to_trace;        # Do nothing if global flag not set
518
519         my @input = @_;
520
521         local $DB::trace = 0;
522         $DB::trace = 0;          # Quiet 'used only once' message
523
524         my $line_number;
525
526         # Loop looking up the stack to get the first non-trace caller
527         my $caller_line;
528         my $caller_name;
529         my $i = 0;
530         do {
531             $line_number = $caller_line;
532             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
533             $caller = $main_with_colon unless defined $caller;
534
535             $caller_name = $caller;
536
537             # get rid of pkg
538             $caller_name =~ s/.*:://;
539             if (substr($caller_name, 0, $main_colon_length)
540                 eq $main_with_colon)
541             {
542                 $caller_name = substr($caller_name, $main_colon_length);
543             }
544
545         } until ($caller_name ne 'trace');
546
547         # If the stack was empty, we were called from the top level
548         $caller_name = 'main' if ($caller_name eq ""
549                                     || $caller_name eq 'trace');
550
551         my $output = "";
552         foreach my $string (@input) {
553             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
554             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
555                 $output .= simple_dumper($string);
556             }
557             else {
558                 $string = "$string" if ref $string;
559                 $string = $UNDEF unless defined $string;
560                 chomp $string;
561                 $string = '""' if $string eq "";
562                 $output .= " " if $output ne ""
563                                 && $string ne ""
564                                 && substr($output, -1, 1) ne " "
565                                 && substr($string, 0, 1) ne " ";
566                 $output .= $string;
567             }
568         }
569
570         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
571         print STDERR "$caller_name: " if $print_caller;
572         print STDERR $output, "\n";
573         return;
574     }
575 }
576
577 # This is for a rarely used development feature that allows you to compare two
578 # versions of the Unicode standard without having to deal with changes caused
579 # by the code points introduced in the later version.  Change the 0 to a
580 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
581 # code points introduced in that release and earlier will be used; later ones
582 # are thrown away.  You use the version number of the earliest one you want to
583 # compare; then run this program on directory structures containing each
584 # release, and compare the outputs.  These outputs will therefore include only
585 # the code points common to both releases, and you can see the changes caused
586 # just by the underlying release semantic changes.  For versions earlier than
587 # 3.2, you must copy a version of DAge.txt into the directory.
588 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
589 my $compare_versions = DEBUG
590                        && $string_compare_versions
591                        && pack "C*", split /\./, $string_compare_versions;
592
593 sub uniques {
594     # Returns non-duplicated input values.  From "Perl Best Practices:
595     # Encapsulated Cleverness".  p. 455 in first edition.
596
597     my %seen;
598     # Arguably this breaks encapsulation, if the goal is to permit multiple
599     # distinct objects to stringify to the same value, and be interchangeable.
600     # However, for this program, no two objects stringify identically, and all
601     # lists passed to this function are either objects or strings. So this
602     # doesn't affect correctness, but it does give a couple of percent speedup.
603     no overloading;
604     return grep { ! $seen{$_}++ } @_;
605 }
606
607 $0 = File::Spec->canonpath($0);
608
609 my $make_test_script = 0;      # ? Should we output a test script
610 my $write_unchanged_files = 0; # ? Should we update the output files even if
611                                #    we don't think they have changed
612 my $use_directory = "";        # ? Should we chdir somewhere.
613 my $pod_directory;             # input directory to store the pod file.
614 my $pod_file = 'perluniprops';
615 my $t_path;                     # Path to the .t test file
616 my $file_list = 'mktables.lst'; # File to store input and output file names.
617                                # This is used to speed up the build, by not
618                                # executing the main body of the program if
619                                # nothing on the list has changed since the
620                                # previous build
621 my $make_list = 1;             # ? Should we write $file_list.  Set to always
622                                # make a list so that when the pumpking is
623                                # preparing a release, s/he won't have to do
624                                # special things
625 my $glob_list = 0;             # ? Should we try to include unknown .txt files
626                                # in the input.
627 my $output_range_counts = $debugging_build;   # ? Should we include the number
628                                               # of code points in ranges in
629                                               # the output
630 my $annotate = 0;              # ? Should character names be in the output
631
632 # Verbosity levels; 0 is quiet
633 my $NORMAL_VERBOSITY = 1;
634 my $PROGRESS = 2;
635 my $VERBOSE = 3;
636
637 my $verbosity = $NORMAL_VERBOSITY;
638
639 # Process arguments
640 while (@ARGV) {
641     my $arg = shift @ARGV;
642     if ($arg eq '-v') {
643         $verbosity = $VERBOSE;
644     }
645     elsif ($arg eq '-p') {
646         $verbosity = $PROGRESS;
647         $| = 1;     # Flush buffers as we go.
648     }
649     elsif ($arg eq '-q') {
650         $verbosity = 0;
651     }
652     elsif ($arg eq '-w') {
653         $write_unchanged_files = 1; # update the files even if havent changed
654     }
655     elsif ($arg eq '-check') {
656         my $this = shift @ARGV;
657         my $ok = shift @ARGV;
658         if ($this ne $ok) {
659             print "Skipping as check params are not the same.\n";
660             exit(0);
661         }
662     }
663     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
664         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
665     }
666     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
667     {
668         $make_test_script = 1;
669     }
670     elsif ($arg eq '-makelist') {
671         $make_list = 1;
672     }
673     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
674         -d $use_directory or croak "Unknown directory '$use_directory'";
675     }
676     elsif ($arg eq '-L') {
677
678         # Existence not tested until have chdir'd
679         $file_list = shift;
680     }
681     elsif ($arg eq '-globlist') {
682         $glob_list = 1;
683     }
684     elsif ($arg eq '-c') {
685         $output_range_counts = ! $output_range_counts
686     }
687     elsif ($arg eq '-annotate') {
688         $annotate = 1;
689         $debugging_build = 1;
690         $output_range_counts = 1;
691     }
692     else {
693         my $with_c = 'with';
694         $with_c .= 'out' if $output_range_counts;   # Complements the state
695         croak <<END;
696 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
697           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
698           [-check A B ]
699   -c          : Output comments $with_c number of code points in ranges
700   -q          : Quiet Mode: Only output serious warnings.
701   -p          : Set verbosity level to normal plus show progress.
702   -v          : Set Verbosity level high:  Show progress and non-serious
703                 warnings
704   -w          : Write files regardless
705   -C dir      : Change to this directory before proceeding. All relative paths
706                 except those specified by the -P and -T options will be done
707                 with respect to this directory.
708   -P dir      : Output $pod_file file to directory 'dir'.
709   -T path     : Create a test script as 'path'; overrides -maketest
710   -L filelist : Use alternate 'filelist' instead of standard one
711   -globlist   : Take as input all non-Test *.txt files in current and sub
712                 directories
713   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
714                 overrides -T
715   -makelist   : Rewrite the file list $file_list based on current setup
716   -annotate   : Output an annotation for each character in the table files;
717                 useful for debugging mktables, looking at diffs; but is slow,
718                 memory intensive; resulting tables are usable but slow and
719                 very large.
720   -check A B  : Executes $0 only if A and B are the same
721 END
722     }
723 }
724
725 # Stores the most-recently changed file.  If none have changed, can skip the
726 # build
727 my $most_recent = (stat $0)[9];   # Do this before the chdir!
728
729 # Change directories now, because need to read 'version' early.
730 if ($use_directory) {
731     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
732         $pod_directory = File::Spec->rel2abs($pod_directory);
733     }
734     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
735         $t_path = File::Spec->rel2abs($t_path);
736     }
737     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
738     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
739         $pod_directory = File::Spec->abs2rel($pod_directory);
740     }
741     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
742         $t_path = File::Spec->abs2rel($t_path);
743     }
744 }
745
746 # Get Unicode version into regular and v-string.  This is done now because
747 # various tables below get populated based on it.  These tables are populated
748 # here to be near the top of the file, and so easily seeable by those needing
749 # to modify things.
750 open my $VERSION, "<", "version"
751                     or croak "$0: can't open required file 'version': $!\n";
752 my $string_version = <$VERSION>;
753 close $VERSION;
754 chomp $string_version;
755 my $v_version = pack "C*", split /\./, $string_version;        # v string
756
757 # The following are the complete names of properties with property values that
758 # are known to not match any code points in some versions of Unicode, but that
759 # may change in the future so they should be matchable, hence an empty file is
760 # generated for them.
761 my @tables_that_may_be_empty = (
762                                 'Joining_Type=Left_Joining',
763                                 );
764 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
765 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
766 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
767                                                     if $v_version ge v4.1.0;
768 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
769                                                     if $v_version ge v6.0.0;
770
771 # The lists below are hashes, so the key is the item in the list, and the
772 # value is the reason why it is in the list.  This makes generation of
773 # documentation easier.
774
775 my %why_suppressed;  # No file generated for these.
776
777 # Files aren't generated for empty extraneous properties.  This is arguable.
778 # Extraneous properties generally come about because a property is no longer
779 # used in a newer version of Unicode.  If we generated a file without code
780 # points, programs that used to work on that property will still execute
781 # without errors.  It just won't ever match (or will always match, with \P{}).
782 # This means that the logic is now likely wrong.  I (khw) think its better to
783 # find this out by getting an error message.  Just move them to the table
784 # above to change this behavior
785 my %why_suppress_if_empty_warn_if_not = (
786
787    # It is the only property that has ever officially been removed from the
788    # Standard.  The database never contained any code points for it.
789    'Special_Case_Condition' => 'Obsolete',
790
791    # Apparently never official, but there were code points in some versions of
792    # old-style PropList.txt
793    'Non_Break' => 'Obsolete',
794 );
795
796 # These would normally go in the warn table just above, but they were changed
797 # a long time before this program was written, so warnings about them are
798 # moot.
799 if ($v_version gt v3.2.0) {
800     push @tables_that_may_be_empty,
801                                 'Canonical_Combining_Class=Attached_Below_Left'
802 }
803
804 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
805 # unless explicitly added.
806 if ($v_version ge v5.2.0) {
807     my $unihan = 'Unihan; remove from list if using Unihan';
808     foreach my $table (qw (
809                            kAccountingNumeric
810                            kOtherNumeric
811                            kPrimaryNumeric
812                            kCompatibilityVariant
813                            kIICore
814                            kIRG_GSource
815                            kIRG_HSource
816                            kIRG_JSource
817                            kIRG_KPSource
818                            kIRG_MSource
819                            kIRG_KSource
820                            kIRG_TSource
821                            kIRG_USource
822                            kIRG_VSource
823                            kRSUnicode
824                         ))
825     {
826         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
827     }
828 }
829
830 # Enum values for to_output_map() method in the Map_Table package.
831 my $EXTERNAL_MAP = 1;
832 my $INTERNAL_MAP = 2;
833
834 # To override computed values for writing the map tables for these properties.
835 # The default for enum map tables is to write them out, so that the Unicode
836 # .txt files can be removed, but all the data to compute any property value
837 # for any code point is available in a more compact form.
838 my %global_to_output_map = (
839     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
840     # get stuck supporting it if things change.  Since it is a STRING
841     # property, it normally would be listed in the pod, but INTERNAL_MAP
842     # suppresses that.
843     Unicode_1_Name => $INTERNAL_MAP,
844
845     Present_In => 0,                # Suppress, as easily computed from Age
846     Block => 0,                     # Suppress, as Blocks.txt is retained.
847
848     # Suppress, as mapping can be found instead from the
849     # Perl_Decomposition_Mapping file
850     Decomposition_Type => 0,
851 );
852
853 # Properties that this program ignores.
854 my @unimplemented_properties;
855
856 # With this release, it is automatically handled if the Unihan db is
857 # downloaded
858 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
859
860 # There are several types of obsolete properties defined by Unicode.  These
861 # must be hand-edited for every new Unicode release.
862 my %why_deprecated;  # Generates a deprecated warning message if used.
863 my %why_stabilized;  # Documentation only
864 my %why_obsolete;    # Documentation only
865
866 {   # Closure
867     my $simple = 'Perl uses the more complete version of this property';
868     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
869
870     my $other_properties = 'other properties';
871     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
872     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
873
874     %why_deprecated = (
875         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
876         'Jamo_Short_Name' => $contributory,
877         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
878         'Other_Alphabetic' => $contributory,
879         'Other_Default_Ignorable_Code_Point' => $contributory,
880         'Other_Grapheme_Extend' => $contributory,
881         'Other_ID_Continue' => $contributory,
882         'Other_ID_Start' => $contributory,
883         'Other_Lowercase' => $contributory,
884         'Other_Math' => $contributory,
885         'Other_Uppercase' => $contributory,
886         'Expands_On_NFC' => $why_no_expand,
887         'Expands_On_NFD' => $why_no_expand,
888         'Expands_On_NFKC' => $why_no_expand,
889         'Expands_On_NFKD' => $why_no_expand,
890     );
891
892     %why_suppressed = (
893         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
894         # contains the same information, but without the algorithmically
895         # determinable Hangul syllables'.  This file is not published, so it's
896         # existence is not noted in the comment.
897         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
898
899         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
900
901         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
902         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
903         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
904         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
905
906         'Name' => "Accessible via 'use charnames;'",
907         'Name_Alias' => "Accessible via 'use charnames;'",
908
909         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
910     );
911
912     # The following are suppressed because they were made contributory or
913     # deprecated by Unicode before Perl ever thought about supporting them.
914     foreach my $property ('Jamo_Short_Name',
915                           'Grapheme_Link',
916                           'Expands_On_NFC',
917                           'Expands_On_NFD',
918                           'Expands_On_NFKC',
919                           'Expands_On_NFKD'
920     ) {
921         $why_suppressed{$property} = $why_deprecated{$property};
922     }
923
924     # Customize the message for all the 'Other_' properties
925     foreach my $property (keys %why_deprecated) {
926         next if (my $main_property = $property) !~ s/^Other_//;
927         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
928     }
929 }
930
931 if ($v_version ge 4.0.0) {
932     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
933     if ($v_version ge 6.0.0) {
934         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
935     }
936 }
937 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
938     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
939     if ($v_version ge 6.0.0) {
940         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
941     }
942 }
943
944 # Probably obsolete forever
945 if ($v_version ge v4.1.0) {
946     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
947 }
948 if ($v_version ge v6.0.0) {
949     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana (or both)"';
950     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
951 }
952
953 # This program can create files for enumerated-like properties, such as
954 # 'Numeric_Type'.  This file would be the same format as for a string
955 # property, with a mapping from code point to its value, so you could look up,
956 # for example, the script a code point is in.  But no one so far wants this
957 # mapping, or they have found another way to get it since this is a new
958 # feature.  So no file is generated except if it is in this list.
959 my @output_mapped_properties = split "\n", <<END;
960 END
961
962 # If you are using the Unihan database in a Unicode version before 5.2, you
963 # need to add the properties that you want to extract from it to this table.
964 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
965 # listed, commented out
966 my @cjk_properties = split "\n", <<'END';
967 #cjkAccountingNumeric; kAccountingNumeric
968 #cjkOtherNumeric; kOtherNumeric
969 #cjkPrimaryNumeric; kPrimaryNumeric
970 #cjkCompatibilityVariant; kCompatibilityVariant
971 #cjkIICore ; kIICore
972 #cjkIRG_GSource; kIRG_GSource
973 #cjkIRG_HSource; kIRG_HSource
974 #cjkIRG_JSource; kIRG_JSource
975 #cjkIRG_KPSource; kIRG_KPSource
976 #cjkIRG_KSource; kIRG_KSource
977 #cjkIRG_TSource; kIRG_TSource
978 #cjkIRG_USource; kIRG_USource
979 #cjkIRG_VSource; kIRG_VSource
980 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
981 END
982
983 # Similarly for the property values.  For your convenience, the lines in the
984 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
985 # '#' marks (for Unicode versions before 5.2)
986 my @cjk_property_values = split "\n", <<'END';
987 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
988 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
989 ## @missing: 0000..10FFFF; cjkIICore; <none>
990 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
991 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
992 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
993 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
994 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
995 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
996 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
997 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
998 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
999 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1000 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1001 END
1002
1003 # The input files don't list every code point.  Those not listed are to be
1004 # defaulted to some value.  Below are hard-coded what those values are for
1005 # non-binary properties as of 5.1.  Starting in 5.0, there are
1006 # machine-parsable comment lines in the files the give the defaults; so this
1007 # list shouldn't have to be extended.  The claim is that all missing entries
1008 # for binary properties will default to 'N'.  Unicode tried to change that in
1009 # 5.2, but the beta period produced enough protest that they backed off.
1010 #
1011 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1012 # be in the form that it expects.  The others may be synonyms.
1013 my $CODE_POINT = '<code point>';
1014 my %default_mapping = (
1015     Age => "Unassigned",
1016     # Bidi_Class => Complicated; set in code
1017     Bidi_Mirroring_Glyph => "",
1018     Block => 'No_Block',
1019     Canonical_Combining_Class => 0,
1020     Case_Folding => $CODE_POINT,
1021     Decomposition_Mapping => $CODE_POINT,
1022     Decomposition_Type => 'None',
1023     East_Asian_Width => "Neutral",
1024     FC_NFKC_Closure => $CODE_POINT,
1025     General_Category => 'Cn',
1026     Grapheme_Cluster_Break => 'Other',
1027     Hangul_Syllable_Type => 'NA',
1028     ISO_Comment => "",
1029     Jamo_Short_Name => "",
1030     Joining_Group => "No_Joining_Group",
1031     # Joining_Type => Complicated; set in code
1032     kIICore => 'N',   #                       Is converted to binary
1033     #Line_Break => Complicated; set in code
1034     Lowercase_Mapping => $CODE_POINT,
1035     Name => "",
1036     Name_Alias => "",
1037     NFC_QC => 'Yes',
1038     NFD_QC => 'Yes',
1039     NFKC_QC => 'Yes',
1040     NFKD_QC => 'Yes',
1041     Numeric_Type => 'None',
1042     Numeric_Value => 'NaN',
1043     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1044     Sentence_Break => 'Other',
1045     Simple_Case_Folding => $CODE_POINT,
1046     Simple_Lowercase_Mapping => $CODE_POINT,
1047     Simple_Titlecase_Mapping => $CODE_POINT,
1048     Simple_Uppercase_Mapping => $CODE_POINT,
1049     Titlecase_Mapping => $CODE_POINT,
1050     Unicode_1_Name => "",
1051     Unicode_Radical_Stroke => "",
1052     Uppercase_Mapping => $CODE_POINT,
1053     Word_Break => 'Other',
1054 );
1055
1056 # Below are files that Unicode furnishes, but this program ignores, and why
1057 my %ignored_files = (
1058     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1059     'Index.txt' => 'Alphabetical index of Unicode characters',
1060     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1061     'NamesList.txt' => 'Annotated list of characters',
1062     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1063     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1064     'ReadMe.txt' => 'Documentation',
1065     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1066     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1067     'IndicMatraCategory.txt' => 'Provisional; for the analysis and processing of Indic scripts',
1068     'IndicSyllabicCategory.txt' => 'Provisional; for the analysis and processing of Indic scripts',
1069     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1070     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1071     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1072     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1073 );
1074
1075 ### End of externally interesting definitions, except for @input_file_objects
1076
1077 my $HEADER=<<"EOF";
1078 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1079 # This file is machine-generated by $0 from the Unicode
1080 # database, Version $string_version.  Any changes made here will be lost!
1081 EOF
1082
1083 my $INTERNAL_ONLY_HEADER = <<"EOF";
1084
1085 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1086 # This file is for internal use by core Perl only.  The format and even the
1087 # name or existence of this file are subject to change without notice.  Don't
1088 # use it directly.
1089 EOF
1090
1091 my $DEVELOPMENT_ONLY=<<"EOF";
1092 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1093 # This file contains information artificially constrained to code points
1094 # present in Unicode release $string_compare_versions.
1095 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1096 # not be used for production.
1097
1098 EOF
1099
1100 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1101 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1102 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1103
1104 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1105 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1106 # to decrease backtracking.  The first regex allows the code point to be at
1107 # the end of a word, but to work properly, the word shouldn't end with a valid
1108 # hex character.  The second one won't match a code point at the end of a
1109 # word, and doesn't have the run-on issue
1110 my $run_on_code_point_re =
1111             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1112 my $code_point_re = qr/\b$run_on_code_point_re/;
1113
1114 # This matches the beginning of the line in the Unicode db files that give the
1115 # defaults for code points not listed (i.e., missing) in the file.  The code
1116 # depends on this ending with a semi-colon, so it can assume it is a valid
1117 # field when the line is split() by semi-colons
1118 my $missing_defaults_prefix =
1119             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1120
1121 # Property types.  Unicode has more types, but these are sufficient for our
1122 # purposes.
1123 my $UNKNOWN = -1;   # initialized to illegal value
1124 my $NON_STRING = 1; # Either binary or enum
1125 my $BINARY = 2;
1126 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1127                        # tables, additional true and false tables are
1128                        # generated so that false is anything matching the
1129                        # default value, and true is everything else.
1130 my $ENUM = 4;       # Include catalog
1131 my $STRING = 5;     # Anything else: string or misc
1132
1133 # Some input files have lines that give default values for code points not
1134 # contained in the file.  Sometimes these should be ignored.
1135 my $NO_DEFAULTS = 0;        # Must evaluate to false
1136 my $NOT_IGNORED = 1;
1137 my $IGNORED = 2;
1138
1139 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1140 # and will appear in the main body of the tables in the output files, but
1141 # there are other types of ranges as well, listed below, that are specially
1142 # handled.   There are pseudo-types as well that will never be stored as a
1143 # type, but will affect the calculation of the type.
1144
1145 # 0 is for normal, non-specials
1146 my $MULTI_CP = 1;           # Sequence of more than code point
1147 my $HANGUL_SYLLABLE = 2;
1148 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1149 my $NULL = 4;               # The map is to the null string; utf8.c can't
1150                             # handle these, nor is there an accepted syntax
1151                             # for them in \p{} constructs
1152 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1153                              # otherwise be $MULTI_CP type are instead type 0
1154
1155 # process_generic_property_file() can accept certain overrides in its input.
1156 # Each of these must begin AND end with $CMD_DELIM.
1157 my $CMD_DELIM = "\a";
1158 my $REPLACE_CMD = 'replace';    # Override the Replace
1159 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1160
1161 my $NO = 0;
1162 my $YES = 1;
1163
1164 # Values for the Replace argument to add_range.
1165 # $NO                      # Don't replace; add only the code points not
1166                            # already present.
1167 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1168                            # the comments at the subroutine definition.
1169 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1170 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1171                            # already there
1172 my $CROAK = 5;             # Die with an error if is already there
1173
1174 # Flags to give property statuses.  The phrases are to remind maintainers that
1175 # if the flag is changed, the indefinite article referring to it in the
1176 # documentation may need to be as well.
1177 my $NORMAL = "";
1178 my $DEPRECATED = 'D';
1179 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1180 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1181 my $DISCOURAGED = 'X';
1182 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1183 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1184 my $STRICTER = 'T';
1185 my $a_bold_stricter = "a 'B<$STRICTER>'";
1186 my $A_bold_stricter = "A 'B<$STRICTER>'";
1187 my $STABILIZED = 'S';
1188 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1189 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1190 my $OBSOLETE = 'O';
1191 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1192 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1193
1194 my %status_past_participles = (
1195     $DISCOURAGED => 'discouraged',
1196     $STABILIZED => 'stabilized',
1197     $OBSOLETE => 'obsolete',
1198     $DEPRECATED => 'deprecated',
1199 );
1200
1201 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1202 # externally documented.
1203 my $ORDINARY = 0;       # The normal fate.
1204 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1205                         # but there is a file written that can be used to
1206                         # reconstruct this table
1207 my $SUPPRESSED = 3;     # The file for this table is not written out.
1208 my $INTERNAL_ONLY = 4;  # The file for this table is written out, but it is
1209                         # for Perl's internal use only
1210 my $PLACEHOLDER = 5;    # A property that is defined as a placeholder in a
1211                         # Unicode version that doesn't have it, but we need it
1212                         # to be defined, if empty, to have things work.
1213                         # Implies no pod entry generated
1214
1215 # The format of the values of the tables:
1216 my $EMPTY_FORMAT = "";
1217 my $BINARY_FORMAT = 'b';
1218 my $DECIMAL_FORMAT = 'd';
1219 my $FLOAT_FORMAT = 'f';
1220 my $INTEGER_FORMAT = 'i';
1221 my $HEX_FORMAT = 'x';
1222 my $RATIONAL_FORMAT = 'r';
1223 my $STRING_FORMAT = 's';
1224 my $DECOMP_STRING_FORMAT = 'c';
1225 my $STRING_WHITE_SPACE_LIST = 'sw';
1226
1227 my %map_table_formats = (
1228     $BINARY_FORMAT => 'binary',
1229     $DECIMAL_FORMAT => 'single decimal digit',
1230     $FLOAT_FORMAT => 'floating point number',
1231     $INTEGER_FORMAT => 'integer',
1232     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1233     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1234     $STRING_FORMAT => 'string',
1235     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1236     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1237 );
1238
1239 # Unicode didn't put such derived files in a separate directory at first.
1240 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1241 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1242 my $AUXILIARY = 'auxiliary';
1243
1244 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1245 my %loose_to_file_of;       # loosely maps table names to their respective
1246                             # files
1247 my %stricter_to_file_of;    # same; but for stricter mapping.
1248 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1249                              # their rational equivalent
1250 my %loose_property_name_of; # Loosely maps (non_string) property names to
1251                             # standard form
1252
1253 # Most properties are immune to caseless matching, otherwise you would get
1254 # nonsensical results, as properties are a function of a code point, not
1255 # everything that is caselessly equivalent to that code point.  For example,
1256 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1257 # be true because 's' and 'S' are equivalent caselessly.  However,
1258 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1259 # extend that concept to those very few properties that are like this.  Each
1260 # such property will match the full range caselessly.  They are hard-coded in
1261 # the program; it's not worth trying to make it general as it's extremely
1262 # unlikely that they will ever change.
1263 my %caseless_equivalent_to;
1264
1265 # These constants names and values were taken from the Unicode standard,
1266 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1267 # syllables.  The '_string' versions are so generated tables can retain the
1268 # hex format, which is the more familiar value
1269 my $SBase_string = "0xAC00";
1270 my $SBase = CORE::hex $SBase_string;
1271 my $LBase_string = "0x1100";
1272 my $LBase = CORE::hex $LBase_string;
1273 my $VBase_string = "0x1161";
1274 my $VBase = CORE::hex $VBase_string;
1275 my $TBase_string = "0x11A7";
1276 my $TBase = CORE::hex $TBase_string;
1277 my $SCount = 11172;
1278 my $LCount = 19;
1279 my $VCount = 21;
1280 my $TCount = 28;
1281 my $NCount = $VCount * $TCount;
1282
1283 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1284 # with the above published constants.
1285 my %Jamo;
1286 my %Jamo_L;     # Leading consonants
1287 my %Jamo_V;     # Vowels
1288 my %Jamo_T;     # Trailing consonants
1289
1290 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1291 # The key is the base name of the code point, and the value is an
1292 # array giving all the ranges that use this base name.  Each range
1293 # is actually a hash giving the 'low' and 'high' values of it.
1294 my %names_ending_in_code_point;
1295 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1296                                         # removed from the names
1297 # Inverse mapping.  The list of ranges that have these kinds of
1298 # names.  Each element contains the low, high, and base names in an
1299 # anonymous hash.
1300 my @code_points_ending_in_code_point;
1301
1302 # Boolean: does this Unicode version have the hangul syllables, and are we
1303 # writing out a table for them?
1304 my $has_hangul_syllables = 0;
1305
1306 # Does this Unicode version have code points whose names end in their
1307 # respective code points, and are we writing out a table for them?  0 for no;
1308 # otherwise points to first property that a table is needed for them, so that
1309 # if multiple tables are needed, we don't create duplicates
1310 my $needing_code_points_ending_in_code_point = 0;
1311
1312 my @backslash_X_tests;     # List of tests read in for testing \X
1313 my @unhandled_properties;  # Will contain a list of properties found in
1314                            # the input that we didn't process.
1315 my @match_properties;      # Properties that have match tables, to be
1316                            # listed in the pod
1317 my @map_properties;        # Properties that get map files written
1318 my @named_sequences;       # NamedSequences.txt contents.
1319 my %potential_files;       # Generated list of all .txt files in the directory
1320                            # structure so we can warn if something is being
1321                            # ignored.
1322 my @files_actually_output; # List of files we generated.
1323 my @more_Names;            # Some code point names are compound; this is used
1324                            # to store the extra components of them.
1325 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1326                            # the minimum before we consider it equivalent to a
1327                            # candidate rational
1328 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1329
1330 # These store references to certain commonly used property objects
1331 my $gc;
1332 my $perl;
1333 my $block;
1334 my $perl_charname;
1335 my $print;
1336 my $Any;
1337 my $script;
1338
1339 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1340 my $has_In_conflicts = 0;
1341 my $has_Is_conflicts = 0;
1342
1343 sub internal_file_to_platform ($) {
1344     # Convert our file paths which have '/' separators to those of the
1345     # platform.
1346
1347     my $file = shift;
1348     return undef unless defined $file;
1349
1350     return File::Spec->join(split '/', $file);
1351 }
1352
1353 sub file_exists ($) {   # platform independent '-e'.  This program internally
1354                         # uses slash as a path separator.
1355     my $file = shift;
1356     return 0 if ! defined $file;
1357     return -e internal_file_to_platform($file);
1358 }
1359
1360 sub objaddr($) {
1361     # Returns the address of the blessed input object.
1362     # It doesn't check for blessedness because that would do a string eval
1363     # every call, and the program is structured so that this is never called
1364     # for a non-blessed object.
1365
1366     no overloading; # If overloaded, numifying below won't work.
1367
1368     # Numifying a ref gives its address.
1369     return pack 'J', $_[0];
1370 }
1371
1372 # These are used only if $annotate is true.
1373 # The entire range of Unicode characters is examined to populate these
1374 # after all the input has been processed.  But most can be skipped, as they
1375 # have the same descriptive phrases, such as being unassigned
1376 my @viacode;            # Contains the 1 million character names
1377 my @printable;          # boolean: And are those characters printable?
1378 my @annotate_char_type; # Contains a type of those characters, specifically
1379                         # for the purposes of annotation.
1380 my $annotate_ranges;    # A map of ranges of code points that have the same
1381                         # name for the purposes of annotation.  They map to the
1382                         # upper edge of the range, so that the end point can
1383                         # be immediately found.  This is used to skip ahead to
1384                         # the end of a range, and avoid processing each
1385                         # individual code point in it.
1386 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1387                                    # characters, but excluding those which are
1388                                    # also noncharacter code points
1389
1390 # The annotation types are an extension of the regular range types, though
1391 # some of the latter are folded into one.  Make the new types negative to
1392 # avoid conflicting with the regular types
1393 my $SURROGATE_TYPE = -1;
1394 my $UNASSIGNED_TYPE = -2;
1395 my $PRIVATE_USE_TYPE = -3;
1396 my $NONCHARACTER_TYPE = -4;
1397 my $CONTROL_TYPE = -5;
1398 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1399
1400 sub populate_char_info ($) {
1401     # Used only with the $annotate option.  Populates the arrays with the
1402     # input code point's info that are needed for outputting more detailed
1403     # comments.  If calling context wants a return, it is the end point of
1404     # any contiguous range of characters that share essentially the same info
1405
1406     my $i = shift;
1407     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1408
1409     $viacode[$i] = $perl_charname->value_of($i) || "";
1410
1411     # A character is generally printable if Unicode says it is,
1412     # but below we make sure that most Unicode general category 'C' types
1413     # aren't.
1414     $printable[$i] = $print->contains($i);
1415
1416     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1417
1418     # Only these two regular types are treated specially for annotations
1419     # purposes
1420     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1421                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1422
1423     # Give a generic name to all code points that don't have a real name.
1424     # We output ranges, if applicable, for these.  Also calculate the end
1425     # point of the range.
1426     my $end;
1427     if (! $viacode[$i]) {
1428         if ($gc-> table('Surrogate')->contains($i)) {
1429             $viacode[$i] = 'Surrogate';
1430             $annotate_char_type[$i] = $SURROGATE_TYPE;
1431             $printable[$i] = 0;
1432             $end = $gc->table('Surrogate')->containing_range($i)->end;
1433         }
1434         elsif ($gc-> table('Private_use')->contains($i)) {
1435             $viacode[$i] = 'Private Use';
1436             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1437             $printable[$i] = 0;
1438             $end = $gc->table('Private_Use')->containing_range($i)->end;
1439         }
1440         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1441                                                                 contains($i))
1442         {
1443             $viacode[$i] = 'Noncharacter';
1444             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1445             $printable[$i] = 0;
1446             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1447                                                     containing_range($i)->end;
1448         }
1449         elsif ($gc-> table('Control')->contains($i)) {
1450             $viacode[$i] = 'Control';
1451             $annotate_char_type[$i] = $CONTROL_TYPE;
1452             $printable[$i] = 0;
1453             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1454         }
1455         elsif ($gc-> table('Unassigned')->contains($i)) {
1456             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1457             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1458             $printable[$i] = 0;
1459
1460             # Because we name the unassigned by the blocks they are in, it
1461             # can't go past the end of that block, and it also can't go past
1462             # the unassigned range it is in.  The special table makes sure
1463             # that the non-characters, which are unassigned, are separated
1464             # out.
1465             $end = min($block->containing_range($i)->end,
1466                        $unassigned_sans_noncharacters-> containing_range($i)->
1467                                                                          end);
1468         }
1469         else {
1470             Carp::my_carp_bug("Can't figure out how to annotate "
1471                               . sprintf("U+%04X", $i)
1472                               . ".  Proceeding anyway.");
1473             $viacode[$i] = 'UNKNOWN';
1474             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1475             $printable[$i] = 0;
1476         }
1477     }
1478
1479     # Here, has a name, but if it's one in which the code point number is
1480     # appended to the name, do that.
1481     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1482         $viacode[$i] .= sprintf("-%04X", $i);
1483         $end = $perl_charname->containing_range($i)->end;
1484     }
1485
1486     # And here, has a name, but if it's a hangul syllable one, replace it with
1487     # the correct name from the Unicode algorithm
1488     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1489         use integer;
1490         my $SIndex = $i - $SBase;
1491         my $L = $LBase + $SIndex / $NCount;
1492         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1493         my $T = $TBase + $SIndex % $TCount;
1494         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1495         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1496         $end = $perl_charname->containing_range($i)->end;
1497     }
1498
1499     return if ! defined wantarray;
1500     return $i if ! defined $end;    # If not a range, return the input
1501
1502     # Save this whole range so can find the end point quickly
1503     $annotate_ranges->add_map($i, $end, $end);
1504
1505     return $end;
1506 }
1507
1508 # Commented code below should work on Perl 5.8.
1509 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1510 ## the native perl version of it (which is what would operate under miniperl)
1511 ## is extremely slow, as it does a string eval every call.
1512 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1513 #                            && defined eval "require Scalar::Util";
1514 #
1515 #sub objaddr($) {
1516 #    # Returns the address of the blessed input object.  Uses the XS version if
1517 #    # available.  It doesn't check for blessedness because that would do a
1518 #    # string eval every call, and the program is structured so that this is
1519 #    # never called for a non-blessed object.
1520 #
1521 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1522 #
1523 #    # Check at least that is a ref.
1524 #    my $pkg = ref($_[0]) or return undef;
1525 #
1526 #    # Change to a fake package to defeat any overloaded stringify
1527 #    bless $_[0], 'main::Fake';
1528 #
1529 #    # Numifying a ref gives its address.
1530 #    my $addr = pack 'J', $_[0];
1531 #
1532 #    # Return to original class
1533 #    bless $_[0], $pkg;
1534 #    return $addr;
1535 #}
1536
1537 sub max ($$) {
1538     my $a = shift;
1539     my $b = shift;
1540     return $a if $a >= $b;
1541     return $b;
1542 }
1543
1544 sub min ($$) {
1545     my $a = shift;
1546     my $b = shift;
1547     return $a if $a <= $b;
1548     return $b;
1549 }
1550
1551 sub clarify_number ($) {
1552     # This returns the input number with underscores inserted every 3 digits
1553     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1554     # checked.
1555
1556     my $number = shift;
1557     my $pos = length($number) - 3;
1558     return $number if $pos <= 1;
1559     while ($pos > 0) {
1560         substr($number, $pos, 0) = '_';
1561         $pos -= 3;
1562     }
1563     return $number;
1564 }
1565
1566
1567 package Carp;
1568
1569 # These routines give a uniform treatment of messages in this program.  They
1570 # are placed in the Carp package to cause the stack trace to not include them,
1571 # although an alternative would be to use another package and set @CARP_NOT
1572 # for it.
1573
1574 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1575
1576 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1577 # and overload trying to load Scalar:Util under miniperl.  See
1578 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1579 undef $overload::VERSION;
1580
1581 sub my_carp {
1582     my $message = shift || "";
1583     my $nofold = shift || 0;
1584
1585     if ($message) {
1586         $message = main::join_lines($message);
1587         $message =~ s/^$0: *//;     # Remove initial program name
1588         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1589         $message = "\n$0: $message;";
1590
1591         # Fold the message with program name, semi-colon end punctuation
1592         # (which looks good with the message that carp appends to it), and a
1593         # hanging indent for continuation lines.
1594         $message = main::simple_fold($message, "", 4) unless $nofold;
1595         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1596                                     # appends is to the same line
1597     }
1598
1599     return $message if defined wantarray;   # If a caller just wants the msg
1600
1601     carp $message;
1602     return;
1603 }
1604
1605 sub my_carp_bug {
1606     # This is called when it is clear that the problem is caused by a bug in
1607     # this program.
1608
1609     my $message = shift;
1610     $message =~ s/^$0: *//;
1611     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1612     carp $message;
1613     return;
1614 }
1615
1616 sub carp_too_few_args {
1617     if (@_ != 2) {
1618         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1619         return;
1620     }
1621
1622     my $args_ref = shift;
1623     my $count = shift;
1624
1625     my_carp_bug("Need at least $count arguments to "
1626         . (caller 1)[3]
1627         . ".  Instead got: '"
1628         . join ', ', @$args_ref
1629         . "'.  No action taken.");
1630     return;
1631 }
1632
1633 sub carp_extra_args {
1634     my $args_ref = shift;
1635     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1636
1637     unless (ref $args_ref) {
1638         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1639         return;
1640     }
1641     my ($package, $file, $line) = caller;
1642     my $subroutine = (caller 1)[3];
1643
1644     my $list;
1645     if (ref $args_ref eq 'HASH') {
1646         foreach my $key (keys %$args_ref) {
1647             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1648         }
1649         $list = join ', ', each %{$args_ref};
1650     }
1651     elsif (ref $args_ref eq 'ARRAY') {
1652         foreach my $arg (@$args_ref) {
1653             $arg = $UNDEF unless defined $arg;
1654         }
1655         $list = join ', ', @$args_ref;
1656     }
1657     else {
1658         my_carp_bug("Can't cope with ref "
1659                 . ref($args_ref)
1660                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1661         return;
1662     }
1663
1664     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1665     return;
1666 }
1667
1668 package main;
1669
1670 { # Closure
1671
1672     # This program uses the inside-out method for objects, as recommended in
1673     # "Perl Best Practices".  This closure aids in generating those.  There
1674     # are two routines.  setup_package() is called once per package to set
1675     # things up, and then set_access() is called for each hash representing a
1676     # field in the object.  These routines arrange for the object to be
1677     # properly destroyed when no longer used, and for standard accessor
1678     # functions to be generated.  If you need more complex accessors, just
1679     # write your own and leave those accesses out of the call to set_access().
1680     # More details below.
1681
1682     my %constructor_fields; # fields that are to be used in constructors; see
1683                             # below
1684
1685     # The values of this hash will be the package names as keys to other
1686     # hashes containing the name of each field in the package as keys, and
1687     # references to their respective hashes as values.
1688     my %package_fields;
1689
1690     sub setup_package {
1691         # Sets up the package, creating standard DESTROY and dump methods
1692         # (unless already defined).  The dump method is used in debugging by
1693         # simple_dumper().
1694         # The optional parameters are:
1695         #   a)  a reference to a hash, that gets populated by later
1696         #       set_access() calls with one of the accesses being
1697         #       'constructor'.  The caller can then refer to this, but it is
1698         #       not otherwise used by these two routines.
1699         #   b)  a reference to a callback routine to call during destruction
1700         #       of the object, before any fields are actually destroyed
1701
1702         my %args = @_;
1703         my $constructor_ref = delete $args{'Constructor_Fields'};
1704         my $destroy_callback = delete $args{'Destroy_Callback'};
1705         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1706
1707         my %fields;
1708         my $package = (caller)[0];
1709
1710         $package_fields{$package} = \%fields;
1711         $constructor_fields{$package} = $constructor_ref;
1712
1713         unless ($package->can('DESTROY')) {
1714             my $destroy_name = "${package}::DESTROY";
1715             no strict "refs";
1716
1717             # Use typeglob to give the anonymous subroutine the name we want
1718             *$destroy_name = sub {
1719                 my $self = shift;
1720                 my $addr = do { no overloading; pack 'J', $self; };
1721
1722                 $self->$destroy_callback if $destroy_callback;
1723                 foreach my $field (keys %{$package_fields{$package}}) {
1724                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1725                     delete $package_fields{$package}{$field}{$addr};
1726                 }
1727                 return;
1728             }
1729         }
1730
1731         unless ($package->can('dump')) {
1732             my $dump_name = "${package}::dump";
1733             no strict "refs";
1734             *$dump_name = sub {
1735                 my $self = shift;
1736                 return dump_inside_out($self, $package_fields{$package}, @_);
1737             }
1738         }
1739         return;
1740     }
1741
1742     sub set_access {
1743         # Arrange for the input field to be garbage collected when no longer
1744         # needed.  Also, creates standard accessor functions for the field
1745         # based on the optional parameters-- none if none of these parameters:
1746         #   'addable'    creates an 'add_NAME()' accessor function.
1747         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1748         #                function.
1749         #   'settable'   creates a 'set_NAME()' accessor function.
1750         #   'constructor' doesn't create an accessor function, but adds the
1751         #                field to the hash that was previously passed to
1752         #                setup_package();
1753         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1754         # 'add' etc. all mean 'addable'.
1755         # The read accessor function will work on both array and scalar
1756         # values.  If another accessor in the parameter list is 'a', the read
1757         # access assumes an array.  You can also force it to be array access
1758         # by specifying 'readable_array' instead of 'readable'
1759         #
1760         # A sort-of 'protected' access can be set-up by preceding the addable,
1761         # readable or settable with some initial portion of 'protected_' (but,
1762         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1763         # "protection" is only by convention.  All that happens is that the
1764         # accessor functions' names begin with an underscore.  So instead of
1765         # calling set_foo, the call is _set_foo.  (Real protection could be
1766         # accomplished by having a new subroutine, end_package, called at the
1767         # end of each package, and then storing the __LINE__ ranges and
1768         # checking them on every accessor.  But that is way overkill.)
1769
1770         # We create anonymous subroutines as the accessors and then use
1771         # typeglobs to assign them to the proper package and name
1772
1773         my $name = shift;   # Name of the field
1774         my $field = shift;  # Reference to the inside-out hash containing the
1775                             # field
1776
1777         my $package = (caller)[0];
1778
1779         if (! exists $package_fields{$package}) {
1780             croak "$0: Must call 'setup_package' before 'set_access'";
1781         }
1782
1783         # Stash the field so DESTROY can get it.
1784         $package_fields{$package}{$name} = $field;
1785
1786         # Remaining arguments are the accessors.  For each...
1787         foreach my $access (@_) {
1788             my $access = lc $access;
1789
1790             my $protected = "";
1791
1792             # Match the input as far as it goes.
1793             if ($access =~ /^(p[^_]*)_/) {
1794                 $protected = $1;
1795                 if (substr('protected_', 0, length $protected)
1796                     eq $protected)
1797                 {
1798
1799                     # Add 1 for the underscore not included in $protected
1800                     $access = substr($access, length($protected) + 1);
1801                     $protected = '_';
1802                 }
1803                 else {
1804                     $protected = "";
1805                 }
1806             }
1807
1808             if (substr('addable', 0, length $access) eq $access) {
1809                 my $subname = "${package}::${protected}add_$name";
1810                 no strict "refs";
1811
1812                 # add_ accessor.  Don't add if already there, which we
1813                 # determine using 'eq' for scalars and '==' otherwise.
1814                 *$subname = sub {
1815                     use strict "refs";
1816                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1817                     my $self = shift;
1818                     my $value = shift;
1819                     my $addr = do { no overloading; pack 'J', $self; };
1820                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1821                     if (ref $value) {
1822                         return if grep { $value == $_ } @{$field->{$addr}};
1823                     }
1824                     else {
1825                         return if grep { $value eq $_ } @{$field->{$addr}};
1826                     }
1827                     push @{$field->{$addr}}, $value;
1828                     return;
1829                 }
1830             }
1831             elsif (substr('constructor', 0, length $access) eq $access) {
1832                 if ($protected) {
1833                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1834                 }
1835                 else {
1836                     $constructor_fields{$package}{$name} = $field;
1837                 }
1838             }
1839             elsif (substr('readable_array', 0, length $access) eq $access) {
1840
1841                 # Here has read access.  If one of the other parameters for
1842                 # access is array, or this one specifies array (by being more
1843                 # than just 'readable_'), then create a subroutine that
1844                 # assumes the data is an array.  Otherwise just a scalar
1845                 my $subname = "${package}::${protected}$name";
1846                 if (grep { /^a/i } @_
1847                     or length($access) > length('readable_'))
1848                 {
1849                     no strict "refs";
1850                     *$subname = sub {
1851                         use strict "refs";
1852                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1853                         my $addr = do { no overloading; pack 'J', $_[0]; };
1854                         if (ref $field->{$addr} ne 'ARRAY') {
1855                             my $type = ref $field->{$addr};
1856                             $type = 'scalar' unless $type;
1857                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1858                             return;
1859                         }
1860                         return scalar @{$field->{$addr}} unless wantarray;
1861
1862                         # Make a copy; had problems with caller modifying the
1863                         # original otherwise
1864                         my @return = @{$field->{$addr}};
1865                         return @return;
1866                     }
1867                 }
1868                 else {
1869
1870                     # Here not an array value, a simpler function.
1871                     no strict "refs";
1872                     *$subname = sub {
1873                         use strict "refs";
1874                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1875                         no overloading;
1876                         return $field->{pack 'J', $_[0]};
1877                     }
1878                 }
1879             }
1880             elsif (substr('settable', 0, length $access) eq $access) {
1881                 my $subname = "${package}::${protected}set_$name";
1882                 no strict "refs";
1883                 *$subname = sub {
1884                     use strict "refs";
1885                     if (main::DEBUG) {
1886                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1887                         Carp::carp_extra_args(\@_) if @_ > 2;
1888                     }
1889                     # $self is $_[0]; $value is $_[1]
1890                     no overloading;
1891                     $field->{pack 'J', $_[0]} = $_[1];
1892                     return;
1893                 }
1894             }
1895             else {
1896                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1897             }
1898         }
1899         return;
1900     }
1901 }
1902
1903 package Input_file;
1904
1905 # All input files use this object, which stores various attributes about them,
1906 # and provides for convenient, uniform handling.  The run method wraps the
1907 # processing.  It handles all the bookkeeping of opening, reading, and closing
1908 # the file, returning only significant input lines.
1909 #
1910 # Each object gets a handler which processes the body of the file, and is
1911 # called by run().  Most should use the generic, default handler, which has
1912 # code scrubbed to handle things you might not expect.  A handler should
1913 # basically be a while(next_line()) {...} loop.
1914 #
1915 # You can also set up handlers to
1916 #   1) call before the first line is read for pre processing
1917 #   2) call to adjust each line of the input before the main handler gets them
1918 #   3) call upon EOF before the main handler exits its loop
1919 #   4) call at the end for post processing
1920 #
1921 # $_ is used to store the input line, and is to be filtered by the
1922 # each_line_handler()s.  So, if the format of the line is not in the desired
1923 # format for the main handler, these are used to do that adjusting.  They can
1924 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1925 # so the $_ output of one is used as the input to the next.  None of the other
1926 # handlers are stackable, but could easily be changed to be so.
1927 #
1928 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1929 # which insert the parameters as lines to be processed before the next input
1930 # file line is read.  This allows the EOF handler to flush buffers, for
1931 # example.  The difference between the two routines is that the lines inserted
1932 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1933 # called it from such a handler, you would get infinite recursion.)  Lines
1934 # inserted by insert_adjusted_lines() go directly to the main handler without
1935 # any adjustments.  If the  post-processing handler calls any of these, there
1936 # will be no effect.  Some error checking for these conditions could be added,
1937 # but it hasn't been done.
1938 #
1939 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1940 # to prevent further processing of the line.  This routine will output the
1941 # message as a warning once, and then keep a count of the lines that have the
1942 # same message, and output that count at the end of the file's processing.
1943 # This keeps the number of messages down to a manageable amount.
1944 #
1945 # get_missings() should be called to retrieve any @missing input lines.
1946 # Messages will be raised if this isn't done if the options aren't to ignore
1947 # missings.
1948
1949 sub trace { return main::trace(@_); }
1950
1951 { # Closure
1952     # Keep track of fields that are to be put into the constructor.
1953     my %constructor_fields;
1954
1955     main::setup_package(Constructor_Fields => \%constructor_fields);
1956
1957     my %file; # Input file name, required
1958     main::set_access('file', \%file, qw{ c r });
1959
1960     my %first_released; # Unicode version file was first released in, required
1961     main::set_access('first_released', \%first_released, qw{ c r });
1962
1963     my %handler;    # Subroutine to process the input file, defaults to
1964                     # 'process_generic_property_file'
1965     main::set_access('handler', \%handler, qw{ c });
1966
1967     my %property;
1968     # name of property this file is for.  defaults to none, meaning not
1969     # applicable, or is otherwise determinable, for example, from each line.
1970     main::set_access('property', \%property, qw{ c });
1971
1972     my %optional;
1973     # If this is true, the file is optional.  If not present, no warning is
1974     # output.  If it is present, the string given by this parameter is
1975     # evaluated, and if false the file is not processed.
1976     main::set_access('optional', \%optional, 'c', 'r');
1977
1978     my %non_skip;
1979     # This is used for debugging, to skip processing of all but a few input
1980     # files.  Add 'non_skip => 1' to the constructor for those files you want
1981     # processed when you set the $debug_skip global.
1982     main::set_access('non_skip', \%non_skip, 'c');
1983
1984     my %skip;
1985     # This is used to skip processing of this input file semi-permanently,
1986     # when it evaluates to true.  The value should be the reason the file is
1987     # being skipped.  It is used for files that we aren't planning to process
1988     # anytime soon, but want to allow to be in the directory and not raise a
1989     # message that we are not handling.  Mostly for test files.  This is in
1990     # contrast to the non_skip element, which is supposed to be used very
1991     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
1992     # pretty much will never look at can be placed in the global
1993     # %ignored_files instead.  Ones used here will be added to that list.
1994     main::set_access('skip', \%skip, 'c');
1995
1996     my %each_line_handler;
1997     # list of subroutines to look at and filter each non-comment line in the
1998     # file.  defaults to none.  The subroutines are called in order, each is
1999     # to adjust $_ for the next one, and the final one adjusts it for
2000     # 'handler'
2001     main::set_access('each_line_handler', \%each_line_handler, 'c');
2002
2003     my %has_missings_defaults;
2004     # ? Are there lines in the file giving default values for code points
2005     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2006     # the norm, but IGNORED means it has such lines, but the handler doesn't
2007     # use them.  Having these three states allows us to catch changes to the
2008     # UCD that this program should track
2009     main::set_access('has_missings_defaults',
2010                                         \%has_missings_defaults, qw{ c r });
2011
2012     my %pre_handler;
2013     # Subroutine to call before doing anything else in the file.  If undef, no
2014     # such handler is called.
2015     main::set_access('pre_handler', \%pre_handler, qw{ c });
2016
2017     my %eof_handler;
2018     # Subroutine to call upon getting an EOF on the input file, but before
2019     # that is returned to the main handler.  This is to allow buffers to be
2020     # flushed.  The handler is expected to call insert_lines() or
2021     # insert_adjusted() with the buffered material
2022     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2023
2024     my %post_handler;
2025     # Subroutine to call after all the lines of the file are read in and
2026     # processed.  If undef, no such handler is called.
2027     main::set_access('post_handler', \%post_handler, qw{ c });
2028
2029     my %progress_message;
2030     # Message to print to display progress in lieu of the standard one
2031     main::set_access('progress_message', \%progress_message, qw{ c });
2032
2033     my %handle;
2034     # cache open file handle, internal.  Is undef if file hasn't been
2035     # processed at all, empty if has;
2036     main::set_access('handle', \%handle);
2037
2038     my %added_lines;
2039     # cache of lines added virtually to the file, internal
2040     main::set_access('added_lines', \%added_lines);
2041
2042     my %errors;
2043     # cache of errors found, internal
2044     main::set_access('errors', \%errors);
2045
2046     my %missings;
2047     # storage of '@missing' defaults lines
2048     main::set_access('missings', \%missings);
2049
2050     sub new {
2051         my $class = shift;
2052
2053         my $self = bless \do{ my $anonymous_scalar }, $class;
2054         my $addr = do { no overloading; pack 'J', $self; };
2055
2056         # Set defaults
2057         $handler{$addr} = \&main::process_generic_property_file;
2058         $non_skip{$addr} = 0;
2059         $skip{$addr} = 0;
2060         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2061         $handle{$addr} = undef;
2062         $added_lines{$addr} = [ ];
2063         $each_line_handler{$addr} = [ ];
2064         $errors{$addr} = { };
2065         $missings{$addr} = [ ];
2066
2067         # Two positional parameters.
2068         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2069         $file{$addr} = main::internal_file_to_platform(shift);
2070         $first_released{$addr} = shift;
2071
2072         # The rest of the arguments are key => value pairs
2073         # %constructor_fields has been set up earlier to list all possible
2074         # ones.  Either set or push, depending on how the default has been set
2075         # up just above.
2076         my %args = @_;
2077         foreach my $key (keys %args) {
2078             my $argument = $args{$key};
2079
2080             # Note that the fields are the lower case of the constructor keys
2081             my $hash = $constructor_fields{lc $key};
2082             if (! defined $hash) {
2083                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2084                 next;
2085             }
2086             if (ref $hash->{$addr} eq 'ARRAY') {
2087                 if (ref $argument eq 'ARRAY') {
2088                     foreach my $argument (@{$argument}) {
2089                         next if ! defined $argument;
2090                         push @{$hash->{$addr}}, $argument;
2091                     }
2092                 }
2093                 else {
2094                     push @{$hash->{$addr}}, $argument if defined $argument;
2095                 }
2096             }
2097             else {
2098                 $hash->{$addr} = $argument;
2099             }
2100             delete $args{$key};
2101         };
2102
2103         # If the file has a property for it, it means that the property is not
2104         # listed in the file's entries.  So add a handler to the list of line
2105         # handlers to insert the property name into the lines, to provide a
2106         # uniform interface to the final processing subroutine.
2107         # the final code doesn't have to worry about that.
2108         if ($property{$addr}) {
2109             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2110         }
2111
2112         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2113             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2114         }
2115
2116         # If skipping, set to optional, and add to list of ignored files,
2117         # including its reason
2118         if ($skip{$addr}) {
2119             $optional{$addr} = 1;
2120             $ignored_files{$file{$addr}} = $skip{$addr}
2121         }
2122
2123         return $self;
2124     }
2125
2126
2127     use overload
2128         fallback => 0,
2129         qw("") => "_operator_stringify",
2130         "." => \&main::_operator_dot,
2131     ;
2132
2133     sub _operator_stringify {
2134         my $self = shift;
2135
2136         return __PACKAGE__ . " object for " . $self->file;
2137     }
2138
2139     # flag to make sure extracted files are processed early
2140     my $seen_non_extracted_non_age = 0;
2141
2142     sub run {
2143         # Process the input object $self.  This opens and closes the file and
2144         # calls all the handlers for it.  Currently,  this can only be called
2145         # once per file, as it destroy's the EOF handler
2146
2147         my $self = shift;
2148         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2149
2150         my $addr = do { no overloading; pack 'J', $self; };
2151
2152         my $file = $file{$addr};
2153
2154         # Don't process if not expecting this file (because released later
2155         # than this Unicode version), and isn't there.  This means if someone
2156         # copies it into an earlier version's directory, we will go ahead and
2157         # process it.
2158         return if $first_released{$addr} gt $v_version && ! -e $file;
2159
2160         # If in debugging mode and this file doesn't have the non-skip
2161         # flag set, and isn't one of the critical files, skip it.
2162         if ($debug_skip
2163             && $first_released{$addr} ne v0
2164             && ! $non_skip{$addr})
2165         {
2166             print "Skipping $file in debugging\n" if $verbosity;
2167             return;
2168         }
2169
2170         # File could be optional
2171         if ($optional{$addr}) {
2172             return unless -e $file;
2173             my $result = eval $optional{$addr};
2174             if (! defined $result) {
2175                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2176                 return;
2177             }
2178             if (! $result) {
2179                 if ($verbosity) {
2180                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2181                 }
2182                 return;
2183             }
2184         }
2185
2186         if (! defined $file || ! -e $file) {
2187
2188             # If the file doesn't exist, see if have internal data for it
2189             # (based on first_released being 0).
2190             if ($first_released{$addr} eq v0) {
2191                 $handle{$addr} = 'pretend_is_open';
2192             }
2193             else {
2194                 if (! $optional{$addr}  # File could be optional
2195                     && $v_version ge $first_released{$addr})
2196                 {
2197                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2198                 }
2199                 return;
2200             }
2201         }
2202         else {
2203
2204             # Here, the file exists.  Some platforms may change the case of
2205             # its name
2206             if ($seen_non_extracted_non_age) {
2207                 if ($file =~ /$EXTRACTED/i) {
2208                     Carp::my_carp_bug(join_lines(<<END
2209 $file should be processed just after the 'Prop...Alias' files, and before
2210 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2211 have subtle problems
2212 END
2213                     ));
2214                 }
2215             }
2216             elsif ($EXTRACTED_DIR
2217                     && $first_released{$addr} ne v0
2218                     && $file !~ /$EXTRACTED/i
2219                     && lc($file) ne 'dage.txt')
2220             {
2221                 # We don't set this (by the 'if' above) if we have no
2222                 # extracted directory, so if running on an early version,
2223                 # this test won't work.  Not worth worrying about.
2224                 $seen_non_extracted_non_age = 1;
2225             }
2226
2227             # And mark the file as having being processed, and warn if it
2228             # isn't a file we are expecting.  As we process the files,
2229             # they are deleted from the hash, so any that remain at the
2230             # end of the program are files that we didn't process.
2231             my $fkey = File::Spec->rel2abs($file);
2232             my $expecting = delete $potential_files{$fkey};
2233             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
2234             Carp::my_carp("Was not expecting '$file'.") if
2235                     ! $expecting
2236                     && ! defined $handle{$addr};
2237
2238             # Having deleted from expected files, we can quit if not to do
2239             # anything.  Don't print progress unless really want verbosity
2240             if ($skip{$addr}) {
2241                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2242                 return;
2243             }
2244
2245             # Open the file, converting the slashes used in this program
2246             # into the proper form for the OS
2247             my $file_handle;
2248             if (not open $file_handle, "<", $file) {
2249                 Carp::my_carp("Can't open $file.  Skipping: $!");
2250                 return 0;
2251             }
2252             $handle{$addr} = $file_handle; # Cache the open file handle
2253         }
2254
2255         if ($verbosity >= $PROGRESS) {
2256             if ($progress_message{$addr}) {
2257                 print "$progress_message{$addr}\n";
2258             }
2259             else {
2260                 # If using a virtual file, say so.
2261                 print "Processing ", (-e $file)
2262                                        ? $file
2263                                        : "substitute $file",
2264                                      "\n";
2265             }
2266         }
2267
2268
2269         # Call any special handler for before the file.
2270         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2271
2272         # Then the main handler
2273         &{$handler{$addr}}($self);
2274
2275         # Then any special post-file handler.
2276         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2277
2278         # If any errors have been accumulated, output the counts (as the first
2279         # error message in each class was output when it was encountered).
2280         if ($errors{$addr}) {
2281             my $total = 0;
2282             my $types = 0;
2283             foreach my $error (keys %{$errors{$addr}}) {
2284                 $total += $errors{$addr}->{$error};
2285                 delete $errors{$addr}->{$error};
2286                 $types++;
2287             }
2288             if ($total > 1) {
2289                 my $message
2290                         = "A total of $total lines had errors in $file.  ";
2291
2292                 $message .= ($types == 1)
2293                             ? '(Only the first one was displayed.)'
2294                             : '(Only the first of each type was displayed.)';
2295                 Carp::my_carp($message);
2296             }
2297         }
2298
2299         if (@{$missings{$addr}}) {
2300             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2301         }
2302
2303         # If a real file handle, close it.
2304         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2305                                                         ref $handle{$addr};
2306         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2307                                # the file, as opposed to undef
2308         return;
2309     }
2310
2311     sub next_line {
2312         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2313         # if such a line exists.  'logical' means that any lines that have
2314         # been added via insert_lines() will be returned in $_ before the file
2315         # is read again.
2316
2317         my $self = shift;
2318         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2319
2320         my $addr = do { no overloading; pack 'J', $self; };
2321
2322         # Here the file is open (or if the handle is not a ref, is an open
2323         # 'virtual' file).  Get the next line; any inserted lines get priority
2324         # over the file itself.
2325         my $adjusted;
2326
2327         LINE:
2328         while (1) { # Loop until find non-comment, non-empty line
2329             #local $to_trace = 1 if main::DEBUG;
2330             my $inserted_ref = shift @{$added_lines{$addr}};
2331             if (defined $inserted_ref) {
2332                 ($adjusted, $_) = @{$inserted_ref};
2333                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2334                 return 1 if $adjusted;
2335             }
2336             else {
2337                 last if ! ref $handle{$addr}; # Don't read unless is real file
2338                 last if ! defined ($_ = readline $handle{$addr});
2339             }
2340             chomp;
2341             trace $_ if main::DEBUG && $to_trace;
2342
2343             # See if this line is the comment line that defines what property
2344             # value that code points that are not listed in the file should
2345             # have.  The format or existence of these lines is not guaranteed
2346             # by Unicode since they are comments, but the documentation says
2347             # that this was added for machine-readability, so probably won't
2348             # change.  This works starting in Unicode Version 5.0.  They look
2349             # like:
2350             #
2351             # @missing: 0000..10FFFF; Not_Reordered
2352             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2353             # @missing: 0000..10FFFF; ; NaN
2354             #
2355             # Save the line for a later get_missings() call.
2356             if (/$missing_defaults_prefix/) {
2357                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2358                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2359                 }
2360                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2361                     my @defaults = split /\s* ; \s*/x, $_;
2362
2363                     # The first field is the @missing, which ends in a
2364                     # semi-colon, so can safely shift.
2365                     shift @defaults;
2366
2367                     # Some of these lines may have empty field placeholders
2368                     # which get in the way.  An example is:
2369                     # @missing: 0000..10FFFF; ; NaN
2370                     # Remove them.  Process starting from the top so the
2371                     # splice doesn't affect things still to be looked at.
2372                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2373                         next if $defaults[$i] ne "";
2374                         splice @defaults, $i, 1;
2375                     }
2376
2377                     # What's left should be just the property (maybe) and the
2378                     # default.  Having only one element means it doesn't have
2379                     # the property.
2380                     my $default;
2381                     my $property;
2382                     if (@defaults >= 1) {
2383                         if (@defaults == 1) {
2384                             $default = $defaults[0];
2385                         }
2386                         else {
2387                             $property = $defaults[0];
2388                             $default = $defaults[1];
2389                         }
2390                     }
2391
2392                     if (@defaults < 1
2393                         || @defaults > 2
2394                         || ($default =~ /^</
2395                             && $default !~ /^<code *point>$/i
2396                             && $default !~ /^<none>$/i))
2397                     {
2398                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2399                     }
2400                     else {
2401
2402                         # If the property is missing from the line, it should
2403                         # be the one for the whole file
2404                         $property = $property{$addr} if ! defined $property;
2405
2406                         # Change <none> to the null string, which is what it
2407                         # really means.  If the default is the code point
2408                         # itself, set it to <code point>, which is what
2409                         # Unicode uses (but sometimes they've forgotten the
2410                         # space)
2411                         if ($default =~ /^<none>$/i) {
2412                             $default = "";
2413                         }
2414                         elsif ($default =~ /^<code *point>$/i) {
2415                             $default = $CODE_POINT;
2416                         }
2417
2418                         # Store them as a sub-arrays with both components.
2419                         push @{$missings{$addr}}, [ $default, $property ];
2420                     }
2421                 }
2422
2423                 # There is nothing for the caller to process on this comment
2424                 # line.
2425                 next;
2426             }
2427
2428             # Remove comments and trailing space, and skip this line if the
2429             # result is empty
2430             s/#.*//;
2431             s/\s+$//;
2432             next if /^$/;
2433
2434             # Call any handlers for this line, and skip further processing of
2435             # the line if the handler sets the line to null.
2436             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2437                 &{$sub_ref}($self);
2438                 next LINE if /^$/;
2439             }
2440
2441             # Here the line is ok.  return success.
2442             return 1;
2443         } # End of looping through lines.
2444
2445         # If there is an EOF handler, call it (only once) and if it generates
2446         # more lines to process go back in the loop to handle them.
2447         if ($eof_handler{$addr}) {
2448             &{$eof_handler{$addr}}($self);
2449             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2450             goto LINE if $added_lines{$addr};
2451         }
2452
2453         # Return failure -- no more lines.
2454         return 0;
2455
2456     }
2457
2458 #   Not currently used, not fully tested.
2459 #    sub peek {
2460 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2461 #        # record.  Not callable from an each_line_handler(), nor does it call
2462 #        # an each_line_handler() on the line.
2463 #
2464 #        my $self = shift;
2465 #        my $addr = do { no overloading; pack 'J', $self; };
2466 #
2467 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2468 #            my ($adjusted, $line) = @{$inserted_ref};
2469 #            next if $adjusted;
2470 #
2471 #            # Remove comments and trailing space, and return a non-empty
2472 #            # resulting line
2473 #            $line =~ s/#.*//;
2474 #            $line =~ s/\s+$//;
2475 #            return $line if $line ne "";
2476 #        }
2477 #
2478 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2479 #        while (1) { # Loop until find non-comment, non-empty line
2480 #            local $to_trace = 1 if main::DEBUG;
2481 #            trace $_ if main::DEBUG && $to_trace;
2482 #            return if ! defined (my $line = readline $handle{$addr});
2483 #            chomp $line;
2484 #            push @{$added_lines{$addr}}, [ 0, $line ];
2485 #
2486 #            $line =~ s/#.*//;
2487 #            $line =~ s/\s+$//;
2488 #            return $line if $line ne "";
2489 #        }
2490 #
2491 #        return;
2492 #    }
2493
2494
2495     sub insert_lines {
2496         # Lines can be inserted so that it looks like they were in the input
2497         # file at the place it was when this routine is called.  See also
2498         # insert_adjusted_lines().  Lines inserted via this routine go through
2499         # any each_line_handler()
2500
2501         my $self = shift;
2502
2503         # Each inserted line is an array, with the first element being 0 to
2504         # indicate that this line hasn't been adjusted, and needs to be
2505         # processed.
2506         no overloading;
2507         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2508         return;
2509     }
2510
2511     sub insert_adjusted_lines {
2512         # Lines can be inserted so that it looks like they were in the input
2513         # file at the place it was when this routine is called.  See also
2514         # insert_lines().  Lines inserted via this routine are already fully
2515         # adjusted, ready to be processed; each_line_handler()s handlers will
2516         # not be called.  This means this is not a completely general
2517         # facility, as only the last each_line_handler on the stack should
2518         # call this.  It could be made more general, by passing to each of the
2519         # line_handlers their position on the stack, which they would pass on
2520         # to this routine, and that would replace the boolean first element in
2521         # the anonymous array pushed here, so that the next_line routine could
2522         # use that to call only those handlers whose index is after it on the
2523         # stack.  But this is overkill for what is needed now.
2524
2525         my $self = shift;
2526         trace $_[0] if main::DEBUG && $to_trace;
2527
2528         # Each inserted line is an array, with the first element being 1 to
2529         # indicate that this line has been adjusted
2530         no overloading;
2531         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2532         return;
2533     }
2534
2535     sub get_missings {
2536         # Returns the stored up @missings lines' values, and clears the list.
2537         # The values are in an array, consisting of the default in the first
2538         # element, and the property in the 2nd.  However, since these lines
2539         # can be stacked up, the return is an array of all these arrays.
2540
2541         my $self = shift;
2542         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2543
2544         my $addr = do { no overloading; pack 'J', $self; };
2545
2546         # If not accepting a list return, just return the first one.
2547         return shift @{$missings{$addr}} unless wantarray;
2548
2549         my @return = @{$missings{$addr}};
2550         undef @{$missings{$addr}};
2551         return @return;
2552     }
2553
2554     sub _insert_property_into_line {
2555         # Add a property field to $_, if this file requires it.
2556
2557         my $self = shift;
2558         my $addr = do { no overloading; pack 'J', $self; };
2559         my $property = $property{$addr};
2560         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2561
2562         $_ =~ s/(;|$)/; $property$1/;
2563         return;
2564     }
2565
2566     sub carp_bad_line {
2567         # Output consistent error messages, using either a generic one, or the
2568         # one given by the optional parameter.  To avoid gazillions of the
2569         # same message in case the syntax of a  file is way off, this routine
2570         # only outputs the first instance of each message, incrementing a
2571         # count so the totals can be output at the end of the file.
2572
2573         my $self = shift;
2574         my $message = shift;
2575         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2576
2577         my $addr = do { no overloading; pack 'J', $self; };
2578
2579         $message = 'Unexpected line' unless $message;
2580
2581         # No trailing punctuation so as to fit with our addenda.
2582         $message =~ s/[.:;,]$//;
2583
2584         # If haven't seen this exact message before, output it now.  Otherwise
2585         # increment the count of how many times it has occurred
2586         unless ($errors{$addr}->{$message}) {
2587             Carp::my_carp("$message in '$_' in "
2588                             . $file{$addr}
2589                             . " at line $..  Skipping this line;");
2590             $errors{$addr}->{$message} = 1;
2591         }
2592         else {
2593             $errors{$addr}->{$message}++;
2594         }
2595
2596         # Clear the line to prevent any further (meaningful) processing of it.
2597         $_ = "";
2598
2599         return;
2600     }
2601 } # End closure
2602
2603 package Multi_Default;
2604
2605 # Certain properties in early versions of Unicode had more than one possible
2606 # default for code points missing from the files.  In these cases, one
2607 # default applies to everything left over after all the others are applied,
2608 # and for each of the others, there is a description of which class of code
2609 # points applies to it.  This object helps implement this by storing the
2610 # defaults, and for all but that final default, an eval string that generates
2611 # the class that it applies to.
2612
2613
2614 {   # Closure
2615
2616     main::setup_package();
2617
2618     my %class_defaults;
2619     # The defaults structure for the classes
2620     main::set_access('class_defaults', \%class_defaults);
2621
2622     my %other_default;
2623     # The default that applies to everything left over.
2624     main::set_access('other_default', \%other_default, 'r');
2625
2626
2627     sub new {
2628         # The constructor is called with default => eval pairs, terminated by
2629         # the left-over default. e.g.
2630         # Multi_Default->new(
2631         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2632         #               -  0x200D',
2633         #        'R' => 'some other expression that evaluates to code points',
2634         #        .
2635         #        .
2636         #        .
2637         #        'U'));
2638
2639         my $class = shift;
2640
2641         my $self = bless \do{my $anonymous_scalar}, $class;
2642         my $addr = do { no overloading; pack 'J', $self; };
2643
2644         while (@_ > 1) {
2645             my $default = shift;
2646             my $eval = shift;
2647             $class_defaults{$addr}->{$default} = $eval;
2648         }
2649
2650         $other_default{$addr} = shift;
2651
2652         return $self;
2653     }
2654
2655     sub get_next_defaults {
2656         # Iterates and returns the next class of defaults.
2657         my $self = shift;
2658         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2659
2660         my $addr = do { no overloading; pack 'J', $self; };
2661
2662         return each %{$class_defaults{$addr}};
2663     }
2664 }
2665
2666 package Alias;
2667
2668 # An alias is one of the names that a table goes by.  This class defines them
2669 # including some attributes.  Everything is currently setup in the
2670 # constructor.
2671
2672
2673 {   # Closure
2674
2675     main::setup_package();
2676
2677     my %name;
2678     main::set_access('name', \%name, 'r');
2679
2680     my %loose_match;
2681     # Should this name match loosely or not.
2682     main::set_access('loose_match', \%loose_match, 'r');
2683
2684     my %make_re_pod_entry;
2685     # Some aliases should not get their own entries in the re section of the
2686     # pod, because they are covered by a wild-card, and some we want to
2687     # discourage use of.  Binary
2688     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
2689
2690     my %status;
2691     # Aliases have a status, like deprecated, or even suppressed (which means
2692     # they don't appear in documentation).  Enum
2693     main::set_access('status', \%status, 'r');
2694
2695     my %externally_ok;
2696     # Similarly, some aliases should not be considered as usable ones for
2697     # external use, such as file names, or we don't want documentation to
2698     # recommend them.  Boolean
2699     main::set_access('externally_ok', \%externally_ok, 'r');
2700
2701     sub new {
2702         my $class = shift;
2703
2704         my $self = bless \do { my $anonymous_scalar }, $class;
2705         my $addr = do { no overloading; pack 'J', $self; };
2706
2707         $name{$addr} = shift;
2708         $loose_match{$addr} = shift;
2709         $make_re_pod_entry{$addr} = shift;
2710         $externally_ok{$addr} = shift;
2711         $status{$addr} = shift;
2712
2713         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2714
2715         # Null names are never ok externally
2716         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2717
2718         return $self;
2719     }
2720 }
2721
2722 package Range;
2723
2724 # A range is the basic unit for storing code points, and is described in the
2725 # comments at the beginning of the program.  Each range has a starting code
2726 # point; an ending code point (not less than the starting one); a value
2727 # that applies to every code point in between the two end-points, inclusive;
2728 # and an enum type that applies to the value.  The type is for the user's
2729 # convenience, and has no meaning here, except that a non-zero type is
2730 # considered to not obey the normal Unicode rules for having standard forms.
2731 #
2732 # The same structure is used for both map and match tables, even though in the
2733 # latter, the value (and hence type) is irrelevant and could be used as a
2734 # comment.  In map tables, the value is what all the code points in the range
2735 # map to.  Type 0 values have the standardized version of the value stored as
2736 # well, so as to not have to recalculate it a lot.
2737
2738 sub trace { return main::trace(@_); }
2739
2740 {   # Closure
2741
2742     main::setup_package();
2743
2744     my %start;
2745     main::set_access('start', \%start, 'r', 's');
2746
2747     my %end;
2748     main::set_access('end', \%end, 'r', 's');
2749
2750     my %value;
2751     main::set_access('value', \%value, 'r');
2752
2753     my %type;
2754     main::set_access('type', \%type, 'r');
2755
2756     my %standard_form;
2757     # The value in internal standard form.  Defined only if the type is 0.
2758     main::set_access('standard_form', \%standard_form);
2759
2760     # Note that if these fields change, the dump() method should as well
2761
2762     sub new {
2763         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2764         my $class = shift;
2765
2766         my $self = bless \do { my $anonymous_scalar }, $class;
2767         my $addr = do { no overloading; pack 'J', $self; };
2768
2769         $start{$addr} = shift;
2770         $end{$addr} = shift;
2771
2772         my %args = @_;
2773
2774         my $value = delete $args{'Value'};  # Can be 0
2775         $value = "" unless defined $value;
2776         $value{$addr} = $value;
2777
2778         $type{$addr} = delete $args{'Type'} || 0;
2779
2780         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2781
2782         if (! $type{$addr}) {
2783             $standard_form{$addr} = main::standardize($value);
2784         }
2785
2786         return $self;
2787     }
2788
2789     use overload
2790         fallback => 0,
2791         qw("") => "_operator_stringify",
2792         "." => \&main::_operator_dot,
2793     ;
2794
2795     sub _operator_stringify {
2796         my $self = shift;
2797         my $addr = do { no overloading; pack 'J', $self; };
2798
2799         # Output it like '0041..0065 (value)'
2800         my $return = sprintf("%04X", $start{$addr})
2801                         .  '..'
2802                         . sprintf("%04X", $end{$addr});
2803         my $value = $value{$addr};
2804         my $type = $type{$addr};
2805         $return .= ' (';
2806         $return .= "$value";
2807         $return .= ", Type=$type" if $type != 0;
2808         $return .= ')';
2809
2810         return $return;
2811     }
2812
2813     sub standard_form {
2814         # The standard form is the value itself if the standard form is
2815         # undefined (that is if the value is special)
2816
2817         my $self = shift;
2818         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2819
2820         my $addr = do { no overloading; pack 'J', $self; };
2821
2822         return $standard_form{$addr} if defined $standard_form{$addr};
2823         return $value{$addr};
2824     }
2825
2826     sub dump {
2827         # Human, not machine readable.  For machine readable, comment out this
2828         # entire routine and let the standard one take effect.
2829         my $self = shift;
2830         my $indent = shift;
2831         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2832
2833         my $addr = do { no overloading; pack 'J', $self; };
2834
2835         my $return = $indent
2836                     . sprintf("%04X", $start{$addr})
2837                     . '..'
2838                     . sprintf("%04X", $end{$addr})
2839                     . " '$value{$addr}';";
2840         if (! defined $standard_form{$addr}) {
2841             $return .= "(type=$type{$addr})";
2842         }
2843         elsif ($standard_form{$addr} ne $value{$addr}) {
2844             $return .= "(standard '$standard_form{$addr}')";
2845         }
2846         return $return;
2847     }
2848 } # End closure
2849
2850 package _Range_List_Base;
2851
2852 # Base class for range lists.  A range list is simply an ordered list of
2853 # ranges, so that the ranges with the lowest starting numbers are first in it.
2854 #
2855 # When a new range is added that is adjacent to an existing range that has the
2856 # same value and type, it merges with it to form a larger range.
2857 #
2858 # Ranges generally do not overlap, except that there can be multiple entries
2859 # of single code point ranges.  This is because of NameAliases.txt.
2860 #
2861 # In this program, there is a standard value such that if two different
2862 # values, have the same standard value, they are considered equivalent.  This
2863 # value was chosen so that it gives correct results on Unicode data
2864
2865 # There are a number of methods to manipulate range lists, and some operators
2866 # are overloaded to handle them.
2867
2868 sub trace { return main::trace(@_); }
2869
2870 { # Closure
2871
2872     our $addr;
2873
2874     main::setup_package();
2875
2876     my %ranges;
2877     # The list of ranges
2878     main::set_access('ranges', \%ranges, 'readable_array');
2879
2880     my %max;
2881     # The highest code point in the list.  This was originally a method, but
2882     # actual measurements said it was used a lot.
2883     main::set_access('max', \%max, 'r');
2884
2885     my %each_range_iterator;
2886     # Iterator position for each_range()
2887     main::set_access('each_range_iterator', \%each_range_iterator);
2888
2889     my %owner_name_of;
2890     # Name of parent this is attached to, if any.  Solely for better error
2891     # messages.
2892     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2893
2894     my %_search_ranges_cache;
2895     # A cache of the previous result from _search_ranges(), for better
2896     # performance
2897     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2898
2899     sub new {
2900         my $class = shift;
2901         my %args = @_;
2902
2903         # Optional initialization data for the range list.
2904         my $initialize = delete $args{'Initialize'};
2905
2906         my $self;
2907
2908         # Use _union() to initialize.  _union() returns an object of this
2909         # class, which means that it will call this constructor recursively.
2910         # But it won't have this $initialize parameter so that it won't
2911         # infinitely loop on this.
2912         return _union($class, $initialize, %args) if defined $initialize;
2913
2914         $self = bless \do { my $anonymous_scalar }, $class;
2915         my $addr = do { no overloading; pack 'J', $self; };
2916
2917         # Optional parent object, only for debug info.
2918         $owner_name_of{$addr} = delete $args{'Owner'};
2919         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2920
2921         # Stringify, in case it is an object.
2922         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2923
2924         # This is used only for error messages, and so a colon is added
2925         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2926
2927         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2928
2929         # Max is initialized to a negative value that isn't adjacent to 0,
2930         # for simpler tests
2931         $max{$addr} = -2;
2932
2933         $_search_ranges_cache{$addr} = 0;
2934         $ranges{$addr} = [];
2935
2936         return $self;
2937     }
2938
2939     use overload
2940         fallback => 0,
2941         qw("") => "_operator_stringify",
2942         "." => \&main::_operator_dot,
2943     ;
2944
2945     sub _operator_stringify {
2946         my $self = shift;
2947         my $addr = do { no overloading; pack 'J', $self; };
2948
2949         return "Range_List attached to '$owner_name_of{$addr}'"
2950                                                 if $owner_name_of{$addr};
2951         return "anonymous Range_List " . \$self;
2952     }
2953
2954     sub _union {
2955         # Returns the union of the input code points.  It can be called as
2956         # either a constructor or a method.  If called as a method, the result
2957         # will be a new() instance of the calling object, containing the union
2958         # of that object with the other parameter's code points;  if called as
2959         # a constructor, the first parameter gives the class the new object
2960         # should be, and the second parameter gives the code points to go into
2961         # it.
2962         # In either case, there are two parameters looked at by this routine;
2963         # any additional parameters are passed to the new() constructor.
2964         #
2965         # The code points can come in the form of some object that contains
2966         # ranges, and has a conventionally named method to access them; or
2967         # they can be an array of individual code points (as integers); or
2968         # just a single code point.
2969         #
2970         # If they are ranges, this routine doesn't make any effort to preserve
2971         # the range values of one input over the other.  Therefore this base
2972         # class should not allow _union to be called from other than
2973         # initialization code, so as to prevent two tables from being added
2974         # together where the range values matter.  The general form of this
2975         # routine therefore belongs in a derived class, but it was moved here
2976         # to avoid duplication of code.  The failure to overload this in this
2977         # class keeps it safe.
2978         #
2979
2980         my $self;
2981         my @args;   # Arguments to pass to the constructor
2982
2983         my $class = shift;
2984
2985         # If a method call, will start the union with the object itself, and
2986         # the class of the new object will be the same as self.
2987         if (ref $class) {
2988             $self = $class;
2989             $class = ref $self;
2990             push @args, $self;
2991         }
2992
2993         # Add the other required parameter.
2994         push @args, shift;
2995         # Rest of parameters are passed on to the constructor
2996
2997         # Accumulate all records from both lists.
2998         my @records;
2999         for my $arg (@args) {
3000             #local $to_trace = 0 if main::DEBUG;
3001             trace "argument = $arg" if main::DEBUG && $to_trace;
3002             if (! defined $arg) {
3003                 my $message = "";
3004                 if (defined $self) {
3005                     no overloading;
3006                     $message .= $owner_name_of{pack 'J', $self};
3007                 }
3008                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
3009                 return;
3010             }
3011             $arg = [ $arg ] if ! ref $arg;
3012             my $type = ref $arg;
3013             if ($type eq 'ARRAY') {
3014                 foreach my $element (@$arg) {
3015                     push @records, Range->new($element, $element);
3016                 }
3017             }
3018             elsif ($arg->isa('Range')) {
3019                 push @records, $arg;
3020             }
3021             elsif ($arg->can('ranges')) {
3022                 push @records, $arg->ranges;
3023             }
3024             else {
3025                 my $message = "";
3026                 if (defined $self) {
3027                     no overloading;
3028                     $message .= $owner_name_of{pack 'J', $self};
3029                 }
3030                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3031                 return;
3032             }
3033         }
3034
3035         # Sort with the range containing the lowest ordinal first, but if
3036         # two ranges start at the same code point, sort with the bigger range
3037         # of the two first, because it takes fewer cycles.
3038         @records = sort { ($a->start <=> $b->start)
3039                                       or
3040                                     # if b is shorter than a, b->end will be
3041                                     # less than a->end, and we want to select
3042                                     # a, so want to return -1
3043                                     ($b->end <=> $a->end)
3044                                    } @records;
3045
3046         my $new = $class->new(@_);
3047
3048         # Fold in records so long as they add new information.
3049         for my $set (@records) {
3050             my $start = $set->start;
3051             my $end   = $set->end;
3052             my $value   = $set->value;
3053             if ($start > $new->max) {
3054                 $new->_add_delete('+', $start, $end, $value);
3055             }
3056             elsif ($end > $new->max) {
3057                 $new->_add_delete('+', $new->max +1, $end, $value);
3058             }
3059         }
3060
3061         return $new;
3062     }
3063
3064     sub range_count {        # Return the number of ranges in the range list
3065         my $self = shift;
3066         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3067
3068         no overloading;
3069         return scalar @{$ranges{pack 'J', $self}};
3070     }
3071
3072     sub min {
3073         # Returns the minimum code point currently in the range list, or if
3074         # the range list is empty, 2 beyond the max possible.  This is a
3075         # method because used so rarely, that not worth saving between calls,
3076         # and having to worry about changing it as ranges are added and
3077         # deleted.
3078
3079         my $self = shift;
3080         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3081
3082         my $addr = do { no overloading; pack 'J', $self; };
3083
3084         # If the range list is empty, return a large value that isn't adjacent
3085         # to any that could be in the range list, for simpler tests
3086         return $MAX_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3087         return $ranges{$addr}->[0]->start;
3088     }
3089
3090     sub contains {
3091         # Boolean: Is argument in the range list?  If so returns $i such that:
3092         #   range[$i]->end < $codepoint <= range[$i+1]->end
3093         # which is one beyond what you want; this is so that the 0th range
3094         # doesn't return false
3095         my $self = shift;
3096         my $codepoint = shift;
3097         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3098
3099         my $i = $self->_search_ranges($codepoint);
3100         return 0 unless defined $i;
3101
3102         # The search returns $i, such that
3103         #   range[$i-1]->end < $codepoint <= range[$i]->end
3104         # So is in the table if and only iff it is at least the start position
3105         # of range $i.
3106         no overloading;
3107         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3108         return $i + 1;
3109     }
3110
3111     sub containing_range {
3112         # Returns the range object that contains the code point, undef if none
3113
3114         my $self = shift;
3115         my $codepoint = shift;
3116         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3117
3118         my $i = $self->contains($codepoint);
3119         return unless $i;
3120
3121         # contains() returns 1 beyond where we should look
3122         no overloading;
3123         return $ranges{pack 'J', $self}->[$i-1];
3124     }
3125
3126     sub value_of {
3127         # Returns the value associated with the code point, undef if none
3128
3129         my $self = shift;
3130         my $codepoint = shift;
3131         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3132
3133         my $range = $self->containing_range($codepoint);
3134         return unless defined $range;
3135
3136         return $range->value;
3137     }
3138
3139     sub type_of {
3140         # Returns the type of the range containing the code point, undef if
3141         # the code point is not in the table
3142
3143         my $self = shift;
3144         my $codepoint = shift;
3145         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3146
3147         my $range = $self->containing_range($codepoint);
3148         return unless defined $range;
3149
3150         return $range->type;
3151     }
3152
3153     sub _search_ranges {
3154         # Find the range in the list which contains a code point, or where it
3155         # should go if were to add it.  That is, it returns $i, such that:
3156         #   range[$i-1]->end < $codepoint <= range[$i]->end
3157         # Returns undef if no such $i is possible (e.g. at end of table), or
3158         # if there is an error.
3159
3160         my $self = shift;
3161         my $code_point = shift;
3162         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3163
3164         my $addr = do { no overloading; pack 'J', $self; };
3165
3166         return if $code_point > $max{$addr};
3167         my $r = $ranges{$addr};                # The current list of ranges
3168         my $range_list_size = scalar @$r;
3169         my $i;
3170
3171         use integer;        # want integer division
3172
3173         # Use the cached result as the starting guess for this one, because,
3174         # an experiment on 5.1 showed that 90% of the time the cache was the
3175         # same as the result on the next call (and 7% it was one less).
3176         $i = $_search_ranges_cache{$addr};
3177         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3178                                             # from an intervening deletion
3179         #local $to_trace = 1 if main::DEBUG;
3180         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3181         return $i if $code_point <= $r->[$i]->end
3182                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3183
3184         # Here the cache doesn't yield the correct $i.  Try adding 1.
3185         if ($i < $range_list_size - 1
3186             && $r->[$i]->end < $code_point &&
3187             $code_point <= $r->[$i+1]->end)
3188         {
3189             $i++;
3190             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3191             $_search_ranges_cache{$addr} = $i;
3192             return $i;
3193         }
3194
3195         # Here, adding 1 also didn't work.  We do a binary search to
3196         # find the correct position, starting with current $i
3197         my $lower = 0;
3198         my $upper = $range_list_size - 1;
3199         while (1) {
3200             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3201
3202             if ($code_point <= $r->[$i]->end) {
3203
3204                 # Here we have met the upper constraint.  We can quit if we
3205                 # also meet the lower one.
3206                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3207
3208                 $upper = $i;        # Still too high.
3209
3210             }
3211             else {
3212
3213                 # Here, $r[$i]->end < $code_point, so look higher up.
3214                 $lower = $i;
3215             }
3216
3217             # Split search domain in half to try again.
3218             my $temp = ($upper + $lower) / 2;
3219
3220             # No point in continuing unless $i changes for next time
3221             # in the loop.
3222             if ($temp == $i) {
3223
3224                 # We can't reach the highest element because of the averaging.
3225                 # So if one below the upper edge, force it there and try one
3226                 # more time.
3227                 if ($i == $range_list_size - 2) {
3228
3229                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3230                     $i = $range_list_size - 1;
3231
3232                     # Change $lower as well so if fails next time through,
3233                     # taking the average will yield the same $i, and we will
3234                     # quit with the error message just below.
3235                     $lower = $i;
3236                     next;
3237                 }
3238                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3239                 return;
3240             }
3241             $i = $temp;
3242         } # End of while loop
3243
3244         if (main::DEBUG && $to_trace) {
3245             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3246             trace "i=  [ $i ]", $r->[$i];
3247             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3248         }
3249
3250         # Here we have found the offset.  Cache it as a starting point for the
3251         # next call.
3252         $_search_ranges_cache{$addr} = $i;
3253         return $i;
3254     }
3255
3256     sub _add_delete {
3257         # Add, replace or delete ranges to or from a list.  The $type
3258         # parameter gives which:
3259         #   '+' => insert or replace a range, returning a list of any changed
3260         #          ranges.
3261         #   '-' => delete a range, returning a list of any deleted ranges.
3262         #
3263         # The next three parameters give respectively the start, end, and
3264         # value associated with the range.  'value' should be null unless the
3265         # operation is '+';
3266         #
3267         # The range list is kept sorted so that the range with the lowest
3268         # starting position is first in the list, and generally, adjacent
3269         # ranges with the same values are merged into a single larger one (see
3270         # exceptions below).
3271         #
3272         # There are more parameters; all are key => value pairs:
3273         #   Type    gives the type of the value.  It is only valid for '+'.
3274         #           All ranges have types; if this parameter is omitted, 0 is
3275         #           assumed.  Ranges with type 0 are assumed to obey the
3276         #           Unicode rules for casing, etc; ranges with other types are
3277         #           not.  Otherwise, the type is arbitrary, for the caller's
3278         #           convenience, and looked at only by this routine to keep
3279         #           adjacent ranges of different types from being merged into
3280         #           a single larger range, and when Replace =>
3281         #           $IF_NOT_EQUIVALENT is specified (see just below).
3282         #   Replace  determines what to do if the range list already contains
3283         #            ranges which coincide with all or portions of the input
3284         #            range.  It is only valid for '+':
3285         #       => $NO            means that the new value is not to replace
3286         #                         any existing ones, but any empty gaps of the
3287         #                         range list coinciding with the input range
3288         #                         will be filled in with the new value.
3289         #       => $UNCONDITIONALLY  means to replace the existing values with
3290         #                         this one unconditionally.  However, if the
3291         #                         new and old values are identical, the
3292         #                         replacement is skipped to save cycles
3293         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3294         #                         with this one if they are not equivalent.
3295         #                         Ranges are equivalent if their types are the
3296         #                         same, and they are the same string; or if
3297         #                         both are type 0 ranges, if their Unicode
3298         #                         standard forms are identical.  In this last
3299         #                         case, the routine chooses the more "modern"
3300         #                         one to use.  This is because some of the
3301         #                         older files are formatted with values that
3302         #                         are, for example, ALL CAPs, whereas the
3303         #                         derived files have a more modern style,
3304         #                         which looks better.  By looking for this
3305         #                         style when the pre-existing and replacement
3306         #                         standard forms are the same, we can move to
3307         #                         the modern style
3308         #       => $MULTIPLE      means that if this range duplicates an
3309         #                         existing one, but has a different value,
3310         #                         don't replace the existing one, but insert
3311         #                         this, one so that the same range can occur
3312         #                         multiple times.  They are stored LIFO, so
3313         #                         that the final one inserted is the first one
3314         #                         returned in an ordered search of the table.
3315         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3316         #
3317         # "same value" means identical for non-type-0 ranges, and it means
3318         # having the same standard forms for type-0 ranges.
3319
3320         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3321
3322         my $self = shift;
3323         my $operation = shift;   # '+' for add/replace; '-' for delete;
3324         my $start = shift;
3325         my $end   = shift;
3326         my $value = shift;
3327
3328         my %args = @_;
3329
3330         $value = "" if not defined $value;        # warning: $value can be "0"
3331
3332         my $replace = delete $args{'Replace'};
3333         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3334
3335         my $type = delete $args{'Type'};
3336         $type = 0 unless defined $type;
3337
3338         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3339
3340         my $addr = do { no overloading; pack 'J', $self; };
3341
3342         if ($operation ne '+' && $operation ne '-') {
3343             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3344             return;
3345         }
3346         unless (defined $start && defined $end) {
3347             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3348             return;
3349         }
3350         unless ($end >= $start) {
3351             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3352             return;
3353         }
3354         #local $to_trace = 1 if main::DEBUG;
3355
3356         if ($operation eq '-') {
3357             if ($replace != $IF_NOT_EQUIVALENT) {
3358                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3359                 $replace = $IF_NOT_EQUIVALENT;
3360             }
3361             if ($type) {
3362                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3363                 $type = 0;
3364             }
3365             if ($value ne "") {
3366                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3367                 $value = "";
3368             }
3369         }
3370
3371         my $r = $ranges{$addr};               # The current list of ranges
3372         my $range_list_size = scalar @$r;     # And its size
3373         my $max = $max{$addr};                # The current high code point in
3374                                               # the list of ranges
3375
3376         # Do a special case requiring fewer machine cycles when the new range
3377         # starts after the current highest point.  The Unicode input data is
3378         # structured so this is common.
3379         if ($start > $max) {
3380
3381             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3382             return if $operation eq '-'; # Deleting a non-existing range is a
3383                                          # no-op
3384
3385             # If the new range doesn't logically extend the current final one
3386             # in the range list, create a new range at the end of the range
3387             # list.  (max cleverly is initialized to a negative number not
3388             # adjacent to 0 if the range list is empty, so even adding a range
3389             # to an empty range list starting at 0 will have this 'if'
3390             # succeed.)
3391             if ($start > $max + 1        # non-adjacent means can't extend.
3392                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3393                 || @{$r}[-1]->type != $type # types differ, can't extend.
3394             ) {
3395                 push @$r, Range->new($start, $end,
3396                                      Value => $value,
3397                                      Type => $type);
3398             }
3399             else {
3400
3401                 # Here, the new range starts just after the current highest in
3402                 # the range list, and they have the same type and value.
3403                 # Extend the current range to incorporate the new one.
3404                 @{$r}[-1]->set_end($end);
3405             }
3406
3407             # This becomes the new maximum.
3408             $max{$addr} = $end;
3409
3410             return;
3411         }
3412         #local $to_trace = 0 if main::DEBUG;
3413
3414         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3415
3416         # Here, the input range isn't after the whole rest of the range list.
3417         # Most likely 'splice' will be needed.  The rest of the routine finds
3418         # the needed splice parameters, and if necessary, does the splice.
3419         # First, find the offset parameter needed by the splice function for
3420         # the input range.  Note that the input range may span multiple
3421         # existing ones, but we'll worry about that later.  For now, just find
3422         # the beginning.  If the input range is to be inserted starting in a
3423         # position not currently in the range list, it must (obviously) come
3424         # just after the range below it, and just before the range above it.
3425         # Slightly less obviously, it will occupy the position currently
3426         # occupied by the range that is to come after it.  More formally, we
3427         # are looking for the position, $i, in the array of ranges, such that:
3428         #
3429         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3430         #
3431         # (The ordered relationships within existing ranges are also shown in
3432         # the equation above).  However, if the start of the input range is
3433         # within an existing range, the splice offset should point to that
3434         # existing range's position in the list; that is $i satisfies a
3435         # somewhat different equation, namely:
3436         #
3437         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3438         #
3439         # More briefly, $start can come before or after r[$i]->start, and at
3440         # this point, we don't know which it will be.  However, these
3441         # two equations share these constraints:
3442         #
3443         #   r[$i-1]->end < $start <= r[$i]->end
3444         #
3445         # And that is good enough to find $i.
3446
3447         my $i = $self->_search_ranges($start);
3448         if (! defined $i) {
3449             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3450             return;
3451         }
3452
3453         # The search function returns $i such that:
3454         #
3455         # r[$i-1]->end < $start <= r[$i]->end
3456         #
3457         # That means that $i points to the first range in the range list
3458         # that could possibly be affected by this operation.  We still don't
3459         # know if the start of the input range is within r[$i], or if it
3460         # points to empty space between r[$i-1] and r[$i].
3461         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3462
3463         # Special case the insertion of data that is not to replace any
3464         # existing data.
3465         if ($replace == $NO) {  # If $NO, has to be operation '+'
3466             #local $to_trace = 1 if main::DEBUG;
3467             trace "Doesn't replace" if main::DEBUG && $to_trace;
3468
3469             # Here, the new range is to take effect only on those code points
3470             # that aren't already in an existing range.  This can be done by
3471             # looking through the existing range list and finding the gaps in
3472             # the ranges that this new range affects, and then calling this
3473             # function recursively on each of those gaps, leaving untouched
3474             # anything already in the list.  Gather up a list of the changed
3475             # gaps first so that changes to the internal state as new ranges
3476             # are added won't be a problem.
3477             my @gap_list;
3478
3479             # First, if the starting point of the input range is outside an
3480             # existing one, there is a gap from there to the beginning of the
3481             # existing range -- add a span to fill the part that this new
3482             # range occupies
3483             if ($start < $r->[$i]->start) {
3484                 push @gap_list, Range->new($start,
3485                                            main::min($end,
3486                                                      $r->[$i]->start - 1),
3487                                            Type => $type);
3488                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3489             }
3490
3491             # Then look through the range list for other gaps until we reach
3492             # the highest range affected by the input one.
3493             my $j;
3494             for ($j = $i+1; $j < $range_list_size; $j++) {
3495                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3496                 last if $end < $r->[$j]->start;
3497
3498                 # If there is a gap between when this range starts and the
3499                 # previous one ends, add a span to fill it.  Note that just
3500                 # because there are two ranges doesn't mean there is a
3501                 # non-zero gap between them.  It could be that they have
3502                 # different values or types
3503                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3504                     push @gap_list,
3505                         Range->new($r->[$j-1]->end + 1,
3506                                    $r->[$j]->start - 1,
3507                                    Type => $type);
3508                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3509                 }
3510             }
3511
3512             # Here, we have either found an existing range in the range list,
3513             # beyond the area affected by the input one, or we fell off the
3514             # end of the loop because the input range affects the whole rest
3515             # of the range list.  In either case, $j is 1 higher than the
3516             # highest affected range.  If $j == $i, it means that there are no
3517             # affected ranges, that the entire insertion is in the gap between
3518             # r[$i-1], and r[$i], which we already have taken care of before
3519             # the loop.
3520             # On the other hand, if there are affected ranges, it might be
3521             # that there is a gap that needs filling after the final such
3522             # range to the end of the input range
3523             if ($r->[$j-1]->end < $end) {
3524                     push @gap_list, Range->new(main::max($start,
3525                                                          $r->[$j-1]->end + 1),
3526                                                $end,
3527                                                Type => $type);
3528                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3529             }
3530
3531             # Call recursively to fill in all the gaps.
3532             foreach my $gap (@gap_list) {
3533                 $self->_add_delete($operation,
3534                                    $gap->start,
3535                                    $gap->end,
3536                                    $value,
3537                                    Type => $type);
3538             }
3539
3540             return;
3541         }
3542
3543         # Here, we have taken care of the case where $replace is $NO.
3544         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3545         # If inserting a multiple record, this is where it goes, before the
3546         # first (if any) existing one.  This implies an insertion, and no
3547         # change to any existing ranges.  Note that $i can be -1 if this new
3548         # range doesn't actually duplicate any existing, and comes at the
3549         # beginning of the list.
3550         if ($replace == $MULTIPLE) {
3551
3552             if ($start != $end) {
3553                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3554                 return;
3555             }
3556
3557             # Don't add an exact duplicate, as it isn't really a multiple
3558             if ($end >= $r->[$i]->start) {
3559                 my $existing_value = $r->[$i]->value;
3560                 my $existing_type = $r->[$i]->type;
3561                 return if $value eq $existing_value && $type eq $existing_type;
3562
3563                 # If the multiple value is part of an existing range, we want
3564                 # to split up that range, so that only the single code point
3565                 # is affected.  To do this, we first call ourselves
3566                 # recursively to delete that code point from the table, having
3567                 # preserved its current data above.  Then we call ourselves
3568                 # recursively again to add the new multiple, which we know by
3569                 # the test just above is different than the current code
3570                 # point's value, so it will become a range containing a single
3571                 # code point: just itself.  Finally, we add back in the
3572                 # pre-existing code point, which will again be a single code
3573                 # point range.  Because 'i' likely will have changed as a
3574                 # result of these operations, we can't just continue on, but
3575                 # do this operation recursively as well.
3576                 if ($r->[$i]->start != $r->[$i]->end) {
3577                     $self->_add_delete('-', $start, $end, "");
3578                     $self->_add_delete('+', $start, $end, $value, Type => $type);
3579                     return $self->_add_delete('+', $start, $end, $existing_value, Type => $existing_type, Replace => $MULTIPLE);
3580                 }
3581             }
3582
3583             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3584             my @return = splice @$r,
3585                                 $i,
3586                                 0,
3587                                 Range->new($start,
3588                                            $end,
3589                                            Value => $value,
3590                                            Type => $type);
3591             if (main::DEBUG && $to_trace) {
3592                 trace "After splice:";
3593                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3594                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3595                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3596                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3597                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3598                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3599             }
3600             return @return;
3601         }
3602
3603         # Here, we have taken care of $NO and $MULTIPLE replaces.  This leaves
3604         # delete, insert, and replace either unconditionally or if not
3605         # equivalent.  $i still points to the first potential affected range.
3606         # Now find the highest range affected, which will determine the length
3607         # parameter to splice.  (The input range can span multiple existing
3608         # ones.)  If this isn't a deletion, while we are looking through the
3609         # range list, see also if this is a replacement rather than a clean
3610         # insertion; that is if it will change the values of at least one
3611         # existing range.  Start off assuming it is an insert, until find it
3612         # isn't.
3613         my $clean_insert = $operation eq '+';
3614         my $j;        # This will point to the highest affected range
3615
3616         # For non-zero types, the standard form is the value itself;
3617         my $standard_form = ($type) ? $value : main::standardize($value);
3618
3619         for ($j = $i; $j < $range_list_size; $j++) {
3620             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3621
3622             # If find a range that it doesn't overlap into, we can stop
3623             # searching
3624             last if $end < $r->[$j]->start;
3625
3626             # Here, overlaps the range at $j.  If the values don't match,
3627             # and so far we think this is a clean insertion, it becomes a
3628             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3629             if ($clean_insert) {
3630                 if ($r->[$j]->standard_form ne $standard_form) {
3631                     $clean_insert = 0;
3632                     if ($replace == $CROAK) {
3633                         main::croak("The range to add "
3634                         . sprintf("%04X", $start)
3635                         . '-'
3636                         . sprintf("%04X", $end)
3637                         . " with value '$value' overlaps an existing range $r->[$j]");
3638                     }
3639                 }
3640                 else {
3641
3642                     # Here, the two values are essentially the same.  If the
3643                     # two are actually identical, replacing wouldn't change
3644                     # anything so skip it.
3645                     my $pre_existing = $r->[$j]->value;
3646                     if ($pre_existing ne $value) {
3647
3648                         # Here the new and old standardized values are the
3649                         # same, but the non-standardized values aren't.  If
3650                         # replacing unconditionally, then replace
3651                         if( $replace == $UNCONDITIONALLY) {
3652                             $clean_insert = 0;
3653                         }
3654                         else {
3655
3656                             # Here, are replacing conditionally.  Decide to
3657                             # replace or not based on which appears to look
3658                             # the "nicest".  If one is mixed case and the
3659                             # other isn't, choose the mixed case one.
3660                             my $new_mixed = $value =~ /[A-Z]/
3661                                             && $value =~ /[a-z]/;
3662                             my $old_mixed = $pre_existing =~ /[A-Z]/
3663                                             && $pre_existing =~ /[a-z]/;
3664
3665                             if ($old_mixed != $new_mixed) {
3666                                 $clean_insert = 0 if $new_mixed;
3667                                 if (main::DEBUG && $to_trace) {
3668                                     if ($clean_insert) {
3669                                         trace "Retaining $pre_existing over $value";
3670                                     }
3671                                     else {
3672                                         trace "Replacing $pre_existing with $value";
3673                                     }
3674                                 }
3675                             }
3676                             else {
3677
3678                                 # Here casing wasn't different between the two.
3679                                 # If one has hyphens or underscores and the
3680                                 # other doesn't, choose the one with the
3681                                 # punctuation.
3682                                 my $new_punct = $value =~ /[-_]/;
3683                                 my $old_punct = $pre_existing =~ /[-_]/;
3684
3685                                 if ($old_punct != $new_punct) {
3686                                     $clean_insert = 0 if $new_punct;
3687                                     if (main::DEBUG && $to_trace) {
3688                                         if ($clean_insert) {
3689                                             trace "Retaining $pre_existing over $value";
3690                                         }
3691                                         else {
3692                                             trace "Replacing $pre_existing with $value";
3693                                         }
3694                                     }
3695                                 }   # else existing one is just as "good";
3696                                     # retain it to save cycles.
3697                             }
3698                         }
3699                     }
3700                 }
3701             }
3702         } # End of loop looking for highest affected range.
3703
3704         # Here, $j points to one beyond the highest range that this insertion
3705         # affects (hence to beyond the range list if that range is the final
3706         # one in the range list).
3707
3708         # The splice length is all the affected ranges.  Get it before
3709         # subtracting, for efficiency, so we don't have to later add 1.
3710         my $length = $j - $i;
3711
3712         $j--;        # $j now points to the highest affected range.
3713         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3714
3715         # Here, have taken care of $NO and $MULTIPLE replaces.
3716         # $j points to the highest affected range.  But it can be < $i or even
3717         # -1.  These happen only if the insertion is entirely in the gap
3718         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3719         # above exited first time through with $end < $r->[$i]->start.  (And
3720         # then we subtracted one from j)  This implies also that $start <
3721         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3722         # $start, so the entire input range is in the gap.
3723         if ($j < $i) {
3724
3725             # Here the entire input range is in the gap before $i.
3726
3727             if (main::DEBUG && $to_trace) {
3728                 if ($i) {
3729                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3730                 }
3731                 else {
3732                     trace "Entire range is before $r->[$i]";
3733                 }
3734             }
3735             return if $operation ne '+'; # Deletion of a non-existent range is
3736                                          # a no-op
3737         }
3738         else {
3739
3740             # Here part of the input range is not in the gap before $i.  Thus,
3741             # there is at least one affected one, and $j points to the highest
3742             # such one.
3743
3744             # At this point, here is the situation:
3745             # This is not an insertion of a multiple, nor of tentative ($NO)
3746             # data.
3747             #   $i  points to the first element in the current range list that
3748             #            may be affected by this operation.  In fact, we know
3749             #            that the range at $i is affected because we are in
3750             #            the else branch of this 'if'
3751             #   $j  points to the highest affected range.
3752             # In other words,
3753             #   r[$i-1]->end < $start <= r[$i]->end
3754             # And:
3755             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3756             #
3757             # Also:
3758             #   $clean_insert is a boolean which is set true if and only if
3759             #        this is a "clean insertion", i.e., not a change nor a
3760             #        deletion (multiple was handled above).
3761
3762             # We now have enough information to decide if this call is a no-op
3763             # or not.  It is a no-op if this is an insertion of already
3764             # existing data.
3765
3766             if (main::DEBUG && $to_trace && $clean_insert
3767                                          && $i == $j
3768                                          && $start >= $r->[$i]->start)
3769             {
3770                     trace "no-op";
3771             }
3772             return if $clean_insert
3773                       && $i == $j # more than one affected range => not no-op
3774
3775                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3776                       # Further, $start and/or $end is >= r[$i]->start
3777                       # The test below hence guarantees that
3778                       #     r[$i]->start < $start <= $end <= r[$i]->end
3779                       # This means the input range is contained entirely in
3780                       # the one at $i, so is a no-op
3781                       && $start >= $r->[$i]->start;
3782         }
3783
3784         # Here, we know that some action will have to be taken.  We have
3785         # calculated the offset and length (though adjustments may be needed)
3786         # for the splice.  Now start constructing the replacement list.
3787         my @replacement;
3788         my $splice_start = $i;
3789
3790         my $extends_below;
3791         my $extends_above;
3792
3793         # See if should extend any adjacent ranges.
3794         if ($operation eq '-') { # Don't extend deletions
3795             $extends_below = $extends_above = 0;
3796         }
3797         else {  # Here, should extend any adjacent ranges.  See if there are
3798                 # any.
3799             $extends_below = ($i > 0
3800                             # can't extend unless adjacent
3801                             && $r->[$i-1]->end == $start -1
3802                             # can't extend unless are same standard value
3803                             && $r->[$i-1]->standard_form eq $standard_form
3804                             # can't extend unless share type
3805                             && $r->[$i-1]->type == $type);
3806             $extends_above = ($j+1 < $range_list_size
3807                             && $r->[$j+1]->start == $end +1
3808                             && $r->[$j+1]->standard_form eq $standard_form
3809                             && $r->[$j+1]->type == $type);
3810         }
3811         if ($extends_below && $extends_above) { # Adds to both
3812             $splice_start--;     # start replace at element below
3813             $length += 2;        # will replace on both sides
3814             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3815
3816             # The result will fill in any gap, replacing both sides, and
3817             # create one large range.
3818             @replacement = Range->new($r->[$i-1]->start,
3819                                       $r->[$j+1]->end,
3820                                       Value => $value,
3821                                       Type => $type);
3822         }
3823         else {
3824
3825             # Here we know that the result won't just be the conglomeration of
3826             # a new range with both its adjacent neighbors.  But it could
3827             # extend one of them.
3828
3829             if ($extends_below) {
3830
3831                 # Here the new element adds to the one below, but not to the
3832                 # one above.  If inserting, and only to that one range,  can
3833                 # just change its ending to include the new one.
3834                 if ($length == 0 && $clean_insert) {
3835                     $r->[$i-1]->set_end($end);
3836                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3837                     return;
3838                 }
3839                 else {
3840                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3841                     $splice_start--;        # start replace at element below
3842                     $length++;              # will replace the element below
3843                     $start = $r->[$i-1]->start;
3844                 }
3845             }
3846             elsif ($extends_above) {
3847
3848                 # Here the new element adds to the one above, but not below.
3849                 # Mirror the code above
3850                 if ($length == 0 && $clean_insert) {
3851                     $r->[$j+1]->set_start($start);
3852                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3853                     return;
3854                 }
3855                 else {
3856                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3857                     $length++;        # will replace the element above
3858                     $end = $r->[$j+1]->end;
3859                 }
3860             }
3861
3862             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3863
3864             # Finally, here we know there will have to be a splice.
3865             # If the change or delete affects only the highest portion of the
3866             # first affected range, the range will have to be split.  The
3867             # splice will remove the whole range, but will replace it by a new
3868             # range containing just the unaffected part.  So, in this case,
3869             # add to the replacement list just this unaffected portion.
3870             if (! $extends_below
3871                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3872             {
3873                 push @replacement,
3874                     Range->new($r->[$i]->start,
3875                                $start - 1,
3876                                Value => $r->[$i]->value,
3877                                Type => $r->[$i]->type);
3878             }
3879
3880             # In the case of an insert or change, but not a delete, we have to
3881             # put in the new stuff;  this comes next.
3882             if ($operation eq '+') {
3883                 push @replacement, Range->new($start,
3884                                               $end,
3885                                               Value => $value,
3886                                               Type => $type);
3887             }
3888
3889             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3890             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3891
3892             # And finally, if we're changing or deleting only a portion of the
3893             # highest affected range, it must be split, as the lowest one was.
3894             if (! $extends_above
3895                 && $j >= 0  # Remember that j can be -1 if before first
3896                             # current element
3897                 && $end >= $r->[$j]->start
3898                 && $end < $r->[$j]->end)
3899             {
3900                 push @replacement,
3901                     Range->new($end + 1,
3902                                $r->[$j]->end,
3903                                Value => $r->[$j]->value,
3904                                Type => $r->[$j]->type);
3905             }
3906         }
3907
3908         # And do the splice, as calculated above
3909         if (main::DEBUG && $to_trace) {
3910             trace "replacing $length element(s) at $i with ";
3911             foreach my $replacement (@replacement) {
3912                 trace "    $replacement";
3913             }
3914             trace "Before splice:";
3915             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3916             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3917             trace "i  =[", $i, "]", $r->[$i];
3918             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3919             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3920         }
3921
3922         my @return = splice @$r, $splice_start, $length, @replacement;
3923
3924         if (main::DEBUG && $to_trace) {
3925             trace "After splice:";
3926             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3927             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3928             trace "i  =[", $i, "]", $r->[$i];
3929             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3930             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3931             trace "removed ", @return if @return;
3932         }
3933
3934         # An actual deletion could have changed the maximum in the list.
3935         # There was no deletion if the splice didn't return something, but
3936         # otherwise recalculate it.  This is done too rarely to worry about
3937         # performance.
3938         if ($operation eq '-' && @return) {
3939             $max{$addr} = $r->[-1]->end;
3940         }
3941         return @return;
3942     }
3943
3944     sub reset_each_range {  # reset the iterator for each_range();
3945         my $self = shift;
3946         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3947
3948         no overloading;
3949         undef $each_range_iterator{pack 'J', $self};
3950         return;
3951     }
3952
3953     sub each_range {
3954         # Iterate over each range in a range list.  Results are undefined if
3955         # the range list is changed during the iteration.
3956
3957         my $self = shift;
3958         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3959
3960         my $addr = do { no overloading; pack 'J', $self; };
3961
3962         return if $self->is_empty;
3963
3964         $each_range_iterator{$addr} = -1
3965                                 if ! defined $each_range_iterator{$addr};
3966         $each_range_iterator{$addr}++;
3967         return $ranges{$addr}->[$each_range_iterator{$addr}]
3968                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3969         undef $each_range_iterator{$addr};
3970         return;
3971     }
3972
3973     sub count {        # Returns count of code points in range list