This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlre: Italicize a bunch of stuff
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a tutorial introduction
11 is available in L<perlretut>.  If you know just a little about them,
12 a quick-start introduction is available in L<perlrequick>.
13
14 Except for L</The Basics> section, this page assumes you are familiar
15 with regular expression basics, like what is a "pattern", what does it
16 look like, and how it is basically used.  For a reference on how they
17 are used, plus various examples of the same, see discussions of C<m//>,
18 C<s///>, C<qr//> and C<"??"> in L<perlop/"Regexp Quote-Like Operators">.
19
20 New in v5.22, L<C<use re 'strict'>|re/'strict' mode> applies stricter
21 rules than otherwise when compiling regular expression patterns.  It can
22 find things that, while legal, may not be what you intended.
23
24 =head2 The Basics
25 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
26
27 Regular expressions are strings with the very particular syntax and
28 meaning described in this document and auxiliary documents referred to
29 by this one.  The strings are called "patterns".  Patterns are used to
30 determine if some other string, called the "target", has (or doesn't
31 have) the characteristics specified by the pattern.  We call this
32 "matching" the target string against the pattern.  Usually the match is
33 done by having the target be the first operand, and the pattern be the
34 second operand, of one of the two binary operators C<=~> and C<!~>,
35 listed in L<perlop/Binding Operators>; and the pattern will have been
36 converted from an ordinary string by one of the operators in
37 L<perlop/"Regexp Quote-Like Operators">, like so:
38
39  $foo =~ m/abc/
40
41 This evaluates to true if and only if the string in the variable C<$foo>
42 contains somewhere in it, the sequence of characters "a", "b", then "c".
43 (The C<=~ m>, or match operator, is described in
44 L<perlop/m/PATTERN/msixpodualngc>.)
45
46 Patterns that aren't already stored in some variable must be delimitted,
47 at both ends, by delimitter characters.  These are often, as in the
48 example above, forward slashes, and the typical way a pattern is written
49 in documentation is with those slashes.  In most cases, the delimitter
50 is the same character, fore and aft, but there are a few cases where a
51 character looks like it has a mirror-image mate, where the opening
52 version is the beginning delimiter, and the closing one is the ending
53 delimiter, like
54
55  $foo =~ m<abc>
56
57 Most times, the pattern is evaluated in double-quotish context, but it
58 is possible to choose delimiters to force single-quotish, like
59
60  $foo =~ m'abc'
61
62 If the pattern contains its delimiter within it, that delimiter must be
63 escaped.  Prefixing it with a backslash (I<e.g.>, C<"/foo\/bar/">)
64 serves this purpose.
65
66 Any single character in a pattern matches that same character in the
67 target string, unless the character is a I<metacharacter> with a special
68 meaning described in this document.  A sequence of non-metacharacters
69 matches the same sequence in the target string, as we saw above with
70 C<m/abc/>.
71
72 Only a few characters (all of them being ASCII punctuation characters)
73 are metacharacters.  The most commonly used one is a dot C<".">, which
74 normally matches almost any character (including a dot itself).
75
76 You can cause characters that normally function as metacharacters to be
77 interpreted literally by prefixing them with a C<"\">, just like the
78 pattern's delimiter must be escaped if it also occurs within the
79 pattern.  Thus, C<"\."> matches just a literal dot, C<"."> instead of
80 its normal meaning.  This means that the backslash is also a
81 metacharacter, so C<"\\"> matches a single C<"\">.  And a sequence that
82 contains an escaped metacharacter matches the same sequence (but without
83 the escape) in the target string.  So, the pattern C</blur\\fl/> would
84 match any target string that contains the sequence C<"blur\fl">.
85
86 The metacharacter C<"|"> is used to match one thing or another.  Thus
87
88  $foo =~ m/this|that/
89
90 is TRUE if and only if C<$foo> contains either the sequence C<"this"> or
91 the sequence C<"that">.  Like all metacharacters, prefixing the C<"|">
92 with a backslash makes it match the plain punctuation character; in its
93 case, the VERTICAL LINE.
94
95  $foo =~ m/this\|that/
96
97 is TRUE if and only if C<$foo> contains the sequence C<"this|that">.
98
99 You aren't limited to just a single C<"|">.
100
101  $foo =~ m/fee|fie|foe|fum/
102
103 is TRUE if and only if C<$foo> contains any of those 4 sequences from
104 the children's story "Jack and the Beanstalk".
105
106 As you can see, the C<"|"> binds less tightly than a sequence of
107 ordinary characters.  We can override this by using the grouping
108 metacharacters, the parentheses C<"("> and C<")">.
109
110  $foo =~ m/th(is|at) thing/
111
112 is TRUE if and only if C<$foo> contains either the sequence S<C<"this
113 thing">> or the sequence S<C<"that thing">>.  The portions of the string
114 that match the portions of the pattern enclosed in parentheses are
115 normally made available separately for use later in the pattern,
116 substitution, or program.  This is called "capturing", and it can get
117 complicated.  See L</Capture groups>.
118
119 The first alternative includes everything from the last pattern
120 delimiter (C<"(">, C<"(?:"> (described later), I<etc>. or the beginning
121 of the pattern) up to the first C<"|">, and the last alternative
122 contains everything from the last C<"|"> to the next closing pattern
123 delimiter.  That's why it's common practice to include alternatives in
124 parentheses: to minimize confusion about where they start and end.
125
126 Alternatives are tried from left to right, so the first
127 alternative found for which the entire expression matches, is the one that
128 is chosen. This means that alternatives are not necessarily greedy. For
129 example: when matching C<foo|foot> against C<"barefoot">, only the C<"foo">
130 part will match, as that is the first alternative tried, and it successfully
131 matches the target string. (This might not seem important, but it is
132 important when you are capturing matched text using parentheses.)
133
134 Besides taking away the special meaning of a metacharacter, a prefixed
135 backslash changes some letter and digit characters away from matching
136 just themselves to instead have special meaning.  These are called
137 "escape sequences", and all such are described in L<perlrebackslash>.  A
138 backslash sequence (of a letter or digit) that doesn't currently have
139 special meaning to Perl will raise a warning if warnings are enabled,
140 as those are reserved for potential future use.
141
142 One such sequence is C<\b>, which matches a boundary of some sort.
143 C<\b{wb}> and a few others give specialized types of boundaries.
144 (They are all described in detail starting at
145 L<perlrebackslash/\b{}, \b, \B{}, \B>.)  Note that these don't match
146 characters, but the zero-width spaces between characters.  They are an
147 example of a L<zero-width assertion|/Assertions>.  Consider again,
148
149  $foo =~ m/fee|fie|foe|fum/
150
151 It evaluates to TRUE if, besides those 4 words, any of the sequences
152 "feed", "field", "Defoe", "fume", and many others are in C<$foo>.  By
153 judicious use of C<\b> (or better (because it is designed to handle
154 natural language) C<\b{wb}>), we can make sure that only the Giant's
155 words are matched:
156
157  $foo =~ m/\b(fee|fie|foe|fum)\b/
158  $foo =~ m/\b{wb}(fee|fie|foe|fum)\b{wb}/
159
160 The final example shows that the characters C<"{"> and C<"}"> are
161 metacharacters.
162
163 Another use for escape sequences is to specify characters that cannot
164 (or which you prefer not to) be written literally.  These are described
165 in detail in L<perlrebackslash/Character Escapes>, but the next three
166 paragraphs briefly describe some of them.
167
168 Various control characters can be written in C language style: C<"\n">
169 matches a newline, C<"\t"> a tab, C<"\r"> a carriage return, C<"\f"> a
170 form feed, I<etc>.
171
172 More generally, C<\I<nnn>>, where I<nnn> is a string of three octal
173 digits, matches the character whose native code point is I<nnn>.  You
174 can easily run into trouble if you don't have exactly three digits.  So
175 always use three, or since Perl 5.14, you can use C<\o{...}> to specify
176 any number of octal digits.
177
178 Similarly, C<\xI<nn>>, where I<nn> are hexadecimal digits, matches the
179 character whose native ordinal is I<nn>.  Again, not using exactly two
180 digits is a recipe for disaster, but you can use C<\x{...}> to specify
181 any number of hex digits.
182
183 Besides being a metacharacter, the C<"."> is an example of a "character
184 class", something that can match any single character of a given set of
185 them.  In its case, the set is just about all possible characters.  Perl
186 predefines several character classes besides the C<".">; there is a
187 separate reference page about just these, L<perlrecharclass>.
188
189 You can define your own custom character classes, by putting into your
190 pattern in the appropriate place(s), a list of all the characters you
191 want in the set.  You do this by enclosing the list within C<[]> bracket
192 characters.  These are called "bracketed character classes" when we are
193 being precise, but often the word "bracketed" is dropped.  (Dropping it
194 usually doesn't cause confusion.)  This means that the C<"["> character
195 is another metacharacter.  It doesn't match anything just by itself; it
196 is used only to tell Perl that what follows it is a bracketed character
197 class.  If you want to match a literal left square bracket, you must
198 escape it, like C<"\[">.  The matching C<"]"> is also a metacharacter;
199 again it doesn't match anything by itself, but just marks the end of
200 your custom class to Perl.  It is an example of a "sometimes
201 metacharacter".  It isn't a metacharacter if there is no corresponding
202 C<"[">, and matches its literal self:
203
204  print "]" =~ /]/;  # prints 1
205
206 The list of characters within the character class gives the set of
207 characters matched by the class.  C<"[abc]"> matches a single "a" or "b"
208 or "c".  But if the first character after the C<"["> is C<"^">, the
209 class instead matches any character not in the list.  Within a list, the
210 C<"-"> character specifies a range of characters, so that C<a-z>
211 represents all characters between "a" and "z", inclusive.  If you want
212 either C<"-"> or C<"]"> itself to be a member of a class, put it at the
213 start of the list (possibly after a C<"^">), or escape it with a
214 backslash.  C<"-"> is also taken literally when it is at the end of the
215 list, just before the closing C<"]">.  (The following all specify the
216 same class of three characters: C<[-az]>, C<[az-]>, and C<[a\-z]>.  All
217 are different from C<[a-z]>, which specifies a class containing
218 twenty-six characters, even on EBCDIC-based character sets.)
219
220 There is lots more to bracketed character classes; full details are in
221 L<perlrecharclass/Bracketed Character Classes>.
222
223 =head3 Metacharacters
224 X<metacharacter>
225 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
226
227 L</The Basics> introduced some of the metacharacters.  This section
228 gives them all.  Most of them have the same meaning as in the I<egrep>
229 command.
230
231 Only the C<"\"> is always a metacharacter.  The others are metacharacters
232 just sometimes.  The following tables lists all of them, summarizes
233 their use, and gives the contexts where they are metacharacters.
234 Outside those contexts or if prefixed by a C<"\">, they match their
235 corresponding punctuation character.  In some cases, their meaning
236 varies depending on various pattern modifiers that alter the default
237 behaviors.  See L</Modifiers>.
238
239
240             PURPOSE                                  WHERE
241  \   Escape the next character                    Always, except when
242                                                   escaped by another \
243  ^   Match the beginning of the string            Not in []
244        (or line, if /m is used)
245  ^   Complement the [] class                      At the beginning of []
246  .   Match any single character except newline    Not in []
247        (under /s, includes newline)
248  $   Match the end of the string                  Not in [], but can
249        (or before newline at the end of the       mean interpolate a
250        string; or before any newline if /m is     scalar
251        used)
252  |   Alternation                                  Not in []
253  ()  Grouping                                     Not in []
254  [   Start Bracketed Character class              Not in []
255  ]   End Bracketed Character class                Only in [], and
256                                                     not first
257  *   Matches the preceding element 0 or more      Not in []
258        times
259  +   Matches the preceding element 1 or more      Not in []
260        times
261  ?   Matches the preceding element 0 or 1         Not in []
262        times
263  {   Starts a sequence that gives number(s)       Not in []
264        of times the preceding element can be
265        matched
266  {   when following certain escape sequences
267        starts a modifier to the meaning of the
268        sequence
269  }   End sequence started by {
270  -   Indicates a range                            Only in [] interior
271  #   Beginning of comment, extends to line end    Only with /x modifier
272
273 Notice that most of the metacharacters lose their special meaning when
274 they occur in a bracketed character class, except C<"^"> has a different
275 meaning when it is at the beginning of such a class.  And C<"-"> and C<"]">
276 are metacharacters only at restricted positions within bracketed
277 character classes; while C<"}"> is a metacharacter only when closing a
278 special construct started by C<"{">.
279
280 In double-quotish context, as is usually the case,  you need to be
281 careful about C<"$"> and the non-metacharacter C<"@">.  Those could
282 interpolate variables, which may or may not be what you intended.
283
284 These rules were designed for compactness of expression, rather than
285 legibility and maintainability.  The L</E<sol>x and E<sol>xx> pattern
286 modifiers allow you to insert white space to improve readability.  And
287 use of S<C<L<re 'strict'|re/'strict' mode>>> adds extra checking to
288 catch some typos that might silently compile into something unintended.
289
290 By default, the C<"^"> character is guaranteed to match only the
291 beginning of the string, the C<"$"> character only the end (or before the
292 newline at the end), and Perl does certain optimizations with the
293 assumption that the string contains only one line.  Embedded newlines
294 will not be matched by C<"^"> or C<"$">.  You may, however, wish to treat a
295 string as a multi-line buffer, such that the C<"^"> will match after any
296 newline within the string (except if the newline is the last character in
297 the string), and C<"$"> will match before any newline.  At the
298 cost of a little more overhead, you can do this by using the
299 L</C<E<sol>m>> modifier on the pattern match operator.  (Older programs
300 did this by setting C<$*>, but this option was removed in perl 5.10.)
301 X<^> X<$> X</m>
302
303 To simplify multi-line substitutions, the C<"."> character never matches a
304 newline unless you use the L<C<E<sol>s>|/s> modifier, which in effect tells
305 Perl to pretend the string is a single line--even if it isn't.
306 X<.> X</s>
307
308 =head2 Modifiers
309
310 =head3 Overview
311
312 The default behavior for matching can be changed, using various
313 modifiers.  Modifiers that relate to the interpretation of the pattern
314 are listed just below.  Modifiers that alter the way a pattern is used
315 by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
316 L<perlop/"Gory details of parsing quoted constructs">.
317
318 =over 4
319
320 =item B<C<m>>
321 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
322
323 Treat the string being matched against as multiple lines.  That is, change C<"^"> and C<"$"> from matching
324 the start of the string's first line and the end of its last line to
325 matching the start and end of each line within the string.
326
327 =item B<C<s>>
328 X</s> X<regex, single-line> X<regexp, single-line>
329 X<regular expression, single-line>
330
331 Treat the string as single line.  That is, change C<"."> to match any character
332 whatsoever, even a newline, which normally it would not match.
333
334 Used together, as C</ms>, they let the C<"."> match any character whatsoever,
335 while still allowing C<"^"> and C<"$"> to match, respectively, just after
336 and just before newlines within the string.
337
338 =item B<C<i>>
339 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
340 X<regular expression, case-insensitive>
341
342 Do case-insensitive pattern matching.  For example, "A" will match "a"
343 under C</i>.
344
345 If locale matching rules are in effect, the case map is taken from the
346 current
347 locale for code points less than 255, and from Unicode rules for larger
348 code points.  However, matches that would cross the Unicode
349 rules/non-Unicode rules boundary (ords 255/256) will not succeed, unless
350 the locale is a UTF-8 one.  See L<perllocale>.
351
352 There are a number of Unicode characters that match a sequence of
353 multiple characters under C</i>.  For example,
354 C<LATIN SMALL LIGATURE FI> should match the sequence C<fi>.  Perl is not
355 currently able to do this when the multiple characters are in the pattern and
356 are split between groupings, or when one or more are quantified.  Thus
357
358  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
359  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
360  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
361
362  # The below doesn't match, and it isn't clear what $1 and $2 would
363  # be even if it did!!
364  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
365
366 Perl doesn't match multiple characters in a bracketed
367 character class unless the character that maps to them is explicitly
368 mentioned, and it doesn't match them at all if the character class is
369 inverted, which otherwise could be highly confusing.  See
370 L<perlrecharclass/Bracketed Character Classes>, and
371 L<perlrecharclass/Negation>.
372
373 =item B<C<x>> and B<C<xx>>
374 X</x>
375
376 Extend your pattern's legibility by permitting whitespace and comments.
377 Details in L</E<sol>x and  E<sol>xx>
378
379 =item B<C<p>>
380 X</p> X<regex, preserve> X<regexp, preserve>
381
382 Preserve the string matched such that C<${^PREMATCH}>, C<${^MATCH}>, and
383 C<${^POSTMATCH}> are available for use after matching.
384
385 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
386 mechanism, C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> will be available
387 after the match regardless of the modifier.
388
389 =item B<C<a>>, B<C<d>>, B<C<l>>, and B<C<u>>
390 X</a> X</d> X</l> X</u>
391
392 These modifiers, all new in 5.14, affect which character-set rules
393 (Unicode, I<etc>.) are used, as described below in
394 L</Character set modifiers>.
395
396 =item B<C<n>>
397 X</n> X<regex, non-capture> X<regexp, non-capture>
398 X<regular expression, non-capture>
399
400 Prevent the grouping metacharacters C<()> from capturing. This modifier,
401 new in 5.22, will stop C<$1>, C<$2>, I<etc>... from being filled in.
402
403   "hello" =~ /(hi|hello)/;   # $1 is "hello"
404   "hello" =~ /(hi|hello)/n;  # $1 is undef
405
406 This is equivalent to putting C<?:> at the beginning of every capturing group:
407
408   "hello" =~ /(?:hi|hello)/; # $1 is undef
409
410 C</n> can be negated on a per-group basis. Alternatively, named captures
411 may still be used.
412
413   "hello" =~ /(?-n:(hi|hello))/n;   # $1 is "hello"
414   "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is
415                                     # "hello"
416
417 =item Other Modifiers
418
419 There are a number of flags that can be found at the end of regular
420 expression constructs that are I<not> generic regular expression flags, but
421 apply to the operation being performed, like matching or substitution (C<m//>
422 or C<s///> respectively).
423
424 Flags described further in
425 L<perlretut/"Using regular expressions in Perl"> are:
426
427   c  - keep the current position during repeated matching
428   g  - globally match the pattern repeatedly in the string
429
430 Substitution-specific modifiers described in
431 L<perlop/"s/PATTERN/REPLACEMENT/msixpodualngcer"> are:
432
433   e  - evaluate the right-hand side as an expression
434   ee - evaluate the right side as a string then eval the result
435   o  - pretend to optimize your code, but actually introduce bugs
436   r  - perform non-destructive substitution and return the new value
437
438 =back
439
440 Regular expression modifiers are usually written in documentation
441 as I<e.g.>, "the C</x> modifier", even though the delimiter
442 in question might not really be a slash.  The modifiers C</imnsxadlup>
443 may also be embedded within the regular expression itself using
444 the C<(?...)> construct, see L</Extended Patterns> below.
445
446 =head3 Details on some modifiers
447
448 Some of the modifiers require more explanation than given in the
449 L</Overview> above.
450
451 =head4 C</x> and  C</xx>
452
453 A single C</x> tells
454 the regular expression parser to ignore most whitespace that is neither
455 backslashed nor within a bracketed character class.  You can use this to
456 break up your regular expression into more readable parts.
457 Also, the C<"#"> character is treated as a metacharacter introducing a
458 comment that runs up to the pattern's closing delimiter, or to the end
459 of the current line if the pattern extends onto the next line.  Hence,
460 this is very much like an ordinary Perl code comment.  (You can include
461 the closing delimiter within the comment only if you precede it with a
462 backslash, so be careful!)
463
464 Use of C</x> means that if you want real
465 whitespace or C<"#"> characters in the pattern (outside a bracketed character
466 class, which is unaffected by C</x>), then you'll either have to
467 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
468 hex, or C<\N{}> escapes.
469 It is ineffective to try to continue a comment onto the next line by
470 escaping the C<\n> with a backslash or C<\Q>.
471
472 You can use L</(?#text)> to create a comment that ends earlier than the
473 end of the current line, but C<text> also can't contain the closing
474 delimiter unless escaped with a backslash.
475
476 A common pitfall is to forget that C<"#"> characters begin a comment under
477 C</x> and are not matched literally.  Just keep that in mind when trying
478 to puzzle out why a particular C</x> pattern isn't working as expected.
479
480 Starting in Perl v5.26, if the modifier has a second C<"x"> within it,
481 it does everything that a single C</x> does, but additionally
482 non-backslashed SPACE and TAB characters within bracketed character
483 classes are also generally ignored, and hence can be added to make the
484 classes more readable.
485
486     / [d-e g-i 3-7]/xx
487     /[ ! @ " # $ % ^ & * () = ? <> ' ]/xx
488
489 may be easier to grasp than the squashed equivalents
490
491     /[d-eg-i3-7]/
492     /[!@"#$%^&*()=?<>']/
493
494 Taken together, these features go a long way towards
495 making Perl's regular expressions more readable.  Here's an example:
496
497     # Delete (most) C comments.
498     $program =~ s {
499         /\*     # Match the opening delimiter.
500         .*?     # Match a minimal number of characters.
501         \*/     # Match the closing delimiter.
502     } []gsx;
503
504 Note that anything inside
505 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
506 space interpretation within a single multi-character construct.  For
507 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
508 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
509 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<"(">,
510 C<"?">, and C<":">.  Within any delimiters for such a
511 construct, allowed spaces are not affected by C</x>, and depend on the
512 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
513 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
514 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
515 L<perluniprops/Properties accessible through \p{} and \P{}>.
516 X</x>
517
518 The set of characters that are deemed whitespace are those that Unicode
519 calls "Pattern White Space", namely:
520
521  U+0009 CHARACTER TABULATION
522  U+000A LINE FEED
523  U+000B LINE TABULATION
524  U+000C FORM FEED
525  U+000D CARRIAGE RETURN
526  U+0020 SPACE
527  U+0085 NEXT LINE
528  U+200E LEFT-TO-RIGHT MARK
529  U+200F RIGHT-TO-LEFT MARK
530  U+2028 LINE SEPARATOR
531  U+2029 PARAGRAPH SEPARATOR
532
533 =head4 Character set modifiers
534
535 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
536 the character set modifiers; they affect the character set rules
537 used for the regular expression.
538
539 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
540 to you, and so you need not worry about them very much.  They exist for
541 Perl's internal use, so that complex regular expression data structures
542 can be automatically serialized and later exactly reconstituted,
543 including all their nuances.  But, since Perl can't keep a secret, and
544 there may be rare instances where they are useful, they are documented
545 here.
546
547 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
548 allow code that is to work mostly on ASCII data to not have to concern
549 itself with Unicode.
550
551 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
552 effect at the time of the execution of the pattern match.
553
554 C</u> sets the character set to B<U>nicode.
555
556 C</a> also sets the character set to Unicode, BUT adds several
557 restrictions for B<A>SCII-safe matching.
558
559 C</d> is the old, problematic, pre-5.14 B<D>efault character set
560 behavior.  Its only use is to force that old behavior.
561
562 At any given time, exactly one of these modifiers is in effect.  Their
563 existence allows Perl to keep the originally compiled behavior of a
564 regular expression, regardless of what rules are in effect when it is
565 actually executed.  And if it is interpolated into a larger regex, the
566 original's rules continue to apply to it, and only it.
567
568 The C</l> and C</u> modifiers are automatically selected for
569 regular expressions compiled within the scope of various pragmas,
570 and we recommend that in general, you use those pragmas instead of
571 specifying these modifiers explicitly.  For one thing, the modifiers
572 affect only pattern matching, and do not extend to even any replacement
573 done, whereas using the pragmas gives consistent results for all
574 appropriate operations within their scopes.  For example,
575
576  s/foo/\Ubar/il
577
578 will match "foo" using the locale's rules for case-insensitive matching,
579 but the C</l> does not affect how the C<\U> operates.  Most likely you
580 want both of them to use locale rules.  To do this, instead compile the
581 regular expression within the scope of C<use locale>.  This both
582 implicitly adds the C</l>, and applies locale rules to the C<\U>.   The
583 lesson is to C<use locale>, and not C</l> explicitly.
584
585 Similarly, it would be better to use C<use feature 'unicode_strings'>
586 instead of,
587
588  s/foo/\Lbar/iu
589
590 to get Unicode rules, as the C<\L> in the former (but not necessarily
591 the latter) would also use Unicode rules.
592
593 More detail on each of the modifiers follows.  Most likely you don't
594 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
595 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
596
597 =head4 /l
598
599 means to use the current locale's rules (see L<perllocale>) when pattern
600 matching.  For example, C<\w> will match the "word" characters of that
601 locale, and C<"/i"> case-insensitive matching will match according to
602 the locale's case folding rules.  The locale used will be the one in
603 effect at the time of execution of the pattern match.  This may not be
604 the same as the compilation-time locale, and can differ from one match
605 to another if there is an intervening call of the
606 L<setlocale() function|perllocale/The setlocale function>.
607
608 Prior to v5.20, Perl did not support multi-byte locales.  Starting then,
609 UTF-8 locales are supported.  No other multi byte locales are ever
610 likely to be supported.  However, in all locales, one can have code
611 points above 255 and these will always be treated as Unicode no matter
612 what locale is in effect.
613
614 Under Unicode rules, there are a few case-insensitive matches that cross
615 the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
616 later, these are disallowed under C</l>.  For example, 0xFF (on ASCII
617 platforms) does not caselessly match the character at 0x178, C<LATIN
618 CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL
619 LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of
620 knowing if that character even exists in the locale, much less what code
621 point it is.
622
623 In a UTF-8 locale in v5.20 and later, the only visible difference
624 between locale and non-locale in regular expressions should be tainting
625 (see L<perlsec>).
626
627 This modifier may be specified to be the default by C<use locale>, but
628 see L</Which character set modifier is in effect?>.
629 X</l>
630
631 =head4 /u
632
633 means to use Unicode rules when pattern matching.  On ASCII platforms,
634 this means that the code points between 128 and 255 take on their
635 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
636 (Otherwise Perl considers their meanings to be undefined.)  Thus,
637 under this modifier, the ASCII platform effectively becomes a Unicode
638 platform; and hence, for example, C<\w> will match any of the more than
639 100_000 word characters in Unicode.
640
641 Unlike most locales, which are specific to a language and country pair,
642 Unicode classifies all the characters that are letters I<somewhere> in
643 the world as
644 C<\w>.  For example, your locale might not think that C<LATIN SMALL
645 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
646 Unicode does.  Similarly, all the characters that are decimal digits
647 somewhere in the world will match C<\d>; this is hundreds, not 10,
648 possible matches.  And some of those digits look like some of the 10
649 ASCII digits, but mean a different number, so a human could easily think
650 a number is a different quantity than it really is.  For example,
651 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
652 C<ASCII DIGIT EIGHT> (U+0038), and C<LEPCHA DIGIT SIX> (U+1C46) looks
653 very much like an C<ASCII DIGIT FIVE> (U+0035).  And, C<\d+>, may match
654 strings of digits that are a mixture from different writing systems,
655 creating a security issue.  A fraudulent website, for example, could
656 display the price of something using U+1C46, and it would appear to the
657 user that something cost 500 units, but it really costs 600.  A browser
658 that enforced script runs (L</Script Runs>) would prevent that
659 fraudulent display.  L<Unicode::UCD/num()> can also be used to sort this
660 out.  Or the C</a> modifier can be used to force C<\d> to match just the
661 ASCII 0 through 9.
662
663 Also, under this modifier, case-insensitive matching works on the full
664 set of Unicode
665 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
666 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
667 if you're not prepared, might make it look like a hexadecimal constant,
668 presenting another potential security issue.  See
669 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
670 security issues.
671
672 This modifier may be specified to be the default by C<use feature
673 'unicode_strings>, C<use locale ':not_characters'>, or
674 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
675 but see L</Which character set modifier is in effect?>.
676 X</u>
677
678 =head4 /d
679
680 This modifier means to use the "Default" native rules of the platform
681 except when there is cause to use Unicode rules instead, as follows:
682
683 =over 4
684
685 =item 1
686
687 the target string is encoded in UTF-8; or
688
689 =item 2
690
691 the pattern is encoded in UTF-8; or
692
693 =item 3
694
695 the pattern explicitly mentions a code point that is above 255 (say by
696 C<\x{100}>); or
697
698 =item 4
699
700 the pattern uses a Unicode name (C<\N{...}>);  or
701
702 =item 5
703
704 the pattern uses a Unicode property (C<\p{...}> or C<\P{...}>); or
705
706 =item 6
707
708 the pattern uses a Unicode break (C<\b{...}> or C<\B{...}>); or
709
710 =item 7
711
712 the pattern uses L</C<(?[ ])>>
713
714 =item 8
715
716 the pattern uses L<C<(*script_run: ...)>|/Script Runs>
717
718 =back
719
720 Another mnemonic for this modifier is "Depends", as the rules actually
721 used depend on various things, and as a result you can get unexpected
722 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
723 become rather infamous, leading to yet another (printable) name for this
724 modifier, "Dodgy".
725
726 Unless the pattern or string are encoded in UTF-8, only ASCII characters
727 can match positively.
728
729 Here are some examples of how that works on an ASCII platform:
730
731  $str =  "\xDF";      # $str is not in UTF-8 format.
732  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
733  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
734  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
735  chop $str;
736  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
737
738 This modifier is automatically selected by default when none of the
739 others are, so yet another name for it is "Default".
740
741 Because of the unexpected behaviors associated with this modifier, you
742 probably should only explicitly use it to maintain weird backward
743 compatibilities.
744
745 =head4 /a (and /aa)
746
747 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier
748 may be doubled-up to increase its effect.
749
750 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
751 the Posix character classes to match only in the ASCII range.  They thus
752 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
753 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
754 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, the vertical tab;
755 C<\w> means the 63 characters
756 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
757 C<[[:print:]]> match only the appropriate ASCII-range characters.
758
759 This modifier is useful for people who only incidentally use Unicode,
760 and who do not wish to be burdened with its complexities and security
761 concerns.
762
763 With C</a>, one can write C<\d> with confidence that it will only match
764 ASCII characters, and should the need arise to match beyond ASCII, you
765 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
766 similar C<\p{...}> constructs that can match beyond ASCII both white
767 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
768 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
769 doesn't mean you can't use Unicode, it means that to get Unicode
770 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
771 signals Unicode.
772
773 As you would expect, this modifier causes, for example, C<\D> to mean
774 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
775 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
776 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
777 for C<\B>).
778
779 Otherwise, C</a> behaves like the C</u> modifier, in that
780 case-insensitive matching uses Unicode rules; for example, "k" will
781 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
782 points in the Latin1 range, above ASCII will have Unicode rules when it
783 comes to case-insensitive matching.
784
785 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
786 specify the C<"a"> twice, for example C</aai> or C</aia>.  (The first
787 occurrence of C<"a"> restricts the C<\d>, I<etc>., and the second occurrence
788 adds the C</i> restrictions.)  But, note that code points outside the
789 ASCII range will use Unicode rules for C</i> matching, so the modifier
790 doesn't really restrict things to just ASCII; it just forbids the
791 intermixing of ASCII and non-ASCII.
792
793 To summarize, this modifier provides protection for applications that
794 don't wish to be exposed to all of Unicode.  Specifying it twice
795 gives added protection.
796
797 This modifier may be specified to be the default by C<use re '/a'>
798 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
799 the C</u> modifier explicitly if there are a few regular expressions
800 where you do want full Unicode rules (but even here, it's best if
801 everything were under feature C<"unicode_strings">, along with the
802 C<use re '/aa'>).  Also see L</Which character set modifier is in
803 effect?>.
804 X</a>
805 X</aa>
806
807 =head4 Which character set modifier is in effect?
808
809 Which of these modifiers is in effect at any given point in a regular
810 expression depends on a fairly complex set of interactions.  These have
811 been designed so that in general you don't have to worry about it, but
812 this section gives the gory details.  As
813 explained below in L</Extended Patterns> it is possible to explicitly
814 specify modifiers that apply only to portions of a regular expression.
815 The innermost always has priority over any outer ones, and one applying
816 to the whole expression has priority over any of the default settings that are
817 described in the remainder of this section.
818
819 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
820 default modifiers (including these) for regular expressions compiled
821 within its scope.  This pragma has precedence over the other pragmas
822 listed below that also change the defaults.
823
824 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
825 and C<L<use feature 'unicode_strings|feature>>, or
826 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
827 C</u> when not in the same scope as either C<L<use locale|perllocale>>
828 or C<L<use bytes|bytes>>.
829 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
830 sets the default to C</u>, overriding any plain C<use locale>.)
831 Unlike the mechanisms mentioned above, these
832 affect operations besides regular expressions pattern matching, and so
833 give more consistent results with other operators, including using
834 C<\U>, C<\l>, I<etc>. in substitution replacements.
835
836 If none of the above apply, for backwards compatibility reasons, the
837 C</d> modifier is the one in effect by default.  As this can lead to
838 unexpected results, it is best to specify which other rule set should be
839 used.
840
841 =head4 Character set modifier behavior prior to Perl 5.14
842
843 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
844 for regexes compiled within the scope of C<use locale>, and C</d> was
845 implied otherwise.  However, interpolating a regex into a larger regex
846 would ignore the original compilation in favor of whatever was in effect
847 at the time of the second compilation.  There were a number of
848 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
849 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
850 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
851
852 =head2 Regular Expressions
853
854 =head3 Quantifiers
855
856 Quantifiers are used when a particular portion of a pattern needs to
857 match a certain number (or numbers) of times.  If there isn't a
858 quantifier the number of times to match is exactly one.  The following
859 standard quantifiers are recognized:
860 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
861
862     *           Match 0 or more times
863     +           Match 1 or more times
864     ?           Match 1 or 0 times
865     {n}         Match exactly n times
866     {n,}        Match at least n times
867     {n,m}       Match at least n but not more than m times
868
869 (If a non-escaped curly bracket occurs in a context other than one of
870 the quantifiers listed above, where it does not form part of a
871 backslashed sequence like C<\x{...}>, it is either a fatal syntax error,
872 or treated as a regular character, generally with a deprecation warning
873 raised.  To escape it, you can precede it with a backslash (C<"\{">) or
874 enclose it within square brackets  (C<"[{]">).
875 This change will allow for future syntax extensions (like making the
876 lower bound of a quantifier optional), and better error checking of
877 quantifiers).
878
879 The C<"*"> quantifier is equivalent to C<{0,}>, the C<"+">
880 quantifier to C<{1,}>, and the C<"?"> quantifier to C<{0,1}>.  I<n> and I<m> are limited
881 to non-negative integral values less than a preset limit defined when perl is built.
882 This is usually 32766 on the most common platforms.  The actual limit can
883 be seen in the error message generated by code such as this:
884
885     $_ **= $_ , / {$_} / for 2 .. 42;
886
887 By default, a quantified subpattern is "greedy", that is, it will match as
888 many times as possible (given a particular starting location) while still
889 allowing the rest of the pattern to match.  If you want it to match the
890 minimum number of times possible, follow the quantifier with a C<"?">.  Note
891 that the meanings don't change, just the "greediness":
892 X<metacharacter> X<greedy> X<greediness>
893 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
894
895     *?        Match 0 or more times, not greedily
896     +?        Match 1 or more times, not greedily
897     ??        Match 0 or 1 time, not greedily
898     {n}?      Match exactly n times, not greedily (redundant)
899     {n,}?     Match at least n times, not greedily
900     {n,m}?    Match at least n but not more than m times, not greedily
901
902 Normally when a quantified subpattern does not allow the rest of the
903 overall pattern to match, Perl will backtrack. However, this behaviour is
904 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
905 as well.
906
907  *+     Match 0 or more times and give nothing back
908  ++     Match 1 or more times and give nothing back
909  ?+     Match 0 or 1 time and give nothing back
910  {n}+   Match exactly n times and give nothing back (redundant)
911  {n,}+  Match at least n times and give nothing back
912  {n,m}+ Match at least n but not more than m times and give nothing back
913
914 For instance,
915
916    'aaaa' =~ /a++a/
917
918 will never match, as the C<a++> will gobble up all the C<"a">'s in the
919 string and won't leave any for the remaining part of the pattern. This
920 feature can be extremely useful to give perl hints about where it
921 shouldn't backtrack. For instance, the typical "match a double-quoted
922 string" problem can be most efficiently performed when written as:
923
924    /"(?:[^"\\]++|\\.)*+"/
925
926 as we know that if the final quote does not match, backtracking will not
927 help. See the independent subexpression
928 L</C<< (?>I<pattern>) >>> for more details;
929 possessive quantifiers are just syntactic sugar for that construct. For
930 instance the above example could also be written as follows:
931
932    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
933
934 Note that the possessive quantifier modifier can not be combined
935 with the non-greedy modifier. This is because it would make no sense.
936 Consider the follow equivalency table:
937
938     Illegal         Legal
939     ------------    ------
940     X??+            X{0}
941     X+?+            X{1}
942     X{min,max}?+    X{min}
943
944 =head3 Escape sequences
945
946 Because patterns are processed as double-quoted strings, the following
947 also work:
948
949  \t          tab                   (HT, TAB)
950  \n          newline               (LF, NL)
951  \r          return                (CR)
952  \f          form feed             (FF)
953  \a          alarm (bell)          (BEL)
954  \e          escape (think troff)  (ESC)
955  \cK         control char          (example: VT)
956  \x{}, \x00  character whose ordinal is the given hexadecimal number
957  \N{name}    named Unicode character or character sequence
958  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
959  \o{}, \000  character whose ordinal is the given octal number
960  \l          lowercase next char (think vi)
961  \u          uppercase next char (think vi)
962  \L          lowercase until \E (think vi)
963  \U          uppercase until \E (think vi)
964  \Q          quote (disable) pattern metacharacters until \E
965  \E          end either case modification or quoted section, think vi
966
967 Details are in L<perlop/Quote and Quote-like Operators>.
968
969 =head3 Character Classes and other Special Escapes
970
971 In addition, Perl defines the following:
972 X<\g> X<\k> X<\K> X<backreference>
973
974  Sequence   Note    Description
975   [...]     [1]  Match a character according to the rules of the
976                    bracketed character class defined by the "...".
977                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
978   [[:...:]] [2]  Match a character according to the rules of the POSIX
979                    character class "..." within the outer bracketed
980                    character class.  Example: [[:upper:]] matches any
981                    uppercase character.
982   (?[...])  [8]  Extended bracketed character class
983   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
984                    other connector punctuation chars plus Unicode
985                    marks)
986   \W        [3]  Match a non-"word" character
987   \s        [3]  Match a whitespace character
988   \S        [3]  Match a non-whitespace character
989   \d        [3]  Match a decimal digit character
990   \D        [3]  Match a non-digit character
991   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
992   \PP       [3]  Match non-P
993   \X        [4]  Match Unicode "eXtended grapheme cluster"
994   \1        [5]  Backreference to a specific capture group or buffer.
995                    '1' may actually be any positive integer.
996   \g1       [5]  Backreference to a specific or previous group,
997   \g{-1}    [5]  The number may be negative indicating a relative
998                    previous group and may optionally be wrapped in
999                    curly brackets for safer parsing.
1000   \g{name}  [5]  Named backreference
1001   \k<name>  [5]  Named backreference
1002   \K        [6]  Keep the stuff left of the \K, don't include it in $&
1003   \N        [7]  Any character but \n.  Not affected by /s modifier
1004   \v        [3]  Vertical whitespace
1005   \V        [3]  Not vertical whitespace
1006   \h        [3]  Horizontal whitespace
1007   \H        [3]  Not horizontal whitespace
1008   \R        [4]  Linebreak
1009
1010 =over 4
1011
1012 =item [1]
1013
1014 See L<perlrecharclass/Bracketed Character Classes> for details.
1015
1016 =item [2]
1017
1018 See L<perlrecharclass/POSIX Character Classes> for details.
1019
1020 =item [3]
1021
1022 See L<perlunicode/Unicode Character Properties> for details
1023
1024 =item [4]
1025
1026 See L<perlrebackslash/Misc> for details.
1027
1028 =item [5]
1029
1030 See L</Capture groups> below for details.
1031
1032 =item [6]
1033
1034 See L</Extended Patterns> below for details.
1035
1036 =item [7]
1037
1038 Note that C<\N> has two meanings.  When of the form C<\N{I<NAME>}>, it
1039 matches the character or character sequence whose name is I<NAME>; and
1040 similarly
1041 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
1042 code point is I<hex>.  Otherwise it matches any character but C<\n>.
1043
1044 =item [8]
1045
1046 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
1047
1048 =back
1049
1050 =head3 Assertions
1051
1052 Besides L<C<"^"> and C<"$">|/Metacharacters>, Perl defines the following
1053 zero-width assertions:
1054 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
1055 X<regexp, zero-width assertion>
1056 X<regular expression, zero-width assertion>
1057 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
1058
1059  \b{}   Match at Unicode boundary of specified type
1060  \B{}   Match where corresponding \b{} doesn't match
1061  \b     Match a \w\W or \W\w boundary
1062  \B     Match except at a \w\W or \W\w boundary
1063  \A     Match only at beginning of string
1064  \Z     Match only at end of string, or before newline at the end
1065  \z     Match only at end of string
1066  \G     Match only at pos() (e.g. at the end-of-match position
1067         of prior m//g)
1068
1069 A Unicode boundary (C<\b{}>), available starting in v5.22, is a spot
1070 between two characters, or before the first character in the string, or
1071 after the final character in the string where certain criteria defined
1072 by Unicode are met.  See L<perlrebackslash/\b{}, \b, \B{}, \B> for
1073 details.
1074
1075 A word boundary (C<\b>) is a spot between two characters
1076 that has a C<\w> on one side of it and a C<\W> on the other side
1077 of it (in either order), counting the imaginary characters off the
1078 beginning and end of the string as matching a C<\W>.  (Within
1079 character classes C<\b> represents backspace rather than a word
1080 boundary, just as it normally does in any double-quoted string.)
1081 The C<\A> and C<\Z> are just like C<"^"> and C<"$">, except that they
1082 won't match multiple times when the C</m> modifier is used, while
1083 C<"^"> and C<"$"> will match at every internal line boundary.  To match
1084 the actual end of the string and not ignore an optional trailing
1085 newline, use C<\z>.
1086 X<\b> X<\A> X<\Z> X<\z> X</m>
1087
1088 The C<\G> assertion can be used to chain global matches (using
1089 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
1090 It is also useful when writing C<lex>-like scanners, when you have
1091 several patterns that you want to match against consequent substrings
1092 of your string; see the previous reference.  The actual location
1093 where C<\G> will match can also be influenced by using C<pos()> as
1094 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
1095 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
1096 is modified somewhat, in that contents to the left of C<\G> are
1097 not counted when determining the length of the match. Thus the following
1098 will not match forever:
1099 X<\G>
1100
1101      my $string = 'ABC';
1102      pos($string) = 1;
1103      while ($string =~ /(.\G)/g) {
1104          print $1;
1105      }
1106
1107 It will print 'A' and then terminate, as it considers the match to
1108 be zero-width, and thus will not match at the same position twice in a
1109 row.
1110
1111 It is worth noting that C<\G> improperly used can result in an infinite
1112 loop. Take care when using patterns that include C<\G> in an alternation.
1113
1114 Note also that C<s///> will refuse to overwrite part of a substitution
1115 that has already been replaced; so for example this will stop after the
1116 first iteration, rather than iterating its way backwards through the
1117 string:
1118
1119     $_ = "123456789";
1120     pos = 6;
1121     s/.(?=.\G)/X/g;
1122     print;      # prints 1234X6789, not XXXXX6789
1123
1124
1125 =head3 Capture groups
1126
1127 The grouping construct C<( ... )> creates capture groups (also referred to as
1128 capture buffers). To refer to the current contents of a group later on, within
1129 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
1130 for the second, and so on.
1131 This is called a I<backreference>.
1132 X<regex, capture buffer> X<regexp, capture buffer>
1133 X<regex, capture group> X<regexp, capture group>
1134 X<regular expression, capture buffer> X<backreference>
1135 X<regular expression, capture group> X<backreference>
1136 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
1137 X<named capture buffer> X<regular expression, named capture buffer>
1138 X<named capture group> X<regular expression, named capture group>
1139 X<%+> X<$+{name}> X<< \k<name> >>
1140 There is no limit to the number of captured substrings that you may use.
1141 Groups are numbered with the leftmost open parenthesis being number 1, I<etc>.  If
1142 a group did not match, the associated backreference won't match either. (This
1143 can happen if the group is optional, or in a different branch of an
1144 alternation.)
1145 You can omit the C<"g">, and write C<"\1">, I<etc>, but there are some issues with
1146 this form, described below.
1147
1148 You can also refer to capture groups relatively, by using a negative number, so
1149 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
1150 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
1151 example:
1152
1153         /
1154          (Y)            # group 1
1155          (              # group 2
1156             (X)         # group 3
1157             \g{-1}      # backref to group 3
1158             \g{-3}      # backref to group 1
1159          )
1160         /x
1161
1162 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
1163 interpolate regexes into larger regexes and not have to worry about the
1164 capture groups being renumbered.
1165
1166 You can dispense with numbers altogether and create named capture groups.
1167 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
1168 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
1169 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
1170 I<name> must not begin with a number, nor contain hyphens.
1171 When different groups within the same pattern have the same name, any reference
1172 to that name assumes the leftmost defined group.  Named groups count in
1173 absolute and relative numbering, and so can also be referred to by those
1174 numbers.
1175 (It's possible to do things with named capture groups that would otherwise
1176 require C<(??{})>.)
1177
1178 Capture group contents are dynamically scoped and available to you outside the
1179 pattern until the end of the enclosing block or until the next successful
1180 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
1181 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
1182 I<etc>); or by name via the C<%+> hash, using C<"$+{I<name>}">.
1183
1184 Braces are required in referring to named capture groups, but are optional for
1185 absolute or relative numbered ones.  Braces are safer when creating a regex by
1186 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
1187 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
1188 is probably not what you intended.
1189
1190 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
1191 there were no named nor relative numbered capture groups.  Absolute numbered
1192 groups were referred to using C<\1>,
1193 C<\2>, I<etc>., and this notation is still
1194 accepted (and likely always will be).  But it leads to some ambiguities if
1195 there are more than 9 capture groups, as C<\10> could mean either the tenth
1196 capture group, or the character whose ordinal in octal is 010 (a backspace in
1197 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
1198 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
1199 a backreference only if at least 11 left parentheses have opened before it.
1200 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
1201 There are several examples below that illustrate these perils.  You can avoid
1202 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
1203 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
1204 digits padded with leading zeros, since a leading zero implies an octal
1205 constant.
1206
1207 The C<\I<digit>> notation also works in certain circumstances outside
1208 the pattern.  See L</Warning on \1 Instead of $1> below for details.
1209
1210 Examples:
1211
1212     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
1213
1214     /(.)\g1/                        # find first doubled char
1215          and print "'$1' is the first doubled character\n";
1216
1217     /(?<char>.)\k<char>/            # ... a different way
1218          and print "'$+{char}' is the first doubled character\n";
1219
1220     /(?'char'.)\g1/                 # ... mix and match
1221          and print "'$1' is the first doubled character\n";
1222
1223     if (/Time: (..):(..):(..)/) {   # parse out values
1224         $hours = $1;
1225         $minutes = $2;
1226         $seconds = $3;
1227     }
1228
1229     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
1230     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
1231     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
1232     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
1233
1234     $a = '(.)\1';        # Creates problems when concatenated.
1235     $b = '(.)\g{1}';     # Avoids the problems.
1236     "aa" =~ /${a}/;      # True
1237     "aa" =~ /${b}/;      # True
1238     "aa0" =~ /${a}0/;    # False!
1239     "aa0" =~ /${b}0/;    # True
1240     "aa\x08" =~ /${a}0/;  # True!
1241     "aa\x08" =~ /${b}0/;  # False
1242
1243 Several special variables also refer back to portions of the previous
1244 match.  C<$+> returns whatever the last bracket match matched.
1245 C<$&> returns the entire matched string.  (At one point C<$0> did
1246 also, but now it returns the name of the program.)  C<$`> returns
1247 everything before the matched string.  C<$'> returns everything
1248 after the matched string. And C<$^N> contains whatever was matched by
1249 the most-recently closed group (submatch). C<$^N> can be used in
1250 extended patterns (see below), for example to assign a submatch to a
1251 variable.
1252 X<$+> X<$^N> X<$&> X<$`> X<$'>
1253
1254 These special variables, like the C<%+> hash and the numbered match variables
1255 (C<$1>, C<$2>, C<$3>, I<etc>.) are dynamically scoped
1256 until the end of the enclosing block or until the next successful
1257 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
1258 X<$+> X<$^N> X<$&> X<$`> X<$'>
1259 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
1260
1261 B<NOTE>: Failed matches in Perl do not reset the match variables,
1262 which makes it easier to write code that tests for a series of more
1263 specific cases and remembers the best match.
1264
1265 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
1266 beware that once Perl sees that you need one of C<$&>, C<$`>, or
1267 C<$'> anywhere in the program, it has to provide them for every
1268 pattern match.  This may substantially slow your program.
1269
1270 Perl uses the same mechanism to produce C<$1>, C<$2>, I<etc>, so you also
1271 pay a price for each pattern that contains capturing parentheses.
1272 (To avoid this cost while retaining the grouping behaviour, use the
1273 extended regular expression C<(?: ... )> instead.)  But if you never
1274 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
1275 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
1276 if you can, but if you can't (and some algorithms really appreciate
1277 them), once you've used them once, use them at will, because you've
1278 already paid the price.
1279 X<$&> X<$`> X<$'>
1280
1281 Perl 5.16 introduced a slightly more efficient mechanism that notes
1282 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
1283 thus may only need to copy part of the string.  Perl 5.20 introduced a
1284 much more efficient copy-on-write mechanism which eliminates any slowdown.
1285
1286 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
1287 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
1288 and C<$'>, B<except> that they are only guaranteed to be defined after a
1289 successful match that was executed with the C</p> (preserve) modifier.
1290 The use of these variables incurs no global performance penalty, unlike
1291 their punctuation character equivalents, however at the trade-off that you
1292 have to tell perl when you want to use them.  As of Perl 5.20, these three
1293 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
1294 X</p> X<p modifier>
1295
1296 =head2 Quoting metacharacters
1297
1298 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
1299 C<\w>, C<\n>.  Unlike some other regular expression languages, there
1300 are no backslashed symbols that aren't alphanumeric.  So anything
1301 that looks like C<\\>, C<\(>, C<\)>, C<\[>, C<\]>, C<\{>, or C<\}> is
1302 always
1303 interpreted as a literal character, not a metacharacter.  This was
1304 once used in a common idiom to disable or quote the special meanings
1305 of regular expression metacharacters in a string that you want to
1306 use for a pattern. Simply quote all non-"word" characters:
1307
1308     $pattern =~ s/(\W)/\\$1/g;
1309
1310 (If C<use locale> is set, then this depends on the current locale.)
1311 Today it is more common to use the C<L<quotemeta()|perlfunc/quotemeta>>
1312 function or the C<\Q> metaquoting escape sequence to disable all
1313 metacharacters' special meanings like this:
1314
1315     /$unquoted\Q$quoted\E$unquoted/
1316
1317 Beware that if you put literal backslashes (those not inside
1318 interpolated variables) between C<\Q> and C<\E>, double-quotish
1319 backslash interpolation may lead to confusing results.  If you
1320 I<need> to use literal backslashes within C<\Q...\E>,
1321 consult L<perlop/"Gory details of parsing quoted constructs">.
1322
1323 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
1324
1325 =head2 Extended Patterns
1326
1327 Perl also defines a consistent extension syntax for features not
1328 found in standard tools like B<awk> and
1329 B<lex>.  The syntax for most of these is a
1330 pair of parentheses with a question mark as the first thing within
1331 the parentheses.  The character after the question mark indicates
1332 the extension.
1333
1334 A question mark was chosen for this and for the minimal-matching
1335 construct because 1) question marks are rare in older regular
1336 expressions, and 2) whenever you see one, you should stop and
1337 "question" exactly what is going on.  That's psychology....
1338
1339 =over 4
1340
1341 =item C<(?#I<text>)>
1342 X<(?#)>
1343
1344 A comment.  The I<text> is ignored.
1345 Note that Perl closes
1346 the comment as soon as it sees a C<")">, so there is no way to put a literal
1347 C<")"> in the comment.  The pattern's closing delimiter must be escaped by
1348 a backslash if it appears in the comment.
1349
1350 See L</E<sol>x> for another way to have comments in patterns.
1351
1352 Note that a comment can go just about anywhere, except in the middle of
1353 an escape sequence.   Examples:
1354
1355  qr/foo(?#comment)bar/'  # Matches 'foobar'
1356
1357  # The pattern below matches 'abcd', 'abccd', or 'abcccd'
1358  qr/abc(?#comment between literal and its quantifier){1,3}d/
1359
1360  # The pattern below generates a syntax error, because the '\p' must
1361  # be followed immediately by a '{'.
1362  qr/\p(?#comment between \p and its property name){Any}/
1363
1364  # The pattern below generates a syntax error, because the initial
1365  # '\(' is a literal opening parenthesis, and so there is nothing
1366  # for the  closing ')' to match
1367  qr/\(?#the backslash means this isn't a comment)p{Any}/
1368
1369  # Comments can be used to fold long patterns into multiple lines
1370  qr/First part of a long regex(?#
1371    )remaining part/
1372
1373 =item C<(?adlupimnsx-imnsx)>
1374
1375 =item C<(?^alupimnsx)>
1376 X<(?)> X<(?^)>
1377
1378 One or more embedded pattern-match modifiers, to be turned on (or
1379 turned off if preceded by C<"-">) for the remainder of the pattern or
1380 the remainder of the enclosing pattern group (if any).
1381
1382 This is particularly useful for dynamically-generated patterns,
1383 such as those read in from a
1384 configuration file, taken from an argument, or specified in a table
1385 somewhere.  Consider the case where some patterns want to be
1386 case-sensitive and some do not:  The case-insensitive ones merely need to
1387 include C<(?i)> at the front of the pattern.  For example:
1388
1389     $pattern = "foobar";
1390     if ( /$pattern/i ) { }
1391
1392     # more flexible:
1393
1394     $pattern = "(?i)foobar";
1395     if ( /$pattern/ ) { }
1396
1397 These modifiers are restored at the end of the enclosing group. For example,
1398
1399     ( (?i) blah ) \s+ \g1
1400
1401 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1402 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1403 modifier outside this group.
1404
1405 These modifiers do not carry over into named subpatterns called in the
1406 enclosing group. In other words, a pattern such as C<((?i)(?&I<NAME>))> does not
1407 change the case-sensitivity of the I<NAME> pattern.
1408
1409 A modifier is overridden by later occurrences of this construct in the
1410 same scope containing the same modifier, so that
1411
1412     /((?im)foo(?-m)bar)/
1413
1414 matches all of C<foobar> case insensitively, but uses C</m> rules for
1415 only the C<foo> portion.  The C<"a"> flag overrides C<aa> as well;
1416 likewise C<aa> overrides C<"a">.  The same goes for C<"x"> and C<xx>.
1417 Hence, in
1418
1419     /(?-x)foo/xx
1420
1421 both C</x> and C</xx> are turned off during matching C<foo>.  And in
1422
1423     /(?x)foo/x
1424
1425 C</x> but NOT C</xx> is turned on for matching C<foo>.  (One might
1426 mistakenly think that since the inner C<(?x)> is already in the scope of
1427 C</x>, that the result would effectively be the sum of them, yielding
1428 C</xx>.  It doesn't work that way.)  Similarly, doing something like
1429 C<(?xx-x)foo> turns off all C<"x"> behavior for matching C<foo>, it is not
1430 that you subtract 1 C<"x"> from 2 to get 1 C<"x"> remaining.
1431
1432 Any of these modifiers can be set to apply globally to all regular
1433 expressions compiled within the scope of a C<use re>.  See
1434 L<re/"'/flags' mode">.
1435
1436 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1437 after the C<"?"> is a shorthand equivalent to C<d-imnsx>.  Flags (except
1438 C<"d">) may follow the caret to override it.
1439 But a minus sign is not legal with it.
1440
1441 Note that the C<"a">, C<"d">, C<"l">, C<"p">, and C<"u"> modifiers are special in
1442 that they can only be enabled, not disabled, and the C<"a">, C<"d">, C<"l">, and
1443 C<"u"> modifiers are mutually exclusive: specifying one de-specifies the
1444 others, and a maximum of one (or two C<"a">'s) may appear in the
1445 construct.  Thus, for
1446 example, C<(?-p)> will warn when compiled under C<use warnings>;
1447 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1448
1449 Note also that the C<"p"> modifier is special in that its presence
1450 anywhere in a pattern has a global effect.
1451
1452 =item C<(?:I<pattern>)>
1453 X<(?:)>
1454
1455 =item C<(?adluimnsx-imnsx:I<pattern>)>
1456
1457 =item C<(?^aluimnsx:I<pattern>)>
1458 X<(?^:)>
1459
1460 This is for clustering, not capturing; it groups subexpressions like
1461 C<"()">, but doesn't make backreferences as C<"()"> does.  So
1462
1463     @fields = split(/\b(?:a|b|c)\b/)
1464
1465 matches the same field delimiters as
1466
1467     @fields = split(/\b(a|b|c)\b/)
1468
1469 but doesn't spit out the delimiters themselves as extra fields (even though
1470 that's the behaviour of L<perlfunc/split> when its pattern contains capturing
1471 groups).  It's also cheaper not to capture
1472 characters if you don't need to.
1473
1474 Any letters between C<"?"> and C<":"> act as flags modifiers as with
1475 C<(?adluimnsx-imnsx)>.  For example,
1476
1477     /(?s-i:more.*than).*million/i
1478
1479 is equivalent to the more verbose
1480
1481     /(?:(?s-i)more.*than).*million/i
1482
1483 Note that any C<()> constructs enclosed within this one will still
1484 capture unless the C</n> modifier is in effect.
1485
1486 Like the L</(?adlupimnsx-imnsx)> construct, C<aa> and C<"a"> override each
1487 other, as do C<xx> and C<"x">.  They are not additive.  So, doing
1488 something like C<(?xx-x:foo)> turns off all C<"x"> behavior for matching
1489 C<foo>.
1490
1491 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1492 after the C<"?"> is a shorthand equivalent to C<d-imnsx>.  Any positive
1493 flags (except C<"d">) may follow the caret, so
1494
1495     (?^x:foo)
1496
1497 is equivalent to
1498
1499     (?x-imns:foo)
1500
1501 The caret tells Perl that this cluster doesn't inherit the flags of any
1502 surrounding pattern, but uses the system defaults (C<d-imnsx>),
1503 modified by any flags specified.
1504
1505 The caret allows for simpler stringification of compiled regular
1506 expressions.  These look like
1507
1508     (?^:pattern)
1509
1510 with any non-default flags appearing between the caret and the colon.
1511 A test that looks at such stringification thus doesn't need to have the
1512 system default flags hard-coded in it, just the caret.  If new flags are
1513 added to Perl, the meaning of the caret's expansion will change to include
1514 the default for those flags, so the test will still work, unchanged.
1515
1516 Specifying a negative flag after the caret is an error, as the flag is
1517 redundant.
1518
1519 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1520 to match at the beginning.
1521
1522 =item C<(?|I<pattern>)>
1523 X<(?|)> X<Branch reset>
1524
1525 This is the "branch reset" pattern, which has the special property
1526 that the capture groups are numbered from the same starting point
1527 in each alternation branch. It is available starting from perl 5.10.0.
1528
1529 Capture groups are numbered from left to right, but inside this
1530 construct the numbering is restarted for each branch.
1531
1532 The numbering within each branch will be as normal, and any groups
1533 following this construct will be numbered as though the construct
1534 contained only one branch, that being the one with the most capture
1535 groups in it.
1536
1537 This construct is useful when you want to capture one of a
1538 number of alternative matches.
1539
1540 Consider the following pattern.  The numbers underneath show in
1541 which group the captured content will be stored.
1542
1543
1544     # before  ---------------branch-reset----------- after
1545     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1546     # 1            2         2  3        2     3     4
1547
1548 Be careful when using the branch reset pattern in combination with
1549 named captures. Named captures are implemented as being aliases to
1550 numbered groups holding the captures, and that interferes with the
1551 implementation of the branch reset pattern. If you are using named
1552 captures in a branch reset pattern, it's best to use the same names,
1553 in the same order, in each of the alternations:
1554
1555    /(?|  (?<a> x ) (?<b> y )
1556       |  (?<a> z ) (?<b> w )) /x
1557
1558 Not doing so may lead to surprises:
1559
1560   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1561   say $+{a};    # Prints '12'
1562   say $+{b};    # *Also* prints '12'.
1563
1564 The problem here is that both the group named C<< a >> and the group
1565 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1566
1567 =item Lookaround Assertions
1568 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1569
1570 Lookaround assertions are zero-width patterns which match a specific
1571 pattern without including it in C<$&>. Positive assertions match when
1572 their subpattern matches, negative assertions match when their subpattern
1573 fails. Lookbehind matches text up to the current match position,
1574 lookahead matches text following the current match position.
1575
1576 =over 4
1577
1578 =item C<(?=I<pattern>)>
1579
1580 =item C<(*pla:I<pattern>)>
1581
1582 =item C<(*positive_lookahead:I<pattern>)>
1583 X<(?=)>
1584 X<(*pla>
1585 X<(*positive_lookahead>
1586 X<look-ahead, positive> X<lookahead, positive>
1587
1588 A zero-width positive lookahead assertion.  For example, C</\w+(?=\t)/>
1589 matches a word followed by a tab, without including the tab in C<$&>.
1590
1591 The alphabetic forms are experimental; using them yields a warning in the
1592 C<experimental::alpha_assertions> category.
1593
1594 =item C<(?!I<pattern>)>
1595
1596 =item C<(*nla:I<pattern>)>
1597
1598 =item C<(*negative_lookahead:I<pattern>)>
1599 X<(?!)>
1600 X<(*nla>
1601 X<(*negative_lookahead>
1602 X<look-ahead, negative> X<lookahead, negative>
1603
1604 A zero-width negative lookahead assertion.  For example C</foo(?!bar)/>
1605 matches any occurrence of "foo" that isn't followed by "bar".  Note
1606 however that lookahead and lookbehind are NOT the same thing.  You cannot
1607 use this for lookbehind.
1608
1609 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1610 will not do what you want.  That's because the C<(?!foo)> is just saying that
1611 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1612 match.  Use lookbehind instead (see below).
1613
1614 The alphabetic forms are experimental; using them yields a warning in the
1615 C<experimental::alpha_assertions> category.
1616
1617 =item C<(?<=I<pattern>)>
1618
1619 =item C<\K>
1620
1621 =item C<(*plb:I<pattern>)>
1622
1623 =item C<(*positive_lookbehind:I<pattern>)>
1624 X<(?<=)>
1625 X<(*plb>
1626 X<(*positive_lookbehind>
1627 X<look-behind, positive> X<lookbehind, positive> X<\K>
1628
1629 A zero-width positive lookbehind assertion.  For example, C</(?<=\t)\w+/>
1630 matches a word that follows a tab, without including the tab in C<$&>.
1631 Works only for fixed-width lookbehind of up to 255 characters.  Note
1632 that a compilation error will be generated if the assertion contains a
1633 multi-character match under C</i>, as that could match a single
1634 character, or it could match two or three, and that makes it variable
1635 length, which is forbidden.
1636
1637 There is a special form of this construct, called C<\K> (available since
1638 Perl 5.10.0), which causes the
1639 regex engine to "keep" everything it had matched prior to the C<\K> and
1640 not include it in C<$&>. This effectively provides variable-length
1641 lookbehind. The use of C<\K> inside of another lookaround assertion
1642 is allowed, but the behaviour is currently not well defined.
1643
1644 For various reasons C<\K> may be significantly more efficient than the
1645 equivalent C<< (?<=...) >> construct, and it is especially useful in
1646 situations where you want to efficiently remove something following
1647 something else in a string. For instance
1648
1649   s/(foo)bar/$1/g;
1650
1651 can be rewritten as the much more efficient
1652
1653   s/foo\Kbar//g;
1654
1655 The alphabetic forms (not including C<\K> are experimental; using them
1656 yields a warning in the C<experimental::alpha_assertions> category.
1657
1658 =item C<(?<!I<pattern>)>
1659
1660 =item C<(*nlb:I<pattern>)>
1661
1662 =item C<(*negative_lookbehind:I<pattern>)>
1663 X<(?<!)>
1664 X<(*nlb>
1665 X<(*negative_lookbehind>
1666 X<look-behind, negative> X<lookbehind, negative>
1667
1668 A zero-width negative lookbehind assertion.  For example C</(?<!bar)foo/>
1669 matches any occurrence of "foo" that does not follow "bar".  Works
1670 only for fixed-width lookbehind of up to 255 characters.  Note that a
1671 compilation error will be generated if the assertion contains a
1672 multi-character match under C</i>, as that could match a single
1673 character, or it could match two or three, and that makes it variable
1674 length, which is forbidden.
1675
1676 The alphabetic forms are experimental; using them yields a warning in the
1677 C<experimental::alpha_assertions> category.
1678
1679 =back
1680
1681 =item C<< (?<I<NAME>>I<pattern>) >>
1682
1683 =item C<(?'I<NAME>'I<pattern>)>
1684 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1685
1686 A named capture group. Identical in every respect to normal capturing
1687 parentheses C<()> but for the additional fact that the group
1688 can be referred to by name in various regular expression
1689 constructs (like C<\g{I<NAME>}>) and can be accessed by name
1690 after a successful match via C<%+> or C<%->. See L<perlvar>
1691 for more details on the C<%+> and C<%-> hashes.
1692
1693 If multiple distinct capture groups have the same name, then
1694 C<$+{I<NAME>}> will refer to the leftmost defined group in the match.
1695
1696 The forms C<(?'I<NAME>'I<pattern>)> and C<< (?<I<NAME>>I<pattern>) >>
1697 are equivalent.
1698
1699 B<NOTE:> While the notation of this construct is the same as the similar
1700 function in .NET regexes, the behavior is not. In Perl the groups are
1701 numbered sequentially regardless of being named or not. Thus in the
1702 pattern
1703
1704   /(x)(?<foo>y)(z)/
1705
1706 C<$+{foo}> will be the same as C<$2>, and C<$3> will contain 'z' instead of
1707 the opposite which is what a .NET regex hacker might expect.
1708
1709 Currently I<NAME> is restricted to simple identifiers only.
1710 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1711 its Unicode extension (see L<utf8>),
1712 though it isn't extended by the locale (see L<perllocale>).
1713
1714 B<NOTE:> In order to make things easier for programmers with experience
1715 with the Python or PCRE regex engines, the pattern C<<
1716 (?PE<lt>I<NAME>E<gt>I<pattern>) >>
1717 may be used instead of C<< (?<I<NAME>>I<pattern>) >>; however this form does not
1718 support the use of single quotes as a delimiter for the name.
1719
1720 =item C<< \k<I<NAME>> >>
1721
1722 =item C<< \k'I<NAME>' >>
1723
1724 Named backreference. Similar to numeric backreferences, except that
1725 the group is designated by name and not number. If multiple groups
1726 have the same name then it refers to the leftmost defined group in
1727 the current match.
1728
1729 It is an error to refer to a name not defined by a C<< (?<I<NAME>>) >>
1730 earlier in the pattern.
1731
1732 Both forms are equivalent.
1733
1734 B<NOTE:> In order to make things easier for programmers with experience
1735 with the Python or PCRE regex engines, the pattern C<< (?P=I<NAME>) >>
1736 may be used instead of C<< \k<I<NAME>> >>.
1737
1738 =item C<(?{ I<code> })>
1739 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1740
1741 B<WARNING>: Using this feature safely requires that you understand its
1742 limitations.  Code executed that has side effects may not perform identically
1743 from version to version due to the effect of future optimisations in the regex
1744 engine.  For more information on this, see L</Embedded Code Execution
1745 Frequency>.
1746
1747 This zero-width assertion executes any embedded Perl code.  It always
1748 succeeds, and its return value is set as C<$^R>.
1749
1750 In literal patterns, the code is parsed at the same time as the
1751 surrounding code. While within the pattern, control is passed temporarily
1752 back to the perl parser, until the logically-balancing closing brace is
1753 encountered. This is similar to the way that an array index expression in
1754 a literal string is handled, for example
1755
1756     "abc$array[ 1 + f('[') + g()]def"
1757
1758 In particular, braces do not need to be balanced:
1759
1760     s/abc(?{ f('{'); })/def/
1761
1762 Even in a pattern that is interpolated and compiled at run-time, literal
1763 code blocks will be compiled once, at perl compile time; the following
1764 prints "ABCD":
1765
1766     print "D";
1767     my $qr = qr/(?{ BEGIN { print "A" } })/;
1768     my $foo = "foo";
1769     /$foo$qr(?{ BEGIN { print "B" } })/;
1770     BEGIN { print "C" }
1771
1772 In patterns where the text of the code is derived from run-time
1773 information rather than appearing literally in a source code /pattern/,
1774 the code is compiled at the same time that the pattern is compiled, and
1775 for reasons of security, C<use re 'eval'> must be in scope. This is to
1776 stop user-supplied patterns containing code snippets from being
1777 executable.
1778
1779 In situations where you need to enable this with C<use re 'eval'>, you should
1780 also have taint checking enabled.  Better yet, use the carefully
1781 constrained evaluation within a Safe compartment.  See L<perlsec> for
1782 details about both these mechanisms.
1783
1784 From the viewpoint of parsing, lexical variable scope and closures,
1785
1786     /AAA(?{ BBB })CCC/
1787
1788 behaves approximately like
1789
1790     /AAA/ && do { BBB } && /CCC/
1791
1792 Similarly,
1793
1794     qr/AAA(?{ BBB })CCC/
1795
1796 behaves approximately like
1797
1798     sub { /AAA/ && do { BBB } && /CCC/ }
1799
1800 In particular:
1801
1802     { my $i = 1; $r = qr/(?{ print $i })/ }
1803     my $i = 2;
1804     /$r/; # prints "1"
1805
1806 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1807 expression is matching against. You can also use C<pos()> to know what is
1808 the current position of matching within this string.
1809
1810 The code block introduces a new scope from the perspective of lexical
1811 variable declarations, but B<not> from the perspective of C<local> and
1812 similar localizing behaviours. So later code blocks within the same
1813 pattern will still see the values which were localized in earlier blocks.
1814 These accumulated localizations are undone either at the end of a
1815 successful match, or if the assertion is backtracked (compare
1816 L</"Backtracking">). For example,
1817
1818   $_ = 'a' x 8;
1819   m<
1820      (?{ $cnt = 0 })               # Initialize $cnt.
1821      (
1822        a
1823        (?{
1824            local $cnt = $cnt + 1;  # Update $cnt,
1825                                    # backtracking-safe.
1826        })
1827      )*
1828      aaaa
1829      (?{ $res = $cnt })            # On success copy to
1830                                    # non-localized location.
1831    >x;
1832
1833 will initially increment C<$cnt> up to 8; then during backtracking, its
1834 value will be unwound back to 4, which is the value assigned to C<$res>.
1835 At the end of the regex execution, C<$cnt> will be wound back to its initial
1836 value of 0.
1837
1838 This assertion may be used as the condition in a
1839
1840     (?(condition)yes-pattern|no-pattern)
1841
1842 switch.  If I<not> used in this way, the result of evaluation of I<code>
1843 is put into the special variable C<$^R>.  This happens immediately, so
1844 C<$^R> can be used from other C<(?{ I<code> })> assertions inside the same
1845 regular expression.
1846
1847 The assignment to C<$^R> above is properly localized, so the old
1848 value of C<$^R> is restored if the assertion is backtracked; compare
1849 L</"Backtracking">.
1850
1851 Note that the special variable C<$^N>  is particularly useful with code
1852 blocks to capture the results of submatches in variables without having to
1853 keep track of the number of nested parentheses. For example:
1854
1855   $_ = "The brown fox jumps over the lazy dog";
1856   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1857   print "color = $color, animal = $animal\n";
1858
1859
1860 =item C<(??{ I<code> })>
1861 X<(??{})>
1862 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1863
1864 B<WARNING>: Using this feature safely requires that you understand its
1865 limitations.  Code executed that has side effects may not perform
1866 identically from version to version due to the effect of future
1867 optimisations in the regex engine.  For more information on this, see
1868 L</Embedded Code Execution Frequency>.
1869
1870 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1871 same way as a C<(?{ I<code> })> code block as described above, except that
1872 its return value, rather than being assigned to C<$^R>, is treated as a
1873 pattern, compiled if it's a string (or used as-is if its a qr// object),
1874 then matched as if it were inserted instead of this construct.
1875
1876 During the matching of this sub-pattern, it has its own set of
1877 captures which are valid during the sub-match, but are discarded once
1878 control returns to the main pattern. For example, the following matches,
1879 with the inner pattern capturing "B" and matching "BB", while the outer
1880 pattern captures "A";
1881
1882     my $inner = '(.)\1';
1883     "ABBA" =~ /^(.)(??{ $inner })\1/;
1884     print $1; # prints "A";
1885
1886 Note that this means that  there is no way for the inner pattern to refer
1887 to a capture group defined outside.  (The code block itself can use C<$1>,
1888 I<etc>., to refer to the enclosing pattern's capture groups.)  Thus, although
1889
1890     ('a' x 100)=~/(??{'(.)' x 100})/
1891
1892 I<will> match, it will I<not> set C<$1> on exit.
1893
1894 The following pattern matches a parenthesized group:
1895
1896  $re = qr{
1897             \(
1898             (?:
1899                (?> [^()]+ )  # Non-parens without backtracking
1900              |
1901                (??{ $re })   # Group with matching parens
1902             )*
1903             \)
1904          }x;
1905
1906 See also
1907 L<C<(?I<PARNO>)>|/(?I<PARNO>) (?-I<PARNO>) (?+I<PARNO>) (?R) (?0)>
1908 for a different, more efficient way to accomplish
1909 the same task.
1910
1911 Executing a postponed regular expression too many times without
1912 consuming any input string will also result in a fatal error.  The depth
1913 at which that happens is compiled into perl, so it can be changed with a
1914 custom build.
1915
1916 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1917 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1918 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1919 X<regex, relative recursion> X<GOSUB> X<GOSTART>
1920
1921 Recursive subpattern. Treat the contents of a given capture buffer in the
1922 current pattern as an independent subpattern and attempt to match it at
1923 the current position in the string. Information about capture state from
1924 the caller for things like backreferences is available to the subpattern,
1925 but capture buffers set by the subpattern are not visible to the caller.
1926
1927 Similar to C<(??{ I<code> })> except that it does not involve executing any
1928 code or potentially compiling a returned pattern string; instead it treats
1929 the part of the current pattern contained within a specified capture group
1930 as an independent pattern that must match at the current position. Also
1931 different is the treatment of capture buffers, unlike C<(??{ I<code> })>
1932 recursive patterns have access to their caller's match state, so one can
1933 use backreferences safely.
1934
1935 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1936 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1937 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1938 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1939 to be relative, with negative numbers indicating preceding capture groups
1940 and positive ones following. Thus C<(?-1)> refers to the most recently
1941 declared group, and C<(?+1)> indicates the next group to be declared.
1942 Note that the counting for relative recursion differs from that of
1943 relative backreferences, in that with recursion unclosed groups B<are>
1944 included.
1945
1946 The following pattern matches a function C<foo()> which may contain
1947 balanced parentheses as the argument.
1948
1949   $re = qr{ (                   # paren group 1 (full function)
1950               foo
1951               (                 # paren group 2 (parens)
1952                 \(
1953                   (             # paren group 3 (contents of parens)
1954                   (?:
1955                    (?> [^()]+ ) # Non-parens without backtracking
1956                   |
1957                    (?2)         # Recurse to start of paren group 2
1958                   )*
1959                   )
1960                 \)
1961               )
1962             )
1963           }x;
1964
1965 If the pattern was used as follows
1966
1967     'foo(bar(baz)+baz(bop))'=~/$re/
1968         and print "\$1 = $1\n",
1969                   "\$2 = $2\n",
1970                   "\$3 = $3\n";
1971
1972 the output produced should be the following:
1973
1974     $1 = foo(bar(baz)+baz(bop))
1975     $2 = (bar(baz)+baz(bop))
1976     $3 = bar(baz)+baz(bop)
1977
1978 If there is no corresponding capture group defined, then it is a
1979 fatal error.  Recursing deeply without consuming any input string will
1980 also result in a fatal error.  The depth at which that happens is
1981 compiled into perl, so it can be changed with a custom build.
1982
1983 The following shows how using negative indexing can make it
1984 easier to embed recursive patterns inside of a C<qr//> construct
1985 for later use:
1986
1987     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1988     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1989        # do something here...
1990     }
1991
1992 B<Note> that this pattern does not behave the same way as the equivalent
1993 PCRE or Python construct of the same form. In Perl you can backtrack into
1994 a recursed group, in PCRE and Python the recursed into group is treated
1995 as atomic. Also, modifiers are resolved at compile time, so constructs
1996 like C<(?i:(?1))> or C<(?:(?i)(?1))> do not affect how the sub-pattern will
1997 be processed.
1998
1999 =item C<(?&I<NAME>)>
2000 X<(?&NAME)>
2001
2002 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
2003 parenthesis to recurse to is determined by name. If multiple parentheses have
2004 the same name, then it recurses to the leftmost.
2005
2006 It is an error to refer to a name that is not declared somewhere in the
2007 pattern.
2008
2009 B<NOTE:> In order to make things easier for programmers with experience
2010 with the Python or PCRE regex engines the pattern C<< (?P>I<NAME>) >>
2011 may be used instead of C<< (?&I<NAME>) >>.
2012
2013 =item C<(?(I<condition>)I<yes-pattern>|I<no-pattern>)>
2014 X<(?()>
2015
2016 =item C<(?(I<condition>)I<yes-pattern>)>
2017
2018 Conditional expression. Matches I<yes-pattern> if I<condition> yields
2019 a true value, matches I<no-pattern> otherwise. A missing pattern always
2020 matches.
2021
2022 C<(I<condition>)> should be one of:
2023
2024 =over 4
2025
2026 =item an integer in parentheses
2027
2028 (which is valid if the corresponding pair of parentheses
2029 matched);
2030
2031 =item a lookahead/lookbehind/evaluate zero-width assertion;
2032
2033 =item a name in angle brackets or single quotes
2034
2035 (which is valid if a group with the given name matched);
2036
2037 =item the special symbol C<(R)>
2038
2039 (true when evaluated inside of recursion or eval).  Additionally the
2040 C<"R"> may be
2041 followed by a number, (which will be true when evaluated when recursing
2042 inside of the appropriate group), or by C<&I<NAME>>, in which case it will
2043 be true only when evaluated during recursion in the named group.
2044
2045 =back
2046
2047 Here's a summary of the possible predicates:
2048
2049 =over 4
2050
2051 =item C<(1)> C<(2)> ...
2052
2053 Checks if the numbered capturing group has matched something.
2054 Full syntax: C<< (?(1)then|else) >>
2055
2056 =item C<(E<lt>I<NAME>E<gt>)> C<('I<NAME>')>
2057
2058 Checks if a group with the given name has matched something.
2059 Full syntax: C<< (?(<name>)then|else) >>
2060
2061 =item C<(?=...)> C<(?!...)> C<(?<=...)> C<(?<!...)>
2062
2063 Checks whether the pattern matches (or does not match, for the C<"!">
2064 variants).
2065 Full syntax: C<< (?(?=I<lookahead>)I<then>|I<else>) >>
2066
2067 =item C<(?{ I<CODE> })>
2068
2069 Treats the return value of the code block as the condition.
2070 Full syntax: C<< (?(?{ I<code> })I<then>|I<else>) >>
2071
2072 =item C<(R)>
2073
2074 Checks if the expression has been evaluated inside of recursion.
2075 Full syntax: C<< (?(R)I<then>|I<else>) >>
2076
2077 =item C<(R1)> C<(R2)> ...
2078
2079 Checks if the expression has been evaluated while executing directly
2080 inside of the n-th capture group. This check is the regex equivalent of
2081
2082   if ((caller(0))[3] eq 'subname') { ... }
2083
2084 In other words, it does not check the full recursion stack.
2085
2086 Full syntax: C<< (?(R1)I<then>|I<else>) >>
2087
2088 =item C<(R&I<NAME>)>
2089
2090 Similar to C<(R1)>, this predicate checks to see if we're executing
2091 directly inside of the leftmost group with a given name (this is the same
2092 logic used by C<(?&I<NAME>)> to disambiguate). It does not check the full
2093 stack, but only the name of the innermost active recursion.
2094 Full syntax: C<< (?(R&I<name>)I<then>|I<else>) >>
2095
2096 =item C<(DEFINE)>
2097
2098 In this case, the yes-pattern is never directly executed, and no
2099 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
2100 See below for details.
2101 Full syntax: C<< (?(DEFINE)I<definitions>...) >>
2102
2103 =back
2104
2105 For example:
2106
2107     m{ ( \( )?
2108        [^()]+
2109        (?(1) \) )
2110      }x
2111
2112 matches a chunk of non-parentheses, possibly included in parentheses
2113 themselves.
2114
2115 A special form is the C<(DEFINE)> predicate, which never executes its
2116 yes-pattern directly, and does not allow a no-pattern. This allows one to
2117 define subpatterns which will be executed only by the recursion mechanism.
2118 This way, you can define a set of regular expression rules that can be
2119 bundled into any pattern you choose.
2120
2121 It is recommended that for this usage you put the DEFINE block at the
2122 end of the pattern, and that you name any subpatterns defined within it.
2123
2124 Also, it's worth noting that patterns defined this way probably will
2125 not be as efficient, as the optimizer is not very clever about
2126 handling them.
2127
2128 An example of how this might be used is as follows:
2129
2130   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
2131    (?(DEFINE)
2132      (?<NAME_PAT>....)
2133      (?<ADDRESS_PAT>....)
2134    )/x
2135
2136 Note that capture groups matched inside of recursion are not accessible
2137 after the recursion returns, so the extra layer of capturing groups is
2138 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
2139 C<$+{NAME}> would be.
2140
2141 Finally, keep in mind that subpatterns created inside a DEFINE block
2142 count towards the absolute and relative number of captures, so this:
2143
2144     my @captures = "a" =~ /(.)                  # First capture
2145                            (?(DEFINE)
2146                                (?<EXAMPLE> 1 )  # Second capture
2147                            )/x;
2148     say scalar @captures;
2149
2150 Will output 2, not 1. This is particularly important if you intend to
2151 compile the definitions with the C<qr//> operator, and later
2152 interpolate them in another pattern.
2153
2154 =item C<< (?>I<pattern>) >>
2155
2156 =item C<< (*atomic:I<pattern>) >>
2157 X<(?E<gt>pattern)>
2158 X<(*atomic>
2159 X<backtrack> X<backtracking> X<atomic> X<possessive>
2160
2161 An "independent" subexpression, one which matches the substring
2162 that a standalone I<pattern> would match if anchored at the given
2163 position, and it matches I<nothing other than this substring>.  This
2164 construct is useful for optimizations of what would otherwise be
2165 "eternal" matches, because it will not backtrack (see L</"Backtracking">).
2166 It may also be useful in places where the "grab all you can, and do not
2167 give anything back" semantic is desirable.
2168
2169 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
2170 (anchored at the beginning of string, as above) will match I<all>
2171 characters C<"a"> at the beginning of string, leaving no C<"a"> for
2172 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
2173 since the match of the subgroup C<a*> is influenced by the following
2174 group C<ab> (see L</"Backtracking">).  In particular, C<a*> inside
2175 C<a*ab> will match fewer characters than a standalone C<a*>, since
2176 this makes the tail match.
2177
2178 C<< (?>I<pattern>) >> does not disable backtracking altogether once it has
2179 matched. It is still possible to backtrack past the construct, but not
2180 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
2181
2182 An effect similar to C<< (?>I<pattern>) >> may be achieved by writing
2183 C<(?=(I<pattern>))\g{-1}>.  This matches the same substring as a standalone
2184 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
2185 makes a zero-length assertion into an analogue of C<< (?>...) >>.
2186 (The difference between these two constructs is that the second one
2187 uses a capturing group, thus shifting ordinals of backreferences
2188 in the rest of a regular expression.)
2189
2190 Consider this pattern:
2191
2192     m{ \(
2193           (
2194             [^()]+           # x+
2195           |
2196             \( [^()]* \)
2197           )+
2198        \)
2199      }x
2200
2201 That will efficiently match a nonempty group with matching parentheses
2202 two levels deep or less.  However, if there is no such group, it
2203 will take virtually forever on a long string.  That's because there
2204 are so many different ways to split a long string into several
2205 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
2206 to a subpattern of the above pattern.  Consider how the pattern
2207 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
2208 seconds, but that each extra letter doubles this time.  This
2209 exponential performance will make it appear that your program has
2210 hung.  However, a tiny change to this pattern
2211
2212     m{ \(
2213           (
2214             (?> [^()]+ )        # change x+ above to (?> x+ )
2215           |
2216             \( [^()]* \)
2217           )+
2218        \)
2219      }x
2220
2221 which uses C<< (?>...) >> matches exactly when the one above does (verifying
2222 this yourself would be a productive exercise), but finishes in a fourth
2223 the time when used on a similar string with 1000000 C<"a">s.  Be aware,
2224 however, that, when this construct is followed by a
2225 quantifier, it currently triggers a warning message under
2226 the C<use warnings> pragma or B<-w> switch saying it
2227 C<"matches null string many times in regex">.
2228
2229 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
2230 effect may be achieved by negative lookahead, as in C<[^()]+ (?! [^()] )>.
2231 This was only 4 times slower on a string with 1000000 C<"a">s.
2232
2233 The "grab all you can, and do not give anything back" semantic is desirable
2234 in many situations where on the first sight a simple C<()*> looks like
2235 the correct solution.  Suppose we parse text with comments being delimited
2236 by C<"#"> followed by some optional (horizontal) whitespace.  Contrary to
2237 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
2238 the comment delimiter, because it may "give up" some whitespace if
2239 the remainder of the pattern can be made to match that way.  The correct
2240 answer is either one of these:
2241
2242     (?>#[ \t]*)
2243     #[ \t]*(?![ \t])
2244
2245 For example, to grab non-empty comments into C<$1>, one should use either
2246 one of these:
2247
2248     / (?> \# [ \t]* ) (        .+ ) /x;
2249     /     \# [ \t]*   ( [^ \t] .* ) /x;
2250
2251 Which one you pick depends on which of these expressions better reflects
2252 the above specification of comments.
2253
2254 In some literature this construct is called "atomic matching" or
2255 "possessive matching".
2256
2257 Possessive quantifiers are equivalent to putting the item they are applied
2258 to inside of one of these constructs. The following equivalences apply:
2259
2260     Quantifier Form     Bracketing Form
2261     ---------------     ---------------
2262     PAT*+               (?>PAT*)
2263     PAT++               (?>PAT+)
2264     PAT?+               (?>PAT?)
2265     PAT{min,max}+       (?>PAT{min,max})
2266
2267 Nested C<(?E<gt>...)> constructs are not no-ops, even if at first glance
2268 they might seem to be.  This is because the nested C<(?E<gt>...)> can
2269 restrict internal backtracking that otherwise might occur.  For example,
2270
2271  "abc" =~ /(?>a[bc]*c)/
2272
2273 matches, but
2274
2275  "abc" =~ /(?>a(?>[bc]*)c)/
2276
2277 does not.
2278
2279 The alphabetic form (C<(*atomic:...)>) is experimental; using it
2280 yields a warning in the C<experimental::alpha_assertions> category.
2281
2282 =item C<(?[ ])>
2283
2284 See L<perlrecharclass/Extended Bracketed Character Classes>.
2285
2286 Note that this feature is currently L<experimental|perlpolicy/experimental>;
2287 using it yields a warning in the C<experimental::regex_sets> category.
2288
2289 =back
2290
2291 =head2 Backtracking
2292 X<backtrack> X<backtracking>
2293
2294 NOTE: This section presents an abstract approximation of regular
2295 expression behavior.  For a more rigorous (and complicated) view of
2296 the rules involved in selecting a match among possible alternatives,
2297 see L</Combining RE Pieces>.
2298
2299 A fundamental feature of regular expression matching involves the
2300 notion called I<backtracking>, which is currently used (when needed)
2301 by all regular non-possessive expression quantifiers, namely C<"*">, C<*?>, C<"+">,
2302 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2303 internally, but the general principle outlined here is valid.
2304
2305 For a regular expression to match, the I<entire> regular expression must
2306 match, not just part of it.  So if the beginning of a pattern containing a
2307 quantifier succeeds in a way that causes later parts in the pattern to
2308 fail, the matching engine backs up and recalculates the beginning
2309 part--that's why it's called backtracking.
2310
2311 Here is an example of backtracking:  Let's say you want to find the
2312 word following "foo" in the string "Food is on the foo table.":
2313
2314     $_ = "Food is on the foo table.";
2315     if ( /\b(foo)\s+(\w+)/i ) {
2316         print "$2 follows $1.\n";
2317     }
2318
2319 When the match runs, the first part of the regular expression (C<\b(foo)>)
2320 finds a possible match right at the beginning of the string, and loads up
2321 C<$1> with "Foo".  However, as soon as the matching engine sees that there's
2322 no whitespace following the "Foo" that it had saved in C<$1>, it realizes its
2323 mistake and starts over again one character after where it had the
2324 tentative match.  This time it goes all the way until the next occurrence
2325 of "foo". The complete regular expression matches this time, and you get
2326 the expected output of "table follows foo."
2327
2328 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2329 everything between "foo" and "bar".  Initially, you write something
2330 like this:
2331
2332     $_ =  "The food is under the bar in the barn.";
2333     if ( /foo(.*)bar/ ) {
2334         print "got <$1>\n";
2335     }
2336
2337 Which perhaps unexpectedly yields:
2338
2339   got <d is under the bar in the >
2340
2341 That's because C<.*> was greedy, so you get everything between the
2342 I<first> "foo" and the I<last> "bar".  Here it's more effective
2343 to use minimal matching to make sure you get the text between a "foo"
2344 and the first "bar" thereafter.
2345
2346     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2347   got <d is under the >
2348
2349 Here's another example. Let's say you'd like to match a number at the end
2350 of a string, and you also want to keep the preceding part of the match.
2351 So you write this:
2352
2353     $_ = "I have 2 numbers: 53147";
2354     if ( /(.*)(\d*)/ ) {                                # Wrong!
2355         print "Beginning is <$1>, number is <$2>.\n";
2356     }
2357
2358 That won't work at all, because C<.*> was greedy and gobbled up the
2359 whole string. As C<\d*> can match on an empty string the complete
2360 regular expression matched successfully.
2361
2362     Beginning is <I have 2 numbers: 53147>, number is <>.
2363
2364 Here are some variants, most of which don't work:
2365
2366     $_ = "I have 2 numbers: 53147";
2367     @pats = qw{
2368         (.*)(\d*)
2369         (.*)(\d+)
2370         (.*?)(\d*)
2371         (.*?)(\d+)
2372         (.*)(\d+)$
2373         (.*?)(\d+)$
2374         (.*)\b(\d+)$
2375         (.*\D)(\d+)$
2376     };
2377
2378     for $pat (@pats) {
2379         printf "%-12s ", $pat;
2380         if ( /$pat/ ) {
2381             print "<$1> <$2>\n";
2382         } else {
2383             print "FAIL\n";
2384         }
2385     }
2386
2387 That will print out:
2388
2389     (.*)(\d*)    <I have 2 numbers: 53147> <>
2390     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2391     (.*?)(\d*)   <> <>
2392     (.*?)(\d+)   <I have > <2>
2393     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2394     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2395     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2396     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2397
2398 As you see, this can be a bit tricky.  It's important to realize that a
2399 regular expression is merely a set of assertions that gives a definition
2400 of success.  There may be 0, 1, or several different ways that the
2401 definition might succeed against a particular string.  And if there are
2402 multiple ways it might succeed, you need to understand backtracking to
2403 know which variety of success you will achieve.
2404
2405 When using lookahead assertions and negations, this can all get even
2406 trickier.  Imagine you'd like to find a sequence of non-digits not
2407 followed by "123".  You might try to write that as
2408
2409     $_ = "ABC123";
2410     if ( /^\D*(?!123)/ ) {                # Wrong!
2411         print "Yup, no 123 in $_\n";
2412     }
2413
2414 But that isn't going to match; at least, not the way you're hoping.  It
2415 claims that there is no 123 in the string.  Here's a clearer picture of
2416 why that pattern matches, contrary to popular expectations:
2417
2418     $x = 'ABC123';
2419     $y = 'ABC445';
2420
2421     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2422     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2423
2424     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2425     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2426
2427 This prints
2428
2429     2: got ABC
2430     3: got AB
2431     4: got ABC
2432
2433 You might have expected test 3 to fail because it seems to a more
2434 general purpose version of test 1.  The important difference between
2435 them is that test 3 contains a quantifier (C<\D*>) and so can use
2436 backtracking, whereas test 1 will not.  What's happening is
2437 that you've asked "Is it true that at the start of C<$x>, following 0 or more
2438 non-digits, you have something that's not 123?"  If the pattern matcher had
2439 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2440 fail.
2441
2442 The search engine will initially match C<\D*> with "ABC".  Then it will
2443 try to match C<(?!123)> with "123", which fails.  But because
2444 a quantifier (C<\D*>) has been used in the regular expression, the
2445 search engine can backtrack and retry the match differently
2446 in the hope of matching the complete regular expression.
2447
2448 The pattern really, I<really> wants to succeed, so it uses the
2449 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2450 time.  Now there's indeed something following "AB" that is not
2451 "123".  It's "C123", which suffices.
2452
2453 We can deal with this by using both an assertion and a negation.
2454 We'll say that the first part in C<$1> must be followed both by a digit
2455 and by something that's not "123".  Remember that the lookaheads
2456 are zero-width expressions--they only look, but don't consume any
2457 of the string in their match.  So rewriting this way produces what
2458 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2459
2460     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2461     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2462
2463     6: got ABC
2464
2465 In other words, the two zero-width assertions next to each other work as though
2466 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2467 matches only if you're at the beginning of the line AND the end of the
2468 line simultaneously.  The deeper underlying truth is that juxtaposition in
2469 regular expressions always means AND, except when you write an explicit OR
2470 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2471 although the attempted matches are made at different positions because "a"
2472 is not a zero-width assertion, but a one-width assertion.
2473
2474 B<WARNING>: Particularly complicated regular expressions can take
2475 exponential time to solve because of the immense number of possible
2476 ways they can use backtracking to try for a match.  For example, without
2477 internal optimizations done by the regular expression engine, this will
2478 take a painfully long time to run:
2479
2480     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2481
2482 And if you used C<"*">'s in the internal groups instead of limiting them
2483 to 0 through 5 matches, then it would take forever--or until you ran
2484 out of stack space.  Moreover, these internal optimizations are not
2485 always applicable.  For example, if you put C<{0,5}> instead of C<"*">
2486 on the external group, no current optimization is applicable, and the
2487 match takes a long time to finish.
2488
2489 A powerful tool for optimizing such beasts is what is known as an
2490 "independent group",
2491 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2492 zero-length lookahead/lookbehind assertions will not backtrack to make
2493 the tail match, since they are in "logical" context: only
2494 whether they match is considered relevant.  For an example
2495 where side-effects of lookahead I<might> have influenced the
2496 following match, see L</C<< (?>pattern) >>>.
2497
2498 =head2 Script Runs
2499 X<(*script_run:...)> X<(sr:...)>
2500 X<(*atomic_script_run:...)> X<(asr:...)>
2501
2502 A script run is basically a sequence of characters, all from the same
2503 Unicode script (see L<perlunicode/Scripts>), such as Latin or Greek.  In
2504 most places a single word would never be written in multiple scripts,
2505 unless it is a spoofing attack.  An infamous example, is
2506
2507  paypal.com
2508
2509 Those letters could all be Latin (as in the example just above), or they
2510 could be all Cyrillic (except for the dot), or they could be a mixture
2511 of the two.  In the case of an internet address the C<.com> would be in
2512 Latin, And any Cyrillic ones would cause it to be a mixture, not a
2513 script run.  Someone clicking on such a link would not be directed to
2514 the real Paypal website, but an attacker would craft a look-alike one to
2515 attempt to gather sensitive information from the person.
2516
2517 Starting in Perl 5.28, it is now easy to detect strings that aren't
2518 script runs.  Simply enclose just about any pattern like either of
2519 these:
2520
2521  (*script_run:pattern)
2522  (*sr:pattern)
2523
2524 What happens is that after I<pattern> succeeds in matching, it is
2525 subjected to the additional criterion that every character in it must be
2526 from the same script (see exceptions below).  If this isn't true,
2527 backtracking occurs until something all in the same script is found that
2528 matches, or all possibilities are exhausted.  This can cause a lot of
2529 backtracking, but generally, only malicious input will result in this,
2530 though the slow down could cause a denial of service attack.  If your
2531 needs permit, it is best to make the pattern atomic to cut down on the
2532 amount of backtracking.  This is so likely to be what you want, that
2533 instead of writing this:
2534
2535  (*script_run:(?>pattern))
2536
2537 you can write either of these:
2538
2539  (*atomic_script_run:pattern)
2540  (*asr:pattern)
2541
2542 (See L</C<(?E<gt>I<pattern>)>>.)
2543
2544 In Taiwan, Japan, and Korea, it is common for text to have a mixture of
2545 characters from their native scripts and base Chinese.  Perl follows
2546 Unicode's UTS 39 (L<http://unicode.org/reports/tr39/>) Unicode Security
2547 Mechanisms in allowing such mixtures.  For example, the Japanese scripts
2548 Katakana and Hiragana are commonly mixed together in practice, along
2549 with some Chinese characters, and hence are treated as being in a single
2550 script run by Perl.
2551
2552 The rules used for matching decimal digits are somewhat different.  Many
2553 scripts have their own sets of digits equivalent to the Western C<0>
2554 through C<9> ones.  A few, such as Arabic, have more than one set.  For
2555 a string to be considered a script run, all digits in it must come from
2556 the same set, as determined by the first digit encountered. The ASCII
2557 C<[0-9]> are accepted as being in any script, even those that have their
2558 own set.  This is because these are often used in commerce even in such
2559 scripts.  But any mixing of the ASCII and other digits will cause the
2560 sequence to not be a script run, failing the match.  As an example,
2561
2562  qr/(*script_run: \d+ \b )/x
2563
2564 guarantees that the digits matched will all be from the same set of 10.
2565 You won't get a look-alike digit from a different script that has a
2566 different value than what it appears to be.
2567
2568 Unicode has three pseudo scripts that are handled specially.
2569
2570 "Unknown" is applied to code points whose meaning has yet to be
2571 determined.  Perl currently will match as a script run, any single
2572 character string consisting of one of these code points.  But any string
2573 longer than one code point containing one of these will not be
2574 considered a script run.
2575
2576 "Inherited" is applied to characters that modify another, such as an
2577 accent of some type.  These are considered to be in the script of the
2578 master character, and so never cause a script run to not match.
2579
2580 The other one is "Common".  This consists of mostly punctuation, emoji,
2581 and characters used in mathematics and music, and the ASCII digits C<0>
2582 through C<9>.  These characters can appear intermixed in text in many of
2583 the world's scripts.  These also don't cause a script run to not match,
2584 except any ASCII digits encountered have to obey the decimal digit rules
2585 described above.
2586
2587 This construct is non-capturing.  You can add parentheses to I<pattern>
2588 to capture, if desired.  You will have to do this if you plan to use
2589 L</(*ACCEPT) (*ACCEPT:arg)> and not have it bypass the script run
2590 checking.
2591
2592 This feature is experimental, and the exact syntax and details of
2593 operation are subject to change; using it yields a warning in the
2594 C<experimental::script_run> category.
2595
2596 The C<Script_Extensions> property as modified by UTS 39
2597 (L<http://unicode.org/reports/tr39/>) is used as the basis for this
2598 feature.
2599
2600 To summarize,
2601
2602 =over 4
2603
2604 =item *
2605
2606 All length 0 or length 1 sequences are script runs.
2607
2608 =item *
2609
2610 A longer sequence is a script run if and only if B<all> of the following
2611 conditions are met:
2612
2613 Z<>
2614
2615 =over
2616
2617 =item 1
2618
2619 No code point in the sequence has the C<Script_Extension> property of
2620 C<Unknown>.
2621
2622 This currently means that all code points in the sequence have been
2623 assigned by Unicode to be characters that aren't private use nor
2624 surrogate code points.
2625
2626 =item 2
2627
2628 All characters in the sequence come from the Common script and/or the
2629 Inherited script and/or a single other script.
2630
2631 The script of a character is determined by the C<Script_Extensions>
2632 property as modified by UTS 39 (L<http://unicode.org/reports/tr39/>), as
2633 described above.
2634
2635 =item 3
2636
2637 All decimal digits in the sequence come from the same block of 10
2638 consecutive digits.
2639
2640 =back
2641
2642 =back
2643
2644 =head2 Special Backtracking Control Verbs
2645
2646 These special patterns are generally of the form C<(*I<VERB>:I<ARG>)>. Unless
2647 otherwise stated the I<ARG> argument is optional; in some cases, it is
2648 mandatory.
2649
2650 Any pattern containing a special backtracking verb that allows an argument
2651 has the special behaviour that when executed it sets the current package's
2652 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
2653 rules apply:
2654
2655 On failure, the C<$REGERROR> variable will be set to the I<ARG> value of the
2656 verb pattern, if the verb was involved in the failure of the match. If the
2657 I<ARG> part of the pattern was omitted, then C<$REGERROR> will be set to the
2658 name of the last C<(*MARK:I<NAME>)> pattern executed, or to TRUE if there was
2659 none. Also, the C<$REGMARK> variable will be set to FALSE.
2660
2661 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
2662 the C<$REGMARK> variable will be set to the name of the last
2663 C<(*MARK:I<NAME>)> pattern executed.  See the explanation for the
2664 C<(*MARK:I<NAME>)> verb below for more details.
2665
2666 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
2667 and most other regex-related variables. They are not local to a scope, nor
2668 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
2669 They are set in the package containing the code that I<executed> the regex
2670 (rather than the one that compiled it, where those differ).  If necessary, you
2671 can use C<local> to localize changes to these variables to a specific scope
2672 before executing a regex.
2673
2674 If a pattern does not contain a special backtracking verb that allows an
2675 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
2676
2677 =over 3
2678
2679 =item Verbs
2680
2681 =over 4
2682
2683 =item C<(*PRUNE)> C<(*PRUNE:I<NAME>)>
2684 X<(*PRUNE)> X<(*PRUNE:NAME)>
2685
2686 This zero-width pattern prunes the backtracking tree at the current point
2687 when backtracked into on failure. Consider the pattern C</I<A> (*PRUNE) I<B>/>,
2688 where I<A> and I<B> are complex patterns. Until the C<(*PRUNE)> verb is reached,
2689 I<A> may backtrack as necessary to match. Once it is reached, matching
2690 continues in I<B>, which may also backtrack as necessary; however, should B
2691 not match, then no further backtracking will take place, and the pattern
2692 will fail outright at the current starting position.
2693
2694 The following example counts all the possible matching strings in a
2695 pattern (without actually matching any of them).
2696
2697     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
2698     print "Count=$count\n";
2699
2700 which produces:
2701
2702     aaab
2703     aaa
2704     aa
2705     a
2706     aab
2707     aa
2708     a
2709     ab
2710     a
2711     Count=9
2712
2713 If we add a C<(*PRUNE)> before the count like the following
2714
2715     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
2716     print "Count=$count\n";
2717
2718 we prevent backtracking and find the count of the longest matching string
2719 at each matching starting point like so:
2720
2721     aaab
2722     aab
2723     ab
2724     Count=3
2725
2726 Any number of C<(*PRUNE)> assertions may be used in a pattern.
2727
2728 See also C<<< L<< /(?>I<pattern>) >> >>> and possessive quantifiers for
2729 other ways to
2730 control backtracking. In some cases, the use of C<(*PRUNE)> can be
2731 replaced with a C<< (?>pattern) >> with no functional difference; however,
2732 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
2733 C<< (?>pattern) >> alone.
2734
2735 =item C<(*SKIP)> C<(*SKIP:I<NAME>)>
2736 X<(*SKIP)>
2737
2738 This zero-width pattern is similar to C<(*PRUNE)>, except that on
2739 failure it also signifies that whatever text that was matched leading up
2740 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
2741 of this pattern. This effectively means that the regex engine "skips" forward
2742 to this position on failure and tries to match again, (assuming that
2743 there is sufficient room to match).
2744
2745 The name of the C<(*SKIP:I<NAME>)> pattern has special significance. If a
2746 C<(*MARK:I<NAME>)> was encountered while matching, then it is that position
2747 which is used as the "skip point". If no C<(*MARK)> of that name was
2748 encountered, then the C<(*SKIP)> operator has no effect. When used
2749 without a name the "skip point" is where the match point was when
2750 executing the C<(*SKIP)> pattern.
2751
2752 Compare the following to the examples in C<(*PRUNE)>; note the string
2753 is twice as long:
2754
2755  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
2756  print "Count=$count\n";
2757
2758 outputs
2759
2760     aaab
2761     aaab
2762     Count=2
2763
2764 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
2765 executed, the next starting point will be where the cursor was when the
2766 C<(*SKIP)> was executed.
2767
2768 =item C<(*MARK:I<NAME>)> C<(*:I<NAME>)>
2769 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
2770
2771 This zero-width pattern can be used to mark the point reached in a string
2772 when a certain part of the pattern has been successfully matched. This
2773 mark may be given a name. A later C<(*SKIP)> pattern will then skip
2774 forward to that point if backtracked into on failure. Any number of
2775 C<(*MARK)> patterns are allowed, and the I<NAME> portion may be duplicated.
2776
2777 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:I<NAME>)>
2778 can be used to "label" a pattern branch, so that after matching, the
2779 program can determine which branches of the pattern were involved in the
2780 match.
2781
2782 When a match is successful, the C<$REGMARK> variable will be set to the
2783 name of the most recently executed C<(*MARK:I<NAME>)> that was involved
2784 in the match.
2785
2786 This can be used to determine which branch of a pattern was matched
2787 without using a separate capture group for each branch, which in turn
2788 can result in a performance improvement, as perl cannot optimize
2789 C</(?:(x)|(y)|(z))/> as efficiently as something like
2790 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
2791
2792 When a match has failed, and unless another verb has been involved in
2793 failing the match and has provided its own name to use, the C<$REGERROR>
2794 variable will be set to the name of the most recently executed
2795 C<(*MARK:I<NAME>)>.
2796
2797 See L</(*SKIP)> for more details.
2798
2799 As a shortcut C<(*MARK:I<NAME>)> can be written C<(*:I<NAME>)>.
2800
2801 =item C<(*THEN)> C<(*THEN:I<NAME>)>
2802
2803 This is similar to the "cut group" operator C<::> from Perl 6.  Like
2804 C<(*PRUNE)>, this verb always matches, and when backtracked into on
2805 failure, it causes the regex engine to try the next alternation in the
2806 innermost enclosing group (capturing or otherwise) that has alternations.
2807 The two branches of a C<(?(I<condition>)I<yes-pattern>|I<no-pattern>)> do not
2808 count as an alternation, as far as C<(*THEN)> is concerned.
2809
2810 Its name comes from the observation that this operation combined with the
2811 alternation operator (C<"|">) can be used to create what is essentially a
2812 pattern-based if/then/else block:
2813
2814   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
2815
2816 Note that if this operator is used and NOT inside of an alternation then
2817 it acts exactly like the C<(*PRUNE)> operator.
2818
2819   / A (*PRUNE) B /
2820
2821 is the same as
2822
2823   / A (*THEN) B /
2824
2825 but
2826
2827   / ( A (*THEN) B | C ) /
2828
2829 is not the same as
2830
2831   / ( A (*PRUNE) B | C ) /
2832
2833 as after matching the I<A> but failing on the I<B> the C<(*THEN)> verb will
2834 backtrack and try I<C>; but the C<(*PRUNE)> verb will simply fail.
2835
2836 =item C<(*COMMIT)> C<(*COMMIT:I<args>)>
2837 X<(*COMMIT)>
2838
2839 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
2840 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
2841 into on failure it causes the match to fail outright. No further attempts
2842 to find a valid match by advancing the start pointer will occur again.
2843 For example,
2844
2845  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2846  print "Count=$count\n";
2847
2848 outputs
2849
2850     aaab
2851     Count=1
2852
2853 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
2854 does not match, the regex engine will not try any further matching on the
2855 rest of the string.
2856
2857 =item C<(*FAIL)> C<(*F)> C<(*FAIL:I<arg>)>
2858 X<(*FAIL)> X<(*F)>
2859
2860 This pattern matches nothing and always fails. It can be used to force the
2861 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
2862 fact, C<(?!)> gets optimised into C<(*FAIL)> internally. You can provide
2863 an argument so that if the match fails because of this C<FAIL> directive
2864 the argument can be obtained from C<$REGERROR>.
2865
2866 It is probably useful only when combined with C<(?{})> or C<(??{})>.
2867
2868 =item C<(*ACCEPT)> C<(*ACCEPT:I<arg>)>
2869 X<(*ACCEPT)>
2870
2871 This pattern matches nothing and causes the end of successful matching at
2872 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
2873 whether there is actually more to match in the string. When inside of a
2874 nested pattern, such as recursion, or in a subpattern dynamically generated
2875 via C<(??{})>, only the innermost pattern is ended immediately.
2876
2877 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
2878 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
2879 For instance:
2880
2881   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2882
2883 will match, and C<$1> will be C<AB> and C<$2> will be C<"B">, C<$3> will not
2884 be set. If another branch in the inner parentheses was matched, such as in the
2885 string 'ACDE', then the C<"D"> and C<"E"> would have to be matched as well.
2886
2887 You can provide an argument, which will be available in the var
2888 C<$REGMARK> after the match completes.
2889
2890 =back
2891
2892 =back
2893
2894 =head2 Warning on C<\1> Instead of C<$1>
2895
2896 Some people get too used to writing things like:
2897
2898     $pattern =~ s/(\W)/\\\1/g;
2899
2900 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2901 shocking the
2902 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2903 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2904 the usual double-quoted string means a control-A.  The customary Unix
2905 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2906 of doing that, you get yourself into trouble if you then add an C</e>
2907 modifier.
2908
2909     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2910
2911 Or if you try to do
2912
2913     s/(\d+)/\1000/;
2914
2915 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2916 C<${1}000>.  The operation of interpolation should not be confused
2917 with the operation of matching a backreference.  Certainly they mean two
2918 different things on the I<left> side of the C<s///>.
2919
2920 =head2 Repeated Patterns Matching a Zero-length Substring
2921
2922 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2923
2924 Regular expressions provide a terse and powerful programming language.  As
2925 with most other power tools, power comes together with the ability
2926 to wreak havoc.
2927
2928 A common abuse of this power stems from the ability to make infinite
2929 loops using regular expressions, with something as innocuous as:
2930
2931     'foo' =~ m{ ( o? )* }x;
2932
2933 The C<o?> matches at the beginning of "C<foo>", and since the position
2934 in the string is not moved by the match, C<o?> would match again and again
2935 because of the C<"*"> quantifier.  Another common way to create a similar cycle
2936 is with the looping modifier C</g>:
2937
2938     @matches = ( 'foo' =~ m{ o? }xg );
2939
2940 or
2941
2942     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2943
2944 or the loop implied by C<split()>.
2945
2946 However, long experience has shown that many programming tasks may
2947 be significantly simplified by using repeated subexpressions that
2948 may match zero-length substrings.  Here's a simple example being:
2949
2950     @chars = split //, $string;           # // is not magic in split
2951     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2952
2953 Thus Perl allows such constructs, by I<forcefully breaking
2954 the infinite loop>.  The rules for this are different for lower-level
2955 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2956 ones like the C</g> modifier or C<split()> operator.
2957
2958 The lower-level loops are I<interrupted> (that is, the loop is
2959 broken) when Perl detects that a repeated expression matched a
2960 zero-length substring.   Thus
2961
2962    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2963
2964 is made equivalent to
2965
2966    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2967
2968 For example, this program
2969
2970    #!perl -l
2971    "aaaaab" =~ /
2972      (?:
2973         a                 # non-zero
2974         |                 # or
2975        (?{print "hello"}) # print hello whenever this
2976                           #    branch is tried
2977        (?=(b))            # zero-width assertion
2978      )*  # any number of times
2979     /x;
2980    print $&;
2981    print $1;
2982
2983 prints
2984
2985    hello
2986    aaaaa
2987    b
2988
2989 Notice that "hello" is only printed once, as when Perl sees that the sixth
2990 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2991 the C<"*">.
2992
2993 The higher-level loops preserve an additional state between iterations:
2994 whether the last match was zero-length.  To break the loop, the following
2995 match after a zero-length match is prohibited to have a length of zero.
2996 This prohibition interacts with backtracking (see L</"Backtracking">),
2997 and so the I<second best> match is chosen if the I<best> match is of
2998 zero length.
2999
3000 For example:
3001
3002     $_ = 'bar';
3003     s/\w??/<$&>/g;
3004
3005 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
3006 match given by non-greedy C<??> is the zero-length match, and the I<second
3007 best> match is what is matched by C<\w>.  Thus zero-length matches
3008 alternate with one-character-long matches.
3009
3010 Similarly, for repeated C<m/()/g> the second-best match is the match at the
3011 position one notch further in the string.
3012
3013 The additional state of being I<matched with zero-length> is associated with
3014 the matched string, and is reset by each assignment to C<pos()>.
3015 Zero-length matches at the end of the previous match are ignored
3016 during C<split>.
3017
3018 =head2 Combining RE Pieces
3019
3020 Each of the elementary pieces of regular expressions which were described
3021 before (such as C<ab> or C<\Z>) could match at most one substring
3022 at the given position of the input string.  However, in a typical regular
3023 expression these elementary pieces are combined into more complicated
3024 patterns using combining operators C<ST>, C<S|T>, C<S*> I<etc>.
3025 (in these examples C<"S"> and C<"T"> are regular subexpressions).
3026
3027 Such combinations can include alternatives, leading to a problem of choice:
3028 if we match a regular expression C<a|ab> against C<"abc">, will it match
3029 substring C<"a"> or C<"ab">?  One way to describe which substring is
3030 actually matched is the concept of backtracking (see L</"Backtracking">).
3031 However, this description is too low-level and makes you think
3032 in terms of a particular implementation.
3033
3034 Another description starts with notions of "better"/"worse".  All the
3035 substrings which may be matched by the given regular expression can be
3036 sorted from the "best" match to the "worst" match, and it is the "best"
3037 match which is chosen.  This substitutes the question of "what is chosen?"
3038 by the question of "which matches are better, and which are worse?".
3039
3040 Again, for elementary pieces there is no such question, since at most
3041 one match at a given position is possible.  This section describes the
3042 notion of better/worse for combining operators.  In the description
3043 below C<"S"> and C<"T"> are regular subexpressions.
3044
3045 =over 4
3046
3047 =item C<ST>
3048
3049 Consider two possible matches, C<AB> and C<A'B'>, C<"A"> and C<A'> are
3050 substrings which can be matched by C<"S">, C<"B"> and C<B'> are substrings
3051 which can be matched by C<"T">.
3052
3053 If C<"A"> is a better match for C<"S"> than C<A'>, C<AB> is a better
3054 match than C<A'B'>.
3055
3056 If C<"A"> and C<A'> coincide: C<AB> is a better match than C<AB'> if
3057 C<"B"> is a better match for C<"T"> than C<B'>.
3058
3059 =item C<S|T>
3060
3061 When C<"S"> can match, it is a better match than when only C<"T"> can match.
3062
3063 Ordering of two matches for C<"S"> is the same as for C<"S">.  Similar for
3064 two matches for C<"T">.
3065
3066 =item C<S{REPEAT_COUNT}>
3067
3068 Matches as C<SSS...S> (repeated as many times as necessary).
3069
3070 =item C<S{min,max}>
3071
3072 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
3073
3074 =item C<S{min,max}?>
3075
3076 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
3077
3078 =item C<S?>, C<S*>, C<S+>
3079
3080 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
3081
3082 =item C<S??>, C<S*?>, C<S+?>
3083
3084 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
3085
3086 =item C<< (?>S) >>
3087
3088 Matches the best match for C<"S"> and only that.
3089
3090 =item C<(?=S)>, C<(?<=S)>
3091
3092 Only the best match for C<"S"> is considered.  (This is important only if
3093 C<"S"> has capturing parentheses, and backreferences are used somewhere
3094 else in the whole regular expression.)
3095
3096 =item C<(?!S)>, C<(?<!S)>
3097
3098 For this grouping operator there is no need to describe the ordering, since
3099 only whether or not C<"S"> can match is important.
3100
3101 =item C<(??{ I<EXPR> })>, C<(?I<PARNO>)>
3102
3103 The ordering is the same as for the regular expression which is
3104 the result of I<EXPR>, or the pattern contained by capture group I<PARNO>.
3105
3106 =item C<(?(I<condition>)I<yes-pattern>|I<no-pattern>)>
3107
3108 Recall that which of I<yes-pattern> or I<no-pattern> actually matches is
3109 already determined.  The ordering of the matches is the same as for the
3110 chosen subexpression.
3111
3112 =back
3113
3114 The above recipes describe the ordering of matches I<at a given position>.
3115 One more rule is needed to understand how a match is determined for the
3116 whole regular expression: a match at an earlier position is always better
3117 than a match at a later position.
3118
3119 =head2 Creating Custom RE Engines
3120
3121 As of Perl 5.10.0, one can create custom regular expression engines.  This
3122 is not for the faint of heart, as they have to plug in at the C level.  See
3123 L<perlreapi> for more details.
3124
3125 As an alternative, overloaded constants (see L<overload>) provide a simple
3126 way to extend the functionality of the RE engine, by substituting one
3127 pattern for another.
3128
3129 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
3130 matches at a boundary between whitespace characters and non-whitespace
3131 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
3132 at these positions, so we want to have each C<\Y|> in the place of the
3133 more complicated version.  We can create a module C<customre> to do
3134 this:
3135
3136     package customre;
3137     use overload;
3138
3139     sub import {
3140       shift;
3141       die "No argument to customre::import allowed" if @_;
3142       overload::constant 'qr' => \&convert;
3143     }
3144
3145     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
3146
3147     # We must also take care of not escaping the legitimate \\Y|
3148     # sequence, hence the presence of '\\' in the conversion rules.
3149     my %rules = ( '\\' => '\\\\',
3150                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
3151     sub convert {
3152       my $re = shift;
3153       $re =~ s{
3154                 \\ ( \\ | Y . )
3155               }
3156               { $rules{$1} or invalid($re,$1) }sgex;
3157       return $re;
3158     }
3159
3160 Now C<use customre> enables the new escape in constant regular
3161 expressions, I<i.e.>, those without any runtime variable interpolations.
3162 As documented in L<overload>, this conversion will work only over
3163 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
3164 part of this regular expression needs to be converted explicitly
3165 (but only if the special meaning of C<\Y|> should be enabled inside C<$re>):
3166
3167     use customre;
3168     $re = <>;
3169     chomp $re;
3170     $re = customre::convert $re;
3171     /\Y|$re\Y|/;
3172
3173 =head2 Embedded Code Execution Frequency
3174
3175 The exact rules for how often C<(??{})> and C<(?{})> are executed in a pattern
3176 are unspecified.  In the case of a successful match you can assume that
3177 they DWIM and will be executed in left to right order the appropriate
3178 number of times in the accepting path of the pattern as would any other
3179 meta-pattern.  How non-accepting pathways and match failures affect the
3180 number of times a pattern is executed is specifically unspecified and
3181 may vary depending on what optimizations can be applied to the pattern
3182 and is likely to change from version to version.
3183
3184 For instance in
3185
3186   "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
3187
3188 the exact number of times "a" or "b" are printed out is unspecified for
3189 failure, but you may assume they will be printed at least once during
3190 a successful match, additionally you may assume that if "b" is printed,
3191 it will be preceded by at least one "a".
3192
3193 In the case of branching constructs like the following:
3194
3195   /a(b|(?{ print "a" }))c(?{ print "c" })/;
3196
3197 you can assume that the input "ac" will output "ac", and that "abc"
3198 will output only "c".
3199
3200 When embedded code is quantified, successful matches will call the
3201 code once for each matched iteration of the quantifier.  For
3202 example:
3203
3204   "good" =~ /g(?:o(?{print "o"}))*d/;
3205
3206 will output "o" twice.
3207
3208 =head2 PCRE/Python Support
3209
3210 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
3211 to the regex syntax. While Perl programmers are encouraged to use the
3212 Perl-specific syntax, the following are also accepted:
3213
3214 =over 4
3215
3216 =item C<< (?PE<lt>I<NAME>E<gt>I<pattern>) >>
3217
3218 Define a named capture group. Equivalent to C<< (?<I<NAME>>I<pattern>) >>.
3219
3220 =item C<< (?P=I<NAME>) >>
3221
3222 Backreference to a named capture group. Equivalent to C<< \g{I<NAME>} >>.
3223
3224 =item C<< (?P>I<NAME>) >>
3225
3226 Subroutine call to a named capture group. Equivalent to C<< (?&I<NAME>) >>.
3227
3228 =back
3229
3230 =head1 BUGS
3231
3232 There are a number of issues with regard to case-insensitive matching
3233 in Unicode rules.  See C<"i"> under L</Modifiers> above.
3234
3235 This document varies from difficult to understand to completely
3236 and utterly opaque.  The wandering prose riddled with jargon is
3237 hard to fathom in several places.
3238
3239 This document needs a rewrite that separates the tutorial content
3240 from the reference content.
3241
3242 =head1 SEE ALSO
3243
3244 The syntax of patterns used in Perl pattern matching evolved from those
3245 supplied in the Bell Labs Research Unix 8th Edition (Version 8) regex
3246 routines.  (The code is actually derived (distantly) from Henry
3247 Spencer's freely redistributable reimplementation of those V8 routines.)
3248
3249 L<perlrequick>.
3250
3251 L<perlretut>.
3252
3253 L<perlop/"Regexp Quote-Like Operators">.
3254
3255 L<perlop/"Gory details of parsing quoted constructs">.
3256
3257 L<perlfaq6>.
3258
3259 L<perlfunc/pos>.
3260
3261 L<perllocale>.
3262
3263 L<perlebcdic>.
3264
3265 I<Mastering Regular Expressions> by Jeffrey Friedl, published
3266 by O'Reilly and Associates.