This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Missing perlfaq chunk.
[perl5.git] / pod / perlfaq4.pod
1 =head1 NAME
2
3 perlfaq4 - Data Manipulation ($Revision: 1.49 $, $Date: 2003/09/20 06:37:43 $)
4
5 =head1 DESCRIPTION
6
7 This section of the FAQ answers questions related to manipulating
8 numbers, dates, strings, arrays, hashes, and miscellaneous data issues.
9
10 =head1 Data: Numbers
11
12 =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
13
14 Internally, your computer represents floating-point numbers
15 in binary. Digital (as in powers of two) computers cannot
16 store all numbers exactly.  Some real numbers lose precision
17 in the process.  This is a problem with how computers store
18 numbers and affects all computer languages, not just Perl.
19
20 L<perlnumber> show the gory details of number
21 representations and conversions.
22
23 To limit the number of decimal places in your numbers, you
24 can use the printf or sprintf function.  See the
25 L<"Floating Point Arithmetic"|perlop> for more details.
26
27         printf "%.2f", 10/3;
28
29         my $number = sprintf "%.2f", 10/3;
30
31 =head2 Why is int() broken?
32
33 Your int() is most probably working just fine.  It's the numbers that
34 aren't quite what you think.
35
36 First, see the above item "Why am I getting long decimals
37 (eg, 19.9499999999999) instead of the numbers I should be getting
38 (eg, 19.95)?".
39
40 For example, this
41
42     print int(0.6/0.2-2), "\n";
43
44 will in most computers print 0, not 1, because even such simple
45 numbers as 0.6 and 0.2 cannot be presented exactly by floating-point
46 numbers.  What you think in the above as 'three' is really more like
47 2.9999999999999995559.
48
49 =head2 Why isn't my octal data interpreted correctly?
50
51 Perl only understands octal and hex numbers as such when they occur as
52 literals in your program.  Octal literals in perl must start with a
53 leading "0" and hexadecimal literals must start with a leading "0x".
54 If they are read in from somewhere and assigned, no automatic
55 conversion takes place.  You must explicitly use oct() or hex() if you
56 want the values converted to decimal.  oct() interprets hex ("0x350"),
57 octal ("0350" or even without the leading "0", like "377") and binary
58 ("0b1010") numbers, while hex() only converts hexadecimal ones, with
59 or without a leading "0x", like "0x255", "3A", "ff", or "deadbeef".
60 The inverse mapping from decimal to octal can be done with either the
61 "%o" or "%O" sprintf() formats.
62
63 This problem shows up most often when people try using chmod(), mkdir(),
64 umask(), or sysopen(), which by widespread tradition typically take
65 permissions in octal.
66
67     chmod(644,  $file); # WRONG
68     chmod(0644, $file); # right
69
70 Note the mistake in the first line was specifying the decimal literal
71 644, rather than the intended octal literal 0644.  The problem can
72 be seen with:
73
74     printf("%#o",644); # prints 01204
75
76 Surely you had not intended C<chmod(01204, $file);> - did you?  If you
77 want to use numeric literals as arguments to chmod() et al. then please
78 try to express them as octal constants, that is with a leading zero and
79 with the following digits restricted to the set 0..7.
80
81 =head2 Does Perl have a round() function?  What about ceil() and floor()?  Trig functions?
82
83 Remember that int() merely truncates toward 0.  For rounding to a
84 certain number of digits, sprintf() or printf() is usually the easiest
85 route.
86
87     printf("%.3f", 3.1415926535);       # prints 3.142
88
89 The POSIX module (part of the standard Perl distribution) implements
90 ceil(), floor(), and a number of other mathematical and trigonometric
91 functions.
92
93     use POSIX;
94     $ceil   = ceil(3.5);                        # 4
95     $floor  = floor(3.5);                       # 3
96
97 In 5.000 to 5.003 perls, trigonometry was done in the Math::Complex
98 module.  With 5.004, the Math::Trig module (part of the standard Perl
99 distribution) implements the trigonometric functions. Internally it
100 uses the Math::Complex module and some functions can break out from
101 the real axis into the complex plane, for example the inverse sine of
102 2.
103
104 Rounding in financial applications can have serious implications, and
105 the rounding method used should be specified precisely.  In these
106 cases, it probably pays not to trust whichever system rounding is
107 being used by Perl, but to instead implement the rounding function you
108 need yourself.
109
110 To see why, notice how you'll still have an issue on half-way-point
111 alternation:
112
113     for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
114
115     0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7
116     0.8 0.8 0.9 0.9 1.0 1.0
117
118 Don't blame Perl.  It's the same as in C.  IEEE says we have to do this.
119 Perl numbers whose absolute values are integers under 2**31 (on 32 bit
120 machines) will work pretty much like mathematical integers.  Other numbers
121 are not guaranteed.
122
123 =head2 How do I convert between numeric representations/bases/radixes?
124
125 As always with Perl there is more than one way to do it.  Below
126 are a few examples of approaches to making common conversions
127 between number representations.  This is intended to be representational
128 rather than exhaustive.
129
130 Some of the examples below use the Bit::Vector module from CPAN.
131 The reason you might choose Bit::Vector over the perl built in
132 functions is that it works with numbers of ANY size, that it is
133 optimized for speed on some operations, and for at least some
134 programmers the notation might be familiar.
135
136 =over 4
137
138 =item How do I convert hexadecimal into decimal
139
140 Using perl's built in conversion of 0x notation:
141
142     $dec = 0xDEADBEEF;
143
144 Using the hex function:
145
146     $dec = hex("DEADBEEF");
147
148 Using pack:
149
150     $dec = unpack("N", pack("H8", substr("0" x 8 . "DEADBEEF", -8)));
151
152 Using the CPAN module Bit::Vector:
153
154     use Bit::Vector;
155     $vec = Bit::Vector->new_Hex(32, "DEADBEEF");
156     $dec = $vec->to_Dec();
157
158 =item How do I convert from decimal to hexadecimal
159
160 Using sprintf:
161
162     $hex = sprintf("%X", 3735928559); # upper case A-F
163     $hex = sprintf("%x", 3735928559); # lower case a-f
164
165 Using unpack:
166
167     $hex = unpack("H*", pack("N", 3735928559));
168
169 Using Bit::Vector:
170
171     use Bit::Vector;
172     $vec = Bit::Vector->new_Dec(32, -559038737);
173     $hex = $vec->to_Hex();
174
175 And Bit::Vector supports odd bit counts:
176
177     use Bit::Vector;
178     $vec = Bit::Vector->new_Dec(33, 3735928559);
179     $vec->Resize(32); # suppress leading 0 if unwanted
180     $hex = $vec->to_Hex();
181
182 =item How do I convert from octal to decimal
183
184 Using Perl's built in conversion of numbers with leading zeros:
185
186     $dec = 033653337357; # note the leading 0!
187
188 Using the oct function:
189
190     $dec = oct("33653337357");
191
192 Using Bit::Vector:
193
194     use Bit::Vector;
195     $vec = Bit::Vector->new(32);
196     $vec->Chunk_List_Store(3, split(//, reverse "33653337357"));
197     $dec = $vec->to_Dec();
198
199 =item How do I convert from decimal to octal
200
201 Using sprintf:
202
203     $oct = sprintf("%o", 3735928559);
204
205 Using Bit::Vector:
206
207     use Bit::Vector;
208     $vec = Bit::Vector->new_Dec(32, -559038737);
209     $oct = reverse join('', $vec->Chunk_List_Read(3));
210
211 =item How do I convert from binary to decimal
212
213 Perl 5.6 lets you write binary numbers directly with
214 the 0b notation:
215
216     $number = 0b10110110;
217
218 Using oct:
219
220     my $input = "10110110";
221     $decimal = oct( "0b$input" );
222
223 Using pack and ord:
224
225     $decimal = ord(pack('B8', '10110110'));
226
227 Using pack and unpack for larger strings:
228
229     $int = unpack("N", pack("B32",
230         substr("0" x 32 . "11110101011011011111011101111", -32)));
231     $dec = sprintf("%d", $int);
232
233     # substr() is used to left pad a 32 character string with zeros.
234
235 Using Bit::Vector:
236
237     $vec = Bit::Vector->new_Bin(32, "11011110101011011011111011101111");
238     $dec = $vec->to_Dec();
239
240 =item How do I convert from decimal to binary
241
242 Using sprintf (perl 5.6+):
243
244     $bin = sprintf("%b", 3735928559);
245
246 Using unpack:
247
248     $bin = unpack("B*", pack("N", 3735928559));
249
250 Using Bit::Vector:
251
252     use Bit::Vector;
253     $vec = Bit::Vector->new_Dec(32, -559038737);
254     $bin = $vec->to_Bin();
255
256 The remaining transformations (e.g. hex -> oct, bin -> hex, etc.)
257 are left as an exercise to the inclined reader.
258
259 =back
260
261 =head2 Why doesn't & work the way I want it to?
262
263 The behavior of binary arithmetic operators depends on whether they're
264 used on numbers or strings.  The operators treat a string as a series
265 of bits and work with that (the string C<"3"> is the bit pattern
266 C<00110011>).  The operators work with the binary form of a number
267 (the number C<3> is treated as the bit pattern C<00000011>).
268
269 So, saying C<11 & 3> performs the "and" operation on numbers (yielding
270 C<3>).  Saying C<"11" & "3"> performs the "and" operation on strings
271 (yielding C<"1">).
272
273 Most problems with C<&> and C<|> arise because the programmer thinks
274 they have a number but really it's a string.  The rest arise because
275 the programmer says:
276
277     if ("\020\020" & "\101\101") {
278         # ...
279     }
280
281 but a string consisting of two null bytes (the result of C<"\020\020"
282 & "\101\101">) is not a false value in Perl.  You need:
283
284     if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
285         # ...
286     }
287
288 =head2 How do I multiply matrices?
289
290 Use the Math::Matrix or Math::MatrixReal modules (available from CPAN)
291 or the PDL extension (also available from CPAN).
292
293 =head2 How do I perform an operation on a series of integers?
294
295 To call a function on each element in an array, and collect the
296 results, use:
297
298     @results = map { my_func($_) } @array;
299
300 For example:
301
302     @triple = map { 3 * $_ } @single;
303
304 To call a function on each element of an array, but ignore the
305 results:
306
307     foreach $iterator (@array) {
308         some_func($iterator);
309     }
310
311 To call a function on each integer in a (small) range, you B<can> use:
312
313     @results = map { some_func($_) } (5 .. 25);
314
315 but you should be aware that the C<..> operator creates an array of
316 all integers in the range.  This can take a lot of memory for large
317 ranges.  Instead use:
318
319     @results = ();
320     for ($i=5; $i < 500_005; $i++) {
321         push(@results, some_func($i));
322     }
323
324 This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
325 loop will iterate over the range, without creating the entire range.
326
327     for my $i (5 .. 500_005) {
328         push(@results, some_func($i));
329     }
330
331 will not create a list of 500,000 integers.
332
333 =head2 How can I output Roman numerals?
334
335 Get the http://www.cpan.org/modules/by-module/Roman module.
336
337 =head2 Why aren't my random numbers random?
338
339 If you're using a version of Perl before 5.004, you must call C<srand>
340 once at the start of your program to seed the random number generator.
341
342          BEGIN { srand() if $] < 5.004 }
343
344 5.004 and later automatically call C<srand> at the beginning.  Don't
345 call C<srand> more than once---you make your numbers less random, rather
346 than more.
347
348 Computers are good at being predictable and bad at being random
349 (despite appearances caused by bugs in your programs :-).  see the
350 F<random> article in the "Far More Than You Ever Wanted To Know"
351 collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz , courtesy of
352 Tom Phoenix, talks more about this.  John von Neumann said, ``Anyone
353 who attempts to generate random numbers by deterministic means is, of
354 course, living in a state of sin.''
355
356 If you want numbers that are more random than C<rand> with C<srand>
357 provides, you should also check out the Math::TrulyRandom module from
358 CPAN.  It uses the imperfections in your system's timer to generate
359 random numbers, but this takes quite a while.  If you want a better
360 pseudorandom generator than comes with your operating system, look at
361 ``Numerical Recipes in C'' at http://www.nr.com/ .
362
363 =head2 How do I get a random number between X and Y?
364
365 Use the following simple function.  It selects a random integer between
366 (and possibly including!) the two given integers, e.g.,
367 C<random_int_in(50,120)>
368
369    sub random_int_in ($$) {
370      my($min, $max) = @_;
371       # Assumes that the two arguments are integers themselves!
372      return $min if $min == $max;
373      ($min, $max) = ($max, $min)  if  $min > $max;
374      return $min + int rand(1 + $max - $min);
375    }
376
377 =head1 Data: Dates
378
379 =head2 How do I find the day or week of the year?
380
381 The localtime function returns the day of the week.  Without an
382 argument localtime uses the current time.
383
384     $day_of_year = (localtime)[7];
385
386 The POSIX module can also format a date as the day of the year or
387 week of the year.
388
389         use POSIX qw/strftime/;
390         my $day_of_year  = strftime "%j", localtime;
391         my $week_of_year = strftime "%W", localtime;
392
393 To get the day of year for any date, use the Time::Local module to get
394 a time in epoch seconds for the argument to localtime.
395
396         use POSIX qw/strftime/;
397         use Time::Local;
398         my $week_of_year = strftime "%W", 
399                 localtime( timelocal( 0, 0, 0, 18, 11, 1987 ) );
400
401 The Date::Calc module provides two functions for to calculate these.
402
403         use Date::Calc;
404         my $day_of_year  = Day_of_Year(  1987, 12, 18 );
405         my $week_of_year = Week_of_Year( 1987, 12, 18 );
406
407 =head2 How do I find the current century or millennium?
408
409 Use the following simple functions:
410
411     sub get_century    {
412         return int((((localtime(shift || time))[5] + 1999))/100);
413     }
414     sub get_millennium {
415         return 1+int((((localtime(shift || time))[5] + 1899))/1000);
416     }
417
418 You can also use the POSIX strftime() function which may be a bit
419 slower but is easier to read and maintain.
420
421         use POSIX qw/strftime/;
422
423         my $week_of_the_year = strftime "%W", localtime;
424         my $day_of_the_year  = strftime "%j", localtime;
425
426 On some systems, the POSIX module's strftime() function has
427 been extended in a non-standard way to use a C<%C> format,
428 which they sometimes claim is the "century".  It isn't,
429 because on most such systems, this is only the first two
430 digits of the four-digit year, and thus cannot be used to
431 reliably determine the current century or millennium.
432
433 =head2 How can I compare two dates and find the difference?
434
435 If you're storing your dates as epoch seconds then simply subtract one
436 from the other.  If you've got a structured date (distinct year, day,
437 month, hour, minute, seconds values), then for reasons of accessibility,
438 simplicity, and efficiency, merely use either timelocal or timegm (from
439 the Time::Local module in the standard distribution) to reduce structured
440 dates to epoch seconds.  However, if you don't know the precise format of
441 your dates, then you should probably use either of the Date::Manip and
442 Date::Calc modules from CPAN before you go hacking up your own parsing
443 routine to handle arbitrary date formats.
444
445 =head2 How can I take a string and turn it into epoch seconds?
446
447 If it's a regular enough string that it always has the same format,
448 you can split it up and pass the parts to C<timelocal> in the standard
449 Time::Local module.  Otherwise, you should look into the Date::Calc
450 and Date::Manip modules from CPAN.
451
452 =head2 How can I find the Julian Day?
453
454 Use the Time::JulianDay module (part of the Time-modules bundle
455 available from CPAN.)
456
457 Before you immerse yourself too deeply in this, be sure to verify that
458 it is the I<Julian> Day you really want.  Are you interested in a way
459 of getting serial days so that you just can tell how many days they
460 are apart or so that you can do also other date arithmetic?  If you
461 are interested in performing date arithmetic, this can be done using
462 modules Date::Manip or Date::Calc.
463
464 There is too many details and much confusion on this issue to cover in
465 this FAQ, but the term is applied (correctly) to a calendar now
466 supplanted by the Gregorian Calendar, with the Julian Calendar failing
467 to adjust properly for leap years on centennial years (among other
468 annoyances).  The term is also used (incorrectly) to mean: [1] days in
469 the Gregorian Calendar; and [2] days since a particular starting time
470 or `epoch', usually 1970 in the Unix world and 1980 in the
471 MS-DOS/Windows world.  If you find that it is not the first meaning
472 that you really want, then check out the Date::Manip and Date::Calc
473 modules.  (Thanks to David Cassell for most of this text.)
474
475 =head2 How do I find yesterday's date?
476
477 If you only need to find the date (and not the same time), you
478 can use the Date::Calc module.
479
480         use Date::Calc qw(Today Add_Delta_Days);
481
482         my @date = Add_Delta_Days( Today(), -1 );
483
484         print "@date\n";
485
486 Most people try to use the time rather than the calendar to
487 figure out dates, but that assumes that your days are
488 twenty-four hours each.  For most people, there are two days
489 a year when they aren't: the switch to and from summer time
490 throws this off. Russ Allbery offers this solution.
491
492     sub yesterday {
493                 my $now  = defined $_[0] ? $_[0] : time;
494                 my $then = $now - 60 * 60 * 24;
495                 my $ndst = (localtime $now)[8] > 0;
496                 my $tdst = (localtime $then)[8] > 0;
497                 $then - ($tdst - $ndst) * 60 * 60;
498                 }
499
500 Should give you "this time yesterday" in seconds since epoch relative to
501 the first argument or the current time if no argument is given and
502 suitable for passing to localtime or whatever else you need to do with
503 it.  $ndst is whether we're currently in daylight savings time; $tdst is
504 whether the point 24 hours ago was in daylight savings time.  If $tdst
505 and $ndst are the same, a boundary wasn't crossed, and the correction
506 will subtract 0.  If $tdst is 1 and $ndst is 0, subtract an hour more
507 from yesterday's time since we gained an extra hour while going off
508 daylight savings time.  If $tdst is 0 and $ndst is 1, subtract a
509 negative hour (add an hour) to yesterday's time since we lost an hour.
510
511 All of this is because during those days when one switches off or onto
512 DST, a "day" isn't 24 hours long; it's either 23 or 25.
513
514 The explicit settings of $ndst and $tdst are necessary because localtime
515 only says it returns the system tm struct, and the system tm struct at
516 least on Solaris doesn't guarantee any particular positive value (like,
517 say, 1) for isdst, just a positive value.  And that value can
518 potentially be negative, if DST information isn't available (this sub
519 just treats those cases like no DST).
520
521 Note that between 2am and 3am on the day after the time zone switches
522 off daylight savings time, the exact hour of "yesterday" corresponding
523 to the current hour is not clearly defined.  Note also that if used
524 between 2am and 3am the day after the change to daylight savings time,
525 the result will be between 3am and 4am of the previous day; it's
526 arguable whether this is correct.
527
528 This sub does not attempt to deal with leap seconds (most things don't).
529
530
531
532 =head2 Does Perl have a Year 2000 problem?  Is Perl Y2K compliant?
533
534 Short answer: No, Perl does not have a Year 2000 problem.  Yes, Perl is
535 Y2K compliant (whatever that means).  The programmers you've hired to
536 use it, however, probably are not.
537
538 Long answer: The question belies a true understanding of the issue.
539 Perl is just as Y2K compliant as your pencil--no more, and no less.
540 Can you use your pencil to write a non-Y2K-compliant memo?  Of course
541 you can.  Is that the pencil's fault?  Of course it isn't.
542
543 The date and time functions supplied with Perl (gmtime and localtime)
544 supply adequate information to determine the year well beyond 2000
545 (2038 is when trouble strikes for 32-bit machines).  The year returned
546 by these functions when used in a list context is the year minus 1900.
547 For years between 1910 and 1999 this I<happens> to be a 2-digit decimal
548 number. To avoid the year 2000 problem simply do not treat the year as
549 a 2-digit number.  It isn't.
550
551 When gmtime() and localtime() are used in scalar context they return
552 a timestamp string that contains a fully-expanded year.  For example,
553 C<$timestamp = gmtime(1005613200)> sets $timestamp to "Tue Nov 13 01:00:00
554 2001".  There's no year 2000 problem here.
555
556 That doesn't mean that Perl can't be used to create non-Y2K compliant
557 programs.  It can.  But so can your pencil.  It's the fault of the user,
558 not the language.  At the risk of inflaming the NRA: ``Perl doesn't
559 break Y2K, people do.''  See http://language.perl.com/news/y2k.html for
560 a longer exposition.
561
562 =head1 Data: Strings
563
564 =head2 How do I validate input?
565
566 The answer to this question is usually a regular expression, perhaps
567 with auxiliary logic.  See the more specific questions (numbers, mail
568 addresses, etc.) for details.
569
570 =head2 How do I unescape a string?
571
572 It depends just what you mean by ``escape''.  URL escapes are dealt
573 with in L<perlfaq9>.  Shell escapes with the backslash (C<\>)
574 character are removed with
575
576     s/\\(.)/$1/g;
577
578 This won't expand C<"\n"> or C<"\t"> or any other special escapes.
579
580 =head2 How do I remove consecutive pairs of characters?
581
582 To turn C<"abbcccd"> into C<"abccd">:
583
584     s/(.)\1/$1/g;       # add /s to include newlines
585
586 Here's a solution that turns "abbcccd" to "abcd":
587
588     y///cs;     # y == tr, but shorter :-)
589
590 =head2 How do I expand function calls in a string?
591
592 This is documented in L<perlref>.  In general, this is fraught with
593 quoting and readability problems, but it is possible.  To interpolate
594 a subroutine call (in list context) into a string:
595
596     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
597
598 See also ``How can I expand variables in text strings?'' in this
599 section of the FAQ.
600
601 =head2 How do I find matching/nesting anything?
602
603 This isn't something that can be done in one regular expression, no
604 matter how complicated.  To find something between two single
605 characters, a pattern like C</x([^x]*)x/> will get the intervening
606 bits in $1. For multiple ones, then something more like
607 C</alpha(.*?)omega/> would be needed.  But none of these deals with
608 nested patterns.  For balanced expressions using C<(>, C<{>, C<[>
609 or C<< < >> as delimiters, use the CPAN module Regexp::Common, or see
610 L<perlre/(??{ code })>.  For other cases, you'll have to write a parser.
611
612 If you are serious about writing a parser, there are a number of
613 modules or oddities that will make your life a lot easier.  There are
614 the CPAN modules Parse::RecDescent, Parse::Yapp, and Text::Balanced;
615 and the byacc program.   Starting from perl 5.8 the Text::Balanced
616 is part of the standard distribution.
617
618 One simple destructive, inside-out approach that you might try is to
619 pull out the smallest nesting parts one at a time:
620
621     while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
622         # do something with $1
623     }
624
625 A more complicated and sneaky approach is to make Perl's regular
626 expression engine do it for you.  This is courtesy Dean Inada, and
627 rather has the nature of an Obfuscated Perl Contest entry, but it
628 really does work:
629
630     # $_ contains the string to parse
631     # BEGIN and END are the opening and closing markers for the
632     # nested text.
633
634     @( = ('(','');
635     @) = (')','');
636     ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
637     @$ = (eval{/$re/},$@!~/unmatched/i);
638     print join("\n",@$[0..$#$]) if( $$[-1] );
639
640 =head2 How do I reverse a string?
641
642 Use reverse() in scalar context, as documented in
643 L<perlfunc/reverse>.
644
645     $reversed = reverse $string;
646
647 =head2 How do I expand tabs in a string?
648
649 You can do it yourself:
650
651     1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
652
653 Or you can just use the Text::Tabs module (part of the standard Perl
654 distribution).
655
656     use Text::Tabs;
657     @expanded_lines = expand(@lines_with_tabs);
658
659 =head2 How do I reformat a paragraph?
660
661 Use Text::Wrap (part of the standard Perl distribution):
662
663     use Text::Wrap;
664     print wrap("\t", '  ', @paragraphs);
665
666 The paragraphs you give to Text::Wrap should not contain embedded
667 newlines.  Text::Wrap doesn't justify the lines (flush-right).
668
669 Or use the CPAN module Text::Autoformat.  Formatting files can be easily
670 done by making a shell alias, like so:
671
672     alias fmt="perl -i -MText::Autoformat -n0777 \
673         -e 'print autoformat $_, {all=>1}' $*"
674
675 See the documentation for Text::Autoformat to appreciate its many
676 capabilities.
677
678 =head2 How can I access or change N characters of a string?
679
680 You can access the first characters of a string with substr().
681 To get the first character, for example, start at position 0
682 and grab the string of length 1.
683
684
685         $string = "Just another Perl Hacker";
686     $first_char = substr( $string, 0, 1 );  #  'J'
687
688 To change part of a string, you can use the optional fourth
689 argument which is the replacement string.
690
691     substr( $string, 13, 4, "Perl 5.8.0" );
692
693 You can also use substr() as an lvalue.
694
695     substr( $string, 13, 4 ) =  "Perl 5.8.0";
696
697 =head2 How do I change the Nth occurrence of something?
698
699 You have to keep track of N yourself.  For example, let's say you want
700 to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
701 C<"whosoever"> or C<"whomsoever">, case insensitively.  These
702 all assume that $_ contains the string to be altered.
703
704     $count = 0;
705     s{((whom?)ever)}{
706         ++$count == 5           # is it the 5th?
707             ? "${2}soever"      # yes, swap
708             : $1                # renege and leave it there
709     }ige;
710
711 In the more general case, you can use the C</g> modifier in a C<while>
712 loop, keeping count of matches.
713
714     $WANT = 3;
715     $count = 0;
716     $_ = "One fish two fish red fish blue fish";
717     while (/(\w+)\s+fish\b/gi) {
718         if (++$count == $WANT) {
719             print "The third fish is a $1 one.\n";
720         }
721     }
722
723 That prints out: C<"The third fish is a red one.">  You can also use a
724 repetition count and repeated pattern like this:
725
726     /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
727
728 =head2 How can I count the number of occurrences of a substring within a string?
729
730 There are a number of ways, with varying efficiency.  If you want a
731 count of a certain single character (X) within a string, you can use the
732 C<tr///> function like so:
733
734     $string = "ThisXlineXhasXsomeXx'sXinXit";
735     $count = ($string =~ tr/X//);
736     print "There are $count X characters in the string";
737
738 This is fine if you are just looking for a single character.  However,
739 if you are trying to count multiple character substrings within a
740 larger string, C<tr///> won't work.  What you can do is wrap a while()
741 loop around a global pattern match.  For example, let's count negative
742 integers:
743
744     $string = "-9 55 48 -2 23 -76 4 14 -44";
745     while ($string =~ /-\d+/g) { $count++ }
746     print "There are $count negative numbers in the string";
747
748 Another version uses a global match in list context, then assigns the
749 result to a scalar, producing a count of the number of matches.
750
751         $count = () = $string =~ /-\d+/g;
752
753 =head2 How do I capitalize all the words on one line?
754
755 To make the first letter of each word upper case:
756
757         $line =~ s/\b(\w)/\U$1/g;
758
759 This has the strange effect of turning "C<don't do it>" into "C<Don'T
760 Do It>".  Sometimes you might want this.  Other times you might need a
761 more thorough solution (Suggested by brian d foy):
762
763     $string =~ s/ (
764                  (^\w)    #at the beginning of the line
765                    |      # or
766                  (\s\w)   #preceded by whitespace
767                    )
768                 /\U$1/xg;
769     $string =~ /([\w']+)/\u\L$1/g;
770
771 To make the whole line upper case:
772
773         $line = uc($line);
774
775 To force each word to be lower case, with the first letter upper case:
776
777         $line =~ s/(\w+)/\u\L$1/g;
778
779 You can (and probably should) enable locale awareness of those
780 characters by placing a C<use locale> pragma in your program.
781 See L<perllocale> for endless details on locales.
782
783 This is sometimes referred to as putting something into "title
784 case", but that's not quite accurate.  Consider the proper
785 capitalization of the movie I<Dr. Strangelove or: How I Learned to
786 Stop Worrying and Love the Bomb>, for example.
787
788 Damian Conway's L<Text::Autoformat> module provides some smart
789 case transformations:
790
791     use Text::Autoformat;
792     my $x = "Dr. Strangelove or: How I Learned to Stop ".
793       "Worrying and Love the Bomb";
794
795     print $x, "\n";
796     for my $style (qw( sentence title highlight ))
797     {
798         print autoformat($x, { case => $style }), "\n";
799     }
800
801 =head2 How can I split a [character] delimited string except when inside [character]?
802
803 Several modules can handle this sort of pasing---Text::Balanced,
804 Text::CVS, Text::CVS_XS, and Text::ParseWords, among others.
805
806 Take the example case of trying to split a string that is
807 comma-separated into its different fields. You can't use C<split(/,/)>
808 because you shouldn't split if the comma is inside quotes.  For
809 example, take a data line like this:
810
811     SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
812
813 Due to the restriction of the quotes, this is a fairly complex
814 problem.  Thankfully, we have Jeffrey Friedl, author of
815 I<Mastering Regular Expressions>, to handle these for us.  He
816 suggests (assuming your string is contained in $text):
817
818      @new = ();
819      push(@new, $+) while $text =~ m{
820          "([^\"\\]*(?:\\.[^\"\\]*)*)",?  # groups the phrase inside the quotes
821        | ([^,]+),?
822        | ,
823      }gx;
824      push(@new, undef) if substr($text,-1,1) eq ',';
825
826 If you want to represent quotation marks inside a
827 quotation-mark-delimited field, escape them with backslashes (eg,
828 C<"like \"this\"">.
829
830 Alternatively, the Text::ParseWords module (part of the standard Perl
831 distribution) lets you say:
832
833     use Text::ParseWords;
834     @new = quotewords(",", 0, $text);
835
836 There's also a Text::CSV (Comma-Separated Values) module on CPAN.
837
838 =head2 How do I strip blank space from the beginning/end of a string?
839
840 Although the simplest approach would seem to be
841
842     $string =~ s/^\s*(.*?)\s*$/$1/;
843
844 not only is this unnecessarily slow and destructive, it also fails with
845 embedded newlines.  It is much faster to do this operation in two steps:
846
847     $string =~ s/^\s+//;
848     $string =~ s/\s+$//;
849
850 Or more nicely written as:
851
852     for ($string) {
853         s/^\s+//;
854         s/\s+$//;
855     }
856
857 This idiom takes advantage of the C<foreach> loop's aliasing
858 behavior to factor out common code.  You can do this
859 on several strings at once, or arrays, or even the
860 values of a hash if you use a slice:
861
862     # trim whitespace in the scalar, the array,
863     # and all the values in the hash
864     foreach ($scalar, @array, @hash{keys %hash}) {
865         s/^\s+//;
866         s/\s+$//;
867     }
868
869 =head2 How do I pad a string with blanks or pad a number with zeroes?
870
871 In the following examples, C<$pad_len> is the length to which you wish
872 to pad the string, C<$text> or C<$num> contains the string to be padded,
873 and C<$pad_char> contains the padding character. You can use a single
874 character string constant instead of the C<$pad_char> variable if you
875 know what it is in advance. And in the same way you can use an integer in
876 place of C<$pad_len> if you know the pad length in advance.
877
878 The simplest method uses the C<sprintf> function. It can pad on the left
879 or right with blanks and on the left with zeroes and it will not
880 truncate the result. The C<pack> function can only pad strings on the
881 right with blanks and it will truncate the result to a maximum length of
882 C<$pad_len>.
883
884     # Left padding a string with blanks (no truncation):
885         $padded = sprintf("%${pad_len}s", $text);
886         $padded = sprintf("%*s", $pad_len, $text);  # same thing
887
888     # Right padding a string with blanks (no truncation):
889         $padded = sprintf("%-${pad_len}s", $text);
890         $padded = sprintf("%-*s", $pad_len, $text); # same thing
891
892     # Left padding a number with 0 (no truncation):
893         $padded = sprintf("%0${pad_len}d", $num);
894         $padded = sprintf("%0*d", $pad_len, $num); # same thing
895
896     # Right padding a string with blanks using pack (will truncate):
897     $padded = pack("A$pad_len",$text);
898
899 If you need to pad with a character other than blank or zero you can use
900 one of the following methods.  They all generate a pad string with the
901 C<x> operator and combine that with C<$text>. These methods do
902 not truncate C<$text>.
903
904 Left and right padding with any character, creating a new string:
905
906     $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
907     $padded = $text . $pad_char x ( $pad_len - length( $text ) );
908
909 Left and right padding with any character, modifying C<$text> directly:
910
911     substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
912     $text .= $pad_char x ( $pad_len - length( $text ) );
913
914 =head2 How do I extract selected columns from a string?
915
916 Use substr() or unpack(), both documented in L<perlfunc>.
917 If you prefer thinking in terms of columns instead of widths,
918 you can use this kind of thing:
919
920     # determine the unpack format needed to split Linux ps output
921     # arguments are cut columns
922     my $fmt = cut2fmt(8, 14, 20, 26, 30, 34, 41, 47, 59, 63, 67, 72);
923
924     sub cut2fmt {
925         my(@positions) = @_;
926         my $template  = '';
927         my $lastpos   = 1;
928         for my $place (@positions) {
929             $template .= "A" . ($place - $lastpos) . " ";
930             $lastpos   = $place;
931         }
932         $template .= "A*";
933         return $template;
934     }
935
936 =head2 How do I find the soundex value of a string?
937
938 Use the standard Text::Soundex module distributed with Perl.
939 Before you do so, you may want to determine whether `soundex' is in
940 fact what you think it is.  Knuth's soundex algorithm compresses words
941 into a small space, and so it does not necessarily distinguish between
942 two words which you might want to appear separately.  For example, the
943 last names `Knuth' and `Kant' are both mapped to the soundex code K530.
944 If Text::Soundex does not do what you are looking for, you might want
945 to consider the String::Approx module available at CPAN.
946
947 =head2 How can I expand variables in text strings?
948
949 Let's assume that you have a string like:
950
951     $text = 'this has a $foo in it and a $bar';
952
953 If those were both global variables, then this would
954 suffice:
955
956     $text =~ s/\$(\w+)/${$1}/g;  # no /e needed
957
958 But since they are probably lexicals, or at least, they could
959 be, you'd have to do this:
960
961     $text =~ s/(\$\w+)/$1/eeg;
962     die if $@;                  # needed /ee, not /e
963
964 It's probably better in the general case to treat those
965 variables as entries in some special hash.  For example:
966
967     %user_defs = (
968         foo  => 23,
969         bar  => 19,
970     );
971     $text =~ s/\$(\w+)/$user_defs{$1}/g;
972
973 See also ``How do I expand function calls in a string?'' in this section
974 of the FAQ.
975
976 =head2 What's wrong with always quoting "$vars"?
977
978 The problem is that those double-quotes force stringification--
979 coercing numbers and references into strings--even when you
980 don't want them to be strings.  Think of it this way: double-quote
981 expansion is used to produce new strings.  If you already
982 have a string, why do you need more?
983
984 If you get used to writing odd things like these:
985
986     print "$var";       # BAD
987     $new = "$old";      # BAD
988     somefunc("$var");   # BAD
989
990 You'll be in trouble.  Those should (in 99.8% of the cases) be
991 the simpler and more direct:
992
993     print $var;
994     $new = $old;
995     somefunc($var);
996
997 Otherwise, besides slowing you down, you're going to break code when
998 the thing in the scalar is actually neither a string nor a number, but
999 a reference:
1000
1001     func(\@array);
1002     sub func {
1003         my $aref = shift;
1004         my $oref = "$aref";  # WRONG
1005     }
1006
1007 You can also get into subtle problems on those few operations in Perl
1008 that actually do care about the difference between a string and a
1009 number, such as the magical C<++> autoincrement operator or the
1010 syscall() function.
1011
1012 Stringification also destroys arrays.
1013
1014     @lines = `command`;
1015     print "@lines";             # WRONG - extra blanks
1016     print @lines;               # right
1017
1018 =head2 Why don't my E<lt>E<lt>HERE documents work?
1019
1020 Check for these three things:
1021
1022 =over 4
1023
1024 =item There must be no space after the E<lt>E<lt> part.
1025
1026 =item There (probably) should be a semicolon at the end.
1027
1028 =item You can't (easily) have any space in front of the tag.
1029
1030 =back
1031
1032 If you want to indent the text in the here document, you
1033 can do this:
1034
1035     # all in one
1036     ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
1037         your text
1038         goes here
1039     HERE_TARGET
1040
1041 But the HERE_TARGET must still be flush against the margin.
1042 If you want that indented also, you'll have to quote
1043 in the indentation.
1044
1045     ($quote = <<'    FINIS') =~ s/^\s+//gm;
1046             ...we will have peace, when you and all your works have
1047             perished--and the works of your dark master to whom you
1048             would deliver us. You are a liar, Saruman, and a corrupter
1049             of men's hearts.  --Theoden in /usr/src/perl/taint.c
1050         FINIS
1051     $quote =~ s/\s+--/\n--/;
1052
1053 A nice general-purpose fixer-upper function for indented here documents
1054 follows.  It expects to be called with a here document as its argument.
1055 It looks to see whether each line begins with a common substring, and
1056 if so, strips that substring off.  Otherwise, it takes the amount of leading
1057 whitespace found on the first line and removes that much off each
1058 subsequent line.
1059
1060     sub fix {
1061         local $_ = shift;
1062         my ($white, $leader);  # common whitespace and common leading string
1063         if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) {
1064             ($white, $leader) = ($2, quotemeta($1));
1065         } else {
1066             ($white, $leader) = (/^(\s+)/, '');
1067         }
1068         s/^\s*?$leader(?:$white)?//gm;
1069         return $_;
1070     }
1071
1072 This works with leading special strings, dynamically determined:
1073
1074     $remember_the_main = fix<<'    MAIN_INTERPRETER_LOOP';
1075         @@@ int
1076         @@@ runops() {
1077         @@@     SAVEI32(runlevel);
1078         @@@     runlevel++;
1079         @@@     while ( op = (*op->op_ppaddr)() );
1080         @@@     TAINT_NOT;
1081         @@@     return 0;
1082         @@@ }
1083     MAIN_INTERPRETER_LOOP
1084
1085 Or with a fixed amount of leading whitespace, with remaining
1086 indentation correctly preserved:
1087
1088     $poem = fix<<EVER_ON_AND_ON;
1089        Now far ahead the Road has gone,
1090           And I must follow, if I can,
1091        Pursuing it with eager feet,
1092           Until it joins some larger way
1093        Where many paths and errands meet.
1094           And whither then? I cannot say.
1095                 --Bilbo in /usr/src/perl/pp_ctl.c
1096     EVER_ON_AND_ON
1097
1098 =head1 Data: Arrays
1099
1100 =head2 What is the difference between a list and an array?
1101
1102 An array has a changeable length.  A list does not.  An array is something
1103 you can push or pop, while a list is a set of values.  Some people make
1104 the distinction that a list is a value while an array is a variable.
1105 Subroutines are passed and return lists, you put things into list
1106 context, you initialize arrays with lists, and you foreach() across
1107 a list.  C<@> variables are arrays, anonymous arrays are arrays, arrays
1108 in scalar context behave like the number of elements in them, subroutines
1109 access their arguments through the array C<@_>, and push/pop/shift only work
1110 on arrays.
1111
1112 As a side note, there's no such thing as a list in scalar context.
1113 When you say
1114
1115     $scalar = (2, 5, 7, 9);
1116
1117 you're using the comma operator in scalar context, so it uses the scalar
1118 comma operator.  There never was a list there at all!  This causes the
1119 last value to be returned: 9.
1120
1121 =head2 What is the difference between $array[1] and @array[1]?
1122
1123 The former is a scalar value; the latter an array slice, making
1124 it a list with one (scalar) value.  You should use $ when you want a
1125 scalar value (most of the time) and @ when you want a list with one
1126 scalar value in it (very, very rarely; nearly never, in fact).
1127
1128 Sometimes it doesn't make a difference, but sometimes it does.
1129 For example, compare:
1130
1131     $good[0] = `some program that outputs several lines`;
1132
1133 with
1134
1135     @bad[0]  = `same program that outputs several lines`;
1136
1137 The C<use warnings> pragma and the B<-w> flag will warn you about these
1138 matters.
1139
1140 =head2 How can I remove duplicate elements from a list or array?
1141
1142 There are several possible ways, depending on whether the array is
1143 ordered and whether you wish to preserve the ordering.
1144
1145 =over 4
1146
1147 =item a)
1148
1149 If @in is sorted, and you want @out to be sorted:
1150 (this assumes all true values in the array)
1151
1152     $prev = "not equal to $in[0]";
1153     @out = grep($_ ne $prev && ($prev = $_, 1), @in);
1154
1155 This is nice in that it doesn't use much extra memory, simulating
1156 uniq(1)'s behavior of removing only adjacent duplicates.  The ", 1"
1157 guarantees that the expression is true (so that grep picks it up)
1158 even if the $_ is 0, "", or undef.
1159
1160 =item b)
1161
1162 If you don't know whether @in is sorted:
1163
1164     undef %saw;
1165     @out = grep(!$saw{$_}++, @in);
1166
1167 =item c)
1168
1169 Like (b), but @in contains only small integers:
1170
1171     @out = grep(!$saw[$_]++, @in);
1172
1173 =item d)
1174
1175 A way to do (b) without any loops or greps:
1176
1177     undef %saw;
1178     @saw{@in} = ();
1179     @out = sort keys %saw;  # remove sort if undesired
1180
1181 =item e)
1182
1183 Like (d), but @in contains only small positive integers:
1184
1185     undef @ary;
1186     @ary[@in] = @in;
1187     @out = grep {defined} @ary;
1188
1189 =back
1190
1191 But perhaps you should have been using a hash all along, eh?
1192
1193 =head2 How can I tell whether a certain element is contained in a list or array?
1194
1195 Hearing the word "in" is an I<in>dication that you probably should have
1196 used a hash, not a list or array, to store your data.  Hashes are
1197 designed to answer this question quickly and efficiently.  Arrays aren't.
1198
1199 That being said, there are several ways to approach this.  If you
1200 are going to make this query many times over arbitrary string values,
1201 the fastest way is probably to invert the original array and maintain a
1202 hash whose keys are the first array's values.
1203
1204     @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1205     %is_blue = ();
1206     for (@blues) { $is_blue{$_} = 1 }
1207
1208 Now you can check whether $is_blue{$some_color}.  It might have been a
1209 good idea to keep the blues all in a hash in the first place.
1210
1211 If the values are all small integers, you could use a simple indexed
1212 array.  This kind of an array will take up less space:
1213
1214     @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1215     @is_tiny_prime = ();
1216     for (@primes) { $is_tiny_prime[$_] = 1 }
1217     # or simply  @istiny_prime[@primes] = (1) x @primes;
1218
1219 Now you check whether $is_tiny_prime[$some_number].
1220
1221 If the values in question are integers instead of strings, you can save
1222 quite a lot of space by using bit strings instead:
1223
1224     @articles = ( 1..10, 150..2000, 2017 );
1225     undef $read;
1226     for (@articles) { vec($read,$_,1) = 1 }
1227
1228 Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1229
1230 Please do not use
1231
1232     ($is_there) = grep $_ eq $whatever, @array;
1233
1234 or worse yet
1235
1236     ($is_there) = grep /$whatever/, @array;
1237
1238 These are slow (checks every element even if the first matches),
1239 inefficient (same reason), and potentially buggy (what if there are
1240 regex characters in $whatever?).  If you're only testing once, then
1241 use:
1242
1243     $is_there = 0;
1244     foreach $elt (@array) {
1245         if ($elt eq $elt_to_find) {
1246             $is_there = 1;
1247             last;
1248         }
1249     }
1250     if ($is_there) { ... }
1251
1252 =head2 How do I compute the difference of two arrays?  How do I compute the intersection of two arrays?
1253
1254 Use a hash.  Here's code to do both and more.  It assumes that
1255 each element is unique in a given array:
1256
1257     @union = @intersection = @difference = ();
1258     %count = ();
1259     foreach $element (@array1, @array2) { $count{$element}++ }
1260     foreach $element (keys %count) {
1261         push @union, $element;
1262         push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1263     }
1264
1265 Note that this is the I<symmetric difference>, that is, all elements in
1266 either A or in B but not in both.  Think of it as an xor operation.
1267
1268 =head2 How do I test whether two arrays or hashes are equal?
1269
1270 The following code works for single-level arrays.  It uses a stringwise
1271 comparison, and does not distinguish defined versus undefined empty
1272 strings.  Modify if you have other needs.
1273
1274     $are_equal = compare_arrays(\@frogs, \@toads);
1275
1276     sub compare_arrays {
1277         my ($first, $second) = @_;
1278         no warnings;  # silence spurious -w undef complaints
1279         return 0 unless @$first == @$second;
1280         for (my $i = 0; $i < @$first; $i++) {
1281             return 0 if $first->[$i] ne $second->[$i];
1282         }
1283         return 1;
1284     }
1285
1286 For multilevel structures, you may wish to use an approach more
1287 like this one.  It uses the CPAN module FreezeThaw:
1288
1289     use FreezeThaw qw(cmpStr);
1290     @a = @b = ( "this", "that", [ "more", "stuff" ] );
1291
1292     printf "a and b contain %s arrays\n",
1293         cmpStr(\@a, \@b) == 0
1294             ? "the same"
1295             : "different";
1296
1297 This approach also works for comparing hashes.  Here
1298 we'll demonstrate two different answers:
1299
1300     use FreezeThaw qw(cmpStr cmpStrHard);
1301
1302     %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1303     $a{EXTRA} = \%b;
1304     $b{EXTRA} = \%a;
1305
1306     printf "a and b contain %s hashes\n",
1307         cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1308
1309     printf "a and b contain %s hashes\n",
1310         cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1311
1312
1313 The first reports that both those the hashes contain the same data,
1314 while the second reports that they do not.  Which you prefer is left as
1315 an exercise to the reader.
1316
1317 =head2 How do I find the first array element for which a condition is true?
1318
1319 To find the first array element which satisfies a condition, you can
1320 use the first() function in the List::Util module, which comes with
1321 Perl 5.8.  This example finds the first element that contains "Perl".
1322
1323         use List::Util qw(first);
1324
1325         my $element = first { /Perl/ } @array;
1326
1327 If you cannot use List::Util, you can make your own loop to do the
1328 same thing.  Once you find the element, you stop the loop with last.
1329
1330         my $found;
1331         foreach my $element ( @array )
1332                 {
1333                 if( /Perl/ ) { $found = $element; last }
1334                 }
1335
1336 If you want the array index, you can iterate through the indices
1337 and check the array element at each index until you find one
1338 that satisfies the condition.
1339
1340         my( $found, $index ) = ( undef, -1 );
1341     for( $i = 0; $i < @array; $i++ )
1342         {
1343         if( $array[$i] =~ /Perl/ )
1344                 {
1345                 $found = $array[$i];
1346                 $index = $i;
1347                 last;
1348                 }
1349         }
1350
1351 =head2 How do I handle linked lists?
1352
1353 In general, you usually don't need a linked list in Perl, since with
1354 regular arrays, you can push and pop or shift and unshift at either end,
1355 or you can use splice to add and/or remove arbitrary number of elements at
1356 arbitrary points.  Both pop and shift are both O(1) operations on Perl's
1357 dynamic arrays.  In the absence of shifts and pops, push in general
1358 needs to reallocate on the order every log(N) times, and unshift will
1359 need to copy pointers each time.
1360
1361 If you really, really wanted, you could use structures as described in
1362 L<perldsc> or L<perltoot> and do just what the algorithm book tells you
1363 to do.  For example, imagine a list node like this:
1364
1365     $node = {
1366         VALUE => 42,
1367         LINK  => undef,
1368     };
1369
1370 You could walk the list this way:
1371
1372     print "List: ";
1373     for ($node = $head;  $node; $node = $node->{LINK}) {
1374         print $node->{VALUE}, " ";
1375     }
1376     print "\n";
1377
1378 You could add to the list this way:
1379
1380     my ($head, $tail);
1381     $tail = append($head, 1);       # grow a new head
1382     for $value ( 2 .. 10 ) {
1383         $tail = append($tail, $value);
1384     }
1385
1386     sub append {
1387         my($list, $value) = @_;
1388         my $node = { VALUE => $value };
1389         if ($list) {
1390             $node->{LINK} = $list->{LINK};
1391             $list->{LINK} = $node;
1392         } else {
1393             $_[0] = $node;      # replace caller's version
1394         }
1395         return $node;
1396     }
1397
1398 But again, Perl's built-in are virtually always good enough.
1399
1400 =head2 How do I handle circular lists?
1401
1402 Circular lists could be handled in the traditional fashion with linked
1403 lists, or you could just do something like this with an array:
1404
1405     unshift(@array, pop(@array));  # the last shall be first
1406     push(@array, shift(@array));   # and vice versa
1407
1408 =head2 How do I shuffle an array randomly?
1409
1410 If you either have Perl 5.8.0 or later installed, or if you have
1411 Scalar-List-Utils 1.03 or later installed, you can say:
1412
1413     use List::Util 'shuffle';
1414
1415         @shuffled = shuffle(@list);
1416
1417 If not, you can use a Fisher-Yates shuffle.
1418
1419     sub fisher_yates_shuffle {
1420         my $deck = shift;  # $deck is a reference to an array
1421         my $i = @$deck;
1422         while ($i--) {
1423             my $j = int rand ($i+1);
1424             @$deck[$i,$j] = @$deck[$j,$i];
1425         }
1426     }
1427
1428     # shuffle my mpeg collection
1429     #
1430     my @mpeg = <audio/*/*.mp3>;
1431     fisher_yates_shuffle( \@mpeg );    # randomize @mpeg in place
1432     print @mpeg;
1433
1434 Note that the above implementation shuffles an array in place,
1435 unlike the List::Util::shuffle() which takes a list and returns
1436 a new shuffled list.
1437
1438 You've probably seen shuffling algorithms that work using splice,
1439 randomly picking another element to swap the current element with
1440
1441     srand;
1442     @new = ();
1443     @old = 1 .. 10;  # just a demo
1444     while (@old) {
1445         push(@new, splice(@old, rand @old, 1));
1446     }
1447
1448 This is bad because splice is already O(N), and since you do it N times,
1449 you just invented a quadratic algorithm; that is, O(N**2).  This does
1450 not scale, although Perl is so efficient that you probably won't notice
1451 this until you have rather largish arrays.
1452
1453 =head2 How do I process/modify each element of an array?
1454
1455 Use C<for>/C<foreach>:
1456
1457     for (@lines) {
1458         s/foo/bar/;     # change that word
1459         y/XZ/ZX/;       # swap those letters
1460     }
1461
1462 Here's another; let's compute spherical volumes:
1463
1464     for (@volumes = @radii) {   # @volumes has changed parts
1465         $_ **= 3;
1466         $_ *= (4/3) * 3.14159;  # this will be constant folded
1467     }
1468
1469 which can also be done with map() which is made to transform
1470 one list into another:
1471
1472         @volumes = map {$_ ** 3 * (4/3) * 3.14159} @radii;
1473
1474 If you want to do the same thing to modify the values of the
1475 hash, you can use the C<values> function.  As of Perl 5.6
1476 the values are not copied, so if you modify $orbit (in this
1477 case), you modify the value.
1478
1479     for $orbit ( values %orbits ) {
1480         ($orbit **= 3) *= (4/3) * 3.14159;
1481     }
1482
1483 Prior to perl 5.6 C<values> returned copies of the values,
1484 so older perl code often contains constructions such as
1485 C<@orbits{keys %orbits}> instead of C<values %orbits> where
1486 the hash is to be modified.
1487
1488 =head2 How do I select a random element from an array?
1489
1490 Use the rand() function (see L<perlfunc/rand>):
1491
1492     # at the top of the program:
1493     srand;                      # not needed for 5.004 and later
1494
1495     # then later on
1496     $index   = rand @array;
1497     $element = $array[$index];
1498
1499 Make sure you I<only call srand once per program, if then>.
1500 If you are calling it more than once (such as before each
1501 call to rand), you're almost certainly doing something wrong.
1502
1503 =head2 How do I permute N elements of a list?
1504
1505 Use the List::Permutor module on CPAN.  If the list is
1506 actually an array, try the Algorithm::Permute module (also
1507 on CPAN).  It's written in XS code and is very efficient.
1508
1509         use Algorithm::Permute;
1510         my @array = 'a'..'d';
1511         my $p_iterator = Algorithm::Permute->new ( \@array );
1512         while (my @perm = $p_iterator->next) {
1513            print "next permutation: (@perm)\n";
1514         }
1515
1516 For even faster execution, you could do:
1517
1518    use Algorithm::Permute;
1519    my @array = 'a'..'d';
1520    Algorithm::Permute::permute {
1521       print "next permutation: (@array)\n";
1522    } @array;
1523
1524 Here's a little program that generates all permutations of
1525 all the words on each line of input. The algorithm embodied
1526 in the permute() function is discussed in Volume 4 (still
1527 unpublished) of Knuth's I<The Art of Computer Programming>
1528 and will work on any list:
1529
1530         #!/usr/bin/perl -n
1531         # Fischer-Kause ordered permutation generator
1532
1533         sub permute (&@) {
1534                 my $code = shift;
1535                 my @idx = 0..$#_;
1536                 while ( $code->(@_[@idx]) ) {
1537                         my $p = $#idx;
1538                         --$p while $idx[$p-1] > $idx[$p];
1539                         my $q = $p or return;
1540                         push @idx, reverse splice @idx, $p;
1541                         ++$q while $idx[$p-1] > $idx[$q];
1542                         @idx[$p-1,$q]=@idx[$q,$p-1];
1543                 }
1544         }
1545
1546         permute {print"@_\n"} split;
1547
1548 =head2 How do I sort an array by (anything)?
1549
1550 Supply a comparison function to sort() (described in L<perlfunc/sort>):
1551
1552     @list = sort { $a <=> $b } @list;
1553
1554 The default sort function is cmp, string comparison, which would
1555 sort C<(1, 2, 10)> into C<(1, 10, 2)>.  C<< <=> >>, used above, is
1556 the numerical comparison operator.
1557
1558 If you have a complicated function needed to pull out the part you
1559 want to sort on, then don't do it inside the sort function.  Pull it
1560 out first, because the sort BLOCK can be called many times for the
1561 same element.  Here's an example of how to pull out the first word
1562 after the first number on each item, and then sort those words
1563 case-insensitively.
1564
1565     @idx = ();
1566     for (@data) {
1567         ($item) = /\d+\s*(\S+)/;
1568         push @idx, uc($item);
1569     }
1570     @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1571
1572 which could also be written this way, using a trick
1573 that's come to be known as the Schwartzian Transform:
1574
1575     @sorted = map  { $_->[0] }
1576               sort { $a->[1] cmp $b->[1] }
1577               map  { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1578
1579 If you need to sort on several fields, the following paradigm is useful.
1580
1581     @sorted = sort { field1($a) <=> field1($b) ||
1582                      field2($a) cmp field2($b) ||
1583                      field3($a) cmp field3($b)
1584                    }     @data;
1585
1586 This can be conveniently combined with precalculation of keys as given
1587 above.
1588
1589 See the F<sort> artitcle article in the "Far More Than You Ever Wanted
1590 To Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz for
1591 more about this approach.
1592
1593 See also the question below on sorting hashes.
1594
1595 =head2 How do I manipulate arrays of bits?
1596
1597 Use pack() and unpack(), or else vec() and the bitwise operations.
1598
1599 For example, this sets $vec to have bit N set if $ints[N] was set:
1600
1601     $vec = '';
1602     foreach(@ints) { vec($vec,$_,1) = 1 }
1603
1604 Here's how, given a vector in $vec, you can
1605 get those bits into your @ints array:
1606
1607     sub bitvec_to_list {
1608         my $vec = shift;
1609         my @ints;
1610         # Find null-byte density then select best algorithm
1611         if ($vec =~ tr/\0// / length $vec > 0.95) {
1612             use integer;
1613             my $i;
1614             # This method is faster with mostly null-bytes
1615             while($vec =~ /[^\0]/g ) {
1616                 $i = -9 + 8 * pos $vec;
1617                 push @ints, $i if vec($vec, ++$i, 1);
1618                 push @ints, $i if vec($vec, ++$i, 1);
1619                 push @ints, $i if vec($vec, ++$i, 1);
1620                 push @ints, $i if vec($vec, ++$i, 1);
1621                 push @ints, $i if vec($vec, ++$i, 1);
1622                 push @ints, $i if vec($vec, ++$i, 1);
1623                 push @ints, $i if vec($vec, ++$i, 1);
1624                 push @ints, $i if vec($vec, ++$i, 1);
1625             }
1626         } else {
1627             # This method is a fast general algorithm
1628             use integer;
1629             my $bits = unpack "b*", $vec;
1630             push @ints, 0 if $bits =~ s/^(\d)// && $1;
1631             push @ints, pos $bits while($bits =~ /1/g);
1632         }
1633         return \@ints;
1634     }
1635
1636 This method gets faster the more sparse the bit vector is.
1637 (Courtesy of Tim Bunce and Winfried Koenig.)
1638
1639 You can make the while loop a lot shorter with this suggestion
1640 from Benjamin Goldberg:
1641
1642         while($vec =~ /[^\0]+/g ) {
1643            push @ints, grep vec($vec, $_, 1), $-[0] * 8 .. $+[0] * 8;
1644         }
1645
1646 Or use the CPAN module Bit::Vector:
1647
1648     $vector = Bit::Vector->new($num_of_bits);
1649     $vector->Index_List_Store(@ints);
1650     @ints = $vector->Index_List_Read();
1651
1652 Bit::Vector provides efficient methods for bit vector, sets of small integers
1653 and "big int" math.
1654
1655 Here's a more extensive illustration using vec():
1656
1657     # vec demo
1658     $vector = "\xff\x0f\xef\xfe";
1659     print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ",
1660         unpack("N", $vector), "\n";
1661     $is_set = vec($vector, 23, 1);
1662     print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1663     pvec($vector);
1664
1665     set_vec(1,1,1);
1666     set_vec(3,1,1);
1667     set_vec(23,1,1);
1668
1669     set_vec(3,1,3);
1670     set_vec(3,2,3);
1671     set_vec(3,4,3);
1672     set_vec(3,4,7);
1673     set_vec(3,8,3);
1674     set_vec(3,8,7);
1675
1676     set_vec(0,32,17);
1677     set_vec(1,32,17);
1678
1679     sub set_vec {
1680         my ($offset, $width, $value) = @_;
1681         my $vector = '';
1682         vec($vector, $offset, $width) = $value;
1683         print "offset=$offset width=$width value=$value\n";
1684         pvec($vector);
1685     }
1686
1687     sub pvec {
1688         my $vector = shift;
1689         my $bits = unpack("b*", $vector);
1690         my $i = 0;
1691         my $BASE = 8;
1692
1693         print "vector length in bytes: ", length($vector), "\n";
1694         @bytes = unpack("A8" x length($vector), $bits);
1695         print "bits are: @bytes\n\n";
1696     }
1697
1698 =head2 Why does defined() return true on empty arrays and hashes?
1699
1700 The short story is that you should probably only use defined on scalars or
1701 functions, not on aggregates (arrays and hashes).  See L<perlfunc/defined>
1702 in the 5.004 release or later of Perl for more detail.
1703
1704 =head1 Data: Hashes (Associative Arrays)
1705
1706 =head2 How do I process an entire hash?
1707
1708 Use the each() function (see L<perlfunc/each>) if you don't care
1709 whether it's sorted:
1710
1711     while ( ($key, $value) = each %hash) {
1712         print "$key = $value\n";
1713     }
1714
1715 If you want it sorted, you'll have to use foreach() on the result of
1716 sorting the keys as shown in an earlier question.
1717
1718 =head2 What happens if I add or remove keys from a hash while iterating over it?
1719
1720 Don't do that. :-)
1721
1722 [lwall] In Perl 4, you were not allowed to modify a hash at all while
1723 iterating over it.  In Perl 5 you can delete from it, but you still
1724 can't add to it, because that might cause a doubling of the hash table,
1725 in which half the entries get copied up to the new top half of the
1726 table, at which point you've totally bamboozled the iterator code.
1727 Even if the table doesn't double, there's no telling whether your new
1728 entry will be inserted before or after the current iterator position.
1729
1730 Either treasure up your changes and make them after the iterator finishes
1731 or use keys to fetch all the old keys at once, and iterate over the list
1732 of keys.
1733
1734 =head2 How do I look up a hash element by value?
1735
1736 Create a reverse hash:
1737
1738     %by_value = reverse %by_key;
1739     $key = $by_value{$value};
1740
1741 That's not particularly efficient.  It would be more space-efficient
1742 to use:
1743
1744     while (($key, $value) = each %by_key) {
1745         $by_value{$value} = $key;
1746     }
1747
1748 If your hash could have repeated values, the methods above will only find
1749 one of the associated keys.   This may or may not worry you.  If it does
1750 worry you, you can always reverse the hash into a hash of arrays instead:
1751
1752      while (($key, $value) = each %by_key) {
1753          push @{$key_list_by_value{$value}}, $key;
1754      }
1755
1756 =head2 How can I know how many entries are in a hash?
1757
1758 If you mean how many keys, then all you have to do is
1759 use the keys() function in a scalar context:
1760
1761     $num_keys = keys %hash;
1762
1763 The keys() function also resets the iterator, which means that you may
1764 see strange results if you use this between uses of other hash operators
1765 such as each().
1766
1767 =head2 How do I sort a hash (optionally by value instead of key)?
1768
1769 Internally, hashes are stored in a way that prevents you from imposing
1770 an order on key-value pairs.  Instead, you have to sort a list of the
1771 keys or values:
1772
1773     @keys = sort keys %hash;    # sorted by key
1774     @keys = sort {
1775                     $hash{$a} cmp $hash{$b}
1776             } keys %hash;       # and by value
1777
1778 Here we'll do a reverse numeric sort by value, and if two keys are
1779 identical, sort by length of key, or if that fails, by straight ASCII
1780 comparison of the keys (well, possibly modified by your locale--see
1781 L<perllocale>).
1782
1783     @keys = sort {
1784                 $hash{$b} <=> $hash{$a}
1785                           ||
1786                 length($b) <=> length($a)
1787                           ||
1788                       $a cmp $b
1789     } keys %hash;
1790
1791 =head2 How can I always keep my hash sorted?
1792
1793 You can look into using the DB_File module and tie() using the
1794 $DB_BTREE hash bindings as documented in L<DB_File/"In Memory Databases">.
1795 The Tie::IxHash module from CPAN might also be instructive.
1796
1797 =head2 What's the difference between "delete" and "undef" with hashes?
1798
1799 Hashes contain pairs of scalars: the first is the key, the
1800 second is the value.  The key will be coerced to a string,
1801 although the value can be any kind of scalar: string,
1802 number, or reference.  If a key $key is present in
1803 %hash, C<exists($hash{$key})> will return true.  The value
1804 for a given key can be C<undef>, in which case
1805 C<$hash{$key}> will be C<undef> while C<exists $hash{$key}>
1806 will return true.  This corresponds to (C<$key>, C<undef>)
1807 being in the hash.
1808
1809 Pictures help...  here's the %hash table:
1810
1811           keys  values
1812         +------+------+
1813         |  a   |  3   |
1814         |  x   |  7   |
1815         |  d   |  0   |
1816         |  e   |  2   |
1817         +------+------+
1818
1819 And these conditions hold
1820
1821         $hash{'a'}                       is true
1822         $hash{'d'}                       is false
1823         defined $hash{'d'}               is true
1824         defined $hash{'a'}               is true
1825         exists $hash{'a'}                is true (Perl5 only)
1826         grep ($_ eq 'a', keys %hash)     is true
1827
1828 If you now say
1829
1830         undef $hash{'a'}
1831
1832 your table now reads:
1833
1834
1835           keys  values
1836         +------+------+
1837         |  a   | undef|
1838         |  x   |  7   |
1839         |  d   |  0   |
1840         |  e   |  2   |
1841         +------+------+
1842
1843 and these conditions now hold; changes in caps:
1844
1845         $hash{'a'}                       is FALSE
1846         $hash{'d'}                       is false
1847         defined $hash{'d'}               is true
1848         defined $hash{'a'}               is FALSE
1849         exists $hash{'a'}                is true (Perl5 only)
1850         grep ($_ eq 'a', keys %hash)     is true
1851
1852 Notice the last two: you have an undef value, but a defined key!
1853
1854 Now, consider this:
1855
1856         delete $hash{'a'}
1857
1858 your table now reads:
1859
1860           keys  values
1861         +------+------+
1862         |  x   |  7   |
1863         |  d   |  0   |
1864         |  e   |  2   |
1865         +------+------+
1866
1867 and these conditions now hold; changes in caps:
1868
1869         $hash{'a'}                       is false
1870         $hash{'d'}                       is false
1871         defined $hash{'d'}               is true
1872         defined $hash{'a'}               is false
1873         exists $hash{'a'}                is FALSE (Perl5 only)
1874         grep ($_ eq 'a', keys %hash)     is FALSE
1875
1876 See, the whole entry is gone!
1877
1878 =head2 Why don't my tied hashes make the defined/exists distinction?
1879
1880 This depends on the tied hash's implementation of EXISTS().
1881 For example, there isn't the concept of undef with hashes
1882 that are tied to DBM* files. It also means that exists() and
1883 defined() do the same thing with a DBM* file, and what they
1884 end up doing is not what they do with ordinary hashes.
1885
1886 =head2 How do I reset an each() operation part-way through?
1887
1888 Using C<keys %hash> in scalar context returns the number of keys in
1889 the hash I<and> resets the iterator associated with the hash.  You may
1890 need to do this if you use C<last> to exit a loop early so that when you
1891 re-enter it, the hash iterator has been reset.
1892
1893 =head2 How can I get the unique keys from two hashes?
1894
1895 First you extract the keys from the hashes into lists, then solve
1896 the "removing duplicates" problem described above.  For example:
1897
1898     %seen = ();
1899     for $element (keys(%foo), keys(%bar)) {
1900         $seen{$element}++;
1901     }
1902     @uniq = keys %seen;
1903
1904 Or more succinctly:
1905
1906     @uniq = keys %{{%foo,%bar}};
1907
1908 Or if you really want to save space:
1909
1910     %seen = ();
1911     while (defined ($key = each %foo)) {
1912         $seen{$key}++;
1913     }
1914     while (defined ($key = each %bar)) {
1915         $seen{$key}++;
1916     }
1917     @uniq = keys %seen;
1918
1919 =head2 How can I store a multidimensional array in a DBM file?
1920
1921 Either stringify the structure yourself (no fun), or else
1922 get the MLDBM (which uses Data::Dumper) module from CPAN and layer
1923 it on top of either DB_File or GDBM_File.
1924
1925 =head2 How can I make my hash remember the order I put elements into it?
1926
1927 Use the Tie::IxHash from CPAN.
1928
1929     use Tie::IxHash;
1930     tie my %myhash, 'Tie::IxHash';
1931     for (my $i=0; $i<20; $i++) {
1932         $myhash{$i} = 2*$i;
1933     }
1934     my @keys = keys %myhash;
1935     # @keys = (0,1,2,3,...)
1936
1937 =head2 Why does passing a subroutine an undefined element in a hash create it?
1938
1939 If you say something like:
1940
1941     somefunc($hash{"nonesuch key here"});
1942
1943 Then that element "autovivifies"; that is, it springs into existence
1944 whether you store something there or not.  That's because functions
1945 get scalars passed in by reference.  If somefunc() modifies C<$_[0]>,
1946 it has to be ready to write it back into the caller's version.
1947
1948 This has been fixed as of Perl5.004.
1949
1950 Normally, merely accessing a key's value for a nonexistent key does
1951 I<not> cause that key to be forever there.  This is different than
1952 awk's behavior.
1953
1954 =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
1955
1956 Usually a hash ref, perhaps like this:
1957
1958     $record = {
1959         NAME   => "Jason",
1960         EMPNO  => 132,
1961         TITLE  => "deputy peon",
1962         AGE    => 23,
1963         SALARY => 37_000,
1964         PALS   => [ "Norbert", "Rhys", "Phineas"],
1965     };
1966
1967 References are documented in L<perlref> and the upcoming L<perlreftut>.
1968 Examples of complex data structures are given in L<perldsc> and
1969 L<perllol>.  Examples of structures and object-oriented classes are
1970 in L<perltoot>.
1971
1972 =head2 How can I use a reference as a hash key?
1973
1974 You can't do this directly, but you could use the standard Tie::RefHash
1975 module distributed with Perl.
1976
1977 =head1 Data: Misc
1978
1979 =head2 How do I handle binary data correctly?
1980
1981 Perl is binary clean, so this shouldn't be a problem.  For example,
1982 this works fine (assuming the files are found):
1983
1984     if (`cat /vmunix` =~ /gzip/) {
1985         print "Your kernel is GNU-zip enabled!\n";
1986     }
1987
1988 On less elegant (read: Byzantine) systems, however, you have
1989 to play tedious games with "text" versus "binary" files.  See
1990 L<perlfunc/"binmode"> or L<perlopentut>.
1991
1992 If you're concerned about 8-bit ASCII data, then see L<perllocale>.
1993
1994 If you want to deal with multibyte characters, however, there are
1995 some gotchas.  See the section on Regular Expressions.
1996
1997 =head2 How do I determine whether a scalar is a number/whole/integer/float?
1998
1999 Assuming that you don't care about IEEE notations like "NaN" or
2000 "Infinity", you probably just want to use a regular expression.
2001
2002    if (/\D/)            { print "has nondigits\n" }
2003    if (/^\d+$/)         { print "is a whole number\n" }
2004    if (/^-?\d+$/)       { print "is an integer\n" }
2005    if (/^[+-]?\d+$/)    { print "is a +/- integer\n" }
2006    if (/^-?\d+\.?\d*$/) { print "is a real number\n" }
2007    if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number\n" }
2008    if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
2009                         { print "a C float\n" }
2010
2011 There are also some commonly used modules for the task.
2012 L<Scalar::Util> (distributed with 5.8) provides access to perl's
2013 internal function C<looks_like_number> for determining
2014 whether a variable looks like a number.  L<Data::Types>
2015 exports functions that validate data types using both the
2016 above and other regular expressions. Thirdly, there is
2017 C<Regexp::Common> which has regular expressions to match
2018 various types of numbers. Those three modules are available
2019 from the CPAN.
2020
2021 If you're on a POSIX system, Perl supports the C<POSIX::strtod>
2022 function.  Its semantics are somewhat cumbersome, so here's a C<getnum>
2023 wrapper function for more convenient access.  This function takes
2024 a string and returns the number it found, or C<undef> for input that
2025 isn't a C float.  The C<is_numeric> function is a front end to C<getnum>
2026 if you just want to say, ``Is this a float?''
2027
2028     sub getnum {
2029         use POSIX qw(strtod);
2030         my $str = shift;
2031         $str =~ s/^\s+//;
2032         $str =~ s/\s+$//;
2033         $! = 0;
2034         my($num, $unparsed) = strtod($str);
2035         if (($str eq '') || ($unparsed != 0) || $!) {
2036             return undef;
2037         } else {
2038             return $num;
2039         }
2040     }
2041
2042     sub is_numeric { defined getnum($_[0]) }
2043
2044 Or you could check out the L<String::Scanf> module on the CPAN
2045 instead. The POSIX module (part of the standard Perl distribution) provides
2046 the C<strtod> and C<strtol> for converting strings to double and longs,
2047 respectively.
2048
2049 =head2 How do I keep persistent data across program calls?
2050
2051 For some specific applications, you can use one of the DBM modules.
2052 See L<AnyDBM_File>.  More generically, you should consult the FreezeThaw
2053 or Storable modules from CPAN.  Starting from Perl 5.8 Storable is part
2054 of the standard distribution.  Here's one example using Storable's C<store>
2055 and C<retrieve> functions:
2056
2057     use Storable;
2058     store(\%hash, "filename");
2059
2060     # later on...
2061     $href = retrieve("filename");        # by ref
2062     %hash = %{ retrieve("filename") };   # direct to hash
2063
2064 =head2 How do I print out or copy a recursive data structure?
2065
2066 The Data::Dumper module on CPAN (or the 5.005 release of Perl) is great
2067 for printing out data structures.  The Storable module on CPAN (or the
2068 5.8 release of Perl), provides a function called C<dclone> that recursively
2069 copies its argument.
2070
2071     use Storable qw(dclone);
2072     $r2 = dclone($r1);
2073
2074 Where $r1 can be a reference to any kind of data structure you'd like.
2075 It will be deeply copied.  Because C<dclone> takes and returns references,
2076 you'd have to add extra punctuation if you had a hash of arrays that
2077 you wanted to copy.
2078
2079     %newhash = %{ dclone(\%oldhash) };
2080
2081 =head2 How do I define methods for every class/object?
2082
2083 Use the UNIVERSAL class (see L<UNIVERSAL>).
2084
2085 =head2 How do I verify a credit card checksum?
2086
2087 Get the Business::CreditCard module from CPAN.
2088
2089 =head2 How do I pack arrays of doubles or floats for XS code?
2090
2091 The kgbpack.c code in the PGPLOT module on CPAN does just this.
2092 If you're doing a lot of float or double processing, consider using
2093 the PDL module from CPAN instead--it makes number-crunching easy.
2094
2095 =head1 AUTHOR AND COPYRIGHT
2096
2097 Copyright (c) 1997-2002 Tom Christiansen and Nathan Torkington.
2098 All rights reserved.
2099
2100 This documentation is free; you can redistribute it and/or modify it
2101 under the same terms as Perl itself.
2102
2103 Irrespective of its distribution, all code examples in this file
2104 are hereby placed into the public domain.  You are permitted and
2105 encouraged to use this code in your own programs for fun
2106 or for profit as you see fit.  A simple comment in the code giving
2107 credit would be courteous but is not required.