This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
In installperl, invert the sense of the variable used for the -o option.
[perl5.git] / installperl
1 #!./perl -w
2
3 BEGIN {
4     require 5.004;
5     chdir '..' if !-d 'lib' and -d '../lib';
6     @INC = 'lib';
7     $ENV{PERL5LIB} = 'lib';
8
9     # This needs to be at BEGIN time, before any use of Config
10     require './install_lib.pl';
11 }
12
13 use strict;
14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
15             %opts $packlist);
16 my ($dostrip, $versiononly, $force,
17     $skip_otherperls, $archname, $nwinstall, $nopods);
18
19 BEGIN {
20     if ($Is_VMS) { eval 'use VMS::Filespec;' }
21 }
22
23 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
24
25 use File::Find;
26 use File::Compare;
27 use File::Copy ();
28 use File::Path ();
29 use ExtUtils::Packlist;
30 use Cwd;
31
32 require './Porting/pod_lib.pl';
33
34 if ($Is_NetWare) {
35     $Is_W32 = 0;
36     $scr_ext = '.pl';
37 }
38
39 # override the ones in the rest of the script
40 sub mkpath {
41     File::Path::mkpath(@_) unless $opts{notify};
42 }
43
44 my $mainperldir = "/usr/bin";
45 my $exe_ext = $Config{exe_ext};
46
47 # Allow "make install PERLNAME=something_besides_perl":
48 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
49
50 # This is the base used for versioned names, like "perl5.6.0".
51 # It's separate because a common use of $PERLNAME is to install
52 # perl as "perl5", if that's used as base for versioned files you
53 # get "perl55.6.0".
54 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
55                     ? $ENV{PERLNAME_VERBASE}
56                     : $perl;
57 my $dbg = '';
58 my $ndbg = '';
59 if ( $Is_VMS ) {
60     if ( defined $Config{usevmsdebug} ) {
61         if ( $Config{usevmsdebug} eq 'define' ) {
62             $dbg = 'dbg';
63             $ndbg = 'ndbg';
64         }
65     }
66 }
67
68 # This little hack simplifies making the code after the comment "Fetch some
69 # frequently-used items from %Config" warning free. With $opts{destdir} always
70 # defined, it's also possible to make the s/\Q$opts{destdir}\E unconditional.
71
72 $opts{destdir} = '';
73 # Consider refactoring this to use Getopt::Long once Getopt::Long's planned
74 # feature is implemented, to distinguish + and - options.
75 while (@ARGV) {
76     $opts{notify} = 1 if $ARGV[0] eq '-n';
77     $dostrip = 1 if $ARGV[0] eq '-s';
78     $versiononly = 1 if $ARGV[0] eq '-v';
79     $versiononly = 0 if $ARGV[0] eq '+v';
80     $opts{silent} = 1 if $ARGV[0] eq '-S';
81     $skip_otherperls = 1 if $ARGV[0] eq '-o';
82     $force = 1 if $ARGV[0] eq '-f';
83     $opts{verbose} = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
84     $archname = 1 if $ARGV[0] eq '-A';
85     $nwinstall = 1 if $ARGV[0] eq '-netware';
86     $nopods = 1 if $ARGV[0] eq '-p';
87     $opts{destdir} = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
88     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
89         print <<"EOT";
90 Usage $0: [switches]
91   -n        Don't actually run any commands; just print them.
92   -s        Run strip on installed binaries.
93   -v        Only install perl as a binary with the version number in the name.
94             (Override whatever config.sh says)
95   +v        Install perl as "perl" and as a binary with the version number in
96             the name.  (Override whatever config.sh says)
97   -S        Silent mode.
98   -f        Force installation (don't check if same version is there)
99   -o        Skip checking for other copies of perl in your PATH.
100   -V        Verbose mode.
101   -A        Also install perl with the architecture's name in the perl binary's
102             name.
103   -p        Don't install the pod files. [This will break use diagnostics;]
104   -netware  Install correctly on a Netware server.
105   -destdir  Prefix installation directories by this string.
106 EOT
107         exit;
108     }
109     shift;
110 }
111
112 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
113 my (@scripts, @tolink);
114 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
115 while (<SCRIPTS>) {
116     next if /^#/;
117     next if /a2p/; # a2p is binary, to be installed separately
118     chomp;
119     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
120         push @scripts, $1;
121         push @tolink, [$1, $2];
122     } else {
123         push @scripts, $_;
124     }
125 }
126 close SCRIPTS;
127
128 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
129
130 # Specify here any .pm files that are actually architecture-dependent.
131 # (Those included with XS extensions under ext/ are automatically
132 # added later.)
133 # Now that the default privlib has the full perl version number included,
134 # we no longer have to play the trick of sticking version-specific .pm
135 # files under the archlib directory.
136 my %archpms = (
137     Config => 1,
138     lib => 1,
139     Cwd => 1,
140 );
141
142 if ($^O eq 'dos') {
143     push(@scripts,'djgpp/fixpmain');
144     $archpms{config} = $archpms{filehand} = 1;
145 }
146
147 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
148     push(@scripts, map("$_.exe", @scripts));
149 }
150
151 # Exclude nonxs extensions that are not architecture dependent
152 my @nonxs = grep(!/^Errno$/, split(' ', $Config{'nonxs_ext'}));
153
154 my @ext_dirs = qw(cpan dist ext);
155 foreach my $ext_dir (@ext_dirs) {
156     find(sub {
157         if (($File::Find::name =~ m{^$ext_dir\b(.*)/([^/]+)\.pm$}) &&
158             ! grep { (my $dir = $_) =~ s/\//-/g;
159                      $File::Find::name =~ /^$ext_dir\/$dir\// } @nonxs)
160         {
161             my($path, $modname) = ($1,$2);
162
163             # Change hyphenated name like Filter-Util-Call to nested
164             # directory name Filter/Util/Call
165             $path =~ s{-}{/}g;
166
167             # strip to optional "/lib", or remove trailing component
168             $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
169
170             # strip any leading /
171             $path =~ s{^/}{};
172
173             # reconstitute canonical module name
174             $modname = "$path/$modname" if length $path;
175
176             # remember it
177             $archpms{$modname} = 1;
178         }
179     }, $ext_dir);
180 }
181
182 # print "[$_]\n" for sort keys %archpms;
183
184 my $ver = $Config{version};
185 my $release = substr($],0,3);   # Not used currently.
186 my $patchlevel = substr($],3,2);
187 die "Patchlevel of perl ($patchlevel)",
188     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
189         if $patchlevel != $Config{'PERL_VERSION'};
190
191 # Fetch some frequently-used items from %Config
192 my $installbin = "$opts{destdir}$Config{installbin}";
193 my $installscript = "$opts{destdir}$Config{installscript}";
194 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
195 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
196 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
197 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
198 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
199 my $man1ext = $Config{man1ext};
200 my $libperl = $Config{libperl};
201 # Shared library and dynamic loading suffixes.
202 my $so = $Config{so};
203 my $dlext = $Config{dlext};
204 my $dlsrc = $Config{dlsrc};
205 if ($^O eq 'os390') {
206     my $pwd;
207     chomp($pwd=`pwd`);
208     my $archlibexp = $Config{archlibexp};
209     my $usedl = $Config{usedl};
210     if ($usedl eq 'define') {
211         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
212     }
213 }
214
215 if ($nwinstall) {
216     # This is required only if we are installing on a NetWare server
217     $installscript = $Config{installnwscripts};
218     $installprivlib = $Config{installnwlib};
219     $installarchlib = $Config{installnwlib};
220     $installsitelib = $Config{installnwlib};
221 }
222
223 my $binexp = $Config{binexp};
224
225 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
226     foreach ( \$installbin,     \$installscript,  \$installprivlib,
227               \$installarchlib, \$installsitelib, \$installsitearch,
228               \$installman1dir ) {
229         $$_ = unixify($$_);  $$_ =~ s:/$::;
230     }
231 }
232
233 # Do some quick sanity checks.
234
235    $installbin          || die "No installbin directory in config.sh\n";
236 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
237 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
238 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
239         unless $installbin =~ m#^/afs/# || $opts{notify};
240
241 if (!$Is_NetWare) {
242 if (!$Is_VMS) {
243 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
244 }
245 else {
246 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
247     if ($dbg) {
248         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
249     }
250 }
251
252 -f 't/rantests'         || $Is_W32
253                         || warn "WARNING: You've never run 'make test' or",
254                                 " some tests failed! (Installing anyway.)\n";
255 } #if (!$Is_NetWare)
256
257 # This will be used to store the packlist
258 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
259
260 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
261     my $perldll;
262
263     if ($Is_Cygwin) {
264         $perldll = $libperl;
265     } else {
266         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
267     }
268
269     if ($dlsrc ne "dl_none.xs") {
270         -f $perldll || die "No perl DLL built\n";
271     }
272
273     # Install the DLL
274     safe_unlink("$installbin/$perldll");
275     copy("$perldll", "$installbin/$perldll");
276     chmod(0755, "$installbin/$perldll");
277     $packlist->{"$Config{installbin}/$perldll"} = { type => 'file' };
278 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
279
280 # First we install the version-numbered executables.
281
282 if ($Is_VMS) {
283     safe_unlink("$installbin/perl_setup.com");
284     copy("perl_setup.com", "$installbin/perl_setup.com");
285     chmod(0755, "$installbin/perl_setup.com");
286     safe_unlink("$installbin/$dbg$perl$exe_ext");
287     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
288     chmod(0755, "$installbin/$dbg$perl$exe_ext");
289     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
290     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
291     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
292     if ($ndbg) {
293         safe_unlink("$installbin/$ndbg$perl$exe_ext");
294         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
295         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
296         safe_unlink("$installbin/${dbg}a2p$exe_ext");
297         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
298         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
299     }
300 }
301 elsif ($^O ne 'dos') {
302     if (!$Is_NetWare) {
303         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
304         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
305         strip("$installbin/$perl_verbase$ver$exe_ext");
306         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
307     }
308     else {
309         # If installing onto a NetWare server
310         if ($nwinstall) {
311             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
312             mkpath($Config{installnwsystem}, $opts{verbose}, 0777);
313             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
314             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
315             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
316             copy("x2p\\a2p.nlm", $Config{installnwsystem});
317             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
318             mkpath($Config{installnwlcgi}, $opts{verbose}, 0777);
319             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
320         }
321     } #if (!$Is_NetWare)
322 }
323 else {
324     safe_unlink("$installbin/$perl.exe");
325     copy("perl.exe", "$installbin/$perl.exe");
326 }
327
328 # Install library files.
329
330 my $do_installarchlib = !samepath($installarchlib, 'lib');
331 my $do_installprivlib = !samepath($installprivlib, 'lib');
332 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
333 $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
334
335 mkpath($installprivlib, $opts{verbose}, 0777);
336 mkpath($installarchlib, $opts{verbose}, 0777);
337 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
338 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
339
340 if (-d 'lib') {
341     find({no_chdir => 1, wanted => \&installlib}, 'lib')
342         if $do_installarchlib || $do_installprivlib;
343 }
344 else {
345     warn "Can't install lib files - 'lib/' does not exist";
346 }
347
348 # Install header files and libraries.
349 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
350 my @corefiles;
351 if ($Is_VMS) {  # We did core file selection during build
352     my $coredir = "lib/$Config{archname}/$ver/CORE";
353     $coredir =~ tr/./_/;
354     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
355 }
356 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
357     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
358     my $coredll = "$installarchlib/CORE/$libperl";
359     my $instcoredll = "$Config{installarchlib}/CORE/$libperl";
360     safe_unlink($coredll);
361     ( $Config{'d_link'} eq 'define' &&
362       eval {
363           CORE::link("$installbin/$libperl", $coredll);
364           $packlist->{$instcoredll} = { from => "$Config{installbin}/$libperl",
365                                     type => 'link' };
366       }
367     ) ||
368     eval {
369         symlink("$installbin/$libperl", $coredll);
370         $packlist->{$instcoredll} = { from => "$Config{installbin}/$libperl",
371                                   type => 'link' };
372     } ||
373     ( copy("$installbin/$libperl", $coredll) &&
374       push(@corefiles, $instcoredll)
375     )
376 } else {
377     # [als] hard-coded 'libperl' name... not good!
378     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
379
380     # AIX needs perl.exp installed as well.
381     push(@corefiles,'perl.exp') if $^O eq 'aix';
382 }
383 foreach my $file (@corefiles) {
384     # HP-UX (at least) needs to maintain execute permissions
385     # on dynamically-loadable libraries. So we do it for all.
386     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
387         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
388             strip("-S", "$installarchlib/CORE/$file") if $^O eq 'darwin';
389             chmod(0555, "$installarchlib/CORE/$file");
390         } else {
391             chmod(0444, "$installarchlib/CORE/$file");
392         }
393     }
394 }
395
396 # Install main perl executables
397 # Make links to ordinary names if installbin directory isn't current directory.
398
399 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
400     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
401     if ($^O eq 'vos') {
402         # VOS doesn't support hard links, so use a symlink.
403         symlink("$installbin/$perl_verbase$ver$exe_ext",
404                 "$installbin/$perl$exe_ext");
405     } else {
406         link("$installbin/$perl_verbase$ver$exe_ext",
407                 "$installbin/$perl$exe_ext");
408     }
409 }
410
411 # For development purposes it can be very useful to have multiple perls
412 # build for different "architectures" (eg threading or not) simultaneously.
413 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
414     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
415     safe_unlink("$installbin/$archperl");
416     if ($^O eq 'vos') {
417         # VOS doesn't support hard links, so use a symlink.
418         symlink("$installbin/$perl_verbase$ver$exe_ext",
419                 "$installbin/$archperl");
420     } else {
421         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
422     }
423 }
424
425 # Offer to install perl in a "standard" location
426
427 my $mainperl_is_instperl = 0;
428
429 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
430     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
431         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
432     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
433     my($instperl)       = "$installbin/$perl$exe_ext";
434     my($expinstperl)    = "$binexp/$perl$exe_ext";
435
436     # First make sure $usrbinperl is not already the same as the perl we
437     # just installed.
438     if (-x $usrbinperl) {
439         # Try to be clever about mainperl being a symbolic link
440         # to binexp/perl if binexp and installbin are different.
441         $mainperl_is_instperl =
442             samepath($usrbinperl, $instperl) ||
443             samepath($usrbinperl, $expinstperl) ||
444              (($binexp ne $installbin) &&
445               (-l $usrbinperl) &&
446               ((readlink $usrbinperl) eq $expinstperl));
447     }
448     if (! $mainperl_is_instperl) {
449         unlink($usrbinperl);
450         ( $Config{'d_link'} eq 'define' &&
451           eval { CORE::link $instperl, $usrbinperl } )  ||
452         eval { symlink $expinstperl, $usrbinperl }      ||
453         copy($instperl, $usrbinperl);
454
455         $mainperl_is_instperl = 1;
456     }
457 }
458
459 # Make links to ordinary names if installbin directory isn't current directory.
460 if (!$Is_NetWare && $dbg eq '') {
461     if (! samepath($installbin, 'x2p')) {
462         my $base = 'a2p';
463         $base .= $ver if $versiononly;
464         safe_unlink("$installbin/$base$exe_ext");
465         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
466         strip("$installbin/$base$exe_ext");
467         chmod(0755, "$installbin/$base$exe_ext");
468     }
469 }
470
471 # cppstdin is just a script, but it is architecture-dependent, so
472 # it can't safely be shared.  Place it in $installbin.
473 # Note that Configure doesn't build cppstin if it isn't needed, so
474 # we skip this if cppstdin doesn't exist.
475 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
476     safe_unlink("$installbin/cppstdin");
477     copy("cppstdin", "$installbin/cppstdin");
478     chmod(0755, "$installbin/cppstdin");
479 }
480
481 sub script_alias {
482     my ($installscript, $orig, $alias, $scr_ext) = @_;
483
484     safe_unlink("$installscript/$alias$scr_ext");
485     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
486         copy("$installscript/$orig$scr_ext",
487              "$installscript/$alias$scr_ext");
488     } elsif ($^O eq 'vos') {
489         symlink("$installscript/$orig$scr_ext",
490                 "$installscript/$alias$scr_ext");
491     } else {
492         link("$installscript/$orig$scr_ext",
493              "$installscript/$alias$scr_ext");
494     }
495 }
496
497 # Install scripts.
498 mkpath($installscript, $opts{verbose}, 0777);
499 if ($versiononly) {
500     for (@scripts) {
501         (my $base = $_) =~ s#.*/##;
502         $base .= $ver;
503         copy($_,    "$installscript/$base");
504         chmod(0755, "$installscript/$base");
505     }
506
507     for (@tolink) {
508         my ($from, $to) = map { "$_$ver" } @$_;
509         (my $frbase = $from) =~ s#.*/##;
510         (my $tobase = $to) =~ s#.*/##;
511         script_alias($installscript, $frbase, $tobase, $scr_ext);
512     }
513 } else {
514     for (@scripts) {
515         (my $base = $_) =~ s#.*/##;
516         copy($_, "$installscript/$base");
517         chmod(0755, "$installscript/$base");
518     }
519
520     for (@tolink) {
521         my ($from, $to) = @$_;
522         (my $frbase = $from) =~ s#.*/##;
523         (my $tobase = $to) =~ s#.*/##;
524         script_alias($installscript, $frbase, $tobase, $scr_ext);
525     }
526 }
527
528 # Install pod pages.  Where? I guess in $installprivlib/pod
529 # ($installprivlib/pods for cygwin).
530 if (!$nopods && (!$versiononly || ($installprivlib =~ m/\Q$vershort/))) {
531     my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
532     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
533
534     for (map {$_->[1]} @{get_pod_metadata()->{master}}) {
535         # $_ is a name like  pod/perl.pod
536         (my $base = $_) =~ s#.*/##;
537         copy_if_diff($_, "${installprivlib}/$pod/${base}");
538         chmod(0644, "${installprivlib}/$pod/${base}");
539     }
540
541 }
542
543 # Check to make sure there aren't other perls around in installer's
544 # path.  This is probably UNIX-specific.  Check all absolute directories
545 # in the path except for where public executables are supposed to live.
546 # Also skip $mainperl if the user opted to have it be a link to the
547 # installed perl.
548
549 if (!$versiononly && !$skip_otherperls) {
550     my ($path, @path);
551     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
552     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
553     @path = split(/$dirsep/, $path);
554     if ($Is_VMS) {
555         my $i = 0;
556         while (exists $ENV{'DCL$PATH' . $i}) {
557             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
558             push(@path,$dir);
559         }
560     }
561     my @otherperls;
562     my %otherperls;
563     for (@path) {
564         next unless m,^/,;
565         # Use &samepath here because some systems have other dirs linked
566         # to $mainperldir (like SunOS)
567         next unless -d;
568         next if samepath($_, $binexp);
569         next if samepath($_, cwd());
570         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
571         my $otherperl = "$_/$perl$exe_ext";
572         next if $otherperls{$otherperl}++;
573         push(@otherperls, $otherperl)
574             if (-x $otherperl && ! -d $otherperl);
575     }
576     if (@otherperls) {
577         warn "\nWarning: $perl appears in your path in the following " .
578             "locations beyond where\nwe just installed it:\n";
579         for (@otherperls) {
580             warn "    ", $_, "\n";
581         }
582         warn "\n";
583     }
584
585 }
586
587 $packlist->write() unless $opts{notify};
588 print "  Installation complete\n" if $opts{verbose};
589
590 exit 0;
591
592 ###############################################################################
593
594 # If these are needed elsewhere, move them into install_lib.pl rather than
595 # copying them.
596
597 sub yn {
598     my($prompt) = @_;
599     my($answer);
600     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
601     print STDERR $prompt;
602     chop($answer = <STDIN>);
603     $answer = $default if $answer =~ m/^\s*$/;
604     ($answer =~ m/^[yY]/);
605 }
606
607 sub safe_unlink {
608     return if $opts{notify} or $Is_VMS;
609     my @names = @_;
610     foreach my $name (@names) {
611         next unless -e $name;
612         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
613         print "  unlink $name\n" if $opts{verbose};
614         next if CORE::unlink($name);
615         warn "Couldn't unlink $name: $!\n";
616         if ($! =~ /busy/i) {
617             print "  mv $name $name.old\n" if $opts{verbose};
618             safe_rename($name, "$name.old")
619                 or warn "Couldn't rename $name: $!\n";
620         }
621     }
622 }
623
624 sub safe_rename {
625     my($from,$to) = @_;
626     if (-f $to and not unlink($to)) {
627         my($i);
628         for ($i = 1; $i < 50; $i++) {
629             last if rename($to, "$to.$i");
630         }
631         warn("Cannot rename to '$to.$i': $!"), return 0
632            if $i >= 50; # Give up!
633     }
634     link($from,$to) || return 0;
635     unlink($from);
636 }
637
638 sub copy {
639     my($from,$to) = @_;
640
641     my $xto = $to;
642     $xto =~ s/^\Q$opts{destdir}\E//;
643     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
644         unless $opts{silent};
645     print "  creating new version of $xto\n"
646         if $Is_VMS and -e $to and !$opts{silent};
647     unless ($opts{notify} or File::Copy::copy($from, $to)) {
648         # Might have been that F::C::c can't overwrite the target
649         warn "Couldn't copy $from to $to: $!\n"
650             unless -f $to and (chmod(0666, $to), unlink $to)
651                    and File::Copy::copy($from, $to);
652     }
653     $packlist->{$xto} = { type => 'file' };
654 }
655
656 sub installlib {
657     my $dir = $File::Find::dir;
658     $dir =~ s!\Alib/?!!;
659
660     m!([^/]+)\z!;
661     my $name = $1;
662
663     # This remains ugly, and in need of refactoring.
664
665     # $name always starts as the leafname
666     # $dir is the directory *within* lib
667     # $name later has $dir pre-pended, to give the relative path in lib/
668     # which is used to create the path in the target directory.
669
670     # $_ was always the filename to use on disk. Adding no_chdir doesn't change
671     # this, as $_ becomes a pathname, and so still works. However, it's not
672     # obvious that $_ is needed later, and hence $_ must not be modified.
673
674     # Also, many of the regex exclusion tests below are now superfluous, as the
675     # files in question are either no longer in blead, or now in ext/, dist/ or
676     # cpan/ and not copied into lib/
677
678     # Ignore version control directories.
679     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
680         $File::Find::prune = 1;
681         return;
682     }
683
684     # ignore patch backups, RCS files, emacs backup & temp files and the
685     # .exists files, .PL files, and test files.
686     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util\.pl$|^filter-util\.pl$|^uupacktool\.pl$|^\.gitignore$} ||
687               $dir  =~ m{/t(?:/|$)};
688     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
689     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
690     # the corelist script from lib/Module/CoreList/bin and ptar* in
691     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
692     # and zipdetails in cpan/IO-Compress/bin
693     # (they're installed later with other utils)
694     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|ptardiff|ptargrep|config_data|zipdetails)\z/;
695     # ignore the Makefiles
696     return if $name =~ /^makefile$/i;
697     # ignore the test extensions
698     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
699     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
700     # ignore the build support code
701     return if $name =~ /\bbuildcustomize\.pl$/;
702     # ignore the demo files
703     return if $dir =~ /\b(?:demos?|eg)\b/;
704     # ignore unneeded unicore files
705     if ( $dir =~ /^unicore/ ) {
706       if ( $name =~ /\.txt\z/ ) {
707         # We can ignore most, but not all .txt files
708         return unless $name =~ /\A(?:Blocks|SpecialCasing|NamedSequences)\.txt\z/;
709       }
710       else {
711         # TestProp only needed during testing
712         return if $name =~ /\ATestProp.pl\z/;
713         # we need version and *.pl files and can skip the rest
714         return unless $name =~ /\A(?:version|\w+\.p[lm])\z/;
715       }
716     }
717
718     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
719     # Changes.e2x and README.e2x are needed by enc2xs.
720     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
721     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
722     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
723     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
724     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
725     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
726
727     # if using a shared perl library then ignore:
728     # - static library files [of statically linked extensions];
729     # - import library files and export library files (only present on Win32
730     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
731     return if $Config{useshrplib} eq 'true' and
732              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
733
734     $name = "$dir/$name" if $dir ne '';
735
736     # ignore pods that are stand alone documentation from dual life modules.
737     return if /\.pod\z/ && is_duplicate_pod($_);
738
739     return if $name eq 'ExtUtils/XSSymSet.pm' and !$Is_VMS;
740
741     my $installlib = $installprivlib;
742     if ($dir =~ /^auto\// ||
743           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
744           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
745           $name=~/^Config_(heavy|git)\.pl\z/
746        ) {
747         $installlib = $installarchlib;
748         return unless $do_installarchlib;
749     } else {
750         return unless $do_installprivlib;
751     }
752
753     if ($Is_NetWare && !$nwinstall && /\.(?:nlp|nlm|bs)$/) {
754         # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
755         # if copied will give problems when building new extensions.
756         # Has to be copied if we are installing on a NetWare server and
757         # hence the check !$nwinstall
758         return;
759     }
760
761     if (-f $_) {
762         my $xname = "$installlib/$name";
763         $xname =~ s/^\Q$opts{destdir}\E//;
764         $packlist->{$xname} = { type => 'file' };
765         if ($force || compare($_, "$installlib/$name") || $opts{notify}) {
766             unlink("$installlib/$name");
767             mkpath("$installlib/$dir", $opts{verbose}, 0777);
768             # HP-UX (at least) needs to maintain execute permissions
769             # on dynamically-loaded libraries.
770             if (copy_if_diff($_, "$installlib/$name")) {
771                 strip("-S", "$installlib/$name")
772                     if $^O eq 'darwin' and /\.(?:so|$dlext|a)$/;
773                 chmod(/\.(so|$dlext)$/ ? 0555 : 0444, "$installlib/$name");
774             }
775         }
776     }
777 }
778
779 # Copy $from to $to, only if $from is different than $to.
780 # Also preserve modification times for .a libraries.
781 # On some systems, if you do
782 #   ranlib libperl.a
783 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
784 # and then try to link against the installed libperl.a, you might
785 # get an error message to the effect that the symbol table is older
786 # than the library.
787 # Return true if copying occurred.
788
789 sub copy_if_diff {
790     my($from,$to)=@_;
791     return 1 if (($^O eq 'VMS') && (-d $from));
792     my $xto = $to;
793     $xto =~ s/^\Q$opts{destdir}\E//;
794     my $perlpodbadsymlink;
795     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
796         -l $from &&
797         ! -e $from) {
798         # Some Linux implementations have problems traversing over
799         # multiple symlinks (when going over NFS?) and fail to read
800         # the symlink target.  Combine this with the fact that some
801         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
802         # and you end up with those pods not getting installed.
803         $perlpodbadsymlink = 1;
804     }
805     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
806     $packlist->{$xto} = { type => 'file' };
807     if ($force || compare($from, $to) || $opts{notify}) {
808         safe_unlink($to);   # In case we don't have write permissions.
809         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
810             $from = "README.$1";
811         }
812         copy($from, $to);
813         # Restore timestamps if it's a .a library or for OS/2.
814         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
815             my ($atime, $mtime) = (stat $from)[8,9];
816             utime $atime, $mtime, $to;
817         }
818         1;
819     }
820 }
821
822 sub strip
823 {
824     my(@args) = @_;
825
826     return unless $dostrip;
827
828     my @opts;
829     while (@args && $args[0] =~ /^(-\w+)$/) {
830         push @opts, shift @args;
831     }
832
833     foreach my $file (@args) {
834         if (-f $file) {
835             if ($opts{verbose}) {
836                 print "  strip " . join(' ', @opts);
837                 print " " if (@opts);
838                 print "$file\n";
839             }
840             system("strip", @opts, $file);
841         } else {
842             print "# file '$file' skipped\n" if $opts{verbose};
843         }
844     }
845 }
846
847 # Local variables:
848 # cperl-indent-level: 4
849 # indent-tabs-mode: nil
850 # End:
851 #
852 # ex: set ts=8 sts=4 sw=4 et: