This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
3fd00325975f956309d5d180684717888baebc6e
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Commas should separate elements of the LIST.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your Perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
370 test operators, in a way that C<-f -w -x $file> is equivalent to
371 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
372 the return value of C<-f $file> as an argument to another filetest
373 operator, no special magic will happen.)
374
375 =item abs VALUE
376
377 =item abs
378
379 Returns the absolute value of its argument.
380 If VALUE is omitted, uses C<$_>.
381
382 =item accept NEWSOCKET,GENERICSOCKET
383
384 Accepts an incoming socket connect, just as the accept(2) system call
385 does.  Returns the packed address if it succeeded, false otherwise.
386 See the example in L<perlipc/"Sockets: Client/Server Communication">.
387
388 On systems that support a close-on-exec flag on files, the flag will
389 be set for the newly opened file descriptor, as determined by the
390 value of $^F.  See L<perlvar/$^F>.
391
392 =item alarm SECONDS
393
394 =item alarm
395
396 Arranges to have a SIGALRM delivered to this process after the
397 specified number of wallclock seconds has elapsed.  If SECONDS is not
398 specified, the value stored in C<$_> is used. (On some machines,
399 unfortunately, the elapsed time may be up to one second less or more
400 than you specified because of how seconds are counted, and process
401 scheduling may delay the delivery of the signal even further.)
402
403 Only one timer may be counting at once.  Each call disables the
404 previous timer, and an argument of C<0> may be supplied to cancel the
405 previous timer without starting a new one.  The returned value is the
406 amount of time remaining on the previous timer.
407
408 For delays of finer granularity than one second, you may use Perl's
409 four-argument version of select() leaving the first three arguments
410 undefined, or you might be able to use the C<syscall> interface to
411 access setitimer(2) if your system supports it.  The Time::HiRes
412 module (from CPAN, and starting from Perl 5.8 part of the standard
413 distribution) may also prove useful.
414
415 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
416 (C<sleep> may be internally implemented in your system with C<alarm>)
417
418 If you want to use C<alarm> to time out a system call you need to use an
419 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
420 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
421 restart system calls on some systems.  Using C<eval>/C<die> always works,
422 modulo the caveats given in L<perlipc/"Signals">.
423
424     eval {
425         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
426         alarm $timeout;
427         $nread = sysread SOCKET, $buffer, $size;
428         alarm 0;
429     };
430     if ($@) {
431         die unless $@ eq "alarm\n";   # propagate unexpected errors
432         # timed out
433     }
434     else {
435         # didn't
436     }
437
438 For more information see L<perlipc>.
439
440 =item atan2 Y,X
441
442 Returns the arctangent of Y/X in the range -PI to PI.
443
444 For the tangent operation, you may use the C<Math::Trig::tan>
445 function, or use the familiar relation:
446
447     sub tan { sin($_[0]) / cos($_[0])  }
448
449 =item bind SOCKET,NAME
450
451 Binds a network address to a socket, just as the bind system call
452 does.  Returns true if it succeeded, false otherwise.  NAME should be a
453 packed address of the appropriate type for the socket.  See the examples in
454 L<perlipc/"Sockets: Client/Server Communication">.
455
456 =item binmode FILEHANDLE, LAYER
457
458 =item binmode FILEHANDLE
459
460 Arranges for FILEHANDLE to be read or written in "binary" or "text"
461 mode on systems where the run-time libraries distinguish between
462 binary and text files.  If FILEHANDLE is an expression, the value is
463 taken as the name of the filehandle.  Returns true on success,
464 otherwise it returns C<undef> and sets C<$!> (errno).
465
466 On some systems (in general, DOS and Windows-based systems) binmode()
467 is necessary when you're not working with a text file.  For the sake
468 of portability it is a good idea to always use it when appropriate,
469 and to never use it when it isn't appropriate.  Also, people can
470 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
471
472 In other words: regardless of platform, use binmode() on binary data,
473 like for example images.
474
475 If LAYER is present it is a single string, but may contain multiple
476 directives. The directives alter the behaviour of the file handle.
477 When LAYER is present using binmode on text file makes sense.
478
479 If LAYER is omitted or specified as C<:raw> the filehandle is made
480 suitable for passing binary data. This includes turning off possible CRLF
481 translation and marking it as bytes (as opposed to Unicode characters).
482 Note that, despite what may be implied in I<"Programming Perl"> (the
483 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
484 -- other layers which would affect binary nature of the stream are
485 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
486 PERLIO environment variable.
487
488 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
489 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
490 establish default I/O layers.  See L<open>.
491
492 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
493 in "Programming Perl, 3rd Edition".  However, since the publishing of this
494 book, by many known as "Camel III", the consensus of the naming of this
495 functionality has moved from "discipline" to "layer".  All documentation
496 of this version of Perl therefore refers to "layers" rather than to
497 "disciplines".  Now back to the regularly scheduled documentation...>
498
499 To mark FILEHANDLE as UTF-8, use C<:utf8>.
500
501 In general, binmode() should be called after open() but before any I/O
502 is done on the filehandle.  Calling binmode() will normally flush any
503 pending buffered output data (and perhaps pending input data) on the
504 handle.  An exception to this is the C<:encoding> layer that
505 changes the default character encoding of the handle, see L<open>.
506 The C<:encoding> layer sometimes needs to be called in
507 mid-stream, and it doesn't flush the stream.  The C<:encoding>
508 also implicitly pushes on top of itself the C<:utf8> layer because
509 internally Perl will operate on UTF-8 encoded Unicode characters.
510
511 The operating system, device drivers, C libraries, and Perl run-time
512 system all work together to let the programmer treat a single
513 character (C<\n>) as the line terminator, irrespective of the external
514 representation.  On many operating systems, the native text file
515 representation matches the internal representation, but on some
516 platforms the external representation of C<\n> is made up of more than
517 one character.
518
519 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
520 character to end each line in the external representation of text (even
521 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
522 on Unix and most VMS files). In other systems like OS/2, DOS and the
523 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
524 but what's stored in text files are the two characters C<\cM\cJ>.  That
525 means that, if you don't use binmode() on these systems, C<\cM\cJ>
526 sequences on disk will be converted to C<\n> on input, and any C<\n> in
527 your program will be converted back to C<\cM\cJ> on output.  This is what
528 you want for text files, but it can be disastrous for binary files.
529
530 Another consequence of using binmode() (on some systems) is that
531 special end-of-file markers will be seen as part of the data stream.
532 For systems from the Microsoft family this means that if your binary
533 data contains C<\cZ>, the I/O subsystem will regard it as the end of
534 the file, unless you use binmode().
535
536 binmode() is not only important for readline() and print() operations,
537 but also when using read(), seek(), sysread(), syswrite() and tell()
538 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
539 in L<perlvar> for how to manually set your input and output
540 line-termination sequences.
541
542 =item bless REF,CLASSNAME
543
544 =item bless REF
545
546 This function tells the thingy referenced by REF that it is now an object
547 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
548 is used.  Because a C<bless> is often the last thing in a constructor,
549 it returns the reference for convenience.  Always use the two-argument
550 version if a derived class might inherit the function doing the blessing.
551 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
552 of objects.
553
554 Consider always blessing objects in CLASSNAMEs that are mixed case.
555 Namespaces with all lowercase names are considered reserved for
556 Perl pragmata.  Builtin types have all uppercase names. To prevent
557 confusion, you may wish to avoid such package names as well.  Make sure
558 that CLASSNAME is a true value.
559
560 See L<perlmod/"Perl Modules">.
561
562 =item caller EXPR
563
564 =item caller
565
566 Returns the context of the current subroutine call.  In scalar context,
567 returns the caller's package name if there is a caller, that is, if
568 we're in a subroutine or C<eval> or C<require>, and the undefined value
569 otherwise.  In list context, returns
570
571     ($package, $filename, $line) = caller;
572
573 With EXPR, it returns some extra information that the debugger uses to
574 print a stack trace.  The value of EXPR indicates how many call frames
575 to go back before the current one.
576
577     ($package, $filename, $line, $subroutine, $hasargs,
578     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
579
580 Here $subroutine may be C<(eval)> if the frame is not a subroutine
581 call, but an C<eval>.  In such a case additional elements $evaltext and
582 C<$is_require> are set: C<$is_require> is true if the frame is created by a
583 C<require> or C<use> statement, $evaltext contains the text of the
584 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
585 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
586 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
587 frame.)  $subroutine may also be C<(unknown)> if this particular
588 subroutine happens to have been deleted from the symbol table.
589 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
590 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
591 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
592 between versions of Perl, and are not meant for external use.
593
594 Furthermore, when called from within the DB package, caller returns more
595 detailed information: it sets the list variable C<@DB::args> to be the
596 arguments with which the subroutine was invoked.
597
598 Be aware that the optimizer might have optimized call frames away before
599 C<caller> had a chance to get the information.  That means that C<caller(N)>
600 might not return information about the call frame you expect it do, for
601 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
602 previous time C<caller> was called.
603
604 =item chdir EXPR
605
606 =item chdir FILEHANDLE
607
608 =item chdir DIRHANDLE
609
610 =item chdir
611
612 Changes the working directory to EXPR, if possible. If EXPR is omitted,
613 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
614 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
615 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
616 neither is set, C<chdir> does nothing. It returns true upon success,
617 false otherwise. See the example under C<die>.
618
619 On systems that support fchdir, you might pass a file handle or
620 directory handle as argument.  On systems that don't support fchdir,
621 passing handles produces a fatal error at run time.
622
623 =item chmod LIST
624
625 Changes the permissions of a list of files.  The first element of the
626 list must be the numerical mode, which should probably be an octal
627 number, and which definitely should I<not> be a string of octal digits:
628 C<0644> is okay, C<'0644'> is not.  Returns the number of files
629 successfully changed.  See also L</oct>, if all you have is a string.
630
631     $cnt = chmod 0755, 'foo', 'bar';
632     chmod 0755, @executables;
633     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
634                                              # --w----r-T
635     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
636     $mode = 0644;   chmod $mode, 'foo';      # this is best
637
638 On systems that support fchmod, you might pass file handles among the
639 files.  On systems that don't support fchmod, passing file handles
640 produces a fatal error at run time.
641
642     open(my $fh, "<", "foo");
643     my $perm = (stat $fh)[2] & 07777;
644     chmod($perm | 0600, $fh);
645
646 You can also import the symbolic C<S_I*> constants from the Fcntl
647 module:
648
649     use Fcntl ':mode';
650
651     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
652     # This is identical to the chmod 0755 of the above example.
653
654 =item chomp VARIABLE
655
656 =item chomp( LIST )
657
658 =item chomp
659
660 This safer version of L</chop> removes any trailing string
661 that corresponds to the current value of C<$/> (also known as
662 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
663 number of characters removed from all its arguments.  It's often used to
664 remove the newline from the end of an input record when you're worried
665 that the final record may be missing its newline.  When in paragraph
666 mode (C<$/ = "">), it removes all trailing newlines from the string.
667 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
668 a reference to an integer or the like, see L<perlvar>) chomp() won't
669 remove anything.
670 If VARIABLE is omitted, it chomps C<$_>.  Example:
671
672     while (<>) {
673         chomp;  # avoid \n on last field
674         @array = split(/:/);
675         # ...
676     }
677
678 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
679
680 You can actually chomp anything that's an lvalue, including an assignment:
681
682     chomp($cwd = `pwd`);
683     chomp($answer = <STDIN>);
684
685 If you chomp a list, each element is chomped, and the total number of
686 characters removed is returned.
687
688 If the C<encoding> pragma is in scope then the lengths returned are
689 calculated from the length of C<$/> in Unicode characters, which is not
690 always the same as the length of C<$/> in the native encoding.
691
692 Note that parentheses are necessary when you're chomping anything
693 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
694 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
695 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
696 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
697 as C<chomp($a, $b)>.
698
699 =item chop VARIABLE
700
701 =item chop( LIST )
702
703 =item chop
704
705 Chops off the last character of a string and returns the character
706 chopped.  It is much more efficient than C<s/.$//s> because it neither
707 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
708 If VARIABLE is a hash, it chops the hash's values, but not its keys.
709
710 You can actually chop anything that's an lvalue, including an assignment.
711
712 If you chop a list, each element is chopped.  Only the value of the
713 last C<chop> is returned.
714
715 Note that C<chop> returns the last character.  To return all but the last
716 character, use C<substr($string, 0, -1)>.
717
718 See also L</chomp>.
719
720 =item chown LIST
721
722 Changes the owner (and group) of a list of files.  The first two
723 elements of the list must be the I<numeric> uid and gid, in that
724 order.  A value of -1 in either position is interpreted by most
725 systems to leave that value unchanged.  Returns the number of files
726 successfully changed.
727
728     $cnt = chown $uid, $gid, 'foo', 'bar';
729     chown $uid, $gid, @filenames;
730
731 On systems that support fchown, you might pass file handles among the
732 files.  On systems that don't support fchown, passing file handles
733 produces a fatal error at run time.
734
735 Here's an example that looks up nonnumeric uids in the passwd file:
736
737     print "User: ";
738     chomp($user = <STDIN>);
739     print "Files: ";
740     chomp($pattern = <STDIN>);
741
742     ($login,$pass,$uid,$gid) = getpwnam($user)
743         or die "$user not in passwd file";
744
745     @ary = glob($pattern);      # expand filenames
746     chown $uid, $gid, @ary;
747
748 On most systems, you are not allowed to change the ownership of the
749 file unless you're the superuser, although you should be able to change
750 the group to any of your secondary groups.  On insecure systems, these
751 restrictions may be relaxed, but this is not a portable assumption.
752 On POSIX systems, you can detect this condition this way:
753
754     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
755     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
756
757 =item chr NUMBER
758
759 =item chr
760
761 Returns the character represented by that NUMBER in the character set.
762 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
763 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
764 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
765 backward compatibility reasons (but see L<encoding>).
766
767 Negative values give the Unicode replacement character (chr(0xfffd)),
768 except under the L</bytes> pragma, where low eight bits of the value
769 (truncated to an integer) are used.
770
771 If NUMBER is omitted, uses C<$_>.
772
773 For the reverse, use L</ord>.
774
775 Note that under the C<bytes> pragma the NUMBER is masked to
776 the low eight bits.
777
778 See L<perlunicode> and L<encoding> for more about Unicode.
779
780 =item chroot FILENAME
781
782 =item chroot
783
784 This function works like the system call by the same name: it makes the
785 named directory the new root directory for all further pathnames that
786 begin with a C</> by your process and all its children.  (It doesn't
787 change your current working directory, which is unaffected.)  For security
788 reasons, this call is restricted to the superuser.  If FILENAME is
789 omitted, does a C<chroot> to C<$_>.
790
791 =item close FILEHANDLE
792
793 =item close
794
795 Closes the file or pipe associated with the file handle, returning
796 true only if IO buffers are successfully flushed and closes the system
797 file descriptor.  Closes the currently selected filehandle if the
798 argument is omitted.
799
800 You don't have to close FILEHANDLE if you are immediately going to do
801 another C<open> on it, because C<open> will close it for you.  (See
802 C<open>.)  However, an explicit C<close> on an input file resets the line
803 counter (C<$.>), while the implicit close done by C<open> does not.
804
805 If the file handle came from a piped open, C<close> will additionally
806 return false if one of the other system calls involved fails, or if the
807 program exits with non-zero status.  (If the only problem was that the
808 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
809 also waits for the process executing on the pipe to complete, in case you
810 want to look at the output of the pipe afterwards, and
811 implicitly puts the exit status value of that command into C<$?> and
812 C<${^CHILD_ERROR_NATIVE}>.
813
814 Prematurely closing the read end of a pipe (i.e. before the process
815 writing to it at the other end has closed it) will result in a
816 SIGPIPE being delivered to the writer.  If the other end can't
817 handle that, be sure to read all the data before closing the pipe.
818
819 Example:
820
821     open(OUTPUT, '|sort >foo')  # pipe to sort
822         or die "Can't start sort: $!";
823     #...                        # print stuff to output
824     close OUTPUT                # wait for sort to finish
825         or warn $! ? "Error closing sort pipe: $!"
826                    : "Exit status $? from sort";
827     open(INPUT, 'foo')          # get sort's results
828         or die "Can't open 'foo' for input: $!";
829
830 FILEHANDLE may be an expression whose value can be used as an indirect
831 filehandle, usually the real filehandle name.
832
833 =item closedir DIRHANDLE
834
835 Closes a directory opened by C<opendir> and returns the success of that
836 system call.
837
838 =item connect SOCKET,NAME
839
840 Attempts to connect to a remote socket, just as the connect system call
841 does.  Returns true if it succeeded, false otherwise.  NAME should be a
842 packed address of the appropriate type for the socket.  See the examples in
843 L<perlipc/"Sockets: Client/Server Communication">.
844
845 =item continue BLOCK
846
847 C<continue> is actually a flow control statement rather than a function.  If
848 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
849 C<foreach>), it is always executed just before the conditional is about to
850 be evaluated again, just like the third part of a C<for> loop in C.  Thus
851 it can be used to increment a loop variable, even when the loop has been
852 continued via the C<next> statement (which is similar to the C C<continue>
853 statement).
854
855 C<last>, C<next>, or C<redo> may appear within a C<continue>
856 block.  C<last> and C<redo> will behave as if they had been executed within
857 the main block.  So will C<next>, but since it will execute a C<continue>
858 block, it may be more entertaining.
859
860     while (EXPR) {
861         ### redo always comes here
862         do_something;
863     } continue {
864         ### next always comes here
865         do_something_else;
866         # then back the top to re-check EXPR
867     }
868     ### last always comes here
869
870 Omitting the C<continue> section is semantically equivalent to using an
871 empty one, logically enough.  In that case, C<next> goes directly back
872 to check the condition at the top of the loop.
873
874 =item cos EXPR
875
876 =item cos
877
878 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
879 takes cosine of C<$_>.
880
881 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
882 function, or use this relation:
883
884     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
885
886 =item crypt PLAINTEXT,SALT
887
888 Creates a digest string exactly like the crypt(3) function in the C
889 library (assuming that you actually have a version there that has not
890 been extirpated as a potential munitions).
891
892 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
893 into a short string, called a digest, which is returned.  The same
894 PLAINTEXT and SALT will always return the same string, but there is no
895 (known) way to get the original PLAINTEXT from the hash.  Small
896 changes in the PLAINTEXT or SALT will result in large changes in the
897 digest.
898
899 There is no decrypt function.  This function isn't all that useful for
900 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
901 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
902 primarily used to check if two pieces of text are the same without
903 having to transmit or store the text itself.  An example is checking
904 if a correct password is given.  The digest of the password is stored,
905 not the password itself.  The user types in a password that is
906 crypt()'d with the same salt as the stored digest.  If the two digests
907 match the password is correct.
908
909 When verifying an existing digest string you should use the digest as
910 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
911 to create the digest is visible as part of the digest.  This ensures
912 crypt() will hash the new string with the same salt as the digest.
913 This allows your code to work with the standard L<crypt|/crypt> and
914 with more exotic implementations.  In other words, do not assume
915 anything about the returned string itself, or how many bytes in the
916 digest matter.
917
918 Traditionally the result is a string of 13 bytes: two first bytes of
919 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
920 the first eight bytes of the digest string mattered, but alternative
921 hashing schemes (like MD5), higher level security schemes (like C2),
922 and implementations on non-UNIX platforms may produce different
923 strings.
924
925 When choosing a new salt create a random two character string whose
926 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
927 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
928 characters is just a recommendation; the characters allowed in
929 the salt depend solely on your system's crypt library, and Perl can't
930 restrict what salts C<crypt()> accepts.
931
932 Here's an example that makes sure that whoever runs this program knows
933 their password:
934
935     $pwd = (getpwuid($<))[1];
936
937     system "stty -echo";
938     print "Password: ";
939     chomp($word = <STDIN>);
940     print "\n";
941     system "stty echo";
942
943     if (crypt($word, $pwd) ne $pwd) {
944         die "Sorry...\n";
945     } else {
946         print "ok\n";
947     }
948
949 Of course, typing in your own password to whoever asks you
950 for it is unwise.
951
952 The L<crypt|/crypt> function is unsuitable for hashing large quantities
953 of data, not least of all because you can't get the information
954 back.  Look at the L<Digest> module for more robust algorithms.
955
956 If using crypt() on a Unicode string (which I<potentially> has
957 characters with codepoints above 255), Perl tries to make sense
958 of the situation by trying to downgrade (a copy of the string)
959 the string back to an eight-bit byte string before calling crypt()
960 (on that copy).  If that works, good.  If not, crypt() dies with
961 C<Wide character in crypt>.
962
963 =item dbmclose HASH
964
965 [This function has been largely superseded by the C<untie> function.]
966
967 Breaks the binding between a DBM file and a hash.
968
969 =item dbmopen HASH,DBNAME,MASK
970
971 [This function has been largely superseded by the C<tie> function.]
972
973 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
974 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
975 argument is I<not> a filehandle, even though it looks like one).  DBNAME
976 is the name of the database (without the F<.dir> or F<.pag> extension if
977 any).  If the database does not exist, it is created with protection
978 specified by MASK (as modified by the C<umask>).  If your system supports
979 only the older DBM functions, you may perform only one C<dbmopen> in your
980 program.  In older versions of Perl, if your system had neither DBM nor
981 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
982 sdbm(3).
983
984 If you don't have write access to the DBM file, you can only read hash
985 variables, not set them.  If you want to test whether you can write,
986 either use file tests or try setting a dummy hash entry inside an C<eval>,
987 which will trap the error.
988
989 Note that functions such as C<keys> and C<values> may return huge lists
990 when used on large DBM files.  You may prefer to use the C<each>
991 function to iterate over large DBM files.  Example:
992
993     # print out history file offsets
994     dbmopen(%HIST,'/usr/lib/news/history',0666);
995     while (($key,$val) = each %HIST) {
996         print $key, ' = ', unpack('L',$val), "\n";
997     }
998     dbmclose(%HIST);
999
1000 See also L<AnyDBM_File> for a more general description of the pros and
1001 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1002 rich implementation.
1003
1004 You can control which DBM library you use by loading that library
1005 before you call dbmopen():
1006
1007     use DB_File;
1008     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1009         or die "Can't open netscape history file: $!";
1010
1011 =item defined EXPR
1012
1013 =item defined
1014
1015 Returns a Boolean value telling whether EXPR has a value other than
1016 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1017 checked.
1018
1019 Many operations return C<undef> to indicate failure, end of file,
1020 system error, uninitialized variable, and other exceptional
1021 conditions.  This function allows you to distinguish C<undef> from
1022 other values.  (A simple Boolean test will not distinguish among
1023 C<undef>, zero, the empty string, and C<"0">, which are all equally
1024 false.)  Note that since C<undef> is a valid scalar, its presence
1025 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1026 returns C<undef> when its argument is an empty array, I<or> when the
1027 element to return happens to be C<undef>.
1028
1029 You may also use C<defined(&func)> to check whether subroutine C<&func>
1030 has ever been defined.  The return value is unaffected by any forward
1031 declarations of C<&func>.  Note that a subroutine which is not defined
1032 may still be callable: its package may have an C<AUTOLOAD> method that
1033 makes it spring into existence the first time that it is called -- see
1034 L<perlsub>.
1035
1036 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1037 used to report whether memory for that aggregate has ever been
1038 allocated.  This behavior may disappear in future versions of Perl.
1039 You should instead use a simple test for size:
1040
1041     if (@an_array) { print "has array elements\n" }
1042     if (%a_hash)   { print "has hash members\n"   }
1043
1044 When used on a hash element, it tells you whether the value is defined,
1045 not whether the key exists in the hash.  Use L</exists> for the latter
1046 purpose.
1047
1048 Examples:
1049
1050     print if defined $switch{'D'};
1051     print "$val\n" while defined($val = pop(@ary));
1052     die "Can't readlink $sym: $!"
1053         unless defined($value = readlink $sym);
1054     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1055     $debugging = 0 unless defined $debugging;
1056
1057 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1058 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1059 defined values.  For example, if you say
1060
1061     "ab" =~ /a(.*)b/;
1062
1063 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1064 matched "nothing".  It didn't really fail to match anything.  Rather, it
1065 matched something that happened to be zero characters long.  This is all
1066 very above-board and honest.  When a function returns an undefined value,
1067 it's an admission that it couldn't give you an honest answer.  So you
1068 should use C<defined> only when you're questioning the integrity of what
1069 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1070 what you want.
1071
1072 See also L</undef>, L</exists>, L</ref>.
1073
1074 =item delete EXPR
1075
1076 Given an expression that specifies a hash element, array element, hash slice,
1077 or array slice, deletes the specified element(s) from the hash or array.
1078 In the case of an array, if the array elements happen to be at the end,
1079 the size of the array will shrink to the highest element that tests
1080 true for exists() (or 0 if no such element exists).
1081
1082 Returns a list with the same number of elements as the number of elements
1083 for which deletion was attempted.  Each element of that list consists of
1084 either the value of the element deleted, or the undefined value.  In scalar
1085 context, this means that you get the value of the last element deleted (or
1086 the undefined value if that element did not exist).
1087
1088     %hash = (foo => 11, bar => 22, baz => 33);
1089     $scalar = delete $hash{foo};             # $scalar is 11
1090     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1091     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1092
1093 Deleting from C<%ENV> modifies the environment.  Deleting from
1094 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1095 from a C<tie>d hash or array may not necessarily return anything.
1096
1097 Deleting an array element effectively returns that position of the array
1098 to its initial, uninitialized state.  Subsequently testing for the same
1099 element with exists() will return false.  Also, deleting array elements
1100 in the middle of an array will not shift the index of the elements
1101 after them down.  Use splice() for that.  See L</exists>.
1102
1103 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1104
1105     foreach $key (keys %HASH) {
1106         delete $HASH{$key};
1107     }
1108
1109     foreach $index (0 .. $#ARRAY) {
1110         delete $ARRAY[$index];
1111     }
1112
1113 And so do these:
1114
1115     delete @HASH{keys %HASH};
1116
1117     delete @ARRAY[0 .. $#ARRAY];
1118
1119 But both of these are slower than just assigning the empty list
1120 or undefining %HASH or @ARRAY:
1121
1122     %HASH = ();         # completely empty %HASH
1123     undef %HASH;        # forget %HASH ever existed
1124
1125     @ARRAY = ();        # completely empty @ARRAY
1126     undef @ARRAY;       # forget @ARRAY ever existed
1127
1128 Note that the EXPR can be arbitrarily complicated as long as the final
1129 operation is a hash element, array element,  hash slice, or array slice
1130 lookup:
1131
1132     delete $ref->[$x][$y]{$key};
1133     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1134
1135     delete $ref->[$x][$y][$index];
1136     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1137
1138 =item die LIST
1139
1140 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1141 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1142 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1143 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1144 an C<eval(),> the error message is stuffed into C<$@> and the
1145 C<eval> is terminated with the undefined value.  This makes
1146 C<die> the way to raise an exception.
1147
1148 Equivalent examples:
1149
1150     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1151     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1152
1153 If the last element of LIST does not end in a newline, the current
1154 script line number and input line number (if any) are also printed,
1155 and a newline is supplied.  Note that the "input line number" (also
1156 known as "chunk") is subject to whatever notion of "line" happens to
1157 be currently in effect, and is also available as the special variable
1158 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1159
1160 Hint: sometimes appending C<", stopped"> to your message will cause it
1161 to make better sense when the string C<"at foo line 123"> is appended.
1162 Suppose you are running script "canasta".
1163
1164     die "/etc/games is no good";
1165     die "/etc/games is no good, stopped";
1166
1167 produce, respectively
1168
1169     /etc/games is no good at canasta line 123.
1170     /etc/games is no good, stopped at canasta line 123.
1171
1172 See also exit(), warn(), and the Carp module.
1173
1174 If LIST is empty and C<$@> already contains a value (typically from a
1175 previous eval) that value is reused after appending C<"\t...propagated">.
1176 This is useful for propagating exceptions:
1177
1178     eval { ... };
1179     die unless $@ =~ /Expected exception/;
1180
1181 If LIST is empty and C<$@> contains an object reference that has a
1182 C<PROPAGATE> method, that method will be called with additional file
1183 and line number parameters.  The return value replaces the value in
1184 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1185 were called.
1186
1187 If C<$@> is empty then the string C<"Died"> is used.
1188
1189 die() can also be called with a reference argument.  If this happens to be
1190 trapped within an eval(), $@ contains the reference.  This behavior permits
1191 a more elaborate exception handling implementation using objects that
1192 maintain arbitrary state about the nature of the exception.  Such a scheme
1193 is sometimes preferable to matching particular string values of $@ using
1194 regular expressions.  Here's an example:
1195
1196     use Scalar::Util 'blessed';
1197
1198     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1199     if ($@) {
1200         if (blessed($@) && $@->isa("Some::Module::Exception")) {
1201             # handle Some::Module::Exception
1202         }
1203         else {
1204             # handle all other possible exceptions
1205         }
1206     }
1207
1208 Because perl will stringify uncaught exception messages before displaying
1209 them, you may want to overload stringification operations on such custom
1210 exception objects.  See L<overload> for details about that.
1211
1212 You can arrange for a callback to be run just before the C<die>
1213 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1214 handler will be called with the error text and can change the error
1215 message, if it sees fit, by calling C<die> again.  See
1216 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1217 L<"eval BLOCK"> for some examples.  Although this feature was 
1218 to be run only right before your program was to exit, this is not
1219 currently the case--the C<$SIG{__DIE__}> hook is currently called
1220 even inside eval()ed blocks/strings!  If one wants the hook to do
1221 nothing in such situations, put
1222
1223         die @_ if $^S;
1224
1225 as the first line of the handler (see L<perlvar/$^S>).  Because
1226 this promotes strange action at a distance, this counterintuitive
1227 behavior may be fixed in a future release.
1228
1229 =item do BLOCK
1230
1231 Not really a function.  Returns the value of the last command in the
1232 sequence of commands indicated by BLOCK.  When modified by a loop
1233 modifier, executes the BLOCK once before testing the loop condition.
1234 (On other statements the loop modifiers test the conditional first.)
1235
1236 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1237 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1238 See L<perlsyn> for alternative strategies.
1239
1240 =item do SUBROUTINE(LIST)
1241
1242 This form of subroutine call is deprecated.  See L<perlsub>.
1243
1244 =item do EXPR
1245
1246 Uses the value of EXPR as a filename and executes the contents of the
1247 file as a Perl script.
1248
1249     do 'stat.pl';
1250
1251 is just like
1252
1253     eval `cat stat.pl`;
1254
1255 except that it's more efficient and concise, keeps track of the current
1256 filename for error messages, searches the @INC directories, and updates
1257 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1258 variables.  It also differs in that code evaluated with C<do FILENAME>
1259 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1260 same, however, in that it does reparse the file every time you call it,
1261 so you probably don't want to do this inside a loop.
1262
1263 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1264 error.  If C<do> can read the file but cannot compile it, it
1265 returns undef and sets an error message in C<$@>.   If the file is
1266 successfully compiled, C<do> returns the value of the last expression
1267 evaluated.
1268
1269 Note that inclusion of library modules is better done with the
1270 C<use> and C<require> operators, which also do automatic error checking
1271 and raise an exception if there's a problem.
1272
1273 You might like to use C<do> to read in a program configuration
1274 file.  Manual error checking can be done this way:
1275
1276     # read in config files: system first, then user
1277     for $file ("/share/prog/defaults.rc",
1278                "$ENV{HOME}/.someprogrc")
1279    {
1280         unless ($return = do $file) {
1281             warn "couldn't parse $file: $@" if $@;
1282             warn "couldn't do $file: $!"    unless defined $return;
1283             warn "couldn't run $file"       unless $return;
1284         }
1285     }
1286
1287 =item dump LABEL
1288
1289 =item dump
1290
1291 This function causes an immediate core dump.  See also the B<-u>
1292 command-line switch in L<perlrun>, which does the same thing.
1293 Primarily this is so that you can use the B<undump> program (not
1294 supplied) to turn your core dump into an executable binary after
1295 having initialized all your variables at the beginning of the
1296 program.  When the new binary is executed it will begin by executing
1297 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1298 Think of it as a goto with an intervening core dump and reincarnation.
1299 If C<LABEL> is omitted, restarts the program from the top.
1300
1301 B<WARNING>: Any files opened at the time of the dump will I<not>
1302 be open any more when the program is reincarnated, with possible
1303 resulting confusion on the part of Perl.
1304
1305 This function is now largely obsolete, partly because it's very
1306 hard to convert a core file into an executable, and because the
1307 real compiler backends for generating portable bytecode and compilable
1308 C code have superseded it.  That's why you should now invoke it as
1309 C<CORE::dump()>, if you don't want to be warned against a possible
1310 typo.
1311
1312 If you're looking to use L<dump> to speed up your program, consider
1313 generating bytecode or native C code as described in L<perlcc>.  If
1314 you're just trying to accelerate a CGI script, consider using the
1315 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1316 You might also consider autoloading or selfloading, which at least
1317 make your program I<appear> to run faster.
1318
1319 =item each HASH
1320
1321 When called in list context, returns a 2-element list consisting of the
1322 key and value for the next element of a hash, so that you can iterate over
1323 it.  When called in scalar context, returns only the key for the next
1324 element in the hash.
1325
1326 Entries are returned in an apparently random order.  The actual random
1327 order is subject to change in future versions of perl, but it is
1328 guaranteed to be in the same order as either the C<keys> or C<values>
1329 function would produce on the same (unmodified) hash.  Since Perl
1330 5.8.1 the ordering is different even between different runs of Perl
1331 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1332
1333 When the hash is entirely read, a null array is returned in list context
1334 (which when assigned produces a false (C<0>) value), and C<undef> in
1335 scalar context.  The next call to C<each> after that will start iterating
1336 again.  There is a single iterator for each hash, shared by all C<each>,
1337 C<keys>, and C<values> function calls in the program; it can be reset by
1338 reading all the elements from the hash, or by evaluating C<keys HASH> or
1339 C<values HASH>.  If you add or delete elements of a hash while you're
1340 iterating over it, you may get entries skipped or duplicated, so
1341 don't.  Exception: It is always safe to delete the item most recently
1342 returned by C<each()>, which means that the following code will work:
1343
1344         while (($key, $value) = each %hash) {
1345           print $key, "\n";
1346           delete $hash{$key};   # This is safe
1347         }
1348
1349 The following prints out your environment like the printenv(1) program,
1350 only in a different order:
1351
1352     while (($key,$value) = each %ENV) {
1353         print "$key=$value\n";
1354     }
1355
1356 See also C<keys>, C<values> and C<sort>.
1357
1358 =item eof FILEHANDLE
1359
1360 =item eof ()
1361
1362 =item eof
1363
1364 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1365 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1366 gives the real filehandle.  (Note that this function actually
1367 reads a character and then C<ungetc>s it, so isn't very useful in an
1368 interactive context.)  Do not read from a terminal file (or call
1369 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1370 as terminals may lose the end-of-file condition if you do.
1371
1372 An C<eof> without an argument uses the last file read.  Using C<eof()>
1373 with empty parentheses is very different.  It refers to the pseudo file
1374 formed from the files listed on the command line and accessed via the
1375 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1376 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1377 used will cause C<@ARGV> to be examined to determine if input is
1378 available.   Similarly, an C<eof()> after C<< <> >> has returned
1379 end-of-file will assume you are processing another C<@ARGV> list,
1380 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1381 see L<perlop/"I/O Operators">.
1382
1383 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1384 detect the end of each file, C<eof()> will only detect the end of the
1385 last file.  Examples:
1386
1387     # reset line numbering on each input file
1388     while (<>) {
1389         next if /^\s*#/;        # skip comments
1390         print "$.\t$_";
1391     } continue {
1392         close ARGV  if eof;     # Not eof()!
1393     }
1394
1395     # insert dashes just before last line of last file
1396     while (<>) {
1397         if (eof()) {            # check for end of last file
1398             print "--------------\n";
1399         }
1400         print;
1401         last if eof();          # needed if we're reading from a terminal
1402     }
1403
1404 Practical hint: you almost never need to use C<eof> in Perl, because the
1405 input operators typically return C<undef> when they run out of data, or if
1406 there was an error.
1407
1408 =item eval EXPR
1409
1410 =item eval BLOCK
1411
1412 =item eval
1413
1414 In the first form, the return value of EXPR is parsed and executed as if it
1415 were a little Perl program.  The value of the expression (which is itself
1416 determined within scalar context) is first parsed, and if there weren't any
1417 errors, executed in the lexical context of the current Perl program, so
1418 that any variable settings or subroutine and format definitions remain
1419 afterwards.  Note that the value is parsed every time the C<eval> executes.
1420 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1421 delay parsing and subsequent execution of the text of EXPR until run time.
1422
1423 In the second form, the code within the BLOCK is parsed only once--at the
1424 same time the code surrounding the C<eval> itself was parsed--and executed
1425 within the context of the current Perl program.  This form is typically
1426 used to trap exceptions more efficiently than the first (see below), while
1427 also providing the benefit of checking the code within BLOCK at compile
1428 time.
1429
1430 The final semicolon, if any, may be omitted from the value of EXPR or within
1431 the BLOCK.
1432
1433 In both forms, the value returned is the value of the last expression
1434 evaluated inside the mini-program; a return statement may be also used, just
1435 as with subroutines.  The expression providing the return value is evaluated
1436 in void, scalar, or list context, depending on the context of the C<eval> 
1437 itself.  See L</wantarray> for more on how the evaluation context can be 
1438 determined.
1439
1440 If there is a syntax error or runtime error, or a C<die> statement is
1441 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1442 error message.  If there was no error, C<$@> is guaranteed to be a null
1443 string.  Beware that using C<eval> neither silences perl from printing
1444 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1445 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1446 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1447 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1448
1449 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1450 determining whether a particular feature (such as C<socket> or C<symlink>)
1451 is implemented.  It is also Perl's exception trapping mechanism, where
1452 the die operator is used to raise exceptions.
1453
1454 If the code to be executed doesn't vary, you may use the eval-BLOCK
1455 form to trap run-time errors without incurring the penalty of
1456 recompiling each time.  The error, if any, is still returned in C<$@>.
1457 Examples:
1458
1459     # make divide-by-zero nonfatal
1460     eval { $answer = $a / $b; }; warn $@ if $@;
1461
1462     # same thing, but less efficient
1463     eval '$answer = $a / $b'; warn $@ if $@;
1464
1465     # a compile-time error
1466     eval { $answer = };                 # WRONG
1467
1468     # a run-time error
1469     eval '$answer =';   # sets $@
1470
1471 Using the C<eval{}> form as an exception trap in libraries does have some
1472 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1473 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1474 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1475 as shown in this example:
1476
1477     # a very private exception trap for divide-by-zero
1478     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1479     warn $@ if $@;
1480
1481 This is especially significant, given that C<__DIE__> hooks can call
1482 C<die> again, which has the effect of changing their error messages:
1483
1484     # __DIE__ hooks may modify error messages
1485     {
1486        local $SIG{'__DIE__'} =
1487               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1488        eval { die "foo lives here" };
1489        print $@ if $@;                # prints "bar lives here"
1490     }
1491
1492 Because this promotes action at a distance, this counterintuitive behavior
1493 may be fixed in a future release.
1494
1495 With an C<eval>, you should be especially careful to remember what's
1496 being looked at when:
1497
1498     eval $x;            # CASE 1
1499     eval "$x";          # CASE 2
1500
1501     eval '$x';          # CASE 3
1502     eval { $x };        # CASE 4
1503
1504     eval "\$$x++";      # CASE 5
1505     $$x++;              # CASE 6
1506
1507 Cases 1 and 2 above behave identically: they run the code contained in
1508 the variable $x.  (Although case 2 has misleading double quotes making
1509 the reader wonder what else might be happening (nothing is).)  Cases 3
1510 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1511 does nothing but return the value of $x.  (Case 4 is preferred for
1512 purely visual reasons, but it also has the advantage of compiling at
1513 compile-time instead of at run-time.)  Case 5 is a place where
1514 normally you I<would> like to use double quotes, except that in this
1515 particular situation, you can just use symbolic references instead, as
1516 in case 6.
1517
1518 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1519 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1520
1521 Note that as a very special case, an C<eval ''> executed within the C<DB>
1522 package doesn't see the usual surrounding lexical scope, but rather the
1523 scope of the first non-DB piece of code that called it. You don't normally
1524 need to worry about this unless you are writing a Perl debugger.
1525
1526 =item exec LIST
1527
1528 =item exec PROGRAM LIST
1529
1530 The C<exec> function executes a system command I<and never returns>--
1531 use C<system> instead of C<exec> if you want it to return.  It fails and
1532 returns false only if the command does not exist I<and> it is executed
1533 directly instead of via your system's command shell (see below).
1534
1535 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1536 warns you if there is a following statement which isn't C<die>, C<warn>,
1537 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1538 I<really> want to follow an C<exec> with some other statement, you
1539 can use one of these styles to avoid the warning:
1540
1541     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1542     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1543
1544 If there is more than one argument in LIST, or if LIST is an array
1545 with more than one value, calls execvp(3) with the arguments in LIST.
1546 If there is only one scalar argument or an array with one element in it,
1547 the argument is checked for shell metacharacters, and if there are any,
1548 the entire argument is passed to the system's command shell for parsing
1549 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1550 If there are no shell metacharacters in the argument, it is split into
1551 words and passed directly to C<execvp>, which is more efficient.
1552 Examples:
1553
1554     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1555     exec "sort $outfile | uniq";
1556
1557 If you don't really want to execute the first argument, but want to lie
1558 to the program you are executing about its own name, you can specify
1559 the program you actually want to run as an "indirect object" (without a
1560 comma) in front of the LIST.  (This always forces interpretation of the
1561 LIST as a multivalued list, even if there is only a single scalar in
1562 the list.)  Example:
1563
1564     $shell = '/bin/csh';
1565     exec $shell '-sh';          # pretend it's a login shell
1566
1567 or, more directly,
1568
1569     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1570
1571 When the arguments get executed via the system shell, results will
1572 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1573 for details.
1574
1575 Using an indirect object with C<exec> or C<system> is also more
1576 secure.  This usage (which also works fine with system()) forces
1577 interpretation of the arguments as a multivalued list, even if the
1578 list had just one argument.  That way you're safe from the shell
1579 expanding wildcards or splitting up words with whitespace in them.
1580
1581     @args = ( "echo surprise" );
1582
1583     exec @args;               # subject to shell escapes
1584                                 # if @args == 1
1585     exec { $args[0] } @args;  # safe even with one-arg list
1586
1587 The first version, the one without the indirect object, ran the I<echo>
1588 program, passing it C<"surprise"> an argument.  The second version
1589 didn't--it tried to run a program literally called I<"echo surprise">,
1590 didn't find it, and set C<$?> to a non-zero value indicating failure.
1591
1592 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1593 output before the exec, but this may not be supported on some platforms
1594 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1595 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1596 open handles in order to avoid lost output.
1597
1598 Note that C<exec> will not call your C<END> blocks, nor will it call
1599 any C<DESTROY> methods in your objects.
1600
1601 =item exists EXPR
1602
1603 Given an expression that specifies a hash element or array element,
1604 returns true if the specified element in the hash or array has ever
1605 been initialized, even if the corresponding value is undefined.  The
1606 element is not autovivified if it doesn't exist.
1607
1608     print "Exists\n"    if exists $hash{$key};
1609     print "Defined\n"   if defined $hash{$key};
1610     print "True\n"      if $hash{$key};
1611
1612     print "Exists\n"    if exists $array[$index];
1613     print "Defined\n"   if defined $array[$index];
1614     print "True\n"      if $array[$index];
1615
1616 A hash or array element can be true only if it's defined, and defined if
1617 it exists, but the reverse doesn't necessarily hold true.
1618
1619 Given an expression that specifies the name of a subroutine,
1620 returns true if the specified subroutine has ever been declared, even
1621 if it is undefined.  Mentioning a subroutine name for exists or defined
1622 does not count as declaring it.  Note that a subroutine which does not
1623 exist may still be callable: its package may have an C<AUTOLOAD>
1624 method that makes it spring into existence the first time that it is
1625 called -- see L<perlsub>.
1626
1627     print "Exists\n"    if exists &subroutine;
1628     print "Defined\n"   if defined &subroutine;
1629
1630 Note that the EXPR can be arbitrarily complicated as long as the final
1631 operation is a hash or array key lookup or subroutine name:
1632
1633     if (exists $ref->{A}->{B}->{$key})  { }
1634     if (exists $hash{A}{B}{$key})       { }
1635
1636     if (exists $ref->{A}->{B}->[$ix])   { }
1637     if (exists $hash{A}{B}[$ix])        { }
1638
1639     if (exists &{$ref->{A}{B}{$key}})   { }
1640
1641 Although the deepest nested array or hash will not spring into existence
1642 just because its existence was tested, any intervening ones will.
1643 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1644 into existence due to the existence test for the $key element above.
1645 This happens anywhere the arrow operator is used, including even:
1646
1647     undef $ref;
1648     if (exists $ref->{"Some key"})      { }
1649     print $ref;             # prints HASH(0x80d3d5c)
1650
1651 This surprising autovivification in what does not at first--or even
1652 second--glance appear to be an lvalue context may be fixed in a future
1653 release.
1654
1655 Use of a subroutine call, rather than a subroutine name, as an argument
1656 to exists() is an error.
1657
1658     exists &sub;        # OK
1659     exists &sub();      # Error
1660
1661 =item exit EXPR
1662
1663 =item exit
1664
1665 Evaluates EXPR and exits immediately with that value.    Example:
1666
1667     $ans = <STDIN>;
1668     exit 0 if $ans =~ /^[Xx]/;
1669
1670 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1671 universally recognized values for EXPR are C<0> for success and C<1>
1672 for error; other values are subject to interpretation depending on the
1673 environment in which the Perl program is running.  For example, exiting
1674 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1675 the mailer to return the item undelivered, but that's not true everywhere.
1676
1677 Don't use C<exit> to abort a subroutine if there's any chance that
1678 someone might want to trap whatever error happened.  Use C<die> instead,
1679 which can be trapped by an C<eval>.
1680
1681 The exit() function does not always exit immediately.  It calls any
1682 defined C<END> routines first, but these C<END> routines may not
1683 themselves abort the exit.  Likewise any object destructors that need to
1684 be called are called before the real exit.  If this is a problem, you
1685 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1686 See L<perlmod> for details.
1687
1688 =item exp EXPR
1689
1690 =item exp
1691
1692 Returns I<e> (the natural logarithm base) to the power of EXPR.
1693 If EXPR is omitted, gives C<exp($_)>.
1694
1695 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1696
1697 Implements the fcntl(2) function.  You'll probably have to say
1698
1699     use Fcntl;
1700
1701 first to get the correct constant definitions.  Argument processing and
1702 value return works just like C<ioctl> below.
1703 For example:
1704
1705     use Fcntl;
1706     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1707         or die "can't fcntl F_GETFL: $!";
1708
1709 You don't have to check for C<defined> on the return from C<fcntl>.
1710 Like C<ioctl>, it maps a C<0> return from the system call into
1711 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1712 in numeric context.  It is also exempt from the normal B<-w> warnings
1713 on improper numeric conversions.
1714
1715 Note that C<fcntl> will produce a fatal error if used on a machine that
1716 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1717 manpage to learn what functions are available on your system.
1718
1719 Here's an example of setting a filehandle named C<REMOTE> to be
1720 non-blocking at the system level.  You'll have to negotiate C<$|>
1721 on your own, though.
1722
1723     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1724
1725     $flags = fcntl(REMOTE, F_GETFL, 0)
1726                 or die "Can't get flags for the socket: $!\n";
1727
1728     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1729                 or die "Can't set flags for the socket: $!\n";
1730
1731 =item fileno FILEHANDLE
1732
1733 Returns the file descriptor for a filehandle, or undefined if the
1734 filehandle is not open.  This is mainly useful for constructing
1735 bitmaps for C<select> and low-level POSIX tty-handling operations.
1736 If FILEHANDLE is an expression, the value is taken as an indirect
1737 filehandle, generally its name.
1738
1739 You can use this to find out whether two handles refer to the
1740 same underlying descriptor:
1741
1742     if (fileno(THIS) == fileno(THAT)) {
1743         print "THIS and THAT are dups\n";
1744     }
1745
1746 (Filehandles connected to memory objects via new features of C<open> may
1747 return undefined even though they are open.)
1748
1749
1750 =item flock FILEHANDLE,OPERATION
1751
1752 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1753 for success, false on failure.  Produces a fatal error if used on a
1754 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1755 C<flock> is Perl's portable file locking interface, although it locks
1756 only entire files, not records.
1757
1758 Two potentially non-obvious but traditional C<flock> semantics are
1759 that it waits indefinitely until the lock is granted, and that its locks
1760 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1761 fewer guarantees.  This means that programs that do not also use C<flock>
1762 may modify files locked with C<flock>.  See L<perlport>, 
1763 your port's specific documentation, or your system-specific local manpages
1764 for details.  It's best to assume traditional behavior if you're writing
1765 portable programs.  (But if you're not, you should as always feel perfectly
1766 free to write for your own system's idiosyncrasies (sometimes called
1767 "features").  Slavish adherence to portability concerns shouldn't get
1768 in the way of your getting your job done.)
1769
1770 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1771 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1772 you can use the symbolic names if you import them from the Fcntl module,
1773 either individually, or as a group using the ':flock' tag.  LOCK_SH
1774 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1775 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1776 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1777 waiting for the lock (check the return status to see if you got it).
1778
1779 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1780 before locking or unlocking it.
1781
1782 Note that the emulation built with lockf(3) doesn't provide shared
1783 locks, and it requires that FILEHANDLE be open with write intent.  These
1784 are the semantics that lockf(3) implements.  Most if not all systems
1785 implement lockf(3) in terms of fcntl(2) locking, though, so the
1786 differing semantics shouldn't bite too many people.
1787
1788 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1789 be open with read intent to use LOCK_SH and requires that it be open
1790 with write intent to use LOCK_EX.
1791
1792 Note also that some versions of C<flock> cannot lock things over the
1793 network; you would need to use the more system-specific C<fcntl> for
1794 that.  If you like you can force Perl to ignore your system's flock(2)
1795 function, and so provide its own fcntl(2)-based emulation, by passing
1796 the switch C<-Ud_flock> to the F<Configure> program when you configure
1797 perl.
1798
1799 Here's a mailbox appender for BSD systems.
1800
1801     use Fcntl ':flock'; # import LOCK_* constants
1802
1803     sub lock {
1804         flock(MBOX,LOCK_EX);
1805         # and, in case someone appended
1806         # while we were waiting...
1807         seek(MBOX, 0, 2);
1808     }
1809
1810     sub unlock {
1811         flock(MBOX,LOCK_UN);
1812     }
1813
1814     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1815             or die "Can't open mailbox: $!";
1816
1817     lock();
1818     print MBOX $msg,"\n\n";
1819     unlock();
1820
1821 On systems that support a real flock(), locks are inherited across fork()
1822 calls, whereas those that must resort to the more capricious fcntl()
1823 function lose the locks, making it harder to write servers.
1824
1825 See also L<DB_File> for other flock() examples.
1826
1827 =item fork
1828
1829 Does a fork(2) system call to create a new process running the
1830 same program at the same point.  It returns the child pid to the
1831 parent process, C<0> to the child process, or C<undef> if the fork is
1832 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1833 are shared, while everything else is copied.  On most systems supporting
1834 fork(), great care has gone into making it extremely efficient (for
1835 example, using copy-on-write technology on data pages), making it the
1836 dominant paradigm for multitasking over the last few decades.
1837
1838 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1839 output before forking the child process, but this may not be supported
1840 on some platforms (see L<perlport>).  To be safe, you may need to set
1841 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1842 C<IO::Handle> on any open handles in order to avoid duplicate output.
1843
1844 If you C<fork> without ever waiting on your children, you will
1845 accumulate zombies.  On some systems, you can avoid this by setting
1846 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1847 forking and reaping moribund children.
1848
1849 Note that if your forked child inherits system file descriptors like
1850 STDIN and STDOUT that are actually connected by a pipe or socket, even
1851 if you exit, then the remote server (such as, say, a CGI script or a
1852 backgrounded job launched from a remote shell) won't think you're done.
1853 You should reopen those to F</dev/null> if it's any issue.
1854
1855 =item format
1856
1857 Declare a picture format for use by the C<write> function.  For
1858 example:
1859
1860     format Something =
1861         Test: @<<<<<<<< @||||| @>>>>>
1862               $str,     $%,    '$' . int($num)
1863     .
1864
1865     $str = "widget";
1866     $num = $cost/$quantity;
1867     $~ = 'Something';
1868     write;
1869
1870 See L<perlform> for many details and examples.
1871
1872 =item formline PICTURE,LIST
1873
1874 This is an internal function used by C<format>s, though you may call it,
1875 too.  It formats (see L<perlform>) a list of values according to the
1876 contents of PICTURE, placing the output into the format output
1877 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1878 Eventually, when a C<write> is done, the contents of
1879 C<$^A> are written to some filehandle.  You could also read C<$^A>
1880 and then set C<$^A> back to C<"">.  Note that a format typically
1881 does one C<formline> per line of form, but the C<formline> function itself
1882 doesn't care how many newlines are embedded in the PICTURE.  This means
1883 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1884 You may therefore need to use multiple formlines to implement a single
1885 record format, just like the format compiler.
1886
1887 Be careful if you put double quotes around the picture, because an C<@>
1888 character may be taken to mean the beginning of an array name.
1889 C<formline> always returns true.  See L<perlform> for other examples.
1890
1891 =item getc FILEHANDLE
1892
1893 =item getc
1894
1895 Returns the next character from the input file attached to FILEHANDLE,
1896 or the undefined value at end of file, or if there was an error (in
1897 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1898 STDIN.  This is not particularly efficient.  However, it cannot be
1899 used by itself to fetch single characters without waiting for the user
1900 to hit enter.  For that, try something more like:
1901
1902     if ($BSD_STYLE) {
1903         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1904     }
1905     else {
1906         system "stty", '-icanon', 'eol', "\001";
1907     }
1908
1909     $key = getc(STDIN);
1910
1911     if ($BSD_STYLE) {
1912         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1913     }
1914     else {
1915         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1916     }
1917     print "\n";
1918
1919 Determination of whether $BSD_STYLE should be set
1920 is left as an exercise to the reader.
1921
1922 The C<POSIX::getattr> function can do this more portably on
1923 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1924 module from your nearest CPAN site; details on CPAN can be found on
1925 L<perlmodlib/CPAN>.
1926
1927 =item getlogin
1928
1929 This implements the C library function of the same name, which on most
1930 systems returns the current login from F</etc/utmp>, if any.  If null,
1931 use C<getpwuid>.
1932
1933     $login = getlogin || getpwuid($<) || "Kilroy";
1934
1935 Do not consider C<getlogin> for authentication: it is not as
1936 secure as C<getpwuid>.
1937
1938 =item getpeername SOCKET
1939
1940 Returns the packed sockaddr address of other end of the SOCKET connection.
1941
1942     use Socket;
1943     $hersockaddr    = getpeername(SOCK);
1944     ($port, $iaddr) = sockaddr_in($hersockaddr);
1945     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1946     $herstraddr     = inet_ntoa($iaddr);
1947
1948 =item getpgrp PID
1949
1950 Returns the current process group for the specified PID.  Use
1951 a PID of C<0> to get the current process group for the
1952 current process.  Will raise an exception if used on a machine that
1953 doesn't implement getpgrp(2).  If PID is omitted, returns process
1954 group of current process.  Note that the POSIX version of C<getpgrp>
1955 does not accept a PID argument, so only C<PID==0> is truly portable.
1956
1957 =item getppid
1958
1959 Returns the process id of the parent process.
1960
1961 Note for Linux users: on Linux, the C functions C<getpid()> and
1962 C<getppid()> return different values from different threads. In order to
1963 be portable, this behavior is not reflected by the perl-level function
1964 C<getppid()>, that returns a consistent value across threads. If you want
1965 to call the underlying C<getppid()>, you may use the CPAN module
1966 C<Linux::Pid>.
1967
1968 =item getpriority WHICH,WHO
1969
1970 Returns the current priority for a process, a process group, or a user.
1971 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1972 machine that doesn't implement getpriority(2).
1973
1974 =item getpwnam NAME
1975
1976 =item getgrnam NAME
1977
1978 =item gethostbyname NAME
1979
1980 =item getnetbyname NAME
1981
1982 =item getprotobyname NAME
1983
1984 =item getpwuid UID
1985
1986 =item getgrgid GID
1987
1988 =item getservbyname NAME,PROTO
1989
1990 =item gethostbyaddr ADDR,ADDRTYPE
1991
1992 =item getnetbyaddr ADDR,ADDRTYPE
1993
1994 =item getprotobynumber NUMBER
1995
1996 =item getservbyport PORT,PROTO
1997
1998 =item getpwent
1999
2000 =item getgrent
2001
2002 =item gethostent
2003
2004 =item getnetent
2005
2006 =item getprotoent
2007
2008 =item getservent
2009
2010 =item setpwent
2011
2012 =item setgrent
2013
2014 =item sethostent STAYOPEN
2015
2016 =item setnetent STAYOPEN
2017
2018 =item setprotoent STAYOPEN
2019
2020 =item setservent STAYOPEN
2021
2022 =item endpwent
2023
2024 =item endgrent
2025
2026 =item endhostent
2027
2028 =item endnetent
2029
2030 =item endprotoent
2031
2032 =item endservent
2033
2034 These routines perform the same functions as their counterparts in the
2035 system library.  In list context, the return values from the
2036 various get routines are as follows:
2037
2038     ($name,$passwd,$uid,$gid,
2039        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2040     ($name,$passwd,$gid,$members) = getgr*
2041     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2042     ($name,$aliases,$addrtype,$net) = getnet*
2043     ($name,$aliases,$proto) = getproto*
2044     ($name,$aliases,$port,$proto) = getserv*
2045
2046 (If the entry doesn't exist you get a null list.)
2047
2048 The exact meaning of the $gcos field varies but it usually contains
2049 the real name of the user (as opposed to the login name) and other
2050 information pertaining to the user.  Beware, however, that in many
2051 system users are able to change this information and therefore it
2052 cannot be trusted and therefore the $gcos is tainted (see
2053 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2054 login shell, are also tainted, because of the same reason.
2055
2056 In scalar context, you get the name, unless the function was a
2057 lookup by name, in which case you get the other thing, whatever it is.
2058 (If the entry doesn't exist you get the undefined value.)  For example:
2059
2060     $uid   = getpwnam($name);
2061     $name  = getpwuid($num);
2062     $name  = getpwent();
2063     $gid   = getgrnam($name);
2064     $name  = getgrgid($num);
2065     $name  = getgrent();
2066     #etc.
2067
2068 In I<getpw*()> the fields $quota, $comment, and $expire are special
2069 cases in the sense that in many systems they are unsupported.  If the
2070 $quota is unsupported, it is an empty scalar.  If it is supported, it
2071 usually encodes the disk quota.  If the $comment field is unsupported,
2072 it is an empty scalar.  If it is supported it usually encodes some
2073 administrative comment about the user.  In some systems the $quota
2074 field may be $change or $age, fields that have to do with password
2075 aging.  In some systems the $comment field may be $class.  The $expire
2076 field, if present, encodes the expiration period of the account or the
2077 password.  For the availability and the exact meaning of these fields
2078 in your system, please consult your getpwnam(3) documentation and your
2079 F<pwd.h> file.  You can also find out from within Perl what your
2080 $quota and $comment fields mean and whether you have the $expire field
2081 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2082 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2083 files are only supported if your vendor has implemented them in the
2084 intuitive fashion that calling the regular C library routines gets the
2085 shadow versions if you're running under privilege or if there exists
2086 the shadow(3) functions as found in System V (this includes Solaris
2087 and Linux.)  Those systems that implement a proprietary shadow password
2088 facility are unlikely to be supported.
2089
2090 The $members value returned by I<getgr*()> is a space separated list of
2091 the login names of the members of the group.
2092
2093 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2094 C, it will be returned to you via C<$?> if the function call fails.  The
2095 C<@addrs> value returned by a successful call is a list of the raw
2096 addresses returned by the corresponding system library call.  In the
2097 Internet domain, each address is four bytes long and you can unpack it
2098 by saying something like:
2099
2100     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2101
2102 The Socket library makes this slightly easier:
2103
2104     use Socket;
2105     $iaddr = inet_aton("127.1"); # or whatever address
2106     $name  = gethostbyaddr($iaddr, AF_INET);
2107
2108     # or going the other way
2109     $straddr = inet_ntoa($iaddr);
2110
2111 If you get tired of remembering which element of the return list
2112 contains which return value, by-name interfaces are provided
2113 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2114 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2115 and C<User::grent>.  These override the normal built-ins, supplying
2116 versions that return objects with the appropriate names
2117 for each field.  For example:
2118
2119    use File::stat;
2120    use User::pwent;
2121    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2122
2123 Even though it looks like they're the same method calls (uid),
2124 they aren't, because a C<File::stat> object is different from
2125 a C<User::pwent> object.
2126
2127 =item getsockname SOCKET
2128
2129 Returns the packed sockaddr address of this end of the SOCKET connection,
2130 in case you don't know the address because you have several different
2131 IPs that the connection might have come in on.
2132
2133     use Socket;
2134     $mysockaddr = getsockname(SOCK);
2135     ($port, $myaddr) = sockaddr_in($mysockaddr);
2136     printf "Connect to %s [%s]\n",
2137        scalar gethostbyaddr($myaddr, AF_INET),
2138        inet_ntoa($myaddr);
2139
2140 =item getsockopt SOCKET,LEVEL,OPTNAME
2141
2142 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2143 Options may exist at multiple protocol levels depending on the socket
2144 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2145 C<Socket> module) will exist. To query options at another level the
2146 protocol number of the appropriate protocol controlling the option
2147 should be supplied. For example, to indicate that an option is to be
2148 interpreted by the TCP protocol, LEVEL should be set to the protocol
2149 number of TCP, which you can get using getprotobyname.
2150
2151 The call returns a packed string representing the requested socket option,
2152 or C<undef> if there is an error (the error reason will be in $!). What
2153 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2154 your system documentation for details. A very common case however is that
2155 the option is an integer, in which case the result will be a packed
2156 integer which you can decode using unpack with the C<i> (or C<I>) format.
2157
2158 An example testing if Nagle's algorithm is turned on on a socket:
2159
2160     use Socket qw(:all);
2161
2162     defined(my $tcp = getprotobyname("tcp"))
2163         or die "Could not determine the protocol number for tcp";
2164     # my $tcp = IPPROTO_TCP; # Alternative
2165     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2166         or die "Could not query TCP_NODELAY socket option: $!";
2167     my $nodelay = unpack("I", $packed);
2168     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2169
2170
2171 =item glob EXPR
2172
2173 =item glob
2174
2175 In list context, returns a (possibly empty) list of filename expansions on
2176 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2177 scalar context, glob iterates through such filename expansions, returning
2178 undef when the list is exhausted. This is the internal function
2179 implementing the C<< <*.c> >> operator, but you can use it directly. If
2180 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2181 more detail in L<perlop/"I/O Operators">.
2182
2183 Beginning with v5.6.0, this operator is implemented using the standard
2184 C<File::Glob> extension.  See L<File::Glob> for details.
2185
2186 =item gmtime EXPR
2187
2188 =item gmtime
2189
2190 Converts a time as returned by the time function to an 8-element list
2191 with the time localized for the standard Greenwich time zone.
2192 Typically used as follows:
2193
2194     #  0    1    2     3     4    5     6     7
2195     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2196                                             gmtime(time);
2197
2198 All list elements are numeric, and come straight out of the C `struct
2199 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2200 specified time.  $mday is the day of the month, and $mon is the month
2201 itself, in the range C<0..11> with 0 indicating January and 11
2202 indicating December.  $year is the number of years since 1900.  That
2203 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2204 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2205 the year, in the range C<0..364> (or C<0..365> in leap years.)
2206
2207 Note that the $year element is I<not> simply the last two digits of
2208 the year.  If you assume it is then you create non-Y2K-compliant
2209 programs--and you wouldn't want to do that, would you?
2210
2211 The proper way to get a complete 4-digit year is simply:
2212
2213         $year += 1900;
2214
2215 And to get the last two digits of the year (e.g., '01' in 2001) do:
2216
2217         $year = sprintf("%02d", $year % 100);
2218
2219 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2220
2221 In scalar context, C<gmtime()> returns the ctime(3) value:
2222
2223     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2224
2225 If you need local time instead of GMT use the L</localtime> builtin. 
2226 See also the C<timegm> function provided by the C<Time::Local> module,
2227 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2228
2229 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2230 instead a Perl builtin.  To get somewhat similar but locale dependent date
2231 strings, see the example in L</localtime>.
2232
2233 See L<perlport/gmtime> for portability concerns.
2234
2235 =item goto LABEL
2236
2237 =item goto EXPR
2238
2239 =item goto &NAME
2240
2241 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2242 execution there.  It may not be used to go into any construct that
2243 requires initialization, such as a subroutine or a C<foreach> loop.  It
2244 also can't be used to go into a construct that is optimized away,
2245 or to get out of a block or subroutine given to C<sort>.
2246 It can be used to go almost anywhere else within the dynamic scope,
2247 including out of subroutines, but it's usually better to use some other
2248 construct such as C<last> or C<die>.  The author of Perl has never felt the
2249 need to use this form of C<goto> (in Perl, that is--C is another matter).
2250 (The difference being that C does not offer named loops combined with
2251 loop control.  Perl does, and this replaces most structured uses of C<goto>
2252 in other languages.)
2253
2254 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2255 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2256 necessarily recommended if you're optimizing for maintainability:
2257
2258     goto ("FOO", "BAR", "GLARCH")[$i];
2259
2260 The C<goto-&NAME> form is quite different from the other forms of
2261 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2262 doesn't have the stigma associated with other gotos.  Instead, it
2263 exits the current subroutine (losing any changes set by local()) and
2264 immediately calls in its place the named subroutine using the current
2265 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2266 load another subroutine and then pretend that the other subroutine had
2267 been called in the first place (except that any modifications to C<@_>
2268 in the current subroutine are propagated to the other subroutine.)
2269 After the C<goto>, not even C<caller> will be able to tell that this
2270 routine was called first.
2271
2272 NAME needn't be the name of a subroutine; it can be a scalar variable
2273 containing a code reference, or a block that evaluates to a code
2274 reference.
2275
2276 =item grep BLOCK LIST
2277
2278 =item grep EXPR,LIST
2279
2280 This is similar in spirit to, but not the same as, grep(1) and its
2281 relatives.  In particular, it is not limited to using regular expressions.
2282
2283 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2284 C<$_> to each element) and returns the list value consisting of those
2285 elements for which the expression evaluated to true.  In scalar
2286 context, returns the number of times the expression was true.
2287
2288     @foo = grep(!/^#/, @bar);    # weed out comments
2289
2290 or equivalently,
2291
2292     @foo = grep {!/^#/} @bar;    # weed out comments
2293
2294 Note that C<$_> is an alias to the list value, so it can be used to
2295 modify the elements of the LIST.  While this is useful and supported,
2296 it can cause bizarre results if the elements of LIST are not variables.
2297 Similarly, grep returns aliases into the original list, much as a for
2298 loop's index variable aliases the list elements.  That is, modifying an
2299 element of a list returned by grep (for example, in a C<foreach>, C<map>
2300 or another C<grep>) actually modifies the element in the original list.
2301 This is usually something to be avoided when writing clear code.
2302
2303 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2304 been declared with C<my $_>) then, in addition to being locally aliased to
2305 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2306 can't be seen from the outside, avoiding any potential side-effects.
2307
2308 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2309
2310 =item hex EXPR
2311
2312 =item hex
2313
2314 Interprets EXPR as a hex string and returns the corresponding value.
2315 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2316 L</oct>.)  If EXPR is omitted, uses C<$_>.
2317
2318     print hex '0xAf'; # prints '175'
2319     print hex 'aF';   # same
2320
2321 Hex strings may only represent integers.  Strings that would cause
2322 integer overflow trigger a warning.  Leading whitespace is not stripped,
2323 unlike oct(). To present something as hex, look into L</printf>,
2324 L</sprintf>, or L</unpack>.
2325
2326 =item import LIST
2327
2328 There is no builtin C<import> function.  It is just an ordinary
2329 method (subroutine) defined (or inherited) by modules that wish to export
2330 names to another module.  The C<use> function calls the C<import> method
2331 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2332
2333 =item index STR,SUBSTR,POSITION
2334
2335 =item index STR,SUBSTR
2336
2337 The index function searches for one string within another, but without
2338 the wildcard-like behavior of a full regular-expression pattern match.
2339 It returns the position of the first occurrence of SUBSTR in STR at
2340 or after POSITION.  If POSITION is omitted, starts searching from the
2341 beginning of the string.  The return value is based at C<0> (or whatever
2342 you've set the C<$[> variable to--but don't do that).  If the substring
2343 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2344
2345 =item int EXPR
2346
2347 =item int
2348
2349 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2350 You should not use this function for rounding: one because it truncates
2351 towards C<0>, and two because machine representations of floating point
2352 numbers can sometimes produce counterintuitive results.  For example,
2353 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2354 because it's really more like -268.99999999999994315658 instead.  Usually,
2355 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2356 functions will serve you better than will int().
2357
2358 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2359
2360 Implements the ioctl(2) function.  You'll probably first have to say
2361
2362     require "sys/ioctl.ph";     # probably in $Config{archlib}/ioctl.ph
2363
2364 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2365 exist or doesn't have the correct definitions you'll have to roll your
2366 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2367 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2368 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2369 written depending on the FUNCTION--a pointer to the string value of SCALAR
2370 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2371 has no string value but does have a numeric value, that value will be
2372 passed rather than a pointer to the string value.  To guarantee this to be
2373 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2374 functions may be needed to manipulate the values of structures used by
2375 C<ioctl>.
2376
2377 The return value of C<ioctl> (and C<fcntl>) is as follows:
2378
2379         if OS returns:          then Perl returns:
2380             -1                    undefined value
2381              0                  string "0 but true"
2382         anything else               that number
2383
2384 Thus Perl returns true on success and false on failure, yet you can
2385 still easily determine the actual value returned by the operating
2386 system:
2387
2388     $retval = ioctl(...) || -1;
2389     printf "System returned %d\n", $retval;
2390
2391 The special string C<"0 but true"> is exempt from B<-w> complaints
2392 about improper numeric conversions.
2393
2394 =item join EXPR,LIST
2395
2396 Joins the separate strings of LIST into a single string with fields
2397 separated by the value of EXPR, and returns that new string.  Example:
2398
2399     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2400
2401 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2402 first argument.  Compare L</split>.
2403
2404 =item keys HASH
2405
2406 Returns a list consisting of all the keys of the named hash.
2407 (In scalar context, returns the number of keys.)
2408
2409 The keys are returned in an apparently random order.  The actual
2410 random order is subject to change in future versions of perl, but it
2411 is guaranteed to be the same order as either the C<values> or C<each>
2412 function produces (given that the hash has not been modified).  Since
2413 Perl 5.8.1 the ordering is different even between different runs of
2414 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2415 Attacks">).
2416
2417 As a side effect, calling keys() resets the HASH's internal iterator
2418 (see L</each>).  In particular, calling keys() in void context resets
2419 the iterator with no other overhead.
2420
2421 Here is yet another way to print your environment:
2422
2423     @keys = keys %ENV;
2424     @values = values %ENV;
2425     while (@keys) {
2426         print pop(@keys), '=', pop(@values), "\n";
2427     }
2428
2429 or how about sorted by key:
2430
2431     foreach $key (sort(keys %ENV)) {
2432         print $key, '=', $ENV{$key}, "\n";
2433     }
2434
2435 The returned values are copies of the original keys in the hash, so
2436 modifying them will not affect the original hash.  Compare L</values>.
2437
2438 To sort a hash by value, you'll need to use a C<sort> function.
2439 Here's a descending numeric sort of a hash by its values:
2440
2441     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2442         printf "%4d %s\n", $hash{$key}, $key;
2443     }
2444
2445 As an lvalue C<keys> allows you to increase the number of hash buckets
2446 allocated for the given hash.  This can gain you a measure of efficiency if
2447 you know the hash is going to get big.  (This is similar to pre-extending
2448 an array by assigning a larger number to $#array.)  If you say
2449
2450     keys %hash = 200;
2451
2452 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2453 in fact, since it rounds up to the next power of two.  These
2454 buckets will be retained even if you do C<%hash = ()>, use C<undef
2455 %hash> if you want to free the storage while C<%hash> is still in scope.
2456 You can't shrink the number of buckets allocated for the hash using
2457 C<keys> in this way (but you needn't worry about doing this by accident,
2458 as trying has no effect).
2459
2460 See also C<each>, C<values> and C<sort>.
2461
2462 =item kill SIGNAL, LIST
2463
2464 Sends a signal to a list of processes.  Returns the number of
2465 processes successfully signaled (which is not necessarily the
2466 same as the number actually killed).
2467
2468     $cnt = kill 1, $child1, $child2;
2469     kill 9, @goners;
2470
2471 If SIGNAL is zero, no signal is sent to the process.  This is a
2472 useful way to check that a child process is alive and hasn't changed
2473 its UID.  See L<perlport> for notes on the portability of this
2474 construct.
2475
2476 Unlike in the shell, if SIGNAL is negative, it kills
2477 process groups instead of processes.  (On System V, a negative I<PROCESS>
2478 number will also kill process groups, but that's not portable.)  That
2479 means you usually want to use positive not negative signals.  You may also
2480 use a signal name in quotes.
2481
2482 See L<perlipc/"Signals"> for more details.
2483
2484 =item last LABEL
2485
2486 =item last
2487
2488 The C<last> command is like the C<break> statement in C (as used in
2489 loops); it immediately exits the loop in question.  If the LABEL is
2490 omitted, the command refers to the innermost enclosing loop.  The
2491 C<continue> block, if any, is not executed:
2492
2493     LINE: while (<STDIN>) {
2494         last LINE if /^$/;      # exit when done with header
2495         #...
2496     }
2497
2498 C<last> cannot be used to exit a block which returns a value such as
2499 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2500 a grep() or map() operation.
2501
2502 Note that a block by itself is semantically identical to a loop
2503 that executes once.  Thus C<last> can be used to effect an early
2504 exit out of such a block.
2505
2506 See also L</continue> for an illustration of how C<last>, C<next>, and
2507 C<redo> work.
2508
2509 =item lc EXPR
2510
2511 =item lc
2512
2513 Returns a lowercased version of EXPR.  This is the internal function
2514 implementing the C<\L> escape in double-quoted strings.  Respects
2515 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2516 and L<perlunicode> for more details about locale and Unicode support.
2517
2518 If EXPR is omitted, uses C<$_>.
2519
2520 =item lcfirst EXPR
2521
2522 =item lcfirst
2523
2524 Returns the value of EXPR with the first character lowercased.  This
2525 is the internal function implementing the C<\l> escape in
2526 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2527 locale> in force.  See L<perllocale> and L<perlunicode> for more
2528 details about locale and Unicode support.
2529
2530 If EXPR is omitted, uses C<$_>.
2531
2532 =item length EXPR
2533
2534 =item length
2535
2536 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2537 omitted, returns length of C<$_>.  Note that this cannot be used on
2538 an entire array or hash to find out how many elements these have.
2539 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2540
2541 Note the I<characters>: if the EXPR is in Unicode, you will get the
2542 number of characters, not the number of bytes.  To get the length
2543 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2544
2545 =item link OLDFILE,NEWFILE
2546
2547 Creates a new filename linked to the old filename.  Returns true for
2548 success, false otherwise.
2549
2550 =item listen SOCKET,QUEUESIZE
2551
2552 Does the same thing that the listen system call does.  Returns true if
2553 it succeeded, false otherwise.  See the example in
2554 L<perlipc/"Sockets: Client/Server Communication">.
2555
2556 =item local EXPR
2557
2558 You really probably want to be using C<my> instead, because C<local> isn't
2559 what most people think of as "local".  See
2560 L<perlsub/"Private Variables via my()"> for details.
2561
2562 A local modifies the listed variables to be local to the enclosing
2563 block, file, or eval.  If more than one value is listed, the list must
2564 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2565 for details, including issues with tied arrays and hashes.
2566
2567 =item localtime EXPR
2568
2569 =item localtime
2570
2571 Converts a time as returned by the time function to a 9-element list
2572 with the time analyzed for the local time zone.  Typically used as
2573 follows:
2574
2575     #  0    1    2     3     4    5     6     7     8
2576     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2577                                                 localtime(time);
2578
2579 All list elements are numeric, and come straight out of the C `struct
2580 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2581 of the specified time.
2582
2583 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2584 the range C<0..11> with 0 indicating January and 11 indicating December.
2585 This makes it easy to get a month name from a list:
2586
2587     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2588     print "$abbr[$mon] $mday";
2589     # $mon=9, $mday=18 gives "Oct 18"
2590
2591 C<$year> is the number of years since 1900, not just the last two digits
2592 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2593 to get a complete 4-digit year is simply:
2594
2595     $year += 1900;
2596
2597 To get the last two digits of the year (e.g., '01' in 2001) do:
2598
2599     $year = sprintf("%02d", $year % 100);
2600
2601 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2602 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2603 (or C<0..365> in leap years.)
2604
2605 C<$isdst> is true if the specified time occurs during Daylight Saving
2606 Time, false otherwise.
2607
2608 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2609
2610 In scalar context, C<localtime()> returns the ctime(3) value:
2611
2612     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2613
2614 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2615 instead of local time use the L</gmtime> builtin. See also the
2616 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2617 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2618 and mktime(3) functions.
2619
2620 To get somewhat similar but locale dependent date strings, set up your
2621 locale environment variables appropriately (please see L<perllocale>) and
2622 try for example:
2623
2624     use POSIX qw(strftime);
2625     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2626     # or for GMT formatted appropriately for your locale:
2627     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2628
2629 Note that the C<%a> and C<%b>, the short forms of the day of the week
2630 and the month of the year, may not necessarily be three characters wide.
2631
2632 See L<perlport/localtime> for portability concerns.
2633
2634 =item lock THING
2635
2636 This function places an advisory lock on a shared variable, or referenced
2637 object contained in I<THING> until the lock goes out of scope.
2638
2639 lock() is a "weak keyword" : this means that if you've defined a function
2640 by this name (before any calls to it), that function will be called
2641 instead. (However, if you've said C<use threads>, lock() is always a
2642 keyword.) See L<threads>.
2643
2644 =item log EXPR
2645
2646 =item log
2647
2648 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2649 returns log of C<$_>.  To get the log of another base, use basic algebra:
2650 The base-N log of a number is equal to the natural log of that number
2651 divided by the natural log of N.  For example:
2652
2653     sub log10 {
2654         my $n = shift;
2655         return log($n)/log(10);
2656     }
2657
2658 See also L</exp> for the inverse operation.
2659
2660 =item lstat EXPR
2661
2662 =item lstat
2663
2664 Does the same thing as the C<stat> function (including setting the
2665 special C<_> filehandle) but stats a symbolic link instead of the file
2666 the symbolic link points to.  If symbolic links are unimplemented on
2667 your system, a normal C<stat> is done.  For much more detailed
2668 information, please see the documentation for C<stat>.
2669
2670 If EXPR is omitted, stats C<$_>.
2671
2672 =item m//
2673
2674 The match operator.  See L<perlop>.
2675
2676 =item map BLOCK LIST
2677
2678 =item map EXPR,LIST
2679
2680 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2681 C<$_> to each element) and returns the list value composed of the
2682 results of each such evaluation.  In scalar context, returns the
2683 total number of elements so generated.  Evaluates BLOCK or EXPR in
2684 list context, so each element of LIST may produce zero, one, or
2685 more elements in the returned value.
2686
2687     @chars = map(chr, @nums);
2688
2689 translates a list of numbers to the corresponding characters.  And
2690
2691     %hash = map { getkey($_) => $_ } @array;
2692
2693 is just a funny way to write
2694
2695     %hash = ();
2696     foreach $_ (@array) {
2697         $hash{getkey($_)} = $_;
2698     }
2699
2700 Note that C<$_> is an alias to the list value, so it can be used to
2701 modify the elements of the LIST.  While this is useful and supported,
2702 it can cause bizarre results if the elements of LIST are not variables.
2703 Using a regular C<foreach> loop for this purpose would be clearer in
2704 most cases.  See also L</grep> for an array composed of those items of
2705 the original list for which the BLOCK or EXPR evaluates to true.
2706
2707 If C<$_> is lexical in the scope where the C<map> appears (because it has
2708 been declared with C<my $_>) then, in addition to being locally aliased to
2709 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2710 can't be seen from the outside, avoiding any potential side-effects.
2711
2712 C<{> starts both hash references and blocks, so C<map { ...> could be either
2713 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2714 ahead for the closing C<}> it has to take a guess at which its dealing with
2715 based what it finds just after the C<{>. Usually it gets it right, but if it
2716 doesn't it won't realize something is wrong until it gets to the C<}> and
2717 encounters the missing (or unexpected) comma. The syntax error will be
2718 reported close to the C<}> but you'll need to change something near the C<{>
2719 such as using a unary C<+> to give perl some help:
2720
2721     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2722     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2723     %hash = map { ("\L$_", 1) } @array  # this also works
2724     %hash = map {  lc($_), 1  } @array  # as does this.
2725     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2726
2727     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2728
2729 or to force an anon hash constructor use C<+{>
2730
2731    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2732
2733 and you get list of anonymous hashes each with only 1 entry.
2734
2735 =item mkdir FILENAME,MASK
2736
2737 =item mkdir FILENAME
2738
2739 =item mkdir
2740
2741 Creates the directory specified by FILENAME, with permissions
2742 specified by MASK (as modified by C<umask>).  If it succeeds it
2743 returns true, otherwise it returns false and sets C<$!> (errno).
2744 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2745 to C<$_>.
2746
2747 In general, it is better to create directories with permissive MASK,
2748 and let the user modify that with their C<umask>, than it is to supply
2749 a restrictive MASK and give the user no way to be more permissive.
2750 The exceptions to this rule are when the file or directory should be
2751 kept private (mail files, for instance).  The perlfunc(1) entry on
2752 C<umask> discusses the choice of MASK in more detail.
2753
2754 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2755 number of trailing slashes.  Some operating and filesystems do not get
2756 this right, so Perl automatically removes all trailing slashes to keep
2757 everyone happy.
2758
2759 =item msgctl ID,CMD,ARG
2760
2761 Calls the System V IPC function msgctl(2).  You'll probably have to say
2762
2763     use IPC::SysV;
2764
2765 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2766 then ARG must be a variable that will hold the returned C<msqid_ds>
2767 structure.  Returns like C<ioctl>: the undefined value for error,
2768 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2769 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2770
2771 =item msgget KEY,FLAGS
2772
2773 Calls the System V IPC function msgget(2).  Returns the message queue
2774 id, or the undefined value if there is an error.  See also
2775 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2776
2777 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2778
2779 Calls the System V IPC function msgrcv to receive a message from
2780 message queue ID into variable VAR with a maximum message size of
2781 SIZE.  Note that when a message is received, the message type as a
2782 native long integer will be the first thing in VAR, followed by the
2783 actual message.  This packing may be opened with C<unpack("l! a*")>.
2784 Taints the variable.  Returns true if successful, or false if there is
2785 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2786 C<IPC::SysV::Msg> documentation.
2787
2788 =item msgsnd ID,MSG,FLAGS
2789
2790 Calls the System V IPC function msgsnd to send the message MSG to the
2791 message queue ID.  MSG must begin with the native long integer message
2792 type, and be followed by the length of the actual message, and finally
2793 the message itself.  This kind of packing can be achieved with
2794 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2795 or false if there is an error.  See also C<IPC::SysV>
2796 and C<IPC::SysV::Msg> documentation.
2797
2798 =item my EXPR
2799
2800 =item my TYPE EXPR
2801
2802 =item my EXPR : ATTRS
2803
2804 =item my TYPE EXPR : ATTRS
2805
2806 A C<my> declares the listed variables to be local (lexically) to the
2807 enclosing block, file, or C<eval>.  If more than one value is listed,
2808 the list must be placed in parentheses.
2809
2810 The exact semantics and interface of TYPE and ATTRS are still
2811 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2812 and attributes are handled using the C<attributes> pragma, or starting
2813 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2814 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2815 L<attributes>, and L<Attribute::Handlers>.
2816
2817 =item next LABEL
2818
2819 =item next
2820
2821 The C<next> command is like the C<continue> statement in C; it starts
2822 the next iteration of the loop:
2823
2824     LINE: while (<STDIN>) {
2825         next LINE if /^#/;      # discard comments
2826         #...
2827     }
2828
2829 Note that if there were a C<continue> block on the above, it would get
2830 executed even on discarded lines.  If the LABEL is omitted, the command
2831 refers to the innermost enclosing loop.
2832
2833 C<next> cannot be used to exit a block which returns a value such as
2834 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2835 a grep() or map() operation.
2836
2837 Note that a block by itself is semantically identical to a loop
2838 that executes once.  Thus C<next> will exit such a block early.
2839
2840 See also L</continue> for an illustration of how C<last>, C<next>, and
2841 C<redo> work.
2842
2843 =item no Module VERSION LIST
2844
2845 =item no Module VERSION
2846
2847 =item no Module LIST
2848
2849 =item no Module
2850
2851 See the C<use> function, of which C<no> is the opposite.
2852
2853 =item oct EXPR
2854
2855 =item oct
2856
2857 Interprets EXPR as an octal string and returns the corresponding
2858 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2859 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2860 binary string.  Leading whitespace is ignored in all three cases.)
2861 The following will handle decimal, binary, octal, and hex in the standard
2862 Perl or C notation:
2863
2864     $val = oct($val) if $val =~ /^0/;
2865
2866 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2867 in octal), use sprintf() or printf():
2868
2869     $perms = (stat("filename"))[2] & 07777;
2870     $oct_perms = sprintf "%lo", $perms;
2871
2872 The oct() function is commonly used when a string such as C<644> needs
2873 to be converted into a file mode, for example. (Although perl will
2874 automatically convert strings into numbers as needed, this automatic
2875 conversion assumes base 10.)
2876
2877 =item open FILEHANDLE,EXPR
2878
2879 =item open FILEHANDLE,MODE,EXPR
2880
2881 =item open FILEHANDLE,MODE,EXPR,LIST
2882
2883 =item open FILEHANDLE,MODE,REFERENCE
2884
2885 =item open FILEHANDLE
2886
2887 Opens the file whose filename is given by EXPR, and associates it with
2888 FILEHANDLE.
2889
2890 (The following is a comprehensive reference to open(): for a gentler
2891 introduction you may consider L<perlopentut>.)
2892
2893 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2894 the variable is assigned a reference to a new anonymous filehandle,
2895 otherwise if FILEHANDLE is an expression, its value is used as the name of
2896 the real filehandle wanted.  (This is considered a symbolic reference, so
2897 C<use strict 'refs'> should I<not> be in effect.)
2898
2899 If EXPR is omitted, the scalar variable of the same name as the
2900 FILEHANDLE contains the filename.  (Note that lexical variables--those
2901 declared with C<my>--will not work for this purpose; so if you're
2902 using C<my>, specify EXPR in your call to open.)
2903
2904 If three or more arguments are specified then the mode of opening and
2905 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2906 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2907 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2908 the file is opened for appending, again being created if necessary.
2909
2910 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2911 indicate that you want both read and write access to the file; thus
2912 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2913 '+>' >> mode would clobber the file first.  You can't usually use
2914 either read-write mode for updating textfiles, since they have
2915 variable length records.  See the B<-i> switch in L<perlrun> for a
2916 better approach.  The file is created with permissions of C<0666>
2917 modified by the process' C<umask> value.
2918
2919 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2920 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2921
2922 In the 2-arguments (and 1-argument) form of the call the mode and
2923 filename should be concatenated (in this order), possibly separated by
2924 spaces.  It is possible to omit the mode in these forms if the mode is
2925 C<< '<' >>.
2926
2927 If the filename begins with C<'|'>, the filename is interpreted as a
2928 command to which output is to be piped, and if the filename ends with a
2929 C<'|'>, the filename is interpreted as a command which pipes output to
2930 us.  See L<perlipc/"Using open() for IPC">
2931 for more examples of this.  (You are not allowed to C<open> to a command
2932 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2933 and L<perlipc/"Bidirectional Communication with Another Process">
2934 for alternatives.)
2935
2936 For three or more arguments if MODE is C<'|-'>, the filename is
2937 interpreted as a command to which output is to be piped, and if MODE
2938 is C<'-|'>, the filename is interpreted as a command which pipes
2939 output to us.  In the 2-arguments (and 1-argument) form one should
2940 replace dash (C<'-'>) with the command.
2941 See L<perlipc/"Using open() for IPC"> for more examples of this.
2942 (You are not allowed to C<open> to a command that pipes both in I<and>
2943 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2944 L<perlipc/"Bidirectional Communication"> for alternatives.)
2945
2946 In the three-or-more argument form of pipe opens, if LIST is specified
2947 (extra arguments after the command name) then LIST becomes arguments
2948 to the command invoked if the platform supports it.  The meaning of
2949 C<open> with more than three arguments for non-pipe modes is not yet
2950 specified. Experimental "layers" may give extra LIST arguments
2951 meaning.
2952
2953 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2954 and opening C<< '>-' >> opens STDOUT.
2955
2956 You may use the three-argument form of open to specify IO "layers"
2957 (sometimes also referred to as "disciplines") to be applied to the handle
2958 that affect how the input and output are processed (see L<open> and
2959 L<PerlIO> for more details). For example
2960
2961   open(FH, "<:utf8", "file")
2962
2963 will open the UTF-8 encoded file containing Unicode characters,
2964 see L<perluniintro>. (Note that if layers are specified in the
2965 three-arg form then default layers set by the C<open> pragma are
2966 ignored.)
2967
2968 Open returns nonzero upon success, the undefined value otherwise.  If
2969 the C<open> involved a pipe, the return value happens to be the pid of
2970 the subprocess.
2971
2972 If you're running Perl on a system that distinguishes between text
2973 files and binary files, then you should check out L</binmode> for tips
2974 for dealing with this.  The key distinction between systems that need
2975 C<binmode> and those that don't is their text file formats.  Systems
2976 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2977 character, and which encode that character in C as C<"\n">, do not
2978 need C<binmode>.  The rest need it.
2979
2980 When opening a file, it's usually a bad idea to continue normal execution
2981 if the request failed, so C<open> is frequently used in connection with
2982 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2983 where you want to make a nicely formatted error message (but there are
2984 modules that can help with that problem)) you should always check
2985 the return value from opening a file.  The infrequent exception is when
2986 working with an unopened filehandle is actually what you want to do.
2987
2988 As a special case the 3-arg form with a read/write mode and the third
2989 argument being C<undef>:
2990
2991     open(TMP, "+>", undef) or die ...
2992
2993 opens a filehandle to an anonymous temporary file.  Also using "+<"
2994 works for symmetry, but you really should consider writing something
2995 to the temporary file first.  You will need to seek() to do the
2996 reading.
2997
2998 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
2999 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3000 "in memory" files held in Perl scalars via:
3001
3002     open($fh, '>', \$variable) || ..
3003
3004 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3005 file, you have to close it first:
3006
3007     close STDOUT;
3008     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3009
3010 Examples:
3011
3012     $ARTICLE = 100;
3013     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3014     while (<ARTICLE>) {...
3015
3016     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3017     # if the open fails, output is discarded
3018
3019     open(DBASE, '+<', 'dbase.mine')             # open for update
3020         or die "Can't open 'dbase.mine' for update: $!";
3021
3022     open(DBASE, '+<dbase.mine')                 # ditto
3023         or die "Can't open 'dbase.mine' for update: $!";
3024
3025     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3026         or die "Can't start caesar: $!";
3027
3028     open(ARTICLE, "caesar <$article |")         # ditto
3029         or die "Can't start caesar: $!";
3030
3031     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3032         or die "Can't start sort: $!";
3033
3034     # in memory files
3035     open(MEMORY,'>', \$var)
3036         or die "Can't open memory file: $!";
3037     print MEMORY "foo!\n";                      # output will end up in $var
3038
3039     # process argument list of files along with any includes
3040
3041     foreach $file (@ARGV) {
3042         process($file, 'fh00');
3043     }
3044
3045     sub process {
3046         my($filename, $input) = @_;
3047         $input++;               # this is a string increment
3048         unless (open($input, $filename)) {
3049             print STDERR "Can't open $filename: $!\n";
3050             return;
3051         }
3052
3053         local $_;
3054         while (<$input>) {              # note use of indirection
3055             if (/^#include "(.*)"/) {
3056                 process($1, $input);
3057                 next;
3058             }
3059             #...                # whatever
3060         }
3061     }
3062
3063 See L<perliol> for detailed info on PerlIO.
3064
3065 You may also, in the Bourne shell tradition, specify an EXPR beginning
3066 with C<< '>&' >>, in which case the rest of the string is interpreted
3067 as the name of a filehandle (or file descriptor, if numeric) to be
3068 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3069 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3070 The mode you specify should match the mode of the original filehandle.
3071 (Duping a filehandle does not take into account any existing contents
3072 of IO buffers.) If you use the 3-arg form then you can pass either a
3073 number, the name of a filehandle or the normal "reference to a glob".
3074
3075 Here is a script that saves, redirects, and restores C<STDOUT> and
3076 C<STDERR> using various methods:
3077
3078     #!/usr/bin/perl
3079     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3080     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3081
3082     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3083     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3084
3085     select STDERR; $| = 1;      # make unbuffered
3086     select STDOUT; $| = 1;      # make unbuffered
3087
3088     print STDOUT "stdout 1\n";  # this works for
3089     print STDERR "stderr 1\n";  # subprocesses too
3090
3091     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3092     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3093
3094     print STDOUT "stdout 2\n";
3095     print STDERR "stderr 2\n";
3096
3097 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3098 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3099 that file descriptor (and not call L<dup(2)>); this is more
3100 parsimonious of file descriptors.  For example:
3101
3102     # open for input, reusing the fileno of $fd
3103     open(FILEHANDLE, "<&=$fd")
3104
3105 or
3106
3107     open(FILEHANDLE, "<&=", $fd)
3108
3109 or
3110
3111     # open for append, using the fileno of OLDFH
3112     open(FH, ">>&=", OLDFH)
3113
3114 or
3115
3116     open(FH, ">>&=OLDFH")
3117
3118 Being parsimonious on filehandles is also useful (besides being
3119 parsimonious) for example when something is dependent on file
3120 descriptors, like for example locking using flock().  If you do just
3121 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3122 descriptor as B, and therefore flock(A) will not flock(B), and vice
3123 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3124 the same file descriptor.
3125
3126 Note that if you are using Perls older than 5.8.0, Perl will be using
3127 the standard C libraries' fdopen() to implement the "=" functionality.
3128 On many UNIX systems fdopen() fails when file descriptors exceed a
3129 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3130 most often the default.
3131
3132 You can see whether Perl has been compiled with PerlIO or not by
3133 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3134 is C<define>, you have PerlIO, otherwise you don't.
3135
3136 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3137 with 2-arguments (or 1-argument) form of open(), then
3138 there is an implicit fork done, and the return value of open is the pid
3139 of the child within the parent process, and C<0> within the child
3140 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3141 The filehandle behaves normally for the parent, but i/o to that
3142 filehandle is piped from/to the STDOUT/STDIN of the child process.
3143 In the child process the filehandle isn't opened--i/o happens from/to
3144 the new STDOUT or STDIN.  Typically this is used like the normal
3145 piped open when you want to exercise more control over just how the
3146 pipe command gets executed, such as when you are running setuid, and
3147 don't want to have to scan shell commands for metacharacters.
3148 The following triples are more or less equivalent:
3149
3150     open(FOO, "|tr '[a-z]' '[A-Z]'");
3151     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3152     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3153     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3154
3155     open(FOO, "cat -n '$file'|");
3156     open(FOO, '-|', "cat -n '$file'");
3157     open(FOO, '-|') || exec 'cat', '-n', $file;
3158     open(FOO, '-|', "cat", '-n', $file);
3159
3160 The last example in each block shows the pipe as "list form", which is
3161 not yet supported on all platforms.  A good rule of thumb is that if
3162 your platform has true C<fork()> (in other words, if your platform is
3163 UNIX) you can use the list form.
3164
3165 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3166
3167 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3168 output before any operation that may do a fork, but this may not be
3169 supported on some platforms (see L<perlport>).  To be safe, you may need
3170 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3171 of C<IO::Handle> on any open handles.
3172
3173 On systems that support a close-on-exec flag on files, the flag will
3174 be set for the newly opened file descriptor as determined by the value
3175 of $^F.  See L<perlvar/$^F>.
3176
3177 Closing any piped filehandle causes the parent process to wait for the
3178 child to finish, and returns the status value in C<$?> and
3179 C<${^CHILD_ERROR_NATIVE}>.
3180
3181 The filename passed to 2-argument (or 1-argument) form of open() will
3182 have leading and trailing whitespace deleted, and the normal
3183 redirection characters honored.  This property, known as "magic open",
3184 can often be used to good effect.  A user could specify a filename of
3185 F<"rsh cat file |">, or you could change certain filenames as needed:
3186
3187     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3188     open(FH, $filename) or die "Can't open $filename: $!";
3189
3190 Use 3-argument form to open a file with arbitrary weird characters in it,
3191
3192     open(FOO, '<', $file);
3193
3194 otherwise it's necessary to protect any leading and trailing whitespace:
3195
3196     $file =~ s#^(\s)#./$1#;
3197     open(FOO, "< $file\0");
3198
3199 (this may not work on some bizarre filesystems).  One should
3200 conscientiously choose between the I<magic> and 3-arguments form
3201 of open():
3202
3203     open IN, $ARGV[0];
3204
3205 will allow the user to specify an argument of the form C<"rsh cat file |">,
3206 but will not work on a filename which happens to have a trailing space, while
3207
3208     open IN, '<', $ARGV[0];
3209
3210 will have exactly the opposite restrictions.
3211
3212 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3213 should use the C<sysopen> function, which involves no such magic (but
3214 may use subtly different filemodes than Perl open(), which is mapped
3215 to C fopen()).  This is
3216 another way to protect your filenames from interpretation.  For example:
3217
3218     use IO::Handle;
3219     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3220         or die "sysopen $path: $!";
3221     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3222     print HANDLE "stuff $$\n";
3223     seek(HANDLE, 0, 0);
3224     print "File contains: ", <HANDLE>;
3225
3226 Using the constructor from the C<IO::Handle> package (or one of its
3227 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3228 filehandles that have the scope of whatever variables hold references to
3229 them, and automatically close whenever and however you leave that scope:
3230
3231     use IO::File;
3232     #...
3233     sub read_myfile_munged {
3234         my $ALL = shift;
3235         my $handle = new IO::File;
3236         open($handle, "myfile") or die "myfile: $!";
3237         $first = <$handle>
3238             or return ();     # Automatically closed here.
3239         mung $first or die "mung failed";       # Or here.
3240         return $first, <$handle> if $ALL;       # Or here.
3241         $first;                                 # Or here.
3242     }
3243
3244 See L</seek> for some details about mixing reading and writing.
3245
3246 =item opendir DIRHANDLE,EXPR
3247
3248 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3249 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3250 DIRHANDLE may be an expression whose value can be used as an indirect
3251 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3252 scalar variable (or array or hash element), the variable is assigned a
3253 reference to a new anonymous dirhandle.
3254 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3255
3256 =item ord EXPR
3257
3258 =item ord
3259
3260 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3261 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3262 uses C<$_>.
3263
3264 For the reverse, see L</chr>.
3265 See L<perlunicode> and L<encoding> for more about Unicode.
3266
3267 =item our EXPR
3268
3269 =item our EXPR TYPE
3270
3271 =item our EXPR : ATTRS
3272
3273 =item our TYPE EXPR : ATTRS
3274
3275 C<our> associates a simple name with a package variable in the current
3276 package for use within the current scope.  When C<use strict 'vars'> is in
3277 effect, C<our> lets you use declared global variables without qualifying
3278 them with package names, within the lexical scope of the C<our> declaration.
3279 In this way C<our> differs from C<use vars>, which is package scoped.
3280
3281 Unlike C<my>, which both allocates storage for a variable and associates
3282 a simple name with that storage for use within the current scope, C<our>
3283 associates a simple name with a package variable in the current package,
3284 for use within the current scope.  In other words, C<our> has the same
3285 scoping rules as C<my>, but does not necessarily create a
3286 variable.
3287
3288 If more than one value is listed, the list must be placed
3289 in parentheses.
3290
3291     our $foo;
3292     our($bar, $baz);
3293
3294 An C<our> declaration declares a global variable that will be visible
3295 across its entire lexical scope, even across package boundaries.  The
3296 package in which the variable is entered is determined at the point
3297 of the declaration, not at the point of use.  This means the following
3298 behavior holds:
3299
3300     package Foo;
3301     our $bar;           # declares $Foo::bar for rest of lexical scope
3302     $bar = 20;
3303
3304     package Bar;
3305     print $bar;         # prints 20, as it refers to $Foo::bar
3306
3307 Multiple C<our> declarations with the same name in the same lexical
3308 scope are allowed if they are in different packages.  If they happen
3309 to be in the same package, Perl will emit warnings if you have asked
3310 for them, just like multiple C<my> declarations.  Unlike a second
3311 C<my> declaration, which will bind the name to a fresh variable, a
3312 second C<our> declaration in the same package, in the same scope, is
3313 merely redundant.
3314
3315     use warnings;
3316     package Foo;
3317     our $bar;           # declares $Foo::bar for rest of lexical scope
3318     $bar = 20;
3319
3320     package Bar;
3321     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3322     print $bar;         # prints 30
3323
3324     our $bar;           # emits warning but has no other effect
3325     print $bar;         # still prints 30
3326
3327 An C<our> declaration may also have a list of attributes associated
3328 with it.
3329
3330 The exact semantics and interface of TYPE and ATTRS are still
3331 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3332 and attributes are handled using the C<attributes> pragma, or starting
3333 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3334 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3335 L<attributes>, and L<Attribute::Handlers>.
3336
3337 The only currently recognized C<our()> attribute is C<unique> which
3338 indicates that a single copy of the global is to be used by all
3339 interpreters should the program happen to be running in a
3340 multi-interpreter environment. (The default behaviour would be for
3341 each interpreter to have its own copy of the global.)  Examples:
3342
3343     our @EXPORT : unique = qw(foo);
3344     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3345     our $VERSION : unique = "1.00";
3346
3347 Note that this attribute also has the effect of making the global
3348 readonly when the first new interpreter is cloned (for example,
3349 when the first new thread is created).
3350
3351 Multi-interpreter environments can come to being either through the
3352 fork() emulation on Windows platforms, or by embedding perl in a
3353 multi-threaded application.  The C<unique> attribute does nothing in
3354 all other environments.
3355
3356 Warning: the current implementation of this attribute operates on the
3357 typeglob associated with the variable; this means that C<our $x : unique>
3358 also has the effect of C<our @x : unique; our %x : unique>. This may be
3359 subject to change.
3360
3361 =item pack TEMPLATE,LIST
3362
3363 Takes a LIST of values and converts it into a string using the rules
3364 given by the TEMPLATE.  The resulting string is the concatenation of
3365 the converted values.  Typically, each converted value looks
3366 like its machine-level representation.  For example, on 32-bit machines
3367 an integer may be represented by a sequence of 4 bytes that will be 
3368 converted to a sequence of 4 characters.
3369
3370 The TEMPLATE is a sequence of characters that give the order and type
3371 of values, as follows:
3372
3373     a   A string with arbitrary binary data, will be null padded.
3374     A   A text (ASCII) string, will be space padded.
3375     Z   A null terminated (ASCIZ) string, will be null padded.
3376
3377     b   A bit string (ascending bit order inside each byte, like vec()).
3378     B   A bit string (descending bit order inside each byte).
3379     h   A hex string (low nybble first).
3380     H   A hex string (high nybble first).
3381
3382     c   A signed char (8-bit) value.
3383     C   An unsigned C char (octet) even under Unicode. Should normally not
3384         be used. See U and W instead.
3385     W   An unsigned char value (can be greater than 255).
3386
3387     s   A signed short (16-bit) value.
3388     S   An unsigned short value.
3389
3390     l   A signed long (32-bit) value.
3391     L   An unsigned long value.
3392
3393     q   A signed quad (64-bit) value.
3394     Q   An unsigned quad value.
3395           (Quads are available only if your system supports 64-bit
3396            integer values _and_ if Perl has been compiled to support those.
3397            Causes a fatal error otherwise.)
3398
3399     i   A signed integer value.
3400     I   A unsigned integer value.
3401           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3402            size depends on what a local C compiler calls 'int'.)
3403  
3404     n   An unsigned short (16-bit) in "network" (big-endian) order.
3405     N   An unsigned long (32-bit) in "network" (big-endian) order.
3406     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3407     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3408
3409     j   A Perl internal signed integer value (IV).
3410     J   A Perl internal unsigned integer value (UV).
3411
3412     f   A single-precision float in the native format.
3413     d   A double-precision float in the native format.
3414
3415     F   A Perl internal floating point value (NV) in the native format
3416     D   A long double-precision float in the native format.
3417           (Long doubles are available only if your system supports long
3418            double values _and_ if Perl has been compiled to support those.
3419            Causes a fatal error otherwise.)
3420
3421     p   A pointer to a null-terminated string.
3422     P   A pointer to a structure (fixed-length string).
3423
3424     u   A uuencoded string.
3425     U   A Unicode character number.  Encodes to UTF-8 internally
3426         (or UTF-EBCDIC in EBCDIC platforms).
3427
3428     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3429         details).  Its bytes represent an unsigned integer in base 128,
3430         most significant digit first, with as few digits as possible.  Bit
3431         eight (the high bit) is set on each byte except the last.
3432
3433     x   A null byte.
3434     X   Back up a byte.
3435     @   Null fill or truncate to absolute position, counted from the
3436         start of the innermost ()-group.
3437     .   Null fill or truncate to absolute position specified by value.
3438     (   Start of a ()-group.
3439
3440 One or more of the modifiers below may optionally follow some letters in the
3441 TEMPLATE (the second column lists the letters for which the modifier is
3442 valid):
3443
3444     !   sSlLiI     Forces native (short, long, int) sizes instead
3445                    of fixed (16-/32-bit) sizes.
3446
3447         xX         Make x and X act as alignment commands.
3448
3449         nNvV       Treat integers as signed instead of unsigned.
3450
3451         @.         Specify position as byte offset in the internal
3452                    representation of the packed string. Efficient but
3453                    dangerous.
3454
3455     >   sSiIlLqQ   Force big-endian byte-order on the type.
3456         jJfFdDpP   (The "big end" touches the construct.)
3457
3458     <   sSiIlLqQ   Force little-endian byte-order on the type.
3459         jJfFdDpP   (The "little end" touches the construct.)
3460
3461 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3462 in which case they force a certain byte-order on all components of
3463 that group, including subgroups.
3464
3465 The following rules apply:
3466
3467 =over 8
3468
3469 =item *
3470
3471 Each letter may optionally be followed by a number giving a repeat
3472 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3473 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3474 that many values from the LIST.  A C<*> for the repeat count means to
3475 use however many items are left, except for C<@>, C<x>, C<X>, where it
3476 is equivalent to C<0>, for <.> where it means relative to string start
3477 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3478 A numeric repeat count may optionally be enclosed in brackets, as in
3479 C<pack 'C[80]', @arr>.
3480
3481 One can replace the numeric repeat count by a template enclosed in brackets;
3482 then the packed length of this template in bytes is used as a count.
3483 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3484 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3485 If the template in brackets contains alignment commands (such as C<x![d]>),
3486 its packed length is calculated as if the start of the template has the maximal
3487 possible alignment.
3488
3489 When used with C<Z>, C<*> results in the addition of a trailing null
3490 byte (so the packed result will be one longer than the byte C<length>
3491 of the item).
3492
3493 When used with C<@>, the repeat count represents an offset from the start
3494 of the innermost () group.
3495
3496 When used with C<.>, the repeat count is used to determine the starting
3497 position from where the value offset is calculated. If the repeat count
3498 is 0, it's relative to the current position. If the repeat count is C<*>,
3499 the offset is relative to the start of the packed string. And if its an
3500 integer C<n> the offset is relative to the start of the n-th innermost
3501 () group (or the start of the string if C<n> is bigger then the group
3502 level).
3503
3504 The repeat count for C<u> is interpreted as the maximal number of bytes
3505 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3506 count should not be more than 65.
3507
3508 =item *
3509
3510 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3511 string of length count, padding with nulls or spaces as necessary.  When
3512 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3513 after the first null, and C<a> returns data verbatim.
3514
3515 If the value-to-pack is too long, it is truncated.  If too long and an
3516 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3517 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3518 count is 0).
3519
3520 =item *
3521
3522 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3523 Each character of the input field of pack() generates 1 bit of the result.
3524 Each result bit is based on the least-significant bit of the corresponding
3525 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3526 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3527
3528 Starting from the beginning of the input string of pack(), each 8-tuple
3529 of characters is converted to 1 character of output.  With format C<b>
3530 the first character of the 8-tuple determines the least-significant bit of a
3531 character, and with format C<B> it determines the most-significant bit of
3532 a character.
3533
3534 If the length of the input string is not exactly divisible by 8, the
3535 remainder is packed as if the input string were padded by null characters
3536 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3537
3538 If the input string of pack() is longer than needed, extra characters are 
3539 ignored. A C<*> for the repeat count of pack() means to use all the 
3540 characters of the input field.  On unpack()ing the bits are converted to a 
3541 string of C<"0">s and C<"1">s.
3542
3543 =item *
3544
3545 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3546 representable as hexadecimal digits, 0-9a-f) long.
3547
3548 Each character of the input field of pack() generates 4 bits of the result.
3549 For non-alphabetical characters the result is based on the 4 least-significant
3550 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3551 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3552 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3553 is compatible with the usual hexadecimal digits, so that C<"a"> and
3554 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3555 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3556
3557 Starting from the beginning of the input string of pack(), each pair
3558 of characters is converted to 1 character of output.  With format C<h> the
3559 first character of the pair determines the least-significant nybble of the
3560 output character, and with format C<H> it determines the most-significant
3561 nybble.
3562
3563 If the length of the input string is not even, it behaves as if padded
3564 by a null character at the end.  Similarly, during unpack()ing the "extra"
3565 nybbles are ignored.
3566
3567 If the input string of pack() is longer than needed, extra characters are
3568 ignored.
3569 A C<*> for the repeat count of pack() means to use all the characters of
3570 the input field.  On unpack()ing the nybbles are converted to a string
3571 of hexadecimal digits.
3572
3573 =item *
3574
3575 The C<p> type packs a pointer to a null-terminated string.  You are
3576 responsible for ensuring the string is not a temporary value (which can
3577 potentially get deallocated before you get around to using the packed result).
3578 The C<P> type packs a pointer to a structure of the size indicated by the
3579 length.  A NULL pointer is created if the corresponding value for C<p> or
3580 C<P> is C<undef>, similarly for unpack().
3581
3582 If your system has a strange pointer size (i.e. a pointer is neither as
3583 big as an int nor as big as a long), it may not be possible to pack or
3584 unpack pointers in big- or little-endian byte order.  Attempting to do
3585 so will result in a fatal error.
3586
3587 =item *
3588
3589 The C</> template character allows packing and unpacking of a sequence of
3590 items where the packed structure contains a packed item count followed by 
3591 the packed items themselves.
3592 You write I<length-item>C</>I<sequence-item>.
3593
3594 The I<length-item> can be any C<pack> template letter, and describes
3595 how the length value is packed.  The ones likely to be of most use are
3596 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3597 SNMP) and C<N> (for Sun XDR).
3598
3599 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3600 the minimum of that and the number of available items is used as argument
3601 for the I<length-item>. If it has no repeat count or uses a '*', the number
3602 of available items is used. For C<unpack> the repeat count is always obtained
3603 by decoding the packed item count, and the I<sequence-item> must not have a
3604 repeat count.
3605
3606 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3607 the I<length-item> is a string length, not a number of strings. If there is
3608 an explicit repeat count for pack, the packed string will be adjusted to that
3609 given length.
3610
3611     unpack 'W/a', "\04Gurusamy";        gives ('Guru')
3612     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond', 'J')
3613     pack 'n/a* w/a','hello,','world';   gives "\000\006hello,\005world"
3614     pack 'a/W2', ord('a') .. ord('z');  gives '2ab'
3615
3616 The I<length-item> is not returned explicitly from C<unpack>.
3617
3618 Adding a count to the I<length-item> letter is unlikely to do anything
3619 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3620 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3621 which Perl does not regard as legal in numeric strings.
3622
3623 =item *
3624
3625 The integer types C<s>, C<S>, C<l>, and C<L> may be
3626 followed by a C<!> modifier to signify native shorts or
3627 longs--as you can see from above for example a bare C<l> does mean
3628 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3629 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3630 see whether using C<!> makes any difference by
3631
3632         print length(pack("s")), " ", length(pack("s!")), "\n";
3633         print length(pack("l")), " ", length(pack("l!")), "\n";
3634
3635 C<i!> and C<I!> also work but only because of completeness;
3636 they are identical to C<i> and C<I>.
3637
3638 The actual sizes (in bytes) of native shorts, ints, longs, and long
3639 longs on the platform where Perl was built are also available via
3640 L<Config>:
3641
3642        use Config;
3643        print $Config{shortsize},    "\n";
3644        print $Config{intsize},      "\n";
3645        print $Config{longsize},     "\n";
3646        print $Config{longlongsize}, "\n";
3647
3648 (The C<$Config{longlongsize}> will be undefined if your system does
3649 not support long longs.)
3650
3651 =item *
3652
3653 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3654 are inherently non-portable between processors and operating systems
3655 because they obey the native byteorder and endianness.  For example a
3656 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3657 (arranged in and handled by the CPU registers) into bytes as
3658
3659         0x12 0x34 0x56 0x78     # big-endian
3660         0x78 0x56 0x34 0x12     # little-endian
3661
3662 Basically, the Intel and VAX CPUs are little-endian, while everybody
3663 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3664 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3665 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3666 mode.
3667
3668 The names `big-endian' and `little-endian' are comic references to
3669 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3670 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3671 the egg-eating habits of the Lilliputians.
3672
3673 Some systems may have even weirder byte orders such as
3674
3675         0x56 0x78 0x12 0x34
3676         0x34 0x12 0x78 0x56
3677
3678 You can see your system's preference with
3679
3680         print join(" ", map { sprintf "%#02x", $_ }
3681                             unpack("W*",pack("L",0x12345678))), "\n";
3682
3683 The byteorder on the platform where Perl was built is also available
3684 via L<Config>:
3685
3686         use Config;
3687         print $Config{byteorder}, "\n";
3688
3689 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3690 and C<'87654321'> are big-endian.
3691
3692 If you want portable packed integers you can either use the formats
3693 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3694 modifiers.  These modifiers are only available as of perl 5.9.2.
3695 See also L<perlport>.
3696
3697 =item *
3698
3699 All integer and floating point formats as well as C<p> and C<P> and
3700 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3701 to force big- or little- endian byte-order, respectively.
3702 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3703 signed integers, 64-bit integers and floating point values.  However,
3704 there are some things to keep in mind.
3705
3706 Exchanging signed integers between different platforms only works
3707 if all platforms store them in the same format.  Most platforms store
3708 signed integers in two's complement, so usually this is not an issue.
3709
3710 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3711 formats on big- or little-endian machines.  Otherwise, attempting to
3712 do so will result in a fatal error.
3713
3714 Forcing big- or little-endian byte-order on floating point values for
3715 data exchange can only work if all platforms are using the same
3716 binary representation (e.g. IEEE floating point format).  Even if all
3717 platforms are using IEEE, there may be subtle differences.  Being able
3718 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3719 but also very dangerous if you don't know exactly what you're doing.
3720 It is definitely not a general way to portably store floating point
3721 values.
3722
3723 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3724 all types inside the group that accept the byte-order modifiers,
3725 including all subgroups.  It will silently be ignored for all other
3726 types.  You are not allowed to override the byte-order within a group
3727 that already has a byte-order modifier suffix.
3728
3729 =item *
3730
3731 Real numbers (floats and doubles) are in the native machine format only;
3732 due to the multiplicity of floating formats around, and the lack of a
3733 standard "network" representation, no facility for interchange has been
3734 made.  This means that packed floating point data written on one machine
3735 may not be readable on another - even if both use IEEE floating point
3736 arithmetic (as the endian-ness of the memory representation is not part
3737 of the IEEE spec).  See also L<perlport>.
3738
3739 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3740 modifiers to force big- or little-endian byte-order on floating point values.
3741
3742 Note that Perl uses doubles (or long doubles, if configured) internally for
3743 all numeric calculation, and converting from double into float and thence back
3744 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3745 will not in general equal $foo).
3746
3747 =item *
3748
3749 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3750 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3751 where the packed string is processed in its UTF-8-encoded Unicode form on
3752 a byte by byte basis. Character mode is the default unless the format string 
3753 starts with an C<U>. You can switch mode at any moment with an explicit 
3754 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3755 or until the end of the ()-group in which it was entered.
3756
3757 =item *
3758
3759 You must yourself do any alignment or padding by inserting for example
3760 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3761 could know where the characters are going to or coming from.  Therefore
3762 C<pack> (and C<unpack>) handle their output and input as flat
3763 sequences of characters.
3764
3765 =item *
3766
3767 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3768 take a repeat count, both as postfix, and for unpack() also via the C</>
3769 template character. Within each repetition of a group, positioning with
3770 C<@> starts again at 0. Therefore, the result of
3771
3772     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3773
3774 is the string "\0a\0\0bc".
3775
3776 =item *
3777
3778 C<x> and C<X> accept C<!> modifier.  In this case they act as
3779 alignment commands: they jump forward/back to the closest position
3780 aligned at a multiple of C<count> characters. For example, to pack() or
3781 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3782 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3783 aligned on the double's size.
3784
3785 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3786 both result in no-ops.
3787
3788 =item *
3789
3790 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3791 will represent signed 16-/32-bit integers in big-/little-endian order.
3792 This is only portable if all platforms sharing the packed data use the
3793 same binary representation for signed integers (e.g. all platforms are
3794 using two's complement representation).
3795
3796 =item *
3797
3798 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3799 White space may be used to separate pack codes from each other, but
3800 modifiers and a repeat count must follow immediately.
3801
3802 =item *
3803
3804 If TEMPLATE requires more arguments to pack() than actually given, pack()
3805 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
3806 to pack() than actually given, extra arguments are ignored.
3807
3808 =back
3809
3810 Examples:
3811
3812     $foo = pack("WWWW",65,66,67,68);
3813     # foo eq "ABCD"
3814     $foo = pack("W4",65,66,67,68);
3815     # same thing
3816     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3817     # same thing with Unicode circled letters.
3818     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3819     # same thing with Unicode circled letters. You don't get the UTF-8
3820     # bytes because the U at the start of the format caused a switch to
3821     # U0-mode, so the UTF-8 bytes get joined into characters
3822     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3823     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3824     # This is the UTF-8 encoding of the string in the previous example
3825
3826     $foo = pack("ccxxcc",65,66,67,68);
3827     # foo eq "AB\0\0CD"
3828
3829     # note: the above examples featuring "W" and "c" are true
3830     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3831     # and UTF-8.  In EBCDIC the first example would be
3832     # $foo = pack("WWWW",193,194,195,196);
3833
3834     $foo = pack("s2",1,2);
3835     # "\1\0\2\0" on little-endian
3836     # "\0\1\0\2" on big-endian
3837
3838     $foo = pack("a4","abcd","x","y","z");
3839     # "abcd"
3840
3841     $foo = pack("aaaa","abcd","x","y","z");
3842     # "axyz"
3843
3844     $foo = pack("a14","abcdefg");
3845     # "abcdefg\0\0\0\0\0\0\0"
3846
3847     $foo = pack("i9pl", gmtime);
3848     # a real struct tm (on my system anyway)
3849
3850     $utmp_template = "Z8 Z8 Z16 L";
3851     $utmp = pack($utmp_template, @utmp1);
3852     # a struct utmp (BSDish)
3853
3854     @utmp2 = unpack($utmp_template, $utmp);
3855     # "@utmp1" eq "@utmp2"
3856
3857     sub bintodec {
3858         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3859     }
3860
3861     $foo = pack('sx2l', 12, 34);
3862     # short 12, two zero bytes padding, long 34
3863     $bar = pack('s@4l', 12, 34);
3864     # short 12, zero fill to position 4, long 34
3865     # $foo eq $bar
3866     $baz = pack('s.l', 12, 4, 34);
3867     # short 12, zero fill to position 4, long 34
3868
3869     $foo = pack('nN', 42, 4711);
3870     # pack big-endian 16- and 32-bit unsigned integers
3871     $foo = pack('S>L>', 42, 4711);
3872     # exactly the same
3873     $foo = pack('s<l<', -42, 4711);
3874     # pack little-endian 16- and 32-bit signed integers
3875     $foo = pack('(sl)<', -42, 4711);
3876     # exactly the same
3877
3878 The same template may generally also be used in unpack().
3879
3880 =item package NAMESPACE
3881
3882 =item package
3883
3884 Declares the compilation unit as being in the given namespace.  The scope
3885 of the package declaration is from the declaration itself through the end
3886 of the enclosing block, file, or eval (the same as the C<my> operator).
3887 All further unqualified dynamic identifiers will be in this namespace.
3888 A package statement affects only dynamic variables--including those
3889 you've used C<local> on--but I<not> lexical variables, which are created
3890 with C<my>.  Typically it would be the first declaration in a file to
3891 be included by the C<require> or C<use> operator.  You can switch into a
3892 package in more than one place; it merely influences which symbol table
3893 is used by the compiler for the rest of that block.  You can refer to
3894 variables and filehandles in other packages by prefixing the identifier
3895 with the package name and a double colon:  C<$Package::Variable>.
3896 If the package name is null, the C<main> package as assumed.  That is,
3897 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3898 still seen in older code).
3899
3900 If NAMESPACE is omitted, then there is no current package, and all
3901 identifiers must be fully qualified or lexicals.  However, you are
3902 strongly advised not to make use of this feature. Its use can cause
3903 unexpected behaviour, even crashing some versions of Perl. It is
3904 deprecated, and will be removed from a future release.
3905
3906 See L<perlmod/"Packages"> for more information about packages, modules,
3907 and classes.  See L<perlsub> for other scoping issues.
3908
3909 =item pipe READHANDLE,WRITEHANDLE
3910
3911 Opens a pair of connected pipes like the corresponding system call.
3912 Note that if you set up a loop of piped processes, deadlock can occur
3913 unless you are very careful.  In addition, note that Perl's pipes use
3914 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3915 after each command, depending on the application.
3916
3917 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3918 for examples of such things.
3919
3920 On systems that support a close-on-exec flag on files, the flag will be set
3921 for the newly opened file descriptors as determined by the value of $^F.
3922 See L<perlvar/$^F>.
3923
3924 =item pop ARRAY
3925
3926 =item pop
3927
3928 Pops and returns the last value of the array, shortening the array by
3929 one element.  Has an effect similar to
3930
3931     $ARRAY[$#ARRAY--]
3932
3933 If there are no elements in the array, returns the undefined value
3934 (although this may happen at other times as well).  If ARRAY is
3935 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3936 array in subroutines, just like C<shift>.
3937
3938 =item pos SCALAR
3939
3940 =item pos
3941
3942 Returns the offset of where the last C<m//g> search left off for the variable
3943 in question (C<$_> is used when the variable is not specified).  Note that
3944 0 is a valid match offset.  C<undef> indicates that the search position
3945 is reset (usually due to match failure, but can also be because no match has
3946 yet been performed on the scalar). C<pos> directly accesses the location used
3947 by the regexp engine to store the offset, so assigning to C<pos> will change
3948 that offset, and so will also influence the C<\G> zero-width assertion in
3949 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
3950 the return from C<pos> won't change either in this case.  See L<perlre> and
3951 L<perlop>.
3952
3953 =item print FILEHANDLE LIST
3954
3955 =item print LIST
3956
3957 =item print
3958
3959 Prints a string or a list of strings.  Returns true if successful.
3960 FILEHANDLE may be a scalar variable name, in which case the variable
3961 contains the name of or a reference to the filehandle, thus introducing
3962 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3963 the next token is a term, it may be misinterpreted as an operator
3964 unless you interpose a C<+> or put parentheses around the arguments.)
3965 If FILEHANDLE is omitted, prints by default to standard output (or
3966 to the last selected output channel--see L</select>).  If LIST is
3967 also omitted, prints C<$_> to the currently selected output channel.
3968 To set the default output channel to something other than STDOUT
3969 use the select operation.  The current value of C<$,> (if any) is
3970 printed between each LIST item.  The current value of C<$\> (if
3971 any) is printed after the entire LIST has been printed.  Because
3972 print takes a LIST, anything in the LIST is evaluated in list
3973 context, and any subroutine that you call will have one or more of
3974 its expressions evaluated in list context.  Also be careful not to
3975 follow the print keyword with a left parenthesis unless you want
3976 the corresponding right parenthesis to terminate the arguments to
3977 the print--interpose a C<+> or put parentheses around all the
3978 arguments.
3979
3980 Note that if you're storing FILEHANDLEs in an array, or if you're using
3981 any other expression more complex than a scalar variable to retrieve it,
3982 you will have to use a block returning the filehandle value instead:
3983
3984     print { $files[$i] } "stuff\n";
3985     print { $OK ? STDOUT : STDERR } "stuff\n";
3986
3987 =item printf FILEHANDLE FORMAT, LIST
3988
3989 =item printf FORMAT, LIST
3990
3991 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3992 (the output record separator) is not appended.  The first argument
3993 of the list will be interpreted as the C<printf> format. See C<sprintf>
3994 for an explanation of the format argument. If C<use locale> is in effect,
3995 the character used for the decimal point in formatted real numbers is
3996 affected by the LC_NUMERIC locale.  See L<perllocale>.
3997
3998 Don't fall into the trap of using a C<printf> when a simple
3999 C<print> would do.  The C<print> is more efficient and less
4000 error prone.
4001
4002 =item prototype FUNCTION
4003
4004 Returns the prototype of a function as a string (or C<undef> if the
4005 function has no prototype).  FUNCTION is a reference to, or the name of,
4006 the function whose prototype you want to retrieve.
4007
4008 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4009 name for Perl builtin.  If the builtin is not I<overridable> (such as
4010 C<qw//>) or its arguments cannot be expressed by a prototype (such as
4011 C<system>) returns C<undef> because the builtin does not really behave
4012 like a Perl function.  Otherwise, the string describing the equivalent
4013 prototype is returned.
4014
4015 =item push ARRAY,LIST
4016
4017 Treats ARRAY as a stack, and pushes the values of LIST
4018 onto the end of ARRAY.  The length of ARRAY increases by the length of
4019 LIST.  Has the same effect as
4020
4021     for $value (LIST) {
4022         $ARRAY[++$#ARRAY] = $value;
4023     }
4024
4025 but is more efficient.  Returns the new number of elements in the array.
4026
4027 =item q/STRING/
4028
4029 =item qq/STRING/
4030
4031 =item qr/STRING/
4032
4033 =item qx/STRING/
4034
4035 =item qw/STRING/
4036
4037 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4038
4039 =item quotemeta EXPR
4040
4041 =item quotemeta
4042
4043 Returns the value of EXPR with all non-"word"
4044 characters backslashed.  (That is, all characters not matching
4045 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4046 returned string, regardless of any locale settings.)
4047 This is the internal function implementing
4048 the C<\Q> escape in double-quoted strings.
4049
4050 If EXPR is omitted, uses C<$_>.
4051
4052 =item rand EXPR
4053
4054 =item rand
4055
4056 Returns a random fractional number greater than or equal to C<0> and less
4057 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4058 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4059 also special-cased as C<1> - this has not been documented before perl 5.8.0
4060 and is subject to change in future versions of perl.  Automatically calls
4061 C<srand> unless C<srand> has already been called.  See also C<srand>.
4062
4063 Apply C<int()> to the value returned by C<rand()> if you want random
4064 integers instead of random fractional numbers.  For example,
4065
4066     int(rand(10))
4067
4068 returns a random integer between C<0> and C<9>, inclusive.
4069
4070 (Note: If your rand function consistently returns numbers that are too
4071 large or too small, then your version of Perl was probably compiled
4072 with the wrong number of RANDBITS.)
4073
4074 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4075
4076 =item read FILEHANDLE,SCALAR,LENGTH
4077
4078 Attempts to read LENGTH I<characters> of data into variable SCALAR
4079 from the specified FILEHANDLE.  Returns the number of characters
4080 actually read, C<0> at end of file, or undef if there was an error (in
4081 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4082 so that the last character actually read is the last character of the
4083 scalar after the read.
4084
4085 An OFFSET may be specified to place the read data at some place in the
4086 string other than the beginning.  A negative OFFSET specifies
4087 placement at that many characters counting backwards from the end of
4088 the string.  A positive OFFSET greater than the length of SCALAR
4089 results in the string being padded to the required size with C<"\0">
4090 bytes before the result of the read is appended.
4091
4092 The call is actually implemented in terms of either Perl's or system's
4093 fread() call.  To get a true read(2) system call, see C<sysread>.
4094
4095 Note the I<characters>: depending on the status of the filehandle,
4096 either (8-bit) bytes or characters are read.  By default all
4097 filehandles operate on bytes, but for example if the filehandle has
4098 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4099 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4100 characters, not bytes.  Similarly for the C<:encoding> pragma:
4101 in that case pretty much any characters can be read.
4102
4103 =item readdir DIRHANDLE
4104
4105 Returns the next directory entry for a directory opened by C<opendir>.
4106 If used in list context, returns all the rest of the entries in the
4107 directory.  If there are no more entries, returns an undefined value in
4108 scalar context or a null list in list context.
4109
4110 If you're planning to filetest the return values out of a C<readdir>, you'd
4111 better prepend the directory in question.  Otherwise, because we didn't
4112 C<chdir> there, it would have been testing the wrong file.
4113
4114     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4115     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4116     closedir DIR;
4117
4118 =item readline EXPR
4119
4120 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4121 context, each call reads and returns the next line, until end-of-file is
4122 reached, whereupon the subsequent call returns undef.  In list context,
4123 reads until end-of-file is reached and returns a list of lines.  Note that
4124 the notion of "line" used here is however you may have defined it
4125 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4126
4127 When C<$/> is set to C<undef>, when readline() is in scalar
4128 context (i.e. file slurp mode), and when an empty file is read, it
4129 returns C<''> the first time, followed by C<undef> subsequently.
4130
4131 This is the internal function implementing the C<< <EXPR> >>
4132 operator, but you can use it directly.  The C<< <EXPR> >>
4133 operator is discussed in more detail in L<perlop/"I/O Operators">.
4134
4135     $line = <STDIN>;
4136     $line = readline(*STDIN);           # same thing
4137
4138 If readline encounters an operating system error, C<$!> will be set with the
4139 corresponding error message.  It can be helpful to check C<$!> when you are
4140 reading from filehandles you don't trust, such as a tty or a socket.  The
4141 following example uses the operator form of C<readline>, and takes the necessary
4142 steps to ensure that C<readline> was successful.
4143
4144     for (;;) {
4145         undef $!;
4146         unless (defined( $line = <> )) {
4147             die $! if $!;
4148             last; # reached EOF
4149         }
4150         # ...
4151     }
4152
4153 =item readlink EXPR
4154
4155 =item readlink
4156
4157 Returns the value of a symbolic link, if symbolic links are
4158 implemented.  If not, gives a fatal error.  If there is some system
4159 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4160 omitted, uses C<$_>.
4161
4162 =item readpipe EXPR
4163
4164 EXPR is executed as a system command.
4165 The collected standard output of the command is returned.
4166 In scalar context, it comes back as a single (potentially
4167 multi-line) string.  In list context, returns a list of lines
4168 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4169 This is the internal function implementing the C<qx/EXPR/>
4170 operator, but you can use it directly.  The C<qx/EXPR/>
4171 operator is discussed in more detail in L<perlop/"I/O Operators">.
4172
4173 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4174
4175 Receives a message on a socket.  Attempts to receive LENGTH characters
4176 of data into variable SCALAR from the specified SOCKET filehandle.
4177 SCALAR will be grown or shrunk to the length actually read.  Takes the
4178 same flags as the system call of the same name.  Returns the address
4179 of the sender if SOCKET's protocol supports this; returns an empty
4180 string otherwise.  If there's an error, returns the undefined value.
4181 This call is actually implemented in terms of recvfrom(2) system call.
4182 See L<perlipc/"UDP: Message Passing"> for examples.
4183
4184 Note the I<characters>: depending on the status of the socket, either
4185 (8-bit) bytes or characters are received.  By default all sockets
4186 operate on bytes, but for example if the socket has been changed using
4187 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4188 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4189 characters, not bytes.  Similarly for the C<:encoding> pragma:
4190 in that case pretty much any characters can be read.
4191
4192 =item redo LABEL
4193
4194 =item redo
4195
4196 The C<redo> command restarts the loop block without evaluating the
4197 conditional again.  The C<continue> block, if any, is not executed.  If
4198 the LABEL is omitted, the command refers to the innermost enclosing
4199 loop.  Programs that want to lie to themselves about what was just input 
4200 normally use this command:
4201
4202     # a simpleminded Pascal comment stripper
4203     # (warning: assumes no { or } in strings)
4204     LINE: while (<STDIN>) {
4205         while (s|({.*}.*){.*}|$1 |) {}
4206         s|{.*}| |;
4207         if (s|{.*| |) {
4208             $front = $_;
4209             while (<STDIN>) {
4210                 if (/}/) {      # end of comment?
4211                     s|^|$front\{|;
4212                     redo LINE;
4213                 }
4214             }
4215         }
4216         print;
4217     }
4218
4219 C<redo> cannot be used to retry a block which returns a value such as
4220 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4221 a grep() or map() operation.
4222
4223 Note that a block by itself is semantically identical to a loop
4224 that executes once.  Thus C<redo> inside such a block will effectively
4225 turn it into a looping construct.
4226
4227 See also L</continue> for an illustration of how C<last>, C<next>, and
4228 C<redo> work.
4229
4230 =item ref EXPR
4231
4232 =item ref
4233
4234 Returns a non-empty string if EXPR is a reference, the empty
4235 string otherwise. If EXPR
4236 is not specified, C<$_> will be used.  The value returned depends on the
4237 type of thing the reference is a reference to.
4238 Builtin types include:
4239
4240     SCALAR
4241     ARRAY
4242     HASH
4243     CODE
4244     REF
4245     GLOB
4246     LVALUE
4247
4248 If the referenced object has been blessed into a package, then that package
4249 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4250
4251     if (ref($r) eq "HASH") {
4252         print "r is a reference to a hash.\n";
4253     }
4254     unless (ref($r)) {
4255         print "r is not a reference at all.\n";
4256     }
4257
4258 See also L<perlref>.
4259
4260 =item rename OLDNAME,NEWNAME
4261
4262 Changes the name of a file; an existing file NEWNAME will be
4263 clobbered.  Returns true for success, false otherwise.
4264
4265 Behavior of this function varies wildly depending on your system
4266 implementation.  For example, it will usually not work across file system
4267 boundaries, even though the system I<mv> command sometimes compensates
4268 for this.  Other restrictions include whether it works on directories,
4269 open files, or pre-existing files.  Check L<perlport> and either the
4270 rename(2) manpage or equivalent system documentation for details.
4271
4272 =item require VERSION
4273
4274 =item require EXPR
4275
4276 =item require
4277
4278 Demands a version of Perl specified by VERSION, or demands some semantics
4279 specified by EXPR or by C<$_> if EXPR is not supplied.
4280
4281 VERSION may be either a numeric argument such as 5.006, which will be
4282 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4283 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4284 VERSION is greater than the version of the current Perl interpreter.
4285 Compare with L</use>, which can do a similar check at compile time.
4286
4287 Specifying VERSION as a literal of the form v5.6.1 should generally be
4288 avoided, because it leads to misleading error messages under earlier
4289 versions of Perl that do not support this syntax.  The equivalent numeric
4290 version should be used instead.
4291
4292     require v5.6.1;     # run time version check
4293     require 5.6.1;      # ditto
4294     require 5.006_001;  # ditto; preferred for backwards compatibility
4295
4296 Otherwise, C<ref> demands that a library file be included if it hasn't already
4297 been included.  The file is included via the do-FILE mechanism, which is
4298 essentially just a variety of C<eval>.  Has semantics similar to the
4299 following subroutine:
4300
4301     sub require {
4302        my ($filename) = @_;
4303        if (exists $INC{$filename}) {
4304            return 1 if $INC{$filename};
4305            die "Compilation failed in require";
4306        }
4307        my ($realfilename,$result);
4308        ITER: {
4309            foreach $prefix (@INC) {
4310                $realfilename = "$prefix/$filename";
4311                if (-f $realfilename) {
4312                    $INC{$filename} = $realfilename;
4313                    $result = do $realfilename;
4314                    last ITER;
4315                }
4316            }
4317            die "Can't find $filename in \@INC";
4318        }
4319        if ($@) {
4320            $INC{$filename} = undef;
4321            die $@;
4322        } elsif (!$result) {
4323            delete $INC{$filename};
4324            die "$filename did not return true value";
4325        } else {
4326            return $result;
4327        }
4328     }
4329
4330 Note that the file will not be included twice under the same specified
4331 name.
4332
4333 The file must return true as the last statement to indicate
4334 successful execution of any initialization code, so it's customary to
4335 end such a file with C<1;> unless you're sure it'll return true
4336 otherwise.  But it's better just to put the C<1;>, in case you add more
4337 statements.
4338
4339 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4340 replaces "F<::>" with "F</>" in the filename for you,
4341 to make it easy to load standard modules.  This form of loading of
4342 modules does not risk altering your namespace.
4343
4344 In other words, if you try this:
4345
4346         require Foo::Bar;    # a splendid bareword
4347
4348 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4349 directories specified in the C<@INC> array.
4350
4351 But if you try this:
4352
4353         $class = 'Foo::Bar';
4354         require $class;      # $class is not a bareword
4355     #or
4356         require "Foo::Bar";  # not a bareword because of the ""
4357
4358 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4359 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4360
4361         eval "require $class";
4362
4363 Now that you understand how C<require> looks for files in the case of
4364 a bareword argument, there is a little extra functionality going on
4365 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4366 it will first look for a filename with a "F<.pmc>" extension.  A file
4367 with this extension is assumed to be Perl bytecode generated by
4368 L<B::Bytecode|B::Bytecode>.  If this file is found, and its modification
4369 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4370 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4371
4372 You can also insert hooks into the import facility, by putting directly
4373 Perl code into the @INC array.  There are three forms of hooks: subroutine
4374 references, array references and blessed objects.
4375
4376 Subroutine references are the simplest case.  When the inclusion system
4377 walks through @INC and encounters a subroutine, this subroutine gets
4378 called with two parameters, the first being a reference to itself, and the
4379 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4380 subroutine should return C<undef> or a filehandle, from which the file to
4381 include will be read.  If C<undef> is returned, C<require> will look at
4382 the remaining elements of @INC.
4383
4384 If the hook is an array reference, its first element must be a subroutine
4385 reference.  This subroutine is called as above, but the first parameter is
4386 the array reference.  This enables to pass indirectly some arguments to
4387 the subroutine.
4388
4389 In other words, you can write:
4390
4391     push @INC, \&my_sub;
4392     sub my_sub {
4393         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4394         ...
4395     }
4396
4397 or:
4398
4399     push @INC, [ \&my_sub, $x, $y, ... ];
4400     sub my_sub {
4401         my ($arrayref, $filename) = @_;
4402         # Retrieve $x, $y, ...
4403         my @parameters = @$arrayref[1..$#$arrayref];
4404         ...
4405     }
4406
4407 If the hook is an object, it must provide an INC method that will be
4408 called as above, the first parameter being the object itself.  (Note that
4409 you must fully qualify the sub's name, as it is always forced into package
4410 C<main>.)  Here is a typical code layout:
4411
4412     # In Foo.pm
4413     package Foo;
4414     sub new { ... }
4415     sub Foo::INC {
4416         my ($self, $filename) = @_;
4417         ...
4418     }
4419
4420     # In the main program
4421     push @INC, new Foo(...);
4422
4423 Note that these hooks are also permitted to set the %INC entry
4424 corresponding to the files they have loaded. See L<perlvar/%INC>.
4425
4426 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4427
4428 =item reset EXPR
4429
4430 =item reset
4431
4432 Generally used in a C<continue> block at the end of a loop to clear
4433 variables and reset C<??> searches so that they work again.  The
4434 expression is interpreted as a list of single characters (hyphens
4435 allowed for ranges).  All variables and arrays beginning with one of
4436 those letters are reset to their pristine state.  If the expression is
4437 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4438 only variables or searches in the current package.  Always returns
4439 1.  Examples:
4440
4441     reset 'X';          # reset all X variables
4442     reset 'a-z';        # reset lower case variables
4443     reset;              # just reset ?one-time? searches
4444
4445 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4446 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4447 variables--lexical variables are unaffected, but they clean themselves
4448 up on scope exit anyway, so you'll probably want to use them instead.
4449 See L</my>.
4450
4451 =item return EXPR
4452
4453 =item return
4454
4455 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4456 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4457 context, depending on how the return value will be used, and the context
4458 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4459 is given, returns an empty list in list context, the undefined value in
4460 scalar context, and (of course) nothing at all in a void context.
4461
4462 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4463 or do FILE will automatically return the value of the last expression
4464 evaluated.)
4465
4466 =item reverse LIST
4467
4468 In list context, returns a list value consisting of the elements
4469 of LIST in the opposite order.  In scalar context, concatenates the
4470 elements of LIST and returns a string value with all characters
4471 in the opposite order.
4472
4473     print reverse <>;           # line tac, last line first
4474
4475     undef $/;                   # for efficiency of <>
4476     print scalar reverse <>;    # character tac, last line tsrif
4477
4478 Used without arguments in scalar context, reverse() reverses C<$_>.
4479
4480 This operator is also handy for inverting a hash, although there are some
4481 caveats.  If a value is duplicated in the original hash, only one of those
4482 can be represented as a key in the inverted hash.  Also, this has to
4483 unwind one hash and build a whole new one, which may take some time
4484 on a large hash, such as from a DBM file.
4485
4486     %by_name = reverse %by_address;     # Invert the hash
4487
4488 =item rewinddir DIRHANDLE
4489
4490 Sets the current position to the beginning of the directory for the
4491 C<readdir> routine on DIRHANDLE.
4492
4493 =item rindex STR,SUBSTR,POSITION
4494
4495 =item rindex STR,SUBSTR
4496
4497 Works just like index() except that it returns the position of the LAST
4498 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4499 last occurrence at or before that position.
4500
4501 =item rmdir FILENAME
4502
4503 =item rmdir
4504
4505 Deletes the directory specified by FILENAME if that directory is
4506 empty.  If it succeeds it returns true, otherwise it returns false and
4507 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4508
4509 =item s///
4510
4511 The substitution operator.  See L<perlop>.
4512
4513 =item scalar EXPR
4514
4515 Forces EXPR to be interpreted in scalar context and returns the value
4516 of EXPR.
4517
4518     @counts = ( scalar @a, scalar @b, scalar @c );
4519
4520 There is no equivalent operator to force an expression to
4521 be interpolated in list context because in practice, this is never
4522 needed.  If you really wanted to do so, however, you could use
4523 the construction C<@{[ (some expression) ]}>, but usually a simple
4524 C<(some expression)> suffices.
4525
4526 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4527 parenthesized list, this behaves as a scalar comma expression, evaluating
4528 all but the last element in void context and returning the final element
4529 evaluated in scalar context.  This is seldom what you want.
4530
4531 The following single statement:
4532
4533         print uc(scalar(&foo,$bar)),$baz;
4534
4535 is the moral equivalent of these two:
4536
4537         &foo;
4538         print(uc($bar),$baz);
4539
4540 See L<perlop> for more details on unary operators and the comma operator.
4541
4542 =item seek FILEHANDLE,POSITION,WHENCE
4543
4544 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4545 FILEHANDLE may be an expression whose value gives the name of the
4546 filehandle.  The values for WHENCE are C<0> to set the new position
4547 I<in bytes> to POSITION, C<1> to set it to the current position plus
4548 POSITION, and C<2> to set it to EOF plus POSITION (typically
4549 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4550 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4551 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4552 otherwise.
4553
4554 Note the I<in bytes>: even if the filehandle has been set to
4555 operate on characters (for example by using the C<:utf8> open
4556 layer), tell() will return byte offsets, not character offsets
4557 (because implementing that would render seek() and tell() rather slow).
4558
4559 If you want to position file for C<sysread> or C<syswrite>, don't use
4560 C<seek>--buffering makes its effect on the file's system position
4561 unpredictable and non-portable.  Use C<sysseek> instead.
4562
4563 Due to the rules and rigors of ANSI C, on some systems you have to do a
4564 seek whenever you switch between reading and writing.  Amongst other
4565 things, this may have the effect of calling stdio's clearerr(3).
4566 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4567
4568     seek(TEST,0,1);
4569
4570 This is also useful for applications emulating C<tail -f>.  Once you hit
4571 EOF on your read, and then sleep for a while, you might have to stick in a
4572 seek() to reset things.  The C<seek> doesn't change the current position,
4573 but it I<does> clear the end-of-file condition on the handle, so that the
4574 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4575
4576 If that doesn't work (some IO implementations are particularly
4577 cantankerous), then you may need something more like this:
4578
4579     for (;;) {
4580         for ($curpos = tell(FILE); $_ = <FILE>;
4581              $curpos = tell(FILE)) {
4582             # search for some stuff and put it into files
4583         }
4584         sleep($for_a_while);
4585         seek(FILE, $curpos, 0);
4586     }
4587
4588 =item seekdir DIRHANDLE,POS
4589
4590 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4591 must be a value returned by C<telldir>.  C<seekdir> also has the same caveats
4592 about possible directory compaction as the corresponding system library
4593 routine.
4594
4595 =item select FILEHANDLE
4596
4597 =item select
4598
4599 Returns the currently selected filehandle.  Sets the current default
4600 filehandle for output, if FILEHANDLE is supplied.  This has two
4601 effects:&nbs