lib/ExtUtils/Mksymlists.pm

   1 package ExtUtils::Mksymlists;
   2 use strict qw[ subs refs ];
   3 # no strict 'vars';  # until filehandles are exempted
   4
   5 use Carp;
   6 use Exporter;
   7 use vars qw( @ISA @EXPORT $VERSION );
   8 @ISA = 'Exporter';
   9 @EXPORT = '&Mksymlists';
  10 $VERSION = substr q$Revision: 1.13 $, 10;
  11
  12 sub Mksymlists {
  13     my(%spec) = @_;
  14     my($osname) = $^O;
  15
  16     croak("Insufficient information specified to Mksymlists")
  17         unless ( $spec{NAME} or
  18                  ($spec{FILE} and ($spec{DL_FUNCS} or $spec{FUNCLIST})) );
  19
  20     $spec{DL_VARS} = [] unless $spec{DL_VARS};
  21     ($spec{FILE} = $spec{NAME}) =~ s/.*::// unless $spec{FILE};
  22     $spec{DL_FUNCS} = { $spec{NAME} => [] }
  23         unless ( ($spec{DL_FUNCS} and keys %{$spec{DL_FUNCS}}) or
  24                  $spec{FUNCLIST});
  25     $spec{FUNCLIST} = [] unless $spec{FUNCLIST};
  26     if (defined $spec{DL_FUNCS}) {
  27         my($package);
  28         foreach $package (keys %{$spec{DL_FUNCS}}) {
  29             my($packprefix,$sym,$bootseen);
  30             ($packprefix = $package) =~ s/\W/_/g;
  31             foreach $sym (@{$spec{DL_FUNCS}->{$package}}) {
  32                 if ($sym =~ /^boot_/) {
  33                     push(@{$spec{FUNCLIST}},$sym);
  34                     $bootseen++;
  35                 }
  36                 else { push(@{$spec{FUNCLIST}},"XS_${packprefix}_$sym"); }
  37             }
  38             push(@{$spec{FUNCLIST}},"boot_$packprefix") unless $bootseen;
  39         }
  40     }
  41
  42 #    We'll need this if we ever add any OS which uses mod2fname
  43 #    not as pseudo-builtin.
  44 #    require DynaLoader;
  45     if (defined &DynaLoader::mod2fname and not $spec{DLBASE}) {
  46         $spec{DLBASE} = DynaLoader::mod2fname([ split(/::/,$spec{NAME}) ]);
  47     }
  48
  49     if    ($osname eq 'aix') { _write_aix(\%spec); }
  50     elsif ($osname eq 'VMS') { _write_vms(\%spec) }
  51     elsif ($osname eq 'os2') { _write_os2(\%spec) }
  52     else { croak("Don't know how to create linker option file for $osname\n"); }
  53 }
  54
  55
  56 sub _write_aix {
  57     my($data) = @_;
  58
  59     rename "$data->{FILE}.exp", "$data->{FILE}.exp_old";
  60
  61     open(EXP,">$data->{FILE}.exp")
  62         or croak("Can't create $data->{FILE}.exp: $!\n");
  63     print EXP join("\n",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  64     print EXP join("\n",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  65     close EXP;
  66 }
  67
  68
  69 sub _write_os2 {
  70     my($data) = @_;
  71
  72     if (not $data->{DLBASE}) {
  73         ($data->{DLBASE} = $data->{NAME}) =~ s/.*:://;
  74         $data->{DLBASE} = substr($data->{DLBASE},0,7) . '_';
  75     }
  76     rename "$data->{FILE}.def", "$data->{FILE}_def.old";
  77
  78     open(DEF,">$data->{FILE}.def")
  79         or croak("Can't create $data->{FILE}.def: $!\n");
  80     print DEF "LIBRARY '$data->{DLBASE}' INITINSTANCE TERMINSTANCE\n";
  81     print DEF "CODE LOADONCALL\n";
  82     print DEF "DATA LOADONCALL NONSHARED MULTIPLE\n";
  83     print DEF "EXPORTS\n  ";
  84     print DEF join("\n  ",@{$data->{DL_VARS}}, "\n") if @{$data->{DL_VARS}};
  85     print DEF join("\n  ",@{$data->{FUNCLIST}}, "\n") if @{$data->{FUNCLIST}};
  86     if (%{$data->{IMPORTS}}) {
  87         print DEF "IMPORTS\n";
  88 my ($name, $exp);
  89 while (($name, $exp)= each %{$data->{IMPORTS}}) {
  90   print DEF "  $name=$exp\n";
  91 }
  92     }
  93     close DEF;
  94 }
  95
  96
  97 sub _write_vms {
  98     my($data) = @_;
  99
 100     require Config; # a reminder for once we do $^O
 101     require ExtUtils::XSSymSet;
 102
 103     my($isvax) = $Config::Config{'arch'} =~ /VAX/i;
 104     my($set) = new ExtUtils::XSSymSet;
 105     my($sym);
 106
 107     rename "$data->{FILE}.opt", "$data->{FILE}.opt_old";
 108
 109     open(OPT,">$data->{FILE}.opt")
 110         or croak("Can't create $data->{FILE}.opt: $!\n");
 111
 112     # Options file declaring universal symbols
 113     # Used when linking shareable image for dynamic extension,
 114     # or when linking PerlShr into which we've added this package
 115     # as a static extension
 116     # We don't do anything to preserve order, so we won't relax
 117     # the GSMATCH criteria for a dynamic extension
 118
 119     foreach $sym (@{$data->{FUNCLIST}}) {
 120         my $safe = $set->addsym($sym);
 121         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 122         else        { print OPT "SYMBOL_VECTOR=($safe=PROCEDURE)\n"; }
 123     }
 124     foreach $sym (@{$data->{DL_VARS}}) {
 125         my $safe = $set->addsym($sym);
 126         print OPT "PSECT_ATTR=${sym},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 127         if ($isvax) { print OPT "UNIVERSAL=$safe\n" }
 128         else        { print OPT "SYMBOL_VECTOR=($safe=DATA)\n"; }
 129     }
 130     close OPT;
 131
 132     # Options file specifying RTLs to which this extension must be linked.
 133     # Eventually, the list of libraries will be supplied by a working
 134     # extliblist routine.
 135     open OPT,'>rtls.opt';
 136     print OPT "PerlShr/Share\n";
 137     foreach $rtl (split(/\s+/,$Config::Config{'libs'})) { print OPT "$rtl\n"; }
 138     close OPT;
 139 }
 140
 141 1;
 142
 143 __END__
 144
 145 =head1 NAME
 146
 147 ExtUtils::Mksymlists - write linker options files for dynamic extension
 148
 149 =head1 SYNOPSIS
 150
 151     use ExtUtils::Mksymlists;
 152     Mksymlists({ NAME     => $name ,
 153                  DL_VARS  => [ $var1, $var2, $var3 ],
 154                  DL_FUNCS => { $pkg1 => [ $func1, $func2 ],
 155                                $pkg2 => [ $func3 ] });
 156
 157 =head1 DESCRIPTION
 158
 159 C<ExtUtils::Mksymlists> produces files used by the linker under some OSs
 160 during the creation of shared libraries for dynamic extensions.  It is
 161 normally called from a MakeMaker-generated Makefile when the extension
 162 is built.  The linker option file is generated by calling the function
 163 C<Mksymlists>, which is exported by default from C<ExtUtils::Mksymlists>.
 164 It takes one argument, a list of key-value pairs, in which the following
 165 keys are recognized:
 166
 167 =over
 168
 169 =item NAME
 170
 171 This gives the name of the extension (I<e.g.> Tk::Canvas) for which
 172 the linker option file will be produced.
 173
 174 =item DL_FUNCS
 175
 176 This is identical to the DL_FUNCS attribute available via MakeMaker,
 177 from which it is usually taken.  Its value is a reference to an
 178 associative array, in which each key is the name of a package, and
 179 each value is an a reference to an array of function names which
 180 should be exported by the extension.  For instance, one might say
 181 C<DL_FUNCS =E<gt> { Homer::Iliad   =E<gt> [ qw(trojans greeks) ],
 182 Homer::Odyssey =E<gt> [ qw(travellers family suitors) ] }>.  The
 183 function names should be identical to those in the XSUB code;
 184 C<Mksymlists> will alter the names written to the linker option
 185 file to match the changes made by F<xsubpp>.  In addition, if
 186 none of the functions in a list begin with the string B<boot_>,
 187 C<Mksymlists> will add a bootstrap function for that package,
 188 just as xsubpp does.  (If a B<boot_E<lt>pkgE<gt>> function is
 189 present in the list, it is passed through unchanged.)  If
 190 DL_FUNCS is not specified, it defaults to the bootstrap
 191 function for the extension specified in NAME.
 192
 193 =item DL_VARS
 194
 195 This is identical to the DL_VARS attribute available via MakeMaker,
 196 and, like DL_FUNCS, it is usually specified via MakeMaker.  Its
 197 value is a reference to an array of variable names which should
 198 be exported by the extension.
 199
 200 =item FILE
 201
 202 This key can be used to specify the name of the linker option file
 203 (minus the OS-specific extension), if for some reason you do not
 204 want to use the default value, which is the last word of the NAME
 205 attribute (I<e.g.> for Tk::Canvas, FILE defaults to 'Canvas').
 206
 207 =item FUNCLIST
 208
 209 This provides an alternate means to specify function names to be
 210 exported from the extension.  Its value is a reference to an
 211 array of function names to be exported by the extension.  These
 212 names are passed through unaltered to the linker options file.
 213
 214 =item DLBASE
 215
 216 This item specifies the name by which the linker knows the
 217 extension, which may be different from the name of the
 218 extension itself (for instance, some linkers add an '_' to the
 219 name of the extension).  If it is not specified, it is derived
 220 from the NAME attribute.  It is presently used only by OS2.
 221
 222 =back
 223
 224 When calling C<Mksymlists>, one should always specify the NAME
 225 attribute.  In most cases, this is all that's necessary.  In
 226 the case of unusual extensions, however, the other attributes
 227 can be used to provide additional information to the linker.
 228
 229 =head1 AUTHOR
 230
 231 Charles Bailey I<E<lt>bailey@genetics.upenn.eduE<gt>>
 232
 233 =head1 REVISION
 234
 235 Last revised 14-Feb-1996, for Perl 5.002.