This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
utf8_heavy: Use new mktables caseless feature
[perl5.git] / lib / utf8_heavy.pl
1 package utf8;
2 use strict;
3 use warnings;
4
5 sub DEBUG () { 0 }
6
7 sub DESTROY {}
8
9 my %Cache;
10
11 sub croak { require Carp; Carp::croak(@_) }
12
13 ##
14 ## "SWASH" == "SWATCH HASH". A "swatch" is a swatch of the Unicode landscape.
15 ## It's a data structure that encodes a set of Unicode characters.
16 ##
17
18 {
19     # If a floating point number is within this distance from the value of a
20     # fraction, it is considered to be that fraction, even if many more digits
21     # are specified that don't exactly match.
22     my $min_floating_slop;
23
24     # To guard against this program calling something that in turn ends up
25     # calling this program with the same inputs, and hence infinitely
26     # recursing, we keep a stack of the properties that are currently in
27     # progress, pushed upon entry, popped upon return.
28     my @recursed;
29
30     sub SWASHNEW {
31         my ($class, $type, $list, $minbits, $none) = @_;
32         local $^D = 0 if $^D;
33
34         $class = "" unless defined $class;
35         print STDERR __LINE__, ": class=$class, type=$type, list=$list, minbits=$minbits, none=$none\n" if DEBUG;
36
37         ##
38         ## Get the list of codepoints for the type.
39         ## Called from swash_init (see utf8.c) or SWASHNEW itself.
40         ##
41         ## Callers of swash_init:
42         ##     op.c:pmtrans             -- for tr/// and y///
43         ##     regexec.c:regclass_swash -- for /[]/, \p, and \P
44         ##     utf8.c:is_utf8_common    -- for common Unicode properties
45         ##     utf8.c:to_utf8_case      -- for lc, uc, ucfirst, etc. and //i
46         ##
47         ## Given a $type, our goal is to fill $list with the set of codepoint
48         ## ranges. If $type is false, $list passed is used.
49         ##
50         ## $minbits:
51         ##     For binary properties, $minbits must be 1.
52         ##     For character mappings (case and transliteration), $minbits must
53         ##     be a number except 1.
54         ##
55         ## $list (or that filled according to $type):
56         ##     Refer to perlunicode.pod, "User-Defined Character Properties."
57         ##     
58         ##     For binary properties, only characters with the property value
59         ##     of True should be listed. The 3rd column, if any, will be ignored
60         ##
61         ## $none is undocumented, so I'm (khw) trying to do some documentation
62         ## of it now.  It appears to be if there is a mapping in an input file
63         ## that maps to 'XXXX', then that is replaced by $none+1, expressed in
64         ## hexadecimal.  The only place I found it possibly used was in
65         ## S_pmtrans in op.c.
66         ##
67         ## To make the parsing of $type clear, this code takes the a rather
68         ## unorthodox approach of last'ing out of the block once we have the
69         ## info we need. Were this to be a subroutine, the 'last' would just
70         ## be a 'return'.
71         ##
72         my $file; ## file to load data from, and also part of the %Cache key.
73         my $ListSorted = 0;
74
75         # Change this to get a different set of Unicode tables
76         my $unicore_dir = 'unicore';
77
78         if ($type)
79         {
80
81             # Verify that this isn't a recursive call for this property.
82             # Can't use croak, as it may try to recurse here itself.
83             my $class_type = $class . "::$type";
84             if (grep { $_ eq $class_type } @recursed) {
85                 CORE::die "panic: Infinite recursion in SWASHNEW for '$type'\n";
86             }
87             push @recursed, $class_type;
88
89             $type =~ s/^\s+//;
90             $type =~ s/\s+$//;
91
92             # regcomp.c surrounds the property name with '__" and '_i' if this
93             # is to be caseless matching.
94             my $caseless = $type =~ s/^__(.*)_i$/$1/;
95
96             print STDERR __LINE__, ": type=$type, caseless=$caseless\n" if DEBUG;
97
98         GETFILE:
99             {
100                 ##
101                 ## It could be a user-defined property.  Look in current
102                 ## package if no package given
103                 ##
104
105                 my $caller1 = $type =~ s/(.+)::// ? $1 : caller(1);
106
107                 if (defined $caller1 && $type =~ /^I[ns]\w+$/) {
108                     my $prop = "${caller1}::$type";
109                     if (exists &{$prop}) {
110                         no strict 'refs';
111                         
112                         $list = &{$prop}($caseless);
113                         last GETFILE;
114                     }
115                 }
116
117                 # During Perl's compilation, this routine may be called before
118                 # the tables are constructed.  If so, we have a chicken/egg
119                 # problem.  If we die, the tables never get constructed, so
120                 # keep going, but return an empty table so only what the code
121                 # has compiled in internally (currently ASCII/Latin1 range
122                 # matching) will work.
123                 BEGIN {
124                     # Poor man's constant, to avoid a run-time check.
125                     $utf8::{miniperl}
126                         = \! defined &DynaLoader::boot_DynaLoader;
127                 }
128                 if (miniperl) {
129                     eval "require '$unicore_dir/Heavy.pl'";
130                     last GETFILE if $@;
131                 }
132                 else {
133                     require "$unicore_dir/Heavy.pl";
134                 }
135                 BEGIN { delete $utf8::{miniperl} }
136
137                 # All property names are matched caselessly
138                 my $property_and_table = lc $type;
139                 print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
140
141                 # See if is of the compound form 'property=value', where the
142                 # value indicates the table we should use.
143                 my ($property, $table, @remainder) =
144                                     split /\s*[:=]\s*/, $property_and_table, -1;
145                 if (@remainder) {
146                     pop @recursed if @recursed;
147                     return $type;
148                 }
149
150                 my $prefix;
151                 if (! defined $table) {
152                         
153                     # Here, is the single form.  The property becomes empty, and
154                     # the whole value is the table.
155                     $table = $property;
156                     $prefix = $property = "";
157                 } else {
158                     print STDERR __LINE__, ": $property\n" if DEBUG;
159
160                     # Here it is the compound property=table form.  The property
161                     # name is always loosely matched, which means remove any of
162                     # these:
163                     $property =~ s/[_\s-]//g;
164
165                     # And convert to canonical form.  Quit if not valid.
166                     $property = $utf8::loose_property_name_of{$property};
167                     if (! defined $property) {
168                         pop @recursed if @recursed;
169                         return $type;
170                     }
171
172                     $prefix = "$property=";
173
174                     # If the rhs looks like it is a number...
175                     print STDERR __LINE__, ": table=$table\n" if DEBUG;
176                     if ($table =~ qr{ ^ [ \s 0-9 _  + / . -]+ $ }x) {
177                         print STDERR __LINE__, ": table=$table\n" if DEBUG;
178
179                         # Don't allow leading nor trailing slashes 
180                         if ($table =~ / ^ \/ | \/ $ /x) {
181                             pop @recursed if @recursed;
182                             return $type;
183                         }
184
185                         # Split on slash, in case it is a rational, like \p{1/5}
186                         my @parts = split qr{ \s* / \s* }x, $table, -1;
187                         print __LINE__, ": $type\n" if @parts > 2 && DEBUG;
188
189                         # Can have maximum of one slash
190                         if (@parts > 2) {
191                             pop @recursed if @recursed;
192                             return $type;
193                         }
194
195                         foreach my $part (@parts) {
196                             print __LINE__, ": part=$part\n" if DEBUG;
197
198                             $part =~ s/^\+\s*//;    # Remove leading plus
199                             $part =~ s/^-\s*/-/;    # Remove blanks after unary
200                                                     # minus
201
202                             # Remove underscores between digits.
203                             $part =~ s/( ?<= [0-9] ) _ (?= [0-9] ) //xg;
204
205                             # No leading zeros (but don't make a single '0'
206                             # into a null string)
207                             $part =~ s/ ^ ( -? ) 0+ /$1/x;
208                             $part .= '0' if $part eq '-' || $part eq "";
209
210                             # No trailing zeros after a decimal point
211                             $part =~ s/ ( \. .*? ) 0+ $ /$1/x;
212
213                             # Begin with a 0 if a leading decimal point
214                             $part =~ s/ ^ ( -? ) \. /${1}0./x;
215
216                             # Ensure not a trailing decimal point: turn into an
217                             # integer
218                             $part =~ s/ \. $ //x;
219
220                             print STDERR __LINE__, ": part=$part\n" if DEBUG;
221                             #return $type if $part eq "";
222                             
223                             # Result better look like a number.  (This test is
224                             # needed because, for example could have a plus in
225                             # the middle.)
226                             if ($part !~ / ^ -? [0-9]+ ( \. [0-9]+)? $ /x) {
227                                 pop @recursed if @recursed;
228                                 return $type;
229                             }
230                         }
231
232                         #  If a rational...
233                         if (@parts == 2) {
234
235                             # If denominator is negative, get rid of it, and ...
236                             if ($parts[1] =~ s/^-//) {
237
238                                 # If numerator is also negative, convert the
239                                 # whole thing to positive, or move the minus to
240                                 # the numerator
241                                 if ($parts[0] !~ s/^-//) {
242                                     $parts[0] = '-' . $parts[0];
243                                 }
244                             }
245                             $table = join '/', @parts;
246                         }
247                         elsif ($property ne 'nv' || $parts[0] !~ /\./) {
248
249                             # Here is not numeric value, or doesn't have a
250                             # decimal point.  No further manipulation is
251                             # necessary.  (Note the hard-coded property name.
252                             # This could fail if other properties eventually
253                             # had fractions as well; perhaps the cjk ones
254                             # could evolve to do that.  This hard-coding could
255                             # be fixed by mktables generating a list of
256                             # properties that could have fractions.)
257                             $table = $parts[0];
258                         } else {
259
260                             # Here is a floating point numeric_value.  Try to
261                             # convert to rational.  First see if is in the list
262                             # of known ones.
263                             if (exists $utf8::nv_floating_to_rational{$parts[0]}) {
264                                 $table = $utf8::nv_floating_to_rational{$parts[0]};
265                             } else {
266
267                                 # Here not in the list.  See if is close
268                                 # enough to something in the list.  First
269                                 # determine what 'close enough' means.  It has
270                                 # to be as tight as what mktables says is the
271                                 # maximum slop, and as tight as how many
272                                 # digits we were passed.  That is, if the user
273                                 # said .667, .6667, .66667, etc.  we match as
274                                 # many digits as they passed until get to
275                                 # where it doesn't matter any more due to the
276                                 # machine's precision.  If they said .6666668,
277                                 # we fail.
278                                 (my $fraction = $parts[0]) =~ s/^.*\.//;
279                                 my $epsilon = 10 ** - (length($fraction));
280                                 if ($epsilon > $utf8::max_floating_slop) {
281                                     $epsilon = $utf8::max_floating_slop;
282                                 }
283
284                                 # But it can't be tighter than the minimum
285                                 # precision for this machine.  If haven't
286                                 # already calculated that minimum, do so now.
287                                 if (! defined $min_floating_slop) {
288
289                                     # Keep going down an order of magnitude
290                                     # until find that adding this quantity to
291                                     # 1 remains 1; but put an upper limit on
292                                     # this so in case this algorithm doesn't
293                                     # work properly on some platform, that we
294                                     # won't loop forever.
295                                     my $count = 0;
296                                     $min_floating_slop = 1;
297                                     while (1+ $min_floating_slop != 1
298                                            && $count++ < 50)
299                                     {
300                                         my $next = $min_floating_slop / 10;
301                                         last if $next == 0; # If underflows,
302                                                             # use previous one
303                                         $min_floating_slop = $next;
304                                         print STDERR __LINE__, ": min_float_slop=$min_floating_slop\n" if DEBUG;
305                                     }
306
307                                     # Back off a couple orders of magnitude,
308                                     # just to be safe.
309                                     $min_floating_slop *= 100;
310                                 }
311                                     
312                                 if ($epsilon < $min_floating_slop) {
313                                     $epsilon = $min_floating_slop;
314                                 }
315                                 print STDERR __LINE__, ": fraction=.$fraction; epsilon=$epsilon\n" if DEBUG;
316
317                                 undef $table;
318
319                                 # And for each possible rational in the table,
320                                 # see if it is within epsilon of the input.
321                                 foreach my $official
322                                         (keys %utf8::nv_floating_to_rational)
323                                 {
324                                     print STDERR __LINE__, ": epsilon=$epsilon, official=$official, diff=", abs($parts[0] - $official), "\n" if DEBUG;
325                                     if (abs($parts[0] - $official) < $epsilon) {
326                                       $table =
327                                       $utf8::nv_floating_to_rational{$official};
328                                         last;
329                                     }
330                                 }
331
332                                 # Quit if didn't find one.
333                                 if (! defined $table) {
334                                     pop @recursed if @recursed;
335                                     return $type;
336                                 }
337                             }
338                         }
339                         print STDERR __LINE__, ": $property=$table\n" if DEBUG;
340                     }
341                 }
342
343                 # Combine lhs (if any) and rhs to get something that matches
344                 # the syntax of the lookups.
345                 $property_and_table = "$prefix$table";
346                 print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
347
348                 # First try stricter matching.
349                 $file = $utf8::stricter_to_file_of{$property_and_table};
350
351                 # If didn't find it, try again with looser matching by editing
352                 # out the applicable characters on the rhs and looking up
353                 # again.
354                 if (! defined $file) {
355                     $table =~ s/ [_\s-] //xg;
356                     $property_and_table = "$prefix$table";
357                     print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
358                     $file = $utf8::loose_to_file_of{$property_and_table};
359                 }
360
361                 # Add the constant and go fetch it in.
362                 if (defined $file) {
363                     if ($utf8::why_deprecated{$file}) {
364                         warnings::warnif('deprecated', "Use of '$type' in \\p{} or \\P{} is deprecated because: $utf8::why_deprecated{$file};");
365                     }
366
367                     if ($caseless
368                         && exists $utf8::caseless_equivalent{$property_and_table})
369                     {
370                         $file = $utf8::caseless_equivalent{$property_and_table};
371                     }
372                     $file= "$unicore_dir/lib/$file.pl";
373                     last GETFILE;
374                 }
375                 print STDERR __LINE__, ": didn't find $property_and_table\n" if DEBUG;
376
377                 ##
378                 ## See if it's a user-level "To".
379                 ##
380
381                 my $caller0 = caller(0);
382
383                 if (defined $caller0 && $type =~ /^To(?:\w+)$/) {
384                     my $map = $caller0 . "::" . $type;
385
386                     if (exists &{$map}) {
387                         no strict 'refs';
388                         
389                         $list = &{$map};
390                         last GETFILE;
391                     }
392                 }
393
394                 ##
395                 ## Last attempt -- see if it's a standard "To" name
396                 ## (e.g. "ToLower")  ToTitle is used by ucfirst().
397                 ## The user-level way to access ToDigit() and ToFold()
398                 ## is to use Unicode::UCD.
399                 ##
400                 if ($type =~ /^To(Digit|Fold|Lower|Title|Upper)$/) {
401                     $file = "$unicore_dir/To/$1.pl";
402                     ## would like to test to see if $file actually exists....
403                     last GETFILE;
404                 }
405
406                 ##
407                 ## If we reach this line, it's because we couldn't figure
408                 ## out what to do with $type. Ouch.
409                 ##
410
411                 pop @recursed if @recursed;
412                 return $type;
413             }
414
415             if (defined $file) {
416                 print STDERR __LINE__, ": found it (file='$file')\n" if DEBUG;
417
418                 ##
419                 ## If we reach here, it was due to a 'last GETFILE' above
420                 ## (exception: user-defined properties and mappings), so we
421                 ## have a filename, so now we load it if we haven't already.
422                 ## If we have, return the cached results. The cache key is the
423                 ## class and file to load.
424                 ##
425                 my $found = $Cache{$class, $file};
426                 if ($found and ref($found) eq $class) {
427                     print STDERR __LINE__, ": Returning cached '$file' for \\p{$type}\n" if DEBUG;
428                     pop @recursed if @recursed;
429                     return $found;
430                 }
431
432                 local $@;
433                 local $!;
434                 $list = do $file; die $@ if $@;
435             }
436
437             $ListSorted = 1; ## we know that these lists are sorted
438         }
439
440         my $extras;
441         my $bits = $minbits;
442
443         if ($list) {
444             my @tmp = split(/^/m, $list);
445             my %seen;
446             no warnings;
447             $extras = join '', grep /^[^0-9a-fA-F]/, @tmp;
448             $list = join '',
449                 map  { $_->[1] }
450                 sort { $a->[0] <=> $b->[0] }
451                 map  { /^([0-9a-fA-F]+)/; [ CORE::hex($1), $_ ] }
452                 grep { /^([0-9a-fA-F]+)/ and not $seen{$1}++ } @tmp; # XXX doesn't do ranges right
453         }
454
455         if ($none) {
456             my $hextra = sprintf "%04x", $none + 1;
457             $list =~ s/\tXXXX$/\t$hextra/mg;
458         }
459
460         if ($minbits != 1 && $minbits < 32) { # not binary property
461             my $top = 0;
462             while ($list =~ /^([0-9a-fA-F]+)(?:[\t]([0-9a-fA-F]+)?)(?:[ \t]([0-9a-fA-F]+))?/mg) {
463                 my $min = CORE::hex $1;
464                 my $max = defined $2 ? CORE::hex $2 : $min;
465                 my $val = defined $3 ? CORE::hex $3 : 0;
466                 $val += $max - $min if defined $3;
467                 $top = $val if $val > $top;
468             }
469             my $topbits =
470                 $top > 0xffff ? 32 :
471                 $top > 0xff ? 16 : 8;
472             $bits = $topbits if $bits < $topbits;
473         }
474
475         my @extras;
476         if ($extras) {
477             for my $x ($extras) {
478                 pos $x = 0;
479                 while ($x =~ /^([^0-9a-fA-F\n])(.*)/mg) {
480                     my $char = $1;
481                     my $name = $2;
482                     print STDERR __LINE__, ": $1 => $2\n" if DEBUG;
483                     if ($char =~ /[-+!&]/) {
484                         my ($c,$t) = split(/::/, $name, 2);     # bogus use of ::, really
485                         my $subobj;
486                         if ($c eq 'utf8') {
487                             $subobj = utf8->SWASHNEW($t, "", $minbits, 0);
488                         }
489                         elsif (exists &$name) {
490                             $subobj = utf8->SWASHNEW($name, "", $minbits, 0);
491                         }
492                         elsif ($c =~ /^([0-9a-fA-F]+)/) {
493                             $subobj = utf8->SWASHNEW("", $c, $minbits, 0);
494                         }
495                         if (! ref $subobj) {
496                             pop @recursed if @recursed && $type;
497                             return $subobj;
498                         }
499                         push @extras, $name => $subobj;
500                         $bits = $subobj->{BITS} if $bits < $subobj->{BITS};
501                     }
502                 }
503             }
504         }
505
506         if (DEBUG) {
507             print STDERR __LINE__, ": CLASS = $class, TYPE => $type, BITS => $bits, NONE => $none";
508             print STDERR "\nLIST =>\n$list" if defined $list;
509             print STDERR "\nEXTRAS =>\n$extras" if defined $extras;
510             print STDERR "\n";
511         }
512
513         my $SWASH = bless {
514             TYPE => $type,
515             BITS => $bits,
516             EXTRAS => $extras,
517             LIST => $list,
518             NONE => $none,
519             @extras,
520         } => $class;
521
522         if ($file) {
523             $Cache{$class, $file} = $SWASH;
524         }
525
526         pop @recursed if @recursed && $type;
527
528         return $SWASH;
529     }
530 }
531
532 # Now SWASHGET is recasted into a C function S_swash_get (see utf8.c).
533
534 1;