This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
447dad3fb1261330a9dd7aea5130d985d50033b1
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
370 test operators, in a way that C<-f -w -x $file> is equivalent to
371 C<-x $file && -w _ && -f _>. (This is only syntax fancy : if you use
372 the return value of C<-f $file> as an argument to another filetest
373 operator, no special magic will happen.)
374
375 =item abs VALUE
376
377 =item abs
378
379 Returns the absolute value of its argument.
380 If VALUE is omitted, uses C<$_>.
381
382 =item accept NEWSOCKET,GENERICSOCKET
383
384 Accepts an incoming socket connect, just as the accept(2) system call
385 does.  Returns the packed address if it succeeded, false otherwise.
386 See the example in L<perlipc/"Sockets: Client/Server Communication">.
387
388 On systems that support a close-on-exec flag on files, the flag will
389 be set for the newly opened file descriptor, as determined by the
390 value of $^F.  See L<perlvar/$^F>.
391
392 =item alarm SECONDS
393
394 =item alarm
395
396 Arranges to have a SIGALRM delivered to this process after the
397 specified number of wallclock seconds have elapsed.  If SECONDS is not
398 specified, the value stored in C<$_> is used. (On some machines,
399 unfortunately, the elapsed time may be up to one second less or more
400 than you specified because of how seconds are counted, and process
401 scheduling may delay the delivery of the signal even further.)
402
403 Only one timer may be counting at once.  Each call disables the
404 previous timer, and an argument of C<0> may be supplied to cancel the
405 previous timer without starting a new one.  The returned value is the
406 amount of time remaining on the previous timer.
407
408 For delays of finer granularity than one second, you may use Perl's
409 four-argument version of select() leaving the first three arguments
410 undefined, or you might be able to use the C<syscall> interface to
411 access setitimer(2) if your system supports it.  The Time::HiRes
412 module (from CPAN, and starting from Perl 5.8 part of the standard
413 distribution) may also prove useful.
414
415 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
416 (C<sleep> may be internally implemented in your system with C<alarm>)
417
418 If you want to use C<alarm> to time out a system call you need to use an
419 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
420 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
421 restart system calls on some systems.  Using C<eval>/C<die> always works,
422 modulo the caveats given in L<perlipc/"Signals">.
423
424     eval {
425         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
426         alarm $timeout;
427         $nread = sysread SOCKET, $buffer, $size;
428         alarm 0;
429     };
430     if ($@) {
431         die unless $@ eq "alarm\n";   # propagate unexpected errors
432         # timed out
433     }
434     else {
435         # didn't
436     }
437
438 For more information see L<perlipc>.
439
440 =item atan2 Y,X
441
442 Returns the arctangent of Y/X in the range -PI to PI.
443
444 For the tangent operation, you may use the C<Math::Trig::tan>
445 function, or use the familiar relation:
446
447     sub tan { sin($_[0]) / cos($_[0])  }
448
449 =item bind SOCKET,NAME
450
451 Binds a network address to a socket, just as the bind system call
452 does.  Returns true if it succeeded, false otherwise.  NAME should be a
453 packed address of the appropriate type for the socket.  See the examples in
454 L<perlipc/"Sockets: Client/Server Communication">.
455
456 =item binmode FILEHANDLE, LAYER
457
458 =item binmode FILEHANDLE
459
460 Arranges for FILEHANDLE to be read or written in "binary" or "text"
461 mode on systems where the run-time libraries distinguish between
462 binary and text files.  If FILEHANDLE is an expression, the value is
463 taken as the name of the filehandle.  Returns true on success,
464 otherwise it returns C<undef> and sets C<$!> (errno).
465
466 On some systems (in general, DOS and Windows-based systems) binmode()
467 is necessary when you're not working with a text file.  For the sake
468 of portability it is a good idea to always use it when appropriate,
469 and to never use it when it isn't appropriate.  Also, people can
470 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
471
472 In other words: regardless of platform, use binmode() on binary data,
473 like for example images.
474
475 If LAYER is present it is a single string, but may contain multiple
476 directives. The directives alter the behaviour of the file handle.
477 When LAYER is present using binmode on text file makes sense.
478
479 If LAYER is omitted or specified as C<:raw> the filehandle is made
480 suitable for passing binary data. This includes turning off possible CRLF
481 translation and marking it as bytes (as opposed to Unicode characters).
482 Note that, despite what may be implied in I<"Programming Perl"> (the
483 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
484 -- other layers which would affect binary nature of the stream are
485 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
486 PERLIO environment variable.
487
488 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
489 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
490 establish default I/O layers.  See L<open>.
491
492 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
493 in "Programming Perl, 3rd Edition".  However, since the publishing of this
494 book, by many known as "Camel III", the consensus of the naming of this
495 functionality has moved from "discipline" to "layer".  All documentation
496 of this version of Perl therefore refers to "layers" rather than to
497 "disciplines".  Now back to the regularly scheduled documentation...>
498
499 To mark FILEHANDLE as UTF-8, use C<:utf8>.
500
501 In general, binmode() should be called after open() but before any I/O
502 is done on the filehandle.  Calling binmode() will normally flush any
503 pending buffered output data (and perhaps pending input data) on the
504 handle.  An exception to this is the C<:encoding> layer that
505 changes the default character encoding of the handle, see L<open>.
506 The C<:encoding> layer sometimes needs to be called in
507 mid-stream, and it doesn't flush the stream.  The C<:encoding>
508 also implicitly pushes on top of itself the C<:utf8> layer because
509 internally Perl will operate on UTF-8 encoded Unicode characters.
510
511 The operating system, device drivers, C libraries, and Perl run-time
512 system all work together to let the programmer treat a single
513 character (C<\n>) as the line terminator, irrespective of the external
514 representation.  On many operating systems, the native text file
515 representation matches the internal representation, but on some
516 platforms the external representation of C<\n> is made up of more than
517 one character.
518
519 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
520 character to end each line in the external representation of text (even
521 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
522 on Unix and most VMS files). In other systems like OS/2, DOS and the
523 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
524 but what's stored in text files are the two characters C<\cM\cJ>.  That
525 means that, if you don't use binmode() on these systems, C<\cM\cJ>
526 sequences on disk will be converted to C<\n> on input, and any C<\n> in
527 your program will be converted back to C<\cM\cJ> on output.  This is what
528 you want for text files, but it can be disastrous for binary files.
529
530 Another consequence of using binmode() (on some systems) is that
531 special end-of-file markers will be seen as part of the data stream.
532 For systems from the Microsoft family this means that if your binary
533 data contains C<\cZ>, the I/O subsystem will regard it as the end of
534 the file, unless you use binmode().
535
536 binmode() is not only important for readline() and print() operations,
537 but also when using read(), seek(), sysread(), syswrite() and tell()
538 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
539 in L<perlvar> for how to manually set your input and output
540 line-termination sequences.
541
542 =item bless REF,CLASSNAME
543
544 =item bless REF
545
546 This function tells the thingy referenced by REF that it is now an object
547 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
548 is used.  Because a C<bless> is often the last thing in a constructor,
549 it returns the reference for convenience.  Always use the two-argument
550 version if the function doing the blessing might be inherited by a
551 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
552 (and blessings) of objects.
553
554 Consider always blessing objects in CLASSNAMEs that are mixed case.
555 Namespaces with all lowercase names are considered reserved for
556 Perl pragmata.  Builtin types have all uppercase names, so to prevent
557 confusion, you may wish to avoid such package names as well.  Make sure
558 that CLASSNAME is a true value.
559
560 See L<perlmod/"Perl Modules">.
561
562 =item caller EXPR
563
564 =item caller
565
566 Returns the context of the current subroutine call.  In scalar context,
567 returns the caller's package name if there is a caller, that is, if
568 we're in a subroutine or C<eval> or C<require>, and the undefined value
569 otherwise.  In list context, returns
570
571     ($package, $filename, $line) = caller;
572
573 With EXPR, it returns some extra information that the debugger uses to
574 print a stack trace.  The value of EXPR indicates how many call frames
575 to go back before the current one.
576
577     ($package, $filename, $line, $subroutine, $hasargs,
578     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
579
580 Here $subroutine may be C<(eval)> if the frame is not a subroutine
581 call, but an C<eval>.  In such a case additional elements $evaltext and
582 C<$is_require> are set: C<$is_require> is true if the frame is created by a
583 C<require> or C<use> statement, $evaltext contains the text of the
584 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
585 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
586 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
587 frame.)  $subroutine may also be C<(unknown)> if this particular
588 subroutine happens to have been deleted from the symbol table.
589 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
590 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
591 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
592 between versions of Perl, and are not meant for external use.
593
594 Furthermore, when called from within the DB package, caller returns more
595 detailed information: it sets the list variable C<@DB::args> to be the
596 arguments with which the subroutine was invoked.
597
598 Be aware that the optimizer might have optimized call frames away before
599 C<caller> had a chance to get the information.  That means that C<caller(N)>
600 might not return information about the call frame you expect it do, for
601 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
602 previous time C<caller> was called.
603
604 =item chdir EXPR
605
606 =item chdir
607
608 Changes the working directory to EXPR, if possible. If EXPR is omitted,
609 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
610 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
611 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
612 neither is set, C<chdir> does nothing. It returns true upon success,
613 false otherwise. See the example under C<die>.
614
615 =item chmod LIST
616
617 Changes the permissions of a list of files.  The first element of the
618 list must be the numerical mode, which should probably be an octal
619 number, and which definitely should I<not> be a string of octal digits:
620 C<0644> is okay, C<'0644'> is not.  Returns the number of files
621 successfully changed.  See also L</oct>, if all you have is a string.
622
623     $cnt = chmod 0755, 'foo', 'bar';
624     chmod 0755, @executables;
625     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
626                                              # --w----r-T
627     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
628     $mode = 0644;   chmod $mode, 'foo';      # this is best
629
630 You can also import the symbolic C<S_I*> constants from the Fcntl
631 module:
632
633     use Fcntl ':mode';
634
635     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
636     # This is identical to the chmod 0755 of the above example.
637
638 =item chomp VARIABLE
639
640 =item chomp( LIST )
641
642 =item chomp
643
644 This safer version of L</chop> removes any trailing string
645 that corresponds to the current value of C<$/> (also known as
646 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
647 number of characters removed from all its arguments.  It's often used to
648 remove the newline from the end of an input record when you're worried
649 that the final record may be missing its newline.  When in paragraph
650 mode (C<$/ = "">), it removes all trailing newlines from the string.
651 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
652 a reference to an integer or the like, see L<perlvar>) chomp() won't
653 remove anything.
654 If VARIABLE is omitted, it chomps C<$_>.  Example:
655
656     while (<>) {
657         chomp;  # avoid \n on last field
658         @array = split(/:/);
659         # ...
660     }
661
662 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
663
664 You can actually chomp anything that's an lvalue, including an assignment:
665
666     chomp($cwd = `pwd`);
667     chomp($answer = <STDIN>);
668
669 If you chomp a list, each element is chomped, and the total number of
670 characters removed is returned.
671
672 If the C<encoding> pragma is in scope then the lengths returned are
673 calculated from the length of C<$/> in Unicode characters, which is not
674 always the same as the length of C<$/> in the native encoding.
675
676 Note that parentheses are necessary when you're chomping anything
677 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
678 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
679 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
680 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
681 as C<chomp($a, $b)>.
682
683 =item chop VARIABLE
684
685 =item chop( LIST )
686
687 =item chop
688
689 Chops off the last character of a string and returns the character
690 chopped.  It is much more efficient than C<s/.$//s> because it neither
691 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
692 If VARIABLE is a hash, it chops the hash's values, but not its keys.
693
694 You can actually chop anything that's an lvalue, including an assignment.
695
696 If you chop a list, each element is chopped.  Only the value of the
697 last C<chop> is returned.
698
699 Note that C<chop> returns the last character.  To return all but the last
700 character, use C<substr($string, 0, -1)>.
701
702 See also L</chomp>.
703
704 =item chown LIST
705
706 Changes the owner (and group) of a list of files.  The first two
707 elements of the list must be the I<numeric> uid and gid, in that
708 order.  A value of -1 in either position is interpreted by most
709 systems to leave that value unchanged.  Returns the number of files
710 successfully changed.
711
712     $cnt = chown $uid, $gid, 'foo', 'bar';
713     chown $uid, $gid, @filenames;
714
715 Here's an example that looks up nonnumeric uids in the passwd file:
716
717     print "User: ";
718     chomp($user = <STDIN>);
719     print "Files: ";
720     chomp($pattern = <STDIN>);
721
722     ($login,$pass,$uid,$gid) = getpwnam($user)
723         or die "$user not in passwd file";
724
725     @ary = glob($pattern);      # expand filenames
726     chown $uid, $gid, @ary;
727
728 On most systems, you are not allowed to change the ownership of the
729 file unless you're the superuser, although you should be able to change
730 the group to any of your secondary groups.  On insecure systems, these
731 restrictions may be relaxed, but this is not a portable assumption.
732 On POSIX systems, you can detect this condition this way:
733
734     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
735     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
736
737 =item chr NUMBER
738
739 =item chr
740
741 Returns the character represented by that NUMBER in the character set.
742 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
743 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
744 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
745 backward compatibility reasons (but see L<encoding>).
746
747 Negative values give the Unicode replacement character (chr(0xfffd)),
748 except under the L</bytes> pragma, where low eight bits of the value
749 (truncated to an integer) are used.
750
751 If NUMBER is omitted, uses C<$_>.
752
753 For the reverse, use L</ord>.
754
755 Note that under the C<bytes> pragma the NUMBER is masked to
756 the low eight bits.
757
758 See L<perlunicode> and L<encoding> for more about Unicode.
759
760 =item chroot FILENAME
761
762 =item chroot
763
764 This function works like the system call by the same name: it makes the
765 named directory the new root directory for all further pathnames that
766 begin with a C</> by your process and all its children.  (It doesn't
767 change your current working directory, which is unaffected.)  For security
768 reasons, this call is restricted to the superuser.  If FILENAME is
769 omitted, does a C<chroot> to C<$_>.
770
771 =item close FILEHANDLE
772
773 =item close
774
775 Closes the file or pipe associated with the file handle, returning
776 true only if IO buffers are successfully flushed and closes the system
777 file descriptor.  Closes the currently selected filehandle if the
778 argument is omitted.
779
780 You don't have to close FILEHANDLE if you are immediately going to do
781 another C<open> on it, because C<open> will close it for you.  (See
782 C<open>.)  However, an explicit C<close> on an input file resets the line
783 counter (C<$.>), while the implicit close done by C<open> does not.
784
785 If the file handle came from a piped open, C<close> will additionally
786 return false if one of the other system calls involved fails, or if the
787 program exits with non-zero status.  (If the only problem was that the
788 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
789 also waits for the process executing on the pipe to complete, in case you
790 want to look at the output of the pipe afterwards, and
791 implicitly puts the exit status value of that command into C<$?> and
792 C<${^CHILD_ERROR_NATIVE}>.
793
794 Prematurely closing the read end of a pipe (i.e. before the process
795 writing to it at the other end has closed it) will result in a
796 SIGPIPE being delivered to the writer.  If the other end can't
797 handle that, be sure to read all the data before closing the pipe.
798
799 Example:
800
801     open(OUTPUT, '|sort >foo')  # pipe to sort
802         or die "Can't start sort: $!";
803     #...                        # print stuff to output
804     close OUTPUT                # wait for sort to finish
805         or warn $! ? "Error closing sort pipe: $!"
806                    : "Exit status $? from sort";
807     open(INPUT, 'foo')          # get sort's results
808         or die "Can't open 'foo' for input: $!";
809
810 FILEHANDLE may be an expression whose value can be used as an indirect
811 filehandle, usually the real filehandle name.
812
813 =item closedir DIRHANDLE
814
815 Closes a directory opened by C<opendir> and returns the success of that
816 system call.
817
818 =item connect SOCKET,NAME
819
820 Attempts to connect to a remote socket, just as the connect system call
821 does.  Returns true if it succeeded, false otherwise.  NAME should be a
822 packed address of the appropriate type for the socket.  See the examples in
823 L<perlipc/"Sockets: Client/Server Communication">.
824
825 =item continue BLOCK
826
827 Actually a flow control statement rather than a function.  If there is a
828 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
829 C<foreach>), it is always executed just before the conditional is about to
830 be evaluated again, just like the third part of a C<for> loop in C.  Thus
831 it can be used to increment a loop variable, even when the loop has been
832 continued via the C<next> statement (which is similar to the C C<continue>
833 statement).
834
835 C<last>, C<next>, or C<redo> may appear within a C<continue>
836 block.  C<last> and C<redo> will behave as if they had been executed within
837 the main block.  So will C<next>, but since it will execute a C<continue>
838 block, it may be more entertaining.
839
840     while (EXPR) {
841         ### redo always comes here
842         do_something;
843     } continue {
844         ### next always comes here
845         do_something_else;
846         # then back the top to re-check EXPR
847     }
848     ### last always comes here
849
850 Omitting the C<continue> section is semantically equivalent to using an
851 empty one, logically enough.  In that case, C<next> goes directly back
852 to check the condition at the top of the loop.
853
854 =item cos EXPR
855
856 =item cos
857
858 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
859 takes cosine of C<$_>.
860
861 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
862 function, or use this relation:
863
864     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
865
866 =item crypt PLAINTEXT,SALT
867
868 Encrypts a string exactly like the crypt(3) function in the C library
869 (assuming that you actually have a version there that has not been
870 extirpated as a potential munition).  This can prove useful for checking
871 the password file for lousy passwords, amongst other things.  Only the
872 guys wearing white hats should do this.
873
874 Note that L<crypt|/crypt> is intended to be a one-way function, much like
875 breaking eggs to make an omelette.  There is no (known) corresponding
876 decrypt function (in other words, the crypt() is a one-way hash
877 function).  As a result, this function isn't all that useful for
878 cryptography.  (For that, see your nearby CPAN mirror.)
879
880 When verifying an existing encrypted string you should use the
881 encrypted text as the salt (like C<crypt($plain, $crypted) eq
882 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
883 and with more exotic implementations.  In other words, do not assume
884 anything about the returned string itself, or how many bytes in
885 the encrypted string matter.
886
887 Traditionally the result is a string of 13 bytes: two first bytes of
888 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
889 the first eight bytes of the encrypted string mattered, but
890 alternative hashing schemes (like MD5), higher level security schemes
891 (like C2), and implementations on non-UNIX platforms may produce
892 different strings.
893
894 When choosing a new salt create a random two character string whose
895 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
896 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
897 characters is just a recommendation; the characters allowed in
898 the salt depend solely on your system's crypt library, and Perl can't
899 restrict what salts C<crypt()> accepts.
900
901 Here's an example that makes sure that whoever runs this program knows
902 their own password:
903
904     $pwd = (getpwuid($<))[1];
905
906     system "stty -echo";
907     print "Password: ";
908     chomp($word = <STDIN>);
909     print "\n";
910     system "stty echo";
911
912     if (crypt($word, $pwd) ne $pwd) {
913         die "Sorry...\n";
914     } else {
915         print "ok\n";
916     }
917
918 Of course, typing in your own password to whoever asks you
919 for it is unwise.
920
921 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
922 of data, not least of all because you can't get the information
923 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
924 on your favorite CPAN mirror for a slew of potentially useful
925 modules.
926
927 If using crypt() on a Unicode string (which I<potentially> has
928 characters with codepoints above 255), Perl tries to make sense
929 of the situation by trying to downgrade (a copy of the string)
930 the string back to an eight-bit byte string before calling crypt()
931 (on that copy).  If that works, good.  If not, crypt() dies with
932 C<Wide character in crypt>.
933
934 =item dbmclose HASH
935
936 [This function has been largely superseded by the C<untie> function.]
937
938 Breaks the binding between a DBM file and a hash.
939
940 =item dbmopen HASH,DBNAME,MASK
941
942 [This function has been largely superseded by the C<tie> function.]
943
944 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
945 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
946 argument is I<not> a filehandle, even though it looks like one).  DBNAME
947 is the name of the database (without the F<.dir> or F<.pag> extension if
948 any).  If the database does not exist, it is created with protection
949 specified by MASK (as modified by the C<umask>).  If your system supports
950 only the older DBM functions, you may perform only one C<dbmopen> in your
951 program.  In older versions of Perl, if your system had neither DBM nor
952 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
953 sdbm(3).
954
955 If you don't have write access to the DBM file, you can only read hash
956 variables, not set them.  If you want to test whether you can write,
957 either use file tests or try setting a dummy hash entry inside an C<eval>,
958 which will trap the error.
959
960 Note that functions such as C<keys> and C<values> may return huge lists
961 when used on large DBM files.  You may prefer to use the C<each>
962 function to iterate over large DBM files.  Example:
963
964     # print out history file offsets
965     dbmopen(%HIST,'/usr/lib/news/history',0666);
966     while (($key,$val) = each %HIST) {
967         print $key, ' = ', unpack('L',$val), "\n";
968     }
969     dbmclose(%HIST);
970
971 See also L<AnyDBM_File> for a more general description of the pros and
972 cons of the various dbm approaches, as well as L<DB_File> for a particularly
973 rich implementation.
974
975 You can control which DBM library you use by loading that library
976 before you call dbmopen():
977
978     use DB_File;
979     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
980         or die "Can't open netscape history file: $!";
981
982 =item defined EXPR
983
984 =item defined
985
986 Returns a Boolean value telling whether EXPR has a value other than
987 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
988 checked.
989
990 Many operations return C<undef> to indicate failure, end of file,
991 system error, uninitialized variable, and other exceptional
992 conditions.  This function allows you to distinguish C<undef> from
993 other values.  (A simple Boolean test will not distinguish among
994 C<undef>, zero, the empty string, and C<"0">, which are all equally
995 false.)  Note that since C<undef> is a valid scalar, its presence
996 doesn't I<necessarily> indicate an exceptional condition: C<pop>
997 returns C<undef> when its argument is an empty array, I<or> when the
998 element to return happens to be C<undef>.
999
1000 You may also use C<defined(&func)> to check whether subroutine C<&func>
1001 has ever been defined.  The return value is unaffected by any forward
1002 declarations of C<&func>.  Note that a subroutine which is not defined
1003 may still be callable: its package may have an C<AUTOLOAD> method that
1004 makes it spring into existence the first time that it is called -- see
1005 L<perlsub>.
1006
1007 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1008 used to report whether memory for that aggregate has ever been
1009 allocated.  This behavior may disappear in future versions of Perl.
1010 You should instead use a simple test for size:
1011
1012     if (@an_array) { print "has array elements\n" }
1013     if (%a_hash)   { print "has hash members\n"   }
1014
1015 When used on a hash element, it tells you whether the value is defined,
1016 not whether the key exists in the hash.  Use L</exists> for the latter
1017 purpose.
1018
1019 Examples:
1020
1021     print if defined $switch{'D'};
1022     print "$val\n" while defined($val = pop(@ary));
1023     die "Can't readlink $sym: $!"
1024         unless defined($value = readlink $sym);
1025     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1026     $debugging = 0 unless defined $debugging;
1027
1028 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1029 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1030 defined values.  For example, if you say
1031
1032     "ab" =~ /a(.*)b/;
1033
1034 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1035 matched "nothing".  But it didn't really match nothing--rather, it
1036 matched something that happened to be zero characters long.  This is all
1037 very above-board and honest.  When a function returns an undefined value,
1038 it's an admission that it couldn't give you an honest answer.  So you
1039 should use C<defined> only when you're questioning the integrity of what
1040 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1041 what you want.
1042
1043 See also L</undef>, L</exists>, L</ref>.
1044
1045 =item delete EXPR
1046
1047 Given an expression that specifies a hash element, array element, hash slice,
1048 or array slice, deletes the specified element(s) from the hash or array.
1049 In the case of an array, if the array elements happen to be at the end,
1050 the size of the array will shrink to the highest element that tests
1051 true for exists() (or 0 if no such element exists).
1052
1053 Returns a list with the same number of elements as the number of elements
1054 for which deletion was attempted.  Each element of that list consists of
1055 either the value of the element deleted, or the undefined value.  In scalar
1056 context, this means that you get the value of the last element deleted (or
1057 the undefined value if that element did not exist).
1058
1059     %hash = (foo => 11, bar => 22, baz => 33);
1060     $scalar = delete $hash{foo};             # $scalar is 11
1061     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1062     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1063
1064 Deleting from C<%ENV> modifies the environment.  Deleting from
1065 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1066 from a C<tie>d hash or array may not necessarily return anything.
1067
1068 Deleting an array element effectively returns that position of the array
1069 to its initial, uninitialized state.  Subsequently testing for the same
1070 element with exists() will return false.  Note that deleting array
1071 elements in the middle of an array will not shift the index of the ones
1072 after them down--use splice() for that.  See L</exists>.
1073
1074 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1075
1076     foreach $key (keys %HASH) {
1077         delete $HASH{$key};
1078     }
1079
1080     foreach $index (0 .. $#ARRAY) {
1081         delete $ARRAY[$index];
1082     }
1083
1084 And so do these:
1085
1086     delete @HASH{keys %HASH};
1087
1088     delete @ARRAY[0 .. $#ARRAY];
1089
1090 But both of these are slower than just assigning the empty list
1091 or undefining %HASH or @ARRAY:
1092
1093     %HASH = ();         # completely empty %HASH
1094     undef %HASH;        # forget %HASH ever existed
1095
1096     @ARRAY = ();        # completely empty @ARRAY
1097     undef @ARRAY;       # forget @ARRAY ever existed
1098
1099 Note that the EXPR can be arbitrarily complicated as long as the final
1100 operation is a hash element, array element,  hash slice, or array slice
1101 lookup:
1102
1103     delete $ref->[$x][$y]{$key};
1104     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1105
1106     delete $ref->[$x][$y][$index];
1107     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1108
1109 =item die LIST
1110
1111 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1112 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1113 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1114 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1115 an C<eval(),> the error message is stuffed into C<$@> and the
1116 C<eval> is terminated with the undefined value.  This makes
1117 C<die> the way to raise an exception.
1118
1119 Equivalent examples:
1120
1121     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1122     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1123
1124 If the last element of LIST does not end in a newline, the current
1125 script line number and input line number (if any) are also printed,
1126 and a newline is supplied.  Note that the "input line number" (also
1127 known as "chunk") is subject to whatever notion of "line" happens to
1128 be currently in effect, and is also available as the special variable
1129 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1130
1131 Hint: sometimes appending C<", stopped"> to your message will cause it
1132 to make better sense when the string C<"at foo line 123"> is appended.
1133 Suppose you are running script "canasta".
1134
1135     die "/etc/games is no good";
1136     die "/etc/games is no good, stopped";
1137
1138 produce, respectively
1139
1140     /etc/games is no good at canasta line 123.
1141     /etc/games is no good, stopped at canasta line 123.
1142
1143 See also exit(), warn(), and the Carp module.
1144
1145 If LIST is empty and C<$@> already contains a value (typically from a
1146 previous eval) that value is reused after appending C<"\t...propagated">.
1147 This is useful for propagating exceptions:
1148
1149     eval { ... };
1150     die unless $@ =~ /Expected exception/;
1151
1152 If LIST is empty and C<$@> contains an object reference that has a
1153 C<PROPAGATE> method, that method will be called with additional file
1154 and line number parameters.  The return value replaces the value in
1155 C<$@>.  ie. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1156 were called.
1157
1158 If C<$@> is empty then the string C<"Died"> is used.
1159
1160 die() can also be called with a reference argument.  If this happens to be
1161 trapped within an eval(), $@ contains the reference.  This behavior permits
1162 a more elaborate exception handling implementation using objects that
1163 maintain arbitrary state about the nature of the exception.  Such a scheme
1164 is sometimes preferable to matching particular string values of $@ using
1165 regular expressions.  Here's an example:
1166
1167     use Scalar::Util 'blessed';
1168
1169     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1170     if ($@) {
1171         if (blessed($@) && $@->isa("Some::Module::Exception")) {
1172             # handle Some::Module::Exception
1173         }
1174         else {
1175             # handle all other possible exceptions
1176         }
1177     }
1178
1179 Because perl will stringify uncaught exception messages before displaying
1180 them, you may want to overload stringification operations on such custom
1181 exception objects.  See L<overload> for details about that.
1182
1183 You can arrange for a callback to be run just before the C<die>
1184 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1185 handler will be called with the error text and can change the error
1186 message, if it sees fit, by calling C<die> again.  See
1187 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1188 L<"eval BLOCK"> for some examples.  Although this feature was meant
1189 to be run only right before your program was to exit, this is not
1190 currently the case--the C<$SIG{__DIE__}> hook is currently called
1191 even inside eval()ed blocks/strings!  If one wants the hook to do
1192 nothing in such situations, put
1193
1194         die @_ if $^S;
1195
1196 as the first line of the handler (see L<perlvar/$^S>).  Because
1197 this promotes strange action at a distance, this counterintuitive
1198 behavior may be fixed in a future release.
1199
1200 =item do BLOCK
1201
1202 Not really a function.  Returns the value of the last command in the
1203 sequence of commands indicated by BLOCK.  When modified by a loop
1204 modifier, executes the BLOCK once before testing the loop condition.
1205 (On other statements the loop modifiers test the conditional first.)
1206
1207 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1208 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1209 See L<perlsyn> for alternative strategies.
1210
1211 =item do SUBROUTINE(LIST)
1212
1213 A deprecated form of subroutine call.  See L<perlsub>.
1214
1215 =item do EXPR
1216
1217 Uses the value of EXPR as a filename and executes the contents of the
1218 file as a Perl script.
1219
1220     do 'stat.pl';
1221
1222 is just like
1223
1224     eval `cat stat.pl`;
1225
1226 except that it's more efficient and concise, keeps track of the current
1227 filename for error messages, searches the @INC directories, and updates
1228 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1229 variables.  It also differs in that code evaluated with C<do FILENAME>
1230 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1231 same, however, in that it does reparse the file every time you call it,
1232 so you probably don't want to do this inside a loop.
1233
1234 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1235 error.  If C<do> can read the file but cannot compile it, it
1236 returns undef and sets an error message in C<$@>.   If the file is
1237 successfully compiled, C<do> returns the value of the last expression
1238 evaluated.
1239
1240 Note that inclusion of library modules is better done with the
1241 C<use> and C<require> operators, which also do automatic error checking
1242 and raise an exception if there's a problem.
1243
1244 You might like to use C<do> to read in a program configuration
1245 file.  Manual error checking can be done this way:
1246
1247     # read in config files: system first, then user
1248     for $file ("/share/prog/defaults.rc",
1249                "$ENV{HOME}/.someprogrc")
1250    {
1251         unless ($return = do $file) {
1252             warn "couldn't parse $file: $@" if $@;
1253             warn "couldn't do $file: $!"    unless defined $return;
1254             warn "couldn't run $file"       unless $return;
1255         }
1256     }
1257
1258 =item dump LABEL
1259
1260 =item dump
1261
1262 This function causes an immediate core dump.  See also the B<-u>
1263 command-line switch in L<perlrun>, which does the same thing.
1264 Primarily this is so that you can use the B<undump> program (not
1265 supplied) to turn your core dump into an executable binary after
1266 having initialized all your variables at the beginning of the
1267 program.  When the new binary is executed it will begin by executing
1268 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1269 Think of it as a goto with an intervening core dump and reincarnation.
1270 If C<LABEL> is omitted, restarts the program from the top.
1271
1272 B<WARNING>: Any files opened at the time of the dump will I<not>
1273 be open any more when the program is reincarnated, with possible
1274 resulting confusion on the part of Perl.
1275
1276 This function is now largely obsolete, partly because it's very
1277 hard to convert a core file into an executable, and because the
1278 real compiler backends for generating portable bytecode and compilable
1279 C code have superseded it.  That's why you should now invoke it as
1280 C<CORE::dump()>, if you don't want to be warned against a possible
1281 typo.
1282
1283 If you're looking to use L<dump> to speed up your program, consider
1284 generating bytecode or native C code as described in L<perlcc>.  If
1285 you're just trying to accelerate a CGI script, consider using the
1286 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1287 You might also consider autoloading or selfloading, which at least
1288 make your program I<appear> to run faster.
1289
1290 =item each HASH
1291
1292 When called in list context, returns a 2-element list consisting of the
1293 key and value for the next element of a hash, so that you can iterate over
1294 it.  When called in scalar context, returns only the key for the next
1295 element in the hash.
1296
1297 Entries are returned in an apparently random order.  The actual random
1298 order is subject to change in future versions of perl, but it is
1299 guaranteed to be in the same order as either the C<keys> or C<values>
1300 function would produce on the same (unmodified) hash.  Since Perl
1301 5.8.1 the ordering is different even between different runs of Perl
1302 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1303
1304 When the hash is entirely read, a null array is returned in list context
1305 (which when assigned produces a false (C<0>) value), and C<undef> in
1306 scalar context.  The next call to C<each> after that will start iterating
1307 again.  There is a single iterator for each hash, shared by all C<each>,
1308 C<keys>, and C<values> function calls in the program; it can be reset by
1309 reading all the elements from the hash, or by evaluating C<keys HASH> or
1310 C<values HASH>.  If you add or delete elements of a hash while you're
1311 iterating over it, you may get entries skipped or duplicated, so
1312 don't.  Exception: It is always safe to delete the item most recently
1313 returned by C<each()>, which means that the following code will work:
1314
1315         while (($key, $value) = each %hash) {
1316           print $key, "\n";
1317           delete $hash{$key};   # This is safe
1318         }
1319
1320 The following prints out your environment like the printenv(1) program,
1321 only in a different order:
1322
1323     while (($key,$value) = each %ENV) {
1324         print "$key=$value\n";
1325     }
1326
1327 See also C<keys>, C<values> and C<sort>.
1328
1329 =item eof FILEHANDLE
1330
1331 =item eof ()
1332
1333 =item eof
1334
1335 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1336 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1337 gives the real filehandle.  (Note that this function actually
1338 reads a character and then C<ungetc>s it, so isn't very useful in an
1339 interactive context.)  Do not read from a terminal file (or call
1340 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1341 as terminals may lose the end-of-file condition if you do.
1342
1343 An C<eof> without an argument uses the last file read.  Using C<eof()>
1344 with empty parentheses is very different.  It refers to the pseudo file
1345 formed from the files listed on the command line and accessed via the
1346 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1347 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1348 used will cause C<@ARGV> to be examined to determine if input is
1349 available.   Similarly, an C<eof()> after C<< <> >> has returned
1350 end-of-file will assume you are processing another C<@ARGV> list,
1351 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1352 see L<perlop/"I/O Operators">.
1353
1354 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1355 detect the end of each file, C<eof()> will only detect the end of the
1356 last file.  Examples:
1357
1358     # reset line numbering on each input file
1359     while (<>) {
1360         next if /^\s*#/;        # skip comments
1361         print "$.\t$_";
1362     } continue {
1363         close ARGV  if eof;     # Not eof()!
1364     }
1365
1366     # insert dashes just before last line of last file
1367     while (<>) {
1368         if (eof()) {            # check for end of last file
1369             print "--------------\n";
1370         }
1371         print;
1372         last if eof();          # needed if we're reading from a terminal
1373     }
1374
1375 Practical hint: you almost never need to use C<eof> in Perl, because the
1376 input operators typically return C<undef> when they run out of data, or if
1377 there was an error.
1378
1379 =item eval EXPR
1380
1381 =item eval BLOCK
1382
1383 =item eval
1384
1385 In the first form, the return value of EXPR is parsed and executed as if it
1386 were a little Perl program.  The value of the expression (which is itself
1387 determined within scalar context) is first parsed, and if there weren't any
1388 errors, executed in the lexical context of the current Perl program, so
1389 that any variable settings or subroutine and format definitions remain
1390 afterwards.  Note that the value is parsed every time the eval executes.
1391 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1392 delay parsing and subsequent execution of the text of EXPR until run time.
1393
1394 In the second form, the code within the BLOCK is parsed only once--at the
1395 same time the code surrounding the eval itself was parsed--and executed
1396 within the context of the current Perl program.  This form is typically
1397 used to trap exceptions more efficiently than the first (see below), while
1398 also providing the benefit of checking the code within BLOCK at compile
1399 time.
1400
1401 The final semicolon, if any, may be omitted from the value of EXPR or within
1402 the BLOCK.
1403
1404 In both forms, the value returned is the value of the last expression
1405 evaluated inside the mini-program; a return statement may be also used, just
1406 as with subroutines.  The expression providing the return value is evaluated
1407 in void, scalar, or list context, depending on the context of the eval itself.
1408 See L</wantarray> for more on how the evaluation context can be determined.
1409
1410 If there is a syntax error or runtime error, or a C<die> statement is
1411 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1412 error message.  If there was no error, C<$@> is guaranteed to be a null
1413 string.  Beware that using C<eval> neither silences perl from printing
1414 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1415 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1416 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1417 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1418
1419 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1420 determining whether a particular feature (such as C<socket> or C<symlink>)
1421 is implemented.  It is also Perl's exception trapping mechanism, where
1422 the die operator is used to raise exceptions.
1423
1424 If the code to be executed doesn't vary, you may use the eval-BLOCK
1425 form to trap run-time errors without incurring the penalty of
1426 recompiling each time.  The error, if any, is still returned in C<$@>.
1427 Examples:
1428
1429     # make divide-by-zero nonfatal
1430     eval { $answer = $a / $b; }; warn $@ if $@;
1431
1432     # same thing, but less efficient
1433     eval '$answer = $a / $b'; warn $@ if $@;
1434
1435     # a compile-time error
1436     eval { $answer = };                 # WRONG
1437
1438     # a run-time error
1439     eval '$answer =';   # sets $@
1440
1441 Due to the current arguably broken state of C<__DIE__> hooks, when using
1442 the C<eval{}> form as an exception trap in libraries, you may wish not
1443 to trigger any C<__DIE__> hooks that user code may have installed.
1444 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1445 as shown in this example:
1446
1447     # a very private exception trap for divide-by-zero
1448     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1449     warn $@ if $@;
1450
1451 This is especially significant, given that C<__DIE__> hooks can call
1452 C<die> again, which has the effect of changing their error messages:
1453
1454     # __DIE__ hooks may modify error messages
1455     {
1456        local $SIG{'__DIE__'} =
1457               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1458        eval { die "foo lives here" };
1459        print $@ if $@;                # prints "bar lives here"
1460     }
1461
1462 Because this promotes action at a distance, this counterintuitive behavior
1463 may be fixed in a future release.
1464
1465 With an C<eval>, you should be especially careful to remember what's
1466 being looked at when:
1467
1468     eval $x;            # CASE 1
1469     eval "$x";          # CASE 2
1470
1471     eval '$x';          # CASE 3
1472     eval { $x };        # CASE 4
1473
1474     eval "\$$x++";      # CASE 5
1475     $$x++;              # CASE 6
1476
1477 Cases 1 and 2 above behave identically: they run the code contained in
1478 the variable $x.  (Although case 2 has misleading double quotes making
1479 the reader wonder what else might be happening (nothing is).)  Cases 3
1480 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1481 does nothing but return the value of $x.  (Case 4 is preferred for
1482 purely visual reasons, but it also has the advantage of compiling at
1483 compile-time instead of at run-time.)  Case 5 is a place where
1484 normally you I<would> like to use double quotes, except that in this
1485 particular situation, you can just use symbolic references instead, as
1486 in case 6.
1487
1488 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1489 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1490
1491 Note that as a very special case, an C<eval ''> executed within the C<DB>
1492 package doesn't see the usual surrounding lexical scope, but rather the
1493 scope of the first non-DB piece of code that called it. You don't normally
1494 need to worry about this unless you are writing a Perl debugger.
1495
1496 =item exec LIST
1497
1498 =item exec PROGRAM LIST
1499
1500 The C<exec> function executes a system command I<and never returns>--
1501 use C<system> instead of C<exec> if you want it to return.  It fails and
1502 returns false only if the command does not exist I<and> it is executed
1503 directly instead of via your system's command shell (see below).
1504
1505 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1506 warns you if there is a following statement which isn't C<die>, C<warn>,
1507 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1508 I<really> want to follow an C<exec> with some other statement, you
1509 can use one of these styles to avoid the warning:
1510
1511     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1512     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1513
1514 If there is more than one argument in LIST, or if LIST is an array
1515 with more than one value, calls execvp(3) with the arguments in LIST.
1516 If there is only one scalar argument or an array with one element in it,
1517 the argument is checked for shell metacharacters, and if there are any,
1518 the entire argument is passed to the system's command shell for parsing
1519 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1520 If there are no shell metacharacters in the argument, it is split into
1521 words and passed directly to C<execvp>, which is more efficient.
1522 Examples:
1523
1524     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1525     exec "sort $outfile | uniq";
1526
1527 If you don't really want to execute the first argument, but want to lie
1528 to the program you are executing about its own name, you can specify
1529 the program you actually want to run as an "indirect object" (without a
1530 comma) in front of the LIST.  (This always forces interpretation of the
1531 LIST as a multivalued list, even if there is only a single scalar in
1532 the list.)  Example:
1533
1534     $shell = '/bin/csh';
1535     exec $shell '-sh';          # pretend it's a login shell
1536
1537 or, more directly,
1538
1539     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1540
1541 When the arguments get executed via the system shell, results will
1542 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1543 for details.
1544
1545 Using an indirect object with C<exec> or C<system> is also more
1546 secure.  This usage (which also works fine with system()) forces
1547 interpretation of the arguments as a multivalued list, even if the
1548 list had just one argument.  That way you're safe from the shell
1549 expanding wildcards or splitting up words with whitespace in them.
1550
1551     @args = ( "echo surprise" );
1552
1553     exec @args;               # subject to shell escapes
1554                                 # if @args == 1
1555     exec { $args[0] } @args;  # safe even with one-arg list
1556
1557 The first version, the one without the indirect object, ran the I<echo>
1558 program, passing it C<"surprise"> an argument.  The second version
1559 didn't--it tried to run a program literally called I<"echo surprise">,
1560 didn't find it, and set C<$?> to a non-zero value indicating failure.
1561
1562 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1563 output before the exec, but this may not be supported on some platforms
1564 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1565 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1566 open handles in order to avoid lost output.
1567
1568 Note that C<exec> will not call your C<END> blocks, nor will it call
1569 any C<DESTROY> methods in your objects.
1570
1571 =item exists EXPR
1572
1573 Given an expression that specifies a hash element or array element,
1574 returns true if the specified element in the hash or array has ever
1575 been initialized, even if the corresponding value is undefined.  The
1576 element is not autovivified if it doesn't exist.
1577
1578     print "Exists\n"    if exists $hash{$key};
1579     print "Defined\n"   if defined $hash{$key};
1580     print "True\n"      if $hash{$key};
1581
1582     print "Exists\n"    if exists $array[$index];
1583     print "Defined\n"   if defined $array[$index];
1584     print "True\n"      if $array[$index];
1585
1586 A hash or array element can be true only if it's defined, and defined if
1587 it exists, but the reverse doesn't necessarily hold true.
1588
1589 Given an expression that specifies the name of a subroutine,
1590 returns true if the specified subroutine has ever been declared, even
1591 if it is undefined.  Mentioning a subroutine name for exists or defined
1592 does not count as declaring it.  Note that a subroutine which does not
1593 exist may still be callable: its package may have an C<AUTOLOAD>
1594 method that makes it spring into existence the first time that it is
1595 called -- see L<perlsub>.
1596
1597     print "Exists\n"    if exists &subroutine;
1598     print "Defined\n"   if defined &subroutine;
1599
1600 Note that the EXPR can be arbitrarily complicated as long as the final
1601 operation is a hash or array key lookup or subroutine name:
1602
1603     if (exists $ref->{A}->{B}->{$key})  { }
1604     if (exists $hash{A}{B}{$key})       { }
1605
1606     if (exists $ref->{A}->{B}->[$ix])   { }
1607     if (exists $hash{A}{B}[$ix])        { }
1608
1609     if (exists &{$ref->{A}{B}{$key}})   { }
1610
1611 Although the deepest nested array or hash will not spring into existence
1612 just because its existence was tested, any intervening ones will.
1613 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1614 into existence due to the existence test for the $key element above.
1615 This happens anywhere the arrow operator is used, including even:
1616
1617     undef $ref;
1618     if (exists $ref->{"Some key"})      { }
1619     print $ref;             # prints HASH(0x80d3d5c)
1620
1621 This surprising autovivification in what does not at first--or even
1622 second--glance appear to be an lvalue context may be fixed in a future
1623 release.
1624
1625 Use of a subroutine call, rather than a subroutine name, as an argument
1626 to exists() is an error.
1627
1628     exists &sub;        # OK
1629     exists &sub();      # Error
1630
1631 =item exit EXPR
1632
1633 =item exit
1634
1635 Evaluates EXPR and exits immediately with that value.    Example:
1636
1637     $ans = <STDIN>;
1638     exit 0 if $ans =~ /^[Xx]/;
1639
1640 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1641 universally recognized values for EXPR are C<0> for success and C<1>
1642 for error; other values are subject to interpretation depending on the
1643 environment in which the Perl program is running.  For example, exiting
1644 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1645 the mailer to return the item undelivered, but that's not true everywhere.
1646
1647 Don't use C<exit> to abort a subroutine if there's any chance that
1648 someone might want to trap whatever error happened.  Use C<die> instead,
1649 which can be trapped by an C<eval>.
1650
1651 The exit() function does not always exit immediately.  It calls any
1652 defined C<END> routines first, but these C<END> routines may not
1653 themselves abort the exit.  Likewise any object destructors that need to
1654 be called are called before the real exit.  If this is a problem, you
1655 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1656 See L<perlmod> for details.
1657
1658 =item exp EXPR
1659
1660 =item exp
1661
1662 Returns I<e> (the natural logarithm base) to the power of EXPR.
1663 If EXPR is omitted, gives C<exp($_)>.
1664
1665 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1666
1667 Implements the fcntl(2) function.  You'll probably have to say
1668
1669     use Fcntl;
1670
1671 first to get the correct constant definitions.  Argument processing and
1672 value return works just like C<ioctl> below.
1673 For example:
1674
1675     use Fcntl;
1676     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1677         or die "can't fcntl F_GETFL: $!";
1678
1679 You don't have to check for C<defined> on the return from C<fcntl>.
1680 Like C<ioctl>, it maps a C<0> return from the system call into
1681 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1682 in numeric context.  It is also exempt from the normal B<-w> warnings
1683 on improper numeric conversions.
1684
1685 Note that C<fcntl> will produce a fatal error if used on a machine that
1686 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1687 manpage to learn what functions are available on your system.
1688
1689 Here's an example of setting a filehandle named C<REMOTE> to be
1690 non-blocking at the system level.  You'll have to negotiate C<$|>
1691 on your own, though.
1692
1693     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1694
1695     $flags = fcntl(REMOTE, F_GETFL, 0)
1696                 or die "Can't get flags for the socket: $!\n";
1697
1698     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1699                 or die "Can't set flags for the socket: $!\n";
1700
1701 =item fileno FILEHANDLE
1702
1703 Returns the file descriptor for a filehandle, or undefined if the
1704 filehandle is not open.  This is mainly useful for constructing
1705 bitmaps for C<select> and low-level POSIX tty-handling operations.
1706 If FILEHANDLE is an expression, the value is taken as an indirect
1707 filehandle, generally its name.
1708
1709 You can use this to find out whether two handles refer to the
1710 same underlying descriptor:
1711
1712     if (fileno(THIS) == fileno(THAT)) {
1713         print "THIS and THAT are dups\n";
1714     }
1715
1716 (Filehandles connected to memory objects via new features of C<open> may
1717 return undefined even though they are open.)
1718
1719
1720 =item flock FILEHANDLE,OPERATION
1721
1722 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1723 for success, false on failure.  Produces a fatal error if used on a
1724 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1725 C<flock> is Perl's portable file locking interface, although it locks
1726 only entire files, not records.
1727
1728 Two potentially non-obvious but traditional C<flock> semantics are
1729 that it waits indefinitely until the lock is granted, and that its locks
1730 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1731 fewer guarantees.  This means that files locked with C<flock> may be
1732 modified by programs that do not also use C<flock>.  See L<perlport>,
1733 your port's specific documentation, or your system-specific local manpages
1734 for details.  It's best to assume traditional behavior if you're writing
1735 portable programs.  (But if you're not, you should as always feel perfectly
1736 free to write for your own system's idiosyncrasies (sometimes called
1737 "features").  Slavish adherence to portability concerns shouldn't get
1738 in the way of your getting your job done.)
1739
1740 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1741 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1742 you can use the symbolic names if you import them from the Fcntl module,
1743 either individually, or as a group using the ':flock' tag.  LOCK_SH
1744 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1745 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1746 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1747 waiting for the lock (check the return status to see if you got it).
1748
1749 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1750 before locking or unlocking it.
1751
1752 Note that the emulation built with lockf(3) doesn't provide shared
1753 locks, and it requires that FILEHANDLE be open with write intent.  These
1754 are the semantics that lockf(3) implements.  Most if not all systems
1755 implement lockf(3) in terms of fcntl(2) locking, though, so the
1756 differing semantics shouldn't bite too many people.
1757
1758 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1759 be open with read intent to use LOCK_SH and requires that it be open
1760 with write intent to use LOCK_EX.
1761
1762 Note also that some versions of C<flock> cannot lock things over the
1763 network; you would need to use the more system-specific C<fcntl> for
1764 that.  If you like you can force Perl to ignore your system's flock(2)
1765 function, and so provide its own fcntl(2)-based emulation, by passing
1766 the switch C<-Ud_flock> to the F<Configure> program when you configure
1767 perl.
1768
1769 Here's a mailbox appender for BSD systems.
1770
1771     use Fcntl ':flock'; # import LOCK_* constants
1772
1773     sub lock {
1774         flock(MBOX,LOCK_EX);
1775         # and, in case someone appended
1776         # while we were waiting...
1777         seek(MBOX, 0, 2);
1778     }
1779
1780     sub unlock {
1781         flock(MBOX,LOCK_UN);
1782     }
1783
1784     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1785             or die "Can't open mailbox: $!";
1786
1787     lock();
1788     print MBOX $msg,"\n\n";
1789     unlock();
1790
1791 On systems that support a real flock(), locks are inherited across fork()
1792 calls, whereas those that must resort to the more capricious fcntl()
1793 function lose the locks, making it harder to write servers.
1794
1795 See also L<DB_File> for other flock() examples.
1796
1797 =item fork
1798
1799 Does a fork(2) system call to create a new process running the
1800 same program at the same point.  It returns the child pid to the
1801 parent process, C<0> to the child process, or C<undef> if the fork is
1802 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1803 are shared, while everything else is copied.  On most systems supporting
1804 fork(), great care has gone into making it extremely efficient (for
1805 example, using copy-on-write technology on data pages), making it the
1806 dominant paradigm for multitasking over the last few decades.
1807
1808 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1809 output before forking the child process, but this may not be supported
1810 on some platforms (see L<perlport>).  To be safe, you may need to set
1811 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1812 C<IO::Handle> on any open handles in order to avoid duplicate output.
1813
1814 If you C<fork> without ever waiting on your children, you will
1815 accumulate zombies.  On some systems, you can avoid this by setting
1816 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1817 forking and reaping moribund children.
1818
1819 Note that if your forked child inherits system file descriptors like
1820 STDIN and STDOUT that are actually connected by a pipe or socket, even
1821 if you exit, then the remote server (such as, say, a CGI script or a
1822 backgrounded job launched from a remote shell) won't think you're done.
1823 You should reopen those to F</dev/null> if it's any issue.
1824
1825 =item format
1826
1827 Declare a picture format for use by the C<write> function.  For
1828 example:
1829
1830     format Something =
1831         Test: @<<<<<<<< @||||| @>>>>>
1832               $str,     $%,    '$' . int($num)
1833     .
1834
1835     $str = "widget";
1836     $num = $cost/$quantity;
1837     $~ = 'Something';
1838     write;
1839
1840 See L<perlform> for many details and examples.
1841
1842 =item formline PICTURE,LIST
1843
1844 This is an internal function used by C<format>s, though you may call it,
1845 too.  It formats (see L<perlform>) a list of values according to the
1846 contents of PICTURE, placing the output into the format output
1847 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1848 Eventually, when a C<write> is done, the contents of
1849 C<$^A> are written to some filehandle, but you could also read C<$^A>
1850 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1851 does one C<formline> per line of form, but the C<formline> function itself
1852 doesn't care how many newlines are embedded in the PICTURE.  This means
1853 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1854 You may therefore need to use multiple formlines to implement a single
1855 record format, just like the format compiler.
1856
1857 Be careful if you put double quotes around the picture, because an C<@>
1858 character may be taken to mean the beginning of an array name.
1859 C<formline> always returns true.  See L<perlform> for other examples.
1860
1861 =item getc FILEHANDLE
1862
1863 =item getc
1864
1865 Returns the next character from the input file attached to FILEHANDLE,
1866 or the undefined value at end of file, or if there was an error (in
1867 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1868 STDIN.  This is not particularly efficient.  However, it cannot be
1869 used by itself to fetch single characters without waiting for the user
1870 to hit enter.  For that, try something more like:
1871
1872     if ($BSD_STYLE) {
1873         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1874     }
1875     else {
1876         system "stty", '-icanon', 'eol', "\001";
1877     }
1878
1879     $key = getc(STDIN);
1880
1881     if ($BSD_STYLE) {
1882         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1883     }
1884     else {
1885         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1886     }
1887     print "\n";
1888
1889 Determination of whether $BSD_STYLE should be set
1890 is left as an exercise to the reader.
1891
1892 The C<POSIX::getattr> function can do this more portably on
1893 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1894 module from your nearest CPAN site; details on CPAN can be found on
1895 L<perlmodlib/CPAN>.
1896
1897 =item getlogin
1898
1899 Implements the C library function of the same name, which on most
1900 systems returns the current login from F</etc/utmp>, if any.  If null,
1901 use C<getpwuid>.
1902
1903     $login = getlogin || getpwuid($<) || "Kilroy";
1904
1905 Do not consider C<getlogin> for authentication: it is not as
1906 secure as C<getpwuid>.
1907
1908 =item getpeername SOCKET
1909
1910 Returns the packed sockaddr address of other end of the SOCKET connection.
1911
1912     use Socket;
1913     $hersockaddr    = getpeername(SOCK);
1914     ($port, $iaddr) = sockaddr_in($hersockaddr);
1915     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1916     $herstraddr     = inet_ntoa($iaddr);
1917
1918 =item getpgrp PID
1919
1920 Returns the current process group for the specified PID.  Use
1921 a PID of C<0> to get the current process group for the
1922 current process.  Will raise an exception if used on a machine that
1923 doesn't implement getpgrp(2).  If PID is omitted, returns process
1924 group of current process.  Note that the POSIX version of C<getpgrp>
1925 does not accept a PID argument, so only C<PID==0> is truly portable.
1926
1927 =item getppid
1928
1929 Returns the process id of the parent process.
1930
1931 Note for Linux users: on Linux, the C functions C<getpid()> and
1932 C<getppid()> return different values from different threads. In order to
1933 be portable, this behavior is not reflected by the perl-level function
1934 C<getppid()>, that returns a consistent value across threads. If you want
1935 to call the underlying C<getppid()>, you may use the CPAN module
1936 C<Linux::Pid>.
1937
1938 =item getpriority WHICH,WHO
1939
1940 Returns the current priority for a process, a process group, or a user.
1941 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1942 machine that doesn't implement getpriority(2).
1943
1944 =item getpwnam NAME
1945
1946 =item getgrnam NAME
1947
1948 =item gethostbyname NAME
1949
1950 =item getnetbyname NAME
1951
1952 =item getprotobyname NAME
1953
1954 =item getpwuid UID
1955
1956 =item getgrgid GID
1957
1958 =item getservbyname NAME,PROTO
1959
1960 =item gethostbyaddr ADDR,ADDRTYPE
1961
1962 =item getnetbyaddr ADDR,ADDRTYPE
1963
1964 =item getprotobynumber NUMBER
1965
1966 =item getservbyport PORT,PROTO
1967
1968 =item getpwent
1969
1970 =item getgrent
1971
1972 =item gethostent
1973
1974 =item getnetent
1975
1976 =item getprotoent
1977
1978 =item getservent
1979
1980 =item setpwent
1981
1982 =item setgrent
1983
1984 =item sethostent STAYOPEN
1985
1986 =item setnetent STAYOPEN
1987
1988 =item setprotoent STAYOPEN
1989
1990 =item setservent STAYOPEN
1991
1992 =item endpwent
1993
1994 =item endgrent
1995
1996 =item endhostent
1997
1998 =item endnetent
1999
2000 =item endprotoent
2001
2002 =item endservent
2003
2004 These routines perform the same functions as their counterparts in the
2005 system library.  In list context, the return values from the
2006 various get routines are as follows:
2007
2008     ($name,$passwd,$uid,$gid,
2009        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2010     ($name,$passwd,$gid,$members) = getgr*
2011     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2012     ($name,$aliases,$addrtype,$net) = getnet*
2013     ($name,$aliases,$proto) = getproto*
2014     ($name,$aliases,$port,$proto) = getserv*
2015
2016 (If the entry doesn't exist you get a null list.)
2017
2018 The exact meaning of the $gcos field varies but it usually contains
2019 the real name of the user (as opposed to the login name) and other
2020 information pertaining to the user.  Beware, however, that in many
2021 system users are able to change this information and therefore it
2022 cannot be trusted and therefore the $gcos is tainted (see
2023 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2024 login shell, are also tainted, because of the same reason.
2025
2026 In scalar context, you get the name, unless the function was a
2027 lookup by name, in which case you get the other thing, whatever it is.
2028 (If the entry doesn't exist you get the undefined value.)  For example:
2029
2030     $uid   = getpwnam($name);
2031     $name  = getpwuid($num);
2032     $name  = getpwent();
2033     $gid   = getgrnam($name);
2034     $name  = getgrgid($num);
2035     $name  = getgrent();
2036     #etc.
2037
2038 In I<getpw*()> the fields $quota, $comment, and $expire are special
2039 cases in the sense that in many systems they are unsupported.  If the
2040 $quota is unsupported, it is an empty scalar.  If it is supported, it
2041 usually encodes the disk quota.  If the $comment field is unsupported,
2042 it is an empty scalar.  If it is supported it usually encodes some
2043 administrative comment about the user.  In some systems the $quota
2044 field may be $change or $age, fields that have to do with password
2045 aging.  In some systems the $comment field may be $class.  The $expire
2046 field, if present, encodes the expiration period of the account or the
2047 password.  For the availability and the exact meaning of these fields
2048 in your system, please consult your getpwnam(3) documentation and your
2049 F<pwd.h> file.  You can also find out from within Perl what your
2050 $quota and $comment fields mean and whether you have the $expire field
2051 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2052 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2053 files are only supported if your vendor has implemented them in the
2054 intuitive fashion that calling the regular C library routines gets the
2055 shadow versions if you're running under privilege or if there exists
2056 the shadow(3) functions as found in System V ( this includes Solaris
2057 and Linux.)  Those systems which implement a proprietary shadow password
2058 facility are unlikely to be supported.
2059
2060 The $members value returned by I<getgr*()> is a space separated list of
2061 the login names of the members of the group.
2062
2063 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2064 C, it will be returned to you via C<$?> if the function call fails.  The
2065 C<@addrs> value returned by a successful call is a list of the raw
2066 addresses returned by the corresponding system library call.  In the
2067 Internet domain, each address is four bytes long and you can unpack it
2068 by saying something like:
2069
2070     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2071
2072 The Socket library makes this slightly easier:
2073
2074     use Socket;
2075     $iaddr = inet_aton("127.1"); # or whatever address
2076     $name  = gethostbyaddr($iaddr, AF_INET);
2077
2078     # or going the other way
2079     $straddr = inet_ntoa($iaddr);
2080
2081 If you get tired of remembering which element of the return list
2082 contains which return value, by-name interfaces are provided
2083 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2084 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2085 and C<User::grent>.  These override the normal built-ins, supplying
2086 versions that return objects with the appropriate names
2087 for each field.  For example:
2088
2089    use File::stat;
2090    use User::pwent;
2091    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2092
2093 Even though it looks like they're the same method calls (uid),
2094 they aren't, because a C<File::stat> object is different from
2095 a C<User::pwent> object.
2096
2097 =item getsockname SOCKET
2098
2099 Returns the packed sockaddr address of this end of the SOCKET connection,
2100 in case you don't know the address because you have several different
2101 IPs that the connection might have come in on.
2102
2103     use Socket;
2104     $mysockaddr = getsockname(SOCK);
2105     ($port, $myaddr) = sockaddr_in($mysockaddr);
2106     printf "Connect to %s [%s]\n",
2107        scalar gethostbyaddr($myaddr, AF_INET),
2108        inet_ntoa($myaddr);
2109
2110 =item getsockopt SOCKET,LEVEL,OPTNAME
2111
2112 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2113 Options may exist at multiple protocol levels depending on the socket
2114 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2115 C<Socket> module) will exist. To query options at another level the
2116 protocol number of the appropriate protocol controlling the option
2117 should be supplied. For example, to indicate that an option is to be
2118 interpreted by the TCP protocol, LEVEL should be set to the protocol
2119 number of TCP, which you can get using getprotobyname.
2120
2121 The call returns a packed string representing the requested socket option,
2122 or C<undef> if there is an error (the error reason will be in $!). What
2123 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2124 your system documentation for details. A very common case however is that
2125 the option is an integer, in which case the result will be an packed
2126 integer which you can decode using unpack with the C<i> (or C<I>) format.
2127
2128 An example testing if Nagle's algorithm is turned on on a socket:
2129
2130     use Socket qw(:all);
2131
2132     defined(my $tcp = getprotobyname("tcp"))
2133         or die "Could not determine the protocol number for tcp";
2134     # my $tcp = IPPROTO_TCP; # Alternative
2135     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2136         or die "Could not query TCP_NODELAY socket option: $!";
2137     my $nodelay = unpack("I", $packed);
2138     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2139
2140
2141 =item glob EXPR
2142
2143 =item glob
2144
2145 In list context, returns a (possibly empty) list of filename expansions on
2146 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2147 scalar context, glob iterates through such filename expansions, returning
2148 undef when the list is exhausted. This is the internal function
2149 implementing the C<< <*.c> >> operator, but you can use it directly. If
2150 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2151 more detail in L<perlop/"I/O Operators">.
2152
2153 Beginning with v5.6.0, this operator is implemented using the standard
2154 C<File::Glob> extension.  See L<File::Glob> for details.
2155
2156 =item gmtime EXPR
2157
2158 =item gmtime
2159
2160 Converts a time as returned by the time function to an 8-element list
2161 with the time localized for the standard Greenwich time zone.
2162 Typically used as follows:
2163
2164     #  0    1    2     3     4    5     6     7
2165     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2166                                             gmtime(time);
2167
2168 All list elements are numeric, and come straight out of the C `struct
2169 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2170 specified time.  $mday is the day of the month, and $mon is the month
2171 itself, in the range C<0..11> with 0 indicating January and 11
2172 indicating December.  $year is the number of years since 1900.  That
2173 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2174 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2175 the year, in the range C<0..364> (or C<0..365> in leap years.)
2176
2177 Note that the $year element is I<not> simply the last two digits of
2178 the year.  If you assume it is, then you create non-Y2K-compliant
2179 programs--and you wouldn't want to do that, would you?
2180
2181 The proper way to get a complete 4-digit year is simply:
2182
2183         $year += 1900;
2184
2185 And to get the last two digits of the year (e.g., '01' in 2001) do:
2186
2187         $year = sprintf("%02d", $year % 100);
2188
2189 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2190
2191 In scalar context, C<gmtime()> returns the ctime(3) value:
2192
2193     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2194
2195 If you need local time instead of GMT use the L</localtime> builtin. 
2196 See also the C<timegm> function provided by the C<Time::Local> module,
2197 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2198
2199 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2200 instead a Perl builtin.  To get somewhat similar but locale dependent date
2201 strings, see the example in L</localtime>.
2202
2203 See L<perlport/gmtime> for portability concerns.
2204
2205 =item goto LABEL
2206
2207 =item goto EXPR
2208
2209 =item goto &NAME
2210
2211 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2212 execution there.  It may not be used to go into any construct that
2213 requires initialization, such as a subroutine or a C<foreach> loop.  It
2214 also can't be used to go into a construct that is optimized away,
2215 or to get out of a block or subroutine given to C<sort>.
2216 It can be used to go almost anywhere else within the dynamic scope,
2217 including out of subroutines, but it's usually better to use some other
2218 construct such as C<last> or C<die>.  The author of Perl has never felt the
2219 need to use this form of C<goto> (in Perl, that is--C is another matter).
2220 (The difference being that C does not offer named loops combined with
2221 loop control.  Perl does, and this replaces most structured uses of C<goto>
2222 in other languages.)
2223
2224 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2225 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2226 necessarily recommended if you're optimizing for maintainability:
2227
2228     goto ("FOO", "BAR", "GLARCH")[$i];
2229
2230 The C<goto-&NAME> form is quite different from the other forms of
2231 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2232 doesn't have the stigma associated with other gotos.  Instead, it
2233 exits the current subroutine (losing any changes set by local()) and
2234 immediately calls in its place the named subroutine using the current
2235 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2236 load another subroutine and then pretend that the other subroutine had
2237 been called in the first place (except that any modifications to C<@_>
2238 in the current subroutine are propagated to the other subroutine.)
2239 After the C<goto>, not even C<caller> will be able to tell that this
2240 routine was called first.
2241
2242 NAME needn't be the name of a subroutine; it can be a scalar variable
2243 containing a code reference, or a block which evaluates to a code
2244 reference.
2245
2246 =item grep BLOCK LIST
2247
2248 =item grep EXPR,LIST
2249
2250 This is similar in spirit to, but not the same as, grep(1) and its
2251 relatives.  In particular, it is not limited to using regular expressions.
2252
2253 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2254 C<$_> to each element) and returns the list value consisting of those
2255 elements for which the expression evaluated to true.  In scalar
2256 context, returns the number of times the expression was true.
2257
2258     @foo = grep(!/^#/, @bar);    # weed out comments
2259
2260 or equivalently,
2261
2262     @foo = grep {!/^#/} @bar;    # weed out comments
2263
2264 Note that C<$_> is an alias to the list value, so it can be used to
2265 modify the elements of the LIST.  While this is useful and supported,
2266 it can cause bizarre results if the elements of LIST are not variables.
2267 Similarly, grep returns aliases into the original list, much as a for
2268 loop's index variable aliases the list elements.  That is, modifying an
2269 element of a list returned by grep (for example, in a C<foreach>, C<map>
2270 or another C<grep>) actually modifies the element in the original list.
2271 This is usually something to be avoided when writing clear code.
2272
2273 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2274 been declared with C<my $_>) then, in addition the be locally aliased to
2275 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2276 can't be seen from the outside, avoiding any potential side-effects.
2277
2278 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2279
2280 =item hex EXPR
2281
2282 =item hex
2283
2284 Interprets EXPR as a hex string and returns the corresponding value.
2285 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2286 L</oct>.)  If EXPR is omitted, uses C<$_>.
2287
2288     print hex '0xAf'; # prints '175'
2289     print hex 'aF';   # same
2290
2291 Hex strings may only represent integers.  Strings that would cause
2292 integer overflow trigger a warning.  Leading whitespace is not stripped,
2293 unlike oct(). To present something as hex, look into L</printf>,
2294 L</sprintf>, or L</unpack>.
2295
2296 =item import LIST
2297
2298 There is no builtin C<import> function.  It is just an ordinary
2299 method (subroutine) defined (or inherited) by modules that wish to export
2300 names to another module.  The C<use> function calls the C<import> method
2301 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2302
2303 =item index STR,SUBSTR,POSITION
2304
2305 =item index STR,SUBSTR
2306
2307 The index function searches for one string within another, but without
2308 the wildcard-like behavior of a full regular-expression pattern match.
2309 It returns the position of the first occurrence of SUBSTR in STR at
2310 or after POSITION.  If POSITION is omitted, starts searching from the
2311 beginning of the string.  The return value is based at C<0> (or whatever
2312 you've set the C<$[> variable to--but don't do that).  If the substring
2313 is not found, returns one less than the base, ordinarily C<-1>.
2314
2315 =item int EXPR
2316
2317 =item int
2318
2319 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2320 You should not use this function for rounding: one because it truncates
2321 towards C<0>, and two because machine representations of floating point
2322 numbers can sometimes produce counterintuitive results.  For example,
2323 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2324 because it's really more like -268.99999999999994315658 instead.  Usually,
2325 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2326 functions will serve you better than will int().
2327
2328 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2329
2330 Implements the ioctl(2) function.  You'll probably first have to say
2331
2332     require "sys/ioctl.ph";     # probably in $Config{archlib}/ioctl.ph
2333
2334 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2335 exist or doesn't have the correct definitions you'll have to roll your
2336 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2337 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2338 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2339 written depending on the FUNCTION--a pointer to the string value of SCALAR
2340 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2341 has no string value but does have a numeric value, that value will be
2342 passed rather than a pointer to the string value.  To guarantee this to be
2343 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2344 functions may be needed to manipulate the values of structures used by
2345 C<ioctl>.
2346
2347 The return value of C<ioctl> (and C<fcntl>) is as follows:
2348
2349         if OS returns:          then Perl returns:
2350             -1                    undefined value
2351              0                  string "0 but true"
2352         anything else               that number
2353
2354 Thus Perl returns true on success and false on failure, yet you can
2355 still easily determine the actual value returned by the operating
2356 system:
2357
2358     $retval = ioctl(...) || -1;
2359     printf "System returned %d\n", $retval;
2360
2361 The special string C<"0 but true"> is exempt from B<-w> complaints
2362 about improper numeric conversions.
2363
2364 =item join EXPR,LIST
2365
2366 Joins the separate strings of LIST into a single string with fields
2367 separated by the value of EXPR, and returns that new string.  Example:
2368
2369     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2370
2371 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2372 first argument.  Compare L</split>.
2373
2374 =item keys HASH
2375
2376 Returns a list consisting of all the keys of the named hash.
2377 (In scalar context, returns the number of keys.)
2378
2379 The keys are returned in an apparently random order.  The actual
2380 random order is subject to change in future versions of perl, but it
2381 is guaranteed to be the same order as either the C<values> or C<each>
2382 function produces (given that the hash has not been modified).  Since
2383 Perl 5.8.1 the ordering is different even between different runs of
2384 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2385 Attacks">).
2386
2387 As a side effect, calling keys() resets the HASH's internal iterator,
2388 see L</each>. (In particular, calling keys() in void context resets
2389 the iterator with no other overhead.)
2390
2391 Here is yet another way to print your environment:
2392
2393     @keys = keys %ENV;
2394     @values = values %ENV;
2395     while (@keys) {
2396         print pop(@keys), '=', pop(@values), "\n";
2397     }
2398
2399 or how about sorted by key:
2400
2401     foreach $key (sort(keys %ENV)) {
2402         print $key, '=', $ENV{$key}, "\n";
2403     }
2404
2405 The returned values are copies of the original keys in the hash, so
2406 modifying them will not affect the original hash.  Compare L</values>.
2407
2408 To sort a hash by value, you'll need to use a C<sort> function.
2409 Here's a descending numeric sort of a hash by its values:
2410
2411     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2412         printf "%4d %s\n", $hash{$key}, $key;
2413     }
2414
2415 As an lvalue C<keys> allows you to increase the number of hash buckets
2416 allocated for the given hash.  This can gain you a measure of efficiency if
2417 you know the hash is going to get big.  (This is similar to pre-extending
2418 an array by assigning a larger number to $#array.)  If you say
2419
2420     keys %hash = 200;
2421
2422 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2423 in fact, since it rounds up to the next power of two.  These
2424 buckets will be retained even if you do C<%hash = ()>, use C<undef
2425 %hash> if you want to free the storage while C<%hash> is still in scope.
2426 You can't shrink the number of buckets allocated for the hash using
2427 C<keys> in this way (but you needn't worry about doing this by accident,
2428 as trying has no effect).
2429
2430 See also C<each>, C<values> and C<sort>.
2431
2432 =item kill SIGNAL, LIST
2433
2434 Sends a signal to a list of processes.  Returns the number of
2435 processes successfully signaled (which is not necessarily the
2436 same as the number actually killed).
2437
2438     $cnt = kill 1, $child1, $child2;
2439     kill 9, @goners;
2440
2441 If SIGNAL is zero, no signal is sent to the process.  This is a
2442 useful way to check that a child process is alive and hasn't changed
2443 its UID.  See L<perlport> for notes on the portability of this
2444 construct.
2445
2446 Unlike in the shell, if SIGNAL is negative, it kills
2447 process groups instead of processes.  (On System V, a negative I<PROCESS>
2448 number will also kill process groups, but that's not portable.)  That
2449 means you usually want to use positive not negative signals.  You may also
2450 use a signal name in quotes.
2451
2452 See L<perlipc/"Signals"> for more details.
2453
2454 =item last LABEL
2455
2456 =item last
2457
2458 The C<last> command is like the C<break> statement in C (as used in
2459 loops); it immediately exits the loop in question.  If the LABEL is
2460 omitted, the command refers to the innermost enclosing loop.  The
2461 C<continue> block, if any, is not executed:
2462
2463     LINE: while (<STDIN>) {
2464         last LINE if /^$/;      # exit when done with header
2465         #...
2466     }
2467
2468 C<last> cannot be used to exit a block which returns a value such as
2469 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2470 a grep() or map() operation.
2471
2472 Note that a block by itself is semantically identical to a loop
2473 that executes once.  Thus C<last> can be used to effect an early
2474 exit out of such a block.
2475
2476 See also L</continue> for an illustration of how C<last>, C<next>, and
2477 C<redo> work.
2478
2479 =item lc EXPR
2480
2481 =item lc
2482
2483 Returns a lowercased version of EXPR.  This is the internal function
2484 implementing the C<\L> escape in double-quoted strings.  Respects
2485 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2486 and L<perlunicode> for more details about locale and Unicode support.
2487
2488 If EXPR is omitted, uses C<$_>.
2489
2490 =item lcfirst EXPR
2491
2492 =item lcfirst
2493
2494 Returns the value of EXPR with the first character lowercased.  This
2495 is the internal function implementing the C<\l> escape in
2496 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2497 locale> in force.  See L<perllocale> and L<perlunicode> for more
2498 details about locale and Unicode support.
2499
2500 If EXPR is omitted, uses C<$_>.
2501
2502 =item length EXPR
2503
2504 =item length
2505
2506 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2507 omitted, returns length of C<$_>.  Note that this cannot be used on
2508 an entire array or hash to find out how many elements these have.
2509 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2510
2511 Note the I<characters>: if the EXPR is in Unicode, you will get the
2512 number of characters, not the number of bytes.  To get the length
2513 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2514
2515 =item link OLDFILE,NEWFILE
2516
2517 Creates a new filename linked to the old filename.  Returns true for
2518 success, false otherwise.
2519
2520 =item listen SOCKET,QUEUESIZE
2521
2522 Does the same thing that the listen system call does.  Returns true if
2523 it succeeded, false otherwise.  See the example in
2524 L<perlipc/"Sockets: Client/Server Communication">.
2525
2526 =item local EXPR
2527
2528 You really probably want to be using C<my> instead, because C<local> isn't
2529 what most people think of as "local".  See
2530 L<perlsub/"Private Variables via my()"> for details.
2531
2532 A local modifies the listed variables to be local to the enclosing
2533 block, file, or eval.  If more than one value is listed, the list must
2534 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2535 for details, including issues with tied arrays and hashes.
2536
2537 =item localtime EXPR
2538
2539 =item localtime
2540
2541 Converts a time as returned by the time function to a 9-element list
2542 with the time analyzed for the local time zone.  Typically used as
2543 follows:
2544
2545     #  0    1    2     3     4    5     6     7     8
2546     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2547                                                 localtime(time);
2548
2549 All list elements are numeric, and come straight out of the C `struct
2550 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2551 of the specified time.
2552
2553 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2554 the range C<0..11> with 0 indicating January and 11 indicating December.
2555 This makes it easy to get a month name from a list:
2556
2557     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2558     print "$abbr[$mon] $mday";
2559     # $mon=9, $mday=18 gives "Oct 18"
2560
2561 C<$year> is the number of years since 1900, not just the last two digits
2562 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2563 to get a complete 4-digit year is simply:
2564
2565     $year += 1900;
2566
2567 To get the last two digits of the year (e.g., '01' in 2001) do:
2568
2569     $year = sprintf("%02d", $year % 100);
2570
2571 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2572 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2573 (or C<0..365> in leap years.)
2574
2575 C<$isdst> is true if the specified time occurs during Daylight Saving
2576 Time, false otherwise.
2577
2578 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2579
2580 In scalar context, C<localtime()> returns the ctime(3) value:
2581
2582     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2583
2584 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2585 instead of local time use the L</gmtime> builtin. See also the
2586 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2587 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2588 and mktime(3) functions.
2589
2590 To get somewhat similar but locale dependent date strings, set up your
2591 locale environment variables appropriately (please see L<perllocale>) and
2592 try for example:
2593
2594     use POSIX qw(strftime);
2595     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2596     # or for GMT formatted appropriately for your locale:
2597     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2598
2599 Note that the C<%a> and C<%b>, the short forms of the day of the week
2600 and the month of the year, may not necessarily be three characters wide.
2601
2602 See L<perlport/localtime> for portability concerns.
2603
2604 =item lock THING
2605
2606 This function places an advisory lock on a shared variable, or referenced
2607 object contained in I<THING> until the lock goes out of scope.
2608
2609 lock() is a "weak keyword" : this means that if you've defined a function
2610 by this name (before any calls to it), that function will be called
2611 instead. (However, if you've said C<use threads>, lock() is always a
2612 keyword.) See L<threads>.
2613
2614 =item log EXPR
2615
2616 =item log
2617
2618 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2619 returns log of C<$_>.  To get the log of another base, use basic algebra:
2620 The base-N log of a number is equal to the natural log of that number
2621 divided by the natural log of N.  For example:
2622
2623     sub log10 {
2624         my $n = shift;
2625         return log($n)/log(10);
2626     }
2627
2628 See also L</exp> for the inverse operation.
2629
2630 =item lstat EXPR
2631
2632 =item lstat
2633
2634 Does the same thing as the C<stat> function (including setting the
2635 special C<_> filehandle) but stats a symbolic link instead of the file
2636 the symbolic link points to.  If symbolic links are unimplemented on
2637 your system, a normal C<stat> is done.  For much more detailed
2638 information, please see the documentation for C<stat>.
2639
2640 If EXPR is omitted, stats C<$_>.
2641
2642 =item m//
2643
2644 The match operator.  See L<perlop>.
2645
2646 =item map BLOCK LIST
2647
2648 =item map EXPR,LIST
2649
2650 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2651 C<$_> to each element) and returns the list value composed of the
2652 results of each such evaluation.  In scalar context, returns the
2653 total number of elements so generated.  Evaluates BLOCK or EXPR in
2654 list context, so each element of LIST may produce zero, one, or
2655 more elements in the returned value.
2656
2657     @chars = map(chr, @nums);
2658
2659 translates a list of numbers to the corresponding characters.  And
2660
2661     %hash = map { getkey($_) => $_ } @array;
2662
2663 is just a funny way to write
2664
2665     %hash = ();
2666     foreach $_ (@array) {
2667         $hash{getkey($_)} = $_;
2668     }
2669
2670 Note that C<$_> is an alias to the list value, so it can be used to
2671 modify the elements of the LIST.  While this is useful and supported,
2672 it can cause bizarre results if the elements of LIST are not variables.
2673 Using a regular C<foreach> loop for this purpose would be clearer in
2674 most cases.  See also L</grep> for an array composed of those items of
2675 the original list for which the BLOCK or EXPR evaluates to true.
2676
2677 If C<$_> is lexical in the scope where the C<map> appears (because it has
2678 been declared with C<my $_>) then, in addition the be locally aliased to
2679 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2680 can't be seen from the outside, avoiding any potential side-effects.
2681
2682 C<{> starts both hash references and blocks, so C<map { ...> could be either
2683 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2684 ahead for the closing C<}> it has to take a guess at which its dealing with
2685 based what it finds just after the C<{>. Usually it gets it right, but if it
2686 doesn't it won't realize something is wrong until it gets to the C<}> and
2687 encounters the missing (or unexpected) comma. The syntax error will be
2688 reported close to the C<}> but you'll need to change something near the C<{>
2689 such as using a unary C<+> to give perl some help:
2690
2691     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2692     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2693     %hash = map { ("\L$_", 1) } @array  # this also works
2694     %hash = map {  lc($_), 1  } @array  # as does this.
2695     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2696
2697     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2698
2699 or to force an anon hash constructor use C<+{>
2700
2701    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2702
2703 and you get list of anonymous hashes each with only 1 entry.
2704
2705 =item mkdir FILENAME,MASK
2706
2707 =item mkdir FILENAME
2708
2709 =item mkdir
2710
2711 Creates the directory specified by FILENAME, with permissions
2712 specified by MASK (as modified by C<umask>).  If it succeeds it
2713 returns true, otherwise it returns false and sets C<$!> (errno).
2714 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2715 to C<$_>.
2716
2717 In general, it is better to create directories with permissive MASK,
2718 and let the user modify that with their C<umask>, than it is to supply
2719 a restrictive MASK and give the user no way to be more permissive.
2720 The exceptions to this rule are when the file or directory should be
2721 kept private (mail files, for instance).  The perlfunc(1) entry on
2722 C<umask> discusses the choice of MASK in more detail.
2723
2724 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2725 number of trailing slashes.  Some operating and filesystems do not get
2726 this right, so Perl automatically removes all trailing slashes to keep
2727 everyone happy.
2728
2729 =item msgctl ID,CMD,ARG
2730
2731 Calls the System V IPC function msgctl(2).  You'll probably have to say
2732
2733     use IPC::SysV;
2734
2735 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2736 then ARG must be a variable which will hold the returned C<msqid_ds>
2737 structure.  Returns like C<ioctl>: the undefined value for error,
2738 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2739 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2740
2741 =item msgget KEY,FLAGS
2742
2743 Calls the System V IPC function msgget(2).  Returns the message queue
2744 id, or the undefined value if there is an error.  See also
2745 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2746
2747 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2748
2749 Calls the System V IPC function msgrcv to receive a message from
2750 message queue ID into variable VAR with a maximum message size of
2751 SIZE.  Note that when a message is received, the message type as a
2752 native long integer will be the first thing in VAR, followed by the
2753 actual message.  This packing may be opened with C<unpack("l! a*")>.
2754 Taints the variable.  Returns true if successful, or false if there is
2755 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2756 C<IPC::SysV::Msg> documentation.
2757
2758 =item msgsnd ID,MSG,FLAGS
2759
2760 Calls the System V IPC function msgsnd to send the message MSG to the
2761 message queue ID.  MSG must begin with the native long integer message
2762 type, and be followed by the length of the actual message, and finally
2763 the message itself.  This kind of packing can be achieved with
2764 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2765 or false if there is an error.  See also C<IPC::SysV>
2766 and C<IPC::SysV::Msg> documentation.
2767
2768 =item my EXPR
2769
2770 =item my TYPE EXPR
2771
2772 =item my EXPR : ATTRS
2773
2774 =item my TYPE EXPR : ATTRS
2775
2776 A C<my> declares the listed variables to be local (lexically) to the
2777 enclosing block, file, or C<eval>.  If more than one value is listed,
2778 the list must be placed in parentheses.
2779
2780 The exact semantics and interface of TYPE and ATTRS are still
2781 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2782 and attributes are handled using the C<attributes> pragma, or starting
2783 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2784 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2785 L<attributes>, and L<Attribute::Handlers>.
2786
2787 =item next LABEL
2788
2789 =item next
2790
2791 The C<next> command is like the C<continue> statement in C; it starts
2792 the next iteration of the loop:
2793
2794     LINE: while (<STDIN>) {
2795         next LINE if /^#/;      # discard comments
2796         #...
2797     }
2798
2799 Note that if there were a C<continue> block on the above, it would get
2800 executed even on discarded lines.  If the LABEL is omitted, the command
2801 refers to the innermost enclosing loop.
2802
2803 C<next> cannot be used to exit a block which returns a value such as
2804 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2805 a grep() or map() operation.
2806
2807 Note that a block by itself is semantically identical to a loop
2808 that executes once.  Thus C<next> will exit such a block early.
2809
2810 See also L</continue> for an illustration of how C<last>, C<next>, and
2811 C<redo> work.
2812
2813 =item no Module VERSION LIST
2814
2815 =item no Module VERSION
2816
2817 =item no Module LIST
2818
2819 =item no Module
2820
2821 See the C<use> function, of which C<no> is the opposite.
2822
2823 =item oct EXPR
2824
2825 =item oct
2826
2827 Interprets EXPR as an octal string and returns the corresponding
2828 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2829 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2830 binary string.  Leading whitespace is ignored in all three cases.)
2831 The following will handle decimal, binary, octal, and hex in the standard
2832 Perl or C notation:
2833
2834     $val = oct($val) if $val =~ /^0/;
2835
2836 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2837 in octal), use sprintf() or printf():
2838
2839     $perms = (stat("filename"))[2] & 07777;
2840     $oct_perms = sprintf "%lo", $perms;
2841
2842 The oct() function is commonly used when a string such as C<644> needs
2843 to be converted into a file mode, for example. (Although perl will
2844 automatically convert strings into numbers as needed, this automatic
2845 conversion assumes base 10.)
2846
2847 =item open FILEHANDLE,EXPR
2848
2849 =item open FILEHANDLE,MODE,EXPR
2850
2851 =item open FILEHANDLE,MODE,EXPR,LIST
2852
2853 =item open FILEHANDLE,MODE,REFERENCE
2854
2855 =item open FILEHANDLE
2856
2857 Opens the file whose filename is given by EXPR, and associates it with
2858 FILEHANDLE.
2859
2860 (The following is a comprehensive reference to open(): for a gentler
2861 introduction you may consider L<perlopentut>.)
2862
2863 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2864 the variable is assigned a reference to a new anonymous filehandle,
2865 otherwise if FILEHANDLE is an expression, its value is used as the name of
2866 the real filehandle wanted.  (This is considered a symbolic reference, so
2867 C<use strict 'refs'> should I<not> be in effect.)
2868
2869 If EXPR is omitted, the scalar variable of the same name as the
2870 FILEHANDLE contains the filename.  (Note that lexical variables--those
2871 declared with C<my>--will not work for this purpose; so if you're
2872 using C<my>, specify EXPR in your call to open.)
2873
2874 If three or more arguments are specified then the mode of opening and
2875 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2876 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2877 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2878 the file is opened for appending, again being created if necessary.
2879
2880 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2881 indicate that you want both read and write access to the file; thus
2882 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2883 '+>' >> mode would clobber the file first.  You can't usually use
2884 either read-write mode for updating textfiles, since they have
2885 variable length records.  See the B<-i> switch in L<perlrun> for a
2886 better approach.  The file is created with permissions of C<0666>
2887 modified by the process' C<umask> value.
2888
2889 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2890 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2891
2892 In the 2-arguments (and 1-argument) form of the call the mode and
2893 filename should be concatenated (in this order), possibly separated by
2894 spaces.  It is possible to omit the mode in these forms if the mode is
2895 C<< '<' >>.
2896
2897 If the filename begins with C<'|'>, the filename is interpreted as a
2898 command to which output is to be piped, and if the filename ends with a
2899 C<'|'>, the filename is interpreted as a command which pipes output to
2900 us.  See L<perlipc/"Using open() for IPC">
2901 for more examples of this.  (You are not allowed to C<open> to a command
2902 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2903 and L<perlipc/"Bidirectional Communication with Another Process">
2904 for alternatives.)
2905
2906 For three or more arguments if MODE is C<'|-'>, the filename is
2907 interpreted as a command to which output is to be piped, and if MODE
2908 is C<'-|'>, the filename is interpreted as a command which pipes
2909 output to us.  In the 2-arguments (and 1-argument) form one should
2910 replace dash (C<'-'>) with the command.
2911 See L<perlipc/"Using open() for IPC"> for more examples of this.
2912 (You are not allowed to C<open> to a command that pipes both in I<and>
2913 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2914 L<perlipc/"Bidirectional Communication"> for alternatives.)
2915
2916 In the three-or-more argument form of pipe opens, if LIST is specified
2917 (extra arguments after the command name) then LIST becomes arguments
2918 to the command invoked if the platform supports it.  The meaning of
2919 C<open> with more than three arguments for non-pipe modes is not yet
2920 specified. Experimental "layers" may give extra LIST arguments
2921 meaning.
2922
2923 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2924 and opening C<< '>-' >> opens STDOUT.
2925
2926 You may use the three-argument form of open to specify IO "layers"
2927 (sometimes also referred to as "disciplines") to be applied to the handle
2928 that affect how the input and output are processed (see L<open> and
2929 L<PerlIO> for more details). For example
2930
2931   open(FH, "<:utf8", "file")
2932
2933 will open the UTF-8 encoded file containing Unicode characters,
2934 see L<perluniintro>. (Note that if layers are specified in the
2935 three-arg form then default layers set by the C<open> pragma are
2936 ignored.)
2937
2938 Open returns nonzero upon success, the undefined value otherwise.  If
2939 the C<open> involved a pipe, the return value happens to be the pid of
2940 the subprocess.
2941
2942 If you're running Perl on a system that distinguishes between text
2943 files and binary files, then you should check out L</binmode> for tips
2944 for dealing with this.  The key distinction between systems that need
2945 C<binmode> and those that don't is their text file formats.  Systems
2946 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2947 character, and which encode that character in C as C<"\n">, do not
2948 need C<binmode>.  The rest need it.
2949
2950 When opening a file, it's usually a bad idea to continue normal execution
2951 if the request failed, so C<open> is frequently used in connection with
2952 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2953 where you want to make a nicely formatted error message (but there are
2954 modules that can help with that problem)) you should always check
2955 the return value from opening a file.  The infrequent exception is when
2956 working with an unopened filehandle is actually what you want to do.
2957
2958 As a special case the 3 arg form with a read/write mode and the third
2959 argument being C<undef>:
2960
2961     open(TMP, "+>", undef) or die ...
2962
2963 opens a filehandle to an anonymous temporary file.  Also using "+<"
2964 works for symmetry, but you really should consider writing something
2965 to the temporary file first.  You will need to seek() to do the
2966 reading.
2967
2968 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
2969 changed this (ie Configure -Uuseperlio), you can open file handles to
2970 "in memory" files held in Perl scalars via:
2971
2972     open($fh, '>', \$variable) || ..
2973
2974 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2975 file, you have to close it first:
2976
2977     close STDOUT;
2978     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2979
2980 Examples:
2981
2982     $ARTICLE = 100;
2983     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2984     while (<ARTICLE>) {...
2985
2986     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2987     # if the open fails, output is discarded
2988
2989     open(DBASE, '+<', 'dbase.mine')             # open for update
2990         or die "Can't open 'dbase.mine' for update: $!";
2991
2992     open(DBASE, '+<dbase.mine')                 # ditto
2993         or die "Can't open 'dbase.mine' for update: $!";
2994
2995     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2996         or die "Can't start caesar: $!";
2997
2998     open(ARTICLE, "caesar <$article |")         # ditto
2999         or die "Can't start caesar: $!";
3000
3001     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3002         or die "Can't start sort: $!";
3003
3004     # in memory files
3005     open(MEMORY,'>', \$var)
3006         or die "Can't open memory file: $!";
3007     print MEMORY "foo!\n";                      # output will end up in $var
3008
3009     # process argument list of files along with any includes
3010
3011     foreach $file (@ARGV) {
3012         process($file, 'fh00');
3013     }
3014
3015     sub process {
3016         my($filename, $input) = @_;
3017         $input++;               # this is a string increment
3018         unless (open($input, $filename)) {
3019             print STDERR "Can't open $filename: $!\n";
3020             return;
3021         }
3022
3023         local $_;
3024         while (<$input>) {              # note use of indirection
3025             if (/^#include "(.*)"/) {
3026                 process($1, $input);
3027                 next;
3028             }
3029             #...                # whatever
3030         }
3031     }
3032
3033 See L<perliol> for detailed info on PerlIO.
3034
3035 You may also, in the Bourne shell tradition, specify an EXPR beginning
3036 with C<< '>&' >>, in which case the rest of the string is interpreted
3037 as the name of a filehandle (or file descriptor, if numeric) to be
3038 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3039 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3040 The mode you specify should match the mode of the original filehandle.
3041 (Duping a filehandle does not take into account any existing contents
3042 of IO buffers.) If you use the 3 arg form then you can pass either a
3043 number, the name of a filehandle or the normal "reference to a glob".
3044
3045 Here is a script that saves, redirects, and restores C<STDOUT> and
3046 C<STDERR> using various methods:
3047
3048     #!/usr/bin/perl
3049     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3050     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3051
3052     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3053     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3054
3055     select STDERR; $| = 1;      # make unbuffered
3056     select STDOUT; $| = 1;      # make unbuffered
3057
3058     print STDOUT "stdout 1\n";  # this works for
3059     print STDERR "stderr 1\n";  # subprocesses too
3060
3061     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3062     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3063
3064     print STDOUT "stdout 2\n";
3065     print STDERR "stderr 2\n";
3066
3067 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3068 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3069 that file descriptor (and not call L<dup(2)>); this is more
3070 parsimonious of file descriptors.  For example:
3071
3072     # open for input, reusing the fileno of $fd
3073     open(FILEHANDLE, "<&=$fd")
3074
3075 or
3076
3077     open(FILEHANDLE, "<&=", $fd)
3078
3079 or
3080
3081     # open for append, using the fileno of OLDFH
3082     open(FH, ">>&=", OLDFH)
3083
3084 or
3085
3086     open(FH, ">>&=OLDFH")
3087
3088 Being parsimonious on filehandles is also useful (besides being
3089 parsimonious) for example when something is dependent on file
3090 descriptors, like for example locking using flock().  If you do just
3091 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3092 descriptor as B, and therefore flock(A) will not flock(B), and vice
3093 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3094 the same file descriptor.
3095
3096 Note that if you are using Perls older than 5.8.0, Perl will be using
3097 the standard C libraries' fdopen() to implement the "=" functionality.
3098 On many UNIX systems fdopen() fails when file descriptors exceed a
3099 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3100 most often the default.
3101
3102 You can see whether Perl has been compiled with PerlIO or not by
3103 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3104 is C<define>, you have PerlIO, otherwise you don't.
3105
3106 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3107 with 2-arguments (or 1-argument) form of open(), then
3108 there is an implicit fork done, and the return value of open is the pid
3109 of the child within the parent process, and C<0> within the child
3110 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3111 The filehandle behaves normally for the parent, but i/o to that
3112 filehandle is piped from/to the STDOUT/STDIN of the child process.
3113 In the child process the filehandle isn't opened--i/o happens from/to
3114 the new STDOUT or STDIN.  Typically this is used like the normal
3115 piped open when you want to exercise more control over just how the
3116 pipe command gets executed, such as when you are running setuid, and
3117 don't want to have to scan shell commands for metacharacters.
3118 The following triples are more or less equivalent:
3119
3120     open(FOO, "|tr '[a-z]' '[A-Z]'");
3121     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3122     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3123     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3124
3125     open(FOO, "cat -n '$file'|");
3126     open(FOO, '-|', "cat -n '$file'");
3127     open(FOO, '-|') || exec 'cat', '-n', $file;
3128     open(FOO, '-|', "cat", '-n', $file);
3129
3130 The last example in each block shows the pipe as "list form", which is
3131 not yet supported on all platforms.  A good rule of thumb is that if
3132 your platform has true C<fork()> (in other words, if your platform is
3133 UNIX) you can use the list form.
3134
3135 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3136
3137 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3138 output before any operation that may do a fork, but this may not be
3139 supported on some platforms (see L<perlport>).  To be safe, you may need
3140 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3141 of C<IO::Handle> on any open handles.
3142
3143 On systems that support a close-on-exec flag on files, the flag will
3144 be set for the newly opened file descriptor as determined by the value
3145 of $^F.  See L<perlvar/$^F>.
3146
3147 Closing any piped filehandle causes the parent process to wait for the
3148 child to finish, and returns the status value in C<$?> and
3149 C<${^CHILD_ERROR_NATIVE}>.
3150
3151 The filename passed to 2-argument (or 1-argument) form of open() will
3152 have leading and trailing whitespace deleted, and the normal
3153 redirection characters honored.  This property, known as "magic open",
3154 can often be used to good effect.  A user could specify a filename of
3155 F<"rsh cat file |">, or you could change certain filenames as needed:
3156
3157     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3158     open(FH, $filename) or die "Can't open $filename: $!";
3159
3160 Use 3-argument form to open a file with arbitrary weird characters in it,
3161
3162     open(FOO, '<', $file);
3163
3164 otherwise it's necessary to protect any leading and trailing whitespace:
3165
3166     $file =~ s#^(\s)#./$1#;
3167     open(FOO, "< $file\0");
3168
3169 (this may not work on some bizarre filesystems).  One should
3170 conscientiously choose between the I<magic> and 3-arguments form
3171 of open():
3172
3173     open IN, $ARGV[0];
3174
3175 will allow the user to specify an argument of the form C<"rsh cat file |">,
3176 but will not work on a filename which happens to have a trailing space, while
3177
3178     open IN, '<', $ARGV[0];
3179
3180 will have exactly the opposite restrictions.
3181
3182 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3183 should use the C<sysopen> function, which involves no such magic (but
3184 may use subtly different filemodes than Perl open(), which is mapped
3185 to C fopen()).  This is
3186 another way to protect your filenames from interpretation.  For example:
3187
3188     use IO::Handle;
3189     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3190         or die "sysopen $path: $!";
3191     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3192     print HANDLE "stuff $$\n";
3193     seek(HANDLE, 0, 0);
3194     print "File contains: ", <HANDLE>;
3195
3196 Using the constructor from the C<IO::Handle> package (or one of its
3197 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3198 filehandles that have the scope of whatever variables hold references to
3199 them, and automatically close whenever and however you leave that scope:
3200
3201     use IO::File;
3202     #...
3203     sub read_myfile_munged {
3204         my $ALL = shift;
3205         my $handle = new IO::File;
3206         open($handle, "myfile") or die "myfile: $!";
3207         $first = <$handle>
3208             or return ();     # Automatically closed here.
3209         mung $first or die "mung failed";       # Or here.
3210         return $first, <$handle> if $ALL;       # Or here.
3211         $first;                                 # Or here.
3212     }
3213
3214 See L</seek> for some details about mixing reading and writing.
3215
3216 =item opendir DIRHANDLE,EXPR
3217
3218 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3219 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3220 DIRHANDLE may be an expression whose value can be used as an indirect
3221 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3222 scalar variable (or array or hash element), the variable is assigned a
3223 reference to a new anonymous dirhandle.
3224 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3225
3226 =item ord EXPR
3227
3228 =item ord
3229
3230 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3231 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3232 uses C<$_>.
3233
3234 For the reverse, see L</chr>.
3235 See L<perlunicode> and L<encoding> for more about Unicode.
3236
3237 =item our EXPR
3238
3239 =item our EXPR TYPE
3240
3241 =item our EXPR : ATTRS
3242
3243 =item our TYPE EXPR : ATTRS
3244
3245 C<our> associates a simple name with a package variable in the current
3246 package for the remander of the lexical scope.  The listed variables
3247 are declared to be valid globals within the enclosing block, file, or
3248 C<eval>.  That is, it has the same scoping rules as a "my"
3249 declaration, but does not create a local variable.  When C<use strict
3250 'vars'> is in effect, the C<our> declaration lets you use the declared
3251 global variable without qualifying it with a package name.  (But only
3252 within the lexical scope of the C<our> declaration.  In this it
3253 differs from "use vars", which is package scoped.)
3254
3255 If more than one value is listed, the list must be placed in
3256 parentheses.
3257
3258     our $foo;
3259     our($bar, $baz);
3260
3261 An C<our> declaration declares a global variable that will be visible
3262 across its entire lexical scope, even across package boundaries.  The
3263 package in which the variable is entered is determined at the point
3264 of the declaration, not at the point of use.  This means the following
3265 behavior holds:
3266
3267     package Foo;
3268     our $bar;           # declares $Foo::bar for rest of lexical scope
3269     $bar = 20;
3270
3271     package Bar;
3272     print $bar;         # prints 20 as it refers to $Foo::bar
3273
3274 Multiple C<our> declarations in the same lexical scope are allowed
3275 if they are in different packages.  If they happen to be in the same
3276 package, Perl will emit warnings if you have asked for them.
3277
3278     use warnings;
3279     package Foo;
3280     our $bar;           # declares $Foo::bar for rest of lexical scope
3281     $bar = 20;
3282
3283     package Bar;
3284     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3285     print $bar;         # prints 30
3286
3287     our $bar;           # emits warning
3288
3289 An C<our> declaration may also have a list of attributes associated
3290 with it.
3291
3292 The exact semantics and interface of TYPE and ATTRS are still
3293 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3294 and attributes are handled using the C<attributes> pragma, or starting
3295 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3296 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3297 L<attributes>, and L<Attribute::Handlers>.
3298
3299 The only currently recognized C<our()> attribute is C<unique> which
3300 indicates that a single copy of the global is to be used by all
3301 interpreters should the program happen to be running in a
3302 multi-interpreter environment. (The default behaviour would be for
3303 each interpreter to have its own copy of the global.)  Examples:
3304
3305     our @EXPORT : unique = qw(foo);
3306     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3307     our $VERSION : unique = "1.00";
3308
3309 Note that this attribute also has the effect of making the global
3310 readonly when the first new interpreter is cloned (for example,
3311 when the first new thread is created).
3312
3313 Multi-interpreter environments can come to being either through the
3314 fork() emulation on Windows platforms, or by embedding perl in a
3315 multi-threaded application.  The C<unique> attribute does nothing in
3316 all other environments.
3317
3318 Warning: the current implementation of this attribute operates on the
3319 typeglob associated with the variable; this means that C<our $x : unique>
3320 also has the effect of C<our @x : unique; our %x : unique>. This may be
3321 subject to change.
3322
3323 =item pack TEMPLATE,LIST
3324
3325 Takes a LIST of values and converts it into a string using the rules
3326 given by the TEMPLATE.  The resulting string is the concatenation of
3327 the converted values.  Typically, each converted value looks
3328 like its machine-level representation.  For example, on 32-bit machines
3329 an integer may be represented by a sequence of 4 bytes which will be 
3330 converted to a sequence of 4 characters.
3331
3332 The TEMPLATE is a sequence of characters that give the order and type
3333 of values, as follows:
3334
3335     a   A string with arbitrary binary data, will be null padded.
3336     A   A text (ASCII) string, will be space padded.
3337     Z   A null terminated (ASCIZ) string, will be null padded.
3338
3339     b   A bit string (ascending bit order inside each byte, like vec()).
3340     B   A bit string (descending bit order inside each byte).
3341     h   A hex string (low nybble first).
3342     H   A hex string (high nybble first).
3343
3344     c   A signed char (8-bit) value.
3345     C   An unsigned C char (octet) even under Unicode. Should normally not
3346         be used. See U and W instead.
3347     W   An unsigned char value (can be greater than 255).
3348
3349     s   A signed short (16-bit) value.
3350     S   An unsigned short value.
3351
3352     l   A signed long (32-bit) value.
3353     L   An unsigned long value.
3354
3355     q   A signed quad (64-bit) value.
3356     Q   An unsigned quad value.
3357           (Quads are available only if your system supports 64-bit
3358            integer values _and_ if Perl has been compiled to support those.
3359            Causes a fatal error otherwise.)
3360
3361     i   A signed integer value.
3362     I   A unsigned integer value.
3363           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3364            size depends on what a local C compiler calls 'int'.)
3365  
3366     n   An unsigned short (16-bit) in "network" (big-endian) order.
3367     N   An unsigned long (32-bit) in "network" (big-endian) order.
3368     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3369     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3370
3371     j   A Perl internal signed integer value (IV).
3372     J   A Perl internal unsigned integer value (UV).
3373
3374     f   A single-precision float in the native format.
3375     d   A double-precision float in the native format.
3376
3377     F   A Perl internal floating point value (NV) in the native format
3378     D   A long double-precision float in the native format.
3379           (Long doubles are available only if your system supports long
3380            double values _and_ if Perl has been compiled to support those.
3381            Causes a fatal error otherwise.)
3382
3383     p   A pointer to a null-terminated string.
3384     P   A pointer to a structure (fixed-length string).
3385
3386     u   A uuencoded string.
3387     U   A Unicode character number.  Encodes to UTF-8 internally
3388         (or UTF-EBCDIC in EBCDIC platforms).
3389
3390     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3391         details).  Its bytes represent an unsigned integer in base 128,
3392         most significant digit first, with as few digits as possible.  Bit
3393         eight (the high bit) is set on each byte except the last.
3394
3395     x   A null byte.
3396     X   Back up a byte.
3397     @   Null fill or truncate to absolute position, counted from the
3398         start of the innermost ()-group.
3399     .   Null fill or truncate to absolute position specified by value.
3400     (   Start of a ()-group.
3401
3402 Some letters in the TEMPLATE may optionally be followed by one or
3403 more of these modifiers (the second column lists the letters for
3404 which the modifier is valid):
3405
3406     !   sSlLiI     Forces native (short, long, int) sizes instead
3407                    of fixed (16-/32-bit) sizes.
3408
3409         xX         Make x and X act as alignment commands.
3410
3411         nNvV       Treat integers as signed instead of unsigned.
3412
3413         @.         Specify position as byte offset in the internal
3414                    representation of the packed string. Efficient but
3415                    dangerous.
3416
3417     >   sSiIlLqQ   Force big-endian byte-order on the type.
3418         jJfFdDpP   (The "big end" touches the construct.)
3419
3420     <   sSiIlLqQ   Force little-endian byte-order on the type.
3421         jJfFdDpP   (The "little end" touches the construct.)
3422
3423 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3424 in which case they force a certain byte-order on all components of
3425 that group, including subgroups.
3426
3427 The following rules apply:
3428
3429 =over 8
3430
3431 =item *
3432
3433 Each letter may optionally be followed by a number giving a repeat
3434 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3435 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3436 that many values from the LIST.  A C<*> for the repeat count means to
3437 use however many items are left, except for C<@>, C<x>, C<X>, where it
3438 is equivalent to C<0>, for <.> where it means relative to string start
3439 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3440 A numeric repeat count may optionally be enclosed in brackets, as in
3441 C<pack 'C[80]', @arr>.
3442
3443 One can replace the numeric repeat count by a template enclosed in brackets;
3444 then the packed length of this template in bytes is used as a count.
3445 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3446 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3447 If the template in brackets contains alignment commands (such as C<x![d]>),
3448 its packed length is calculated as if the start of the template has the maximal
3449 possible alignment.
3450
3451 When used with C<Z>, C<*> results in the addition of a trailing null
3452 byte (so the packed result will be one longer than the byte C<length>
3453 of the item).
3454
3455 When used with C<@>, the repeat count represents an offset from the start
3456 of the innermost () group.
3457
3458 When used with C<.>, the repeat count is used to determine the starting
3459 position from where the value offset is calculated. If the repeat count
3460 is 0, it's relative to the current position. If the repeat count is C<*>,
3461 the offset is relative to the start of the packed string. And if its an
3462 integer C<n> the offset is relative to the start of the n-th innermost
3463 () group (or the start of the string if C<n> is bigger then the group
3464 level).
3465
3466 The repeat count for C<u> is interpreted as the maximal number of bytes
3467 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3468 count should not be more than 65.
3469
3470 =item *
3471
3472 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3473 string of length count, padding with nulls or spaces as necessary.  When
3474 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3475 after the first null, and C<a> returns data verbatim.
3476
3477 If the value-to-pack is too long, it is truncated.  If too long and an
3478 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3479 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3480 count is 0).
3481
3482 =item *
3483
3484 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3485 Each character of the input field of pack() generates 1 bit of the result.
3486 Each result bit is based on the least-significant bit of the corresponding
3487 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3488 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3489
3490 Starting from the beginning of the input string of pack(), each 8-tuple
3491 of characters is converted to 1 character of output.  With format C<b>
3492 the first character of the 8-tuple determines the least-significant bit of a
3493 character, and with format C<B> it determines the most-significant bit of
3494 a character.
3495
3496 If the length of the input string is not exactly divisible by 8, the
3497 remainder is packed as if the input string were padded by null characters
3498 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3499
3500 If the input string of pack() is longer than needed, extra characters are 
3501 ignored. A C<*> for the repeat count of pack() means to use all the 
3502 characters of the input field.  On unpack()ing the bits are converted to a 
3503 string of C<"0">s and C<"1">s.
3504
3505 =item *
3506
3507 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3508 representable as hexadecimal digits, 0-9a-f) long.
3509
3510 Each character of the input field of pack() generates 4 bits of the result.
3511 For non-alphabetical characters the result is based on the 4 least-significant
3512 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3513 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3514 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3515 is compatible with the usual hexadecimal digits, so that C<"a"> and
3516 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3517 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3518
3519 Starting from the beginning of the input string of pack(), each pair
3520 of characters is converted to 1 character of output.  With format C<h> the
3521 first character of the pair determines the least-significant nybble of the
3522 output character, and with format C<H> it determines the most-significant
3523 nybble.
3524
3525 If the length of the input string is not even, it behaves as if padded
3526 by a null character at the end.  Similarly, during unpack()ing the "extra"
3527 nybbles are ignored.
3528
3529 If the input string of pack() is longer than needed, extra characters are
3530 ignored.
3531 A C<*> for the repeat count of pack() means to use all the characters of
3532 the input field.  On unpack()ing the nybbles are converted to a string
3533 of hexadecimal digits.
3534
3535 =item *
3536
3537 The C<p> type packs a pointer to a null-terminated string.  You are
3538 responsible for ensuring the string is not a temporary value (which can
3539 potentially get deallocated before you get around to using the packed result).
3540 The C<P> type packs a pointer to a structure of the size indicated by the
3541 length.  A NULL pointer is created if the corresponding value for C<p> or
3542 C<P> is C<undef>, similarly for unpack().
3543
3544 If your system has a strange pointer size (i.e. a pointer is neither as
3545 big as an int nor as big as a long), it may not be possible to pack or
3546 unpack pointers in big- or little-endian byte order.  Attempting to do
3547 so will result in a fatal error.
3548
3549 =item *
3550
3551 The C</> template character allows packing and unpacking of a sequence of
3552 items where the packed structure contains a packed item count followed by 
3553 the packed items themselves.
3554 You write I<length-item>C</>I<sequence-item>.
3555
3556 The I<length-item> can be any C<pack> template letter, and describes
3557 how the length value is packed.  The ones likely to be of most use are
3558 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3559 SNMP) and C<N> (for Sun XDR).
3560
3561 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3562 the minimum of that and the number of available items is used as argument
3563 for the I<length-item>. If it has no repeat count or uses a '*', the number
3564 of available items is used. For C<unpack> the repeat count is always obtained
3565 by decoding the packed item count, and the I<sequence-item> must not have a
3566 repeat count.
3567
3568 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3569 the I<length-item> is a string length, not a number of strings. If there is
3570 an explicit repeat count for pack, the packed string will be adjusted to that
3571 given length.
3572
3573     unpack 'W/a', "\04Gurusamy";        gives ('Guru')
3574     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond', 'J')
3575     pack 'n/a* w/a','hello,','world';   gives "\000\006hello,\005world"
3576     pack 'a/W2', ord('a') .. ord('z');  gives '2ab'
3577
3578 The I<length-item> is not returned explicitly from C<unpack>.
3579
3580 Adding a count to the I<length-item> letter is unlikely to do anything
3581 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3582 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3583 which Perl does not regard as legal in numeric strings.
3584
3585 =item *
3586
3587 The integer types C<s>, C<S>, C<l>, and C<L> may be
3588 followed by a C<!> modifier to signify native shorts or
3589 longs--as you can see from above for example a bare C<l> does mean
3590 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3591 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3592 see whether using C<!> makes any difference by
3593
3594         print length(pack("s")), " ", length(pack("s!")), "\n";
3595         print length(pack("l")), " ", length(pack("l!")), "\n";
3596
3597 C<i!> and C<I!> also work but only because of completeness;
3598 they are identical to C<i> and C<I>.
3599
3600 The actual sizes (in bytes) of native shorts, ints, longs, and long
3601 longs on the platform where Perl was built are also available via
3602 L<Config>:
3603
3604        use Config;
3605        print $Config{shortsize},    "\n";
3606        print $Config{intsize},      "\n";
3607        print $Config{longsize},     "\n";
3608        print $Config{longlongsize}, "\n";
3609
3610 (The C<$Config{longlongsize}> will be undefined if your system does
3611 not support long longs.)
3612
3613 =item *
3614
3615 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3616 are inherently non-portable between processors and operating systems
3617 because they obey the native byteorder and endianness.  For example a
3618 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3619 (arranged in and handled by the CPU registers) into bytes as
3620
3621         0x12 0x34 0x56 0x78     # big-endian
3622         0x78 0x56 0x34 0x12     # little-endian
3623
3624 Basically, the Intel and VAX CPUs are little-endian, while everybody
3625 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3626 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3627 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3628 mode.
3629
3630 The names `big-endian' and `little-endian' are comic references to
3631 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3632 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3633 the egg-eating habits of the Lilliputians.
3634
3635 Some systems may have even weirder byte orders such as
3636
3637         0x56 0x78 0x12 0x34
3638         0x34 0x12 0x78 0x56
3639
3640 You can see your system's preference with
3641
3642         print join(" ", map { sprintf "%#02x", $_ }
3643                             unpack("W*",pack("L",0x12345678))), "\n";
3644
3645 The byteorder on the platform where Perl was built is also available
3646 via L<Config>:
3647
3648         use Config;
3649         print $Config{byteorder}, "\n";
3650
3651 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3652 and C<'87654321'> are big-endian.
3653
3654 If you want portable packed integers you can either use the formats
3655 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3656 modifiers.  These modifiers are only available as of perl 5.9.2.
3657 See also L<perlport>.
3658
3659 =item *
3660
3661 All integer and floating point formats as well as C<p> and C<P> and
3662 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3663 to force big- or little- endian byte-order, respectively.
3664 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3665 signed integers, 64-bit integers and floating point values.  However,
3666 there are some things to keep in mind.
3667
3668 Exchanging signed integers between different platforms only works
3669 if all platforms store them in the same format.  Most platforms store
3670 signed integers in two's complement, so usually this is not an issue.
3671
3672 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3673 formats on big- or little-endian machines.  Otherwise, attempting to
3674 do so will result in a fatal error.
3675
3676 Forcing big- or little-endian byte-order on floating point values for
3677 data exchange can only work if all platforms are using the same
3678 binary representation (e.g. IEEE floating point format).  Even if all
3679 platforms are using IEEE, there may be subtle differences.  Being able
3680 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3681 but also very dangerous if you don't know exactly what you're doing.
3682 It is definetely not a general way to portably store floating point
3683 values.
3684
3685 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3686 all types inside the group that accept the byte-order modifiers,
3687 including all subgroups.  It will silently be ignored for all other
3688 types.  You are not allowed to override the byte-order within a group
3689 that already has a byte-order modifier suffix.
3690
3691 =item *
3692
3693 Real numbers (floats and doubles) are in the native machine format only;
3694 due to the multiplicity of floating formats around, and the lack of a
3695 standard "network" representation, no facility for interchange has been
3696 made.  This means that packed floating point data written on one machine
3697 may not be readable on another - even if both use IEEE floating point
3698 arithmetic (as the endian-ness of the memory representation is not part
3699 of the IEEE spec).  See also L<perlport>.
3700
3701 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3702 modifiers to force big- or little-endian byte-order on floating point values.
3703
3704 Note that Perl uses doubles (or long doubles, if configured) internally for
3705 all numeric calculation, and converting from double into float and thence back
3706 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3707 will not in general equal $foo).
3708
3709 =item *
3710
3711 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3712 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3713 where the packed string is processed in its UTF-8-encoded Unicode form on
3714 a byte by byte basis. Character mode is the default unless the format string 
3715 starts with an C<U>. You can switch mode at any moment with an explicit 
3716 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3717 or until the end of the ()-group in which it was entered.
3718
3719 =item *
3720
3721 You must yourself do any alignment or padding by inserting for example
3722 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3723 could know where the characters are going to or coming from.  Therefore
3724 C<pack> (and C<unpack>) handle their output and input as flat
3725 sequences of characters.
3726
3727 =item *
3728
3729 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3730 take a repeat count, both as postfix, and for unpack() also via the C</>
3731 template character. Within each repetition of a group, positioning with
3732 C<@> starts again at 0. Therefore, the result of
3733
3734     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3735
3736 is the string "\0a\0\0bc".
3737
3738 =item *
3739
3740 C<x> and C<X> accept C<!> modifier.  In this case they act as
3741 alignment commands: they jump forward/back to the closest position
3742 aligned at a multiple of C<count> characters. For example, to pack() or
3743 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3744 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3745 aligned on the double's size.
3746
3747 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3748 both result in no-ops.
3749
3750 =item *
3751
3752 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3753 will represent signed 16-/32-bit integers in big-/little-endian order.
3754 This is only portable if all platforms sharing the packed data use the
3755 same binary representation for signed integers (e.g. all platforms are
3756 using two's complement representation).
3757
3758 =item *
3759
3760 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3761 White space may be used to separate pack codes from each other, but
3762 modifiers and a repeat count must follow immediately.
3763
3764 =item *
3765
3766 If TEMPLATE requires more arguments to pack() than actually given, pack()
3767 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3768 to pack() than actually given, extra arguments are ignored.
3769
3770 =back
3771
3772 Examples:
3773
3774     $foo = pack("WWWW",65,66,67,68);
3775     # foo eq "ABCD"
3776     $foo = pack("W4",65,66,67,68);
3777     # same thing
3778     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3779     # same thing with Unicode circled letters.
3780     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3781     # same thing with Unicode circled letters. You don't get the UTF-8
3782     # bytes because the U at the start of the format caused a switch to
3783     # U0-mode, so the UTF-8 bytes get joined into characters
3784     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3785     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3786     # This is the UTF-8 encoding of the string in the previous example
3787
3788     $foo = pack("ccxxcc",65,66,67,68);
3789     # foo eq "AB\0\0CD"
3790
3791     # note: the above examples featuring "W" and "c" are true
3792     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3793     # and UTF-8.  In EBCDIC the first example would be
3794     # $foo = pack("WWWW",193,194,195,196);
3795
3796     $foo = pack("s2",1,2);
3797     # "\1\0\2\0" on little-endian
3798     # "\0\1\0\2" on big-endian
3799
3800     $foo = pack("a4","abcd","x","y","z");
3801     # "abcd"
3802
3803     $foo = pack("aaaa","abcd","x","y","z");
3804     # "axyz"
3805
3806     $foo = pack("a14","abcdefg");
3807     # "abcdefg\0\0\0\0\0\0\0"
3808
3809     $foo = pack("i9pl", gmtime);
3810     # a real struct tm (on my system anyway)
3811
3812     $utmp_template = "Z8 Z8 Z16 L";
3813     $utmp = pack($utmp_template, @utmp1);
3814     # a struct utmp (BSDish)
3815
3816     @utmp2 = unpack($utmp_template, $utmp);
3817     # "@utmp1" eq "@utmp2"
3818
3819     sub bintodec {
3820         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3821     }
3822
3823     $foo = pack('sx2l', 12, 34);
3824     # short 12, two zero bytes padding, long 34
3825     $bar = pack('s@4l', 12, 34);
3826     # short 12, zero fill to position 4, long 34
3827     # $foo eq $bar
3828     $baz = pack('s.l', 12, 4, 34);
3829     # short 12, zero fill to position 4, long 34
3830
3831     $foo = pack('nN', 42, 4711);
3832     # pack big-endian 16- and 32-bit unsigned integers
3833     $foo = pack('S>L>', 42, 4711);
3834     # exactly the same
3835     $foo = pack('s<l<', -42, 4711);
3836     # pack little-endian 16- and 32-bit signed integers
3837     $foo = pack('(sl)<', -42, 4711);
3838     # exactly the same
3839
3840 The same template may generally also be used in unpack().
3841
3842 =item package NAMESPACE
3843
3844 =item package
3845
3846 Declares the compilation unit as being in the given namespace.  The scope
3847 of the package declaration is from the declaration itself through the end
3848 of the enclosing block, file, or eval (the same as the C<my> operator).
3849 All further unqualified dynamic identifiers will be in this namespace.
3850 A package statement affects only dynamic variables--including those
3851 you've used C<local> on--but I<not> lexical variables, which are created
3852 with C<my>.  Typically it would be the first declaration in a file to
3853 be included by the C<require> or C<use> operator.  You can switch into a
3854 package in more than one place; it merely influences which symbol table
3855 is used by the compiler for the rest of that block.  You can refer to
3856 variables and filehandles in other packages by prefixing the identifier
3857 with the package name and a double colon:  C<$Package::Variable>.
3858 If the package name is null, the C<main> package as assumed.  That is,
3859 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3860 still seen in older code).
3861
3862 If NAMESPACE is omitted, then there is no current package, and all
3863 identifiers must be fully qualified or lexicals.  However, you are
3864 strongly advised not to make use of this feature. Its use can cause
3865 unexpected behaviour, even crashing some versions of Perl. It is
3866 deprecated, and will be removed from a future release.
3867
3868 See L<perlmod/"Packages"> for more information about packages, modules,
3869 and classes.  See L<perlsub> for other scoping issues.
3870
3871 =item pipe READHANDLE,WRITEHANDLE
3872
3873 Opens a pair of connected pipes like the corresponding system call.
3874 Note that if you set up a loop of piped processes, deadlock can occur
3875 unless you are very careful.  In addition, note that Perl's pipes use
3876 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3877 after each command, depending on the application.
3878
3879 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3880 for examples of such things.
3881
3882 On systems that support a close-on-exec flag on files, the flag will be set
3883 for the newly opened file descriptors as determined by the value of $^F.
3884 See L<perlvar/$^F>.
3885
3886 =item pop ARRAY
3887
3888 =item pop
3889
3890 Pops and returns the last value of the array, shortening the array by
3891 one element.  Has an effect similar to
3892
3893     $ARRAY[$#ARRAY--]
3894
3895 If there are no elements in the array, returns the undefined value
3896 (although this may happen at other times as well).  If ARRAY is
3897 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3898 array in subroutines, just like C<shift>.
3899
3900 =item pos SCALAR
3901
3902 =item pos
3903
3904 Returns the offset of where the last C<m//g> search left off for the variable
3905 in question (C<$_> is used when the variable is not specified).  Note that
3906 0 is a valid match offset, while C<undef> indicates that the search position
3907 is reset (usually due to match failure, but can also be because no match has
3908 yet been performed on the scalar). C<pos> directly accesses the location used
3909 by the regexp engine to store the offset, so assigning to C<pos> will change
3910 that offset, and so will also influence the C<\G> zero-width assertion in
3911 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
3912 the return from C<pos> won't change either in this case.  See L<perlre> and
3913 L<perlop>.
3914
3915 =item print FILEHANDLE LIST
3916
3917 =item print LIST
3918
3919 =item print
3920
3921 Prints a string or a list of strings.  Returns true if successful.
3922 FILEHANDLE may be a scalar variable name, in which case the variable
3923 contains the name of or a reference to the filehandle, thus introducing
3924 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3925 the next token is a term, it may be misinterpreted as an operator
3926 unless you interpose a C<+> or put parentheses around the arguments.)
3927 If FILEHANDLE is omitted, prints by default to standard output (or
3928 to the last selected output channel--see L</select>).  If LIST is
3929 also omitted, prints C<$_> to the currently selected output channel.
3930 To set the default output channel to something other than STDOUT
3931 use the select operation.  The current value of C<$,> (if any) is
3932 printed between each LIST item.  The current value of C<$\> (if
3933 any) is printed after the entire LIST has been printed.  Because
3934 print takes a LIST, anything in the LIST is evaluated in list
3935 context, and any subroutine that you call will have one or more of
3936 its expressions evaluated in list context.  Also be careful not to
3937 follow the print keyword with a left parenthesis unless you want
3938 the corresponding right parenthesis to terminate the arguments to
3939 the print--interpose a C<+> or put parentheses around all the
3940 arguments.
3941
3942 Note that if you're storing FILEHANDLEs in an array, or if you're using
3943 any other expression more complex than a scalar variable to retrieve it,
3944 you will have to use a block returning the filehandle value instead:
3945
3946     print { $files[$i] } "stuff\n";
3947     print { $OK ? STDOUT : STDERR } "stuff\n";
3948
3949 =item printf FILEHANDLE FORMAT, LIST
3950
3951 =item printf FORMAT, LIST
3952
3953 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3954 (the output record separator) is not appended.  The first argument
3955 of the list will be interpreted as the C<printf> format. See C<sprintf>
3956 for an explanation of the format argument. If C<use locale> is in effect,
3957 the character used for the decimal point in formatted real numbers is
3958 affected by the LC_NUMERIC locale.  See L<perllocale>.
3959
3960 Don't fall into the trap of using a C<printf> when a simple
3961 C<print> would do.  The C<print> is more efficient and less
3962 error prone.
3963
3964 =item prototype FUNCTION
3965
3966 Returns the prototype of a function as a string (or C<undef> if the
3967 function has no prototype).  FUNCTION is a reference to, or the name of,
3968 the function whose prototype you want to retrieve.
3969
3970 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3971 name for Perl builtin.  If the builtin is not I<overridable> (such as
3972 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3973 C<system>) returns C<undef> because the builtin does not really behave
3974 like a Perl function.  Otherwise, the string describing the equivalent
3975 prototype is returned.
3976
3977 =item push ARRAY,LIST
3978
3979 Treats ARRAY as a stack, and pushes the values of LIST
3980 onto the end of ARRAY.  The length of ARRAY increases by the length of
3981 LIST.  Has the same effect as
3982
3983     for $value (LIST) {
3984         $ARRAY[++$#ARRAY] = $value;
3985     }
3986
3987 but is more efficient.  Returns the new number of elements in the array.
3988
3989 =item q/STRING/
3990
3991 =item qq/STRING/
3992
3993 =item qr/STRING/
3994
3995 =item qx/STRING/
3996
3997 =item qw/STRING/
3998
3999 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4000
4001 =item quotemeta EXPR
4002
4003 =item quotemeta
4004
4005 Returns the value of EXPR with all non-"word"
4006 characters backslashed.  (That is, all characters not matching
4007 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4008 returned string, regardless of any locale settings.)
4009 This is the internal function implementing
4010 the C<\Q> escape in double-quoted strings.
4011
4012 If EXPR is omitted, uses C<$_>.
4013
4014 =item rand EXPR
4015
4016 =item rand
4017
4018 Returns a random fractional number greater than or equal to C<0> and less
4019 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4020 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4021 also special-cased as C<1> - this has not been documented before perl 5.8.0
4022 and is subject to change in future versions of perl.  Automatically calls
4023 C<srand> unless C<srand> has already been called.  See also C<srand>.
4024
4025 Apply C<int()> to the value returned by C<rand()> if you want random
4026 integers instead of random fractional numbers.  For example,
4027
4028     int(rand(10))
4029
4030 returns a random integer between C<0> and C<9>, inclusive.
4031
4032 (Note: If your rand function consistently returns numbers that are too
4033 large or too small, then your version of Perl was probably compiled
4034 with the wrong number of RANDBITS.)
4035
4036 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4037
4038 =item read FILEHANDLE,SCALAR,LENGTH
4039
4040 Attempts to read LENGTH I<characters> of data into variable SCALAR
4041 from the specified FILEHANDLE.  Returns the number of characters
4042 actually read, C<0> at end of file, or undef if there was an error (in
4043 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4044 so that the last character actually read is the last character of the
4045 scalar after the read.
4046
4047 An OFFSET may be specified to place the read data at some place in the
4048 string other than the beginning.  A negative OFFSET specifies
4049 placement at that many characters counting backwards from the end of
4050 the string.  A positive OFFSET greater than the length of SCALAR
4051 results in the string being padded to the required size with C<"\0">
4052 bytes before the result of the read is appended.
4053
4054 The call is actually implemented in terms of either Perl's or system's
4055 fread() call.  To get a true read(2) system call, see C<sysread>.
4056
4057 Note the I<characters>: depending on the status of the filehandle,
4058 either (8-bit) bytes or characters are read.  By default all
4059 filehandles operate on bytes, but for example if the filehandle has
4060 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4061 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4062 characters, not bytes.  Similarly for the C<:encoding> pragma:
4063 in that case pretty much any characters can be read.
4064
4065 =item readdir DIRHANDLE
4066
4067 Returns the next directory entry for a directory opened by C<opendir>.
4068 If used in list context, returns all the rest of the entries in the
4069 directory.  If there are no more entries, returns an undefined value in
4070 scalar context or a null list in list context.
4071
4072 If you're planning to filetest the return values out of a C<readdir>, you'd
4073 better prepend the directory in question.  Otherwise, because we didn't
4074 C<chdir> there, it would have been testing the wrong file.
4075
4076     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4077     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4078     closedir DIR;
4079
4080 =item readline EXPR
4081
4082 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4083 context, each call reads and returns the next line, until end-of-file is
4084 reached, whereupon the subsequent call returns undef.  In list context,
4085 reads until end-of-file is reached and returns a list of lines.  Note that
4086 the notion of "line" used here is however you may have defined it
4087 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4088
4089 When C<$/> is set to C<undef>, when readline() is in scalar
4090 context (i.e. file slurp mode), and when an empty file is read, it
4091 returns C<''> the first time, followed by C<undef> subsequently.
4092
4093 This is the internal function implementing the C<< <EXPR> >>
4094 operator, but you can use it directly.  The C<< <EXPR> >>
4095 operator is discussed in more detail in L<perlop/"I/O Operators">.
4096
4097     $line = <STDIN>;
4098     $line = readline(*STDIN);           # same thing
4099
4100 If readline encounters an operating system error, C<$!> will be set with the
4101 corresponding error message.  It can be helpful to check C<$!> when you are
4102 reading from filehandles you don't trust, such as a tty or a socket.  The
4103 following example uses the operator form of C<readline>, and takes the necessary
4104 steps to ensure that C<readline> was successful.
4105
4106     for (;;) {
4107         undef $!;
4108         unless (defined( $line = <> )) {
4109             die $! if $!;
4110             last; # reached EOF
4111         }
4112         # ...
4113     }
4114
4115 =item readlink EXPR
4116
4117 =item readlink
4118
4119 Returns the value of a symbolic link, if symbolic links are
4120 implemented.  If not, gives a fatal error.  If there is some system
4121 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4122 omitted, uses C<$_>.
4123
4124 =item readpipe EXPR
4125
4126 EXPR is executed as a system command.
4127 The collected standard output of the command is returned.
4128 In scalar context, it comes back as a single (potentially
4129 multi-line) string.  In list context, returns a list of lines
4130 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4131 This is the internal function implementing the C<qx/EXPR/>
4132 operator, but you can use it directly.  The C<qx/EXPR/>
4133 operator is discussed in more detail in L<perlop/"I/O Operators">.
4134
4135 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4136
4137 Receives a message on a socket.  Attempts to receive LENGTH characters
4138 of data into variable SCALAR from the specified SOCKET filehandle.
4139 SCALAR will be grown or shrunk to the length actually read.  Takes the
4140 same flags as the system call of the same name.  Returns the address
4141 of the sender if SOCKET's protocol supports this; returns an empty
4142 string otherwise.  If there's an error, returns the undefined value.
4143 This call is actually implemented in terms of recvfrom(2) system call.
4144 See L<perlipc/"UDP: Message Passing"> for examples.
4145
4146 Note the I<characters>: depending on the status of the socket, either
4147 (8-bit) bytes or characters are received.  By default all sockets
4148 operate on bytes, but for example if the socket has been changed using
4149 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4150 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4151 characters, not bytes.  Similarly for the C<:encoding> pragma:
4152 in that case pretty much any characters can be read.
4153
4154 =item redo LABEL
4155
4156 =item redo
4157
4158 The C<redo> command restarts the loop block without evaluating the
4159 conditional again.  The C<continue> block, if any, is not executed.  If
4160 the LABEL is omitted, the command refers to the innermost enclosing
4161 loop.  This command is normally used by programs that want to lie to
4162 themselves about what was just input:
4163
4164     # a simpleminded Pascal comment stripper
4165     # (warning: assumes no { or } in strings)
4166     LINE: while (<STDIN>) {
4167         while (s|({.*}.*){.*}|$1 |) {}
4168         s|{.*}| |;
4169         if (s|{.*| |) {
4170             $front = $_;
4171             while (<STDIN>) {
4172                 if (/}/) {      # end of comment?
4173                     s|^|$front\{|;
4174                     redo LINE;
4175                 }
4176             }
4177         }
4178         print;
4179     }
4180
4181 C<redo> cannot be used to retry a block which returns a value such as
4182 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4183 a grep() or map() operation.
4184
4185 Note that a block by itself is semantically identical to a loop
4186 that executes once.  Thus C<redo> inside such a block will effectively
4187 turn it into a looping construct.
4188
4189 See also L</continue> for an illustration of how C<last>, C<next>, and
4190 C<redo> work.
4191
4192 =item ref EXPR
4193
4194 =item ref
4195
4196 Returns a non-empty string if EXPR is a reference, the empty
4197 string otherwise. If EXPR
4198 is not specified, C<$_> will be used.  The value returned depends on the
4199 type of thing the reference is a reference to.
4200 Builtin types include:
4201
4202     SCALAR
4203     ARRAY
4204     HASH
4205     CODE
4206     REF
4207     GLOB
4208     LVALUE
4209
4210 If the referenced object has been blessed into a package, then that package
4211 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4212
4213     if (ref($r) eq "HASH") {
4214         print "r is a reference to a hash.\n";
4215     }
4216     unless (ref($r)) {
4217         print "r is not a reference at all.\n";
4218     }
4219
4220 See also L<perlref>.
4221
4222 =item rename OLDNAME,NEWNAME
4223
4224 Changes the name of a file; an existing file NEWNAME will be
4225 clobbered.  Returns true for success, false otherwise.
4226
4227 Behavior of this function varies wildly depending on your system
4228 implementation.  For example, it will usually not work across file system
4229 boundaries, even though the system I<mv> command sometimes compensates
4230 for this.  Other restrictions include whether it works on directories,
4231 open files, or pre-existing files.  Check L<perlport> and either the
4232 rename(2) manpage or equivalent system documentation for details.
4233
4234 =item require VERSION
4235
4236 =item require EXPR
4237
4238 =item require
4239
4240 Demands a version of Perl specified by VERSION, or demands some semantics
4241 specified by EXPR or by C<$_> if EXPR is not supplied.
4242
4243 VERSION may be either a numeric argument such as 5.006, which will be
4244 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4245 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4246 VERSION is greater than the version of the current Perl interpreter.
4247 Compare with L</use>, which can do a similar check at compile time.
4248
4249 Specifying VERSION as a literal of the form v5.6.1 should generally be
4250 avoided, because it leads to misleading error messages under earlier
4251 versions of Perl which do not support this syntax.  The equivalent numeric
4252 version should be used instead.
4253
4254     require v5.6.1;     # run time version check
4255     require 5.6.1;      # ditto
4256     require 5.006_001;  # ditto; preferred for backwards compatibility
4257
4258 Otherwise, demands that a library file be included if it hasn't already
4259 been included.  The file is included via the do-FILE mechanism, which is
4260 essentially just a variety of C<eval>.  Has semantics similar to the
4261 following subroutine:
4262
4263     sub require {
4264        my ($filename) = @_;
4265        if (exists $INC{$filename}) {
4266            return 1 if $INC{$filename};
4267            die "Compilation failed in require";
4268        }
4269        my ($realfilename,$result);
4270        ITER: {
4271            foreach $prefix (@INC) {
4272                $realfilename = "$prefix/$filename";
4273                if (-f $realfilename) {
4274                    $INC{$filename} = $realfilename;
4275                    $result = do $realfilename;
4276                    last ITER;
4277                }
4278            }
4279            die "Can't find $filename in \@INC";
4280        }
4281        if ($@) {
4282            $INC{$filename} = undef;
4283            die $@;
4284        } elsif (!$result) {
4285            delete $INC{$filename};
4286            die "$filename did not return true value";
4287        } else {
4288            return $result;
4289        }
4290     }
4291
4292 Note that the file will not be included twice under the same specified
4293 name.
4294
4295 The file must return true as the last statement to indicate
4296 successful execution of any initialization code, so it's customary to
4297 end such a file with C<1;> unless you're sure it'll return true
4298 otherwise.  But it's better just to put the C<1;>, in case you add more
4299 statements.
4300
4301 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4302 replaces "F<::>" with "F</>" in the filename for you,
4303 to make it easy to load standard modules.  This form of loading of
4304 modules does not risk altering your namespace.
4305
4306 In other words, if you try this:
4307
4308         require Foo::Bar;    # a splendid bareword
4309
4310 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4311 directories specified in the C<@INC> array.
4312
4313 But if you try this:
4314
4315         $class = 'Foo::Bar';
4316         require $class;      # $class is not a bareword
4317     #or
4318         require "Foo::Bar";  # not a bareword because of the ""
4319
4320 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4321 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4322
4323         eval "require $class";
4324
4325 Now that you understand how C<require> looks for files in the case of
4326 a bareword argument, there is a little extra functionality going on
4327 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4328 it will first look for a filename with a "F<.pmc>" extension.  A file
4329 with this extension is assumed to be Perl bytecode generated by
4330 L<B::Bytecode|B::Bytecode>.  If this file is found, and its modification
4331 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4332 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4333
4334 You can also insert hooks into the import facility, by putting directly
4335 Perl code into the @INC array.  There are three forms of hooks: subroutine
4336 references, array references and blessed objects.
4337
4338 Subroutine references are the simplest case.  When the inclusion system
4339 walks through @INC and encounters a subroutine, this subroutine gets
4340 called with two parameters, the first being a reference to itself, and the
4341 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4342 subroutine should return C<undef> or a filehandle, from which the file to
4343 include will be read.  If C<undef> is returned, C<require> will look at
4344 the remaining elements of @INC.
4345
4346 If the hook is an array reference, its first element must be a subroutine
4347 reference.  This subroutine is called as above, but the first parameter is
4348 the array reference.  This enables to pass indirectly some arguments to
4349 the subroutine.
4350
4351 In other words, you can write:
4352
4353     push @INC, \&my_sub;
4354     sub my_sub {
4355         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4356         ...
4357     }
4358
4359 or:
4360
4361     push @INC, [ \&my_sub, $x, $y, ... ];
4362     sub my_sub {
4363         my ($arrayref, $filename) = @_;
4364         # Retrieve $x, $y, ...
4365         my @parameters = @$arrayref[1..$#$arrayref];
4366         ...
4367     }
4368
4369 If the hook is an object, it must provide an INC method, that will be
4370 called as above, the first parameter being the object itself.  (Note that
4371 you must fully qualify the sub's name, as it is always forced into package
4372 C<main>.)  Here is a typical code layout:
4373
4374     # In Foo.pm
4375     package Foo;
4376     sub new { ... }
4377     sub Foo::INC {
4378         my ($self, $filename) = @_;
4379         ...
4380     }
4381
4382     # In the main program
4383     push @INC, new Foo(...);
4384
4385 Note that these hooks are also permitted to set the %INC entry
4386 corresponding to the files they have loaded. See L<perlvar/%INC>.
4387
4388 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4389
4390 =item reset EXPR
4391
4392 =item reset
4393
4394 Generally used in a C<continue> block at the end of a loop to clear
4395 variables and reset C<??> searches so that they work again.  The
4396 expression is interpreted as a list of single characters (hyphens
4397 allowed for ranges).  All variables and arrays beginning with one of
4398 those letters are reset to their pristine state.  If the expression is
4399 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4400 only variables or searches in the current package.  Always returns
4401 1.  Examples:
4402
4403     reset 'X';          # reset all X variables
4404     reset 'a-z';        # reset lower case variables
4405     reset;              # just reset ?one-time? searches
4406
4407 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4408 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4409 variables--lexical variables are unaffected, but they clean themselves
4410 up on scope exit anyway, so you'll probably want to use them instead.
4411 See L</my>.
4412
4413 =item return EXPR
4414
4415 =item return
4416
4417 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4418 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4419 context, depending on how the return value will be used, and the context
4420 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4421 is given, returns an empty list in list context, the undefined value in
4422 scalar context, and (of course) nothing at all in a void context.
4423
4424 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4425 or do FILE will automatically return the value of the last expression
4426 evaluated.)
4427
4428 =item reverse LIST
4429
4430 In list context, returns a list value consisting of the elements
4431 of LIST in the opposite order.  In scalar context, concatenates the
4432 elements of LIST and returns a string value with all characters
4433 in the opposite order.
4434
4435     print reverse <>;           # line tac, last line first
4436
4437     undef $/;                   # for efficiency of <>
4438     print scalar reverse <>;    # character tac, last line tsrif
4439
4440 Used without arguments in scalar context, reverse() reverses C<$_>.
4441
4442 This operator is also handy for inverting a hash, although there are some
4443 caveats.  If a value is duplicated in the original hash, only one of those
4444 can be represented as a key in the inverted hash.  Also, this has to
4445 unwind one hash and build a whole new one, which may take some time
4446 on a large hash, such as from a DBM file.
4447
4448     %by_name = reverse %by_address;     # Invert the hash
4449
4450 =item rewinddir DIRHANDLE
4451
4452 Sets the current position to the beginning of the directory for the
4453 C<readdir> routine on DIRHANDLE.
4454
4455 =item rindex STR,SUBSTR,POSITION
4456
4457 =item rindex STR,SUBSTR
4458
4459 Works just like index() except that it returns the position of the LAST
4460 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4461 last occurrence at or before that position.
4462
4463 =item rmdir FILENAME
4464
4465 =item rmdir
4466
4467 Deletes the directory specified by FILENAME if that directory is
4468 empty.  If it succeeds it returns true, otherwise it returns false and
4469 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4470
4471 =item s///
4472
4473 The substitution operator.  See L<perlop>.
4474
4475 =item scalar EXPR
4476
4477 Forces EXPR to be interpreted in scalar context and returns the value
4478 of EXPR.
4479
4480     @counts = ( scalar @a, scalar @b, scalar @c );
4481
4482 There is no equivalent operator to force an expression to
4483 be interpolated in list context because in practice, this is never
4484 needed.  If you really wanted to do so, however, you could use
4485 the construction C<@{[ (some expression) ]}>, but usually a simple
4486 C<(some expression)> suffices.
4487
4488 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4489 parenthesized list, this behaves as a scalar comma expression, evaluating
4490 all but the last element in void context and returning the final element
4491 evaluated in scalar context.  This is seldom what you want.
4492
4493 The following single statement:
4494
4495         print uc(scalar(&foo,$bar)),$baz;
4496
4497 is the moral equivalent of these two:
4498
4499         &foo;
4500         print(uc($bar),$baz);
4501
4502 See L<perlop> for more details on unary operators and the comma operator.
4503
4504 =item seek FILEHANDLE,POSITION,WHENCE
4505
4506 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4507 FILEHANDLE may be an expression whose value gives the name of the
4508 filehandle.  The values for WHENCE are C<0> to set the new position
4509 I<in bytes> to POSITION, C<1> to set it to the current position plus
4510 POSITION, and C<2> to set it to EOF plus POSITION (typically
4511 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4512 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4513 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4514 otherwise.
4515
4516 Note the I<in bytes>: even if the filehandle has been set to
4517 operate on characters (for example by using the C<:utf8> open
4518 layer), tell() will return byte offsets, not character offsets
4519 (because implementing that would render seek() and tell() rather slow).
4520
4521 If you want to position file for C<sysread> or C<syswrite>, don't use
4522 C<seek>--buffering makes its effect on the file's system position
4523 unpredictable and non-portable.  Use C<sysseek> instead.
4524
4525 Due to the rules and rigors of ANSI C, on some systems you have to do a
4526 seek whenever you switch between reading and writing.  Amongst other
4527 things, this may have the effect of calling stdio's clearerr(3).
4528 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4529
4530     seek(TEST,0,1);
4531
4532 This is also useful for applications emulating C<tail -f>.  Once you hit
4533 EOF on your read, and then sleep for a while, you might have to stick in a
4534 seek() to reset things.  The C<seek> doesn't change the current position,
4535 but it I<does> clear the end-of-file condition on the handle, so that the
4536 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4537
4538 If that doesn't work (some IO implementations are particularly
4539 cantankerous), then you may need something more like this:
4540
4541     for (;;) {
4542         for ($curpos = tell(FILE); $_ = <FILE>;
4543              $curpos = tell(FILE)) {
4544             # search for some stuff and put it into files
4545         }
4546         sleep($for_a_while);
4547         seek(FILE, $curpos, 0);
4548     }
4549
4550 =item seekdir DIRHANDLE,POS
4551
4552 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4553 must be a value returned by C<telldir>.  Has the same caveats about
4554 possible directory compaction as the corresponding system library
4555 routine.
4556
4557 =item select FILEHANDLE
4558
4559 =item select
4560
4561 Returns the currently selected filehandle.  Sets the current default
4562 filehandle for output, if FILEHANDLE is supplied.  This has two
4563 effects: first, a C<write> or a C<print> without a filehandle will
4564 default to this FILEHANDLE.  Second, references to variables related to
4565 output will refer to this output channel.  For example, if you have to
4566 set the top of form format for more than one output channel, you might
4567 do the following:
4568
4569     select(REPORT1);
4570     $^ = 'report1_top';
4571     select(REPORT2);
4572     $^ = 'report2_top';
4573
4574 FILEHANDLE may be an expression whose value gives the name of the
4575 actual filehandle.  Thus:
4576
4577     $oldfh = select(STDERR); $| = 1; select($oldfh);
4578
4579 Some programmers may prefer to think of filehandles as objects with
4580 methods, preferring to write the last example as:
4581
4582     use IO::Handle;
4583     STDERR->autoflush(1);
4584
4585 =item select RBITS,WBITS,EBITS,TIMEOUT
4586
4587 This calls the select(2) system call with the bit masks specified, which
4588 can be constructed using C<fileno> and C<vec>, along these lines:
4589
4590     $rin = $win = $ein = '';
4591     vec($rin,fileno(STDIN),1) = 1;
4592     vec($win,fileno(STDOUT),1) = 1;
4593     $ein = $rin | $win;
4594
4595 If you want to select on many filehandles you might wish to write a
4596 subroutine:
4597
4598     sub fhbits {
4599         my(@fhlist) = split(' ',$_[0]);
4600         my($bits);
4601         for (@fhlist) {
4602             vec($bits,fileno($_),1) = 1;
4603         }
4604         $bits;
4605     }