installperl

   1 #!./perl -w
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8
   9     # This needs to be at BEGIN time, before any use of Config
  10     require './install_lib.pl';
  11 }
  12
  13 use strict;
  14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
  15             %opts $packlist);
  16 my $versiononly;
  17
  18 BEGIN {
  19     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  20 }
  21
  22 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  23
  24 use File::Find;
  25 use File::Compare;
  26 use File::Copy ();
  27 use File::Path ();
  28 use ExtUtils::Packlist;
  29 use Cwd;
  30 # nogetopt_compat to disable treating +v as meaning -v
  31 use Getopt::Long qw(:config nogetopt_compat no_auto_abbrev noignorecase);
  32
  33 require './Porting/pod_lib.pl';
  34
  35 if ($Is_NetWare) {
  36     $Is_W32 = 0;
  37     $scr_ext = '.pl';
  38 }
  39
  40 # override the ones in the rest of the script
  41 sub mkpath {
  42     File::Path::mkpath(@_) unless $opts{notify};
  43 }
  44
  45 my $mainperldir = "/usr/bin";
  46 my $exe_ext = $Config{exe_ext};
  47
  48 # Allow "make install PERLNAME=something_besides_perl":
  49 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  50
  51 # This is the base used for versioned names, like "perl5.6.0".
  52 # It's separate because a common use of $PERLNAME is to install
  53 # perl as "perl5", if that's used as base for versioned files you
  54 # get "perl55.6.0".
  55 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  56                     ? $ENV{PERLNAME_VERBASE}
  57                     : $perl;
  58 my $dbg = '';
  59 my $ndbg = '';
  60 if ( $Is_VMS ) {
  61     if ( defined $Config{usevmsdebug} ) {
  62         if ( $Config{usevmsdebug} eq 'define' ) {
  63             $dbg = 'dbg';
  64             $ndbg = 'ndbg';
  65         }
  66     }
  67 }
  68
  69 # This little hack simplifies making the code after the comment "Fetch some
  70 # frequently-used items from %Config" warning free. With $opts{destdir} always
  71 # defined, it's also possible to make the s/\Q$opts{destdir}\E unconditional.
  72
  73 $opts{destdir} = '';
  74 {
  75     my $usage = 0;
  76     if (!GetOptions(\%opts, 'notify|n', 'strip|s', 'silent|S',
  77                     'skip-otherperls|o', 'force|f', 'verbose|V', 'archname|A',
  78                     'netware', 'nopods|p', 'destdir:s', 'help|h|?',
  79                     'versiononly|v' => \$versiononly, '<>' => sub {
  80                         if ($_[0] eq '+v') {
  81                             $versiononly = 0;
  82                         } else {
  83                             # Any other unknown argument is going to be an error
  84                             $usage = 1;
  85                         }
  86                     },
  87                    )) {
  88         $usage = 1;
  89     }
  90     $opts{verbose} ||= $opts{notify};
  91
  92     if ($usage || $opts{help}) {
  93         print <<"EOT";
  94 Usage $0: [switches]
  95   -n        Don't actually run any commands; just print them.
  96   -s        Run strip on installed binaries.
  97   -v        Only install perl as a binary with the version number in the name.
  98             (Override whatever config.sh says)
  99   +v        Install perl as "perl" and as a binary with the version number in
 100             the name.  (Override whatever config.sh says)
 101   -S        Silent mode.
 102   -f        Force installation (don't check if same version is there)
 103   -o        Skip checking for other copies of perl in your PATH.
 104   -V        Verbose mode.
 105   -A        Also install perl with the architecture's name in the perl binary's
 106             name.
 107   -p        Don't install the pod files. [This will break use diagnostics;]
 108   -netware  Install correctly on a Netware server.
 109   -destdir  Prefix installation directories by this string.
 110   -h        Display this help message.
 111 EOT
 112         exit $usage;
 113     }
 114 }
 115
 116 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 117 my (@scripts, @tolink);
 118 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 119 while (<SCRIPTS>) {
 120     next if /^#/;
 121     next if /a2p/; # a2p is binary, to be installed separately
 122     chomp;
 123     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 124         push @scripts, $1;
 125         push @tolink, [$1, $2];
 126     } else {
 127         push @scripts, $_;
 128     }
 129 }
 130 close SCRIPTS;
 131
 132 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 133
 134 # Specify here any .pm files that are actually architecture-dependent.
 135 # (Those included with XS extensions under ext/ are automatically
 136 # added later.)
 137 # Now that the default privlib has the full perl version number included,
 138 # we no longer have to play the trick of sticking version-specific .pm
 139 # files under the archlib directory.
 140 my %archpms = (
 141     Config => 1,
 142     lib => 1,
 143     Cwd => 1,
 144 );
 145
 146 if ($^O eq 'dos') {
 147     push(@scripts,'djgpp/fixpmain');
 148     $archpms{config} = $archpms{filehand} = 1;
 149 }
 150
 151 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 152     push(@scripts, map("$_.exe", @scripts));
 153 }
 154
 155 # Exclude nonxs extensions that are not architecture dependent
 156 my @nonxs = grep(!/^Errno$/, split(' ', $Config{'nonxs_ext'}));
 157
 158 my @ext_dirs = qw(cpan dist ext);
 159 foreach my $ext_dir (@ext_dirs) {
 160     find(sub {
 161         if (($File::Find::name =~ m{^$ext_dir\b(.*)/([^/]+)\.pm$}) &&
 162             ! grep { (my $dir = $_) =~ s/\//-/g;
 163                      $File::Find::name =~ /^$ext_dir\/$dir\// } @nonxs)
 164         {
 165             my($path, $modname) = ($1,$2);
 166
 167             # Change hyphenated name like Filter-Util-Call to nested
 168             # directory name Filter/Util/Call
 169             $path =~ s{-}{/}g;
 170
 171             # strip to optional "/lib", or remove trailing component
 172             $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
 173
 174             # strip any leading /
 175             $path =~ s{^/}{};
 176
 177             # reconstitute canonical module name
 178             $modname = "$path/$modname" if length $path;
 179
 180             # remember it
 181             $archpms{$modname} = 1;
 182         }
 183     }, $ext_dir);
 184 }
 185
 186 # print "[$_]\n" for sort keys %archpms;
 187
 188 my $ver = $Config{version};
 189 my $release = substr($],0,3);   # Not used currently.
 190 my $patchlevel = substr($],3,2);
 191 die "Patchlevel of perl ($patchlevel)",
 192     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 193         if $patchlevel != $Config{'PERL_VERSION'};
 194
 195 # Fetch some frequently-used items from %Config
 196 my $installbin = "$opts{destdir}$Config{installbin}";
 197 my $installscript = "$opts{destdir}$Config{installscript}";
 198 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
 199 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
 200 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
 201 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
 202 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
 203 my $man1ext = $Config{man1ext};
 204 my $libperl = $Config{libperl};
 205 # Shared library and dynamic loading suffixes.
 206 my $so = $Config{so};
 207 my $dlext = $Config{dlext};
 208 my $dlsrc = $Config{dlsrc};
 209 if ($^O eq 'os390') {
 210     my $pwd;
 211     chomp($pwd=`pwd`);
 212     my $archlibexp = $Config{archlibexp};
 213     my $usedl = $Config{usedl};
 214     if ($usedl eq 'define') {
 215         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 216     }
 217 }
 218
 219 if ($opts{netware}) {
 220     # This is required only if we are installing on a NetWare server
 221     $installscript = $Config{installnwscripts};
 222     $installprivlib = $Config{installnwlib};
 223     $installarchlib = $Config{installnwlib};
 224     $installsitelib = $Config{installnwlib};
 225 }
 226
 227 my $binexp = $Config{binexp};
 228
 229 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 230     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 231               \$installarchlib, \$installsitelib, \$installsitearch,
 232               \$installman1dir ) {
 233         $$_ = unixify($$_);  $$_ =~ s:/$::;
 234     }
 235 }
 236
 237 # Do some quick sanity checks.
 238
 239    $installbin          || die "No installbin directory in config.sh\n";
 240 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
 241 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
 242 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
 243         unless $installbin =~ m#^/afs/# || $opts{notify};
 244
 245 if (!$Is_NetWare) {
 246 if (!$Is_VMS) {
 247 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 248 }
 249 else {
 250 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 251     if ($dbg) {
 252         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 253     }
 254 }
 255
 256 -f 't/rantests'         || $Is_W32
 257                         || warn "WARNING: You've never run 'make test' or",
 258                                 " some tests failed! (Installing anyway.)\n";
 259 } #if (!$Is_NetWare)
 260
 261 # This will be used to store the packlist
 262 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 263
 264 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 265     my $perldll;
 266
 267     if ($Is_Cygwin) {
 268         $perldll = $libperl;
 269     } else {
 270         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
 271     }
 272
 273     if ($dlsrc ne "dl_none.xs") {
 274         -f $perldll || die "No perl DLL built\n";
 275     }
 276
 277     # Install the DLL
 278     safe_unlink("$installbin/$perldll");
 279     copy("$perldll", "$installbin/$perldll");
 280     chmod(0755, "$installbin/$perldll");
 281     $packlist->{"$Config{installbin}/$perldll"} = { type => 'file' };
 282 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 283
 284 # First we install the version-numbered executables.
 285
 286 if ($Is_VMS) {
 287     safe_unlink("$installbin/perl_setup.com");
 288     copy("perl_setup.com", "$installbin/perl_setup.com");
 289     chmod(0755, "$installbin/perl_setup.com");
 290     safe_unlink("$installbin/$dbg$perl$exe_ext");
 291     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 292     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 293     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 294     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 295     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 296     if ($ndbg) {
 297         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 298         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 299         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 300         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 301         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 302         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 303     }
 304 }
 305 elsif ($^O ne 'dos') {
 306     if (!$Is_NetWare) {
 307         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 308         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 309         strip("$installbin/$perl_verbase$ver$exe_ext");
 310         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 311     }
 312     else {
 313         # If installing onto a NetWare server
 314         if ($opts{netware}) {
 315             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 316             mkpath($Config{installnwsystem}, $opts{verbose}, 0777);
 317             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 318             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 319             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 320             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 321             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 322             mkpath($Config{installnwlcgi}, $opts{verbose}, 0777);
 323             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 324         }
 325     } #if (!$Is_NetWare)
 326 }
 327 else {
 328     safe_unlink("$installbin/$perl.exe");
 329     copy("perl.exe", "$installbin/$perl.exe");
 330 }
 331
 332 # Install library files.
 333
 334 my $do_installarchlib = !samepath($installarchlib, 'lib');
 335 my $do_installprivlib = !samepath($installprivlib, 'lib');
 336 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
 337 $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
 338
 339 mkpath($installprivlib, $opts{verbose}, 0777);
 340 mkpath($installarchlib, $opts{verbose}, 0777);
 341 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
 342 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
 343
 344 if (-d 'lib') {
 345     find({no_chdir => 1, wanted => \&installlib}, 'lib')
 346         if $do_installarchlib || $do_installprivlib;
 347 }
 348 else {
 349     warn "Can't install lib files - 'lib/' does not exist";
 350 }
 351
 352 # Install header files and libraries.
 353 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
 354 my @corefiles;
 355 if ($Is_VMS) {  # We did core file selection during build
 356     my $coredir = "lib/$Config{archname}/$ver/CORE";
 357     $coredir =~ tr/./_/;
 358     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 359 }
 360 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
 361     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 362     my $coredll = "$installarchlib/CORE/$libperl";
 363     my $instcoredll = "$Config{installarchlib}/CORE/$libperl";
 364     safe_unlink($coredll);
 365     ( $Config{'d_link'} eq 'define' &&
 366       eval {
 367           CORE::link("$installbin/$libperl", $coredll);
 368           $packlist->{$instcoredll} = { from => "$Config{installbin}/$libperl",
 369                                     type => 'link' };
 370       }
 371     ) ||
 372     eval {
 373         symlink("$installbin/$libperl", $coredll);
 374         $packlist->{$instcoredll} = { from => "$Config{installbin}/$libperl",
 375                                   type => 'link' };
 376     } ||
 377     ( copy("$installbin/$libperl", $coredll) &&
 378       push(@corefiles, $instcoredll)
 379     )
 380 } else {
 381     # [als] hard-coded 'libperl' name... not good!
 382     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 383
 384     # AIX needs perl.exp installed as well.
 385     push(@corefiles,'perl.exp') if $^O eq 'aix';
 386 }
 387 foreach my $file (@corefiles) {
 388     # HP-UX (at least) needs to maintain execute permissions
 389     # on dynamically-loadable libraries. So we do it for all.
 390     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 391         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 392             strip("-S", "$installarchlib/CORE/$file") if $^O eq 'darwin';
 393             chmod(0555, "$installarchlib/CORE/$file");
 394         } else {
 395             chmod(0444, "$installarchlib/CORE/$file");
 396         }
 397     }
 398 }
 399
 400 # Install main perl executables
 401 # Make links to ordinary names if installbin directory isn't current directory.
 402
 403 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 404     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 405     if ($^O eq 'vos') {
 406         # VOS doesn't support hard links, so use a symlink.
 407         symlink("$installbin/$perl_verbase$ver$exe_ext",
 408                 "$installbin/$perl$exe_ext");
 409     } else {
 410         link("$installbin/$perl_verbase$ver$exe_ext",
 411                 "$installbin/$perl$exe_ext");
 412     }
 413 }
 414
 415 # For development purposes it can be very useful to have multiple perls
 416 # build for different "architectures" (eg threading or not) simultaneously.
 417 if ($opts{archname} && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 418     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 419     safe_unlink("$installbin/$archperl");
 420     if ($^O eq 'vos') {
 421         # VOS doesn't support hard links, so use a symlink.
 422         symlink("$installbin/$perl_verbase$ver$exe_ext",
 423                 "$installbin/$archperl");
 424     } else {
 425         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 426     }
 427 }
 428
 429 # Offer to install perl in a "standard" location
 430
 431 my $mainperl_is_instperl = 0;
 432
 433 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 434     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 435         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 436     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 437     my($instperl)       = "$installbin/$perl$exe_ext";
 438     my($expinstperl)    = "$binexp/$perl$exe_ext";
 439
 440     # First make sure $usrbinperl is not already the same as the perl we
 441     # just installed.
 442     if (-x $usrbinperl) {
 443         # Try to be clever about mainperl being a symbolic link
 444         # to binexp/perl if binexp and installbin are different.
 445         $mainperl_is_instperl =
 446             samepath($usrbinperl, $instperl) ||
 447             samepath($usrbinperl, $expinstperl) ||
 448              (($binexp ne $installbin) &&
 449               (-l $usrbinperl) &&
 450               ((readlink $usrbinperl) eq $expinstperl));
 451     }
 452     if (! $mainperl_is_instperl) {
 453         unlink($usrbinperl);
 454         ( $Config{'d_link'} eq 'define' &&
 455           eval { CORE::link $instperl, $usrbinperl } )  ||
 456         eval { symlink $expinstperl, $usrbinperl }      ||
 457         copy($instperl, $usrbinperl);
 458
 459         $mainperl_is_instperl = 1;
 460     }
 461 }
 462
 463 # Make links to ordinary names if installbin directory isn't current directory.
 464 if (!$Is_NetWare && $dbg eq '') {
 465     if (! samepath($installbin, 'x2p')) {
 466         my $base = 'a2p';
 467         $base .= $ver if $versiononly;
 468         safe_unlink("$installbin/$base$exe_ext");
 469         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 470         strip("$installbin/$base$exe_ext");
 471         chmod(0755, "$installbin/$base$exe_ext");
 472     }
 473 }
 474
 475 # cppstdin is just a script, but it is architecture-dependent, so
 476 # it can't safely be shared.  Place it in $installbin.
 477 # Note that Configure doesn't build cppstin if it isn't needed, so
 478 # we skip this if cppstdin doesn't exist.
 479 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 480     safe_unlink("$installbin/cppstdin");
 481     copy("cppstdin", "$installbin/cppstdin");
 482     chmod(0755, "$installbin/cppstdin");
 483 }
 484
 485 sub script_alias {
 486     my ($installscript, $orig, $alias, $scr_ext) = @_;
 487
 488     safe_unlink("$installscript/$alias$scr_ext");
 489     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 490         copy("$installscript/$orig$scr_ext",
 491              "$installscript/$alias$scr_ext");
 492     } elsif ($^O eq 'vos') {
 493         symlink("$installscript/$orig$scr_ext",
 494                 "$installscript/$alias$scr_ext");
 495     } else {
 496         link("$installscript/$orig$scr_ext",
 497              "$installscript/$alias$scr_ext");
 498     }
 499 }
 500
 501 # Install scripts.
 502 mkpath($installscript, $opts{verbose}, 0777);
 503 if ($versiononly) {
 504     for (@scripts) {
 505         (my $base = $_) =~ s#.*/##;
 506         $base .= $ver;
 507         copy($_,    "$installscript/$base");
 508         chmod(0755, "$installscript/$base");
 509     }
 510
 511     for (@tolink) {
 512         my ($from, $to) = map { "$_$ver" } @$_;
 513         (my $frbase = $from) =~ s#.*/##;
 514         (my $tobase = $to) =~ s#.*/##;
 515         script_alias($installscript, $frbase, $tobase, $scr_ext);
 516     }
 517 } else {
 518     for (@scripts) {
 519         (my $base = $_) =~ s#.*/##;
 520         copy($_, "$installscript/$base");
 521         chmod(0755, "$installscript/$base");
 522     }
 523
 524     for (@tolink) {
 525         my ($from, $to) = @$_;
 526         (my $frbase = $from) =~ s#.*/##;
 527         (my $tobase = $to) =~ s#.*/##;
 528         script_alias($installscript, $frbase, $tobase, $scr_ext);
 529     }
 530 }
 531
 532 # Install pod pages.  Where? I guess in $installprivlib/pod
 533 # ($installprivlib/pods for cygwin).
 534 if (!$opts{nopods} && (!$versiononly || ($installprivlib =~ m/\Q$vershort/))) {
 535     my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
 536     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
 537
 538     for (map {$_->[1]} @{get_pod_metadata()->{master}}) {
 539         # $_ is a name like  pod/perl.pod
 540         (my $base = $_) =~ s#.*/##;
 541         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 542         chmod(0644, "${installprivlib}/$pod/${base}");
 543     }
 544
 545 }
 546
 547 # Check to make sure there aren't other perls around in installer's
 548 # path.  This is probably UNIX-specific.  Check all absolute directories
 549 # in the path except for where public executables are supposed to live.
 550 # Also skip $mainperl if the user opted to have it be a link to the
 551 # installed perl.
 552
 553 if (!$versiononly && !$opts{'skip-otherperls'}) {
 554     my ($path, @path);
 555     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 556     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 557     @path = split(/$dirsep/, $path);
 558     if ($Is_VMS) {
 559         my $i = 0;
 560         while (exists $ENV{'DCL$PATH' . $i}) {
 561             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 562             push(@path,$dir);
 563         }
 564     }
 565     my @otherperls;
 566     my %otherperls;
 567     for (@path) {
 568         next unless m,^/,;
 569         # Use &samepath here because some systems have other dirs linked
 570         # to $mainperldir (like SunOS)
 571         next unless -d;
 572         next if samepath($_, $binexp);
 573         next if samepath($_, cwd());
 574         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 575         my $otherperl = "$_/$perl$exe_ext";
 576         next if $otherperls{$otherperl}++;
 577         push(@otherperls, $otherperl)
 578             if (-x $otherperl && ! -d $otherperl);
 579     }
 580     if (@otherperls) {
 581         warn "\nWarning: $perl appears in your path in the following " .
 582             "locations beyond where\nwe just installed it:\n";
 583         for (@otherperls) {
 584             warn "    ", $_, "\n";
 585         }
 586         warn "\n";
 587     }
 588
 589 }
 590
 591 $packlist->write() unless $opts{notify};
 592 print "  Installation complete\n" if $opts{verbose};
 593
 594 exit 0;
 595
 596 ###############################################################################
 597
 598 # If these are needed elsewhere, move them into install_lib.pl rather than
 599 # copying them.
 600
 601 sub yn {
 602     my($prompt) = @_;
 603     my($answer);
 604     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 605     print STDERR $prompt;
 606     chop($answer = <STDIN>);
 607     $answer = $default if $answer =~ m/^\s*$/;
 608     ($answer =~ m/^[yY]/);
 609 }
 610
 611 sub safe_unlink {
 612     return if $opts{notify} or $Is_VMS;
 613     my @names = @_;
 614     foreach my $name (@names) {
 615         next unless -e $name;
 616         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 617         print "  unlink $name\n" if $opts{verbose};
 618         next if CORE::unlink($name);
 619         warn "Couldn't unlink $name: $!\n";
 620         if ($! =~ /busy/i) {
 621             print "  mv $name $name.old\n" if $opts{verbose};
 622             safe_rename($name, "$name.old")
 623                 or warn "Couldn't rename $name: $!\n";
 624         }
 625     }
 626 }
 627
 628 sub copy {
 629     my($from,$to) = @_;
 630
 631     my $xto = $to;
 632     $xto =~ s/^\Q$opts{destdir}\E//;
 633     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
 634         unless $opts{silent};
 635     print "  creating new version of $xto\n"
 636         if $Is_VMS and -e $to and !$opts{silent};
 637     unless ($opts{notify} or File::Copy::copy($from, $to)) {
 638         # Might have been that F::C::c can't overwrite the target
 639         warn "Couldn't copy $from to $to: $!\n"
 640             unless -f $to and (chmod(0666, $to), unlink $to)
 641                    and File::Copy::copy($from, $to);
 642     }
 643     $packlist->{$xto} = { type => 'file' };
 644 }
 645
 646 sub installlib {
 647     my $dir = $File::Find::dir;
 648     $dir =~ s!\Alib/?!!;
 649
 650     m!([^/]+)\z!;
 651     my $name = $1;
 652
 653     # This remains ugly, and in need of refactoring.
 654
 655     # $name always starts as the leafname
 656     # $dir is the directory *within* lib
 657     # $name later has $dir pre-pended, to give the relative path in lib/
 658     # which is used to create the path in the target directory.
 659
 660     # $_ was always the filename to use on disk. Adding no_chdir doesn't change
 661     # this, as $_ becomes a pathname, and so still works. However, it's not
 662     # obvious that $_ is needed later, and hence $_ must not be modified.
 663
 664     # Also, many of the regex exclusion tests below are now superfluous, as the
 665     # files in question are either no longer in blead, or now in ext/, dist/ or
 666     # cpan/ and not copied into lib/
 667
 668     # Ignore version control directories.
 669     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 670         $File::Find::prune = 1;
 671         return;
 672     }
 673
 674     # ignore patch backups, RCS files, emacs backup & temp files and the
 675     # .exists files, .PL files, and test files.
 676     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util\.pl$|^filter-util\.pl$|^uupacktool\.pl$|^\.gitignore$} ||
 677               $dir  =~ m{/t(?:/|$)};
 678     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 679     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
 680     # the corelist script from lib/Module/CoreList/bin and ptar* in
 681     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
 682     # and zipdetails in cpan/IO-Compress/bin
 683     # (they're installed later with other utils)
 684     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|ptardiff|ptargrep|config_data|zipdetails)\z/;
 685     # ignore the Makefiles
 686     return if $name =~ /^makefile$/i;
 687     # ignore the test extensions
 688     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
 689     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
 690     # ignore the build support code
 691     return if $name =~ /\bbuildcustomize\.pl$/;
 692     # ignore the demo files
 693     return if $dir =~ /\b(?:demos?|eg)\b/;
 694     # ignore unneeded unicore files
 695     if ( $dir =~ /^unicore/ ) {
 696       if ( $name =~ /\.txt\z/ ) {
 697         # We can ignore most, but not all .txt files
 698         return unless $name =~ /\A(?:Blocks|SpecialCasing|NamedSequences)\.txt\z/;
 699       }
 700       else {
 701         # TestProp only needed during testing
 702         return if $name =~ /\ATestProp.pl\z/;
 703         # we need version and *.pl files and can skip the rest
 704         return unless $name =~ /\A(?:version|\w+\.p[lm])\z/;
 705       }
 706     }
 707
 708     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
 709     # Changes.e2x and README.e2x are needed by enc2xs.
 710     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
 711     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
 712     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
 713     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
 714     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
 715     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
 716
 717     # if using a shared perl library then ignore:
 718     # - static library files [of statically linked extensions];
 719     # - import library files and export library files (only present on Win32
 720     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
 721     return if $Config{useshrplib} eq 'true' and
 722              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
 723
 724     $name = "$dir/$name" if $dir ne '';
 725
 726     # ignore pods that are stand alone documentation from dual life modules.
 727     return if /\.pod\z/ && is_duplicate_pod($_);
 728
 729     return if $name eq 'ExtUtils/XSSymSet.pm' and !$Is_VMS;
 730
 731     my $installlib = $installprivlib;
 732     if ($dir =~ /^auto\// ||
 733           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 734           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
 735           $name=~/^Config_(heavy|git)\.pl\z/
 736        ) {
 737         $installlib = $installarchlib;
 738         return unless $do_installarchlib;
 739     } else {
 740         return unless $do_installprivlib;
 741     }
 742
 743     if ($Is_NetWare && !$opts{netware} && /\.(?:nlp|nlm|bs)$/) {
 744         # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 745         # if copied will give problems when building new extensions.
 746         # Has to be copied if we are installing on a NetWare server and
 747         # hence the check !$opts{netware}
 748         return;
 749     }
 750
 751     if (-f $_) {
 752         my $xname = "$installlib/$name";
 753         $xname =~ s/^\Q$opts{destdir}\E//;
 754         $packlist->{$xname} = { type => 'file' };
 755         if ($opts{force} || compare($_, "$installlib/$name") || $opts{notify}) {
 756             unlink("$installlib/$name");
 757             mkpath("$installlib/$dir", $opts{verbose}, 0777);
 758             # HP-UX (at least) needs to maintain execute permissions
 759             # on dynamically-loaded libraries.
 760             if (copy_if_diff($_, "$installlib/$name")) {
 761                 strip("-S", "$installlib/$name")
 762                     if $^O eq 'darwin' and /\.(?:so|$dlext|a)$/;
 763                 chmod(/\.(so|$dlext)$/ ? 0555 : 0444, "$installlib/$name");
 764             }
 765         }
 766     }
 767 }
 768
 769 # Copy $from to $to, only if $from is different than $to.
 770 # Also preserve modification times for .a libraries.
 771 # On some systems, if you do
 772 #   ranlib libperl.a
 773 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 774 # and then try to link against the installed libperl.a, you might
 775 # get an error message to the effect that the symbol table is older
 776 # than the library.
 777 # Return true if copying occurred.
 778
 779 sub copy_if_diff {
 780     my($from,$to)=@_;
 781     return 1 if (($^O eq 'VMS') && (-d $from));
 782     my $xto = $to;
 783     $xto =~ s/^\Q$opts{destdir}\E//;
 784     my $perlpodbadsymlink;
 785     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 786         -l $from &&
 787         ! -e $from) {
 788         # Some Linux implementations have problems traversing over
 789         # multiple symlinks (when going over NFS?) and fail to read
 790         # the symlink target.  Combine this with the fact that some
 791         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 792         # and you end up with those pods not getting installed.
 793         $perlpodbadsymlink = 1;
 794     }
 795     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 796     $packlist->{$xto} = { type => 'file' };
 797     if ($opts{force} || compare($from, $to) || $opts{notify}) {
 798         safe_unlink($to);   # In case we don't have write permissions.
 799         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 800             $from = "README.$1";
 801         }
 802         copy($from, $to);
 803         # Restore timestamps if it's a .a library or for OS/2.
 804         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
 805             my ($atime, $mtime) = (stat $from)[8,9];
 806             utime $atime, $mtime, $to;
 807         }
 808         1;
 809     }
 810 }
 811
 812 sub strip
 813 {
 814     my(@args) = @_;
 815
 816     return unless $opts{strip};
 817
 818     my @opts;
 819     while (@args && $args[0] =~ /^(-\w+)$/) {
 820         push @opts, shift @args;
 821     }
 822
 823     foreach my $file (@args) {
 824         if (-f $file) {
 825             if ($opts{verbose}) {
 826                 print "  strip " . join(' ', @opts);
 827                 print " " if (@opts);
 828                 print "$file\n";
 829             }
 830             system("strip", @opts, $file);
 831         } else {
 832             print "# file '$file' skipped\n" if $opts{verbose};
 833         }
 834     }
 835 }
 836
 837 # Local variables:
 838 # cperl-indent-level: 4
 839 # indent-tabs-mode: nil
 840 # End:
 841 #
 842 # ex: set ts=8 sts=4 sw=4 et: