regen_perly.pl

   1 #!/usr/bin/perl
   2 #
   3 # regen_perly.pl, DAPM 12-Feb-04
   4 #
   5 # Copyright (c) 2004, 2005 Larry Wall
   6 #
   7 # Given an input file perly.y, run bison on it and produce
   8 # the following output files:
   9 #
  10 # perly.h       standard bison header file with minor doctoring of
  11 #               #line directives plus adding a #ifdef PERL_CORE
  12 #
  13 # perly.tab     the parser table C definitions extracted from the bison output
  14 #               plus an extra table generated by this script.
  15 #
  16 # perly.act     the action case statements extracted from the bison output
  17 #
  18 # Note that perly.c is *not* regenerated - this is now a static file which
  19 # is not dependent on perly.y any more.
  20 #
  21 # If a filename of the form foo.y is given on the command line, then
  22 # this is used instead as the basename for all the files mentioned
  23 # above.
  24 #
  25 # Note that temporary files of the form perlytmp.h and perlytmp.c are
  26 # created and then deleted during this process
  27 #
  28 # Note also that this script is intended to be run on a UNIX system;
  29 # it may work elsewhere but no specific attempt has been made to make it
  30 # portable.
  31
  32 sub usage { die "usage: $0 [ -b bison_executable ] [ file.y ]\n" }
  33
  34 use warnings;
  35 use strict;
  36
  37 my $bison = 'bison';
  38
  39 if (@ARGV >= 2 and $ARGV[0] eq '-b') {
  40     shift;
  41     $bison = shift;
  42 }
  43
  44 my $y_file = shift || 'perly.y';
  45
  46 usage unless @ARGV==0 && $y_file =~ /\.y$/;
  47
  48 (my $h_file    = $y_file) =~ s/\.y$/.h/;
  49 (my $act_file  = $y_file) =~ s/\.y$/.act/;
  50 (my $tab_file  = $y_file) =~ s/\.y$/.tab/;
  51 (my $tmpc_file = $y_file) =~ s/\.y$/tmp.c/;
  52 (my $tmph_file = $y_file) =~ s/\.y$/tmp.h/;
  53
  54 # the yytranslate[] table generated by bison is ASCII/EBCDIC sensitive
  55
  56 die "$0: must be run on an ASCII system\n" unless ord 'A' == 65;
  57
  58 # check for correct version number. The constraints are:
  59 #  * must be >= 1.24 to avoid licensing issues.
  60 #  * it must generate the yystos[] table. Version 1.28 doesn't generate
  61 #    this; 1.35+ does
  62 #  * Must produce output which is extractable by the regexes below
  63 #  * Must produce the right values.
  64 # These last two contstraints  may well be met by earlier versions, but
  65 # I simply haven't tested them yet. If it works for you, then modify
  66 # the test below to allow that version too. DAPM Feb 04.
  67
  68 my $version = `$bison -V`;
  69 unless ($version =~ /\b(1\.875[a-z]?|2\.[013])\b/) { die <<EOF; }
  70
  71 You have the wrong version of bison in your path; currently 1.875
  72 2.0, 2.1 or 2.3 is required.  Try installing
  73     http://ftp.gnu.org/gnu/bison/bison-2.1.tar.gz
  74 or similar.  Your bison identifies itself as:
  75
  76 $version
  77 EOF
  78
  79 # creates $tmpc_file and $tmph_file
  80 my_system("$bison -d -o $tmpc_file $y_file");
  81
  82 open CTMPFILE, $tmpc_file or die "Can't open $tmpc_file: $!\n";
  83 my $clines;
  84 { local $/; $clines = <CTMPFILE>; }
  85 die "failed to read $tmpc_file: length mismatch\n"
  86     unless length $clines == -s $tmpc_file;
  87 close CTMPFILE;
  88
  89 my ($actlines, $tablines) = extract($clines);
  90
  91 $tablines .= make_type_tab($y_file, $tablines);
  92
  93 chmod 0644, $act_file;
  94 open ACTFILE, ">$act_file" or die "can't open $act_file: $!\n";
  95 print ACTFILE $actlines;
  96 close ACTFILE;
  97 chmod 0444, $act_file;
  98
  99 chmod 0644, $tab_file;
 100 open TABFILE, ">$tab_file" or die "can't open $tab_file: $!\n";
 101 print TABFILE $tablines;
 102 close TABFILE;
 103 chmod 0444, $tab_file;
 104
 105 unlink $tmpc_file;
 106
 107 # Wrap PERL_CORE round the symbol definitions. Also,  the
 108 # C<#line 30 "perly.y"> confuses the Win32 resource compiler and the
 109 # C<#line 188 "perlytmp.h"> gets picked up by make depend, so remove them.
 110
 111 open TMPH_FILE, $tmph_file or die "Can't open $tmph_file: $!\n";
 112 chmod 0644, $h_file;
 113 open H_FILE, ">$h_file" or die "Can't open $h_file: $!\n";
 114 my $endcore_done = 0;
 115 while (<TMPH_FILE>) {
 116     print H_FILE "#ifdef PERL_CORE\n" if $. == 1;
 117     if (!$endcore_done and /YYSTYPE_IS_DECLARED/) {
 118         print H_FILE "#endif /* PERL_CORE */\n";
 119         $endcore_done = 1;
 120     }
 121     next if /^#line \d+ ".*"/;
 122     print H_FILE $_;
 123 }
 124 close TMPH_FILE;
 125 close H_FILE;
 126 chmod 0444, $h_file;
 127 unlink $tmph_file;
 128
 129 print "rebuilt:  $h_file $tab_file $act_file\n";
 130
 131 exit 0;
 132
 133
 134 sub extract {
 135     my $clines = shift;
 136     my $tablines;
 137     my $actlines;
 138
 139     $clines =~ m@
 140         (?:
 141             ^/* YYFINAL[^\n]+\n         #optional comment
 142         )?
 143         \# \s* define \s* YYFINAL       # first #define
 144         .*?                             # other defines + most tables
 145         yystos\[\]\s*=                  # start of last table
 146         .*?
 147         }\s*;                           # end of last table
 148     @xms
 149         or die "Can't extract tables from $tmpc_file\n";
 150     $tablines = $&;
 151
 152
 153     $clines =~ m@
 154         switch \s* \( \s* \w+ \s* \) \s* { \s*
 155         (
 156             case \s* \d+ \s* : \s*
 157             \#line [^\n]+"\Q$y_file\E"
 158             .*?
 159         )
 160         }
 161         \s*
 162         ( \s* /\* .*? \*/ \s* )*        # optional C-comments
 163         \s*
 164         (
 165             \#line[^\n]+\.c"
 166         |
 167             \#line[^\n]+\.simple"
 168         |
 169             YY_SYMBOL_PRINT
 170         )
 171     @xms
 172         or die "Can't extract actions from $tmpc_file\n";
 173     $actlines = $1;
 174
 175     # C<#line 188 "perlytmp.c"> gets picked up by make depend, so remove them.
 176     $actlines =~ s/^#line \d+ "\Q$tmpc_file\E".*$//gm;
 177
 178     # convert yyvsp[nnn] into ps[nnn].val
 179
 180     $actlines =~ s/yyvsp\[(.*?)\]/ps[$1].val/g
 181         or die "Can't convert value stack name\n";
 182
 183     return $actlines. "\n", $tablines. "\n";
 184 }
 185
 186 # Generate a table, yy_type_tab[], that specifies for each token, what
 187 # type of value it holds.
 188 #
 189 # Read the .y file and extract a list of all the token names and
 190 # non-terminal names; then scan the string $tablines for the table yytname,
 191 # which gives the token index of each token/non-terminal; then use this to
 192 # create yy_type_tab.
 193 #
 194 # ie given (in perly.y),
 195 #
 196 #   %token <opval> A
 197 #   %token <ival>  B
 198 #   %type  <pval>  C
 199 #   %type  <opval> D
 200 #
 201 # and (in $tablines),
 202 #
 203 #   yytname[] = { "A" "B", "C", "D", "E" };
 204 #
 205 # then return
 206 #
 207 #    typedef enum { toketype_ival, toketype_opval, toketype_pval } toketypes;
 208 #
 209 #    static const toketypes yy_type_tab[]
 210 #          = { toketype_opval, toketype_ival, toketype_pval,
 211 #                toketype_opval, toketype_ival }
 212 #
 213 # where "E" has the default type. The default type is determined
 214 # by the __DEFAULT__ comment  next to the appropriate union member in
 215 # perly.y
 216
 217 sub make_type_tab {
 218     my ($y_file, $tablines) = @_;
 219     my %tokens;
 220     my %types;
 221     my $default_token;
 222     open my $fh, '<', $y_file or die "Can't open $y_file: $!\n";
 223     while (<$fh>) {
 224         if (/(\$\d+)\s*=/) {
 225             warn "$y_file:$.: dangerous assignment to $1: $_";
 226         }
 227
 228         if (/__DEFAULT__/) {
 229             m{(\w+) \s* ; \s* /\* \s* __DEFAULT__}x
 230                 or die "$y_file: can't parse __DEFAULT__ line: $_";
 231             die "$y_file: duplicate __DEFAULT__ line: $_"
 232                     if defined $default_token;
 233             $default_token = $1;
 234             next;
 235         }
 236
 237         next unless /^%(token|type)/;
 238         s/^%(token|type)\s+<(\w+)>\s+//
 239             or die "$y_file: unparseable token/type line: $_";
 240         $tokens{$_} = $2 for (split ' ', $_);
 241         $types{$2} = 1;
 242     }
 243     die "$y_file: no __DEFAULT__ token defined\n" unless $default_token;
 244     $types{$default_token} = 1;
 245
 246     $tablines =~ /^\Qstatic const char *const yytname[] =\E\n
 247             {\n
 248             (.*?)
 249             ^};
 250             /xsm
 251         or die "Can't extract yytname[] from table string\n";
 252     my $fields = $1;
 253     $fields =~ s{"([^"]+)"}
 254                 { "toketype_" .
 255                     (defined $tokens{$1} ? $tokens{$1} : $default_token)
 256                 }ge;
 257     $fields =~ s/, \s* 0 \s* $//x
 258         or die "make_type_tab: couldn't delete trailing ',0'\n";
 259
 260     return
 261           "\ntypedef enum {\n\t"
 262         . join(", ", map "toketype_$_", sort keys %types)
 263         . "\n} toketypes;\n\n"
 264         . "/* type of each token/terminal */\n"
 265         . "static const toketypes yy_type_tab[] =\n{\n"
 266         . $fields
 267         . "\n};\n";
 268 }
 269
 270
 271 sub my_system {
 272     system(@_);
 273     if ($? == -1) {
 274         die "failed to execute command '@_': $!\n";
 275     }
 276     elsif ($? & 127) {
 277         die sprintf "command '@_' died with signal %d\n",
 278             ($? & 127);
 279     }
 280     elsif ($? >> 8) {
 281         die sprintf "command '@_' exited with value %d\n", $? >> 8;
 282     }
 283 }