This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
590053f98846a5c26b6322c71ab5f03c1219e488
[perl5.git] / autodoc.pl
1 #!/usr/bin/perl -w
2
3 # Unconditionally regenerate:
4 #
5 #    pod/perlintern.pod
6 #    pod/perlapi.pod
7 #
8 # from information stored in
9 #
10 #    embed.fnc
11 #    plus all the .c and .h files listed in MANIFEST
12 #
13 # Has an optional arg, which is the directory to chdir to before reading
14 # MANIFEST and *.[ch].
15 #
16 # This script is invoked as part of 'make all'
17 #
18 # '=head1' are the only headings looked for.  If the first non-blank line after
19 # the heading begins with a word character, it is considered to be the first 
20 # line of documentation that applies to the heading itself.  That is, it is 
21 # output immediately after the heading, before the first function, and not 
22 # indented. The next input line that is a pod directive terminates this 
23 # heading-level documentation.
24
25 # The meanings of the flags fields in embed.fnc and the source code is
26 # documented at the top of embed.fnc.
27
28 use strict;
29
30 if (@ARGV) {
31     my $workdir = shift;
32     chdir $workdir
33         or die "Couldn't chdir to '$workdir': $!";
34 }
35 require './regen/regen_lib.pl';
36 require './regen/embed_lib.pl';
37
38 my @specialized_docs = sort qw( perlguts
39                                 perlxs
40                                 perlxstut
41                                 perlclib
42                                 warnings
43                                 perlapio
44                                 perlcall
45                                 perlfilter
46                               );
47 my $other_places_api = join " ",    map { "L<$_>" } sort @specialized_docs, 'perlintern';
48 my $other_places_intern = join " ", map { "L<$_>" } sort @specialized_docs, 'perlapi';
49
50 @specialized_docs = map { "L<$_>" } sort @specialized_docs;
51 $specialized_docs[-1] =~ s/^/and /;
52 my $specialized_docs = join ", ", @specialized_docs;
53
54 #
55 # See database of global and static function prototypes in embed.fnc
56 # This is used to generate prototype headers under various configurations,
57 # export symbols lists for different platforms, and macros to provide an
58 # implicit interpreter context argument.
59 #
60
61 my %docs;
62 my %funcflags;
63 my %missing;
64
65 my $curheader = "Unknown section";
66
67 sub autodoc ($$) { # parse a file and extract documentation info
68     my($fh,$file) = @_;
69     my($in, $doc, $line, $header_doc);
70
71     # Count lines easier
72     my $get_next_line = sub { $line++; return <$fh> };
73
74 FUNC:
75     while (defined($in = $get_next_line->())) {
76         if ($in=~ /^=head1 (.*)/) {
77             $curheader = $1;
78
79             # If the next non-space line begins with a word char, then it is
80             # the start of heading-level documentation.
81             if (defined($doc = $get_next_line->())) {
82                 # Skip over empty lines
83                 while ($doc =~ /^\s+$/) {
84                     if (! defined($doc = $get_next_line->())) {
85                         next FUNC;
86                     }
87                 }
88
89                 if ($doc !~ /^\w/) {
90                     $in = $doc;
91                     redo FUNC;
92                 }
93                 $header_doc = $doc;
94
95                 # Continue getting the heading-level documentation until read
96                 # in any pod directive (or as a fail-safe, find a closing
97                 # comment to this pod in a C language file
98 HDR_DOC:
99                 while (defined($doc = $get_next_line->())) {
100                     if ($doc =~ /^=\w/) {
101                         $in = $doc;
102                         redo FUNC;
103                     }
104
105                     if ($doc =~ m:^\s*\*/$:) {
106                         warn "=cut missing? $file:$line:$doc";;
107                         last HDR_DOC;
108                     }
109                     $header_doc .= $doc;
110                 }
111             }
112             next FUNC;
113         }
114         if ($in =~ /^=for\s+apidoc\s+(.*?)\s*\n/) {
115             my $proto_in_file = $1;
116             my $proto = $proto_in_file;
117             $proto = "||$proto" unless $proto =~ /\|/;
118             my($flags, $ret, $name, @args) = split /\s*\|\s*/, $proto;
119             $name or die <<EOS;
120 Bad apidoc at $file line $.:
121   $in
122 Expected:
123   =for apidoc flags|returntype|name|arg|arg|...
124   =for apidoc flags|returntype|name
125   =for apidoc name
126 EOS
127             next FUNC if $flags =~ /h/;
128
129             warn ("'$name' not \\w+ in '$proto_in_file' in $file")
130                         if $flags !~ /N/ && $name !~ / ^ [_[:alpha:]] \w* $ /x;
131             my $docs = "";
132 DOC:
133             while (defined($doc = $get_next_line->())) {
134
135                 # Other pod commands are considered part of the current
136                 # function's docs, so can have lists, etc.
137                 last DOC if $doc =~ /^=(cut|for\s+apidoc|head)/;
138                 if ($doc =~ m:^\*/$:) {
139                     warn "=cut missing? $file:$line:$doc";;
140                     last DOC;
141                 }
142                 $docs .= $doc;
143             }
144             $docs = "\n$docs" if $docs and $docs !~ /^\n/;
145
146             # If the entry is also in embed.fnc, it should be defined
147             # completely there, but not here
148             my $embed_docref = delete $funcflags{$name};
149             if ($embed_docref and %$embed_docref) {
150                 warn "embed.fnc entry overrides redundant information in"
151                    . " '$proto_in_file' in $file" if $flags || $ret || @args;
152                 $flags = $embed_docref->{'flags'};
153                 warn "embed.fnc entry '$name' missing 'd' flag"
154                                                             unless $flags =~ /d/;
155                 next FUNC if $flags =~ /h/;
156                 $ret = $embed_docref->{'retval'};
157                 @args = @{$embed_docref->{args}};
158             } elsif ($flags !~ /m/)  { # Not in embed.fnc, is missing if not a
159                                        # macro
160                 $missing{$name} = $file;
161             }
162
163             my $inline_where = $flags =~ /A/ ? 'api' : 'guts';
164
165             if (exists $docs{$inline_where}{$curheader}{$name}) {
166                 warn "$0: duplicate API entry for '$name' in $inline_where/$curheader\n";
167                 next;
168             }
169             $docs{$inline_where}{$curheader}{$name}
170                 = [$flags, $docs, $ret, $file, @args];
171
172             # Create a special entry with an empty-string name for the
173             # heading-level documentation.
174             if (defined $header_doc) {
175                 $docs{$inline_where}{$curheader}{""} = $header_doc;
176                 undef $header_doc;
177             }
178
179             if (defined $doc) {
180                 if ($doc =~ /^=(?:for|head)/) {
181                     $in = $doc;
182                     redo FUNC;
183                 }
184             } else {
185                 warn "$file:$line:$in";
186             }
187         }
188     }
189 }
190
191 sub docout ($$$) { # output the docs for one function
192     my($fh, $name, $docref) = @_;
193     my($flags, $docs, $ret, $file, @args) = @$docref;
194     $name =~ s/\s*$//;
195
196     if ($flags =~ /D/) {
197         $docs = "\n\nDEPRECATED!  It is planned to remove this function from a
198 future release of Perl.  Do not use it for new code; remove it from
199 existing code.\n\n$docs";
200     }
201     else {
202         $docs = "\n\nNOTE: this function is experimental and may change or be
203 removed without notice.\n\n$docs" if $flags =~ /x/;
204     }
205
206     # Is Perl_, but no #define foo # Perl_foo
207     my $p = $flags =~ /p/ && $flags =~ /o/ && $flags !~ /M/;
208
209     $docs .= "NOTE: the perl_ form of this function is deprecated.\n\n"
210          if $flags =~ /O/;
211     if ($p) {
212         $docs .= "NOTE: this function must be explicitly called as Perl_$name";
213         $docs .= " with an aTHX_ parameter" if $flags !~ /T/;
214         $docs .= ".\n\n"
215     }
216
217     print $fh "=item $name\nX<$name>\n$docs";
218
219     if ($flags =~ /U/) { # no usage
220         warn("U and s flags are incompatible") if $flags =~ /s/;
221         # nothing
222     } else {
223         if ($flags =~ /n/) { # no args
224             warn("n flag without m") unless $flags =~ /m/;
225             warn("n flag but apparently has args") if @args;
226             print $fh "\t$ret\t$name";
227         } else { # full usage
228             my $n            = "Perl_"x$p . $name;
229             my $large_ret    = length $ret > 7;
230             my $indent_size  = 7+8 # nroff: 7 under =head + 8 under =item
231                             +8+($large_ret ? 1 + length $ret : 8)
232                             +length($n) + 1;
233             my $indent;
234             print $fh "\t$ret" . ($large_ret ? ' ' : "\t") . "$n(";
235             my $long_args;
236             for (@args) {
237                 if ($indent_size + 2 + length > 79) {
238                     $long_args=1;
239                     $indent_size -= length($n) - 3;
240                     last;
241                 }
242             }
243             my $args = '';
244             if ($p && $flags !~ /T/) {
245                 $args = @args ? "pTHX_ " : "pTHX";
246                 if ($long_args) { print $fh $args; $args = '' }
247             }
248             $long_args and print $fh "\n";
249             my $first = !$long_args;
250             while () {
251                 if (!@args or
252                     length $args
253                     && $indent_size + 3 + length($args[0]) + length $args > 79
254                 ) {
255                     print $fh
256                     $first ? '' : (
257                         $indent //=
258                         "\t".($large_ret ? " " x (1+length $ret) : "\t")
259                         ." "x($long_args ? 4 : 1 + length $n)
260                     ),
261                     $args, (","x($args ne 'pTHX_ ') . "\n")x!!@args;
262                     $args = $first = '';
263                 }
264                 @args or last;
265                 $args .= ", "x!!(length $args && $args ne 'pTHX_ ')
266                     . shift @args;
267             }
268             if ($long_args) { print $fh "\n", substr $indent, 0, -4 }
269             print $fh ")";
270         }
271         print $fh ";" if $flags =~ /s/; # semicolon "dTHR;"
272         print $fh "\n\n";
273     }
274     print $fh "=for hackers\nFound in file $file\n\n";
275 }
276
277 sub sort_helper {
278     # Do a case-insensitive dictionary sort, with only alphabetics
279     # significant, falling back to using everything for determinancy
280     return (uc($a =~ s/[[:^alpha:]]//r) cmp uc($b =~ s/[[:^alpha:]]//r))
281            || uc($a) cmp uc($b)
282            || $a cmp $b;
283 }
284
285 sub output {
286     my ($podname, $header, $dochash, $missing, $footer) = @_;
287     #
288     # strip leading '|' from each line which had been used to hide
289     # pod from pod checkers.
290     s/^\|//gm for $header, $footer;
291
292     my $fh = open_new("pod/$podname.pod", undef,
293                       {by => "$0 extracting documentation",
294                        from => 'the C source files'}, 1);
295
296     print $fh $header;
297
298     my $key;
299     for $key (sort sort_helper keys %$dochash) {
300         my $section = $dochash->{$key}; 
301         print $fh "\n=head1 $key\n\n";
302
303         # Output any heading-level documentation and delete so won't get in
304         # the way later
305         if (exists $section->{""}) {
306             print $fh $section->{""} . "\n";
307             delete $section->{""};
308         }
309         print $fh "=over 8\n\n";
310
311         for my $key (sort sort_helper keys %$section) {
312             docout($fh, $key, $section->{$key});
313         }
314         print $fh "\n=back\n";
315     }
316
317     if (@$missing) {
318         print $fh "\n=head1 Undocumented functions\n\n";
319     print $fh $podname eq 'perlapi' ? <<'_EOB_' : <<'_EOB_';
320 The following functions have been flagged as part of the public API,
321 but are currently undocumented.  Use them at your own risk, as the
322 interfaces are subject to change.  Functions that are not listed in this
323 document are not intended for public use, and should NOT be used under any
324 circumstances.
325
326 If you feel you need to use one of these functions, first send email to
327 L<perl5-porters@perl.org|mailto:perl5-porters@perl.org>.  It may be
328 that there is a good reason for the function not being documented, and it
329 should be removed from this list; or it may just be that no one has gotten
330 around to documenting it.  In the latter case, you will be asked to submit a
331 patch to document the function.  Once your patch is accepted, it will indicate
332 that the interface is stable (unless it is explicitly marked otherwise) and
333 usable by you.
334 _EOB_
335 The following functions are currently undocumented.  If you use one of
336 them, you may wish to consider creating and submitting documentation for
337 it.
338 _EOB_
339     print $fh "\n=over\n\n";
340
341     for my $missing (sort @$missing) {
342         print $fh "=item $missing\nX<$missing>\n\n";
343     }
344     print $fh "=back\n\n";
345 }
346     print $fh $footer, "=cut\n";
347
348     read_only_bottom_close_and_rename($fh);
349 }
350
351 foreach (@{(setup_embed())[0]}) {
352     next if @$_ < 2;
353     my ($flags, $retval, $func, @args) = @$_;
354     s/\b(?:NN|NULLOK)\b\s+//g for @args;
355
356     $funcflags{$func} = {
357                          flags => $flags,
358                          retval => $retval,
359                          args => \@args,
360                         };
361 }
362
363 # glob() picks up docs from extra .c or .h files that may be in unclean
364 # development trees.
365 open my $fh, '<', 'MANIFEST'
366     or die "Can't open MANIFEST: $!";
367 while (my $line = <$fh>) {
368     next unless my ($file) = $line =~ /^(\S+\.(?:[ch]|pod))\t/;
369
370     open F, '<', $file or die "Cannot open $file for docs: $!\n";
371     $curheader = "Functions in file $file\n";
372     autodoc(\*F,$file);
373     close F or die "Error closing $file: $!\n";
374 }
375 close $fh or die "Error whilst reading MANIFEST: $!";
376
377 for (sort keys %funcflags) {
378     next unless $funcflags{$_}{flags} =~ /d/;
379     next if $funcflags{$_}{flags} =~ /h/;
380     warn "no docs for $_\n"
381 }
382
383 foreach (sort keys %missing) {
384     warn "Function '$_', documented in $missing{$_}, not listed in embed.fnc";
385 }
386
387 # walk table providing an array of components in each line to
388 # subroutine, printing the result
389
390 # List of funcs in the public API that aren't also marked as experimental nor
391 # deprecated.
392 my @missing_api = grep $funcflags{$_}{flags} =~ /A/
393                     && $funcflags{$_}{flags} !~ /[xD]/
394                     && !$docs{api}{$_}, keys %funcflags;
395 output('perlapi', <<"_EOB_", $docs{api}, \@missing_api, <<"_EOE_");
396 |=encoding UTF-8
397 |
398 |=head1 NAME
399 |
400 |perlapi - autogenerated documentation for the perl public API
401 |
402 |=head1 DESCRIPTION
403 |X<Perl API> X<API> X<api>
404 |
405 |This file contains most of the documentation of the perl public API, as
406 |generated by F<embed.pl>.  Specifically, it is a listing of functions,
407 |macros, flags, and variables that may be used by extension writers.  Some
408 |specialized items are instead documented in $specialized_docs.
409 |
410 |L<At the end|/Undocumented functions> is a list of functions which have yet
411 |to be documented.  Patches welcome!  The interfaces of these are subject to
412 |change without notice.
413 |
414 |Anything not listed here is not part of the public API, and should not be
415 |used by extension writers at all.  For these reasons, blindly using functions
416 |listed in proto.h is to be avoided when writing extensions.
417 |
418 |In Perl, unlike C, a string of characters may generally contain embedded
419 |C<NUL> characters.  Sometimes in the documentation a Perl string is referred
420 |to as a "buffer" to distinguish it from a C string, but sometimes they are
421 |both just referred to as strings.
422 |
423 |Note that all Perl API global variables must be referenced with the C<PL_>
424 |prefix.  Again, those not listed here are not to be used by extension writers,
425 |and can be changed or removed without notice; same with macros.
426 |Some macros are provided for compatibility with the older,
427 |unadorned names, but this support may be disabled in a future release.
428 |
429 |Perl was originally written to handle US-ASCII only (that is characters
430 |whose ordinal numbers are in the range 0 - 127).
431 |And documentation and comments may still use the term ASCII, when
432 |sometimes in fact the entire range from 0 - 255 is meant.
433 |
434 |The non-ASCII characters below 256 can have various meanings, depending on
435 |various things.  (See, most notably, L<perllocale>.)  But usually the whole
436 |range can be referred to as ISO-8859-1.  Often, the term "Latin-1" (or
437 |"Latin1") is used as an equivalent for ISO-8859-1.  But some people treat
438 |"Latin1" as referring just to the characters in the range 128 through 255, or
439 |somethimes from 160 through 255.
440 |This documentation uses "Latin1" and "Latin-1" to refer to all 256 characters.
441 |
442 |Note that Perl can be compiled and run under either ASCII or EBCDIC (See
443 |L<perlebcdic>).  Most of the documentation (and even comments in the code)
444 |ignore the EBCDIC possibility.
445 |For almost all purposes the differences are transparent.
446 |As an example, under EBCDIC,
447 |instead of UTF-8, UTF-EBCDIC is used to encode Unicode strings, and so
448 |whenever this documentation refers to C<utf8>
449 |(and variants of that name, including in function names),
450 |it also (essentially transparently) means C<UTF-EBCDIC>.
451 |But the ordinals of characters differ between ASCII, EBCDIC, and
452 |the UTF- encodings, and a string encoded in UTF-EBCDIC may occupy a different
453 |number of bytes than in UTF-8.
454 |
455 |The listing below is alphabetical, case insensitive.
456 |
457 _EOB_
458 |
459 |=head1 AUTHORS
460 |
461 |Until May 1997, this document was maintained by Jeff Okamoto
462 |<okamoto\@corp.hp.com>.  It is now maintained as part of Perl itself.
463 |
464 |With lots of help and suggestions from Dean Roehrich, Malcolm Beattie,
465 |Andreas Koenig, Paul Hudson, Ilya Zakharevich, Paul Marquess, Neil
466 |Bowers, Matthew Green, Tim Bunce, Spider Boardman, Ulrich Pfeifer,
467 |Stephen McCamant, and Gurusamy Sarathy.
468 |
469 |API Listing originally by Dean Roehrich <roehrich\@cray.com>.
470 |
471 |Updated to be autogenerated from comments in the source by Benjamin Stuhl.
472 |
473 |=head1 SEE ALSO
474 |
475 $other_places_api
476 _EOE_
477
478 # List of non-static internal functions
479 my @missing_guts =
480  grep $funcflags{$_}{flags} !~ /[AS]/ && !$docs{guts}{$_}, keys %funcflags;
481
482 output('perlintern', <<'_EOB_', $docs{guts}, \@missing_guts, <<"_EOE_");
483 |=head1 NAME
484 |
485 |perlintern - autogenerated documentation of purely B<internal>
486 |Perl functions
487 |
488 |=head1 DESCRIPTION
489 |X<internal Perl functions> X<interpreter functions>
490 |
491 |This file is the autogenerated documentation of functions in the
492 |Perl interpreter that are documented using Perl's internal documentation
493 |format but are not marked as part of the Perl API.  In other words,
494 |B<they are not for use in extensions>!
495 |
496 _EOB_
497 |
498 |=head1 AUTHORS
499 |
500 |The autodocumentation system was originally added to the Perl core by
501 |Benjamin Stuhl.  Documentation is by whoever was kind enough to
502 |document their functions.
503 |
504 |=head1 SEE ALSO
505 |
506 $other_places_intern
507 _EOE_