This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Hexadecimal float sprintf, for perl #122219
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 =for Pod::Functions =String
111
112 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
113 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
114 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
115
116 C<fc> is available only if the C<"fc"> feature is enabled or if it is
117 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
118 with a C<use v5.16> (or higher) declaration in the current scope.
119
120
121 =item Regular expressions and pattern matching
122 X<regular expression> X<regex> X<regexp>
123
124 =for Pod::Functions =Regexp
125
126 C<m//>, C<pos>, C<qr//>, C<quotemeta>, C<s///>, C<split>, C<study>
127
128 =item Numeric functions
129 X<numeric> X<number> X<trigonometric> X<trigonometry>
130
131 =for Pod::Functions =Math
132
133 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
134 C<sin>, C<sqrt>, C<srand>
135
136 =item Functions for real @ARRAYs
137 X<array>
138
139 =for Pod::Functions =ARRAY
140
141 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
142
143 =item Functions for list data
144 X<list>
145
146 =for Pod::Functions =LIST
147
148 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
149
150 =item Functions for real %HASHes
151 X<hash>
152
153 =for Pod::Functions =HASH
154
155 C<delete>, C<each>, C<exists>, C<keys>, C<values>
156
157 =item Input and output functions
158 X<I/O> X<input> X<output> X<dbm>
159
160 =for Pod::Functions =I/O
161
162 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
163 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
164 C<readdir>, C<readline> C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>,
165 C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>,
166 C<truncate>, C<warn>, C<write>
167
168 C<say> is available only if the C<"say"> feature is enabled or if it is
169 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
170 with a C<use v5.10> (or higher) declaration in the current scope.
171
172 =item Functions for fixed-length data or records
173
174 =for Pod::Functions =Binary
175
176 C<pack>, C<read>, C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<unpack>,
177 C<vec>
178
179 =item Functions for filehandles, files, or directories
180 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
181
182 =for Pod::Functions =File
183
184 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
185 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
186 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
187 C<umask>, C<unlink>, C<utime>
188
189 =item Keywords related to the control flow of your Perl program
190 X<control flow>
191
192 =for Pod::Functions =Flow
193
194 C<break>, C<caller>, C<continue>, C<die>, C<do>,
195 C<dump>, C<eval>, C<evalbytes> C<exit>,
196 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
197 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
198
199 C<break> is available only if you enable the experimental C<"switch">
200 feature or use the C<CORE::> prefix.  The C<"switch"> feature also enables
201 the C<default>, C<given> and C<when> statements, which are documented in
202 L<perlsyn/"Switch Statements">.  The C<"switch"> feature is enabled
203 automatically with a C<use v5.10> (or higher) declaration in the current
204 scope.  In Perl v5.14 and earlier, C<continue> required the C<"switch">
205 feature, like the other keywords.
206
207 C<evalbytes> is only available with the C<"evalbytes"> feature (see
208 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
209 with the C<"current_sub"> feature or if prefixed with C<CORE::>.  Both
210 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
211 with a C<use v5.16> (or higher) declaration in the current scope.
212
213 =item Keywords related to scoping
214
215 =for Pod::Functions =Namespace
216
217 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
218
219 C<state> is available only if the C<"state"> feature is enabled or if it is
220 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
221 with a C<use v5.10> (or higher) declaration in the current scope.
222
223 =item Miscellaneous functions
224
225 =for Pod::Functions =Misc
226
227 C<defined>, C<formline>, C<lock>, C<prototype>, C<reset>, C<scalar>, C<undef>
228
229 =item Functions for processes and process groups
230 X<process> X<pid> X<process id>
231
232 =for Pod::Functions =Process
233
234 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
235 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
236 C<setpriority>, C<sleep>, C<system>,
237 C<times>, C<wait>, C<waitpid>
238
239 =item Keywords related to Perl modules
240 X<module>
241
242 =for Pod::Functions =Modules
243
244 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
245
246 =item Keywords related to classes and object-orientation
247 X<object> X<class> X<package>
248
249 =for Pod::Functions =Objects
250
251 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
252 C<untie>, C<use>
253
254 =item Low-level socket functions
255 X<socket> X<sock>
256
257 =for Pod::Functions =Socket
258
259 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
260 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
261 C<socket>, C<socketpair>
262
263 =item System V interprocess communication functions
264 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
265
266 =for Pod::Functions =SysV
267
268 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
269 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
270
271 =item Fetching user and group info
272 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
273
274 =for Pod::Functions =User
275
276 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
277 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
278 C<getpwuid>, C<setgrent>, C<setpwent>
279
280 =item Fetching network info
281 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
282
283 =for Pod::Functions =Network
284
285 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
286 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
287 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
288 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
289 C<setnetent>, C<setprotoent>, C<setservent>
290
291 =item Time-related functions
292 X<time> X<date>
293
294 =for Pod::Functions =Time
295
296 C<gmtime>, C<localtime>, C<time>, C<times>
297
298 =item Non-function keywords
299
300 =for Pod::Functions =!Non-functions
301
302 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
303 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
304 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
305 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
306 C<while>, C<x>, C<xor>
307
308 =back
309
310 =head2 Portability
311 X<portability> X<Unix> X<portable>
312
313 Perl was born in Unix and can therefore access all common Unix
314 system calls.  In non-Unix environments, the functionality of some
315 Unix system calls may not be available or details of the available
316 functionality may differ slightly.  The Perl functions affected
317 by this are:
318
319 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
320 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
321 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
322 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
323 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
324 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
325 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
326 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
327 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
328 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
329 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
330 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
331 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
332 C<shmwrite>, C<socket>, C<socketpair>,
333 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
334 C<times>, C<truncate>, C<umask>, C<unlink>,
335 C<utime>, C<wait>, C<waitpid>
336
337 For more information about the portability of these functions, see
338 L<perlport> and other available platform-specific documentation.
339
340 =head2 Alphabetical Listing of Perl Functions
341
342 =over 
343
344 =item -X FILEHANDLE
345 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
346 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
347
348 =item -X EXPR
349
350 =item -X DIRHANDLE
351
352 =item -X
353
354 =for Pod::Functions a file test (-r, -x, etc)
355
356 A file test, where X is one of the letters listed below.  This unary
357 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
358 and tests the associated file to see if something is true about it.  If the
359 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
360 Unless otherwise documented, it returns C<1> for true and C<''> for false.
361 If the file doesn't exist or can't be examined, it returns C<undef> and
362 sets C<$!> (errno).  Despite the funny names, precedence is the same as any
363 other named unary operator.  The operator may be any of:
364
365     -r  File is readable by effective uid/gid.
366     -w  File is writable by effective uid/gid.
367     -x  File is executable by effective uid/gid.
368     -o  File is owned by effective uid.
369
370     -R  File is readable by real uid/gid.
371     -W  File is writable by real uid/gid.
372     -X  File is executable by real uid/gid.
373     -O  File is owned by real uid.
374
375     -e  File exists.
376     -z  File has zero size (is empty).
377     -s  File has nonzero size (returns size in bytes).
378
379     -f  File is a plain file.
380     -d  File is a directory.
381     -l  File is a symbolic link (false if symlinks aren't
382         supported by the file system).
383     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
384     -S  File is a socket.
385     -b  File is a block special file.
386     -c  File is a character special file.
387     -t  Filehandle is opened to a tty.
388
389     -u  File has setuid bit set.
390     -g  File has setgid bit set.
391     -k  File has sticky bit set.
392
393     -T  File is an ASCII text file (heuristic guess).
394     -B  File is a "binary" file (opposite of -T).
395
396     -M  Script start time minus file modification time, in days.
397     -A  Same for access time.
398     -C  Same for inode change time (Unix, may differ for other
399         platforms)
400
401 Example:
402
403     while (<>) {
404         chomp;
405         next unless -f $_;  # ignore specials
406         #...
407     }
408
409 Note that C<-s/a/b/> does not do a negated substitution.  Saying
410 C<-exp($foo)> still works as expected, however: only single letters
411 following a minus are interpreted as file tests.
412
413 These operators are exempt from the "looks like a function rule" described
414 above.  That is, an opening parenthesis after the operator does not affect
415 how much of the following code constitutes the argument.  Put the opening
416 parentheses before the operator to separate it from code that follows (this
417 applies only to operators with higher precedence than unary operators, of
418 course):
419
420     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
421     (-s $file) + 1024  # correct
422
423 The interpretation of the file permission operators C<-r>, C<-R>,
424 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
425 of the file and the uids and gids of the user.  There may be other
426 reasons you can't actually read, write, or execute the file: for
427 example network filesystem access controls, ACLs (access control lists),
428 read-only filesystems, and unrecognized executable formats.  Note
429 that the use of these six specific operators to verify if some operation
430 is possible is usually a mistake, because it may be open to race
431 conditions.
432
433 Also note that, for the superuser on the local filesystems, the C<-r>,
434 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
435 if any execute bit is set in the mode.  Scripts run by the superuser
436 may thus need to do a stat() to determine the actual mode of the file,
437 or temporarily set their effective uid to something else.
438
439 If you are using ACLs, there is a pragma called C<filetest> that may
440 produce more accurate results than the bare stat() mode bits.
441 When under C<use filetest 'access'> the above-mentioned filetests
442 test whether the permission can(not) be granted using the
443 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
444 under this pragma return true even if there are no execute permission
445 bits set (nor any extra execute permission ACLs).  This strangeness is
446 due to the underlying system calls' definitions.  Note also that, due to
447 the implementation of C<use filetest 'access'>, the C<_> special
448 filehandle won't cache the results of the file tests when this pragma is
449 in effect.  Read the documentation for the C<filetest> pragma for more
450 information.
451
452 The C<-T> and C<-B> switches work as follows.  The first block or so of the
453 file is examined for odd characters such as strange control codes or
454 characters with the high bit set.  If too many strange characters (>30%)
455 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
456 containing a zero byte in the first block is considered a binary file.  If C<-T>
457 or C<-B> is used on a filehandle, the current IO buffer is examined
458 rather than the first block.  Both C<-T> and C<-B> return true on an empty
459 file, or a file at EOF when testing a filehandle.  Because you have to
460 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
461 against the file first, as in C<next unless -f $file && -T $file>.
462
463 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
464 the special filehandle consisting of a solitary underline, then the stat
465 structure of the previous file test (or stat operator) is used, saving
466 a system call.  (This doesn't work with C<-t>, and you need to remember
467 that lstat() and C<-l> leave values in the stat structure for the
468 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
469 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
470 Example:
471
472     print "Can do.\n" if -r $a || -w _ || -x _;
473
474     stat($filename);
475     print "Readable\n" if -r _;
476     print "Writable\n" if -w _;
477     print "Executable\n" if -x _;
478     print "Setuid\n" if -u _;
479     print "Setgid\n" if -g _;
480     print "Sticky\n" if -k _;
481     print "Text\n" if -T _;
482     print "Binary\n" if -B _;
483
484 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
485 test operators, in a way that C<-f -w -x $file> is equivalent to
486 C<-x $file && -w _ && -f _>.  (This is only fancy syntax: if you use
487 the return value of C<-f $file> as an argument to another filetest
488 operator, no special magic will happen.)
489
490 Portability issues: L<perlport/-X>.
491
492 To avoid confusing would-be users of your code with mysterious
493 syntax errors, put something like this at the top of your script:
494
495     use 5.010;  # so filetest ops can stack
496
497 =item abs VALUE
498 X<abs> X<absolute>
499
500 =item abs
501
502 =for Pod::Functions absolute value function
503
504 Returns the absolute value of its argument.
505 If VALUE is omitted, uses C<$_>.
506
507 =item accept NEWSOCKET,GENERICSOCKET
508 X<accept>
509
510 =for Pod::Functions accept an incoming socket connect
511
512 Accepts an incoming socket connect, just as accept(2) 
513 does.  Returns the packed address if it succeeded, false otherwise.
514 See the example in L<perlipc/"Sockets: Client/Server Communication">.
515
516 On systems that support a close-on-exec flag on files, the flag will
517 be set for the newly opened file descriptor, as determined by the
518 value of $^F.  See L<perlvar/$^F>.
519
520 =item alarm SECONDS
521 X<alarm>
522 X<SIGALRM>
523 X<timer>
524
525 =item alarm
526
527 =for Pod::Functions schedule a SIGALRM
528
529 Arranges to have a SIGALRM delivered to this process after the
530 specified number of wallclock seconds has elapsed.  If SECONDS is not
531 specified, the value stored in C<$_> is used.  (On some machines,
532 unfortunately, the elapsed time may be up to one second less or more
533 than you specified because of how seconds are counted, and process
534 scheduling may delay the delivery of the signal even further.)
535
536 Only one timer may be counting at once.  Each call disables the
537 previous timer, and an argument of C<0> may be supplied to cancel the
538 previous timer without starting a new one.  The returned value is the
539 amount of time remaining on the previous timer.
540
541 For delays of finer granularity than one second, the Time::HiRes module
542 (from CPAN, and starting from Perl 5.8 part of the standard
543 distribution) provides ualarm().  You may also use Perl's four-argument
544 version of select() leaving the first three arguments undefined, or you
545 might be able to use the C<syscall> interface to access setitimer(2) if
546 your system supports it.  See L<perlfaq8> for details.
547
548 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
549 C<sleep> may be internally implemented on your system with C<alarm>.
550
551 If you want to use C<alarm> to time out a system call you need to use an
552 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
553 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
554 restart system calls on some systems.  Using C<eval>/C<die> always works,
555 modulo the caveats given in L<perlipc/"Signals">.
556
557     eval {
558         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
559         alarm $timeout;
560         $nread = sysread SOCKET, $buffer, $size;
561         alarm 0;
562     };
563     if ($@) {
564         die unless $@ eq "alarm\n";   # propagate unexpected errors
565         # timed out
566     }
567     else {
568         # didn't
569     }
570
571 For more information see L<perlipc>.
572
573 Portability issues: L<perlport/alarm>.
574
575 =item atan2 Y,X
576 X<atan2> X<arctangent> X<tan> X<tangent>
577
578 =for Pod::Functions arctangent of Y/X in the range -PI to PI
579
580 Returns the arctangent of Y/X in the range -PI to PI.
581
582 For the tangent operation, you may use the C<Math::Trig::tan>
583 function, or use the familiar relation:
584
585     sub tan { sin($_[0]) / cos($_[0])  }
586
587 The return value for C<atan2(0,0)> is implementation-defined; consult
588 your atan2(3) manpage for more information.
589
590 Portability issues: L<perlport/atan2>.
591
592 =item bind SOCKET,NAME
593 X<bind>
594
595 =for Pod::Functions binds an address to a socket
596
597 Binds a network address to a socket, just as bind(2)
598 does.  Returns true if it succeeded, false otherwise.  NAME should be a
599 packed address of the appropriate type for the socket.  See the examples in
600 L<perlipc/"Sockets: Client/Server Communication">.
601
602 =item binmode FILEHANDLE, LAYER
603 X<binmode> X<binary> X<text> X<DOS> X<Windows>
604
605 =item binmode FILEHANDLE
606
607 =for Pod::Functions prepare binary files for I/O
608
609 Arranges for FILEHANDLE to be read or written in "binary" or "text"
610 mode on systems where the run-time libraries distinguish between
611 binary and text files.  If FILEHANDLE is an expression, the value is
612 taken as the name of the filehandle.  Returns true on success,
613 otherwise it returns C<undef> and sets C<$!> (errno).
614
615 On some systems (in general, DOS- and Windows-based systems) binmode()
616 is necessary when you're not working with a text file.  For the sake
617 of portability it is a good idea always to use it when appropriate,
618 and never to use it when it isn't appropriate.  Also, people can
619 set their I/O to be by default UTF8-encoded Unicode, not bytes.
620
621 In other words: regardless of platform, use binmode() on binary data,
622 like images, for example.
623
624 If LAYER is present it is a single string, but may contain multiple
625 directives.  The directives alter the behaviour of the filehandle.
626 When LAYER is present, using binmode on a text file makes sense.
627
628 If LAYER is omitted or specified as C<:raw> the filehandle is made
629 suitable for passing binary data.  This includes turning off possible CRLF
630 translation and marking it as bytes (as opposed to Unicode characters).
631 Note that, despite what may be implied in I<"Programming Perl"> (the
632 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
633 Other layers that would affect the binary nature of the stream are
634 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
635 PERLIO environment variable.
636
637 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
638 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
639 establish default I/O layers.  See L<open>.
640
641 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
642 in "Programming Perl, 3rd Edition".  However, since the publishing of this
643 book, by many known as "Camel III", the consensus of the naming of this
644 functionality has moved from "discipline" to "layer".  All documentation
645 of this version of Perl therefore refers to "layers" rather than to
646 "disciplines".  Now back to the regularly scheduled documentation...>
647
648 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
649 C<:utf8> just marks the data as UTF-8 without further checking,
650 while C<:encoding(UTF-8)> checks the data for actually being valid
651 UTF-8.  More details can be found in L<PerlIO::encoding>.
652
653 In general, binmode() should be called after open() but before any I/O
654 is done on the filehandle.  Calling binmode() normally flushes any
655 pending buffered output data (and perhaps pending input data) on the
656 handle.  An exception to this is the C<:encoding> layer that
657 changes the default character encoding of the handle; see L</open>.
658 The C<:encoding> layer sometimes needs to be called in
659 mid-stream, and it doesn't flush the stream.  The C<:encoding>
660 also implicitly pushes on top of itself the C<:utf8> layer because
661 internally Perl operates on UTF8-encoded Unicode characters.
662
663 The operating system, device drivers, C libraries, and Perl run-time
664 system all conspire to let the programmer treat a single
665 character (C<\n>) as the line terminator, irrespective of external
666 representation.  On many operating systems, the native text file
667 representation matches the internal representation, but on some
668 platforms the external representation of C<\n> is made up of more than
669 one character.
670
671 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
672 a single character to end each line in the external representation of text
673 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
674 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
675 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
676 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
677 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
678 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
679 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
680 output.  This is what you want for text files, but it can be disastrous for
681 binary files.
682
683 Another consequence of using binmode() (on some systems) is that
684 special end-of-file markers will be seen as part of the data stream.
685 For systems from the Microsoft family this means that, if your binary
686 data contain C<\cZ>, the I/O subsystem will regard it as the end of
687 the file, unless you use binmode().
688
689 binmode() is important not only for readline() and print() operations,
690 but also when using read(), seek(), sysread(), syswrite() and tell()
691 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
692 in L<perlvar> for how to manually set your input and output
693 line-termination sequences.
694
695 Portability issues: L<perlport/binmode>.
696
697 =item bless REF,CLASSNAME
698 X<bless>
699
700 =item bless REF
701
702 =for Pod::Functions create an object
703
704 This function tells the thingy referenced by REF that it is now an object
705 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
706 is used.  Because a C<bless> is often the last thing in a constructor,
707 it returns the reference for convenience.  Always use the two-argument
708 version if a derived class might inherit the function doing the blessing.
709 See L<perlobj> for more about the blessing (and blessings) of objects.
710
711 Consider always blessing objects in CLASSNAMEs that are mixed case.
712 Namespaces with all lowercase names are considered reserved for
713 Perl pragmata.  Builtin types have all uppercase names.  To prevent
714 confusion, you may wish to avoid such package names as well.  Make sure
715 that CLASSNAME is a true value.
716
717 See L<perlmod/"Perl Modules">.
718
719 =item break
720
721 =for Pod::Functions +switch break out of a C<given> block
722
723 Break out of a C<given()> block.
724
725 This keyword is enabled by the C<"switch"> feature; see L<feature> for
726 more information on C<"switch">.  You can also access it by prefixing it
727 with C<CORE::>.  Alternatively, include a C<use v5.10> or later to the
728 current scope.
729
730 =item caller EXPR
731 X<caller> X<call stack> X<stack> X<stack trace>
732
733 =item caller
734
735 =for Pod::Functions get context of the current subroutine call
736
737 Returns the context of the current pure perl subroutine call.  In scalar
738 context, returns the caller's package name if there I<is> a caller (that is, if
739 we're in a subroutine or C<eval> or C<require>) and the undefined value
740 otherwise.  caller never returns XS subs and they are skipped.  The next pure
741 perl sub will appear instead of the XS sub in caller's return values. In list
742 context, caller returns
743
744     # 0         1          2
745     ($package, $filename, $line) = caller;
746
747 With EXPR, it returns some extra information that the debugger uses to
748 print a stack trace.  The value of EXPR indicates how many call frames
749 to go back before the current one.
750
751     #  0         1          2      3            4
752     ($package, $filename, $line, $subroutine, $hasargs,
753
754     #  5          6          7            8       9         10
755     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
756      = caller($i);
757
758 Here, $subroutine is the function that the caller called (rather than the
759 function containing the caller). Note that $subroutine may be C<(eval)> if
760 the frame is not a subroutine call, but an C<eval>.  In such a case
761 additional elements $evaltext and
762 C<$is_require> are set: C<$is_require> is true if the frame is created by a
763 C<require> or C<use> statement, $evaltext contains the text of the
764 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
765 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
766 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
767 frame.)  $subroutine may also be C<(unknown)> if this particular
768 subroutine happens to have been deleted from the symbol table.
769 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
770 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
771 compiled with.  C<$hints> corresponds to C<$^H>, and C<$bitmask>
772 corresponds to C<${^WARNING_BITS}>.  The
773 C<$hints> and C<$bitmask> values are subject
774 to change between versions of Perl, and are not meant for external use.
775
776 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
777 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
778 of this hash, as they are the actual values stored in the optree.
779
780 Furthermore, when called from within the DB package in
781 list context, and with an argument, caller returns more
782 detailed information: it sets the list variable C<@DB::args> to be the
783 arguments with which the subroutine was invoked.
784
785 Be aware that the optimizer might have optimized call frames away before
786 C<caller> had a chance to get the information.  That means that C<caller(N)>
787 might not return information about the call frame you expect it to, for
788 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
789 previous time C<caller> was called.
790
791 Be aware that setting C<@DB::args> is I<best effort>, intended for
792 debugging or generating backtraces, and should not be relied upon.  In
793 particular, as C<@_> contains aliases to the caller's arguments, Perl does
794 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
795 subroutine makes to C<@_> or its contents, not the original values at call
796 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
797 elements, so under certain cases its elements may have become freed and
798 reallocated for other variables or temporary values.  Finally, a side effect
799 of the current implementation is that the effects of C<shift @_> can
800 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
801 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
802 elements), so C<@DB::args> is actually a hybrid of the current state and
803 initial state of C<@_>.  Buyer beware.
804
805 =item chdir EXPR
806 X<chdir>
807 X<cd>
808 X<directory, change>
809
810 =item chdir FILEHANDLE
811
812 =item chdir DIRHANDLE
813
814 =item chdir
815
816 =for Pod::Functions change your current working directory
817
818 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
819 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
820 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
821 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
822 neither is set, C<chdir> does nothing.  It returns true on success,
823 false otherwise.  See the example under C<die>.
824
825 On systems that support fchdir(2), you may pass a filehandle or
826 directory handle as the argument.  On systems that don't support fchdir(2),
827 passing handles raises an exception.
828
829 =item chmod LIST
830 X<chmod> X<permission> X<mode>
831
832 =for Pod::Functions changes the permissions on a list of files
833
834 Changes the permissions of a list of files.  The first element of the
835 list must be the numeric mode, which should probably be an octal
836 number, and which definitely should I<not> be a string of octal digits:
837 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
838 successfully changed.  See also L</oct> if all you have is a string.
839
840     $cnt = chmod 0755, "foo", "bar";
841     chmod 0755, @executables;
842     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
843                                              # --w----r-T
844     $mode = "0644"; chmod oct($mode), "foo"; # this is better
845     $mode = 0644;   chmod $mode, "foo";      # this is best
846
847 On systems that support fchmod(2), you may pass filehandles among the
848 files.  On systems that don't support fchmod(2), passing filehandles raises
849 an exception.  Filehandles must be passed as globs or glob references to be
850 recognized; barewords are considered filenames.
851
852     open(my $fh, "<", "foo");
853     my $perm = (stat $fh)[2] & 07777;
854     chmod($perm | 0600, $fh);
855
856 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
857 module:
858
859     use Fcntl qw( :mode );
860     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
861     # Identical to the chmod 0755 of the example above.
862
863 Portability issues: L<perlport/chmod>.
864
865 =item chomp VARIABLE
866 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
867
868 =item chomp( LIST )
869
870 =item chomp
871
872 =for Pod::Functions remove a trailing record separator from a string
873
874 This safer version of L</chop> removes any trailing string
875 that corresponds to the current value of C<$/> (also known as
876 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
877 number of characters removed from all its arguments.  It's often used to
878 remove the newline from the end of an input record when you're worried
879 that the final record may be missing its newline.  When in paragraph
880 mode (C<$/ = "">), it removes all trailing newlines from the string.
881 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
882 a reference to an integer or the like; see L<perlvar>) chomp() won't
883 remove anything.
884 If VARIABLE is omitted, it chomps C<$_>.  Example:
885
886     while (<>) {
887         chomp;  # avoid \n on last field
888         @array = split(/:/);
889         # ...
890     }
891
892 If VARIABLE is a hash, it chomps the hash's values, but not its keys,
893 resetting the C<each> iterator in the process.
894
895 You can actually chomp anything that's an lvalue, including an assignment:
896
897     chomp($cwd = `pwd`);
898     chomp($answer = <STDIN>);
899
900 If you chomp a list, each element is chomped, and the total number of
901 characters removed is returned.
902
903 Note that parentheses are necessary when you're chomping anything
904 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
905 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
906 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
907 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
908 as C<chomp($a, $b)>.
909
910 =item chop VARIABLE
911 X<chop>
912
913 =item chop( LIST )
914
915 =item chop
916
917 =for Pod::Functions remove the last character from a string
918
919 Chops off the last character of a string and returns the character
920 chopped.  It is much more efficient than C<s/.$//s> because it neither
921 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
922 If VARIABLE is a hash, it chops the hash's values, but not its keys,
923 resetting the C<each> iterator in the process.
924
925 You can actually chop anything that's an lvalue, including an assignment.
926
927 If you chop a list, each element is chopped.  Only the value of the
928 last C<chop> is returned.
929
930 Note that C<chop> returns the last character.  To return all but the last
931 character, use C<substr($string, 0, -1)>.
932
933 See also L</chomp>.
934
935 =item chown LIST
936 X<chown> X<owner> X<user> X<group>
937
938 =for Pod::Functions change the ownership on a list of files
939
940 Changes the owner (and group) of a list of files.  The first two
941 elements of the list must be the I<numeric> uid and gid, in that
942 order.  A value of -1 in either position is interpreted by most
943 systems to leave that value unchanged.  Returns the number of files
944 successfully changed.
945
946     $cnt = chown $uid, $gid, 'foo', 'bar';
947     chown $uid, $gid, @filenames;
948
949 On systems that support fchown(2), you may pass filehandles among the
950 files.  On systems that don't support fchown(2), passing filehandles raises
951 an exception.  Filehandles must be passed as globs or glob references to be
952 recognized; barewords are considered filenames.
953
954 Here's an example that looks up nonnumeric uids in the passwd file:
955
956     print "User: ";
957     chomp($user = <STDIN>);
958     print "Files: ";
959     chomp($pattern = <STDIN>);
960
961     ($login,$pass,$uid,$gid) = getpwnam($user)
962         or die "$user not in passwd file";
963
964     @ary = glob($pattern);  # expand filenames
965     chown $uid, $gid, @ary;
966
967 On most systems, you are not allowed to change the ownership of the
968 file unless you're the superuser, although you should be able to change
969 the group to any of your secondary groups.  On insecure systems, these
970 restrictions may be relaxed, but this is not a portable assumption.
971 On POSIX systems, you can detect this condition this way:
972
973     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
974     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
975
976 Portability issues: L<perlport/chown>.
977
978 =item chr NUMBER
979 X<chr> X<character> X<ASCII> X<Unicode>
980
981 =item chr
982
983 =for Pod::Functions get character this number represents
984
985 Returns the character represented by that NUMBER in the character set.
986 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
987 chr(0x263a) is a Unicode smiley face.  
988
989 Negative values give the Unicode replacement character (chr(0xfffd)),
990 except under the L<bytes> pragma, where the low eight bits of the value
991 (truncated to an integer) are used.
992
993 If NUMBER is omitted, uses C<$_>.
994
995 For the reverse, use L</ord>.
996
997 Note that characters from 128 to 255 (inclusive) are by default
998 internally not encoded as UTF-8 for backward compatibility reasons.
999
1000 See L<perlunicode> for more about Unicode.
1001
1002 =item chroot FILENAME
1003 X<chroot> X<root>
1004
1005 =item chroot
1006
1007 =for Pod::Functions make directory new root for path lookups
1008
1009 This function works like the system call by the same name: it makes the
1010 named directory the new root directory for all further pathnames that
1011 begin with a C</> by your process and all its children.  (It doesn't
1012 change your current working directory, which is unaffected.)  For security
1013 reasons, this call is restricted to the superuser.  If FILENAME is
1014 omitted, does a C<chroot> to C<$_>.
1015
1016 B<NOTE:>  It is good security practice to do C<chdir("/")> (to the root
1017 directory) immediately after a C<chroot()>.
1018
1019 Portability issues: L<perlport/chroot>.
1020
1021 =item close FILEHANDLE
1022 X<close>
1023
1024 =item close
1025
1026 =for Pod::Functions close file (or pipe or socket) handle
1027
1028 Closes the file or pipe associated with the filehandle, flushes the IO
1029 buffers, and closes the system file descriptor.  Returns true if those
1030 operations succeed and if no error was reported by any PerlIO
1031 layer.  Closes the currently selected filehandle if the argument is
1032 omitted.
1033
1034 You don't have to close FILEHANDLE if you are immediately going to do
1035 another C<open> on it, because C<open> closes it for you.  (See
1036 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
1037 counter (C<$.>), while the implicit close done by C<open> does not.
1038
1039 If the filehandle came from a piped open, C<close> returns false if one of
1040 the other syscalls involved fails or if its program exits with non-zero
1041 status.  If the only problem was that the program exited non-zero, C<$!>
1042 will be set to C<0>.  Closing a pipe also waits for the process executing
1043 on the pipe to exit--in case you wish to look at the output of the pipe
1044 afterwards--and implicitly puts the exit status value of that command into
1045 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
1046
1047 If there are multiple threads running, C<close> on a filehandle from a
1048 piped open returns true without waiting for the child process to terminate,
1049 if the filehandle is still open in another thread.
1050
1051 Closing the read end of a pipe before the process writing to it at the
1052 other end is done writing results in the writer receiving a SIGPIPE.  If
1053 the other end can't handle that, be sure to read all the data before
1054 closing the pipe.
1055
1056 Example:
1057
1058     open(OUTPUT, '|sort >foo')  # pipe to sort
1059         or die "Can't start sort: $!";
1060     #...                        # print stuff to output
1061     close OUTPUT                # wait for sort to finish
1062         or warn $! ? "Error closing sort pipe: $!"
1063                    : "Exit status $? from sort";
1064     open(INPUT, 'foo')          # get sort's results
1065         or die "Can't open 'foo' for input: $!";
1066
1067 FILEHANDLE may be an expression whose value can be used as an indirect
1068 filehandle, usually the real filehandle name or an autovivified handle.
1069
1070 =item closedir DIRHANDLE
1071 X<closedir>
1072
1073 =for Pod::Functions close directory handle
1074
1075 Closes a directory opened by C<opendir> and returns the success of that
1076 system call.
1077
1078 =item connect SOCKET,NAME
1079 X<connect>
1080
1081 =for Pod::Functions connect to a remote socket
1082
1083 Attempts to connect to a remote socket, just like connect(2).
1084 Returns true if it succeeded, false otherwise.  NAME should be a
1085 packed address of the appropriate type for the socket.  See the examples in
1086 L<perlipc/"Sockets: Client/Server Communication">.
1087
1088 =item continue BLOCK
1089 X<continue>
1090
1091 =item continue
1092
1093 =for Pod::Functions optional trailing block in a while or foreach
1094
1095 When followed by a BLOCK, C<continue> is actually a
1096 flow control statement rather than a function.  If
1097 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1098 C<foreach>), it is always executed just before the conditional is about to
1099 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1100 it can be used to increment a loop variable, even when the loop has been
1101 continued via the C<next> statement (which is similar to the C C<continue>
1102 statement).
1103
1104 C<last>, C<next>, or C<redo> may appear within a C<continue>
1105 block; C<last> and C<redo> behave as if they had been executed within
1106 the main block.  So will C<next>, but since it will execute a C<continue>
1107 block, it may be more entertaining.
1108
1109     while (EXPR) {
1110         ### redo always comes here
1111         do_something;
1112     } continue {
1113         ### next always comes here
1114         do_something_else;
1115         # then back the top to re-check EXPR
1116     }
1117     ### last always comes here
1118
1119 Omitting the C<continue> section is equivalent to using an
1120 empty one, logically enough, so C<next> goes directly back
1121 to check the condition at the top of the loop.
1122
1123 When there is no BLOCK, C<continue> is a function that
1124 falls through the current C<when> or C<default> block instead of iterating
1125 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1126 In Perl 5.14 and earlier, this form of C<continue> was
1127 only available when the C<"switch"> feature was enabled.
1128 See L<feature> and L<perlsyn/"Switch Statements"> for more
1129 information.
1130
1131 =item cos EXPR
1132 X<cos> X<cosine> X<acos> X<arccosine>
1133
1134 =item cos
1135
1136 =for Pod::Functions cosine function
1137
1138 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1139 takes the cosine of C<$_>.
1140
1141 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1142 function, or use this relation:
1143
1144     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1145
1146 =item crypt PLAINTEXT,SALT
1147 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1148 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1149
1150 =for Pod::Functions one-way passwd-style encryption
1151
1152 Creates a digest string exactly like the crypt(3) function in the C
1153 library (assuming that you actually have a version there that has not
1154 been extirpated as a potential munition).
1155
1156 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1157 into a short string, called a digest, which is returned.  The same
1158 PLAINTEXT and SALT will always return the same string, but there is no
1159 (known) way to get the original PLAINTEXT from the hash.  Small
1160 changes in the PLAINTEXT or SALT will result in large changes in the
1161 digest.
1162
1163 There is no decrypt function.  This function isn't all that useful for
1164 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1165 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1166 primarily used to check if two pieces of text are the same without
1167 having to transmit or store the text itself.  An example is checking
1168 if a correct password is given.  The digest of the password is stored,
1169 not the password itself.  The user types in a password that is
1170 crypt()'d with the same salt as the stored digest.  If the two digests
1171 match, the password is correct.
1172
1173 When verifying an existing digest string you should use the digest as
1174 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1175 to create the digest is visible as part of the digest.  This ensures
1176 crypt() will hash the new string with the same salt as the digest.
1177 This allows your code to work with the standard L<crypt|/crypt> and
1178 with more exotic implementations.  In other words, assume
1179 nothing about the returned string itself nor about how many bytes 
1180 of SALT may matter.
1181
1182 Traditionally the result is a string of 13 bytes: two first bytes of
1183 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1184 the first eight bytes of PLAINTEXT mattered.  But alternative
1185 hashing schemes (like MD5), higher level security schemes (like C2),
1186 and implementations on non-Unix platforms may produce different
1187 strings.
1188
1189 When choosing a new salt create a random two character string whose
1190 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1191 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1192 characters is just a recommendation; the characters allowed in
1193 the salt depend solely on your system's crypt library, and Perl can't
1194 restrict what salts C<crypt()> accepts.
1195
1196 Here's an example that makes sure that whoever runs this program knows
1197 their password:
1198
1199     $pwd = (getpwuid($<))[1];
1200
1201     system "stty -echo";
1202     print "Password: ";
1203     chomp($word = <STDIN>);
1204     print "\n";
1205     system "stty echo";
1206
1207     if (crypt($word, $pwd) ne $pwd) {
1208         die "Sorry...\n";
1209     } else {
1210         print "ok\n";
1211     }
1212
1213 Of course, typing in your own password to whoever asks you
1214 for it is unwise.
1215
1216 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1217 of data, not least of all because you can't get the information
1218 back.  Look at the L<Digest> module for more robust algorithms.
1219
1220 If using crypt() on a Unicode string (which I<potentially> has
1221 characters with codepoints above 255), Perl tries to make sense
1222 of the situation by trying to downgrade (a copy of)
1223 the string back to an eight-bit byte string before calling crypt()
1224 (on that copy).  If that works, good.  If not, crypt() dies with
1225 C<Wide character in crypt>.
1226
1227 Portability issues: L<perlport/crypt>.
1228
1229 =item dbmclose HASH
1230 X<dbmclose>
1231
1232 =for Pod::Functions breaks binding on a tied dbm file
1233
1234 [This function has been largely superseded by the C<untie> function.]
1235
1236 Breaks the binding between a DBM file and a hash.
1237
1238 Portability issues: L<perlport/dbmclose>.
1239
1240 =item dbmopen HASH,DBNAME,MASK
1241 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1242
1243 =for Pod::Functions create binding on a tied dbm file
1244
1245 [This function has been largely superseded by the
1246 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1247
1248 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1249 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1250 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1251 is the name of the database (without the F<.dir> or F<.pag> extension if
1252 any).  If the database does not exist, it is created with protection
1253 specified by MASK (as modified by the C<umask>).  To prevent creation of
1254 the database if it doesn't exist, you may specify a MODE
1255 of 0, and the function will return a false value if it
1256 can't find an existing database.  If your system supports
1257 only the older DBM functions, you may make only one C<dbmopen> call in your
1258 program.  In older versions of Perl, if your system had neither DBM nor
1259 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1260 sdbm(3).
1261
1262 If you don't have write access to the DBM file, you can only read hash
1263 variables, not set them.  If you want to test whether you can write,
1264 either use file tests or try setting a dummy hash entry inside an C<eval> 
1265 to trap the error.
1266
1267 Note that functions such as C<keys> and C<values> may return huge lists
1268 when used on large DBM files.  You may prefer to use the C<each>
1269 function to iterate over large DBM files.  Example:
1270
1271     # print out history file offsets
1272     dbmopen(%HIST,'/usr/lib/news/history',0666);
1273     while (($key,$val) = each %HIST) {
1274         print $key, ' = ', unpack('L',$val), "\n";
1275     }
1276     dbmclose(%HIST);
1277
1278 See also L<AnyDBM_File> for a more general description of the pros and
1279 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1280 rich implementation.
1281
1282 You can control which DBM library you use by loading that library
1283 before you call dbmopen():
1284
1285     use DB_File;
1286     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1287         or die "Can't open netscape history file: $!";
1288
1289 Portability issues: L<perlport/dbmopen>.
1290
1291 =item defined EXPR
1292 X<defined> X<undef> X<undefined>
1293
1294 =item defined
1295
1296 =for Pod::Functions test whether a value, variable, or function is defined
1297
1298 Returns a Boolean value telling whether EXPR has a value other than
1299 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1300 checked.
1301
1302 Many operations return C<undef> to indicate failure, end of file,
1303 system error, uninitialized variable, and other exceptional
1304 conditions.  This function allows you to distinguish C<undef> from
1305 other values.  (A simple Boolean test will not distinguish among
1306 C<undef>, zero, the empty string, and C<"0">, which are all equally
1307 false.)  Note that since C<undef> is a valid scalar, its presence
1308 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1309 returns C<undef> when its argument is an empty array, I<or> when the
1310 element to return happens to be C<undef>.
1311
1312 You may also use C<defined(&func)> to check whether subroutine C<&func>
1313 has ever been defined.  The return value is unaffected by any forward
1314 declarations of C<&func>.  A subroutine that is not defined
1315 may still be callable: its package may have an C<AUTOLOAD> method that
1316 makes it spring into existence the first time that it is called; see
1317 L<perlsub>.
1318
1319 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1320 used to report whether memory for that aggregate had ever been
1321 allocated.  This behavior may disappear in future versions of Perl.
1322 You should instead use a simple test for size:
1323
1324     if (@an_array) { print "has array elements\n" }
1325     if (%a_hash)   { print "has hash members\n"   }
1326
1327 When used on a hash element, it tells you whether the value is defined,
1328 not whether the key exists in the hash.  Use L</exists> for the latter
1329 purpose.
1330
1331 Examples:
1332
1333     print if defined $switch{D};
1334     print "$val\n" while defined($val = pop(@ary));
1335     die "Can't readlink $sym: $!"
1336         unless defined($value = readlink $sym);
1337     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1338     $debugging = 0 unless defined $debugging;
1339
1340 Note:  Many folks tend to overuse C<defined> and are then surprised to
1341 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1342 defined values.  For example, if you say
1343
1344     "ab" =~ /a(.*)b/;
1345
1346 The pattern match succeeds and C<$1> is defined, although it
1347 matched "nothing".  It didn't really fail to match anything.  Rather, it
1348 matched something that happened to be zero characters long.  This is all
1349 very above-board and honest.  When a function returns an undefined value,
1350 it's an admission that it couldn't give you an honest answer.  So you
1351 should use C<defined> only when questioning the integrity of what
1352 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1353 what you want.
1354
1355 See also L</undef>, L</exists>, L</ref>.
1356
1357 =item delete EXPR
1358 X<delete>
1359
1360 =for Pod::Functions deletes a value from a hash
1361
1362 Given an expression that specifies an element or slice of a hash, C<delete>
1363 deletes the specified elements from that hash so that exists() on that element
1364 no longer returns true.  Setting a hash element to the undefined value does
1365 not remove its key, but deleting it does; see L</exists>.
1366
1367 In list context, returns the value or values deleted, or the last such
1368 element in scalar context.  The return list's length always matches that of
1369 the argument list: deleting non-existent elements returns the undefined value
1370 in their corresponding positions.
1371
1372 delete() may also be used on arrays and array slices, but its behavior is less
1373 straightforward.  Although exists() will return false for deleted entries,
1374 deleting array elements never changes indices of existing values; use shift()
1375 or splice() for that.  However, if any deleted elements fall at the end of an
1376 array, the array's size shrinks to the position of the highest element that
1377 still tests true for exists(), or to 0 if none do. In other words, an
1378 array won't have trailing nonexistent elements after a delete.
1379
1380 B<WARNING:> Calling delete on array values is deprecated and likely to
1381 be removed in a future version of Perl.
1382
1383 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1384 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1385 or array may not necessarily return anything; it depends on the implementation
1386 of the C<tied> package's DELETE method, which may do whatever it pleases.
1387
1388 The C<delete local EXPR> construct localizes the deletion to the current
1389 block at run time.  Until the block exits, elements locally deleted
1390 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1391 of composite types">.
1392
1393     %hash = (foo => 11, bar => 22, baz => 33);
1394     $scalar = delete $hash{foo};         # $scalar is 11
1395     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1396     @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1397
1398 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1399
1400     foreach $key (keys %HASH) {
1401         delete $HASH{$key};
1402     }
1403
1404     foreach $index (0 .. $#ARRAY) {
1405         delete $ARRAY[$index];
1406     }
1407
1408 And so do these:
1409
1410     delete @HASH{keys %HASH};
1411
1412     delete @ARRAY[0 .. $#ARRAY];
1413
1414 But both are slower than assigning the empty list
1415 or undefining %HASH or @ARRAY, which is the customary 
1416 way to empty out an aggregate:
1417
1418     %HASH = ();     # completely empty %HASH
1419     undef %HASH;    # forget %HASH ever existed
1420
1421     @ARRAY = ();    # completely empty @ARRAY
1422     undef @ARRAY;   # forget @ARRAY ever existed
1423
1424 The EXPR can be arbitrarily complicated provided its
1425 final operation is an element or slice of an aggregate:
1426
1427     delete $ref->[$x][$y]{$key};
1428     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1429
1430     delete $ref->[$x][$y][$index];
1431     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1432
1433 =item die LIST
1434 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1435
1436 =for Pod::Functions raise an exception or bail out
1437
1438 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1439 into C<$@> and the C<eval> is terminated with the undefined value.
1440 If the exception is outside of all enclosing C<eval>s, then the uncaught
1441 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1442 need to exit the process with a specific exit code, see L</exit>.
1443
1444 Equivalent examples:
1445
1446     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1447     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1448
1449 If the last element of LIST does not end in a newline, the current
1450 script line number and input line number (if any) are also printed,
1451 and a newline is supplied.  Note that the "input line number" (also
1452 known as "chunk") is subject to whatever notion of "line" happens to
1453 be currently in effect, and is also available as the special variable
1454 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1455
1456 Hint: sometimes appending C<", stopped"> to your message will cause it
1457 to make better sense when the string C<"at foo line 123"> is appended.
1458 Suppose you are running script "canasta".
1459
1460     die "/etc/games is no good";
1461     die "/etc/games is no good, stopped";
1462
1463 produce, respectively
1464
1465     /etc/games is no good at canasta line 123.
1466     /etc/games is no good, stopped at canasta line 123.
1467
1468 If the output is empty and C<$@> already contains a value (typically from a
1469 previous eval) that value is reused after appending C<"\t...propagated">.
1470 This is useful for propagating exceptions:
1471
1472     eval { ... };
1473     die unless $@ =~ /Expected exception/;
1474
1475 If the output is empty and C<$@> contains an object reference that has a
1476 C<PROPAGATE> method, that method will be called with additional file
1477 and line number parameters.  The return value replaces the value in
1478 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1479 were called.
1480
1481 If C<$@> is empty then the string C<"Died"> is used.
1482
1483 If an uncaught exception results in interpreter exit, the exit code is
1484 determined from the values of C<$!> and C<$?> with this pseudocode:
1485
1486     exit $! if $!;              # errno
1487     exit $? >> 8 if $? >> 8;    # child exit status
1488     exit 255;                   # last resort
1489
1490 The intent is to squeeze as much possible information about the likely cause
1491 into the limited space of the system exit
1492 code.  However, as C<$!> is the value
1493 of C's C<errno>, which can be set by any system call, this means that the value
1494 of the exit code used by C<die> can be non-predictable, so should not be relied
1495 upon, other than to be non-zero.
1496
1497 You can also call C<die> with a reference argument, and if this is trapped
1498 within an C<eval>, C<$@> contains that reference.  This permits more
1499 elaborate exception handling using objects that maintain arbitrary state
1500 about the exception.  Such a scheme is sometimes preferable to matching
1501 particular string values of C<$@> with regular expressions.  Because C<$@> 
1502 is a global variable and C<eval> may be used within object implementations,
1503 be careful that analyzing the error object doesn't replace the reference in
1504 the global variable.  It's easiest to make a local copy of the reference
1505 before any manipulations.  Here's an example:
1506
1507     use Scalar::Util "blessed";
1508
1509     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1510     if (my $ev_err = $@) {
1511         if (blessed($ev_err)
1512             && $ev_err->isa("Some::Module::Exception")) {
1513             # handle Some::Module::Exception
1514         }
1515         else {
1516             # handle all other possible exceptions
1517         }
1518     }
1519
1520 Because Perl stringifies uncaught exception messages before display,
1521 you'll probably want to overload stringification operations on
1522 exception objects.  See L<overload> for details about that.
1523
1524 You can arrange for a callback to be run just before the C<die>
1525 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1526 handler is called with the error text and can change the error
1527 message, if it sees fit, by calling C<die> again.  See
1528 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1529 L<"eval BLOCK"> for some examples.  Although this feature was 
1530 to be run only right before your program was to exit, this is not
1531 currently so: the C<$SIG{__DIE__}> hook is currently called
1532 even inside eval()ed blocks/strings!  If one wants the hook to do
1533 nothing in such situations, put
1534
1535     die @_ if $^S;
1536
1537 as the first line of the handler (see L<perlvar/$^S>).  Because
1538 this promotes strange action at a distance, this counterintuitive
1539 behavior may be fixed in a future release.
1540
1541 See also exit(), warn(), and the Carp module.
1542
1543 =item do BLOCK
1544 X<do> X<block>
1545
1546 =for Pod::Functions turn a BLOCK into a TERM
1547
1548 Not really a function.  Returns the value of the last command in the
1549 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1550 C<until> loop modifier, executes the BLOCK once before testing the loop
1551 condition.  (On other statements the loop modifiers test the conditional
1552 first.)
1553
1554 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1555 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1556 See L<perlsyn> for alternative strategies.
1557
1558 =item do EXPR
1559 X<do>
1560
1561 Uses the value of EXPR as a filename and executes the contents of the
1562 file as a Perl script.
1563
1564     do 'stat.pl';
1565
1566 is largely like
1567
1568     eval `cat stat.pl`;
1569
1570 except that it's more concise, runs no external processes, keeps track of
1571 the current
1572 filename for error messages, searches the C<@INC> directories, and updates
1573 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1574 these variables.  It also differs in that code evaluated with C<do FILENAME>
1575 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1576 same, however, in that it does reparse the file every time you call it,
1577 so you probably don't want to do this inside a loop.
1578
1579 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1580 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1581 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1582 could fail in a way that also sets C<$!>.  If the file is successfully
1583 compiled, C<do> returns the value of the last expression evaluated.
1584
1585 Inclusion of library modules is better done with the
1586 C<use> and C<require> operators, which also do automatic error checking
1587 and raise an exception if there's a problem.
1588
1589 You might like to use C<do> to read in a program configuration
1590 file.  Manual error checking can be done this way:
1591
1592     # read in config files: system first, then user
1593     for $file ("/share/prog/defaults.rc",
1594                "$ENV{HOME}/.someprogrc")
1595     {
1596         unless ($return = do $file) {
1597             warn "couldn't parse $file: $@" if $@;
1598             warn "couldn't do $file: $!"    unless defined $return;
1599             warn "couldn't run $file"       unless $return;
1600         }
1601     }
1602
1603 =item dump LABEL
1604 X<dump> X<core> X<undump>
1605
1606 =item dump EXPR
1607
1608 =item dump
1609
1610 =for Pod::Functions create an immediate core dump
1611
1612 This function causes an immediate core dump.  See also the B<-u>
1613 command-line switch in L<perlrun>, which does the same thing.
1614 Primarily this is so that you can use the B<undump> program (not
1615 supplied) to turn your core dump into an executable binary after
1616 having initialized all your variables at the beginning of the
1617 program.  When the new binary is executed it will begin by executing
1618 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1619 Think of it as a goto with an intervening core dump and reincarnation.
1620 If C<LABEL> is omitted, restarts the program from the top.  The
1621 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1622 computed at run time, being otherwise identical to C<dump LABEL>.
1623
1624 B<WARNING>: Any files opened at the time of the dump will I<not>
1625 be open any more when the program is reincarnated, with possible
1626 resulting confusion by Perl.
1627
1628 This function is now largely obsolete, mostly because it's very hard to
1629 convert a core file into an executable.  That's why you should now invoke
1630 it as C<CORE::dump()>, if you don't want to be warned against a possible
1631 typo.
1632
1633 Unlike most named operators, this has the same precedence as assignment.
1634 It is also exempt from the looks-like-a-function rule, so
1635 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1636 C<dump>.
1637
1638 Portability issues: L<perlport/dump>.
1639
1640 =item each HASH
1641 X<each> X<hash, iterator>
1642
1643 =item each ARRAY
1644 X<array, iterator>
1645
1646 =item each EXPR
1647
1648 =for Pod::Functions retrieve the next key/value pair from a hash
1649
1650 When called on a hash in list context, returns a 2-element list
1651 consisting of the key and value for the next element of a hash.  In Perl
1652 5.12 and later only, it will also return the index and value for the next
1653 element of an array so that you can iterate over it; older Perls consider
1654 this a syntax error.  When called in scalar context, returns only the key
1655 (not the value) in a hash, or the index in an array.
1656
1657 Hash entries are returned in an apparently random order.  The actual random
1658 order is specific to a given hash; the exact same series of operations
1659 on two hashes may result in a different order for each hash.  Any insertion
1660 into the hash may change the order, as will any deletion, with the exception
1661 that the most recent key returned by C<each> or C<keys> may be deleted
1662 without changing the order.  So long as a given hash is unmodified you may
1663 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
1664 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
1665 details on why hash order is randomized.  Aside from the guarantees
1666 provided here the exact details of Perl's hash algorithm and the hash
1667 traversal order are subject to change in any release of Perl.
1668
1669 After C<each> has returned all entries from the hash or array, the next
1670 call to C<each> returns the empty list in list context and C<undef> in
1671 scalar context; the next call following I<that> one restarts iteration.
1672 Each hash or array has its own internal iterator, accessed by C<each>,
1673 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1674 reached the end as just described; it can be explicitly reset by calling
1675 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1676 elements while iterating over it, the effect on the iterator is
1677 unspecified; for example, entries may be skipped or duplicated--so don't
1678 do that.  Exception: It is always safe to delete the item most recently
1679 returned by C<each()>, so the following code works properly:
1680
1681         while (($key, $value) = each %hash) {
1682           print $key, "\n";
1683           delete $hash{$key};   # This is safe
1684         }
1685
1686 Tied hashes may have a different ordering behaviour to perl's hash
1687 implementation.
1688
1689 This prints out your environment like the printenv(1) program,
1690 but in a different order:
1691
1692     while (($key,$value) = each %ENV) {
1693         print "$key=$value\n";
1694     }
1695
1696 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1697 reference to an unblessed hash or array.  The argument will be dereferenced
1698 automatically.  This aspect of C<each> is considered highly experimental.
1699 The exact behaviour may change in a future version of Perl.
1700
1701     while (($key,$value) = each $hashref) { ... }
1702
1703 As of Perl 5.18 you can use a bare C<each> in a C<while> loop,
1704 which will set C<$_> on every iteration.
1705
1706     while(each %ENV) {
1707         print "$_=$ENV{$_}\n";
1708     }
1709
1710 To avoid confusing would-be users of your code who are running earlier
1711 versions of Perl with mysterious syntax errors, put this sort of thing at
1712 the top of your file to signal that your code will work I<only> on Perls of
1713 a recent vintage:
1714
1715     use 5.012;  # so keys/values/each work on arrays
1716     use 5.014;  # so keys/values/each work on scalars (experimental)
1717     use 5.018;  # so each assigns to $_ in a lone while test
1718
1719 See also C<keys>, C<values>, and C<sort>.
1720
1721 =item eof FILEHANDLE
1722 X<eof>
1723 X<end of file>
1724 X<end-of-file>
1725
1726 =item eof ()
1727
1728 =item eof
1729
1730 =for Pod::Functions test a filehandle for its end
1731
1732 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1733 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1734 gives the real filehandle.  (Note that this function actually
1735 reads a character and then C<ungetc>s it, so isn't useful in an
1736 interactive context.)  Do not read from a terminal file (or call
1737 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1738 as terminals may lose the end-of-file condition if you do.
1739
1740 An C<eof> without an argument uses the last file read.  Using C<eof()>
1741 with empty parentheses is different.  It refers to the pseudo file
1742 formed from the files listed on the command line and accessed via the
1743 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1744 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1745 used will cause C<@ARGV> to be examined to determine if input is
1746 available.   Similarly, an C<eof()> after C<< <> >> has returned
1747 end-of-file will assume you are processing another C<@ARGV> list,
1748 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1749 see L<perlop/"I/O Operators">.
1750
1751 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1752 detect the end of each file, whereas C<eof()> will detect the end 
1753 of the very last file only.  Examples:
1754
1755     # reset line numbering on each input file
1756     while (<>) {
1757         next if /^\s*#/;  # skip comments
1758         print "$.\t$_";
1759     } continue {
1760         close ARGV if eof;  # Not eof()!
1761     }
1762
1763     # insert dashes just before last line of last file
1764     while (<>) {
1765         if (eof()) {  # check for end of last file
1766             print "--------------\n";
1767         }
1768         print;
1769         last if eof();     # needed if we're reading from a terminal
1770     }
1771
1772 Practical hint: you almost never need to use C<eof> in Perl, because the
1773 input operators typically return C<undef> when they run out of data or 
1774 encounter an error.
1775
1776 =item eval EXPR
1777 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1778 X<error, handling> X<exception, handling>
1779
1780 =item eval BLOCK
1781
1782 =item eval
1783
1784 =for Pod::Functions catch exceptions or compile and run code
1785
1786 In the first form, often referred to as a "string eval", the return
1787 value of EXPR is parsed and executed as if it
1788 were a little Perl program.  The value of the expression (which is itself
1789 determined within scalar context) is first parsed, and if there were no
1790 errors, executed as a block within the lexical context of the current Perl
1791 program.  This means, that in particular, any outer lexical variables are
1792 visible to it, and any package variable settings or subroutine and format
1793 definitions remain afterwards.
1794
1795 Note that the value is parsed every time the C<eval> executes.
1796 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1797 delay parsing and subsequent execution of the text of EXPR until run time.
1798
1799 If the C<unicode_eval> feature is enabled (which is the default under a
1800 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1801 characters, so C<use utf8> declarations have no effect, and source filters
1802 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1803 will sometimes be treated as characters and sometimes as bytes, depending
1804 on the internal encoding, and source filters activated within the C<eval>
1805 exhibit the erratic, but historical, behaviour of affecting some outer file
1806 scope that is still compiling.  See also the L</evalbytes> keyword, which
1807 always treats its input as a byte stream and works properly with source
1808 filters, and the L<feature> pragma.
1809
1810 Problems can arise if the string expands a scalar containing a floating
1811 point number.  That scalar can expand to letters, such as C<"NaN"> or
1812 C<"Infinity">; or, within the scope of a C<use locale>, the decimal
1813 point character may be something other than a dot (such as a comma).
1814 None of these are likely to parse as you are likely expecting.
1815
1816 In the second form, the code within the BLOCK is parsed only once--at the
1817 same time the code surrounding the C<eval> itself was parsed--and executed
1818 within the context of the current Perl program.  This form is typically
1819 used to trap exceptions more efficiently than the first (see below), while
1820 also providing the benefit of checking the code within BLOCK at compile
1821 time.
1822
1823 The final semicolon, if any, may be omitted from the value of EXPR or within
1824 the BLOCK.
1825
1826 In both forms, the value returned is the value of the last expression
1827 evaluated inside the mini-program; a return statement may be also used, just
1828 as with subroutines.  The expression providing the return value is evaluated
1829 in void, scalar, or list context, depending on the context of the C<eval> 
1830 itself.  See L</wantarray> for more on how the evaluation context can be 
1831 determined.
1832
1833 If there is a syntax error or runtime error, or a C<die> statement is
1834 executed, C<eval> returns C<undef> in scalar context
1835 or an empty list in list context, and C<$@> is set to the error
1836 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1837 in list context for syntax errors, but not for runtime errors.)
1838 If there was no error, C<$@> is set to the empty string.  A
1839 control flow operator like C<last> or C<goto> can bypass the setting of
1840 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1841 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1842 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1843 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1844 See L</warn>, L<perlvar>, and L<warnings>.
1845
1846 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1847 determining whether a particular feature (such as C<socket> or C<symlink>)
1848 is implemented.  It is also Perl's exception-trapping mechanism, where
1849 the die operator is used to raise exceptions.
1850
1851 If you want to trap errors when loading an XS module, some problems with
1852 the binary interface (such as Perl version skew) may be fatal even with
1853 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1854
1855 If the code to be executed doesn't vary, you may use the eval-BLOCK
1856 form to trap run-time errors without incurring the penalty of
1857 recompiling each time.  The error, if any, is still returned in C<$@>.
1858 Examples:
1859
1860     # make divide-by-zero nonfatal
1861     eval { $answer = $a / $b; }; warn $@ if $@;
1862
1863     # same thing, but less efficient
1864     eval '$answer = $a / $b'; warn $@ if $@;
1865
1866     # a compile-time error
1867     eval { $answer = }; # WRONG
1868
1869     # a run-time error
1870     eval '$answer =';   # sets $@
1871
1872 Using the C<eval{}> form as an exception trap in libraries does have some
1873 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1874 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1875 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1876 as this example shows:
1877
1878     # a private exception trap for divide-by-zero
1879     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1880     warn $@ if $@;
1881
1882 This is especially significant, given that C<__DIE__> hooks can call
1883 C<die> again, which has the effect of changing their error messages:
1884
1885     # __DIE__ hooks may modify error messages
1886     {
1887        local $SIG{'__DIE__'} =
1888               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1889        eval { die "foo lives here" };
1890        print $@ if $@;                # prints "bar lives here"
1891     }
1892
1893 Because this promotes action at a distance, this counterintuitive behavior
1894 may be fixed in a future release.
1895
1896 With an C<eval>, you should be especially careful to remember what's
1897 being looked at when:
1898
1899     eval $x;        # CASE 1
1900     eval "$x";      # CASE 2
1901
1902     eval '$x';      # CASE 3
1903     eval { $x };    # CASE 4
1904
1905     eval "\$$x++";  # CASE 5
1906     $$x++;          # CASE 6
1907
1908 Cases 1 and 2 above behave identically: they run the code contained in
1909 the variable $x.  (Although case 2 has misleading double quotes making
1910 the reader wonder what else might be happening (nothing is).)  Cases 3
1911 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1912 does nothing but return the value of $x.  (Case 4 is preferred for
1913 purely visual reasons, but it also has the advantage of compiling at
1914 compile-time instead of at run-time.)  Case 5 is a place where
1915 normally you I<would> like to use double quotes, except that in this
1916 particular situation, you can just use symbolic references instead, as
1917 in case 6.
1918
1919 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1920 of localized variables, which means that for your code to run on older
1921 versions, a temporary is required if you want to mask some but not all
1922 errors:
1923
1924     # alter $@ on nefarious repugnancy only
1925     {
1926        my $e;
1927        {
1928          local $@; # protect existing $@
1929          eval { test_repugnancy() };
1930          # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1931          $@ =~ /nefarious/ and $e = $@;
1932        }
1933        die $e if defined $e
1934     }
1935
1936 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1937 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1938
1939 An C<eval ''> executed within a subroutine defined
1940 in the C<DB> package doesn't see the usual
1941 surrounding lexical scope, but rather the scope of the first non-DB piece
1942 of code that called it.  You don't normally need to worry about this unless
1943 you are writing a Perl debugger.
1944
1945 =item evalbytes EXPR
1946 X<evalbytes>
1947
1948 =item evalbytes
1949
1950 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
1951
1952 This function is like L</eval> with a string argument, except it always
1953 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1954 string containing characters whose ordinal value exceeds 255 results in an
1955 error.  Source filters activated within the evaluated code apply to the
1956 code itself.
1957
1958 This function is only available under the C<evalbytes> feature, a
1959 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1960 L<feature> for more information.
1961
1962 =item exec LIST
1963 X<exec> X<execute>
1964
1965 =item exec PROGRAM LIST
1966
1967 =for Pod::Functions abandon this program to run another
1968
1969 The C<exec> function executes a system command I<and never returns>;
1970 use C<system> instead of C<exec> if you want it to return.  It fails and
1971 returns false only if the command does not exist I<and> it is executed
1972 directly instead of via your system's command shell (see below).
1973
1974 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1975 warns you if C<exec> is called in void context and if there is a following
1976 statement that isn't C<die>, C<warn>, or C<exit> (if C<-w> is set--but
1977 you always do that, right?).  If you I<really> want to follow an C<exec>
1978 with some other statement, you can use one of these styles to avoid the warning:
1979
1980     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1981     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1982
1983 If there is more than one argument in LIST, this calls execvp(3) with the
1984 arguments in LIST.  If there is only one element in LIST, the argument is
1985 checked for shell metacharacters, and if there are any, the entire
1986 argument is passed to the system's command shell for parsing (this is
1987 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
1988 there are no shell metacharacters in the argument, it is split into words
1989 and passed directly to C<execvp>, which is more efficient.  Examples:
1990
1991     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1992     exec "sort $outfile | uniq";
1993
1994 If you don't really want to execute the first argument, but want to lie
1995 to the program you are executing about its own name, you can specify
1996 the program you actually want to run as an "indirect object" (without a
1997 comma) in front of the LIST, as in C<exec PROGRAM LIST>.  (This always
1998 forces interpretation of the LIST as a multivalued list, even if there
1999 is only a single scalar in the list.)  Example:
2000
2001     $shell = '/bin/csh';
2002     exec $shell '-sh';    # pretend it's a login shell
2003
2004 or, more directly,
2005
2006     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
2007
2008 When the arguments get executed via the system shell, results are
2009 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
2010 for details.
2011
2012 Using an indirect object with C<exec> or C<system> is also more
2013 secure.  This usage (which also works fine with system()) forces
2014 interpretation of the arguments as a multivalued list, even if the
2015 list had just one argument.  That way you're safe from the shell
2016 expanding wildcards or splitting up words with whitespace in them.
2017
2018     @args = ( "echo surprise" );
2019
2020     exec @args;               # subject to shell escapes
2021                                 # if @args == 1
2022     exec { $args[0] } @args;  # safe even with one-arg list
2023
2024 The first version, the one without the indirect object, ran the I<echo>
2025 program, passing it C<"surprise"> an argument.  The second version didn't;
2026 it tried to run a program named I<"echo surprise">, didn't find it, and set
2027 C<$?> to a non-zero value indicating failure.
2028
2029 On Windows, only the C<exec PROGRAM LIST> indirect object syntax will
2030 reliably avoid using the shell; C<exec LIST>, even with more than one
2031 element, will fall back to the shell if the first spawn fails.
2032
2033 Perl attempts to flush all files opened for output before the exec,
2034 but this may not be supported on some platforms (see L<perlport>).
2035 To be safe, you may need to set C<$|> ($AUTOFLUSH in English) or
2036 call the C<autoflush()> method of C<IO::Handle> on any open handles
2037 to avoid lost output.
2038
2039 Note that C<exec> will not call your C<END> blocks, nor will it invoke
2040 C<DESTROY> methods on your objects.
2041
2042 Portability issues: L<perlport/exec>.
2043
2044 =item exists EXPR
2045 X<exists> X<autovivification>
2046
2047 =for Pod::Functions test whether a hash key is present
2048
2049 Given an expression that specifies an element of a hash, returns true if the
2050 specified element in the hash has ever been initialized, even if the
2051 corresponding value is undefined.
2052
2053     print "Exists\n"    if exists $hash{$key};
2054     print "Defined\n"   if defined $hash{$key};
2055     print "True\n"      if $hash{$key};
2056
2057 exists may also be called on array elements, but its behavior is much less
2058 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
2059 that calling exists on array values is deprecated and likely to be removed in
2060 a future version of Perl.
2061
2062     print "Exists\n"    if exists $array[$index];
2063     print "Defined\n"   if defined $array[$index];
2064     print "True\n"      if $array[$index];
2065
2066 A hash or array element can be true only if it's defined and defined only if
2067 it exists, but the reverse doesn't necessarily hold true.
2068
2069 Given an expression that specifies the name of a subroutine,
2070 returns true if the specified subroutine has ever been declared, even
2071 if it is undefined.  Mentioning a subroutine name for exists or defined
2072 does not count as declaring it.  Note that a subroutine that does not
2073 exist may still be callable: its package may have an C<AUTOLOAD>
2074 method that makes it spring into existence the first time that it is
2075 called; see L<perlsub>.
2076
2077     print "Exists\n"  if exists &subroutine;
2078     print "Defined\n" if defined &subroutine;
2079
2080 Note that the EXPR can be arbitrarily complicated as long as the final
2081 operation is a hash or array key lookup or subroutine name:
2082
2083     if (exists $ref->{A}->{B}->{$key})  { }
2084     if (exists $hash{A}{B}{$key})       { }
2085
2086     if (exists $ref->{A}->{B}->[$ix])   { }
2087     if (exists $hash{A}{B}[$ix])        { }
2088
2089     if (exists &{$ref->{A}{B}{$key}})   { }
2090
2091 Although the most deeply nested array or hash element will not spring into
2092 existence just because its existence was tested, any intervening ones will.
2093 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2094 into existence due to the existence test for the $key element above.
2095 This happens anywhere the arrow operator is used, including even here:
2096
2097     undef $ref;
2098     if (exists $ref->{"Some key"})    { }
2099     print $ref;  # prints HASH(0x80d3d5c)
2100
2101 This surprising autovivification in what does not at first--or even
2102 second--glance appear to be an lvalue context may be fixed in a future
2103 release.
2104
2105 Use of a subroutine call, rather than a subroutine name, as an argument
2106 to exists() is an error.
2107
2108     exists &sub;    # OK
2109     exists &sub();  # Error
2110
2111 =item exit EXPR
2112 X<exit> X<terminate> X<abort>
2113
2114 =item exit
2115
2116 =for Pod::Functions terminate this program
2117
2118 Evaluates EXPR and exits immediately with that value.    Example:
2119
2120     $ans = <STDIN>;
2121     exit 0 if $ans =~ /^[Xx]/;
2122
2123 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
2124 universally recognized values for EXPR are C<0> for success and C<1>
2125 for error; other values are subject to interpretation depending on the
2126 environment in which the Perl program is running.  For example, exiting
2127 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2128 the mailer to return the item undelivered, but that's not true everywhere.
2129
2130 Don't use C<exit> to abort a subroutine if there's any chance that
2131 someone might want to trap whatever error happened.  Use C<die> instead,
2132 which can be trapped by an C<eval>.
2133
2134 The exit() function does not always exit immediately.  It calls any
2135 defined C<END> routines first, but these C<END> routines may not
2136 themselves abort the exit.  Likewise any object destructors that need to
2137 be called are called before the real exit.  C<END> routines and destructors
2138 can change the exit status by modifying C<$?>.  If this is a problem, you
2139 can call C<POSIX::_exit($status)> to avoid END and destructor processing.
2140 See L<perlmod> for details.
2141
2142 Portability issues: L<perlport/exit>.
2143
2144 =item exp EXPR
2145 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2146
2147 =item exp
2148
2149 =for Pod::Functions raise I<e> to a power
2150
2151 Returns I<e> (the natural logarithm base) to the power of EXPR.
2152 If EXPR is omitted, gives C<exp($_)>.
2153
2154 =item fc EXPR
2155 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2156
2157 =item fc
2158
2159 =for Pod::Functions +fc return casefolded version of a string
2160
2161 Returns the casefolded version of EXPR.  This is the internal function
2162 implementing the C<\F> escape in double-quoted strings.
2163
2164 Casefolding is the process of mapping strings to a form where case
2165 differences are erased; comparing two strings in their casefolded
2166 form is effectively a way of asking if two strings are equal,
2167 regardless of case.
2168
2169 Roughly, if you ever found yourself writing this
2170
2171     lc($this) eq lc($that)    # Wrong!
2172         # or
2173     uc($this) eq uc($that)    # Also wrong!
2174         # or
2175     $this =~ /^\Q$that\E\z/i  # Right!
2176
2177 Now you can write
2178
2179     fc($this) eq fc($that)
2180
2181 And get the correct results.
2182
2183 Perl only implements the full form of casefolding,
2184 but you can access the simple folds using L<Unicode::UCD/casefold()> and
2185 L<Unicode::UCD/prop_invmap()>.
2186 For further information on casefolding, refer to
2187 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2188 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2189 available at L<http://www.unicode.org/versions/latest/>, as well as the
2190 Case Charts available at L<http://www.unicode.org/charts/case/>.
2191
2192 If EXPR is omitted, uses C<$_>.
2193
2194 This function behaves the same way under various pragma, such as within
2195 S<C<"use feature 'unicode_strings">>, as L</lc> does, with the single
2196 exception of C<fc> of LATIN CAPITAL LETTER SHARP S (U+1E9E) within the
2197 scope of S<C<use locale>>.  The foldcase of this character would
2198 normally be C<"ss">, but as explained in the L</lc> section, case
2199 changes that cross the 255/256 boundary are problematic under locales,
2200 and are hence prohibited.  Therefore, this function under locale returns
2201 instead the string C<"\x{17F}\x{17F}">, which is the LATIN SMALL LETTER
2202 LONG S.  Since that character itself folds to C<"s">, the string of two
2203 of them together should be equivalent to a single U+1E9E when foldcased.
2204
2205 While the Unicode Standard defines two additional forms of casefolding,
2206 one for Turkic languages and one that never maps one character into multiple
2207 characters, these are not provided by the Perl core; However, the CPAN module
2208 C<Unicode::Casing> may be used to provide an implementation.
2209
2210 This keyword is available only when the C<"fc"> feature is enabled,
2211 or when prefixed with C<CORE::>; See L<feature>.  Alternately,
2212 include a C<use v5.16> or later to the current scope.
2213
2214 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2215 X<fcntl>
2216
2217 =for Pod::Functions file control system call
2218
2219 Implements the fcntl(2) function.  You'll probably have to say
2220
2221     use Fcntl;
2222
2223 first to get the correct constant definitions.  Argument processing and
2224 value returned work just like C<ioctl> below.
2225 For example:
2226
2227     use Fcntl;
2228     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2229         or die "can't fcntl F_GETFL: $!";
2230
2231 You don't have to check for C<defined> on the return from C<fcntl>.
2232 Like C<ioctl>, it maps a C<0> return from the system call into
2233 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2234 in numeric context.  It is also exempt from the normal B<-w> warnings
2235 on improper numeric conversions.
2236
2237 Note that C<fcntl> raises an exception if used on a machine that
2238 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2239 manpage to learn what functions are available on your system.
2240
2241 Here's an example of setting a filehandle named C<REMOTE> to be
2242 non-blocking at the system level.  You'll have to negotiate C<$|>
2243 on your own, though.
2244
2245     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2246
2247     $flags = fcntl(REMOTE, F_GETFL, 0)
2248                 or die "Can't get flags for the socket: $!\n";
2249
2250     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2251                 or die "Can't set flags for the socket: $!\n";
2252
2253 Portability issues: L<perlport/fcntl>.
2254
2255 =item __FILE__
2256 X<__FILE__>
2257
2258 =for Pod::Functions the name of the current source file
2259
2260 A special token that returns the name of the file in which it occurs.
2261
2262 =item fileno FILEHANDLE
2263 X<fileno>
2264
2265 =for Pod::Functions return file descriptor from filehandle
2266
2267 Returns the file descriptor for a filehandle, or undefined if the
2268 filehandle is not open.  If there is no real file descriptor at the OS
2269 level, as can happen with filehandles connected to memory objects via
2270 C<open> with a reference for the third argument, -1 is returned.
2271
2272 This is mainly useful for constructing
2273 bitmaps for C<select> and low-level POSIX tty-handling operations.
2274 If FILEHANDLE is an expression, the value is taken as an indirect
2275 filehandle, generally its name.
2276
2277 You can use this to find out whether two handles refer to the
2278 same underlying descriptor:
2279
2280     if (fileno(THIS) != -1 && fileno(THIS) == fileno(THAT)) {
2281         print "THIS and THAT are dups\n";
2282     } elsif (fileno(THIS) != -1 && fileno(THAT) != -1) {
2283         print "THIS and THAT have different " .
2284             "underlying file descriptors\n";
2285     } else {
2286         print "At least one of THIS and THAT does " .
2287             "not have a real file descriptor\n";
2288     }
2289
2290 =item flock FILEHANDLE,OPERATION
2291 X<flock> X<lock> X<locking>
2292
2293 =for Pod::Functions lock an entire file with an advisory lock
2294
2295 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2296 for success, false on failure.  Produces a fatal error if used on a
2297 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2298 C<flock> is Perl's portable file-locking interface, although it locks
2299 entire files only, not records.
2300
2301 Two potentially non-obvious but traditional C<flock> semantics are
2302 that it waits indefinitely until the lock is granted, and that its locks
2303 are B<merely advisory>.  Such discretionary locks are more flexible, but
2304 offer fewer guarantees.  This means that programs that do not also use
2305 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2306 your port's specific documentation, and your system-specific local manpages
2307 for details.  It's best to assume traditional behavior if you're writing
2308 portable programs.  (But if you're not, you should as always feel perfectly
2309 free to write for your own system's idiosyncrasies (sometimes called
2310 "features").  Slavish adherence to portability concerns shouldn't get
2311 in the way of your getting your job done.)
2312
2313 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2314 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2315 you can use the symbolic names if you import them from the L<Fcntl> module,
2316 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2317 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2318 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2319 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2320 waiting for the lock; check the return status to see if you got it.
2321
2322 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2323 before locking or unlocking it.
2324
2325 Note that the emulation built with lockf(3) doesn't provide shared
2326 locks, and it requires that FILEHANDLE be open with write intent.  These
2327 are the semantics that lockf(3) implements.  Most if not all systems
2328 implement lockf(3) in terms of fcntl(2) locking, though, so the
2329 differing semantics shouldn't bite too many people.
2330
2331 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2332 be open with read intent to use LOCK_SH and requires that it be open
2333 with write intent to use LOCK_EX.
2334
2335 Note also that some versions of C<flock> cannot lock things over the
2336 network; you would need to use the more system-specific C<fcntl> for
2337 that.  If you like you can force Perl to ignore your system's flock(2)
2338 function, and so provide its own fcntl(2)-based emulation, by passing
2339 the switch C<-Ud_flock> to the F<Configure> program when you configure
2340 and build a new Perl.
2341
2342 Here's a mailbox appender for BSD systems.
2343
2344     # import LOCK_* and SEEK_END constants
2345     use Fcntl qw(:flock SEEK_END);
2346
2347     sub lock {
2348         my ($fh) = @_;
2349         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2350
2351         # and, in case someone appended while we were waiting...
2352         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2353     }
2354
2355     sub unlock {
2356         my ($fh) = @_;
2357         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2358     }
2359
2360     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2361         or die "Can't open mailbox: $!";
2362
2363     lock($mbox);
2364     print $mbox $msg,"\n\n";
2365     unlock($mbox);
2366
2367 On systems that support a real flock(2), locks are inherited across fork()
2368 calls, whereas those that must resort to the more capricious fcntl(2)
2369 function lose their locks, making it seriously harder to write servers.
2370
2371 See also L<DB_File> for other flock() examples.
2372
2373 Portability issues: L<perlport/flock>.
2374
2375 =item fork
2376 X<fork> X<child> X<parent>
2377
2378 =for Pod::Functions create a new process just like this one
2379
2380 Does a fork(2) system call to create a new process running the
2381 same program at the same point.  It returns the child pid to the
2382 parent process, C<0> to the child process, or C<undef> if the fork is
2383 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2384 are shared, while everything else is copied.  On most systems supporting
2385 fork(), great care has gone into making it extremely efficient (for
2386 example, using copy-on-write technology on data pages), making it the
2387 dominant paradigm for multitasking over the last few decades.
2388
2389 Perl attempts to flush all files opened for
2390 output before forking the child process, but this may not be supported
2391 on some platforms (see L<perlport>).  To be safe, you may need to set
2392 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2393 C<IO::Handle> on any open handles to avoid duplicate output.
2394
2395 If you C<fork> without ever waiting on your children, you will
2396 accumulate zombies.  On some systems, you can avoid this by setting
2397 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2398 forking and reaping moribund children.
2399
2400 Note that if your forked child inherits system file descriptors like
2401 STDIN and STDOUT that are actually connected by a pipe or socket, even
2402 if you exit, then the remote server (such as, say, a CGI script or a
2403 backgrounded job launched from a remote shell) won't think you're done.
2404 You should reopen those to F</dev/null> if it's any issue.
2405
2406 On some platforms such as Windows, where the fork() system call is not available,
2407 Perl can be built to emulate fork() in the Perl interpreter.
2408 The emulation is designed, at the level of the Perl program,
2409 to be as compatible as possible with the "Unix" fork().
2410 However it has limitations that have to be considered in code intended to be portable.
2411 See L<perlfork> for more details.
2412
2413 Portability issues: L<perlport/fork>.
2414
2415 =item format
2416 X<format>
2417
2418 =for Pod::Functions declare a picture format with use by the write() function
2419
2420 Declare a picture format for use by the C<write> function.  For
2421 example:
2422
2423     format Something =
2424         Test: @<<<<<<<< @||||| @>>>>>
2425               $str,     $%,    '$' . int($num)
2426     .
2427
2428     $str = "widget";
2429     $num = $cost/$quantity;
2430     $~ = 'Something';
2431     write;
2432
2433 See L<perlform> for many details and examples.
2434
2435 =item formline PICTURE,LIST
2436 X<formline>
2437
2438 =for Pod::Functions internal function used for formats
2439
2440 This is an internal function used by C<format>s, though you may call it,
2441 too.  It formats (see L<perlform>) a list of values according to the
2442 contents of PICTURE, placing the output into the format output
2443 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2444 Eventually, when a C<write> is done, the contents of
2445 C<$^A> are written to some filehandle.  You could also read C<$^A>
2446 and then set C<$^A> back to C<"">.  Note that a format typically
2447 does one C<formline> per line of form, but the C<formline> function itself
2448 doesn't care how many newlines are embedded in the PICTURE.  This means
2449 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2450 You may therefore need to use multiple formlines to implement a single
2451 record format, just like the C<format> compiler.
2452
2453 Be careful if you put double quotes around the picture, because an C<@>
2454 character may be taken to mean the beginning of an array name.
2455 C<formline> always returns true.  See L<perlform> for other examples.
2456
2457 If you are trying to use this instead of C<write> to capture the output,
2458 you may find it easier to open a filehandle to a scalar
2459 (C<< open $fh, ">", \$output >>) and write to that instead.
2460
2461 =item getc FILEHANDLE
2462 X<getc> X<getchar> X<character> X<file, read>
2463
2464 =item getc
2465
2466 =for Pod::Functions get the next character from the filehandle
2467
2468 Returns the next character from the input file attached to FILEHANDLE,
2469 or the undefined value at end of file or if there was an error (in
2470 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2471 STDIN.  This is not particularly efficient.  However, it cannot be
2472 used by itself to fetch single characters without waiting for the user
2473 to hit enter.  For that, try something more like:
2474
2475     if ($BSD_STYLE) {
2476         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2477     }
2478     else {
2479         system "stty", '-icanon', 'eol', "\001";
2480     }
2481
2482     $key = getc(STDIN);
2483
2484     if ($BSD_STYLE) {
2485         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2486     }
2487     else {
2488         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2489     }
2490     print "\n";
2491
2492 Determination of whether $BSD_STYLE should be set
2493 is left as an exercise to the reader.
2494
2495 The C<POSIX::getattr> function can do this more portably on
2496 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2497 module from your nearest L<CPAN|http://www.cpan.org> site.
2498
2499 =item getlogin
2500 X<getlogin> X<login>
2501
2502 =for Pod::Functions return who logged in at this tty
2503
2504 This implements the C library function of the same name, which on most
2505 systems returns the current login from F</etc/utmp>, if any.  If it
2506 returns the empty string, use C<getpwuid>.
2507
2508     $login = getlogin || getpwuid($<) || "Kilroy";
2509
2510 Do not consider C<getlogin> for authentication: it is not as
2511 secure as C<getpwuid>.
2512
2513 Portability issues: L<perlport/getlogin>.
2514
2515 =item getpeername SOCKET
2516 X<getpeername> X<peer>
2517
2518 =for Pod::Functions find the other end of a socket connection
2519
2520 Returns the packed sockaddr address of the other end of the SOCKET
2521 connection.
2522
2523     use Socket;
2524     $hersockaddr    = getpeername(SOCK);
2525     ($port, $iaddr) = sockaddr_in($hersockaddr);
2526     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2527     $herstraddr     = inet_ntoa($iaddr);
2528
2529 =item getpgrp PID
2530 X<getpgrp> X<group>
2531
2532 =for Pod::Functions get process group
2533
2534 Returns the current process group for the specified PID.  Use
2535 a PID of C<0> to get the current process group for the
2536 current process.  Will raise an exception if used on a machine that
2537 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2538 group of the current process.  Note that the POSIX version of C<getpgrp>
2539 does not accept a PID argument, so only C<PID==0> is truly portable.
2540
2541 Portability issues: L<perlport/getpgrp>.
2542
2543 =item getppid
2544 X<getppid> X<parent> X<pid>
2545
2546 =for Pod::Functions get parent process ID
2547
2548 Returns the process id of the parent process.
2549
2550 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2551 around non-POSIX thread semantics the minority of Linux systems (and
2552 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2553 has since been removed.  See the documentation for L<$$|perlvar/$$> for
2554 details.
2555
2556 Portability issues: L<perlport/getppid>.
2557
2558 =item getpriority WHICH,WHO
2559 X<getpriority> X<priority> X<nice>
2560
2561 =for Pod::Functions get current nice value
2562
2563 Returns the current priority for a process, a process group, or a user.
2564 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2565 machine that doesn't implement getpriority(2).
2566
2567 Portability issues: L<perlport/getpriority>.
2568
2569 =item getpwnam NAME
2570 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2571 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2572 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2573 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2574 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2575 X<endnetent> X<endprotoent> X<endservent> 
2576
2577 =for Pod::Functions get passwd record given user login name
2578
2579 =item getgrnam NAME
2580
2581 =for Pod::Functions get group record given group name
2582
2583 =item gethostbyname NAME
2584
2585 =for Pod::Functions get host record given name
2586
2587 =item getnetbyname NAME
2588
2589 =for Pod::Functions get networks record given name
2590
2591 =item getprotobyname NAME
2592
2593 =for Pod::Functions get protocol record given name
2594
2595 =item getpwuid UID
2596
2597 =for Pod::Functions get passwd record given user ID
2598
2599 =item getgrgid GID
2600
2601 =for Pod::Functions get group record given group user ID
2602
2603 =item getservbyname NAME,PROTO
2604
2605 =for Pod::Functions get services record given its name
2606
2607 =item gethostbyaddr ADDR,ADDRTYPE
2608
2609 =for Pod::Functions get host record given its address
2610
2611 =item getnetbyaddr ADDR,ADDRTYPE
2612
2613 =for Pod::Functions get network record given its address
2614
2615 =item getprotobynumber NUMBER
2616
2617 =for Pod::Functions get protocol record numeric protocol
2618
2619 =item getservbyport PORT,PROTO
2620
2621 =for Pod::Functions get services record given numeric port
2622
2623 =item getpwent
2624
2625 =for Pod::Functions get next passwd record
2626
2627 =item getgrent
2628
2629 =for Pod::Functions get next group record
2630
2631 =item gethostent
2632
2633 =for Pod::Functions get next hosts record
2634
2635 =item getnetent
2636
2637 =for Pod::Functions get next networks record
2638
2639 =item getprotoent
2640
2641 =for Pod::Functions get next protocols record
2642
2643 =item getservent
2644
2645 =for Pod::Functions get next services record
2646
2647 =item setpwent
2648
2649 =for Pod::Functions prepare passwd file for use
2650
2651 =item setgrent
2652
2653 =for Pod::Functions prepare group file for use
2654
2655 =item sethostent STAYOPEN
2656
2657 =for Pod::Functions prepare hosts file for use
2658
2659 =item setnetent STAYOPEN
2660
2661 =for Pod::Functions prepare networks file for use
2662
2663 =item setprotoent STAYOPEN
2664
2665 =for Pod::Functions prepare protocols file for use
2666
2667 =item setservent STAYOPEN
2668
2669 =for Pod::Functions prepare services file for use
2670
2671 =item endpwent
2672
2673 =for Pod::Functions be done using passwd file
2674
2675 =item endgrent
2676
2677 =for Pod::Functions be done using group file
2678
2679 =item endhostent
2680
2681 =for Pod::Functions be done using hosts file
2682
2683 =item endnetent
2684
2685 =for Pod::Functions be done using networks file
2686
2687 =item endprotoent
2688
2689 =for Pod::Functions be done using protocols file
2690
2691 =item endservent
2692
2693 =for Pod::Functions be done using services file
2694
2695 These routines are the same as their counterparts in the
2696 system C library.  In list context, the return values from the
2697 various get routines are as follows:
2698
2699  # 0        1          2           3         4
2700  ( $name,   $passwd,   $gid,       $members  ) = getgr*
2701  ( $name,   $aliases,  $addrtype,  $net      ) = getnet*
2702  ( $name,   $aliases,  $port,      $proto    ) = getserv*
2703  ( $name,   $aliases,  $proto                ) = getproto*
2704  ( $name,   $aliases,  $addrtype,  $length,  @addrs ) = gethost*
2705  ( $name,   $passwd,   $uid,       $gid,     $quota,
2706  $comment,  $gcos,     $dir,       $shell,   $expire ) = getpw*
2707  # 5        6          7           8         9
2708
2709 (If the entry doesn't exist you get an empty list.)
2710
2711 The exact meaning of the $gcos field varies but it usually contains
2712 the real name of the user (as opposed to the login name) and other
2713 information pertaining to the user.  Beware, however, that in many
2714 system users are able to change this information and therefore it
2715 cannot be trusted and therefore the $gcos is tainted (see
2716 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2717 login shell, are also tainted, for the same reason.
2718
2719 In scalar context, you get the name, unless the function was a
2720 lookup by name, in which case you get the other thing, whatever it is.
2721 (If the entry doesn't exist you get the undefined value.)  For example:
2722
2723     $uid   = getpwnam($name);
2724     $name  = getpwuid($num);
2725     $name  = getpwent();
2726     $gid   = getgrnam($name);
2727     $name  = getgrgid($num);
2728     $name  = getgrent();
2729     #etc.
2730
2731 In I<getpw*()> the fields $quota, $comment, and $expire are special
2732 in that they are unsupported on many systems.  If the
2733 $quota is unsupported, it is an empty scalar.  If it is supported, it
2734 usually encodes the disk quota.  If the $comment field is unsupported,
2735 it is an empty scalar.  If it is supported it usually encodes some
2736 administrative comment about the user.  In some systems the $quota
2737 field may be $change or $age, fields that have to do with password
2738 aging.  In some systems the $comment field may be $class.  The $expire
2739 field, if present, encodes the expiration period of the account or the
2740 password.  For the availability and the exact meaning of these fields
2741 in your system, please consult getpwnam(3) and your system's 
2742 F<pwd.h> file.  You can also find out from within Perl what your
2743 $quota and $comment fields mean and whether you have the $expire field
2744 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2745 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2746 files are supported only if your vendor has implemented them in the
2747 intuitive fashion that calling the regular C library routines gets the
2748 shadow versions if you're running under privilege or if there exists
2749 the shadow(3) functions as found in System V (this includes Solaris
2750 and Linux).  Those systems that implement a proprietary shadow password
2751 facility are unlikely to be supported.
2752
2753 The $members value returned by I<getgr*()> is a space-separated list of
2754 the login names of the members of the group.
2755
2756 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2757 C, it will be returned to you via C<$?> if the function call fails.  The
2758 C<@addrs> value returned by a successful call is a list of raw
2759 addresses returned by the corresponding library call.  In the
2760 Internet domain, each address is four bytes long; you can unpack it
2761 by saying something like:
2762
2763     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2764
2765 The Socket library makes this slightly easier:
2766
2767     use Socket;
2768     $iaddr = inet_aton("127.1"); # or whatever address
2769     $name  = gethostbyaddr($iaddr, AF_INET);
2770
2771     # or going the other way
2772     $straddr = inet_ntoa($iaddr);
2773
2774 In the opposite way, to resolve a hostname to the IP address
2775 you can write this:
2776
2777     use Socket;
2778     $packed_ip = gethostbyname("www.perl.org");
2779     if (defined $packed_ip) {
2780         $ip_address = inet_ntoa($packed_ip);
2781     }
2782
2783 Make sure C<gethostbyname()> is called in SCALAR context and that
2784 its return value is checked for definedness.
2785
2786 The C<getprotobynumber> function, even though it only takes one argument,
2787 has the precedence of a list operator, so beware:
2788
2789     getprotobynumber $number eq 'icmp'   # WRONG
2790     getprotobynumber($number eq 'icmp')  # actually means this
2791     getprotobynumber($number) eq 'icmp'  # better this way
2792
2793 If you get tired of remembering which element of the return list
2794 contains which return value, by-name interfaces are provided
2795 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2796 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2797 and C<User::grent>.  These override the normal built-ins, supplying
2798 versions that return objects with the appropriate names
2799 for each field.  For example:
2800
2801    use File::stat;
2802    use User::pwent;
2803    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2804
2805 Even though it looks as though they're the same method calls (uid),
2806 they aren't, because a C<File::stat> object is different from
2807 a C<User::pwent> object.
2808
2809 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2810
2811 =item getsockname SOCKET
2812 X<getsockname>
2813
2814 =for Pod::Functions retrieve the sockaddr for a given socket
2815
2816 Returns the packed sockaddr address of this end of the SOCKET connection,
2817 in case you don't know the address because you have several different
2818 IPs that the connection might have come in on.
2819
2820     use Socket;
2821     $mysockaddr = getsockname(SOCK);
2822     ($port, $myaddr) = sockaddr_in($mysockaddr);
2823     printf "Connect to %s [%s]\n",
2824        scalar gethostbyaddr($myaddr, AF_INET),
2825        inet_ntoa($myaddr);
2826
2827 =item getsockopt SOCKET,LEVEL,OPTNAME
2828 X<getsockopt>
2829
2830 =for Pod::Functions get socket options on a given socket
2831
2832 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2833 Options may exist at multiple protocol levels depending on the socket
2834 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2835 C<Socket> module) will exist.  To query options at another level the
2836 protocol number of the appropriate protocol controlling the option
2837 should be supplied.  For example, to indicate that an option is to be
2838 interpreted by the TCP protocol, LEVEL should be set to the protocol
2839 number of TCP, which you can get using C<getprotobyname>.
2840
2841 The function returns a packed string representing the requested socket
2842 option, or C<undef> on error, with the reason for the error placed in
2843 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2844 consult getsockopt(2) for details.  A common case is that the option is an
2845 integer, in which case the result is a packed integer, which you can decode
2846 using C<unpack> with the C<i> (or C<I>) format.
2847
2848 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2849
2850     use Socket qw(:all);
2851
2852     defined(my $tcp = getprotobyname("tcp"))
2853         or die "Could not determine the protocol number for tcp";
2854     # my $tcp = IPPROTO_TCP; # Alternative
2855     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2856         or die "getsockopt TCP_NODELAY: $!";
2857     my $nodelay = unpack("I", $packed);
2858     print "Nagle's algorithm is turned ",
2859            $nodelay ? "off\n" : "on\n";
2860
2861 Portability issues: L<perlport/getsockopt>.
2862
2863 =item glob EXPR
2864 X<glob> X<wildcard> X<filename, expansion> X<expand>
2865
2866 =item glob
2867
2868 =for Pod::Functions expand filenames using wildcards
2869
2870 In list context, returns a (possibly empty) list of filename expansions on
2871 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2872 scalar context, glob iterates through such filename expansions, returning
2873 undef when the list is exhausted.  This is the internal function
2874 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2875 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2876 more detail in L<perlop/"I/O Operators">.
2877
2878 Note that C<glob> splits its arguments on whitespace and treats
2879 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2880 matches all files with a F<.c> or F<.h> extension.  The expression
2881 C<glob(".* *")> matches all files in the current working directory.
2882 If you want to glob filenames that might contain whitespace, you'll
2883 have to use extra quotes around the spacey filename to protect it.
2884 For example, to glob filenames that have an C<e> followed by a space
2885 followed by an C<f>, use either of:
2886
2887     @spacies = <"*e f*">;
2888     @spacies = glob '"*e f*"';
2889     @spacies = glob q("*e f*");
2890
2891 If you had to get a variable through, you could do this:
2892
2893     @spacies = glob "'*${var}e f*'";
2894     @spacies = glob qq("*${var}e f*");
2895
2896 If non-empty braces are the only wildcard characters used in the
2897 C<glob>, no filenames are matched, but potentially many strings
2898 are returned.  For example, this produces nine strings, one for
2899 each pairing of fruits and colors:
2900
2901     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2902
2903 This operator is implemented using the standard
2904 C<File::Glob> extension.  See L<File::Glob> for details, including
2905 C<bsd_glob> which does not treat whitespace as a pattern separator.
2906
2907 Portability issues: L<perlport/glob>.
2908
2909 =item gmtime EXPR
2910 X<gmtime> X<UTC> X<Greenwich>
2911
2912 =item gmtime
2913
2914 =for Pod::Functions convert UNIX time into record or string using Greenwich time
2915
2916 Works just like L</localtime> but the returned values are
2917 localized for the standard Greenwich time zone.
2918
2919 Note: When called in list context, $isdst, the last value
2920 returned by gmtime, is always C<0>.  There is no
2921 Daylight Saving Time in GMT.
2922
2923 Portability issues: L<perlport/gmtime>.
2924
2925 =item goto LABEL
2926 X<goto> X<jump> X<jmp>
2927
2928 =item goto EXPR
2929
2930 =item goto &NAME
2931
2932 =for Pod::Functions create spaghetti code
2933
2934 The C<goto LABEL> form finds the statement labeled with LABEL and
2935 resumes execution there.  It can't be used to get out of a block or
2936 subroutine given to C<sort>.  It can be used to go almost anywhere
2937 else within the dynamic scope, including out of subroutines, but it's
2938 usually better to use some other construct such as C<last> or C<die>.
2939 The author of Perl has never felt the need to use this form of C<goto>
2940 (in Perl, that is; C is another matter).  (The difference is that C
2941 does not offer named loops combined with loop control.  Perl does, and
2942 this replaces most structured uses of C<goto> in other languages.)
2943
2944 The C<goto EXPR> form expects to evaluate C<EXPR> to a code reference or
2945 a label name.  If it evaluates to a code reference, it will be handled
2946 like C<goto &NAME>, below.  This is especially useful for implementing
2947 tail recursion via C<goto __SUB__>.
2948
2949 If the expression evaluates to a label name, its scope will be resolved
2950 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2951 necessarily recommended if you're optimizing for maintainability:
2952
2953     goto ("FOO", "BAR", "GLARCH")[$i];
2954
2955 As shown in this example, C<goto EXPR> is exempt from the "looks like a
2956 function" rule.  A pair of parentheses following it does not (necessarily)
2957 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2958 Also, unlike most named operators, this has the same precedence as
2959 assignment.
2960
2961 Use of C<goto LABEL> or C<goto EXPR> to jump into a construct is
2962 deprecated and will issue a warning.  Even then, it may not be used to
2963 go into any construct that requires initialization, such as a
2964 subroutine or a C<foreach> loop.  It also can't be used to go into a
2965 construct that is optimized away.
2966
2967 The C<goto &NAME> form is quite different from the other forms of
2968 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2969 doesn't have the stigma associated with other gotos.  Instead, it
2970 exits the current subroutine (losing any changes set by local()) and
2971 immediately calls in its place the named subroutine using the current
2972 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2973 load another subroutine and then pretend that the other subroutine had
2974 been called in the first place (except that any modifications to C<@_>
2975 in the current subroutine are propagated to the other subroutine.)
2976 After the C<goto>, not even C<caller> will be able to tell that this
2977 routine was called first.
2978
2979 NAME needn't be the name of a subroutine; it can be a scalar variable
2980 containing a code reference or a block that evaluates to a code
2981 reference.
2982
2983 =item grep BLOCK LIST
2984 X<grep>
2985
2986 =item grep EXPR,LIST
2987
2988 =for Pod::Functions locate elements in a list test true against a given criterion
2989
2990 This is similar in spirit to, but not the same as, grep(1) and its
2991 relatives.  In particular, it is not limited to using regular expressions.
2992
2993 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2994 C<$_> to each element) and returns the list value consisting of those
2995 elements for which the expression evaluated to true.  In scalar
2996 context, returns the number of times the expression was true.
2997
2998     @foo = grep(!/^#/, @bar);    # weed out comments
2999
3000 or equivalently,
3001
3002     @foo = grep {!/^#/} @bar;    # weed out comments
3003
3004 Note that C<$_> is an alias to the list value, so it can be used to
3005 modify the elements of the LIST.  While this is useful and supported,
3006 it can cause bizarre results if the elements of LIST are not variables.
3007 Similarly, grep returns aliases into the original list, much as a for
3008 loop's index variable aliases the list elements.  That is, modifying an
3009 element of a list returned by grep (for example, in a C<foreach>, C<map>
3010 or another C<grep>) actually modifies the element in the original list.
3011 This is usually something to be avoided when writing clear code.
3012
3013 If C<$_> is lexical in the scope where the C<grep> appears (because it has
3014 been declared with the deprecated C<my $_> construct)
3015 then, in addition to being locally aliased to
3016 the list elements, C<$_> keeps being lexical inside the block; i.e., it
3017 can't be seen from the outside, avoiding any potential side-effects.
3018
3019 See also L</map> for a list composed of the results of the BLOCK or EXPR.
3020
3021 =item hex EXPR
3022 X<hex> X<hexadecimal>
3023
3024 =item hex
3025
3026 =for Pod::Functions convert a string to a hexadecimal number
3027
3028 Interprets EXPR as a hex string and returns the corresponding value.
3029 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
3030 L</oct>.)  If EXPR is omitted, uses C<$_>.
3031
3032     print hex '0xAf'; # prints '175'
3033     print hex 'aF';   # same
3034
3035 Hex strings may only represent integers.  Strings that would cause
3036 integer overflow trigger a warning.  Leading whitespace is not stripped,
3037 unlike oct().  To present something as hex, look into L</printf>,
3038 L</sprintf>, and L</unpack>.
3039
3040 =item import LIST
3041 X<import>
3042
3043 =for Pod::Functions patch a module's namespace into your own
3044
3045 There is no builtin C<import> function.  It is just an ordinary
3046 method (subroutine) defined (or inherited) by modules that wish to export
3047 names to another module.  The C<use> function calls the C<import> method
3048 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
3049
3050 =item index STR,SUBSTR,POSITION
3051 X<index> X<indexOf> X<InStr>
3052
3053 =item index STR,SUBSTR
3054
3055 =for Pod::Functions find a substring within a string
3056
3057 The index function searches for one string within another, but without
3058 the wildcard-like behavior of a full regular-expression pattern match.
3059 It returns the position of the first occurrence of SUBSTR in STR at
3060 or after POSITION.  If POSITION is omitted, starts searching from the
3061 beginning of the string.  POSITION before the beginning of the string
3062 or after its end is treated as if it were the beginning or the end,
3063 respectively.  POSITION and the return value are based at zero.
3064 If the substring is not found, C<index> returns -1.
3065
3066 =item int EXPR
3067 X<int> X<integer> X<truncate> X<trunc> X<floor>
3068
3069 =item int
3070
3071 =for Pod::Functions get the integer portion of a number
3072
3073 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
3074 You should not use this function for rounding: one because it truncates
3075 towards C<0>, and two because machine representations of floating-point
3076 numbers can sometimes produce counterintuitive results.  For example,
3077 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3078 because it's really more like -268.99999999999994315658 instead.  Usually,
3079 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
3080 functions will serve you better than will int().
3081
3082 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3083 X<ioctl>
3084
3085 =for Pod::Functions system-dependent device control system call
3086
3087 Implements the ioctl(2) function.  You'll probably first have to say
3088
3089     require "sys/ioctl.ph";  # probably in
3090                              # $Config{archlib}/sys/ioctl.ph
3091
3092 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3093 exist or doesn't have the correct definitions you'll have to roll your
3094 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3095 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3096 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3097 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3098 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
3099 has no string value but does have a numeric value, that value will be
3100 passed rather than a pointer to the string value.  To guarantee this to be
3101 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
3102 functions may be needed to manipulate the values of structures used by
3103 C<ioctl>.
3104
3105 The return value of C<ioctl> (and C<fcntl>) is as follows:
3106
3107     if OS returns:      then Perl returns:
3108         -1               undefined value
3109          0              string "0 but true"
3110     anything else           that number
3111
3112 Thus Perl returns true on success and false on failure, yet you can
3113 still easily determine the actual value returned by the operating
3114 system:
3115
3116     $retval = ioctl(...) || -1;
3117     printf "System returned %d\n", $retval;
3118
3119 The special string C<"0 but true"> is exempt from B<-w> complaints
3120 about improper numeric conversions.
3121
3122 Portability issues: L<perlport/ioctl>.
3123
3124 =item join EXPR,LIST
3125 X<join>
3126
3127 =for Pod::Functions join a list into a string using a separator
3128
3129 Joins the separate strings of LIST into a single string with fields
3130 separated by the value of EXPR, and returns that new string.  Example:
3131
3132     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3133
3134 Beware that unlike C<split>, C<join> doesn't take a pattern as its
3135 first argument.  Compare L</split>.
3136
3137 =item keys HASH
3138 X<keys> X<key>
3139
3140 =item keys ARRAY
3141
3142 =item keys EXPR
3143
3144 =for Pod::Functions retrieve list of indices from a hash
3145
3146 Called in list context, returns a list consisting of all the keys of the
3147 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3148 releases prior to 5.12 will produce a syntax error if you try to use an
3149 array argument.  In scalar context, returns the number of keys or indices.
3150
3151 Hash entries are returned in an apparently random order.  The actual random
3152 order is specific to a given hash; the exact same series of operations
3153 on two hashes may result in a different order for each hash.  Any insertion
3154 into the hash may change the order, as will any deletion, with the exception
3155 that the most recent key returned by C<each> or C<keys> may be deleted
3156 without changing the order.  So long as a given hash is unmodified you may
3157 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
3158 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
3159 details on why hash order is randomized.  Aside from the guarantees
3160 provided here the exact details of Perl's hash algorithm and the hash
3161 traversal order are subject to change in any release of Perl.  Tied hashes
3162 may behave differently to Perl's hashes with respect to changes in order on
3163 insertion and deletion of items.
3164
3165 As a side effect, calling keys() resets the internal iterator of the HASH or
3166 ARRAY (see L</each>).  In particular, calling keys() in void context resets
3167 the iterator with no other overhead.
3168
3169 Here is yet another way to print your environment:
3170
3171     @keys = keys %ENV;
3172     @values = values %ENV;
3173     while (@keys) {
3174         print pop(@keys), '=', pop(@values), "\n";
3175     }
3176
3177 or how about sorted by key:
3178
3179     foreach $key (sort(keys %ENV)) {
3180         print $key, '=', $ENV{$key}, "\n";
3181     }
3182
3183 The returned values are copies of the original keys in the hash, so
3184 modifying them will not affect the original hash.  Compare L</values>.
3185
3186 To sort a hash by value, you'll need to use a C<sort> function.
3187 Here's a descending numeric sort of a hash by its values:
3188
3189     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3190         printf "%4d %s\n", $hash{$key}, $key;
3191     }
3192
3193 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
3194 allocated for the given hash.  This can gain you a measure of efficiency if
3195 you know the hash is going to get big.  (This is similar to pre-extending
3196 an array by assigning a larger number to $#array.)  If you say
3197
3198     keys %hash = 200;
3199
3200 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3201 in fact, since it rounds up to the next power of two.  These
3202 buckets will be retained even if you do C<%hash = ()>, use C<undef
3203 %hash> if you want to free the storage while C<%hash> is still in scope.
3204 You can't shrink the number of buckets allocated for the hash using
3205 C<keys> in this way (but you needn't worry about doing this by accident,
3206 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
3207 error.
3208
3209 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
3210 a reference to an unblessed hash or array.  The argument will be
3211 dereferenced automatically.  This aspect of C<keys> is considered highly
3212 experimental.  The exact behaviour may change in a future version of Perl.
3213
3214     for (keys $hashref) { ... }
3215     for (keys $obj->get_arrayref) { ... }
3216
3217 To avoid confusing would-be users of your code who are running earlier
3218 versions of Perl with mysterious syntax errors, put this sort of thing at
3219 the top of your file to signal that your code will work I<only> on Perls of
3220 a recent vintage:
3221
3222     use 5.012;  # so keys/values/each work on arrays
3223     use 5.014;  # so keys/values/each work on scalars (experimental)
3224
3225 See also C<each>, C<values>, and C<sort>.
3226
3227 =item kill SIGNAL, LIST
3228
3229 =item kill SIGNAL
3230 X<kill> X<signal>
3231
3232 =for Pod::Functions send a signal to a process or process group
3233
3234 Sends a signal to a list of processes.  Returns the number of arguments
3235 that were successfully used to signal (which is not necessarily the same
3236 as the number of processes actually killed, e.g. where a process group is
3237 killed).
3238
3239     $cnt = kill 'HUP', $child1, $child2;
3240     kill 'KILL', @goners;
3241
3242 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3243 name may start with a C<SIG> prefix, thus C<FOO> and C<SIGFOO> refer to the
3244 same signal.  The string form of SIGNAL is recommended for portability because
3245 the same signal may have different numbers in different operating systems.
3246
3247 A list of signal names supported by the current platform can be found in
3248 C<$Config{sig_name}>, which is provided by the C<Config> module.  See L<Config>
3249 for more details.
3250
3251 A negative signal name is the same as a negative signal number, killing process
3252 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3253 C<kill -9, $pgrp> will send C<SIGKILL> to
3254 the entire process group specified.  That
3255 means you usually want to use positive not negative signals.
3256
3257 If SIGNAL is either the number 0 or the string C<ZERO> (or C<SIGZERO>),
3258 no signal is sent to
3259 the process, but C<kill> checks whether it's I<possible> to send a signal to it
3260 (that means, to be brief, that the process is owned by the same user, or we are
3261 the super-user).  This is useful to check that a child process is still
3262 alive (even if only as a zombie) and hasn't changed its UID.  See
3263 L<perlport> for notes on the portability of this construct.
3264
3265 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3266 the operating system.  For example, on POSIX-conforming systems, zero will
3267 signal the current process group, -1 will signal all processes, and any
3268 other negative PROCESS number will act as a negative signal number and
3269 kill the entire process group specified.
3270
3271 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3272 A warning may be produced in a future version.
3273
3274 See L<perlipc/"Signals"> for more details.
3275
3276 On some platforms such as Windows where the fork() system call is not
3277 available, Perl can be built to emulate fork() at the interpreter level.
3278 This emulation has limitations related to kill that have to be considered,
3279 for code running on Windows and in code intended to be portable.
3280
3281 See L<perlfork> for more details.
3282
3283 If there is no I<LIST> of processes, no signal is sent, and the return
3284 value is 0.  This form is sometimes used, however, because it causes
3285 tainting checks to be run.  But see
3286 L<perlsec/Laundering and Detecting Tainted Data>.
3287
3288 Portability issues: L<perlport/kill>.
3289
3290 =item last LABEL
3291 X<last> X<break>
3292
3293 =item last EXPR
3294
3295 =item last
3296
3297 =for Pod::Functions exit a block prematurely
3298
3299 The C<last> command is like the C<break> statement in C (as used in
3300 loops); it immediately exits the loop in question.  If the LABEL is
3301 omitted, the command refers to the innermost enclosing
3302 loop.  The C<last EXPR> form, available starting in Perl
3303 5.18.0, allows a label name to be computed at run time,
3304 and is otherwise identical to C<last LABEL>.  The
3305 C<continue> block, if any, is not executed:
3306
3307     LINE: while (<STDIN>) {
3308         last LINE if /^$/;  # exit when done with header
3309         #...
3310     }
3311
3312 C<last> cannot be used to exit a block that returns a value such as
3313 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3314 a grep() or map() operation.
3315
3316 Note that a block by itself is semantically identical to a loop
3317 that executes once.  Thus C<last> can be used to effect an early
3318 exit out of such a block.
3319
3320 See also L</continue> for an illustration of how C<last>, C<next>, and
3321 C<redo> work.
3322
3323 Unlike most named operators, this has the same precedence as assignment.
3324 It is also exempt from the looks-like-a-function rule, so
3325 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3326 C<last>.
3327
3328 =item lc EXPR
3329 X<lc> X<lowercase>
3330
3331 =item lc
3332
3333 =for Pod::Functions return lower-case version of a string
3334
3335 Returns a lowercased version of EXPR.  This is the internal function
3336 implementing the C<\L> escape in double-quoted strings.
3337
3338 If EXPR is omitted, uses C<$_>.
3339
3340 What gets returned depends on several factors:
3341
3342 =over
3343
3344 =item If C<use bytes> is in effect:
3345
3346 The results follow ASCII rules.  Only the characters C<A-Z> change,
3347 to C<a-z> respectively.
3348
3349 =item Otherwise, if C<use locale> for C<LC_CTYPE> is in effect:
3350
3351 Respects current C<LC_CTYPE> locale for code points < 256; and uses Unicode
3352 rules for the remaining code points (this last can only happen if
3353 the UTF8 flag is also set).  See L<perllocale>.
3354
3355 Starting in v5.20, Perl wil use full Unicode rules if the locale is
3356 UTF-8.  Otherwise, there is a deficiency in this scheme, which is that
3357 case changes that cross the 255/256
3358 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3359 LETTER SHARP S (U+1E9E) in Unicode rules is U+00DF (on ASCII
3360 platforms).   But under C<use locale> (prior to v5.20 or not a UTF-8
3361 locale), the lower case of U+1E9E is
3362 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3363 current locale, and Perl has no way of knowing if that character even
3364 exists in the locale, much less what code point it is.  Perl returns
3365 the input character unchanged, for all instances (and there aren't
3366 many) where the 255/256 boundary would otherwise be crossed.
3367
3368 =item Otherwise, If EXPR has the UTF8 flag set:
3369
3370 Unicode rules are used for the case change.
3371
3372 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'> is in effect:
3373
3374 Unicode rules are used for the case change.
3375
3376 =item Otherwise:
3377
3378 ASCII rules are used for the case change.  The lowercase of any character
3379 outside the ASCII range is the character itself.
3380
3381 =back
3382
3383 =item lcfirst EXPR
3384 X<lcfirst> X<lowercase>
3385
3386 =item lcfirst
3387
3388 =for Pod::Functions return a string with just the next letter in lower case
3389
3390 Returns the value of EXPR with the first character lowercased.  This
3391 is the internal function implementing the C<\l> escape in
3392 double-quoted strings.
3393
3394 If EXPR is omitted, uses C<$_>.
3395
3396 This function behaves the same way under various pragmata, such as in a locale,
3397 as L</lc> does.
3398
3399 =item length EXPR
3400 X<length> X<size>
3401
3402 =item length
3403
3404 =for Pod::Functions return the number of characters in a string
3405
3406 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3407 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3408 C<undef>.
3409
3410 This function cannot be used on an entire array or hash to find out how
3411 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3412 %hash>, respectively.
3413
3414 Like all Perl character operations, length() normally deals in logical
3415 characters, not physical bytes.  For how many bytes a string encoded as
3416 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3417 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3418
3419 =item __LINE__
3420 X<__LINE__>
3421
3422 =for Pod::Functions the current source line number
3423
3424 A special token that compiles to the current line number.
3425
3426 =item link OLDFILE,NEWFILE
3427 X<link>
3428
3429 =for Pod::Functions create a hard link in the filesystem
3430
3431 Creates a new filename linked to the old filename.  Returns true for
3432 success, false otherwise.
3433
3434 Portability issues: L<perlport/link>.
3435
3436 =item listen SOCKET,QUEUESIZE
3437 X<listen>
3438
3439 =for Pod::Functions register your socket as a server
3440
3441 Does the same thing that the listen(2) system call does.  Returns true if
3442 it succeeded, false otherwise.  See the example in
3443 L<perlipc/"Sockets: Client/Server Communication">.
3444
3445 =item local EXPR
3446 X<local>
3447
3448 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3449
3450 You really probably want to be using C<my> instead, because C<local> isn't
3451 what most people think of as "local".  See
3452 L<perlsub/"Private Variables via my()"> for details.
3453
3454 A local modifies the listed variables to be local to the enclosing
3455 block, file, or eval.  If more than one value is listed, the list must
3456 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3457 for details, including issues with tied arrays and hashes.
3458
3459 The C<delete local EXPR> construct can also be used to localize the deletion
3460 of array/hash elements to the current block.
3461 See L<perlsub/"Localized deletion of elements of composite types">.
3462
3463 =item localtime EXPR
3464 X<localtime> X<ctime>
3465
3466 =item localtime
3467
3468 =for Pod::Functions convert UNIX time into record or string using local time
3469
3470 Converts a time as returned by the time function to a 9-element list
3471 with the time analyzed for the local time zone.  Typically used as
3472 follows:
3473
3474     #  0    1    2     3     4    5     6     7     8
3475     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3476                                                 localtime(time);
3477
3478 All list elements are numeric and come straight out of the C `struct
3479 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3480 of the specified time.
3481
3482 C<$mday> is the day of the month and C<$mon> the month in
3483 the range C<0..11>, with 0 indicating January and 11 indicating December.
3484 This makes it easy to get a month name from a list:
3485
3486     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3487     print "$abbr[$mon] $mday";
3488     # $mon=9, $mday=18 gives "Oct 18"
3489
3490 C<$year> contains the number of years since 1900.  To get a 4-digit
3491 year write:
3492
3493     $year += 1900;
3494
3495 To get the last two digits of the year (e.g., "01" in 2001) do:
3496
3497     $year = sprintf("%02d", $year % 100);
3498
3499 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3500 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3501 (or C<0..365> in leap years.)
3502
3503 C<$isdst> is true if the specified time occurs during Daylight Saving
3504 Time, false otherwise.
3505
3506 If EXPR is omitted, C<localtime()> uses the current time (as returned
3507 by time(3)).
3508
3509 In scalar context, C<localtime()> returns the ctime(3) value:
3510
3511     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3512
3513 The format of this scalar value is B<not> locale-dependent
3514 but built into Perl.  For GMT instead of local
3515 time use the L</gmtime> builtin.  See also the
3516 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3517 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3518 and mktime(3) functions.
3519
3520 To get somewhat similar but locale-dependent date strings, set up your
3521 locale environment variables appropriately (please see L<perllocale>) and
3522 try for example:
3523
3524     use POSIX qw(strftime);
3525     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3526     # or for GMT formatted appropriately for your locale:
3527     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3528
3529 Note that the C<%a> and C<%b>, the short forms of the day of the week
3530 and the month of the year, may not necessarily be three characters wide.
3531
3532 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3533 by-name access mechanism to the gmtime() and localtime() functions,
3534 respectively.
3535
3536 For a comprehensive date and time representation look at the
3537 L<DateTime> module on CPAN.
3538
3539 Portability issues: L<perlport/localtime>.
3540
3541 =item lock THING
3542 X<lock>
3543
3544 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
3545
3546 This function places an advisory lock on a shared variable or referenced
3547 object contained in I<THING> until the lock goes out of scope.
3548
3549 The value returned is the scalar itself, if the argument is a scalar, or a
3550 reference, if the argument is a hash, array or subroutine.
3551
3552 lock() is a "weak keyword" : this means that if you've defined a function
3553 by this name (before any calls to it), that function will be called
3554 instead.  If you are not under C<use threads::shared> this does nothing.
3555 See L<threads::shared>.
3556
3557 =item log EXPR
3558 X<log> X<logarithm> X<e> X<ln> X<base>
3559
3560 =item log
3561
3562 =for Pod::Functions retrieve the natural logarithm for a number
3563
3564 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3565 returns the log of C<$_>.  To get the
3566 log of another base, use basic algebra:
3567 The base-N log of a number is equal to the natural log of that number
3568 divided by the natural log of N.  For example:
3569
3570     sub log10 {
3571         my $n = shift;
3572         return log($n)/log(10);
3573     }
3574
3575 See also L</exp> for the inverse operation.
3576
3577 =item lstat FILEHANDLE
3578 X<lstat>
3579
3580 =item lstat EXPR
3581
3582 =item lstat DIRHANDLE
3583
3584 =item lstat
3585
3586 =for Pod::Functions stat a symbolic link
3587
3588 Does the same thing as the C<stat> function (including setting the
3589 special C<_> filehandle) but stats a symbolic link instead of the file
3590 the symbolic link points to.  If symbolic links are unimplemented on
3591 your system, a normal C<stat> is done.  For much more detailed
3592 information, please see the documentation for C<stat>.
3593
3594 If EXPR is omitted, stats C<$_>.
3595
3596 Portability issues: L<perlport/lstat>.
3597
3598 =item m//
3599
3600 =for Pod::Functions match a string with a regular expression pattern
3601
3602 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3603
3604 =item map BLOCK LIST
3605 X<map>
3606
3607 =item map EXPR,LIST
3608
3609 =for Pod::Functions apply a change to a list to get back a new list with the changes
3610
3611 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3612 C<$_> to each element) and returns the list value composed of the
3613 results of each such evaluation.  In scalar context, returns the
3614 total number of elements so generated.  Evaluates BLOCK or EXPR in
3615 list context, so each element of LIST may produce zero, one, or
3616 more elements in the returned value.
3617
3618     @chars = map(chr, @numbers);
3619
3620 translates a list of numbers to the corresponding characters.
3621
3622     my @squares = map { $_ * $_ } @numbers;
3623
3624 translates a list of numbers to their squared values.
3625
3626     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3627
3628 shows that number of returned elements can differ from the number of
3629 input elements.  To omit an element, return an empty list ().
3630 This could also be achieved by writing
3631
3632     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3633
3634 which makes the intention more clear.
3635
3636 Map always returns a list, which can be
3637 assigned to a hash such that the elements
3638 become key/value pairs.  See L<perldata> for more details.
3639
3640     %hash = map { get_a_key_for($_) => $_ } @array;
3641
3642 is just a funny way to write
3643
3644     %hash = ();
3645     foreach (@array) {
3646         $hash{get_a_key_for($_)} = $_;
3647     }
3648
3649 Note that C<$_> is an alias to the list value, so it can be used to
3650 modify the elements of the LIST.  While this is useful and supported,
3651 it can cause bizarre results if the elements of LIST are not variables.
3652 Using a regular C<foreach> loop for this purpose would be clearer in
3653 most cases.  See also L</grep> for an array composed of those items of
3654 the original list for which the BLOCK or EXPR evaluates to true.
3655
3656 If C<$_> is lexical in the scope where the C<map> appears (because it has
3657 been declared with the deprecated C<my $_> construct),
3658 then, in addition to being locally aliased to
3659 the list elements, C<$_> keeps being lexical inside the block; that is, it
3660 can't be seen from the outside, avoiding any potential side-effects.
3661
3662 C<{> starts both hash references and blocks, so C<map { ...> could be either
3663 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3664 ahead for the closing C<}> it has to take a guess at which it's dealing with
3665 based on what it finds just after the
3666 C<{>.  Usually it gets it right, but if it
3667 doesn't it won't realize something is wrong until it gets to the C<}> and
3668 encounters the missing (or unexpected) comma.  The syntax error will be
3669 reported close to the C<}>, but you'll need to change something near the C<{>
3670 such as using a unary C<+> to give Perl some help:
3671
3672     %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
3673     %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
3674     %hash = map { ("\L$_" => 1) } @array # this also works
3675     %hash = map {  lc($_) => 1  } @array # as does this.
3676     %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
3677
3678     %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
3679
3680 or to force an anon hash constructor use C<+{>:
3681
3682     @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
3683                                            # comma at end
3684
3685 to get a list of anonymous hashes each with only one entry apiece.
3686
3687 =item mkdir FILENAME,MASK
3688 X<mkdir> X<md> X<directory, create>
3689
3690 =item mkdir FILENAME
3691
3692 =item mkdir
3693
3694 =for Pod::Functions create a directory
3695
3696 Creates the directory specified by FILENAME, with permissions
3697 specified by MASK (as modified by C<umask>).  If it succeeds it
3698 returns true; otherwise it returns false and sets C<$!> (errno).
3699 MASK defaults to 0777 if omitted, and FILENAME defaults
3700 to C<$_> if omitted.
3701
3702 In general, it is better to create directories with a permissive MASK
3703 and let the user modify that with their C<umask> than it is to supply
3704 a restrictive MASK and give the user no way to be more permissive.
3705 The exceptions to this rule are when the file or directory should be
3706 kept private (mail files, for instance).  The perlfunc(1) entry on
3707 C<umask> discusses the choice of MASK in more detail.
3708
3709 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3710 number of trailing slashes.  Some operating and filesystems do not get
3711 this right, so Perl automatically removes all trailing slashes to keep
3712 everyone happy.
3713
3714 To recursively create a directory structure, look at
3715 the C<make_path> function of the L<File::Path> module.
3716
3717 =item msgctl ID,CMD,ARG
3718 X<msgctl>
3719
3720 =for Pod::Functions SysV IPC message control operations
3721
3722 Calls the System V IPC function msgctl(2).  You'll probably have to say
3723
3724     use IPC::SysV;
3725
3726 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3727 then ARG must be a variable that will hold the returned C<msqid_ds>
3728 structure.  Returns like C<ioctl>: the undefined value for error,
3729 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3730 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3731 C<IPC::Semaphore>.
3732
3733 Portability issues: L<perlport/msgctl>.
3734
3735 =item msgget KEY,FLAGS
3736 X<msgget>
3737
3738 =for Pod::Functions get SysV IPC message queue
3739
3740 Calls the System V IPC function msgget(2).  Returns the message queue
3741 id, or C<undef> on error.  See also
3742 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3743 C<IPC::Msg>.
3744
3745 Portability issues: L<perlport/msgget>.
3746
3747 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3748 X<msgrcv>
3749
3750 =for Pod::Functions receive a SysV IPC message from a message queue
3751
3752 Calls the System V IPC function msgrcv to receive a message from
3753 message queue ID into variable VAR with a maximum message size of
3754 SIZE.  Note that when a message is received, the message type as a
3755 native long integer will be the first thing in VAR, followed by the
3756 actual message.  This packing may be opened with C<unpack("l! a*")>.
3757 Taints the variable.  Returns true if successful, false 
3758 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3759 C<IPC::SysV> and C<IPC::SysV::Msg>.
3760
3761 Portability issues: L<perlport/msgrcv>.
3762
3763 =item msgsnd ID,MSG,FLAGS
3764 X<msgsnd>
3765
3766 =for Pod::Functions send a SysV IPC message to a message queue
3767
3768 Calls the System V IPC function msgsnd to send the message MSG to the
3769 message queue ID.  MSG must begin with the native long integer message
3770 type, be followed by the length of the actual message, and then finally
3771 the message itself.  This kind of packing can be achieved with
3772 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3773 false on error.  See also the C<IPC::SysV>
3774 and C<IPC::SysV::Msg> documentation.
3775
3776 Portability issues: L<perlport/msgsnd>.
3777
3778 =item my VARLIST
3779 X<my>
3780
3781 =item my TYPE VARLIST
3782
3783 =item my VARLIST : ATTRS
3784
3785 =item my TYPE VARLIST : ATTRS
3786
3787 =for Pod::Functions declare and assign a local variable (lexical scoping)
3788
3789 A C<my> declares the listed variables to be local (lexically) to the
3790 enclosing block, file, or C<eval>.  If more than one variable is listed,
3791 the list must be placed in parentheses.
3792
3793 The exact semantics and interface of TYPE and ATTRS are still
3794 evolving.  TYPE may be a bareword, a constant declared
3795 with C<use constant>, or C<__PACKAGE__>.  It is
3796 currently bound to the use of the C<fields> pragma,
3797 and attributes are handled using the C<attributes> pragma, or starting
3798 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3799 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3800 L<attributes>, and L<Attribute::Handlers>.
3801
3802 Note that with a parenthesised list, C<undef> can be used as a dummy
3803 placeholder, for example to skip assignment of initial values:
3804
3805     my ( undef, $min, $hour ) = localtime;
3806
3807 =item next LABEL
3808 X<next> X<continue>
3809
3810 =item next EXPR
3811
3812 =item next
3813
3814 =for Pod::Functions iterate a block prematurely
3815
3816 The C<next> command is like the C<continue> statement in C; it starts
3817 the next iteration of the loop:
3818
3819     LINE: while (<STDIN>) {
3820         next LINE if /^#/;  # discard comments
3821         #...
3822     }
3823
3824 Note that if there were a C<continue> block on the above, it would get
3825 executed even on discarded lines.  If LABEL is omitted, the command
3826 refers to the innermost enclosing loop.  The C<next EXPR> form, available
3827 as of Perl 5.18.0, allows a label name to be computed at run time, being
3828 otherwise identical to C<next LABEL>.
3829
3830 C<next> cannot be used to exit a block which returns a value such as
3831 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3832 a grep() or map() operation.
3833
3834 Note that a block by itself is semantically identical to a loop
3835 that executes once.  Thus C<next> will exit such a block early.
3836
3837 See also L</continue> for an illustration of how C<last>, C<next>, and
3838 C<redo> work.
3839
3840 Unlike most named operators, this has the same precedence as assignment.
3841 It is also exempt from the looks-like-a-function rule, so
3842 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
3843 C<next>.
3844
3845 =item no MODULE VERSION LIST
3846 X<no declarations>
3847 X<unimporting>
3848
3849 =item no MODULE VERSION
3850
3851 =item no MODULE LIST
3852
3853 =item no MODULE
3854
3855 =item no VERSION
3856
3857 =for Pod::Functions unimport some module symbols or semantics at compile time
3858
3859 See the C<use> function, of which C<no> is the opposite.
3860
3861 =item oct EXPR
3862 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3863
3864 =item oct
3865
3866 =for Pod::Functions convert a string to an octal number
3867
3868 Interprets EXPR as an octal string and returns the corresponding
3869 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3870 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3871 binary string.  Leading whitespace is ignored in all three cases.)
3872 The following will handle decimal, binary, octal, and hex in standard
3873 Perl notation:
3874
3875     $val = oct($val) if $val =~ /^0/;
3876
3877 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3878 in octal), use sprintf() or printf():
3879
3880     $dec_perms = (stat("filename"))[2] & 07777;
3881     $oct_perm_str = sprintf "%o", $perms;
3882
3883 The oct() function is commonly used when a string such as C<644> needs
3884 to be converted into a file mode, for example.  Although Perl 
3885 automatically converts strings into numbers as needed, this automatic
3886 conversion assumes base 10.
3887
3888 Leading white space is ignored without warning, as too are any trailing 
3889 non-digits, such as a decimal point (C<oct> only handles non-negative
3890 integers, not negative integers or floating point).
3891
3892 =item open FILEHANDLE,EXPR
3893 X<open> X<pipe> X<file, open> X<fopen>
3894
3895 =item open FILEHANDLE,MODE,EXPR
3896
3897 =item open FILEHANDLE,MODE,EXPR,LIST
3898
3899 =item open FILEHANDLE,MODE,REFERENCE
3900
3901 =item open FILEHANDLE
3902
3903 =for Pod::Functions open a file, pipe, or descriptor
3904
3905 Opens the file whose filename is given by EXPR, and associates it with
3906 FILEHANDLE.
3907
3908 Simple examples to open a file for reading:
3909
3910     open(my $fh, "<", "input.txt") 
3911         or die "cannot open < input.txt: $!";
3912
3913 and for writing:
3914
3915     open(my $fh, ">", "output.txt") 
3916         or die "cannot open > output.txt: $!";
3917
3918 (The following is a comprehensive reference to open(): for a gentler
3919 introduction you may consider L<perlopentut>.)
3920
3921 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3922 new filehandle is autovivified, meaning that the variable is assigned a
3923 reference to a newly allocated anonymous filehandle.  Otherwise if
3924 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3925 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3926 in effect.)
3927
3928 If three (or more) arguments are specified, the open mode (including
3929 optional encoding) in the second argument are distinct from the filename in
3930 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3931 If MODE is C<< > >>, the file is opened for output, with existing files
3932 first being truncated ("clobbered") and nonexisting files newly created.
3933 If MODE is C<<< >> >>>, the file is opened for appending, again being
3934 created if necessary.
3935
3936 You can put a C<+> in front of the C<< > >> or C<< < >> to
3937 indicate that you want both read and write access to the file; thus
3938 C<< +< >> is almost always preferred for read/write updates--the 
3939 C<< +> >> mode would clobber the file first.  You can't usually use
3940 either read-write mode for updating textfiles, since they have
3941 variable-length records.  See the B<-i> switch in L<perlrun> for a
3942 better approach.  The file is created with permissions of C<0666>
3943 modified by the process's C<umask> value.
3944
3945 These various prefixes correspond to the fopen(3) modes of C<r>,
3946 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3947
3948 In the one- and two-argument forms of the call, the mode and filename
3949 should be concatenated (in that order), preferably separated by white
3950 space.  You can--but shouldn't--omit the mode in these forms when that mode
3951 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3952 the filename argument is a known literal.
3953
3954 For three or more arguments if MODE is C<|->, the filename is
3955 interpreted as a command to which output is to be piped, and if MODE
3956 is C<-|>, the filename is interpreted as a command that pipes
3957 output to us.  In the two-argument (and one-argument) form, one should
3958 replace dash (C<->) with the command.
3959 See L<perlipc/"Using open() for IPC"> for more examples of this.
3960 (You are not allowed to C<open> to a command that pipes both in I<and>
3961 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3962 L<perlipc/"Bidirectional Communication with Another Process"> for
3963 alternatives.)
3964
3965 In the form of pipe opens taking three or more arguments, if LIST is specified
3966 (extra arguments after the command name) then LIST becomes arguments
3967 to the command invoked if the platform supports it.  The meaning of
3968 C<open> with more than three arguments for non-pipe modes is not yet
3969 defined, but experimental "layers" may give extra LIST arguments
3970 meaning.
3971
3972 In the two-argument (and one-argument) form, opening C<< <- >> 
3973 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3974
3975 You may (and usually should) use the three-argument form of open to specify
3976 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3977 that affect how the input and output are processed (see L<open> and
3978 L<PerlIO> for more details).  For example:
3979
3980   open(my $fh, "<:encoding(UTF-8)", "filename")
3981     || die "can't open UTF-8 encoded filename: $!";
3982
3983 opens the UTF8-encoded file containing Unicode characters;
3984 see L<perluniintro>.  Note that if layers are specified in the
3985 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3986 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3987 Those layers will also be ignored if you specifying a colon with no name
3988 following it.  In that case the default layer for the operating system
3989 (:raw on Unix, :crlf on Windows) is used.
3990
3991 Open returns nonzero on success, the undefined value otherwise.  If
3992 the C<open> involved a pipe, the return value happens to be the pid of
3993 the subprocess.
3994
3995 If you're running Perl on a system that distinguishes between text
3996 files and binary files, then you should check out L</binmode> for tips
3997 for dealing with this.  The key distinction between systems that need
3998 C<binmode> and those that don't is their text file formats.  Systems
3999 like Unix, Mac OS, and Plan 9, that end lines with a single
4000 character and encode that character in C as C<"\n"> do not
4001 need C<binmode>.  The rest need it.
4002
4003 When opening a file, it's seldom a good idea to continue 
4004 if the request failed, so C<open> is frequently used with
4005 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
4006 where you want to format a suitable error message (but there are
4007 modules that can help with that problem)) always check
4008 the return value from opening a file.  
4009
4010 The filehandle will be closed when its reference count reaches zero.
4011 If it is a lexically scoped variable declared with C<my>, that usually
4012 means the end of the enclosing scope.  However, this automatic close
4013 does not check for errors, so it is better to explicitly close
4014 filehandles, especially those used for writing:
4015
4016     close($handle)
4017        || warn "close failed: $!";
4018
4019 An older style is to use a bareword as the filehandle, as
4020
4021     open(FH, "<", "input.txt")
4022        or die "cannot open < input.txt: $!";
4023
4024 Then you can use C<FH> as the filehandle, in C<< close FH >> and C<<
4025 <FH> >> and so on.  Note that it's a global variable, so this form is
4026 not recommended in new code.
4027
4028 As a shortcut a one-argument call takes the filename from the global
4029 scalar variable of the same name as the filehandle:
4030
4031     $ARTICLE = 100;
4032     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
4033
4034 Here C<$ARTICLE> must be a global (package) scalar variable - not one
4035 declared with C<my> or C<state>.
4036
4037 As a special case the three-argument form with a read/write mode and the third
4038 argument being C<undef>:
4039
4040     open(my $tmp, "+>", undef) or die ...
4041
4042 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
4043 works for symmetry, but you really should consider writing something
4044 to the temporary file first.  You will need to seek() to do the
4045 reading.
4046
4047 Perl is built using PerlIO by default; Unless you've
4048 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
4049 open filehandles directly to Perl scalars via:
4050
4051     open($fh, ">", \$variable) || ..
4052
4053 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
4054
4055     close STDOUT;
4056     open(STDOUT, ">", \$variable)
4057         or die "Can't open STDOUT: $!";
4058
4059 General examples:
4060
4061     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
4062     # if the open fails, output is discarded
4063
4064     open(my $dbase, "+<", "dbase.mine")      # open for update
4065         or die "Can't open 'dbase.mine' for update: $!";
4066
4067     open(my $dbase, "+<dbase.mine")          # ditto
4068         or die "Can't open 'dbase.mine' for update: $!";
4069
4070     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
4071         or die "Can't start caesar: $!";
4072
4073     open(ARTICLE, "caesar <$article |")      # ditto
4074         or die "Can't start caesar: $!";
4075
4076     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
4077         or die "Can't start sort: $!";
4078
4079     # in-memory files
4080     open(MEMORY, ">", \$var)
4081         or die "Can't open memory file: $!";
4082     print MEMORY "foo!\n";              # output will appear in $var
4083
4084     # process argument list of files along with any includes
4085
4086     foreach $file (@ARGV) {
4087         process($file, "fh00");
4088     }
4089
4090     sub process {
4091         my($filename, $input) = @_;
4092         $input++;    # this is a string increment
4093         unless (open($input, "<", $filename)) {
4094             print STDERR "Can't open $filename: $!\n";
4095             return;
4096         }
4097
4098         local $_;
4099         while (<$input>) {    # note use of indirection
4100             if (/^#include "(.*)"/) {
4101                 process($1, $input);
4102                 next;
4103             }
4104             #...          # whatever
4105         }
4106     }
4107
4108 See L<perliol> for detailed info on PerlIO.
4109
4110 You may also, in the Bourne shell tradition, specify an EXPR beginning
4111 with C<< >& >>, in which case the rest of the string is interpreted
4112 as the name of a filehandle (or file descriptor, if numeric) to be
4113 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4114 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4115 The mode you specify should match the mode of the original filehandle.
4116 (Duping a filehandle does not take into account any existing contents
4117 of IO buffers.)  If you use the three-argument
4118 form, then you can pass either a
4119 number, the name of a filehandle, or the normal "reference to a glob".
4120
4121 Here is a script that saves, redirects, and restores C<STDOUT> and
4122 C<STDERR> using various methods:
4123
4124     #!/usr/bin/perl
4125     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4126     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4127
4128     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4129     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4130
4131     select STDERR; $| = 1;  # make unbuffered
4132     select STDOUT; $| = 1;  # make unbuffered
4133
4134     print STDOUT "stdout 1\n";  # this works for
4135     print STDERR "stderr 1\n";  # subprocesses too
4136
4137     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4138     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4139
4140     print STDOUT "stdout 2\n";
4141     print STDERR "stderr 2\n";
4142
4143 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4144 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
4145 that file descriptor (and not call C<dup(2)>); this is more
4146 parsimonious of file descriptors.  For example:
4147
4148     # open for input, reusing the fileno of $fd
4149     open(FILEHANDLE, "<&=$fd")
4150
4151 or
4152
4153     open(FILEHANDLE, "<&=", $fd)
4154
4155 or
4156
4157     # open for append, using the fileno of OLDFH
4158     open(FH, ">>&=", OLDFH)
4159
4160 or
4161
4162     open(FH, ">>&=OLDFH")
4163
4164 Being parsimonious on filehandles is also useful (besides being
4165 parsimonious) for example when something is dependent on file
4166 descriptors, like for example locking using flock().  If you do just
4167 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
4168 descriptor as B, and therefore flock(A) will not flock(B) nor vice
4169 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
4170 the same underlying system file descriptor.
4171
4172 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4173 fdopen() to implement the C<=> functionality.  On many Unix systems,
4174 fdopen() fails when file descriptors exceed a certain value, typically 255.
4175 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4176
4177 You can see whether your Perl was built with PerlIO by running C<perl -V>
4178 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
4179 have PerlIO; otherwise you don't.
4180
4181 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4182 with the one- or two-argument forms of C<open>), 
4183 an implicit C<fork> is done, so C<open> returns twice: in the parent
4184 process it returns the pid
4185 of the child process, and in the child process it returns (a defined) C<0>.
4186 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4187
4188 For example, use either
4189
4190     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
4191
4192 or
4193
4194     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
4195
4196 followed by 
4197
4198     if ($child_pid) {
4199         # am the parent:
4200         # either write TO_KID or else read FROM_KID
4201         ...
4202        waitpid $child_pid, 0;
4203     } else {
4204         # am the child; use STDIN/STDOUT normally
4205         ...
4206         exit;
4207     } 
4208
4209 The filehandle behaves normally for the parent, but I/O to that
4210 filehandle is piped from/to the STDOUT/STDIN of the child process.
4211 In the child process, the filehandle isn't opened--I/O happens from/to
4212 the new STDOUT/STDIN.  Typically this is used like the normal
4213 piped open when you want to exercise more control over just how the
4214 pipe command gets executed, such as when running setuid and
4215 you don't want to have to scan shell commands for metacharacters.
4216
4217 The following blocks are more or less equivalent:
4218
4219     open(FOO, "|tr '[a-z]' '[A-Z]'");
4220     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
4221     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4222     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
4223
4224     open(FOO, "cat -n '$file'|");
4225     open(FOO, "-|", "cat -n '$file'");
4226     open(FOO, "-|") || exec "cat", "-n", $file;
4227     open(FOO, "-|", "cat", "-n", $file);
4228
4229 The last two examples in each block show the pipe as "list form", which is
4230 not yet supported on all platforms.  A good rule of thumb is that if
4231 your platform has a real C<fork()> (in other words, if your platform is
4232 Unix, including Linux and MacOS X), you can use the list form.  You would 
4233 want to use the list form of the pipe so you can pass literal arguments
4234 to the command without risk of the shell interpreting any shell metacharacters
4235 in them.  However, this also bars you from opening pipes to commands
4236 that intentionally contain shell metacharacters, such as:
4237
4238     open(FOO, "|cat -n | expand -4 | lpr")
4239         // die "Can't open pipeline to lpr: $!";
4240
4241 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
4242
4243 Perl will attempt to flush all files opened for
4244 output before any operation that may do a fork, but this may not be
4245 supported on some platforms (see L<perlport>).  To be safe, you may need
4246 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
4247 of C<IO::Handle> on any open handles.
4248
4249 On systems that support a close-on-exec flag on files, the flag will
4250 be set for the newly opened file descriptor as determined by the value
4251 of C<$^F>.  See L<perlvar/$^F>.
4252
4253 Closing any piped filehandle causes the parent process to wait for the
4254 child to finish, then returns the status value in C<$?> and
4255 C<${^CHILD_ERROR_NATIVE}>.
4256
4257 The filename passed to the one- and two-argument forms of open() will
4258 have leading and trailing whitespace deleted and normal
4259 redirection characters honored.  This property, known as "magic open",
4260 can often be used to good effect.  A user could specify a filename of
4261 F<"rsh cat file |">, or you could change certain filenames as needed:
4262
4263     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
4264     open(FH, $filename) or die "Can't open $filename: $!";
4265
4266 Use the three-argument form to open a file with arbitrary weird characters in it,
4267
4268     open(FOO, "<", $file)
4269         || die "can't open < $file: $!";
4270
4271 otherwise it's necessary to protect any leading and trailing whitespace:
4272
4273     $file =~ s#^(\s)#./$1#;
4274     open(FOO, "< $file\0")
4275         || die "open failed: $!";
4276
4277 (this may not work on some bizarre filesystems).  One should
4278 conscientiously choose between the I<magic> and I<three-argument> form
4279 of open():
4280
4281     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
4282
4283 will allow the user to specify an argument of the form C<"rsh cat file |">,
4284 but will not work on a filename that happens to have a trailing space, while
4285
4286     open(IN, "<", $ARGV[0])
4287         || die "can't open < $ARGV[0]: $!";
4288
4289 will have exactly the opposite restrictions.
4290
4291 If you want a "real" C C<open> (see L<open(2)> on your system), then you
4292 should use the C<sysopen> function, which involves no such magic (but may
4293 use subtly different filemodes than Perl open(), which is mapped to C
4294 fopen()).  This is another way to protect your filenames from
4295 interpretation.  For example:
4296
4297     use IO::Handle;
4298     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
4299         or die "sysopen $path: $!";
4300     $oldfh = select(HANDLE); $| = 1; select($oldfh);
4301     print HANDLE "stuff $$\n";
4302     seek(HANDLE, 0, 0);
4303     print "File contains: ", <HANDLE>;
4304
4305 See L</seek> for some details about mixing reading and writing.
4306
4307 Portability issues: L<perlport/open>.
4308
4309 =item opendir DIRHANDLE,EXPR
4310 X<opendir>
4311
4312 =for Pod::Functions open a directory
4313
4314 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
4315 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
4316 DIRHANDLE may be an expression whose value can be used as an indirect
4317 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
4318 scalar variable (or array or hash element), the variable is assigned a
4319 reference to a new anonymous dirhandle; that is, it's autovivified.
4320 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
4321
4322 See the example at C<readdir>.
4323
4324 =item ord EXPR
4325 X<ord> X<encoding>
4326
4327 =item ord
4328
4329 =for Pod::Functions find a character's numeric representation
4330
4331 Returns the numeric value of the first character of EXPR.
4332 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
4333 (Note I<character>, not byte.)
4334
4335 For the reverse, see L</chr>.
4336 See L<perlunicode> for more about Unicode.
4337
4338 =item our VARLIST
4339 X<our> X<global>
4340
4341 =item our TYPE VARLIST
4342
4343 =item our VARLIST : ATTRS
4344
4345 =item our TYPE VARLIST : ATTRS
4346
4347 =for Pod::Functions +5.6.0 declare and assign a package variable (lexical scoping)
4348
4349 C<our> makes a lexical alias to a package (i.e. global) variable of the
4350 same name in the current package for use within the current lexical scope.
4351
4352 C<our> has the same scoping rules as C<my> or C<state>, meaning that it is
4353 only valid within a lexical scope.  Unlike C<my> and C<state>, which both
4354 declare new (lexical) variables, C<our> only creates an alias to an
4355 existing variable: a package variable of the same name.
4356
4357 This means that when C<use strict 'vars'> is in effect, C<our> lets you use
4358 a package variable without qualifying it with the package name, but only within
4359 the lexical scope of the C<our> declaration.
4360
4361     package Foo;
4362     use strict;
4363
4364     $Foo::foo = 23;
4365
4366     {
4367         our $foo;   # alias to $Foo::foo
4368         print $foo; # prints 23
4369     }
4370
4371     print $Foo::foo; # prints 23
4372
4373     print $foo; # ERROR: requires explicit package name
4374
4375 This works even if the package variable has not been used before, as
4376 package variables spring into existence when first used.
4377
4378     package Foo;
4379     use strict;
4380
4381     our $foo = 23;   # just like $Foo::foo = 23
4382
4383     print $Foo::foo; # prints 23
4384
4385 If more than one variable is listed, the list must be placed
4386 in parentheses.
4387
4388     our($bar, $baz);
4389
4390 An C<our> declaration declares an alias for a package variable that will be visible
4391 across its entire lexical scope, even across package boundaries.  The
4392 package in which the variable is entered is determined at the point
4393 of the declaration, not at the point of use.  This means the following
4394 behavior holds:
4395
4396     package Foo;
4397     our $bar;      # declares $Foo::bar for rest of lexical scope
4398     $bar = 20;
4399
4400     package Bar;
4401     print $bar;    # prints 20, as it refers to $Foo::bar
4402
4403 Multiple C<our> declarations with the same name in the same lexical
4404 scope are allowed if they are in different packages.  If they happen
4405 to be in the same package, Perl will emit warnings if you have asked
4406 for them, just like multiple C<my> declarations.  Unlike a second
4407 C<my> declaration, which will bind the name to a fresh variable, a
4408 second C<our> declaration in the same package, in the same scope, is
4409 merely redundant.
4410
4411     use warnings;
4412     package Foo;
4413     our $bar;      # declares $Foo::bar for rest of lexical scope
4414     $bar = 20;
4415
4416     package Bar;
4417     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4418     print $bar;    # prints 30
4419
4420     our $bar;      # emits warning but has no other effect
4421     print $bar;    # still prints 30
4422
4423 An C<our> declaration may also have a list of attributes associated
4424 with it.
4425
4426 The exact semantics and interface of TYPE and ATTRS are still
4427 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4428 and attributes are handled using the C<attributes> pragma, or, starting
4429 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4430 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4431 L<attributes>, and L<Attribute::Handlers>.
4432
4433 Note that with a parenthesised list, C<undef> can be used as a dummy
4434 placeholder, for example to skip assignment of initial values:
4435
4436     our ( undef, $min, $hour ) = localtime;
4437
4438 C<our> differs from C<use vars>, which allows use of an unqualified name
4439 I<only> within the affected package, but across scopes.
4440
4441 =item pack TEMPLATE,LIST
4442 X<pack>
4443
4444 =for Pod::Functions convert a list into a binary representation
4445
4446 Takes a LIST of values and converts it into a string using the rules
4447 given by the TEMPLATE.  The resulting string is the concatenation of
4448 the converted values.  Typically, each converted value looks
4449 like its machine-level representation.  For example, on 32-bit machines
4450 an integer may be represented by a sequence of 4 bytes, which  will in
4451 Perl be presented as a string that's 4 characters long. 
4452
4453 See L<perlpacktut> for an introduction to this function.
4454
4455 The TEMPLATE is a sequence of characters that give the order and type
4456 of values, as follows:
4457
4458     a  A string with arbitrary binary data, will be null padded.
4459     A  A text (ASCII) string, will be space padded.
4460     Z  A null-terminated (ASCIZ) string, will be null padded.
4461
4462     b  A bit string (ascending bit order inside each byte,
4463        like vec()).
4464     B  A bit string (descending bit order inside each byte).
4465     h  A hex string (low nybble first).
4466     H  A hex string (high nybble first).
4467
4468     c  A signed char (8-bit) value.
4469     C  An unsigned char (octet) value.
4470     W  An unsigned char value (can be greater than 255).
4471
4472     s  A signed short (16-bit) value.
4473     S  An unsigned short value.
4474
4475     l  A signed long (32-bit) value.
4476     L  An unsigned long value.
4477
4478     q  A signed quad (64-bit) value.
4479     Q  An unsigned quad value.
4480          (Quads are available only if your system supports 64-bit
4481           integer values _and_ if Perl has been compiled to support
4482           those.  Raises an exception otherwise.)
4483
4484     i  A signed integer value.
4485     I  A unsigned integer value.
4486          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4487           size depends on what a local C compiler calls 'int'.)
4488
4489     n  An unsigned short (16-bit) in "network" (big-endian) order.
4490     N  An unsigned long (32-bit) in "network" (big-endian) order.
4491     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4492     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4493
4494     j  A Perl internal signed integer value (IV).
4495     J  A Perl internal unsigned integer value (UV).
4496
4497     f  A single-precision float in native format.
4498     d  A double-precision float in native format.
4499
4500     F  A Perl internal floating-point value (NV) in native format
4501     D  A float of long-double precision in native format.
4502          (Long doubles are available only if your system supports
4503           long double values _and_ if Perl has been compiled to
4504           support those.  Raises an exception otherwise.)
4505
4506     p  A pointer to a null-terminated string.
4507     P  A pointer to a structure (fixed-length string).
4508
4509     u  A uuencoded string.
4510     U  A Unicode character number.  Encodes to a character in char-
4511        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4512        byte mode.
4513
4514     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4515        for details).  Its bytes represent an unsigned integer in
4516        base 128, most significant digit first, with as few digits
4517        as possible.  Bit eight (the high bit) is set on each byte
4518        except the last.
4519
4520     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4521     X  Back up a byte.
4522     @  Null-fill or truncate to absolute position, counted from the
4523        start of the innermost ()-group.
4524     .  Null-fill or truncate to absolute position specified by
4525        the value.
4526     (  Start of a ()-group.
4527
4528 One or more modifiers below may optionally follow certain letters in the
4529 TEMPLATE (the second column lists letters for which the modifier is valid):
4530
4531     !   sSlLiI     Forces native (short, long, int) sizes instead
4532                    of fixed (16-/32-bit) sizes.
4533
4534     !   xX         Make x and X act as alignment commands.
4535
4536     !   nNvV       Treat integers as signed instead of unsigned.
4537
4538     !   @.         Specify position as byte offset in the internal
4539                    representation of the packed string.  Efficient
4540                    but dangerous.
4541
4542     >   sSiIlLqQ   Force big-endian byte-order on the type.
4543         jJfFdDpP   (The "big end" touches the construct.)
4544
4545     <   sSiIlLqQ   Force little-endian byte-order on the type.
4546         jJfFdDpP   (The "little end" touches the construct.)
4547
4548 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4549 to force a particular byte-order on all components in that group, 
4550 including all its subgroups.
4551
4552 =begin comment
4553
4554 Larry recalls that the hex and bit string formats (H, h, B, b) were added to
4555 pack for processing data from NASA's Magellan probe.  Magellan was in an
4556 elliptical orbit, using the antenna for the radar mapping when close to
4557 Venus and for communicating data back to Earth for the rest of the orbit.
4558 There were two transmission units, but one of these failed, and then the
4559 other developed a fault whereby it would randomly flip the sense of all the
4560 bits. It was easy to automatically detect complete records with the correct
4561 sense, and complete records with all the bits flipped. However, this didn't
4562 recover the records where the sense flipped midway. A colleague of Larry's
4563 was able to pretty much eyeball where the records flipped, so they wrote an
4564 editor named kybble (a pun on the dog food Kibbles 'n Bits) to enable him to
4565 manually correct the records and recover the data. For this purpose pack
4566 gained the hex and bit string format specifiers.
4567
4568 git shows that they were added to perl 3.0 in patch #44 (Jan 1991, commit
4569 27e2fb84680b9cc1), but the patch description makes no mention of their
4570 addition, let alone the story behind them.
4571
4572 =end comment
4573
4574 The following rules apply:
4575
4576 =over 
4577
4578 =item *
4579
4580 Each letter may optionally be followed by a number indicating the repeat
4581 count.  A numeric repeat count may optionally be enclosed in brackets, as
4582 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4583 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4584 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4585 something else, described below.  Supplying a C<*> for the repeat count
4586 instead of a number means to use however many items are left, except for:
4587
4588 =over 
4589
4590 =item * 
4591
4592 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4593
4594 =item * 
4595
4596 <.>, where it means relative to the start of the string.
4597
4598 =item * 
4599
4600 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4601
4602 =back 
4603
4604 One can replace a numeric repeat count with a template letter enclosed in
4605 brackets to use the packed byte length of the bracketed template for the
4606 repeat count.
4607
4608 For example, the template C<x[L]> skips as many bytes as in a packed long,
4609 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4610 variable-expanded) unpacks.  If the template in brackets contains alignment
4611 commands (such as C<x![d]>), its packed length is calculated as if the
4612 start of the template had the maximal possible alignment.
4613
4614 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4615 trailing null byte, so the resulting string is always one byte longer than
4616 the byte length of the item itself.
4617
4618 When used with C<@>, the repeat count represents an offset from the start
4619 of the innermost C<()> group.
4620
4621 When used with C<.>, the repeat count determines the starting position to
4622 calculate the value offset as follows:
4623
4624 =over 
4625
4626 =item *
4627
4628 If the repeat count is C<0>, it's relative to the current position.
4629
4630 =item *
4631
4632 If the repeat count is C<*>, the offset is relative to the start of the
4633 packed string.
4634
4635 =item *
4636
4637 And if it's an integer I<n>, the offset is relative to the start of the
4638 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4639 bigger then the group level.
4640
4641 =back
4642
4643 The repeat count for C<u> is interpreted as the maximal number of bytes
4644 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4645 count should not be more than 65.
4646
4647 =item *
4648
4649 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4650 string of length count, padding with nulls or spaces as needed.  When
4651 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4652 after the first null, and C<a> returns data with no stripping at all.
4653
4654 If the value to pack is too long, the result is truncated.  If it's too
4655 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4656 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4657 when the count is 0.
4658
4659 =item *
4660
4661 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4662 Each such format generates 1 bit of the result.  These are typically followed
4663 by a repeat count like C<B8> or C<B64>.
4664
4665 Each result bit is based on the least-significant bit of the corresponding
4666 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4667 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4668
4669 Starting from the beginning of the input string, each 8-tuple
4670 of characters is converted to 1 character of output.  With format C<b>,
4671 the first character of the 8-tuple determines the least-significant bit of a
4672 character; with format C<B>, it determines the most-significant bit of
4673 a character.
4674
4675 If the length of the input string is not evenly divisible by 8, the
4676 remainder is packed as if the input string were padded by null characters
4677 at the end.  Similarly during unpacking, "extra" bits are ignored.
4678
4679 If the input string is longer than needed, remaining characters are ignored.
4680
4681 A C<*> for the repeat count uses all characters of the input field.  
4682 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4683
4684 =item *
4685
4686 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4687 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4688
4689 For each such format, pack() generates 4 bits of result.
4690 With non-alphabetical characters, the result is based on the 4 least-significant
4691 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4692 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4693 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result