This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
RT#114312: prevent ls from colourizing output
[perl5.git] / t / op / stat.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = '../lib';
6     require './test.pl';        # for which_perl() etc
7 }
8
9 use Config;
10
11 my ($Null, $Curdir);
12 if(eval {require File::Spec; 1}) {
13     $Null = File::Spec->devnull;
14     $Curdir = File::Spec->curdir;
15 } else {
16     die $@ unless is_miniperl();
17     $Curdir = '.';
18     diag("miniperl failed to load File::Spec, error is:\n$@");
19     diag("\ncontinuing, assuming '.' for current directory. Some tests will be skipped.");
20 }
21
22
23 plan tests => 113;
24
25 my $Perl = which_perl();
26
27 $ENV{LC_ALL}   = 'C';           # Forge English error messages.
28 $ENV{LANGUAGE} = 'C';           # Ditto in GNU.
29
30 $Is_Amiga   = $^O eq 'amigaos';
31 $Is_Cygwin  = $^O eq 'cygwin';
32 $Is_Darwin  = $^O eq 'darwin';
33 $Is_Dos     = $^O eq 'dos';
34 $Is_MPE     = $^O eq 'mpeix';
35 $Is_MSWin32 = $^O eq 'MSWin32';
36 $Is_NetWare = $^O eq 'NetWare';
37 $Is_OS2     = $^O eq 'os2';
38 $Is_Solaris = $^O eq 'solaris';
39 $Is_VMS     = $^O eq 'VMS';
40 $Is_DGUX    = $^O eq 'dgux';
41 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
42 $Is_Rhapsody= $^O eq 'rhapsody';
43
44 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare;
45
46 $Is_UFS     = $Is_Darwin && (() = `df -t ufs . 2>/dev/null`) == 2;
47
48 if ($Is_Cygwin) {
49   require Win32;
50   Win32->import;
51 }
52
53 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
54    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
55
56 my $tmpfile = tempfile();
57 my $tmpfile_link = tempfile();
58
59 chmod 0666, $tmpfile;
60 unlink_all $tmpfile;
61 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
62 close FOO;
63
64 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
65
66 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
67
68 # The clock on a network filesystem might be different from the
69 # system clock.
70 my $Filesystem_Time_Offset = abs($mtime - time); 
71
72 #nlink should if link support configured in Perl.
73 SKIP: {
74     skip "No link count - Hard link support not built in.", 1
75         unless $Config{d_link};
76
77     is($nlink, 1, 'nlink on regular file');
78 }
79
80 SKIP: {
81   skip "mtime and ctime not reliable", 2
82     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_Darwin;
83
84   ok( $mtime,           'mtime' );
85   is( $mtime, $ctime,   'mtime == ctime' );
86 }
87
88
89 # Cygwin seems to have a 3 second granularity on its timestamps.
90 my $funky_FAT_timestamps = $Is_Cygwin;
91 sleep 3 if $funky_FAT_timestamps;
92
93 print FOO "Now is the time for all good men to come to.\n";
94 close(FOO);
95
96 sleep 2;
97
98
99 SKIP: {
100     unlink $tmpfile_link;
101     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
102     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
103
104     is( $@, '',         'link() implemented' );
105     ok( $lnk_result,    'linked tmp testfile' );
106     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
107
108     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
109
110     SKIP: {
111         skip "No link count", 1 if $Config{dont_use_nlink};
112         skip "Cygwin9X fakes hard links by copying", 1
113           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
114
115         is($nlink, 2,     'Link count on hard linked file' );
116     }
117
118     SKIP: {
119         skip_if_miniperl("File::Spec not built for minitest", 2);
120         my $cwd = File::Spec->rel2abs($Curdir);
121         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
122                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
123                                         $mtime && $mtime == $ctime;
124         skip "AFS has different mtime/ctime link semantics", 2
125                                      if $cwd =~ m#$Config{'afsroot'}/#;
126         skip "AmigaOS has different mtime/ctime link semantics", 2
127                                      if $Is_Amiga;
128         # Win32 could pass $mtime test but as FAT and NTFS have
129         # no ctime concept $ctime is ALWAYS == $mtime
130         # expect netware to be the same ...
131         skip "No ctime concept on this OS", 2
132                                      if $Is_MSWin32 || 
133                                         ($Is_Darwin && $Is_UFS);
134
135         if( !ok($mtime, 'hard link mtime') ||
136             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
137             print STDERR <<DIAG;
138 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
139 # has this problem.  Building on the ClearCase VOBS filesystem may also
140 # cause this failure.
141 #
142 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
143 # this test.
144 DIAG
145         }
146     }
147
148 }
149
150 # truncate and touch $tmpfile.
151 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
152 ok(-z \*F,     '-z on empty filehandle');
153 ok(! -s \*F,   '   and -s');
154 close F;
155
156 ok(-z $tmpfile,     '-z on empty file');
157 ok(! -s $tmpfile,   '   and -s');
158
159 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
160 print F "hi\n";
161 close F;
162
163 open(F, "<$tmpfile") || DIE("Can't open temp test file: $!");
164 ok(!-z *F,     '-z on empty filehandle');
165 ok( -s *F,   '   and -s');
166 close F;
167
168 ok(! -z $tmpfile,   '-z on non-empty file');
169 ok(-s $tmpfile,     '   and -s');
170
171
172 # Strip all access rights from the file.
173 ok( chmod(0000, $tmpfile),     'chmod 0000' );
174
175 SKIP: {
176     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
177
178     SKIP: {
179         # Going to try to switch away from root.  Might not work.
180         my $olduid = $>;
181         eval { $> = 1; };
182         skip "Can't test -r or -w meaningfully if you're superuser", 2
183           if ($Is_Cygwin ? Win32::IsAdminUser : $> == 0);
184
185         SKIP: {
186             skip "Can't test -r meaningfully?", 1 if $Is_Dos;
187             ok(!-r $tmpfile,    "   -r");
188         }
189
190         ok(!-w $tmpfile,    "   -w");
191
192         # switch uid back (may not be implemented)
193         eval { $> = $olduid; };
194     }
195
196     ok(! -x $tmpfile,   '   -x');
197 }
198
199
200
201 ok(chmod(0700,$tmpfile),    'chmod 0700');
202 ok(-r $tmpfile,     '   -r');
203 ok(-w $tmpfile,     '   -w');
204
205 SKIP: {
206     skip "-x simply determines if a file ends in an executable suffix", 1
207       if $Is_Dosish;
208
209     ok(-x $tmpfile,     '   -x');
210 }
211
212 ok(  -f $tmpfile,   '   -f');
213 ok(! -d $tmpfile,   '   !-d');
214
215 # Is this portable?
216 ok(  -d '.',          '-d cwd' );
217 ok(! -f '.',          '!-f cwd' );
218
219
220 SKIP: {
221     unlink($tmpfile_link);
222     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
223     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
224
225     is( $@, '',     'symlink() implemented' );
226     ok( $symlink_rslt,      'symlink() ok' );
227     ok(-l $tmpfile_link,    '-l');
228 }
229
230 ok(-o $tmpfile,     '-o');
231
232 ok(-e $tmpfile,     '-e');
233
234 unlink($tmpfile_link);
235 ok(! -e $tmpfile_link,  '   -e on unlinked file');
236
237 SKIP: {
238     skip "No character, socket or block special files", 6
239       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
240     skip "/dev isn't available to test against", 6
241       unless -d '/dev' && -r '/dev' && -x '/dev';
242     skip "Skipping: unexpected ls output in MP-RAS", 6
243       if $Is_MPRAS;
244
245     # VMS problem:  If GNV or other UNIX like tool is installed, then
246     # sometimes Perl will find /bin/ls, and will try to run it.
247     # But since Perl on VMS does not know to run it under Bash, it will
248     # try to run the DCL verb LS.  And if the VMS product Language
249     # Sensitive Editor is installed, or some other LS verb, that will
250     # be run instead.  So do not do this until we can teach Perl
251     # when to use BASH on VMS.
252     skip "ls command not available to Perl in OpenVMS right now.", 6
253       if $Is_VMS;
254
255     delete $ENV{CLICOLOR_FORCE};
256     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
257     my $CMD = "$LS /dev 2>/dev/null";
258     my $DEV = qx($CMD);
259
260     skip "$CMD failed", 6 if $DEV eq '';
261
262     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
263
264     skip "opendir failed: $!", 6 if @DEV == 0;
265
266     # /dev/stdout might be either character special or a named pipe,
267     # or a symlink, or a socket, depending on which OS and how are
268     # you running the test, so let's censor that one away.
269     # Similar remarks hold for stderr.
270     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
271     @DEV =  grep { $_ ne 'stdout' } @DEV;
272     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
273     @DEV =  grep { $_ ne 'stderr' } @DEV;
274
275     # /dev/printer is also naughty: in IRIX it shows up as
276     # Srwx-----, not srwx------.
277     $DEV =~ s{^.+?\sprinter$}{}m;
278     @DEV =  grep { $_ ne 'printer' } @DEV;
279
280     # If running as root, we will see .files in the ls result,
281     # and readdir() will see them always.  Potential for conflict,
282     # so let's weed them out.
283     $DEV =~ s{^.+?\s\..+?$}{}m;
284     @DEV =  grep { ! m{^\..+$} } @DEV;
285
286     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
287     if ($^O eq 'irix') {
288         $DEV =~ s{^S(.+?)}{s$1}mg;
289     }
290
291     my $try = sub {
292         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
293         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
294         my $c1 = scalar @c1;
295         my $c2 = scalar @c2;
296         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
297     };
298
299 SKIP: {
300     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
301
302     $try->('b', '-b');
303     $try->('c', '-c');
304     $try->('s', '-S');
305
306 }
307
308 ok(! -b $Curdir,    '!-b cwd');
309 ok(! -c $Curdir,    '!-c cwd');
310 ok(! -S $Curdir,    '!-S cwd');
311
312 }
313
314 SKIP: {
315     my($cnt, $uid);
316     $cnt = $uid = 0;
317
318     # Find a set of directories that's very likely to have setuid files
319     # but not likely to be *all* setuid files.
320     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
321     skip "Can't find a setuid file to test with", 3 unless @bin;
322
323     for my $bin (@bin) {
324         opendir BIN, $bin or die "Can't opendir $bin: $!";
325         while (defined($_ = readdir BIN)) {
326             $_ = "$bin/$_";
327             $cnt++;
328             $uid++ if -u;
329             last if $uid && $uid < $cnt;
330         }
331     }
332     closedir BIN;
333
334     skip "No setuid programs", 3 if $uid == 0;
335
336     isnt($cnt, 0,    'found some programs');
337     isnt($uid, 0,    '  found some setuid programs');
338     ok($uid < $cnt,  "    they're not all setuid");
339 }
340
341
342 # To assist in automated testing when a controlling terminal (/dev/tty)
343 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
344 # can be set to skip the tests that need a tty.
345 SKIP: {
346     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
347
348     my $TTY = $Is_Rhapsody ? "/dev/ttyp0" : "/dev/tty";
349
350     SKIP: {
351         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
352         skip "No TTY to test -t with", 2 unless -e $TTY;
353
354         open(TTY, $TTY) ||
355           warn "Can't open $TTY--run t/TEST outside of make.\n";
356         ok(-t TTY,  '-t');
357         ok(-c TTY,  'tty is -c');
358         close(TTY);
359     }
360     ok(! -t TTY,    '!-t on closed TTY filehandle');
361
362     {
363         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
364         ok(-t,          '-t on STDIN');
365     }
366 }
367
368 SKIP: {
369     skip "No null device to test with", 1 unless -e $Null;
370     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
371
372     open(NULL, $Null) or DIE("Can't open $Null: $!");
373     ok(! -t NULL,   'null device is not a TTY');
374     close(NULL);
375 }
376
377
378 # These aren't strictly "stat" calls, but so what?
379 my $statfile = './op/stat.t';
380 ok(  -T $statfile,    '-T');
381 ok(! -B $statfile,    '!-B');
382
383 SKIP: {
384      skip("DG/UX", 1) if $Is_DGUX;
385 ok(-B $Perl,      '-B');
386 }
387
388 ok(! -T $Perl,    '!-T');
389
390 open(FOO,$statfile);
391 SKIP: {
392     eval { -T FOO; };
393     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
394
395     is( $@, '',     '-T on filehandle causes no errors' );
396
397     ok(-T FOO,      '   -T');
398     ok(! -B FOO,    '   !-B');
399
400     $_ = <FOO>;
401     like($_, qr/perl/, 'after readline');
402     ok(-T FOO,      '   still -T');
403     ok(! -B FOO,    '   still -B');
404     close(FOO);
405
406     open(FOO,$statfile);
407     $_ = <FOO>;
408     like($_, qr/perl/,      'reopened and after readline');
409     ok(-T FOO,      '   still -T');
410     ok(! -B FOO,    '   still !-B');
411
412     ok(seek(FOO,0,0),   'after seek');
413     ok(-T FOO,          '   still -T');
414     ok(! -B FOO,        '   still !-B');
415
416     # It's documented this way in perlfunc *shrug*
417     () = <FOO>;
418     ok(eof FOO,         'at EOF');
419     ok(-T FOO,          '   still -T');
420     ok(-B FOO,          '   now -B');
421 }
422 close(FOO);
423
424
425 SKIP: {
426     skip "No null device to test with", 2 unless -e $Null;
427
428     ok(-T $Null,  'null device is -T');
429     ok(-B $Null,  '    and -B');
430 }
431
432
433 # and now, a few parsing tests:
434 $_ = $tmpfile;
435 ok(-f,      'bare -f   uses $_');
436 ok(-f(),    '     -f() "');
437
438 unlink $tmpfile or print "# unlink failed: $!\n";
439
440 # bug id 20011101.069
441 my @r = \stat($Curdir);
442 is(scalar @r, 13,   'stat returns full 13 elements');
443
444 stat $0;
445 eval { lstat _ };
446 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
447     'lstat _ croaks after stat' );
448 eval { lstat *_ };
449 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
450     'lstat *_ croaks after stat' );
451 eval { lstat \*_ };
452 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
453     'lstat \*_ croaks after stat' );
454 eval { -l _ };
455 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
456     '-l _ croaks after stat' );
457
458 lstat $0;
459 eval { lstat _ };
460 is( "$@", "", "lstat _ ok after lstat" );
461 eval { -l _ };
462 is( "$@", "", "-l _ ok after lstat" );
463
464 eval { lstat "test.pl" };
465 {
466     open my $fh, "test.pl";
467     stat *$fh{IO};
468     eval { lstat _ }
469 }
470 like $@, qr/^The stat preceding lstat\(\) wasn't an lstat at /,
471 'stat $ioref resets stat type';
472
473 {
474     my @statbuf = stat STDOUT;
475     stat "test.pl";
476     my @lstatbuf = lstat *STDOUT{IO};
477     is "@lstatbuf", "@statbuf", 'lstat $ioref reverts to regular fstat';
478 }
479   
480 SKIP: {
481     skip "No lstat", 2 unless $Config{d_lstat};
482
483     # bug id 20020124.004
484     # If we have d_lstat, we should have symlink()
485     my $linkname = 'stat-' . rand =~ y/.//dr;
486     my $target = $Perl;
487     $target =~ s/;\d+\z// if $Is_VMS; # symlinks don't like version numbers
488     symlink $target, $linkname or die "# Can't symlink $0: $!";
489     lstat $linkname;
490     -T _;
491     eval { lstat _ };
492     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
493         'lstat croaks after -T _' );
494     eval { -l _ };
495     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
496         '-l _ croaks after -T _' );
497     unlink $linkname or print "# unlink $linkname failed: $!\n";
498 }
499
500 SKIP: {
501     skip "Too much clock skew between system and filesystem", 5
502         if ($Filesystem_Time_Offset > 5);
503     print "# Zzz...\n";
504     sleep($Filesystem_Time_Offset+1);
505     my $f = 'tstamp.tmp';
506     unlink $f;
507     ok (open(S, "> $f"), 'can create tmp file');
508     close S or die;
509     my @a = stat $f;
510     print "# time=$^T, stat=(@a)\n";
511     my @b = (-M _, -A _, -C _);
512     print "# -MAC=(@b)\n";
513     ok( (-M _) < 0, 'negative -M works');
514     ok( (-A _) < 0, 'negative -A works');
515     ok( (-C _) < 0, 'negative -C works');
516     ok(unlink($f), 'unlink tmp file');
517 }
518
519 # [perl #4253]
520 {
521     ok(open(F, ">", $tmpfile), 'can create temp file');
522     close F;
523     chmod 0077, $tmpfile;
524     my @a = stat($tmpfile);
525     my $s1 = -s _;
526     -T _;
527     my $s2 = -s _;
528     is($s1, $s2, q(-T _ doesn't break the statbuffer));
529     SKIP: {
530         skip "No lstat", 1 unless $Config{d_lstat};
531         skip "uid=0", 1 unless $<&&$>;
532         skip "Readable by group/other means readable by me", 1 if $^O eq 'VMS';
533         lstat($tmpfile);
534         -T _;
535         ok(eval { lstat _ },
536            q(-T _ doesn't break lstat for unreadable file));
537     }
538     unlink $tmpfile;
539 }
540
541 SKIP: {
542     skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
543     ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
544     ok(stat(DIR), "stat() on dirhandle works"); 
545     ok(-d -r _ , "chained -x's on dirhandle"); 
546     ok(-d DIR, "-d on a dirhandle works");
547
548     # And now for the ambiguous bareword case
549     {
550         no warnings 'deprecated';
551         ok(open(DIR, "TEST"), 'Can open "TEST" dir')
552             || diag "Can't open 'TEST':  $!";
553     }
554     my $size = (stat(DIR))[7];
555     ok(defined $size, "stat() on bareword works");
556     is($size, -s "TEST", "size returned by stat of bareword is for the file");
557     ok(-f _, "ambiguous bareword uses file handle, not dir handle");
558     ok(-f DIR);
559     closedir DIR or die $!;
560     close DIR or die $!;
561 }
562
563 {
564     # RT #8244: *FILE{IO} does not behave like *FILE for stat() and -X() operators
565     ok(open(F, ">", $tmpfile), 'can create temp file');
566     my @thwap = stat *F{IO};
567     ok(@thwap, "stat(*F{IO}) works");    
568     ok( -f *F{IO} , "single file tests work with *F{IO}");
569     close F;
570     unlink $tmpfile;
571
572     #PVIO's hold dirhandle information, so let's test them too.
573
574     SKIP: {
575         skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
576         ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
577         ok(stat(*DIR{IO}), "stat() on *DIR{IO} works");
578         ok(-d _ , "The special file handle _ is set correctly"); 
579         ok(-d -r *DIR{IO} , "chained -x's on *DIR{IO}");
580
581         # And now for the ambiguous bareword case
582         {
583             no warnings 'deprecated';
584             ok(open(DIR, "TEST"), 'Can open "TEST" dir')
585                 || diag "Can't open 'TEST':  $!";
586         }
587         my $size = (stat(*DIR{IO}))[7];
588         ok(defined $size, "stat() on *THINGY{IO} works");
589         is($size, -s "TEST",
590            "size returned by stat of *THINGY{IO} is for the file");
591         ok(-f _, "ambiguous *THINGY{IO} uses file handle, not dir handle");
592         ok(-f *DIR{IO});
593         closedir DIR or die $!;
594         close DIR or die $!;
595     }
596 }
597
598 # [perl #71002]
599 {
600     local $^W = 1;
601     my $w;
602     local $SIG{__WARN__} = sub { warn shift; ++$w };
603     stat 'prepeinamehyparcheiarcheiometoonomaavto';
604     stat _;
605     is $w, undef, 'no unopened warning from stat _';
606 }
607
608 END {
609     chmod 0666, $tmpfile;
610     unlink_all $tmpfile;
611 }