t/op/pack.t

   1 #!./perl -w
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';
   7 }
   8
   9 # This is truth in an if statement, and could be a skip message
  10 my $no_endianness = $] > 5.009 ? '' :
  11   "Endianness pack modifiers not available on this perl";
  12 my $no_signedness = $] > 5.009 ? '' :
  13   "Signed/unsigned pack modifiers not available on this perl";
  14
  15 plan tests => 14699;
  16
  17 use strict;
  18 use warnings qw(FATAL all);
  19 use Config;
  20
  21 my $Is_EBCDIC = (defined $Config{ebcdic} && $Config{ebcdic} eq 'define');
  22 my $Perl = which_perl();
  23 my @valid_errors = (qr/^Invalid type '\w'/);
  24
  25 my $ByteOrder = 'unknown';
  26 my $maybe_not_avail = '(?:hto[bl]e|[bl]etoh)';
  27 if ($no_endianness) {
  28   push @valid_errors, qr/^Invalid type '[<>]'/;
  29 } elsif ($Config{byteorder} =~ /^1234(?:5678)?$/) {
  30   $ByteOrder = 'little';
  31   $maybe_not_avail = '(?:htobe|betoh)';
  32 }
  33 elsif ($Config{byteorder} =~ /^(?:8765)?4321$/) {
  34   $ByteOrder = 'big';
  35   $maybe_not_avail = '(?:htole|letoh)';
  36 }
  37 else {
  38   push @valid_errors, qr/^Can't (?:un)?pack (?:big|little)-endian .*? on this platform/;
  39 }
  40
  41 if ($no_signedness) {
  42   push @valid_errors, qr/^'!' allowed only after types sSiIlLxX in (?:un)?pack/;
  43 }
  44
  45 for my $size ( 16, 32, 64 ) {
  46   if (defined $Config{"u${size}size"} and ($Config{"u${size}size"}||0) != ($size >> 3)) {
  47     push @valid_errors, qr/^Perl_my_$maybe_not_avail$size\(\) not available/;
  48   }
  49 }
  50
  51 my $IsTwosComplement = pack('i', -1) eq "\xFF" x $Config{intsize};
  52 print "# \$IsTwosComplement = $IsTwosComplement\n";
  53
  54 sub is_valid_error
  55 {
  56   my $err = shift;
  57
  58   for my $e (@valid_errors) {
  59     $err =~ $e and return 1;
  60   }
  61
  62   return 0;
  63 }
  64
  65 sub encode_list {
  66   my @result = map {_qq($_)} @_;
  67   if (@result == 1) {
  68     return @result;
  69   }
  70   return '(' . join (', ', @result) . ')';
  71 }
  72
  73
  74 sub list_eq ($$) {
  75   my ($l, $r) = @_;
  76   return 0 unless @$l == @$r;
  77   for my $i (0..$#$l) {
  78     if (defined $l->[$i]) {
  79       return 0 unless defined ($r->[$i]) && $l->[$i] eq $r->[$i];
  80     } else {
  81       return 0 if defined $r->[$i]
  82     }
  83   }
  84   return 1;
  85 }
  86
  87 ##############################################################################
  88 #
  89 # Here starteth the tests
  90 #
  91
  92 {
  93     my $format = "c2 x5 C C x s d i l a6";
  94     # Need the expression in here to force ary[5] to be numeric.  This avoids
  95     # test2 failing because ary2 goes str->numeric->str and ary doesn't.
  96     my @ary = (1,-100,127,128,32767,987.654321098 / 100.0,12345,123456,
  97                "abcdef");
  98     my $foo = pack($format,@ary);
  99     my @ary2 = unpack($format,$foo);
 100
 101     is($#ary, $#ary2);
 102
 103     my $out1=join(':',@ary);
 104     my $out2=join(':',@ary2);
 105     # Using long double NVs may introduce greater accuracy than wanted.
 106     $out1 =~ s/:9\.87654321097999\d*:/:9.87654321098:/;
 107     $out2 =~ s/:9\.87654321097999\d*:/:9.87654321098:/;
 108     is($out1, $out2);
 109
 110     like($foo, qr/def/);
 111 }
 112 # How about counting bits?
 113
 114 {
 115     my $x;
 116     is( ($x = unpack("%32B*", "\001\002\004\010\020\040\100\200\377")), 16 );
 117
 118     is( ($x = unpack("%32b69", "\001\002\004\010\020\040\100\200\017")), 12 );
 119
 120     is( ($x = unpack("%32B69", "\001\002\004\010\020\040\100\200\017")), 9 );
 121 }
 122
 123 {
 124     my $sum = 129; # ASCII
 125     $sum = 103 if $Is_EBCDIC;
 126
 127     my $x;
 128     is( ($x = unpack("%32B*", "Now is the time for all good blurfl")), $sum );
 129
 130     my $foo;
 131     open(BIN, $Perl) || die "Can't open $Perl: $!\n";
 132     binmode BIN;
 133     sysread BIN, $foo, 8192;
 134     close BIN;
 135
 136     $sum = unpack("%32b*", $foo);
 137     my $longway = unpack("b*", $foo);
 138     is( $sum, $longway =~ tr/1/1/ );
 139 }
 140
 141 {
 142   my $x;
 143   is( ($x = unpack("I",pack("I", 0xFFFFFFFF))), 0xFFFFFFFF );
 144 }
 145
 146 {
 147     # check 'w'
 148     my @x = (5,130,256,560,32000,3097152,268435455,1073741844, 2**33,
 149              '4503599627365785','23728385234614992549757750638446');
 150     my $x = pack('w*', @x);
 151     my $y = pack 'H*', '0581028200843081fa0081bd8440ffffff7f8480808014A0808'.
 152                        '0800087ffffffffffdb19caefe8e1eeeea0c2e1e3e8ede1ee6e';
 153
 154     is($x, $y);
 155
 156     my @y = unpack('w*', $y);
 157     my $a;
 158     while ($a = pop @x) {
 159         my $b = pop @y;
 160         is($a, $b);
 161     }
 162
 163     @y = unpack('w2', $x);
 164
 165     is(scalar(@y), 2);
 166     is($y[1], 130);
 167     $x = pack('w*', 5000000000); $y = '';
 168     eval {
 169     use Math::BigInt;
 170     $y = pack('w*', Math::BigInt::->new(5000000000));
 171     };
 172     is($x, $y);
 173
 174     $x = pack 'w', ~0;
 175     $y = pack 'w', (~0).'';
 176     is($x, $y);
 177     is(unpack ('w',$x), ~0);
 178     is(unpack ('w',$y), ~0);
 179
 180     $x = pack 'w', ~0 - 1;
 181     $y = pack 'w', (~0) - 2;
 182
 183     if (~0 - 1 == (~0) - 2) {
 184         is($x, $y, "NV arithmetic");
 185     } else {
 186         isnt($x, $y, "IV/NV arithmetic");
 187     }
 188     cmp_ok(unpack ('w',$x), '==', ~0 - 1);
 189     cmp_ok(unpack ('w',$y), '==', ~0 - 2);
 190
 191     # These should spot that pack 'w' is using NV, not double, on platforms
 192     # where IVs are smaller than doubles, and harmlessly pass elsewhere.
 193     # (tests for change 16861)
 194     my $x0 = 2**54+3;
 195     my $y0 = 2**54-2;
 196
 197     $x = pack 'w', $x0;
 198     $y = pack 'w', $y0;
 199
 200     if ($x0 == $y0) {
 201         is($x, $y, "NV arithmetic");
 202     } else {
 203         isnt($x, $y, "IV/NV arithmetic");
 204     }
 205     cmp_ok(unpack ('w',$x), '==', $x0);
 206     cmp_ok(unpack ('w',$y), '==', $y0);
 207 }
 208
 209
 210 {
 211   print "# test exceptions\n";
 212   my $x;
 213   eval { $x = unpack 'w', pack 'C*', 0xff, 0xff};
 214   like($@, qr/^Unterminated compressed integer/);
 215
 216   eval { $x = unpack 'w', pack 'C*', 0xff, 0xff, 0xff, 0xff};
 217   like($@, qr/^Unterminated compressed integer/);
 218
 219   eval { $x = unpack 'w', pack 'C*', 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff};
 220   like($@, qr/^Unterminated compressed integer/);
 221
 222   eval { $x = pack 'w', -1 };
 223   like ($@, qr/^Cannot compress negative numbers/);
 224
 225   eval { $x = pack 'w', '1'x(1 + length ~0) . 'e0' };
 226   like ($@, qr/^Can only compress unsigned integers/);
 227
 228   # Check that the warning behaviour on the modifiers !, < and > is as we
 229   # expect it for this perl.
 230   my $can_endian = $no_endianness ? '' : 'sSiIlLqQjJfFdDpP';
 231   my $can_shriek = 'sSiIlL';
 232   $can_shriek .= 'nNvV' unless $no_signedness;
 233   # h and H can't do either, so act as sanity checks in blead
 234   foreach my $base (split '', 'hHsSiIlLqQjJfFdDpPnNvV') {
 235     foreach my $mod ('', '<', '>', '!', '<!', '>!', '!<', '!>') {
 236     SKIP: {
 237         # Avoid void context warnings.
 238         my $a = eval {pack "$base$mod"};
 239         skip "pack can't $base", 1 if $@ =~ /^Invalid type '\w'/;
 240         # Which error you get when 2 would be possible seems to be emergent
 241         # behaviour of pack's format parser.
 242
 243         my $fails_shriek = $mod =~ /!/ && index ($can_shriek, $base) == -1;
 244         my $fails_endian = $mod =~ /[<>]/ && index ($can_endian, $base) == -1;
 245         my $shriek_first = $mod =~ /^!/;
 246
 247         if ($no_endianness and ($mod eq '<!' or $mod eq '>!')) {
 248           # The ! isn't seem as part of $base. Instead it's seen as a modifier
 249           # on > or <
 250           $fails_shriek = 1;
 251           undef $fails_endian;
 252         } elsif ($fails_shriek and $fails_endian) {
 253           if ($shriek_first) {
 254             undef $fails_endian;
 255           }
 256         }
 257
 258         if ($fails_endian) {
 259           if ($no_endianness) {
 260             # < and > are seen as pattern letters, not modifiers
 261             like ($@, qr/^Invalid type '[<>]'/, "pack can't $base$mod");
 262           } else {
 263             like ($@, qr/^'[<>]' allowed only after types/,
 264                   "pack can't $base$mod");
 265           }
 266         } elsif ($fails_shriek) {
 267           like ($@, qr/^'!' allowed only after types/,
 268                 "pack can't $base$mod");
 269         } else {
 270           is ($@, '', "pack can $base$mod");
 271         }
 272       }
 273     }
 274   }
 275
 276  SKIP: {
 277     skip $no_endianness, 2*3 + 2*8 if $no_endianness;
 278     for my $mod (qw( ! < > )) {
 279       eval { $x = pack "a$mod", 42 };
 280       like ($@, qr/^'$mod' allowed only after types \S+ in pack/);
 281
 282       eval { $x = unpack "a$mod", 'x'x8 };
 283       like ($@, qr/^'$mod' allowed only after types \S+ in unpack/);
 284     }
 285
 286     for my $mod (qw( <> >< !<> !>< <!> >!< <>! ><! )) {
 287       eval { $x = pack "sI${mod}s", 42, 47, 11 };
 288       like ($@, qr/^Can't use both '<' and '>' after type 'I' in pack/);
 289
 290       eval { $x = unpack "sI${mod}s", 'x'x16 };
 291       like ($@, qr/^Can't use both '<' and '>' after type 'I' in unpack/);
 292     }
 293   }
 294
 295  SKIP: {
 296     # Is this a stupid thing to do on VMS, VOS and other unusual platforms?
 297
 298     skip("-- the IEEE infinity model is unavailable in this configuration.", 1)
 299        if (($^O eq 'VMS') && !defined($Config{useieee}));
 300
 301     skip("-- $^O has serious fp indigestion on w-packed infinities", 1)
 302        if (
 303            ($^O eq 'mpeix')
 304            ||
 305            ($^O eq 'ultrix')
 306            ||
 307            ($^O =~ /^svr4/ && -f "/etc/issue" && -f "/etc/.relid") # NCR MP-RAS
 308            );
 309
 310     my $inf = eval '2**1000000';
 311
 312     skip("Couldn't generate infinity - got error '$@'", 1)
 313       unless defined $inf and $inf == $inf / 2 and $inf + 1 == $inf;
 314
 315     local our $TODO;
 316     $TODO = "VOS needs a fix for posix-1022 to pass this test."
 317       if ($^O eq 'vos');
 318
 319     eval { $x = pack 'w', $inf };
 320     like ($@, qr/^Cannot compress integer/, "Cannot compress integer");
 321   }
 322
 323  SKIP: {
 324
 325     skip("-- the full range of an IEEE double may not be available in this configuration.", 3)
 326        if (($^O eq 'VMS') && !defined($Config{useieee}));
 327
 328     skip("-- $^O does not like 2**1023", 3)
 329        if (($^O eq 'ultrix'));
 330
 331     # This should be about the biggest thing possible on an IEEE double
 332     my $big = eval '2**1023';
 333
 334     skip("Couldn't generate 2**1023 - got error '$@'", 3)
 335       unless defined $big and $big != $big / 2;
 336
 337     eval { $x = pack 'w', $big };
 338     is ($@, '', "Should be able to pack 'w', $big # 2**1023");
 339
 340     my $y = eval {unpack 'w', $x};
 341     is ($@, '',
 342         "Should be able to unpack 'w' the result of pack 'w', $big # 2**1023");
 343
 344     # I'm getting about 1e-16 on FreeBSD
 345     my $quotient = int (100 * ($y - $big) / $big);
 346     ok($quotient < 2 && $quotient > -2,
 347        "Round trip pack, unpack 'w' of $big is within 1% ($quotient%)");
 348   }
 349
 350 }
 351
 352 print "# test the 'p' template\n";
 353
 354 # literals
 355 is(unpack("p",pack("p","foo")), "foo");
 356 SKIP: {
 357   skip $no_endianness, 2 if $no_endianness;
 358   is(unpack("p<",pack("p<","foo")), "foo");
 359   is(unpack("p>",pack("p>","foo")), "foo");
 360 }
 361 # scalars
 362 is(unpack("p",pack("p",239)), 239);
 363 SKIP: {
 364   skip $no_endianness, 2 if $no_endianness;
 365   is(unpack("p<",pack("p<",239)), 239);
 366   is(unpack("p>",pack("p>",239)), 239);
 367 }
 368
 369 # temps
 370 sub foo { my $a = "a"; return $a . $a++ . $a++ }
 371 {
 372   use warnings qw(NONFATAL all);;
 373   my $warning;
 374   local $SIG{__WARN__} = sub {
 375       $warning = $_[0];
 376   };
 377   my $junk = pack("p", &foo);
 378
 379   like($warning, qr/temporary val/);
 380 }
 381
 382 # undef should give null pointer
 383 like(pack("p", undef), qr/^\0+$/);
 384 SKIP: {
 385   skip $no_endianness, 2 if $no_endianness;
 386   like(pack("p<", undef), qr/^\0+$/);
 387   like(pack("p>", undef), qr/^\0+$/);
 388 }
 389
 390 # Check for optimizer bug (e.g.  Digital Unix GEM cc with -O4 on DU V4.0B gives
 391 #                                4294967295 instead of -1)
 392 #                                see #ifdef __osf__ in pp.c pp_unpack
 393 is((unpack("i",pack("i",-1))), -1);
 394
 395 print "# test the pack lengths of s S i I l L n N v V + modifiers\n";
 396
 397 my @lengths = (
 398   qw(s 2 S 2 i -4 I -4 l 4 L 4 n 2 N 4 v 2 V 4 n! 2 N! 4 v! 2 V! 4),
 399   's!'  => $Config{shortsize}, 'S!'  => $Config{shortsize},
 400   'i!'  => $Config{intsize},   'I!'  => $Config{intsize},
 401   'l!'  => $Config{longsize},  'L!'  => $Config{longsize},
 402 );
 403
 404 while (my ($base, $expect) = splice @lengths, 0, 2) {
 405   my @formats = ($base);
 406   $base =~ /^[nv]/i or push @formats, "$base>", "$base<";
 407   for my $format (@formats) {
 408   SKIP: {
 409       skip $no_endianness, 1 if $no_endianness && $format =~ m/[<>]/;
 410       skip $no_signedness, 1 if $no_signedness && $format =~ /[nNvV]!/;
 411       my $len = length(pack($format, 0));
 412       if ($expect > 0) {
 413         is($expect, $len, "format '$format'");
 414       } else {
 415         $expect = -$expect;
 416         ok ($len >= $expect, "format '$format'") ||
 417           print "# format '$format' has length $len, expected >= $expect\n";
 418       }
 419     }
 420   }
 421 }
 422
 423
 424 print "# test unpack-pack lengths\n";
 425
 426 my @templates = qw(c C W i I s S l L n N v V f d q Q);
 427
 428 foreach my $base (@templates) {
 429     my @tmpl = ($base);
 430     $base =~ /^[cwnv]/i or push @tmpl, "$base>", "$base<";
 431     foreach my $t (@tmpl) {
 432         SKIP: {
 433             my @t = eval { unpack("$t*", pack("$t*", 12, 34)) };
 434
 435             skip "cannot pack '$t' on this perl", 4
 436               if is_valid_error($@);
 437
 438             is( $@, '', "Template $t works");
 439             is(scalar @t, 2);
 440
 441             is($t[0], 12);
 442             is($t[1], 34);
 443         }
 444     }
 445 }
 446
 447 {
 448     # uuencode/decode
 449
 450     # Note that first uuencoding known 'text' data and then checking the
 451     # binary values of the uuencoded version would not be portable between
 452     # character sets.  Uuencoding is meant for encoding binary data, not
 453     # text data.
 454
 455     my $in = pack 'C*', 0 .. 255;
 456
 457     # just to be anal, we do some random tr/`/ /
 458     my $uu = <<'EOUU';
 459 M` $"`P0%!@<("0H+# T.#Q`1$A,4%187&!D:&QP='A\@(2(C)"4F)R@I*BLL
 460 M+2XO,#$R,S0U-C<X.3H[/#T^/T!!0D-$149'2$E*2TQ-3D]045)35%565UA9
 461 M6EM<75Y?8&%B8V1E9F=H:6IK;&UN;W!Q<G-T=79W>'EZ>WQ]?G^`@8*#A(6&
 462 MAXB)BHN,C8Z/D)&2DY25EI>8F9J;G)V>GZ"AHJ.DI::GJ*FJJZRMKJ^PL;*S
 463 MM+6VM[BYNKN\O;Z_P,'"P\3%QL?(R<K+S,W.S]#1TM/4U=;7V-G:V]S=WM_@
 464 ?X>+CY.7FY^CIZNOL[>[O\/'R\_3U]O?X^?K[_/W^_P `
 465 EOUU
 466
 467     $_ = $uu;
 468     tr/ /`/;
 469
 470     is(pack('u', $in), $_);
 471
 472     is(unpack('u', $uu), $in);
 473
 474     $in = "\x1f\x8b\x08\x08\x58\xdc\xc4\x35\x02\x03\x4a\x41\x50\x55\x00\xf3\x2a\x2d\x2e\x51\x48\xcc\xcb\x2f\xc9\x48\x2d\x52\x08\x48\x2d\xca\x51\x28\x2d\x4d\xce\x4f\x49\x2d\xe2\x02\x00\x64\x66\x60\x5c\x1a\x00\x00\x00";
 475     $uu = <<'EOUU';
 476 M'XL("%C<Q#4"`TI!4%4`\RHM+E%(S,LOR4@M4@A(+<I1*"U-SD])+>("`&1F
 477 &8%P:````
 478 EOUU
 479
 480     is(unpack('u', $uu), $in);
 481
 482 # This is identical to the above except that backquotes have been
 483 # changed to spaces
 484
 485     $uu = <<'EOUU';
 486 M'XL("%C<Q#4" TI!4%4 \RHM+E%(S,LOR4@M4@A(+<I1*"U-SD])+>(" &1F
 487 &8%P:
 488 EOUU
 489
 490     # ' # Grr
 491     is(unpack('u', $uu), $in);
 492
 493 }
 494
 495 # test the ascii template types (A, a, Z)
 496
 497 foreach (
 498 ['p', 'A*',  "foo\0bar\0 ", "foo\0bar\0 "],
 499 ['p', 'A11', "foo\0bar\0 ", "foo\0bar\0   "],
 500 ['u', 'A*',  "foo\0bar \0", "foo\0bar"],
 501 ['u', 'A8',  "foo\0bar \0", "foo\0bar"],
 502 ['p', 'a*',  "foo\0bar\0 ", "foo\0bar\0 "],
 503 ['p', 'a11', "foo\0bar\0 ", "foo\0bar\0 \0\0"],
 504 ['u', 'a*',  "foo\0bar \0", "foo\0bar \0"],
 505 ['u', 'a8',  "foo\0bar \0", "foo\0bar "],
 506 ['p', 'Z*',  "foo\0bar\0 ", "foo\0bar\0 \0"],
 507 ['p', 'Z11', "foo\0bar\0 ", "foo\0bar\0 \0\0"],
 508 ['p', 'Z3',  "foo",         "fo\0"],
 509 ['u', 'Z*',  "foo\0bar \0", "foo"],
 510 ['u', 'Z8',  "foo\0bar \0", "foo"],
 511 )
 512 {
 513     my ($what, $template, $in, $out) = @$_;
 514     my $got = $what eq 'u' ? (unpack $template, $in) : (pack $template, $in);
 515     unless (is($got, $out)) {
 516         my $un = $what eq 'u' ? 'un' : '';
 517         print "# ${un}pack ('$template', "._qq($in).') gave '._qq($out).
 518             ' not '._qq($got)."\n";
 519     }
 520 }
 521
 522 print "# packing native shorts/ints/longs\n";
 523
 524 is(length(pack("s!", 0)), $Config{shortsize});
 525 is(length(pack("i!", 0)), $Config{intsize});
 526 is(length(pack("l!", 0)), $Config{longsize});
 527 ok(length(pack("s!", 0)) <= length(pack("i!", 0)));
 528 ok(length(pack("i!", 0)) <= length(pack("l!", 0)));
 529 is(length(pack("i!", 0)), length(pack("i", 0)));
 530
 531 sub numbers {
 532   my $base = shift;
 533   my @formats = ($base);
 534   $base =~ /^[silqjfdp]/i and push @formats, "$base>", "$base<";
 535   for my $format (@formats) {
 536     numbers_with_total ($format, undef, @_);
 537   }
 538 }
 539
 540 sub numbers_with_total {
 541   my $format = shift;
 542   my $total = shift;
 543   if (!defined $total) {
 544     foreach (@_) {
 545       $total += $_;
 546     }
 547   }
 548   print "# numbers test for $format\n";
 549   foreach (@_) {
 550     SKIP: {
 551         my $out = eval {unpack($format, pack($format, $_))};
 552         skip "cannot pack '$format' on this perl", 2
 553           if is_valid_error($@);
 554
 555         is($@, '', "no error");
 556         is($out, $_, "unpack pack $format $_");
 557     }
 558   }
 559
 560   my $skip_if_longer_than = ~0; # "Infinity"
 561   if (~0 - 1 == ~0) {
 562     # If we're running with -DNO_PERLPRESERVE_IVUV and NVs don't preserve all
 563     # UVs (in which case ~0 is NV, ~0-1 will be the same NV) then we can't
 564     # correctly in perl calculate UV totals for long checksums, as pp_unpack
 565     # is using UV maths, and we've only got NVs.
 566     $skip_if_longer_than = $Config{nv_preserves_uv_bits};
 567   }
 568
 569   foreach ('', 1, 2, 3, 15, 16, 17, 31, 32, 33, 53, 54, 63, 64, 65) {
 570     SKIP: {
 571       my $sum = eval {unpack "%$_$format*", pack "$format*", @_};
 572       skip "cannot pack '$format' on this perl", 3
 573         if is_valid_error($@);
 574
 575       is($@, '', "no error");
 576       ok(defined $sum, "sum bits $_, format $format defined");
 577
 578       my $len = $_; # Copy, so that we can reassign ''
 579       $len = 16 unless length $len;
 580
 581       SKIP: {
 582         skip "cannot test checksums over $skip_if_longer_than bits", 1
 583           if $len > $skip_if_longer_than;
 584
 585         # Our problem with testing this portably is that the checksum code in
 586         # pp_unpack is able to cast signed to unsigned, and do modulo 2**n
 587         # arithmetic in unsigned ints, which perl has no operators to do.
 588         # (use integer; does signed ints, which won't wrap on UTS, which is just
 589         # fine with ANSI, but not with most people's assumptions.
 590         # This is why we need to supply the totals for 'Q' as there's no way in
 591         # perl to calculate them, short of unpack '%0Q' (is that documented?)
 592         # ** returns NVs; make sure it's IV.
 593         my $max = 1 + 2 * (int (2 ** ($len-1))-1); # The max possible checksum
 594         my $max_p1 = $max + 1;
 595         my ($max_is_integer, $max_p1_is_integer);
 596         $max_p1_is_integer = 1 unless $max_p1 + 1 == $max_p1;
 597         $max_is_integer = 1 if $max - 1 < ~0;
 598
 599         my $calc_sum;
 600         if (ref $total) {
 601             $calc_sum = &$total($len);
 602         } else {
 603             $calc_sum = $total;
 604             # Shift into range by some multiple of the total
 605             my $mult = $max_p1 ? int ($total / $max_p1) : undef;
 606             # Need this to make sure that -1 + (~0+1) is ~0 (ie still integer)
 607             $calc_sum = $total - $mult;
 608             $calc_sum -= $mult * $max;
 609             if ($calc_sum < 0) {
 610                 $calc_sum += 1;
 611                 $calc_sum += $max;
 612             }
 613         }
 614         if ($calc_sum == $calc_sum - 1 && $calc_sum == $max_p1) {
 615             # we're into floating point (either by getting out of the range of
 616             # UV arithmetic, or because we're doing a floating point checksum)
 617             # and our calculation of the checksum has become rounded up to
 618             # max_checksum + 1
 619             $calc_sum = 0;
 620         }
 621
 622         if ($calc_sum == $sum) { # HAS to be ==, not eq (so no is()).
 623             pass ("unpack '%$_$format' gave $sum");
 624         } else {
 625             my $delta = 1.000001;
 626             if ($format =~ tr /dDfF//
 627                 && ($calc_sum <= $sum * $delta && $calc_sum >= $sum / $delta)) {
 628                 pass ("unpack '%$_$format' gave $sum, expected $calc_sum");
 629             } else {
 630                 my $text = ref $total ? &$total($len) : $total;
 631                 fail;
 632                 print "# For list (" . join (", ", @_) . ") (total $text)"
 633                     . " packed with $format unpack '%$_$format' gave $sum,"
 634                     . " expected $calc_sum\n";
 635             }
 636         }
 637       }
 638     }
 639   }
 640 }
 641
 642 numbers ('c', -128, -1, 0, 1, 127);
 643 numbers ('C', 0, 1, 127, 128, 255);
 644 numbers ('W', 0, 1, 127, 128, 255, 256, 0x7ff, 0x800, 0xfffd);
 645 numbers ('s', -32768, -1, 0, 1, 32767);
 646 numbers ('S', 0, 1, 32767, 32768, 65535);
 647 numbers ('i', -2147483648, -1, 0, 1, 2147483647);
 648 numbers ('I', 0, 1, 2147483647, 2147483648, 4294967295);
 649 numbers ('l', -2147483648, -1, 0, 1, 2147483647);
 650 numbers ('L', 0, 1, 2147483647, 2147483648, 4294967295);
 651 numbers ('s!', -32768, -1, 0, 1, 32767);
 652 numbers ('S!', 0, 1, 32767, 32768, 65535);
 653 numbers ('i!', -2147483648, -1, 0, 1, 2147483647);
 654 numbers ('I!', 0, 1, 2147483647, 2147483648, 4294967295);
 655 numbers ('l!', -2147483648, -1, 0, 1, 2147483647);
 656 numbers ('L!', 0, 1, 2147483647, 2147483648, 4294967295);
 657 numbers ('n', 0, 1, 32767, 32768, 65535);
 658 numbers ('v', 0, 1, 32767, 32768, 65535);
 659 numbers ('N', 0, 1, 2147483647, 2147483648, 4294967295);
 660 numbers ('V', 0, 1, 2147483647, 2147483648, 4294967295);
 661 numbers ('n!', -32768, -1, 0, 1, 32767);
 662 numbers ('v!', -32768, -1, 0, 1, 32767);
 663 numbers ('N!', -2147483648, -1, 0, 1, 2147483647);
 664 numbers ('V!', -2147483648, -1, 0, 1, 2147483647);
 665 # All these should have exact binary representations:
 666 numbers ('f', -1, 0, 0.5, 42, 2**34);
 667 numbers ('d', -(2**34), -1, 0, 1, 2**34);
 668 ## These don't, but 'd' is NV.  XXX wrong, it's double
 669 #numbers ('d', -1, 0, 1, 1-exp(-1), -exp(1));
 670
 671 numbers_with_total ('q', -1,
 672                     -9223372036854775808, -1, 0, 1,9223372036854775807);
 673 # This total is icky, but the true total is 2**65-1, and need a way to generate
 674 # the epxected checksum on any system including those where NVs can preserve
 675 # 65 bits. (long double is 128 bits on sparc, so they certainly can)
 676 # or where rounding is down not up on binary conversion (crays)
 677 numbers_with_total ('Q', sub {
 678                       my $len = shift;
 679                       $len = 65 if $len > 65; # unmasked total is 2**65-1 here
 680                       my $total = 1 + 2 * (int (2**($len - 1)) - 1);
 681                       return 0 if $total == $total - 1; # Overflowed integers
 682                       return $total; # NVs still accurate to nearest integer
 683                     },
 684                     0, 1,9223372036854775807, 9223372036854775808,
 685                     18446744073709551615);
 686
 687 print "# pack nvNV byteorders\n";
 688
 689 is(pack("n", 0xdead), "\xde\xad");
 690 is(pack("v", 0xdead), "\xad\xde");
 691 is(pack("N", 0xdeadbeef), "\xde\xad\xbe\xef");
 692 is(pack("V", 0xdeadbeef), "\xef\xbe\xad\xde");
 693
 694 SKIP: {
 695   skip $no_signedness, 4 if $no_signedness;
 696   is(pack("n!", 0xdead), "\xde\xad");
 697   is(pack("v!", 0xdead), "\xad\xde");
 698   is(pack("N!", 0xdeadbeef), "\xde\xad\xbe\xef");
 699   is(pack("V!", 0xdeadbeef), "\xef\xbe\xad\xde");
 700 }
 701
 702 print "# test big-/little-endian conversion\n";
 703
 704 sub byteorder
 705 {
 706   my $format = shift;
 707   print "# byteorder test for $format\n";
 708   for my $value (@_) {
 709     SKIP: {
 710       my($nat,$be,$le) = eval { map { pack $format.$_, $value } '', '>', '<' };
 711       skip "cannot pack '$format' on this perl", 5
 712         if is_valid_error($@);
 713
 714       {
 715         use warnings qw(NONFATAL utf8);
 716         print "# [$value][$nat][$be][$le][$@]\n";
 717       }
 718
 719       SKIP: {
 720         skip "cannot compare native byteorder with big-/little-endian", 1
 721             if $ByteOrder eq 'unknown';
 722
 723         is($nat, $ByteOrder eq 'big' ? $be : $le);
 724       }
 725       is($be, reverse($le));
 726       my @x = eval { unpack "$format$format>$format<", $nat.$be.$le };
 727
 728       print "# [$value][", join('][', @x), "][$@]\n";
 729
 730       is($@, '');
 731       is($x[0], $x[1]);
 732       is($x[0], $x[2]);
 733     }
 734   }
 735 }
 736
 737 byteorder('s', -32768, -1, 0, 1, 32767);
 738 byteorder('S', 0, 1, 32767, 32768, 65535);
 739 byteorder('i', -2147483648, -1, 0, 1, 2147483647);
 740 byteorder('I', 0, 1, 2147483647, 2147483648, 4294967295);
 741 byteorder('l', -2147483648, -1, 0, 1, 2147483647);
 742 byteorder('L', 0, 1, 2147483647, 2147483648, 4294967295);
 743 byteorder('j', -2147483648, -1, 0, 1, 2147483647);
 744 byteorder('J', 0, 1, 2147483647, 2147483648, 4294967295);
 745 byteorder('s!', -32768, -1, 0, 1, 32767);
 746 byteorder('S!', 0, 1, 32767, 32768, 65535);
 747 byteorder('i!', -2147483648, -1, 0, 1, 2147483647);
 748 byteorder('I!', 0, 1, 2147483647, 2147483648, 4294967295);
 749 byteorder('l!', -2147483648, -1, 0, 1, 2147483647);
 750 byteorder('L!', 0, 1, 2147483647, 2147483648, 4294967295);
 751 byteorder('q', -9223372036854775808, -1, 0, 1, 9223372036854775807);
 752 byteorder('Q', 0, 1, 9223372036854775807, 9223372036854775808, 18446744073709551615);
 753 byteorder('f', -1, 0, 0.5, 42, 2**34);
 754 byteorder('F', -1, 0, 0.5, 42, 2**34);
 755 byteorder('d', -(2**34), -1, 0, 1, 2**34);
 756 byteorder('D', -(2**34), -1, 0, 1, 2**34);
 757
 758 print "# test negative numbers\n";
 759
 760 SKIP: {
 761   skip "platform is not using two's complement for negative integers", 120
 762     unless $IsTwosComplement;
 763
 764   for my $format (qw(s i l j s! i! l! q)) {
 765     SKIP: {
 766       my($nat,$be,$le) = eval { map { pack $format.$_, -1 } '', '>', '<' };
 767       skip "cannot pack '$format' on this perl", 15
 768         if is_valid_error($@);
 769
 770       my $len = length $nat;
 771       is($_, "\xFF"x$len) for $nat, $be, $le;
 772
 773       my(@val,@ref);
 774       if ($len >= 8) {
 775         @val = (-2, -81985529216486896, -9223372036854775808);
 776         @ref = ("\xFF\xFF\xFF\xFF\xFF\xFF\xFF\xFE",
 777                 "\xFE\xDC\xBA\x98\x76\x54\x32\x10",
 778                 "\x80\x00\x00\x00\x00\x00\x00\x00");
 779       }
 780       elsif ($len >= 4) {
 781         @val = (-2, -19088744, -2147483648);
 782         @ref = ("\xFF\xFF\xFF\xFE",
 783                 "\xFE\xDC\xBA\x98",
 784                 "\x80\x00\x00\x00");
 785       }
 786       else {
 787         @val = (-2, -292, -32768);
 788         @ref = ("\xFF\xFE",
 789                 "\xFE\xDC",
 790                 "\x80\x00");
 791       }
 792       for my $x (@ref) {
 793         if ($len > length $x) {
 794           $x = $x . "\xFF" x ($len - length $x);
 795         }
 796       }
 797
 798       for my $i (0 .. $#val) {
 799         my($nat,$be,$le) = eval { map { pack $format.$_, $val[$i] } '', '>', '<' };
 800         is($@, '');
 801
 802         SKIP: {
 803           skip "cannot compare native byteorder with big-/little-endian", 1
 804               if $ByteOrder eq 'unknown';
 805
 806           is($nat, $ByteOrder eq 'big' ? $be : $le);
 807         }
 808
 809         is($be, $ref[$i]);
 810         is($be, reverse($le));
 811       }
 812     }
 813   }
 814 }
 815
 816 {
 817   # /
 818
 819   my ($x, $y, $z);
 820   eval { ($x) = unpack '/a*','hello' };
 821   like($@, qr!'/' must follow a numeric type!);
 822   undef $x;
 823   eval { $x = unpack '/a*','hello' };
 824   like($@, qr!'/' must follow a numeric type!);
 825
 826   undef $x;
 827   eval { ($z,$x,$y) = unpack 'a3/A C/a* C/Z', "003ok \003yes\004z\000abc" };
 828   is($@, '');
 829   is($z, 'ok');
 830   is($x, 'yes');
 831   is($y, 'z');
 832   undef $z;
 833   eval { $z = unpack 'a3/A C/a* C/Z', "003ok \003yes\004z\000abc" };
 834   is($@, '');
 835   is($z, 'ok');
 836
 837
 838   undef $x;
 839   eval { ($x) = pack '/a*','hello' };
 840   like($@,  qr!Invalid type '/'!);
 841   undef $x;
 842   eval { $x = pack '/a*','hello' };
 843   like($@,  qr!Invalid type '/'!);
 844
 845   $z = pack 'n/a* N/Z* w/A*','string','hi there ','etc';
 846   my $expect = "\000\006string\0\0\0\012hi there \000\003etc";
 847   is($z, $expect);
 848
 849   undef $x;
 850   $expect = 'hello world';
 851   eval { ($x) = unpack ("w/a", chr (11) . "hello world!")};
 852   is($x, $expect);
 853   is($@, '');
 854
 855   undef $x;
 856   # Doing this in scalar context used to fail.
 857   eval { $x = unpack ("w/a", chr (11) . "hello world!")};
 858   is($@, '');
 859   is($x, $expect);
 860
 861   foreach (
 862            ['a/a*/a*', '212ab345678901234567','ab3456789012'],
 863            ['a/a*/a*', '3012ab345678901234567', 'ab3456789012'],
 864            ['a/a*/b*', '212ab', $Is_EBCDIC ? '100000010100' : '100001100100'],
 865   )
 866   {
 867     my ($pat, $in, $expect) = @$_;
 868     undef $x;
 869     eval { ($x) = unpack $pat, $in };
 870     is($@, '');
 871     is($x, $expect) ||
 872       printf "# list unpack ('$pat', '$in') gave %s, expected '$expect'\n",
 873              encode_list ($x);
 874
 875     undef $x;
 876     eval { $x = unpack $pat, $in };
 877     is($@, '');
 878     is($x, $expect) ||
 879       printf "# scalar unpack ('$pat', '$in') gave %s, expected '$expect'\n",
 880              encode_list ($x);
 881   }
 882
 883   # / with #
 884
 885   my $pattern = <<'EOU';
 886  a3/A                   # Count in ASCII
 887  C/a*                   # Count in a C char
 888  C/Z                    # Count in a C char but skip after \0
 889 EOU
 890
 891   $x = $y = $z =undef;
 892   eval { ($z,$x,$y) = unpack $pattern, "003ok \003yes\004z\000abc" };
 893   is($@, '');
 894   is($z, 'ok');
 895   is($x, 'yes');
 896   is($y, 'z');
 897   undef $x;
 898   eval { $z = unpack $pattern, "003ok \003yes\004z\000abc" };
 899   is($@, '');
 900   is($z, 'ok');
 901
 902   $pattern = <<'EOP';
 903   n/a*                  # Count as network short
 904   w/A*                  # Count a  BER integer
 905 EOP
 906   $expect = "\000\006string\003etc";
 907   $z = pack $pattern,'string','etc';
 908   is($z, $expect);
 909 }
 910
 911
 912 SKIP: {
 913     skip("(EBCDIC and) version strings are bad idea", 2) if $Is_EBCDIC;
 914
 915     is("1.20.300.4000", sprintf "%vd", pack("U*",1,20,300,4000));
 916     is("1.20.300.4000", sprintf "%vd", pack("  U*",1,20,300,4000));
 917 }
 918 isnt(v1.20.300.4000, sprintf "%vd", pack("C0U*",1,20,300,4000));
 919
 920 my $rslt = $Is_EBCDIC ? "156 67" : "199 162";
 921 is(join(" ", unpack("U0 C*", chr(0x1e2))), $rslt);
 922
 923 # does pack U create Unicode?
 924 is(ord(pack('U', 300)), 300);
 925
 926 # does unpack U deref Unicode?
 927 is((unpack('U', chr(300)))[0], 300);
 928
 929 # is unpack U the reverse of pack U for Unicode string?
 930 is("@{[unpack('U*', pack('U*', 100, 200, 300))]}", "100 200 300");
 931
 932 # is unpack U the reverse of pack U for byte string?
 933 is("@{[unpack('U*', pack('U*', 100, 200))]}", "100 200");
 934
 935
 936 SKIP: {
 937     skip "Not for EBCDIC", 4 if $Is_EBCDIC;
 938
 939     # does pack U0C create Unicode?
 940     is("@{[pack('U0C*', 100, 195, 136)]}", v100.v200);
 941
 942     # does pack C0U create characters?
 943     is("@{[pack('C0U*', 100, 200)]}", pack("C*", 100, 195, 136));
 944
 945     # does unpack U0U on byte data warn?
 946     {
 947         use warnings qw(NONFATAL all);;
 948
 949         my $bad = pack("U0C", 255);
 950         local $SIG{__WARN__} = sub { $@ = "@_" };
 951         my @null = unpack('U0U', $bad);
 952         like($@, qr/^Malformed UTF-8 character /);
 953     }
 954 }
 955
 956 {
 957   my $p = pack 'i*', -2147483648, ~0, 0, 1, 2147483647;
 958   my (@a);
 959   # bug - % had to be at the start of the pattern, no leading whitespace or
 960   # comments. %i! didn't work at all.
 961   foreach my $pat ('%32i*', ' %32i*', "# Muhahahaha\n%32i*", '%32i*  ',
 962                    '%32i!*', ' %32i!*', "\n#\n#\n\r \t\f%32i!*", '%32i!*#') {
 963     @a = unpack $pat, $p;
 964     is($a[0], 0xFFFFFFFF) || print "# $pat\n";
 965     @a = scalar unpack $pat, $p;
 966     is($a[0], 0xFFFFFFFF) || print "# $pat\n";
 967   }
 968
 969
 970   $p = pack 'I*', 42, 12;
 971   # Multiline patterns in scalar context failed.
 972   foreach my $pat ('I', <<EOPOEMSNIPPET, 'I#I', 'I # I', 'I # !!!') {
 973 # On the Ning Nang Nong
 974 # Where the Cows go Bong!
 975 # And the Monkeys all say Boo!
 976 I
 977 EOPOEMSNIPPET
 978     @a = unpack $pat, $p;
 979     is(scalar @a, 1);
 980     is($a[0], 42);
 981     @a = scalar unpack $pat, $p;
 982     is(scalar @a, 1);
 983     is($a[0], 42);
 984   }
 985
 986   # shorts (of all flavours) didn't calculate checksums > 32 bits with floating
 987   # point, so a pathologically long pattern would wrap at 32 bits.
 988   my $pat = "\xff\xff"x65538; # Start with it long, to save any copying.
 989   foreach (4,3,2,1,0) {
 990     my $len = 65534 + $_;
 991     is(unpack ("%33n$len", $pat), 65535 * $len);
 992   }
 993 }
 994
 995
 996 # pack x X @
 997 foreach (
 998          ['x', "N", "\0"],
 999          ['x4', "N", "\0"x4],
1000          ['xX', "N", ""],
1001          ['xXa*', "Nick", "Nick"],
1002          ['a5Xa5', "cameL", "llama", "camellama"],
1003          ['@4', 'N', "\0"x4],
1004          ['a*@8a*', 'Camel', 'Dromedary', "Camel\0\0\0Dromedary"],
1005          ['a*@4a', 'Perl rules', '!', 'Perl!'],
1006 )
1007 {
1008   my ($template, @in) = @$_;
1009   my $out = pop @in;
1010   my $got = eval {pack $template, @in};
1011   is($@, '');
1012   is($out, $got) ||
1013     printf "# pack ('$template', %s) gave %s expected %s\n",
1014            encode_list (@in), encode_list ($got), encode_list ($out);
1015 }
1016
1017 # unpack x X @
1018 foreach (
1019          ['x', "N"],
1020          ['xX', "N"],
1021          ['xXa*', "Nick", "Nick"],
1022          ['a5Xa5', "camellama", "camel", "llama"],
1023          ['@3', "ice"],
1024          ['@2a2', "water", "te"],
1025          ['a*@1a3', "steam", "steam", "tea"],
1026 )
1027 {
1028   my ($template, $in, @out) = @$_;
1029   my @got = eval {unpack $template, $in};
1030   is($@, '');
1031   ok (list_eq (\@got, \@out)) ||
1032     printf "# list unpack ('$template', %s) gave %s expected %s\n",
1033            _qq($in), encode_list (@got), encode_list (@out);
1034
1035   my $got = eval {unpack $template, $in};
1036   is($@, '');
1037   @out ? is( $got, $out[0] ) # 1 or more items; should get first
1038        : ok( !defined $got ) # 0 items; should get undef
1039     or printf "# scalar unpack ('$template', %s) gave %s expected %s\n",
1040               _qq($in), encode_list ($got), encode_list ($out[0]);
1041 }
1042
1043 {
1044     my $t = 'Z*Z*';
1045     my ($u, $v) = qw(foo xyzzy);
1046     my $p = pack($t, $u, $v);
1047     my @u = unpack($t, $p);
1048     is(scalar @u, 2);
1049     is($u[0], $u);
1050     is($u[1], $v);
1051 }
1052
1053 {
1054     is((unpack("w/a*", "\x02abc"))[0], "ab");
1055
1056     # "w/a*" should be seen as one unit
1057
1058     is(scalar unpack("w/a*", "\x02abc"), "ab");
1059 }
1060
1061 SKIP: {
1062   print "# group modifiers\n";
1063
1064   skip $no_endianness, 3 * 2 + 3 * 2 + 1 if $no_endianness;
1065
1066   for my $t (qw{ (s<)< (sl>s)> (s(l(sl)<l)s)< }) {
1067     print "# testing pattern '$t'\n";
1068     eval { ($_) = unpack($t, 'x'x18); };
1069     is($@, '');
1070     eval { $_ = pack($t, (0)x6); };
1071     is($@, '');
1072   }
1073
1074   for my $t (qw{ (s<)> (sl>s)< (s(l(sl)<l)s)> }) {
1075     print "# testing pattern '$t'\n";
1076     eval { ($_) = unpack($t, 'x'x18); };
1077     like($@, qr/Can't use '[<>]' in a group with different byte-order in unpack/);
1078     eval { $_ = pack($t, (0)x6); };
1079     like($@, qr/Can't use '[<>]' in a group with different byte-order in pack/);
1080   }
1081
1082   is(pack('L<L>', (0x12345678)x2),
1083      pack('(((L1)1)<)(((L)1)1)>1', (0x12345678)x2));
1084 }
1085
1086 {
1087   sub compress_template {
1088     my $t = shift;
1089     for my $mod (qw( < > )) {
1090       $t =~ s/((?:(?:[SILQJFDP]!?$mod|[^SILQJFDP\W]!?)(?:\d+|\*|\[(?:[^]]+)\])?\/?){2,})/
1091               my $x = $1; $x =~ s!$mod!!g ? "($x)$mod" : $x /ieg;
1092     }
1093     return $t;
1094   }
1095
1096   my %templates = (
1097     's<'                  => [-42],
1098     's<c2x![S]S<'         => [-42, -11, 12, 4711],
1099     '(i<j<[s]l<)3'        => [-11, -22, -33, 1000000, 1100, 2201, 3302,
1100                               -1000000, 32767, -32768, 1, -123456789 ],
1101     '(I!<4(J<2L<)3)5'     => [1 .. 65],
1102     'q<Q<'                => [-50000000005, 60000000006],
1103     'f<F<d<'              => [3.14159, 111.11, 2222.22],
1104     'D<cCD<'              => [1e42, -128, 255, 1e-42],
1105     'n/a*'                => ['/usr/bin/perl'],
1106     'C/a*S</A*L</Z*I</a*' => [qw(Just another Perl hacker)],
1107   );
1108
1109   for my $tle (sort keys %templates) {
1110     my @d = @{$templates{$tle}};
1111     my $tbe = $tle;
1112     $tbe =~ y/</>/;
1113     for my $t ($tbe, $tle) {
1114       my $c = compress_template($t);
1115       print "# '$t' -> '$c'\n";
1116       SKIP: {
1117         my $p1 = eval { pack $t, @d };
1118         skip "cannot pack '$t' on this perl", 5 if is_valid_error($@);
1119         my $p2 = eval { pack $c, @d };
1120         is($@, '');
1121         is($p1, $p2);
1122         s!(/[aAZ])\*!$1!g for $t, $c;
1123         my @u1 = eval { unpack $t, $p1 };
1124         is($@, '');
1125         my @u2 = eval { unpack $c, $p2 };
1126         is($@, '');
1127         is(join('!', @u1), join('!', @u2));
1128       }
1129     }
1130   }
1131 }
1132
1133 {
1134     # from Wolfgang Laun: fix in change #13163
1135
1136     my $s = 'ABC' x 10;
1137     my $t = '*';
1138     my $x = ord($t);
1139     my $buf = pack( 'Z*/A* C',  $s, $x );
1140     my $y;
1141
1142     my $h = $buf;
1143     $h =~ s/[^[:print:]]/./g;
1144     ( $s, $y ) = unpack( "Z*/A* C", $buf );
1145     is($h, "30.ABCABCABCABCABCABCABCABCABCABC$t");
1146     is(length $buf, 34);
1147     is($s, "ABCABCABCABCABCABCABCABCABCABC");
1148     is($y, $x);
1149 }
1150
1151 {
1152     # from Wolfgang Laun: fix in change #13288
1153
1154     eval { my $t=unpack("P*", "abc") };
1155     like($@, qr/'P' must have an explicit size/);
1156 }
1157
1158 {   # Grouping constructs
1159     my (@a, @b);
1160     @a = unpack '(SL)',   pack 'SLSLSL', 67..90;
1161     is("@a", "67 68");
1162     @a = unpack '(SL)3',   pack 'SLSLSL', 67..90;
1163     @b = (67..72);
1164     is("@a", "@b");
1165     @a = unpack '(SL)3',   pack 'SLSLSLSL', 67..90;
1166     is("@a", "@b");
1167     @a = unpack '(SL)[3]', pack 'SLSLSLSL', 67..90;
1168     is("@a", "@b");
1169     @a = unpack '(SL)[2] SL', pack 'SLSLSLSL', 67..90;
1170     is("@a", "@b");
1171     @a = unpack 'A/(SL)',  pack 'ASLSLSLSL', 3, 67..90;
1172     is("@a", "@b");
1173     @a = unpack 'A/(SL)SL',  pack 'ASLSLSLSL', 2, 67..90;
1174     is("@a", "@b");
1175     @a = unpack '(SL)*',   pack 'SLSLSLSL', 67..90;
1176     @b = (67..74);
1177     is("@a", "@b");
1178     @a = unpack '(SL)*SL',   pack 'SLSLSLSL', 67..90;
1179     is("@a", "@b");
1180     eval { @a = unpack '(*SL)',   '' };
1181     like($@, qr/\(\)-group starts with a count/);
1182     eval { @a = unpack '(3SL)',   '' };
1183     like($@, qr/\(\)-group starts with a count/);
1184     eval { @a = unpack '([3]SL)',   '' };
1185     like($@, qr/\(\)-group starts with a count/);
1186     eval { @a = pack '(*SL)' };
1187     like($@, qr/\(\)-group starts with a count/);
1188     @a = unpack '(SL)3 SL',   pack '(SL)4', 67..74;
1189     is("@a", "@b");
1190     @a = unpack '(SL)3 SL',   pack '(SL)[4]', 67..74;
1191     is("@a", "@b");
1192     @a = unpack '(SL)3 SL',   pack '(SL)*', 67..74;
1193     is("@a", "@b");
1194 }
1195
1196 {  # more on grouping (W.Laun)
1197   # @ absolute within ()-group
1198   my $badc = pack( '(a)*', unpack( '(@1a @0a @2)*', 'abcd' ) );
1199   is( $badc, 'badc' );
1200   my @b = ( 1, 2, 3 );
1201   my $buf = pack( '(@1c)((@2C)@3c)', @b );
1202   is( $buf, "\0\1\0\0\2\3" );
1203   my @a = unpack( '(@1c)((@2c)@3c)', $buf );
1204   is( "@a", "@b" );
1205
1206   # various unpack count/code scenarios
1207   my @Env = ( a => 'AAA', b => 'BBB' );
1208   my $env = pack( 'S(S/A*S/A*)*', @Env/2, @Env );
1209
1210   # unpack full length - ok
1211   my @pup = unpack( 'S/(S/A* S/A*)', $env );
1212   is( "@pup", "@Env" );
1213
1214   # warn when count/code goes beyond end of string
1215   # \0002 \0001 a \0003 AAA \0001 b \0003 BBB
1216   #     2     4 5     7  10    1213
1217   eval { @pup = unpack( 'S/(S/A* S/A*)', substr( $env, 0, 13 ) ) };
1218   like( $@, qr{length/code after end of string} );
1219
1220   # postfix repeat count
1221   $env = pack( '(S/A* S/A*)' . @Env/2, @Env );
1222
1223   # warn when count/code goes beyond end of string
1224   # \0001 a \0003 AAA \0001  b \0003 BBB
1225   #     2 3c    5   8    10 11    13  16
1226   eval { @pup = unpack( '(S/A* S/A*)' . @Env/2, substr( $env, 0, 11 ) ) };
1227   like( $@, qr{length/code after end of string} );
1228
1229   # catch stack overflow/segfault
1230   eval { $_ = pack( ('(' x 105) . 'A' . (')' x 105) ); };
1231   like( $@, qr{Too deeply nested \(\)-groups} );
1232 }
1233
1234 { # syntax checks (W.Laun)
1235   use warnings qw(NONFATAL all);;
1236   my @warning;
1237   local $SIG{__WARN__} = sub {
1238       push( @warning, $_[0] );
1239   };
1240   eval { my $s = pack( 'Ax![4c]A', 1..5 ); };
1241   like( $@, qr{Malformed integer in \[\]} );
1242
1243   eval { my $buf = pack( '(c/*a*)', 'AAA', 'BB' ); };
1244   like( $@, qr{'/' does not take a repeat count} );
1245
1246   eval { my @inf = unpack( 'c/1a', "\x03AAA\x02BB" ); };
1247   like( $@, qr{'/' does not take a repeat count} );
1248
1249   eval { my @inf = unpack( 'c/*a', "\x03AAA\x02BB" ); };
1250   like( $@, qr{'/' does not take a repeat count} );
1251
1252   # white space where possible
1253   my @Env = ( a => 'AAA', b => 'BBB' );
1254   my $env = pack( ' S ( S / A*   S / A* )* ', @Env/2, @Env );
1255   my @pup = unpack( ' S / ( S / A*   S / A* ) ', $env );
1256   is( "@pup", "@Env" );
1257
1258   # white space in 4 wrong places
1259   for my $temp (  'A ![4]', 'A [4]', 'A *', 'A 4' ){
1260       eval { my $s = pack( $temp, 'B' ); };
1261       like( $@, qr{Invalid type } );
1262   }
1263
1264   # warning for commas
1265   @warning = ();
1266   my $x = pack( 'I,A', 4, 'X' );
1267   like( $warning[0], qr{Invalid type ','} );
1268
1269   # comma warning only once
1270   @warning = ();
1271   $x = pack( 'C(C,C)C,C', 65..71  );
1272   like( scalar @warning, 1 );
1273
1274   # forbidden code in []
1275   eval { my $x = pack( 'A[@4]', 'XXXX' ); };
1276   like( $@, qr{Within \[\]-length '\@' not allowed} );
1277
1278   # @ repeat default 1
1279   my $s = pack( 'AA@A', 'A', 'B', 'C' );
1280   my @c = unpack( 'AA@A', $s );
1281   is( $s, 'AC' );
1282   is( "@c", "A C C" );
1283
1284   # no unpack code after /
1285   eval { my @a = unpack( "C/", "\3" ); };
1286   like( $@, qr{Code missing after '/'} );
1287
1288  SKIP: {
1289     skip $no_endianness, 6 if $no_endianness;
1290
1291     # modifier warnings
1292     @warning = ();
1293     $x = pack "I>>s!!", 47, 11;
1294     ($x) = unpack "I<<l!>!>", 'x'x20;
1295     is(scalar @warning, 5);
1296     like($warning[0], qr/Duplicate modifier '>' after 'I' in pack/);
1297     like($warning[1], qr/Duplicate modifier '!' after 's' in pack/);
1298     like($warning[2], qr/Duplicate modifier '<' after 'I' in unpack/);
1299     like($warning[3], qr/Duplicate modifier '!' after 'l' in unpack/);
1300     like($warning[4], qr/Duplicate modifier '>' after 'l' in unpack/);
1301   }
1302 }
1303
1304 {  # Repeat count [SUBEXPR]
1305    my @codes = qw( x A Z a c C W B b H h s v n S i I l V N L p P f F d
1306                    s! S! i! I! l! L! j J);
1307    my $G;
1308    if (eval { pack 'q', 1 } ) {
1309      push @codes, qw(q Q);
1310    } else {
1311      push @codes, qw(s S);      # Keep the count the same
1312    }
1313    if (eval { pack 'D', 1 } ) {
1314      push @codes, 'D';
1315    } else {
1316      push @codes, 'd';  # Keep the count the same
1317    }
1318
1319    push @codes, map { /^[silqjfdp]/i ? ("$_<", "$_>") : () } @codes;
1320
1321    my %val;
1322    @val{@codes} = map { / [Xx]  (?{ undef })
1323                         | [AZa] (?{ 'something' })
1324                         | C     (?{ 214 })
1325                         | W     (?{ 8188 })
1326                         | c     (?{ 114 })
1327                         | [Bb]  (?{ '101' })
1328                         | [Hh]  (?{ 'b8' })
1329                         | [svnSiIlVNLqQjJ]  (?{ 10111 })
1330                         | [FfDd]  (?{ 1.36514538e67 })
1331                         | [pP]  (?{ "try this buffer" })
1332                         /x; $^R } @codes;
1333    my @end = (0x12345678, 0x23456781, 0x35465768, 0x15263748);
1334    my $end = "N4";
1335
1336    for my $type (@codes) {
1337      my @list = $val{$type};
1338      @list = () unless defined $list[0];
1339      for my $count ('', '3', '[11]') {
1340        my $c = 1;
1341        $c = $1 if $count =~ /(\d+)/;
1342        my @list1 = @list;
1343        @list1 = (@list1) x $c unless $type =~ /[XxAaZBbHhP]/;
1344        for my $groupend ('', ')2', ')[8]') {
1345            my $groupbegin = ($groupend ? '(' : '');
1346            $c = 1;
1347            $c = $1 if $groupend =~ /(\d+)/;
1348            my @list2 = (@list1) x $c;
1349
1350            SKIP: {
1351              my $junk1 = "$groupbegin $type$count $groupend";
1352              # print "# junk1=$junk1\n";
1353              my $p = eval { pack $junk1, @list2 };
1354              skip "cannot pack '$type' on this perl", 12
1355                if is_valid_error($@);
1356              die "pack $junk1 failed: $@" if $@;
1357
1358              my $half = int( (length $p)/2 );
1359              for my $move ('', "X$half", "X!$half", 'x1', 'x!8', "x$half") {
1360                my $junk = "$junk1 $move";
1361                # print "# junk='$junk', list=(@list2)\n";
1362                $p = pack "$junk $end", @list2, @end;
1363                my @l = unpack "x[$junk] $end", $p;
1364                is(scalar @l, scalar @end);
1365                is("@l", "@end", "skipping x[$junk]");
1366              }
1367            }
1368        }
1369      }
1370    }
1371 }
1372
1373 # / is recognized after spaces in scalar context
1374 # XXXX no spaces are allowed in pack...  In pack only before the slash...
1375 is(scalar unpack('A /A Z20', pack 'A/A* Z20', 'bcde', 'xxxxx'), 'bcde');
1376 is(scalar unpack('A /A /A Z20', '3004bcde'), 'bcde');
1377
1378 { # X! and x!
1379   my $t = 'C[3]  x!8 C[2]';
1380   my @a = (0x73..0x77);
1381   my $p = pack($t, @a);
1382   is($p, "\x73\x74\x75\0\0\0\0\0\x76\x77");
1383   my @b = unpack $t, $p;
1384   is(scalar @b, scalar @a);
1385   is("@b", "@a", 'x!8');
1386   $t = 'x[5] C[6] X!8 C[2]';
1387   @a = (0x73..0x7a);
1388   $p = pack($t, @a);
1389   is($p, "\0\0\0\0\0\x73\x74\x75\x79\x7a");
1390   @b = unpack $t, $p;
1391   @a = (0x73..0x75, 0x79, 0x7a, 0x79, 0x7a);
1392   is(scalar @b, scalar @a);
1393   is("@b", "@a");
1394 }
1395
1396 { # struct {char c1; double d; char cc[2];}
1397   my $t = 'C x![d] d C[2]';
1398   my @a = (173, 1.283476517e-45, 42, 215);
1399   my $p = pack $t, @a;
1400   ok( length $p);
1401   my @b = unpack "$t X[$t] $t", $p;     # Extract, step back, extract again
1402   is(scalar @b, 2 * scalar @a);
1403   $b = "@b";
1404   $b =~ s/(?:17000+|16999+)\d+(e-45) /17$1 /gi; # stringification is gamble
1405   is($b, "@a @a");
1406
1407   use warnings qw(NONFATAL all);;
1408   my $warning;
1409   local $SIG{__WARN__} = sub {
1410       $warning = $_[0];
1411   };
1412   @b = unpack "x[C] x[$t] X[$t] X[C] $t", "$p\0";
1413
1414   is($warning, undef);
1415   is(scalar @b, scalar @a);
1416   $b = "@b";
1417   $b =~ s/(?:17000+|16999+)\d+(e-45) /17$1 /gi; # stringification is gamble
1418   is($b, "@a");
1419 }
1420
1421 is(length(pack("j", 0)), $Config{ivsize});
1422 is(length(pack("J", 0)), $Config{uvsize});
1423 is(length(pack("F", 0)), $Config{nvsize});
1424
1425 numbers ('j', -2147483648, -1, 0, 1, 2147483647);
1426 numbers ('J', 0, 1, 2147483647, 2147483648, 4294967295);
1427 numbers ('F', -(2**34), -1, 0, 1, 2**34);
1428 SKIP: {
1429     my $t = eval { unpack("D*", pack("D", 12.34)) };
1430
1431     skip "Long doubles not in use", 166 if $@ =~ /Invalid type/;
1432
1433     is(length(pack("D", 0)), $Config{longdblsize});
1434     numbers ('D', -(2**34), -1, 0, 1, 2**34);
1435 }
1436
1437 # Maybe this knowledge needs to be "global" for all of pack.t
1438 # Or a "can checksum" which would effectively be all the number types"
1439 my %cant_checksum = map {$_=> 1} qw(A Z u w);
1440 # not a b B h H
1441 foreach my $template (qw(A Z c C s S i I l L n N v V q Q j J f d F D u U w)) {
1442   SKIP: {
1443     my $packed = eval {pack "${template}4", 1, 4, 9, 16};
1444     if ($@) {
1445       die unless $@ =~ /Invalid type '$template'/;
1446       skip ("$template not supported on this perl",
1447             $cant_checksum{$template} ? 4 : 8);
1448     }
1449     my @unpack4 = unpack "${template}4", $packed;
1450     my @unpack = unpack "${template}*", $packed;
1451     my @unpack1 = unpack "${template}", $packed;
1452     my @unpack1s = scalar unpack "${template}", $packed;
1453     my @unpack4s = scalar unpack "${template}4", $packed;
1454     my @unpacks = scalar unpack "${template}*", $packed;
1455
1456     my @tests = ( ["${template}4 vs ${template}*", \@unpack4, \@unpack],
1457                   ["scalar ${template} ${template}", \@unpack1s, \@unpack1],
1458                   ["scalar ${template}4 vs ${template}", \@unpack4s, \@unpack1],
1459                   ["scalar ${template}* vs ${template}", \@unpacks, \@unpack1],
1460                 );
1461
1462     unless ($cant_checksum{$template}) {
1463       my @unpack4_c = unpack "\%${template}4", $packed;
1464       my @unpack_c = unpack "\%${template}*", $packed;
1465       my @unpack1_c = unpack "\%${template}", $packed;
1466       my @unpack1s_c = scalar unpack "\%${template}", $packed;
1467       my @unpack4s_c = scalar unpack "\%${template}4", $packed;
1468       my @unpacks_c = scalar unpack "\%${template}*", $packed;
1469
1470       push @tests,
1471         ( ["% ${template}4 vs ${template}*", \@unpack4_c, \@unpack_c],
1472           ["% scalar ${template} ${template}", \@unpack1s_c, \@unpack1_c],
1473           ["% scalar ${template}4 vs ${template}*", \@unpack4s_c, \@unpack_c],
1474           ["% scalar ${template}* vs ${template}*", \@unpacks_c, \@unpack_c],
1475         );
1476     }
1477     foreach my $test (@tests) {
1478       ok (list_eq ($test->[1], $test->[2]), $test->[0]) ||
1479         printf "# unpack gave %s expected %s\n",
1480           encode_list (@{$test->[1]}), encode_list (@{$test->[2]});
1481     }
1482   }
1483 }
1484
1485 ok(pack('u2', 'AA'), "[perl #8026]"); # used to hang and eat RAM in perl 5.7.2
1486
1487 $_ = pack('c', 65); # 'A' would not be EBCDIC-friendly
1488 is(unpack('c'), 65, "one-arg unpack (change #18751)"); # defaulting to $_
1489
1490 {
1491     my $a = "X\x0901234567\n" x 100; # \t would not be EBCDIC TAB
1492     my @a = unpack("(a1 c/a)*", $a);
1493     is(scalar @a, 200,       "[perl #15288]");
1494     is($a[-1], "01234567\n", "[perl #15288]");
1495     is($a[-2], "X",          "[perl #15288]");
1496 }
1497
1498 {
1499     use warnings qw(NONFATAL all);;
1500     my $warning;
1501     local $SIG{__WARN__} = sub {
1502         $warning = $_[0];
1503     };
1504     my $out = pack("u99", "foo" x 99);
1505     like($warning, qr/Field too wide in 'u' format in pack at /,
1506          "Warn about too wide uuencode");
1507     is($out, ("_" . "9F]O" x 21 . "\n") x 4 . "M" . "9F]O" x 15 . "\n",
1508        "Use max width in case of too wide uuencode");
1509 }
1510
1511 # checksums
1512 {
1513     # verify that unpack advances correctly wrt a checksum
1514     my (@x) = unpack("b10a", "abcd");
1515     my (@y) = unpack("%b10a", "abcd");
1516     is($x[1], $y[1], "checksum advance ok");
1517
1518     # verify that the checksum is not overflowed with C0
1519     if (ord('A') == 193) {
1520         is(unpack("C0%128U", "/bcd"), unpack("U0%128U", "abcd"), "checksum not overflowed");
1521     } else {
1522         is(unpack("C0%128U", "abcd"), unpack("U0%128U", "abcd"), "checksum not overflowed");
1523     }
1524 }
1525
1526 {
1527     # U0 and C0 must be scoped
1528     my (@x) = unpack("a(U0)U", "b\341\277\274");
1529     is($x[0], 'b', 'before scope');
1530     is($x[1], 8188, 'after scope');
1531
1532     is(pack("a(U0)U", "b", 8188), "b\341\277\274");
1533 }
1534
1535 {
1536     # counted length prefixes shouldn't change C0/U0 mode
1537     # (note the length is actually 0 in this test)
1538     if (ord('A') == 193) {
1539         is(join(',', unpack("aU0C/UU", "b\0\341\277\274")), 'b,0');
1540         is(join(',', unpack("aU0C/CU", "b\0\341\277\274")), 'b,0');
1541     } else {
1542         is(join(',', unpack("aC/UU",   "b\0\341\277\274")), 'b,8188');
1543         is(join(',', unpack("aC/CU",   "b\0\341\277\274")), 'b,8188');
1544         is(join(',', unpack("aU0C/UU", "b\0\341\277\274")), 'b,225');
1545         is(join(',', unpack("aU0C/CU", "b\0\341\277\274")), 'b,225');
1546     }
1547 }
1548
1549 {
1550     # "Z0" (bug #34062)
1551     my (@x) = unpack("C*", pack("CZ0", 1, "b"));
1552     is(join(',', @x), '1', 'pack Z0 doesn\'t destroy the character before');
1553 }
1554
1555 {
1556     # Encoding neutrality
1557     # String we will pull apart and rebuild in several ways:
1558     my $down = "\xf8\xf9\xfa\xfb\xfc\xfd\xfe\xff\x05\x06";
1559     my $up   = $down;
1560     utf8::upgrade($up);
1561
1562     my %expect =
1563         # [expected result,
1564         #  how many chars it should progress,
1565         #  (optional) expected result of pack]
1566         (a5 => ["\xf8\xf9\xfa\xfb\xfc", 5],
1567          A5 => ["\xf8\xf9\xfa\xfb\xfc", 5],
1568          Z5 => ["\xf8\xf9\xfa\xfb\xfc", 5, "\xf8\xf9\xfa\xfb\x00\xfd"],
1569          b21 => ["000111111001111101011", 3, "\xf8\xf9\x1a\xfb"],
1570          B21 => ["111110001111100111111", 3, "\xf8\xf9\xf8\xfb"],
1571          H5 => ["f8f9f", 3, "\xf8\xf9\xf0\xfb"],
1572          h5 => ["8f9fa", 3, "\xf8\xf9\x0a\xfb"],
1573          "s<"  => [-1544, 2],
1574          "s>"  => [-1799, 2],
1575          "S<"  => [0xf9f8, 2],
1576          "S>"  => [0xf8f9, 2],
1577          "l<"  => [-67438088, 4],
1578          "l>"  => [-117835013, 4],
1579          "L>"  => [0xf8f9fafb, 4],
1580          "L<"  => [0xfbfaf9f8, 4],
1581          n     => [0xf8f9, 2],
1582          N     => [0xf8f9fafb, 4],
1583          v     => [63992, 2],
1584          V     => [0xfbfaf9f8, 4],
1585          c     => [-8, 1],
1586          U0U   => [0xf8, 1],
1587          w     => ["8715569050387726213", 9],
1588          q     => ["-283686952306184", 8],
1589          Q     => ["18446460386757245432", 8],
1590          );
1591
1592     for my $string ($down, $up) {
1593         for my $format (sort {lc($a) cmp lc($b) || $a cmp $b } keys %expect) {
1594           SKIP: {
1595               my $expect = $expect{$format};
1596               # unpack upgraded and downgraded string
1597               my @result = eval { unpack("$format C0 W", $string) };
1598               skip "cannot pack/unpack '$format C0 W' on this perl", 5 if
1599                   $@ && is_valid_error($@);
1600               is(@result, 2, "Two results from unpack $format C0 W");
1601
1602               # pack to downgraded
1603               my $new = pack("$format C0 W", @result);
1604               is(length($new), $expect->[1]+1,
1605                  "pack $format C0 W should give $expect->[1]+1 chars");
1606               is($new, $expect->[2] || substr($string, 0, length $new),
1607                  "pack $format C0 W returns expected value");
1608
1609               # pack to upgraded
1610               $new = pack("a0 $format C0 W", chr(256), @result);
1611               is(length($new), $expect->[1]+1,
1612                  "pack a0 $format C0 W should give $expect->[1]+1 chars");
1613               is($new, $expect->[2] || substr($string, 0, length $new),
1614                  "pack a0 $format C0 W returns expected value");
1615           }
1616         }
1617     }
1618 }
1619
1620 {
1621     # Encoding neutrality, numbers
1622     my $val = -2.68;
1623     for my $format (qw(s S i I l L j J f d F D q Q
1624                        s! S! i! I! l! L! n! N! v! V!)) {
1625       SKIP: {
1626           my $down = eval { pack($format, $val) };
1627           skip "cannot pack/unpack $format on this perl", 9 if
1628               $@ && is_valid_error($@);
1629           ok(!utf8::is_utf8($down), "Simple $format pack doesn't get upgraded");
1630           my $up = pack("a0 $format", chr(256), $val);
1631           ok(utf8::is_utf8($up), "a0 $format with high char leads to upgrade");
1632           is($down, $up, "$format generated strings are equal though");
1633           my @down_expanded = unpack("$format W", $down . chr(0xce));
1634           is(@down_expanded, 2, "Expand to two values");
1635           is($down_expanded[1], 0xce,
1636              "unpack $format left us at the expected position");
1637           my @up_expanded   = unpack("$format W", $up   . chr(0xce));
1638           is(@up_expanded, 2, "Expand to two values");
1639           is($up_expanded[1], 0xce,
1640              "unpack $format left us at the expected position");
1641           is($down_expanded[0], $up_expanded[0], "$format unpack was neutral");
1642           is(pack($format, $down_expanded[0]), $down, "Pack $format undoes unpack $format");
1643       }
1644     }
1645 }
1646
1647 {
1648     # C *is* neutral
1649     my $down = "\xf8\xf9\xfa\xfb\xfc\xfd\xfe\xff\x05\x06";
1650     my $up   = $down;
1651     utf8::upgrade($up);
1652     my @down = unpack("C*", $down);
1653     my @expect_down = (0xf8, 0xf9, 0xfa, 0xfb, 0xfc, 0xfd, 0xfe, 0xff, 0x05, 0x06);
1654     is("@down", "@expect_down", "byte expand");
1655     is(pack("C*", @down), $down, "byte join");
1656
1657     my @up   = unpack("C*", $up);
1658     my @expect_up = (0xf8, 0xf9, 0xfa, 0xfb, 0xfc, 0xfd, 0xfe, 0xff, 0x05, 0x06);
1659     is("@up", "@expect_up", "UTF-8 expand");
1660     is(pack("U0C0C*", @up), $up, "UTF-8 join");
1661 }
1662
1663 {
1664     # Harder cases for the neutrality test
1665
1666     # u format
1667     my $down = "\xf8\xf9\xfa\xfb\xfc\xfd\xfe\xff\x05\x06";
1668     my $up   = $down;
1669     utf8::upgrade($up);
1670     is(pack("u", $down), pack("u", $up), "u pack is neutral");
1671     is(unpack("u", pack("u", $down)), $down, "u unpack to downgraded works");
1672     is(unpack("U0C0u", pack("u", $down)), $up, "u unpack to upgraded works");
1673
1674     # p/P format
1675     # This actually only tests something if the address contains a byte >= 0x80
1676     my $str = "abc\xa5\x00\xfede";
1677     $down = pack("p", $str);
1678     is(pack("P", $str), $down);
1679     is(pack("U0C0p", $str), $down);
1680     is(pack("U0C0P", $str), $down);
1681     is(unpack("p", $down), "abc\xa5", "unpack p downgraded");
1682     $up   = $down;
1683     utf8::upgrade($up);
1684     is(unpack("p", $up), "abc\xa5", "unpack p upgraded");
1685
1686     is(unpack("P7", $down), "abc\xa5\x00\xfed", "unpack P downgraded");
1687     is(unpack("P7", $up),   "abc\xa5\x00\xfed", "unpack P upgraded");
1688
1689     # x, X and @
1690     $down = "\xf8\xf9\xfa\xfb\xfc\xfd\xfe\xff\x05\x06";
1691     $up   = $down;
1692     utf8::upgrade($up);
1693
1694     is(unpack('@4W', $down), 0xfc, "\@positioning on downgraded string");
1695     is(unpack('@4W', $up),   0xfc, "\@positioning on upgraded string");
1696
1697     is(unpack('@4x2W', $down), 0xfe, "x moving on downgraded string");
1698     is(unpack('@4x2W', $up),   0xfe, "x moving on upgraded string");
1699     is(unpack('@4x!4W', $down), 0xfc, "x! moving on downgraded string");
1700     is(unpack('@4x!4W', $up),   0xfc, "x! moving on upgraded string");
1701     is(unpack('@5x!4W', $down), 0x05, "x! moving on downgraded string");
1702     is(unpack('@5x!4W', $up),   0x05, "x! moving on upgraded string");
1703
1704     is(unpack('@4X2W', $down), 0xfa, "X moving on downgraded string");
1705     is(unpack('@4X2W', $up),   0xfa, "X moving on upgraded string");
1706     is(unpack('@4X!4W', $down), 0xfc, "X! moving on downgraded string");
1707     is(unpack('@4X!4W', $up),   0xfc, "X! moving on upgraded string");
1708     is(unpack('@5X!4W', $down), 0xfc, "X! moving on downgraded string");
1709     is(unpack('@5X!4W', $up),   0xfc, "X! moving on upgraded string");
1710     is(unpack('@5X!8W', $down), 0xf8, "X! moving on downgraded string");
1711     is(unpack('@5X!8W', $up),   0xf8, "X! moving on upgraded string");
1712
1713     is(pack("W2x", 0xfa, 0xe3), "\xfa\xe3\x00", "x on downgraded string");
1714     is(pack("W2x!4", 0xfa, 0xe3), "\xfa\xe3\x00\x00",
1715        "x! on downgraded string");
1716     is(pack("W2x!2", 0xfa, 0xe3), "\xfa\xe3", "x! on downgraded string");
1717     is(pack("U0C0W2x", 0xfa, 0xe3), "\xfa\xe3\x00", "x on upgraded string");
1718     is(pack("U0C0W2x!4", 0xfa, 0xe3), "\xfa\xe3\x00\x00",
1719        "x! on upgraded string");
1720     is(pack("U0C0W2x!2", 0xfa, 0xe3), "\xfa\xe3", "x! on upgraded string");
1721     is(pack("W2X", 0xfa, 0xe3), "\xfa", "X on downgraded string");
1722     is(pack("U0C0W2X", 0xfa, 0xe3), "\xfa", "X on upgraded string");
1723     is(pack("W2X!2", 0xfa, 0xe3), "\xfa\xe3", "X! on downgraded string");
1724     is(pack("U0C0W2X!2", 0xfa, 0xe3), "\xfa\xe3", "X! on upgraded string");
1725     is(pack("W3X!2", 0xfa, 0xe3, 0xa6), "\xfa\xe3", "X! on downgraded string");
1726     is(pack("U0C0W3X!2", 0xfa, 0xe3, 0xa6), "\xfa\xe3",
1727        "X! on upgraded string");
1728
1729     # backward eating through a ( moves the group starting point backwards
1730     is(pack("a*(Xa)", "abc", "q"), "abq",
1731        "eating before strbeg moves it back");
1732     is(pack("a*(Xa)", "ab" . chr(512), "q"), "abq",
1733        "eating before strbeg moves it back");
1734
1735     # Check marked_upgrade
1736     is(pack('W(W(Wa@3W)@6W)@9W', 0xa1, 0xa2, 0xa3, "a", 0xa4, 0xa5, 0xa6),
1737        "\xa1\xa2\xa3a\x00\xa4\x00\xa5\x00\xa6");
1738     $up = "a";
1739     utf8::upgrade($up);
1740     is(pack('W(W(Wa@3W)@6W)@9W', 0xa1, 0xa2, 0xa3, $up, 0xa4, 0xa5, 0xa6),
1741        "\xa1\xa2\xa3a\x00\xa4\x00\xa5\x00\xa6", "marked upgrade caused by a");
1742     is(pack('W(W(WW@3W)@6W)@9W', 0xa1, 0xa2, 0xa3, 256, 0xa4, 0xa5, 0xa6),
1743        "\xa1\xa2\xa3\x{100}\x00\xa4\x00\xa5\x00\xa6",
1744        "marked upgrade caused by W");
1745     is(pack('W(W(WU0aC0@3W)@6W)@9W', 0xa1, 0xa2, 0xa3, "a", 0xa4, 0xa5, 0xa6),
1746        "\xa1\xa2\xa3a\x00\xa4\x00\xa5\x00\xa6", "marked upgrade caused by U0");
1747
1748     # a, A and Z
1749     $down = "\xa4\xa6\xa7";
1750     $up   = $down;
1751     utf8::upgrade($up);
1752     utf8::upgrade(my $high = "\xfeb");
1753
1754     for my $format ("a0", "A0", "Z0", "U0a0C0", "U0A0C0", "U0Z0C0") {
1755         is(pack("a* $format a*", "ab", $down, "cd"), "abcd",
1756            "$format format on plain string");
1757         is(pack("a* $format a*", "ab", $up,   "cd"), "abcd",
1758            "$format format on upgraded string");
1759         is(pack("a* $format a*", $high, $down, "cd"), "\xfebcd",
1760            "$format format on plain string");
1761         is(pack("a* $format a*", $high, $up,   "cd"), "\xfebcd",
1762            "$format format on upgraded string");
1763         my @down = unpack("a1 $format a*", "\xfeb");
1764         is("@down", "\xfe  b", "unpack $format");
1765         my @up = unpack("a1 $format a*", $high);
1766         is("@up", "\xfe  b", "unpack $format");
1767     }
1768     is(pack("a1", $high), "\xfe");
1769     is(pack("A1", $high), "\xfe");
1770     is(pack("Z1", $high), "\x00");
1771     is(pack("a2", $high), "\xfeb");
1772     is(pack("A2", $high), "\xfeb");
1773     is(pack("Z2", $high), "\xfe\x00");
1774     is(pack("a5", $high), "\xfeb\x00\x00\x00");
1775     is(pack("A5", $high), "\xfeb   ");
1776     is(pack("Z5", $high), "\xfeb\x00\x00\x00");
1777     is(pack("a*", $high), "\xfeb");
1778     is(pack("A*", $high), "\xfeb");
1779     is(pack("Z*", $high), "\xfeb\x00");
1780
1781     utf8::upgrade($high = "\xc3\xbeb");
1782     is(pack("U0a2", $high), "\xfe");
1783     is(pack("U0A2", $high), "\xfe");
1784     is(pack("U0Z1", $high), "\x00");
1785     is(pack("U0a3", $high), "\xfeb");
1786     is(pack("U0A3", $high), "\xfeb");
1787     is(pack("U0Z3", $high), "\xfe\x00");
1788     is(pack("U0a6", $high), "\xfeb\x00\x00\x00");
1789     is(pack("U0A6", $high), "\xfeb   ");
1790     is(pack("U0Z6", $high), "\xfeb\x00\x00\x00");
1791     is(pack("U0a*", $high), "\xfeb");
1792     is(pack("U0A*", $high), "\xfeb");
1793     is(pack("U0Z*", $high), "\xfeb\x00");
1794 }
1795 {
1796     # pack /
1797     my @array = 1..14;
1798     my @out = unpack("N/S", pack("N/S", @array) . "abcd");
1799     is("@out", "@array", "pack N/S works");
1800     @out = unpack("N/S*", pack("N/S*", @array) . "abcd");
1801     is("@out", "@array", "pack N/S* works");
1802     @out = unpack("N/S*", pack("N/S14", @array) . "abcd");
1803     is("@out", "@array", "pack N/S14 works");
1804     @out = unpack("N/S*", pack("N/S15", @array) . "abcd");
1805     is("@out", "@array", "pack N/S15 works");
1806     @out = unpack("N/S*", pack("N/S13", @array) . "abcd");
1807     is("@out", "@array[0..12]", "pack N/S13 works");
1808     @out = unpack("N/S*", pack("N/S0", @array) . "abcd");
1809     is("@out", "", "pack N/S0 works");
1810     is(pack("Z*/a0", "abc"), "0\0", "pack Z*/a0 makes a short string");
1811     is(pack("Z*/Z0", "abc"), "0\0", "pack Z*/Z0 makes a short string");
1812     is(pack("Z*/a3", "abc"), "3\0abc", "pack Z*/a3 makes a full string");
1813     is(pack("Z*/Z3", "abc"), "3\0ab\0", "pack Z*/Z3 makes a short string");
1814     is(pack("Z*/a5", "abc"), "5\0abc\0\0", "pack Z*/a5 makes a long string");
1815     is(pack("Z*/Z5", "abc"), "5\0abc\0\0", "pack Z*/Z5 makes a long string");
1816     is(pack("Z*/Z"), "1\0\0", "pack Z*/Z makes an extended string");
1817     is(pack("Z*/Z", ""), "1\0\0", "pack Z*/Z makes an extended string");
1818     is(pack("Z*/a", ""), "0\0", "pack Z*/a makes an extended string");
1819 }
1820 {
1821     # unpack("A*", $unicode) strips general unicode spaces
1822     is(unpack("A*", "ab \n\xa0 \0"), "ab \n\xa0",
1823        'normal A* strip leaves \xa0');
1824     is(unpack("U0C0A*", "ab \n\xa0 \0"), "ab \n\xa0",
1825        'normal A* strip leaves \xa0 even if it got upgraded for technical reasons');
1826     is(unpack("A*", pack("a*(U0U)a*", "ab \n", 0xa0, " \0")), "ab",
1827        'upgraded strings A* removes \xa0');
1828     is(unpack("A*", pack("a*(U0UU)a*", "ab \n", 0xa0, 0x1680, " \0")), "ab",
1829        'upgraded strings A* removes all unicode whitespace');
1830     is(unpack("A5", pack("a*(U0U)a*", "ab \n", 0x1680, "def", "ab")), "ab",
1831        'upgraded strings A5 removes all unicode whitespace');
1832     is(unpack("A*", pack("U", 0x1680)), "",
1833        'upgraded strings A* with nothing left');
1834 }
1835 {
1836     # Testing unpack . and .!
1837     is(unpack(".", "ABCD"), 0, "offset at start of string is 0");
1838     is(unpack(".", ""), 0, "offset at start of empty string is 0");
1839     is(unpack("x3.", "ABCDEF"), 3, "simple offset works");
1840     is(unpack("x3.", "ABC"), 3, "simple offset at end of string works");
1841     is(unpack("x3.0", "ABC"), 0, "self offset is 0");
1842     is(unpack("x3(x2.)", "ABCDEF"), 2, "offset is relative to inner group");
1843     is(unpack("x3(X2.)", "ABCDEF"), -2,
1844        "negative offset relative to inner group");
1845     is(unpack("x3(X2.2)", "ABCDEF"), 1, "offset is relative to inner group");
1846     is(unpack("x3(x2.0)", "ABCDEF"), 0, "self offset in group is still 0");
1847     is(unpack("x3(x2.2)", "ABCDEF"), 5, "offset counts groups");
1848     is(unpack("x3(x2.*)", "ABCDEF"), 5, "star offset is relative to start");
1849
1850     my $high = chr(8188) x 6;
1851     is(unpack("x3(x2.)", $high), 2, "utf8 offset is relative to inner group");
1852     is(unpack("x3(X2.)", $high), -2,
1853        "utf8 negative offset relative to inner group");
1854     is(unpack("x3(X2.2)", $high), 1, "utf8 offset counts groups");
1855     is(unpack("x3(x2.0)", $high), 0, "utf8 self offset in group is still 0");
1856     is(unpack("x3(x2.2)", $high), 5, "utf8 offset counts groups");
1857     is(unpack("x3(x2.*)", $high), 5, "utf8 star offset is relative to start");
1858
1859     is(unpack("U0x3(x2.)", $high), 2,
1860        "U0 mode utf8 offset is relative to inner group");
1861     is(unpack("U0x3(X2.)", $high), -2,
1862        "U0 mode utf8 negative offset relative to inner group");
1863     is(unpack("U0x3(X2.2)", $high), 1,
1864        "U0 mode utf8 offset counts groups");
1865     is(unpack("U0x3(x2.0)", $high), 0,
1866        "U0 mode utf8 self offset in group is still 0");
1867     is(unpack("U0x3(x2.2)", $high), 5,
1868        "U0 mode utf8 offset counts groups");
1869     is(unpack("U0x3(x2.*)", $high), 5,
1870        "U0 mode utf8 star offset is relative to start");
1871
1872     is(unpack("x3(x2.!)", $high), 2*3,
1873        "utf8 offset is relative to inner group");
1874     is(unpack("x3(X2.!)", $high), -2*3,
1875        "utf8 negative offset relative to inner group");
1876     is(unpack("x3(X2.!2)", $high), 1*3,
1877        "utf8 offset counts groups");
1878     is(unpack("x3(x2.!0)", $high), 0,
1879        "utf8 self offset in group is still 0");
1880     is(unpack("x3(x2.!2)", $high), 5*3,
1881        "utf8 offset counts groups");
1882     is(unpack("x3(x2.!*)", $high), 5*3,
1883        "utf8 star offset is relative to start");
1884
1885     is(unpack("U0x3(x2.!)", $high), 2,
1886        "U0 mode utf8 offset is relative to inner group");
1887     is(unpack("U0x3(X2.!)", $high), -2,
1888        "U0 mode utf8 negative offset relative to inner group");
1889     is(unpack("U0x3(X2.!2)", $high), 1,
1890        "U0 mode utf8 offset counts groups");
1891     is(unpack("U0x3(x2.!0)", $high), 0,
1892        "U0 mode utf8 self offset in group is still 0");
1893     is(unpack("U0x3(x2.!2)", $high), 5,
1894        "U0 mode utf8 offset counts groups");
1895     is(unpack("U0x3(x2.!*)", $high), 5,
1896        "U0 mode utf8 star offset is relative to start");
1897 }
1898 {
1899     # Testing pack . and .!
1900     is(pack("(a)5 .", 1..5, 3), "123", ". relative to string start, shorten");
1901     eval { () = pack("(a)5 .", 1..5, -3) };
1902     like($@, qr{'\.' outside of string in pack}, "Proper error message");
1903     is(pack("(a)5 .", 1..5, 8), "12345\x00\x00\x00",
1904        ". relative to string start, extend");
1905     is(pack("(a)5 .", 1..5, 5), "12345", ". relative to string start, keep");
1906
1907     is(pack("(a)5 .0", 1..5, -3), "12",
1908        ". relative to string current, shorten");
1909     is(pack("(a)5 .0", 1..5, 2), "12345\x00\x00",
1910        ". relative to string current, extend");
1911     is(pack("(a)5 .0", 1..5, 0), "12345",
1912        ". relative to string current, keep");
1913
1914     is(pack("(a)5 (.)", 1..5, -3), "12",
1915        ". relative to group, shorten");
1916     is(pack("(a)5 (.)", 1..5, 2), "12345\x00\x00",
1917        ". relative to group, extend");
1918     is(pack("(a)5 (.)", 1..5, 0), "12345",
1919        ". relative to group, keep");
1920
1921     is(pack("(a)3 ((a)2 .)", 1..5, -2), "1",
1922        ". relative to group, shorten");
1923     is(pack("(a)3 ((a)2 .)", 1..5, 2), "12345",
1924        ". relative to group, keep");
1925     is(pack("(a)3 ((a)2 .)", 1..5, 4), "12345\x00\x00",
1926        ". relative to group, extend");
1927
1928     is(pack("(a)3 ((a)2 .2)", 1..5, 2), "12",
1929        ". relative to counted group, shorten");
1930     is(pack("(a)3 ((a)2 .2)", 1..5, 7), "12345\x00\x00",
1931        ". relative to counted group, extend");
1932     is(pack("(a)3 ((a)2 .2)", 1..5, 5), "12345",
1933        ". relative to counted group, keep");
1934
1935     is(pack("(a)3 ((a)2 .*)", 1..5, 2), "12",
1936        ". relative to start, shorten");
1937     is(pack("(a)3 ((a)2 .*)", 1..5, 7), "12345\x00\x00",
1938        ". relative to start, extend");
1939     is(pack("(a)3 ((a)2 .*)", 1..5, 5), "12345",
1940        ". relative to start, keep");
1941
1942     is(pack('(a)5 (. @2 a)', 1..5, -3, "a"), "12\x00\x00a",
1943        ". based shrink properly updates group starts");
1944
1945     is(pack("(W)3 ((W)2 .)", 0x301..0x305, -2), "\x{301}",
1946        "utf8 . relative to group, shorten");
1947     is(pack("(W)3 ((W)2 .)", 0x301..0x305, 2),
1948        "\x{301}\x{302}\x{303}\x{304}\x{305}",
1949        "utf8 . relative to group, keep");
1950     is(pack("(W)3 ((W)2 .)", 0x301..0x305, 4),
1951        "\x{301}\x{302}\x{303}\x{304}\x{305}\x00\x00",
1952        "utf8 . relative to group, extend");
1953
1954     is(pack("(W)3 ((W)2 .!)", 0x301..0x305, -2), "\x{301}\x{302}",
1955        "utf8 . relative to group, shorten");
1956     is(pack("(W)3 ((W)2 .!)", 0x301..0x305, 4),
1957        "\x{301}\x{302}\x{303}\x{304}\x{305}",
1958        "utf8 . relative to group, keep");
1959     is(pack("(W)3 ((W)2 .!)", 0x301..0x305, 6),
1960        "\x{301}\x{302}\x{303}\x{304}\x{305}\x00\x00",
1961        "utf8 . relative to group, extend");
1962
1963     is(pack('(W)5 (. @2 a)', 0x301..0x305, -3, "a"),
1964        "\x{301}\x{302}\x00\x00a",
1965        "utf8 . based shrink properly updates group starts");
1966 }
1967 {
1968     # Testing @!
1969     is(pack('a* @3',  "abcde"), "abc", 'Test basic @');
1970     is(pack('a* @!3', "abcde"), "abc", 'Test basic @!');
1971     is(pack('a* @2', "\x{301}\x{302}\x{303}\x{304}\x{305}"), "\x{301}\x{302}",
1972        'Test basic utf8 @');
1973     is(pack('a* @!2', "\x{301}\x{302}\x{303}\x{304}\x{305}"), "\x{301}",
1974        'Test basic utf8 @!');
1975
1976     is(unpack('@4 a*',  "abcde"), "e", 'Test basic @');
1977     is(unpack('@!4 a*', "abcde"), "e", 'Test basic @!');
1978     is(unpack('@4 a*',  "\x{301}\x{302}\x{303}\x{304}\x{305}"), "\x{305}",
1979        'Test basic utf8 @');
1980     is(unpack('@!4 a*', "\x{301}\x{302}\x{303}\x{304}\x{305}"),
1981        "\x{303}\x{304}\x{305}", 'Test basic utf8 @!');
1982 }
1983 {
1984     #50256
1985     my ($v) = split //, unpack ('(B)*', 'ab');
1986     is($v, 0); # Doesn't SEGV :-)
1987 }
1988 {
1989     #73814
1990     my $x = runperl( prog => 'print split( /,/, unpack(q(%2H*), q(hello world))), qq(\n)' );
1991     is($x, "0\n", "split /a/, unpack('%2H*'...) didn't crash");
1992
1993     my $y = runperl( prog => 'print split( /,/, unpack(q(%32u*), q(#,3,Q)), qq(\n)), qq(\n)' );
1994     is($y, "0\n", "split /a/, unpack('%32u*'...) didn't crash");
1995 }