ext/POSIX/lib/POSIX.pm

   1 package POSIX;
   2 use strict;
   3 use warnings;
   4
   5 our ($AUTOLOAD, %SIGRT);
   6
   7 our $VERSION = '1.25';
   8
   9 require XSLoader;
  10
  11 use Fcntl qw(FD_CLOEXEC F_DUPFD F_GETFD F_GETFL F_GETLK F_RDLCK F_SETFD
  12              F_SETFL F_SETLK F_SETLKW F_UNLCK F_WRLCK O_ACCMODE O_APPEND
  13              O_CREAT O_EXCL O_NOCTTY O_NONBLOCK O_RDONLY O_RDWR O_TRUNC
  14              O_WRONLY SEEK_CUR SEEK_END SEEK_SET
  15              S_ISBLK S_ISCHR S_ISDIR S_ISFIFO S_ISREG
  16              S_IRGRP S_IROTH S_IRUSR S_IRWXG S_IRWXO S_IRWXU S_ISGID S_ISUID
  17              S_IWGRP S_IWOTH S_IWUSR S_IXGRP S_IXOTH S_IXUSR);
  18
  19 my $loaded;
  20
  21 sub import {
  22     my $pkg = shift;
  23
  24     load_imports() unless $loaded++;
  25
  26     # Grandfather old foo_h form to new :foo_h form
  27     s/^(?=\w+_h$)/:/ for my @list = @_;
  28
  29     local $Exporter::ExportLevel = 1;
  30     Exporter::import($pkg,@list);
  31 }
  32
  33 sub croak { require Carp;  goto &Carp::croak }
  34 sub usage { croak "Usage: POSIX::$_[0]" }
  35
  36 XSLoader::load();
  37
  38 my %replacement = (
  39     atexit      => 'END {}',
  40     atof        => undef,
  41     atoi        => undef,
  42     atol        => undef,
  43     bsearch     => \'not supplied',
  44     calloc      => undef,
  45     clearerr    => 'IO::Handle::clearerr',
  46     div         => '/, % and int',
  47     execl       => undef,
  48     execle      => undef,
  49     execlp      => undef,
  50     execv       => undef,
  51     execve      => undef,
  52     execvp      => undef,
  53     fclose      => 'IO::Handle::close',
  54     fdopen      => 'IO::Handle::new_from_fd',
  55     feof        => 'IO::Handle::eof',
  56     ferror      => 'IO::Handle::error',
  57     fflush      => 'IO::Handle::flush',
  58     fgetc       => 'IO::Handle::getc',
  59     fgetpos     => 'IO::Seekable::getpos',
  60     fgets       => 'IO::Handle::gets',
  61     fileno      => 'IO::Handle::fileno',
  62     fopen       => 'IO::File::open',
  63     fprintf     => 'printf',
  64     fputc       => 'print',
  65     fputs       => 'print',
  66     fread       => 'read',
  67     free        => undef,
  68     freopen     => 'open',
  69     fscanf      => '<> and regular expressions',
  70     fseek       => 'IO::Seekable::seek',
  71     fsetpos     => 'IO::Seekable::setpos',
  72     fsync       => 'IO::Handle::sync',
  73     ftell       => 'IO::Seekable::tell',
  74     fwrite      => 'print',
  75     labs        => 'abs',
  76     ldiv        => '/, % and int',
  77     longjmp     => 'die',
  78     malloc      => undef,
  79     memchr      => 'index()',
  80     memcmp      => 'eq',
  81     memcpy      => '=',
  82     memmove     => '=',
  83     memset      => 'x',
  84     offsetof    => undef,
  85     putc        => 'print',
  86     putchar     => 'print',
  87     puts        => 'print',
  88     qsort       => 'sort',
  89     rand        => \'non-portable, use Perl\'s rand instead',
  90     realloc     => undef,
  91     scanf       => '<> and regular expressions',
  92     setbuf      => 'IO::Handle::setbuf',
  93     setjmp      => 'eval {}',
  94     setvbuf     => 'IO::Handle::setvbuf',
  95     siglongjmp  => 'die',
  96     sigsetjmp   => 'eval {}',
  97     srand       => \'not supplied, refer to Perl\'s srand documentation',
  98     sscanf      => 'regular expressions',
  99     strcat      => '.=',
 100     strchr      => 'index()',
 101     strcmp      => 'eq',
 102     strcpy      => '=',
 103     strcspn     => 'regular expressions',
 104     strlen      => 'length',
 105     strncat     => '.=',
 106     strncmp     => 'eq',
 107     strncpy     => '=',
 108     strpbrk     => undef,
 109     strrchr     => 'rindex()',
 110     strspn      => undef,
 111     strtok      => undef,
 112     tmpfile     => 'IO::File::new_tmpfile',
 113     ungetc      => 'IO::Handle::ungetc',
 114     vfprintf    => undef,
 115     vprintf     => undef,
 116     vsprintf    => undef,
 117 );
 118
 119 my %reimpl = (
 120     assert    => 'expr => croak "Assertion failed" if !$_[0]',
 121     tolower   => 'string => lc($_[0])',
 122     toupper   => 'string => uc($_[0])',
 123     closedir  => 'dirhandle => CORE::closedir($_[0])',
 124     opendir   => 'directory => my $dh; CORE::opendir($dh, $_[0]) ? $dh : undef',
 125     readdir   => 'dirhandle => CORE::readdir($_[0])',
 126     rewinddir => 'dirhandle => CORE::rewinddir($_[0])',
 127     errno     => '$! + 0',
 128     creat     => 'filename, mode => &open($_[0], &O_WRONLY | &O_CREAT | &O_TRUNC, $_[1])',
 129     fcntl     => 'filehandle, cmd, arg => CORE::fcntl($_[0], $_[1], $_[2])',
 130     getgrgid  => 'gid => CORE::getgrgid($_[0])',
 131     getgrnam  => 'name => CORE::getgrnam($_[0])',
 132     atan2     => 'x, y => CORE::atan2($_[0], $_[1])',
 133     cos       => 'x => CORE::cos($_[0])',
 134     exp       => 'x => CORE::exp($_[0])',
 135     fabs      => 'x => CORE::abs($_[0])',
 136     log       => 'x => CORE::log($_[0])',
 137     pow       => 'x, exponent => $_[0] ** $_[1]',
 138     sin       => 'x => CORE::sin($_[0])',
 139     sqrt      => 'x => CORE::sqrt($_[0])',
 140     getpwnam  => 'name => CORE::getpwnam($_[0])',
 141     getpwuid  => 'uid => CORE::getpwuid($_[0])',
 142     kill      => 'pid, sig => CORE::kill $_[1], $_[0]',
 143     raise     => 'sig => CORE::kill $_[0], $$;  # Is this good enough',
 144     getc      => 'handle => CORE::getc($_[0])',
 145     getchar   => 'CORE::getc(STDIN)',
 146     gets      => 'scalar <STDIN>',
 147     remove    => 'filename => (-d $_[0]) ? CORE::rmdir($_[0]) : CORE::unlink($_[0])',
 148     rename    => 'oldfilename, newfilename => CORE::rename($_[0], $_[1])',
 149     rewind    => 'filehandle => CORE::seek($_[0],0,0)',
 150     abs       => 'x => CORE::abs($_[0])',
 151     exit      => 'status => CORE::exit($_[0])',
 152     getenv    => 'name => $ENV{$_[0]}',
 153     system    => 'command => CORE::system($_[0])',
 154     strerror  => 'errno => local $! = $_[0]; "$!"',
 155     strstr    => 'big, little => CORE::index($_[0], $_[1])',
 156     chmod     => 'mode, filename => CORE::chmod($_[0], $_[1])',
 157     fstat     => 'fd => CORE::open my $dup, "<&", $_[0]; CORE::stat($dup)', # Gross.
 158     mkdir     => 'directoryname, mode => CORE::mkdir($_[0], $_[1])',
 159     stat      => 'filename => CORE::stat($_[0])',
 160     umask     => 'mask => CORE::umask($_[0])',
 161     wait      => 'CORE::wait()',
 162     waitpid   => 'pid, options => CORE::waitpid($_[0], $_[1])',
 163     gmtime    => 'time => CORE::gmtime($_[0])',
 164     localtime => 'time => CORE::localtime($_[0])',
 165     time      => 'CORE::time',
 166     alarm     => 'seconds => CORE::alarm($_[0])',
 167     chdir     => 'directory => CORE::chdir($_[0])',
 168     chown     => 'uid, gid, filename => CORE::chown($_[0], $_[1], $_[2])',
 169     fork      => 'CORE::fork',
 170     getegid   => '$) + 0',
 171     geteuid   => '$> + 0',
 172     getgid    => '$( + 0',
 173     getgroups => 'my %seen; grep !$seen{$_}++, split " ", $)',
 174     getlogin  => 'CORE::getlogin()',
 175     getpgrp   => 'CORE::getpgrp',
 176     getpid    => '$$',
 177     getppid   => 'CORE::getppid',
 178     getuid    => '$<',
 179     isatty    => 'filehandle => -t $_[0]',
 180     link      => 'oldfilename, newfilename => CORE::link($_[0], $_[1])',
 181     rmdir     => 'directoryname => CORE::rmdir($_[0])',
 182     sleep     => 'seconds => $_[0] - CORE::sleep($_[0])',
 183     unlink    => 'filename => CORE::unlink($_[0])',
 184     utime     => 'filename, atime, mtime => CORE::utime($_[1], $_[2], $_[0])',
 185 );
 186
 187 eval join ';', map "sub $_", keys %replacement, keys %reimpl;
 188
 189 sub AUTOLOAD {
 190     my ($func) = ($AUTOLOAD =~ /.*::(.*)/);
 191
 192     if (my $code = delete $reimpl{$func}) {
 193         my ($num, $arg) = (0, '');
 194         if ($code =~ s/^(.*?) *=> *//) {
 195             $arg = $1;
 196             $num = 1 + $arg =~ tr/,//;
 197         }
 198         # no warnings to be consistent with the old implementation, where each
 199         # function was in its own little AutoSplit world:
 200         eval qq{ sub $func {
 201                 no warnings;
 202                 usage "$func($arg)" if \@_ != $num;
 203                 $code
 204             } };
 205         no strict;
 206         goto &$AUTOLOAD;
 207     }
 208     if (exists $replacement{$func}) {
 209         my $how = $replacement{$func};
 210         croak "Unimplemented: POSIX::$func() is C-specific, stopped"
 211             unless defined $how;
 212         croak "Unimplemented: POSIX::$func() is $$how" if ref $how;
 213         croak "Use method $how() instead of POSIX::$func()" if $how =~ /::/;
 214         croak "Unimplemented: POSIX::$func() is C-specific, use $how instead";
 215     }
 216
 217     constant($func);
 218 }
 219
 220 sub perror {
 221     print STDERR "@_: " if @_;
 222     print STDERR $!,"\n";
 223 }
 224
 225 sub printf {
 226     usage "printf(pattern, args...)" if @_ < 1;
 227     CORE::printf STDOUT @_;
 228 }
 229
 230 sub sprintf {
 231     usage "sprintf(pattern, args...)" if @_ == 0;
 232     CORE::sprintf(shift,@_);
 233 }
 234
 235 sub load_imports {
 236 our %EXPORT_TAGS = (
 237
 238     assert_h => [qw(assert NDEBUG)],
 239
 240     ctype_h =>  [qw(isalnum isalpha iscntrl isdigit isgraph islower
 241                 isprint ispunct isspace isupper isxdigit tolower toupper)],
 242
 243     dirent_h => [],
 244
 245     errno_h =>  [qw(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EAFNOSUPPORT
 246                 EAGAIN EALREADY EBADF EBUSY ECHILD ECONNABORTED
 247                 ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDOM EDQUOT
 248                 EEXIST EFAULT EFBIG EHOSTDOWN EHOSTUNREACH EINPROGRESS
 249                 EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK
 250                 EMSGSIZE ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH
 251                 ENFILE ENOBUFS ENODEV ENOENT ENOEXEC ENOLCK ENOMEM
 252                 ENOPROTOOPT ENOSPC ENOSYS ENOTBLK ENOTCONN ENOTDIR
 253                 ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM
 254                 EPFNOSUPPORT EPIPE EPROCLIM EPROTONOSUPPORT EPROTOTYPE
 255                 ERANGE EREMOTE ERESTART EROFS ESHUTDOWN ESOCKTNOSUPPORT
 256                 ESPIPE ESRCH ESTALE ETIMEDOUT ETOOMANYREFS ETXTBSY
 257                 EUSERS EWOULDBLOCK EXDEV errno)],
 258
 259     fcntl_h =>  [qw(FD_CLOEXEC F_DUPFD F_GETFD F_GETFL F_GETLK F_RDLCK
 260                 F_SETFD F_SETFL F_SETLK F_SETLKW F_UNLCK F_WRLCK
 261                 O_ACCMODE O_APPEND O_CREAT O_EXCL O_NOCTTY O_NONBLOCK
 262                 O_RDONLY O_RDWR O_TRUNC O_WRONLY
 263                 creat
 264                 SEEK_CUR SEEK_END SEEK_SET
 265                 S_IRGRP S_IROTH S_IRUSR S_IRWXG S_IRWXO S_IRWXU
 266                 S_ISBLK S_ISCHR S_ISDIR S_ISFIFO S_ISGID S_ISREG S_ISUID
 267                 S_IWGRP S_IWOTH S_IWUSR)],
 268
 269     float_h =>  [qw(DBL_DIG DBL_EPSILON DBL_MANT_DIG
 270                 DBL_MAX DBL_MAX_10_EXP DBL_MAX_EXP
 271                 DBL_MIN DBL_MIN_10_EXP DBL_MIN_EXP
 272                 FLT_DIG FLT_EPSILON FLT_MANT_DIG
 273                 FLT_MAX FLT_MAX_10_EXP FLT_MAX_EXP
 274                 FLT_MIN FLT_MIN_10_EXP FLT_MIN_EXP
 275                 FLT_RADIX FLT_ROUNDS
 276                 LDBL_DIG LDBL_EPSILON LDBL_MANT_DIG
 277                 LDBL_MAX LDBL_MAX_10_EXP LDBL_MAX_EXP
 278                 LDBL_MIN LDBL_MIN_10_EXP LDBL_MIN_EXP)],
 279
 280     grp_h =>    [],
 281
 282     limits_h => [qw( ARG_MAX CHAR_BIT CHAR_MAX CHAR_MIN CHILD_MAX
 283                 INT_MAX INT_MIN LINK_MAX LONG_MAX LONG_MIN MAX_CANON
 284                 MAX_INPUT MB_LEN_MAX NAME_MAX NGROUPS_MAX OPEN_MAX
 285                 PATH_MAX PIPE_BUF SCHAR_MAX SCHAR_MIN SHRT_MAX SHRT_MIN
 286                 SSIZE_MAX STREAM_MAX TZNAME_MAX UCHAR_MAX UINT_MAX
 287                 ULONG_MAX USHRT_MAX _POSIX_ARG_MAX _POSIX_CHILD_MAX
 288                 _POSIX_LINK_MAX _POSIX_MAX_CANON _POSIX_MAX_INPUT
 289                 _POSIX_NAME_MAX _POSIX_NGROUPS_MAX _POSIX_OPEN_MAX
 290                 _POSIX_PATH_MAX _POSIX_PIPE_BUF _POSIX_SSIZE_MAX
 291                 _POSIX_STREAM_MAX _POSIX_TZNAME_MAX)],
 292
 293     locale_h => [qw(LC_ALL LC_COLLATE LC_CTYPE LC_MESSAGES
 294                     LC_MONETARY LC_NUMERIC LC_TIME NULL
 295                     localeconv setlocale)],
 296
 297     math_h =>   [qw(HUGE_VAL acos asin atan ceil cosh fabs floor fmod
 298                 frexp ldexp log10 modf pow sinh tan tanh)],
 299
 300     pwd_h =>    [],
 301
 302     setjmp_h => [qw(longjmp setjmp siglongjmp sigsetjmp)],
 303
 304     signal_h => [qw(SA_NOCLDSTOP SA_NOCLDWAIT SA_NODEFER SA_ONSTACK
 305                 SA_RESETHAND SA_RESTART SA_SIGINFO SIGABRT SIGALRM
 306                 SIGCHLD SIGCONT SIGFPE SIGHUP SIGILL SIGINT SIGKILL
 307                 SIGPIPE %SIGRT SIGRTMIN SIGRTMAX SIGQUIT SIGSEGV SIGSTOP
 308                 SIGTERM SIGTSTP SIGTTIN SIGTTOU SIGUSR1 SIGUSR2 SIGBUS
 309                 SIGPOLL SIGPROF SIGSYS SIGTRAP SIGURG SIGVTALRM SIGXCPU SIGXFSZ
 310                 SIG_BLOCK SIG_DFL SIG_ERR SIG_IGN SIG_SETMASK SIG_UNBLOCK
 311                 raise sigaction signal sigpending sigprocmask sigsuspend)],
 312
 313     stdarg_h => [],
 314
 315     stddef_h => [qw(NULL offsetof)],
 316
 317     stdio_h =>  [qw(BUFSIZ EOF FILENAME_MAX L_ctermid L_cuserid
 318                 L_tmpname NULL SEEK_CUR SEEK_END SEEK_SET
 319                 STREAM_MAX TMP_MAX stderr stdin stdout
 320                 clearerr fclose fdopen feof ferror fflush fgetc fgetpos
 321                 fgets fopen fprintf fputc fputs fread freopen
 322                 fscanf fseek fsetpos ftell fwrite getchar gets
 323                 perror putc putchar puts remove rewind
 324                 scanf setbuf setvbuf sscanf tmpfile tmpnam
 325                 ungetc vfprintf vprintf vsprintf)],
 326
 327     stdlib_h => [qw(EXIT_FAILURE EXIT_SUCCESS MB_CUR_MAX NULL RAND_MAX
 328                 abort atexit atof atoi atol bsearch calloc div
 329                 free getenv labs ldiv malloc mblen mbstowcs mbtowc
 330                 qsort realloc strtod strtol strtoul wcstombs wctomb)],
 331
 332     string_h => [qw(NULL memchr memcmp memcpy memmove memset strcat
 333                 strchr strcmp strcoll strcpy strcspn strerror strlen
 334                 strncat strncmp strncpy strpbrk strrchr strspn strstr
 335                 strtok strxfrm)],
 336
 337     sys_stat_h => [qw(S_IRGRP S_IROTH S_IRUSR S_IRWXG S_IRWXO S_IRWXU
 338                 S_ISBLK S_ISCHR S_ISDIR S_ISFIFO S_ISGID S_ISREG
 339                 S_ISUID S_IWGRP S_IWOTH S_IWUSR S_IXGRP S_IXOTH S_IXUSR
 340                 fstat mkfifo)],
 341
 342     sys_times_h => [],
 343
 344     sys_types_h => [],
 345
 346     sys_utsname_h => [qw(uname)],
 347
 348     sys_wait_h => [qw(WEXITSTATUS WIFEXITED WIFSIGNALED WIFSTOPPED
 349                 WNOHANG WSTOPSIG WTERMSIG WUNTRACED)],
 350
 351     termios_h => [qw( B0 B110 B1200 B134 B150 B1800 B19200 B200 B2400
 352                 B300 B38400 B4800 B50 B600 B75 B9600 BRKINT CLOCAL
 353                 CREAD CS5 CS6 CS7 CS8 CSIZE CSTOPB ECHO ECHOE ECHOK
 354                 ECHONL HUPCL ICANON ICRNL IEXTEN IGNBRK IGNCR IGNPAR
 355                 INLCR INPCK ISIG ISTRIP IXOFF IXON NCCS NOFLSH OPOST
 356                 PARENB PARMRK PARODD TCIFLUSH TCIOFF TCIOFLUSH TCION
 357                 TCOFLUSH TCOOFF TCOON TCSADRAIN TCSAFLUSH TCSANOW
 358                 TOSTOP VEOF VEOL VERASE VINTR VKILL VMIN VQUIT VSTART
 359                 VSTOP VSUSP VTIME
 360                 cfgetispeed cfgetospeed cfsetispeed cfsetospeed tcdrain
 361                 tcflow tcflush tcgetattr tcsendbreak tcsetattr )],
 362
 363     time_h =>   [qw(CLK_TCK CLOCKS_PER_SEC NULL asctime clock ctime
 364                 difftime mktime strftime tzset tzname)],
 365
 366     unistd_h => [qw(F_OK NULL R_OK SEEK_CUR SEEK_END SEEK_SET
 367                 STDERR_FILENO STDIN_FILENO STDOUT_FILENO W_OK X_OK
 368                 _PC_CHOWN_RESTRICTED _PC_LINK_MAX _PC_MAX_CANON
 369                 _PC_MAX_INPUT _PC_NAME_MAX _PC_NO_TRUNC _PC_PATH_MAX
 370                 _PC_PIPE_BUF _PC_VDISABLE _POSIX_CHOWN_RESTRICTED
 371                 _POSIX_JOB_CONTROL _POSIX_NO_TRUNC _POSIX_SAVED_IDS
 372                 _POSIX_VDISABLE _POSIX_VERSION _SC_ARG_MAX
 373                 _SC_CHILD_MAX _SC_CLK_TCK _SC_JOB_CONTROL
 374                 _SC_NGROUPS_MAX _SC_OPEN_MAX _SC_PAGESIZE _SC_SAVED_IDS
 375                 _SC_STREAM_MAX _SC_TZNAME_MAX _SC_VERSION
 376                 _exit access ctermid cuserid
 377                 dup2 dup execl execle execlp execv execve execvp
 378                 fpathconf fsync getcwd getegid geteuid getgid getgroups
 379                 getpid getuid isatty lseek pathconf pause setgid setpgid
 380                 setsid setuid sysconf tcgetpgrp tcsetpgrp ttyname)],
 381
 382     utime_h =>  [],
 383 );
 384
 385 # Exporter::export_tags();
 386 {
 387   # De-duplicate the export list:
 388   my %export;
 389   @export{map {@$_} values %EXPORT_TAGS} = ();
 390   # Doing the de-dup with a temporary hash has the advantage that the SVs in
 391   # @EXPORT are actually shared hash key scalars, which will save some memory.
 392   our @EXPORT = keys %export;
 393 }
 394
 395 our @EXPORT_OK = qw(
 396                 abs
 397                 alarm
 398                 atan2
 399                 chdir
 400                 chmod
 401                 chown
 402                 close
 403                 closedir
 404                 cos
 405                 exit
 406                 exp
 407                 fcntl
 408                 fileno
 409                 fork
 410                 getc
 411                 getgrgid
 412                 getgrnam
 413                 getlogin
 414                 getpgrp
 415                 getppid
 416                 getpwnam
 417                 getpwuid
 418                 gmtime
 419                 kill
 420                 lchown
 421                 link
 422                 localtime
 423                 log
 424                 mkdir
 425                 nice
 426                 open
 427                 opendir
 428                 pipe
 429                 printf
 430                 rand
 431                 read
 432                 readdir
 433                 rename
 434                 rewinddir
 435                 rmdir
 436                 sin
 437                 sleep
 438                 sprintf
 439                 sqrt
 440                 srand
 441                 stat
 442                 system
 443                 time
 444                 times
 445                 umask
 446                 unlink
 447                 utime
 448                 wait
 449                 waitpid
 450                 write
 451 );
 452
 453 require Exporter;
 454 }
 455
 456 package POSIX::SigAction;
 457
 458 sub new { bless {HANDLER => $_[1], MASK => $_[2], FLAGS => $_[3] || 0, SAFE => 0}, $_[0] }
 459 sub handler { $_[0]->{HANDLER} = $_[1] if @_ > 1; $_[0]->{HANDLER} };
 460 sub mask    { $_[0]->{MASK}    = $_[1] if @_ > 1; $_[0]->{MASK} };
 461 sub flags   { $_[0]->{FLAGS}   = $_[1] if @_ > 1; $_[0]->{FLAGS} };
 462 sub safe    { $_[0]->{SAFE}    = $_[1] if @_ > 1; $_[0]->{SAFE} };
 463
 464 package POSIX::SigRt;
 465
 466 require Tie::Hash;
 467
 468 our @ISA = 'Tie::StdHash';
 469
 470 our ($_SIGRTMIN, $_SIGRTMAX, $_sigrtn);
 471
 472 our $SIGACTION_FLAGS = 0;
 473
 474 sub _init {
 475     $_SIGRTMIN = &POSIX::SIGRTMIN;
 476     $_SIGRTMAX = &POSIX::SIGRTMAX;
 477     $_sigrtn   = $_SIGRTMAX - $_SIGRTMIN;
 478 }
 479
 480 sub _croak {
 481     &_init unless defined $_sigrtn;
 482     die "POSIX::SigRt not available" unless defined $_sigrtn && $_sigrtn > 0;
 483 }
 484
 485 sub _getsig {
 486     &_croak;
 487     my $rtsig = $_[0];
 488     # Allow (SIGRT)?MIN( + n)?, a common idiom when doing these things in C.
 489     $rtsig = $_SIGRTMIN + ($1 || 0)
 490         if $rtsig =~ /^(?:(?:SIG)?RT)?MIN(\s*\+\s*(\d+))?$/;
 491     return $rtsig;
 492 }
 493
 494 sub _exist {
 495     my $rtsig = _getsig($_[1]);
 496     my $ok    = $rtsig >= $_SIGRTMIN && $rtsig <= $_SIGRTMAX;
 497     ($rtsig, $ok);
 498 }
 499
 500 sub _check {
 501     my ($rtsig, $ok) = &_exist;
 502     die "No POSIX::SigRt signal $_[1] (valid range SIGRTMIN..SIGRTMAX, or $_SIGRTMIN..$_SIGRTMAX)"
 503         unless $ok;
 504     return $rtsig;
 505 }
 506
 507 sub new {
 508     my ($rtsig, $handler, $flags) = @_;
 509     my $sigset = POSIX::SigSet->new($rtsig);
 510     my $sigact = POSIX::SigAction->new($handler, $sigset, $flags);
 511     POSIX::sigaction($rtsig, $sigact);
 512 }
 513
 514 sub EXISTS { &_exist }
 515 sub FETCH  { my $rtsig = &_check;
 516              my $oa = POSIX::SigAction->new();
 517              POSIX::sigaction($rtsig, undef, $oa);
 518              return $oa->{HANDLER} }
 519 sub STORE  { my $rtsig = &_check; new($rtsig, $_[2], $SIGACTION_FLAGS) }
 520 sub DELETE { delete $SIG{ &_check } }
 521 sub CLEAR  { &_exist; delete @SIG{ &POSIX::SIGRTMIN .. &POSIX::SIGRTMAX } }
 522 sub SCALAR { &_croak; $_sigrtn + 1 }
 523
 524 tie %POSIX::SIGRT, 'POSIX::SigRt';
 525 # and the expression on the line above is true, so we return true.