This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
552e45cdfa218ee5c4c12cde9eb6bfa67f85f4e5
[perl5.git] / dist / ExtUtils-CBuilder / lib / ExtUtils / CBuilder / Platform / Windows / MSVC.pm
1 package ExtUtils::CBuilder::Platform::Windows::MSVC;
2 $ExtUtils::CBuilder::Platform::Windows::MSVC::VERSION = '0.280223';
3 sub arg_exec_file {
4   my ($self, $file) = @_;
5   return "/OUT:$file";
6 }
7
8 sub format_compiler_cmd {
9   my ($self, %spec) = @_;
10
11   foreach my $path ( @{ $spec{includes} || [] },
12                      @{ $spec{perlinc}  || [] } ) {
13     $path = '-I' . $path;
14   }
15
16   %spec = $self->write_compiler_script(%spec)
17     if $spec{use_scripts};
18
19   return [ grep {defined && length} (
20     $spec{cc},'-nologo','-c',
21     @{$spec{includes}}      ,
22     @{$spec{cflags}}        ,
23     @{$spec{optimize}}      ,
24     @{$spec{defines}}       ,
25     @{$spec{perlinc}}       ,
26     "-Fo$spec{output}"      ,
27     $spec{source}           ,
28   ) ];
29 }
30
31 sub write_compiler_script {
32   my ($self, %spec) = @_;
33
34   my $script = File::Spec->catfile( $spec{srcdir},
35                                     $spec{basename} . '.ccs' );
36
37   $self->add_to_cleanup($script);
38   print "Generating script '$script'\n" if !$self->{quiet};
39
40   my $SCRIPT = IO::File->new( ">$script" )
41     or die( "Could not create script '$script': $!" );
42
43   print $SCRIPT join( "\n",
44     map { ref $_ ? @{$_} : $_ }
45     grep defined,
46     delete(
47       @spec{ qw(includes cflags optimize defines perlinc) } )
48   );
49
50   push @{$spec{includes}}, '@"' . $script . '"';
51
52   return %spec;
53 }
54
55 sub format_linker_cmd {
56   my ($self, %spec) = @_;
57   my $cf = $self->{config};
58
59   foreach my $path ( @{$spec{libpath}} ) {
60     $path = "-libpath:$path";
61   }
62
63   my $output = $spec{output};
64   my $manifest = $spec{manifest};
65
66   $spec{def_file}  &&= '-def:'      . $spec{def_file};
67   $spec{output}    &&= '-out:'      . $spec{output};
68   $spec{manifest}  &&= '-manifest ' . $spec{manifest};
69   $spec{implib}    &&= '-implib:'   . $spec{implib};
70   $spec{map_file}  &&= '-map:'      . $spec{map_file};
71
72   %spec = $self->write_linker_script(%spec)
73     if $spec{use_scripts};
74
75   my @cmds; # Stores the series of commands needed to build the module.
76
77   push @cmds, [ grep {defined && length} (
78     $spec{ld}               ,
79     @{$spec{lddlflags}}     ,
80     @{$spec{libpath}}       ,
81     @{$spec{other_ldflags}} ,
82     @{$spec{startup}}       ,
83     @{$spec{objects}}       ,
84     $spec{map_file}         ,
85     $spec{libperl}          ,
86     @{$spec{perllibs}}      ,
87     $spec{def_file}         ,
88     $spec{implib}           ,
89     $spec{output}           ,
90   ) ];
91
92   # Embed the manifest file if it exists
93   push @cmds, [
94     'if', 'exist', $manifest, 'mt', '-nologo', $spec{manifest}, '-outputresource:' . "$output;2"
95   ];
96
97   return @cmds;
98 }
99
100 sub write_linker_script {
101   my ($self, %spec) = @_;
102
103   my $script = File::Spec->catfile( $spec{srcdir},
104                                     $spec{basename} . '.lds' );
105
106   $self->add_to_cleanup($script);
107
108   print "Generating script '$script'\n" if !$self->{quiet};
109
110   my $SCRIPT = IO::File->new( ">$script" )
111     or die( "Could not create script '$script': $!" );
112
113   print $SCRIPT join( "\n",
114     map { ref $_ ? @{$_} : $_ }
115     grep defined,
116     delete(
117       @spec{ qw(lddlflags libpath other_ldflags
118                 startup objects libperl perllibs
119                 def_file implib map_file)            } )
120   );
121
122   push @{$spec{lddlflags}}, '@"' . $script . '"';
123
124   return %spec;
125 }
126
127 1;
128
129