This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: Add code point ages to --annotate option
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # There was an attempt when this was first rewritten to make it 5.8
8 # compatible, but that has now been abandoned, and newer constructs are used
9 # as convenient.
10
11 my $start_time;
12 BEGIN { # Get the time the script started running; do it at compilation to
13         # get it as close as possible
14     $start_time= time;
15 }
16
17 require 5.010_001;
18 use strict;
19 use warnings;
20 use Carp;
21 use Config;
22 use File::Find;
23 use File::Path;
24 use File::Spec;
25 use Text::Tabs;
26 use re "/aa";
27 use feature 'state';
28
29 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
30 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
31
32 sub NON_ASCII_PLATFORM { ord("A") != 65 }
33
34 ##########################################################################
35 #
36 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
37 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
38 # a pod file and .t files, depending on option parameters.
39 #
40 # The structure of this file is:
41 #   First these introductory comments; then
42 #   code needed for everywhere, such as debugging stuff; then
43 #   code to handle input parameters; then
44 #   data structures likely to be of external interest (some of which depend on
45 #       the input parameters, so follows them; then
46 #   more data structures and subroutine and package (class) definitions; then
47 #   the small actual loop to process the input files and finish up; then
48 #   a __DATA__ section, for the .t tests
49 #
50 # This program works on all releases of Unicode so far.  The outputs have been
51 # scrutinized most intently for release 5.1.  The others have been checked for
52 # somewhat more than just sanity.  It can handle all non-provisional Unicode
53 # character properties in those releases.
54 #
55 # This program is mostly about Unicode character (or code point) properties.
56 # A property describes some attribute or quality of a code point, like if it
57 # is lowercase or not, its name, what version of Unicode it was first defined
58 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
59 # possibilities by making all properties into mappings from each code point
60 # into some corresponding value.  In the case of it being lowercase or not,
61 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
62 # property maps each Unicode code point to a single value, called a "property
63 # value".  (Some more recently defined properties, map a code point to a set
64 # of values.)
65 #
66 # When using a property in a regular expression, what is desired isn't the
67 # mapping of the code point to its property's value, but the reverse (or the
68 # mathematical "inverse relation"): starting with the property value, "Does a
69 # code point map to it?"  These are written in a "compound" form:
70 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
71 # files containing the lists of code points that map to each such regular
72 # expression property value, one file per list
73 #
74 # There is also a single form shortcut that Perl adds for many of the commonly
75 # used properties.  This happens for all binary properties, plus script,
76 # general_category, and block properties.
77 #
78 # Thus the outputs of this program are files.  There are map files, mostly in
79 # the 'To' directory; and there are list files for use in regular expression
80 # matching, all in subdirectories of the 'lib' directory, with each
81 # subdirectory being named for the property that the lists in it are for.
82 # Bookkeeping, test, and documentation files are also generated.
83
84 my $matches_directory = 'lib';   # Where match (\p{}) files go.
85 my $map_directory = 'To';        # Where map files go.
86
87 # DATA STRUCTURES
88 #
89 # The major data structures of this program are Property, of course, but also
90 # Table.  There are two kinds of tables, very similar to each other.
91 # "Match_Table" is the data structure giving the list of code points that have
92 # a particular property value, mentioned above.  There is also a "Map_Table"
93 # data structure which gives the property's mapping from code point to value.
94 # There are two structures because the match tables need to be combined in
95 # various ways, such as constructing unions, intersections, complements, etc.,
96 # and the map ones don't.  And there would be problems, perhaps subtle, if
97 # a map table were inadvertently operated on in some of those ways.
98 # The use of separate classes with operations defined on one but not the other
99 # prevents accidentally confusing the two.
100 #
101 # At the heart of each table's data structure is a "Range_List", which is just
102 # an ordered list of "Ranges", plus ancillary information, and methods to
103 # operate on them.  A Range is a compact way to store property information.
104 # Each range has a starting code point, an ending code point, and a value that
105 # is meant to apply to all the code points between the two end points,
106 # inclusive.  For a map table, this value is the property value for those
107 # code points.  Two such ranges could be written like this:
108 #   0x41 .. 0x5A, 'Upper',
109 #   0x61 .. 0x7A, 'Lower'
110 #
111 # Each range also has a type used as a convenience to classify the values.
112 # Most ranges in this program will be Type 0, or normal, but there are some
113 # ranges that have a non-zero type.  These are used only in map tables, and
114 # are for mappings that don't fit into the normal scheme of things.  Mappings
115 # that require a hash entry to communicate with utf8.c are one example;
116 # another example is mappings for charnames.pm to use which indicate a name
117 # that is algorithmically determinable from its code point (and the reverse).
118 # These are used to significantly compact these tables, instead of listing
119 # each one of the tens of thousands individually.
120 #
121 # In a match table, the value of a range is irrelevant (and hence the type as
122 # well, which will always be 0), and arbitrarily set to the null string.
123 # Using the example above, there would be two match tables for those two
124 # entries, one named Upper would contain the 0x41..0x5A range, and the other
125 # named Lower would contain 0x61..0x7A.
126 #
127 # Actually, there are two types of range lists, "Range_Map" is the one
128 # associated with map tables, and "Range_List" with match tables.
129 # Again, this is so that methods can be defined on one and not the others so
130 # as to prevent operating on them in incorrect ways.
131 #
132 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
133 # in the perl core.  All tables could in theory be written, but some are
134 # suppressed because there is no current practical use for them.  It is easy
135 # to change which get written by changing various lists that are near the top
136 # of the actual code in this file.  The table data structures contain enough
137 # ancillary information to allow them to be treated as separate entities for
138 # writing, such as the path to each one's file.  There is a heading in each
139 # map table that gives the format of its entries, and what the map is for all
140 # the code points missing from it.  (This allows tables to be more compact.)
141 #
142 # The Property data structure contains one or more tables.  All properties
143 # contain a map table (except the $perl property which is a
144 # pseudo-property containing only match tables), and any properties that
145 # are usable in regular expression matches also contain various matching
146 # tables, one for each value the property can have.  A binary property can
147 # have two values, True and False (or Y and N, which are preferred by Unicode
148 # terminology).  Thus each of these properties will have a map table that
149 # takes every code point and maps it to Y or N (but having ranges cuts the
150 # number of entries in that table way down), and two match tables, one
151 # which has a list of all the code points that map to Y, and one for all the
152 # code points that map to N.  (For each binary property, a third table is also
153 # generated for the pseudo Perl property.  It contains the identical code
154 # points as the Y table, but can be written in regular expressions, not in the
155 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
156 # properties are binary, but some properties have several possible values,
157 # some have many, and properties like Name have a different value for every
158 # named code point.  Those will not, unless the controlling lists are changed,
159 # have their match tables written out.  But all the ones which can be used in
160 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
161 # a property would have either its map table or its match tables written but
162 # not both.  Again, what gets written is controlled by lists which can easily
163 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
164 # tables needed to reconstruct the Unicode db are now written out, while
165 # suppressing the Unicode .txt files that contain the data.  Our tables are
166 # much more compact than the .txt files, so a significant space savings was
167 # achieved.  Also, tables are not written out that are trivially derivable
168 # from tables that do get written.  So, there typically is no file containing
169 # the code points not matched by a binary property (the table for \P{} versus
170 # lowercase \p{}), since you just need to invert the True table to get the
171 # False table.
172
173 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
174 # how many match tables there are and the content of the maps.  This 'Type' is
175 # different than a range 'Type', so don't get confused by the two concepts
176 # having the same name.
177 #
178 # For information about the Unicode properties, see Unicode's UAX44 document:
179
180 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
181
182 # As stated earlier, this program will work on any release of Unicode so far.
183 # Most obvious problems in earlier data have NOT been corrected except when
184 # necessary to make Perl or this program work reasonably, and to keep out
185 # potential security issues.  For example, no folding information was given in
186 # early releases, so this program substitutes lower case instead, just so that
187 # a regular expression with the /i option will do something that actually
188 # gives the right results in many cases.  There are also a couple other
189 # corrections for version 1.1.5, commented at the point they are made.  As an
190 # example of corrections that weren't made (but could be) is this statement
191 # from DerivedAge.txt: "The supplementary private use code points and the
192 # non-character code points were assigned in version 2.0, but not specifically
193 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
194 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
195 # further down in these introductory comments.
196 #
197 # This program works on all non-provisional properties as of the current
198 # Unicode release, though the files for some are suppressed for various
199 # reasons.  You can change which are output by changing lists in this program.
200 #
201 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
202 # loose matchings rules (from Unicode TR18):
203 #
204 #    The recommended names for UCD properties and property values are in
205 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
206 #    [PropValue]. There are both abbreviated names and longer, more
207 #    descriptive names. It is strongly recommended that both names be
208 #    recognized, and that loose matching of property names be used,
209 #    whereby the case distinctions, whitespace, hyphens, and underbar
210 #    are ignored.
211 #
212 # The program still allows Fuzzy to override its determination of if loose
213 # matching should be used, but it isn't currently used, as it is no longer
214 # needed; the calculations it makes are good enough.
215 #
216 # SUMMARY OF HOW IT WORKS:
217 #
218 #   Process arguments
219 #
220 #   A list is constructed containing each input file that is to be processed
221 #
222 #   Each file on the list is processed in a loop, using the associated handler
223 #   code for each:
224 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
225 #            first.  These files name the properties and property values.
226 #            Objects are created of all the property and property value names
227 #            that the rest of the input should expect, including all synonyms.
228 #        The other input files give mappings from properties to property
229 #           values.  That is, they list code points and say what the mapping
230 #           is under the given property.  Some files give the mappings for
231 #           just one property; and some for many.  This program goes through
232 #           each file and populates the properties and their map tables from
233 #           them.  Some properties are listed in more than one file, and
234 #           Unicode has set up a precedence as to which has priority if there
235 #           is a conflict.  Thus the order of processing matters, and this
236 #           program handles the conflict possibility by processing the
237 #           overriding input files last, so that if necessary they replace
238 #           earlier values.
239 #        After this is all done, the program creates the property mappings not
240 #            furnished by Unicode, but derivable from what it does give.
241 #        The tables of code points that match each property value in each
242 #            property that is accessible by regular expressions are created.
243 #        The Perl-defined properties are created and populated.  Many of these
244 #            require data determined from the earlier steps
245 #        Any Perl-defined synonyms are created, and name clashes between Perl
246 #            and Unicode are reconciled and warned about.
247 #        All the properties are written to files
248 #        Any other files are written, and final warnings issued.
249 #
250 # For clarity, a number of operators have been overloaded to work on tables:
251 #   ~ means invert (take all characters not in the set).  The more
252 #       conventional '!' is not used because of the possibility of confusing
253 #       it with the actual boolean operation.
254 #   + means union
255 #   - means subtraction
256 #   & means intersection
257 # The precedence of these is the order listed.  Parentheses should be
258 # copiously used.  These are not a general scheme.  The operations aren't
259 # defined for a number of things, deliberately, to avoid getting into trouble.
260 # Operations are done on references and affect the underlying structures, so
261 # that the copy constructors for them have been overloaded to not return a new
262 # clone, but the input object itself.
263 #
264 # The bool operator is deliberately not overloaded to avoid confusion with
265 # "should it mean if the object merely exists, or also is non-empty?".
266 #
267 # WHY CERTAIN DESIGN DECISIONS WERE MADE
268 #
269 # This program needs to be able to run under miniperl.  Therefore, it uses a
270 # minimum of other modules, and hence implements some things itself that could
271 # be gotten from CPAN
272 #
273 # This program uses inputs published by the Unicode Consortium.  These can
274 # change incompatibly between releases without the Perl maintainers realizing
275 # it.  Therefore this program is now designed to try to flag these.  It looks
276 # at the directories where the inputs are, and flags any unrecognized files.
277 # It keeps track of all the properties in the files it handles, and flags any
278 # that it doesn't know how to handle.  It also flags any input lines that
279 # don't match the expected syntax, among other checks.
280 #
281 # It is also designed so if a new input file matches one of the known
282 # templates, one hopefully just needs to add it to a list to have it
283 # processed.
284 #
285 # As mentioned earlier, some properties are given in more than one file.  In
286 # particular, the files in the extracted directory are supposedly just
287 # reformattings of the others.  But they contain information not easily
288 # derivable from the other files, including results for Unihan (which isn't
289 # usually available to this program) and for unassigned code points.  They
290 # also have historically had errors or been incomplete.  In an attempt to
291 # create the best possible data, this program thus processes them first to
292 # glean information missing from the other files; then processes those other
293 # files to override any errors in the extracted ones.  Much of the design was
294 # driven by this need to store things and then possibly override them.
295 #
296 # It tries to keep fatal errors to a minimum, to generate something usable for
297 # testing purposes.  It always looks for files that could be inputs, and will
298 # warn about any that it doesn't know how to handle (the -q option suppresses
299 # the warning).
300 #
301 # Why is there more than one type of range?
302 #   This simplified things.  There are some very specialized code points that
303 #   have to be handled specially for output, such as Hangul syllable names.
304 #   By creating a range type (done late in the development process), it
305 #   allowed this to be stored with the range, and overridden by other input.
306 #   Originally these were stored in another data structure, and it became a
307 #   mess trying to decide if a second file that was for the same property was
308 #   overriding the earlier one or not.
309 #
310 # Why are there two kinds of tables, match and map?
311 #   (And there is a base class shared by the two as well.)  As stated above,
312 #   they actually are for different things.  Development proceeded much more
313 #   smoothly when I (khw) realized the distinction.  Map tables are used to
314 #   give the property value for every code point (actually every code point
315 #   that doesn't map to a default value).  Match tables are used for regular
316 #   expression matches, and are essentially the inverse mapping.  Separating
317 #   the two allows more specialized methods, and error checks so that one
318 #   can't just take the intersection of two map tables, for example, as that
319 #   is nonsensical.
320 #
321 # What about 'fate' and 'status'.  The concept of a table's fate was created
322 #   late when it became clear that something more was needed.  The difference
323 #   between this and 'status' is unclean, and could be improved if someone
324 #   wanted to spend the effort.
325 #
326 # DEBUGGING
327 #
328 # This program is written so it will run under miniperl.  Occasionally changes
329 # will cause an error where the backtrace doesn't work well under miniperl.
330 # To diagnose the problem, you can instead run it under regular perl, if you
331 # have one compiled.
332 #
333 # There is a good trace facility.  To enable it, first sub DEBUG must be set
334 # to return true.  Then a line like
335 #
336 # local $to_trace = 1 if main::DEBUG;
337 #
338 # can be added to enable tracing in its lexical scope (plus dynamic) or until
339 # you insert another line:
340 #
341 # local $to_trace = 0 if main::DEBUG;
342 #
343 # To actually trace, use a line like "trace $a, @b, %c, ...;
344 #
345 # Some of the more complex subroutines already have trace statements in them.
346 # Permanent trace statements should be like:
347 #
348 # trace ... if main::DEBUG && $to_trace;
349 #
350 # If there is just one or a few files that you're debugging, you can easily
351 # cause most everything else to be skipped.  Change the line
352 #
353 # my $debug_skip = 0;
354 #
355 # to 1, and every file whose object is in @input_file_objects and doesn't have
356 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
357 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
358 #
359 # To compare the output tables, it may be useful to specify the -annotate
360 # flag.  (As of this writing, this can't be done on a clean workspace, due to
361 # requirements in Text::Tabs used in this option; so first run mktables
362 # without this option.)  This option adds comment lines to each table, one for
363 # each non-algorithmically named character giving, currently its code point,
364 # name, and graphic representation if printable (and you have a font that
365 # knows about it).  This makes it easier to see what the particular code
366 # points are in each output table.  Non-named code points are annotated with a
367 # description of their status, and contiguous ones with the same description
368 # will be output as a range rather than individually.  Algorithmically named
369 # characters are also output as ranges, except when there are just a few
370 # contiguous ones.
371 #
372 # FUTURE ISSUES
373 #
374 # The program would break if Unicode were to change its names so that
375 # interior white space, underscores, or dashes differences were significant
376 # within property and property value names.
377 #
378 # It might be easier to use the xml versions of the UCD if this program ever
379 # would need heavy revision, and the ability to handle old versions was not
380 # required.
381 #
382 # There is the potential for name collisions, in that Perl has chosen names
383 # that Unicode could decide it also likes.  There have been such collisions in
384 # the past, with mostly Perl deciding to adopt the Unicode definition of the
385 # name.  However in the 5.2 Unicode beta testing, there were a number of such
386 # collisions, which were withdrawn before the final release, because of Perl's
387 # and other's protests.  These all involved new properties which began with
388 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
389 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
390 # Unicode document, so they are unlikely to be used by Unicode for another
391 # purpose.  However, they might try something beginning with 'In', or use any
392 # of the other Perl-defined properties.  This program will warn you of name
393 # collisions, and refuse to generate tables with them, but manual intervention
394 # will be required in this event.  One scheme that could be implemented, if
395 # necessary, would be to have this program generate another file, or add a
396 # field to mktables.lst that gives the date of first definition of a property.
397 # Each new release of Unicode would use that file as a basis for the next
398 # iteration.  And the Perl synonym addition code could sort based on the age
399 # of the property, so older properties get priority, and newer ones that clash
400 # would be refused; hence existing code would not be impacted, and some other
401 # synonym would have to be used for the new property.  This is ugly, and
402 # manual intervention would certainly be easier to do in the short run; lets
403 # hope it never comes to this.
404 #
405 # A NOTE ON UNIHAN
406 #
407 # This program can generate tables from the Unihan database.  But that db
408 # isn't normally available, so it is marked as optional.  Prior to version
409 # 5.2, this database was in a single file, Unihan.txt.  In 5.2 the database
410 # was split into 8 different files, all beginning with the letters 'Unihan'.
411 # If you plunk those files down into the directory mktables ($0) is in, this
412 # program will read them and automatically create tables for the properties
413 # from it that are listed in PropertyAliases.txt and PropValueAliases.txt,
414 # plus any you add to the @cjk_properties array and the @cjk_property_values
415 # array, being sure to add necessary '# @missings' lines to the latter.  For
416 # Unicode versions earlier than 5.2, most of the Unihan properties are not
417 # listed at all in PropertyAliases nor PropValueAliases.  This program assumes
418 # for these early releases that you want the properties that are specified in
419 # the 5.2 release.
420 #
421 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
422 # and filter_unihan_line() are the functions where this is done.  This program
423 # already does some adjusting to make the lines look more like the rest of the
424 # Unicode DB;  You can see what that is in filter_unihan_line()
425 #
426 # There is a bug in the 3.2 data file in which some values for the
427 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
428 # could be added to correct these; or for a particular installation, the
429 # Unihan.txt file could be edited to fix them.
430 #
431 # HOW TO ADD A FILE TO BE PROCESSED
432 #
433 # A new file from Unicode needs to have an object constructed for it in
434 # @input_file_objects, probably at the end or at the end of the extracted
435 # ones.  The program should warn you if its name will clash with others on
436 # restrictive file systems, like DOS.  If so, figure out a better name, and
437 # add lines to the README.perl file giving that.  If the file is a character
438 # property, it should be in the format that Unicode has implicitly
439 # standardized for such files for the more recently introduced ones.
440 # If so, the Input_file constructor for @input_file_objects can just be the
441 # file name and release it first appeared in.  If not, then it should be
442 # possible to construct an each_line_handler() to massage the line into the
443 # standardized form.
444 #
445 # For non-character properties, more code will be needed.  You can look at
446 # the existing entries for clues.
447 #
448 # UNICODE VERSIONS NOTES
449 #
450 # The Unicode UCD has had a number of errors in it over the versions.  And
451 # these remain, by policy, in the standard for that version.  Therefore it is
452 # risky to correct them, because code may be expecting the error.  So this
453 # program doesn't generally make changes, unless the error breaks the Perl
454 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
455 # for U+1105, which causes real problems for the algorithms for Jamo
456 # calculations, so it is changed here.
457 #
458 # But it isn't so clear cut as to what to do about concepts that are
459 # introduced in a later release; should they extend back to earlier releases
460 # where the concept just didn't exist?  It was easier to do this than to not,
461 # so that's what was done.  For example, the default value for code points not
462 # in the files for various properties was probably undefined until changed by
463 # some version.  No_Block for blocks is such an example.  This program will
464 # assign No_Block even in Unicode versions that didn't have it.  This has the
465 # benefit that code being written doesn't have to special case earlier
466 # versions; and the detriment that it doesn't match the Standard precisely for
467 # the affected versions.
468 #
469 # Here are some observations about some of the issues in early versions:
470 #
471 # Prior to version 3.0, there were 3 character decompositions.  These are not
472 # handled by Unicode::Normalize, nor will it compile when presented a version
473 # that has them.  However, you can trivially get it to compile by simply
474 # ignoring those decompositions, by changing the croak to a carp.  At the time
475 # of this writing, the line (in cpan/Unicode-Normalize/Normalize.pm or
476 # cpan/Unicode-Normalize/mkheader) reads
477 #
478 #   croak("Weird Canonical Decomposition of U+$h");
479 #
480 # Simply comment it out.  It will compile, but will not know about any three
481 # character decompositions.
482
483 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
484 # that the reason is that the CJK block starting at 4E00 was removed from
485 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
486 # single property name \p{alpha}) has the correct values.  But the compound
487 # form is simply not generated until 3.1, as it can be argued that prior to
488 # this release, this was not an official property.  The comments for
489 # filter_old_style_proplist() give more details.
490 #
491 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
492 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
493 # reason is that 3.2 introduced U+205F=medium math space, which was not
494 # classed as white space, but Perl figured out that it should have been. 4.0
495 # reclassified it correctly.
496 #
497 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
498 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
499 # became 202, and ATBL was left with no code points, as all the ones that
500 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
501 # name for the class, it would not have been affected, but if it used the
502 # mnemonic, it would have been.
503 #
504 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that, code
505 # points which eventually came to have this script property value, instead
506 # mapped to "Unknown".  But in the next release all these code points were
507 # moved to \p{sc=common} instead.
508
509 # The tests furnished  by Unicode for testing WordBreak and SentenceBreak
510 # generate errors in 5.0 and earlier.
511 #
512 # The default for missing code points for BidiClass is complicated.  Starting
513 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
514 # tries to do the best it can for earlier releases.  It is done in
515 # process_PropertyAliases()
516 #
517 # In version 2.1.2, the entry in UnicodeData.txt:
518 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
519 # should instead be
520 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
521 # Without this change, there are casing problems for this character.
522 #
523 # Search for $string_compare_versions to see how to compare changes to
524 # properties between Unicode versions
525 #
526 ##############################################################################
527
528 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
529                         # and errors
530 my $MAX_LINE_WIDTH = 78;
531
532 # Debugging aid to skip most files so as to not be distracted by them when
533 # concentrating on the ones being debugged.  Add
534 # non_skip => 1,
535 # to the constructor for those files you want processed when you set this.
536 # Files with a first version number of 0 are special: they are always
537 # processed regardless of the state of this flag.  Generally, Jamo.txt and
538 # UnicodeData.txt must not be skipped if you want this program to not die
539 # before normal completion.
540 my $debug_skip = 0;
541
542
543 # Normally these are suppressed.
544 my $write_Unicode_deprecated_tables = 0;
545
546 # Set to 1 to enable tracing.
547 our $to_trace = 0;
548
549 { # Closure for trace: debugging aid
550     my $print_caller = 1;        # ? Include calling subroutine name
551     my $main_with_colon = 'main::';
552     my $main_colon_length = length($main_with_colon);
553
554     sub trace {
555         return unless $to_trace;        # Do nothing if global flag not set
556
557         my @input = @_;
558
559         local $DB::trace = 0;
560         $DB::trace = 0;          # Quiet 'used only once' message
561
562         my $line_number;
563
564         # Loop looking up the stack to get the first non-trace caller
565         my $caller_line;
566         my $caller_name;
567         my $i = 0;
568         do {
569             $line_number = $caller_line;
570             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
571             $caller = $main_with_colon unless defined $caller;
572
573             $caller_name = $caller;
574
575             # get rid of pkg
576             $caller_name =~ s/.*:://;
577             if (substr($caller_name, 0, $main_colon_length)
578                 eq $main_with_colon)
579             {
580                 $caller_name = substr($caller_name, $main_colon_length);
581             }
582
583         } until ($caller_name ne 'trace');
584
585         # If the stack was empty, we were called from the top level
586         $caller_name = 'main' if ($caller_name eq ""
587                                     || $caller_name eq 'trace');
588
589         my $output = "";
590         #print STDERR __LINE__, ": ", join ", ", @input, "\n";
591         foreach my $string (@input) {
592             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
593                 $output .= simple_dumper($string);
594             }
595             else {
596                 $string = "$string" if ref $string;
597                 $string = $UNDEF unless defined $string;
598                 chomp $string;
599                 $string = '""' if $string eq "";
600                 $output .= " " if $output ne ""
601                                 && $string ne ""
602                                 && substr($output, -1, 1) ne " "
603                                 && substr($string, 0, 1) ne " ";
604                 $output .= $string;
605             }
606         }
607
608         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
609         print STDERR "$caller_name: " if $print_caller;
610         print STDERR $output, "\n";
611         return;
612     }
613 }
614
615 # This is for a rarely used development feature that allows you to compare two
616 # versions of the Unicode standard without having to deal with changes caused
617 # by the code points introduced in the later version.  You probably also want
618 # to use the -annotate option when using this.  Change the 0 to a string
619 # containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only code
620 # points introduced in that release and earlier will be used; later ones are
621 # thrown away.  You use the version number of the earliest one you want to
622 # compare; then run this program on directory structures containing each
623 # release, and compare the outputs.  These outputs will therefore include only
624 # the code points common to both releases, and you can see the changes caused
625 # just by the underlying release semantic changes.  For versions earlier than
626 # 3.2, you must copy a version of DAge.txt into the directory.
627 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
628 my $compare_versions = DEBUG
629                        && $string_compare_versions
630                        && pack "C*", split /\./, $string_compare_versions;
631
632 sub uniques {
633     # Returns non-duplicated input values.  From "Perl Best Practices:
634     # Encapsulated Cleverness".  p. 455 in first edition.
635
636     my %seen;
637     # Arguably this breaks encapsulation, if the goal is to permit multiple
638     # distinct objects to stringify to the same value, and be interchangeable.
639     # However, for this program, no two objects stringify identically, and all
640     # lists passed to this function are either objects or strings. So this
641     # doesn't affect correctness, but it does give a couple of percent speedup.
642     no overloading;
643     return grep { ! $seen{$_}++ } @_;
644 }
645
646 $0 = File::Spec->canonpath($0);
647
648 my $make_test_script = 0;      # ? Should we output a test script
649 my $make_norm_test_script = 0; # ? Should we output a normalization test script
650 my $write_unchanged_files = 0; # ? Should we update the output files even if
651                                #    we don't think they have changed
652 my $use_directory = "";        # ? Should we chdir somewhere.
653 my $pod_directory;             # input directory to store the pod file.
654 my $pod_file = 'perluniprops';
655 my $t_path;                     # Path to the .t test file
656 my $file_list = 'mktables.lst'; # File to store input and output file names.
657                                # This is used to speed up the build, by not
658                                # executing the main body of the program if
659                                # nothing on the list has changed since the
660                                # previous build
661 my $make_list = 1;             # ? Should we write $file_list.  Set to always
662                                # make a list so that when the pumpking is
663                                # preparing a release, s/he won't have to do
664                                # special things
665 my $glob_list = 0;             # ? Should we try to include unknown .txt files
666                                # in the input.
667 my $output_range_counts = $debugging_build;   # ? Should we include the number
668                                               # of code points in ranges in
669                                               # the output
670 my $annotate = 0;              # ? Should character names be in the output
671
672 # Verbosity levels; 0 is quiet
673 my $NORMAL_VERBOSITY = 1;
674 my $PROGRESS = 2;
675 my $VERBOSE = 3;
676
677 my $verbosity = $NORMAL_VERBOSITY;
678
679 # Stored in mktables.lst so that if this program is called with different
680 # options, will regenerate even if the files otherwise look like they're
681 # up-to-date.
682 my $command_line_arguments = join " ", @ARGV;
683
684 # Process arguments
685 while (@ARGV) {
686     my $arg = shift @ARGV;
687     if ($arg eq '-v') {
688         $verbosity = $VERBOSE;
689     }
690     elsif ($arg eq '-p') {
691         $verbosity = $PROGRESS;
692         $| = 1;     # Flush buffers as we go.
693     }
694     elsif ($arg eq '-q') {
695         $verbosity = 0;
696     }
697     elsif ($arg eq '-w') {
698         $write_unchanged_files = 1; # update the files even if havent changed
699     }
700     elsif ($arg eq '-check') {
701         my $this = shift @ARGV;
702         my $ok = shift @ARGV;
703         if ($this ne $ok) {
704             print "Skipping as check params are not the same.\n";
705             exit(0);
706         }
707     }
708     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
709         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
710     }
711     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
712     {
713         $make_test_script = 1;
714     }
715     elsif ($arg eq '-makenormtest')
716     {
717         $make_norm_test_script = 1;
718     }
719     elsif ($arg eq '-makelist') {
720         $make_list = 1;
721     }
722     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
723         -d $use_directory or croak "Unknown directory '$use_directory'";
724     }
725     elsif ($arg eq '-L') {
726
727         # Existence not tested until have chdir'd
728         $file_list = shift;
729     }
730     elsif ($arg eq '-globlist') {
731         $glob_list = 1;
732     }
733     elsif ($arg eq '-c') {
734         $output_range_counts = ! $output_range_counts
735     }
736     elsif ($arg eq '-annotate') {
737         $annotate = 1;
738         $debugging_build = 1;
739         $output_range_counts = 1;
740     }
741     else {
742         my $with_c = 'with';
743         $with_c .= 'out' if $output_range_counts;   # Complements the state
744         croak <<END;
745 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
746           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
747           [-check A B ]
748   -c          : Output comments $with_c number of code points in ranges
749   -q          : Quiet Mode: Only output serious warnings.
750   -p          : Set verbosity level to normal plus show progress.
751   -v          : Set Verbosity level high:  Show progress and non-serious
752                 warnings
753   -w          : Write files regardless
754   -C dir      : Change to this directory before proceeding. All relative paths
755                 except those specified by the -P and -T options will be done
756                 with respect to this directory.
757   -P dir      : Output $pod_file file to directory 'dir'.
758   -T path     : Create a test script as 'path'; overrides -maketest
759   -L filelist : Use alternate 'filelist' instead of standard one
760   -globlist   : Take as input all non-Test *.txt files in current and sub
761                 directories
762   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
763                 overrides -T
764   -makelist   : Rewrite the file list $file_list based on current setup
765   -annotate   : Output an annotation for each character in the table files;
766                 useful for debugging mktables, looking at diffs; but is slow
767                 and memory intensive
768   -check A B  : Executes $0 only if A and B are the same
769 END
770     }
771 }
772
773 # Stores the most-recently changed file.  If none have changed, can skip the
774 # build
775 my $most_recent = (stat $0)[9];   # Do this before the chdir!
776
777 # Change directories now, because need to read 'version' early.
778 if ($use_directory) {
779     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
780         $pod_directory = File::Spec->rel2abs($pod_directory);
781     }
782     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
783         $t_path = File::Spec->rel2abs($t_path);
784     }
785     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
786     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
787         $pod_directory = File::Spec->abs2rel($pod_directory);
788     }
789     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
790         $t_path = File::Spec->abs2rel($t_path);
791     }
792 }
793
794 # Get Unicode version into regular and v-string.  This is done now because
795 # various tables below get populated based on it.  These tables are populated
796 # here to be near the top of the file, and so easily seeable by those needing
797 # to modify things.
798 open my $VERSION, "<", "version"
799                     or croak "$0: can't open required file 'version': $!\n";
800 my $string_version = <$VERSION>;
801 close $VERSION;
802 chomp $string_version;
803 my $v_version = pack "C*", split /\./, $string_version;        # v string
804
805 # The following are the complete names of properties with property values that
806 # are known to not match any code points in some versions of Unicode, but that
807 # may change in the future so they should be matchable, hence an empty file is
808 # generated for them.
809 my @tables_that_may_be_empty;
810 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
811                                                     if $v_version lt v6.3.0;
812 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
813 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
814 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
815                                                     if $v_version ge v4.1.0;
816 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
817                                                     if $v_version ge v6.0.0;
818 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
819                                                     if $v_version ge v6.1.0;
820 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
821                                                     if $v_version ge v6.2.0;
822
823 # The lists below are hashes, so the key is the item in the list, and the
824 # value is the reason why it is in the list.  This makes generation of
825 # documentation easier.
826
827 my %why_suppressed;  # No file generated for these.
828
829 # Files aren't generated for empty extraneous properties.  This is arguable.
830 # Extraneous properties generally come about because a property is no longer
831 # used in a newer version of Unicode.  If we generated a file without code
832 # points, programs that used to work on that property will still execute
833 # without errors.  It just won't ever match (or will always match, with \P{}).
834 # This means that the logic is now likely wrong.  I (khw) think its better to
835 # find this out by getting an error message.  Just move them to the table
836 # above to change this behavior
837 my %why_suppress_if_empty_warn_if_not = (
838
839    # It is the only property that has ever officially been removed from the
840    # Standard.  The database never contained any code points for it.
841    'Special_Case_Condition' => 'Obsolete',
842
843    # Apparently never official, but there were code points in some versions of
844    # old-style PropList.txt
845    'Non_Break' => 'Obsolete',
846 );
847
848 # These would normally go in the warn table just above, but they were changed
849 # a long time before this program was written, so warnings about them are
850 # moot.
851 if ($v_version gt v3.2.0) {
852     push @tables_that_may_be_empty,
853                                 'Canonical_Combining_Class=Attached_Below_Left'
854 }
855
856 # Enum values for to_output_map() method in the Map_Table package. (0 is don't
857 # output)
858 my $EXTERNAL_MAP = 1;
859 my $INTERNAL_MAP = 2;
860 my $OUTPUT_ADJUSTED = 3;
861
862 # To override computed values for writing the map tables for these properties.
863 # The default for enum map tables is to write them out, so that the Unicode
864 # .txt files can be removed, but all the data to compute any property value
865 # for any code point is available in a more compact form.
866 my %global_to_output_map = (
867     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
868     # get stuck supporting it if things change.  Since it is a STRING
869     # property, it normally would be listed in the pod, but INTERNAL_MAP
870     # suppresses that.
871     Unicode_1_Name => $INTERNAL_MAP,
872
873     Present_In => 0,                # Suppress, as easily computed from Age
874     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
875                                             # retained, but needed for
876                                             # non-ASCII
877
878     # Suppress, as mapping can be found instead from the
879     # Perl_Decomposition_Mapping file
880     Decomposition_Type => 0,
881 );
882
883 # There are several types of obsolete properties defined by Unicode.  These
884 # must be hand-edited for every new Unicode release.
885 my %why_deprecated;  # Generates a deprecated warning message if used.
886 my %why_stabilized;  # Documentation only
887 my %why_obsolete;    # Documentation only
888
889 {   # Closure
890     my $simple = 'Perl uses the more complete version';
891     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
892
893     my $other_properties = 'other properties';
894     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
895     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
896
897     %why_deprecated = (
898         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
899         'Jamo_Short_Name' => $contributory,
900         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
901         'Other_Alphabetic' => $contributory,
902         'Other_Default_Ignorable_Code_Point' => $contributory,
903         'Other_Grapheme_Extend' => $contributory,
904         'Other_ID_Continue' => $contributory,
905         'Other_ID_Start' => $contributory,
906         'Other_Lowercase' => $contributory,
907         'Other_Math' => $contributory,
908         'Other_Uppercase' => $contributory,
909         'Expands_On_NFC' => $why_no_expand,
910         'Expands_On_NFD' => $why_no_expand,
911         'Expands_On_NFKC' => $why_no_expand,
912         'Expands_On_NFKD' => $why_no_expand,
913     );
914
915     %why_suppressed = (
916         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
917         # contains the same information, but without the algorithmically
918         # determinable Hangul syllables'.  This file is not published, so it's
919         # existence is not noted in the comment.
920         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or prop_invmap() or charprop() in Unicode::UCD::',
921
922         # Don't suppress ISO_Comment, as otherwise special handling is needed
923         # to differentiate between it and gc=c, which can be written as 'isc',
924         # which is the same characters as ISO_Comment's short name.
925
926         'Name' => "Accessible via \\N{...} or 'use charnames;' or charprop() or prop_invmap() in Unicode::UCD::",
927
928         'Simple_Case_Folding' => "$simple.  Can access this through casefold(), charprop(), or prop_invmap() in Unicode::UCD",
929         'Simple_Lowercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
930         'Simple_Titlecase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
931         'Simple_Uppercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
932
933         FC_NFKC_Closure => 'Deprecated by Unicode, and supplanted in usage by NFKC_Casefold; otherwise not useful',
934     );
935
936     foreach my $property (
937
938             # The following are suppressed because they were made contributory
939             # or deprecated by Unicode before Perl ever thought about
940             # supporting them.
941             'Jamo_Short_Name',
942             'Grapheme_Link',
943             'Expands_On_NFC',
944             'Expands_On_NFD',
945             'Expands_On_NFKC',
946             'Expands_On_NFKD',
947
948             # The following are suppressed because they have been marked
949             # as deprecated for a sufficient amount of time
950             'Other_Alphabetic',
951             'Other_Default_Ignorable_Code_Point',
952             'Other_Grapheme_Extend',
953             'Other_ID_Continue',
954             'Other_ID_Start',
955             'Other_Lowercase',
956             'Other_Math',
957             'Other_Uppercase',
958     ) {
959         $why_suppressed{$property} = $why_deprecated{$property};
960     }
961
962     # Customize the message for all the 'Other_' properties
963     foreach my $property (keys %why_deprecated) {
964         next if (my $main_property = $property) !~ s/^Other_//;
965         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
966     }
967 }
968
969 if ($write_Unicode_deprecated_tables) {
970     foreach my $property (keys %why_suppressed) {
971         delete $why_suppressed{$property} if $property =~
972                                                     / ^ Other | Grapheme /x;
973     }
974 }
975
976 if ($v_version ge 4.0.0) {
977     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
978     if ($v_version ge 6.0.0) {
979         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
980     }
981 }
982 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
983     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
984     if ($v_version ge 6.0.0) {
985         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
986     }
987 }
988
989 # Probably obsolete forever
990 if ($v_version ge v4.1.0) {
991     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
992 }
993 if ($v_version ge v6.0.0) {
994     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
995     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
996 }
997
998 # This program can create files for enumerated-like properties, such as
999 # 'Numeric_Type'.  This file would be the same format as for a string
1000 # property, with a mapping from code point to its value, so you could look up,
1001 # for example, the script a code point is in.  But no one so far wants this
1002 # mapping, or they have found another way to get it since this is a new
1003 # feature.  So no file is generated except if it is in this list.
1004 my @output_mapped_properties = split "\n", <<END;
1005 END
1006
1007 # If you want more Unihan properties than the default, you need to add them to
1008 # these arrays.  Depending on the property type, @missing lines might have to
1009 # be added to the second array.  A sample entry would be (including the '#'):
1010 # @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1011 my @cjk_properties = split "\n", <<'END';
1012 END
1013 my @cjk_property_values = split "\n", <<'END';
1014 END
1015
1016 # The input files don't list every code point.  Those not listed are to be
1017 # defaulted to some value.  Below are hard-coded what those values are for
1018 # non-binary properties as of 5.1.  Starting in 5.0, there are
1019 # machine-parsable comment lines in the files that give the defaults; so this
1020 # list shouldn't have to be extended.  The claim is that all missing entries
1021 # for binary properties will default to 'N'.  Unicode tried to change that in
1022 # 5.2, but the beta period produced enough protest that they backed off.
1023 #
1024 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1025 # be in the form that it expects.  The others may be synonyms.
1026 my $CODE_POINT = '<code point>';
1027 my %default_mapping = (
1028     Age => "Unassigned",
1029     # Bidi_Class => Complicated; set in code
1030     Bidi_Mirroring_Glyph => "",
1031     Block => 'No_Block',
1032     Canonical_Combining_Class => 0,
1033     Case_Folding => $CODE_POINT,
1034     Decomposition_Mapping => $CODE_POINT,
1035     Decomposition_Type => 'None',
1036     East_Asian_Width => "Neutral",
1037     FC_NFKC_Closure => $CODE_POINT,
1038     General_Category => ($v_version le 6.3.0) ? 'Cn' : 'Unassigned',
1039     Grapheme_Cluster_Break => 'Other',
1040     Hangul_Syllable_Type => 'NA',
1041     ISO_Comment => "",
1042     Jamo_Short_Name => "",
1043     Joining_Group => "No_Joining_Group",
1044     # Joining_Type => Complicated; set in code
1045     kIICore => 'N',   #                       Is converted to binary
1046     #Line_Break => Complicated; set in code
1047     Lowercase_Mapping => $CODE_POINT,
1048     Name => "",
1049     Name_Alias => "",
1050     NFC_QC => 'Yes',
1051     NFD_QC => 'Yes',
1052     NFKC_QC => 'Yes',
1053     NFKD_QC => 'Yes',
1054     Numeric_Type => 'None',
1055     Numeric_Value => 'NaN',
1056     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1057     Sentence_Break => 'Other',
1058     Simple_Case_Folding => $CODE_POINT,
1059     Simple_Lowercase_Mapping => $CODE_POINT,
1060     Simple_Titlecase_Mapping => $CODE_POINT,
1061     Simple_Uppercase_Mapping => $CODE_POINT,
1062     Titlecase_Mapping => $CODE_POINT,
1063     Unicode_1_Name => "",
1064     Unicode_Radical_Stroke => "",
1065     Uppercase_Mapping => $CODE_POINT,
1066     Word_Break => 'Other',
1067 );
1068
1069 ### End of externally interesting definitions, except for @input_file_objects
1070
1071 my $HEADER=<<"EOF";
1072 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1073 # This file is machine-generated by $0 from the Unicode
1074 # database, Version $string_version.  Any changes made here will be lost!
1075 EOF
1076
1077 my $INTERNAL_ONLY_HEADER = <<"EOF";
1078
1079 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1080 # This file is for internal use by core Perl only.  The format and even the
1081 # name or existence of this file are subject to change without notice.  Don't
1082 # use it directly.  Use Unicode::UCD to access the Unicode character data
1083 # base.
1084 EOF
1085
1086 my $DEVELOPMENT_ONLY=<<"EOF";
1087 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1088 # This file contains information artificially constrained to code points
1089 # present in Unicode release $string_compare_versions.
1090 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1091 # not be used for production.
1092
1093 EOF
1094
1095 my $MAX_UNICODE_CODEPOINT_STRING = ($v_version ge v2.0.0)
1096                                    ? "10FFFF"
1097                                    : "FFFF";
1098 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1099 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1100
1101 # We work with above-Unicode code points, up to UV_MAX.   But when you get
1102 # that high, above IV_MAX, some operations don't work, and you can easily get
1103 # overflow.  Therefore for internal use, we use a much smaller number,
1104 # translating it to UV_MAX only for output.  The exact number is immaterial
1105 # (all Unicode code points are treated exactly the same), but the algorithm
1106 # requires it to be at least 2 * $MAX_UNICODE_CODEPOINTS + 1;
1107 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1108 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1109 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1110
1111 my $MAX_PLATFORM_CODEPOINT = ~0;
1112
1113 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1114 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1115 # to decrease backtracking.  The first regex allows the code point to be at
1116 # the end of a word, but to work properly, the word shouldn't end with a valid
1117 # hex character.  The second one won't match a code point at the end of a
1118 # word, and doesn't have the run-on issue
1119 my $run_on_code_point_re =
1120             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1121 my $code_point_re = qr/\b$run_on_code_point_re/;
1122
1123 # This matches the beginning of the line in the Unicode db files that give the
1124 # defaults for code points not listed (i.e., missing) in the file.  The code
1125 # depends on this ending with a semi-colon, so it can assume it is a valid
1126 # field when the line is split() by semi-colons
1127 my $missing_defaults_prefix = qr/^#\s+\@missing:\s+0000\.\.10FFFF\s*;/;
1128
1129 # Property types.  Unicode has more types, but these are sufficient for our
1130 # purposes.
1131 my $UNKNOWN = -1;   # initialized to illegal value
1132 my $NON_STRING = 1; # Either binary or enum
1133 my $BINARY = 2;
1134 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1135                        # tables, additional true and false tables are
1136                        # generated so that false is anything matching the
1137                        # default value, and true is everything else.
1138 my $ENUM = 4;       # Include catalog
1139 my $STRING = 5;     # Anything else: string or misc
1140
1141 # Some input files have lines that give default values for code points not
1142 # contained in the file.  Sometimes these should be ignored.
1143 my $NO_DEFAULTS = 0;        # Must evaluate to false
1144 my $NOT_IGNORED = 1;
1145 my $IGNORED = 2;
1146
1147 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1148 # and will appear in the main body of the tables in the output files, but
1149 # there are other types of ranges as well, listed below, that are specially
1150 # handled.   There are pseudo-types as well that will never be stored as a
1151 # type, but will affect the calculation of the type.
1152
1153 # 0 is for normal, non-specials
1154 my $MULTI_CP = 1;           # Sequence of more than code point
1155 my $HANGUL_SYLLABLE = 2;
1156 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1157 my $NULL = 4;               # The map is to the null string; utf8.c can't
1158                             # handle these, nor is there an accepted syntax
1159                             # for them in \p{} constructs
1160 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1161                              # otherwise be $MULTI_CP type are instead type 0
1162
1163 # process_generic_property_file() can accept certain overrides in its input.
1164 # Each of these must begin AND end with $CMD_DELIM.
1165 my $CMD_DELIM = "\a";
1166 my $REPLACE_CMD = 'replace';    # Override the Replace
1167 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1168
1169 my $NO = 0;
1170 my $YES = 1;
1171
1172 # Values for the Replace argument to add_range.
1173 # $NO                      # Don't replace; add only the code points not
1174                            # already present.
1175 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1176                            # the comments at the subroutine definition.
1177 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1178 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1179                            # already there
1180 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1181                            # already there
1182 my $CROAK = 6;             # Die with an error if is already there
1183
1184 # Flags to give property statuses.  The phrases are to remind maintainers that
1185 # if the flag is changed, the indefinite article referring to it in the
1186 # documentation may need to be as well.
1187 my $NORMAL = "";
1188 my $DEPRECATED = 'D';
1189 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1190 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1191 my $DISCOURAGED = 'X';
1192 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1193 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1194 my $STRICTER = 'T';
1195 my $a_bold_stricter = "a 'B<$STRICTER>'";
1196 my $A_bold_stricter = "A 'B<$STRICTER>'";
1197 my $STABILIZED = 'S';
1198 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1199 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1200 my $OBSOLETE = 'O';
1201 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1202 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1203
1204 # Aliases can also have an extra status:
1205 my $INTERNAL_ALIAS = 'P';
1206
1207 my %status_past_participles = (
1208     $DISCOURAGED => 'discouraged',
1209     $STABILIZED => 'stabilized',
1210     $OBSOLETE => 'obsolete',
1211     $DEPRECATED => 'deprecated',
1212     $INTERNAL_ALIAS => 'reserved for Perl core internal use only',
1213 );
1214
1215 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1216 # externally documented.
1217 my $ORDINARY = 0;       # The normal fate.
1218 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1219                         # but there is a file written that can be used to
1220                         # reconstruct this table
1221 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1222                         # for Perl's internal use only
1223 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1224                         # Is for backwards compatibility for applications that
1225                         # read the file directly, so it's format is
1226                         # unchangeable.
1227 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1228                         # result, we don't bother to do many computations on
1229                         # it.
1230 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1231                         # computations anyway, as the values are needed for
1232                         # things to work.  This happens when we have Perl
1233                         # extensions that depend on Unicode tables that
1234                         # wouldn't normally be in a given Unicode version.
1235
1236 # The format of the values of the tables:
1237 my $EMPTY_FORMAT = "";
1238 my $BINARY_FORMAT = 'b';
1239 my $DECIMAL_FORMAT = 'd';
1240 my $FLOAT_FORMAT = 'f';
1241 my $INTEGER_FORMAT = 'i';
1242 my $HEX_FORMAT = 'x';
1243 my $RATIONAL_FORMAT = 'r';
1244 my $STRING_FORMAT = 's';
1245 my $ADJUST_FORMAT = 'a';
1246 my $HEX_ADJUST_FORMAT = 'ax';
1247 my $DECOMP_STRING_FORMAT = 'c';
1248 my $STRING_WHITE_SPACE_LIST = 'sw';
1249
1250 my %map_table_formats = (
1251     $BINARY_FORMAT => 'binary',
1252     $DECIMAL_FORMAT => 'single decimal digit',
1253     $FLOAT_FORMAT => 'floating point number',
1254     $INTEGER_FORMAT => 'integer',
1255     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1256     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1257     $STRING_FORMAT => 'string',
1258     $ADJUST_FORMAT => 'some entries need adjustment',
1259     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1260     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1261     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1262 );
1263
1264 # Unicode didn't put such derived files in a separate directory at first.
1265 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1266 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1267 my $AUXILIARY = 'auxiliary';
1268
1269 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1270 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1271 my %loose_to_file_of;       # loosely maps table names to their respective
1272                             # files
1273 my %stricter_to_file_of;    # same; but for stricter mapping.
1274 my %loose_property_to_file_of; # Maps a loose property name to its map file
1275 my %strict_property_to_file_of; # Same, but strict
1276 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1277                             # inversion list.  When a definition is inlined,
1278                             # its value in the hash it's in (one of the two
1279                             # defined just above) will include an index into
1280                             # this array.  The 0th element is initialized to
1281                             # the definition for a zero length inversion list
1282 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1283                             # in the hash %utf8::SwashInfo
1284 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1285                              # their rational equivalent
1286 my %loose_property_name_of; # Loosely maps (non_string) property names to
1287                             # standard form
1288 my %strict_property_name_of; # Strictly maps (non_string) property names to
1289                             # standard form
1290 my %string_property_loose_to_name; # Same, for string properties.
1291 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1292                             # the property name in standard loose form, and
1293                             # 'value' is the default value for that property,
1294                             # also in standard loose form.
1295 my %loose_to_standard_value; # loosely maps table names to the canonical
1296                             # alias for them
1297 my %ambiguous_names;        # keys are alias names (in standard form) that
1298                             # have more than one possible meaning.
1299 my %combination_property;   # keys are alias names (in standard form) that
1300                             # have both a map table, and a binary one that
1301                             # yields true for all non-null maps.
1302 my %prop_aliases;           # Keys are standard property name; values are each
1303                             # one's aliases
1304 my %prop_value_aliases;     # Keys of top level are standard property name;
1305                             # values are keys to another hash,  Each one is
1306                             # one of the property's values, in standard form.
1307                             # The values are that prop-val's aliases.
1308 my %skipped_files;          # List of files that we skip
1309 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1310
1311 # Most properties are immune to caseless matching, otherwise you would get
1312 # nonsensical results, as properties are a function of a code point, not
1313 # everything that is caselessly equivalent to that code point.  For example,
1314 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1315 # be true because 's' and 'S' are equivalent caselessly.  However,
1316 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1317 # extend that concept to those very few properties that are like this.  Each
1318 # such property will match the full range caselessly.  They are hard-coded in
1319 # the program; it's not worth trying to make it general as it's extremely
1320 # unlikely that they will ever change.
1321 my %caseless_equivalent_to;
1322
1323 # These constants names and values were taken from the Unicode standard,
1324 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1325 # syllables.  The '_string' versions are so generated tables can retain the
1326 # hex format, which is the more familiar value
1327 my $SBase_string = "0xAC00";
1328 my $SBase = CORE::hex $SBase_string;
1329 my $LBase_string = "0x1100";
1330 my $LBase = CORE::hex $LBase_string;
1331 my $VBase_string = "0x1161";
1332 my $VBase = CORE::hex $VBase_string;
1333 my $TBase_string = "0x11A7";
1334 my $TBase = CORE::hex $TBase_string;
1335 my $SCount = 11172;
1336 my $LCount = 19;
1337 my $VCount = 21;
1338 my $TCount = 28;
1339 my $NCount = $VCount * $TCount;
1340
1341 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1342 # with the above published constants.
1343 my %Jamo;
1344 my %Jamo_L;     # Leading consonants
1345 my %Jamo_V;     # Vowels
1346 my %Jamo_T;     # Trailing consonants
1347
1348 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1349 # The key is the base name of the code point, and the value is an
1350 # array giving all the ranges that use this base name.  Each range
1351 # is actually a hash giving the 'low' and 'high' values of it.
1352 my %names_ending_in_code_point;
1353 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1354                                         # removed from the names
1355 # Inverse mapping.  The list of ranges that have these kinds of
1356 # names.  Each element contains the low, high, and base names in an
1357 # anonymous hash.
1358 my @code_points_ending_in_code_point;
1359
1360 # To hold Unicode's normalization test suite
1361 my @normalization_tests;
1362
1363 # Boolean: does this Unicode version have the hangul syllables, and are we
1364 # writing out a table for them?
1365 my $has_hangul_syllables = 0;
1366
1367 # Does this Unicode version have code points whose names end in their
1368 # respective code points, and are we writing out a table for them?  0 for no;
1369 # otherwise points to first property that a table is needed for them, so that
1370 # if multiple tables are needed, we don't create duplicates
1371 my $needing_code_points_ending_in_code_point = 0;
1372
1373 my @backslash_X_tests;     # List of tests read in for testing \X
1374 my @SB_tests;              # List of tests read in for testing \b{sb}
1375 my @WB_tests;              # List of tests read in for testing \b{wb}
1376 my @unhandled_properties;  # Will contain a list of properties found in
1377                            # the input that we didn't process.
1378 my @match_properties;      # Properties that have match tables, to be
1379                            # listed in the pod
1380 my @map_properties;        # Properties that get map files written
1381 my @named_sequences;       # NamedSequences.txt contents.
1382 my %potential_files;       # Generated list of all .txt files in the directory
1383                            # structure so we can warn if something is being
1384                            # ignored.
1385 my @missing_early_files;   # Generated list of absent files that we need to
1386                            # proceed in compiling this early Unicode version
1387 my @files_actually_output; # List of files we generated.
1388 my @more_Names;            # Some code point names are compound; this is used
1389                            # to store the extra components of them.
1390 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1391                            # the minimum before we consider it equivalent to a
1392                            # candidate rational
1393 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1394
1395 # These store references to certain commonly used property objects
1396 my $ccc;
1397 my $gc;
1398 my $perl;
1399 my $block;
1400 my $perl_charname;
1401 my $print;
1402 my $All;
1403 my $Assigned;   # All assigned characters in this Unicode release
1404 my $script;
1405
1406 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1407 my $has_In_conflicts = 0;
1408 my $has_Is_conflicts = 0;
1409
1410 sub internal_file_to_platform ($) {
1411     # Convert our file paths which have '/' separators to those of the
1412     # platform.
1413
1414     my $file = shift;
1415     return undef unless defined $file;
1416
1417     return File::Spec->join(split '/', $file);
1418 }
1419
1420 sub file_exists ($) {   # platform independent '-e'.  This program internally
1421                         # uses slash as a path separator.
1422     my $file = shift;
1423     return 0 if ! defined $file;
1424     return -e internal_file_to_platform($file);
1425 }
1426
1427 sub objaddr($) {
1428     # Returns the address of the blessed input object.
1429     # It doesn't check for blessedness because that would do a string eval
1430     # every call, and the program is structured so that this is never called
1431     # for a non-blessed object.
1432
1433     no overloading; # If overloaded, numifying below won't work.
1434
1435     # Numifying a ref gives its address.
1436     return pack 'J', $_[0];
1437 }
1438
1439 # These are used only if $annotate is true.
1440 # The entire range of Unicode characters is examined to populate these
1441 # after all the input has been processed.  But most can be skipped, as they
1442 # have the same descriptive phrases, such as being unassigned
1443 my @viacode;            # Contains the 1 million character names
1444 my @age;                # And their ages ("" if none)
1445 my @printable;          # boolean: And are those characters printable?
1446 my @annotate_char_type; # Contains a type of those characters, specifically
1447                         # for the purposes of annotation.
1448 my $annotate_ranges;    # A map of ranges of code points that have the same
1449                         # name for the purposes of annotation.  They map to the
1450                         # upper edge of the range, so that the end point can
1451                         # be immediately found.  This is used to skip ahead to
1452                         # the end of a range, and avoid processing each
1453                         # individual code point in it.
1454 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1455                                    # characters, but excluding those which are
1456                                    # also noncharacter code points
1457
1458 # The annotation types are an extension of the regular range types, though
1459 # some of the latter are folded into one.  Make the new types negative to
1460 # avoid conflicting with the regular types
1461 my $SURROGATE_TYPE = -1;
1462 my $UNASSIGNED_TYPE = -2;
1463 my $PRIVATE_USE_TYPE = -3;
1464 my $NONCHARACTER_TYPE = -4;
1465 my $CONTROL_TYPE = -5;
1466 my $ABOVE_UNICODE_TYPE = -6;
1467 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1468
1469 sub populate_char_info ($) {
1470     # Used only with the $annotate option.  Populates the arrays with the
1471     # input code point's info that are needed for outputting more detailed
1472     # comments.  If calling context wants a return, it is the end point of
1473     # any contiguous range of characters that share essentially the same info
1474
1475     my $i = shift;
1476     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1477
1478     $viacode[$i] = $perl_charname->value_of($i) || "";
1479
1480     # A character is generally printable if Unicode says it is,
1481     # but below we make sure that most Unicode general category 'C' types
1482     # aren't.
1483     $printable[$i] = $print->contains($i);
1484
1485     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1486
1487     # Only these two regular types are treated specially for annotations
1488     # purposes
1489     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1490                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1491
1492     # Give a generic name to all code points that don't have a real name.
1493     # We output ranges, if applicable, for these.  Also calculate the end
1494     # point of the range.
1495     my $end;
1496     if (! $viacode[$i]) {
1497         my $nonchar;
1498         if ($i > $MAX_UNICODE_CODEPOINT) {
1499             $viacode[$i] = 'Above-Unicode';
1500             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1501             $printable[$i] = 0;
1502             $end = $MAX_WORKING_CODEPOINT;
1503             $age[$i] = "";
1504         }
1505         elsif ($gc-> table('Private_use')->contains($i)) {
1506             $viacode[$i] = 'Private Use';
1507             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1508             $printable[$i] = 0;
1509             $end = $gc->table('Private_Use')->containing_range($i)->end;
1510             $age[$i] = property_ref("Age")->value_of($i);
1511         }
1512         elsif ((defined ($nonchar =
1513                             Property::property_ref('Noncharacter_Code_Point'))
1514                && $nonchar->table('Y')->contains($i)))
1515         {
1516             $viacode[$i] = 'Noncharacter';
1517             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1518             $printable[$i] = 0;
1519             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1520                                                     containing_range($i)->end;
1521             $age[$i] = property_ref("Age")->value_of($i);
1522         }
1523         elsif ($gc-> table('Control')->contains($i)) {
1524             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1525             $annotate_char_type[$i] = $CONTROL_TYPE;
1526             $printable[$i] = 0;
1527             $age[$i] = property_ref("Age")->value_of($i);
1528         }
1529         elsif ($gc-> table('Unassigned')->contains($i)) {
1530             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1531             $printable[$i] = 0;
1532             if (defined $block) { # No blocks in earliest releases
1533                 $viacode[$i] = 'Unassigned';
1534                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1535             }
1536             else {
1537                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1538
1539                 # Because we name the unassigned by the blocks they are in, it
1540                 # can't go past the end of that block, and it also can't go
1541                 # past the unassigned range it is in.  The special table makes
1542                 # sure that the non-characters, which are unassigned, are
1543                 # separated out.
1544                 $end = min($block->containing_range($i)->end,
1545                            $unassigned_sans_noncharacters->
1546                                                     containing_range($i)->end);
1547             }
1548             $age[$i] = property_ref("Age")->value_of($i);
1549         }
1550         elsif ($perl->table('_Perl_Surrogate')->contains($i)) {
1551             $viacode[$i] = 'Surrogate';
1552             $annotate_char_type[$i] = $SURROGATE_TYPE;
1553             $printable[$i] = 0;
1554             $end = $gc->table('Surrogate')->containing_range($i)->end;
1555             $age[$i] = property_ref("Age")->value_of($i);
1556         }
1557         else {
1558             Carp::my_carp_bug("Can't figure out how to annotate "
1559                               . sprintf("U+%04X", $i)
1560                               . ".  Proceeding anyway.");
1561             $viacode[$i] = 'UNKNOWN';
1562             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1563             $printable[$i] = 0;
1564         }
1565     }
1566
1567     # Here, has a name, but if it's one in which the code point number is
1568     # appended to the name, do that.
1569     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1570         $viacode[$i] .= sprintf("-%04X", $i);
1571
1572         # Do all these as groups of the same age, instead of individually,
1573         # because their names are so meaningless, and there are typically
1574         # large quantities of them.
1575         my $Age = property_ref("Age");
1576         $age[$i] = $Age->value_of($i);
1577         my $limit = $perl_charname->containing_range($i)->end;
1578         $end = $i + 1;
1579         while ($end <= $limit && $Age->value_of($end) == $age[$i]) {
1580             $end++;
1581         }
1582         $end--;
1583     }
1584
1585     # And here, has a name, but if it's a hangul syllable one, replace it with
1586     # the correct name from the Unicode algorithm
1587     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1588         use integer;
1589         my $SIndex = $i - $SBase;
1590         my $L = $LBase + $SIndex / $NCount;
1591         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1592         my $T = $TBase + $SIndex % $TCount;
1593         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1594         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1595         $age[$i] = property_ref("Age")->value_of($i);
1596         $end = $perl_charname->containing_range($i)->end;
1597     }
1598     else {
1599         $age[$i] = property_ref("Age")->value_of($i);
1600     }
1601
1602     return if ! defined wantarray;
1603     return $i if ! defined $end;    # If not a range, return the input
1604
1605     # Save this whole range so can find the end point quickly
1606     $annotate_ranges->add_map($i, $end, $end);
1607
1608     return $end;
1609 }
1610
1611 # Commented code below should work on Perl 5.8.
1612 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1613 ## the native perl version of it (which is what would operate under miniperl)
1614 ## is extremely slow, as it does a string eval every call.
1615 #my $has_fast_scalar_util = $^X !~ /miniperl/
1616 #                            && defined eval "require Scalar::Util";
1617 #
1618 #sub objaddr($) {
1619 #    # Returns the address of the blessed input object.  Uses the XS version if
1620 #    # available.  It doesn't check for blessedness because that would do a
1621 #    # string eval every call, and the program is structured so that this is
1622 #    # never called for a non-blessed object.
1623 #
1624 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1625 #
1626 #    # Check at least that is a ref.
1627 #    my $pkg = ref($_[0]) or return undef;
1628 #
1629 #    # Change to a fake package to defeat any overloaded stringify
1630 #    bless $_[0], 'main::Fake';
1631 #
1632 #    # Numifying a ref gives its address.
1633 #    my $addr = pack 'J', $_[0];
1634 #
1635 #    # Return to original class
1636 #    bless $_[0], $pkg;
1637 #    return $addr;
1638 #}
1639
1640 sub max ($$) {
1641     my $a = shift;
1642     my $b = shift;
1643     return $a if $a >= $b;
1644     return $b;
1645 }
1646
1647 sub min ($$) {
1648     my $a = shift;
1649     my $b = shift;
1650     return $a if $a <= $b;
1651     return $b;
1652 }
1653
1654 sub clarify_number ($) {
1655     # This returns the input number with underscores inserted every 3 digits
1656     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1657     # checked.
1658
1659     my $number = shift;
1660     my $pos = length($number) - 3;
1661     return $number if $pos <= 1;
1662     while ($pos > 0) {
1663         substr($number, $pos, 0) = '_';
1664         $pos -= 3;
1665     }
1666     return $number;
1667 }
1668
1669 sub clarify_code_point_count ($) {
1670     # This is like clarify_number(), but the input is assumed to be a count of
1671     # code points, rather than a generic number.
1672
1673     my $append = "";
1674
1675     my $number = shift;
1676     if ($number > $MAX_UNICODE_CODEPOINTS) {
1677         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1678         return "All above-Unicode code points" if $number == 0;
1679         $append = " + all above-Unicode code points";
1680     }
1681     return clarify_number($number) . $append;
1682 }
1683
1684 package Carp;
1685
1686 # These routines give a uniform treatment of messages in this program.  They
1687 # are placed in the Carp package to cause the stack trace to not include them,
1688 # although an alternative would be to use another package and set @CARP_NOT
1689 # for it.
1690
1691 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1692
1693 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1694 # and overload trying to load Scalar:Util under miniperl.  See
1695 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1696 undef $overload::VERSION;
1697
1698 sub my_carp {
1699     my $message = shift || "";
1700     my $nofold = shift || 0;
1701
1702     if ($message) {
1703         $message = main::join_lines($message);
1704         $message =~ s/^$0: *//;     # Remove initial program name
1705         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1706         $message = "\n$0: $message;";
1707
1708         # Fold the message with program name, semi-colon end punctuation
1709         # (which looks good with the message that carp appends to it), and a
1710         # hanging indent for continuation lines.
1711         $message = main::simple_fold($message, "", 4) unless $nofold;
1712         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1713                                     # appends is to the same line
1714     }
1715
1716     return $message if defined wantarray;   # If a caller just wants the msg
1717
1718     carp $message;
1719     return;
1720 }
1721
1722 sub my_carp_bug {
1723     # This is called when it is clear that the problem is caused by a bug in
1724     # this program.
1725
1726     my $message = shift;
1727     $message =~ s/^$0: *//;
1728     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1729     carp $message;
1730     return;
1731 }
1732
1733 sub carp_too_few_args {
1734     if (@_ != 2) {
1735         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1736         return;
1737     }
1738
1739     my $args_ref = shift;
1740     my $count = shift;
1741
1742     my_carp_bug("Need at least $count arguments to "
1743         . (caller 1)[3]
1744         . ".  Instead got: '"
1745         . join ', ', @$args_ref
1746         . "'.  No action taken.");
1747     return;
1748 }
1749
1750 sub carp_extra_args {
1751     my $args_ref = shift;
1752     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1753
1754     unless (ref $args_ref) {
1755         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1756         return;
1757     }
1758     my ($package, $file, $line) = caller;
1759     my $subroutine = (caller 1)[3];
1760
1761     my $list;
1762     if (ref $args_ref eq 'HASH') {
1763         foreach my $key (keys %$args_ref) {
1764             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1765         }
1766         $list = join ', ', each %{$args_ref};
1767     }
1768     elsif (ref $args_ref eq 'ARRAY') {
1769         foreach my $arg (@$args_ref) {
1770             $arg = $UNDEF unless defined $arg;
1771         }
1772         $list = join ', ', @$args_ref;
1773     }
1774     else {
1775         my_carp_bug("Can't cope with ref "
1776                 . ref($args_ref)
1777                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1778         return;
1779     }
1780
1781     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1782     return;
1783 }
1784
1785 package main;
1786
1787 { # Closure
1788
1789     # This program uses the inside-out method for objects, as recommended in
1790     # "Perl Best Practices".  (This is the best solution still, since this has
1791     # to run under miniperl.)  This closure aids in generating those.  There
1792     # are two routines.  setup_package() is called once per package to set
1793     # things up, and then set_access() is called for each hash representing a
1794     # field in the object.  These routines arrange for the object to be
1795     # properly destroyed when no longer used, and for standard accessor
1796     # functions to be generated.  If you need more complex accessors, just
1797     # write your own and leave those accesses out of the call to set_access().
1798     # More details below.
1799
1800     my %constructor_fields; # fields that are to be used in constructors; see
1801                             # below
1802
1803     # The values of this hash will be the package names as keys to other
1804     # hashes containing the name of each field in the package as keys, and
1805     # references to their respective hashes as values.
1806     my %package_fields;
1807
1808     sub setup_package {
1809         # Sets up the package, creating standard DESTROY and dump methods
1810         # (unless already defined).  The dump method is used in debugging by
1811         # simple_dumper().
1812         # The optional parameters are:
1813         #   a)  a reference to a hash, that gets populated by later
1814         #       set_access() calls with one of the accesses being
1815         #       'constructor'.  The caller can then refer to this, but it is
1816         #       not otherwise used by these two routines.
1817         #   b)  a reference to a callback routine to call during destruction
1818         #       of the object, before any fields are actually destroyed
1819
1820         my %args = @_;
1821         my $constructor_ref = delete $args{'Constructor_Fields'};
1822         my $destroy_callback = delete $args{'Destroy_Callback'};
1823         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1824
1825         my %fields;
1826         my $package = (caller)[0];
1827
1828         $package_fields{$package} = \%fields;
1829         $constructor_fields{$package} = $constructor_ref;
1830
1831         unless ($package->can('DESTROY')) {
1832             my $destroy_name = "${package}::DESTROY";
1833             no strict "refs";
1834
1835             # Use typeglob to give the anonymous subroutine the name we want
1836             *$destroy_name = sub {
1837                 my $self = shift;
1838                 my $addr = do { no overloading; pack 'J', $self; };
1839
1840                 $self->$destroy_callback if $destroy_callback;
1841                 foreach my $field (keys %{$package_fields{$package}}) {
1842                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1843                     delete $package_fields{$package}{$field}{$addr};
1844                 }
1845                 return;
1846             }
1847         }
1848
1849         unless ($package->can('dump')) {
1850             my $dump_name = "${package}::dump";
1851             no strict "refs";
1852             *$dump_name = sub {
1853                 my $self = shift;
1854                 return dump_inside_out($self, $package_fields{$package}, @_);
1855             }
1856         }
1857         return;
1858     }
1859
1860     sub set_access {
1861         # Arrange for the input field to be garbage collected when no longer
1862         # needed.  Also, creates standard accessor functions for the field
1863         # based on the optional parameters-- none if none of these parameters:
1864         #   'addable'    creates an 'add_NAME()' accessor function.
1865         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1866         #                function.
1867         #   'settable'   creates a 'set_NAME()' accessor function.
1868         #   'constructor' doesn't create an accessor function, but adds the
1869         #                field to the hash that was previously passed to
1870         #                setup_package();
1871         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1872         # 'add' etc. all mean 'addable'.
1873         # The read accessor function will work on both array and scalar
1874         # values.  If another accessor in the parameter list is 'a', the read
1875         # access assumes an array.  You can also force it to be array access
1876         # by specifying 'readable_array' instead of 'readable'
1877         #
1878         # A sort-of 'protected' access can be set-up by preceding the addable,
1879         # readable or settable with some initial portion of 'protected_' (but,
1880         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1881         # "protection" is only by convention.  All that happens is that the
1882         # accessor functions' names begin with an underscore.  So instead of
1883         # calling set_foo, the call is _set_foo.  (Real protection could be
1884         # accomplished by having a new subroutine, end_package, called at the
1885         # end of each package, and then storing the __LINE__ ranges and
1886         # checking them on every accessor.  But that is way overkill.)
1887
1888         # We create anonymous subroutines as the accessors and then use
1889         # typeglobs to assign them to the proper package and name
1890
1891         my $name = shift;   # Name of the field
1892         my $field = shift;  # Reference to the inside-out hash containing the
1893                             # field
1894
1895         my $package = (caller)[0];
1896
1897         if (! exists $package_fields{$package}) {
1898             croak "$0: Must call 'setup_package' before 'set_access'";
1899         }
1900
1901         # Stash the field so DESTROY can get it.
1902         $package_fields{$package}{$name} = $field;
1903
1904         # Remaining arguments are the accessors.  For each...
1905         foreach my $access (@_) {
1906             my $access = lc $access;
1907
1908             my $protected = "";
1909
1910             # Match the input as far as it goes.
1911             if ($access =~ /^(p[^_]*)_/) {
1912                 $protected = $1;
1913                 if (substr('protected_', 0, length $protected)
1914                     eq $protected)
1915                 {
1916
1917                     # Add 1 for the underscore not included in $protected
1918                     $access = substr($access, length($protected) + 1);
1919                     $protected = '_';
1920                 }
1921                 else {
1922                     $protected = "";
1923                 }
1924             }
1925
1926             if (substr('addable', 0, length $access) eq $access) {
1927                 my $subname = "${package}::${protected}add_$name";
1928                 no strict "refs";
1929
1930                 # add_ accessor.  Don't add if already there, which we
1931                 # determine using 'eq' for scalars and '==' otherwise.
1932                 *$subname = sub {
1933                     use strict "refs";
1934                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1935                     my $self = shift;
1936                     my $value = shift;
1937                     my $addr = do { no overloading; pack 'J', $self; };
1938                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1939                     if (ref $value) {
1940                         return if grep { $value == $_ } @{$field->{$addr}};
1941                     }
1942                     else {
1943                         return if grep { $value eq $_ } @{$field->{$addr}};
1944                     }
1945                     push @{$field->{$addr}}, $value;
1946                     return;
1947                 }
1948             }
1949             elsif (substr('constructor', 0, length $access) eq $access) {
1950                 if ($protected) {
1951                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1952                 }
1953                 else {
1954                     $constructor_fields{$package}{$name} = $field;
1955                 }
1956             }
1957             elsif (substr('readable_array', 0, length $access) eq $access) {
1958
1959                 # Here has read access.  If one of the other parameters for
1960                 # access is array, or this one specifies array (by being more
1961                 # than just 'readable_'), then create a subroutine that
1962                 # assumes the data is an array.  Otherwise just a scalar
1963                 my $subname = "${package}::${protected}$name";
1964                 if (grep { /^a/i } @_
1965                     or length($access) > length('readable_'))
1966                 {
1967                     no strict "refs";
1968                     *$subname = sub {
1969                         use strict "refs";
1970                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1971                         my $addr = do { no overloading; pack 'J', $_[0]; };
1972                         if (ref $field->{$addr} ne 'ARRAY') {
1973                             my $type = ref $field->{$addr};
1974                             $type = 'scalar' unless $type;
1975                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1976                             return;
1977                         }
1978                         return scalar @{$field->{$addr}} unless wantarray;
1979
1980                         # Make a copy; had problems with caller modifying the
1981                         # original otherwise
1982                         my @return = @{$field->{$addr}};
1983                         return @return;
1984                     }
1985                 }
1986                 else {
1987
1988                     # Here not an array value, a simpler function.
1989                     no strict "refs";
1990                     *$subname = sub {
1991                         use strict "refs";
1992                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1993                         no overloading;
1994                         return $field->{pack 'J', $_[0]};
1995                     }
1996                 }
1997             }
1998             elsif (substr('settable', 0, length $access) eq $access) {
1999                 my $subname = "${package}::${protected}set_$name";
2000                 no strict "refs";
2001                 *$subname = sub {
2002                     use strict "refs";
2003                     if (main::DEBUG) {
2004                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2005                         Carp::carp_extra_args(\@_) if @_ > 2;
2006                     }
2007                     # $self is $_[0]; $value is $_[1]
2008                     no overloading;
2009                     $field->{pack 'J', $_[0]} = $_[1];
2010                     return;
2011                 }
2012             }
2013             else {
2014                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2015             }
2016         }
2017         return;
2018     }
2019 }
2020
2021 package Input_file;
2022
2023 # All input files use this object, which stores various attributes about them,
2024 # and provides for convenient, uniform handling.  The run method wraps the
2025 # processing.  It handles all the bookkeeping of opening, reading, and closing
2026 # the file, returning only significant input lines.
2027 #
2028 # Each object gets a handler which processes the body of the file, and is
2029 # called by run().  All character property files must use the generic,
2030 # default handler, which has code scrubbed to handle things you might not
2031 # expect, including automatic EBCDIC handling.  For files that don't deal with
2032 # mapping code points to a property value, such as test files,
2033 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2034 # handler to be a custom one.  Such a handler should basically be a
2035 # while(next_line()) {...} loop.
2036 #
2037 # You can also set up handlers to
2038 #   0) call during object construction time, after everything else is done
2039 #   1) call before the first line is read, for pre processing
2040 #   2) call to adjust each line of the input before the main handler gets
2041 #      them.  This can be automatically generated, if appropriately simple
2042 #      enough, by specifiying a Properties parameter in the constructor.
2043 #   3) call upon EOF before the main handler exits its loop
2044 #   4) call at the end, for post processing
2045 #
2046 # $_ is used to store the input line, and is to be filtered by the
2047 # each_line_handler()s.  So, if the format of the line is not in the desired
2048 # format for the main handler, these are used to do that adjusting.  They can
2049 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2050 # so the $_ output of one is used as the input to the next.  The eof handler
2051 # is also stackable, but none of the others are, but could easily be changed
2052 # to be so.
2053 #
2054 # Some properties are used by the Perl core but aren't defined until later
2055 # Unicode releases.  The perl interpreter would have problems working when
2056 # compiled with an earlier Unicode version that doesn't have them, so we need
2057 # to define them somehow for those releases.  The 'Early' constructor
2058 # parameter can be used to automatically handle this.  It is essentially
2059 # ignored if the Unicode version being compiled has a data file for this
2060 # property.  Either code to execute or a file to read can be specified.
2061 # Details are at the %early definition.
2062 #
2063 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2064 # which insert the parameters as lines to be processed before the next input
2065 # file line is read.  This allows the EOF handler(s) to flush buffers, for
2066 # example.  The difference between the two routines is that the lines inserted
2067 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2068 # called it from such a handler, you would get infinite recursion without some
2069 # mechanism to prevent that.)  Lines inserted by insert_adjusted_lines() go
2070 # directly to the main handler without any adjustments.  If the
2071 # post-processing handler calls any of these, there will be no effect.  Some
2072 # error checking for these conditions could be added, but it hasn't been done.
2073 #
2074 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2075 # to prevent further processing of the line.  This routine will output the
2076 # message as a warning once, and then keep a count of the lines that have the
2077 # same message, and output that count at the end of the file's processing.
2078 # This keeps the number of messages down to a manageable amount.
2079 #
2080 # get_missings() should be called to retrieve any @missing input lines.
2081 # Messages will be raised if this isn't done if the options aren't to ignore
2082 # missings.
2083
2084 sub trace { return main::trace(@_); }
2085
2086 { # Closure
2087     # Keep track of fields that are to be put into the constructor.
2088     my %constructor_fields;
2089
2090     main::setup_package(Constructor_Fields => \%constructor_fields);
2091
2092     my %file; # Input file name, required
2093     main::set_access('file', \%file, qw{ c r });
2094
2095     my %first_released; # Unicode version file was first released in, required
2096     main::set_access('first_released', \%first_released, qw{ c r });
2097
2098     my %handler;    # Subroutine to process the input file, defaults to
2099                     # 'process_generic_property_file'
2100     main::set_access('handler', \%handler, qw{ c });
2101
2102     my %property;
2103     # name of property this file is for.  defaults to none, meaning not
2104     # applicable, or is otherwise determinable, for example, from each line.
2105     main::set_access('property', \%property, qw{ c r });
2106
2107     my %optional;
2108     # This is either an unsigned number, or a list of property names.  In the
2109     # former case, if it is non-zero, it means the file is optional, so if the
2110     # file is absent, no warning about that is output.  In the latter case, it
2111     # is a list of properties that the file (exclusively) defines.  If the
2112     # file is present, tables for those properties will be produced; if
2113     # absent, none will, even if they are listed elsewhere (namely
2114     # PropertyAliases.txt and PropValueAliases.txt) as being in this release,
2115     # and no warnings will be raised about them not being available.  (And no
2116     # warning about the file itself will be raised.)
2117     main::set_access('optional', \%optional, qw{ c readable_array } );
2118
2119     my %non_skip;
2120     # This is used for debugging, to skip processing of all but a few input
2121     # files.  Add 'non_skip => 1' to the constructor for those files you want
2122     # processed when you set the $debug_skip global.
2123     main::set_access('non_skip', \%non_skip, 'c');
2124
2125     my %skip;
2126     # This is used to skip processing of this input file (semi-) permanently.
2127     # The value should be the reason the file is being skipped.  It is used
2128     # for files that we aren't planning to process anytime soon, but want to
2129     # allow to be in the directory and be checked for their names not
2130     # conflicting with any other files on a DOS 8.3 name filesystem, but to
2131     # not otherwise be processed, and to not raise a warning about not being
2132     # handled.  In the constructor call, any value that evaluates to a numeric
2133     # 0 or undef means don't skip.  Any other value is a string giving the
2134     # reason it is being skippped, and this will appear in generated pod.
2135     # However, an empty string reason will suppress the pod entry.
2136     # Internally, calls that evaluate to numeric 0 are changed into undef to
2137     # distinguish them from an empty string call.
2138     main::set_access('skip', \%skip, 'c', 'r');
2139
2140     my %each_line_handler;
2141     # list of subroutines to look at and filter each non-comment line in the
2142     # file.  defaults to none.  The subroutines are called in order, each is
2143     # to adjust $_ for the next one, and the final one adjusts it for
2144     # 'handler'
2145     main::set_access('each_line_handler', \%each_line_handler, 'c');
2146
2147     my %properties; # Optional ordered list of the properties that occur in each
2148     # meaningful line of the input file.  If present, an appropriate
2149     # each_line_handler() is automatically generated and pushed onto the stack
2150     # of such handlers.  This is useful when a file contains multiple
2151     # proerties per line, but no other special considerations are necessary.
2152     # The special value "<ignored>" means to discard the corresponding input
2153     # field.
2154     # Any @missing lines in the file should also match this syntax; no such
2155     # files exist as of 6.3.  But if it happens in a future release, the code
2156     # could be expanded to properly parse them.
2157     main::set_access('properties', \%properties, qw{ c r });
2158
2159     my %has_missings_defaults;
2160     # ? Are there lines in the file giving default values for code points
2161     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2162     # the norm, but IGNORED means it has such lines, but the handler doesn't
2163     # use them.  Having these three states allows us to catch changes to the
2164     # UCD that this program should track.  XXX This could be expanded to
2165     # specify the syntax for such lines, like %properties above.
2166     main::set_access('has_missings_defaults',
2167                                         \%has_missings_defaults, qw{ c r });
2168
2169     my %construction_time_handler;
2170     # Subroutine to call at the end of the new method.  If undef, no such
2171     # handler is called.
2172     main::set_access('construction_time_handler',
2173                                         \%construction_time_handler, qw{ c });
2174
2175     my %pre_handler;
2176     # Subroutine to call before doing anything else in the file.  If undef, no
2177     # such handler is called.
2178     main::set_access('pre_handler', \%pre_handler, qw{ c });
2179
2180     my %eof_handler;
2181     # Subroutines to call upon getting an EOF on the input file, but before
2182     # that is returned to the main handler.  This is to allow buffers to be
2183     # flushed.  The handler is expected to call insert_lines() or
2184     # insert_adjusted() with the buffered material
2185     main::set_access('eof_handler', \%eof_handler, qw{ c });
2186
2187     my %post_handler;
2188     # Subroutine to call after all the lines of the file are read in and
2189     # processed.  If undef, no such handler is called.  Note that this cannot
2190     # add lines to be processed; instead use eof_handler
2191     main::set_access('post_handler', \%post_handler, qw{ c });
2192
2193     my %progress_message;
2194     # Message to print to display progress in lieu of the standard one
2195     main::set_access('progress_message', \%progress_message, qw{ c });
2196
2197     my %handle;
2198     # cache open file handle, internal.  Is undef if file hasn't been
2199     # processed at all, empty if has;
2200     main::set_access('handle', \%handle);
2201
2202     my %added_lines;
2203     # cache of lines added virtually to the file, internal
2204     main::set_access('added_lines', \%added_lines);
2205
2206     my %remapped_lines;
2207     # cache of lines added virtually to the file, internal
2208     main::set_access('remapped_lines', \%remapped_lines);
2209
2210     my %errors;
2211     # cache of errors found, internal
2212     main::set_access('errors', \%errors);
2213
2214     my %missings;
2215     # storage of '@missing' defaults lines
2216     main::set_access('missings', \%missings);
2217
2218     my %early;
2219     # Used for properties that must be defined (for Perl's purposes) on
2220     # versions of Unicode earlier than Unicode itself defines them.  The
2221     # parameter is an array (it would be better to be a hash, but not worth
2222     # bothering about due to its rare use).
2223     #
2224     # The first element is either a code reference to call when in a release
2225     # earlier than the Unicode file is available in, or it is an alternate
2226     # file to use instead of the non-existent one.  This file must have been
2227     # plunked down in the same directory as mktables.  Should you be compiling
2228     # on a release that needs such a file, mktables will abort the
2229     # compilation, and tell you where to get the necessary file(s), and what
2230     # name(s) to use to store them as.
2231     # In the case of specifying an alternate file, the array must contain two
2232     # further elements:
2233     #
2234     # [1] is the name of the property that will be generated by this file.
2235     # The class automatically takes the input file and excludes any code
2236     # points in it that were not assigned in the Unicode version being
2237     # compiled.  It then uses this result to define the property in the given
2238     # version.  Since the property doesn't actually exist in the Unicode
2239     # version being compiled, this should be a name accessible only by core
2240     # perl.  If it is the same name as the regular property, the constructor
2241     # will mark the output table as a $PLACEHOLDER so that it doesn't actually
2242     # get output, and so will be unusable by non-core code.  Otherwise it gets
2243     # marked as $INTERNAL_ONLY.
2244     #
2245     # [2] is a property value to assign (only when compiling Unicode 1.1.5) to
2246     # the Hangul syllables in that release (which were ripped out in version
2247     # 2) for the given property .  (Hence it is ignored except when compiling
2248     # version 1.  You only get one value that applies to all of them, which
2249     # may not be the actual reality, but probably nobody cares anyway for
2250     # these obsolete characters.)
2251     #
2252     # Not all files can be handled in the above way, and so the code ref
2253     # alternative is available.  It can do whatever it needs to.  The other
2254     # array elements are optional in this case, and the code is free to use or
2255     # ignore them if they are present.
2256     #
2257     # Internally, the constructor unshifts a 0 or 1 onto this array to
2258     # indicate if an early alternative is actually being used or not.  This
2259     # makes for easier testing later on.
2260     main::set_access('early', \%early, 'c');
2261
2262     my %required_even_in_debug_skip;
2263     # debug_skip is used to speed up compilation during debugging by skipping
2264     # processing files that are not needed for the task at hand.  However,
2265     # some files pretty much can never be skipped, and this is used to specify
2266     # that this is one of them.  In order to skip this file, the call to the
2267     # constructor must be edited to comment out this parameter.
2268     main::set_access('required_even_in_debug_skip',
2269                      \%required_even_in_debug_skip, 'c');
2270
2271     my %withdrawn;
2272     # Some files get removed from the Unicode DB.  This is a version object
2273     # giving the first release without this file.
2274     main::set_access('withdrawn', \%withdrawn, 'c');
2275
2276     my %in_this_release;
2277     # Calculated value from %first_released and %withdrawn.  Are we compiling
2278     # a Unicode release which includes this file?
2279     main::set_access('in_this_release', \%in_this_release);
2280
2281     sub _next_line;
2282     sub _next_line_with_remapped_range;
2283
2284     sub new {
2285         my $class = shift;
2286
2287         my $self = bless \do{ my $anonymous_scalar }, $class;
2288         my $addr = do { no overloading; pack 'J', $self; };
2289
2290         # Set defaults
2291         $handler{$addr} = \&main::process_generic_property_file;
2292         $non_skip{$addr} = 0;
2293         $skip{$addr} = undef;
2294         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2295         $handle{$addr} = undef;
2296         $added_lines{$addr} = [ ];
2297         $remapped_lines{$addr} = [ ];
2298         $each_line_handler{$addr} = [ ];
2299         $eof_handler{$addr} = [ ];
2300         $errors{$addr} = { };
2301         $missings{$addr} = [ ];
2302         $early{$addr} = [ ];
2303         $optional{$addr} = [ ];
2304
2305         # Two positional parameters.
2306         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2307         $file{$addr} = main::internal_file_to_platform(shift);
2308         $first_released{$addr} = shift;
2309
2310         # The rest of the arguments are key => value pairs
2311         # %constructor_fields has been set up earlier to list all possible
2312         # ones.  Either set or push, depending on how the default has been set
2313         # up just above.
2314         my %args = @_;
2315         foreach my $key (keys %args) {
2316             my $argument = $args{$key};
2317
2318             # Note that the fields are the lower case of the constructor keys
2319             my $hash = $constructor_fields{lc $key};
2320             if (! defined $hash) {
2321                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2322                 next;
2323             }
2324             if (ref $hash->{$addr} eq 'ARRAY') {
2325                 if (ref $argument eq 'ARRAY') {
2326                     foreach my $argument (@{$argument}) {
2327                         next if ! defined $argument;
2328                         push @{$hash->{$addr}}, $argument;
2329                     }
2330                 }
2331                 else {
2332                     push @{$hash->{$addr}}, $argument if defined $argument;
2333                 }
2334             }
2335             else {
2336                 $hash->{$addr} = $argument;
2337             }
2338             delete $args{$key};
2339         };
2340
2341         $non_skip{$addr} = 1 if $required_even_in_debug_skip{$addr};
2342
2343         # Convert 0 (meaning don't skip) to undef
2344         undef $skip{$addr} unless $skip{$addr};
2345
2346         # Handle the case where this file is optional
2347         my $pod_message_for_non_existent_optional = "";
2348         if ($optional{$addr}->@*) {
2349
2350             # First element is the pod message
2351             $pod_message_for_non_existent_optional
2352                                                 = shift $optional{$addr}->@*;
2353             # Convert a 0 'Optional' argument to an empty list to make later
2354             # code more concise.
2355             if (   $optional{$addr}->@*
2356                 && $optional{$addr}->@* == 1
2357                 && $optional{$addr}[0] ne ""
2358                 && $optional{$addr}[0] !~ /\D/
2359                 && $optional{$addr}[0] == 0)
2360             {
2361                 $optional{$addr} = [ ];
2362             }
2363             else {  # But if the only element doesn't evaluate to 0, make sure
2364                     # that this file is indeed considered optional below.
2365                 unshift $optional{$addr}->@*, 1;
2366             }
2367         }
2368
2369         my $progress;
2370         my $function_instead_of_file = 0;
2371
2372         # If we are compiling a Unicode release earlier than the file became
2373         # available, the constructor may have supplied a substitute
2374         if ($first_released{$addr} gt $v_version && $early{$addr}->@*) {
2375
2376             # Yes, we have a substitute, that we will use; mark it so
2377             unshift $early{$addr}->@*, 1;
2378
2379             # See the definition of %early for what the array elements mean.
2380             # If we have a property this defines, create a table and default
2381             # map for it now (at essentially compile time), so that it will be
2382             # available for the whole of run time.  (We will want to add this
2383             # name as an alias when we are using the official property name;
2384             # but this must be deferred until run(), because at construction
2385             # time the official names have yet to be defined.)
2386             if ($early{$addr}[2]) {
2387                 my $fate = ($property{$addr}
2388                             && $property{$addr} eq $early{$addr}[2])
2389                           ? $PLACEHOLDER
2390                           : $INTERNAL_ONLY;
2391                 my $prop_object = Property->new($early{$addr}[2],
2392                                                 Fate => $fate,
2393                                                 Perl_Extension => 1,
2394                                                 );
2395
2396                 # Use the default mapping for the regular property for this
2397                 # substitute one.
2398                 if (    defined $property{$addr}
2399                     &&  defined $default_mapping{$property{$addr}})
2400                 {
2401                     $prop_object
2402                         ->set_default_map($default_mapping{$property{$addr}});
2403                 }
2404             }
2405
2406             if (ref $early{$addr}[1] eq 'CODE') {
2407                 $function_instead_of_file = 1;
2408
2409                 # If the first element of the array is a code ref, the others
2410                 # are optional.
2411                 $handler{$addr} = $early{$addr}[1];
2412                 $property{$addr} = $early{$addr}[2]
2413                                                 if defined $early{$addr}[2];
2414                 $progress = "substitute $file{$addr}";
2415
2416                 undef $file{$addr};
2417             }
2418             else {  # Specifying a substitute file
2419
2420                 if (! main::file_exists($early{$addr}[1])) {
2421
2422                     # If we don't see the substitute file, generate an error
2423                     # message giving the needed things, and add it to the list
2424                     # of such to output before actual processing happens
2425                     # (hence the user finds out all of them in one run).
2426                     # Instead of creating a general method for NameAliases,
2427                     # hard-code it here, as there is unlikely to ever be a
2428                     # second one which needs special handling.
2429                     my $string_version = ($file{$addr} eq "NameAliases.txt")
2430                                     ? 'at least 6.1 (the later, the better)'
2431                                     : sprintf "%vd", $first_released{$addr};
2432                     push @missing_early_files, <<END;
2433 '$file{$addr}' version $string_version should be copied to '$early{$addr}[1]'.
2434 END
2435                     ;
2436                     return;
2437                 }
2438                 $progress = $early{$addr}[1];
2439                 $progress .= ", substituting for $file{$addr}" if $file{$addr};
2440                 $file{$addr} = $early{$addr}[1];
2441                 $property{$addr} = $early{$addr}[2];
2442
2443                 # Ignore code points not in the version being compiled
2444                 push $each_line_handler{$addr}->@*, \&_exclude_unassigned;
2445
2446                 if (   $v_version lt v2.0        # Hanguls in this release ...
2447                     && defined $early{$addr}[3]) # ... need special treatment
2448                 {
2449                     push $eof_handler{$addr}->@*, \&_fixup_obsolete_hanguls;
2450                 }
2451             }
2452
2453             # And this substitute is valid for all releases.
2454             $first_released{$addr} = v0;
2455         }
2456         else {  # Normal behavior
2457             $progress = $file{$addr};
2458             unshift $early{$addr}->@*, 0; # No substitute
2459         }
2460
2461         my $file = $file{$addr};
2462         $progress_message{$addr} = "Processing $progress"
2463                                             unless $progress_message{$addr};
2464
2465         # A file should be there if it is within the window of versions for
2466         # which Unicode supplies it
2467         if ($withdrawn{$addr} && $withdrawn{$addr} le $v_version) {
2468             $in_this_release{$addr} = 0;
2469             $skip{$addr} = "";
2470         }
2471         else {
2472             $in_this_release{$addr} = $first_released{$addr} le $v_version;
2473
2474             # Check that the file for this object (possibly using a substitute
2475             # for early releases) exists or we have a function alternative
2476             if (   ! $function_instead_of_file
2477                 && ! main::file_exists($file))
2478             {
2479                 # Here there is nothing available for this release.  This is
2480                 # fine if we aren't expecting anything in this release.
2481                 if (! $in_this_release{$addr}) {
2482                     $skip{$addr} = "";  # Don't remark since we expected
2483                                         # nothing and got nothing
2484                 }
2485                 elsif ($optional{$addr}->@*) {
2486
2487                     # Here the file is optional in this release; Use the
2488                     # passed in text to document this case in the pod.
2489                     $skip{$addr} = $pod_message_for_non_existent_optional;
2490                 }
2491                 elsif (   $in_this_release{$addr}
2492                        && ! defined $skip{$addr}
2493                        && defined $file)
2494                 { # Doesn't exist but should.
2495                     $skip{$addr} = "'$file' not found.  Possibly Big problems";
2496                     Carp::my_carp($skip{$addr});
2497                 }
2498             }
2499             elsif ($debug_skip && ! defined $skip{$addr} && ! $non_skip{$addr})
2500             {
2501
2502                 # The file exists; if not skipped for another reason, and we are
2503                 # skipping most everything during debugging builds, use that as
2504                 # the skip reason.
2505                 $skip{$addr} = '$debug_skip is on'
2506             }
2507         }
2508
2509         if (   ! $debug_skip
2510             && $non_skip{$addr}
2511             && ! $required_even_in_debug_skip{$addr}
2512             && $verbosity)
2513         {
2514             print "Warning: " . __PACKAGE__ . " constructor for $file has useless 'non_skip' in it\n";
2515         }
2516
2517         # Here, we have figured out if we will be skipping this file or not.
2518         # If so, we add any single property it defines to any passed in
2519         # optional property list.  These will be dealt with at run time.
2520         if (defined $skip{$addr}) {
2521             if ($property{$addr}) {
2522                 push $optional{$addr}->@*, $property{$addr};
2523             }
2524         } # Otherwise, are going to process the file.
2525         elsif ($property{$addr}) {
2526
2527             # If the file has a property defined in the constructor for it, it
2528             # means that the property is not listed in the file's entries.  So
2529             # add a handler (to the list of line handlers) to insert the
2530             # property name into the lines, to provide a uniform interface to
2531             # the final processing subroutine.
2532             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2533         }
2534         elsif ($properties{$addr}) {
2535
2536             # Similarly, there may be more than one property represented on
2537             # each line, with no clue but the constructor input what those
2538             # might be.  Add a handler for each line in the input so that it
2539             # creates a separate input line for each property in those input
2540             # lines, thus making them suitable to handle generically.
2541
2542             push @{$each_line_handler{$addr}},
2543                  sub {
2544                     my $file = shift;
2545                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2546
2547                     my @fields = split /\s*;\s*/, $_, -1;
2548
2549                     if (@fields - 1 > @{$properties{$addr}}) {
2550                         $file->carp_bad_line('Extra fields');
2551                         $_ = "";
2552                         return;
2553                     }
2554                     my $range = shift @fields;  # 0th element is always the
2555                                                 # range
2556
2557                     # The next fields in the input line correspond
2558                     # respectively to the stored properties.
2559                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2560                         my $property_name = $properties{$addr}[$i];
2561                         next if $property_name eq '<ignored>';
2562                         $file->insert_adjusted_lines(
2563                               "$range; $property_name; $fields[$i]");
2564                     }
2565                     $_ = "";
2566
2567                     return;
2568                 };
2569         }
2570
2571         {   # On non-ascii platforms, we use a special pre-handler
2572             no strict;
2573             no warnings 'once';
2574             *next_line = (main::NON_ASCII_PLATFORM)
2575                          ? *_next_line_with_remapped_range
2576                          : *_next_line;
2577         }
2578
2579         &{$construction_time_handler{$addr}}($self)
2580                                         if $construction_time_handler{$addr};
2581
2582         return $self;
2583     }
2584
2585
2586     use overload
2587         fallback => 0,
2588         qw("") => "_operator_stringify",
2589         "." => \&main::_operator_dot,
2590         ".=" => \&main::_operator_dot_equal,
2591     ;
2592
2593     sub _operator_stringify {
2594         my $self = shift;
2595
2596         return __PACKAGE__ . " object for " . $self->file;
2597     }
2598
2599     sub run {
2600         # Process the input object $self.  This opens and closes the file and
2601         # calls all the handlers for it.  Currently,  this can only be called
2602         # once per file, as it destroy's the EOF handlers
2603
2604         # flag to make sure extracted files are processed early
2605         state $seen_non_extracted_non_age = 0;
2606
2607         my $self = shift;
2608         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2609
2610         my $addr = do { no overloading; pack 'J', $self; };
2611
2612         my $file = $file{$addr};
2613
2614         if (! $file) {
2615             $handle{$addr} = 'pretend_is_open';
2616         }
2617         else {
2618             if ($seen_non_extracted_non_age) {
2619                 if ($file =~ /$EXTRACTED/i) # Some platforms may change the
2620                                             # case of the file's name
2621                 {
2622                     Carp::my_carp_bug(main::join_lines(<<END
2623 $file should be processed just after the 'Prop...Alias' files, and before
2624 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2625 have subtle problems
2626 END
2627                     ));
2628                 }
2629             }
2630             elsif ($EXTRACTED_DIR
2631
2632                     # We only do this check for generic property files
2633                     && $handler{$addr} == \&main::process_generic_property_file
2634
2635                     && $file !~ /$EXTRACTED/i
2636                     && lc($file) ne 'dage.txt')
2637             {
2638                 # We don't set this (by the 'if' above) if we have no
2639                 # extracted directory, so if running on an early version,
2640                 # this test won't work.  Not worth worrying about.
2641                 $seen_non_extracted_non_age = 1;
2642             }
2643
2644             # Mark the file as having being processed, and warn if it
2645             # isn't a file we are expecting.  As we process the files,
2646             # they are deleted from the hash, so any that remain at the
2647             # end of the program are files that we didn't process.
2648             my $fkey = File::Spec->rel2abs($file);
2649             my $exists = delete $potential_files{lc($fkey)};
2650
2651             Carp::my_carp("Was not expecting '$file'.")
2652                                     if $exists && ! $in_this_release{$addr};
2653
2654             # If there is special handling for compiling Unicode releases
2655             # earlier than the first one in which Unicode defines this
2656             # property ...
2657             if ($early{$addr}->@* > 1) {
2658
2659                 # Mark as processed any substitute file that would be used in
2660                 # such a release
2661                 $fkey = File::Spec->rel2abs($early{$addr}[1]);
2662                 delete $potential_files{lc($fkey)};
2663
2664                 # As commented in the constructor code, when using the
2665                 # official property, we still have to allow the publicly
2666                 # inaccessible early name so that the core code which uses it
2667                 # will work regardless.
2668                 if (! $early{$addr}[0] && $early{$addr}->@* > 2) {
2669                     my $early_property_name = $early{$addr}[2];
2670                     if ($property{$addr} ne $early_property_name) {
2671                         main::property_ref($property{$addr})
2672                                             ->add_alias($early_property_name);
2673                     }
2674                 }
2675             }
2676
2677             # We may be skipping this file ...
2678             if (defined $skip{$addr}) {
2679
2680                 # If the file isn't supposed to be in this release, there is
2681                 # nothing to do
2682                 if ($in_this_release{$addr}) {
2683
2684                     # But otherwise, we may print a message
2685                     if ($debug_skip) {
2686                         print STDERR "Skipping input file '$file'",
2687                                      " because '$skip{$addr}'\n";
2688                     }
2689
2690                     # And add it to the list of skipped files, which is later
2691                     # used to make the pod
2692                     $skipped_files{$file} = $skip{$addr};
2693
2694                     # The 'optional' list contains properties that are also to
2695                     # be skipped along with the file.  (There may also be
2696                     # digits which are just placeholders to make sure it isn't
2697                     # an empty list
2698                     foreach my $property ($optional{$addr}->@*) {
2699                         next unless $property =~ /\D/;
2700                         my $prop_object = main::property_ref($property);
2701                         next unless defined $prop_object;
2702                         $prop_object->set_fate($SUPPRESSED, $skip{$addr});
2703                     }
2704                 }
2705
2706                 return;
2707             }
2708
2709             # Here, we are going to process the file.  Open it, converting the
2710             # slashes used in this program into the proper form for the OS
2711             my $file_handle;
2712             if (not open $file_handle, "<", $file) {
2713                 Carp::my_carp("Can't open $file.  Skipping: $!");
2714                 return;
2715             }
2716             $handle{$addr} = $file_handle; # Cache the open file handle
2717
2718             # If possible, make sure that the file is the correct version.
2719             # (This data isn't available on early Unicode releases or in
2720             # UnicodeData.txt.)  We don't do this check if we are using a
2721             # substitute file instead of the official one (though the code
2722             # could be extended to do so).
2723             if ($in_this_release{$addr}
2724                 && ! $early{$addr}[0]
2725                 && lc($file) ne 'unicodedata.txt')
2726             {
2727                 if ($file !~ /^Unihan/i) {
2728
2729                     # The non-Unihan files started getting version numbers in
2730                     # 3.2, but some files in 4.0 are unchanged from 3.2, and
2731                     # marked as 3.2.  4.0.1 is the first version where there
2732                     # are no files marked as being from less than 4.0, though
2733                     # some are marked as 4.0.  In versions after that, the
2734                     # numbers are correct.
2735                     if ($v_version ge v4.0.1) {
2736                         $_ = <$file_handle>;    # The version number is in the
2737                                                 # very first line
2738                         if ($_ !~ / - $string_version \. /x) {
2739                             chomp;
2740                             $_ =~ s/^#\s*//;
2741
2742                             # 4.0.1 had some valid files that weren't updated.
2743                             if (! ($v_version eq v4.0.1 && $_ =~ /4\.0\.0/)) {
2744                                 die Carp::my_carp("File '$file' is version "
2745                                                 . "'$_'.  It should be "
2746                                                 . "version $string_version");
2747                             }
2748                         }
2749                     }
2750                 }
2751                 elsif ($v_version ge v6.0.0) { # Unihan
2752
2753                     # Unihan files didn't get accurate version numbers until
2754                     # 6.0.  The version is somewhere in the first comment
2755                     # block
2756                     while (<$file_handle>) {
2757                         if ($_ !~ /^#/) {
2758                             Carp::my_carp_bug("Could not find the expected "
2759                                             . "version info in file '$file'");
2760                             last;
2761                         }
2762                         chomp;
2763                         $_ =~ s/^#\s*//;
2764                         next if $_ !~ / version: /x;
2765                         last if $_ =~ /$string_version/;
2766                         die Carp::my_carp("File '$file' is version "
2767                                         . "'$_'.  It should be "
2768                                         . "version $string_version");
2769                     }
2770                 }
2771             }
2772         }
2773
2774         print "$progress_message{$addr}\n" if $verbosity >= $PROGRESS;
2775
2776         # Call any special handler for before the file.
2777         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2778
2779         # Then the main handler
2780         &{$handler{$addr}}($self);
2781
2782         # Then any special post-file handler.
2783         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2784
2785         # If any errors have been accumulated, output the counts (as the first
2786         # error message in each class was output when it was encountered).
2787         if ($errors{$addr}) {
2788             my $total = 0;
2789             my $types = 0;
2790             foreach my $error (keys %{$errors{$addr}}) {
2791                 $total += $errors{$addr}->{$error};
2792                 delete $errors{$addr}->{$error};
2793                 $types++;
2794             }
2795             if ($total > 1) {
2796                 my $message
2797                         = "A total of $total lines had errors in $file.  ";
2798
2799                 $message .= ($types == 1)
2800                             ? '(Only the first one was displayed.)'
2801                             : '(Only the first of each type was displayed.)';
2802                 Carp::my_carp($message);
2803             }
2804         }
2805
2806         if (@{$missings{$addr}}) {
2807             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2808         }
2809
2810         # If a real file handle, close it.
2811         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2812                                                         ref $handle{$addr};
2813         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2814                                # the file, as opposed to undef
2815         return;
2816     }
2817
2818     sub _next_line {
2819         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2820         # if such a line exists.  'logical' means that any lines that have
2821         # been added via insert_lines() will be returned in $_ before the file
2822         # is read again.
2823
2824         my $self = shift;
2825         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2826
2827         my $addr = do { no overloading; pack 'J', $self; };
2828
2829         # Here the file is open (or if the handle is not a ref, is an open
2830         # 'virtual' file).  Get the next line; any inserted lines get priority
2831         # over the file itself.
2832         my $adjusted;
2833
2834         LINE:
2835         while (1) { # Loop until find non-comment, non-empty line
2836             #local $to_trace = 1 if main::DEBUG;
2837             my $inserted_ref = shift @{$added_lines{$addr}};
2838             if (defined $inserted_ref) {
2839                 ($adjusted, $_) = @{$inserted_ref};
2840                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2841                 return 1 if $adjusted;
2842             }
2843             else {
2844                 last if ! ref $handle{$addr}; # Don't read unless is real file
2845                 last if ! defined ($_ = readline $handle{$addr});
2846             }
2847             chomp;
2848             trace $_ if main::DEBUG && $to_trace;
2849
2850             # See if this line is the comment line that defines what property
2851             # value that code points that are not listed in the file should
2852             # have.  The format or existence of these lines is not guaranteed
2853             # by Unicode since they are comments, but the documentation says
2854             # that this was added for machine-readability, so probably won't
2855             # change.  This works starting in Unicode Version 5.0.  They look
2856             # like:
2857             #
2858             # @missing: 0000..10FFFF; Not_Reordered
2859             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2860             # @missing: 0000..10FFFF; ; NaN
2861             #
2862             # Save the line for a later get_missings() call.
2863             if (/$missing_defaults_prefix/) {
2864                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2865                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2866                 }
2867                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2868                     my @defaults = split /\s* ; \s*/x, $_;
2869
2870                     # The first field is the @missing, which ends in a
2871                     # semi-colon, so can safely shift.
2872                     shift @defaults;
2873
2874                     # Some of these lines may have empty field placeholders
2875                     # which get in the way.  An example is:
2876                     # @missing: 0000..10FFFF; ; NaN
2877                     # Remove them.  Process starting from the top so the
2878                     # splice doesn't affect things still to be looked at.
2879                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2880                         next if $defaults[$i] ne "";
2881                         splice @defaults, $i, 1;
2882                     }
2883
2884                     # What's left should be just the property (maybe) and the
2885                     # default.  Having only one element means it doesn't have
2886                     # the property.
2887                     my $default;
2888                     my $property;
2889                     if (@defaults >= 1) {
2890                         if (@defaults == 1) {
2891                             $default = $defaults[0];
2892                         }
2893                         else {
2894                             $property = $defaults[0];
2895                             $default = $defaults[1];
2896                         }
2897                     }
2898
2899                     if (@defaults < 1
2900                         || @defaults > 2
2901                         || ($default =~ /^</
2902                             && $default !~ /^<code *point>$/i
2903                             && $default !~ /^<none>$/i
2904                             && $default !~ /^<script>$/i))
2905                     {
2906                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2907                     }
2908                     else {
2909
2910                         # If the property is missing from the line, it should
2911                         # be the one for the whole file
2912                         $property = $property{$addr} if ! defined $property;
2913
2914                         # Change <none> to the null string, which is what it
2915                         # really means.  If the default is the code point
2916                         # itself, set it to <code point>, which is what
2917                         # Unicode uses (but sometimes they've forgotten the
2918                         # space)
2919                         if ($default =~ /^<none>$/i) {
2920                             $default = "";
2921                         }
2922                         elsif ($default =~ /^<code *point>$/i) {
2923                             $default = $CODE_POINT;
2924                         }
2925                         elsif ($default =~ /^<script>$/i) {
2926
2927                             # Special case this one.  Currently is from
2928                             # ScriptExtensions.txt, and means for all unlisted
2929                             # code points, use their Script property values.
2930                             # For the code points not listed in that file, the
2931                             # default value is 'Unknown'.
2932                             $default = "Unknown";
2933                         }
2934
2935                         # Store them as a sub-arrays with both components.
2936                         push @{$missings{$addr}}, [ $default, $property ];
2937                     }
2938                 }
2939
2940                 # There is nothing for the caller to process on this comment
2941                 # line.
2942                 next;
2943             }
2944
2945             # Remove comments and trailing space, and skip this line if the
2946             # result is empty
2947             s/#.*//;
2948             s/\s+$//;
2949             next if /^$/;
2950
2951             # Call any handlers for this line, and skip further processing of
2952             # the line if the handler sets the line to null.
2953             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2954                 &{$sub_ref}($self);
2955                 next LINE if /^$/;
2956             }
2957
2958             # Here the line is ok.  return success.
2959             return 1;
2960         } # End of looping through lines.
2961
2962         # If there are EOF handlers, call each (only once) and if it generates
2963         # more lines to process go back in the loop to handle them.
2964         while ($eof_handler{$addr}->@*) {
2965             &{$eof_handler{$addr}[0]}($self);
2966             shift $eof_handler{$addr}->@*;   # Currently only get one shot at it.
2967             goto LINE if $added_lines{$addr};
2968         }
2969
2970         # Return failure -- no more lines.
2971         return 0;
2972
2973     }
2974
2975     sub _next_line_with_remapped_range {
2976         my $self = shift;
2977         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2978
2979         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
2980         # to be the next logical input line, if any.  Returns non-zero if such
2981         # a line exists.  'logical' means that any lines that have been added
2982         # via insert_lines() will be returned in $_ before the file is read
2983         # again.
2984         #
2985         # The difference from _next_line() is that this remaps the Unicode
2986         # code points in the input to those of the native platform.  Each
2987         # input line contains a single code point, or a single contiguous
2988         # range of them  This routine splits each range into its individual
2989         # code points and caches them.  It returns the cached values,
2990         # translated into their native equivalents, one at a time, for each
2991         # call, before reading the next line.  Since native values can only be
2992         # a single byte wide, no translation is needed for code points above
2993         # 0xFF, and ranges that are entirely above that number are not split.
2994         # If an input line contains the range 254-1000, it would be split into
2995         # three elements: 254, 255, and 256-1000.  (The downstream table
2996         # insertion code will sort and coalesce the individual code points
2997         # into appropriate ranges.)
2998
2999         my $addr = do { no overloading; pack 'J', $self; };
3000
3001         while (1) {
3002
3003             # Look in cache before reading the next line.  Return any cached
3004             # value, translated
3005             my $inserted = shift @{$remapped_lines{$addr}};
3006             if (defined $inserted) {
3007                 trace $inserted if main::DEBUG && $to_trace;
3008                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
3009                 trace $_ if main::DEBUG && $to_trace;
3010                 return 1;
3011             }
3012
3013             # Get the next line.
3014             return 0 unless _next_line($self);
3015
3016             # If there is a special handler for it, return the line,
3017             # untranslated.  This should happen only for files that are
3018             # special, not being code-point related, such as property names.
3019             return 1 if $handler{$addr}
3020                                     != \&main::process_generic_property_file;
3021
3022             my ($range, $property_name, $map, @remainder)
3023                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3024
3025             if (@remainder
3026                 || ! defined $property_name
3027                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3028             {
3029                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
3030             }
3031
3032             my $low = hex $1;
3033             my $high = (defined $2) ? hex $2 : $low;
3034
3035             # If the input maps the range to another code point, remap the
3036             # target if it is between 0 and 255.
3037             my $tail;
3038             if (defined $map) {
3039                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
3040                 $tail = "$property_name; $map";
3041                 $_ = "$range; $tail";
3042             }
3043             else {
3044                 $tail = $property_name;
3045             }
3046
3047             # If entire range is above 255, just return it, unchanged (except
3048             # any mapped-to code point, already changed above)
3049             return 1 if $low > 255;
3050
3051             # Cache an entry for every code point < 255.  For those in the
3052             # range above 255, return a dummy entry for just that portion of
3053             # the range.  Note that this will be out-of-order, but that is not
3054             # a problem.
3055             foreach my $code_point ($low .. $high) {
3056                 if ($code_point > 255) {
3057                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
3058                     return 1;
3059                 }
3060                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
3061             }
3062         } # End of looping through lines.
3063
3064         # NOTREACHED
3065     }
3066
3067 #   Not currently used, not fully tested.
3068 #    sub peek {
3069 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
3070 #        # record.  Not callable from an each_line_handler(), nor does it call
3071 #        # an each_line_handler() on the line.
3072 #
3073 #        my $self = shift;
3074 #        my $addr = do { no overloading; pack 'J', $self; };
3075 #
3076 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
3077 #            my ($adjusted, $line) = @{$inserted_ref};
3078 #            next if $adjusted;
3079 #
3080 #            # Remove comments and trailing space, and return a non-empty
3081 #            # resulting line
3082 #            $line =~ s/#.*//;
3083 #            $line =~ s/\s+$//;
3084 #            return $line if $line ne "";
3085 #        }
3086 #
3087 #        return if ! ref $handle{$addr}; # Don't read unless is real file
3088 #        while (1) { # Loop until find non-comment, non-empty line
3089 #            local $to_trace = 1 if main::DEBUG;
3090 #            trace $_ if main::DEBUG && $to_trace;
3091 #            return if ! defined (my $line = readline $handle{$addr});
3092 #            chomp $line;
3093 #            push @{$added_lines{$addr}}, [ 0, $line ];
3094 #
3095 #            $line =~ s/#.*//;
3096 #            $line =~ s/\s+$//;
3097 #            return $line if $line ne "";
3098 #        }
3099 #
3100 #        return;
3101 #    }
3102
3103
3104     sub insert_lines {
3105         # Lines can be inserted so that it looks like they were in the input
3106         # file at the place it was when this routine is called.  See also
3107         # insert_adjusted_lines().  Lines inserted via this routine go through
3108         # any each_line_handler()
3109
3110         my $self = shift;
3111
3112         # Each inserted line is an array, with the first element being 0 to
3113         # indicate that this line hasn't been adjusted, and needs to be
3114         # processed.
3115         no overloading;
3116         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
3117         return;
3118     }
3119
3120     sub insert_adjusted_lines {
3121         # Lines can be inserted so that it looks like they were in the input
3122         # file at the place it was when this routine is called.  See also
3123         # insert_lines().  Lines inserted via this routine are already fully
3124         # adjusted, ready to be processed; each_line_handler()s handlers will
3125         # not be called.  This means this is not a completely general
3126         # facility, as only the last each_line_handler on the stack should
3127         # call this.  It could be made more general, by passing to each of the
3128         # line_handlers their position on the stack, which they would pass on
3129         # to this routine, and that would replace the boolean first element in
3130         # the anonymous array pushed here, so that the next_line routine could
3131         # use that to call only those handlers whose index is after it on the
3132         # stack.  But this is overkill for what is needed now.
3133
3134         my $self = shift;
3135         trace $_[0] if main::DEBUG && $to_trace;
3136
3137         # Each inserted line is an array, with the first element being 1 to
3138         # indicate that this line has been adjusted
3139         no overloading;
3140         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
3141         return;
3142     }
3143
3144     sub get_missings {
3145         # Returns the stored up @missings lines' values, and clears the list.
3146         # The values are in an array, consisting of the default in the first
3147         # element, and the property in the 2nd.  However, since these lines
3148         # can be stacked up, the return is an array of all these arrays.
3149
3150         my $self = shift;
3151         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3152
3153         my $addr = do { no overloading; pack 'J', $self; };
3154
3155         # If not accepting a list return, just return the first one.
3156         return shift @{$missings{$addr}} unless wantarray;
3157
3158         my @return = @{$missings{$addr}};
3159         undef @{$missings{$addr}};
3160         return @return;
3161     }
3162
3163     sub _exclude_unassigned {
3164
3165         # Takes the range in $_ and excludes code points that aren't assigned
3166         # in this release
3167
3168         state $skip_inserted_count = 0;
3169
3170         # Ignore recursive calls.
3171         if ($skip_inserted_count) {
3172             $skip_inserted_count--;
3173             return;
3174         }
3175
3176         # Find what code points are assigned in this release
3177         main::calculate_Assigned() if ! defined $Assigned;
3178
3179         my $self = shift;
3180         my $addr = do { no overloading; pack 'J', $self; };
3181         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3182
3183         my ($range, @remainder)
3184             = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3185
3186         # Examine the range.
3187         if ($range =~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3188         {
3189             my $low = hex $1;
3190             my $high = (defined $2) ? hex $2 : $low;
3191
3192             # Split the range into subranges of just those code points in it
3193             # that are assigned.
3194             my @ranges = (Range_List->new(Initialize
3195                               => Range->new($low, $high)) & $Assigned)->ranges;
3196
3197             # Do nothing if nothing in the original range is assigned in this
3198             # release; handle normally if everything is in this release.
3199             if (! @ranges) {
3200                 $_ = "";
3201             }
3202             elsif (@ranges != 1) {
3203
3204                 # Here, some code points in the original range aren't in this
3205                 # release; @ranges gives the ones that are.  Create fake input
3206                 # lines for each of the ranges, and set things up so that when
3207                 # this routine is called on that fake input, it will do
3208                 # nothing.
3209                 $skip_inserted_count = @ranges;
3210                 my $remainder = join ";", @remainder;
3211                 for my $range (@ranges) {
3212                     $self->insert_lines(sprintf("%04X..%04X;%s",
3213                                     $range->start, $range->end, $remainder));
3214                 }
3215                 $_ = "";    # The original range is now defunct.
3216             }
3217         }
3218
3219         return;
3220     }
3221
3222     sub _fixup_obsolete_hanguls {
3223
3224         # This is called only when compiling Unicode version 1.  All Unicode
3225         # data for subsequent releases assumes that the code points that were
3226         # Hangul syllables in this release only are something else, so if
3227         # using such data, we have to override it
3228
3229         my $self = shift;
3230         my $addr = do { no overloading; pack 'J', $self; };
3231         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3232
3233         my $object = main::property_ref($property{$addr});
3234         $object->add_map(0x3400, 0x4DFF,
3235                          $early{$addr}[3],  # Passed-in value for these
3236                          Replace => $UNCONDITIONALLY);
3237     }
3238
3239     sub _insert_property_into_line {
3240         # Add a property field to $_, if this file requires it.
3241
3242         my $self = shift;
3243         my $addr = do { no overloading; pack 'J', $self; };
3244         my $property = $property{$addr};
3245         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3246
3247         $_ =~ s/(;|$)/; $property$1/;
3248         return;
3249     }
3250
3251     sub carp_bad_line {
3252         # Output consistent error messages, using either a generic one, or the
3253         # one given by the optional parameter.  To avoid gazillions of the
3254         # same message in case the syntax of a  file is way off, this routine
3255         # only outputs the first instance of each message, incrementing a
3256         # count so the totals can be output at the end of the file.
3257
3258         my $self = shift;
3259         my $message = shift;
3260         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3261
3262         my $addr = do { no overloading; pack 'J', $self; };
3263
3264         $message = 'Unexpected line' unless $message;
3265
3266         # No trailing punctuation so as to fit with our addenda.
3267         $message =~ s/[.:;,]$//;
3268
3269         # If haven't seen this exact message before, output it now.  Otherwise
3270         # increment the count of how many times it has occurred
3271         unless ($errors{$addr}->{$message}) {
3272             Carp::my_carp("$message in '$_' in "
3273                             . $file{$addr}
3274                             . " at line $..  Skipping this line;");
3275             $errors{$addr}->{$message} = 1;
3276         }
3277         else {
3278             $errors{$addr}->{$message}++;
3279         }
3280
3281         # Clear the line to prevent any further (meaningful) processing of it.
3282         $_ = "";
3283
3284         return;
3285     }
3286 } # End closure
3287
3288 package Multi_Default;
3289
3290 # Certain properties in early versions of Unicode had more than one possible
3291 # default for code points missing from the files.  In these cases, one
3292 # default applies to everything left over after all the others are applied,
3293 # and for each of the others, there is a description of which class of code
3294 # points applies to it.  This object helps implement this by storing the
3295 # defaults, and for all but that final default, an eval string that generates
3296 # the class that it applies to.
3297
3298
3299 {   # Closure
3300
3301     main::setup_package();
3302
3303     my %class_defaults;
3304     # The defaults structure for the classes
3305     main::set_access('class_defaults', \%class_defaults);
3306
3307     my %other_default;
3308     # The default that applies to everything left over.
3309     main::set_access('other_default', \%other_default, 'r');
3310
3311
3312     sub new {
3313         # The constructor is called with default => eval pairs, terminated by
3314         # the left-over default. e.g.
3315         # Multi_Default->new(
3316         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3317         #               -  0x200D',
3318         #        'R' => 'some other expression that evaluates to code points',
3319         #        .
3320         #        .
3321         #        .
3322         #        'U'));
3323         # It is best to leave the final value be the one that matches the
3324         # above-Unicode code points.
3325
3326         my $class = shift;
3327
3328         my $self = bless \do{my $anonymous_scalar}, $class;
3329         my $addr = do { no overloading; pack 'J', $self; };
3330
3331         while (@_ > 1) {
3332             my $default = shift;
3333             my $eval = shift;
3334             $class_defaults{$addr}->{$default} = $eval;
3335         }
3336
3337         $other_default{$addr} = shift;
3338
3339         return $self;
3340     }
3341
3342     sub get_next_defaults {
3343         # Iterates and returns the next class of defaults.
3344         my $self = shift;
3345         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3346
3347         my $addr = do { no overloading; pack 'J', $self; };
3348
3349         return each %{$class_defaults{$addr}};
3350     }
3351 }
3352
3353 package Alias;
3354
3355 # An alias is one of the names that a table goes by.  This class defines them
3356 # including some attributes.  Everything is currently setup in the
3357 # constructor.
3358
3359
3360 {   # Closure
3361
3362     main::setup_package();
3363
3364     my %name;
3365     main::set_access('name', \%name, 'r');
3366
3367     my %loose_match;
3368     # Should this name match loosely or not.
3369     main::set_access('loose_match', \%loose_match, 'r');
3370
3371     my %make_re_pod_entry;
3372     # Some aliases should not get their own entries in the re section of the
3373     # pod, because they are covered by a wild-card, and some we want to
3374     # discourage use of.  Binary
3375     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3376
3377     my %ucd;
3378     # Is this documented to be accessible via Unicode::UCD
3379     main::set_access('ucd', \%ucd, 'r', 's');
3380
3381     my %status;
3382     # Aliases have a status, like deprecated, or even suppressed (which means
3383     # they don't appear in documentation).  Enum
3384     main::set_access('status', \%status, 'r');
3385
3386     my %ok_as_filename;
3387     # Similarly, some aliases should not be considered as usable ones for
3388     # external use, such as file names, or we don't want documentation to
3389     # recommend them.  Boolean
3390     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3391
3392     sub new {
3393         my $class = shift;
3394
3395         my $self = bless \do { my $anonymous_scalar }, $class;
3396         my $addr = do { no overloading; pack 'J', $self; };
3397
3398         $name{$addr} = shift;
3399         $loose_match{$addr} = shift;
3400         $make_re_pod_entry{$addr} = shift;
3401         $ok_as_filename{$addr} = shift;
3402         $status{$addr} = shift;
3403         $ucd{$addr} = shift;
3404
3405         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3406
3407         # Null names are never ok externally
3408         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3409
3410         return $self;
3411     }
3412 }
3413
3414 package Range;
3415
3416 # A range is the basic unit for storing code points, and is described in the
3417 # comments at the beginning of the program.  Each range has a starting code
3418 # point; an ending code point (not less than the starting one); a value
3419 # that applies to every code point in between the two end-points, inclusive;
3420 # and an enum type that applies to the value.  The type is for the user's
3421 # convenience, and has no meaning here, except that a non-zero type is
3422 # considered to not obey the normal Unicode rules for having standard forms.
3423 #
3424 # The same structure is used for both map and match tables, even though in the
3425 # latter, the value (and hence type) is irrelevant and could be used as a
3426 # comment.  In map tables, the value is what all the code points in the range
3427 # map to.  Type 0 values have the standardized version of the value stored as
3428 # well, so as to not have to recalculate it a lot.
3429
3430 sub trace { return main::trace(@_); }
3431
3432 {   # Closure
3433
3434     main::setup_package();
3435
3436     my %start;
3437     main::set_access('start', \%start, 'r', 's');
3438
3439     my %end;
3440     main::set_access('end', \%end, 'r', 's');
3441
3442     my %value;
3443     main::set_access('value', \%value, 'r');
3444
3445     my %type;
3446     main::set_access('type', \%type, 'r');
3447
3448     my %standard_form;
3449     # The value in internal standard form.  Defined only if the type is 0.
3450     main::set_access('standard_form', \%standard_form);
3451
3452     # Note that if these fields change, the dump() method should as well
3453
3454     sub new {
3455         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3456         my $class = shift;
3457
3458         my $self = bless \do { my $anonymous_scalar }, $class;
3459         my $addr = do { no overloading; pack 'J', $self; };
3460
3461         $start{$addr} = shift;
3462         $end{$addr} = shift;
3463
3464         my %args = @_;
3465
3466         my $value = delete $args{'Value'};  # Can be 0
3467         $value = "" unless defined $value;
3468         $value{$addr} = $value;
3469
3470         $type{$addr} = delete $args{'Type'} || 0;
3471
3472         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3473
3474         return $self;
3475     }
3476
3477     use overload
3478         fallback => 0,
3479         qw("") => "_operator_stringify",
3480         "." => \&main::_operator_dot,
3481         ".=" => \&main::_operator_dot_equal,
3482     ;
3483
3484     sub _operator_stringify {
3485         my $self = shift;
3486         my $addr = do { no overloading; pack 'J', $self; };
3487
3488         # Output it like '0041..0065 (value)'
3489         my $return = sprintf("%04X", $start{$addr})
3490                         .  '..'
3491                         . sprintf("%04X", $end{$addr});
3492         my $value = $value{$addr};
3493         my $type = $type{$addr};
3494         $return .= ' (';
3495         $return .= "$value";
3496         $return .= ", Type=$type" if $type != 0;
3497         $return .= ')';
3498
3499         return $return;
3500     }
3501
3502     sub standard_form {
3503         # Calculate the standard form only if needed, and cache the result.
3504         # The standard form is the value itself if the type is special.
3505         # This represents a considerable CPU and memory saving - at the time
3506         # of writing there are 368676 non-special objects, but the standard
3507         # form is only requested for 22047 of them - ie about 6%.
3508
3509         my $self = shift;
3510         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3511
3512         my $addr = do { no overloading; pack 'J', $self; };
3513
3514         return $standard_form{$addr} if defined $standard_form{$addr};
3515
3516         my $value = $value{$addr};
3517         return $value if $type{$addr};
3518         return $standard_form{$addr} = main::standardize($value);
3519     }
3520
3521     sub dump {
3522         # Human, not machine readable.  For machine readable, comment out this
3523         # entire routine and let the standard one take effect.
3524         my $self = shift;
3525         my $indent = shift;
3526         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3527
3528         my $addr = do { no overloading; pack 'J', $self; };
3529
3530         my $return = $indent
3531                     . sprintf("%04X", $start{$addr})
3532                     . '..'
3533                     . sprintf("%04X", $end{$addr})
3534                     . " '$value{$addr}';";
3535         if (! defined $standard_form{$addr}) {
3536             $return .= "(type=$type{$addr})";
3537         }
3538         elsif ($standard_form{$addr} ne $value{$addr}) {
3539             $return .= "(standard '$standard_form{$addr}')";
3540         }
3541         return $return;
3542     }
3543 } # End closure
3544
3545 package _Range_List_Base;
3546
3547 # Base class for range lists.  A range list is simply an ordered list of
3548 # ranges, so that the ranges with the lowest starting numbers are first in it.
3549 #
3550 # When a new range is added that is adjacent to an existing range that has the
3551 # same value and type, it merges with it to form a larger range.
3552 #
3553 # Ranges generally do not overlap, except that there can be multiple entries
3554 # of single code point ranges.  This is because of NameAliases.txt.
3555 #
3556 # In this program, there is a standard value such that if two different
3557 # values, have the same standard value, they are considered equivalent.  This
3558 # value was chosen so that it gives correct results on Unicode data
3559
3560 # There are a number of methods to manipulate range lists, and some operators
3561 # are overloaded to handle them.
3562
3563 sub trace { return main::trace(@_); }
3564
3565 { # Closure
3566
3567     our $addr;
3568
3569     # Max is initialized to a negative value that isn't adjacent to 0, for
3570     # simpler tests
3571     my $max_init = -2;
3572
3573     main::setup_package();
3574
3575     my %ranges;
3576     # The list of ranges
3577     main::set_access('ranges', \%ranges, 'readable_array');
3578
3579     my %max;
3580     # The highest code point in the list.  This was originally a method, but
3581     # actual measurements said it was used a lot.
3582     main::set_access('max', \%max, 'r');
3583
3584     my %each_range_iterator;
3585     # Iterator position for each_range()
3586     main::set_access('each_range_iterator', \%each_range_iterator);
3587
3588     my %owner_name_of;
3589     # Name of parent this is attached to, if any.  Solely for better error
3590     # messages.
3591     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3592
3593     my %_search_ranges_cache;
3594     # A cache of the previous result from _search_ranges(), for better
3595     # performance
3596     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3597
3598     sub new {
3599         my $class = shift;
3600         my %args = @_;
3601
3602         # Optional initialization data for the range list.
3603         my $initialize = delete $args{'Initialize'};
3604
3605         my $self;
3606
3607         # Use _union() to initialize.  _union() returns an object of this
3608         # class, which means that it will call this constructor recursively.
3609         # But it won't have this $initialize parameter so that it won't
3610         # infinitely loop on this.
3611         return _union($class, $initialize, %args) if defined $initialize;
3612
3613         $self = bless \do { my $anonymous_scalar }, $class;
3614         my $addr = do { no overloading; pack 'J', $self; };
3615
3616         # Optional parent object, only for debug info.
3617         $owner_name_of{$addr} = delete $args{'Owner'};
3618         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3619
3620         # Stringify, in case it is an object.
3621         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3622
3623         # This is used only for error messages, and so a colon is added
3624         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3625
3626         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3627
3628         $max{$addr} = $max_init;
3629
3630         $_search_ranges_cache{$addr} = 0;
3631         $ranges{$addr} = [];
3632
3633         return $self;
3634     }
3635
3636     use overload
3637         fallback => 0,
3638         qw("") => "_operator_stringify",
3639         "." => \&main::_operator_dot,
3640         ".=" => \&main::_operator_dot_equal,
3641     ;
3642
3643     sub _operator_stringify {
3644         my $self = shift;
3645         my $addr = do { no overloading; pack 'J', $self; };
3646
3647         return "Range_List attached to '$owner_name_of{$addr}'"
3648                                                 if $owner_name_of{$addr};
3649         return "anonymous Range_List " . \$self;
3650     }
3651
3652     sub _union {
3653         # Returns the union of the input code points.  It can be called as
3654         # either a constructor or a method.  If called as a method, the result
3655         # will be a new() instance of the calling object, containing the union
3656         # of that object with the other parameter's code points;  if called as
3657         # a constructor, the first parameter gives the class that the new object
3658         # should be, and the second parameter gives the code points to go into
3659         # it.
3660         # In either case, there are two parameters looked at by this routine;
3661         # any additional parameters are passed to the new() constructor.
3662         #
3663         # The code points can come in the form of some object that contains
3664         # ranges, and has a conventionally named method to access them; or
3665         # they can be an array of individual code points (as integers); or
3666         # just a single code point.
3667         #
3668         # If they are ranges, this routine doesn't make any effort to preserve
3669         # the range values and types of one input over the other.  Therefore
3670         # this base class should not allow _union to be called from other than
3671         # initialization code, so as to prevent two tables from being added
3672         # together where the range values matter.  The general form of this
3673         # routine therefore belongs in a derived class, but it was moved here
3674         # to avoid duplication of code.  The failure to overload this in this
3675         # class keeps it safe.
3676         #
3677         # It does make the effort during initialization to accept tables with
3678         # multiple values for the same code point, and to preserve the order
3679         # of these.  If there is only one input range or range set, it doesn't
3680         # sort (as it should already be sorted to the desired order), and will
3681         # accept multiple values per code point.  Otherwise it will merge
3682         # multiple values into a single one.
3683
3684         my $self;
3685         my @args;   # Arguments to pass to the constructor
3686
3687         my $class = shift;
3688
3689         # If a method call, will start the union with the object itself, and
3690         # the class of the new object will be the same as self.
3691         if (ref $class) {
3692             $self = $class;
3693             $class = ref $self;
3694             push @args, $self;
3695         }
3696
3697         # Add the other required parameter.
3698         push @args, shift;
3699         # Rest of parameters are passed on to the constructor
3700
3701         # Accumulate all records from both lists.
3702         my @records;
3703         my $input_count = 0;
3704         for my $arg (@args) {
3705             #local $to_trace = 0 if main::DEBUG;
3706             trace "argument = $arg" if main::DEBUG && $to_trace;
3707             if (! defined $arg) {
3708                 my $message = "";
3709                 if (defined $self) {
3710                     no overloading;
3711                     $message .= $owner_name_of{pack 'J', $self};
3712                 }
3713                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3714                 return;
3715             }
3716
3717             $arg = [ $arg ] if ! ref $arg;
3718             my $type = ref $arg;
3719             if ($type eq 'ARRAY') {
3720                 foreach my $element (@$arg) {
3721                     push @records, Range->new($element, $element);
3722                     $input_count++;
3723                 }
3724             }
3725             elsif ($arg->isa('Range')) {
3726                 push @records, $arg;
3727                 $input_count++;
3728             }
3729             elsif ($arg->can('ranges')) {
3730                 push @records, $arg->ranges;
3731                 $input_count++;
3732             }
3733             else {
3734                 my $message = "";
3735                 if (defined $self) {
3736                     no overloading;
3737                     $message .= $owner_name_of{pack 'J', $self};
3738                 }
3739                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3740                 return;
3741             }
3742         }
3743
3744         # Sort with the range containing the lowest ordinal first, but if
3745         # two ranges start at the same code point, sort with the bigger range
3746         # of the two first, because it takes fewer cycles.
3747         if ($input_count > 1) {
3748             @records = sort { ($a->start <=> $b->start)
3749                                       or
3750                                     # if b is shorter than a, b->end will be
3751                                     # less than a->end, and we want to select
3752                                     # a, so want to return -1
3753                                     ($b->end <=> $a->end)
3754                                    } @records;
3755         }
3756
3757         my $new = $class->new(@_);
3758
3759         # Fold in records so long as they add new information.
3760         for my $set (@records) {
3761             my $start = $set->start;
3762             my $end   = $set->end;
3763             my $value = $set->value;
3764             my $type  = $set->type;
3765             if ($start > $new->max) {
3766                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3767             }
3768             elsif ($end > $new->max) {
3769                 $new->_add_delete('+', $new->max +1, $end, $value,
3770                                                                 Type => $type);
3771             }
3772             elsif ($input_count == 1) {
3773                 # Here, overlaps existing range, but is from a single input,
3774                 # so preserve the multiple values from that input.
3775                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3776                                                 Replace => $MULTIPLE_AFTER);
3777             }
3778         }
3779
3780         return $new;
3781     }
3782
3783     sub range_count {        # Return the number of ranges in the range list
3784         my $self = shift;
3785         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3786
3787         no overloading;
3788         return scalar @{$ranges{pack 'J', $self}};
3789     }
3790
3791     sub min {
3792         # Returns the minimum code point currently in the range list, or if
3793         # the range list is empty, 2 beyond the max possible.  This is a
3794         # method because used so rarely, that not worth saving between calls,
3795         # and having to worry about changing it as ranges are added and
3796         # deleted.
3797
3798         my $self = shift;
3799         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3800
3801         my $addr = do { no overloading; pack 'J', $self; };
3802
3803         # If the range list is empty, return a large value that isn't adjacent
3804         # to any that could be in the range list, for simpler tests
3805         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3806         return $ranges{$addr}->[0]->start;
3807     }
3808
3809     sub contains {
3810         # Boolean: Is argument in the range list?  If so returns $i such that:
3811         #   range[$i]->end < $codepoint <= range[$i+1]->end
3812         # which is one beyond what you want; this is so that the 0th range
3813         # doesn't return false
3814         my $self = shift;
3815         my $codepoint = shift;
3816         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3817
3818         my $i = $self->_search_ranges($codepoint);
3819         return 0 unless defined $i;
3820
3821         # The search returns $i, such that
3822         #   range[$i-1]->end < $codepoint <= range[$i]->end
3823         # So is in the table if and only iff it is at least the start position
3824         # of range $i.
3825         no overloading;
3826         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3827         return $i + 1;
3828     }
3829
3830     sub containing_range {
3831         # Returns the range object that contains the code point, undef if none
3832
3833         my $self = shift;
3834         my $codepoint = shift;
3835         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3836
3837         my $i = $self->contains($codepoint);
3838         return unless $i;
3839
3840         # contains() returns 1 beyond where we should look
3841         no overloading;
3842         return $ranges{pack 'J', $self}->[$i-1];
3843     }
3844
3845     sub value_of {
3846         # Returns the value associated with the code point, undef if none
3847
3848         my $self = shift;
3849         my $codepoint = shift;
3850         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3851
3852         my $range = $self->containing_range($codepoint);
3853         return unless defined $range;
3854
3855         return $range->value;
3856     }
3857
3858     sub type_of {
3859         # Returns the type of the range containing the code point, undef if
3860         # the code point is not in the table
3861
3862         my $self = shift;
3863         my $codepoint = shift;
3864         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3865
3866         my $range = $self->containing_range($codepoint);
3867         return unless defined $range;
3868
3869         return $range->type;
3870     }
3871
3872     sub _search_ranges {
3873         # Find the range in the list which contains a code point, or where it
3874         # should go if were to add it.  That is, it returns $i, such that:
3875         #   range[$i-1]->end < $codepoint <= range[$i]->end
3876         # Returns undef if no such $i is possible (e.g. at end of table), or
3877         # if there is an error.
3878
3879         my $self = shift;
3880         my $code_point = shift;
3881         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3882
3883         my $addr = do { no overloading; pack 'J', $self; };
3884
3885         return if $code_point > $max{$addr};
3886         my $r = $ranges{$addr};                # The current list of ranges
3887         my $range_list_size = scalar @$r;
3888         my $i;
3889
3890         use integer;        # want integer division
3891
3892         # Use the cached result as the starting guess for this one, because,
3893         # an experiment on 5.1 showed that 90% of the time the cache was the
3894         # same as the result on the next call (and 7% it was one less).
3895         $i = $_search_ranges_cache{$addr};
3896         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3897                                             # from an intervening deletion
3898         #local $to_trace = 1 if main::DEBUG;
3899         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3900         return $i if $code_point <= $r->[$i]->end
3901                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3902
3903         # Here the cache doesn't yield the correct $i.  Try adding 1.
3904         if ($i < $range_list_size - 1
3905             && $r->[$i]->end < $code_point &&
3906             $code_point <= $r->[$i+1]->end)
3907         {
3908             $i++;
3909             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3910             $_search_ranges_cache{$addr} = $i;
3911             return $i;
3912         }
3913
3914         # Here, adding 1 also didn't work.  We do a binary search to
3915         # find the correct position, starting with current $i
3916         my $lower = 0;
3917         my $upper = $range_list_size - 1;
3918         while (1) {
3919             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3920
3921             if ($code_point <= $r->[$i]->end) {
3922
3923                 # Here we have met the upper constraint.  We can quit if we
3924                 # also meet the lower one.
3925                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3926
3927                 $upper = $i;        # Still too high.
3928
3929             }
3930             else {
3931
3932                 # Here, $r[$i]->end < $code_point, so look higher up.
3933                 $lower = $i;
3934             }
3935
3936             # Split search domain in half to try again.
3937             my $temp = ($upper + $lower) / 2;
3938
3939             # No point in continuing unless $i changes for next time
3940             # in the loop.
3941             if ($temp == $i) {
3942
3943                 # We can't reach the highest element because of the averaging.
3944                 # So if one below the upper edge, force it there and try one
3945                 # more time.
3946                 if ($i == $range_list_size - 2) {
3947
3948                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3949                     $i = $range_list_size - 1;
3950
3951                     # Change $lower as well so if fails next time through,
3952                     # taking the average will yield the same $i, and we will
3953                     # quit with the error message just below.
3954                     $lower = $i;
3955                     next;
3956                 }
3957                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3958                 return;
3959             }
3960             $i = $temp;
3961         } # End of while loop
3962
3963         if (main::DEBUG && $to_trace) {
3964             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3965             trace "i=  [ $i ]", $r->[$i];
3966             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3967         }
3968
3969         # Here we have found the offset.  Cache it as a starting point for the
3970         # next call.
3971         $_search_ranges_cache{$addr} = $i;
3972         return $i;
3973     }
3974
3975     sub _add_delete {
3976         # Add, replace or delete ranges to or from a list.  The $type
3977         # parameter gives which:
3978         #   '+' => insert or replace a range, returning a list of any changed
3979         #          ranges.
3980         #   '-' => delete a range, returning a list of any deleted ranges.
3981         #
3982         # The next three parameters give respectively the start, end, and
3983         # value associated with the range.  'value' should be null unless the
3984         # operation is '+';
3985         #
3986         # The range list is kept sorted so that the range with the lowest
3987         # starting position is first in the list, and generally, adjacent
3988         # ranges with the same values are merged into a single larger one (see
3989         # exceptions below).
3990         #
3991         # There are more parameters; all are key => value pairs:
3992         #   Type    gives the type of the value.  It is only valid for '+'.
3993         #           All ranges have types; if this parameter is omitted, 0 is
3994         #           assumed.  Ranges with type 0 are assumed to obey the
3995         #           Unicode rules for casing, etc; ranges with other types are
3996         #           not.  Otherwise, the type is arbitrary, for the caller's
3997         #           convenience, and looked at only by this routine to keep
3998         #           adjacent ranges of different types from being merged into
3999         #           a single larger range, and when Replace =>
4000         #           $IF_NOT_EQUIVALENT is specified (see just below).
4001         #   Replace  determines what to do if the range list already contains
4002         #            ranges which coincide with all or portions of the input
4003         #            range.  It is only valid for '+':
4004         #       => $NO            means that the new value is not to replace
4005         #                         any existing ones, but any empty gaps of the
4006         #                         range list coinciding with the input range
4007         #                         will be filled in with the new value.
4008         #       => $UNCONDITIONALLY  means to replace the existing values with
4009         #                         this one unconditionally.  However, if the
4010         #                         new and old values are identical, the
4011         #                         replacement is skipped to save cycles
4012         #       => $IF_NOT_EQUIVALENT means to replace the existing values
4013         #          (the default)  with this one if they are not equivalent.
4014         #                         Ranges are equivalent if their types are the
4015         #                         same, and they are the same string; or if
4016         #                         both are type 0 ranges, if their Unicode
4017         #                         standard forms are identical.  In this last
4018         #                         case, the routine chooses the more "modern"