This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Doc update for changes in 5.15.0 + tweaks
[perl5.git] / dist / B-Deparse / t / deparse.t
1 #!./perl
2
3 BEGIN {
4     unshift @INC, 't';
5     require Config;
6     if (($Config::Config{'extensions'} !~ /\bB\b/) ){
7         print "1..0 # Skip -- Perl configured without B module\n";
8         exit 0;
9     }
10 }
11
12 use warnings;
13 use strict;
14 BEGIN {
15     # BEGIN block is actually a subroutine :-)
16     return unless $] > 5.009;
17     require feature;
18     feature->import(':5.10');
19 }
20 use Test::More;
21 use Config ();
22
23 use B::Deparse;
24 my $deparse = B::Deparse->new();
25 isa_ok($deparse, 'B::Deparse', 'instantiate a B::Deparse object');
26
27 # Tell B::Deparse about our ambient pragmas
28 { my ($hint_bits, $warning_bits, $hinthash);
29  BEGIN { ($hint_bits, $warning_bits, $hinthash) = ($^H, ${^WARNING_BITS}, \%^H); }
30  $deparse->ambient_pragmas (
31      hint_bits    => $hint_bits,
32      warning_bits => $warning_bits,
33      '$['         => 0 + $[,
34      '%^H'        => $hinthash,
35  );
36 }
37
38 $/ = "\n####\n";
39 while (<DATA>) {
40     chomp;
41     # This code is pinched from the t/lib/common.pl for TODO.
42     # It's not clear how to avoid duplication
43     # Now tweaked a bit to do skip or todo
44     my %reason;
45     foreach my $what (qw(skip todo)) {
46         s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
47         # If the SKIP reason starts ? then it's taken as a code snippet to
48         # evaluate. This provides the flexibility to have conditional SKIPs
49         if ($reason{$what} && $reason{$what} =~ s/^\?//) {
50             my $temp = eval $reason{$what};
51             if ($@) {
52                 die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
53             }
54             $reason{$what} = $temp;
55         }
56     }
57
58     s/^\s*#\s*(.*)$//mg;
59     my $desc = $1;
60     die "Missing name in test $_" unless defined $desc;
61
62     if ($reason{skip}) {
63         # Like this to avoid needing a label SKIP:
64        Test::More->builder->skip($reason{skip});
65         next;
66     }
67
68     my ($input, $expected);
69     if (/(.*)\n>>>>\n(.*)/s) {
70         ($input, $expected) = ($1, $2);
71     }
72     else {
73         ($input, $expected) = ($_, $_);
74     }
75
76     my $coderef = eval "sub {$input}";
77
78     if ($@) {
79         is($@, "", "compilation of $desc");
80     }
81     else {
82         my $deparsed = $deparse->coderef2text( $coderef );
83         my $regex = $expected;
84         $regex =~ s/(\S+)/\Q$1/g;
85         $regex =~ s/\s+/\\s+/g;
86         $regex = '^\{\s*' . $regex . '\s*\}$';
87
88         local $::TODO = $reason{todo};
89         like($deparsed, qr/$regex/, $desc);
90     }
91 }
92
93 use constant 'c', 'stuff';
94 is((eval "sub ".$deparse->coderef2text(\&c))->(), 'stuff',
95    'the subroutine generated by use constant deparses');
96
97 my $a = 0;
98 is($deparse->coderef2text(sub{(-1) ** $a }), "{\n    (-1) ** \$a;\n}",
99    'anon sub capturing an external lexical');
100
101 use constant cr => ['hello'];
102 my $string = "sub " . $deparse->coderef2text(\&cr);
103 my $val = (eval $string)->() or diag $string;
104 is(ref($val), 'ARRAY', 'constant array references deparse');
105 is($val->[0], 'hello', 'and return the correct value');
106
107 my $path = join " ", map { qq["-I$_"] } @INC;
108
109 $a = `$^X $path "-MO=Deparse" -anlwi.bak -e 1 2>&1`;
110 $a =~ s/-e syntax OK\n//g;
111 $a =~ s/.*possible typo.*\n//;     # Remove warning line
112 $a =~ s{\\340\\242}{\\s} if (ord("\\") == 224); # EBCDIC, cp 1047 or 037
113 $a =~ s{\\274\\242}{\\s} if (ord("\\") == 188); # $^O eq 'posix-bc'
114 $b = <<'EOF';
115 BEGIN { $^I = ".bak"; }
116 BEGIN { $^W = 1; }
117 BEGIN { $/ = "\n"; $\ = "\n"; }
118 LINE: while (defined($_ = <ARGV>)) {
119     chomp $_;
120     our(@F) = split(' ', $_, 0);
121     '???';
122 }
123 EOF
124 is($a, $b,
125    'command line flags deparse as BEGIN blocks setting control variables');
126
127 $a = `$^X $path "-MO=Deparse" -e "use constant PI => 4" 2>&1`;
128 $a =~ s/-e syntax OK\n//g;
129 is($a, "use constant ('PI', 4);\n",
130    "Proxy Constant Subroutines must not show up as (incorrect) prototypes");
131
132 #Re: perlbug #35857, patch #24505
133 #handle warnings::register-ed packages properly.
134 package B::Deparse::Wrapper;
135 use strict;
136 use warnings;
137 use warnings::register;
138 sub getcode {
139    my $deparser = B::Deparse->new();
140    return $deparser->coderef2text(shift);
141 }
142
143 package Moo;
144 use overload '0+' => sub { 42 };
145
146 package main;
147 use strict;
148 use warnings;
149 use constant GLIPP => 'glipp';
150 use constant PI => 4;
151 use constant OVERLOADED_NUMIFICATION => bless({}, 'Moo');
152 use Fcntl qw/O_TRUNC O_APPEND O_EXCL/;
153 BEGIN { delete $::Fcntl::{O_APPEND}; }
154 use POSIX qw/O_CREAT/;
155 sub test {
156    my $val = shift;
157    my $res = B::Deparse::Wrapper::getcode($val);
158    like($res, qr/use warnings/,
159         '[perl #35857] [PATCH] B::Deparse doesnt handle warnings register properly');
160 }
161 my ($q,$p);
162 my $x=sub { ++$q,++$p };
163 test($x);
164 eval <<EOFCODE and test($x);
165    package bar;
166    use strict;
167    use warnings;
168    use warnings::register;
169    package main;
170    1
171 EOFCODE
172
173 # Exotic sub declarations
174 $a = `$^X $path "-MO=Deparse" -e "sub ::::{}sub ::::::{}" 2>&1`;
175 $a =~ s/-e syntax OK\n//g;
176 is($a, <<'EOCODG', "sub :::: and sub ::::::");
177 sub :::: {
178     
179 }
180 sub :::::: {
181     
182 }
183 EOCODG
184
185 # [perl #33752]
186 {
187   my $code = <<"EOCODE";
188 {
189     our \$\x{1e1f}\x{14d}\x{14d};
190 }
191 EOCODE
192   my $deparsed
193    = $deparse->coderef2text(eval "sub { our \$\x{1e1f}\x{14d}\x{14d} }" );
194   s/$ \n//x for $deparsed, $code;
195   is $deparsed, $code, 'our $funny_Unicode_chars';
196 }
197
198 # [perl #62500]
199 $a =
200   `$^X $path "-MO=Deparse" -e "BEGIN{*CORE::GLOBAL::require=sub{1}}" 2>&1`;
201 $a =~ s/-e syntax OK\n//g;
202 is($a, <<'EOCODF', "CORE::GLOBAL::require override causing panick");
203 sub BEGIN {
204     *CORE::GLOBAL::require = sub {
205         1;
206     }
207     ;
208 }
209 EOCODF
210
211 done_testing();
212
213 __DATA__
214 # A constant
215 1;
216 ####
217 # Constants in a block
218 {
219     no warnings;
220     '???';
221     2;
222 }
223 ####
224 # Lexical and simple arithmetic
225 my $test;
226 ++$test and $test /= 2;
227 >>>>
228 my $test;
229 $test /= 2 if ++$test;
230 ####
231 # list x
232 -((1, 2) x 2);
233 ####
234 # lvalue sub
235 {
236     my $test = sub : lvalue {
237         my $x;
238     }
239     ;
240 }
241 ####
242 # method
243 {
244     my $test = sub : method {
245         my $x;
246     }
247     ;
248 }
249 ####
250 # block with continue
251 {
252     234;
253 }
254 continue {
255     123;
256 }
257 ####
258 # lexical and package scalars
259 my $x;
260 print $main::x;
261 ####
262 # lexical and package arrays
263 my @x;
264 print $main::x[1];
265 ####
266 # lexical and package hashes
267 my %x;
268 $x{warn()};
269 ####
270 # <>
271 my $foo;
272 $_ .= <ARGV> . <$foo>;
273 ####
274 # \x{}
275 my $foo = "Ab\x{100}\200\x{200}\237Cd\000Ef\x{1000}\cA\x{2000}\cZ";
276 ####
277 # s///e
278 s/x/'y';/e;
279 ####
280 # block
281 { my $x; }
282 ####
283 # while 1
284 while (1) { my $k; }
285 ####
286 # trailing for
287 my ($x,@a);
288 $x=1 for @a;
289 >>>>
290 my($x, @a);
291 $x = 1 foreach (@a);
292 ####
293 # 2 arguments in a 3 argument for
294 for (my $i = 0; $i < 2;) {
295     my $z = 1;
296 }
297 ####
298 # 3 argument for
299 for (my $i = 0; $i < 2; ++$i) {
300     my $z = 1;
301 }
302 ####
303 # 3 argument for again
304 for (my $i = 0; $i < 2; ++$i) {
305     my $z = 1;
306 }
307 ####
308 # while/continue
309 my $i;
310 while ($i) { my $z = 1; } continue { $i = 99; }
311 ####
312 # foreach with my
313 foreach my $i (1, 2) {
314     my $z = 1;
315 }
316 ####
317 # foreach
318 my $i;
319 foreach $i (1, 2) {
320     my $z = 1;
321 }
322 ####
323 # foreach, 2 mys
324 my $i;
325 foreach my $i (1, 2) {
326     my $z = 1;
327 }
328 ####
329 # foreach
330 foreach my $i (1, 2) {
331     my $z = 1;
332 }
333 ####
334 # foreach with our
335 foreach our $i (1, 2) {
336     my $z = 1;
337 }
338 ####
339 # foreach with my and our
340 my $i;
341 foreach our $i (1, 2) {
342     my $z = 1;
343 }
344 ####
345 # reverse sort
346 my @x;
347 print reverse sort(@x);
348 ####
349 # sort with cmp
350 my @x;
351 print((sort {$b cmp $a} @x));
352 ####
353 # reverse sort with block
354 my @x;
355 print((reverse sort {$b <=> $a} @x));
356 ####
357 # foreach reverse
358 our @a;
359 print $_ foreach (reverse @a);
360 ####
361 # foreach reverse (not inplace)
362 our @a;
363 print $_ foreach (reverse 1, 2..5);
364 ####
365 # bug #38684
366 our @ary;
367 @ary = split(' ', 'foo', 0);
368 ####
369 # bug #40055
370 do { () }; 
371 ####
372 # bug #40055
373 do { my $x = 1; $x }; 
374 ####
375 # <20061012113037.GJ25805@c4.convolution.nl>
376 my $f = sub {
377     +{[]};
378 } ;
379 ####
380 # bug #43010
381 '!@$%'->();
382 ####
383 # bug #43010
384 ::();
385 ####
386 # bug #43010
387 '::::'->();
388 ####
389 # bug #43010
390 &::::;
391 ####
392 # variables as method names
393 my $bar;
394 'Foo'->$bar('orz');
395 'Foo'->$bar('orz') = 'a stranger stranger than before';
396 ####
397 # constants as method names
398 'Foo'->bar('orz');
399 ####
400 # constants as method names without ()
401 'Foo'->bar;
402 ####
403 # SKIP ?$] < 5.010 && "say not implemented on this Perl version"
404 # say
405 say 'foo';
406 ####
407 # SKIP ?$] < 5.010 && "state vars not implemented on this Perl version"
408 # state vars
409 state $x = 42;
410 ####
411 # SKIP ?$] < 5.010 && "state vars not implemented on this Perl version"
412 # state var assignment
413 {
414     my $y = (state $x = 42);
415 }
416 ####
417 # SKIP ?$] < 5.010 && "state vars not implemented on this Perl version"
418 # state vars in anonymous subroutines
419 $a = sub {
420     state $x;
421     return $x++;
422 }
423 ;
424 ####
425 # SKIP ?$] < 5.011 && 'each @array not implemented on this Perl version'
426 # each @array;
427 each @ARGV;
428 each @$a;
429 ####
430 # SKIP ?$] < 5.011 && 'each @array not implemented on this Perl version'
431 # keys @array; values @array
432 keys @$a if keys @ARGV;
433 values @ARGV if values @$a;
434 ####
435 # Anonymous arrays and hashes, and references to them
436 my $a = {};
437 my $b = \{};
438 my $c = [];
439 my $d = \[];
440 ####
441 # SKIP ?$] < 5.010 && "smartmatch and given/when not implemented on this Perl version"
442 # implicit smartmatch in given/when
443 given ('foo') {
444     when ('bar') { continue; }
445     when ($_ ~~ 'quux') { continue; }
446     default { 0; }
447 }
448 ####
449 # conditions in elsifs (regression in change #33710 which fixed bug #37302)
450 if ($a) { x(); }
451 elsif ($b) { x(); }
452 elsif ($a and $b) { x(); }
453 elsif ($a or $b) { x(); }
454 else { x(); }
455 ####
456 # interpolation in regexps
457 my($y, $t);
458 /x${y}z$t/;
459 ####
460 # TODO new undocumented cpan-bug #33708
461 # cpan-bug #33708
462 %{$_ || {}}
463 ####
464 # TODO hash constants not yet fixed
465 # cpan-bug #33708
466 use constant H => { "#" => 1 }; H->{"#"}
467 ####
468 # TODO optimized away 0 not yet fixed
469 # cpan-bug #33708
470 foreach my $i (@_) { 0 }
471 ####
472 # tests with not, not optimized
473 my $c;
474 x() unless $a;
475 x() if not $a and $b;
476 x() if $a and not $b;
477 x() unless not $a and $b;
478 x() unless $a and not $b;
479 x() if not $a or $b;
480 x() if $a or not $b;
481 x() unless not $a or $b;
482 x() unless $a or not $b;
483 x() if $a and not $b and $c;
484 x() if not $a and $b and not $c;
485 x() unless $a and not $b and $c;
486 x() unless not $a and $b and not $c;
487 x() if $a or not $b or $c;
488 x() if not $a or $b or not $c;
489 x() unless $a or not $b or $c;
490 x() unless not $a or $b or not $c;
491 ####
492 # tests with not, optimized
493 my $c;
494 x() if not $a;
495 x() unless not $a;
496 x() if not $a and not $b;
497 x() unless not $a and not $b;
498 x() if not $a or not $b;
499 x() unless not $a or not $b;
500 x() if not $a and not $b and $c;
501 x() unless not $a and not $b and $c;
502 x() if not $a or not $b or $c;
503 x() unless not $a or not $b or $c;
504 x() if not $a and not $b and not $c;
505 x() unless not $a and not $b and not $c;
506 x() if not $a or not $b or not $c;
507 x() unless not $a or not $b or not $c;
508 x() unless not $a or not $b or not $c;
509 >>>>
510 my $c;
511 x() unless $a;
512 x() if $a;
513 x() unless $a or $b;
514 x() if $a or $b;
515 x() unless $a and $b;
516 x() if $a and $b;
517 x() if not $a || $b and $c;
518 x() unless not $a || $b and $c;
519 x() if not $a && $b or $c;
520 x() unless not $a && $b or $c;
521 x() unless $a or $b or $c;
522 x() if $a or $b or $c;
523 x() unless $a and $b and $c;
524 x() if $a and $b and $c;
525 x() unless not $a && $b && $c;
526 ####
527 # tests that should be constant folded
528 x() if 1;
529 x() if GLIPP;
530 x() if !GLIPP;
531 x() if GLIPP && GLIPP;
532 x() if !GLIPP || GLIPP;
533 x() if do { GLIPP };
534 x() if do { no warnings 'void'; 5; GLIPP };
535 x() if do { !GLIPP };
536 if (GLIPP) { x() } else { z() }
537 if (!GLIPP) { x() } else { z() }
538 if (GLIPP) { x() } elsif (GLIPP) { z() }
539 if (!GLIPP) { x() } elsif (GLIPP) { z() }
540 if (GLIPP) { x() } elsif (!GLIPP) { z() }
541 if (!GLIPP) { x() } elsif (!GLIPP) { z() }
542 if (!GLIPP) { x() } elsif (!GLIPP) { z() } elsif (GLIPP) { t() }
543 if (!GLIPP) { x() } elsif (!GLIPP) { z() } elsif (!GLIPP) { t() }
544 if (!GLIPP) { x() } elsif (!GLIPP) { z() } elsif (!GLIPP) { t() }
545 >>>>
546 x();
547 x();
548 '???';
549 x();
550 x();
551 x();
552 x();
553 do {
554     '???'
555 };
556 do {
557     x()
558 };
559 do {
560     z()
561 };
562 do {
563     x()
564 };
565 do {
566     z()
567 };
568 do {
569     x()
570 };
571 '???';
572 do {
573     t()
574 };
575 '???';
576 !1;
577 ####
578 # TODO constant deparsing has been backed out for 5.12
579 # XXXTODO ? $Config::Config{useithreads} && "doesn't work with threads"
580 # tests that shouldn't be constant folded
581 # It might be fundamentally impossible to make this work on ithreads, in which
582 # case the TODO should become a SKIP
583 x() if $a;
584 if ($a == 1) { x() } elsif ($b == 2) { z() }
585 if (do { foo(); GLIPP }) { x() }
586 if (do { $a++; GLIPP }) { x() }
587 >>>>
588 x() if $a;
589 if ($a == 1) { x(); } elsif ($b == 2) { z(); }
590 if (do { foo(); GLIPP }) { x(); }
591 if (do { ++$a; GLIPP }) { x(); }
592 ####
593 # TODO constant deparsing has been backed out for 5.12
594 # tests for deparsing constants
595 warn PI;
596 ####
597 # TODO constant deparsing has been backed out for 5.12
598 # tests for deparsing imported constants
599 warn O_TRUNC;
600 ####
601 # TODO constant deparsing has been backed out for 5.12
602 # tests for deparsing re-exported constants
603 warn O_CREAT;
604 ####
605 # TODO constant deparsing has been backed out for 5.12
606 # tests for deparsing imported constants that got deleted from the original namespace
607 warn O_APPEND;
608 ####
609 # TODO constant deparsing has been backed out for 5.12
610 # XXXTODO ? $Config::Config{useithreads} && "doesn't work with threads"
611 # tests for deparsing constants which got turned into full typeglobs
612 # It might be fundamentally impossible to make this work on ithreads, in which
613 # case the TODO should become a SKIP
614 warn O_EXCL;
615 eval '@Fcntl::O_EXCL = qw/affe tiger/;';
616 warn O_EXCL;
617 ####
618 # TODO constant deparsing has been backed out for 5.12
619 # tests for deparsing of blessed constant with overloaded numification
620 warn OVERLOADED_NUMIFICATION;
621 ####
622 # TODO Only strict 'refs' currently supported
623 # strict
624 no strict;
625 $x;
626 ####
627 # TODO Subsets of warnings could be encoded textually, rather than as bitflips.
628 # subsets of warnings
629 no warnings 'deprecated';
630 my $x;
631 ####
632 # TODO Better test for CPAN #33708 - the deparsed code has different behaviour
633 # CPAN #33708
634 use strict;
635 no warnings;
636
637 foreach (0..3) {
638     my $x = 2;
639     {
640         my $x if 0;
641         print ++$x, "\n";
642     }
643 }
644 ####
645 # no attribute list
646 my $pi = 4;
647 ####
648 # SKIP ?$] > 5.013006 && ":= is now a syntax error"
649 # := treated as an empty attribute list
650 no warnings;
651 my $pi := 4;
652 >>>>
653 no warnings;
654 my $pi = 4;
655 ####
656 # : = empty attribute list
657 my $pi : = 4;
658 >>>>
659 my $pi = 4;
660 ####
661 # in place sort
662 our @a;
663 my @b;
664 @a = sort @a;
665 @b = sort @b;
666 ();
667 ####
668 # in place reverse
669 our @a;
670 my @b;
671 @a = reverse @a;
672 @b = reverse @b;
673 ();
674 ####
675 # #71870 Use of uninitialized value in bitwise and B::Deparse
676 my($r, $s, @a);
677 @a = split(/foo/, $s, 0);
678 $r = qr/foo/;
679 @a = split(/$r/, $s, 0);
680 ();
681 ####
682 # package declaration before label
683 {
684     package Foo;
685     label: print 123;
686 }
687 ####
688 # shift optimisation
689 shift;
690 >>>>
691 shift();
692 ####
693 # shift optimisation
694 shift @_;
695 ####
696 # shift optimisation
697 pop;
698 >>>>
699 pop();
700 ####
701 # shift optimisation
702 pop @_;
703 ####
704 #[perl #20444]
705 "foo" =~ (1 ? /foo/ : /bar/);
706 "foo" =~ (1 ? y/foo// : /bar/);
707 "foo" =~ (1 ? s/foo// : /bar/);
708 >>>>
709 'foo' =~ ($_ =~ /foo/);
710 'foo' =~ ($_ =~ tr/fo//);
711 'foo' =~ ($_ =~ s/foo//);
712 ####
713 # Test @threadsv_names under 5005threads
714 foreach $' (1, 2) {
715     sleep $';
716 }
717 ####
718 # y///r
719 tr/a/b/r;
720 ####
721 # y/uni/code/
722 tr/\x{345}/\x{370}/;
723 ####
724 # [perl #90898]
725 <a,>;
726 ####
727 # [perl #91008]
728 each $@;
729 keys $~;
730 values $!;
731 ####
732 # readpipe with complex expression
733 readpipe $a + $b;
734 ####
735 # aelemfast
736 $b::a[0] = 1;
737 ####
738 # aelemfast for a lexical
739 my @a;
740 $a[0] = 1;
741 ####
742 # feature features without feature
743 BEGIN {
744     delete $^H{'feature_say'};
745     delete $^H{'feature_state'};
746     delete $^H{'feature_switch'};
747 }
748 CORE::state $x;
749 CORE::say $x;
750 CORE::given ($x) {
751     CORE::when (3) {
752         continue;
753     }
754     CORE::default {
755         die;
756     }
757 }