installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  13     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41     $Is_W32 = 0;
  42     $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63
  64 $otherperls = 1;
  65 my $destdir = '';
  66 while (@ARGV) {
  67     $nonono = 1 if $ARGV[0] eq '-n';
  68     $dostrip = 1 if $ARGV[0] eq '-s';
  69     $versiononly = 1 if $ARGV[0] eq '-v';
  70     $versiononly = 0 if $ARGV[0] eq '+v';
  71     $silent = 1 if $ARGV[0] eq '-S';
  72     $otherperls = 0 if $ARGV[0] eq '-o';
  73     $force = 1 if $ARGV[0] eq '-f';
  74     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  75     $archname = 1 if $ARGV[0] eq '-A';
  76     $nwinstall = 1 if $ARGV[0] eq '-netware';
  77     $nopods = 1 if $ARGV[0] eq '-p';
  78     $destdir = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
  79     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  80         print <<"EOT";
  81 Usage $0: [switches]
  82   -n        Don't actually run any commands; just print them.
  83   -s        Run strip on installed binaries.
  84   -v        Only install perl as a binary with the version number in the name.
  85             (Override whatever config.sh says)
  86   +v        Install perl as "perl" and as a binary with the version number in
  87             the name.  (Override whatever config.sh says)
  88   -S        Silent mode.
  89   -f        Force installation (don't check if same version is there)
  90   -o        Skip checking for other copies of perl in your PATH.
  91   -V        Verbose mode.
  92   -A        Also install perl with the architecture's name in the perl binary's
  93             name.
  94   -p        Don't install the pod files. [This will break use diagnostics;]
  95   -netware  Install correctly on a Netware server.
  96 EOT
  97         exit;
  98     }
  99     shift;
 100 }
 101
 102 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 103 my (@scripts, @tolink);
 104 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 105 while (<SCRIPTS>) {
 106     next if /^#/;
 107     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 108     next if /a2p/; # a2p is binary, to be installed separately
 109     chomp;
 110     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 111         push @scripts, $1;
 112         push @tolink, [$1, $2];
 113     } else {
 114         push @scripts, $_;
 115     }
 116 }
 117 close SCRIPTS;
 118
 119 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 120
 121 my @pods = $nopods ? () : (<pod/*.pod>);
 122
 123 # Specify here any .pm files that are actually architecture-dependent.
 124 # (Those included with XS extensions under ext/ are automatically
 125 # added later.)
 126 # Now that the default privlib has the full perl version number included,
 127 # we no longer have to play the trick of sticking version-specific .pm
 128 # files under the archlib directory.
 129 my %archpms = (
 130     Config => 1,
 131     lib => 1,
 132     Cwd => 1,
 133 );
 134
 135 if ($^O eq 'dos') {
 136     push(@scripts,'djgpp/fixpmain');
 137     $archpms{config} = $archpms{filehand} = 1;
 138 }
 139
 140 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 141     push(@scripts, map("$_.exe", @scripts));
 142 }
 143
 144 find(sub {
 145     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 146         my($path, $modname) = ($1,$2);
 147
 148         # strip trailing component first
 149         $path =~ s{/[^/]*$}{};
 150
 151         # strip optional "/lib";
 152         $path =~ s{/lib\b}{};
 153
 154         # strip any leading /
 155         $path =~ s{^/}{};
 156
 157         # reconstitute canonical module name
 158         $modname = "$path/$modname" if length $path;
 159
 160         # remember it
 161         $archpms{$modname} = 1;
 162     }
 163 }, 'ext');
 164
 165 # print "[$_]\n" for sort keys %archpms;
 166
 167 my $ver = $Config{version};
 168 my $release = substr($],0,3);   # Not used currently.
 169 my $patchlevel = substr($],3,2);
 170 die "Patchlevel of perl ($patchlevel)",
 171     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 172         if $patchlevel != $Config{'PERL_VERSION'};
 173
 174 # Fetch some frequently-used items from %Config
 175 my $installbin = "$destdir$Config{installbin}";
 176 my $installscript = "$destdir$Config{installscript}";
 177 my $installprivlib = "$destdir$Config{installprivlib}";
 178 my $installarchlib = "$destdir$Config{installarchlib}";
 179 my $installsitelib = "$destdir$Config{installsitelib}";
 180 my $installsitearch = "$destdir$Config{installsitearch}";
 181 my $installman1dir = "$destdir$Config{installman1dir}";
 182 my $man1ext = $Config{man1ext};
 183 my $libperl = $Config{libperl};
 184 # Shared library and dynamic loading suffixes.
 185 my $so = $Config{so};
 186 my $dlext = $Config{dlext};
 187 my $dlsrc = $Config{dlsrc};
 188 if ($^O eq 'os390') {
 189     my $pwd;
 190     chomp($pwd=`pwd`);
 191     my $archlibexp = $Config{archlibexp};
 192     my $usedl = $Config{usedl};
 193     if ($usedl eq 'define') {
 194         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 195     }
 196 }
 197
 198 if ($nwinstall) {
 199     # This is required only if we are installing on a NetWare server
 200     $installscript = $Config{installnwscripts};
 201     $installprivlib = $Config{installnwlib};
 202     $installarchlib = $Config{installnwlib};
 203     $installsitelib = $Config{installnwlib};
 204 }
 205
 206 my $d_dosuid = $Config{d_dosuid};
 207 my $binexp = $Config{binexp};
 208
 209 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 210     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 211               \$installarchlib, \$installsitelib, \$installsitearch,
 212               \$installman1dir ) {
 213         $$_ = unixify($$_);  $$_ =~ s:/$::;
 214     }
 215 }
 216
 217 # Do some quick sanity checks.
 218
 219 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 220
 221    $installbin          || die "No installbin directory in config.sh\n";
 222 -d $installbin          || mkpath($installbin, $verbose, 0777);
 223 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 224 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 225         unless $installbin =~ m#^/afs/# || $nonono;
 226
 227 if (!$Is_NetWare) {
 228 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 229 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 230
 231 -f 't/rantests'         || $Is_W32
 232                         || warn "WARNING: You've never run 'make test' or",
 233                                 " some tests failed! (Installing anyway.)\n";
 234 } #if (!$Is_NetWare)
 235
 236 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 237     my $perldll;
 238
 239     if ($Is_Cygwin) {
 240         $perldll = $libperl;
 241         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 242         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 243         $perldll =~ s/^lib/cyg/;
 244         if ($Config{useshrplib} eq 'true') {
 245             # install ld2 and perlld as well
 246             foreach ('ld2', 'perlld') {
 247                 safe_unlink("$installbin/$_");
 248                 copy("$_", "$installbin/$_");
 249                 chmod(0755, "$installbin/$_");
 250             };
 251             open (LD2, ">$installbin/ld2");
 252             print LD2 <<SHELL;
 253 #!/bin/sh
 254 #
 255 # ld wrapper, passes all args to perlld;
 256 #
 257 for trythis in $installbin/perl
 258 do
 259   if [ -x \$trythis ]
 260   then
 261     \$trythis $installbin/perlld "\$\@"
 262     exit \$?
 263   fi
 264 done
 265 # hard luck!
 266 echo I see no perl executable around there
 267 echo perl is required to build dynamic libraries
 268 echo look if the path to perl in /bin/ld2 is correct
 269 exit 1
 270 SHELL
 271             close LD2;
 272             chmod(0755, "$installbin/ld2");
 273         };
 274     } else {
 275         $perldll = 'perl59.' . $dlext;
 276     }
 277
 278     if ($dlsrc ne "dl_none.xs") {
 279         -f $perldll || die "No perl DLL built\n";
 280     }
 281
 282     # Install the DLL
 283     safe_unlink("$installbin/$perldll");
 284     copy("$perldll", "$installbin/$perldll");
 285     chmod(0755, "$installbin/$perldll");
 286 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 287
 288 # This will be used to store the packlist
 289 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 290
 291 # First we install the version-numbered executables.
 292
 293 if ($Is_VMS) {
 294     safe_unlink("$installbin/$perl$exe_ext");
 295     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 296     chmod(0755, "$installbin/$perl$exe_ext");
 297     safe_unlink("$installbin/${perl}shr$exe_ext");
 298     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 299     chmod(0755, "$installbin/${perl}shr$exe_ext");
 300 }
 301 elsif ($^O eq 'mpeix') {
 302     # MPE lacks hard links and requires that executables with special
 303     # capabilities reside in the MPE namespace.
 304     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 305     # Install the primary executable into the MPE namespace as perlpath.
 306     copy("perl$exe_ext", $Config{perlpath});
 307     chmod(0755, $Config{perlpath});
 308     # Create a backup copy with the version number.
 309     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 310 }
 311 elsif ($^O ne 'dos') {
 312     if (!$Is_NetWare) {
 313         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 314         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 315         strip("$installbin/$perl_verbase$ver$exe_ext");
 316         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 317     }
 318     else {
 319         # If installing onto a NetWare server
 320         if ($nwinstall) {
 321             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 322             mkpath($Config{installnwsystem}, 1, 0777);
 323             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 324             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 325             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 326             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 327             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 328             mkpath($Config{installnwlcgi}, 1, 0777);
 329             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 330         }
 331     } #if (!$Is_NetWare)
 332 }
 333 else {
 334     safe_unlink("$installbin/$perl.exe");
 335     copy("perl.exe", "$installbin/$perl.exe");
 336 }
 337
 338 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 339 if ($d_dosuid) {
 340     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 341     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 342 }
 343
 344 # Install library files.
 345
 346 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 347
 348 mkpath($installprivlib, $verbose, 0777);
 349 mkpath($installarchlib, $verbose, 0777);
 350 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 351 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 352
 353 if (chdir "lib") {
 354     $do_installarchlib = ! samepath($installarchlib, '.');
 355     $do_installprivlib = ! samepath($installprivlib, '.');
 356     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 357
 358     if ($do_installarchlib || $do_installprivlib) {
 359         find(\&installlib, '.');
 360     }
 361     chdir ".." || die "Can't cd back to source directory: $!\n";
 362 }
 363 else {
 364     warn "Can't cd to lib to install lib files: $!\n";
 365 }
 366
 367 # Install header files and libraries.
 368 mkpath("$installarchlib/CORE", $verbose, 0777);
 369 my @corefiles;
 370 if ($Is_VMS) {  # We did core file selection during build
 371     my $coredir = "lib/$Config{archname}/$ver/CORE";
 372     $coredir =~ tr/./_/;
 373     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 374 }
 375 else {
 376     # [als] hard-coded 'libperl' name... not good!
 377     @corefiles = <*.h libperl*.*>;
 378
 379     # AIX needs perl.exp installed as well.
 380     push(@corefiles,'perl.exp') if $^O eq 'aix';
 381     if ($^O eq 'mpeix') {
 382         # MPE needs mpeixish.h installed as well.
 383         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 384         push(@corefiles,'mpeix/mpeixish.h');
 385     }
 386     # If they have built sperl.o...
 387     push(@corefiles,'sperl.o') if -f 'sperl.o';
 388 }
 389 foreach my $file (@corefiles) {
 390     # HP-UX (at least) needs to maintain execute permissions
 391     # on dynamically-loadable libraries. So we do it for all.
 392     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 393         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 394             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 395             chmod(0555, "$installarchlib/CORE/$file");
 396         } else {
 397             chmod(0444, "$installarchlib/CORE/$file");
 398         }
 399     }
 400 }
 401
 402 # Install main perl executables
 403 # Make links to ordinary names if installbin directory isn't current directory.
 404
 405 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 406     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 407     if ($^O eq 'mpeix') {
 408         # MPE doesn't support hard links, so use a symlink.
 409         # We don't want another cloned copy.
 410         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 411     } elsif ($^O eq 'vos') {
 412         # VOS doesn't support hard links, so use a symlink.
 413         symlink("$installbin/$perl_verbase$ver$exe_ext",
 414                 "$installbin/$perl$exe_ext");
 415     } else {
 416         link("$installbin/$perl_verbase$ver$exe_ext",
 417                 "$installbin/$perl$exe_ext");
 418     }
 419     link("$installbin/s$perl_verbase$ver$exe_ext",
 420             "$installbin/suid$perl$exe_ext")
 421       if $d_dosuid;
 422 }
 423
 424 # For development purposes it can be very useful to have multiple perls
 425 # build for different "architectures" (eg threading or not) simultaneously.
 426 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 427     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 428     safe_unlink("$installbin/$archperl");
 429     if ($^O eq 'mpeix') {
 430         # MPE doesn't support hard links, so use a symlink.
 431         # We don't want another cloned copy.
 432         symlink($Config{perlpath}, "$installbin/$archperl");
 433     } elsif ($^O eq 'vos') {
 434         # VOS doesn't support hard links, so use a symlink.
 435         symlink("$installbin/$perl_verbase$ver$exe_ext",
 436                 "$installbin/$archperl");
 437     } else {
 438         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 439     }
 440 }
 441
 442 # Offer to install perl in a "standard" location
 443
 444 my $mainperl_is_instperl = 0;
 445
 446 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 447     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 448         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 449     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 450     my($instperl)       = "$installbin/$perl$exe_ext";
 451     my($expinstperl)    = "$binexp/$perl$exe_ext";
 452
 453     # First make sure $usrbinperl is not already the same as the perl we
 454     # just installed.
 455     if (-x $usrbinperl) {
 456         # Try to be clever about mainperl being a symbolic link
 457         # to binexp/perl if binexp and installbin are different.
 458         $mainperl_is_instperl =
 459             samepath($usrbinperl, $instperl) ||
 460             samepath($usrbinperl, $expinstperl) ||
 461              (($binexp ne $installbin) &&
 462               (-l $usrbinperl) &&
 463               ((readlink $usrbinperl) eq $expinstperl));
 464     }
 465     if (! $mainperl_is_instperl) {
 466         unlink($usrbinperl);
 467         ( $Config{'d_link'} eq 'define' &&
 468           eval { CORE::link $instperl, $usrbinperl } )  ||
 469         eval { symlink $expinstperl, $usrbinperl }      ||
 470         copy($instperl, $usrbinperl);
 471
 472         $mainperl_is_instperl = 1;
 473     }
 474 }
 475
 476 # Make links to ordinary names if installbin directory isn't current directory.
 477 if (!$Is_NetWare) {
 478     if (! samepath($installbin, 'x2p')) {
 479         my $base = 'a2p';
 480         $base .= $ver if $versiononly;
 481         safe_unlink("$installbin/$base$exe_ext");
 482         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 483         strip("$installbin/$base$exe_ext");
 484         chmod(0755, "$installbin/$base$exe_ext");
 485     }
 486 }
 487
 488 # cppstdin is just a script, but it is architecture-dependent, so
 489 # it can't safely be shared.  Place it in $installbin.
 490 # Note that Configure doesn't build cppstin if it isn't needed, so
 491 # we skip this if cppstdin doesn't exist.
 492 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 493     safe_unlink("$installbin/cppstdin");
 494     copy("cppstdin", "$installbin/cppstdin");
 495     chmod(0755, "$installbin/cppstdin");
 496 }
 497
 498 sub script_alias {
 499     my ($installscript, $orig, $alias, $scr_ext) = @_;
 500
 501     safe_unlink("$installscript/$alias$scr_ext");
 502     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 503         copy("$installscript/$orig$scr_ext",
 504              "$installscript/$alias$scr_ext");
 505     } elsif ($^O eq 'vos') {
 506         symlink("$installscript/$orig$scr_ext",
 507                 "$installscript/$alias$scr_ext");
 508     } else {
 509         link("$installscript/$orig$scr_ext",
 510              "$installscript/$alias$scr_ext");
 511     }
 512 }
 513
 514 # Install scripts.
 515 mkpath($installscript, $verbose, 0777);
 516 if ($versiononly) {
 517     for (@scripts) {
 518         (my $base = $_) =~ s#.*/##;
 519         $base .= $ver;
 520         copy($_,    "$installscript/$base");
 521         chmod(0755, "$installscript/$base");
 522     }
 523
 524     for (@tolink) {
 525         my ($from, $to) = map { "$_$ver" } @$_;
 526         (my $frbase = $from) =~ s#.*/##;
 527         (my $tobase = $to) =~ s#.*/##;
 528         script_alias($installscript, $frbase, $tobase, $scr_ext);
 529     }
 530 } else {
 531     for (@scripts) {
 532         (my $base = $_) =~ s#.*/##;
 533         copy($_, "$installscript/$base");
 534         chmod(0755, "$installscript/$base");
 535     }
 536
 537     for (@tolink) {
 538         my ($from, $to) = @$_;
 539         (my $frbase = $from) =~ s#.*/##;
 540         (my $tobase = $to) =~ s#.*/##;
 541         script_alias($installscript, $frbase, $tobase, $scr_ext);
 542     }
 543 }
 544
 545 # Install pod pages.  Where? I guess in $installprivlib/pod
 546 # ($installprivlib/pods for cygwin).
 547
 548 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 549 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 550     mkpath("${installprivlib}/$pod", $verbose, 0777);
 551
 552     # If Perl 5.003's perldiag.pod is there, rename it.
 553     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 554         read POD, $_, 4000;
 555         close POD;
 556         # Some of Perl 5.003's diagnostic messages ended with periods.
 557         if (/^=.*\.$/m) {
 558             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 559                                "${installprivlib}/$pod/perldiag-5.003.pod");
 560             print "  rename $from $to";
 561             rename($from, $to)
 562                 or warn "Couldn't rename $from to $to: $!\n"
 563                 unless $nonono;
 564         }
 565     }
 566
 567     for (@pods) {
 568         # $_ is a name like  pod/perl.pod
 569         (my $base = $_) =~ s#.*/##;
 570         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 571     }
 572
 573 }
 574
 575 # Check to make sure there aren't other perls around in installer's
 576 # path.  This is probably UNIX-specific.  Check all absolute directories
 577 # in the path except for where public executables are supposed to live.
 578 # Also skip $mainperl if the user opted to have it be a link to the
 579 # installed perl.
 580
 581 if (!$versiononly && $otherperls) {
 582     my ($path, @path);
 583     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 584     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 585     @path = split(/$dirsep/, $path);
 586     if ($Is_VMS) {
 587         my $i = 0;
 588         while (exists $ENV{'DCL$PATH' . $i}) {
 589             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 590             push(@path,$dir);
 591         }
 592     }
 593     my @otherperls;
 594     my %otherperls;
 595     for (@path) {
 596         next unless m,^/,;
 597         # Use &samepath here because some systems have other dirs linked
 598         # to $mainperldir (like SunOS)
 599         next if samepath($_, $binexp);
 600         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 601         my $otherperl = "$_/$perl$exe_ext";
 602         next if $otherperls{$otherperl}++;
 603         push(@otherperls, $otherperl)
 604             if (-x $otherperl && ! -d $otherperl);
 605     }
 606     if (@otherperls) {
 607         warn "\nWarning: $perl appears in your path in the following " .
 608             "locations beyond where\nwe just installed it:\n";
 609         for (@otherperls) {
 610             warn "    ", $_, "\n";
 611         }
 612         warn "\n";
 613     }
 614
 615 }
 616
 617 $packlist->write() unless $nonono;
 618 print "  Installation complete\n" if $verbose;
 619
 620 exit 0;
 621
 622 ###############################################################################
 623
 624 sub yn {
 625     my($prompt) = @_;
 626     my($answer);
 627     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 628     print STDERR $prompt;
 629     chop($answer = <STDIN>);
 630     $answer = $default if $answer =~ m/^\s*$/;
 631     ($answer =~ m/^[yY]/);
 632 }
 633
 634 sub unlink {
 635     my(@names) = @_;
 636     my($cnt) = 0;
 637
 638     return scalar(@names) if $Is_VMS;
 639
 640     foreach my $name (@names) {
 641         next unless -e $name;
 642         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 643         print "  unlink $name\n" if $verbose;
 644         ( CORE::unlink($name) and ++$cnt
 645           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 646     }
 647     return $cnt;
 648 }
 649
 650 sub safe_unlink {
 651     return if $nonono or $Is_VMS;
 652     my @names = @_;
 653     foreach my $name (@names) {
 654         next unless -e $name;
 655         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 656         print "  unlink $name\n" if $verbose;
 657         next if CORE::unlink($name);
 658         warn "Couldn't unlink $name: $!\n";
 659         if ($! =~ /busy/i) {
 660             print "  mv $name $name.old\n" if $verbose;
 661             safe_rename($name, "$name.old")
 662                 or warn "Couldn't rename $name: $!\n";
 663         }
 664     }
 665 }
 666
 667 sub safe_rename {
 668     my($from,$to) = @_;
 669     if (-f $to and not unlink($to)) {
 670         my($i);
 671         for ($i = 1; $i < 50; $i++) {
 672             last if rename($to, "$to.$i");
 673         }
 674         warn("Cannot rename to `$to.$i': $!"), return 0
 675            if $i >= 50; # Give up!
 676     }
 677     link($from,$to) || return 0;
 678     unlink($from);
 679 }
 680
 681 sub link {
 682     my($from,$to) = @_;
 683     my($success) = 0;
 684
 685     my $xfrom = $from;
 686     $xfrom =~ s/^\Q$destdir\E// if $destdir;
 687     my $xto = $to;
 688     $xto =~ s/^\Q$destdir\E// if $destdir;
 689     print $verbose ? "  ln $xfrom $xto\n" : "  $xto\n" unless $silent;
 690     eval {
 691         CORE::link($from, $to)
 692             ? $success++
 693             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 694               ? die "AFS"  # okay inside eval {}
 695               : die "Couldn't link $from to $to: $!\n"
 696           unless $nonono;
 697         $packlist->{$xto} = { from => $xfrom, type => 'link' };
 698     };
 699     if ($@) {
 700         warn $@;
 701         print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 702         print "  creating new version of $xto\n"
 703                  if $Is_VMS and -e $to and !$silent;
 704         File::Copy::copy($from, $to)
 705             ? $success++
 706             : warn "Couldn't copy $from to $to: $!\n"
 707           unless $nonono;
 708         $packlist->{$xto} = { type => 'file' };
 709     }
 710     $success;
 711 }
 712
 713 sub chmod {
 714     my($mode,$name) = @_;
 715
 716     return if ($^O eq 'dos');
 717     printf "  chmod %o %s\n", $mode, $name if $verbose;
 718     CORE::chmod($mode,$name)
 719         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 720       unless $nonono;
 721 }
 722
 723 sub copy {
 724     my($from,$to) = @_;
 725
 726     my $xto = $to;
 727     $xto =~ s/^\Q$destdir\E// if $destdir;
 728     print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 729     print "  creating new version of $xto\n" if $Is_VMS and -e $to and !$silent;
 730     File::Copy::copy($from, $to)
 731         || warn "Couldn't copy $from to $to: $!\n"
 732       unless $nonono;
 733     $packlist->{$xto} = { type => 'file' };
 734 }
 735
 736 sub samepath {
 737     my($p1, $p2) = @_;
 738
 739     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 740
 741     if ($p1 ne $p2) {
 742         my($dev1, $ino1, $dev2, $ino2);
 743         ($dev1, $ino1) = stat($p1);
 744         ($dev2, $ino2) = stat($p2);
 745         ($dev1 == $dev2 && $ino1 == $ino2);
 746     }
 747     else {
 748         1;
 749     }
 750 }
 751
 752 sub installlib {
 753     my $dir = $File::Find::dir;
 754     $dir =~ s#^\.(?![^/])/?##;
 755     local($depth) = $dir ? "lib/$dir" : "lib";
 756
 757     my $name = $_;
 758
 759     # Ignore version control directories.
 760     if (($name eq 'CVS' or $name eq 'RCS' or $name eq '.svn') and -d $name) {
 761         $File::Find::prune = 1;
 762         return;
 763     }
 764
 765     # ignore patch backups, RCS files, emacs backup & temp files and the
 766     # .exists files, .PL files, and test files.
 767     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$} ||
 768               $dir  =~ m{/t(?:/|$)};
 769     # ignore the cpan script in lib/CPAN/bin (installed later with other utils)
 770     return if $name eq 'cpan';
 771     # ignore the test extensions
 772     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 773
 774     $name = "$dir/$name" if $dir ne '';
 775
 776     my $installlib = $installprivlib;
 777     if ($dir =~ /^auto/ ||
 778           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 779           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
 780        ) {
 781         $installlib = $installarchlib;
 782         return unless $do_installarchlib;
 783     } else {
 784         return unless $do_installprivlib;
 785     }
 786
 787     if (-f $_) {
 788         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 789             $installlib = $installprivlib;
 790             #We're installing *.al and *.ix files into $installprivlib,
 791             #but we have to delete old *.al and *.ix files from the 5.000
 792             #distribution:
 793             #This might not work because $archname might have changed.
 794             unlink("$installarchlib/$name");
 795         }
 796         my $xname = "$installlib/$name";
 797         $xname =~ s/^\Q$destdir\E// if $destdir;
 798         $packlist->{$xname} = { type => 'file' };
 799         if ($force || compare($_, "$installlib/$name") || $nonono) {
 800             unlink("$installlib/$name");
 801             mkpath("$installlib/$dir", $verbose, 0777);
 802             # HP-UX (at least) needs to maintain execute permissions
 803             # on dynamically-loaded libraries.
 804             if ($Is_NetWare && !$nwinstall) {
 805                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 806                 # if copied will give problems when building new extensions.
 807                 # Has to be copied if we are installing on a NetWare server and hence
 808                 # the check !$nwinstall
 809                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 810                     copy_if_diff($_, "$installlib/$name")
 811                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 812                                   "$installlib/$name");
 813                 }
 814            } else {
 815                 if (copy_if_diff($_, "$installlib/$name")) {
 816                     if ($name =~ /\.(so|$dlext)$/o) {
 817                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 818                         chmod(0555, "$installlib/$name");
 819                     } else {
 820                         strip("-S", "$installlib/$name")
 821                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 822                         chmod(0444, "$installlib/$name");
 823                     }
 824                 }
 825             } #if ($Is_NetWare)
 826         }
 827     }
 828 }
 829
 830 # Copy $from to $to, only if $from is different than $to.
 831 # Also preserve modification times for .a libraries.
 832 # On some systems, if you do
 833 #   ranlib libperl.a
 834 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 835 # and then try to link against the installed libperl.a, you might
 836 # get an error message to the effect that the symbol table is older
 837 # than the library.
 838 # Return true if copying occurred.
 839
 840 sub copy_if_diff {
 841     my($from,$to)=@_;
 842     return 1 if (($^O eq 'VMS') && (-d $from));
 843     my $xto = $to;
 844     $xto =~ s/^\Q$destdir\E// if $destdir;
 845     my $perlpodbadsymlink;
 846     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 847         -l $from &&
 848         ! -e $from) {
 849         # Some Linux implementations have problems traversing over
 850         # multiple symlinks (when going over NFS?) and fail to read
 851         # the symlink target.  Combine this with the fact that some
 852         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 853         # and you end up with those pods not getting installed.
 854         $perlpodbadsymlink = 1;
 855     }
 856     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 857     $packlist->{$xto} = { type => 'file' };
 858     if ($force || compare($from, $to) || $nonono) {
 859         safe_unlink($to);   # In case we don't have write permissions.
 860         if ($nonono) {
 861             $from = $depth . "/" . $from if $depth;
 862         }
 863         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 864             $from = "README.$1";
 865         }
 866         copy($from, $to);
 867         # Restore timestamps if it's a .a library or for OS/2.
 868         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 869             my ($atime, $mtime) = (stat $from)[8,9];
 870             utime $atime, $mtime, $to;
 871         }
 872         1;
 873     }
 874 }
 875
 876 sub strip
 877 {
 878     my(@args) = @_;
 879
 880     return unless $dostrip;
 881
 882     my @opts;
 883     while (@args && $args[0] =~ /^(-\w+)$/) {
 884         push @opts, shift @args;
 885     }
 886
 887     foreach my $file (@args) {
 888         if (-f $file) {
 889             if ($verbose) {
 890                 print "  strip " . join(' ', @opts);
 891                 print " " if (@opts);
 892                 print "$file\n";
 893             }
 894             system("strip", @opts, $file);
 895         } else {
 896             print "# file '$file' skipped\n" if $verbose;
 897         }
 898     }
 899 }