This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Implement "my $_".
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program. This aliases all the short names to the long
17 names in the current package. Some even have medium names, generally
18 borrowed from B<awk>. In general, it's best to use the
19
20     use English '-no_match_vars';
21
22 invocation if you don't need $PREMATCH, $MATCH, or $POSTMATCH, as it avoids
23 a certain performance hit with the use of regular expressions. See
24 L<English>.
25
26 Variables that depend on the currently selected filehandle may be set by
27 calling an appropriate object method on the IO::Handle object, although
28 this is less efficient than using the regular built-in variables. (Summary
29 lines below for this contain the word HANDLE.) First you must say
30
31     use IO::Handle;
32
33 after which you may use either
34
35     method HANDLE EXPR
36
37 or more safely,
38
39     HANDLE->method(EXPR)
40
41 Each method returns the old value of the IO::Handle attribute.
42 The methods each take an optional EXPR, which, if supplied, specifies the
43 new value for the IO::Handle attribute in question.  If not supplied,
44 most methods do nothing to the current value--except for
45 autoflush(), which will assume a 1 for you, just to be different.
46
47 Because loading in the IO::Handle class is an expensive operation, you should
48 learn how to use the regular built-in variables.
49
50 A few of these variables are considered "read-only".  This means that if
51 you try to assign to this variable, either directly or indirectly through
52 a reference, you'll raise a run-time exception.
53
54 You should be very careful when modifying the default values of most
55 special variables described in this document. In most cases you want
56 to localize these variables before changing them, since if you don't,
57 the change may affect other modules which rely on the default values
58 of the special variables that you have changed. This is one of the
59 correct ways to read the whole file at once:
60
61     open my $fh, "foo" or die $!;
62     local $/; # enable localized slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 But the following code is quite bad:
67
68     open my $fh, "foo" or die $!;
69     undef $/; # enable slurp mode
70     my $content = <$fh>;
71     close $fh;
72
73 since some other module, may want to read data from some file in the
74 default "line mode", so if the code we have just presented has been
75 executed, the global value of C<$/> is now changed for any other code
76 running inside the same Perl interpreter.
77
78 Usually when a variable is localized you want to make sure that this
79 change affects the shortest scope possible. So unless you are already
80 inside some short C<{}> block, you should create one yourself. For
81 example:
82
83     my $content = '';
84     open my $fh, "foo" or die $!;
85     {
86         local $/;
87         $content = <$fh>;
88     }
89     close $fh;
90
91 Here is an example of how your own code can go broken:
92
93     for (1..5){
94         nasty_break();
95         print "$_ ";
96     }
97     sub nasty_break {
98         $_ = 5;
99         # do something with $_
100     }
101
102 You probably expect this code to print:
103
104     1 2 3 4 5
105
106 but instead you get:
107
108     5 5 5 5 5
109
110 Why? Because nasty_break() modifies C<$_> without localizing it
111 first. The fix is to add local():
112
113         local $_ = 5;
114
115 It's easy to notice the problem in such a short example, but in more
116 complicated code you are looking for trouble if you don't localize
117 changes to the special variables.
118
119 The following list is ordered by scalar variables first, then the
120 arrays, then the hashes.
121
122 =over 8
123
124 =item $ARG
125
126 =item $_
127
128 The default input and pattern-searching space.  The following pairs are
129 equivalent:
130
131     while (<>) {...}    # equivalent only in while!
132     while (defined($_ = <>)) {...}
133
134     /^Subject:/
135     $_ =~ /^Subject:/
136
137     tr/a-z/A-Z/
138     $_ =~ tr/a-z/A-Z/
139
140     chomp
141     chomp($_)
142
143 Here are the places where Perl will assume $_ even if you
144 don't use it:
145
146 =over 3
147
148 =item *
149
150 Various unary functions, including functions like ord() and int(), as well
151 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
152 STDIN.
153
154 =item *
155
156 Various list functions like print() and unlink().
157
158 =item *
159
160 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
161 without an C<=~> operator.
162
163 =item *
164
165 The default iterator variable in a C<foreach> loop if no other
166 variable is supplied.
167
168 =item *
169
170 The implicit iterator variable in the grep() and map() functions.
171
172 =item *
173
174 The default place to put an input record when a C<< <FH> >>
175 operation's result is tested by itself as the sole criterion of a C<while>
176 test.  Outside a C<while> test, this will not happen.
177
178 =back
179
180 As C<$_> is a global variable, this may lead in some cases to unwanted
181 side-effects.  As of perl 5.9.1, you can now use a lexical version of
182 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
183 declaring C<our $> restores the global C<$_> in the current scope.
184
185 (Mnemonic: underline is understood in certain operations.)
186
187 =back
188
189 =over 8
190
191 =item $a
192
193 =item $b
194
195 Special package variables when using sort(), see L<perlfunc/sort>.
196 Because of this specialness $a and $b don't need to be declared
197 (using use vars, or our()) even when using the C<strict 'vars'> pragma.
198 Don't lexicalize them with C<my $a> or C<my $b> if you want to be
199 able to use them in the sort() comparison block or function.
200
201 =back
202
203 =over 8
204
205 =item $<I<digits>>
206
207 Contains the subpattern from the corresponding set of capturing
208 parentheses from the last pattern match, not counting patterns
209 matched in nested blocks that have been exited already.  (Mnemonic:
210 like \digits.)  These variables are all read-only and dynamically
211 scoped to the current BLOCK.
212
213 =item $MATCH
214
215 =item $&
216
217 The string matched by the last successful pattern match (not counting
218 any matches hidden within a BLOCK or eval() enclosed by the current
219 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
220 and dynamically scoped to the current BLOCK.
221
222 The use of this variable anywhere in a program imposes a considerable
223 performance penalty on all regular expression matches.  See L</BUGS>.
224
225 =item $PREMATCH
226
227 =item $`
228
229 The string preceding whatever was matched by the last successful
230 pattern match (not counting any matches hidden within a BLOCK or eval
231 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
232 string.)  This variable is read-only.
233
234 The use of this variable anywhere in a program imposes a considerable
235 performance penalty on all regular expression matches.  See L</BUGS>.
236
237 =item $POSTMATCH
238
239 =item $'
240
241 The string following whatever was matched by the last successful
242 pattern match (not counting any matches hidden within a BLOCK or eval()
243 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
244 string.)  Example:
245
246     local $_ = 'abcdefghi';
247     /def/;
248     print "$`:$&:$'\n";         # prints abc:def:ghi
249
250 This variable is read-only and dynamically scoped to the current BLOCK.
251
252 The use of this variable anywhere in a program imposes a considerable
253 performance penalty on all regular expression matches.  See L</BUGS>.
254
255 =item $LAST_PAREN_MATCH
256
257 =item $+
258
259 The text matched by the last bracket of the last successful search pattern.
260 This is useful if you don't know which one of a set of alternative patterns
261 matched. For example:
262
263     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
264
265 (Mnemonic: be positive and forward looking.)
266 This variable is read-only and dynamically scoped to the current BLOCK.
267
268 =item $^N
269
270 The text matched by the used group most-recently closed (i.e. the group
271 with the rightmost closing parenthesis) of the last successful search
272 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
273 recently closed.)
274
275 This is primarily used inside C<(?{...})> blocks for examining text
276 recently matched. For example, to effectively capture text to a variable
277 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
278
279      (?:(...)(?{ $var = $^N }))
280
281 By setting and then using C<$var> in this way relieves you from having to
282 worry about exactly which numbered set of parentheses they are.
283
284 This variable is dynamically scoped to the current BLOCK.
285
286 =item @LAST_MATCH_END
287
288 =item @+
289
290 This array holds the offsets of the ends of the last successful
291 submatches in the currently active dynamic scope.  C<$+[0]> is
292 the offset into the string of the end of the entire match.  This
293 is the same value as what the C<pos> function returns when called
294 on the variable that was matched against.  The I<n>th element
295 of this array holds the offset of the I<n>th submatch, so
296 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
297 past where $2 ends, and so on.  You can use C<$#+> to determine
298 how many subgroups were in the last successful match.  See the
299 examples given for the C<@-> variable.
300
301 =item HANDLE->input_line_number(EXPR)
302
303 =item $INPUT_LINE_NUMBER
304
305 =item $NR
306
307 =item $.
308
309 Current line number for the last filehandle accessed. 
310
311 Each filehandle in Perl counts the number of lines that have been read
312 from it.  (Depending on the value of C<$/>, Perl's idea of what
313 constitutes a line may not match yours.)  When a line is read from a
314 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
315 called on it, C<$.> becomes an alias to the line counter for that
316 filehandle.
317
318 You can adjust the counter by assigning to C<$.>, but this will not
319 actually move the seek pointer.  I<Localizing C<$.> will not localize
320 the filehandle's line count>.  Instead, it will localize perl's notion
321 of which filehandle C<$.> is currently aliased to.
322
323 C<$.> is reset when the filehandle is closed, but B<not> when an open
324 filehandle is reopened without an intervening close().  For more
325 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
326 an explicit close, line numbers increase across ARGV files (but see
327 examples in L<perlfunc/eof>).
328
329 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
330 line counter for a given filehandle without having to worry about
331 which handle you last accessed.
332
333 (Mnemonic: many programs use "." to mean the current line number.)
334
335 =item IO::Handle->input_record_separator(EXPR)
336
337 =item $INPUT_RECORD_SEPARATOR
338
339 =item $RS
340
341 =item $/
342
343 The input record separator, newline by default.  This 
344 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
345 variable, including treating empty lines as a terminator if set to
346 the null string.  (An empty line cannot contain any spaces
347 or tabs.)  You may set it to a multi-character string to match a
348 multi-character terminator, or to C<undef> to read through the end
349 of file.  Setting it to C<"\n\n"> means something slightly
350 different than setting to C<"">, if the file contains consecutive
351 empty lines.  Setting to C<""> will treat two or more consecutive
352 empty lines as a single empty line.  Setting to C<"\n\n"> will
353 blindly assume that the next input character belongs to the next
354 paragraph, even if it's a newline.  (Mnemonic: / delimits
355 line boundaries when quoting poetry.)
356
357     local $/;           # enable "slurp" mode
358     local $_ = <FH>;    # whole file now here
359     s/\n[ \t]+/ /g;
360
361 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
362 better for something. :-)
363
364 Setting C<$/> to a reference to an integer, scalar containing an integer, or
365 scalar that's convertible to an integer will attempt to read records
366 instead of lines, with the maximum record size being the referenced
367 integer.  So this:
368
369     local $/ = \32768; # or \"32768", or \$var_containing_32768
370     open my $fh, $myfile or die $!;
371     local $_ = <$fh>;
372
373 will read a record of no more than 32768 bytes from FILE.  If you're
374 not reading from a record-oriented file (or your OS doesn't have
375 record-oriented files), then you'll likely get a full chunk of data
376 with every read.  If a record is larger than the record size you've
377 set, you'll get the record back in pieces.
378
379 On VMS, record reads are done with the equivalent of C<sysread>,
380 so it's best not to mix record and non-record reads on the same
381 file.  (This is unlikely to be a problem, because any file you'd
382 want to read in record mode is probably unusable in line mode.)
383 Non-VMS systems do normal I/O, so it's safe to mix record and
384 non-record reads of a file.
385
386 See also L<perlport/"Newlines">.  Also see C<$.>.
387
388 =item HANDLE->autoflush(EXPR)
389
390 =item $OUTPUT_AUTOFLUSH
391
392 =item $|
393
394 If set to nonzero, forces a flush right away and after every write
395 or print on the currently selected output channel.  Default is 0
396 (regardless of whether the channel is really buffered by the
397 system or not; C<$|> tells you only whether you've asked Perl
398 explicitly to flush after each write).  STDOUT will
399 typically be line buffered if output is to the terminal and block
400 buffered otherwise.  Setting this variable is useful primarily when
401 you are outputting to a pipe or socket, such as when you are running
402 a Perl program under B<rsh> and want to see the output as it's
403 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
404 for that.  (Mnemonic: when you want your pipes to be piping hot.)
405
406 =item IO::Handle->output_field_separator EXPR
407
408 =item $OUTPUT_FIELD_SEPARATOR
409
410 =item $OFS
411
412 =item $,
413
414 The output field separator for the print operator.  Ordinarily the
415 print operator simply prints out its arguments without further
416 adornment.  To get behavior more like B<awk>, set this variable as
417 you would set B<awk>'s OFS variable to specify what is printed
418 between fields.  (Mnemonic: what is printed when there is a "," in
419 your print statement.)
420
421 =item IO::Handle->output_record_separator EXPR
422
423 =item $OUTPUT_RECORD_SEPARATOR
424
425 =item $ORS
426
427 =item $\
428
429 The output record separator for the print operator.  Ordinarily the
430 print operator simply prints out its arguments as is, with no
431 trailing newline or other end-of-record string added.  To get
432 behavior more like B<awk>, set this variable as you would set
433 B<awk>'s ORS variable to specify what is printed at the end of the
434 print.  (Mnemonic: you set C<$\> instead of adding "\n" at the
435 end of the print.  Also, it's just like C<$/>, but it's what you
436 get "back" from Perl.)
437
438 =item $LIST_SEPARATOR
439
440 =item $"
441
442 This is like C<$,> except that it applies to array and slice values
443 interpolated into a double-quoted string (or similar interpreted
444 string).  Default is a space.  (Mnemonic: obvious, I think.)
445
446 =item $SUBSCRIPT_SEPARATOR
447
448 =item $SUBSEP
449
450 =item $;
451
452 The subscript separator for multidimensional array emulation.  If you
453 refer to a hash element as
454
455     $foo{$a,$b,$c}
456
457 it really means
458
459     $foo{join($;, $a, $b, $c)}
460
461 But don't put
462
463     @foo{$a,$b,$c}      # a slice--note the @
464
465 which means
466
467     ($foo{$a},$foo{$b},$foo{$c})
468
469 Default is "\034", the same as SUBSEP in B<awk>.  If your
470 keys contain binary data there might not be any safe value for C<$;>.
471 (Mnemonic: comma (the syntactic subscript separator) is a
472 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
473 taken for something more important.)
474
475 Consider using "real" multidimensional arrays as described
476 in L<perllol>.
477
478 =item $#
479
480 The output format for printed numbers.  This variable is a half-hearted
481 attempt to emulate B<awk>'s OFMT variable.  There are times, however,
482 when B<awk> and Perl have differing notions of what counts as 
483 numeric.  The initial value is "%.I<n>g", where I<n> is the value
484 of the macro DBL_DIG from your system's F<float.h>.  This is different from
485 B<awk>'s default OFMT setting of "%.6g", so you need to set C<$#>
486 explicitly to get B<awk>'s value.  (Mnemonic: # is the number sign.)
487
488 Use of C<$#> is deprecated.
489
490 =item HANDLE->format_page_number(EXPR)
491
492 =item $FORMAT_PAGE_NUMBER
493
494 =item $%
495
496 The current page number of the currently selected output channel.
497 Used with formats.
498 (Mnemonic: % is page number in B<nroff>.)
499
500 =item HANDLE->format_lines_per_page(EXPR)
501
502 =item $FORMAT_LINES_PER_PAGE
503
504 =item $=
505
506 The current page length (printable lines) of the currently selected
507 output channel.  Default is 60.  
508 Used with formats.
509 (Mnemonic: = has horizontal lines.)
510
511 =item HANDLE->format_lines_left(EXPR)
512
513 =item $FORMAT_LINES_LEFT
514
515 =item $-
516
517 The number of lines left on the page of the currently selected output
518 channel.  
519 Used with formats.
520 (Mnemonic: lines_on_page - lines_printed.)
521
522 =item @LAST_MATCH_START
523
524 =item @-
525
526 $-[0] is the offset of the start of the last successful match.
527 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
528 I<n>-th subpattern, or undef if the subpattern did not match.
529
530 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
531 $+[0] - $-[0]>.  Similarly, C<$>I<n> coincides with C<substr $_, $-[>I<n>C<],
532 $+[>I<n>C<] - $-[>I<n>C<]> if C<$-[>I<n>C<]> is defined, and $+ coincides with
533 C<substr $_, $-[$#-], $+[$#-]>.  One can use C<$#-> to find the last
534 matched subgroup in the last successful match.  Contrast with
535 C<$#+>, the number of subgroups in the regular expression.  Compare
536 with C<@+>.
537
538 This array holds the offsets of the beginnings of the last
539 successful submatches in the currently active dynamic scope.
540 C<$-[0]> is the offset into the string of the beginning of the
541 entire match.  The I<n>th element of this array holds the offset
542 of the I<n>th submatch, so C<$-[1]> is the offset where $1
543 begins, C<$-[2]> the offset where $2 begins, and so on.
544
545 After a match against some variable $var:
546
547 =over 5
548
549 =item C<$`> is the same as C<substr($var, 0, $-[0])>
550
551 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
552
553 =item C<$'> is the same as C<substr($var, $+[0])>
554
555 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
556
557 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
558
559 =item C<$3> is the same as C<substr $var, $-[3], $+[3] - $-[3])>
560
561 =back
562
563 =item HANDLE->format_name(EXPR)
564
565 =item $FORMAT_NAME
566
567 =item $~
568
569 The name of the current report format for the currently selected output
570 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
571 C<$^>.)
572
573 =item HANDLE->format_top_name(EXPR)
574
575 =item $FORMAT_TOP_NAME
576
577 =item $^
578
579 The name of the current top-of-page format for the currently selected
580 output channel.  Default is the name of the filehandle with _TOP
581 appended.  (Mnemonic: points to top of page.)
582
583 =item IO::Handle->format_line_break_characters EXPR
584
585 =item $FORMAT_LINE_BREAK_CHARACTERS
586
587 =item $:
588
589 The current set of characters after which a string may be broken to
590 fill continuation fields (starting with ^) in a format.  Default is
591 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
592 poetry is a part of a line.)
593
594 =item IO::Handle->format_formfeed EXPR
595
596 =item $FORMAT_FORMFEED
597
598 =item $^L
599
600 What formats output as a form feed.  Default is \f.
601
602 =item $ACCUMULATOR
603
604 =item $^A
605
606 The current value of the write() accumulator for format() lines.  A format
607 contains formline() calls that put their result into C<$^A>.  After
608 calling its format, write() prints out the contents of C<$^A> and empties.
609 So you never really see the contents of C<$^A> unless you call
610 formline() yourself and then look at it.  See L<perlform> and
611 L<perlfunc/formline()>.
612
613 =item $CHILD_ERROR
614
615 =item $?
616
617 The status returned by the last pipe close, backtick (C<``>) command,
618 successful call to wait() or waitpid(), or from the system()
619 operator.  This is just the 16-bit status word returned by the
620 wait() system call (or else is made up to look like it).  Thus, the
621 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
622 C<$? & 127> gives which signal, if any, the process died from, and
623 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
624 similar to B<sh> and B<ksh>.)
625
626 Additionally, if the C<h_errno> variable is supported in C, its value
627 is returned via $? if any C<gethost*()> function fails.
628
629 If you have installed a signal handler for C<SIGCHLD>, the
630 value of C<$?> will usually be wrong outside that handler.
631
632 Inside an C<END> subroutine C<$?> contains the value that is going to be
633 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
634 change the exit status of your program.  For example:
635
636     END {
637         $? = 1 if $? == 255;  # die would make it 255
638     } 
639
640 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
641 actual VMS exit status, instead of the default emulation of POSIX
642 status; see L<perlvms/$?> for details.
643
644 Also see L<Error Indicators>.
645
646 =item ${^ENCODING}
647
648 The I<object reference> to the Encode object that is used to convert
649 the source code to Unicode.  Thanks to this variable your perl script
650 does not have to be written in UTF-8.  Default is I<undef>.  The direct
651 manipulation of this variable is highly discouraged.  See L<encoding>
652 for more details.
653
654 =item $OS_ERROR
655
656 =item $ERRNO
657
658 =item $!
659
660 If used numerically, yields the current value of the C C<errno>
661 variable, or in other words, if a system or library call fails, it
662 sets this variable.  This means that the value of C<$!> is meaningful
663 only I<immediately> after a B<failure>:
664
665     if (open(FH, $filename)) {
666         # Here $! is meaningless.
667         ...
668     } else {
669         # ONLY here is $! meaningful.
670         ...
671         # Already here $! might be meaningless.
672     }
673     # Since here we might have either success or failure,
674     # here $! is meaningless.
675
676 In the above I<meaningless> stands for anything: zero, non-zero,
677 C<undef>.  A successful system or library call does B<not> set
678 the variable to zero.
679
680 If used as a string, yields the corresponding system error string.
681 You can assign a number to C<$!> to set I<errno> if, for instance,
682 you want C<"$!"> to return the string for error I<n>, or you want
683 to set the exit value for the die() operator.  (Mnemonic: What just
684 went bang?)
685
686 Also see L<Error Indicators>.
687
688 =item %!
689
690 Each element of C<%!> has a true value only if C<$!> is set to that
691 value.  For example, C<$!{ENOENT}> is true if and only if the current
692 value of C<$!> is C<ENOENT>; that is, if the most recent error was
693 "No such file or directory" (or its moral equivalent: not all operating
694 systems give that exact error, and certainly not all languages).
695 To check if a particular key is meaningful on your system, use
696 C<exists $!{the_key}>; for a list of legal keys, use C<keys %!>.
697 See L<Errno> for more information, and also see above for the
698 validity of C<$!>.
699
700 =item $EXTENDED_OS_ERROR
701
702 =item $^E
703
704 Error information specific to the current operating system.  At
705 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
706 (and for MacPerl).  On all other platforms, C<$^E> is always just
707 the same as C<$!>.
708
709 Under VMS, C<$^E> provides the VMS status value from the last
710 system error.  This is more specific information about the last
711 system error than that provided by C<$!>.  This is particularly
712 important when C<$!> is set to B<EVMSERR>.
713
714 Under OS/2, C<$^E> is set to the error code of the last call to
715 OS/2 API either via CRT, or directly from perl.
716
717 Under Win32, C<$^E> always returns the last error information
718 reported by the Win32 call C<GetLastError()> which describes
719 the last error from within the Win32 API.  Most Win32-specific
720 code will report errors via C<$^E>.  ANSI C and Unix-like calls
721 set C<errno> and so most portable Perl code will report errors
722 via C<$!>. 
723
724 Caveats mentioned in the description of C<$!> generally apply to
725 C<$^E>, also.  (Mnemonic: Extra error explanation.)
726
727 Also see L<Error Indicators>.
728
729 =item $EVAL_ERROR
730
731 =item $@
732
733 The Perl syntax error message from the last eval() operator.
734 If $@ is the null string, the last eval() parsed and executed
735 correctly (although the operations you invoked may have failed in the
736 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
737
738 Warning messages are not collected in this variable.  You can,
739 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
740 as described below.
741
742 Also see L<Error Indicators>.
743
744 =item $PROCESS_ID
745
746 =item $PID
747
748 =item $$
749
750 The process number of the Perl running this script.  You should
751 consider this variable read-only, although it will be altered
752 across fork() calls.  (Mnemonic: same as shells.)
753
754 Note for Linux users: on Linux, the C functions C<getpid()> and
755 C<getppid()> return different values from different threads. In order to
756 be portable, this behavior is not reflected by C<$$>, whose value remains
757 consistent across threads. If you want to call the underlying C<getpid()>,
758 you may use the CPAN module C<Linux::Pid>.
759
760 =item $REAL_USER_ID
761
762 =item $UID
763
764 =item $<
765
766 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
767 if you're running setuid.)  You can change both the real uid and
768 the effective uid at the same time by using POSIX::setuid().
769
770 =item $EFFECTIVE_USER_ID
771
772 =item $EUID
773
774 =item $>
775
776 The effective uid of this process.  Example:
777
778     $< = $>;            # set real to effective uid
779     ($<,$>) = ($>,$<);  # swap real and effective uid
780
781 You can change both the effective uid and the real uid at the same
782 time by using POSIX::setuid().
783
784 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
785 C<< $< >> and C<< $> >> can be swapped only on machines
786 supporting setreuid().
787
788 =item $REAL_GROUP_ID
789
790 =item $GID
791
792 =item $(
793
794 The real gid of this process.  If you are on a machine that supports
795 membership in multiple groups simultaneously, gives a space separated
796 list of groups you are in.  The first number is the one returned by
797 getgid(), and the subsequent ones by getgroups(), one of which may be
798 the same as the first number.
799
800 However, a value assigned to C<$(> must be a single number used to
801 set the real gid.  So the value given by C<$(> should I<not> be assigned
802 back to C<$(> without being forced numeric, such as by adding zero.
803
804 You can change both the real gid and the effective gid at the same
805 time by using POSIX::setgid().
806
807 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
808 group you I<left>, if you're running setgid.)
809
810 =item $EFFECTIVE_GROUP_ID
811
812 =item $EGID
813
814 =item $)
815
816 The effective gid of this process.  If you are on a machine that
817 supports membership in multiple groups simultaneously, gives a space
818 separated list of groups you are in.  The first number is the one
819 returned by getegid(), and the subsequent ones by getgroups(), one of
820 which may be the same as the first number.
821
822 Similarly, a value assigned to C<$)> must also be a space-separated
823 list of numbers.  The first number sets the effective gid, and
824 the rest (if any) are passed to setgroups().  To get the effect of an
825 empty list for setgroups(), just repeat the new effective gid; that is,
826 to force an effective gid of 5 and an effectively empty setgroups()
827 list, say C< $) = "5 5" >.
828
829 You can change both the effective gid and the real gid at the same
830 time by using POSIX::setgid() (use only a single numeric argument).
831
832 (Mnemonic: parentheses are used to I<group> things.  The effective gid
833 is the group that's I<right> for you, if you're running setgid.)
834
835 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
836 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
837 and C<$)> can be swapped only on machines supporting setregid().
838
839 =item $PROGRAM_NAME
840
841 =item $0
842
843 Contains the name of the program being executed.
844
845 On some (read: not all) operating systems assigning to C<$0> modifies
846 the argument area that the C<ps> program sees.  On some platforms you
847 may have to use special C<ps> options or a different C<ps> to see the
848 changes.  Modifying the $0 is more useful as a way of indicating the
849 current program state than it is for hiding the program you're
850 running.  (Mnemonic: same as B<sh> and B<ksh>.)
851
852 Note that there are platform specific limitations on the the maximum
853 length of C<$0>.  In the most extreme case it may be limited to the
854 space occupied by the original C<$0>.
855
856 In some platforms there may be arbitrary amount of padding, for
857 example space characters, after the modified name as shown by C<ps>.
858 In some platforms this padding may extend all the way to the original
859 length of the argument area, no matter what you do (this is the case
860 for example with Linux 2.2).
861
862 Note for BSD users: setting C<$0> does not completely remove "perl"
863 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
864 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
865 and the " (perl)" suffix are shown depends on your exact BSD variant
866 and version).  This is an operating system feature, Perl cannot help it.
867
868 In multithreaded scripts Perl coordinates the threads so that any
869 thread may modify its copy of the C<$0> and the change becomes visible
870 to ps(1) (assuming the operating system plays along).  Note that the
871 the view of C<$0> the other threads have will not change since they
872 have their own copies of it.
873
874 =item $[
875
876 The index of the first element in an array, and of the first character
877 in a substring.  Default is 0, but you could theoretically set it
878 to 1 to make Perl behave more like B<awk> (or Fortran) when
879 subscripting and when evaluating the index() and substr() functions.
880 (Mnemonic: [ begins subscripts.)
881
882 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
883 directive, and cannot influence the behavior of any other file.
884 (That's why you can only assign compile-time constants to it.)
885 Its use is highly discouraged.
886
887 Note that, unlike other compile-time directives (such as L<strict>),
888 assignment to $[ can be seen from outer lexical scopes in the same file.
889 However, you can use local() on it to strictly bound its value to a
890 lexical block.
891
892 =item $]
893
894 The version + patchlevel / 1000 of the Perl interpreter.  This variable
895 can be used to determine whether the Perl interpreter executing a
896 script is in the right range of versions.  (Mnemonic: Is this version
897 of perl in the right bracket?)  Example:
898
899     warn "No checksumming!\n" if $] < 3.019;
900
901 See also the documentation of C<use VERSION> and C<require VERSION>
902 for a convenient way to fail if the running Perl interpreter is too old.
903
904 The floating point representation can sometimes lead to inaccurate
905 numeric comparisons.  See C<$^V> for a more modern representation of
906 the Perl version that allows accurate string comparisons.
907
908 =item $COMPILING
909
910 =item $^C
911
912 The current value of the flag associated with the B<-c> switch.
913 Mainly of use with B<-MO=...> to allow code to alter its behavior
914 when being compiled, such as for example to AUTOLOAD at compile
915 time rather than normal, deferred loading.  See L<perlcc>.  Setting
916 C<$^C = 1> is similar to calling C<B::minus_c>.
917
918 =item $DEBUGGING
919
920 =item $^D
921
922 The current value of the debugging flags.  (Mnemonic: value of B<-D>
923 switch.) May be read or set. Like its command-line equivalent, you can use
924 numeric or symbolic values, eg C<$^D = 10> or C<$^D = "st">.
925
926 =item $SYSTEM_FD_MAX
927
928 =item $^F
929
930 The maximum system file descriptor, ordinarily 2.  System file
931 descriptors are passed to exec()ed processes, while higher file
932 descriptors are not.  Also, during an open(), system file descriptors are
933 preserved even if the open() fails.  (Ordinary file descriptors are
934 closed before the open() is attempted.)  The close-on-exec
935 status of a file descriptor will be decided according to the value of
936 C<$^F> when the corresponding file, pipe, or socket was opened, not the
937 time of the exec().
938
939 =item $^H
940
941 WARNING: This variable is strictly for internal use only.  Its availability,
942 behavior, and contents are subject to change without notice.
943
944 This variable contains compile-time hints for the Perl interpreter.  At the
945 end of compilation of a BLOCK the value of this variable is restored to the
946 value when the interpreter started to compile the BLOCK.
947
948 When perl begins to parse any block construct that provides a lexical scope
949 (e.g., eval body, required file, subroutine body, loop body, or conditional
950 block), the existing value of $^H is saved, but its value is left unchanged.
951 When the compilation of the block is completed, it regains the saved value.
952 Between the points where its value is saved and restored, code that
953 executes within BEGIN blocks is free to change the value of $^H.
954
955 This behavior provides the semantic of lexical scoping, and is used in,
956 for instance, the C<use strict> pragma.
957
958 The contents should be an integer; different bits of it are used for
959 different pragmatic flags.  Here's an example:
960
961     sub add_100 { $^H |= 0x100 }
962
963     sub foo {
964         BEGIN { add_100() }
965         bar->baz($boon);
966     }
967
968 Consider what happens during execution of the BEGIN block.  At this point
969 the BEGIN block has already been compiled, but the body of foo() is still
970 being compiled.  The new value of $^H will therefore be visible only while
971 the body of foo() is being compiled.
972
973 Substitution of the above BEGIN block with:
974
975     BEGIN { require strict; strict->import('vars') }
976
977 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
978 version of the same lexical pragma:
979
980     BEGIN { require strict; strict->import('vars') if $condition }
981
982 =item %^H
983
984 WARNING: This variable is strictly for internal use only.  Its availability,
985 behavior, and contents are subject to change without notice.
986
987 The %^H hash provides the same scoping semantic as $^H.  This makes it
988 useful for implementation of lexically scoped pragmas.
989
990 =item $INPLACE_EDIT
991
992 =item $^I
993
994 The current value of the inplace-edit extension.  Use C<undef> to disable
995 inplace editing.  (Mnemonic: value of B<-i> switch.)
996
997 =item $^M
998
999 By default, running out of memory is an untrappable, fatal error.
1000 However, if suitably built, Perl can use the contents of C<$^M>
1001 as an emergency memory pool after die()ing.  Suppose that your Perl
1002 were compiled with -DPERL_EMERGENCY_SBRK and used Perl's malloc.
1003 Then
1004
1005     $^M = 'a' x (1 << 16);
1006
1007 would allocate a 64K buffer for use in an emergency.  See the
1008 F<INSTALL> file in the Perl distribution for information on how to
1009 enable this option.  To discourage casual use of this advanced
1010 feature, there is no L<English|English> long name for this variable.
1011
1012 =item $OSNAME
1013
1014 =item $^O
1015
1016 The name of the operating system under which this copy of Perl was
1017 built, as determined during the configuration process.  The value
1018 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
1019 B<-V> command-line switch documented in L<perlrun>.
1020
1021 In Windows platforms, $^O is not very helpful: since it is always
1022 C<MSWin32>, it doesn't tell the difference between
1023 95/98/ME/NT/2000/XP/CE/.NET.  Use Win32::GetOSName() or
1024 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
1025 between the variants.
1026
1027 =item ${^OPEN}
1028
1029 An internal variable used by PerlIO.  A string in two parts, separated
1030 by a C<\0> byte, the first part describes the input layers, the second
1031 part describes the output layers.
1032
1033 =item $PERLDB
1034
1035 =item $^P
1036
1037 The internal variable for debugging support.  The meanings of the
1038 various bits are subject to change, but currently indicate:
1039
1040 =over 6
1041
1042 =item 0x01
1043
1044 Debug subroutine enter/exit.
1045
1046 =item 0x02
1047
1048 Line-by-line debugging.
1049
1050 =item 0x04
1051
1052 Switch off optimizations.
1053
1054 =item 0x08
1055
1056 Preserve more data for future interactive inspections.
1057
1058 =item 0x10
1059
1060 Keep info about source lines on which a subroutine is defined.
1061
1062 =item 0x20
1063
1064 Start with single-step on.
1065
1066 =item 0x40
1067
1068 Use subroutine address instead of name when reporting.
1069
1070 =item 0x80
1071
1072 Report C<goto &subroutine> as well.
1073
1074 =item 0x100
1075
1076 Provide informative "file" names for evals based on the place they were compiled.
1077
1078 =item 0x200
1079
1080 Provide informative names to anonymous subroutines based on the place they
1081 were compiled.
1082
1083 =item 0x400
1084
1085 Debug assertion subroutines enter/exit.
1086
1087 =back
1088
1089 Some bits may be relevant at compile-time only, some at
1090 run-time only.  This is a new mechanism and the details may change.
1091
1092 =item $LAST_REGEXP_CODE_RESULT
1093
1094 =item $^R
1095
1096 The result of evaluation of the last successful C<(?{ code })>
1097 regular expression assertion (see L<perlre>).  May be written to.
1098
1099 =item $EXCEPTIONS_BEING_CAUGHT
1100
1101 =item $^S
1102
1103 Current state of the interpreter.
1104
1105     $^S         State
1106     ---------   -------------------
1107     undef       Parsing module/eval
1108     true (1)    Executing an eval
1109     false (0)   Otherwise
1110
1111 The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.
1112
1113 =item $BASETIME
1114
1115 =item $^T
1116
1117 The time at which the program began running, in seconds since the
1118 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1119 and B<-C> filetests are based on this value.
1120
1121 =item ${^TAINT}
1122
1123 Reflects if taint mode is on or off.  1 for on (the program was run with
1124 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
1125 B<-t> or B<-TU>).  This variable is read-only.
1126
1127 =item ${^UNICODE}
1128
1129 Reflects certain Unicode settings of Perl.  See L<perlrun>
1130 documentation for the C<-C> switch for more information about
1131 the possible values. This variable is set during Perl startup
1132 and is thereafter read-only.
1133
1134 =item $PERL_VERSION
1135
1136 =item $^V
1137
1138 The revision, version, and subversion of the Perl interpreter, represented
1139 as a string composed of characters with those ordinals.  Thus in Perl v5.6.0
1140 it equals C<chr(5) . chr(6) . chr(0)> and will return true for
1141 C<$^V eq v5.6.0>.  Note that the characters in this string value can
1142 potentially be in Unicode range.
1143
1144 This can be used to determine whether the Perl interpreter executing a
1145 script is in the right range of versions.  (Mnemonic: use ^V for Version
1146 Control.)  Example:
1147
1148     warn "No \"our\" declarations!\n" if $^V and $^V lt v5.6.0;
1149
1150 To convert C<$^V> into its string representation use sprintf()'s
1151 C<"%vd"> conversion:
1152
1153     printf "version is v%vd\n", $^V;  # Perl's version
1154
1155 See the documentation of C<use VERSION> and C<require VERSION>
1156 for a convenient way to fail if the running Perl interpreter is too old.
1157
1158 See also C<$]> for an older representation of the Perl version.
1159
1160 =item $WARNING
1161
1162 =item $^W
1163
1164 The current value of the warning switch, initially true if B<-w>
1165 was used, false otherwise, but directly modifiable.  (Mnemonic:
1166 related to the B<-w> switch.)  See also L<warnings>.
1167
1168 =item ${^WARNING_BITS}
1169
1170 The current set of warning checks enabled by the C<use warnings> pragma.
1171 See the documentation of C<warnings> for more details.
1172
1173 =item $EXECUTABLE_NAME
1174
1175 =item $^X
1176
1177 The name used to execute the current copy of Perl, from C's
1178 C<argv[0]>.
1179
1180 Depending on the host operating system, the value of $^X may be
1181 a relative or absolute pathname of the perl program file, or may
1182 be the string used to invoke perl but not the pathname of the
1183 perl program file.  Also, most operating systems permit invoking
1184 programs that are not in the PATH environment variable, so there
1185 is no guarantee that the value of $^X is in PATH.  For VMS, the
1186 value may or may not include a version number.
1187
1188 You usually can use the value of $^X to re-invoke an independent
1189 copy of the same perl that is currently running, e.g.,
1190
1191   @first_run = `$^X -le "print int rand 100 for 1..100"`;
1192
1193 But recall that not all operating systems support forking or
1194 capturing of the output of commands, so this complex statement
1195 may not be portable.
1196
1197 It is not safe to use the value of $^X as a path name of a file,
1198 as some operating systems that have a mandatory suffix on
1199 executable files do not require use of the suffix when invoking
1200 a command.  To convert the value of $^X to a path name, use the
1201 following statements:
1202
1203 # Build up a set of file names (not command names).
1204   use Config;
1205   $this_perl = $^X;
1206   if ($^O ne 'VMS')
1207      {$this_perl .= $Config{_exe}
1208           unless $this_perl =~ m/$Config{_exe}$/i;}
1209
1210 Because many operating systems permit anyone with read access to
1211 the Perl program file to make a copy of it, patch the copy, and
1212 then execute the copy, the security-conscious Perl programmer
1213 should take care to invoke the installed copy of perl, not the
1214 copy referenced by $^X.  The following statements accomplish
1215 this goal, and produce a pathname that can be invoked as a
1216 command or referenced as a file.
1217
1218   use Config;
1219   $secure_perl_path = $Config{perlpath};
1220   if ($^O ne 'VMS')
1221      {$secure_perl_path .= $Config{_exe}
1222           unless $secure_perl_path =~ m/$Config{_exe}$/i;}
1223
1224 =item ARGV
1225
1226 The special filehandle that iterates over command-line filenames in
1227 C<@ARGV>. Usually written as the null filehandle in the angle operator
1228 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1229 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1230 corresponding to the last file opened by C<< <> >>. In particular,
1231 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1232 may not cause your function to automatically read the contents of all the
1233 files in C<@ARGV>.
1234
1235 =item $ARGV
1236
1237 contains the name of the current file when reading from <>.
1238
1239 =item @ARGV
1240
1241 The array @ARGV contains the command-line arguments intended for
1242 the script.  C<$#ARGV> is generally the number of arguments minus
1243 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1244 command name itself.  See C<$0> for the command name.
1245
1246 =item ARGVOUT
1247
1248 The special filehandle that points to the currently open output file
1249 when doing edit-in-place processing with B<-i>.  Useful when you have
1250 to do a lot of inserting and don't want to keep modifying $_.  See
1251 L<perlrun> for the B<-i> switch.
1252
1253 =item @F
1254
1255 The array @F contains the fields of each line read in when autosplit
1256 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1257 is package-specific, and must be declared or given a full package name
1258 if not in package main when running under C<strict 'vars'>.
1259
1260 =item @INC
1261
1262 The array @INC contains the list of places that the C<do EXPR>,
1263 C<require>, or C<use> constructs look for their library files.  It
1264 initially consists of the arguments to any B<-I> command-line
1265 switches, followed by the default Perl library, probably
1266 F</usr/local/lib/perl>, followed by ".", to represent the current
1267 directory.  ("." will not be appended if taint checks are enabled, either by
1268 C<-T> or by C<-t>.)  If you need to modify this at runtime, you should use
1269 the C<use lib> pragma to get the machine-dependent library properly
1270 loaded also:
1271
1272     use lib '/mypath/libdir/';
1273     use SomeMod;
1274
1275 You can also insert hooks into the file inclusion system by putting Perl
1276 code directly into @INC.  Those hooks may be subroutine references, array
1277 references or blessed objects.  See L<perlfunc/require> for details.
1278
1279 =item @_
1280
1281 Within a subroutine the array @_ contains the parameters passed to that
1282 subroutine.  See L<perlsub>.
1283
1284 =item %INC
1285
1286 The hash %INC contains entries for each filename included via the
1287 C<do>, C<require>, or C<use> operators.  The key is the filename
1288 you specified (with module names converted to pathnames), and the
1289 value is the location of the file found.  The C<require>
1290 operator uses this hash to determine whether a particular file has
1291 already been included.
1292
1293 If the file was loaded via a hook (e.g. a subroutine reference, see
1294 L<perlfunc/require> for a description of these hooks), this hook is
1295 by default inserted into %INC in place of a filename.  Note, however,
1296 that the hook may have set the %INC entry by itself to provide some more
1297 specific info.
1298
1299 =item %ENV
1300
1301 =item $ENV{expr}
1302
1303 The hash %ENV contains your current environment.  Setting a
1304 value in C<ENV> changes the environment for any child processes
1305 you subsequently fork() off.
1306
1307 =item %SIG
1308
1309 =item $SIG{expr}
1310
1311 The hash %SIG contains signal handlers for signals.  For example:
1312
1313     sub handler {       # 1st argument is signal name
1314         my($sig) = @_;
1315         print "Caught a SIG$sig--shutting down\n";
1316         close(LOG);
1317         exit(0);
1318     }
1319
1320     $SIG{'INT'}  = \&handler;
1321     $SIG{'QUIT'} = \&handler;
1322     ...
1323     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1324     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1325
1326 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1327 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1328 this special case.
1329
1330 Here are some other examples:
1331
1332     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1333     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1334     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1335     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1336
1337 Be sure not to use a bareword as the name of a signal handler,
1338 lest you inadvertently call it. 
1339
1340 If your system has the sigaction() function then signal handlers are
1341 installed using it.  This means you get reliable signal handling.
1342
1343 The default delivery policy of signals changed in Perl 5.8.0 from 
1344 immediate (also known as "unsafe") to deferred, also known as 
1345 "safe signals".  See L<perlipc> for more information.
1346
1347 Certain internal hooks can be also set using the %SIG hash.  The
1348 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1349 about to be printed.  The warning message is passed as the first
1350 argument.  The presence of a __WARN__ hook causes the ordinary printing
1351 of warnings to STDERR to be suppressed.  You can use this to save warnings
1352 in a variable, or turn warnings into fatal errors, like this:
1353
1354     local $SIG{__WARN__} = sub { die $_[0] };
1355     eval $proggie;
1356
1357 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1358 is about to be thrown.  The error message is passed as the first
1359 argument.  When a __DIE__ hook routine returns, the exception
1360 processing continues as it would have in the absence of the hook,
1361 unless the hook routine itself exits via a C<goto>, a loop exit, or a die().
1362 The C<__DIE__> handler is explicitly disabled during the call, so that you
1363 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1364
1365 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1366 even inside an eval().  Do not use this to rewrite a pending exception
1367 in C<$@>, or as a bizarre substitute for overriding CORE::GLOBAL::die().
1368 This strange action at a distance may be fixed in a future release
1369 so that C<$SIG{__DIE__}> is only called if your program is about
1370 to exit, as was the original intent.  Any other use is deprecated.
1371
1372 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1373 they may be called to report (probable) errors found by the parser.
1374 In such a case the parser may be in inconsistent state, so any
1375 attempt to evaluate Perl code from such a handler will probably
1376 result in a segfault.  This means that warnings or errors that
1377 result from parsing Perl should be used with extreme caution, like
1378 this:
1379
1380     require Carp if defined $^S;
1381     Carp::confess("Something wrong") if defined &Carp::confess;
1382     die "Something wrong, but could not load Carp to give backtrace...
1383          To see backtrace try starting Perl with -MCarp switch";
1384
1385 Here the first line will load Carp I<unless> it is the parser who
1386 called the handler.  The second line will print backtrace and die if
1387 Carp was available.  The third line will be executed only if Carp was
1388 not available.
1389
1390 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1391 L<warnings> for additional information.
1392
1393 =back
1394
1395 =head2 Error Indicators
1396
1397 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1398 about different types of error conditions that may appear during
1399 execution of a Perl program.  The variables are shown ordered by
1400 the "distance" between the subsystem which reported the error and
1401 the Perl process.  They correspond to errors detected by the Perl
1402 interpreter, C library, operating system, or an external program,
1403 respectively.
1404
1405 To illustrate the differences between these variables, consider the 
1406 following Perl expression, which uses a single-quoted string:
1407
1408     eval q{
1409         open my $pipe, "/cdrom/install |" or die $!;
1410         my @res = <$pipe>;
1411         close $pipe or die "bad pipe: $?, $!";
1412     };
1413
1414 After execution of this statement all 4 variables may have been set.  
1415
1416 C<$@> is set if the string to be C<eval>-ed did not compile (this
1417 may happen if C<open> or C<close> were imported with bad prototypes),
1418 or if Perl code executed during evaluation die()d .  In these cases
1419 the value of $@ is the compile error, or the argument to C<die>
1420 (which will interpolate C<$!> and C<$?>!).  (See also L<Fatal>,
1421 though.)
1422
1423 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1424 and C<close> are translated to calls in the C run-time library and
1425 thence to the operating system kernel.  C<$!> is set to the C library's
1426 C<errno> if one of these calls fails. 
1427
1428 Under a few operating systems, C<$^E> may contain a more verbose
1429 error indicator, such as in this case, "CDROM tray not closed."
1430 Systems that do not support extended error messages leave C<$^E>
1431 the same as C<$!>.
1432
1433 Finally, C<$?> may be set to non-0 value if the external program
1434 F</cdrom/install> fails.  The upper eight bits reflect specific
1435 error conditions encountered by the program (the program's exit()
1436 value).   The lower eight bits reflect mode of failure, like signal
1437 death and core dump information  See wait(2) for details.  In
1438 contrast to C<$!> and C<$^E>, which are set only if error condition
1439 is detected, the variable C<$?> is set on each C<wait> or pipe
1440 C<close>, overwriting the old value.  This is more like C<$@>, which
1441 on every eval() is always set on failure and cleared on success.
1442
1443 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1444 and C<$?>.
1445
1446 =head2 Technical Note on the Syntax of Variable Names
1447
1448 Variable names in Perl can have several formats.  Usually, they
1449 must begin with a letter or underscore, in which case they can be
1450 arbitrarily long (up to an internal limit of 251 characters) and
1451 may contain letters, digits, underscores, or the special sequence
1452 C<::> or C<'>.  In this case, the part before the last C<::> or
1453 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1454
1455 Perl variable names may also be a sequence of digits or a single
1456 punctuation or control character.  These names are all reserved for
1457 special uses by Perl; for example, the all-digits names are used
1458 to hold data captured by backreferences after a regular expression
1459 match.  Perl has a special syntax for the single-control-character
1460 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1461 character.  For example, the notation C<$^W> (dollar-sign caret
1462 C<W>) is the scalar variable whose name is the single character
1463 control-C<W>.  This is better than typing a literal control-C<W>
1464 into your program.
1465
1466 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1467 strings that begin with control characters (or better yet, a caret).
1468 These variables must be written in the form C<${^Foo}>; the braces
1469 are not optional.  C<${^Foo}> denotes the scalar variable whose
1470 name is a control-C<F> followed by two C<o>'s.  These variables are
1471 reserved for future special uses by Perl, except for the ones that
1472 begin with C<^_> (control-underscore or caret-underscore).  No
1473 control-character name that begins with C<^_> will acquire a special
1474 meaning in any future version of Perl; such names may therefore be
1475 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1476
1477 Perl identifiers that begin with digits, control characters, or
1478 punctuation characters are exempt from the effects of the C<package>
1479 declaration and are always forced to be in package C<main>; they are
1480 also exempt from C<strict 'vars'> errors.  A few other names are also
1481 exempt in these ways:
1482
1483         ENV             STDIN
1484         INC             STDOUT
1485         ARGV            STDERR
1486         ARGVOUT         _
1487         SIG
1488
1489 In particular, the new special C<${^_XYZ}> variables are always taken
1490 to be in package C<main>, regardless of any C<package> declarations
1491 presently in scope.  
1492
1493 =head1 BUGS
1494
1495 Due to an unfortunate accident of Perl's implementation, C<use
1496 English> imposes a considerable performance penalty on all regular
1497 expression matches in a program, regardless of whether they occur
1498 in the scope of C<use English>.  For that reason, saying C<use
1499 English> in libraries is strongly discouraged.  See the
1500 Devel::SawAmpersand module documentation from CPAN
1501 ( http://www.cpan.org/modules/by-module/Devel/ )
1502 for more information.
1503
1504 Having to even think about the C<$^S> variable in your exception
1505 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1506 invites grievous and difficult to track down errors.  Avoid it
1507 and use an C<END{}> or CORE::GLOBAL::die override instead.