This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Someone actually reads the Makefile.PL messages, it seems.
[perl5.git] / ext / Time / HiRes / Makefile.PL
1
2 # See lib/ExtUtils/MakeMaker.pm for details of how to influence
3 # the contents of the Makefile that is written.
4 #
5
6 require 5.002;
7
8 use Config;
9 use ExtUtils::MakeMaker;
10 use strict;
11
12 my $VERBOSE = $ENV{VERBOSE};
13 my $DEFINE;
14 my $LIBS = [];
15 my $XSOPT;
16
17 use vars qw($self); # Used in 'sourcing' the hints.
18
19 my $ld_exeext = ($^O eq 'os2' and $Config{ldflags} =~ /-Zexe\b/) ? '.exe' : '';
20
21 unless($ENV{PERL_CORE}) {
22     $ENV{PERL_CORE} = 1 if grep { $_ eq 'PERL_CORE=1' } @ARGV;
23 }
24
25 # Perls 5.002 and 5.003 did not have File::Spec, fake what we need.
26
27 sub my_dirsep {
28     $^O eq 'VMS' ? '.' :
29         $^O =~ /mswin32|netware|djgpp/i ? '\\' :
30             $^O eq 'MacOS' ? ':'
31                 : '/';
32 }
33
34 sub my_catdir {
35     shift;
36     my $catdir = join(my_dirsep, @_);
37     $^O eq 'VMS' ? "[$catdir]" : $catdir;
38 }
39
40 sub my_catfile {
41     shift;
42     return join(my_dirsep, @_) unless $^O eq 'VMS';
43     my $file = pop;
44     return my_catdir (undef, @_) . $file;
45 }
46
47 sub my_updir {
48     shift;
49     $^O eq 'VMS' ? "-" : "..";
50 }
51
52 BEGIN {
53     eval { require File::Spec };
54     if ($@) {
55         *File::Spec::catdir  = \&my_catdir;
56         *File::Spec::updir   = \&my_updir;
57         *File::Spec::catfile = \&my_catfile;
58     }
59 }
60
61 # Avoid 'used only once' warnings.
62 my $nop1 = *File::Spec::catdir;
63 my $nop2 = *File::Spec::updir;
64 my $nop3 = *File::Spec::catfile;
65
66 # if you have 5.004_03 (and some slightly older versions?), xsubpp
67 # tries to generate line numbers in the C code generated from the .xs.
68 # unfortunately, it is a little buggy around #ifdef'd code.
69 # my choice is leave it in and have people with old perls complain
70 # about the "Usage" bug, or leave it out and be unable to compile myself
71 # without changing it, and then I'd always forget to change it before a
72 # release. Sorry, Edward :)
73
74 sub TMPDIR {
75     my $TMPDIR =
76         (grep(defined $_ && -d $_ && -w _,
77               ((defined $ENV{'TMPDIR'} ? $ENV{'TMPDIR'} : undef),
78                qw(/var/tmp /usr/tmp /tmp c:/temp))))[0];
79     $TMPDIR || die "Cannot find writable temporary directory.\n";
80 }
81
82 sub try_compile_and_link {
83     my ($c, %args) = @_;
84
85     my ($ok) = 0;
86     my ($tmp) = (($^O eq 'VMS') ? "sys\$scratch:tmp$$" : TMPDIR() . '/' . "tmp$$");
87     local(*TMPC);
88
89     my $obj_ext = $Config{obj_ext} || ".o";
90     unlink("$tmp.c", "$tmp$obj_ext");
91
92     if (open(TMPC, ">$tmp.c")) {
93         print TMPC $c;
94         close(TMPC);
95
96         my $cccmd = $args{cccmd};
97
98         my $errornull;
99
100         my $COREincdir;
101
102         if ($ENV{PERL_CORE}) {
103             my $updir = File::Spec->updir;
104             $COREincdir = File::Spec->catdir(($updir) x 3);
105         } else {
106             $COREincdir = File::Spec->catdir($Config{'archlibexp'}, 'CORE');
107         }
108
109         my $ccflags = $Config{'ccflags'} . ' ' . "-I$COREincdir";
110
111         if ($^O eq 'VMS') {
112             if ($ENV{PERL_CORE}) {
113                 # Fragile if the extensions change hierachy within
114                 # the Perl core but this should do for now.
115                 $cccmd = "$Config{'cc'} /include=([---]) $tmp.c";
116             } else {
117                 my $perl_core = $Config{'installarchlib'};
118                 $perl_core =~ s/\]$/.CORE]/;
119                 $cccmd = "$Config{'cc'} /include=(perl_root:[000000],$perl_core) $tmp.c";
120             }
121         }
122
123         if ($args{silent} || !$VERBOSE) {
124             $errornull = "2>/dev/null" unless defined $errornull;
125         } else {
126             $errornull = '';
127         }
128
129         $cccmd = "$Config{'cc'} -o $tmp $ccflags $tmp.c @$LIBS $errornull"
130             unless defined $cccmd;
131
132        if ($^O eq 'VMS') {
133             open( CMDFILE, ">$tmp.com" );
134             print CMDFILE "\$ SET MESSAGE/NOFACILITY/NOSEVERITY/NOIDENT/NOTEXT\n";
135             print CMDFILE "\$ $cccmd\n";
136             print CMDFILE "\$ IF \$SEVERITY .NE. 1 THEN EXIT 44\n"; # escalate
137             close CMDFILE;
138             system("\@ $tmp.com");
139             $ok = $?==0;
140             for ("$tmp.c", "$tmp$obj_ext", "$tmp.com", "$tmp$Config{exe_ext}") {
141                 1 while unlink $_;
142             }
143         }
144         else
145         {
146             my $tmp_exe = "$tmp$ld_exeext";
147             printf "cccmd = $cccmd\n" if $VERBOSE;
148             my $res = system($cccmd);
149             $ok = defined($res) && $res==0 && -s $tmp_exe && -x _;
150             unlink("$tmp.c", $tmp_exe);
151         }
152     }
153
154     $ok;
155 }
156
157 sub has_gettimeofday {
158     # confusing but true (if condition true ==> -DHAS_GETTIMEOFDAY already)
159     return 0 if $Config{d_gettimeod} eq 'define';
160     return 1 if try_compile_and_link(<<EOM);
161 #include "EXTERN.h"
162 #include "perl.h"
163 #include "XSUB.h"
164 #ifdef I_SYS_TYPES
165 #   include <sys/types.h>
166 #endif
167
168 #ifdef I_SYS_TIME
169 #   include <sys/time.h>
170 #endif
171
172 #ifdef I_SYS_SELECT
173 #   include <sys/select.h>      /* struct timeval might be hidden in here */
174 #endif
175 static int foo()
176 {
177     struct timeval tv;
178     gettimeofday(&tv, 0);
179 }
180 int main _((int argc, char** argv, char** env))
181 {
182     foo();
183 }
184 EOM
185     return 0;
186 }
187
188 sub has_x {
189     my ($x, %args) = @_;
190
191     return 1 if
192     try_compile_and_link(<<EOM, %args);
193 #include "EXTERN.h"
194 #include "perl.h"
195 #include "XSUB.h"
196
197 #ifdef I_UNISTD
198 #   include <unistd.h>
199 #endif
200
201 #ifdef I_SYS_TYPES
202 #   include <sys/types.h>
203 #endif
204
205 #ifdef I_SYS_TIME
206 #   include <sys/time.h>
207 #endif
208
209 int main _((int argc, char** argv, char** env))
210 {
211         $x;
212 }
213 EOM
214     return 0;
215 }
216
217 sub init {
218     my $hints = File::Spec->catfile("hints", "$^O.pl");
219     if (-f $hints) {
220         print "Using hints $hints...\n";
221         local $self;
222         do $hints;
223         if (exists $self->{LIBS}) {
224             $LIBS = $self->{LIBS};
225             print "Extra libraries: @$LIBS...\n";
226         }
227     }
228
229     $DEFINE = '';
230
231     print "Looking for gettimeofday()... ";
232     my $has_gettimeofday;
233     if (exists $Config{d_gettimeod}) {
234         $has_gettimeofday++ if $Config{d_gettimeod};
235     } elsif (has_gettimeofday()) {
236         $DEFINE .= ' -DHAS_GETTIMEOFDAY';
237         $has_gettimeofday++;
238     }
239
240     if ($has_gettimeofday) {
241         print "found.\n";
242     } else {
243         die <<EOD
244 Your operating system does not seem to have the gettimeofday() function.
245 (or, at least, I cannot find it)
246
247 There is no way Time::HiRes is going to work.
248
249 I am awfully sorry but I cannot go further.
250
251 Aborting configuration.
252
253 EOD
254     }
255
256     print "Looking for setitimer()... ";
257     my $has_setitimer;
258     if (exists $Config{d_setitimer}) {
259         $has_setitimer++ if $Config{d_setitimer};
260     } elsif (has_x("setitimer(ITIMER_REAL, 0, 0)")) {
261         $has_setitimer++;
262         $DEFINE .= ' -DHAS_SETITIMER';
263     }
264
265     if ($has_setitimer) {
266         print "found.\n";
267     } else {
268         print "NOT found.\n";
269     }
270
271     print "Looking for getitimer()... ";
272     my $has_getitimer;
273     if (exists $Config{'d_getitimer'}) {
274         $has_getitimer++ if $Config{'d_getitimer'};
275     } elsif (has_x("getitimer(ITIMER_REAL, 0)")) {
276         $has_getitimer++;
277         $DEFINE .= ' -DHAS_GETITIMER';
278     }
279
280     if ($has_getitimer) {
281         print "found.\n";
282     } else {
283         print "NOT found.\n";
284     }
285
286     if ($has_setitimer && $has_getitimer) {
287         print "You have interval timers (both setitimer and getitimer).\n";
288     } else {
289         print "You do not have interval timers.\n";
290     }
291
292     print "Looking for ualarm()... ";
293     my $has_ualarm;
294     if (exists $Config{d_ualarm}) {
295         $has_ualarm++ if $Config{d_ualarm};
296     } elsif (has_x ("ualarm (0, 0)")) {
297         $has_ualarm++;
298         $DEFINE .= ' -DHAS_UALARM';
299     }
300
301     if ($has_ualarm) {
302         print "found.\n";
303     } else {
304         print "NOT found.\n";
305         if ($has_setitimer) {
306             print "But you have setitimer().\n";
307             print "We can make a Time::HiRes::ualarm().\n";
308         }
309     }
310
311     print "Looking for usleep()... ";
312     my $has_usleep;
313     if (exists $Config{d_usleep}) {
314         $has_usleep++ if $Config{d_usleep};
315     } elsif (has_x ("usleep (0)")) {
316         $has_usleep++;
317         $DEFINE .= ' -DHAS_USLEEP';
318     }
319
320     if ($has_usleep) {
321         print "found.\n";
322     } else {
323         print "NOT found.\n";
324         print "Let's see if you have select()... ";
325         if ($Config{'d_select'} eq 'define') {
326             print "found.\n";
327             print "We can make a Time::HiRes::usleep().\n";
328         } else {
329             print "NOT found.\n";
330             print "You won't have a Time::HiRes::usleep().\n";
331         }
332     }
333
334     print "Looking for nanosleep()... ";
335     my $has_nanosleep;
336     if (exists $Config{d_nanosleep}) {
337         if ($Config{d_nanosleep}) {
338             $has_nanosleep++;
339             $DEFINE .= ' -DTIME_HIRES_NANOSLEEP';
340         }
341     } elsif ($^O ne 'mpeix' && # MPE/iX falsely finds nanosleep.
342              has_x ("nanosleep (NULL, NULL)")) {
343         $has_nanosleep++;
344         $DEFINE .= ' -DTIME_HIRES_NANOSLEEP';
345     }
346
347     if ($has_nanosleep) {
348         print "found.\n";
349         print "You can mix subsecond sleeps with signals.\n";
350     } else {
351         print "NOT found.\n";
352         my $nt = ($^O eq 'os2' ? '' : 'not');
353         print "You can$nt mix subsecond sleeps with signals.\n";
354     }
355
356     if ($DEFINE) {
357         $DEFINE =~ s/^\s+//;
358         if (open(XDEFINE, ">xdefine")) {
359             print XDEFINE $DEFINE, "\n";
360             close(XDEFINE);
361         }
362     }
363 }
364
365 sub doMakefile {
366     my @makefileopts = ();
367
368     if ($] >= 5.005) {
369         push (@makefileopts,
370             'AUTHOR'    => 'Jarkko Hietaniemi <jhi@iki.fi>',
371             'ABSTRACT_FROM' => 'HiRes.pm',
372         );
373         $DEFINE .= " -DATLEASTFIVEOHOHFIVE";
374     }
375
376     push (@makefileopts,
377         'NAME'  => 'Time::HiRes',
378         'VERSION_FROM' => 'HiRes.pm', # finds $VERSION
379         'LIBS'  => $LIBS,   # e.g., '-lm'
380         'DEFINE'        => $DEFINE,     # e.g., '-DHAS_SOMETHING'
381         'XSOPT' => $XSOPT,
382     # do not even think about 'INC' => '-I/usr/ucbinclude', Solaris will avenge.
383         'INC'   => '',     # e.g., '-I/usr/include/other'
384         'INSTALLDIRS' => 'perl',
385         'dist'      => {
386             'CI'       => 'ci -l',
387             'COMPRESS' => 'gzip -9f',
388             'SUFFIX'   => 'gz',
389         },
390         clean => { FILES => "xdefine" },
391         realclean => {FILES=> 'const-c.inc const-xs.inc'},
392     );
393
394     if ($ENV{PERL_CORE}) {
395         push @makefileopts, MAN3PODS => {};
396     }
397
398     WriteMakefile(@makefileopts);
399 }
400
401 sub doConstants {
402     if (eval {require ExtUtils::Constant; 1}) {
403         my @names = (qw(ITIMER_REAL ITIMER_VIRTUAL ITIMER_PROF
404                         ITIMER_REALPROF));
405         foreach (qw (d_usleep d_ualarm d_gettimeofday d_getitimer d_setitimer
406                      d_nanosleep)) {
407             my $macro = $_;
408             if ($macro eq 'd_nanosleep') {
409                 $macro =~ s/d_(.*)/TIME_HIRES_\U$1/;
410             } else {
411                 $macro =~ s/d_(.*)/HAS_\U$1/;
412             }
413             push @names, {name => $_, macro => $macro, value => 1,
414                           default => ["IV", "0"]};
415         }
416         ExtUtils::Constant::WriteConstants(
417                                            NAME => 'Time::HiRes',
418                                            NAMES => \@names,
419                                           );
420     } else {
421         foreach my $file ('const-c.inc', 'const-xs.inc') {
422             my $fallback = File::Spec->catfile('fallback', $file);
423             local $/;
424             open IN, "<$fallback" or die "Can't open $fallback: $!";
425             open OUT, ">$file" or die "Can't open $file: $!";
426             print OUT <IN> or die $!;
427             close OUT or die "Can't close $file: $!";
428             close IN or die "Can't close $fallback: $!";
429         }
430     }
431 }
432
433 sub main {
434     print "Configuring Time::HiRes...\n";
435
436     if ($^O =~ /Win32/i) {
437       $DEFINE = '-DSELECT_IS_BROKEN';
438       $LIBS = [];
439     } else {
440       init();
441     }
442     doMakefile;
443     doConstants;
444     my $make = $Config{'make'} || "make";
445     unless ($ENV{PERL_CORE}) {
446         print  <<EOM;
447 Now you may issue '$make'.  Do not forget also '$make test'.
448
449 EOM
450        if ($ENV{LC_ALL}   =~ /utf-?8/i ||
451            $ENV{LC_CTYPE} =~ /utf-?8/i ||
452            $ENV{LANG}     =~ /utf-?8/i) {
453             print  <<EOM;
454 NOTE: if you get an error like this (the line number may vary):
455 Makefile:91: *** missing separator
456 then set the environment variable LC_ALL to "C" and retry.
457
458 EOM
459         }
460     }
461 }
462
463 &main;
464
465 # EOF