dist/ExtUtils-ParseXS/lib/ExtUtils/ParseXS.pm

   1 package ExtUtils::ParseXS;
   2 use strict;
   3
   4 use 5.006;  # We use /??{}/ in regexes
   5 use Cwd;
   6 use Config;
   7 use Exporter;
   8 use File::Basename;
   9 use File::Spec;
  10 use Symbol;
  11 use ExtUtils::ParseXS::Constants ();
  12 use ExtUtils::ParseXS::CountLines;
  13 use ExtUtils::ParseXS::Utilities qw(
  14   standard_typemap_locations
  15   trim_whitespace
  16   tidy_type
  17   C_string
  18   valid_proto_string
  19   process_typemaps
  20   make_targetable
  21   map_type
  22   standard_XS_defs
  23   assign_func_args
  24   analyze_preprocessor_statements
  25   set_cond
  26   Warn
  27   CurrentLineNumber
  28   blurt
  29   death
  30   check_conditional_preprocessor_statements
  31 );
  32
  33 our @ISA = qw(Exporter);
  34 our @EXPORT_OK = qw(
  35   process_file
  36   report_error_count
  37 );
  38 our $VERSION = '3';
  39 $VERSION = eval $VERSION if $VERSION =~ /_/;
  40
  41 # The scalars in the line below remain as 'our' variables because pulling
  42 # them into $self led to build problems.  In most cases, strings being
  43 # 'eval'-ed contain the variables' names hard-coded.
  44 our (
  45   $FH, $Package, $func_name, $Full_func_name, $pname, $ALIAS,
  46 );
  47
  48 our $self = bless {} => __PACKAGE__;
  49
  50 sub process_file {
  51
  52   # Allow for $package->process_file(%hash) in the future
  53   my ($pkg, %options) = @_ % 2 ? @_ : (__PACKAGE__, @_);
  54
  55   $self->{ProtoUsed} = exists $options{prototypes};
  56
  57   # Set defaults.
  58   my %args = (
  59     argtypes        => 1,
  60     csuffix         => '.c',
  61     except          => 0,
  62     hiertype        => 0,
  63     inout           => 1,
  64     linenumbers     => 1,
  65     optimize        => 1,
  66     output          => \*STDOUT,
  67     prototypes      => 0,
  68     typemap         => [],
  69     versioncheck    => 1,
  70     %options,
  71   );
  72   $args{except} = $args{except} ? ' TRY' : '';
  73
  74   # Global Constants
  75
  76   my ($Is_VMS, $SymSet);
  77   if ($^O eq 'VMS') {
  78     $Is_VMS = 1;
  79     # Establish set of global symbols with max length 28, since xsubpp
  80     # will later add the 'XS_' prefix.
  81     require ExtUtils::XSSymSet;
  82     $SymSet = ExtUtils::XSSymSet->new(28);
  83   }
  84   @{ $self->{XSStack} } = ({type => 'none'});
  85   $self->{InitFileCode} = [ @ExtUtils::ParseXS::Constants::InitFileCode ];
  86   $FH                   = $ExtUtils::ParseXS::Constants::FH;
  87   $self->{Overload}     = $ExtUtils::ParseXS::Constants::Overload;
  88   $self->{errors}       = $ExtUtils::ParseXS::Constants::errors;
  89   $self->{Fallback}     = $ExtUtils::ParseXS::Constants::Fallback;
  90
  91   # Most of the 1500 lines below uses these globals.  We'll have to
  92   # clean this up sometime, probably.  For now, we just pull them out
  93   # of %args.  -Ken
  94
  95   $self->{hiertype} = $args{hiertype};
  96   $self->{WantPrototypes} = $args{prototypes};
  97   $self->{WantVersionChk} = $args{versioncheck};
  98   $self->{WantLineNumbers} = $args{linenumbers};
  99   $self->{IncludedFiles} = {};
 100
 101   die "Missing required parameter 'filename'" unless $args{filename};
 102   $self->{filepathname} = $args{filename};
 103   ($self->{dir}, $self->{filename}) =
 104     (dirname($args{filename}), basename($args{filename}));
 105   $self->{filepathname} =~ s/\\/\\\\/g;
 106   $self->{IncludedFiles}->{$args{filename}}++;
 107
 108   # Open the output file if given as a string.  If they provide some
 109   # other kind of reference, trust them that we can print to it.
 110   if (not ref $args{output}) {
 111     open my($fh), "> $args{output}" or die "Can't create $args{output}: $!";
 112     $args{outfile} = $args{output};
 113     $args{output} = $fh;
 114   }
 115
 116   # Really, we shouldn't have to chdir() or select() in the first
 117   # place.  For now, just save and restore.
 118   my $orig_cwd = cwd();
 119   my $orig_fh = select();
 120
 121   chdir($self->{dir});
 122   my $pwd = cwd();
 123   my $csuffix = $args{csuffix};
 124
 125   if ($self->{WantLineNumbers}) {
 126     my $cfile;
 127     if ( $args{outfile} ) {
 128       $cfile = $args{outfile};
 129     }
 130     else {
 131       $cfile = $args{filename};
 132       $cfile =~ s/\.xs$/$csuffix/i or $cfile .= $csuffix;
 133     }
 134     tie(*PSEUDO_STDOUT, 'ExtUtils::ParseXS::CountLines', $cfile, $args{output});
 135     select PSEUDO_STDOUT;
 136   }
 137   else {
 138     select $args{output};
 139   }
 140
 141   $self->{typemap} = process_typemaps( $args{typemap}, $pwd );
 142
 143   my $END = "!End!\n\n";        # "impossible" keyword (multiple newline)
 144
 145   # Match an XS keyword
 146   $self->{BLOCK_re} = '\s*(' .
 147     join('|' => @ExtUtils::ParseXS::Constants::XSKeywords) .
 148     "|$END)\\s*:";
 149
 150   our ($C_group_rex, $C_arg);
 151   # Group in C (no support for comments or literals)
 152   $C_group_rex = qr/ [({\[]
 153                (?: (?> [^()\[\]{}]+ ) | (??{ $C_group_rex }) )*
 154                [)}\]] /x;
 155   # Chunk in C without comma at toplevel (no comments):
 156   $C_arg = qr/ (?: (?> [^()\[\]{},"']+ )
 157          |   (??{ $C_group_rex })
 158          |   " (?: (?> [^\\"]+ )
 159            |   \\.
 160            )* "        # String literal
 161                 |   ' (?: (?> [^\\']+ ) | \\. )* ' # Char literal
 162          )* /xs;
 163
 164   # Since at this point we're ready to begin printing to the output file and
 165   # reading from the input file, I want to get as much data as possible into
 166   # the proto-object $self.  That means assigning to $self and elements of
 167   # %args referenced below this point.
 168   # HOWEVER:  This resulted in an error when I tried:
 169   #   $args{'s'} ---> $self->{s}.
 170   # Use of uninitialized value in quotemeta at
 171   #   .../blib/lib/ExtUtils/ParseXS.pm line 733
 172
 173   foreach my $datum ( qw| argtypes except inout optimize | ) {
 174     $self->{$datum} = $args{$datum};
 175   }
 176
 177   # Identify the version of xsubpp used
 178   print <<EOM;
 179 /*
 180  * This file was generated automatically by ExtUtils::ParseXS version $VERSION from the
 181  * contents of $self->{filename}. Do not edit this file, edit $self->{filename} instead.
 182  *
 183  *    ANY CHANGES MADE HERE WILL BE LOST!
 184  *
 185  */
 186
 187 EOM
 188
 189
 190   print("#line 1 \"$self->{filepathname}\"\n")
 191     if $self->{WantLineNumbers};
 192
 193   # Open the input file (using $self->{filename} which
 194   # is a basename'd $args{filename} due to chdir above)
 195   open($FH, $self->{filename}) or die "cannot open $self->{filename}: $!\n";
 196
 197   firstmodule:
 198   while (<$FH>) {
 199     if (/^=/) {
 200       my $podstartline = $.;
 201       do {
 202         if (/^=cut\s*$/) {
 203           # We can't just write out a /* */ comment, as our embedded
 204           # POD might itself be in a comment. We can't put a /**/
 205           # comment inside #if 0, as the C standard says that the source
 206           # file is decomposed into preprocessing characters in the stage
 207           # before preprocessing commands are executed.
 208           # I don't want to leave the text as barewords, because the spec
 209           # isn't clear whether macros are expanded before or after
 210           # preprocessing commands are executed, and someone pathological
 211           # may just have defined one of the 3 words as a macro that does
 212           # something strange. Multiline strings are illegal in C, so
 213           # the "" we write must be a string literal. And they aren't
 214           # concatenated until 2 steps later, so we are safe.
 215           #     - Nicholas Clark
 216           print("#if 0\n  \"Skipped embedded POD.\"\n#endif\n");
 217           printf("#line %d \"$self->{filepathname}\"\n", $. + 1)
 218             if $self->{WantLineNumbers};
 219           next firstmodule
 220         }
 221
 222       } while (<$FH>);
 223       # At this point $. is at end of file so die won't state the start
 224       # of the problem, and as we haven't yet read any lines &death won't
 225       # show the correct line in the message either.
 226       die ("Error: Unterminated pod in $self->{filename}, line $podstartline\n")
 227         unless $self->{lastline};
 228     }
 229     last if ($Package, $self->{Prefix}) =
 230       /^MODULE\s*=\s*[\w:]+(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/;
 231
 232     print $_;
 233   }
 234   unless (defined $_) {
 235     warn "Didn't find a 'MODULE ... PACKAGE ... PREFIX' line\n";
 236     exit 0; # Not a fatal error for the caller process
 237   }
 238
 239   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
 240
 241   standard_XS_defs();
 242
 243   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
 244
 245   $self->{lastline}    = $_;
 246   $self->{lastline_no} = $.;
 247
 248   my $BootCode_ref = [];
 249   my $XSS_work_idx = 0;
 250   my $cpp_next_tmp = 'XSubPPtmpAAAA';
 251  PARAGRAPH:
 252   while ($self->fetch_para()) {
 253     my $outlist_ref  = [];
 254     # Print initial preprocessor statements and blank lines
 255     while (@{ $self->{line} } && $self->{line}->[0] !~ /^[^\#]/) {
 256       my $ln = shift(@{ $self->{line} });
 257       print $ln, "\n";
 258       next unless $ln =~ /^\#\s*((if)(?:n?def)?|elsif|else|endif)\b/;
 259       my $statement = $+;
 260       ( $self, $XSS_work_idx, $BootCode_ref ) =
 261         analyze_preprocessor_statements(
 262           $self, $statement, $XSS_work_idx, $BootCode_ref
 263         );
 264     }
 265
 266     next PARAGRAPH unless @{ $self->{line} };
 267
 268     if ($XSS_work_idx && !$self->{XSStack}->[$XSS_work_idx]{varname}) {
 269       # We are inside an #if, but have not yet #defined its xsubpp variable.
 270       print "#define $cpp_next_tmp 1\n\n";
 271       push(@{ $self->{InitFileCode} }, "#if $cpp_next_tmp\n");
 272       push(@{ $BootCode_ref },     "#if $cpp_next_tmp");
 273       $self->{XSStack}->[$XSS_work_idx]{varname} = $cpp_next_tmp++;
 274     }
 275
 276     $self->death(
 277       "Code is not inside a function"
 278         ." (maybe last function was ended by a blank line "
 279         ." followed by a statement on column one?)")
 280       if $self->{line}->[0] =~ /^\s/;
 281
 282     # initialize info arrays
 283     foreach my $member (qw(args_match var_types defaults arg_list
 284                            argtype_seen in_out lengthof))
 285     {
 286       $self->{$member} = {};
 287     }
 288     $self->{proto_arg} = [];
 289     $self->{processing_arg_with_types} = undef;
 290     $self->{proto_in_this_xsub}        = undef;
 291     $self->{scope_in_this_xsub}        = undef;
 292     $self->{interface}                 = undef;
 293     $self->{interface_macro}           = 'XSINTERFACE_FUNC';
 294     $self->{interface_macro_set}       = 'XSINTERFACE_FUNC_SET';
 295     $self->{ProtoThisXSUB}             = $self->{WantPrototypes};
 296     $self->{ScopeThisXSUB}             = 0;
 297
 298     my $xsreturn = 0;
 299
 300     $_ = shift(@{ $self->{line} });
 301     while (my $kwd = $self->check_keyword("REQUIRE|PROTOTYPES|FALLBACK|VERSIONCHECK|INCLUDE(?:_COMMAND)?|SCOPE")) {
 302       my $method = $kwd . "_handler";
 303       $self->$method($_);
 304       next PARAGRAPH unless @{ $self->{line} };
 305       $_ = shift(@{ $self->{line} });
 306     }
 307
 308     if ($self->check_keyword("BOOT")) {
 309       check_conditional_preprocessor_statements($self);
 310       push (@{ $BootCode_ref }, "#line $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} }] \"$self->{filepathname}\"")
 311         if $self->{WantLineNumbers} && $self->{line}->[0] !~ /^\s*#\s*line\b/;
 312       push (@{ $BootCode_ref }, @{ $self->{line} }, "");
 313       next PARAGRAPH;
 314     }
 315
 316     # extract return type, function name and arguments
 317     ($self->{ret_type}) = tidy_type($_);
 318     my $RETVAL_no_return = 1 if $self->{ret_type} =~ s/^NO_OUTPUT\s+//;
 319
 320     # Allow one-line ANSI-like declaration
 321     unshift @{ $self->{line} }, $2
 322       if $self->{argtypes}
 323         and $self->{ret_type} =~ s/^(.*?\w.*?)\s*\b(\w+\s*\(.*)/$1/s;
 324
 325     # a function definition needs at least 2 lines
 326     $self->blurt("Error: Function definition too short '$self->{ret_type}'"), next PARAGRAPH
 327       unless @{ $self->{line} };
 328
 329     my $externC = 1 if $self->{ret_type} =~ s/^extern "C"\s+//;
 330     my $static  = 1 if $self->{ret_type} =~ s/^static\s+//;
 331
 332     my $func_header = shift(@{ $self->{line} });
 333     $self->blurt("Error: Cannot parse function definition from '$func_header'"), next PARAGRAPH
 334       unless $func_header =~ /^(?:([\w:]*)::)?(\w+)\s*\(\s*(.*?)\s*\)\s*(const)?\s*(;\s*)?$/s;
 335
 336     my ($class, $orig_args);
 337     ($class, $func_name, $orig_args) =  ($1, $2, $3);
 338     $class = "$4 $class" if $4;
 339     ($pname = $func_name) =~ s/^($self->{Prefix})?/$self->{Packprefix}/;
 340     my $clean_func_name;
 341     ($clean_func_name = $func_name) =~ s/^$self->{Prefix}//;
 342     $Full_func_name = "$self->{Packid}_$clean_func_name";
 343     if ($Is_VMS) {
 344       $Full_func_name = $SymSet->addsym($Full_func_name);
 345     }
 346
 347     # Check for duplicate function definition
 348     for my $tmp (@{ $self->{XSStack} }) {
 349       next unless defined $tmp->{functions}{$Full_func_name};
 350       Warn( $self, "Warning: duplicate function definition '$clean_func_name' detected");
 351       last;
 352     }
 353     $self->{XSStack}->[$XSS_work_idx]{functions}{$Full_func_name}++;
 354     %{ $self->{XsubAliases} }     = ();
 355     %{ $self->{XsubAliasValues} } = ();
 356     %{ $self->{Interfaces} }      = ();
 357     @{ $self->{Attributes} }      = ();
 358     $self->{DoSetMagic} = 1;
 359
 360     $orig_args =~ s/\\\s*/ /g;    # process line continuations
 361     my @args;
 362
 363     my (@fake_INPUT_pre);    # For length(s) generated variables
 364     my (@fake_INPUT);
 365     my $only_C_inlist_ref = {};        # Not in the signature of Perl function
 366     if ($self->{argtypes} and $orig_args =~ /\S/) {
 367       my $args = "$orig_args ,";
 368       if ($args =~ /^( (??{ $C_arg }) , )* $ /x) {
 369         @args = ($args =~ /\G ( (??{ $C_arg }) ) , /xg);
 370         for ( @args ) {
 371           s/^\s+//;
 372           s/\s+$//;
 373           my ($arg, $default) = ($_ =~ m/ ( [^=]* ) ( (?: = .* )? ) /x);
 374           my ($pre, $len_name) = ($arg =~ /(.*?) \s*
 375                              \b ( \w+ | length\( \s*\w+\s* \) )
 376                              \s* $ /x);
 377           next unless defined($pre) && length($pre);
 378           my $out_type = '';
 379           my $inout_var;
 380           if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//) {
 381             my $type = $1;
 382             $out_type = $type if $type ne 'IN';
 383             $arg =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
 384             $pre =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
 385           }
 386           my $islength;
 387           if ($len_name =~ /^length\( \s* (\w+) \s* \)\z/x) {
 388             $len_name = "XSauto_length_of_$1";
 389             $islength = 1;
 390             die "Default value on length() argument: `$_'"
 391               if length $default;
 392           }
 393           if (length $pre or $islength) { # Has a type
 394             if ($islength) {
 395               push @fake_INPUT_pre, $arg;
 396             }
 397             else {
 398               push @fake_INPUT, $arg;
 399             }
 400             # warn "pushing '$arg'\n";
 401             $self->{argtype_seen}->{$len_name}++;
 402             $_ = "$len_name$default"; # Assigns to @args
 403           }
 404           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST" or $islength;
 405           push @{ $outlist_ref }, $len_name if $out_type =~ /OUTLIST$/;
 406           $self->{in_out}->{$len_name} = $out_type if $out_type;
 407         }
 408       }
 409       else {
 410         @args = split(/\s*,\s*/, $orig_args);
 411         Warn( $self, "Warning: cannot parse argument list '$orig_args', fallback to split");
 412       }
 413     }
 414     else {
 415       @args = split(/\s*,\s*/, $orig_args);
 416       for (@args) {
 417         if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|IN_OUT|OUT)\b\s*//) {
 418           my $out_type = $1;
 419           next if $out_type eq 'IN';
 420           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST";
 421           if ($out_type =~ /OUTLIST$/) {
 422               push @{ $outlist_ref }, undef;
 423           }
 424           $self->{in_out}->{$_} = $out_type;
 425         }
 426       }
 427     }
 428     if (defined($class)) {
 429       my $arg0 = ((defined($static) or $func_name eq 'new')
 430           ? "CLASS" : "THIS");
 431       unshift(@args, $arg0);
 432     }
 433     my $extra_args = 0;
 434     my @args_num = ();
 435     my $num_args = 0;
 436     my $report_args = '';
 437     my $ellipsis;
 438     foreach my $i (0 .. $#args) {
 439       if ($args[$i] =~ s/\.\.\.//) {
 440         $ellipsis = 1;
 441         if ($args[$i] eq '' && $i == $#args) {
 442           $report_args .= ", ...";
 443           pop(@args);
 444           last;
 445         }
 446       }
 447       if ($only_C_inlist_ref->{$args[$i]}) {
 448         push @args_num, undef;
 449       }
 450       else {
 451         push @args_num, ++$num_args;
 452           $report_args .= ", $args[$i]";
 453       }
 454       if ($args[$i] =~ /^([^=]*[^\s=])\s*=\s*(.*)/s) {
 455         $extra_args++;
 456         $args[$i] = $1;
 457         $self->{defaults}->{$args[$i]} = $2;
 458         $self->{defaults}->{$args[$i]} =~ s/"/\\"/g;
 459       }
 460       $self->{proto_arg}->[$i+1] = '$';
 461     }
 462     my $min_args = $num_args - $extra_args;
 463     $report_args =~ s/"/\\"/g;
 464     $report_args =~ s/^,\s+//;
 465     $self->{func_args} = assign_func_args($self, \@args, $class);
 466     @{ $self->{args_match} }{@args} = @args_num;
 467
 468     my $PPCODE = grep(/^\s*PPCODE\s*:/, @{ $self->{line} });
 469     my $CODE = grep(/^\s*CODE\s*:/, @{ $self->{line} });
 470     # Detect CODE: blocks which use ST(n)= or XST_m*(n,v)
 471     # to set explicit return values.
 472     my $EXPLICIT_RETURN = ($CODE &&
 473             ("@{ $self->{line} }" =~ /(\bST\s*\([^;]*=) | (\bXST_m\w+\s*\()/x ));
 474
 475     # The $ALIAS which follows is only explicitly called within the scope of
 476     # process_file().  In principle, it ought to be a lexical, i.e., 'my
 477     # $ALIAS' like the other nearby variables.  However, implementing that
 478     # change produced a slight difference in the resulting .c output in at
 479     # least two distributions:  B/BD/BDFOY/Crypt-Rijndael and
 480     # G/GF/GFUJI/Hash-FieldHash.  The difference is, arguably, an improvement
 481     # in the resulting C code.  Example:
 482     # 388c388
 483     # <                       GvNAME(CvGV(cv)),
 484     # ---
 485     # >                       "Crypt::Rijndael::encrypt",
 486     # But at this point we're committed to generating the *same* C code that
 487     # the current version of ParseXS.pm does.  So we're declaring it as 'our'.
 488     $ALIAS  = grep(/^\s*ALIAS\s*:/,  @{ $self->{line} });
 489
 490     my $INTERFACE  = grep(/^\s*INTERFACE\s*:/,  @{ $self->{line} });
 491
 492     $xsreturn = 1 if $EXPLICIT_RETURN;
 493
 494     $externC = $externC ? qq[extern "C"] : "";
 495
 496     # print function header
 497     print Q(<<"EOF");
 498 #$externC
 499 #XS(XS_${Full_func_name}); /* prototype to pass -Wmissing-prototypes */
 500 #XS(XS_${Full_func_name})
 501 #[[
 502 ##ifdef dVAR
 503 #    dVAR; dXSARGS;
 504 ##else
 505 #    dXSARGS;
 506 ##endif
 507 EOF
 508     print Q(<<"EOF") if $ALIAS;
 509 #    dXSI32;
 510 EOF
 511     print Q(<<"EOF") if $INTERFACE;
 512 #    dXSFUNCTION($self->{ret_type});
 513 EOF
 514
 515     $self->{cond} = set_cond($ellipsis, $min_args, $num_args);
 516
 517     print Q(<<"EOF") if $self->{except};
 518 #    char errbuf[1024];
 519 #    *errbuf = '\0';
 520 EOF
 521
 522     if($self->{cond}) {
 523       print Q(<<"EOF");
 524 #    if ($self->{cond})
 525 #       croak_xs_usage(cv,  "$report_args");
 526 EOF
 527     }
 528     else {
 529     # cv likely to be unused
 530     print Q(<<"EOF");
 531 #    PERL_UNUSED_VAR(cv); /* -W */
 532 EOF
 533     }
 534
 535     #gcc -Wall: if an xsub has PPCODE is used
 536     #it is possible none of ST, XSRETURN or XSprePUSH macros are used
 537     #hence `ax' (setup by dXSARGS) is unused
 538     #XXX: could breakup the dXSARGS; into dSP;dMARK;dITEMS
 539     #but such a move could break third-party extensions
 540     print Q(<<"EOF") if $PPCODE;
 541 #    PERL_UNUSED_VAR(ax); /* -Wall */
 542 EOF
 543
 544     print Q(<<"EOF") if $PPCODE;
 545 #    SP -= items;
 546 EOF
 547
 548     # Now do a block of some sort.
 549
 550     $self->{condnum} = 0;
 551     $self->{cond} = '';            # last CASE: conditional
 552     push(@{ $self->{line} }, "$END:");
 553     push(@{ $self->{line_no} }, $self->{line_no}->[-1]);
 554     $_ = '';
 555     check_conditional_preprocessor_statements();
 556     while (@{ $self->{line} }) {
 557       $self->CASE_handler($_) if $self->check_keyword("CASE");
 558       print Q(<<"EOF");
 559 #   $self->{except} [[
 560 EOF
 561
 562       # do initialization of input variables
 563       $self->{thisdone} = 0;
 564       $self->{retvaldone} = 0;
 565       $self->{deferred} = "";
 566       %{ $self->{arg_list} } = ();
 567       $self->{gotRETVAL} = 0;
 568
 569       $self->INPUT_handler($_);
 570       $self->process_keyword("INPUT|PREINIT|INTERFACE_MACRO|C_ARGS|ALIAS|ATTRS|PROTOTYPE|SCOPE|OVERLOAD");
 571
 572       print Q(<<"EOF") if $self->{ScopeThisXSUB};
 573 #   ENTER;
 574 #   [[
 575 EOF
 576
 577       if (!$self->{thisdone} && defined($class)) {
 578         if (defined($static) or $func_name eq 'new') {
 579           print "\tchar *";
 580           $self->{var_types}->{"CLASS"} = "char *";
 581           generate_init( {
 582             type          => "char *",
 583             num           => 1,
 584             var           => "CLASS",
 585             printed_name  => undef,
 586           } );
 587         }
 588         else {
 589           print "\t$class *";
 590           $self->{var_types}->{"THIS"} = "$class *";
 591           generate_init( {
 592             type          => "$class *",
 593             num           => 1,
 594             var           => "THIS",
 595             printed_name  => undef,
 596           } );
 597         }
 598       }
 599
 600       my ($wantRETVAL);
 601       # do code
 602       if (/^\s*NOT_IMPLEMENTED_YET/) {
 603         print "\n\tPerl_croak(aTHX_ \"$pname: not implemented yet\");\n";
 604         $_ = '';
 605       }
 606       else {
 607         if ($self->{ret_type} ne "void") {
 608           print "\t" . map_type($self, $self->{ret_type}, 'RETVAL') . ";\n"
 609             if !$self->{retvaldone};
 610           $self->{args_match}->{"RETVAL"} = 0;
 611           $self->{var_types}->{"RETVAL"} = $self->{ret_type};
 612           my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
 613           print "\tdXSTARG;\n"
 614             if $self->{optimize} and $outputmap and $outputmap->targetable;
 615         }
 616
 617         if (@fake_INPUT or @fake_INPUT_pre) {
 618           unshift @{ $self->{line} }, @fake_INPUT_pre, @fake_INPUT, $_;
 619           $_ = "";
 620           $self->{processing_arg_with_types} = 1;
 621           $self->INPUT_handler($_);
 622         }
 623         print $self->{deferred};
 624
 625         $self->process_keyword("INIT|ALIAS|ATTRS|PROTOTYPE|INTERFACE_MACRO|INTERFACE|C_ARGS|OVERLOAD");
 626
 627         if ($self->check_keyword("PPCODE")) {
 628           $self->print_section();
 629           $self->death("PPCODE must be last thing") if @{ $self->{line} };
 630           print "\tLEAVE;\n" if $self->{ScopeThisXSUB};
 631           print "\tPUTBACK;\n\treturn;\n";
 632         }
 633         elsif ($self->check_keyword("CODE")) {
 634           $self->print_section();
 635         }
 636         elsif (defined($class) and $func_name eq "DESTROY") {
 637           print "\n\t";
 638           print "delete THIS;\n";
 639         }
 640         else {
 641           print "\n\t";
 642           if ($self->{ret_type} ne "void") {
 643             print "RETVAL = ";
 644             $wantRETVAL = 1;
 645           }
 646           if (defined($static)) {
 647             if ($func_name eq 'new') {
 648               $func_name = "$class";
 649             }
 650             else {
 651               print "${class}::";
 652             }
 653           }
 654           elsif (defined($class)) {
 655             if ($func_name eq 'new') {
 656               $func_name .= " $class";
 657             }
 658             else {
 659               print "THIS->";
 660             }
 661           }
 662           $func_name =~ s/^\Q$args{'s'}//
 663             if exists $args{'s'};
 664           $func_name = 'XSFUNCTION' if $self->{interface};
 665           print "$func_name($self->{func_args});\n";
 666         }
 667       }
 668
 669       # do output variables
 670       $self->{gotRETVAL} = 0;        # 1 if RETVAL seen in OUTPUT section;
 671       undef $self->{RETVAL_code} ;    # code to set RETVAL (from OUTPUT section);
 672       # $wantRETVAL set if 'RETVAL =' autogenerated
 673       ($wantRETVAL, $self->{ret_type}) = (0, 'void') if $RETVAL_no_return;
 674       undef %{ $self->{outargs} };
 675       $self->process_keyword("POSTCALL|OUTPUT|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
 676
 677       generate_output( {
 678         type        => $self->{var_types}->{$_},
 679         num         => $self->{args_match}->{$_},
 680         var         => $_,
 681         do_setmagic => $self->{DoSetMagic},
 682         do_push     => undef,
 683       } ) for grep $self->{in_out}->{$_} =~ /OUT$/, keys %{ $self->{in_out} };
 684
 685       my $prepush_done;
 686       # all OUTPUT done, so now push the return value on the stack
 687       if ($self->{gotRETVAL} && $self->{RETVAL_code}) {
 688         print "\t$self->{RETVAL_code}\n";
 689       }
 690       elsif ($self->{gotRETVAL} || $wantRETVAL) {
 691         my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
 692         my $t = $self->{optimize} && $outputmap && $outputmap->targetable;
 693         # Although the '$var' declared in the next line is never explicitly
 694         # used within this 'elsif' block, commenting it out leads to
 695         # disaster, starting with the first 'eval qq' inside the 'elsif' block
 696         # below.
 697         # It appears that this is related to the fact that at this point the
 698         # value of $t is a reference to an array whose [2] element includes
 699         # '$var' as a substring:
 700         # <i> <> <(IV)$var>
 701         my $var = 'RETVAL';
 702         my $type = $self->{ret_type};
 703
 704         if ($t and not $t->{with_size} and $t->{type} eq 'p') {
 705           # PUSHp corresponds to setpvn.  Treat setpv directly
 706           my $what = eval qq("$t->{what}");
 707           warn $@ if $@;
 708
 709           print "\tsv_setpv(TARG, $what); XSprePUSH; PUSHTARG;\n";
 710           $prepush_done = 1;
 711         }
 712         elsif ($t) {
 713           my $what = eval qq("$t->{what}");
 714           warn $@ if $@;
 715
 716           my $tsize = $t->{what_size};
 717           $tsize = '' unless defined $tsize;
 718           $tsize = eval qq("$tsize");
 719           warn $@ if $@;
 720           print "\tXSprePUSH; PUSH$t->{type}($what$tsize);\n";
 721           $prepush_done = 1;
 722         }
 723         else {
 724           # RETVAL almost never needs SvSETMAGIC()
 725           generate_output( {
 726             type        => $self->{ret_type},
 727             num         => 0,
 728             var         => 'RETVAL',
 729             do_setmagic => 0,
 730             do_push     => undef,
 731           } );
 732         }
 733       }
 734
 735       $xsreturn = 1 if $self->{ret_type} ne "void";
 736       my $num = $xsreturn;
 737       my $c = @{ $outlist_ref };
 738       print "\tXSprePUSH;" if $c and not $prepush_done;
 739       print "\tEXTEND(SP,$c);\n" if $c;
 740       $xsreturn += $c;
 741       generate_output( {
 742         type        => $self->{var_types}->{$_},
 743         num         => $num++,
 744         var         => $_,
 745         do_setmagic => 0,
 746         do_push     => 1,
 747       } ) for @{ $outlist_ref };
 748
 749       # do cleanup
 750       $self->process_keyword("CLEANUP|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
 751
 752       print Q(<<"EOF") if $self->{ScopeThisXSUB};
 753 #   ]]
 754 EOF
 755       print Q(<<"EOF") if $self->{ScopeThisXSUB} and not $PPCODE;
 756 #   LEAVE;
 757 EOF
 758
 759       # print function trailer
 760       print Q(<<"EOF");
 761 #    ]]
 762 EOF
 763       print Q(<<"EOF") if $self->{except};
 764 #    BEGHANDLERS
 765 #    CATCHALL
 766 #    sprintf(errbuf, "%s: %s\\tpropagated", Xname, Xreason);
 767 #    ENDHANDLERS
 768 EOF
 769       if ($self->check_keyword("CASE")) {
 770         $self->blurt("Error: No `CASE:' at top of function")
 771           unless $self->{condnum};
 772         $_ = "CASE: $_";    # Restore CASE: label
 773         next;
 774       }
 775       last if $_ eq "$END:";
 776       $self->death(/^$self->{BLOCK_re}/o ? "Misplaced `$1:'" : "Junk at end of function ($_)");
 777     }
 778
 779     print Q(<<"EOF") if $self->{except};
 780 #    if (errbuf[0])
 781 #    Perl_croak(aTHX_ errbuf);
 782 EOF
 783
 784     if ($xsreturn) {
 785       print Q(<<"EOF") unless $PPCODE;
 786 #    XSRETURN($xsreturn);
 787 EOF
 788     }
 789     else {
 790       print Q(<<"EOF") unless $PPCODE;
 791 #    XSRETURN_EMPTY;
 792 EOF
 793     }
 794
 795     print Q(<<"EOF");
 796 #]]
 797 #
 798 EOF
 799
 800     $self->{newXS} = "newXS";
 801     $self->{proto} = "";
 802
 803     # Build the prototype string for the xsub
 804     if ($self->{ProtoThisXSUB}) {
 805       $self->{newXS} = "newXSproto_portable";
 806
 807       if ($self->{ProtoThisXSUB} eq 2) {
 808         # User has specified empty prototype
 809       }
 810       elsif ($self->{ProtoThisXSUB} eq 1) {
 811         my $s = ';';
 812         if ($min_args < $num_args)  {
 813           $s = '';
 814           $self->{proto_arg}->[$min_args] .= ";";
 815         }
 816         push @{ $self->{proto_arg} }, "$s\@"
 817           if $ellipsis;
 818
 819         $self->{proto} = join ("", grep defined, @{ $self->{proto_arg} } );
 820       }
 821       else {
 822         # User has specified a prototype
 823         $self->{proto} = $self->{ProtoThisXSUB};
 824       }
 825       $self->{proto} = qq{, "$self->{proto}"};
 826     }
 827
 828     if (%{ $self->{XsubAliases} }) {
 829       $self->{XsubAliases}->{$pname} = 0
 830         unless defined $self->{XsubAliases}->{$pname};
 831       while ( my ($xname, $value) = each %{ $self->{XsubAliases} }) {
 832         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
 833 #        cv = $self->{newXS}(\"$xname\", XS_$Full_func_name, file$self->{proto});
 834 #        XSANY.any_i32 = $value;
 835 EOF
 836       }
 837     }
 838     elsif (@{ $self->{Attributes} }) {
 839       push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
 840 #        cv = $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});
 841 #        apply_attrs_string("$Package", cv, "@{ $self->{Attributes} }", 0);
 842 EOF
 843     }
 844     elsif ($self->{interface}) {
 845       while ( my ($yname, $value) = each %{ $self->{Interfaces} }) {
 846         $yname = "$Package\::$yname" unless $yname =~ /::/;
 847         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
 848 #        cv = $self->{newXS}(\"$yname\", XS_$Full_func_name, file$self->{proto});
 849 #        $self->{interface_macro_set}(cv,$value);
 850 EOF
 851       }
 852     }
 853     elsif($self->{newXS} eq 'newXS'){ # work around P5NCI's empty newXS macro
 854       push(@{ $self->{InitFileCode} },
 855        "        $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
 856     }
 857     else {
 858       push(@{ $self->{InitFileCode} },
 859        "        (void)$self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
 860     }
 861   } # END 'PARAGRAPH' 'while' loop
 862
 863   if ($self->{Overload}) { # make it findable with fetchmethod
 864     print Q(<<"EOF");
 865 #XS(XS_$self->{Packid}_nil); /* prototype to pass -Wmissing-prototypes */
 866 #XS(XS_$self->{Packid}_nil)
 867 #{
 868 #   dXSARGS;
 869 #   XSRETURN_EMPTY;
 870 #}
 871 #
 872 EOF
 873     unshift(@{ $self->{InitFileCode} }, <<"MAKE_FETCHMETHOD_WORK");
 874     /* Making a sub named "${Package}::()" allows the package */
 875     /* to be findable via fetchmethod(), and causes */
 876     /* overload::Overloaded("${Package}") to return true. */
 877     (void)$self->{newXS}("${Package}::()", XS_$self->{Packid}_nil, file$self->{proto});
 878 MAKE_FETCHMETHOD_WORK
 879   }
 880
 881   # print initialization routine
 882
 883   print Q(<<"EOF");
 884 ##ifdef __cplusplus
 885 #extern "C"
 886 ##endif
 887 EOF
 888
 889   print Q(<<"EOF");
 890 #XS(boot_$self->{Module_cname}); /* prototype to pass -Wmissing-prototypes */
 891 #XS(boot_$self->{Module_cname})
 892 EOF
 893
 894   print Q(<<"EOF");
 895 #[[
 896 ##ifdef dVAR
 897 #    dVAR; dXSARGS;
 898 ##else
 899 #    dXSARGS;
 900 ##endif
 901 EOF
 902
 903   #Under 5.8.x and lower, newXS is declared in proto.h as expecting a non-const
 904   #file name argument. If the wrong qualifier is used, it causes breakage with
 905   #C++ compilers and warnings with recent gcc.
 906   #-Wall: if there is no $Full_func_name there are no xsubs in this .xs
 907   #so `file' is unused
 908   print Q(<<"EOF") if $Full_func_name;
 909 ##if (PERL_REVISION == 5 && PERL_VERSION < 9)
 910 #    char* file = __FILE__;
 911 ##else
 912 #    const char* file = __FILE__;
 913 ##endif
 914 EOF
 915
 916   print Q("#\n");
 917
 918   print Q(<<"EOF");
 919 #    PERL_UNUSED_VAR(cv); /* -W */
 920 #    PERL_UNUSED_VAR(items); /* -W */
 921 ##ifdef XS_APIVERSION_BOOTCHECK
 922 #    XS_APIVERSION_BOOTCHECK;
 923 ##endif
 924 EOF
 925
 926   print Q(<<"EOF") if $self->{WantVersionChk};
 927 #    XS_VERSION_BOOTCHECK;
 928 #
 929 EOF
 930
 931   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
 932 #    {
 933 #        CV * cv;
 934 #
 935 EOF
 936
 937   print Q(<<"EOF") if ($self->{Overload});
 938 #    /* register the overloading (type 'A') magic */
 939 #    PL_amagic_generation++;
 940 #    /* The magic for overload gets a GV* via gv_fetchmeth as */
 941 #    /* mentioned above, and looks in the SV* slot of it for */
 942 #    /* the "fallback" status. */
 943 #    sv_setsv(
 944 #        get_sv( "${Package}::()", TRUE ),
 945 #        $self->{Fallback}
 946 #    );
 947 EOF
 948
 949   print @{ $self->{InitFileCode} };
 950
 951   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
 952 #    }
 953 EOF
 954
 955   if (@{ $BootCode_ref }) {
 956     print "\n    /* Initialisation Section */\n\n";
 957     @{ $self->{line} } = @{ $BootCode_ref };
 958     $self->print_section();
 959     print "\n    /* End of Initialisation Section */\n\n";
 960   }
 961
 962   print Q(<<'EOF');
 963 ##if (PERL_REVISION == 5 && PERL_VERSION >= 9)
 964 #  if (PL_unitcheckav)
 965 #       call_list(PL_scopestack_ix, PL_unitcheckav);
 966 ##endif
 967 EOF
 968
 969   print Q(<<"EOF");
 970 #    XSRETURN_YES;
 971 #]]
 972 #
 973 EOF
 974
 975   warn("Please specify prototyping behavior for $self->{filename} (see perlxs manual)\n")
 976     unless $self->{ProtoUsed};
 977
 978   chdir($orig_cwd);
 979   select($orig_fh);
 980   untie *PSEUDO_STDOUT if tied *PSEUDO_STDOUT;
 981   close $FH;
 982
 983   return 1;
 984 }
 985
 986 sub report_error_count { $self->{errors} }
 987
 988 # Input:  ($self, $_, @{ $self->{line} }) == unparsed input.
 989 # Output: ($_, @{ $self->{line} }) == (rest of line, following lines).
 990 # Return: the matched keyword if found, otherwise 0
 991 sub check_keyword {
 992   my $self = shift;
 993   $_ = shift(@{ $self->{line} }) while !/\S/ && @{ $self->{line} };
 994   s/^(\s*)($_[0])\s*:\s*(?:#.*)?/$1/s && $2;
 995 }
 996
 997 sub print_section {
 998   my $self = shift;
 999
1000   # the "do" is required for right semantics
1001   do { $_ = shift(@{ $self->{line} }) } while !/\S/ && @{ $self->{line} };
1002
1003   print("#line ", $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} } -1], " \"$self->{filepathname}\"\n")
1004     if $self->{WantLineNumbers} && !/^\s*#\s*line\b/ && !/^#if XSubPPtmp/;
1005   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1006     print "$_\n";
1007   }
1008   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
1009 }
1010
1011 sub merge_section {
1012   my $self = shift;
1013   my $in = '';
1014
1015   while (!/\S/ && @{ $self->{line} }) {
1016     $_ = shift(@{ $self->{line} });
1017   }
1018
1019   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1020     $in .= "$_\n";
1021   }
1022   chomp $in;
1023   return $in;
1024 }
1025
1026 sub process_keyword {
1027   my($self, $pattern) = @_;
1028
1029   while (my $kwd = $self->check_keyword($pattern)) {
1030     my $method = $kwd . "_handler";
1031     $self->$method($_);
1032   }
1033 }
1034
1035 sub CASE_handler {
1036   my $self = shift;
1037   $_ = shift;
1038   $self->blurt("Error: `CASE:' after unconditional `CASE:'")
1039     if $self->{condnum} && $self->{cond} eq '';
1040   $self->{cond} = $_;
1041   trim_whitespace($self->{cond});
1042   print "   ", ($self->{condnum}++ ? " else" : ""), ($self->{cond} ? " if ($self->{cond})\n" : "\n");
1043   $_ = '';
1044 }
1045
1046 sub INPUT_handler {
1047   my $self = shift;
1048   $_ = shift;
1049   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1050     last if /^\s*NOT_IMPLEMENTED_YET/;
1051     next unless /\S/;        # skip blank lines
1052
1053     trim_whitespace($_);
1054     my $ln = $_;
1055
1056     # remove trailing semicolon if no initialisation
1057     s/\s*;$//g unless /[=;+].*\S/;
1058
1059     # Process the length(foo) declarations
1060     if (s/^([^=]*)\blength\(\s*(\w+)\s*\)\s*$/$1 XSauto_length_of_$2=NO_INIT/x) {
1061       print "\tSTRLEN\tSTRLEN_length_of_$2;\n";
1062       $self->{lengthof}->{$2} = undef;
1063       $self->{deferred} .= "\n\tXSauto_length_of_$2 = STRLEN_length_of_$2;\n";
1064     }
1065
1066     # check for optional initialisation code
1067     my $var_init = '';
1068     $var_init = $1 if s/\s*([=;+].*)$//s;
1069     $var_init =~ s/"/\\"/g;
1070
1071     s/\s+/ /g;
1072     my ($var_type, $var_addr, $var_name) = /^(.*?[^&\s])\s*(\&?)\s*\b(\w+)$/s
1073       or $self->blurt("Error: invalid argument declaration '$ln'"), next;
1074
1075     # Check for duplicate definitions
1076     $self->blurt("Error: duplicate definition of argument '$var_name' ignored"), next
1077       if $self->{arg_list}->{$var_name}++
1078         or defined $self->{argtype_seen}->{$var_name} and not $self->{processing_arg_with_types};
1079
1080     $self->{thisdone} |= $var_name eq "THIS";
1081     $self->{retvaldone} |= $var_name eq "RETVAL";
1082     $self->{var_types}->{$var_name} = $var_type;
1083     # XXXX This check is a safeguard against the unfinished conversion of
1084     # generate_init().  When generate_init() is fixed,
1085     # one can use 2-args map_type() unconditionally.
1086     my $printed_name;
1087     if ($var_type =~ / \( \s* \* \s* \) /x) {
1088       # Function pointers are not yet supported with output_init()!
1089       print "\t" . map_type($self, $var_type, $var_name);
1090       $printed_name = 1;
1091     }
1092     else {
1093       print "\t" . map_type($self, $var_type, undef);
1094       $printed_name = 0;
1095     }
1096     $self->{var_num} = $self->{args_match}->{$var_name};
1097
1098     if ($self->{var_num}) {
1099       my $typemap = $self->{typemap}->get_typemap(ctype => $var_type);
1100       $self->death("Could not find a typemap for C type '$var_type'")
1101         if not $typemap;
1102       $self->{proto_arg}->[$self->{var_num}] = ($typemap && $typemap->proto) || "\$";
1103     }
1104     $self->{func_args} =~ s/\b($var_name)\b/&$1/ if $var_addr;
1105     if ($var_init =~ /^[=;]\s*NO_INIT\s*;?\s*$/
1106       or $self->{in_out}->{$var_name} and $self->{in_out}->{$var_name} =~ /^OUT/
1107       and $var_init !~ /\S/) {
1108       if ($printed_name) {
1109         print ";\n";
1110       }
1111       else {
1112         print "\t$var_name;\n";
1113       }
1114     }
1115     elsif ($var_init =~ /\S/) {
1116       output_init( {
1117         type          => $var_type,
1118         num           => $self->{var_num},
1119         var           => $var_name,
1120         init          => $var_init,
1121         printed_name  => $printed_name,
1122       } );
1123     }
1124     elsif ($self->{var_num}) {
1125       generate_init( {
1126         type          => $var_type,
1127         num           => $self->{var_num},
1128         var           => $var_name,
1129         printed_name  => $printed_name,
1130       } );
1131     }
1132     else {
1133       print ";\n";
1134     }
1135   }
1136 }
1137
1138 sub OUTPUT_handler {
1139   my $self = shift;
1140   $_ = shift;
1141   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1142     next unless /\S/;
1143     if (/^\s*SETMAGIC\s*:\s*(ENABLE|DISABLE)\s*/) {
1144       $self->{DoSetMagic} = ($1 eq "ENABLE" ? 1 : 0);
1145       next;
1146     }
1147     my ($outarg, $outcode) = /^\s*(\S+)\s*(.*?)\s*$/s;
1148     $self->blurt("Error: duplicate OUTPUT argument '$outarg' ignored"), next
1149       if $self->{outargs}->{$outarg}++;
1150     if (!$self->{gotRETVAL} and $outarg eq 'RETVAL') {
1151       # deal with RETVAL last
1152       $self->{RETVAL_code} = $outcode;
1153       $self->{gotRETVAL} = 1;
1154       next;
1155     }
1156     $self->blurt("Error: OUTPUT $outarg not an argument"), next
1157       unless defined($self->{args_match}->{$outarg});
1158     $self->blurt("Error: No input definition for OUTPUT argument '$outarg' - ignored"), next
1159       unless defined $self->{var_types}->{$outarg};
1160     $self->{var_num} = $self->{args_match}->{$outarg};
1161     if ($outcode) {
1162       print "\t$outcode\n";
1163       print "\tSvSETMAGIC(ST(" , $self->{var_num} - 1 , "));\n" if $self->{DoSetMagic};
1164     }
1165     else {
1166       generate_output( {
1167         type        => $self->{var_types}->{$outarg},
1168         num         => $self->{var_num},
1169         var         => $outarg,
1170         do_setmagic => $self->{DoSetMagic},
1171         do_push     => undef,
1172       } );
1173     }
1174     delete $self->{in_out}->{$outarg}     # No need to auto-OUTPUT
1175       if exists $self->{in_out}->{$outarg} and $self->{in_out}->{$outarg} =~ /OUT$/;
1176   }
1177 }
1178
1179 sub C_ARGS_handler {
1180   my $self = shift;
1181   $_ = shift;
1182   my $in = $self->merge_section();
1183
1184   trim_whitespace($in);
1185   $self->{func_args} = $in;
1186 }
1187
1188 sub INTERFACE_MACRO_handler {
1189   my $self = shift;
1190   $_ = shift;
1191   my $in = $self->merge_section();
1192
1193   trim_whitespace($in);
1194   if ($in =~ /\s/) {        # two
1195     ($self->{interface_macro}, $self->{interface_macro_set}) = split ' ', $in;
1196   }
1197   else {
1198     $self->{interface_macro} = $in;
1199     $self->{interface_macro_set} = 'UNKNOWN_CVT'; # catch later
1200   }
1201   $self->{interface} = 1;        # local
1202   $self->{interfaces} = 1;        # global
1203 }
1204
1205 sub INTERFACE_handler {
1206   my $self = shift;
1207   $_ = shift;
1208   my $in = $self->merge_section();
1209
1210   trim_whitespace($in);
1211
1212   foreach (split /[\s,]+/, $in) {
1213     my $iface_name = $_;
1214     $iface_name =~ s/^$self->{Prefix}//;
1215     $self->{Interfaces}->{$iface_name} = $_;
1216   }
1217   print Q(<<"EOF");
1218 #    XSFUNCTION = $self->{interface_macro}($self->{ret_type},cv,XSANY.any_dptr);
1219 EOF
1220   $self->{interface} = 1;        # local
1221   $self->{interfaces} = 1;        # global
1222 }
1223
1224 sub CLEANUP_handler {
1225   my $self = shift;
1226   $self->print_section();
1227 }
1228
1229 sub PREINIT_handler {
1230   my $self = shift;
1231   $self->print_section();
1232 }
1233
1234 sub POSTCALL_handler {
1235   my $self = shift;
1236   $self->print_section();
1237 }
1238
1239 sub INIT_handler {
1240   my $self = shift;
1241   $self->print_section();
1242 }
1243
1244 sub get_aliases {
1245   my $self = shift;
1246   my ($line) = @_;
1247   my ($orig) = $line;
1248
1249   # Parse alias definitions
1250   # format is
1251   #    alias = value alias = value ...
1252
1253   while ($line =~ s/^\s*([\w:]+)\s*=\s*(\w+)\s*//) {
1254     my ($alias, $value) = ($1, $2);
1255     my $orig_alias = $alias;
1256
1257     # check for optional package definition in the alias
1258     $alias = $self->{Packprefix} . $alias if $alias !~ /::/;
1259
1260     # check for duplicate alias name & duplicate value
1261     Warn( $self, "Warning: Ignoring duplicate alias '$orig_alias'")
1262       if defined $self->{XsubAliases}->{$alias};
1263
1264     Warn( $self, "Warning: Aliases '$orig_alias' and '$self->{XsubAliasValues}->{$value}' have identical values")
1265       if $self->{XsubAliasValues}->{$value};
1266
1267     $self->{xsubaliases} = 1;
1268     $self->{XsubAliases}->{$alias} = $value;
1269     $self->{XsubAliasValues}->{$value} = $orig_alias;
1270   }
1271
1272   blurt( $self, "Error: Cannot parse ALIAS definitions from '$orig'")
1273     if $line;
1274 }
1275
1276 sub ATTRS_handler {
1277   my $self = shift;
1278   $_ = shift;
1279
1280   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1281     next unless /\S/;
1282     trim_whitespace($_);
1283     push @{ $self->{Attributes} }, $_;
1284   }
1285 }
1286
1287 sub ALIAS_handler {
1288   my $self = shift;
1289   $_ = shift;
1290
1291   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1292     next unless /\S/;
1293     trim_whitespace($_);
1294     $self->get_aliases($_) if $_;
1295   }
1296 }
1297
1298 sub OVERLOAD_handler {
1299   my $self = shift;
1300   $_ = shift;
1301
1302   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1303     next unless /\S/;
1304     trim_whitespace($_);
1305     while ( s/^\s*([\w:"\\)\+\-\*\/\%\<\>\.\&\|\^\!\~\{\}\=]+)\s*//) {
1306       $self->{Overload} = 1 unless $self->{Overload};
1307       my $overload = "$Package\::(".$1;
1308       push(@{ $self->{InitFileCode} },
1309        "        (void)$self->{newXS}(\"$overload\", XS_$Full_func_name, file$self->{proto});\n");
1310     }
1311   }
1312 }
1313
1314 sub FALLBACK_handler {
1315   my $self = shift;
1316   $_ = shift;
1317
1318   # the rest of the current line should contain either TRUE,
1319   # FALSE or UNDEF
1320
1321   trim_whitespace($_);
1322   my %map = (
1323     TRUE => "&PL_sv_yes", 1 => "&PL_sv_yes",
1324     FALSE => "&PL_sv_no", 0 => "&PL_sv_no",
1325     UNDEF => "&PL_sv_undef",
1326   );
1327
1328   # check for valid FALLBACK value
1329   $self->death("Error: FALLBACK: TRUE/FALSE/UNDEF") unless exists $map{uc $_};
1330
1331   $self->{Fallback} = $map{uc $_};
1332 }
1333
1334
1335 sub REQUIRE_handler {
1336   my $self = shift;
1337   # the rest of the current line should contain a version number
1338   my $Ver = shift;
1339
1340   trim_whitespace($Ver);
1341
1342   $self->death("Error: REQUIRE expects a version number")
1343     unless $Ver;
1344
1345   # check that the version number is of the form n.n
1346   $self->death("Error: REQUIRE: expected a number, got '$Ver'")
1347     unless $Ver =~ /^\d+(\.\d*)?/;
1348
1349   $self->death("Error: xsubpp $Ver (or better) required--this is only $VERSION.")
1350     unless $VERSION >= $Ver;
1351 }
1352
1353 sub VERSIONCHECK_handler {
1354   my $self = shift;
1355   $_ = shift;
1356
1357   # the rest of the current line should contain either ENABLE or
1358   # DISABLE
1359
1360   trim_whitespace($_);
1361
1362   # check for ENABLE/DISABLE
1363   $self->death("Error: VERSIONCHECK: ENABLE/DISABLE")
1364     unless /^(ENABLE|DISABLE)/i;
1365
1366   $self->{WantVersionChk} = 1 if $1 eq 'ENABLE';
1367   $self->{WantVersionChk} = 0 if $1 eq 'DISABLE';
1368
1369 }
1370
1371 sub PROTOTYPE_handler {
1372   my $self = shift;
1373   $_ = shift;
1374
1375   my $specified;
1376
1377   $self->death("Error: Only 1 PROTOTYPE definition allowed per xsub")
1378     if $self->{proto_in_this_xsub}++;
1379
1380   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1381     next unless /\S/;
1382     $specified = 1;
1383     trim_whitespace($_);
1384     if ($_ eq 'DISABLE') {
1385       $self->{ProtoThisXSUB} = 0;
1386     }
1387     elsif ($_ eq 'ENABLE') {
1388       $self->{ProtoThisXSUB} = 1;
1389     }
1390     else {
1391       # remove any whitespace
1392       s/\s+//g;
1393       $self->death("Error: Invalid prototype '$_'")
1394         unless valid_proto_string($_);
1395       $self->{ProtoThisXSUB} = C_string($_);
1396     }
1397   }
1398
1399   # If no prototype specified, then assume empty prototype ""
1400   $self->{ProtoThisXSUB} = 2 unless $specified;
1401
1402   $self->{ProtoUsed} = 1;
1403 }
1404
1405 sub SCOPE_handler {
1406   my $self = shift;
1407   $_ = shift;
1408
1409   $self->death("Error: Only 1 SCOPE declaration allowed per xsub")
1410     if $self->{scope_in_this_xsub}++;
1411
1412   trim_whitespace($_);
1413   $self->death("Error: SCOPE: ENABLE/DISABLE")
1414       unless /^(ENABLE|DISABLE)\b/i;
1415   $self->{ScopeThisXSUB} = ( uc($1) eq 'ENABLE' );
1416 }
1417
1418 sub PROTOTYPES_handler {
1419   my $self = shift;
1420   $_ = shift;
1421
1422   # the rest of the current line should contain either ENABLE or
1423   # DISABLE
1424
1425   trim_whitespace($_);
1426
1427   # check for ENABLE/DISABLE
1428   $self->death("Error: PROTOTYPES: ENABLE/DISABLE")
1429     unless /^(ENABLE|DISABLE)/i;
1430
1431   $self->{WantPrototypes} = 1 if $1 eq 'ENABLE';
1432   $self->{WantPrototypes} = 0 if $1 eq 'DISABLE';
1433   $self->{ProtoUsed} = 1;
1434 }
1435
1436 sub PushXSStack {
1437   my $self = shift;
1438   my %args = @_;
1439   # Save the current file context.
1440   push(@{ $self->{XSStack} }, {
1441           type            => 'file',
1442           LastLine        => $self->{lastline},
1443           LastLineNo      => $self->{lastline_no},
1444           Line            => $self->{line},
1445           LineNo          => $self->{line_no},
1446           Filename        => $self->{filename},
1447           Filepathname    => $self->{filepathname},
1448           Handle          => $FH,
1449           IsPipe          => scalar($self->{filename} =~ /\|\s*$/),
1450           %args,
1451          });
1452
1453 }
1454
1455 sub INCLUDE_handler {
1456   my $self = shift;
1457   $_ = shift;
1458   # the rest of the current line should contain a valid filename
1459
1460   trim_whitespace($_);
1461
1462   $self->death("INCLUDE: filename missing")
1463     unless $_;
1464
1465   $self->death("INCLUDE: output pipe is illegal")
1466     if /^\s*\|/;
1467
1468   # simple minded recursion detector
1469   $self->death("INCLUDE loop detected")
1470     if $self->{IncludedFiles}->{$_};
1471
1472   ++$self->{IncludedFiles}->{$_} unless /\|\s*$/;
1473
1474   if (/\|\s*$/ && /^\s*perl\s/) {
1475     Warn( $self, "The INCLUDE directive with a command is discouraged." .
1476           " Use INCLUDE_COMMAND instead! In particular using 'perl'" .
1477           " in an 'INCLUDE: ... |' directive is not guaranteed to pick" .
1478           " up the correct perl. The INCLUDE_COMMAND directive allows" .
1479           " the use of \$^X as the currently running perl, see" .
1480           " 'perldoc perlxs' for details.");
1481   }
1482
1483   $self->PushXSStack();
1484
1485   $FH = Symbol::gensym();
1486
1487   # open the new file
1488   open ($FH, "$_") or $self->death("Cannot open '$_': $!");
1489
1490   print Q(<<"EOF");
1491 #
1492 #/* INCLUDE:  Including '$_' from '$self->{filename}' */
1493 #
1494 EOF
1495
1496   $self->{filename} = $_;
1497   $self->{filepathname} = File::Spec->catfile($self->{dir}, $self->{filename});
1498
1499   # Prime the pump by reading the first
1500   # non-blank line
1501
1502   # skip leading blank lines
1503   while (<$FH>) {
1504     last unless /^\s*$/;
1505   }
1506
1507   $self->{lastline} = $_;
1508   $self->{lastline_no} = $.;
1509 }
1510
1511 sub QuoteArgs {
1512   my $cmd = shift;
1513   my @args = split /\s+/, $cmd;
1514   $cmd = shift @args;
1515   for (@args) {
1516     $_ = q(").$_.q(") if !/^\"/ && length($_) > 0;
1517   }
1518   return join (' ', ($cmd, @args));
1519 }
1520
1521 sub INCLUDE_COMMAND_handler {
1522   my $self = shift;
1523   $_ = shift;
1524   # the rest of the current line should contain a valid command
1525
1526   trim_whitespace($_);
1527
1528   $_ = QuoteArgs($_) if $^O eq 'VMS';
1529
1530   $self->death("INCLUDE_COMMAND: command missing")
1531     unless $_;
1532
1533   $self->death("INCLUDE_COMMAND: pipes are illegal")
1534     if /^\s*\|/ or /\|\s*$/;
1535
1536   $self->PushXSStack( IsPipe => 1 );
1537
1538   $FH = Symbol::gensym();
1539
1540   # If $^X is used in INCLUDE_COMMAND, we know it's supposed to be
1541   # the same perl interpreter as we're currently running
1542   s/^\s*\$\^X/$^X/;
1543
1544   # open the new file
1545   open ($FH, "-|", "$_")
1546     or $self->death( $self, "Cannot run command '$_' to include its output: $!");
1547
1548   print Q(<<"EOF");
1549 #
1550 #/* INCLUDE_COMMAND:  Including output of '$_' from '$self->{filename}' */
1551 #
1552 EOF
1553
1554   $self->{filename} = $_;
1555   $self->{filepathname} = $self->{filename};
1556   $self->{filepathname} =~ s/\"/\\"/g;
1557
1558   # Prime the pump by reading the first
1559   # non-blank line
1560
1561   # skip leading blank lines
1562   while (<$FH>) {
1563     last unless /^\s*$/;
1564   }
1565
1566   $self->{lastline} = $_;
1567   $self->{lastline_no} = $.;
1568 }
1569
1570 sub PopFile {
1571   my $self = shift;
1572
1573   return 0 unless $self->{XSStack}->[-1]{type} eq 'file';
1574
1575   my $data     = pop @{ $self->{XSStack} };
1576   my $ThisFile = $self->{filename};
1577   my $isPipe   = $data->{IsPipe};
1578
1579   --$self->{IncludedFiles}->{$self->{filename}}
1580     unless $isPipe;
1581
1582   close $FH;
1583
1584   $FH         = $data->{Handle};
1585   # $filename is the leafname, which for some reason isused for diagnostic
1586   # messages, whereas $filepathname is the full pathname, and is used for
1587   # #line directives.
1588   $self->{filename}   = $data->{Filename};
1589   $self->{filepathname} = $data->{Filepathname};
1590   $self->{lastline}   = $data->{LastLine};
1591   $self->{lastline_no} = $data->{LastLineNo};
1592   @{ $self->{line} }       = @{ $data->{Line} };
1593   @{ $self->{line_no} }    = @{ $data->{LineNo} };
1594
1595   if ($isPipe and $? ) {
1596     --$self->{lastline_no};
1597     print STDERR "Error reading from pipe '$ThisFile': $! in $self->{filename}, line $self->{lastline_no}\n" ;
1598     exit 1;
1599   }
1600
1601   print Q(<<"EOF");
1602 #
1603 #/* INCLUDE: Returning to '$self->{filename}' from '$ThisFile' */
1604 #
1605 EOF
1606
1607   return 1;
1608 }
1609
1610 sub Q {
1611   my($text) = @_;
1612   $text =~ s/^#//gm;
1613   $text =~ s/\[\[/{/g;
1614   $text =~ s/\]\]/}/g;
1615   $text;
1616 }
1617
1618 # Read next xsub into @{ $self->{line} } from ($lastline, <$FH>).
1619 sub fetch_para {
1620   my $self = shift;
1621
1622   # parse paragraph
1623   $self->death("Error: Unterminated `#if/#ifdef/#ifndef'")
1624     if !defined $self->{lastline} && $self->{XSStack}->[-1]{type} eq 'if';
1625   @{ $self->{line} } = ();
1626   @{ $self->{line_no} } = ();
1627   return $self->PopFile() if !defined $self->{lastline};
1628
1629   if ($self->{lastline} =~
1630       /^MODULE\s*=\s*([\w:]+)(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/) {
1631     my $Module = $1;
1632     $Package = defined($2) ? $2 : ''; # keep -w happy
1633     $self->{Prefix}  = defined($3) ? $3 : ''; # keep -w happy
1634     $self->{Prefix} = quotemeta $self->{Prefix};
1635     ($self->{Module_cname} = $Module) =~ s/\W/_/g;
1636     ($self->{Packid} = $Package) =~ tr/:/_/;
1637     $self->{Packprefix} = $Package;
1638     $self->{Packprefix} .= "::" if $self->{Packprefix} ne "";
1639     $self->{lastline} = "";
1640   }
1641
1642   for (;;) {
1643     # Skip embedded PODs
1644     while ($self->{lastline} =~ /^=/) {
1645       while ($self->{lastline} = <$FH>) {
1646         last if ($self->{lastline} =~ /^=cut\s*$/);
1647       }
1648       $self->death("Error: Unterminated pod") unless $self->{lastline};
1649       $self->{lastline} = <$FH>;
1650       chomp $self->{lastline};
1651       $self->{lastline} =~ s/^\s+$//;
1652     }
1653
1654     # This chunk of code strips out (and parses) embedded TYPEMAP blocks
1655     # which support a HEREdoc-alike block syntax.
1656     # This is special cased from the usual paragraph-handler logic
1657     # due to the HEREdoc-ish syntax.
1658     if ($self->{lastline} =~ /^TYPEMAP\s*:\s*<<\s*(?:(["'])(.+?)\1|([^\s'"]+))\s*;?\s*$/) {
1659       my $end_marker = quotemeta(defined($1) ? $2 : $3);
1660       my @tmaplines;
1661       while (1) {
1662         $self->{lastline} = <$FH>;
1663         $self->death("Error: Unterminated typemap") if not defined $self->{lastline};
1664         last if $self->{lastline} =~ /^$end_marker\s*$/;
1665         push @tmaplines, $self->{lastline};
1666       }
1667
1668       my $tmapcode = join "", @tmaplines;
1669       my $tmap = ExtUtils::Typemaps->new(
1670         string => $tmapcode,
1671         lineno_offset => $self->CurrentLineNumber()+1,
1672         fake_filename => $self->{filename},
1673       );
1674       $self->{typemap}->merge(typemap => $tmap, replace => 1);
1675
1676       last unless defined($self->{lastline} = <$FH>);
1677       next;
1678     }
1679
1680     if ($self->{lastline} !~ /^\s*#/ ||
1681     # CPP directives:
1682     #    ANSI:    if ifdef ifndef elif else endif define undef
1683     #        line error pragma
1684     #    gcc:    warning include_next
1685     #   obj-c:    import
1686     #   others:    ident (gcc notes that some cpps have this one)
1687     $self->{lastline} =~ /^#[ \t]*(?:(?:if|ifn?def|elif|else|endif|define|undef|pragma|error|warning|line\s+\d+|ident)\b|(?:include(?:_next)?|import)\s*["<].*[>"])/) {
1688       last if $self->{lastline} =~ /^\S/ && @{ $self->{line} } && $self->{line}->[-1] eq "";
1689       push(@{ $self->{line} }, $self->{lastline});
1690       push(@{ $self->{line_no} }, $self->{lastline_no});
1691     }
1692
1693     # Read next line and continuation lines
1694     last unless defined($self->{lastline} = <$FH>);
1695     $self->{lastline_no} = $.;
1696     my $tmp_line;
1697     $self->{lastline} .= $tmp_line
1698       while ($self->{lastline} =~ /\\$/ && defined($tmp_line = <$FH>));
1699
1700     chomp $self->{lastline};
1701     $self->{lastline} =~ s/^\s+$//;
1702   }
1703   pop(@{ $self->{line} }), pop(@{ $self->{line_no} }) while @{ $self->{line} } && $self->{line}->[-1] eq "";
1704   1;
1705 }
1706
1707 sub output_init {
1708   my $argsref = shift;
1709   my ($type, $num, $var, $init, $printed_name) = (
1710     $argsref->{type},
1711     $argsref->{num},
1712     $argsref->{var},
1713     $argsref->{init},
1714     $argsref->{printed_name}
1715   );
1716   my $arg = "ST(" . ($num - 1) . ")";
1717
1718   if (  $init =~ /^=/  ) {
1719     if ($printed_name) {
1720       eval qq/print " $init\\n"/;
1721     }
1722     else {
1723       eval qq/print "\\t$var $init\\n"/;
1724     }
1725     warn $@ if $@;
1726   }
1727   else {
1728     if (  $init =~ s/^\+//  &&  $num  ) {
1729       generate_init( {
1730         type          => $type,
1731         num           => $num,
1732         var           => $var,
1733         printed_name  => $printed_name,
1734       } );
1735     }
1736     elsif ($printed_name) {
1737       print ";\n";
1738       $init =~ s/^;//;
1739     }
1740     else {
1741       eval qq/print "\\t$var;\\n"/;
1742       warn $@ if $@;
1743       $init =~ s/^;//;
1744     }
1745     $self->{deferred} .= eval qq/"\\n\\t$init\\n"/;
1746     warn $@ if $@;
1747   }
1748 }
1749
1750 sub generate_init {
1751   my $argsref = shift;
1752   my ($type, $num, $var, $printed_name) = (
1753     $argsref->{type},
1754     $argsref->{num},
1755     $argsref->{var},
1756     $argsref->{printed_name},
1757   );
1758   my $arg = "ST(" . ($num - 1) . ")";
1759   my ($argoff, $ntype);
1760   $argoff = $num - 1;
1761
1762   my $typemaps = $self->{typemap};
1763
1764   $type = tidy_type($type);
1765   $self->blurt("Error: '$type' not in typemap"), return
1766     unless $typemaps->get_typemap(ctype => $type);
1767
1768   ($ntype = $type) =~ s/\s*\*/Ptr/g;
1769   my $subtype;
1770   ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1771   my $typem = $typemaps->get_typemap(ctype => $type);
1772   my $xstype = $typem->xstype;
1773   $xstype =~ s/OBJ$/REF/ if $func_name =~ /DESTROY$/;
1774   if ($xstype eq 'T_PV' and exists $self->{lengthof}->{$var}) {
1775     print "\t$var" unless $printed_name;
1776     print " = ($type)SvPV($arg, STRLEN_length_of_$var);\n";
1777     die "default value not supported with length(NAME) supplied"
1778       if defined $self->{defaults}->{$var};
1779     return;
1780   }
1781   $type =~ tr/:/_/ unless $self->{hiertype};
1782
1783   my $inputmap = $typemaps->get_inputmap(xstype => $xstype);
1784   $self->blurt("Error: No INPUT definition for type '$type', typekind '" . $type->xstype . "' found"), return
1785     unless defined $inputmap;
1786
1787   my $expr = $inputmap->cleaned_code;
1788   # Note: This gruesome bit either needs heavy rethinking or documentation. I vote for the former. --Steffen
1789   if ($expr =~ /DO_ARRAY_ELEM/) {
1790     my $subtypemap  = $typemaps->get_typemap(ctype => $subtype);
1791     my $subinputmap = $typemaps->get_inputmap(xstype => $subtypemap->xstype);
1792     $self->blurt("Error: '$subtype' not in typemap"), return
1793       unless $subtypemap;
1794     $self->blurt("Error: No INPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1795       unless $subinputmap;
1796     my $subexpr = $subinputmap->cleaned_code;
1797     $subexpr =~ s/\$type/\$subtype/g;
1798     $subexpr =~ s/ntype/subtype/g;
1799     $subexpr =~ s/\$arg/ST(ix_$var)/g;
1800     $subexpr =~ s/\n\t/\n\t\t/g;
1801     $subexpr =~ s/is not of (.*\")/[arg %d] is not of $1, ix_$var + 1/g;
1802     $subexpr =~ s/\$var/${var}[ix_$var - $argoff]/;
1803     $expr =~ s/DO_ARRAY_ELEM/$subexpr/;
1804   }
1805   if ($expr =~ m#/\*.*scope.*\*/#i) {  # "scope" in C comments
1806     $self->{ScopeThisXSUB} = 1;
1807   }
1808   if (defined($self->{defaults}->{$var})) {
1809     $expr =~ s/(\t+)/$1    /g;
1810     $expr =~ s/        /\t/g;
1811     if ($printed_name) {
1812       print ";\n";
1813     }
1814     else {
1815       eval qq/print "\\t$var;\\n"/;
1816       warn $@ if $@;
1817     }
1818     if ($self->{defaults}->{$var} eq 'NO_INIT') {
1819       $self->{deferred} .= eval qq/"\\n\\tif (items >= $num) {\\n$expr;\\n\\t}\\n"/;
1820     }
1821     else {
1822       $self->{deferred} .= eval qq/"\\n\\tif (items < $num)\\n\\t    $var = $self->{defaults}->{$var};\\n\\telse {\\n$expr;\\n\\t}\\n"/;
1823     }
1824     warn $@ if $@;
1825   }
1826   elsif ($self->{ScopeThisXSUB} or $expr !~ /^\s*\$var =/) {
1827     if ($printed_name) {
1828       print ";\n";
1829     }
1830     else {
1831       eval qq/print "\\t$var;\\n"/;
1832       warn $@ if $@;
1833     }
1834     $self->{deferred} .= eval qq/"\\n$expr;\\n"/;
1835     warn $@ if $@;
1836   }
1837   else {
1838     die "panic: do not know how to handle this branch for function pointers"
1839       if $printed_name;
1840     eval qq/print "$expr;\\n"/;
1841     warn $@ if $@;
1842   }
1843 }
1844
1845 sub generate_output {
1846   my $argsref = shift;
1847   my ($type, $num, $var, $do_setmagic, $do_push) = (
1848     $argsref->{type},
1849     $argsref->{num},
1850     $argsref->{var},
1851     $argsref->{do_setmagic},
1852     $argsref->{do_push}
1853   );
1854   my $arg = "ST(" . ($num - ($num != 0)) . ")";
1855   my $ntype;
1856
1857   my $typemaps = $self->{typemap};
1858
1859   $type = tidy_type($type);
1860   if ($type =~ /^array\(([^,]*),(.*)\)/) {
1861     print "\t$arg = sv_newmortal();\n";
1862     print "\tsv_setpvn($arg, (char *)$var, $2 * sizeof($1));\n";
1863     print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1864   }
1865   else {
1866     my $typemap   = $typemaps->get_typemap(ctype => $type);
1867     my $outputmap = $typemaps->get_outputmap(xstype => $typemap->xstype);
1868     $self->blurt("Error: '$type' not in typemap"), return
1869       unless $typemap;
1870     $self->blurt("Error: No OUTPUT definition for type '$type', typekind '" . $typemap->xstype . "' found"), return
1871       unless $outputmap;
1872     ($ntype = $type) =~ s/\s*\*/Ptr/g;
1873     $ntype =~ s/\(\)//g;
1874     my $subtype;
1875     ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1876
1877     my $expr = $outputmap->cleaned_code;
1878     if ($expr =~ /DO_ARRAY_ELEM/) {
1879       my $subtypemap   = $typemaps->get_typemap(ctype => $subtype);
1880       my $suboutputmap = $typemaps->get_outputmap(xstype => $subtypemap->xstype);
1881       $self->blurt("Error: '$subtype' not in typemap"), return
1882         unless $subtypemap;
1883       $self->blurt("Error: No OUTPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1884         unless $suboutputmap;
1885       my $subexpr = $suboutputmap->cleaned_code;
1886       $subexpr =~ s/ntype/subtype/g;
1887       $subexpr =~ s/\$arg/ST(ix_$var)/g;
1888       $subexpr =~ s/\$var/${var}[ix_$var]/g;
1889       $subexpr =~ s/\n\t/\n\t\t/g;
1890       $expr =~ s/DO_ARRAY_ELEM\n/$subexpr/;
1891       eval "print qq\a$expr\a";
1892       warn $@ if $@;
1893       print "\t\tSvSETMAGIC(ST(ix_$var));\n" if $do_setmagic;
1894     }
1895     elsif ($var eq 'RETVAL') {
1896       if ($expr =~ /^\t\$arg = new/) {
1897         # We expect that $arg has refcnt 1, so we need to
1898         # mortalize it.
1899         eval "print qq\a$expr\a";
1900         warn $@ if $@;
1901         print "\tsv_2mortal(ST($num));\n";
1902         print "\tSvSETMAGIC(ST($num));\n" if $do_setmagic;
1903       }
1904       elsif ($expr =~ /^\s*\$arg\s*=/) {
1905         # We expect that $arg has refcnt >=1, so we need
1906         # to mortalize it!
1907         eval "print qq\a$expr\a";
1908         warn $@ if $@;
1909         print "\tsv_2mortal(ST(0));\n";
1910         print "\tSvSETMAGIC(ST(0));\n" if $do_setmagic;
1911       }
1912       else {
1913         # Just hope that the entry would safely write it
1914         # over an already mortalized value. By
1915         # coincidence, something like $arg = &sv_undef
1916         # works too.
1917         print "\tST(0) = sv_newmortal();\n";
1918         eval "print qq\a$expr\a";
1919         warn $@ if $@;
1920         # new mortals don't have set magic
1921       }
1922     }
1923     elsif ($do_push) {
1924       print "\tPUSHs(sv_newmortal());\n";
1925       $arg = "ST($num)";
1926       eval "print qq\a$expr\a";
1927       warn $@ if $@;
1928       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1929     }
1930     elsif ($arg =~ /^ST\(\d+\)$/) {
1931       eval "print qq\a$expr\a";
1932       warn $@ if $@;
1933       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1934     }
1935   }
1936 }
1937
1938 1;
1939
1940 # vim: ts=2 sw=2 et: