This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Nothing uses $ENV{PERL_CORE_MINITEST} any more, so don't set it in t/TEST
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still currrent
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17
18 # directories with special sets of test switches
19 my %dir_to_switch =
20     (base => '',
21      comp => '',
22      run => '',
23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
24      );
25
26 # "not absolute" is the the default, as it saves some fakery within TestInit
27 # which can peturb tests, and takes CPU. Working with the upstream author of
28 # any of these, to figure out how to remove them from this list, considered
29 # "a good thing".
30 my %abs = (
31            '../cpan/Archive-Extract' => 1,
32            '../cpan/Archive-Tar' => 1,
33            '../cpan/AutoLoader' => 1,
34            '../cpan/CPAN' => 1,
35            '../cpan/Class-ISA' => 1,
36            '../cpan/Devel-PPPort' => 1,
37            '../cpan/Encode' => 1,
38            '../cpan/ExtUtils-Constant' => 1,
39            '../cpan/ExtUtils-MakeMaker' => 1,
40            '../cpan/File-Fetch' => 1,
41            '../cpan/IPC-Cmd' => 1,
42            '../cpan/IPC-SysV' => 1,
43            '../cpan/Locale-Codes' => 1,
44            '../cpan/Log-Message' => 1,
45            '../cpan/Math-Complex' => 1,
46            '../cpan/Module-Build' => 1,
47            '../cpan/Module-Load' => 1,
48            '../cpan/Module-Load-Conditional' => 1,
49            '../cpan/Object-Accessor' => 1,
50            '../cpan/Package-Constants' => 1,
51            '../cpan/Parse-CPAN-Meta' => 1,
52            '../cpan/Pod-Simple' => 1,
53            '../cpan/Term-UI' => 1,
54            '../cpan/Test-Simple' => 1,
55            '../cpan/Tie-File' => 1,
56            '../cpan/podlators' => 1,
57            '../dist/Cwd' => 1,
58            '../dist/ExtUtils-Command' => 1,
59            '../dist/ExtUtils-Install' => 1,
60            '../dist/ExtUtils-Manifest' => 1,
61            '../dist/ExtUtils-ParseXS' => 1,
62           );
63
64 my %temp_no_core =
65     ('../cpan/B-Debug' => 1,
66      '../cpan/Compress-Raw-Bzip2' => 1,
67      '../cpan/Compress-Raw-Zlib' => 1,
68      '../cpan/Devel-PPPort' => 1,
69      '../cpan/Getopt-Long' => 1,
70      '../cpan/IO-Compress' => 1,
71      '../cpan/MIME-Base64' => 1,
72      '../cpan/parent' => 1,
73      '../cpan/Parse-CPAN-Meta' => 1,
74      '../cpan/Pod-Simple' => 1,
75      '../cpan/podlators' => 1,
76      '../cpan/Test-Simple' => 1,
77      '../cpan/Tie-RefHash' => 1,
78      '../cpan/Time-HiRes' => 1,
79      '../cpan/Unicode-Collate' => 1,
80      '../cpan/Unicode-Normalize' => 1,
81     );
82
83 # delete env vars that may influence the results
84 # but allow override via *_TEST env var if wanted
85 # (e.g. PERL5OPT_TEST=-d:NYTProf)
86 for my $envname (qw(PERL5LIB PERLLIB PERL5OPT)) {
87     my $override = $ENV{"${envname}_TEST"};
88     if (defined $override) {
89         warn "$0: $envname=$override\n";
90         $ENV{$envname} = $override;
91     }
92     else {
93         delete $ENV{$envname};
94     }
95 }
96
97 if ($::do_nothing) {
98     return 1;
99 }
100
101 # Location to put the Valgrind log.
102 our $Valgrind_Log;
103
104 $| = 1;
105
106 # for testing TEST only
107 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
108 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
109
110 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
111 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
112 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
113
114 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
115 # can't rely on require working.
116 {
117     my @argv = ();
118     foreach my $idx (0..$#ARGV) {
119         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
120         $::benchmark = 1 if $1 eq 'benchmark';
121         $::core    = 1 if $1 eq 'core';
122         $::verbose = 1 if $1 eq 'v';
123         $::torture = 1 if $1 eq 'torture';
124         $::with_utf8 = 1 if $1 eq 'utf8';
125         $::with_utf16 = 1 if $1 eq 'utf16';
126         $::taintwarn = 1 if $1 eq 'taintwarn';
127         if ($1 =~ /^deparse(,.+)?$/) {
128             $::deparse = 1;
129             $::deparse_opts = $1;
130         }
131     }
132     @ARGV = @argv;
133 }
134
135 chdir 't' if -f 't/TEST';
136 if (-f 'TEST' && -f 'harness' && -d '../lib') {
137     @INC = '../lib';
138 }
139
140 die "You need to run \"make test\" first to set things up.\n"
141   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
142
143 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
144     unless (-x 'perl.third') {
145         unless (-x '../perl.third') {
146             die "You need to run \"make perl.third first.\n";
147         }
148         else {
149             print "Symlinking ../perl.third as perl.third...\n";
150             die "Failed to symlink: $!\n"
151                 unless symlink("../perl.third", "perl.third");
152             die "Symlinked but no executable perl.third: $!\n"
153                 unless -x 'perl.third';
154         }
155     }
156 }
157
158 # check leakage for embedders
159 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
160
161 $ENV{EMXSHELL} = 'sh';        # For OS/2
162
163 if ($show_elapsed_time) { require Time::HiRes }
164
165 my %skip = (
166             '.' => 1,
167             '..' => 1,
168             'CVS' => 1,
169             'RCS' => 1,
170             'SCCS' => 1,
171             '.svn' => 1,
172            );
173
174 # Roll your own File::Find!
175 sub _find_tests {
176     my($dir) = @_;
177     opendir DIR, $dir or die "Trouble opening $dir: $!";
178     foreach my $f (sort { $a cmp $b } readdir DIR) {
179         next if $skip{$f};
180
181         my $fullpath = "$dir/$f";
182
183         if (-d $fullpath) {
184             _find_tests($fullpath);
185         } elsif ($f =~ /\.t$/) {
186             push @ARGV, $fullpath;
187         }
188     }
189 }
190
191
192 # Scan the text of the test program to find switches and special options
193 # we might need to apply.
194 sub _scan_test {
195     my($test, $type) = @_;
196
197     open(my $script, "<", $test) or die "Can't read $test.\n";
198     my $first_line = <$script>;
199
200     $first_line =~ tr/\0//d if $::with_utf16;
201
202     my $switch = "";
203     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
204         $switch = "-$1";
205     } else {
206         if ($::taintwarn) {
207             # not all tests are expected to pass with this option
208             $switch = '-t';
209         } else {
210             $switch = '';
211         }
212     }
213
214     my $file_opts = "";
215     if ($type eq 'deparse') {
216         # Look for #line directives which change the filename
217         while (<$script>) {
218             $file_opts = $file_opts . ",-f$3$4"
219               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
220         }
221     }
222
223     close $script;
224
225     my $perl = './perl';
226     my $lib  = '../lib';
227     my $run_dir;
228     my $return_dir;
229
230     $test =~ /^(.+)\/[^\/]+/;
231     my $dir = $1;
232     my $testswitch = $dir_to_switch{$dir};
233     if (!defined $testswitch) {
234         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
235             $run_dir = $1;
236             $return_dir = '../../t';
237             $lib = '../../lib';
238             $perl = '../../t/perl';
239             $testswitch = "-I../.. -MTestInit=U2T";
240             if ($2 eq 'cpan' || $2 eq 'dist') {
241                 if($abs{$run_dir}) {
242                     $testswitch = $testswitch . ',A';
243                 }
244                 if ($temp_no_core{$run_dir}) {
245                     $testswitch = $testswitch . ',NC';
246                 }
247             }
248         } elsif ($test =~ m!^\.\./lib!) {
249             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
250         } else {
251             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
252         }
253     }
254
255     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
256
257     my %options = (
258         perl => $perl,
259         lib => $lib,
260         test => $test,
261         run_dir => $run_dir,
262         return_dir => $return_dir,
263         testswitch => $testswitch,
264         utf8 => $utf8,
265         file => $file_opts,
266         switch => $switch,
267     );
268
269     return \%options;
270 }
271
272 sub _cmd {
273     my($options, $type) = @_;
274
275     my $test = $options->{test};
276
277     my $cmd;
278     if ($type eq 'deparse') {
279         my $perl = "$options->{perl} $options->{testswitch}";
280         my $lib = $options->{lib};
281
282         $cmd = (
283           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
284           "-l$::deparse_opts$options->{file} ".
285           "$test > $test.dp ".
286           "&& $perl $options->{switch} -I$lib $test.dp"
287         );
288     }
289     elsif ($type eq 'perl') {
290         my $perl = $options->{perl};
291         my $redir = $^O eq 'VMS' ? '2>&1' : '';
292
293         if ($ENV{PERL_VALGRIND}) {
294             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
295             my $valgrind = $ENV{VALGRIND} // 'valgrind';
296             my $vg_opts = $ENV{VG_OPTS}
297               //  "--suppressions=$perl_supp --leak-check=yes "
298                 . "--leak-resolution=high --show-reachable=yes "
299                   . "--num-callers=50 --track-origins=yes";
300             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
301             $redir = "3>$Valgrind_Log";
302             if ($options->{run_dir}) {
303                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
304             }
305         }
306
307         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
308         $cmd = $perl . _quote_args($args) . " $test $redir";
309     }
310
311     return $cmd;
312 }
313
314 sub _before_fork {
315     my ($options) = @_;
316
317     if ($options->{run_dir}) {
318         my $run_dir = $options->{run_dir};
319         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
320     }
321
322     return;
323 }
324
325 sub _after_fork {
326     my ($options) = @_;
327
328     if ($options->{return_dir}) {
329         my $return_dir = $options->{return_dir};
330         chdir $return_dir
331            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
332     }
333
334     return;
335 }
336
337 sub _run_test {
338     my ($test, $type) = @_;
339
340     my $options = _scan_test($test, $type);
341     # $test might have changed if we're in ext/Foo, so don't use it anymore
342     # from now on. Use $options->{test} instead.
343
344     _before_fork($options);
345
346     my $cmd = _cmd($options, $type);
347
348     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
349
350     _after_fork($options);
351
352     # Our environment may force us to use UTF-8, but we can't be sure that
353     # anything we're reading from will be generating (well formed) UTF-8
354     # This may not be the best way - possibly we should unset ${^OPEN} up
355     # top?
356     binmode $results;
357
358     return $results;
359 }
360
361 sub _quote_args {
362     my ($args) = @_;
363     my $argstring = '';
364
365     foreach (split(/\s+/,$args)) {
366        # In VMS protect with doublequotes because otherwise
367        # DCL will lowercase -- unless already doublequoted.
368        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
369        $argstring = $argstring . ' ' . $_;
370     }
371     return $argstring;
372 }
373
374 sub _populate_hash {
375     return unless defined $_[0];
376     return map {$_, 1} split /\s+/, $_[0];
377 }
378
379 sub _tests_from_manifest {
380     my ($extensions, $known_extensions) = @_;
381     my %skip;
382     my %extensions = _populate_hash($extensions);
383     my %known_extensions = _populate_hash($known_extensions);
384
385     foreach (keys %known_extensions) {
386         $skip{$_} = 1 unless $extensions{$_};
387     }
388
389     my @results;
390     my $mani = '../MANIFEST';
391     if (open(MANI, $mani)) {
392         while (<MANI>) {
393             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
394                 my $t = $1;
395                 my $extension = $2;
396                 if (!$::core || $t =~ m!^lib/[a-z]!) {
397                     if (defined $extension) {
398                         $extension =~ s!/t(:?/\S+)*$!!;
399                         # XXX Do I want to warn that I'm skipping these?
400                         next if $skip{$extension};
401                         my $flat_extension = $extension;
402                         $flat_extension =~ s!-!/!g;
403                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
404                     }
405                     my $path = "../$t";
406                     push @results, $path;
407                     $::path_to_name{$path} = $t;
408                 }
409             }
410         }
411         close MANI;
412     } else {
413         warn "$0: cannot open $mani: $!\n";
414     }
415     return @results;
416 }
417
418 unless (@ARGV) {
419     # base first, as TEST bails out if that can't run
420     # then comp, to validate that require works
421     # then run, to validate that -M works
422     # then we know we can -MTestInit for everything else, making life simpler
423     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
424         _find_tests($dir);
425     }
426     _find_tests("lib") unless $::core;
427     # Config.pm may be broken for make minitest. And this is only a refinement
428     # for skipping tests on non-default builds, so it is allowed to fail.
429     # What we want to to is make a list of extensions which we did not build.
430     my $configsh = '../config.sh';
431     my ($extensions, $known_extensions);
432     if (-f $configsh) {
433         open FH, $configsh or die "Can't open $configsh: $!";
434         while (<FH>) {
435             if (/^extensions=['"](.*)['"]$/) {
436                 $extensions = $1;
437             }
438             elsif (/^known_extensions=['"](.*)['"]$/) {
439                 $known_extensions = $1;
440             }
441         }
442         if (!defined $known_extensions) {
443             warn "No known_extensions line found in $configsh";
444         }
445         if (!defined $extensions) {
446             warn "No extensions line found in $configsh";
447         }
448     }
449     # The "complex" constructions of list return from a subroutine, and push of
450     # a list, might fail if perl is really hosed, but they aren't needed for
451     # make minitest, and the building of extensions will likely also fail if
452     # something is that badly wrong.
453     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
454     unless ($::core) {
455         _find_tests('x2p');
456         _find_tests('porting');
457         _find_tests('japh') if $::torture;
458         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
459     }
460 }
461
462 if ($::deparse) {
463     _testprogs('deparse', '',   @ARGV);
464 }
465 elsif ($::with_utf16) {
466     for my $e (0, 1) {
467         for my $b (0, 1) {
468             print STDERR "# ENDIAN $e BOM $b\n";
469             my @UARGV;
470             for my $a (@ARGV) {
471                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
472                 my $f = $e ? "v" : "n";
473                 push @UARGV, $u;
474                 unlink($u);
475                 if (open(A, $a)) {
476                     if (open(U, ">$u")) {
477                         print U pack("$f", 0xFEFF) if $b;
478                         while (<A>) {
479                             print U pack("$f*", unpack("C*", $_));
480                         }
481                         close(U);
482                     }
483                     close(A);
484                 }
485             }
486             _testprogs('perl', '', @UARGV);
487             unlink(@UARGV);
488         }
489     }
490 }
491 else {
492     _testprogs('perl',    '',   @ARGV);
493 }
494
495 sub _testprogs {
496     my ($type, $args, @tests) = @_;
497
498     print <<'EOT' if ($type eq 'deparse');
499 ------------------------------------------------------------------------------
500 TESTING DEPARSER
501 ------------------------------------------------------------------------------
502 EOT
503
504     $::bad_files = 0;
505
506     foreach my $t (@tests) {
507       unless (exists $::path_to_name{$t}) {
508         my $tname = "t/$t";
509         $::path_to_name{$t} = $tname;
510       }
511     }
512     my $maxlen = 0;
513     foreach (@::path_to_name{@tests}) {
514         s/\.\w+\z/./;
515         my $len = length ;
516         $maxlen = $len if $len > $maxlen;
517     }
518     # + 3 : we want three dots between the test name and the "ok"
519     my $dotdotdot = $maxlen + 3 ;
520     my $valgrind = 0;
521     my $total_files = @tests;
522     my $good_files = 0;
523     my $tested_files  = 0;
524     my $totmax = 0;
525     my %failed_tests;
526
527     while (my $test = shift @tests) {
528         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
529
530         if ($test =~ /^$/) {
531             next;
532         }
533         if ($type eq 'deparse') {
534             if ($test eq "comp/redef.t") {
535                 # Redefinition happens at compile time
536                 next;
537             }
538             elsif ($test =~ m{lib/Switch/t/}) {
539                 # B::Deparse doesn't support source filtering
540                 next;
541             }
542         }
543         my $te = $::path_to_name{$test} . '.'
544                     x ($dotdotdot - length($::path_to_name{$test}));
545
546         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
547             print $te;
548             $te = '';
549         }
550
551         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
552         my $results = _run_test($test, $type);
553
554         my $failure;
555         my $next = 0;
556         my $seen_leader = 0;
557         my $seen_ok = 0;
558         my $trailing_leader = 0;
559         my $max;
560         my %todo;
561         while (<$results>) {
562             next if /^\s*$/; # skip blank lines
563             if (/^1..$/ && ($^O eq 'VMS')) {
564                 # VMS pipe bug inserts blank lines.
565                 my $l2 = <RESULTS>;
566                 if ($l2 =~ /^\s*$/) {
567                     $l2 = <RESULTS>;
568                 }
569                 $_ = '1..' . $l2;
570             }
571             if ($::verbose) {
572                 print $_;
573             }
574             unless (/^\#/) {
575                 if ($trailing_leader) {
576                     # shouldn't be anything following a postfix 1..n
577                     $failure = 'FAILED--extra output after trailing 1..n';
578                     last;
579                 }
580                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
581                     if ($seen_leader) {
582                         $failure = 'FAILED--seen duplicate leader';
583                         last;
584                     }
585                     $max = $1;
586                     %todo = map { $_ => 1 } split / /, $3 if $3;
587                     $totmax = $totmax + $max;
588                     $tested_files = $tested_files + 1;
589                     if ($seen_ok) {
590                         # 1..n appears at end of file
591                         $trailing_leader = 1;
592                         if ($next != $max) {
593                             $failure = "FAILED--expected $max tests, saw $next";
594                             last;
595                         }
596                     }
597                     else {
598                         $next = 0;
599                     }
600                     $seen_leader = 1;
601                 }
602                 else {
603                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
604                         unless ($seen_leader) {
605                             unless ($seen_ok) {
606                                 $next = 0;
607                             }
608                         }
609                         $seen_ok = 1;
610                         $next = $next + 1;
611                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
612                         $num = $next unless $num;
613
614                         if ($num == $next) {
615
616                             # SKIP is essentially the same as TODO for t/TEST
617                             # this still conforms to TAP:
618                             # http://search.cpan.org/dist/TAP/TAP.pm
619                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
620                             $istodo = 1 if $todo{$num};
621
622                             if( $not && !$istodo ) {
623                                 $failure = "FAILED at test $num";
624                                 last;
625                             }
626                         }
627                         else {
628                             $failure ="FAILED--expected test $next, saw test $num";
629                             last;
630                         }
631                     }
632                     elsif (/^Bail out!\s*(.*)/i) { # magic words
633                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
634                     }
635                     else {
636                         # module tests are allowed extra output,
637                         # because Test::Harness allows it
638                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
639                         $failure = "FAILED--unexpected output at test $next";
640                         last;
641                     }
642                 }
643             }
644         }
645         close $results;
646
647         if (not defined $failure) {
648             $failure = 'FAILED--no leader found' unless $seen_leader;
649         }
650
651         if ($ENV{PERL_VALGRIND}) {
652             my @valgrind;
653             if (-e $Valgrind_Log) {
654                 if (open(V, $Valgrind_Log)) {
655                     @valgrind = <V>;
656                     close V;
657                 } else {
658                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
659                 }
660             }
661             if ($ENV{VG_OPTS} =~ /cachegrind/) {
662                 if (rename $Valgrind_Log, "$test.valgrind") {
663                     $valgrind = $valgrind + 1;
664                 } else {
665                     warn "$0: Failed to create '$test.valgrind': $!\n";
666                 }
667             }
668             elsif (@valgrind) {
669                 my $leaks = 0;
670                 my $errors = 0;
671                 for my $i (0..$#valgrind) {
672                     local $_ = $valgrind[$i];
673                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
674                         $errors = $errors + $1;   # there may be multiple error summaries
675                     } elsif (/^==\d+== LEAK SUMMARY:/) {
676                         for my $off (1 .. 4) {
677                             if ($valgrind[$i+$off] =~
678                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
679                                 $leaks = $leaks + $1;
680                             }
681                         }
682                     }
683                 }
684                 if ($errors or $leaks) {
685                     if (rename $Valgrind_Log, "$test.valgrind") {
686                         $valgrind = $valgrind + 1;
687                     } else {
688                         warn "$0: Failed to create '$test.valgrind': $!\n";
689                     }
690                 }
691             } else {
692                 warn "No valgrind output?\n";
693             }
694             if (-e $Valgrind_Log) {
695                 unlink $Valgrind_Log
696                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
697             }
698         }
699         if ($type eq 'deparse') {
700             unlink "./$test.dp";
701         }
702         if ($ENV{PERL_3LOG}) {
703             my $tpp = $test;
704             $tpp =~ s:^\.\./::;
705             $tpp =~ s:/:_:g;
706             $tpp =~ s:\.t$:.3log:;
707             rename("perl.3log", $tpp) ||
708                 die "rename: perl3.log to $tpp: $!\n";
709         }
710         if (not defined $failure and $next != $max) {
711             $failure="FAILED--expected $max tests, saw $next";
712         }
713
714         if( !defined $failure  # don't mask a test failure
715             and $? )
716         {
717             $failure = "FAILED--non-zero wait status: $?";
718         }
719
720         if (defined $failure) {
721             print "${te}$failure\n";
722             $::bad_files = $::bad_files + 1;
723             if ($test =~ /^base/) {
724                 die "Failed a basic test ($test) -- cannot continue.\n";
725             }
726             $failed_tests{$test} = 1;
727         }
728         else {
729             if ($max) {
730                 my $elapsed;
731                 if ( $show_elapsed_time ) {
732                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
733                 }
734                 else {
735                     $elapsed = "";
736                 }
737                 print "${te}ok$elapsed\n";
738                 $good_files = $good_files + 1;
739             }
740             else {
741                 print "${te}skipped\n";
742                 $tested_files = $tested_files - 1;
743             }
744         }
745     } # while tests
746
747     if ($::bad_files == 0) {
748         if ($good_files) {
749             print "All tests successful.\n";
750             # XXX add mention of 'perlbug -ok' ?
751         }
752         else {
753             die "FAILED--no tests were run for some reason.\n";
754         }
755     }
756     else {
757         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
758         my $s = $::bad_files == 1 ? "" : "s";
759         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
760         for my $test ( sort keys %failed_tests ) {
761             print "\t$test\n";
762         }
763         warn <<'SHRDLU_1';
764 ### Since not all tests were successful, you may want to run some of
765 ### them individually and examine any diagnostic messages they produce.
766 ### See the INSTALL document's section on "make test".
767 SHRDLU_1
768         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
769 ### You have a good chance to get more information by running
770 ###   ./perl harness
771 ### in the 't' directory since most (>=80%) of the tests succeeded.
772 SHRDLU_2
773         if (eval {require Config; import Config; 1}) {
774             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
775                 warn <<SHRDLU_3;
776 ### You may have to set your dynamic library search path,
777 ### $p, to point to the build directory:
778 SHRDLU_3
779                 if (exists $ENV{$p} && $ENV{$p} ne '') {
780                     warn <<SHRDLU_4a;
781 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
782 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
783 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
784 SHRDLU_4a
785                 } else {
786                     warn <<SHRDLU_4b;
787 ###   setenv $p `pwd`; cd t; ./perl harness
788 ###   $p=`pwd`; export $p; cd t; ./perl harness
789 ###   export $p=`pwd`; cd t; ./perl harness
790 SHRDLU_4b
791                 }
792                 warn <<SHRDLU_5;
793 ### for csh-style shells, like tcsh; or for traditional/modern
794 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
795 SHRDLU_5
796             }
797         }
798     }
799     my ($user,$sys,$cuser,$csys) = times;
800     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
801         $user,$sys,$cuser,$csys,$tested_files,$totmax);
802     if ($ENV{PERL_VALGRIND}) {
803         my $s = $valgrind == 1 ? '' : 's';
804         print "$valgrind valgrind report$s created.\n", ;
805     }
806 }
807 exit ($::bad_files != 0);
808
809 # ex: set ts=8 sts=4 sw=4 noet: