This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Deparse typed vars
[perl5.git] / lib / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
18          OPpSORT_REVERSE
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          SVpad_TYPED
21          CVf_METHOD CVf_LVALUE
22          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
23          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
24 $VERSION = '1.27';
25 use strict;
26 use vars qw/$AUTOLOAD/;
27 use warnings ();
28 require feature;
29
30 BEGIN {
31     # List version-specific constants here.
32     # Easiest way to keep this code portable between version looks to
33     # be to fake up a dummy constant that will never actually be true.
34     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
35                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
36                 RXf_PMf_CHARSET RXf_PMf_KEEPCOPY
37                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
38                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES)) {
39         eval { import B $_ };
40         no strict 'refs';
41         *{$_} = sub () {0} unless *{$_}{CODE};
42     }
43 }
44
45 # Changes between 0.50 and 0.51:
46 # - fixed nulled leave with live enter in sort { }
47 # - fixed reference constants (\"str")
48 # - handle empty programs gracefully
49 # - handle infinite loops (for (;;) {}, while (1) {})
50 # - differentiate between 'for my $x ...' and 'my $x; for $x ...'
51 # - various minor cleanups
52 # - moved globals into an object
53 # - added '-u', like B::C
54 # - package declarations using cop_stash
55 # - subs, formats and code sorted by cop_seq
56 # Changes between 0.51 and 0.52:
57 # - added pp_threadsv (special variables under USE_5005THREADS)
58 # - added documentation
59 # Changes between 0.52 and 0.53:
60 # - many changes adding precedence contexts and associativity
61 # - added '-p' and '-s' output style options
62 # - various other minor fixes
63 # Changes between 0.53 and 0.54:
64 # - added support for new 'for (1..100)' optimization,
65 #   thanks to Gisle Aas
66 # Changes between 0.54 and 0.55:
67 # - added support for new qr// construct
68 # - added support for new pp_regcreset OP
69 # Changes between 0.55 and 0.56:
70 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
71 # - fixed $# on non-lexicals broken in last big rewrite
72 # - added temporary fix for change in opcode of OP_STRINGIFY
73 # - fixed problem in 0.54's for() patch in 'for (@ary)'
74 # - fixed precedence in conditional of ?:
75 # - tweaked list paren elimination in 'my($x) = @_'
76 # - made continue-block detection trickier wrt. null ops
77 # - fixed various prototype problems in pp_entersub
78 # - added support for sub prototypes that never get GVs
79 # - added unquoting for special filehandle first arg in truncate
80 # - print doubled rv2gv (a bug) as '*{*GV}' instead of illegal '**GV'
81 # - added semicolons at the ends of blocks
82 # - added -l '#line' declaration option -- fixes cmd/subval.t 27,28
83 # Changes between 0.56 and 0.561:
84 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
85 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
86 # Changes between 0.561 and 0.57:
87 # - stylistic changes to symbolic constant stuff
88 # - handled scope in s///e replacement code
89 # - added unquote option for expanding "" into concats, etc.
90 # - split method and proto parts of pp_entersub into separate functions
91 # - various minor cleanups
92 # Changes after 0.57:
93 # - added parens in \&foo (patch by Albert Dvornik)
94 # Changes between 0.57 and 0.58:
95 # - fixed '0' statements that weren't being printed
96 # - added methods for use from other programs
97 #   (based on patches from James Duncan and Hugo van der Sanden)
98 # - added -si and -sT to control indenting (also based on a patch from Hugo)
99 # - added -sv to print something else instead of '???'
100 # - preliminary version of utf8 tr/// handling
101 # Changes after 0.58:
102 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
103 # - added support for Hugo's new OP_SETSTATE (like nextstate)
104 # Changes between 0.58 and 0.59
105 # - added support for Chip's OP_METHOD_NAMED
106 # - added support for Ilya's OPpTARGET_MY optimization
107 # - elided arrows before '()' subscripts when possible
108 # Changes between 0.59 and 0.60
109 # - support for method attributes was added
110 # - some warnings fixed
111 # - separate recognition of constant subs
112 # - rewrote continue block handling, now recognizing for loops
113 # - added more control of expanding control structures
114 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
115 # - many bug-fixes
116 # - support for pragmas and 'use'
117 # - support for the little-used $[ variable
118 # - support for __DATA__ sections
119 # - UTF8 support
120 # - BEGIN, CHECK, INIT and END blocks
121 # - scoping of subroutine declarations fixed
122 # - compile-time output from the input program can be suppressed, so that the
123 #   output is just the deparsed code. (a change to O.pm in fact)
124 # - our() declarations
125 # - *all* the known bugs are now listed in the BUGS section
126 # - comprehensive test mechanism (TEST -deparse)
127 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
128 # - bug-fixes
129 # - new switch -P
130 # - support for command-line switches (-l, -0, etc.)
131 # Changes between 0.63 and 0.64
132 # - support for //, CHECK blocks, and assertions
133 # - improved handling of foreach loops and lexicals
134 # - option to use Data::Dumper for constants
135 # - more bug fixes
136 # - discovered lots more bugs not yet fixed
137 #
138 # ...
139 #
140 # Changes between 0.72 and 0.73
141 # - support new switch constructs
142
143 # Todo:
144 #  (See also BUGS section at the end of this file)
145 #
146 # - finish tr/// changes
147 # - add option for even more parens (generalize \&foo change)
148 # - left/right context
149 # - copy comments (look at real text with $^P?)
150 # - avoid semis in one-statement blocks
151 # - associativity of &&=, ||=, ?:
152 # - ',' => '=>' (auto-unquote?)
153 # - break long lines ("\r" as discretionary break?)
154 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
155 # - more style options: brace style, hex vs. octal, quotes, ...
156 # - print big ints as hex/octal instead of decimal (heuristic?)
157 # - handle 'my $x if 0'?
158 # - version using op_next instead of op_first/sibling?
159 # - avoid string copies (pass arrays, one big join?)
160 # - here-docs?
161
162 # Current test.deparse failures
163 # comp/hints 6 - location of BEGIN blocks wrt. block openings
164 # run/switchI 1 - missing -I switches entirely
165 #    perl -Ifoo -e 'print @INC'
166 # op/caller 2 - warning mask propagates backwards before warnings::register
167 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
168 # op/getpid 2 - can't assign to shared my() declaration (threads only)
169 #    'my $x : shared = 5'
170 # op/override 7 - parens on overridden require change v-string interpretation
171 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
172 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
173 # op/pat 774 - losing Unicode-ness of Latin1-only strings
174 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
175 # op/recurse 12 - missing parens on recursive call makes it look like method
176 #    'sub f { f($x) }'
177 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
178 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
179 # op/tiehandle compile - "use strict" deparsed in the wrong place
180 # uni/tr_ several
181 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
182 # ext/Data/Dumper/t/dumper compile
183 # ext/DB_file/several
184 # ext/Encode/several
185 # ext/Ernno/Errno warnings
186 # ext/IO/lib/IO/t/io_sel 23
187 # ext/PerlIO/t/encoding compile
188 # ext/POSIX/t/posix 6
189 # ext/Socket/Socket 8
190 # ext/Storable/t/croak compile
191 # lib/Attribute/Handlers/t/multi compile
192 # lib/bignum/ several
193 # lib/charnames 35
194 # lib/constant 32
195 # lib/English 40
196 # lib/ExtUtils/t/bytes 4
197 # lib/File/DosGlob compile
198 # lib/Filter/Simple/t/data 1
199 # lib/Math/BigInt/t/constant 1
200 # lib/Net/t/config Deparse-warning
201 # lib/overload compile
202 # lib/Switch/ several
203 # lib/Symbol 4
204 # lib/Test/Simple several
205 # lib/Term/Complete
206 # lib/Tie/File/t/29_downcopy 5
207 # lib/vars 22
208
209 # Object fields (were globals):
210 #
211 # avoid_local:
212 # (local($a), local($b)) and local($a, $b) have the same internal
213 # representation but the short form looks better. We notice we can
214 # use a large-scale local when checking the list, but need to prevent
215 # individual locals too. This hash holds the addresses of OPs that
216 # have already had their local-ness accounted for. The same thing
217 # is done with my().
218 #
219 # curcv:
220 # CV for current sub (or main program) being deparsed
221 #
222 # curcvlex:
223 # Cached hash of lexical variables for curcv: keys are
224 # names prefixed with "m" or "o" (representing my/our), and
225 # each value is an array with two elements indicating the cop_seq
226 # of scopes in which a var of that name is valid and a third ele-
227 # ment referencing the pad name.
228 #
229 # curcop:
230 # COP for statement being deparsed
231 #
232 # curstash:
233 # name of the current package for deparsed code
234 #
235 # subs_todo:
236 # array of [cop_seq, CV, is_format?] for subs and formats we still
237 # want to deparse
238 #
239 # protos_todo:
240 # as above, but [name, prototype] for subs that never got a GV
241 #
242 # subs_done, forms_done:
243 # keys are addresses of GVs for subs and formats we've already
244 # deparsed (or at least put into subs_todo)
245 #
246 # subs_declared
247 # keys are names of subs for which we've printed declarations.
248 # That means we can omit parentheses from the arguments. It also means we
249 # need to put CORE:: on core functions of the same name.
250 #
251 # subs_deparsed
252 # Keeps track of fully qualified names of all deparsed subs.
253 #
254 # in_subst_repl
255 # True when deparsing the replacement part of a substitution.
256 #
257 # parens: -p
258 # linenums: -l
259 # unquote: -q
260 # cuddle: ' ' or '\n', depending on -sC
261 # indent_size: -si
262 # use_tabs: -sT
263 # ex_const: -sv
264
265 # A little explanation of how precedence contexts and associativity
266 # work:
267 #
268 # deparse() calls each per-op subroutine with an argument $cx (short
269 # for context, but not the same as the cx* in the perl core), which is
270 # a number describing the op's parents in terms of precedence, whether
271 # they're inside an expression or at statement level, etc.  (see
272 # chart below). When ops with children call deparse on them, they pass
273 # along their precedence. Fractional values are used to implement
274 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
275 # parentheses hacks. The major disadvantage of this scheme is that
276 # it doesn't know about right sides and left sides, so say if you
277 # assign a listop to a variable, it can't tell it's allowed to leave
278 # the parens off the listop.
279
280 # Precedences:
281 # 26             [TODO] inside interpolation context ("")
282 # 25 left        terms and list operators (leftward)
283 # 24 left        ->
284 # 23 nonassoc    ++ --
285 # 22 right       **
286 # 21 right       ! ~ \ and unary + and -
287 # 20 left        =~ !~
288 # 19 left        * / % x
289 # 18 left        + - .
290 # 17 left        << >>
291 # 16 nonassoc    named unary operators
292 # 15 nonassoc    < > <= >= lt gt le ge
293 # 14 nonassoc    == != <=> eq ne cmp
294 # 13 left        &
295 # 12 left        | ^
296 # 11 left        &&
297 # 10 left        ||
298 #  9 nonassoc    ..  ...
299 #  8 right       ?:
300 #  7 right       = += -= *= etc.
301 #  6 left        , =>
302 #  5 nonassoc    list operators (rightward)
303 #  4 right       not
304 #  3 left        and
305 #  2 left        or xor
306 #  1             statement modifiers
307 #  0.5           statements, but still print scopes as do { ... }
308 #  0             statement level
309 # -1             format body
310
311 # Nonprinting characters with special meaning:
312 # \cS - steal parens (see maybe_parens_unop)
313 # \n - newline and indent
314 # \t - increase indent
315 # \b - decrease indent ('outdent')
316 # \f - flush left (no indent)
317 # \cK - kill following semicolon, if any
318
319
320
321 BEGIN { for (qw[ const stringify rv2sv list glob pushmark null]) {
322     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
323 }}
324
325 # _pessimise_walk(): recursively walk the optree of a sub,
326 # possibly undoing optimisations along the way.
327
328 sub _pessimise_walk {
329     my ($self, $startop) = @_;
330
331     return unless $$startop;
332     my ($op, $prevop);
333     for ($op = $startop; $$op; $prevop = $op, $op = $op->sibling) {
334         my $ppname = $op->name;
335
336         # pessimisations start here
337
338         if ($ppname eq "padrange") {
339             # remove PADRANGE:
340             # the original optimisation either (1) changed this:
341             #    pushmark -> (various pad and list and null ops) -> the_rest
342             # or (2), for the = @_ case, changed this:
343             #    pushmark -> gv[_] -> rv2av -> (pad stuff)       -> the_rest
344             # into this:
345             #    padrange ----------------------------------------> the_rest
346             # so we just need to convert the padrange back into a
347             # pushmark, and in case (1), set its op_next to op_sibling,
348             # which is the head of the original chain of optimised-away
349             # pad ops, or for (2), set it to sibling->first, which is
350             # the original gv[_].
351
352             $B::overlay->{$$op} = {
353                     type => OP_PUSHMARK,
354                     name => 'pushmark',
355                     private => ($op->private & OPpLVAL_INTRO),
356                     next    => ($op->flags & OPf_SPECIAL)
357                                     ? $op->sibling->first
358                                     : $op->sibling,
359             };
360         }
361
362         # pessimisations end here
363
364         if (class($op) eq 'PMOP'
365             && ref($op->pmreplroot)
366             && ${$op->pmreplroot}
367             && $op->pmreplroot->isa( 'B::OP' ))
368         {
369             $self-> _pessimise_walk($op->pmreplroot);
370         }
371
372         if ($op->flags & OPf_KIDS) {
373             $self-> _pessimise_walk($op->first);
374         }
375
376     }
377 }
378
379
380 # _pessimise_walk_exe(): recursively walk the op_next chain of a sub,
381 # possibly undoing optimisations along the way.
382
383 sub _pessimise_walk_exe {
384     my ($self, $startop, $visited) = @_;
385
386     return unless $$startop;
387     return if $visited->{$$startop};
388     my ($op, $prevop);
389     for ($op = $startop; $$op; $prevop = $op, $op = $op->next) {
390         last if $visited->{$$op};
391         $visited->{$$op} = 1;
392         my $ppname = $op->name;
393         if ($ppname =~
394             /^((and|d?or)(assign)?|(map|grep)while|range|cond_expr|once)$/
395             # entertry is also a logop, but its op_other invariably points
396             # into the same chain as the main execution path, so we skip it
397         ) {
398             $self->_pessimise_walk_exe($op->other, $visited);
399         }
400         elsif ($ppname eq "subst") {
401             $self->_pessimise_walk_exe($op->pmreplstart, $visited);
402         }
403         elsif ($ppname =~ /^(enter(loop|iter))$/) {
404             # redoop and nextop will already be covered by the main block
405             # of the loop
406             $self->_pessimise_walk_exe($op->lastop, $visited);
407         }
408
409         # pessimisations start here
410     }
411 }
412
413 # Go through an optree and "remove" some optimisations by using an
414 # overlay to selectively modify or un-null some ops. Deparsing in the
415 # absence of those optimisations is then easier.
416 #
417 # Note that older optimisations are not removed, as Deparse was already
418 # written to recognise them before the pessimise/overlay system was added.
419
420 sub pessimise {
421     my ($self, $root, $start) = @_;
422
423     # walk tree in root-to-branch order
424     $self->_pessimise_walk($root);
425
426     my %visited;
427     # walk tree in execution order
428     $self->_pessimise_walk_exe($start, \%visited);
429 }
430
431
432 sub null {
433     my $op = shift;
434     return class($op) eq "NULL";
435 }
436
437 sub todo {
438     my $self = shift;
439     my($cv, $is_form) = @_;
440     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
441     my $seq;
442     if ($cv->OUTSIDE_SEQ) {
443         $seq = $cv->OUTSIDE_SEQ;
444     } elsif (!null($cv->START) and is_state($cv->START)) {
445         $seq = $cv->START->cop_seq;
446     } else {
447         $seq = 0;
448     }
449     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
450     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
451         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
452     }
453 }
454
455 sub next_todo {
456     my $self = shift;
457     my $ent = shift @{$self->{'subs_todo'}};
458     my $cv = $ent->[1];
459     my $gv = $cv->GV;
460     my $name = $self->gv_name($gv);
461     if ($ent->[2]) {
462         return "format $name =\n"
463             . $self->deparse_format($ent->[1]). "\n";
464     } else {
465         $self->{'subs_declared'}{$name} = 1;
466         if ($name eq "BEGIN") {
467             my $use_dec = $self->begin_is_use($cv);
468             if (defined ($use_dec) and $self->{'expand'} < 5) {
469                 return () if 0 == length($use_dec);
470                 return $use_dec;
471             }
472         }
473         my $l = '';
474         if ($self->{'linenums'}) {
475             my $line = $gv->LINE;
476             my $file = $gv->FILE;
477             $l = "\n\f#line $line \"$file\"\n";
478         }
479         my $p = '';
480         if (class($cv->STASH) ne "SPECIAL") {
481             my $stash = $cv->STASH->NAME;
482             if ($stash ne $self->{'curstash'}) {
483                 $p = "package $stash;\n";
484                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
485                 $self->{'curstash'} = $stash;
486             }
487             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
488         }
489         return "${p}${l}sub $name " . $self->deparse_sub($cv);
490     }
491 }
492
493 # Return a "use" declaration for this BEGIN block, if appropriate
494 sub begin_is_use {
495     my ($self, $cv) = @_;
496     my $root = $cv->ROOT;
497     local @$self{qw'curcv curcvlex'} = ($cv);
498     local $B::overlay = {};
499     $self->pessimise($root, $cv->START);
500 #require B::Debug;
501 #B::walkoptree($cv->ROOT, "debug");
502     my $lineseq = $root->first;
503     return if $lineseq->name ne "lineseq";
504
505     my $req_op = $lineseq->first->sibling;
506     return if $req_op->name ne "require";
507
508     my $module;
509     if ($req_op->first->private & OPpCONST_BARE) {
510         # Actually it should always be a bareword
511         $module = $self->const_sv($req_op->first)->PV;
512         $module =~ s[/][::]g;
513         $module =~ s/.pm$//;
514     }
515     else {
516         $module = $self->const($self->const_sv($req_op->first), 6);
517     }
518
519     my $version;
520     my $version_op = $req_op->sibling;
521     return if class($version_op) eq "NULL";
522     if ($version_op->name eq "lineseq") {
523         # We have a version parameter; skip nextstate & pushmark
524         my $constop = $version_op->first->next->next;
525
526         return unless $self->const_sv($constop)->PV eq $module;
527         $constop = $constop->sibling;
528         $version = $self->const_sv($constop);
529         if (class($version) eq "IV") {
530             $version = $version->int_value;
531         } elsif (class($version) eq "NV") {
532             $version = $version->NV;
533         } elsif (class($version) ne "PVMG") {
534             # Includes PVIV and PVNV
535             $version = $version->PV;
536         } else {
537             # version specified as a v-string
538             $version = 'v'.join '.', map ord, split //, $version->PV;
539         }
540         $constop = $constop->sibling;
541         return if $constop->name ne "method_named";
542         return if $self->const_sv($constop)->PV ne "VERSION";
543     }
544
545     $lineseq = $version_op->sibling;
546     return if $lineseq->name ne "lineseq";
547     my $entersub = $lineseq->first->sibling;
548     if ($entersub->name eq "stub") {
549         return "use $module $version ();\n" if defined $version;
550         return "use $module ();\n";
551     }
552     return if $entersub->name ne "entersub";
553
554     # See if there are import arguments
555     my $args = '';
556
557     my $svop = $entersub->first->sibling; # Skip over pushmark
558     return unless $self->const_sv($svop)->PV eq $module;
559
560     # Pull out the arguments
561     for ($svop=$svop->sibling; $svop->name ne "method_named";
562                 $svop = $svop->sibling) {
563         $args .= ", " if length($args);
564         $args .= $self->deparse($svop, 6);
565     }
566
567     my $use = 'use';
568     my $method_named = $svop;
569     return if $method_named->name ne "method_named";
570     my $method_name = $self->const_sv($method_named)->PV;
571
572     if ($method_name eq "unimport") {
573         $use = 'no';
574     }
575
576     # Certain pragmas are dealt with using hint bits,
577     # so we ignore them here
578     if ($module eq 'strict' || $module eq 'integer'
579         || $module eq 'bytes' || $module eq 'warnings'
580         || $module eq 'feature') {
581         return "";
582     }
583
584     if (defined $version && length $args) {
585         return "$use $module $version ($args);\n";
586     } elsif (defined $version) {
587         return "$use $module $version;\n";
588     } elsif (length $args) {
589         return "$use $module ($args);\n";
590     } else {
591         return "$use $module;\n";
592     }
593 }
594
595 sub stash_subs {
596     my ($self, $pack, $seen) = @_;
597     my (@ret, $stash);
598     if (!defined $pack) {
599         $pack = '';
600         $stash = \%::;
601     }
602     else {
603         $pack =~ s/(::)?$/::/;
604         no strict 'refs';
605         $stash = \%{"main::$pack"};
606     }
607     return
608         if ($seen ||= {})->{
609             $INC{"overload.pm"} ? overload::StrVal($stash) : $stash
610            }++;
611     my %stash = svref_2object($stash)->ARRAY;
612     while (my ($key, $val) = each %stash) {
613         my $class = class($val);
614         if ($class eq "PV") {
615             # Just a prototype. As an ugly but fairly effective way
616             # to find out if it belongs here is to see if the AUTOLOAD
617             # (if any) for the stash was defined in one of our files.
618             my $A = $stash{"AUTOLOAD"};
619             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
620                 && class($A->CV) eq "CV") {
621                 my $AF = $A->FILE;
622                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
623             }
624             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
625         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
626             # Just a name. As above.
627             # But skip proxy constant subroutines, as some form of perl-space
628             # visible code must have created them, be it a use statement, or
629             # some direct symbol-table manipulation code that we will Deparse
630             my $A = $stash{"AUTOLOAD"};
631             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
632                 && class($A->CV) eq "CV") {
633                 my $AF = $A->FILE;
634                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
635             }
636             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
637         } elsif ($class eq "GV") {
638             if (class(my $cv = $val->CV) ne "SPECIAL") {
639                 next if $self->{'subs_done'}{$$val}++;
640                 next if $$val != ${$cv->GV};   # Ignore imposters
641                 $self->todo($cv, 0);
642             }
643             if (class(my $cv = $val->FORM) ne "SPECIAL") {
644                 next if $self->{'forms_done'}{$$val}++;
645                 next if $$val != ${$cv->GV};   # Ignore imposters
646                 $self->todo($cv, 1);
647             }
648             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
649                 $self->stash_subs($pack . $key, $seen);
650             }
651         }
652     }
653 }
654
655 sub print_protos {
656     my $self = shift;
657     my $ar;
658     my @ret;
659     foreach $ar (@{$self->{'protos_todo'}}) {
660         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
661         push @ret, "sub " . $ar->[0] .  "$proto;\n";
662     }
663     delete $self->{'protos_todo'};
664     return @ret;
665 }
666
667 sub style_opts {
668     my $self = shift;
669     my $opts = shift;
670     my $opt;
671     while (length($opt = substr($opts, 0, 1))) {
672         if ($opt eq "C") {
673             $self->{'cuddle'} = " ";
674             $opts = substr($opts, 1);
675         } elsif ($opt eq "i") {
676             $opts =~ s/^i(\d+)//;
677             $self->{'indent_size'} = $1;
678         } elsif ($opt eq "T") {
679             $self->{'use_tabs'} = 1;
680             $opts = substr($opts, 1);
681         } elsif ($opt eq "v") {
682             $opts =~ s/^v([^.]*)(.|$)//;
683             $self->{'ex_const'} = $1;
684         }
685     }
686 }
687
688 sub new {
689     my $class = shift;
690     my $self = bless {}, $class;
691     $self->{'cuddle'} = "\n";
692     $self->{'curcop'} = undef;
693     $self->{'curstash'} = "main";
694     $self->{'ex_const'} = "'???'";
695     $self->{'expand'} = 0;
696     $self->{'files'} = {};
697     $self->{'indent_size'} = 4;
698     $self->{'linenums'} = 0;
699     $self->{'parens'} = 0;
700     $self->{'subs_todo'} = [];
701     $self->{'unquote'} = 0;
702     $self->{'use_dumper'} = 0;
703     $self->{'use_tabs'} = 0;
704
705     $self->{'ambient_arybase'} = 0;
706     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
707     $self->{'ambient_hints'} = 0;
708     $self->{'ambient_hinthash'} = undef;
709     $self->init();
710
711     while (my $arg = shift @_) {
712         if ($arg eq "-d") {
713             $self->{'use_dumper'} = 1;
714             require Data::Dumper;
715         } elsif ($arg =~ /^-f(.*)/) {
716             $self->{'files'}{$1} = 1;
717         } elsif ($arg eq "-l") {
718             $self->{'linenums'} = 1;
719         } elsif ($arg eq "-p") {
720             $self->{'parens'} = 1;
721         } elsif ($arg eq "-P") {
722             $self->{'noproto'} = 1;
723         } elsif ($arg eq "-q") {
724             $self->{'unquote'} = 1;
725         } elsif (substr($arg, 0, 2) eq "-s") {
726             $self->style_opts(substr $arg, 2);
727         } elsif ($arg =~ /^-x(\d)$/) {
728             $self->{'expand'} = $1;
729         }
730     }
731     return $self;
732 }
733
734 {
735     # Mask out the bits that L<warnings::register> uses
736     my $WARN_MASK;
737     BEGIN {
738         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
739     }
740     sub WARN_MASK () {
741         return $WARN_MASK;
742     }
743 }
744
745 # Initialise the contextual information, either from
746 # defaults provided with the ambient_pragmas method,
747 # or from perl's own defaults otherwise.
748 sub init {
749     my $self = shift;
750
751     $self->{'arybase'}  = $self->{'ambient_arybase'};
752     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
753                                 ? $self->{'ambient_warnings'} & WARN_MASK
754                                 : undef;
755     $self->{'hints'}    = $self->{'ambient_hints'};
756     $self->{'hints'} &= 0xFF if $] < 5.009;
757     $self->{'hinthash'} = $self->{'ambient_hinthash'};
758
759     # also a convenient place to clear out subs_declared
760     delete $self->{'subs_declared'};
761 }
762
763 sub compile {
764     my(@args) = @_;
765     return sub {
766         my $self = B::Deparse->new(@args);
767         # First deparse command-line args
768         if (defined $^I) { # deparse -i
769             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
770         }
771         if ($^W) { # deparse -w
772             print qq(BEGIN { \$^W = $^W; }\n);
773         }
774         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
775             my $fs = perlstring($/) || 'undef';
776             my $bs = perlstring($O::savebackslash) || 'undef';
777             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
778         }
779         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
780         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
781             ? B::unitcheck_av->ARRAY
782             : ();
783         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
784         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
785         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
786         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
787             $self->todo($block, 0);
788         }
789         $self->stash_subs();
790         local($SIG{"__DIE__"}) =
791           sub {
792               if ($self->{'curcop'}) {
793                   my $cop = $self->{'curcop'};
794                   my($line, $file) = ($cop->line, $cop->file);
795                   print STDERR "While deparsing $file near line $line,\n";
796               }
797             };
798         $self->{'curcv'} = main_cv;
799         $self->{'curcvlex'} = undef;
800         print $self->print_protos;
801         @{$self->{'subs_todo'}} =
802           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
803         my $root = main_root;
804         local $B::overlay = {};
805         unless (null $root) {
806             $self->pessimise($root, main_start);
807             print $self->indent($self->deparse_root($root)), "\n";
808         }
809         my @text;
810         while (scalar(@{$self->{'subs_todo'}})) {
811             push @text, $self->next_todo;
812         }
813         print $self->indent(join("", @text)), "\n" if @text;
814
815         # Print __DATA__ section, if necessary
816         no strict 'refs';
817         my $laststash = defined $self->{'curcop'}
818             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
819         if (defined *{$laststash."::DATA"}{IO}) {
820             print "package $laststash;\n"
821                 unless $laststash eq $self->{'curstash'};
822             print "__DATA__\n";
823             print readline(*{$laststash."::DATA"});
824         }
825     }
826 }
827
828 sub coderef2text {
829     my $self = shift;
830     my $sub = shift;
831     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
832
833     $self->init();
834     return $self->indent($self->deparse_sub(svref_2object($sub)));
835 }
836
837 my %strict_bits = do {
838     local $^H;
839     map +($_ => strict::bits($_)), qw/refs subs vars/
840 };
841
842 sub ambient_pragmas {
843     my $self = shift;
844     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
845
846     while (@_ > 1) {
847         my $name = shift();
848         my $val  = shift();
849
850         if ($name eq 'strict') {
851             require strict;
852
853             if ($val eq 'none') {
854                 $hint_bits &= $strict_bits{$_} for qw/refs subs vars/;
855                 next();
856             }
857
858             my @names;
859             if ($val eq "all") {
860                 @names = qw/refs subs vars/;
861             }
862             elsif (ref $val) {
863                 @names = @$val;
864             }
865             else {
866                 @names = split' ', $val;
867             }
868             $hint_bits |= $strict_bits{$_} for @names;
869         }
870
871         elsif ($name eq '$[') {
872             if (OPpCONST_ARYBASE) {
873                 $arybase = $val;
874             } else {
875                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
876             }
877         }
878
879         elsif ($name eq 'integer'
880             || $name eq 'bytes'
881             || $name eq 'utf8') {
882             require "$name.pm";
883             if ($val) {
884                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
885             }
886             else {
887                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
888             }
889         }
890
891         elsif ($name eq 're') {
892             require re;
893             if ($val eq 'none') {
894                 $hint_bits &= ~re::bits(qw/taint eval/);
895                 next();
896             }
897
898             my @names;
899             if ($val eq 'all') {
900                 @names = qw/taint eval/;
901             }
902             elsif (ref $val) {
903                 @names = @$val;
904             }
905             else {
906                 @names = split' ',$val;
907             }
908             $hint_bits |= re::bits(@names);
909         }
910
911         elsif ($name eq 'warnings') {
912             if ($val eq 'none') {
913                 $warning_bits = $warnings::NONE;
914                 next();
915             }
916
917             my @names;
918             if (ref $val) {
919                 @names = @$val;
920             }
921             else {
922                 @names = split/\s+/, $val;
923             }
924
925             $warning_bits = $warnings::NONE if !defined ($warning_bits);
926             $warning_bits |= warnings::bits(@names);
927         }
928
929         elsif ($name eq 'warning_bits') {
930             $warning_bits = $val;
931         }
932
933         elsif ($name eq 'hint_bits') {
934             $hint_bits = $val;
935         }
936
937         elsif ($name eq '%^H') {
938             $hinthash = $val;
939         }
940
941         else {
942             croak "Unknown pragma type: $name";
943         }
944     }
945     if (@_) {
946         croak "The ambient_pragmas method expects an even number of args";
947     }
948
949     $self->{'ambient_arybase'} = $arybase;
950     $self->{'ambient_warnings'} = $warning_bits;
951     $self->{'ambient_hints'} = $hint_bits;
952     $self->{'ambient_hinthash'} = $hinthash;
953 }
954
955 # This method is the inner loop, so try to keep it simple
956 sub deparse {
957     my $self = shift;
958     my($op, $cx) = @_;
959
960     Carp::confess("Null op in deparse") if !defined($op)
961                                         || class($op) eq "NULL";
962     my $meth = "pp_" . $op->name;
963     return $self->$meth($op, $cx);
964 }
965
966 sub indent {
967     my $self = shift;
968     my $txt = shift;
969     my @lines = split(/\n/, $txt);
970     my $leader = "";
971     my $level = 0;
972     my $line;
973     for $line (@lines) {
974         my $cmd = substr($line, 0, 1);
975         if ($cmd eq "\t" or $cmd eq "\b") {
976             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
977             if ($self->{'use_tabs'}) {
978                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
979             } else {
980                 $leader = " " x $level;
981             }
982             $line = substr($line, 1);
983         }
984         if (index($line, "\f") > 0) {
985                 $line =~ s/\f/\n/;
986         }
987         if (substr($line, 0, 1) eq "\f") {
988             $line = substr($line, 1); # no indent
989         } else {
990             $line = $leader . $line;
991         }
992         $line =~ s/\cK;?//g;
993     }
994     return join("\n", @lines);
995 }
996
997 sub deparse_sub {
998     my $self = shift;
999     my $cv = shift;
1000     my $proto = "";
1001 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
1002 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
1003     local $self->{'curcop'} = $self->{'curcop'};
1004     if ($cv->FLAGS & SVf_POK) {
1005         $proto = "(". $cv->PV . ") ";
1006     }
1007     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
1008         $proto .= ": ";
1009         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
1010         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
1011         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
1012     }
1013
1014     local($self->{'curcv'}) = $cv;
1015     local($self->{'curcvlex'});
1016     local(@$self{qw'curstash warnings hints hinthash'})
1017                 = @$self{qw'curstash warnings hints hinthash'};
1018     my $body;
1019     my $root = $cv->ROOT;
1020     local $B::overlay = {};
1021     if (not null $root) {
1022         $self->pessimise($root, $cv->START);
1023         my $lineseq = $root->first;
1024         if ($lineseq->name eq "lineseq") {
1025             my @ops;
1026             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
1027                 push @ops, $o;
1028             }
1029             $body = $self->lineseq(undef, 0, @ops).";";
1030             my $scope_en = $self->find_scope_en($lineseq);
1031             if (defined $scope_en) {
1032                 my $subs = join"", $self->seq_subs($scope_en);
1033                 $body .= ";\n$subs" if length($subs);
1034             }
1035         }
1036         else {
1037             $body = $self->deparse($root->first, 0);
1038         }
1039     }
1040     else {
1041         my $sv = $cv->const_sv;
1042         if ($$sv) {
1043             # uh-oh. inlinable sub... format it differently
1044             return $proto . "{ " . $self->const($sv, 0) . " }\n";
1045         } else { # XSUB? (or just a declaration)
1046             return "$proto;\n";
1047         }
1048     }
1049     return $proto ."{\n\t$body\n\b}" ."\n";
1050 }
1051
1052 sub deparse_format {
1053     my $self = shift;
1054     my $form = shift;
1055     my @text;
1056     local($self->{'curcv'}) = $form;
1057     local($self->{'curcvlex'});
1058     local($self->{'in_format'}) = 1;
1059     local(@$self{qw'curstash warnings hints hinthash'})
1060                 = @$self{qw'curstash warnings hints hinthash'};
1061     my $op = $form->ROOT;
1062     local $B::overlay = {};
1063     $self->pessimise($op, $form->START);
1064     my $kid;
1065     return "\f." if $op->first->name eq 'stub'
1066                 || $op->first->name eq 'nextstate';
1067     $op = $op->first->first; # skip leavewrite, lineseq
1068     while (not null $op) {
1069         $op = $op->sibling; # skip nextstate
1070         my @exprs;
1071         $kid = $op->first->sibling; # skip pushmark
1072         push @text, "\f".$self->const_sv($kid)->PV;
1073         $kid = $kid->sibling;
1074         for (; not null $kid; $kid = $kid->sibling) {
1075             push @exprs, $self->deparse($kid, -1);
1076             $exprs[-1] =~ s/;\z//;
1077         }
1078         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
1079         $op = $op->sibling;
1080     }
1081     return join("", @text) . "\f.";
1082 }
1083
1084 sub is_scope {
1085     my $op = shift;
1086     return $op->name eq "leave" || $op->name eq "scope"
1087       || $op->name eq "lineseq"
1088         || ($op->name eq "null" && class($op) eq "UNOP"
1089             && (is_scope($op->first) || $op->first->name eq "enter"));
1090 }
1091
1092 sub is_state {
1093     my $name = $_[0]->name;
1094     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
1095 }
1096
1097 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
1098     my $op = shift;
1099     return (!null($op) and null($op->sibling)
1100             and $op->name eq "null" and class($op) eq "UNOP"
1101             and (($op->first->name =~ /^(and|or)$/
1102                   and $op->first->first->sibling->name eq "lineseq")
1103                  or ($op->first->name eq "lineseq"
1104                      and not null $op->first->first->sibling
1105                      and $op->first->first->sibling->name eq "unstack")
1106                  ));
1107 }
1108
1109 # Check if the op and its sibling are the initialization and the rest of a
1110 # for (..;..;..) { ... } loop
1111 sub is_for_loop {
1112     my $op = shift;
1113     # This OP might be almost anything, though it won't be a
1114     # nextstate. (It's the initialization, so in the canonical case it
1115     # will be an sassign.) The sibling is (old style) a lineseq whose
1116     # first child is a nextstate and whose second is a leaveloop, or
1117     # (new style) an unstack whose sibling is a leaveloop.
1118     my $lseq = $op->sibling;
1119     return 0 unless !is_state($op) and !null($lseq);
1120     if ($lseq->name eq "lineseq") {
1121         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
1122             && (my $sib = $lseq->first->sibling)) {
1123             return (!null($sib) && $sib->name eq "leaveloop");
1124         }
1125     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
1126         my $sib = $lseq->sibling;
1127         return $sib && !null($sib) && $sib->name eq "leaveloop";
1128     }
1129     return 0;
1130 }
1131
1132 sub is_scalar {
1133     my $op = shift;
1134     return ($op->name eq "rv2sv" or
1135             $op->name eq "padsv" or
1136             $op->name eq "gv" or # only in array/hash constructs
1137             $op->flags & OPf_KIDS && !null($op->first)
1138               && $op->first->name eq "gvsv");
1139 }
1140
1141 sub maybe_parens {
1142     my $self = shift;
1143     my($text, $cx, $prec) = @_;
1144     if ($prec < $cx              # unary ops nest just fine
1145         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1146         or $self->{'parens'})
1147     {
1148         $text = "($text)";
1149         # In a unop, let parent reuse our parens; see maybe_parens_unop
1150         $text = "\cS" . $text if $cx == 16;
1151         return $text;
1152     } else {
1153         return $text;
1154     }
1155 }
1156
1157 # same as above, but get around the 'if it looks like a function' rule
1158 sub maybe_parens_unop {
1159     my $self = shift;
1160     my($name, $kid, $cx) = @_;
1161     if ($cx > 16 or $self->{'parens'}) {
1162         $kid =  $self->deparse($kid, 1);
1163         if ($name eq "umask" && $kid =~ /^\d+$/) {
1164             $kid = sprintf("%#o", $kid);
1165         }
1166         return $self->keyword($name) . "($kid)";
1167     } else {
1168         $kid = $self->deparse($kid, 16);
1169         if ($name eq "umask" && $kid =~ /^\d+$/) {
1170             $kid = sprintf("%#o", $kid);
1171         }
1172         $name = $self->keyword($name);
1173         if (substr($kid, 0, 1) eq "\cS") {
1174             # use kid's parens
1175             return $name . substr($kid, 1);
1176         } elsif (substr($kid, 0, 1) eq "(") {
1177             # avoid looks-like-a-function trap with extra parens
1178             # ('+' can lead to ambiguities)
1179             return "$name(" . $kid  . ")";
1180         } else {
1181             return "$name $kid";
1182         }
1183     }
1184 }
1185
1186 sub maybe_parens_func {
1187     my $self = shift;
1188     my($func, $text, $cx, $prec) = @_;
1189     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1190         return "$func($text)";
1191     } else {
1192         return "$func $text";
1193     }
1194 }
1195
1196 sub find_our_type {
1197     my ($self, $name) = @_;
1198     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1199     my $seq = $self->{'curcop'}->cop_seq;
1200     for my $a (@{$self->{'curcvlex'}{"o$name"}}) {
1201         my ($st, undef, $padname) = @$a;
1202         if ($st == $seq && $padname->FLAGS & SVpad_TYPED) {
1203             return $padname->SvSTASH->NAME;
1204         }
1205     }
1206     return '';
1207 }
1208
1209 sub maybe_local {
1210     my $self = shift;
1211     my($op, $cx, $text) = @_;
1212     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1213     if ($op->private & (OPpLVAL_INTRO|$our_intro)) {
1214         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1215         if( $our_local eq 'our' ) {
1216             if ( $text !~ /^\W(\w+::)*\w+\z/
1217              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1218             ) {
1219                 die "Unexpected our($text)\n";
1220             }
1221             $text =~ s/(\w+::)+//;
1222
1223             if (my $type = $self->find_our_type($text)) {
1224                 $our_local .= ' ' . $type;
1225             }
1226         }
1227         return $text if $self->{'avoid_local'}{$$op};
1228         if (want_scalar($op)) {
1229             return "$our_local $text";
1230         } else {
1231             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1232         }
1233     } else {
1234         return $text;
1235     }
1236 }
1237
1238 sub maybe_targmy {
1239     my $self = shift;
1240     my($op, $cx, $func, @args) = @_;
1241     if ($op->private & OPpTARGET_MY) {
1242         my $var = $self->padname($op->targ);
1243         my $val = $func->($self, $op, 7, @args);
1244         return $self->maybe_parens("$var = $val", $cx, 7);
1245     } else {
1246         return $func->($self, $op, $cx, @args);
1247     }
1248 }
1249
1250 sub padname_sv {
1251     my $self = shift;
1252     my $targ = shift;
1253     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1254 }
1255
1256 sub maybe_my {
1257     my $self = shift;
1258     my($op, $cx, $padname, $forbid_parens) = @_;
1259     my $text = $padname->PVX;
1260     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1261         my $my = $op->private & OPpPAD_STATE
1262             ? $self->keyword("state")
1263             : "my";
1264         if ($padname->FLAGS & SVpad_TYPED) {
1265             $my .= ' ' . $padname->SvSTASH->NAME;
1266         }
1267         if ($forbid_parens || want_scalar($op)) {
1268             return "$my $text";
1269         } else {
1270             return $self->maybe_parens_func($my, $text, $cx, 16);
1271         }
1272     } else {
1273         return $text;
1274     }
1275 }
1276
1277 # The following OPs don't have functions:
1278
1279 # pp_padany -- does not exist after parsing
1280
1281 sub AUTOLOAD {
1282     if ($AUTOLOAD =~ s/^.*::pp_//) {
1283         warn "unexpected OP_".uc $AUTOLOAD;
1284         return "XXX";
1285     } else {
1286         die "Undefined subroutine $AUTOLOAD called";
1287     }
1288 }
1289
1290 sub DESTROY {}  #       Do not AUTOLOAD
1291
1292 # $root should be the op which represents the root of whatever
1293 # we're sequencing here. If it's undefined, then we don't append
1294 # any subroutine declarations to the deparsed ops, otherwise we
1295 # append appropriate declarations.
1296 sub lineseq {
1297     my($self, $root, $cx, @ops) = @_;
1298     my($expr, @exprs);
1299
1300     my $out_cop = $self->{'curcop'};
1301     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1302     my $limit_seq;
1303     if (defined $root) {
1304         $limit_seq = $out_seq;
1305         my $nseq;
1306         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1307         $limit_seq = $nseq if !defined($limit_seq)
1308                            or defined($nseq) && $nseq < $limit_seq;
1309     }
1310     $limit_seq = $self->{'limit_seq'}
1311         if defined($self->{'limit_seq'})
1312         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1313     local $self->{'limit_seq'} = $limit_seq;
1314
1315     $self->walk_lineseq($root, \@ops,
1316                        sub { push @exprs, $_[0]} );
1317
1318     my $sep = $cx ? '; ' : ";\n";
1319     my $body = join($sep, grep {length} @exprs);
1320     my $subs = "";
1321     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1322         $subs = join "\n", $self->seq_subs($limit_seq);
1323     }
1324     return join($sep, grep {length} $body, $subs);
1325 }
1326
1327 sub scopeop {
1328     my($real_block, $self, $op, $cx) = @_;
1329     my $kid;
1330     my @kids;
1331
1332     local(@$self{qw'curstash warnings hints hinthash'})
1333                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1334     if ($real_block) {
1335         $kid = $op->first->sibling; # skip enter
1336         if (is_miniwhile($kid)) {
1337             my $top = $kid->first;
1338             my $name = $top->name;
1339             if ($name eq "and") {
1340                 $name = "while";
1341             } elsif ($name eq "or") {
1342                 $name = "until";
1343             } else { # no conditional -> while 1 or until 0
1344                 return $self->deparse($top->first, 1) . " while 1";
1345             }
1346             my $cond = $top->first;
1347             my $body = $cond->sibling->first; # skip lineseq
1348             $cond = $self->deparse($cond, 1);
1349             $body = $self->deparse($body, 1);
1350             return "$body $name $cond";
1351         }
1352     } else {
1353         $kid = $op->first;
1354     }
1355     for (; !null($kid); $kid = $kid->sibling) {
1356         push @kids, $kid;
1357     }
1358     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1359         my $body = $self->lineseq($op, 0, @kids);
1360         return is_lexical_subs(@kids) ? $body : "do {\n\t$body\n\b}";
1361     } else {
1362         my $lineseq = $self->lineseq($op, $cx, @kids);
1363         return (length ($lineseq) ? "$lineseq;" : "");
1364     }
1365 }
1366
1367 sub pp_scope { scopeop(0, @_); }
1368 sub pp_lineseq { scopeop(0, @_); }
1369 sub pp_leave { scopeop(1, @_); }
1370
1371 # This is a special case of scopeop and lineseq, for the case of the
1372 # main_root. The difference is that we print the output statements as
1373 # soon as we get them, for the sake of impatient users.
1374 sub deparse_root {
1375     my $self = shift;
1376     my($op) = @_;
1377     local(@$self{qw'curstash warnings hints hinthash'})
1378       = @$self{qw'curstash warnings hints hinthash'};
1379     my @kids;
1380     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1381     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1382         push @kids, $kid;
1383     }
1384     $self->walk_lineseq($op, \@kids,
1385                         sub { print $self->indent($_[0].';');
1386                               print "\n" unless $_[1] == $#kids;
1387                           });
1388 }
1389
1390 sub walk_lineseq {
1391     my ($self, $op, $kids, $callback) = @_;
1392     my @kids = @$kids;
1393     for (my $i = 0; $i < @kids; $i++) {
1394         my $expr = "";
1395         if (is_state $kids[$i]) {
1396             $expr = $self->deparse($kids[$i++], 0);
1397             if ($i > $#kids) {
1398                 $callback->($expr, $i);
1399                 last;
1400             }
1401         }
1402         if (is_for_loop($kids[$i])) {
1403             $callback->($expr . $self->for_loop($kids[$i], 0),
1404                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1405             next;
1406         }
1407         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1408         $expr =~ s/;\n?\z//;
1409         $callback->($expr, $i);
1410     }
1411 }
1412
1413 # The BEGIN {} is used here because otherwise this code isn't executed
1414 # when you run B::Deparse on itself.
1415 my %globalnames;
1416 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1417             "ENV", "ARGV", "ARGVOUT", "_"); }
1418
1419 sub gv_name {
1420     my $self = shift;
1421     my $gv = shift;
1422     my $raw = shift;
1423 Carp::confess() unless ref($gv) eq "B::GV";
1424     my $stash = $gv->STASH->NAME;
1425     my $name = $raw ? $gv->NAME : $gv->SAFENAME;
1426     if ($stash eq 'main' && $name =~ /^::/) {
1427         $stash = '::';
1428     }
1429     elsif (($stash eq 'main'
1430             && ($globalnames{$name} || $name =~ /^[^A-Za-z_:]/))
1431         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1432             && ($stash eq 'main' || $name !~ /::/))
1433           )
1434     {
1435         $stash = "";
1436     } else {
1437         $stash = $stash . "::";
1438     }
1439     if (!$raw and $name =~ /^(\^..|{)/) {
1440         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1441     }
1442     return $stash . $name;
1443 }
1444
1445 # Return the name to use for a stash variable.
1446 # If a lexical with the same name is in scope, or
1447 # if strictures are enabled, it may need to be
1448 # fully-qualified.
1449 sub stash_variable {
1450     my ($self, $prefix, $name, $cx) = @_;
1451
1452     return "$prefix$name" if $name =~ /::/;
1453
1454     unless ($prefix eq '$' || $prefix eq '@' || #'
1455             $prefix eq '%' || $prefix eq '$#') {
1456         return "$prefix$name";
1457     }
1458
1459     if ($name =~ /^[^\w+-]$/) {
1460       if (defined $cx && $cx == 26) {
1461         if ($prefix eq '@') {
1462             return "$prefix\{$name}";
1463         }
1464         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1465       }
1466       if ($prefix eq '$#') {
1467         return "\$#{$name}";
1468       }
1469     }
1470
1471     return $prefix . $self->maybe_qualify($prefix, $name);
1472 }
1473
1474 # Return just the name, without the prefix.  It may be returned as a quoted
1475 # string.  The second return value is a boolean indicating that.
1476 sub stash_variable_name {
1477     my($self, $prefix, $gv) = @_;
1478     my $name = $self->gv_name($gv, 1);
1479     $name = $self->maybe_qualify($prefix,$name);
1480     if ($name =~ /^(?:\S|(?!\d)[\ca-\cz]?(?:\w|::)*|\d+)\z/) {
1481         $name =~ s/^([\ca-\cz])/'^'.($1|'@')/e;
1482         $name =~ /^(\^..|{)/ and $name = "{$name}";
1483         return $name, 0; # not quoted
1484     }
1485     else {
1486         single_delim("q", "'", $name), 1;
1487     }
1488 }
1489
1490 sub maybe_qualify {
1491     my ($self,$prefix,$name) = @_;
1492     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1493     return $name if !$prefix || $name =~ /::/;
1494     return $self->{'curstash'}.'::'. $name
1495         if
1496             $name =~ /^(?!\d)\w/         # alphabetic
1497          && $v    !~ /^\$[ab]\z/         # not $a or $b
1498          && !$globalnames{$name}         # not a global name
1499          && $self->{hints} & $strict_bits{vars}  # strict vars
1500          && !$self->lex_in_scope($v,1)   # no "our"
1501       or $self->lex_in_scope($v);        # conflicts with "my" variable
1502     return $name;
1503 }
1504
1505 sub lex_in_scope {
1506     my ($self, $name, $our) = @_;
1507     substr $name, 0, 0, = $our ? 'o' : 'm'; # our/my
1508     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1509
1510     return 0 if !defined($self->{'curcop'});
1511     my $seq = $self->{'curcop'}->cop_seq;
1512     return 0 if !exists $self->{'curcvlex'}{$name};
1513     for my $a (@{$self->{'curcvlex'}{$name}}) {
1514         my ($st, $en) = @$a;
1515         return 1 if $seq > $st && $seq <= $en;
1516     }
1517     return 0;
1518 }
1519
1520 sub populate_curcvlex {
1521     my $self = shift;
1522     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1523         my $padlist = $cv->PADLIST;
1524         # an undef CV still in lexical chain
1525         next if class($padlist) eq "SPECIAL";
1526         my @padlist = $padlist->ARRAY;
1527         my @ns = $padlist[0]->ARRAY;
1528
1529         for (my $i=0; $i<@ns; ++$i) {
1530             next if class($ns[$i]) eq "SPECIAL";
1531             if (class($ns[$i]) eq "PV") {
1532                 # Probably that pesky lexical @_
1533                 next;
1534             }
1535             my $name = $ns[$i]->PVX;
1536             my ($seq_st, $seq_en) =
1537                 ($ns[$i]->FLAGS & SVf_FAKE)
1538                     ? (0, 999999)
1539                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1540
1541             push @{$self->{'curcvlex'}{
1542                         ($ns[$i]->FLAGS & SVpad_OUR ? 'o' : 'm') . $name
1543                   }}, [$seq_st, $seq_en, $ns[$i]];
1544         }
1545     }
1546 }
1547
1548 sub find_scope_st { ((find_scope(@_))[0]); }
1549 sub find_scope_en { ((find_scope(@_))[1]); }
1550
1551 # Recurses down the tree, looking for pad variable introductions and COPs
1552 sub find_scope {
1553     my ($self, $op, $scope_st, $scope_en) = @_;
1554     carp("Undefined op in find_scope") if !defined $op;
1555     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1556
1557     my @queue = ($op);
1558     while(my $op = shift @queue ) {
1559         for (my $o=$op->first; $$o; $o=$o->sibling) {
1560             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1561                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1562                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1563                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1564                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1565                 return ($scope_st, $scope_en);
1566             }
1567             elsif (is_state($o)) {
1568                 my $c = $o->cop_seq;
1569                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1570                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1571                 return ($scope_st, $scope_en);
1572             }
1573             elsif ($o->flags & OPf_KIDS) {
1574                 unshift (@queue, $o);
1575             }
1576         }
1577     }
1578
1579     return ($scope_st, $scope_en);
1580 }
1581
1582 # Returns a list of subs which should be inserted before the COP
1583 sub cop_subs {
1584     my ($self, $op, $out_seq) = @_;
1585     my $seq = $op->cop_seq;
1586     # If we have nephews, then our sequence number indicates
1587     # the cop_seq of the end of some sort of scope.
1588     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1589         and my $nseq = $self->find_scope_st($op->sibling) ) {
1590         $seq = $nseq;
1591     }
1592     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1593     return $self->seq_subs($seq);
1594 }
1595
1596 sub seq_subs {
1597     my ($self, $seq) = @_;
1598     my @text;
1599 #push @text, "# ($seq)\n";
1600
1601     return "" if !defined $seq;
1602     while (scalar(@{$self->{'subs_todo'}})
1603            and $seq > $self->{'subs_todo'}[0][0]) {
1604         push @text, $self->next_todo;
1605     }
1606     return @text;
1607 }
1608
1609 sub _features_from_bundle {
1610     my ($hints, $hh) = @_;
1611     foreach (@{$feature::feature_bundle{@feature::hint_bundles[$hints >> $feature::hint_shift]}}) {
1612         $hh->{$feature::feature{$_}} = 1;
1613     }
1614     return $hh;
1615 }
1616
1617 # Notice how subs and formats are inserted between statements here;
1618 # also $[ assignments and pragmas.
1619 sub pp_nextstate {
1620     my $self = shift;
1621     my($op, $cx) = @_;
1622     $self->{'curcop'} = $op;
1623     my @text;
1624     push @text, $self->cop_subs($op);
1625     my $stash = $op->stashpv;
1626     if ($stash ne $self->{'curstash'}) {
1627         push @text, "package $stash;\n";
1628         $self->{'curstash'} = $stash;
1629     }
1630
1631     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1632         push @text, '$[ = '. $op->arybase .";\n";
1633         $self->{'arybase'} = $op->arybase;
1634     }
1635
1636     my $warnings = $op->warnings;
1637     my $warning_bits;
1638     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1639         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1640     }
1641     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1642         $warning_bits = $warnings::NONE;
1643     }
1644     elsif ($warnings->isa("B::SPECIAL")) {
1645         $warning_bits = undef;
1646     }
1647     else {
1648         $warning_bits = $warnings->PV & WARN_MASK;
1649     }
1650
1651     if (defined ($warning_bits) and
1652        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1653         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1654         $self->{'warnings'} = $warning_bits;
1655     }
1656
1657     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1658     my $old_hints = $self->{'hints'};
1659     if ($self->{'hints'} != $hints) {
1660         push @text, declare_hints($self->{'hints'}, $hints);
1661         $self->{'hints'} = $hints;
1662     }
1663
1664     my $newhh;
1665     if ($] > 5.009) {
1666         $newhh = $op->hints_hash->HASH;
1667     }
1668
1669     if ($] >= 5.015006) {
1670         # feature bundle hints
1671         my $from = $old_hints & $feature::hint_mask;
1672         my $to   = $    hints & $feature::hint_mask;
1673         if ($from != $to) {
1674             if ($to == $feature::hint_mask) {
1675                 if ($self->{'hinthash'}) {
1676                     delete $self->{'hinthash'}{$_}
1677                         for grep /^feature_/, keys %{$self->{'hinthash'}};
1678                 }
1679                 else { $self->{'hinthash'} = {} }
1680                 $self->{'hinthash'}
1681                     = _features_from_bundle($from, $self->{'hinthash'});
1682             }
1683             else {
1684                 my $bundle =
1685                     $feature::hint_bundles[$to >> $feature::hint_shift];
1686                 $bundle =~ s/(\d[13579])\z/$1+1/e; # 5.11 => 5.12
1687                 push @text, "no feature;\n",
1688                             "use feature ':$bundle';\n";
1689             }
1690         }
1691     }
1692
1693     if ($] > 5.009) {
1694         push @text, declare_hinthash(
1695             $self->{'hinthash'}, $newhh,
1696             $self->{indent_size}, $self->{hints},
1697         );
1698         $self->{'hinthash'} = $newhh;
1699     }
1700
1701     # This should go after of any branches that add statements, to
1702     # increase the chances that it refers to the same line it did in
1703     # the original program.
1704     if ($self->{'linenums'}) {
1705         push @text, "\f#line " . $op->line .
1706           ' "' . $op->file, qq'"\n';
1707     }
1708
1709     push @text, $op->label . ": " if $op->label;
1710
1711     return join("", @text);
1712 }
1713
1714 sub declare_warnings {
1715     my ($from, $to) = @_;
1716     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1717         return "use warnings;\n";
1718     }
1719     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1720         return "no warnings;\n";
1721     }
1722     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1723 }
1724
1725 sub declare_hints {
1726     my ($from, $to) = @_;
1727     my $use = $to   & ~$from;
1728     my $no  = $from & ~$to;
1729     my $decls = "";
1730     for my $pragma (hint_pragmas($use)) {
1731         $decls .= "use $pragma;\n";
1732     }
1733     for my $pragma (hint_pragmas($no)) {
1734         $decls .= "no $pragma;\n";
1735     }
1736     return $decls;
1737 }
1738
1739 # Internal implementation hints that the core sets automatically, so don't need
1740 # (or want) to be passed back to the user
1741 my %ignored_hints = (
1742     'open<' => 1,
1743     'open>' => 1,
1744     ':'     => 1,
1745     'strict/refs' => 1,
1746     'strict/subs' => 1,
1747     'strict/vars' => 1,
1748 );
1749
1750 my %rev_feature;
1751
1752 sub declare_hinthash {
1753     my ($from, $to, $indent, $hints) = @_;
1754     my $doing_features =
1755         ($hints & $feature::hint_mask) == $feature::hint_mask;
1756     my @decls;
1757     my @features;
1758     my @unfeatures; # bugs?
1759     for my $key (sort keys %$to) {
1760         next if $ignored_hints{$key};
1761         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1762         next if $is_feature and not $doing_features;
1763         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
1764             push(@features, $key), next if $is_feature;
1765             push @decls,
1766                 qq(\$^H{) . single_delim("q", "'", $key) . qq(} = )
1767               . (
1768                    defined $to->{$key}
1769                         ? single_delim("q", "'", $to->{$key})
1770                         : 'undef'
1771                 )
1772               . qq(;);
1773         }
1774     }
1775     for my $key (sort keys %$from) {
1776         next if $ignored_hints{$key};
1777         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1778         next if $is_feature and not $doing_features;
1779         if (!exists $to->{$key}) {
1780             push(@unfeatures, $key), next if $is_feature;
1781             push @decls, qq(delete \$^H{'$key'};);
1782         }
1783     }
1784     my @ret;
1785     if (@features || @unfeatures) {
1786         if (!%rev_feature) { %rev_feature = reverse %feature::feature }
1787     }
1788     if (@features) {
1789         push @ret, "use feature "
1790                  . join(", ", map "'$rev_feature{$_}'", @features) . ";\n";
1791     }
1792     if (@unfeatures) {
1793         push @ret, "no feature "
1794                  . join(", ", map "'$rev_feature{$_}'", @unfeatures)
1795                  . ";\n";
1796     }
1797     @decls and
1798         push @ret,
1799              join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1800     return @ret;
1801 }
1802
1803 sub hint_pragmas {
1804     my ($bits) = @_;
1805     my (@pragmas, @strict);
1806     push @pragmas, "integer" if $bits & 0x1;
1807     for (sort keys %strict_bits) {
1808         push @strict, "'$_'" if $bits & $strict_bits{$_};
1809     }
1810     if (@strict == keys %strict_bits) {
1811         push @pragmas, "strict";
1812     }
1813     elsif (@strict) {
1814         push @pragmas, "strict " . join ', ', @strict;
1815     }
1816     push @pragmas, "bytes" if $bits & 0x8;
1817     return @pragmas;
1818 }
1819
1820 sub pp_dbstate { pp_nextstate(@_) }
1821 sub pp_setstate { pp_nextstate(@_) }
1822
1823 sub pp_unstack { return "" } # see also leaveloop
1824
1825 my %feature_keywords = (
1826   # keyword => 'feature',
1827     state   => 'state',
1828     say     => 'say',
1829     given   => 'switch',
1830     when    => 'switch',
1831     default => 'switch',
1832     break   => 'switch',
1833     evalbytes=>'evalbytes',
1834     __SUB__ => '__SUB__',
1835    fc       => 'fc',
1836 );
1837
1838 # keywords that are strong and also have a prototype
1839 #
1840 my %strong_proto_keywords = map { $_ => 1 } qw(
1841     pos
1842     prototype
1843     scalar
1844     study
1845     undef
1846 );
1847
1848 sub keyword {
1849     my $self = shift;
1850     my $name = shift;
1851     return $name if $name =~ /^CORE::/; # just in case
1852     if (exists $feature_keywords{$name}) {
1853         my $hh;
1854         my $hints = $self->{hints} & $feature::hint_mask;
1855         if ($hints && $hints != $feature::hint_mask) {
1856             $hh = _features_from_bundle($hints);
1857         }
1858         elsif ($hints) { $hh = $self->{'hinthash'} }
1859         return "CORE::$name"
1860          if !$hh
1861          || !$hh->{"feature_$feature_keywords{$name}"}
1862     }
1863     if ($strong_proto_keywords{$name}
1864         || ($name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
1865             && !defined eval{prototype "CORE::$name"})
1866     ) { return $name }
1867     if (
1868         exists $self->{subs_declared}{$name}
1869          or
1870         exists &{"$self->{curstash}::$name"}
1871     ) {
1872         return "CORE::$name"
1873     }
1874     return $name;
1875 }
1876
1877 sub baseop {
1878     my $self = shift;
1879     my($op, $cx, $name) = @_;
1880     return $self->keyword($name);
1881 }
1882
1883 sub pp_stub {
1884     my $self = shift;
1885     my($op, $cx, $name) = @_;
1886     if ($cx >= 1) {
1887         return "()";
1888     }
1889     else {
1890         return "();";
1891     }
1892 }
1893 sub pp_wantarray { baseop(@_, "wantarray") }
1894 sub pp_fork { baseop(@_, "fork") }
1895 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1896 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1897 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1898 sub pp_tms { baseop(@_, "times") }
1899 sub pp_ghostent { baseop(@_, "gethostent") }
1900 sub pp_gnetent { baseop(@_, "getnetent") }
1901 sub pp_gprotoent { baseop(@_, "getprotoent") }
1902 sub pp_gservent { baseop(@_, "getservent") }
1903 sub pp_ehostent { baseop(@_, "endhostent") }
1904 sub pp_enetent { baseop(@_, "endnetent") }
1905 sub pp_eprotoent { baseop(@_, "endprotoent") }
1906 sub pp_eservent { baseop(@_, "endservent") }
1907 sub pp_gpwent { baseop(@_, "getpwent") }
1908 sub pp_spwent { baseop(@_, "setpwent") }
1909 sub pp_epwent { baseop(@_, "endpwent") }
1910 sub pp_ggrent { baseop(@_, "getgrent") }
1911 sub pp_sgrent { baseop(@_, "setgrent") }
1912 sub pp_egrent { baseop(@_, "endgrent") }
1913 sub pp_getlogin { baseop(@_, "getlogin") }
1914
1915 sub POSTFIX () { 1 }
1916
1917 # I couldn't think of a good short name, but this is the category of
1918 # symbolic unary operators with interesting precedence
1919
1920 sub pfixop {
1921     my $self = shift;
1922     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1923     my $kid = $op->first;
1924     $kid = $self->deparse($kid, $prec);
1925     return $self->maybe_parens(($flags & POSTFIX)
1926                                  ? "$kid$name"
1927                                    # avoid confusion with filetests
1928                                  : $name eq '-'
1929                                    && $kid =~ /^[a-zA-Z](?!\w)/
1930                                         ? "$name($kid)"
1931                                         : "$name$kid",
1932                                $cx, $prec);
1933 }
1934
1935 sub pp_preinc { pfixop(@_, "++", 23) }
1936 sub pp_predec { pfixop(@_, "--", 23) }
1937 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1938 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1939 sub pp_i_preinc { pfixop(@_, "++", 23) }
1940 sub pp_i_predec { pfixop(@_, "--", 23) }
1941 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1942 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1943 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1944
1945 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1946 sub real_negate {
1947     my $self = shift;
1948     my($op, $cx) = @_;
1949     if ($op->first->name =~ /^(i_)?negate$/) {
1950         # avoid --$x
1951         $self->pfixop($op, $cx, "-", 21.5);
1952     } else {
1953         $self->pfixop($op, $cx, "-", 21);       
1954     }
1955 }
1956 sub pp_i_negate { pp_negate(@_) }
1957
1958 sub pp_not {
1959     my $self = shift;
1960     my($op, $cx) = @_;
1961     if ($cx <= 4) {
1962         $self->listop($op, $cx, "not", $op->first);
1963     } else {
1964         $self->pfixop($op, $cx, "!", 21);       
1965     }
1966 }
1967
1968 sub unop {
1969     my $self = shift;
1970     my($op, $cx, $name, $nollafr) = @_;
1971     my $kid;
1972     if ($op->flags & OPf_KIDS) {
1973         $kid = $op->first;
1974         if (not $name) {
1975             # this deals with 'boolkeys' right now
1976             return $self->deparse($kid,$cx);
1977         }
1978         my $builtinname = $name;
1979         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1980         if (defined prototype($builtinname)
1981            && prototype($builtinname) =~ /^;?\*/
1982            && $kid->name eq "rv2gv") {
1983             $kid = $kid->first;
1984         }
1985
1986         if ($nollafr) {
1987             ($kid = $self->deparse($kid, 16)) =~ s/^\cS//;
1988             return $self->maybe_parens(
1989                         $self->keyword($name) . " $kid", $cx, 16
1990                    );
1991         }   
1992         return $self->maybe_parens_unop($name, $kid, $cx);
1993     } else {
1994         return $self->maybe_parens(
1995             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
1996             $cx, 16,
1997         );
1998     }
1999 }
2000
2001 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
2002 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
2003 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
2004 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
2005 sub pp_defined { unop(@_, "defined") }
2006 sub pp_undef { unop(@_, "undef") }
2007 sub pp_study { unop(@_, "study") }
2008 sub pp_ref { unop(@_, "ref") }
2009 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
2010
2011 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
2012 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
2013 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
2014 sub pp_srand { unop(@_, "srand") }
2015 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
2016 sub pp_log { maybe_targmy(@_, \&unop, "log") }
2017 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
2018 sub pp_int { maybe_targmy(@_, \&unop, "int") }
2019 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
2020 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
2021 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
2022
2023 sub pp_length { maybe_targmy(@_, \&unop, "length") }
2024 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
2025 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
2026
2027 sub pp_each { unop(@_, "each") }
2028 sub pp_values { unop(@_, "values") }
2029 sub pp_keys { unop(@_, "keys") }
2030 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
2031 sub pp_boolkeys { 
2032     # no name because its an optimisation op that has no keyword
2033     unop(@_,"");
2034 }
2035 sub pp_aeach { unop(@_, "each") }
2036 sub pp_avalues { unop(@_, "values") }
2037 sub pp_akeys { unop(@_, "keys") }
2038 sub pp_pop { unop(@_, "pop") }
2039 sub pp_shift { unop(@_, "shift") }
2040
2041 sub pp_caller { unop(@_, "caller") }
2042 sub pp_reset { unop(@_, "reset") }
2043 sub pp_exit { unop(@_, "exit") }
2044 sub pp_prototype { unop(@_, "prototype") }
2045
2046 sub pp_close { unop(@_, "close") }
2047 sub pp_fileno { unop(@_, "fileno") }
2048 sub pp_umask { unop(@_, "umask") }
2049 sub pp_untie { unop(@_, "untie") }
2050 sub pp_tied { unop(@_, "tied") }
2051 sub pp_dbmclose { unop(@_, "dbmclose") }
2052 sub pp_getc { unop(@_, "getc") }
2053 sub pp_eof { unop(@_, "eof") }
2054 sub pp_tell { unop(@_, "tell") }
2055 sub pp_getsockname { unop(@_, "getsockname") }
2056 sub pp_getpeername { unop(@_, "getpeername") }
2057
2058 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
2059 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
2060 sub pp_readlink { unop(@_, "readlink") }
2061 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
2062 sub pp_readdir { unop(@_, "readdir") }
2063 sub pp_telldir { unop(@_, "telldir") }
2064 sub pp_rewinddir { unop(@_, "rewinddir") }
2065 sub pp_closedir { unop(@_, "closedir") }
2066 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
2067 sub pp_localtime { unop(@_, "localtime") }
2068 sub pp_gmtime { unop(@_, "gmtime") }
2069 sub pp_alarm { unop(@_, "alarm") }
2070 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
2071
2072 sub pp_dofile {
2073     my $code = unop(@_, "do", 1); # llafr does not apply
2074     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
2075     $code;
2076 }
2077 sub pp_entereval {
2078     unop(
2079       @_,
2080       $_[1]->private & OPpEVAL_BYTES ? $_[0]->keyword('evalbytes') : "eval"
2081     )
2082 }
2083
2084 sub pp_ghbyname { unop(@_, "gethostbyname") }
2085 sub pp_gnbyname { unop(@_, "getnetbyname") }
2086 sub pp_gpbyname { unop(@_, "getprotobyname") }
2087 sub pp_shostent { unop(@_, "sethostent") }
2088 sub pp_snetent { unop(@_, "setnetent") }
2089 sub pp_sprotoent { unop(@_, "setprotoent") }
2090 sub pp_sservent { unop(@_, "setservent") }
2091 sub pp_gpwnam { unop(@_, "getpwnam") }
2092 sub pp_gpwuid { unop(@_, "getpwuid") }
2093 sub pp_ggrnam { unop(@_, "getgrnam") }
2094 sub pp_ggrgid { unop(@_, "getgrgid") }
2095
2096 sub pp_lock { unop(@_, "lock") }
2097
2098 sub pp_continue { unop(@_, "continue"); }
2099 sub pp_break { unop(@_, "break"); }
2100
2101 sub givwhen {
2102     my $self = shift;
2103     my($op, $cx, $givwhen) = @_;
2104
2105     my $enterop = $op->first;
2106     my ($head, $block);
2107     if ($enterop->flags & OPf_SPECIAL) {
2108         $head = $self->keyword("default");
2109         $block = $self->deparse($enterop->first, 0);
2110     }
2111     else {
2112         my $cond = $enterop->first;
2113         my $cond_str = $self->deparse($cond, 1);
2114         $head = "$givwhen ($cond_str)";
2115         $block = $self->deparse($cond->sibling, 0);
2116     }
2117
2118     return "$head {\n".
2119         "\t$block\n".
2120         "\b}\cK";
2121 }
2122
2123 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
2124 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
2125
2126 sub pp_exists {
2127     my $self = shift;
2128     my($op, $cx) = @_;
2129     my $arg;
2130     if ($op->private & OPpEXISTS_SUB) {
2131         # Checking for the existence of a subroutine
2132         return $self->maybe_parens_func("exists",
2133                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
2134     }
2135     if ($op->flags & OPf_SPECIAL) {
2136         # Array element, not hash element
2137         return $self->maybe_parens_func("exists",
2138                                 $self->pp_aelem($op->first, 16), $cx, 16);
2139     }
2140     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
2141                                     $cx, 16);
2142 }
2143
2144 sub pp_delete {
2145     my $self = shift;
2146     my($op, $cx) = @_;
2147     my $arg;
2148     if ($op->private & OPpSLICE) {
2149         if ($op->flags & OPf_SPECIAL) {
2150             # Deleting from an array, not a hash
2151             return $self->maybe_parens_func("delete",
2152                                         $self->pp_aslice($op->first, 16),
2153                                         $cx, 16);
2154         }
2155         return $self->maybe_parens_func("delete",
2156                                         $self->pp_hslice($op->first, 16),
2157                                         $cx, 16);
2158     } else {
2159         if ($op->flags & OPf_SPECIAL) {
2160             # Deleting from an array, not a hash
2161             return $self->maybe_parens_func("delete",
2162                                         $self->pp_aelem($op->first, 16),
2163                                         $cx, 16);
2164         }
2165         return $self->maybe_parens_func("delete",
2166                                         $self->pp_helem($op->first, 16),
2167                                         $cx, 16);
2168     }
2169 }
2170
2171 sub pp_require {
2172     my $self = shift;
2173     my($op, $cx) = @_;
2174     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
2175     if (class($op) eq "UNOP" and $op->first->name eq "const"
2176         and $op->first->private & OPpCONST_BARE)
2177     {
2178         my $name = $self->const_sv($op->first)->PV;
2179         $name =~ s[/][::]g;
2180         $name =~ s/\.pm//g;
2181         return $self->maybe_parens("$opname $name", $cx, 16);
2182     } else {    
2183         $self->unop(
2184             $op, $cx,
2185             $op->first->name eq 'const'
2186              && $op->first->private & OPpCONST_NOVER
2187                  ? "no"
2188                  : $opname,
2189             1, # llafr does not apply
2190         );
2191     }
2192 }
2193
2194 sub pp_scalar {
2195     my $self = shift;
2196     my($op, $cx) = @_;
2197     my $kid = $op->first;
2198     if (not null $kid->sibling) {
2199         # XXX Was a here-doc
2200         return $self->dquote($op);
2201     }
2202     $self->unop(@_, "scalar");
2203 }
2204
2205
2206 sub padval {
2207     my $self = shift;
2208     my $targ = shift;
2209     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
2210 }
2211
2212 sub anon_hash_or_list {
2213     my $self = shift;
2214     my($op, $cx) = @_;
2215
2216     my($pre, $post) = @{{"anonlist" => ["[","]"],
2217                          "anonhash" => ["{","}"]}->{$op->name}};
2218     my($expr, @exprs);
2219     $op = $op->first->sibling; # skip pushmark
2220     for (; !null($op); $op = $op->sibling) {
2221         $expr = $self->deparse($op, 6);
2222         push @exprs, $expr;
2223     }
2224     if ($pre eq "{" and $cx < 1) {
2225         # Disambiguate that it's not a block
2226         $pre = "+{";
2227     }
2228     return $pre . join(", ", @exprs) . $post;
2229 }
2230
2231 sub pp_anonlist {
2232     my $self = shift;
2233     my ($op, $cx) = @_;
2234     if ($op->flags & OPf_SPECIAL) {
2235         return $self->anon_hash_or_list($op, $cx);
2236     }
2237     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
2238     return 'XXX';
2239 }
2240
2241 *pp_anonhash = \&pp_anonlist;
2242
2243 sub pp_refgen {
2244     my $self = shift;   
2245     my($op, $cx) = @_;
2246     my $kid = $op->first;
2247     if ($kid->name eq "null") {
2248         $kid = $kid->first;
2249         if (!null($kid->sibling) and
2250                  $kid->sibling->name eq "anoncode") {
2251             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
2252         } elsif ($kid->name eq "pushmark") {
2253             my $sib_name = $kid->sibling->name;
2254             if ($sib_name =~ /^(pad|rv2)[ah]v$/
2255                 and not $kid->sibling->flags & OPf_REF)
2256             {
2257                 # The @a in \(@a) isn't in ref context, but only when the
2258                 # parens are there.
2259                 return "\\(" . $self->pp_list($op->first) . ")";
2260             } elsif ($sib_name eq 'entersub') {
2261                 my $text = $self->deparse($kid->sibling, 1);
2262                 # Always show parens for \(&func()), but only with -p otherwise
2263                 $text = "($text)" if $self->{'parens'}
2264                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
2265                 return "\\$text";
2266             }
2267         }
2268     }
2269     $self->pfixop($op, $cx, "\\", 20);
2270 }
2271
2272 sub e_anoncode {
2273     my ($self, $info) = @_;
2274     my $text = $self->deparse_sub($info->{code});
2275     return "sub " . $text;
2276 }
2277
2278 sub pp_srefgen { pp_refgen(@_) }
2279
2280 sub pp_readline {
2281     my $self = shift;
2282     my($op, $cx) = @_;
2283     my $kid = $op->first;
2284     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
2285     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
2286     return $self->unop($op, $cx, "readline");
2287 }
2288
2289 sub pp_rcatline {
2290     my $self = shift;
2291     my($op) = @_;
2292     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
2293 }
2294
2295 # Unary operators that can occur as pseudo-listops inside double quotes
2296 sub dq_unop {
2297     my $self = shift;
2298     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2299     my $kid;
2300     if ($op->flags & OPf_KIDS) {
2301        $kid = $op->first;
2302        # If there's more than one kid, the first is an ex-pushmark.
2303        $kid = $kid->sibling if not null $kid->sibling;
2304        return $self->maybe_parens_unop($name, $kid, $cx);
2305     } else {
2306        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2307     }
2308 }
2309
2310 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2311 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2312 sub pp_uc { dq_unop(@_, "uc") }
2313 sub pp_lc { dq_unop(@_, "lc") }
2314 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2315 sub pp_fc { dq_unop(@_, "fc") }
2316
2317 sub loopex {
2318     my $self = shift;
2319     my ($op, $cx, $name) = @_;
2320     if (class($op) eq "PVOP") {
2321         $name .= " " . $op->pv;
2322     } elsif (class($op) eq "OP") {
2323         # no-op
2324     } elsif (class($op) eq "UNOP") {
2325         (my $kid = $self->deparse($op->first, 7)) =~ s/^\cS//;
2326         $name .= " $kid";
2327     }
2328     return $self->maybe_parens($name, $cx, 7);
2329 }
2330
2331 sub pp_last { loopex(@_, "last") }
2332 sub pp_next { loopex(@_, "next") }
2333 sub pp_redo { loopex(@_, "redo") }
2334 sub pp_goto { loopex(@_, "goto") }
2335 sub pp_dump { loopex(@_, "CORE::dump") }
2336
2337 sub ftst {
2338     my $self = shift;
2339     my($op, $cx, $name) = @_;
2340     if (class($op) eq "UNOP") {
2341         # Genuine '-X' filetests are exempt from the LLAFR, but not
2342         # l?stat()
2343         if ($name =~ /^-/) {
2344             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2345             return $self->maybe_parens("$name $kid", $cx, 16);
2346         }
2347         return $self->maybe_parens_unop($name, $op->first, $cx);
2348     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2349         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2350     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2351         return $name;
2352     }
2353 }
2354
2355 sub pp_lstat    { ftst(@_, "lstat") }
2356 sub pp_stat     { ftst(@_, "stat") }
2357 sub pp_ftrread  { ftst(@_, "-R") }
2358 sub pp_ftrwrite { ftst(@_, "-W") }
2359 sub pp_ftrexec  { ftst(@_, "-X") }
2360 sub pp_fteread  { ftst(@_, "-r") }
2361 sub pp_ftewrite { ftst(@_, "-w") }
2362 sub pp_fteexec  { ftst(@_, "-x") }
2363 sub pp_ftis     { ftst(@_, "-e") }
2364 sub pp_fteowned { ftst(@_, "-O") }
2365 sub pp_ftrowned { ftst(@_, "-o") }
2366 sub pp_ftzero   { ftst(@_, "-z") }
2367 sub pp_ftsize   { ftst(@_, "-s") }
2368 sub pp_ftmtime  { ftst(@_, "-M") }
2369 sub pp_ftatime  { ftst(@_, "-A") }
2370 sub pp_ftctime  { ftst(@_, "-C") }
2371 sub pp_ftsock   { ftst(@_, "-S") }
2372 sub pp_ftchr    { ftst(@_, "-c") }
2373 sub pp_ftblk    { ftst(@_, "-b") }
2374 sub pp_ftfile   { ftst(@_, "-f") }
2375 sub pp_ftdir    { ftst(@_, "-d") }
2376 sub pp_ftpipe   { ftst(@_, "-p") }
2377 sub pp_ftlink   { ftst(@_, "-l") }
2378 sub pp_ftsuid   { ftst(@_, "-u") }
2379 sub pp_ftsgid   { ftst(@_, "-g") }
2380 sub pp_ftsvtx   { ftst(@_, "-k") }
2381 sub pp_fttty    { ftst(@_, "-t") }
2382 sub pp_fttext   { ftst(@_, "-T") }
2383 sub pp_ftbinary { ftst(@_, "-B") }
2384
2385 sub SWAP_CHILDREN () { 1 }
2386 sub ASSIGN () { 2 } # has OP= variant
2387 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2388
2389 my(%left, %right);
2390
2391 sub assoc_class {
2392     my $op = shift;
2393     my $name = $op->name;
2394     if ($name eq "concat" and $op->first->name eq "concat") {
2395         # avoid spurious '=' -- see comment in pp_concat
2396         return "concat";
2397     }
2398     if ($name eq "null" and class($op) eq "UNOP"
2399         and $op->first->name =~ /^(and|x?or)$/
2400         and null $op->first->sibling)
2401     {
2402         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2403         # with a null that's used as the common end point of the two
2404         # flows of control. For precedence purposes, ignore it.
2405         # (COND_EXPRs have these too, but we don't bother with
2406         # their associativity).
2407         return assoc_class($op->first);
2408     }
2409     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2410 }
2411
2412 # Left associative operators, like '+', for which
2413 # $a + $b + $c is equivalent to ($a + $b) + $c
2414
2415 BEGIN {
2416     %left = ('multiply' => 19, 'i_multiply' => 19,
2417              'divide' => 19, 'i_divide' => 19,
2418              'modulo' => 19, 'i_modulo' => 19,
2419              'repeat' => 19,
2420              'add' => 18, 'i_add' => 18,
2421              'subtract' => 18, 'i_subtract' => 18,
2422              'concat' => 18,
2423              'left_shift' => 17, 'right_shift' => 17,
2424              'bit_and' => 13,
2425              'bit_or' => 12, 'bit_xor' => 12,
2426              'and' => 3,
2427              'or' => 2, 'xor' => 2,
2428             );
2429 }
2430
2431 sub deparse_binop_left {
2432     my $self = shift;
2433     my($op, $left, $prec) = @_;
2434     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2435         and $left{assoc_class($op)} == $left{assoc_class($left)})
2436     {
2437         return $self->deparse($left, $prec - .00001);
2438     } else {
2439         return $self->deparse($left, $prec);    
2440     }
2441 }
2442
2443 # Right associative operators, like '=', for which
2444 # $a = $b = $c is equivalent to $a = ($b = $c)
2445
2446 BEGIN {
2447     %right = ('pow' => 22,
2448               'sassign=' => 7, 'aassign=' => 7,
2449               'multiply=' => 7, 'i_multiply=' => 7,
2450               'divide=' => 7, 'i_divide=' => 7,
2451               'modulo=' => 7, 'i_modulo=' => 7,
2452               'repeat=' => 7,
2453               'add=' => 7, 'i_add=' => 7,
2454               'subtract=' => 7, 'i_subtract=' => 7,
2455               'concat=' => 7,
2456               'left_shift=' => 7, 'right_shift=' => 7,
2457               'bit_and=' => 7,
2458               'bit_or=' => 7, 'bit_xor=' => 7,
2459               'andassign' => 7,
2460               'orassign' => 7,
2461              );
2462 }
2463
2464 sub deparse_binop_right {
2465     my $self = shift;
2466     my($op, $right, $prec) = @_;
2467     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2468         and $right{assoc_class($op)} == $right{assoc_class($right)})
2469     {
2470         return $self->deparse($right, $prec - .00001);
2471     } else {
2472         return $self->deparse($right, $prec);   
2473     }
2474 }
2475
2476 sub binop {
2477     my $self = shift;
2478     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2479     my $left = $op->first;
2480     my $right = $op->last;
2481     my $eq = "";
2482     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2483         $eq = "=";
2484         $prec = 7;
2485     }
2486     if ($flags & SWAP_CHILDREN) {
2487         ($left, $right) = ($right, $left);
2488     }
2489     $left = $self->deparse_binop_left($op, $left, $prec);
2490     $left = "($left)" if $flags & LIST_CONTEXT
2491                 && $left !~ /^(my|our|local|)[\@\(]/;
2492     $right = $self->deparse_binop_right($op, $right, $prec);
2493     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2494 }
2495
2496 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2497 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2498 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2499 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2500 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2501 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2502 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2503 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2504 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2505 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2506 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2507
2508 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2509 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2510 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2511 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2512 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2513
2514 sub pp_eq { binop(@_, "==", 14) }
2515 sub pp_ne { binop(@_, "!=", 14) }
2516 sub pp_lt { binop(@_, "<", 15) }
2517 sub pp_gt { binop(@_, ">", 15) }
2518 sub pp_ge { binop(@_, ">=", 15) }
2519 sub pp_le { binop(@_, "<=", 15) }
2520 sub pp_ncmp { binop(@_, "<=>", 14) }
2521 sub pp_i_eq { binop(@_, "==", 14) }
2522 sub pp_i_ne { binop(@_, "!=", 14) }
2523 sub pp_i_lt { binop(@_, "<", 15) }
2524 sub pp_i_gt { binop(@_, ">", 15) }
2525 sub pp_i_ge { binop(@_, ">=", 15) }
2526 sub pp_i_le { binop(@_, "<=", 15) }
2527 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2528
2529 sub pp_seq { binop(@_, "eq", 14) }
2530 sub pp_sne { binop(@_, "ne", 14) }
2531 sub pp_slt { binop(@_, "lt", 15) }
2532 sub pp_sgt { binop(@_, "gt", 15) }
2533 sub pp_sge { binop(@_, "ge", 15) }
2534 sub pp_sle { binop(@_, "le", 15) }
2535 sub pp_scmp { binop(@_, "cmp", 14) }
2536
2537 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2538 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2539
2540 sub pp_smartmatch {
2541     my ($self, $op, $cx) = @_;
2542     if ($op->flags & OPf_SPECIAL) {
2543         return $self->deparse($op->last, $cx);
2544     }
2545     else {
2546         binop(@_, "~~", 14);
2547     }
2548 }
2549
2550 # '.' is special because concats-of-concats are optimized to save copying
2551 # by making all but the first concat stacked. The effect is as if the
2552 # programmer had written '($a . $b) .= $c', except legal.
2553 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2554 sub real_concat {
2555     my $self = shift;
2556     my($op, $cx) = @_;
2557     my $left = $op->first;
2558     my $right = $op->last;
2559     my $eq = "";
2560     my $prec = 18;
2561     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2562         $eq = "=";
2563         $prec = 7;
2564     }
2565     $left = $self->deparse_binop_left($op, $left, $prec);
2566     $right = $self->deparse_binop_right($op, $right, $prec);
2567     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2568 }
2569
2570 # 'x' is weird when the left arg is a list
2571 sub pp_repeat {
2572     my $self = shift;
2573     my($op, $cx) = @_;
2574     my $left = $op->first;
2575     my $right = $op->last;
2576     my $eq = "";
2577     my $prec = 19;
2578     if ($op->flags & OPf_STACKED) {
2579         $eq = "=";
2580         $prec = 7;
2581     }
2582     if (null($right)) { # list repeat; count is inside left-side ex-list
2583         my $kid = $left->first->sibling; # skip pushmark
2584         my @exprs;
2585         for (; !null($kid->sibling); $kid = $kid->sibling) {
2586             push @exprs, $self->deparse($kid, 6);
2587         }
2588         $right = $kid;
2589         $left = "(" . join(", ", @exprs). ")";
2590     } else {
2591         $left = $self->deparse_binop_left($op, $left, $prec);
2592     }
2593     $right = $self->deparse_binop_right($op, $right, $prec);
2594     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2595 }
2596
2597 sub range {
2598     my $self = shift;
2599     my ($op, $cx, $type) = @_;
2600     my $left = $op->first;
2601     my $right = $left->sibling;
2602     $left = $self->deparse($left, 9);
2603     $right = $self->deparse($right, 9);
2604     return $self->maybe_parens("$left $type $right", $cx, 9);
2605 }
2606
2607 sub pp_flop {
2608     my $self = shift;
2609     my($op, $cx) = @_;
2610     my $flip = $op->first;
2611     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2612     return $self->range($flip->first, $cx, $type);
2613 }
2614
2615 # one-line while/until is handled in pp_leave
2616
2617 sub logop {
2618     my $self = shift;
2619     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2620     my $left = $op->first;
2621     my $right = $op->first->sibling;
2622     if ($cx < 1 and is_scope($right) and $blockname
2623         and $self->{'expand'} < 7)
2624     { # if ($a) {$b}
2625         $left = $self->deparse($left, 1);
2626         $right = $self->deparse($right, 0);
2627         return "$blockname ($left) {\n\t$right\n\b}\cK";
2628     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2629              and $self->{'expand'} < 7) { # $b if $a
2630         $right = $self->deparse($right, 1);
2631         $left = $self->deparse($left, 1);
2632         return "$right $blockname $left";
2633     } elsif ($cx > $lowprec and $highop) { # $a && $b
2634         $left = $self->deparse_binop_left($op, $left, $highprec);
2635         $right = $self->deparse_binop_right($op, $right, $highprec);
2636         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2637     } else { # $a and $b
2638         $left = $self->deparse_binop_left($op, $left, $lowprec);
2639         $right = $self->deparse_binop_right($op, $right, $lowprec);
2640         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2641     }
2642 }
2643
2644 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2645 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2646 sub pp_dor { logop(@_, "//", 10) }
2647
2648 # xor is syntactically a logop, but it's really a binop (contrary to
2649 # old versions of opcode.pl). Syntax is what matters here.
2650 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2651
2652 sub logassignop {
2653     my $self = shift;
2654     my ($op, $cx, $opname) = @_;
2655     my $left = $op->first;
2656     my $right = $op->first->sibling->first; # skip sassign
2657     $left = $self->deparse($left, 7);
2658     $right = $self->deparse($right, 7);
2659     return $self->maybe_parens("$left $opname $right", $cx, 7);
2660 }
2661
2662 sub pp_andassign { logassignop(@_, "&&=") }
2663 sub pp_orassign  { logassignop(@_, "||=") }
2664 sub pp_dorassign { logassignop(@_, "//=") }
2665
2666 sub rv2gv_or_string {
2667     my($self,$op) = @_;
2668     if ($op->name eq "gv") { # could be open("open") or open("###")
2669         my($name,$quoted) =
2670             $self->stash_variable_name("", $self->gv_or_padgv($op));
2671         $quoted ? $name : "*$name";
2672     }
2673     else {
2674         $self->deparse($op, 6);
2675     }
2676 }
2677
2678 sub listop {
2679     my $self = shift;
2680     my($op, $cx, $name, $kid, $nollafr) = @_;
2681     my(@exprs);
2682     my $parens = ($cx >= 5) || $self->{'parens'};
2683     $kid ||= $op->first->sibling;
2684     # If there are no arguments, add final parentheses (or parenthesize the
2685     # whole thing if the llafr does not apply) to account for cases like
2686     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
2687     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
2688     if (null $kid) {
2689         return $nollafr
2690                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
2691                 : $self->keyword($name) . '()' x (7 < $cx);
2692     }
2693     my $first;
2694     my $fullname = $self->keyword($name);
2695     my $proto = prototype("CORE::$name");
2696     if (
2697          (     (defined $proto && $proto =~ /^;?\*/)
2698             || $name eq 'select' # select(F) doesn't have a proto
2699          )
2700          && $kid->name eq "rv2gv"
2701          && !($kid->private & OPpLVAL_INTRO)
2702     ) {
2703         $first = $self->rv2gv_or_string($kid->first);
2704     }
2705     else {
2706         $first = $self->deparse($kid, 6);
2707     }
2708     if ($name eq "chmod" && $first =~ /^\d+$/) {
2709         $first = sprintf("%#o", $first);
2710     }
2711     $first = "+$first"
2712         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
2713     push @exprs, $first;
2714     $kid = $kid->sibling;
2715     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
2716          && !($kid->private & OPpLVAL_INTRO)) {
2717         push @exprs, $first = $self->rv2gv_or_string($kid->first);
2718         $kid = $kid->sibling;
2719     }
2720     for (; !null($kid); $kid = $kid->sibling) {
2721         push @exprs, $self->deparse($kid, 6);
2722     }
2723     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2724         return "$exprs[0] = $fullname"
2725                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2726     }
2727     if ($name =~ /^(system|exec)$/
2728         && ($op->flags & OPf_STACKED)
2729         && @exprs > 1)
2730     {
2731         # handle the "system prog a1,a2,.." form
2732         my $prog = shift @exprs;
2733         $exprs[0] = "$prog $exprs[0]";
2734     }
2735
2736     if ($parens && $nollafr) {
2737         return "($fullname " . join(", ", @exprs) . ")";
2738     } elsif ($parens) {
2739         return "$fullname(" . join(", ", @exprs) . ")";
2740     } else {
2741         return "$fullname " . join(", ", @exprs);
2742     }
2743 }
2744
2745 sub pp_bless { listop(@_, "bless") }
2746 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2747 sub pp_substr {
2748     my ($self,$op,$cx) = @_;
2749     if ($op->private & OPpSUBSTR_REPL_FIRST) {
2750         return
2751            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
2752          . " = "
2753          . $self->deparse($op->first->sibling, 7);
2754     }
2755     maybe_local(@_, listop(@_, "substr"))
2756 }
2757 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2758 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2759 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2760 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2761 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2762 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2763 sub pp_unpack { listop(@_, "unpack") }
2764 sub pp_pack { listop(@_, "pack") }
2765 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2766 sub pp_splice { listop(@_, "splice") }
2767 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2768 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2769 sub pp_reverse { listop(@_, "reverse") }
2770 sub pp_warn { listop(@_, "warn") }
2771 sub pp_die { listop(@_, "die") }
2772 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
2773 sub pp_open { listop(@_, "open") }
2774 sub pp_pipe_op { listop(@_, "pipe") }
2775 sub pp_tie { listop(@_, "tie") }
2776 sub pp_binmode { listop(@_, "binmode") }
2777 sub pp_dbmopen { listop(@_, "dbmopen") }
2778 sub pp_sselect { listop(@_, "select") }
2779 sub pp_select { listop(@_, "select") }
2780 sub pp_read { listop(@_, "read") }
2781 sub pp_sysopen { listop(@_, "sysopen") }
2782 sub pp_sysseek { listop(@_, "sysseek") }
2783 sub pp_sysread { listop(@_, "sysread") }
2784 sub pp_syswrite { listop(@_, "syswrite") }
2785 sub pp_send { listop(@_, "send") }
2786 sub pp_recv { listop(@_, "recv") }
2787 sub pp_seek { listop(@_, "seek") }
2788 sub pp_fcntl { listop(@_, "fcntl") }
2789 sub pp_ioctl { listop(@_, "ioctl") }
2790 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2791 sub pp_socket { listop(@_, "socket") }
2792 sub pp_sockpair { listop(@_, "socketpair") }
2793 sub pp_bind { listop(@_, "bind") }
2794 sub pp_connect { listop(@_, "connect") }
2795 sub pp_listen { listop(@_, "listen") }
2796 sub pp_accept { listop(@_, "accept") }
2797 sub pp_shutdown { listop(@_, "shutdown") }
2798 sub pp_gsockopt { listop(@_, "getsockopt") }
2799 sub pp_ssockopt { listop(@_, "setsockopt") }
2800 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2801 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2802 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2803 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2804 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2805 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2806 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2807 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2808 sub pp_open_dir { listop(@_, "opendir") }
2809 sub pp_seekdir { listop(@_, "seekdir") }
2810 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2811 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2812 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2813 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2814 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2815 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2816 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2817 sub pp_shmget { listop(@_, "shmget") }
2818 sub pp_shmctl { listop(@_, "shmctl") }
2819 sub pp_shmread { listop(@_, "shmread") }
2820 sub pp_shmwrite { listop(@_, "shmwrite") }
2821 sub pp_msgget { listop(@_, "msgget") }
2822 sub pp_msgctl { listop(@_, "msgctl") }
2823 sub pp_msgsnd { listop(@_, "msgsnd") }
2824 sub pp_msgrcv { listop(@_, "msgrcv") }
2825 sub pp_semget { listop(@_, "semget") }
2826 sub pp_semctl { listop(@_, "semctl") }
2827 sub pp_semop { listop(@_, "semop") }
2828 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2829 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2830 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2831 sub pp_gsbyname { listop(@_, "getservbyname") }
2832 sub pp_gsbyport { listop(@_, "getservbyport") }
2833 sub pp_syscall { listop(@_, "syscall") }
2834
2835 sub pp_glob {
2836     my $self = shift;
2837     my($op, $cx) = @_;
2838     my $kid = $op->first->sibling;  # skip pushmark
2839     my $keyword =
2840         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
2841     my $text;
2842     if ($keyword =~ /^CORE::/
2843         or $kid->name ne 'const'
2844         or ($text = $self->dq($kid))
2845              =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2846         or $text =~ /[<>]/) {
2847         $text = $self->deparse($kid);
2848         return $cx >= 5 || $self->{'parens'}
2849             ? "$keyword($text)"
2850             : "$keyword $text";
2851     } else {
2852         return '<' . $text . '>';
2853     }
2854 }
2855
2856 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2857 # be a filehandle. This could probably be better fixed in the core
2858 # by moving the GV lookup into ck_truc.
2859
2860 sub pp_truncate {
2861     my $self = shift;
2862     my($op, $cx) = @_;
2863     my(@exprs);
2864     my $parens = ($cx >= 5) || $self->{'parens'};
2865     my $kid = $op->first->sibling;
2866     my $fh;
2867     if ($op->flags & OPf_SPECIAL) {
2868         # $kid is an OP_CONST
2869         $fh = $self->const_sv($kid)->PV;
2870     } else {
2871         $fh = $self->deparse($kid, 6);
2872         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2873     }
2874     my $len = $self->deparse($kid->sibling, 6);
2875     my $name = $self->keyword('truncate');
2876     if ($parens) {
2877         return "$name($fh, $len)";
2878     } else {
2879         return "$name $fh, $len";
2880     }
2881 }
2882
2883 sub indirop {
2884     my $self = shift;
2885     my($op, $cx, $name) = @_;
2886     my($expr, @exprs);
2887     my $firstkid = my $kid = $op->first->sibling;
2888     my $indir = "";
2889     if ($op->flags & OPf_STACKED) {
2890         $indir = $kid;
2891         $indir = $indir->first; # skip rv2gv
2892         if (is_scope($indir)) {
2893             $indir = "{" . $self->deparse($indir, 0) . "}";
2894             $indir = "{;}" if $indir eq "{}";
2895         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2896             $indir = $self->const_sv($indir)->PV;
2897         } else {
2898             $indir = $self->deparse($indir, 24);
2899         }
2900         $indir = $indir . " ";
2901         $kid = $kid->sibling;
2902     }
2903     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2904         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2905                                                   : '{$a <=> $b} ';
2906     }
2907     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2908         $indir = '{$b cmp $a} ';
2909     }
2910     for (; !null($kid); $kid = $kid->sibling) {
2911         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
2912         push @exprs, $expr;
2913     }
2914     my $name2;
2915     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2916         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2917     }
2918     else { $name2 = $self->keyword($name) }
2919     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2920         return "$exprs[0] = $name2 $indir $exprs[0]";
2921     }
2922
2923     my $args = $indir . join(", ", @exprs);
2924     if ($indir ne "" && $name eq "sort") {
2925         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2926         # give bareword warnings in that case. Therefore if context
2927         # requires, we'll put parens around the outside "(sort f 1, 2,
2928         # 3)". Unfortunately, we'll currently think the parens are
2929         # necessary more often that they really are, because we don't
2930         # distinguish which side of an assignment we're on.
2931         if ($cx >= 5) {
2932             return "($name2 $args)";
2933         } else {
2934             return "$name2 $args";
2935         }
2936     } elsif (
2937         !$indir && $name eq "sort"
2938       && !null($op->first->sibling)
2939       && $op->first->sibling->name eq 'entersub'
2940     ) {
2941         # We cannot say sort foo(bar), as foo will be interpreted as a
2942         # comparison routine.  We have to say sort(...) in that case.
2943         return "$name2($args)";
2944     } else {
2945         return $self->maybe_parens_func($name2, $args, $cx, 5);
2946     }
2947
2948 }
2949
2950 sub pp_prtf { indirop(@_, "printf") }
2951 sub pp_print { indirop(@_, "print") }
2952 sub pp_say  { indirop(@_, "say") }
2953 sub pp_sort { indirop(@_, "sort") }
2954
2955 sub mapop {
2956     my $self = shift;
2957     my($op, $cx, $name) = @_;
2958     my($expr, @exprs);
2959     my $kid = $op->first; # this is the (map|grep)start
2960     $kid = $kid->first->sibling; # skip a pushmark
2961     my $code = $kid->first; # skip a null
2962     if (is_scope $code) {
2963         $code = "{" . $self->deparse($code, 0) . "} ";
2964     } else {
2965         $code = $self->deparse($code, 24);
2966         $code .= ", " if !null($kid->sibling);
2967     }
2968     $kid = $kid->sibling;
2969     for (; !null($kid); $kid = $kid->sibling) {
2970         $expr = $self->deparse($kid, 6);
2971         push @exprs, $expr if defined $expr;
2972     }
2973     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2974 }
2975
2976 sub pp_mapwhile { mapop(@_, "map") }
2977 sub pp_grepwhile { mapop(@_, "grep") }
2978 sub pp_mapstart { baseop(@_, "map") }
2979 sub pp_grepstart { baseop(@_, "grep") }
2980
2981 sub pp_list {
2982     my $self = shift;
2983     my($op, $cx) = @_;
2984     my($expr, @exprs);
2985     my $kid = $op->first->sibling; # skip pushmark
2986     return '' if class($kid) eq 'NULL';
2987     my $lop;
2988     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2989     my $type;
2990     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2991         # This assumes that no other private flags equal 128, and that
2992         # OPs that store things other than flags in their op_private,
2993         # like OP_AELEMFAST, won't be immediate children of a list.
2994         #
2995         # OP_ENTERSUB and OP_SPLIT can break this logic, so check for them.
2996         # I suspect that open and exit can too.
2997         # XXX This really needs to be rewritten to accept only those ops
2998         #     known to take the OPpLVAL_INTRO flag.
2999
3000         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
3001                 or $lop->name eq "undef")
3002             or $lop->name =~ /^(?:entersub|exit|open|split)\z/)
3003         {
3004             $local = ""; # or not
3005             last;
3006         }
3007         my $newtype;
3008         if ($lop->name =~ /^pad[ash]v$/) {
3009             if ($lop->private & OPpPAD_STATE) { # state()
3010                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
3011                 $local = "state";
3012             } else { # my()
3013                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
3014                 $local = "my";
3015             }
3016             my $padname = $self->padname_sv($lop->targ);
3017             if ($padname->FLAGS & SVpad_TYPED) {
3018                 $newtype = $padname->SvSTASH->NAME;
3019             }
3020         } elsif ($lop->name =~ /^(?:gv|rv2)([ash])v$/
3021                         && $lop->private & OPpOUR_INTRO
3022                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
3023                         && $lop->first->private & OPpOUR_INTRO) { # our()
3024             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
3025             $local = "our";
3026             my $funny = !$1 || $1 eq 's' ? '$' : $1 eq 'a' ? '@' : '%';
3027             if (my $t = $self->find_our_type(
3028                     $funny . $self->gv_or_padgv($lop->first)->NAME
3029                )) {
3030                 $newtype = $t;
3031             }
3032         } elsif ($lop->name ne "undef"
3033                 # specifically avoid the "reverse sort" optimisation,
3034                 # where "reverse" is nullified
3035                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
3036         {
3037             # local()
3038             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
3039             $local = "local";
3040         }
3041         if (defined $type && defined $newtype && $newtype ne $type) {
3042             $local = '';
3043             last;
3044         }
3045         $type = $newtype;
3046     }
3047     $local = "" if $local eq "either"; # no point if it's all undefs
3048     $local .= " $type " if $local && length $type;
3049     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
3050     for (; !null($kid); $kid = $kid->sibling) {
3051         if ($local) {
3052             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
3053                 $lop = $kid->first;
3054             } else {
3055                 $lop = $kid;
3056             }
3057             $self->{'avoid_local'}{$$lop}++;
3058             $expr = $self->deparse($kid, 6);
3059             delete $self->{'avoid_local'}{$$lop};
3060         } else {
3061             $expr = $self->deparse($kid, 6);
3062         }
3063         push @exprs, $expr;
3064     }
3065     if ($local) {
3066         return "$local(" . join(", ", @exprs) . ")";
3067     } else {
3068         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
3069     }
3070 }
3071
3072 sub is_ifelse_cont {
3073     my $op = shift;
3074     return ($op->name eq "null" and class($op) eq "UNOP"
3075             and $op->first->name =~ /^(and|cond_expr)$/
3076             and is_scope($op->first->first->sibling));
3077 }
3078
3079 sub pp_cond_expr {
3080     my $self = shift;
3081     my($op, $cx) = @_;
3082     my $cond = $op->first;
3083     my $true = $cond->sibling;
3084     my $false = $true->sibling;
3085     my $cuddle = $self->{'cuddle'};
3086     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
3087             (is_scope($false) || is_ifelse_cont($false))
3088             and $self->{'expand'} < 7) {
3089         $cond = $self->deparse($cond, 8);
3090         $true = $self->deparse($true, 6);
3091         $false = $self->deparse($false, 8);
3092         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
3093     }
3094
3095     $cond = $self->deparse($cond, 1);
3096     $true = $self->deparse($true, 0);
3097     my $head = "if ($cond) {\n\t$true\n\b}";
3098     my @elsifs;
3099     while (!null($false) and is_ifelse_cont($false)) {
3100         my $newop = $false->first;
3101         my $newcond = $newop->first;
3102         my $newtrue = $newcond->sibling;
3103         $false = $newtrue->sibling; # last in chain is OP_AND => no else
3104         if ($newcond->name eq "lineseq")
3105         {
3106             # lineseq to ensure correct line numbers in elsif()
3107             # Bug #37302 fixed by change #33710.
3108             $newcond = $newcond->first->sibling;
3109         }
3110         $newcond = $self->deparse($newcond, 1);
3111         $newtrue = $self->deparse($newtrue, 0);
3112         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
3113     }
3114     if (!null($false)) {
3115         $false = $cuddle . "else {\n\t" .
3116           $self->deparse($false, 0) . "\n\b}\cK";
3117     } else {
3118         $false = "\cK";
3119     }
3120     return $head . join($cuddle, "", @elsifs) . $false;
3121 }
3122
3123 sub pp_once {
3124     my ($self, $op, $cx) = @_;
3125     my $cond = $op->first;
3126     my $true = $cond->sibling;
3127
3128     return $self->deparse($true, $cx);
3129 }
3130
3131 sub loop_common {
3132     my $self = shift;
3133     my($op, $cx, $init) = @_;
3134     my $enter = $op->first;
3135     my $kid = $enter->sibling;
3136     local(@$self{qw'curstash warnings hints hinthash'})
3137                 = @$self{qw'curstash warnings hints hinthash'};
3138     my $head = "";
3139     my $bare = 0;
3140     my $body;
3141     my $cond = undef;
3142     if ($kid->name eq "lineseq") { # bare or infinite loop
3143         if ($kid->last->name eq "unstack") { # infinite
3144             $head = "while (1) "; # Can't use for(;;) if there's a continue
3145             $cond = "";
3146         } else {
3147             $bare = 1;
3148         }
3149         $body = $kid;
3150     } elsif ($enter->name eq "enteriter") { # foreach
3151         my $ary = $enter->first->sibling; # first was pushmark
3152         my $var = $ary->sibling;
3153         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
3154             # "reverse" was optimised away
3155             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
3156         } elsif ($enter->flags & OPf_STACKED
3157             and not null $ary->first->sibling->sibling)
3158         {
3159             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
3160               $self->deparse($ary->first->sibling->sibling, 9);
3161         } else {
3162             $ary = $self->deparse($ary, 1);
3163         }
3164         if (null $var) {
3165             if (($enter->flags & OPf_SPECIAL) && ($] < 5.009)) {
3166                 # thread special var, under 5005threads
3167                 $var = $self->pp_threadsv($enter, 1);
3168             } else { # regular my() variable
3169                 $var = $self->pp_padsv($enter, 1, 1);
3170             }
3171         } elsif ($var->name eq "rv2gv") {
3172             $var = $self->pp_rv2sv($var, 1);
3173             if ($enter->private & OPpOUR_INTRO) {
3174                 # our declarations don't have package names
3175                 $var =~ s/^(.).*::/$1/;
3176                 $var = "our $var";
3177             }
3178         } elsif ($var->name eq "gv") {
3179             $var = "\$" . $self->deparse($var, 1);
3180         }
3181         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
3182         if (!is_state $body->first and $body->first->name !~ /^(?:stub|leave|scope)$/) {
3183             confess unless $var eq '$_';
3184             $body = $body->first;
3185             return $self->deparse($body, 2) . " foreach ($ary)";
3186         }
3187         $head = "foreach $var ($ary) ";
3188     } elsif ($kid->name eq "null") { # while/until
3189         $kid = $kid->first;
3190         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
3191         $cond = $self->deparse($kid->first, 1);
3192         $head = "$name ($cond) ";
3193         $body = $kid->first->sibling;
3194     } elsif ($kid->name eq "stub") { # bare and empty
3195         return "{;}"; # {} could be a hashref
3196     }
3197     # If there isn't a continue block, then the next pointer for the loop
3198     # will point to the unstack, which is kid's last child, except
3199     # in a bare loop, when it will point to the leaveloop. When neither of
3200     # these conditions hold, then the second-to-last child is the continue
3201     # block (or the last in a bare loop).
3202     my $cont_start = $enter->nextop;
3203     my $cont;
3204     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
3205         if ($bare) {
3206             $cont = $body->last;
3207         } else {
3208             $cont = $body->first;
3209             while (!null($cont->sibling->sibling)) {
3210                 $cont = $cont->sibling;
3211             }
3212         }
3213         my $state = $body->first;
3214         my $cuddle = $self->{'cuddle'};
3215         my @states;
3216         for (; $$state != $$cont; $state = $state->sibling) {
3217             push @states, $state;
3218         }
3219         $body = $self->lineseq(undef, 0, @states);
3220         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
3221             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
3222             $cont = "\cK";
3223         } else {
3224             $cont = $cuddle . "continue {\n\t" .
3225               $self->deparse($cont, 0) . "\n\b}\cK";
3226         }
3227     } else {
3228         return "" if !defined $body;
3229         if (length $init) {
3230             $head = "for ($init; $cond;) ";
3231         }
3232         $cont = "\cK";
3233         $body = $self->deparse($body, 0);
3234     }
3235     $body =~ s/;?$/;\n/;
3236
3237     return $head . "{\n\t" . $body . "\b}" . $cont;
3238 }
3239
3240 sub pp_leaveloop { shift->loop_common(@_, "") }
3241
3242 sub for_loop {
3243     my $self = shift;
3244     my($op, $cx) = @_;
3245     my $init = $self->deparse($op, 1);
3246     my $s = $op->sibling;
3247     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
3248     return $self->loop_common($ll, $cx, $init);
3249 }
3250
3251 sub pp_leavetry {
3252     my $self = shift;
3253     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
3254 }
3255
3256 sub _op_is_or_was {
3257   my ($op, $expect_type) = @_;
3258   my $type = $op->type;
3259   return($type == $expect_type
3260          || ($type == OP_NULL && $op->targ == $expect_type));
3261 }
3262
3263 sub pp_null {
3264     my $self = shift;
3265     my($op, $cx) = @_;
3266     if (class($op) eq "OP") {
3267         # old value is lost
3268         return $self->{'ex_const'} if $op->targ == OP_CONST;
3269     } elsif ($op->first->name eq 'pushmark'
3270              or $op->first->name eq 'null'
3271                 && $op->first->targ == OP_PUSHMARK
3272                 && _op_is_or_was($op, OP_LIST)) {
3273         return $self->pp_list($op, $cx);
3274     } elsif ($op->first->name eq "enter") {
3275         return $self->pp_leave($op, $cx);
3276     } elsif ($op->first->name eq "leave") {
3277         return $self->pp_leave($op->first, $cx);
3278     } elsif ($op->first->name eq "scope") {
3279         return $self->pp_scope($op->first, $cx);
3280     } elsif ($op->targ == OP_STRINGIFY) {
3281         return $self->dquote($op, $cx);
3282     } elsif ($op->targ == OP_GLOB) {
3283         return $self->pp_glob(
3284                  $op->first    # entersub
3285                     ->first    # ex-list
3286                     ->first    # pushmark
3287                     ->sibling, # glob
3288                  $cx
3289                );
3290     } elsif (!null($op->first->sibling) and
3291              $op->first->sibling->name eq "readline" and
3292              $op->first->sibling->flags & OPf_STACKED) {
3293         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
3294                                    . $self->deparse($op->first->sibling, 7),
3295                                    $cx, 7);
3296     } elsif (!null($op->first->sibling) and
3297              $op->first->sibling->name eq "trans" and
3298              $op->first->sibling->flags & OPf_STACKED) {
3299         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
3300                                    . $self->deparse($op->first->sibling, 20),
3301                                    $cx, 20);
3302     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
3303         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
3304     } elsif (!null($op->first->sibling) and
3305              $op->first->sibling->name eq "null" and
3306              class($op->first->sibling) eq "UNOP" and
3307              $op->first->sibling->first->flags & OPf_STACKED and
3308              $op->first->sibling->first->name eq "rcatline") {
3309         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
3310                                    . $self->deparse($op->first->sibling, 18),
3311                                    $cx, 18);
3312     } else {
3313         return $self->deparse($op->first, $cx);
3314     }
3315 }
3316
3317 sub padname {
3318     my $self = shift;
3319     my $targ = shift;
3320     return $self->padname_sv($targ)->PVX;
3321 }
3322
3323 sub padany {
3324     my $self = shift;
3325     my $op = shift;
3326     return substr($self->padname($op->targ), 1); # skip $/@/%
3327 }
3328
3329 sub pp_padsv {
3330     my $self = shift;
3331     my($op, $cx, $forbid_parens) = @_;
3332     return $self->maybe_my($op, $cx, $self->padname_sv($op->targ),
3333                            $forbid_parens);
3334 }
3335
3336 sub pp_padav { pp_padsv(@_) }
3337 sub pp_padhv { pp_padsv(@_) }
3338
3339 my @threadsv_names = B::threadsv_names;
3340 sub pp_threadsv {
3341     my $self = shift;
3342     my($op, $cx) = @_;
3343     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
3344 }
3345
3346 sub gv_or_padgv {
3347     my $self = shift;
3348     my $op = shift;
3349     if (class($op) eq "PADOP") {
3350         return $self->padval($op->padix);
3351     } else { # class($op) eq "SVOP"
3352         return $op->gv;
3353     }
3354 }
3355
3356 sub pp_gvsv {
3357     my $self = shift;
3358     my($op, $cx) = @_;
3359     my $gv = $self->gv_or_padgv($op);
3360     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
3361                                  $self->gv_name($gv), $cx));
3362 }
3363
3364 sub pp_gv {
3365     my $self = shift;
3366     my($op, $cx) = @_;
3367     my $gv = $self->gv_or_padgv($op);
3368     return $self->gv_name($gv);
3369 }
3370
3371 sub pp_aelemfast_lex {
3372     my $self = shift;
3373     my($op, $cx) = @_;
3374     my $name = $self->padname($op->targ);
3375     $name =~ s/^@/\$/;
3376     my $i = $op->private;
3377     $i -= 256 if $i > 127;
3378     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
3379 }
3380
3381 sub pp_aelemfast {
3382     my $self = shift;
3383     my($op, $cx) = @_;
3384     # optimised PADAV, pre 5.15
3385     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
3386
3387     my $gv = $self->gv_or_padgv($op);
3388     my($name,$quoted) = $self->stash_variable_name('@',$gv);
3389     $name = $quoted ? "$name->" : '$' . $name;
3390     my $i = $op->private;
3391     $i -= 256 if $i > 127;
3392     return $name . "[" .  ($i + $self->{'arybase'}) . "]";
3393 }
3394
3395 sub rv2x {
3396     my $self = shift;
3397     my($op, $cx, $type) = @_;
3398
3399     if (class($op) eq 'NULL' || !$op->can("first")) {
3400         carp("Unexpected op in pp_rv2x");
3401         return 'XXX';
3402     }
3403     my $kid = $op->first;
3404     if ($kid->name eq "gv") {
3405         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
3406     } elsif (is_scalar $kid) {
3407         my $str = $self->deparse($kid, 0);
3408         if ($str =~ /^\$([^\w\d])\z/) {
3409             # "$$+" isn't a legal way to write the scalar dereference
3410             # of $+, since the lexer can't tell you aren't trying to
3411             # do something like "$$ + 1" to get one more than your
3412             # PID. Either "${$+}" or "$${+}" are workable
3413             # disambiguations, but if the programmer did the former,
3414             # they'd be in the "else" clause below rather than here.
3415             # It's not clear if this should somehow be unified with
3416             # the code in dq and re_dq that also adds lexer
3417             # disambiguation braces.
3418             $str = '$' . "{$1}"; #'
3419         }
3420         return $type . $str;
3421     } else {
3422         return $type . "{" . $self->deparse($kid, 0) . "}";
3423     }
3424 }
3425
3426 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3427 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3428 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3429
3430 # skip rv2av
3431 sub pp_av2arylen {
3432     my $self = shift;
3433     my($op, $cx) = @_;
3434     if ($op->first->name eq "padav") {
3435         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3436     } else {
3437         return $self->maybe_local($op, $cx,
3438                                   $self->rv2x($op->first, $cx, '$#'));
3439     }
3440 }
3441
3442 # skip down to the old, ex-rv2cv
3443 sub pp_rv2cv {
3444     my ($self, $op, $cx) = @_;
3445     if (!null($op->first) && $op->first->name eq 'null' &&
3446         $op->first->targ == OP_LIST)
3447     {
3448         return $self->rv2x($op->first->first->sibling, $cx, "&")
3449     }
3450     else {
3451         return $self->rv2x($op, $cx, "")
3452     }
3453 }
3454
3455 sub list_const {
3456     my $self = shift;
3457     my($cx, @list) = @_;
3458     my @a = map $self->const($_, 6), @list;
3459     if (@a == 0) {
3460         return "()";
3461     } elsif (@a == 1) {
3462         return $a[0];
3463     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3464         # collapse (-1,0,1,2) into (-1..2)
3465         my ($s, $e) = @a[0,-1];
3466         my $i = $s;
3467         return $self->maybe_parens("$s..$e", $cx, 9)
3468           unless grep $i++ != $_, @a;
3469     }
3470     return $self->maybe_parens(join(", ", @a), $cx, 6);
3471 }
3472
3473 sub pp_rv2av {
3474     my $self = shift;
3475     my($op, $cx) = @_;
3476     my $kid = $op->first;
3477     if ($kid->name eq "const") { # constant list
3478         my $av = $self->const_sv($kid);
3479         return $self->list_const($cx, $av->ARRAY);
3480     } else {
3481         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3482     }
3483  }
3484
3485 sub is_subscriptable {
3486     my $op = shift;
3487     if ($op->name =~ /^[ahg]elem/) {
3488         return 1;
3489     } elsif ($op->name eq "entersub") {
3490         my $kid = $op->first;
3491         return 0 unless null $kid->sibling;
3492         $kid = $kid->first;
3493         $kid = $kid->sibling until null $kid->sibling;
3494         return 0 if is_scope($kid);
3495         $kid = $kid->first;
3496         return 0 if $kid->name eq "gv" || $kid->name eq "padcv";
3497         return 0 if is_scalar($kid);
3498         return is_subscriptable($kid);  
3499     } else {
3500         return 0;
3501     }
3502 }
3503
3504 sub elem_or_slice_array_name
3505 {
3506     my $self = shift;
3507     my ($array, $left, $padname, $allow_arrow) = @_;
3508
3509     if ($array->name eq $padname) {
3510         return $self->padany($array);
3511     } elsif (is_scope($array)) { # ${expr}[0]
3512         return "{" . $self->deparse($array, 0) . "}";
3513     } elsif ($array->name eq "gv") {
3514         ($array, my $quoted) =
3515             $self->stash_variable_name(
3516                 $left eq '[' ? '@' : '%', $self->gv_or_padgv($array)
3517             );
3518         if (!$allow_arrow && $quoted) {
3519             # This cannot happen.
3520             die "Invalid variable name $array for slice";
3521         }
3522         return $quoted ? "$array->" : $array;
3523     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3524         return $self->deparse($array, 24);
3525     } else {
3526         return undef;
3527     }
3528 }
3529
3530 sub elem_or_slice_single_index
3531 {
3532     my $self = shift;
3533     my ($idx) = @_;
3534
3535     $idx = $self->deparse($idx, 1);
3536
3537     # Outer parens in an array index will confuse perl
3538     # if we're interpolating in a regular expression, i.e.
3539     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3540     #
3541     # If $self->{parens}, then an initial '(' will
3542     # definitely be paired with a final ')'. If
3543     # !$self->{parens}, the misleading parens won't
3544     # have been added in the first place.
3545     #
3546     # [You might think that we could get "(...)...(...)"
3547     # where the initial and final parens do not match
3548     # each other. But we can't, because the above would
3549     # only happen if there's an infix binop between the
3550     # two pairs of parens, and *that* means that the whole
3551     # expression would be parenthesized as well.]
3552     #
3553     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3554
3555     # Hash-element braces will autoquote a bareword inside themselves.
3556     # We need to make sure that C<$hash{warn()}> doesn't come out as
3557     # C<$hash{warn}>, which has a quite different meaning. Currently
3558     # B::Deparse will always quote strings, even if the string was a
3559     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3560     # for constant strings.) So we can cheat slightly here - if we see
3561     # a bareword, we know that it is supposed to be a function call.
3562     #
3563     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3564
3565     return $idx;
3566 }
3567
3568 sub elem {
3569     my $self = shift;
3570     my ($op, $cx, $left, $right, $padname) = @_;
3571     my($array, $idx) = ($op->first, $op->first->sibling);
3572
3573     $idx = $self->elem_or_slice_single_index($idx);
3574
3575     unless ($array->name eq $padname) { # Maybe this has been fixed     
3576         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3577     }
3578     if (my $array_name=$self->elem_or_slice_array_name
3579             ($array, $left, $padname, 1)) {
3580         return ($array_name =~ /->\z/
3581                     ? $array_name
3582                     : $array_name eq '#' ? '${#}' : "\$" . $array_name)
3583               . $left . $idx . $right;
3584     } else {
3585         # $x[20][3]{hi} or expr->[20]
3586         my $arrow = is_subscriptable($array) ? "" : "->";
3587         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3588     }
3589
3590 }
3591
3592 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3593 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3594
3595 sub pp_gelem {
3596     my $self = shift;
3597     my($op, $cx) = @_;
3598     my($glob, $part) = ($op->first, $op->last);
3599     $glob = $glob->first; # skip rv2gv
3600     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3601     my $scope = is_scope($glob);
3602     $glob = $self->deparse($glob, 0);
3603     $part = $self->deparse($part, 1);
3604     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3605 }
3606
3607 sub slice {
3608     my $self = shift;
3609     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3610     my $last;
3611     my(@elems, $kid, $array, $list);
3612     if (class($op) eq "LISTOP") {
3613         $last = $op->last;
3614     } else { # ex-hslice inside delete()
3615         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3616         $last = $kid;
3617     }
3618     $array = $last;
3619     $array = $array->first
3620         if $array->name eq $regname or $array->name eq "null";
3621     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3622     $kid = $op->first->sibling; # skip pushmark
3623     if ($kid->name eq "list") {
3624         $kid = $kid->first->sibling; # skip list, pushmark
3625         for (; !null $kid; $kid = $kid->sibling) {
3626             push @elems, $self->deparse($kid, 6);
3627         }
3628         $list = join(", ", @elems);
3629     } else {
3630         $list = $self->elem_or_slice_single_index($kid);
3631     }
3632     my $lead = '@';
3633     $lead = '%' if $op->name =~ /^kv/i;
3634     return $lead . $array . $left . $list . $right;
3635 }
3636
3637 sub pp_aslice   { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3638 sub pp_kvaslice {                 slice(@_, "[", "]", "rv2av", "padav")  }
3639 sub pp_hslice   { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3640 sub pp_kvhslice {                 slice(@_, "{", "}", "rv2hv", "padhv")  }
3641
3642 sub pp_lslice {
3643     my $self = shift;
3644     my($op, $cx) = @_;
3645     my $idx = $op->first;
3646     my $list = $op->last;
3647     my(@elems, $kid);
3648     $list = $self->deparse($list, 1);
3649     $idx = $self->deparse($idx, 1);
3650     return "($list)" . "[$idx]";
3651 }
3652
3653 sub want_scalar {
3654     my $op = shift;
3655     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3656 }
3657
3658 sub want_list {
3659     my $op = shift;
3660     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3661 }
3662
3663 sub _method {
3664     my $self = shift;
3665     my($op, $cx) = @_;
3666     my $kid = $op->first->sibling; # skip pushmark
3667     my($meth, $obj, @exprs);
3668     if ($kid->name eq "list" and want_list $kid) {
3669         # When an indirect object isn't a bareword but the args are in
3670         # parens, the parens aren't part of the method syntax (the LLAFR
3671         # doesn't apply), but they make a list with OPf_PARENS set that
3672         # doesn't get flattened by the append_elem that adds the method,
3673         # making a (object, arg1, arg2, ...) list where the object
3674         # usually is. This can be distinguished from
3675         # '($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3676         # object) because in the later the list is in scalar context
3677         # as the left side of -> always is, while in the former
3678         # the list is in list context as method arguments always are.
3679         # (Good thing there aren't method prototypes!)
3680         $meth = $kid->sibling;
3681         $kid = $kid->first->sibling; # skip pushmark
3682         $obj = $kid;
3683         $kid = $kid->sibling;
3684         for (; not null $kid; $kid = $kid->sibling) {
3685             push @exprs, $kid;
3686         }
3687     } else {
3688         $obj = $kid;
3689         $kid = $kid->sibling;
3690         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3691               $kid = $kid->sibling) {
3692             push @exprs, $kid
3693         }
3694         $meth = $kid;
3695     }
3696
3697     if ($meth->name eq "method_named") {
3698         $meth = $self->const_sv($meth)->PV;
3699     } else {
3700         $meth = $meth->first;
3701         if ($meth->name eq "const") {
3702             # As of 5.005_58, this case is probably obsoleted by the
3703             # method_named case above
3704             $meth = $self->const_sv($meth)->PV; # needs to be bare
3705         }
3706     }
3707
3708     return { method => $meth, variable_method => ref($meth),
3709              object => $obj, args => \@exprs  },
3710            $cx;
3711 }
3712
3713 # compat function only
3714 sub method {
3715     my $self = shift;
3716     my $info = $self->_method(@_);
3717     return $self->e_method( $self->_method(@_) );
3718 }
3719
3720 sub e_method {
3721     my ($self, $info, $cx) = @_;
3722     my $obj = $self->deparse($info->{object}, 24);
3723
3724     my $meth = $info->{method};
3725     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3726     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3727     if ($info->{object}->name eq 'scope' && want_list $info->{object}) {
3728         # method { $object }
3729         # This must be deparsed this way to preserve list context
3730         # of $object.
3731         my $need_paren = $cx >= 6;
3732         return '(' x $need_paren
3733              . $meth . substr($obj,2) # chop off the "do"
3734              . " $args"
3735              . ')' x $need_paren;
3736     }
3737     my $kid = $obj . "->" . $meth;
3738     if (length $args) {
3739         return $kid . "(" . $args . ")"; # parens mandatory
3740     } else {
3741         return $kid;
3742     }
3743 }
3744
3745 # returns "&" if the prototype doesn't match the args,
3746 # or ("", $args_after_prototype_demunging) if it does.
3747 sub check_proto {
3748     my $self = shift;
3749     return "&" if $self->{'noproto'};
3750     my($proto, @args) = @_;
3751     my($arg, $real);
3752     my $doneok = 0;
3753     my @reals;
3754     # An unbackslashed @ or % gobbles up the rest of the args
3755     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3756     $proto =~ s/^\s*//;
3757     while ($proto) {
3758         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)\s*//;
3759         my $chr = $1;
3760         if ($chr eq "") {
3761             return "&" if @args;
3762         } elsif ($chr eq ";") {
3763             $doneok = 1;
3764         } elsif ($chr eq "@" or $chr eq "%") {
3765             push @reals, map($self->deparse($_, 6), @args);
3766             @args = ();
3767         } else {
3768             $arg = shift @args;
3769             last unless $arg;
3770             if ($chr eq "\$" || $chr eq "_") {
3771                 if (want_scalar $arg) {
3772                     push @reals, $self->deparse($arg, 6);
3773                 } else {
3774                     return "&";
3775                 }
3776             } elsif ($chr eq "&") {
3777                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3778                     push @reals, $self->deparse($arg, 6);
3779                 } else {
3780                     return "&";
3781                 }
3782             } elsif ($chr eq "*") {
3783                 if ($arg->name =~ /^s?refgen$/
3784                     and $arg->first->first->name eq "rv2gv")
3785                   {
3786                       $real = $arg->first->first; # skip refgen, null
3787                       if ($real->first->name eq "gv") {
3788                           push @reals, $self->deparse($real, 6);
3789                       } else {
3790                           push @reals, $self->deparse($real->first, 6);
3791                       }
3792                   } else {
3793                       return "&";
3794                   }
3795             } elsif (substr($chr, 0, 1) eq "\\") {
3796                 $chr =~ tr/\\[]//d;
3797                 if ($arg->name =~ /^s?refgen$/ and
3798                     !null($real = $arg->first) and
3799                     ($chr =~ /\$/ && is_scalar($real->first)
3800                      or ($chr =~ /@/
3801                          && class($real->first->sibling) ne 'NULL'
3802                          && $real->first->sibling->name
3803                          =~ /^(rv2|pad)av$/)
3804                      or ($chr =~ /%/
3805                          && class($real->first->sibling) ne 'NULL'
3806                          && $real->first->sibling->name
3807                          =~ /^(rv2|pad)hv$/)
3808                      #or ($chr =~ /&/ # This doesn't work
3809                      #   && $real->first->name eq "rv2cv")
3810                      or ($chr =~ /\*/
3811                          && $real->first->name eq "rv2gv")))
3812                   {
3813                       push @reals, $self->deparse($real, 6);
3814                   } else {
3815                       return "&";
3816                   }
3817             }
3818        }
3819     }
3820     return "&" if $proto and !$doneok; # too few args and no ';'
3821     return "&" if @args;               # too many args
3822     return ("", join ", ", @reals);
3823 }
3824
3825 sub pp_entersub {
3826     my $self = shift;
3827     my($op, $cx) = @_;
3828     return $self->e_method($self->_method($op, $cx))
3829         unless null $op->first->sibling;
3830     my $prefix = "";
3831     my $amper = "";
3832     my($kid, @exprs);
3833     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3834         $prefix = "do ";
3835     } elsif ($op->private & OPpENTERSUB_AMPER) {
3836         $amper = "&";
3837     }
3838     $kid = $op->first;
3839     $kid = $kid->first->sibling; # skip ex-list, pushmark
3840     for (; not null $kid->sibling; $kid = $kid->sibling) {
3841         push @exprs, $kid;
3842     }
3843     my $simple = 0;
3844     my $proto = undef;
3845     if (is_scope($kid)) {
3846         $amper = "&";
3847         $kid = "{" . $self->deparse($kid, 0) . "}";
3848     } elsif ($kid->first->name eq "gv") {
3849         my $gv = $self->gv_or_padgv($kid->first);
3850         if (class($gv->CV) ne "SPECIAL") {
3851             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3852         }
3853         $simple = 1; # only calls of named functions can be prototyped
3854         $kid = $self->deparse($kid, 24);
3855         if (!$amper) {
3856             if ($kid eq 'main::') {
3857                 $kid = '::';
3858             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3859                 $kid = single_delim("q", "'", $kid) . '->';
3860             }
3861         }
3862     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3863         $amper = "&";
3864         $kid = $self->deparse($kid, 24);
3865     } else {
3866         $prefix = "";
3867         my $arrow = is_subscriptable($kid->first) || $kid->first->name eq "padcv" ? "" : "->";
3868         $kid = $self->deparse($kid, 24) . $arrow;
3869     }
3870
3871     # Doesn't matter how many prototypes there are, if
3872     # they haven't happened yet!
3873     my $declared;
3874     {
3875         no strict 'refs';
3876         no warnings 'uninitialized';
3877         $declared = exists $self->{'subs_declared'}{$kid}
3878             || (
3879                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3880                  && !exists
3881                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3882                  && defined prototype $self->{'curstash'}."::".$kid
3883                );
3884         if (!$declared && defined($proto)) {
3885             # Avoid "too early to check prototype" warning
3886             ($amper, $proto) = ('&');
3887         }
3888     }
3889
3890     my $args;
3891     if ($declared and defined $proto and not $amper) {
3892         ($amper, $args) = $self->check_proto($proto, @exprs);
3893         if ($amper eq "&") {
3894             $args = join(", ", map($self->deparse($_, 6), @exprs));
3895         }
3896     } else {
3897         $args = join(", ", map($self->deparse($_, 6), @exprs));
3898     }
3899     if ($prefix or $amper) {
3900         if ($kid eq '&') { $kid = "{$kid}" } # &{&} cannot be written as &&
3901         if ($op->flags & OPf_STACKED) {
3902             return $prefix . $amper . $kid . "(" . $args . ")";
3903         } else {
3904             return $prefix . $amper. $kid;
3905         }
3906     } else {
3907         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
3908         # so it must have been translated from a keyword call. Translate
3909         # it back.
3910         $kid =~ s/^CORE::GLOBAL:://;
3911
3912         my $dproto = defined($proto) ? $proto : "undefined";
3913         if (!$declared) {
3914             return "$kid(" . $args . ")";
3915         } elsif ($dproto =~ /^\s*\z/) {
3916             return $kid;
3917         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3918             # is_scalar is an excessively conservative test here:
3919             # really, we should be comparing to the precedence of the
3920             # top operator of $exprs[0] (ala unop()), but that would
3921             # take some major code restructuring to do right.
3922             return $self->maybe_parens_func($kid, $args, $cx, 16);
3923         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3924             return $self->maybe_parens_func($kid, $args, $cx, 5);
3925         } else {
3926             return "$kid(" . $args . ")";
3927         }
3928     }
3929 }
3930
3931 sub pp_enterwrite { unop(@_, "write") }
3932
3933 # escape things that cause interpolation in double quotes,
3934 # but not character escapes
3935 sub uninterp {
3936     my($str) = @_;
3937     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3938     return $str;
3939 }
3940
3941 {
3942 my $bal;
3943 BEGIN {
3944     use re "eval";
3945     # Matches any string which is balanced with respect to {braces}
3946     $bal = qr(
3947       (?:
3948         [^\\{}]
3949       | \\\\
3950       | \\[{}]
3951       | \{(??{$bal})\}
3952       )*
3953     )x;
3954 }
3955
3956 # the same, but treat $|, $), $( and $ at the end of the string differently
3957 sub re_uninterp {
3958     my($str) = @_;
3959
3960     $str =~ s/
3961           ( ^|\G                  # $1
3962           | [^\\]
3963           )
3964
3965           (                       # $2
3966             (?:\\\\)*
3967           )
3968
3969           (                       # $3
3970             (\(\?\??\{$bal\}\))   # $4
3971           | [\$\@]
3972             (?!\||\)|\(|$)
3973           | \\[uUlLQE]
3974           )
3975
3976         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3977
3978     return $str;
3979 }
3980
3981 # This is for regular expressions with the /x modifier
3982 # We have to leave comments unmangled.
3983 sub re_uninterp_extended {
3984     my($str) = @_;
3985
3986     $str =~ s/
3987           ( ^|\G                  # $1
3988           | [^\\]
3989           )
3990
3991           (                       # $2
3992             (?:\\\\)*
3993           )
3994
3995           (                       # $3
3996             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3997             | \#[^\n]*            #     (skip over comments)
3998             )
3999           | [\$\@]
4000             (?!\||\)|\(|$|\s)
4001           | \\[uUlLQE]
4002           )
4003
4004         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
4005
4006     return $str;
4007 }
4008 }
4009
4010 my %unctrl = # portable to EBCDIC
4011     (
4012      "\c@" => '\c@',    # unused
4013      "\cA" => '\cA',
4014      "\cB" => '\cB',
4015      "\cC" => '\cC',
4016      "\cD" => '\cD',
4017      "\cE" => '\cE',
4018      "\cF" => '\cF',
4019      "\cG" => '\cG',
4020      "\cH" => '\cH',
4021      "\cI" => '\cI',
4022      "\cJ" => '\cJ',
4023      "\cK" => '\cK',
4024      "\cL" => '\cL',
4025      "\cM" => '\cM',
4026      "\cN" => '\cN',
4027      "\cO" => '\cO',
4028      "\cP" => '\cP',
4029      "\cQ" => '\cQ',
4030      "\cR" => '\cR',
4031      "\cS" => '\cS',
4032      "\cT" => '\cT',
4033      "\cU" => '\cU',
4034      "\cV" => '\cV',
4035      "\cW" => '\cW',
4036      "\cX" => '\cX',
4037      "\cY" => '\cY',
4038      "\cZ" => '\cZ',
4039      "\c[" => '\c[',    # unused
4040      "\c\\" => '\c\\',  # unused
4041      "\c]" => '\c]',    # unused
4042      "\c_" => '\c_',    # unused
4043     );
4044
4045 # character escapes, but not delimiters that might need to be escaped
4046 sub escape_str { # ASCII, UTF8
4047     my($str) = @_;
4048     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4049     $str =~ s/\a/\\a/g;
4050 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
4051     $str =~ s/\t/\\t/g;
4052     $str =~ s/\n/\\n/g;
4053     $str =~ s/\e/\\e/g;
4054     $str =~ s/\f/\\f/g;
4055     $str =~ s/\r/\\r/g;
4056     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
4057     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
4058     return $str;
4059 }
4060
4061 # For regexes with the /x modifier.
4062 # Leave whitespace unmangled.
4063 sub escape_extended_re {
4064     my($str) = @_;
4065     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4066     $str =~ s/([[:^print:]])/
4067         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
4068     $str =~ s/\n/\n\f/g;
4069     return $str;
4070 }
4071
4072 # Don't do this for regexen
4073 sub unback {
4074     my($str) = @_;
4075     $str =~ s/\\/\\\\/g;
4076     return $str;
4077 }
4078
4079 # Remove backslashes which precede literal control characters,
4080 # to avoid creating ambiguity when we escape the latter.
4081 sub re_unback {
4082     my($str) = @_;
4083
4084     # the insane complexity here is due to the behaviour of "\c\"
4085     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
4086     return $str;
4087 }
4088
4089 sub balanced_delim {
4090     my($str) = @_;
4091     my @str = split //, $str;
4092     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
4093     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
4094         ($open, $close) = @$ar;
4095         $fail = 0; $cnt = 0; $last_bs = 0;
4096         for $c (@str) {
4097             if ($c eq $open) {
4098                 $fail = 1 if $last_bs;
4099                 $cnt++;
4100             } elsif ($c eq $close) {
4101                 $fail = 1 if $last_bs;
4102                 $cnt--;
4103                 if ($cnt < 0) {
4104                     # qq()() isn't ")("
4105                     $fail = 1;
4106                     last;
4107                 }
4108             }
4109             $last_bs = $c eq '\\';
4110         }
4111         $fail = 1 if $cnt != 0;
4112         return ($open, "$open$str$close") if not $fail;
4113     }
4114     return ("", $str);
4115 }
4116
4117 sub single_delim {
4118     my($q, $default, $str) = @_;
4119     return "$default$str$default" if $default and index($str, $default) == -1;
4120     if ($q ne 'qr') {
4121         (my $succeed, $str) = balanced_delim($str);
4122         return "$q$str" if $succeed;
4123     }
4124     for my $delim ('/', '"', '#') {
4125         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
4126     }
4127     if ($default) {
4128         $str =~ s/$default/\\$default/g;
4129         return "$default$str$default";
4130     } else {
4131         $str =~ s[/][\\/]g;
4132         return "$q/$str/";
4133     }
4134 }
4135
4136 my $max_prec;
4137 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
4138
4139 # Split a floating point number into an integer mantissa and a binary
4140 # exponent. Assumes you've already made sure the number isn't zero or
4141 # some weird infinity or NaN.
4142 sub split_float {
4143     my($f) = @_;
4144     my $exponent = 0;
4145     if ($f == int($f)) {
4146         while ($f % 2 == 0) {
4147             $f /= 2;
4148             $exponent++;
4149         }
4150     } else {
4151         while ($f != int($f)) {
4152             $f *= 2;
4153             $exponent--;
4154         }
4155     }
4156     my $mantissa = sprintf("%.0f", $f);
4157     return ($mantissa, $exponent);
4158 }
4159
4160 sub const {
4161     my $self = shift;
4162     my($sv, $cx) = @_;
4163     if ($self->{'use_dumper'}) {
4164         return $self->const_dumper($sv, $cx);
4165     }
4166     if (class($sv) eq "SPECIAL") {
4167         # sv_undef, sv_yes, sv_no
4168         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
4169     }
4170     if (class($sv) eq "NULL") {
4171        return 'undef';
4172     }
4173     # convert a version object into the "v1.2.3" string in its V magic
4174     if ($sv->FLAGS & SVs_RMG) {
4175         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4176             return $mg->PTR if $mg->TYPE eq 'V';
4177         }
4178     }
4179
4180     if ($sv->FLAGS & SVf_IOK) {
4181         my $str = $sv->int_value;
4182         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
4183         return $str;
4184     } elsif ($sv->FLAGS & SVf_NOK) {
4185         my $nv = $sv->NV;
4186         if ($nv == 0) {
4187             if (pack("F", $nv) eq pack("F", 0)) {
4188                 # positive zero
4189                 return "0";
4190             } else {
4191                 # negative zero
4192                 return $self->maybe_parens("-.0", $cx, 21);
4193             }
4194         } elsif (1/$nv == 0) {
4195             if ($nv > 0) {
4196                 # positive infinity
4197                 return $self->maybe_parens("9**9**9", $cx, 22);
4198             } else {
4199                 # negative infinity
4200                 return $self->maybe_parens("-9**9**9", $cx, 21);
4201             }
4202         } elsif ($nv != $nv) {
4203             # NaN
4204             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
4205                 # the normal kind
4206                 return "sin(9**9**9)";
4207             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
4208                 # the inverted kind
4209                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
4210             } else {
4211                 # some other kind
4212                 my $hex = unpack("h*", pack("F", $nv));
4213                 return qq'unpack("F", pack("h*", "$hex"))';
4214             }
4215         }
4216         # first, try the default stringification
4217         my $str = "$nv";
4218         if ($str != $nv) {
4219             # failing that, try using more precision
4220             $str = sprintf("%.${max_prec}g", $nv);
4221 #           if (pack("F", $str) ne pack("F", $nv)) {
4222             if ($str != $nv) {
4223                 # not representable in decimal with whatever sprintf()
4224                 # and atof() Perl is using here.
4225                 my($mant, $exp) = split_float($nv);
4226                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
4227             }
4228         }
4229         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
4230         return $str;
4231     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
4232         my $ref = $sv->RV;
4233         if (class($ref) eq "AV") {
4234             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
4235         } elsif (class($ref) eq "HV") {
4236             my %hash = $ref->ARRAY;
4237             my @elts;
4238             for my $k (sort keys %hash) {
4239                 push @elts, "$k => " . $self->const($hash{$k}, 6);
4240             }
4241             return "{" . join(", ", @elts) . "}";
4242         } elsif (class($ref) eq "CV") {
4243             BEGIN {
4244                 if ($] > 5.0150051) {
4245                     require overloading;
4246                     unimport overloading;
4247                 }
4248             }
4249             if ($] > 5.0150051 && $self->{curcv} &&
4250                  $self->{curcv}->object_2svref == $ref->object_2svref) {
4251                 return $self->keyword("__SUB__");
4252             }
4253             return "sub " . $self->deparse_sub($ref);
4254         }
4255         if ($ref->FLAGS & SVs_SMG) {
4256             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4257                 if ($mg->TYPE eq 'r') {
4258                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
4259                     return single_delim("qr", "", $re);
4260                 }
4261             }
4262         }
4263         
4264         my $const = $self->const($ref, 20);
4265         if ($self->{in_subst_repl} && $const =~ /^[0-9]/) {
4266             $const = "($const)";
4267         }
4268         return $self->maybe_parens("\\$const", $cx, 20);
4269     } elsif ($sv->FLAGS & SVf_POK) {
4270         my $str = $sv->PV;
4271         if ($str =~ /[[:^print:]]/) {
4272             return single_delim("qq", '"', uninterp escape_str unback $str);
4273         } else {
4274             return single_delim("q", "'", unback $str);
4275         }
4276     } else {
4277         return "undef";
4278     }
4279 }
4280
4281 sub const_dumper {
4282     my $self = shift;
4283     my($sv, $cx) = @_;
4284     my $ref = $sv->object_2svref();
4285     my $dumper = Data::Dumper->new([$$ref], ['$v']);
4286     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
4287     my $str = $dumper->Dump();
4288     if ($str =~ /^\$v/) {
4289         return '${my ' . $str . ' \$v}';
4290     } else {
4291         return $str;
4292     }
4293 }
4294
4295 sub const_sv {
4296     my $self = shift;
4297     my $op = shift;
4298     my $sv = $op->sv;
4299     # the constant could be in the pad (under useithreads)
4300     $sv = $self->padval($op->targ) unless $$sv;
4301     return $sv;
4302 }
4303
4304 sub pp_const {
4305     my $self = shift;
4306     my($op, $cx) = @_;
4307     if ($op->private & OPpCONST_ARYBASE) {
4308         return '$[';
4309     }
4310 #    if ($op->private & OPpCONST_BARE) { # trouble with '=>' autoquoting
4311 #       return $self->const_sv($op)->PV;
4312 #    }
4313     my $sv = $self->const_sv($op);
4314     return $self->const($sv, $cx);
4315 }
4316
4317 sub dq {
4318     my $self = shift;
4319     my $op = shift;
4320     my $type = $op->name;
4321     if ($type eq "const") {
4322         return '$[' if $op->private & OPpCONST_ARYBASE;
4323         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
4324     } elsif ($type eq "concat") {
4325         my $first = $self->dq($op->first);
4326         my $last  = $self->dq($op->last);
4327
4328         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
4329         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4330             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4331             || ($last =~ /^[:'{\[\w_]/ && #'
4332                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4333
4334         return $first . $last;
4335     } elsif ($type eq "uc") {
4336         return '\U' . $self->dq($op->first->sibling) . '\E';
4337     } elsif ($type eq "lc") {
4338         return '\L' . $self->dq($op->first->sibling) . '\E';
4339     } elsif ($type eq "ucfirst") {
4340         return '\u' . $self->dq($op->first->sibling);
4341     } elsif ($type eq "lcfirst") {
4342         return '\l' . $self->dq($op->first->sibling);
4343     } elsif ($type eq "quotemeta") {
4344         return '\Q' . $self->dq($op->first->sibling) . '\E';
4345     } elsif ($type eq "fc") {
4346         return '\F' . $self->dq($op->first->sibling) . '\E';
4347     } elsif ($type eq "join") {
4348         return $self->deparse($op->last, 26); # was join($", @ary)
4349     } else {
4350         return $self->deparse($op, 26);
4351     }
4352 }
4353
4354 sub pp_backtick {
4355     my $self = shift;
4356     my($op, $cx) = @_;
4357     # skip pushmark if it exists (readpipe() vs ``)
4358     my $child = $op->first->sibling->isa('B::NULL')
4359         ? $op->first : $op->first->sibling;
4360     if ($self->pure_string($child)) {
4361         return single_delim("qx", '`', $self->dq($child, 1));
4362     }
4363     unop($self, @_, "readpipe");
4364 }
4365
4366 sub dquote {
4367     my $self = shift;
4368     my($op, $cx) = @_;
4369     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
4370     return $self->deparse($kid, $cx) if $self->{'unquote'};
4371     $self->maybe_targmy($kid, $cx,
4372                         sub {single_delim("qq", '"', $self->dq($_[1]))});
4373 }
4374
4375 # OP_STRINGIFY is a listop, but it only ever has one arg
4376 sub pp_stringify { maybe_targmy(@_, \&dquote) }
4377
4378 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
4379 # note that tr(from)/to/ is OK, but not tr/from/(to)
4380 sub double_delim {
4381     my($from, $to) = @_;
4382     my($succeed, $delim);
4383     if ($from !~ m[/] and $to !~ m[/]) {
4384         return "/$from/$to/";
4385     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
4386         if (($succeed, $to) = balanced_delim($to) and $succeed) {
4387             return "$from$to";
4388         } else {
4389             for $delim ('/', '"', '#') { # note no "'" -- s''' is special
4390                 return "$from$delim$to$delim" if index($to, $delim) == -1;
4391             }
4392             $to =~ s[/][\\/]g;
4393             return "$from/$to/";
4394         }
4395     } else {
4396         for $delim ('/', '"', '#') { # note no '
4397             return "$delim$from$delim$to$delim"
4398                 if index($to . $from, $delim) == -1;
4399         }
4400         $from =~ s[/][\\/]g;
4401         $to =~ s[/][\\/]g;
4402         return "/$from/$to/";   
4403     }
4404 }
4405
4406 # Only used by tr///, so backslashes hyphens
4407 sub pchr { # ASCII
4408     my($n) = @_;
4409     if ($n == ord '\\') {
4410         return '\\\\';
4411     } elsif ($n == ord "-") {
4412         return "\\-";
4413     } elsif ($n >= ord(' ') and $n <= ord('~')) {
4414         return chr($n);
4415     } elsif ($n == ord "\a") {
4416         return '\\a';
4417     } elsif ($n == ord "\b") {
4418         return '\\b';
4419     } elsif ($n == ord "\t") {
4420         return '\\t';
4421     } elsif ($n == ord "\n") {
4422         return '\\n';
4423     } elsif ($n == ord "\e") {
4424         return '\\e';
4425     } elsif ($n == ord "\f") {
4426         return '\\f';
4427     } elsif ($n == ord "\r") {
4428         return '\\r';
4429     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
4430         return '\\c' . chr(ord("@") + $n);
4431     } else {
4432 #       return '\x' . sprintf("%02x", $n);
4433         return '\\' . sprintf("%03o", $n);
4434     }
4435 }
4436
4437 sub collapse {
4438     my(@chars) = @_;
4439     my($str, $c, $tr) = ("");
4440     for ($c = 0; $c < @chars; $c++) {
4441         $tr = $chars[$c];
4442         $str .= pchr($tr);
4443         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
4444             $chars[$c + 2] == $tr + 2)
4445         {
4446             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
4447               {}
4448             $str .= "-";
4449             $str .= pchr($chars[$c]);
4450         }
4451     }
4452     return $str;
4453 }
4454
4455 sub tr_decode_byte {
4456     my($table, $flags) = @_;
4457     my(@table) = unpack("s*", $table);
4458     splice @table, 0x100, 1;   # Number of subsequent elements
4459     my($c, $tr, @from, @to, @delfrom, $delhyphen);
4460     if ($table[ord "-"] != -1 and
4461         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
4462     {
4463         $tr = $table[ord "-"];
4464         $table[ord "-"] = -1;
4465         if ($tr >= 0) {
4466             @from = ord("-");
4467             @to = $tr;
4468         } else { # -2 ==> delete
4469             $delhyphen = 1;
4470         }
4471     }
4472     for ($c = 0; $c < @table; $c++) {
4473         $tr = $table[$c];
4474         if ($tr >= 0) {
4475             push @from, $c; push @to, $tr;
4476         } elsif ($tr == -2) {
4477             push @delfrom, $c;
4478         }
4479     }
4480     @from = (@from, @delfrom);
4481     if ($flags & OPpTRANS_COMPLEMENT) {
4482         my @newfrom = ();
4483         my %from;
4484         @from{@from} = (1) x @from;
4485         for ($c = 0; $c < 256; $c++) {
4486             push @newfrom, $c unless $from{$c};
4487         }
4488         @from = @newfrom;
4489     }
4490     unless ($flags & OPpTRANS_DELETE || !@to) {
4491         pop @to while $#to and $to[$#to] == $to[$#to -1];
4492     }
4493     my($from, $to);
4494     $from = collapse(@from);
4495     $to = collapse(@to);
4496     $from .= "-" if $delhyphen;
4497     return ($from, $to);
4498 }
4499
4500 sub tr_chr {
4501     my $x = shift;
4502     if ($x == ord "-") {
4503         return "\\-";
4504     } elsif ($x == ord "\\") {
4505         return "\\\\";
4506     } else {
4507         return chr $x;
4508     }
4509 }
4510
4511 # XXX This doesn't yet handle all cases correctly either
4512
4513 sub tr_decode_utf8 {
4514     my($swash_hv, $flags) = @_;
4515     my %swash = $swash_hv->ARRAY;
4516     my $final = undef;
4517     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
4518     my $none = $swash{"NONE"}->IV;
4519     my $extra = $none + 1;
4520     my(@from, @delfrom, @to);
4521     my $line;
4522     foreach $line (split /\n/, $swash{'LIST'}->PV) {
4523         my($min, $max, $result) = split(/\t/, $line);
4524         $min = hex $min;
4525         if (length $max) {