vms/gen_shrfls.pl

   1 # Create global symbol declarations, transfer vector, and
   2 # linker options files for PerlShr.
   3 #
   4 # Input:
   5 #    $cflags - command line qualifiers passed to cc when preprocesing perl.h
   6 #        Note: A rather simple-minded attempt is made to restore quotes to
   7 #        a /Define clause - use with care.
   8 #    $objsuffix - file type (including '.') used for object files.
   9 #    $libperl - Perl object library.
  10 #    $extnames - package names for static extensions (used to generate
  11 #        linker options file entries for boot functions)
  12 #    $rtlopt - name of options file specifying RTLs to which PerlShr.Exe
  13 #        must be linked
  14 #
  15 # Output:
  16 #    PerlShr_Attr.Opt - linker options file which speficies that global vars
  17 #        be placed in NOSHR,WRT psects.  Use when linking any object files
  18 #        against PerlShr.Exe, since cc places global vars in SHR,WRT psects
  19 #        by default.
  20 #    PerlShr_Bld.Opt - declares universal symbols for PerlShr.Exe
  21 #    Perlshr_Gbl*.Mar, Perlshr_Gbl*.Obj (VAX  only) - declares global symbols
  22 #        for global vars (done here because gcc can't globaldef) and creates
  23 #        transfer vectors for routines on a VAX.
  24 #    PerlShr_Gbl.Opt (VAX only) - list of PerlShr_Gbl*.Obj, used for input
  25 #        to the linker when building PerlShr.Exe.
  26 #
  27 # To do:
  28 #   - figure out a good way to collect global vars in one psect, given that
  29 #     we can't use globaldef because of gcc.
  30 #   - then, check for existing files and preserve symbol and transfer vector
  31 #     order for upward compatibility
  32 #   - then, add GSMATCH to options file - but how do we insure that new
  33 #     library has everything old one did
  34 #     (i.e. /Define=DEBUGGING,EMBED,MULTIPLICITY)?
  35 #
  36 # Author: Charles Bailey  bailey@newman.upenn.edu
  37
  38 require 5.000;
  39
  40 $debug = $ENV{'GEN_SHRFLS_DEBUG'};
  41
  42 print "gen_shrfls.pl Rev. 14-Dec-1997\n" if $debug;
  43
  44 if ($ARGV[0] eq '-f') {
  45   open(INP,$ARGV[1]) or die "Can't read input file $ARGV[1]: $!\n";
  46   print "Input taken from file $ARGV[1]\n" if $debug;
  47   @ARGV = ();
  48   while (<INP>) {
  49     chomp;
  50     push(@ARGV,split(/\|/,$_));
  51   }
  52   close INP;
  53   print "Read input data | ",join(' | ',@ARGV)," |\n" if $debug > 1;
  54 }
  55
  56 $cc_cmd = shift @ARGV;
  57
  58 # Someday, we'll have $GetSyI built into perl . . .
  59 $isvax = `\$ Write Sys\$Output F\$GetSyI(\"HW_MODEL\")` <= 1024;
  60 print "\$isvax: \\$isvax\\\n" if $debug;
  61
  62 print "Input \$cc_cmd: \\$cc_cmd\\\n" if $debug;
  63 $docc = ($cc_cmd !~ /^~~/);
  64 print "\$docc = $docc\n" if $debug;
  65
  66 if ($docc) {
  67   if (-f 'perl.h') { $dir = '[]'; }
  68   elsif (-f '[-]perl.h') { $dir = '[-]'; }
  69   else { die "$0: Can't find perl.h\n"; }
  70
  71   # Go see if debugging is enabled in config.h
  72   $config = $dir . "config.h";
  73   open CONFIG, "< $config";
  74   while(<CONFIG>) {
  75     $debugging_enabled++ if /define\s+DEBUGGING/;
  76     $use_mymalloc++ if /define\s+MYMALLOC/;
  77     $hide_mymalloc++ if /define\s+EMBEDMYMALLOC/;
  78     $use_threads++ if /define\s+USE_THREADS/;
  79   }
  80
  81   # put quotes back onto defines - they were removed by DCL on the way in
  82   if (($prefix,$defines,$suffix) =
  83          ($cc_cmd =~ m#(.*)/Define=(.*?)([/\s].*)#i)) {
  84     $defines =~ s/^\((.*)\)$/$1/;
  85     $debugging_enabled ||= $defines =~ /\bDEBUGGING\b/;
  86     @defines = split(/,/,$defines);
  87     $cc_cmd = "$prefix/Define=(" . join(',',grep($_ = "\"$_\"",@defines))
  88               . ')' . $suffix;
  89   }
  90   print "Filtered \$cc_cmd: \\$cc_cmd\\\n" if $debug;
  91
  92   # check for gcc - if present, we'll need to use MACRO hack to
  93   # define global symbols for shared variables
  94   $isvaxc = 0;
  95   $isgcc = `$cc_cmd _nla0:/Version` =~ /GNU/
  96            or 0; # make debug output nice
  97   $isvaxc = (!$isgcc && $isvax &&
  98              # Check exit status too, in case message is shut off
  99              (`$cc_cmd /prefix=all _nla0:` =~ /IVQUAL/ || $? == 0x38240))
 100             or 0; # again, make debug output nice
 101   print "\$isgcc: $isgcc\n" if $debug;
 102   print "\$isvaxc: $isvaxc\n" if $debug;
 103   print "\$debugging_enabled: $debugging_enabled\n" if $debug;
 104
 105 }
 106 else {
 107   ($junk,$junk,$cpp_file,$cc_cmd) = split(/~~/,$cc_cmd,4);
 108   $isgcc = $cc_cmd =~ /case_hack/i
 109            or 0;  # for nice debug output
 110   $isvaxc = (!$isgcc && $cc_cmd !~ /standard=/i)
 111             or 0;  # again, for nice debug output
 112   $debugging_enabled = $cc_cmd =~ /\bdebugging\b/i;
 113   print "\$isgcc: \\$isgcc\\\n" if $debug;
 114   print "\$isvaxc: \\$isvaxc\\\n" if $debug;
 115   print "\$debugging_enabled: \\$debugging_enabled\\\n" if $debug;
 116   print "Not running cc, preprocesor output in \\$cpp_file\\\n" if $debug;
 117 }
 118
 119 $objsuffix = shift @ARGV;
 120 print "\$objsuffix: \\$objsuffix\\\n" if $debug;
 121 $dbgprefix = shift @ARGV;
 122 print "\$dbgprefix: \\$dbgprefix\\\n" if $debug;
 123 $olbsuffix = shift @ARGV;
 124 print "\$olbsuffix: \\$olbsuffix\\\n" if $debug;
 125 $libperl = "${dbgprefix}libperl$olbsuffix";
 126 $extnames = shift @ARGV;
 127 print "\$extnames: \\$extnames\\\n" if $debug;
 128 $rtlopt = shift @ARGV;
 129 print "\$rtlopt: \\$rtlopt\\\n" if $debug;
 130
 131 # This part gets tricky.  VAXC creates global symbols for each of the
 132 # constants in an enum if that enum is ever used as the data type of a
 133 # global[dr]ef.  We have to detect enums which are used in this way, so we
 134 # can set up the constants as universal symbols, since anything which
 135 # #includes perl.h will want to resolve these global symbols.
 136 # We're using a weak test here - we basically know that the only enums
 137 # we need to handle now are the big one in opcode.h, and the
 138 # "typedef enum { ... } expectation" in perl.h, so we hard code
 139 # appropriate tests below. Since we can't know in general whether a given
 140 # enum will be used elsewhere in a globaldef, it's hard to decide a
 141 # priori whether its constants need to be treated as global symbols.
 142 sub scan_enum {
 143   my($line) = @_;
 144
 145   return unless $isvaxc;
 146
 147   return unless /^\s+(OP|X)/;  # we only want opcode and expectation enums
 148   print "\tchecking for enum constant\n" if $debug > 1;
 149   $line =~ s#/\*.+##;
 150   $line =~ s/,?\s*\n?$//;
 151   print "\tfiltered to \\$line\\\n" if $debug > 1;
 152   if ($line =~ /(\w+)$/) {
 153     print "\tconstant name is \\$1\\\n" if $debug > 1;
 154     $enums{$1}++;
 155   }
 156 }
 157
 158 sub scan_var {
 159   my($line) = @_;
 160   my($const) = $line =~ /^EXTCONST/;
 161
 162   print "\tchecking for global variable\n" if $debug > 1;
 163   $line =~ s/\s*EXT/EXT/;
 164   $line =~ s/INIT\s*\(.*\)//;
 165   $line =~ s/\[.*//;
 166   $line =~ s/=.*//;
 167   $line =~ s/\W*;?\s*$//;
 168   $line =~ s/\W*\)\s*\(.*$//; # closing paren for args stripped in previous stmt
 169   print "\tfiltered to \\$line\\\n" if $debug > 1;
 170   if ($line =~ /(\w+)$/) {
 171     print "\tvar name is \\$1\\" . ($const ? ' (const)' : '') . "\n" if $debug > 1;
 172    if ($const) { $cvars{$1}++; }
 173    else        { $vars{$1}++;  }
 174   }
 175   if ($isvaxc) {
 176     my($type) = $line =~ /^\s*EXT\w*\s+(\w+)/;
 177     print "\tchecking for use of enum (type is \"$type\")\n" if $debug > 2;
 178     if ($type eq 'expectation') {
 179       $used_expectation_enum++;
 180       print "\tsaw global use of enum \"expectation\"\n" if $debug > 1;
 181     }
 182     if ($type eq 'opcode') {
 183       $used_opcode_enum++;
 184       print "\tsaw global use of enum \"opcode\"\n" if $debug > 1;
 185     }
 186   }
 187 }
 188
 189 sub scan_func {
 190   my($line) = @_;
 191
 192   print "\tchecking for global routine\n" if $debug > 1;
 193   if ( $line =~ /(\w+)\s*\(/ ) {
 194     print "\troutine name is \\$1\\\n" if $debug > 1;
 195     if ($1 eq 'main' || $1 eq 'perl_init_ext') {
 196       print "\tskipped\n" if $debug > 1;
 197     }
 198     else { $fcns{uc($1)}++ }
 199   }
 200 }
 201
 202 # Go add some right up front if we need 'em
 203 if ($use_mymalloc) {
 204   $fcns{uc('Perl_malloc')}++;
 205   $fcns{uc('Perl_calloc')}++;
 206   $fcns{uc('Perl_realloc')}++;
 207   $fcns{uc('Perl_mfree')}++;
 208 }
 209
 210 $used_expectation_enum = $used_opcode_enum = 0; # avoid warnings
 211 if ($docc) {
 212   open(CPP,"${cc_cmd}/NoObj/PreProc=Sys\$Output ${dir}perl.h|")
 213     or die "$0: Can't preprocess ${dir}perl.h: $!\n";
 214 }
 215 else {
 216   open(CPP,"$cpp_file") or die "$0: Can't read preprocessed file $cpp_file: $!\n";
 217 }
 218 %checkh = map { $_,1 } qw( thread bytecode byterun proto );
 219 $ckfunc = 0;
 220 LINE: while (<CPP>) {
 221   while (/^#.*vmsish\.h/i .. /^#.*perl\.h/i) {
 222     while (/__VMS_PROTOTYPES__/i .. /__VMS_SEPYTOTORP__/i) {
 223       print "vms_proto>> $_" if $debug > 2;
 224       if (/^\s*EXT/) { &scan_var($_);  }
 225       else        { &scan_func($_); }
 226       last LINE unless defined($_ = <CPP>);
 227     }
 228     print "vmsish.h>> $_" if $debug > 2;
 229     if (/^\s*EXT/) { &scan_var($_); }
 230     last LINE unless defined($_ = <CPP>);
 231   }
 232   while (/^#.*opcode\.h/i .. /^#.*perl\.h/i) {
 233     print "opcode.h>> $_" if $debug > 2;
 234     if (/^OP \*\s/) { &scan_func($_); }
 235     if (/^\s*EXT/) { &scan_var($_); }
 236     if (/^\s+OP_/) { &scan_enum($_); }
 237     last LINE unless defined($_ = <CPP>);
 238   }
 239   while (/^typedef enum/ .. /^\s*\}/) {
 240     print "global enum>> $_" if $debug > 2;
 241     &scan_enum($_);
 242     last LINE unless defined($_ = <CPP>);
 243   }
 244   # Check for transition to new header file
 245   if (/^# \d+ "(\S+)"/) {
 246     my $spec = $1;
 247     # Pull name from library module or header filespec
 248     $spec =~ /^(\w+)$/ or $spec =~ /(\w+)\.h/i;
 249     my $name = lc $1;
 250     $ckfunc = exists $checkh{$name} ? 1 : 0;
 251     $scanname = $name if $ckfunc;
 252     print "Header file transition: ckfunc = $ckfunc for $name.h\n" if $debug > 1;
 253   }
 254   if ($ckfunc) {
 255     print "$scanname>> $_" if $debug > 2;
 256     if (/\s*^EXT/) { &scan_var($_);  }
 257     else           { &scan_func($_); }
 258   }
 259   else {
 260     print $_ if $debug > 3 && ($debug > 5 || length($_));
 261     if (/^\s*EXT/) { &scan_var($_); }
 262   }
 263 }
 264 close CPP;
 265
 266 while (<DATA>) {
 267   next if /^#/;
 268   s/\s+#.*\n//;
 269   next if /^\s*$/;
 270   ($key,$array) = split('=',$_);
 271   if ($array eq 'vars') { $key = "PL_$key";   }
 272   else                  { $key = "Perl_$key"; }
 273   print "Adding $key to \%$array list\n" if $debug > 1;
 274   ${$array}{$key}++;
 275 }
 276 if ($debugging_enabled and $isgcc) { $vars{'colors'}++ }
 277 foreach (split /\s+/, $extnames) {
 278   my($pkgname) = $_;
 279   $pkgname =~ s/::/__/g;
 280   $fcns{"boot_$pkgname"}++;
 281   print "Adding boot_$pkgname to \%fcns (for extension $_)\n" if $debug;
 282 }
 283
 284 # If we're using VAXC, fold in the names of the constants for enums
 285 # we've seen as the type of global vars.
 286 if ($isvaxc) {
 287   foreach (keys %enums) {
 288     if (/^OP/) {
 289       $vars{$_}++ if $used_opcode_enum;
 290       next;
 291     }
 292     if (/^X/) {
 293       $vars{$_}++ if $used_expectation_enum;
 294       next;
 295     }
 296     print STDERR "Unrecognized enum constant \"$_\" ignored\n";
 297   }
 298 }
 299
 300 # Eventually, we'll check against existing copies here, so we can add new
 301 # symbols to an existing options file in an upwardly-compatible manner.
 302
 303 $marord++;
 304 open(OPTBLD,">${dir}${dbgprefix}perlshr_bld.opt")
 305   or die "$0: Can't write to ${dir}${dbgprefix}perlshr_bld.opt: $!\n";
 306 if ($isvax) {
 307   open(MAR,">${dir}perlshr_gbl${marord}.mar")
 308     or die "$0: Can't write to ${dir}perlshr_gbl${marord}.mar: $!\n";
 309   print MAR "\t.title perlshr_gbl$marord\n";
 310 }
 311
 312 unless ($isgcc) {
 313   print OPTBLD "PSECT_ATTR=\$GLOBAL_RO_VARS,PIC,NOEXE,RD,NOWRT,SHR\n";
 314   print OPTBLD "PSECT_ATTR=\$GLOBAL_RW_VARS,PIC,NOEXE,RD,WRT,NOSHR\n";
 315 }
 316 foreach $var (sort (keys %vars,keys %cvars)) {
 317   if ($isvax) { print OPTBLD "UNIVERSAL=$var\n"; }
 318   else { print OPTBLD "SYMBOL_VECTOR=($var=DATA)\n"; }
 319   # This hack brought to you by the lack of a globaldef in gcc.
 320   if ($isgcc) {
 321     if ($count++ > 200) {  # max 254 psects/file
 322       print MAR "\t.end\n";
 323       close MAR;
 324       $marord++;
 325       open(MAR,">${dir}perlshr_gbl${marord}.mar")
 326         or die "$0: Can't write to ${dir}perlshr_gbl${marord}.mar: $!\n";
 327       print MAR "\t.title perlshr_gbl$marord\n";
 328       $count = 0;
 329     }
 330     print MAR "\t.psect ${var},long,pic,ovr,rd,wrt,noexe,noshr\n";
 331     print MAR "\t${var}::       .blkl 1\n";
 332   }
 333 }
 334
 335 print MAR "\t.psect \$transfer_vec,pic,rd,nowrt,exe,shr\n" if ($isvax);
 336 foreach $func (sort keys %fcns) {
 337   if ($isvax) {
 338     print MAR "\t.transfer $func\n";
 339     print MAR "\t.mask $func\n";
 340     print MAR "\tjmp G\^${func}+2\n";
 341   }
 342   else { print OPTBLD "SYMBOL_VECTOR=($func=PROCEDURE)\n"; }
 343 }
 344 if ($isvax) {
 345   print MAR "\t.end\n";
 346   close MAR;
 347 }
 348
 349 open(OPTATTR,">${dir}perlshr_attr.opt")
 350   or die "$0: Can't write to ${dir}perlshr_attr.opt: $!\n";
 351 if ($isvaxc) {
 352   print OPTATTR "PSECT_ATTR=\$CHAR_STRING_CONSTANTS,PIC,SHR,NOEXE,RD,NOWRT\n";
 353 }
 354 elsif ($isgcc) {
 355   foreach $var (sort keys %cvars) {
 356     print OPTATTR "PSECT_ATTR=${var},PIC,OVR,RD,NOEXE,NOWRT,SHR\n";
 357   }
 358   foreach $var (sort keys %vars) {
 359     print OPTATTR "PSECT_ATTR=${var},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
 360   }
 361 }
 362 else {
 363   print OPTATTR "! No additional linker directives are needed when using DECC\n";
 364 }
 365 close OPTATTR;
 366
 367 $incstr = 'perl,globals';
 368 if ($isvax) {
 369   $drvrname = "Compile_shrmars.tmp_".time;
 370   open (DRVR,">$drvrname") or die "$0: Can't write to $drvrname: $!\n";
 371   print DRVR "\$ Set NoOn\n";
 372   print DRVR "\$ Delete/NoLog/NoConfirm $drvrname;\n";
 373   print DRVR "\$ old_proc_vfy = F\$Environment(\"VERIFY_PROCEDURE\")\n";
 374   print DRVR "\$ old_img_vfy = F\$Environment(\"VERIFY_IMAGE\")\n";
 375   print DRVR "\$ MCR $^X -e \"\$ENV{'LIBPERL_RDT'} = (stat('$libperl'))[9]\"\n";
 376   print DRVR "\$ Set Verify\n";
 377   print DRVR "\$ If F\$Search(\"$libperl\").eqs.\"\" Then Library/Object/Create $libperl\n";
 378   do {
 379     push(@symfiles,"perlshr_gbl$marord");
 380     print DRVR "\$ Macro/NoDebug/Object=PerlShr_Gbl${marord}$objsuffix PerlShr_Gbl$marord.Mar\n";
 381     print DRVR "\$ Library/Object/Replace/Log $libperl PerlShr_Gbl${marord}$objsuffix\n";
 382   } while (--$marord);
 383   # We had to have a working miniperl to run this program; it's probably the
 384   # one we just built.  It depended on LibPerl, which will be changed when
 385   # the PerlShr_Gbl* modules get inserted, so miniperl will be out of date,
 386   # and so, therefore, will all of its dependents . . .
 387   # We touch LibPerl here so it'll be back 'in date', and we won't rebuild
 388   # miniperl etc., and therefore LibPerl, the next time we invoke MM[KS].
 389   print DRVR "\$ old_proc_vfy = F\$Verify(old_proc_vfy,old_img_vfy)\n";
 390   print DRVR "\$ MCR $^X -e \"utime 0, \$ENV{'LIBPERL_RDT'}, '$libperl'\"\n";
 391   close DRVR;
 392 }
 393
 394 # Initial hack to permit building of compatible shareable images for a
 395 # given version of Perl.
 396 if ($ENV{PERLSHR_USE_GSMATCH}) {
 397   if ($ENV{PERLSHR_USE_GSMATCH} eq 'INCLUDE_COMPILE_OPTIONS') {
 398     # Build up a major ID. Since it can only be 8 bits, we encode the version
 399     # number in the top four bits and use the bottom four for build options
 400     # that'll cause incompatibilities
 401     ($ver, $sub) = $] =~ /\.(\d\d\d)(\d\d)/;
 402     $gsmatch = ($sub >= 50) ? "equal" : "lequal"; # Force an equal match for
 403                                                   # dev, but be more forgiving
 404                                                   # for releases
 405
 406     $ver *=16;
 407     $ver += 8 if $debugging_enabled;    # If DEBUGGING is set
 408     $ver += 4 if $use_threads;          # if we're threaded
 409     $ver += 2 if $use_mymalloc;         # if we're using perl's malloc
 410     print OPTBLD "GSMATCH=$gsmatch,$ver,$sub\n";
 411   }
 412   else {
 413     my $major = int($] * 1000)                        & 0xFF;  # range 0..255
 414     my $minor = int(($] * 1000 - $major) * 100 + 0.5) & 0xFF;  # range 0..255
 415     print OPTBLD "GSMATCH=LEQUAL,$major,$minor\n";
 416   }
 417   print OPTBLD 'CLUSTER=$$TRANSFER_VECTOR,,',
 418                map(",$_$objsuffix",@symfiles), "\n";
 419 }
 420 elsif (@symfiles) { $incstr .= ',' . join(',',@symfiles); }
 421 # Include object modules and RTLs in options file
 422 # Linker wants /Include and /Library on different lines
 423 print OPTBLD "$libperl/Include=($incstr)\n";
 424 print OPTBLD "$libperl/Library\n";
 425 open(RTLOPT,$rtlopt) or die "$0: Can't read options file $rtlopt: $!\n";
 426 while (<RTLOPT>) { print OPTBLD; }
 427 close RTLOPT;
 428 close OPTBLD;
 429
 430 exec "\$ \@$drvrname" if $isvax;
 431
 432
 433 __END__
 434
 435 # Oddball cases, so we can keep the perl.h scan above simple
 436 regkind=vars    # declared in regcomp.h
 437 simple=vars     # declared in regcomp.h
 438 varies=vars     # declared in regcomp.h