This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Updated HTTP::Tiny to CPAN version 0.010
[perl5.git] / cpan / HTTP-Tiny / t / 110_mirror.t
1 #!perl
2 #
3 # This file is part of HTTP-Tiny
4 #
5 # This software is copyright (c) 2011 by Christian Hansen.
6 #
7 # This is free software; you can redistribute it and/or modify it under
8 # the same terms as the Perl 5 programming language system itself.
9 #
10
11 use strict;
12 use warnings;
13
14 use File::Basename;
15 use Test::More 0.88;
16 use t::Util    qw[tmpfile rewind slurp monkey_patch dir_list parse_case
17                   set_socket_source sort_headers $CRLF $LF];
18 use HTTP::Tiny;
19 use File::Temp qw/tempdir/;
20 use File::Spec;
21
22 BEGIN { monkey_patch() }
23
24 my $tempdir = tempdir( TMPDIR => 1, CLEANUP => 1 );
25 my $tempfile = File::Spec->catfile( $tempdir, "tempfile.txt" );
26
27 my $known_epoch = 760233600;
28 my $day = 24*3600;
29
30 my %timestamp = (
31   'modified.txt'      => $known_epoch - 2 * $day,
32   'not-modified.txt'  => $known_epoch - 2 * $day,
33 );
34
35 for my $file ( dir_list("t/cases", qr/^mirror/ ) ) {
36   1 while unlink $tempfile;
37   my $data = do { local (@ARGV,$/) = $file; <> };
38   my ($params, $expect_req, $give_res) = split /--+\n/, $data;
39   # cleanup source data
40   my $version = HTTP::Tiny->VERSION || 0;
41   $expect_req =~ s{VERSION}{$version};
42   s{\n}{$CRLF}g for ($expect_req, $give_res);
43
44   # figure out what request to make
45   my $case = parse_case($params);
46   my $url = $case->{url}->[0];
47   my %options;
48
49   my %headers;
50   for my $line ( @{ $case->{headers} } ) {
51     my ($k,$v) = ($line =~ m{^([^:]+): (.*)$}g);
52     $headers{$k} = $v;
53   }
54   $options{headers} = \%headers if %headers;
55
56   # maybe create a file
57   (my $url_basename = $url) =~ s{.*/}{};
58   if ( my $mtime = $timestamp{$url_basename} ) {
59     open my $fh, ">", $tempfile;
60     close $fh;
61     utime $mtime, $mtime, $tempfile;
62   }
63
64   # setup mocking and test
65   my $res_fh = tmpfile($give_res);
66   my $req_fh = tmpfile();
67
68   my $http = HTTP::Tiny->new;
69   set_socket_source($req_fh, $res_fh);
70
71   my @call_args = %options ? ($url, $tempfile, \%options) : ($url, $tempfile);
72   my $response  = $http->mirror(@call_args);
73
74   my $got_req = slurp($req_fh);
75
76   my $label = basename($file);
77
78   is( sort_headers($got_req), sort_headers($expect_req), "$label request" );
79
80   my ($rc) = $give_res =~ m{\S+\s+(\d+)}g;
81   is( $response->{status}, $rc, "$label response code $rc" )
82     or diag $response->{content};
83
84   if ( substr($rc,0,1) eq '2' ) {
85     ok( $response->{success}, "$label success flag true" );
86     ok( -e $tempfile, "$label file created" );
87   }
88   elsif ( $rc eq '304' ) {
89     ok( $response->{success}, "$label success flag true" );
90     is( (stat($tempfile))[9], $timestamp{$url_basename},
91       "$label file not overwritten" );
92   }
93   else {
94     ok( ! $response->{success}, "$label success flag false" );
95     ok( ! -e $tempfile, "$label file not created" );
96   }
97 }
98
99 done_testing;