This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
51c130685b073e600b95052af389147c3c705818
[perl5.git] / regen / mg_vtable.pl
1 #!/usr/bin/perl -w
2 #
3 # Regenerate (overwriting only if changed):
4 #
5 #    mg_names.c
6 #    mg_raw.h
7 #    mg_vtable.h
8 #    pod/perlguts.pod
9 #
10 # from information stored in this file.  pod/perlguts.pod is not completely
11 # regenerated.  Only the magic table is replaced; the other parts remain
12 # untouched.
13 #
14 # Accepts the standard regen_lib -q and -v args.
15 #
16 # This script is normally invoked from regen.pl.
17
18 use strict;
19 require 5.004;
20
21 BEGIN {
22     # Get function prototypes
23     require 'regen/regen_lib.pl';
24 }
25
26 my %mg =
27     (
28      sv => { char => '\0', vtable => 'sv', readonly_acceptable => 1,
29              desc => 'Special scalar variable' },
30      # overload, or type "A" magic, used to be here.  Hence overloaded is
31      # often called AMAGIC internally, even though it does not use "A"
32      # magic any more.
33      overload_table => { char => 'c', vtable => 'ovrld',
34                          desc => 'Holds overload table (AMT) on stash' },
35      bm => { char => 'B', vtable => 'regexp', value_magic => 1,
36              readonly_acceptable => 1,
37              desc => 'Boyer-Moore (fast string search)' },
38      regdata => { char => 'D', vtable => 'regdata',
39                   desc => "Regex match position data\n(\@+ and \@- vars)" },
40      regdatum => { char => 'd', vtable => 'regdatum',
41                    desc => 'Regex match position data element' },
42      env => { char => 'E', vtable => 'env', desc => '%ENV hash' },
43      envelem => { char => 'e', vtable => 'envelem',
44                   desc => '%ENV hash element' },
45      fm => { char => 'f', vtable => 'regexp', value_magic => 1,
46              readonly_acceptable => 1, desc => "Formline ('compiled' format)" },
47      regex_global => { char => 'g', vtable => 'mglob', value_magic => 1,
48                        readonly_acceptable => 1, desc => 'm//g target' },
49      hints => { char => 'H', vtable => 'hints', desc => '%^H hash' },
50      hintselem => { char => 'h', vtable => 'hintselem',
51                     desc => '%^H hash element' },
52      isa => { char => 'I', vtable => 'isa', desc => '@ISA array' },
53      isaelem => { char => 'i', vtable => 'isaelem',
54                   desc => '@ISA array element' },
55      nkeys => { char => 'k', vtable => 'nkeys', value_magic => 1,
56                 desc => 'scalar(keys()) lvalue' },
57      dbfile => { char => 'L',
58                  desc => 'Debugger %_<filename' },
59      dbline => { char => 'l', vtable => 'dbline',
60                  desc => 'Debugger %_<filename element' },
61      shared => { char => 'N', desc => 'Shared between threads',
62                  unknown_to_sv_magic => 1 },
63      shared_scalar => { char => 'n', desc => 'Shared between threads',
64                         unknown_to_sv_magic => 1 },
65      collxfrm => { char => 'o', vtable => 'collxfrm', value_magic => 1,
66                    desc => 'Locale transformation' },
67      tied => { char => 'P', vtable => 'pack',
68                value_magic => 1, # treat as value, so 'local @tied' isn't tied
69                desc => 'Tied array or hash' },
70      tiedelem => { char => 'p', vtable => 'packelem',
71                    desc => 'Tied array or hash element' },
72      tiedscalar => { char => 'q', vtable => 'packelem',
73                      desc => 'Tied scalar or handle' },
74      qr => { char => 'r', vtable => 'regexp', value_magic => 1, 
75              readonly_acceptable => 1, desc => 'precompiled qr// regex' },
76      sig => { char => 'S', desc => '%SIG hash' },
77      sigelem => { char => 's', vtable => 'sigelem',
78                   desc => '%SIG hash element' },
79      taint => { char => 't', vtable => 'taint', value_magic => 1,
80                 desc => 'Taintedness' },
81      uvar => { char => 'U', vtable => 'uvar',
82                desc => 'Available for use by extensions' },
83      uvar_elem => { char => 'u', desc => 'Reserved for use by extensions',
84                     unknown_to_sv_magic => 1 },
85      vec => { char => 'v', vtable => 'vec', value_magic => 1,
86               desc => 'vec() lvalue' },
87      vstring => { char => 'V', value_magic => 1,
88                   desc => 'SV was vstring literal' },
89      utf8 => { char => 'w', vtable => 'utf8', value_magic => 1,
90                desc => 'Cached UTF-8 information' },
91      substr => { char => 'x', vtable => 'substr',  value_magic => 1,
92                  desc => 'substr() lvalue' },
93      defelem => { char => 'y', vtable => 'defelem', value_magic => 1,
94                   desc => "Shadow \"foreach\" iterator variable /\nsmart parameter vivification" },
95      arylen => { char => '#', vtable => 'arylen', value_magic => 1,
96                  desc => 'Array length ($#ary)' },
97      proto => { char => '&', desc => 'my sub prototype CV' },
98      pos => { char => '.', vtable => 'pos', value_magic => 1,
99               desc => 'pos() lvalue' },
100      backref => { char => '<', vtable => 'backref', value_magic => 1,
101                   readonly_acceptable => 1, desc => 'for weak ref data' },
102      symtab => { char => ':', value_magic => 1,
103                  desc => 'extra data for symbol tables' },
104      rhash => { char => '%', value_magic => 1,
105                 desc => 'extra data for restricted hashes' },
106      arylen_p => { char => '@', value_magic => 1,
107                    desc => 'to move arylen out of XPVAV' },
108      ext => { char => '~', desc => 'Available for use by extensions' },
109      checkcall => { char => ']', value_magic => 1, vtable => 'checkcall',
110                     desc => 'inlining/mutation of call to this CV'},
111      debugvar => { char => '*', desc => '$DB::single, signal, trace vars',
112                    vtable => 'debugvar' },
113 );
114
115 # These have a subtly different "namespace" from the magic types.
116 my %sig =
117     (
118      'sv' => {get => 'get', set => 'set'},
119      'env' => {set => 'set_all_env', clear => 'clear_all_env'},
120      'envelem' => {set => 'setenv', clear => 'clearenv'},
121      'sigelem' => {get => 'getsig', set => 'setsig', clear => 'clearsig',
122                    cond => '#ifndef PERL_MICRO'},
123      'pack' => {len => 'sizepack', clear => 'wipepack'},
124      'packelem' => {get => 'getpack', set => 'setpack', clear => 'clearpack'},
125      'dbline' => {set => 'setdbline'},
126      'isa' => {set => 'setisa', clear => 'clearisa'},
127      'isaelem' => {set => 'setisa'},
128      'arylen' => {get => 'getarylen', set => 'setarylen', const => 1},
129      'arylen_p' => {clear => 'cleararylen_p', free => 'freearylen_p'},
130      'mglob' => {set => 'setmglob'},
131      'nkeys' => {get => 'getnkeys', set => 'setnkeys'},
132      'taint' => {get => 'gettaint', set => 'settaint'},
133      'substr' => {get => 'getsubstr', set => 'setsubstr'},
134      'vec' => {get => 'getvec', set => 'setvec'},
135      'pos' => {get => 'getpos', set => 'setpos'},
136      'uvar' => {get => 'getuvar', set => 'setuvar'},
137      'defelem' => {get => 'getdefelem', set => 'setdefelem'},
138      'regexp' => {set => 'setregexp', alias => [qw(bm fm)]},
139      'regdata' => {len => 'regdata_cnt'},
140      'regdatum' => {get => 'regdatum_get', set => 'regdatum_set'},
141      'backref' => {free => 'killbackrefs'},
142      'ovrld' => {free => 'freeovrld'},
143      'utf8' => {set => 'setutf8'},
144      'collxfrm' => {set => 'setcollxfrm',
145                     cond => '#ifdef USE_LOCALE_COLLATE'},
146      'hintselem' => {set => 'sethint', clear => 'clearhint'},
147      'hints' => {clear => 'clearhints'},
148      'checkcall' => {copy => 'copycallchecker'},
149      'debugvar' => { set => 'setdebugvar', get => 'getdebugvar' },
150 );
151
152 my ($vt, $raw, $names) = map {
153     open_new($_, '>',
154              { by => 'regen/mg_vtable.pl', file => $_, style => '*' });
155 } 'mg_vtable.h', 'mg_raw.h', 'mg_names.c';
156 my $guts = open_new("pod/perlguts.pod", ">");
157
158 print $vt <<'EOH';
159 /* These constants should be used in preference to raw characters
160  * when using magic. Note that some perl guts still assume
161  * certain character properties of these constants, namely that
162  * isUPPER() and toLOWER() may do useful mappings.
163  */
164
165 EOH
166
167 # Of course, it would be *much* easier if we could output this table directly
168 # here and now. However, for our sins, we try to support EBCDIC, which wouldn't
169 # be *so* bad, except that there are (at least) 3 EBCDIC charset variants, and
170 # they don't agree on the code point for '~'. Which we use. Great.
171 # So we have to get the local build runtime to sort our table in character order
172 # (And of course, just to be helpful, in POSIX BC '~' is \xFF, so we can't even
173 # simplify the C code by assuming that the last element of the array is
174 # predictable)
175
176 {
177     my $longest = 0;
178     foreach (keys %mg) {
179         $longest = length $_ if length $_ > $longest;
180     }
181
182     my $longest_p1 = $longest + 1;
183
184     my %mg_order;
185     while (my ($name, $data) = each %mg) {
186         my $byte = eval qq{"$data->{char}"};
187         $data->{byte} = $byte;
188         $mg_order{(uc $byte) . $byte} = $name;
189     }
190     my @rows;
191     foreach (sort keys %mg_order) {
192         my $name = $mg_order{$_};
193         my $data = $mg{$name};
194         my $i = ord $data->{byte};
195         unless ($data->{unknown_to_sv_magic}) {
196             my $value = $data->{vtable}
197                 ? "want_vtbl_$data->{vtable}" : 'magic_vtable_max';
198             $value .= ' | PERL_MAGIC_READONLY_ACCEPTABLE'
199                 if $data->{readonly_acceptable};
200             $value .= ' | PERL_MAGIC_VALUE_MAGIC' if $data->{value_magic};
201             my $comment = "/* $name '$data->{char}' $data->{desc} */";
202             $comment =~ s/([\\"])/\\$1/g;
203             $comment =~ tr/\n/ /;
204             print $raw qq{    { '$data->{char}', "$value",\n      "$comment" },\n};
205         }
206
207         my $comment = $data->{desc};
208         my $leader = ' ' x ($longest + 27);
209         $comment =~ s/\n/\n$leader/s;
210         printf $vt "#define PERL_MAGIC_%-${longest}s '%s' /* %s */\n",
211             $name, $data->{char}, $comment;
212
213         my $char = $data->{char};
214         $char =~ s/([\\"])/\\$1/g;
215         printf $names qq[\t{ PERL_MAGIC_%-${longest_p1}s "%s(%s)" },\n],
216             "$name,", $name, $char;
217
218         push @rows, [(sprintf "%-2s PERL_MAGIC_%s", $data->{char}, $name),
219                      $data->{vtable} ? "vtbl_$data->{vtable}" : '(none)',
220                      $data->{desc}];
221     }
222     select +(select($guts), do {
223         my @header = ('(old-style char and macro)', 'MGVTBL', 'Type of magic');
224         my @widths = (0, 0);
225         foreach my $row (@rows) {
226             for (0, 1) {
227                 $widths[$_] = length $row->[$_]
228                     if length $row->[$_] > $widths[$_];
229             }
230         }
231         my $indent = ' ';
232         my $format
233             = sprintf "$indent%%-%ds%%-%ds%%s\n", $widths[0] + 1, $widths[1] + 1;
234         my $desc_wrap =
235             79 - 7 - (length $indent) - $widths[0] - $widths[1] - 2;
236
237         open my $oldguts, "<", "pod/perlguts.pod"
238            or die "$0 cannot open pod/perlguts.pod for reading: $!";
239         while (<$oldguts>) {
240             print;
241             last if /^=for mg_vtable.pl begin/
242         }
243
244         print "\n", $indent . "mg_type\n";
245         printf $format, @header;
246         printf $format, map {'-' x length $_} @header;
247         foreach (@rows) {
248             my ($type, $vtbl, $desc) = @$_;
249             $desc =~ tr/\n/ /;
250             my @cont;
251             if (length $desc > $desc_wrap) {
252                 # If it's too long, first split on '(', if there.
253                 # [Which, if there, is always short enough, currently.
254                 # Make this more robust if that changes]
255                 ($desc, @cont) = split /(?=\()/, $desc;
256                 if (!@cont) {
257                     ($desc, @cont) = $desc =~ /(.{1,$desc_wrap})(?: |\z)/g
258                 }
259             }
260             printf $format, $type, $vtbl, $desc;
261             printf $format, '', '', $_ foreach @cont;
262         }
263         print "\n";
264
265         while (<$oldguts>) {
266             last if /^=for mg_vtable.pl end/;
267         }
268         do { print } while <$oldguts>;
269     })[0];
270 }
271
272 my @names = sort keys %sig;
273 {
274     my $want = join ",\n    ", (map {"want_vtbl_$_"} @names), 'magic_vtable_max';
275     my $names = join qq{",\n    "}, @names;
276
277     print $vt <<"EOH";
278
279 enum {          /* pass one of these to get_vtbl */
280     $want
281 };
282
283 #ifdef DOINIT
284 EXTCONST char * const PL_magic_vtable_names[magic_vtable_max] = {
285     "$names"
286 };
287 #else
288 EXTCONST char * const PL_magic_vtable_names[magic_vtable_max];
289 #endif
290
291 EOH
292 }
293
294 print $vt <<'EOH';
295 /* These all need to be 0, not NULL, as NULL can be (void*)0, which is a
296  * pointer to data, whereas we're assigning pointers to functions, which are
297  * not the same beast. ANSI doesn't allow the assignment from one to the other.
298  * (although most, but not all, compilers are prepared to do it)
299  */
300
301 /* order is:
302     get
303     set
304     len
305     clear
306     free
307     copy
308     dup
309     local
310 */
311
312 #ifdef DOINIT
313 EXT_MGVTBL PL_magic_vtables[magic_vtable_max] = {
314 EOH
315
316 my @vtable_names;
317 my @aliases;
318
319 while (my $name = shift @names) {
320     my $data = $sig{$name};
321     push @vtable_names, $name;
322     my @funcs = map {
323         $data->{$_} ? "Perl_magic_$data->{$_}" : 0;
324     } qw(get set len clear free copy dup local);
325
326     $funcs[0] = "(int (*)(pTHX_ SV *, MAGIC *))" . $funcs[0] if $data->{const};
327     my $funcs = join ", ", @funcs;
328
329     # Because we can't have a , after the last {...}
330     my $comma = @names ? ',' : '';
331
332     print $vt "$data->{cond}\n" if $data->{cond};
333     print $vt "  { $funcs }$comma\n";
334     print $vt <<"EOH" if $data->{cond};
335 #else
336   { 0, 0, 0, 0, 0, 0, 0, 0 }$comma
337 #endif
338 EOH
339     foreach(@{$data->{alias}}) {
340         push @aliases, "#define want_vtbl_$_ want_vtbl_$name\n";
341         push @vtable_names, $_;
342     }
343 }
344
345 print $vt <<'EOH';
346 };
347 #else
348 EXT_MGVTBL PL_magic_vtables[magic_vtable_max];
349 #endif
350
351 EOH
352
353 print $vt (sort @aliases), "\n";
354
355 print $vt "#define PL_vtbl_$_ PL_magic_vtables[want_vtbl_$_]\n"
356     foreach sort @vtable_names;
357
358 # 63, not 64, As we rely on the last possible value to mean "NULL vtable"
359 die "Too many vtable names" if @vtable_names > 63;
360
361 read_only_bottom_close_and_rename($_) foreach $vt, $raw, $names;
362                  close_and_rename($guts);