This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
re.pm: correct typo
[perl5.git] / ext / re / re.pm
1 package re;
2
3 # pragma for controlling the regexp engine
4 use strict;
5 use warnings;
6
7 our $VERSION     = "0.15";
8 our @ISA         = qw(Exporter);
9 our @EXPORT_OK   = ('regmust',
10                     qw(is_regexp regexp_pattern
11                        regname regnames regnames_count));
12 our %EXPORT_OK = map { $_ => 1 } @EXPORT_OK;
13
14 my %bitmask = (
15     taint   => 0x00100000, # HINT_RE_TAINT
16     eval    => 0x00200000, # HINT_RE_EVAL
17 );
18
19 my $flags_hint = 0x02000000; # HINT_RE_FLAGS
20 my $PMMOD_SHIFT = 0;
21 my %reflags = (
22     m => 1 << ($PMMOD_SHIFT + 0),
23     s => 1 << ($PMMOD_SHIFT + 1),
24     i => 1 << ($PMMOD_SHIFT + 2),
25     x => 1 << ($PMMOD_SHIFT + 3),
26     p => 1 << ($PMMOD_SHIFT + 4),
27 # special cases:
28     l => 1 << ($PMMOD_SHIFT + 5),
29     u => 1 << ($PMMOD_SHIFT + 6),
30     d => 0,
31 );
32
33 sub setcolor {
34  eval {                         # Ignore errors
35   require Term::Cap;
36
37   my $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
38   my $props = $ENV{PERL_RE_TC} || 'md,me,so,se,us,ue';
39   my @props = split /,/, $props;
40   my $colors = join "\t", map {$terminal->Tputs($_,1)} @props;
41
42   $colors =~ s/\0//g;
43   $ENV{PERL_RE_COLORS} = $colors;
44  };
45  if ($@) {
46     $ENV{PERL_RE_COLORS} ||= qq'\t\t> <\t> <\t\t';
47  }
48
49 }
50
51 my %flags = (
52     COMPILE         => 0x0000FF,
53     PARSE           => 0x000001,
54     OPTIMISE        => 0x000002,
55     TRIEC           => 0x000004,
56     DUMP            => 0x000008,
57     FLAGS           => 0x000010,
58
59     EXECUTE         => 0x00FF00,
60     INTUIT          => 0x000100,
61     MATCH           => 0x000200,
62     TRIEE           => 0x000400,
63
64     EXTRA           => 0xFF0000,
65     TRIEM           => 0x010000,
66     OFFSETS         => 0x020000,
67     OFFSETSDBG      => 0x040000,
68     STATE           => 0x080000,
69     OPTIMISEM       => 0x100000,
70     STACK           => 0x280000,
71     BUFFERS         => 0x400000,
72     GPOS            => 0x800000,
73 );
74 $flags{ALL} = -1 & ~($flags{OFFSETS}|$flags{OFFSETSDBG}|$flags{BUFFERS});
75 $flags{All} = $flags{all} = $flags{DUMP} | $flags{EXECUTE};
76 $flags{Extra} = $flags{EXECUTE} | $flags{COMPILE} | $flags{GPOS};
77 $flags{More} = $flags{MORE} = $flags{All} | $flags{TRIEC} | $flags{TRIEM} | $flags{STATE};
78 $flags{State} = $flags{DUMP} | $flags{EXECUTE} | $flags{STATE};
79 $flags{TRIE} = $flags{DUMP} | $flags{EXECUTE} | $flags{TRIEC};
80
81 if (defined &DynaLoader::boot_DynaLoader) {
82     require XSLoader;
83     XSLoader::load();
84 }
85 # else we're miniperl
86 # We need to work for miniperl, because the XS toolchain uses Text::Wrap, which
87 # uses re 'taint'.
88
89 sub _load_unload {
90     my ($on)= @_;
91     if ($on) {
92         # We call install() every time, as if we didn't, we wouldn't
93         # "see" any changes to the color environment var since
94         # the last time it was called.
95
96         # install() returns an integer, which if casted properly
97         # in C resolves to a structure containing the regexp
98         # hooks. Setting it to a random integer will guarantee
99         # segfaults.
100         $^H{regcomp} = install();
101     } else {
102         delete $^H{regcomp};
103     }
104 }
105
106 sub bits {
107     my $on = shift;
108     my $bits = 0;
109     unless (@_) {
110         require Carp;
111         Carp::carp("Useless use of \"re\" pragma"); 
112     }
113    ARG:
114     foreach my $idx (0..$#_){
115         my $s=$_[$idx];
116         if ($s eq 'Debug' or $s eq 'Debugcolor') {
117             setcolor() if $s =~/color/i;
118             ${^RE_DEBUG_FLAGS} = 0 unless defined ${^RE_DEBUG_FLAGS};
119             for my $idx ($idx+1..$#_) {
120                 if ($flags{$_[$idx]}) {
121                     if ($on) {
122                         ${^RE_DEBUG_FLAGS} |= $flags{$_[$idx]};
123                     } else {
124                         ${^RE_DEBUG_FLAGS} &= ~ $flags{$_[$idx]};
125                     }
126                 } else {
127                     require Carp;
128                     Carp::carp("Unknown \"re\" Debug flag '$_[$idx]', possible flags: ",
129                                join(", ",sort keys %flags ) );
130                 }
131             }
132             _load_unload($on ? 1 : ${^RE_DEBUG_FLAGS});
133             last;
134         } elsif ($s eq 'debug' or $s eq 'debugcolor') {
135             setcolor() if $s =~/color/i;
136             _load_unload($on);
137             last;
138         } elsif (exists $bitmask{$s}) {
139             $bits |= $bitmask{$s};
140         } elsif ($EXPORT_OK{$s}) {
141             require Exporter;
142             re->export_to_level(2, 're', $s);
143         } elsif ($s =~ s/^\///) {
144             my $reflags = $^H{reflags} || 0;
145             my $seen_dul;
146             for(split//, $s) {
147                 if (/[dul]/) {
148                     if ($on) {
149                         if ($seen_dul && $seen_dul ne $_) {
150                             require Carp;
151                             Carp::carp(
152                               qq 'The "$seen_dul" and "$_" flags '
153                              .qq 'are exclusive'
154                             );
155                         }
156                         $^H{reflags_dul} = $reflags{$_};
157                         $seen_dul = $_;
158                     }
159                     else {
160                         delete $^H{reflags_dul}
161                          if  defined $^H{reflags_dul}
162                           && $^H{reflags_dul} == $reflags{$_};
163                     }
164                 } elsif (exists $reflags{$_}) {
165                     $on
166                       ? $reflags |= $reflags{$_}
167                       : ($reflags &= ~$reflags{$_});
168                 } else {
169                     require Carp;
170                     Carp::carp(
171                      qq'Unknown regular expression flag "$_"'
172                     );
173                     next ARG;
174                 }
175             }
176             ($^H{reflags} = $reflags or defined $^H{reflags_dul})
177              ? $^H |= $flags_hint
178              : ($^H &= ~$flags_hint);
179         } else {
180             require Carp;
181             Carp::carp("Unknown \"re\" subpragma '$s' (known ones are: ",
182                        join(', ', map {qq('$_')} 'debug', 'debugcolor', sort keys %bitmask),
183                        ")");
184         }
185     }
186     $bits;
187 }
188
189 sub import {
190     shift;
191     $^H |= bits(1, @_);
192 }
193
194 sub unimport {
195     shift;
196     $^H &= ~ bits(0, @_);
197 }
198
199 1;
200
201 __END__
202
203 =head1 NAME
204
205 re - Perl pragma to alter regular expression behaviour
206
207 =head1 SYNOPSIS
208
209     use re 'taint';
210     ($x) = ($^X =~ /^(.*)$/s);     # $x is tainted here
211
212     $pat = '(?{ $foo = 1 })';
213     use re 'eval';
214     /foo${pat}bar/;                # won't fail (when not under -T switch)
215
216     {
217         no re 'taint';             # the default
218         ($x) = ($^X =~ /^(.*)$/s); # $x is not tainted here
219
220         no re 'eval';              # the default
221         /foo${pat}bar/;            # disallowed (with or without -T switch)
222     }
223
224     use re '/ix';
225     "FOO" =~ / foo /; # /ix implied
226     no re '/x';
227     "FOO" =~ /foo/; # just /i implied
228
229     use re 'debug';                # output debugging info during
230     /^(.*)$/s;                     #     compile and run time
231
232
233     use re 'debugcolor';           # same as 'debug', but with colored output
234     ...
235
236     use re qw(Debug All);          # Finer tuned debugging options.
237     use re qw(Debug More);
238     no re qw(Debug ALL);           # Turn of all re debugging in this scope
239
240     use re qw(is_regexp regexp_pattern); # import utility functions
241     my ($pat,$mods)=regexp_pattern(qr/foo/i);
242     if (is_regexp($obj)) { 
243         print "Got regexp: ",
244             scalar regexp_pattern($obj); # just as perl would stringify it
245     }                                    # but no hassle with blessed re's.
246
247 (We use $^X in these examples because it's tainted by default.)
248
249 =head1 DESCRIPTION
250
251 =head2 'taint' mode
252
253 When C<use re 'taint'> is in effect, and a tainted string is the target
254 of a regexp, the regexp memories (or values returned by the m// operator
255 in list context) are tainted.  This feature is useful when regexp operations
256 on tainted data aren't meant to extract safe substrings, but to perform
257 other transformations.
258
259 =head2 'eval' mode
260
261 When C<use re 'eval'> is in effect, a regexp is allowed to contain
262 C<(?{ ... })> zero-width assertions and C<(??{ ... })> postponed
263 subexpressions, even if the regular expression contains
264 variable interpolation.  That is normally disallowed, since it is a
265 potential security risk.  Note that this pragma is ignored when the regular
266 expression is obtained from tainted data, i.e.  evaluation is always
267 disallowed with tainted regular expressions.  See L<perlre/(?{ code })> 
268 and L<perlre/(??{ code })>.
269
270 For the purpose of this pragma, interpolation of precompiled regular
271 expressions (i.e., the result of C<qr//>) is I<not> considered variable
272 interpolation.  Thus:
273
274     /foo${pat}bar/
275
276 I<is> allowed if $pat is a precompiled regular expression, even
277 if $pat contains C<(?{ ... })> assertions or C<(??{ ... })> subexpressions.
278
279 =head2 '/flags' mode
280
281 When C<use re '/flags'> is specified, the given flags are automatically
282 added to every regular expression till the end of the lexical scope.
283
284 C<no re '/flags'> will turn off the effect of C<use re '/flags'> for the
285 given flags.
286
287 For example, if you want all your regular expressions to have /msx on by
288 default, simply put
289
290     use re '/msx';
291
292 at the top of your code.
293
294 The /dul flags cancel each other out. So, in this example,
295
296     use re "/u";
297     "ss" =~ /\xdf/;
298     use re "/d";
299     "ss" =~ /\xdf/;
300
301 the second C<use re> does an implicit C<no re '/u'>.
302
303 Turning on the /l and /u flags with C<use re> takes precedence over the
304 C<locale> pragma and the 'unicode_strings' C<feature>, for regular
305 expressions. Turning off one of these flags when it is active reverts to
306 the behaviour specified by whatever other pragmata are in scope. For
307 example:
308
309     use feature "unicode_strings";
310     no re "/u"; # does nothing
311     use re "/l";
312     no re "/l"; # reverts to unicode_strings behaviour
313
314 =head2 'debug' mode
315
316 When C<use re 'debug'> is in effect, perl emits debugging messages when
317 compiling and using regular expressions.  The output is the same as that
318 obtained by running a C<-DDEBUGGING>-enabled perl interpreter with the
319 B<-Dr> switch. It may be quite voluminous depending on the complexity
320 of the match.  Using C<debugcolor> instead of C<debug> enables a
321 form of output that can be used to get a colorful display on terminals
322 that understand termcap color sequences.  Set C<$ENV{PERL_RE_TC}> to a
323 comma-separated list of C<termcap> properties to use for highlighting
324 strings on/off, pre-point part on/off.
325 See L<perldebug/"Debugging regular expressions"> for additional info.
326
327 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
328 lexically scoped, as the other directives are.  However they have both 
329 compile-time and run-time effects.
330
331 See L<perlmodlib/Pragmatic Modules>.
332
333 =head2 'Debug' mode
334
335 Similarly C<use re 'Debug'> produces debugging output, the difference
336 being that it allows the fine tuning of what debugging output will be
337 emitted. Options are divided into three groups, those related to
338 compilation, those related to execution and those related to special
339 purposes. The options are as follows:
340
341 =over 4
342
343 =item Compile related options
344
345 =over 4
346
347 =item COMPILE
348
349 Turns on all compile related debug options.
350
351 =item PARSE
352
353 Turns on debug output related to the process of parsing the pattern.
354
355 =item OPTIMISE
356
357 Enables output related to the optimisation phase of compilation.
358
359 =item TRIEC
360
361 Detailed info about trie compilation.
362
363 =item DUMP
364
365 Dump the final program out after it is compiled and optimised.
366
367 =back
368
369 =item Execute related options
370
371 =over 4
372
373 =item EXECUTE
374
375 Turns on all execute related debug options.
376
377 =item MATCH
378
379 Turns on debugging of the main matching loop.
380
381 =item TRIEE
382
383 Extra debugging of how tries execute.
384
385 =item INTUIT
386
387 Enable debugging of start point optimisations.
388
389 =back
390
391 =item Extra debugging options
392
393 =over 4
394
395 =item EXTRA
396
397 Turns on all "extra" debugging options.
398
399 =item BUFFERS
400
401 Enable debugging the capture group storage during match. Warning,
402 this can potentially produce extremely large output.
403
404 =item TRIEM
405
406 Enable enhanced TRIE debugging. Enhances both TRIEE
407 and TRIEC.
408
409 =item STATE
410
411 Enable debugging of states in the engine.
412
413 =item STACK
414
415 Enable debugging of the recursion stack in the engine. Enabling
416 or disabling this option automatically does the same for debugging
417 states as well. This output from this can be quite large.
418
419 =item OPTIMISEM
420
421 Enable enhanced optimisation debugging and start point optimisations.
422 Probably not useful except when debugging the regexp engine itself.
423
424 =item OFFSETS
425
426 Dump offset information. This can be used to see how regops correlate
427 to the pattern. Output format is
428
429    NODENUM:POSITION[LENGTH]
430
431 Where 1 is the position of the first char in the string. Note that position
432 can be 0, or larger than the actual length of the pattern, likewise length
433 can be zero.
434
435 =item OFFSETSDBG
436
437 Enable debugging of offsets information. This emits copious
438 amounts of trace information and doesn't mesh well with other
439 debug options.
440
441 Almost definitely only useful to people hacking
442 on the offsets part of the debug engine.
443
444 =back
445
446 =item Other useful flags
447
448 These are useful shortcuts to save on the typing.
449
450 =over 4
451
452 =item ALL
453
454 Enable all options at once except OFFSETS, OFFSETSDBG and BUFFERS
455
456 =item All
457
458 Enable DUMP and all execute options. Equivalent to:
459
460   use re 'debug';
461
462 =item MORE
463
464 =item More
465
466 Enable TRIEM and all execute compile and execute options.
467
468 =back
469
470 =back
471
472 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
473 lexically scoped, as the other directives are.  However they have both
474 compile-time and run-time effects.
475
476 =head2 Exportable Functions
477
478 As of perl 5.9.5 're' debug contains a number of utility functions that
479 may be optionally exported into the caller's namespace. They are listed
480 below.
481
482 =over 4
483
484 =item is_regexp($ref)
485
486 Returns true if the argument is a compiled regular expression as returned
487 by C<qr//>, false if it is not.
488
489 This function will not be confused by overloading or blessing. In
490 internals terms, this extracts the regexp pointer out of the
491 PERL_MAGIC_qr structure so it cannot be fooled.
492
493 =item regexp_pattern($ref)
494
495 If the argument is a compiled regular expression as returned by C<qr//>,
496 then this function returns the pattern.
497
498 In list context it returns a two element list, the first element
499 containing the pattern and the second containing the modifiers used when
500 the pattern was compiled.
501
502   my ($pat, $mods) = regexp_pattern($ref);
503
504 In scalar context it returns the same as perl would when stringifying a raw
505 C<qr//> with the same pattern inside.  If the argument is not a compiled
506 reference then this routine returns false but defined in scalar context,
507 and the empty list in list context. Thus the following
508
509     if (regexp_pattern($ref) eq '(?^i:foo)')
510
511 will be warning free regardless of what $ref actually is.
512
513 Like C<is_regexp> this function will not be confused by overloading
514 or blessing of the object.
515
516 =item regmust($ref)
517
518 If the argument is a compiled regular expression as returned by C<qr//>,
519 then this function returns what the optimiser considers to be the longest
520 anchored fixed string and longest floating fixed string in the pattern.
521
522 A I<fixed string> is defined as being a substring that must appear for the
523 pattern to match. An I<anchored fixed string> is a fixed string that must
524 appear at a particular offset from the beginning of the match. A I<floating
525 fixed string> is defined as a fixed string that can appear at any point in
526 a range of positions relative to the start of the match. For example,
527
528     my $qr = qr/here .* there/x;
529     my ($anchored, $floating) = regmust($qr);
530     print "anchored:'$anchored'\nfloating:'$floating'\n";
531
532 results in
533
534     anchored:'here'
535     floating:'there'
536
537 Because the C<here> is before the C<.*> in the pattern, its position
538 can be determined exactly. That's not true, however, for the C<there>;
539 it could appear at any point after where the anchored string appeared.
540 Perl uses both for its optimisations, prefering the longer, or, if they are
541 equal, the floating.
542
543 B<NOTE:> This may not necessarily be the definitive longest anchored and
544 floating string. This will be what the optimiser of the Perl that you
545 are using thinks is the longest. If you believe that the result is wrong
546 please report it via the L<perlbug> utility.
547
548 =item regname($name,$all)
549
550 Returns the contents of a named buffer of the last successful match. If
551 $all is true, then returns an array ref containing one entry per buffer,
552 otherwise returns the first defined buffer.
553
554 =item regnames($all)
555
556 Returns a list of all of the named buffers defined in the last successful
557 match. If $all is true, then it returns all names defined, if not it returns
558 only names which were involved in the match.
559
560 =item regnames_count()
561
562 Returns the number of distinct names defined in the pattern used
563 for the last successful match.
564
565 B<Note:> this result is always the actual number of distinct
566 named buffers defined, it may not actually match that which is
567 returned by C<regnames()> and related routines when those routines
568 have not been called with the $all parameter set.
569
570 =back
571
572 =head1 SEE ALSO
573
574 L<perlmodlib/Pragmatic Modules>.
575
576 =cut