This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
3c5e0608573f72a71558f675ffcb5e408d18e48e
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34 use re "/aa";
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 sub NON_ASCII_PLATFORM { ord("A") != 65 }
40
41 ##########################################################################
42 #
43 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
44 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
45 # a pod file and .t files, depending on option parameters.
46 #
47 # The structure of this file is:
48 #   First these introductory comments; then
49 #   code needed for everywhere, such as debugging stuff; then
50 #   code to handle input parameters; then
51 #   data structures likely to be of external interest (some of which depend on
52 #       the input parameters, so follows them; then
53 #   more data structures and subroutine and package (class) definitions; then
54 #   the small actual loop to process the input files and finish up; then
55 #   a __DATA__ section, for the .t tests
56 #
57 # This program works on all releases of Unicode so far.  The outputs have been
58 # scrutinized most intently for release 5.1.  The others have been checked for
59 # somewhat more than just sanity.  It can handle all non-provisional Unicode
60 # character properties in those releases.
61 #
62 # This program is mostly about Unicode character (or code point) properties.
63 # A property describes some attribute or quality of a code point, like if it
64 # is lowercase or not, its name, what version of Unicode it was first defined
65 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
66 # possibilities by making all properties into mappings from each code point
67 # into some corresponding value.  In the case of it being lowercase or not,
68 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
69 # property maps each Unicode code point to a single value, called a "property
70 # value".  (Some more recently defined properties, map a code point to a set
71 # of values.)
72 #
73 # When using a property in a regular expression, what is desired isn't the
74 # mapping of the code point to its property's value, but the reverse (or the
75 # mathematical "inverse relation"): starting with the property value, "Does a
76 # code point map to it?"  These are written in a "compound" form:
77 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
78 # files containing the lists of code points that map to each such regular
79 # expression property value, one file per list
80 #
81 # There is also a single form shortcut that Perl adds for many of the commonly
82 # used properties.  This happens for all binary properties, plus script,
83 # general_category, and block properties.
84 #
85 # Thus the outputs of this program are files.  There are map files, mostly in
86 # the 'To' directory; and there are list files for use in regular expression
87 # matching, all in subdirectories of the 'lib' directory, with each
88 # subdirectory being named for the property that the lists in it are for.
89 # Bookkeeping, test, and documentation files are also generated.
90
91 my $matches_directory = 'lib';   # Where match (\p{}) files go.
92 my $map_directory = 'To';        # Where map files go.
93
94 # DATA STRUCTURES
95 #
96 # The major data structures of this program are Property, of course, but also
97 # Table.  There are two kinds of tables, very similar to each other.
98 # "Match_Table" is the data structure giving the list of code points that have
99 # a particular property value, mentioned above.  There is also a "Map_Table"
100 # data structure which gives the property's mapping from code point to value.
101 # There are two structures because the match tables need to be combined in
102 # various ways, such as constructing unions, intersections, complements, etc.,
103 # and the map ones don't.  And there would be problems, perhaps subtle, if
104 # a map table were inadvertently operated on in some of those ways.
105 # The use of separate classes with operations defined on one but not the other
106 # prevents accidentally confusing the two.
107 #
108 # At the heart of each table's data structure is a "Range_List", which is just
109 # an ordered list of "Ranges", plus ancillary information, and methods to
110 # operate on them.  A Range is a compact way to store property information.
111 # Each range has a starting code point, an ending code point, and a value that
112 # is meant to apply to all the code points between the two end points,
113 # inclusive.  For a map table, this value is the property value for those
114 # code points.  Two such ranges could be written like this:
115 #   0x41 .. 0x5A, 'Upper',
116 #   0x61 .. 0x7A, 'Lower'
117 #
118 # Each range also has a type used as a convenience to classify the values.
119 # Most ranges in this program will be Type 0, or normal, but there are some
120 # ranges that have a non-zero type.  These are used only in map tables, and
121 # are for mappings that don't fit into the normal scheme of things.  Mappings
122 # that require a hash entry to communicate with utf8.c are one example;
123 # another example is mappings for charnames.pm to use which indicate a name
124 # that is algorithmically determinable from its code point (and the reverse).
125 # These are used to significantly compact these tables, instead of listing
126 # each one of the tens of thousands individually.
127 #
128 # In a match table, the value of a range is irrelevant (and hence the type as
129 # well, which will always be 0), and arbitrarily set to the null string.
130 # Using the example above, there would be two match tables for those two
131 # entries, one named Upper would contain the 0x41..0x5A range, and the other
132 # named Lower would contain 0x61..0x7A.
133 #
134 # Actually, there are two types of range lists, "Range_Map" is the one
135 # associated with map tables, and "Range_List" with match tables.
136 # Again, this is so that methods can be defined on one and not the others so
137 # as to prevent operating on them in incorrect ways.
138 #
139 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
140 # in the perl core.  All tables could in theory be written, but some are
141 # suppressed because there is no current practical use for them.  It is easy
142 # to change which get written by changing various lists that are near the top
143 # of the actual code in this file.  The table data structures contain enough
144 # ancillary information to allow them to be treated as separate entities for
145 # writing, such as the path to each one's file.  There is a heading in each
146 # map table that gives the format of its entries, and what the map is for all
147 # the code points missing from it.  (This allows tables to be more compact.)
148 #
149 # The Property data structure contains one or more tables.  All properties
150 # contain a map table (except the $perl property which is a
151 # pseudo-property containing only match tables), and any properties that
152 # are usable in regular expression matches also contain various matching
153 # tables, one for each value the property can have.  A binary property can
154 # have two values, True and False (or Y and N, which are preferred by Unicode
155 # terminology).  Thus each of these properties will have a map table that
156 # takes every code point and maps it to Y or N (but having ranges cuts the
157 # number of entries in that table way down), and two match tables, one
158 # which has a list of all the code points that map to Y, and one for all the
159 # code points that map to N.  (For each binary property, a third table is also
160 # generated for the pseudo Perl property.  It contains the identical code
161 # points as the Y table, but can be written in regular expressions, not in the
162 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
163 # properties are binary, but some properties have several possible values,
164 # some have many, and properties like Name have a different value for every
165 # named code point.  Those will not, unless the controlling lists are changed,
166 # have their match tables written out.  But all the ones which can be used in
167 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
168 # a property would have either its map table or its match tables written but
169 # not both.  Again, what gets written is controlled by lists which can easily
170 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
171 # tables needed to reconstruct the Unicode db are now written out, while
172 # suppressing the Unicode .txt files that contain the data.  Our tables are
173 # much more compact than the .txt files, so a significant space savings was
174 # achieved.  Also, tables are not written out that are trivially derivable
175 # from tables that do get written.  So, there typically is no file containing
176 # the code points not matched by a binary property (the table for \P{} versus
177 # lowercase \p{}), since you just need to invert the True table to get the
178 # False table.
179
180 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
181 # how many match tables there are and the content of the maps.  This 'Type' is
182 # different than a range 'Type', so don't get confused by the two concepts
183 # having the same name.
184 #
185 # For information about the Unicode properties, see Unicode's UAX44 document:
186
187 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
188
189 # As stated earlier, this program will work on any release of Unicode so far.
190 # Most obvious problems in earlier data have NOT been corrected except when
191 # necessary to make Perl or this program work reasonably, and to keep out
192 # potential security issues.  For example, no folding information was given in
193 # early releases, so this program substitutes lower case instead, just so that
194 # a regular expression with the /i option will do something that actually
195 # gives the right results in many cases.  There are also a couple other
196 # corrections for version 1.1.5, commented at the point they are made.  As an
197 # example of corrections that weren't made (but could be) is this statement
198 # from DerivedAge.txt: "The supplementary private use code points and the
199 # non-character code points were assigned in version 2.0, but not specifically
200 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
201 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
202 # further down in these introductory comments.
203 #
204 # This program works on all non-provisional properties as of the current
205 # Unicode release, though the files for some are suppressed for various
206 # reasons.  You can change which are output by changing lists in this program.
207 #
208 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
209 # loose matchings rules (from Unicode TR18):
210 #
211 #    The recommended names for UCD properties and property values are in
212 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
213 #    [PropValue]. There are both abbreviated names and longer, more
214 #    descriptive names. It is strongly recommended that both names be
215 #    recognized, and that loose matching of property names be used,
216 #    whereby the case distinctions, whitespace, hyphens, and underbar
217 #    are ignored.
218 #
219 # The program still allows Fuzzy to override its determination of if loose
220 # matching should be used, but it isn't currently used, as it is no longer
221 # needed; the calculations it makes are good enough.
222 #
223 # SUMMARY OF HOW IT WORKS:
224 #
225 #   Process arguments
226 #
227 #   A list is constructed containing each input file that is to be processed
228 #
229 #   Each file on the list is processed in a loop, using the associated handler
230 #   code for each:
231 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
232 #            first.  These files name the properties and property values.
233 #            Objects are created of all the property and property value names
234 #            that the rest of the input should expect, including all synonyms.
235 #        The other input files give mappings from properties to property
236 #           values.  That is, they list code points and say what the mapping
237 #           is under the given property.  Some files give the mappings for
238 #           just one property; and some for many.  This program goes through
239 #           each file and populates the properties and their map tables from
240 #           them.  Some properties are listed in more than one file, and
241 #           Unicode has set up a precedence as to which has priority if there
242 #           is a conflict.  Thus the order of processing matters, and this
243 #           program handles the conflict possibility by processing the
244 #           overriding input files last, so that if necessary they replace
245 #           earlier values.
246 #        After this is all done, the program creates the property mappings not
247 #            furnished by Unicode, but derivable from what it does give.
248 #        The tables of code points that match each property value in each
249 #            property that is accessible by regular expressions are created.
250 #        The Perl-defined properties are created and populated.  Many of these
251 #            require data determined from the earlier steps
252 #        Any Perl-defined synonyms are created, and name clashes between Perl
253 #            and Unicode are reconciled and warned about.
254 #        All the properties are written to files
255 #        Any other files are written, and final warnings issued.
256 #
257 # For clarity, a number of operators have been overloaded to work on tables:
258 #   ~ means invert (take all characters not in the set).  The more
259 #       conventional '!' is not used because of the possibility of confusing
260 #       it with the actual boolean operation.
261 #   + means union
262 #   - means subtraction
263 #   & means intersection
264 # The precedence of these is the order listed.  Parentheses should be
265 # copiously used.  These are not a general scheme.  The operations aren't
266 # defined for a number of things, deliberately, to avoid getting into trouble.
267 # Operations are done on references and affect the underlying structures, so
268 # that the copy constructors for them have been overloaded to not return a new
269 # clone, but the input object itself.
270 #
271 # The bool operator is deliberately not overloaded to avoid confusion with
272 # "should it mean if the object merely exists, or also is non-empty?".
273 #
274 # WHY CERTAIN DESIGN DECISIONS WERE MADE
275 #
276 # This program needs to be able to run under miniperl.  Therefore, it uses a
277 # minimum of other modules, and hence implements some things itself that could
278 # be gotten from CPAN
279 #
280 # This program uses inputs published by the Unicode Consortium.  These can
281 # change incompatibly between releases without the Perl maintainers realizing
282 # it.  Therefore this program is now designed to try to flag these.  It looks
283 # at the directories where the inputs are, and flags any unrecognized files.
284 # It keeps track of all the properties in the files it handles, and flags any
285 # that it doesn't know how to handle.  It also flags any input lines that
286 # don't match the expected syntax, among other checks.
287 #
288 # It is also designed so if a new input file matches one of the known
289 # templates, one hopefully just needs to add it to a list to have it
290 # processed.
291 #
292 # As mentioned earlier, some properties are given in more than one file.  In
293 # particular, the files in the extracted directory are supposedly just
294 # reformattings of the others.  But they contain information not easily
295 # derivable from the other files, including results for Unihan, which this
296 # program doesn't ordinarily look at, and for unassigned code points.  They
297 # also have historically had errors or been incomplete.  In an attempt to
298 # create the best possible data, this program thus processes them first to
299 # glean information missing from the other files; then processes those other
300 # files to override any errors in the extracted ones.  Much of the design was
301 # driven by this need to store things and then possibly override them.
302 #
303 # It tries to keep fatal errors to a minimum, to generate something usable for
304 # testing purposes.  It always looks for files that could be inputs, and will
305 # warn about any that it doesn't know how to handle (the -q option suppresses
306 # the warning).
307 #
308 # Why is there more than one type of range?
309 #   This simplified things.  There are some very specialized code points that
310 #   have to be handled specially for output, such as Hangul syllable names.
311 #   By creating a range type (done late in the development process), it
312 #   allowed this to be stored with the range, and overridden by other input.
313 #   Originally these were stored in another data structure, and it became a
314 #   mess trying to decide if a second file that was for the same property was
315 #   overriding the earlier one or not.
316 #
317 # Why are there two kinds of tables, match and map?
318 #   (And there is a base class shared by the two as well.)  As stated above,
319 #   they actually are for different things.  Development proceeded much more
320 #   smoothly when I (khw) realized the distinction.  Map tables are used to
321 #   give the property value for every code point (actually every code point
322 #   that doesn't map to a default value).  Match tables are used for regular
323 #   expression matches, and are essentially the inverse mapping.  Separating
324 #   the two allows more specialized methods, and error checks so that one
325 #   can't just take the intersection of two map tables, for example, as that
326 #   is nonsensical.
327 #
328 # What about 'fate' and 'status'.  The concept of a table's fate was created
329 #   late when it became clear that something more was needed.  The difference
330 #   between this and 'status' is unclean, and could be improved if someone
331 #   wanted to spend the effort.
332 #
333 # DEBUGGING
334 #
335 # This program is written so it will run under miniperl.  Occasionally changes
336 # will cause an error where the backtrace doesn't work well under miniperl.
337 # To diagnose the problem, you can instead run it under regular perl, if you
338 # have one compiled.
339 #
340 # There is a good trace facility.  To enable it, first sub DEBUG must be set
341 # to return true.  Then a line like
342 #
343 # local $to_trace = 1 if main::DEBUG;
344 #
345 # can be added to enable tracing in its lexical scope (plus dynamic) or until
346 # you insert another line:
347 #
348 # local $to_trace = 0 if main::DEBUG;
349 #
350 # To actually trace, use a line like "trace $a, @b, %c, ...;
351 #
352 # Some of the more complex subroutines already have trace statements in them.
353 # Permanent trace statements should be like:
354 #
355 # trace ... if main::DEBUG && $to_trace;
356 #
357 # If there is just one or a few files that you're debugging, you can easily
358 # cause most everything else to be skipped.  Change the line
359 #
360 # my $debug_skip = 0;
361 #
362 # to 1, and every file whose object is in @input_file_objects and doesn't have
363 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
364 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
365 #
366 # To compare the output tables, it may be useful to specify the -annotate
367 # flag.  (As of this writing, this can't be done on a clean workspace, due to
368 # requirements in Text::Tabs used in this option; so first run mktables
369 # without this option.)  This option adds comment lines to each table, one for
370 # each non-algorithmically named character giving, currently its code point,
371 # name, and graphic representation if printable (and you have a font that
372 # knows about it).  This makes it easier to see what the particular code
373 # points are in each output table.  Non-named code points are annotated with a
374 # description of their status, and contiguous ones with the same description
375 # will be output as a range rather than individually.  Algorithmically named
376 # characters are also output as ranges, except when there are just a few
377 # contiguous ones.
378 #
379 # FUTURE ISSUES
380 #
381 # The program would break if Unicode were to change its names so that
382 # interior white space, underscores, or dashes differences were significant
383 # within property and property value names.
384 #
385 # It might be easier to use the xml versions of the UCD if this program ever
386 # would need heavy revision, and the ability to handle old versions was not
387 # required.
388 #
389 # There is the potential for name collisions, in that Perl has chosen names
390 # that Unicode could decide it also likes.  There have been such collisions in
391 # the past, with mostly Perl deciding to adopt the Unicode definition of the
392 # name.  However in the 5.2 Unicode beta testing, there were a number of such
393 # collisions, which were withdrawn before the final release, because of Perl's
394 # and other's protests.  These all involved new properties which began with
395 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
396 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
397 # Unicode document, so they are unlikely to be used by Unicode for another
398 # purpose.  However, they might try something beginning with 'In', or use any
399 # of the other Perl-defined properties.  This program will warn you of name
400 # collisions, and refuse to generate tables with them, but manual intervention
401 # will be required in this event.  One scheme that could be implemented, if
402 # necessary, would be to have this program generate another file, or add a
403 # field to mktables.lst that gives the date of first definition of a property.
404 # Each new release of Unicode would use that file as a basis for the next
405 # iteration.  And the Perl synonym addition code could sort based on the age
406 # of the property, so older properties get priority, and newer ones that clash
407 # would be refused; hence existing code would not be impacted, and some other
408 # synonym would have to be used for the new property.  This is ugly, and
409 # manual intervention would certainly be easier to do in the short run; lets
410 # hope it never comes to this.
411 #
412 # A NOTE ON UNIHAN
413 #
414 # This program can generate tables from the Unihan database.  But it doesn't
415 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
416 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
417 # database was split into 8 different files, all beginning with the letters
418 # 'Unihan'.  This program will read those file(s) if present, but it needs to
419 # know which of the many properties in the file(s) should have tables created
420 # for them.  It will create tables for any properties listed in
421 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
422 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
423 # property you want is not in those files of the release you are building
424 # against, you must add it to those two arrays.  Starting in 4.0, the
425 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
426 # is present in the directory, a table will be generated for that property.
427 # In 5.2, several more properties were added.  For your convenience, the two
428 # arrays are initialized with all the 6.0 listed properties that are also in
429 # earlier releases.  But these are commented out.  You can just uncomment the
430 # ones you want, or use them as a template for adding entries for other
431 # properties.
432 #
433 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
434 # and filter_unihan_line() are the functions where this is done.  This program
435 # already does some adjusting to make the lines look more like the rest of the
436 # Unicode DB;  You can see what that is in filter_unihan_line()
437 #
438 # There is a bug in the 3.2 data file in which some values for the
439 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
440 # could be added for these; or for a particular installation, the Unihan.txt
441 # file could be edited to fix them.
442 #
443 # HOW TO ADD A FILE TO BE PROCESSED
444 #
445 # A new file from Unicode needs to have an object constructed for it in
446 # @input_file_objects, probably at the end or at the end of the extracted
447 # ones.  The program should warn you if its name will clash with others on
448 # restrictive file systems, like DOS.  If so, figure out a better name, and
449 # add lines to the README.perl file giving that.  If the file is a character
450 # property, it should be in the format that Unicode has implicitly
451 # standardized for such files for the more recently introduced ones.
452 # If so, the Input_file constructor for @input_file_objects can just be the
453 # file name and release it first appeared in.  If not, then it should be
454 # possible to construct an each_line_handler() to massage the line into the
455 # standardized form.
456 #
457 # For non-character properties, more code will be needed.  You can look at
458 # the existing entries for clues.
459 #
460 # UNICODE VERSIONS NOTES
461 #
462 # The Unicode UCD has had a number of errors in it over the versions.  And
463 # these remain, by policy, in the standard for that version.  Therefore it is
464 # risky to correct them, because code may be expecting the error.  So this
465 # program doesn't generally make changes, unless the error breaks the Perl
466 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
467 # for U+1105, which causes real problems for the algorithms for Jamo
468 # calculations, so it is changed here.
469 #
470 # But it isn't so clear cut as to what to do about concepts that are
471 # introduced in a later release; should they extend back to earlier releases
472 # where the concept just didn't exist?  It was easier to do this than to not,
473 # so that's what was done.  For example, the default value for code points not
474 # in the files for various properties was probably undefined until changed by
475 # some version.  No_Block for blocks is such an example.  This program will
476 # assign No_Block even in Unicode versions that didn't have it.  This has the
477 # benefit that code being written doesn't have to special case earlier
478 # versions; and the detriment that it doesn't match the Standard precisely for
479 # the affected versions.
480 #
481 # Here are some observations about some of the issues in early versions:
482 #
483 # Prior to version 3.0, there were 3 character decompositions.  These are not
484 # handled by Unicode::Normalize, nor will it compile when presented a version
485 # that has them.  However, you can trivially get it to compile by simply
486 # ignoring those decompositions, by changing the croak to a carp.  At the time
487 # of this writing, the line (in cpan/Unicode-Normalize/mkheader) reads
488 #
489 #   croak("Weird Canonical Decomposition of U+$h");
490 #
491 # Simply change to a carp.  It will compile, but will not know about any three
492 # character decomposition.
493
494 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
495 # that the reason is that the CJK block starting at 4E00 was removed from
496 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
497 # single property name \p{alpha}) has the correct values.  But the compound
498 # form is simply not generated until 3.1, as it can be argued that prior to
499 # this release, this was not an official property.  The comments for
500 # filter_old_style_proplist() give more details.
501 #
502 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
503 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
504 # reason is that 3.2 introduced U+205F=medium math space, which was not
505 # classed as white space, but Perl figured out that it should have been. 4.0
506 # reclassified it correctly.
507 #
508 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
509 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
510 # became 202, and ATBL was left with no code points, as all the ones that
511 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
512 # name for the class, it would not have been affected, but if it used the
513 # mnemonic, it would have been.
514 #
515 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
516 # points which eventually came to have this script property value, instead
517 # mapped to "Unknown".  But in the next release all these code points were
518 # moved to \p{sc=common} instead.
519 #
520 # The default for missing code points for BidiClass is complicated.  Starting
521 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
522 # tries to do the best it can for earlier releases.  It is done in
523 # process_PropertyAliases()
524 #
525 # In version 2.1.2, the entry in UnicodeData.txt:
526 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
527 # should instead be
528 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
529 # Without this change, there are casing problems for this character.
530 #
531 ##############################################################################
532
533 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
534                         # and errors
535 my $MAX_LINE_WIDTH = 78;
536
537 # Debugging aid to skip most files so as to not be distracted by them when
538 # concentrating on the ones being debugged.  Add
539 # non_skip => 1,
540 # to the constructor for those files you want processed when you set this.
541 # Files with a first version number of 0 are special: they are always
542 # processed regardless of the state of this flag.  Generally, Jamo.txt and
543 # UnicodeData.txt must not be skipped if you want this program to not die
544 # before normal completion.
545 my $debug_skip = 0;
546
547
548 # Normally these are suppressed.
549 my $write_Unicode_deprecated_tables = 0;
550
551 # Set to 1 to enable tracing.
552 our $to_trace = 0;
553
554 { # Closure for trace: debugging aid
555     my $print_caller = 1;        # ? Include calling subroutine name
556     my $main_with_colon = 'main::';
557     my $main_colon_length = length($main_with_colon);
558
559     sub trace {
560         return unless $to_trace;        # Do nothing if global flag not set
561
562         my @input = @_;
563
564         local $DB::trace = 0;
565         $DB::trace = 0;          # Quiet 'used only once' message
566
567         my $line_number;
568
569         # Loop looking up the stack to get the first non-trace caller
570         my $caller_line;
571         my $caller_name;
572         my $i = 0;
573         do {
574             $line_number = $caller_line;
575             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
576             $caller = $main_with_colon unless defined $caller;
577
578             $caller_name = $caller;
579
580             # get rid of pkg
581             $caller_name =~ s/.*:://;
582             if (substr($caller_name, 0, $main_colon_length)
583                 eq $main_with_colon)
584             {
585                 $caller_name = substr($caller_name, $main_colon_length);
586             }
587
588         } until ($caller_name ne 'trace');
589
590         # If the stack was empty, we were called from the top level
591         $caller_name = 'main' if ($caller_name eq ""
592                                     || $caller_name eq 'trace');
593
594         my $output = "";
595         foreach my $string (@input) {
596             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
597             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
598                 $output .= simple_dumper($string);
599             }
600             else {
601                 $string = "$string" if ref $string;
602                 $string = $UNDEF unless defined $string;
603                 chomp $string;
604                 $string = '""' if $string eq "";
605                 $output .= " " if $output ne ""
606                                 && $string ne ""
607                                 && substr($output, -1, 1) ne " "
608                                 && substr($string, 0, 1) ne " ";
609                 $output .= $string;
610             }
611         }
612
613         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
614         print STDERR "$caller_name: " if $print_caller;
615         print STDERR $output, "\n";
616         return;
617     }
618 }
619
620 # This is for a rarely used development feature that allows you to compare two
621 # versions of the Unicode standard without having to deal with changes caused
622 # by the code points introduced in the later version.  Change the 0 to a
623 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
624 # code points introduced in that release and earlier will be used; later ones
625 # are thrown away.  You use the version number of the earliest one you want to
626 # compare; then run this program on directory structures containing each
627 # release, and compare the outputs.  These outputs will therefore include only
628 # the code points common to both releases, and you can see the changes caused
629 # just by the underlying release semantic changes.  For versions earlier than
630 # 3.2, you must copy a version of DAge.txt into the directory.
631 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
632 my $compare_versions = DEBUG
633                        && $string_compare_versions
634                        && pack "C*", split /\./, $string_compare_versions;
635
636 sub uniques {
637     # Returns non-duplicated input values.  From "Perl Best Practices:
638     # Encapsulated Cleverness".  p. 455 in first edition.
639
640     my %seen;
641     # Arguably this breaks encapsulation, if the goal is to permit multiple
642     # distinct objects to stringify to the same value, and be interchangeable.
643     # However, for this program, no two objects stringify identically, and all
644     # lists passed to this function are either objects or strings. So this
645     # doesn't affect correctness, but it does give a couple of percent speedup.
646     no overloading;
647     return grep { ! $seen{$_}++ } @_;
648 }
649
650 $0 = File::Spec->canonpath($0);
651
652 my $make_test_script = 0;      # ? Should we output a test script
653 my $make_norm_test_script = 0; # ? Should we output a normalization test script
654 my $write_unchanged_files = 0; # ? Should we update the output files even if
655                                #    we don't think they have changed
656 my $use_directory = "";        # ? Should we chdir somewhere.
657 my $pod_directory;             # input directory to store the pod file.
658 my $pod_file = 'perluniprops';
659 my $t_path;                     # Path to the .t test file
660 my $file_list = 'mktables.lst'; # File to store input and output file names.
661                                # This is used to speed up the build, by not
662                                # executing the main body of the program if
663                                # nothing on the list has changed since the
664                                # previous build
665 my $make_list = 1;             # ? Should we write $file_list.  Set to always
666                                # make a list so that when the pumpking is
667                                # preparing a release, s/he won't have to do
668                                # special things
669 my $glob_list = 0;             # ? Should we try to include unknown .txt files
670                                # in the input.
671 my $output_range_counts = $debugging_build;   # ? Should we include the number
672                                               # of code points in ranges in
673                                               # the output
674 my $annotate = 0;              # ? Should character names be in the output
675
676 # Verbosity levels; 0 is quiet
677 my $NORMAL_VERBOSITY = 1;
678 my $PROGRESS = 2;
679 my $VERBOSE = 3;
680
681 my $verbosity = $NORMAL_VERBOSITY;
682
683 # Stored in mktables.lst so that if this program is called with different
684 # options, will regenerate even if the files otherwise look like they're
685 # up-to-date.
686 my $command_line_arguments = join " ", @ARGV;
687
688 # Process arguments
689 while (@ARGV) {
690     my $arg = shift @ARGV;
691     if ($arg eq '-v') {
692         $verbosity = $VERBOSE;
693     }
694     elsif ($arg eq '-p') {
695         $verbosity = $PROGRESS;
696         $| = 1;     # Flush buffers as we go.
697     }
698     elsif ($arg eq '-q') {
699         $verbosity = 0;
700     }
701     elsif ($arg eq '-w') {
702         $write_unchanged_files = 1; # update the files even if havent changed
703     }
704     elsif ($arg eq '-check') {
705         my $this = shift @ARGV;
706         my $ok = shift @ARGV;
707         if ($this ne $ok) {
708             print "Skipping as check params are not the same.\n";
709             exit(0);
710         }
711     }
712     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
713         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
714     }
715     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
716     {
717         $make_test_script = 1;
718     }
719     elsif ($arg eq '-makenormtest')
720     {
721         $make_norm_test_script = 1;
722     }
723     elsif ($arg eq '-makelist') {
724         $make_list = 1;
725     }
726     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
727         -d $use_directory or croak "Unknown directory '$use_directory'";
728     }
729     elsif ($arg eq '-L') {
730
731         # Existence not tested until have chdir'd
732         $file_list = shift;
733     }
734     elsif ($arg eq '-globlist') {
735         $glob_list = 1;
736     }
737     elsif ($arg eq '-c') {
738         $output_range_counts = ! $output_range_counts
739     }
740     elsif ($arg eq '-annotate') {
741         $annotate = 1;
742         $debugging_build = 1;
743         $output_range_counts = 1;
744     }
745     else {
746         my $with_c = 'with';
747         $with_c .= 'out' if $output_range_counts;   # Complements the state
748         croak <<END;
749 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
750           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
751           [-check A B ]
752   -c          : Output comments $with_c number of code points in ranges
753   -q          : Quiet Mode: Only output serious warnings.
754   -p          : Set verbosity level to normal plus show progress.
755   -v          : Set Verbosity level high:  Show progress and non-serious
756                 warnings
757   -w          : Write files regardless
758   -C dir      : Change to this directory before proceeding. All relative paths
759                 except those specified by the -P and -T options will be done
760                 with respect to this directory.
761   -P dir      : Output $pod_file file to directory 'dir'.
762   -T path     : Create a test script as 'path'; overrides -maketest
763   -L filelist : Use alternate 'filelist' instead of standard one
764   -globlist   : Take as input all non-Test *.txt files in current and sub
765                 directories
766   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
767                 overrides -T
768   -makelist   : Rewrite the file list $file_list based on current setup
769   -annotate   : Output an annotation for each character in the table files;
770                 useful for debugging mktables, looking at diffs; but is slow
771                 and memory intensive
772   -check A B  : Executes $0 only if A and B are the same
773 END
774     }
775 }
776
777 # Stores the most-recently changed file.  If none have changed, can skip the
778 # build
779 my $most_recent = (stat $0)[9];   # Do this before the chdir!
780
781 # Change directories now, because need to read 'version' early.
782 if ($use_directory) {
783     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
784         $pod_directory = File::Spec->rel2abs($pod_directory);
785     }
786     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
787         $t_path = File::Spec->rel2abs($t_path);
788     }
789     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
790     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
791         $pod_directory = File::Spec->abs2rel($pod_directory);
792     }
793     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
794         $t_path = File::Spec->abs2rel($t_path);
795     }
796 }
797
798 # Get Unicode version into regular and v-string.  This is done now because
799 # various tables below get populated based on it.  These tables are populated
800 # here to be near the top of the file, and so easily seeable by those needing
801 # to modify things.
802 open my $VERSION, "<", "version"
803                     or croak "$0: can't open required file 'version': $!\n";
804 my $string_version = <$VERSION>;
805 close $VERSION;
806 chomp $string_version;
807 my $v_version = pack "C*", split /\./, $string_version;        # v string
808
809 # The following are the complete names of properties with property values that
810 # are known to not match any code points in some versions of Unicode, but that
811 # may change in the future so they should be matchable, hence an empty file is
812 # generated for them.
813 my @tables_that_may_be_empty;
814 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
815                                                     if $v_version lt v6.3.0;
816 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
817 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
818 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
819                                                     if $v_version ge v4.1.0;
820 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
821                                                     if $v_version ge v6.0.0;
822 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
823                                                     if $v_version ge v6.1.0;
824 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
825                                                     if $v_version ge v6.2.0;
826
827 # The lists below are hashes, so the key is the item in the list, and the
828 # value is the reason why it is in the list.  This makes generation of
829 # documentation easier.
830
831 my %why_suppressed;  # No file generated for these.
832
833 # Files aren't generated for empty extraneous properties.  This is arguable.
834 # Extraneous properties generally come about because a property is no longer
835 # used in a newer version of Unicode.  If we generated a file without code
836 # points, programs that used to work on that property will still execute
837 # without errors.  It just won't ever match (or will always match, with \P{}).
838 # This means that the logic is now likely wrong.  I (khw) think its better to
839 # find this out by getting an error message.  Just move them to the table
840 # above to change this behavior
841 my %why_suppress_if_empty_warn_if_not = (
842
843    # It is the only property that has ever officially been removed from the
844    # Standard.  The database never contained any code points for it.
845    'Special_Case_Condition' => 'Obsolete',
846
847    # Apparently never official, but there were code points in some versions of
848    # old-style PropList.txt
849    'Non_Break' => 'Obsolete',
850 );
851
852 # These would normally go in the warn table just above, but they were changed
853 # a long time before this program was written, so warnings about them are
854 # moot.
855 if ($v_version gt v3.2.0) {
856     push @tables_that_may_be_empty,
857                                 'Canonical_Combining_Class=Attached_Below_Left'
858 }
859
860 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
861 # unless explicitly added.
862 if ($v_version ge v5.2.0) {
863     my $unihan = 'Unihan; remove from list if using Unihan';
864     foreach my $table (qw (
865                            kAccountingNumeric
866                            kOtherNumeric
867                            kPrimaryNumeric
868                            kCompatibilityVariant
869                            kIICore
870                            kIRG_GSource
871                            kIRG_HSource
872                            kIRG_JSource
873                            kIRG_KPSource
874                            kIRG_MSource
875                            kIRG_KSource
876                            kIRG_TSource
877                            kIRG_USource
878                            kIRG_VSource
879                            kRSUnicode
880                         ))
881     {
882         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
883     }
884 }
885
886 # Enum values for to_output_map() method in the Map_Table package.
887 my $EXTERNAL_MAP = 1;
888 my $INTERNAL_MAP = 2;
889 my $OUTPUT_ADJUSTED = 3;
890
891 # To override computed values for writing the map tables for these properties.
892 # The default for enum map tables is to write them out, so that the Unicode
893 # .txt files can be removed, but all the data to compute any property value
894 # for any code point is available in a more compact form.
895 my %global_to_output_map = (
896     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
897     # get stuck supporting it if things change.  Since it is a STRING
898     # property, it normally would be listed in the pod, but INTERNAL_MAP
899     # suppresses that.
900     Unicode_1_Name => $INTERNAL_MAP,
901
902     Present_In => 0,                # Suppress, as easily computed from Age
903     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
904                                             # retained, but needed for
905                                             # non-ASCII
906
907     # Suppress, as mapping can be found instead from the
908     # Perl_Decomposition_Mapping file
909     Decomposition_Type => 0,
910 );
911
912 # Properties that this program ignores.
913 my @unimplemented_properties;
914
915 # With this release, it is automatically handled if the Unihan db is
916 # downloaded
917 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
918
919 # There are several types of obsolete properties defined by Unicode.  These
920 # must be hand-edited for every new Unicode release.
921 my %why_deprecated;  # Generates a deprecated warning message if used.
922 my %why_stabilized;  # Documentation only
923 my %why_obsolete;    # Documentation only
924
925 {   # Closure
926     my $simple = 'Perl uses the more complete version';
927     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
928
929     my $other_properties = 'other properties';
930     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
931     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
932
933     %why_deprecated = (
934         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
935         'Jamo_Short_Name' => $contributory,
936         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
937         'Other_Alphabetic' => $contributory,
938         'Other_Default_Ignorable_Code_Point' => $contributory,
939         'Other_Grapheme_Extend' => $contributory,
940         'Other_ID_Continue' => $contributory,
941         'Other_ID_Start' => $contributory,
942         'Other_Lowercase' => $contributory,
943         'Other_Math' => $contributory,
944         'Other_Uppercase' => $contributory,
945         'Expands_On_NFC' => $why_no_expand,
946         'Expands_On_NFD' => $why_no_expand,
947         'Expands_On_NFKC' => $why_no_expand,
948         'Expands_On_NFKD' => $why_no_expand,
949     );
950
951     %why_suppressed = (
952         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
953         # contains the same information, but without the algorithmically
954         # determinable Hangul syllables'.  This file is not published, so it's
955         # existence is not noted in the comment.
956         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or Unicode::UCD::prop_invmap()',
957
958         'Indic_Matra_Category' => "Provisional",
959         'Indic_Syllabic_Category' => "Provisional",
960
961         # Don't suppress ISO_Comment, as otherwise special handling is needed
962         # to differentiate between it and gc=c, which can be written as 'isc',
963         # which is the same characters as ISO_Comment's short name.
964
965         'Name' => "Accessible via \\N{...} or 'use charnames;' or Unicode::UCD::prop_invmap()",
966
967         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold or Unicode::UCD::prop_invmap()",
968         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
969         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
970         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
971
972         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
973     );
974
975     foreach my $property (
976
977             # The following are suppressed because they were made contributory
978             # or deprecated by Unicode before Perl ever thought about
979             # supporting them.
980             'Jamo_Short_Name',
981             'Grapheme_Link',
982             'Expands_On_NFC',
983             'Expands_On_NFD',
984             'Expands_On_NFKC',
985             'Expands_On_NFKD',
986
987             # The following are suppressed because they have been marked
988             # as deprecated for a sufficient amount of time
989             'Other_Alphabetic',
990             'Other_Default_Ignorable_Code_Point',
991             'Other_Grapheme_Extend',
992             'Other_ID_Continue',
993             'Other_ID_Start',
994             'Other_Lowercase',
995             'Other_Math',
996             'Other_Uppercase',
997     ) {
998         $why_suppressed{$property} = $why_deprecated{$property};
999     }
1000
1001     # Customize the message for all the 'Other_' properties
1002     foreach my $property (keys %why_deprecated) {
1003         next if (my $main_property = $property) !~ s/^Other_//;
1004         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
1005     }
1006 }
1007
1008 if ($write_Unicode_deprecated_tables) {
1009     foreach my $property (keys %why_suppressed) {
1010         delete $why_suppressed{$property} if $property =~
1011                                                     / ^ Other | Grapheme /x;
1012     }
1013 }
1014
1015 if ($v_version ge 4.0.0) {
1016     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1017     if ($v_version ge 6.0.0) {
1018         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1019     }
1020 }
1021 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1022     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1023     if ($v_version ge 6.0.0) {
1024         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1025     }
1026 }
1027
1028 # Probably obsolete forever
1029 if ($v_version ge v4.1.0) {
1030     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1031 }
1032 if ($v_version ge v6.0.0) {
1033     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
1034     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1035 }
1036
1037 # This program can create files for enumerated-like properties, such as
1038 # 'Numeric_Type'.  This file would be the same format as for a string
1039 # property, with a mapping from code point to its value, so you could look up,
1040 # for example, the script a code point is in.  But no one so far wants this
1041 # mapping, or they have found another way to get it since this is a new
1042 # feature.  So no file is generated except if it is in this list.
1043 my @output_mapped_properties = split "\n", <<END;
1044 END
1045
1046 # If you are using the Unihan database in a Unicode version before 5.2, you
1047 # need to add the properties that you want to extract from it to this table.
1048 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
1049 # listed, commented out
1050 my @cjk_properties = split "\n", <<'END';
1051 #cjkAccountingNumeric; kAccountingNumeric
1052 #cjkOtherNumeric; kOtherNumeric
1053 #cjkPrimaryNumeric; kPrimaryNumeric
1054 #cjkCompatibilityVariant; kCompatibilityVariant
1055 #cjkIICore ; kIICore
1056 #cjkIRG_GSource; kIRG_GSource
1057 #cjkIRG_HSource; kIRG_HSource
1058 #cjkIRG_JSource; kIRG_JSource
1059 #cjkIRG_KPSource; kIRG_KPSource
1060 #cjkIRG_KSource; kIRG_KSource
1061 #cjkIRG_TSource; kIRG_TSource
1062 #cjkIRG_USource; kIRG_USource
1063 #cjkIRG_VSource; kIRG_VSource
1064 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1065 END
1066
1067 # Similarly for the property values.  For your convenience, the lines in the
1068 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1069 # '#' marks (for Unicode versions before 5.2)
1070 my @cjk_property_values = split "\n", <<'END';
1071 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1072 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1073 ## @missing: 0000..10FFFF; cjkIICore; <none>
1074 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1075 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1076 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1077 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1078 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1079 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1080 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1081 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1082 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1083 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1084 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1085 END
1086
1087 # The input files don't list every code point.  Those not listed are to be
1088 # defaulted to some value.  Below are hard-coded what those values are for
1089 # non-binary properties as of 5.1.  Starting in 5.0, there are
1090 # machine-parsable comment lines in the files that give the defaults; so this
1091 # list shouldn't have to be extended.  The claim is that all missing entries
1092 # for binary properties will default to 'N'.  Unicode tried to change that in
1093 # 5.2, but the beta period produced enough protest that they backed off.
1094 #
1095 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1096 # be in the form that it expects.  The others may be synonyms.
1097 my $CODE_POINT = '<code point>';
1098 my %default_mapping = (
1099     Age => "Unassigned",
1100     # Bidi_Class => Complicated; set in code
1101     Bidi_Mirroring_Glyph => "",
1102     Block => 'No_Block',
1103     Canonical_Combining_Class => 0,
1104     Case_Folding => $CODE_POINT,
1105     Decomposition_Mapping => $CODE_POINT,
1106     Decomposition_Type => 'None',
1107     East_Asian_Width => "Neutral",
1108     FC_NFKC_Closure => $CODE_POINT,
1109     General_Category => 'Cn',
1110     Grapheme_Cluster_Break => 'Other',
1111     Hangul_Syllable_Type => 'NA',
1112     ISO_Comment => "",
1113     Jamo_Short_Name => "",
1114     Joining_Group => "No_Joining_Group",
1115     # Joining_Type => Complicated; set in code
1116     kIICore => 'N',   #                       Is converted to binary
1117     #Line_Break => Complicated; set in code
1118     Lowercase_Mapping => $CODE_POINT,
1119     Name => "",
1120     Name_Alias => "",
1121     NFC_QC => 'Yes',
1122     NFD_QC => 'Yes',
1123     NFKC_QC => 'Yes',
1124     NFKD_QC => 'Yes',
1125     Numeric_Type => 'None',
1126     Numeric_Value => 'NaN',
1127     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1128     Sentence_Break => 'Other',
1129     Simple_Case_Folding => $CODE_POINT,
1130     Simple_Lowercase_Mapping => $CODE_POINT,
1131     Simple_Titlecase_Mapping => $CODE_POINT,
1132     Simple_Uppercase_Mapping => $CODE_POINT,
1133     Titlecase_Mapping => $CODE_POINT,
1134     Unicode_1_Name => "",
1135     Unicode_Radical_Stroke => "",
1136     Uppercase_Mapping => $CODE_POINT,
1137     Word_Break => 'Other',
1138 );
1139
1140 # Below are files that Unicode furnishes, but this program ignores, and why.
1141 # NormalizationCorrections.txt requires some more explanation.  It documents
1142 # the cumulative fixes to erroneous normalizations in earlier Unicode
1143 # versions.  Its main purpose is so that someone running on an earlier version
1144 # can use this file to override what got published in that earlier release.
1145 # It would be easy for mktables to read and handle this file.  But all the
1146 # corrections in it should already be in the other files for the release it
1147 # is.  To get it to actually mean something useful, someone would have to be
1148 # using an earlier Unicode release, and copy it to the files for that release
1149 # and recomplile.  So far there has been no demand to do that, so this hasn't
1150 # been implemented.
1151 my %ignored_files = (
1152     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1153     'Index.txt' => 'Alphabetical index of Unicode characters',
1154     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1155     'NamesList.txt' => 'Annotated list of characters',
1156     'NamesList.html' => 'Describes the format and contents of F<NamesList.txt>',
1157     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1158     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1159     'ReadMe.txt' => 'Documentation',
1160     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1161     'StandardizedVariants.html' => 'Provides a visual display of the standard variant sequences derived from F<StandardizedVariants.txt>.',
1162     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1163     'USourceData.txt' => 'Documentation of status and cross reference of proposals for encoding by Unicode of Unihan characters',
1164     'USourceGlyphs.pdf' => 'Pictures of the characters in F<USourceData.txt>',
1165     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1166     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1167     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1168     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1169 );
1170
1171 my %skipped_files;  # List of files that we skip
1172
1173 ### End of externally interesting definitions, except for @input_file_objects
1174
1175 my $HEADER=<<"EOF";
1176 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1177 # This file is machine-generated by $0 from the Unicode
1178 # database, Version $string_version.  Any changes made here will be lost!
1179 EOF
1180
1181 my $INTERNAL_ONLY_HEADER = <<"EOF";
1182
1183 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1184 # This file is for internal use by core Perl only.  The format and even the
1185 # name or existence of this file are subject to change without notice.  Don't
1186 # use it directly.  Use Unicode::UCD to access the Unicode character data
1187 # base.
1188 EOF
1189
1190 my $DEVELOPMENT_ONLY=<<"EOF";
1191 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1192 # This file contains information artificially constrained to code points
1193 # present in Unicode release $string_compare_versions.
1194 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1195 # not be used for production.
1196
1197 EOF
1198
1199 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1200 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1201 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1202
1203 # We work with above-Unicode code points, up to UV_MAX.   But when you get
1204 # that high, above IV_MAX, some operations don't work, and you can easily get
1205 # overflow.  Therefore for internal use, we use a much smaller number,
1206 # translating it to UV_MAX only for output.  The exact number is immaterial
1207 # (all Unicode code points are treated exactly the same), but the algorithm
1208 # requires it to be at least 2 * $MAX_UNICODE_CODEPOINTS + 1;
1209 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1210 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1211 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1212
1213 my $MAX_PLATFORM_CODEPOINT = ~0;
1214
1215 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1216 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1217 # to decrease backtracking.  The first regex allows the code point to be at
1218 # the end of a word, but to work properly, the word shouldn't end with a valid
1219 # hex character.  The second one won't match a code point at the end of a
1220 # word, and doesn't have the run-on issue
1221 my $run_on_code_point_re =
1222             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1223 my $code_point_re = qr/\b$run_on_code_point_re/;
1224
1225 # This matches the beginning of the line in the Unicode db files that give the
1226 # defaults for code points not listed (i.e., missing) in the file.  The code
1227 # depends on this ending with a semi-colon, so it can assume it is a valid
1228 # field when the line is split() by semi-colons
1229 my $missing_defaults_prefix =
1230             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1231
1232 # Property types.  Unicode has more types, but these are sufficient for our
1233 # purposes.
1234 my $UNKNOWN = -1;   # initialized to illegal value
1235 my $NON_STRING = 1; # Either binary or enum
1236 my $BINARY = 2;
1237 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1238                        # tables, additional true and false tables are
1239                        # generated so that false is anything matching the
1240                        # default value, and true is everything else.
1241 my $ENUM = 4;       # Include catalog
1242 my $STRING = 5;     # Anything else: string or misc
1243
1244 # Some input files have lines that give default values for code points not
1245 # contained in the file.  Sometimes these should be ignored.
1246 my $NO_DEFAULTS = 0;        # Must evaluate to false
1247 my $NOT_IGNORED = 1;
1248 my $IGNORED = 2;
1249
1250 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1251 # and will appear in the main body of the tables in the output files, but
1252 # there are other types of ranges as well, listed below, that are specially
1253 # handled.   There are pseudo-types as well that will never be stored as a
1254 # type, but will affect the calculation of the type.
1255
1256 # 0 is for normal, non-specials
1257 my $MULTI_CP = 1;           # Sequence of more than code point
1258 my $HANGUL_SYLLABLE = 2;
1259 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1260 my $NULL = 4;               # The map is to the null string; utf8.c can't
1261                             # handle these, nor is there an accepted syntax
1262                             # for them in \p{} constructs
1263 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1264                              # otherwise be $MULTI_CP type are instead type 0
1265
1266 # process_generic_property_file() can accept certain overrides in its input.
1267 # Each of these must begin AND end with $CMD_DELIM.
1268 my $CMD_DELIM = "\a";
1269 my $REPLACE_CMD = 'replace';    # Override the Replace
1270 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1271
1272 my $NO = 0;
1273 my $YES = 1;
1274
1275 # Values for the Replace argument to add_range.
1276 # $NO                      # Don't replace; add only the code points not
1277                            # already present.
1278 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1279                            # the comments at the subroutine definition.
1280 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1281 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1282                            # already there
1283 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1284                            # already there
1285 my $CROAK = 6;             # Die with an error if is already there
1286
1287 # Flags to give property statuses.  The phrases are to remind maintainers that
1288 # if the flag is changed, the indefinite article referring to it in the
1289 # documentation may need to be as well.
1290 my $NORMAL = "";
1291 my $DEPRECATED = 'D';
1292 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1293 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1294 my $DISCOURAGED = 'X';
1295 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1296 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1297 my $STRICTER = 'T';
1298 my $a_bold_stricter = "a 'B<$STRICTER>'";
1299 my $A_bold_stricter = "A 'B<$STRICTER>'";
1300 my $STABILIZED = 'S';
1301 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1302 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1303 my $OBSOLETE = 'O';
1304 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1305 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1306
1307 my %status_past_participles = (
1308     $DISCOURAGED => 'discouraged',
1309     $STABILIZED => 'stabilized',
1310     $OBSOLETE => 'obsolete',
1311     $DEPRECATED => 'deprecated',
1312 );
1313
1314 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1315 # externally documented.
1316 my $ORDINARY = 0;       # The normal fate.
1317 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1318                         # but there is a file written that can be used to
1319                         # reconstruct this table
1320 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1321                         # for Perl's internal use only
1322 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1323                         # Is for backwards compatibility for applications that
1324                         # read the file directly, so it's format is
1325                         # unchangeable.
1326 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1327                         # result, we don't bother to do many computations on
1328                         # it.
1329 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1330                         # computations anyway, as the values are needed for
1331                         # things to work.  This happens when we have Perl
1332                         # extensions that depend on Unicode tables that
1333                         # wouldn't normally be in a given Unicode version.
1334
1335 # The format of the values of the tables:
1336 my $EMPTY_FORMAT = "";
1337 my $BINARY_FORMAT = 'b';
1338 my $DECIMAL_FORMAT = 'd';
1339 my $FLOAT_FORMAT = 'f';
1340 my $INTEGER_FORMAT = 'i';
1341 my $HEX_FORMAT = 'x';
1342 my $RATIONAL_FORMAT = 'r';
1343 my $STRING_FORMAT = 's';
1344 my $ADJUST_FORMAT = 'a';
1345 my $HEX_ADJUST_FORMAT = 'ax';
1346 my $DECOMP_STRING_FORMAT = 'c';
1347 my $STRING_WHITE_SPACE_LIST = 'sw';
1348
1349 my %map_table_formats = (
1350     $BINARY_FORMAT => 'binary',
1351     $DECIMAL_FORMAT => 'single decimal digit',
1352     $FLOAT_FORMAT => 'floating point number',
1353     $INTEGER_FORMAT => 'integer',
1354     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1355     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1356     $STRING_FORMAT => 'string',
1357     $ADJUST_FORMAT => 'some entries need adjustment',
1358     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1359     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1360     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1361 );
1362
1363 # Unicode didn't put such derived files in a separate directory at first.
1364 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1365 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1366 my $AUXILIARY = 'auxiliary';
1367
1368 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1369 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1370 my %loose_to_file_of;       # loosely maps table names to their respective
1371                             # files
1372 my %stricter_to_file_of;    # same; but for stricter mapping.
1373 my %loose_property_to_file_of; # Maps a loose property name to its map file
1374 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1375                             # inversion list.  When a definition is inlined,
1376                             # its value in the hash it's in (one of the two
1377                             # defined just above) will include an index into
1378                             # this array.  The 0th element is initialized to
1379                             # the definition for a zero length invwersion list
1380 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1381                             # in the hash %utf8::SwashInfo
1382 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1383                              # their rational equivalent
1384 my %loose_property_name_of; # Loosely maps (non_string) property names to
1385                             # standard form
1386 my %string_property_loose_to_name; # Same, for string properties.
1387 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1388                             # the property name in standard loose form, and
1389                             # 'value' is the default value for that property,
1390                             # also in standard loose form.
1391 my %loose_to_standard_value; # loosely maps table names to the canonical
1392                             # alias for them
1393 my %ambiguous_names;        # keys are alias names (in standard form) that
1394                             # have more than one possible meaning.
1395 my %prop_aliases;           # Keys are standard property name; values are each
1396                             # one's aliases
1397 my %prop_value_aliases;     # Keys of top level are standard property name;
1398                             # values are keys to another hash,  Each one is
1399                             # one of the property's values, in standard form.
1400                             # The values are that prop-val's aliases.
1401 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1402
1403 # Most properties are immune to caseless matching, otherwise you would get
1404 # nonsensical results, as properties are a function of a code point, not
1405 # everything that is caselessly equivalent to that code point.  For example,
1406 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1407 # be true because 's' and 'S' are equivalent caselessly.  However,
1408 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1409 # extend that concept to those very few properties that are like this.  Each
1410 # such property will match the full range caselessly.  They are hard-coded in
1411 # the program; it's not worth trying to make it general as it's extremely
1412 # unlikely that they will ever change.
1413 my %caseless_equivalent_to;
1414
1415 # These constants names and values were taken from the Unicode standard,
1416 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1417 # syllables.  The '_string' versions are so generated tables can retain the
1418 # hex format, which is the more familiar value
1419 my $SBase_string = "0xAC00";
1420 my $SBase = CORE::hex $SBase_string;
1421 my $LBase_string = "0x1100";
1422 my $LBase = CORE::hex $LBase_string;
1423 my $VBase_string = "0x1161";
1424 my $VBase = CORE::hex $VBase_string;
1425 my $TBase_string = "0x11A7";
1426 my $TBase = CORE::hex $TBase_string;
1427 my $SCount = 11172;
1428 my $LCount = 19;
1429 my $VCount = 21;
1430 my $TCount = 28;
1431 my $NCount = $VCount * $TCount;
1432
1433 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1434 # with the above published constants.
1435 my %Jamo;
1436 my %Jamo_L;     # Leading consonants
1437 my %Jamo_V;     # Vowels
1438 my %Jamo_T;     # Trailing consonants
1439
1440 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1441 # The key is the base name of the code point, and the value is an
1442 # array giving all the ranges that use this base name.  Each range
1443 # is actually a hash giving the 'low' and 'high' values of it.
1444 my %names_ending_in_code_point;
1445 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1446                                         # removed from the names
1447 # Inverse mapping.  The list of ranges that have these kinds of
1448 # names.  Each element contains the low, high, and base names in an
1449 # anonymous hash.
1450 my @code_points_ending_in_code_point;
1451
1452 # To hold Unicode's normalization test suite
1453 my @normalization_tests;
1454
1455 # Boolean: does this Unicode version have the hangul syllables, and are we
1456 # writing out a table for them?
1457 my $has_hangul_syllables = 0;
1458
1459 # Does this Unicode version have code points whose names end in their
1460 # respective code points, and are we writing out a table for them?  0 for no;
1461 # otherwise points to first property that a table is needed for them, so that
1462 # if multiple tables are needed, we don't create duplicates
1463 my $needing_code_points_ending_in_code_point = 0;
1464
1465 my @backslash_X_tests;     # List of tests read in for testing \X
1466 my @unhandled_properties;  # Will contain a list of properties found in
1467                            # the input that we didn't process.
1468 my @match_properties;      # Properties that have match tables, to be
1469                            # listed in the pod
1470 my @map_properties;        # Properties that get map files written
1471 my @named_sequences;       # NamedSequences.txt contents.
1472 my %potential_files;       # Generated list of all .txt files in the directory
1473                            # structure so we can warn if something is being
1474                            # ignored.
1475 my @files_actually_output; # List of files we generated.
1476 my @more_Names;            # Some code point names are compound; this is used
1477                            # to store the extra components of them.
1478 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1479                            # the minimum before we consider it equivalent to a
1480                            # candidate rational
1481 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1482
1483 # These store references to certain commonly used property objects
1484 my $ccc;
1485 my $gc;
1486 my $perl;
1487 my $block;
1488 my $perl_charname;
1489 my $print;
1490 my $All;
1491 my $script;
1492
1493 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1494 my $has_In_conflicts = 0;
1495 my $has_Is_conflicts = 0;
1496
1497 sub internal_file_to_platform ($) {
1498     # Convert our file paths which have '/' separators to those of the
1499     # platform.
1500
1501     my $file = shift;
1502     return undef unless defined $file;
1503
1504     return File::Spec->join(split '/', $file);
1505 }
1506
1507 sub file_exists ($) {   # platform independent '-e'.  This program internally
1508                         # uses slash as a path separator.
1509     my $file = shift;
1510     return 0 if ! defined $file;
1511     return -e internal_file_to_platform($file);
1512 }
1513
1514 sub objaddr($) {
1515     # Returns the address of the blessed input object.
1516     # It doesn't check for blessedness because that would do a string eval
1517     # every call, and the program is structured so that this is never called
1518     # for a non-blessed object.
1519
1520     no overloading; # If overloaded, numifying below won't work.
1521
1522     # Numifying a ref gives its address.
1523     return pack 'J', $_[0];
1524 }
1525
1526 # These are used only if $annotate is true.
1527 # The entire range of Unicode characters is examined to populate these
1528 # after all the input has been processed.  But most can be skipped, as they
1529 # have the same descriptive phrases, such as being unassigned
1530 my @viacode;            # Contains the 1 million character names
1531 my @printable;          # boolean: And are those characters printable?
1532 my @annotate_char_type; # Contains a type of those characters, specifically
1533                         # for the purposes of annotation.
1534 my $annotate_ranges;    # A map of ranges of code points that have the same
1535                         # name for the purposes of annotation.  They map to the
1536                         # upper edge of the range, so that the end point can
1537                         # be immediately found.  This is used to skip ahead to
1538                         # the end of a range, and avoid processing each
1539                         # individual code point in it.
1540 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1541                                    # characters, but excluding those which are
1542                                    # also noncharacter code points
1543
1544 # The annotation types are an extension of the regular range types, though
1545 # some of the latter are folded into one.  Make the new types negative to
1546 # avoid conflicting with the regular types
1547 my $SURROGATE_TYPE = -1;
1548 my $UNASSIGNED_TYPE = -2;
1549 my $PRIVATE_USE_TYPE = -3;
1550 my $NONCHARACTER_TYPE = -4;
1551 my $CONTROL_TYPE = -5;
1552 my $ABOVE_UNICODE_TYPE = -6;
1553 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1554
1555 sub populate_char_info ($) {
1556     # Used only with the $annotate option.  Populates the arrays with the
1557     # input code point's info that are needed for outputting more detailed
1558     # comments.  If calling context wants a return, it is the end point of
1559     # any contiguous range of characters that share essentially the same info
1560
1561     my $i = shift;
1562     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1563
1564     $viacode[$i] = $perl_charname->value_of($i) || "";
1565
1566     # A character is generally printable if Unicode says it is,
1567     # but below we make sure that most Unicode general category 'C' types
1568     # aren't.
1569     $printable[$i] = $print->contains($i);
1570
1571     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1572
1573     # Only these two regular types are treated specially for annotations
1574     # purposes
1575     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1576                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1577
1578     # Give a generic name to all code points that don't have a real name.
1579     # We output ranges, if applicable, for these.  Also calculate the end
1580     # point of the range.
1581     my $end;
1582     if (! $viacode[$i]) {
1583         my $nonchar;
1584         if ($i > $MAX_UNICODE_CODEPOINT) {
1585             $viacode[$i] = 'Above-Unicode';
1586             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1587             $printable[$i] = 0;
1588             $end = $MAX_WORKING_CODEPOINT;
1589         }
1590         elsif ($gc-> table('Private_use')->contains($i)) {
1591             $viacode[$i] = 'Private Use';
1592             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1593             $printable[$i] = 0;
1594             $end = $gc->table('Private_Use')->containing_range($i)->end;
1595         }
1596         elsif ((defined ($nonchar =
1597                             Property::property_ref('Noncharacter_Code_Point'))
1598                && $nonchar->table('Y')->contains($i)))
1599         {
1600             $viacode[$i] = 'Noncharacter';
1601             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1602             $printable[$i] = 0;
1603             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1604                                                     containing_range($i)->end;
1605         }
1606         elsif ($gc-> table('Control')->contains($i)) {
1607             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1608             $annotate_char_type[$i] = $CONTROL_TYPE;
1609             $printable[$i] = 0;
1610         }
1611         elsif ($gc-> table('Unassigned')->contains($i)) {
1612             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1613             $printable[$i] = 0;
1614             if ($v_version lt v2.0.0) { # No blocks in earliest releases
1615                 $viacode[$i] = 'Unassigned';
1616                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1617             }
1618             else {
1619                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1620
1621                 # Because we name the unassigned by the blocks they are in, it
1622                 # can't go past the end of that block, and it also can't go
1623                 # past the unassigned range it is in.  The special table makes
1624                 # sure that the non-characters, which are unassigned, are
1625                 # separated out.
1626                 $end = min($block->containing_range($i)->end,
1627                            $unassigned_sans_noncharacters->
1628                                                     containing_range($i)->end);
1629             }
1630         }
1631         elsif ($v_version lt v2.0.0) {  # No surrogates in earliest releases
1632             $viacode[$i] = $gc->value_of($i);
1633             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1634             $printable[$i] = 0;
1635         }
1636         elsif ($gc-> table('Surrogate')->contains($i)) {
1637             $viacode[$i] = 'Surrogate';
1638             $annotate_char_type[$i] = $SURROGATE_TYPE;
1639             $printable[$i] = 0;
1640             $end = $gc->table('Surrogate')->containing_range($i)->end;
1641         }
1642         else {
1643             Carp::my_carp_bug("Can't figure out how to annotate "
1644                               . sprintf("U+%04X", $i)
1645                               . ".  Proceeding anyway.");
1646             $viacode[$i] = 'UNKNOWN';
1647             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1648             $printable[$i] = 0;
1649         }
1650     }
1651
1652     # Here, has a name, but if it's one in which the code point number is
1653     # appended to the name, do that.
1654     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1655         $viacode[$i] .= sprintf("-%04X", $i);
1656         $end = $perl_charname->containing_range($i)->end;
1657     }
1658
1659     # And here, has a name, but if it's a hangul syllable one, replace it with
1660     # the correct name from the Unicode algorithm
1661     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1662         use integer;
1663         my $SIndex = $i - $SBase;
1664         my $L = $LBase + $SIndex / $NCount;
1665         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1666         my $T = $TBase + $SIndex % $TCount;
1667         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1668         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1669         $end = $perl_charname->containing_range($i)->end;
1670     }
1671
1672     return if ! defined wantarray;
1673     return $i if ! defined $end;    # If not a range, return the input
1674
1675     # Save this whole range so can find the end point quickly
1676     $annotate_ranges->add_map($i, $end, $end);
1677
1678     return $end;
1679 }
1680
1681 # Commented code below should work on Perl 5.8.
1682 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1683 ## the native perl version of it (which is what would operate under miniperl)
1684 ## is extremely slow, as it does a string eval every call.
1685 #my $has_fast_scalar_util = $^X !~ /miniperl/
1686 #                            && defined eval "require Scalar::Util";
1687 #
1688 #sub objaddr($) {
1689 #    # Returns the address of the blessed input object.  Uses the XS version if
1690 #    # available.  It doesn't check for blessedness because that would do a
1691 #    # string eval every call, and the program is structured so that this is
1692 #    # never called for a non-blessed object.
1693 #
1694 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1695 #
1696 #    # Check at least that is a ref.
1697 #    my $pkg = ref($_[0]) or return undef;
1698 #
1699 #    # Change to a fake package to defeat any overloaded stringify
1700 #    bless $_[0], 'main::Fake';
1701 #
1702 #    # Numifying a ref gives its address.
1703 #    my $addr = pack 'J', $_[0];
1704 #
1705 #    # Return to original class
1706 #    bless $_[0], $pkg;
1707 #    return $addr;
1708 #}
1709
1710 sub max ($$) {
1711     my $a = shift;
1712     my $b = shift;
1713     return $a if $a >= $b;
1714     return $b;
1715 }
1716
1717 sub min ($$) {
1718     my $a = shift;
1719     my $b = shift;
1720     return $a if $a <= $b;
1721     return $b;
1722 }
1723
1724 sub clarify_number ($) {
1725     # This returns the input number with underscores inserted every 3 digits
1726     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1727     # checked.
1728
1729     my $number = shift;
1730     my $pos = length($number) - 3;
1731     return $number if $pos <= 1;
1732     while ($pos > 0) {
1733         substr($number, $pos, 0) = '_';
1734         $pos -= 3;
1735     }
1736     return $number;
1737 }
1738
1739 sub clarify_code_point_count ($) {
1740     # This is like clarify_number(), but the input is assumed to be a count of
1741     # code points, rather than a generic number.
1742
1743     my $append = "";
1744
1745     my $number = shift;
1746     if ($number > $MAX_UNICODE_CODEPOINTS) {
1747         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1748         return "All above-Unicode code points" if $number == 0;
1749         $append = " + all above-Unicode code points";
1750     }
1751     return clarify_number($number) . $append;
1752 }
1753
1754 package Carp;
1755
1756 # These routines give a uniform treatment of messages in this program.  They
1757 # are placed in the Carp package to cause the stack trace to not include them,
1758 # although an alternative would be to use another package and set @CARP_NOT
1759 # for it.
1760
1761 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1762
1763 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1764 # and overload trying to load Scalar:Util under miniperl.  See
1765 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1766 undef $overload::VERSION;
1767
1768 sub my_carp {
1769     my $message = shift || "";
1770     my $nofold = shift || 0;
1771
1772     if ($message) {
1773         $message = main::join_lines($message);
1774         $message =~ s/^$0: *//;     # Remove initial program name
1775         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1776         $message = "\n$0: $message;";
1777
1778         # Fold the message with program name, semi-colon end punctuation
1779         # (which looks good with the message that carp appends to it), and a
1780         # hanging indent for continuation lines.
1781         $message = main::simple_fold($message, "", 4) unless $nofold;
1782         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1783                                     # appends is to the same line
1784     }
1785
1786     return $message if defined wantarray;   # If a caller just wants the msg
1787
1788     carp $message;
1789     return;
1790 }
1791
1792 sub my_carp_bug {
1793     # This is called when it is clear that the problem is caused by a bug in
1794     # this program.
1795
1796     my $message = shift;
1797     $message =~ s/^$0: *//;
1798     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1799     carp $message;
1800     return;
1801 }
1802
1803 sub carp_too_few_args {
1804     if (@_ != 2) {
1805         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1806         return;
1807     }
1808
1809     my $args_ref = shift;
1810     my $count = shift;
1811
1812     my_carp_bug("Need at least $count arguments to "
1813         . (caller 1)[3]
1814         . ".  Instead got: '"
1815         . join ', ', @$args_ref
1816         . "'.  No action taken.");
1817     return;
1818 }
1819
1820 sub carp_extra_args {
1821     my $args_ref = shift;
1822     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1823
1824     unless (ref $args_ref) {
1825         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1826         return;
1827     }
1828     my ($package, $file, $line) = caller;
1829     my $subroutine = (caller 1)[3];
1830
1831     my $list;
1832     if (ref $args_ref eq 'HASH') {
1833         foreach my $key (keys %$args_ref) {
1834             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1835         }
1836         $list = join ', ', each %{$args_ref};
1837     }
1838     elsif (ref $args_ref eq 'ARRAY') {
1839         foreach my $arg (@$args_ref) {
1840             $arg = $UNDEF unless defined $arg;
1841         }
1842         $list = join ', ', @$args_ref;
1843     }
1844     else {
1845         my_carp_bug("Can't cope with ref "
1846                 . ref($args_ref)
1847                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1848         return;
1849     }
1850
1851     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1852     return;
1853 }
1854
1855 package main;
1856
1857 { # Closure
1858
1859     # This program uses the inside-out method for objects, as recommended in
1860     # "Perl Best Practices".  (This is the best solution still, since this has
1861     # to run under miniperl.)  This closure aids in generating those.  There
1862     # are two routines.  setup_package() is called once per package to set
1863     # things up, and then set_access() is called for each hash representing a
1864     # field in the object.  These routines arrange for the object to be
1865     # properly destroyed when no longer used, and for standard accessor
1866     # functions to be generated.  If you need more complex accessors, just
1867     # write your own and leave those accesses out of the call to set_access().
1868     # More details below.
1869
1870     my %constructor_fields; # fields that are to be used in constructors; see
1871                             # below
1872
1873     # The values of this hash will be the package names as keys to other
1874     # hashes containing the name of each field in the package as keys, and
1875     # references to their respective hashes as values.
1876     my %package_fields;
1877
1878     sub setup_package {
1879         # Sets up the package, creating standard DESTROY and dump methods
1880         # (unless already defined).  The dump method is used in debugging by
1881         # simple_dumper().
1882         # The optional parameters are:
1883         #   a)  a reference to a hash, that gets populated by later
1884         #       set_access() calls with one of the accesses being
1885         #       'constructor'.  The caller can then refer to this, but it is
1886         #       not otherwise used by these two routines.
1887         #   b)  a reference to a callback routine to call during destruction
1888         #       of the object, before any fields are actually destroyed
1889
1890         my %args = @_;
1891         my $constructor_ref = delete $args{'Constructor_Fields'};
1892         my $destroy_callback = delete $args{'Destroy_Callback'};
1893         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1894
1895         my %fields;
1896         my $package = (caller)[0];
1897
1898         $package_fields{$package} = \%fields;
1899         $constructor_fields{$package} = $constructor_ref;
1900
1901         unless ($package->can('DESTROY')) {
1902             my $destroy_name = "${package}::DESTROY";
1903             no strict "refs";
1904
1905             # Use typeglob to give the anonymous subroutine the name we want
1906             *$destroy_name = sub {
1907                 my $self = shift;
1908                 my $addr = do { no overloading; pack 'J', $self; };
1909
1910                 $self->$destroy_callback if $destroy_callback;
1911                 foreach my $field (keys %{$package_fields{$package}}) {
1912                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1913                     delete $package_fields{$package}{$field}{$addr};
1914                 }
1915                 return;
1916             }
1917         }
1918
1919         unless ($package->can('dump')) {
1920             my $dump_name = "${package}::dump";
1921             no strict "refs";
1922             *$dump_name = sub {
1923                 my $self = shift;
1924                 return dump_inside_out($self, $package_fields{$package}, @_);
1925             }
1926         }
1927         return;
1928     }
1929
1930     sub set_access {
1931         # Arrange for the input field to be garbage collected when no longer
1932         # needed.  Also, creates standard accessor functions for the field
1933         # based on the optional parameters-- none if none of these parameters:
1934         #   'addable'    creates an 'add_NAME()' accessor function.
1935         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1936         #                function.
1937         #   'settable'   creates a 'set_NAME()' accessor function.
1938         #   'constructor' doesn't create an accessor function, but adds the
1939         #                field to the hash that was previously passed to
1940         #                setup_package();
1941         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1942         # 'add' etc. all mean 'addable'.
1943         # The read accessor function will work on both array and scalar
1944         # values.  If another accessor in the parameter list is 'a', the read
1945         # access assumes an array.  You can also force it to be array access
1946         # by specifying 'readable_array' instead of 'readable'
1947         #
1948         # A sort-of 'protected' access can be set-up by preceding the addable,
1949         # readable or settable with some initial portion of 'protected_' (but,
1950         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1951         # "protection" is only by convention.  All that happens is that the
1952         # accessor functions' names begin with an underscore.  So instead of
1953         # calling set_foo, the call is _set_foo.  (Real protection could be
1954         # accomplished by having a new subroutine, end_package, called at the
1955         # end of each package, and then storing the __LINE__ ranges and
1956         # checking them on every accessor.  But that is way overkill.)
1957
1958         # We create anonymous subroutines as the accessors and then use
1959         # typeglobs to assign them to the proper package and name
1960
1961         my $name = shift;   # Name of the field
1962         my $field = shift;  # Reference to the inside-out hash containing the
1963                             # field
1964
1965         my $package = (caller)[0];
1966
1967         if (! exists $package_fields{$package}) {
1968             croak "$0: Must call 'setup_package' before 'set_access'";
1969         }
1970
1971         # Stash the field so DESTROY can get it.
1972         $package_fields{$package}{$name} = $field;
1973
1974         # Remaining arguments are the accessors.  For each...
1975         foreach my $access (@_) {
1976             my $access = lc $access;
1977
1978             my $protected = "";
1979
1980             # Match the input as far as it goes.
1981             if ($access =~ /^(p[^_]*)_/) {
1982                 $protected = $1;
1983                 if (substr('protected_', 0, length $protected)
1984                     eq $protected)
1985                 {
1986
1987                     # Add 1 for the underscore not included in $protected
1988                     $access = substr($access, length($protected) + 1);
1989                     $protected = '_';
1990                 }
1991                 else {
1992                     $protected = "";
1993                 }
1994             }
1995
1996             if (substr('addable', 0, length $access) eq $access) {
1997                 my $subname = "${package}::${protected}add_$name";
1998                 no strict "refs";
1999
2000                 # add_ accessor.  Don't add if already there, which we
2001                 # determine using 'eq' for scalars and '==' otherwise.
2002                 *$subname = sub {
2003                     use strict "refs";
2004                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2005                     my $self = shift;
2006                     my $value = shift;
2007                     my $addr = do { no overloading; pack 'J', $self; };
2008                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2009                     if (ref $value) {
2010                         return if grep { $value == $_ } @{$field->{$addr}};
2011                     }
2012                     else {
2013                         return if grep { $value eq $_ } @{$field->{$addr}};
2014                     }
2015                     push @{$field->{$addr}}, $value;
2016                     return;
2017                 }
2018             }
2019             elsif (substr('constructor', 0, length $access) eq $access) {
2020                 if ($protected) {
2021                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
2022                 }
2023                 else {
2024                     $constructor_fields{$package}{$name} = $field;
2025                 }
2026             }
2027             elsif (substr('readable_array', 0, length $access) eq $access) {
2028
2029                 # Here has read access.  If one of the other parameters for
2030                 # access is array, or this one specifies array (by being more
2031                 # than just 'readable_'), then create a subroutine that
2032                 # assumes the data is an array.  Otherwise just a scalar
2033                 my $subname = "${package}::${protected}$name";
2034                 if (grep { /^a/i } @_
2035                     or length($access) > length('readable_'))
2036                 {
2037                     no strict "refs";
2038                     *$subname = sub {
2039                         use strict "refs";
2040                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2041                         my $addr = do { no overloading; pack 'J', $_[0]; };
2042                         if (ref $field->{$addr} ne 'ARRAY') {
2043                             my $type = ref $field->{$addr};
2044                             $type = 'scalar' unless $type;
2045                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
2046                             return;
2047                         }
2048                         return scalar @{$field->{$addr}} unless wantarray;
2049
2050                         # Make a copy; had problems with caller modifying the
2051                         # original otherwise
2052                         my @return = @{$field->{$addr}};
2053                         return @return;
2054                     }
2055                 }
2056                 else {
2057
2058                     # Here not an array value, a simpler function.
2059                     no strict "refs";
2060                     *$subname = sub {
2061                         use strict "refs";
2062                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2063                         no overloading;
2064                         return $field->{pack 'J', $_[0]};
2065                     }
2066                 }
2067             }
2068             elsif (substr('settable', 0, length $access) eq $access) {
2069                 my $subname = "${package}::${protected}set_$name";
2070                 no strict "refs";
2071                 *$subname = sub {
2072                     use strict "refs";
2073                     if (main::DEBUG) {
2074                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2075                         Carp::carp_extra_args(\@_) if @_ > 2;
2076                     }
2077                     # $self is $_[0]; $value is $_[1]
2078                     no overloading;
2079                     $field->{pack 'J', $_[0]} = $_[1];
2080                     return;
2081                 }
2082             }
2083             else {
2084                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2085             }
2086         }
2087         return;
2088     }
2089 }
2090
2091 package Input_file;
2092
2093 # All input files use this object, which stores various attributes about them,
2094 # and provides for convenient, uniform handling.  The run method wraps the
2095 # processing.  It handles all the bookkeeping of opening, reading, and closing
2096 # the file, returning only significant input lines.
2097 #
2098 # Each object gets a handler which processes the body of the file, and is
2099 # called by run().  All character property files must use the generic,
2100 # default handler, which has code scrubbed to handle things you might not
2101 # expect, including automatic EBCDIC handling.  For files that don't deal with
2102 # mapping code points to a property value, such as test files,
2103 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2104 # handler to be a custom one.  Such a handler should basically be a
2105 # while(next_line()) {...} loop.
2106 #
2107 # You can also set up handlers to
2108 #   1) call before the first line is read, for pre processing
2109 #   2) call to adjust each line of the input before the main handler gets
2110 #      them.  This can be automatically generated, if appropriately simple
2111 #      enough, by specifiying a Properties parameter in the constructor.
2112 #   3) call upon EOF before the main handler exits its loop
2113 #   4) call at the end, for post processing
2114 #
2115 # $_ is used to store the input line, and is to be filtered by the
2116 # each_line_handler()s.  So, if the format of the line is not in the desired
2117 # format for the main handler, these are used to do that adjusting.  They can
2118 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2119 # so the $_ output of one is used as the input to the next.  None of the other
2120 # handlers are stackable, but could easily be changed to be so.
2121 #
2122 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2123 # which insert the parameters as lines to be processed before the next input
2124 # file line is read.  This allows the EOF handler to flush buffers, for
2125 # example.  The difference between the two routines is that the lines inserted
2126 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2127 # called it from such a handler, you would get infinite recursion.)  Lines
2128 # inserted by insert_adjusted_lines() go directly to the main handler without
2129 # any adjustments.  If the  post-processing handler calls any of these, there
2130 # will be no effect.  Some error checking for these conditions could be added,
2131 # but it hasn't been done.
2132 #
2133 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2134 # to prevent further processing of the line.  This routine will output the
2135 # message as a warning once, and then keep a count of the lines that have the
2136 # same message, and output that count at the end of the file's processing.
2137 # This keeps the number of messages down to a manageable amount.
2138 #
2139 # get_missings() should be called to retrieve any @missing input lines.
2140 # Messages will be raised if this isn't done if the options aren't to ignore
2141 # missings.
2142
2143 sub trace { return main::trace(@_); }
2144
2145 { # Closure
2146     # Keep track of fields that are to be put into the constructor.
2147     my %constructor_fields;
2148
2149     main::setup_package(Constructor_Fields => \%constructor_fields);
2150
2151     my %file; # Input file name, required
2152     main::set_access('file', \%file, qw{ c r });
2153
2154     my %first_released; # Unicode version file was first released in, required
2155     main::set_access('first_released', \%first_released, qw{ c r });
2156
2157     my %handler;    # Subroutine to process the input file, defaults to
2158                     # 'process_generic_property_file'
2159     main::set_access('handler', \%handler, qw{ c });
2160
2161     my %property;
2162     # name of property this file is for.  defaults to none, meaning not
2163     # applicable, or is otherwise determinable, for example, from each line.
2164     main::set_access('property', \%property, qw{ c r });
2165
2166     my %optional;
2167     # If this is true, the file is optional.  If not present, no warning is
2168     # output.  If it is present, the string given by this parameter is
2169     # evaluated, and if false the file is not processed.
2170     main::set_access('optional', \%optional, 'c', 'r');
2171
2172     my %non_skip;
2173     # This is used for debugging, to skip processing of all but a few input
2174     # files.  Add 'non_skip => 1' to the constructor for those files you want
2175     # processed when you set the $debug_skip global.
2176     main::set_access('non_skip', \%non_skip, 'c');
2177
2178     my %skip;
2179     # This is used to skip processing of this input file semi-permanently,
2180     # when it evaluates to true.  The value should be the reason the file is
2181     # being skipped.  It is used for files that we aren't planning to process
2182     # anytime soon, but want to allow to be in the directory and not raise a
2183     # message that we are not handling.  Mostly for test files.  This is in
2184     # contrast to the non_skip element, which is supposed to be used very
2185     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2186     # pretty much will never look at can be placed in the global
2187     # %ignored_files instead.  Ones used here will be added to %skipped files
2188     main::set_access('skip', \%skip, 'c');
2189
2190     my %each_line_handler;
2191     # list of subroutines to look at and filter each non-comment line in the
2192     # file.  defaults to none.  The subroutines are called in order, each is
2193     # to adjust $_ for the next one, and the final one adjusts it for
2194     # 'handler'
2195     main::set_access('each_line_handler', \%each_line_handler, 'c');
2196
2197     my %properties; # Optional ordered list of the properties that occur in each
2198     # meaningful line of the input file.  If present, an appropriate
2199     # each_line_handler() is automatically generated and pushed onto the stack
2200     # of such handlers.  This is useful when a file contains multiple
2201     # proerties per line, but no other special considerations are necessary.
2202     # The special value "<ignored>" means to discard the corresponding input
2203     # field.
2204     # Any @missing lines in the file should also match this syntax; no such
2205     # files exist as of 6.3.  But if it happens in a future release, the code
2206     # could be expanded to properly parse them.
2207     main::set_access('properties', \%properties, qw{ c r });
2208
2209     my %has_missings_defaults;
2210     # ? Are there lines in the file giving default values for code points
2211     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2212     # the norm, but IGNORED means it has such lines, but the handler doesn't
2213     # use them.  Having these three states allows us to catch changes to the
2214     # UCD that this program should track.  XXX This could be expanded to
2215     # specify the syntax for such lines, like %properties above.
2216     main::set_access('has_missings_defaults',
2217                                         \%has_missings_defaults, qw{ c r });
2218
2219     my %pre_handler;
2220     # Subroutine to call before doing anything else in the file.  If undef, no
2221     # such handler is called.
2222     main::set_access('pre_handler', \%pre_handler, qw{ c });
2223
2224     my %eof_handler;
2225     # Subroutine to call upon getting an EOF on the input file, but before
2226     # that is returned to the main handler.  This is to allow buffers to be
2227     # flushed.  The handler is expected to call insert_lines() or
2228     # insert_adjusted() with the buffered material
2229     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2230
2231     my %post_handler;
2232     # Subroutine to call after all the lines of the file are read in and
2233     # processed.  If undef, no such handler is called.
2234     main::set_access('post_handler', \%post_handler, qw{ c });
2235
2236     my %progress_message;
2237     # Message to print to display progress in lieu of the standard one
2238     main::set_access('progress_message', \%progress_message, qw{ c });
2239
2240     my %handle;
2241     # cache open file handle, internal.  Is undef if file hasn't been
2242     # processed at all, empty if has;
2243     main::set_access('handle', \%handle);
2244
2245     my %added_lines;
2246     # cache of lines added virtually to the file, internal
2247     main::set_access('added_lines', \%added_lines);
2248
2249     my %remapped_lines;
2250     # cache of lines added virtually to the file, internal
2251     main::set_access('remapped_lines', \%remapped_lines);
2252
2253     my %errors;
2254     # cache of errors found, internal
2255     main::set_access('errors', \%errors);
2256
2257     my %missings;
2258     # storage of '@missing' defaults lines
2259     main::set_access('missings', \%missings);
2260
2261     sub _next_line;
2262     sub _next_line_with_remapped_range;
2263
2264     sub new {
2265         my $class = shift;
2266
2267         my $self = bless \do{ my $anonymous_scalar }, $class;
2268         my $addr = do { no overloading; pack 'J', $self; };
2269
2270         # Set defaults
2271         $handler{$addr} = \&main::process_generic_property_file;
2272         $non_skip{$addr} = 0;
2273         $skip{$addr} = 0;
2274         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2275         $handle{$addr} = undef;
2276         $added_lines{$addr} = [ ];
2277         $remapped_lines{$addr} = [ ];
2278         $each_line_handler{$addr} = [ ];
2279         $errors{$addr} = { };
2280         $missings{$addr} = [ ];
2281
2282         # Two positional parameters.
2283         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2284         $file{$addr} = main::internal_file_to_platform(shift);
2285         $first_released{$addr} = shift;
2286
2287         # The rest of the arguments are key => value pairs
2288         # %constructor_fields has been set up earlier to list all possible
2289         # ones.  Either set or push, depending on how the default has been set
2290         # up just above.
2291         my %args = @_;
2292         foreach my $key (keys %args) {
2293             my $argument = $args{$key};
2294
2295             # Note that the fields are the lower case of the constructor keys
2296             my $hash = $constructor_fields{lc $key};
2297             if (! defined $hash) {
2298                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2299                 next;
2300             }
2301             if (ref $hash->{$addr} eq 'ARRAY') {
2302                 if (ref $argument eq 'ARRAY') {
2303                     foreach my $argument (@{$argument}) {
2304                         next if ! defined $argument;
2305                         push @{$hash->{$addr}}, $argument;
2306                     }
2307                 }
2308                 else {
2309                     push @{$hash->{$addr}}, $argument if defined $argument;
2310                 }
2311             }
2312             else {
2313                 $hash->{$addr} = $argument;
2314             }
2315             delete $args{$key};
2316         };
2317
2318         # If the file has a property for it, it means that the property is not
2319         # listed in the file's entries.  So add a handler to the list of line
2320         # handlers to insert the property name into the lines, to provide a
2321         # uniform interface to the final processing subroutine.
2322         # the final code doesn't have to worry about that.
2323         if ($property{$addr}) {
2324             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2325         }
2326
2327         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2328             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2329         }
2330
2331         # If skipping, set to optional, and add to list of ignored files,
2332         # including its reason
2333         if ($skip{$addr}) {
2334             $optional{$addr} = 1;
2335             $skipped_files{$file{$addr}} = $skip{$addr}
2336         }
2337         elsif ($properties{$addr}) {
2338
2339             # Add a handler for each line in the input so that it creates a
2340             # separate input line for each property in those input lines, thus
2341             # making them suitable for process_generic_property_file().
2342
2343             push @{$each_line_handler{$addr}},
2344                  sub {
2345                     my $file = shift;
2346                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2347
2348                     my @fields = split /\s*;\s*/, $_, -1;
2349
2350                     if (@fields - 1 > @{$properties{$addr}}) {
2351                         $file->carp_bad_line('Extra fields');
2352                         $_ = "";
2353                         return;
2354                     }
2355                     my $range = shift @fields;  # 0th element is always the
2356                                                 # range
2357
2358                     # The next fields in the input line correspond
2359                     # respectively to the stored properties.
2360                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2361                         my $property_name = $properties{$addr}[$i];
2362                         next if $property_name eq '<ignored>';
2363                         $file->insert_adjusted_lines(
2364                               "$range; $property_name; $fields[$i]");
2365                     }
2366                     $_ = "";
2367
2368                     return;
2369                 };
2370         }
2371
2372         {   # On non-ascii platforms, we use a special handler
2373             no strict;
2374             no warnings 'once';
2375             *next_line = (main::NON_ASCII_PLATFORM)
2376                          ? *_next_line_with_remapped_range
2377                          : *_next_line;
2378         }
2379
2380         return $self;
2381     }
2382
2383
2384     use overload
2385         fallback => 0,
2386         qw("") => "_operator_stringify",
2387         "." => \&main::_operator_dot,
2388         ".=" => \&main::_operator_dot_equal,
2389     ;
2390
2391     sub _operator_stringify {
2392         my $self = shift;
2393
2394         return __PACKAGE__ . " object for " . $self->file;
2395     }
2396
2397     # flag to make sure extracted files are processed early
2398     my $seen_non_extracted_non_age = 0;
2399
2400     sub run {
2401         # Process the input object $self.  This opens and closes the file and
2402         # calls all the handlers for it.  Currently,  this can only be called
2403         # once per file, as it destroy's the EOF handler
2404
2405         my $self = shift;
2406         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2407
2408         my $addr = do { no overloading; pack 'J', $self; };
2409
2410         my $file = $file{$addr};
2411
2412         # Don't process if not expecting this file (because released later
2413         # than this Unicode version), and isn't there.  This means if someone
2414         # copies it into an earlier version's directory, we will go ahead and
2415         # process it.
2416         return if $first_released{$addr} gt $v_version && ! -e $file;
2417
2418         # If in debugging mode and this file doesn't have the non-skip
2419         # flag set, and isn't one of the critical files, skip it.
2420         if ($debug_skip
2421             && $first_released{$addr} ne v0
2422             && ! $non_skip{$addr})
2423         {
2424             print "Skipping $file in debugging\n" if $verbosity;
2425             return;
2426         }
2427
2428         # File could be optional
2429         if ($optional{$addr}) {
2430             return unless -e $file;
2431             my $result = eval $optional{$addr};
2432             if (! defined $result) {
2433                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2434                 return;
2435             }
2436             if (! $result) {
2437                 if ($verbosity) {
2438                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2439                 }
2440                 return;
2441             }
2442         }
2443
2444         if (! defined $file || ! -e $file) {
2445
2446             # If the file doesn't exist, see if have internal data for it
2447             # (based on first_released being 0).
2448             if ($first_released{$addr} eq v0) {
2449                 $handle{$addr} = 'pretend_is_open';
2450             }
2451             else {
2452                 if (! $optional{$addr}  # File could be optional
2453                     && $v_version ge $first_released{$addr})
2454                 {
2455                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2456                 }
2457                 return;
2458             }
2459         }
2460         else {
2461
2462             # Here, the file exists.  Some platforms may change the case of
2463             # its name
2464             if ($seen_non_extracted_non_age) {
2465                 if ($file =~ /$EXTRACTED/i) {
2466                     Carp::my_carp_bug(main::join_lines(<<END
2467 $file should be processed just after the 'Prop...Alias' files, and before
2468 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2469 have subtle problems
2470 END
2471                     ));
2472                 }
2473             }
2474             elsif ($EXTRACTED_DIR
2475                     && $first_released{$addr} ne v0
2476                     && $file !~ /$EXTRACTED/i
2477                     && lc($file) ne 'dage.txt')
2478             {
2479                 # We don't set this (by the 'if' above) if we have no
2480                 # extracted directory, so if running on an early version,
2481                 # this test won't work.  Not worth worrying about.
2482                 $seen_non_extracted_non_age = 1;
2483             }
2484
2485             # And mark the file as having being processed, and warn if it
2486             # isn't a file we are expecting.  As we process the files,
2487             # they are deleted from the hash, so any that remain at the
2488             # end of the program are files that we didn't process.
2489             my $fkey = File::Spec->rel2abs($file);
2490             my $expecting = delete $potential_files{lc($fkey)};
2491
2492             Carp::my_carp("Was not expecting '$file'.") if
2493                     ! $expecting
2494                     && ! defined $handle{$addr};
2495
2496             # Having deleted from expected files, we can quit if not to do
2497             # anything.  Don't print progress unless really want verbosity
2498             if ($skip{$addr}) {
2499                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2500                 return;
2501             }
2502
2503             # Open the file, converting the slashes used in this program
2504             # into the proper form for the OS
2505             my $file_handle;
2506             if (not open $file_handle, "<", $file) {
2507                 Carp::my_carp("Can't open $file.  Skipping: $!");
2508                 return 0;
2509             }
2510             $handle{$addr} = $file_handle; # Cache the open file handle
2511
2512             if ($v_version ge v3.2.0
2513                 && lc($file) ne 'unicodedata.txt'
2514
2515                     # Unihan files used another format until v7
2516                 && ($v_version ge v7.0.0 || $file !~ /^Unihan/i))
2517             {
2518                 $_ = <$file_handle>;
2519                 if ($_ !~ / - $string_version \. /x) {
2520                     chomp;
2521                     $_ =~ s/^#\s*//;
2522                     die Carp::my_carp("File '$file' is version '$_'.  It should be version $string_version");
2523                 }
2524             }
2525         }
2526
2527         if ($verbosity >= $PROGRESS) {
2528             if ($progress_message{$addr}) {
2529                 print "$progress_message{$addr}\n";
2530             }
2531             else {
2532                 # If using a virtual file, say so.
2533                 print "Processing ", (-e $file)
2534                                        ? $file
2535                                        : "substitute $file",
2536                                      "\n";
2537             }
2538         }
2539
2540
2541         # Call any special handler for before the file.
2542         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2543
2544         # Then the main handler
2545         &{$handler{$addr}}($self);
2546
2547         # Then any special post-file handler.
2548         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2549
2550         # If any errors have been accumulated, output the counts (as the first
2551         # error message in each class was output when it was encountered).
2552         if ($errors{$addr}) {
2553             my $total = 0;
2554             my $types = 0;
2555             foreach my $error (keys %{$errors{$addr}}) {
2556                 $total += $errors{$addr}->{$error};
2557                 delete $errors{$addr}->{$error};
2558                 $types++;
2559             }
2560             if ($total > 1) {
2561                 my $message
2562                         = "A total of $total lines had errors in $file.  ";
2563
2564                 $message .= ($types == 1)
2565                             ? '(Only the first one was displayed.)'
2566                             : '(Only the first of each type was displayed.)';
2567                 Carp::my_carp($message);
2568             }
2569         }
2570
2571         if (@{$missings{$addr}}) {
2572             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2573         }
2574
2575         # If a real file handle, close it.
2576         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2577                                                         ref $handle{$addr};
2578         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2579                                # the file, as opposed to undef
2580         return;
2581     }
2582
2583     sub _next_line {
2584         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2585         # if such a line exists.  'logical' means that any lines that have
2586         # been added via insert_lines() will be returned in $_ before the file
2587         # is read again.
2588
2589         my $self = shift;
2590         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2591
2592         my $addr = do { no overloading; pack 'J', $self; };
2593
2594         # Here the file is open (or if the handle is not a ref, is an open
2595         # 'virtual' file).  Get the next line; any inserted lines get priority
2596         # over the file itself.
2597         my $adjusted;
2598
2599         LINE:
2600         while (1) { # Loop until find non-comment, non-empty line
2601             #local $to_trace = 1 if main::DEBUG;
2602             my $inserted_ref = shift @{$added_lines{$addr}};
2603             if (defined $inserted_ref) {
2604                 ($adjusted, $_) = @{$inserted_ref};
2605                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2606                 return 1 if $adjusted;
2607             }
2608             else {
2609                 last if ! ref $handle{$addr}; # Don't read unless is real file
2610                 last if ! defined ($_ = readline $handle{$addr});
2611             }
2612             chomp;
2613             trace $_ if main::DEBUG && $to_trace;
2614
2615             # See if this line is the comment line that defines what property
2616             # value that code points that are not listed in the file should
2617             # have.  The format or existence of these lines is not guaranteed
2618             # by Unicode since they are comments, but the documentation says
2619             # that this was added for machine-readability, so probably won't
2620             # change.  This works starting in Unicode Version 5.0.  They look
2621             # like:
2622             #
2623             # @missing: 0000..10FFFF; Not_Reordered
2624             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2625             # @missing: 0000..10FFFF; ; NaN
2626             #
2627             # Save the line for a later get_missings() call.
2628             if (/$missing_defaults_prefix/) {
2629                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2630                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2631                 }
2632                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2633                     my @defaults = split /\s* ; \s*/x, $_;
2634
2635                     # The first field is the @missing, which ends in a
2636                     # semi-colon, so can safely shift.
2637                     shift @defaults;
2638
2639                     # Some of these lines may have empty field placeholders
2640                     # which get in the way.  An example is:
2641                     # @missing: 0000..10FFFF; ; NaN
2642                     # Remove them.  Process starting from the top so the
2643                     # splice doesn't affect things still to be looked at.
2644                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2645                         next if $defaults[$i] ne "";
2646                         splice @defaults, $i, 1;
2647                     }
2648
2649                     # What's left should be just the property (maybe) and the
2650                     # default.  Having only one element means it doesn't have
2651                     # the property.
2652                     my $default;
2653                     my $property;
2654                     if (@defaults >= 1) {
2655                         if (@defaults == 1) {
2656                             $default = $defaults[0];
2657                         }
2658                         else {
2659                             $property = $defaults[0];
2660                             $default = $defaults[1];
2661                         }
2662                     }
2663
2664                     if (@defaults < 1
2665                         || @defaults > 2
2666                         || ($default =~ /^</
2667                             && $default !~ /^<code *point>$/i
2668                             && $default !~ /^<none>$/i
2669                             && $default !~ /^<script>$/i))
2670                     {
2671                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2672                     }
2673                     else {
2674
2675                         # If the property is missing from the line, it should
2676                         # be the one for the whole file
2677                         $property = $property{$addr} if ! defined $property;
2678
2679                         # Change <none> to the null string, which is what it
2680                         # really means.  If the default is the code point
2681                         # itself, set it to <code point>, which is what
2682                         # Unicode uses (but sometimes they've forgotten the
2683                         # space)
2684                         if ($default =~ /^<none>$/i) {
2685                             $default = "";
2686                         }
2687                         elsif ($default =~ /^<code *point>$/i) {
2688                             $default = $CODE_POINT;
2689                         }
2690                         elsif ($default =~ /^<script>$/i) {
2691
2692                             # Special case this one.  Currently is from
2693                             # ScriptExtensions.txt, and means for all unlisted
2694                             # code points, use their Script property values.
2695                             # For the code points not listed in that file, the
2696                             # default value is 'Unknown'.
2697                             $default = "Unknown";
2698                         }
2699
2700                         # Store them as a sub-arrays with both components.
2701                         push @{$missings{$addr}}, [ $default, $property ];
2702                     }
2703                 }
2704
2705                 # There is nothing for the caller to process on this comment
2706                 # line.
2707                 next;
2708             }
2709
2710             # Remove comments and trailing space, and skip this line if the
2711             # result is empty
2712             s/#.*//;
2713             s/\s+$//;
2714             next if /^$/;
2715
2716             # Call any handlers for this line, and skip further processing of
2717             # the line if the handler sets the line to null.
2718             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2719                 &{$sub_ref}($self);
2720                 next LINE if /^$/;
2721             }
2722
2723             # Here the line is ok.  return success.
2724             return 1;
2725         } # End of looping through lines.
2726
2727         # If there is an EOF handler, call it (only once) and if it generates
2728         # more lines to process go back in the loop to handle them.
2729         if ($eof_handler{$addr}) {
2730             &{$eof_handler{$addr}}($self);
2731             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2732             goto LINE if $added_lines{$addr};
2733         }
2734
2735         # Return failure -- no more lines.
2736         return 0;
2737
2738     }
2739
2740     sub _next_line_with_remapped_range {
2741         my $self = shift;
2742         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2743
2744         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
2745         # to be the next logical input line, if any.  Returns non-zero if such
2746         # a line exists.  'logical' means that any lines that have been added
2747         # via insert_lines() will be returned in $_ before the file is read
2748         # again.
2749         #
2750         # The difference from _next_line() is that this remaps the Unicode
2751         # code points in the input to those of the native platform.  Each
2752         # input line contains a single code point, or a single contiguous
2753         # range of them  This routine splits each range into its individual
2754         # code points and caches them.  It returns the cached values,
2755         # translated into their native equivalents, one at a time, for each
2756         # call, before reading the next line.  Since native values can only be
2757         # a single byte wide, no translation is needed for code points above
2758         # 0xFF, and ranges that are entirely above that number are not split.
2759         # If an input line contains the range 254-1000, it would be split into
2760         # three elements: 254, 255, and 256-1000.  (The downstream table
2761         # insertion code will sort and coalesce the individual code points
2762         # into appropriate ranges.)
2763
2764         my $addr = do { no overloading; pack 'J', $self; };
2765
2766         while (1) {
2767
2768             # Look in cache before reading the next line.  Return any cached
2769             # value, translated
2770             my $inserted = shift @{$remapped_lines{$addr}};
2771             if (defined $inserted) {
2772                 trace $inserted if main::DEBUG && $to_trace;
2773                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
2774                 trace $_ if main::DEBUG && $to_trace;
2775                 return 1;
2776             }
2777
2778             # Get the next line.
2779             return 0 unless _next_line($self);
2780
2781             # If there is a special handler for it, return the line,
2782             # untranslated.  This should happen only for files that are
2783             # special, not being code-point related, such as property names.
2784             return 1 if $handler{$addr}
2785                                     != \&main::process_generic_property_file;
2786
2787             my ($range, $property_name, $map, @remainder)
2788                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
2789
2790             if (@remainder
2791                 || ! defined $property_name
2792                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
2793             {
2794                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
2795             }
2796
2797             my $low = hex $1;
2798             my $high = (defined $2) ? hex $2 : $low;
2799
2800             # If the input maps the range to another code point, remap the
2801             # target if it is between 0 and 255.
2802             my $tail;
2803             if (defined $map) {
2804                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
2805                 $tail = "$property_name; $map";
2806                 $_ = "$range; $tail";
2807             }
2808             else {
2809                 $tail = $property_name;
2810             }
2811
2812             # If entire range is above 255, just return it, unchanged (except
2813             # any mapped-to code point, already changed above)
2814             return 1 if $low > 255;
2815
2816             # Cache an entry for every code point < 255.  For those in the
2817             # range above 255, return a dummy entry for just that portion of
2818             # the range.  Note that this will be out-of-order, but that is not
2819             # a problem.
2820             foreach my $code_point ($low .. $high) {
2821                 if ($code_point > 255) {
2822                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
2823                     return 1;
2824                 }
2825                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
2826             }
2827         } # End of looping through lines.
2828
2829         # NOTREACHED
2830     }
2831
2832 #   Not currently used, not fully tested.
2833 #    sub peek {
2834 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2835 #        # record.  Not callable from an each_line_handler(), nor does it call
2836 #        # an each_line_handler() on the line.
2837 #
2838 #        my $self = shift;
2839 #        my $addr = do { no overloading; pack 'J', $self; };
2840 #
2841 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2842 #            my ($adjusted, $line) = @{$inserted_ref};
2843 #            next if $adjusted;
2844 #
2845 #            # Remove comments and trailing space, and return a non-empty
2846 #            # resulting line
2847 #            $line =~ s/#.*//;
2848 #            $line =~ s/\s+$//;
2849 #            return $line if $line ne "";
2850 #        }
2851 #
2852 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2853 #        while (1) { # Loop until find non-comment, non-empty line
2854 #            local $to_trace = 1 if main::DEBUG;
2855 #            trace $_ if main::DEBUG && $to_trace;
2856 #            return if ! defined (my $line = readline $handle{$addr});
2857 #            chomp $line;
2858 #            push @{$added_lines{$addr}}, [ 0, $line ];
2859 #
2860 #            $line =~ s/#.*//;
2861 #            $line =~ s/\s+$//;
2862 #            return $line if $line ne "";
2863 #        }
2864 #
2865 #        return;
2866 #    }
2867
2868
2869     sub insert_lines {
2870         # Lines can be inserted so that it looks like they were in the input
2871         # file at the place it was when this routine is called.  See also
2872         # insert_adjusted_lines().  Lines inserted via this routine go through
2873         # any each_line_handler()
2874
2875         my $self = shift;
2876
2877         # Each inserted line is an array, with the first element being 0 to
2878         # indicate that this line hasn't been adjusted, and needs to be
2879         # processed.
2880         no overloading;
2881         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2882         return;
2883     }
2884
2885     sub insert_adjusted_lines {
2886         # Lines can be inserted so that it looks like they were in the input
2887         # file at the place it was when this routine is called.  See also
2888         # insert_lines().  Lines inserted via this routine are already fully
2889         # adjusted, ready to be processed; each_line_handler()s handlers will
2890         # not be called.  This means this is not a completely general
2891         # facility, as only the last each_line_handler on the stack should
2892         # call this.  It could be made more general, by passing to each of the
2893         # line_handlers their position on the stack, which they would pass on
2894         # to this routine, and that would replace the boolean first element in
2895         # the anonymous array pushed here, so that the next_line routine could
2896         # use that to call only those handlers whose index is after it on the
2897         # stack.  But this is overkill for what is needed now.
2898
2899         my $self = shift;
2900         trace $_[0] if main::DEBUG && $to_trace;
2901
2902         # Each inserted line is an array, with the first element being 1 to
2903         # indicate that this line has been adjusted
2904         no overloading;
2905         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2906         return;
2907     }
2908
2909     sub get_missings {
2910         # Returns the stored up @missings lines' values, and clears the list.
2911         # The values are in an array, consisting of the default in the first
2912         # element, and the property in the 2nd.  However, since these lines
2913         # can be stacked up, the return is an array of all these arrays.
2914
2915         my $self = shift;
2916         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2917
2918         my $addr = do { no overloading; pack 'J', $self; };
2919
2920         # If not accepting a list return, just return the first one.
2921         return shift @{$missings{$addr}} unless wantarray;
2922
2923         my @return = @{$missings{$addr}};
2924         undef @{$missings{$addr}};
2925         return @return;
2926     }
2927
2928     sub _insert_property_into_line {
2929         # Add a property field to $_, if this file requires it.
2930
2931         my $self = shift;
2932         my $addr = do { no overloading; pack 'J', $self; };
2933         my $property = $property{$addr};
2934         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2935
2936         $_ =~ s/(;|$)/; $property$1/;
2937         return;
2938     }
2939
2940     sub carp_bad_line {
2941         # Output consistent error messages, using either a generic one, or the
2942         # one given by the optional parameter.  To avoid gazillions of the
2943         # same message in case the syntax of a  file is way off, this routine
2944         # only outputs the first instance of each message, incrementing a
2945         # count so the totals can be output at the end of the file.
2946
2947         my $self = shift;
2948         my $message = shift;
2949         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2950
2951         my $addr = do { no overloading; pack 'J', $self; };
2952
2953         $message = 'Unexpected line' unless $message;
2954
2955         # No trailing punctuation so as to fit with our addenda.
2956         $message =~ s/[.:;,]$//;
2957
2958         # If haven't seen this exact message before, output it now.  Otherwise
2959         # increment the count of how many times it has occurred
2960         unless ($errors{$addr}->{$message}) {
2961             Carp::my_carp("$message in '$_' in "
2962                             . $file{$addr}
2963                             . " at line $..  Skipping this line;");
2964             $errors{$addr}->{$message} = 1;
2965         }
2966         else {
2967             $errors{$addr}->{$message}++;
2968         }
2969
2970         # Clear the line to prevent any further (meaningful) processing of it.
2971         $_ = "";
2972
2973         return;
2974     }
2975 } # End closure
2976
2977 package Multi_Default;
2978
2979 # Certain properties in early versions of Unicode had more than one possible
2980 # default for code points missing from the files.  In these cases, one
2981 # default applies to everything left over after all the others are applied,
2982 # and for each of the others, there is a description of which class of code
2983 # points applies to it.  This object helps implement this by storing the
2984 # defaults, and for all but that final default, an eval string that generates
2985 # the class that it applies to.
2986
2987
2988 {   # Closure
2989
2990     main::setup_package();
2991
2992     my %class_defaults;
2993     # The defaults structure for the classes
2994     main::set_access('class_defaults', \%class_defaults);
2995
2996     my %other_default;
2997     # The default that applies to everything left over.
2998     main::set_access('other_default', \%other_default, 'r');
2999
3000
3001     sub new {
3002         # The constructor is called with default => eval pairs, terminated by
3003         # the left-over default. e.g.
3004         # Multi_Default->new(
3005         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3006         #               -  0x200D',
3007         #        'R' => 'some other expression that evaluates to code points',
3008         #        .
3009         #        .
3010         #        .
3011         #        'U'));
3012
3013         my $class = shift;
3014
3015         my $self = bless \do{my $anonymous_scalar}, $class;
3016         my $addr = do { no overloading; pack 'J', $self; };
3017
3018         while (@_ > 1) {
3019             my $default = shift;
3020             my $eval = shift;
3021             $class_defaults{$addr}->{$default} = $eval;
3022         }
3023
3024         $other_default{$addr} = shift;
3025
3026         return $self;
3027     }
3028
3029     sub get_next_defaults {
3030         # Iterates and returns the next class of defaults.
3031         my $self = shift;
3032         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3033
3034         my $addr = do { no overloading; pack 'J', $self; };
3035
3036         return each %{$class_defaults{$addr}};
3037     }
3038 }
3039
3040 package Alias;
3041
3042 # An alias is one of the names that a table goes by.  This class defines them
3043 # including some attributes.  Everything is currently setup in the
3044 # constructor.
3045
3046
3047 {   # Closure
3048
3049     main::setup_package();
3050
3051     my %name;
3052     main::set_access('name', \%name, 'r');
3053
3054     my %loose_match;
3055     # Should this name match loosely or not.
3056     main::set_access('loose_match', \%loose_match, 'r');
3057
3058     my %make_re_pod_entry;
3059     # Some aliases should not get their own entries in the re section of the
3060     # pod, because they are covered by a wild-card, and some we want to
3061     # discourage use of.  Binary
3062     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3063
3064     my %ucd;
3065     # Is this documented to be accessible via Unicode::UCD
3066     main::set_access('ucd', \%ucd, 'r', 's');
3067
3068     my %status;
3069     # Aliases have a status, like deprecated, or even suppressed (which means
3070     # they don't appear in documentation).  Enum
3071     main::set_access('status', \%status, 'r');
3072
3073     my %ok_as_filename;
3074     # Similarly, some aliases should not be considered as usable ones for
3075     # external use, such as file names, or we don't want documentation to
3076     # recommend them.  Boolean
3077     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3078
3079     sub new {
3080         my $class = shift;
3081
3082         my $self = bless \do { my $anonymous_scalar }, $class;
3083         my $addr = do { no overloading; pack 'J', $self; };
3084
3085         $name{$addr} = shift;
3086         $loose_match{$addr} = shift;
3087         $make_re_pod_entry{$addr} = shift;
3088         $ok_as_filename{$addr} = shift;
3089         $status{$addr} = shift;
3090         $ucd{$addr} = shift;
3091
3092         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3093
3094         # Null names are never ok externally
3095         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3096
3097         return $self;
3098     }
3099 }
3100
3101 package Range;
3102
3103 # A range is the basic unit for storing code points, and is described in the
3104 # comments at the beginning of the program.  Each range has a starting code
3105 # point; an ending code point (not less than the starting one); a value
3106 # that applies to every code point in between the two end-points, inclusive;
3107 # and an enum type that applies to the value.  The type is for the user's
3108 # convenience, and has no meaning here, except that a non-zero type is
3109 # considered to not obey the normal Unicode rules for having standard forms.
3110 #
3111 # The same structure is used for both map and match tables, even though in the
3112 # latter, the value (and hence type) is irrelevant and could be used as a
3113 # comment.  In map tables, the value is what all the code points in the range
3114 # map to.  Type 0 values have the standardized version of the value stored as
3115 # well, so as to not have to recalculate it a lot.
3116
3117 sub trace { return main::trace(@_); }
3118
3119 {   # Closure
3120
3121     main::setup_package();
3122
3123     my %start;
3124     main::set_access('start', \%start, 'r', 's');
3125
3126     my %end;
3127     main::set_access('end', \%end, 'r', 's');
3128
3129     my %value;
3130     main::set_access('value', \%value, 'r');
3131
3132     my %type;
3133     main::set_access('type', \%type, 'r');
3134
3135     my %standard_form;
3136     # The value in internal standard form.  Defined only if the type is 0.
3137     main::set_access('standard_form', \%standard_form);
3138
3139     # Note that if these fields change, the dump() method should as well
3140
3141     sub new {
3142         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3143         my $class = shift;
3144
3145         my $self = bless \do { my $anonymous_scalar }, $class;
3146         my $addr = do { no overloading; pack 'J', $self; };
3147
3148         $start{$addr} = shift;
3149         $end{$addr} = shift;
3150
3151         my %args = @_;
3152
3153         my $value = delete $args{'Value'};  # Can be 0
3154         $value = "" unless defined $value;
3155         $value{$addr} = $value;
3156
3157         $type{$addr} = delete $args{'Type'} || 0;
3158
3159         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3160
3161         return $self;
3162     }
3163
3164     use overload
3165         fallback => 0,
3166         qw("") => "_operator_stringify",
3167         "." => \&main::_operator_dot,
3168         ".=" => \&main::_operator_dot_equal,
3169     ;
3170
3171     sub _operator_stringify {
3172         my $self = shift;
3173         my $addr = do { no overloading; pack 'J', $self; };
3174
3175         # Output it like '0041..0065 (value)'
3176         my $return = sprintf("%04X", $start{$addr})
3177                         .  '..'
3178                         . sprintf("%04X", $end{$addr});
3179         my $value = $value{$addr};
3180         my $type = $type{$addr};
3181         $return .= ' (';
3182         $return .= "$value";
3183         $return .= ", Type=$type" if $type != 0;
3184         $return .= ')';
3185
3186         return $return;
3187     }
3188
3189     sub standard_form {
3190         # Calculate the standard form only if needed, and cache the result.
3191         # The standard form is the value itself if the type is special.
3192         # This represents a considerable CPU and memory saving - at the time
3193         # of writing there are 368676 non-special objects, but the standard
3194         # form is only requested for 22047 of them - ie about 6%.
3195
3196         my $self = shift;
3197         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3198
3199         my $addr = do { no overloading; pack 'J', $self; };
3200
3201         return $standard_form{$addr} if defined $standard_form{$addr};
3202
3203         my $value = $value{$addr};
3204         return $value if $type{$addr};
3205         return $standard_form{$addr} = main::standardize($value);
3206     }
3207
3208     sub dump {
3209         # Human, not machine readable.  For machine readable, comment out this
3210         # entire routine and let the standard one take effect.
3211         my $self = shift;
3212         my $indent = shift;
3213         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3214
3215         my $addr = do { no overloading; pack 'J', $self; };
3216
3217         my $return = $indent
3218                     . sprintf("%04X", $start{$addr})
3219                     . '..'
3220                     . sprintf("%04X", $end{$addr})
3221                     . " '$value{$addr}';";
3222         if (! defined $standard_form{$addr}) {
3223             $return .= "(type=$type{$addr})";
3224         }
3225         elsif ($standard_form{$addr} ne $value{$addr}) {
3226             $return .= "(standard '$standard_form{$addr}')";
3227         }
3228         return $return;
3229     }
3230 } # End closure
3231
3232 package _Range_List_Base;
3233
3234 # Base class for range lists.  A range list is simply an ordered list of
3235 # ranges, so that the ranges with the lowest starting numbers are first in it.
3236 #
3237 # When a new range is added that is adjacent to an existing range that has the
3238 # same value and type, it merges with it to form a larger range.
3239 #
3240 # Ranges generally do not overlap, except that there can be multiple entries
3241 # of single code point ranges.  This is because of NameAliases.txt.
3242 #
3243 # In this program, there is a standard value such that if two different
3244 # values, have the same standard value, they are considered equivalent.  This
3245 # value was chosen so that it gives correct results on Unicode data
3246
3247 # There are a number of methods to manipulate range lists, and some operators
3248 # are overloaded to handle them.
3249
3250 sub trace { return main::trace(@_); }
3251
3252 { # Closure
3253
3254     our $addr;
3255
3256     # Max is initialized to a negative value that isn't adjacent to 0, for
3257     # simpler tests
3258     my $max_init = -2;
3259
3260     main::setup_package();
3261
3262     my %ranges;
3263     # The list of ranges
3264     main::set_access('ranges', \%ranges, 'readable_array');
3265
3266     my %max;
3267     # The highest code point in the list.  This was originally a method, but
3268     # actual measurements said it was used a lot.
3269     main::set_access('max', \%max, 'r');
3270
3271     my %each_range_iterator;
3272     # Iterator position for each_range()
3273     main::set_access('each_range_iterator', \%each_range_iterator);
3274
3275     my %owner_name_of;
3276     # Name of parent this is attached to, if any.  Solely for better error
3277     # messages.
3278     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3279
3280     my %_search_ranges_cache;
3281     # A cache of the previous result from _search_ranges(), for better
3282     # performance
3283     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3284
3285     sub new {
3286         my $class = shift;
3287         my %args = @_;
3288
3289         # Optional initialization data for the range list.
3290         my $initialize = delete $args{'Initialize'};
3291
3292         my $self;
3293
3294         # Use _union() to initialize.  _union() returns an object of this
3295         # class, which means that it will call this constructor recursively.
3296         # But it won't have this $initialize parameter so that it won't
3297         # infinitely loop on this.
3298         return _union($class, $initialize, %args) if defined $initialize;
3299
3300         $self = bless \do { my $anonymous_scalar }, $class;
3301         my $addr = do { no overloading; pack 'J', $self; };
3302
3303         # Optional parent object, only for debug info.
3304         $owner_name_of{$addr} = delete $args{'Owner'};
3305         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3306
3307         # Stringify, in case it is an object.
3308         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3309
3310         # This is used only for error messages, and so a colon is added
3311         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3312
3313         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3314
3315         $max{$addr} = $max_init;
3316
3317         $_search_ranges_cache{$addr} = 0;
3318         $ranges{$addr} = [];
3319
3320         return $self;
3321     }
3322
3323     use overload
3324         fallback => 0,
3325         qw("") => "_operator_stringify",
3326         "." => \&main::_operator_dot,
3327         ".=" => \&main::_operator_dot_equal,
3328     ;
3329
3330     sub _operator_stringify {
3331         my $self = shift;
3332         my $addr = do { no overloading; pack 'J', $self; };
3333
3334         return "Range_List attached to '$owner_name_of{$addr}'"
3335                                                 if $owner_name_of{$addr};
3336         return "anonymous Range_List " . \$self;
3337     }
3338
3339     sub _union {
3340         # Returns the union of the input code points.  It can be called as
3341         # either a constructor or a method.  If called as a method, the result
3342         # will be a new() instance of the calling object, containing the union
3343         # of that object with the other parameter's code points;  if called as
3344         # a constructor, the first parameter gives the class that the new object
3345         # should be, and the second parameter gives the code points to go into
3346         # it.
3347         # In either case, there are two parameters looked at by this routine;
3348         # any additional parameters are passed to the new() constructor.
3349         #
3350         # The code points can come in the form of some object that contains
3351         # ranges, and has a conventionally named method to access them; or
3352         # they can be an array of individual code points (as integers); or
3353         # just a single code point.
3354         #
3355         # If they are ranges, this routine doesn't make any effort to preserve
3356         # the range values and types of one input over the other.  Therefore
3357         # this base class should not allow _union to be called from other than
3358         # initialization code, so as to prevent two tables from being added
3359         # together where the range values matter.  The general form of this
3360         # routine therefore belongs in a derived class, but it was moved here
3361         # to avoid duplication of code.  The failure to overload this in this
3362         # class keeps it safe.
3363         #
3364         # It does make the effort during initialization to accept tables with
3365         # multiple values for the same code point, and to preserve the order
3366         # of these.  If there is only one input range or range set, it doesn't
3367         # sort (as it should already be sorted to the desired order), and will
3368         # accept multiple values per code point.  Otherwise it will merge
3369         # multiple values into a single one.
3370
3371         my $self;
3372         my @args;   # Arguments to pass to the constructor
3373
3374         my $class = shift;
3375
3376         # If a method call, will start the union with the object itself, and
3377         # the class of the new object will be the same as self.
3378         if (ref $class) {
3379             $self = $class;
3380             $class = ref $self;
3381             push @args, $self;
3382         }
3383
3384         # Add the other required parameter.
3385         push @args, shift;
3386         # Rest of parameters are passed on to the constructor
3387
3388         # Accumulate all records from both lists.
3389         my @records;
3390         my $input_count = 0;
3391         for my $arg (@args) {
3392             #local $to_trace = 0 if main::DEBUG;
3393             trace "argument = $arg" if main::DEBUG && $to_trace;
3394             if (! defined $arg) {
3395                 my $message = "";
3396                 if (defined $self) {
3397                     no overloading;
3398                     $message .= $owner_name_of{pack 'J', $self};
3399                 }
3400                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3401                 return;
3402             }
3403
3404             $arg = [ $arg ] if ! ref $arg;
3405             my $type = ref $arg;
3406             if ($type eq 'ARRAY') {
3407                 foreach my $element (@$arg) {
3408                     push @records, Range->new($element, $element);
3409                     $input_count++;
3410                 }
3411             }
3412             elsif ($arg->isa('Range')) {
3413                 push @records, $arg;
3414                 $input_count++;
3415             }
3416             elsif ($arg->can('ranges')) {
3417                 push @records, $arg->ranges;
3418                 $input_count++;
3419             }
3420             else {
3421                 my $message = "";
3422                 if (defined $self) {
3423                     no overloading;
3424                     $message .= $owner_name_of{pack 'J', $self};
3425                 }
3426                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3427                 return;
3428             }
3429         }
3430
3431         # Sort with the range containing the lowest ordinal first, but if
3432         # two ranges start at the same code point, sort with the bigger range
3433         # of the two first, because it takes fewer cycles.
3434         if ($input_count > 1) {
3435             @records = sort { ($a->start <=> $b->start)
3436                                       or
3437                                     # if b is shorter than a, b->end will be
3438                                     # less than a->end, and we want to select
3439                                     # a, so want to return -1
3440                                     ($b->end <=> $a->end)
3441                                    } @records;
3442         }
3443
3444         my $new = $class->new(@_);
3445
3446         # Fold in records so long as they add new information.
3447         for my $set (@records) {
3448             my $start = $set->start;
3449             my $end   = $set->end;
3450             my $value = $set->value;
3451             my $type  = $set->type;
3452             if ($start > $new->max) {
3453                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3454             }
3455             elsif ($end > $new->max) {
3456                 $new->_add_delete('+', $new->max +1, $end, $value,
3457                                                                 Type => $type);
3458             }
3459             elsif ($input_count == 1) {
3460                 # Here, overlaps existing range, but is from a single input,
3461                 # so preserve the multiple values from that input.
3462                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3463                                                 Replace => $MULTIPLE_AFTER);
3464             }
3465         }
3466
3467         return $new;
3468     }
3469
3470     sub range_count {        # Return the number of ranges in the range list
3471         my $self = shift;
3472         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3473
3474         no overloading;
3475         return scalar @{$ranges{pack 'J', $self}};
3476     }
3477
3478     sub min {
3479         # Returns the minimum code point currently in the range list, or if
3480         # the range list is empty, 2 beyond the max possible.  This is a
3481         # method because used so rarely, that not worth saving between calls,
3482         # and having to worry about changing it as ranges are added and
3483         # deleted.
3484
3485         my $self = shift;
3486         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3487
3488         my $addr = do { no overloading; pack 'J', $self; };
3489
3490         # If the range list is empty, return a large value that isn't adjacent
3491         # to any that could be in the range list, for simpler tests
3492         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3493         return $ranges{$addr}->[0]->start;
3494     }
3495
3496     sub contains {
3497         # Boolean: Is argument in the range list?  If so returns $i such that:
3498         #   range[$i]->end < $codepoint <= range[$i+1]->end
3499         # which is one beyond what you want; this is so that the 0th range
3500         # doesn't return false
3501         my $self = shift;
3502         my $codepoint = shift;
3503         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3504
3505         my $i = $self->_search_ranges($codepoint);
3506         return 0 unless defined $i;
3507
3508         # The search returns $i, such that
3509         #   range[$i-1]->end < $codepoint <= range[$i]->end
3510         # So is in the table if and only iff it is at least the start position
3511         # of range $i.
3512         no overloading;
3513         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3514         return $i + 1;
3515     }
3516
3517     sub containing_range {
3518         # Returns the range object that contains the code point, undef if none
3519
3520         my $self = shift;
3521         my $codepoint = shift;
3522         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3523
3524         my $i = $self->contains($codepoint);
3525         return unless $i;
3526
3527         # contains() returns 1 beyond where we should look
3528         no overloading;
3529         return $ranges{pack 'J', $self}->[$i-1];
3530     }
3531
3532     sub value_of {
3533         # Returns the value associated with the code point, undef if none
3534
3535         my $self = shift;
3536         my $codepoint = shift;
3537         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3538
3539         my $range = $self->containing_range($codepoint);
3540         return unless defined $range;
3541
3542         return $range->value;
3543     }
3544
3545     sub type_of {
3546         # Returns the type of the range containing the code point, undef if
3547         # the code point is not in the table
3548
3549         my $self = shift;
3550         my $codepoint = shift;
3551         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3552
3553         my $range = $self->containing_range($codepoint);
3554         return unless defined $range;
3555
3556         return $range->type;
3557     }
3558
3559     sub _search_ranges {
3560         # Find the range in the list which contains a code point, or where it
3561         # should go if were to add it.  That is, it returns $i, such that:
3562         #   range[$i-1]->end < $codepoint <= range[$i]->end
3563         # Returns undef if no such $i is possible (e.g. at end of table), or
3564         # if there is an error.
3565
3566         my $self = shift;
3567         my $code_point = shift;
3568         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3569
3570         my $addr = do { no overloading; pack 'J', $self; };
3571
3572         return if $code_point > $max{$addr};
3573         my $r = $ranges{$addr};                # The current list of ranges
3574         my $range_list_size = scalar @$r;
3575         my $i;
3576
3577         use integer;        # want integer division
3578
3579         # Use the cached result as the starting guess for this one, because,
3580         # an experiment on 5.1 showed that 90% of the time the cache was the
3581         # same as the result on the next call (and 7% it was one less).
3582         $i = $_search_ranges_cache{$addr};
3583         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3584                                             # from an intervening deletion
3585         #local $to_trace = 1 if main::DEBUG;
3586         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3587         return $i if $code_point <= $r->[$i]->end
3588                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3589
3590         # Here the cache doesn't yield the correct $i.  Try adding 1.
3591         if ($i < $range_list_size - 1
3592             && $r->[$i]->end < $code_point &&
3593             $code_point <= $r->[$i+1]->end)
3594         {
3595             $i++;
3596             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3597             $_search_ranges_cache{$addr} = $i;
3598             return $i;
3599         }
3600
3601         # Here, adding 1 also didn't work.  We do a binary search to
3602         # find the correct position, starting with current $i
3603         my $lower = 0;
3604         my $upper = $range_list_size - 1;
3605         while (1) {
3606             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3607
3608             if ($code_point <= $r->[$i]->end) {
3609
3610                 # Here we have met the upper constraint.  We can quit if we
3611                 # also meet the lower one.
3612                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3613
3614                 $upper = $i;        # Still too high.
3615
3616             }
3617             else {
3618
3619                 # Here, $r[$i]->end < $code_point, so look higher up.
3620                 $lower = $i;
3621             }
3622
3623             # Split search domain in half to try again.
3624             my $temp = ($upper + $lower) / 2;
3625
3626             # No point in continuing unless $i changes for next time
3627             # in the loop.
3628             if ($temp == $i) {
3629
3630                 # We can't reach the highest element because of the averaging.
3631                 # So if one below the upper edge, force it there and try one
3632                 # more time.
3633                 if ($i == $range_list_size - 2) {
3634
3635                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3636                     $i = $range_list_size - 1;
3637
3638                     # Change $lower as well so if fails next time through,
3639                     # taking the average will yield the same $i, and we will
3640                     # quit with the error message just below.
3641                     $lower = $i;
3642                     next;
3643                 }
3644                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3645                 return;
3646             }
3647             $i = $temp;
3648         } # End of while loop
3649
3650         if (main::DEBUG && $to_trace) {
3651             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3652             trace "i=  [ $i ]", $r->[$i];
3653             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3654         }
3655
3656         # Here we have found the offset.  Cache it as a starting point for the
3657         # next call.
3658         $_search_ranges_cache{$addr} = $i;
3659         return $i;
3660     }
3661
3662     sub _add_delete {
3663         # Add, replace or delete ranges to or from a list.  The $type
3664         # parameter gives which:
3665         #   '+' => insert or replace a range, returning a list of any changed
3666         #          ranges.
3667         #   '-' => delete a range, returning a list of any deleted ranges.
3668         #
3669         # The next three parameters give respectively the start, end, and
3670         # value associated with the range.  'value' should be null unless the
3671         # operation is '+';
3672         #
3673         # The range list is kept sorted so that the range with the lowest
3674         # starting position is first in the list, and generally, adjacent
3675         # ranges with the same values are merged into a single larger one (see
3676         # exceptions below).
3677         #
3678         # There are more parameters; all are key => value pairs:
3679         #   Type    gives the type of the value.  It is only valid for '+'.
3680         #           All ranges have types; if this parameter is omitted, 0 is
3681         #           assumed.  Ranges with type 0 are assumed to obey the
3682         #           Unicode rules for casing, etc; ranges with other types are
3683         #           not.  Otherwise, the type is arbitrary, for the caller's
3684         #           convenience, and looked at only by this routine to keep
3685         #           adjacent ranges of different types from being merged into
3686         #           a single larger range, and when Replace =>
3687         #           $IF_NOT_EQUIVALENT is specified (see just below).
3688         #   Replace  determines what to do if the range list already contains
3689         #            ranges which coincide with all or portions of the input
3690         #            range.  It is only valid for '+':
3691         #       => $NO            means that the new value is not to replace
3692         #                         any existing ones, but any empty gaps of the
3693         #                         range list coinciding with the input range
3694         #                         will be filled in with the new value.
3695         #       => $UNCONDITIONALLY  means to replace the existing values with
3696         #                         this one unconditionally.  However, if the
3697         #                         new and old values are identical, the
3698         #                         replacement is skipped to save cycles
3699         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3700         #          (the default)  with this one if they are not equivalent.
3701         #                         Ranges are equivalent if their types are the
3702         #                         same, and they are the same string; or if
3703         #                         both are type 0 ranges, if their Unicode
3704         #                         standard forms are identical.  In this last
3705         #                         case, the routine chooses the more "modern"
3706         #                         one to use.  This is because some of the
3707         #                         older files are formatted with values that
3708         #                         are, for example, ALL CAPs, whereas the
3709         #                         derived files have a more modern style,
3710         #                         which looks better.  By looking for this
3711         #                         style when the pre-existing and replacement
3712         #                         standard forms are the same, we can move to
3713         #                         the modern style
3714         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3715         #                         existing one, but has a different value,
3716         #                         don't replace the existing one, but insert
3717         #                         this, one so that the same range can occur
3718         #                         multiple times.  They are stored LIFO, so
3719         #                         that the final one inserted is the first one
3720         #                         returned in an ordered search of the table.
3721         #                         If this is an exact duplicate, including the
3722         #                         value, the original will be moved to be
3723         #                         first, before any other duplicate ranges
3724         #                         with different values.
3725         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3726         #                         FIFO, so that this one is inserted after all
3727         #                         others that currently exist.  If this is an
3728         #                         exact duplicate, including value, of an
3729         #                         existing range, this one is discarded
3730         #                         (leaving the existing one in its original,
3731         #                         higher priority position
3732         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3733         #
3734         # "same value" means identical for non-type-0 ranges, and it means
3735         # having the same standard forms for type-0 ranges.
3736
3737         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3738
3739         my $self = shift;
3740         my $operation = shift;   # '+' for add/replace; '-' for delete;
3741         my $start = shift;
3742         my $end   = shift;
3743         my $value = shift;
3744
3745         my %args = @_;
3746
3747         $value = "" if not defined $value;        # warning: $value can be "0"
3748
3749         my $replace = delete $args{'Replace'};
3750         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3751
3752         my $type = delete $args{'Type'};
3753         $type = 0 unless defined $type;
3754
3755         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3756
3757         my $addr = do { no overloading; pack 'J', $self; };
3758
3759         if ($operation ne '+' && $operation ne '-') {
3760             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3761             return;
3762         }
3763         unless (defined $start && defined $end) {
3764             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3765             return;
3766         }
3767         unless ($end >= $start) {
3768             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3769             return;
3770         }
3771         #local $to_trace = 1 if main::DEBUG;
3772
3773         if ($operation eq '-') {
3774             if ($replace != $IF_NOT_EQUIVALENT) {
3775                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3776                 $replace = $IF_NOT_EQUIVALENT;
3777             }
3778             if ($type) {
3779                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3780                 $type = 0;
3781             }
3782             if ($value ne "") {
3783                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3784                 $value = "";
3785             }
3786         }
3787
3788         my $r = $ranges{$addr};               # The current list of ranges
3789         my $range_list_size = scalar @$r;     # And its size
3790         my $max = $max{$addr};                # The current high code point in
3791                                               # the list of ranges
3792
3793         # Do a special case requiring fewer machine cycles when the new range
3794         # starts after the current highest point.  The Unicode input data is
3795         # structured so this is common.
3796         if ($start > $max) {
3797
3798             trace "$owner_name_of{$addr} $operation", sprintf("%04X..%04X (%s) type=%d; prev max=%04X", $start, $end, $value, $type, $max) if main::DEBUG && $to_trace;
3799             return if $operation eq '-'; # Deleting a non-existing range is a
3800                                          # no-op
3801
3802             # If the new range doesn't logically extend the current final one
3803             # in the range list, create a new range at the end of the range
3804             # list.  (max cleverly is initialized to a negative number not
3805             # adjacent to 0 if the range list is empty, so even adding a range
3806             # to an empty range list starting at 0 will have this 'if'
3807             # succeed.)
3808             if ($start > $max + 1        # non-adjacent means can't extend.
3809                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3810                 || @{$r}[-1]->type != $type # types differ, can't extend.
3811             ) {
3812                 push @$r, Range->new($start, $end,
3813                                      Value => $value,
3814                                      Type => $type);
3815             }
3816             else {
3817
3818                 # Here, the new range starts just after the current highest in
3819                 # the range list, and they have the same type and value.
3820                 # Extend the current range to incorporate the new one.
3821                 @{$r}[-1]->set_end($end);
3822             }
3823
3824             # This becomes the new maximum.
3825             $max{$addr} = $end;
3826
3827             return;
3828         }
3829         #local $to_trace = 0 if main::DEBUG;
3830
3831         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3832
3833         # Here, the input range isn't after the whole rest of the range list.
3834         # Most likely 'splice' will be needed.  The rest of the routine finds
3835         # the needed splice parameters, and if necessary, does the splice.
3836         # First, find the offset parameter needed by the splice function for
3837         # the input range.  Note that the input range may span multiple
3838         # existing ones, but we'll worry about that later.  For now, just find
3839         # the beginning.  If the input range is to be inserted starting in a
3840         # position not currently in the range list, it must (obviously) come
3841         # just after the range below it, and just before the range above it.
3842         # Slightly less obviously, it will occupy the position currently
3843         # occupied by the range that is to come after it.  More formally, we
3844         # are looking for the position, $i, in the array of ranges, such that:
3845         #
3846         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3847         #
3848         # (The ordered relationships within existing ranges are also shown in
3849         # the equation above).  However, if the start of the input range is
3850         # within an existing range, the splice offset should point to that
3851         # existing range's position in the list; that is $i satisfies a
3852         # somewhat different equation, namely:
3853         #
3854         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3855         #
3856         # More briefly, $start can come before or after r[$i]->start, and at
3857         # this point, we don't know which it will be.  However, these
3858         # two equations share these constraints:
3859         #
3860         #   r[$i-1]->end < $start <= r[$i]->end
3861         #
3862         # And that is good enough to find $i.
3863
3864         my $i = $self->_search_ranges($start);
3865         if (! defined $i) {
3866             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3867             return;
3868         }
3869
3870         # The search function returns $i such that:
3871         #
3872         # r[$i-1]->end < $start <= r[$i]->end
3873         #
3874         # That means that $i points to the first range in the range list
3875         # that could possibly be affected by this operation.  We still don't
3876         # know if the start of the input range is within r[$i], or if it
3877         # points to empty space between r[$i-1] and r[$i].
3878         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3879
3880         # Special case the insertion of data that is not to replace any
3881         # existing data.
3882         if ($replace == $NO) {  # If $NO, has to be operation '+'
3883             #local $to_trace = 1 if main::DEBUG;
3884             trace "Doesn't replace" if main::DEBUG && $to_trace;
3885
3886             # Here, the new range is to take effect only on those code points
3887             # that aren't already in an existing range.  This can be done by
3888             # looking through the existing range list and finding the gaps in
3889             # the ranges that this new range affects, and then calling this
3890             # function recursively on each of those gaps, leaving untouched
3891             # anything already in the list.  Gather up a list of the changed
3892             # gaps first so that changes to the internal state as new ranges
3893             # are added won't be a problem.
3894             my @gap_list;
3895
3896             # First, if the starting point of the input range is outside an
3897             # existing one, there is a gap from there to the beginning of the
3898             # existing range -- add a span to fill the part that this new
3899             # range occupies
3900             if ($start < $r->[$i]->start) {
3901                 push @gap_list, Range->new($start,
3902                                            main::min($end,
3903                                                      $r->[$i]->start - 1),
3904                                            Type => $type);
3905                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3906             }
3907
3908             # Then look through the range list for other gaps until we reach
3909             # the highest range affected by the input one.
3910             my $j;
3911             for ($j = $i+1; $j < $range_list_size; $j++) {
3912                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3913                 last if $end < $r->[$j]->start;
3914
3915                 # If there is a gap between when this range starts and the
3916                 # previous one ends, add a span to fill it.  Note that just
3917                 # because there are two ranges doesn't mean there is a
3918                 # non-zero gap between them.  It could be that they have
3919                 # different values or types
3920                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3921                     push @gap_list,
3922                         Range->new($r->[$j-1]->end + 1,
3923                                    $r->[$j]->start - 1,
3924                                    Type => $type);
3925                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3926                 }
3927             }
3928
3929             # Here, we have either found an existing range in the range list,
3930             # beyond the area affected by the input one, or we fell off the
3931             # end of the loop because the input range affects the whole rest
3932             # of the range list.  In either case, $j is 1 higher than the
3933             # highest affected range.  If $j == $i, it means that there are no
3934             # affected ranges, that the entire insertion is in the gap between
3935             # r[$i-1], and r[$i], which we already have taken care of before
3936             # the loop.
3937             # On the other hand, if there are affected ranges, it might be
3938             # that there is a gap that needs filling after the final such
3939             # range to the end of the input range
3940             if ($r->[$j-1]->end < $end) {
3941                     push @gap_list, Range->new(main::max($start,
3942                                                          $r->[$j-1]->end + 1),
3943                                                $end,
3944                                                Type => $type);
3945                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3946             }
3947
3948             # Call recursively to fill in all the gaps.
3949             foreach my $gap (@gap_list) {
3950                 $self->_add_delete($operation,
3951                                    $gap->start,
3952                                    $gap->end,
3953                                    $value,
3954                                    Type => $type);
3955             }
3956
3957             return;
3958         }
3959
3960         # Here, we have taken care of the case where $replace is $NO.
3961         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3962         # If inserting a multiple record, this is where it goes, before the
3963         # first (if any) existing one if inserting LIFO.  (If this is to go
3964         # afterwards, FIFO, we below move the pointer to there.)  These imply
3965         # an insertion, and no change to any existing ranges.  Note that $i
3966         # can be -1 if this new range doesn't actually duplicate any existing,
3967         # and comes at the beginning of the list.
3968         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3969
3970             if ($start != $end) {
3971                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3972                 return;
3973             }
3974
3975             # If the new code point is within a current range ...
3976             if ($end >= $r->[$i]->start) {
3977
3978                 # Don't add an exact duplicate, as it isn't really a multiple
3979                 my $existing_value = $r->[$i]->value;
3980                 my $existing_type = $r->[$i]->type;
3981                 return if $value eq $existing_value && $type eq $existing_type;
3982
3983                 # If the multiple value is part of an existing range, we want
3984                 # to split up that range, so that only the single code point
3985                 # is affected.  To do this, we first call ourselves
3986                 # recursively to delete that code point from the table, having
3987                 # preserved its current data above.  Then we call ourselves
3988                 # recursively again to add the new multiple, which we know by
3989                 # the test just above is different than the current code
3990                 # point's value, so it will become a range containing a single
3991                 # code point: just itself.  Finally, we add back in the
3992                 # pre-existing code point, which will again be a single code
3993                 # point range.  Because 'i' likely will have changed as a
3994                 # result of these operations, we can't just continue on, but
3995                 # do this operation recursively as well.  If we are inserting
3996                 # LIFO, the pre-existing code point needs to go after the new
3997                 # one, so use MULTIPLE_AFTER; and vice versa.
3998                 if ($r->[$i]->start != $r->[$i]->end) {
3999                     $self->_add_delete('-', $start, $end, "");