This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
-x should be C<-x>, reported by Gerben Wierda.
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar and list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one list argument.)  For instance, splice() has three scalar
19 arguments followed by a list.
20
21 In the syntax descriptions that follow, list operators that expect a
22 list (and provide list context for the elements of the list) are shown
23 with LIST as an argument.  Such a list may consist of any combination
24 of scalar arguments or list values; the list values will be included
25 in the list as if each individual element were interpolated at that
26 point in the list, forming a longer single-dimensional list value.
27 Elements of the LIST should be separated by commas.
28
29 Any function in the list below may be used either with or without
30 parentheses around its arguments.  (The syntax descriptions omit the
31 parentheses.)  If you use the parentheses, the simple (but occasionally
32 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
33 function, and precedence doesn't matter.  Otherwise it's a list
34 operator or unary operator, and precedence does matter.  And whitespace
35 between the function and left parenthesis doesn't count--so you need to
36 be careful sometimes:
37
38     print 1+2+4;        # Prints 7.
39     print(1+2) + 4;     # Prints 3.
40     print (1+2)+4;      # Also prints 3!
41     print +(1+2)+4;     # Prints 7.
42     print ((1+2)+4);    # Prints 7.
43
44 If you run Perl with the B<-w> switch it can warn you about this.  For
45 example, the third line above produces:
46
47     print (...) interpreted as function at - line 1.
48     Useless use of integer addition in void context at - line 1.
49
50 For functions that can be used in either a scalar or list context,
51 nonabortive failure is generally indicated in a scalar context by
52 returning the undefined value, and in a list context by returning the
53 null list.
54
55 Remember the following important rule: There is B<no rule> that relates
56 the behavior of an expression in list context to its behavior in scalar
57 context, or vice versa.  It might do two totally different things.
58 Each operator and function decides which sort of value it would be most
59 appropriate to return in a scalar context.  Some operators return the
60 length of the list that would have been returned in list context.  Some
61 operators return the first value in the list.  Some operators return the
62 last value in the list.  Some operators return a count of successful
63 operations.  In general, they do what you want, unless you want
64 consistency.
65
66 An named array in scalar context is quite different from what would at
67 first glance appear to be a list in scalar context.  You can't get a list
68 like C<(1,2,3)> into being in scalar context, because the compiler knows
69 the context at compile time.  It would generate the scalar comma operator
70 there, not the list construction version of the comma.  That means it
71 was never a list to start with.
72
73 In general, functions in Perl that serve as wrappers for system calls
74 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
75 true when they succeed and C<undef> otherwise, as is usually mentioned
76 in the descriptions below.  This is different from the C interfaces,
77 which return C<-1> on failure.  Exceptions to this rule are C<wait()>,
78 C<waitpid()>, and C<syscall()>.  System calls also set the special C<$!>
79 variable on failure.  Other functions do not, except accidentally.
80
81 =head2 Perl Functions by Category
82
83 Here are Perl's functions (including things that look like
84 functions, like some keywords and named operators)
85 arranged by category.  Some functions appear in more
86 than one place.
87
88 =over
89
90 =item Functions for SCALARs or strings
91
92 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
93 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
94 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
95
96 =item Regular expressions and pattern matching
97
98 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
99
100 =item Numeric functions
101
102 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
103 C<sin>, C<sqrt>, C<srand>
104
105 =item Functions for real @ARRAYs
106
107 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
108
109 =item Functions for list data
110
111 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
112
113 =item Functions for real %HASHes
114
115 C<delete>, C<each>, C<exists>, C<keys>, C<values>
116
117 =item Input and output functions
118
119 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
120 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
121 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
122 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
123 C<warn>, C<write>
124
125 =item Functions for fixed length data or records
126
127 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
128
129 =item Functions for filehandles, files, or directories
130
131 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
132 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
133 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
134 C<unlink>, C<utime>
135
136 =item Keywords related to the control flow of your perl program
137
138 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<else>, C<elsif>,
139 C<eval>, C<exit>, C<for>, C<foreach>, C<goto>, C<if>, C<last>,
140 C<next>, C<redo>, C<return>, C<sub>, C<unless>, C<wantarray>,
141 C<while>, C<until>
142
143 =item Keywords related to scoping
144
145 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
146
147 =item Miscellaneous functions
148
149 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
150 C<scalar>, C<undef>, C<wantarray>
151
152 =item Functions for processes and process groups
153
154 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
155 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
156 C<times>, C<wait>, C<waitpid>
157
158 =item Keywords related to perl modules
159
160 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
161
162 =item Keywords related to classes and object-orientedness
163
164 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
165 C<untie>, C<use>
166
167 =item Low-level socket functions
168
169 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
170 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
171 C<socket>, C<socketpair>
172
173 =item System V interprocess communication functions
174
175 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
176 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
177
178 =item Fetching user and group info
179
180 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
181 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
182 C<getpwuid>, C<setgrent>, C<setpwent>
183
184 =item Fetching network info
185
186 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
187 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
188 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
189 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
190 C<setnetent>, C<setprotoent>, C<setservent>
191
192 =item Time-related functions
193
194 C<gmtime>, C<localtime>, C<time>, C<times>
195
196 =item Functions new in perl5
197
198 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
199 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
200 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
201 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
202
203 * - C<sub> was a keyword in perl4, but in perl5 it is an
204 operator, which can be used in expressions.
205
206 =item Functions obsoleted in perl5
207
208 C<dbmclose>, C<dbmopen>
209
210 =back
211
212 =head2 Portability
213
214 Perl was born in UNIX and therefore it can access all the common UNIX
215 system calls.  In non-UNIX environments the functionality of many
216 UNIX system calls may not be available or the details of the available
217 functionality may be slightly different.  The Perl functions affected
218 by this are:
219
220 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
221 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
222 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
223 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
224 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
225 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
226 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
227 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
228 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
229 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<select>, C<semctl>,
230 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
231 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
232 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
233 C<shmwrite>, C<socketpair>, C<stat>, C<symlink>, C<syscall>,
234 C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<utime>,
235 C<wait>, C<waitpid>
236
237 For more information about the portability of these functions, see
238 L<perlport> and other available platform-specific documentation.
239
240 =head2 Alphabetical Listing of Perl Functions
241
242 =over 8
243
244 =item I<-X> FILEHANDLE
245
246 =item I<-X> EXPR
247
248 =item I<-X>
249
250 A file test, where X is one of the letters listed below.  This unary
251 operator takes one argument, either a filename or a filehandle, and
252 tests the associated file to see if something is true about it.  If the
253 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
254 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
255 the undefined value if the file doesn't exist.  Despite the funny
256 names, precedence is the same as any other named unary operator, and
257 the argument may be parenthesized like any other unary operator.  The
258 operator may be any of:
259 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
260 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
261
262     -r  File is readable by effective uid/gid.
263     -w  File is writable by effective uid/gid.
264     -x  File is executable by effective uid/gid.
265     -o  File is owned by effective uid.
266
267     -R  File is readable by real uid/gid.
268     -W  File is writable by real uid/gid.
269     -X  File is executable by real uid/gid.
270     -O  File is owned by real uid.
271
272     -e  File exists.
273     -z  File has zero size.
274     -s  File has nonzero size (returns size).
275
276     -f  File is a plain file.
277     -d  File is a directory.
278     -l  File is a symbolic link.
279     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
280     -S  File is a socket.
281     -b  File is a block special file.
282     -c  File is a character special file.
283     -t  Filehandle is opened to a tty.
284
285     -u  File has setuid bit set.
286     -g  File has setgid bit set.
287     -k  File has sticky bit set.
288
289     -T  File is a text file.
290     -B  File is a binary file (opposite of -T).
291
292     -M  Age of file in days when script started.
293     -A  Same for access time.
294     -C  Same for inode change time.
295
296 Example:
297
298     while (<>) {
299         chop;
300         next unless -f $_;      # ignore specials
301         #...
302     }
303
304 The interpretation of the file permission operators C<-r>, C<-R>,
305 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
306 of the file and the uids and gids of the user.  There may be other
307 reasons you can't actually read, write, or execute the file.  Such
308 reasons may be for example network filesystem access controls, ACLs
309 (access control lists), read-only filesystems, and unrecognized
310 executable formats.
311
312 Also note that, for the superuser on the local filesystems, C<-r>,
313 C<-R>, C<-w>, and C<-W> always return 1, and C<-x> and C<-X> return 1
314 if any execute bit is set in the mode.  Scripts run by the superuser
315 may thus need to do a stat() to determine the actual mode of the file,
316 or temporarily set the uid to something else.
317
318 If you are using ACLs, there is a pragma called C<filetest> that may
319 produce more accurate results than the bare stat() mode bits.
320
321 When under the C<use filetest 'access'> the above-mentioned filetests
322 will test whether the permission can (not) be granted using the
323 access() family of system calls.  Also note that the C<-x> and C<-X> may
324 under this pragma return true even if there are no execute permission
325 bits set (nor any extra execute permission ACLs).  This strangeness is
326 due to the underlying system calls' definitions.  Read the
327 documentation for the C<filetest> pragma for more information.
328
329 Note that C<-s/a/b/> does not do a negated substitution.  Saying
330 C<-exp($foo)> still works as expected, however--only single letters
331 following a minus are interpreted as file tests.
332
333 The C<-T> and C<-B> switches work as follows.  The first block or so of the
334 file is examined for odd characters such as strange control codes or
335 characters with the high bit set.  If too many strange characters (E<gt>30%)
336 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
337 containing null in the first block is considered a binary file.  If C<-T>
338 or C<-B> is used on a filehandle, the current stdio buffer is examined
339 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
340 file, or a file at EOF when testing a filehandle.  Because you have to
341 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
342 against the file first, as in C<next unless -f $file && -T $file>.
343
344 If any of the file tests (or either the C<stat()> or C<lstat()> operators) are given
345 the special filehandle consisting of a solitary underline, then the stat
346 structure of the previous file test (or stat operator) is used, saving
347 a system call.  (This doesn't work with C<-t>, and you need to remember
348 that lstat() and C<-l> will leave values in the stat structure for the
349 symbolic link, not the real file.)  Example:
350
351     print "Can do.\n" if -r $a || -w _ || -x _;
352
353     stat($filename);
354     print "Readable\n" if -r _;
355     print "Writable\n" if -w _;
356     print "Executable\n" if -x _;
357     print "Setuid\n" if -u _;
358     print "Setgid\n" if -g _;
359     print "Sticky\n" if -k _;
360     print "Text\n" if -T _;
361     print "Binary\n" if -B _;
362
363 =item abs VALUE
364
365 =item abs
366
367 Returns the absolute value of its argument.
368 If VALUE is omitted, uses C<$_>.
369
370 =item accept NEWSOCKET,GENERICSOCKET
371
372 Accepts an incoming socket connect, just as the accept(2) system call
373 does.  Returns the packed address if it succeeded, FALSE otherwise.
374 See example in L<perlipc/"Sockets: Client/Server Communication">.
375
376 =item alarm SECONDS
377
378 =item alarm
379
380 Arranges to have a SIGALRM delivered to this process after the
381 specified number of seconds have elapsed.  If SECONDS is not specified,
382 the value stored in C<$_> is used. (On some machines,
383 unfortunately, the elapsed time may be up to one second less than you
384 specified because of how seconds are counted.)  Only one timer may be
385 counting at once.  Each call disables the previous timer, and an
386 argument of C<0> may be supplied to cancel the previous timer without
387 starting a new one.  The returned value is the amount of time remaining
388 on the previous timer.
389
390 For delays of finer granularity than one second, you may use Perl's
391 C<syscall()> interface to access setitimer(2) if your system supports it,
392 or else see L</select()>.  It is usually a mistake to intermix C<alarm()>
393 and C<sleep()> calls.
394
395 If you want to use C<alarm()> to time out a system call you need to use an
396 C<eval()>/C<die()> pair.  You can't rely on the alarm causing the system call to
397 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
398 restart system calls on some systems.  Using C<eval()>/C<die()> always works,
399 modulo the caveats given in L<perlipc/"Signals">.
400
401     eval {
402         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
403         alarm $timeout;
404         $nread = sysread SOCKET, $buffer, $size;
405         alarm 0;
406     };
407     if ($@) {
408         die unless $@ eq "alarm\n";   # propagate unexpected errors
409         # timed out
410     }
411     else {
412         # didn't
413     }
414
415 =item atan2 Y,X
416
417 Returns the arctangent of Y/X in the range -PI to PI.
418
419 For the tangent operation, you may use the C<POSIX::tan()>
420 function, or use the familiar relation:
421
422     sub tan { sin($_[0]) / cos($_[0])  }
423
424 =item bind SOCKET,NAME
425
426 Binds a network address to a socket, just as the bind system call
427 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
428 packed address of the appropriate type for the socket.  See the examples in
429 L<perlipc/"Sockets: Client/Server Communication">.
430
431 =item binmode FILEHANDLE
432
433 Arranges for the file to be read or written in "binary" mode in operating
434 systems that distinguish between binary and text files.  Files that are
435 not in binary mode have CR LF sequences translated to LF on input and LF
436 translated to CR LF on output.  Binmode has no effect under Unix; in MS-DOS
437 and similarly archaic systems, it may be imperative--otherwise your
438 MS-DOS-damaged C library may mangle your file.  The key distinction between
439 systems that need C<binmode()> and those that don't is their text file
440 formats.  Systems like Unix, MacOS, and Plan9 that delimit lines with a single
441 character, and that encode that character in C as C<"\n">, do not need
442 C<binmode()>.  The rest need it.  If FILEHANDLE is an expression, the value
443 is taken as the name of the filehandle.
444
445 =item bless REF,CLASSNAME
446
447 =item bless REF
448
449 This function tells the thingy referenced by REF that it is now
450 an object in the CLASSNAME package--or the current package if no CLASSNAME
451 is specified, which is often the case.  It returns the reference for
452 convenience, because a C<bless()> is often the last thing in a constructor.
453 Always use the two-argument version if the function doing the blessing
454 might be inherited by a derived class.  See L<perltoot> and L<perlobj>
455 for more about the blessing (and blessings) of objects.
456
457 =item caller EXPR
458
459 =item caller
460
461 Returns the context of the current subroutine call.  In scalar context,
462 returns the caller's package name if there is a caller, that is, if
463 we're in a subroutine or C<eval()> or C<require()>, and the undefined value
464 otherwise.  In list context, returns
465
466     ($package, $filename, $line) = caller;
467
468 With EXPR, it returns some extra information that the debugger uses to
469 print a stack trace.  The value of EXPR indicates how many call frames
470 to go back before the current one.
471
472     ($package, $filename, $line, $subroutine,
473      $hasargs, $wantarray, $evaltext, $is_require) = caller($i);
474
475 Here C<$subroutine> may be C<"(eval)"> if the frame is not a subroutine
476 call, but an C<eval()>.  In such a case additional elements C<$evaltext> and
477 C<$is_require> are set: C<$is_require> is true if the frame is created by a
478 C<require> or C<use> statement, C<$evaltext> contains the text of the
479 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
480 C<$filename> is C<"(eval)">, but C<$evaltext> is undefined.  (Note also that
481 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
482 frame.
483
484 Furthermore, when called from within the DB package, caller returns more
485 detailed information: it sets the list variable C<@DB::args> to be the
486 arguments with which the subroutine was invoked.
487
488 Be aware that the optimizer might have optimized call frames away before
489 C<caller()> had a chance to get the information. That means that C<caller(N)>
490 might not return information about the call frame you expect it do, for
491 C<N E<gt> 1>. In particular, C<@DB::args> might have information from the 
492 previous time C<caller()> was called.
493
494 =item chdir EXPR
495
496 Changes the working directory to EXPR, if possible.  If EXPR is
497 omitted, changes to home directory.  Returns TRUE upon success, FALSE
498 otherwise.  See example under C<die()>.
499
500 =item chmod LIST
501
502 Changes the permissions of a list of files.  The first element of the
503 list must be the numerical mode, which should probably be an octal
504 number, and which definitely should I<not> a string of octal digits:
505 C<0644> is okay, C<'0644'> is not.  Returns the number of files
506 successfully changed.  See also L</oct>, if all you have is a string.
507
508     $cnt = chmod 0755, 'foo', 'bar';
509     chmod 0755, @executables;
510     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
511                                              # --w----r-T
512     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
513     $mode = 0644;   chmod $mode, 'foo';      # this is best
514
515 =item chomp VARIABLE
516
517 =item chomp LIST
518
519 =item chomp
520
521 This is a slightly safer version of L</chop>.  It removes any
522 line ending that corresponds to the current value of C<$/> (also known as
523 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
524 number of characters removed from all its arguments.  It's often used to
525 remove the newline from the end of an input record when you're worried
526 that the final record may be missing its newline.  When in paragraph mode
527 (C<$/ = "">), it removes all trailing newlines from the string.  If
528 VARIABLE is omitted, it chomps C<$_>.  Example:
529
530     while (<>) {
531         chomp;  # avoid \n on last field
532         @array = split(/:/);
533         # ...
534     }
535
536 You can actually chomp anything that's an lvalue, including an assignment:
537
538     chomp($cwd = `pwd`);
539     chomp($answer = <STDIN>);
540
541 If you chomp a list, each element is chomped, and the total number of
542 characters removed is returned.
543
544 =item chop VARIABLE
545
546 =item chop LIST
547
548 =item chop
549
550 Chops off the last character of a string and returns the character
551 chopped.  It's used primarily to remove the newline from the end of an
552 input record, but is much more efficient than C<s/\n//> because it neither
553 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
554 Example:
555
556     while (<>) {
557         chop;   # avoid \n on last field
558         @array = split(/:/);
559         #...
560     }
561
562 You can actually chop anything that's an lvalue, including an assignment:
563
564     chop($cwd = `pwd`);
565     chop($answer = <STDIN>);
566
567 If you chop a list, each element is chopped.  Only the value of the
568 last C<chop()> is returned.
569
570 Note that C<chop()> returns the last character.  To return all but the last
571 character, use C<substr($string, 0, -1)>.
572
573 =item chown LIST
574
575 Changes the owner (and group) of a list of files.  The first two
576 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
577 Returns the number of files successfully changed.
578
579     $cnt = chown $uid, $gid, 'foo', 'bar';
580     chown $uid, $gid, @filenames;
581
582 Here's an example that looks up nonnumeric uids in the passwd file:
583
584     print "User: ";
585     chop($user = <STDIN>);
586     print "Files: ";
587     chop($pattern = <STDIN>);
588
589     ($login,$pass,$uid,$gid) = getpwnam($user)
590         or die "$user not in passwd file";
591
592     @ary = glob($pattern);      # expand filenames
593     chown $uid, $gid, @ary;
594
595 On most systems, you are not allowed to change the ownership of the
596 file unless you're the superuser, although you should be able to change
597 the group to any of your secondary groups.  On insecure systems, these
598 restrictions may be relaxed, but this is not a portable assumption.
599
600 =item chr NUMBER
601
602 =item chr
603
604 Returns the character represented by that NUMBER in the character set.
605 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
606 chr(0x263a) is a Unicode smiley face (but only within the scope of a
607 C<use utf8>).  For the reverse, use L</ord>.
608
609 If NUMBER is omitted, uses C<$_>.
610
611 =item chroot FILENAME
612
613 =item chroot
614
615 This function works like the system call by the same name: it makes the
616 named directory the new root directory for all further pathnames that
617 begin with a C<"/"> by your process and all its children.  (It doesn't
618 change your current working directory, which is unaffected.)  For security
619 reasons, this call is restricted to the superuser.  If FILENAME is
620 omitted, does a C<chroot()> to C<$_>.
621
622 =item close FILEHANDLE
623
624 =item close
625
626 Closes the file or pipe associated with the file handle, returning TRUE
627 only if stdio successfully flushes buffers and closes the system file
628 descriptor. Closes the currently selected filehandle if the argument
629 is omitted.
630
631 You don't have to close FILEHANDLE if you are immediately going to do
632 another C<open()> on it, because C<open()> will close it for you.  (See
633 C<open()>.)  However, an explicit C<close()> on an input file resets the line
634 counter (C<$.>), while the implicit close done by C<open()> does not.
635
636 If the file handle came from a piped open C<close()> will additionally
637 return FALSE if one of the other system calls involved fails or if the
638 program exits with non-zero status.  (If the only problem was that the
639 program exited non-zero C<$!> will be set to C<0>.)  Also, closing a pipe 
640 waits for the process executing on the pipe to complete, in case you
641 want to look at the output of the pipe afterwards.  Closing a pipe
642 explicitly also puts the exit status value of the command into C<$?>.
643
644 Example:
645
646     open(OUTPUT, '|sort >foo')  # pipe to sort
647         or die "Can't start sort: $!";
648     #...                        # print stuff to output
649     close OUTPUT                # wait for sort to finish
650         or warn $! ? "Error closing sort pipe: $!"
651                    : "Exit status $? from sort";
652     open(INPUT, 'foo')          # get sort's results
653         or die "Can't open 'foo' for input: $!";
654
655 FILEHANDLE may be an expression whose value can be used as an indirect
656 filehandle, usually the real filehandle name.
657
658 =item closedir DIRHANDLE
659
660 Closes a directory opened by C<opendir()> and returns the success of that
661 system call.
662
663 DIRHANDLE may be an expression whose value can be used as an indirect
664 dirhandle, usually the real dirhandle name.
665
666 =item connect SOCKET,NAME
667
668 Attempts to connect to a remote socket, just as the connect system call
669 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
670 packed address of the appropriate type for the socket.  See the examples in
671 L<perlipc/"Sockets: Client/Server Communication">.
672
673 =item continue BLOCK
674
675 Actually a flow control statement rather than a function.  If there is a
676 C<continue> BLOCK attached to a BLOCK (typically in a L</while> or
677 L</foreach>), it is always executed just before the conditional is about to
678 be evaluated again, just like the third part of a L</for> loop in C.  Thus
679 it can be used to increment a loop variable, even when the loop has been
680 continued via the C<next> statement (which is similar to the C C<continue>
681 statement).
682
683 L</last>, L</next>, or L</redo> may appear within a C<continue>
684 block. C<last> and C<redo> will behave as if they had been executed within
685 the main block. So will C<next>, but since it will execute a C<continue>
686 block, it may be more entertaining.
687
688     while (EXPR) {
689         ### redo always comes here
690         do_something;
691     } continue {
692         ### next always comes here
693         do_something_else;
694         # then back the top to re-check EXPR
695     }
696     ### last always comes here
697
698 Omitting the C<continue> section is semantically equivalent to using an
699 empty one, logically enough. In that case, C<next> goes directly back
700 to check the condition at the top of the loop.
701
702 See also L<perlsyn>.
703
704 =item cos EXPR
705
706 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
707 takes cosine of C<$_>.
708
709 For the inverse cosine operation, you may use the C<POSIX::acos()>
710 function, or use this relation:
711
712     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
713
714 =item crypt PLAINTEXT,SALT
715
716 Encrypts a string exactly like the crypt(3) function in the C library
717 (assuming that you actually have a version there that has not been
718 extirpated as a potential munition).  This can prove useful for checking
719 the password file for lousy passwords, amongst other things.  Only the
720 guys wearing white hats should do this.
721
722 Note that C<crypt()> is intended to be a one-way function, much like breaking
723 eggs to make an omelette.  There is no (known) corresponding decrypt
724 function.  As a result, this function isn't all that useful for
725 cryptography.  (For that, see your nearby CPAN mirror.)
726
727 When verifying an existing encrypted string you should use the encrypted
728 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
729 allows your code to work with the standard C<crypt()> and with more
730 exotic implementations.  When choosing a new salt create a random two
731 character string whose characters come from the set C<[./0-9A-Za-z]>
732 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
733
734 Here's an example that makes sure that whoever runs this program knows
735 their own password:
736
737     $pwd = (getpwuid($<))[1];
738
739     system "stty -echo";
740     print "Password: ";
741     chomp($word = <STDIN>);
742     print "\n";
743     system "stty echo";
744
745     if (crypt($word, $pwd) ne $pwd) {
746         die "Sorry...\n";
747     } else {
748         print "ok\n";
749     }
750
751 Of course, typing in your own password to whoever asks you
752 for it is unwise.
753
754 =item dbmclose HASH
755
756 [This function has been superseded by the C<untie()> function.]
757
758 Breaks the binding between a DBM file and a hash.
759
760 =item dbmopen HASH,DBNAME,MODE
761
762 [This function has been superseded by the C<tie()> function.]
763
764 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
765 hash.  HASH is the name of the hash.  (Unlike normal C<open()>, the first
766 argument is I<NOT> a filehandle, even though it looks like one).  DBNAME
767 is the name of the database (without the F<.dir> or F<.pag> extension if
768 any).  If the database does not exist, it is created with protection
769 specified by MODE (as modified by the C<umask()>).  If your system supports
770 only the older DBM functions, you may perform only one C<dbmopen()> in your
771 program.  In older versions of Perl, if your system had neither DBM nor
772 ndbm, calling C<dbmopen()> produced a fatal error; it now falls back to
773 sdbm(3).
774
775 If you don't have write access to the DBM file, you can only read hash
776 variables, not set them.  If you want to test whether you can write,
777 either use file tests or try setting a dummy hash entry inside an C<eval()>,
778 which will trap the error.
779
780 Note that functions such as C<keys()> and C<values()> may return huge lists
781 when used on large DBM files.  You may prefer to use the C<each()>
782 function to iterate over large DBM files.  Example:
783
784     # print out history file offsets
785     dbmopen(%HIST,'/usr/lib/news/history',0666);
786     while (($key,$val) = each %HIST) {
787         print $key, ' = ', unpack('L',$val), "\n";
788     }
789     dbmclose(%HIST);
790
791 See also L<AnyDBM_File> for a more general description of the pros and
792 cons of the various dbm approaches, as well as L<DB_File> for a particularly
793 rich implementation.
794
795 =item defined EXPR
796
797 =item defined
798
799 Returns a Boolean value telling whether EXPR has a value other than
800 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
801 checked.
802
803 Many operations return C<undef> to indicate failure, end of file,
804 system error, uninitialized variable, and other exceptional
805 conditions.  This function allows you to distinguish C<undef> from
806 other values.  (A simple Boolean test will not distinguish among
807 C<undef>, zero, the empty string, and C<"0">, which are all equally
808 false.)  Note that since C<undef> is a valid scalar, its presence
809 doesn't I<necessarily> indicate an exceptional condition: C<pop()>
810 returns C<undef> when its argument is an empty array, I<or> when the
811 element to return happens to be C<undef>.
812
813 You may also use C<defined()> to check whether a subroutine exists, by
814 saying C<defined &func> without parentheses.  On the other hand, use
815 of C<defined()> upon aggregates (hashes and arrays) is not guaranteed to
816 produce intuitive results, and should probably be avoided.
817
818 When used on a hash element, it tells you whether the value is defined,
819 not whether the key exists in the hash.  Use L</exists> for the latter
820 purpose.
821
822 Examples:
823
824     print if defined $switch{'D'};
825     print "$val\n" while defined($val = pop(@ary));
826     die "Can't readlink $sym: $!"
827         unless defined($value = readlink $sym);
828     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
829     $debugging = 0 unless defined $debugging;
830
831 Note:  Many folks tend to overuse C<defined()>, and then are surprised to
832 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
833 defined values.  For example, if you say
834
835     "ab" =~ /a(.*)b/;
836
837 The pattern match succeeds, and C<$1> is defined, despite the fact that it
838 matched "nothing".  But it didn't really match nothing--rather, it
839 matched something that happened to be C<0> characters long.  This is all
840 very above-board and honest.  When a function returns an undefined value,
841 it's an admission that it couldn't give you an honest answer.  So you
842 should use C<defined()> only when you're questioning the integrity of what
843 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
844 what you want.
845
846 Currently, using C<defined()> on an entire array or hash reports whether
847 memory for that aggregate has ever been allocated.  So an array you set
848 to the empty list appears undefined initially, and one that once was full
849 and that you then set to the empty list still appears defined.  You
850 should instead use a simple test for size:
851
852     if (@an_array) { print "has array elements\n" }
853     if (%a_hash)   { print "has hash members\n"   }
854
855 Using C<undef()> on these, however, does clear their memory and then report
856 them as not defined anymore, but you shouldn't do that unless you don't
857 plan to use them again, because it saves time when you load them up
858 again to have memory already ready to be filled.  The normal way to 
859 free up space used by an aggregate is to assign the empty list.
860
861 This counterintuitive behavior of C<defined()> on aggregates may be
862 changed, fixed, or broken in a future release of Perl.
863
864 See also L</undef>, L</exists>, L</ref>.
865
866 =item delete EXPR
867
868 Deletes the specified key(s) and their associated values from a hash.
869 For each key, returns the deleted value associated with that key, or
870 the undefined value if there was no such key.  Deleting from C<$ENV{}>
871 modifies the environment.  Deleting from a hash tied to a DBM file
872 deletes the entry from the DBM file.  (But deleting from a C<tie()>d hash
873 doesn't necessarily return anything.)
874
875 The following deletes all the values of a hash:
876
877     foreach $key (keys %HASH) {
878         delete $HASH{$key};
879     }
880
881 And so does this:
882
883     delete @HASH{keys %HASH}
884
885 (But both of these are slower than just assigning the empty list, or
886 using C<undef()>.)  Note that the EXPR can be arbitrarily complicated as
887 long as the final operation is a hash element lookup or hash slice:
888
889     delete $ref->[$x][$y]{$key};
890     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
891
892 =item die LIST
893
894 Outside an C<eval()>, prints the value of LIST to C<STDERR> and exits with
895 the current value of C<$!> (errno).  If C<$!> is C<0>, exits with the value of
896 C<($? E<gt>E<gt> 8)> (backtick `command` status).  If C<($? E<gt>E<gt> 8)>
897 is C<0>, exits with C<255>.  Inside an C<eval(),> the error message is stuffed into
898 C<$@> and the C<eval()> is terminated with the undefined value.  This makes
899 C<die()> the way to raise an exception.
900
901 Equivalent examples:
902
903     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
904     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
905
906 If the value of EXPR does not end in a newline, the current script line
907 number and input line number (if any) are also printed, and a newline
908 is supplied.  Hint: sometimes appending C<", stopped"> to your message
909 will cause it to make better sense when the string C<"at foo line 123"> is
910 appended.  Suppose you are running script "canasta".
911
912     die "/etc/games is no good";
913     die "/etc/games is no good, stopped";
914
915 produce, respectively
916
917     /etc/games is no good at canasta line 123.
918     /etc/games is no good, stopped at canasta line 123.
919
920 See also C<exit()> and C<warn()>.
921
922 If LIST is empty and C<$@> already contains a value (typically from a
923 previous eval) that value is reused after appending C<"\t...propagated">.
924 This is useful for propagating exceptions:
925
926     eval { ... };
927     die unless $@ =~ /Expected exception/;
928
929 If C<$@> is empty then the string C<"Died"> is used.
930
931 You can arrange for a callback to be run just before the C<die()> does
932 its deed, by setting the C<$SIG{__DIE__}> hook.  The associated handler
933 will be called with the error text and can change the error message, if
934 it sees fit, by calling C<die()> again.  See L<perlvar/$SIG{expr}> for details on
935 setting C<%SIG> entries, and L<"eval BLOCK"> for some examples.
936
937 Note that the C<$SIG{__DIE__}> hook is called even inside eval()ed
938 blocks/strings.  If one wants the hook to do nothing in such
939 situations, put
940
941         die @_ if $^S;
942
943 as the first line of the handler (see L<perlvar/$^S>).
944
945 =item do BLOCK
946
947 Not really a function.  Returns the value of the last command in the
948 sequence of commands indicated by BLOCK.  When modified by a loop
949 modifier such as L</while> or L</until>, executes the BLOCK once
950 before testing the loop condition.  (On other statements the loop
951 modifiers test the conditional first.)
952
953 C<do BLOCK> does I<not> count as a loop, so the loop control statements
954 L</next>, L</last> or L</redo> cannot be used to leave or restart the block.
955
956 =item do SUBROUTINE(LIST)
957
958 A deprecated form of subroutine call.  See L<perlsub>.
959
960 =item do EXPR
961
962 Uses the value of EXPR as a filename and executes the contents of the
963 file as a Perl script.  Its primary use is to include subroutines
964 from a Perl subroutine library.
965
966     do 'stat.pl';
967
968 is just like
969
970     scalar eval `cat stat.pl`;
971
972 except that it's more efficient and concise, keeps track of the
973 current filename for error messages, and searches all the B<-I>
974 libraries if the file isn't in the current directory (see also the @INC
975 array in L<perlvar/Predefined Names>).  It is also different in how
976 code evaluated with C<do FILENAME> doesn't see lexicals in the enclosing
977 scope like C<eval STRING> does.  It's the same, however, in that it does
978 reparse the file every time you call it, so you probably don't want to
979 do this inside a loop.
980
981 If C<do> cannot read the file, it returns undef and sets C<$!> to the
982 error.    If C<do> can read the file but cannot compile it, it
983 returns undef and sets an error message in C<$@>.   If the file is
984 successfully compiled, C<do> returns the value of the last expression
985 evaluated.
986
987 Note that inclusion of library modules is better done with the
988 C<use()> and C<require()> operators, which also do automatic error checking
989 and raise an exception if there's a problem.
990
991 You might like to use C<do> to read in a program configuration
992 file.  Manual error checking can be done this way:
993
994     # read in config files: system first, then user 
995     for $file ("/share/prog/defaults.rc",
996                "$ENV{HOME}/.someprogrc") {
997         unless ($return = do $file) {
998             warn "couldn't parse $file: $@" if $@;
999             warn "couldn't do $file: $!"    unless defined $return;
1000             warn "couldn't run $file"       unless $return;
1001         }
1002     }
1003
1004 =item dump LABEL
1005
1006 This causes an immediate core dump.  Primarily this is so that you can
1007 use the B<undump> program to turn your core dump into an executable binary
1008 after having initialized all your variables at the beginning of the
1009 program.  When the new binary is executed it will begin by executing a
1010 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
1011 it as a goto with an intervening core dump and reincarnation.  If C<LABEL>
1012 is omitted, restarts the program from the top.  WARNING: Any files
1013 opened at the time of the dump will NOT be open any more when the
1014 program is reincarnated, with possible resulting confusion on the part
1015 of Perl.  See also B<-u> option in L<perlrun>.
1016
1017 Example:
1018
1019     #!/usr/bin/perl
1020     require 'getopt.pl';
1021     require 'stat.pl';
1022     %days = (
1023         'Sun' => 1,
1024         'Mon' => 2,
1025         'Tue' => 3,
1026         'Wed' => 4,
1027         'Thu' => 5,
1028         'Fri' => 6,
1029         'Sat' => 7,
1030     );
1031
1032     dump QUICKSTART if $ARGV[0] eq '-d';
1033
1034     QUICKSTART:
1035     Getopt('f');
1036
1037 This operator is largely obsolete, partly because it's very hard to 
1038 convert a core file into an executable, and because the real perl-to-C
1039 compiler has superseded it.
1040
1041 =item each HASH
1042
1043 When called in list context, returns a 2-element list consisting of the
1044 key and value for the next element of a hash, so that you can iterate over
1045 it.  When called in scalar context, returns the key for only the "next"
1046 element in the hash.  (Note: Keys may be C<"0"> or C<"">, which are logically
1047 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
1048 for this reason.)
1049
1050 Entries are returned in an apparently random order.  When the hash is
1051 entirely read, a null array is returned in list context (which when
1052 assigned produces a FALSE (C<0>) value), and C<undef> in
1053 scalar context.  The next call to C<each()> after that will start iterating
1054 again.  There is a single iterator for each hash, shared by all C<each()>,
1055 C<keys()>, and C<values()> function calls in the program; it can be reset by
1056 reading all the elements from the hash, or by evaluating C<keys HASH> or
1057 C<values HASH>.  If you add or delete elements of a hash while you're
1058 iterating over it, you may get entries skipped or duplicated, so don't.
1059
1060 The following prints out your environment like the printenv(1) program,
1061 only in a different order:
1062
1063     while (($key,$value) = each %ENV) {
1064         print "$key=$value\n";
1065     }
1066
1067 See also C<keys()> and C<values()>.
1068
1069 =item else BLOCK
1070
1071 =item elsif (EXPR) BLOCK
1072
1073 See L</if>.
1074
1075 =item eof FILEHANDLE
1076
1077 =item eof ()
1078
1079 =item eof
1080
1081 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1082 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1083 gives the real filehandle.  (Note that this function actually
1084 reads a character and then C<ungetc()>s it, so isn't very useful in an
1085 interactive context.)  Do not read from a terminal file (or call
1086 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
1087 as terminals may lose the end-of-file condition if you do.
1088
1089 An C<eof> without an argument uses the last file read as argument.
1090 Using C<eof()> with empty parentheses is very different.  It indicates the pseudo file formed of
1091 the files listed on the command line, i.e., C<eof()> is reasonable to
1092 use inside a C<while (E<lt>E<gt>)> loop to detect the end of only the
1093 last file.  Use C<eof(ARGV)> or eof without the parentheses to test
1094 I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
1095
1096     # reset line numbering on each input file
1097     while (<>) {
1098         next if /^\s*#/;        # skip comments 
1099         print "$.\t$_";
1100     } continue {
1101         close ARGV  if eof;     # Not eof()!
1102     }
1103
1104     # insert dashes just before last line of last file
1105     while (<>) {
1106         if (eof()) {            # check for end of current file
1107             print "--------------\n";
1108             close(ARGV);        # close or break; is needed if we
1109                                 # are reading from the terminal
1110         }
1111         print;
1112     }
1113
1114 Practical hint: you almost never need to use C<eof> in Perl, because the
1115 input operators return false values when they run out of data, or if there
1116 was an error.
1117
1118 =item eval EXPR
1119
1120 =item eval BLOCK
1121
1122 In the first form, the return value of EXPR is parsed and executed as if it
1123 were a little Perl program.  The value of the expression (which is itself
1124 determined within scalar context) is first parsed, and if there weren't any
1125 errors, executed in the context of the current Perl program, so that any
1126 variable settings or subroutine and format definitions remain afterwards.
1127 Note that the value is parsed every time the eval executes.  If EXPR is
1128 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1129 and subsequent execution of the text of EXPR until run time.
1130
1131 In the second form, the code within the BLOCK is parsed only once--at the
1132 same time the code surrounding the eval itself was parsed--and executed
1133 within the context of the current Perl program.  This form is typically
1134 used to trap exceptions more efficiently than the first (see below), while
1135 also providing the benefit of checking the code within BLOCK at compile
1136 time.
1137
1138 The final semicolon, if any, may be omitted from the value of EXPR or within
1139 the BLOCK.
1140
1141 In both forms, the value returned is the value of the last expression
1142 evaluated inside the mini-program; a return statement may be also used, just
1143 as with subroutines.  The expression providing the return value is evaluated
1144 in void, scalar, or list context, depending on the context of the eval itself.
1145 See L</wantarray> for more on how the evaluation context can be determined.
1146
1147 If there is a syntax error or runtime error, or a C<die()> statement is
1148 executed, an undefined value is returned by C<eval()>, and C<$@> is set to the
1149 error message.  If there was no error, C<$@> is guaranteed to be a null
1150 string.  Beware that using C<eval()> neither silences perl from printing
1151 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1152 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1153 L</warn> and L<perlvar>.
1154
1155 Note that, because C<eval()> traps otherwise-fatal errors, it is useful for
1156 determining whether a particular feature (such as C<socket()> or C<symlink()>)
1157 is implemented.  It is also Perl's exception trapping mechanism, where
1158 the die operator is used to raise exceptions.
1159
1160 If the code to be executed doesn't vary, you may use the eval-BLOCK
1161 form to trap run-time errors without incurring the penalty of
1162 recompiling each time.  The error, if any, is still returned in C<$@>.
1163 Examples:
1164
1165     # make divide-by-zero nonfatal
1166     eval { $answer = $a / $b; }; warn $@ if $@;
1167
1168     # same thing, but less efficient
1169     eval '$answer = $a / $b'; warn $@ if $@;
1170
1171     # a compile-time error
1172     eval { $answer = };                 # WRONG
1173
1174     # a run-time error
1175     eval '$answer =';   # sets $@
1176
1177 When using the C<eval{}> form as an exception trap in libraries, you may
1178 wish not to trigger any C<__DIE__> hooks that user code may have
1179 installed.  You can use the C<local $SIG{__DIE__}> construct for this
1180 purpose, as shown in this example:
1181
1182     # a very private exception trap for divide-by-zero
1183     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1184     warn $@ if $@;
1185
1186 This is especially significant, given that C<__DIE__> hooks can call
1187 C<die()> again, which has the effect of changing their error messages:
1188
1189     # __DIE__ hooks may modify error messages
1190     {
1191        local $SIG{'__DIE__'} =
1192               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1193        eval { die "foo lives here" };
1194        print $@ if $@;                # prints "bar lives here"
1195     }
1196
1197 With an C<eval()>, you should be especially careful to remember what's
1198 being looked at when:
1199
1200     eval $x;            # CASE 1
1201     eval "$x";          # CASE 2
1202
1203     eval '$x';          # CASE 3
1204     eval { $x };        # CASE 4
1205
1206     eval "\$$x++";      # CASE 5
1207     $$x++;              # CASE 6
1208
1209 Cases 1 and 2 above behave identically: they run the code contained in
1210 the variable C<$x>.  (Although case 2 has misleading double quotes making
1211 the reader wonder what else might be happening (nothing is).)  Cases 3
1212 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1213 does nothing but return the value of C<$x>.  (Case 4 is preferred for
1214 purely visual reasons, but it also has the advantage of compiling at
1215 compile-time instead of at run-time.)  Case 5 is a place where
1216 normally you I<WOULD> like to use double quotes, except that in this
1217 particular situation, you can just use symbolic references instead, as
1218 in case 6.
1219
1220 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1221 C<next>, C<last> or C<redo> cannot be used to leave or restart the block.
1222
1223
1224 =item exec LIST
1225
1226 =item exec PROGRAM LIST
1227
1228 The C<exec()> function executes a system command I<AND NEVER RETURNS> -
1229 use C<system()> instead of C<exec()> if you want it to return. It fails and
1230 returns FALSE only if the command does not exist I<and> it is executed
1231 directly instead of via your system's command shell (see below).
1232
1233 Since it's a common mistake to use C<exec()> instead of C<system()>, Perl
1234 warns you if there is a following statement which isn't C<die()>, C<warn()>,
1235 or C<exit()> (if C<-w> is set  -  but you always do that).   If you
1236 I<really> want to follow an C<exec()> with some other statement, you
1237 can use one of these styles to avoid the warning:
1238
1239     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1240     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1241
1242 If there is more than one argument in LIST, or if LIST is an array
1243 with more than one value, calls execvp(3) with the arguments in LIST.
1244 If there is only one scalar argument or an array with one element in it,
1245 the argument is checked for shell metacharacters, and if there are any,
1246 the entire argument is passed to the system's command shell for parsing
1247 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1248 If there are no shell metacharacters in the argument, it is split into
1249 words and passed directly to C<execvp()>, which is more efficient.  Note:
1250 C<exec()> and C<system()> do not flush your output buffer, so you may need to
1251 set C<$|> to avoid lost output.  Examples:
1252
1253     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1254     exec "sort $outfile | uniq";
1255
1256 If you don't really want to execute the first argument, but want to lie
1257 to the program you are executing about its own name, you can specify
1258 the program you actually want to run as an "indirect object" (without a
1259 comma) in front of the LIST.  (This always forces interpretation of the
1260 LIST as a multivalued list, even if there is only a single scalar in
1261 the list.)  Example:
1262
1263     $shell = '/bin/csh';
1264     exec $shell '-sh';          # pretend it's a login shell
1265
1266 or, more directly,
1267
1268     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1269
1270 When the arguments get executed via the system shell, results will
1271 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1272 for details.
1273
1274 Using an indirect object with C<exec()> or C<system()> is also more secure.
1275 This usage forces interpretation of the arguments as a multivalued list,
1276 even if the list had just one argument.  That way you're safe from the
1277 shell expanding wildcards or splitting up words with whitespace in them.
1278
1279     @args = ( "echo surprise" );
1280
1281     system @args;               # subject to shell escapes
1282                                 # if @args == 1
1283     system { $args[0] } @args;  # safe even with one-arg list
1284
1285 The first version, the one without the indirect object, ran the I<echo>
1286 program, passing it C<"surprise"> an argument.  The second version
1287 didn't--it tried to run a program literally called I<"echo surprise">,
1288 didn't find it, and set C<$?> to a non-zero value indicating failure.
1289
1290 Note that C<exec()> will not call your C<END> blocks, nor will it call
1291 any C<DESTROY> methods in your objects.
1292
1293 =item exists EXPR
1294
1295 Returns TRUE if the specified hash key exists in its hash array, even
1296 if the corresponding value is undefined.
1297
1298     print "Exists\n" if exists $array{$key};
1299     print "Defined\n" if defined $array{$key};
1300     print "True\n" if $array{$key};
1301
1302 A hash element can be TRUE only if it's defined, and defined if
1303 it exists, but the reverse doesn't necessarily hold true.
1304
1305 Note that the EXPR can be arbitrarily complicated as long as the final
1306 operation is a hash key lookup:
1307
1308     if (exists $ref->{"A"}{"B"}{$key}) { ... }
1309
1310 Although the last element will not spring into existence just because its
1311 existence was tested, intervening ones will.  Thus C<$ref-E<gt>{"A"}>
1312 C<$ref-E<gt>{"B"}> will spring into existence due to the existence
1313 test for a $key element.  This autovivification may be fixed in a later
1314 release.
1315
1316 =item exit EXPR
1317
1318 Evaluates EXPR and exits immediately with that value.  (Actually, it
1319 calls any defined C<END> routines first, but the C<END> routines may not
1320 abort the exit.  Likewise any object destructors that need to be called
1321 are called before exit.)  Example:
1322
1323     $ans = <STDIN>;
1324     exit 0 if $ans =~ /^[Xx]/;
1325
1326 See also C<die()>.  If EXPR is omitted, exits with C<0> status.  The only
1327 universally portable values for EXPR are C<0> for success and C<1> for error;
1328 all other values are subject to unpredictable interpretation depending
1329 on the environment in which the Perl program is running.
1330
1331 You shouldn't use C<exit()> to abort a subroutine if there's any chance that
1332 someone might want to trap whatever error happened.  Use C<die()> instead,
1333 which can be trapped by an C<eval()>.
1334
1335 All C<END{}> blocks are run at exit time.  See L<perlsub> for details.
1336
1337 =item exp EXPR
1338
1339 =item exp
1340
1341 Returns I<e> (the natural logarithm base) to the power of EXPR.
1342 If EXPR is omitted, gives C<exp($_)>.
1343
1344 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1345
1346 Implements the fcntl(2) function.  You'll probably have to say
1347
1348     use Fcntl;
1349
1350 first to get the correct constant definitions.  Argument processing and
1351 value return works just like C<ioctl()> below.  
1352 For example:
1353
1354     use Fcntl;
1355     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1356         or die "can't fcntl F_GETFL: $!";
1357
1358 You don't have to check for C<defined()> on the return from 
1359 C<fnctl()>.  Like C<ioctl()>, it maps a C<0> return from the system
1360 call into "C<0> but true" in Perl.  This string is true in 
1361 boolean context and C<0> in numeric context.  It is also 
1362 exempt from the normal B<-w> warnings on improper numeric
1363 conversions.
1364
1365 Note that C<fcntl()> will produce a fatal error if used on a machine that
1366 doesn't implement fcntl(2).
1367
1368 =item fileno FILEHANDLE
1369
1370 Returns the file descriptor for a filehandle.  This is useful for
1371 constructing bitmaps for C<select()> and low-level POSIX tty-handling
1372 operations.  If FILEHANDLE is an expression, the value is taken as 
1373 an indirect filehandle, generally its name. 
1374
1375 You can use this to find out whether two handles refer to the 
1376 same underlying descriptor:
1377
1378     if (fileno(THIS) == fileno(THAT)) {
1379         print "THIS and THAT are dups\n";
1380     } 
1381
1382 =item flock FILEHANDLE,OPERATION
1383
1384 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns TRUE for
1385 success, FALSE on failure.  Produces a fatal error if used on a machine
1386 that doesn't implement flock(2), fcntl(2) locking, or lockf(3).  C<flock()>
1387 is Perl's portable file locking interface, although it locks only entire
1388 files, not records.
1389
1390 On many platforms (including most versions or clones of Unix), locks
1391 established by C<flock()> are B<merely advisory>.  Such discretionary locks
1392 are more flexible, but offer fewer guarantees.  This means that files
1393 locked with C<flock()> may be modified by programs that do not also use
1394 C<flock()>.  Windows NT and OS/2 are among the platforms which
1395 enforce mandatory locking.  See your local documentation for details.
1396
1397 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1398 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1399 you can use the symbolic names if import them from the Fcntl module,
1400 either individually, or as a group using the ':flock' tag.  LOCK_SH
1401 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1402 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1403 LOCK_EX then C<flock()> will return immediately rather than blocking
1404 waiting for the lock (check the return status to see if you got it).
1405
1406 To avoid the possibility of mis-coordination, Perl flushes FILEHANDLE
1407 before (un)locking it.
1408
1409 Note that the emulation built with lockf(3) doesn't provide shared
1410 locks, and it requires that FILEHANDLE be open with write intent.  These
1411 are the semantics that lockf(3) implements.  Most (all?) systems
1412 implement lockf(3) in terms of fcntl(2) locking, though, so the
1413 differing semantics shouldn't bite too many people.
1414
1415 Note also that some versions of C<flock()> cannot lock things over the
1416 network; you would need to use the more system-specific C<fcntl()> for
1417 that.  If you like you can force Perl to ignore your system's flock(2)
1418 function, and so provide its own fcntl(2)-based emulation, by passing
1419 the switch C<-Ud_flock> to the F<Configure> program when you configure
1420 perl.
1421
1422 Here's a mailbox appender for BSD systems.
1423
1424     use Fcntl ':flock'; # import LOCK_* constants
1425
1426     sub lock {
1427         flock(MBOX,LOCK_EX);
1428         # and, in case someone appended
1429         # while we were waiting...
1430         seek(MBOX, 0, 2);
1431     }
1432
1433     sub unlock {
1434         flock(MBOX,LOCK_UN);
1435     }
1436
1437     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1438             or die "Can't open mailbox: $!";
1439
1440     lock();
1441     print MBOX $msg,"\n\n";
1442     unlock();
1443
1444 See also L<DB_File> for other flock() examples.
1445
1446 =item for (INITIAL; WHILE; EACH) BLOCK
1447
1448 Do INITIAL, enter BLOCK while EXPR is true, at the end of each round
1449 do EACH. For example:
1450
1451         for ($i = 0, $j = 0; $i < 10; $i++) {
1452                 if ($i % 3 == 0) { $j++ }
1453                 print "i = $i, j = $j\n";
1454         }
1455
1456 See L<perlsyn> for more details.  See also L</foreach>, a twin of
1457 C<for>, L</while> and L</until>, close cousins of L<for>, and
1458 L</last>, L</next>, and L</redo> for additional control flow.
1459
1460 =item foreach LOOPVAR (LIST) BLOCK
1461
1462 Enter BLOCK as LOOPVAR set in turn to each element of LIST.
1463 For example:
1464
1465         foreach $rolling (@stones) { print "rolling $stone\n" }
1466
1467         foreach my $file (@files)  { print "file $file\n" }
1468
1469 The LOOPVAR is optional and defaults to C<$_>.  If the elements are
1470 modifiable (as opposed to constants or tied variables) you can modify them.
1471
1472         foreach (@words) { tr/abc/xyz/ }
1473
1474 See L<perlsyn> for more details.  See also L</for>, a twin of
1475 C<foreach>, L</while> and L</until>, close cousins of L<for>, and
1476 L</last>, L</next>, and L</redo> for additional control flow.
1477
1478 =item fork
1479
1480 Does a fork(2) system call.  Returns the child pid to the parent process,
1481 C<0> to the child process, or C<undef> if the fork is unsuccessful.
1482
1483 Note: unflushed buffers remain unflushed in both processes, which means
1484 you may need to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()>
1485 method of C<IO::Handle> to avoid duplicate output.
1486
1487 If you C<fork()> without ever waiting on your children, you will accumulate
1488 zombies:
1489
1490     $SIG{CHLD} = sub { wait };
1491
1492 There's also the double-fork trick (error checking on
1493 C<fork()> returns omitted);
1494
1495     unless ($pid = fork) {
1496         unless (fork) {
1497             exec "what you really wanna do";
1498             die "no exec";
1499             # ... or ...
1500             ## (some_perl_code_here)
1501             exit 0;
1502         }
1503         exit 0;
1504     }
1505     waitpid($pid,0);
1506
1507 See also L<perlipc> for more examples of forking and reaping
1508 moribund children.
1509
1510 Note that if your forked child inherits system file descriptors like
1511 STDIN and STDOUT that are actually connected by a pipe or socket, even
1512 if you exit, then the remote server (such as, say, httpd or rsh) won't think
1513 you're done.  You should reopen those to F</dev/null> if it's any issue.
1514
1515 =item format
1516
1517 Declare a picture format for use by the C<write()> function.  For
1518 example:
1519
1520     format Something =
1521         Test: @<<<<<<<< @||||| @>>>>>
1522               $str,     $%,    '$' . int($num)
1523     .
1524
1525     $str = "widget";
1526     $num = $cost/$quantity;
1527     $~ = 'Something';
1528     write;
1529
1530 See L<perlform> for many details and examples.
1531
1532 =item formline PICTURE,LIST
1533
1534 This is an internal function used by C<format>s, though you may call it,
1535 too.  It formats (see L<perlform>) a list of values according to the
1536 contents of PICTURE, placing the output into the format output
1537 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1538 Eventually, when a C<write()> is done, the contents of
1539 C<$^A> are written to some filehandle, but you could also read C<$^A>
1540 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1541 does one C<formline()> per line of form, but the C<formline()> function itself
1542 doesn't care how many newlines are embedded in the PICTURE.  This means
1543 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1544 You may therefore need to use multiple formlines to implement a single
1545 record format, just like the format compiler.
1546
1547 Be careful if you put double quotes around the picture, because an "C<@>"
1548 character may be taken to mean the beginning of an array name.
1549 C<formline()> always returns TRUE.  See L<perlform> for other examples.
1550
1551 =item getc FILEHANDLE
1552
1553 =item getc
1554
1555 Returns the next character from the input file attached to FILEHANDLE,
1556 or the undefined value at end of file, or if there was an error.  If
1557 FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1558 efficient.  It cannot be used to get unbuffered single-characters,
1559 however.  For that, try something more like:
1560
1561     if ($BSD_STYLE) {
1562         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1563     }
1564     else {
1565         system "stty", '-icanon', 'eol', "\001";
1566     }
1567
1568     $key = getc(STDIN);
1569
1570     if ($BSD_STYLE) {
1571         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1572     }
1573     else {
1574         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1575     }
1576     print "\n";
1577
1578 Determination of whether $BSD_STYLE should be set
1579 is left as an exercise to the reader.
1580
1581 The C<POSIX::getattr()> function can do this more portably on systems
1582 purporting POSIX compliance.
1583 See also the C<Term::ReadKey> module from your nearest CPAN site;
1584 details on CPAN can be found on L<perlmod/CPAN>.
1585
1586 =item getlogin
1587
1588 Implements the C library function of the same name, which on most
1589 systems returns the current login from F</etc/utmp>, if any.  If null,
1590 use C<getpwuid()>.
1591
1592     $login = getlogin || getpwuid($<) || "Kilroy";
1593
1594 Do not consider C<getlogin()> for authentication: it is not as
1595 secure as C<getpwuid()>.
1596
1597 =item getpeername SOCKET
1598
1599 Returns the packed sockaddr address of other end of the SOCKET connection.
1600
1601     use Socket;
1602     $hersockaddr    = getpeername(SOCK);
1603     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1604     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1605     $herstraddr     = inet_ntoa($iaddr);
1606
1607 =item getpgrp PID
1608
1609 Returns the current process group for the specified PID.  Use
1610 a PID of C<0> to get the current process group for the
1611 current process.  Will raise an exception if used on a machine that
1612 doesn't implement getpgrp(2).  If PID is omitted, returns process
1613 group of current process.  Note that the POSIX version of C<getpgrp()>
1614 does not accept a PID argument, so only C<PID==0> is truly portable.
1615
1616 =item getppid
1617
1618 Returns the process id of the parent process.
1619
1620 =item getpriority WHICH,WHO
1621
1622 Returns the current priority for a process, a process group, or a user.
1623 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1624 machine that doesn't implement getpriority(2).
1625
1626 =item getpwnam NAME
1627
1628 =item getgrnam NAME
1629
1630 =item gethostbyname NAME
1631
1632 =item getnetbyname NAME
1633
1634 =item getprotobyname NAME
1635
1636 =item getpwuid UID
1637
1638 =item getgrgid GID
1639
1640 =item getservbyname NAME,PROTO
1641
1642 =item gethostbyaddr ADDR,ADDRTYPE
1643
1644 =item getnetbyaddr ADDR,ADDRTYPE
1645
1646 =item getprotobynumber NUMBER
1647
1648 =item getservbyport PORT,PROTO
1649
1650 =item getpwent
1651
1652 =item getgrent
1653
1654 =item gethostent
1655
1656 =item getnetent
1657
1658 =item getprotoent
1659
1660 =item getservent
1661
1662 =item setpwent
1663
1664 =item setgrent
1665
1666 =item sethostent STAYOPEN
1667
1668 =item setnetent STAYOPEN
1669
1670 =item setprotoent STAYOPEN
1671
1672 =item setservent STAYOPEN
1673
1674 =item endpwent
1675
1676 =item endgrent
1677
1678 =item endhostent
1679
1680 =item endnetent
1681
1682 =item endprotoent
1683
1684 =item endservent
1685
1686 These routines perform the same functions as their counterparts in the
1687 system library.  In list context, the return values from the
1688 various get routines are as follows:
1689
1690     ($name,$passwd,$uid,$gid,
1691        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1692     ($name,$passwd,$gid,$members) = getgr*
1693     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1694     ($name,$aliases,$addrtype,$net) = getnet*
1695     ($name,$aliases,$proto) = getproto*
1696     ($name,$aliases,$port,$proto) = getserv*
1697
1698 (If the entry doesn't exist you get a null list.)
1699
1700 In scalar context, you get the name, unless the function was a
1701 lookup by name, in which case you get the other thing, whatever it is.
1702 (If the entry doesn't exist you get the undefined value.)  For example:
1703
1704     $uid   = getpwnam($name);
1705     $name  = getpwuid($num);
1706     $name  = getpwent();
1707     $gid   = getgrnam($name);
1708     $name  = getgrgid($num;
1709     $name  = getgrent();
1710     #etc.
1711
1712 In I<getpw*()> the fields C<$quota>, C<$comment>, and C<$expire> are special
1713 cases in the sense that in many systems they are unsupported.  If the
1714 C<$quota> is unsupported, it is an empty scalar.  If it is supported, it
1715 usually encodes the disk quota.  If the C<$comment> field is unsupported,
1716 it is an empty scalar.  If it is supported it usually encodes some
1717 administrative comment about the user.  In some systems the $quota
1718 field may be C<$change> or C<$age>, fields that have to do with password
1719 aging.  In some systems the C<$comment> field may be C<$class>.  The C<$expire>
1720 field, if present, encodes the expiration period of the account or the
1721 password.  For the availability and the exact meaning of these fields
1722 in your system, please consult your getpwnam(3) documentation and your
1723 F<pwd.h> file.  You can also find out from within Perl which meaning
1724 your C<$quota> and C<$comment> fields have and whether you have the C<$expire>
1725 field by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1726 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.
1727
1728 The C<$members> value returned by I<getgr*()> is a space separated list of
1729 the login names of the members of the group.
1730
1731 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1732 C, it will be returned to you via C<$?> if the function call fails.  The
1733 C<@addrs> value returned by a successful call is a list of the raw
1734 addresses returned by the corresponding system library call.  In the
1735 Internet domain, each address is four bytes long and you can unpack it
1736 by saying something like:
1737
1738     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1739
1740 If you get tired of remembering which element of the return list contains
1741 which return value, by-name interfaces are also provided in modules:
1742 C<File::stat>, C<Net::hostent>, C<Net::netent>, C<Net::protoent>, C<Net::servent>,
1743 C<Time::gmtime>, C<Time::localtime>, and C<User::grent>.  These override the
1744 normal built-in, replacing them with versions that return objects with
1745 the appropriate names for each field.  For example:
1746
1747    use File::stat;
1748    use User::pwent;
1749    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1750
1751 Even though it looks like they're the same method calls (uid), 
1752 they aren't, because a C<File::stat> object is different from a C<User::pwent> object.
1753
1754 =item getsockname SOCKET
1755
1756 Returns the packed sockaddr address of this end of the SOCKET connection.
1757
1758     use Socket;
1759     $mysockaddr = getsockname(SOCK);
1760     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1761
1762 =item getsockopt SOCKET,LEVEL,OPTNAME
1763
1764 Returns the socket option requested, or undef if there is an error.
1765
1766 =item glob EXPR
1767
1768 =item glob
1769
1770 Returns the value of EXPR with filename expansions such as the standard Unix shell F</bin/sh> would
1771 do.  This is the internal function implementing the C<E<lt>*.cE<gt>>
1772 operator, but you can use it directly.  If EXPR is omitted, C<$_> is used.
1773 The C<E<lt>*.cE<gt>> operator is discussed in more detail in
1774 L<perlop/"I/O Operators">.
1775
1776 =item gmtime EXPR
1777
1778 Converts a time as returned by the time function to a 9-element array
1779 with the time localized for the standard Greenwich time zone.
1780 Typically used as follows:
1781
1782     #  0    1    2     3     4    5     6     7     8
1783     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1784                                             gmtime(time);
1785
1786 All array elements are numeric, and come straight out of a struct tm.
1787 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
1788 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
1789 years since 1900, that is, C<$year> is C<123> in year 2023, I<not> simply the last two digits of the year.
1790
1791 If EXPR is omitted, does C<gmtime(time())>.
1792
1793 In scalar context, returns the ctime(3) value:
1794
1795     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1796
1797 Also see the C<timegm()> function provided by the C<Time::Local> module,
1798 and the strftime(3) function available via the POSIX module.
1799
1800 This scalar value is B<not> locale dependent, see L<perllocale>, but
1801 instead a Perl builtin.  Also see the C<Time::Local> module, and the
1802 strftime(3) and mktime(3) function available via the POSIX module.  To
1803 get somewhat similar but locale dependent date strings, set up your
1804 locale environment variables appropriately (please see L<perllocale>)
1805 and try for example:
1806
1807     use POSIX qw(strftime);
1808         $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
1809
1810 Note that the C<%a> and C<%b>, the short forms of the day of the week
1811 and the month of the year, may not necessarily be three characters wide.
1812
1813 =item goto LABEL
1814
1815 =item goto EXPR
1816
1817 =item goto &NAME
1818
1819 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
1820 execution there.  It may not be used to go into any construct that
1821 requires initialization, such as a subroutine or a C<foreach> loop.  It
1822 also can't be used to go into a construct that is optimized away,
1823 or to get out of a block or subroutine given to C<sort()>.
1824 It can be used to go almost anywhere else within the dynamic scope,
1825 including out of subroutines, but it's usually better to use some other
1826 construct such as C<last> or C<die()>.  The author of Perl has never felt the
1827 need to use this form of C<goto> (in Perl, that is--C is another matter).
1828
1829 The C<goto-EXPR> form expects a label name, whose scope will be resolved
1830 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
1831 necessarily recommended if you're optimizing for maintainability:
1832
1833     goto ("FOO", "BAR", "GLARCH")[$i];
1834
1835 The C<goto-&NAME> form is highly magical, and substitutes a call to the
1836 named subroutine for the currently running subroutine.  This is used by
1837 C<AUTOLOAD> subroutines that wish to load another subroutine and then
1838 pretend that the other subroutine had been called in the first place
1839 (except that any modifications to C<@_> in the current subroutine are
1840 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
1841 will be able to tell that this routine was called first.
1842
1843 =item grep BLOCK LIST
1844
1845 =item grep EXPR,LIST
1846
1847 This is similar in spirit to, but not the same as, grep(1)
1848 and its relatives.  In particular, it is not limited to using
1849 regular expressions.
1850
1851 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1852 C<$_> to each element) and returns the list value consisting of those
1853 elements for which the expression evaluated to TRUE.  In a scalar
1854 context, returns the number of times the expression was TRUE.
1855
1856     @foo = grep(!/^#/, @bar);    # weed out comments
1857
1858 or equivalently,
1859
1860     @foo = grep {!/^#/} @bar;    # weed out comments
1861
1862 Note that, because C<$_> is a reference into the list value, it can be used
1863 to modify the elements of the array.  While this is useful and
1864 supported, it can cause bizarre results if the LIST is not a named
1865 array.  Similarly, grep returns aliases into the original list,
1866 much like the way that a for loop's index variable aliases the list
1867 elements.  That is, modifying an element of a list returned by grep
1868 (for example, in a C<foreach>, C<map()> or another C<grep()>)
1869 actually modifies the element in the original list.
1870
1871 See also L</map> for an array composed of the results of the BLOCK or EXPR.
1872
1873 =item hex EXPR
1874
1875 =item hex
1876
1877 Interprets EXPR as a hex string and returns the corresponding
1878 value.  (To convert strings that might start with either 0 or 0x
1879 see L</oct>.)  If EXPR is omitted, uses C<$_>.
1880
1881     print hex '0xAf'; # prints '175'
1882     print hex 'aF';   # same
1883
1884 =item if (EXPR) BLOCK
1885
1886 =item if (EXPR) BLOCK else BLOCK2
1887
1888 =item if (EXPR) BLOCK elsif (EXPR2) BLOCK2
1889
1890 Enter BLOCKs conditionally.  The first EXPR to return true
1891 causes the corresponding BLOCK to be entered, or, in the case
1892 of C<else>, the fall-through default BLOCK.
1893
1894 Take notice: Perl wants BLOCKS, expressions (like e.g. in C, C++, or
1895 Pascal) won't do.
1896
1897 See L<perlsyn> for more details.  See also C<unless>.
1898
1899 =item import
1900
1901 There is no builtin C<import()> function.  It is just an ordinary
1902 method (subroutine) defined (or inherited) by modules that wish to export
1903 names to another module.  The C<use()> function calls the C<import()> method
1904 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
1905
1906 =item index STR,SUBSTR,POSITION
1907
1908 =item index STR,SUBSTR
1909
1910 Returns the position of the first occurrence of SUBSTR in STR at or after
1911 POSITION.  If POSITION is omitted, starts searching from the beginning of
1912 the string.  The return value is based at C<0> (or whatever you've set the C<$[>
1913 variable to--but don't do that).  If the substring is not found, returns
1914 one less than the base, ordinarily C<-1>.
1915
1916 =item int EXPR
1917
1918 =item int
1919
1920 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
1921 You should not use this for rounding, because it truncates
1922 towards C<0>, and because machine representations of floating point
1923 numbers can sometimes produce counterintuitive results.  Usually C<sprintf()> or C<printf()>,
1924 or the C<POSIX::floor> or C<POSIX::ceil> functions, would serve you better.
1925
1926 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1927
1928 Implements the ioctl(2) function.  You'll probably have to say
1929
1930     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1931
1932 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1933 exist or doesn't have the correct definitions you'll have to roll your
1934 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1935 (There is a Perl script called B<h2ph> that comes with the Perl kit that
1936 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
1937 written depending on the FUNCTION--a pointer to the string value of SCALAR
1938 will be passed as the third argument of the actual C<ioctl()> call.  (If SCALAR
1939 has no string value but does have a numeric value, that value will be
1940 passed rather than a pointer to the string value.  To guarantee this to be
1941 TRUE, add a C<0> to the scalar before using it.)  The C<pack()> and C<unpack()>
1942 functions are useful for manipulating the values of structures used by
1943 C<ioctl()>.  The following example sets the erase character to DEL.
1944
1945     require 'ioctl.ph';
1946     $getp = &TIOCGETP;
1947     die "NO TIOCGETP" if $@ || !$getp;
1948     $sgttyb_t = "ccccs";                # 4 chars and a short
1949     if (ioctl(STDIN,$getp,$sgttyb)) {
1950         @ary = unpack($sgttyb_t,$sgttyb);
1951         $ary[2] = 127;
1952         $sgttyb = pack($sgttyb_t,@ary);
1953         ioctl(STDIN,&TIOCSETP,$sgttyb)
1954             || die "Can't ioctl: $!";
1955     }
1956
1957 The return value of C<ioctl()> (and C<fcntl()>) is as follows:
1958
1959         if OS returns:          then Perl returns:
1960             -1                    undefined value
1961              0                  string "0 but true"
1962         anything else               that number
1963
1964 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1965 still easily determine the actual value returned by the operating
1966 system:
1967
1968     ($retval = ioctl(...)) || ($retval = -1);
1969     printf "System returned %d\n", $retval;
1970
1971 The special string "C<0> but true" is excempt from B<-w> complaints
1972 about improper numeric conversions.
1973
1974 =item join EXPR,LIST
1975
1976 Joins the separate strings of LIST into a single string with
1977 fields separated by the value of EXPR, and returns the string.
1978 Example:
1979
1980     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1981
1982 See L</split>.
1983
1984 =item keys HASH
1985
1986 Returns a list consisting of all the keys of the named hash.  (In a
1987 scalar context, returns the number of keys.)  The keys are returned in
1988 an apparently random order, but it is the same order as either the
1989 C<values()> or C<each()> function produces (given that the hash has not been
1990 modified).  As a side effect, it resets HASH's iterator.
1991
1992 Here is yet another way to print your environment:
1993
1994     @keys = keys %ENV;
1995     @values = values %ENV;
1996     while ($#keys >= 0) {
1997         print pop(@keys), '=', pop(@values), "\n";
1998     }
1999
2000 or how about sorted by key:
2001
2002     foreach $key (sort(keys %ENV)) {
2003         print $key, '=', $ENV{$key}, "\n";
2004     }
2005
2006 To sort a hash by value, you'll need to use a C<sort()> function.
2007 Here's a descending numeric sort of a hash by its values:
2008
2009     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2010         printf "%4d %s\n", $hash{$key}, $key;
2011     }
2012
2013 As an lvalue C<keys()> allows you to increase the number of hash buckets
2014 allocated for the given hash.  This can gain you a measure of efficiency if
2015 you know the hash is going to get big.  (This is similar to pre-extending
2016 an array by assigning a larger number to $#array.)  If you say
2017
2018     keys %hash = 200;
2019
2020 then C<%hash> will have at least 200 buckets allocated for it--256 of them, in fact, since 
2021 it rounds up to the next power of two.  These
2022 buckets will be retained even if you do C<%hash = ()>, use C<undef
2023 %hash> if you want to free the storage while C<%hash> is still in scope.
2024 You can't shrink the number of buckets allocated for the hash using
2025 C<keys()> in this way (but you needn't worry about doing this by accident,
2026 as trying has no effect).
2027
2028 =item kill LIST
2029
2030 Sends a signal to a list of processes.  The first element of
2031 the list must be the signal to send.  Returns the number of
2032 processes successfully signaled.
2033
2034     $cnt = kill 1, $child1, $child2;
2035     kill 9, @goners;
2036
2037 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
2038 process groups instead of processes.  (On System V, a negative I<PROCESS>
2039 number will also kill process groups, but that's not portable.)  That
2040 means you usually want to use positive not negative signals.  You may also
2041 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2042
2043 =item last LABEL
2044
2045 =item last
2046
2047 The C<last> command is like the C<break> statement in C (as used in
2048 loops); it immediately exits the loop in question.  If the LABEL is
2049 omitted, the command refers to the innermost enclosing loop.  The
2050 C<continue> block, if any, is not executed:
2051
2052     LINE: while (<STDIN>) {
2053         last LINE if /^$/;      # exit when done with header
2054         #...
2055     }
2056
2057 C<last> cannot be used to exit a block which returns a value such as
2058 C<eval {}>, C<sub {}> or C<do {}>.
2059
2060 See also L</continue> for an illustration of how C<last>, L</next>, and
2061 L</redo> work.
2062
2063 See also L<perlsyn>.
2064
2065 =item lc EXPR
2066
2067 =item lc
2068
2069 Returns an lowercased version of EXPR.  This is the internal function
2070 implementing the C<\L> escape in double-quoted strings.
2071 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2072
2073 If EXPR is omitted, uses C<$_>.
2074
2075 =item lcfirst EXPR
2076
2077 =item lcfirst
2078
2079 Returns the value of EXPR with the first character lowercased.  This is
2080 the internal function implementing the C<\l> escape in double-quoted strings.
2081 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2082
2083 If EXPR is omitted, uses C<$_>.
2084
2085 =item length EXPR
2086
2087 =item length
2088
2089 Returns the length in characters of the value of EXPR.  If EXPR is
2090 omitted, returns length of C<$_>.
2091
2092 =item link OLDFILE,NEWFILE
2093
2094 Creates a new filename linked to the old filename.  Returns TRUE for
2095 success, FALSE otherwise.
2096
2097 =item listen SOCKET,QUEUESIZE
2098
2099 Does the same thing that the listen system call does.  Returns TRUE if
2100 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
2101
2102 =item local EXPR
2103
2104 A local modifies the listed variables to be local to the enclosing
2105 block, file, or eval.  If more than one value is listed, the list must
2106 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2107 for details, including issues with tied arrays and hashes.
2108
2109 You really probably want to be using C<my()> instead, because C<local()> isn't
2110 what most people think of as "local".  See L<perlsub/"Private Variables
2111 via my()"> for details.
2112
2113 =item localtime EXPR
2114
2115 Converts a time as returned by the time function to a 9-element array
2116 with the time analyzed for the local time zone.  Typically used as
2117 follows:
2118
2119     #  0    1    2     3     4    5     6     7     8
2120     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2121                                                 localtime(time);
2122
2123 All array elements are numeric, and come straight out of a struct tm.
2124 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
2125 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
2126 years since 1900, that is, C<$year> is C<123> in year 2023, and I<not> simply the last two digits of the year.
2127
2128 If EXPR is omitted, uses the current time (C<localtime(time)>).
2129
2130 In scalar context, returns the ctime(3) value:
2131
2132     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2133
2134 This scalar value is B<not> locale dependent, see L<perllocale>, but
2135 instead a Perl builtin.  Also see the C<Time::Local> module, and the
2136 strftime(3) and mktime(3) function available via the POSIX module.  To
2137 get somewhat similar but locale dependent date strings, set up your
2138 locale environment variables appropriately (please see L<perllocale>)
2139 and try for example:
2140
2141     use POSIX qw(strftime);
2142         $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2143
2144 Note that the C<%a> and C<%b>, the short forms of the day of the week
2145 and the month of the year, may not necessarily be three characters wide.
2146
2147 =item log EXPR
2148
2149 =item log
2150
2151 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
2152 of C<$_>.
2153
2154 =item lstat FILEHANDLE
2155
2156 =item lstat EXPR
2157
2158 =item lstat
2159
2160 Does the same thing as the C<stat()> function (including setting the
2161 special C<_> filehandle) but stats a symbolic link instead of the file
2162 the symbolic link points to.  If symbolic links are unimplemented on
2163 your system, a normal C<stat()> is done.
2164
2165 If EXPR is omitted, stats C<$_>.
2166
2167 =item m//
2168
2169 The match operator.  See L<perlop>.
2170
2171 =item map BLOCK LIST
2172
2173 =item map EXPR,LIST
2174
2175 Evaluates the BLOCK or EXPR for each element of LIST (locally setting C<$_> to each
2176 element) and returns the list value composed of the results of each such
2177 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
2178 may produce zero, one, or more elements in the returned value.
2179
2180     @chars = map(chr, @nums);
2181
2182 translates a list of numbers to the corresponding characters.  And
2183
2184     %hash = map { getkey($_) => $_ } @array;
2185
2186 is just a funny way to write
2187
2188     %hash = ();
2189     foreach $_ (@array) {
2190         $hash{getkey($_)} = $_;
2191     }
2192
2193 Note that, because C<$_> is a reference into the list value, it can be used
2194 to modify the elements of the array.  While this is useful and
2195 supported, it can cause bizarre results if the LIST is not a named
2196 array.  See also L</grep> for an array composed of those items of the 
2197 original list for which the BLOCK or EXPR evaluates to true.
2198
2199 =item mkdir FILENAME,MODE
2200
2201 Creates the directory specified by FILENAME, with permissions
2202 specified by MODE (as modified by C<umask>).  If it succeeds it
2203 returns TRUE, otherwise it returns FALSE and sets C<$!> (errno).
2204
2205 In general, it is better to create directories with permissive MODEs,
2206 and let the user modify that with their C<umask>, than it is to supply
2207 a restrictive MODE and give the user no way to be more permissive.
2208 The exceptions to this rule are when the file or directory should be
2209 kept private (mail files, for instance).  The perlfunc(1) entry on
2210 C<umask> discusses the choice of MODE in more detail.
2211
2212 =item msgctl ID,CMD,ARG
2213
2214 Calls the System V IPC function msgctl(2).  You'll probably have to say
2215
2216     use IPC::SysV;
2217
2218 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2219 then ARG must be a variable which will hold the returned C<msqid_ds>
2220 structure.  Returns like C<ioctl()>: the undefined value for error, "C<0> but
2221 true" for zero, or the actual return value otherwise.  See also
2222 C<IPC::SysV> and C<IPC::Semaphore::Msg> documentation.
2223
2224 =item msgget KEY,FLAGS
2225
2226 Calls the System V IPC function msgget(2).  Returns the message queue
2227 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2228 and C<IPC::SysV::Msg> documentation.
2229
2230 =item msgsnd ID,MSG,FLAGS
2231
2232 Calls the System V IPC function msgsnd to send the message MSG to the
2233 message queue ID.  MSG must begin with the long integer message type,
2234 which may be created with C<pack("l", $type)>.  Returns TRUE if
2235 successful, or FALSE if there is an error.  See also C<IPC::SysV>
2236 and C<IPC::SysV::Msg> documentation.
2237
2238 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2239
2240 Calls the System V IPC function msgrcv to receive a message from
2241 message queue ID into variable VAR with a maximum message size of
2242 SIZE.  Note that if a message is received, the message type will be
2243 the first thing in VAR, and the maximum length of VAR is SIZE plus the
2244 size of the message type.  Returns TRUE if successful, or FALSE if
2245 there is an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2246
2247 =item my EXPR
2248
2249 A C<my()> declares the listed variables to be local (lexically) to the
2250 enclosing block, file, or C<eval()>.  If
2251 more than one value is listed, the list must be placed in parentheses.  See
2252 L<perlsub/"Private Variables via my()"> for details.
2253
2254 =item next LABEL
2255
2256 =item next
2257
2258 The C<next> command is like the C<continue> statement in C; it starts
2259 the next iteration of the loop:
2260
2261     LINE: while (<STDIN>) {
2262         next LINE if /^#/;      # discard comments
2263         #...
2264     }
2265
2266 Note that if there were a C<continue> block on the above, it would get
2267 executed even on discarded lines.  If the LABEL is omitted, the command
2268 refers to the innermost enclosing loop.
2269
2270 C<next> cannot be used to exit a block which returns a value such as
2271 C<eval {}>, C<sub {}> or C<do {}>.
2272
2273 See also L</continue> for an illustration of how L</last>, C<next>, and
2274 L</redo> work.
2275
2276 See also L<perlsyn>.
2277
2278 =item no Module LIST
2279
2280 See the L</use> function, which C<no> is the opposite of.
2281
2282 =item oct EXPR
2283
2284 =item oct
2285
2286 Interprets EXPR as an octal string and returns the corresponding
2287 value.  (If EXPR happens to start off with C<0x>, interprets it as
2288 a hex string instead.)  The following will handle decimal, octal, and
2289 hex in the standard Perl or C notation:
2290
2291     $val = oct($val) if $val =~ /^0/;
2292
2293 If EXPR is omitted, uses C<$_>.  This function is commonly used when
2294 a string such as C<644> needs to be converted into a file mode, for
2295 example. (Although perl will automatically convert strings into
2296 numbers as needed, this automatic conversion assumes base 10.)
2297
2298 =item open FILEHANDLE,EXPR
2299
2300 =item open FILEHANDLE
2301
2302 Opens the file whose filename is given by EXPR, and associates it with
2303 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2304 name of the real filehandle wanted.  If EXPR is omitted, the scalar
2305 variable of the same name as the FILEHANDLE contains the filename.
2306 (Note that lexical variables--those declared with C<my()>--will not work
2307 for this purpose; so if you're using C<my()>, specify EXPR in your call
2308 to open.)
2309
2310 If the filename begins with C<'E<lt>'> or nothing, the file is opened for input.
2311 If the filename begins with C<'E<gt>'>, the file is truncated and opened for
2312 output, being created if necessary. If the filename begins with C<'E<gt>E<gt>'>,
2313 the file is opened for appending, again being created if necessary. 
2314 You can put a C<'+'> in front of the C<'E<gt>'> or C<'E<lt>'> to indicate that
2315 you want both read and write access to the file; thus C<'+E<lt>'> is almost
2316 always preferred for read/write updates--the C<'+E<gt>'> mode would clobber the
2317 file first.  You can't usually use either read-write mode for updating
2318 textfiles, since they have variable length records.  See the B<-i>
2319 switch in L<perlrun> for a better approach.  The file is created with
2320 permissions of C<0666> modified by the process' C<umask> value.
2321
2322 The prefix and the filename may be separated with spaces.
2323 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>, C<'w'>,
2324 C<'w+'>, C<'a'>, and C<'a+'>.
2325
2326 If the filename begins with C<'|'>, the filename is interpreted as a
2327 command to which output is to be piped, and if the filename ends with a
2328 C<'|'>, the filename is interpreted See L<perlipc/"Using open() for IPC">
2329 for more examples of this.  (You are not allowed to C<open()> to a command
2330 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2331 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2332
2333 Opening C<'-'> opens STDIN and opening C<'E<gt>-'> opens STDOUT.  Open returns
2334 nonzero upon success, the undefined value otherwise.  If the C<open()>
2335 involved a pipe, the return value happens to be the pid of the
2336 subprocess.
2337
2338 If you're unfortunate enough to be running Perl on a system that
2339 distinguishes between text files and binary files (modern operating
2340 systems don't care), then you should check out L</binmode> for tips for
2341 dealing with this.  The key distinction between systems that need C<binmode()>
2342 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2343 Plan9, which delimit lines with a single character, and which encode that
2344 character in C as C<"\n">, do not need C<binmode()>.  The rest need it.
2345
2346 When opening a file, it's usually a bad idea to continue normal execution
2347 if the request failed, so C<open()> is frequently used in connection with
2348 C<die()>. Even if C<die()> won't do what you want (say, in a CGI script,
2349 where you want to make a nicely formatted error message (but there are
2350 modules that can help with that problem)) you should always check
2351 the return value from opening a file. The infrequent exception is when
2352 working with an unopened filehandle is actually what you want to do.
2353
2354 Examples:
2355
2356     $ARTICLE = 100;
2357     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2358     while (<ARTICLE>) {...
2359
2360     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
2361     # if the open fails, output is discarded
2362
2363     open(DBASE, '+<dbase.mine')             # open for update
2364         or die "Can't open 'dbase.mine' for update: $!";
2365
2366     open(ARTICLE, "caesar <$article |")     # decrypt article
2367         or die "Can't start caesar: $!";
2368
2369     open(EXTRACT, "|sort >/tmp/Tmp$$")      # $$ is our process id
2370         or die "Can't start sort: $!";
2371
2372     # process argument list of files along with any includes
2373
2374     foreach $file (@ARGV) {
2375         process($file, 'fh00');
2376     }
2377
2378     sub process {
2379         my($filename, $input) = @_;
2380         $input++;               # this is a string increment
2381         unless (open($input, $filename)) {
2382             print STDERR "Can't open $filename: $!\n";
2383             return;
2384         }
2385
2386         local $_;
2387         while (<$input>) {              # note use of indirection
2388             if (/^#include "(.*)"/) {
2389                 process($1, $input);
2390                 next;
2391             }
2392             #...                # whatever
2393         }
2394     }
2395
2396 You may also, in the Bourne shell tradition, specify an EXPR beginning
2397 with C<'E<gt>&'>, in which case the rest of the string is interpreted as the
2398 name of a filehandle (or file descriptor, if numeric) to be
2399 duped and opened.  You may use C<&> after C<E<gt>>, C<E<gt>E<gt>>, C<E<lt>>, C<+E<gt>>,
2400 C<+E<gt>E<gt>>, and C<+E<lt>>.  The
2401 mode you specify should match the mode of the original filehandle.
2402 (Duping a filehandle does not take into account any existing contents of
2403 stdio buffers.)
2404 Here is a script that saves, redirects, and restores STDOUT and
2405 STDERR:
2406
2407     #!/usr/bin/perl
2408     open(OLDOUT, ">&STDOUT");
2409     open(OLDERR, ">&STDERR");
2410
2411     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
2412     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
2413
2414     select(STDERR); $| = 1;     # make unbuffered
2415     select(STDOUT); $| = 1;     # make unbuffered
2416
2417     print STDOUT "stdout 1\n";  # this works for
2418     print STDERR "stderr 1\n";  # subprocesses too
2419
2420     close(STDOUT);
2421     close(STDERR);
2422
2423     open(STDOUT, ">&OLDOUT");
2424     open(STDERR, ">&OLDERR");
2425
2426     print STDOUT "stdout 2\n";
2427     print STDERR "stderr 2\n";
2428
2429
2430 If you specify C<'E<lt>&=N'>, where C<N> is a number, then Perl will do an
2431 equivalent of C's C<fdopen()> of that file descriptor; this is more
2432 parsimonious of file descriptors.  For example:
2433
2434     open(FILEHANDLE, "<&=$fd")
2435
2436 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>, then
2437 there is an implicit fork done, and the return value of open is the pid
2438 of the child within the parent process, and C<0> within the child
2439 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2440 The filehandle behaves normally for the parent, but i/o to that
2441 filehandle is piped from/to the STDOUT/STDIN of the child process.
2442 In the child process the filehandle isn't opened--i/o happens from/to
2443 the new STDOUT or STDIN.  Typically this is used like the normal
2444 piped open when you want to exercise more control over just how the
2445 pipe command gets executed, such as when you are running setuid, and
2446 don't want to have to scan shell commands for metacharacters.
2447 The following pairs are more or less equivalent:
2448
2449     open(FOO, "|tr '[a-z]' '[A-Z]'");
2450     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
2451
2452     open(FOO, "cat -n '$file'|");
2453     open(FOO, "-|") || exec 'cat', '-n', $file;
2454
2455 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2456
2457 NOTE: On any operation that may do a fork, any unflushed buffers remain
2458 unflushed in both processes, which means you may need to set C<$|> to
2459 avoid duplicate output.  On systems that support a close-on-exec flag on
2460 files, the flag will be set for the newly opened file descriptor as
2461 determined by the value of $^F.  See L<perlvar/$^F>.
2462
2463 Closing any piped filehandle causes the parent process to wait for the
2464 child to finish, and returns the status value in C<$?>.
2465
2466 The filename passed to open will have leading and trailing
2467 whitespace deleted, and the normal redirection characters
2468 honored.  This property, known as "magic open", 
2469 can often be used to good effect.  A user could specify a filename of
2470 F<"rsh cat file |">, or you could change certain filenames as needed:
2471
2472     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2473     open(FH, $filename) or die "Can't open $filename: $!";
2474
2475 However, to open a file with arbitrary weird characters in it, it's
2476 necessary to protect any leading and trailing whitespace:
2477
2478     $file =~ s#^(\s)#./$1#;
2479     open(FOO, "< $file\0");
2480
2481 If you want a "real" C C<open()> (see L<open(2)> on your system), then you
2482 should use the C<sysopen()> function, which involves no such magic.  This is
2483 another way to protect your filenames from interpretation.  For example:
2484
2485     use IO::Handle;
2486     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2487         or die "sysopen $path: $!";
2488     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2489     print HANDLE "stuff $$\n");
2490     seek(HANDLE, 0, 0);
2491     print "File contains: ", <HANDLE>;
2492
2493 Using the constructor from the C<IO::Handle> package (or one of its
2494 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2495 filehandles that have the scope of whatever variables hold references to
2496 them, and automatically close whenever and however you leave that scope:
2497
2498     use IO::File;
2499     #...
2500     sub read_myfile_munged {
2501         my $ALL = shift;
2502         my $handle = new IO::File;
2503         open($handle, "myfile") or die "myfile: $!";
2504         $first = <$handle>
2505             or return ();     # Automatically closed here.
2506         mung $first or die "mung failed";       # Or here.
2507         return $first, <$handle> if $ALL;       # Or here.
2508         $first;                                 # Or here.
2509     }
2510
2511 See L</seek()> for some details about mixing reading and writing.
2512
2513 =item opendir DIRHANDLE,EXPR
2514
2515 Opens a directory named EXPR for processing by C<readdir()>, C<telldir()>,
2516 C<seekdir()>, C<rewinddir()>, and C<closedir()>.  Returns TRUE if successful.
2517 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2518
2519 =item ord EXPR
2520
2521 =item ord
2522
2523 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2524 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2525
2526 =item pack TEMPLATE,LIST
2527
2528 Takes an array or list of values and packs it into a binary structure,
2529 returning the string containing the structure.  The TEMPLATE is a
2530 sequence of characters that give the order and type of values, as
2531 follows:
2532
2533     A   An ascii string, will be space padded.
2534     a   An ascii string, will be null padded.
2535     b   A bit string (ascending bit order, like vec()).
2536     B   A bit string (descending bit order).
2537     h   A hex string (low nybble first).
2538     H   A hex string (high nybble first).
2539
2540     c   A signed char value.
2541     C   An unsigned char value.  Only does bytes.  See U for Unicode.
2542
2543     s   A signed short value.
2544     S   An unsigned short value.
2545           (This 'short' is _exactly_ 16 bits, which may differ from
2546            what a local C compiler calls 'short'.)
2547
2548     i   A signed integer value.
2549     I   An unsigned integer value.
2550           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2551            size depends on what a local C compiler calls 'int',
2552            and may even be larger than the 'long' described in
2553            the next item.)
2554
2555     l   A signed long value.
2556     L   An unsigned long value.
2557           (This 'long' is _exactly_ 32 bits, which may differ from
2558            what a local C compiler calls 'long'.)
2559
2560     n   A short in "network" (big-endian) order.
2561     N   A long in "network" (big-endian) order.
2562     v   A short in "VAX" (little-endian) order.
2563     V   A long in "VAX" (little-endian) order.
2564           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2565            _exactly_ 32 bits, respectively.)
2566
2567     q   A signed quad (64-bit) value.
2568     Q   An unsigned quad value.
2569           (Available only if your system supports 64-bit integer values
2570            _and_ if Perl has been compiled to support those.
2571            Causes a fatal error otherwise.)
2572
2573     f   A single-precision float in the native format.
2574     d   A double-precision float in the native format.
2575
2576     p   A pointer to a null-terminated string.
2577     P   A pointer to a structure (fixed-length string).
2578
2579     u   A uuencoded string.
2580     U   A Unicode character number.  Encodes to UTF-8 internally.
2581         Works even if C<use utf8> is not in effect.
2582
2583     w   A BER compressed integer.  Its bytes represent an unsigned
2584         integer in base 128, most significant digit first, with as
2585         few digits as possible.  Bit eight (the high bit) is set
2586         on each byte except the last.
2587
2588     x   A null byte.
2589     X   Back up a byte.
2590     @   Null fill to absolute position.
2591
2592 Each letter may optionally be followed by a number giving a repeat
2593 count.  With all types except C<"a">, C<"A">, C<"b">, C<"B">, C<"h">, C<"H">, and C<"P"> the
2594 pack function will gobble up that many values from the LIST.  A C<*> for the
2595 repeat count means to use however many items are left.  The C<"a"> and C<"A">
2596 types gobble just one value, but pack it as a string of length count,
2597 padding with nulls or spaces as necessary.  (When unpacking, C<"A"> strips
2598 trailing spaces and nulls, but C<"a"> does not.)  Likewise, the C<"b"> and C<"B">
2599 fields pack a string that many bits long.  The C<"h"> and C<"H"> fields pack a
2600 string that many nybbles long.  The C<"p"> type packs a pointer to a null-
2601 terminated string.  You are responsible for ensuring the string is not a
2602 temporary value (which can potentially get deallocated before you get
2603 around to using the packed result).  The C<"P"> packs a pointer to a structure
2604 of the size indicated by the length. A NULL pointer is created if the 
2605 corresponding value for C<"p"> or C<"P"> is C<undef>.
2606 Real numbers (floats and doubles) are
2607 in the native machine format only; due to the multiplicity of floating
2608 formats around, and the lack of a standard "network" representation, no
2609 facility for interchange has been made.  This means that packed floating
2610 point data written on one machine may not be readable on another - even if
2611 both use IEEE floating point arithmetic (as the endian-ness of the memory
2612 representation is not part of the IEEE spec).  Note that Perl uses doubles
2613 internally for all numeric calculation, and converting from double into
2614 float and thence back to double again will lose precision (i.e.,
2615 C<unpack("f", pack("f", $foo)>) will not in general equal C<$foo>).
2616
2617 Examples:
2618
2619     $foo = pack("CCCC",65,66,67,68);
2620     # foo eq "ABCD"
2621     $foo = pack("C4",65,66,67,68);
2622     # same thing
2623     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
2624     # same thing with Unicode circled letters
2625
2626     $foo = pack("ccxxcc",65,66,67,68);
2627     # foo eq "AB\0\0CD"
2628
2629     $foo = pack("s2",1,2);
2630     # "\1\0\2\0" on little-endian
2631     # "\0\1\0\2" on big-endian
2632
2633     $foo = pack("a4","abcd","x","y","z");
2634     # "abcd"
2635
2636     $foo = pack("aaaa","abcd","x","y","z");
2637     # "axyz"
2638
2639     $foo = pack("a14","abcdefg");
2640     # "abcdefg\0\0\0\0\0\0\0"
2641
2642     $foo = pack("i9pl", gmtime);
2643     # a real struct tm (on my system anyway)
2644
2645     sub bintodec {
2646         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2647     }
2648
2649 The same template may generally also be used in the unpack function.
2650
2651 =item package 
2652
2653 =item package NAMESPACE
2654
2655 Declares the compilation unit as being in the given namespace.  The scope
2656 of the package declaration is from the declaration itself through the end of
2657 the enclosing block (the same scope as the C<local()> operator).  All further
2658 unqualified dynamic identifiers will be in this namespace.  A package
2659 statement affects only dynamic variables--including those you've used
2660 C<local()> on--but I<not> lexical variables created with C<my()>.  Typically it
2661 would be the first declaration in a file to be included by the C<require>
2662 or C<use> operator.  You can switch into a package in more than one place;
2663 it merely influences which symbol table is used by the compiler for the
2664 rest of that block.  You can refer to variables and filehandles in other
2665 packages by prefixing the identifier with the package name and a double
2666 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2667 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2668
2669 If NAMESPACE is omitted, then there is no current package, and all
2670 identifiers must be fully qualified or lexicals.  This is stricter
2671 than C<use strict>, since it also extends to function names.
2672
2673 See L<perlmod/"Packages"> for more information about packages, modules,
2674 and classes.  See L<perlsub> for other scoping issues.
2675
2676 =item pipe READHANDLE,WRITEHANDLE
2677
2678 Opens a pair of connected pipes like the corresponding system call.
2679 Note that if you set up a loop of piped processes, deadlock can occur
2680 unless you are very careful.  In addition, note that Perl's pipes use
2681 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2682 after each command, depending on the application.
2683
2684 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2685 for examples of such things.
2686
2687 On systems that support a close-on-exec flag on files, the flag will be set
2688 for the newly opened file descriptors as determined by the value of $^F.
2689 See L<perlvar/$^F>.
2690
2691 =item pop ARRAY
2692
2693 =item pop
2694
2695 Pops and returns the last value of the array, shortening the array by
2696 1.  Has a similar effect to
2697
2698     $tmp = $ARRAY[$#ARRAY--];
2699
2700 If there are no elements in the array, returns the undefined value.
2701 If ARRAY is omitted, pops the
2702 C<@ARGV> array in the main program, and the C<@_> array in subroutines, just
2703 like C<shift()>.
2704
2705 =item pos SCALAR
2706
2707 =item pos
2708
2709 Returns the offset of where the last C<m//g> search left off for the variable
2710 is in question (C<$_> is used when the variable is not specified).  May be
2711 modified to change that offset.  Such modification will also influence
2712 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
2713 L<perlop>.
2714
2715 =item print FILEHANDLE LIST
2716
2717 =item print LIST
2718
2719 =item print
2720
2721 Prints a string or a comma-separated list of strings.  Returns TRUE
2722 if successful.  FILEHANDLE may be a scalar variable name, in which case
2723 the variable contains the name of or a reference to the filehandle, thus introducing one
2724 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2725 token is a term, it may be misinterpreted as an operator unless you
2726 interpose a C<+> or put parentheses around the arguments.)  If FILEHANDLE is
2727 omitted, prints by default to standard output (or to the last selected
2728 output channel--see L</select>).  If LIST is also omitted, prints C<$_> to
2729 the currently selected output channel.  To set the default output channel to something other than
2730 STDOUT use the select operation.  Note that, because print takes a
2731 LIST, anything in the LIST is evaluated in list context, and any
2732 subroutine that you call will have one or more of its expressions
2733 evaluated in list context.  Also be careful not to follow the print
2734 keyword with a left parenthesis unless you want the corresponding right
2735 parenthesis to terminate the arguments to the print--interpose a C<+> or
2736 put parentheses around all the arguments.
2737
2738 Note that if you're storing FILEHANDLES in an array or other expression,
2739 you will have to use a block returning its value instead:
2740
2741     print { $files[$i] } "stuff\n";
2742     print { $OK ? STDOUT : STDERR } "stuff\n";
2743
2744 =item printf FILEHANDLE FORMAT, LIST
2745
2746 =item printf FORMAT, LIST
2747
2748 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
2749 (the output record separator) is not appended.  The first argument
2750 of the list will be interpreted as the C<printf()> format.  If C<use locale> is
2751 in effect, the character used for the decimal point in formatted real numbers
2752 is affected by the LC_NUMERIC locale.  See L<perllocale>.
2753
2754 Don't fall into the trap of using a C<printf()> when a simple
2755 C<print()> would do.  The C<print()> is more efficient and less
2756 error prone.
2757
2758 =item prototype FUNCTION
2759
2760 Returns the prototype of a function as a string (or C<undef> if the
2761 function has no prototype).  FUNCTION is a reference to, or the name of,
2762 the function whose prototype you want to retrieve.
2763
2764 If FUNCTION is a string starting with C<CORE::>, the rest is taken as
2765 a name for Perl builtin.  If builtin is not I<overridable> (such as
2766 C<qw//>) or its arguments cannot be expressed by a prototype (such as
2767 C<system()>) - in other words, the builtin does not behave like a Perl
2768 function - returns C<undef>.  Otherwise, the string describing the
2769 equivalent prototype is returned.
2770
2771 =item push ARRAY,LIST
2772
2773 Treats ARRAY as a stack, and pushes the values of LIST
2774 onto the end of ARRAY.  The length of ARRAY increases by the length of
2775 LIST.  Has the same effect as
2776
2777     for $value (LIST) {
2778         $ARRAY[++$#ARRAY] = $value;
2779     }
2780
2781 but is more efficient.  Returns the new number of elements in the array.
2782
2783 =item q/STRING/
2784
2785 =item qq/STRING/
2786
2787 =item qr/STRING/
2788
2789 =item qx/STRING/
2790
2791 =item qw/STRING/
2792
2793 Generalized quotes.  See L<perlop>.
2794
2795 =item quotemeta EXPR
2796
2797 =item quotemeta
2798
2799 Returns the value of EXPR with all non-alphanumeric
2800 characters backslashed.  (That is, all characters not matching
2801 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
2802 returned string, regardless of any locale settings.)
2803 This is the internal function implementing
2804 the C<\Q> escape in double-quoted strings.
2805
2806 If EXPR is omitted, uses C<$_>.
2807
2808 =item rand EXPR
2809
2810 =item rand
2811
2812 Returns a random fractional number greater than or equal to C<0> and less
2813 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
2814 omitted, the value C<1> is used.  Automatically calls C<srand()> unless
2815 C<srand()> has already been called.  See also C<srand()>.
2816
2817 (Note: If your rand function consistently returns numbers that are too
2818 large or too small, then your version of Perl was probably compiled
2819 with the wrong number of RANDBITS.)
2820
2821 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2822
2823 =item read FILEHANDLE,SCALAR,LENGTH
2824
2825 Attempts to read LENGTH bytes of data into variable SCALAR from the
2826 specified FILEHANDLE.  Returns the number of bytes actually read,
2827 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
2828 or shrunk to the length actually read.  An OFFSET may be specified to
2829 place the read data at some other place than the beginning of the
2830 string.  This call is actually implemented in terms of stdio's fread(3)
2831 call.  To get a true read(2) system call, see C<sysread()>.
2832
2833 =item readdir DIRHANDLE
2834
2835 Returns the next directory entry for a directory opened by C<opendir()>.
2836 If used in list context, returns all the rest of the entries in the
2837 directory.  If there are no more entries, returns an undefined value in
2838 scalar context or a null list in list context.
2839
2840 If you're planning to filetest the return values out of a C<readdir()>, you'd
2841 better prepend the directory in question.  Otherwise, because we didn't
2842 C<chdir()> there, it would have been testing the wrong file.
2843
2844     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2845     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2846     closedir DIR;
2847
2848 =item readline EXPR
2849
2850 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar context, a single line
2851 is read and returned.  In list context, reads until end-of-file is
2852 reached and returns a list of lines (however you've defined lines
2853 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2854 This is the internal function implementing the C<E<lt>EXPRE<gt>>
2855 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
2856 operator is discussed in more detail in L<perlop/"I/O Operators">.
2857
2858     $line = <STDIN>;
2859     $line = readline(*STDIN);           # same thing
2860
2861 =item readlink EXPR
2862
2863 =item readlink
2864
2865 Returns the value of a symbolic link, if symbolic links are
2866 implemented.  If not, gives a fatal error.  If there is some system
2867 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2868 omitted, uses C<$_>.
2869
2870 =item readpipe EXPR
2871
2872 EXPR is executed as a system command.
2873 The collected standard output of the command is returned.
2874 In scalar context, it comes back as a single (potentially
2875 multi-line) string.  In list context, returns a list of lines
2876 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2877 This is the internal function implementing the C<qx/EXPR/>
2878 operator, but you can use it directly.  The C<qx/EXPR/>
2879 operator is discussed in more detail in L<perlop/"I/O Operators">.
2880
2881 =item recv SOCKET,SCALAR,LEN,FLAGS
2882
2883 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2884 data into variable SCALAR from the specified SOCKET filehandle.
2885 Actually does a C C<recvfrom()>, so that it can return the address of the
2886 sender.  Returns the undefined value if there's an error.  SCALAR will
2887 be grown or shrunk to the length actually read.  Takes the same flags
2888 as the system call of the same name.
2889 See L<perlipc/"UDP: Message Passing"> for examples.
2890
2891 =item redo LABEL
2892
2893 =item redo
2894
2895 The C<redo> command restarts the loop block without evaluating the
2896 conditional again.  The L</continue> block, if any, is not executed.  If
2897 the LABEL is omitted, the command refers to the innermost enclosing
2898 loop.  This command is normally used by programs that want to lie to
2899 themselves about what was just input:
2900
2901     # a simpleminded Pascal comment stripper
2902     # (warning: assumes no { or } in strings)
2903     LINE: while (<STDIN>) {
2904         while (s|({.*}.*){.*}|$1 |) {}
2905         s|{.*}| |;
2906         if (s|{.*| |) {
2907             $front = $_;
2908             while (<STDIN>) {
2909                 if (/}/) {      # end of comment?
2910                     s|^|$front\{|;
2911                     redo LINE;
2912                 }
2913             }
2914         }
2915         print;
2916     }
2917
2918 C<redo> cannot be used to retry a block which returns a value such as
2919 C<eval {}>, C<sub {}> or C<do {}>.
2920
2921 See also L</continue> for an illustration of how L</last>, L</next>, and
2922 C<redo> work.
2923
2924 See also L<perlsyn>.
2925
2926 =item ref EXPR
2927
2928 =item ref
2929
2930 Returns a TRUE value if EXPR is a reference, FALSE otherwise.  If EXPR
2931 is not specified, C<$_> will be used.  The value returned depends on the
2932 type of thing the reference is a reference to.
2933 Builtin types include:
2934
2935     REF
2936     SCALAR
2937     ARRAY
2938     HASH
2939     CODE
2940     GLOB
2941
2942 If the referenced object has been blessed into a package, then that package
2943 name is returned instead.  You can think of C<ref()> as a C<typeof()> operator.
2944
2945     if (ref($r) eq "HASH") {
2946         print "r is a reference to a hash.\n";
2947     }
2948     if (!ref($r)) {
2949         print "r is not a reference at all.\n";
2950     }
2951
2952 See also L<perlref>.
2953
2954 =item rename OLDNAME,NEWNAME
2955
2956 Changes the name of a file.  Returns C<1> for success, C<0> otherwise.  Will
2957 not work across file system boundaries.
2958
2959 =item require EXPR
2960
2961 =item require
2962
2963 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
2964 supplied.  If EXPR is numeric, demands that the current version of Perl
2965 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2966
2967 Otherwise, demands that a library file be included if it hasn't already
2968 been included.  The file is included via the do-FILE mechanism, which is
2969 essentially just a variety of C<eval()>.  Has semantics similar to the following
2970 subroutine:
2971
2972     sub require {
2973         my($filename) = @_;
2974         return 1 if $INC{$filename};
2975         my($realfilename,$result);
2976         ITER: {
2977             foreach $prefix (@INC) {
2978                 $realfilename = "$prefix/$filename";
2979                 if (-f $realfilename) {
2980                     $result = do $realfilename;
2981                     last ITER;
2982                 }
2983             }
2984             die "Can't find $filename in \@INC";
2985         }
2986         die $@ if $@;
2987         die "$filename did not return true value" unless $result;
2988         $INC{$filename} = $realfilename;
2989         return $result;
2990     }
2991
2992 Note that the file will not be included twice under the same specified
2993 name.  The file must return TRUE as the last statement to indicate
2994 successful execution of any initialization code, so it's customary to
2995 end such a file with "C<1;>" unless you're sure it'll return TRUE
2996 otherwise.  But it's better just to put the "C<1;>", in case you add more
2997 statements.
2998
2999 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3000 replaces "F<::>" with "F</>" in the filename for you,
3001 to make it easy to load standard modules.  This form of loading of
3002 modules does not risk altering your namespace.
3003
3004 In other words, if you try this:
3005
3006         require Foo::Bar;    # a splendid bareword 
3007
3008 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
3009 directories specified in the C<@INC> array.
3010
3011 But if you try this:
3012
3013         $class = 'Foo::Bar';
3014         require $class;      # $class is not a bareword
3015     #or
3016         require "Foo::Bar";  # not a bareword because of the ""
3017
3018 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
3019 will complain about not finding "F<Foo::Bar>" there. In this case you can do:
3020
3021         eval "require $class";
3022
3023 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3024
3025 =item reset EXPR
3026
3027 =item reset
3028
3029 Generally used in a C<continue> block at the end of a loop to clear
3030 variables and reset C<??> searches so that they work again.  The
3031 expression is interpreted as a list of single characters (hyphens
3032 allowed for ranges).  All variables and arrays beginning with one of
3033 those letters are reset to their pristine state.  If the expression is
3034 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3035 only variables or searches in the current package.  Always returns
3036 1.  Examples:
3037
3038     reset 'X';          # reset all X variables
3039     reset 'a-z';        # reset lower case variables
3040     reset;              # just reset ?? searches
3041
3042 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3043 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package variables--lexical variables
3044 are unaffected, but they clean themselves up on scope exit anyway,
3045 so you'll probably want to use them instead.  See L</my>.
3046
3047 =item return EXPR
3048
3049 =item return
3050
3051 Returns from a subroutine, C<eval()>, or C<do FILE> with the value 
3052 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3053 context, depending on how the return value will be used, and the context
3054 may vary from one execution to the next (see C<wantarray()>).  If no EXPR
3055 is given, returns an empty list in list context, an undefined value in
3056 scalar context, or nothing in a void context.
3057
3058 (Note that in the absence of a return, a subroutine, eval, or do FILE
3059 will automatically return the value of the last expression evaluated.)
3060
3061 =item reverse LIST
3062
3063 In list context, returns a list value consisting of the elements
3064 of LIST in the opposite order.  In scalar context, concatenates the
3065 elements of LIST, and returns a string value with all the characters
3066 in the opposite order.
3067
3068     print reverse <>;           # line tac, last line first
3069
3070     undef $/;                   # for efficiency of <>
3071     print scalar reverse <>;    # character tac, last line tsrif
3072
3073 This operator is also handy for inverting a hash, although there are some
3074 caveats.  If a value is duplicated in the original hash, only one of those
3075 can be represented as a key in the inverted hash.  Also, this has to
3076 unwind one hash and build a whole new one, which may take some time
3077 on a large hash.
3078
3079     %by_name = reverse %by_address;     # Invert the hash
3080
3081 =item rewinddir DIRHANDLE
3082
3083 Sets the current position to the beginning of the directory for the
3084 C<readdir()> routine on DIRHANDLE.
3085
3086 =item rindex STR,SUBSTR,POSITION
3087
3088 =item rindex STR,SUBSTR
3089
3090 Works just like index except that it returns the position of the LAST
3091 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3092 last occurrence at or before that position.
3093
3094 =item rmdir FILENAME
3095
3096 =item rmdir
3097
3098 Deletes the directory specified by FILENAME if that directory is empty.  If it
3099 succeeds it returns TRUE, otherwise it returns FALSE and sets C<$!> (errno).  If
3100 FILENAME is omitted, uses C<$_>.
3101
3102 =item s///
3103
3104 The substitution operator.  See L<perlop>.
3105
3106 =item scalar EXPR
3107
3108 Forces EXPR to be interpreted in scalar context and returns the value
3109 of EXPR.
3110
3111     @counts = ( scalar @a, scalar @b, scalar @c );
3112
3113 There is no equivalent operator to force an expression to
3114 be interpolated in list context because it's in practice never
3115 needed.  If you really wanted to do so, however, you could use
3116 the construction C<@{[ (some expression) ]}>, but usually a simple
3117 C<(some expression)> suffices.
3118
3119 =item seek FILEHANDLE,POSITION,WHENCE
3120
3121 Sets FILEHANDLE's position, just like the C<fseek()> call of C<stdio()>.
3122 FILEHANDLE may be an expression whose value gives the name of the
3123 filehandle.  The values for WHENCE are C<0> to set the new position to
3124 POSITION, C<1> to set it to the current position plus POSITION, and C<2> to
3125 set it to EOF plus POSITION (typically negative).  For WHENCE you may
3126 use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END> from either the
3127 C<IO::Seekable> or the POSIX module.  Returns C<1> upon success, C<0> otherwise.
3128
3129 If you want to position file for C<sysread()> or C<syswrite()>, don't use
3130 C<seek()> -- buffering makes its effect on the file's system position
3131 unpredictable and non-portable.  Use C<sysseek()> instead.
3132
3133 On some systems you have to do a seek whenever you switch between reading
3134 and writing.  Amongst other things, this may have the effect of calling
3135 stdio's clearerr(3).  A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving
3136 the file position:
3137
3138     seek(TEST,0,1);
3139
3140 This is also useful for applications emulating C<tail -f>.  Once you hit
3141 EOF on your read, and then sleep for a while, you might have to stick in a
3142 seek() to reset things.  The C<seek()> doesn't change the current position,
3143 but it I<does> clear the end-of-file condition on the handle, so that the
3144 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
3145
3146 If that doesn't work (some stdios are particularly cantankerous), then
3147 you may need something more like this:
3148
3149     for (;;) {
3150         for ($curpos = tell(FILE); $_ = <FILE>;
3151              $curpos = tell(FILE)) {
3152             # search for some stuff and put it into files
3153         }
3154         sleep($for_a_while);
3155         seek(FILE, $curpos, 0);
3156     }
3157
3158 =item seekdir DIRHANDLE,POS
3159
3160 Sets the current position for the C<readdir()> routine on DIRHANDLE.  POS
3161 must be a value returned by C<telldir()>.  Has the same caveats about
3162 possible directory compaction as the corresponding system library
3163 routine.
3164
3165 =item select FILEHANDLE
3166
3167 =item select
3168
3169 Returns the currently selected filehandle.  Sets the current default
3170 filehandle for output, if FILEHANDLE is supplied.  This has two
3171 effects: first, a C<write()> or a C<print()> without a filehandle will
3172 default to this FILEHANDLE.  Second, references to variables related to
3173 output will refer to this output channel.  For example, if you have to
3174 set the top of form format for more than one output channel, you might
3175 do the following:
3176
3177     select(REPORT1);
3178     $^ = 'report1_top';
3179     select(REPORT2);
3180     $^ = 'report2_top';
3181
3182 FILEHANDLE may be an expression whose value gives the name of the
3183 actual filehandle.  Thus:
3184
3185     $oldfh = select(STDERR); $| = 1; select($oldfh);
3186
3187 Some programmers may prefer to think of filehandles as objects with
3188 methods, preferring to write the last example as:
3189
3190     use IO::Handle;
3191     STDERR->autoflush(1);
3192
3193 =item select RBITS,WBITS,EBITS,TIMEOUT
3194
3195 This calls the select(2) system call with the bit masks specified, which
3196 can be constructed using C<fileno()> and C<vec()>, along these lines:
3197
3198     $rin = $win = $ein = '';
3199     vec($rin,fileno(STDIN),1) = 1;
3200     vec($win,fileno(STDOUT),1) = 1;
3201     $ein = $rin | $win;
3202
3203 If you want to select on many filehandles you might wish to write a
3204 subroutine:
3205
3206     sub fhbits {
3207         my(@fhlist) = split(' ',$_[0]);
3208         my($bits);
3209         for (@fhlist) {
3210             vec($bits,fileno($_),1) = 1;
3211         }
3212         $bits;
3213     }
3214     $rin = fhbits('STDIN TTY SOCK');
3215
3216 The usual idiom is:
3217
3218     ($nfound,$timeleft) =
3219       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3220
3221 or to block until something becomes ready just do this
3222
3223     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3224
3225 Most systems do not bother to return anything useful in C<$timeleft>, so
3226 calling select() in scalar context just returns C<$nfound>.
3227
3228 Any of the bit masks can also be undef.  The timeout, if specified, is
3229 in seconds, which may be fractional.  Note: not all implementations are
3230 capable of returning theC<$timeleft>.  If not, they always return
3231 C<$timeleft> equal to the supplied C<$timeout>.
3232
3233 You can effect a sleep of 250 milliseconds this way:
3234
3235     select(undef, undef, undef, 0.25);
3236
3237 B<WARNING>: One should not attempt to mix buffered I/O (like C<read()>
3238 or E<lt>FHE<gt>) with C<select()>, except as permitted by POSIX, and even
3239 then only on POSIX systems.  You have to use C<sysread()> instead.
3240
3241 =item semctl ID,SEMNUM,CMD,ARG
3242
3243 Calls the System V IPC function C<semctl()>.  You'll probably have to say
3244
3245     use IPC::SysV;
3246
3247 first to get the correct constant definitions.  If CMD is IPC_STAT or
3248 GETALL, then ARG must be a variable which will hold the returned
3249 semid_ds structure or semaphore value array.  Returns like C<ioctl()>: the
3250 undefined value for error, "C<0> but true" for zero, or the actual return
3251 value otherwise.  See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3252
3253 =item semget KEY,NSEMS,FLAGS
3254
3255 Calls the System V IPC function semget.  Returns the semaphore id, or
3256 the undefined value if there is an error.  See also C<IPC::SysV> and
3257 C<IPC::SysV::Semaphore> documentation.
3258
3259 =item semop KEY,OPSTRING
3260
3261 Calls the System V IPC function semop to perform semaphore operations
3262 such as signaling and waiting.  OPSTRING must be a packed array of
3263 semop structures.  Each semop structure can be generated with
3264 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3265 operations is implied by the length of OPSTRING.  Returns TRUE if
3266 successful, or FALSE if there is an error.  As an example, the
3267 following code waits on semaphore C<$semnum> of semaphore id C<$semid>:
3268
3269     $semop = pack("sss", $semnum, -1, 0);
3270     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3271
3272 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3273 and C<IPC::SysV::Semaphore> documentation.
3274
3275 =item send SOCKET,MSG,FLAGS,TO
3276
3277 =item send SOCKET,MSG,FLAGS
3278
3279 Sends a message on a socket.  Takes the same flags as the system call
3280 of the same name.  On unconnected sockets you must specify a
3281 destination to send TO, in which case it does a C C<sendto()>.  Returns
3282 the number of characters sent, or the undefined value if there is an
3283 error.
3284 See L<perlipc/"UDP: Message Passing"> for examples.
3285
3286 =item setpgrp PID,PGRP
3287
3288 Sets the current process group for the specified PID, C<0> for the current
3289 process.  Will produce a fatal error if used on a machine that doesn't
3290 implement setpgrp(2).  If the arguments are omitted, it defaults to
3291 C<0,0>.  Note that the POSIX version of C<setpgrp()> does not accept any
3292 arguments, so only setpgrp C<0,0> is portable.
3293
3294 =item setpriority WHICH,WHO,PRIORITY
3295
3296 Sets the current priority for a process, a process group, or a user.
3297 (See setpriority(2).)  Will produce a fatal error if used on a machine
3298 that doesn't implement setpriority(2).
3299
3300 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3301
3302 Sets the socket option requested.  Returns undefined if there is an
3303 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3304 argument.
3305
3306 =item shift ARRAY
3307
3308 =item shift
3309
3310 Shifts the first value of the array off and returns it, shortening the
3311 array by 1 and moving everything down.  If there are no elements in the
3312 array, returns the undefined value.  If ARRAY is omitted, shifts the
3313 C<@_> array within the lexical scope of subroutines and formats, and the
3314 C<@ARGV> array at file scopes or within the lexical scopes established by
3315 the C<eval ''>, C<BEGIN {}>, C<END {}>, and C<INIT {}> constructs.
3316 See also C<unshift()>, C<push()>, and C<pop()>.  C<Shift()> and C<unshift()> do the
3317 same thing to the left end of an array that C<pop()> and C<push()> do to the
3318 right end.
3319
3320 =item shmctl ID,CMD,ARG
3321
3322 Calls the System V IPC function shmctl.  You'll probably have to say
3323
3324     use IPC::SysV;
3325
3326 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3327 then ARG must be a variable which will hold the returned C<shmid_ds>
3328 structure.  Returns like ioctl: the undefined value for error, "C<0> but
3329 true" for zero, or the actual return value otherwise.
3330 See also C<IPC::SysV> documentation.
3331
3332 =item shmget KEY,SIZE,FLAGS
3333
3334 Calls the System V IPC function shmget.  Returns the shared memory
3335 segment id, or the undefined value if there is an error.
3336 See also C<IPC::SysV> documentation.
3337
3338 =item shmread ID,VAR,POS,SIZE
3339
3340 =item shmwrite ID,STRING,POS,SIZE
3341
3342 Reads or writes the System V shared memory segment ID starting at
3343 position POS for size SIZE by attaching to it, copying in/out, and
3344 detaching from it.  When reading, VAR must be a variable that will
3345 hold the data read.  When writing, if STRING is too long, only SIZE
3346 bytes are used; if STRING is too short, nulls are written to fill out
3347 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
3348 See also C<IPC::SysV> documentation.
3349
3350 =item shutdown SOCKET,HOW
3351
3352 Shuts down a socket connection in the manner indicated by HOW, which
3353 has the same interpretation as in the system call of the same name.
3354
3355     shutdown(SOCKET, 0);    # I/we have stopped reading data
3356     shutdown(SOCKET, 1);    # I/we have stopped writing data
3357     shutdown(SOCKET, 2);    # I/we have stopped using this socket
3358
3359 This is useful with sockets when you want to tell the other
3360 side you're done writing but not done reading, or vice versa.
3361 It's also a more insistent form of close because it also 
3362 disables the filedescriptor in any forked copies in other
3363 processes.
3364
3365 =item sin EXPR
3366
3367 =item sin
3368
3369 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
3370 returns sine of C<$_>.
3371
3372 For the inverse sine operation, you may use the C<POSIX::asin()>
3373 function, or use this relation:
3374
3375     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
3376
3377 =item sleep EXPR
3378
3379 =item sleep
3380
3381 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
3382 May be interrupted if the process receives a signal such as C<SIGALRM>.
3383 Returns the number of seconds actually slept.  You probably cannot
3384 mix C<alarm()> and C<sleep()> calls, because C<sleep()> is often implemented
3385 using C<alarm()>.
3386
3387 On some older systems, it may sleep up to a full second less than what
3388 you requested, depending on how it counts seconds.  Most modern systems
3389 always sleep the full amount.  They may appear to sleep longer than that,
3390 however, because your process might not be scheduled right away in a
3391 busy multitasking system.
3392
3393 For delays of finer granularity than one second, you may use Perl's
3394 C<syscall()> interface to access setitimer(2) if your system supports it,
3395 or else see L</select()> above.
3396
3397 See also the POSIX module's C<sigpause()> function.
3398
3399 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
3400
3401 Opens a socket of the specified kind and attaches it to filehandle
3402 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
3403 system call of the same name.  You should "C<use Socket;>" first to get
3404 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
3405
3406 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
3407
3408 Creates an unnamed pair of sockets in the specified domain, of the
3409 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
3410 for the system call of the same name.  If unimplemented, yields a fatal
3411 error.  Returns TRUE if successful.
3412
3413 Some systems defined C<pipe()> in terms of C<socketpair()>, in which a call
3414 to C<pipe(Rdr, Wtr)> is essentially:
3415
3416     use Socket;
3417     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
3418     shutdown(Rdr, 1);        # no more writing for reader
3419     shutdown(Wtr, 0);        # no more reading for writer
3420
3421 See L<perlipc> for an example of socketpair use.
3422
3423 =item sort SUBNAME LIST
3424
3425 =item sort BLOCK LIST
3426
3427 =item sort LIST
3428
3429 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
3430 is omitted, C<sort()>s in standard string comparison order.  If SUBNAME is
3431 specified, it gives the name of a subroutine that returns an integer
3432 less than, equal to, or greater than C<0>, depending on how the elements
3433 of the array are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
3434 operators are extremely useful in such routines.)  SUBNAME may be a
3435 scalar variable name (unsubscripted), in which case the value provides
3436 the name of (or a reference to) the actual subroutine to use.  In place
3437 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
3438 subroutine.
3439
3440 In the interests of efficiency the normal calling code for subroutines is
3441 bypassed, with the following effects: the subroutine may not be a
3442 recursive subroutine, and the two elements to be compared are passed into
3443 the subroutine not via C<@_> but as the package global variables C<$a> and
3444 C<$b> (see example below).  They are passed by reference, so don't
3445 modify C<$a> and C<$b>.  And don't try to declare them as lexicals either.
3446
3447 You also cannot exit out of the sort block or subroutine using any of the
3448 loop control operators described in L<perlsyn> or with C<goto()>.
3449
3450 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
3451 current collation locale.  See L<perllocale>.
3452
3453 Examples:
3454
3455     # sort lexically
3456     @articles = sort @files;
3457
3458     # same thing, but with explicit sort routine
3459     @articles = sort {$a cmp $b} @files;
3460
3461     # now case-insensitively
3462     @articles = sort {uc($a) cmp uc($b)} @files;
3463
3464     # same thing in reversed order
3465     @articles = sort {$b cmp $a} @files;
3466
3467     # sort numerically ascending
3468     @articles = sort {$a <=> $b} @files;
3469
3470     # sort numerically descending
3471     @articles = sort {$b <=> $a} @files;
3472
3473     # sort using explicit subroutine name
3474     sub byage {
3475         $age{$a} <=> $age{$b};  # presuming numeric
3476     }
3477     @sortedclass = sort byage @class;
3478
3479     # this sorts the %age hash by value instead of key
3480     # using an in-line function
3481     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
3482
3483     sub backwards { $b cmp $a; }
3484     @harry = ('dog','cat','x','Cain','Abel');
3485     @george = ('gone','chased','yz','Punished','Axed');
3486     print sort @harry;
3487             # prints AbelCaincatdogx
3488     print sort backwards @harry;
3489             # prints xdogcatCainAbel
3490     print sort @george, 'to', @harry;
3491             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
3492
3493     # inefficiently sort by descending numeric compare using
3494     # the first integer after the first = sign, or the
3495     # whole record case-insensitively otherwise
3496
3497     @new = sort {
3498         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
3499                             ||
3500                     uc($a)  cmp  uc($b)
3501     } @old;
3502
3503     # same thing, but much more efficiently;
3504     # we'll build auxiliary indices instead
3505     # for speed
3506     @nums = @caps = ();
3507     for (@old) {
3508         push @nums, /=(\d+)/;
3509         push @caps, uc($_);
3510     }
3511
3512     @new = @old[ sort {
3513                         $nums[$b] <=> $nums[$a]
3514                                  ||
3515                         $caps[$a] cmp $caps[$b]
3516                        } 0..$#old
3517                ];
3518
3519     # same thing using a Schwartzian Transform (no temps)
3520     @new = map { $_->[0] }
3521         sort { $b->[1] <=> $a->[1]
3522                         ||
3523                $a->[2] cmp $b->[2]
3524         } map { [$_, /=(\d+)/, uc($_)] } @old;
3525
3526 If you're using strict, you I<MUST NOT> declare C<$a>
3527 and C<$b> as lexicals.  They are package globals.  That means
3528 if you're in the C<main> package, it's
3529
3530     @articles = sort {$main::b <=> $main::a} @files;
3531
3532 or just
3533
3534     @articles = sort {$::b <=> $::a} @files;
3535
3536 but if you're in the C<FooPack> package, it's
3537
3538     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
3539
3540 The comparison function is required to behave.  If it returns
3541 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
3542 sometimes saying the opposite, for example) the results are not
3543 well-defined.
3544
3545 =item splice ARRAY,OFFSET,LENGTH,LIST
3546
3547 =item splice ARRAY,OFFSET,LENGTH
3548
3549 =item splice ARRAY,OFFSET
3550
3551 Removes the elements designated by OFFSET and LENGTH from an array, and
3552 replaces them with the elements of LIST, if any.  In list context,
3553 returns the elements removed from the array.  In scalar context,
3554 returns the last element removed, or C<undef> if no elements are
3555 removed.  The array grows or shrinks as necessary.
3556 If OFFSET is negative then it start that far from the end of the array.
3557 If LENGTH is omitted, removes everything from OFFSET onward.
3558 If LENGTH is negative, leave that many elements off the end of the array.
3559 The following equivalences hold (assuming C<$[ == 0>):
3560
3561     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
3562     pop(@a)             splice(@a,-1)
3563     shift(@a)           splice(@a,0,1)
3564     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
3565     $a[$x] = $y         splice(@a,$x,1,$y)
3566
3567 Example, assuming array lengths are passed before arrays:
3568
3569     sub aeq {   # compare two list values
3570         my(@a) = splice(@_,0,shift);
3571         my(@b) = splice(@_,0,shift);
3572         return 0 unless @a == @b;       # same len?
3573         while (@a) {
3574             return 0 if pop(@a) ne pop(@b);
3575         }
3576         return 1;
3577     }
3578     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
3579
3580 =item split /PATTERN/,EXPR,LIMIT
3581
3582 =item split /PATTERN/,EXPR
3583
3584 =item split /PATTERN/
3585
3586 =item split
3587
3588 Splits a string into an array of strings, and returns it.  By default,
3589 empty leading fields are preserved, and empty trailing ones are deleted.
3590
3591 If not in list context, returns the number of fields found and splits into
3592 the C<@_> array.  (In list context, you can force the split into C<@_> by
3593 using C<??> as the pattern delimiters, but it still returns the list
3594 value.)  The use of implicit split to C<@_> is deprecated, however, because
3595 it clobbers your subroutine arguments.
3596
3597 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
3598 splits on whitespace (after skipping any leading whitespace).  Anything
3599 matching PATTERN is taken to be a delimiter separating the fields.  (Note
3600 that the delimiter may be longer than one character.)
3601
3602 If LIMIT is specified and positive, splits into no more than that
3603 many fields (though it may split into fewer).  If LIMIT is unspecified
3604 or zero, trailing null fields are stripped (which potential users
3605 of C<pop()> would do well to remember).  If LIMIT is negative, it is
3606 treated as if an arbitrarily large LIMIT had been specified.
3607
3608 A pattern matching the null string (not to be confused with
3609 a null pattern C<//>, which is just one member of the set of patterns
3610 matching a null string) will split the value of EXPR into separate
3611 characters at each point it matches that way.  For example:
3612
3613     print join(':', split(/ */, 'hi there'));
3614
3615 produces the output 'h:i:t:h:e:r:e'.
3616
3617 The LIMIT parameter can be used to split a line partially
3618
3619     ($login, $passwd, $remainder) = split(/:/, $_, 3);
3620
3621 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
3622 one larger than the number of variables in the list, to avoid
3623 unnecessary work.  For the list above LIMIT would have been 4 by
3624 default.  In time critical applications it behooves you not to split
3625 into more fields than you really need.
3626
3627 If the PATTERN contains parentheses, additional array elements are
3628 created from each matching substring in the delimiter.
3629
3630     split(/([,-])/, "1-10,20", 3);
3631
3632 produces the list value
3633
3634     (1, '-', 10, ',', 20)
3635
3636 If you had the entire header of a normal Unix email message in C<$header>,
3637 you could split it up into fields and their values this way:
3638
3639     $header =~ s/\n\s+/ /g;  # fix continuation lines
3640     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
3641
3642 The pattern C</PATTERN/> may be replaced with an expression to specify
3643 patterns that vary at runtime.  (To do runtime compilation only once,
3644 use C</$variable/o>.)
3645
3646 As a special case, specifying a PATTERN of space (C<' '>) will split on
3647 white space just as C<split()> with no arguments does.  Thus, C<split(' ')> can
3648 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
3649 will give you as many null initial fields as there are leading spaces.
3650 A C<split()> on C</\s+/> is like a C<split(' ')> except that any leading
3651 whitespace produces a null first field.  A C<split()> with no arguments
3652 really does a C<split(' ', $_)> internally.
3653
3654 Example:
3655
3656     open(PASSWD, '/etc/passwd');
3657     while (<PASSWD>) {
3658         ($login, $passwd, $uid, $gid,
3659          $gcos, $home, $shell) = split(/:/);
3660         #...
3661     }
3662
3663 (Note that C<$shell> above will still have a newline on it.  See L</chop>,
3664 L</chomp>, and L</join>.)
3665
3666 =item sprintf FORMAT, LIST
3667
3668 Returns a string formatted by the usual C<printf()> conventions of the
3669 C library function C<sprintf()>.  See L<sprintf(3)> or L<printf(3)>
3670 on your system for an explanation of the general principles.
3671
3672 Perl does its own C<sprintf()> formatting -- it emulates the C
3673 function C<sprintf()>, but it doesn't use it (except for floating-point
3674 numbers, and even then only the standard modifiers are allowed).  As a
3675 result, any non-standard extensions in your local C<sprintf()> are not
3676 available from Perl.
3677
3678 Perl's C<sprintf()> permits the following universally-known conversions:
3679
3680    %%   a percent sign
3681    %c   a character with the given number
3682    %s   a string
3683    %d   a signed integer, in decimal
3684    %u   an unsigned integer, in decimal
3685    %o   an unsigned integer, in octal
3686    %x   an unsigned integer, in hexadecimal
3687    %e   a floating-point number, in scientific notation
3688    %f   a floating-point number, in fixed decimal notation
3689    %g   a floating-point number, in %e or %f notation
3690
3691 In addition, Perl permits the following widely-supported conversions:
3692
3693    %X   like %x, but using upper-case letters
3694    %E   like %e, but using an upper-case "E"
3695    %G   like %g, but with an upper-case "E" (if applicable)
3696    %p   a pointer (outputs the Perl value's address in hexadecimal)
3697    %n   special: *stores* the number of characters output so far
3698         into the next variable in the parameter list 
3699
3700 Finally, for backward (and we do mean "backward") compatibility, Perl
3701 permits these unnecessary but widely-supported conversions:
3702
3703    %i   a synonym for %d
3704    %D   a synonym for %ld
3705    %U   a synonym for %lu
3706    %O   a synonym for %lo
3707    %F   a synonym for %f
3708
3709 Perl permits the following universally-known flags between the C<%>
3710 and the conversion letter:
3711
3712    space   prefix positive number with a space
3713    +       prefix positive number with a plus sign
3714    -       left-justify within the field
3715    0       use zeros, not spaces, to right-justify
3716    #       prefix non-zero octal with "0", non-zero hex with "0x"
3717    number  minimum field width
3718    .number "precision": digits after decimal point for
3719            floating-point, max length for string, minimum length
3720            for integer
3721    l       interpret integer as C type "long" or "unsigned long"
3722    h       interpret integer as C type "short" or "unsigned short"
3723
3724 There is also one Perl-specific flag:
3725
3726    V       interpret integer as Perl's standard integer type
3727
3728 Where a number would appear in the flags, an asterisk ("C<*>") may be
3729 used instead, in which case Perl uses the next item in the parameter
3730 list as the given number (that is, as the field width or precision).
3731 If a field width obtained through "C<*>" is negative, it has the same
3732 effect as the "C<->" flag: left-justification.
3733
3734 If C<use locale> is in effect, the character used for the decimal
3735 point in formatted real numbers is affected by the LC_NUMERIC locale.
3736 See L<perllocale>.
3737
3738 =item sqrt EXPR
3739
3740 =item sqrt
3741
3742 Return the square root of EXPR.  If EXPR is omitted, returns square
3743 root of C<$_>.
3744
3745 =item srand EXPR
3746
3747 =item srand
3748
3749 Sets the random number seed for the C<rand()> operator.  If EXPR is
3750 omitted, uses a semi-random value supplied by the kernel (if it supports
3751 the F</dev/urandom> device) or based on the current time and process
3752 ID, among other things.  In versions of Perl prior to 5.004 the default
3753 seed was just the current C<time()>.  This isn't a particularly good seed,
3754 so many old programs supply their own seed value (often C<time ^ $$> or
3755 C<time ^ ($$ + ($$ E<lt>E<lt> 15))>), but that isn't necessary any more.
3756
3757 In fact, it's usually not necessary to call C<srand()> at all, because if
3758 it is not called explicitly, it is called implicitly at the first use of
3759 the C<rand()> operator.  However, this was not the case in version of Perl
3760 before 5.004, so if your script will run under older Perl versions, it
3761 should call C<srand()>.
3762
3763 Note that you need something much more random than the default seed for
3764 cryptographic purposes.  Checksumming the compressed output of one or more
3765 rapidly changing operating system status programs is the usual method.  For
3766 example:
3767
3768     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
3769
3770 If you're particularly concerned with this, see the C<Math::TrulyRandom>
3771 module in CPAN.
3772
3773 Do I<not> call C<srand()> multiple times in your program unless you know
3774 exactly what you're doing and why you're doing it.  The point of the
3775 function is to "seed" the C<rand()> function so that C<rand()> can produce
3776 a different sequence each time you run your program.  Just do it once at the
3777 top of your program, or you I<won't> get random numbers out of C<rand()>!
3778
3779 Frequently called programs (like CGI scripts) that simply use
3780
3781     time ^ $$
3782
3783 for a seed can fall prey to the mathematical property that
3784
3785     a^b == (a+1)^(b+1)
3786
3787 one-third of the time.  So don't do that.
3788
3789 =item stat FILEHANDLE
3790
3791 =item stat EXPR
3792
3793 =item stat
3794
3795 Returns a 13-element list giving the status info for a file, either
3796 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
3797 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
3798 as follows:
3799
3800     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
3801        $atime,$mtime,$ctime,$blksize,$blocks)
3802            = stat($filename);
3803
3804 Not all fields are supported on all filesystem types.  Here are the
3805 meaning of the fields:
3806
3807   0 dev      device number of filesystem
3808   1 ino      inode number
3809   2 mode     file mode  (type and permissions)
3810   3 nlink    number of (hard) links to the file
3811   4 uid      numeric user ID of file's owner
3812   5 gid      numeric group ID of file's owner
3813   6 rdev     the device identifier (special files only)
3814   7 size     total size of file, in bytes
3815   8 atime    last access time since the epoch
3816   9 mtime    last modify time since the epoch
3817  10 ctime    inode change time (NOT creation time!) since the epoch
3818  11 blksize  preferred block size for file system I/O
3819  12 blocks   actual number of blocks allocated
3820
3821 (The epoch was at 00:00 January 1, 1970 GMT.)
3822
3823 If stat is passed the special filehandle consisting of an underline, no
3824 stat is done, but the current contents of the stat structure from the
3825 last stat or filetest are returned.  Example:
3826
3827     if (-x $file && (($d) = stat(_)) && $d < 0) {
3828         print "$file is executable NFS file\n";
3829     }
3830
3831 (This works on machines only for which the device number is negative under NFS.)
3832
3833 In scalar context, C<stat()> returns a boolean value indicating success
3834 or failure, and, if successful, sets the information associated with
3835 the special filehandle C<_>.
3836
3837 =item study SCALAR
3838
3839 =item study
3840
3841 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
3842 doing many pattern matches on the string before it is next modified.
3843 This may or may not save time, depending on the nature and number of
3844 patterns you are searching on, and on the distribution of character
3845 frequencies in the string to be searched -- you probably want to compare
3846 run times with and without it to see which runs faster.  Those loops
3847 which scan for many short constant strings (including the constant
3848 parts of more complex patterns) will benefit most.  You may have only
3849 one C<study()> active at a time -- if you study a different scalar the first
3850 is "unstudied".  (The way C<study()> works is this: a linked list of every
3851 character in the string to be searched is made, so we know, for
3852 example, where all the C<'k'> characters are.  From each search string,
3853 the rarest character is selected, based on some static frequency tables
3854 constructed from some C programs and English text.  Only those places
3855 that contain this "rarest" character are examined.)
3856
3857 For example, here is a loop that inserts index producing entries
3858 before any line containing a certain pattern:
3859
3860     while (<>) {
3861         study;
3862         print ".IX foo\n" if /\bfoo\b/;
3863         print ".IX bar\n" if /\bbar\b/;
3864         print ".IX blurfl\n" if /\bblurfl\b/;
3865         # ...
3866         print;
3867     }
3868
3869 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<"f">
3870 will be looked at, because C<"f"> is rarer than C<"o">.  In general, this is
3871 a big win except in pathological cases.  The only question is whether
3872 it saves you more time than it took to build the linked list in the
3873 first place.
3874
3875 Note that if you have to look for strings that you don't know till
3876 runtime, you can build an entire loop as a string and C<eval()> that to
3877 avoid recompiling all your patterns all the time.  Together with
3878 undefining C<$/> to input entire files as one record, this can be very
3879 fast, often faster than specialized programs like fgrep(1).  The following
3880 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3881 out the names of those files that contain a match:
3882
3883     $search = 'while (<>) { study;';
3884     foreach $word (@words) {
3885         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3886     }
3887     $search .= "}";
3888     @ARGV = @files;
3889     undef $/;
3890     eval $search;               # this screams
3891     $/ = "\n";          # put back to normal input delimiter
3892     foreach $file (sort keys(%seen)) {
3893         print $file, "\n";
3894     }
3895
3896 =item sub BLOCK
3897
3898 =item sub NAME
3899
3900 =item sub NAME BLOCK
3901
3902 This is subroutine definition, not a real function I<per se>.  With just a
3903 NAME (and possibly prototypes), it's just a forward declaration.  Without
3904 a NAME, it's an anonymous function declaration, and does actually return a
3905 value: the CODE ref of the closure you just created.  See L<perlsub> and
3906 L<perlref> for details.
3907
3908 =item substr EXPR,OFFSET,LEN,REPLACEMENT
3909
3910 =item substr EXPR,OFFSET,LEN
3911
3912 =item substr EXPR,OFFSET
3913
3914 Extracts a substring out of EXPR and returns it.  First character is at
3915 offset C<0>, or whatever you've set C<$[> to (but don't do that).
3916 If OFFSET is negative (or more precisely, less than C<$[>), starts
3917 that far from the end of the string.  If LEN is omitted, returns
3918 everything to the end of the string.  If LEN is negative, leaves that
3919 many characters off the end of the string.
3920
3921 If you specify a substring that is partly outside the string, the part
3922 within the string is returned.    If the substring is totally outside
3923 the string a warning is produced.
3924
3925 You can use the C<substr()> function
3926 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3927 something shorter than LEN, the string will shrink, and if you assign
3928 something longer than LEN, the string will grow to accommodate it.  To
3929 keep the string the same length you may need to pad or chop your value
3930 using C<sprintf()>.
3931
3932 An alternative to using C<substr()> as an lvalue is to specify the
3933 replacement string as the 4th argument.  This allows you to replace
3934 parts of the EXPR and return what was there before in one operation.
3935
3936 =item symlink OLDFILE,NEWFILE
3937
3938 Creates a new filename symbolically linked to the old filename.
3939 Returns C<1> for success, C<0> otherwise.  On systems that don't support
3940 symbolic links, produces a fatal error at run time.  To check for that,
3941 use eval:
3942
3943     $symlink_exists =  eval { symlink("",""); 1 };
3944
3945 =item syscall LIST
3946
3947 Calls the system call specified as the first element of the list,
3948 passing the remaining elements as arguments to the system call.  If
3949 unimplemented, produces a fatal error.  The arguments are interpreted
3950 as follows: if a given argument is numeric, the argument is passed as
3951 an int.  If not, the pointer to the string value is passed.  You are
3952 responsible to make sure a string is pre-extended long enough to
3953 receive any result that might be written into a string.  You can't use a
3954 string literal (or other read-only string) as an argument to C<syscall()>
3955 because Perl has to assume that any string pointer might be written
3956 through.  If your
3957 integer arguments are not literals and have never been interpreted in a
3958 numeric context, you may need to add C<0> to them to force them to look
3959 like numbers.  This emulates the C<syswrite()> function (or vice versa):
3960
3961     require 'syscall.ph';               # may need to run h2ph
3962     $s = "hi there\n";
3963     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
3964
3965 Note that Perl supports passing of up to only 14 arguments to your system call,
3966 which in practice should usually suffice.
3967
3968 Syscall returns whatever value returned by the system call it calls.
3969 If the system call fails, C<syscall()> returns C<-1> and sets C<$!> (errno).
3970 Note that some system calls can legitimately return C<-1>.  The proper
3971 way to handle such calls is to assign C<$!=0;> before the call and
3972 check the value of C<$!> if syscall returns C<-1>.
3973
3974 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
3975 number of the read end of the pipe it creates.  There is no way
3976 to retrieve the file number of the other end.  You can avoid this 
3977 problem by using C<pipe()> instead.
3978
3979 =item sysopen FILEHANDLE,FILENAME,MODE
3980
3981 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
3982
3983 Opens the file whose filename is given by FILENAME, and associates it
3984 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
3985 the name of the real filehandle wanted.  This function calls the
3986 underlying operating system's C<open()> function with the parameters
3987 FILENAME, MODE, PERMS.
3988
3989 The possible values and flag bits of the MODE parameter are
3990 system-dependent; they are available via the standard module C<Fcntl>.
3991 For historical reasons, some values work on almost every system
3992 supported by perl: zero means read-only, one means write-only, and two
3993 means read/write.  We know that these values do I<not> work under
3994 OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to
3995 use them in new code.
3996
3997 If the file named by FILENAME does not exist and the C<open()> call creates
3998 it (typically because MODE includes the C<O_CREAT> flag), then the value of
3999 PERMS specifies the permissions of the newly created file.  If you omit
4000 the PERMS argument to C<sysopen()>, Perl uses the octal value C<0666>.
4001 These permission values need to be in octal, and are modified by your
4002 process's current C<umask>.
4003
4004 Seldom if ever use C<0644> as argument to C<sysopen()> because that
4005 takes away the user's option to have a more permissive umask.  Better
4006 to omit it.  See the perlfunc(1) entry on C<umask> for more on this.
4007
4008 The C<IO::File> module provides a more object-oriented approach, if you're
4009 into that kind of thing.
4010
4011 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
4012
4013 =item sysread FILEHANDLE,SCALAR,LENGTH
4014
4015 Attempts to read LENGTH bytes of data into variable SCALAR from the
4016 specified FILEHANDLE, using the system call read(2).  It bypasses stdio,
4017 so mixing this with other kinds of reads, C<print()>, C<write()>,
4018 C<seek()>, C<tell()>, or C<eof()> can cause confusion because stdio
4019 usually buffers data.  Returns the number of bytes actually read, C<0>
4020 at end of file, or undef if there was an error.  SCALAR will be grown or
4021 shrunk so that the last byte actually read is the last byte of the
4022 scalar after the read.
4023
4024 An OFFSET may be specified to place the read data at some place in the
4025 string other than the beginning.  A negative OFFSET specifies
4026 placement at that many bytes counting backwards from the end of the
4027 string.  A positive OFFSET greater than the length of SCALAR results
4028 in the string being padded to the required size with C<"\0"> bytes before
4029 the result of the read is appended.
4030
4031 =item sysseek FILEHANDLE,POSITION,WHENCE
4032
4033 Sets FILEHANDLE's system position using the system call lseek(2).  It
4034 bypasses stdio, so mixing this with reads (other than C<sysread()>),
4035 C<print()>, C<write()>, C<seek()>, C<tell()>, or C<eof()> may cause
4036 confusion.  FILEHANDLE may be an expression whose value gives the name
4037 of the filehandle.  The values for WHENCE are C<0> to set the new
4038 position to POSITION, C<1> to set the it to the current position plus
4039 POSITION, and C<2> to set it to EOF plus POSITION (typically negative).
4040 For WHENCE, you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and
4041 C<SEEK_END> from either the C<IO::Seekable> or the POSIX module.
4042
4043 Returns the new position, or the undefined value on failure.  A position
4044 of zero is returned as the string "C<0> but true"; thus C<sysseek()> returns
4045 TRUE on success and FALSE on failure, yet you can still easily determine
4046 the new position.
4047
4048 =item system LIST
4049
4050 =item system PROGRAM LIST
4051
4052 Does exactly the same thing as "C<exec LIST>" except that a fork is done
4053 first, and the parent process waits for the child process to complete.
4054 Note that argument processing varies depending on the number of
4055 arguments.  If there is more than one argument in LIST, or if LIST is
4056 an array with more than one value, starts the program given by the
4057 first element of the list with arguments given by the rest of the list.
4058 If there is only one scalar argument, the argument is
4059 checked for shell metacharacters, and if there are any, the entire
4060 argument is passed to the system's command shell for parsing (this is
4061 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
4062 there are no shell metacharacters in the argument, it is split into
4063 words and passed directly to C<execvp()>, which is more efficient.
4064
4065 The return value is the exit status of the program as
4066 returned by the C<wait()> call.  To get the actual exit value divide by
4067 256.  See also L</exec>.  This is I<NOT> what you want to use to capture
4068 the output from a command, for that you should use merely backticks or
4069 C<qx//>, as described in L<perlop/"`STRING`">.
4070
4071 Like C<exec()>, C<system()> allows you to lie to a program about its name if
4072 you use the "C<system PROGRAM LIST>" syntax.  Again, see L</exec>.
4073
4074 Because C<system()> and backticks block C<SIGINT> and C<SIGQUIT>, killing the
4075 program they're running doesn't actually interrupt your program.
4076
4077     @args = ("command", "arg1", "arg2");
4078     system(@args) == 0
4079          or die "system @args failed: $?"
4080
4081 You can check all the failure possibilities by inspecting
4082 C<$?> like this:
4083
4084     $exit_value  = $? >> 8;
4085     $signal_num  = $? & 127;
4086     $dumped_core = $? & 128;
4087
4088 When the arguments get executed via the system shell, results
4089 and return codes will be subject to its quirks and capabilities.
4090 See L<perlop/"`STRING`"> and L</exec> for details.
4091
4092 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
4093
4094 =item syswrite FILEHANDLE,SCALAR,LENGTH
4095
4096 =item syswrite FILEHANDLE,SCALAR
4097
4098 Attempts to write LENGTH bytes of data from variable SCALAR to the
4099 specified FILEHANDLE, using the system call write(2).  If LENGTH is
4100 not specified, writes whole SCALAR. It bypasses
4101 stdio, so mixing this with reads (other than C<sysread())>, C<print()>,
4102 C<write()>, C<seek()>, C<tell()>, or C<eof()> may cause confusion
4103 because stdio usually buffers data.  Returns the number of bytes
4104 actually written, or C<undef> if there was an error.  If the LENGTH is
4105 greater than the available data in the SCALAR after the OFFSET, only as
4106 much data as is available will be written.
4107
4108 An OFFSET may be specified to write the data from some part of the
4109 string other than the beginning.  A negative OFFSET specifies writing
4110 that many bytes counting backwards from the end of the string.  In the
4111 case the SCALAR is empty you can use OFFSET but only zero offset.
4112
4113 =item tell FILEHANDLE
4114
4115 =item tell
4116
4117 Returns the current position for FILEHANDLE.  FILEHANDLE may be an
4118 expression whose value gives the name of the actual filehandle.  If
4119 FILEHANDLE is omitted, assumes the file last read.
4120
4121 =item telldir DIRHANDLE
4122
4123 Returns the current position of the C<readdir()> routines on DIRHANDLE.
4124 Value may be given to C<seekdir()> to access a particular location in a
4125 directory.  Has the same caveats about possible directory compaction as
4126 the corresponding system library routine.
4127
4128 =item tie VARIABLE,CLASSNAME,LIST
4129
4130 This function binds a variable to a package class that will provide the
4131 implementation for the variable.  VARIABLE is the name of the variable
4132 to be enchanted.  CLASSNAME is the name of a class implementing objects
4133 of correct type.  Any additional arguments are passed to the "C<new()>"
4134 method of the class (meaning C<TIESCALAR>, C<TIEARRAY>, or C<TIEHASH>).
4135 Typically these are arguments such as might be passed to the C<dbm_open()>
4136 function of C.  The object returned by the "C<new()>" method is also
4137 returned by the C<tie()> function, which would be useful if you want to
4138 access other methods in CLASSNAME.
4139
4140 Note that functions such as C<keys()> and C<values()> may return huge lists
4141 when used on large objects, like DBM files.  You may prefer to use the
4142 C<each()> function to iterate over such.  Example:
4143
4144     # print out history file offsets
4145     use NDBM_File;
4146     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
4147     while (($key,$val) = each %HIST) {
4148         print $key, ' = ', unpack('L',$val), "\n";
4149     }
4150     untie(%HIST);
4151
4152 A class implementing a hash should have the following methods:
4153
4154     TIEHASH classname, LIST
4155     DESTROY this
4156     FETCH this, key
4157     STORE this, key, value
4158     DELETE this, key
4159     EXISTS this, key
4160     FIRSTKEY this
4161     NEXTKEY this, lastkey
4162
4163 A class implementing an ordinary array should have the following methods:
4164
4165     TIEARRAY classname, LIST
4166     DESTROY this
4167     FETCH this, key
4168     STORE this, key, value
4169     [others TBD]
4170
4171 A class implementing a scalar should have the following methods:
4172
4173     TIESCALAR classname, LIST
4174     DESTROY this
4175     FETCH this,
4176     STORE this, value
4177
4178 Unlike C<dbmopen()>, the C<tie()> function will not use or require a module
4179 for you--you need to do that explicitly yourself.  See L<DB_File>
4180 or the F<Config> module for interesting C<tie()> implementations.
4181
4182 For further details see L<perltie>, L<tied VARIABLE>.
4183
4184 =item tied VARIABLE
4185
4186 Returns a reference to the object underlying VARIABLE (the same value
4187 that was originally returned by the C<tie()> call that bound the variable
4188 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
4189 package.
4190
4191 =item time
4192
4193 Returns the number of non-leap seconds since whatever time the system
4194 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
4195 and 00:00:00 UTC, January 1, 1970 for most other systems).
4196 Suitable for feeding to C<gmtime()> and C<localtime()>.
4197
4198 =item times
4199
4200 Returns a four-element list giving the user and system times, in
4201 seconds, for this process and the children of this process.
4202
4203     ($user,$system,$cuser,$csystem) = times;
4204
4205 =item tr///
4206
4207 The transliteration operator.  Same as C<y///>. See L<perlop>.
4208
4209 =item truncate FILEHANDLE,LENGTH
4210
4211 =item truncate EXPR,LENGTH
4212
4213 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
4214 specified length.  Produces a fatal error if truncate isn't implemented
4215 on your system.  Returns TRUE if successful, the undefined value
4216 otherwise.
4217
4218 =item uc EXPR
4219
4220 =item uc
4221
4222 Returns an uppercased version of EXPR.  This is the internal function
4223 implementing the C<\U> escape in double-quoted strings.
4224 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4225 Under Unicode (C<use utf8>) it uses the standard Unicode uppercase mappings.  (It
4226 does not attempt to do titlecase mapping on initial letters.  See C<ucfirst()> for that.)
4227
4228 If EXPR is omitted, uses C<$_>.
4229
4230 =item ucfirst EXPR
4231
4232 =item ucfirst
4233
4234 Returns the value of EXPR with the first character
4235 in uppercase (titlecase in Unicode).  This is
4236 the internal function implementing the C<\u> escape in double-quoted strings.
4237 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4238
4239 If EXPR is omitted, uses C<$_>.
4240
4241 =item umask EXPR
4242
4243 =item umask
4244
4245 Sets the umask for the process to EXPR and returns the previous value.
4246 If EXPR is omitted, merely returns the current umask.
4247
4248 The Unix permission C<rwxr-x---> is represented as three sets of three
4249 bits, or three octal digits: C<0750> (the leading 0 indicates octal
4250 and isn't one of the the digits).  The C<umask> value is such a number
4251 representing disabled permissions bits.  The permission (or "mode")
4252 values you pass C<mkdir> or C<sysopen> are modified by your umask, so
4253 even if you tell C<sysopen> to create a file with permissions C<0777>,
4254 if your umask is C<0022> then the file will actually be created with
4255 permissions C<0755>.  If your C<umask> were C<0027> (group can't
4256 write; others can't read, write, or execute), then passing
4257 C<sysopen()> C<0666> would create a file with mode C<0640> (C<0666 &~
4258 027> is C<0640>).
4259
4260 Here's some advice: supply a creation mode of C<0666> for regular
4261 files (in C<sysopen()>) and one of C<0777> for directories (in
4262 C<mkdir()>) and executable files.  This gives users the freedom of
4263 choice: if they want protected files, they might choose process umasks
4264 of C<022>, C<027>, or even the particularly antisocial mask of C<077>.
4265 Programs should rarely if ever make policy decisions better left to
4266 the user.  The exception to this is when writing files that should be
4267 kept private: mail files, web browser cookies, I<.rhosts> files, and
4268 so on.
4269
4270 If umask(2) is not implemented on your system and you are trying to
4271 restrict access for I<yourself> (i.e., (EXPR & 0700) > 0), produces a
4272 fatal error at run time.  If umask(2) is not implemented and you are
4273 not trying to restrict access for yourself, returns C<undef>.
4274
4275 Remember that a umask is a number, usually given in octal; it is I<not> a
4276 string of octal digits.  See also L</oct>, if all you have is a string.
4277
4278 =item undef EXPR
4279
4280 =item undef
4281
4282 Undefines the value of EXPR, which must be an lvalue.  Use only on a
4283 scalar value, an array (using "C<@>"), a hash (using "C<%>"), a subroutine
4284 (using "C<&>"), or a typeglob (using "<*>").  (Saying C<undef $hash{$key}>
4285 will probably not do what you expect on most predefined variables or
4286 DBM list values, so don't do that; see L<delete>.)  Always returns the
4287 undefined value.  You can omit the EXPR, in which case nothing is
4288 undefined, but you still get an undefined value that you could, for
4289 instance, return from a subroutine, assign to a variable or pass as a
4290 parameter.  Examples:
4291
4292     undef $foo;
4293     undef $bar{'blurfl'};      # Compare to: delete $bar{'blurfl'};
4294     undef @ary;
4295     undef %hash;
4296     undef &mysub;
4297     undef *xyz;       # destroys $xyz, @xyz, %xyz, &xyz, etc.
4298     return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
4299     select undef, undef, undef, 0.25;
4300     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
4301
4302 Note that this is a unary operator, not a list operator.
4303
4304 =item unless (EXPR) BLOCK
4305
4306 The negative counterpart of L</if>.  If the EXPR returns false the
4307 BLOCK is entered.
4308
4309 See also L<perlsyn>.
4310
4311 =item unlink LIST
4312
4313 =item unlink
4314
4315 Deletes a list of files.  Returns the number of files successfully
4316 deleted.
4317
4318     $cnt = unlink 'a', 'b', 'c';
4319     unlink @goners;
4320     unlink <*.bak>;
4321
4322 Note: C<unlink()> will not delete directories unless you are superuser and
4323 the B<-U> flag is supplied to Perl.  Even if these conditions are
4324 met, be warned that unlinking a directory can inflict damage on your
4325 filesystem.  Use C<rmdir()> instead.
4326
4327 If LIST is omitted, uses C<$_>.
4328
4329 =item unpack TEMPLATE,EXPR
4330
4331 C<Unpack()> does the reverse of C<pack()>: it takes a string representing a
4332 structure and expands it out into a list value, returning the array
4333 value.  (In scalar context, it returns merely the first value
4334 produced.)  The TEMPLATE has the same format as in the C<pack()> function.
4335 Here's a subroutine that does substring:
4336
4337     sub substr {
4338         my($what,$where,$howmuch) = @_;
4339         unpack("x$where a$howmuch", $what);
4340     }
4341
4342 and then there's
4343
4344     sub ordinal { unpack("c",$_[0]); } # same as ord()
4345
4346 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
4347 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
4348 themselves.  Default is a 16-bit checksum.  For example, the following
4349 computes the same number as the System V sum program:
4350
4351     while (<>) {
4352         $checksum += unpack("%16C*", $_);
4353     }
4354     $checksum %= 65536;
4355
4356 The following efficiently counts the number of set bits in a bit vector:
4357
4358     $setbits = unpack("%32b*", $selectmask);
4359
4360 =item unshift ARRAY,LIST
4361
4362 Does the opposite of a C<shift()>.  Or the opposite of a C<push()>,
4363 depending on how you look at it.  Prepends list to the front of the
4364 array, and returns the new number of elements in the array.
4365
4366     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
4367
4368 Note the LIST is prepended whole, not one element at a time, so the
4369 prepended elements stay in the same order.  Use C<reverse()> to do the
4370 reverse.
4371
4372 =item until (EXPR) BLOCK
4373
4374 =item do BLOCK until (EXPR)
4375
4376 Enter BLOCK until EXPR returns false.  The first form may avoid entering
4377 the BLOCK, the second form enters the BLOCK at least once.
4378
4379 See L</do>, L</while>, and L</for>.
4380
4381 See also L<perlsyn>.
4382
4383 =item untie VARIABLE
4384
4385 Breaks the binding between a variable and a package.  (See C<tie()>.)
4386
4387 =item use Module LIST
4388
4389 =item use Module
4390
4391 =item use Module VERSION LIST
4392
4393 =item use VERSION
4394
4395 Imports some semantics into the current package from the named module,
4396 generally by aliasing certain subroutine or variable names into your
4397 package.  It is exactly equivalent to
4398
4399     BEGIN { require Module; import Module LIST; }
4400
4401 except that Module I<must> be a bareword.
4402
4403 If the first argument to C<use> is a number, it is treated as a version
4404 number instead of a module name.  If the version of the Perl interpreter
4405 is less than VERSION, then an error message is printed and Perl exits
4406 immediately.  This is often useful if you need to check the current
4407 Perl version before C<use>ing library modules that have changed in
4408 incompatible ways from older versions of Perl.  (We try not to do
4409 this more than we have to.)
4410
4411 The C<BEGIN> forces the C<require> and C<import()> to happen at compile time.  The
4412 C<require> makes sure the module is loaded into memory if it hasn't been
4413 yet.  The C<import()> is not a builtin--it's just an ordinary static method
4414 call into the "C<Module>" package to tell the module to import the list of
4415 features back into the current package.  The module can implement its
4416 C<import()> method any way it likes, though most modules just choose to
4417 derive their C<import()> method via inheritance from the C<Exporter> class that
4418 is defined in the C<Exporter> module.  See L<Exporter>.  If no C<import()>
4419 method can be found then the error is currently silently ignored.  This
4420 may change to a fatal error in a future version.
4421
4422 If you don't want your namespace altered, explicitly supply an empty list:
4423
4424     use Module ();
4425
4426 That is exactly equivalent to
4427
4428     BEGIN { require Module }
4429
4430 If the VERSION argument is present between Module and LIST, then the
4431 C<use> will call the VERSION method in class Module with the given
4432 version as an argument.  The default VERSION method, inherited from
4433 the Universal class, croaks if the given version is larger than the
4434 value of the variable C<$Module::VERSION>.  (Note that there is not a
4435 comma after VERSION!)
4436
4437 Because this is a wide-open interface, pragmas (compiler directives)
4438 are also implemented this way.  Currently implemented pragmas are:
4439
4440     use integer;
4441     use diagnostics;
4442     use sigtrap qw(SEGV BUS);
4443     use strict  qw(subs vars refs);
4444     use subs    qw(afunc blurfl);
4445
4446 Some of these these pseudo-modules import semantics into the current
4447 block scope (like C<strict> or C<integer>, unlike ordinary modules,
4448 which import symbols into the current package (which are effective
4449 through the end of the file).
4450
4451 There's a corresponding "C<no>" command that unimports meanings imported
4452 by C<use>, i.e., it calls C<unimport Module LIST> instead of C<import()>.
4453
4454     no integer;
4455     no strict 'refs';
4456
4457 If no C<unimport()> method can be found the call fails with a fatal error.
4458
4459 See L<perlmod> for a list of standard modules and pragmas.
4460
4461 =item utime LIST
4462
4463 Changes the access and modification times on each file of a list of
4464 files.  The first two elements of the list must be the NUMERICAL access
4465 and modification times, in that order.  Returns the number of files
4466 successfully changed.  The inode modification time of each file is set
4467 to the current time.  This code has the same effect as the "C<touch>"
4468 command if the files already exist:
4469
4470     #!/usr/bin/perl
4471     $now = time;
4472     utime $now, $now, @ARGV;
4473
4474 =item values HASH
4475
4476 Returns a list consisting of all the values of the named hash.  (In a
4477 scalar context, returns the number of values.)  The values are
4478 returned in an apparently random order, but it is the same order as
4479 either the C<keys()> or C<each()> function would produce on the same hash.
4480 As a side effect, it resets HASH's iterator.  See also C<keys()>, C<each()>,
4481 and C<sort()>.
4482
4483 =item vec EXPR,OFFSET,BITS
4484
4485 Treats the string in EXPR as a vector of unsigned integers, and
4486 returns the value of the bit field specified by OFFSET.  BITS specifies
4487 the number of bits that are reserved for each entry in the bit
4488 vector.  This must be a power of two from 1 to 32. C<vec()> may also be
4489 assigned to, in which case parentheses are needed to give the expression
4490 the correct precedence as in
4491
4492     vec($image, $max_x * $x + $y, 8) = 3;
4493
4494 Vectors created with C<vec()> can also be manipulated with the logical
4495 operators C<|>, C<&>, and C<^>, which will assume a bit vector operation is
4496 desired when both operands are strings.
4497
4498 The following code will build up an ASCII string saying C<'PerlPerlPerl'>.
4499 The comments show the string after each step. Note that this code works
4500 in the same way on big-endian or little-endian machines.
4501
4502     my $foo = '';
4503     vec($foo,  0, 32) = 0x5065726C;     # 'Perl'
4504     vec($foo,  2, 16) = 0x5065;         # 'PerlPe'
4505     vec($foo,  3, 16) = 0x726C;         # 'PerlPerl'
4506     vec($foo,  8,  8) = 0x50;           # 'PerlPerlP'
4507     vec($foo,  9,  8) = 0x65;           # 'PerlPerlPe'
4508     vec($foo, 20,  4) = 2;              # 'PerlPerlPe'   . "\x02"
4509     vec($foo, 21,  4) = 7;              # 'PerlPerlPer'
4510                                         # 'r' is "\x72"
4511     vec($foo, 45,  2) = 3;              # 'PerlPerlPer'  . "\x0c"
4512     vec($foo, 93,  1) = 1;              # 'PerlPerlPer'  . "\x2c"
4513     vec($foo, 94,  1) = 1;              # 'PerlPerlPerl'
4514                                         # 'l' is "\x6c"
4515
4516 To transform a bit vector into a string or array of 0's and 1's, use these:
4517
4518     $bits = unpack("b*", $vector);
4519     @bits = split(//, unpack("b*", $vector));
4520
4521 If you know the exact length in bits, it can be used in place of the C<*>.
4522
4523 =item wait
4524
4525 Waits for a child process to terminate and returns the pid of the
4526 deceased process, or C<-1> if there are no child processes.  The status is
4527 returned in C<$?>.  Note that a return value of C<-1> could mean that
4528 child processes are being automatically reaped, as described in L<perlipc>.
4529
4530 =item waitpid PID,FLAGS
4531
4532 Waits for a particular child process to terminate and returns the pid
4533 of the deceased process, or C<-1> if there is no such child process.  The
4534 status is returned in C<$?>.  If you say
4535
4536     use POSIX ":sys_wait_h";
4537     #...
4538     waitpid(-1,&WNOHANG);
4539
4540 then you can do a non-blocking wait for any process.  Non-blocking wait
4541 is available on machines supporting either the waitpid(2) or
4542 wait4(2) system calls.  However, waiting for a particular pid with
4543 FLAGS of C<0> is implemented everywhere.  (Perl emulates the system call
4544 by remembering the status values of processes that have exited but have
4545 not been harvested by the Perl script yet.)
4546
4547 Note that a return value of C<-1> could mean that child processes are being
4548 automatically reaped.  See L<perlipc> for details, and for other examples.
4549
4550 =item wantarray
4551
4552 Returns TRUE if the context of the currently executing subroutine is
4553 looking for a list value.  Returns FALSE if the context is looking
4554 for a scalar.  Returns the undefined value if the context is looking
4555 for no value (void context).
4556
4557     return unless defined wantarray;    # don't bother doing more
4558     my @a = complex_calculation();
4559     return wantarray ? @a : "@a";
4560
4561 =item warn LIST
4562
4563 Produces a message on STDERR just like C<die()>, but doesn't exit or throw
4564 an exception.
4565
4566 If LIST is empty and C<$@> already contains a value (typically from a
4567 previous eval) that value is used after appending C<"\t...caught">
4568 to C<$@>. This is useful for staying almost, but not entirely similar to
4569 C<die()>.
4570
4571 If C<$@> is empty then the string C<"Warning: Something's wrong"> is used.
4572
4573 No message is printed if there is a C<$SIG{__WARN__}> handler
4574 installed.  It is the handler's responsibility to deal with the message
4575 as it sees fit (like, for instance, converting it into a C<die()>).  Most
4576 handlers must therefore make arrangements to actually display the
4577 warnings that they are not prepared to deal with, by calling C<warn()>
4578 again in the handler.  Note that this is quite safe and will not
4579 produce an endless loop, since C<__WARN__> hooks are not called from
4580 inside one.
4581
4582 You will find this behavior is slightly different from that of
4583 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
4584 instead call C<die()> again to change it).
4585
4586 Using a C<__WARN__> handler provides a powerful way to silence all
4587 warnings (even the so-called mandatory ones).  An example:
4588
4589     # wipe out *all* compile-time warnings
4590     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
4591     my $foo = 10;
4592     my $foo = 20;          # no warning about duplicate my $foo,
4593                            # but hey, you asked for it!
4594     # no compile-time or run-time warnings before here
4595     $DOWARN = 1;
4596
4597     # run-time warnings enabled after here
4598     warn "\$foo is alive and $foo!";     # does show up
4599
4600 See L<perlvar> for details on setting C<%SIG> entries, and for more
4601 examples.
4602
4603 =item while (EXPR) BLOCK
4604
4605 =item do BLOCK while (EXPR)
4606
4607 Enter BLOCK while EXPR is true.  The first form may avoid entering the
4608 BLOCK, the second form enters the BLOCK at least once.
4609
4610 See also L<perlsyn>, L</for>, L</until>, and L</continue>.
4611
4612 =item write FILEHANDLE
4613
4614 =item write EXPR
4615
4616 =item write
4617
4618 Writes a formatted record (possibly multi-line) to the specified FILEHANDLE,
4619 using the format associated with that file.  By default the format for
4620 a file is the one having the same name as the filehandle, but the
4621 format for the current output channel (see the C<select()> function) may be set
4622 explicitly by assigning the name of the format to the C<$~> variable.
4623
4624 Top of form processing is handled automatically:  if there is
4625 insufficient room on the current page for the formatted record, the
4626 page is advanced by writing a form feed, a special top-of-page format
4627 is used to format the new page header, and then the record is written.
4628 By default the top-of-page format is the name of the filehandle with
4629 "_TOP" appended, but it may be dynamically set to the format of your
4630 choice by assigning the name to the C<$^> variable while the filehandle is
4631 selected.  The number of lines remaining on the current page is in
4632 variable C<$->, which can be set to C<0> to force a new page.
4633
4634 If FILEHANDLE is unspecified, output goes to the current default output
4635 channel, which starts out as STDOUT but may be changed by the
4636 C<select()> operator.  If the FILEHANDLE is an EXPR, then the expression
4637 is evaluated and the resulting string is used to look up the name of
4638 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
4639
4640 Note that write is I<NOT> the opposite of C<read()>.  Unfortunately.
4641
4642 =item y///
4643
4644 The transliteration operator.  Same as C<tr///>.  See L<perlop>.
4645
4646 =back