This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: Add error check
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compiliation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25
26 require 5.010_001;
27 use strict;
28 use warnings;
29 use Carp;
30 use Config;
31 use File::Find;
32 use File::Path;
33 use File::Spec;
34 use Text::Tabs;
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and a .t file
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode through at least 6.0.  The
56 # outputs have been scrutinized most intently for release 5.1.  The others
57 # have been checked for somewhat more than just sanity.  It can handle all
58 # existing Unicode character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Hence each Unicode property is a true mathematical function with
69 # exactly one value per code point.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and vice-versa).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the other so as
135 # to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each of these, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written, not in the compound form, but in
160 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
161 # properties have several possible values, some have many, and properties like
162 # Name have a different value for every named code point.  Those will not,
163 # unless the controlling lists are changed, have their match tables written
164 # out.  But all the ones which can be used in regular expression \p{} and \P{}
165 # constructs will.  Generally a property will have either its map table or its
166 # match tables written but not both.  Again, what gets written is controlled
167 # by lists which can easily be changed.  Properties have a 'Type', like
168 # binary, or string, or enum depending on how many match tables there are and
169 # the content of the maps.  This 'Type' is different than a range 'Type', so
170 # don't get confused by the two concepts having the same name.
171 #
172 # For information about the Unicode properties, see Unicode's UAX44 document:
173
174 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
175
176 # As stated earlier, this program will work on any release of Unicode so far.
177 # Most obvious problems in earlier data have NOT been corrected except when
178 # necessary to make Perl or this program work reasonably.  For example, no
179 # folding information was given in early releases, so this program uses the
180 # substitute of lower case, just so that a regular expression with the /i
181 # option will do something that actually gives the right results in many
182 # cases.  There are also a couple other corrections for version 1.1.5,
183 # commented at the point they are made.  As an example of corrections that
184 # weren't made (but could be) is this statement from DerivedAge.txt: "The
185 # supplementary private use code points and the non-character code points were
186 # assigned in version 2.0, but not specifically listed in the UCD until
187 # versions 3.0 and 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0)
188 # More information on Unicode version glitches is further down in these
189 # introductory comments.
190 #
191 # This program works on all non-provisional properties as of 6.0, though the
192 # files for some are suppressed from apparent lack of demand for them.  You
193 # can change which are output by changing lists in this program.
194 #
195 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
196 # loose matchings rules (from Unicode TR18):
197 #
198 #    The recommended names for UCD properties and property values are in
199 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
200 #    [PropValue]. There are both abbreviated names and longer, more
201 #    descriptive names. It is strongly recommended that both names be
202 #    recognized, and that loose matching of property names be used,
203 #    whereby the case distinctions, whitespace, hyphens, and underbar
204 #    are ignored.
205 # The program still allows Fuzzy to override its determination of if loose
206 # matching should be used, but it isn't currently used, as it is no longer
207 # needed; the calculations it makes are good enough.
208 #
209 # SUMMARY OF HOW IT WORKS:
210 #
211 #   Process arguments
212 #
213 #   A list is constructed containing each input file that is to be processed
214 #
215 #   Each file on the list is processed in a loop, using the associated handler
216 #   code for each:
217 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
218 #            first.  These files name the properties and property values.
219 #            Objects are created of all the property and property value names
220 #            that the rest of the input should expect, including all synonyms.
221 #        The other input files give mappings from properties to property
222 #           values.  That is, they list code points and say what the mapping
223 #           is under the given property.  Some files give the mappings for
224 #           just one property; and some for many.  This program goes through
225 #           each file and populates the properties from them.  Some properties
226 #           are listed in more than one file, and Unicode has set up a
227 #           precedence as to which has priority if there is a conflict.  Thus
228 #           the order of processing matters, and this program handles the
229 #           conflict possibility by processing the overriding input files
230 #           last, so that if necessary they replace earlier values.
231 #        After this is all done, the program creates the property mappings not
232 #            furnished by Unicode, but derivable from what it does give.
233 #        The tables of code points that match each property value in each
234 #            property that is accessible by regular expressions are created.
235 #        The Perl-defined properties are created and populated.  Many of these
236 #            require data determined from the earlier steps
237 #        Any Perl-defined synonyms are created, and name clashes between Perl
238 #            and Unicode are reconciled and warned about.
239 #        All the properties are written to files
240 #        Any other files are written, and final warnings issued.
241 #
242 # For clarity, a number of operators have been overloaded to work on tables:
243 #   ~ means invert (take all characters not in the set).  The more
244 #       conventional '!' is not used because of the possibility of confusing
245 #       it with the actual boolean operation.
246 #   + means union
247 #   - means subtraction
248 #   & means intersection
249 # The precedence of these is the order listed.  Parentheses should be
250 # copiously used.  These are not a general scheme.  The operations aren't
251 # defined for a number of things, deliberately, to avoid getting into trouble.
252 # Operations are done on references and affect the underlying structures, so
253 # that the copy constructors for them have been overloaded to not return a new
254 # clone, but the input object itself.
255 #
256 # The bool operator is deliberately not overloaded to avoid confusion with
257 # "should it mean if the object merely exists, or also is non-empty?".
258 #
259 # WHY CERTAIN DESIGN DECISIONS WERE MADE
260 #
261 # This program needs to be able to run under miniperl.  Therefore, it uses a
262 # minimum of other modules, and hence implements some things itself that could
263 # be gotten from CPAN
264 #
265 # This program uses inputs published by the Unicode Consortium.  These can
266 # change incompatibly between releases without the Perl maintainers realizing
267 # it.  Therefore this program is now designed to try to flag these.  It looks
268 # at the directories where the inputs are, and flags any unrecognized files.
269 # It keeps track of all the properties in the files it handles, and flags any
270 # that it doesn't know how to handle.  It also flags any input lines that
271 # don't match the expected syntax, among other checks.
272 #
273 # It is also designed so if a new input file matches one of the known
274 # templates, one hopefully just needs to add it to a list to have it
275 # processed.
276 #
277 # As mentioned earlier, some properties are given in more than one file.  In
278 # particular, the files in the extracted directory are supposedly just
279 # reformattings of the others.  But they contain information not easily
280 # derivable from the other files, including results for Unihan, which this
281 # program doesn't ordinarily look at, and for unassigned code points.  They
282 # also have historically had errors or been incomplete.  In an attempt to
283 # create the best possible data, this program thus processes them first to
284 # glean information missing from the other files; then processes those other
285 # files to override any errors in the extracted ones.  Much of the design was
286 # driven by this need to store things and then possibly override them.
287 #
288 # It tries to keep fatal errors to a minimum, to generate something usable for
289 # testing purposes.  It always looks for files that could be inputs, and will
290 # warn about any that it doesn't know how to handle (the -q option suppresses
291 # the warning).
292 #
293 # Why have files written out for binary 'N' matches?
294 #   For binary properties, if you know the mapping for either Y or N; the
295 #   other is trivial to construct, so could be done at Perl run-time by just
296 #   complementing the result, instead of having a file for it.  That is, if
297 #   someone types in \p{foo: N}, Perl could translate that to \P{foo: Y} and
298 #   not need a file.   The problem is communicating to Perl that a given
299 #   property is binary.  Perl can't figure it out from looking at the N (or
300 #   No), as some non-binary properties have these as property values.  So
301 #   rather than inventing a way to communicate this info back to the core,
302 #   which would have required changes there as well, it was simpler just to
303 #   add the extra tables.
304 #
305 # Why is there more than one type of range?
306 #   This simplified things.  There are some very specialized code points that
307 #   have to be handled specially for output, such as Hangul syllable names.
308 #   By creating a range type (done late in the development process), it
309 #   allowed this to be stored with the range, and overridden by other input.
310 #   Originally these were stored in another data structure, and it became a
311 #   mess trying to decide if a second file that was for the same property was
312 #   overriding the earlier one or not.
313 #
314 # Why are there two kinds of tables, match and map?
315 #   (And there is a base class shared by the two as well.)  As stated above,
316 #   they actually are for different things.  Development proceeded much more
317 #   smoothly when I (khw) realized the distinction.  Map tables are used to
318 #   give the property value for every code point (actually every code point
319 #   that doesn't map to a default value).  Match tables are used for regular
320 #   expression matches, and are essentially the inverse mapping.  Separating
321 #   the two allows more specialized methods, and error checks so that one
322 #   can't just take the intersection of two map tables, for example, as that
323 #   is nonsensical.
324 #
325 # There are no match tables generated for matches of the null string.  These
326 # would look like qr/\p{JSN=}/ currently without modifying the regex code.
327 # Perhaps something like them could be added if necessary.  The JSN does have
328 # a real code point U+110B that maps to the null string, but it is a
329 # contributory property, and therefore not output by default.  And it's easily
330 # handled so far by making the null string the default where it is a
331 # possibility.
332 #
333 # DEBUGGING
334 #
335 # This program is written so it will run under miniperl.  Occasionally changes
336 # will cause an error where the backtrace doesn't work well under miniperl.
337 # To diagnose the problem, you can instead run it under regular perl, if you
338 # have one compiled.
339 #
340 # There is a good trace facility.  To enable it, first sub DEBUG must be set
341 # to return true.  Then a line like
342 #
343 # local $to_trace = 1 if main::DEBUG;
344 #
345 # can be added to enable tracing in its lexical scope or until you insert
346 # another line:
347 #
348 # local $to_trace = 0 if main::DEBUG;
349 #
350 # then use a line like "trace $a, @b, %c, ...;
351 #
352 # Some of the more complex subroutines already have trace statements in them.
353 # Permanent trace statements should be like:
354 #
355 # trace ... if main::DEBUG && $to_trace;
356 #
357 # If there is just one or a few files that you're debugging, you can easily
358 # cause most everything else to be skipped.  Change the line
359 #
360 # my $debug_skip = 0;
361 #
362 # to 1, and every file whose object is in @input_file_objects and doesn't have
363 # a, 'non_skip => 1,' in its constructor will be skipped.
364 #
365 # To compare the output tables, it may be useful to specify the -annotate
366 # flag.  This causes the tables to expand so there is one entry for each
367 # non-algorithmically named code point giving, currently its name, and its
368 # graphic representation if printable (and you have a font that knows about
369 # it).  This makes it easier to see what the particular code points are in
370 # each output table.  The tables are usable, but because they don't have
371 # ranges (for the most part), a Perl using them will run slower.  Non-named
372 # code points are annotated with a description of their status, and contiguous
373 # ones with the same description will be output as a range rather than
374 # individually.  Algorithmically named characters are also output as ranges,
375 # except when there are just a few contiguous ones.
376 #
377 # FUTURE ISSUES
378 #
379 # The program would break if Unicode were to change its names so that
380 # interior white space, underscores, or dashes differences were significant
381 # within property and property value names.
382 #
383 # It might be easier to use the xml versions of the UCD if this program ever
384 # would need heavy revision, and the ability to handle old versions was not
385 # required.
386 #
387 # There is the potential for name collisions, in that Perl has chosen names
388 # that Unicode could decide it also likes.  There have been such collisions in
389 # the past, with mostly Perl deciding to adopt the Unicode definition of the
390 # name.  However in the 5.2 Unicode beta testing, there were a number of such
391 # collisions, which were withdrawn before the final release, because of Perl's
392 # and other's protests.  These all involved new properties which began with
393 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
394 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
395 # Unicode document, so they are unlikely to be used by Unicode for another
396 # purpose.  However, they might try something beginning with 'In', or use any
397 # of the other Perl-defined properties.  This program will warn you of name
398 # collisions, and refuse to generate tables with them, but manual intervention
399 # will be required in this event.  One scheme that could be implemented, if
400 # necessary, would be to have this program generate another file, or add a
401 # field to mktables.lst that gives the date of first definition of a property.
402 # Each new release of Unicode would use that file as a basis for the next
403 # iteration.  And the Perl synonym addition code could sort based on the age
404 # of the property, so older properties get priority, and newer ones that clash
405 # would be refused; hence existing code would not be impacted, and some other
406 # synonym would have to be used for the new property.  This is ugly, and
407 # manual intervention would certainly be easier to do in the short run; lets
408 # hope it never comes to this.
409 #
410 # A NOTE ON UNIHAN
411 #
412 # This program can generate tables from the Unihan database.  But it doesn't
413 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
414 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
415 # database was split into 8 different files, all beginning with the letters
416 # 'Unihan'.  This program will read those file(s) if present, but it needs to
417 # know which of the many properties in the file(s) should have tables created
418 # for them.  It will create tables for any properties listed in
419 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
420 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
421 # property you want is not in those files of the release you are building
422 # against, you must add it to those two arrays.  Starting in 4.0, the
423 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
424 # is present in the directory, a table will be generated for that property.
425 # In 5.2, several more properties were added.  For your convenience, the two
426 # arrays are initialized with all the 6.0 listed properties that are also in
427 # earlier releases.  But these are commented out.  You can just uncomment the
428 # ones you want, or use them as a template for adding entries for other
429 # properties.
430 #
431 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
432 # and filter_unihan_line() are the functions where this is done.  This program
433 # already does some adjusting to make the lines look more like the rest of the
434 # Unicode DB;  You can see what that is in filter_unihan_line()
435 #
436 # There is a bug in the 3.2 data file in which some values for the
437 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
438 # could be added for these; or for a particular installation, the Unihan.txt
439 # file could be edited to fix them.
440 #
441 # HOW TO ADD A FILE TO BE PROCESSED
442 #
443 # A new file from Unicode needs to have an object constructed for it in
444 # @input_file_objects, probably at the end or at the end of the extracted
445 # ones.  The program should warn you if its name will clash with others on
446 # restrictive file systems, like DOS.  If so, figure out a better name, and
447 # add lines to the README.perl file giving that.  If the file is a character
448 # property, it should be in the format that Unicode has by default
449 # standardized for such files for the more recently introduced ones.
450 # If so, the Input_file constructor for @input_file_objects can just be the
451 # file name and release it first appeared in.  If not, then it should be
452 # possible to construct an each_line_handler() to massage the line into the
453 # standardized form.
454 #
455 # For non-character properties, more code will be needed.  You can look at
456 # the existing entries for clues.
457 #
458 # UNICODE VERSIONS NOTES
459 #
460 # The Unicode UCD has had a number of errors in it over the versions.  And
461 # these remain, by policy, in the standard for that version.  Therefore it is
462 # risky to correct them, because code may be expecting the error.  So this
463 # program doesn't generally make changes, unless the error breaks the Perl
464 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
465 # for U+1105, which causes real problems for the algorithms for Jamo
466 # calculations, so it is changed here.
467 #
468 # But it isn't so clear cut as to what to do about concepts that are
469 # introduced in a later release; should they extend back to earlier releases
470 # where the concept just didn't exist?  It was easier to do this than to not,
471 # so that's what was done.  For example, the default value for code points not
472 # in the files for various properties was probably undefined until changed by
473 # some version.  No_Block for blocks is such an example.  This program will
474 # assign No_Block even in Unicode versions that didn't have it.  This has the
475 # benefit that code being written doesn't have to special case earlier
476 # versions; and the detriment that it doesn't match the Standard precisely for
477 # the affected versions.
478 #
479 # Here are some observations about some of the issues in early versions:
480 #
481 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
482 # the reason is that the CJK block starting at 4E00 was removed from PropList,
483 # and was not put back in until 3.1.0
484 #
485 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
486 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
487 # reason is that 3.2 introduced U+205F=medium math space, which was not
488 # classed as white space, but Perl figured out that it should have been. 4.0
489 # reclassified it correctly.
490 #
491 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
492 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
493 # was left with no code points, as all the ones that mapped to 202 stayed
494 # mapped to 202.  Thus if your program used the numeric name for the class,
495 # it would not have been affected, but if it used the mnemonic, it would have
496 # been.
497 #
498 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
499 # points which eventually came to have this script property value, instead
500 # mapped to "Unknown".  But in the next release all these code points were
501 # moved to \p{sc=common} instead.
502 #
503 # The default for missing code points for BidiClass is complicated.  Starting
504 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
505 # tries to do the best it can for earlier releases.  It is done in
506 # process_PropertyAliases()
507 #
508 ##############################################################################
509
510 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
511                         # and errors
512 my $MAX_LINE_WIDTH = 78;
513
514 # Debugging aid to skip most files so as to not be distracted by them when
515 # concentrating on the ones being debugged.  Add
516 # non_skip => 1,
517 # to the constructor for those files you want processed when you set this.
518 # Files with a first version number of 0 are special: they are always
519 # processed regardless of the state of this flag.
520 my $debug_skip = 0;
521
522 # Set to 1 to enable tracing.
523 our $to_trace = 0;
524
525 { # Closure for trace: debugging aid
526     my $print_caller = 1;        # ? Include calling subroutine name
527     my $main_with_colon = 'main::';
528     my $main_colon_length = length($main_with_colon);
529
530     sub trace {
531         return unless $to_trace;        # Do nothing if global flag not set
532
533         my @input = @_;
534
535         local $DB::trace = 0;
536         $DB::trace = 0;          # Quiet 'used only once' message
537
538         my $line_number;
539
540         # Loop looking up the stack to get the first non-trace caller
541         my $caller_line;
542         my $caller_name;
543         my $i = 0;
544         do {
545             $line_number = $caller_line;
546             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
547             $caller = $main_with_colon unless defined $caller;
548
549             $caller_name = $caller;
550
551             # get rid of pkg
552             $caller_name =~ s/.*:://;
553             if (substr($caller_name, 0, $main_colon_length)
554                 eq $main_with_colon)
555             {
556                 $caller_name = substr($caller_name, $main_colon_length);
557             }
558
559         } until ($caller_name ne 'trace');
560
561         # If the stack was empty, we were called from the top level
562         $caller_name = 'main' if ($caller_name eq ""
563                                     || $caller_name eq 'trace');
564
565         my $output = "";
566         foreach my $string (@input) {
567             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
568             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
569                 $output .= simple_dumper($string);
570             }
571             else {
572                 $string = "$string" if ref $string;
573                 $string = $UNDEF unless defined $string;
574                 chomp $string;
575                 $string = '""' if $string eq "";
576                 $output .= " " if $output ne ""
577                                 && $string ne ""
578                                 && substr($output, -1, 1) ne " "
579                                 && substr($string, 0, 1) ne " ";
580                 $output .= $string;
581             }
582         }
583
584         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
585         print STDERR "$caller_name: " if $print_caller;
586         print STDERR $output, "\n";
587         return;
588     }
589 }
590
591 # This is for a rarely used development feature that allows you to compare two
592 # versions of the Unicode standard without having to deal with changes caused
593 # by the code points introduced in the later verson.  Change the 0 to a SINGLE
594 # dotted Unicode release number (e.g. 2.1).  Only code points introduced in
595 # that release and earlier will be used; later ones are thrown away.  You use
596 # the version number of the earliest one you want to compare; then run this
597 # program on directory structures containing each release, and compare the
598 # outputs.  These outputs will therefore include only the code points common
599 # to both releases, and you can see the changes caused just by the underlying
600 # release semantic changes.  For versions earlier than 3.2, you must copy a
601 # version of DAge.txt into the directory.
602 my $string_compare_versions = DEBUG && 0; #  e.g., v2.1;
603 my $compare_versions = DEBUG
604                        && $string_compare_versions
605                        && pack "C*", split /\./, $string_compare_versions;
606
607 sub uniques {
608     # Returns non-duplicated input values.  From "Perl Best Practices:
609     # Encapsulated Cleverness".  p. 455 in first edition.
610
611     my %seen;
612     # Arguably this breaks encapsulation, if the goal is to permit multiple
613     # distinct objects to stringify to the same value, and be interchangeable.
614     # However, for this program, no two objects stringify identically, and all
615     # lists passed to this function are either objects or strings. So this
616     # doesn't affect correctness, but it does give a couple of percent speedup.
617     no overloading;
618     return grep { ! $seen{$_}++ } @_;
619 }
620
621 $0 = File::Spec->canonpath($0);
622
623 my $make_test_script = 0;      # ? Should we output a test script
624 my $write_unchanged_files = 0; # ? Should we update the output files even if
625                                #    we don't think they have changed
626 my $use_directory = "";        # ? Should we chdir somewhere.
627 my $pod_directory;             # input directory to store the pod file.
628 my $pod_file = 'perluniprops';
629 my $t_path;                     # Path to the .t test file
630 my $file_list = 'mktables.lst'; # File to store input and output file names.
631                                # This is used to speed up the build, by not
632                                # executing the main body of the program if
633                                # nothing on the list has changed since the
634                                # previous build
635 my $make_list = 1;             # ? Should we write $file_list.  Set to always
636                                # make a list so that when the pumpking is
637                                # preparing a release, s/he won't have to do
638                                # special things
639 my $glob_list = 0;             # ? Should we try to include unknown .txt files
640                                # in the input.
641 my $output_range_counts = $debugging_build;   # ? Should we include the number
642                                               # of code points in ranges in
643                                               # the output
644 my $annotate = 0;              # ? Should character names be in the output
645
646 # Verbosity levels; 0 is quiet
647 my $NORMAL_VERBOSITY = 1;
648 my $PROGRESS = 2;
649 my $VERBOSE = 3;
650
651 my $verbosity = $NORMAL_VERBOSITY;
652
653 # Process arguments
654 while (@ARGV) {
655     my $arg = shift @ARGV;
656     if ($arg eq '-v') {
657         $verbosity = $VERBOSE;
658     }
659     elsif ($arg eq '-p') {
660         $verbosity = $PROGRESS;
661         $| = 1;     # Flush buffers as we go.
662     }
663     elsif ($arg eq '-q') {
664         $verbosity = 0;
665     }
666     elsif ($arg eq '-w') {
667         $write_unchanged_files = 1; # update the files even if havent changed
668     }
669     elsif ($arg eq '-check') {
670         my $this = shift @ARGV;
671         my $ok = shift @ARGV;
672         if ($this ne $ok) {
673             print "Skipping as check params are not the same.\n";
674             exit(0);
675         }
676     }
677     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
678         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
679     }
680     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
681     {
682         $make_test_script = 1;
683     }
684     elsif ($arg eq '-makelist') {
685         $make_list = 1;
686     }
687     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
688         -d $use_directory or croak "Unknown directory '$use_directory'";
689     }
690     elsif ($arg eq '-L') {
691
692         # Existence not tested until have chdir'd
693         $file_list = shift;
694     }
695     elsif ($arg eq '-globlist') {
696         $glob_list = 1;
697     }
698     elsif ($arg eq '-c') {
699         $output_range_counts = ! $output_range_counts
700     }
701     elsif ($arg eq '-annotate') {
702         $annotate = 1;
703         $debugging_build = 1;
704         $output_range_counts = 1;
705     }
706     else {
707         my $with_c = 'with';
708         $with_c .= 'out' if $output_range_counts;   # Complements the state
709         croak <<END;
710 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
711           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
712           [-check A B ]
713   -c          : Output comments $with_c number of code points in ranges
714   -q          : Quiet Mode: Only output serious warnings.
715   -p          : Set verbosity level to normal plus show progress.
716   -v          : Set Verbosity level high:  Show progress and non-serious
717                 warnings
718   -w          : Write files regardless
719   -C dir      : Change to this directory before proceeding. All relative paths
720                 except those specified by the -P and -T options will be done
721                 with respect to this directory.
722   -P dir      : Output $pod_file file to directory 'dir'.
723   -T path     : Create a test script as 'path'; overrides -maketest
724   -L filelist : Use alternate 'filelist' instead of standard one
725   -globlist   : Take as input all non-Test *.txt files in current and sub
726                 directories
727   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
728                 overrides -T
729   -makelist   : Rewrite the file list $file_list based on current setup
730   -annotate   : Output an annotation for each character in the table files;
731                 useful for debugging mktables, looking at diffs; but is slow,
732                 memory intensive; resulting tables are usable but slow and
733                 very large.
734   -check A B  : Executes $0 only if A and B are the same
735 END
736     }
737 }
738
739 # Stores the most-recently changed file.  If none have changed, can skip the
740 # build
741 my $most_recent = (stat $0)[9];   # Do this before the chdir!
742
743 # Change directories now, because need to read 'version' early.
744 if ($use_directory) {
745     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
746         $pod_directory = File::Spec->rel2abs($pod_directory);
747     }
748     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
749         $t_path = File::Spec->rel2abs($t_path);
750     }
751     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
752     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
753         $pod_directory = File::Spec->abs2rel($pod_directory);
754     }
755     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
756         $t_path = File::Spec->abs2rel($t_path);
757     }
758 }
759
760 # Get Unicode version into regular and v-string.  This is done now because
761 # various tables below get populated based on it.  These tables are populated
762 # here to be near the top of the file, and so easily seeable by those needing
763 # to modify things.
764 open my $VERSION, "<", "version"
765                     or croak "$0: can't open required file 'version': $!\n";
766 my $string_version = <$VERSION>;
767 close $VERSION;
768 chomp $string_version;
769 my $v_version = pack "C*", split /\./, $string_version;        # v string
770
771 # The following are the complete names of properties with property values that
772 # are known to not match any code points in some versions of Unicode, but that
773 # may change in the future so they should be matchable, hence an empty file is
774 # generated for them.
775 my @tables_that_may_be_empty = (
776                                 'Joining_Type=Left_Joining',
777                                 );
778 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
779 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
780 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
781                                                     if $v_version ge v4.1.0;
782
783 # The lists below are hashes, so the key is the item in the list, and the
784 # value is the reason why it is in the list.  This makes generation of
785 # documentation easier.
786
787 my %why_suppressed;  # No file generated for these.
788
789 # Files aren't generated for empty extraneous properties.  This is arguable.
790 # Extraneous properties generally come about because a property is no longer
791 # used in a newer version of Unicode.  If we generated a file without code
792 # points, programs that used to work on that property will still execute
793 # without errors.  It just won't ever match (or will always match, with \P{}).
794 # This means that the logic is now likely wrong.  I (khw) think its better to
795 # find this out by getting an error message.  Just move them to the table
796 # above to change this behavior
797 my %why_suppress_if_empty_warn_if_not = (
798
799    # It is the only property that has ever officially been removed from the
800    # Standard.  The database never contained any code points for it.
801    'Special_Case_Condition' => 'Obsolete',
802
803    # Apparently never official, but there were code points in some versions of
804    # old-style PropList.txt
805    'Non_Break' => 'Obsolete',
806 );
807
808 # These would normally go in the warn table just above, but they were changed
809 # a long time before this program was written, so warnings about them are
810 # moot.
811 if ($v_version gt v3.2.0) {
812     push @tables_that_may_be_empty,
813                                 'Canonical_Combining_Class=Attached_Below_Left'
814 }
815
816 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
817 # unless explicitly added.
818 if ($v_version ge v5.2.0) {
819     my $unihan = 'Unihan; remove from list if using Unihan';
820     foreach my $table (qw (
821                            kAccountingNumeric
822                            kOtherNumeric
823                            kPrimaryNumeric
824                            kCompatibilityVariant
825                            kIICore
826                            kIRG_GSource
827                            kIRG_HSource
828                            kIRG_JSource
829                            kIRG_KPSource
830                            kIRG_MSource
831                            kIRG_KSource
832                            kIRG_TSource
833                            kIRG_USource
834                            kIRG_VSource
835                            kRSUnicode
836                         ))
837     {
838         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
839     }
840 }
841
842 # Properties that this program ignores.
843 my @unimplemented_properties = (
844 'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
845 );
846
847 # There are several types of obsolete properties defined by Unicode.  These
848 # must be hand-edited for every new Unicode release.
849 my %why_deprecated;  # Generates a deprecated warning message if used.
850 my %why_stabilized;  # Documentation only
851 my %why_obsolete;    # Documentation only
852
853 {   # Closure
854     my $simple = 'Perl uses the more complete version of this property';
855     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
856
857     my $other_properties = 'other properties';
858     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
859     my $why_no_expand  = "Deprecated by Unicode: less useful than UTF-specific calculations",
860
861     %why_deprecated = (
862         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
863         'Jamo_Short_Name' => $contributory,
864         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
865         'Other_Alphabetic' => $contributory,
866         'Other_Default_Ignorable_Code_Point' => $contributory,
867         'Other_Grapheme_Extend' => $contributory,
868         'Other_ID_Continue' => $contributory,
869         'Other_ID_Start' => $contributory,
870         'Other_Lowercase' => $contributory,
871         'Other_Math' => $contributory,
872         'Other_Uppercase' => $contributory,
873     );
874
875     %why_suppressed = (
876         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
877         # contains the same information, but without the algorithmically
878         # determinable Hangul syllables'.  This file is not published, so it's
879         # existence is not noted in the comment.
880         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
881
882         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
883         'Unicode_1_Name' => "$simple, and no apparent demand for it, but can access it through Unicode::UCD::charinfo.  If there is no later name for a code point, then this one is used instead in charnames",
884
885         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
886         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
887         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
888         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
889
890         'Name' => "Accessible via 'use charnames;'",
891         'Name_Alias' => "Accessible via 'use charnames;'",
892
893         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
894         Expands_On_NFC => $why_no_expand,
895         Expands_On_NFD => $why_no_expand,
896         Expands_On_NFKC => $why_no_expand,
897         Expands_On_NFKD => $why_no_expand,
898     );
899
900     # The following are suppressed because they were made contributory or
901     # deprecated by Unicode before Perl ever thought about supporting them.
902     foreach my $property ('Jamo_Short_Name', 'Grapheme_Link') {
903         $why_suppressed{$property} = $why_deprecated{$property};
904     }
905
906     # Customize the message for all the 'Other_' properties
907     foreach my $property (keys %why_deprecated) {
908         next if (my $main_property = $property) !~ s/^Other_//;
909         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
910     }
911 }
912
913 if ($v_version ge 4.0.0) {
914     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
915     if ($v_version ge 6.0.0) {
916         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
917     }
918 }
919 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
920     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
921     if ($v_version ge 6.0.0) {
922         $why_deprecated{'ISO_Comment'} = 'No longer needed for chart generation; otherwise not useful, and code points for it have been removed';
923     }
924 }
925
926 # Probably obsolete forever
927 if ($v_version ge v4.1.0) {
928     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common"';
929 }
930
931 # This program can create files for enumerated-like properties, such as
932 # 'Numeric_Type'.  This file would be the same format as for a string
933 # property, with a mapping from code point to its value, so you could look up,
934 # for example, the script a code point is in.  But no one so far wants this
935 # mapping, or they have found another way to get it since this is a new
936 # feature.  So no file is generated except if it is in this list.
937 my @output_mapped_properties = split "\n", <<END;
938 END
939
940 # If you are using the Unihan database, you need to add the properties that
941 # you want to extract from it to this table.  For your convenience, the
942 # properties in the 6.0 PropertyAliases.txt file are listed, commented out
943 my @cjk_properties = split "\n", <<'END';
944 #cjkAccountingNumeric; kAccountingNumeric
945 #cjkOtherNumeric; kOtherNumeric
946 #cjkPrimaryNumeric; kPrimaryNumeric
947 #cjkCompatibilityVariant; kCompatibilityVariant
948 #cjkIICore ; kIICore
949 #cjkIRG_GSource; kIRG_GSource
950 #cjkIRG_HSource; kIRG_HSource
951 #cjkIRG_JSource; kIRG_JSource
952 #cjkIRG_KPSource; kIRG_KPSource
953 #cjkIRG_KSource; kIRG_KSource
954 #cjkIRG_TSource; kIRG_TSource
955 #cjkIRG_USource; kIRG_USource
956 #cjkIRG_VSource; kIRG_VSource
957 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
958 END
959
960 # Similarly for the property values.  For your convenience, the lines in the
961 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
962 # '#' marks
963 my @cjk_property_values = split "\n", <<'END';
964 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
965 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
966 ## @missing: 0000..10FFFF; cjkIICore; <none>
967 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
968 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
969 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
970 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
971 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
972 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
973 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
974 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
975 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
976 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
977 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
978 END
979
980 # The input files don't list every code point.  Those not listed are to be
981 # defaulted to some value.  Below are hard-coded what those values are for
982 # non-binary properties as of 5.1.  Starting in 5.0, there are
983 # machine-parsable comment lines in the files the give the defaults; so this
984 # list shouldn't have to be extended.  The claim is that all missing entries
985 # for binary properties will default to 'N'.  Unicode tried to change that in
986 # 5.2, but the beta period produced enough protest that they backed off.
987 #
988 # The defaults for the fields that appear in UnicodeData.txt in this hash must
989 # be in the form that it expects.  The others may be synonyms.
990 my $CODE_POINT = '<code point>';
991 my %default_mapping = (
992     Age => "Unassigned",
993     # Bidi_Class => Complicated; set in code
994     Bidi_Mirroring_Glyph => "",
995     Block => 'No_Block',
996     Canonical_Combining_Class => 0,
997     Case_Folding => $CODE_POINT,
998     Decomposition_Mapping => $CODE_POINT,
999     Decomposition_Type => 'None',
1000     East_Asian_Width => "Neutral",
1001     FC_NFKC_Closure => $CODE_POINT,
1002     General_Category => 'Cn',
1003     Grapheme_Cluster_Break => 'Other',
1004     Hangul_Syllable_Type => 'NA',
1005     ISO_Comment => "",
1006     Jamo_Short_Name => "",
1007     Joining_Group => "No_Joining_Group",
1008     # Joining_Type => Complicated; set in code
1009     kIICore => 'N',   #                       Is converted to binary
1010     #Line_Break => Complicated; set in code
1011     Lowercase_Mapping => $CODE_POINT,
1012     Name => "",
1013     Name_Alias => "",
1014     NFC_QC => 'Yes',
1015     NFD_QC => 'Yes',
1016     NFKC_QC => 'Yes',
1017     NFKD_QC => 'Yes',
1018     Numeric_Type => 'None',
1019     Numeric_Value => 'NaN',
1020     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1021     Sentence_Break => 'Other',
1022     Simple_Case_Folding => $CODE_POINT,
1023     Simple_Lowercase_Mapping => $CODE_POINT,
1024     Simple_Titlecase_Mapping => $CODE_POINT,
1025     Simple_Uppercase_Mapping => $CODE_POINT,
1026     Titlecase_Mapping => $CODE_POINT,
1027     Unicode_1_Name => "",
1028     Unicode_Radical_Stroke => "",
1029     Uppercase_Mapping => $CODE_POINT,
1030     Word_Break => 'Other',
1031 );
1032
1033 # Below are files that Unicode furnishes, but this program ignores, and why
1034 my %ignored_files = (
1035     'CJKRadicals.txt' => 'Unihan data',
1036     'Index.txt' => 'An index, not actual data',
1037     'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
1038     'NamesList.txt' => 'Just adds commentary',
1039     'NormalizationCorrections.txt' => 'Data is already in other files.',
1040     'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
1041     'ReadMe.txt' => 'Just comments',
1042     'README.TXT' => 'Just comments',
1043     'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
1044     'EmojiSources.txt' => 'Not of general utility: for Japanese legacy cell-phone applications',
1045     'IndicMatraCategory.txt' => 'Provisional',
1046     'IndicSyllabicCategory.txt' => 'Provisional',
1047     'ScriptExtensions.txt' => 'Provisional',
1048 );
1049
1050 ### End of externally interesting definitions, except for @input_file_objects
1051
1052 my $HEADER=<<"EOF";
1053 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1054 # This file is machine-generated by $0 from the Unicode
1055 # database, Version $string_version.  Any changes made here will be lost!
1056 EOF
1057
1058 my $INTERNAL_ONLY=<<"EOF";
1059
1060 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1061 # This file is for internal use by the Perl program only.  The format and even
1062 # the name or existence of this file are subject to change without notice.
1063 # Don't use it directly.
1064 EOF
1065
1066 my $DEVELOPMENT_ONLY=<<"EOF";
1067 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1068 # This file contains information artificially constrained to code points
1069 # present in Unicode release $string_compare_versions.
1070 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1071 # not be used for production.
1072
1073 EOF
1074
1075 my $LAST_UNICODE_CODEPOINT_STRING = "10FFFF";
1076 my $LAST_UNICODE_CODEPOINT = hex $LAST_UNICODE_CODEPOINT_STRING;
1077 my $MAX_UNICODE_CODEPOINTS = $LAST_UNICODE_CODEPOINT + 1;
1078
1079 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1080 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1081 # to decrease backtracking
1082 my $code_point_re =
1083         qr/ \b (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1084
1085 # This matches the beginning of the line in the Unicode db files that give the
1086 # defaults for code points not listed (i.e., missing) in the file.  The code
1087 # depends on this ending with a semi-colon, so it can assume it is a valid
1088 # field when the line is split() by semi-colons
1089 my $missing_defaults_prefix =
1090             qr/^#\s+\@missing:\s+0000\.\.$LAST_UNICODE_CODEPOINT_STRING\s*;/;
1091
1092 # Property types.  Unicode has more types, but these are sufficient for our
1093 # purposes.
1094 my $UNKNOWN = -1;   # initialized to illegal value
1095 my $NON_STRING = 1; # Either binary or enum
1096 my $BINARY = 2;
1097 my $ENUM = 3;       # Include catalog
1098 my $STRING = 4;     # Anything else: string or misc
1099
1100 # Some input files have lines that give default values for code points not
1101 # contained in the file.  Sometimes these should be ignored.
1102 my $NO_DEFAULTS = 0;        # Must evaluate to false
1103 my $NOT_IGNORED = 1;
1104 my $IGNORED = 2;
1105
1106 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1107 # and will appear in the main body of the tables in the output files, but
1108 # there are other types of ranges as well, listed below, that are specially
1109 # handled.   There are pseudo-types as well that will never be stored as a
1110 # type, but will affect the calculation of the type.
1111
1112 # 0 is for normal, non-specials
1113 my $MULTI_CP = 1;           # Sequence of more than code point
1114 my $HANGUL_SYLLABLE = 2;
1115 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1116 my $NULL = 4;               # The map is to the null string; utf8.c can't
1117                             # handle these, nor is there an accepted syntax
1118                             # for them in \p{} constructs
1119 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1120                              # otherwise be $MULTI_CP type are instead type 0
1121
1122 # process_generic_property_file() can accept certain overrides in its input.
1123 # Each of these must begin AND end with $CMD_DELIM.
1124 my $CMD_DELIM = "\a";
1125 my $REPLACE_CMD = 'replace';    # Override the Replace
1126 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1127
1128 my $NO = 0;
1129 my $YES = 1;
1130
1131 # Values for the Replace argument to add_range.
1132 # $NO                      # Don't replace; add only the code points not
1133                            # already present.
1134 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1135                            # the comments at the subroutine definition.
1136 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1137 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1138                            # already there
1139 my $CROAK = 5;             # Die with an error if is already there
1140
1141 # Flags to give property statuses.  The phrases are to remind maintainers that
1142 # if the flag is changed, the indefinite article referring to it in the
1143 # documentation may need to be as well.
1144 my $NORMAL = "";
1145 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1146                         # it is suppressed
1147 my $PLACEHOLDER = 'P';  # Implies no pod entry generated
1148 my $DEPRECATED = 'D';
1149 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1150 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1151 my $DISCOURAGED = 'X';
1152 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1153 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1154 my $STRICTER = 'T';
1155 my $a_bold_stricter = "a 'B<$STRICTER>'";
1156 my $A_bold_stricter = "A 'B<$STRICTER>'";
1157 my $STABILIZED = 'S';
1158 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1159 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1160 my $OBSOLETE = 'O';
1161 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1162 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1163
1164 my %status_past_participles = (
1165     $DISCOURAGED => 'discouraged',
1166     $SUPPRESSED => 'should never be generated',
1167     $STABILIZED => 'stabilized',
1168     $OBSOLETE => 'obsolete',
1169     $DEPRECATED => 'deprecated',
1170 );
1171
1172 # The format of the values of the tables:
1173 my $EMPTY_FORMAT = "";
1174 my $BINARY_FORMAT = 'b';
1175 my $DECIMAL_FORMAT = 'd';
1176 my $FLOAT_FORMAT = 'f';
1177 my $INTEGER_FORMAT = 'i';
1178 my $HEX_FORMAT = 'x';
1179 my $RATIONAL_FORMAT = 'r';
1180 my $STRING_FORMAT = 's';
1181 my $DECOMP_STRING_FORMAT = 'c';
1182
1183 my %map_table_formats = (
1184     $BINARY_FORMAT => 'binary',
1185     $DECIMAL_FORMAT => 'single decimal digit',
1186     $FLOAT_FORMAT => 'floating point number',
1187     $INTEGER_FORMAT => 'integer',
1188     $HEX_FORMAT => 'positive hex whole number; a code point',
1189     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1190     $STRING_FORMAT => 'string',
1191     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1192 );
1193
1194 # Unicode didn't put such derived files in a separate directory at first.
1195 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1196 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1197 my $AUXILIARY = 'auxiliary';
1198
1199 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1200 my %loose_to_file_of;       # loosely maps table names to their respective
1201                             # files
1202 my %stricter_to_file_of;    # same; but for stricter mapping.
1203 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1204                              # their rational equivalent
1205 my %loose_property_name_of; # Loosely maps property names to standard form
1206
1207 # These constants names and values were taken from the Unicode standard,
1208 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1209 # syllables.  The '_string' versions are so generated tables can retain the
1210 # hex format, which is the more familiar value
1211 my $SBase_string = "0xAC00";
1212 my $SBase = CORE::hex $SBase_string;
1213 my $LBase_string = "0x1100";
1214 my $LBase = CORE::hex $LBase_string;
1215 my $VBase_string = "0x1161";
1216 my $VBase = CORE::hex $VBase_string;
1217 my $TBase_string = "0x11A7";
1218 my $TBase = CORE::hex $TBase_string;
1219 my $SCount = 11172;
1220 my $LCount = 19;
1221 my $VCount = 21;
1222 my $TCount = 28;
1223 my $NCount = $VCount * $TCount;
1224
1225 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1226 # with the above published constants.
1227 my %Jamo;
1228 my %Jamo_L;     # Leading consonants
1229 my %Jamo_V;     # Vowels
1230 my %Jamo_T;     # Trailing consonants
1231
1232 my @backslash_X_tests;     # List of tests read in for testing \X
1233 my @unhandled_properties;  # Will contain a list of properties found in
1234                            # the input that we didn't process.
1235 my @match_properties;      # Properties that have match tables, to be
1236                            # listed in the pod
1237 my @map_properties;        # Properties that get map files written
1238 my @named_sequences;       # NamedSequences.txt contents.
1239 my %potential_files;       # Generated list of all .txt files in the directory
1240                            # structure so we can warn if something is being
1241                            # ignored.
1242 my @files_actually_output; # List of files we generated.
1243 my @more_Names;            # Some code point names are compound; this is used
1244                            # to store the extra components of them.
1245 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1246                            # the minimum before we consider it equivalent to a
1247                            # candidate rational
1248 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1249
1250 # These store references to certain commonly used property objects
1251 my $gc;
1252 my $perl;
1253 my $block;
1254 my $perl_charname;
1255 my $print;
1256
1257 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1258 my $has_In_conflicts = 0;
1259 my $has_Is_conflicts = 0;
1260
1261 sub internal_file_to_platform ($) {
1262     # Convert our file paths which have '/' separators to those of the
1263     # platform.
1264
1265     my $file = shift;
1266     return undef unless defined $file;
1267
1268     return File::Spec->join(split '/', $file);
1269 }
1270
1271 sub file_exists ($) {   # platform independent '-e'.  This program internally
1272                         # uses slash as a path separator.
1273     my $file = shift;
1274     return 0 if ! defined $file;
1275     return -e internal_file_to_platform($file);
1276 }
1277
1278 sub objaddr($) {
1279     # Returns the address of the blessed input object.
1280     # It doesn't check for blessedness because that would do a string eval
1281     # every call, and the program is structured so that this is never called
1282     # for a non-blessed object.
1283
1284     no overloading; # If overloaded, numifying below won't work.
1285
1286     # Numifying a ref gives its address.
1287     return pack 'J', $_[0];
1288 }
1289
1290 # These are used only if $annotate is true.
1291 # The entire range of Unicode characters is examined to populate these
1292 # after all the input has been processed.  But most can be skipped, as they
1293 # have the same descriptive phrases, such as being unassigned
1294 my @viacode;            # Contains the 1 million character names
1295 my @printable;          # boolean: And are those characters printable?
1296 my @annotate_char_type; # Contains a type of those characters, specifically
1297                         # for the purposes of annotation.
1298 my $annotate_ranges;    # A map of ranges of code points that have the same
1299                         # name for the purposes of annoation.  They map to the
1300                         # upper edge of the range, so that the end point can
1301                         # be immediately found.  This is used to skip ahead to
1302                         # the end of a range, and avoid processing each
1303                         # individual code point in it.
1304 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1305                                    # characters, but excluding those which are
1306                                    # also noncharacter code points
1307
1308 # The annotation types are an extension of the regular range types, though
1309 # some of the latter are folded into one.  Make the new types negative to
1310 # avoid conflicting with the regular types
1311 my $SURROGATE_TYPE = -1;
1312 my $UNASSIGNED_TYPE = -2;
1313 my $PRIVATE_USE_TYPE = -3;
1314 my $NONCHARACTER_TYPE = -4;
1315 my $CONTROL_TYPE = -5;
1316 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1317
1318 sub populate_char_info ($) {
1319     # Used only with the $annotate option.  Populates the arrays with the
1320     # input code point's info that are needed for outputting more detailed
1321     # comments.  If calling context wants a return, it is the end point of
1322     # any contiguous range of characters that share essentially the same info
1323
1324     my $i = shift;
1325     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1326
1327     $viacode[$i] = $perl_charname->value_of($i) || "";
1328
1329     # A character is generally printable if Unicode says it is,
1330     # but below we make sure that most Unicode general category 'C' types
1331     # aren't.
1332     $printable[$i] = $print->contains($i);
1333
1334     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1335
1336     # Only these two regular types are treated specially for annotations
1337     # purposes
1338     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1339                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1340
1341     # Give a generic name to all code points that don't have a real name.
1342     # We output ranges, if applicable, for these.  Also calculate the end
1343     # point of the range.
1344     my $end;
1345     if (! $viacode[$i]) {
1346         if ($gc-> table('Surrogate')->contains($i)) {
1347             $viacode[$i] = 'Surrogate';
1348             $annotate_char_type[$i] = $SURROGATE_TYPE;
1349             $printable[$i] = 0;
1350             $end = $gc->table('Surrogate')->containing_range($i)->end;
1351         }
1352         elsif ($gc-> table('Private_use')->contains($i)) {
1353             $viacode[$i] = 'Private Use';
1354             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1355             $printable[$i] = 0;
1356             $end = $gc->table('Private_Use')->containing_range($i)->end;
1357         }
1358         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1359                                                                 contains($i))
1360         {
1361             $viacode[$i] = 'Noncharacter';
1362             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1363             $printable[$i] = 0;
1364             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1365                                                     containing_range($i)->end;
1366         }
1367         elsif ($gc-> table('Control')->contains($i)) {
1368             $viacode[$i] = 'Control';
1369             $annotate_char_type[$i] = $CONTROL_TYPE;
1370             $printable[$i] = 0;
1371             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1372         }
1373         elsif ($gc-> table('Unassigned')->contains($i)) {
1374             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1375             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1376             $printable[$i] = 0;
1377
1378             # Because we name the unassigned by the blocks they are in, it
1379             # can't go past the end of that block, and it also can't go past
1380             # the unassigned range it is in.  The special table makes sure
1381             # that the non-characters, which are unassigned, are separated
1382             # out.
1383             $end = min($block->containing_range($i)->end,
1384                        $unassigned_sans_noncharacters-> containing_range($i)->
1385                                                                          end);
1386         }
1387         else {
1388             Carp::my_carp_bug("Can't figure out how to annotate "
1389                               . sprintf("U+%04X", $i)
1390                               . ".  Proceeding anyway.");
1391             $viacode[$i] = 'UNKNOWN';
1392             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1393             $printable[$i] = 0;
1394         }
1395     }
1396
1397     # Here, has a name, but if it's one in which the code point number is
1398     # appended to the name, do that.
1399     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1400         $viacode[$i] .= sprintf("-%04X", $i);
1401         $end = $perl_charname->containing_range($i)->end;
1402     }
1403
1404     # And here, has a name, but if it's a hangul syllable one, replace it with
1405     # the correct name from the Unicode algorithm
1406     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1407         use integer;
1408         my $SIndex = $i - $SBase;
1409         my $L = $LBase + $SIndex / $NCount;
1410         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1411         my $T = $TBase + $SIndex % $TCount;
1412         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1413         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1414         $end = $perl_charname->containing_range($i)->end;
1415     }
1416
1417     return if ! defined wantarray;
1418     return $i if ! defined $end;    # If not a range, return the input
1419
1420     # Save this whole range so can find the end point quickly
1421     $annotate_ranges->add_map($i, $end, $end);
1422
1423     return $end;
1424 }
1425
1426 # Commented code below should work on Perl 5.8.
1427 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1428 ## the native perl version of it (which is what would operate under miniperl)
1429 ## is extremely slow, as it does a string eval every call.
1430 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1431 #                            && defined eval "require Scalar::Util";
1432 #
1433 #sub objaddr($) {
1434 #    # Returns the address of the blessed input object.  Uses the XS version if
1435 #    # available.  It doesn't check for blessedness because that would do a
1436 #    # string eval every call, and the program is structured so that this is
1437 #    # never called for a non-blessed object.
1438 #
1439 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1440 #
1441 #    # Check at least that is a ref.
1442 #    my $pkg = ref($_[0]) or return undef;
1443 #
1444 #    # Change to a fake package to defeat any overloaded stringify
1445 #    bless $_[0], 'main::Fake';
1446 #
1447 #    # Numifying a ref gives its address.
1448 #    my $addr = pack 'J', $_[0];
1449 #
1450 #    # Return to original class
1451 #    bless $_[0], $pkg;
1452 #    return $addr;
1453 #}
1454
1455 sub max ($$) {
1456     my $a = shift;
1457     my $b = shift;
1458     return $a if $a >= $b;
1459     return $b;
1460 }
1461
1462 sub min ($$) {
1463     my $a = shift;
1464     my $b = shift;
1465     return $a if $a <= $b;
1466     return $b;
1467 }
1468
1469 sub clarify_number ($) {
1470     # This returns the input number with underscores inserted every 3 digits
1471     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1472     # checked.
1473
1474     my $number = shift;
1475     my $pos = length($number) - 3;
1476     return $number if $pos <= 1;
1477     while ($pos > 0) {
1478         substr($number, $pos, 0) = '_';
1479         $pos -= 3;
1480     }
1481     return $number;
1482 }
1483
1484
1485 package Carp;
1486
1487 # These routines give a uniform treatment of messages in this program.  They
1488 # are placed in the Carp package to cause the stack trace to not include them,
1489 # although an alternative would be to use another package and set @CARP_NOT
1490 # for it.
1491
1492 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1493
1494 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1495 # and overload trying to load Scalar:Util under miniperl.  See
1496 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1497 undef $overload::VERSION;
1498
1499 sub my_carp {
1500     my $message = shift || "";
1501     my $nofold = shift || 0;
1502
1503     if ($message) {
1504         $message = main::join_lines($message);
1505         $message =~ s/^$0: *//;     # Remove initial program name
1506         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1507         $message = "\n$0: $message;";
1508
1509         # Fold the message with program name, semi-colon end punctuation
1510         # (which looks good with the message that carp appends to it), and a
1511         # hanging indent for continuation lines.
1512         $message = main::simple_fold($message, "", 4) unless $nofold;
1513         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1514                                     # appends is to the same line
1515     }
1516
1517     return $message if defined wantarray;   # If a caller just wants the msg
1518
1519     carp $message;
1520     return;
1521 }
1522
1523 sub my_carp_bug {
1524     # This is called when it is clear that the problem is caused by a bug in
1525     # this program.
1526
1527     my $message = shift;
1528     $message =~ s/^$0: *//;
1529     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1530     carp $message;
1531     return;
1532 }
1533
1534 sub carp_too_few_args {
1535     if (@_ != 2) {
1536         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1537         return;
1538     }
1539
1540     my $args_ref = shift;
1541     my $count = shift;
1542
1543     my_carp_bug("Need at least $count arguments to "
1544         . (caller 1)[3]
1545         . ".  Instead got: '"
1546         . join ', ', @$args_ref
1547         . "'.  No action taken.");
1548     return;
1549 }
1550
1551 sub carp_extra_args {
1552     my $args_ref = shift;
1553     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1554
1555     unless (ref $args_ref) {
1556         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1557         return;
1558     }
1559     my ($package, $file, $line) = caller;
1560     my $subroutine = (caller 1)[3];
1561
1562     my $list;
1563     if (ref $args_ref eq 'HASH') {
1564         foreach my $key (keys %$args_ref) {
1565             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1566         }
1567         $list = join ', ', each %{$args_ref};
1568     }
1569     elsif (ref $args_ref eq 'ARRAY') {
1570         foreach my $arg (@$args_ref) {
1571             $arg = $UNDEF unless defined $arg;
1572         }
1573         $list = join ', ', @$args_ref;
1574     }
1575     else {
1576         my_carp_bug("Can't cope with ref "
1577                 . ref($args_ref)
1578                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1579         return;
1580     }
1581
1582     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1583     return;
1584 }
1585
1586 package main;
1587
1588 { # Closure
1589
1590     # This program uses the inside-out method for objects, as recommended in
1591     # "Perl Best Practices".  This closure aids in generating those.  There
1592     # are two routines.  setup_package() is called once per package to set
1593     # things up, and then set_access() is called for each hash representing a
1594     # field in the object.  These routines arrange for the object to be
1595     # properly destroyed when no longer used, and for standard accessor
1596     # functions to be generated.  If you need more complex accessors, just
1597     # write your own and leave those accesses out of the call to set_access().
1598     # More details below.
1599
1600     my %constructor_fields; # fields that are to be used in constructors; see
1601                             # below
1602
1603     # The values of this hash will be the package names as keys to other
1604     # hashes containing the name of each field in the package as keys, and
1605     # references to their respective hashes as values.
1606     my %package_fields;
1607
1608     sub setup_package {
1609         # Sets up the package, creating standard DESTROY and dump methods
1610         # (unless already defined).  The dump method is used in debugging by
1611         # simple_dumper().
1612         # The optional parameters are:
1613         #   a)  a reference to a hash, that gets populated by later
1614         #       set_access() calls with one of the accesses being
1615         #       'constructor'.  The caller can then refer to this, but it is
1616         #       not otherwise used by these two routines.
1617         #   b)  a reference to a callback routine to call during destruction
1618         #       of the object, before any fields are actually destroyed
1619
1620         my %args = @_;
1621         my $constructor_ref = delete $args{'Constructor_Fields'};
1622         my $destroy_callback = delete $args{'Destroy_Callback'};
1623         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1624
1625         my %fields;
1626         my $package = (caller)[0];
1627
1628         $package_fields{$package} = \%fields;
1629         $constructor_fields{$package} = $constructor_ref;
1630
1631         unless ($package->can('DESTROY')) {
1632             my $destroy_name = "${package}::DESTROY";
1633             no strict "refs";
1634
1635             # Use typeglob to give the anonymous subroutine the name we want
1636             *$destroy_name = sub {
1637                 my $self = shift;
1638                 my $addr = do { no overloading; pack 'J', $self; };
1639
1640                 $self->$destroy_callback if $destroy_callback;
1641                 foreach my $field (keys %{$package_fields{$package}}) {
1642                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1643                     delete $package_fields{$package}{$field}{$addr};
1644                 }
1645                 return;
1646             }
1647         }
1648
1649         unless ($package->can('dump')) {
1650             my $dump_name = "${package}::dump";
1651             no strict "refs";
1652             *$dump_name = sub {
1653                 my $self = shift;
1654                 return dump_inside_out($self, $package_fields{$package}, @_);
1655             }
1656         }
1657         return;
1658     }
1659
1660     sub set_access {
1661         # Arrange for the input field to be garbage collected when no longer
1662         # needed.  Also, creates standard accessor functions for the field
1663         # based on the optional parameters-- none if none of these parameters:
1664         #   'addable'    creates an 'add_NAME()' accessor function.
1665         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1666         #                function.
1667         #   'settable'   creates a 'set_NAME()' accessor function.
1668         #   'constructor' doesn't create an accessor function, but adds the
1669         #                field to the hash that was previously passed to
1670         #                setup_package();
1671         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1672         # 'add' etc. all mean 'addable'.
1673         # The read accessor function will work on both array and scalar
1674         # values.  If another accessor in the parameter list is 'a', the read
1675         # access assumes an array.  You can also force it to be array access
1676         # by specifying 'readable_array' instead of 'readable'
1677         #
1678         # A sort-of 'protected' access can be set-up by preceding the addable,
1679         # readable or settable with some initial portion of 'protected_' (but,
1680         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1681         # "protection" is only by convention.  All that happens is that the
1682         # accessor functions' names begin with an underscore.  So instead of
1683         # calling set_foo, the call is _set_foo.  (Real protection could be
1684         # accomplished by having a new subroutine, end_package, called at the
1685         # end of each package, and then storing the __LINE__ ranges and
1686         # checking them on every accessor.  But that is way overkill.)
1687
1688         # We create anonymous subroutines as the accessors and then use
1689         # typeglobs to assign them to the proper package and name
1690
1691         my $name = shift;   # Name of the field
1692         my $field = shift;  # Reference to the inside-out hash containing the
1693                             # field
1694
1695         my $package = (caller)[0];
1696
1697         if (! exists $package_fields{$package}) {
1698             croak "$0: Must call 'setup_package' before 'set_access'";
1699         }
1700
1701         # Stash the field so DESTROY can get it.
1702         $package_fields{$package}{$name} = $field;
1703
1704         # Remaining arguments are the accessors.  For each...
1705         foreach my $access (@_) {
1706             my $access = lc $access;
1707
1708             my $protected = "";
1709
1710             # Match the input as far as it goes.
1711             if ($access =~ /^(p[^_]*)_/) {
1712                 $protected = $1;
1713                 if (substr('protected_', 0, length $protected)
1714                     eq $protected)
1715                 {
1716
1717                     # Add 1 for the underscore not included in $protected
1718                     $access = substr($access, length($protected) + 1);
1719                     $protected = '_';
1720                 }
1721                 else {
1722                     $protected = "";
1723                 }
1724             }
1725
1726             if (substr('addable', 0, length $access) eq $access) {
1727                 my $subname = "${package}::${protected}add_$name";
1728                 no strict "refs";
1729
1730                 # add_ accessor.  Don't add if already there, which we
1731                 # determine using 'eq' for scalars and '==' otherwise.
1732                 *$subname = sub {
1733                     use strict "refs";
1734                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1735                     my $self = shift;
1736                     my $value = shift;
1737                     my $addr = do { no overloading; pack 'J', $self; };
1738                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1739                     if (ref $value) {
1740                         return if grep { $value == $_ } @{$field->{$addr}};
1741                     }
1742                     else {
1743                         return if grep { $value eq $_ } @{$field->{$addr}};
1744                     }
1745                     push @{$field->{$addr}}, $value;
1746                     return;
1747                 }
1748             }
1749             elsif (substr('constructor', 0, length $access) eq $access) {
1750                 if ($protected) {
1751                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1752                 }
1753                 else {
1754                     $constructor_fields{$package}{$name} = $field;
1755                 }
1756             }
1757             elsif (substr('readable_array', 0, length $access) eq $access) {
1758
1759                 # Here has read access.  If one of the other parameters for
1760                 # access is array, or this one specifies array (by being more
1761                 # than just 'readable_'), then create a subroutine that
1762                 # assumes the data is an array.  Otherwise just a scalar
1763                 my $subname = "${package}::${protected}$name";
1764                 if (grep { /^a/i } @_
1765                     or length($access) > length('readable_'))
1766                 {
1767                     no strict "refs";
1768                     *$subname = sub {
1769                         use strict "refs";
1770                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1771                         my $addr = do { no overloading; pack 'J', $_[0]; };
1772                         if (ref $field->{$addr} ne 'ARRAY') {
1773                             my $type = ref $field->{$addr};
1774                             $type = 'scalar' unless $type;
1775                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1776                             return;
1777                         }
1778                         return scalar @{$field->{$addr}} unless wantarray;
1779
1780                         # Make a copy; had problems with caller modifying the
1781                         # original otherwise
1782                         my @return = @{$field->{$addr}};
1783                         return @return;
1784                     }
1785                 }
1786                 else {
1787
1788                     # Here not an array value, a simpler function.
1789                     no strict "refs";
1790                     *$subname = sub {
1791                         use strict "refs";
1792                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1793                         no overloading;
1794                         return $field->{pack 'J', $_[0]};
1795                     }
1796                 }
1797             }
1798             elsif (substr('settable', 0, length $access) eq $access) {
1799                 my $subname = "${package}::${protected}set_$name";
1800                 no strict "refs";
1801                 *$subname = sub {
1802                     use strict "refs";
1803                     if (main::DEBUG) {
1804                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1805                         Carp::carp_extra_args(\@_) if @_ > 2;
1806                     }
1807                     # $self is $_[0]; $value is $_[1]
1808                     no overloading;
1809                     $field->{pack 'J', $_[0]} = $_[1];
1810                     return;
1811                 }
1812             }
1813             else {
1814                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1815             }
1816         }
1817         return;
1818     }
1819 }
1820
1821 package Input_file;
1822
1823 # All input files use this object, which stores various attributes about them,
1824 # and provides for convenient, uniform handling.  The run method wraps the
1825 # processing.  It handles all the bookkeeping of opening, reading, and closing
1826 # the file, returning only significant input lines.
1827 #
1828 # Each object gets a handler which processes the body of the file, and is
1829 # called by run().  Most should use the generic, default handler, which has
1830 # code scrubbed to handle things you might not expect.  A handler should
1831 # basically be a while(next_line()) {...} loop.
1832 #
1833 # You can also set up handlers to
1834 #   1) call before the first line is read for pre processing
1835 #   2) call to adjust each line of the input before the main handler gets them
1836 #   3) call upon EOF before the main handler exits its loop
1837 #   4) call at the end for post processing
1838 #
1839 # $_ is used to store the input line, and is to be filtered by the
1840 # each_line_handler()s.  So, if the format of the line is not in the desired
1841 # format for the main handler, these are used to do that adjusting.  They can
1842 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1843 # so the $_ output of one is used as the input to the next.  None of the other
1844 # handlers are stackable, but could easily be changed to be so.
1845 #
1846 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1847 # which insert the parameters as lines to be processed before the next input
1848 # file line is read.  This allows the EOF handler to flush buffers, for
1849 # example.  The difference between the two routines is that the lines inserted
1850 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1851 # called it from such a handler, you would get infinite recursion.)  Lines
1852 # inserted by insert_adjusted_lines() go directly to the main handler without
1853 # any adjustments.  If the  post-processing handler calls any of these, there
1854 # will be no effect.  Some error checking for these conditions could be added,
1855 # but it hasn't been done.
1856 #
1857 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1858 # to prevent further processing of the line.  This routine will output the
1859 # message as a warning once, and then keep a count of the lines that have the
1860 # same message, and output that count at the end of the file's processing.
1861 # This keeps the number of messages down to a manageable amount.
1862 #
1863 # get_missings() should be called to retrieve any @missing input lines.
1864 # Messages will be raised if this isn't done if the options aren't to ignore
1865 # missings.
1866
1867 sub trace { return main::trace(@_); }
1868
1869 { # Closure
1870     # Keep track of fields that are to be put into the constructor.
1871     my %constructor_fields;
1872
1873     main::setup_package(Constructor_Fields => \%constructor_fields);
1874
1875     my %file; # Input file name, required
1876     main::set_access('file', \%file, qw{ c r });
1877
1878     my %first_released; # Unicode version file was first released in, required
1879     main::set_access('first_released', \%first_released, qw{ c r });
1880
1881     my %handler;    # Subroutine to process the input file, defaults to
1882                     # 'process_generic_property_file'
1883     main::set_access('handler', \%handler, qw{ c });
1884
1885     my %property;
1886     # name of property this file is for.  defaults to none, meaning not
1887     # applicable, or is otherwise determinable, for example, from each line.
1888     main::set_access('property', \%property, qw{ c });
1889
1890     my %optional;
1891     # If this is true, the file is optional.  If not present, no warning is
1892     # output.  If it is present, the string given by this parameter is
1893     # evaluated, and if false the file is not processed.
1894     main::set_access('optional', \%optional, 'c', 'r');
1895
1896     my %non_skip;
1897     # This is used for debugging, to skip processing of all but a few input
1898     # files.  Add 'non_skip => 1' to the constructor for those files you want
1899     # processed when you set the $debug_skip global.
1900     main::set_access('non_skip', \%non_skip, 'c');
1901
1902     my %skip;
1903     # This is used to skip processing of this input file semi-permanently.
1904     # It is used for files that we aren't planning to process anytime soon,
1905     # but want to allow to be in the directory and not raise a message that we
1906     # are not handling.  Mostly for test files.  This is in contrast to the
1907     # non_skip element, which is supposed to be used very temporarily for
1908     # debugging.  Sets 'optional' to 1
1909     main::set_access('skip', \%skip, 'c');
1910
1911     my %each_line_handler;
1912     # list of subroutines to look at and filter each non-comment line in the
1913     # file.  defaults to none.  The subroutines are called in order, each is
1914     # to adjust $_ for the next one, and the final one adjusts it for
1915     # 'handler'
1916     main::set_access('each_line_handler', \%each_line_handler, 'c');
1917
1918     my %has_missings_defaults;
1919     # ? Are there lines in the file giving default values for code points
1920     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1921     # the norm, but IGNORED means it has such lines, but the handler doesn't
1922     # use them.  Having these three states allows us to catch changes to the
1923     # UCD that this program should track
1924     main::set_access('has_missings_defaults',
1925                                         \%has_missings_defaults, qw{ c r });
1926
1927     my %pre_handler;
1928     # Subroutine to call before doing anything else in the file.  If undef, no
1929     # such handler is called.
1930     main::set_access('pre_handler', \%pre_handler, qw{ c });
1931
1932     my %eof_handler;
1933     # Subroutine to call upon getting an EOF on the input file, but before
1934     # that is returned to the main handler.  This is to allow buffers to be
1935     # flushed.  The handler is expected to call insert_lines() or
1936     # insert_adjusted() with the buffered material
1937     main::set_access('eof_handler', \%eof_handler, qw{ c r });
1938
1939     my %post_handler;
1940     # Subroutine to call after all the lines of the file are read in and
1941     # processed.  If undef, no such handler is called.
1942     main::set_access('post_handler', \%post_handler, qw{ c });
1943
1944     my %progress_message;
1945     # Message to print to display progress in lieu of the standard one
1946     main::set_access('progress_message', \%progress_message, qw{ c });
1947
1948     my %handle;
1949     # cache open file handle, internal.  Is undef if file hasn't been
1950     # processed at all, empty if has;
1951     main::set_access('handle', \%handle);
1952
1953     my %added_lines;
1954     # cache of lines added virtually to the file, internal
1955     main::set_access('added_lines', \%added_lines);
1956
1957     my %errors;
1958     # cache of errors found, internal
1959     main::set_access('errors', \%errors);
1960
1961     my %missings;
1962     # storage of '@missing' defaults lines
1963     main::set_access('missings', \%missings);
1964
1965     sub new {
1966         my $class = shift;
1967
1968         my $self = bless \do{ my $anonymous_scalar }, $class;
1969         my $addr = do { no overloading; pack 'J', $self; };
1970
1971         # Set defaults
1972         $handler{$addr} = \&main::process_generic_property_file;
1973         $non_skip{$addr} = 0;
1974         $skip{$addr} = 0;
1975         $has_missings_defaults{$addr} = $NO_DEFAULTS;
1976         $handle{$addr} = undef;
1977         $added_lines{$addr} = [ ];
1978         $each_line_handler{$addr} = [ ];
1979         $errors{$addr} = { };
1980         $missings{$addr} = [ ];
1981
1982         # Two positional parameters.
1983         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1984         $file{$addr} = main::internal_file_to_platform(shift);
1985         $first_released{$addr} = shift;
1986
1987         # The rest of the arguments are key => value pairs
1988         # %constructor_fields has been set up earlier to list all possible
1989         # ones.  Either set or push, depending on how the default has been set
1990         # up just above.
1991         my %args = @_;
1992         foreach my $key (keys %args) {
1993             my $argument = $args{$key};
1994
1995             # Note that the fields are the lower case of the constructor keys
1996             my $hash = $constructor_fields{lc $key};
1997             if (! defined $hash) {
1998                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
1999                 next;
2000             }
2001             if (ref $hash->{$addr} eq 'ARRAY') {
2002                 if (ref $argument eq 'ARRAY') {
2003                     foreach my $argument (@{$argument}) {
2004                         next if ! defined $argument;
2005                         push @{$hash->{$addr}}, $argument;
2006                     }
2007                 }
2008                 else {
2009                     push @{$hash->{$addr}}, $argument if defined $argument;
2010                 }
2011             }
2012             else {
2013                 $hash->{$addr} = $argument;
2014             }
2015             delete $args{$key};
2016         };
2017
2018         # If the file has a property for it, it means that the property is not
2019         # listed in the file's entries.  So add a handler to the list of line
2020         # handlers to insert the property name into the lines, to provide a
2021         # uniform interface to the final processing subroutine.
2022         # the final code doesn't have to worry about that.
2023         if ($property{$addr}) {
2024             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2025         }
2026
2027         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2028             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2029         }
2030
2031         $optional{$addr} = 1 if $skip{$addr};
2032
2033         return $self;
2034     }
2035
2036
2037     use overload
2038         fallback => 0,
2039         qw("") => "_operator_stringify",
2040         "." => \&main::_operator_dot,
2041     ;
2042
2043     sub _operator_stringify {
2044         my $self = shift;
2045
2046         return __PACKAGE__ . " object for " . $self->file;
2047     }
2048
2049     # flag to make sure extracted files are processed early
2050     my $seen_non_extracted_non_age = 0;
2051
2052     sub run {
2053         # Process the input object $self.  This opens and closes the file and
2054         # calls all the handlers for it.  Currently,  this can only be called
2055         # once per file, as it destroy's the EOF handler
2056
2057         my $self = shift;
2058         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2059
2060         my $addr = do { no overloading; pack 'J', $self; };
2061
2062         my $file = $file{$addr};
2063
2064         # Don't process if not expecting this file (because released later
2065         # than this Unicode version), and isn't there.  This means if someone
2066         # copies it into an earlier version's directory, we will go ahead and
2067         # process it.
2068         return if $first_released{$addr} gt $v_version && ! -e $file;
2069
2070         # If in debugging mode and this file doesn't have the non-skip
2071         # flag set, and isn't one of the critical files, skip it.
2072         if ($debug_skip
2073             && $first_released{$addr} ne v0
2074             && ! $non_skip{$addr})
2075         {
2076             print "Skipping $file in debugging\n" if $verbosity;
2077             return;
2078         }
2079
2080         # File could be optional
2081         if ($optional{$addr}) {
2082             return unless -e $file;
2083             my $result = eval $optional{$addr};
2084             if (! defined $result) {
2085                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2086                 return;
2087             }
2088             if (! $result) {
2089                 if ($verbosity) {
2090                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2091                 }
2092                 return;
2093             }
2094         }
2095
2096         if (! defined $file || ! -e $file) {
2097
2098             # If the file doesn't exist, see if have internal data for it
2099             # (based on first_released being 0).
2100             if ($first_released{$addr} eq v0) {
2101                 $handle{$addr} = 'pretend_is_open';
2102             }
2103             else {
2104                 if (! $optional{$addr}  # File could be optional
2105                     && $v_version ge $first_released{$addr})
2106                 {
2107                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2108                 }
2109                 return;
2110             }
2111         }
2112         else {
2113
2114             # Here, the file exists.  Some platforms may change the case of
2115             # its name
2116             if ($seen_non_extracted_non_age) {
2117                 if ($file =~ /$EXTRACTED/i) {
2118                     Carp::my_carp_bug(join_lines(<<END
2119 $file should be processed just after the 'Prop...Alias' files, and before
2120 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2121 have subtle problems
2122 END
2123                     ));
2124                 }
2125             }
2126             elsif ($EXTRACTED_DIR
2127                     && $first_released{$addr} ne v0
2128                     && $file !~ /$EXTRACTED/i
2129                     && lc($file) ne 'dage.txt')
2130             {
2131                 # We don't set this (by the 'if' above) if we have no
2132                 # extracted directory, so if running on an early version,
2133                 # this test won't work.  Not worth worrying about.
2134                 $seen_non_extracted_non_age = 1;
2135             }
2136
2137             # And mark the file as having being processed, and warn if it
2138             # isn't a file we are expecting.  As we process the files,
2139             # they are deleted from the hash, so any that remain at the
2140             # end of the program are files that we didn't process.
2141             my $fkey = File::Spec->rel2abs($file);
2142             my $expecting = delete $potential_files{$fkey};
2143             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
2144             Carp::my_carp("Was not expecting '$file'.") if
2145                     ! $expecting
2146                     && ! defined $handle{$addr};
2147
2148             # Having deleted from expected files, we can quit if not to do
2149             # anything.  Don't print progress unless really want verbosity
2150             if ($skip{$addr}) {
2151                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2152                 return;
2153             }
2154
2155             # Open the file, converting the slashes used in this program
2156             # into the proper form for the OS
2157             my $file_handle;
2158             if (not open $file_handle, "<", $file) {
2159                 Carp::my_carp("Can't open $file.  Skipping: $!");
2160                 return 0;
2161             }
2162             $handle{$addr} = $file_handle; # Cache the open file handle
2163         }
2164
2165         if ($verbosity >= $PROGRESS) {
2166             if ($progress_message{$addr}) {
2167                 print "$progress_message{$addr}\n";
2168             }
2169             else {
2170                 # If using a virtual file, say so.
2171                 print "Processing ", (-e $file)
2172                                        ? $file
2173                                        : "substitute $file",
2174                                      "\n";
2175             }
2176         }
2177
2178
2179         # Call any special handler for before the file.
2180         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2181
2182         # Then the main handler
2183         &{$handler{$addr}}($self);
2184
2185         # Then any special post-file handler.
2186         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2187
2188         # If any errors have been accumulated, output the counts (as the first
2189         # error message in each class was output when it was encountered).
2190         if ($errors{$addr}) {
2191             my $total = 0;
2192             my $types = 0;
2193             foreach my $error (keys %{$errors{$addr}}) {
2194                 $total += $errors{$addr}->{$error};
2195                 delete $errors{$addr}->{$error};
2196                 $types++;
2197             }
2198             if ($total > 1) {
2199                 my $message
2200                         = "A total of $total lines had errors in $file.  ";
2201
2202                 $message .= ($types == 1)
2203                             ? '(Only the first one was displayed.)'
2204                             : '(Only the first of each type was displayed.)';
2205                 Carp::my_carp($message);
2206             }
2207         }
2208
2209         if (@{$missings{$addr}}) {
2210             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2211         }
2212
2213         # If a real file handle, close it.
2214         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2215                                                         ref $handle{$addr};
2216         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2217                                # the file, as opposed to undef
2218         return;
2219     }
2220
2221     sub next_line {
2222         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2223         # if such a line exists.  'logical' means that any lines that have
2224         # been added via insert_lines() will be returned in $_ before the file
2225         # is read again.
2226
2227         my $self = shift;
2228         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2229
2230         my $addr = do { no overloading; pack 'J', $self; };
2231
2232         # Here the file is open (or if the handle is not a ref, is an open
2233         # 'virtual' file).  Get the next line; any inserted lines get priority
2234         # over the file itself.
2235         my $adjusted;
2236
2237         LINE:
2238         while (1) { # Loop until find non-comment, non-empty line
2239             #local $to_trace = 1 if main::DEBUG;
2240             my $inserted_ref = shift @{$added_lines{$addr}};
2241             if (defined $inserted_ref) {
2242                 ($adjusted, $_) = @{$inserted_ref};
2243                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2244                 return 1 if $adjusted;
2245             }
2246             else {
2247                 last if ! ref $handle{$addr}; # Don't read unless is real file
2248                 last if ! defined ($_ = readline $handle{$addr});
2249             }
2250             chomp;
2251             trace $_ if main::DEBUG && $to_trace;
2252
2253             # See if this line is the comment line that defines what property
2254             # value that code points that are not listed in the file should
2255             # have.  The format or existence of these lines is not guaranteed
2256             # by Unicode since they are comments, but the documentation says
2257             # that this was added for machine-readability, so probably won't
2258             # change.  This works starting in Unicode Version 5.0.  They look
2259             # like:
2260             #
2261             # @missing: 0000..10FFFF; Not_Reordered
2262             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2263             # @missing: 0000..10FFFF; ; NaN
2264             #
2265             # Save the line for a later get_missings() call.
2266             if (/$missing_defaults_prefix/) {
2267                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2268                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2269                 }
2270                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2271                     my @defaults = split /\s* ; \s*/x, $_;
2272
2273                     # The first field is the @missing, which ends in a
2274                     # semi-colon, so can safely shift.
2275                     shift @defaults;
2276
2277                     # Some of these lines may have empty field placeholders
2278                     # which get in the way.  An example is:
2279                     # @missing: 0000..10FFFF; ; NaN
2280                     # Remove them.  Process starting from the top so the
2281                     # splice doesn't affect things still to be looked at.
2282                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2283                         next if $defaults[$i] ne "";
2284                         splice @defaults, $i, 1;
2285                     }
2286
2287                     # What's left should be just the property (maybe) and the
2288                     # default.  Having only one element means it doesn't have
2289                     # the property.
2290                     my $default;
2291                     my $property;
2292                     if (@defaults >= 1) {
2293                         if (@defaults == 1) {
2294                             $default = $defaults[0];
2295                         }
2296                         else {
2297                             $property = $defaults[0];
2298                             $default = $defaults[1];
2299                         }
2300                     }
2301
2302                     if (@defaults < 1
2303                         || @defaults > 2
2304                         || ($default =~ /^</
2305                             && $default !~ /^<code *point>$/i
2306                             && $default !~ /^<none>$/i))
2307                     {
2308                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2309                     }
2310                     else {
2311
2312                         # If the property is missing from the line, it should
2313                         # be the one for the whole file
2314                         $property = $property{$addr} if ! defined $property;
2315
2316                         # Change <none> to the null string, which is what it
2317                         # really means.  If the default is the code point
2318                         # itself, set it to <code point>, which is what
2319                         # Unicode uses (but sometimes they've forgotten the
2320                         # space)
2321                         if ($default =~ /^<none>$/i) {
2322                             $default = "";
2323                         }
2324                         elsif ($default =~ /^<code *point>$/i) {
2325                             $default = $CODE_POINT;
2326                         }
2327
2328                         # Store them as a sub-arrays with both components.
2329                         push @{$missings{$addr}}, [ $default, $property ];
2330                     }
2331                 }
2332
2333                 # There is nothing for the caller to process on this comment
2334                 # line.
2335                 next;
2336             }
2337
2338             # Remove comments and trailing space, and skip this line if the
2339             # result is empty
2340             s/#.*//;
2341             s/\s+$//;
2342             next if /^$/;
2343
2344             # Call any handlers for this line, and skip further processing of
2345             # the line if the handler sets the line to null.
2346             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2347                 &{$sub_ref}($self);
2348                 next LINE if /^$/;
2349             }
2350
2351             # Here the line is ok.  return success.
2352             return 1;
2353         } # End of looping through lines.
2354
2355         # If there is an EOF handler, call it (only once) and if it generates
2356         # more lines to process go back in the loop to handle them.
2357         if ($eof_handler{$addr}) {
2358             &{$eof_handler{$addr}}($self);
2359             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2360             goto LINE if $added_lines{$addr};
2361         }
2362
2363         # Return failure -- no more lines.
2364         return 0;
2365
2366     }
2367
2368 #   Not currently used, not fully tested.
2369 #    sub peek {
2370 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2371 #        # record.  Not callable from an each_line_handler(), nor does it call
2372 #        # an each_line_handler() on the line.
2373 #
2374 #        my $self = shift;
2375 #        my $addr = do { no overloading; pack 'J', $self; };
2376 #
2377 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2378 #            my ($adjusted, $line) = @{$inserted_ref};
2379 #            next if $adjusted;
2380 #
2381 #            # Remove comments and trailing space, and return a non-empty
2382 #            # resulting line
2383 #            $line =~ s/#.*//;
2384 #            $line =~ s/\s+$//;
2385 #            return $line if $line ne "";
2386 #        }
2387 #
2388 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2389 #        while (1) { # Loop until find non-comment, non-empty line
2390 #            local $to_trace = 1 if main::DEBUG;
2391 #            trace $_ if main::DEBUG && $to_trace;
2392 #            return if ! defined (my $line = readline $handle{$addr});
2393 #            chomp $line;
2394 #            push @{$added_lines{$addr}}, [ 0, $line ];
2395 #
2396 #            $line =~ s/#.*//;
2397 #            $line =~ s/\s+$//;
2398 #            return $line if $line ne "";
2399 #        }
2400 #
2401 #        return;
2402 #    }
2403
2404
2405     sub insert_lines {
2406         # Lines can be inserted so that it looks like they were in the input
2407         # file at the place it was when this routine is called.  See also
2408         # insert_adjusted_lines().  Lines inserted via this routine go through
2409         # any each_line_handler()
2410
2411         my $self = shift;
2412
2413         # Each inserted line is an array, with the first element being 0 to
2414         # indicate that this line hasn't been adjusted, and needs to be
2415         # processed.
2416         no overloading;
2417         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2418         return;
2419     }
2420
2421     sub insert_adjusted_lines {
2422         # Lines can be inserted so that it looks like they were in the input
2423         # file at the place it was when this routine is called.  See also
2424         # insert_lines().  Lines inserted via this routine are already fully
2425         # adjusted, ready to be processed; each_line_handler()s handlers will
2426         # not be called.  This means this is not a completely general
2427         # facility, as only the last each_line_handler on the stack should
2428         # call this.  It could be made more general, by passing to each of the
2429         # line_handlers their position on the stack, which they would pass on
2430         # to this routine, and that would replace the boolean first element in
2431         # the anonymous array pushed here, so that the next_line routine could
2432         # use that to call only those handlers whose index is after it on the
2433         # stack.  But this is overkill for what is needed now.
2434
2435         my $self = shift;
2436         trace $_[0] if main::DEBUG && $to_trace;
2437
2438         # Each inserted line is an array, with the first element being 1 to
2439         # indicate that this line has been adjusted
2440         no overloading;
2441         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2442         return;
2443     }
2444
2445     sub get_missings {
2446         # Returns the stored up @missings lines' values, and clears the list.
2447         # The values are in an array, consisting of the default in the first
2448         # element, and the property in the 2nd.  However, since these lines
2449         # can be stacked up, the return is an array of all these arrays.
2450
2451         my $self = shift;
2452         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2453
2454         my $addr = do { no overloading; pack 'J', $self; };
2455
2456         # If not accepting a list return, just return the first one.
2457         return shift @{$missings{$addr}} unless wantarray;
2458
2459         my @return = @{$missings{$addr}};
2460         undef @{$missings{$addr}};
2461         return @return;
2462     }
2463
2464     sub _insert_property_into_line {
2465         # Add a property field to $_, if this file requires it.
2466
2467         my $self = shift;
2468         my $addr = do { no overloading; pack 'J', $self; };
2469         my $property = $property{$addr};
2470         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2471
2472         $_ =~ s/(;|$)/; $property$1/;
2473         return;
2474     }
2475
2476     sub carp_bad_line {
2477         # Output consistent error messages, using either a generic one, or the
2478         # one given by the optional parameter.  To avoid gazillions of the
2479         # same message in case the syntax of a  file is way off, this routine
2480         # only outputs the first instance of each message, incrementing a
2481         # count so the totals can be output at the end of the file.
2482
2483         my $self = shift;
2484         my $message = shift;
2485         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2486
2487         my $addr = do { no overloading; pack 'J', $self; };
2488
2489         $message = 'Unexpected line' unless $message;
2490
2491         # No trailing punctuation so as to fit with our addenda.
2492         $message =~ s/[.:;,]$//;
2493
2494         # If haven't seen this exact message before, output it now.  Otherwise
2495         # increment the count of how many times it has occurred
2496         unless ($errors{$addr}->{$message}) {
2497             Carp::my_carp("$message in '$_' in "
2498                             . $file{$addr}
2499                             . " at line $..  Skipping this line;");
2500             $errors{$addr}->{$message} = 1;
2501         }
2502         else {
2503             $errors{$addr}->{$message}++;
2504         }
2505
2506         # Clear the line to prevent any further (meaningful) processing of it.
2507         $_ = "";
2508
2509         return;
2510     }
2511 } # End closure
2512
2513 package Multi_Default;
2514
2515 # Certain properties in early versions of Unicode had more than one possible
2516 # default for code points missing from the files.  In these cases, one
2517 # default applies to everything left over after all the others are applied,
2518 # and for each of the others, there is a description of which class of code
2519 # points applies to it.  This object helps implement this by storing the
2520 # defaults, and for all but that final default, an eval string that generates
2521 # the class that it applies to.
2522
2523
2524 {   # Closure
2525
2526     main::setup_package();
2527
2528     my %class_defaults;
2529     # The defaults structure for the classes
2530     main::set_access('class_defaults', \%class_defaults);
2531
2532     my %other_default;
2533     # The default that applies to everything left over.
2534     main::set_access('other_default', \%other_default, 'r');
2535
2536
2537     sub new {
2538         # The constructor is called with default => eval pairs, terminated by
2539         # the left-over default. e.g.
2540         # Multi_Default->new(
2541         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2542         #               -  0x200D',
2543         #        'R' => 'some other expression that evaluates to code points',
2544         #        .
2545         #        .
2546         #        .
2547         #        'U'));
2548
2549         my $class = shift;
2550
2551         my $self = bless \do{my $anonymous_scalar}, $class;
2552         my $addr = do { no overloading; pack 'J', $self; };
2553
2554         while (@_ > 1) {
2555             my $default = shift;
2556             my $eval = shift;
2557             $class_defaults{$addr}->{$default} = $eval;
2558         }
2559
2560         $other_default{$addr} = shift;
2561
2562         return $self;
2563     }
2564
2565     sub get_next_defaults {
2566         # Iterates and returns the next class of defaults.
2567         my $self = shift;
2568         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2569
2570         my $addr = do { no overloading; pack 'J', $self; };
2571
2572         return each %{$class_defaults{$addr}};
2573     }
2574 }
2575
2576 package Alias;
2577
2578 # An alias is one of the names that a table goes by.  This class defines them
2579 # including some attributes.  Everything is currently setup in the
2580 # constructor.
2581
2582
2583 {   # Closure
2584
2585     main::setup_package();
2586
2587     my %name;
2588     main::set_access('name', \%name, 'r');
2589
2590     my %loose_match;
2591     # Determined by the constructor code if this name should match loosely or
2592     # not.  The constructor parameters can override this, but it isn't fully
2593     # implemented, as should have ability to override Unicode one's via
2594     # something like a set_loose_match()
2595     main::set_access('loose_match', \%loose_match, 'r');
2596
2597     my %make_pod_entry;
2598     # Some aliases should not get their own entries because they are covered
2599     # by a wild-card, and some we want to discourage use of.  Binary
2600     main::set_access('make_pod_entry', \%make_pod_entry, 'r');
2601
2602     my %status;
2603     # Aliases have a status, like deprecated, or even suppressed (which means
2604     # they don't appear in documentation).  Enum
2605     main::set_access('status', \%status, 'r');
2606
2607     my %externally_ok;
2608     # Similarly, some aliases should not be considered as usable ones for
2609     # external use, such as file names, or we don't want documentation to
2610     # recommend them.  Boolean
2611     main::set_access('externally_ok', \%externally_ok, 'r');
2612
2613     sub new {
2614         my $class = shift;
2615
2616         my $self = bless \do { my $anonymous_scalar }, $class;
2617         my $addr = do { no overloading; pack 'J', $self; };
2618
2619         $name{$addr} = shift;
2620         $loose_match{$addr} = shift;
2621         $make_pod_entry{$addr} = shift;
2622         $externally_ok{$addr} = shift;
2623         $status{$addr} = shift;
2624
2625         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2626
2627         # Null names are never ok externally
2628         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2629
2630         return $self;
2631     }
2632 }
2633
2634 package Range;
2635
2636 # A range is the basic unit for storing code points, and is described in the
2637 # comments at the beginning of the program.  Each range has a starting code
2638 # point; an ending code point (not less than the starting one); a value
2639 # that applies to every code point in between the two end-points, inclusive;
2640 # and an enum type that applies to the value.  The type is for the user's
2641 # convenience, and has no meaning here, except that a non-zero type is
2642 # considered to not obey the normal Unicode rules for having standard forms.
2643 #
2644 # The same structure is used for both map and match tables, even though in the
2645 # latter, the value (and hence type) is irrelevant and could be used as a
2646 # comment.  In map tables, the value is what all the code points in the range
2647 # map to.  Type 0 values have the standardized version of the value stored as
2648 # well, so as to not have to recalculate it a lot.
2649
2650 sub trace { return main::trace(@_); }
2651
2652 {   # Closure
2653
2654     main::setup_package();
2655
2656     my %start;
2657     main::set_access('start', \%start, 'r', 's');
2658
2659     my %end;
2660     main::set_access('end', \%end, 'r', 's');
2661
2662     my %value;
2663     main::set_access('value', \%value, 'r');
2664
2665     my %type;
2666     main::set_access('type', \%type, 'r');
2667
2668     my %standard_form;
2669     # The value in internal standard form.  Defined only if the type is 0.
2670     main::set_access('standard_form', \%standard_form);
2671
2672     # Note that if these fields change, the dump() method should as well
2673
2674     sub new {
2675         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2676         my $class = shift;
2677
2678         my $self = bless \do { my $anonymous_scalar }, $class;
2679         my $addr = do { no overloading; pack 'J', $self; };
2680
2681         $start{$addr} = shift;
2682         $end{$addr} = shift;
2683
2684         my %args = @_;
2685
2686         my $value = delete $args{'Value'};  # Can be 0
2687         $value = "" unless defined $value;
2688         $value{$addr} = $value;
2689
2690         $type{$addr} = delete $args{'Type'} || 0;
2691
2692         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2693
2694         if (! $type{$addr}) {
2695             $standard_form{$addr} = main::standardize($value);
2696         }
2697
2698         return $self;
2699     }
2700
2701     use overload
2702         fallback => 0,
2703         qw("") => "_operator_stringify",
2704         "." => \&main::_operator_dot,
2705     ;
2706
2707     sub _operator_stringify {
2708         my $self = shift;
2709         my $addr = do { no overloading; pack 'J', $self; };
2710
2711         # Output it like '0041..0065 (value)'
2712         my $return = sprintf("%04X", $start{$addr})
2713                         .  '..'
2714                         . sprintf("%04X", $end{$addr});
2715         my $value = $value{$addr};
2716         my $type = $type{$addr};
2717         $return .= ' (';
2718         $return .= "$value";
2719         $return .= ", Type=$type" if $type != 0;
2720         $return .= ')';
2721
2722         return $return;
2723     }
2724
2725     sub standard_form {
2726         # The standard form is the value itself if the standard form is
2727         # undefined (that is if the value is special)
2728
2729         my $self = shift;
2730         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2731
2732         my $addr = do { no overloading; pack 'J', $self; };
2733
2734         return $standard_form{$addr} if defined $standard_form{$addr};
2735         return $value{$addr};
2736     }
2737
2738     sub dump {
2739         # Human, not machine readable.  For machine readable, comment out this
2740         # entire routine and let the standard one take effect.
2741         my $self = shift;
2742         my $indent = shift;
2743         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2744
2745         my $addr = do { no overloading; pack 'J', $self; };
2746
2747         my $return = $indent
2748                     . sprintf("%04X", $start{$addr})
2749                     . '..'
2750                     . sprintf("%04X", $end{$addr})
2751                     . " '$value{$addr}';";
2752         if (! defined $standard_form{$addr}) {
2753             $return .= "(type=$type{$addr})";
2754         }
2755         elsif ($standard_form{$addr} ne $value{$addr}) {
2756             $return .= "(standard '$standard_form{$addr}')";
2757         }
2758         return $return;
2759     }
2760 } # End closure
2761
2762 package _Range_List_Base;
2763
2764 # Base class for range lists.  A range list is simply an ordered list of
2765 # ranges, so that the ranges with the lowest starting numbers are first in it.
2766 #
2767 # When a new range is added that is adjacent to an existing range that has the
2768 # same value and type, it merges with it to form a larger range.
2769 #
2770 # Ranges generally do not overlap, except that there can be multiple entries
2771 # of single code point ranges.  This is because of NameAliases.txt.
2772 #
2773 # In this program, there is a standard value such that if two different
2774 # values, have the same standard value, they are considered equivalent.  This
2775 # value was chosen so that it gives correct results on Unicode data
2776
2777 # There are a number of methods to manipulate range lists, and some operators
2778 # are overloaded to handle them.
2779
2780 sub trace { return main::trace(@_); }
2781
2782 { # Closure
2783
2784     our $addr;
2785
2786     main::setup_package();
2787
2788     my %ranges;
2789     # The list of ranges
2790     main::set_access('ranges', \%ranges, 'readable_array');
2791
2792     my %max;
2793     # The highest code point in the list.  This was originally a method, but
2794     # actual measurements said it was used a lot.
2795     main::set_access('max', \%max, 'r');
2796
2797     my %each_range_iterator;
2798     # Iterator position for each_range()
2799     main::set_access('each_range_iterator', \%each_range_iterator);
2800
2801     my %owner_name_of;
2802     # Name of parent this is attached to, if any.  Solely for better error
2803     # messages.
2804     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2805
2806     my %_search_ranges_cache;
2807     # A cache of the previous result from _search_ranges(), for better
2808     # performance
2809     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2810
2811     sub new {
2812         my $class = shift;
2813         my %args = @_;
2814
2815         # Optional initialization data for the range list.
2816         my $initialize = delete $args{'Initialize'};
2817
2818         my $self;
2819
2820         # Use _union() to initialize.  _union() returns an object of this
2821         # class, which means that it will call this constructor recursively.
2822         # But it won't have this $initialize parameter so that it won't
2823         # infinitely loop on this.
2824         return _union($class, $initialize, %args) if defined $initialize;
2825
2826         $self = bless \do { my $anonymous_scalar }, $class;
2827         my $addr = do { no overloading; pack 'J', $self; };
2828
2829         # Optional parent object, only for debug info.
2830         $owner_name_of{$addr} = delete $args{'Owner'};
2831         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2832
2833         # Stringify, in case it is an object.
2834         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2835
2836         # This is used only for error messages, and so a colon is added
2837         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2838
2839         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2840
2841         # Max is initialized to a negative value that isn't adjacent to 0,
2842         # for simpler tests
2843         $max{$addr} = -2;
2844
2845         $_search_ranges_cache{$addr} = 0;
2846         $ranges{$addr} = [];
2847
2848         return $self;
2849     }
2850
2851     use overload
2852         fallback => 0,
2853         qw("") => "_operator_stringify",
2854         "." => \&main::_operator_dot,
2855     ;
2856
2857     sub _operator_stringify {
2858         my $self = shift;
2859         my $addr = do { no overloading; pack 'J', $self; };
2860
2861         return "Range_List attached to '$owner_name_of{$addr}'"
2862                                                 if $owner_name_of{$addr};
2863         return "anonymous Range_List " . \$self;
2864     }
2865
2866     sub _union {
2867         # Returns the union of the input code points.  It can be called as
2868         # either a constructor or a method.  If called as a method, the result
2869         # will be a new() instance of the calling object, containing the union
2870         # of that object with the other parameter's code points;  if called as
2871         # a constructor, the first parameter gives the class the new object
2872         # should be, and the second parameter gives the code points to go into
2873         # it.
2874         # In either case, there are two parameters looked at by this routine;
2875         # any additional parameters are passed to the new() constructor.
2876         #
2877         # The code points can come in the form of some object that contains
2878         # ranges, and has a conventionally named method to access them; or
2879         # they can be an array of individual code points (as integers); or
2880         # just a single code point.
2881         #
2882         # If they are ranges, this routine doesn't make any effort to preserve
2883         # the range values of one input over the other.  Therefore this base
2884         # class should not allow _union to be called from other than
2885         # initialization code, so as to prevent two tables from being added
2886         # together where the range values matter.  The general form of this
2887         # routine therefore belongs in a derived class, but it was moved here
2888         # to avoid duplication of code.  The failure to overload this in this
2889         # class keeps it safe.
2890         #
2891
2892         my $self;
2893         my @args;   # Arguments to pass to the constructor
2894
2895         my $class = shift;
2896
2897         # If a method call, will start the union with the object itself, and
2898         # the class of the new object will be the same as self.
2899         if (ref $class) {
2900             $self = $class;
2901             $class = ref $self;
2902             push @args, $self;
2903         }
2904
2905         # Add the other required parameter.
2906         push @args, shift;
2907         # Rest of parameters are passed on to the constructor
2908
2909         # Accumulate all records from both lists.
2910         my @records;
2911         for my $arg (@args) {
2912             #local $to_trace = 0 if main::DEBUG;
2913             trace "argument = $arg" if main::DEBUG && $to_trace;
2914             if (! defined $arg) {
2915                 my $message = "";
2916                 if (defined $self) {
2917                     no overloading;
2918                     $message .= $owner_name_of{pack 'J', $self};
2919                 }
2920                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
2921                 return;
2922             }
2923             $arg = [ $arg ] if ! ref $arg;
2924             my $type = ref $arg;
2925             if ($type eq 'ARRAY') {
2926                 foreach my $element (@$arg) {
2927                     push @records, Range->new($element, $element);
2928                 }
2929             }
2930             elsif ($arg->isa('Range')) {
2931                 push @records, $arg;
2932             }
2933             elsif ($arg->can('ranges')) {
2934                 push @records, $arg->ranges;
2935             }
2936             else {
2937                 my $message = "";
2938                 if (defined $self) {
2939                     no overloading;
2940                     $message .= $owner_name_of{pack 'J', $self};
2941                 }
2942                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
2943                 return;
2944             }
2945         }
2946
2947         # Sort with the range containing the lowest ordinal first, but if
2948         # two ranges start at the same code point, sort with the bigger range
2949         # of the two first, because it takes fewer cycles.
2950         @records = sort { ($a->start <=> $b->start)
2951                                       or
2952                                     # if b is shorter than a, b->end will be
2953                                     # less than a->end, and we want to select
2954                                     # a, so want to return -1
2955                                     ($b->end <=> $a->end)
2956                                    } @records;
2957
2958         my $new = $class->new(@_);
2959
2960         # Fold in records so long as they add new information.
2961         for my $set (@records) {
2962             my $start = $set->start;
2963             my $end   = $set->end;
2964             my $value   = $set->value;
2965             if ($start > $new->max) {
2966                 $new->_add_delete('+', $start, $end, $value);
2967             }
2968             elsif ($end > $new->max) {
2969                 $new->_add_delete('+', $new->max +1, $end, $value);
2970             }
2971         }
2972
2973         return $new;
2974     }
2975
2976     sub range_count {        # Return the number of ranges in the range list
2977         my $self = shift;
2978         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2979
2980         no overloading;
2981         return scalar @{$ranges{pack 'J', $self}};
2982     }
2983
2984     sub min {
2985         # Returns the minimum code point currently in the range list, or if
2986         # the range list is empty, 2 beyond the max possible.  This is a
2987         # method because used so rarely, that not worth saving between calls,
2988         # and having to worry about changing it as ranges are added and
2989         # deleted.
2990
2991         my $self = shift;
2992         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2993
2994         my $addr = do { no overloading; pack 'J', $self; };
2995
2996         # If the range list is empty, return a large value that isn't adjacent
2997         # to any that could be in the range list, for simpler tests
2998         return $LAST_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
2999         return $ranges{$addr}->[0]->start;
3000     }
3001
3002     sub contains {
3003         # Boolean: Is argument in the range list?  If so returns $i such that:
3004         #   range[$i]->end < $codepoint <= range[$i+1]->end
3005         # which is one beyond what you want; this is so that the 0th range
3006         # doesn't return false
3007         my $self = shift;
3008         my $codepoint = shift;
3009         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3010
3011         my $i = $self->_search_ranges($codepoint);
3012         return 0 unless defined $i;
3013
3014         # The search returns $i, such that
3015         #   range[$i-1]->end < $codepoint <= range[$i]->end
3016         # So is in the table if and only iff it is at least the start position
3017         # of range $i.
3018         no overloading;
3019         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3020         return $i + 1;
3021     }
3022
3023     sub containing_range {
3024         # Returns the range object that contains the code point, undef if none
3025
3026         my $self = shift;
3027         my $codepoint = shift;
3028         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3029
3030         my $i = $self->contains($codepoint);
3031         return unless $i;
3032
3033         # contains() returns 1 beyond where we should look
3034         no overloading;
3035         return $ranges{pack 'J', $self}->[$i-1];
3036     }
3037
3038     sub value_of {
3039         # Returns the value associated with the code point, undef if none
3040
3041         my $self = shift;
3042         my $codepoint = shift;
3043         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3044
3045         my $range = $self->containing_range($codepoint);
3046         return unless defined $range;
3047
3048         return $range->value;
3049     }
3050
3051     sub type_of {
3052         # Returns the type of the range containing the code point, undef if
3053         # the code point is not in the table
3054
3055         my $self = shift;
3056         my $codepoint = shift;
3057         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3058
3059         my $range = $self->containing_range($codepoint);
3060         return unless defined $range;
3061
3062         return $range->type;
3063     }
3064
3065     sub _search_ranges {
3066         # Find the range in the list which contains a code point, or where it
3067         # should go if were to add it.  That is, it returns $i, such that:
3068         #   range[$i-1]->end < $codepoint <= range[$i]->end
3069         # Returns undef if no such $i is possible (e.g. at end of table), or
3070         # if there is an error.
3071
3072         my $self = shift;
3073         my $code_point = shift;
3074         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3075
3076         my $addr = do { no overloading; pack 'J', $self; };
3077
3078         return if $code_point > $max{$addr};
3079         my $r = $ranges{$addr};                # The current list of ranges
3080         my $range_list_size = scalar @$r;
3081         my $i;
3082
3083         use integer;        # want integer division
3084
3085         # Use the cached result as the starting guess for this one, because,
3086         # an experiment on 5.1 showed that 90% of the time the cache was the
3087         # same as the result on the next call (and 7% it was one less).
3088         $i = $_search_ranges_cache{$addr};
3089         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3090                                             # from an intervening deletion
3091         #local $to_trace = 1 if main::DEBUG;
3092         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3093         return $i if $code_point <= $r->[$i]->end
3094                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3095
3096         # Here the cache doesn't yield the correct $i.  Try adding 1.
3097         if ($i < $range_list_size - 1
3098             && $r->[$i]->end < $code_point &&
3099             $code_point <= $r->[$i+1]->end)
3100         {
3101             $i++;
3102             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3103             $_search_ranges_cache{$addr} = $i;
3104             return $i;
3105         }
3106
3107         # Here, adding 1 also didn't work.  We do a binary search to
3108         # find the correct position, starting with current $i
3109         my $lower = 0;
3110         my $upper = $range_list_size - 1;
3111         while (1) {
3112             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3113
3114             if ($code_point <= $r->[$i]->end) {
3115
3116                 # Here we have met the upper constraint.  We can quit if we
3117                 # also meet the lower one.
3118                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3119
3120                 $upper = $i;        # Still too high.
3121
3122             }
3123             else {
3124
3125                 # Here, $r[$i]->end < $code_point, so look higher up.
3126                 $lower = $i;
3127             }
3128
3129             # Split search domain in half to try again.
3130             my $temp = ($upper + $lower) / 2;
3131
3132             # No point in continuing unless $i changes for next time
3133             # in the loop.
3134             if ($temp == $i) {
3135
3136                 # We can't reach the highest element because of the averaging.
3137                 # So if one below the upper edge, force it there and try one
3138                 # more time.
3139                 if ($i == $range_list_size - 2) {
3140
3141                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3142                     $i = $range_list_size - 1;
3143
3144                     # Change $lower as well so if fails next time through,
3145                     # taking the average will yield the same $i, and we will
3146                     # quit with the error message just below.
3147                     $lower = $i;
3148                     next;
3149                 }
3150                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3151                 return;
3152             }
3153             $i = $temp;
3154         } # End of while loop
3155
3156         if (main::DEBUG && $to_trace) {
3157             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3158             trace "i=  [ $i ]", $r->[$i];
3159             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3160         }
3161
3162         # Here we have found the offset.  Cache it as a starting point for the
3163         # next call.
3164         $_search_ranges_cache{$addr} = $i;
3165         return $i;
3166     }
3167
3168     sub _add_delete {
3169         # Add, replace or delete ranges to or from a list.  The $type
3170         # parameter gives which:
3171         #   '+' => insert or replace a range, returning a list of any changed
3172         #          ranges.
3173         #   '-' => delete a range, returning a list of any deleted ranges.
3174         #
3175         # The next three parameters give respectively the start, end, and
3176         # value associated with the range.  'value' should be null unless the
3177         # operation is '+';
3178         #
3179         # The range list is kept sorted so that the range with the lowest
3180         # starting position is first in the list, and generally, adjacent
3181         # ranges with the same values are merged into a single larger one (see
3182         # exceptions below).
3183         #
3184         # There are more parameters; all are key => value pairs:
3185         #   Type    gives the type of the value.  It is only valid for '+'.
3186         #           All ranges have types; if this parameter is omitted, 0 is
3187         #           assumed.  Ranges with type 0 are assumed to obey the
3188         #           Unicode rules for casing, etc; ranges with other types are
3189         #           not.  Otherwise, the type is arbitrary, for the caller's
3190         #           convenience, and looked at only by this routine to keep
3191         #           adjacent ranges of different types from being merged into
3192         #           a single larger range, and when Replace =>
3193         #           $IF_NOT_EQUIVALENT is specified (see just below).
3194         #   Replace  determines what to do if the range list already contains
3195         #            ranges which coincide with all or portions of the input
3196         #            range.  It is only valid for '+':
3197         #       => $NO            means that the new value is not to replace
3198         #                         any existing ones, but any empty gaps of the
3199         #                         range list coinciding with the input range
3200         #                         will be filled in with the new value.
3201         #       => $UNCONDITIONALLY  means to replace the existing values with
3202         #                         this one unconditionally.  However, if the
3203         #                         new and old values are identical, the
3204         #                         replacement is skipped to save cycles
3205         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3206         #                         with this one if they are not equivalent.
3207         #                         Ranges are equivalent if their types are the
3208         #                         same, and they are the same string; or if
3209         #                         both are type 0 ranges, if their Unicode
3210         #                         standard forms are identical.  In this last
3211         #                         case, the routine chooses the more "modern"
3212         #                         one to use.  This is because some of the
3213         #                         older files are formatted with values that
3214         #                         are, for example, ALL CAPs, whereas the
3215         #                         derived files have a more modern style,
3216         #                         which looks better.  By looking for this
3217         #                         style when the pre-existing and replacement
3218         #                         standard forms are the same, we can move to
3219         #                         the modern style
3220         #       => $MULTIPLE      means that if this range duplicates an
3221         #                         existing one, but has a different value,
3222         #                         don't replace the existing one, but insert
3223         #                         this, one so that the same range can occur
3224         #                         multiple times.  They are stored LIFO, so
3225         #                         that the final one inserted is the first one
3226         #                         returned in an ordered search of the table.
3227         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3228         #
3229         # "same value" means identical for non-type-0 ranges, and it means
3230         # having the same standard forms for type-0 ranges.
3231
3232         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3233
3234         my $self = shift;
3235         my $operation = shift;   # '+' for add/replace; '-' for delete;
3236         my $start = shift;
3237         my $end   = shift;
3238         my $value = shift;
3239
3240         my %args = @_;
3241
3242         $value = "" if not defined $value;        # warning: $value can be "0"
3243
3244         my $replace = delete $args{'Replace'};
3245         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3246
3247         my $type = delete $args{'Type'};
3248         $type = 0 unless defined $type;
3249
3250         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3251
3252         my $addr = do { no overloading; pack 'J', $self; };
3253
3254         if ($operation ne '+' && $operation ne '-') {
3255             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3256             return;
3257         }
3258         unless (defined $start && defined $end) {
3259             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3260             return;
3261         }
3262         unless ($end >= $start) {
3263             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3264             return;
3265         }
3266         #local $to_trace = 1 if main::DEBUG;
3267
3268         if ($operation eq '-') {
3269             if ($replace != $IF_NOT_EQUIVALENT) {
3270                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3271                 $replace = $IF_NOT_EQUIVALENT;
3272             }
3273             if ($type) {
3274                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3275                 $type = 0;
3276             }
3277             if ($value ne "") {
3278                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3279                 $value = "";
3280             }
3281         }
3282
3283         my $r = $ranges{$addr};               # The current list of ranges
3284         my $range_list_size = scalar @$r;     # And its size
3285         my $max = $max{$addr};                # The current high code point in
3286                                               # the list of ranges
3287
3288         # Do a special case requiring fewer machine cycles when the new range
3289         # starts after the current highest point.  The Unicode input data is
3290         # structured so this is common.
3291         if ($start > $max) {
3292
3293             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3294             return if $operation eq '-'; # Deleting a non-existing range is a
3295                                          # no-op
3296
3297             # If the new range doesn't logically extend the current final one
3298             # in the range list, create a new range at the end of the range
3299             # list.  (max cleverly is initialized to a negative number not
3300             # adjacent to 0 if the range list is empty, so even adding a range
3301             # to an empty range list starting at 0 will have this 'if'
3302             # succeed.)
3303             if ($start > $max + 1        # non-adjacent means can't extend.
3304                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3305                 || @{$r}[-1]->type != $type # types differ, can't extend.
3306             ) {
3307                 push @$r, Range->new($start, $end,
3308                                      Value => $value,
3309                                      Type => $type);
3310             }
3311             else {
3312
3313                 # Here, the new range starts just after the current highest in
3314                 # the range list, and they have the same type and value.
3315                 # Extend the current range to incorporate the new one.
3316                 @{$r}[-1]->set_end($end);
3317             }
3318
3319             # This becomes the new maximum.
3320             $max{$addr} = $end;
3321
3322             return;
3323         }
3324         #local $to_trace = 0 if main::DEBUG;
3325
3326         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3327
3328         # Here, the input range isn't after the whole rest of the range list.
3329         # Most likely 'splice' will be needed.  The rest of the routine finds
3330         # the needed splice parameters, and if necessary, does the splice.
3331         # First, find the offset parameter needed by the splice function for
3332         # the input range.  Note that the input range may span multiple
3333         # existing ones, but we'll worry about that later.  For now, just find
3334         # the beginning.  If the input range is to be inserted starting in a
3335         # position not currently in the range list, it must (obviously) come
3336         # just after the range below it, and just before the range above it.
3337         # Slightly less obviously, it will occupy the position currently
3338         # occupied by the range that is to come after it.  More formally, we
3339         # are looking for the position, $i, in the array of ranges, such that:
3340         #
3341         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3342         #
3343         # (The ordered relationships within existing ranges are also shown in
3344         # the equation above).  However, if the start of the input range is
3345         # within an existing range, the splice offset should point to that
3346         # existing range's position in the list; that is $i satisfies a
3347         # somewhat different equation, namely:
3348         #
3349         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3350         #
3351         # More briefly, $start can come before or after r[$i]->start, and at
3352         # this point, we don't know which it will be.  However, these
3353         # two equations share these constraints:
3354         #
3355         #   r[$i-1]->end < $start <= r[$i]->end
3356         #
3357         # And that is good enough to find $i.
3358
3359         my $i = $self->_search_ranges($start);
3360         if (! defined $i) {
3361             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3362             return;
3363         }
3364
3365         # The search function returns $i such that:
3366         #
3367         # r[$i-1]->end < $start <= r[$i]->end
3368         #
3369         # That means that $i points to the first range in the range list
3370         # that could possibly be affected by this operation.  We still don't
3371         # know if the start of the input range is within r[$i], or if it
3372         # points to empty space between r[$i-1] and r[$i].
3373         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3374
3375         # Special case the insertion of data that is not to replace any
3376         # existing data.
3377         if ($replace == $NO) {  # If $NO, has to be operation '+'
3378             #local $to_trace = 1 if main::DEBUG;
3379             trace "Doesn't replace" if main::DEBUG && $to_trace;
3380
3381             # Here, the new range is to take effect only on those code points
3382             # that aren't already in an existing range.  This can be done by
3383             # looking through the existing range list and finding the gaps in
3384             # the ranges that this new range affects, and then calling this
3385             # function recursively on each of those gaps, leaving untouched
3386             # anything already in the list.  Gather up a list of the changed
3387             # gaps first so that changes to the internal state as new ranges
3388             # are added won't be a problem.
3389             my @gap_list;
3390
3391             # First, if the starting point of the input range is outside an
3392             # existing one, there is a gap from there to the beginning of the
3393             # existing range -- add a span to fill the part that this new
3394             # range occupies
3395             if ($start < $r->[$i]->start) {
3396                 push @gap_list, Range->new($start,
3397                                            main::min($end,
3398                                                      $r->[$i]->start - 1),
3399                                            Type => $type);
3400                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3401             }
3402
3403             # Then look through the range list for other gaps until we reach
3404             # the highest range affected by the input one.
3405             my $j;
3406             for ($j = $i+1; $j < $range_list_size; $j++) {
3407                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3408                 last if $end < $r->[$j]->start;
3409
3410                 # If there is a gap between when this range starts and the
3411                 # previous one ends, add a span to fill it.  Note that just
3412                 # because there are two ranges doesn't mean there is a
3413                 # non-zero gap between them.  It could be that they have
3414                 # different values or types
3415                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3416                     push @gap_list,
3417                         Range->new($r->[$j-1]->end + 1,
3418                                    $r->[$j]->start - 1,
3419                                    Type => $type);
3420                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3421                 }
3422             }
3423
3424             # Here, we have either found an existing range in the range list,
3425             # beyond the area affected by the input one, or we fell off the
3426             # end of the loop because the input range affects the whole rest
3427             # of the range list.  In either case, $j is 1 higher than the
3428             # highest affected range.  If $j == $i, it means that there are no
3429             # affected ranges, that the entire insertion is in the gap between
3430             # r[$i-1], and r[$i], which we already have taken care of before
3431             # the loop.
3432             # On the other hand, if there are affected ranges, it might be
3433             # that there is a gap that needs filling after the final such
3434             # range to the end of the input range
3435             if ($r->[$j-1]->end < $end) {
3436                     push @gap_list, Range->new(main::max($start,
3437                                                          $r->[$j-1]->end + 1),
3438                                                $end,
3439                                                Type => $type);
3440                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3441             }
3442
3443             # Call recursively to fill in all the gaps.
3444             foreach my $gap (@gap_list) {
3445                 $self->_add_delete($operation,
3446                                    $gap->start,
3447                                    $gap->end,
3448                                    $value,
3449                                    Type => $type);
3450             }
3451
3452             return;
3453         }
3454
3455         # Here, we have taken care of the case where $replace is $NO.
3456         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3457         # If inserting a multiple record, this is where it goes, before the
3458         # first (if any) existing one.  This implies an insertion, and no
3459         # change to any existing ranges.  Note that $i can be -1 if this new
3460         # range doesn't actually duplicate any existing, and comes at the
3461         # beginning of the list.
3462         if ($replace == $MULTIPLE) {
3463
3464             if ($start != $end) {
3465                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3466                 return;
3467             }
3468
3469             # Don't add an exact duplicate, as it isn't really a multiple
3470             if ($end >= $r->[$i]->start) {
3471                 if ($r->[$i]->start != $r->[$i]->end) {
3472                     Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the other range ($r->[$i]) contains more than one code point.  No action taken.");
3473                     return;
3474                 }
3475                 return if $value eq $r->[$i]->value && $type eq $r->[$i]->type;
3476             }
3477
3478             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3479             my @return = splice @$r,
3480                                 $i,
3481                                 0,
3482                                 Range->new($start,
3483                                            $end,
3484                                            Value => $value,
3485                                            Type => $type);
3486             if (main::DEBUG && $to_trace) {
3487                 trace "After splice:";
3488                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3489                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3490                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3491                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3492                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3493                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3494             }
3495             return @return;
3496         }
3497
3498         # Here, we have taken care of $NO and $MULTIPLE replaces.  This leaves
3499         # delete, insert, and replace either unconditionally or if not
3500         # equivalent.  $i still points to the first potential affected range.
3501         # Now find the highest range affected, which will determine the length
3502         # parameter to splice.  (The input range can span multiple existing
3503         # ones.)  If this isn't a deletion, while we are looking through the
3504         # range list, see also if this is a replacement rather than a clean
3505         # insertion; that is if it will change the values of at least one
3506         # existing range.  Start off assuming it is an insert, until find it
3507         # isn't.
3508         my $clean_insert = $operation eq '+';
3509         my $j;        # This will point to the highest affected range
3510
3511         # For non-zero types, the standard form is the value itself;
3512         my $standard_form = ($type) ? $value : main::standardize($value);
3513
3514         for ($j = $i; $j < $range_list_size; $j++) {
3515             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3516
3517             # If find a range that it doesn't overlap into, we can stop
3518             # searching
3519             last if $end < $r->[$j]->start;
3520
3521             # Here, overlaps the range at $j.  If the values don't match,
3522             # and so far we think this is a clean insertion, it becomes a
3523             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3524             if ($clean_insert) {
3525                 if ($r->[$j]->standard_form ne $standard_form) {
3526                     $clean_insert = 0;
3527                     if ($replace == $CROAK) {
3528                         main::croak("The range to add "
3529                         . sprintf("%04X", $start)
3530                         . '-'
3531                         . sprintf("%04X", $end)
3532                         . " with value '$value' overlaps an existing range $r->[$j]");
3533                     }
3534                 }
3535                 else {
3536
3537                     # Here, the two values are essentially the same.  If the
3538                     # two are actually identical, replacing wouldn't change
3539                     # anything so skip it.
3540                     my $pre_existing = $r->[$j]->value;
3541                     if ($pre_existing ne $value) {
3542
3543                         # Here the new and old standardized values are the
3544                         # same, but the non-standardized values aren't.  If
3545                         # replacing unconditionally, then replace
3546                         if( $replace == $UNCONDITIONALLY) {
3547                             $clean_insert = 0;
3548                         }
3549                         else {
3550
3551                             # Here, are replacing conditionally.  Decide to
3552                             # replace or not based on which appears to look
3553                             # the "nicest".  If one is mixed case and the
3554                             # other isn't, choose the mixed case one.
3555                             my $new_mixed = $value =~ /[A-Z]/
3556                                             && $value =~ /[a-z]/;
3557                             my $old_mixed = $pre_existing =~ /[A-Z]/
3558                                             && $pre_existing =~ /[a-z]/;
3559
3560                             if ($old_mixed != $new_mixed) {
3561                                 $clean_insert = 0 if $new_mixed;
3562                                 if (main::DEBUG && $to_trace) {
3563                                     if ($clean_insert) {
3564                                         trace "Retaining $pre_existing over $value";
3565                                     }
3566                                     else {
3567                                         trace "Replacing $pre_existing with $value";
3568                                     }
3569                                 }
3570                             }
3571                             else {
3572
3573                                 # Here casing wasn't different between the two.
3574                                 # If one has hyphens or underscores and the
3575                                 # other doesn't, choose the one with the
3576                                 # punctuation.
3577                                 my $new_punct = $value =~ /[-_]/;
3578                                 my $old_punct = $pre_existing =~ /[-_]/;
3579
3580                                 if ($old_punct != $new_punct) {
3581                                     $clean_insert = 0 if $new_punct;
3582                                     if (main::DEBUG && $to_trace) {
3583                                         if ($clean_insert) {
3584                                             trace "Retaining $pre_existing over $value";
3585                                         }
3586                                         else {
3587                                             trace "Replacing $pre_existing with $value";
3588                                         }
3589                                     }
3590                                 }   # else existing one is just as "good";
3591                                     # retain it to save cycles.
3592                             }
3593                         }
3594                     }
3595                 }
3596             }
3597         } # End of loop looking for highest affected range.
3598
3599         # Here, $j points to one beyond the highest range that this insertion
3600         # affects (hence to beyond the range list if that range is the final
3601         # one in the range list).
3602
3603         # The splice length is all the affected ranges.  Get it before
3604         # subtracting, for efficiency, so we don't have to later add 1.
3605         my $length = $j - $i;
3606
3607         $j--;        # $j now points to the highest affected range.
3608         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3609
3610         # Here, have taken care of $NO and $MULTIPLE replaces.
3611         # $j points to the highest affected range.  But it can be < $i or even
3612         # -1.  These happen only if the insertion is entirely in the gap
3613         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3614         # above exited first time through with $end < $r->[$i]->start.  (And
3615         # then we subtracted one from j)  This implies also that $start <
3616         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3617         # $start, so the entire input range is in the gap.
3618         if ($j < $i) {
3619
3620             # Here the entire input range is in the gap before $i.
3621
3622             if (main::DEBUG && $to_trace) {
3623                 if ($i) {
3624                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3625                 }
3626                 else {
3627                     trace "Entire range is before $r->[$i]";
3628                 }
3629             }
3630             return if $operation ne '+'; # Deletion of a non-existent range is
3631                                          # a no-op
3632         }
3633         else {
3634
3635             # Here part of the input range is not in the gap before $i.  Thus,
3636             # there is at least one affected one, and $j points to the highest
3637             # such one.
3638
3639             # At this point, here is the situation:
3640             # This is not an insertion of a multiple, nor of tentative ($NO)
3641             # data.
3642             #   $i  points to the first element in the current range list that
3643             #            may be affected by this operation.  In fact, we know
3644             #            that the range at $i is affected because we are in
3645             #            the else branch of this 'if'
3646             #   $j  points to the highest affected range.
3647             # In other words,
3648             #   r[$i-1]->end < $start <= r[$i]->end
3649             # And:
3650             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3651             #
3652             # Also:
3653             #   $clean_insert is a boolean which is set true if and only if
3654             #        this is a "clean insertion", i.e., not a change nor a
3655             #        deletion (multiple was handled above).
3656
3657             # We now have enough information to decide if this call is a no-op
3658             # or not.  It is a no-op if this is an insertion of already
3659             # existing data.
3660
3661             if (main::DEBUG && $to_trace && $clean_insert
3662                                          && $i == $j
3663                                          && $start >= $r->[$i]->start)
3664             {
3665                     trace "no-op";
3666             }
3667             return if $clean_insert
3668                       && $i == $j # more than one affected range => not no-op
3669
3670                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3671                       # Further, $start and/or $end is >= r[$i]->start
3672                       # The test below hence guarantees that
3673                       #     r[$i]->start < $start <= $end <= r[$i]->end
3674                       # This means the input range is contained entirely in
3675                       # the one at $i, so is a no-op
3676                       && $start >= $r->[$i]->start;
3677         }
3678
3679         # Here, we know that some action will have to be taken.  We have
3680         # calculated the offset and length (though adjustments may be needed)
3681         # for the splice.  Now start constructing the replacement list.
3682         my @replacement;
3683         my $splice_start = $i;
3684
3685         my $extends_below;
3686         my $extends_above;
3687
3688         # See if should extend any adjacent ranges.
3689         if ($operation eq '-') { # Don't extend deletions
3690             $extends_below = $extends_above = 0;
3691         }
3692         else {  # Here, should extend any adjacent ranges.  See if there are
3693                 # any.
3694             $extends_below = ($i > 0
3695                             # can't extend unless adjacent
3696                             && $r->[$i-1]->end == $start -1
3697                             # can't extend unless are same standard value
3698                             && $r->[$i-1]->standard_form eq $standard_form
3699                             # can't extend unless share type
3700                             && $r->[$i-1]->type == $type);
3701             $extends_above = ($j+1 < $range_list_size
3702                             && $r->[$j+1]->start == $end +1
3703                             && $r->[$j+1]->standard_form eq $standard_form
3704                             && $r->[$j+1]->type == $type);
3705         }
3706         if ($extends_below && $extends_above) { # Adds to both
3707             $splice_start--;     # start replace at element below
3708             $length += 2;        # will replace on both sides
3709             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3710
3711             # The result will fill in any gap, replacing both sides, and
3712             # create one large range.
3713             @replacement = Range->new($r->[$i-1]->start,
3714                                       $r->[$j+1]->end,
3715                                       Value => $value,
3716                                       Type => $type);
3717         }
3718         else {
3719
3720             # Here we know that the result won't just be the conglomeration of
3721             # a new range with both its adjacent neighbors.  But it could
3722             # extend one of them.
3723
3724             if ($extends_below) {
3725
3726                 # Here the new element adds to the one below, but not to the
3727                 # one above.  If inserting, and only to that one range,  can
3728                 # just change its ending to include the new one.
3729                 if ($length == 0 && $clean_insert) {
3730                     $r->[$i-1]->set_end($end);
3731                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3732                     return;
3733                 }
3734                 else {
3735                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3736                     $splice_start--;        # start replace at element below
3737                     $length++;              # will replace the element below
3738                     $start = $r->[$i-1]->start;
3739                 }
3740             }
3741             elsif ($extends_above) {
3742
3743                 # Here the new element adds to the one above, but not below.
3744                 # Mirror the code above
3745                 if ($length == 0 && $clean_insert) {
3746                     $r->[$j+1]->set_start($start);
3747                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3748                     return;
3749                 }
3750                 else {
3751                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3752                     $length++;        # will replace the element above
3753                     $end = $r->[$j+1]->end;
3754                 }
3755             }
3756
3757             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3758
3759             # Finally, here we know there will have to be a splice.
3760             # If the change or delete affects only the highest portion of the
3761             # first affected range, the range will have to be split.  The
3762             # splice will remove the whole range, but will replace it by a new
3763             # range containing just the unaffected part.  So, in this case,
3764             # add to the replacement list just this unaffected portion.
3765             if (! $extends_below
3766                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3767             {
3768                 push @replacement,
3769                     Range->new($r->[$i]->start,
3770                                $start - 1,
3771                                Value => $r->[$i]->value,
3772                                Type => $r->[$i]->type);
3773             }
3774
3775             # In the case of an insert or change, but not a delete, we have to
3776             # put in the new stuff;  this comes next.
3777             if ($operation eq '+') {
3778                 push @replacement, Range->new($start,
3779                                               $end,
3780                                               Value => $value,
3781                                               Type => $type);
3782             }
3783
3784             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3785             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3786
3787             # And finally, if we're changing or deleting only a portion of the
3788             # highest affected range, it must be split, as the lowest one was.
3789             if (! $extends_above
3790                 && $j >= 0  # Remember that j can be -1 if before first
3791                             # current element
3792                 && $end >= $r->[$j]->start
3793                 && $end < $r->[$j]->end)
3794             {
3795                 push @replacement,
3796                     Range->new($end + 1,
3797                                $r->[$j]->end,
3798                                Value => $r->[$j]->value,
3799                                Type => $r->[$j]->type);
3800             }
3801         }
3802
3803         # And do the splice, as calculated above
3804         if (main::DEBUG && $to_trace) {
3805             trace "replacing $length element(s) at $i with ";
3806             foreach my $replacement (@replacement) {
3807                 trace "    $replacement";
3808             }
3809             trace "Before splice:";
3810             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3811             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3812             trace "i  =[", $i, "]", $r->[$i];
3813             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3814             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3815         }
3816
3817         my @return = splice @$r, $splice_start, $length, @replacement;
3818
3819         if (main::DEBUG && $to_trace) {
3820             trace "After splice:";
3821             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3822             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3823             trace "i  =[", $i, "]", $r->[$i];
3824             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3825             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3826             trace "removed @return";
3827         }
3828
3829         # An actual deletion could have changed the maximum in the list.
3830         # There was no deletion if the splice didn't return something, but
3831         # otherwise recalculate it.  This is done too rarely to worry about
3832         # performance.
3833         if ($operation eq '-' && @return) {
3834             $max{$addr} = $r->[-1]->end;
3835         }
3836         return @return;
3837     }
3838
3839     sub reset_each_range {  # reset the iterator for each_range();
3840         my $self = shift;
3841         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3842
3843         no overloading;
3844         undef $each_range_iterator{pack 'J', $self};
3845         return;
3846     }
3847
3848     sub each_range {
3849         # Iterate over each range in a range list.  Results are undefined if
3850         # the range list is changed during the iteration.
3851
3852         my $self = shift;
3853         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3854
3855         my $addr = do { no overloading; pack 'J', $self; };
3856
3857         return if $self->is_empty;
3858
3859         $each_range_iterator{$addr} = -1
3860                                 if ! defined $each_range_iterator{$addr};
3861         $each_range_iterator{$addr}++;
3862         return $ranges{$addr}->[$each_range_iterator{$addr}]
3863                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3864         undef $each_range_iterator{$addr};
3865         return;
3866     }
3867
3868     sub count {        # Returns count of code points in range list
3869         my $self = shift;
3870         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3871
3872         my $addr = do { no overloading; pack 'J', $self; };
3873
3874         my $count = 0;
3875         foreach my $range (@{$ranges{$addr}}) {
3876             $count += $range->end - $range->start + 1;
3877         }
3878         return $count;
3879     }
3880
3881     sub delete_range {    # Delete a range
3882         my $self = shift;
3883         my $start = shift;
3884         my $end = shift;
3885
3886         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3887
3888         return $self->_add_delete('-', $start, $end, "");
3889     }
3890
3891     sub is_empty { # Returns boolean as to if a range list is empty
3892         my $self = shift;
3893         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3894
3895         no overloading;
3896         return scalar @{$ranges{pack 'J', $self}} == 0;
3897     }
3898
3899     sub hash {
3900         # Quickly returns a scalar suitable for separating tables into
3901         # buckets, i.e. it is a hash function of the contents of a table, so
3902         # there are relatively few conflicts.
3903
3904         my $self = shift;
3905         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3906
3907         my $addr = do { no overloading; pack 'J', $self; };
3908
3909         # These are quickly computable.  Return looks like 'min..max;count'
3910         return $self->min . "..$max{$addr};" . scalar @{$ranges{$addr}};
3911     }
3912 } # End closure for _Range_List_Base
3913
3914 package Range_List;
3915 use base '_Range_List_Base';
3916
3917 # A Range_List is a range list for match tables; i.e. the range values are
3918 # not significant.  Thus a number of operations can be safely added to it,
3919 # such as inversion, intersection.  Note that union is also an unsafe
3920 # operation when range values are cared about, and that method is in the base
3921 # class, not here.  But things are set up so that that method is callable only
3922 # during initialization.  Only in this derived class, is there an operation
3923 # that combines two tables.  A Range_Map can thus be used to initialize a
3924 # Range_List, and its mappings will be in the list, but are not significant to
3925 # this class.
3926
3927 sub trace { return main::trace(@_); }
3928
3929 { # Closure
3930
3931     use overload
3932         fallback => 0,
3933         '+' => sub { my $self = shift;
3934                     my $other = shift;
3935
3936                     return $self->_union($other)
3937                 },
3938         '&' => sub { my $self = shift;
3939                     my $other = shift;
3940
3941                     return $self->_intersect($other, 0);
3942                 },
3943         '~' => "_invert",
3944         '-' => "_subtract",
3945     ;
3946
3947     sub _invert {
3948         # Returns a new Range_List that gives all code points not in $self.
3949
3950         my $self = shift;
3951
3952         my $new = Range_List->new;
3953
3954         # Go through each range in the table, finding the gaps between them
3955         my $max = -1;   # Set so no gap before range beginning at 0
3956         for my $range ($self->ranges) {
3957             my $start = $range->start;
3958             my $end   = $range->end;
3959
3960             # If there is a gap before this range, the inverse will contain
3961             # that gap.
3962             if ($start > $max + 1) {
3963                 $new->add_range($max + 1, $start - 1);
3964             }
3965             $max = $end;
3966         }
3967
3968         # And finally, add the gap from the end of the table to the max
3969         # possible code point
3970         if ($max < $LAST_UNICODE_CODEPOINT) {
3971             $new->add_range($max + 1, $LAST_UNICODE_CODEPOINT);
3972         }
3973         return $new;
3974     }
3975
3976     sub _subtract {
3977         # Returns a new Range_List with the argument deleted from it.  The
3978         # argument can be a single code point, a range, or something that has
3979         # a range, with the _range_list() method on it returning them
3980
3981         my $self = shift;
3982         my $other = shift;
3983         my $reversed = shift;
3984         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3985
3986         if ($reversed) {
3987             Carp::my_carp_bug("Can't cope with a "
3988              .  __PACKAGE__
3989              . " being the second parameter in a '-'.  Subtraction ignored.");
3990             return $self;
3991         }
3992
3993         my $new = Range_List->new(Initialize => $self);
3994
3995         if (! ref $other) { # Single code point
3996             $new->delete_range($other, $other);
3997         }
3998         elsif ($other->isa('Range')) {
3999             $new->delete_range($other->start, $other->end);