This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
50249373719189315c129bb2c06fa1dd47712407
[perl5.git] / ext / POSIX / t / posix.t
1 #!./perl
2
3 BEGIN {
4     require Config; import Config;
5     if ($^O ne 'VMS' and $Config{'extensions'} !~ /\bPOSIX\b/) {
6         print "1..0\n";
7         exit 0;
8     }
9     unshift @INC, "../../t";
10     require 'loc_tools.pl';
11 }
12
13 use Test::More tests => 96;
14
15 use POSIX qw(fcntl_h signal_h limits_h _exit getcwd open read strftime write
16              errno localeconv dup dup2 lseek access);
17 use strict 'subs';
18 use warnings;
19
20 sub next_test {
21     my $builder = Test::More->builder;
22     $builder->current_test($builder->current_test() + 1);
23 }
24
25 $| = 1;
26
27 $Is_W32     = $^O eq 'MSWin32';
28 $Is_Dos     = $^O eq 'dos';
29 $Is_VMS     = $^O eq 'VMS';
30 $Is_OS2     = $^O eq 'os2';
31 $Is_UWin    = $^O eq 'uwin';
32 $Is_OS390   = $^O eq 'os390';
33
34 my $vms_unix_rpt = 0;
35 my $vms_efs = 0;
36 my $unix_mode = 1;
37
38 if ($Is_VMS) {
39     $unix_mode = 0;
40     if (eval 'require VMS::Feature') {
41         $vms_unix_rpt = VMS::Feature::current("filename_unix_report");
42         $vms_efs = VMS::Feature::current("efs_charset");
43     } else {
44         my $unix_rpt = $ENV{'DECC$FILENAME_UNIX_REPORT'} || '';
45         my $efs_charset = $ENV{'DECC$EFS_CHARSET'} || '';
46         $vms_unix_rpt = $unix_rpt =~ /^[ET1]/i;
47         $vms_efs = $efs_charset =~ /^[ET1]/i;
48     }
49
50     # Traditional VMS mode only if VMS is not in UNIX compatible mode.
51     $unix_mode = ($vms_efs && $vms_unix_rpt);
52
53 }
54
55 my $testfd = open("Makefile.PL", O_RDONLY, 0);
56 like($testfd, qr/\A\d+\z/, 'O_RDONLY with open');
57 read($testfd, $buffer, 4) if $testfd > 2;
58 is( $buffer, "# Ex",                      '    with read' );
59
60 TODO:
61 {
62     local $TODO = "read to array element not working";
63
64     read($testfd, $buffer[1], 5) if $testfd > 2;
65     is( $buffer[1], "perl\n",                  '    read to array element' );
66 }
67
68 my $test = next_test();
69 write(1,"ok $test\nnot ok $test\n", 5);
70
71 SKIP: {
72     skip("no pipe() support on DOS", 2) if $Is_Dos;
73
74     @fds = POSIX::pipe();
75     cmp_ok($fds[0], '>', $testfd, 'POSIX::pipe');
76
77     CORE::open(my $reader, "<&=".$fds[0]);
78     CORE::open(my $writer, ">&=".$fds[1]);
79     my $test = next_test();
80     print $writer "ok $test\n";
81     close $writer;
82     print <$reader>;
83     close $reader;
84 }
85
86 SKIP: {
87     skip("no sigaction support on win32/dos", 6) if $Is_W32 || $Is_Dos;
88
89     my $sigset = new POSIX::SigSet 1, 3;
90     $sigset->delset(1);
91     ok(! $sigset->ismember(1),  'POSIX::SigSet->delset' );
92     ok(  $sigset->ismember(3),  'POSIX::SigSet->ismember' );
93
94     my $sigint_called = 0;
95
96     my $mask   = new POSIX::SigSet &SIGINT;
97     my $action = new POSIX::SigAction 'main::SigHUP', $mask, 0;
98     sigaction(&SIGHUP, $action);
99     $SIG{'INT'} = 'SigINT';
100
101     # At least OpenBSD/i386 3.3 is okay, as is NetBSD 1.5.
102     # But not NetBSD 1.6 & 1.6.1: the test makes perl crash.
103     # So the kill() must not be done with this config in order to
104     # finish the test.
105     # For others (darwin & freebsd), let the test fail without crashing.
106     # the test passes at least from freebsd 8.1
107     my $todo = $^O eq 'netbsd' && $Config{osvers}=~/^1\.6/;
108     my $why_todo = "# TODO $^O $Config{osvers} seems to lose blocked signals";
109     if (!$todo) {
110       kill 'HUP', $$;
111     } else {
112       print "not ok 9 - sigaction SIGHUP ",$why_todo,"\n";
113       print "not ok 10 - sig mask delayed SIGINT ",$why_todo,"\n";
114     }
115     sleep 1;
116
117     $todo = 1 if ($^O eq 'freebsd' && $Config{osvers} < 8)
118               || ($^O eq 'darwin' && $Config{osvers} < '6.6');
119     printf "%s 11 - masked SIGINT received %s\n",
120         $sigint_called ? "ok" : "not ok",
121         $todo ? $why_todo : '';
122
123     print "ok 12 - signal masks successful\n";
124
125     sub SigHUP {
126         print "ok 9 - sigaction SIGHUP\n";
127         kill 'INT', $$;
128         sleep 2;
129         print "ok 10 - sig mask delayed SIGINT\n";
130     }
131
132     sub SigINT {
133         $sigint_called++;
134     }
135
136     # The order of the above tests is very important, so
137     # we use literal prints and hard coded numbers.
138     next_test() for 1..4;
139 }
140
141 SKIP: {
142     skip("_POSIX_OPEN_MAX undefined ($fds[1])",  1) unless &_POSIX_OPEN_MAX;
143
144     cmp_ok(&_POSIX_OPEN_MAX, '>=', 16,
145            "The minimum allowed values according to susv2" );
146
147 }
148
149 my $pat;
150 if ( $unix_mode ) {
151     $pat = qr#[\\/]POSIX$#i;
152 }
153 else {
154     $pat = qr/\.POSIX\]/i;
155 }
156 like( getcwd(), qr/$pat/, 'getcwd' );
157
158 # Check string conversion functions.
159 my $weasel_words = "(though differences may be beyond the displayed digits)";
160
161 SKIP: { 
162     skip("strtod() not present", 3) unless $Config{d_strtod};
163
164     if (locales_enabled('LC_NUMERIC')) {
165         $lc = &POSIX::setlocale(&POSIX::LC_NUMERIC);
166         &POSIX::setlocale(&POSIX::LC_NUMERIC, 'C');
167     }
168
169     # we're just checking that strtod works, not how accurate it is
170     ($n, $x) = &POSIX::strtod('3.14159_OR_SO');
171     cmp_ok(abs("3.14159" - $n), '<', 1e-6, 'strtod works');
172     is($x, 6, 'strtod works');
173
174     # If $Config{nvtype} is 'double' we check that strtod assigns the same value as
175     # perl for the input 8.87359152e-6.
176     # We check that value as it is known to have produced discrepancies in the past.
177     # If this check fails then perl's buggy atof has probably assigned the value,
178     # instead of the preferred Perl_strtod function.
179
180     $n = &POSIX::strtod('8.87359152e-6');
181     if($Config{nvtype} eq 'double' || ($Config{nvtype} eq 'long double' && $Config{longdblkind} == 0)) {
182       cmp_ok($n, '==', 8.87359152e-6, "strtod and perl agree $weasel_words");
183     }
184     else {
185       cmp_ok($n, '!=', 8.87359152e-6, "strtod and perl should differ $weasel_words");
186     }
187
188     &POSIX::setlocale(&POSIX::LC_NUMERIC, $lc) if locales_enabled('LC_NUMERIC');
189 }
190
191 SKIP: {
192     skip("strtold() not present", 3) unless $Config{d_strtold};
193
194     if (locales_enabled('LC_NUMERIC')) {
195         $lc = &POSIX::setlocale(&POSIX::LC_NUMERIC);
196         &POSIX::setlocale(&POSIX::LC_NUMERIC, 'C');
197     }
198
199     # we're just checking that strtold works, not how accurate it is
200     ($n, $x) = &POSIX::strtold('2.718_ISH');
201     cmp_ok(abs("2.718" - $n), '<', 1e-6, 'strtold works');
202     is($x, 4, 'strtold works');
203
204     # If $Config{nvtype} is 'long double' we check that strtold assigns the same value as
205     # perl for the input 9.81256119e4.
206     # We check that value as it is known to have produced discrepancies in the past.
207     # If this check fails then perl's buggy atof has probably assigned the value,
208     # instead of the preferred Perl_strtod function.
209
210     if($Config{nvtype} eq 'long double') {
211       $n = &POSIX::strtold('9.81256119e4820');
212       cmp_ok($n, '==', 9.81256119e4820, "strtold and perl agree $weasel_words");
213     }
214     elsif($Config{nvtype} eq '__float128') {
215       $n = &POSIX::strtold('9.81256119e4820');
216       if($Config{longdblkind} == 1 || $Config{longdblkind} == 2) {
217         cmp_ok($n, '==', 9.81256119e4820, "strtold and perl agree $weasel_words");
218       }
219       else {
220         cmp_ok($n, '!=', 9.81256119e4820, "strtold and perl should differ $weasel_words");
221       }
222     }
223     else { # nvtype is double ... don't try and make this into a meaningful test
224       cmp_ok(1, '==', 1, 'skipping comparison between strtold amd perl');
225     }
226
227     &POSIX::setlocale(&POSIX::LC_NUMERIC, $lc) if locales_enabled('LC_NUMERIC');
228 }
229
230 SKIP: {
231     # We don't yet have a POSIX::strtoflt128 - but let's at least check that
232     # Perl_strtod, not perl's atof, is assigning the values on quadmath builds.
233     # Do this by checking that 3329232e296 (which is known to be assigned
234     # incorrectly by perl's atof) is assigned to its correct value.
235
236     skip("not a -Dusequadmath build", 1) unless $Config{nvtype} eq '__float128';
237     cmp_ok(scalar(reverse(unpack("h*", pack("F<", 3329232e296)))),
238            'eq','43ebf120d02ce967d48e180409b3f958',
239            '3329232e296 is assigned correctly');
240 }
241
242 SKIP: {
243     skip("strtol() not present", 2) unless $Config{d_strtol};
244
245     ($n, $x) = &POSIX::strtol('21_PENGUINS');
246     is($n, 21, 'strtol() number');
247     is($x, 9,  '         unparsed chars');
248 }
249
250 SKIP: {
251     skip("strtoul() not present", 2) unless $Config{d_strtoul};
252
253     ($n, $x) = &POSIX::strtoul('88_TEARS');
254     is($n, 88, 'strtoul() number');
255     is($x, 6,  '          unparsed chars');
256 }
257
258 # Pick up whether we're really able to dynamically load everything.
259 cmp_ok(&POSIX::acos(1.0), '==', 0.0, 'dynamic loading');
260
261 # This can coredump if struct tm has a timezone field and we
262 # didn't detect it.  If this fails, try adding
263 # -DSTRUCT_TM_HASZONE to your cflags when compiling ext/POSIX/POSIX.c.
264 # See ext/POSIX/hints/sunos_4.pl and ext/POSIX/hints/linux.pl 
265 $test = next_test();
266 print POSIX::strftime("ok $test # %H:%M, on %m/%d/%y\n", localtime());
267
268 # If that worked, validate the mini_mktime() routine's normalisation of
269 # input fields to strftime().
270 sub try_strftime {
271     my $expect = shift;
272     my $got = POSIX::strftime("%a %b %d %H:%M:%S %Y %j", @_);
273     is($got, $expect, "validating mini_mktime() and strftime(): $expect");
274 }
275
276 if (locales_enabled('LC_TIME')) {
277     $lc = &POSIX::setlocale(&POSIX::LC_TIME);
278     &POSIX::setlocale(&POSIX::LC_TIME, 'C');
279 }
280
281 try_strftime("Wed Feb 28 00:00:00 1996 059", 0,0,0, 28,1,96);
282 SKIP: {
283     skip("VC++ 8 and Vista's CRTs regard 60 seconds as an invalid parameter", 1)
284         if ($Is_W32
285             and (($Config{cc} eq 'cl' and
286                     $Config{ccversion} =~ /^(\d+)/ and $1 >= 14)
287                 or ($Config{cc} eq 'icl' and
288                     `cl --version 2>&1` =~ /^.*Version\s+([\d.]+)/ and $1 >= 14)
289                 or (Win32::GetOSVersion())[1] >= 6));
290
291     try_strftime("Thu Feb 29 00:00:60 1996 060", 60,0,-24, 30,1,96);
292 }
293 try_strftime("Fri Mar 01 00:00:00 1996 061", 0,0,-24, 31,1,96);
294 try_strftime("Sun Feb 28 00:00:00 1999 059", 0,0,0, 28,1,99);
295 try_strftime("Mon Mar 01 00:00:00 1999 060", 0,0,24, 28,1,99);
296 try_strftime("Mon Feb 28 00:00:00 2000 059", 0,0,0, 28,1,100);
297 try_strftime("Tue Feb 29 00:00:00 2000 060", 0,0,0, 0,2,100);
298 try_strftime("Wed Mar 01 00:00:00 2000 061", 0,0,0, 1,2,100);
299 try_strftime("Fri Mar 31 00:00:00 2000 091", 0,0,0, 31,2,100);
300
301 { # rt 72232
302
303   # Std C/POSIX allows day/month to be negative and requires that
304   # wday/yday be adjusted as needed
305   # previously mini_mktime() would allow yday to dominate if mday and
306   # month were both non-positive
307   # check that yday doesn't dominate
308   try_strftime("Thu Dec 30 00:00:00 1999 364", 0,0,0, -1,0,100);
309   try_strftime("Thu Dec 30 00:00:00 1999 364", 0,0,0, -1,0,100,-1,10);
310   # it would also allow a positive wday to override the calculated value
311   # check that wday is recalculated too
312   try_strftime("Thu Dec 30 00:00:00 1999 364", 0,0,0, -1,0,100,0,10);
313 }
314
315 &POSIX::setlocale(&POSIX::LC_TIME, $lc) if locales_enabled('LC_TIME');
316
317 {
318     for my $test (0, 1) {
319         $! = 0;
320         # POSIX::errno is autoloaded. 
321         # Autoloading requires many system calls.
322         # errno() looks at $! to generate its result.
323         # Autoloading should not munge the value.
324         my $foo  = $!;
325         my $errno = POSIX::errno();
326
327         # Force numeric context.
328         is( $errno + 0, $foo + 0,     'autoloading and errno() mix' );
329     }
330 }
331
332 is (eval "kill 0", 0, "check we have CORE::kill")
333   or print "\$\@ is " . _qq($@) . "\n";
334
335 # Check that we can import the POSIX kill routine
336 POSIX->import ('kill');
337 my $result = eval "kill 0";
338 is ($result, undef, "we should now have POSIX::kill");
339 # Check usage.
340 like ($@, qr/^Usage: POSIX::kill\(pid, sig\)/, "check its usage message");
341
342 # Check unimplemented.
343 $result = eval {POSIX::offsetof};
344 is ($result, undef, "offsetof should fail");
345 like ($@, qr/^Unimplemented: POSIX::offsetof\(\): C-specific/,
346       "check its unimplemented message");
347
348 # Check reimplemented.
349 $result = eval {POSIX::fgets};
350 is ($result, undef, "fgets should fail");
351 like ($@, qr/^Unimplemented: POSIX::fgets\(\): Use method IO::Handle::gets\(\) instead/,
352       "check its redef message");
353
354 eval { use strict; POSIX->import("S_ISBLK"); my $x = S_ISBLK };
355 unlike( $@, qr/Can't use string .* as a symbol ref/, "Can import autoloaded constants" );
356
357 SKIP: {
358     skip("locales not available", 26) unless locales_enabled([ qw(NUMERIC MONETARY) ]);
359     skip("localeconv() not available", 26) unless $Config{d_locconv};
360     my $conv = localeconv;
361     is(ref $conv, 'HASH', 'localeconv returns a hash reference');
362
363     foreach (qw(decimal_point thousands_sep grouping int_curr_symbol
364                 currency_symbol mon_decimal_point mon_thousands_sep
365                 mon_grouping positive_sign negative_sign)) {
366     SKIP: {
367             skip("localeconv has no result for $_", 1)
368                 unless exists $conv->{$_};
369             unlike(delete $conv->{$_}, qr/\A\z/,
370                    "localeconv returned a non-empty string for $_");
371         }
372     }
373
374     my @lconv = qw(
375         int_frac_digits frac_digits
376         p_cs_precedes   p_sep_by_space
377         n_cs_precedes   n_sep_by_space
378         p_sign_posn     n_sign_posn
379     );
380
381     SKIP: {
382         skip('No HAS_LC_MONETARY_2008', 6) unless $Config{d_lc_monetary_2008};
383
384         push @lconv, qw(
385             int_p_cs_precedes int_p_sep_by_space
386             int_n_cs_precedes int_n_sep_by_space
387             int_p_sign_posn   int_n_sign_posn
388         );
389     }
390
391     foreach (@lconv) {
392     SKIP: {
393             skip("localeconv has no result for $_", 1)
394                 unless exists $conv->{$_};
395             like(delete $conv->{$_}, qr/\A-?\d+\z/,
396                  "localeconv returned an integer for $_");
397         }
398     }
399     is_deeply([%$conv], [], 'no unexpected keys returned by localeconv');
400 }
401
402 my $fd1 = open("Makefile.PL", O_RDONLY, 0);
403 like($fd1, qr/\A\d+\z/, 'O_RDONLY with open');
404 cmp_ok($fd1, '>', $testfd);
405 my $fd2 = dup($fd1);
406 like($fd2, qr/\A\d+\z/, 'dup');
407 cmp_ok($fd2, '>', $fd1);
408 is(POSIX::close($fd1), '0 but true', 'close');
409 is(POSIX::close($testfd), '0 but true', 'close');
410 $! = 0;
411 undef $buffer;
412 is(read($fd1, $buffer, 4), undef, 'read on closed file handle fails');
413 cmp_ok($!, '==', POSIX::EBADF);
414 undef $buffer;
415 read($fd2, $buffer, 4) if $fd2 > 2;
416 is($buffer, "# Ex", 'read');
417 # The descriptor $testfd was using is now free, and is lower than that which
418 # $fd1 was using. Hence if dup2() behaves as dup(), we'll know :-)
419 {
420     $testfd = dup2($fd2, $fd1);
421     is($testfd, $fd1, 'dup2');
422     undef $buffer;
423     read($testfd, $buffer, 4) if $testfd > 2;
424     is($buffer, 'pect', 'read');
425     is(lseek($testfd, 0, 0), 0, 'lseek back');
426     # The two should share file position:
427     undef $buffer;
428     read($fd2, $buffer, 4) if $fd2 > 2;
429     is($buffer, "# Ex", 'read');
430 }
431
432 # The FreeBSD man page warns:
433 # The access() system call is a potential security hole due to race
434 # conditions and should never be used.
435 is(access('Makefile.PL', POSIX::F_OK), '0 but true', 'access');
436 is(access('Makefile.PL', POSIX::R_OK), '0 but true', 'access');
437 $! = 0;
438 is(access('no such file', POSIX::F_OK), undef, 'access on missing file');
439 cmp_ok($!, '==', POSIX::ENOENT);
440 is(access('Makefile.PL/nonsense', POSIX::F_OK), undef,
441    'access on not-a-directory');
442 SKIP: {
443     skip("$^O is insufficiently POSIX", 1)
444         if $Is_W32 || $Is_VMS;
445     cmp_ok($!, '==', POSIX::ENOTDIR);
446 }
447
448 {   # tmpnam() has been removed as unsafe
449     my $x = eval { POSIX::tmpnam() };
450     is($x, undef, 'tmpnam has been removed');
451     like($@, qr/use File::Temp/, 'tmpnam advises File::Temp');
452 }
453
454 # Check that output is not flushed by _exit. This test should be last
455 # in the file, and is not counted in the total number of tests.
456 if ($^O eq 'vos') {
457  print "# TODO - hit VOS bug posix-885 - _exit flushes output buffers.\n";
458 } else {
459  $| = 0;
460  # The following line assumes buffered output, which may be not true:
461  print '@#!*$@(!@#$' unless ($Is_OS2 || $Is_UWin || $Is_OS390 ||
462                             $Is_VMS ||
463                             (defined $ENV{PERLIO} &&
464                              $ENV{PERLIO} eq 'unix' &&
465                              $Config::Config{useperlio}));
466  _exit(0);
467 }