t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10
  11 my ($Null, $Curdir);
  12 if(eval {require File::Spec; 1}) {
  13     $Null = File::Spec->devnull;
  14     $Curdir = File::Spec->curdir;
  15 } else {
  16     die $@ unless is_miniperl();
  17     $Curdir = '.';
  18     diag("miniperl failed to load File::Spec, error is:\n$@");
  19     diag("\ncontinuing, assuming '.' for current directory. Some tests will be skipped.");
  20 }
  21
  22
  23 plan tests => 113;
  24
  25 my $Perl = which_perl();
  26
  27 $ENV{LC_ALL}   = 'C';           # Forge English error messages.
  28 $ENV{LANGUAGE} = 'C';           # Ditto in GNU.
  29
  30 $Is_Amiga   = $^O eq 'amigaos';
  31 $Is_Cygwin  = $^O eq 'cygwin';
  32 $Is_Darwin  = $^O eq 'darwin';
  33 $Is_Dos     = $^O eq 'dos';
  34 $Is_MPE     = $^O eq 'mpeix';
  35 $Is_MSWin32 = $^O eq 'MSWin32';
  36 $Is_NetWare = $^O eq 'NetWare';
  37 $Is_OS2     = $^O eq 'os2';
  38 $Is_Solaris = $^O eq 'solaris';
  39 $Is_VMS     = $^O eq 'VMS';
  40 $Is_DGUX    = $^O eq 'dgux';
  41 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
  42 $Is_Rhapsody= $^O eq 'rhapsody';
  43
  44 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare;
  45
  46 $Is_UFS     = $Is_Darwin && (() = `df -t ufs . 2>/dev/null`) == 2;
  47
  48 if ($Is_Cygwin) {
  49   require Win32;
  50   Win32->import;
  51 }
  52
  53 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  54    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  55
  56 my $tmpfile = tempfile();
  57 my $tmpfile_link = tempfile();
  58
  59 chmod 0666, $tmpfile;
  60 unlink_all $tmpfile;
  61 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  62 close FOO;
  63
  64 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  65
  66 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  67
  68 # The clock on a network filesystem might be different from the
  69 # system clock.
  70 my $Filesystem_Time_Offset = abs($mtime - time);
  71
  72 #nlink should if link support configured in Perl.
  73 SKIP: {
  74     skip "No link count - Hard link support not built in.", 1
  75         unless $Config{d_link};
  76
  77     is($nlink, 1, 'nlink on regular file');
  78 }
  79
  80 SKIP: {
  81   skip "mtime and ctime not reliable", 2
  82     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_Darwin;
  83
  84   ok( $mtime,           'mtime' );
  85   is( $mtime, $ctime,   'mtime == ctime' );
  86 }
  87
  88
  89 # Cygwin seems to have a 3 second granularity on its timestamps.
  90 my $funky_FAT_timestamps = $Is_Cygwin;
  91 sleep 3 if $funky_FAT_timestamps;
  92
  93 print FOO "Now is the time for all good men to come to.\n";
  94 close(FOO);
  95
  96 sleep 2;
  97
  98
  99 SKIP: {
 100     unlink $tmpfile_link;
 101     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
 102     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
 103
 104     is( $@, '',         'link() implemented' );
 105     ok( $lnk_result,    'linked tmp testfile' );
 106     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
 107
 108     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
 109
 110     SKIP: {
 111         skip "No link count", 1 if $Config{dont_use_nlink};
 112         skip "Cygwin9X fakes hard links by copying", 1
 113           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
 114
 115         is($nlink, 2,     'Link count on hard linked file' );
 116     }
 117
 118     SKIP: {
 119         skip_if_miniperl("File::Spec not built for minitest", 2);
 120         my $cwd = File::Spec->rel2abs($Curdir);
 121         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
 122                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
 123                                         $mtime && $mtime == $ctime;
 124         skip "AFS has different mtime/ctime link semantics", 2
 125                                      if $cwd =~ m#$Config{'afsroot'}/#;
 126         skip "AmigaOS has different mtime/ctime link semantics", 2
 127                                      if $Is_Amiga;
 128         # Win32 could pass $mtime test but as FAT and NTFS have
 129         # no ctime concept $ctime is ALWAYS == $mtime
 130         # expect netware to be the same ...
 131         skip "No ctime concept on this OS", 2
 132                                      if $Is_MSWin32 ||
 133                                         ($Is_Darwin && $Is_UFS);
 134
 135         if( !ok($mtime, 'hard link mtime') ||
 136             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 137             print STDERR <<DIAG;
 138 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 139 # has this problem.  Building on the ClearCase VOBS filesystem may also
 140 # cause this failure.
 141 #
 142 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
 143 # this test.
 144 DIAG
 145         }
 146     }
 147
 148 }
 149
 150 # truncate and touch $tmpfile.
 151 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 152 ok(-z \*F,     '-z on empty filehandle');
 153 ok(! -s \*F,   '   and -s');
 154 close F;
 155
 156 ok(-z $tmpfile,     '-z on empty file');
 157 ok(! -s $tmpfile,   '   and -s');
 158
 159 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 160 print F "hi\n";
 161 close F;
 162
 163 open(F, "<$tmpfile") || DIE("Can't open temp test file: $!");
 164 ok(!-z *F,     '-z on empty filehandle');
 165 ok( -s *F,   '   and -s');
 166 close F;
 167
 168 ok(! -z $tmpfile,   '-z on non-empty file');
 169 ok(-s $tmpfile,     '   and -s');
 170
 171
 172 # Strip all access rights from the file.
 173 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 174
 175 SKIP: {
 176     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 177
 178     SKIP: {
 179         # Going to try to switch away from root.  Might not work.
 180         my $olduid = $>;
 181         eval { $> = 1; };
 182         skip "Can't test -r or -w meaningfully if you're superuser", 2
 183           if ($Is_Cygwin ? Win32::IsAdminUser : $> == 0);
 184
 185         SKIP: {
 186             skip "Can't test -r meaningfully?", 1 if $Is_Dos;
 187             ok(!-r $tmpfile,    "   -r");
 188         }
 189
 190         ok(!-w $tmpfile,    "   -w");
 191
 192         # switch uid back (may not be implemented)
 193         eval { $> = $olduid; };
 194     }
 195
 196     ok(! -x $tmpfile,   '   -x');
 197 }
 198
 199
 200
 201 ok(chmod(0700,$tmpfile),    'chmod 0700');
 202 ok(-r $tmpfile,     '   -r');
 203 ok(-w $tmpfile,     '   -w');
 204
 205 SKIP: {
 206     skip "-x simply determines if a file ends in an executable suffix", 1
 207       if $Is_Dosish;
 208
 209     ok(-x $tmpfile,     '   -x');
 210 }
 211
 212 ok(  -f $tmpfile,   '   -f');
 213 ok(! -d $tmpfile,   '   !-d');
 214
 215 # Is this portable?
 216 ok(  -d '.',          '-d cwd' );
 217 ok(! -f '.',          '!-f cwd' );
 218
 219
 220 SKIP: {
 221     unlink($tmpfile_link);
 222     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 223     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 224
 225     is( $@, '',     'symlink() implemented' );
 226     ok( $symlink_rslt,      'symlink() ok' );
 227     ok(-l $tmpfile_link,    '-l');
 228 }
 229
 230 ok(-o $tmpfile,     '-o');
 231
 232 ok(-e $tmpfile,     '-e');
 233
 234 unlink($tmpfile_link);
 235 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 236
 237 SKIP: {
 238     skip "No character, socket or block special files", 6
 239       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 240     skip "/dev isn't available to test against", 6
 241       unless -d '/dev' && -r '/dev' && -x '/dev';
 242     skip "Skipping: unexpected ls output in MP-RAS", 6
 243       if $Is_MPRAS;
 244
 245     # VMS problem:  If GNV or other UNIX like tool is installed, then
 246     # sometimes Perl will find /bin/ls, and will try to run it.
 247     # But since Perl on VMS does not know to run it under Bash, it will
 248     # try to run the DCL verb LS.  And if the VMS product Language
 249     # Sensitive Editor is installed, or some other LS verb, that will
 250     # be run instead.  So do not do this until we can teach Perl
 251     # when to use BASH on VMS.
 252     skip "ls command not available to Perl in OpenVMS right now.", 6
 253       if $Is_VMS;
 254
 255     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 256     my $CMD = "$LS /dev 2>/dev/null";
 257     my $DEV = qx($CMD);
 258
 259     skip "$CMD failed", 6 if $DEV eq '';
 260
 261     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 262
 263     skip "opendir failed: $!", 6 if @DEV == 0;
 264
 265     # /dev/stdout might be either character special or a named pipe,
 266     # or a symlink, or a socket, depending on which OS and how are
 267     # you running the test, so let's censor that one away.
 268     # Similar remarks hold for stderr.
 269     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 270     @DEV =  grep { $_ ne 'stdout' } @DEV;
 271     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 272     @DEV =  grep { $_ ne 'stderr' } @DEV;
 273
 274     # /dev/printer is also naughty: in IRIX it shows up as
 275     # Srwx-----, not srwx------.
 276     $DEV =~ s{^.+?\sprinter$}{}m;
 277     @DEV =  grep { $_ ne 'printer' } @DEV;
 278
 279     # If running as root, we will see .files in the ls result,
 280     # and readdir() will see them always.  Potential for conflict,
 281     # so let's weed them out.
 282     $DEV =~ s{^.+?\s\..+?$}{}m;
 283     @DEV =  grep { ! m{^\..+$} } @DEV;
 284
 285     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
 286     if ($^O eq 'irix') {
 287         $DEV =~ s{^S(.+?)}{s$1}mg;
 288     }
 289
 290     my $try = sub {
 291         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 292         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 293         my $c1 = scalar @c1;
 294         my $c2 = scalar @c2;
 295         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 296     };
 297
 298 SKIP: {
 299     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
 300
 301     $try->('b', '-b');
 302     $try->('c', '-c');
 303     $try->('s', '-S');
 304
 305 }
 306
 307 ok(! -b $Curdir,    '!-b cwd');
 308 ok(! -c $Curdir,    '!-c cwd');
 309 ok(! -S $Curdir,    '!-S cwd');
 310
 311 }
 312
 313 SKIP: {
 314     my($cnt, $uid);
 315     $cnt = $uid = 0;
 316
 317     # Find a set of directories that's very likely to have setuid files
 318     # but not likely to be *all* setuid files.
 319     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 320     skip "Can't find a setuid file to test with", 3 unless @bin;
 321
 322     for my $bin (@bin) {
 323         opendir BIN, $bin or die "Can't opendir $bin: $!";
 324         while (defined($_ = readdir BIN)) {
 325             $_ = "$bin/$_";
 326             $cnt++;
 327             $uid++ if -u;
 328             last if $uid && $uid < $cnt;
 329         }
 330     }
 331     closedir BIN;
 332
 333     skip "No setuid programs", 3 if $uid == 0;
 334
 335     isnt($cnt, 0,    'found some programs');
 336     isnt($uid, 0,    '  found some setuid programs');
 337     ok($uid < $cnt,  "    they're not all setuid");
 338 }
 339
 340
 341 # To assist in automated testing when a controlling terminal (/dev/tty)
 342 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 343 # can be set to skip the tests that need a tty.
 344 SKIP: {
 345     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 346
 347     my $TTY = $Is_Rhapsody ? "/dev/ttyp0" : "/dev/tty";
 348
 349     SKIP: {
 350         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 351         skip "No TTY to test -t with", 2 unless -e $TTY;
 352
 353         open(TTY, $TTY) ||
 354           warn "Can't open $TTY--run t/TEST outside of make.\n";
 355         ok(-t TTY,  '-t');
 356         ok(-c TTY,  'tty is -c');
 357         close(TTY);
 358     }
 359     ok(! -t TTY,    '!-t on closed TTY filehandle');
 360
 361     {
 362         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 363         ok(-t,          '-t on STDIN');
 364     }
 365 }
 366
 367 SKIP: {
 368     skip "No null device to test with", 1 unless -e $Null;
 369     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 370
 371     open(NULL, $Null) or DIE("Can't open $Null: $!");
 372     ok(! -t NULL,   'null device is not a TTY');
 373     close(NULL);
 374 }
 375
 376
 377 # These aren't strictly "stat" calls, but so what?
 378 my $statfile = './op/stat.t';
 379 ok(  -T $statfile,    '-T');
 380 ok(! -B $statfile,    '!-B');
 381
 382 SKIP: {
 383      skip("DG/UX", 1) if $Is_DGUX;
 384 ok(-B $Perl,      '-B');
 385 }
 386
 387 ok(! -T $Perl,    '!-T');
 388
 389 open(FOO,$statfile);
 390 SKIP: {
 391     eval { -T FOO; };
 392     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 393
 394     is( $@, '',     '-T on filehandle causes no errors' );
 395
 396     ok(-T FOO,      '   -T');
 397     ok(! -B FOO,    '   !-B');
 398
 399     $_ = <FOO>;
 400     like($_, qr/perl/, 'after readline');
 401     ok(-T FOO,      '   still -T');
 402     ok(! -B FOO,    '   still -B');
 403     close(FOO);
 404
 405     open(FOO,$statfile);
 406     $_ = <FOO>;
 407     like($_, qr/perl/,      'reopened and after readline');
 408     ok(-T FOO,      '   still -T');
 409     ok(! -B FOO,    '   still !-B');
 410
 411     ok(seek(FOO,0,0),   'after seek');
 412     ok(-T FOO,          '   still -T');
 413     ok(! -B FOO,        '   still !-B');
 414
 415     # It's documented this way in perlfunc *shrug*
 416     () = <FOO>;
 417     ok(eof FOO,         'at EOF');
 418     ok(-T FOO,          '   still -T');
 419     ok(-B FOO,          '   now -B');
 420 }
 421 close(FOO);
 422
 423
 424 SKIP: {
 425     skip "No null device to test with", 2 unless -e $Null;
 426
 427     ok(-T $Null,  'null device is -T');
 428     ok(-B $Null,  '    and -B');
 429 }
 430
 431
 432 # and now, a few parsing tests:
 433 $_ = $tmpfile;
 434 ok(-f,      'bare -f   uses $_');
 435 ok(-f(),    '     -f() "');
 436
 437 unlink $tmpfile or print "# unlink failed: $!\n";
 438
 439 # bug id 20011101.069
 440 my @r = \stat($Curdir);
 441 is(scalar @r, 13,   'stat returns full 13 elements');
 442
 443 stat $0;
 444 eval { lstat _ };
 445 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 446     'lstat _ croaks after stat' );
 447 eval { lstat *_ };
 448 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 449     'lstat *_ croaks after stat' );
 450 eval { lstat \*_ };
 451 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 452     'lstat \*_ croaks after stat' );
 453 eval { -l _ };
 454 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 455     '-l _ croaks after stat' );
 456
 457 lstat $0;
 458 eval { lstat _ };
 459 is( "$@", "", "lstat _ ok after lstat" );
 460 eval { -l _ };
 461 is( "$@", "", "-l _ ok after lstat" );
 462
 463 eval { lstat "test.pl" };
 464 {
 465     open my $fh, "test.pl";
 466     stat *$fh{IO};
 467     eval { lstat _ }
 468 }
 469 like $@, qr/^The stat preceding lstat\(\) wasn't an lstat at /,
 470 'stat $ioref resets stat type';
 471
 472 {
 473     my @statbuf = stat STDOUT;
 474     stat "test.pl";
 475     my @lstatbuf = lstat *STDOUT{IO};
 476     is "@lstatbuf", "@statbuf", 'lstat $ioref reverts to regular fstat';
 477 }
 478
 479 SKIP: {
 480     skip "No lstat", 2 unless $Config{d_lstat};
 481
 482     # bug id 20020124.004
 483     # If we have d_lstat, we should have symlink()
 484     my $linkname = 'stat-' . rand =~ y/.//dr;
 485     my $target = $Perl;
 486     $target =~ s/;\d+\z// if $Is_VMS; # symlinks don't like version numbers
 487     symlink $target, $linkname or die "# Can't symlink $0: $!";
 488     lstat $linkname;
 489     -T _;
 490     eval { lstat _ };
 491     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 492         'lstat croaks after -T _' );
 493     eval { -l _ };
 494     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 495         '-l _ croaks after -T _' );
 496     unlink $linkname or print "# unlink $linkname failed: $!\n";
 497 }
 498
 499 SKIP: {
 500     skip "Too much clock skew between system and filesystem", 5
 501         if ($Filesystem_Time_Offset > 5);
 502     print "# Zzz...\n";
 503     sleep($Filesystem_Time_Offset+1);
 504     my $f = 'tstamp.tmp';
 505     unlink $f;
 506     ok (open(S, "> $f"), 'can create tmp file');
 507     close S or die;
 508     my @a = stat $f;
 509     print "# time=$^T, stat=(@a)\n";
 510     my @b = (-M _, -A _, -C _);
 511     print "# -MAC=(@b)\n";
 512     ok( (-M _) < 0, 'negative -M works');
 513     ok( (-A _) < 0, 'negative -A works');
 514     ok( (-C _) < 0, 'negative -C works');
 515     ok(unlink($f), 'unlink tmp file');
 516 }
 517
 518 # [perl #4253]
 519 {
 520     ok(open(F, ">", $tmpfile), 'can create temp file');
 521     close F;
 522     chmod 0077, $tmpfile;
 523     my @a = stat($tmpfile);
 524     my $s1 = -s _;
 525     -T _;
 526     my $s2 = -s _;
 527     is($s1, $s2, q(-T _ doesn't break the statbuffer));
 528     SKIP: {
 529         skip "No lstat", 1 unless $Config{d_lstat};
 530         skip "uid=0", 1 unless $<&&$>;
 531         skip "Readable by group/other means readable by me", 1 if $^O eq 'VMS';
 532         lstat($tmpfile);
 533         -T _;
 534         ok(eval { lstat _ },
 535            q(-T _ doesn't break lstat for unreadable file));
 536     }
 537     unlink $tmpfile;
 538 }
 539
 540 SKIP: {
 541     skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 542     ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 543     ok(stat(DIR), "stat() on dirhandle works");
 544     ok(-d -r _ , "chained -x's on dirhandle");
 545     ok(-d DIR, "-d on a dirhandle works");
 546
 547     # And now for the ambiguous bareword case
 548     {
 549         no warnings 'deprecated';
 550         ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 551             || diag "Can't open 'TEST':  $!";
 552     }
 553     my $size = (stat(DIR))[7];
 554     ok(defined $size, "stat() on bareword works");
 555     is($size, -s "TEST", "size returned by stat of bareword is for the file");
 556     ok(-f _, "ambiguous bareword uses file handle, not dir handle");
 557     ok(-f DIR);
 558     closedir DIR or die $!;
 559     close DIR or die $!;
 560 }
 561
 562 {
 563     # RT #8244: *FILE{IO} does not behave like *FILE for stat() and -X() operators
 564     ok(open(F, ">", $tmpfile), 'can create temp file');
 565     my @thwap = stat *F{IO};
 566     ok(@thwap, "stat(*F{IO}) works");
 567     ok( -f *F{IO} , "single file tests work with *F{IO}");
 568     close F;
 569     unlink $tmpfile;
 570
 571     #PVIO's hold dirhandle information, so let's test them too.
 572
 573     SKIP: {
 574         skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 575         ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 576         ok(stat(*DIR{IO}), "stat() on *DIR{IO} works");
 577         ok(-d _ , "The special file handle _ is set correctly");
 578         ok(-d -r *DIR{IO} , "chained -x's on *DIR{IO}");
 579
 580         # And now for the ambiguous bareword case
 581         {
 582             no warnings 'deprecated';
 583             ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 584                 || diag "Can't open 'TEST':  $!";
 585         }
 586         my $size = (stat(*DIR{IO}))[7];
 587         ok(defined $size, "stat() on *THINGY{IO} works");
 588         is($size, -s "TEST",
 589            "size returned by stat of *THINGY{IO} is for the file");
 590         ok(-f _, "ambiguous *THINGY{IO} uses file handle, not dir handle");
 591         ok(-f *DIR{IO});
 592         closedir DIR or die $!;
 593         close DIR or die $!;
 594     }
 595 }
 596
 597 # [perl #71002]
 598 {
 599     local $^W = 1;
 600     my $w;
 601     local $SIG{__WARN__} = sub { warn shift; ++$w };
 602     stat 'prepeinamehyparcheiarcheiometoonomaavto';
 603     stat _;
 604     is $w, undef, 'no unopened warning from stat _';
 605 }
 606
 607 END {
 608     chmod 0666, $tmpfile;
 609     unlink_all $tmpfile;
 610 }