t/test.pl

   1 #
   2 # t/test.pl - most of Test::More functionality without the fuss, plus
   3 # has mappings native_to_latin1 and latin1_to_native so that fewer tests
   4 # on non ASCII-ish platforms need to be skipped
   5
   6
   7 # NOTE:
   8 #
   9 # Increment ($x++) has a certain amount of cleverness for things like
  10 #
  11 #   $x = 'zz';
  12 #   $x++; # $x eq 'aaa';
  13 #
  14 # stands more chance of breaking than just a simple
  15 #
  16 #   $x = $x + 1
  17 #
  18 # In this file, we use the latter "Baby Perl" approach, and increment
  19 # will be worked over by t/op/inc.t
  20
  21 $Level = 1;
  22 my $test = 1;
  23 my $planned;
  24 my $noplan;
  25 my $Perl;       # Safer version of $^X set by which_perl()
  26
  27 # This defines ASCII/UTF-8 vs EBCDIC/UTF-EBCDIC
  28 $::IS_ASCII  = ord 'A' ==  65;
  29 $::IS_EBCDIC = ord 'A' == 193;
  30
  31 $TODO = 0;
  32 $NO_ENDING = 0;
  33 $Tests_Are_Passing = 1;
  34
  35 # Use this instead of print to avoid interference while testing globals.
  36 sub _print {
  37     local($\, $", $,) = (undef, ' ', '');
  38     print STDOUT @_;
  39 }
  40
  41 sub _print_stderr {
  42     local($\, $", $,) = (undef, ' ', '');
  43     print STDERR @_;
  44 }
  45
  46 sub plan {
  47     my $n;
  48     if (@_ == 1) {
  49         $n = shift;
  50         if ($n eq 'no_plan') {
  51           undef $n;
  52           $noplan = 1;
  53         }
  54     } else {
  55         my %plan = @_;
  56         $n = $plan{tests};
  57     }
  58     _print "1..$n\n" unless $noplan;
  59     $planned = $n;
  60 }
  61
  62
  63 # Set the plan at the end.  See Test::More::done_testing.
  64 sub done_testing {
  65     my $n = $test - 1;
  66     $n = shift if @_;
  67
  68     _print "1..$n\n";
  69     $planned = $n;
  70 }
  71
  72
  73 END {
  74     my $ran = $test - 1;
  75     if (!$NO_ENDING) {
  76         if (defined $planned && $planned != $ran) {
  77             _print_stderr
  78                 "# Looks like you planned $planned tests but ran $ran.\n";
  79         } elsif ($noplan) {
  80             _print "1..$ran\n";
  81         }
  82     }
  83 }
  84
  85 sub _diag {
  86     return unless @_;
  87     my @mess = _comment(@_);
  88     $TODO ? _print(@mess) : _print_stderr(@mess);
  89 }
  90
  91 # Use this instead of "print STDERR" when outputting failure diagnostic
  92 # messages
  93 sub diag {
  94     _diag(@_);
  95 }
  96
  97 # Use this instead of "print" when outputting informational messages
  98 sub note {
  99     return unless @_;
 100     _print( _comment(@_) );
 101 }
 102
 103 sub is_miniperl {
 104     return !defined &DynaLoader::boot_DynaLoader;
 105 }
 106
 107 sub _comment {
 108     return map { /^#/ ? "$_\n" : "# $_\n" }
 109            map { split /\n/ } @_;
 110 }
 111
 112 sub _have_dynamic_extension {
 113     my $extension = shift;
 114     unless (eval {require Config; 1}) {
 115         warn "test.pl had problems loading Config: $@";
 116         return 1;
 117     }
 118     $extension =~ s!::!/!g;
 119     return 1 if ($Config::Config{extensions} =~ /\b$extension\b/);
 120 }
 121
 122 sub skip_all {
 123     if (@_) {
 124         _print "1..0 # Skip @_\n";
 125     } else {
 126         _print "1..0\n";
 127     }
 128     exit(0);
 129 }
 130
 131 sub skip_all_if_miniperl {
 132     skip_all(@_) if is_miniperl();
 133 }
 134
 135 sub skip_all_without_dynamic_extension {
 136     my ($extension) = @_;
 137     skip_all("no dynamic loading on miniperl, no $extension") if is_miniperl();
 138     return if &_have_dynamic_extension;
 139     skip_all("$extension was not built");
 140 }
 141
 142 sub skip_all_without_perlio {
 143     skip_all('no PerlIO') unless PerlIO::Layer->find('perlio');
 144 }
 145
 146 sub skip_all_without_config {
 147     unless (eval {require Config; 1}) {
 148         warn "test.pl had problems loading Config: $@";
 149         return;
 150     }
 151     foreach (@_) {
 152         next if $Config::Config{$_};
 153         my $key = $_; # Need to copy, before trying to modify.
 154         $key =~ s/^use//;
 155         $key =~ s/^d_//;
 156         skip_all("no $key");
 157     }
 158 }
 159
 160 sub find_git_or_skip {
 161     my ($source_dir, $reason);
 162     if (-d '.git') {
 163         $source_dir = '.';
 164     } elsif (-l 'MANIFEST' && -l 'AUTHORS') {
 165         my $where = readlink 'MANIFEST';
 166         die "Can't readling MANIFEST: $!" unless defined $where;
 167         die "Confusing symlink target for MANIFEST, '$where'"
 168             unless $where =~ s!/MANIFEST\z!!;
 169         if (-d "$where/.git") {
 170             # Looks like we are in a symlink tree
 171             if (exists $ENV{GIT_DIR}) {
 172                 diag("Found source tree at $where, but \$ENV{GIT_DIR} is $ENV{GIT_DIR}. Not changing it");
 173             } else {
 174                 note("Found source tree at $where, setting \$ENV{GIT_DIR}");
 175                 $ENV{GIT_DIR} = "$where/.git";
 176             }
 177             $source_dir = $where;
 178         }
 179     }
 180     if ($source_dir) {
 181         my $version_string = `git --version`;
 182         if (defined $version_string
 183               && $version_string =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
 184             return $source_dir if eval "v$1 ge v1.5.0";
 185             # If you have earlier than 1.5.0 and it works, change this test
 186             $reason = "in git checkout, but git version '$1$2' too old";
 187         } else {
 188             $reason = "in git checkout, but cannot run git";
 189         }
 190     } else {
 191         $reason = 'not being run from a git checkout';
 192     }
 193     skip_all($reason) if $_[0] && $_[0] eq 'all';
 194     skip($reason, @_);
 195 }
 196
 197 sub BAIL_OUT {
 198     my ($reason) = @_;
 199     _print("Bail out!  $reason\n");
 200     exit 255;
 201 }
 202
 203 sub _ok {
 204     my ($pass, $where, $name, @mess) = @_;
 205     # Do not try to microoptimize by factoring out the "not ".
 206     # VMS will avenge.
 207     my $out;
 208     if ($name) {
 209         # escape out '#' or it will interfere with '# skip' and such
 210         $name =~ s/#/\\#/g;
 211         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
 212     } else {
 213         $out = $pass ? "ok $test" : "not ok $test";
 214     }
 215
 216     if ($TODO) {
 217         $out = $out . " # TODO $TODO";
 218     } else {
 219         $Tests_Are_Passing = 0 unless $pass;
 220     }
 221
 222     _print "$out\n";
 223
 224     if ($pass) {
 225         note @mess; # Ensure that the message is properly escaped.
 226     }
 227     else {
 228         my $msg = "# Failed test $test - ";
 229         $msg.= "$name " if $name;
 230         $msg .= "$where\n";
 231         _diag $msg;
 232         _diag @mess;
 233     }
 234
 235     $test = $test + 1; # don't use ++
 236
 237     return $pass;
 238 }
 239
 240 sub _where {
 241     my @caller = caller($Level);
 242     return "at $caller[1] line $caller[2]";
 243 }
 244
 245 # DON'T use this for matches. Use like() instead.
 246 sub ok ($@) {
 247     my ($pass, $name, @mess) = @_;
 248     _ok($pass, _where(), $name, @mess);
 249 }
 250
 251 sub _q {
 252     my $x = shift;
 253     return 'undef' unless defined $x;
 254     my $q = $x;
 255     $q =~ s/\\/\\\\/g;
 256     $q =~ s/'/\\'/g;
 257     return "'$q'";
 258 }
 259
 260 sub _qq {
 261     my $x = shift;
 262     return defined $x ? '"' . display ($x) . '"' : 'undef';
 263 };
 264
 265 # keys are the codes \n etc map to, values are 2 char strings such as \n
 266 my %backslash_escape;
 267 foreach my $x (split //, 'nrtfa\\\'"') {
 268     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
 269 }
 270 # A way to display scalars containing control characters and Unicode.
 271 # Trying to avoid setting $_, or relying on local $_ to work.
 272 sub display {
 273     my @result;
 274     foreach my $x (@_) {
 275         if (defined $x and not ref $x) {
 276             my $y = '';
 277             foreach my $c (unpack("U*", $x)) {
 278                 if ($c > 255) {
 279                     $y = $y . sprintf "\\x{%x}", $c;
 280                 } elsif ($backslash_escape{$c}) {
 281                     $y = $y . $backslash_escape{$c};
 282                 } else {
 283                     my $z = chr $c; # Maybe we can get away with a literal...
 284                     if ($z =~ /[[:^print:]]/) {
 285
 286                         # Use octal for characters traditionally expressed as
 287                         # such: the low controls
 288                         if ($c <= 037) {
 289                             $z = sprintf "\\%03o", $c;
 290                         } else {
 291                             $z = sprintf "\\x{%x}", $c;
 292                         }
 293                     }
 294                     $y = $y . $z;
 295                 }
 296             }
 297             $x = $y;
 298         }
 299         return $x unless wantarray;
 300         push @result, $x;
 301     }
 302     return @result;
 303 }
 304
 305 sub is ($$@) {
 306     my ($got, $expected, $name, @mess) = @_;
 307
 308     my $pass;
 309     if( !defined $got || !defined $expected ) {
 310         # undef only matches undef
 311         $pass = !defined $got && !defined $expected;
 312     }
 313     else {
 314         $pass = $got eq $expected;
 315     }
 316
 317     unless ($pass) {
 318         unshift(@mess, "#      got "._qq($got)."\n",
 319                        "# expected "._qq($expected)."\n");
 320     }
 321     _ok($pass, _where(), $name, @mess);
 322 }
 323
 324 sub isnt ($$@) {
 325     my ($got, $isnt, $name, @mess) = @_;
 326
 327     my $pass;
 328     if( !defined $got || !defined $isnt ) {
 329         # undef only matches undef
 330         $pass = defined $got || defined $isnt;
 331     }
 332     else {
 333         $pass = $got ne $isnt;
 334     }
 335
 336     unless( $pass ) {
 337         unshift(@mess, "# it should not be "._qq($got)."\n",
 338                        "# but it is.\n");
 339     }
 340     _ok($pass, _where(), $name, @mess);
 341 }
 342
 343 sub cmp_ok ($$$@) {
 344     my($got, $type, $expected, $name, @mess) = @_;
 345
 346     my $pass;
 347     {
 348         local $^W = 0;
 349         local($@,$!);   # don't interfere with $@
 350                         # eval() sometimes resets $!
 351         $pass = eval "\$got $type \$expected";
 352     }
 353     unless ($pass) {
 354         # It seems Irix long doubles can have 2147483648 and 2147483648
 355         # that stringify to the same thing but are actually numerically
 356         # different. Display the numbers if $type isn't a string operator,
 357         # and the numbers are stringwise the same.
 358         # (all string operators have alphabetic names, so tr/a-z// is true)
 359         # This will also show numbers for some unneeded cases, but will
 360         # definitely be helpful for things such as == and <= that fail
 361         if ($got eq $expected and $type !~ tr/a-z//) {
 362             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 363         }
 364         unshift(@mess, "#      got "._qq($got)."\n",
 365                        "# expected $type "._qq($expected)."\n");
 366     }
 367     _ok($pass, _where(), $name, @mess);
 368 }
 369
 370 # Check that $got is within $range of $expected
 371 # if $range is 0, then check it's exact
 372 # else if $expected is 0, then $range is an absolute value
 373 # otherwise $range is a fractional error.
 374 # Here $range must be numeric, >= 0
 375 # Non numeric ranges might be a useful future extension. (eg %)
 376 sub within ($$$@) {
 377     my ($got, $expected, $range, $name, @mess) = @_;
 378     my $pass;
 379     if (!defined $got or !defined $expected or !defined $range) {
 380         # This is a fail, but doesn't need extra diagnostics
 381     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
 382         # This is a fail
 383         unshift @mess, "# got, expected and range must be numeric\n";
 384     } elsif ($range < 0) {
 385         # This is also a fail
 386         unshift @mess, "# range must not be negative\n";
 387     } elsif ($range == 0) {
 388         # Within 0 is ==
 389         $pass = $got == $expected;
 390     } elsif ($expected == 0) {
 391         # If expected is 0, treat range as absolute
 392         $pass = ($got <= $range) && ($got >= - $range);
 393     } else {
 394         my $diff = $got - $expected;
 395         $pass = abs ($diff / $expected) < $range;
 396     }
 397     unless ($pass) {
 398         if ($got eq $expected) {
 399             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 400         }
 401         unshift@mess, "#      got "._qq($got)."\n",
 402                       "# expected "._qq($expected)." (within "._qq($range).")\n";
 403     }
 404     _ok($pass, _where(), $name, @mess);
 405 }
 406
 407 # Note: this isn't quite as fancy as Test::More::like().
 408
 409 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
 410 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
 411
 412 sub like_yn ($$$@) {
 413     my ($flip, undef, $expected, $name, @mess) = @_;
 414     my $pass;
 415     $pass = $_[1] =~ /$expected/ if !$flip;
 416     $pass = $_[1] !~ /$expected/ if $flip;
 417     unless ($pass) {
 418         unshift(@mess, "#      got '$_[1]'\n",
 419                 $flip
 420                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
 421     }
 422     local $Level = $Level + 1;
 423     _ok($pass, _where(), $name, @mess);
 424 }
 425
 426 sub pass {
 427     _ok(1, '', @_);
 428 }
 429
 430 sub fail {
 431     _ok(0, _where(), @_);
 432 }
 433
 434 sub curr_test {
 435     $test = shift if @_;
 436     return $test;
 437 }
 438
 439 sub next_test {
 440   my $retval = $test;
 441   $test = $test + 1; # don't use ++
 442   $retval;
 443 }
 444
 445 # Note: can't pass multipart messages since we try to
 446 # be compatible with Test::More::skip().
 447 sub skip {
 448     my $why = shift;
 449     my $n    = @_ ? shift : 1;
 450     for (1..$n) {
 451         _print "ok $test # skip $why\n";
 452         $test = $test + 1;
 453     }
 454     local $^W = 0;
 455     last SKIP;
 456 }
 457
 458 sub skip_if_miniperl {
 459     skip(@_) if is_miniperl();
 460 }
 461
 462 sub skip_without_dynamic_extension {
 463     my ($extension) = @_;
 464     skip("no dynamic loading on miniperl, no $extension") if is_miniperl();
 465     return if &_have_dynamic_extension;
 466     skip("$extension was not built");
 467 }
 468
 469 sub todo_skip {
 470     my $why = shift;
 471     my $n   = @_ ? shift : 1;
 472
 473     for (1..$n) {
 474         _print "not ok $test # TODO & SKIP $why\n";
 475         $test = $test + 1;
 476     }
 477     local $^W = 0;
 478     last TODO;
 479 }
 480
 481 sub eq_array {
 482     my ($ra, $rb) = @_;
 483     return 0 unless $#$ra == $#$rb;
 484     for my $i (0..$#$ra) {
 485         next     if !defined $ra->[$i] && !defined $rb->[$i];
 486         return 0 if !defined $ra->[$i];
 487         return 0 if !defined $rb->[$i];
 488         return 0 unless $ra->[$i] eq $rb->[$i];
 489     }
 490     return 1;
 491 }
 492
 493 sub eq_hash {
 494   my ($orig, $suspect) = @_;
 495   my $fail;
 496   while (my ($key, $value) = each %$suspect) {
 497     # Force a hash recompute if this perl's internals can cache the hash key.
 498     $key = "" . $key;
 499     if (exists $orig->{$key}) {
 500       if (
 501         defined $orig->{$key} != defined $value
 502         || (defined $value && $orig->{$key} ne $value)
 503       ) {
 504         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
 505                      " now ", _qq($value), "\n";
 506         $fail = 1;
 507       }
 508     } else {
 509       _print "# key ", _qq($key), " is ", _qq($value),
 510                    ", not in original.\n";
 511       $fail = 1;
 512     }
 513   }
 514   foreach (keys %$orig) {
 515     # Force a hash recompute if this perl's internals can cache the hash key.
 516     $_ = "" . $_;
 517     next if (exists $suspect->{$_});
 518     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
 519     $fail = 1;
 520   }
 521   !$fail;
 522 }
 523
 524 # We only provide a subset of the Test::More functionality.
 525 sub require_ok ($) {
 526     my ($require) = @_;
 527     if ($require =~ tr/[A-Za-z0-9:.]//c) {
 528         fail("Invalid character in \"$require\", passed to require_ok");
 529     } else {
 530         eval <<REQUIRE_OK;
 531 require $require;
 532 REQUIRE_OK
 533         is($@, '', _where(), "require $require");
 534     }
 535 }
 536
 537 sub use_ok ($) {
 538     my ($use) = @_;
 539     if ($use =~ tr/[A-Za-z0-9:.]//c) {
 540         fail("Invalid character in \"$use\", passed to use");
 541     } else {
 542         eval <<USE_OK;
 543 use $use;
 544 USE_OK
 545         is($@, '', _where(), "use $use");
 546     }
 547 }
 548
 549 # runperl - Runs a separate perl interpreter.
 550 # Arguments :
 551 #   switches => [ command-line switches ]
 552 #   nolib    => 1 # don't use -I../lib (included by default)
 553 #   non_portable => Don't warn if a one liner contains quotes
 554 #   prog     => one-liner (avoid quotes)
 555 #   progs    => [ multi-liner (avoid quotes) ]
 556 #   progfile => perl script
 557 #   stdin    => string to feed the stdin (or undef to redirect from /dev/null)
 558 #   stderr   => redirect stderr to stdout
 559 #   args     => [ command-line arguments to the perl program ]
 560 #   verbose  => print the command line
 561
 562 my $is_mswin    = $^O eq 'MSWin32';
 563 my $is_netware  = $^O eq 'NetWare';
 564 my $is_vms      = $^O eq 'VMS';
 565 my $is_cygwin   = $^O eq 'cygwin';
 566
 567 sub _quote_args {
 568     my ($runperl, $args) = @_;
 569
 570     foreach (@$args) {
 571         # In VMS protect with doublequotes because otherwise
 572         # DCL will lowercase -- unless already doublequoted.
 573        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
 574        $runperl = $runperl . ' ' . $_;
 575     }
 576     return $runperl;
 577 }
 578
 579 sub _create_runperl { # Create the string to qx in runperl().
 580     my %args = @_;
 581     my $runperl = which_perl();
 582     if ($runperl =~ m/\s/) {
 583         $runperl = qq{"$runperl"};
 584     }
 585     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
 586     if ($ENV{PERL_RUNPERL_DEBUG}) {
 587         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
 588     }
 589     unless ($args{nolib}) {
 590         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
 591     }
 592     if ($args{switches}) {
 593         local $Level = 2;
 594         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
 595             unless ref $args{switches} eq "ARRAY";
 596         $runperl = _quote_args($runperl, $args{switches});
 597     }
 598     if (defined $args{prog}) {
 599         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
 600             if defined $args{progs};
 601         $args{progs} = [$args{prog}]
 602     }
 603     if (defined $args{progs}) {
 604         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
 605             unless ref $args{progs} eq "ARRAY";
 606         foreach my $prog (@{$args{progs}}) {
 607             if ($prog =~ tr/'"// && !$args{non_portable}) {
 608                 warn "quotes in prog >>$prog<< are not portable";
 609             }
 610             if ($is_mswin || $is_netware || $is_vms) {
 611                 $runperl = $runperl . qq ( -e "$prog" );
 612             }
 613             else {
 614                 $runperl = $runperl . qq ( -e '$prog' );
 615             }
 616         }
 617     } elsif (defined $args{progfile}) {
 618         $runperl = $runperl . qq( "$args{progfile}");
 619     } else {
 620         # You probably didn't want to be sucking in from the upstream stdin
 621         die "test.pl:runperl(): none of prog, progs, progfile, args, "
 622             . " switches or stdin specified"
 623             unless defined $args{args} or defined $args{switches}
 624                 or defined $args{stdin};
 625     }
 626     if (defined $args{stdin}) {
 627         # so we don't try to put literal newlines and crs onto the
 628         # command line.
 629         $args{stdin} =~ s/\n/\\n/g;
 630         $args{stdin} =~ s/\r/\\r/g;
 631
 632         if ($is_mswin || $is_netware || $is_vms) {
 633             $runperl = qq{$Perl -e "print qq(} .
 634                 $args{stdin} . q{)" | } . $runperl;
 635         }
 636         else {
 637             $runperl = qq{$Perl -e 'print qq(} .
 638                 $args{stdin} . q{)' | } . $runperl;
 639         }
 640     } elsif (exists $args{stdin}) {
 641         # Using the pipe construction above can cause fun on systems which use
 642         # ksh as /bin/sh, as ksh does pipes differently (with one less process)
 643         # With sh, for the command line 'perl -e 'print qq()' | perl -e ...'
 644         # the sh process forks two children, which use exec to start the two
 645         # perl processes. The parent shell process persists for the duration of
 646         # the pipeline, and the second perl process starts with no children.
 647         # With ksh (and zsh), the shell saves a process by forking a child for
 648         # just the first perl process, and execing itself to start the second.
 649         # This means that the second perl process starts with one child which
 650         # it didn't create. This causes "fun" when if the tests assume that
 651         # wait (or waitpid) will only return information about processes
 652         # started within the test.
 653         # They also cause fun on VMS, where the pipe implementation returns
 654         # the exit code of the process at the front of the pipeline, not the
 655         # end. This messes up any test using OPTION FATAL.
 656         # Hence it's useful to have a way to make STDIN be at eof without
 657         # needing a pipeline, so that the fork tests have a sane environment
 658         # without these surprises.
 659
 660         # /dev/null appears to be surprisingly portable.
 661         $runperl = $runperl . ($is_mswin ? ' <nul' : ' </dev/null');
 662     }
 663     if (defined $args{args}) {
 664         $runperl = _quote_args($runperl, $args{args});
 665     }
 666     $runperl = $runperl . ' 2>&1' if $args{stderr};
 667     if ($args{verbose}) {
 668         my $runperldisplay = $runperl;
 669         $runperldisplay =~ s/\n/\n\#/g;
 670         _print_stderr "# $runperldisplay\n";
 671     }
 672     return $runperl;
 673 }
 674
 675 sub runperl {
 676     die "test.pl:runperl() does not take a hashref"
 677         if ref $_[0] and ref $_[0] eq 'HASH';
 678     my $runperl = &_create_runperl;
 679     my $result;
 680
 681     my $tainted = ${^TAINT};
 682     my %args = @_;
 683     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
 684
 685     if ($tainted) {
 686         # We will assume that if you're running under -T, you really mean to
 687         # run a fresh perl, so we'll brute force launder everything for you
 688         my $sep;
 689
 690         if (! eval {require Config; 1}) {
 691             warn "test.pl had problems loading Config: $@";
 692             $sep = ':';
 693         } else {
 694             $sep = $Config::Config{path_sep};
 695         }
 696
 697         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
 698         local @ENV{@keys} = ();
 699         # Untaint, plus take out . and empty string:
 700         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
 701         $ENV{PATH} =~ /(.*)/s;
 702         local $ENV{PATH} =
 703             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
 704                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
 705                     split quotemeta ($sep), $1;
 706         if ($is_cygwin) {   # Must have /bin under Cygwin
 707             if (length $ENV{PATH}) {
 708                 $ENV{PATH} = $ENV{PATH} . $sep;
 709             }
 710             $ENV{PATH} = $ENV{PATH} . '/bin';
 711         }
 712         $runperl =~ /(.*)/s;
 713         $runperl = $1;
 714
 715         $result = `$runperl`;
 716     } else {
 717         $result = `$runperl`;
 718     }
 719     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
 720     return $result;
 721 }
 722
 723 # Nice alias
 724 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
 725
 726 sub DIE {
 727     _print_stderr "# @_\n";
 728     exit 1;
 729 }
 730
 731 # A somewhat safer version of the sometimes wrong $^X.
 732 sub which_perl {
 733     unless (defined $Perl) {
 734         $Perl = $^X;
 735
 736         # VMS should have 'perl' aliased properly
 737         return $Perl if $is_vms;
 738
 739         my $exe;
 740         if (! eval {require Config; 1}) {
 741             warn "test.pl had problems loading Config: $@";
 742             $exe = '';
 743         } else {
 744             $exe = $Config::Config{_exe};
 745         }
 746        $exe = '' unless defined $exe;
 747
 748         # This doesn't absolutize the path: beware of future chdirs().
 749         # We could do File::Spec->abs2rel() but that does getcwd()s,
 750         # which is a bit heavyweight to do here.
 751
 752         if ($Perl =~ /^perl\Q$exe\E$/i) {
 753             my $perl = "perl$exe";
 754             if (! eval {require File::Spec; 1}) {
 755                 warn "test.pl had problems loading File::Spec: $@";
 756                 $Perl = "./$perl";
 757             } else {
 758                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
 759             }
 760         }
 761
 762         # Build up the name of the executable file from the name of
 763         # the command.
 764
 765         if ($Perl !~ /\Q$exe\E$/i) {
 766             $Perl = $Perl . $exe;
 767         }
 768
 769         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
 770
 771         # For subcommands to use.
 772         $ENV{PERLEXE} = $Perl;
 773     }
 774     return $Perl;
 775 }
 776
 777 sub unlink_all {
 778     my $count = 0;
 779     foreach my $file (@_) {
 780         1 while unlink $file;
 781         if( -f $file ){
 782             _print_stderr "# Couldn't unlink '$file': $!\n";
 783         }else{
 784             ++$count;
 785         }
 786     }
 787     $count;
 788 }
 789
 790 # _num_to_alpha - Returns a string of letters representing a positive integer.
 791 # Arguments :
 792 #   number to convert
 793 #   maximum number of letters
 794
 795 # returns undef if the number is negative
 796 # returns undef if the number of letters is greater than the maximum wanted
 797
 798 # _num_to_alpha( 0) eq 'A';
 799 # _num_to_alpha( 1) eq 'B';
 800 # _num_to_alpha(25) eq 'Z';
 801 # _num_to_alpha(26) eq 'AA';
 802 # _num_to_alpha(27) eq 'AB';
 803
 804 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
 805
 806 # Avoid ++ -- ranges split negative numbers
 807 sub _num_to_alpha{
 808     my($num,$max_char) = @_;
 809     return unless $num >= 0;
 810     my $alpha = '';
 811     my $char_count = 0;
 812     $max_char = 0 if $max_char < 0;
 813
 814     while( 1 ){
 815         $alpha = $letters[ $num % 26 ] . $alpha;
 816         $num = int( $num / 26 );
 817         last if $num == 0;
 818         $num = $num - 1;
 819
 820         # char limit
 821         next unless $max_char;
 822         $char_count = $char_count + 1;
 823         return if $char_count == $max_char;
 824     }
 825     return $alpha;
 826 }
 827
 828 my %tmpfiles;
 829 END { unlink_all keys %tmpfiles }
 830
 831 # A regexp that matches the tempfile names
 832 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
 833
 834 # Avoid ++, avoid ranges, avoid split //
 835 my $tempfile_count = 0;
 836 sub tempfile {
 837     while(1){
 838         my $try = "tmp$$";
 839         my $alpha = _num_to_alpha($tempfile_count,2);
 840         last unless defined $alpha;
 841         $try = $try . $alpha;
 842         $tempfile_count = $tempfile_count + 1;
 843
 844         # Need to note all the file names we allocated, as a second request may
 845         # come before the first is created.
 846         if (!$tmpfiles{$try} && !-e $try) {
 847             # We have a winner
 848             $tmpfiles{$try} = 1;
 849             return $try;
 850         }
 851     }
 852     die "Can't find temporary file name starting \"tmp$$\"";
 853 }
 854
 855 # This is the temporary file for _fresh_perl
 856 my $tmpfile = tempfile();
 857
 858 sub _fresh_perl {
 859     my($prog, $action, $expect, $runperl_args, $name) = @_;
 860
 861     # Given the choice of the mis-parsable {}
 862     # (we want an anon hash, but a borked lexer might think that it's a block)
 863     # or relying on taking a reference to a lexical
 864     # (\ might be mis-parsed, and the reference counting on the pad may go
 865     #  awry)
 866     # it feels like the least-worse thing is to assume that auto-vivification
 867     # works. At least, this is only going to be a run-time failure, so won't
 868     # affect tests using this file but not this function.
 869     $runperl_args->{progfile} ||= $tmpfile;
 870     $runperl_args->{stderr}     = 1 unless exists $runperl_args->{stderr};
 871
 872     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
 873     print TEST $prog;
 874     close TEST or die "Cannot close $tmpfile: $!";
 875
 876     my $results = runperl(%$runperl_args);
 877     my $status = $?;
 878
 879     # Clean up the results into something a bit more predictable.
 880     $results  =~ s/\n+$//;
 881     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
 882     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
 883
 884     # bison says 'parse error' instead of 'syntax error',
 885     # various yaccs may or may not capitalize 'syntax'.
 886     $results =~ s/^(syntax|parse) error/syntax error/mig;
 887
 888     if ($is_vms) {
 889         # some tests will trigger VMS messages that won't be expected
 890         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
 891
 892         # pipes double these sometimes
 893         $results =~ s/\n\n/\n/g;
 894     }
 895
 896     # Use the first line of the program as a name if none was given
 897     unless( $name ) {
 898         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
 899         $name = $name . '...' if length $first_line > length $name;
 900     }
 901
 902     # Historically this was implemented using a closure, but then that means
 903     # that the tests for closures avoid using this code. Given that there
 904     # are exactly two callers, doing exactly two things, the simpler approach
 905     # feels like a better trade off.
 906     my $pass;
 907     if ($action eq 'eq') {
 908         $pass = is($results, $expect, $name);
 909     } elsif ($action eq '=~') {
 910         $pass = like($results, $expect, $name);
 911     } else {
 912         die "_fresh_perl can't process action '$action'";
 913     }
 914
 915     unless ($pass) {
 916         _diag "# PROG: \n$prog\n";
 917         _diag "# STATUS: $status\n";
 918     }
 919
 920     return $pass;
 921 }
 922
 923 #
 924 # fresh_perl_is
 925 #
 926 # Combination of run_perl() and is().
 927 #
 928
 929 sub fresh_perl_is {
 930     my($prog, $expected, $runperl_args, $name) = @_;
 931
 932     # _fresh_perl() is going to clip the trailing newlines off the result.
 933     # This will make it so the test author doesn't have to know that.
 934     $expected =~ s/\n+$//;
 935
 936     local $Level = 2;
 937     _fresh_perl($prog, 'eq', $expected, $runperl_args, $name);
 938 }
 939
 940 #
 941 # fresh_perl_like
 942 #
 943 # Combination of run_perl() and like().
 944 #
 945
 946 sub fresh_perl_like {
 947     my($prog, $expected, $runperl_args, $name) = @_;
 948     local $Level = 2;
 949     _fresh_perl($prog, '=~', $expected, $runperl_args, $name);
 950 }
 951
 952 # Many tests use the same format in __DATA__ or external files to specify a
 953 # sequence of (fresh) tests to run, extra files they may temporarily need, and
 954 # what the expected output is. So have excatly one copy of the code to run that
 955 #
 956 # Each program is source code to run followed by an "EXPECT" line, followed
 957 # by the expected output.
 958 #
 959 # The code to run may begin with a command line switch such as -w or -0777
 960 # (alphanumerics only), and may contain (note the '# ' on each):
 961 #   # TODO reason for todo
 962 #   # SKIP reason for skip
 963 #   # SKIP ?code to test if this should be skipped
 964 #   # NAME name of the test (as with ok($ok, $name))
 965 #
 966 # The expected output may contain:
 967 #   OPTION list of options
 968 #   OPTIONS list of options
 969 #
 970 # The possible options for OPTION may be:
 971 #   regex - the expected output is a regular expression
 972 #   random - all lines match but in any order
 973 #   fatal - the code will fail fatally (croak, die)
 974 #
 975 # If the actual output contains a line "SKIPPED" the test will be
 976 # skipped.
 977 #
 978 # If the actual output contains a line "PREFIX", any output starting with that
 979 # line will be ignored when comparing with the expected output
 980 #
 981 # If the global variable $FATAL is true then OPTION fatal is the
 982 # default.
 983
 984 sub _setup_one_file {
 985     my $fh = shift;
 986     # Store the filename as a program that started at line 0.
 987     # Real files count lines starting at line 1.
 988     my @these = (0, shift);
 989     my ($lineno, $current);
 990     while (<$fh>) {
 991         if ($_ eq "########\n") {
 992             if (defined $current) {
 993                 push @these, $lineno, $current;
 994             }
 995             undef $current;
 996         } else {
 997             if (!defined $current) {
 998                 $lineno = $.;
 999             }
1000             $current .= $_;
1001         }
1002     }
1003     if (defined $current) {
1004         push @these, $lineno, $current;
1005     }
1006     ((scalar @these) / 2 - 1, @these);
1007 }
1008
1009 sub setup_multiple_progs {
1010     my ($tests, @prgs);
1011     foreach my $file (@_) {
1012         next if $file =~ /(?:~|\.orig|,v)$/;
1013         next if $file =~ /perlio$/ && !PerlIO::Layer->find('perlio');
1014         next if -d $file;
1015
1016         open my $fh, '<', $file or die "Cannot open $file: $!\n" ;
1017         my $found;
1018         while (<$fh>) {
1019             if (/^__END__/) {
1020                 ++$found;
1021                 last;
1022             }
1023         }
1024         # This is an internal error, and should never happen. All bar one of
1025         # the files had an __END__ marker to signal the end of their preamble,
1026         # although for some it wasn't technically necessary as they have no
1027         # tests. It might be possible to process files without an __END__ by
1028         # seeking back to the start and treating the whole file as tests, but
1029         # it's simpler and more reliable just to make the rule that all files
1030         # must have __END__ in. This should never fail - a file without an
1031         # __END__ should not have been checked in, because the regression tests
1032         # would not have passed.
1033         die "Could not find '__END__' in $file"
1034             unless $found;
1035
1036         my ($t, @p) = _setup_one_file($fh, $file);
1037         $tests += $t;
1038         push @prgs, @p;
1039
1040         close $fh
1041             or die "Cannot close $file: $!\n";
1042     }
1043     return ($tests, @prgs);
1044 }
1045
1046 sub run_multiple_progs {
1047     my $up = shift;
1048     my @prgs;
1049     if ($up) {
1050         # The tests in lib run in a temporary subdirectory of t, and always
1051         # pass in a list of "programs" to run
1052         @prgs = @_;
1053     } else {
1054         # The tests below t run in t and pass in a file handle. In theory we
1055         # can pass (caller)[1] as the second argument to report errors with
1056         # the filename of our caller, as the handle is always DATA. However,
1057         # line numbers in DATA count from the __END__ token, so will be wrong.
1058         # Which is more confusing than not providing line numbers. So, for now,
1059         # don't provide line numbers. No obvious clean solution - one hack
1060         # would be to seek DATA back to the start and read to the __END__ token,
1061         # but that feels almost like we should just open $0 instead.
1062
1063         # Not going to rely on undef in list assignment.
1064         my $dummy;
1065         ($dummy, @prgs) = _setup_one_file(shift);
1066     }
1067
1068     my $tmpfile = tempfile();
1069
1070     my ($file, $line);
1071   PROGRAM:
1072     while (defined ($line = shift @prgs)) {
1073         $_ = shift @prgs;
1074         unless ($line) {
1075             $file = $_;
1076             if (defined $file) {
1077                 print "# From $file\n";
1078             }
1079             next;
1080         }
1081         my $switch = "";
1082         my @temps ;
1083         my @temp_path;
1084         if (s/^(\s*-\w+)//) {
1085             $switch = $1;
1086         }
1087         my ($prog, $expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
1088
1089         my %reason;
1090         foreach my $what (qw(skip todo)) {
1091             $prog =~ s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
1092             # If the SKIP reason starts ? then it's taken as a code snippet to
1093             # evaluate. This provides the flexibility to have conditional SKIPs
1094             if ($reason{$what} && $reason{$what} =~ s/^\?//) {
1095                 my $temp = eval $reason{$what};
1096                 if ($@) {
1097                     die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
1098                 }
1099                 $reason{$what} = $temp;
1100             }
1101         }
1102
1103         my $name = '';
1104         if ($prog =~ s/^#\s*NAME\s+(.+)\n//m) {
1105             $name = $1;
1106         }
1107
1108         if ($reason{skip}) {
1109         SKIP:
1110           {
1111             skip($name ? "$name - $reason{skip}" : $reason{skip}, 1);
1112           }
1113           next PROGRAM;
1114         }
1115
1116         if ($prog =~ /--FILE--/) {
1117             my @files = split(/\n?--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
1118             shift @files ;
1119             die "Internal error: test $_ didn't split into pairs, got " .
1120                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
1121                     if @files % 2;
1122             while (@files > 2) {
1123                 my $filename = shift @files;
1124                 my $code = shift @files;
1125                 push @temps, $filename;
1126                 if ($filename =~ m#(.*)/# && $filename !~ m#^\.\./#) {
1127                     require File::Path;
1128                     File::Path::mkpath($1);
1129                     push(@temp_path, $1);
1130                 }
1131                 open my $fh, '>', $filename or die "Cannot open $filename: $!\n";
1132                 print $fh $code;
1133                 close $fh or die "Cannot close $filename: $!\n";
1134             }
1135             shift @files;
1136             $prog = shift @files;
1137         }
1138
1139         open my $fh, '>', $tmpfile or die "Cannot open >$tmpfile: $!";
1140         print $fh q{
1141         BEGIN {
1142             open STDERR, '>&', STDOUT
1143               or die "Can't dup STDOUT->STDERR: $!;";
1144         }
1145         };
1146         print $fh "\n#line 1\n";  # So the line numbers don't get messed up.
1147         print $fh $prog,"\n";
1148         close $fh or die "Cannot close $tmpfile: $!";
1149         my $results = runperl( stderr => 1, progfile => $tmpfile,
1150                                stdin => undef, $up
1151                                ? (switches => ["-I$up/lib", $switch], nolib => 1)
1152                                : (switches => [$switch])
1153                                 );
1154         my $status = $?;
1155         $results =~ s/\n+$//;
1156         # allow expected output to be written as if $prog is on STDIN
1157         $results =~ s/$::tempfile_regexp/-/g;
1158         if ($^O eq 'VMS') {
1159             # some tests will trigger VMS messages that won't be expected
1160             $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
1161
1162             # pipes double these sometimes
1163             $results =~ s/\n\n/\n/g;
1164         }
1165         # bison says 'parse error' instead of 'syntax error',
1166         # various yaccs may or may not capitalize 'syntax'.
1167         $results =~ s/^(syntax|parse) error/syntax error/mig;
1168         # allow all tests to run when there are leaks
1169         $results =~ s/Scalars leaked: \d+\n//g;
1170
1171         $expected =~ s/\n+$//;
1172         my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
1173         # any special options? (OPTIONS foo bar zap)
1174         my $option_regex = 0;
1175         my $option_random = 0;
1176         my $fatal = $FATAL;
1177         if ($expected =~ s/^OPTIONS? (.+)\n//) {
1178             foreach my $option (split(' ', $1)) {
1179                 if ($option eq 'regex') { # allow regular expressions
1180                     $option_regex = 1;
1181                 }
1182                 elsif ($option eq 'random') { # all lines match, but in any order
1183                     $option_random = 1;
1184                 }
1185                 elsif ($option eq 'fatal') { # perl should fail
1186                     $fatal = 1;
1187                 }
1188                 else {
1189                     die "$0: Unknown OPTION '$option'\n";
1190                 }
1191             }
1192         }
1193         die "$0: can't have OPTION regex and random\n"
1194             if $option_regex + $option_random > 1;
1195         my $ok = 0;
1196         if ($results =~ s/^SKIPPED\n//) {
1197             print "$results\n" ;
1198             $ok = 1;
1199         }
1200         else {
1201             if ($option_random) {
1202                 my @got = sort split "\n", $results;
1203                 my @expected = sort split "\n", $expected;
1204
1205                 $ok = "@got" eq "@expected";
1206             }
1207             elsif ($option_regex) {
1208                 $ok = $results =~ /^$expected/;
1209             }
1210             elsif ($prefix) {
1211                 $ok = $results =~ /^\Q$expected/;
1212             }
1213             else {
1214                 $ok = $results eq $expected;
1215             }
1216
1217             if ($ok && $fatal && !($status >> 8)) {
1218                 $ok = 0;
1219             }
1220         }
1221
1222         local $::TODO = $reason{todo};
1223
1224         unless ($ok) {
1225             my $err_line = "PROG: $switch\n$prog\n" .
1226                            "EXPECTED:\n$expected\n";
1227             $err_line   .= "EXIT STATUS: != 0\n" if $fatal;
1228             $err_line   .= "GOT:\n$results\n";
1229             $err_line   .= "EXIT STATUS: " . ($status >> 8) . "\n" if $fatal;
1230             if ($::TODO) {
1231                 $err_line =~ s/^/# /mg;
1232                 print $err_line;  # Harness can't filter it out from STDERR.
1233             }
1234             else {
1235                 print STDERR $err_line;
1236             }
1237         }
1238
1239         if (defined $file) {
1240             _ok($ok, "at $file line $line", $name);
1241         } else {
1242             # We don't have file and line number data for the test, so report
1243             # errors as coming from our caller.
1244             local $Level = $Level + 1;
1245             ok($ok, $name);
1246         }
1247
1248         foreach (@temps) {
1249             unlink $_ if $_;
1250         }
1251         foreach (@temp_path) {
1252             File::Path::rmtree $_ if -d $_;
1253         }
1254     }
1255 }
1256
1257 sub can_ok ($@) {
1258     my($proto, @methods) = @_;
1259     my $class = ref $proto || $proto;
1260
1261     unless( @methods ) {
1262         return _ok( 0, _where(), "$class->can(...)" );
1263     }
1264
1265     my @nok = ();
1266     foreach my $method (@methods) {
1267         local($!, $@);  # don't interfere with caller's $@
1268                         # eval sometimes resets $!
1269         eval { $proto->can($method) } || push @nok, $method;
1270     }
1271
1272     my $name;
1273     $name = @methods == 1 ? "$class->can('$methods[0]')"
1274                           : "$class->can(...)";
1275
1276     _ok( !@nok, _where(), $name );
1277 }
1278
1279
1280 # Call $class->new( @$args ); and run the result through object_ok.
1281 # See Test::More::new_ok
1282 sub new_ok {
1283     my($class, $args, $obj_name) = @_;
1284     $args ||= [];
1285     $object_name = "The object" unless defined $obj_name;
1286
1287     local $Level = $Level + 1;
1288
1289     my $obj;
1290     my $ok = eval { $obj = $class->new(@$args); 1 };
1291     my $error = $@;
1292
1293     if($ok) {
1294         object_ok($obj, $class, $object_name);
1295     }
1296     else {
1297         ok( 0, "new() died" );
1298         diag("Error was:  $@");
1299     }
1300
1301     return $obj;
1302
1303 }
1304
1305
1306 sub isa_ok ($$;$) {
1307     my($object, $class, $obj_name) = @_;
1308
1309     my $diag;
1310     $obj_name = 'The object' unless defined $obj_name;
1311     my $name = "$obj_name isa $class";
1312     if( !defined $object ) {
1313         $diag = "$obj_name isn't defined";
1314     }
1315     else {
1316         my $whatami = ref $object ? 'object' : 'class';
1317
1318         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
1319         local($@, $!);  # eval sometimes resets $!
1320         my $rslt = eval { $object->isa($class) };
1321         my $error = $@;  # in case something else blows away $@
1322
1323         if( $error ) {
1324             if( $error =~ /^Can't call method "isa" on unblessed reference/ ) {
1325                 # It's an unblessed reference
1326                 $obj_name = 'The reference' unless defined $obj_name;
1327                 if( !UNIVERSAL::isa($object, $class) ) {
1328                     my $ref = ref $object;
1329                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
1330                 }
1331             }
1332             elsif( $error =~ /Can't call method "isa" without a package/ ) {
1333                 # It's something that can't even be a class
1334                 $obj_name = 'The thing' unless defined $obj_name;
1335                 $diag = "$obj_name isn't a class or reference";
1336             }
1337             else {
1338                 die <<WHOA;
1339 WHOA! I tried to call ->isa on your object and got some weird error.
1340 This should never happen.  Please contact the author immediately.
1341 Here's the error.
1342 $@
1343 WHOA
1344             }
1345         }
1346         elsif( !$rslt ) {
1347             $obj_name = "The $whatami" unless defined $obj_name;
1348             my $ref = ref $object;
1349             $diag = "$obj_name isn't a '$class' it's a '$ref'";
1350         }
1351     }
1352
1353     _ok( !$diag, _where(), $name );
1354 }
1355
1356
1357 sub class_ok {
1358     my($class, $isa, $class_name) = @_;
1359
1360     # Written so as to count as one test
1361     local $Level = $Level + 1;
1362     if( ref $class ) {
1363         ok( 0, "$class is a refrence, not a class name" );
1364     }
1365     else {
1366         isa_ok($class, $isa, $class_name);
1367     }
1368 }
1369
1370
1371 sub object_ok {
1372     my($obj, $isa, $obj_name) = @_;
1373
1374     local $Level = $Level + 1;
1375     if( !ref $obj ) {
1376         ok( 0, "$obj is not a reference" );
1377     }
1378     else {
1379         isa_ok($obj, $isa, $obj_name);
1380     }
1381 }
1382
1383
1384 # Purposefully avoiding a closure.
1385 sub __capture {
1386     push @::__capture, join "", @_;
1387 }
1388
1389 sub capture_warnings {
1390     my $code = shift;
1391
1392     local @::__capture;
1393     local $SIG {__WARN__} = \&__capture;
1394     &$code;
1395     return @::__capture;
1396 }
1397
1398 # This will generate a variable number of tests.
1399 # Use done_testing() instead of a fixed plan.
1400 sub warnings_like {
1401     my ($code, $expect, $name) = @_;
1402     local $Level = $Level + 1;
1403
1404     my @w = capture_warnings($code);
1405
1406     cmp_ok(scalar @w, '==', scalar @$expect, $name);
1407     foreach my $e (@$expect) {
1408         if (ref $e) {
1409             like(shift @w, $e, $name);
1410         } else {
1411             is(shift @w, $e, $name);
1412         }
1413     }
1414     if (@w) {
1415         diag("Saw these additional warnings:");
1416         diag($_) foreach @w;
1417     }
1418 }
1419
1420 sub _fail_excess_warnings {
1421     my($expect, $got, $name) = @_;
1422     local $Level = $Level + 1;
1423     # This will fail, and produce diagnostics
1424     is($expect, scalar @$got, $name);
1425     diag("Saw these warnings:");
1426     diag($_) foreach @$got;
1427 }
1428
1429 sub warning_is {
1430     my ($code, $expect, $name) = @_;
1431     die sprintf "Expect must be a string or undef, not a %s reference", ref $expect
1432         if ref $expect;
1433     local $Level = $Level + 1;
1434     my @w = capture_warnings($code);
1435     if (@w > 1) {
1436         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1437     } else {
1438         is($w[0], $expect, $name);
1439     }
1440 }
1441
1442 sub warning_like {
1443     my ($code, $expect, $name) = @_;
1444     die sprintf "Expect must be a regexp object"
1445         unless ref $expect eq 'Regexp';
1446     local $Level = $Level + 1;
1447     my @w = capture_warnings($code);
1448     if (@w > 1) {
1449         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1450     } else {
1451         like($w[0], $expect, $name);
1452     }
1453 }
1454
1455 # Set a watchdog to timeout the entire test file
1456 # NOTE:  If the test file uses 'threads', then call the watchdog() function
1457 #        _AFTER_ the 'threads' module is loaded.
1458 sub watchdog ($;$)
1459 {
1460     my $timeout = shift;
1461     my $method  = shift || "";
1462     my $timeout_msg = 'Test process timed out - terminating';
1463
1464     # Valgrind slows perl way down so give it more time before dying.
1465     $timeout *= 10 if $ENV{PERL_VALGRIND};
1466
1467     my $pid_to_kill = $$;   # PID for this process
1468
1469     if ($method eq "alarm") {
1470         goto WATCHDOG_VIA_ALARM;
1471     }
1472
1473     # shut up use only once warning
1474     my $threads_on = $threads::threads && $threads::threads;
1475
1476     # Don't use a watchdog process if 'threads' is loaded -
1477     #   use a watchdog thread instead
1478     if (!$threads_on || $method eq "process") {
1479
1480         # On Windows and VMS, try launching a watchdog process
1481         #   using system(1, ...) (see perlport.pod)
1482         if ($is_mswin || $is_vms) {
1483             # On Windows, try to get the 'real' PID
1484             if ($is_mswin) {
1485                 eval { require Win32; };
1486                 if (defined(&Win32::GetCurrentProcessId)) {
1487                     $pid_to_kill = Win32::GetCurrentProcessId();
1488                 }
1489             }
1490
1491             # If we still have a fake PID, we can't use this method at all
1492             return if ($pid_to_kill <= 0);
1493
1494             # Launch watchdog process
1495             my $watchdog;
1496             eval {
1497                 local $SIG{'__WARN__'} = sub {
1498                     _diag("Watchdog warning: $_[0]");
1499                 };
1500                 my $sig = $is_vms ? 'TERM' : 'KILL';
1501                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
1502                                                     "warn qq/# $timeout_msg" . '\n/;' .
1503                                                     "kill($sig, $pid_to_kill);");
1504                 $watchdog = system(1, $cmd);
1505             };
1506             if ($@ || ($watchdog <= 0)) {
1507                 _diag('Failed to start watchdog');
1508                 _diag($@) if $@;
1509                 undef($watchdog);
1510                 return;
1511             }
1512
1513             # Add END block to parent to terminate and
1514             #   clean up watchdog process
1515             eval "END { local \$! = 0; local \$? = 0;
1516                         wait() if kill('KILL', $watchdog); };";
1517             return;
1518         }
1519
1520         # Try using fork() to generate a watchdog process
1521         my $watchdog;
1522         eval { $watchdog = fork() };
1523         if (defined($watchdog)) {
1524             if ($watchdog) {   # Parent process
1525                 # Add END block to parent to terminate and
1526                 #   clean up watchdog process
1527                 eval "END { local \$! = 0; local \$? = 0;
1528                             wait() if kill('KILL', $watchdog); };";
1529                 return;
1530             }
1531
1532             ### Watchdog process code
1533
1534             # Load POSIX if available
1535             eval { require POSIX; };
1536
1537             # Execute the timeout
1538             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
1539             sleep(2);
1540
1541             # Kill test process if still running
1542             if (kill(0, $pid_to_kill)) {
1543                 _diag($timeout_msg);
1544                 kill('KILL', $pid_to_kill);
1545                 if ($is_cygwin) {
1546                     # sometimes the above isn't enough on cygwin
1547                     sleep 1; # wait a little, it might have worked after all
1548                     system("/bin/kill -f $pid_to_kill");
1549                 }
1550             }
1551
1552             # Don't execute END block (added at beginning of this file)
1553             $NO_ENDING = 1;
1554
1555             # Terminate ourself (i.e., the watchdog)
1556             POSIX::_exit(1) if (defined(&POSIX::_exit));
1557             exit(1);
1558         }
1559
1560         # fork() failed - fall through and try using a thread
1561     }
1562
1563     # Use a watchdog thread because either 'threads' is loaded,
1564     #   or fork() failed
1565     if (eval {require threads; 1}) {
1566         'threads'->create(sub {
1567                 # Load POSIX if available
1568                 eval { require POSIX; };
1569
1570                 # Execute the timeout
1571                 my $time_left = $timeout;
1572                 do {
1573                     $time_left = $time_left - sleep($time_left);
1574                 } while ($time_left > 0);
1575
1576                 # Kill the parent (and ourself)
1577                 select(STDERR); $| = 1;
1578                 _diag($timeout_msg);
1579                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1580                 my $sig = $is_vms ? 'TERM' : 'KILL';
1581                 kill($sig, $pid_to_kill);
1582             })->detach();
1583         return;
1584     }
1585
1586     # If everything above fails, then just use an alarm timeout
1587 WATCHDOG_VIA_ALARM:
1588     if (eval { alarm($timeout); 1; }) {
1589         # Load POSIX if available
1590         eval { require POSIX; };
1591
1592         # Alarm handler will do the actual 'killing'
1593         $SIG{'ALRM'} = sub {
1594             select(STDERR); $| = 1;
1595             _diag($timeout_msg);
1596             POSIX::_exit(1) if (defined(&POSIX::_exit));
1597             my $sig = $is_vms ? 'TERM' : 'KILL';
1598             kill($sig, $pid_to_kill);
1599         };
1600     }
1601 }
1602
1603 my $cp_0037 =   # EBCDIC code page 0037
1604     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x25\x0B\x0C\x0D\x0E\x0F' .
1605     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1606     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1607     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1608     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1609     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBA\xE0\xBB\xB0\x6D' .
1610     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1611     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1612     '\x20\x21\x22\x23\x24\x15\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1613     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1614     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBD\xB4\x9A\x8A\x5F\xCA\xAF\xBC' .
1615     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1616     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1617     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xAD\xAE\x59' .
1618     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1619     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1620
1621 my $cp_1047 =   # EBCDIC code page 1047
1622     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1623     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1624     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1625     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1626     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1627     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xAD\xE0\xBD\x5F\x6D' .
1628     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1629     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1630     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1631     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1632     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBB\xB4\x9A\x8A\xB0\xCA\xAF\xBC' .
1633     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1634     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1635     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xBA\xAE\x59' .
1636     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1637     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1638
1639 my $cp_bc = # EBCDIC code page POSiX-BC
1640     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1641     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1642     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1643     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1644     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1645     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBB\xBC\xBD\x6A\x6D' .
1646     '\x4A\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1647     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xFB\x4F\xFD\xFF\x07' .
1648     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1649     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\x5F' .
1650     '\x41\xAA\xB0\xB1\x9F\xB2\xD0\xB5\x79\xB4\x9A\x8A\xBA\xCA\xAF\xA1' .
1651     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1652     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1653     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xE0\xFE\xDD\xFC\xAD\xAE\x59' .
1654     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1655     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xC0\xDE\xDB\xDC\x8D\x8E\xDF';
1656
1657 my $straight =  # Avoid ranges
1658     '\x00\x01\x02\x03\x04\x05\x06\x07\x08\x09\x0A\x0B\x0C\x0D\x0E\x0F' .
1659     '\x10\x11\x12\x13\x14\x15\x16\x17\x18\x19\x1A\x1B\x1C\x1D\x1E\x1F' .
1660     '\x20\x21\x22\x23\x24\x25\x26\x27\x28\x29\x2A\x2B\x2C\x2D\x2E\x2F' .
1661     '\x30\x31\x32\x33\x34\x35\x36\x37\x38\x39\x3A\x3B\x3C\x3D\x3E\x3F' .
1662     '\x40\x41\x42\x43\x44\x45\x46\x47\x48\x49\x4A\x4B\x4C\x4D\x4E\x4F' .
1663     '\x50\x51\x52\x53\x54\x55\x56\x57\x58\x59\x5A\x5B\x5C\x5D\x5E\x5F' .
1664     '\x60\x61\x62\x63\x64\x65\x66\x67\x68\x69\x6A\x6B\x6C\x6D\x6E\x6F' .
1665     '\x70\x71\x72\x73\x74\x75\x76\x77\x78\x79\x7A\x7B\x7C\x7D\x7E\x7F' .
1666     '\x80\x81\x82\x83\x84\x85\x86\x87\x88\x89\x8A\x8B\x8C\x8D\x8E\x8F' .
1667     '\x90\x91\x92\x93\x94\x95\x96\x97\x98\x99\x9A\x9B\x9C\x9D\x9E\x9F' .
1668     '\xA0\xA1\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xAA\xAB\xAC\xAD\xAE\xAF' .
1669     '\xB0\xB1\xB2\xB3\xB4\xB5\xB6\xB7\xB8\xB9\xBA\xBB\xBC\xBD\xBE\xBF' .
1670     '\xC0\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xCA\xCB\xCC\xCD\xCE\xCF' .
1671     '\xD0\xD1\xD2\xD3\xD4\xD5\xD6\xD7\xD8\xD9\xDA\xDB\xDC\xDD\xDE\xDF' .
1672     '\xE0\xE1\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xEA\xEB\xEC\xED\xEE\xEF' .
1673     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\xFA\xFB\xFC\xFD\xFE\xFF';
1674
1675 # The following 2 functions allow tests to work on both EBCDIC and
1676 # ASCII-ish platforms.  They convert string scalars between the native
1677 # character set and the set of 256 characters which is usually called
1678 # Latin1.
1679 #
1680 # These routines don't work on UTF-EBCDIC and UTF-8.
1681
1682 sub native_to_latin1($) {
1683     my $string = shift;
1684
1685     return $string if ord('^') == 94;   # ASCII, Latin1
1686     my $cp;
1687     if (ord('^') == 95) {    # EBCDIC 1047
1688         $cp = \$cp_1047;
1689     }
1690     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1691         $cp = \$cp_bc;
1692     }
1693     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1694         $cp = \$cp_0037;
1695     }
1696     else {
1697         die "Unknown native character set";
1698     }
1699
1700     eval '$string =~ tr/' . $$cp . '/' . $straight . '/';
1701     return $string;
1702 }
1703
1704 sub latin1_to_native($) {
1705     my $string = shift;
1706
1707     return $string if ord('^') == 94;   # ASCII, Latin1
1708     my $cp;
1709     if (ord('^') == 95) {    # EBCDIC 1047
1710         $cp = \$cp_1047;
1711     }
1712     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1713         $cp = \$cp_bc;
1714     }
1715     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1716         $cp = \$cp_0037;
1717     }
1718     else {
1719         die "Unknown native character set";
1720     }
1721
1722     eval '$string =~ tr/' . $straight . '/' . $$cp . '/';
1723     return $string;
1724 }
1725
1726 sub ord_latin1_to_native {
1727     # given an input code point, return the platform's native
1728     # equivalent value.  Anything above latin1 is itself.
1729
1730     my $ord = shift;
1731     return $ord if $ord > 255;
1732     return ord latin1_to_native(chr $ord);
1733 }
1734
1735 sub ord_native_to_latin1 {
1736     # given an input platform code point, return the latin1 equivalent value.
1737     # Anything above latin1 is itself.
1738
1739     my $ord = shift;
1740     return $ord if $ord > 255;
1741     return ord native_to_latin1(chr $ord);
1742 }
1743
1744 1;