This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
504b7b35229a1b020fc26078349d3b11e3ec4a82
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 =for Pod::Functions =String
111
112 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
113 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
114 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
115
116 C<fc> is available only if the C<"fc"> feature is enabled or if it is
117 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
118 with a C<use v5.16> (or higher) declaration in the current scope.
119
120
121 =item Regular expressions and pattern matching
122 X<regular expression> X<regex> X<regexp>
123
124 =for Pod::Functions =Regexp
125
126 C<m//>, C<pos>, C<qr//>, C<quotemeta>, C<s///>, C<split>, C<study>
127
128 =item Numeric functions
129 X<numeric> X<number> X<trigonometric> X<trigonometry>
130
131 =for Pod::Functions =Math
132
133 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
134 C<sin>, C<sqrt>, C<srand>
135
136 =item Functions for real @ARRAYs
137 X<array>
138
139 =for Pod::Functions =ARRAY
140
141 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
142
143 =item Functions for list data
144 X<list>
145
146 =for Pod::Functions =LIST
147
148 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
149
150 =item Functions for real %HASHes
151 X<hash>
152
153 =for Pod::Functions =HASH
154
155 C<delete>, C<each>, C<exists>, C<keys>, C<values>
156
157 =item Input and output functions
158 X<I/O> X<input> X<output> X<dbm>
159
160 =for Pod::Functions =I/O
161
162 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
163 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
164 C<readdir>, C<readline> C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>,
165 C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>,
166 C<truncate>, C<warn>, C<write>
167
168 C<say> is available only if the C<"say"> feature is enabled or if it is
169 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
170 with a C<use v5.10> (or higher) declaration in the current scope.
171
172 =item Functions for fixed-length data or records
173
174 =for Pod::Functions =Binary
175
176 C<pack>, C<read>, C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<unpack>,
177 C<vec>
178
179 =item Functions for filehandles, files, or directories
180 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
181
182 =for Pod::Functions =File
183
184 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
185 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
186 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
187 C<umask>, C<unlink>, C<utime>
188
189 =item Keywords related to the control flow of your Perl program
190 X<control flow>
191
192 =for Pod::Functions =Flow
193
194 C<break>, C<caller>, C<continue>, C<die>, C<do>,
195 C<dump>, C<eval>, C<evalbytes> C<exit>,
196 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
197 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
198
199 C<break> is available only if you enable the experimental C<"switch">
200 feature or use the C<CORE::> prefix. The C<"switch"> feature also enables
201 the C<default>, C<given> and C<when> statements, which are documented in
202 L<perlsyn/"Switch Statements">. The C<"switch"> feature is enabled
203 automatically with a C<use v5.10> (or higher) declaration in the current
204 scope. In Perl v5.14 and earlier, C<continue> required the C<"switch">
205 feature, like the other keywords.
206
207 C<evalbytes> is only available with the C<"evalbytes"> feature (see
208 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
209 with the C<"current_sub"> feature or if prefixed with C<CORE::>. Both
210 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
211 with a C<use v5.16> (or higher) declaration in the current scope.
212
213 =item Keywords related to scoping
214
215 =for Pod::Functions =Namespace
216
217 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
218
219 C<state> is available only if the C<"state"> feature is enabled or if it is
220 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
221 with a C<use v5.10> (or higher) declaration in the current scope.
222
223 =item Miscellaneous functions
224
225 =for Pod::Functions =Misc
226
227 C<defined>, C<formline>, C<lock>, C<prototype>, C<reset>, C<scalar>, C<undef>
228
229 =item Functions for processes and process groups
230 X<process> X<pid> X<process id>
231
232 =for Pod::Functions =Process
233
234 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
235 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
236 C<setpriority>, C<sleep>, C<system>,
237 C<times>, C<wait>, C<waitpid>
238
239 =item Keywords related to Perl modules
240 X<module>
241
242 =for Pod::Functions =Modules
243
244 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
245
246 =item Keywords related to classes and object-orientation
247 X<object> X<class> X<package>
248
249 =for Pod::Functions =Objects
250
251 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
252 C<untie>, C<use>
253
254 =item Low-level socket functions
255 X<socket> X<sock>
256
257 =for Pod::Functions =Socket
258
259 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
260 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
261 C<socket>, C<socketpair>
262
263 =item System V interprocess communication functions
264 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
265
266 =for Pod::Functions =SysV
267
268 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
269 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
270
271 =item Fetching user and group info
272 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
273
274 =for Pod::Functions =User
275
276 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
277 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
278 C<getpwuid>, C<setgrent>, C<setpwent>
279
280 =item Fetching network info
281 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
282
283 =for Pod::Functions =Network
284
285 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
286 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
287 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
288 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
289 C<setnetent>, C<setprotoent>, C<setservent>
290
291 =item Time-related functions
292 X<time> X<date>
293
294 =for Pod::Functions =Time
295
296 C<gmtime>, C<localtime>, C<time>, C<times>
297
298 =item Non-function keywords
299
300 =for Pod::Functions =!Non-functions
301
302 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
303 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
304 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
305 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
306 C<while>, C<x>, C<xor>
307
308 =back
309
310 =head2 Portability
311 X<portability> X<Unix> X<portable>
312
313 Perl was born in Unix and can therefore access all common Unix
314 system calls.  In non-Unix environments, the functionality of some
315 Unix system calls may not be available or details of the available
316 functionality may differ slightly.  The Perl functions affected
317 by this are:
318
319 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
320 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
321 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
322 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
323 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
324 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
325 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
326 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
327 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
328 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
329 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
330 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
331 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
332 C<shmwrite>, C<socket>, C<socketpair>,
333 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
334 C<times>, C<truncate>, C<umask>, C<unlink>,
335 C<utime>, C<wait>, C<waitpid>
336
337 For more information about the portability of these functions, see
338 L<perlport> and other available platform-specific documentation.
339
340 =head2 Alphabetical Listing of Perl Functions
341
342 =over 
343
344 =item -X FILEHANDLE
345 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
346 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
347
348 =item -X EXPR
349
350 =item -X DIRHANDLE
351
352 =item -X
353
354 =for Pod::Functions a file test (-r, -x, etc)
355
356 A file test, where X is one of the letters listed below.  This unary
357 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
358 and tests the associated file to see if something is true about it.  If the
359 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
360 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
361 the undefined value if the file doesn't exist.  Despite the funny
362 names, precedence is the same as any other named unary operator.  The
363 operator may be any of:
364
365     -r  File is readable by effective uid/gid.
366     -w  File is writable by effective uid/gid.
367     -x  File is executable by effective uid/gid.
368     -o  File is owned by effective uid.
369
370     -R  File is readable by real uid/gid.
371     -W  File is writable by real uid/gid.
372     -X  File is executable by real uid/gid.
373     -O  File is owned by real uid.
374
375     -e  File exists.
376     -z  File has zero size (is empty).
377     -s  File has nonzero size (returns size in bytes).
378
379     -f  File is a plain file.
380     -d  File is a directory.
381     -l  File is a symbolic link.
382     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
383     -S  File is a socket.
384     -b  File is a block special file.
385     -c  File is a character special file.
386     -t  Filehandle is opened to a tty.
387
388     -u  File has setuid bit set.
389     -g  File has setgid bit set.
390     -k  File has sticky bit set.
391
392     -T  File is an ASCII text file (heuristic guess).
393     -B  File is a "binary" file (opposite of -T).
394
395     -M  Script start time minus file modification time, in days.
396     -A  Same for access time.
397     -C  Same for inode change time (Unix, may differ for other
398         platforms)
399
400 Example:
401
402     while (<>) {
403         chomp;
404         next unless -f $_;  # ignore specials
405         #...
406     }
407
408 Note that C<-s/a/b/> does not do a negated substitution.  Saying
409 C<-exp($foo)> still works as expected, however: only single letters
410 following a minus are interpreted as file tests.
411
412 These operators are exempt from the "looks like a function rule" described
413 above.  That is, an opening parenthesis after the operator does not affect
414 how much of the following code constitutes the argument.  Put the opening
415 parentheses before the operator to separate it from code that follows (this
416 applies only to operators with higher precedence than unary operators, of
417 course):
418
419     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
420     (-s $file) + 1024  # correct
421
422 The interpretation of the file permission operators C<-r>, C<-R>,
423 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
424 of the file and the uids and gids of the user.  There may be other
425 reasons you can't actually read, write, or execute the file: for
426 example network filesystem access controls, ACLs (access control lists),
427 read-only filesystems, and unrecognized executable formats.  Note
428 that the use of these six specific operators to verify if some operation
429 is possible is usually a mistake, because it may be open to race
430 conditions.
431
432 Also note that, for the superuser on the local filesystems, the C<-r>,
433 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
434 if any execute bit is set in the mode.  Scripts run by the superuser
435 may thus need to do a stat() to determine the actual mode of the file,
436 or temporarily set their effective uid to something else.
437
438 If you are using ACLs, there is a pragma called C<filetest> that may
439 produce more accurate results than the bare stat() mode bits.
440 When under C<use filetest 'access'> the above-mentioned filetests
441 test whether the permission can(not) be granted using the
442 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
443 under this pragma return true even if there are no execute permission
444 bits set (nor any extra execute permission ACLs).  This strangeness is
445 due to the underlying system calls' definitions.  Note also that, due to
446 the implementation of C<use filetest 'access'>, the C<_> special
447 filehandle won't cache the results of the file tests when this pragma is
448 in effect.  Read the documentation for the C<filetest> pragma for more
449 information.
450
451 The C<-T> and C<-B> switches work as follows.  The first block or so of the
452 file is examined for odd characters such as strange control codes or
453 characters with the high bit set.  If too many strange characters (>30%)
454 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
455 containing a zero byte in the first block is considered a binary file.  If C<-T>
456 or C<-B> is used on a filehandle, the current IO buffer is examined
457 rather than the first block.  Both C<-T> and C<-B> return true on an empty
458 file, or a file at EOF when testing a filehandle.  Because you have to
459 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
460 against the file first, as in C<next unless -f $file && -T $file>.
461
462 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
463 the special filehandle consisting of a solitary underline, then the stat
464 structure of the previous file test (or stat operator) is used, saving
465 a system call.  (This doesn't work with C<-t>, and you need to remember
466 that lstat() and C<-l> leave values in the stat structure for the
467 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
468 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
469 Example:
470
471     print "Can do.\n" if -r $a || -w _ || -x _;
472
473     stat($filename);
474     print "Readable\n" if -r _;
475     print "Writable\n" if -w _;
476     print "Executable\n" if -x _;
477     print "Setuid\n" if -u _;
478     print "Setgid\n" if -g _;
479     print "Sticky\n" if -k _;
480     print "Text\n" if -T _;
481     print "Binary\n" if -B _;
482
483 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
484 test operators, in a way that C<-f -w -x $file> is equivalent to
485 C<-x $file && -w _ && -f _>.  (This is only fancy fancy: if you use
486 the return value of C<-f $file> as an argument to another filetest
487 operator, no special magic will happen.)
488
489 Portability issues: L<perlport/-X>.
490
491 To avoid confusing would-be users of your code with mysterious
492 syntax errors, put something like this at the top of your script:
493
494     use 5.010;  # so filetest ops can stack
495
496 =item abs VALUE
497 X<abs> X<absolute>
498
499 =item abs
500
501 =for Pod::Functions absolute value function
502
503 Returns the absolute value of its argument.
504 If VALUE is omitted, uses C<$_>.
505
506 =item accept NEWSOCKET,GENERICSOCKET
507 X<accept>
508
509 =for Pod::Functions accept an incoming socket connect
510
511 Accepts an incoming socket connect, just as accept(2) 
512 does.  Returns the packed address if it succeeded, false otherwise.
513 See the example in L<perlipc/"Sockets: Client/Server Communication">.
514
515 On systems that support a close-on-exec flag on files, the flag will
516 be set for the newly opened file descriptor, as determined by the
517 value of $^F.  See L<perlvar/$^F>.
518
519 =item alarm SECONDS
520 X<alarm>
521 X<SIGALRM>
522 X<timer>
523
524 =item alarm
525
526 =for Pod::Functions schedule a SIGALRM
527
528 Arranges to have a SIGALRM delivered to this process after the
529 specified number of wallclock seconds has elapsed.  If SECONDS is not
530 specified, the value stored in C<$_> is used.  (On some machines,
531 unfortunately, the elapsed time may be up to one second less or more
532 than you specified because of how seconds are counted, and process
533 scheduling may delay the delivery of the signal even further.)
534
535 Only one timer may be counting at once.  Each call disables the
536 previous timer, and an argument of C<0> may be supplied to cancel the
537 previous timer without starting a new one.  The returned value is the
538 amount of time remaining on the previous timer.
539
540 For delays of finer granularity than one second, the Time::HiRes module
541 (from CPAN, and starting from Perl 5.8 part of the standard
542 distribution) provides ualarm().  You may also use Perl's four-argument
543 version of select() leaving the first three arguments undefined, or you
544 might be able to use the C<syscall> interface to access setitimer(2) if
545 your system supports it.  See L<perlfaq8> for details.
546
547 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
548 C<sleep> may be internally implemented on your system with C<alarm>.
549
550 If you want to use C<alarm> to time out a system call you need to use an
551 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
552 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
553 restart system calls on some systems.  Using C<eval>/C<die> always works,
554 modulo the caveats given in L<perlipc/"Signals">.
555
556     eval {
557         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
558         alarm $timeout;
559         $nread = sysread SOCKET, $buffer, $size;
560         alarm 0;
561     };
562     if ($@) {
563         die unless $@ eq "alarm\n";   # propagate unexpected errors
564         # timed out
565     }
566     else {
567         # didn't
568     }
569
570 For more information see L<perlipc>.
571
572 Portability issues: L<perlport/alarm>.
573
574 =item atan2 Y,X
575 X<atan2> X<arctangent> X<tan> X<tangent>
576
577 =for Pod::Functions arctangent of Y/X in the range -PI to PI
578
579 Returns the arctangent of Y/X in the range -PI to PI.
580
581 For the tangent operation, you may use the C<Math::Trig::tan>
582 function, or use the familiar relation:
583
584     sub tan { sin($_[0]) / cos($_[0])  }
585
586 The return value for C<atan2(0,0)> is implementation-defined; consult
587 your atan2(3) manpage for more information.
588
589 Portability issues: L<perlport/atan2>.
590
591 =item bind SOCKET,NAME
592 X<bind>
593
594 =for Pod::Functions binds an address to a socket
595
596 Binds a network address to a socket, just as bind(2)
597 does.  Returns true if it succeeded, false otherwise.  NAME should be a
598 packed address of the appropriate type for the socket.  See the examples in
599 L<perlipc/"Sockets: Client/Server Communication">.
600
601 =item binmode FILEHANDLE, LAYER
602 X<binmode> X<binary> X<text> X<DOS> X<Windows>
603
604 =item binmode FILEHANDLE
605
606 =for Pod::Functions prepare binary files for I/O
607
608 Arranges for FILEHANDLE to be read or written in "binary" or "text"
609 mode on systems where the run-time libraries distinguish between
610 binary and text files.  If FILEHANDLE is an expression, the value is
611 taken as the name of the filehandle.  Returns true on success,
612 otherwise it returns C<undef> and sets C<$!> (errno).
613
614 On some systems (in general, DOS- and Windows-based systems) binmode()
615 is necessary when you're not working with a text file.  For the sake
616 of portability it is a good idea always to use it when appropriate,
617 and never to use it when it isn't appropriate.  Also, people can
618 set their I/O to be by default UTF8-encoded Unicode, not bytes.
619
620 In other words: regardless of platform, use binmode() on binary data,
621 like images, for example.
622
623 If LAYER is present it is a single string, but may contain multiple
624 directives.  The directives alter the behaviour of the filehandle.
625 When LAYER is present, using binmode on a text file makes sense.
626
627 If LAYER is omitted or specified as C<:raw> the filehandle is made
628 suitable for passing binary data.  This includes turning off possible CRLF
629 translation and marking it as bytes (as opposed to Unicode characters).
630 Note that, despite what may be implied in I<"Programming Perl"> (the
631 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
632 Other layers that would affect the binary nature of the stream are
633 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
634 PERLIO environment variable.
635
636 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
637 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
638 establish default I/O layers.  See L<open>.
639
640 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
641 in "Programming Perl, 3rd Edition".  However, since the publishing of this
642 book, by many known as "Camel III", the consensus of the naming of this
643 functionality has moved from "discipline" to "layer".  All documentation
644 of this version of Perl therefore refers to "layers" rather than to
645 "disciplines".  Now back to the regularly scheduled documentation...>
646
647 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
648 C<:utf8> just marks the data as UTF-8 without further checking,
649 while C<:encoding(UTF-8)> checks the data for actually being valid
650 UTF-8.  More details can be found in L<PerlIO::encoding>.
651
652 In general, binmode() should be called after open() but before any I/O
653 is done on the filehandle.  Calling binmode() normally flushes any
654 pending buffered output data (and perhaps pending input data) on the
655 handle.  An exception to this is the C<:encoding> layer that
656 changes the default character encoding of the handle; see L</open>.
657 The C<:encoding> layer sometimes needs to be called in
658 mid-stream, and it doesn't flush the stream.  The C<:encoding>
659 also implicitly pushes on top of itself the C<:utf8> layer because
660 internally Perl operates on UTF8-encoded Unicode characters.
661
662 The operating system, device drivers, C libraries, and Perl run-time
663 system all conspire to let the programmer treat a single
664 character (C<\n>) as the line terminator, irrespective of external
665 representation.  On many operating systems, the native text file
666 representation matches the internal representation, but on some
667 platforms the external representation of C<\n> is made up of more than
668 one character.
669
670 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
671 a single character to end each line in the external representation of text
672 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
673 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
674 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
675 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
676 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
677 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
678 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
679 output.  This is what you want for text files, but it can be disastrous for
680 binary files.
681
682 Another consequence of using binmode() (on some systems) is that
683 special end-of-file markers will be seen as part of the data stream.
684 For systems from the Microsoft family this means that, if your binary
685 data contain C<\cZ>, the I/O subsystem will regard it as the end of
686 the file, unless you use binmode().
687
688 binmode() is important not only for readline() and print() operations,
689 but also when using read(), seek(), sysread(), syswrite() and tell()
690 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
691 in L<perlvar> for how to manually set your input and output
692 line-termination sequences.
693
694 Portability issues: L<perlport/binmode>.
695
696 =item bless REF,CLASSNAME
697 X<bless>
698
699 =item bless REF
700
701 =for Pod::Functions create an object
702
703 This function tells the thingy referenced by REF that it is now an object
704 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
705 is used.  Because a C<bless> is often the last thing in a constructor,
706 it returns the reference for convenience.  Always use the two-argument
707 version if a derived class might inherit the function doing the blessing.
708 See L<perlobj> for more about the blessing (and blessings) of objects.
709
710 Consider always blessing objects in CLASSNAMEs that are mixed case.
711 Namespaces with all lowercase names are considered reserved for
712 Perl pragmata.  Builtin types have all uppercase names.  To prevent
713 confusion, you may wish to avoid such package names as well.  Make sure
714 that CLASSNAME is a true value.
715
716 See L<perlmod/"Perl Modules">.
717
718 =item break
719
720 =for Pod::Functions +switch break out of a C<given> block
721
722 Break out of a C<given()> block.
723
724 This keyword is enabled by the C<"switch"> feature; see L<feature> for
725 more information on C<"switch">.  You can also access it by prefixing it
726 with C<CORE::>.  Alternatively, include a C<use v5.10> or later to the
727 current scope.
728
729 =item caller EXPR
730 X<caller> X<call stack> X<stack> X<stack trace>
731
732 =item caller
733
734 =for Pod::Functions get context of the current subroutine call
735
736 Returns the context of the current subroutine call.  In scalar context,
737 returns the caller's package name if there I<is> a caller (that is, if
738 we're in a subroutine or C<eval> or C<require>) and the undefined value
739 otherwise.  In list context, returns
740
741     # 0         1          2
742     ($package, $filename, $line) = caller;
743
744 With EXPR, it returns some extra information that the debugger uses to
745 print a stack trace.  The value of EXPR indicates how many call frames
746 to go back before the current one.
747
748     #  0         1          2      3            4
749     ($package, $filename, $line, $subroutine, $hasargs,
750
751     #  5          6          7            8       9         10
752     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
753      = caller($i);
754
755 Here $subroutine may be C<(eval)> if the frame is not a subroutine
756 call, but an C<eval>.  In such a case additional elements $evaltext and
757 C<$is_require> are set: C<$is_require> is true if the frame is created by a
758 C<require> or C<use> statement, $evaltext contains the text of the
759 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
760 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
761 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
762 frame.)  $subroutine may also be C<(unknown)> if this particular
763 subroutine happens to have been deleted from the symbol table.
764 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
765 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
766 compiled with.  C<$hints> corresponds to C<$^H>, and C<$bitmask>
767 corresponds to C<${^WARNING_BITS}>.  The
768 C<$hints> and C<$bitmask> values are subject
769 to change between versions of Perl, and are not meant for external use.
770
771 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
772 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
773 of this hash, as they are the actual values stored in the optree.
774
775 Furthermore, when called from within the DB package in
776 list context, and with an argument, caller returns more
777 detailed information: it sets the list variable C<@DB::args> to be the
778 arguments with which the subroutine was invoked.
779
780 Be aware that the optimizer might have optimized call frames away before
781 C<caller> had a chance to get the information.  That means that C<caller(N)>
782 might not return information about the call frame you expect it to, for
783 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
784 previous time C<caller> was called.
785
786 Be aware that setting C<@DB::args> is I<best effort>, intended for
787 debugging or generating backtraces, and should not be relied upon.  In
788 particular, as C<@_> contains aliases to the caller's arguments, Perl does
789 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
790 subroutine makes to C<@_> or its contents, not the original values at call
791 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
792 elements, so under certain cases its elements may have become freed and
793 reallocated for other variables or temporary values.  Finally, a side effect
794 of the current implementation is that the effects of C<shift @_> can
795 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
796 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
797 elements), so C<@DB::args> is actually a hybrid of the current state and
798 initial state of C<@_>.  Buyer beware.
799
800 =item chdir EXPR
801 X<chdir>
802 X<cd>
803 X<directory, change>
804
805 =item chdir FILEHANDLE
806
807 =item chdir DIRHANDLE
808
809 =item chdir
810
811 =for Pod::Functions change your current working directory
812
813 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
814 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
815 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
816 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
817 neither is set, C<chdir> does nothing.  It returns true on success,
818 false otherwise.  See the example under C<die>.
819
820 On systems that support fchdir(2), you may pass a filehandle or
821 directory handle as the argument.  On systems that don't support fchdir(2),
822 passing handles raises an exception.
823
824 =item chmod LIST
825 X<chmod> X<permission> X<mode>
826
827 =for Pod::Functions changes the permissions on a list of files
828
829 Changes the permissions of a list of files.  The first element of the
830 list must be the numeric mode, which should probably be an octal
831 number, and which definitely should I<not> be a string of octal digits:
832 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
833 successfully changed.  See also L</oct> if all you have is a string.
834
835     $cnt = chmod 0755, "foo", "bar";
836     chmod 0755, @executables;
837     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
838                                              # --w----r-T
839     $mode = "0644"; chmod oct($mode), "foo"; # this is better
840     $mode = 0644;   chmod $mode, "foo";      # this is best
841
842 On systems that support fchmod(2), you may pass filehandles among the
843 files.  On systems that don't support fchmod(2), passing filehandles raises
844 an exception.  Filehandles must be passed as globs or glob references to be
845 recognized; barewords are considered filenames.
846
847     open(my $fh, "<", "foo");
848     my $perm = (stat $fh)[2] & 07777;
849     chmod($perm | 0600, $fh);
850
851 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
852 module:
853
854     use Fcntl qw( :mode );
855     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
856     # Identical to the chmod 0755 of the example above.
857
858 Portability issues: L<perlport/chmod>.
859
860 =item chomp VARIABLE
861 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
862
863 =item chomp( LIST )
864
865 =item chomp
866
867 =for Pod::Functions remove a trailing record separator from a string
868
869 This safer version of L</chop> removes any trailing string
870 that corresponds to the current value of C<$/> (also known as
871 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
872 number of characters removed from all its arguments.  It's often used to
873 remove the newline from the end of an input record when you're worried
874 that the final record may be missing its newline.  When in paragraph
875 mode (C<$/ = "">), it removes all trailing newlines from the string.
876 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
877 a reference to an integer or the like; see L<perlvar>) chomp() won't
878 remove anything.
879 If VARIABLE is omitted, it chomps C<$_>.  Example:
880
881     while (<>) {
882         chomp;  # avoid \n on last field
883         @array = split(/:/);
884         # ...
885     }
886
887 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
888
889 You can actually chomp anything that's an lvalue, including an assignment:
890
891     chomp($cwd = `pwd`);
892     chomp($answer = <STDIN>);
893
894 If you chomp a list, each element is chomped, and the total number of
895 characters removed is returned.
896
897 Note that parentheses are necessary when you're chomping anything
898 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
899 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
900 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
901 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
902 as C<chomp($a, $b)>.
903
904 =item chop VARIABLE
905 X<chop>
906
907 =item chop( LIST )
908
909 =item chop
910
911 =for Pod::Functions remove the last character from a string
912
913 Chops off the last character of a string and returns the character
914 chopped.  It is much more efficient than C<s/.$//s> because it neither
915 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
916 If VARIABLE is a hash, it chops the hash's values, but not its keys.
917
918 You can actually chop anything that's an lvalue, including an assignment.
919
920 If you chop a list, each element is chopped.  Only the value of the
921 last C<chop> is returned.
922
923 Note that C<chop> returns the last character.  To return all but the last
924 character, use C<substr($string, 0, -1)>.
925
926 See also L</chomp>.
927
928 =item chown LIST
929 X<chown> X<owner> X<user> X<group>
930
931 =for Pod::Functions change the ownership on a list of files
932
933 Changes the owner (and group) of a list of files.  The first two
934 elements of the list must be the I<numeric> uid and gid, in that
935 order.  A value of -1 in either position is interpreted by most
936 systems to leave that value unchanged.  Returns the number of files
937 successfully changed.
938
939     $cnt = chown $uid, $gid, 'foo', 'bar';
940     chown $uid, $gid, @filenames;
941
942 On systems that support fchown(2), you may pass filehandles among the
943 files.  On systems that don't support fchown(2), passing filehandles raises
944 an exception.  Filehandles must be passed as globs or glob references to be
945 recognized; barewords are considered filenames.
946
947 Here's an example that looks up nonnumeric uids in the passwd file:
948
949     print "User: ";
950     chomp($user = <STDIN>);
951     print "Files: ";
952     chomp($pattern = <STDIN>);
953
954     ($login,$pass,$uid,$gid) = getpwnam($user)
955         or die "$user not in passwd file";
956
957     @ary = glob($pattern);  # expand filenames
958     chown $uid, $gid, @ary;
959
960 On most systems, you are not allowed to change the ownership of the
961 file unless you're the superuser, although you should be able to change
962 the group to any of your secondary groups.  On insecure systems, these
963 restrictions may be relaxed, but this is not a portable assumption.
964 On POSIX systems, you can detect this condition this way:
965
966     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
967     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
968
969 Portability issues: L<perlport/chmod>.
970
971 =item chr NUMBER
972 X<chr> X<character> X<ASCII> X<Unicode>
973
974 =item chr
975
976 =for Pod::Functions get character this number represents
977
978 Returns the character represented by that NUMBER in the character set.
979 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
980 chr(0x263a) is a Unicode smiley face.  
981
982 Negative values give the Unicode replacement character (chr(0xfffd)),
983 except under the L<bytes> pragma, where the low eight bits of the value
984 (truncated to an integer) are used.
985
986 If NUMBER is omitted, uses C<$_>.
987
988 For the reverse, use L</ord>.
989
990 Note that characters from 128 to 255 (inclusive) are by default
991 internally not encoded as UTF-8 for backward compatibility reasons.
992
993 See L<perlunicode> for more about Unicode.
994
995 =item chroot FILENAME
996 X<chroot> X<root>
997
998 =item chroot
999
1000 =for Pod::Functions make directory new root for path lookups
1001
1002 This function works like the system call by the same name: it makes the
1003 named directory the new root directory for all further pathnames that
1004 begin with a C</> by your process and all its children.  (It doesn't
1005 change your current working directory, which is unaffected.)  For security
1006 reasons, this call is restricted to the superuser.  If FILENAME is
1007 omitted, does a C<chroot> to C<$_>.
1008
1009 Portability issues: L<perlport/chroot>.
1010
1011 =item close FILEHANDLE
1012 X<close>
1013
1014 =item close
1015
1016 =for Pod::Functions close file (or pipe or socket) handle
1017
1018 Closes the file or pipe associated with the filehandle, flushes the IO
1019 buffers, and closes the system file descriptor.  Returns true if those
1020 operations succeed and if no error was reported by any PerlIO
1021 layer.  Closes the currently selected filehandle if the argument is
1022 omitted.
1023
1024 You don't have to close FILEHANDLE if you are immediately going to do
1025 another C<open> on it, because C<open> closes it for you.  (See
1026 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
1027 counter (C<$.>), while the implicit close done by C<open> does not.
1028
1029 If the filehandle came from a piped open, C<close> returns false if one of
1030 the other syscalls involved fails or if its program exits with non-zero
1031 status.  If the only problem was that the program exited non-zero, C<$!>
1032 will be set to C<0>.  Closing a pipe also waits for the process executing
1033 on the pipe to exit--in case you wish to look at the output of the pipe
1034 afterwards--and implicitly puts the exit status value of that command into
1035 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
1036
1037 If there are multiple threads running, C<close> on a filehandle from a
1038 piped open returns true without waiting for the child process to terminate,
1039 if the filehandle is still open in another thread.
1040
1041 Closing the read end of a pipe before the process writing to it at the
1042 other end is done writing results in the writer receiving a SIGPIPE.  If
1043 the other end can't handle that, be sure to read all the data before
1044 closing the pipe.
1045
1046 Example:
1047
1048     open(OUTPUT, '|sort >foo')  # pipe to sort
1049         or die "Can't start sort: $!";
1050     #...                        # print stuff to output
1051     close OUTPUT                # wait for sort to finish
1052         or warn $! ? "Error closing sort pipe: $!"
1053                    : "Exit status $? from sort";
1054     open(INPUT, 'foo')          # get sort's results
1055         or die "Can't open 'foo' for input: $!";
1056
1057 FILEHANDLE may be an expression whose value can be used as an indirect
1058 filehandle, usually the real filehandle name or an autovivified handle.
1059
1060 =item closedir DIRHANDLE
1061 X<closedir>
1062
1063 =for Pod::Functions close directory handle
1064
1065 Closes a directory opened by C<opendir> and returns the success of that
1066 system call.
1067
1068 =item connect SOCKET,NAME
1069 X<connect>
1070
1071 =for Pod::Functions connect to a remote socket
1072
1073 Attempts to connect to a remote socket, just like connect(2).
1074 Returns true if it succeeded, false otherwise.  NAME should be a
1075 packed address of the appropriate type for the socket.  See the examples in
1076 L<perlipc/"Sockets: Client/Server Communication">.
1077
1078 =item continue BLOCK
1079 X<continue>
1080
1081 =item continue
1082
1083 =for Pod::Functions optional trailing block in a while or foreach
1084
1085 When followed by a BLOCK, C<continue> is actually a
1086 flow control statement rather than a function.  If
1087 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1088 C<foreach>), it is always executed just before the conditional is about to
1089 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1090 it can be used to increment a loop variable, even when the loop has been
1091 continued via the C<next> statement (which is similar to the C C<continue>
1092 statement).
1093
1094 C<last>, C<next>, or C<redo> may appear within a C<continue>
1095 block; C<last> and C<redo> behave as if they had been executed within
1096 the main block.  So will C<next>, but since it will execute a C<continue>
1097 block, it may be more entertaining.
1098
1099     while (EXPR) {
1100         ### redo always comes here
1101         do_something;
1102     } continue {
1103         ### next always comes here
1104         do_something_else;
1105         # then back the top to re-check EXPR
1106     }
1107     ### last always comes here
1108
1109 Omitting the C<continue> section is equivalent to using an
1110 empty one, logically enough, so C<next> goes directly back
1111 to check the condition at the top of the loop.
1112
1113 When there is no BLOCK, C<continue> is a function that
1114 falls through the current C<when> or C<default> block instead of iterating
1115 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1116 In Perl 5.14 and earlier, this form of C<continue> was
1117 only available when the C<"switch"> feature was enabled.
1118 See L<feature> and L<perlsyn/"Switch Statements"> for more
1119 information.
1120
1121 =item cos EXPR
1122 X<cos> X<cosine> X<acos> X<arccosine>
1123
1124 =item cos
1125
1126 =for Pod::Functions cosine function
1127
1128 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1129 takes the cosine of C<$_>.
1130
1131 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1132 function, or use this relation:
1133
1134     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1135
1136 =item crypt PLAINTEXT,SALT
1137 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1138 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1139
1140 =for Pod::Functions one-way passwd-style encryption
1141
1142 Creates a digest string exactly like the crypt(3) function in the C
1143 library (assuming that you actually have a version there that has not
1144 been extirpated as a potential munition).
1145
1146 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1147 into a short string, called a digest, which is returned.  The same
1148 PLAINTEXT and SALT will always return the same string, but there is no
1149 (known) way to get the original PLAINTEXT from the hash.  Small
1150 changes in the PLAINTEXT or SALT will result in large changes in the
1151 digest.
1152
1153 There is no decrypt function.  This function isn't all that useful for
1154 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1155 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1156 primarily used to check if two pieces of text are the same without
1157 having to transmit or store the text itself.  An example is checking
1158 if a correct password is given.  The digest of the password is stored,
1159 not the password itself.  The user types in a password that is
1160 crypt()'d with the same salt as the stored digest.  If the two digests
1161 match, the password is correct.
1162
1163 When verifying an existing digest string you should use the digest as
1164 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1165 to create the digest is visible as part of the digest.  This ensures
1166 crypt() will hash the new string with the same salt as the digest.
1167 This allows your code to work with the standard L<crypt|/crypt> and
1168 with more exotic implementations.  In other words, assume
1169 nothing about the returned string itself nor about how many bytes 
1170 of SALT may matter.
1171
1172 Traditionally the result is a string of 13 bytes: two first bytes of
1173 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1174 the first eight bytes of PLAINTEXT mattered.  But alternative
1175 hashing schemes (like MD5), higher level security schemes (like C2),
1176 and implementations on non-Unix platforms may produce different
1177 strings.
1178
1179 When choosing a new salt create a random two character string whose
1180 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1181 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1182 characters is just a recommendation; the characters allowed in
1183 the salt depend solely on your system's crypt library, and Perl can't
1184 restrict what salts C<crypt()> accepts.
1185
1186 Here's an example that makes sure that whoever runs this program knows
1187 their password:
1188
1189     $pwd = (getpwuid($<))[1];
1190
1191     system "stty -echo";
1192     print "Password: ";
1193     chomp($word = <STDIN>);
1194     print "\n";
1195     system "stty echo";
1196
1197     if (crypt($word, $pwd) ne $pwd) {
1198         die "Sorry...\n";
1199     } else {
1200         print "ok\n";
1201     }
1202
1203 Of course, typing in your own password to whoever asks you
1204 for it is unwise.
1205
1206 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1207 of data, not least of all because you can't get the information
1208 back.  Look at the L<Digest> module for more robust algorithms.
1209
1210 If using crypt() on a Unicode string (which I<potentially> has
1211 characters with codepoints above 255), Perl tries to make sense
1212 of the situation by trying to downgrade (a copy of)
1213 the string back to an eight-bit byte string before calling crypt()
1214 (on that copy).  If that works, good.  If not, crypt() dies with
1215 C<Wide character in crypt>.
1216
1217 Portability issues: L<perlport/crypt>.
1218
1219 =item dbmclose HASH
1220 X<dbmclose>
1221
1222 =for Pod::Functions breaks binding on a tied dbm file
1223
1224 [This function has been largely superseded by the C<untie> function.]
1225
1226 Breaks the binding between a DBM file and a hash.
1227
1228 Portability issues: L<perlport/dbmclose>.
1229
1230 =item dbmopen HASH,DBNAME,MASK
1231 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1232
1233 =for Pod::Functions create binding on a tied dbm file
1234
1235 [This function has been largely superseded by the
1236 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1237
1238 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1239 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1240 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1241 is the name of the database (without the F<.dir> or F<.pag> extension if
1242 any).  If the database does not exist, it is created with protection
1243 specified by MASK (as modified by the C<umask>).  To prevent creation of
1244 the database if it doesn't exist, you may specify a MODE
1245 of 0, and the function will return a false value if it
1246 can't find an existing database.  If your system supports
1247 only the older DBM functions, you may make only one C<dbmopen> call in your
1248 program.  In older versions of Perl, if your system had neither DBM nor
1249 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1250 sdbm(3).
1251
1252 If you don't have write access to the DBM file, you can only read hash
1253 variables, not set them.  If you want to test whether you can write,
1254 either use file tests or try setting a dummy hash entry inside an C<eval> 
1255 to trap the error.
1256
1257 Note that functions such as C<keys> and C<values> may return huge lists
1258 when used on large DBM files.  You may prefer to use the C<each>
1259 function to iterate over large DBM files.  Example:
1260
1261     # print out history file offsets
1262     dbmopen(%HIST,'/usr/lib/news/history',0666);
1263     while (($key,$val) = each %HIST) {
1264         print $key, ' = ', unpack('L',$val), "\n";
1265     }
1266     dbmclose(%HIST);
1267
1268 See also L<AnyDBM_File> for a more general description of the pros and
1269 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1270 rich implementation.
1271
1272 You can control which DBM library you use by loading that library
1273 before you call dbmopen():
1274
1275     use DB_File;
1276     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1277         or die "Can't open netscape history file: $!";
1278
1279 Portability issues: L<perlport/dbmopen>.
1280
1281 =item defined EXPR
1282 X<defined> X<undef> X<undefined>
1283
1284 =item defined
1285
1286 =for Pod::Functions test whether a value, variable, or function is defined
1287
1288 Returns a Boolean value telling whether EXPR has a value other than
1289 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1290 checked.
1291
1292 Many operations return C<undef> to indicate failure, end of file,
1293 system error, uninitialized variable, and other exceptional
1294 conditions.  This function allows you to distinguish C<undef> from
1295 other values.  (A simple Boolean test will not distinguish among
1296 C<undef>, zero, the empty string, and C<"0">, which are all equally
1297 false.)  Note that since C<undef> is a valid scalar, its presence
1298 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1299 returns C<undef> when its argument is an empty array, I<or> when the
1300 element to return happens to be C<undef>.
1301
1302 You may also use C<defined(&func)> to check whether subroutine C<&func>
1303 has ever been defined.  The return value is unaffected by any forward
1304 declarations of C<&func>.  A subroutine that is not defined
1305 may still be callable: its package may have an C<AUTOLOAD> method that
1306 makes it spring into existence the first time that it is called; see
1307 L<perlsub>.
1308
1309 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1310 used to report whether memory for that aggregate had ever been
1311 allocated.  This behavior may disappear in future versions of Perl.
1312 You should instead use a simple test for size:
1313
1314     if (@an_array) { print "has array elements\n" }
1315     if (%a_hash)   { print "has hash members\n"   }
1316
1317 When used on a hash element, it tells you whether the value is defined,
1318 not whether the key exists in the hash.  Use L</exists> for the latter
1319 purpose.
1320
1321 Examples:
1322
1323     print if defined $switch{D};
1324     print "$val\n" while defined($val = pop(@ary));
1325     die "Can't readlink $sym: $!"
1326         unless defined($value = readlink $sym);
1327     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1328     $debugging = 0 unless defined $debugging;
1329
1330 Note:  Many folks tend to overuse C<defined> and are then surprised to
1331 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1332 defined values.  For example, if you say
1333
1334     "ab" =~ /a(.*)b/;
1335
1336 The pattern match succeeds and C<$1> is defined, although it
1337 matched "nothing".  It didn't really fail to match anything.  Rather, it
1338 matched something that happened to be zero characters long.  This is all
1339 very above-board and honest.  When a function returns an undefined value,
1340 it's an admission that it couldn't give you an honest answer.  So you
1341 should use C<defined> only when questioning the integrity of what
1342 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1343 what you want.
1344
1345 See also L</undef>, L</exists>, L</ref>.
1346
1347 =item delete EXPR
1348 X<delete>
1349
1350 =for Pod::Functions deletes a value from a hash
1351
1352 Given an expression that specifies an element or slice of a hash, C<delete>
1353 deletes the specified elements from that hash so that exists() on that element
1354 no longer returns true.  Setting a hash element to the undefined value does
1355 not remove its key, but deleting it does; see L</exists>.
1356
1357 In list context, returns the value or values deleted, or the last such
1358 element in scalar context.  The return list's length always matches that of
1359 the argument list: deleting non-existent elements returns the undefined value
1360 in their corresponding positions.
1361
1362 delete() may also be used on arrays and array slices, but its behavior is less
1363 straightforward.  Although exists() will return false for deleted entries,
1364 deleting array elements never changes indices of existing values; use shift()
1365 or splice() for that.  However, if all deleted elements fall at the end of an
1366 array, the array's size shrinks to the position of the highest element that
1367 still tests true for exists(), or to 0 if none do.
1368
1369 B<WARNING:> Calling delete on array values is deprecated and likely to
1370 be removed in a future version of Perl.
1371
1372 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1373 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1374 or array may not necessarily return anything; it depends on the implementation
1375 of the C<tied> package's DELETE method, which may do whatever it pleases.
1376
1377 The C<delete local EXPR> construct localizes the deletion to the current
1378 block at run time.  Until the block exits, elements locally deleted
1379 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1380 of composite types">.
1381
1382     %hash = (foo => 11, bar => 22, baz => 33);
1383     $scalar = delete $hash{foo};         # $scalar is 11
1384     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1385     @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1386
1387 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1388
1389     foreach $key (keys %HASH) {
1390         delete $HASH{$key};
1391     }
1392
1393     foreach $index (0 .. $#ARRAY) {
1394         delete $ARRAY[$index];
1395     }
1396
1397 And so do these:
1398
1399     delete @HASH{keys %HASH};
1400
1401     delete @ARRAY[0 .. $#ARRAY];
1402
1403 But both are slower than assigning the empty list
1404 or undefining %HASH or @ARRAY, which is the customary 
1405 way to empty out an aggregate:
1406
1407     %HASH = ();     # completely empty %HASH
1408     undef %HASH;    # forget %HASH ever existed
1409
1410     @ARRAY = ();    # completely empty @ARRAY
1411     undef @ARRAY;   # forget @ARRAY ever existed
1412
1413 The EXPR can be arbitrarily complicated provided its
1414 final operation is an element or slice of an aggregate:
1415
1416     delete $ref->[$x][$y]{$key};
1417     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1418
1419     delete $ref->[$x][$y][$index];
1420     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1421
1422 =item die LIST
1423 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1424
1425 =for Pod::Functions raise an exception or bail out
1426
1427 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1428 into C<$@> and the C<eval> is terminated with the undefined value.
1429 If the exception is outside of all enclosing C<eval>s, then the uncaught
1430 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1431 need to exit the process with a specific exit code, see L</exit>.
1432
1433 Equivalent examples:
1434
1435     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1436     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1437
1438 If the last element of LIST does not end in a newline, the current
1439 script line number and input line number (if any) are also printed,
1440 and a newline is supplied.  Note that the "input line number" (also
1441 known as "chunk") is subject to whatever notion of "line" happens to
1442 be currently in effect, and is also available as the special variable
1443 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1444
1445 Hint: sometimes appending C<", stopped"> to your message will cause it
1446 to make better sense when the string C<"at foo line 123"> is appended.
1447 Suppose you are running script "canasta".
1448
1449     die "/etc/games is no good";
1450     die "/etc/games is no good, stopped";
1451
1452 produce, respectively
1453
1454     /etc/games is no good at canasta line 123.
1455     /etc/games is no good, stopped at canasta line 123.
1456
1457 If the output is empty and C<$@> already contains a value (typically from a
1458 previous eval) that value is reused after appending C<"\t...propagated">.
1459 This is useful for propagating exceptions:
1460
1461     eval { ... };
1462     die unless $@ =~ /Expected exception/;
1463
1464 If the output is empty and C<$@> contains an object reference that has a
1465 C<PROPAGATE> method, that method will be called with additional file
1466 and line number parameters.  The return value replaces the value in
1467 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1468 were called.
1469
1470 If C<$@> is empty then the string C<"Died"> is used.
1471
1472 If an uncaught exception results in interpreter exit, the exit code is
1473 determined from the values of C<$!> and C<$?> with this pseudocode:
1474
1475     exit $! if $!;              # errno
1476     exit $? >> 8 if $? >> 8;    # child exit status
1477     exit 255;                   # last resort
1478
1479 The intent is to squeeze as much possible information about the likely cause
1480 into the limited space of the system exit
1481 code.  However, as C<$!> is the value
1482 of C's C<errno>, which can be set by any system call, this means that the value
1483 of the exit code used by C<die> can be non-predictable, so should not be relied
1484 upon, other than to be non-zero.
1485
1486 You can also call C<die> with a reference argument, and if this is trapped
1487 within an C<eval>, C<$@> contains that reference.  This permits more
1488 elaborate exception handling using objects that maintain arbitrary state
1489 about the exception.  Such a scheme is sometimes preferable to matching
1490 particular string values of C<$@> with regular expressions.  Because C<$@> 
1491 is a global variable and C<eval> may be used within object implementations,
1492 be careful that analyzing the error object doesn't replace the reference in
1493 the global variable.  It's easiest to make a local copy of the reference
1494 before any manipulations.  Here's an example:
1495
1496     use Scalar::Util "blessed";
1497
1498     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1499     if (my $ev_err = $@) {
1500         if (blessed($ev_err)
1501             && $ev_err->isa("Some::Module::Exception")) {
1502             # handle Some::Module::Exception
1503         }
1504         else {
1505             # handle all other possible exceptions
1506         }
1507     }
1508
1509 Because Perl stringifies uncaught exception messages before display,
1510 you'll probably want to overload stringification operations on
1511 exception objects.  See L<overload> for details about that.
1512
1513 You can arrange for a callback to be run just before the C<die>
1514 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1515 handler is called with the error text and can change the error
1516 message, if it sees fit, by calling C<die> again.  See
1517 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1518 L<"eval BLOCK"> for some examples.  Although this feature was 
1519 to be run only right before your program was to exit, this is not
1520 currently so: the C<$SIG{__DIE__}> hook is currently called
1521 even inside eval()ed blocks/strings!  If one wants the hook to do
1522 nothing in such situations, put
1523
1524     die @_ if $^S;
1525
1526 as the first line of the handler (see L<perlvar/$^S>).  Because
1527 this promotes strange action at a distance, this counterintuitive
1528 behavior may be fixed in a future release.
1529
1530 See also exit(), warn(), and the Carp module.
1531
1532 =item do BLOCK
1533 X<do> X<block>
1534
1535 =for Pod::Functions turn a BLOCK into a TERM
1536
1537 Not really a function.  Returns the value of the last command in the
1538 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1539 C<until> loop modifier, executes the BLOCK once before testing the loop
1540 condition.  (On other statements the loop modifiers test the conditional
1541 first.)
1542
1543 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1544 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1545 See L<perlsyn> for alternative strategies.
1546
1547 =item do SUBROUTINE(LIST)
1548 X<do>
1549
1550 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword
1551 or scalar variable.
1552
1553 =item do EXPR
1554 X<do>
1555
1556 Uses the value of EXPR as a filename and executes the contents of the
1557 file as a Perl script.
1558
1559     do 'stat.pl';
1560
1561 is largely like
1562
1563     eval `cat stat.pl`;
1564
1565 except that it's more concise, runs no external processes, keeps track of
1566 the current
1567 filename for error messages, searches the C<@INC> directories, and updates
1568 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1569 these variables.  It also differs in that code evaluated with C<do FILENAME>
1570 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1571 same, however, in that it does reparse the file every time you call it,
1572 so you probably don't want to do this inside a loop.
1573
1574 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1575 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1576 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1577 could fail in a way that also sets C<$!>.  If the file is successfully
1578 compiled, C<do> returns the value of the last expression evaluated.
1579
1580 Inclusion of library modules is better done with the
1581 C<use> and C<require> operators, which also do automatic error checking
1582 and raise an exception if there's a problem.
1583
1584 You might like to use C<do> to read in a program configuration
1585 file.  Manual error checking can be done this way:
1586
1587     # read in config files: system first, then user
1588     for $file ("/share/prog/defaults.rc",
1589                "$ENV{HOME}/.someprogrc")
1590     {
1591         unless ($return = do $file) {
1592             warn "couldn't parse $file: $@" if $@;
1593             warn "couldn't do $file: $!"    unless defined $return;
1594             warn "couldn't run $file"       unless $return;
1595         }
1596     }
1597
1598 =item dump LABEL
1599 X<dump> X<core> X<undump>
1600
1601 =item dump EXPR
1602
1603 =item dump
1604
1605 =for Pod::Functions create an immediate core dump
1606
1607 This function causes an immediate core dump.  See also the B<-u>
1608 command-line switch in L<perlrun>, which does the same thing.
1609 Primarily this is so that you can use the B<undump> program (not
1610 supplied) to turn your core dump into an executable binary after
1611 having initialized all your variables at the beginning of the
1612 program.  When the new binary is executed it will begin by executing
1613 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1614 Think of it as a goto with an intervening core dump and reincarnation.
1615 If C<LABEL> is omitted, restarts the program from the top.  The
1616 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1617 computed at run time, being otherwise identical to C<dump LABEL>.
1618
1619 B<WARNING>: Any files opened at the time of the dump will I<not>
1620 be open any more when the program is reincarnated, with possible
1621 resulting confusion by Perl.
1622
1623 This function is now largely obsolete, mostly because it's very hard to
1624 convert a core file into an executable.  That's why you should now invoke
1625 it as C<CORE::dump()>, if you don't want to be warned against a possible
1626 typo.
1627
1628 Unlike most named operators, this has the same precedence as assignment.
1629 It is also exempt from the looks-like-a-function rule, so
1630 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1631 C<dump>.
1632
1633 Portability issues: L<perlport/dump>.
1634
1635 =item each HASH
1636 X<each> X<hash, iterator>
1637
1638 =item each ARRAY
1639 X<array, iterator>
1640
1641 =item each EXPR
1642
1643 =for Pod::Functions retrieve the next key/value pair from a hash
1644
1645 When called on a hash in list context, returns a 2-element list
1646 consisting of the key and value for the next element of a hash.  In Perl
1647 5.12 and later only, it will also return the index and value for the next
1648 element of an array so that you can iterate over it; older Perls consider
1649 this a syntax error.  When called in scalar context, returns only the key
1650 (not the value) in a hash, or the index in an array.
1651
1652 Hash entries are returned in an apparently random order.  The actual random
1653 order is subject to change in future versions of Perl, but it is
1654 guaranteed to be in the same order as either the C<keys> or C<values>
1655 function would produce on the same (unmodified) hash.  Since Perl
1656 5.8.2 the ordering can be different even between different runs of Perl
1657 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1658
1659 After C<each> has returned all entries from the hash or array, the next
1660 call to C<each> returns the empty list in list context and C<undef> in
1661 scalar context; the next call following I<that> one restarts iteration.
1662 Each hash or array has its own internal iterator, accessed by C<each>,
1663 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1664 reached the end as just described; it can be explicitly reset by calling
1665 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1666 elements while iterating over it, entries may be skipped or duplicated--so
1667 don't do that.  Exception: In the current implementation, it is always safe
1668 to delete the item most recently returned by C<each()>, so the following
1669 code works properly:
1670
1671         while (($key, $value) = each %hash) {
1672           print $key, "\n";
1673           delete $hash{$key};   # This is safe
1674         }
1675
1676 This prints out your environment like the printenv(1) program,
1677 but in a different order:
1678
1679     while (($key,$value) = each %ENV) {
1680         print "$key=$value\n";
1681     }
1682
1683 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1684 reference to an unblessed hash or array.  The argument will be dereferenced
1685 automatically.  This aspect of C<each> is considered highly experimental.
1686 The exact behaviour may change in a future version of Perl.
1687
1688     while (($key,$value) = each $hashref) { ... }
1689
1690 As of Perl 5.18 you can use a bare C<each> in a C<while> loop,
1691 which will set C<$_> on every iteration.
1692
1693     while(each %ENV) {
1694         print "$_=$ENV{$_}\n";
1695     }
1696
1697 To avoid confusing would-be users of your code who are running earlier
1698 versions of Perl with mysterious syntax errors, put this sort of thing at
1699 the top of your file to signal that your code will work I<only> on Perls of
1700 a recent vintage:
1701
1702     use 5.012;  # so keys/values/each work on arrays
1703     use 5.014;  # so keys/values/each work on scalars (experimental)
1704     use 5.018;  # so each assigns to $_ in a lone while test
1705
1706 See also C<keys>, C<values>, and C<sort>.
1707
1708 =item eof FILEHANDLE
1709 X<eof>
1710 X<end of file>
1711 X<end-of-file>
1712
1713 =item eof ()
1714
1715 =item eof
1716
1717 =for Pod::Functions test a filehandle for its end
1718
1719 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1720 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1721 gives the real filehandle.  (Note that this function actually
1722 reads a character and then C<ungetc>s it, so isn't useful in an
1723 interactive context.)  Do not read from a terminal file (or call
1724 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1725 as terminals may lose the end-of-file condition if you do.
1726
1727 An C<eof> without an argument uses the last file read.  Using C<eof()>
1728 with empty parentheses is different.  It refers to the pseudo file
1729 formed from the files listed on the command line and accessed via the
1730 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1731 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1732 used will cause C<@ARGV> to be examined to determine if input is
1733 available.   Similarly, an C<eof()> after C<< <> >> has returned
1734 end-of-file will assume you are processing another C<@ARGV> list,
1735 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1736 see L<perlop/"I/O Operators">.
1737
1738 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1739 detect the end of each file, whereas C<eof()> will detect the end 
1740 of the very last file only.  Examples:
1741
1742     # reset line numbering on each input file
1743     while (<>) {
1744         next if /^\s*#/;  # skip comments
1745         print "$.\t$_";
1746     } continue {
1747         close ARGV if eof;  # Not eof()!
1748     }
1749
1750     # insert dashes just before last line of last file
1751     while (<>) {
1752         if (eof()) {  # check for end of last file
1753             print "--------------\n";
1754         }
1755         print;
1756         last if eof();     # needed if we're reading from a terminal
1757     }
1758
1759 Practical hint: you almost never need to use C<eof> in Perl, because the
1760 input operators typically return C<undef> when they run out of data or 
1761 encounter an error.
1762
1763 =item eval EXPR
1764 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1765 X<error, handling> X<exception, handling>
1766
1767 =item eval BLOCK
1768
1769 =item eval
1770
1771 =for Pod::Functions catch exceptions or compile and run code
1772
1773 In the first form, the return value of EXPR is parsed and executed as if it
1774 were a little Perl program.  The value of the expression (which is itself
1775 determined within scalar context) is first parsed, and if there were no
1776 errors, executed as a block within the lexical context of the current Perl
1777 program.  This means, that in particular, any outer lexical variables are
1778 visible to it, and any package variable settings or subroutine and format
1779 definitions remain afterwards.
1780
1781 Note that the value is parsed every time the C<eval> executes.
1782 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1783 delay parsing and subsequent execution of the text of EXPR until run time.
1784
1785 If the C<unicode_eval> feature is enabled (which is the default under a
1786 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1787 characters, so C<use utf8> declarations have no effect, and source filters
1788 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1789 will sometimes be treated as characters and sometimes as bytes, depending
1790 on the internal encoding, and source filters activated within the C<eval>
1791 exhibit the erratic, but historical, behaviour of affecting some outer file
1792 scope that is still compiling.  See also the L</evalbytes> keyword, which
1793 always treats its input as a byte stream and works properly with source
1794 filters, and the L<feature> pragma.
1795
1796 In the second form, the code within the BLOCK is parsed only once--at the
1797 same time the code surrounding the C<eval> itself was parsed--and executed
1798 within the context of the current Perl program.  This form is typically
1799 used to trap exceptions more efficiently than the first (see below), while
1800 also providing the benefit of checking the code within BLOCK at compile
1801 time.
1802
1803 The final semicolon, if any, may be omitted from the value of EXPR or within
1804 the BLOCK.
1805
1806 In both forms, the value returned is the value of the last expression
1807 evaluated inside the mini-program; a return statement may be also used, just
1808 as with subroutines.  The expression providing the return value is evaluated
1809 in void, scalar, or list context, depending on the context of the C<eval> 
1810 itself.  See L</wantarray> for more on how the evaluation context can be 
1811 determined.
1812
1813 If there is a syntax error or runtime error, or a C<die> statement is
1814 executed, C<eval> returns C<undef> in scalar context
1815 or an empty list in list context, and C<$@> is set to the error
1816 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1817 in list context for syntax errors, but not for runtime errors.)
1818 If there was no error, C<$@> is set to the empty string.  A
1819 control flow operator like C<last> or C<goto> can bypass the setting of
1820 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1821 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1822 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1823 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1824 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1825
1826 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1827 determining whether a particular feature (such as C<socket> or C<symlink>)
1828 is implemented.  It is also Perl's exception-trapping mechanism, where
1829 the die operator is used to raise exceptions.
1830
1831 If you want to trap errors when loading an XS module, some problems with
1832 the binary interface (such as Perl version skew) may be fatal even with
1833 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1834
1835 If the code to be executed doesn't vary, you may use the eval-BLOCK
1836 form to trap run-time errors without incurring the penalty of
1837 recompiling each time.  The error, if any, is still returned in C<$@>.
1838 Examples:
1839
1840     # make divide-by-zero nonfatal
1841     eval { $answer = $a / $b; }; warn $@ if $@;
1842
1843     # same thing, but less efficient
1844     eval '$answer = $a / $b'; warn $@ if $@;
1845
1846     # a compile-time error
1847     eval { $answer = }; # WRONG
1848
1849     # a run-time error
1850     eval '$answer =';   # sets $@
1851
1852 Using the C<eval{}> form as an exception trap in libraries does have some
1853 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1854 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1855 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1856 as this example shows:
1857
1858     # a private exception trap for divide-by-zero
1859     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1860     warn $@ if $@;
1861
1862 This is especially significant, given that C<__DIE__> hooks can call
1863 C<die> again, which has the effect of changing their error messages:
1864
1865     # __DIE__ hooks may modify error messages
1866     {
1867        local $SIG{'__DIE__'} =
1868               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1869        eval { die "foo lives here" };
1870        print $@ if $@;                # prints "bar lives here"
1871     }
1872
1873 Because this promotes action at a distance, this counterintuitive behavior
1874 may be fixed in a future release.
1875
1876 With an C<eval>, you should be especially careful to remember what's
1877 being looked at when:
1878
1879     eval $x;        # CASE 1
1880     eval "$x";      # CASE 2
1881
1882     eval '$x';      # CASE 3
1883     eval { $x };    # CASE 4
1884
1885     eval "\$$x++";  # CASE 5
1886     $$x++;          # CASE 6
1887
1888 Cases 1 and 2 above behave identically: they run the code contained in
1889 the variable $x.  (Although case 2 has misleading double quotes making
1890 the reader wonder what else might be happening (nothing is).)  Cases 3
1891 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1892 does nothing but return the value of $x.  (Case 4 is preferred for
1893 purely visual reasons, but it also has the advantage of compiling at
1894 compile-time instead of at run-time.)  Case 5 is a place where
1895 normally you I<would> like to use double quotes, except that in this
1896 particular situation, you can just use symbolic references instead, as
1897 in case 6.
1898
1899 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1900 of localized variables, which means that for your code to run on older
1901 versions, a temporary is required if you want to mask some but not all
1902 errors:
1903
1904     # alter $@ on nefarious repugnancy only
1905     {
1906        my $e;
1907        {
1908          local $@; # protect existing $@
1909          eval { test_repugnancy() };
1910          # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1911          $@ =~ /nefarious/ and $e = $@;
1912        }
1913        die $e if defined $e
1914     }
1915
1916 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1917 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1918
1919 An C<eval ''> executed within a subroutine defined
1920 in the C<DB> package doesn't see the usual
1921 surrounding lexical scope, but rather the scope of the first non-DB piece
1922 of code that called it.  You don't normally need to worry about this unless
1923 you are writing a Perl debugger.
1924
1925 =item evalbytes EXPR
1926 X<evalbytes>
1927
1928 =item evalbytes
1929
1930 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
1931
1932 This function is like L</eval> with a string argument, except it always
1933 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1934 string containing characters whose ordinal value exceeds 255 results in an
1935 error.  Source filters activated within the evaluated code apply to the
1936 code itself.
1937
1938 This function is only available under the C<evalbytes> feature, a
1939 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1940 L<feature> for more information.
1941
1942 =item exec LIST
1943 X<exec> X<execute>
1944
1945 =item exec PROGRAM LIST
1946
1947 =for Pod::Functions abandon this program to run another
1948
1949 The C<exec> function executes a system command I<and never returns>;
1950 use C<system> instead of C<exec> if you want it to return.  It fails and
1951 returns false only if the command does not exist I<and> it is executed
1952 directly instead of via your system's command shell (see below).
1953
1954 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1955 warns you if C<exec> is called in void context and if there is a following
1956 statement that isn't C<die>, C<warn>, or C<exit> (if C<-w> is set--but
1957 you always do that, right?).  If you I<really> want to follow an C<exec>
1958 with some other statement, you can use one of these styles to avoid the warning:
1959
1960     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1961     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1962
1963 If there is more than one argument in LIST, or if LIST is an array
1964 with more than one value, calls execvp(3) with the arguments in LIST.
1965 If there is only one scalar argument or an array with one element in it,
1966 the argument is checked for shell metacharacters, and if there are any,
1967 the entire argument is passed to the system's command shell for parsing
1968 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1969 If there are no shell metacharacters in the argument, it is split into
1970 words and passed directly to C<execvp>, which is more efficient.
1971 Examples:
1972
1973     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1974     exec "sort $outfile | uniq";
1975
1976 If you don't really want to execute the first argument, but want to lie
1977 to the program you are executing about its own name, you can specify
1978 the program you actually want to run as an "indirect object" (without a
1979 comma) in front of the LIST.  (This always forces interpretation of the
1980 LIST as a multivalued list, even if there is only a single scalar in
1981 the list.)  Example:
1982
1983     $shell = '/bin/csh';
1984     exec $shell '-sh';    # pretend it's a login shell
1985
1986 or, more directly,
1987
1988     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1989
1990 When the arguments get executed via the system shell, results are
1991 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1992 for details.
1993
1994 Using an indirect object with C<exec> or C<system> is also more
1995 secure.  This usage (which also works fine with system()) forces
1996 interpretation of the arguments as a multivalued list, even if the
1997 list had just one argument.  That way you're safe from the shell
1998 expanding wildcards or splitting up words with whitespace in them.
1999
2000     @args = ( "echo surprise" );
2001
2002     exec @args;               # subject to shell escapes
2003                                 # if @args == 1
2004     exec { $args[0] } @args;  # safe even with one-arg list
2005
2006 The first version, the one without the indirect object, ran the I<echo>
2007 program, passing it C<"surprise"> an argument.  The second version didn't;
2008 it tried to run a program named I<"echo surprise">, didn't find it, and set
2009 C<$?> to a non-zero value indicating failure.
2010
2011 Perl attempts to flush all files opened for output before the exec,
2012 but this may not be supported on some platforms (see L<perlport>).
2013 To be safe, you may need to set C<$|> ($AUTOFLUSH in English) or
2014 call the C<autoflush()> method of C<IO::Handle> on any open handles
2015 to avoid lost output.
2016
2017 Note that C<exec> will not call your C<END> blocks, nor will it invoke
2018 C<DESTROY> methods on your objects.
2019
2020 Portability issues: L<perlport/exec>.
2021
2022 =item exists EXPR
2023 X<exists> X<autovivification>
2024
2025 =for Pod::Functions test whether a hash key is present
2026
2027 Given an expression that specifies an element of a hash, returns true if the
2028 specified element in the hash has ever been initialized, even if the
2029 corresponding value is undefined.
2030
2031     print "Exists\n"    if exists $hash{$key};
2032     print "Defined\n"   if defined $hash{$key};
2033     print "True\n"      if $hash{$key};
2034
2035 exists may also be called on array elements, but its behavior is much less
2036 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
2037 that calling exists on array values is deprecated and likely to be removed in
2038 a future version of Perl.
2039
2040     print "Exists\n"    if exists $array[$index];
2041     print "Defined\n"   if defined $array[$index];
2042     print "True\n"      if $array[$index];
2043
2044 A hash or array element can be true only if it's defined and defined only if
2045 it exists, but the reverse doesn't necessarily hold true.
2046
2047 Given an expression that specifies the name of a subroutine,
2048 returns true if the specified subroutine has ever been declared, even
2049 if it is undefined.  Mentioning a subroutine name for exists or defined
2050 does not count as declaring it.  Note that a subroutine that does not
2051 exist may still be callable: its package may have an C<AUTOLOAD>
2052 method that makes it spring into existence the first time that it is
2053 called; see L<perlsub>.
2054
2055     print "Exists\n"  if exists &subroutine;
2056     print "Defined\n" if defined &subroutine;
2057
2058 Note that the EXPR can be arbitrarily complicated as long as the final
2059 operation is a hash or array key lookup or subroutine name:
2060
2061     if (exists $ref->{A}->{B}->{$key})  { }
2062     if (exists $hash{A}{B}{$key})       { }
2063
2064     if (exists $ref->{A}->{B}->[$ix])   { }
2065     if (exists $hash{A}{B}[$ix])        { }
2066
2067     if (exists &{$ref->{A}{B}{$key}})   { }
2068
2069 Although the most deeply nested array or hash element will not spring into
2070 existence just because its existence was tested, any intervening ones will.
2071 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2072 into existence due to the existence test for the $key element above.
2073 This happens anywhere the arrow operator is used, including even here:
2074
2075     undef $ref;
2076     if (exists $ref->{"Some key"})    { }
2077     print $ref;  # prints HASH(0x80d3d5c)
2078
2079 This surprising autovivification in what does not at first--or even
2080 second--glance appear to be an lvalue context may be fixed in a future
2081 release.
2082
2083 Use of a subroutine call, rather than a subroutine name, as an argument
2084 to exists() is an error.
2085
2086     exists &sub;    # OK
2087     exists &sub();  # Error
2088
2089 =item exit EXPR
2090 X<exit> X<terminate> X<abort>
2091
2092 =item exit
2093
2094 =for Pod::Functions terminate this program
2095
2096 Evaluates EXPR and exits immediately with that value.    Example:
2097
2098     $ans = <STDIN>;
2099     exit 0 if $ans =~ /^[Xx]/;
2100
2101 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
2102 universally recognized values for EXPR are C<0> for success and C<1>
2103 for error; other values are subject to interpretation depending on the
2104 environment in which the Perl program is running.  For example, exiting
2105 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2106 the mailer to return the item undelivered, but that's not true everywhere.
2107
2108 Don't use C<exit> to abort a subroutine if there's any chance that
2109 someone might want to trap whatever error happened.  Use C<die> instead,
2110 which can be trapped by an C<eval>.
2111
2112 The exit() function does not always exit immediately.  It calls any
2113 defined C<END> routines first, but these C<END> routines may not
2114 themselves abort the exit.  Likewise any object destructors that need to
2115 be called are called before the real exit.  C<END> routines and destructors
2116 can change the exit status by modifying C<$?>.  If this is a problem, you
2117 can call C<POSIX::_exit($status)> to avoid END and destructor processing.
2118 See L<perlmod> for details.
2119
2120 Portability issues: L<perlport/exit>.
2121
2122 =item exp EXPR
2123 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2124
2125 =item exp
2126
2127 =for Pod::Functions raise I<e> to a power
2128
2129 Returns I<e> (the natural logarithm base) to the power of EXPR.
2130 If EXPR is omitted, gives C<exp($_)>.
2131
2132 =item fc EXPR
2133 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2134
2135 =item fc
2136
2137 =for Pod::Functions +fc return casefolded version of a string
2138
2139 Returns the casefolded version of EXPR.  This is the internal function
2140 implementing the C<\F> escape in double-quoted strings.
2141
2142 Casefolding is the process of mapping strings to a form where case
2143 differences are erased; comparing two strings in their casefolded
2144 form is effectively a way of asking if two strings are equal,
2145 regardless of case.
2146
2147 Roughly, if you ever found yourself writing this
2148
2149     lc($this) eq lc($that)    # Wrong!
2150         # or
2151     uc($this) eq uc($that)    # Also wrong!
2152         # or
2153     $this =~ /^\Q$that\E\z/i  # Right!
2154
2155 Now you can write
2156
2157     fc($this) eq fc($that)
2158
2159 And get the correct results.
2160
2161 Perl only implements the full form of casefolding,
2162 but you can access the simple folds using L<Unicode::UCD/casefold()> and
2163 L<Unicode::UCD/prop_invmap()>.
2164 For further information on casefolding, refer to
2165 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2166 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2167 available at L<http://www.unicode.org/versions/latest/>, as well as the
2168 Case Charts available at L<http://www.unicode.org/charts/case/>.
2169
2170 If EXPR is omitted, uses C<$_>.
2171
2172 This function behaves the same way under various pragma, such as in a locale,
2173 as L</lc> does.
2174
2175 While the Unicode Standard defines two additional forms of casefolding,
2176 one for Turkic languages and one that never maps one character into multiple
2177 characters, these are not provided by the Perl core; However, the CPAN module
2178 C<Unicode::Casing> may be used to provide an implementation.
2179
2180 This keyword is available only when the C<"fc"> feature is enabled,
2181 or when prefixed with C<CORE::>; See L<feature>. Alternately,
2182 include a C<use v5.16> or later to the current scope.
2183
2184 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2185 X<fcntl>
2186
2187 =for Pod::Functions file control system call
2188
2189 Implements the fcntl(2) function.  You'll probably have to say
2190
2191     use Fcntl;
2192
2193 first to get the correct constant definitions.  Argument processing and
2194 value returned work just like C<ioctl> below.
2195 For example:
2196
2197     use Fcntl;
2198     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2199         or die "can't fcntl F_GETFL: $!";
2200
2201 You don't have to check for C<defined> on the return from C<fcntl>.
2202 Like C<ioctl>, it maps a C<0> return from the system call into
2203 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2204 in numeric context.  It is also exempt from the normal B<-w> warnings
2205 on improper numeric conversions.
2206
2207 Note that C<fcntl> raises an exception if used on a machine that
2208 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2209 manpage to learn what functions are available on your system.
2210
2211 Here's an example of setting a filehandle named C<REMOTE> to be
2212 non-blocking at the system level.  You'll have to negotiate C<$|>
2213 on your own, though.
2214
2215     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2216
2217     $flags = fcntl(REMOTE, F_GETFL, 0)
2218                 or die "Can't get flags for the socket: $!\n";
2219
2220     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2221                 or die "Can't set flags for the socket: $!\n";
2222
2223 Portability issues: L<perlport/fcntl>.
2224
2225 =item __FILE__
2226 X<__FILE__>
2227
2228 =for Pod::Functions the name of the current source file
2229
2230 A special token that returns the name of the file in which it occurs.
2231
2232 =item fileno FILEHANDLE
2233 X<fileno>
2234
2235 =for Pod::Functions return file descriptor from filehandle
2236
2237 Returns the file descriptor for a filehandle, or undefined if the
2238 filehandle is not open.  If there is no real file descriptor at the OS
2239 level, as can happen with filehandles connected to memory objects via
2240 C<open> with a reference for the third argument, -1 is returned.
2241
2242 This is mainly useful for constructing
2243 bitmaps for C<select> and low-level POSIX tty-handling operations.
2244 If FILEHANDLE is an expression, the value is taken as an indirect
2245 filehandle, generally its name.
2246
2247 You can use this to find out whether two handles refer to the
2248 same underlying descriptor:
2249
2250     if (fileno(THIS) == fileno(THAT)) {
2251         print "THIS and THAT are dups\n";
2252     }
2253
2254 =item flock FILEHANDLE,OPERATION
2255 X<flock> X<lock> X<locking>
2256
2257 =for Pod::Functions lock an entire file with an advisory lock
2258
2259 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2260 for success, false on failure.  Produces a fatal error if used on a
2261 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2262 C<flock> is Perl's portable file-locking interface, although it locks
2263 entire files only, not records.
2264
2265 Two potentially non-obvious but traditional C<flock> semantics are
2266 that it waits indefinitely until the lock is granted, and that its locks
2267 are B<merely advisory>.  Such discretionary locks are more flexible, but
2268 offer fewer guarantees.  This means that programs that do not also use
2269 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2270 your port's specific documentation, and your system-specific local manpages
2271 for details.  It's best to assume traditional behavior if you're writing
2272 portable programs.  (But if you're not, you should as always feel perfectly
2273 free to write for your own system's idiosyncrasies (sometimes called
2274 "features").  Slavish adherence to portability concerns shouldn't get
2275 in the way of your getting your job done.)
2276
2277 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2278 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2279 you can use the symbolic names if you import them from the L<Fcntl> module,
2280 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2281 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2282 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2283 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2284 waiting for the lock; check the return status to see if you got it.
2285
2286 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2287 before locking or unlocking it.
2288
2289 Note that the emulation built with lockf(3) doesn't provide shared
2290 locks, and it requires that FILEHANDLE be open with write intent.  These
2291 are the semantics that lockf(3) implements.  Most if not all systems
2292 implement lockf(3) in terms of fcntl(2) locking, though, so the
2293 differing semantics shouldn't bite too many people.
2294
2295 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2296 be open with read intent to use LOCK_SH and requires that it be open
2297 with write intent to use LOCK_EX.
2298
2299 Note also that some versions of C<flock> cannot lock things over the
2300 network; you would need to use the more system-specific C<fcntl> for
2301 that.  If you like you can force Perl to ignore your system's flock(2)
2302 function, and so provide its own fcntl(2)-based emulation, by passing
2303 the switch C<-Ud_flock> to the F<Configure> program when you configure
2304 and build a new Perl.
2305
2306 Here's a mailbox appender for BSD systems.
2307
2308     # import LOCK_* and SEEK_END constants
2309     use Fcntl qw(:flock SEEK_END);
2310
2311     sub lock {
2312         my ($fh) = @_;
2313         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2314
2315         # and, in case someone appended while we were waiting...
2316         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2317     }
2318
2319     sub unlock {
2320         my ($fh) = @_;
2321         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2322     }
2323
2324     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2325         or die "Can't open mailbox: $!";
2326
2327     lock($mbox);
2328     print $mbox $msg,"\n\n";
2329     unlock($mbox);
2330
2331 On systems that support a real flock(2), locks are inherited across fork()
2332 calls, whereas those that must resort to the more capricious fcntl(2)
2333 function lose their locks, making it seriously harder to write servers.
2334
2335 See also L<DB_File> for other flock() examples.
2336
2337 Portability issues: L<perlport/flock>.
2338
2339 =item fork
2340 X<fork> X<child> X<parent>
2341
2342 =for Pod::Functions create a new process just like this one
2343
2344 Does a fork(2) system call to create a new process running the
2345 same program at the same point.  It returns the child pid to the
2346 parent process, C<0> to the child process, or C<undef> if the fork is
2347 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2348 are shared, while everything else is copied.  On most systems supporting
2349 fork(), great care has gone into making it extremely efficient (for
2350 example, using copy-on-write technology on data pages), making it the
2351 dominant paradigm for multitasking over the last few decades.
2352
2353 Perl attempts to flush all files opened for
2354 output before forking the child process, but this may not be supported
2355 on some platforms (see L<perlport>).  To be safe, you may need to set
2356 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2357 C<IO::Handle> on any open handles to avoid duplicate output.
2358
2359 If you C<fork> without ever waiting on your children, you will
2360 accumulate zombies.  On some systems, you can avoid this by setting
2361 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2362 forking and reaping moribund children.
2363
2364 Note that if your forked child inherits system file descriptors like
2365 STDIN and STDOUT that are actually connected by a pipe or socket, even
2366 if you exit, then the remote server (such as, say, a CGI script or a
2367 backgrounded job launched from a remote shell) won't think you're done.
2368 You should reopen those to F</dev/null> if it's any issue.
2369
2370 On some platforms such as Windows, where the fork() system call is not available,
2371 Perl can be built to emulate fork() in the Perl interpreter.
2372 The emulation is designed, at the level of the Perl program,
2373 to be as compatible as possible with the "Unix" fork().
2374 However it has limitations that have to be considered in code intended to be portable.
2375 See L<perlfork> for more details.
2376
2377 Portability issues: L<perlport/fork>.
2378
2379 =item format
2380 X<format>
2381
2382 =for Pod::Functions declare a picture format with use by the write() function
2383
2384 Declare a picture format for use by the C<write> function.  For
2385 example:
2386
2387     format Something =
2388         Test: @<<<<<<<< @||||| @>>>>>
2389               $str,     $%,    '$' . int($num)
2390     .
2391
2392     $str = "widget";
2393     $num = $cost/$quantity;
2394     $~ = 'Something';
2395     write;
2396
2397 See L<perlform> for many details and examples.
2398
2399 =item formline PICTURE,LIST
2400 X<formline>
2401
2402 =for Pod::Functions internal function used for formats
2403
2404 This is an internal function used by C<format>s, though you may call it,
2405 too.  It formats (see L<perlform>) a list of values according to the
2406 contents of PICTURE, placing the output into the format output
2407 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2408 Eventually, when a C<write> is done, the contents of
2409 C<$^A> are written to some filehandle.  You could also read C<$^A>
2410 and then set C<$^A> back to C<"">.  Note that a format typically
2411 does one C<formline> per line of form, but the C<formline> function itself
2412 doesn't care how many newlines are embedded in the PICTURE.  This means
2413 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2414 You may therefore need to use multiple formlines to implement a single
2415 record format, just like the C<format> compiler.
2416
2417 Be careful if you put double quotes around the picture, because an C<@>
2418 character may be taken to mean the beginning of an array name.
2419 C<formline> always returns true.  See L<perlform> for other examples.
2420
2421 If you are trying to use this instead of C<write> to capture the output,
2422 you may find it easier to open a filehandle to a scalar
2423 (C<< open $fh, ">", \$output >>) and write to that instead.
2424
2425 =item getc FILEHANDLE
2426 X<getc> X<getchar> X<character> X<file, read>
2427
2428 =item getc
2429
2430 =for Pod::Functions get the next character from the filehandle
2431
2432 Returns the next character from the input file attached to FILEHANDLE,
2433 or the undefined value at end of file or if there was an error (in
2434 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2435 STDIN.  This is not particularly efficient.  However, it cannot be
2436 used by itself to fetch single characters without waiting for the user
2437 to hit enter.  For that, try something more like:
2438
2439     if ($BSD_STYLE) {
2440         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2441     }
2442     else {
2443         system "stty", '-icanon', 'eol', "\001";
2444     }
2445
2446     $key = getc(STDIN);
2447
2448     if ($BSD_STYLE) {
2449         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2450     }
2451     else {
2452         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2453     }
2454     print "\n";
2455
2456 Determination of whether $BSD_STYLE should be set
2457 is left as an exercise to the reader.
2458
2459 The C<POSIX::getattr> function can do this more portably on
2460 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2461 module from your nearest CPAN site; details on CPAN can be found under
2462 L<perlmodlib/CPAN>.
2463
2464 =item getlogin
2465 X<getlogin> X<login>
2466
2467 =for Pod::Functions return who logged in at this tty
2468
2469 This implements the C library function of the same name, which on most
2470 systems returns the current login from F</etc/utmp>, if any.  If it
2471 returns the empty string, use C<getpwuid>.
2472
2473     $login = getlogin || getpwuid($<) || "Kilroy";
2474
2475 Do not consider C<getlogin> for authentication: it is not as
2476 secure as C<getpwuid>.
2477
2478 Portability issues: L<perlport/getlogin>.
2479
2480 =item getpeername SOCKET
2481 X<getpeername> X<peer>
2482
2483 =for Pod::Functions find the other end of a socket connection
2484
2485 Returns the packed sockaddr address of the other end of the SOCKET
2486 connection.
2487
2488     use Socket;
2489     $hersockaddr    = getpeername(SOCK);
2490     ($port, $iaddr) = sockaddr_in($hersockaddr);
2491     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2492     $herstraddr     = inet_ntoa($iaddr);
2493
2494 =item getpgrp PID
2495 X<getpgrp> X<group>
2496
2497 =for Pod::Functions get process group
2498
2499 Returns the current process group for the specified PID.  Use
2500 a PID of C<0> to get the current process group for the
2501 current process.  Will raise an exception if used on a machine that
2502 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2503 group of the current process.  Note that the POSIX version of C<getpgrp>
2504 does not accept a PID argument, so only C<PID==0> is truly portable.
2505
2506 Portability issues: L<perlport/getpgrp>.
2507
2508 =item getppid
2509 X<getppid> X<parent> X<pid>
2510
2511 =for Pod::Functions get parent process ID
2512
2513 Returns the process id of the parent process.
2514
2515 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2516 around non-POSIX thread semantics the minority of Linux systems (and
2517 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2518 has since been removed. See the documentation for L<$$|perlvar/$$> for
2519 details.
2520
2521 Portability issues: L<perlport/getppid>.
2522
2523 =item getpriority WHICH,WHO
2524 X<getpriority> X<priority> X<nice>
2525
2526 =for Pod::Functions get current nice value
2527
2528 Returns the current priority for a process, a process group, or a user.
2529 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2530 machine that doesn't implement getpriority(2).
2531
2532 Portability issues: L<perlport/getpriority>.
2533
2534 =item getpwnam NAME
2535 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2536 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2537 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2538 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2539 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2540 X<endnetent> X<endprotoent> X<endservent> 
2541
2542 =for Pod::Functions get passwd record given user login name
2543
2544 =item getgrnam NAME
2545
2546 =for Pod::Functions get group record given group name
2547
2548 =item gethostbyname NAME
2549
2550 =for Pod::Functions get host record given name
2551
2552 =item getnetbyname NAME
2553
2554 =for Pod::Functions get networks record given name
2555
2556 =item getprotobyname NAME
2557
2558 =for Pod::Functions get protocol record given name
2559
2560 =item getpwuid UID
2561
2562 =for Pod::Functions get passwd record given user ID
2563
2564 =item getgrgid GID
2565
2566 =for Pod::Functions get group record given group user ID
2567
2568 =item getservbyname NAME,PROTO
2569
2570 =for Pod::Functions get services record given its name
2571
2572 =item gethostbyaddr ADDR,ADDRTYPE
2573
2574 =for Pod::Functions get host record given its address
2575
2576 =item getnetbyaddr ADDR,ADDRTYPE
2577
2578 =for Pod::Functions get network record given its address
2579
2580 =item getprotobynumber NUMBER
2581
2582 =for Pod::Functions get protocol record numeric protocol
2583
2584 =item getservbyport PORT,PROTO
2585
2586 =for Pod::Functions get services record given numeric port
2587
2588 =item getpwent
2589
2590 =for Pod::Functions get next passwd record
2591
2592 =item getgrent
2593
2594 =for Pod::Functions get next group record
2595
2596 =item gethostent
2597
2598 =for Pod::Functions get next hosts record
2599
2600 =item getnetent
2601
2602 =for Pod::Functions get next networks record
2603
2604 =item getprotoent
2605
2606 =for Pod::Functions get next protocols record
2607
2608 =item getservent
2609
2610 =for Pod::Functions get next services record
2611
2612 =item setpwent
2613
2614 =for Pod::Functions prepare passwd file for use
2615
2616 =item setgrent
2617
2618 =for Pod::Functions prepare group file for use
2619
2620 =item sethostent STAYOPEN
2621
2622 =for Pod::Functions prepare hosts file for use
2623
2624 =item setnetent STAYOPEN
2625
2626 =for Pod::Functions prepare networks file for use
2627
2628 =item setprotoent STAYOPEN
2629
2630 =for Pod::Functions prepare protocols file for use
2631
2632 =item setservent STAYOPEN
2633
2634 =for Pod::Functions prepare services file for use
2635
2636 =item endpwent
2637
2638 =for Pod::Functions be done using passwd file
2639
2640 =item endgrent
2641
2642 =for Pod::Functions be done using group file
2643
2644 =item endhostent
2645
2646 =for Pod::Functions be done using hosts file
2647
2648 =item endnetent
2649
2650 =for Pod::Functions be done using networks file
2651
2652 =item endprotoent
2653
2654 =for Pod::Functions be done using protocols file
2655
2656 =item endservent
2657
2658 =for Pod::Functions be done using services file
2659
2660 These routines are the same as their counterparts in the
2661 system C library.  In list context, the return values from the
2662 various get routines are as follows:
2663
2664     ($name,$passwd,$uid,$gid,
2665        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2666     ($name,$passwd,$gid,$members) = getgr*
2667     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2668     ($name,$aliases,$addrtype,$net) = getnet*
2669     ($name,$aliases,$proto) = getproto*
2670     ($name,$aliases,$port,$proto) = getserv*
2671
2672 (If the entry doesn't exist you get an empty list.)
2673
2674 The exact meaning of the $gcos field varies but it usually contains
2675 the real name of the user (as opposed to the login name) and other
2676 information pertaining to the user.  Beware, however, that in many
2677 system users are able to change this information and therefore it
2678 cannot be trusted and therefore the $gcos is tainted (see
2679 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2680 login shell, are also tainted, for the same reason.
2681
2682 In scalar context, you get the name, unless the function was a
2683 lookup by name, in which case you get the other thing, whatever it is.
2684 (If the entry doesn't exist you get the undefined value.)  For example:
2685
2686     $uid   = getpwnam($name);
2687     $name  = getpwuid($num);
2688     $name  = getpwent();
2689     $gid   = getgrnam($name);
2690     $name  = getgrgid($num);
2691     $name  = getgrent();
2692     #etc.
2693
2694 In I<getpw*()> the fields $quota, $comment, and $expire are special
2695 in that they are unsupported on many systems.  If the
2696 $quota is unsupported, it is an empty scalar.  If it is supported, it
2697 usually encodes the disk quota.  If the $comment field is unsupported,
2698 it is an empty scalar.  If it is supported it usually encodes some
2699 administrative comment about the user.  In some systems the $quota
2700 field may be $change or $age, fields that have to do with password
2701 aging.  In some systems the $comment field may be $class.  The $expire
2702 field, if present, encodes the expiration period of the account or the
2703 password.  For the availability and the exact meaning of these fields
2704 in your system, please consult getpwnam(3) and your system's 
2705 F<pwd.h> file.  You can also find out from within Perl what your
2706 $quota and $comment fields mean and whether you have the $expire field
2707 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2708 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2709 files are supported only if your vendor has implemented them in the
2710 intuitive fashion that calling the regular C library routines gets the
2711 shadow versions if you're running under privilege or if there exists
2712 the shadow(3) functions as found in System V (this includes Solaris
2713 and Linux).  Those systems that implement a proprietary shadow password
2714 facility are unlikely to be supported.
2715
2716 The $members value returned by I<getgr*()> is a space-separated list of
2717 the login names of the members of the group.
2718
2719 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2720 C, it will be returned to you via C<$?> if the function call fails.  The
2721 C<@addrs> value returned by a successful call is a list of raw
2722 addresses returned by the corresponding library call.  In the
2723 Internet domain, each address is four bytes long; you can unpack it
2724 by saying something like:
2725
2726     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2727
2728 The Socket library makes this slightly easier:
2729
2730     use Socket;
2731     $iaddr = inet_aton("127.1"); # or whatever address
2732     $name  = gethostbyaddr($iaddr, AF_INET);
2733
2734     # or going the other way
2735     $straddr = inet_ntoa($iaddr);
2736
2737 In the opposite way, to resolve a hostname to the IP address
2738 you can write this:
2739
2740     use Socket;
2741     $packed_ip = gethostbyname("www.perl.org");
2742     if (defined $packed_ip) {
2743         $ip_address = inet_ntoa($packed_ip);
2744     }
2745
2746 Make sure C<gethostbyname()> is called in SCALAR context and that
2747 its return value is checked for definedness.
2748
2749 The C<getprotobynumber> function, even though it only takes one argument,
2750 has the precedence of a list operator, so beware:
2751
2752     getprotobynumber $number eq 'icmp'   # WRONG
2753     getprotobynumber($number eq 'icmp')  # actually means this
2754     getprotobynumber($number) eq 'icmp'  # better this way
2755
2756 If you get tired of remembering which element of the return list
2757 contains which return value, by-name interfaces are provided
2758 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2759 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2760 and C<User::grent>.  These override the normal built-ins, supplying
2761 versions that return objects with the appropriate names
2762 for each field.  For example:
2763
2764    use File::stat;
2765    use User::pwent;
2766    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2767
2768 Even though it looks as though they're the same method calls (uid),
2769 they aren't, because a C<File::stat> object is different from
2770 a C<User::pwent> object.
2771
2772 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2773
2774 =item getsockname SOCKET
2775 X<getsockname>
2776
2777 =for Pod::Functions retrieve the sockaddr for a given socket
2778
2779 Returns the packed sockaddr address of this end of the SOCKET connection,
2780 in case you don't know the address because you have several different
2781 IPs that the connection might have come in on.
2782
2783     use Socket;
2784     $mysockaddr = getsockname(SOCK);
2785     ($port, $myaddr) = sockaddr_in($mysockaddr);
2786     printf "Connect to %s [%s]\n",
2787        scalar gethostbyaddr($myaddr, AF_INET),
2788        inet_ntoa($myaddr);
2789
2790 =item getsockopt SOCKET,LEVEL,OPTNAME
2791 X<getsockopt>
2792
2793 =for Pod::Functions get socket options on a given socket
2794
2795 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2796 Options may exist at multiple protocol levels depending on the socket
2797 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2798 C<Socket> module) will exist.  To query options at another level the
2799 protocol number of the appropriate protocol controlling the option
2800 should be supplied.  For example, to indicate that an option is to be
2801 interpreted by the TCP protocol, LEVEL should be set to the protocol
2802 number of TCP, which you can get using C<getprotobyname>.
2803
2804 The function returns a packed string representing the requested socket
2805 option, or C<undef> on error, with the reason for the error placed in
2806 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2807 consult getsockopt(2) for details.  A common case is that the option is an
2808 integer, in which case the result is a packed integer, which you can decode
2809 using C<unpack> with the C<i> (or C<I>) format.
2810
2811 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2812
2813     use Socket qw(:all);
2814
2815     defined(my $tcp = getprotobyname("tcp"))
2816         or die "Could not determine the protocol number for tcp";
2817     # my $tcp = IPPROTO_TCP; # Alternative
2818     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2819         or die "getsockopt TCP_NODELAY: $!";
2820     my $nodelay = unpack("I", $packed);
2821     print "Nagle's algorithm is turned ",
2822            $nodelay ? "off\n" : "on\n";
2823
2824 Portability issues: L<perlport/getsockopt>.
2825
2826 =item glob EXPR
2827 X<glob> X<wildcard> X<filename, expansion> X<expand>
2828
2829 =item glob
2830
2831 =for Pod::Functions expand filenames using wildcards
2832
2833 In list context, returns a (possibly empty) list of filename expansions on
2834 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2835 scalar context, glob iterates through such filename expansions, returning
2836 undef when the list is exhausted.  This is the internal function
2837 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2838 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2839 more detail in L<perlop/"I/O Operators">.
2840
2841 Note that C<glob> splits its arguments on whitespace and treats
2842 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2843 matches all files with a F<.c> or F<.h> extension.  The expression
2844 C<glob(".* *")> matches all files in the current working directory.
2845 If you want to glob filenames that might contain whitespace, you'll
2846 have to use extra quotes around the spacey filename to protect it.
2847 For example, to glob filenames that have an C<e> followed by a space
2848 followed by an C<f>, use either of:
2849
2850     @spacies = <"*e f*">;
2851     @spacies = glob '"*e f*"';
2852     @spacies = glob q("*e f*");
2853
2854 If you had to get a variable through, you could do this:
2855
2856     @spacies = glob "'*${var}e f*'";
2857     @spacies = glob qq("*${var}e f*");
2858
2859 If non-empty braces are the only wildcard characters used in the
2860 C<glob>, no filenames are matched, but potentially many strings
2861 are returned.  For example, this produces nine strings, one for
2862 each pairing of fruits and colors:
2863
2864     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2865
2866 This operator is implemented using the standard
2867 C<File::Glob> extension.  See L<File::Glob> for details, including
2868 C<bsd_glob> which does not treat whitespace as a pattern separator.
2869
2870 Portability issues: L<perlport/glob>.
2871
2872 =item gmtime EXPR
2873 X<gmtime> X<UTC> X<Greenwich>
2874
2875 =item gmtime
2876
2877 =for Pod::Functions convert UNIX time into record or string using Greenwich time
2878
2879 Works just like L</localtime> but the returned values are
2880 localized for the standard Greenwich time zone.
2881
2882 Note: When called in list context, $isdst, the last value
2883 returned by gmtime, is always C<0>.  There is no
2884 Daylight Saving Time in GMT.
2885
2886 Portability issues: L<perlport/gmtime>.
2887
2888 =item goto LABEL
2889 X<goto> X<jump> X<jmp>
2890
2891 =item goto EXPR
2892
2893 =item goto &NAME
2894
2895 =for Pod::Functions create spaghetti code
2896
2897 The C<goto-LABEL> form finds the statement labeled with LABEL and
2898 resumes execution there.  It can't be used to get out of a block or
2899 subroutine given to C<sort>.  It can be used to go almost anywhere
2900 else within the dynamic scope, including out of subroutines, but it's
2901 usually better to use some other construct such as C<last> or C<die>.
2902 The author of Perl has never felt the need to use this form of C<goto>
2903 (in Perl, that is; C is another matter).  (The difference is that C
2904 does not offer named loops combined with loop control.  Perl does, and
2905 this replaces most structured uses of C<goto> in other languages.)
2906
2907 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2908 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2909 necessarily recommended if you're optimizing for maintainability:
2910
2911     goto ("FOO", "BAR", "GLARCH")[$i];
2912
2913 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2914 function" rule.  A pair of parentheses following it does not (necessarily)
2915 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2916 Also, unlike most named operators, this has the same precedence as
2917 assignment.
2918
2919 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2920 deprecated and will issue a warning.  Even then, it may not be used to
2921 go into any construct that requires initialization, such as a
2922 subroutine or a C<foreach> loop.  It also can't be used to go into a
2923 construct that is optimized away.
2924
2925 The C<goto-&NAME> form is quite different from the other forms of
2926 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2927 doesn't have the stigma associated with other gotos.  Instead, it
2928 exits the current subroutine (losing any changes set by local()) and
2929 immediately calls in its place the named subroutine using the current
2930 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2931 load another subroutine and then pretend that the other subroutine had
2932 been called in the first place (except that any modifications to C<@_>
2933 in the current subroutine are propagated to the other subroutine.)
2934 After the C<goto>, not even C<caller> will be able to tell that this
2935 routine was called first.
2936
2937 NAME needn't be the name of a subroutine; it can be a scalar variable
2938 containing a code reference or a block that evaluates to a code
2939 reference.
2940
2941 =item grep BLOCK LIST
2942 X<grep>
2943
2944 =item grep EXPR,LIST
2945
2946 =for Pod::Functions locate elements in a list test true against a given criterion
2947
2948 This is similar in spirit to, but not the same as, grep(1) and its
2949 relatives.  In particular, it is not limited to using regular expressions.
2950
2951 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2952 C<$_> to each element) and returns the list value consisting of those
2953 elements for which the expression evaluated to true.  In scalar
2954 context, returns the number of times the expression was true.
2955
2956     @foo = grep(!/^#/, @bar);    # weed out comments
2957
2958 or equivalently,
2959
2960     @foo = grep {!/^#/} @bar;    # weed out comments
2961
2962 Note that C<$_> is an alias to the list value, so it can be used to
2963 modify the elements of the LIST.  While this is useful and supported,
2964 it can cause bizarre results if the elements of LIST are not variables.
2965 Similarly, grep returns aliases into the original list, much as a for
2966 loop's index variable aliases the list elements.  That is, modifying an
2967 element of a list returned by grep (for example, in a C<foreach>, C<map>
2968 or another C<grep>) actually modifies the element in the original list.
2969 This is usually something to be avoided when writing clear code.
2970
2971 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2972 been declared with the deprecated C<my $_> construct)
2973 then, in addition to being locally aliased to
2974 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2975 can't be seen from the outside, avoiding any potential side-effects.
2976
2977 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2978
2979 =item hex EXPR
2980 X<hex> X<hexadecimal>
2981
2982 =item hex
2983
2984 =for Pod::Functions convert a string to a hexadecimal number
2985
2986 Interprets EXPR as a hex string and returns the corresponding value.
2987 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2988 L</oct>.)  If EXPR is omitted, uses C<$_>.
2989
2990     print hex '0xAf'; # prints '175'
2991     print hex 'aF';   # same
2992
2993 Hex strings may only represent integers.  Strings that would cause
2994 integer overflow trigger a warning.  Leading whitespace is not stripped,
2995 unlike oct().  To present something as hex, look into L</printf>,
2996 L</sprintf>, and L</unpack>.
2997
2998 =item import LIST
2999 X<import>
3000
3001 =for Pod::Functions patch a module's namespace into your own
3002
3003 There is no builtin C<import> function.  It is just an ordinary
3004 method (subroutine) defined (or inherited) by modules that wish to export
3005 names to another module.  The C<use> function calls the C<import> method
3006 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
3007
3008 =item index STR,SUBSTR,POSITION
3009 X<index> X<indexOf> X<InStr>
3010
3011 =item index STR,SUBSTR
3012
3013 =for Pod::Functions find a substring within a string
3014
3015 The index function searches for one string within another, but without
3016 the wildcard-like behavior of a full regular-expression pattern match.
3017 It returns the position of the first occurrence of SUBSTR in STR at
3018 or after POSITION.  If POSITION is omitted, starts searching from the
3019 beginning of the string.  POSITION before the beginning of the string
3020 or after its end is treated as if it were the beginning or the end,
3021 respectively.  POSITION and the return value are based at zero.
3022 If the substring is not found, C<index> returns -1.
3023
3024 =item int EXPR
3025 X<int> X<integer> X<truncate> X<trunc> X<floor>
3026
3027 =item int
3028
3029 =for Pod::Functions get the integer portion of a number
3030
3031 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
3032 You should not use this function for rounding: one because it truncates
3033 towards C<0>, and two because machine representations of floating-point
3034 numbers can sometimes produce counterintuitive results.  For example,
3035 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3036 because it's really more like -268.99999999999994315658 instead.  Usually,
3037 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
3038 functions will serve you better than will int().
3039
3040 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3041 X<ioctl>
3042
3043 =for Pod::Functions system-dependent device control system call
3044
3045 Implements the ioctl(2) function.  You'll probably first have to say
3046
3047     require "sys/ioctl.ph";  # probably in
3048                              # $Config{archlib}/sys/ioctl.ph
3049
3050 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3051 exist or doesn't have the correct definitions you'll have to roll your
3052 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3053 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3054 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3055 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3056 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
3057 has no string value but does have a numeric value, that value will be
3058 passed rather than a pointer to the string value.  To guarantee this to be
3059 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
3060 functions may be needed to manipulate the values of structures used by
3061 C<ioctl>.
3062
3063 The return value of C<ioctl> (and C<fcntl>) is as follows:
3064
3065     if OS returns:      then Perl returns:
3066         -1               undefined value
3067          0              string "0 but true"
3068     anything else           that number
3069
3070 Thus Perl returns true on success and false on failure, yet you can
3071 still easily determine the actual value returned by the operating
3072 system:
3073
3074     $retval = ioctl(...) || -1;
3075     printf "System returned %d\n", $retval;
3076
3077 The special string C<"0 but true"> is exempt from B<-w> complaints
3078 about improper numeric conversions.
3079
3080 Portability issues: L<perlport/ioctl>.
3081
3082 =item join EXPR,LIST
3083 X<join>
3084
3085 =for Pod::Functions join a list into a string using a separator
3086
3087 Joins the separate strings of LIST into a single string with fields
3088 separated by the value of EXPR, and returns that new string.  Example:
3089
3090     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3091
3092 Beware that unlike C<split>, C<join> doesn't take a pattern as its
3093 first argument.  Compare L</split>.
3094
3095 =item keys HASH
3096 X<keys> X<key>
3097
3098 =item keys ARRAY
3099
3100 =item keys EXPR
3101
3102 =for Pod::Functions retrieve list of indices from a hash
3103
3104 Called in list context, returns a list consisting of all the keys of the
3105 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3106 releases prior to 5.12 will produce a syntax error if you try to use an
3107 array argument.  In scalar context, returns the number of keys or indices.
3108
3109 The keys of a hash are returned in an apparently random order.  The actual
3110 random order is subject to change in future versions of Perl, but it
3111 is guaranteed to be the same order as either the C<values> or C<each>
3112 function produces (given that the hash has not been modified).  Since
3113 Perl 5.8.1 the ordering can be different even between different runs of
3114 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
3115 Attacks">).
3116
3117 As a side effect, calling keys() resets the internal iterator of the HASH or
3118 ARRAY (see L</each>).  In particular, calling keys() in void context resets
3119 the iterator with no other overhead.
3120
3121 Here is yet another way to print your environment:
3122
3123     @keys = keys %ENV;
3124     @values = values %ENV;
3125     while (@keys) {
3126         print pop(@keys), '=', pop(@values), "\n";
3127     }
3128
3129 or how about sorted by key:
3130
3131     foreach $key (sort(keys %ENV)) {
3132         print $key, '=', $ENV{$key}, "\n";
3133     }
3134
3135 The returned values are copies of the original keys in the hash, so
3136 modifying them will not affect the original hash.  Compare L</values>.
3137
3138 To sort a hash by value, you'll need to use a C<sort> function.
3139 Here's a descending numeric sort of a hash by its values:
3140
3141     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3142         printf "%4d %s\n", $hash{$key}, $key;
3143     }
3144
3145 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
3146 allocated for the given hash.  This can gain you a measure of efficiency if
3147 you know the hash is going to get big.  (This is similar to pre-extending
3148 an array by assigning a larger number to $#array.)  If you say
3149
3150     keys %hash = 200;
3151
3152 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3153 in fact, since it rounds up to the next power of two.  These
3154 buckets will be retained even if you do C<%hash = ()>, use C<undef
3155 %hash> if you want to free the storage while C<%hash> is still in scope.
3156 You can't shrink the number of buckets allocated for the hash using
3157 C<keys> in this way (but you needn't worry about doing this by accident,
3158 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
3159 error.
3160
3161 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
3162 a reference to an unblessed hash or array.  The argument will be
3163 dereferenced automatically.  This aspect of C<keys> is considered highly
3164 experimental.  The exact behaviour may change in a future version of Perl.
3165
3166     for (keys $hashref) { ... }
3167     for (keys $obj->get_arrayref) { ... }
3168
3169 To avoid confusing would-be users of your code who are running earlier
3170 versions of Perl with mysterious syntax errors, put this sort of thing at
3171 the top of your file to signal that your code will work I<only> on Perls of
3172 a recent vintage:
3173
3174     use 5.012;  # so keys/values/each work on arrays
3175     use 5.014;  # so keys/values/each work on scalars (experimental)
3176
3177 See also C<each>, C<values>, and C<sort>.
3178
3179 =item kill SIGNAL, LIST
3180
3181 =item kill SIGNAL
3182 X<kill> X<signal>
3183
3184 =for Pod::Functions send a signal to a process or process group
3185
3186 Sends a signal to a list of processes.  Returns the number of
3187 processes successfully signaled (which is not necessarily the
3188 same as the number actually killed).
3189
3190     $cnt = kill 'HUP', $child1, $child2;
3191     kill 'KILL', @goners;
3192
3193 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3194 name may start with a C<SIG> prefix, i.e. C<FOO> and C<SIGFOO> refer to the
3195 same signal.  The string form of SIGNAL is recommended for portability because
3196 the same signal may have different numbers in different operating systems.
3197
3198 A list of signal names supported by the current platform can be found in
3199 C<$Config{sig_name}>, which is provided by the C<Config> module. See L<Config>
3200 for more details.
3201
3202 A negative signal name is the same as a negative signal number, killing process
3203 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3204 C<kill -9, $pgrp> will send C<SIGKILL> to the entire process group specified. That
3205 means you usually want to use positive not negative signals.
3206
3207 If SIGNAL is either the number 0 or the string C<ZERO>, no signal is sent to
3208 the process, but C<kill> checks whether it's I<possible> to send a signal to it
3209 (that means, to be brief, that the process is owned by the same user, or we are
3210 the super-user).  This is useful to check that a child process is still
3211 alive (even if only as a zombie) and hasn't changed its UID.  See
3212 L<perlport> for notes on the portability of this construct.
3213
3214 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3215 the operating system.  For example, on POSIX-conforming systems, zero will
3216 signal the current process group, -1 will signal all processes, and any
3217 other negative PROCESS number will act as a negative signal number and
3218 kill the entire process group specified.
3219
3220 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3221 A warning may be produced in a future version.
3222
3223 See L<perlipc/"Signals"> for more details.
3224
3225 On some platforms such as Windows where the fork() system call is not available.
3226 Perl can be built to emulate fork() at the interpreter level.
3227 This emulation has limitations related to kill that have to be considered,
3228 for code running on Windows and in code intended to be portable.
3229
3230 See L<perlfork> for more details.
3231
3232 If there is no I<LIST> of processes, no signal is sent, and the return
3233 value is 0.  This form is sometimes used, however, because it causes
3234 tainting checks to be run.  But see
3235 L<perlsec/Laundering and Detecting Tainted Data>.
3236
3237 Portability issues: L<perlport/kill>.
3238
3239 =item last LABEL
3240 X<last> X<break>
3241
3242 =item last EXPR
3243
3244 =item last
3245
3246 =for Pod::Functions exit a block prematurely
3247
3248 The C<last> command is like the C<break> statement in C (as used in
3249 loops); it immediately exits the loop in question.  If the LABEL is
3250 omitted, the command refers to the innermost enclosing
3251 loop.  The C<last EXPR> form, available starting in Perl
3252 5.18.0, allows a label name to be computed at run time,
3253 and is otherwise identical to C<last LABEL>.  The
3254 C<continue> block, if any, is not executed:
3255
3256     LINE: while (<STDIN>) {
3257         last LINE if /^$/;  # exit when done with header
3258         #...
3259     }
3260
3261 C<last> cannot be used to exit a block that returns a value such as
3262 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3263 a grep() or map() operation.
3264
3265 Note that a block by itself is semantically identical to a loop
3266 that executes once.  Thus C<last> can be used to effect an early
3267 exit out of such a block.
3268
3269 See also L</continue> for an illustration of how C<last>, C<next>, and
3270 C<redo> work.
3271
3272 Unlike most named operators, this has the same precedence as assignment.
3273 It is also exempt from the looks-like-a-function rule, so
3274 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3275 C<last>.
3276
3277 =item lc EXPR
3278 X<lc> X<lowercase>
3279
3280 =item lc
3281
3282 =for Pod::Functions return lower-case version of a string
3283
3284 Returns a lowercased version of EXPR.  This is the internal function
3285 implementing the C<\L> escape in double-quoted strings.
3286
3287 If EXPR is omitted, uses C<$_>.
3288
3289 What gets returned depends on several factors:
3290
3291 =over
3292
3293 =item If C<use bytes> is in effect:
3294
3295 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3296 respectively.
3297
3298 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3299
3300 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3301 semantics for the remaining code points (this last can only happen if
3302 the UTF8 flag is also set).  See L<perllocale>.
3303
3304 A deficiency in this is that case changes that cross the 255/256
3305 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3306 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3307 platforms).   But under C<use locale>, the lower case of U+1E9E is
3308 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3309 current locale, and Perl has no way of knowing if that character even
3310 exists in the locale, much less what code point it is.  Perl returns
3311 the input character unchanged, for all instances (and there aren't
3312 many) where the 255/256 boundary would otherwise be crossed.
3313
3314 =item Otherwise, If EXPR has the UTF8 flag set:
3315
3316 Unicode semantics are used for the case change.
3317
3318 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'>) is in effect:
3319
3320 Unicode semantics are used for the case change.
3321
3322 =item Otherwise:
3323
3324 ASCII semantics are used for the case change.  The lowercase of any character
3325 outside the ASCII range is the character itself.
3326
3327 =back
3328
3329 =item lcfirst EXPR
3330 X<lcfirst> X<lowercase>
3331
3332 =item lcfirst
3333
3334 =for Pod::Functions return a string with just the next letter in lower case
3335
3336 Returns the value of EXPR with the first character lowercased.  This
3337 is the internal function implementing the C<\l> escape in
3338 double-quoted strings.
3339
3340 If EXPR is omitted, uses C<$_>.
3341
3342 This function behaves the same way under various pragmata, such as in a locale,
3343 as L</lc> does.
3344
3345 =item length EXPR
3346 X<length> X<size>
3347
3348 =item length
3349
3350 =for Pod::Functions return the number of characters in a string
3351
3352 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3353 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3354 C<undef>.
3355
3356 This function cannot be used on an entire array or hash to find out how
3357 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3358 %hash>, respectively.
3359
3360 Like all Perl character operations, length() normally deals in logical
3361 characters, not physical bytes.  For how many bytes a string encoded as
3362 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3363 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3364
3365 =item __LINE__
3366 X<__LINE__>
3367
3368 =for Pod::Functions the current source line number
3369
3370 A special token that compiles to the current line number.
3371
3372 =item link OLDFILE,NEWFILE
3373 X<link>
3374
3375 =for Pod::Functions create a hard link in the filesystem
3376
3377 Creates a new filename linked to the old filename.  Returns true for
3378 success, false otherwise.
3379
3380 Portability issues: L<perlport/link>.
3381
3382 =item listen SOCKET,QUEUESIZE
3383 X<listen>
3384
3385 =for Pod::Functions register your socket as a server
3386
3387 Does the same thing that the listen(2) system call does.  Returns true if
3388 it succeeded, false otherwise.  See the example in
3389 L<perlipc/"Sockets: Client/Server Communication">.
3390
3391 =item local EXPR
3392 X<local>
3393
3394 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3395
3396 You really probably want to be using C<my> instead, because C<local> isn't
3397 what most people think of as "local".  See
3398 L<perlsub/"Private Variables via my()"> for details.
3399
3400 A local modifies the listed variables to be local to the enclosing
3401 block, file, or eval.  If more than one value is listed, the list must
3402 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3403 for details, including issues with tied arrays and hashes.
3404
3405 The C<delete local EXPR> construct can also be used to localize the deletion
3406 of array/hash elements to the current block.
3407 See L<perlsub/"Localized deletion of elements of composite types">.
3408
3409 =item localtime EXPR
3410 X<localtime> X<ctime>
3411
3412 =item localtime
3413
3414 =for Pod::Functions convert UNIX time into record or string using local time
3415
3416 Converts a time as returned by the time function to a 9-element list
3417 with the time analyzed for the local time zone.  Typically used as
3418 follows:
3419
3420     #  0    1    2     3     4    5     6     7     8
3421     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3422                                                 localtime(time);
3423
3424 All list elements are numeric and come straight out of the C `struct
3425 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3426 of the specified time.
3427
3428 C<$mday> is the day of the month and C<$mon> the month in
3429 the range C<0..11>, with 0 indicating January and 11 indicating December.
3430 This makes it easy to get a month name from a list:
3431
3432     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3433     print "$abbr[$mon] $mday";
3434     # $mon=9, $mday=18 gives "Oct 18"
3435
3436 C<$year> contains the number of years since 1900.  To get a 4-digit
3437 year write:
3438
3439     $year += 1900;
3440
3441 To get the last two digits of the year (e.g., "01" in 2001) do:
3442
3443     $year = sprintf("%02d", $year % 100);
3444
3445 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3446 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3447 (or C<0..365> in leap years.)
3448
3449 C<$isdst> is true if the specified time occurs during Daylight Saving
3450 Time, false otherwise.
3451
3452 If EXPR is omitted, C<localtime()> uses the current time (as returned
3453 by time(3)).
3454
3455 In scalar context, C<localtime()> returns the ctime(3) value:
3456
3457     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3458
3459 The format of this scalar value is B<not> locale-dependent
3460 but built into Perl.  For GMT instead of local
3461 time use the L</gmtime> builtin.  See also the
3462 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3463 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3464 and mktime(3) functions.
3465
3466 To get somewhat similar but locale-dependent date strings, set up your
3467 locale environment variables appropriately (please see L<perllocale>) and
3468 try for example:
3469
3470     use POSIX qw(strftime);
3471     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3472     # or for GMT formatted appropriately for your locale:
3473     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3474
3475 Note that the C<%a> and C<%b>, the short forms of the day of the week
3476 and the month of the year, may not necessarily be three characters wide.
3477
3478 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3479 by-name access mechanism to the gmtime() and localtime() functions,
3480 respectively.
3481
3482 For a comprehensive date and time representation look at the
3483 L<DateTime> module on CPAN.
3484
3485 Portability issues: L<perlport/localtime>.
3486
3487 =item lock THING
3488 X<lock>
3489
3490 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
3491
3492 This function places an advisory lock on a shared variable or referenced
3493 object contained in I<THING> until the lock goes out of scope.
3494
3495 The value returned is the scalar itself, if the argument is a scalar, or a
3496 reference, if the argument is a hash, array or subroutine.
3497
3498 lock() is a "weak keyword" : this means that if you've defined a function
3499 by this name (before any calls to it), that function will be called
3500 instead.  If you are not under C<use threads::shared> this does nothing.
3501 See L<threads::shared>.
3502
3503 =item log EXPR
3504 X<log> X<logarithm> X<e> X<ln> X<base>
3505
3506 =item log
3507
3508 =for Pod::Functions retrieve the natural logarithm for a number
3509
3510 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3511 returns the log of C<$_>.  To get the
3512 log of another base, use basic algebra:
3513 The base-N log of a number is equal to the natural log of that number
3514 divided by the natural log of N.  For example:
3515
3516     sub log10 {
3517         my $n = shift;
3518         return log($n)/log(10);
3519     }
3520
3521 See also L</exp> for the inverse operation.
3522
3523 =item lstat FILEHANDLE
3524 X<lstat>
3525
3526 =item lstat EXPR
3527
3528 =item lstat DIRHANDLE
3529
3530 =item lstat
3531
3532 =for Pod::Functions stat a symbolic link
3533
3534 Does the same thing as the C<stat> function (including setting the
3535 special C<_> filehandle) but stats a symbolic link instead of the file
3536 the symbolic link points to.  If symbolic links are unimplemented on
3537 your system, a normal C<stat> is done.  For much more detailed
3538 information, please see the documentation for C<stat>.
3539
3540 If EXPR is omitted, stats C<$_>.
3541
3542 Portability issues: L<perlport/lstat>.
3543
3544 =item m//
3545
3546 =for Pod::Functions match a string with a regular expression pattern
3547
3548 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3549
3550 =item map BLOCK LIST
3551 X<map>
3552
3553 =item map EXPR,LIST
3554
3555 =for Pod::Functions apply a change to a list to get back a new list with the changes
3556
3557 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3558 C<$_> to each element) and returns the list value composed of the
3559 results of each such evaluation.  In scalar context, returns the
3560 total number of elements so generated.  Evaluates BLOCK or EXPR in
3561 list context, so each element of LIST may produce zero, one, or
3562 more elements in the returned value.
3563
3564     @chars = map(chr, @numbers);
3565
3566 translates a list of numbers to the corresponding characters.
3567
3568     my @squares = map { $_ * $_ } @numbers;
3569
3570 translates a list of numbers to their squared values.
3571
3572     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3573
3574 shows that number of returned elements can differ from the number of
3575 input elements.  To omit an element, return an empty list ().
3576 This could also be achieved by writing
3577
3578     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3579
3580 which makes the intention more clear.
3581
3582 Map always returns a list, which can be
3583 assigned to a hash such that the elements
3584 become key/value pairs.  See L<perldata> for more details.
3585
3586     %hash = map { get_a_key_for($_) => $_ } @array;
3587
3588 is just a funny way to write
3589
3590     %hash = ();
3591     foreach (@array) {
3592         $hash{get_a_key_for($_)} = $_;
3593     }
3594
3595 Note that C<$_> is an alias to the list value, so it can be used to
3596 modify the elements of the LIST.  While this is useful and supported,
3597 it can cause bizarre results if the elements of LIST are not variables.
3598 Using a regular C<foreach> loop for this purpose would be clearer in
3599 most cases.  See also L</grep> for an array composed of those items of
3600 the original list for which the BLOCK or EXPR evaluates to true.
3601
3602 If C<$_> is lexical in the scope where the C<map> appears (because it has
3603 been declared with the deprecated C<my $_> construct),
3604 then, in addition to being locally aliased to
3605 the list elements, C<$_> keeps being lexical inside the block; that is, it
3606 can't be seen from the outside, avoiding any potential side-effects.
3607
3608 C<{> starts both hash references and blocks, so C<map { ...> could be either
3609 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3610 ahead for the closing C<}> it has to take a guess at which it's dealing with
3611 based on what it finds just after the
3612 C<{>.  Usually it gets it right, but if it
3613 doesn't it won't realize something is wrong until it gets to the C<}> and
3614 encounters the missing (or unexpected) comma.  The syntax error will be
3615 reported close to the C<}>, but you'll need to change something near the C<{>
3616 such as using a unary C<+> to give Perl some help:
3617
3618     %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
3619     %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
3620     %hash = map { ("\L$_" => 1) } @array # this also works
3621     %hash = map {  lc($_) => 1  } @array # as does this.
3622     %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
3623
3624     %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
3625
3626 or to force an anon hash constructor use C<+{>:
3627
3628     @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
3629                                            # comma at end
3630
3631 to get a list of anonymous hashes each with only one entry apiece.
3632
3633 =item mkdir FILENAME,MASK
3634 X<mkdir> X<md> X<directory, create>
3635
3636 =item mkdir FILENAME
3637
3638 =item mkdir
3639
3640 =for Pod::Functions create a directory
3641
3642 Creates the directory specified by FILENAME, with permissions
3643 specified by MASK (as modified by C<umask>).  If it succeeds it
3644 returns true; otherwise it returns false and sets C<$!> (errno).
3645 MASK defaults to 0777 if omitted, and FILENAME defaults
3646 to C<$_> if omitted.
3647
3648 In general, it is better to create directories with a permissive MASK
3649 and let the user modify that with their C<umask> than it is to supply
3650 a restrictive MASK and give the user no way to be more permissive.
3651 The exceptions to this rule are when the file or directory should be
3652 kept private (mail files, for instance).  The perlfunc(1) entry on
3653 C<umask> discusses the choice of MASK in more detail.
3654
3655 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3656 number of trailing slashes.  Some operating and filesystems do not get
3657 this right, so Perl automatically removes all trailing slashes to keep
3658 everyone happy.
3659
3660 To recursively create a directory structure, look at
3661 the C<mkpath> function of the L<File::Path> module.
3662
3663 =item msgctl ID,CMD,ARG
3664 X<msgctl>
3665
3666 =for Pod::Functions SysV IPC message control operations
3667
3668 Calls the System V IPC function msgctl(2).  You'll probably have to say
3669
3670     use IPC::SysV;
3671
3672 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3673 then ARG must be a variable that will hold the returned C<msqid_ds>
3674 structure.  Returns like C<ioctl>: the undefined value for error,
3675 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3676 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3677 C<IPC::Semaphore>.
3678
3679 Portability issues: L<perlport/msgctl>.
3680
3681 =item msgget KEY,FLAGS
3682 X<msgget>
3683
3684 =for Pod::Functions get SysV IPC message queue
3685
3686 Calls the System V IPC function msgget(2).  Returns the message queue
3687 id, or C<undef> on error.  See also
3688 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3689 C<IPC::Msg>.
3690
3691 Portability issues: L<perlport/msgget>.
3692
3693 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3694 X<msgrcv>
3695
3696 =for Pod::Functions receive a SysV IPC message from a message queue
3697
3698 Calls the System V IPC function msgrcv to receive a message from
3699 message queue ID into variable VAR with a maximum message size of
3700 SIZE.  Note that when a message is received, the message type as a
3701 native long integer will be the first thing in VAR, followed by the
3702 actual message.  This packing may be opened with C<unpack("l! a*")>.
3703 Taints the variable.  Returns true if successful, false 
3704 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3705 C<IPC::SysV> and C<IPC::SysV::Msg>.
3706
3707 Portability issues: L<perlport/msgrcv>.
3708
3709 =item msgsnd ID,MSG,FLAGS
3710 X<msgsnd>
3711
3712 =for Pod::Functions send a SysV IPC message to a message queue
3713
3714 Calls the System V IPC function msgsnd to send the message MSG to the
3715 message queue ID.  MSG must begin with the native long integer message
3716 type, be followed by the length of the actual message, and then finally
3717 the message itself.  This kind of packing can be achieved with
3718 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3719 false on error.  See also the C<IPC::SysV>
3720 and C<IPC::SysV::Msg> documentation.
3721
3722 Portability issues: L<perlport/msgsnd>.
3723
3724 =item my EXPR
3725 X<my>
3726
3727 =item my TYPE EXPR
3728
3729 =item my EXPR : ATTRS
3730
3731 =item my TYPE EXPR : ATTRS
3732
3733 =for Pod::Functions declare and assign a local variable (lexical scoping)
3734
3735 A C<my> declares the listed variables to be local (lexically) to the
3736 enclosing block, file, or C<eval>.  If more than one value is listed,
3737 the list must be placed in parentheses.
3738
3739 The exact semantics and interface of TYPE and ATTRS are still
3740 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3741 and attributes are handled using the C<attributes> pragma, or starting
3742 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3743 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3744 L<attributes>, and L<Attribute::Handlers>.
3745
3746 =item next LABEL
3747 X<next> X<continue>
3748
3749 =item next EXPR
3750
3751 =item next
3752
3753 =for Pod::Functions iterate a block prematurely
3754
3755 The C<next> command is like the C<continue> statement in C; it starts
3756 the next iteration of the loop:
3757
3758     LINE: while (<STDIN>) {
3759         next LINE if /^#/;  # discard comments
3760         #...
3761     }
3762
3763 Note that if there were a C<continue> block on the above, it would get
3764 executed even on discarded lines.  If LABEL is omitted, the command
3765 refers to the innermost enclosing loop.  The C<next EXPR> form, available
3766 as of Perl 5.18.0, allows a label name to be computed at run time, being
3767 otherwise identical to C<next LABEL>.
3768
3769 C<next> cannot be used to exit a block which returns a value such as
3770 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3771 a grep() or map() operation.
3772
3773 Note that a block by itself is semantically identical to a loop
3774 that executes once.  Thus C<next> will exit such a block early.
3775
3776 See also L</continue> for an illustration of how C<last>, C<next>, and
3777 C<redo> work.
3778
3779 Unlike most named operators, this has the same precedence as assignment.
3780 It is also exempt from the looks-like-a-function rule, so
3781 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
3782 C<next>.
3783
3784 =item no MODULE VERSION LIST
3785 X<no declarations>
3786 X<unimporting>
3787
3788 =item no MODULE VERSION
3789
3790 =item no MODULE LIST
3791
3792 =item no MODULE
3793
3794 =item no VERSION
3795
3796 =for Pod::Functions unimport some module symbols or semantics at compile time
3797
3798 See the C<use> function, of which C<no> is the opposite.
3799
3800 =item oct EXPR
3801 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3802
3803 =item oct
3804
3805 =for Pod::Functions convert a string to an octal number
3806
3807 Interprets EXPR as an octal string and returns the corresponding
3808 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3809 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3810 binary string.  Leading whitespace is ignored in all three cases.)
3811 The following will handle decimal, binary, octal, and hex in standard
3812 Perl notation:
3813
3814     $val = oct($val) if $val =~ /^0/;
3815
3816 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3817 in octal), use sprintf() or printf():
3818
3819     $dec_perms = (stat("filename"))[2] & 07777;
3820     $oct_perm_str = sprintf "%o", $perms;
3821
3822 The oct() function is commonly used when a string such as C<644> needs
3823 to be converted into a file mode, for example.  Although Perl 
3824 automatically converts strings into numbers as needed, this automatic
3825 conversion assumes base 10.
3826
3827 Leading white space is ignored without warning, as too are any trailing 
3828 non-digits, such as a decimal point (C<oct> only handles non-negative
3829 integers, not negative integers or floating point).
3830
3831 =item open FILEHANDLE,EXPR
3832 X<open> X<pipe> X<file, open> X<fopen>
3833
3834 =item open FILEHANDLE,MODE,EXPR
3835
3836 =item open FILEHANDLE,MODE,EXPR,LIST
3837
3838 =item open FILEHANDLE,MODE,REFERENCE
3839
3840 =item open FILEHANDLE
3841
3842 =for Pod::Functions open a file, pipe, or descriptor
3843
3844 Opens the file whose filename is given by EXPR, and associates it with
3845 FILEHANDLE.
3846
3847 Simple examples to open a file for reading:
3848
3849     open(my $fh, "<", "input.txt") 
3850         or die "cannot open < input.txt: $!";
3851
3852 and for writing:
3853
3854     open(my $fh, ">", "output.txt") 
3855         or die "cannot open > output.txt: $!";
3856
3857 (The following is a comprehensive reference to open(): for a gentler
3858 introduction you may consider L<perlopentut>.)
3859
3860 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3861 new filehandle is autovivified, meaning that the variable is assigned a
3862 reference to a newly allocated anonymous filehandle.  Otherwise if
3863 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3864 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3865 in effect.)
3866
3867 If EXPR is omitted, the global (package) scalar variable of the same
3868 name as the FILEHANDLE contains the filename.  (Note that lexical 
3869 variables--those declared with C<my> or C<state>--will not work for this
3870 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3871 call to open.)
3872
3873 If three (or more) arguments are specified, the open mode (including
3874 optional encoding) in the second argument are distinct from the filename in
3875 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3876 If MODE is C<< > >>, the file is opened for output, with existing files
3877 first being truncated ("clobbered") and nonexisting files newly created.
3878 If MODE is C<<< >> >>>, the file is opened for appending, again being
3879 created if necessary.
3880
3881 You can put a C<+> in front of the C<< > >> or C<< < >> to
3882 indicate that you want both read and write access to the file; thus
3883 C<< +< >> is almost always preferred for read/write updates--the 
3884 C<< +> >> mode would clobber the file first.  You can't usually use
3885 either read-write mode for updating textfiles, since they have
3886 variable-length records.  See the B<-i> switch in L<perlrun> for a
3887 better approach.  The file is created with permissions of C<0666>
3888 modified by the process's C<umask> value.
3889
3890 These various prefixes correspond to the fopen(3) modes of C<r>,
3891 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3892
3893 In the one- and two-argument forms of the call, the mode and filename
3894 should be concatenated (in that order), preferably separated by white
3895 space.  You can--but shouldn't--omit the mode in these forms when that mode
3896 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3897 the filename argument is a known literal.
3898
3899 For three or more arguments if MODE is C<|->, the filename is
3900 interpreted as a command to which output is to be piped, and if MODE
3901 is C<-|>, the filename is interpreted as a command that pipes
3902 output to us.  In the two-argument (and one-argument) form, one should
3903 replace dash (C<->) with the command.
3904 See L<perlipc/"Using open() for IPC"> for more examples of this.
3905 (You are not allowed to C<open> to a command that pipes both in I<and>
3906 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3907 L<perlipc/"Bidirectional Communication with Another Process"> for
3908 alternatives.)
3909
3910 In the form of pipe opens taking three or more arguments, if LIST is specified
3911 (extra arguments after the command name) then LIST becomes arguments
3912 to the command invoked if the platform supports it.  The meaning of
3913 C<open> with more than three arguments for non-pipe modes is not yet
3914 defined, but experimental "layers" may give extra LIST arguments
3915 meaning.
3916
3917 In the two-argument (and one-argument) form, opening C<< <- >> 
3918 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3919
3920 You may (and usually should) use the three-argument form of open to specify
3921 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3922 that affect how the input and output are processed (see L<open> and
3923 L<PerlIO> for more details).  For example:
3924
3925   open(my $fh, "<:encoding(UTF-8)", "filename")
3926     || die "can't open UTF-8 encoded filename: $!";
3927
3928 opens the UTF8-encoded file containing Unicode characters;
3929 see L<perluniintro>.  Note that if layers are specified in the
3930 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3931 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3932 Those layers will also be ignored if you specifying a colon with no name
3933 following it.  In that case the default layer for the operating system
3934 (:raw on Unix, :crlf on Windows) is used.
3935
3936 Open returns nonzero on success, the undefined value otherwise.  If
3937 the C<open> involved a pipe, the return value happens to be the pid of
3938 the subprocess.
3939
3940 If you're running Perl on a system that distinguishes between text
3941 files and binary files, then you should check out L</binmode> for tips
3942 for dealing with this.  The key distinction between systems that need
3943 C<binmode> and those that don't is their text file formats.  Systems
3944 like Unix, Mac OS, and Plan 9, that end lines with a single
3945 character and encode that character in C as C<"\n"> do not
3946 need C<binmode>.  The rest need it.
3947
3948 When opening a file, it's seldom a good idea to continue 
3949 if the request failed, so C<open> is frequently used with
3950 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3951 where you want to format a suitable error message (but there are
3952 modules that can help with that problem)) always check
3953 the return value from opening a file.  
3954
3955 As a special case the three-argument form with a read/write mode and the third
3956 argument being C<undef>:
3957
3958     open(my $tmp, "+>", undef) or die ...
3959
3960 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3961 works for symmetry, but you really should consider writing something
3962 to the temporary file first.  You will need to seek() to do the
3963 reading.
3964
3965 Perl is built using PerlIO by default; Unless you've
3966 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3967 open filehandles directly to Perl scalars via:
3968
3969     open($fh, ">", \$variable) || ..
3970
3971 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3972
3973     close STDOUT;
3974     open(STDOUT, ">", \$variable)
3975         or die "Can't open STDOUT: $!";
3976
3977 General examples:
3978
3979     $ARTICLE = 100;
3980     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3981     while (<ARTICLE>) {...
3982
3983     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3984     # if the open fails, output is discarded
3985
3986     open(my $dbase, "+<", "dbase.mine")      # open for update
3987         or die "Can't open 'dbase.mine' for update: $!";
3988
3989     open(my $dbase, "+<dbase.mine")          # ditto
3990         or die "Can't open 'dbase.mine' for update: $!";
3991
3992     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3993         or die "Can't start caesar: $!";
3994
3995     open(ARTICLE, "caesar <$article |")      # ditto
3996         or die "Can't start caesar: $!";
3997
3998     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3999         or die "Can't start sort: $!";
4000
4001     # in-memory files
4002     open(MEMORY, ">", \$var)
4003         or die "Can't open memory file: $!";
4004     print MEMORY "foo!\n";              # output will appear in $var
4005
4006     # process argument list of files along with any includes
4007
4008     foreach $file (@ARGV) {
4009         process($file, "fh00");
4010     }
4011
4012     sub process {
4013         my($filename, $input) = @_;
4014         $input++;    # this is a string increment
4015         unless (open($input, "<", $filename)) {
4016             print STDERR "Can't open $filename: $!\n";
4017             return;
4018         }
4019
4020         local $_;
4021         while (<$input>) {    # note use of indirection
4022             if (/^#include "(.*)"/) {
4023                 process($1, $input);
4024                 next;
4025             }
4026             #...          # whatever
4027         }
4028     }
4029
4030 See L<perliol> for detailed info on PerlIO.
4031
4032 You may also, in the Bourne shell tradition, specify an EXPR beginning
4033 with C<< >& >>, in which case the rest of the string is interpreted
4034 as the name of a filehandle (or file descriptor, if numeric) to be
4035 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4036 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4037 The mode you specify should match the mode of the original filehandle.
4038 (Duping a filehandle does not take into account any existing contents
4039 of IO buffers.)  If you use the three-argument
4040 form, then you can pass either a
4041 number, the name of a filehandle, or the normal "reference to a glob".
4042
4043 Here is a script that saves, redirects, and restores C<STDOUT> and
4044 C<STDERR> using various methods:
4045
4046     #!/usr/bin/perl
4047     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4048     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4049
4050     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4051     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4052
4053     select STDERR; $| = 1;  # make unbuffered
4054     select STDOUT; $| = 1;  # make unbuffered
4055
4056     print STDOUT "stdout 1\n";  # this works for
4057     print STDERR "stderr 1\n";  # subprocesses too
4058
4059     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4060     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4061
4062     print STDOUT "stdout 2\n";
4063     print STDERR "stderr 2\n";
4064
4065 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4066 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
4067 that file descriptor (and not call C<dup(2)>); this is more
4068 parsimonious of file descriptors.  For example:
4069
4070     # open for input, reusing the fileno of $fd
4071     open(FILEHANDLE, "<&=$fd")
4072
4073 or
4074
4075     open(FILEHANDLE, "<&=", $fd)
4076
4077 or
4078
4079     # open for append, using the fileno of OLDFH
4080     open(FH, ">>&=", OLDFH)
4081
4082 or
4083
4084     open(FH, ">>&=OLDFH")
4085
4086 Being parsimonious on filehandles is also useful (besides being
4087 parsimonious) for example when something is dependent on file
4088 descriptors, like for example locking using flock().  If you do just
4089 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
4090 descriptor as B, and therefore flock(A) will not flock(B) nor vice
4091 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
4092 the same underlying system file descriptor.
4093
4094 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4095 fdopen() to implement the C<=> functionality.  On many Unix systems,
4096 fdopen() fails when file descriptors exceed a certain value, typically 255.
4097 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4098
4099 You can see whether your Perl was built with PerlIO by running C<perl -V>
4100 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
4101 have PerlIO; otherwise you don't.
4102
4103 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4104 with the one- or two-argument forms of C<open>), 
4105 an implicit C<fork> is done, so C<open> returns twice: in the parent
4106 process it returns the pid
4107 of the child process, and in the child process it returns (a defined) C<0>.
4108 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4109
4110 For example, use either
4111
4112     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
4113
4114 or
4115
4116     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
4117
4118 followed by 
4119
4120     if ($child_pid) {
4121         # am the parent:
4122         # either write TO_KID or else read FROM_KID
4123         ...
4124        waitpid $child_pid, 0;
4125     } else {
4126         # am the child; use STDIN/STDOUT normally
4127         ...
4128         exit;
4129     } 
4130
4131 The filehandle behaves normally for the parent, but I/O to that
4132 filehandle is piped from/to the STDOUT/STDIN of the child process.
4133 In the child process, the filehandle isn't opened--I/O happens from/to
4134 the new STDOUT/STDIN.  Typically this is used like the normal
4135 piped open when you want to exercise more control over just how the
4136 pipe command gets executed, such as when running setuid and
4137 you don't want to have to scan shell commands for metacharacters.
4138
4139 The following blocks are more or less equivalent:
4140
4141     open(FOO, "|tr '[a-z]' '[A-Z]'");
4142     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
4143     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4144     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
4145
4146     open(FOO, "cat -n '$file'|");
4147     open(FOO, "-|", "cat -n '$file'");
4148     open(FOO, "-|") || exec "cat", "-n", $file;
4149     open(FOO, "-|", "cat", "-n", $file);
4150
4151 The last two examples in each block show the pipe as "list form", which is
4152 not yet supported on all platforms.  A good rule of thumb is that if
4153 your platform has a real C<fork()> (in other words, if your platform is
4154 Unix, including Linux and MacOS X), you can use the list form.  You would 
4155 want to use the list form of the pipe so you can pass literal arguments
4156 to the command without risk of the shell interpreting any shell metacharacters
4157 in them.  However, this also bars you from opening pipes to commands
4158 that intentionally contain shell metacharacters, such as:
4159
4160     open(FOO, "|cat -n | expand -4 | lpr")
4161         // die "Can't open pipeline to lpr: $!";
4162
4163 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
4164
4165 Perl will attempt to flush all files opened for
4166 output before any operation that may do a fork, but this may not be
4167 supported on some platforms (see L<perlport>).  To be safe, you may need
4168 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
4169 of C<IO::Handle> on any open handles.
4170
4171 On systems that support a close-on-exec flag on files, the flag will
4172 be set for the newly opened file descriptor as determined by the value
4173 of C<$^F>.  See L<perlvar/$^F>.
4174
4175 Closing any piped filehandle causes the parent process to wait for the
4176 child to finish, then returns the status value in C<$?> and
4177 C<${^CHILD_ERROR_NATIVE}>.
4178
4179 The filename passed to the one- and two-argument forms of open() will
4180 have leading and trailing whitespace deleted and normal
4181 redirection characters honored.  This property, known as "magic open",
4182 can often be used to good effect.  A user could specify a filename of
4183 F<"rsh cat file |">, or you could change certain filenames as needed:
4184
4185     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
4186     open(FH, $filename) or die "Can't open $filename: $!";
4187
4188 Use the three-argument form to open a file with arbitrary weird characters in it,
4189
4190     open(FOO, "<", $file)
4191         || die "can't open < $file: $!";
4192
4193 otherwise it's necessary to protect any leading and trailing whitespace:
4194
4195     $file =~ s#^(\s)#./$1#;
4196     open(FOO, "< $file\0")
4197         || die "open failed: $!";
4198
4199 (this may not work on some bizarre filesystems).  One should
4200 conscientiously choose between the I<magic> and I<three-argument> form
4201 of open():
4202
4203     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
4204
4205 will allow the user to specify an argument of the form C<"rsh cat file |">,
4206 but will not work on a filename that happens to have a trailing space, while
4207
4208     open(IN, "<", $ARGV[0])
4209         || die "can't open < $ARGV[0]: $!";
4210
4211 will have exactly the opposite restrictions.
4212
4213 If you want a "real" C C<open> (see L<open(2)> on your system), then you
4214 should use the C<sysopen> function, which involves no such magic (but may
4215 use subtly different filemodes than Perl open(), which is mapped to C
4216 fopen()).  This is another way to protect your filenames from
4217 interpretation.  For example:
4218
4219     use IO::Handle;
4220     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
4221         or die "sysopen $path: $!";
4222     $oldfh = select(HANDLE); $| = 1; select($oldfh);
4223     print HANDLE "stuff $$\n";
4224     seek(HANDLE, 0, 0);
4225     print "File contains: ", <HANDLE>;
4226
4227 Using the constructor from the C<IO::Handle> package (or one of its
4228 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
4229 filehandles that have the scope of the variables used to hold them, then
4230 automatically (but silently) close once their reference counts become
4231 zero, typically at scope exit:
4232
4233     use IO::File;
4234     #...
4235     sub read_myfile_munged {
4236         my $ALL = shift;
4237         # or just leave it undef to autoviv
4238         my $handle = IO::File->new;
4239         open($handle, "<", "myfile") or die "myfile: $!";
4240         $first = <$handle>
4241             or return ();     # Automatically closed here.
4242         mung($first) or die "mung failed";  # Or here.
4243         return (first, <$handle>) if $ALL;  # Or here.
4244         return $first;                      # Or here.
4245     }
4246
4247 B<WARNING:> The previous example has a bug because the automatic
4248 close that happens when the refcount on C<handle> reaches zero does not
4249 properly detect and report failures.  I<Always> close the handle
4250 yourself and inspect the return value.
4251
4252     close($handle) 
4253         || warn "close failed: $!";
4254
4255 See L</seek> for some details about mixing reading and writing.
4256
4257 Portability issues: L<perlport/open>.
4258
4259 =item opendir DIRHANDLE,EXPR
4260 X<opendir>
4261
4262 =for Pod::Functions open a directory
4263
4264 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
4265 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
4266 DIRHANDLE may be an expression whose value can be used as an indirect
4267 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
4268 scalar variable (or array or hash element), the variable is assigned a
4269 reference to a new anonymous dirhandle; that is, it's autovivified.
4270 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
4271
4272 See the example at C<readdir>.
4273
4274 =item ord EXPR
4275 X<ord> X<encoding>
4276
4277 =item ord
4278
4279 =for Pod::Functions find a character's numeric representation
4280
4281 Returns the numeric value of the first character of EXPR.
4282 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
4283 (Note I<character>, not byte.)
4284
4285 For the reverse, see L</chr>.
4286 See L<perlunicode> for more about Unicode.
4287
4288 =item our EXPR
4289 X<our> X<global>
4290
4291 =item our TYPE EXPR
4292
4293 =item our EXPR : ATTRS
4294
4295 =item our TYPE EXPR : ATTRS
4296
4297 =for Pod::Functions +5.6.0 declare and assign a package variable (lexical scoping)
4298
4299 C<our> makes a lexical alias to a package variable of the same name in the current
4300 package for use within the current lexical scope.
4301
4302 C<our> has the same scoping rules as C<my> or C<state>, but C<our> only
4303 declares an alias, whereas C<my> or C<state> both declare a variable name and
4304 allocate storage for that name within the current scope.
4305
4306 This means that when C<use strict 'vars'> is in effect, C<our> lets you use
4307 a package variable without qualifying it with the package name, but only within
4308 the lexical scope of the C<our> declaration.  In this way, C<our> differs from
4309 C<use vars>, which allows use of an unqualified name I<only> within the
4310 affected package, but across scopes.
4311
4312 If more than one value is listed, the list must be placed
4313 in parentheses.
4314
4315     our $foo;
4316     our($bar, $baz);
4317
4318 An C<our> declaration declares an alias for a package variable that will be visible
4319 across its entire lexical scope, even across package boundaries.  The
4320 package in which the variable is entered is determined at the point
4321 of the declaration, not at the point of use.  This means the following
4322 behavior holds:
4323
4324     package Foo;
4325     our $bar;      # declares $Foo::bar for rest of lexical scope
4326     $bar = 20;
4327
4328     package Bar;
4329     print $bar;    # prints 20, as it refers to $Foo::bar
4330
4331 Multiple C<our> declarations with the same name in the same lexical
4332 scope are allowed if they are in different packages.  If they happen
4333 to be in the same package, Perl will emit warnings if you have asked
4334 for them, just like multiple C<my> declarations.  Unlike a second
4335 C<my> declaration, which will bind the name to a fresh variable, a
4336 second C<our> declaration in the same package, in the same scope, is
4337 merely redundant.
4338
4339     use warnings;
4340     package Foo;
4341     our $bar;      # declares $Foo::bar for rest of lexical scope
4342     $bar = 20;
4343
4344     package Bar;
4345     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4346     print $bar;    # prints 30
4347
4348     our $bar;      # emits warning but has no other effect
4349     print $bar;    # still prints 30
4350
4351 An C<our> declaration may also have a list of attributes associated
4352 with it.
4353
4354 The exact semantics and interface of TYPE and ATTRS are still
4355 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4356 and attributes are handled using the C<attributes> pragma, or, starting
4357 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4358 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4359 L<attributes>, and L<Attribute::Handlers>.
4360
4361 =item pack TEMPLATE,LIST
4362 X<pack>
4363
4364 =for Pod::Functions convert a list into a binary representation
4365
4366 Takes a LIST of values and converts it into a string using the rules
4367 given by the TEMPLATE.  The resulting string is the concatenation of
4368 the converted values.  Typically, each converted value looks
4369 like its machine-level representation.  For example, on 32-bit machines
4370 an integer may be represented by a sequence of 4 bytes, which  will in
4371 Perl be presented as a string that's 4 characters long. 
4372
4373 See L<perlpacktut> for an introduction to this function.
4374
4375 The TEMPLATE is a sequence of characters that give the order and type
4376 of values, as follows:
4377
4378     a  A string with arbitrary binary data, will be null padded.
4379     A  A text (ASCII) string, will be space padded.
4380     Z  A null-terminated (ASCIZ) string, will be null padded.
4381
4382     b  A bit string (ascending bit order inside each byte,
4383        like vec()).
4384     B  A bit string (descending bit order inside each byte).
4385     h  A hex string (low nybble first).
4386     H  A hex string (high nybble first).
4387
4388     c  A signed char (8-bit) value.
4389     C  An unsigned char (octet) value.
4390     W  An unsigned char value (can be greater than 255).
4391
4392     s  A signed short (16-bit) value.
4393     S  An unsigned short value.
4394
4395     l  A signed long (32-bit) value.
4396     L  An unsigned long value.
4397
4398     q  A signed quad (64-bit) value.
4399     Q  An unsigned quad value.
4400          (Quads are available only if your system supports 64-bit
4401           integer values _and_ if Perl has been compiled to support
4402           those.  Raises an exception otherwise.)
4403
4404     i  A signed integer value.
4405     I  A unsigned integer value.
4406          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4407           size depends on what a local C compiler calls 'int'.)
4408
4409     n  An unsigned short (16-bit) in "network" (big-endian) order.
4410     N  An unsigned long (32-bit) in "network" (big-endian) order.
4411     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4412     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4413
4414     j  A Perl internal signed integer value (IV).
4415     J  A Perl internal unsigned integer value (UV).
4416
4417     f  A single-precision float in native format.
4418     d  A double-precision float in native format.
4419
4420     F  A Perl internal floating-point value (NV) in native format
4421     D  A float of long-double precision in native format.
4422          (Long doubles are available only if your system supports
4423           long double values _and_ if Perl has been compiled to
4424           support those.  Raises an exception otherwise.)
4425
4426     p  A pointer to a null-terminated string.
4427     P  A pointer to a structure (fixed-length string).
4428
4429     u  A uuencoded string.
4430     U  A Unicode character number.  Encodes to a character in char-
4431        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4432        byte mode.
4433
4434     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4435        for details).  Its bytes represent an unsigned integer in
4436        base 128, most significant digit first, with as few digits
4437        as possible.  Bit eight (the high bit) is set on each byte
4438        except the last.
4439
4440     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4441     X  Back up a byte.
4442     @  Null-fill or truncate to absolute position, counted from the
4443        start of the innermost ()-group.
4444     .  Null-fill or truncate to absolute position specified by
4445        the value.
4446     (  Start of a ()-group.
4447
4448 One or more modifiers below may optionally follow certain letters in the
4449 TEMPLATE (the second column lists letters for which the modifier is valid):
4450
4451     !   sSlLiI     Forces native (short, long, int) sizes instead
4452                    of fixed (16-/32-bit) sizes.
4453
4454         xX         Make x and X act as alignment commands.
4455
4456         nNvV       Treat integers as signed instead of unsigned.
4457
4458         @.         Specify position as byte offset in the internal
4459                    representation of the packed string.  Efficient
4460                    but dangerous.
4461
4462     >   sSiIlLqQ   Force big-endian byte-order on the type.
4463         jJfFdDpP   (The "big end" touches the construct.)
4464
4465     <   sSiIlLqQ   Force little-endian byte-order on the type.
4466         jJfFdDpP   (The "little end" touches the construct.)
4467
4468 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4469 to force a particular byte-order on all components in that group, 
4470 including all its subgroups.
4471
4472 =begin comment
4473
4474 Larry recalls that the hex and bit string formats (H, h, B, b) were added to
4475 pack for processing data from NASA's Magellan probe. Magellan was in an
4476 elliptical orbit, using the antenna for the radar mapping when close to
4477 Venus and for communicating data back to Earth for the rest of the orbit.
4478 There were two transmission units, but one of these failed, and then the
4479 other developed a fault whereby it would randomly flip the sense of all the
4480 bits. It was easy to automatically detect complete records with the correct
4481 sense, and complete records with all the bits flipped. However, this didn't
4482 recover the records where the sense flipped midway. A colleague of Larry's
4483 was able to pretty much eyeball where the records flipped, so they wrote an
4484 editor named kybble (a pun on the dog food Kibbles 'n Bits) to enable him to
4485 manually correct the records and recover the data. For this purpose pack
4486 gained the hex and bit string format specifiers.
4487
4488 git shows that they were added to perl 3.0 in patch #44 (Jan 1991, commit
4489 27e2fb84680b9cc1), but the patch description makes no mention of their
4490 addition, let alone the story behind them.
4491
4492 =end comment
4493
4494 The following rules apply:
4495
4496 =over 
4497
4498 =item *
4499
4500 Each letter may optionally be followed by a number indicating the repeat
4501 count.  A numeric repeat count may optionally be enclosed in brackets, as
4502 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4503 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4504 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4505 something else, described below.  Supplying a C<*> for the repeat count
4506 instead of a number means to use however many items are left, except for:
4507
4508 =over 
4509
4510 =item * 
4511
4512 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4513
4514 =item * 
4515
4516 <.>, where it means relative to the start of the string.
4517
4518 =item * 
4519
4520 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4521
4522 =back 
4523
4524 One can replace a numeric repeat count with a template letter enclosed in
4525 brackets to use the packed byte length of the bracketed template for the
4526 repeat count.
4527
4528 For example, the template C<x[L]> skips as many bytes as in a packed long,
4529 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4530 variable-expanded) unpacks.  If the template in brackets contains alignment
4531 commands (such as C<x![d]>), its packed length is calculated as if the
4532 start of the template had the maximal possible alignment.
4533
4534 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4535 trailing null byte, so the resulting string is always one byte longer than
4536 the byte length of the item itself.
4537
4538 When used with C<@>, the repeat count represents an offset from the start
4539 of the innermost C<()> group.
4540
4541 When used with C<.>, the repeat count determines the starting position to
4542 calculate the value offset as follows:
4543
4544 =over 
4545
4546 =item *
4547
4548 If the repeat count is C<0>, it's relative to the current position.
4549
4550 =item *
4551
4552 If the repeat count is C<*>, the offset is relative to the start of the
4553 packed string.
4554
4555 =item *
4556
4557 And if it's an integer I<n>, the offset is relative to the start of the
4558 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4559 bigger then the group level.
4560
4561 =back
4562
4563 The repeat count for C<u> is interpreted as the maximal number of bytes
4564 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4565 count should not be more than 65.
4566
4567 =item *
4568
4569 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4570 string of length count, padding with nulls or spaces as needed.  When
4571 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4572 after the first null, and C<a> returns data with no stripping at all.
4573
4574 If the value to pack is too long, the result is truncated.  If it's too
4575 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4576 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4577 when the count is 0.
4578
4579 =item *
4580
4581 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4582 Each such format generates 1 bit of the result.  These are typically followed
4583 by a repeat count like C<B8> or C<B64>.
4584
4585 Each result bit is based on the least-significant bit of the corresponding
4586 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4587 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4588
4589 Starting from the beginning of the input string, each 8-tuple
4590 of characters is converted to 1 character of output.  With format C<b>,
4591 the first character of the 8-tuple determines the least-significant bit of a
4592 character; with format C<B>, it determines the most-significant bit of
4593 a character.
4594
4595 If the length of the input string is not evenly divisible by 8, the
4596 remainder is packed as if the input string were padded by null characters
4597 at the end.  Similarly during unpacking, "extra" bits are ignored.
4598
4599 If the input string is longer than needed, remaining characters are ignored.
4600
4601 A C<*> for the repeat count uses all characters of the input field.  
4602 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4603
4604 =item *
4605
4606 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4607 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4608
4609 For each such format, pack() generates 4 bits of result.
4610 With non-alphabetical characters, the result is based on the 4 least-significant
4611 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4612 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4613 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4614 is compatible with the usual hexadecimal digits, so that C<"a"> and
4615 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4616 characters with this format.
4617
4618 Starting from the beginning of the template to pack(), each pair
4619 of characters is converted to 1 character of output.  With format C<h>, the
4620 first character of the pair determines the least-significant nybble of the
4621 output character; with format C<H>, it determines the most-significant
4622 nybble.
4623
4624 If the length of the input string is not even, it behaves as if padded by
4625 a null character at the end.  Similarly, "extra" nybbles are ignored during
4626 unpacking.
4627
4628 If the input string is longer than needed, extra characters are ignored.
4629
4630 A C<*> for the repeat count uses all characters of the input field.  For
4631 unpack(), nybbles are converted to a string of hexadecimal digits.
4632
4633 =item *
4634
4635 The C<p> format packs a pointer to a null-terminated string.  You are
4636 responsible for ensuring that the string is not a temporary value, as that
4637 could potentially get deallocated before you got around to using the packed
4638 result.  The C<P> format packs a pointer to a structure of the size indicated
4639 by the length.  A null pointer is created if the corresponding value for
4640 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4641 unpacks into C<undef>.
4642
4643 If your system has a strange pointer size--meaning a pointer is neither as
4644 big as an int nor as big as a long--it may not be possible to pack or
4645 unpack pointers in big- or little-endian byte order.  Attempting to do
4646 so raises an exception.
4647
4648 =item *
4649
4650 The C</> template character allows packing and unpacking of a sequence of
4651 items where the packed structure contains a packed item count followed by
4652 the packed items themselves.  This is useful when the structure you're
4653 unpacking has encoded the sizes or repeat counts for some of its fields
4654 within the structure itself as separate fields.
4655
4656 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4657 I<length-item> describes how the length value is packed.  Formats likely
4658 to be of most use are integer-packing ones like C<n> for Java strings,
4659 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4660
4661 For C<pack>, I<sequence-item> may have a repeat count, in which case
4662 the minimum of that and the number of available items is used as the argument
4663 for I<length-item>.  If it has no repeat count or uses a '*', the number
4664 of available items is used.
4665
4666 For C<unpack>, an internal stack of integer arguments unpacked so far is
4667 used.  You write C</>I<sequence-item> and the repeat count is obtained by
4668 popping off the last element from the stack.  The I<sequence-item> must not
4669 have a repeat count.
4670
4671 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4672 the I<length-item> is the string length, not the number of strings.  With
4673 an explicit repeat count for pack, the packed string is adjusted to that
4674 length.  For example:
4675
4676  This code:                             gives this result:
4677
4678  unpack("W/a", "\004Gurusamy")          ("Guru")
4679  unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4680  unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4681
4682  pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4683