This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
4705669e6d58387dd4a0c756a575efeebf611d8d
[perl5.git] / ext / Data / Dumper / Dumper.pm
1 #
2 # Data/Dumper.pm
3 #
4 # convert perl data structures into perl syntax suitable for both printing
5 # and eval
6 #
7 # Documentation at the __END__
8 #
9
10 package Data::Dumper;
11
12 $VERSION = $VERSION = '2.101';
13
14 #$| = 1;
15
16 require 5.004;
17 require Exporter;
18 require DynaLoader;
19 require overload;
20
21 use Carp;
22
23 @ISA = qw(Exporter DynaLoader);
24 @EXPORT = qw(Dumper);
25 @EXPORT_OK = qw(DumperX);
26
27 bootstrap Data::Dumper;
28
29 # module vars and their defaults
30 $Indent = 2 unless defined $Indent;
31 $Purity = 0 unless defined $Purity;
32 $Pad = "" unless defined $Pad;
33 $Varname = "VAR" unless defined $Varname;
34 $Useqq = 0 unless defined $Useqq;
35 $Terse = 0 unless defined $Terse;
36 $Freezer = "" unless defined $Freezer;
37 $Toaster = "" unless defined $Toaster;
38 $Deepcopy = 0 unless defined $Deepcopy;
39 $Quotekeys = 1 unless defined $Quotekeys;
40 $Bless = "bless" unless defined $Bless;
41 #$Expdepth = 0 unless defined $Expdepth;
42 $Maxdepth = 0 unless defined $Maxdepth;
43
44 #
45 # expects an arrayref of values to be dumped.
46 # can optionally pass an arrayref of names for the values.
47 # names must have leading $ sign stripped. begin the name with *
48 # to cause output of arrays and hashes rather than refs.
49 #
50 sub new {
51   my($c, $v, $n) = @_;
52
53   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])" 
54     unless (defined($v) && (ref($v) eq 'ARRAY'));
55   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
56
57   my($s) = { 
58              level      => 0,           # current recursive depth
59              indent     => $Indent,     # various styles of indenting
60              pad        => $Pad,        # all lines prefixed by this string
61              xpad       => "",          # padding-per-level
62              apad       => "",          # added padding for hash keys n such
63              sep        => "",          # list separator
64              seen       => {},          # local (nested) refs (id => [name, val])
65              todump     => $v,          # values to dump []
66              names      => $n,          # optional names for values []
67              varname    => $Varname,    # prefix to use for tagging nameless ones
68              purity     => $Purity,     # degree to which output is evalable
69              useqq      => $Useqq,      # use "" for strings (backslashitis ensues)
70              terse      => $Terse,      # avoid name output (where feasible)
71              freezer    => $Freezer,    # name of Freezer method for objects
72              toaster    => $Toaster,    # name of method to revive objects
73              deepcopy   => $Deepcopy,   # dont cross-ref, except to stop recursion
74              quotekeys  => $Quotekeys,  # quote hash keys
75              'bless'    => $Bless,      # keyword to use for "bless"
76 #            expdepth   => $Expdepth,   # cutoff depth for explicit dumping
77              maxdepth   => $Maxdepth,   # depth beyond which we give up
78            };
79
80   if ($Indent > 0) {
81     $s->{xpad} = "  ";
82     $s->{sep} = "\n";
83   }
84   return bless($s, $c);
85 }
86
87 #
88 # add-to or query the table of already seen references
89 #
90 sub Seen {
91   my($s, $g) = @_;
92   if (defined($g) && (ref($g) eq 'HASH'))  {
93     my($k, $v, $id);
94     while (($k, $v) = each %$g) {
95       if (defined $v and ref $v) {
96         ($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
97         if ($k =~ /^[*](.*)$/) {
98           $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
99                (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
100                (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
101                                      (   "\$" . $1 ) ;
102         }
103         elsif ($k !~ /^\$/) {
104           $k = "\$" . $k;
105         }
106         $s->{seen}{$id} = [$k, $v];
107       }
108       else {
109         carp "Only refs supported, ignoring non-ref item \$$k";
110       }
111     }
112     return $s;
113   }
114   else {
115     return map { @$_ } values %{$s->{seen}};
116   }
117 }
118
119 #
120 # set or query the values to be dumped
121 #
122 sub Values {
123   my($s, $v) = @_;
124   if (defined($v) && (ref($v) eq 'ARRAY'))  {
125     $s->{todump} = [@$v];        # make a copy
126     return $s;
127   }
128   else {
129     return @{$s->{todump}};
130   }
131 }
132
133 #
134 # set or query the names of the values to be dumped
135 #
136 sub Names {
137   my($s, $n) = @_;
138   if (defined($n) && (ref($n) eq 'ARRAY'))  {
139     $s->{names} = [@$n];         # make a copy
140     return $s;
141   }
142   else {
143     return @{$s->{names}};
144   }
145 }
146
147 sub DESTROY {}
148
149 #
150 # dump the refs in the current dumper object.
151 # expects same args as new() if called via package name.
152 #
153 sub Dump {
154   my($s) = shift;
155   my(@out, $val, $name);
156   my($i) = 0;
157   local(@post);
158
159   $s = $s->new(@_) unless ref $s;
160
161   for $val (@{$s->{todump}}) {
162     my $out = "";
163     @post = ();
164     $name = $s->{names}[$i++];
165     if (defined $name) {
166       if ($name =~ /^[*](.*)$/) {
167         if (defined $val) {
168           $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
169                   (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
170                   (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
171                                           ( "\$" . $1 ) ;
172         }
173         else {
174           $name = "\$" . $1;
175         }
176       }
177       elsif ($name !~ /^\$/) {
178         $name = "\$" . $name;
179       }
180     }
181     else {
182       $name = "\$" . $s->{varname} . $i;
183     }
184
185     my $valstr;
186     {
187       local($s->{apad}) = $s->{apad};
188       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
189       $valstr = $s->_dump($val, $name);
190     }
191
192     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
193     $out .= $s->{pad} . $valstr . $s->{sep};
194     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post) 
195       . ';' . $s->{sep} if @post;
196
197     push @out, $out;
198   }
199   return wantarray ? @out : join('', @out);
200 }
201
202 #
203 # twist, toil and turn;
204 # and recurse, of course.
205 #
206 sub _dump {
207   my($s, $val, $name) = @_;
208   my($sname);
209   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
210
211   $type = ref $val;
212   $out = "";
213
214   if ($type) {
215
216     # prep it, if it looks like an object
217     if ($type =~ /[a-z_:]/) {
218       my $freezer = $s->{freezer};
219       $val->$freezer() if $freezer && UNIVERSAL::can($val, $freezer);
220     }
221
222     ($realpack, $realtype, $id) =
223       (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
224
225     # if it has a name, we need to either look it up, or keep a tab
226     # on it so we know when we hit it later
227     if (defined($name) and length($name)) {
228       # keep a tab on it so that we dont fall into recursive pit
229       if (exists $s->{seen}{$id}) {
230 #       if ($s->{expdepth} < $s->{level}) {
231           if ($s->{purity} and $s->{level} > 0) {
232             $out = ($realtype eq 'HASH')  ? '{}' :
233               ($realtype eq 'ARRAY') ? '[]' :
234                 "''" ;
235             push @post, $name . " = " . $s->{seen}{$id}[0];
236           }
237           else {
238             $out = $s->{seen}{$id}[0];
239             if ($name =~ /^([\@\%])/) {
240               my $start = $1;
241               if ($out =~ /^\\$start/) {
242                 $out = substr($out, 1);
243               }
244               else {
245                 $out = $start . '{' . $out . '}';
246               }
247             }
248           }
249           return $out;
250 #        }
251       }
252       else {
253         # store our name
254         $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
255                              ($realtype eq 'CODE' and
256                               $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
257                              $name          ),
258                             $val ];
259       }
260     }
261
262     if ($realpack and $realpack eq 'Regexp') {
263         $out = "$val";
264         $out =~ s,/,\\/,g;
265         return "qr/$out/";
266     }
267
268     # If purity is not set and maxdepth is set, then check depth: 
269     # if we have reached maximum depth, return the string
270     # representation of the thing we are currently examining
271     # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)'). 
272     if (!$s->{purity}
273         and $s->{maxdepth} > 0
274         and $s->{level} >= $s->{maxdepth})
275     {
276       return qq['$val'];
277     }
278
279     # we have a blessed ref
280     if ($realpack) {
281       $out = $s->{'bless'} . '( ';
282       $blesspad = $s->{apad};
283       $s->{apad} .= '       ' if ($s->{indent} >= 2);
284     }
285
286     $s->{level}++;
287     $ipad = $s->{xpad} x $s->{level};
288
289     
290     if ($realtype eq 'SCALAR') {
291       if ($realpack) {
292         $out .= 'do{\\(my $o = ' . $s->_dump($$val, "\${$name}") . ')}';
293       }
294       else {
295         $out .= '\\' . $s->_dump($$val, "\${$name}");
296       }
297     }
298     elsif ($realtype eq 'GLOB') {
299         $out .= '\\' . $s->_dump($$val, "*{$name}");
300     }
301     elsif ($realtype eq 'ARRAY') {
302       my($v, $pad, $mname);
303       my($i) = 0;
304       $out .= ($name =~ /^\@/) ? '(' : '[';
305       $pad = $s->{sep} . $s->{pad} . $s->{apad};
306       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) : 
307         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
308         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
309           ($mname = $name . '->');
310       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
311       for $v (@$val) {
312         $sname = $mname . '[' . $i . ']';
313         $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
314         $out .= $pad . $ipad . $s->_dump($v, $sname);
315         $out .= "," if $i++ < $#$val;
316       }
317       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
318       $out .= ($name =~ /^\@/) ? ')' : ']';
319     }
320     elsif ($realtype eq 'HASH') {
321       my($k, $v, $pad, $lpad, $mname);
322       $out .= ($name =~ /^\%/) ? '(' : '{';
323       $pad = $s->{sep} . $s->{pad} . $s->{apad};
324       $lpad = $s->{apad};
325       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
326         # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
327         ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
328           ($mname = $name . '->');
329       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
330       while (($k, $v) = each %$val) {
331         my $nk = $s->_dump($k, "");
332         $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
333         $sname = $mname . '{' . $nk . '}';
334         $out .= $pad . $ipad . $nk . " => ";
335
336         # temporarily alter apad
337         $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
338         $out .= $s->_dump($val->{$k}, $sname) . ",";
339         $s->{apad} = $lpad if $s->{indent} >= 2;
340       }
341       if (substr($out, -1) eq ',') {
342         chop $out;
343         $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
344       }
345       $out .= ($name =~ /^\%/) ? ')' : '}';
346     }
347     elsif ($realtype eq 'CODE') {
348       $out .= 'sub { "DUMMY" }';
349       carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
350     }
351     else {
352       croak "Can\'t handle $realtype type.";
353     }
354     
355     if ($realpack) { # we have a blessed ref
356       $out .= ', \'' . $realpack . '\'' . ' )';
357       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
358       $s->{apad} = $blesspad;
359     }
360     $s->{level}--;
361
362   }
363   else {                                 # simple scalar
364
365     my $ref = \$_[1];
366     # first, catalog the scalar
367     if ($name ne '') {
368       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
369       if (exists $s->{seen}{$id}) {
370         if ($s->{seen}{$id}[2]) {
371           $out = $s->{seen}{$id}[0];
372           #warn "[<$out]\n";
373           return "\${$out}";
374         }
375       }
376       else {
377         #warn "[>\\$name]\n";
378         $s->{seen}{$id} = ["\\$name", $ref];
379       }
380     }
381     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
382       my $name = substr($val, 1);
383       if ($name =~ /^[A-Za-z_][\w:]*$/) {
384         $name =~ s/^main::/::/;
385         $sname = $name;
386       }
387       else {
388         $sname = $s->_dump($name, "");
389         $sname = '{' . $sname . '}';
390       }
391       if ($s->{purity}) {
392         my $k;
393         local ($s->{level}) = 0;
394         for $k (qw(SCALAR ARRAY HASH)) {
395           my $gval = *$val{$k};
396           next unless defined $gval;
397           next if $k eq "SCALAR" && ! defined $$gval;  # always there
398
399           # _dump can push into @post, so we hold our place using $postlen
400           my $postlen = scalar @post;
401           $post[$postlen] = "\*$sname = ";
402           local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
403           $post[$postlen] .= $s->_dump($gval, "\*$sname\{$k\}");
404         }
405       }
406       $out .= '*' . $sname;
407     }
408     elsif (!defined($val)) {
409       $out .= "undef";
410     }
411     elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})$/) { # safe decimal number
412       $out .= $val;
413     }
414     else {                               # string
415       if ($s->{useqq}) {
416         $out .= qquote($val, $s->{useqq});
417       }
418       else {
419         $val =~ s/([\\\'])/\\$1/g;
420         $out .= '\'' . $val .  '\'';
421       }
422     }
423   }
424   if ($id) {
425     # if we made it this far, $id was added to seen list at current
426     # level, so remove it to get deep copies
427     if ($s->{deepcopy}) {
428       delete($s->{seen}{$id});
429     }
430     elsif ($name) {
431       $s->{seen}{$id}[2] = 1;
432     }
433   }
434   return $out;
435 }
436   
437 #
438 # non-OO style of earlier version
439 #
440 sub Dumper {
441   return Data::Dumper->Dump([@_]);
442 }
443
444 #
445 # same, only calls the XS version
446 #
447 sub DumperX {
448   return Data::Dumper->Dumpxs([@_], []);
449 }
450
451 sub Dumpf { return Data::Dumper->Dump(@_) }
452
453 sub Dumpp { print Data::Dumper->Dump(@_) }
454
455 #
456 # reset the "seen" cache 
457 #
458 sub Reset {
459   my($s) = shift;
460   $s->{seen} = {};
461   return $s;
462 }
463
464 sub Indent {
465   my($s, $v) = @_;
466   if (defined($v)) {
467     if ($v == 0) {
468       $s->{xpad} = "";
469       $s->{sep} = "";
470     }
471     else {
472       $s->{xpad} = "  ";
473       $s->{sep} = "\n";
474     }
475     $s->{indent} = $v;
476     return $s;
477   }
478   else {
479     return $s->{indent};
480   }
481 }
482
483 sub Pad {
484   my($s, $v) = @_;
485   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
486 }
487
488 sub Varname {
489   my($s, $v) = @_;
490   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
491 }
492
493 sub Purity {
494   my($s, $v) = @_;
495   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
496 }
497
498 sub Useqq {
499   my($s, $v) = @_;
500   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
501 }
502
503 sub Terse {
504   my($s, $v) = @_;
505   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
506 }
507
508 sub Freezer {
509   my($s, $v) = @_;
510   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
511 }
512
513 sub Toaster {
514   my($s, $v) = @_;
515   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
516 }
517
518 sub Deepcopy {
519   my($s, $v) = @_;
520   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
521 }
522
523 sub Quotekeys {
524   my($s, $v) = @_;
525   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
526 }
527
528 sub Bless {
529   my($s, $v) = @_;
530   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
531 }
532
533 sub Maxdepth {
534   my($s, $v) = @_;
535   defined($v) ? (($s->{'maxdepth'} = $v), return $s) : $s->{'maxdepth'};
536 }
537
538
539 # used by qquote below
540 my %esc = (  
541     "\a" => "\\a",
542     "\b" => "\\b",
543     "\t" => "\\t",
544     "\n" => "\\n",
545     "\f" => "\\f",
546     "\r" => "\\r",
547     "\e" => "\\e",
548 );
549
550 # put a string value in double quotes
551 sub qquote {
552   local($_) = shift;
553   s/([\\\"\@\$])/\\$1/g;
554   return qq("$_") unless /[^\040-\176]/;  # fast exit
555
556   my $high = shift || "";
557   s/([\a\b\t\n\f\r\e])/$esc{$1}/g;
558
559   # no need for 3 digits in escape for these
560   s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
561
562   s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
563   if ($high eq "iso8859") {
564     s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
565   } elsif ($high eq "utf8") {
566 #   use utf8;
567 #   $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
568   } elsif ($high eq "8bit") {
569       # leave it as it is
570   } else {
571     s/([\0-\037\177-\377])/'\\'.sprintf('%03o',ord($1))/eg;
572   }
573   return qq("$_");
574 }
575
576 1;
577 __END__
578
579 =head1 NAME
580
581 Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
582
583
584 =head1 SYNOPSIS
585
586     use Data::Dumper;
587
588     # simple procedural interface
589     print Dumper($foo, $bar);
590
591     # extended usage with names
592     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
593
594     # configuration variables
595     {
596       local $Data::Dump::Purity = 1;
597       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
598     }
599
600     # OO usage
601     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
602        ...
603     print $d->Dump;
604        ...
605     $d->Purity(1)->Terse(1)->Deepcopy(1);
606     eval $d->Dump;
607
608
609 =head1 DESCRIPTION
610
611 Given a list of scalars or reference variables, writes out their contents in
612 perl syntax. The references can also be objects.  The contents of each
613 variable is output in a single Perl statement.  Handles self-referential
614 structures correctly.
615
616 The return value can be C<eval>ed to get back an identical copy of the
617 original reference structure.
618
619 Any references that are the same as one of those passed in will be named
620 C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
621 to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
622 notation.  You can specify names for individual values to be dumped if you
623 use the C<Dump()> method, or you can change the default C<$VAR> prefix to
624 something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
625 below.
626
627 The default output of self-referential structures can be C<eval>ed, but the
628 nested references to C<$VAR>I<n> will be undefined, since a recursive
629 structure cannot be constructed using one Perl statement.  You should set the
630 C<Purity> flag to 1 to get additional statements that will correctly fill in
631 these references.
632
633 In the extended usage form, the references to be dumped can be given
634 user-specified names.  If a name begins with a C<*>, the output will 
635 describe the dereferenced type of the supplied reference for hashes and
636 arrays, and coderefs.  Output of names will be avoided where possible if
637 the C<Terse> flag is set.
638
639 In many cases, methods that are used to set the internal state of the
640 object will return the object itself, so method calls can be conveniently
641 chained together.
642
643 Several styles of output are possible, all controlled by setting
644 the C<Indent> flag.  See L<Configuration Variables or Methods> below 
645 for details.
646
647
648 =head2 Methods
649
650 =over 4
651
652 =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
653
654 Returns a newly created C<Data::Dumper> object.  The first argument is an
655 anonymous array of values to be dumped.  The optional second argument is an
656 anonymous array of names for the values.  The names need not have a leading
657 C<$> sign, and must be comprised of alphanumeric characters.  You can begin
658 a name with a C<*> to specify that the dereferenced type must be dumped
659 instead of the reference itself, for ARRAY and HASH references.
660
661 The prefix specified by C<$Data::Dumper::Varname> will be used with a
662 numeric suffix if the name for a value is undefined.
663
664 Data::Dumper will catalog all references encountered while dumping the
665 values. Cross-references (in the form of names of substructures in perl
666 syntax) will be inserted at all possible points, preserving any structural
667 interdependencies in the original set of values.  Structure traversal is
668 depth-first,  and proceeds in order from the first supplied value to
669 the last.
670
671 =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
672
673 Returns the stringified form of the values stored in the object (preserving
674 the order in which they were supplied to C<new>), subject to the
675 configuration options below.  In an array context, it returns a list
676 of strings corresponding to the supplied values.
677
678 The second form, for convenience, simply calls the C<new> method on its
679 arguments before dumping the object immediately.
680
681 =item I<$OBJ>->Dumpxs  I<or>  I<PACKAGE>->Dumpxs(I<ARRAYREF [>, I<ARRAYREF]>)
682
683 This method is available if you were able to compile and install the XSUB
684 extension to C<Data::Dumper>. It is exactly identical to the C<Dump> method 
685 above, only about 4 to 5 times faster, since it is written entirely in C.
686
687 =item I<$OBJ>->Seen(I<[HASHREF]>)
688
689 Queries or adds to the internal table of already encountered references.
690 You must use C<Reset> to explicitly clear the table if needed.  Such
691 references are not dumped; instead, their names are inserted wherever they
692 are encountered subsequently.  This is useful especially for properly
693 dumping subroutine references.
694
695 Expects a anonymous hash of name => value pairs.  Same rules apply for names
696 as in C<new>.  If no argument is supplied, will return the "seen" list of
697 name => value pairs, in an array context.  Otherwise, returns the object
698 itself.
699
700 =item I<$OBJ>->Values(I<[ARRAYREF]>)
701
702 Queries or replaces the internal array of values that will be dumped.
703 When called without arguments, returns the values.  Otherwise, returns the
704 object itself.
705
706 =item I<$OBJ>->Names(I<[ARRAYREF]>)
707
708 Queries or replaces the internal array of user supplied names for the values
709 that will be dumped.  When called without arguments, returns the names.
710 Otherwise, returns the object itself.
711
712 =item I<$OBJ>->Reset
713
714 Clears the internal table of "seen" references and returns the object
715 itself.
716
717 =back
718
719 =head2 Functions
720
721 =over 4
722
723 =item Dumper(I<LIST>)
724
725 Returns the stringified form of the values in the list, subject to the
726 configuration options below.  The values will be named C<$VAR>I<n> in the
727 output, where I<n> is a numeric suffix.  Will return a list of strings
728 in an array context.
729
730 =item DumperX(I<LIST>)
731
732 Identical to the C<Dumper()> function above, but this calls the XSUB 
733 implementation.  Only available if you were able to compile and install
734 the XSUB extensions in C<Data::Dumper>.
735
736 =back
737
738 =head2 Configuration Variables or Methods
739
740 Several configuration variables can be used to control the kind of output
741 generated when using the procedural interface.  These variables are usually
742 C<local>ized in a block so that other parts of the code are not affected by
743 the change.  
744
745 These variables determine the default state of the object created by calling
746 the C<new> method, but cannot be used to alter the state of the object
747 thereafter.  The equivalent method names should be used instead to query
748 or set the internal state of the object.
749
750 The method forms return the object itself when called with arguments,
751 so that they can be chained together nicely.
752
753 =over 4
754
755 =item $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
756
757 Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
758 spews output without any newlines, indentation, or spaces between list
759 items.  It is the most compact format possible that can still be called
760 valid perl.  Style 1 outputs a readable form with newlines but no fancy
761 indentation (each level in the structure is simply indented by a fixed
762 amount of whitespace).  Style 2 (the default) outputs a very readable form
763 which takes into account the length of hash keys (so the hash value lines
764 up).  Style 3 is like style 2, but also annotates the elements of arrays
765 with their index (but the comment is on its own line, so array output
766 consumes twice the number of lines).  Style 2 is the default.
767
768 =item $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
769
770 Controls the degree to which the output can be C<eval>ed to recreate the
771 supplied reference structures.  Setting it to 1 will output additional perl
772 statements that will correctly recreate nested references.  The default is
773 0.
774
775 =item $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
776
777 Specifies the string that will be prefixed to every line of the output.
778 Empty string by default.
779
780 =item $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
781
782 Contains the prefix to use for tagging variable names in the output. The
783 default is "VAR".
784
785 =item $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
786
787 When set, enables the use of double quotes for representing string values.
788 Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
789 characters will be backslashed, and unprintable characters will be output as
790 quoted octal integers.  Since setting this variable imposes a performance
791 penalty, the default is 0.  The C<Dumpxs()> method does not honor this
792 flag yet.
793
794 =item $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
795
796 When set, Data::Dumper will emit single, non-self-referential values as
797 atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
798 will be avoided where possible, but be advised that such output may not
799 always be parseable by C<eval>.
800
801 =item $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
802
803 Can be set to a method name, or to an empty string to disable the feature.
804 Data::Dumper will invoke that method via the object before attempting to
805 stringify it.  This method can alter the contents of the object (if, for
806 instance, it contains data allocated from C), and even rebless it in a
807 different package.  The client is responsible for making sure the specified
808 method can be called via the object, and that the object ends up containing
809 only perl data types after the method has been called.  Defaults to an empty
810 string.
811
812 =item $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
813
814 Can be set to a method name, or to an empty string to disable the feature.
815 Data::Dumper will emit a method call for any objects that are to be dumped
816 using the syntax C<bless(DATA, CLASS)->METHOD()>.  Note that this means that
817 the method specified will have to perform any modifications required on the
818 object (like creating new state within it, and/or reblessing it in a
819 different package) and then return it.  The client is responsible for making
820 sure the method can be called via the object, and that it returns a valid
821 object.  Defaults to an empty string.
822
823 =item $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
824
825 Can be set to a boolean value to enable deep copies of structures.
826 Cross-referencing will then only be done when absolutely essential
827 (i.e., to break reference cycles).  Default is 0.
828
829 =item $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
830
831 Can be set to a boolean value to control whether hash keys are quoted.
832 A false value will avoid quoting hash keys when it looks like a simple
833 string.  Default is 1, which will always enclose hash keys in quotes.
834
835 =item $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
836
837 Can be set to a string that specifies an alternative to the C<bless>
838 builtin operator used to create objects.  A function with the specified
839 name should exist, and should accept the same arguments as the builtin.
840 Default is C<bless>.
841
842 =item $Data::Dumper::Maxdepth  I<or>  $I<OBJ>->Maxdepth(I<[NEWVAL]>)
843
844 Can be set to a positive integer that specifies the depth beyond which
845 which we don't venture into a structure.  Has no effect when
846 C<Data::Dumper::Purity> is set.  (Useful in debugger when we often don't
847 want to see more than enough).  Default is 0, which means there is 
848 no maximum depth. 
849
850 =back
851
852 =head2 Exports
853
854 =over 4
855
856 =item Dumper
857
858 =back
859
860 =head1 EXAMPLES
861
862 Run these code snippets to get a quick feel for the behavior of this
863 module.  When you are through with these examples, you may want to
864 add or change the various configuration variables described above,
865 to see their behavior.  (See the testsuite in the Data::Dumper
866 distribution for more examples.)
867
868
869     use Data::Dumper;
870
871     package Foo;
872     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
873
874     package Fuz;                       # a weird REF-REF-SCALAR object
875     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
876
877     package main;
878     $foo = Foo->new;
879     $fuz = Fuz->new;
880     $boo = [ 1, [], "abcd", \*foo,
881              {1 => 'a', 023 => 'b', 0x45 => 'c'}, 
882              \\"p\q\'r", $foo, $fuz];
883     
884     ########
885     # simple usage
886     ########
887
888     $bar = eval(Dumper($boo));
889     print($@) if $@;
890     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
891
892     $Data::Dumper::Terse = 1;          # don't output names where feasible
893     $Data::Dumper::Indent = 0;         # turn off all pretty print
894     print Dumper($boo), "\n";
895
896     $Data::Dumper::Indent = 1;         # mild pretty print
897     print Dumper($boo);
898
899     $Data::Dumper::Indent = 3;         # pretty print with array indices
900     print Dumper($boo);
901
902     $Data::Dumper::Useqq = 1;          # print strings in double quotes
903     print Dumper($boo);
904     
905     
906     ########
907     # recursive structures
908     ########
909     
910     @c = ('c');
911     $c = \@c;
912     $b = {};
913     $a = [1, $b, $c];
914     $b->{a} = $a;
915     $b->{b} = $a->[1];
916     $b->{c} = $a->[2];
917     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
918     
919     
920     $Data::Dumper::Purity = 1;         # fill in the holes for eval
921     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
922     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
923     
924     
925     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
926     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
927     
928     
929     $Data::Dumper::Purity = 0;         # avoid cross-refs
930     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
931     
932     ########
933     # deep structures
934     ########
935     
936     $a = "pearl";
937     $b = [ $a ];
938     $c = { 'b' => $b };
939     $d = [ $c ];
940     $e = { 'd' => $d };
941     $f = { 'e' => $e };
942     print Data::Dumper->Dump([$f], [qw(f)]);
943
944     $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
945     print Data::Dumper->Dump([$f], [qw(f)]);
946
947     
948     ########
949     # object-oriented usage
950     ########
951     
952     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
953     $d->Seen({'*c' => $c});            # stash a ref without printing it
954     $d->Indent(3);
955     print $d->Dump;
956     $d->Reset->Purity(0);              # empty the seen cache
957     print join "----\n", $d->Dump;
958     
959     
960     ########
961     # persistence
962     ########
963     
964     package Foo;
965     sub new { bless { state => 'awake' }, shift }
966     sub Freeze {
967         my $s = shift;
968         print STDERR "preparing to sleep\n";
969         $s->{state} = 'asleep';
970         return bless $s, 'Foo::ZZZ';
971     }
972     
973     package Foo::ZZZ;
974     sub Thaw {
975         my $s = shift;
976         print STDERR "waking up\n";
977         $s->{state} = 'awake';
978         return bless $s, 'Foo';
979     }
980     
981     package Foo;
982     use Data::Dumper;
983     $a = Foo->new;
984     $b = Data::Dumper->new([$a], ['c']);
985     $b->Freezer('Freeze');
986     $b->Toaster('Thaw');
987     $c = $b->Dump;
988     print $c;
989     $d = eval $c;
990     print Data::Dumper->Dump([$d], ['d']);
991     
992     
993     ########
994     # symbol substitution (useful for recreating CODE refs)
995     ########
996     
997     sub foo { print "foo speaking\n" }
998     *other = \&foo;
999     $bar = [ \&other ];
1000     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
1001     $d->Seen({ '*foo' => \&foo });
1002     print $d->Dump;
1003
1004
1005 =head1 BUGS
1006
1007 Due to limitations of Perl subroutine call semantics, you cannot pass an
1008 array or hash.  Prepend it with a C<\> to pass its reference instead.  This
1009 will be remedied in time, with the arrival of prototypes in later versions
1010 of Perl.  For now, you need to use the extended usage form, and prepend the
1011 name with a C<*> to output it as a hash or array.
1012
1013 C<Data::Dumper> cheats with CODE references.  If a code reference is
1014 encountered in the structure being processed, an anonymous subroutine that
1015 contains the string '"DUMMY"' will be inserted in its place, and a warning
1016 will be printed if C<Purity> is set.  You can C<eval> the result, but bear
1017 in mind that the anonymous sub that gets created is just a placeholder.
1018 Someday, perl will have a switch to cache-on-demand the string
1019 representation of a compiled piece of code, I hope.  If you have prior
1020 knowledge of all the code refs that your data structures are likely
1021 to have, you can use the C<Seen> method to pre-seed the internal reference
1022 table and make the dumped output point to them, instead.  See L<EXAMPLES>
1023 above.
1024
1025 The C<Useqq> flag is not honored by C<Dumpxs()> (it always outputs
1026 strings in single quotes).
1027
1028 SCALAR objects have the weirdest looking C<bless> workaround.
1029
1030
1031 =head1 AUTHOR
1032
1033 Gurusamy Sarathy        gsar@umich.edu
1034
1035 Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
1036 This program is free software; you can redistribute it and/or
1037 modify it under the same terms as Perl itself.
1038
1039
1040 =head1 VERSION
1041
1042 Version 2.11   (unreleased)
1043
1044 =head1 SEE ALSO
1045
1046 perl(1)
1047
1048 =cut