This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
pp_sys.c: pp_tie and untie UTF8 cleanup.
[perl5.git] / t / uni / gv.t
1 #!./perl
2
3 #
4 # various typeglob tests
5 #
6
7 BEGIN {
8     chdir 't' if -d 't';
9     @INC = '../lib';
10     require './test.pl';
11 }
12
13 use utf8;
14 use open qw( :utf8 :std );
15 use warnings;
16
17 plan( tests => 212 );
18
19 # type coersion on assignment
20 $ᕘ = 'ᕘ';
21 $ᴮᛅ = *main::ᕘ;
22 $ᴮᛅ = $ᕘ;
23 is(ref(\$ᴮᛅ), 'SCALAR');
24 $ᕘ = *main::ᴮᛅ;
25
26 # type coersion (not) on misc ops
27
28 ok($ᕘ);
29 is(ref(\$ᕘ), 'GLOB');
30
31 unlike ($ᕘ, qr/abcd/);
32 is(ref(\$ᕘ), 'GLOB');
33
34 is($ᕘ, '*main::ᴮᛅ');
35 is(ref(\$ᕘ), 'GLOB');
36
37 {
38  no warnings;
39  ${\*$ᕘ} = undef;
40  is(ref(\$ᕘ), 'GLOB', 'no type coersion when assigning to *{} retval');
41  $::{ఫケ} = *ᴮᛅ;
42  is(
43    \$::{ఫケ}, \*{"ఫケ"},
44    'symbolic *{} returns symtab entry when FAKE'
45  );
46  ${\*{"ఫケ"}} = undef;
47  is(
48    ref(\$::{ఫケ}), 'GLOB',
49   'no type coersion when assigning to retval of symbolic *{}'
50  );
51  $::{pɥአQuઍ} = *ᴮᛅ;
52  eval '
53    is(
54      \$::{pɥአQuઍ}, \*pɥአQuઍ,
55      "compile-time *{} returns symtab entry when FAKE"
56    );
57    ${\*pɥአQuઍ} = undef;
58  ';
59  is(
60    ref(\$::{pɥአQuઍ}), 'GLOB',
61   'no type coersion when assigning to retval of compile-time *{}'
62  );
63 }
64
65 # type coersion on substitutions that match
66 $a = *main::ᕘ;
67 $b = $a;
68 $a =~ s/^X//;
69 is(ref(\$a), 'GLOB');
70 $a =~ s/^\*//;
71 is($a, 'main::ᕘ');
72 is(ref(\$b), 'GLOB');
73
74 # typeglobs as lvalues
75 substr($ᕘ, 0, 1) = "XXX";
76 is(ref(\$ᕘ), 'SCALAR');
77 is($ᕘ, 'XXXmain::ᴮᛅ');
78
79 # returning glob values
80 sub ᕘ {
81   local($ᴮᛅ) = *main::ᕘ;
82   $ᕘ = *main::ᴮᛅ;
83   return ($ᕘ, $ᴮᛅ);
84 }
85
86 ($ፉṶ, $ባ) = ᕘ();
87 ok(defined $ፉṶ);
88 is(ref(\$ፉṶ), 'GLOB');
89
90
91 ok(defined $ባ);
92 is(ref(\$ባ), 'GLOB');
93
94 # nested package globs
95 # NOTE:  It's probably OK if these semantics change, because the
96 #        fact that %X::Y:: is stored in %X:: isn't documented.
97 #        (I hope.)
98
99 { package ฝ오::ʉ; no warnings 'once'; $test=1; }
100 ok(exists $ฝ오::{'ʉ::'});
101 is($ฝ오::{'ʉ::'}, '*ฝ오::ʉ::');
102
103
104 # test undef operator clearing out entire glob
105 $ᕘ = 'stuff';
106 @ᕘ = qw(more stuff);
107 %ᕘ = qw(even more random stuff);
108 undef *ᕘ;
109 is ($ᕘ, undef);
110 is (scalar @ᕘ, 0);
111 is (scalar %ᕘ, 0);
112
113 TODO: {
114     local $TODO = "sprintf formats might not be clean on globs";
115     # test warnings from assignment of undef to glob
116     my $msg = '';
117     local $SIG{__WARN__} = sub { $msg = $_[0] };
118     use warnings;
119     *ᕘ = 'ᴮᛅ';
120     is($msg, '');
121     *ᕘ = undef;
122     like($msg, qr/Undefined value assigned to typeglob/);
123
124     no warnings 'once';
125     # test warnings for converting globs to other forms
126     my $copy = *PWÒMPF;
127     foreach ($copy, *SKRÈÈÈ) {
128         $msg = '';
129         my $victim = sprintf "%d", $_;
130         like($msg, qr/Argument "\*main::[\p{XIDS}\p{XIDC}]{6}" isn't numeric in sprintf/,
131              "Warning on conversion to IV");
132         is($victim, 0);
133
134         $msg = '';
135         $victim = sprintf "%u", $_;
136         like($msg, qr/Argument "\*main::[\p{XIDS}\p{XIDC}]{6}" isn't numeric in sprintf/,
137              "Warning on conversion to UV");
138         is($victim, 0);
139
140         $msg = '';
141         $victim = sprintf "%e", $_;
142         like($msg, qr/Argument "\*main::[\p{XIDS}\p{XIDC}]{6}" isn't numeric in sprintf/,
143              "Warning on conversion to NV");
144         like($victim, qr/^0\.0+E\+?00/i, "Expect floating point zero");
145
146         $msg = '';
147         $victim = sprintf "%s", $_;
148         is($msg, '', "No warning on stringification");
149         is($victim, '' . $_);
150     }
151 }
152
153 my $test = curr_test();
154 # test *glob{THING} syntax
155 $Ẋ = "ok $test\n";
156 ++$test;
157 @Ẋ = ("ok $test\n");
158 ++$test;
159 %Ẋ = ("ok $test" => "\n");
160 ++$test;
161 sub Ẋ { "ok $test\n" }
162 print ${*Ẋ{SCALAR}}, @{*Ẋ{ARRAY}}, %{*Ẋ{HASH}}, &{*Ẋ{CODE}};
163 # This needs to go here, after the print, as sub Ẋ will return the current
164 # value of test
165 ++$test;
166 format Ẋ =
167 XXX This text isn't used. Should it be?
168 .
169 curr_test($test);
170
171 is (ref *Ẋ{FORMAT}, "FORMAT");
172 *Ẋ = *STDOUT;
173 is (*{*Ẋ{GLOB}}, "*main::STDOUT");
174
175 {
176     my $test = curr_test();
177
178     print {*Ẋ{IO}} "ok $test\n";
179     ++$test;
180
181     my $warn;
182     local $SIG{__WARN__} = sub {
183         $warn .= $_[0];
184     };
185     my $val = *Ẋ{FILEHANDLE};
186     print {*Ẋ{IO}} ($warn =~ /is deprecated/
187                     ? "ok $test\n" : "not ok $test\n");
188     curr_test(++$test);
189 }
190
191
192 {
193     # test if defined() doesn't create any new symbols
194
195     my $a = "Sʎm000";
196     ok(!defined *{$a});
197
198     ok(!defined @{$a});
199     ok(!defined *{$a});
200
201     {
202         no warnings 'deprecated';
203         ok(!defined %{$a});
204     }
205     ok(!defined *{$a});
206
207     ok(!defined ${$a});
208     ok(!defined *{$a});
209
210     ok(!defined &{$a});
211     ok(!defined *{$a});
212
213     my $state = "not";
214     *{$a} = sub { $state = "ok" };
215     ok(defined &{$a});
216     ok(defined *{$a});
217     &{$a};
218     is ($state, 'ok');
219 }
220
221 # [ID 20010526.001] localized glob loses value when assigned to
222
223 $J=1; %J=(a=>1); @J=(1); local *J=*J; *J = sub{};
224
225 is($J, 1);
226 is($J{a}, 1);
227 is($J[0], 1);
228
229 {
230     # does pp_readline() handle glob-ness correctly?
231     my $g = *ᕘ;
232     $g = <DATA>;
233     is ($g, "Perl\n");
234 }
235
236 {
237     my $w = '';
238     local $SIG{__WARN__} = sub { $w = $_[0] };
239     sub aʙȼ1 ();
240     local *aʙȼ1 = sub { };
241     is ($w, '');
242     sub aʙȼ2 ();
243     local *aʙȼ2;
244     *aʙȼ2 = sub { };
245     is ($w, '');
246     sub aʙȼ3 ();
247     *aʙȼ3 = sub { };
248     like ($w, qr/Prototype mismatch/);
249 }
250
251 {
252     # [17375] rcatline to formerly-defined undef was broken. Fixed in
253     # do_readline by checking SvOK. AMS, 20020918
254     my $x = "not ";
255     $x  = undef;
256     $x .= <DATA>;
257     is ($x, "Rules\n");
258 }
259
260 {
261     # test the assignment of a GLOB to an LVALUE
262     my $e = '';
263     local $SIG{__DIE__} = sub { $e = $_[0] };
264     my %V;
265     sub ƒ { $_[0] = 0; $_[0] = "a"; $_[0] = *DATA }
266     ƒ($V{V});
267     is ($V{V}, '*main::DATA');
268     is (ref\$V{V}, 'GLOB', 'lvalue assignment preserves globs');
269     my $x = readline $V{V};
270     is ($x, "perl\n");
271     is ($e, '', '__DIE__ handler never called');
272 }
273
274 {
275
276     my $e = '';
277     # GLOB assignment to tied element
278     local $SIG{__DIE__} = sub { $e = $_[0] };
279     sub Ʈ::TIEARRAY  { bless [] => "Ʈ" }
280     sub Ʈ::STORE     { $_[0]->[ $_[1] ] = $_[2] }
281     sub Ʈ::FETCH     { $_[0]->[ $_[1] ] }
282     sub Ʈ::FETCHSIZE { @{$_[0]} }
283     tie my @ary => "Ʈ";
284     $ary[0] = *DATA;
285     is ($ary[0], '*main::DATA');
286     is (
287       ref\tied(@ary)->[0], 'GLOB',
288      'tied elem assignment preserves globs'
289     );
290     is ($e, '', '__DIE__ handler not called');
291     my $x = readline $ary[0];
292     is($x, "rocks\n");
293     is ($e, '', '__DIE__ handler never called');
294 }
295
296 {
297     SKIP: {
298         skip_if_miniperl('no dynamic loading on miniperl, no Encode');
299         # Need some sort of die or warn to get the global destruction text if the
300         # bug is still present
301         my $prog = <<'EOPROG';
302             use utf8;
303             use open qw( :utf8 :std );
304             package ᴹ;
305             $| = 1;
306             sub DESTROY {eval {die qq{Farewell $_[0]}}; print $@}
307             package main;
308     
309             bless \$Ⱥ::ㄅ, q{ᴹ};
310             *Ⱥ:: = \*ㄅ::;
311 EOPROG
312     
313         utf8::decode($prog);
314         my $output = runperl(prog => $prog);
315         
316         require Encode;
317         $output = Encode::decode("UTF-8", $output);
318         like($output, qr/^Farewell ᴹ=SCALAR/, "DESTROY was called");
319         unlike($output, qr/global destruction/,
320             "unreferenced symbol tables should be cleaned up immediately");
321     }
322 }
323
324 TODO: {
325     local $TODO = "prototype() (and prototypes in general) not yet clean";
326     # Possibly not the correct test file for these tests.
327     # There are certain space optimisations implemented via promotion rules to
328     # GVs
329     
330     foreach (qw (оઓnḲ ga_ㄕƚo잎)) {
331         ok(!exists $::{$_}, "no symbols of any sort to start with for $_");
332     }
333     
334     # A string in place of the typeglob is promoted to the function prototype
335     $::{оઓnḲ} = "pìè";
336     my $proto = eval 'prototype \&оઓnḲ';
337     die if $@;
338     is ($proto, "pìè", "String is promoted to prototype");
339     
340     
341     # A reference to a value is used to generate a constant subroutine
342     foreach my $value (3, "Perl rules", \42, qr/whatever/, [1,2,3], {1=>2},
343                     \*STDIN, \&ok, \undef, *STDOUT) {
344         delete $::{оઓnḲ};
345         $::{оઓnḲ} = \$value;
346         $proto = eval 'prototype \&оઓnḲ';
347         die if $@;
348         is ($proto, '', "Prototype for a constant subroutine is empty");
349     
350         my $got = eval 'оઓnḲ';
351         die if $@;
352         is (ref $got, ref $value, "Correct type of value (" . ref($value) . ")");
353         is ($got, $value, "Value is correctly set");
354     }
355 }
356
357 delete $::{оઓnḲ};
358 $::{оઓnḲ} = \"Value";
359
360 *{"ga_ㄕƚo잎"} = \&{"оઓnḲ"};
361
362 is (ref $::{ga_ㄕƚo잎}, 'SCALAR', "Export of proxy constant as is");
363 is (ref $::{оઓnḲ}, 'SCALAR', "Export doesn't affect original");
364 is (eval 'ga_ㄕƚo잎', "Value", "Constant has correct value");
365 is (ref $::{ga_ㄕƚo잎}, 'SCALAR',
366     "Inlining of constant doesn't change representation");
367
368 delete $::{ga_ㄕƚo잎};
369
370 eval 'sub ga_ㄕƚo잎 (); 1' or die $@;
371 is ($::{ga_ㄕƚo잎}, '', "Prototype is stored as an empty string");
372
373 # Check that a prototype expands.
374 *{"ga_ㄕƚo잎"} = \&{"оઓnḲ"};
375
376 is (ref $::{оઓnḲ}, 'SCALAR', "Export doesn't affect original");
377 is (eval 'ga_ㄕƚo잎', "Value", "Constant has correct value");
378 is (ref \$::{ga_ㄕƚo잎}, 'GLOB', "Symbol table has full typeglob");
379
380
381 @::zᐓt = ('Zᐓt!');
382
383 # Check that assignment to an existing typeglob works
384 {
385   my $w = '';
386   local $SIG{__WARN__} = sub { $w = $_[0] };
387   *{"zᐓt"} = \&{"оઓnḲ"};
388   is($w, '', "Should be no warning");
389 }
390
391 is (ref $::{оઓnḲ}, 'SCALAR', "Export doesn't affect original");
392 is (eval 'zᐓt', "Value", "Constant has correct value");
393 is (ref \$::{zᐓt}, 'GLOB', "Symbol table has full typeglob");
394 is (join ('!', @::zᐓt), 'Zᐓt!', "Existing array still in typeglob");
395
396 sub Ṩp맅싵Ş () {
397     "Traditional";
398 }
399
400 # Check that assignment to an existing subroutine works
401 TODO: {
402   local $TODO = "Warnings not yet UTF-8 clean";
403   my $w = '';
404   local $SIG{__WARN__} = sub { $w = $_[0] };
405   *{"Ṩp맅싵Ş"} = \&{"оઓnḲ"};
406   like($w, qr/^Constant subroutine main::Ṩp맅싵Ş redefined/,
407        "Redefining a constant sub should warn");
408 }
409
410 is (ref $::{оઓnḲ}, 'SCALAR', "Export doesn't affect original");
411 is (eval 'Ṩp맅싵Ş', "Value", "Constant has correct value");
412 is (ref \$::{Ṩp맅싵Ş}, 'GLOB', "Symbol table has full typeglob");
413
414 # Check that assignment to an existing typeglob works
415 {
416   my $w = '';
417   local $SIG{__WARN__} = sub { $w = $_[0] };
418   *{"plუᒃ"} = [];
419   *{"plუᒃ"} = \&{"оઓnḲ"};
420   is($w, '', "Should be no warning");
421 }
422
423 is (ref $::{оઓnḲ}, 'SCALAR', "Export doesn't affect original");
424 is (eval 'plუᒃ', "Value", "Constant has correct value");
425 is (ref \$::{plუᒃ}, 'GLOB', "Symbol table has full typeglob");
426
427 my $gr = eval '\*plუᒃ' or die;
428
429 {
430   my $w = '';
431   local $SIG{__WARN__} = sub { $w = $_[0] };
432   *{$gr} = \&{"оઓnḲ"};
433   is($w, '', "Redefining a constant sub to another constant sub with the same underlying value should not warn (It's just re-exporting, and that was always legal)");
434 }
435
436 is (ref $::{оઓnḲ}, 'SCALAR', "Export doesn't affect original");
437 is (eval 'plუᒃ', "Value", "Constant has correct value");
438 is (ref \$::{plუᒃ}, 'GLOB', "Symbol table has full typeglob");
439
440 # Non-void context should defeat the optimisation, and will cause the original
441 # to be promoted (what change 26482 intended)
442 my $result;
443 {
444   my $w = '';
445   local $SIG{__WARN__} = sub { $w = $_[0] };
446   $result = *{"aẈʞƙʞƙʞƙ"} = \&{"оઓnḲ"};
447   is($w, '', "Should be no warning");
448 }
449
450 is (ref \$result, 'GLOB',
451     "Non void assignment should still return a typeglob");
452
453 is (ref \$::{оઓnḲ}, 'GLOB', "This export does affect original");
454 is (eval 'plუᒃ', "Value", "Constant has correct value");
455 is (ref \$::{plუᒃ}, 'GLOB', "Symbol table has full typeglob");
456
457 delete $::{оઓnḲ};
458 $::{оઓnḲ} = \"Value";
459
460 sub non_dangling {
461   my $w = '';
462   local $SIG{__WARN__} = sub { $w = $_[0] };
463   *{"z앞"} = \&{"оઓnḲ"};
464   is($w, '', "Should be no warning");
465 }
466
467 non_dangling();
468 is (ref $::{оઓnḲ}, 'SCALAR', "Export doesn't affect original");
469 is (eval 'z앞', "Value", "Constant has correct value");
470 is (ref $::{z앞}, 'SCALAR', "Exported target is also a PCS");
471
472 sub dangling {
473   local $SIG{__WARN__} = sub { die $_[0] };
474   *{"ビfᶠ"} = \&{"оઓnḲ"};
475 }
476
477 dangling();
478 is (ref \$::{оઓnḲ}, 'GLOB', "This export does affect original");
479 is (eval 'ビfᶠ', "Value", "Constant has correct value");
480 is (ref \$::{ビfᶠ}, 'GLOB', "Symbol table has full typeglob");
481
482 {
483     use vars qw($gᓙʞ $sምḲ $ᕘf);
484     # Check reference assignment isn't affected by the SV type (bug #38439)
485     $gᓙʞ = 3;
486     $sምḲ = 4;
487     $ᕘf = "halt and cool down";
488
489     my $rv = \*sምḲ;
490     is($gᓙʞ, 3);
491     *gᓙʞ = $rv;
492     is($gᓙʞ, 4);
493
494     my $pv = "";
495     $pv = \*sምḲ;
496     is($ᕘf, "halt and cool down");
497     *ᕘf = $pv;
498     is($ᕘf, 4);
499 }
500
501 TODO: {
502 local $TODO = "Prototypes not yet clean";
503 no warnings 'once';
504 format =
505 .
506     
507     foreach my $value ([1,2,3], {1=>2}, *STDOUT{IO}, \&ok, *STDOUT{FORMAT}) {
508         # *STDOUT{IO} returns a reference to a PVIO. As it's blessed, ref returns
509         # IO::Handle, which isn't what we want.
510         my $type = $value;
511         $type =~ s/.*=//;
512         $type =~ s/\(.*//;
513         delete $::{оઓnḲ};
514         $::{оઓnḲ} = $value;
515         $proto = eval 'prototype \&оઓnḲ';
516         like ($@, qr/^Cannot convert a reference to $type to typeglob/,
517             "Cannot upgrade ref-to-$type to typeglob");
518     }
519 }
520
521 {
522     no warnings qw(once uninitialized);
523     my $g = \*ȼલᑧɹ;
524     my $r = eval {no strict; ${*{$g}{SCALAR}}};
525     is ($@, '', "PERL_DONT_CREATE_GVSV shouldn't affect thingy syntax");
526
527     $g = \*vȍwɯ;
528     $r = eval {use strict; ${*{$g}{SCALAR}}};
529     is ($@, '',
530         "PERL_DONT_CREATE_GVSV shouldn't affect thingy syntax under strict");
531 }
532
533 {
534     # Bug reported by broquaint on IRC
535     *ᔅᓗsḨ::{HASH}->{ISA}=[];
536     ᔅᓗsḨ->import;
537     pass("gv_fetchmeth coped with the unexpected");
538
539     # An audit found these:
540     {
541         package ᔅᓗsḨ;
542         sub 맆 {
543             my $s = shift;
544             $s->SUPER::맆;
545         }
546     }
547     {
548         local $TODO = "Warnings not yet clean";
549         eval {ᔅᓗsḨ->맆;};
550         like ($@, qr/^Can't locate object method "맆"/, "Even with SUPER");
551     }
552     is(ᔅᓗsḨ->isa('swoosh'), '');
553 }
554
555 {
556     die if exists $::{본ㄎ};
557     $::{본ㄎ} = \"포ヰe";
558     *{"본ㄎ"} = \&{"본ㄎ"};
559     eval 'is(본ㄎ(), "포ヰe",
560              "Assignment works when glob created midway (bug 45607)"); 1'
561         or die $@;
562 }
563
564
565 # [perl #72740] - indirect object syntax, heuristically imputed due to
566 # the non-existence of a function, should not cause a stash entry to be
567 # created for the non-existent function.
568 {
569     {
570             package RƬ72740a;
571             my $f = bless({}, RƬ72740b);
572             sub s1 { s2 $f; }
573             our $s4;
574             sub s3 { s4 $f; }
575     }
576     {
577             package RƬ72740b;
578             sub s2 { "RƬ72740b::s2" }
579             sub s4 { "RƬ72740b::s4" }
580     }
581     ok(exists($RƬ72740a::{s1}), "RƬ72740a::s1 exists");
582     ok(!exists($RƬ72740a::{s2}), "RƬ72740a::s2 does not exist");
583     ok(exists($RƬ72740a::{s3}), "RƬ72740a::s3 exists");
584     ok(exists($RƬ72740a::{s4}), "RƬ72740a::s4 exists");
585     is(RƬ72740a::s1(), "RƬ72740b::s2", "RƬ72740::s1 parsed correctly");
586     is(RƬ72740a::s3(), "RƬ72740b::s4", "RƬ72740::s3 parsed correctly");
587 }
588
589 # [perl #71686] Globs that are in symbol table can be un-globbed
590 $ŚyṀ = undef;
591 $::{Ḟ앜ɞ} = *ŚyṀ;
592 is (eval 'local *::Ḟ앜ɞ = \"chuck"; $Ḟ앜ɞ', 'chuck',
593         "Localized glob didn't coerce into a RV");
594 is ($@, '', "Can localize FAKE glob that's present in stash");
595 TODO: {
596     local $TODO = q!$::{glob} = "something"; not yet clean.!;
597     is (scalar $::{Ḟ앜ɞ}, "*main::ŚyṀ",
598             "Localized FAKE glob's value was correctly restored");
599 }
600
601 # [perl #1804] *$x assignment when $x is a copy of another glob
602 # And [perl #77508] (same thing with list assignment)
603 TODO: {
604     local $TODO = "Glob/Stash stringify not yet fully clean";
605     no warnings 'once';
606     my $x = *_ràndom::glob_that_is_not_used_elsewhere;
607     *$x = sub{};
608     is(
609       "$x", '*_ràndom::glob_that_is_not_used_elsewhere',
610       '[perl #1804] *$x assignment when $x is FAKE',
611     );
612     $x = *_ràndom::glob_that_is_not_used_elsewhere;
613     (my $dummy, *$x) = (undef,[]);
614     is(
615       "$x", '*_ràndom::glob_that_is_not_used_elsewhere',
616       '[perl #77508] *$x list assignment when $x is FAKE',
617     ) or require Devel::Peek, ($TODO ? () : Devel::Peek::Dump($x));
618 }
619
620 # [perl #76540]
621 # this caused panics or 'Attempt to free unreferenced scalar'
622 # (its a compile-time issue, so the die lets us skip the prints)
623 {
624     my @warnings;
625     local $SIG{__WARN__} = sub { push @warnings, @_ };
626
627     eval <<'EOF';
628 BEGIN { $::{FÒÒ} = \'ᴮᛅ' }
629 die "made it";
630 print FÒÒ, "\n";
631 print FÒÒ, "\n";
632 EOF
633
634     like($@, qr/made it/, "#76540 - no panic");
635     ok(!@warnings, "#76540 - no 'Attempt to free unreferenced scalar'");
636 }
637
638 # [perl #77362] various bugs related to globs as PVLVs
639 TODO: {
640  local $TODO = "Glob stringify not fully clean yet.";
641  no warnings qw 'once void';
642  my %h; # We pass a key of this hash to the subroutine to get a PVLV.
643  sub { for(shift) {
644   # Set up our glob-as-PVLV
645   $_ = *hòn;
646   is $_, "*main::hòn";
647
648   # Bad symbol for array
649   ok eval{ @$_; 1 }, 'PVLV glob slots can be autovivified' or diag $@;
650
651     TODO: {
652         local $TODO = "Tie not yet clean";
653         # This should call TIEHANDLE, not TIESCALAR
654         *thèxt::TIEHANDLE = sub{};
655         ok eval{ tie *$_, 'thèxt'; 1 }, 'PVLV globs can be tied as handles'
656             or diag $@;
657     }
658   # Assigning undef to the glob should not overwrite it...
659   {
660    my $w;
661    local $SIG{__WARN__} = sub { $w = shift };
662    *$_ = undef;
663    is $_, "*main::hòn", 'PVLV: assigning undef to the glob does nothing';
664    like $w, qr\Undefined value assigned to typeglob\,
665     'PVLV: assigning undef to the glob warns';
666   }
667
668   # Neither should reference assignment.
669   *$_ = [];
670   is $_, "*main::hòn", "PVLV: arrayref assignment assigns to the AV slot";
671
672   # Concatenation should still work.
673   ok eval { $_ .= 'thlèw' }, 'PVLV concatenation does not die' or diag $@;
674   is $_, '*main::hònthlèw', 'PVLV concatenation works';
675
676   # And we should be able to overwrite it with a string, number, or refer-
677   # ence, too, if we omit the *.
678   $_ = *hòn; $_ = 'tzòr';
679   is $_, 'tzòr', 'PVLV: assigning a string over a glob';
680   $_ = *hòn; $_ = 23;
681   is $_, 23, 'PVLV: assigning an integer over a glob';
682   $_ = *hòn; $_ = 23.23;
683   is $_, 23.23, 'PVLV: assigning a float over a glob';
684   $_ = *hòn; $_ = \my $sthat;
685   is $_, \$sthat, 'PVLV: assigning a reference over a glob';
686
687   # This bug was found by code inspection. Could this ever happen in
688   # real life? :-)
689   # This duplicates a file handle, accessing it through a PVLV glob, the
690   # glob having been removed from the symbol table, so a stringified form
691   # of it does not work. This checks that sv_2io does not stringify a PVLV.
692   $_ = *quìn;
693   open *quìn, "test.pl"; # test.pl is as good a file as any
694   delete $::{quìn};
695   ok eval { open my $zow, "<&", $_ }, 'PVLV: sv_2io stringifieth not'
696    or diag $@;
697
698   # Similar tests to make sure sv_2cv etc. do not stringify.
699   *$_ = sub { 1 };
700   ok eval { &$_ }, "PVLV glob can be called as a sub" or diag $@;
701   *flèlp = sub { 2 };
702   $_ = 'flèlp';
703   is eval { &$_ }, 2, 'PVLV holding a string can be called as a sub'
704    or diag $@;
705
706   # Coderef-to-glob assignment when the glob is no longer accessible
707   # under its name: These tests are to make sure the OPpASSIGN_CV_TO_GV
708   # optimisation takes PVLVs into account, which is why the RHSs have to be
709   # named subs.
710   use constant ghèèn => 'quàrè';
711   $_ = *mìng;
712   delete $::{mìng};
713   *$_ = \&ghèèn;
714   is eval { &$_ }, 'quàrè',
715    'PVLV: constant assignment when the glob is detached from the symtab'
716     or diag $@;
717   $_ = *bèngth;
718   delete $::{bèngth};
719   *ghèck = sub { 'lon' };
720   *$_ = \&ghèck;
721   is eval { &$_ }, 'lon',
722    'PVLV: coderef assignment when the glob is detached from the symtab'
723     or diag $@;
724
725 SKIP: {
726     skip_if_miniperl("no dynamic loading on miniperl, so can't load PerlIO::scalar", 1);
727     # open should accept a PVLV as its first argument
728     $_ = *hòn;
729     ok eval { open $_,'<', \my $thlext }, 'PVLV can be the first arg to open'
730         or diag $@;
731   }
732
733   # -t should not stringify
734   $_ = *thlìt; delete $::{thlìt};
735   *$_ = *STDOUT{IO};
736   ok defined -t $_, 'PVLV: -t does not stringify';
737
738   # neither should -T
739   # but some systems donâ\80\99t support this on file handles
740   my $pass;
741   ok
742     eval {
743      open my $quìle, "<", 'test.pl';
744      $_ = *$quìle;
745      $pass = -T $_;
746      1
747     } ? $pass : $@ =~ /not implemented on filehandles/,
748    "PVLV: -T does not stringify";
749   # Unopened file handle
750   {
751    my $w;
752    local $SIG{__WARN__} = sub { $w .= shift };
753    $_ = *vòr;
754    close $_;
755    like $w, qr\unopened filehandle vòr\,
756     'PVLV globs get their names reported in unopened error messages';
757   }
758
759  }}->($h{k});
760 }
761
762 *àieee = 4;
763 pass('Can assign integers to typeglobs');
764 *àieee = 3.14;
765 pass('Can assign floats to typeglobs');
766 *àieee = 'pi';
767 pass('Can assign strings to typeglobs');
768
769
770 {
771   package thrèxt;
772   sub TIESCALAR{bless[]}
773   sub STORE{ die "No!"}
774   sub FETCH{ no warnings 'once'; *thrìt }
775   tie my $a, "thrèxt";
776   () = "$a"; # do a fetch; now $a holds a glob
777   eval { *$a = sub{} };
778   untie $a;
779   eval { $a = "ᴮᛅ" };
780   ::is $a, "ᴮᛅ",
781     "[perl #77812] Globs in tied scalars can be reified if STORE dies"
782 }
783
784 # These two crashed prior to 5.13.6. In 5.13.6 they were fatal errors. They
785 # were fixed in 5.13.7.
786 ok eval {
787   my $glob = \*hèèn::ISA;
788   delete $::{"hèèn::"};
789   *$glob = *ᴮᛅ; 
790 }, "glob-to-*ISA assignment works when *ISA has lost its stash";
791 ok eval {
792   my $glob = \*slàre::ISA;
793   delete $::{"slàre::"};
794   *$glob = []; 
795 }, "array-to-*ISA assignment works when *ISA has lost its stash";
796 # These two crashed in 5.13.6. They were likewise fixed in 5.13.7.
797 ok eval {
798   sub grèck;
799   my $glob = do { no warnings "once"; \*phìng::ᕘ};
800   delete $::{"phìng::"};
801   *$glob = *grèck; 
802 }, "Assigning a glob-with-sub to a glob that has lost its stash warks";
803 ok eval {
804   sub pòn::ᕘ;
805   my $glob = \*pòn::ᕘ;
806   delete $::{"pòn::"};
807   *$glob = *ᕘ; 
808 }, "Assigning a glob to a glob-with-sub that has lost its stash warks";
809
810 {
811   package Tie::Alias;
812   sub TIESCALAR{ bless \\pop }
813   sub FETCH { $${$_[0]} }
814   sub STORE { $${$_[0]} = $_[1] }
815   package main;
816   tie my $alias, 'Tie::Alias', my $var;
817   no warnings 'once';
818   $var = *gàlobbe;
819   {
820     local *$alias = [];
821     $var = 3;
822     is $alias, 3, "[perl #77926] Glob reification during localisation";
823   }
824 }
825
826 # This code causes gp_free to call a destructor when a glob is being
827 # restored on scope exit. The destructor used to see SVs with a refcount of
828 # zero inside the glob, which could result in crashes (though not in this
829 # test case, which just panics).
830 {
831  no warnings 'once';
832  my $survived;
833  *Trìt::DESTROY = sub {
834    $thwèxt = 42;  # panic
835    $survived = 1;
836  };
837  {
838   local *thwèxt = bless [],'Trìt';
839   ();
840  }
841  ok $survived,
842   'no error when gp_free calls a destructor that assigns to the gv';
843 }
844
845 __END__
846 Perl
847 Rules
848 perl
849 rocks