This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
576fe5cfec44da319c59f468dc70f935bca5c91f
[perl5.git] / write_buildcustomize.pl
1 #!./miniperl -w
2
3 use strict;
4 if (@ARGV) {
5     my $dir = shift;
6     chdir $dir or die "Can't chdir '$dir': $!";
7     unshift @INC, 'lib';
8 }
9
10 my $file = 'lib/buildcustomize.pl';
11
12 # To clarify, this isn't the entire suite of modules considered "toolchain"
13 # It's not even all modules needed to build ext/
14 # It's just the source paths of the (minimum complete set of) modules in ext/
15 # needed to build the nonxs modules
16 # After which, all nonxs modules are in lib, which was always sufficient to
17 # allow miniperl to build everything else.
18 # Term::ReadLine is not here for building but for allowing the debugger to
19 # run under miniperl when nothing but miniperl will build :-(.
20
21 my @toolchain = qw(cpan/AutoLoader/lib
22                    dist/Carp/lib
23                    dist/Cwd dist/Cwd/lib
24                    dist/ExtUtils-Command/lib
25                    dist/ExtUtils-Install/lib
26                    cpan/ExtUtils-MakeMaker/lib
27                    dist/ExtUtils-Manifest/lib
28                    cpan/File-Path/lib
29                    ext/re
30                    dist/Term-ReadLine/lib
31                    );
32
33 # Used only in ExtUtils::Liblist::Kid::_win32_ext()
34 push @toolchain, 'cpan/Text-ParseWords/lib' if $^O eq 'MSWin32';
35 push @toolchain, 'ext/VMS-Filespec/lib' if $^O eq 'VMS';
36
37 unshift @INC, @toolchain;
38 require File::Spec::Functions;
39
40 # lib must be last, as the toolchain modules write themselves into it
41 # as they build, and it's important that @INC order ensures that the partially
42 # written files are always masked by the complete versions.
43
44 my $inc = join ",\n        ",
45     map { "q\0$_\0" }
46     (map {File::Spec::Functions::rel2abs($_)} @toolchain, 'lib'), '.';
47
48 open my $fh, '>', $file
49     or die "Can't open $file: $!";
50
51 my $error;
52
53 # If any of the system's build tools are written in Perl, then this module
54 # may well be loaded by a much older version than we are building. So keep it
55 # as backwards compatible as is easy.
56 print $fh <<"EOT" or $error = "Can't print to $file: $!";
57 #!perl
58
59 # We are miniperl, building extensions
60 # Reset \@INC completely, adding the directories we need, and removing the
61 # installed directories (which we don't need to read, and may confuse us)
62 \@INC = ($inc);
63 EOT
64
65 if ($error) {
66     close $fh
67         or warn "Can't unlink $file after error: $!";
68 } else {
69     if (close $fh) {
70         do $file and exit;
71         $error = "Can't load generated $file: $@";
72     } else {
73         $error = "Can't close $file: $!";
74     }
75 }
76
77 # It's going very wrong, so try to remove the botched file.
78
79 unlink $file
80     or warn "Can't unlink $file after error: $!";
81 die $error;
82
83 # Local variables:
84 # cperl-indent-level: 4
85 # indent-tabs-mode: nil
86 # End:
87 #
88 # ex: set ts=8 sts=4 sw=4 et: