This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
some method calls not autoloaded
[perl5.git] / pod / perlsub.pod
1 =head1 NAME
2
3 perlsub - Perl subroutines
4
5 =head1 SYNOPSIS
6
7 To declare subroutines:
8
9     sub NAME;                     # A "forward" declaration.
10     sub NAME(PROTO);              #  ditto, but with prototypes
11     sub NAME : ATTRS;             #  with attributes
12     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
13
14     sub NAME BLOCK                # A declaration and a definition.
15     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
16     sub NAME : ATTRS BLOCK        #  with attributes
17     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
18
19 To define an anonymous subroutine at runtime:
20
21     $subref = sub BLOCK;                 # no proto
22     $subref = sub (PROTO) BLOCK;         # with proto
23     $subref = sub : ATTRS BLOCK;         # with attributes
24     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
25
26 To import subroutines:
27
28     use MODULE qw(NAME1 NAME2 NAME3);
29
30 To call subroutines:
31
32     NAME(LIST);    # & is optional with parentheses.
33     NAME LIST;     # Parentheses optional if predeclared/imported.
34     &NAME(LIST);   # Circumvent prototypes.
35     &NAME;         # Makes current @_ visible to called subroutine.
36
37 =head1 DESCRIPTION
38
39 Like many languages, Perl provides for user-defined subroutines.
40 These may be located anywhere in the main program, loaded in from
41 other files via the C<do>, C<require>, or C<use> keywords, or
42 generated on the fly using C<eval> or anonymous subroutines.
43 You can even call a function indirectly using a variable containing
44 its name or a CODE reference.
45
46 The Perl model for function call and return values is simple: all
47 functions are passed as parameters one single flat list of scalars, and
48 all functions likewise return to their caller one single flat list of
49 scalars.  Any arrays or hashes in these call and return lists will
50 collapse, losing their identities--but you may always use
51 pass-by-reference instead to avoid this.  Both call and return lists may
52 contain as many or as few scalar elements as you'd like.  (Often a
53 function without an explicit return statement is called a subroutine, but
54 there's really no difference from Perl's perspective.)
55
56 Any arguments passed in show up in the array C<@_>.  Therefore, if
57 you called a function with two arguments, those would be stored in
58 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
59 elements are aliases for the actual scalar parameters.  In particular,
60 if an element C<$_[0]> is updated, the corresponding argument is
61 updated (or an error occurs if it is not updatable).  If an argument
62 is an array or hash element which did not exist when the function
63 was called, that element is created only when (and if) it is modified
64 or a reference to it is taken.  (Some earlier versions of Perl
65 created the element whether or not the element was assigned to.)
66 Assigning to the whole array C<@_> removes that aliasing, and does
67 not update any arguments.
68
69 The return value of a subroutine is the value of the last expression
70 evaluated.  More explicitly, a C<return> statement may be used to exit the
71 subroutine, optionally specifying the returned value, which will be
72 evaluated in the appropriate context (list, scalar, or void) depending
73 on the context of the subroutine call.  If you specify no return value,
74 the subroutine returns an empty list in list context, the undefined
75 value in scalar context, or nothing in void context.  If you return
76 one or more aggregates (arrays and hashes), these will be flattened
77 together into one large indistinguishable list.
78
79 Perl does not have named formal parameters.  In practice all you
80 do is assign to a C<my()> list of these.  Variables that aren't
81 declared to be private are global variables.  For gory details
82 on creating private variables, see L<"Private Variables via my()">
83 and L<"Temporary Values via local()">.  To create protected
84 environments for a set of functions in a separate package (and
85 probably a separate file), see L<perlmod/"Packages">.
86
87 Example:
88
89     sub max {
90         my $max = shift(@_);
91         foreach $foo (@_) {
92             $max = $foo if $max < $foo;
93         }
94         return $max;
95     }
96     $bestday = max($mon,$tue,$wed,$thu,$fri);
97
98 Example:
99
100     # get a line, combining continuation lines
101     #  that start with whitespace
102
103     sub get_line {
104         $thisline = $lookahead;  # global variables!
105         LINE: while (defined($lookahead = <STDIN>)) {
106             if ($lookahead =~ /^[ \t]/) {
107                 $thisline .= $lookahead;
108             }
109             else {
110                 last LINE;
111             }
112         }
113         return $thisline;
114     }
115
116     $lookahead = <STDIN>;       # get first line
117     while (defined($line = get_line())) {
118         ...
119     }
120
121 Assigning to a list of private variables to name your arguments:
122
123     sub maybeset {
124         my($key, $value) = @_;
125         $Foo{$key} = $value unless $Foo{$key};
126     }
127
128 Because the assignment copies the values, this also has the effect
129 of turning call-by-reference into call-by-value.  Otherwise a
130 function is free to do in-place modifications of C<@_> and change
131 its caller's values.
132
133     upcase_in($v1, $v2);  # this changes $v1 and $v2
134     sub upcase_in {
135         for (@_) { tr/a-z/A-Z/ }
136     }
137
138 You aren't allowed to modify constants in this way, of course.  If an
139 argument were actually literal and you tried to change it, you'd take a
140 (presumably fatal) exception.   For example, this won't work:
141
142     upcase_in("frederick");
143
144 It would be much safer if the C<upcase_in()> function
145 were written to return a copy of its parameters instead
146 of changing them in place:
147
148     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
149     sub upcase {
150         return unless defined wantarray;  # void context, do nothing
151         my @parms = @_;
152         for (@parms) { tr/a-z/A-Z/ }
153         return wantarray ? @parms : $parms[0];
154     }
155
156 Notice how this (unprototyped) function doesn't care whether it was
157 passed real scalars or arrays.  Perl sees all arguments as one big,
158 long, flat parameter list in C<@_>.  This is one area where
159 Perl's simple argument-passing style shines.  The C<upcase()>
160 function would work perfectly well without changing the C<upcase()>
161 definition even if we fed it things like this:
162
163     @newlist   = upcase(@list1, @list2);
164     @newlist   = upcase( split /:/, $var );
165
166 Do not, however, be tempted to do this:
167
168     (@a, @b)   = upcase(@list1, @list2);
169
170 Like the flattened incoming parameter list, the return list is also
171 flattened on return.  So all you have managed to do here is stored
172 everything in C<@a> and made C<@b> empty.  See 
173 L<Pass by Reference> for alternatives.
174
175 A subroutine may be called using an explicit C<&> prefix.  The
176 C<&> is optional in modern Perl, as are parentheses if the
177 subroutine has been predeclared.  The C<&> is I<not> optional
178 when just naming the subroutine, such as when it's used as
179 an argument to defined() or undef().  Nor is it optional when you
180 want to do an indirect subroutine call with a subroutine name or
181 reference using the C<&$subref()> or C<&{$subref}()> constructs,
182 although the C<< $subref->() >> notation solves that problem.
183 See L<perlref> for more about all that.
184
185 Subroutines may be called recursively.  If a subroutine is called
186 using the C<&> form, the argument list is optional, and if omitted,
187 no C<@_> array is set up for the subroutine: the C<@_> array at the
188 time of the call is visible to subroutine instead.  This is an
189 efficiency mechanism that new users may wish to avoid.
190
191     &foo(1,2,3);        # pass three arguments
192     foo(1,2,3);         # the same
193
194     foo();              # pass a null list
195     &foo();             # the same
196
197     &foo;               # foo() get current args, like foo(@_) !!
198     foo;                # like foo() IFF sub foo predeclared, else "foo"
199
200 Not only does the C<&> form make the argument list optional, it also
201 disables any prototype checking on arguments you do provide.  This
202 is partly for historical reasons, and partly for having a convenient way
203 to cheat if you know what you're doing.  See L<Prototypes> below.
204
205 Functions whose names are in all upper case are reserved to the Perl
206 core, as are modules whose names are in all lower case.  A
207 function in all capitals is a loosely-held convention meaning it
208 will be called indirectly by the run-time system itself, usually
209 due to a triggered event.  Functions that do special, pre-defined
210 things include C<BEGIN>, C<CHECK>, C<INIT>, C<END>, C<AUTOLOAD>,
211 C<CLONE> and C<DESTROY>--plus all functions mentioned in L<perltie>.
212
213 =head2 Private Variables via my()
214
215 Synopsis:
216
217     my $foo;            # declare $foo lexically local
218     my (@wid, %get);    # declare list of variables local
219     my $foo = "flurp";  # declare $foo lexical, and init it
220     my @oof = @bar;     # declare @oof lexical, and init it
221     my $x : Foo = $y;   # similar, with an attribute applied
222
223 B<WARNING>: The use of attribute lists on C<my> declarations is still
224 evolving.  The current semantics and interface are subject to change.
225 See L<attributes> and L<Attribute::Handlers>.
226
227 The C<my> operator declares the listed variables to be lexically
228 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
229 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
230 or C<do/require/use>'d file.  If more than one value is listed, the
231 list must be placed in parentheses.  All listed elements must be
232 legal lvalues.  Only alphanumeric identifiers may be lexically
233 scoped--magical built-ins like C<$/> must currently be C<local>ize
234 with C<local> instead.
235
236 Unlike dynamic variables created by the C<local> operator, lexical
237 variables declared with C<my> are totally hidden from the outside
238 world, including any called subroutines.  This is true if it's the
239 same subroutine called from itself or elsewhere--every call gets
240 its own copy.
241
242 This doesn't mean that a C<my> variable declared in a statically
243 enclosing lexical scope would be invisible.  Only dynamic scopes
244 are cut off.   For example, the C<bumpx()> function below has access
245 to the lexical $x variable because both the C<my> and the C<sub>
246 occurred at the same scope, presumably file scope.
247
248     my $x = 10;
249     sub bumpx { $x++ } 
250
251 An C<eval()>, however, can see lexical variables of the scope it is
252 being evaluated in, so long as the names aren't hidden by declarations within
253 the C<eval()> itself.  See L<perlref>.
254
255 The parameter list to my() may be assigned to if desired, which allows you
256 to initialize your variables.  (If no initializer is given for a
257 particular variable, it is created with the undefined value.)  Commonly
258 this is used to name input parameters to a subroutine.  Examples:
259
260     $arg = "fred";        # "global" variable
261     $n = cube_root(27);
262     print "$arg thinks the root is $n\n";
263  fred thinks the root is 3
264
265     sub cube_root {
266         my $arg = shift;  # name doesn't matter
267         $arg **= 1/3;
268         return $arg;
269     }
270
271 The C<my> is simply a modifier on something you might assign to.  So when
272 you do assign to variables in its argument list, C<my> doesn't
273 change whether those variables are viewed as a scalar or an array.  So
274
275     my ($foo) = <STDIN>;                # WRONG?
276     my @FOO = <STDIN>;
277
278 both supply a list context to the right-hand side, while
279
280     my $foo = <STDIN>;
281
282 supplies a scalar context.  But the following declares only one variable:
283
284     my $foo, $bar = 1;                  # WRONG
285
286 That has the same effect as
287
288     my $foo;
289     $bar = 1;
290
291 The declared variable is not introduced (is not visible) until after
292 the current statement.  Thus,
293
294     my $x = $x;
295
296 can be used to initialize a new $x with the value of the old $x, and
297 the expression
298
299     my $x = 123 and $x == 123
300
301 is false unless the old $x happened to have the value C<123>.
302
303 Lexical scopes of control structures are not bounded precisely by the
304 braces that delimit their controlled blocks; control expressions are
305 part of that scope, too.  Thus in the loop
306
307     while (my $line = <>) {
308         $line = lc $line;
309     } continue {
310         print $line;
311     }
312
313 the scope of $line extends from its declaration throughout the rest of
314 the loop construct (including the C<continue> clause), but not beyond
315 it.  Similarly, in the conditional
316
317     if ((my $answer = <STDIN>) =~ /^yes$/i) {
318         user_agrees();
319     } elsif ($answer =~ /^no$/i) {
320         user_disagrees();
321     } else {
322         chomp $answer;
323         die "'$answer' is neither 'yes' nor 'no'";
324     }
325
326 the scope of $answer extends from its declaration through the rest
327 of that conditional, including any C<elsif> and C<else> clauses, 
328 but not beyond it.  See L<perlsyn/"Simple statements"> for information
329 on the scope of variables in statements with modifiers.
330
331 The C<foreach> loop defaults to scoping its index variable dynamically
332 in the manner of C<local>.  However, if the index variable is
333 prefixed with the keyword C<my>, or if there is already a lexical
334 by that name in scope, then a new lexical is created instead.  Thus
335 in the loop
336
337     for my $i (1, 2, 3) {
338         some_function();
339     }
340
341 the scope of $i extends to the end of the loop, but not beyond it,
342 rendering the value of $i inaccessible within C<some_function()>.
343
344 Some users may wish to encourage the use of lexically scoped variables.
345 As an aid to catching implicit uses to package variables,
346 which are always global, if you say
347
348     use strict 'vars';
349
350 then any variable mentioned from there to the end of the enclosing
351 block must either refer to a lexical variable, be predeclared via
352 C<our> or C<use vars>, or else must be fully qualified with the package name.
353 A compilation error results otherwise.  An inner block may countermand
354 this with C<no strict 'vars'>.
355
356 A C<my> has both a compile-time and a run-time effect.  At compile
357 time, the compiler takes notice of it.  The principal usefulness
358 of this is to quiet C<use strict 'vars'>, but it is also essential
359 for generation of closures as detailed in L<perlref>.  Actual
360 initialization is delayed until run time, though, so it gets executed
361 at the appropriate time, such as each time through a loop, for
362 example.
363
364 Variables declared with C<my> are not part of any package and are therefore
365 never fully qualified with the package name.  In particular, you're not
366 allowed to try to make a package variable (or other global) lexical:
367
368     my $pack::var;      # ERROR!  Illegal syntax
369     my $_;              # also illegal (currently)
370
371 In fact, a dynamic variable (also known as package or global variables)
372 are still accessible using the fully qualified C<::> notation even while a
373 lexical of the same name is also visible:
374
375     package main;
376     local $x = 10;
377     my    $x = 20;
378     print "$x and $::x\n";
379
380 That will print out C<20> and C<10>.
381
382 You may declare C<my> variables at the outermost scope of a file
383 to hide any such identifiers from the world outside that file.  This
384 is similar in spirit to C's static variables when they are used at
385 the file level.  To do this with a subroutine requires the use of
386 a closure (an anonymous function that accesses enclosing lexicals).
387 If you want to create a private subroutine that cannot be called
388 from outside that block, it can declare a lexical variable containing
389 an anonymous sub reference:
390
391     my $secret_version = '1.001-beta';
392     my $secret_sub = sub { print $secret_version };
393     &$secret_sub();
394
395 As long as the reference is never returned by any function within the
396 module, no outside module can see the subroutine, because its name is not in
397 any package's symbol table.  Remember that it's not I<REALLY> called
398 C<$some_pack::secret_version> or anything; it's just $secret_version,
399 unqualified and unqualifiable.
400
401 This does not work with object methods, however; all object methods
402 have to be in the symbol table of some package to be found.  See
403 L<perlref/"Function Templates"> for something of a work-around to
404 this.
405
406 =head2 Persistent Private Variables
407
408 Just because a lexical variable is lexically (also called statically)
409 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
410 within a function it works like a C static.  It normally works more
411 like a C auto, but with implicit garbage collection.  
412
413 Unlike local variables in C or C++, Perl's lexical variables don't
414 necessarily get recycled just because their scope has exited.
415 If something more permanent is still aware of the lexical, it will
416 stick around.  So long as something else references a lexical, that
417 lexical won't be freed--which is as it should be.  You wouldn't want
418 memory being free until you were done using it, or kept around once you
419 were done.  Automatic garbage collection takes care of this for you.
420
421 This means that you can pass back or save away references to lexical
422 variables, whereas to return a pointer to a C auto is a grave error.
423 It also gives us a way to simulate C's function statics.  Here's a
424 mechanism for giving a function private variables with both lexical
425 scoping and a static lifetime.  If you do want to create something like
426 C's static variables, just enclose the whole function in an extra block,
427 and put the static variable outside the function but in the block.
428
429     {
430         my $secret_val = 0;
431         sub gimme_another {
432             return ++$secret_val;
433         }
434     }
435     # $secret_val now becomes unreachable by the outside
436     # world, but retains its value between calls to gimme_another
437
438 If this function is being sourced in from a separate file
439 via C<require> or C<use>, then this is probably just fine.  If it's
440 all in the main program, you'll need to arrange for the C<my>
441 to be executed early, either by putting the whole block above
442 your main program, or more likely, placing merely a C<BEGIN>
443 sub around it to make sure it gets executed before your program
444 starts to run:
445
446     sub BEGIN {
447         my $secret_val = 0;
448         sub gimme_another {
449             return ++$secret_val;
450         }
451     }
452
453 See L<perlmod/"Package Constructors and Destructors"> about the
454 special triggered functions, C<BEGIN>, C<CHECK>, C<INIT> and C<END>.
455
456 If declared at the outermost scope (the file scope), then lexicals
457 work somewhat like C's file statics.  They are available to all
458 functions in that same file declared below them, but are inaccessible
459 from outside that file.  This strategy is sometimes used in modules
460 to create private variables that the whole module can see.
461
462 =head2 Temporary Values via local()
463
464 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
465 it's faster and safer.  Exceptions to this include the global punctuation
466 variables, filehandles and formats, and direct manipulation of the Perl
467 symbol table itself.  Format variables often use C<local> though, as do
468 other variables whose current value must be visible to called
469 subroutines.
470
471 Synopsis:
472
473     local $foo;                 # declare $foo dynamically local
474     local (@wid, %get);         # declare list of variables local
475     local $foo = "flurp";       # declare $foo dynamic, and init it
476     local @oof = @bar;          # declare @oof dynamic, and init it
477
478     local *FH;                  # localize $FH, @FH, %FH, &FH  ...
479     local *merlyn = *randal;    # now $merlyn is really $randal, plus
480                                 #     @merlyn is really @randal, etc
481     local *merlyn = 'randal';   # SAME THING: promote 'randal' to *randal
482     local *merlyn = \$randal;   # just alias $merlyn, not @merlyn etc
483
484 A C<local> modifies its listed variables to be "local" to the
485 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
486 called from within that block>.  A C<local> just gives temporary
487 values to global (meaning package) variables.  It does I<not> create
488 a local variable.  This is known as dynamic scoping.  Lexical scoping
489 is done with C<my>, which works more like C's auto declarations.
490
491 If more than one variable is given to C<local>, they must be placed in
492 parentheses.  All listed elements must be legal lvalues.  This operator works
493 by saving the current values of those variables in its argument list on a
494 hidden stack and restoring them upon exiting the block, subroutine, or
495 eval.  This means that called subroutines can also reference the local
496 variable, but not the global one.  The argument list may be assigned to if
497 desired, which allows you to initialize your local variables.  (If no
498 initializer is given for a particular variable, it is created with an
499 undefined value.)  Commonly this is used to name the parameters to a
500 subroutine.  Examples:
501
502     for $i ( 0 .. 9 ) {
503         $digits{$i} = $i;
504     }
505     # assume this function uses global %digits hash
506     parse_num();
507
508     # now temporarily add to %digits hash
509     if ($base12) {
510         # (NOTE: not claiming this is efficient!)
511         local %digits  = (%digits, 't' => 10, 'e' => 11);
512         parse_num();  # parse_num gets this new %digits!
513     }
514     # old %digits restored here
515
516 Because C<local> is a run-time operator, it gets executed each time
517 through a loop.  In releases of Perl previous to 5.0, this used more stack
518 storage each time until the loop was exited.  Perl now reclaims the space
519 each time through, but it's still more efficient to declare your variables
520 outside the loop.
521
522 A C<local> is simply a modifier on an lvalue expression.  When you assign to
523 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
524 as a scalar or an array.  So
525
526     local($foo) = <STDIN>;
527     local @FOO = <STDIN>;
528
529 both supply a list context to the right-hand side, while
530
531     local $foo = <STDIN>;
532
533 supplies a scalar context.
534
535 A note about C<local()> and composite types is in order.  Something
536 like C<local(%foo)> works by temporarily placing a brand new hash in
537 the symbol table.  The old hash is left alone, but is hidden "behind"
538 the new one.
539
540 This means the old variable is completely invisible via the symbol
541 table (i.e. the hash entry in the C<*foo> typeglob) for the duration
542 of the dynamic scope within which the C<local()> was seen.  This
543 has the effect of allowing one to temporarily occlude any magic on
544 composite types.  For instance, this will briefly alter a tied
545 hash to some other implementation:
546
547     tie %ahash, 'APackage';
548     [...]
549     {
550        local %ahash;
551        tie %ahash, 'BPackage';
552        [..called code will see %ahash tied to 'BPackage'..]
553        {
554           local %ahash;
555           [..%ahash is a normal (untied) hash here..]
556        }
557     }
558     [..%ahash back to its initial tied self again..]
559
560 B<WARNING> The code example above does not currently work as described.
561 This will be fixed in a future release of Perl; in the meantime, avoid
562 code that relies on any particular behaviour of localising tied arrays
563 or hashes (localising individual elements is still okay).
564 See L<perldelta/"Localising Tied Arrays and Hashes Is Broken"> for more
565 details.
566
567 As another example, a custom implementation of C<%ENV> might look
568 like this:
569
570     {
571         local %ENV;
572         tie %ENV, 'MyOwnEnv';
573         [..do your own fancy %ENV manipulation here..]
574     }
575     [..normal %ENV behavior here..]
576
577 It's also worth taking a moment to explain what happens when you
578 C<local>ize a member of a composite type (i.e. an array or hash element).
579 In this case, the element is C<local>ized I<by name>. This means that
580 when the scope of the C<local()> ends, the saved value will be
581 restored to the hash element whose key was named in the C<local()>, or
582 the array element whose index was named in the C<local()>.  If that
583 element was deleted while the C<local()> was in effect (e.g. by a
584 C<delete()> from a hash or a C<shift()> of an array), it will spring
585 back into existence, possibly extending an array and filling in the
586 skipped elements with C<undef>.  For instance, if you say
587
588     %hash = ( 'This' => 'is', 'a' => 'test' );
589     @ary  = ( 0..5 );
590     {
591          local($ary[5]) = 6;
592          local($hash{'a'}) = 'drill';
593          while (my $e = pop(@ary)) {
594              print "$e . . .\n";
595              last unless $e > 3;
596          }
597          if (@ary) {
598              $hash{'only a'} = 'test';
599              delete $hash{'a'};
600          }
601     }
602     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
603     print "The array has ",scalar(@ary)," elements: ",
604           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
605
606 Perl will print
607
608     6 . . .
609     4 . . .
610     3 . . .
611     This is a test only a test.
612     The array has 6 elements: 0, 1, 2, undef, undef, 5
613
614 The behavior of local() on non-existent members of composite
615 types is subject to change in future.
616
617 =head2 Lvalue subroutines
618
619 B<WARNING>: Lvalue subroutines are still experimental and the
620 implementation may change in future versions of Perl.
621
622 It is possible to return a modifiable value from a subroutine.
623 To do this, you have to declare the subroutine to return an lvalue.
624
625     my $val;
626     sub canmod : lvalue {
627         # return $val; this doesn't work, don't say "return"
628         $val;
629     }
630     sub nomod {
631         $val;
632     }
633
634     canmod() = 5;   # assigns to $val
635     nomod()  = 5;   # ERROR
636
637 The scalar/list context for the subroutine and for the right-hand
638 side of assignment is determined as if the subroutine call is replaced
639 by a scalar. For example, consider:
640
641     data(2,3) = get_data(3,4);
642
643 Both subroutines here are called in a scalar context, while in:
644
645     (data(2,3)) = get_data(3,4);
646
647 and in:
648
649     (data(2),data(3)) = get_data(3,4);
650
651 all the subroutines are called in a list context.
652
653 =over 4
654
655 =item Lvalue subroutines are EXPERIMENTAL
656
657 They appear to be convenient, but there are several reasons to be
658 circumspect.
659
660 You can't use the return keyword, you must pass out the value before
661 falling out of subroutine scope. (see comment in example above).  This
662 is usually not a problem, but it disallows an explicit return out of a
663 deeply nested loop, which is sometimes a nice way out.
664
665 They violate encapsulation.  A normal mutator can check the supplied
666 argument before setting the attribute it is protecting, an lvalue
667 subroutine never gets that chance.  Consider;
668
669     my $some_array_ref = [];    # protected by mutators ??
670
671     sub set_arr {               # normal mutator
672         my $val = shift;
673         die("expected array, you supplied ", ref $val)
674            unless ref $val eq 'ARRAY';
675         $some_array_ref = $val;
676     }
677     sub set_arr_lv : lvalue {   # lvalue mutator
678         $some_array_ref;
679     }
680
681     # set_arr_lv cannot stop this !
682     set_arr_lv() = { a => 1 };
683
684 =back
685
686 =head2 Passing Symbol Table Entries (typeglobs)
687
688 B<WARNING>: The mechanism described in this section was originally
689 the only way to simulate pass-by-reference in older versions of
690 Perl.  While it still works fine in modern versions, the new reference
691 mechanism is generally easier to work with.  See below.
692
693 Sometimes you don't want to pass the value of an array to a subroutine
694 but rather the name of it, so that the subroutine can modify the global
695 copy of it rather than working with a local copy.  In perl you can
696 refer to all objects of a particular name by prefixing the name
697 with a star: C<*foo>.  This is often known as a "typeglob", because the
698 star on the front can be thought of as a wildcard match for all the
699 funny prefix characters on variables and subroutines and such.
700
701 When evaluated, the typeglob produces a scalar value that represents
702 all the objects of that name, including any filehandle, format, or
703 subroutine.  When assigned to, it causes the name mentioned to refer to
704 whatever C<*> value was assigned to it.  Example:
705
706     sub doubleary {
707         local(*someary) = @_;
708         foreach $elem (@someary) {
709             $elem *= 2;
710         }
711     }
712     doubleary(*foo);
713     doubleary(*bar);
714
715 Scalars are already passed by reference, so you can modify
716 scalar arguments without using this mechanism by referring explicitly
717 to C<$_[0]> etc.  You can modify all the elements of an array by passing
718 all the elements as scalars, but you have to use the C<*> mechanism (or
719 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
720 an array.  It will certainly be faster to pass the typeglob (or reference).
721
722 Even if you don't want to modify an array, this mechanism is useful for
723 passing multiple arrays in a single LIST, because normally the LIST
724 mechanism will merge all the array values so that you can't extract out
725 the individual arrays.  For more on typeglobs, see
726 L<perldata/"Typeglobs and Filehandles">.
727
728 =head2 When to Still Use local()
729
730 Despite the existence of C<my>, there are still three places where the
731 C<local> operator still shines.  In fact, in these three places, you
732 I<must> use C<local> instead of C<my>.
733
734 =over 4
735
736 =item 1.
737
738 You need to give a global variable a temporary value, especially $_.
739
740 The global variables, like C<@ARGV> or the punctuation variables, must be 
741 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
742 it up into chunks separated by lines of equal signs, which are placed
743 in C<@Fields>.
744
745     {
746         local @ARGV = ("/etc/motd");
747         local $/ = undef;
748         local $_ = <>;  
749         @Fields = split /^\s*=+\s*$/;
750     } 
751
752 It particular, it's important to C<local>ize $_ in any routine that assigns
753 to it.  Look out for implicit assignments in C<while> conditionals.
754
755 =item 2.
756
757 You need to create a local file or directory handle or a local function.
758
759 A function that needs a filehandle of its own must use
760 C<local()> on a complete typeglob.   This can be used to create new symbol
761 table entries:
762
763     sub ioqueue {
764         local  (*READER, *WRITER);    # not my!
765         pipe    (READER,  WRITER)     or die "pipe: $!";
766         return (*READER, *WRITER);
767     }
768     ($head, $tail) = ioqueue();
769
770 See the Symbol module for a way to create anonymous symbol table
771 entries.
772
773 Because assignment of a reference to a typeglob creates an alias, this
774 can be used to create what is effectively a local function, or at least,
775 a local alias.
776
777     {
778         local *grow = \&shrink; # only until this block exists
779         grow();                 # really calls shrink()
780         move();                 # if move() grow()s, it shrink()s too
781     }
782     grow();                     # get the real grow() again
783
784 See L<perlref/"Function Templates"> for more about manipulating
785 functions by name in this way.
786
787 =item 3.
788
789 You want to temporarily change just one element of an array or hash.
790
791 You can C<local>ize just one element of an aggregate.  Usually this
792 is done on dynamics:
793
794     {
795         local $SIG{INT} = 'IGNORE';
796         funct();                            # uninterruptible
797     } 
798     # interruptibility automatically restored here
799
800 But it also works on lexically declared aggregates.  Prior to 5.005,
801 this operation could on occasion misbehave.
802
803 =back
804
805 =head2 Pass by Reference
806
807 If you want to pass more than one array or hash into a function--or
808 return them from it--and have them maintain their integrity, then
809 you're going to have to use an explicit pass-by-reference.  Before you
810 do that, you need to understand references as detailed in L<perlref>.
811 This section may not make much sense to you otherwise.
812
813 Here are a few simple examples.  First, let's pass in several arrays
814 to a function and have it C<pop> all of then, returning a new list
815 of all their former last elements:
816
817     @tailings = popmany ( \@a, \@b, \@c, \@d );
818
819     sub popmany {
820         my $aref;
821         my @retlist = ();
822         foreach $aref ( @_ ) {
823             push @retlist, pop @$aref;
824         }
825         return @retlist;
826     }
827
828 Here's how you might write a function that returns a
829 list of keys occurring in all the hashes passed to it:
830
831     @common = inter( \%foo, \%bar, \%joe );
832     sub inter {
833         my ($k, $href, %seen); # locals
834         foreach $href (@_) {
835             while ( $k = each %$href ) {
836                 $seen{$k}++;
837             }
838         }
839         return grep { $seen{$_} == @_ } keys %seen;
840     }
841
842 So far, we're using just the normal list return mechanism.
843 What happens if you want to pass or return a hash?  Well,
844 if you're using only one of them, or you don't mind them
845 concatenating, then the normal calling convention is ok, although
846 a little expensive.
847
848 Where people get into trouble is here:
849
850     (@a, @b) = func(@c, @d);
851 or
852     (%a, %b) = func(%c, %d);
853
854 That syntax simply won't work.  It sets just C<@a> or C<%a> and
855 clears the C<@b> or C<%b>.  Plus the function didn't get passed
856 into two separate arrays or hashes: it got one long list in C<@_>,
857 as always.
858
859 If you can arrange for everyone to deal with this through references, it's
860 cleaner code, although not so nice to look at.  Here's a function that
861 takes two array references as arguments, returning the two array elements
862 in order of how many elements they have in them:
863
864     ($aref, $bref) = func(\@c, \@d);
865     print "@$aref has more than @$bref\n";
866     sub func {
867         my ($cref, $dref) = @_;
868         if (@$cref > @$dref) {
869             return ($cref, $dref);
870         } else {
871             return ($dref, $cref);
872         }
873     }
874
875 It turns out that you can actually do this also:
876
877     (*a, *b) = func(\@c, \@d);
878     print "@a has more than @b\n";
879     sub func {
880         local (*c, *d) = @_;
881         if (@c > @d) {
882             return (\@c, \@d);
883         } else {
884             return (\@d, \@c);
885         }
886     }
887
888 Here we're using the typeglobs to do symbol table aliasing.  It's
889 a tad subtle, though, and also won't work if you're using C<my>
890 variables, because only globals (even in disguise as C<local>s)
891 are in the symbol table.
892
893 If you're passing around filehandles, you could usually just use the bare
894 typeglob, like C<*STDOUT>, but typeglobs references work, too.
895 For example:
896
897     splutter(\*STDOUT);
898     sub splutter {
899         my $fh = shift;
900         print $fh "her um well a hmmm\n";
901     }
902
903     $rec = get_rec(\*STDIN);
904     sub get_rec {
905         my $fh = shift;
906         return scalar <$fh>;
907     }
908
909 If you're planning on generating new filehandles, you could do this.
910 Notice to pass back just the bare *FH, not its reference.
911
912     sub openit {
913         my $path = shift;
914         local *FH;
915         return open (FH, $path) ? *FH : undef;
916     }
917
918 =head2 Prototypes
919
920 Perl supports a very limited kind of compile-time argument checking
921 using function prototyping.  If you declare
922
923     sub mypush (\@@)
924
925 then C<mypush()> takes arguments exactly like C<push()> does.  The
926 function declaration must be visible at compile time.  The prototype
927 affects only interpretation of new-style calls to the function,
928 where new-style is defined as not using the C<&> character.  In
929 other words, if you call it like a built-in function, then it behaves
930 like a built-in function.  If you call it like an old-fashioned
931 subroutine, then it behaves like an old-fashioned subroutine.  It
932 naturally falls out from this rule that prototypes have no influence
933 on subroutine references like C<\&foo> or on indirect subroutine
934 calls like C<&{$subref}> or C<< $subref->() >>.
935
936 Method calls are not influenced by prototypes either, because the
937 function to be called is indeterminate at compile time, since
938 the exact code called depends on inheritance.
939
940 Because the intent of this feature is primarily to let you define
941 subroutines that work like built-in functions, here are prototypes
942 for some other functions that parse almost exactly like the
943 corresponding built-in.
944
945     Declared as                 Called as
946
947     sub mylink ($$)          mylink $old, $new
948     sub myvec ($$$)          myvec $var, $offset, 1
949     sub myindex ($$;$)       myindex &getstring, "substr"
950     sub mysyswrite ($$$;$)   mysyswrite $buf, 0, length($buf) - $off, $off
951     sub myreverse (@)        myreverse $a, $b, $c
952     sub myjoin ($@)          myjoin ":", $a, $b, $c
953     sub mypop (\@)           mypop @array
954     sub mysplice (\@$$@)     mysplice @array, @array, 0, @pushme
955     sub mykeys (\%)          mykeys %{$hashref}
956     sub myopen (*;$)         myopen HANDLE, $name
957     sub mypipe (**)          mypipe READHANDLE, WRITEHANDLE
958     sub mygrep (&@)          mygrep { /foo/ } $a, $b, $c
959     sub myrand ($)           myrand 42
960     sub mytime ()            mytime
961
962 Any backslashed prototype character represents an actual argument
963 that absolutely must start with that character.  The value passed
964 as part of C<@_> will be a reference to the actual argument given
965 in the subroutine call, obtained by applying C<\> to that argument.
966
967 You can also backslash several argument types simultaneously by using
968 the C<\[]> notation:
969
970     sub myref (\[$@%&*])
971
972 will allow calling myref() as
973
974     myref $var
975     myref @array
976     myref %hash
977     myref &sub
978     myref *glob
979
980 and the first argument of myref() will be a reference to
981 a scalar, an array, a hash, a code, or a glob.
982
983 Unbackslashed prototype characters have special meanings.  Any
984 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
985 list context.  An argument represented by C<$> forces scalar context.  An
986 C<&> requires an anonymous subroutine, which, if passed as the first
987 argument, does not require the C<sub> keyword or a subsequent comma.
988
989 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
990 typeglob, or a reference to a typeglob in that slot.  The value will be
991 available to the subroutine either as a simple scalar, or (in the latter
992 two cases) as a reference to the typeglob.  If you wish to always convert
993 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
994 follows:
995
996     use Symbol 'qualify_to_ref';
997
998     sub foo (*) {
999         my $fh = qualify_to_ref(shift, caller);
1000         ...
1001     }
1002
1003 A semicolon separates mandatory arguments from optional arguments.
1004 It is redundant before C<@> or C<%>, which gobble up everything else.
1005
1006 Note how the last three examples in the table above are treated
1007 specially by the parser.  C<mygrep()> is parsed as a true list
1008 operator, C<myrand()> is parsed as a true unary operator with unary
1009 precedence the same as C<rand()>, and C<mytime()> is truly without
1010 arguments, just like C<time()>.  That is, if you say
1011
1012     mytime +2;
1013
1014 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
1015 without a prototype.
1016
1017 The interesting thing about C<&> is that you can generate new syntax with it,
1018 provided it's in the initial position:
1019
1020     sub try (&@) {
1021         my($try,$catch) = @_;
1022         eval { &$try };
1023         if ($@) {
1024             local $_ = $@;
1025             &$catch;
1026         }
1027     }
1028     sub catch (&) { $_[0] }
1029
1030     try {
1031         die "phooey";
1032     } catch {
1033         /phooey/ and print "unphooey\n";
1034     };
1035
1036 That prints C<"unphooey">.  (Yes, there are still unresolved
1037 issues having to do with visibility of C<@_>.  I'm ignoring that
1038 question for the moment.  (But note that if we make C<@_> lexically
1039 scoped, those anonymous subroutines can act like closures... (Gee,
1040 is this sounding a little Lispish?  (Never mind.))))
1041
1042 And here's a reimplementation of the Perl C<grep> operator:
1043
1044     sub mygrep (&@) {
1045         my $code = shift;
1046         my @result;
1047         foreach $_ (@_) {
1048             push(@result, $_) if &$code;
1049         }
1050         @result;
1051     }
1052
1053 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1054 been intentionally left out of prototypes for the express purpose of
1055 someday in the future adding named, formal parameters.  The current
1056 mechanism's main goal is to let module writers provide better diagnostics
1057 for module users.  Larry feels the notation quite understandable to Perl
1058 programmers, and that it will not intrude greatly upon the meat of the
1059 module, nor make it harder to read.  The line noise is visually
1060 encapsulated into a small pill that's easy to swallow.
1061
1062 If you try to use an alphanumeric sequence in a prototype you will
1063 generate an optional warning - "Illegal character in prototype...".
1064 Unfortunately earlier versions of Perl allowed the prototype to be
1065 used as long as its prefix was a valid prototype.  The warning may be
1066 upgraded to a fatal error in a future version of Perl once the
1067 majority of offending code is fixed.
1068
1069 It's probably best to prototype new functions, not retrofit prototyping
1070 into older ones.  That's because you must be especially careful about
1071 silent impositions of differing list versus scalar contexts.  For example,
1072 if you decide that a function should take just one parameter, like this:
1073
1074     sub func ($) {
1075         my $n = shift;
1076         print "you gave me $n\n";
1077     }
1078
1079 and someone has been calling it with an array or expression
1080 returning a list:
1081
1082     func(@foo);
1083     func( split /:/ );
1084
1085 Then you've just supplied an automatic C<scalar> in front of their
1086 argument, which can be more than a bit surprising.  The old C<@foo>
1087 which used to hold one thing doesn't get passed in.  Instead,
1088 C<func()> now gets passed in a C<1>; that is, the number of elements
1089 in C<@foo>.  And the C<split> gets called in scalar context so it
1090 starts scribbling on your C<@_> parameter list.  Ouch!
1091
1092 This is all very powerful, of course, and should be used only in moderation
1093 to make the world a better place.
1094
1095 =head2 Constant Functions
1096
1097 Functions with a prototype of C<()> are potential candidates for
1098 inlining.  If the result after optimization and constant folding
1099 is either a constant or a lexically-scoped scalar which has no other
1100 references, then it will be used in place of function calls made
1101 without C<&>.  Calls made using C<&> are never inlined.  (See
1102 F<constant.pm> for an easy way to declare most constants.)
1103
1104 The following functions would all be inlined:
1105
1106     sub pi ()           { 3.14159 }             # Not exact, but close.
1107     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1108                                                 # and it's inlined, too!
1109     sub ST_DEV ()       { 0 }
1110     sub ST_INO ()       { 1 }
1111
1112     sub FLAG_FOO ()     { 1 << 8 }
1113     sub FLAG_BAR ()     { 1 << 9 }
1114     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1115
1116     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1117     sub BAZ_VAL () {
1118         if (OPT_BAZ) {
1119             return 23;
1120         }
1121         else {
1122             return 42;
1123         }
1124     }
1125
1126     sub N () { int(BAZ_VAL) / 3 }
1127     BEGIN {
1128         my $prod = 1;
1129         for (1..N) { $prod *= $_ }
1130         sub N_FACTORIAL () { $prod }
1131     }
1132
1133 If you redefine a subroutine that was eligible for inlining, you'll get
1134 a mandatory warning.  (You can use this warning to tell whether or not a
1135 particular subroutine is considered constant.)  The warning is
1136 considered severe enough not to be optional because previously compiled
1137 invocations of the function will still be using the old value of the
1138 function.  If you need to be able to redefine the subroutine, you need to
1139 ensure that it isn't inlined, either by dropping the C<()> prototype
1140 (which changes calling semantics, so beware) or by thwarting the
1141 inlining mechanism in some other way, such as
1142
1143     sub not_inlined () {
1144         23 if $];
1145     }
1146
1147 =head2 Overriding Built-in Functions
1148
1149 Many built-in functions may be overridden, though this should be tried
1150 only occasionally and for good reason.  Typically this might be
1151 done by a package attempting to emulate missing built-in functionality
1152 on a non-Unix system.
1153
1154 Overriding may be done only by importing the name from a module at
1155 compile time--ordinary predeclaration isn't good enough.  However, the
1156 C<use subs> pragma lets you, in effect, predeclare subs
1157 via the import syntax, and these names may then override built-in ones:
1158
1159     use subs 'chdir', 'chroot', 'chmod', 'chown';
1160     chdir $somewhere;
1161     sub chdir { ... }
1162
1163 To unambiguously refer to the built-in form, precede the
1164 built-in name with the special package qualifier C<CORE::>.  For example,
1165 saying C<CORE::open()> always refers to the built-in C<open()>, even
1166 if the current package has imported some other subroutine called
1167 C<&open()> from elsewhere.  Even though it looks like a regular
1168 function call, it isn't: you can't take a reference to it, such as
1169 the incorrect C<\&CORE::open> might appear to produce.
1170
1171 Library modules should not in general export built-in names like C<open>
1172 or C<chdir> as part of their default C<@EXPORT> list, because these may
1173 sneak into someone else's namespace and change the semantics unexpectedly.
1174 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1175 possible for a user to import the name explicitly, but not implicitly.
1176 That is, they could say
1177
1178     use Module 'open';
1179
1180 and it would import the C<open> override.  But if they said
1181
1182     use Module;
1183
1184 they would get the default imports without overrides.
1185
1186 The foregoing mechanism for overriding built-in is restricted, quite
1187 deliberately, to the package that requests the import.  There is a second
1188 method that is sometimes applicable when you wish to override a built-in
1189 everywhere, without regard to namespace boundaries.  This is achieved by
1190 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1191 example that quite brazenly replaces the C<glob> operator with something
1192 that understands regular expressions.
1193
1194     package REGlob;
1195     require Exporter;
1196     @ISA = 'Exporter';
1197     @EXPORT_OK = 'glob';
1198
1199     sub import {
1200         my $pkg = shift;
1201         return unless @_;
1202         my $sym = shift;
1203         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1204         $pkg->export($where, $sym, @_);
1205     }
1206
1207     sub glob {
1208         my $pat = shift;
1209         my @got;
1210         local *D;
1211         if (opendir D, '.') { 
1212             @got = grep /$pat/, readdir D; 
1213             closedir D;   
1214         }
1215         return @got;
1216     }
1217     1;
1218
1219 And here's how it could be (ab)used:
1220
1221     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1222     package Foo;
1223     use REGlob 'glob';              # override glob() in Foo:: only
1224     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1225
1226 The initial comment shows a contrived, even dangerous example.
1227 By overriding C<glob> globally, you would be forcing the new (and
1228 subversive) behavior for the C<glob> operator for I<every> namespace,
1229 without the complete cognizance or cooperation of the modules that own
1230 those namespaces.  Naturally, this should be done with extreme caution--if
1231 it must be done at all.
1232
1233 The C<REGlob> example above does not implement all the support needed to
1234 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1235 different behaviors depending on whether it appears in a scalar or list
1236 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1237 context sensitive behaviors, and these must be adequately supported by
1238 a properly written override.  For a fully functional example of overriding
1239 C<glob>, study the implementation of C<File::DosGlob> in the standard
1240 library.
1241
1242 When you override a built-in, your replacement should be consistent (if
1243 possible) with the built-in native syntax.  You can achieve this by using
1244 a suitable prototype.  To get the prototype of an overridable built-in,
1245 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1246 (see L<perlfunc/prototype>).
1247
1248 Note however that some built-ins can't have their syntax expressed by a
1249 prototype (such as C<system> or C<chomp>).  If you override them you won't
1250 be able to fully mimic their original syntax.
1251
1252 The built-ins C<do>, C<require> and C<glob> can also be overridden, but due
1253 to special magic, their original syntax is preserved, and you don't have
1254 to define a prototype for their replacements.  (You can't override the
1255 C<do BLOCK> syntax, though).
1256
1257 C<require> has special additional dark magic: if you invoke your
1258 C<require> replacement as C<require Foo::Bar>, it will actually receive
1259 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1260
1261 And, as you'll have noticed from the previous example, if you override
1262 C<glob>, the C<< <*> >> glob operator is overridden as well.
1263
1264 In a similar fashion, overriding the C<readline> function also overrides
1265 the equivalent I/O operator C<< <FILEHANDLE> >>.
1266
1267 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overridden.
1268
1269 =head2 Autoloading
1270
1271 If you call a subroutine that is undefined, you would ordinarily
1272 get an immediate, fatal error complaining that the subroutine doesn't
1273 exist.  (Likewise for subroutines being used as methods, when the
1274 method doesn't exist in any base class of the class's package.)
1275 However, if an C<AUTOLOAD> subroutine is defined in the package or
1276 packages used to locate the original subroutine, then that
1277 C<AUTOLOAD> subroutine is called with the arguments that would have
1278 been passed to the original subroutine.  The fully qualified name
1279 of the original subroutine magically appears in the global $AUTOLOAD
1280 variable of the same package as the C<AUTOLOAD> routine.  The name
1281 is not passed as an ordinary argument because, er, well, just
1282 because, that's why.  (As an exception, a method call to a nonexistent
1283 C<import> or C<unimport> method is just skipped instead.)
1284
1285 Many C<AUTOLOAD> routines load in a definition for the requested
1286 subroutine using eval(), then execute that subroutine using a special
1287 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1288 without a trace.  (See the source to the standard module documented
1289 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1290 also just emulate the routine and never define it.   For example,
1291 let's pretend that a function that wasn't defined should just invoke
1292 C<system> with those arguments.  All you'd do is:
1293
1294     sub AUTOLOAD {
1295         my $program = $AUTOLOAD;
1296         $program =~ s/.*:://;
1297         system($program, @_);
1298     }
1299     date();
1300     who('am', 'i');
1301     ls('-l');
1302
1303 In fact, if you predeclare functions you want to call that way, you don't
1304 even need parentheses:
1305
1306     use subs qw(date who ls);
1307     date;
1308     who "am", "i";
1309     ls '-l';
1310
1311 A more complete example of this is the standard Shell module, which
1312 can treat undefined subroutine calls as calls to external programs.
1313
1314 Mechanisms are available to help modules writers split their modules
1315 into autoloadable files.  See the standard AutoLoader module
1316 described in L<AutoLoader> and in L<AutoSplit>, the standard
1317 SelfLoader modules in L<SelfLoader>, and the document on adding C
1318 functions to Perl code in L<perlxs>.
1319
1320 =head2 Subroutine Attributes
1321
1322 A subroutine declaration or definition may have a list of attributes
1323 associated with it.  If such an attribute list is present, it is
1324 broken up at space or colon boundaries and treated as though a
1325 C<use attributes> had been seen.  See L<attributes> for details
1326 about what attributes are currently supported.
1327 Unlike the limitation with the obsolescent C<use attrs>, the
1328 C<sub : ATTRLIST> syntax works to associate the attributes with
1329 a pre-declaration, and not just with a subroutine definition.
1330
1331 The attributes must be valid as simple identifier names (without any
1332 punctuation other than the '_' character).  They may have a parameter
1333 list appended, which is only checked for whether its parentheses ('(',')')
1334 nest properly.
1335
1336 Examples of valid syntax (even though the attributes are unknown):
1337
1338     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive ;
1339     sub plugh () : Ugly('\(") :Bad ;
1340     sub xyzzy : _5x5 { ... }
1341
1342 Examples of invalid syntax:
1343
1344     sub fnord : switch(10,foo() ; # ()-string not balanced
1345     sub snoid : Ugly('(') ;       # ()-string not balanced
1346     sub xyzzy : 5x5 ;             # "5x5" not a valid identifier
1347     sub plugh : Y2::north ;       # "Y2::north" not a simple identifier
1348     sub snurt : foo + bar ;       # "+" not a colon or space
1349
1350 The attribute list is passed as a list of constant strings to the code
1351 which associates them with the subroutine.  In particular, the second example
1352 of valid syntax above currently looks like this in terms of how it's
1353 parsed and invoked:
1354
1355     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1356
1357 For further details on attribute lists and their manipulation,
1358 see L<attributes> and L<Attribute::Handlers>.
1359
1360 =head1 SEE ALSO
1361
1362 See L<perlref/"Function Templates"> for more about references and closures.
1363 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1364 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1365 See L<perlmod> to learn about bundling up your functions in separate files.
1366 See L<perlmodlib> to learn what library modules come standard on your system.
1367 See L<perltoot> to learn how to make object method calls.