This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Integrate mainline
[perl5.git] / lib / ExtUtils / t / Installed.t
1 #!/usr/bin/perl -w
2
3 BEGIN {
4     if( $ENV{PERL_CORE} ) {
5         chdir 't' if -d 't';
6         @INC = '../lib';
7     }
8 }
9 chdir 't';
10
11
12 use strict;
13 use warnings;
14
15 # for _is_type() tests
16 use Config;
17
18 # for new() tests
19 use Cwd;
20 use File::Path;
21
22 # for directories() tests
23 use File::Basename;
24
25 use Test::More tests => 43;
26
27 BEGIN { use_ok( 'ExtUtils::Installed' ) }
28
29 my $mandirs =  !!$Config{man1direxp} + !!$Config{man3direxp};
30
31 # saves having to qualify package name for class methods
32 my $ei = bless( {}, 'ExtUtils::Installed' );
33
34 # _is_prefix
35 is( $ei->_is_prefix('foo/bar', 'foo'), 1, 
36         '_is_prefix() should match valid path prefix' );
37 is( $ei->_is_prefix('\foo\bar', '\bar'), 0, 
38         '... should not match wrong prefix' );
39
40 # _is_type
41 is( $ei->_is_type(0, 'all'), 1, '_is_type() should be true for type of "all"' );
42
43 foreach my $path (qw( man1dir man3dir )) {
44 SKIP: {
45         my $dir = $Config{$path.'exp'};
46         skip("no man directory $path on this system", 2 ) unless $dir;
47
48         my $file = $dir . '/foo';
49         is( $ei->_is_type($file, 'doc'), 1, "... should find doc file in $path" );
50         is( $ei->_is_type($file, 'prog'), 0, "... but not prog file in $path" );
51     }
52 }
53
54 is( $ei->_is_type($Config{prefixexp} . '/bar', 'prog'), 1, 
55         "... should find prog file under $Config{prefixexp}" );
56
57 SKIP: {
58         skip('no man directories on this system', 1) unless $mandirs;
59         is( $ei->_is_type('bar', 'doc'), 0, 
60                 '... should not find doc file outside path' );
61 }
62
63 is( $ei->_is_type('bar', 'prog'), 0, 
64         '... nor prog file outside path' );
65 is( $ei->_is_type('whocares', 'someother'), 0, '... nor other type anywhere' );
66
67 # _is_under
68 ok( $ei->_is_under('foo'), '_is_under() should return true with no dirs' );
69
70 my @under = qw( boo bar baz );
71 is( $ei->_is_under('foo', @under), 0, '... should find no file not under dirs');
72 is( $ei->_is_under('baz', @under), 1, '... should find file under dir' );
73
74 # new
75 my $realei;
76 {
77     # We're going to get warnings about not being able to find install
78     # directories if we're not installed.
79     local $SIG{__WARN__} = sub {
80         warn @_ unless $ENV{PERL_CORE} && $_[0] =~ /^Can't stat/;
81     };
82     $realei = ExtUtils::Installed->new();
83 }
84
85 isa_ok( $realei, 'ExtUtils::Installed' );
86 isa_ok( $realei->{Perl}{packlist}, 'ExtUtils::Packlist' );
87 is( $realei->{Perl}{version}, $Config{version}, 
88         'new() should set Perl version from %Config' );
89
90 my $wrotelist;
91 if (mkpath('auto/FakeMod')) {
92         if (open(PACKLIST, '>', 'auto/FakeMod/.packlist')) {
93                 print PACKLIST 'list';
94                 close PACKLIST;
95                 if (open(FAKEMOD, '>', 'auto/FakeMod/FakeMod.pm')) {
96                         print FAKEMOD <<'FAKE';
97 package FakeMod;
98 use vars qw( $VERSION );
99 $VERSION = '1.1.1';
100 1;
101 FAKE
102
103                         close FAKEMOD;
104                         $wrotelist = 1;
105                 }
106         }
107 }
108
109
110 SKIP: {
111         skip("could not write packlist: $!", 3 ) unless $wrotelist;
112
113         # avoid warning and death by localizing glob
114         local *ExtUtils::Installed::Config;
115         my $fake_mod_dir = File::Spec->catdir(cwd(), 'auto', 'FakeMod');
116         %ExtUtils::Installed::Config = (
117                 archlibexp         => cwd(),
118                 sitearchexp        => $fake_mod_dir,
119         );
120
121         # necessary to fool new()
122         push @INC, $fake_mod_dir;
123
124         my $realei = ExtUtils::Installed->new();
125         ok( exists $realei->{FakeMod}, 'new() should find modules with .packlists');
126         isa_ok( $realei->{FakeMod}{packlist}, 'ExtUtils::Packlist' );
127         is( $realei->{FakeMod}{version}, '1.1.1', 
128                 '... should find version in modules' );
129 }
130
131 # modules
132 $ei->{$_} = 1 for qw( abc def ghi );
133 is( join(' ', $ei->modules()), 'abc def ghi', 
134         'modules() should return sorted keys' );
135
136 # files
137 $ei->{goodmod} = { 
138         packlist => { 
139                 ($Config{man1direxp} ? 
140                     (File::Spec->catdir($Config{man1direxp}, 'foo') => 1) : 
141                         ()),
142                 ($Config{man3direxp} ? 
143                     (File::Spec->catdir($Config{man3direxp}, 'bar') => 1) : 
144                         ()),
145                 File::Spec->catdir($Config{prefixexp}, 'foobar') => 1,
146                 foobaz  => 1,
147         },
148 };
149
150 eval { $ei->files('badmod') };
151 like( $@, qr/badmod is not installed/,'files() should croak given bad modname');
152 eval { $ei->files('goodmod', 'badtype' ) };
153 like( $@, qr/type must be/,'files() should croak given bad type' );
154
155 my @files;
156 SKIP: {
157     skip('no man directory man1dir on this system', 2) unless $Config{man1direxp}; 
158     @files = $ei->files('goodmod', 'doc', $Config{man1direxp});
159     is( scalar @files, 1, '... should find doc file under given dir' );
160     is( grep({ /foo$/ } @files), 1, '... checking file name' );
161 }
162 SKIP: {
163     skip('no man directories on this system', 1) unless $mandirs;
164     @files = $ei->files('goodmod', 'doc');
165     is( scalar @files, $mandirs, '... should find all doc files with no dir' );
166 }
167
168 @files = $ei->files('goodmod', 'prog', 'fake', 'fake2');
169 is( scalar @files, 0, '... should find no doc files given wrong dirs' );
170 @files = $ei->files('goodmod', 'prog');
171 is( scalar @files, 1, '... should find doc file in correct dir' );
172 like( $files[0], qr/foobar$/, '... checking file name' );
173 @files = $ei->files('goodmod');
174 is( scalar @files, 2 + $mandirs, '... should find all files with no type specified' );
175 my %dirnames = map { lc($_) => dirname($_) } @files;
176
177 # directories
178 my @dirs = $ei->directories('goodmod', 'prog', 'fake');
179 is( scalar @dirs, 0, 'directories() should return no dirs if no files found' );
180
181 SKIP: {
182     skip('no man directories on this system', 1) unless $mandirs;
183     @dirs = $ei->directories('goodmod', 'doc');
184     is( scalar @dirs, $mandirs, '... should find all files files() would' );
185 }
186 @dirs = $ei->directories('goodmod');
187 is( scalar @dirs, 2 + $mandirs, '... should find all files files() would, again' );
188 @files = sort map { exists $dirnames{lc($_)} ? $dirnames{lc($_)} : '' } @files;
189 is( join(' ', @files), join(' ', @dirs), '... should sort output' );
190
191 # directory_tree
192 my $expectdirs = 
193        ($mandirs == 2) && 
194        (dirname($Config{man1direxp}) eq dirname($Config{man3direxp}))
195        ? 3 : 2;
196  
197 SKIP: {
198     skip('no man directories on this system', 1) unless $mandirs;
199     @dirs = $ei->directory_tree('goodmod', 'doc', $Config{man1direxp} ?
200        dirname($Config{man1direxp}) : dirname($Config{man3direxp}));
201     is( scalar @dirs, $expectdirs, 
202         'directory_tree() should report intermediate dirs to those requested' );
203 }
204
205 my $fakepak = Fakepak->new(102);
206
207 $ei->{yesmod} = { 
208         version         => 101,
209         packlist        => $fakepak,
210 };
211
212 # these should all croak
213 foreach my $sub (qw( validate packlist version )) {
214         eval { $ei->$sub('nomod') };
215         like( $@, qr/nomod is not installed/, 
216                 "$sub() should croak when asked about uninstalled module" );
217 }
218
219 # validate
220 is( $ei->validate('yesmod'), 'validated', 
221         'validate() should return results of packlist validate() call' );
222
223 # packlist
224 is( ${ $ei->packlist('yesmod') }, 102, 
225         'packlist() should report installed mod packlist' );
226
227 # version
228 is( $ei->version('yesmod'), 101, 
229         'version() should report installed mod version' );
230
231 # needs a DESTROY, for some reason
232 can_ok( $ei, 'DESTROY' );
233
234 END {
235         if ($wrotelist) {
236                 for my $file (qw( .packlist FakePak.pm )) {
237                         1 while unlink $file;
238                 }
239                 File::Path::rmtree('auto') or warn "Couldn't rmtree auto: $!";
240         }
241 }
242
243 package Fakepak;
244
245 sub new {
246         my $class = shift;
247         bless(\(my $scalar = shift), $class);
248 }
249
250 sub validate {
251         'validated'
252 }