This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
patch for perlvar.pod
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program.  This will alias all the short names to the
17 long names in the current package.  Some even have medium names,
18 generally borrowed from B<awk>.
19
20 If you don't mind the performance hit, variables that depend on the
21 currently selected filehandle may instead be set by calling an
22 appropriate object method on the IO::Handle object.  (Summary lines
23 below for this contain the word HANDLE.)  First you must say
24
25     use IO::Handle;
26
27 after which you may use either
28
29     method HANDLE EXPR
30
31 or more safely,
32
33     HANDLE->method(EXPR)
34
35 Each method returns the old value of the IO::Handle attribute.
36 The methods each take an optional EXPR, which if supplied specifies the
37 new value for the IO::Handle attribute in question.  If not supplied,
38 most methods do nothing to the current value--except for
39 autoflush(), which will assume a 1 for you, just to be different.
40 Because loading in the IO::Handle class is an expensive operation, you should
41 learn how to use the regular built-in variables.
42
43 A few of these variables are considered "read-only".  This means that if
44 you try to assign to this variable, either directly or indirectly through
45 a reference, you'll raise a run-time exception.
46
47 The following list is ordered by scalar variables first, then the
48 arrays, then the hashes.
49
50 =over 8
51
52 =item $ARG
53
54 =item $_
55
56 The default input and pattern-searching space.  The following pairs are
57 equivalent:
58
59     while (<>) {...}    # equivalent only in while!
60     while (defined($_ = <>)) {...}
61
62     /^Subject:/
63     $_ =~ /^Subject:/
64
65     tr/a-z/A-Z/
66     $_ =~ tr/a-z/A-Z/
67
68     chomp
69     chomp($_)
70
71 Here are the places where Perl will assume $_ even if you
72 don't use it:
73
74 =over 3
75
76 =item *
77
78 Various unary functions, including functions like ord() and int(), as well
79 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
80 STDIN.
81
82 =item *
83
84 Various list functions like print() and unlink().
85
86 =item *
87
88 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
89 without an C<=~> operator.
90
91 =item *
92
93 The default iterator variable in a C<foreach> loop if no other
94 variable is supplied.
95
96 =item *
97
98 The implicit iterator variable in the grep() and map() functions.
99
100 =item *
101
102 The default place to put an input record when a C<< <FH> >>
103 operation's result is tested by itself as the sole criterion of a C<while>
104 test.  Outside a C<while> test, this will not happen.
105
106 =back
107
108 (Mnemonic: underline is understood in certain operations.)
109
110 =back
111
112 =over 8
113
114 =item $a
115
116 =item $b
117
118 Special package variables when using sort(), see L<perlfunc/sort>.
119 Because of this specialness $a and $b don't need to be declared
120 (using local(), use vars, or our()) even when using the strict
121 vars pragma.  Don't lexicalize them with C<my $a> or C<my $b>
122 if you want to be able to use them in the sort() comparison block
123 or function.
124
125 =back
126
127 =over 8
128
129 =item $<I<digits>>
130
131 Contains the subpattern from the corresponding set of capturing
132 parentheses from the last pattern match, not counting patterns
133 matched in nested blocks that have been exited already.  (Mnemonic:
134 like \digits.)  These variables are all read-only and dynamically
135 scoped to the current BLOCK.
136
137 =item $MATCH
138
139 =item $&
140
141 The string matched by the last successful pattern match (not counting
142 any matches hidden within a BLOCK or eval() enclosed by the current
143 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
144 and dynamically scoped to the current BLOCK.
145
146 The use of this variable anywhere in a program imposes a considerable
147 performance penalty on all regular expression matches.  See L<BUGS>.
148
149 =item $PREMATCH
150
151 =item $`
152
153 The string preceding whatever was matched by the last successful
154 pattern match (not counting any matches hidden within a BLOCK or eval
155 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
156 string.)  This variable is read-only.
157
158 The use of this variable anywhere in a program imposes a considerable
159 performance penalty on all regular expression matches.  See L<BUGS>.
160
161 =item $POSTMATCH
162
163 =item $'
164
165 The string following whatever was matched by the last successful
166 pattern match (not counting any matches hidden within a BLOCK or eval()
167 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
168 string.)  Example:
169
170     $_ = 'abcdefghi';
171     /def/;
172     print "$`:$&:$'\n";         # prints abc:def:ghi
173
174 This variable is read-only and dynamically scoped to the current BLOCK.
175
176 The use of this variable anywhere in a program imposes a considerable
177 performance penalty on all regular expression matches.  See L<BUGS>.
178
179 =item $LAST_PAREN_MATCH
180
181 =item $+
182
183 The text matched by the last bracket of the last successful search pattern.
184 This is useful if you don't know which one of a set of alternative patterns
185 matched. For example:
186
187     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
188
189 (Mnemonic: be positive and forward looking.)
190 This variable is read-only and dynamically scoped to the current BLOCK.
191
192 =item $^N
193
194 The text matched by the used group most-recently closed (i.e. the group
195 with the rightmost closing parenthesis) of the last successful search
196 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
197 recently closed.)
198
199 This is primarly used inside C<(?{...})> blocks for examining text
200 recently matched. For example, to effectively capture text to a variable
201 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
202
203      (?:(...)(?{ $var = $^N }))
204
205 By setting and then using C<$var> in this way relieves you from having to
206 worry about exactly which numbered set of parentheses they are.
207
208 This variable is dynamically scoped to the current BLOCK.
209
210 =item @LAST_MATCH_END
211
212 =item @+
213
214 This array holds the offsets of the ends of the last successful
215 submatches in the currently active dynamic scope.  C<$+[0]> is
216 the offset into the string of the end of the entire match.  This
217 is the same value as what the C<pos> function returns when called
218 on the variable that was matched against.  The I<n>th element
219 of this array holds the offset of the I<n>th submatch, so
220 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
221 past where $2 ends, and so on.  You can use C<$#+> to determine
222 how many subgroups were in the last successful match.  See the
223 examples given for the C<@-> variable.
224
225 =item $MULTILINE_MATCHING
226
227 =item $*
228
229 Set to a non-zero integer value to do multi-line matching within a
230 string, 0 (or undefined) to tell Perl that it can assume that strings
231 contain a single line, for the purpose of optimizing pattern matches.
232 Pattern matches on strings containing multiple newlines can produce
233 confusing results when C<$*> is 0 or undefined. Default is undefined.
234 (Mnemonic: * matches multiple things.) This variable influences the
235 interpretation of only C<^> and C<$>. A literal newline can be searched
236 for even when C<$* == 0>.
237
238 Use of C<$*> is deprecated in modern Perl, supplanted by 
239 the C</s> and C</m> modifiers on pattern matching.
240
241 Assigning a non-numerical value to C<$*> triggers a warning (and makes
242 C<$*> act if C<$* == 0>), while assigning a numerical value to C<$*>
243 makes that an implicit C<int> is applied on the value.
244
245 =item input_line_number HANDLE EXPR
246
247 =item $INPUT_LINE_NUMBER
248
249 =item $NR
250
251 =item $.
252
253 The current input record number for the last file handle from which
254 you just read() (or called a C<seek> or C<tell> on).  The value
255 may be different from the actual physical line number in the file,
256 depending on what notion of "line" is in effect--see C<$/> on how
257 to change that.  An explicit close on a filehandle resets the line
258 number.  Because C<< <> >> never does an explicit close, line
259 numbers increase across ARGV files (but see examples in L<perlfunc/eof>).
260 Consider this variable read-only: setting it does not reposition
261 the seek pointer; you'll have to do that on your own.  Localizing C<$.>
262 has the effect of also localizing Perl's notion of "the last read
263 filehandle".  (Mnemonic: many programs use "." to mean the current line
264 number.)
265
266 =item IO::Handle->input_record_separator EXPR
267
268 =item $INPUT_RECORD_SEPARATOR
269
270 =item $RS
271
272 =item $/
273
274 The input record separator, newline by default.  This 
275 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
276 variable, including treating empty lines as a terminator if set to
277 the null string.  (An empty line cannot contain any spaces
278 or tabs.)  You may set it to a multi-character string to match a
279 multi-character terminator, or to C<undef> to read through the end
280 of file.  Setting it to C<"\n\n"> means something slightly
281 different than setting to C<"">, if the file contains consecutive
282 empty lines.  Setting to C<""> will treat two or more consecutive
283 empty lines as a single empty line.  Setting to C<"\n\n"> will
284 blindly assume that the next input character belongs to the next
285 paragraph, even if it's a newline.  (Mnemonic: / delimits
286 line boundaries when quoting poetry.)
287
288     undef $/;           # enable "slurp" mode
289     $_ = <FH>;          # whole file now here
290     s/\n[ \t]+/ /g;
291
292 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
293 better for something. :-)
294
295 Setting C<$/> to a reference to an integer, scalar containing an integer, or
296 scalar that's convertible to an integer will attempt to read records
297 instead of lines, with the maximum record size being the referenced
298 integer.  So this:
299
300     $/ = \32768; # or \"32768", or \$var_containing_32768
301     open(FILE, $myfile);
302     $_ = <FILE>;
303
304 will read a record of no more than 32768 bytes from FILE.  If you're
305 not reading from a record-oriented file (or your OS doesn't have
306 record-oriented files), then you'll likely get a full chunk of data
307 with every read.  If a record is larger than the record size you've
308 set, you'll get the record back in pieces.
309
310 On VMS, record reads are done with the equivalent of C<sysread>,
311 so it's best not to mix record and non-record reads on the same
312 file.  (This is unlikely to be a problem, because any file you'd
313 want to read in record mode is probably unusable in line mode.)
314 Non-VMS systems do normal I/O, so it's safe to mix record and
315 non-record reads of a file.
316
317 See also L<perlport/"Newlines">.  Also see C<$.>.
318
319 =item autoflush HANDLE EXPR
320
321 =item $OUTPUT_AUTOFLUSH
322
323 =item $|
324
325 If set to nonzero, forces a flush right away and after every write
326 or print on the currently selected output channel.  Default is 0
327 (regardless of whether the channel is really buffered by the
328 system or not; C<$|> tells you only whether you've asked Perl
329 explicitly to flush after each write).  STDOUT will
330 typically be line buffered if output is to the terminal and block
331 buffered otherwise.  Setting this variable is useful primarily when
332 you are outputting to a pipe or socket, such as when you are running
333 a Perl program under B<rsh> and want to see the output as it's
334 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
335 for that.  (Mnemonic: when you want your pipes to be piping hot.)
336
337 =item IO::Handle->output_field_separator EXPR
338
339 =item $OUTPUT_FIELD_SEPARATOR
340
341 =item $OFS
342
343 =item $,
344
345 The output field separator for the print operator.  Ordinarily the
346 print operator simply prints out its arguments without further
347 adornment.  To get behavior more like B<awk>, set this variable as
348 you would set B<awk>'s OFS variable to specify what is printed
349 between fields.  (Mnemonic: what is printed when there is a "," in
350 your print statement.)
351
352 =item IO::Handle->output_record_separator EXPR
353
354 =item $OUTPUT_RECORD_SEPARATOR
355
356 =item $ORS
357
358 =item $\
359
360 The output record separator for the print operator.  Ordinarily the
361 print operator simply prints out its arguments as is, with no
362 trailing newline or other end-of-record string added.  To get
363 behavior more like B<awk>, set this variable as you would set
364 B<awk>'s ORS variable to specify what is printed at the end of the
365 print.  (Mnemonic: you set C<$\> instead of adding "\n" at the
366 end of the print.  Also, it's just like C<$/>, but it's what you
367 get "back" from Perl.)
368
369 =item $LIST_SEPARATOR
370
371 =item $"
372
373 This is like C<$,> except that it applies to array and slice values
374 interpolated into a double-quoted string (or similar interpreted
375 string).  Default is a space.  (Mnemonic: obvious, I think.)
376
377 =item $SUBSCRIPT_SEPARATOR
378
379 =item $SUBSEP
380
381 =item $;
382
383 The subscript separator for multidimensional array emulation.  If you
384 refer to a hash element as
385
386     $foo{$a,$b,$c}
387
388 it really means
389
390     $foo{join($;, $a, $b, $c)}
391
392 But don't put
393
394     @foo{$a,$b,$c}      # a slice--note the @
395
396 which means
397
398     ($foo{$a},$foo{$b},$foo{$c})
399
400 Default is "\034", the same as SUBSEP in B<awk>.  If your
401 keys contain binary data there might not be any safe value for C<$;>.
402 (Mnemonic: comma (the syntactic subscript separator) is a
403 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
404 taken for something more important.)
405
406 Consider using "real" multidimensional arrays as described
407 in L<perllol>.
408
409 =item $OFMT
410
411 =item $#
412
413 The output format for printed numbers.  This variable is a half-hearted
414 attempt to emulate B<awk>'s OFMT variable.  There are times, however,
415 when B<awk> and Perl have differing notions of what counts as 
416 numeric.  The initial value is "%.I<n>g", where I<n> is the value
417 of the macro DBL_DIG from your system's F<float.h>.  This is different from
418 B<awk>'s default OFMT setting of "%.6g", so you need to set C<$#>
419 explicitly to get B<awk>'s value.  (Mnemonic: # is the number sign.)
420
421 Use of C<$#> is deprecated.
422
423 =item format_page_number HANDLE EXPR
424
425 =item $FORMAT_PAGE_NUMBER
426
427 =item $%
428
429 The current page number of the currently selected output channel.
430 Used with formats.
431 (Mnemonic: % is page number in B<nroff>.)
432
433 =item format_lines_per_page HANDLE EXPR
434
435 =item $FORMAT_LINES_PER_PAGE
436
437 =item $=
438
439 The current page length (printable lines) of the currently selected
440 output channel.  Default is 60.  
441 Used with formats.
442 (Mnemonic: = has horizontal lines.)
443
444 =item format_lines_left HANDLE EXPR
445
446 =item $FORMAT_LINES_LEFT
447
448 =item $-
449
450 The number of lines left on the page of the currently selected output
451 channel.  
452 Used with formats.
453 (Mnemonic: lines_on_page - lines_printed.)
454
455 =item @LAST_MATCH_START
456
457 =item @-
458
459 $-[0] is the offset of the start of the last successful match.
460 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
461 I<n>-th subpattern, or undef if the subpattern did not match.
462
463 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
464 $+[0] - $-[0]>.  Similarly, C<$>I<n> coincides with C<substr $_, $-[>I<n>C<],
465 $+[>I<n>C<] - $-[>I<n>C<]> if C<$-[>I<n>C<]> is defined, and $+ coincides with
466 C<substr $_, $-[$#-], $+[$#-]>.  One can use C<$#-> to find the last
467 matched subgroup in the last successful match.  Contrast with
468 C<$#+>, the number of subgroups in the regular expression.  Compare
469 with C<@+>.
470
471 This array holds the offsets of the beginnings of the last
472 successful submatches in the currently active dynamic scope.
473 C<$-[0]> is the offset into the string of the beginning of the
474 entire match.  The I<n>th element of this array holds the offset
475 of the I<n>th submatch, so C<$-[1]> is the offset where $1
476 begins, C<$-[2]> the offset where $2 begins, and so on.
477
478 After a match against some variable $var:
479
480 =over 5
481
482 =item C<$`> is the same as C<substr($var, 0, $-[0])>
483
484 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
485
486 =item C<$'> is the same as C<substr($var, $+[0])>
487
488 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
489
490 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
491
492 =item C<$3> is the same as C<substr $var, $-[3], $+[3] - $-[3])>
493
494 =back
495
496 =item format_name HANDLE EXPR
497
498 =item $FORMAT_NAME
499
500 =item $~
501
502 The name of the current report format for the currently selected output
503 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
504 C<$^>.)
505
506 =item format_top_name HANDLE EXPR
507
508 =item $FORMAT_TOP_NAME
509
510 =item $^
511
512 The name of the current top-of-page format for the currently selected
513 output channel.  Default is the name of the filehandle with _TOP
514 appended.  (Mnemonic: points to top of page.)
515
516 =item IO::Handle->format_line_break_characters EXPR
517
518 =item $FORMAT_LINE_BREAK_CHARACTERS
519
520 =item $:
521
522 The current set of characters after which a string may be broken to
523 fill continuation fields (starting with ^) in a format.  Default is
524 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
525 poetry is a part of a line.)
526
527 =item IO::Handle->format_formfeed EXPR
528
529 =item $FORMAT_FORMFEED
530
531 =item $^L
532
533 What formats output as a form feed.  Default is \f.
534
535 =item $ACCUMULATOR
536
537 =item $^A
538
539 The current value of the write() accumulator for format() lines.  A format
540 contains formline() calls that put their result into C<$^A>.  After
541 calling its format, write() prints out the contents of C<$^A> and empties.
542 So you never really see the contents of C<$^A> unless you call
543 formline() yourself and then look at it.  See L<perlform> and
544 L<perlfunc/formline()>.
545
546 =item $CHILD_ERROR
547
548 =item $?
549
550 The status returned by the last pipe close, backtick (C<``>) command,
551 successful call to wait() or waitpid(), or from the system()
552 operator.  This is just the 16-bit status word returned by the
553 wait() system call (or else is made up to look like it).  Thus, the
554 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
555 C<$? & 127> gives which signal, if any, the process died from, and
556 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
557 similar to B<sh> and B<ksh>.)
558
559 Additionally, if the C<h_errno> variable is supported in C, its value
560 is returned via $? if any C<gethost*()> function fails.
561
562 If you have installed a signal handler for C<SIGCHLD>, the
563 value of C<$?> will usually be wrong outside that handler.
564
565 Inside an C<END> subroutine C<$?> contains the value that is going to be
566 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
567 change the exit status of your program.  For example:
568
569     END {
570         $? = 1 if $? == 255;  # die would make it 255
571     } 
572
573 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
574 actual VMS exit status, instead of the default emulation of POSIX
575 status; see L<perlvms/$?> for details.
576
577 Also see L<Error Indicators>.
578
579 =item $OS_ERROR
580
581 =item $ERRNO
582
583 =item $!
584
585 If used numerically, yields the current value of the C C<errno>
586 variable, with all the usual caveats.  (This means that you shouldn't
587 depend on the value of C<$!> to be anything in particular unless
588 you've gotten a specific error return indicating a system error.)
589 If used an a string, yields the corresponding system error string.
590 You can assign a number to C<$!> to set I<errno> if, for instance,
591 you want C<"$!"> to return the string for error I<n>, or you want
592 to set the exit value for the die() operator.  (Mnemonic: What just
593 went bang?)
594
595 Also see L<Error Indicators>.
596
597 =item $EXTENDED_OS_ERROR
598
599 =item $^E
600
601 Error information specific to the current operating system.  At
602 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
603 (and for MacPerl).  On all other platforms, C<$^E> is always just
604 the same as C<$!>.
605
606 Under VMS, C<$^E> provides the VMS status value from the last
607 system error.  This is more specific information about the last
608 system error than that provided by C<$!>.  This is particularly
609 important when C<$!> is set to B<EVMSERR>.
610
611 Under OS/2, C<$^E> is set to the error code of the last call to
612 OS/2 API either via CRT, or directly from perl.
613
614 Under Win32, C<$^E> always returns the last error information
615 reported by the Win32 call C<GetLastError()> which describes
616 the last error from within the Win32 API.  Most Win32-specific
617 code will report errors via C<$^E>.  ANSI C and Unix-like calls
618 set C<errno> and so most portable Perl code will report errors
619 via C<$!>. 
620
621 Caveats mentioned in the description of C<$!> generally apply to
622 C<$^E>, also.  (Mnemonic: Extra error explanation.)
623
624 Also see L<Error Indicators>.
625
626 =item $EVAL_ERROR
627
628 =item $@
629
630 The Perl syntax error message from the last eval() operator.
631 If $@ is the null string, the last eval() parsed and executed
632 correctly (although the operations you invoked may have failed in the
633 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
634
635 Warning messages are not collected in this variable.  You can,
636 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
637 as described below.
638
639 Also see L<Error Indicators>.
640
641 =item $PROCESS_ID
642
643 =item $PID
644
645 =item $$
646
647 The process number of the Perl running this script.  You should
648 consider this variable read-only, although it will be altered
649 across fork() calls.  (Mnemonic: same as shells.)
650
651 =item $REAL_USER_ID
652
653 =item $UID
654
655 =item $<
656
657 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
658 if you're running setuid.)  You can change both the real uid and
659 the effective uid at the same time by using POSIX::setuid().
660
661 =item $EFFECTIVE_USER_ID
662
663 =item $EUID
664
665 =item $>
666
667 The effective uid of this process.  Example:
668
669     $< = $>;            # set real to effective uid
670     ($<,$>) = ($>,$<);  # swap real and effective uid
671
672 You can change both the effective uid and the real uid at the same
673 time by using POSIX::setuid().
674
675 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
676 C<< $< >> and C<< $> >> can be swapped only on machines
677 supporting setreuid().
678
679 =item $REAL_GROUP_ID
680
681 =item $GID
682
683 =item $(
684
685 The real gid of this process.  If you are on a machine that supports
686 membership in multiple groups simultaneously, gives a space separated
687 list of groups you are in.  The first number is the one returned by
688 getgid(), and the subsequent ones by getgroups(), one of which may be
689 the same as the first number.
690
691 However, a value assigned to C<$(> must be a single number used to
692 set the real gid.  So the value given by C<$(> should I<not> be assigned
693 back to C<$(> without being forced numeric, such as by adding zero.
694
695 You can change both the real gid and the effective gid at the same
696 time by using POSIX::setgid().
697
698 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
699 group you I<left>, if you're running setgid.)
700
701 =item $EFFECTIVE_GROUP_ID
702
703 =item $EGID
704
705 =item $)
706
707 The effective gid of this process.  If you are on a machine that
708 supports membership in multiple groups simultaneously, gives a space
709 separated list of groups you are in.  The first number is the one
710 returned by getegid(), and the subsequent ones by getgroups(), one of
711 which may be the same as the first number.
712
713 Similarly, a value assigned to C<$)> must also be a space-separated
714 list of numbers.  The first number sets the effective gid, and
715 the rest (if any) are passed to setgroups().  To get the effect of an
716 empty list for setgroups(), just repeat the new effective gid; that is,
717 to force an effective gid of 5 and an effectively empty setgroups()
718 list, say C< $) = "5 5" >.
719
720 You can change both the effective gid and the real gid at the same
721 time by using POSIX::setgid() (use only a single numeric argument).
722
723 (Mnemonic: parentheses are used to I<group> things.  The effective gid
724 is the group that's I<right> for you, if you're running setgid.)
725
726 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
727 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
728 and C<$)> can be swapped only on machines supporting setregid().
729
730 =item $PROGRAM_NAME
731
732 =item $0
733
734 Contains the name of the program being executed.  On some operating
735 systems assigning to C<$0> modifies the argument area that the B<ps>
736 program sees.  This is more useful as a way of indicating the current
737 program state than it is for hiding the program you're running.
738 (Mnemonic: same as B<sh> and B<ksh>.)
739
740 Note for BSD users: setting C<$0> does not completely remove "perl"
741 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> will
742 result in C<"perl: foobar (perl)">.  This is an operating system
743 feature.
744
745 =item $[
746
747 The index of the first element in an array, and of the first character
748 in a substring.  Default is 0, but you could theoretically set it
749 to 1 to make Perl behave more like B<awk> (or Fortran) when
750 subscripting and when evaluating the index() and substr() functions.
751 (Mnemonic: [ begins subscripts.)
752
753 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
754 directive, and cannot influence the behavior of any other file.
755 Its use is highly discouraged.
756
757 =item $]
758
759 The version + patchlevel / 1000 of the Perl interpreter.  This variable
760 can be used to determine whether the Perl interpreter executing a
761 script is in the right range of versions.  (Mnemonic: Is this version
762 of perl in the right bracket?)  Example:
763
764     warn "No checksumming!\n" if $] < 3.019;
765
766 See also the documentation of C<use VERSION> and C<require VERSION>
767 for a convenient way to fail if the running Perl interpreter is too old.
768
769 The use of this variable is deprecated.  The floating point representation
770 can sometimes lead to inaccurate numeric comparisons.  See C<$^V> for a
771 more modern representation of the Perl version that allows accurate string
772 comparisons.
773
774 =item $COMPILING
775
776 =item $^C
777
778 The current value of the flag associated with the B<-c> switch.
779 Mainly of use with B<-MO=...> to allow code to alter its behavior
780 when being compiled, such as for example to AUTOLOAD at compile
781 time rather than normal, deferred loading.  See L<perlcc>.  Setting
782 C<$^C = 1> is similar to calling C<B::minus_c>.
783
784 =item $DEBUGGING
785
786 =item $^D
787
788 The current value of the debugging flags.  (Mnemonic: value of B<-D>
789 switch.)
790
791 =item $SYSTEM_FD_MAX
792
793 =item $^F
794
795 The maximum system file descriptor, ordinarily 2.  System file
796 descriptors are passed to exec()ed processes, while higher file
797 descriptors are not.  Also, during an open(), system file descriptors are
798 preserved even if the open() fails.  (Ordinary file descriptors are
799 closed before the open() is attempted.)  The close-on-exec
800 status of a file descriptor will be decided according to the value of
801 C<$^F> when the corresponding file, pipe, or socket was opened, not the
802 time of the exec().
803
804 =item $^H
805
806 WARNING: This variable is strictly for internal use only.  Its availability,
807 behavior, and contents are subject to change without notice.
808
809 This variable contains compile-time hints for the Perl interpreter.  At the
810 end of compilation of a BLOCK the value of this variable is restored to the
811 value when the interpreter started to compile the BLOCK.
812
813 When perl begins to parse any block construct that provides a lexical scope
814 (e.g., eval body, required file, subroutine body, loop body, or conditional
815 block), the existing value of $^H is saved, but its value is left unchanged.
816 When the compilation of the block is completed, it regains the saved value.
817 Between the points where its value is saved and restored, code that
818 executes within BEGIN blocks is free to change the value of $^H.
819
820 This behavior provides the semantic of lexical scoping, and is used in,
821 for instance, the C<use strict> pragma.
822
823 The contents should be an integer; different bits of it are used for
824 different pragmatic flags.  Here's an example:
825
826     sub add_100 { $^H |= 0x100 }
827
828     sub foo {
829         BEGIN { add_100() }
830         bar->baz($boon);
831     }
832
833 Consider what happens during execution of the BEGIN block.  At this point
834 the BEGIN block has already been compiled, but the body of foo() is still
835 being compiled.  The new value of $^H will therefore be visible only while
836 the body of foo() is being compiled.
837
838 Substitution of the above BEGIN block with:
839
840     BEGIN { require strict; strict->import('vars') }
841
842 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
843 version of the same lexical pragma:
844
845     BEGIN { require strict; strict->import('vars') if $condition }
846
847 =item %^H
848
849 WARNING: This variable is strictly for internal use only.  Its availability,
850 behavior, and contents are subject to change without notice.
851
852 The %^H hash provides the same scoping semantic as $^H.  This makes it
853 useful for implementation of lexically scoped pragmas.
854
855 =item $INPLACE_EDIT
856
857 =item $^I
858
859 The current value of the inplace-edit extension.  Use C<undef> to disable
860 inplace editing.  (Mnemonic: value of B<-i> switch.)
861
862 =item $^M
863
864 By default, running out of memory is an untrappable, fatal error.
865 However, if suitably built, Perl can use the contents of C<$^M>
866 as an emergency memory pool after die()ing.  Suppose that your Perl
867 were compiled with -DPERL_EMERGENCY_SBRK and used Perl's malloc.
868 Then
869
870     $^M = 'a' x (1 << 16);
871
872 would allocate a 64K buffer for use in an emergency.  See the
873 F<INSTALL> file in the Perl distribution for information on how to
874 enable this option.  To discourage casual use of this advanced
875 feature, there is no L<English|English> long name for this variable.
876
877 =item $OSNAME
878
879 =item $^O
880
881 The name of the operating system under which this copy of Perl was
882 built, as determined during the configuration process.  The value
883 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
884 B<-V> command-line switch documented in L<perlrun>.
885
886 =item $PERLDB
887
888 =item $^P
889
890 The internal variable for debugging support.  The meanings of the
891 various bits are subject to change, but currently indicate:
892
893 =over 6
894
895 =item 0x01
896
897 Debug subroutine enter/exit.
898
899 =item 0x02
900
901 Line-by-line debugging.
902
903 =item 0x04
904
905 Switch off optimizations.
906
907 =item 0x08
908
909 Preserve more data for future interactive inspections.
910
911 =item 0x10
912
913 Keep info about source lines on which a subroutine is defined.
914
915 =item 0x20
916
917 Start with single-step on.
918
919 =item 0x40
920
921 Use subroutine address instead of name when reporting.
922
923 =item 0x80
924
925 Report C<goto &subroutine> as well.
926
927 =item 0x100
928
929 Provide informative "file" names for evals based on the place they were compiled.
930
931 =item 0x200
932
933 Provide informative names to anonymous subroutines based on the place they
934 were compiled.
935
936 =back
937
938 Some bits may be relevant at compile-time only, some at
939 run-time only.  This is a new mechanism and the details may change.
940
941 =item $LAST_REGEXP_CODE_RESULT
942
943 =item $^R
944
945 The result of evaluation of the last successful C<(?{ code })>
946 regular expression assertion (see L<perlre>).  May be written to.
947
948 =item $EXCEPTIONS_BEING_CAUGHT
949
950 =item $^S
951
952 Current state of the interpreter.  Undefined if parsing of the current
953 module/eval is not finished (may happen in $SIG{__DIE__} and
954 $SIG{__WARN__} handlers).  True if inside an eval(), otherwise false.
955
956 =item $BASETIME
957
958 =item $^T
959
960 The time at which the program began running, in seconds since the
961 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
962 and B<-C> filetests are based on this value.
963
964 =item $PERL_VERSION
965
966 =item $^V
967
968 The revision, version, and subversion of the Perl interpreter, represented
969 as a string composed of characters with those ordinals.  Thus in Perl v5.6.0
970 it equals C<chr(5) . chr(6) . chr(0)> and will return true for
971 C<$^V eq v5.6.0>.  Note that the characters in this string value can
972 potentially be in Unicode range.
973
974 This can be used to determine whether the Perl interpreter executing a
975 script is in the right range of versions.  (Mnemonic: use ^V for Version
976 Control.)  Example:
977
978     warn "No \"our\" declarations!\n" if $^V and $^V lt v5.6.0;
979
980 See the documentation of C<use VERSION> and C<require VERSION>
981 for a convenient way to fail if the running Perl interpreter is too old.
982
983 See also C<$]> for an older representation of the Perl version.
984
985 =item $WARNING
986
987 =item $^W
988
989 The current value of the warning switch, initially true if B<-w>
990 was used, false otherwise, but directly modifiable.  (Mnemonic:
991 related to the B<-w> switch.)  See also L<warnings>.
992
993 =item ${^WARNING_BITS}
994
995 The current set of warning checks enabled by the C<use warnings> pragma.
996 See the documentation of C<warnings> for more details.
997
998 =item ${^WIDE_SYSTEM_CALLS}
999
1000 Global flag that enables system calls made by Perl to use wide character
1001 APIs native to the system, if available.  This is currently only implemented
1002 on the Windows platform.
1003
1004 This can also be enabled from the command line using the C<-C> switch.
1005
1006 The initial value is typically C<0> for compatibility with Perl versions
1007 earlier than 5.6, but may be automatically set to C<1> by Perl if the system
1008 provides a user-settable default (e.g., C<$ENV{LC_CTYPE}>).
1009
1010 The C<bytes> pragma always overrides the effect of this flag in the current
1011 lexical scope.  See L<bytes>.
1012
1013 =item $EXECUTABLE_NAME
1014
1015 =item $^X
1016
1017 The name that the Perl binary itself was executed as, from C's C<argv[0]>.
1018 This may not be a full pathname, nor even necessarily in your path.
1019
1020 =item $ARGV
1021
1022 contains the name of the current file when reading from <>.
1023
1024 =item @ARGV
1025
1026 The array @ARGV contains the command-line arguments intended for
1027 the script.  C<$#ARGV> is generally the number of arguments minus
1028 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1029 command name itself.  See C<$0> for the command name.
1030
1031 =item @F
1032
1033 The array @F contains the fields of each line read in when autosplit
1034 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1035 is package-specific, and must be declared or given a full package name
1036 if not in package main when running under C<strict 'vars'>.
1037
1038 =item @INC
1039
1040 The array @INC contains the list of places that the C<do EXPR>,
1041 C<require>, or C<use> constructs look for their library files.  It
1042 initially consists of the arguments to any B<-I> command-line
1043 switches, followed by the default Perl library, probably
1044 F</usr/local/lib/perl>, followed by ".", to represent the current
1045 directory.  If you need to modify this at runtime, you should use
1046 the C<use lib> pragma to get the machine-dependent library properly
1047 loaded also:
1048
1049     use lib '/mypath/libdir/';
1050     use SomeMod;
1051
1052 =item @_
1053
1054 Within a subroutine the array @_ contains the parameters passed to that
1055 subroutine.  See L<perlsub>.
1056
1057 =item %INC
1058
1059 The hash %INC contains entries for each filename included via the
1060 C<do>, C<require>, or C<use> operators.  The key is the filename
1061 you specified (with module names converted to pathnames), and the
1062 value is the location of the file found.  The C<require>
1063 operator uses this hash to determine whether a particular file has
1064 already been included.
1065
1066 =item %ENV
1067
1068 =item $ENV{expr}
1069
1070 The hash %ENV contains your current environment.  Setting a
1071 value in C<ENV> changes the environment for any child processes
1072 you subsequently fork() off.
1073
1074 =item %SIG
1075
1076 =item $SIG{expr}
1077
1078 The hash %SIG contains signal handlers for signals.  For example:
1079
1080     sub handler {       # 1st argument is signal name
1081         my($sig) = @_;
1082         print "Caught a SIG$sig--shutting down\n";
1083         close(LOG);
1084         exit(0);
1085     }
1086
1087     $SIG{'INT'}  = \&handler;
1088     $SIG{'QUIT'} = \&handler;
1089     ...
1090     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1091     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1092
1093 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1094 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1095 this special case.
1096
1097 Here are some other examples:
1098
1099     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1100     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1101     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1102     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1103
1104 Be sure not to use a bareword as the name of a signal handler,
1105 lest you inadvertently call it. 
1106
1107 If your system has the sigaction() function then signal handlers are
1108 installed using it.  This means you get reliable signal handling.  If
1109 your system has the SA_RESTART flag it is used when signals handlers are
1110 installed.  This means that system calls for which restarting is supported
1111 continue rather than returning when a signal arrives.  If you want your
1112 system calls to be interrupted by signal delivery then do something like
1113 this:
1114
1115     use POSIX ':signal_h';
1116
1117     my $alarm = 0;
1118     sigaction SIGALRM, new POSIX::SigAction sub { $alarm = 1 }
1119         or die "Error setting SIGALRM handler: $!\n";
1120
1121 See L<POSIX>.
1122
1123 Certain internal hooks can be also set using the %SIG hash.  The
1124 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1125 about to be printed.  The warning message is passed as the first
1126 argument.  The presence of a __WARN__ hook causes the ordinary printing
1127 of warnings to STDERR to be suppressed.  You can use this to save warnings
1128 in a variable, or turn warnings into fatal errors, like this:
1129
1130     local $SIG{__WARN__} = sub { die $_[0] };
1131     eval $proggie;
1132
1133 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1134 is about to be thrown.  The error message is passed as the first
1135 argument.  When a __DIE__ hook routine returns, the exception
1136 processing continues as it would have in the absence of the hook,
1137 unless the hook routine itself exits via a C<goto>, a loop exit, or a die().
1138 The C<__DIE__> handler is explicitly disabled during the call, so that you
1139 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1140
1141 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1142 even inside an eval().  Do not use this to rewrite a pending exception
1143 in C<$@>, or as a bizarre substitute for overriding CORE::GLOBAL::die().
1144 This strange action at a distance may be fixed in a future release
1145 so that C<$SIG{__DIE__}> is only called if your program is about
1146 to exit, as was the original intent.  Any other use is deprecated.
1147
1148 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1149 they may be called to report (probable) errors found by the parser.
1150 In such a case the parser may be in inconsistent state, so any
1151 attempt to evaluate Perl code from such a handler will probably
1152 result in a segfault.  This means that warnings or errors that
1153 result from parsing Perl should be used with extreme caution, like
1154 this:
1155
1156     require Carp if defined $^S;
1157     Carp::confess("Something wrong") if defined &Carp::confess;
1158     die "Something wrong, but could not load Carp to give backtrace...
1159          To see backtrace try starting Perl with -MCarp switch";
1160
1161 Here the first line will load Carp I<unless> it is the parser who
1162 called the handler.  The second line will print backtrace and die if
1163 Carp was available.  The third line will be executed only if Carp was
1164 not available.
1165
1166 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1167 L<warnings> for additional information.
1168
1169 =back
1170
1171 =head2 Error Indicators
1172
1173 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1174 about different types of error conditions that may appear during
1175 execution of a Perl program.  The variables are shown ordered by
1176 the "distance" between the subsystem which reported the error and
1177 the Perl process.  They correspond to errors detected by the Perl
1178 interpreter, C library, operating system, or an external program,
1179 respectively.
1180
1181 To illustrate the differences between these variables, consider the 
1182 following Perl expression, which uses a single-quoted string:
1183
1184     eval q{
1185         open PIPE, "/cdrom/install |";
1186         @res = <PIPE>;
1187         close PIPE or die "bad pipe: $?, $!";
1188     };
1189
1190 After execution of this statement all 4 variables may have been set.  
1191
1192 C<$@> is set if the string to be C<eval>-ed did not compile (this
1193 may happen if C<open> or C<close> were imported with bad prototypes),
1194 or if Perl code executed during evaluation die()d .  In these cases
1195 the value of $@ is the compile error, or the argument to C<die>
1196 (which will interpolate C<$!> and C<$?>!).  (See also L<Fatal>,
1197 though.)
1198
1199 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1200 and C<close> are translated to calls in the C run-time library and
1201 thence to the operating system kernel.  C<$!> is set to the C library's
1202 C<errno> if one of these calls fails. 
1203
1204 Under a few operating systems, C<$^E> may contain a more verbose
1205 error indicator, such as in this case, "CDROM tray not closed."
1206 Systems that do not support extended error messages leave C<$^E>
1207 the same as C<$!>.
1208
1209 Finally, C<$?> may be set to non-0 value if the external program
1210 F</cdrom/install> fails.  The upper eight bits reflect specific
1211 error conditions encountered by the program (the program's exit()
1212 value).   The lower eight bits reflect mode of failure, like signal
1213 death and core dump information  See wait(2) for details.  In
1214 contrast to C<$!> and C<$^E>, which are set only if error condition
1215 is detected, the variable C<$?> is set on each C<wait> or pipe
1216 C<close>, overwriting the old value.  This is more like C<$@>, which
1217 on every eval() is always set on failure and cleared on success.
1218
1219 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1220 and C<$?>.
1221
1222 =head2 Technical Note on the Syntax of Variable Names
1223
1224 Variable names in Perl can have several formats.  Usually, they
1225 must begin with a letter or underscore, in which case they can be
1226 arbitrarily long (up to an internal limit of 251 characters) and
1227 may contain letters, digits, underscores, or the special sequence
1228 C<::> or C<'>.  In this case, the part before the last C<::> or
1229 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1230
1231 Perl variable names may also be a sequence of digits or a single
1232 punctuation or control character.  These names are all reserved for
1233 special uses by Perl; for example, the all-digits names are used
1234 to hold data captured by backreferences after a regular expression
1235 match.  Perl has a special syntax for the single-control-character
1236 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1237 character.  For example, the notation C<$^W> (dollar-sign caret
1238 C<W>) is the scalar variable whose name is the single character
1239 control-C<W>.  This is better than typing a literal control-C<W>
1240 into your program.
1241
1242 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1243 strings that begin with control characters (or better yet, a caret).
1244 These variables must be written in the form C<${^Foo}>; the braces
1245 are not optional.  C<${^Foo}> denotes the scalar variable whose
1246 name is a control-C<F> followed by two C<o>'s.  These variables are
1247 reserved for future special uses by Perl, except for the ones that
1248 begin with C<^_> (control-underscore or caret-underscore).  No
1249 control-character name that begins with C<^_> will acquire a special
1250 meaning in any future version of Perl; such names may therefore be
1251 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1252
1253 Perl identifiers that begin with digits, control characters, or
1254 punctuation characters are exempt from the effects of the C<package>
1255 declaration and are always forced to be in package C<main>.  A few
1256 other names are also exempt:
1257
1258         ENV             STDIN
1259         INC             STDOUT
1260         ARGV            STDERR
1261         ARGVOUT
1262         SIG
1263
1264 In particular, the new special C<${^_XYZ}> variables are always taken
1265 to be in package C<main>, regardless of any C<package> declarations
1266 presently in scope.
1267
1268 =head1 BUGS
1269
1270 Due to an unfortunate accident of Perl's implementation, C<use
1271 English> imposes a considerable performance penalty on all regular
1272 expression matches in a program, regardless of whether they occur
1273 in the scope of C<use English>.  For that reason, saying C<use
1274 English> in libraries is strongly discouraged.  See the
1275 Devel::SawAmpersand module documentation from CPAN
1276 (http://www.perl.com/CPAN/modules/by-module/Devel/)
1277 for more information.
1278
1279 Having to even think about the C<$^S> variable in your exception
1280 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1281 invites grievous and difficult to track down errors.  Avoid it
1282 and use an C<END{}> or CORE::GLOBAL::die override instead.