This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
410085ffbc07690efec74283ab17dd4311c74466
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands.  For example S<C<$x + $y>>
10 is always a numeric addition, and if C<$x> or C<$y> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument.  It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison.  For example S<C<$x == $y>> compares
17 two numbers for equality, and S<C<$x eq $y>> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in S<C<2 + 4 * 5>>, the multiplication has higher
32 precedence so S<C<4 * 5>> is evaluated first yielding S<C<2 + 20 ==
33 22>> and not S<C<6 * 5 == 30>>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first, or the right first.  For example, in
38 S<C<8 - 4 - 2>>, subtraction is left associative so Perl evaluates the
39 expression left to right.  S<C<8 - 4>> is evaluated first making the
40 expression S<C<4 - 2 == 2>> and not S<C<8 - 2 == 6>>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in detail, in the
75 same order in which they appear in the table above.
76
77 Many operators can be overloaded for objects.  See L<overload>.
78
79 =head2 Terms and List Operators (Leftward)
80 X<list operator> X<operator, list> X<term>
81
82 A TERM has the highest precedence in Perl.  They include variables,
83 quote and quote-like operators, any expression in parentheses,
84 and any function whose arguments are parenthesized.  Actually, there
85 aren't really functions in this sense, just list operators and unary
86 operators behaving as functions because you put parentheses around
87 the arguments.  These are all documented in L<perlfunc>.
88
89 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
90 is followed by a left parenthesis as the next token, the operator and
91 arguments within parentheses are taken to be of highest precedence,
92 just like a normal function call.
93
94 In the absence of parentheses, the precedence of list operators such as
95 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
96 whether you are looking at the left side or the right side of the operator.
97 For example, in
98
99     @ary = (1, 3, sort 4, 2);
100     print @ary;         # prints 1324
101
102 the commas on the right of the C<sort> are evaluated before the C<sort>,
103 but the commas on the left are evaluated after.  In other words,
104 list operators tend to gobble up all arguments that follow, and
105 then act like a simple TERM with regard to the preceding expression.
106 Be careful with parentheses:
107
108     # These evaluate exit before doing the print:
109     print($foo, exit);  # Obviously not what you want.
110     print $foo, exit;   # Nor is this.
111
112     # These do the print before evaluating exit:
113     (print $foo), exit; # This is what you want.
114     print($foo), exit;  # Or this.
115     print ($foo), exit; # Or even this.
116
117 Also note that
118
119     print ($foo & 255) + 1, "\n";
120
121 probably doesn't do what you expect at first glance.  The parentheses
122 enclose the argument list for C<print> which is evaluated (printing
123 the result of S<C<$foo & 255>>).  Then one is added to the return value
124 of C<print> (usually 1).  The result is something like this:
125
126     1 + 1, "\n";    # Obviously not what you meant.
127
128 To do what you meant properly, you must write:
129
130     print(($foo & 255) + 1, "\n");
131
132 See L</Named Unary Operators> for more discussion of this.
133
134 Also parsed as terms are the S<C<do {}>> and S<C<eval {}>> constructs, as
135 well as subroutine and method calls, and the anonymous
136 constructors C<[]> and C<{}>.
137
138 See also L</Quote and Quote-like Operators> toward the end of this section,
139 as well as L</"I/O Operators">.
140
141 =head2 The Arrow Operator
142 X<arrow> X<dereference> X<< -> >>
143
144 "C<< -> >>" is an infix dereference operator, just as it is in C
145 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
146 C<(...)> subscript, then the left side must be either a hard or
147 symbolic reference to an array, a hash, or a subroutine respectively.
148 (Or technically speaking, a location capable of holding a hard
149 reference, if it's an array or hash reference being used for
150 assignment.)  See L<perlreftut> and L<perlref>.
151
152 Otherwise, the right side is a method name or a simple scalar
153 variable containing either the method name or a subroutine reference,
154 and the left side must be either an object (a blessed reference)
155 or a class name (that is, a package name).  See L<perlobj>.
156
157 The dereferencing cases (as opposed to method-calling cases) are
158 somewhat extended by the C<postderef> feature.  For the
159 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
160
161 =head2 Auto-increment and Auto-decrement
162 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
163
164 C<"++"> and C<"--"> work as in C.  That is, if placed before a variable,
165 they increment or decrement the variable by one before returning the
166 value, and if placed after, increment or decrement after returning the
167 value.
168
169     $i = 0;  $j = 0;
170     print $i++;  # prints 0
171     print ++$j;  # prints 1
172
173 Note that just as in C, Perl doesn't define B<when> the variable is
174 incremented or decremented.  You just know it will be done sometime
175 before or after the value is returned.  This also means that modifying
176 a variable twice in the same statement will lead to undefined behavior.
177 Avoid statements like:
178
179     $i = $i ++;
180     print ++ $i + $i ++;
181
182 Perl will not guarantee what the result of the above statements is.
183
184 The auto-increment operator has a little extra builtin magic to it.  If
185 you increment a variable that is numeric, or that has ever been used in
186 a numeric context, you get a normal increment.  If, however, the
187 variable has been used in only string contexts since it was set, and
188 has a value that is not the empty string and matches the pattern
189 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
190 character within its range, with carry:
191
192     print ++($foo = "99");      # prints "100"
193     print ++($foo = "a0");      # prints "a1"
194     print ++($foo = "Az");      # prints "Ba"
195     print ++($foo = "zz");      # prints "aaa"
196
197 C<undef> is always treated as numeric, and in particular is changed
198 to C<0> before incrementing (so that a post-increment of an undef value
199 will return C<0> rather than C<undef>).
200
201 The auto-decrement operator is not magical.
202
203 =head2 Exponentiation
204 X<**> X<exponentiation> X<power>
205
206 Binary C<"**"> is the exponentiation operator.  It binds even more
207 tightly than unary minus, so C<-2**4> is C<-(2**4)>, not C<(-2)**4>.
208 (This is
209 implemented using C's C<pow(3)> function, which actually works on doubles
210 internally.)
211
212 Note that certain exponentiation expressions are ill-defined:
213 these include C<0**0>, C<1**Inf>, and C<Inf**0>.  Do not expect
214 any particular results from these special cases, the results
215 are platform-dependent.
216
217 =head2 Symbolic Unary Operators
218 X<unary operator> X<operator, unary>
219
220 Unary C<"!"> performs logical negation, that is, "not".  See also
221 L<C<not>|/Logical Not> for a lower precedence version of this.
222 X<!>
223
224 Unary C<"-"> performs arithmetic negation if the operand is numeric,
225 including any string that looks like a number.  If the operand is
226 an identifier, a string consisting of a minus sign concatenated
227 with the identifier is returned.  Otherwise, if the string starts
228 with a plus or minus, a string starting with the opposite sign is
229 returned.  One effect of these rules is that C<-bareword> is equivalent
230 to the string C<"-bareword">.  If, however, the string begins with a
231 non-alphabetic character (excluding C<"+"> or C<"-">), Perl will attempt
232 to convert
233 the string to a numeric, and the arithmetic negation is performed.  If the
234 string cannot be cleanly converted to a numeric, Perl will give the warning
235 B<Argument "the string" isn't numeric in negation (-) at ...>.
236 X<-> X<negation, arithmetic>
237
238 Unary C<"~"> performs bitwise negation, that is, 1's complement.  For
239 example, S<C<0666 & ~027>> is 0640.  (See also L</Integer Arithmetic> and
240 L</Bitwise String Operators>.)  Note that the width of the result is
241 platform-dependent: C<~0> is 32 bits wide on a 32-bit platform, but 64
242 bits wide on a 64-bit platform, so if you are expecting a certain bit
243 width, remember to use the C<"&"> operator to mask off the excess bits.
244 X<~> X<negation, binary>
245
246 Starting in Perl 5.28, it is a fatal error to try to complement a string
247 containing a character with an ordinal value above 255.
248
249 If the experimental "bitwise" feature is enabled via S<C<use feature
250 'bitwise'>>, then unary C<"~"> always treats its argument as a number, and an
251 alternate form of the operator, C<"~.">, always treats its argument as a
252 string.  So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms,
253 whereas C<~.0> and C<~."0"> will both yield C<"\xff">.  This feature
254 produces a warning unless you use S<C<no warnings 'experimental::bitwise'>>.
255
256 Unary C<"+"> has no effect whatsoever, even on strings.  It is useful
257 syntactically for separating a function name from a parenthesized expression
258 that would otherwise be interpreted as the complete list of function
259 arguments.  (See examples above under L</Terms and List Operators (Leftward)>.)
260 X<+>
261
262 Unary C<"\"> creates a reference to whatever follows it.  See L<perlreftut>
263 and L<perlref>.  Do not confuse this behavior with the behavior of
264 backslash within a string, although both forms do convey the notion
265 of protecting the next thing from interpolation.
266 X<\> X<reference> X<backslash>
267
268 =head2 Binding Operators
269 X<binding> X<operator, binding> X<=~> X<!~>
270
271 Binary C<"=~"> binds a scalar expression to a pattern match.  Certain operations
272 search or modify the string C<$_> by default.  This operator makes that kind
273 of operation work on some other string.  The right argument is a search
274 pattern, substitution, or transliteration.  The left argument is what is
275 supposed to be searched, substituted, or transliterated instead of the default
276 C<$_>.  When used in scalar context, the return value generally indicates the
277 success of the operation.  The exceptions are substitution (C<s///>)
278 and transliteration (C<y///>) with the C</r> (non-destructive) option,
279 which cause the B<r>eturn value to be the result of the substitution.
280 Behavior in list context depends on the particular operator.
281 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
282 examples using these operators.
283
284 If the right argument is an expression rather than a search pattern,
285 substitution, or transliteration, it is interpreted as a search pattern at run
286 time.  Note that this means that its
287 contents will be interpolated twice, so
288
289     '\\' =~ q'\\';
290
291 is not ok, as the regex engine will end up trying to compile the
292 pattern C<\>, which it will consider a syntax error.
293
294 Binary C<"!~"> is just like C<"=~"> except the return value is negated in
295 the logical sense.
296
297 Binary C<"!~"> with a non-destructive substitution (C<s///r>) or transliteration
298 (C<y///r>) is a syntax error.
299
300 =head2 Multiplicative Operators
301 X<operator, multiplicative>
302
303 Binary C<"*"> multiplies two numbers.
304 X<*>
305
306 Binary C<"/"> divides two numbers.
307 X</> X<slash>
308
309 Binary C<"%"> is the modulo operator, which computes the division
310 remainder of its first argument with respect to its second argument.
311 Given integer
312 operands C<$m> and C<$n>: If C<$n> is positive, then S<C<$m % $n>> is
313 C<$m> minus the largest multiple of C<$n> less than or equal to
314 C<$m>.  If C<$n> is negative, then S<C<$m % $n>> is C<$m> minus the
315 smallest multiple of C<$n> that is not less than C<$m> (that is, the
316 result will be less than or equal to zero).  If the operands
317 C<$m> and C<$n> are floating point values and the absolute value of
318 C<$n> (that is C<abs($n)>) is less than S<C<(UV_MAX + 1)>>, only
319 the integer portion of C<$m> and C<$n> will be used in the operation
320 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
321 If the absolute value of the right operand (C<abs($n)>) is greater than
322 or equal to S<C<(UV_MAX + 1)>>, C<"%"> computes the floating-point remainder
323 C<$r> in the equation S<C<($r = $m - $i*$n)>> where C<$i> is a certain
324 integer that makes C<$r> have the same sign as the right operand
325 C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>)
326 and the absolute value less than that of C<$n>.
327 Note that when S<C<use integer>> is in scope, C<"%"> gives you direct access
328 to the modulo operator as implemented by your C compiler.  This
329 operator is not as well defined for negative operands, but it will
330 execute faster.
331 X<%> X<remainder> X<modulo> X<mod>
332
333 Binary C<"x"> is the repetition operator.  In scalar context or if the left
334 operand is not enclosed in parentheses, it returns a string consisting
335 of the left operand repeated the number of times specified by the right
336 operand.  In list context, if the left operand is enclosed in
337 parentheses or is a list formed by C<qw/I<STRING>/>, it repeats the list.
338 If the right operand is zero or negative (raising a warning on
339 negative), it returns an empty string
340 or an empty list, depending on the context.
341 X<x>
342
343     print '-' x 80;             # print row of dashes
344
345     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
346
347     @ones = (1) x 80;           # a list of 80 1's
348     @ones = (5) x @ones;        # set all elements to 5
349
350
351 =head2 Additive Operators
352 X<operator, additive>
353
354 Binary C<"+"> returns the sum of two numbers.
355 X<+>
356
357 Binary C<"-"> returns the difference of two numbers.
358 X<->
359
360 Binary C<"."> concatenates two strings.
361 X<string, concatenation> X<concatenation>
362 X<cat> X<concat> X<concatenate> X<.>
363
364 =head2 Shift Operators
365 X<shift operator> X<operator, shift> X<<< << >>>
366 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
367 X<shl> X<shr> X<shift, right> X<shift, left>
368
369 Binary C<<< "<<" >>> returns the value of its left argument shifted left by the
370 number of bits specified by the right argument.  Arguments should be
371 integers.  (See also L</Integer Arithmetic>.)
372
373 Binary C<<< ">>" >>> returns the value of its left argument shifted right by
374 the number of bits specified by the right argument.  Arguments should
375 be integers.  (See also L</Integer Arithmetic>.)
376
377 If S<C<use integer>> (see L</Integer Arithmetic>) is in force then
378 signed C integers are used (I<arithmetic shift>), otherwise unsigned C
379 integers are used (I<logical shift>), even for negative shiftees.
380 In arithmetic right shift the sign bit is replicated on the left,
381 in logical shift zero bits come in from the left.
382
383 Either way, the implementation isn't going to generate results larger
384 than the size of the integer type Perl was built with (32 bits or 64 bits).
385
386 Shifting by negative number of bits means the reverse shift: left
387 shift becomes right shift, right shift becomes left shift.  This is
388 unlike in C, where negative shift is undefined.
389
390 Shifting by more bits than the size of the integers means most of the
391 time zero (all bits fall off), except that under S<C<use integer>>
392 right overshifting a negative shiftee results in -1.  This is unlike
393 in C, where shifting by too many bits is undefined.  A common C
394 behavior is "shift by modulo wordbits", so that for example
395
396     1 >> 64 == 1 >> (64 % 64) == 1 >> 0 == 1  # Common C behavior.
397
398 but that is completely accidental.
399
400 If you get tired of being subject to your platform's native integers,
401 the S<C<use bigint>> pragma neatly sidesteps the issue altogether:
402
403     print 20 << 20;  # 20971520
404     print 20 << 40;  # 5120 on 32-bit machines,
405                      # 21990232555520 on 64-bit machines
406     use bigint;
407     print 20 << 100; # 25353012004564588029934064107520
408
409 =head2 Named Unary Operators
410 X<operator, named unary>
411
412 The various named unary operators are treated as functions with one
413 argument, with optional parentheses.
414
415 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
416 is followed by a left parenthesis as the next token, the operator and
417 arguments within parentheses are taken to be of highest precedence,
418 just like a normal function call.  For example,
419 because named unary operators are higher precedence than C<||>:
420
421     chdir $foo    || die;       # (chdir $foo) || die
422     chdir($foo)   || die;       # (chdir $foo) || die
423     chdir ($foo)  || die;       # (chdir $foo) || die
424     chdir +($foo) || die;       # (chdir $foo) || die
425
426 but, because C<"*"> is higher precedence than named operators:
427
428     chdir $foo * 20;    # chdir ($foo * 20)
429     chdir($foo) * 20;   # (chdir $foo) * 20
430     chdir ($foo) * 20;  # (chdir $foo) * 20
431     chdir +($foo) * 20; # chdir ($foo * 20)
432
433     rand 10 * 20;       # rand (10 * 20)
434     rand(10) * 20;      # (rand 10) * 20
435     rand (10) * 20;     # (rand 10) * 20
436     rand +(10) * 20;    # rand (10 * 20)
437
438 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
439 treated like named unary operators, but they don't follow this functional
440 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
441 equivalent to S<C<-f "$file.bak">>.
442 X<-X> X<filetest> X<operator, filetest>
443
444 See also L</"Terms and List Operators (Leftward)">.
445
446 =head2 Relational Operators
447 X<relational operator> X<operator, relational>
448
449 Perl operators that return true or false generally return values
450 that can be safely used as numbers.  For example, the relational
451 operators in this section and the equality operators in the next
452 one return C<1> for true and a special version of the defined empty
453 string, C<"">, which counts as a zero but is exempt from warnings
454 about improper numeric conversions, just as S<C<"0 but true">> is.
455
456 Binary C<< "<" >> returns true if the left argument is numerically less than
457 the right argument.
458 X<< < >>
459
460 Binary C<< ">" >> returns true if the left argument is numerically greater
461 than the right argument.
462 X<< > >>
463
464 Binary C<< "<=" >> returns true if the left argument is numerically less than
465 or equal to the right argument.
466 X<< <= >>
467
468 Binary C<< ">=" >> returns true if the left argument is numerically greater
469 than or equal to the right argument.
470 X<< >= >>
471
472 Binary C<"lt"> returns true if the left argument is stringwise less than
473 the right argument.
474 X<< lt >>
475
476 Binary C<"gt"> returns true if the left argument is stringwise greater
477 than the right argument.
478 X<< gt >>
479
480 Binary C<"le"> returns true if the left argument is stringwise less than
481 or equal to the right argument.
482 X<< le >>
483
484 Binary C<"ge"> returns true if the left argument is stringwise greater
485 than or equal to the right argument.
486 X<< ge >>
487
488 =head2 Equality Operators
489 X<equality> X<equal> X<equals> X<operator, equality>
490
491 Binary C<< "==" >> returns true if the left argument is numerically equal to
492 the right argument.
493 X<==>
494
495 Binary C<< "!=" >> returns true if the left argument is numerically not equal
496 to the right argument.
497 X<!=>
498
499 Binary C<< "<=>" >> returns -1, 0, or 1 depending on whether the left
500 argument is numerically less than, equal to, or greater than the right
501 argument.  If your platform supports C<NaN>'s (not-a-numbers) as numeric
502 values, using them with C<< "<=>" >> returns undef.  C<NaN> is not
503 C<< "<" >>, C<< "==" >>, C<< ">" >>, C<< "<=" >> or C<< ">=" >> anything
504 (even C<NaN>), so those 5 return false.  S<C<< NaN != NaN >>> returns
505 true, as does S<C<NaN !=> I<anything else>>.  If your platform doesn't
506 support C<NaN>'s then C<NaN> is just a string with numeric value 0.
507 X<< <=> >>
508 X<spaceship>
509
510     $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
511     $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'
512
513 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all
514 support C<"NaN">.)
515
516 Binary C<"eq"> returns true if the left argument is stringwise equal to
517 the right argument.
518 X<eq>
519
520 Binary C<"ne"> returns true if the left argument is stringwise not equal
521 to the right argument.
522 X<ne>
523
524 Binary C<"cmp"> returns -1, 0, or 1 depending on whether the left
525 argument is stringwise less than, equal to, or greater than the right
526 argument.
527 X<cmp>
528
529 Binary C<"~~"> does a smartmatch between its arguments.  Smart matching
530 is described in the next section.
531 X<~~>
532
533 C<"lt">, C<"le">, C<"ge">, C<"gt"> and C<"cmp"> use the collation (sort)
534 order specified by the current C<LC_COLLATE> locale if a S<C<use
535 locale>> form that includes collation is in effect.  See L<perllocale>.
536 Do not mix these with Unicode,
537 only use them with legacy 8-bit locale encodings.
538 The standard C<L<Unicode::Collate>> and
539 C<L<Unicode::Collate::Locale>> modules offer much more powerful
540 solutions to collation issues.
541
542 For case-insensitive comparisions, look at the L<perlfunc/fc> case-folding
543 function, available in Perl v5.16 or later:
544
545     if ( fc($x) eq fc($y) ) { ... }
546
547 =head2 Smartmatch Operator
548
549 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
550 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
551 used implicitly in the C<when> construct described in L<perlsyn>, although
552 not all C<when> clauses call the smartmatch operator.  Unique among all of
553 Perl's operators, the smartmatch operator can recurse.  The smartmatch
554 operator is L<experimental|perlpolicy/experimental> and its behavior is
555 subject to change.
556
557 It is also unique in that all other Perl operators impose a context
558 (usually string or numeric context) on their operands, autoconverting
559 those operands to those imposed contexts.  In contrast, smartmatch
560 I<infers> contexts from the actual types of its operands and uses that
561 type information to select a suitable comparison mechanism.
562
563 The C<~~> operator compares its operands "polymorphically", determining how
564 to compare them according to their actual types (numeric, string, array,
565 hash, etc.)  Like the equality operators with which it shares the same
566 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
567 read aloud as "in", "inside of", or "is contained in", because the left
568 operand is often looked for I<inside> the right operand.  That makes the
569 order of the operands to the smartmatch operand often opposite that of
570 the regular match operator.  In other words, the "smaller" thing is usually
571 placed in the left operand and the larger one in the right.
572
573 The behavior of a smartmatch depends on what type of things its arguments
574 are, as determined by the following table.  The first row of the table
575 whose types apply determines the smartmatch behavior.  Because what
576 actually happens is mostly determined by the type of the second operand,
577 the table is sorted on the right operand instead of on the left.
578
579  Left      Right      Description and pseudocode
580  ===============================================================
581  Any       undef      check whether Any is undefined
582                 like: !defined Any
583
584  Any       Object     invoke ~~ overloading on Object, or die
585
586  Right operand is an ARRAY:
587
588  Left      Right      Description and pseudocode
589  ===============================================================
590  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
591                 like: (ARRAY1[0] ~~ ARRAY2[0])
592                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
593  HASH      ARRAY      any ARRAY elements exist as HASH keys
594                 like: grep { exists HASH->{$_} } ARRAY
595  Regexp    ARRAY      any ARRAY elements pattern match Regexp
596                 like: grep { /Regexp/ } ARRAY
597  undef     ARRAY      undef in ARRAY
598                 like: grep { !defined } ARRAY
599  Any       ARRAY      smartmatch each ARRAY element[3]
600                 like: grep { Any ~~ $_ } ARRAY
601
602  Right operand is a HASH:
603
604  Left      Right      Description and pseudocode
605  ===============================================================
606  HASH1     HASH2      all same keys in both HASHes
607                 like: keys HASH1 ==
608                          grep { exists HASH2->{$_} } keys HASH1
609  ARRAY     HASH       any ARRAY elements exist as HASH keys
610                 like: grep { exists HASH->{$_} } ARRAY
611  Regexp    HASH       any HASH keys pattern match Regexp
612                 like: grep { /Regexp/ } keys HASH
613  undef     HASH       always false (undef can't be a key)
614                 like: 0 == 1
615  Any       HASH       HASH key existence
616                 like: exists HASH->{Any}
617
618  Right operand is CODE:
619
620  Left      Right      Description and pseudocode
621  ===============================================================
622  ARRAY     CODE       sub returns true on all ARRAY elements[1]
623                 like: !grep { !CODE->($_) } ARRAY
624  HASH      CODE       sub returns true on all HASH keys[1]
625                 like: !grep { !CODE->($_) } keys HASH
626  Any       CODE       sub passed Any returns true
627                 like: CODE->(Any)
628
629 Right operand is a Regexp:
630
631  Left      Right      Description and pseudocode
632  ===============================================================
633  ARRAY     Regexp     any ARRAY elements match Regexp
634                 like: grep { /Regexp/ } ARRAY
635  HASH      Regexp     any HASH keys match Regexp
636                 like: grep { /Regexp/ } keys HASH
637  Any       Regexp     pattern match
638                 like: Any =~ /Regexp/
639
640  Other:
641
642  Left      Right      Description and pseudocode
643  ===============================================================
644  Object    Any        invoke ~~ overloading on Object,
645                       or fall back to...
646
647  Any       Num        numeric equality
648                  like: Any == Num
649  Num       nummy[4]    numeric equality
650                  like: Num == nummy
651  undef     Any        check whether undefined
652                  like: !defined(Any)
653  Any       Any        string equality
654                  like: Any eq Any
655
656
657 Notes:
658
659 =over
660
661 =item 1.
662 Empty hashes or arrays match.
663
664 =item 2.
665 That is, each element smartmatches the element of the same index in the other array.[3]
666
667 =item 3.
668 If a circular reference is found, fall back to referential equality.
669
670 =item 4.
671 Either an actual number, or a string that looks like one.
672
673 =back
674
675 The smartmatch implicitly dereferences any non-blessed hash or array
676 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
677 For blessed references, the C<I<Object>> entries apply.  Smartmatches
678 involving hashes only consider hash keys, never hash values.
679
680 The "like" code entry is not always an exact rendition.  For example, the
681 smartmatch operator short-circuits whenever possible, but C<grep> does
682 not.  Also, C<grep> in scalar context returns the number of matches, but
683 C<~~> returns only true or false.
684
685 Unlike most operators, the smartmatch operator knows to treat C<undef>
686 specially:
687
688     use v5.10.1;
689     @array = (1, 2, 3, undef, 4, 5);
690     say "some elements undefined" if undef ~~ @array;
691
692 Each operand is considered in a modified scalar context, the modification
693 being that array and hash variables are passed by reference to the
694 operator, which implicitly dereferences them.  Both elements
695 of each pair are the same:
696
697     use v5.10.1;
698
699     my %hash = (red    => 1, blue   => 2, green  => 3,
700                 orange => 4, yellow => 5, purple => 6,
701                 black  => 7, grey   => 8, white  => 9);
702
703     my @array = qw(red blue green);
704
705     say "some array elements in hash keys" if  @array ~~  %hash;
706     say "some array elements in hash keys" if \@array ~~ \%hash;
707
708     say "red in array" if "red" ~~  @array;
709     say "red in array" if "red" ~~ \@array;
710
711     say "some keys end in e" if /e$/ ~~  %hash;
712     say "some keys end in e" if /e$/ ~~ \%hash;
713
714 Two arrays smartmatch if each element in the first array smartmatches
715 (that is, is "in") the corresponding element in the second array,
716 recursively.
717
718     use v5.10.1;
719     my @little = qw(red blue green);
720     my @bigger = ("red", "blue", [ "orange", "green" ] );
721     if (@little ~~ @bigger) {  # true!
722         say "little is contained in bigger";
723     }
724
725 Because the smartmatch operator recurses on nested arrays, this
726 will still report that "red" is in the array.
727
728     use v5.10.1;
729     my @array = qw(red blue green);
730     my $nested_array = [[[[[[[ @array ]]]]]]];
731     say "red in array" if "red" ~~ $nested_array;
732
733 If two arrays smartmatch each other, then they are deep
734 copies of each others' values, as this example reports:
735
736     use v5.12.0;
737     my @a = (0, 1, 2, [3, [4, 5], 6], 7);
738     my @b = (0, 1, 2, [3, [4, 5], 6], 7);
739
740     if (@a ~~ @b && @b ~~ @a) {
741         say "a and b are deep copies of each other";
742     }
743     elsif (@a ~~ @b) {
744         say "a smartmatches in b";
745     }
746     elsif (@b ~~ @a) {
747         say "b smartmatches in a";
748     }
749     else {
750         say "a and b don't smartmatch each other at all";
751     }
752
753
754 If you were to set S<C<$b[3] = 4>>, then instead of reporting that "a and b
755 are deep copies of each other", it now reports that C<"b smartmatches in a">.
756 That's because the corresponding position in C<@a> contains an array that
757 (eventually) has a 4 in it.
758
759 Smartmatching one hash against another reports whether both contain the
760 same keys, no more and no less.  This could be used to see whether two
761 records have the same field names, without caring what values those fields
762 might have.  For example:
763
764     use v5.10.1;
765     sub make_dogtag {
766         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
767
768         my ($class, $init_fields) = @_;
769
770         die "Must supply (only) name, rank, and serial number"
771             unless $init_fields ~~ $REQUIRED_FIELDS;
772
773         ...
774     }
775
776 However, this only does what you mean if C<$init_fields> is indeed a hash
777 reference. The condition C<$init_fields ~~ $REQUIRED_FIELDS> also allows the
778 strings C<"name">, C<"rank">, C<"serial_num"> as well as any array reference
779 that contains C<"name"> or C<"rank"> or C<"serial_num"> anywhere to pass
780 through.
781
782 The smartmatch operator is most often used as the implicit operator of a
783 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
784
785 =head3 Smartmatching of Objects
786
787 To avoid relying on an object's underlying representation, if the
788 smartmatch's right operand is an object that doesn't overload C<~~>,
789 it raises the exception "C<Smartmatching a non-overloaded object
790 breaks encapsulation>".  That's because one has no business digging
791 around to see whether something is "in" an object.  These are all
792 illegal on objects without a C<~~> overload:
793
794     %hash ~~ $object
795        42 ~~ $object
796    "fred" ~~ $object
797
798 However, you can change the way an object is smartmatched by overloading
799 the C<~~> operator.  This is allowed to
800 extend the usual smartmatch semantics.
801 For objects that do have an C<~~> overload, see L<overload>.
802
803 Using an object as the left operand is allowed, although not very useful.
804 Smartmatching rules take precedence over overloading, so even if the
805 object in the left operand has smartmatch overloading, this will be
806 ignored.  A left operand that is a non-overloaded object falls back on a
807 string or numeric comparison of whatever the C<ref> operator returns.  That
808 means that
809
810     $object ~~ X
811
812 does I<not> invoke the overload method with C<I<X>> as an argument.
813 Instead the above table is consulted as normal, and based on the type of
814 C<I<X>>, overloading may or may not be invoked.  For simple strings or
815 numbers, "in" becomes equivalent to this:
816
817     $object ~~ $number          ref($object) == $number
818     $object ~~ $string          ref($object) eq $string
819
820 For example, this reports that the handle smells IOish
821 (but please don't really do this!):
822
823     use IO::Handle;
824     my $fh = IO::Handle->new();
825     if ($fh ~~ /\bIO\b/) {
826         say "handle smells IOish";
827     }
828
829 That's because it treats C<$fh> as a string like
830 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
831
832 =head2 Bitwise And
833 X<operator, bitwise, and> X<bitwise and> X<&>
834
835 Binary C<"&"> returns its operands ANDed together bit by bit.  Although no
836 warning is currently raised, the result is not well defined when this operation
837 is performed on operands that aren't either numbers (see
838 L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String Operators>).
839
840 Note that C<"&"> has lower priority than relational operators, so for example
841 the parentheses are essential in a test like
842
843     print "Even\n" if ($x & 1) == 0;
844
845 If the experimental "bitwise" feature is enabled via S<C<use feature
846 'bitwise'>>, then this operator always treats its operand as numbers.  This
847 feature produces a warning unless you also use C<S<no warnings
848 'experimental::bitwise'>>.
849
850 =head2 Bitwise Or and Exclusive Or
851 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
852 X<bitwise xor> X<^>
853
854 Binary C<"|"> returns its operands ORed together bit by bit.
855
856 Binary C<"^"> returns its operands XORed together bit by bit.
857
858 Although no warning is currently raised, the results are not well
859 defined when these operations are performed on operands that aren't either
860 numbers (see L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String
861 Operators>).
862
863 Note that C<"|"> and C<"^"> have lower priority than relational operators, so
864 for example the parentheses are essential in a test like
865
866     print "false\n" if (8 | 2) != 10;
867
868 If the experimental "bitwise" feature is enabled via S<C<use feature
869 'bitwise'>>, then this operator always treats its operand as numbers.  This
870 feature produces a warning unless you also use S<C<no warnings
871 'experimental::bitwise'>>.
872
873 =head2 C-style Logical And
874 X<&&> X<logical and> X<operator, logical, and>
875
876 Binary C<"&&"> performs a short-circuit logical AND operation.  That is,
877 if the left operand is false, the right operand is not even evaluated.
878 Scalar or list context propagates down to the right operand if it
879 is evaluated.
880
881 =head2 C-style Logical Or
882 X<||> X<operator, logical, or>
883
884 Binary C<"||"> performs a short-circuit logical OR operation.  That is,
885 if the left operand is true, the right operand is not even evaluated.
886 Scalar or list context propagates down to the right operand if it
887 is evaluated.
888
889 =head2 Logical Defined-Or
890 X<//> X<operator, logical, defined-or>
891
892 Although it has no direct equivalent in C, Perl's C<//> operator is related
893 to its C-style "or".  In fact, it's exactly the same as C<||>, except that it
894 tests the left hand side's definedness instead of its truth.  Thus,
895 S<C<< EXPR1 // EXPR2 >>> returns the value of C<< EXPR1 >> if it's defined,
896 otherwise, the value of C<< EXPR2 >> is returned.
897 (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >>
898 in the context of C<< // >> itself).  Usually,
899 this is the same result as S<C<< defined(EXPR1) ? EXPR1 : EXPR2 >>> (except that
900 the ternary-operator form can be used as a lvalue, while S<C<< EXPR1 // EXPR2 >>>
901 cannot).  This is very useful for
902 providing default values for variables.  If you actually want to test if
903 at least one of C<$x> and C<$y> is defined, use S<C<defined($x // $y)>>.
904
905 The C<||>, C<//> and C<&&> operators return the last value evaluated
906 (unlike C's C<||> and C<&&>, which return 0 or 1).  Thus, a reasonably
907 portable way to find out the home directory might be:
908
909     $home =  $ENV{HOME}
910           // $ENV{LOGDIR}
911           // (getpwuid($<))[7]
912           // die "You're homeless!\n";
913
914 In particular, this means that you shouldn't use this
915 for selecting between two aggregates for assignment:
916
917     @a = @b || @c;            # This doesn't do the right thing
918     @a = scalar(@b) || @c;    # because it really means this.
919     @a = @b ? @b : @c;        # This works fine, though.
920
921 As alternatives to C<&&> and C<||> when used for
922 control flow, Perl provides the C<and> and C<or> operators (see below).
923 The short-circuit behavior is identical.  The precedence of C<"and">
924 and C<"or"> is much lower, however, so that you can safely use them after a
925 list operator without the need for parentheses:
926
927     unlink "alpha", "beta", "gamma"
928             or gripe(), next LINE;
929
930 With the C-style operators that would have been written like this:
931
932     unlink("alpha", "beta", "gamma")
933             || (gripe(), next LINE);
934
935 It would be even more readable to write that this way:
936
937     unless(unlink("alpha", "beta", "gamma")) {
938         gripe();
939         next LINE;
940     }
941
942 Using C<"or"> for assignment is unlikely to do what you want; see below.
943
944 =head2 Range Operators
945 X<operator, range> X<range> X<..> X<...>
946
947 Binary C<".."> is the range operator, which is really two different
948 operators depending on the context.  In list context, it returns a
949 list of values counting (up by ones) from the left value to the right
950 value.  If the left value is greater than the right value then it
951 returns the empty list.  The range operator is useful for writing
952 S<C<foreach (1..10)>> loops and for doing slice operations on arrays.  In
953 the current implementation, no temporary array is created when the
954 range operator is used as the expression in C<foreach> loops, but older
955 versions of Perl might burn a lot of memory when you write something
956 like this:
957
958     for (1 .. 1_000_000) {
959         # code
960     }
961
962 The range operator also works on strings, using the magical
963 auto-increment, see below.
964
965 In scalar context, C<".."> returns a boolean value.  The operator is
966 bistable, like a flip-flop, and emulates the line-range (comma)
967 operator of B<sed>, B<awk>, and various editors.  Each C<".."> operator
968 maintains its own boolean state, even across calls to a subroutine
969 that contains it.  It is false as long as its left operand is false.
970 Once the left operand is true, the range operator stays true until the
971 right operand is true, I<AFTER> which the range operator becomes false
972 again.  It doesn't become false till the next time the range operator
973 is evaluated.  It can test the right operand and become false on the
974 same evaluation it became true (as in B<awk>), but it still returns
975 true once.  If you don't want it to test the right operand until the
976 next evaluation, as in B<sed>, just use three dots (C<"...">) instead of
977 two.  In all other regards, C<"..."> behaves just like C<".."> does.
978
979 The right operand is not evaluated while the operator is in the
980 "false" state, and the left operand is not evaluated while the
981 operator is in the "true" state.  The precedence is a little lower
982 than || and &&.  The value returned is either the empty string for
983 false, or a sequence number (beginning with 1) for true.  The sequence
984 number is reset for each range encountered.  The final sequence number
985 in a range has the string C<"E0"> appended to it, which doesn't affect
986 its numeric value, but gives you something to search for if you want
987 to exclude the endpoint.  You can exclude the beginning point by
988 waiting for the sequence number to be greater than 1.
989
990 If either operand of scalar C<".."> is a constant expression,
991 that operand is considered true if it is equal (C<==>) to the current
992 input line number (the C<$.> variable).
993
994 To be pedantic, the comparison is actually S<C<int(EXPR) == int(EXPR)>>,
995 but that is only an issue if you use a floating point expression; when
996 implicitly using C<$.> as described in the previous paragraph, the
997 comparison is S<C<int(EXPR) == int($.)>> which is only an issue when C<$.>
998 is set to a floating point value and you are not reading from a file.
999 Furthermore, S<C<"span" .. "spat">> or S<C<2.18 .. 3.14>> will not do what
1000 you want in scalar context because each of the operands are evaluated
1001 using their integer representation.
1002
1003 Examples:
1004
1005 As a scalar operator:
1006
1007     if (101 .. 200) { print; } # print 2nd hundred lines, short for
1008                                #  if ($. == 101 .. $. == 200) { print; }
1009
1010     next LINE if (1 .. /^$/);  # skip header lines, short for
1011                                #   next LINE if ($. == 1 .. /^$/);
1012                                # (typically in a loop labeled LINE)
1013
1014     s/^/> / if (/^$/ .. eof());  # quote body
1015
1016     # parse mail messages
1017     while (<>) {
1018         $in_header =   1  .. /^$/;
1019         $in_body   = /^$/ .. eof;
1020         if ($in_header) {
1021             # do something
1022         } else { # in body
1023             # do something else
1024         }
1025     } continue {
1026         close ARGV if eof;             # reset $. each file
1027     }
1028
1029 Here's a simple example to illustrate the difference between
1030 the two range operators:
1031
1032     @lines = ("   - Foo",
1033               "01 - Bar",
1034               "1  - Baz",
1035               "   - Quux");
1036
1037     foreach (@lines) {
1038         if (/0/ .. /1/) {
1039             print "$_\n";
1040         }
1041     }
1042
1043 This program will print only the line containing "Bar".  If
1044 the range operator is changed to C<...>, it will also print the
1045 "Baz" line.
1046
1047 And now some examples as a list operator:
1048
1049     for (101 .. 200) { print }      # print $_ 100 times
1050     @foo = @foo[0 .. $#foo];        # an expensive no-op
1051     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1052
1053 The range operator (in list context) makes use of the magical
1054 auto-increment algorithm if the operands are strings.  You
1055 can say
1056
1057     @alphabet = ("A" .. "Z");
1058
1059 to get all normal letters of the English alphabet, or
1060
1061     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1062
1063 to get a hexadecimal digit, or
1064
1065     @z2 = ("01" .. "31");
1066     print $z2[$mday];
1067
1068 to get dates with leading zeros.
1069
1070 If the final value specified is not in the sequence that the magical
1071 increment would produce, the sequence goes until the next value would
1072 be longer than the final value specified.
1073
1074 As of Perl 5.26, the list-context range operator on strings works as expected
1075 in the scope of L<< S<C<"use feature 'unicode_strings">>|feature/The
1076 'unicode_strings' feature >>. In previous versions, and outside the scope of
1077 that feature, it exhibits L<perlunicode/The "Unicode Bug">: its behavior
1078 depends on the internal encoding of the range endpoint.
1079
1080 If the initial value specified isn't part of a magical increment
1081 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1082 only the initial value will be returned.  So the following will only
1083 return an alpha:
1084
1085     use charnames "greek";
1086     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1087
1088 To get the 25 traditional lowercase Greek letters, including both sigmas,
1089 you could use this instead:
1090
1091     use charnames "greek";
1092     my @greek_small =  map { chr } ( ord("\N{alpha}")
1093                                         ..
1094                                      ord("\N{omega}")
1095                                    );
1096
1097 However, because there are I<many> other lowercase Greek characters than
1098 just those, to match lowercase Greek characters in a regular expression,
1099 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1100 L<experimental feature|perlrecharclass/Extended Bracketed Character
1101 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1102
1103 Because each operand is evaluated in integer form, S<C<2.18 .. 3.14>> will
1104 return two elements in list context.
1105
1106     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1107
1108 =head2 Conditional Operator
1109 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1110
1111 Ternary C<"?:"> is the conditional operator, just as in C.  It works much
1112 like an if-then-else.  If the argument before the C<?> is true, the
1113 argument before the C<:> is returned, otherwise the argument after the
1114 C<:> is returned.  For example:
1115
1116     printf "I have %d dog%s.\n", $n,
1117             ($n == 1) ? "" : "s";
1118
1119 Scalar or list context propagates downward into the 2nd
1120 or 3rd argument, whichever is selected.
1121
1122     $x = $ok ? $y : $z;  # get a scalar
1123     @x = $ok ? @y : @z;  # get an array
1124     $x = $ok ? @y : @z;  # oops, that's just a count!
1125
1126 The operator may be assigned to if both the 2nd and 3rd arguments are
1127 legal lvalues (meaning that you can assign to them):
1128
1129     ($x_or_y ? $x : $y) = $z;
1130
1131 Because this operator produces an assignable result, using assignments
1132 without parentheses will get you in trouble.  For example, this:
1133
1134     $x % 2 ? $x += 10 : $x += 2
1135
1136 Really means this:
1137
1138     (($x % 2) ? ($x += 10) : $x) += 2
1139
1140 Rather than this:
1141
1142     ($x % 2) ? ($x += 10) : ($x += 2)
1143
1144 That should probably be written more simply as:
1145
1146     $x += ($x % 2) ? 10 : 2;
1147
1148 =head2 Assignment Operators
1149 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1150 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1151 X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=>
1152
1153 C<"="> is the ordinary assignment operator.
1154
1155 Assignment operators work as in C.  That is,
1156
1157     $x += 2;
1158
1159 is equivalent to
1160
1161     $x = $x + 2;
1162
1163 although without duplicating any side effects that dereferencing the lvalue
1164 might trigger, such as from C<tie()>.  Other assignment operators work similarly.
1165 The following are recognized:
1166
1167     **=    +=    *=    &=    &.=    <<=    &&=
1168            -=    /=    |=    |.=    >>=    ||=
1169            .=    %=    ^=    ^.=           //=
1170                  x=
1171
1172 Although these are grouped by family, they all have the precedence
1173 of assignment.  These combined assignment operators can only operate on
1174 scalars, whereas the ordinary assignment operator can assign to arrays,
1175 hashes, lists and even references.  (See L<"Context"|perldata/Context>
1176 and L<perldata/List value constructors>, and L<perlref/Assigning to
1177 References>.)
1178
1179 Unlike in C, the scalar assignment operator produces a valid lvalue.
1180 Modifying an assignment is equivalent to doing the assignment and
1181 then modifying the variable that was assigned to.  This is useful
1182 for modifying a copy of something, like this:
1183
1184     ($tmp = $global) =~ tr/13579/24680/;
1185
1186 Although as of 5.14, that can be also be accomplished this way:
1187
1188     use v5.14;
1189     $tmp = ($global =~  tr/13579/24680/r);
1190
1191 Likewise,
1192
1193     ($x += 2) *= 3;
1194
1195 is equivalent to
1196
1197     $x += 2;
1198     $x *= 3;
1199
1200 Similarly, a list assignment in list context produces the list of
1201 lvalues assigned to, and a list assignment in scalar context returns
1202 the number of elements produced by the expression on the right hand
1203 side of the assignment.
1204
1205 The three dotted bitwise assignment operators (C<&.=> C<|.=> C<^.=>) are new in
1206 Perl 5.22 and experimental.  See L</Bitwise String Operators>.
1207
1208 =head2 Comma Operator
1209 X<comma> X<operator, comma> X<,>
1210
1211 Binary C<","> is the comma operator.  In scalar context it evaluates
1212 its left argument, throws that value away, then evaluates its right
1213 argument and returns that value.  This is just like C's comma operator.
1214
1215 In list context, it's just the list argument separator, and inserts
1216 both its arguments into the list.  These arguments are also evaluated
1217 from left to right.
1218
1219 The C<< => >> operator (sometimes pronounced "fat comma") is a synonym
1220 for the comma except that it causes a
1221 word on its left to be interpreted as a string if it begins with a letter
1222 or underscore and is composed only of letters, digits and underscores.
1223 This includes operands that might otherwise be interpreted as operators,
1224 constants, single number v-strings or function calls.  If in doubt about
1225 this behavior, the left operand can be quoted explicitly.
1226
1227 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1228 or list argument separator, according to context.
1229
1230 For example:
1231
1232     use constant FOO => "something";
1233
1234     my %h = ( FOO => 23 );
1235
1236 is equivalent to:
1237
1238     my %h = ("FOO", 23);
1239
1240 It is I<NOT>:
1241
1242     my %h = ("something", 23);
1243
1244 The C<< => >> operator is helpful in documenting the correspondence
1245 between keys and values in hashes, and other paired elements in lists.
1246
1247     %hash = ( $key => $value );
1248     login( $username => $password );
1249
1250 The special quoting behavior ignores precedence, and hence may apply to
1251 I<part> of the left operand:
1252
1253     print time.shift => "bbb";
1254
1255 That example prints something like C<"1314363215shiftbbb">, because the
1256 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1257 the fact that C<time.shift> is the entire left operand.
1258
1259 =head2 List Operators (Rightward)
1260 X<operator, list, rightward> X<list operator>
1261
1262 On the right side of a list operator, the comma has very low precedence,
1263 such that it controls all comma-separated expressions found there.
1264 The only operators with lower precedence are the logical operators
1265 C<"and">, C<"or">, and C<"not">, which may be used to evaluate calls to list
1266 operators without the need for parentheses:
1267
1268     open HANDLE, "< :encoding(UTF-8)", "filename"
1269         or die "Can't open: $!\n";
1270
1271 However, some people find that code harder to read than writing
1272 it with parentheses:
1273
1274     open(HANDLE, "< :encoding(UTF-8)", "filename")
1275         or die "Can't open: $!\n";
1276
1277 in which case you might as well just use the more customary C<"||"> operator:
1278
1279     open(HANDLE, "< :encoding(UTF-8)", "filename")
1280         || die "Can't open: $!\n";
1281
1282 See also discussion of list operators in L</Terms and List Operators (Leftward)>.
1283
1284 =head2 Logical Not
1285 X<operator, logical, not> X<not>
1286
1287 Unary C<"not"> returns the logical negation of the expression to its right.
1288 It's the equivalent of C<"!"> except for the very low precedence.
1289
1290 =head2 Logical And
1291 X<operator, logical, and> X<and>
1292
1293 Binary C<"and"> returns the logical conjunction of the two surrounding
1294 expressions.  It's equivalent to C<&&> except for the very low
1295 precedence.  This means that it short-circuits: the right
1296 expression is evaluated only if the left expression is true.
1297
1298 =head2 Logical or and Exclusive Or
1299 X<operator, logical, or> X<operator, logical, xor>
1300 X<operator, logical, exclusive or>
1301 X<or> X<xor>
1302
1303 Binary C<"or"> returns the logical disjunction of the two surrounding
1304 expressions.  It's equivalent to C<||> except for the very low precedence.
1305 This makes it useful for control flow:
1306
1307     print FH $data              or die "Can't write to FH: $!";
1308
1309 This means that it short-circuits: the right expression is evaluated
1310 only if the left expression is false.  Due to its precedence, you must
1311 be careful to avoid using it as replacement for the C<||> operator.
1312 It usually works out better for flow control than in assignments:
1313
1314     $x = $y or $z;              # bug: this is wrong
1315     ($x = $y) or $z;            # really means this
1316     $x = $y || $z;              # better written this way
1317
1318 However, when it's a list-context assignment and you're trying to use
1319 C<||> for control flow, you probably need C<"or"> so that the assignment
1320 takes higher precedence.
1321
1322     @info = stat($file) || die;     # oops, scalar sense of stat!
1323     @info = stat($file) or die;     # better, now @info gets its due
1324
1325 Then again, you could always use parentheses.
1326
1327 Binary C<"xor"> returns the exclusive-OR of the two surrounding expressions.
1328 It cannot short-circuit (of course).
1329
1330 There is no low precedence operator for defined-OR.
1331
1332 =head2 C Operators Missing From Perl
1333 X<operator, missing from perl> X<&> X<*>
1334 X<typecasting> X<(TYPE)>
1335
1336 Here is what C has that Perl doesn't:
1337
1338 =over 8
1339
1340 =item unary &
1341
1342 Address-of operator.  (But see the C<"\"> operator for taking a reference.)
1343
1344 =item unary *
1345
1346 Dereference-address operator.  (Perl's prefix dereferencing
1347 operators are typed: C<$>, C<@>, C<%>, and C<&>.)
1348
1349 =item (TYPE)
1350
1351 Type-casting operator.
1352
1353 =back
1354
1355 =head2 Quote and Quote-like Operators
1356 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1357 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1358 X<escape sequence> X<escape>
1359
1360 While we usually think of quotes as literal values, in Perl they
1361 function as operators, providing various kinds of interpolating and
1362 pattern matching capabilities.  Perl provides customary quote characters
1363 for these behaviors, but also provides a way for you to choose your
1364 quote character for any of them.  In the following table, a C<{}> represents
1365 any pair of delimiters you choose.
1366
1367     Customary  Generic        Meaning        Interpolates
1368         ''       q{}          Literal             no
1369         ""      qq{}          Literal             yes
1370         ``      qx{}          Command             yes*
1371                 qw{}         Word list            no
1372         //       m{}       Pattern match          yes*
1373                 qr{}          Pattern             yes*
1374                  s{}{}      Substitution          yes*
1375                 tr{}{}    Transliteration         no (but see below)
1376                  y{}{}    Transliteration         no (but see below)
1377         <<EOF                 here-doc            yes*
1378
1379         * unless the delimiter is ''.
1380
1381 Non-bracketing delimiters use the same character fore and aft, but the four
1382 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1383 that
1384
1385     q{foo{bar}baz}
1386
1387 is the same as
1388
1389     'foo{bar}baz'
1390
1391 Note, however, that this does not always work for quoting Perl code:
1392
1393     $s = q{ if($x eq "}") ... }; # WRONG
1394
1395 is a syntax error.  The C<L<Text::Balanced>> module (standard as of v5.8,
1396 and from CPAN before then) is able to do this properly.
1397
1398 There can (and in some cases, must) be whitespace between the operator
1399 and the quoting
1400 characters, except when C<#> is being used as the quoting character.
1401 C<q#foo#> is parsed as the string C<foo>, while S<C<q #foo#>> is the
1402 operator C<q> followed by a comment.  Its argument will be taken
1403 from the next line.  This allows you to write:
1404
1405     s {foo}  # Replace foo
1406       {bar}  # with bar.
1407
1408 The cases where whitespace must be used are when the quoting character
1409 is a word character (meaning it matches C</\w/>):
1410
1411     q XfooX # Works: means the string 'foo'
1412     qXfooX  # WRONG!
1413
1414 The following escape sequences are available in constructs that interpolate,
1415 and in transliterations:
1416 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1417 X<\o{}>
1418
1419     Sequence     Note  Description
1420     \t                  tab               (HT, TAB)
1421     \n                  newline           (NL)
1422     \r                  return            (CR)
1423     \f                  form feed         (FF)
1424     \b                  backspace         (BS)
1425     \a                  alarm (bell)      (BEL)
1426     \e                  escape            (ESC)
1427     \x{263A}     [1,8]  hex char          (example: SMILEY)
1428     \x1b         [2,8]  restricted range hex char (example: ESC)
1429     \N{name}     [3]    named Unicode character or character sequence
1430     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1431     \c[          [5]    control char      (example: chr(27))
1432     \o{23072}    [6,8]  octal char        (example: SMILEY)
1433     \033         [7,8]  restricted range octal char  (example: ESC)
1434
1435 =over 4
1436
1437 =item [1]
1438
1439 The result is the character specified by the hexadecimal number between
1440 the braces.  See L</[8]> below for details on which character.
1441
1442 Only hexadecimal digits are valid between the braces.  If an invalid
1443 character is encountered, a warning will be issued and the invalid
1444 character and all subsequent characters (valid or invalid) within the
1445 braces will be discarded.
1446
1447 If there are no valid digits between the braces, the generated character is
1448 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1449 will not cause a warning (currently).
1450
1451 =item [2]
1452
1453 The result is the character specified by the hexadecimal number in the range
1454 0x00 to 0xFF.  See L</[8]> below for details on which character.
1455
1456 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1457 by fewer than two valid digits, any valid digits will be zero-padded.  This
1458 means that C<\x7> will be interpreted as C<\x07>, and a lone C<"\x"> will be
1459 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1460 two valid digits will result in a warning.  Note that although the warning
1461 says the illegal character is ignored, it is only ignored as part of the
1462 escape and will still be used as the subsequent character in the string.
1463 For example:
1464
1465   Original    Result    Warns?
1466   "\x7"       "\x07"    no
1467   "\x"        "\x00"    no
1468   "\x7q"      "\x07q"   yes
1469   "\xq"       "\x00q"   yes
1470
1471 =item [3]
1472
1473 The result is the Unicode character or character sequence given by I<name>.
1474 See L<charnames>.
1475
1476 =item [4]
1477
1478 S<C<\N{U+I<hexadecimal number>}>> means the Unicode character whose Unicode code
1479 point is I<hexadecimal number>.
1480
1481 =item [5]
1482
1483 The character following C<\c> is mapped to some other character as shown in the
1484 table:
1485
1486  Sequence   Value
1487    \c@      chr(0)
1488    \cA      chr(1)
1489    \ca      chr(1)
1490    \cB      chr(2)
1491    \cb      chr(2)
1492    ...
1493    \cZ      chr(26)
1494    \cz      chr(26)
1495    \c[      chr(27)
1496                      # See below for chr(28)
1497    \c]      chr(29)
1498    \c^      chr(30)
1499    \c_      chr(31)
1500    \c?      chr(127) # (on ASCII platforms; see below for link to
1501                      #  EBCDIC discussion)
1502
1503 In other words, it's the character whose code point has had 64 xor'd with
1504 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1505 S<C<ord("?") ^ 64>> is 127, and
1506 C<\c@> is NULL because the ord of C<"@"> is 64, so xor'ing 64 itself produces 0.
1507
1508 Also, C<\c\I<X>> yields S<C< chr(28) . "I<X>">> for any I<X>, but cannot come at the
1509 end of a string, because the backslash would be parsed as escaping the end
1510 quote.
1511
1512 On ASCII platforms, the resulting characters from the list above are the
1513 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1514 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1515 differences between these for ASCII versus EBCDIC platforms.
1516
1517 Use of any other character following the C<"c"> besides those listed above is
1518 discouraged, and as of Perl v5.20, the only characters actually allowed
1519 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1520 for any of the allowed other characters is that the value is derived by
1521 xor'ing with the seventh bit, which is 64, and a warning raised if
1522 enabled.  Using the non-allowed characters generates a fatal error.
1523
1524 To get platform independent controls, you can use C<\N{...}>.
1525
1526 =item [6]
1527
1528 The result is the character specified by the octal number between the braces.
1529 See L</[8]> below for details on which character.
1530
1531 If a character that isn't an octal digit is encountered, a warning is raised,
1532 and the value is based on the octal digits before it, discarding it and all
1533 following characters up to the closing brace.  It is a fatal error if there are
1534 no octal digits at all.
1535
1536 =item [7]
1537
1538 The result is the character specified by the three-digit octal number in the
1539 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1540 L</[8]> below for details on which character.
1541
1542 Some contexts allow 2 or even 1 digit, but any usage without exactly
1543 three digits, the first being a zero, may give unintended results.  (For
1544 example, in a regular expression it may be confused with a backreference;
1545 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1546 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1547 use this construct only for ordinals C<\077> and below, remembering to pad to
1548 the left with zeros to make three digits.  For larger ordinals, either use
1549 C<\o{}>, or convert to something else, such as to hex and use C<\N{U+}>
1550 (which is portable between platforms with different character sets) or
1551 C<\x{}> instead.
1552
1553 =item [8]
1554
1555 Several constructs above specify a character by a number.  That number
1556 gives the character's position in the character set encoding (indexed from 0).
1557 This is called synonymously its ordinal, code position, or code point.  Perl
1558 works on platforms that have a native encoding currently of either ASCII/Latin1
1559 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1560 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1561 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1562 it as a Unicode code point and the result is the corresponding Unicode
1563 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1564 decimal, which is less than 256, so the number is interpreted in the native
1565 character set encoding.  In ASCII the character in the 80th position (indexed
1566 from 0) is the letter C<"P">, and in EBCDIC it is the ampersand symbol C<"&">.
1567 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1568 as a Unicode code point no matter what the native encoding is.  The name of the
1569 character in the 256th position (indexed by 0) in Unicode is
1570 C<LATIN CAPITAL LETTER A WITH MACRON>.
1571
1572 An exception to the above rule is that S<C<\N{U+I<hex number>}>> is
1573 always interpreted as a Unicode code point, so that C<\N{U+0050}> is C<"P"> even
1574 on EBCDIC platforms.
1575
1576 =back
1577
1578 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1579 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1580 use C<\N{VT}>, C<\ck>, C<\N{U+0b}>, or C<\x0b>.  (C<\v>
1581 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1582
1583 The following escape sequences are available in constructs that interpolate,
1584 but not in transliterations.
1585 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1586
1587     \l          lowercase next character only
1588     \u          titlecase (not uppercase!) next character only
1589     \L          lowercase all characters till \E or end of string
1590     \U          uppercase all characters till \E or end of string
1591     \F          foldcase all characters till \E or end of string
1592     \Q          quote (disable) pattern metacharacters till \E or
1593                 end of string
1594     \E          end either case modification or quoted section
1595                 (whichever was last seen)
1596
1597 See L<perlfunc/quotemeta> for the exact definition of characters that
1598 are quoted by C<\Q>.
1599
1600 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1601 C<\E> for each.  For example:
1602
1603  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1604  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1605
1606 If a S<C<use locale>> form that includes C<LC_CTYPE> is in effect (see
1607 L<perllocale>), the case map used by C<\l>, C<\L>, C<\u>, and C<\U> is
1608 taken from the current locale.  If Unicode (for example, C<\N{}> or code
1609 points of 0x100 or beyond) is being used, the case map used by C<\l>,
1610 C<\L>, C<\u>, and C<\U> is as defined by Unicode.  That means that
1611 case-mapping a single character can sometimes produce a sequence of
1612 several characters.
1613 Under S<C<use locale>>, C<\F> produces the same results as C<\L>
1614 for all locales but a UTF-8 one, where it instead uses the Unicode
1615 definition.
1616
1617 All systems use the virtual C<"\n"> to represent a line terminator,
1618 called a "newline".  There is no such thing as an unvarying, physical
1619 newline character.  It is only an illusion that the operating system,
1620 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1621 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1622 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1623 and on systems without a line terminator,
1624 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1625 you mean a "newline" for your system, but use the literal ASCII when you
1626 need an exact character.  For example, most networking protocols expect
1627 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1628 and although they often accept just C<"\012">, they seldom tolerate just
1629 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1630 you may be burned some day.
1631 X<newline> X<line terminator> X<eol> X<end of line>
1632 X<\n> X<\r> X<\r\n>
1633
1634 For constructs that do interpolate, variables beginning with "C<$>"
1635 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1636 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1637 But method calls such as C<< $obj->meth >> are not.
1638
1639 Interpolating an array or slice interpolates the elements in order,
1640 separated by the value of C<$">, so is equivalent to interpolating
1641 S<C<join $", @array>>.  "Punctuation" arrays such as C<@*> are usually
1642 interpolated only if the name is enclosed in braces C<@{*}>, but the
1643 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1644
1645 For double-quoted strings, the quoting from C<\Q> is applied after
1646 interpolation and escapes are processed.
1647
1648     "abc\Qfoo\tbar$s\Exyz"
1649
1650 is equivalent to
1651
1652     "abc" . quotemeta("foo\tbar$s") . "xyz"
1653
1654 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1655 the quoting from C<\Q> is applied after interpolation is processed,
1656 but before escapes are processed.  This allows the pattern to match
1657 literally (except for C<$> and C<@>).  For example, the following matches:
1658
1659     '\s\t' =~ /\Q\s\t/
1660
1661 Because C<$> or C<@> trigger interpolation, you'll need to use something
1662 like C</\Quser\E\@\Qhost/> to match them literally.
1663
1664 Patterns are subject to an additional level of interpretation as a
1665 regular expression.  This is done as a second pass, after variables are
1666 interpolated, so that regular expressions may be incorporated into the
1667 pattern from the variables.  If this is not what you want, use C<\Q> to
1668 interpolate a variable literally.
1669
1670 Apart from the behavior described above, Perl does not expand
1671 multiple levels of interpolation.  In particular, contrary to the
1672 expectations of shell programmers, back-quotes do I<NOT> interpolate
1673 within double quotes, nor do single quotes impede evaluation of
1674 variables when used within double quotes.
1675
1676 =head2 Regexp Quote-Like Operators
1677 X<operator, regexp>
1678
1679 Here are the quote-like operators that apply to pattern
1680 matching and related activities.
1681
1682 =over 8
1683
1684 =item C<qr/I<STRING>/msixpodualn>
1685 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1686
1687 This operator quotes (and possibly compiles) its I<STRING> as a regular
1688 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1689 in C<m/I<PATTERN>/>.  If C<"'"> is used as the delimiter, no variable
1690 interpolation is done.  Returns a Perl value which may be used instead of the
1691 corresponding C</I<STRING>/msixpodualn> expression.  The returned value is a
1692 normalized version of the original pattern.  It magically differs from
1693 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1694 however, dereferencing it is not well defined (you currently get the
1695 normalized version of the original pattern, but this may change).
1696
1697
1698 For example,
1699
1700     $rex = qr/my.STRING/is;
1701     print $rex;                 # prints (?si-xm:my.STRING)
1702     s/$rex/foo/;
1703
1704 is equivalent to
1705
1706     s/my.STRING/foo/is;
1707
1708 The result may be used as a subpattern in a match:
1709
1710     $re = qr/$pattern/;
1711     $string =~ /foo${re}bar/;   # can be interpolated in other
1712                                 # patterns
1713     $string =~ $re;             # or used standalone
1714     $string =~ /$re/;           # or this way
1715
1716 Since Perl may compile the pattern at the moment of execution of the C<qr()>
1717 operator, using C<qr()> may have speed advantages in some situations,
1718 notably if the result of C<qr()> is used standalone:
1719
1720     sub match {
1721         my $patterns = shift;
1722         my @compiled = map qr/$_/i, @$patterns;
1723         grep {
1724             my $success = 0;
1725             foreach my $pat (@compiled) {
1726                 $success = 1, last if /$pat/;
1727             }
1728             $success;
1729         } @_;
1730     }
1731
1732 Precompilation of the pattern into an internal representation at
1733 the moment of C<qr()> avoids the need to recompile the pattern every
1734 time a match C</$pat/> is attempted.  (Perl has many other internal
1735 optimizations, but none would be triggered in the above example if
1736 we did not use C<qr()> operator.)
1737
1738 Options (specified by the following modifiers) are:
1739
1740     m   Treat string as multiple lines.
1741     s   Treat string as single line. (Make . match a newline)
1742     i   Do case-insensitive pattern matching.
1743     x   Use extended regular expressions; specifying two
1744         x's means \t and the SPACE character are ignored within
1745         square-bracketed character classes
1746     p   When matching preserve a copy of the matched string so
1747         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1748         defined (ignored starting in v5.20) as these are always
1749         defined starting in that release
1750     o   Compile pattern only once.
1751     a   ASCII-restrict: Use ASCII for \d, \s, \w and [[:posix:]]
1752         character classes; specifying two a's adds the further
1753         restriction that no ASCII character will match a
1754         non-ASCII one under /i.
1755     l   Use the current run-time locale's rules.
1756     u   Use Unicode rules.
1757     d   Use Unicode or native charset, as in 5.12 and earlier.
1758     n   Non-capture mode. Don't let () fill in $1, $2, etc...
1759
1760 If a precompiled pattern is embedded in a larger pattern then the effect
1761 of C<"msixpluadn"> will be propagated appropriately.  The effect that the
1762 C</o> modifier has is not propagated, being restricted to those patterns
1763 explicitly using it.
1764
1765 The last four modifiers listed above, added in Perl 5.14,
1766 control the character set rules, but C</a> is the only one you are likely
1767 to want to specify explicitly; the other three are selected
1768 automatically by various pragmas.
1769
1770 See L<perlre> for additional information on valid syntax for I<STRING>, and
1771 for a detailed look at the semantics of regular expressions.  In
1772 particular, all modifiers except the largely obsolete C</o> are further
1773 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1774
1775 =item C<m/I<PATTERN>/msixpodualngc>
1776 X<m> X<operator, match>
1777 X<regexp, options> X<regexp> X<regex, options> X<regex>
1778 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1779
1780 =item C</I<PATTERN>/msixpodualngc>
1781
1782 Searches a string for a pattern match, and in scalar context returns
1783 true if it succeeds, false if it fails.  If no string is specified
1784 via the C<=~> or C<!~> operator, the C<$_> string is searched.  (The
1785 string specified with C<=~> need not be an lvalue--it may be the
1786 result of an expression evaluation, but remember the C<=~> binds
1787 rather tightly.)  See also L<perlre>.
1788
1789 Options are as described in C<qr//> above; in addition, the following match
1790 process modifiers are available:
1791
1792  g  Match globally, i.e., find all occurrences.
1793  c  Do not reset search position on a failed match when /g is
1794     in effect.
1795
1796 If C<"/"> is the delimiter then the initial C<m> is optional.  With the C<m>
1797 you can use any pair of non-whitespace (ASCII) characters
1798 as delimiters.  This is particularly useful for matching path names
1799 that contain C<"/">, to avoid LTS (leaning toothpick syndrome).  If C<"?"> is
1800 the delimiter, then a match-only-once rule applies,
1801 described in C<m?I<PATTERN>?> below.  If C<"'"> (single quote) is the delimiter,
1802 no variable interpolation is performed on the I<PATTERN>.
1803 When using a delimiter character valid in an identifier, whitespace is required
1804 after the C<m>.
1805
1806 I<PATTERN> may contain variables, which will be interpolated
1807 every time the pattern search is evaluated, except
1808 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1809 C<$|> are not interpolated because they look like end-of-string tests.)
1810 Perl will not recompile the pattern unless an interpolated
1811 variable that it contains changes.  You can force Perl to skip the
1812 test and never recompile by adding a C</o> (which stands for "once")
1813 after the trailing delimiter.
1814 Once upon a time, Perl would recompile regular expressions
1815 unnecessarily, and this modifier was useful to tell it not to do so, in the
1816 interests of speed.  But now, the only reasons to use C</o> are one of:
1817
1818 =over
1819
1820 =item 1
1821
1822 The variables are thousands of characters long and you know that they
1823 don't change, and you need to wring out the last little bit of speed by
1824 having Perl skip testing for that.  (There is a maintenance penalty for
1825 doing this, as mentioning C</o> constitutes a promise that you won't
1826 change the variables in the pattern.  If you do change them, Perl won't
1827 even notice.)
1828
1829 =item 2
1830
1831 you want the pattern to use the initial values of the variables
1832 regardless of whether they change or not.  (But there are saner ways
1833 of accomplishing this than using C</o>.)
1834
1835 =item 3
1836
1837 If the pattern contains embedded code, such as
1838
1839     use re 'eval';
1840     $code = 'foo(?{ $x })';
1841     /$code/
1842
1843 then perl will recompile each time, even though the pattern string hasn't
1844 changed, to ensure that the current value of C<$x> is seen each time.
1845 Use C</o> if you want to avoid this.
1846
1847 =back
1848
1849 The bottom line is that using C</o> is almost never a good idea.
1850
1851 =item The empty pattern C<//>
1852
1853 If the I<PATTERN> evaluates to the empty string, the last
1854 I<successfully> matched regular expression is used instead.  In this
1855 case, only the C<g> and C<c> flags on the empty pattern are honored;
1856 the other flags are taken from the original pattern.  If no match has
1857 previously succeeded, this will (silently) act instead as a genuine
1858 empty pattern (which will always match).
1859
1860 Note that it's possible to confuse Perl into thinking C<//> (the empty
1861 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1862 good about this, but some pathological cases might trigger this, such as
1863 C<$x///> (is that S<C<($x) / (//)>> or S<C<$x // />>?) and S<C<print $fh //>>
1864 (S<C<print $fh(//>> or S<C<print($fh //>>?).  In all of these examples, Perl
1865 will assume you meant defined-or.  If you meant the empty regex, just
1866 use parentheses or spaces to disambiguate, or even prefix the empty
1867 regex with an C<m> (so C<//> becomes C<m//>).
1868
1869 =item Matching in list context
1870
1871 If the C</g> option is not used, C<m//> in list context returns a
1872 list consisting of the subexpressions matched by the parentheses in the
1873 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1874 also set).  When there are no parentheses in the pattern, the return
1875 value is the list C<(1)> for success.
1876 With or without parentheses, an empty list is returned upon failure.
1877
1878 Examples:
1879
1880  open(TTY, "+</dev/tty")
1881     || die "can't access /dev/tty: $!";
1882
1883  <TTY> =~ /^y/i && foo();       # do foo if desired
1884
1885  if (/Version: *([0-9.]*)/) { $version = $1; }
1886
1887  next if m#^/usr/spool/uucp#;
1888
1889  # poor man's grep
1890  $arg = shift;
1891  while (<>) {
1892     print if /$arg/o; # compile only once (no longer needed!)
1893  }
1894
1895  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1896
1897 This last example splits C<$foo> into the first two words and the
1898 remainder of the line, and assigns those three fields to C<$F1>, C<$F2>, and
1899 C<$Etc>.  The conditional is true if any variables were assigned; that is,
1900 if the pattern matched.
1901
1902 The C</g> modifier specifies global pattern matching--that is,
1903 matching as many times as possible within the string.  How it behaves
1904 depends on the context.  In list context, it returns a list of the
1905 substrings matched by any capturing parentheses in the regular
1906 expression.  If there are no parentheses, it returns a list of all
1907 the matched strings, as if there were parentheses around the whole
1908 pattern.
1909
1910 In scalar context, each execution of C<m//g> finds the next match,
1911 returning true if it matches, and false if there is no further match.
1912 The position after the last match can be read or set using the C<pos()>
1913 function; see L<perlfunc/pos>.  A failed match normally resets the
1914 search position to the beginning of the string, but you can avoid that
1915 by adding the C</c> modifier (for example, C<m//gc>).  Modifying the target
1916 string also resets the search position.
1917
1918 =item C<\G I<assertion>>
1919
1920 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1921 zero-width assertion that matches the exact position where the
1922 previous C<m//g>, if any, left off.  Without the C</g> modifier, the
1923 C<\G> assertion still anchors at C<pos()> as it was at the start of
1924 the operation (see L<perlfunc/pos>), but the match is of course only
1925 attempted once.  Using C<\G> without C</g> on a target string that has
1926 not previously had a C</g> match applied to it is the same as using
1927 the C<\A> assertion to match the beginning of the string.  Note also
1928 that, currently, C<\G> is only properly supported when anchored at the
1929 very beginning of the pattern.
1930
1931 Examples:
1932
1933     # list context
1934     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1935
1936     # scalar context
1937     local $/ = "";
1938     while ($paragraph = <>) {
1939         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1940             $sentences++;
1941         }
1942     }
1943     say $sentences;
1944
1945 Here's another way to check for sentences in a paragraph:
1946
1947  my $sentence_rx = qr{
1948     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1949                                 # whitespace
1950     \p{Lu}                      # capital letter
1951     .*?                         # a bunch of anything
1952     (?<= \S )                   # that ends in non-
1953                                 # whitespace
1954     (?<! \b [DMS]r  )           # but isn't a common abbr.
1955     (?<! \b Mrs )
1956     (?<! \b Sra )
1957     (?<! \b St  )
1958     [.?!]                       # followed by a sentence
1959                                 # ender
1960     (?= $ | \s )                # in front of end-of-string
1961                                 # or whitespace
1962  }sx;
1963  local $/ = "";
1964  while (my $paragraph = <>) {
1965     say "NEW PARAGRAPH";
1966     my $count = 0;
1967     while ($paragraph =~ /($sentence_rx)/g) {
1968         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1969     }
1970  }
1971
1972 Here's how to use C<m//gc> with C<\G>:
1973
1974     $_ = "ppooqppqq";
1975     while ($i++ < 2) {
1976         print "1: '";
1977         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1978         print "2: '";
1979         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1980         print "3: '";
1981         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1982     }
1983     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1984
1985 The last example should print:
1986
1987     1: 'oo', pos=4
1988     2: 'q', pos=5
1989     3: 'pp', pos=7
1990     1: '', pos=7
1991     2: 'q', pos=8
1992     3: '', pos=8
1993     Final: 'q', pos=8
1994
1995 Notice that the final match matched C<q> instead of C<p>, which a match
1996 without the C<\G> anchor would have done.  Also note that the final match
1997 did not update C<pos>.  C<pos> is only updated on a C</g> match.  If the
1998 final match did indeed match C<p>, it's a good bet that you're running a
1999 very old (pre-5.6.0) version of Perl.
2000
2001 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
2002 combine several regexps like this to process a string part-by-part,
2003 doing different actions depending on which regexp matched.  Each
2004 regexp tries to match where the previous one leaves off.
2005
2006  $_ = <<'EOL';
2007     $url = URI::URL->new( "http://example.com/" );
2008     die if $url eq "xXx";
2009  EOL
2010
2011  LOOP: {
2012      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
2013      print(" lowercase"),    redo LOOP
2014                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
2015      print(" UPPERCASE"),    redo LOOP
2016                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
2017      print(" Capitalized"),  redo LOOP
2018                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
2019      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
2020      print(" alphanumeric"), redo LOOP
2021                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
2022      print(" line-noise"),   redo LOOP if /\G\W+/gc;
2023      print ". That's all!\n";
2024  }
2025
2026 Here is the output (split into several lines):
2027
2028  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
2029  line-noise lowercase line-noise lowercase line-noise lowercase
2030  lowercase line-noise lowercase lowercase line-noise lowercase
2031  lowercase line-noise MiXeD line-noise. That's all!
2032
2033 =item C<m?I<PATTERN>?msixpodualngc>
2034 X<?> X<operator, match-once>
2035
2036 This is just like the C<m/I<PATTERN>/> search, except that it matches
2037 only once between calls to the C<reset()> operator.  This is a useful
2038 optimization when you want to see only the first occurrence of
2039 something in each file of a set of files, for instance.  Only C<m??>
2040 patterns local to the current package are reset.
2041
2042     while (<>) {
2043         if (m?^$?) {
2044                             # blank line between header and body
2045         }
2046     } continue {
2047         reset if eof;       # clear m?? status for next file
2048     }
2049
2050 Another example switched the first "latin1" encoding it finds
2051 to "utf8" in a pod file:
2052
2053     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
2054
2055 The match-once behavior is controlled by the match delimiter being
2056 C<?>; with any other delimiter this is the normal C<m//> operator.
2057
2058 In the past, the leading C<m> in C<m?I<PATTERN>?> was optional, but omitting it
2059 would produce a deprecation warning.  As of v5.22.0, omitting it produces a
2060 syntax error.  If you encounter this construct in older code, you can just add
2061 C<m>.
2062
2063 =item C<s/I<PATTERN>/I<REPLACEMENT>/msixpodualngcer>
2064 X<s> X<substitute> X<substitution> X<replace> X<regexp, replace>
2065 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2066
2067 Searches a string for a pattern, and if found, replaces that pattern
2068 with the replacement text and returns the number of substitutions
2069 made.  Otherwise it returns false (a value that is both an empty string (C<"">)
2070 and numeric zero (C<0>) as described in L</Relational Operators>).
2071
2072 If the C</r> (non-destructive) option is used then it runs the
2073 substitution on a copy of the string and instead of returning the
2074 number of substitutions, it returns the copy whether or not a
2075 substitution occurred.  The original string is never changed when
2076 C</r> is used.  The copy will always be a plain string, even if the
2077 input is an object or a tied variable.
2078
2079 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2080 variable is searched and modified.  Unless the C</r> option is used,
2081 the string specified must be a scalar variable, an array element, a
2082 hash element, or an assignment to one of those; that is, some sort of
2083 scalar lvalue.
2084
2085 If the delimiter chosen is a single quote, no variable interpolation is
2086 done on either the I<PATTERN> or the I<REPLACEMENT>.  Otherwise, if the
2087 I<PATTERN> contains a C<$> that looks like a variable rather than an
2088 end-of-string test, the variable will be interpolated into the pattern
2089 at run-time.  If you want the pattern compiled only once the first time
2090 the variable is interpolated, use the C</o> option.  If the pattern
2091 evaluates to the empty string, the last successfully executed regular
2092 expression is used instead.  See L<perlre> for further explanation on these.
2093
2094 Options are as with C<m//> with the addition of the following replacement
2095 specific options:
2096
2097     e   Evaluate the right side as an expression.
2098     ee  Evaluate the right side as a string then eval the
2099         result.
2100     r   Return substitution and leave the original string
2101         untouched.
2102
2103 Any non-whitespace delimiter may replace the slashes.  Add space after
2104 the C<s> when using a character allowed in identifiers.  If single quotes
2105 are used, no interpretation is done on the replacement string (the C</e>
2106 modifier overrides this, however).  Note that Perl treats backticks
2107 as normal delimiters; the replacement text is not evaluated as a command.
2108 If the I<PATTERN> is delimited by bracketing quotes, the I<REPLACEMENT> has
2109 its own pair of quotes, which may or may not be bracketing quotes, for example,
2110 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2111 replacement portion to be treated as a full-fledged Perl expression
2112 and evaluated right then and there.  It is, however, syntax checked at
2113 compile-time.  A second C<e> modifier will cause the replacement portion
2114 to be C<eval>ed before being run as a Perl expression.
2115
2116 Examples:
2117
2118     s/\bgreen\b/mauve/g;              # don't change wintergreen
2119
2120     $path =~ s|/usr/bin|/usr/local/bin|;
2121
2122     s/Login: $foo/Login: $bar/; # run-time pattern
2123
2124     ($foo = $bar) =~ s/this/that/;      # copy first, then
2125                                         # change
2126     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2127                                         # copy, then change
2128     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2129     $foo = $bar =~ s/this/that/r
2130                 =~ s/that/the other/r;  # Chained substitutes
2131                                         # using /r
2132     @foo = map { s/this/that/r } @bar   # /r is very useful in
2133                                         # maps
2134
2135     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2136
2137     $_ = 'abc123xyz';
2138     s/\d+/$&*2/e;               # yields 'abc246xyz'
2139     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2140     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2141
2142     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2143     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2144     s/^=(\w+)/pod($1)/ge;       # use function call
2145
2146     $_ = 'abc123xyz';
2147     $x = s/abc/def/r;           # $x is 'def123xyz' and
2148                                 # $_ remains 'abc123xyz'.
2149
2150     # expand variables in $_, but dynamics only, using
2151     # symbolic dereferencing
2152     s/\$(\w+)/${$1}/g;
2153
2154     # Add one to the value of any numbers in the string
2155     s/(\d+)/1 + $1/eg;
2156
2157     # Titlecase words in the last 30 characters only
2158     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2159
2160     # This will expand any embedded scalar variable
2161     # (including lexicals) in $_ : First $1 is interpolated
2162     # to the variable name, and then evaluated
2163     s/(\$\w+)/$1/eeg;
2164
2165     # Delete (most) C comments.
2166     $program =~ s {
2167         /\*     # Match the opening delimiter.
2168         .*?     # Match a minimal number of characters.
2169         \*/     # Match the closing delimiter.
2170     } []gsx;
2171
2172     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2173                                 # expensively
2174
2175     for ($variable) {           # trim whitespace in $variable,
2176                                 # cheap
2177         s/^\s+//;
2178         s/\s+$//;
2179     }
2180
2181     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2182
2183 Note the use of C<$> instead of C<\> in the last example.  Unlike
2184 B<sed>, we use the \<I<digit>> form only in the left hand side.
2185 Anywhere else it's $<I<digit>>.
2186
2187 Occasionally, you can't use just a C</g> to get all the changes
2188 to occur that you might want.  Here are two common cases:
2189
2190     # put commas in the right places in an integer
2191     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2192
2193     # expand tabs to 8-column spacing
2194     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2195
2196 =back
2197
2198 =head2 Quote-Like Operators
2199 X<operator, quote-like>
2200
2201 =over 4
2202
2203 =item C<q/I<STRING>/>
2204 X<q> X<quote, single> X<'> X<''>
2205
2206 =item C<'I<STRING>'>
2207
2208 A single-quoted, literal string.  A backslash represents a backslash
2209 unless followed by the delimiter or another backslash, in which case
2210 the delimiter or backslash is interpolated.
2211
2212     $foo = q!I said, "You said, 'She said it.'"!;
2213     $bar = q('This is it.');
2214     $baz = '\n';                # a two-character string
2215
2216 =item C<qq/I<STRING>/>
2217 X<qq> X<quote, double> X<"> X<"">
2218
2219 =item "I<STRING>"
2220
2221 A double-quoted, interpolated string.
2222
2223     $_ .= qq
2224      (*** The previous line contains the naughty word "$1".\n)
2225                 if /\b(tcl|java|python)\b/i;      # :-)
2226     $baz = "\n";                # a one-character string
2227
2228 =item C<qx/I<STRING>/>
2229 X<qx> X<`> X<``> X<backtick>
2230
2231 =item C<`I<STRING>`>
2232
2233 A string which is (possibly) interpolated and then executed as a
2234 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2235 pipes, and redirections will be honored.  The collected standard
2236 output of the command is returned; standard error is unaffected.  In
2237 scalar context, it comes back as a single (potentially multi-line)
2238 string, or C<undef> if the command failed.  In list context, returns a
2239 list of lines (however you've defined lines with C<$/> or
2240 C<$INPUT_RECORD_SEPARATOR>), or an empty list if the command failed.
2241
2242 Because backticks do not affect standard error, use shell file descriptor
2243 syntax (assuming the shell supports this) if you care to address this.
2244 To capture a command's STDERR and STDOUT together:
2245
2246     $output = `cmd 2>&1`;
2247
2248 To capture a command's STDOUT but discard its STDERR:
2249
2250     $output = `cmd 2>/dev/null`;
2251
2252 To capture a command's STDERR but discard its STDOUT (ordering is
2253 important here):
2254
2255     $output = `cmd 2>&1 1>/dev/null`;
2256
2257 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2258 but leave its STDOUT to come out the old STDERR:
2259
2260     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2261
2262 To read both a command's STDOUT and its STDERR separately, it's easiest
2263 to redirect them separately to files, and then read from those files
2264 when the program is done:
2265
2266     system("program args 1>program.stdout 2>program.stderr");
2267
2268 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2269 For example:
2270
2271     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2272     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2273     print STDOUT `sort`;
2274
2275 will print the sorted contents of the file named F<"stuff">.
2276
2277 Using single-quote as a delimiter protects the command from Perl's
2278 double-quote interpolation, passing it on to the shell instead:
2279
2280     $perl_info  = qx(ps $$);            # that's Perl's $$
2281     $shell_info = qx'ps $$';            # that's the new shell's $$
2282
2283 How that string gets evaluated is entirely subject to the command
2284 interpreter on your system.  On most platforms, you will have to protect
2285 shell metacharacters if you want them treated literally.  This is in
2286 practice difficult to do, as it's unclear how to escape which characters.
2287 See L<perlsec> for a clean and safe example of a manual C<fork()> and C<exec()>
2288 to emulate backticks safely.
2289
2290 On some platforms (notably DOS-like ones), the shell may not be
2291 capable of dealing with multiline commands, so putting newlines in
2292 the string may not get you what you want.  You may be able to evaluate
2293 multiple commands in a single line by separating them with the command
2294 separator character, if your shell supports that (for example, C<;> on
2295 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2296
2297 Perl will attempt to flush all files opened for
2298 output before starting the child process, but this may not be supported
2299 on some platforms (see L<perlport>).  To be safe, you may need to set
2300 C<$|> (C<$AUTOFLUSH> in C<L<English>>) or call the C<autoflush()> method of
2301 C<L<IO::Handle>> on any open handles.
2302
2303 Beware that some command shells may place restrictions on the length
2304 of the command line.  You must ensure your strings don't exceed this
2305 limit after any necessary interpolations.  See the platform-specific
2306 release notes for more details about your particular environment.
2307
2308 Using this operator can lead to programs that are difficult to port,
2309 because the shell commands called vary between systems, and may in
2310 fact not be present at all.  As one example, the C<type> command under
2311 the POSIX shell is very different from the C<type> command under DOS.
2312 That doesn't mean you should go out of your way to avoid backticks
2313 when they're the right way to get something done.  Perl was made to be
2314 a glue language, and one of the things it glues together is commands.
2315 Just understand what you're getting yourself into.
2316
2317 Like C<system>, backticks put the child process exit code in C<$?>.
2318 If you'd like to manually inspect failure, you can check all possible
2319 failure modes by inspecting C<$?> like this:
2320
2321     if ($? == -1) {
2322         print "failed to execute: $!\n";
2323     }
2324     elsif ($? & 127) {
2325         printf "child died with signal %d, %s coredump\n",
2326             ($? & 127),  ($? & 128) ? 'with' : 'without';
2327     }
2328     else {
2329         printf "child exited with value %d\n", $? >> 8;
2330     }
2331
2332 Use the L<open> pragma to control the I/O layers used when reading the
2333 output of the command, for example:
2334
2335   use open IN => ":encoding(UTF-8)";
2336   my $x = `cmd-producing-utf-8`;
2337
2338 See L</"I/O Operators"> for more discussion.
2339
2340 =item C<qw/I<STRING>/>
2341 X<qw> X<quote, list> X<quote, words>
2342
2343 Evaluates to a list of the words extracted out of I<STRING>, using embedded
2344 whitespace as the word delimiters.  It can be understood as being roughly
2345 equivalent to:
2346
2347     split(" ", q/STRING/);
2348
2349 the differences being that it generates a real list at compile time, and
2350 in scalar context it returns the last element in the list.  So
2351 this expression:
2352
2353     qw(foo bar baz)
2354
2355 is semantically equivalent to the list:
2356
2357     "foo", "bar", "baz"
2358
2359 Some frequently seen examples:
2360
2361     use POSIX qw( setlocale localeconv )
2362     @EXPORT = qw( foo bar baz );
2363
2364 A common mistake is to try to separate the words with commas or to
2365 put comments into a multi-line C<qw>-string.  For this reason, the
2366 S<C<use warnings>> pragma and the B<-w> switch (that is, the C<$^W> variable)
2367 produces warnings if the I<STRING> contains the C<","> or the C<"#"> character.
2368
2369 =item C<tr/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2370 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2371
2372 =item C<y/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2373
2374 Transliterates all occurrences of the characters found in the search list
2375 with the corresponding character in the replacement list.  It returns
2376 the number of characters replaced or deleted.  If no string is
2377 specified via the C<=~> or C<!~> operator, the C<$_> string is transliterated.
2378
2379 If the C</r> (non-destructive) option is present, a new copy of the string
2380 is made and its characters transliterated, and this copy is returned no
2381 matter whether it was modified or not: the original string is always
2382 left unchanged.  The new copy is always a plain string, even if the input
2383 string is an object or a tied variable.
2384
2385 Unless the C</r> option is used, the string specified with C<=~> must be a
2386 scalar variable, an array element, a hash element, or an assignment to one
2387 of those; in other words, an lvalue.
2388
2389 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2390 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2391 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2392 I<SEARCHLIST> is delimited by bracketing quotes, the I<REPLACEMENTLIST>
2393 must have its own pair of quotes, which may or may not be bracketing
2394 quotes; for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2395
2396 Characters may be literals or any of the escape sequences accepted in
2397 double-quoted strings.  But there is no variable interpolation, so C<"$">
2398 and C<"@"> are treated as literals.  A hyphen at the beginning or end, or
2399 preceded by a backslash is considered a literal.  Escape sequence
2400 details are in L<the table near the beginning of this section|/Quote and
2401 Quote-like Operators>.
2402
2403 Note that C<tr> does B<not> do regular expression character classes such as
2404 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the C<L<tr(1)>>
2405 utility.  C<tr[a-z][A-Z]> will uppercase the 26 letters "a" through "z",
2406 but for case changing not confined to ASCII, use
2407 L<C<lc>|perlfunc/lc>, L<C<uc>|perlfunc/uc>,
2408 L<C<lcfirst>|perlfunc/lcfirst>, L<C<ucfirst>|perlfunc/ucfirst>
2409 (all documented in L<perlfunc>), or the
2410 L<substitution operator C<sE<sol>I<PATTERN>E<sol>I<REPLACEMENT>E<sol>>|/sE<sol>PATTERNE<sol>REPLACEMENTE<sol>msixpodualngcer>
2411 (with C<\U>, C<\u>, C<\L>, and C<\l> string-interpolation escapes in the
2412 I<REPLACEMENT> portion).
2413
2414 Most ranges are unportable between character sets, but certain ones
2415 signal Perl to do special handling to make them portable.  There are two
2416 classes of portable ranges.  The first are any subsets of the ranges
2417 C<A-Z>, C<a-z>, and C<0-9>, when expressed as literal characters.
2418
2419   tr/h-k/H-K/
2420
2421 capitalizes the letters C<"h">, C<"i">, C<"j">, and C<"k"> and nothing
2422 else, no matter what the platform's character set is.  In contrast, all
2423 of
2424
2425   tr/\x68-\x6B/\x48-\x4B/
2426   tr/h-\x6B/H-\x4B/
2427   tr/\x68-k/\x48-K/
2428
2429 do the same capitalizations as the previous example when run on ASCII
2430 platforms, but something completely different on EBCDIC ones.
2431
2432 The second class of portable ranges is invoked when one or both of the
2433 range's end points are expressed as C<\N{...}>
2434
2435  $string =~ tr/\N{U+20}-\N{U+7E}//d;
2436
2437 removes from C<$string> all the platform's characters which are
2438 equivalent to any of Unicode U+0020, U+0021, ... U+007D, U+007E.  This
2439 is a portable range, and has the same effect on every platform it is
2440 run on.  It turns out that in this example, these are the ASCII
2441 printable characters.  So after this is run, C<$string> has only
2442 controls and characters which have no ASCII equivalents.
2443
2444 But, even for portable ranges, it is not generally obvious what is
2445 included without having to look things up.  A sound principle is to use
2446 only ranges that begin from and end at either ASCII alphabetics of equal
2447 case (C<b-e>, C<B-E>), or digits (C<1-4>).  Anything else is unclear
2448 (and unportable unless C<\N{...}> is used).  If in doubt, spell out the
2449 character sets in full.
2450
2451 Options:
2452
2453     c   Complement the SEARCHLIST.
2454     d   Delete found but unreplaced characters.
2455     s   Squash duplicate replaced characters.
2456     r   Return the modified string and leave the original string
2457         untouched.
2458
2459 If the C</c> modifier is specified, the I<SEARCHLIST> character set
2460 is complemented.  If the C</d> modifier is specified, any characters
2461 specified by I<SEARCHLIST> not found in I<REPLACEMENTLIST> are deleted.
2462 (Note that this is slightly more flexible than the behavior of some
2463 B<tr> programs, which delete anything they find in the I<SEARCHLIST>,
2464 period.)  If the C</s> modifier is specified, sequences of characters
2465 that were transliterated to the same character are squashed down
2466 to a single instance of the character.
2467
2468 If the C</d> modifier is used, the I<REPLACEMENTLIST> is always interpreted
2469 exactly as specified.  Otherwise, if the I<REPLACEMENTLIST> is shorter
2470 than the I<SEARCHLIST>, the final character is replicated till it is long
2471 enough.  If the I<REPLACEMENTLIST> is empty, the I<SEARCHLIST> is replicated.
2472 This latter is useful for counting characters in a class or for
2473 squashing character sequences in a class.
2474
2475 Examples:
2476
2477     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2478
2479     $cnt = tr/*/*/;             # count the stars in $_
2480
2481     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2482
2483     $cnt = tr/0-9//;            # count the digits in $_
2484
2485     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2486
2487     ($HOST = $host) =~ tr/a-z/A-Z/;
2488      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2489
2490     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2491                   =~ s/:/ -p/r;
2492
2493     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2494
2495     @stripped = map tr/a-zA-Z/ /csr, @original;
2496                                 # /r with map
2497
2498     tr [\200-\377]
2499        [\000-\177];             # wickedly delete 8th bit
2500
2501 If multiple transliterations are given for a character, only the
2502 first one is used:
2503
2504     tr/AAA/XYZ/
2505
2506 will transliterate any A to X.
2507
2508 Because the transliteration table is built at compile time, neither
2509 the I<SEARCHLIST> nor the I<REPLACEMENTLIST> are subjected to double quote
2510 interpolation.  That means that if you want to use variables, you
2511 must use an C<eval()>:
2512
2513     eval "tr/$oldlist/$newlist/";
2514     die $@ if $@;
2515
2516     eval "tr/$oldlist/$newlist/, 1" or die $@;
2517
2518 =item C<< <<I<EOF> >>
2519 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2520
2521 A line-oriented form of quoting is based on the shell "here-document"
2522 syntax.  Following a C<< << >> you specify a string to terminate
2523 the quoted material, and all lines following the current line down to
2524 the terminating string are the value of the item.
2525
2526 Prefixing the terminating string with a C<~> specifies that you
2527 want to use L</Indented Here-docs> (see below).
2528
2529 The terminating string may be either an identifier (a word), or some
2530 quoted text.  An unquoted identifier works like double quotes.
2531 There may not be a space between the C<< << >> and the identifier,
2532 unless the identifier is explicitly quoted.  (If you put a space it
2533 will be treated as a null identifier, which is valid, and matches the
2534 first empty line.)  The terminating string must appear by itself
2535 (unquoted and with no surrounding whitespace) on the terminating line.
2536
2537 If the terminating string is quoted, the type of quotes used determine
2538 the treatment of the text.
2539
2540 =over 4
2541
2542 =item Double Quotes
2543
2544 Double quotes indicate that the text will be interpolated using exactly
2545 the same rules as normal double quoted strings.
2546
2547        print <<EOF;
2548     The price is $Price.
2549     EOF
2550
2551        print << "EOF"; # same as above
2552     The price is $Price.
2553     EOF
2554
2555
2556 =item Single Quotes
2557
2558 Single quotes indicate the text is to be treated literally with no
2559 interpolation of its content.  This is similar to single quoted
2560 strings except that backslashes have no special meaning, with C<\\>
2561 being treated as two backslashes and not one as they would in every
2562 other quoting construct.
2563
2564 Just as in the shell, a backslashed bareword following the C<<< << >>>
2565 means the same thing as a single-quoted string does:
2566
2567         $cost = <<'VISTA';  # hasta la ...
2568     That'll be $10 please, ma'am.
2569     VISTA
2570
2571         $cost = <<\VISTA;   # Same thing!
2572     That'll be $10 please, ma'am.
2573     VISTA
2574
2575 This is the only form of quoting in perl where there is no need
2576 to worry about escaping content, something that code generators
2577 can and do make good use of.
2578
2579 =item Backticks
2580
2581 The content of the here doc is treated just as it would be if the
2582 string were embedded in backticks.  Thus the content is interpolated
2583 as though it were double quoted and then executed via the shell, with
2584 the results of the execution returned.
2585
2586        print << `EOC`; # execute command and get results
2587     echo hi there
2588     EOC
2589
2590 =back
2591
2592 =over 4
2593
2594 =item Indented Here-docs
2595
2596 The here-doc modifier C<~> allows you to indent your here-docs to make
2597 the code more readable:
2598
2599     if ($some_var) {
2600       print <<~EOF;
2601         This is a here-doc
2602         EOF
2603     }
2604
2605 This will print...
2606
2607     This is a here-doc
2608
2609 ...with no leading whitespace.
2610
2611 The delimiter is used to determine the B<exact> whitespace to
2612 remove from the beginning of each line.  All lines B<must> have
2613 at least the same starting whitespace (except lines only
2614 containing a newline) or perl will croak.  Tabs and spaces can
2615 be mixed, but are matched exactly.  One tab will not be equal to
2616 8 spaces!
2617
2618 Additional beginning whitespace (beyond what preceded the
2619 delimiter) will be preserved:
2620
2621     print <<~EOF;
2622       This text is not indented
2623         This text is indented with two spaces
2624                 This text is indented with two tabs
2625       EOF
2626
2627 Finally, the modifier may be used with all of the forms
2628 mentioned above:
2629
2630     <<~\EOF;
2631     <<~'EOF'
2632     <<~"EOF"
2633     <<~`EOF`
2634
2635 And whitespace may be used between the C<~> and quoted delimiters:
2636
2637     <<~ 'EOF'; # ... "EOF", `EOF`
2638
2639 =back
2640
2641 It is possible to stack multiple here-docs in a row:
2642
2643        print <<"foo", <<"bar"; # you can stack them
2644     I said foo.
2645     foo
2646     I said bar.
2647     bar
2648
2649        myfunc(<< "THIS", 23, <<'THAT');
2650     Here's a line
2651     or two.
2652     THIS
2653     and here's another.
2654     THAT
2655
2656 Just don't forget that you have to put a semicolon on the end
2657 to finish the statement, as Perl doesn't know you're not going to
2658 try to do this:
2659
2660        print <<ABC
2661     179231
2662     ABC
2663        + 20;
2664
2665 If you want to remove the line terminator from your here-docs,
2666 use C<chomp()>.
2667
2668     chomp($string = <<'END');
2669     This is a string.
2670     END
2671
2672 If you want your here-docs to be indented with the rest of the code,
2673 use the C<<< <<~FOO >>> construct described under L</Indented Here-docs>:
2674
2675     $quote = <<~'FINIS';
2676        The Road goes ever on and on,
2677        down from the door where it began.
2678        FINIS
2679
2680 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2681 the quoted material must still come on the line following the
2682 C<<< <<FOO >>> marker, which means it may be inside the delimited
2683 construct:
2684
2685     s/this/<<E . 'that'
2686     the other
2687     E
2688      . 'more '/eg;
2689
2690 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2691 you would have to write
2692
2693     s/this/<<E . 'that'
2694      . 'more '/eg;
2695     the other
2696     E
2697
2698 outside of string evals.
2699
2700 Additionally, quoting rules for the end-of-string identifier are
2701 unrelated to Perl's quoting rules.  C<q()>, C<qq()>, and the like are not
2702 supported in place of C<''> and C<"">, and the only interpolation is for
2703 backslashing the quoting character:
2704
2705     print << "abc\"def";
2706     testing...
2707     abc"def
2708
2709 Finally, quoted strings cannot span multiple lines.  The general rule is
2710 that the identifier must be a string literal.  Stick with that, and you
2711 should be safe.
2712
2713 =back
2714
2715 =head2 Gory details of parsing quoted constructs
2716 X<quote, gory details>
2717
2718 When presented with something that might have several different
2719 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2720 principle to pick the most probable interpretation.  This strategy
2721 is so successful that Perl programmers often do not suspect the
2722 ambivalence of what they write.  But from time to time, Perl's
2723 notions differ substantially from what the author honestly meant.
2724
2725 This section hopes to clarify how Perl handles quoted constructs.
2726 Although the most common reason to learn this is to unravel labyrinthine
2727 regular expressions, because the initial steps of parsing are the
2728 same for all quoting operators, they are all discussed together.
2729
2730 The most important Perl parsing rule is the first one discussed
2731 below: when processing a quoted construct, Perl first finds the end
2732 of that construct, then interprets its contents.  If you understand
2733 this rule, you may skip the rest of this section on the first
2734 reading.  The other rules are likely to contradict the user's
2735 expectations much less frequently than this first one.
2736
2737 Some passes discussed below are performed concurrently, but because
2738 their results are the same, we consider them individually.  For different
2739 quoting constructs, Perl performs different numbers of passes, from
2740 one to four, but these passes are always performed in the same order.
2741
2742 =over 4
2743
2744 =item Finding the end
2745
2746 The first pass is finding the end of the quoted construct.  This results
2747 in saving to a safe location a copy of the text (between the starting
2748 and ending delimiters), normalized as necessary to avoid needing to know
2749 what the original delimiters were.
2750
2751 If the construct is a here-doc, the ending delimiter is a line
2752 that has a terminating string as the content.  Therefore C<<<EOF> is
2753 terminated by C<EOF> immediately followed by C<"\n"> and starting
2754 from the first column of the terminating line.
2755 When searching for the terminating line of a here-doc, nothing
2756 is skipped.  In other words, lines after the here-doc syntax
2757 are compared with the terminating string line by line.
2758
2759 For the constructs except here-docs, single characters are used as starting
2760 and ending delimiters.  If the starting delimiter is an opening punctuation
2761 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2762 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2763 If the starting delimiter is an unpaired character like C</> or a closing
2764 punctuation, the ending delimiter is the same as the starting delimiter.
2765 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2766 both C<qq[]> and C<qq]]> constructs.
2767
2768 When searching for single-character delimiters, escaped delimiters
2769 and C<\\> are skipped.  For example, while searching for terminating C</>,
2770 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2771 bracketing, nested pairs are also skipped.  For example, while searching
2772 for a closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2773 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2774 However, when backslashes are used as the delimiters (like C<qq\\> and
2775 C<tr\\\>), nothing is skipped.
2776 During the search for the end, backslashes that escape delimiters or
2777 other backslashes are removed (exactly speaking, they are not copied to the
2778 safe location).
2779
2780 For constructs with three-part delimiters (C<s///>, C<y///>, and
2781 C<tr///>), the search is repeated once more.
2782 If the first delimiter is not an opening punctuation, the three delimiters must
2783 be the same, such as C<s!!!> and C<tr)))>,
2784 in which case the second delimiter
2785 terminates the left part and starts the right part at once.
2786 If the left part is delimited by bracketing punctuation (that is C<()>,
2787 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2788 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2789 and comments are allowed between the two parts, although the comment must follow
2790 at least one whitespace character; otherwise a character expected as the
2791 start of the comment may be regarded as the starting delimiter of the right part.
2792
2793 During this search no attention is paid to the semantics of the construct.
2794 Thus:
2795
2796     "$hash{"$foo/$bar"}"
2797
2798 or:
2799
2800     m/
2801       bar       # NOT a comment, this slash / terminated m//!
2802      /x
2803
2804 do not form legal quoted expressions.   The quoted part ends on the
2805 first C<"> and C</>, and the rest happens to be a syntax error.
2806 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2807 the example above is not C<m//x>, but rather C<m//> with no C</x>
2808 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2809
2810 Also no attention is paid to C<\c\> (multichar control char syntax) during
2811 this search.  Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2812 of C<\/>, and the following C</> is not recognized as a delimiter.
2813 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2814
2815 =item Interpolation
2816 X<interpolation>
2817
2818 The next step is interpolation in the text obtained, which is now
2819 delimiter-independent.  There are multiple cases.
2820
2821 =over 4
2822
2823 =item C<<<'EOF'>
2824
2825 No interpolation is performed.
2826 Note that the combination C<\\> is left intact, since escaped delimiters
2827 are not available for here-docs.
2828
2829 =item  C<m''>, the pattern of C<s'''>
2830
2831 No interpolation is performed at this stage.
2832 Any backslashed sequences including C<\\> are treated at the stage
2833 to L</"parsing regular expressions">.
2834
2835 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2836
2837 The only interpolation is removal of C<\> from pairs of C<\\>.
2838 Therefore C<"-"> in C<tr'''> and C<y'''> is treated literally
2839 as a hyphen and no character range is available.
2840 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2841
2842 =item C<tr///>, C<y///>
2843
2844 No variable interpolation occurs.  String modifying combinations for
2845 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2846 The other escape sequences such as C<\200> and C<\t> and backslashed
2847 characters such as C<\\> and C<\-> are converted to appropriate literals.
2848 The character C<"-"> is treated specially and therefore C<\-> is treated
2849 as a literal C<"-">.
2850
2851 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2852
2853 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2854 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2855 is converted to S<C<$foo . (quotemeta("baz" . $bar))>> internally.
2856 The other escape sequences such as C<\200> and C<\t> and backslashed
2857 characters such as C<\\> and C<\-> are replaced with appropriate
2858 expansions.
2859
2860 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2861 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2862 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2863 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2864 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2865 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2866 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2867
2868   $str = '\t';
2869   return "\Q$str";
2870
2871 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2872
2873 Interpolated scalars and arrays are converted internally to the C<join> and
2874 C<"."> catenation operations.  Thus, S<C<"$foo XXX '@arr'">> becomes:
2875
2876   $foo . " XXX '" . (join $", @arr) . "'";
2877
2878 All operations above are performed simultaneously, left to right.
2879
2880 Because the result of S<C<"\Q I<STRING> \E">> has all metacharacters
2881 quoted, there is no way to insert a literal C<$> or C<@> inside a
2882 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to become
2883 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2884 scalar.
2885
2886 Note also that the interpolation code needs to make a decision on
2887 where the interpolated scalar ends.  For instance, whether
2888 S<C<< "a $x -> {c}" >>> really means:
2889
2890   "a " . $x . " -> {c}";
2891
2892 or:
2893
2894   "a " . $x -> {c};
2895
2896 Most of the time, the longest possible text that does not include
2897 spaces between components and which contains matching braces or
2898 brackets.  because the outcome may be determined by voting based
2899 on heuristic estimators, the result is not strictly predictable.
2900 Fortunately, it's usually correct for ambiguous cases.
2901
2902 =item the replacement of C<s///>
2903
2904 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2905 happens as with C<qq//> constructs.
2906
2907 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2908 the replacement text of C<s///>, in order to correct the incorrigible
2909 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2910 is emitted if the S<C<use warnings>> pragma or the B<-w> command-line flag
2911 (that is, the C<$^W> variable) was set.
2912
2913 =item C<RE> in C<m?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2914
2915 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2916 and interpolation happens (almost) as with C<qq//> constructs.
2917
2918 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2919 form for the regex compiler.  (This is because, as mentioned below, the regex
2920 compilation may be done at execution time, and C<\N{...}> is a compile-time
2921 construct.)
2922
2923 However any other combinations of C<\> followed by a character
2924 are not substituted but only skipped, in order to parse them
2925 as regular expressions at the following step.
2926 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2927 treated as an array symbol (for example C<@foo>),
2928 even though the same text in C<qq//> gives interpolation of C<\c@>.
2929
2930 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2931 back to the perl parser, in a similar way that an interpolated array
2932 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2933
2934 Moreover, inside C<(?{BLOCK})>, S<C<(?# comment )>>, and
2935 a C<#>-comment in a C</x>-regular expression, no processing is
2936 performed whatsoever.  This is the first step at which the presence
2937 of the C</x> modifier is relevant.
2938
2939 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2940 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2941 voted (by several different estimators) to be either an array element
2942 or C<$var> followed by an RE alternative.  This is where the notation
2943 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2944 array element C<-9>, not as a regular expression from the variable
2945 C<$arr> followed by a digit, which would be the interpretation of
2946 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2947 the result is not predictable.
2948
2949 The lack of processing of C<\\> creates specific restrictions on
2950 the post-processed text.  If the delimiter is C</>, one cannot get
2951 the combination C<\/> into the result of this step.  C</> will
2952 finish the regular expression, C<\/> will be stripped to C</> on
2953 the previous step, and C<\\/> will be left as is.  Because C</> is
2954 equivalent to C<\/> inside a regular expression, this does not
2955 matter unless the delimiter happens to be character special to the
2956 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<m?foo?>; or an
2957 alphanumeric char, as in:
2958
2959   m m ^ a \s* b mmx;
2960
2961 In the RE above, which is intentionally obfuscated for illustration, the
2962 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2963 RE is the same as for S<C<m/ ^ a \s* b /mx>>.  There's more than one
2964 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2965 non-whitespace choices.
2966
2967 =back
2968
2969 This step is the last one for all constructs except regular expressions,
2970 which are processed further.
2971
2972 =item parsing regular expressions
2973 X<regexp, parse>
2974
2975 Previous steps were performed during the compilation of Perl code,
2976 but this one happens at run time, although it may be optimized to
2977 be calculated at compile time if appropriate.  After preprocessing
2978 described above, and possibly after evaluation if concatenation,
2979 joining, casing translation, or metaquoting are involved, the
2980 resulting I<string> is passed to the RE engine for compilation.
2981
2982 Whatever happens in the RE engine might be better discussed in L<perlre>,
2983 but for the sake of continuity, we shall do so here.
2984
2985 This is another step where the presence of the C</x> modifier is
2986 relevant.  The RE engine scans the string from left to right and
2987 converts it into a finite automaton.
2988
2989 Backslashed characters are either replaced with corresponding
2990 literal strings (as with C<\{>), or else they generate special nodes
2991 in the finite automaton (as with C<\b>).  Characters special to the
2992 RE engine (such as C<|>) generate corresponding nodes or groups of
2993 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2994 converted to literal strings to match, or else is ignored (as is
2995 whitespace and C<#>-style comments if C</x> is present).
2996
2997 Parsing of the bracketed character class construct, C<[...]>, is
2998 rather different than the rule used for the rest of the pattern.
2999 The terminator of this construct is found using the same rules as
3000 for finding the terminator of a C<{}>-delimited construct, the only
3001 exception being that C<]> immediately following C<[> is treated as
3002 though preceded by a backslash.
3003
3004 The terminator of runtime C<(?{...})> is found by temporarily switching
3005 control to the perl parser, which should stop at the point where the
3006 logically balancing terminating C<}> is found.
3007
3008 It is possible to inspect both the string given to RE engine and the
3009 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
3010 in the S<C<use L<re>>> pragma, as well as Perl's B<-Dr> command-line
3011 switch documented in L<perlrun/"Command Switches">.
3012
3013 =item Optimization of regular expressions
3014 X<regexp, optimization>
3015
3016 This step is listed for completeness only.  Since it does not change
3017 semantics, details of this step are not documented and are subject
3018 to change without notice.  This step is performed over the finite
3019 automaton that was generated during the previous pass.
3020
3021 It is at this stage that C<split()> silently optimizes C</^/> to
3022 mean C</^/m>.
3023
3024 =back
3025
3026 =head2 I/O Operators
3027 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
3028 X<< <> >> X<< <<>> >> X<@ARGV>
3029
3030 There are several I/O operators you should know about.
3031
3032 A string enclosed by backticks (grave accents) first undergoes
3033 double-quote interpolation.  It is then interpreted as an external
3034 command, and the output of that command is the value of the
3035 backtick string, like in a shell.  In scalar context, a single string
3036 consisting of all output is returned.  In list context, a list of
3037 values is returned, one per line of output.  (You can set C<$/> to use
3038 a different line terminator.)  The command is executed each time the
3039 pseudo-literal is evaluated.  The status value of the command is
3040 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
3041 Unlike in B<csh>, no translation is done on the return data--newlines
3042 remain newlines.  Unlike in any of the shells, single quotes do not
3043 hide variable names in the command from interpretation.  To pass a
3044 literal dollar-sign through to the shell you need to hide it with a
3045 backslash.  The generalized form of backticks is C<qx//>.  (Because
3046 backticks always undergo shell expansion as well, see L<perlsec> for
3047 security concerns.)
3048 X<qx> X<`> X<``> X<backtick> X<glob>
3049
3050 In scalar context, evaluating a filehandle in angle brackets yields
3051 the next line from that file (the newline, if any, included), or
3052 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
3053 (sometimes known as file-slurp mode) and the file is empty, it
3054 returns C<''> the first time, followed by C<undef> subsequently.
3055
3056 Ordinarily you must assign the returned value to a variable, but
3057 there is one situation where an automatic assignment happens.  If
3058 and only if the input symbol is the only thing inside the conditional
3059 of a C<while> statement (even if disguised as a C<for(;;)> loop),
3060 the value is automatically assigned to the global variable C<$_>,
3061 destroying whatever was there previously.  (This may seem like an
3062 odd thing to you, but you'll use the construct in almost every Perl
3063 script you write.)  The C<$_> variable is not implicitly localized.
3064 You'll have to put a S<C<local $_;>> before the loop if you want that
3065 to happen.
3066
3067 The following lines are equivalent:
3068
3069     while (defined($_ = <STDIN>)) { print; }
3070     while ($_ = <STDIN>) { print; }
3071     while (<STDIN>) { print; }
3072     for (;<STDIN>;) { print; }
3073     print while defined($_ = <STDIN>);
3074     print while ($_ = <STDIN>);
3075     print while <STDIN>;
3076
3077 This also behaves similarly, but assigns to a lexical variable
3078 instead of to C<$_>:
3079
3080     while (my $line = <STDIN>) { print $line }
3081
3082 In these loop constructs, the assigned value (whether assignment
3083 is automatic or explicit) is then tested to see whether it is
3084 defined.  The defined test avoids problems where the line has a string
3085 value that would be treated as false by Perl; for example a "" or
3086 a C<"0"> with no trailing newline.  If you really mean for such values
3087 to terminate the loop, they should be tested for explicitly:
3088
3089     while (($_ = <STDIN>) ne '0') { ... }
3090     while (<STDIN>) { last unless $_; ... }
3091
3092 In other boolean contexts, C<< <I<FILEHANDLE>> >> without an
3093 explicit C<defined> test or comparison elicits a warning if the
3094 S<C<use warnings>> pragma or the B<-w>
3095 command-line switch (the C<$^W> variable) is in effect.
3096
3097 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
3098 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
3099 in packages, where they would be interpreted as local identifiers
3100 rather than global.)  Additional filehandles may be created with
3101 the C<open()> function, amongst others.  See L<perlopentut> and
3102 L<perlfunc/open> for details on this.
3103 X<stdin> X<stdout> X<sterr>
3104
3105 If a C<< <I<FILEHANDLE>> >> is used in a context that is looking for
3106 a list, a list comprising all input lines is returned, one line per
3107 list element.  It's easy to grow to a rather large data space this
3108 way, so use with care.
3109
3110 C<< <I<FILEHANDLE>> >>  may also be spelled C<readline(*I<FILEHANDLE>)>.
3111 See L<perlfunc/readline>.
3112
3113 The null filehandle C<< <> >> is special: it can be used to emulate the
3114 behavior of B<sed> and B<awk>, and any other Unix filter program
3115 that takes a list of filenames, doing the same to each line
3116 of input from all of them.  Input from C<< <> >> comes either from
3117 standard input, or from each file listed on the command line.  Here's
3118 how it works: the first time C<< <> >> is evaluated, the C<@ARGV> array is
3119 checked, and if it is empty, C<$ARGV[0]> is set to C<"-">, which when opened
3120 gives you standard input.  The C<@ARGV> array is then processed as a list
3121 of filenames.  The loop
3122
3123     while (<>) {
3124         ...                     # code for each line
3125     }
3126
3127 is equivalent to the following Perl-like pseudo code:
3128
3129     unshift(@ARGV, '-') unless @ARGV;
3130     while ($ARGV = shift) {
3131         open(ARGV, $ARGV);
3132         while (<ARGV>) {
3133             ...         # code for each line
3134         }
3135     }
3136
3137 except that it isn't so cumbersome to say, and will actually work.
3138 It really does shift the C<@ARGV> array and put the current filename
3139 into the C<$ARGV> variable.  It also uses filehandle I<ARGV>
3140 internally.  C<< <> >> is just a synonym for C<< <ARGV> >>, which
3141 is magical.  (The pseudo code above doesn't work because it treats
3142 C<< <ARGV> >> as non-magical.)
3143
3144 Since the null filehandle uses the two argument form of L<perlfunc/open>
3145 it interprets special characters, so if you have a script like this:
3146
3147     while (<>) {
3148         print;
3149     }
3150
3151 and call it with S<C<perl dangerous.pl 'rm -rfv *|'>>, it actually opens a
3152 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
3153 If you want all items in C<@ARGV> to be interpreted as file names, you
3154 can use the module C<ARGV::readonly> from CPAN, or use the double bracket:
3155
3156     while (<<>>) {
3157         print;
3158     }
3159
3160 Using double angle brackets inside of a while causes the open to use the
3161 three argument form (with the second argument being C<< < >>), so all
3162 arguments in C<ARGV> are treated as literal filenames (including C<"-">).
3163 (Note that for convenience, if you use C<< <<>> >> and if C<@ARGV> is
3164 empty, it will still read from the standard input.)
3165
3166 You can modify C<@ARGV> before the first C<< <> >> as long as the array ends up
3167 containing the list of filenames you really want.  Line numbers (C<$.>)
3168 continue as though the input were one big happy file.  See the example
3169 in L<perlfunc/eof> for how to reset line numbers on each file.
3170
3171 If you want to set C<@ARGV> to your own list of files, go right ahead.
3172 This sets C<@ARGV> to all plain text files if no C<@ARGV> was given:
3173
3174     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
3175
3176 You can even set them to pipe commands.  For example, this automatically
3177 filters compressed arguments through B<gzip>:
3178
3179     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
3180
3181 If you want to pass switches into your script, you can use one of the
3182 C<Getopts> modules or put a loop on the front like this:
3183
3184     while ($_ = $ARGV[0], /^-/) {
3185         shift;
3186         last if /^--$/;
3187         if (/^-D(.*)/) { $debug = $1 }
3188         if (/^-v/)     { $verbose++  }
3189         # ...           # other switches
3190     }
3191
3192     while (<>) {
3193         # ...           # code for each line
3194     }
3195
3196 The C<< <> >> symbol will return C<undef> for end-of-file only once.
3197 If you call it again after this, it will assume you are processing another
3198 C<@ARGV> list, and if you haven't set C<@ARGV>, will read input from STDIN.
3199
3200 If what the angle brackets contain is a simple scalar variable (for example,
3201 C<$foo>), then that variable contains the name of the
3202 filehandle to input from, or its typeglob, or a reference to the
3203 same.  For example:
3204
3205     $fh = \*STDIN;
3206     $line = <$fh>;
3207
3208 If what's within the angle brackets is neither a filehandle nor a simple
3209 scalar variable containing a filehandle name, typeglob, or typeglob
3210 reference, it is interpreted as a filename pattern to be globbed, and
3211 either a list of filenames or the next filename in the list is returned,
3212 depending on context.  This distinction is determined on syntactic
3213 grounds alone.  That means C<< <$x> >> is always a C<readline()> from
3214 an indirect handle, but C<< <$hash{key}> >> is always a C<glob()>.
3215 That's because C<$x> is a simple scalar variable, but C<$hash{key}> is
3216 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3217 is treated as C<glob("$x ")>, not C<readline($x)>.
3218
3219 One level of double-quote interpretation is done first, but you can't
3220 say C<< <$foo> >> because that's an indirect filehandle as explained
3221 in the previous paragraph.  (In older versions of Perl, programmers
3222 would insert curly brackets to force interpretation as a filename glob:
3223 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3224 internal function directly as C<glob($foo)>, which is probably the right
3225 way to have done it in the first place.)  For example:
3226
3227     while (<*.c>) {
3228         chmod 0644, $_;
3229     }
3230
3231 is roughly equivalent to:
3232
3233     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3234     while (<FOO>) {
3235         chomp;
3236         chmod 0644, $_;
3237     }
3238
3239 except that the globbing is actually done internally using the standard
3240 C<L<File::Glob>> extension.  Of course, the shortest way to do the above is:
3241
3242     chmod 0644, <*.c>;
3243
3244 A (file)glob evaluates its (embedded) argument only when it is
3245 starting a new list.  All values must be read before it will start
3246 over.  In list context, this isn't important because you automatically
3247 get them all anyway.  However, in scalar context the operator returns
3248 the next value each time it's called, or C<undef> when the list has
3249 run out.  As with filehandle reads, an automatic C<defined> is
3250 generated when the glob occurs in the test part of a C<while>,
3251 because legal glob returns (for example,
3252 a file called F<0>) would otherwise
3253 terminate the loop.  Again, C<undef> is returned only once.  So if
3254 you're expecting a single value from a glob, it is much better to
3255 say
3256
3257     ($file) = <blurch*>;
3258
3259 than
3260
3261     $file = <blurch*>;
3262
3263 because the latter will alternate between returning a filename and
3264 returning false.
3265
3266 If you're trying to do variable interpolation, it's definitely better
3267 to use the C<glob()> function, because the older notation can cause people
3268 to become confused with the indirect filehandle notation.
3269
3270     @files = glob("$dir/*.[ch]");
3271     @files = glob($files[$i]);
3272
3273 =head2 Constant Folding
3274 X<constant folding> X<folding>
3275
3276 Like C, Perl does a certain amount of expression evaluation at
3277 compile time whenever it determines that all arguments to an
3278 operator are static and have no side effects.  In particular, string
3279 concatenation happens at compile time between literals that don't do
3280 variable substitution.  Backslash interpolation also happens at
3281 compile time.  You can say
3282
3283       'Now is the time for all'
3284     . "\n"
3285     .  'good men to come to.'
3286
3287 and this all reduces to one string internally.  Likewise, if
3288 you say
3289
3290     foreach $file (@filenames) {
3291         if (-s $file > 5 + 100 * 2**16) {  }
3292     }
3293
3294 the compiler precomputes the number which that expression
3295 represents so that the interpreter won't have to.
3296
3297 =head2 No-ops
3298 X<no-op> X<nop>
3299
3300 Perl doesn't officially have a no-op operator, but the bare constants
3301 C<0> and C<1> are special-cased not to produce a warning in void
3302 context, so you can for example safely do
3303
3304     1 while foo();
3305
3306 =head2 Bitwise String Operators
3307 X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.>
3308
3309 Bitstrings of any size may be manipulated by the bitwise operators
3310 (C<~ | & ^>).
3311
3312 If the operands to a binary bitwise op are strings of different
3313 sizes, B<|> and B<^> ops act as though the shorter operand had
3314 additional zero bits on the right, while the B<&> op acts as though
3315 the longer operand were truncated to the length of the shorter.
3316 The granularity for such extension or truncation is one or more
3317 bytes.
3318
3319     # ASCII-based examples
3320     print "j p \n" ^ " a h";            # prints "JAPH\n"
3321     print "JA" | "  ph\n";              # prints "japh\n"
3322     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3323     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3324
3325 If you are intending to manipulate bitstrings, be certain that
3326 you're supplying bitstrings: If an operand is a number, that will imply
3327 a B<numeric> bitwise operation.  You may explicitly show which type of
3328 operation you intend by using C<""> or C<0+>, as in the examples below.
3329
3330     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3331     $foo = '150' |  105;        # yields 255
3332     $foo =  150  | '105';       # yields 255
3333     $foo = '150' | '105';       # yields string '155' (under ASCII)
3334
3335     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3336     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3337
3338 This somewhat unpredictable behavior can be avoided with the experimental
3339 "bitwise" feature, new in Perl 5.22.  You can enable it via S<C<use feature
3340 'bitwise'>>.  By default, it will warn unless the C<"experimental::bitwise">
3341 warnings category has been disabled.  (S<C<use experimental 'bitwise'>> will
3342 enable the feature and disable the warning.)  Under this feature, the four
3343 standard bitwise operators (C<~ | & ^>) are always numeric.  Adding a dot
3344 after each operator (C<~. |. &. ^.>) forces it to treat its operands as
3345 strings:
3346
3347     use experimental "bitwise";
3348     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3349     $foo = '150' |  105;        # yields 255
3350     $foo =  150  | '105';       # yields 255
3351     $foo = '150' | '105';       # yields 255
3352     $foo =  150  |. 105;        # yields string '155'
3353     $foo = '150' |. 105;        # yields string '155'
3354     $foo =  150  |.'105';       # yields string '155'
3355     $foo = '150' |.'105';       # yields string '155'
3356
3357     $baz = $foo &  $bar;        # both operands numeric
3358     $biz = $foo ^. $bar;        # both operands stringy
3359
3360 The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>)
3361 behave likewise under the feature.
3362
3363 It is a fatal error if an operand contains a character whose ordinal
3364 value is above 0xFF, and hence not expressible except in UTF-8.  The
3365 operation is performed on a non-UTF-8 copy for other operands encoded in
3366 UTF-8.  See L<perlunicode/Byte and Character Semantics>.
3367
3368 See L<perlfunc/vec> for information on how to manipulate individual bits
3369 in a bit vector.
3370
3371 =head2 Integer Arithmetic
3372 X<integer>
3373
3374 By default, Perl assumes that it must do most of its arithmetic in
3375 floating point.  But by saying
3376
3377     use integer;
3378
3379 you may tell the compiler to use integer operations
3380 (see L<integer> for a detailed explanation) from here to the end of
3381 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3382
3383     no integer;
3384
3385 which lasts until the end of that BLOCK.  Note that this doesn't
3386 mean everything is an integer, merely that Perl will use integer
3387 operations for arithmetic, comparison, and bitwise operators.  For
3388 example, even under S<C<use integer>>, if you take the C<sqrt(2)>, you'll
3389 still get C<1.4142135623731> or so.
3390
3391 Used on numbers, the bitwise operators (C<&> C<|> C<^> C<~> C<< << >>
3392 C<< >> >>) always produce integral results.  (But see also
3393 L</Bitwise String Operators>.)  However, S<C<use integer>> still has meaning for
3394 them.  By default, their results are interpreted as unsigned integers, but
3395 if S<C<use integer>> is in effect, their results are interpreted
3396 as signed integers.  For example, C<~0> usually evaluates to a large
3397 integral value.  However, S<C<use integer; ~0>> is C<-1> on two's-complement
3398 machines.
3399
3400 =head2 Floating-point Arithmetic
3401
3402 X<floating-point> X<floating point> X<float> X<real>
3403
3404 While S<C<use integer>> provides integer-only arithmetic, there is no
3405 analogous mechanism to provide automatic rounding or truncation to a
3406 certain number of decimal places.  For rounding to a certain number
3407 of digits, C<sprintf()> or C<printf()> is usually the easiest route.
3408 See L<perlfaq4>.
3409
3410 Floating-point numbers are only approximations to what a mathematician
3411 would call real numbers.  There are infinitely more reals than floats,
3412 so some corners must be cut.  For example:
3413
3414     printf "%.20g\n", 123456789123456789;
3415     #        produces 123456789123456784
3416
3417 Testing for exact floating-point equality or inequality is not a
3418 good idea.  Here's a (relatively expensive) work-around to compare
3419 whether two floating-point numbers are equal to a particular number of
3420 decimal places.  See Knuth, volume II, for a more robust treatment of
3421 this topic.
3422
3423     sub fp_equal {
3424         my ($X, $Y, $POINTS) = @_;
3425         my ($tX, $tY);
3426         $tX = sprintf("%.${POINTS}g", $X);
3427         $tY = sprintf("%.${POINTS}g", $Y);
3428         return $tX eq $tY;
3429     }
3430
3431 The POSIX module (part of the standard perl distribution) implements
3432 C<ceil()>, C<floor()>, and other mathematical and trigonometric functions.
3433 The C<L<Math::Complex>> module (part of the standard perl distribution)
3434 defines mathematical functions that work on both the reals and the
3435 imaginary numbers.  C<Math::Complex> is not as efficient as POSIX, but
3436 POSIX can't work with complex numbers.
3437
3438 Rounding in financial applications can have serious implications, and
3439 the rounding method used should be specified precisely.  In these
3440 cases, it probably pays not to trust whichever system rounding is
3441 being used by Perl, but to instead implement the rounding function you
3442 need yourself.
3443
3444 =head2 Bigger Numbers
3445 X<number, arbitrary precision>
3446
3447 The standard C<L<Math::BigInt>>, C<L<Math::BigRat>>, and
3448 C<L<Math::BigFloat>> modules,
3449 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3450 variable-precision arithmetic and overloaded operators, although
3451 they're currently pretty slow.  At the cost of some space and
3452 considerable speed, they avoid the normal pitfalls associated with
3453 limited-precision representations.
3454
3455         use 5.010;
3456         use bigint;  # easy interface to Math::BigInt
3457         $x = 123456789123456789;
3458         say $x * $x;
3459     +15241578780673678515622620750190521
3460
3461 Or with rationals:
3462
3463         use 5.010;
3464         use bigrat;
3465         $x = 3/22;
3466         $y = 4/6;
3467         say "x/y is ", $x/$y;
3468         say "x*y is ", $x*$y;
3469         x/y is 9/44
3470         x*y is 1/11
3471
3472 Several modules let you calculate with unlimited or fixed precision
3473 (bound only by memory and CPU time).  There
3474 are also some non-standard modules that
3475 provide faster implementations via external C libraries.
3476
3477 Here is a short, but incomplete summary:
3478
3479   Math::String           treat string sequences like numbers
3480   Math::FixedPrecision   calculate with a fixed precision
3481   Math::Currency         for currency calculations
3482   Bit::Vector            manipulate bit vectors fast (uses C)
3483   Math::BigIntFast       Bit::Vector wrapper for big numbers
3484   Math::Pari             provides access to the Pari C library
3485   Math::Cephes           uses the external Cephes C library (no
3486                          big numbers)
3487   Math::Cephes::Fraction fractions via the Cephes library
3488   Math::GMP              another one using an external C library
3489   Math::GMPz             an alternative interface to libgmp's big ints
3490   Math::GMPq             an interface to libgmp's fraction numbers
3491   Math::GMPf             an interface to libgmp's floating point numbers
3492
3493 Choose wisely.
3494
3495 =cut