pod/perlrebackslash.pod

   1 =head1 NAME
   2
   3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
   4
   5 =head1 DESCRIPTION
   6
   7 The top level documentation about Perl regular expressions
   8 is found in L<perlre>.
   9
  10 This document describes all backslash and escape sequences. After
  11 explaining the role of the backslash, it lists all the sequences that have
  12 a special meaning in Perl regular expressions (in alphabetical order),
  13 then describes each of them.
  14
  15 Most sequences are described in detail in different documents; the primary
  16 purpose of this document is to have a quick reference guide describing all
  17 backslash and escape sequences.
  18
  19 =head2 The backslash
  20
  21 In a regular expression, the backslash can perform one of two tasks:
  22 it either takes away the special meaning of the character following it
  23 (for instance, C<\|> matches a vertical bar, it's not an alternation),
  24 or it is the start of a backslash or escape sequence.
  25
  26 The rules determining what it is are quite simple: if the character
  27 following the backslash is an ASCII punctuation (non-word) character (that is,
  28 anything that is not a letter, digit, or underscore), then the backslash just
  29 takes away any special meaning of the character following it.
  30
  31 If the character following the backslash is an ASCII letter or an ASCII digit,
  32 then the sequence may be special; if so, it's listed below. A few letters have
  33 not been used yet, so escaping them with a backslash doesn't change them to be
  34 special.  A future version of Perl may assign a special meaning to them, so if
  35 you have warnings turned on, Perl issues a warning if you use such a
  36 sequence.  [1].
  37
  38 It is however guaranteed that backslash or escape sequences never have a
  39 punctuation character following the backslash, not now, and not in a future
  40 version of Perl 5. So it is safe to put a backslash in front of a non-word
  41 character.
  42
  43 Note that the backslash itself is special; if you want to match a backslash,
  44 you have to escape the backslash with a backslash: C</\\/> matches a single
  45 backslash.
  46
  47 =over 4
  48
  49 =item [1]
  50
  51 There is one exception. If you use an alphanumeric character as the
  52 delimiter of your pattern (which you probably shouldn't do for readability
  53 reasons), you have to escape the delimiter if you want to match
  54 it. Perl won't warn then. See also L<perlop/Gory details of parsing
  55 quoted constructs>.
  56
  57 =back
  58
  59
  60 =head2 All the sequences and escapes
  61
  62 Those not usable within a bracketed character class (like C<[\da-z]>) are marked
  63 as C<Not in [].>
  64
  65  \000              Octal escape sequence.  See also \o{}.
  66  \1                Absolute backreference.  Not in [].
  67  \a                Alarm or bell.
  68  \A                Beginning of string.  Not in [].
  69  \b{}, \b          Boundary. (\b is a backspace in []).
  70  \B{}, \B          Not a boundary.
  71  \cX               Control-X.
  72  \C                Single octet, even under UTF-8.  Not in [].
  73                    (Deprecated)
  74  \d                Character class for digits.
  75  \D                Character class for non-digits.
  76  \e                Escape character.
  77  \E                Turn off \Q, \L and \U processing.  Not in [].
  78  \f                Form feed.
  79  \F                Foldcase till \E.  Not in [].
  80  \g{}, \g1         Named, absolute or relative backreference.
  81                    Not in [].
  82  \G                Pos assertion.  Not in [].
  83  \h                Character class for horizontal whitespace.
  84  \H                Character class for non horizontal whitespace.
  85  \k{}, \k<>, \k''  Named backreference.  Not in [].
  86  \K                Keep the stuff left of \K.  Not in [].
  87  \l                Lowercase next character.  Not in [].
  88  \L                Lowercase till \E.  Not in [].
  89  \n                (Logical) newline character.
  90  \N                Any character but newline.  Not in [].
  91  \N{}              Named or numbered (Unicode) character or sequence.
  92  \o{}              Octal escape sequence.
  93  \p{}, \pP         Character with the given Unicode property.
  94  \P{}, \PP         Character without the given Unicode property.
  95  \Q                Quote (disable) pattern metacharacters till \E.  Not
  96                    in [].
  97  \r                Return character.
  98  \R                Generic new line.  Not in [].
  99  \s                Character class for whitespace.
 100  \S                Character class for non whitespace.
 101  \t                Tab character.
 102  \u                Titlecase next character.  Not in [].
 103  \U                Uppercase till \E.  Not in [].
 104  \v                Character class for vertical whitespace.
 105  \V                Character class for non vertical whitespace.
 106  \w                Character class for word characters.
 107  \W                Character class for non-word characters.
 108  \x{}, \x00        Hexadecimal escape sequence.
 109  \X                Unicode "extended grapheme cluster".  Not in [].
 110  \z                End of string.  Not in [].
 111  \Z                End of string.  Not in [].
 112
 113 =head2 Character Escapes
 114
 115 =head3  Fixed characters
 116
 117 A handful of characters have a dedicated I<character escape>. The following
 118 table shows them, along with their ASCII code points (in decimal and hex),
 119 their ASCII name, the control escape on ASCII platforms and a short
 120 description.  (For EBCDIC platforms, see L<perlebcdic/OPERATOR DIFFERENCES>.)
 121
 122  Seq.  Code Point  ASCII   Cntrl   Description.
 123        Dec    Hex
 124   \a     7     07    BEL    \cG    alarm or bell
 125   \b     8     08     BS    \cH    backspace [1]
 126   \e    27     1B    ESC    \c[    escape character
 127   \f    12     0C     FF    \cL    form feed
 128   \n    10     0A     LF    \cJ    line feed [2]
 129   \r    13     0D     CR    \cM    carriage return
 130   \t     9     09    TAB    \cI    tab
 131
 132 =over 4
 133
 134 =item [1]
 135
 136 C<\b> is the backspace character only inside a character class. Outside a
 137 character class, C<\b> alone is a word-character/non-word-character
 138 boundary, and C<\b{}> is some other type of boundary.
 139
 140 =item [2]
 141
 142 C<\n> matches a logical newline. Perl converts between C<\n> and your
 143 OS's native newline character when reading from or writing to text files.
 144
 145 =back
 146
 147 =head4 Example
 148
 149  $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
 150
 151 =head3 Control characters
 152
 153 C<\c> is used to denote a control character; the character following C<\c>
 154 determines the value of the construct.  For example the value of C<\cA> is
 155 C<chr(1)>, and the value of C<\cb> is C<chr(2)>, etc.
 156 The gory details are in L<perlop/"Regexp Quote-Like Operators">.  A complete
 157 list of what C<chr(1)>, etc. means for ASCII and EBCDIC platforms is in
 158 L<perlebcdic/OPERATOR DIFFERENCES>.
 159
 160 Note that C<\c\> alone at the end of a regular expression (or doubled-quoted
 161 string) is not valid.  The backslash must be followed by another character.
 162 That is, C<\c\I<X>> means C<chr(28) . 'I<X>'> for all characters I<X>.
 163
 164 To write platform-independent code, you must use C<\N{I<NAME>}> instead, like
 165 C<\N{ESCAPE}> or C<\N{U+001B}>, see L<charnames>.
 166
 167 Mnemonic: I<c>ontrol character.
 168
 169 =head4 Example
 170
 171  $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
 172
 173 =head3 Named or numbered characters and character sequences
 174
 175 Unicode characters have a Unicode name and numeric code point (ordinal)
 176 value.  Use the
 177 C<\N{}> construct to specify a character by either of these values.
 178 Certain sequences of characters also have names.
 179
 180 To specify by name, the name of the character or character sequence goes
 181 between the curly braces.
 182
 183 To specify a character by Unicode code point, use the form C<\N{U+I<code
 184 point>}>, where I<code point> is a number in hexadecimal that gives the
 185 code point that Unicode has assigned to the desired character.  It is
 186 customary but not required to use leading zeros to pad the number to 4
 187 digits.  Thus C<\N{U+0041}> means C<LATIN CAPITAL LETTER A>, and you will
 188 rarely see it written without the two leading zeros.  C<\N{U+0041}> means
 189 "A" even on EBCDIC machines (where the ordinal value of "A" is not 0x41).
 190
 191 It is even possible to give your own names to characters and character
 192 sequences.  For details, see L<charnames>.
 193
 194 (There is an expanded internal form that you may see in debug output:
 195 C<\N{U+I<code point>.I<code point>...}>.
 196 The C<...> means any number of these I<code point>s separated by dots.
 197 This represents the sequence formed by the characters.  This is an internal
 198 form only, subject to change, and you should not try to use it yourself.)
 199
 200 Mnemonic: I<N>amed character.
 201
 202 Note that a character or character sequence expressed as a named
 203 or numbered character is considered a character without special
 204 meaning by the regex engine, and will match "as is".
 205
 206 =head4 Example
 207
 208  $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
 209
 210  use charnames 'Cyrillic';            # Loads Cyrillic names.
 211  $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
 212
 213 =head3 Octal escapes
 214
 215 There are two forms of octal escapes.  Each is used to specify a character by
 216 its code point specified in octal notation.
 217
 218 One form, available starting in Perl 5.14 looks like C<\o{...}>, where the dots
 219 represent one or more octal digits.  It can be used for any Unicode character.
 220
 221 It was introduced to avoid the potential problems with the other form,
 222 available in all Perls.  That form consists of a backslash followed by three
 223 octal digits.  One problem with this form is that it can look exactly like an
 224 old-style backreference (see
 225 L</Disambiguation rules between old-style octal escapes and backreferences>
 226 below.)  You can avoid this by making the first of the three digits always a
 227 zero, but that makes \077 the largest code point specifiable.
 228
 229 In some contexts, a backslash followed by two or even one octal digits may be
 230 interpreted as an octal escape, sometimes with a warning, and because of some
 231 bugs, sometimes with surprising results.  Also, if you are creating a regex
 232 out of smaller snippets concatenated together, and you use fewer than three
 233 digits, the beginning of one snippet may be interpreted as adding digits to the
 234 ending of the snippet before it.  See L</Absolute referencing> for more
 235 discussion and examples of the snippet problem.
 236
 237 Note that a character expressed as an octal escape is considered
 238 a character without special meaning by the regex engine, and will match
 239 "as is".
 240
 241 To summarize, the C<\o{}> form is always safe to use, and the other form is
 242 safe to use for code points through \077 when you use exactly three digits to
 243 specify them.
 244
 245 Mnemonic: I<0>ctal or I<o>ctal.
 246
 247 =head4 Examples (assuming an ASCII platform)
 248
 249  $str = "Perl";
 250  $str =~ /\o{120}/;  # Match, "\120" is "P".
 251  $str =~ /\120/;     # Same.
 252  $str =~ /\o{120}+/; # Match, "\120" is "P",
 253                      # it's repeated at least once.
 254  $str =~ /\120+/;    # Same.
 255  $str =~ /P\053/;    # No match, "\053" is "+" and taken literally.
 256  /\o{23073}/         # Black foreground, white background smiling face.
 257  /\o{4801234567}/    # Raises a warning, and yields chr(4).
 258
 259 =head4 Disambiguation rules between old-style octal escapes and backreferences
 260
 261 Octal escapes of the C<\000> form outside of bracketed character classes
 262 potentially clash with old-style backreferences (see L</Absolute referencing>
 263 below).  They both consist of a backslash followed by numbers.  So Perl has to
 264 use heuristics to determine whether it is a backreference or an octal escape.
 265 Perl uses the following rules to disambiguate:
 266
 267 =over 4
 268
 269 =item 1
 270
 271 If the backslash is followed by a single digit, it's a backreference.
 272
 273 =item 2
 274
 275 If the first digit following the backslash is a 0, it's an octal escape.
 276
 277 =item 3
 278
 279 If the number following the backslash is N (in decimal), and Perl already
 280 has seen N capture groups, Perl considers this a backreference.  Otherwise,
 281 it considers it an octal escape. If N has more than three digits, Perl
 282 takes only the first three for the octal escape; the rest are matched as is.
 283
 284  my $pat  = "(" x 999;
 285     $pat .= "a";
 286     $pat .= ")" x 999;
 287  /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
 288  /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
 289                     #  and \1000 is seen as \100 (a '@') and a '0'.
 290
 291 =back
 292
 293 You can force a backreference interpretation always by using the C<\g{...}>
 294 form.  You can the force an octal interpretation always by using the C<\o{...}>
 295 form, or for numbers up through \077 (= 63 decimal), by using three digits,
 296 beginning with a "0".
 297
 298 =head3 Hexadecimal escapes
 299
 300 Like octal escapes, there are two forms of hexadecimal escapes, but both start
 301 with the sequence C<\x>.  This is followed by either exactly two hexadecimal
 302 digits forming a number, or a hexadecimal number of arbitrary length surrounded
 303 by curly braces. The hexadecimal number is the code point of the character you
 304 want to express.
 305
 306 Note that a character expressed as one of these escapes is considered a
 307 character without special meaning by the regex engine, and will match
 308 "as is".
 309
 310 Mnemonic: heI<x>adecimal.
 311
 312 =head4 Examples (assuming an ASCII platform)
 313
 314  $str = "Perl";
 315  $str =~ /\x50/;    # Match, "\x50" is "P".
 316  $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once
 317  $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
 318
 319  /\x{2603}\x{2602}/ # Snowman with an umbrella.
 320                     # The Unicode character 2603 is a snowman,
 321                     # the Unicode character 2602 is an umbrella.
 322  /\x{263B}/         # Black smiling face.
 323  /\x{263b}/         # Same, the hex digits A - F are case insensitive.
 324
 325 =head2 Modifiers
 326
 327 A number of backslash sequences have to do with changing the character,
 328 or characters following them. C<\l> will lowercase the character following
 329 it, while C<\u> will uppercase (or, more accurately, titlecase) the
 330 character following it. They provide functionality similar to the
 331 functions C<lcfirst> and C<ucfirst>.
 332
 333 To uppercase or lowercase several characters, one might want to use
 334 C<\L> or C<\U>, which will lowercase/uppercase all characters following
 335 them, until either the end of the pattern or the next occurrence of
 336 C<\E>, whichever comes first. They provide functionality similar to what
 337 the functions C<lc> and C<uc> provide.
 338
 339 C<\Q> is used to quote (disable) pattern metacharacters, up to the next
 340 C<\E> or the end of the pattern. C<\Q> adds a backslash to any character
 341 that could have special meaning to Perl.  In the ASCII range, it quotes
 342 every character that isn't a letter, digit, or underscore.  See
 343 L<perlfunc/quotemeta> for details on what gets quoted for non-ASCII
 344 code points.  Using this ensures that any character between C<\Q> and
 345 C<\E> will be matched literally, not interpreted as a metacharacter by
 346 the regex engine.
 347
 348 C<\F> can be used to casefold all characters following, up to the next C<\E>
 349 or the end of the pattern. It provides the functionality similar to
 350 the C<fc> function.
 351
 352 Mnemonic: I<L>owercase, I<U>ppercase, I<F>old-case, I<Q>uotemeta, I<E>nd.
 353
 354 =head4 Examples
 355
 356  $sid     = "sid";
 357  $greg    = "GrEg";
 358  $miranda = "(Miranda)";
 359  $str     =~ /\u$sid/;        # Matches 'Sid'
 360  $str     =~ /\L$greg/;       # Matches 'greg'
 361  $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
 362                               #   had been written as /\(Miranda\)/
 363
 364 =head2 Character classes
 365
 366 Perl regular expressions have a large range of character classes. Some of
 367 the character classes are written as a backslash sequence. We will briefly
 368 discuss those here; full details of character classes can be found in
 369 L<perlrecharclass>.
 370
 371 C<\w> is a character class that matches any single I<word> character
 372 (letters, digits, Unicode marks, and connector punctuation (like the
 373 underscore)).  C<\d> is a character class that matches any decimal
 374 digit, while the character class C<\s> matches any whitespace character.
 375 New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
 376 and vertical whitespace characters.
 377
 378 The exact set of characters matched by C<\d>, C<\s>, and C<\w> varies
 379 depending on various pragma and regular expression modifiers.  It is
 380 possible to restrict the match to the ASCII range by using the C</a>
 381 regular expression modifier.  See L<perlrecharclass>.
 382
 383 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
 384 character classes that match, respectively, any character that isn't a
 385 word character, digit, whitespace, horizontal whitespace, or vertical
 386 whitespace.
 387
 388 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
 389
 390 =head3 Unicode classes
 391
 392 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
 393 match a character that matches the given Unicode property; properties
 394 include things like "letter", or "thai character". Capitalizing the
 395 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
 396 that doesn't match the given Unicode property. For more details, see
 397 L<perlrecharclass/Backslash sequences> and
 398 L<perlunicode/Unicode Character Properties>.
 399
 400 Mnemonic: I<p>roperty.
 401
 402 =head2 Referencing
 403
 404 If capturing parenthesis are used in a regular expression, we can refer
 405 to the part of the source string that was matched, and match exactly the
 406 same thing. There are three ways of referring to such I<backreference>:
 407 absolutely, relatively, and by name.
 408
 409 =for later add link to perlrecapture
 410
 411 =head3 Absolute referencing
 412
 413 Either C<\gI<N>> (starting in Perl 5.10.0), or C<\I<N>> (old-style) where I<N>
 414 is a positive (unsigned) decimal number of any length is an absolute reference
 415 to a capturing group.
 416
 417 I<N> refers to the Nth set of parentheses, so C<\gI<N>> refers to whatever has
 418 been matched by that set of parentheses.  Thus C<\g1> refers to the first
 419 capture group in the regex.
 420
 421 The C<\gI<N>> form can be equivalently written as C<\g{I<N>}>
 422 which avoids ambiguity when building a regex by concatenating shorter
 423 strings.  Otherwise if you had a regex C<qr/$a$b/>, and C<$a> contained
 424 C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which is
 425 probably not what you intended.
 426
 427 In the C<\I<N>> form, I<N> must not begin with a "0", and there must be at
 428 least I<N> capturing groups, or else I<N> is considered an octal escape
 429 (but something like C<\18> is the same as C<\0018>; that is, the octal escape
 430 C<"\001"> followed by a literal digit C<"8">).
 431
 432 Mnemonic: I<g>roup.
 433
 434 =head4 Examples
 435
 436  /(\w+) \g1/;    # Finds a duplicated word, (e.g. "cat cat").
 437  /(\w+) \1/;     # Same thing; written old-style.
 438  /(.)(.)\g2\g1/;  # Match a four letter palindrome (e.g. "ABBA").
 439
 440
 441 =head3 Relative referencing
 442
 443 C<\g-I<N>> (starting in Perl 5.10.0) is used for relative addressing.  (It can
 444 be written as C<\g{-I<N>>.)  It refers to the I<N>th group before the
 445 C<\g{-I<N>}>.
 446
 447 The big advantage of this form is that it makes it much easier to write
 448 patterns with references that can be interpolated in larger patterns,
 449 even if the larger pattern also contains capture groups.
 450
 451 =head4 Examples
 452
 453  /(A)        # Group 1
 454   (          # Group 2
 455     (B)      # Group 3
 456     \g{-1}   # Refers to group 3 (B)
 457     \g{-3}   # Refers to group 1 (A)
 458   )
 459  /x;         # Matches "ABBA".
 460
 461  my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
 462  /$qr$qr/                           # Matches 'ababcdcd'.
 463
 464 =head3 Named referencing
 465
 466 C<\g{I<name>}> (starting in Perl 5.10.0) can be used to back refer to a
 467 named capture group, dispensing completely with having to think about capture
 468 buffer positions.
 469
 470 To be compatible with .Net regular expressions, C<\g{name}> may also be
 471 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
 472
 473 To prevent any ambiguity, I<name> must not start with a digit nor contain a
 474 hyphen.
 475
 476 =head4 Examples
 477
 478  /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
 479  /(?<word>\w+) \k{word}/ # Same.
 480  /(?<word>\w+) \k<word>/ # Same.
 481  /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
 482                          # Match a four letter palindrome (e.g. "ABBA")
 483
 484 =head2 Assertions
 485
 486 Assertions are conditions that have to be true; they don't actually
 487 match parts of the substring. There are six assertions that are written as
 488 backslash sequences.
 489
 490 =over 4
 491
 492 =item \A
 493
 494 C<\A> only matches at the beginning of the string. If the C</m> modifier
 495 isn't used, then C</\A/> is equivalent to C</^/>. However, if the C</m>
 496 modifier is used, then C</^/> matches internal newlines, but the meaning
 497 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
 498 of the string regardless whether the C</m> modifier is used.
 499
 500 =item \z, \Z
 501
 502 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
 503 used, then C</\Z/> is equivalent to C</$/>; that is, it matches at the
 504 end of the string, or one before the newline at the end of the string. If the
 505 C</m> modifier is used, then C</$/> matches at internal newlines, but the
 506 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
 507 the end of the string (or just before a trailing newline) regardless whether
 508 the C</m> modifier is used.
 509
 510 C<\z> is just like C<\Z>, except that it does not match before a trailing
 511 newline. C<\z> matches at the end of the string only, regardless of the
 512 modifiers used, and not just before a newline.  It is how to anchor the
 513 match to the true end of the string under all conditions.
 514
 515 =item \G
 516
 517 C<\G> is usually used only in combination with the C</g> modifier. If the
 518 C</g> modifier is used and the match is done in scalar context, Perl
 519 remembers where in the source string the last match ended, and the next time,
 520 it will start the match from where it ended the previous time.
 521
 522 C<\G> matches the point where the previous match on that string ended,
 523 or the beginning of that string if there was no previous match.
 524
 525 =for later add link to perlremodifiers
 526
 527 Mnemonic: I<G>lobal.
 528
 529 =item \b{}, \b, \B{}, \B
 530
 531 C<\b{...}>, available starting in v5.22, matches a boundary (between two
 532 characters, or before the first character of the string, or after the
 533 final character of the string) based on the Unicode rules for the
 534 boundary type specified inside the braces.  The currently known boundary
 535 types are given a few paragraphs below.  C<\B{...}> matches at any place
 536 between characters where C<\b{...}> of the same type doesn't match.
 537
 538 C<\b> when not immediately followed by a C<"{"> matches at any place
 539 between a word (something matched by C<\w>) and a non-word character
 540 (C<\W>); C<\B> when not immediately followed by a C<"{"> matches at any
 541 place between characters where C<\b> doesn't match.  To get better
 542 word matching of natural language text, see L<\b{wb}> below.
 543
 544 C<\b>
 545 and C<\B> assume there's a non-word character before the beginning and after
 546 the end of the source string; so C<\b> will match at the beginning (or end)
 547 of the source string if the source string begins (or ends) with a word
 548 character. Otherwise, C<\B> will match.
 549
 550 Do not use something like C<\b=head\d\b> and expect it to match the
 551 beginning of a line.  It can't, because for there to be a boundary before
 552 the non-word "=", there must be a word character immediately previous.
 553 All plain C<\b> and C<\B> boundary determinations look for word
 554 characters alone, not for
 555 non-word characters nor for string ends.  It may help to understand how
 556 <\b> and <\B> work by equating them as follows:
 557
 558     \b  really means    (?:(?<=\w)(?!\w)|(?<!\w)(?=\w))
 559     \B  really means    (?:(?<=\w)(?=\w)|(?<!\w)(?!\w))
 560
 561 In contrast, C<\b{...}> and C<\B{...}> may or may not match at the
 562 beginning and end of the line, depending on the boundary type.  These
 563 implement the Unicode default boundaries, specified in
 564 L<http://www.unicode.org/reports/tr29/>.
 565 The boundary types currently available are:
 566
 567 =over
 568
 569 =item C<\b{gcb}> or C<\b{g}>
 570
 571 This matches a Unicode "Grapheme Cluster Boundary".  (Actually Perl
 572 always uses the improved "extended" grapheme cluster").  These are
 573 explained below under L</C<\X>>.  In fact, C<\X> is another way to get
 574 the same functionality.  It is equivalent to C</.+?\b{gcb}/>.  Use
 575 whichever is most convenient for your situation.
 576
 577 =item C<\b{sb}>
 578
 579 This matches a Unicode "Sentence Boundary".  This is an aid to parsing
 580 natural language sentences.  It gives good, but imperfect results.  For
 581 example, it thinks that "Mr. Smith" is two sentences.  More details are
 582 at L<http://www.unicode.org/reports/tr29/>.  Note also that it thinks
 583 that anything matching L</\R> (except form feed and vertical tab) is a
 584 sentence boundary.  C<\b{sb}> works with text designed for
 585 word-processors which wrap lines
 586 automatically for display, but hard-coded line boundaries are considered
 587 to be essentially the ends of text blocks (paragraphs really), and hence
 588 the ends of sententces.  C<\b{sb}> doesn't do well with text containing
 589 embedded newlines, like the source text of the document you are reading.
 590 Such text needs to be preprocessed to get rid of the line separators
 591 before looking for sentence boundaries.  Some people view this as a bug
 592 in the Unicode standard.
 593
 594 =item C<\b{wb}>
 595
 596 This matches a Unicode "Word Boundary".  This gives better (though not
 597 perfect) results for natural language processing than plain C<\b>
 598 (without braces) does.  For example, it understands that apostrophes can
 599 be in the middle of words and that parentheses aren't (see the examples
 600 below).   More details are at L<http://www.unicode.org/reports/tr29/>.
 601
 602 =back
 603
 604 It is important to realize that these are default boundary definitions,
 605 and that implementations may wish to tailor the results for particular
 606 purposes and locales.  Also note that Perl gives you the definitions
 607 valid for the version of the Unicode Standard compiled into Perl.  These
 608 rules are not considered stable and have been somewhat more subject to
 609 change than the rest of the Standard, and hence changing to a later Perl
 610 version may give you a different Unicode version whose changes may not
 611 be compatibile with what you coded for.  If, necessary, you can
 612 recompile Perl with an earlier version of the Unicode standard.  More
 613 information about that is in L<perluniprops/Unicode character properties
 614 that are NOT accepted by Perl>
 615
 616 Unicode defines a fourth boundary type, accessible through the
 617 L<Unicode::LineBreak> module.
 618
 619 Mnemonic: I<b>oundary.
 620
 621 =back
 622
 623 =head4 Examples
 624
 625   "cat"   =~ /\Acat/;     # Match.
 626   "cat"   =~ /cat\Z/;     # Match.
 627   "cat\n" =~ /cat\Z/;     # Match.
 628   "cat\n" =~ /cat\z/;     # No match.
 629
 630   "cat"   =~ /\bcat\b/;   # Matches.
 631   "cats"  =~ /\bcat\b/;   # No match.
 632   "cat"   =~ /\bcat\B/;   # No match.
 633   "cats"  =~ /\bcat\B/;   # Match.
 634
 635   while ("cat dog" =~ /(\w+)/g) {
 636       print $1;           # Prints 'catdog'
 637   }
 638   while ("cat dog" =~ /\G(\w+)/g) {
 639       print $1;           # Prints 'cat'
 640   }
 641
 642   my $s = "He said, \"Is pi 3.14? (I'm not sure).\"";
 643   print join("|", $s =~ m/ ( .+? \b     ) /xg), "\n";
 644   print join("|", $s =~ m/ ( .+? \b{wb} ) /xg), "\n";
 645  prints
 646   He| |said|, "|Is| |pi| |3|.|14|? (|I|'|m| |not| |sure
 647   He| |said|,| |"|Is| |pi| |3.14|?| |(|I'm| |not| |sure|)|.|"
 648
 649 =head2 Misc
 650
 651 Here we document the backslash sequences that don't fall in one of the
 652 categories above. These are:
 653
 654 =over 4
 655
 656 =item \C
 657
 658 (Deprecated.) C<\C> always matches a single octet, even if the source
 659 string is encoded
 660 in UTF-8 format, and the character to be matched is a multi-octet character.
 661 This is very dangerous, because it violates
 662 the logical character abstraction and can cause UTF-8 sequences to become malformed.
 663
 664 Use C<utf8::encode()> instead.
 665
 666 Mnemonic: oI<C>tet.
 667
 668 =item \K
 669
 670 This appeared in perl 5.10.0. Anything matched left of C<\K> is
 671 not included in C<$&>, and will not be replaced if the pattern is
 672 used in a substitution. This lets you write C<s/PAT1 \K PAT2/REPL/x>
 673 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
 674
 675 Mnemonic: I<K>eep.
 676
 677 =item \N
 678
 679 This feature, available starting in v5.12,  matches any character
 680 that is B<not> a newline.  It is a short-hand for writing C<[^\n]>, and is
 681 identical to the C<.> metasymbol, except under the C</s> flag, which changes
 682 the meaning of C<.>, but not C<\N>.
 683
 684 Note that C<\N{...}> can mean a
 685 L<named or numbered character
 686 |/Named or numbered characters and character sequences>.
 687
 688 Mnemonic: Complement of I<\n>.
 689
 690 =item \R
 691 X<\R>
 692
 693 C<\R> matches a I<generic newline>; that is, anything considered a
 694 linebreak sequence by Unicode. This includes all characters matched by
 695 C<\v> (vertical whitespace), and the multi character sequence C<"\x0D\x0A">
 696 (carriage return followed by a line feed, sometimes called the network
 697 newline; it's the end of line sequence used in Microsoft text files opened
 698 in binary mode). C<\R> is equivalent to C<< (?>\x0D\x0A|\v) >>.  (The
 699 reason it doesn't backtrack is that the sequence is considered
 700 inseparable.  That means that
 701
 702  "\x0D\x0A" =~ /^\R\x0A$/   # No match
 703
 704 fails, because the C<\R> matches the entire string, and won't backtrack
 705 to match just the C<"\x0D">.)  Since
 706 C<\R> can match a sequence of more than one character, it cannot be put
 707 inside a bracketed character class; C</[\R]/> is an error; use C<\v>
 708 instead.  C<\R> was introduced in perl 5.10.0.
 709
 710 Note that this does not respect any locale that might be in effect; it
 711 matches according to the platform's native character set.
 712
 713 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
 714 and more importantly because Unicode recommends such a regular expression
 715 metacharacter, and suggests C<\R> as its notation.
 716
 717 =item \X
 718 X<\X>
 719
 720 This matches a Unicode I<extended grapheme cluster>.
 721
 722 C<\X> matches quite well what normal (non-Unicode-programmer) usage
 723 would consider a single character.  As an example, consider a G with some sort
 724 of diacritic mark, such as an arrow.  There is no such single character in
 725 Unicode, but one can be composed by using a G followed by a Unicode "COMBINING
 726 UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it
 727 were a single character.
 728
 729 The match is greedy and non-backtracking, so that the cluster is never
 730 broken up into smaller components.
 731
 732 See also L<C<\b{gcb}>|/\b{}, \b, \B{}, \B>.
 733
 734 Mnemonic: eI<X>tended Unicode character.
 735
 736 =back
 737
 738 =head4 Examples
 739
 740  $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'
 741  $str =~ s/(.)\K\g1//g;    # Delete duplicated characters.
 742
 743  "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
 744  "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
 745  "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
 746
 747  "P\x{307}" =~ /^\X$/     # \X matches a P with a dot above.
 748
 749 =cut