This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
4eac093b0e029c31999c33ca5c6e91a70e995edf
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar and list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one list argument.)  For instance, splice() has three scalar
19 arguments followed by a list.
20
21 In the syntax descriptions that follow, list operators that expect a
22 list (and provide list context for the elements of the list) are shown
23 with LIST as an argument.  Such a list may consist of any combination
24 of scalar arguments or list values; the list values will be included
25 in the list as if each individual element were interpolated at that
26 point in the list, forming a longer single-dimensional list value.
27 Elements of the LIST should be separated by commas.
28
29 Any function in the list below may be used either with or without
30 parentheses around its arguments.  (The syntax descriptions omit the
31 parentheses.)  If you use the parentheses, the simple (but occasionally
32 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
33 function, and precedence doesn't matter.  Otherwise it's a list
34 operator or unary operator, and precedence does matter.  And whitespace
35 between the function and left parenthesis doesn't count--so you need to
36 be careful sometimes:
37
38     print 1+2+4;        # Prints 7.
39     print(1+2) + 4;     # Prints 3.
40     print (1+2)+4;      # Also prints 3!
41     print +(1+2)+4;     # Prints 7.
42     print ((1+2)+4);    # Prints 7.
43
44 If you run Perl with the B<-w> switch it can warn you about this.  For
45 example, the third line above produces:
46
47     print (...) interpreted as function at - line 1.
48     Useless use of integer addition in void context at - line 1.
49
50 For functions that can be used in either a scalar or list context,
51 nonabortive failure is generally indicated in a scalar context by
52 returning the undefined value, and in a list context by returning the
53 null list.
54
55 Remember the following important rule: There is B<no rule> that relates
56 the behavior of an expression in list context to its behavior in scalar
57 context, or vice versa.  It might do two totally different things.
58 Each operator and function decides which sort of value it would be most
59 appropriate to return in a scalar context.  Some operators return the
60 length of the list that would have been returned in list context.  Some
61 operators return the first value in the list.  Some operators return the
62 last value in the list.  Some operators return a count of successful
63 operations.  In general, they do what you want, unless you want
64 consistency.
65
66 An named array in scalar context is quite different from what would at
67 first glance appear to be a list in scalar context.  You can't get a list
68 like C<(1,2,3)> into being in scalar context, because the compiler knows
69 the context at compile time.  It would generate the scalar comma operator
70 there, not the list construction version of the comma.  That means it
71 was never a list to start with.
72
73 In general, functions in Perl that serve as wrappers for system calls
74 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
75 true when they succeed and C<undef> otherwise, as is usually mentioned
76 in the descriptions below.  This is different from the C interfaces,
77 which return C<-1> on failure.  Exceptions to this rule are C<wait()>,
78 C<waitpid()>, and C<syscall()>.  System calls also set the special C<$!>
79 variable on failure.  Other functions do not, except accidentally.
80
81 =head2 Perl Functions by Category
82
83 Here are Perl's functions (including things that look like
84 functions, like some keywords and named operators)
85 arranged by category.  Some functions appear in more
86 than one place.
87
88 =over
89
90 =item Functions for SCALARs or strings
91
92 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
93 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
94 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
95
96 =item Regular expressions and pattern matching
97
98 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
99
100 =item Numeric functions
101
102 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
103 C<sin>, C<sqrt>, C<srand>
104
105 =item Functions for real @ARRAYs
106
107 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
108
109 =item Functions for list data
110
111 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
112
113 =item Functions for real %HASHes
114
115 C<delete>, C<each>, C<exists>, C<keys>, C<values>
116
117 =item Input and output functions
118
119 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
120 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
121 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
122 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
123 C<warn>, C<write>
124
125 =item Functions for fixed length data or records
126
127 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
128
129 =item Functions for filehandles, files, or directories
130
131 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
132 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>, C<readlink>,
133 C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>, C<unlink>, C<utime>
134
135 =item Keywords related to the control flow of your perl program
136
137 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
138 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
139
140 =item Keywords related to scoping
141
142 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
143
144 =item Miscellaneous functions
145
146 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
147 C<scalar>, C<undef>, C<wantarray>
148
149 =item Functions for processes and process groups
150
151 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
152 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
153 C<times>, C<wait>, C<waitpid>
154
155 =item Keywords related to perl modules
156
157 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
158
159 =item Keywords related to classes and object-orientedness
160
161 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
162 C<untie>, C<use>
163
164 =item Low-level socket functions
165
166 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
167 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
168 C<socket>, C<socketpair>
169
170 =item System V interprocess communication functions
171
172 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
173 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
174
175 =item Fetching user and group info
176
177 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
178 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
179 C<getpwuid>, C<setgrent>, C<setpwent>
180
181 =item Fetching network info
182
183 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
184 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
185 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
186 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
187 C<setnetent>, C<setprotoent>, C<setservent>
188
189 =item Time-related functions
190
191 C<gmtime>, C<localtime>, C<time>, C<times>
192
193 =item Functions new in perl5
194
195 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
196 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
197 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
198 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
199
200 * - C<sub> was a keyword in perl4, but in perl5 it is an
201 operator, which can be used in expressions.
202
203 =item Functions obsoleted in perl5
204
205 C<dbmclose>, C<dbmopen>
206
207 =back
208
209 =head2 Alphabetical Listing of Perl Functions
210
211 =over 8
212
213 =item I<-X> FILEHANDLE
214
215 =item I<-X> EXPR
216
217 =item I<-X>
218
219 A file test, where X is one of the letters listed below.  This unary
220 operator takes one argument, either a filename or a filehandle, and
221 tests the associated file to see if something is true about it.  If the
222 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
223 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
224 the undefined value if the file doesn't exist.  Despite the funny
225 names, precedence is the same as any other named unary operator, and
226 the argument may be parenthesized like any other unary operator.  The
227 operator may be any of:
228 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
229 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
230
231     -r  File is readable by effective uid/gid.
232     -w  File is writable by effective uid/gid.
233     -x  File is executable by effective uid/gid.
234     -o  File is owned by effective uid.
235
236     -R  File is readable by real uid/gid.
237     -W  File is writable by real uid/gid.
238     -X  File is executable by real uid/gid.
239     -O  File is owned by real uid.
240
241     -e  File exists.
242     -z  File has zero size.
243     -s  File has nonzero size (returns size).
244
245     -f  File is a plain file.
246     -d  File is a directory.
247     -l  File is a symbolic link.
248     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
249     -S  File is a socket.
250     -b  File is a block special file.
251     -c  File is a character special file.
252     -t  Filehandle is opened to a tty.
253
254     -u  File has setuid bit set.
255     -g  File has setgid bit set.
256     -k  File has sticky bit set.
257
258     -T  File is a text file.
259     -B  File is a binary file (opposite of -T).
260
261     -M  Age of file in days when script started.
262     -A  Same for access time.
263     -C  Same for inode change time.
264
265 The interpretation of the file permission operators C<-r>, C<-R>, C<-w>,
266 C<-W>, C<-x>, and C<-X> is based solely on the mode of the file and the
267 uids and gids of the user.  There may be other reasons you can't actually
268 read, write, or execute the file, such as AFS access control lists.  Also note that, for the superuser,
269 C<-r>, C<-R>, C<-w>, and C<-W> always return C<1>, and C<-x> and C<-X> return
270 C<1> if any execute bit is set in the mode.  Scripts run by the superuser may
271 thus need to do a C<stat()> to determine the actual mode of the
272 file, or temporarily set the uid to something else.
273
274 Example:
275
276     while (<>) {
277         chop;
278         next unless -f $_;      # ignore specials
279         #...
280     }
281
282 Note that C<-s/a/b/> does not do a negated substitution.  Saying
283 C<-exp($foo)> still works as expected, however--only single letters
284 following a minus are interpreted as file tests.
285
286 The C<-T> and C<-B> switches work as follows.  The first block or so of the
287 file is examined for odd characters such as strange control codes or
288 characters with the high bit set.  If too many strange characters (E<gt>30%)
289 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
290 containing null in the first block is considered a binary file.  If C<-T>
291 or C<-B> is used on a filehandle, the current stdio buffer is examined
292 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
293 file, or a file at EOF when testing a filehandle.  Because you have to
294 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
295 against the file first, as in C<next unless -f $file && -T $file>.
296
297 If any of the file tests (or either the C<stat()> or C<lstat()> operators) are given
298 the special filehandle consisting of a solitary underline, then the stat
299 structure of the previous file test (or stat operator) is used, saving
300 a system call.  (This doesn't work with C<-t>, and you need to remember
301 that lstat() and C<-l> will leave values in the stat structure for the
302 symbolic link, not the real file.)  Example:
303
304     print "Can do.\n" if -r $a || -w _ || -x _;
305
306     stat($filename);
307     print "Readable\n" if -r _;
308     print "Writable\n" if -w _;
309     print "Executable\n" if -x _;
310     print "Setuid\n" if -u _;
311     print "Setgid\n" if -g _;
312     print "Sticky\n" if -k _;
313     print "Text\n" if -T _;
314     print "Binary\n" if -B _;
315
316 =item abs VALUE
317
318 =item abs
319
320 Returns the absolute value of its argument.
321 If VALUE is omitted, uses C<$_>.
322
323 =item accept NEWSOCKET,GENERICSOCKET
324
325 Accepts an incoming socket connect, just as the accept(2) system call
326 does.  Returns the packed address if it succeeded, FALSE otherwise.
327 See example in L<perlipc/"Sockets: Client/Server Communication">.
328
329 =item alarm SECONDS
330
331 =item alarm
332
333 Arranges to have a SIGALRM delivered to this process after the
334 specified number of seconds have elapsed.  If SECONDS is not specified,
335 the value stored in C<$_> is used. (On some machines,
336 unfortunately, the elapsed time may be up to one second less than you
337 specified because of how seconds are counted.)  Only one timer may be
338 counting at once.  Each call disables the previous timer, and an
339 argument of C<0> may be supplied to cancel the previous timer without
340 starting a new one.  The returned value is the amount of time remaining
341 on the previous timer.
342
343 For delays of finer granularity than one second, you may use Perl's
344 C<syscall()> interface to access setitimer(2) if your system supports it,
345 or else see L</select()>.  It is usually a mistake to intermix C<alarm()>
346 and C<sleep()> calls.
347
348 If you want to use C<alarm()> to time out a system call you need to use an
349 C<eval()>/C<die()> pair.  You can't rely on the alarm causing the system call to
350 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
351 restart system calls on some systems.  Using C<eval()>/C<die()> always works,
352 modulo the caveats given in L<perlipc/"Signals">.
353
354     eval {
355         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
356         alarm $timeout;
357         $nread = sysread SOCKET, $buffer, $size;
358         alarm 0;
359     };
360     if ($@) {
361         die unless $@ eq "alarm\n";   # propagate unexpected errors
362         # timed out
363     }
364     else {
365         # didn't
366     }
367
368 =item atan2 Y,X
369
370 Returns the arctangent of Y/X in the range -PI to PI.
371
372 For the tangent operation, you may use the C<POSIX::tan()>
373 function, or use the familiar relation:
374
375     sub tan { sin($_[0]) / cos($_[0])  }
376
377 =item bind SOCKET,NAME
378
379 Binds a network address to a socket, just as the bind system call
380 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
381 packed address of the appropriate type for the socket.  See the examples in
382 L<perlipc/"Sockets: Client/Server Communication">.
383
384 =item binmode FILEHANDLE
385
386 Arranges for the file to be read or written in "binary" mode in operating
387 systems that distinguish between binary and text files.  Files that are
388 not in binary mode have CR LF sequences translated to LF on input and LF
389 translated to CR LF on output.  Binmode has no effect under Unix; in MS-DOS
390 and similarly archaic systems, it may be imperative--otherwise your
391 MS-DOS-damaged C library may mangle your file.  The key distinction between
392 systems that need C<binmode()> and those that don't is their text file
393 formats.  Systems like Unix, MacOS, and Plan9 that delimit lines with a single
394 character, and that encode that character in C as C<"\n">, do not need
395 C<binmode()>.  The rest need it.  If FILEHANDLE is an expression, the value
396 is taken as the name of the filehandle.
397
398 =item bless REF,CLASSNAME
399
400 =item bless REF
401
402 This function tells the thingy referenced by REF that it is now
403 an object in the CLASSNAME package--or the current package if no CLASSNAME
404 is specified, which is often the case.  It returns the reference for
405 convenience, because a C<bless()> is often the last thing in a constructor.
406 Always use the two-argument version if the function doing the blessing
407 might be inherited by a derived class.  See L<perltoot> and L<perlobj>
408 for more about the blessing (and blessings) of objects.
409
410 =item caller EXPR
411
412 =item caller
413
414 Returns the context of the current subroutine call.  In scalar context,
415 returns the caller's package name if there is a caller, that is, if
416 we're in a subroutine or C<eval()> or C<require()>, and the undefined value
417 otherwise.  In list context, returns
418
419     ($package, $filename, $line) = caller;
420
421 With EXPR, it returns some extra information that the debugger uses to
422 print a stack trace.  The value of EXPR indicates how many call frames
423 to go back before the current one.
424
425     ($package, $filename, $line, $subroutine,
426      $hasargs, $wantarray, $evaltext, $is_require) = caller($i);
427
428 Here C<$subroutine> may be C<"(eval)"> if the frame is not a subroutine
429 call, but an C<eval()>.  In such a case additional elements C<$evaltext> and
430 C<$is_require> are set: C<$is_require> is true if the frame is created by a
431 C<require> or C<use> statement, C<$evaltext> contains the text of the
432 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
433 C<$filename> is C<"(eval)">, but C<$evaltext> is undefined.  (Note also that
434 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
435 frame.
436
437 Furthermore, when called from within the DB package, caller returns more
438 detailed information: it sets the list variable C<@DB::args> to be the
439 arguments with which the subroutine was invoked.
440
441 Be aware that the optimizer might have optimized call frames away before
442 C<caller()> had a chance to get the information. That means that C<caller(N)>
443 might not return information about the call frame you expect it do, for
444 C<N E<gt> 1>. In particular, C<@DB::args> might have information from the 
445 previous time C<caller()> was called.
446
447 =item chdir EXPR
448
449 Changes the working directory to EXPR, if possible.  If EXPR is
450 omitted, changes to home directory.  Returns TRUE upon success, FALSE
451 otherwise.  See example under C<die()>.
452
453 =item chmod LIST
454
455 Changes the permissions of a list of files.  The first element of the
456 list must be the numerical mode, which should probably be an octal
457 number, and which definitely should I<not> a string of octal digits:
458 C<0644> is okay, C<'0644'> is not.  Returns the number of files
459 successfully changed.  See also L</oct>, if all you have is a string.
460
461     $cnt = chmod 0755, 'foo', 'bar';
462     chmod 0755, @executables;
463     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
464                                              # --w----r-T
465     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
466     $mode = 0644;   chmod $mode, 'foo';      # this is best
467
468 =item chomp VARIABLE
469
470 =item chomp LIST
471
472 =item chomp
473
474 This is a slightly safer version of L</chop>.  It removes any
475 line ending that corresponds to the current value of C<$/> (also known as
476 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
477 number of characters removed from all its arguments.  It's often used to
478 remove the newline from the end of an input record when you're worried
479 that the final record may be missing its newline.  When in paragraph mode
480 (C<$/ = "">), it removes all trailing newlines from the string.  If
481 VARIABLE is omitted, it chomps C<$_>.  Example:
482
483     while (<>) {
484         chomp;  # avoid \n on last field
485         @array = split(/:/);
486         # ...
487     }
488
489 You can actually chomp anything that's an lvalue, including an assignment:
490
491     chomp($cwd = `pwd`);
492     chomp($answer = <STDIN>);
493
494 If you chomp a list, each element is chomped, and the total number of
495 characters removed is returned.
496
497 =item chop VARIABLE
498
499 =item chop LIST
500
501 =item chop
502
503 Chops off the last character of a string and returns the character
504 chopped.  It's used primarily to remove the newline from the end of an
505 input record, but is much more efficient than C<s/\n//> because it neither
506 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
507 Example:
508
509     while (<>) {
510         chop;   # avoid \n on last field
511         @array = split(/:/);
512         #...
513     }
514
515 You can actually chop anything that's an lvalue, including an assignment:
516
517     chop($cwd = `pwd`);
518     chop($answer = <STDIN>);
519
520 If you chop a list, each element is chopped.  Only the value of the
521 last C<chop()> is returned.
522
523 Note that C<chop()> returns the last character.  To return all but the last
524 character, use C<substr($string, 0, -1)>.
525
526 =item chown LIST
527
528 Changes the owner (and group) of a list of files.  The first two
529 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
530 Returns the number of files successfully changed.
531
532     $cnt = chown $uid, $gid, 'foo', 'bar';
533     chown $uid, $gid, @filenames;
534
535 Here's an example that looks up nonnumeric uids in the passwd file:
536
537     print "User: ";
538     chop($user = <STDIN>);
539     print "Files: ";
540     chop($pattern = <STDIN>);
541
542     ($login,$pass,$uid,$gid) = getpwnam($user)
543         or die "$user not in passwd file";
544
545     @ary = glob($pattern);      # expand filenames
546     chown $uid, $gid, @ary;
547
548 On most systems, you are not allowed to change the ownership of the
549 file unless you're the superuser, although you should be able to change
550 the group to any of your secondary groups.  On insecure systems, these
551 restrictions may be relaxed, but this is not a portable assumption.
552
553 =item chr NUMBER
554
555 =item chr
556
557 Returns the character represented by that NUMBER in the character set.
558 For example, C<chr(65)> is C<"A"> in ASCII.  For the reverse, use L</ord>.
559
560 If NUMBER is omitted, uses C<$_>.
561
562 =item chroot FILENAME
563
564 =item chroot
565
566 This function works like the system call by the same name: it makes the
567 named directory the new root directory for all further pathnames that
568 begin with a C<"/"> by your process and all its children.  (It doesn't
569 change your current working directory, which is unaffected.)  For security
570 reasons, this call is restricted to the superuser.  If FILENAME is
571 omitted, does a C<chroot()> to C<$_>.
572
573 =item close FILEHANDLE
574
575 =item close
576
577 Closes the file or pipe associated with the file handle, returning TRUE
578 only if stdio successfully flushes buffers and closes the system file
579 descriptor. Closes the currently selected filehandle if the argument
580 is omitted.
581
582 You don't have to close FILEHANDLE if you are immediately going to do
583 another C<open()> on it, because C<open()> will close it for you.  (See
584 C<open()>.)  However, an explicit C<close()> on an input file resets the line
585 counter (C<$.>), while the implicit close done by C<open()> does not.
586
587 If the file handle came from a piped open C<close()> will additionally
588 return FALSE if one of the other system calls involved fails or if the
589 program exits with non-zero status.  (If the only problem was that the
590 program exited non-zero C<$!> will be set to C<0>.)  Also, closing a pipe 
591 waits for the process executing on the pipe to complete, in case you
592 want to look at the output of the pipe afterwards.  Closing a pipe
593 explicitly also puts the exit status value of the command into C<$?>.
594
595 Example:
596
597     open(OUTPUT, '|sort >foo')  # pipe to sort
598         or die "Can't start sort: $!";
599     #...                        # print stuff to output
600     close OUTPUT                # wait for sort to finish
601         or warn $! ? "Error closing sort pipe: $!"
602                    : "Exit status $? from sort";
603     open(INPUT, 'foo')          # get sort's results
604         or die "Can't open 'foo' for input: $!";
605
606 FILEHANDLE may be an expression whose value can be used as an indirect
607 filehandle, usually the real filehandle name.
608
609 =item closedir DIRHANDLE
610
611 Closes a directory opened by C<opendir()> and returns the success of that
612 system call.
613
614 DIRHANDLE may be an expression whose value can be used as an indirect
615 dirhandle, usually the real dirhandle name.
616
617 =item connect SOCKET,NAME
618
619 Attempts to connect to a remote socket, just as the connect system call
620 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
621 packed address of the appropriate type for the socket.  See the examples in
622 L<perlipc/"Sockets: Client/Server Communication">.
623
624 =item continue BLOCK
625
626 Actually a flow control statement rather than a function.  If there is a
627 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
628 C<foreach>), it is always executed just before the conditional is about to
629 be evaluated again, just like the third part of a C<for> loop in C.  Thus
630 it can be used to increment a loop variable, even when the loop has been
631 continued via the C<next> statement (which is similar to the C C<continue>
632 statement).
633
634 C<last>, C<next>, or C<redo> may appear within a C<continue>
635 block. C<last> and C<redo> will behave as if they had been executed within
636 the main block. So will C<next>, but since it will execute a C<continue>
637 block, it may be more entertaining.
638
639     while (EXPR) {
640         ### redo always comes here
641         do_something;
642     } continue {
643         ### next always comes here
644         do_something_else;
645         # then back the top to re-check EXPR
646     }
647     ### last always comes here
648
649 Omitting the C<continue> section is semantically equivalent to using an
650 empty one, logically enough. In that case, C<next> goes directly back
651 to check the condition at the top of the loop.
652
653 =item cos EXPR
654
655 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
656 takes cosine of C<$_>.
657
658 For the inverse cosine operation, you may use the C<POSIX::acos()>
659 function, or use this relation:
660
661     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
662
663 =item crypt PLAINTEXT,SALT
664
665 Encrypts a string exactly like the crypt(3) function in the C library
666 (assuming that you actually have a version there that has not been
667 extirpated as a potential munition).  This can prove useful for checking
668 the password file for lousy passwords, amongst other things.  Only the
669 guys wearing white hats should do this.
670
671 Note that C<crypt()> is intended to be a one-way function, much like breaking
672 eggs to make an omelette.  There is no (known) corresponding decrypt
673 function.  As a result, this function isn't all that useful for
674 cryptography.  (For that, see your nearby CPAN mirror.)
675
676 Here's an example that makes sure that whoever runs this program knows
677 their own password:
678
679     $pwd = (getpwuid($<))[1];
680     $salt = substr($pwd, 0, 2);
681
682     system "stty -echo";
683     print "Password: ";
684     chop($word = <STDIN>);
685     print "\n";
686     system "stty echo";
687
688     if (crypt($word, $salt) ne $pwd) {
689         die "Sorry...\n";
690     } else {
691         print "ok\n";
692     }
693
694 Of course, typing in your own password to whoever asks you
695 for it is unwise.
696
697 =item dbmclose HASH
698
699 [This function has been superseded by the C<untie()> function.]
700
701 Breaks the binding between a DBM file and a hash.
702
703 =item dbmopen HASH,DBNAME,MODE
704
705 [This function has been superseded by the C<tie()> function.]
706
707 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
708 hash.  HASH is the name of the hash.  (Unlike normal C<open()>, the first
709 argument is I<NOT> a filehandle, even though it looks like one).  DBNAME
710 is the name of the database (without the F<.dir> or F<.pag> extension if
711 any).  If the database does not exist, it is created with protection
712 specified by MODE (as modified by the C<umask()>).  If your system supports
713 only the older DBM functions, you may perform only one C<dbmopen()> in your
714 program.  In older versions of Perl, if your system had neither DBM nor
715 ndbm, calling C<dbmopen()> produced a fatal error; it now falls back to
716 sdbm(3).
717
718 If you don't have write access to the DBM file, you can only read hash
719 variables, not set them.  If you want to test whether you can write,
720 either use file tests or try setting a dummy hash entry inside an C<eval()>,
721 which will trap the error.
722
723 Note that functions such as C<keys()> and C<values()> may return huge lists
724 when used on large DBM files.  You may prefer to use the C<each()>
725 function to iterate over large DBM files.  Example:
726
727     # print out history file offsets
728     dbmopen(%HIST,'/usr/lib/news/history',0666);
729     while (($key,$val) = each %HIST) {
730         print $key, ' = ', unpack('L',$val), "\n";
731     }
732     dbmclose(%HIST);
733
734 See also L<AnyDBM_File> for a more general description of the pros and
735 cons of the various dbm approaches, as well as L<DB_File> for a particularly
736 rich implementation.
737
738 =item defined EXPR
739
740 =item defined
741
742 Returns a Boolean value telling whether EXPR has a value other than
743 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
744 checked.
745
746 Many operations return C<undef> to indicate failure, end of file,
747 system error, uninitialized variable, and other exceptional
748 conditions.  This function allows you to distinguish C<undef> from
749 other values.  (A simple Boolean test will not distinguish among
750 C<undef>, zero, the empty string, and C<"0">, which are all equally
751 false.)  Note that since C<undef> is a valid scalar, its presence
752 doesn't I<necessarily> indicate an exceptional condition: C<pop()>
753 returns C<undef> when its argument is an empty array, I<or> when the
754 element to return happens to be C<undef>.
755
756 You may also use C<defined()> to check whether a subroutine exists, by
757 saying C<defined &func> without parentheses.  On the other hand, use
758 of C<defined()> upon aggregates (hashes and arrays) is not guaranteed to
759 produce intuitive results, and should probably be avoided.
760
761 When used on a hash element, it tells you whether the value is defined,
762 not whether the key exists in the hash.  Use L</exists> for the latter
763 purpose.
764
765 Examples:
766
767     print if defined $switch{'D'};
768     print "$val\n" while defined($val = pop(@ary));
769     die "Can't readlink $sym: $!"
770         unless defined($value = readlink $sym);
771     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
772     $debugging = 0 unless defined $debugging;
773
774 Note:  Many folks tend to overuse C<defined()>, and then are surprised to
775 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
776 defined values.  For example, if you say
777
778     "ab" =~ /a(.*)b/;
779
780 The pattern match succeeds, and C<$1> is defined, despite the fact that it
781 matched "nothing".  But it didn't really match nothing--rather, it
782 matched something that happened to be C<0> characters long.  This is all
783 very above-board and honest.  When a function returns an undefined value,
784 it's an admission that it couldn't give you an honest answer.  So you
785 should use C<defined()> only when you're questioning the integrity of what
786 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
787 what you want.
788
789 Currently, using C<defined()> on an entire array or hash reports whether
790 memory for that aggregate has ever been allocated.  So an array you set
791 to the empty list appears undefined initially, and one that once was full
792 and that you then set to the empty list still appears defined.  You
793 should instead use a simple test for size:
794
795     if (@an_array) { print "has array elements\n" }
796     if (%a_hash)   { print "has hash members\n"   }
797
798 Using C<undef()> on these, however, does clear their memory and then report
799 them as not defined anymore, but you shouldn't do that unless you don't
800 plan to use them again, because it saves time when you load them up
801 again to have memory already ready to be filled.  The normal way to 
802 free up space used by an aggregate is to assign the empty list.
803
804 This counterintuitive behavior of C<defined()> on aggregates may be
805 changed, fixed, or broken in a future release of Perl.
806
807 See also L</undef>, L</exists>, L</ref>.
808
809 =item delete EXPR
810
811 Deletes the specified key(s) and their associated values from a hash.
812 For each key, returns the deleted value associated with that key, or
813 the undefined value if there was no such key.  Deleting from C<$ENV{}>
814 modifies the environment.  Deleting from a hash tied to a DBM file
815 deletes the entry from the DBM file.  (But deleting from a C<tie()>d hash
816 doesn't necessarily return anything.)
817
818 The following deletes all the values of a hash:
819
820     foreach $key (keys %HASH) {
821         delete $HASH{$key};
822     }
823
824 And so does this:
825
826     delete @HASH{keys %HASH}
827
828 (But both of these are slower than just assigning the empty list, or
829 using C<undef()>.)  Note that the EXPR can be arbitrarily complicated as
830 long as the final operation is a hash element lookup or hash slice:
831
832     delete $ref->[$x][$y]{$key};
833     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
834
835 =item die LIST
836
837 Outside an C<eval()>, prints the value of LIST to C<STDERR> and exits with
838 the current value of C<$!> (errno).  If C<$!> is C<0>, exits with the value of
839 C<($? E<gt>E<gt> 8)> (backtick `command` status).  If C<($? E<gt>E<gt> 8)>
840 is C<0>, exits with C<255>.  Inside an C<eval(),> the error message is stuffed into
841 C<$@> and the C<eval()> is terminated with the undefined value.  This makes
842 C<die()> the way to raise an exception.
843
844 Equivalent examples:
845
846     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
847     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
848
849 If the value of EXPR does not end in a newline, the current script line
850 number and input line number (if any) are also printed, and a newline
851 is supplied.  Hint: sometimes appending C<", stopped"> to your message
852 will cause it to make better sense when the string C<"at foo line 123"> is
853 appended.  Suppose you are running script "canasta".
854
855     die "/etc/games is no good";
856     die "/etc/games is no good, stopped";
857
858 produce, respectively
859
860     /etc/games is no good at canasta line 123.
861     /etc/games is no good, stopped at canasta line 123.
862
863 See also C<exit()> and C<warn()>.
864
865 If LIST is empty and C<$@> already contains a value (typically from a
866 previous eval) that value is reused after appending C<"\t...propagated">.
867 This is useful for propagating exceptions:
868
869     eval { ... };
870     die unless $@ =~ /Expected exception/;
871
872 If C<$@> is empty then the string C<"Died"> is used.
873
874 You can arrange for a callback to be run just before the C<die()> does
875 its deed, by setting the C<$SIG{__DIE__}> hook.  The associated handler
876 will be called with the error text and can change the error message, if
877 it sees fit, by calling C<die()> again.  See L<perlvar/$SIG{expr}> for details on
878 setting C<%SIG> entries, and L<"eval BLOCK"> for some examples.
879
880 Note that the C<$SIG{__DIE__}> hook is called even inside eval()ed
881 blocks/strings.  If one wants the hook to do nothing in such
882 situations, put
883
884         die @_ if $^S;
885
886 as the first line of the handler (see L<perlvar/$^S>).
887
888 =item do BLOCK
889
890 Not really a function.  Returns the value of the last command in the
891 sequence of commands indicated by BLOCK.  When modified by a loop
892 modifier, executes the BLOCK once before testing the loop condition.
893 (On other statements the loop modifiers test the conditional first.)
894
895 =item do SUBROUTINE(LIST)
896
897 A deprecated form of subroutine call.  See L<perlsub>.
898
899 =item do EXPR
900
901 Uses the value of EXPR as a filename and executes the contents of the
902 file as a Perl script.  Its primary use is to include subroutines
903 from a Perl subroutine library.
904
905     do 'stat.pl';
906
907 is just like
908
909     scalar eval `cat stat.pl`;
910
911 except that it's more efficient and concise, keeps track of the
912 current filename for error messages, and searches all the B<-I>
913 libraries if the file isn't in the current directory (see also the @INC
914 array in L<perlvar/Predefined Names>).  It is also different in how
915 code evaluated with C<do FILENAME> doesn't see lexicals in the enclosing
916 scope like C<eval STRING> does.  It's the same, however, in that it does
917 reparse the file every time you call it, so you probably don't want to
918 do this inside a loop.
919
920 If C<do> cannot read the file, it returns undef and sets C<$!> to the
921 error.    If C<do> can read the file but cannot compile it, it
922 returns undef and sets an error message in C<$@>.   If the file is
923 successfully compiled, C<do> returns the value of the last expression
924 evaluated.
925
926 Note that inclusion of library modules is better done with the
927 C<use()> and C<require()> operators, which also do automatic error checking
928 and raise an exception if there's a problem.
929
930 You might like to use C<do> to read in a program configuration
931 file.  Manual error checking can be done this way:
932
933     # read in config files: system first, then user 
934     for $file ("/share/prog/defaults.rc",
935                "$ENV{HOME}/.someprogrc") {
936         unless ($return = do $file) {
937             warn "couldn't parse $file: $@" if $@;
938             warn "couldn't do $file: $!"    unless defined $return;
939             warn "couldn't run $file"       unless $return;
940         }
941     }
942
943 =item dump LABEL
944
945 This causes an immediate core dump.  Primarily this is so that you can
946 use the B<undump> program to turn your core dump into an executable binary
947 after having initialized all your variables at the beginning of the
948 program.  When the new binary is executed it will begin by executing a
949 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
950 it as a goto with an intervening core dump and reincarnation.  If C<LABEL>
951 is omitted, restarts the program from the top.  WARNING: Any files
952 opened at the time of the dump will NOT be open any more when the
953 program is reincarnated, with possible resulting confusion on the part
954 of Perl.  See also B<-u> option in L<perlrun>.
955
956 Example:
957
958     #!/usr/bin/perl
959     require 'getopt.pl';
960     require 'stat.pl';
961     %days = (
962         'Sun' => 1,
963         'Mon' => 2,
964         'Tue' => 3,
965         'Wed' => 4,
966         'Thu' => 5,
967         'Fri' => 6,
968         'Sat' => 7,
969     );
970
971     dump QUICKSTART if $ARGV[0] eq '-d';
972
973     QUICKSTART:
974     Getopt('f');
975
976 This operator is largely obsolete, partly because it's very hard to 
977 convert a core file into an executable, and because the real perl-to-C
978 compiler has superseded it.
979
980 =item each HASH
981
982 When called in list context, returns a 2-element list consisting of the
983 key and value for the next element of a hash, so that you can iterate over
984 it.  When called in scalar context, returns the key for only the "next"
985 element in the hash.  (Note: Keys may be C<"0"> or C<"">, which are logically
986 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
987 for this reason.)
988
989 Entries are returned in an apparently random order.  When the hash is
990 entirely read, a null array is returned in list context (which when
991 assigned produces a FALSE (C<0>) value), and C<undef> in
992 scalar context.  The next call to C<each()> after that will start iterating
993 again.  There is a single iterator for each hash, shared by all C<each()>,
994 C<keys()>, and C<values()> function calls in the program; it can be reset by
995 reading all the elements from the hash, or by evaluating C<keys HASH> or
996 C<values HASH>.  If you add or delete elements of a hash while you're
997 iterating over it, you may get entries skipped or duplicated, so don't.
998
999 The following prints out your environment like the printenv(1) program,
1000 only in a different order:
1001
1002     while (($key,$value) = each %ENV) {
1003         print "$key=$value\n";
1004     }
1005
1006 See also C<keys()> and C<values()>.
1007
1008 =item eof FILEHANDLE
1009
1010 =item eof ()
1011
1012 =item eof
1013
1014 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1015 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1016 gives the real filehandle.  (Note that this function actually
1017 reads a character and then C<ungetc()>s it, so isn't very useful in an
1018 interactive context.)  Do not read from a terminal file (or call
1019 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
1020 as terminals may lose the end-of-file condition if you do.
1021
1022 An C<eof> without an argument uses the last file read as argument.
1023 Using C<eof()> with empty parentheses is very different.  It indicates the pseudo file formed of
1024 the files listed on the command line, i.e., C<eof()> is reasonable to
1025 use inside a C<while (E<lt>E<gt>)> loop to detect the end of only the
1026 last file.  Use C<eof(ARGV)> or eof without the parentheses to test
1027 I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
1028
1029     # reset line numbering on each input file
1030     while (<>) {
1031         next if /^\s*#/;        # skip comments 
1032         print "$.\t$_";
1033     } continue {
1034         close ARGV  if eof;     # Not eof()!
1035     }
1036
1037     # insert dashes just before last line of last file
1038     while (<>) {
1039         if (eof()) {            # check for end of current file
1040             print "--------------\n";
1041             close(ARGV);        # close or break; is needed if we
1042                                 # are reading from the terminal
1043         }
1044         print;
1045     }
1046
1047 Practical hint: you almost never need to use C<eof> in Perl, because the
1048 input operators return false values when they run out of data, or if there
1049 was an error.
1050
1051 =item eval EXPR
1052
1053 =item eval BLOCK
1054
1055 In the first form, the return value of EXPR is parsed and executed as if it
1056 were a little Perl program.  The value of the expression (which is itself
1057 determined within scalar context) is first parsed, and if there weren't any
1058 errors, executed in the context of the current Perl program, so that any
1059 variable settings or subroutine and format definitions remain afterwards.
1060 Note that the value is parsed every time the eval executes.  If EXPR is
1061 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1062 and subsequent execution of the text of EXPR until run time.
1063
1064 In the second form, the code within the BLOCK is parsed only once--at the
1065 same time the code surrounding the eval itself was parsed--and executed
1066 within the context of the current Perl program.  This form is typically
1067 used to trap exceptions more efficiently than the first (see below), while
1068 also providing the benefit of checking the code within BLOCK at compile
1069 time.
1070
1071 The final semicolon, if any, may be omitted from the value of EXPR or within
1072 the BLOCK.
1073
1074 In both forms, the value returned is the value of the last expression
1075 evaluated inside the mini-program; a return statement may be also used, just
1076 as with subroutines.  The expression providing the return value is evaluated
1077 in void, scalar, or list context, depending on the context of the eval itself.
1078 See L</wantarray> for more on how the evaluation context can be determined.
1079
1080 If there is a syntax error or runtime error, or a C<die()> statement is
1081 executed, an undefined value is returned by C<eval()>, and C<$@> is set to the
1082 error message.  If there was no error, C<$@> is guaranteed to be a null
1083 string.  Beware that using C<eval()> neither silences perl from printing
1084 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1085 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1086 L</warn> and L<perlvar>.
1087
1088 Note that, because C<eval()> traps otherwise-fatal errors, it is useful for
1089 determining whether a particular feature (such as C<socket()> or C<symlink()>)
1090 is implemented.  It is also Perl's exception trapping mechanism, where
1091 the die operator is used to raise exceptions.
1092
1093 If the code to be executed doesn't vary, you may use the eval-BLOCK
1094 form to trap run-time errors without incurring the penalty of
1095 recompiling each time.  The error, if any, is still returned in C<$@>.
1096 Examples:
1097
1098     # make divide-by-zero nonfatal
1099     eval { $answer = $a / $b; }; warn $@ if $@;
1100
1101     # same thing, but less efficient
1102     eval '$answer = $a / $b'; warn $@ if $@;
1103
1104     # a compile-time error
1105     eval { $answer = };                 # WRONG
1106
1107     # a run-time error
1108     eval '$answer =';   # sets $@
1109
1110 When using the C<eval{}> form as an exception trap in libraries, you may
1111 wish not to trigger any C<__DIE__> hooks that user code may have
1112 installed.  You can use the C<local $SIG{__DIE__}> construct for this
1113 purpose, as shown in this example:
1114
1115     # a very private exception trap for divide-by-zero
1116     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1117     warn $@ if $@;
1118
1119 This is especially significant, given that C<__DIE__> hooks can call
1120 C<die()> again, which has the effect of changing their error messages:
1121
1122     # __DIE__ hooks may modify error messages
1123     {
1124        local $SIG{'__DIE__'} =
1125               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1126        eval { die "foo lives here" };
1127        print $@ if $@;                # prints "bar lives here"
1128     }
1129
1130 With an C<eval()>, you should be especially careful to remember what's
1131 being looked at when:
1132
1133     eval $x;            # CASE 1
1134     eval "$x";          # CASE 2
1135
1136     eval '$x';          # CASE 3
1137     eval { $x };        # CASE 4
1138
1139     eval "\$$x++";      # CASE 5
1140     $$x++;              # CASE 6
1141
1142 Cases 1 and 2 above behave identically: they run the code contained in
1143 the variable C<$x>.  (Although case 2 has misleading double quotes making
1144 the reader wonder what else might be happening (nothing is).)  Cases 3
1145 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1146 does nothing but return the value of C<$x>.  (Case 4 is preferred for
1147 purely visual reasons, but it also has the advantage of compiling at
1148 compile-time instead of at run-time.)  Case 5 is a place where
1149 normally you I<WOULD> like to use double quotes, except that in this
1150 particular situation, you can just use symbolic references instead, as
1151 in case 6.
1152
1153 =item exec LIST
1154
1155 =item exec PROGRAM LIST
1156
1157 The C<exec()> function executes a system command I<AND NEVER RETURNS> -
1158 use C<system()> instead of C<exec()> if you want it to return. It fails and
1159 returns FALSE only if the command does not exist I<and> it is executed
1160 directly instead of via your system's command shell (see below).
1161
1162 Since it's a common mistake to use C<exec()> instead of C<system()>, Perl
1163 warns you if there is a following statement which isn't C<die()>, C<warn()>,
1164 or C<exit()> (if C<-w> is set  -  but you always do that).   If you
1165 I<really> want to follow an C<exec()> with some other statement, you
1166 can use one of these styles to avoid the warning:
1167
1168     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1169     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1170
1171 If there is more than one argument in LIST, or if LIST is an array
1172 with more than one value, calls execvp(3) with the arguments in LIST.
1173 If there is only one scalar argument or an array with one element in it,
1174 the argument is checked for shell metacharacters, and if there are any,
1175 the entire argument is passed to the system's command shell for parsing
1176 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1177 If there are no shell metacharacters in the argument, it is split into
1178 words and passed directly to C<execvp()>, which is more efficient.  Note:
1179 C<exec()> and C<system()> do not flush your output buffer, so you may need to
1180 set C<$|> to avoid lost output.  Examples:
1181
1182     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1183     exec "sort $outfile | uniq";
1184
1185 If you don't really want to execute the first argument, but want to lie
1186 to the program you are executing about its own name, you can specify
1187 the program you actually want to run as an "indirect object" (without a
1188 comma) in front of the LIST.  (This always forces interpretation of the
1189 LIST as a multivalued list, even if there is only a single scalar in
1190 the list.)  Example:
1191
1192     $shell = '/bin/csh';
1193     exec $shell '-sh';          # pretend it's a login shell
1194
1195 or, more directly,
1196
1197     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1198
1199 When the arguments get executed via the system shell, results will
1200 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1201 for details.
1202
1203 Using an indirect object with C<exec()> or C<system()> is also more secure.
1204 This usage forces interpretation of the arguments as a multivalued list,
1205 even if the list had just one argument.  That way you're safe from the
1206 shell expanding wildcards or splitting up words with whitespace in them.
1207
1208     @args = ( "echo surprise" );
1209
1210     system @args;               # subject to shell escapes
1211                                 # if @args == 1
1212     system { $args[0] } @args;  # safe even with one-arg list
1213
1214 The first version, the one without the indirect object, ran the I<echo>
1215 program, passing it C<"surprise"> an argument.  The second version
1216 didn't--it tried to run a program literally called I<"echo surprise">,
1217 didn't find it, and set C<$?> to a non-zero value indicating failure.
1218
1219 Note that C<exec()> will not call your C<END> blocks, nor will it call
1220 any C<DESTROY> methods in your objects.
1221
1222 =item exists EXPR
1223
1224 Returns TRUE if the specified hash key exists in its hash array, even
1225 if the corresponding value is undefined.
1226
1227     print "Exists\n" if exists $array{$key};
1228     print "Defined\n" if defined $array{$key};
1229     print "True\n" if $array{$key};
1230
1231 A hash element can be TRUE only if it's defined, and defined if
1232 it exists, but the reverse doesn't necessarily hold true.
1233
1234 Note that the EXPR can be arbitrarily complicated as long as the final
1235 operation is a hash key lookup:
1236
1237     if (exists $ref->{"A"}{"B"}{$key}) { ... }
1238
1239 Although the last element will not spring into existence just because its
1240 existence was tested, intervening ones will.  Thus C<$ref-E<gt>{"A"}>
1241 C<$ref-E<gt>{"B"}> will spring into existence due to the existence
1242 test for a $key element.  This autovivification may be fixed in a later
1243 release.
1244
1245 =item exit EXPR
1246
1247 Evaluates EXPR and exits immediately with that value.  (Actually, it
1248 calls any defined C<END> routines first, but the C<END> routines may not
1249 abort the exit.  Likewise any object destructors that need to be called
1250 are called before exit.)  Example:
1251
1252     $ans = <STDIN>;
1253     exit 0 if $ans =~ /^[Xx]/;
1254
1255 See also C<die()>.  If EXPR is omitted, exits with C<0> status.  The only
1256 universally portable values for EXPR are C<0> for success and C<1> for error;
1257 all other values are subject to unpredictable interpretation depending
1258 on the environment in which the Perl program is running.
1259
1260 You shouldn't use C<exit()> to abort a subroutine if there's any chance that
1261 someone might want to trap whatever error happened.  Use C<die()> instead,
1262 which can be trapped by an C<eval()>.
1263
1264 All C<END{}> blocks are run at exit time.  See L<perlsub> for details.
1265
1266 =item exp EXPR
1267
1268 =item exp
1269
1270 Returns I<e> (the natural logarithm base) to the power of EXPR.
1271 If EXPR is omitted, gives C<exp($_)>.
1272
1273 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1274
1275 Implements the fcntl(2) function.  You'll probably have to say
1276
1277     use Fcntl;
1278
1279 first to get the correct constant definitions.  Argument processing and
1280 value return works just like C<ioctl()> below.  
1281 For example:
1282
1283     use Fcntl;
1284     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1285         or die "can't fcntl F_GETFL: $!";
1286
1287 You don't have to check for C<defined()> on the return from 
1288 C<fnctl()>.  Like C<ioctl()>, it maps a C<0> return from the system
1289 call into "C<0> but true" in Perl.  This string is true in 
1290 boolean context and C<0> in numeric context.  It is also 
1291 exempt from the normal B<-w> warnings on improper numeric
1292 conversions.
1293
1294 Note that C<fcntl()> will produce a fatal error if used on a machine that
1295 doesn't implement fcntl(2).
1296
1297 =item fileno FILEHANDLE
1298
1299 Returns the file descriptor for a filehandle.  This is useful for
1300 constructing bitmaps for C<select()> and low-level POSIX tty-handling
1301 operations.  If FILEHANDLE is an expression, the value is taken as 
1302 an indirect filehandle, generally its name. 
1303
1304 You can use this to find out whether two handles refer to the 
1305 same underlying descriptor:
1306
1307     if (fileno(THIS) == fileno(THAT)) {
1308         print "THIS and THAT are dups\n";
1309     } 
1310
1311 =item flock FILEHANDLE,OPERATION
1312
1313 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns TRUE for
1314 success, FALSE on failure.  Produces a fatal error if used on a machine
1315 that doesn't implement flock(2), fcntl(2) locking, or lockf(3).  C<flock()>
1316 is Perl's portable file locking interface, although it locks only entire
1317 files, not records.
1318
1319 On many platforms (including most versions or clones of Unix), locks
1320 established by C<flock()> are B<merely advisory>.  Such discretionary locks
1321 are more flexible, but offer fewer guarantees.  This means that files
1322 locked with C<flock()> may be modified by programs that do not also use
1323 C<flock()>.  Windows NT and OS/2 are among the platforms which
1324 enforce mandatory locking.  See your local documentation for details.
1325
1326 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1327 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1328 you can use the symbolic names if import them from the Fcntl module,
1329 either individually, or as a group using the ':flock' tag.  LOCK_SH
1330 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1331 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1332 LOCK_EX then C<flock()> will return immediately rather than blocking
1333 waiting for the lock (check the return status to see if you got it).
1334
1335 To avoid the possibility of mis-coordination, Perl flushes FILEHANDLE
1336 before (un)locking it.
1337
1338 Note that the emulation built with lockf(3) doesn't provide shared
1339 locks, and it requires that FILEHANDLE be open with write intent.  These
1340 are the semantics that lockf(3) implements.  Most (all?) systems
1341 implement lockf(3) in terms of fcntl(2) locking, though, so the
1342 differing semantics shouldn't bite too many people.
1343
1344 Note also that some versions of C<flock()> cannot lock things over the
1345 network; you would need to use the more system-specific C<fcntl()> for
1346 that.  If you like you can force Perl to ignore your system's flock(2)
1347 function, and so provide its own fcntl(2)-based emulation, by passing
1348 the switch C<-Ud_flock> to the F<Configure> program when you configure
1349 perl.
1350
1351 Here's a mailbox appender for BSD systems.
1352
1353     use Fcntl ':flock'; # import LOCK_* constants
1354
1355     sub lock {
1356         flock(MBOX,LOCK_EX);
1357         # and, in case someone appended
1358         # while we were waiting...
1359         seek(MBOX, 0, 2);
1360     }
1361
1362     sub unlock {
1363         flock(MBOX,LOCK_UN);
1364     }
1365
1366     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1367             or die "Can't open mailbox: $!";
1368
1369     lock();
1370     print MBOX $msg,"\n\n";
1371     unlock();
1372
1373 See also L<DB_File> for other flock() examples.
1374
1375 =item fork
1376
1377 Does a fork(2) system call.  Returns the child pid to the parent process,
1378 C<0> to the child process, or C<undef> if the fork is unsuccessful.
1379
1380 Note: unflushed buffers remain unflushed in both processes, which means
1381 you may need to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()>
1382 method of C<IO::Handle> to avoid duplicate output.
1383
1384 If you C<fork()> without ever waiting on your children, you will accumulate
1385 zombies:
1386
1387     $SIG{CHLD} = sub { wait };
1388
1389 There's also the double-fork trick (error checking on
1390 C<fork()> returns omitted);
1391
1392     unless ($pid = fork) {
1393         unless (fork) {
1394             exec "what you really wanna do";
1395             die "no exec";
1396             # ... or ...
1397             ## (some_perl_code_here)
1398             exit 0;
1399         }
1400         exit 0;
1401     }
1402     waitpid($pid,0);
1403
1404 See also L<perlipc> for more examples of forking and reaping
1405 moribund children.
1406
1407 Note that if your forked child inherits system file descriptors like
1408 STDIN and STDOUT that are actually connected by a pipe or socket, even
1409 if you exit, then the remote server (such as, say, httpd or rsh) won't think
1410 you're done.  You should reopen those to F</dev/null> if it's any issue.
1411
1412 =item format
1413
1414 Declare a picture format for use by the C<write()> function.  For
1415 example:
1416
1417     format Something =
1418         Test: @<<<<<<<< @||||| @>>>>>
1419               $str,     $%,    '$' . int($num)
1420     .
1421
1422     $str = "widget";
1423     $num = $cost/$quantity;
1424     $~ = 'Something';
1425     write;
1426
1427 See L<perlform> for many details and examples.
1428
1429 =item formline PICTURE,LIST
1430
1431 This is an internal function used by C<format>s, though you may call it,
1432 too.  It formats (see L<perlform>) a list of values according to the
1433 contents of PICTURE, placing the output into the format output
1434 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1435 Eventually, when a C<write()> is done, the contents of
1436 C<$^A> are written to some filehandle, but you could also read C<$^A>
1437 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1438 does one C<formline()> per line of form, but the C<formline()> function itself
1439 doesn't care how many newlines are embedded in the PICTURE.  This means
1440 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1441 You may therefore need to use multiple formlines to implement a single
1442 record format, just like the format compiler.
1443
1444 Be careful if you put double quotes around the picture, because an "C<@>"
1445 character may be taken to mean the beginning of an array name.
1446 C<formline()> always returns TRUE.  See L<perlform> for other examples.
1447
1448 =item getc FILEHANDLE
1449
1450 =item getc
1451
1452 Returns the next character from the input file attached to FILEHANDLE,
1453 or the undefined value at end of file, or if there was an error.  If
1454 FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1455 efficient.  It cannot be used to get unbuffered single-characters,
1456 however.  For that, try something more like:
1457
1458     if ($BSD_STYLE) {
1459         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1460     }
1461     else {
1462         system "stty", '-icanon', 'eol', "\001";
1463     }
1464
1465     $key = getc(STDIN);
1466
1467     if ($BSD_STYLE) {
1468         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1469     }
1470     else {
1471         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1472     }
1473     print "\n";
1474
1475 Determination of whether $BSD_STYLE should be set
1476 is left as an exercise to the reader.
1477
1478 The C<POSIX::getattr()> function can do this more portably on systems
1479 purporting POSIX compliance.
1480 See also the C<Term::ReadKey> module from your nearest CPAN site;
1481 details on CPAN can be found on L<perlmod/CPAN>.
1482
1483 =item getlogin
1484
1485 Implements the C library function of the same name, which on most
1486 systems returns the current login from F</etc/utmp>, if any.  If null,
1487 use C<getpwuid()>.
1488
1489     $login = getlogin || getpwuid($<) || "Kilroy";
1490
1491 Do not consider C<getlogin()> for authentication: it is not as
1492 secure as C<getpwuid()>.
1493
1494 =item getpeername SOCKET
1495
1496 Returns the packed sockaddr address of other end of the SOCKET connection.
1497
1498     use Socket;
1499     $hersockaddr    = getpeername(SOCK);
1500     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1501     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1502     $herstraddr     = inet_ntoa($iaddr);
1503
1504 =item getpgrp PID
1505
1506 Returns the current process group for the specified PID.  Use
1507 a PID of C<0> to get the current process group for the
1508 current process.  Will raise an exception if used on a machine that
1509 doesn't implement getpgrp(2).  If PID is omitted, returns process
1510 group of current process.  Note that the POSIX version of C<getpgrp()>
1511 does not accept a PID argument, so only C<PID==0> is truly portable.
1512
1513 =item getppid
1514
1515 Returns the process id of the parent process.
1516
1517 =item getpriority WHICH,WHO
1518
1519 Returns the current priority for a process, a process group, or a user.
1520 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1521 machine that doesn't implement getpriority(2).
1522
1523 =item getpwnam NAME
1524
1525 =item getgrnam NAME
1526
1527 =item gethostbyname NAME
1528
1529 =item getnetbyname NAME
1530
1531 =item getprotobyname NAME
1532
1533 =item getpwuid UID
1534
1535 =item getgrgid GID
1536
1537 =item getservbyname NAME,PROTO
1538
1539 =item gethostbyaddr ADDR,ADDRTYPE
1540
1541 =item getnetbyaddr ADDR,ADDRTYPE
1542
1543 =item getprotobynumber NUMBER
1544
1545 =item getservbyport PORT,PROTO
1546
1547 =item getpwent
1548
1549 =item getgrent
1550
1551 =item gethostent
1552
1553 =item getnetent
1554
1555 =item getprotoent
1556
1557 =item getservent
1558
1559 =item setpwent
1560
1561 =item setgrent
1562
1563 =item sethostent STAYOPEN
1564
1565 =item setnetent STAYOPEN
1566
1567 =item setprotoent STAYOPEN
1568
1569 =item setservent STAYOPEN
1570
1571 =item endpwent
1572
1573 =item endgrent
1574
1575 =item endhostent
1576
1577 =item endnetent
1578
1579 =item endprotoent
1580
1581 =item endservent
1582
1583 These routines perform the same functions as their counterparts in the
1584 system library.  In list context, the return values from the
1585 various get routines are as follows:
1586
1587     ($name,$passwd,$uid,$gid,
1588        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1589     ($name,$passwd,$gid,$members) = getgr*
1590     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1591     ($name,$aliases,$addrtype,$net) = getnet*
1592     ($name,$aliases,$proto) = getproto*
1593     ($name,$aliases,$port,$proto) = getserv*
1594
1595 (If the entry doesn't exist you get a null list.)
1596
1597 In scalar context, you get the name, unless the function was a
1598 lookup by name, in which case you get the other thing, whatever it is.
1599 (If the entry doesn't exist you get the undefined value.)  For example:
1600
1601     $uid   = getpwnam($name);
1602     $name  = getpwuid($num);
1603     $name  = getpwent();
1604     $gid   = getgrnam($name);
1605     $name  = getgrgid($num;
1606     $name  = getgrent();
1607     #etc.
1608
1609 In I<getpw*()> the fields C<$quota>, C<$comment>, and C<$expire> are special
1610 cases in the sense that in many systems they are unsupported.  If the
1611 C<$quota> is unsupported, it is an empty scalar.  If it is supported, it
1612 usually encodes the disk quota.  If the C<$comment> field is unsupported,
1613 it is an empty scalar.  If it is supported it usually encodes some
1614 administrative comment about the user.  In some systems the $quota
1615 field may be C<$change> or C<$age>, fields that have to do with password
1616 aging.  In some systems the C<$comment> field may be C<$class>.  The C<$expire>
1617 field, if present, encodes the expiration period of the account or the
1618 password.  For the availability and the exact meaning of these fields
1619 in your system, please consult your getpwnam(3) documentation and your
1620 F<pwd.h> file.  You can also find out from within Perl which meaning
1621 your C<$quota> and C<$comment> fields have and whether you have the C<$expire>
1622 field by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1623 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.
1624
1625 The C<$members> value returned by I<getgr*()> is a space separated list of
1626 the login names of the members of the group.
1627
1628 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1629 C, it will be returned to you via C<$?> if the function call fails.  The
1630 C<@addrs> value returned by a successful call is a list of the raw
1631 addresses returned by the corresponding system library call.  In the
1632 Internet domain, each address is four bytes long and you can unpack it
1633 by saying something like:
1634
1635     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1636
1637 If you get tired of remembering which element of the return list contains
1638 which return value, by-name interfaces are also provided in modules:
1639 C<File::stat>, C<Net::hostent>, C<Net::netent>, C<Net::protoent>, C<Net::servent>,
1640 C<Time::gmtime>, C<Time::localtime>, and C<User::grent>.  These override the
1641 normal built-in, replacing them with versions that return objects with
1642 the appropriate names for each field.  For example:
1643
1644    use File::stat;
1645    use User::pwent;
1646    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1647
1648 Even though it looks like they're the same method calls (uid), 
1649 they aren't, because a C<File::stat> object is different from a C<User::pwent> object.
1650
1651 =item getsockname SOCKET
1652
1653 Returns the packed sockaddr address of this end of the SOCKET connection.
1654
1655     use Socket;
1656     $mysockaddr = getsockname(SOCK);
1657     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1658
1659 =item getsockopt SOCKET,LEVEL,OPTNAME
1660
1661 Returns the socket option requested, or undef if there is an error.
1662
1663 =item glob EXPR
1664
1665 =item glob
1666
1667 Returns the value of EXPR with filename expansions such as the standard Unix shell F</bin/sh> would
1668 do.  This is the internal function implementing the C<E<lt>*.cE<gt>>
1669 operator, but you can use it directly.  If EXPR is omitted, C<$_> is used.
1670 The C<E<lt>*.cE<gt>> operator is discussed in more detail in
1671 L<perlop/"I/O Operators">.
1672
1673 =item gmtime EXPR
1674
1675 Converts a time as returned by the time function to a 9-element array
1676 with the time localized for the standard Greenwich time zone.
1677 Typically used as follows:
1678
1679     #  0    1    2     3     4    5     6     7     8
1680     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1681                                             gmtime(time);
1682
1683 All array elements are numeric, and come straight out of a struct tm.
1684 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
1685 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
1686 years since 1900, that is, C<$year> is C<123> in year 2023, I<not> simply the last two digits of the year.
1687
1688 If EXPR is omitted, does C<gmtime(time())>.
1689
1690 In scalar context, returns the ctime(3) value:
1691
1692     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1693
1694 Also see the C<timegm()> function provided by the C<Time::Local> module,
1695 and the strftime(3) function available via the POSIX module.
1696
1697 This scalar value is B<not> locale dependent, see L<perllocale>, but
1698 instead a Perl builtin.  Also see the C<Time::Local> module, and the
1699 strftime(3) and mktime(3) function available via the POSIX module.  To
1700 get somewhat similar but locale dependent date strings, set up your
1701 locale environment variables appropriately (please see L<perllocale>)
1702 and try for example:
1703
1704     use POSIX qw(strftime);
1705         $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
1706
1707 Note that the C<%a> and C<%b>, the short forms of the day of the week
1708 and the month of the year, may not necessarily be three characters wide.
1709
1710 =item goto LABEL
1711
1712 =item goto EXPR
1713
1714 =item goto &NAME
1715
1716 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
1717 execution there.  It may not be used to go into any construct that
1718 requires initialization, such as a subroutine or a C<foreach> loop.  It
1719 also can't be used to go into a construct that is optimized away,
1720 or to get out of a block or subroutine given to C<sort()>.
1721 It can be used to go almost anywhere else within the dynamic scope,
1722 including out of subroutines, but it's usually better to use some other
1723 construct such as C<last> or C<die()>.  The author of Perl has never felt the
1724 need to use this form of C<goto> (in Perl, that is--C is another matter).
1725
1726 The C<goto-EXPR> form expects a label name, whose scope will be resolved
1727 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
1728 necessarily recommended if you're optimizing for maintainability:
1729
1730     goto ("FOO", "BAR", "GLARCH")[$i];
1731
1732 The C<goto-&NAME> form is highly magical, and substitutes a call to the
1733 named subroutine for the currently running subroutine.  This is used by
1734 C<AUTOLOAD> subroutines that wish to load another subroutine and then
1735 pretend that the other subroutine had been called in the first place
1736 (except that any modifications to C<@_> in the current subroutine are
1737 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
1738 will be able to tell that this routine was called first.
1739
1740 =item grep BLOCK LIST
1741
1742 =item grep EXPR,LIST
1743
1744 This is similar in spirit to, but not the same as, grep(1)
1745 and its relatives.  In particular, it is not limited to using
1746 regular expressions.
1747
1748 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1749 C<$_> to each element) and returns the list value consisting of those
1750 elements for which the expression evaluated to TRUE.  In a scalar
1751 context, returns the number of times the expression was TRUE.
1752
1753     @foo = grep(!/^#/, @bar);    # weed out comments
1754
1755 or equivalently,
1756
1757     @foo = grep {!/^#/} @bar;    # weed out comments
1758
1759 Note that, because C<$_> is a reference into the list value, it can be used
1760 to modify the elements of the array.  While this is useful and
1761 supported, it can cause bizarre results if the LIST is not a named
1762 array.  Similarly, grep returns aliases into the original list,
1763 much like the way that a for loop's index variable aliases the list
1764 elements.  That is, modifying an element of a list returned by grep
1765 (for example, in a C<foreach>, C<map()> or another C<grep()>)
1766 actually modifies the element in the original list.
1767
1768 See also L</map> for an array composed of the results of the BLOCK or EXPR.
1769
1770 =item hex EXPR
1771
1772 =item hex
1773
1774 Interprets EXPR as a hex string and returns the corresponding
1775 value.  (To convert strings that might start with either 0 or 0x
1776 see L</oct>.)  If EXPR is omitted, uses C<$_>.
1777
1778     print hex '0xAf'; # prints '175'
1779     print hex 'aF';   # same
1780
1781 =item import
1782
1783 There is no builtin C<import()> function.  It is just an ordinary
1784 method (subroutine) defined (or inherited) by modules that wish to export
1785 names to another module.  The C<use()> function calls the C<import()> method
1786 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
1787
1788 =item index STR,SUBSTR,POSITION
1789
1790 =item index STR,SUBSTR
1791
1792 Returns the position of the first occurrence of SUBSTR in STR at or after
1793 POSITION.  If POSITION is omitted, starts searching from the beginning of
1794 the string.  The return value is based at C<0> (or whatever you've set the C<$[>
1795 variable to--but don't do that).  If the substring is not found, returns
1796 one less than the base, ordinarily C<-1>.
1797
1798 =item int EXPR
1799
1800 =item int
1801
1802 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
1803 You should not use this for rounding, because it truncates
1804 towards C<0>, and because machine representations of floating point
1805 numbers can sometimes produce counterintuitive results.  Usually C<sprintf()> or C<printf()>,
1806 or the C<POSIX::floor> or C<POSIX::ceil> functions, would serve you better.
1807
1808 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1809
1810 Implements the ioctl(2) function.  You'll probably have to say
1811
1812     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1813
1814 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1815 exist or doesn't have the correct definitions you'll have to roll your
1816 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1817 (There is a Perl script called B<h2ph> that comes with the Perl kit that
1818 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
1819 written depending on the FUNCTION--a pointer to the string value of SCALAR
1820 will be passed as the third argument of the actual C<ioctl()> call.  (If SCALAR
1821 has no string value but does have a numeric value, that value will be
1822 passed rather than a pointer to the string value.  To guarantee this to be
1823 TRUE, add a C<0> to the scalar before using it.)  The C<pack()> and C<unpack()>
1824 functions are useful for manipulating the values of structures used by
1825 C<ioctl()>.  The following example sets the erase character to DEL.
1826
1827     require 'ioctl.ph';
1828     $getp = &TIOCGETP;
1829     die "NO TIOCGETP" if $@ || !$getp;
1830     $sgttyb_t = "ccccs";                # 4 chars and a short
1831     if (ioctl(STDIN,$getp,$sgttyb)) {
1832         @ary = unpack($sgttyb_t,$sgttyb);
1833         $ary[2] = 127;
1834         $sgttyb = pack($sgttyb_t,@ary);
1835         ioctl(STDIN,&TIOCSETP,$sgttyb)
1836             || die "Can't ioctl: $!";
1837     }
1838
1839 The return value of C<ioctl()> (and C<fcntl()>) is as follows:
1840
1841         if OS returns:          then Perl returns:
1842             -1                    undefined value
1843              0                  string "0 but true"
1844         anything else               that number
1845
1846 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1847 still easily determine the actual value returned by the operating
1848 system:
1849
1850     ($retval = ioctl(...)) || ($retval = -1);
1851     printf "System returned %d\n", $retval;
1852
1853 The special string "C<0> but true" is excempt from B<-w> complaints
1854 about improper numeric conversions.
1855
1856 =item join EXPR,LIST
1857
1858 Joins the separate strings of LIST into a single string with
1859 fields separated by the value of EXPR, and returns the string.
1860 Example:
1861
1862     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1863
1864 See L</split>.
1865
1866 =item keys HASH
1867
1868 Returns a list consisting of all the keys of the named hash.  (In a
1869 scalar context, returns the number of keys.)  The keys are returned in
1870 an apparently random order, but it is the same order as either the
1871 C<values()> or C<each()> function produces (given that the hash has not been
1872 modified).  As a side effect, it resets HASH's iterator.
1873
1874 Here is yet another way to print your environment:
1875
1876     @keys = keys %ENV;
1877     @values = values %ENV;
1878     while ($#keys >= 0) {
1879         print pop(@keys), '=', pop(@values), "\n";
1880     }
1881
1882 or how about sorted by key:
1883
1884     foreach $key (sort(keys %ENV)) {
1885         print $key, '=', $ENV{$key}, "\n";
1886     }
1887
1888 To sort an array by value, you'll need to use a C<sort()> function.
1889 Here's a descending numeric sort of a hash by its values:
1890
1891     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
1892         printf "%4d %s\n", $hash{$key}, $key;
1893     }
1894
1895 As an lvalue C<keys()> allows you to increase the number of hash buckets
1896 allocated for the given hash.  This can gain you a measure of efficiency if
1897 you know the hash is going to get big.  (This is similar to pre-extending
1898 an array by assigning a larger number to $#array.)  If you say
1899
1900     keys %hash = 200;
1901
1902 then C<%hash> will have at least 200 buckets allocated for it--256 of them, in fact, since 
1903 it rounds up to the next power of two.  These
1904 buckets will be retained even if you do C<%hash = ()>, use C<undef
1905 %hash> if you want to free the storage while C<%hash> is still in scope.
1906 You can't shrink the number of buckets allocated for the hash using
1907 C<keys()> in this way (but you needn't worry about doing this by accident,
1908 as trying has no effect).
1909
1910 =item kill LIST
1911
1912 Sends a signal to a list of processes.  The first element of
1913 the list must be the signal to send.  Returns the number of
1914 processes successfully signaled.
1915
1916     $cnt = kill 1, $child1, $child2;
1917     kill 9, @goners;
1918
1919 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
1920 process groups instead of processes.  (On System V, a negative I<PROCESS>
1921 number will also kill process groups, but that's not portable.)  That
1922 means you usually want to use positive not negative signals.  You may also
1923 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
1924
1925 =item last LABEL
1926
1927 =item last
1928
1929 The C<last> command is like the C<break> statement in C (as used in
1930 loops); it immediately exits the loop in question.  If the LABEL is
1931 omitted, the command refers to the innermost enclosing loop.  The
1932 C<continue> block, if any, is not executed:
1933
1934     LINE: while (<STDIN>) {
1935         last LINE if /^$/;      # exit when done with header
1936         #...
1937     }
1938
1939 See also L</continue> for an illustration of how C<last>, C<next>, and
1940 C<redo> work.
1941
1942 =item lc EXPR
1943
1944 =item lc
1945
1946 Returns an lowercased version of EXPR.  This is the internal function
1947 implementing the C<\L> escape in double-quoted strings.
1948 Respects current C<LC_CTYPE> locale if C<use locale> in force.  See L<perllocale>.
1949
1950 If EXPR is omitted, uses C<$_>.
1951
1952 =item lcfirst EXPR
1953
1954 =item lcfirst
1955
1956 Returns the value of EXPR with the first character lowercased.  This is
1957 the internal function implementing the C<\l> escape in double-quoted strings.
1958 Respects current C<LC_CTYPE> locale if C<use locale> in force.  See L<perllocale>.
1959
1960 If EXPR is omitted, uses C<$_>.
1961
1962 =item length EXPR
1963
1964 =item length
1965
1966 Returns the length in bytes of the value of EXPR.  If EXPR is
1967 omitted, returns length of C<$_>.
1968
1969 =item link OLDFILE,NEWFILE
1970
1971 Creates a new filename linked to the old filename.  Returns TRUE for
1972 success, FALSE otherwise.
1973
1974 =item listen SOCKET,QUEUESIZE
1975
1976 Does the same thing that the listen system call does.  Returns TRUE if
1977 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
1978
1979 =item local EXPR
1980
1981 A local modifies the listed variables to be local to the enclosing
1982 block, file, or eval.  If more than one value is listed, the list must
1983 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
1984 for details, including issues with tied arrays and hashes.
1985
1986 You really probably want to be using C<my()> instead, because C<local()> isn't
1987 what most people think of as "local".  See L<perlsub/"Private Variables
1988 via my()"> for details.
1989
1990 =item localtime EXPR
1991
1992 Converts a time as returned by the time function to a 9-element array
1993 with the time analyzed for the local time zone.  Typically used as
1994 follows:
1995
1996     #  0    1    2     3     4    5     6     7     8
1997     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1998                                                 localtime(time);
1999
2000 All array elements are numeric, and come straight out of a struct tm.
2001 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
2002 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
2003 years since 1900, that is, C<$year> is C<123> in year 2023, and I<not> simply the last two digits of the year.
2004
2005 If EXPR is omitted, uses the current time (C<localtime(time)>).
2006
2007 In scalar context, returns the ctime(3) value:
2008
2009     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2010
2011 This scalar value is B<not> locale dependent, see L<perllocale>, but
2012 instead a Perl builtin.  Also see the C<Time::Local> module, and the
2013 strftime(3) and mktime(3) function available via the POSIX module.  To
2014 get somewhat similar but locale dependent date strings, set up your
2015 locale environment variables appropriately (please see L<perllocale>)
2016 and try for example:
2017
2018     use POSIX qw(strftime);
2019         $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2020
2021 Note that the C<%a> and C<%b>, the short forms of the day of the week
2022 and the month of the year, may not necessarily be three characters wide.
2023
2024 =item log EXPR
2025
2026 =item log
2027
2028 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
2029 of C<$_>.
2030
2031 =item lstat FILEHANDLE
2032
2033 =item lstat EXPR
2034
2035 =item lstat
2036
2037 Does the same thing as the C<stat()> function (including setting the
2038 special C<_> filehandle) but stats a symbolic link instead of the file
2039 the symbolic link points to.  If symbolic links are unimplemented on
2040 your system, a normal C<stat()> is done.
2041
2042 If EXPR is omitted, stats C<$_>.
2043
2044 =item m//
2045
2046 The match operator.  See L<perlop>.
2047
2048 =item map BLOCK LIST
2049
2050 =item map EXPR,LIST
2051
2052 Evaluates the BLOCK or EXPR for each element of LIST (locally setting C<$_> to each
2053 element) and returns the list value composed of the results of each such
2054 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
2055 may produce zero, one, or more elements in the returned value.
2056
2057     @chars = map(chr, @nums);
2058
2059 translates a list of numbers to the corresponding characters.  And
2060
2061     %hash = map { getkey($_) => $_ } @array;
2062
2063 is just a funny way to write
2064
2065     %hash = ();
2066     foreach $_ (@array) {
2067         $hash{getkey($_)} = $_;
2068     }
2069
2070 Note that, because C<$_> is a reference into the list value, it can be used
2071 to modify the elements of the array.  While this is useful and
2072 supported, it can cause bizarre results if the LIST is not a named
2073 array.  See also L</grep> for an array composed of those items of the 
2074 original list for which the BLOCK or EXPR evaluates to true.
2075
2076 =item mkdir FILENAME,MODE
2077
2078 Creates the directory specified by FILENAME, with permissions specified
2079 by MODE (as modified by umask).  If it succeeds it returns TRUE, otherwise
2080 it returns FALSE and sets C<$!> (errno).
2081
2082 =item msgctl ID,CMD,ARG
2083
2084 Calls the System V IPC function msgctl(2).  You'll probably have to say
2085
2086     use IPC::SysV;
2087
2088 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2089 then ARG must be a variable which will hold the returned C<msqid_ds>
2090 structure.  Returns like C<ioctl()>: the undefined value for error, "C<0> but
2091 true" for zero, or the actual return value otherwise.  See also
2092 C<IPC::SysV> and C<IPC::Semaphore::Msg> documentation.
2093
2094 =item msgget KEY,FLAGS
2095
2096 Calls the System V IPC function msgget(2).  Returns the message queue
2097 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2098 and C<IPC::SysV::Msg> documentation.
2099
2100 =item msgsnd ID,MSG,FLAGS
2101
2102 Calls the System V IPC function msgsnd to send the message MSG to the
2103 message queue ID.  MSG must begin with the long integer message type,
2104 which may be created with C<pack("l", $type)>.  Returns TRUE if
2105 successful, or FALSE if there is an error.  See also C<IPC::SysV>
2106 and C<IPC::SysV::Msg> documentation.
2107
2108 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2109
2110 Calls the System V IPC function msgrcv to receive a message from
2111 message queue ID into variable VAR with a maximum message size of
2112 SIZE.  Note that if a message is received, the message type will be
2113 the first thing in VAR, and the maximum length of VAR is SIZE plus the
2114 size of the message type.  Returns TRUE if successful, or FALSE if
2115 there is an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2116
2117 =item my EXPR
2118
2119 A C<my()> declares the listed variables to be local (lexically) to the
2120 enclosing block, file, or C<eval()>.  If
2121 more than one value is listed, the list must be placed in parentheses.  See
2122 L<perlsub/"Private Variables via my()"> for details.
2123
2124 =item next LABEL
2125
2126 =item next
2127
2128 The C<next> command is like the C<continue> statement in C; it starts
2129 the next iteration of the loop:
2130
2131     LINE: while (<STDIN>) {
2132         next LINE if /^#/;      # discard comments
2133         #...
2134     }
2135
2136 Note that if there were a C<continue> block on the above, it would get
2137 executed even on discarded lines.  If the LABEL is omitted, the command
2138 refers to the innermost enclosing loop.
2139
2140 See also L</continue> for an illustration of how C<last>, C<next>, and
2141 C<redo> work.
2142
2143 =item no Module LIST
2144
2145 See the L</use> function, which C<no> is the opposite of.
2146
2147 =item oct EXPR
2148
2149 =item oct
2150
2151 Interprets EXPR as an octal string and returns the corresponding
2152 value.  (If EXPR happens to start off with C<0x>, interprets it as
2153 a hex string instead.)  The following will handle decimal, octal, and
2154 hex in the standard Perl or C notation:
2155
2156     $val = oct($val) if $val =~ /^0/;
2157
2158 If EXPR is omitted, uses C<$_>.  This function is commonly used when
2159 a string such as C<644> needs to be converted into a file mode, for
2160 example. (Although perl will automatically convert strings into
2161 numbers as needed, this automatic conversion assumes base 10.)
2162
2163 =item open FILEHANDLE,EXPR
2164
2165 =item open FILEHANDLE
2166
2167 Opens the file whose filename is given by EXPR, and associates it with
2168 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2169 name of the real filehandle wanted.  If EXPR is omitted, the scalar
2170 variable of the same name as the FILEHANDLE contains the filename.
2171 (Note that lexical variables--those declared with C<my()>--will not work
2172 for this purpose; so if you're using C<my()>, specify EXPR in your call
2173 to open.)
2174
2175 If the filename begins with C<'E<lt>'> or nothing, the file is opened for input.
2176 If the filename begins with C<'E<gt>'>, the file is truncated and opened for
2177 output, being created if necessary. If the filename begins with C<'E<gt>E<gt>'>,
2178 the file is opened for appending, again being created if necessary. 
2179 You can put a C<'+'> in front of the C<'E<gt>'> or C<'E<lt>'> to indicate that
2180 you want both read and write access to the file; thus C<'+E<lt>'> is almost
2181 always preferred for read/write updates--the C<'+E<gt>'> mode would clobber the
2182 file first.  You can't usually use either read-write mode for updating
2183 textfiles, since they have variable length records.  See the B<-i>
2184 switch in L<perlrun> for a better approach.
2185
2186 The prefix and the filename may be separated with spaces.
2187 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>, C<'w'>,
2188 C<'w+'>, C<'a'>, and C<'a+'>.
2189
2190 If the filename begins with C<'|'>, the filename is interpreted as a
2191 command to which output is to be piped, and if the filename ends with a
2192 C<'|'>, the filename is interpreted See L<perlipc/"Using open() for IPC">
2193 for more examples of this.  (You are not allowed to C<open()> to a command
2194 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2195 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2196
2197 Opening C<'-'> opens STDIN and opening C<'E<gt>-'> opens STDOUT.  Open returns
2198 nonzero upon success, the undefined value otherwise.  If the C<open()>
2199 involved a pipe, the return value happens to be the pid of the
2200 subprocess.
2201
2202 If you're unfortunate enough to be running Perl on a system that
2203 distinguishes between text files and binary files (modern operating
2204 systems don't care), then you should check out L</binmode> for tips for
2205 dealing with this.  The key distinction between systems that need C<binmode()>
2206 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2207 Plan9, which delimit lines with a single character, and which encode that
2208 character in C as C<"\n">, do not need C<binmode()>.  The rest need it.
2209
2210 When opening a file, it's usually a bad idea to continue normal execution
2211 if the request failed, so C<open()> is frequently used in connection with
2212 C<die()>. Even if C<die()> won't do what you want (say, in a CGI script,
2213 where you want to make a nicely formatted error message (but there are
2214 modules that can help with that problem)) you should always check
2215 the return value from opening a file. The infrequent exception is when
2216 working with an unopened filehandle is actually what you want to do.
2217
2218 Examples:
2219
2220     $ARTICLE = 100;
2221     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2222     while (<ARTICLE>) {...
2223
2224     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
2225     # if the open fails, output is discarded
2226
2227     open(DBASE, '+<dbase.mine')             # open for update
2228         or die "Can't open 'dbase.mine' for update: $!";
2229
2230     open(ARTICLE, "caesar <$article |")     # decrypt article
2231         or die "Can't start caesar: $!";
2232
2233     open(EXTRACT, "|sort >/tmp/Tmp$$")      # $$ is our process id
2234         or die "Can't start sort: $!";
2235
2236     # process argument list of files along with any includes
2237
2238     foreach $file (@ARGV) {
2239         process($file, 'fh00');
2240     }
2241
2242     sub process {
2243         my($filename, $input) = @_;
2244         $input++;               # this is a string increment
2245         unless (open($input, $filename)) {
2246             print STDERR "Can't open $filename: $!\n";
2247             return;
2248         }
2249
2250         local $_;
2251         while (<$input>) {              # note use of indirection
2252             if (/^#include "(.*)"/) {
2253                 process($1, $input);
2254                 next;
2255             }
2256             #...                # whatever
2257         }
2258     }
2259
2260 You may also, in the Bourne shell tradition, specify an EXPR beginning
2261 with C<'E<gt>&'>, in which case the rest of the string is interpreted as the
2262 name of a filehandle (or file descriptor, if numeric) to be
2263 duped and opened.  You may use C<&> after C<E<gt>>, C<E<gt>E<gt>>, C<E<lt>>, C<+E<gt>>,
2264 C<+E<gt>E<gt>>, and C<+E<lt>>.  The
2265 mode you specify should match the mode of the original filehandle.
2266 (Duping a filehandle does not take into account any existing contents of
2267 stdio buffers.)
2268 Here is a script that saves, redirects, and restores STDOUT and
2269 STDERR:
2270
2271     #!/usr/bin/perl
2272     open(OLDOUT, ">&STDOUT");
2273     open(OLDERR, ">&STDERR");
2274
2275     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
2276     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
2277
2278     select(STDERR); $| = 1;     # make unbuffered
2279     select(STDOUT); $| = 1;     # make unbuffered
2280
2281     print STDOUT "stdout 1\n";  # this works for
2282     print STDERR "stderr 1\n";  # subprocesses too
2283
2284     close(STDOUT);
2285     close(STDERR);
2286
2287     open(STDOUT, ">&OLDOUT");
2288     open(STDERR, ">&OLDERR");
2289
2290     print STDOUT "stdout 2\n";
2291     print STDERR "stderr 2\n";
2292
2293
2294 If you specify C<'E<lt>&=N'>, where C<N> is a number, then Perl will do an
2295 equivalent of C's C<fdopen()> of that file descriptor; this is more
2296 parsimonious of file descriptors.  For example:
2297
2298     open(FILEHANDLE, "<&=$fd")
2299
2300 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>, then
2301 there is an implicit fork done, and the return value of open is the pid
2302 of the child within the parent process, and C<0> within the child
2303 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2304 The filehandle behaves normally for the parent, but i/o to that
2305 filehandle is piped from/to the STDOUT/STDIN of the child process.
2306 In the child process the filehandle isn't opened--i/o happens from/to
2307 the new STDOUT or STDIN.  Typically this is used like the normal
2308 piped open when you want to exercise more control over just how the
2309 pipe command gets executed, such as when you are running setuid, and
2310 don't want to have to scan shell commands for metacharacters.
2311 The following pairs are more or less equivalent:
2312
2313     open(FOO, "|tr '[a-z]' '[A-Z]'");
2314     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
2315
2316     open(FOO, "cat -n '$file'|");
2317     open(FOO, "-|") || exec 'cat', '-n', $file;
2318
2319 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2320
2321 NOTE: On any operation that may do a fork, any unflushed buffers remain
2322 unflushed in both processes, which means you may need to set C<$|> to
2323 avoid duplicate output.
2324
2325 Closing any piped filehandle causes the parent process to wait for the
2326 child to finish, and returns the status value in C<$?>.
2327
2328 The filename passed to open will have leading and trailing
2329 whitespace deleted, and the normal redirection characters
2330 honored.  This property, known as "magic open", 
2331 can often be used to good effect.  A user could specify a filename of
2332 F<"rsh cat file |">, or you could change certain filenames as needed:
2333
2334     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2335     open(FH, $filename) or die "Can't open $filename: $!";
2336
2337 However, to open a file with arbitrary weird characters in it, it's
2338 necessary to protect any leading and trailing whitespace:
2339
2340     $file =~ s#^(\s)#./$1#;
2341     open(FOO, "< $file\0");
2342
2343 If you want a "real" C C<open()> (see L<open(2)> on your system), then you
2344 should use the C<sysopen()> function, which involves no such magic.  This is
2345 another way to protect your filenames from interpretation.  For example:
2346
2347     use IO::Handle;
2348     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2349         or die "sysopen $path: $!";
2350     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2351     print HANDLE "stuff $$\n");
2352     seek(HANDLE, 0, 0);
2353     print "File contains: ", <HANDLE>;
2354
2355 Using the constructor from the C<IO::Handle> package (or one of its
2356 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2357 filehandles that have the scope of whatever variables hold references to
2358 them, and automatically close whenever and however you leave that scope:
2359
2360     use IO::File;
2361     #...
2362     sub read_myfile_munged {
2363         my $ALL = shift;
2364         my $handle = new IO::File;
2365         open($handle, "myfile") or die "myfile: $!";
2366         $first = <$handle>
2367             or return ();     # Automatically closed here.
2368         mung $first or die "mung failed";       # Or here.
2369         return $first, <$handle> if $ALL;       # Or here.
2370         $first;                                 # Or here.
2371     }
2372
2373 See L</seek()> for some details about mixing reading and writing.
2374
2375 =item opendir DIRHANDLE,EXPR
2376
2377 Opens a directory named EXPR for processing by C<readdir()>, C<telldir()>,
2378 C<seekdir()>, C<rewinddir()>, and C<closedir()>.  Returns TRUE if successful.
2379 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2380
2381 =item ord EXPR
2382
2383 =item ord
2384
2385 Returns the numeric ascii value of the first character of EXPR.  If
2386 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2387
2388 =item pack TEMPLATE,LIST
2389
2390 Takes an array or list of values and packs it into a binary structure,
2391 returning the string containing the structure.  The TEMPLATE is a
2392 sequence of characters that give the order and type of values, as
2393 follows:
2394
2395     A   An ascii string, will be space padded.
2396     a   An ascii string, will be null padded.
2397     b   A bit string (ascending bit order, like vec()).
2398     B   A bit string (descending bit order).
2399     h   A hex string (low nybble first).
2400     H   A hex string (high nybble first).
2401
2402     c   A signed char value.
2403     C   An unsigned char value.
2404
2405     s   A signed short value.
2406     S   An unsigned short value.
2407           (This 'short' is _exactly_ 16 bits, which may differ from
2408            what a local C compiler calls 'short'.)
2409
2410     i   A signed integer value.
2411     I   An unsigned integer value.
2412           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2413            size depends on what a local C compiler calls 'int',
2414            and may even be larger than the 'long' described in
2415            the next item.)
2416
2417     l   A signed long value.
2418     L   An unsigned long value.
2419           (This 'long' is _exactly_ 32 bits, which may differ from
2420            what a local C compiler calls 'long'.)
2421
2422     n   A short in "network" (big-endian) order.
2423     N   A long in "network" (big-endian) order.
2424     v   A short in "VAX" (little-endian) order.
2425     V   A long in "VAX" (little-endian) order.
2426           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2427            _exactly_ 32 bits, respectively.)
2428
2429     f   A single-precision float in the native format.
2430     d   A double-precision float in the native format.
2431
2432     p   A pointer to a null-terminated string.
2433     P   A pointer to a structure (fixed-length string).
2434
2435     u   A uuencoded string.
2436
2437     w   A BER compressed integer.  Its bytes represent an unsigned
2438         integer in base 128, most significant digit first, with as
2439         few digits as possible.  Bit eight (the high bit) is set
2440         on each byte except the last.
2441
2442     x   A null byte.
2443     X   Back up a byte.
2444     @   Null fill to absolute position.
2445
2446 Each letter may optionally be followed by a number giving a repeat
2447 count.  With all types except C<"a">, C<"A">, C<"b">, C<"B">, C<"h">, C<"H">, and C<"P"> the
2448 pack function will gobble up that many values from the LIST.  A C<*> for the
2449 repeat count means to use however many items are left.  The C<"a"> and C<"A">
2450 types gobble just one value, but pack it as a string of length count,
2451 padding with nulls or spaces as necessary.  (When unpacking, C<"A"> strips
2452 trailing spaces and nulls, but C<"a"> does not.)  Likewise, the C<"b"> and C<"B">
2453 fields pack a string that many bits long.  The C<"h"> and C<"H"> fields pack a
2454 string that many nybbles long.  The C<"p"> type packs a pointer to a null-
2455 terminated string.  You are responsible for ensuring the string is not a
2456 temporary value (which can potentially get deallocated before you get
2457 around to using the packed result).  The C<"P"> packs a pointer to a structure
2458 of the size indicated by the length. A NULL pointer is created if the 
2459 corresponding value for C<"p"> or C<"P"> is C<undef>.
2460 Real numbers (floats and doubles) are
2461 in the native machine format only; due to the multiplicity of floating
2462 formats around, and the lack of a standard "network" representation, no
2463 facility for interchange has been made.  This means that packed floating
2464 point data written on one machine may not be readable on another - even if
2465 both use IEEE floating point arithmetic (as the endian-ness of the memory
2466 representation is not part of the IEEE spec).  Note that Perl uses doubles
2467 internally for all numeric calculation, and converting from double into
2468 float and thence back to double again will lose precision (i.e.,
2469 C<unpack("f", pack("f", $foo)>) will not in general equal C<$foo>).
2470
2471 Examples:
2472
2473     $foo = pack("cccc",65,66,67,68);
2474     # foo eq "ABCD"
2475     $foo = pack("c4",65,66,67,68);
2476     # same thing
2477
2478     $foo = pack("ccxxcc",65,66,67,68);
2479     # foo eq "AB\0\0CD"
2480
2481     $foo = pack("s2",1,2);
2482     # "\1\0\2\0" on little-endian
2483     # "\0\1\0\2" on big-endian
2484
2485     $foo = pack("a4","abcd","x","y","z");
2486     # "abcd"
2487
2488     $foo = pack("aaaa","abcd","x","y","z");
2489     # "axyz"
2490
2491     $foo = pack("a14","abcdefg");
2492     # "abcdefg\0\0\0\0\0\0\0"
2493
2494     $foo = pack("i9pl", gmtime);
2495     # a real struct tm (on my system anyway)
2496
2497     sub bintodec {
2498         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2499     }
2500
2501 The same template may generally also be used in the unpack function.
2502
2503 =item package 
2504
2505 =item package NAMESPACE
2506
2507 Declares the compilation unit as being in the given namespace.  The scope
2508 of the package declaration is from the declaration itself through the end of
2509 the enclosing block (the same scope as the C<local()> operator).  All further
2510 unqualified dynamic identifiers will be in this namespace.  A package
2511 statement affects only dynamic variables--including those you've used
2512 C<local()> on--but I<not> lexical variables created with C<my()>.  Typically it
2513 would be the first declaration in a file to be included by the C<require>
2514 or C<use> operator.  You can switch into a package in more than one place;
2515 it merely influences which symbol table is used by the compiler for the
2516 rest of that block.  You can refer to variables and filehandles in other
2517 packages by prefixing the identifier with the package name and a double
2518 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2519 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2520
2521 If NAMESPACE is omitted, then there is no current package, and all
2522 identifiers must be fully qualified or lexicals.  This is stricter
2523 than C<use strict>, since it also extends to function names.
2524
2525 See L<perlmod/"Packages"> for more information about packages, modules,
2526 and classes.  See L<perlsub> for other scoping issues.
2527
2528 =item pipe READHANDLE,WRITEHANDLE
2529
2530 Opens a pair of connected pipes like the corresponding system call.
2531 Note that if you set up a loop of piped processes, deadlock can occur
2532 unless you are very careful.  In addition, note that Perl's pipes use
2533 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2534 after each command, depending on the application.
2535
2536 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2537 for examples of such things.
2538
2539 =item pop ARRAY
2540
2541 =item pop
2542
2543 Pops and returns the last value of the array, shortening the array by
2544 1.  Has a similar effect to
2545
2546     $tmp = $ARRAY[$#ARRAY--];
2547
2548 If there are no elements in the array, returns the undefined value.
2549 If ARRAY is omitted, pops the
2550 C<@ARGV> array in the main program, and the C<@_> array in subroutines, just
2551 like C<shift()>.
2552
2553 =item pos SCALAR
2554
2555 =item pos
2556
2557 Returns the offset of where the last C<m//g> search left off for the variable
2558 is in question (C<$_> is used when the variable is not specified).  May be
2559 modified to change that offset.  Such modification will also influence
2560 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
2561 L<perlop>.
2562
2563 =item print FILEHANDLE LIST
2564
2565 =item print LIST
2566
2567 =item print
2568
2569 Prints a string or a comma-separated list of strings.  Returns TRUE
2570 if successful.  FILEHANDLE may be a scalar variable name, in which case
2571 the variable contains the name of or a reference to the filehandle, thus introducing one
2572 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2573 token is a term, it may be misinterpreted as an operator unless you
2574 interpose a C<+> or put parentheses around the arguments.)  If FILEHANDLE is
2575 omitted, prints by default to standard output (or to the last selected
2576 output channel--see L</select>).  If LIST is also omitted, prints C<$_> to
2577 the currently selected output channel.  To set the default output channel to something other than
2578 STDOUT use the select operation.  Note that, because print takes a
2579 LIST, anything in the LIST is evaluated in list context, and any
2580 subroutine that you call will have one or more of its expressions
2581 evaluated in list context.  Also be careful not to follow the print
2582 keyword with a left parenthesis unless you want the corresponding right
2583 parenthesis to terminate the arguments to the print--interpose a C<+> or
2584 put parentheses around all the arguments.
2585
2586 Note that if you're storing FILEHANDLES in an array or other expression,
2587 you will have to use a block returning its value instead:
2588
2589     print { $files[$i] } "stuff\n";
2590     print { $OK ? STDOUT : STDERR } "stuff\n";
2591
2592 =item printf FILEHANDLE FORMAT, LIST
2593
2594 =item printf FORMAT, LIST
2595
2596 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
2597 (the output record separator) is not appended.  The first argument
2598 of the list will be interpreted as the C<printf()> format.  If C<use locale> is
2599 in effect, the character used for the decimal point in formatted real numbers
2600 is affected by the LC_NUMERIC locale.  See L<perllocale>.
2601
2602 Don't fall into the trap of using a C<printf()> when a simple
2603 C<print()> would do.  The C<print()> is more efficient and less
2604 error prone.
2605
2606 =item prototype FUNCTION
2607
2608 Returns the prototype of a function as a string (or C<undef> if the
2609 function has no prototype).  FUNCTION is a reference to, or the name of,
2610 the function whose prototype you want to retrieve.
2611
2612 If FUNCTION is a string starting with C<CORE::>, the rest is taken as
2613 a name for Perl builtin.  If builtin is not I<overridable> (such as
2614 C<qw//>) or its arguments cannot be expressed by a prototype (such as
2615 C<system()>) - in other words, the builtin does not behave like a Perl
2616 function - returns C<undef>.  Otherwise, the string describing the
2617 equivalent prototype is returned.
2618
2619 =item push ARRAY,LIST
2620
2621 Treats ARRAY as a stack, and pushes the values of LIST
2622 onto the end of ARRAY.  The length of ARRAY increases by the length of
2623 LIST.  Has the same effect as
2624
2625     for $value (LIST) {
2626         $ARRAY[++$#ARRAY] = $value;
2627     }
2628
2629 but is more efficient.  Returns the new number of elements in the array.
2630
2631 =item q/STRING/
2632
2633 =item qq/STRING/
2634
2635 =item qr/STRING/
2636
2637 =item qx/STRING/
2638
2639 =item qw/STRING/
2640
2641 Generalized quotes.  See L<perlop>.
2642
2643 =item quotemeta EXPR
2644
2645 =item quotemeta
2646
2647 Returns the value of EXPR with all non-alphanumeric
2648 characters backslashed.  (That is, all characters not matching
2649 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
2650 returned string, regardless of any locale settings.)
2651 This is the internal function implementing
2652 the C<\Q> escape in double-quoted strings.
2653
2654 If EXPR is omitted, uses C<$_>.
2655
2656 =item rand EXPR
2657
2658 =item rand
2659
2660 Returns a random fractional number greater than or equal to C<0> and less
2661 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
2662 omitted, the value C<1> is used.  Automatically calls C<srand()> unless
2663 C<srand()> has already been called.  See also C<srand()>.
2664
2665 (Note: If your rand function consistently returns numbers that are too
2666 large or too small, then your version of Perl was probably compiled
2667 with the wrong number of RANDBITS.)
2668
2669 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2670
2671 =item read FILEHANDLE,SCALAR,LENGTH
2672
2673 Attempts to read LENGTH bytes of data into variable SCALAR from the
2674 specified FILEHANDLE.  Returns the number of bytes actually read,
2675 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
2676 or shrunk to the length actually read.  An OFFSET may be specified to
2677 place the read data at some other place than the beginning of the
2678 string.  This call is actually implemented in terms of stdio's fread(3)
2679 call.  To get a true read(2) system call, see C<sysread()>.
2680
2681 =item readdir DIRHANDLE
2682
2683 Returns the next directory entry for a directory opened by C<opendir()>.
2684 If used in list context, returns all the rest of the entries in the
2685 directory.  If there are no more entries, returns an undefined value in
2686 scalar context or a null list in list context.
2687
2688 If you're planning to filetest the return values out of a C<readdir()>, you'd
2689 better prepend the directory in question.  Otherwise, because we didn't
2690 C<chdir()> there, it would have been testing the wrong file.
2691
2692     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2693     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2694     closedir DIR;
2695
2696 =item readline EXPR
2697
2698 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar context, a single line
2699 is read and returned.  In list context, reads until end-of-file is
2700 reached and returns a list of lines (however you've defined lines
2701 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2702 This is the internal function implementing the C<E<lt>EXPRE<gt>>
2703 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
2704 operator is discussed in more detail in L<perlop/"I/O Operators">.
2705
2706     $line = <STDIN>;
2707     $line = readline(*STDIN);           # same thing
2708
2709 =item readlink EXPR
2710
2711 =item readlink
2712
2713 Returns the value of a symbolic link, if symbolic links are
2714 implemented.  If not, gives a fatal error.  If there is some system
2715 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2716 omitted, uses C<$_>.
2717
2718 =item readpipe EXPR
2719
2720 EXPR is executed as a system command.
2721 The collected standard output of the command is returned.
2722 In scalar context, it comes back as a single (potentially
2723 multi-line) string.  In list context, returns a list of lines
2724 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2725 This is the internal function implementing the C<qx/EXPR/>
2726 operator, but you can use it directly.  The C<qx/EXPR/>
2727 operator is discussed in more detail in L<perlop/"I/O Operators">.
2728
2729 =item recv SOCKET,SCALAR,LEN,FLAGS
2730
2731 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2732 data into variable SCALAR from the specified SOCKET filehandle.
2733 Actually does a C C<recvfrom()>, so that it can return the address of the
2734 sender.  Returns the undefined value if there's an error.  SCALAR will
2735 be grown or shrunk to the length actually read.  Takes the same flags
2736 as the system call of the same name.
2737 See L<perlipc/"UDP: Message Passing"> for examples.
2738
2739 =item redo LABEL
2740
2741 =item redo
2742
2743 The C<redo> command restarts the loop block without evaluating the
2744 conditional again.  The C<continue> block, if any, is not executed.  If
2745 the LABEL is omitted, the command refers to the innermost enclosing
2746 loop.  This command is normally used by programs that want to lie to
2747 themselves about what was just input:
2748
2749     # a simpleminded Pascal comment stripper
2750     # (warning: assumes no { or } in strings)
2751     LINE: while (<STDIN>) {
2752         while (s|({.*}.*){.*}|$1 |) {}
2753         s|{.*}| |;
2754         if (s|{.*| |) {
2755             $front = $_;
2756             while (<STDIN>) {
2757                 if (/}/) {      # end of comment?
2758                     s|^|$front\{|;
2759                     redo LINE;
2760                 }
2761             }
2762         }
2763         print;
2764     }
2765
2766 See also L</continue> for an illustration of how C<last>, C<next>, and
2767 C<redo> work.
2768
2769 =item ref EXPR
2770
2771 =item ref
2772
2773 Returns a TRUE value if EXPR is a reference, FALSE otherwise.  If EXPR
2774 is not specified, C<$_> will be used.  The value returned depends on the
2775 type of thing the reference is a reference to.
2776 Builtin types include:
2777
2778     REF
2779     SCALAR
2780     ARRAY
2781     HASH
2782     CODE
2783     GLOB
2784
2785 If the referenced object has been blessed into a package, then that package
2786 name is returned instead.  You can think of C<ref()> as a C<typeof()> operator.
2787
2788     if (ref($r) eq "HASH") {
2789         print "r is a reference to a hash.\n";
2790     }
2791     if (!ref($r)) {
2792         print "r is not a reference at all.\n";
2793     }
2794
2795 See also L<perlref>.
2796
2797 =item rename OLDNAME,NEWNAME
2798
2799 Changes the name of a file.  Returns C<1> for success, C<0> otherwise.  Will
2800 not work across file system boundaries.
2801
2802 =item require EXPR
2803
2804 =item require
2805
2806 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
2807 supplied.  If EXPR is numeric, demands that the current version of Perl
2808 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2809
2810 Otherwise, demands that a library file be included if it hasn't already
2811 been included.  The file is included via the do-FILE mechanism, which is
2812 essentially just a variety of C<eval()>.  Has semantics similar to the following
2813 subroutine:
2814
2815     sub require {
2816         my($filename) = @_;
2817         return 1 if $INC{$filename};
2818         my($realfilename,$result);
2819         ITER: {
2820             foreach $prefix (@INC) {
2821                 $realfilename = "$prefix/$filename";
2822                 if (-f $realfilename) {
2823                     $result = do $realfilename;
2824                     last ITER;
2825                 }
2826             }
2827             die "Can't find $filename in \@INC";
2828         }
2829         die $@ if $@;
2830         die "$filename did not return true value" unless $result;
2831         $INC{$filename} = $realfilename;
2832         return $result;
2833     }
2834
2835 Note that the file will not be included twice under the same specified
2836 name.  The file must return TRUE as the last statement to indicate
2837 successful execution of any initialization code, so it's customary to
2838 end such a file with "C<1;>" unless you're sure it'll return TRUE
2839 otherwise.  But it's better just to put the "C<1;>", in case you add more
2840 statements.
2841
2842 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
2843 replaces "F<::>" with "F</>" in the filename for you,
2844 to make it easy to load standard modules.  This form of loading of
2845 modules does not risk altering your namespace.
2846
2847 In other words, if you try this:
2848
2849         require Foo::Bar;    # a splendid bareword 
2850
2851 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
2852 directories specified in the C<@INC> array.
2853
2854 But if you try this:
2855
2856         $class = 'Foo::Bar';
2857         require $class;      # $class is not a bareword
2858     #or
2859         require "Foo::Bar";  # not a bareword because of the ""
2860
2861 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
2862 will complain about not finding "F<Foo::Bar>" there. In this case you can do:
2863
2864         eval "require $class";
2865
2866 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
2867
2868 =item reset EXPR
2869
2870 =item reset
2871
2872 Generally used in a C<continue> block at the end of a loop to clear
2873 variables and reset C<??> searches so that they work again.  The
2874 expression is interpreted as a list of single characters (hyphens
2875 allowed for ranges).  All variables and arrays beginning with one of
2876 those letters are reset to their pristine state.  If the expression is
2877 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
2878 only variables or searches in the current package.  Always returns
2879 1.  Examples:
2880
2881     reset 'X';          # reset all X variables
2882     reset 'a-z';        # reset lower case variables
2883     reset;              # just reset ?? searches
2884
2885 Resetting C<"A-Z"> is not recommended because you'll wipe out your
2886 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package variables--lexical variables
2887 are unaffected, but they clean themselves up on scope exit anyway,
2888 so you'll probably want to use them instead.  See L</my>.
2889
2890 =item return EXPR
2891
2892 =item return
2893
2894 Returns from a subroutine, C<eval()>, or C<do FILE> with the value 
2895 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
2896 context, depending on how the return value will be used, and the context
2897 may vary from one execution to the next (see C<wantarray()>).  If no EXPR
2898 is given, returns an empty list in list context, an undefined value in
2899 scalar context, or nothing in a void context.
2900
2901 (Note that in the absence of a return, a subroutine, eval, or do FILE
2902 will automatically return the value of the last expression evaluated.)
2903
2904 =item reverse LIST
2905
2906 In list context, returns a list value consisting of the elements
2907 of LIST in the opposite order.  In scalar context, concatenates the
2908 elements of LIST, and returns a string value consisting of those bytes,
2909 but in the opposite order.
2910
2911     print reverse <>;           # line tac, last line first
2912
2913     undef $/;                   # for efficiency of <>
2914     print scalar reverse <>;    # byte tac, last line tsrif
2915
2916 This operator is also handy for inverting a hash, although there are some
2917 caveats.  If a value is duplicated in the original hash, only one of those
2918 can be represented as a key in the inverted hash.  Also, this has to
2919 unwind one hash and build a whole new one, which may take some time
2920 on a large hash.
2921
2922     %by_name = reverse %by_address;     # Invert the hash
2923
2924 =item rewinddir DIRHANDLE
2925
2926 Sets the current position to the beginning of the directory for the
2927 C<readdir()> routine on DIRHANDLE.
2928
2929 =item rindex STR,SUBSTR,POSITION
2930
2931 =item rindex STR,SUBSTR
2932
2933 Works just like index except that it returns the position of the LAST
2934 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
2935 last occurrence at or before that position.
2936
2937 =item rmdir FILENAME
2938
2939 =item rmdir
2940
2941 Deletes the directory specified by FILENAME if that directory is empty.  If it
2942 succeeds it returns TRUE, otherwise it returns FALSE and sets C<$!> (errno).  If
2943 FILENAME is omitted, uses C<$_>.
2944
2945 =item s///
2946
2947 The substitution operator.  See L<perlop>.
2948
2949 =item scalar EXPR
2950
2951 Forces EXPR to be interpreted in scalar context and returns the value
2952 of EXPR.
2953
2954     @counts = ( scalar @a, scalar @b, scalar @c );
2955
2956 There is no equivalent operator to force an expression to
2957 be interpolated in list context because it's in practice never
2958 needed.  If you really wanted to do so, however, you could use
2959 the construction C<@{[ (some expression) ]}>, but usually a simple
2960 C<(some expression)> suffices.
2961
2962 =item seek FILEHANDLE,POSITION,WHENCE
2963
2964 Sets FILEHANDLE's position, just like the C<fseek()> call of C<stdio()>.
2965 FILEHANDLE may be an expression whose value gives the name of the
2966 filehandle.  The values for WHENCE are C<0> to set the new position to
2967 POSITION, C<1> to set it to the current position plus POSITION, and C<2> to
2968 set it to EOF plus POSITION (typically negative).  For WHENCE you may
2969 use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END> from either the
2970 C<IO::Seekable> or the POSIX module.  Returns C<1> upon success, C<0> otherwise.
2971
2972 If you want to position file for C<sysread()> or C<syswrite()>, don't use
2973 C<seek()> -- buffering makes its effect on the file's system position
2974 unpredictable and non-portable.  Use C<sysseek()> instead.
2975
2976 On some systems you have to do a seek whenever you switch between reading
2977 and writing.  Amongst other things, this may have the effect of calling
2978 stdio's clearerr(3).  A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving
2979 the file position:
2980
2981     seek(TEST,0,1);
2982
2983 This is also useful for applications emulating C<tail -f>.  Once you hit
2984 EOF on your read, and then sleep for a while, you might have to stick in a
2985 seek() to reset things.  The C<seek()> doesn't change the current position,
2986 but it I<does> clear the end-of-file condition on the handle, so that the
2987 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
2988
2989 If that doesn't work (some stdios are particularly cantankerous), then
2990 you may need something more like this:
2991
2992     for (;;) {
2993         for ($curpos = tell(FILE); $_ = <FILE>;
2994              $curpos = tell(FILE)) {
2995             # search for some stuff and put it into files
2996         }
2997         sleep($for_a_while);
2998         seek(FILE, $curpos, 0);
2999     }
3000
3001 =item seekdir DIRHANDLE,POS
3002
3003 Sets the current position for the C<readdir()> routine on DIRHANDLE.  POS
3004 must be a value returned by C<telldir()>.  Has the same caveats about
3005 possible directory compaction as the corresponding system library
3006 routine.
3007
3008 =item select FILEHANDLE
3009
3010 =item select
3011
3012 Returns the currently selected filehandle.  Sets the current default
3013 filehandle for output, if FILEHANDLE is supplied.  This has two
3014 effects: first, a C<write()> or a C<print()> without a filehandle will
3015 default to this FILEHANDLE.  Second, references to variables related to
3016 output will refer to this output channel.  For example, if you have to
3017 set the top of form format for more than one output channel, you might
3018 do the following:
3019
3020     select(REPORT1);
3021     $^ = 'report1_top';
3022     select(REPORT2);
3023     $^ = 'report2_top';
3024
3025 FILEHANDLE may be an expression whose value gives the name of the
3026 actual filehandle.  Thus:
3027
3028     $oldfh = select(STDERR); $| = 1; select($oldfh);
3029
3030 Some programmers may prefer to think of filehandles as objects with
3031 methods, preferring to write the last example as:
3032
3033     use IO::Handle;
3034     STDERR->autoflush(1);
3035
3036 =item select RBITS,WBITS,EBITS,TIMEOUT
3037
3038 This calls the select(2) system call with the bit masks specified, which
3039 can be constructed using C<fileno()> and C<vec()>, along these lines:
3040
3041     $rin = $win = $ein = '';
3042     vec($rin,fileno(STDIN),1) = 1;
3043     vec($win,fileno(STDOUT),1) = 1;
3044     $ein = $rin | $win;
3045
3046 If you want to select on many filehandles you might wish to write a
3047 subroutine:
3048
3049     sub fhbits {
3050         my(@fhlist) = split(' ',$_[0]);
3051         my($bits);
3052         for (@fhlist) {
3053             vec($bits,fileno($_),1) = 1;
3054         }
3055         $bits;
3056     }
3057     $rin = fhbits('STDIN TTY SOCK');
3058
3059 The usual idiom is:
3060
3061     ($nfound,$timeleft) =
3062       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3063
3064 or to block until something becomes ready just do this
3065
3066     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3067
3068 Most systems do not bother to return anything useful in C<$timeleft>, so
3069 calling select() in scalar context just returns C<$nfound>.
3070
3071 Any of the bit masks can also be undef.  The timeout, if specified, is
3072 in seconds, which may be fractional.  Note: not all implementations are
3073 capable of returning theC<$timeleft>.  If not, they always return
3074 C<$timeleft> equal to the supplied C<$timeout>.
3075
3076 You can effect a sleep of 250 milliseconds this way:
3077
3078     select(undef, undef, undef, 0.25);
3079
3080 B<WARNING>: One should not attempt to mix buffered I/O (like C<read()>
3081 or E<lt>FHE<gt>) with C<select()>, except as permitted by POSIX, and even
3082 then only on POSIX systems.  You have to use C<sysread()> instead.
3083
3084 =item semctl ID,SEMNUM,CMD,ARG
3085
3086 Calls the System V IPC function C<semctl()>.  You'll probably have to say
3087
3088     use IPC::SysV;
3089
3090 first to get the correct constant definitions.  If CMD is IPC_STAT or
3091 GETALL, then ARG must be a variable which will hold the returned
3092 semid_ds structure or semaphore value array.  Returns like C<ioctl()>: the
3093 undefined value for error, "C<0> but true" for zero, or the actual return
3094 value otherwise.  See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3095
3096 =item semget KEY,NSEMS,FLAGS
3097
3098 Calls the System V IPC function semget.  Returns the semaphore id, or
3099 the undefined value if there is an error.  See also C<IPC::SysV> and
3100 C<IPC::SysV::Semaphore> documentation.
3101
3102 =item semop KEY,OPSTRING
3103
3104 Calls the System V IPC function semop to perform semaphore operations
3105 such as signaling and waiting.  OPSTRING must be a packed array of
3106 semop structures.  Each semop structure can be generated with
3107 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3108 operations is implied by the length of OPSTRING.  Returns TRUE if
3109 successful, or FALSE if there is an error.  As an example, the
3110 following code waits on semaphore C<$semnum> of semaphore id C<$semid>:
3111
3112     $semop = pack("sss", $semnum, -1, 0);
3113     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3114
3115 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3116 and C<IPC::SysV::Semaphore> documentation.
3117
3118 =item send SOCKET,MSG,FLAGS,TO
3119
3120 =item send SOCKET,MSG,FLAGS
3121
3122 Sends a message on a socket.  Takes the same flags as the system call
3123 of the same name.  On unconnected sockets you must specify a
3124 destination to send TO, in which case it does a C C<sendto()>.  Returns
3125 the number of characters sent, or the undefined value if there is an
3126 error.
3127 See L<perlipc/"UDP: Message Passing"> for examples.
3128
3129 =item setpgrp PID,PGRP
3130
3131 Sets the current process group for the specified PID, C<0> for the current
3132 process.  Will produce a fatal error if used on a machine that doesn't
3133 implement setpgrp(2).  If the arguments are omitted, it defaults to
3134 C<0,0>.  Note that the POSIX version of C<setpgrp()> does not accept any
3135 arguments, so only setpgrp C<0,0> is portable.
3136
3137 =item setpriority WHICH,WHO,PRIORITY
3138
3139 Sets the current priority for a process, a process group, or a user.
3140 (See setpriority(2).)  Will produce a fatal error if used on a machine
3141 that doesn't implement setpriority(2).
3142
3143 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3144
3145 Sets the socket option requested.  Returns undefined if there is an
3146 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3147 argument.
3148
3149 =item shift ARRAY
3150
3151 =item shift
3152
3153 Shifts the first value of the array off and returns it, shortening the
3154 array by 1 and moving everything down.  If there are no elements in the
3155 array, returns the undefined value.  If ARRAY is omitted, shifts the
3156 C<@_> array within the lexical scope of subroutines and formats, and the
3157 C<@ARGV> array at file scopes or within the lexical scopes established by
3158 the C<eval ''>, C<BEGIN {}>, C<END {}>, and C<INIT {}> constructs.
3159 See also C<unshift()>, C<push()>, and C<pop()>.  C<Shift()> and C<unshift()> do the
3160 same thing to the left end of an array that C<pop()> and C<push()> do to the
3161 right end.
3162
3163 =item shmctl ID,CMD,ARG
3164
3165 Calls the System V IPC function shmctl.  You'll probably have to say
3166
3167     use IPC::SysV;
3168
3169 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3170 then ARG must be a variable which will hold the returned C<shmid_ds>
3171 structure.  Returns like ioctl: the undefined value for error, "C<0> but
3172 true" for zero, or the actual return value otherwise.
3173 See also C<IPC::SysV> documentation.
3174
3175 =item shmget KEY,SIZE,FLAGS
3176
3177 Calls the System V IPC function shmget.  Returns the shared memory
3178 segment id, or the undefined value if there is an error.
3179 See also C<IPC::SysV> documentation.
3180
3181 =item shmread ID,VAR,POS,SIZE
3182
3183 =item shmwrite ID,STRING,POS,SIZE
3184
3185 Reads or writes the System V shared memory segment ID starting at
3186 position POS for size SIZE by attaching to it, copying in/out, and
3187 detaching from it.  When reading, VAR must be a variable that will
3188 hold the data read.  When writing, if STRING is too long, only SIZE
3189 bytes are used; if STRING is too short, nulls are written to fill out
3190 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
3191 See also C<IPC::SysV> documentation.
3192
3193 =item shutdown SOCKET,HOW
3194
3195 Shuts down a socket connection in the manner indicated by HOW, which
3196 has the same interpretation as in the system call of the same name.
3197
3198     shutdown(SOCKET, 0);    # I/we have stopped reading data
3199     shutdown(SOCKET, 1);    # I/we have stopped writing data
3200     shutdown(SOCKET, 2);    # I/we have stopped using this socket
3201
3202 This is useful with sockets when you want to tell the other
3203 side you're done writing but not done reading, or vice versa.
3204 It's also a more insistent form of close because it also 
3205 disables the filedescriptor in any forked copies in other
3206 processes.
3207
3208 =item sin EXPR
3209
3210 =item sin
3211
3212 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
3213 returns sine of C<$_>.
3214
3215 For the inverse sine operation, you may use the C<POSIX::asin()>
3216 function, or use this relation:
3217
3218     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
3219
3220 =item sleep EXPR
3221
3222 =item sleep
3223
3224 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
3225 May be interrupted if the process receives a signal such as C<SIGALRM>.
3226 Returns the number of seconds actually slept.  You probably cannot
3227 mix C<alarm()> and C<sleep()> calls, because C<sleep()> is often implemented
3228 using C<alarm()>.
3229
3230 On some older systems, it may sleep up to a full second less than what
3231 you requested, depending on how it counts seconds.  Most modern systems
3232 always sleep the full amount.  They may appear to sleep longer than that,
3233 however, because your process might not be scheduled right away in a
3234 busy multitasking system.
3235
3236 For delays of finer granularity than one second, you may use Perl's
3237 C<syscall()> interface to access setitimer(2) if your system supports it,
3238 or else see L</select()> above.
3239
3240 See also the POSIX module's C<sigpause()> function.
3241
3242 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
3243
3244 Opens a socket of the specified kind and attaches it to filehandle
3245 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
3246 system call of the same name.  You should "C<use Socket;>" first to get
3247 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
3248
3249 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
3250
3251 Creates an unnamed pair of sockets in the specified domain, of the
3252 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
3253 for the system call of the same name.  If unimplemented, yields a fatal
3254 error.  Returns TRUE if successful.
3255
3256 Some systems defined C<pipe()> in terms of C<socketpair()>, in which a call
3257 to C<pipe(Rdr, Wtr)> is essentially:
3258
3259     use Socket;
3260     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
3261     shutdown(Rdr, 1);        # no more writing for reader
3262     shutdown(Wtr, 0);        # no more reading for writer
3263
3264 See L<perlipc> for an example of socketpair use.
3265
3266 =item sort SUBNAME LIST
3267
3268 =item sort BLOCK LIST
3269
3270 =item sort LIST
3271
3272 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
3273 is omitted, C<sort()>s in standard string comparison order.  If SUBNAME is
3274 specified, it gives the name of a subroutine that returns an integer
3275 less than, equal to, or greater than C<0>, depending on how the elements
3276 of the array are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
3277 operators are extremely useful in such routines.)  SUBNAME may be a
3278 scalar variable name (unsubscripted), in which case the value provides
3279 the name of (or a reference to) the actual subroutine to use.  In place
3280 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
3281 subroutine.
3282
3283 In the interests of efficiency the normal calling code for subroutines is
3284 bypassed, with the following effects: the subroutine may not be a
3285 recursive subroutine, and the two elements to be compared are passed into
3286 the subroutine not via C<@_> but as the package global variables C<$a> and
3287 C<$b> (see example below).  They are passed by reference, so don't
3288 modify C<$a> and C<$b>.  And don't try to declare them as lexicals either.
3289
3290 You also cannot exit out of the sort block or subroutine using any of the
3291 loop control operators described in L<perlsyn> or with C<goto()>.
3292
3293 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
3294 current collation locale.  See L<perllocale>.
3295
3296 Examples:
3297
3298     # sort lexically
3299     @articles = sort @files;
3300
3301     # same thing, but with explicit sort routine
3302     @articles = sort {$a cmp $b} @files;
3303
3304     # now case-insensitively
3305     @articles = sort {uc($a) cmp uc($b)} @files;
3306
3307     # same thing in reversed order
3308     @articles = sort {$b cmp $a} @files;
3309
3310     # sort numerically ascending
3311     @articles = sort {$a <=> $b} @files;
3312
3313     # sort numerically descending
3314     @articles = sort {$b <=> $a} @files;
3315
3316     # sort using explicit subroutine name
3317     sub byage {
3318         $age{$a} <=> $age{$b};  # presuming numeric
3319     }
3320     @sortedclass = sort byage @class;
3321
3322     # this sorts the %age hash by value instead of key
3323     # using an in-line function
3324     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
3325
3326     sub backwards { $b cmp $a; }
3327     @harry = ('dog','cat','x','Cain','Abel');
3328     @george = ('gone','chased','yz','Punished','Axed');
3329     print sort @harry;
3330             # prints AbelCaincatdogx
3331     print sort backwards @harry;
3332             # prints xdogcatCainAbel
3333     print sort @george, 'to', @harry;
3334             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
3335
3336     # inefficiently sort by descending numeric compare using
3337     # the first integer after the first = sign, or the
3338     # whole record case-insensitively otherwise
3339
3340     @new = sort {
3341         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
3342                             ||
3343                     uc($a)  cmp  uc($b)
3344     } @old;
3345
3346     # same thing, but much more efficiently;
3347     # we'll build auxiliary indices instead
3348     # for speed
3349     @nums = @caps = ();
3350     for (@old) {
3351         push @nums, /=(\d+)/;
3352         push @caps, uc($_);
3353     }
3354
3355     @new = @old[ sort {
3356                         $nums[$b] <=> $nums[$a]
3357                                  ||
3358                         $caps[$a] cmp $caps[$b]
3359                        } 0..$#old
3360                ];
3361
3362     # same thing using a Schwartzian Transform (no temps)
3363     @new = map { $_->[0] }
3364         sort { $b->[1] <=> $a->[1]
3365                         ||
3366                $a->[2] cmp $b->[2]
3367         } map { [$_, /=(\d+)/, uc($_)] } @old;
3368
3369 If you're using strict, you I<MUST NOT> declare C<$a>
3370 and C<$b> as lexicals.  They are package globals.  That means
3371 if you're in the C<main> package, it's
3372
3373     @articles = sort {$main::b <=> $main::a} @files;
3374
3375 or just
3376
3377     @articles = sort {$::b <=> $::a} @files;
3378
3379 but if you're in the C<FooPack> package, it's
3380
3381     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
3382
3383 The comparison function is required to behave.  If it returns
3384 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
3385 sometimes saying the opposite, for example) the results are not
3386 well-defined.
3387
3388 =item splice ARRAY,OFFSET,LENGTH,LIST
3389
3390 =item splice ARRAY,OFFSET,LENGTH
3391
3392 =item splice ARRAY,OFFSET
3393
3394 Removes the elements designated by OFFSET and LENGTH from an array, and
3395 replaces them with the elements of LIST, if any.  In list context,
3396 returns the elements removed from the array.  In scalar context,
3397 returns the last element removed, or C<undef> if no elements are
3398 removed.  The array grows or shrinks as necessary.
3399 If OFFSET is negative then it start that far from the end of the array.
3400 If LENGTH is omitted, removes everything from OFFSET onward.
3401 If LENGTH is negative, leave that many elements off the end of the array.
3402 The following equivalences hold (assuming C<$[ == 0>):
3403
3404     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
3405     pop(@a)             splice(@a,-1)
3406     shift(@a)           splice(@a,0,1)
3407     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
3408     $a[$x] = $y         splice(@a,$x,1,$y)
3409
3410 Example, assuming array lengths are passed before arrays:
3411
3412     sub aeq {   # compare two list values
3413         my(@a) = splice(@_,0,shift);
3414         my(@b) = splice(@_,0,shift);
3415         return 0 unless @a == @b;       # same len?
3416         while (@a) {
3417             return 0 if pop(@a) ne pop(@b);
3418         }
3419         return 1;
3420     }
3421     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
3422
3423 =item split /PATTERN/,EXPR,LIMIT
3424
3425 =item split /PATTERN/,EXPR
3426
3427 =item split /PATTERN/
3428
3429 =item split
3430
3431 Splits a string into an array of strings, and returns it.  By default,
3432 empty leading fields are preserved, and empty trailing ones are deleted.
3433
3434 If not in list context, returns the number of fields found and splits into
3435 the C<@_> array.  (In list context, you can force the split into C<@_> by
3436 using C<??> as the pattern delimiters, but it still returns the list
3437 value.)  The use of implicit split to C<@_> is deprecated, however, because
3438 it clobbers your subroutine arguments.
3439
3440 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
3441 splits on whitespace (after skipping any leading whitespace).  Anything
3442 matching PATTERN is taken to be a delimiter separating the fields.  (Note
3443 that the delimiter may be longer than one character.)
3444
3445 If LIMIT is specified and positive, splits into no more than that
3446 many fields (though it may split into fewer).  If LIMIT is unspecified
3447 or zero, trailing null fields are stripped (which potential users
3448 of C<pop()> would do well to remember).  If LIMIT is negative, it is
3449 treated as if an arbitrarily large LIMIT had been specified.
3450
3451 A pattern matching the null string (not to be confused with
3452 a null pattern C<//>, which is just one member of the set of patterns
3453 matching a null string) will split the value of EXPR into separate
3454 characters at each point it matches that way.  For example:
3455
3456     print join(':', split(/ */, 'hi there'));
3457
3458 produces the output 'h:i:t:h:e:r:e'.
3459
3460 The LIMIT parameter can be used to split a line partially
3461
3462     ($login, $passwd, $remainder) = split(/:/, $_, 3);
3463
3464 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
3465 one larger than the number of variables in the list, to avoid
3466 unnecessary work.  For the list above LIMIT would have been 4 by
3467 default.  In time critical applications it behooves you not to split
3468 into more fields than you really need.
3469
3470 If the PATTERN contains parentheses, additional array elements are
3471 created from each matching substring in the delimiter.
3472
3473     split(/([,-])/, "1-10,20", 3);
3474
3475 produces the list value
3476
3477     (1, '-', 10, ',', 20)
3478
3479 If you had the entire header of a normal Unix email message in C<$header>,
3480 you could split it up into fields and their values this way:
3481
3482     $header =~ s/\n\s+/ /g;  # fix continuation lines
3483     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
3484
3485 The pattern C</PATTERN/> may be replaced with an expression to specify
3486 patterns that vary at runtime.  (To do runtime compilation only once,
3487 use C</$variable/o>.)
3488
3489 As a special case, specifying a PATTERN of space (C<' '>) will split on
3490 white space just as C<split()> with no arguments does.  Thus, C<split(' ')> can
3491 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
3492 will give you as many null initial fields as there are leading spaces.
3493 A C<split()> on C</\s+/> is like a C<split(' ')> except that any leading
3494 whitespace produces a null first field.  A C<split()> with no arguments
3495 really does a C<split(' ', $_)> internally.
3496
3497 Example:
3498
3499     open(PASSWD, '/etc/passwd');
3500     while (<PASSWD>) {
3501         ($login, $passwd, $uid, $gid,
3502          $gcos, $home, $shell) = split(/:/);
3503         #...
3504     }
3505
3506 (Note that C<$shell> above will still have a newline on it.  See L</chop>,
3507 L</chomp>, and L</join>.)
3508
3509 =item sprintf FORMAT, LIST
3510
3511 Returns a string formatted by the usual C<printf()> conventions of the
3512 C library function C<sprintf()>.  See L<sprintf(3)> or L<printf(3)>
3513 on your system for an explanation of the general principles.
3514
3515 Perl does its own C<sprintf()> formatting -- it emulates the C
3516 function C<sprintf()>, but it doesn't use it (except for floating-point
3517 numbers, and even then only the standard modifiers are allowed).  As a
3518 result, any non-standard extensions in your local C<sprintf()> are not
3519 available from Perl.
3520
3521 Perl's C<sprintf()> permits the following universally-known conversions:
3522
3523    %%   a percent sign
3524    %c   a character with the given number
3525    %s   a string
3526    %d   a signed integer, in decimal
3527    %u   an unsigned integer, in decimal
3528    %o   an unsigned integer, in octal
3529    %x   an unsigned integer, in hexadecimal
3530    %e   a floating-point number, in scientific notation
3531    %f   a floating-point number, in fixed decimal notation
3532    %g   a floating-point number, in %e or %f notation
3533
3534 In addition, Perl permits the following widely-supported conversions:
3535
3536    %X   like %x, but using upper-case letters
3537    %E   like %e, but using an upper-case "E"
3538    %G   like %g, but with an upper-case "E" (if applicable)
3539    %p   a pointer (outputs the Perl value's address in hexadecimal)
3540    %n   special: *stores* the number of characters output so far
3541         into the next variable in the parameter list 
3542
3543 Finally, for backward (and we do mean "backward") compatibility, Perl
3544 permits these unnecessary but widely-supported conversions:
3545
3546    %i   a synonym for %d
3547    %D   a synonym for %ld
3548    %U   a synonym for %lu
3549    %O   a synonym for %lo
3550    %F   a synonym for %f
3551
3552 Perl permits the following universally-known flags between the C<%>
3553 and the conversion letter:
3554
3555    space   prefix positive number with a space
3556    +       prefix positive number with a plus sign
3557    -       left-justify within the field
3558    0       use zeros, not spaces, to right-justify
3559    #       prefix non-zero octal with "0", non-zero hex with "0x"
3560    number  minimum field width
3561    .number "precision": digits after decimal point for
3562            floating-point, max length for string, minimum length
3563            for integer
3564    l       interpret integer as C type "long" or "unsigned long"
3565    h       interpret integer as C type "short" or "unsigned short"
3566
3567 There is also one Perl-specific flag:
3568
3569    V       interpret integer as Perl's standard integer type
3570
3571 Where a number would appear in the flags, an asterisk ("C<*>") may be
3572 used instead, in which case Perl uses the next item in the parameter
3573 list as the given number (that is, as the field width or precision).
3574 If a field width obtained through "C<*>" is negative, it has the same
3575 effect as the "C<->" flag: left-justification.
3576
3577 If C<use locale> is in effect, the character used for the decimal
3578 point in formatted real numbers is affected by the LC_NUMERIC locale.
3579 See L<perllocale>.
3580
3581 =item sqrt EXPR
3582
3583 =item sqrt
3584
3585 Return the square root of EXPR.  If EXPR is omitted, returns square
3586 root of C<$_>.
3587
3588 =item srand EXPR
3589
3590 =item srand
3591
3592 Sets the random number seed for the C<rand()> operator.  If EXPR is
3593 omitted, uses a semi-random value based on the current time and process
3594 ID, among other things.  In versions of Perl prior to 5.004 the default
3595 seed was just the current C<time()>.  This isn't a particularly good seed,
3596 so many old programs supply their own seed value (often C<time ^ $$> or
3597 C<time ^ ($$ + ($$ E<lt>E<lt> 15))>), but that isn't necessary any more.
3598
3599 In fact, it's usually not necessary to call C<srand()> at all, because if
3600 it is not called explicitly, it is called implicitly at the first use of
3601 the C<rand()> operator.  However, this was not the case in version of Perl
3602 before 5.004, so if your script will run under older Perl versions, it
3603 should call C<srand()>.
3604
3605 Note that you need something much more random than the default seed for
3606 cryptographic purposes.  Checksumming the compressed output of one or more
3607 rapidly changing operating system status programs is the usual method.  For
3608 example:
3609
3610     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
3611
3612 If you're particularly concerned with this, see the C<Math::TrulyRandom>
3613 module in CPAN.
3614
3615 Do I<not> call C<srand()> multiple times in your program unless you know
3616 exactly what you're doing and why you're doing it.  The point of the
3617 function is to "seed" the C<rand()> function so that C<rand()> can produce
3618 a different sequence each time you run your program.  Just do it once at the
3619 top of your program, or you I<won't> get random numbers out of C<rand()>!
3620
3621 Frequently called programs (like CGI scripts) that simply use
3622
3623     time ^ $$
3624
3625 for a seed can fall prey to the mathematical property that
3626
3627     a^b == (a+1)^(b+1)
3628
3629 one-third of the time.  So don't do that.
3630
3631 =item stat FILEHANDLE
3632
3633 =item stat EXPR
3634
3635 =item stat
3636
3637 Returns a 13-element list giving the status info for a file, either
3638 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
3639 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
3640 as follows:
3641
3642     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
3643        $atime,$mtime,$ctime,$blksize,$blocks)
3644            = stat($filename);
3645
3646 Not all fields are supported on all filesystem types.  Here are the
3647 meaning of the fields:
3648
3649   0 dev      device number of filesystem
3650   1 ino      inode number
3651   2 mode     file mode  (type and permissions)
3652   3 nlink    number of (hard) links to the file
3653   4 uid      numeric user ID of file's owner
3654   5 gid      numeric group ID of file's owner
3655   6 rdev     the device identifier (special files only)
3656   7 size     total size of file, in bytes
3657   8 atime    last access time since the epoch
3658   9 mtime    last modify time since the epoch
3659  10 ctime    inode change time (NOT creation time!) since the epoch
3660  11 blksize  preferred block size for file system I/O
3661  12 blocks   actual number of blocks allocated
3662
3663 (The epoch was at 00:00 January 1, 1970 GMT.)
3664
3665 If stat is passed the special filehandle consisting of an underline, no
3666 stat is done, but the current contents of the stat structure from the
3667 last stat or filetest are returned.  Example:
3668
3669     if (-x $file && (($d) = stat(_)) && $d < 0) {
3670         print "$file is executable NFS file\n";
3671     }
3672
3673 (This works on machines only for which the device number is negative under NFS.)
3674
3675 In scalar context, C<stat()> returns a boolean value indicating success
3676 or failure, and, if successful, sets the information associated with
3677 the special filehandle C<_>.
3678
3679 =item study SCALAR
3680
3681 =item study
3682
3683 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
3684 doing many pattern matches on the string before it is next modified.
3685 This may or may not save time, depending on the nature and number of
3686 patterns you are searching on, and on the distribution of character
3687 frequencies in the string to be searched -- you probably want to compare
3688 run times with and without it to see which runs faster.  Those loops
3689 which scan for many short constant strings (including the constant
3690 parts of more complex patterns) will benefit most.  You may have only
3691 one C<study()> active at a time -- if you study a different scalar the first
3692 is "unstudied".  (The way C<study()> works is this: a linked list of every
3693 character in the string to be searched is made, so we know, for
3694 example, where all the C<'k'> characters are.  From each search string,
3695 the rarest character is selected, based on some static frequency tables
3696 constructed from some C programs and English text.  Only those places
3697 that contain this "rarest" character are examined.)
3698
3699 For example, here is a loop that inserts index producing entries
3700 before any line containing a certain pattern:
3701
3702     while (<>) {
3703         study;
3704         print ".IX foo\n" if /\bfoo\b/;
3705         print ".IX bar\n" if /\bbar\b/;
3706         print ".IX blurfl\n" if /\bblurfl\b/;
3707         # ...
3708         print;
3709     }
3710
3711 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<"f">
3712 will be looked at, because C<"f"> is rarer than C<"o">.  In general, this is
3713 a big win except in pathological cases.  The only question is whether
3714 it saves you more time than it took to build the linked list in the
3715 first place.
3716
3717 Note that if you have to look for strings that you don't know till
3718 runtime, you can build an entire loop as a string and C<eval()> that to
3719 avoid recompiling all your patterns all the time.  Together with
3720 undefining C<$/> to input entire files as one record, this can be very
3721 fast, often faster than specialized programs like fgrep(1).  The following
3722 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3723 out the names of those files that contain a match:
3724
3725     $search = 'while (<>) { study;';
3726     foreach $word (@words) {
3727         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3728     }
3729     $search .= "}";
3730     @ARGV = @files;
3731     undef $/;
3732     eval $search;               # this screams
3733     $/ = "\n";          # put back to normal input delimiter
3734     foreach $file (sort keys(%seen)) {
3735         print $file, "\n";
3736     }
3737
3738 =item sub BLOCK
3739
3740 =item sub NAME
3741
3742 =item sub NAME BLOCK
3743
3744 This is subroutine definition, not a real function I<per se>.  With just a
3745 NAME (and possibly prototypes), it's just a forward declaration.  Without
3746 a NAME, it's an anonymous function declaration, and does actually return a
3747 value: the CODE ref of the closure you just created.  See L<perlsub> and
3748 L<perlref> for details.
3749
3750 =item substr EXPR,OFFSET,LEN,REPLACEMENT
3751
3752 =item substr EXPR,OFFSET,LEN
3753
3754 =item substr EXPR,OFFSET
3755
3756 Extracts a substring out of EXPR and returns it.  First character is at
3757 offset C<0>, or whatever you've set C<$[> to (but don't do that).
3758 If OFFSET is negative (or more precisely, less than C<$[>), starts
3759 that far from the end of the string.  If LEN is omitted, returns
3760 everything to the end of the string.  If LEN is negative, leaves that
3761 many characters off the end of the string.
3762
3763 If you specify a substring that is partly outside the string, the part
3764 within the string is returned.    If the substring is totally outside
3765 the string a warning is produced.
3766
3767 You can use the C<substr()> function
3768 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3769 something shorter than LEN, the string will shrink, and if you assign
3770 something longer than LEN, the string will grow to accommodate it.  To
3771 keep the string the same length you may need to pad or chop your value
3772 using C<sprintf()>.
3773
3774 An alternative to using C<substr()> as an lvalue is to specify the
3775 replacement string as the 4th argument.  This allows you to replace
3776 parts of the EXPR and return what was there before in one operation.
3777
3778 =item symlink OLDFILE,NEWFILE
3779
3780 Creates a new filename symbolically linked to the old filename.
3781 Returns C<1> for success, C<0> otherwise.  On systems that don't support
3782 symbolic links, produces a fatal error at run time.  To check for that,
3783 use eval:
3784
3785     $symlink_exists =  eval { symlink("",""); 1 };
3786
3787 =item syscall LIST
3788
3789 Calls the system call specified as the first element of the list,
3790 passing the remaining elements as arguments to the system call.  If
3791 unimplemented, produces a fatal error.  The arguments are interpreted
3792 as follows: if a given argument is numeric, the argument is passed as
3793 an int.  If not, the pointer to the string value is passed.  You are
3794 responsible to make sure a string is pre-extended long enough to
3795 receive any result that might be written into a string.  You can't use a
3796 string literal (or other read-only string) as an argument to C<syscall()>
3797 because Perl has to assume that any string pointer might be written
3798 through.  If your
3799 integer arguments are not literals and have never been interpreted in a
3800 numeric context, you may need to add C<0> to them to force them to look
3801 like numbers.  This emulates the C<syswrite()> function (or vice versa):
3802
3803     require 'syscall.ph';               # may need to run h2ph
3804     $s = "hi there\n";
3805     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
3806
3807 Note that Perl supports passing of up to only 14 arguments to your system call,
3808 which in practice should usually suffice.
3809
3810 Syscall returns whatever value returned by the system call it calls.
3811 If the system call fails, C<syscall()> returns C<-1> and sets C<$!> (errno).
3812 Note that some system calls can legitimately return C<-1>.  The proper
3813 way to handle such calls is to assign C<$!=0;> before the call and
3814 check the value of C<$!> if syscall returns C<-1>.
3815
3816 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
3817 number of the read end of the pipe it creates.  There is no way
3818 to retrieve the file number of the other end.  You can avoid this 
3819 problem by using C<pipe()> instead.
3820
3821 =item sysopen FILEHANDLE,FILENAME,MODE
3822
3823 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
3824
3825 Opens the file whose filename is given by FILENAME, and associates it
3826 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
3827 the name of the real filehandle wanted.  This function calls the
3828 underlying operating system's C<open()> function with the parameters
3829 FILENAME, MODE, PERMS.
3830
3831 The possible values and flag bits of the MODE parameter are
3832 system-dependent; they are available via the standard module C<Fcntl>.
3833 For historical reasons, some values work on almost every system
3834 supported by perl: zero means read-only, one means write-only, and two
3835 means read/write.  We know that these values do I<not> work under
3836 OS/390 Unix and on the Macintosh; you probably don't want to use them
3837 in new code.
3838
3839 If the file named by FILENAME does not exist and the C<open()> call creates
3840 it (typically because MODE includes the C<O_CREAT> flag), then the value of
3841 PERMS specifies the permissions of the newly created file.  If you omit
3842 the PERMS argument to C<sysopen()>, Perl uses the octal value C<0666>.
3843 These permission values need to be in octal, and are modified by your
3844 process's current C<umask>.  The C<umask> value is a number representing
3845 disabled permissions bits--if your C<umask> were C<027> (group can't write;
3846 others can't read, write, or execute), then passing C<sysopen()> C<0666> would
3847 create a file with mode C<0640> (C<0666 &~ 027> is C<0640>).
3848
3849 If you find this C<umask()> talk confusing, here's some advice: supply a
3850 creation mode of C<0666> for regular files and one of C<0777> for directories
3851 (in C<mkdir()>) and executable files.  This gives users the freedom of
3852 choice: if they want protected files, they might choose process umasks
3853 of C<022>, C<027>, or even the particularly antisocial mask of C<077>.  Programs
3854 should rarely if ever make policy decisions better left to the user.
3855 The exception to this is when writing files that should be kept private:
3856 mail files, web browser cookies, I<.rhosts> files, and so on.  In short,
3857 seldom if ever use C<0644> as argument to C<sysopen()> because that takes
3858 away the user's option to have a more permissive umask.  Better to omit it.
3859
3860 The C<IO::File> module provides a more object-oriented approach, if you're
3861 into that kind of thing.
3862
3863 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
3864
3865 =item sysread FILEHANDLE,SCALAR,LENGTH
3866
3867 Attempts to read LENGTH bytes of data into variable SCALAR from the
3868 specified FILEHANDLE, using the system call read(2).  It bypasses
3869 stdio, so mixing this with other kinds of reads, C<print()>, C<write()>,
3870 C<seek()>, or C<tell()> can cause confusion because stdio usually buffers
3871 data.  Returns the number of bytes actually read, C<0> at end of file,
3872 or undef if there was an error.  SCALAR will be grown or shrunk so that
3873 the last byte actually read is the last byte of the scalar after the read.
3874
3875 An OFFSET may be specified to place the read data at some place in the
3876 string other than the beginning.  A negative OFFSET specifies
3877 placement at that many bytes counting backwards from the end of the
3878 string.  A positive OFFSET greater than the length of SCALAR results
3879 in the string being padded to the required size with C<"\0"> bytes before
3880 the result of the read is appended.
3881
3882 =item sysseek FILEHANDLE,POSITION,WHENCE
3883
3884 Sets FILEHANDLE's system position using the system call lseek(2).  It
3885 bypasses stdio, so mixing this with reads (other than C<sysread()>),
3886 C<print()>, C<write()>, C<seek()>, or C<tell()> may cause confusion.  FILEHANDLE may
3887 be an expression whose value gives the name of the filehandle.  The
3888 values for WHENCE are C<0> to set the new position to POSITION, C<1> to set
3889 the it to the current position plus POSITION, and C<2> to set it to EOF
3890 plus POSITION (typically negative).  For WHENCE, you may use the
3891 constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END> from either the C<IO::Seekable>
3892 or the POSIX module.
3893
3894 Returns the new position, or the undefined value on failure.  A position
3895 of zero is returned as the string "C<0> but true"; thus C<sysseek()> returns
3896 TRUE on success and FALSE on failure, yet you can still easily determine
3897 the new position.
3898
3899 =item system LIST
3900
3901 =item system PROGRAM LIST
3902
3903 Does exactly the same thing as "C<exec LIST>" except that a fork is done
3904 first, and the parent process waits for the child process to complete.
3905 Note that argument processing varies depending on the number of
3906 arguments.  If there is more than one argument in LIST, or if LIST is
3907 an array with more than one value, starts the program given by the
3908 first element of the list with arguments given by the rest of the list.
3909 If there is only one scalar argument, the argument is
3910 checked for shell metacharacters, and if there are any, the entire
3911 argument is passed to the system's command shell for parsing (this is
3912 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
3913 there are no shell metacharacters in the argument, it is split into
3914 words and passed directly to C<execvp()>, which is more efficient.
3915
3916 The return value is the exit status of the program as
3917 returned by the C<wait()> call.  To get the actual exit value divide by
3918 256.  See also L</exec>.  This is I<NOT> what you want to use to capture
3919 the output from a command, for that you should use merely backticks or
3920 C<qx//>, as described in L<perlop/"`STRING`">.
3921
3922 Like C<exec()>, C<system()> allows you to lie to a program about its name if
3923 you use the "C<system PROGRAM LIST>" syntax.  Again, see L</exec>.
3924
3925 Because C<system()> and backticks block C<SIGINT> and C<SIGQUIT>, killing the
3926 program they're running doesn't actually interrupt your program.
3927
3928     @args = ("command", "arg1", "arg2");
3929     system(@args) == 0
3930          or die "system @args failed: $?"
3931
3932 You can check all the failure possibilities by inspecting
3933 C<$?> like this:
3934
3935     $exit_value  = $? >> 8;
3936     $signal_num  = $? & 127;
3937     $dumped_core = $? & 128;
3938
3939 When the arguments get executed via the system shell, results
3940 and return codes will be subject to its quirks and capabilities.
3941 See L<perlop/"`STRING`"> and L</exec> for details.
3942
3943 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
3944
3945 =item syswrite FILEHANDLE,SCALAR,LENGTH
3946
3947 Attempts to write LENGTH bytes of data from variable SCALAR to the
3948 specified FILEHANDLE, using the system call write(2).  It bypasses
3949 stdio, so mixing this with reads (other than C<sysread())>, C<print()>,
3950 C<write()>, C<seek()>, or C<tell()> may cause confusion because stdio usually
3951 buffers data.  Returns the number of bytes actually written, or C<undef>
3952 if there was an error.  If the LENGTH is greater than the available
3953 data in the SCALAR after the OFFSET, only as much data as is available
3954 will be written.
3955
3956 An OFFSET may be specified to write the data from some part of the
3957 string other than the beginning.  A negative OFFSET specifies writing
3958 that many bytes counting backwards from the end of the string.  In the
3959 case the SCALAR is empty you can use OFFSET but only zero offset.
3960
3961 =item tell FILEHANDLE
3962
3963 =item tell
3964
3965 Returns the current position for FILEHANDLE.  FILEHANDLE may be an
3966 expression whose value gives the name of the actual filehandle.  If
3967 FILEHANDLE is omitted, assumes the file last read.
3968
3969 =item telldir DIRHANDLE
3970
3971 Returns the current position of the C<readdir()> routines on DIRHANDLE.
3972 Value may be given to C<seekdir()> to access a particular location in a
3973 directory.  Has the same caveats about possible directory compaction as
3974 the corresponding system library routine.
3975
3976 =item tie VARIABLE,CLASSNAME,LIST
3977
3978 This function binds a variable to a package class that will provide the
3979 implementation for the variable.  VARIABLE is the name of the variable
3980 to be enchanted.  CLASSNAME is the name of a class implementing objects
3981 of correct type.  Any additional arguments are passed to the "C<new()>"
3982 method of the class (meaning C<TIESCALAR>, C<TIEARRAY>, or C<TIEHASH>).
3983 Typically these are arguments such as might be passed to the C<dbm_open()>
3984 function of C.  The object returned by the "C<new()>" method is also
3985 returned by the C<tie()> function, which would be useful if you want to
3986 access other methods in CLASSNAME.
3987
3988 Note that functions such as C<keys()> and C<values()> may return huge lists
3989 when used on large objects, like DBM files.  You may prefer to use the
3990 C<each()> function to iterate over such.  Example:
3991
3992     # print out history file offsets
3993     use NDBM_File;
3994     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
3995     while (($key,$val) = each %HIST) {
3996         print $key, ' = ', unpack('L',$val), "\n";
3997     }
3998     untie(%HIST);
3999
4000 A class implementing a hash should have the following methods:
4001
4002     TIEHASH classname, LIST
4003     DESTROY this
4004     FETCH this, key
4005     STORE this, key, value
4006     DELETE this, key
4007     EXISTS this, key
4008     FIRSTKEY this
4009     NEXTKEY this, lastkey
4010
4011 A class implementing an ordinary array should have the following methods:
4012
4013     TIEARRAY classname, LIST
4014     DESTROY this
4015     FETCH this, key
4016     STORE this, key, value
4017     [others TBD]
4018
4019 A class implementing a scalar should have the following methods:
4020
4021     TIESCALAR classname, LIST
4022     DESTROY this
4023     FETCH this,
4024     STORE this, value
4025
4026 Unlike C<dbmopen()>, the C<tie()> function will not use or require a module
4027 for you--you need to do that explicitly yourself.  See L<DB_File>
4028 or the F<Config> module for interesting C<tie()> implementations.
4029
4030 For further details see L<perltie>, L<tied VARIABLE>.
4031
4032 =item tied VARIABLE
4033
4034 Returns a reference to the object underlying VARIABLE (the same value
4035 that was originally returned by the C<tie()> call that bound the variable
4036 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
4037 package.
4038
4039 =item time
4040
4041 Returns the number of non-leap seconds since whatever time the system
4042 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
4043 and 00:00:00 UTC, January 1, 1970 for most other systems).
4044 Suitable for feeding to C<gmtime()> and C<localtime()>.
4045
4046 =item times
4047
4048 Returns a four-element list giving the user and system times, in
4049 seconds, for this process and the children of this process.
4050
4051     ($user,$system,$cuser,$csystem) = times;
4052
4053 =item tr///
4054
4055 The transliteration operator.  Same as C<y///>. See L<perlop>.
4056
4057 =item truncate FILEHANDLE,LENGTH
4058
4059 =item truncate EXPR,LENGTH
4060
4061 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
4062 specified length.  Produces a fatal error if truncate isn't implemented
4063 on your system.  Returns TRUE if successful, the undefined value
4064 otherwise.
4065
4066 =item uc EXPR
4067
4068 =item uc
4069
4070 Returns an uppercased version of EXPR.  This is the internal function
4071 implementing the C<\U> escape in double-quoted strings.
4072 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4073
4074 If EXPR is omitted, uses C<$_>.
4075
4076 =item ucfirst EXPR
4077
4078 =item ucfirst
4079
4080 Returns the value of EXPR with the first character uppercased.  This is
4081 the internal function implementing the C<\u> escape in double-quoted strings.
4082 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4083
4084 If EXPR is omitted, uses C<$_>.
4085
4086 =item umask EXPR
4087
4088 =item umask
4089
4090 Sets the umask for the process to EXPR and returns the previous value.
4091 If EXPR is omitted, merely returns the current umask.
4092
4093 If umask(2) is not implemented on your system and you are trying to
4094 restrict access for I<yourself> (i.e., (EXPR & 0700) > 0), produces a
4095 fatal error at run time.  If umask(2) is not implemented and you are
4096 not trying to restrict access for yourself, returns C<undef>.
4097
4098 Remember that a umask is a number, usually given in octal; it is I<not> a
4099 string of octal digits.  See also L</oct>, if all you have is a string.
4100
4101 =item undef EXPR
4102
4103 =item undef
4104
4105 Undefines the value of EXPR, which must be an lvalue.  Use only on a
4106 scalar value, an array (using "C<@>"), a hash (using "C<%>"), a subroutine
4107 (using "C<&>"), or a typeglob (using "<*>").  (Saying C<undef $hash{$key}>
4108 will probably not do what you expect on most predefined variables or
4109 DBM list values, so don't do that; see L<delete>.)  Always returns the
4110 undefined value.  You can omit the EXPR, in which case nothing is
4111 undefined, but you still get an undefined value that you could, for
4112 instance, return from a subroutine, assign to a variable or pass as a
4113 parameter.  Examples:
4114
4115     undef $foo;
4116     undef $bar{'blurfl'};      # Compare to: delete $bar{'blurfl'};
4117     undef @ary;
4118     undef %hash;
4119     undef &mysub;
4120     undef *xyz;       # destroys $xyz, @xyz, %xyz, &xyz, etc.
4121     return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
4122     select undef, undef, undef, 0.25;
4123     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
4124
4125 Note that this is a unary operator, not a list operator.
4126
4127 =item unlink LIST
4128
4129 =item unlink
4130
4131 Deletes a list of files.  Returns the number of files successfully
4132 deleted.
4133
4134     $cnt = unlink 'a', 'b', 'c';
4135     unlink @goners;
4136     unlink <*.bak>;
4137
4138 Note: C<unlink()> will not delete directories unless you are superuser and
4139 the B<-U> flag is supplied to Perl.  Even if these conditions are
4140 met, be warned that unlinking a directory can inflict damage on your
4141 filesystem.  Use C<rmdir()> instead.
4142
4143 If LIST is omitted, uses C<$_>.
4144
4145 =item unpack TEMPLATE,EXPR
4146
4147 C<Unpack()> does the reverse of C<pack()>: it takes a string representing a
4148 structure and expands it out into a list value, returning the array
4149 value.  (In scalar context, it returns merely the first value
4150 produced.)  The TEMPLATE has the same format as in the C<pack()> function.
4151 Here's a subroutine that does substring:
4152
4153     sub substr {
4154         my($what,$where,$howmuch) = @_;
4155         unpack("x$where a$howmuch", $what);
4156     }
4157
4158 and then there's
4159
4160     sub ordinal { unpack("c",$_[0]); } # same as ord()
4161
4162 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
4163 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
4164 themselves.  Default is a 16-bit checksum.  For example, the following
4165 computes the same number as the System V sum program:
4166
4167     while (<>) {
4168         $checksum += unpack("%16C*", $_);
4169     }
4170     $checksum %= 65536;
4171
4172 The following efficiently counts the number of set bits in a bit vector:
4173
4174     $setbits = unpack("%32b*", $selectmask);
4175
4176 =item untie VARIABLE
4177
4178 Breaks the binding between a variable and a package.  (See C<tie()>.)
4179
4180 =item unshift ARRAY,LIST
4181
4182 Does the opposite of a C<shift()>.  Or the opposite of a C<push()>,
4183 depending on how you look at it.  Prepends list to the front of the
4184 array, and returns the new number of elements in the array.
4185
4186     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
4187
4188 Note the LIST is prepended whole, not one element at a time, so the
4189 prepended elements stay in the same order.  Use C<reverse()> to do the
4190 reverse.
4191
4192 =item use Module LIST
4193
4194 =item use Module
4195
4196 =item use Module VERSION LIST
4197
4198 =item use VERSION
4199
4200 Imports some semantics into the current package from the named module,
4201 generally by aliasing certain subroutine or variable names into your
4202 package.  It is exactly equivalent to
4203
4204     BEGIN { require Module; import Module LIST; }
4205
4206 except that Module I<must> be a bareword.
4207
4208 If the first argument to C<use> is a number, it is treated as a version
4209 number instead of a module name.  If the version of the Perl interpreter
4210 is less than VERSION, then an error message is printed and Perl exits
4211 immediately.  This is often useful if you need to check the current
4212 Perl version before C<use>ing library modules that have changed in
4213 incompatible ways from older versions of Perl.  (We try not to do
4214 this more than we have to.)
4215
4216 The C<BEGIN> forces the C<require> and C<import()> to happen at compile time.  The
4217 C<require> makes sure the module is loaded into memory if it hasn't been
4218 yet.  The C<import()> is not a builtin--it's just an ordinary static method
4219 call into the "C<Module>" package to tell the module to import the list of
4220 features back into the current package.  The module can implement its
4221 C<import()> method any way it likes, though most modules just choose to
4222 derive their C<import()> method via inheritance from the C<Exporter> class that
4223 is defined in the C<Exporter> module.  See L<Exporter>.  If no C<import()>
4224 method can be found then the error is currently silently ignored.  This
4225 may change to a fatal error in a future version.
4226
4227 If you don't want your namespace altered, explicitly supply an empty list:
4228
4229     use Module ();
4230
4231 That is exactly equivalent to
4232
4233     BEGIN { require Module }
4234
4235 If the VERSION argument is present between Module and LIST, then the
4236 C<use> will call the VERSION method in class Module with the given
4237 version as an argument.  The default VERSION method, inherited from
4238 the Universal class, croaks if the given version is larger than the
4239 value of the variable C<$Module::VERSION>.  (Note that there is not a
4240 comma after VERSION!)
4241
4242 Because this is a wide-open interface, pragmas (compiler directives)
4243 are also implemented this way.  Currently implemented pragmas are:
4244
4245     use integer;
4246     use diagnostics;
4247     use sigtrap qw(SEGV BUS);
4248     use strict  qw(subs vars refs);
4249     use subs    qw(afunc blurfl);
4250
4251 Some of these these pseudo-modules import semantics into the current
4252 block scope (like C<strict> or C<integer>, unlike ordinary modules,
4253 which import symbols into the current package (which are effective
4254 through the end of the file).
4255
4256 There's a corresponding "C<no>" command that unimports meanings imported
4257 by C<use>, i.e., it calls C<unimport Module LIST> instead of C<import()>.
4258
4259     no integer;
4260     no strict 'refs';
4261
4262 If no C<unimport()> method can be found the call fails with a fatal error.
4263
4264 See L<perlmod> for a list of standard modules and pragmas.
4265
4266 =item utime LIST
4267
4268 Changes the access and modification times on each file of a list of
4269 files.  The first two elements of the list must be the NUMERICAL access
4270 and modification times, in that order.  Returns the number of files
4271 successfully changed.  The inode modification time of each file is set
4272 to the current time.  This code has the same effect as the "C<touch>"
4273 command if the files already exist:
4274
4275     #!/usr/bin/perl
4276     $now = time;
4277     utime $now, $now, @ARGV;
4278
4279 =item values HASH
4280
4281 Returns a list consisting of all the values of the named hash.  (In a
4282 scalar context, returns the number of values.)  The values are
4283 returned in an apparently random order, but it is the same order as
4284 either the C<keys()> or C<each()> function would produce on the same hash.
4285 As a side effect, it resets HASH's iterator.  See also C<keys()>, C<each()>,
4286 and C<sort()>.
4287
4288 =item vec EXPR,OFFSET,BITS
4289
4290 Treats the string in EXPR as a vector of unsigned integers, and
4291 returns the value of the bit field specified by OFFSET.  BITS specifies
4292 the number of bits that are reserved for each entry in the bit
4293 vector.  This must be a power of two from 1 to 32. C<vec()> may also be
4294 assigned to, in which case parentheses are needed to give the expression
4295 the correct precedence as in
4296
4297     vec($image, $max_x * $x + $y, 8) = 3;
4298
4299 Vectors created with C<vec()> can also be manipulated with the logical
4300 operators C<|>, C<&>, and C<^>, which will assume a bit vector operation is
4301 desired when both operands are strings.
4302
4303 The following code will build up an ASCII string saying C<'PerlPerlPerl'>.
4304 The comments show the string after each step. Note that this code works
4305 in the same way on big-endian or little-endian machines.
4306
4307     my $foo = '';
4308     vec($foo,  0, 32) = 0x5065726C;     # 'Perl'
4309     vec($foo,  2, 16) = 0x5065;         # 'PerlPe'
4310     vec($foo,  3, 16) = 0x726C;         # 'PerlPerl'
4311     vec($foo,  8,  8) = 0x50;           # 'PerlPerlP'
4312     vec($foo,  9,  8) = 0x65;           # 'PerlPerlPe'
4313     vec($foo, 20,  4) = 2;              # 'PerlPerlPe'   . "\x02"
4314     vec($foo, 21,  4) = 7;              # 'PerlPerlPer'
4315                                         # 'r' is "\x72"
4316     vec($foo, 45,  2) = 3;              # 'PerlPerlPer'  . "\x0c"
4317     vec($foo, 93,  1) = 1;              # 'PerlPerlPer'  . "\x2c"
4318     vec($foo, 94,  1) = 1;              # 'PerlPerlPerl'
4319                                         # 'l' is "\x6c"
4320
4321 To transform a bit vector into a string or array of 0's and 1's, use these:
4322
4323     $bits = unpack("b*", $vector);
4324     @bits = split(//, unpack("b*", $vector));
4325
4326 If you know the exact length in bits, it can be used in place of the C<*>.
4327
4328 =item wait
4329
4330 Waits for a child process to terminate and returns the pid of the
4331 deceased process, or C<-1> if there are no child processes.  The status is
4332 returned in C<$?>.
4333
4334 =item waitpid PID,FLAGS
4335
4336 Waits for a particular child process to terminate and returns the pid
4337 of the deceased process, or C<-1> if there is no such child process.  The
4338 status is returned in C<$?>.  If you say
4339
4340     use POSIX ":sys_wait_h";
4341     #...
4342     waitpid(-1,&WNOHANG);
4343
4344 then you can do a non-blocking wait for any process.  Non-blocking wait
4345 is available on machines supporting either the waitpid(2) or
4346 wait4(2) system calls.  However, waiting for a particular pid with
4347 FLAGS of C<0> is implemented everywhere.  (Perl emulates the system call
4348 by remembering the status values of processes that have exited but have
4349 not been harvested by the Perl script yet.)
4350
4351 See L<perlipc> for other examples.
4352
4353 =item wantarray
4354
4355 Returns TRUE if the context of the currently executing subroutine is
4356 looking for a list value.  Returns FALSE if the context is looking
4357 for a scalar.  Returns the undefined value if the context is looking
4358 for no value (void context).
4359
4360     return unless defined wantarray;    # don't bother doing more
4361     my @a = complex_calculation();
4362     return wantarray ? @a : "@a";
4363
4364 =item warn LIST
4365
4366 Produces a message on STDERR just like C<die()>, but doesn't exit or throw
4367 an exception.
4368
4369 If LIST is empty and C<$@> already contains a value (typically from a
4370 previous eval) that value is used after appending C<"\t...caught">
4371 to C<$@>. This is useful for staying almost, but not entirely similar to
4372 C<die()>.
4373
4374 If C<$@> is empty then the string C<"Warning: Something's wrong"> is used.
4375
4376 No message is printed if there is a C<$SIG{__WARN__}> handler
4377 installed.  It is the handler's responsibility to deal with the message
4378 as it sees fit (like, for instance, converting it into a C<die()>).  Most
4379 handlers must therefore make arrangements to actually display the
4380 warnings that they are not prepared to deal with, by calling C<warn()>
4381 again in the handler.  Note that this is quite safe and will not
4382 produce an endless loop, since C<__WARN__> hooks are not called from
4383 inside one.
4384
4385 You will find this behavior is slightly different from that of
4386 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
4387 instead call C<die()> again to change it).
4388
4389 Using a C<__WARN__> handler provides a powerful way to silence all
4390 warnings (even the so-called mandatory ones).  An example:
4391
4392     # wipe out *all* compile-time warnings
4393     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
4394     my $foo = 10;
4395     my $foo = 20;          # no warning about duplicate my $foo,
4396                            # but hey, you asked for it!
4397     # no compile-time or run-time warnings before here
4398     $DOWARN = 1;
4399
4400     # run-time warnings enabled after here
4401     warn "\$foo is alive and $foo!";     # does show up
4402
4403 See L<perlvar> for details on setting C<%SIG> entries, and for more
4404 examples.
4405
4406 =item write FILEHANDLE
4407
4408 =item write EXPR
4409
4410 =item write
4411
4412 Writes a formatted record (possibly multi-line) to the specified FILEHANDLE,
4413 using the format associated with that file.  By default the format for
4414 a file is the one having the same name as the filehandle, but the
4415 format for the current output channel (see the C<select()> function) may be set
4416 explicitly by assigning the name of the format to the C<$~> variable.
4417
4418 Top of form processing is handled automatically:  if there is
4419 insufficient room on the current page for the formatted record, the
4420 page is advanced by writing a form feed, a special top-of-page format
4421 is used to format the new page header, and then the record is written.
4422 By default the top-of-page format is the name of the filehandle with
4423 "_TOP" appended, but it may be dynamically set to the format of your
4424 choice by assigning the name to the C<$^> variable while the filehandle is
4425 selected.  The number of lines remaining on the current page is in
4426 variable C<$->, which can be set to C<0> to force a new page.
4427
4428 If FILEHANDLE is unspecified, output goes to the current default output
4429 channel, which starts out as STDOUT but may be changed by the
4430 C<select()> operator.  If the FILEHANDLE is an EXPR, then the expression
4431 is evaluated and the resulting string is used to look up the name of
4432 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
4433
4434 Note that write is I<NOT> the opposite of C<read()>.  Unfortunately.
4435
4436 =item y///
4437
4438 The transliteration operator.  Same as C<tr///>.  See L<perlop>.
4439
4440 =back