cpan/IO-Compress/lib/IO/Uncompress/AnyInflate.pm

   1 package IO::Uncompress::AnyInflate ;
   2
   3 # for RFC1950, RFC1951 or RFC1952
   4
   5 use strict;
   6 use warnings;
   7 use bytes;
   8
   9 use IO::Compress::Base::Common  2.047 qw(createSelfTiedObject);
  10
  11 use IO::Uncompress::Adapter::Inflate  2.047 ();
  12
  13
  14 use IO::Uncompress::Base  2.047 ;
  15 use IO::Uncompress::Gunzip  2.047 ;
  16 use IO::Uncompress::Inflate  2.047 ;
  17 use IO::Uncompress::RawInflate  2.047 ;
  18 use IO::Uncompress::Unzip  2.047 ;
  19
  20 require Exporter ;
  21
  22 our ($VERSION, @ISA, @EXPORT_OK, %EXPORT_TAGS, $AnyInflateError);
  23
  24 $VERSION = '2.047';
  25 $AnyInflateError = '';
  26
  27 @ISA = qw( Exporter IO::Uncompress::Base );
  28 @EXPORT_OK = qw( $AnyInflateError anyinflate ) ;
  29 %EXPORT_TAGS = %IO::Uncompress::Base::DEFLATE_CONSTANTS ;
  30 push @{ $EXPORT_TAGS{all} }, @EXPORT_OK ;
  31 Exporter::export_ok_tags('all');
  32
  33 # TODO - allow the user to pick a set of the three formats to allow
  34 #        or just assume want to auto-detect any of the three formats.
  35
  36 sub new
  37 {
  38     my $class = shift ;
  39     my $obj = createSelfTiedObject($class, \$AnyInflateError);
  40     $obj->_create(undef, 0, @_);
  41 }
  42
  43 sub anyinflate
  44 {
  45     my $obj = createSelfTiedObject(undef, \$AnyInflateError);
  46     return $obj->_inf(@_) ;
  47 }
  48
  49 sub getExtraParams
  50 {
  51     use IO::Compress::Base::Common  2.047 qw(:Parse);
  52     return ( 'RawInflate' => [1, 1, Parse_boolean,  0] ) ;
  53 }
  54
  55 sub ckParams
  56 {
  57     my $self = shift ;
  58     my $got = shift ;
  59
  60     # any always needs both crc32 and adler32
  61     $got->value('CRC32' => 1);
  62     $got->value('ADLER32' => 1);
  63
  64     return 1;
  65 }
  66
  67 sub mkUncomp
  68 {
  69     my $self = shift ;
  70     my $got = shift ;
  71
  72     my ($obj, $errstr, $errno) = IO::Uncompress::Adapter::Inflate::mkUncompObject();
  73
  74     return $self->saveErrorString(undef, $errstr, $errno)
  75         if ! defined $obj;
  76
  77     *$self->{Uncomp} = $obj;
  78
  79      my @possible = qw( Inflate Gunzip Unzip );
  80      unshift @possible, 'RawInflate'
  81         if 1 || $got->value('RawInflate');
  82
  83      my $magic = $self->ckMagic( @possible );
  84
  85      if ($magic) {
  86         *$self->{Info} = $self->readHeader($magic)
  87             or return undef ;
  88
  89         return 1;
  90      }
  91
  92      return 0 ;
  93 }
  94
  95
  96
  97 sub ckMagic
  98 {
  99     my $self = shift;
 100     my @names = @_ ;
 101
 102     my $keep = ref $self ;
 103     for my $class ( map { "IO::Uncompress::$_" } @names)
 104     {
 105         bless $self => $class;
 106         my $magic = $self->ckMagic();
 107
 108         if ($magic)
 109         {
 110             #bless $self => $class;
 111             return $magic ;
 112         }
 113
 114         $self->pushBack(*$self->{HeaderPending})  ;
 115         *$self->{HeaderPending} = ''  ;
 116     }
 117
 118     bless $self => $keep;
 119     return undef;
 120 }
 121
 122 1 ;
 123
 124 __END__
 125
 126
 127 =head1 NAME
 128
 129 IO::Uncompress::AnyInflate - Uncompress zlib-based (zip, gzip) file/buffer
 130
 131 =head1 SYNOPSIS
 132
 133     use IO::Uncompress::AnyInflate qw(anyinflate $AnyInflateError) ;
 134
 135     my $status = anyinflate $input => $output [,OPTS]
 136         or die "anyinflate failed: $AnyInflateError\n";
 137
 138     my $z = new IO::Uncompress::AnyInflate $input [OPTS]
 139         or die "anyinflate failed: $AnyInflateError\n";
 140
 141     $status = $z->read($buffer)
 142     $status = $z->read($buffer, $length)
 143     $status = $z->read($buffer, $length, $offset)
 144     $line = $z->getline()
 145     $char = $z->getc()
 146     $char = $z->ungetc()
 147     $char = $z->opened()
 148
 149     $status = $z->inflateSync()
 150
 151     $data = $z->trailingData()
 152     $status = $z->nextStream()
 153     $data = $z->getHeaderInfo()
 154     $z->tell()
 155     $z->seek($position, $whence)
 156     $z->binmode()
 157     $z->fileno()
 158     $z->eof()
 159     $z->close()
 160
 161     $AnyInflateError ;
 162
 163     # IO::File mode
 164
 165     <$z>
 166     read($z, $buffer);
 167     read($z, $buffer, $length);
 168     read($z, $buffer, $length, $offset);
 169     tell($z)
 170     seek($z, $position, $whence)
 171     binmode($z)
 172     fileno($z)
 173     eof($z)
 174     close($z)
 175
 176 =head1 DESCRIPTION
 177
 178 This module provides a Perl interface that allows the reading of
 179 files/buffers that have been compressed in a number of formats that use the
 180 zlib compression library.
 181
 182 The formats supported are
 183
 184 =over 5
 185
 186 =item RFC 1950
 187
 188 =item RFC 1951 (optionally)
 189
 190 =item gzip (RFC 1952)
 191
 192 =item zip
 193
 194 =back
 195
 196 The module will auto-detect which, if any, of the supported
 197 compression formats is being used.
 198
 199 =head1 Functional Interface
 200
 201 A top-level function, C<anyinflate>, is provided to carry out
 202 "one-shot" uncompression between buffers and/or files. For finer
 203 control over the uncompression process, see the L</"OO Interface">
 204 section.
 205
 206     use IO::Uncompress::AnyInflate qw(anyinflate $AnyInflateError) ;
 207
 208     anyinflate $input => $output [,OPTS]
 209         or die "anyinflate failed: $AnyInflateError\n";
 210
 211 The functional interface needs Perl5.005 or better.
 212
 213 =head2 anyinflate $input => $output [, OPTS]
 214
 215 C<anyinflate> expects at least two parameters, C<$input> and C<$output>.
 216
 217 =head3 The C<$input> parameter
 218
 219 The parameter, C<$input>, is used to define the source of
 220 the compressed data.
 221
 222 It can take one of the following forms:
 223
 224 =over 5
 225
 226 =item A filename
 227
 228 If the C<$input> parameter is a simple scalar, it is assumed to be a
 229 filename. This file will be opened for reading and the input data
 230 will be read from it.
 231
 232 =item A filehandle
 233
 234 If the C<$input> parameter is a filehandle, the input data will be
 235 read from it.
 236 The string '-' can be used as an alias for standard input.
 237
 238 =item A scalar reference
 239
 240 If C<$input> is a scalar reference, the input data will be read
 241 from C<$$input>.
 242
 243 =item An array reference
 244
 245 If C<$input> is an array reference, each element in the array must be a
 246 filename.
 247
 248 The input data will be read from each file in turn.
 249
 250 The complete array will be walked to ensure that it only
 251 contains valid filenames before any data is uncompressed.
 252
 253 =item An Input FileGlob string
 254
 255 If C<$input> is a string that is delimited by the characters "<" and ">"
 256 C<anyinflate> will assume that it is an I<input fileglob string>. The
 257 input is the list of files that match the fileglob.
 258
 259 See L<File::GlobMapper|File::GlobMapper> for more details.
 260
 261 =back
 262
 263 If the C<$input> parameter is any other type, C<undef> will be returned.
 264
 265 =head3 The C<$output> parameter
 266
 267 The parameter C<$output> is used to control the destination of the
 268 uncompressed data. This parameter can take one of these forms.
 269
 270 =over 5
 271
 272 =item A filename
 273
 274 If the C<$output> parameter is a simple scalar, it is assumed to be a
 275 filename.  This file will be opened for writing and the uncompressed
 276 data will be written to it.
 277
 278 =item A filehandle
 279
 280 If the C<$output> parameter is a filehandle, the uncompressed data
 281 will be written to it.
 282 The string '-' can be used as an alias for standard output.
 283
 284 =item A scalar reference
 285
 286 If C<$output> is a scalar reference, the uncompressed data will be
 287 stored in C<$$output>.
 288
 289 =item An Array Reference
 290
 291 If C<$output> is an array reference, the uncompressed data will be
 292 pushed onto the array.
 293
 294 =item An Output FileGlob
 295
 296 If C<$output> is a string that is delimited by the characters "<" and ">"
 297 C<anyinflate> will assume that it is an I<output fileglob string>. The
 298 output is the list of files that match the fileglob.
 299
 300 When C<$output> is an fileglob string, C<$input> must also be a fileglob
 301 string. Anything else is an error.
 302
 303 See L<File::GlobMapper|File::GlobMapper> for more details.
 304
 305 =back
 306
 307 If the C<$output> parameter is any other type, C<undef> will be returned.
 308
 309 =head2 Notes
 310
 311 When C<$input> maps to multiple compressed files/buffers and C<$output> is
 312 a single file/buffer, after uncompression C<$output> will contain a
 313 concatenation of all the uncompressed data from each of the input
 314 files/buffers.
 315
 316 =head2 Optional Parameters
 317
 318 Unless specified below, the optional parameters for C<anyinflate>,
 319 C<OPTS>, are the same as those used with the OO interface defined in the
 320 L</"Constructor Options"> section below.
 321
 322 =over 5
 323
 324 =item C<< AutoClose => 0|1 >>
 325
 326 This option applies to any input or output data streams to
 327 C<anyinflate> that are filehandles.
 328
 329 If C<AutoClose> is specified, and the value is true, it will result in all
 330 input and/or output filehandles being closed once C<anyinflate> has
 331 completed.
 332
 333 This parameter defaults to 0.
 334
 335 =item C<< BinModeOut => 0|1 >>
 336
 337 When writing to a file or filehandle, set C<binmode> before writing to the
 338 file.
 339
 340 Defaults to 0.
 341
 342 =item C<< Append => 0|1 >>
 343
 344 The behaviour of this option is dependent on the type of output data
 345 stream.
 346
 347 =over 5
 348
 349 =item * A Buffer
 350
 351 If C<Append> is enabled, all uncompressed data will be append to the end of
 352 the output buffer. Otherwise the output buffer will be cleared before any
 353 uncompressed data is written to it.
 354
 355 =item * A Filename
 356
 357 If C<Append> is enabled, the file will be opened in append mode. Otherwise
 358 the contents of the file, if any, will be truncated before any uncompressed
 359 data is written to it.
 360
 361 =item * A Filehandle
 362
 363 If C<Append> is enabled, the filehandle will be positioned to the end of
 364 the file via a call to C<seek> before any uncompressed data is
 365 written to it.  Otherwise the file pointer will not be moved.
 366
 367 =back
 368
 369 When C<Append> is specified, and set to true, it will I<append> all uncompressed
 370 data to the output data stream.
 371
 372 So when the output is a filehandle it will carry out a seek to the eof
 373 before writing any uncompressed data. If the output is a filename, it will be opened for
 374 appending. If the output is a buffer, all uncompressed data will be
 375 appended to the existing buffer.
 376
 377 Conversely when C<Append> is not specified, or it is present and is set to
 378 false, it will operate as follows.
 379
 380 When the output is a filename, it will truncate the contents of the file
 381 before writing any uncompressed data. If the output is a filehandle
 382 its position will not be changed. If the output is a buffer, it will be
 383 wiped before any uncompressed data is output.
 384
 385 Defaults to 0.
 386
 387 =item C<< MultiStream => 0|1 >>
 388
 389 If the input file/buffer contains multiple compressed data streams, this
 390 option will uncompress the whole lot as a single data stream.
 391
 392 Defaults to 0.
 393
 394 =item C<< TrailingData => $scalar >>
 395
 396 Returns the data, if any, that is present immediately after the compressed
 397 data stream once uncompression is complete.
 398
 399 This option can be used when there is useful information immediately
 400 following the compressed data stream, and you don't know the length of the
 401 compressed data stream.
 402
 403 If the input is a buffer, C<trailingData> will return everything from the
 404 end of the compressed data stream to the end of the buffer.
 405
 406 If the input is a filehandle, C<trailingData> will return the data that is
 407 left in the filehandle input buffer once the end of the compressed data
 408 stream has been reached. You can then use the filehandle to read the rest
 409 of the input file.
 410
 411 Don't bother using C<trailingData> if the input is a filename.
 412
 413 If you know the length of the compressed data stream before you start
 414 uncompressing, you can avoid having to use C<trailingData> by setting the
 415 C<InputLength> option.
 416
 417 =back
 418
 419 =head2 Examples
 420
 421 To read the contents of the file C<file1.txt.Compressed> and write the
 422 uncompressed data to the file C<file1.txt>.
 423
 424     use strict ;
 425     use warnings ;
 426     use IO::Uncompress::AnyInflate qw(anyinflate $AnyInflateError) ;
 427
 428     my $input = "file1.txt.Compressed";
 429     my $output = "file1.txt";
 430     anyinflate $input => $output
 431         or die "anyinflate failed: $AnyInflateError\n";
 432
 433 To read from an existing Perl filehandle, C<$input>, and write the
 434 uncompressed data to a buffer, C<$buffer>.
 435
 436     use strict ;
 437     use warnings ;
 438     use IO::Uncompress::AnyInflate qw(anyinflate $AnyInflateError) ;
 439     use IO::File ;
 440
 441     my $input = new IO::File "<file1.txt.Compressed"
 442         or die "Cannot open 'file1.txt.Compressed': $!\n" ;
 443     my $buffer ;
 444     anyinflate $input => \$buffer
 445         or die "anyinflate failed: $AnyInflateError\n";
 446
 447 To uncompress all files in the directory "/my/home" that match "*.txt.Compressed" and store the compressed data in the same directory
 448
 449     use strict ;
 450     use warnings ;
 451     use IO::Uncompress::AnyInflate qw(anyinflate $AnyInflateError) ;
 452
 453     anyinflate '</my/home/*.txt.Compressed>' => '</my/home/#1.txt>'
 454         or die "anyinflate failed: $AnyInflateError\n";
 455
 456 and if you want to compress each file one at a time, this will do the trick
 457
 458     use strict ;
 459     use warnings ;
 460     use IO::Uncompress::AnyInflate qw(anyinflate $AnyInflateError) ;
 461
 462     for my $input ( glob "/my/home/*.txt.Compressed" )
 463     {
 464         my $output = $input;
 465         $output =~ s/.Compressed// ;
 466         anyinflate $input => $output
 467             or die "Error compressing '$input': $AnyInflateError\n";
 468     }
 469
 470 =head1 OO Interface
 471
 472 =head2 Constructor
 473
 474 The format of the constructor for IO::Uncompress::AnyInflate is shown below
 475
 476     my $z = new IO::Uncompress::AnyInflate $input [OPTS]
 477         or die "IO::Uncompress::AnyInflate failed: $AnyInflateError\n";
 478
 479 Returns an C<IO::Uncompress::AnyInflate> object on success and undef on failure.
 480 The variable C<$AnyInflateError> will contain an error message on failure.
 481
 482 If you are running Perl 5.005 or better the object, C<$z>, returned from
 483 IO::Uncompress::AnyInflate can be used exactly like an L<IO::File|IO::File> filehandle.
 484 This means that all normal input file operations can be carried out with
 485 C<$z>.  For example, to read a line from a compressed file/buffer you can
 486 use either of these forms
 487
 488     $line = $z->getline();
 489     $line = <$z>;
 490
 491 The mandatory parameter C<$input> is used to determine the source of the
 492 compressed data. This parameter can take one of three forms.
 493
 494 =over 5
 495
 496 =item A filename
 497
 498 If the C<$input> parameter is a scalar, it is assumed to be a filename. This
 499 file will be opened for reading and the compressed data will be read from it.
 500
 501 =item A filehandle
 502
 503 If the C<$input> parameter is a filehandle, the compressed data will be
 504 read from it.
 505 The string '-' can be used as an alias for standard input.
 506
 507 =item A scalar reference
 508
 509 If C<$input> is a scalar reference, the compressed data will be read from
 510 C<$$output>.
 511
 512 =back
 513
 514 =head2 Constructor Options
 515
 516 The option names defined below are case insensitive and can be optionally
 517 prefixed by a '-'.  So all of the following are valid
 518
 519     -AutoClose
 520     -autoclose
 521     AUTOCLOSE
 522     autoclose
 523
 524 OPTS is a combination of the following options:
 525
 526 =over 5
 527
 528 =item C<< AutoClose => 0|1 >>
 529
 530 This option is only valid when the C<$input> parameter is a filehandle. If
 531 specified, and the value is true, it will result in the file being closed once
 532 either the C<close> method is called or the IO::Uncompress::AnyInflate object is
 533 destroyed.
 534
 535 This parameter defaults to 0.
 536
 537 =item C<< MultiStream => 0|1 >>
 538
 539 Allows multiple concatenated compressed streams to be treated as a single
 540 compressed stream. Decompression will stop once either the end of the
 541 file/buffer is reached, an error is encountered (premature eof, corrupt
 542 compressed data) or the end of a stream is not immediately followed by the
 543 start of another stream.
 544
 545 This parameter defaults to 0.
 546
 547 =item C<< Prime => $string >>
 548
 549 This option will uncompress the contents of C<$string> before processing the
 550 input file/buffer.
 551
 552 This option can be useful when the compressed data is embedded in another
 553 file/data structure and it is not possible to work out where the compressed
 554 data begins without having to read the first few bytes. If this is the
 555 case, the uncompression can be I<primed> with these bytes using this
 556 option.
 557
 558 =item C<< Transparent => 0|1 >>
 559
 560 If this option is set and the input file/buffer is not compressed data,
 561 the module will allow reading of it anyway.
 562
 563 In addition, if the input file/buffer does contain compressed data and
 564 there is non-compressed data immediately following it, setting this option
 565 will make this module treat the whole file/buffer as a single data stream.
 566
 567 This option defaults to 1.
 568
 569 =item C<< BlockSize => $num >>
 570
 571 When reading the compressed input data, IO::Uncompress::AnyInflate will read it in
 572 blocks of C<$num> bytes.
 573
 574 This option defaults to 4096.
 575
 576 =item C<< InputLength => $size >>
 577
 578 When present this option will limit the number of compressed bytes read
 579 from the input file/buffer to C<$size>. This option can be used in the
 580 situation where there is useful data directly after the compressed data
 581 stream and you know beforehand the exact length of the compressed data
 582 stream.
 583
 584 This option is mostly used when reading from a filehandle, in which case
 585 the file pointer will be left pointing to the first byte directly after the
 586 compressed data stream.
 587
 588 This option defaults to off.
 589
 590 =item C<< Append => 0|1 >>
 591
 592 This option controls what the C<read> method does with uncompressed data.
 593
 594 If set to 1, all uncompressed data will be appended to the output parameter
 595 of the C<read> method.
 596
 597 If set to 0, the contents of the output parameter of the C<read> method
 598 will be overwritten by the uncompressed data.
 599
 600 Defaults to 0.
 601
 602 =item C<< Strict => 0|1 >>
 603
 604 This option controls whether the extra checks defined below are used when
 605 carrying out the decompression. When Strict is on, the extra tests are
 606 carried out, when Strict is off they are not.
 607
 608 The default for this option is off.
 609
 610 If the input is an RFC 1950 data stream, the following will be checked:
 611
 612 =over 5
 613
 614 =item 1
 615
 616 The ADLER32 checksum field must be present.
 617
 618 =item 2
 619
 620 The value of the ADLER32 field read must match the adler32 value of the
 621 uncompressed data actually contained in the file.
 622
 623 =back
 624
 625 If the input is a gzip (RFC 1952) data stream, the following will be checked:
 626
 627 =over 5
 628
 629 =item 1
 630
 631 If the FHCRC bit is set in the gzip FLG header byte, the CRC16 bytes in the
 632 header must match the crc16 value of the gzip header actually read.
 633
 634 =item 2
 635
 636 If the gzip header contains a name field (FNAME) it consists solely of ISO
 637 8859-1 characters.
 638
 639 =item 3
 640
 641 If the gzip header contains a comment field (FCOMMENT) it consists solely
 642 of ISO 8859-1 characters plus line-feed.
 643
 644 =item 4
 645
 646 If the gzip FEXTRA header field is present it must conform to the sub-field
 647 structure as defined in RFC 1952.
 648
 649 =item 5
 650
 651 The CRC32 and ISIZE trailer fields must be present.
 652
 653 =item 6
 654
 655 The value of the CRC32 field read must match the crc32 value of the
 656 uncompressed data actually contained in the gzip file.
 657
 658 =item 7
 659
 660 The value of the ISIZE fields read must match the length of the
 661 uncompressed data actually read from the file.
 662
 663 =back
 664
 665 =item C<< RawInflate => 0|1 >>
 666
 667 When auto-detecting the compressed format, try to test for raw-deflate (RFC
 668 1951) content using the C<IO::Uncompress::RawInflate> module.
 669
 670 The reason this is not default behaviour is because RFC 1951 content can
 671 only be detected by attempting to uncompress it. This process is error
 672 prone and can result is false positives.
 673
 674 Defaults to 0.
 675
 676 =item C<< ParseExtra => 0|1 >>
 677 If the gzip FEXTRA header field is present and this option is set, it will
 678 force the module to check that it conforms to the sub-field structure as
 679 defined in RFC 1952.
 680
 681 If the C<Strict> is on it will automatically enable this option.
 682
 683 Defaults to 0.
 684
 685 =back
 686
 687 =head2 Examples
 688
 689 TODO
 690
 691 =head1 Methods
 692
 693 =head2 read
 694
 695 Usage is
 696
 697     $status = $z->read($buffer)
 698
 699 Reads a block of compressed data (the size the the compressed block is
 700 determined by the C<Buffer> option in the constructor), uncompresses it and
 701 writes any uncompressed data into C<$buffer>. If the C<Append> parameter is
 702 set in the constructor, the uncompressed data will be appended to the
 703 C<$buffer> parameter. Otherwise C<$buffer> will be overwritten.
 704
 705 Returns the number of uncompressed bytes written to C<$buffer>, zero if eof
 706 or a negative number on error.
 707
 708 =head2 read
 709
 710 Usage is
 711
 712     $status = $z->read($buffer, $length)
 713     $status = $z->read($buffer, $length, $offset)
 714
 715     $status = read($z, $buffer, $length)
 716     $status = read($z, $buffer, $length, $offset)
 717
 718 Attempt to read C<$length> bytes of uncompressed data into C<$buffer>.
 719
 720 The main difference between this form of the C<read> method and the
 721 previous one, is that this one will attempt to return I<exactly> C<$length>
 722 bytes. The only circumstances that this function will not is if end-of-file
 723 or an IO error is encountered.
 724
 725 Returns the number of uncompressed bytes written to C<$buffer>, zero if eof
 726 or a negative number on error.
 727
 728 =head2 getline
 729
 730 Usage is
 731
 732     $line = $z->getline()
 733     $line = <$z>
 734
 735 Reads a single line.
 736
 737 This method fully supports the use of of the variable C<$/> (or
 738 C<$INPUT_RECORD_SEPARATOR> or C<$RS> when C<English> is in use) to
 739 determine what constitutes an end of line. Paragraph mode, record mode and
 740 file slurp mode are all supported.
 741
 742 =head2 getc
 743
 744 Usage is
 745
 746     $char = $z->getc()
 747
 748 Read a single character.
 749
 750 =head2 ungetc
 751
 752 Usage is
 753
 754     $char = $z->ungetc($string)
 755
 756 =head2 inflateSync
 757
 758 Usage is
 759
 760     $status = $z->inflateSync()
 761
 762 TODO
 763
 764 =head2 getHeaderInfo
 765
 766 Usage is
 767
 768     $hdr  = $z->getHeaderInfo();
 769     @hdrs = $z->getHeaderInfo();
 770
 771 This method returns either a hash reference (in scalar context) or a list
 772 or hash references (in array context) that contains information about each
 773 of the header fields in the compressed data stream(s).
 774
 775 =head2 tell
 776
 777 Usage is
 778
 779     $z->tell()
 780     tell $z
 781
 782 Returns the uncompressed file offset.
 783
 784 =head2 eof
 785
 786 Usage is
 787
 788     $z->eof();
 789     eof($z);
 790
 791 Returns true if the end of the compressed input stream has been reached.
 792
 793 =head2 seek
 794
 795     $z->seek($position, $whence);
 796     seek($z, $position, $whence);
 797
 798 Provides a sub-set of the C<seek> functionality, with the restriction
 799 that it is only legal to seek forward in the input file/buffer.
 800 It is a fatal error to attempt to seek backward.
 801
 802 The C<$whence> parameter takes one the usual values, namely SEEK_SET,
 803 SEEK_CUR or SEEK_END.
 804
 805 Returns 1 on success, 0 on failure.
 806
 807 =head2 binmode
 808
 809 Usage is
 810
 811     $z->binmode
 812     binmode $z ;
 813
 814 This is a noop provided for completeness.
 815
 816 =head2 opened
 817
 818     $z->opened()
 819
 820 Returns true if the object currently refers to a opened file/buffer.
 821
 822 =head2 autoflush
 823
 824     my $prev = $z->autoflush()
 825     my $prev = $z->autoflush(EXPR)
 826
 827 If the C<$z> object is associated with a file or a filehandle, this method
 828 returns the current autoflush setting for the underlying filehandle. If
 829 C<EXPR> is present, and is non-zero, it will enable flushing after every
 830 write/print operation.
 831
 832 If C<$z> is associated with a buffer, this method has no effect and always
 833 returns C<undef>.
 834
 835 B<Note> that the special variable C<$|> B<cannot> be used to set or
 836 retrieve the autoflush setting.
 837
 838 =head2 input_line_number
 839
 840     $z->input_line_number()
 841     $z->input_line_number(EXPR)
 842
 843 Returns the current uncompressed line number. If C<EXPR> is present it has
 844 the effect of setting the line number. Note that setting the line number
 845 does not change the current position within the file/buffer being read.
 846
 847 The contents of C<$/> are used to to determine what constitutes a line
 848 terminator.
 849
 850 =head2 fileno
 851
 852     $z->fileno()
 853     fileno($z)
 854
 855 If the C<$z> object is associated with a file or a filehandle, C<fileno>
 856 will return the underlying file descriptor. Once the C<close> method is
 857 called C<fileno> will return C<undef>.
 858
 859 If the C<$z> object is associated with a buffer, this method will return
 860 C<undef>.
 861
 862 =head2 close
 863
 864     $z->close() ;
 865     close $z ;
 866
 867 Closes the output file/buffer.
 868
 869 For most versions of Perl this method will be automatically invoked if
 870 the IO::Uncompress::AnyInflate object is destroyed (either explicitly or by the
 871 variable with the reference to the object going out of scope). The
 872 exceptions are Perl versions 5.005 through 5.00504 and 5.8.0. In
 873 these cases, the C<close> method will be called automatically, but
 874 not until global destruction of all live objects when the program is
 875 terminating.
 876
 877 Therefore, if you want your scripts to be able to run on all versions
 878 of Perl, you should call C<close> explicitly and not rely on automatic
 879 closing.
 880
 881 Returns true on success, otherwise 0.
 882
 883 If the C<AutoClose> option has been enabled when the IO::Uncompress::AnyInflate
 884 object was created, and the object is associated with a file, the
 885 underlying file will also be closed.
 886
 887 =head2 nextStream
 888
 889 Usage is
 890
 891     my $status = $z->nextStream();
 892
 893 Skips to the next compressed data stream in the input file/buffer. If a new
 894 compressed data stream is found, the eof marker will be cleared and C<$.>
 895 will be reset to 0.
 896
 897 Returns 1 if a new stream was found, 0 if none was found, and -1 if an
 898 error was encountered.
 899
 900 =head2 trailingData
 901
 902 Usage is
 903
 904     my $data = $z->trailingData();
 905
 906 Returns the data, if any, that is present immediately after the compressed
 907 data stream once uncompression is complete. It only makes sense to call
 908 this method once the end of the compressed data stream has been
 909 encountered.
 910
 911 This option can be used when there is useful information immediately
 912 following the compressed data stream, and you don't know the length of the
 913 compressed data stream.
 914
 915 If the input is a buffer, C<trailingData> will return everything from the
 916 end of the compressed data stream to the end of the buffer.
 917
 918 If the input is a filehandle, C<trailingData> will return the data that is
 919 left in the filehandle input buffer once the end of the compressed data
 920 stream has been reached. You can then use the filehandle to read the rest
 921 of the input file.
 922
 923 Don't bother using C<trailingData> if the input is a filename.
 924
 925 If you know the length of the compressed data stream before you start
 926 uncompressing, you can avoid having to use C<trailingData> by setting the
 927 C<InputLength> option in the constructor.
 928
 929 =head1 Importing
 930
 931 No symbolic constants are required by this IO::Uncompress::AnyInflate at present.
 932
 933 =over 5
 934
 935 =item :all
 936
 937 Imports C<anyinflate> and C<$AnyInflateError>.
 938 Same as doing this
 939
 940     use IO::Uncompress::AnyInflate qw(anyinflate $AnyInflateError) ;
 941
 942 =back
 943
 944 =head1 EXAMPLES
 945
 946 =head2 Working with Net::FTP
 947
 948 See L<IO::Uncompress::AnyInflate::FAQ|IO::Uncompress::AnyInflate::FAQ/"Compressed files and Net::FTP">
 949
 950 =head1 SEE ALSO
 951
 952 L<Compress::Zlib>, L<IO::Compress::Gzip>, L<IO::Uncompress::Gunzip>, L<IO::Compress::Deflate>, L<IO::Uncompress::Inflate>, L<IO::Compress::RawDeflate>, L<IO::Uncompress::RawInflate>, L<IO::Compress::Bzip2>, L<IO::Uncompress::Bunzip2>, L<IO::Compress::Lzma>, L<IO::Uncompress::UnLzma>, L<IO::Compress::Xz>, L<IO::Uncompress::UnXz>, L<IO::Compress::Lzop>, L<IO::Uncompress::UnLzop>, L<IO::Compress::Lzf>, L<IO::Uncompress::UnLzf>, L<IO::Uncompress::AnyUncompress>
 953
 954 L<IO::Compress::FAQ|IO::Compress::FAQ>
 955
 956 L<File::GlobMapper|File::GlobMapper>, L<Archive::Zip|Archive::Zip>,
 957 L<Archive::Tar|Archive::Tar>,
 958 L<IO::Zlib|IO::Zlib>
 959
 960 For RFC 1950, 1951 and 1952 see
 961 F<http://www.faqs.org/rfcs/rfc1950.html>,
 962 F<http://www.faqs.org/rfcs/rfc1951.html> and
 963 F<http://www.faqs.org/rfcs/rfc1952.html>
 964
 965 The I<zlib> compression library was written by Jean-loup Gailly
 966 F<gzip@prep.ai.mit.edu> and Mark Adler F<madler@alumni.caltech.edu>.
 967
 968 The primary site for the I<zlib> compression library is
 969 F<http://www.zlib.org>.
 970
 971 The primary site for gzip is F<http://www.gzip.org>.
 972
 973 =head1 AUTHOR
 974
 975 This module was written by Paul Marquess, F<pmqs@cpan.org>.
 976
 977 =head1 MODIFICATION HISTORY
 978
 979 See the Changes file.
 980
 981 =head1 COPYRIGHT AND LICENSE
 982
 983 Copyright (c) 2005-2012 Paul Marquess. All rights reserved.
 984
 985 This program is free software; you can redistribute it and/or
 986 modify it under the same terms as Perl itself.
 987