This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Certain variables are not longer allowed; document this.
[perl5.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8 X<variable, name> X<variable name> X<data type> X<type>
9
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes".  A scalar is a 
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>).  Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0.  Hashes are unordered collections of scalar 
16 values indexed by their associated string key.
17
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers.  The rest of the name tells you the particular
21 value to which it refers.  Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits.  In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details).  For a more in-depth discussion
28 on identifiers, see L</Identifier parsing>.  It's possible to
29 substitute for a simple identifier, an expression that produces a reference
30 to the value at runtime.   This is described in more detail below
31 and in L<perlref>.
32 X<identifier>
33
34 Perl also has its own built-in variables whose names don't follow
35 these rules.  They have strange names so they don't accidentally
36 collide with one of your normal variables.  Strings that match
37 parenthesized parts of a regular expression are saved under names
38 containing only digits after the C<$> (see L<perlop> and L<perlre>).
39 In addition, several special variables that provide windows into
40 the inner working of Perl have names containing punctuation characters.
41 These are documented in L<perlvar>.
42 X<variable, built-in>
43
44 Scalar values are always named with '$', even when referring to a
45 scalar that is part of an array or a hash.  The '$' symbol works
46 semantically like the English word "the" in that it indicates a
47 single value is expected.
48 X<scalar>
49
50     $days               # the simple scalar value "days"
51     $days[28]           # the 29th element of array @days
52     $days{'Feb'}        # the 'Feb' value from hash %days
53     $#days              # the last index of array @days
54
55 Entire arrays (and slices of arrays and hashes) are denoted by '@',
56 which works much as the word "these" or "those" does in English,
57 in that it indicates multiple values are expected.
58 X<array>
59
60     @days               # ($days[0], $days[1],... $days[n])
61     @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
62     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
63
64 Entire hashes are denoted by '%':
65 X<hash>
66
67     %days               # (key1, val1, key2, val2 ...)
68
69 In addition, subroutines are named with an initial '&', though this
70 is optional when unambiguous, just as the word "do" is often redundant
71 in English.  Symbol table entries can be named with an initial '*',
72 but you don't really care about that yet (if ever :-).
73
74 Every variable type has its own namespace, as do several
75 non-variable identifiers.  This means that you can, without fear
76 of conflict, use the same name for a scalar variable, an array, or
77 a hash--or, for that matter, for a filehandle, a directory handle, a
78 subroutine name, a format name, or a label.  This means that $foo
79 and @foo are two different variables.  It also means that C<$foo[1]>
80 is a part of @foo, not a part of $foo.  This may seem a bit weird,
81 but that's okay, because it is weird.
82 X<namespace>
83
84 Because variable references always start with '$', '@', or '%', the
85 "reserved" words aren't in fact reserved with respect to variable
86 names.  They I<are> reserved with respect to labels and filehandles,
87 however, which don't have an initial special character.  You can't
88 have a filehandle named "log", for instance.  Hint: you could say
89 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using
90 uppercase filehandles also improves readability and protects you
91 from conflict with future reserved words.  Case I<is> significant--"FOO",
92 "Foo", and "foo" are all different names.  Names that start with a
93 letter or underscore may also contain digits and underscores.
94 X<identifier, case sensitivity>
95 X<case>
96
97 It is possible to replace such an alphanumeric name with an expression
98 that returns a reference to the appropriate type.  For a description
99 of this, see L<perlref>.
100
101 Names that start with a digit may contain only more digits.  Names
102 that do not start with a letter, underscore, digit or a caret are
103 limited to one character, e.g.,  C<$%> or
104 C<$$>.  (Most of these one character names have a predefined
105 significance to Perl.  For instance, C<$$> is the current process
106 id.  And all such names are reserved for Perl's possible use.)
107
108 =head2 Identifier parsing
109 X<identifiers>
110
111 Up until Perl 5.18, the actual rules of what a valid identifier
112 was were a bit fuzzy.  However, in general, anything defined here should
113 work on previous versions of Perl, while the opposite -- edge cases
114 that work in previous versions, but aren't defined here -- probably
115 won't work on newer versions.
116 As an important side note, please note that the following only applies
117 to bareword identifiers as found in Perl source code, not identifiers
118 introduced through symbolic references, which have much fewer
119 restrictions.
120 If working under the effect of the C<use utf8;> pragma, the following
121 rules apply:
122
123     / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ])
124       (?[ ( \p{Word} & \p{XID_Continue} ) ]) *    /x
125
126 That is, a "start" character followed by any number of "continue"
127 characters.  Perl requires every character in an identifier to also
128 match C<\w> (this prevents some problematic cases); and Perl
129 additionally accepts identfier names beginning with an underscore.
130
131 If not under C<use utf8>, the source is treated as ASCII + 128 extra
132 generic characters, and identifiers should match
133
134     / (?aa) (?!\d) \w+ /x
135
136 That is, any word character in the ASCII range, as long as the first
137 character is not a digit.
138
139 There are two package separators in Perl: A double colon (C<::>) and a single
140 quote (C<'>).  Normal identifiers can start or end with a double colon, and
141 can contain several parts delimited by double colons.
142 Single quotes have similar rules, but with the exception that they are not
143 legal at the end of an identifier: That is, C<$'foo> and C<$foo'bar> are
144 legal, but C<$foo'bar'> is not.
145
146 Additionally, if the identifier is preceded by a sigil --
147 that is, if the identifier is part of a variable name -- it
148 may optionally be enclosed in braces.
149
150 While you can mix double colons with singles quotes, the quotes must come
151 after the colons: C<$::::'foo> and C<$foo::'bar> are legal, but C<$::'::foo>
152 and C<$foo'::bar> are not.
153
154 Put together, a grammar to match a basic identifier becomes
155
156  /
157   (?(DEFINE)
158       (?<variable>
159           (?&sigil)
160           (?:
161                   (?&normal_identifier)
162               |   \{ \s* (?&normal_identifier) \s* \}
163           )
164       )
165       (?<normal_identifier>
166           (?: :: )* '?
167            (?&basic_identifier)
168            (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )?
169           (?: :: )*
170       )
171       (?<basic_identifier>
172         # is use utf8 on?
173           (?(?{ (caller(0))[8] & $utf8::hint_bits })
174               (?&Perl_XIDS) (?&Perl_XIDC)*
175             | (?aa) (?!\d) \w+
176           )
177       )
178       (?<sigil> [&*\$\@\%])
179       (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) )
180       (?<Perl_XIDC> (?[ \p{Word} & \p{XID_Continue} ]) )
181   )
182  /x
183
184 Meanwhile, special identifiers don't follow the above rules; For the most
185 part, all of the identifiers in this category have a special meaning given
186 by Perl.  Because they have special parsing rules, these generally can't be
187 fully-qualified.  They come in six forms (but don't use forms 5 and 6):
188
189 =over
190
191 =item 1.
192
193 A sigil, followed solely by digits matching C<\p{POSIX_Digit}>, like
194 C<$0>, C<$1>, or C<$10000>.
195
196 =item 2.
197
198 A sigil followed by a single character matching the C<\p{POSIX_Punct}>
199 property, like C<$!> or C<%+>, except the character C<"{"> doesn't work.
200
201 =item 3.
202
203 A sigil, followed by a caret and any one of the characters
204 C<[][A-Z^_?\]>, like C<$^V> or C<$^]>.
205
206 =item 4.
207
208 Similar to the above, a sigil, followed by bareword text in braces,
209 where the first character is a caret.  The next character is any one of
210 the characters C<[][A-Z^_?\]>, followed by ASCII word characters.  An
211 example is C<${^GLOBAL_PHASE}>.
212
213 =item 5.
214
215 A sigil, followed by any single character in the range C<[\xA1-\xAC\xAE-\xFF]>
216 when not under C<S<"use utf8">>.  (Under C<S<"use utf8">>, the normal
217 identifier rules given earlier in this section apply.)  Use of
218 non-graphic characters (the C1 controls, the NO-BREAK SPACE, and the
219 SOFT HYPHEN) has been disallowed since v5.26.0.
220 The use of the other characters is unwise, as these are all
221 reserved to have special meaning to Perl, and none of them currently
222 do have special meaning, though this could change without notice.
223
224 Note that an implication of this form is that there are identifiers only
225 legal under C<S<"use utf8">>, and vice-versa, for example the identifier
226 C<$E<233>tat> is legal under C<S<"use utf8">>, but is otherwise
227 considered to be the single character variable C<$E<233>> followed by
228 the bareword C<"tat">, the combination of which is a syntax error.
229
230 =item 6.
231
232 This is a combination of the previous two forms.  It is valid only when
233 not under S<C<"use utf8">> (normal identifier rules apply when under
234 S<C<"use utf8">>).  The form is a sigil, followed by text in braces,
235 where the first character is any one of the characters in the range
236 C<[\x80-\xFF]> followed by ASCII word characters up to the trailing
237 brace.
238
239 The same caveats as the previous form apply:  The non-graphic
240 characters are no longer allowed with S<"use utf8">, it is unwise
241 to use this form at all, and utf8ness makes a big difference.
242
243 =back
244
245 Prior to Perl v5.24, non-graphical ASCII control characters were also
246 allowed in some situations; this had been deprecated since v5.20.
247
248 =head2 Context
249 X<context> X<scalar context> X<list context>
250
251 The interpretation of operations and values in Perl sometimes depends
252 on the requirements of the context around the operation or value.
253 There are two major contexts: list and scalar.  Certain operations
254 return list values in contexts wanting a list, and scalar values
255 otherwise.  If this is true of an operation it will be mentioned in
256 the documentation for that operation.  In other words, Perl overloads
257 certain operations based on whether the expected return value is
258 singular or plural.  Some words in English work this way, like "fish"
259 and "sheep".
260
261 In a reciprocal fashion, an operation provides either a scalar or a
262 list context to each of its arguments.  For example, if you say
263
264     int( <STDIN> )
265
266 the integer operation provides scalar context for the <>
267 operator, which responds by reading one line from STDIN and passing it
268 back to the integer operation, which will then find the integer value
269 of that line and return that.  If, on the other hand, you say
270
271     sort( <STDIN> )
272
273 then the sort operation provides list context for <>, which
274 will proceed to read every line available up to the end of file, and
275 pass that list of lines back to the sort routine, which will then
276 sort those lines and return them as a list to whatever the context
277 of the sort was.
278
279 Assignment is a little bit special in that it uses its left argument
280 to determine the context for the right argument.  Assignment to a
281 scalar evaluates the right-hand side in scalar context, while
282 assignment to an array or hash evaluates the righthand side in list
283 context.  Assignment to a list (or slice, which is just a list
284 anyway) also evaluates the right-hand side in list context.
285
286 When you use the C<use warnings> pragma or Perl's B<-w> command-line 
287 option, you may see warnings
288 about useless uses of constants or functions in "void context".
289 Void context just means the value has been discarded, such as a
290 statement containing only C<"fred";> or C<getpwuid(0);>.  It still
291 counts as scalar context for functions that care whether or not
292 they're being called in list context.
293
294 User-defined subroutines may choose to care whether they are being
295 called in a void, scalar, or list context.  Most subroutines do not
296 need to bother, though.  That's because both scalars and lists are
297 automatically interpolated into lists.  See L<perlfunc/wantarray>
298 for how you would dynamically discern your function's calling
299 context.
300
301 =head2 Scalar values
302 X<scalar> X<number> X<string> X<reference>
303
304 All data in Perl is a scalar, an array of scalars, or a hash of
305 scalars.  A scalar may contain one single value in any of three
306 different flavors: a number, a string, or a reference.  In general,
307 conversion from one form to another is transparent.  Although a
308 scalar may not directly hold multiple values, it may contain a
309 reference to an array or hash which in turn contains multiple values.
310
311 Scalars aren't necessarily one thing or another.  There's no place
312 to declare a scalar variable to be of type "string", type "number",
313 type "reference", or anything else.  Because of the automatic
314 conversion of scalars, operations that return scalars don't need
315 to care (and in fact, cannot care) whether their caller is looking
316 for a string, a number, or a reference.  Perl is a contextually
317 polymorphic language whose scalars can be strings, numbers, or
318 references (which includes objects).  Although strings and numbers
319 are considered pretty much the same thing for nearly all purposes,
320 references are strongly-typed, uncastable pointers with builtin
321 reference-counting and destructor invocation.
322
323 A scalar value is interpreted as FALSE in the Boolean sense
324 if it is undefined, the null string or the number 0 (or its
325 string equivalent, "0"), and TRUE if it is anything else.  The
326 Boolean context is just a special kind of scalar context where no 
327 conversion to a string or a number is ever performed.
328 X<boolean> X<bool> X<true> X<false> X<truth>
329
330 There are actually two varieties of null strings (sometimes referred
331 to as "empty" strings), a defined one and an undefined one.  The
332 defined version is just a string of length zero, such as C<"">.
333 The undefined version is the value that indicates that there is
334 no real value for something, such as when there was an error, or
335 at end of file, or when you refer to an uninitialized variable or
336 element of an array or hash.  Although in early versions of Perl,
337 an undefined scalar could become defined when first used in a
338 place expecting a defined value, this no longer happens except for
339 rare cases of autovivification as explained in L<perlref>.  You can
340 use the defined() operator to determine whether a scalar value is
341 defined (this has no meaning on arrays or hashes), and the undef()
342 operator to produce an undefined value.
343 X<defined> X<undefined> X<undef> X<null> X<string, null>
344
345 To find out whether a given string is a valid non-zero number, it's
346 sometimes enough to test it against both numeric 0 and also lexical
347 "0" (although this will cause noises if warnings are on).  That's 
348 because strings that aren't numbers count as 0, just as they do in B<awk>:
349
350     if ($str == 0 && $str ne "0")  {
351         warn "That doesn't look like a number";
352     }
353
354 That method may be best because otherwise you won't treat IEEE
355 notations like C<NaN> or C<Infinity> properly.  At other times, you
356 might prefer to determine whether string data can be used numerically
357 by calling the POSIX::strtod() function or by inspecting your string
358 with a regular expression (as documented in L<perlre>).
359
360     warn "has nondigits"        if     /\D/;
361     warn "not a natural number" unless /^\d+$/;             # rejects -3
362     warn "not an integer"       unless /^-?\d+$/;           # rejects +3
363     warn "not an integer"       unless /^[+-]?\d+$/;
364     warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
365     warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
366     warn "not a C float"
367         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
368
369 The length of an array is a scalar value.  You may find the length
370 of array @days by evaluating C<$#days>, as in B<csh>.  However, this
371 isn't the length of the array; it's the subscript of the last element,
372 which is a different value since there is ordinarily a 0th element.
373 Assigning to C<$#days> actually changes the length of the array.
374 Shortening an array this way destroys intervening values.  Lengthening
375 an array that was previously shortened does not recover values
376 that were in those elements.
377 X<$#> X<array, length>
378
379 You can also gain some minuscule measure of efficiency by pre-extending
380 an array that is going to get big.  You can also extend an array
381 by assigning to an element that is off the end of the array.  You
382 can truncate an array down to nothing by assigning the null list
383 () to it.  The following are equivalent:
384
385     @whatever = ();
386     $#whatever = -1;
387
388 If you evaluate an array in scalar context, it returns the length
389 of the array.  (Note that this is not true of lists, which return
390 the last value, like the C comma operator, nor of built-in functions,
391 which return whatever they feel like returning.)  The following is
392 always true:
393 X<array, length>
394
395     scalar(@whatever) == $#whatever + 1;
396
397 Some programmers choose to use an explicit conversion so as to 
398 leave nothing to doubt:
399
400     $element_count = scalar(@whatever);
401
402 If you evaluate a hash in scalar context, it returns false if the
403 hash is empty.  If there are any key/value pairs, it returns true.
404 A more precise definition is version dependent.
405
406 Prior to Perl 5.25 the value returned was a string consisting of the
407 number of used buckets and the number of allocated buckets, separated
408 by a slash.  This is pretty much useful only to find out whether
409 Perl's internal hashing algorithm is performing poorly on your data
410 set.  For example, you stick 10,000 things in a hash, but evaluating
411 %HASH in scalar context reveals C<"1/16">, which means only one out
412 of sixteen buckets has been touched, and presumably contains all
413 10,000 of your items.  This isn't supposed to happen.
414
415 As of Perl 5.25 the return was changed to be the count of keys in the
416 hash. If you need access to the old behavior you can use
417 C<Hash::Util::bucket_ratio()> instead.
418
419 If a tied hash is evaluated in scalar context, the C<SCALAR> method is
420 called (with a fallback to C<FIRSTKEY>).
421 X<hash, scalar context> X<hash, bucket> X<bucket>
422
423 You can preallocate space for a hash by assigning to the keys() function.
424 This rounds up the allocated buckets to the next power of two:
425
426     keys(%users) = 1000;                # allocate 1024 buckets
427
428 =head2 Scalar value constructors
429 X<scalar, literal> X<scalar, constant>
430
431 Numeric literals are specified in any of the following floating point or
432 integer formats:
433
434  12345
435  12345.67
436  .23E-10             # a very small number
437  3.14_15_92          # a very important number
438  4_294_967_296       # underscore for legibility
439  0xff                # hex
440  0xdead_beef         # more hex
441  0377                # octal (only numbers, begins with 0)
442  0b011011            # binary
443  0x1.999ap-4         # hexadecimal floating point (the 'p' is required)
444
445 You are allowed to use underscores (underbars) in numeric literals
446 between digits for legibility (but not multiple underscores in a row:
447 C<23__500> is not legal; C<23_500> is).
448 You could, for example, group binary
449 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
450 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
451 X<number, literal>
452
453 String literals are usually delimited by either single or double
454 quotes.  They work much like quotes in the standard Unix shells:
455 double-quoted string literals are subject to backslash and variable
456 substitution; single-quoted strings are not (except for C<\'> and
457 C<\\>).  The usual C-style backslash rules apply for making
458 characters such as newline, tab, etc., as well as some more exotic
459 forms.  See L<perlop/"Quote and Quote-like Operators"> for a list.
460 X<string, literal>
461
462 Hexadecimal, octal, or binary, representations in string literals
463 (e.g. '0xff') are not automatically converted to their integer
464 representation.  The hex() and oct() functions make these conversions
465 for you.  See L<perlfunc/hex> and L<perlfunc/oct> for more details.
466
467 Hexadecimal floating point can start just like a hexadecimal literal,
468 and it can be followed by an optional fractional hexadecimal part,
469 but it must be followed by C<p>, an optional sign, and a power of two.
470 The format is useful for accurately presenting floating point values,
471 avoiding conversions to or from decimal floating point, and therefore
472 avoiding possible loss in precision.  Notice that while most current
473 platforms use the 64-bit IEEE 754 floating point, not all do.  Another
474 potential source of (low-order) differences are the floating point
475 rounding modes, which can differ between CPUs, operating systems,
476 and compilers, and which Perl doesn't control.
477
478 You can also embed newlines directly in your strings, i.e., they can end
479 on a different line than they begin.  This is nice, but if you forget
480 your trailing quote, the error will not be reported until Perl finds
481 another line containing the quote character, which may be much further
482 on in the script.  Variable substitution inside strings is limited to
483 scalar variables, arrays, and array or hash slices.  (In other words,
484 names beginning with $ or @, followed by an optional bracketed
485 expression as a subscript.)  The following code segment prints out "The
486 price is $Z<>100."
487 X<interpolation>
488
489     $Price = '$100';    # not interpolated
490     print "The price is $Price.\n";     # interpolated
491
492 There is no double interpolation in Perl, so the C<$100> is left as is.
493
494 By default floating point numbers substituted inside strings use the
495 dot (".")  as the decimal separator.  If C<use locale> is in effect,
496 and POSIX::setlocale() has been called, the character used for the
497 decimal separator is affected by the LC_NUMERIC locale.
498 See L<perllocale> and L<POSIX>.
499
500 As in some shells, you can enclose the variable name in braces to
501 disambiguate it from following alphanumerics (and underscores).
502 You must also do
503 this when interpolating a variable into a string to separate the
504 variable name from a following double-colon or an apostrophe, since
505 these would be otherwise treated as a package separator:
506 X<interpolation>
507
508     $who = "Larry";
509     print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
510     print "We use ${who}speak when ${who}'s here.\n";
511
512 Without the braces, Perl would have looked for a $whospeak, a
513 C<$who::0>, and a C<$who's> variable.  The last two would be the
514 $0 and the $s variables in the (presumably) non-existent package
515 C<who>.
516
517 In fact, a simple identifier within such curlies is forced to be
518 a string, and likewise within a hash subscript.  Neither need
519 quoting.  Our earlier example, C<$days{'Feb'}> can be written as
520 C<$days{Feb}> and the quotes will be assumed automatically.  But
521 anything more complicated in the subscript will be interpreted as an
522 expression.  This means for example that C<$version{2.0}++> is
523 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
524
525 =head3 Special floating point: infinity (Inf) and not-a-number (NaN)
526
527 Floating point values include the special values C<Inf> and C<NaN>,
528 for infinity and not-a-number.  The infinity can be also negative.
529
530 The infinity is the result of certain math operations that overflow
531 the floating point range, like 9**9**9.  The not-a-number is the
532 result when the result is undefined or unrepresentable.  Though note
533 that you cannot get C<NaN> from some common "undefined" or
534 "out-of-range" operations like dividing by zero, or square root of
535 a negative number, since Perl generates fatal errors for those.
536
537 The infinity and not-a-number have their own special arithmetic rules.
538 The general rule is that they are "contagious": C<Inf> plus one is
539 C<Inf>, and C<NaN> plus one is C<NaN>.  Where things get interesting
540 is when you combine infinities and not-a-numbers: C<Inf> minus C<Inf>
541 and C<Inf> divided by C<Inf> are C<NaN> (while C<Inf> plus C<Inf> is
542 C<Inf> and C<Inf> times C<Inf> is C<Inf>).  C<NaN> is also curious
543 in that it does not equal any number, I<including> itself:
544 C<NaN> != C<NaN>.
545
546 Perl doesn't understand C<Inf> and C<NaN> as numeric literals, but
547 you can have them as strings, and Perl will convert them as needed:
548 "Inf" + 1.  (You can, however, import them from the POSIX extension;
549 C<use POSIX qw(Inf NaN);> and then use them as literals.)
550
551 Note that on input (string to number) Perl accepts C<Inf> and C<NaN>
552 in many forms.   Case is ignored, and the Win32-specific forms like
553 C<1.#INF> are understood, but on output the values are normalized to
554 C<Inf> and C<NaN>.
555
556 =head3 Version Strings
557 X<version string> X<vstring> X<v-string>
558
559 A literal of the form C<v1.20.300.4000> is parsed as a string composed
560 of characters with the specified ordinals.  This form, known as
561 v-strings, provides an alternative, more readable way to construct
562 strings, rather than use the somewhat less readable interpolation form
563 C<"\x{1}\x{14}\x{12c}\x{fa0}">.  This is useful for representing
564 Unicode strings, and for comparing version "numbers" using the string
565 comparison operators, C<cmp>, C<gt>, C<lt> etc.  If there are two or
566 more dots in the literal, the leading C<v> may be omitted.
567
568     print v9786;              # prints SMILEY, "\x{263a}"
569     print v102.111.111;       # prints "foo"
570     print 102.111.111;        # same
571
572 Such literals are accepted by both C<require> and C<use> for
573 doing a version check.  Note that using the v-strings for IPv4
574 addresses is not portable unless you also use the
575 inet_aton()/inet_ntoa() routines of the Socket package.
576
577 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
578 are not v-strings before the C<< => >> operator (which is usually used
579 to separate a hash key from a hash value); instead they are interpreted
580 as literal strings ('v65').  They were v-strings from Perl 5.6.0 to
581 Perl 5.8.0, but that caused more confusion and breakage than good.
582 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
583 be v-strings always.
584
585 =head3 Special Literals
586 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
587 X<end> X<data> X<^D> X<^Z>
588
589 The special literals __FILE__, __LINE__, and __PACKAGE__
590 represent the current filename, line number, and package name at that
591 point in your program.  __SUB__ gives a reference to the current
592 subroutine.  They may be used only as separate tokens; they
593 will not be interpolated into strings.  If there is no current package
594 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
595 value.  (But the empty C<package;> is no longer supported, as of version
596 5.10.)  Outside of a subroutine, __SUB__ is the undefined value.  __SUB__
597 is only available in 5.16 or higher, and only with a C<use v5.16> or
598 C<use feature "current_sub"> declaration.
599 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<__SUB__>
600 X<line> X<file> X<package>
601
602 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
603 may be used to indicate the logical end of the script before the actual
604 end of file.  Any following text is ignored.
605
606 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
607 where C<PACKNAME> is the package that was current when the __DATA__
608 token was encountered.  The filehandle is left open pointing to the
609 line after __DATA__.  The program should C<close DATA> when it is done
610 reading from it.  (Leaving it open leaks filehandles if the module is
611 reloaded for any reason, so it's a safer practice to close it.)  For
612 compatibility with older scripts written before __DATA__ was
613 introduced, __END__ behaves like __DATA__ in the top level script (but
614 not in files loaded with C<require> or C<do>) and leaves the remaining
615 contents of the file accessible via C<main::DATA>.
616
617 See L<SelfLoader> for more description of __DATA__, and
618 an example of its use.  Note that you cannot read from the DATA
619 filehandle in a BEGIN block: the BEGIN block is executed as soon
620 as it is seen (during compilation), at which point the corresponding
621 __DATA__ (or __END__) token has not yet been seen.
622
623 =head3 Barewords
624 X<bareword>
625
626 A word that has no other interpretation in the grammar will
627 be treated as if it were a quoted string.  These are known as
628 "barewords".  As with filehandles and labels, a bareword that consists
629 entirely of lowercase letters risks conflict with future reserved
630 words, and if you use the C<use warnings> pragma or the B<-w> switch, 
631 Perl will warn you about any such words.  Perl limits barewords (like
632 identifiers) to about 250 characters.  Future versions of Perl are likely
633 to eliminate these arbitrary limitations.
634
635 Some people may wish to outlaw barewords entirely.  If you
636 say
637
638     use strict 'subs';
639
640 then any bareword that would NOT be interpreted as a subroutine call
641 produces a compile-time error instead.  The restriction lasts to the
642 end of the enclosing block.  An inner block may countermand this
643 by saying C<no strict 'subs'>.
644
645 =head3 Array Interpolation
646 X<array, interpolation> X<interpolation, array> X<$">
647
648 Arrays and slices are interpolated into double-quoted strings
649 by joining the elements with the delimiter specified in the C<$">
650 variable (C<$LIST_SEPARATOR> if "use English;" is specified), 
651 space by default.  The following are equivalent:
652
653     $temp = join($", @ARGV);
654     system "echo $temp";
655
656     system "echo @ARGV";
657
658 Within search patterns (which also undergo double-quotish substitution)
659 there is an unfortunate ambiguity:  Is C</$foo[bar]/> to be interpreted as
660 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
661 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
662 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
663 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
664 and is almost always right.  If it does guess wrong, or if you're just
665 plain paranoid, you can force the correct interpretation with curly
666 braces as above.
667
668 If you're looking for the information on how to use here-documents,
669 which used to be here, that's been moved to
670 L<perlop/Quote and Quote-like Operators>.
671
672 =head2 List value constructors
673 X<list>
674
675 List values are denoted by separating individual values by commas
676 (and enclosing the list in parentheses where precedence requires it):
677
678     (LIST)
679
680 In a context not requiring a list value, the value of what appears
681 to be a list literal is simply the value of the final element, as
682 with the C comma operator.  For example,
683
684     @foo = ('cc', '-E', $bar);
685
686 assigns the entire list value to array @foo, but
687
688     $foo = ('cc', '-E', $bar);
689
690 assigns the value of variable $bar to the scalar variable $foo.
691 Note that the value of an actual array in scalar context is the
692 length of the array; the following assigns the value 3 to $foo:
693
694     @foo = ('cc', '-E', $bar);
695     $foo = @foo;                # $foo gets 3
696
697 You may have an optional comma before the closing parenthesis of a
698 list literal, so that you can say:
699
700     @foo = (
701         1,
702         2,
703         3,
704     );
705
706 To use a here-document to assign an array, one line per element,
707 you might use an approach like this:
708
709     @sauces = <<End_Lines =~ m/(\S.*\S)/g;
710         normal tomato
711         spicy tomato
712         green chile
713         pesto
714         white wine
715     End_Lines
716
717 LISTs do automatic interpolation of sublists.  That is, when a LIST is
718 evaluated, each element of the list is evaluated in list context, and
719 the resulting list value is interpolated into LIST just as if each
720 individual element were a member of LIST.  Thus arrays and hashes lose their
721 identity in a LIST--the list
722
723     (@foo,@bar,&SomeSub,%glarch)
724
725 contains all the elements of @foo followed by all the elements of @bar,
726 followed by all the elements returned by the subroutine named SomeSub 
727 called in list context, followed by the key/value pairs of %glarch.
728 To make a list reference that does I<NOT> interpolate, see L<perlref>.
729
730 The null list is represented by ().  Interpolating it in a list
731 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
732 interpolating an array with no elements is the same as if no
733 array had been interpolated at that point.
734
735 This interpolation combines with the facts that the opening
736 and closing parentheses are optional (except when necessary for
737 precedence) and lists may end with an optional comma to mean that
738 multiple commas within lists are legal syntax.  The list C<1,,3> is a
739 concatenation of two lists, C<1,> and C<3>, the first of which ends
740 with that optional comma.  C<1,,3> is C<(1,),(3)> is C<1,3> (And
741 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.)  Not that
742 we'd advise you to use this obfuscation.
743
744 A list value may also be subscripted like a normal array.  You must
745 put the list in parentheses to avoid ambiguity.  For example:
746
747     # Stat returns list value.
748     $time = (stat($file))[8];
749
750     # SYNTAX ERROR HERE.
751     $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES
752
753     # Find a hex digit.
754     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
755
756     # A "reverse comma operator".
757     return (pop(@foo),pop(@foo))[0];
758
759 Lists may be assigned to only when each element of the list
760 is itself legal to assign to:
761
762     ($a, $b, $c) = (1, 2, 3);
763
764     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
765
766 An exception to this is that you may assign to C<undef> in a list.
767 This is useful for throwing away some of the return values of a
768 function:
769
770     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
771
772 As of Perl 5.22, you can also use C<(undef)x2> instead of C<undef, undef>.
773 (You can also do C<($x) x 2>, which is less useful, because it assigns to
774 the same variable twice, clobbering the first value assigned.)
775
776 List assignment in scalar context returns the number of elements
777 produced by the expression on the right side of the assignment:
778
779     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
780     $x = (($foo,$bar) = f());           # set $x to f()'s return count
781
782 This is handy when you want to do a list assignment in a Boolean
783 context, because most list functions return a null list when finished,
784 which when assigned produces a 0, which is interpreted as FALSE.
785
786 It's also the source of a useful idiom for executing a function or
787 performing an operation in list context and then counting the number of
788 return values, by assigning to an empty list and then using that
789 assignment in scalar context.  For example, this code:
790
791     $count = () = $string =~ /\d+/g;
792
793 will place into $count the number of digit groups found in $string.
794 This happens because the pattern match is in list context (since it
795 is being assigned to the empty list), and will therefore return a list
796 of all matching parts of the string.  The list assignment in scalar
797 context will translate that into the number of elements (here, the
798 number of times the pattern matched) and assign that to $count.  Note
799 that simply using
800
801     $count = $string =~ /\d+/g;
802
803 would not have worked, since a pattern match in scalar context will
804 only return true or false, rather than a count of matches.
805
806 The final element of a list assignment may be an array or a hash:
807
808     ($a, $b, @rest) = split;
809     my($a, $b, %rest) = @_;
810
811 You can actually put an array or hash anywhere in the list, but the first one
812 in the list will soak up all the values, and anything after it will become
813 undefined.  This may be useful in a my() or local().
814
815 A hash can be initialized using a literal list holding pairs of
816 items to be interpreted as a key and a value:
817
818     # same as map assignment above
819     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
820
821 While literal lists and named arrays are often interchangeable, that's
822 not the case for hashes.  Just because you can subscript a list value like
823 a normal array does not mean that you can subscript a list value as a
824 hash.  Likewise, hashes included as parts of other lists (including
825 parameters lists and return lists from functions) always flatten out into
826 key/value pairs.  That's why it's good to use references sometimes.
827
828 It is often more readable to use the C<< => >> operator between key/value
829 pairs.  The C<< => >> operator is mostly just a more visually distinctive
830 synonym for a comma, but it also arranges for its left-hand operand to be
831 interpreted as a string if it's a bareword that would be a legal simple
832 identifier.  C<< => >> doesn't quote compound identifiers, that contain
833 double colons.  This makes it nice for initializing hashes:
834
835     %map = (
836                  red   => 0x00f,
837                  blue  => 0x0f0,
838                  green => 0xf00,
839    );
840
841 or for initializing hash references to be used as records:
842
843     $rec = {
844                 witch => 'Mable the Merciless',
845                 cat   => 'Fluffy the Ferocious',
846                 date  => '10/31/1776',
847     };
848
849 or for using call-by-named-parameter to complicated functions:
850
851    $field = $query->radio_group(
852                name      => 'group_name',
853                values    => ['eenie','meenie','minie'],
854                default   => 'meenie',
855                linebreak => 'true',
856                labels    => \%labels
857    );
858
859 Note that just because a hash is initialized in that order doesn't
860 mean that it comes out in that order.  See L<perlfunc/sort> for examples
861 of how to arrange for an output ordering.
862
863 If a key appears more than once in the initializer list of a hash, the last
864 occurrence wins:
865
866     %circle = (
867                   center => [5, 10],
868                   center => [27, 9],
869                   radius => 100,
870                   color => [0xDF, 0xFF, 0x00],
871                   radius => 54,
872     );
873
874     # same as
875     %circle = (
876                   center => [27, 9],
877                   color => [0xDF, 0xFF, 0x00],
878                   radius => 54,
879     );
880
881 This can be used to provide overridable configuration defaults:
882
883     # values in %args take priority over %config_defaults
884     %config = (%config_defaults, %args);
885
886 =head2 Subscripts
887
888 An array can be accessed one scalar at a
889 time by specifying a dollar sign (C<$>), then the
890 name of the array (without the leading C<@>), then the subscript inside
891 square brackets.  For example:
892
893     @myarray = (5, 50, 500, 5000);
894     print "The Third Element is", $myarray[2], "\n";
895
896 The array indices start with 0.  A negative subscript retrieves its 
897 value from the end.  In our example, C<$myarray[-1]> would have been 
898 5000, and C<$myarray[-2]> would have been 500.
899
900 Hash subscripts are similar, only instead of square brackets curly brackets
901 are used.  For example:
902
903     %scientists = 
904     (
905         "Newton" => "Isaac",
906         "Einstein" => "Albert",
907         "Darwin" => "Charles",
908         "Feynman" => "Richard",
909     );
910
911     print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
912
913 You can also subscript a list to get a single element from it:
914
915     $dir = (getpwnam("daemon"))[7];
916
917 =head2 Multi-dimensional array emulation
918
919 Multidimensional arrays may be emulated by subscripting a hash with a
920 list.  The elements of the list are joined with the subscript separator
921 (see L<perlvar/$;>).
922
923     $foo{$a,$b,$c}
924
925 is equivalent to
926
927     $foo{join($;, $a, $b, $c)}
928
929 The default subscript separator is "\034", the same as SUBSEP in B<awk>.
930
931 =head2 Slices
932 X<slice> X<array, slice> X<hash, slice>
933
934 A slice accesses several elements of a list, an array, or a hash
935 simultaneously using a list of subscripts.  It's more convenient
936 than writing out the individual elements as a list of separate
937 scalar values.
938
939     ($him, $her)   = @folks[0,-1];              # array slice
940     @them          = @folks[0 .. 3];            # array slice
941     ($who, $home)  = @ENV{"USER", "HOME"};      # hash slice
942     ($uid, $dir)   = (getpwnam("daemon"))[2,7]; # list slice
943
944 Since you can assign to a list of variables, you can also assign to
945 an array or hash slice.
946
947     @days[3..5]    = qw/Wed Thu Fri/;
948     @colors{'red','blue','green'} 
949                    = (0xff0000, 0x0000ff, 0x00ff00);
950     @folks[0, -1]  = @folks[-1, 0];
951
952 The previous assignments are exactly equivalent to
953
954     ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
955     ($colors{'red'}, $colors{'blue'}, $colors{'green'})
956                    = (0xff0000, 0x0000ff, 0x00ff00);
957     ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
958
959 Since changing a slice changes the original array or hash that it's
960 slicing, a C<foreach> construct will alter some--or even all--of the
961 values of the array or hash.
962
963     foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } 
964
965     foreach (@hash{qw[key1 key2]}) {
966         s/^\s+//;           # trim leading whitespace
967         s/\s+$//;           # trim trailing whitespace
968         s/(\w+)/\u\L$1/g;   # "titlecase" words
969     }
970
971 As a special exception, when you slice a list (but not an array or a hash),
972 if the list evaluates to empty, then taking a slice of that empty list will
973 always yield the empty list in turn.  Thus:
974
975     @a = ()[0,1];          # @a has no elements
976     @b = (@a)[0,1];        # @b has no elements
977     @c = (sub{}->())[0,1]; # @c has no elements
978     @d = ('a','b')[0,1];   # @d has two elements
979     @e = (@d)[0,1,8,9];    # @e has four elements
980     @f = (@d)[8,9];        # @f has two elements
981
982 This makes it easy to write loops that terminate when a null list
983 is returned:
984
985     while ( ($home, $user) = (getpwent)[7,0] ) {
986         printf "%-8s %s\n", $user, $home;
987     }
988
989 As noted earlier in this document, the scalar sense of list assignment
990 is the number of elements on the right-hand side of the assignment.
991 The null list contains no elements, so when the password file is
992 exhausted, the result is 0, not 2.
993
994 Slices in scalar context return the last item of the slice.
995
996     @a = qw/first second third/;
997     %h = (first => 'A', second => 'B');
998     $t = @a[0, 1];                  # $t is now 'second'
999     $u = @h{'first', 'second'};     # $u is now 'B'
1000
1001 If you're confused about why you use an '@' there on a hash slice
1002 instead of a '%', think of it like this.  The type of bracket (square
1003 or curly) governs whether it's an array or a hash being looked at.
1004 On the other hand, the leading symbol ('$' or '@') on the array or
1005 hash indicates whether you are getting back a singular value (a
1006 scalar) or a plural one (a list).
1007
1008 =head3 Key/Value Hash Slices
1009
1010 Starting in Perl 5.20, a hash slice operation
1011 with the % symbol is a variant of slice operation
1012 returning a list of key/value pairs rather than just values:
1013
1014     %h = (blonk => 2, foo => 3, squink => 5, bar => 8);
1015     %subset = %h{'foo', 'bar'}; # key/value hash slice
1016     # %subset is now (foo => 3, bar => 8)
1017
1018 However, the result of such a slice cannot be localized, deleted or used
1019 in assignment.  These are otherwise very much consistent with hash slices
1020 using the @ symbol.
1021
1022 =head3 Index/Value Array Slices
1023
1024 Similar to key/value hash slices (and also introduced
1025 in Perl 5.20), the % array slice syntax returns a list
1026 of index/value pairs:
1027
1028     @a = "a".."z";
1029     @list = %a[3,4,6];
1030     # @list is now (3, "d", 4, "e", 6, "g")
1031
1032 =head2 Typeglobs and Filehandles
1033 X<typeglob> X<filehandle> X<*>
1034
1035 Perl uses an internal type called a I<typeglob> to hold an entire
1036 symbol table entry.  The type prefix of a typeglob is a C<*>, because
1037 it represents all types.  This used to be the preferred way to
1038 pass arrays and hashes by reference into a function, but now that
1039 we have real references, this is seldom needed.  
1040
1041 The main use of typeglobs in modern Perl is create symbol table aliases.
1042 This assignment:
1043
1044     *this = *that;
1045
1046 makes $this an alias for $that, @this an alias for @that, %this an alias
1047 for %that, &this an alias for &that, etc.  Much safer is to use a reference.
1048 This:
1049
1050     local *Here::blue = \$There::green;
1051
1052 temporarily makes $Here::blue an alias for $There::green, but doesn't
1053 make @Here::blue an alias for @There::green, or %Here::blue an alias for
1054 %There::green, etc.  See L<perlmod/"Symbol Tables"> for more examples
1055 of this.  Strange though this may seem, this is the basis for the whole
1056 module import/export system.
1057
1058 Another use for typeglobs is to pass filehandles into a function or
1059 to create new filehandles.  If you need to use a typeglob to save away
1060 a filehandle, do it this way:
1061
1062     $fh = *STDOUT;
1063
1064 or perhaps as a real reference, like this:
1065
1066     $fh = \*STDOUT;
1067
1068 See L<perlsub> for examples of using these as indirect filehandles
1069 in functions.
1070
1071 Typeglobs are also a way to create a local filehandle using the local()
1072 operator.  These last until their block is exited, but may be passed back.
1073 For example:
1074
1075     sub newopen {
1076         my $path = shift;
1077         local  *FH;  # not my!
1078         open   (FH, $path)          or  return undef;
1079         return *FH;
1080     }
1081     $fh = newopen('/etc/passwd');
1082
1083 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
1084 for filehandle manipulations, although they're still needed to pass brand
1085 new file and directory handles into or out of functions.  That's because
1086 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
1087 In other words, C<*FH> must be used to create new symbol table entries;
1088 C<*foo{THING}> cannot.  When in doubt, use C<*FH>.
1089
1090 All functions that are capable of creating filehandles (open(),
1091 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
1092 automatically create an anonymous filehandle if the handle passed to
1093 them is an uninitialized scalar variable.  This allows the constructs
1094 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
1095 create filehandles that will conveniently be closed automatically when
1096 the scope ends, provided there are no other references to them.  This
1097 largely eliminates the need for typeglobs when opening filehandles
1098 that must be passed around, as in the following example:
1099
1100     sub myopen {
1101         open my $fh, "@_"
1102              or die "Can't open '@_': $!";
1103         return $fh;
1104     }
1105
1106     {
1107         my $f = myopen("</etc/motd");
1108         print <$f>;
1109         # $f implicitly closed here
1110     }
1111
1112 Note that if an initialized scalar variable is used instead the
1113 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
1114 to C<open( *{'zzz'}, ...)>.
1115 C<use strict 'refs'> forbids such practice.
1116
1117 Another way to create anonymous filehandles is with the Symbol
1118 module or with the IO::Handle module and its ilk.  These modules
1119 have the advantage of not hiding different types of the same name
1120 during the local().  See the bottom of L<perlfunc/open> for an
1121 example.
1122
1123 =head1 SEE ALSO
1124
1125 See L<perlvar> for a description of Perl's built-in variables and
1126 a discussion of legal variable names.  See L<perlref>, L<perlsub>,
1127 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
1128 the C<*foo{THING}> syntax.