This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Remove old Class-ISA remnants
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still current
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17
18 # directories with special sets of test switches
19 my %dir_to_switch =
20     (base => '',
21      comp => '',
22      run => '',
23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
24      );
25
26 # "not absolute" is the default, as it saves some fakery within TestInit
27 # which can perturb tests, and takes CPU. Working with the upstream author of
28 # any of these, to figure out how to remove them from this list, considered
29 # "a good thing".
30 my %abs = (
31            '../cpan/Archive-Tar' => 1,
32            '../cpan/AutoLoader' => 1,
33            '../cpan/CPAN' => 1,
34            '../cpan/Devel-PPPort' => 1,
35            '../cpan/Encode' => 1,
36            '../cpan/ExtUtils-Constant' => 1,
37            '../cpan/ExtUtils-MakeMaker' => 1,
38            '../cpan/File-Fetch' => 1,
39            '../cpan/IPC-Cmd' => 1,
40            '../cpan/IPC-SysV' => 1,
41            '../cpan/Locale-Codes' => 1,
42            '../cpan/Module-Load' => 1,
43            '../cpan/Module-Load-Conditional' => 1,
44            '../cpan/Parse-CPAN-Meta' => 1,
45            '../cpan/Pod-Simple' => 1,
46            '../cpan/Test-Simple' => 1,
47            '../cpan/podlators' => 1,
48            '../dist/Cwd' => 1,
49            '../dist/ExtUtils-Command' => 1,
50            '../dist/ExtUtils-Install' => 1,
51            '../dist/ExtUtils-Manifest' => 1,
52            '../dist/ExtUtils-ParseXS' => 1,
53            '../dist/Tie-File' => 1,
54           );
55
56 my %temp_no_core =
57     ('../cpan/B-Debug' => 1,
58      '../cpan/Compress-Raw-Bzip2' => 1,
59      '../cpan/Compress-Raw-Zlib' => 1,
60      '../cpan/Devel-PPPort' => 1,
61      '../cpan/Getopt-Long' => 1,
62      '../cpan/IO-Compress' => 1,
63      '../cpan/MIME-Base64' => 1,
64      '../cpan/parent' => 1,
65      '../cpan/Parse-CPAN-Meta' => 1,
66      '../cpan/Pod-Simple' => 1,
67      '../cpan/podlators' => 1,
68      '../cpan/Test-Simple' => 1,
69      '../cpan/Tie-RefHash' => 1,
70      '../cpan/Unicode-Collate' => 1,
71      '../cpan/Unicode-Normalize' => 1,
72     );
73
74 # delete env vars that may influence the results
75 # but allow override via *_TEST env var if wanted
76 # (e.g. PERL5OPT_TEST=-d:NYTProf)
77 my @bad_env_vars = qw(
78     PERL5LIB PERLLIB PERL5OPT
79     PERL_YAML_BACKEND PERL_JSON_BACKEND
80 );
81
82 for my $envname (@bad_env_vars) {
83     my $override = $ENV{"${envname}_TEST"};
84     if (defined $override) {
85         warn "$0: $envname=$override\n";
86         $ENV{$envname} = $override;
87     }
88     else {
89         delete $ENV{$envname};
90     }
91 }
92
93 # Location to put the Valgrind log.
94 our $Valgrind_Log;
95
96 my %skip = (
97             '.' => 1,
98             '..' => 1,
99             'CVS' => 1,
100             'RCS' => 1,
101             'SCCS' => 1,
102             '.svn' => 1,
103            );
104
105
106 if ($::do_nothing) {
107     return 1;
108 }
109
110 $| = 1;
111
112 # for testing TEST only
113 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
114 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
115
116 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
117 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
118 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
119
120 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
121 # can't rely on require working.
122 {
123     my @argv = ();
124     foreach my $idx (0..$#ARGV) {
125         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
126         $::benchmark = 1 if $1 eq 'benchmark';
127         $::core    = 1 if $1 eq 'core';
128         $::verbose = 1 if $1 eq 'v';
129         $::torture = 1 if $1 eq 'torture';
130         $::with_utf8 = 1 if $1 eq 'utf8';
131         $::with_utf16 = 1 if $1 eq 'utf16';
132         $::taintwarn = 1 if $1 eq 'taintwarn';
133         if ($1 =~ /^deparse(,.+)?$/) {
134             $::deparse = 1;
135             $::deparse_opts = $1;
136         }
137     }
138     @ARGV = @argv;
139 }
140
141 chdir 't' if -f 't/TEST';
142 if (-f 'TEST' && -f 'harness' && -d '../lib') {
143     @INC = '../lib';
144 }
145
146 die "You need to run \"make test\" first to set things up.\n"
147   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
148
149 # check leakage for embedders
150 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
151 # check existence of all symbols
152 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
153
154 $ENV{EMXSHELL} = 'sh';        # For OS/2
155
156 if ($show_elapsed_time) { require Time::HiRes }
157 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
158
159 # Roll your own File::Find!
160 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
161 sub _find_files {
162     my($patt, @dirs) = @_;
163     for my $dir (@dirs) {
164         opendir DIR, $dir or die "Trouble opening $dir: $!";
165         foreach my $f (sort { $a cmp $b } readdir DIR) {
166             next if $skip{$f};
167
168             my $fullpath = "$dir/$f";
169             
170             if (-d $fullpath) {
171                 _find_files($patt, $fullpath);
172             } elsif ($f =~ /$patt/) {
173                 push @found, $fullpath;
174             }
175         }
176     }
177     @found;
178 }
179
180
181 # Scan the text of the test program to find switches and special options
182 # we might need to apply.
183 sub _scan_test {
184     my($test, $type) = @_;
185
186     open(my $script, "<", $test) or die "Can't read $test.\n";
187     my $first_line = <$script>;
188
189     $first_line =~ tr/\0//d if $::with_utf16;
190
191     my $switch = "";
192     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
193         $switch = "-$1";
194     } else {
195         if ($::taintwarn) {
196             # not all tests are expected to pass with this option
197             $switch = '-t';
198         } else {
199             $switch = '';
200         }
201     }
202
203     my $file_opts = "";
204     if ($type eq 'deparse') {
205         # Look for #line directives which change the filename
206         while (<$script>) {
207             $file_opts = $file_opts . ",-f$3$4"
208               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
209         }
210     }
211
212     close $script;
213
214     my $perl = './perl';
215     my $lib  = '../lib';
216     my $run_dir;
217     my $return_dir;
218
219     $test =~ /^(.+)\/[^\/]+/;
220     my $dir = $1;
221     my $testswitch = $dir_to_switch{$dir};
222     if (!defined $testswitch) {
223         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
224             $run_dir = $1;
225             $return_dir = '../../t';
226             $lib = '../../lib';
227             $perl = '../../t/perl';
228             $testswitch = "-I../.. -MTestInit=U2T";
229             if ($2 eq 'cpan' || $2 eq 'dist') {
230                 if($abs{$run_dir}) {
231                     $testswitch = $testswitch . ',A';
232                 }
233                 if ($temp_no_core{$run_dir}) {
234                     $testswitch = $testswitch . ',NC';
235                 }
236             }
237         } elsif ($test =~ m!^\.\./lib!) {
238             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
239         } else {
240             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
241         }
242     }
243
244     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
245
246     my %options = (
247         perl => $perl,
248         lib => $lib,
249         test => $test,
250         run_dir => $run_dir,
251         return_dir => $return_dir,
252         testswitch => $testswitch,
253         utf8 => $utf8,
254         file => $file_opts,
255         switch => $switch,
256     );
257
258     return \%options;
259 }
260
261 sub _cmd {
262     my($options, $type) = @_;
263
264     my $test = $options->{test};
265
266     my $cmd;
267     if ($type eq 'deparse') {
268         my $perl = "$options->{perl} $options->{testswitch}";
269         my $lib = $options->{lib};
270
271         $cmd = (
272           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
273           "-l$::deparse_opts$options->{file} ".
274           "$test > $test.dp ".
275           "&& $perl $options->{switch} -I$lib $test.dp"
276         );
277     }
278     elsif ($type eq 'perl') {
279         my $perl = $options->{perl};
280         my $redir = $^O eq 'VMS' ? '2>&1' : '';
281
282         if ($ENV{PERL_VALGRIND}) {
283             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
284             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
285             if ($options->{run_dir}) {
286                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
287             }
288             my $vg_opts = $ENV{VG_OPTS}
289                //   "--log-file=$Valgrind_Log "
290                   . "--suppressions=$perl_supp --leak-check=yes "
291                   . "--leak-resolution=high --show-reachable=yes "
292                   . "--num-callers=50 --track-origins=yes";
293             # Force logging if not asked for (so cachegrind reporting works below)
294             if ($vg_opts !~ /--log-file/) {
295                 $vg_opts = "--log-file=$Valgrind_Log $vg_opts";
296             }
297             $perl = "$valgrind_exe $vg_opts $perl";
298         }
299
300         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
301         $cmd = $perl . _quote_args($args) . " $test $redir";
302     }
303     return $cmd;
304 }
305
306 sub _before_fork {
307     my ($options) = @_;
308
309     if ($options->{run_dir}) {
310         my $run_dir = $options->{run_dir};
311         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
312     }
313
314     # Remove previous valgrind output otherwise it will interfere
315     my $test = $options->{test};
316
317     (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
318
319     if ($ENV{PERL_VALGRIND} && -e $Valgrind_Log) {
320         unlink $Valgrind_Log
321             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
322     }
323
324     return;
325 }
326
327 sub _after_fork {
328     my ($options) = @_;
329
330     if ($options->{return_dir}) {
331         my $return_dir = $options->{return_dir};
332         chdir $return_dir
333            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
334     }
335
336     return;
337 }
338
339 sub _run_test {
340     my ($test, $type) = @_;
341
342     my $options = _scan_test($test, $type);
343     # $test might have changed if we're in ext/Foo, so don't use it anymore
344     # from now on. Use $options->{test} instead.
345
346     _before_fork($options);
347
348     my $cmd = _cmd($options, $type);
349
350     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
351
352     _after_fork($options);
353
354     # Our environment may force us to use UTF-8, but we can't be sure that
355     # anything we're reading from will be generating (well formed) UTF-8
356     # This may not be the best way - possibly we should unset ${^OPEN} up
357     # top?
358     binmode $results;
359
360     return $results;
361 }
362
363 sub _quote_args {
364     my ($args) = @_;
365     my $argstring = '';
366
367     foreach (split(/\s+/,$args)) {
368        # In VMS protect with doublequotes because otherwise
369        # DCL will lowercase -- unless already doublequoted.
370        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
371        $argstring = $argstring . ' ' . $_;
372     }
373     return $argstring;
374 }
375
376 sub _populate_hash {
377     return unless defined $_[0];
378     return map {$_, 1} split /\s+/, $_[0];
379 }
380
381 sub _tests_from_manifest {
382     my ($extensions, $known_extensions) = @_;
383     my %skip;
384     my %extensions = _populate_hash($extensions);
385     my %known_extensions = _populate_hash($known_extensions);
386
387     foreach (keys %known_extensions) {
388         $skip{$_} = 1 unless $extensions{$_};
389     }
390
391     my @results;
392     my $mani = '../MANIFEST';
393     if (open(MANI, $mani)) {
394         while (<MANI>) {
395             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
396                 my $t = $1;
397                 my $extension = $2;
398                 if (!$::core || $t =~ m!^lib/[a-z]!) {
399                     if (defined $extension) {
400                         $extension =~ s!/t(:?/\S+)*$!!;
401                         # XXX Do I want to warn that I'm skipping these?
402                         next if $skip{$extension};
403                         my $flat_extension = $extension;
404                         $flat_extension =~ s!-!/!g;
405                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
406                     }
407                     my $path = "../$t";
408                     push @results, $path;
409                     $::path_to_name{$path} = $t;
410                 }
411             }
412         }
413         close MANI;
414     } else {
415         warn "$0: cannot open $mani: $!\n";
416     }
417     return @results;
418 }
419
420 unless (@ARGV) {
421     # base first, as TEST bails out if that can't run
422     # then comp, to validate that require works
423     # then run, to validate that -M works
424     # then we know we can -MTestInit for everything else, making life simpler
425     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro)) {
426         _find_tests($dir);
427     }
428     unless ($::core) {
429         _find_tests('porting');
430         _find_tests("lib"); 
431     }
432     # Config.pm may be broken for make minitest. And this is only a refinement
433     # for skipping tests on non-default builds, so it is allowed to fail.
434     # What we want to to is make a list of extensions which we did not build.
435     my $configsh = '../config.sh';
436     my ($extensions, $known_extensions);
437     if (-f $configsh) {
438         open FH, $configsh or die "Can't open $configsh: $!";
439         while (<FH>) {
440             if (/^extensions=['"](.*)['"]$/) {
441                 $extensions = $1;
442             }
443             elsif (/^known_extensions=['"](.*)['"]$/) {
444                 $known_extensions = $1;
445             }
446         }
447         if (!defined $known_extensions) {
448             warn "No known_extensions line found in $configsh";
449         }
450         if (!defined $extensions) {
451             warn "No extensions line found in $configsh";
452         }
453     }
454     # The "complex" constructions of list return from a subroutine, and push of
455     # a list, might fail if perl is really hosed, but they aren't needed for
456     # make minitest, and the building of extensions will likely also fail if
457     # something is that badly wrong.
458     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
459     unless ($::core) {
460         _find_tests('japh') if $::torture;
461         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
462         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
463     }
464 }
465
466 if ($::deparse) {
467     _testprogs('deparse', '',   @ARGV);
468 }
469 elsif ($::with_utf16) {
470     for my $e (0, 1) {
471         for my $b (0, 1) {
472             print STDERR "# ENDIAN $e BOM $b\n";
473             my @UARGV;
474             for my $a (@ARGV) {
475                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
476                 my $f = $e ? "v" : "n";
477                 push @UARGV, $u;
478                 unlink($u);
479                 if (open(A, $a)) {
480                     if (open(U, ">$u")) {
481                         print U pack("$f", 0xFEFF) if $b;
482                         while (<A>) {
483                             print U pack("$f*", unpack("C*", $_));
484                         }
485                         close(U);
486                     }
487                     close(A);
488                 }
489             }
490             _testprogs('perl', '', @UARGV);
491             unlink(@UARGV);
492         }
493     }
494 }
495 else {
496     _testprogs('perl',    '',   @ARGV);
497 }
498
499 sub _testprogs {
500     my ($type, $args, @tests) = @_;
501
502     print <<'EOT' if ($type eq 'deparse');
503 ------------------------------------------------------------------------------
504 TESTING DEPARSER
505 ------------------------------------------------------------------------------
506 EOT
507
508     $::bad_files = 0;
509
510     foreach my $t (@tests) {
511       unless (exists $::path_to_name{$t}) {
512         my $tname = "t/$t";
513         $::path_to_name{$t} = $tname;
514       }
515     }
516     my $maxlen = 0;
517     foreach (@::path_to_name{@tests}) {
518         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
519         my $len = length ;
520         $maxlen = $len if $len > $maxlen;
521     }
522     # + 3 : we want three dots between the test name and the "ok"
523     my $dotdotdot = $maxlen + 3 ;
524     my $grind_ct = 0;           # count of non-empty valgrind reports
525     my $total_files = @tests;
526     my $good_files = 0;
527     my $tested_files  = 0;
528     my $totmax = 0;
529     my %failed_tests;
530     my $toolnm;         # valgrind, cachegrind, perf
531
532     while (my $test = shift @tests) {
533         my ($test_start_time, @starttimes) = 0;
534         if ($show_elapsed_time) {
535             $test_start_time = Time::HiRes::time();
536             # times() reports usage by TEST, but we want usage of each
537             # testprog it calls, so record accumulated times now,
538             # subtract them out afterwards.  Ideally, we'd take times
539             # in BEGIN/END blocks (giving better visibility of self vs
540             # children of each testprog), but that would require some
541             # IPC to send results back here, or a completely different
542             # collection scheme (Storable isn't tuned for incremental use)
543             @starttimes = times;
544         }
545         if ($test =~ /^$/) {
546             next;
547         }
548         if ($type eq 'deparse') {
549             if ($test eq "comp/redef.t") {
550                 # Redefinition happens at compile time
551                 next;
552             }
553             elsif ($test =~ m{lib/Switch/t/}) {
554                 # B::Deparse doesn't support source filtering
555                 next;
556             }
557         }
558         my $te = $::path_to_name{$test} . '.'
559                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
560
561         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
562             print $te;
563             $te = '';
564         }
565
566         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
567
568         my $results = _run_test($test, $type);
569
570         my $failure;
571         my $next = 0;
572         my $seen_leader = 0;
573         my $seen_ok = 0;
574         my $trailing_leader = 0;
575         my $max;
576         my %todo;
577         while (<$results>) {
578             next if /^\s*$/; # skip blank lines
579             if (/^1..$/ && ($^O eq 'VMS')) {
580                 # VMS pipe bug inserts blank lines.
581                 my $l2 = <$results>;
582                 if ($l2 =~ /^\s*$/) {
583                     $l2 = <$results>;
584                 }
585                 $_ = '1..' . $l2;
586             }
587             if ($::verbose) {
588                 print $_;
589             }
590             unless (/^\#/) {
591                 if ($trailing_leader) {
592                     # shouldn't be anything following a postfix 1..n
593                     $failure = 'FAILED--extra output after trailing 1..n';
594                     last;
595                 }
596                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
597                     if ($seen_leader) {
598                         $failure = 'FAILED--seen duplicate leader';
599                         last;
600                     }
601                     $max = $1;
602                     %todo = map { $_ => 1 } split / /, $3 if $3;
603                     $totmax = $totmax + $max;
604                     $tested_files = $tested_files + 1;
605                     if ($seen_ok) {
606                         # 1..n appears at end of file
607                         $trailing_leader = 1;
608                         if ($next != $max) {
609                             $failure = "FAILED--expected $max tests, saw $next";
610                             last;
611                         }
612                     }
613                     else {
614                         $next = 0;
615                     }
616                     $seen_leader = 1;
617                 }
618                 else {
619                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
620                         unless ($seen_leader) {
621                             unless ($seen_ok) {
622                                 $next = 0;
623                             }
624                         }
625                         $seen_ok = 1;
626                         $next = $next + 1;
627                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
628                         $num = $next unless $num;
629
630                         if ($num == $next) {
631
632                             # SKIP is essentially the same as TODO for t/TEST
633                             # this still conforms to TAP:
634                             # http://testanything.org/wiki/index.php/TAP_specification
635                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
636                             $istodo = 1 if $todo{$num};
637
638                             if( $not && !$istodo ) {
639                                 $failure = "FAILED at test $num";
640                                 last;
641                             }
642                         }
643                         else {
644                             $failure ="FAILED--expected test $next, saw test $num";
645                             last;
646                         }
647                     }
648                     elsif (/^Bail out!\s*(.*)/i) { # magic words
649                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
650                     }
651                     else {
652                         # module tests are allowed extra output,
653                         # because Test::Harness allows it
654                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
655                         $failure = "FAILED--unexpected output at test $next";
656                         last;
657                     }
658                 }
659             }
660         }
661         close $results;
662
663         if (not defined $failure) {
664             $failure = 'FAILED--no leader found' unless $seen_leader;
665         }
666
667         _check_valgrind(\$toolnm, \$grind_ct, \$test);
668
669         if ($type eq 'deparse') {
670             unlink "./$test.dp";
671         }
672         if (not defined $failure and $next != $max) {
673             $failure="FAILED--expected $max tests, saw $next";
674         }
675
676         if( !defined $failure  # don't mask a test failure
677             and $? )
678         {
679             $failure = "FAILED--non-zero wait status: $?";
680         }
681
682         if (defined $failure) {
683             print "${te}$failure\n";
684             $::bad_files = $::bad_files + 1;
685             if ($test =~ /^base/ && ! defined &DynaLoader::boot_DynaLoader) {
686                 # Die if running under minitest (no DynaLoader).  Otherwise
687                 # keep going, as  we know that Perl basically works, or we
688                 # would not have been able to actually compile it all the way.
689                 die "Failed a basic test ($test) under minitest -- cannot continue.\n";
690             }
691             $failed_tests{$test} = 1;
692         }
693         else {
694             if ($max) {
695                 my ($elapsed, $etms) = ("", 0);
696                 if ( $show_elapsed_time ) {
697                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
698                     $elapsed = sprintf(" %8.0f ms", $etms);
699
700                     my (@endtimes) = times;
701                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
702                     splice @endtimes, 0, 2;    # drop self/harness times
703                     $_ *= 1000 for @endtimes;  # and scale to ms
704                     $timings{$test} = [$etms,@endtimes];
705                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
706                 }
707                 print "${te}ok$elapsed\n";
708                 $good_files = $good_files + 1;
709             }
710             else {
711                 print "${te}skipped\n";
712                 $tested_files = $tested_files - 1;
713             }
714         }
715     } # while tests
716
717     if ($::bad_files == 0) {
718         if ($good_files) {
719             print "All tests successful.\n";
720             # XXX add mention of 'perlbug -ok' ?
721         }
722         else {
723             die "FAILED--no tests were run for some reason.\n";
724         }
725     }
726     else {
727         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
728         my $s = $::bad_files == 1 ? "" : "s";
729         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
730         for my $test ( sort keys %failed_tests ) {
731             print "\t$test\n";
732         }
733         warn <<'SHRDLU_1';
734 ### Since not all tests were successful, you may want to run some of
735 ### them individually and examine any diagnostic messages they produce.
736 ### See the INSTALL document's section on "make test".
737 SHRDLU_1
738         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
739 ### You have a good chance to get more information by running
740 ###   ./perl harness
741 ### in the 't' directory since most (>=80%) of the tests succeeded.
742 SHRDLU_2
743         if (eval {require Config; import Config; 1}) {
744             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
745                 warn <<SHRDLU_3;
746 ### You may have to set your dynamic library search path,
747 ### $p, to point to the build directory:
748 SHRDLU_3
749                 if (exists $ENV{$p} && $ENV{$p} ne '') {
750                     warn <<SHRDLU_4a;
751 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
752 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
753 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
754 SHRDLU_4a
755                 } else {
756                     warn <<SHRDLU_4b;
757 ###   setenv $p `pwd`; cd t; ./perl harness
758 ###   $p=`pwd`; export $p; cd t; ./perl harness
759 ###   export $p=`pwd`; cd t; ./perl harness
760 SHRDLU_4b
761                 }
762                 warn <<SHRDLU_5;
763 ### for csh-style shells, like tcsh; or for traditional/modern
764 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
765 SHRDLU_5
766             }
767         }
768     }
769     my ($user,$sys,$cuser,$csys) = times;
770     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
771                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
772     print "$tot\n";
773     if ($good_files) {
774         if (-d $show_elapsed_time) {
775             # HARNESS_TIMER = <a-directory>.  Save timings etc to
776             # storable file there.  NB: the test cds to ./t/, so
777             # relative path must account for that, ie ../../perf
778             # points to dir next to source tree.
779             require Storable;
780             my @dt = localtime;
781             $dt[5] += 1900; $dt[4] += 1; # fix year, month
782             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
783             Storable::store({ perf => \%timings,
784                               gather_conf_platform_info(),
785                               total => $tot,
786                             }, $fn);
787             print "wrote storable file: $fn\n";
788         }
789     }
790
791     _cleanup_valgrind(\$toolnm, \$grind_ct);
792 }
793 exit ($::bad_files != 0);
794
795 # Collect platform, config data that should allow comparing
796 # performance data between different machines.  With enough data,
797 # and/or clever statistical analysis, it should be possible to
798 # determine the effect of config choices, more memory, etc
799
800 sub gather_conf_platform_info {
801     # currently rather quick & dirty, and subject to change
802     # for both content and format.
803     require Config;
804     my (%conf, @platform) = ();
805     $conf{$_} = $Config::Config{$_} for
806         grep /cc|git|config_arg\d+/, keys %Config::Config;
807     if (-f '/proc/cpuinfo') {
808         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
809         @platform = grep /name|cpu/, <$fh>;
810         chomp $_ for @platform;
811     }
812     unshift @platform, $^O;
813
814     return (
815         conf => \%conf,
816         platform => {cpu => \@platform,
817                      mem => [ grep s/\s+/ /,
818                               grep chomp, `free` ],
819                      load => [ grep chomp, `uptime` ],
820         },
821         host => (grep chomp, `hostname -f`),
822         version => '0.03', # bump for conf, platform, or data collection changes
823         );
824 }
825
826 sub _check_valgrind {
827     return unless $ENV{PERL_VALGRIND};
828
829     my ($toolnm, $grind_ct, $test) = @_;
830
831     $$toolnm = $ENV{VALGRIND};
832     $$toolnm =~ s|.*/||;  # keep basename
833     my @valgrind;       # gets content of file
834     if (-e $Valgrind_Log) {
835         if (open(V, $Valgrind_Log)) {
836             @valgrind = <V>;
837             close V;
838         } else {
839             warn "$0: Failed to open '$Valgrind_Log': $!\n";
840         }
841     }
842     if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $$toolnm =~ /(perf)/) {
843         $$toolnm = $1;
844         if ($$toolnm eq 'perf') {
845             # append perfs subcommand, not just stat
846             my ($sub) = split /\s/, $ENV{VG_OPTS};
847             $$toolnm .= "-$sub";
848         }
849         if (rename $Valgrind_Log, "$$test.$$toolnm") {
850             $$grind_ct++;
851         } else {
852             warn "$0: Failed to create '$$test.$$toolnm': $!\n";
853         }
854     }
855     elsif (@valgrind) {
856         my $leaks = 0;
857         my $errors = 0;
858         for my $i (0..$#valgrind) {
859             local $_ = $valgrind[$i];
860             if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
861                 $errors = $errors + $1;   # there may be multiple error summaries
862             } elsif (/^==\d+== LEAK SUMMARY:/) {
863                 for my $off (1 .. 4) {
864                     if ($valgrind[$i+$off] =~
865                         /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
866                             $leaks = $leaks + $1;
867                     }
868                 }
869             }
870         }
871         if ($errors or $leaks) {
872             if (rename $Valgrind_Log, "$$test.valgrind") {
873                 $$grind_ct = $$grind_ct + 1;
874             } else {
875                 warn "$0: Failed to create '$$test.valgrind': $!\n";
876             }
877         }
878     } else {
879         # Quiet wasn't asked for? Something may be amiss
880         if ($ENV{VG_OPTS} && $ENV{VG_OPTS} !~ /(^|\s)(-q|--quiet)(\s|$)/) {
881             warn "No valgrind output?\n";
882         }
883     }
884     if (-e $Valgrind_Log) {
885         unlink $Valgrind_Log
886             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
887     }
888 }
889
890 sub _cleanup_valgrind {
891     return unless $ENV{PERL_VALGRIND};
892
893     my ($toolnm, $grind_ct) = @_;
894     my $s = $$grind_ct == 1 ? '' : 's';
895     print "$$grind_ct valgrind report$s created.\n", ;
896     if ($$toolnm eq 'cachegrind') {
897         # cachegrind leaves a lot of cachegrind.out.$pid litter
898         # around the tree, find and delete them
899         unlink _find_files('cachegrind.out.\d+$',
900                      qw ( ../t ../cpan ../ext ../dist/ ));
901     }
902 }
903
904 # ex: set ts=8 sts=4 sw=4 noet: